This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: fchmod, fchown, fchdir
[perl5.git] / t / op / chdir.t
1 #!./perl -w
2
3 BEGIN {
4     # We're not going to chdir() into 't' because we don't know if
5     # chdir() works!  Instead, we'll hedge our bets and put both
6     # possibilities into @INC.
7     @INC = qw(t . lib ../lib);
8 }
9
10 use Config;
11 require "test.pl";
12 plan(tests => 38);
13
14 my $IsVMS   = $^O eq 'VMS';
15 my $IsMacOS = $^O eq 'MacOS';
16
17 # Might be a little early in the testing process to start using these,
18 # but I can't think of a way to write this test without them.
19 use File::Spec::Functions qw(:DEFAULT splitdir rel2abs splitpath);
20
21 # Can't use Cwd::abs_path() because it has different ideas about
22 # path separators than File::Spec.
23 sub abs_path {
24     my $d = rel2abs(curdir);
25
26     $d = uc($d) if $IsVMS;
27     $d = lc($d) if $^O =~ /^uwin/;
28     $d;
29 }
30
31 my $Cwd = abs_path;
32
33 # Let's get to a known position
34 SKIP: {
35     my ($vol,$dir) = splitpath(abs_path,1);
36     my $test_dir = $IsVMS ? 'T' : 't';
37     skip("Already in t/", 2) if (splitdir($dir))[-1] eq $test_dir;
38
39     ok( chdir($test_dir),     'chdir($test_dir)');
40     is( abs_path, catdir($Cwd, $test_dir),    '  abs_path() agrees' );
41 }
42
43 $Cwd = abs_path;
44
45 SKIP: {
46     skip("no fchdir", 6) unless ($Config{d_fchdir} || "") eq "define";
47     ok(opendir(my $dh, "."), "opendir .");
48     ok(open(my $fh, "<", "op"), "open op");
49     ok(chdir($fh), "fchdir op");
50     ok(-f "chdir.t", "verify that we are in op");
51     ok(chdir($dh), "fchdir back");
52     ok(-d "op", "verify that we are back");
53 }
54
55 SKIP: {
56     skip("has fchdir", 1) if ($Config{d_fchdir} || "") eq "define";
57     opendir(my $dh, "op");
58     eval { chdir($dh); };
59     like($@, qr/^The fchdir function is unimplemented at/, "fchdir is unimplemented");
60 }
61
62 # The environment variables chdir() pays attention to.
63 my @magic_envs = qw(HOME LOGDIR SYS$LOGIN);
64
65 sub check_env {
66     my($key) = @_;
67
68     # Make sure $ENV{'SYS$LOGIN'} is only honored on VMS.
69     if( $key eq 'SYS$LOGIN' && !$IsVMS && !$IsMacOS ) {
70         ok( !chdir(),         "chdir() on $^O ignores only \$ENV{$key} set" );
71         is( abs_path, $Cwd,   '  abs_path() did not change' );
72         pass( "  no need to test SYS\$LOGIN on $^O" ) for 1..7;
73     }
74     else {
75         ok( chdir(),              "chdir() w/ only \$ENV{$key} set" );
76         is( abs_path, $ENV{$key}, '  abs_path() agrees' );
77         chdir($Cwd);
78         is( abs_path, $Cwd,       '  and back again' );
79
80         my $warning = '';
81         local $SIG{__WARN__} = sub { $warning .= join '', @_ };
82
83
84         # Check the deprecated chdir(undef) feature.
85 #line 64
86         ok( chdir(undef),           "chdir(undef) w/ only \$ENV{$key} set" );
87         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
88         is( $warning,  <<WARNING,   '  got uninit & deprecation warning' );
89 Use of uninitialized value in chdir at $0 line 64.
90 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 64.
91 WARNING
92
93         chdir($Cwd);
94
95         # Ditto chdir('').
96         $warning = '';
97 #line 76
98         ok( chdir(''),              "chdir('') w/ only \$ENV{$key} set" );
99         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
100         is( $warning,  <<WARNING,   '  got deprecation warning' );
101 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 76.
102 WARNING
103
104         chdir($Cwd);
105     }
106 }
107
108 my %Saved_Env = ();
109 sub clean_env {
110     foreach my $env (@magic_envs) {
111         $Saved_Env{$env} = $ENV{$env};
112
113         # Can't actually delete SYS$ stuff on VMS.
114         next if $IsVMS && $env eq 'SYS$LOGIN';
115         next if $IsVMS && $env eq 'HOME' && !$Config{'d_setenv'};
116
117         unless ($IsMacOS) { # ENV on MacOS is "special" :-)
118             # On VMS, %ENV is many layered.
119             delete $ENV{$env} while exists $ENV{$env};
120         }
121     }
122
123     # The following means we won't really be testing for non-existence,
124     # but in Perl we can only delete from the process table, not the job 
125     # table.
126     $ENV{'SYS$LOGIN'} = '' if $IsVMS;
127 }
128
129 END {
130     no warnings 'uninitialized';
131
132     # Restore the environment for VMS (and doesn't hurt for anyone else)
133     @ENV{@magic_envs} = @Saved_Env{@magic_envs};
134 }
135
136
137 foreach my $key (@magic_envs) {
138     # We're going to be using undefs a lot here.
139     no warnings 'uninitialized';
140
141     clean_env;
142     $ENV{$key} = catdir $Cwd, ($IsVMS ? 'OP' : 'op');
143
144     check_env($key);
145 }
146
147 {
148     clean_env;
149     if (($IsVMS || $IsMacOS) && !$Config{'d_setenv'}) {
150         pass("Can't reset HOME, so chdir() test meaningless");
151     } else {
152         ok( !chdir(),                   'chdir() w/o any ENV set' );
153     }
154     is( abs_path, $Cwd,             '  abs_path() agrees' );
155 }