This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: fchmod, fchown, fchdir
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy : if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds have elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 =item bind SOCKET,NAME
450
451 Binds a network address to a socket, just as the bind system call
452 does.  Returns true if it succeeded, false otherwise.  NAME should be a
453 packed address of the appropriate type for the socket.  See the examples in
454 L<perlipc/"Sockets: Client/Server Communication">.
455
456 =item binmode FILEHANDLE, LAYER
457
458 =item binmode FILEHANDLE
459
460 Arranges for FILEHANDLE to be read or written in "binary" or "text"
461 mode on systems where the run-time libraries distinguish between
462 binary and text files.  If FILEHANDLE is an expression, the value is
463 taken as the name of the filehandle.  Returns true on success,
464 otherwise it returns C<undef> and sets C<$!> (errno).
465
466 On some systems (in general, DOS and Windows-based systems) binmode()
467 is necessary when you're not working with a text file.  For the sake
468 of portability it is a good idea to always use it when appropriate,
469 and to never use it when it isn't appropriate.  Also, people can
470 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
471
472 In other words: regardless of platform, use binmode() on binary data,
473 like for example images.
474
475 If LAYER is present it is a single string, but may contain multiple
476 directives. The directives alter the behaviour of the file handle.
477 When LAYER is present using binmode on text file makes sense.
478
479 If LAYER is omitted or specified as C<:raw> the filehandle is made
480 suitable for passing binary data. This includes turning off possible CRLF
481 translation and marking it as bytes (as opposed to Unicode characters).
482 Note that, despite what may be implied in I<"Programming Perl"> (the
483 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
484 -- other layers which would affect binary nature of the stream are
485 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
486 PERLIO environment variable.
487
488 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
489 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
490 establish default I/O layers.  See L<open>.
491
492 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
493 in "Programming Perl, 3rd Edition".  However, since the publishing of this
494 book, by many known as "Camel III", the consensus of the naming of this
495 functionality has moved from "discipline" to "layer".  All documentation
496 of this version of Perl therefore refers to "layers" rather than to
497 "disciplines".  Now back to the regularly scheduled documentation...>
498
499 To mark FILEHANDLE as UTF-8, use C<:utf8>.
500
501 In general, binmode() should be called after open() but before any I/O
502 is done on the filehandle.  Calling binmode() will normally flush any
503 pending buffered output data (and perhaps pending input data) on the
504 handle.  An exception to this is the C<:encoding> layer that
505 changes the default character encoding of the handle, see L<open>.
506 The C<:encoding> layer sometimes needs to be called in
507 mid-stream, and it doesn't flush the stream.  The C<:encoding>
508 also implicitly pushes on top of itself the C<:utf8> layer because
509 internally Perl will operate on UTF-8 encoded Unicode characters.
510
511 The operating system, device drivers, C libraries, and Perl run-time
512 system all work together to let the programmer treat a single
513 character (C<\n>) as the line terminator, irrespective of the external
514 representation.  On many operating systems, the native text file
515 representation matches the internal representation, but on some
516 platforms the external representation of C<\n> is made up of more than
517 one character.
518
519 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
520 character to end each line in the external representation of text (even
521 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
522 on Unix and most VMS files). In other systems like OS/2, DOS and the
523 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
524 but what's stored in text files are the two characters C<\cM\cJ>.  That
525 means that, if you don't use binmode() on these systems, C<\cM\cJ>
526 sequences on disk will be converted to C<\n> on input, and any C<\n> in
527 your program will be converted back to C<\cM\cJ> on output.  This is what
528 you want for text files, but it can be disastrous for binary files.
529
530 Another consequence of using binmode() (on some systems) is that
531 special end-of-file markers will be seen as part of the data stream.
532 For systems from the Microsoft family this means that if your binary
533 data contains C<\cZ>, the I/O subsystem will regard it as the end of
534 the file, unless you use binmode().
535
536 binmode() is not only important for readline() and print() operations,
537 but also when using read(), seek(), sysread(), syswrite() and tell()
538 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
539 in L<perlvar> for how to manually set your input and output
540 line-termination sequences.
541
542 =item bless REF,CLASSNAME
543
544 =item bless REF
545
546 This function tells the thingy referenced by REF that it is now an object
547 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
548 is used.  Because a C<bless> is often the last thing in a constructor,
549 it returns the reference for convenience.  Always use the two-argument
550 version if the function doing the blessing might be inherited by a
551 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
552 (and blessings) of objects.
553
554 Consider always blessing objects in CLASSNAMEs that are mixed case.
555 Namespaces with all lowercase names are considered reserved for
556 Perl pragmata.  Builtin types have all uppercase names, so to prevent
557 confusion, you may wish to avoid such package names as well.  Make sure
558 that CLASSNAME is a true value.
559
560 See L<perlmod/"Perl Modules">.
561
562 =item caller EXPR
563
564 =item caller
565
566 Returns the context of the current subroutine call.  In scalar context,
567 returns the caller's package name if there is a caller, that is, if
568 we're in a subroutine or C<eval> or C<require>, and the undefined value
569 otherwise.  In list context, returns
570
571     ($package, $filename, $line) = caller;
572
573 With EXPR, it returns some extra information that the debugger uses to
574 print a stack trace.  The value of EXPR indicates how many call frames
575 to go back before the current one.
576
577     ($package, $filename, $line, $subroutine, $hasargs,
578     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
579
580 Here $subroutine may be C<(eval)> if the frame is not a subroutine
581 call, but an C<eval>.  In such a case additional elements $evaltext and
582 C<$is_require> are set: C<$is_require> is true if the frame is created by a
583 C<require> or C<use> statement, $evaltext contains the text of the
584 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
585 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
586 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
587 frame.)  $subroutine may also be C<(unknown)> if this particular
588 subroutine happens to have been deleted from the symbol table.
589 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
590 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
591 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
592 between versions of Perl, and are not meant for external use.
593
594 Furthermore, when called from within the DB package, caller returns more
595 detailed information: it sets the list variable C<@DB::args> to be the
596 arguments with which the subroutine was invoked.
597
598 Be aware that the optimizer might have optimized call frames away before
599 C<caller> had a chance to get the information.  That means that C<caller(N)>
600 might not return information about the call frame you expect it do, for
601 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
602 previous time C<caller> was called.
603
604 =item chdir EXPR
605
606 =item chdir FILEHANDLE
607
608 =item chdir DIRHANDLE
609
610 =item chdir
611
612 Changes the working directory to EXPR, if possible. If EXPR is omitted,
613 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
614 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
615 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
616 neither is set, C<chdir> does nothing. It returns true upon success,
617 false otherwise. See the example under C<die>.
618
619 On systems that support fchdir, you might pass a file handle or
620 directory handle as argument.  On systems that don't support fchdir,
621 passing handles produces a fatal error at run time.
622
623 =item chmod LIST
624
625 Changes the permissions of a list of files.  The first element of the
626 list must be the numerical mode, which should probably be an octal
627 number, and which definitely should I<not> be a string of octal digits:
628 C<0644> is okay, C<'0644'> is not.  Returns the number of files
629 successfully changed.  See also L</oct>, if all you have is a string.
630
631     $cnt = chmod 0755, 'foo', 'bar';
632     chmod 0755, @executables;
633     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
634                                              # --w----r-T
635     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
636     $mode = 0644;   chmod $mode, 'foo';      # this is best
637
638 On systems that support fchmod, you might pass file handles among the
639 files.  On systems that don't support fchmod, passing file handles
640 produces a fatal error at run time.
641
642     open(my $fh, "<", "foo");
643     my $perm = (stat $fh)[2] & 07777;
644     chmod($perm | 0600, $fh);
645
646 You can also import the symbolic C<S_I*> constants from the Fcntl
647 module:
648
649     use Fcntl ':mode';
650
651     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
652     # This is identical to the chmod 0755 of the above example.
653
654 =item chomp VARIABLE
655
656 =item chomp( LIST )
657
658 =item chomp
659
660 This safer version of L</chop> removes any trailing string
661 that corresponds to the current value of C<$/> (also known as
662 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
663 number of characters removed from all its arguments.  It's often used to
664 remove the newline from the end of an input record when you're worried
665 that the final record may be missing its newline.  When in paragraph
666 mode (C<$/ = "">), it removes all trailing newlines from the string.
667 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
668 a reference to an integer or the like, see L<perlvar>) chomp() won't
669 remove anything.
670 If VARIABLE is omitted, it chomps C<$_>.  Example:
671
672     while (<>) {
673         chomp;  # avoid \n on last field
674         @array = split(/:/);
675         # ...
676     }
677
678 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
679
680 You can actually chomp anything that's an lvalue, including an assignment:
681
682     chomp($cwd = `pwd`);
683     chomp($answer = <STDIN>);
684
685 If you chomp a list, each element is chomped, and the total number of
686 characters removed is returned.
687
688 If the C<encoding> pragma is in scope then the lengths returned are
689 calculated from the length of C<$/> in Unicode characters, which is not
690 always the same as the length of C<$/> in the native encoding.
691
692 Note that parentheses are necessary when you're chomping anything
693 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
694 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
695 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
696 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
697 as C<chomp($a, $b)>.
698
699 =item chop VARIABLE
700
701 =item chop( LIST )
702
703 =item chop
704
705 Chops off the last character of a string and returns the character
706 chopped.  It is much more efficient than C<s/.$//s> because it neither
707 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
708 If VARIABLE is a hash, it chops the hash's values, but not its keys.
709
710 You can actually chop anything that's an lvalue, including an assignment.
711
712 If you chop a list, each element is chopped.  Only the value of the
713 last C<chop> is returned.
714
715 Note that C<chop> returns the last character.  To return all but the last
716 character, use C<substr($string, 0, -1)>.
717
718 See also L</chomp>.
719
720 =item chown LIST
721
722 Changes the owner (and group) of a list of files.  The first two
723 elements of the list must be the I<numeric> uid and gid, in that
724 order.  A value of -1 in either position is interpreted by most
725 systems to leave that value unchanged.  Returns the number of files
726 successfully changed.
727
728     $cnt = chown $uid, $gid, 'foo', 'bar';
729     chown $uid, $gid, @filenames;
730
731 On systems that support fchown, you might pass file handles among the
732 files.  On systems that don't support fchown, passing file handles
733 produces a fatal error at run time.
734
735 Here's an example that looks up nonnumeric uids in the passwd file:
736
737     print "User: ";
738     chomp($user = <STDIN>);
739     print "Files: ";
740     chomp($pattern = <STDIN>);
741
742     ($login,$pass,$uid,$gid) = getpwnam($user)
743         or die "$user not in passwd file";
744
745     @ary = glob($pattern);      # expand filenames
746     chown $uid, $gid, @ary;
747
748 On most systems, you are not allowed to change the ownership of the
749 file unless you're the superuser, although you should be able to change
750 the group to any of your secondary groups.  On insecure systems, these
751 restrictions may be relaxed, but this is not a portable assumption.
752 On POSIX systems, you can detect this condition this way:
753
754     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
755     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
756
757 =item chr NUMBER
758
759 =item chr
760
761 Returns the character represented by that NUMBER in the character set.
762 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
763 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
764 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
765 backward compatibility reasons (but see L<encoding>).
766
767 Negative values give the Unicode replacement character (chr(0xfffd)),
768 except under the L</bytes> pragma, where low eight bits of the value
769 (truncated to an integer) are used.
770
771 If NUMBER is omitted, uses C<$_>.
772
773 For the reverse, use L</ord>.
774
775 Note that under the C<bytes> pragma the NUMBER is masked to
776 the low eight bits.
777
778 See L<perlunicode> and L<encoding> for more about Unicode.
779
780 =item chroot FILENAME
781
782 =item chroot
783
784 This function works like the system call by the same name: it makes the
785 named directory the new root directory for all further pathnames that
786 begin with a C</> by your process and all its children.  (It doesn't
787 change your current working directory, which is unaffected.)  For security
788 reasons, this call is restricted to the superuser.  If FILENAME is
789 omitted, does a C<chroot> to C<$_>.
790
791 =item close FILEHANDLE
792
793 =item close
794
795 Closes the file or pipe associated with the file handle, returning
796 true only if IO buffers are successfully flushed and closes the system
797 file descriptor.  Closes the currently selected filehandle if the
798 argument is omitted.
799
800 You don't have to close FILEHANDLE if you are immediately going to do
801 another C<open> on it, because C<open> will close it for you.  (See
802 C<open>.)  However, an explicit C<close> on an input file resets the line
803 counter (C<$.>), while the implicit close done by C<open> does not.
804
805 If the file handle came from a piped open, C<close> will additionally
806 return false if one of the other system calls involved fails, or if the
807 program exits with non-zero status.  (If the only problem was that the
808 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
809 also waits for the process executing on the pipe to complete, in case you
810 want to look at the output of the pipe afterwards, and
811 implicitly puts the exit status value of that command into C<$?> and
812 C<${^CHILD_ERROR_NATIVE}>.
813
814 Prematurely closing the read end of a pipe (i.e. before the process
815 writing to it at the other end has closed it) will result in a
816 SIGPIPE being delivered to the writer.  If the other end can't
817 handle that, be sure to read all the data before closing the pipe.
818
819 Example:
820
821     open(OUTPUT, '|sort >foo')  # pipe to sort
822         or die "Can't start sort: $!";
823     #...                        # print stuff to output
824     close OUTPUT                # wait for sort to finish
825         or warn $! ? "Error closing sort pipe: $!"
826                    : "Exit status $? from sort";
827     open(INPUT, 'foo')          # get sort's results
828         or die "Can't open 'foo' for input: $!";
829
830 FILEHANDLE may be an expression whose value can be used as an indirect
831 filehandle, usually the real filehandle name.
832
833 =item closedir DIRHANDLE
834
835 Closes a directory opened by C<opendir> and returns the success of that
836 system call.
837
838 =item connect SOCKET,NAME
839
840 Attempts to connect to a remote socket, just as the connect system call
841 does.  Returns true if it succeeded, false otherwise.  NAME should be a
842 packed address of the appropriate type for the socket.  See the examples in
843 L<perlipc/"Sockets: Client/Server Communication">.
844
845 =item continue BLOCK
846
847 Actually a flow control statement rather than a function.  If there is a
848 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
849 C<foreach>), it is always executed just before the conditional is about to
850 be evaluated again, just like the third part of a C<for> loop in C.  Thus
851 it can be used to increment a loop variable, even when the loop has been
852 continued via the C<next> statement (which is similar to the C C<continue>
853 statement).
854
855 C<last>, C<next>, or C<redo> may appear within a C<continue>
856 block.  C<last> and C<redo> will behave as if they had been executed within
857 the main block.  So will C<next>, but since it will execute a C<continue>
858 block, it may be more entertaining.
859
860     while (EXPR) {
861         ### redo always comes here
862         do_something;
863     } continue {
864         ### next always comes here
865         do_something_else;
866         # then back the top to re-check EXPR
867     }
868     ### last always comes here
869
870 Omitting the C<continue> section is semantically equivalent to using an
871 empty one, logically enough.  In that case, C<next> goes directly back
872 to check the condition at the top of the loop.
873
874 =item cos EXPR
875
876 =item cos
877
878 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
879 takes cosine of C<$_>.
880
881 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
882 function, or use this relation:
883
884     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
885
886 =item crypt PLAINTEXT,SALT
887
888 Encrypts a string exactly like the crypt(3) function in the C library
889 (assuming that you actually have a version there that has not been
890 extirpated as a potential munition).  This can prove useful for checking
891 the password file for lousy passwords, amongst other things.  Only the
892 guys wearing white hats should do this.
893
894 Note that L<crypt|/crypt> is intended to be a one-way function, much like
895 breaking eggs to make an omelette.  There is no (known) corresponding
896 decrypt function (in other words, the crypt() is a one-way hash
897 function).  As a result, this function isn't all that useful for
898 cryptography.  (For that, see your nearby CPAN mirror.)
899
900 When verifying an existing encrypted string you should use the
901 encrypted text as the salt (like C<crypt($plain, $crypted) eq
902 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
903 and with more exotic implementations.  In other words, do not assume
904 anything about the returned string itself, or how many bytes in
905 the encrypted string matter.
906
907 Traditionally the result is a string of 13 bytes: two first bytes of
908 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
909 the first eight bytes of the encrypted string mattered, but
910 alternative hashing schemes (like MD5), higher level security schemes
911 (like C2), and implementations on non-UNIX platforms may produce
912 different strings.
913
914 When choosing a new salt create a random two character string whose
915 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
916 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
917 characters is just a recommendation; the characters allowed in
918 the salt depend solely on your system's crypt library, and Perl can't
919 restrict what salts C<crypt()> accepts.
920
921 Here's an example that makes sure that whoever runs this program knows
922 their own password:
923
924     $pwd = (getpwuid($<))[1];
925
926     system "stty -echo";
927     print "Password: ";
928     chomp($word = <STDIN>);
929     print "\n";
930     system "stty echo";
931
932     if (crypt($word, $pwd) ne $pwd) {
933         die "Sorry...\n";
934     } else {
935         print "ok\n";
936     }
937
938 Of course, typing in your own password to whoever asks you
939 for it is unwise.
940
941 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
942 of data, not least of all because you can't get the information
943 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
944 on your favorite CPAN mirror for a slew of potentially useful
945 modules.
946
947 If using crypt() on a Unicode string (which I<potentially> has
948 characters with codepoints above 255), Perl tries to make sense
949 of the situation by trying to downgrade (a copy of the string)
950 the string back to an eight-bit byte string before calling crypt()
951 (on that copy).  If that works, good.  If not, crypt() dies with
952 C<Wide character in crypt>.
953
954 =item dbmclose HASH
955
956 [This function has been largely superseded by the C<untie> function.]
957
958 Breaks the binding between a DBM file and a hash.
959
960 =item dbmopen HASH,DBNAME,MASK
961
962 [This function has been largely superseded by the C<tie> function.]
963
964 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
965 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
966 argument is I<not> a filehandle, even though it looks like one).  DBNAME
967 is the name of the database (without the F<.dir> or F<.pag> extension if
968 any).  If the database does not exist, it is created with protection
969 specified by MASK (as modified by the C<umask>).  If your system supports
970 only the older DBM functions, you may perform only one C<dbmopen> in your
971 program.  In older versions of Perl, if your system had neither DBM nor
972 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
973 sdbm(3).
974
975 If you don't have write access to the DBM file, you can only read hash
976 variables, not set them.  If you want to test whether you can write,
977 either use file tests or try setting a dummy hash entry inside an C<eval>,
978 which will trap the error.
979
980 Note that functions such as C<keys> and C<values> may return huge lists
981 when used on large DBM files.  You may prefer to use the C<each>
982 function to iterate over large DBM files.  Example:
983
984     # print out history file offsets
985     dbmopen(%HIST,'/usr/lib/news/history',0666);
986     while (($key,$val) = each %HIST) {
987         print $key, ' = ', unpack('L',$val), "\n";
988     }
989     dbmclose(%HIST);
990
991 See also L<AnyDBM_File> for a more general description of the pros and
992 cons of the various dbm approaches, as well as L<DB_File> for a particularly
993 rich implementation.
994
995 You can control which DBM library you use by loading that library
996 before you call dbmopen():
997
998     use DB_File;
999     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1000         or die "Can't open netscape history file: $!";
1001
1002 =item defined EXPR
1003
1004 =item defined
1005
1006 Returns a Boolean value telling whether EXPR has a value other than
1007 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1008 checked.
1009
1010 Many operations return C<undef> to indicate failure, end of file,
1011 system error, uninitialized variable, and other exceptional
1012 conditions.  This function allows you to distinguish C<undef> from
1013 other values.  (A simple Boolean test will not distinguish among
1014 C<undef>, zero, the empty string, and C<"0">, which are all equally
1015 false.)  Note that since C<undef> is a valid scalar, its presence
1016 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1017 returns C<undef> when its argument is an empty array, I<or> when the
1018 element to return happens to be C<undef>.
1019
1020 You may also use C<defined(&func)> to check whether subroutine C<&func>
1021 has ever been defined.  The return value is unaffected by any forward
1022 declarations of C<&func>.  Note that a subroutine which is not defined
1023 may still be callable: its package may have an C<AUTOLOAD> method that
1024 makes it spring into existence the first time that it is called -- see
1025 L<perlsub>.
1026
1027 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1028 used to report whether memory for that aggregate has ever been
1029 allocated.  This behavior may disappear in future versions of Perl.
1030 You should instead use a simple test for size:
1031
1032     if (@an_array) { print "has array elements\n" }
1033     if (%a_hash)   { print "has hash members\n"   }
1034
1035 When used on a hash element, it tells you whether the value is defined,
1036 not whether the key exists in the hash.  Use L</exists> for the latter
1037 purpose.
1038
1039 Examples:
1040
1041     print if defined $switch{'D'};
1042     print "$val\n" while defined($val = pop(@ary));
1043     die "Can't readlink $sym: $!"
1044         unless defined($value = readlink $sym);
1045     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1046     $debugging = 0 unless defined $debugging;
1047
1048 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1049 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1050 defined values.  For example, if you say
1051
1052     "ab" =~ /a(.*)b/;
1053
1054 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1055 matched "nothing".  But it didn't really match nothing--rather, it
1056 matched something that happened to be zero characters long.  This is all
1057 very above-board and honest.  When a function returns an undefined value,
1058 it's an admission that it couldn't give you an honest answer.  So you
1059 should use C<defined> only when you're questioning the integrity of what
1060 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1061 what you want.
1062
1063 See also L</undef>, L</exists>, L</ref>.
1064
1065 =item delete EXPR
1066
1067 Given an expression that specifies a hash element, array element, hash slice,
1068 or array slice, deletes the specified element(s) from the hash or array.
1069 In the case of an array, if the array elements happen to be at the end,
1070 the size of the array will shrink to the highest element that tests
1071 true for exists() (or 0 if no such element exists).
1072
1073 Returns a list with the same number of elements as the number of elements
1074 for which deletion was attempted.  Each element of that list consists of
1075 either the value of the element deleted, or the undefined value.  In scalar
1076 context, this means that you get the value of the last element deleted (or
1077 the undefined value if that element did not exist).
1078
1079     %hash = (foo => 11, bar => 22, baz => 33);
1080     $scalar = delete $hash{foo};             # $scalar is 11
1081     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1082     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1083
1084 Deleting from C<%ENV> modifies the environment.  Deleting from
1085 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1086 from a C<tie>d hash or array may not necessarily return anything.
1087
1088 Deleting an array element effectively returns that position of the array
1089 to its initial, uninitialized state.  Subsequently testing for the same
1090 element with exists() will return false.  Note that deleting array
1091 elements in the middle of an array will not shift the index of the ones
1092 after them down--use splice() for that.  See L</exists>.
1093
1094 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1095
1096     foreach $key (keys %HASH) {
1097         delete $HASH{$key};
1098     }
1099
1100     foreach $index (0 .. $#ARRAY) {
1101         delete $ARRAY[$index];
1102     }
1103
1104 And so do these:
1105
1106     delete @HASH{keys %HASH};
1107
1108     delete @ARRAY[0 .. $#ARRAY];
1109
1110 But both of these are slower than just assigning the empty list
1111 or undefining %HASH or @ARRAY:
1112
1113     %HASH = ();         # completely empty %HASH
1114     undef %HASH;        # forget %HASH ever existed
1115
1116     @ARRAY = ();        # completely empty @ARRAY
1117     undef @ARRAY;       # forget @ARRAY ever existed
1118
1119 Note that the EXPR can be arbitrarily complicated as long as the final
1120 operation is a hash element, array element,  hash slice, or array slice
1121 lookup:
1122
1123     delete $ref->[$x][$y]{$key};
1124     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1125
1126     delete $ref->[$x][$y][$index];
1127     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1128
1129 =item die LIST
1130
1131 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1132 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1133 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1134 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1135 an C<eval(),> the error message is stuffed into C<$@> and the
1136 C<eval> is terminated with the undefined value.  This makes
1137 C<die> the way to raise an exception.
1138
1139 Equivalent examples:
1140
1141     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1142     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1143
1144 If the last element of LIST does not end in a newline, the current
1145 script line number and input line number (if any) are also printed,
1146 and a newline is supplied.  Note that the "input line number" (also
1147 known as "chunk") is subject to whatever notion of "line" happens to
1148 be currently in effect, and is also available as the special variable
1149 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1150
1151 Hint: sometimes appending C<", stopped"> to your message will cause it
1152 to make better sense when the string C<"at foo line 123"> is appended.
1153 Suppose you are running script "canasta".
1154
1155     die "/etc/games is no good";
1156     die "/etc/games is no good, stopped";
1157
1158 produce, respectively
1159
1160     /etc/games is no good at canasta line 123.
1161     /etc/games is no good, stopped at canasta line 123.
1162
1163 See also exit(), warn(), and the Carp module.
1164
1165 If LIST is empty and C<$@> already contains a value (typically from a
1166 previous eval) that value is reused after appending C<"\t...propagated">.
1167 This is useful for propagating exceptions:
1168
1169     eval { ... };
1170     die unless $@ =~ /Expected exception/;
1171
1172 If LIST is empty and C<$@> contains an object reference that has a
1173 C<PROPAGATE> method, that method will be called with additional file
1174 and line number parameters.  The return value replaces the value in
1175 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1176 were called.
1177
1178 If C<$@> is empty then the string C<"Died"> is used.
1179
1180 die() can also be called with a reference argument.  If this happens to be
1181 trapped within an eval(), $@ contains the reference.  This behavior permits
1182 a more elaborate exception handling implementation using objects that
1183 maintain arbitrary state about the nature of the exception.  Such a scheme
1184 is sometimes preferable to matching particular string values of $@ using
1185 regular expressions.  Here's an example:
1186
1187     use Scalar::Util 'blessed';
1188
1189     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1190     if ($@) {
1191         if (blessed($@) && $@->isa("Some::Module::Exception")) {
1192             # handle Some::Module::Exception
1193         }
1194         else {
1195             # handle all other possible exceptions
1196         }
1197     }
1198
1199 Because perl will stringify uncaught exception messages before displaying
1200 them, you may want to overload stringification operations on such custom
1201 exception objects.  See L<overload> for details about that.
1202
1203 You can arrange for a callback to be run just before the C<die>
1204 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1205 handler will be called with the error text and can change the error
1206 message, if it sees fit, by calling C<die> again.  See
1207 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1208 L<"eval BLOCK"> for some examples.  Although this feature was meant
1209 to be run only right before your program was to exit, this is not
1210 currently the case--the C<$SIG{__DIE__}> hook is currently called
1211 even inside eval()ed blocks/strings!  If one wants the hook to do
1212 nothing in such situations, put
1213
1214         die @_ if $^S;
1215
1216 as the first line of the handler (see L<perlvar/$^S>).  Because
1217 this promotes strange action at a distance, this counterintuitive
1218 behavior may be fixed in a future release.
1219
1220 =item do BLOCK
1221
1222 Not really a function.  Returns the value of the last command in the
1223 sequence of commands indicated by BLOCK.  When modified by a loop
1224 modifier, executes the BLOCK once before testing the loop condition.
1225 (On other statements the loop modifiers test the conditional first.)
1226
1227 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1228 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1229 See L<perlsyn> for alternative strategies.
1230
1231 =item do SUBROUTINE(LIST)
1232
1233 A deprecated form of subroutine call.  See L<perlsub>.
1234
1235 =item do EXPR
1236
1237 Uses the value of EXPR as a filename and executes the contents of the
1238 file as a Perl script.
1239
1240     do 'stat.pl';
1241
1242 is just like
1243
1244     eval `cat stat.pl`;
1245
1246 except that it's more efficient and concise, keeps track of the current
1247 filename for error messages, searches the @INC directories, and updates
1248 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1249 variables.  It also differs in that code evaluated with C<do FILENAME>
1250 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1251 same, however, in that it does reparse the file every time you call it,
1252 so you probably don't want to do this inside a loop.
1253
1254 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1255 error.  If C<do> can read the file but cannot compile it, it
1256 returns undef and sets an error message in C<$@>.   If the file is
1257 successfully compiled, C<do> returns the value of the last expression
1258 evaluated.
1259
1260 Note that inclusion of library modules is better done with the
1261 C<use> and C<require> operators, which also do automatic error checking
1262 and raise an exception if there's a problem.
1263
1264 You might like to use C<do> to read in a program configuration
1265 file.  Manual error checking can be done this way:
1266
1267     # read in config files: system first, then user
1268     for $file ("/share/prog/defaults.rc",
1269                "$ENV{HOME}/.someprogrc")
1270    {
1271         unless ($return = do $file) {
1272             warn "couldn't parse $file: $@" if $@;
1273             warn "couldn't do $file: $!"    unless defined $return;
1274             warn "couldn't run $file"       unless $return;
1275         }
1276     }
1277
1278 =item dump LABEL
1279
1280 =item dump
1281
1282 This function causes an immediate core dump.  See also the B<-u>
1283 command-line switch in L<perlrun>, which does the same thing.
1284 Primarily this is so that you can use the B<undump> program (not
1285 supplied) to turn your core dump into an executable binary after
1286 having initialized all your variables at the beginning of the
1287 program.  When the new binary is executed it will begin by executing
1288 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1289 Think of it as a goto with an intervening core dump and reincarnation.
1290 If C<LABEL> is omitted, restarts the program from the top.
1291
1292 B<WARNING>: Any files opened at the time of the dump will I<not>
1293 be open any more when the program is reincarnated, with possible
1294 resulting confusion on the part of Perl.
1295
1296 This function is now largely obsolete, partly because it's very
1297 hard to convert a core file into an executable, and because the
1298 real compiler backends for generating portable bytecode and compilable
1299 C code have superseded it.  That's why you should now invoke it as
1300 C<CORE::dump()>, if you don't want to be warned against a possible
1301 typo.
1302
1303 If you're looking to use L<dump> to speed up your program, consider
1304 generating bytecode or native C code as described in L<perlcc>.  If
1305 you're just trying to accelerate a CGI script, consider using the
1306 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1307 You might also consider autoloading or selfloading, which at least
1308 make your program I<appear> to run faster.
1309
1310 =item each HASH
1311
1312 When called in list context, returns a 2-element list consisting of the
1313 key and value for the next element of a hash, so that you can iterate over
1314 it.  When called in scalar context, returns only the key for the next
1315 element in the hash.
1316
1317 Entries are returned in an apparently random order.  The actual random
1318 order is subject to change in future versions of perl, but it is
1319 guaranteed to be in the same order as either the C<keys> or C<values>
1320 function would produce on the same (unmodified) hash.  Since Perl
1321 5.8.1 the ordering is different even between different runs of Perl
1322 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1323
1324 When the hash is entirely read, a null array is returned in list context
1325 (which when assigned produces a false (C<0>) value), and C<undef> in
1326 scalar context.  The next call to C<each> after that will start iterating
1327 again.  There is a single iterator for each hash, shared by all C<each>,
1328 C<keys>, and C<values> function calls in the program; it can be reset by
1329 reading all the elements from the hash, or by evaluating C<keys HASH> or
1330 C<values HASH>.  If you add or delete elements of a hash while you're
1331 iterating over it, you may get entries skipped or duplicated, so
1332 don't.  Exception: It is always safe to delete the item most recently
1333 returned by C<each()>, which means that the following code will work:
1334
1335         while (($key, $value) = each %hash) {
1336           print $key, "\n";
1337           delete $hash{$key};   # This is safe
1338         }
1339
1340 The following prints out your environment like the printenv(1) program,
1341 only in a different order:
1342
1343     while (($key,$value) = each %ENV) {
1344         print "$key=$value\n";
1345     }
1346
1347 See also C<keys>, C<values> and C<sort>.
1348
1349 =item eof FILEHANDLE
1350
1351 =item eof ()
1352
1353 =item eof
1354
1355 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1356 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1357 gives the real filehandle.  (Note that this function actually
1358 reads a character and then C<ungetc>s it, so isn't very useful in an
1359 interactive context.)  Do not read from a terminal file (or call
1360 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1361 as terminals may lose the end-of-file condition if you do.
1362
1363 An C<eof> without an argument uses the last file read.  Using C<eof()>
1364 with empty parentheses is very different.  It refers to the pseudo file
1365 formed from the files listed on the command line and accessed via the
1366 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1367 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1368 used will cause C<@ARGV> to be examined to determine if input is
1369 available.   Similarly, an C<eof()> after C<< <> >> has returned
1370 end-of-file will assume you are processing another C<@ARGV> list,
1371 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1372 see L<perlop/"I/O Operators">.
1373
1374 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1375 detect the end of each file, C<eof()> will only detect the end of the
1376 last file.  Examples:
1377
1378     # reset line numbering on each input file
1379     while (<>) {
1380         next if /^\s*#/;        # skip comments
1381         print "$.\t$_";
1382     } continue {
1383         close ARGV  if eof;     # Not eof()!
1384     }
1385
1386     # insert dashes just before last line of last file
1387     while (<>) {
1388         if (eof()) {            # check for end of last file
1389             print "--------------\n";
1390         }
1391         print;
1392         last if eof();          # needed if we're reading from a terminal
1393     }
1394
1395 Practical hint: you almost never need to use C<eof> in Perl, because the
1396 input operators typically return C<undef> when they run out of data, or if
1397 there was an error.
1398
1399 =item eval EXPR
1400
1401 =item eval BLOCK
1402
1403 =item eval
1404
1405 In the first form, the return value of EXPR is parsed and executed as if it
1406 were a little Perl program.  The value of the expression (which is itself
1407 determined within scalar context) is first parsed, and if there weren't any
1408 errors, executed in the lexical context of the current Perl program, so
1409 that any variable settings or subroutine and format definitions remain
1410 afterwards.  Note that the value is parsed every time the eval executes.
1411 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1412 delay parsing and subsequent execution of the text of EXPR until run time.
1413
1414 In the second form, the code within the BLOCK is parsed only once--at the
1415 same time the code surrounding the eval itself was parsed--and executed
1416 within the context of the current Perl program.  This form is typically
1417 used to trap exceptions more efficiently than the first (see below), while
1418 also providing the benefit of checking the code within BLOCK at compile
1419 time.
1420
1421 The final semicolon, if any, may be omitted from the value of EXPR or within
1422 the BLOCK.
1423
1424 In both forms, the value returned is the value of the last expression
1425 evaluated inside the mini-program; a return statement may be also used, just
1426 as with subroutines.  The expression providing the return value is evaluated
1427 in void, scalar, or list context, depending on the context of the eval itself.
1428 See L</wantarray> for more on how the evaluation context can be determined.
1429
1430 If there is a syntax error or runtime error, or a C<die> statement is
1431 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1432 error message.  If there was no error, C<$@> is guaranteed to be a null
1433 string.  Beware that using C<eval> neither silences perl from printing
1434 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1435 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1436 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1437 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1438
1439 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1440 determining whether a particular feature (such as C<socket> or C<symlink>)
1441 is implemented.  It is also Perl's exception trapping mechanism, where
1442 the die operator is used to raise exceptions.
1443
1444 If the code to be executed doesn't vary, you may use the eval-BLOCK
1445 form to trap run-time errors without incurring the penalty of
1446 recompiling each time.  The error, if any, is still returned in C<$@>.
1447 Examples:
1448
1449     # make divide-by-zero nonfatal
1450     eval { $answer = $a / $b; }; warn $@ if $@;
1451
1452     # same thing, but less efficient
1453     eval '$answer = $a / $b'; warn $@ if $@;
1454
1455     # a compile-time error
1456     eval { $answer = };                 # WRONG
1457
1458     # a run-time error
1459     eval '$answer =';   # sets $@
1460
1461 Due to the current arguably broken state of C<__DIE__> hooks, when using
1462 the C<eval{}> form as an exception trap in libraries, you may wish not
1463 to trigger any C<__DIE__> hooks that user code may have installed.
1464 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1465 as shown in this example:
1466
1467     # a very private exception trap for divide-by-zero
1468     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1469     warn $@ if $@;
1470
1471 This is especially significant, given that C<__DIE__> hooks can call
1472 C<die> again, which has the effect of changing their error messages:
1473
1474     # __DIE__ hooks may modify error messages
1475     {
1476        local $SIG{'__DIE__'} =
1477               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1478        eval { die "foo lives here" };
1479        print $@ if $@;                # prints "bar lives here"
1480     }
1481
1482 Because this promotes action at a distance, this counterintuitive behavior
1483 may be fixed in a future release.
1484
1485 With an C<eval>, you should be especially careful to remember what's
1486 being looked at when:
1487
1488     eval $x;            # CASE 1
1489     eval "$x";          # CASE 2
1490
1491     eval '$x';          # CASE 3
1492     eval { $x };        # CASE 4
1493
1494     eval "\$$x++";      # CASE 5
1495     $$x++;              # CASE 6
1496
1497 Cases 1 and 2 above behave identically: they run the code contained in
1498 the variable $x.  (Although case 2 has misleading double quotes making
1499 the reader wonder what else might be happening (nothing is).)  Cases 3
1500 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1501 does nothing but return the value of $x.  (Case 4 is preferred for
1502 purely visual reasons, but it also has the advantage of compiling at
1503 compile-time instead of at run-time.)  Case 5 is a place where
1504 normally you I<would> like to use double quotes, except that in this
1505 particular situation, you can just use symbolic references instead, as
1506 in case 6.
1507
1508 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1509 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1510
1511 Note that as a very special case, an C<eval ''> executed within the C<DB>
1512 package doesn't see the usual surrounding lexical scope, but rather the
1513 scope of the first non-DB piece of code that called it. You don't normally
1514 need to worry about this unless you are writing a Perl debugger.
1515
1516 =item exec LIST
1517
1518 =item exec PROGRAM LIST
1519
1520 The C<exec> function executes a system command I<and never returns>--
1521 use C<system> instead of C<exec> if you want it to return.  It fails and
1522 returns false only if the command does not exist I<and> it is executed
1523 directly instead of via your system's command shell (see below).
1524
1525 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1526 warns you if there is a following statement which isn't C<die>, C<warn>,
1527 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1528 I<really> want to follow an C<exec> with some other statement, you
1529 can use one of these styles to avoid the warning:
1530
1531     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1532     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1533
1534 If there is more than one argument in LIST, or if LIST is an array
1535 with more than one value, calls execvp(3) with the arguments in LIST.
1536 If there is only one scalar argument or an array with one element in it,
1537 the argument is checked for shell metacharacters, and if there are any,
1538 the entire argument is passed to the system's command shell for parsing
1539 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1540 If there are no shell metacharacters in the argument, it is split into
1541 words and passed directly to C<execvp>, which is more efficient.
1542 Examples:
1543
1544     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1545     exec "sort $outfile | uniq";
1546
1547 If you don't really want to execute the first argument, but want to lie
1548 to the program you are executing about its own name, you can specify
1549 the program you actually want to run as an "indirect object" (without a
1550 comma) in front of the LIST.  (This always forces interpretation of the
1551 LIST as a multivalued list, even if there is only a single scalar in
1552 the list.)  Example:
1553
1554     $shell = '/bin/csh';
1555     exec $shell '-sh';          # pretend it's a login shell
1556
1557 or, more directly,
1558
1559     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1560
1561 When the arguments get executed via the system shell, results will
1562 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1563 for details.
1564
1565 Using an indirect object with C<exec> or C<system> is also more
1566 secure.  This usage (which also works fine with system()) forces
1567 interpretation of the arguments as a multivalued list, even if the
1568 list had just one argument.  That way you're safe from the shell
1569 expanding wildcards or splitting up words with whitespace in them.
1570
1571     @args = ( "echo surprise" );
1572
1573     exec @args;               # subject to shell escapes
1574                                 # if @args == 1
1575     exec { $args[0] } @args;  # safe even with one-arg list
1576
1577 The first version, the one without the indirect object, ran the I<echo>
1578 program, passing it C<"surprise"> an argument.  The second version
1579 didn't--it tried to run a program literally called I<"echo surprise">,
1580 didn't find it, and set C<$?> to a non-zero value indicating failure.
1581
1582 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1583 output before the exec, but this may not be supported on some platforms
1584 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1585 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1586 open handles in order to avoid lost output.
1587
1588 Note that C<exec> will not call your C<END> blocks, nor will it call
1589 any C<DESTROY> methods in your objects.
1590
1591 =item exists EXPR
1592
1593 Given an expression that specifies a hash element or array element,
1594 returns true if the specified element in the hash or array has ever
1595 been initialized, even if the corresponding value is undefined.  The
1596 element is not autovivified if it doesn't exist.
1597
1598     print "Exists\n"    if exists $hash{$key};
1599     print "Defined\n"   if defined $hash{$key};
1600     print "True\n"      if $hash{$key};
1601
1602     print "Exists\n"    if exists $array[$index];
1603     print "Defined\n"   if defined $array[$index];
1604     print "True\n"      if $array[$index];
1605
1606 A hash or array element can be true only if it's defined, and defined if
1607 it exists, but the reverse doesn't necessarily hold true.
1608
1609 Given an expression that specifies the name of a subroutine,
1610 returns true if the specified subroutine has ever been declared, even
1611 if it is undefined.  Mentioning a subroutine name for exists or defined
1612 does not count as declaring it.  Note that a subroutine which does not
1613 exist may still be callable: its package may have an C<AUTOLOAD>
1614 method that makes it spring into existence the first time that it is
1615 called -- see L<perlsub>.
1616
1617     print "Exists\n"    if exists &subroutine;
1618     print "Defined\n"   if defined &subroutine;
1619
1620 Note that the EXPR can be arbitrarily complicated as long as the final
1621 operation is a hash or array key lookup or subroutine name:
1622
1623     if (exists $ref->{A}->{B}->{$key})  { }
1624     if (exists $hash{A}{B}{$key})       { }
1625
1626     if (exists $ref->{A}->{B}->[$ix])   { }
1627     if (exists $hash{A}{B}[$ix])        { }
1628
1629     if (exists &{$ref->{A}{B}{$key}})   { }
1630
1631 Although the deepest nested array or hash will not spring into existence
1632 just because its existence was tested, any intervening ones will.
1633 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1634 into existence due to the existence test for the $key element above.
1635 This happens anywhere the arrow operator is used, including even:
1636
1637     undef $ref;
1638     if (exists $ref->{"Some key"})      { }
1639     print $ref;             # prints HASH(0x80d3d5c)
1640
1641 This surprising autovivification in what does not at first--or even
1642 second--glance appear to be an lvalue context may be fixed in a future
1643 release.
1644
1645 Use of a subroutine call, rather than a subroutine name, as an argument
1646 to exists() is an error.
1647
1648     exists &sub;        # OK
1649     exists &sub();      # Error
1650
1651 =item exit EXPR
1652
1653 =item exit
1654
1655 Evaluates EXPR and exits immediately with that value.    Example:
1656
1657     $ans = <STDIN>;
1658     exit 0 if $ans =~ /^[Xx]/;
1659
1660 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1661 universally recognized values for EXPR are C<0> for success and C<1>
1662 for error; other values are subject to interpretation depending on the
1663 environment in which the Perl program is running.  For example, exiting
1664 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1665 the mailer to return the item undelivered, but that's not true everywhere.
1666
1667 Don't use C<exit> to abort a subroutine if there's any chance that
1668 someone might want to trap whatever error happened.  Use C<die> instead,
1669 which can be trapped by an C<eval>.
1670
1671 The exit() function does not always exit immediately.  It calls any
1672 defined C<END> routines first, but these C<END> routines may not
1673 themselves abort the exit.  Likewise any object destructors that need to
1674 be called are called before the real exit.  If this is a problem, you
1675 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1676 See L<perlmod> for details.
1677
1678 =item exp EXPR
1679
1680 =item exp
1681
1682 Returns I<e> (the natural logarithm base) to the power of EXPR.
1683 If EXPR is omitted, gives C<exp($_)>.
1684
1685 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1686
1687 Implements the fcntl(2) function.  You'll probably have to say
1688
1689     use Fcntl;
1690
1691 first to get the correct constant definitions.  Argument processing and
1692 value return works just like C<ioctl> below.
1693 For example:
1694
1695     use Fcntl;
1696     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1697         or die "can't fcntl F_GETFL: $!";
1698
1699 You don't have to check for C<defined> on the return from C<fcntl>.
1700 Like C<ioctl>, it maps a C<0> return from the system call into
1701 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1702 in numeric context.  It is also exempt from the normal B<-w> warnings
1703 on improper numeric conversions.
1704
1705 Note that C<fcntl> will produce a fatal error if used on a machine that
1706 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1707 manpage to learn what functions are available on your system.
1708
1709 Here's an example of setting a filehandle named C<REMOTE> to be
1710 non-blocking at the system level.  You'll have to negotiate C<$|>
1711 on your own, though.
1712
1713     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1714
1715     $flags = fcntl(REMOTE, F_GETFL, 0)
1716                 or die "Can't get flags for the socket: $!\n";
1717
1718     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1719                 or die "Can't set flags for the socket: $!\n";
1720
1721 =item fileno FILEHANDLE
1722
1723 Returns the file descriptor for a filehandle, or undefined if the
1724 filehandle is not open.  This is mainly useful for constructing
1725 bitmaps for C<select> and low-level POSIX tty-handling operations.
1726 If FILEHANDLE is an expression, the value is taken as an indirect
1727 filehandle, generally its name.
1728
1729 You can use this to find out whether two handles refer to the
1730 same underlying descriptor:
1731
1732     if (fileno(THIS) == fileno(THAT)) {
1733         print "THIS and THAT are dups\n";
1734     }
1735
1736 (Filehandles connected to memory objects via new features of C<open> may
1737 return undefined even though they are open.)
1738
1739
1740 =item flock FILEHANDLE,OPERATION
1741
1742 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1743 for success, false on failure.  Produces a fatal error if used on a
1744 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1745 C<flock> is Perl's portable file locking interface, although it locks
1746 only entire files, not records.
1747
1748 Two potentially non-obvious but traditional C<flock> semantics are
1749 that it waits indefinitely until the lock is granted, and that its locks
1750 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1751 fewer guarantees.  This means that files locked with C<flock> may be
1752 modified by programs that do not also use C<flock>.  See L<perlport>,
1753 your port's specific documentation, or your system-specific local manpages
1754 for details.  It's best to assume traditional behavior if you're writing
1755 portable programs.  (But if you're not, you should as always feel perfectly
1756 free to write for your own system's idiosyncrasies (sometimes called
1757 "features").  Slavish adherence to portability concerns shouldn't get
1758 in the way of your getting your job done.)
1759
1760 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1761 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1762 you can use the symbolic names if you import them from the Fcntl module,
1763 either individually, or as a group using the ':flock' tag.  LOCK_SH
1764 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1765 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1766 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1767 waiting for the lock (check the return status to see if you got it).
1768
1769 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1770 before locking or unlocking it.
1771
1772 Note that the emulation built with lockf(3) doesn't provide shared
1773 locks, and it requires that FILEHANDLE be open with write intent.  These
1774 are the semantics that lockf(3) implements.  Most if not all systems
1775 implement lockf(3) in terms of fcntl(2) locking, though, so the
1776 differing semantics shouldn't bite too many people.
1777
1778 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1779 be open with read intent to use LOCK_SH and requires that it be open
1780 with write intent to use LOCK_EX.
1781
1782 Note also that some versions of C<flock> cannot lock things over the
1783 network; you would need to use the more system-specific C<fcntl> for
1784 that.  If you like you can force Perl to ignore your system's flock(2)
1785 function, and so provide its own fcntl(2)-based emulation, by passing
1786 the switch C<-Ud_flock> to the F<Configure> program when you configure
1787 perl.
1788
1789 Here's a mailbox appender for BSD systems.
1790
1791     use Fcntl ':flock'; # import LOCK_* constants
1792
1793     sub lock {
1794         flock(MBOX,LOCK_EX);
1795         # and, in case someone appended
1796         # while we were waiting...
1797         seek(MBOX, 0, 2);
1798     }
1799
1800     sub unlock {
1801         flock(MBOX,LOCK_UN);
1802     }
1803
1804     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1805             or die "Can't open mailbox: $!";
1806
1807     lock();
1808     print MBOX $msg,"\n\n";
1809     unlock();
1810
1811 On systems that support a real flock(), locks are inherited across fork()
1812 calls, whereas those that must resort to the more capricious fcntl()
1813 function lose the locks, making it harder to write servers.
1814
1815 See also L<DB_File> for other flock() examples.
1816
1817 =item fork
1818
1819 Does a fork(2) system call to create a new process running the
1820 same program at the same point.  It returns the child pid to the
1821 parent process, C<0> to the child process, or C<undef> if the fork is
1822 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1823 are shared, while everything else is copied.  On most systems supporting
1824 fork(), great care has gone into making it extremely efficient (for
1825 example, using copy-on-write technology on data pages), making it the
1826 dominant paradigm for multitasking over the last few decades.
1827
1828 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1829 output before forking the child process, but this may not be supported
1830 on some platforms (see L<perlport>).  To be safe, you may need to set
1831 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1832 C<IO::Handle> on any open handles in order to avoid duplicate output.
1833
1834 If you C<fork> without ever waiting on your children, you will
1835 accumulate zombies.  On some systems, you can avoid this by setting
1836 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1837 forking and reaping moribund children.
1838
1839 Note that if your forked child inherits system file descriptors like
1840 STDIN and STDOUT that are actually connected by a pipe or socket, even
1841 if you exit, then the remote server (such as, say, a CGI script or a
1842 backgrounded job launched from a remote shell) won't think you're done.
1843 You should reopen those to F</dev/null> if it's any issue.
1844
1845 =item format
1846
1847 Declare a picture format for use by the C<write> function.  For
1848 example:
1849
1850     format Something =
1851         Test: @<<<<<<<< @||||| @>>>>>
1852               $str,     $%,    '$' . int($num)
1853     .
1854
1855     $str = "widget";
1856     $num = $cost/$quantity;
1857     $~ = 'Something';
1858     write;
1859
1860 See L<perlform> for many details and examples.
1861
1862 =item formline PICTURE,LIST
1863
1864 This is an internal function used by C<format>s, though you may call it,
1865 too.  It formats (see L<perlform>) a list of values according to the
1866 contents of PICTURE, placing the output into the format output
1867 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1868 Eventually, when a C<write> is done, the contents of
1869 C<$^A> are written to some filehandle, but you could also read C<$^A>
1870 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1871 does one C<formline> per line of form, but the C<formline> function itself
1872 doesn't care how many newlines are embedded in the PICTURE.  This means
1873 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1874 You may therefore need to use multiple formlines to implement a single
1875 record format, just like the format compiler.
1876
1877 Be careful if you put double quotes around the picture, because an C<@>
1878 character may be taken to mean the beginning of an array name.
1879 C<formline> always returns true.  See L<perlform> for other examples.
1880
1881 =item getc FILEHANDLE
1882
1883 =item getc
1884
1885 Returns the next character from the input file attached to FILEHANDLE,
1886 or the undefined value at end of file, or if there was an error (in
1887 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1888 STDIN.  This is not particularly efficient.  However, it cannot be
1889 used by itself to fetch single characters without waiting for the user
1890 to hit enter.  For that, try something more like:
1891
1892     if ($BSD_STYLE) {
1893         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1894     }
1895     else {
1896         system "stty", '-icanon', 'eol', "\001";
1897     }
1898
1899     $key = getc(STDIN);
1900
1901     if ($BSD_STYLE) {
1902         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1903     }
1904     else {
1905         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1906     }
1907     print "\n";
1908
1909 Determination of whether $BSD_STYLE should be set
1910 is left as an exercise to the reader.
1911
1912 The C<POSIX::getattr> function can do this more portably on
1913 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1914 module from your nearest CPAN site; details on CPAN can be found on
1915 L<perlmodlib/CPAN>.
1916
1917 =item getlogin
1918
1919 Implements the C library function of the same name, which on most
1920 systems returns the current login from F</etc/utmp>, if any.  If null,
1921 use C<getpwuid>.
1922
1923     $login = getlogin || getpwuid($<) || "Kilroy";
1924
1925 Do not consider C<getlogin> for authentication: it is not as
1926 secure as C<getpwuid>.
1927
1928 =item getpeername SOCKET
1929
1930 Returns the packed sockaddr address of other end of the SOCKET connection.
1931
1932     use Socket;
1933     $hersockaddr    = getpeername(SOCK);
1934     ($port, $iaddr) = sockaddr_in($hersockaddr);
1935     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1936     $herstraddr     = inet_ntoa($iaddr);
1937
1938 =item getpgrp PID
1939
1940 Returns the current process group for the specified PID.  Use
1941 a PID of C<0> to get the current process group for the
1942 current process.  Will raise an exception if used on a machine that
1943 doesn't implement getpgrp(2).  If PID is omitted, returns process
1944 group of current process.  Note that the POSIX version of C<getpgrp>
1945 does not accept a PID argument, so only C<PID==0> is truly portable.
1946
1947 =item getppid
1948
1949 Returns the process id of the parent process.
1950
1951 Note for Linux users: on Linux, the C functions C<getpid()> and
1952 C<getppid()> return different values from different threads. In order to
1953 be portable, this behavior is not reflected by the perl-level function
1954 C<getppid()>, that returns a consistent value across threads. If you want
1955 to call the underlying C<getppid()>, you may use the CPAN module
1956 C<Linux::Pid>.
1957
1958 =item getpriority WHICH,WHO
1959
1960 Returns the current priority for a process, a process group, or a user.
1961 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1962 machine that doesn't implement getpriority(2).
1963
1964 =item getpwnam NAME
1965
1966 =item getgrnam NAME
1967
1968 =item gethostbyname NAME
1969
1970 =item getnetbyname NAME
1971
1972 =item getprotobyname NAME
1973
1974 =item getpwuid UID
1975
1976 =item getgrgid GID
1977
1978 =item getservbyname NAME,PROTO
1979
1980 =item gethostbyaddr ADDR,ADDRTYPE
1981
1982 =item getnetbyaddr ADDR,ADDRTYPE
1983
1984 =item getprotobynumber NUMBER
1985
1986 =item getservbyport PORT,PROTO
1987
1988 =item getpwent
1989
1990 =item getgrent
1991
1992 =item gethostent
1993
1994 =item getnetent
1995
1996 =item getprotoent
1997
1998 =item getservent
1999
2000 =item setpwent
2001
2002 =item setgrent
2003
2004 =item sethostent STAYOPEN
2005
2006 =item setnetent STAYOPEN
2007
2008 =item setprotoent STAYOPEN
2009
2010 =item setservent STAYOPEN
2011
2012 =item endpwent
2013
2014 =item endgrent
2015
2016 =item endhostent
2017
2018 =item endnetent
2019
2020 =item endprotoent
2021
2022 =item endservent
2023
2024 These routines perform the same functions as their counterparts in the
2025 system library.  In list context, the return values from the
2026 various get routines are as follows:
2027
2028     ($name,$passwd,$uid,$gid,
2029        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2030     ($name,$passwd,$gid,$members) = getgr*
2031     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2032     ($name,$aliases,$addrtype,$net) = getnet*
2033     ($name,$aliases,$proto) = getproto*
2034     ($name,$aliases,$port,$proto) = getserv*
2035
2036 (If the entry doesn't exist you get a null list.)
2037
2038 The exact meaning of the $gcos field varies but it usually contains
2039 the real name of the user (as opposed to the login name) and other
2040 information pertaining to the user.  Beware, however, that in many
2041 system users are able to change this information and therefore it
2042 cannot be trusted and therefore the $gcos is tainted (see
2043 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2044 login shell, are also tainted, because of the same reason.
2045
2046 In scalar context, you get the name, unless the function was a
2047 lookup by name, in which case you get the other thing, whatever it is.
2048 (If the entry doesn't exist you get the undefined value.)  For example:
2049
2050     $uid   = getpwnam($name);
2051     $name  = getpwuid($num);
2052     $name  = getpwent();
2053     $gid   = getgrnam($name);
2054     $name  = getgrgid($num);
2055     $name  = getgrent();
2056     #etc.
2057
2058 In I<getpw*()> the fields $quota, $comment, and $expire are special
2059 cases in the sense that in many systems they are unsupported.  If the
2060 $quota is unsupported, it is an empty scalar.  If it is supported, it
2061 usually encodes the disk quota.  If the $comment field is unsupported,
2062 it is an empty scalar.  If it is supported it usually encodes some
2063 administrative comment about the user.  In some systems the $quota
2064 field may be $change or $age, fields that have to do with password
2065 aging.  In some systems the $comment field may be $class.  The $expire
2066 field, if present, encodes the expiration period of the account or the
2067 password.  For the availability and the exact meaning of these fields
2068 in your system, please consult your getpwnam(3) documentation and your
2069 F<pwd.h> file.  You can also find out from within Perl what your
2070 $quota and $comment fields mean and whether you have the $expire field
2071 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2072 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2073 files are only supported if your vendor has implemented them in the
2074 intuitive fashion that calling the regular C library routines gets the
2075 shadow versions if you're running under privilege or if there exists
2076 the shadow(3) functions as found in System V ( this includes Solaris
2077 and Linux.)  Those systems which implement a proprietary shadow password
2078 facility are unlikely to be supported.
2079
2080 The $members value returned by I<getgr*()> is a space separated list of
2081 the login names of the members of the group.
2082
2083 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2084 C, it will be returned to you via C<$?> if the function call fails.  The
2085 C<@addrs> value returned by a successful call is a list of the raw
2086 addresses returned by the corresponding system library call.  In the
2087 Internet domain, each address is four bytes long and you can unpack it
2088 by saying something like:
2089
2090     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2091
2092 The Socket library makes this slightly easier:
2093
2094     use Socket;
2095     $iaddr = inet_aton("127.1"); # or whatever address
2096     $name  = gethostbyaddr($iaddr, AF_INET);
2097
2098     # or going the other way
2099     $straddr = inet_ntoa($iaddr);
2100
2101 If you get tired of remembering which element of the return list
2102 contains which return value, by-name interfaces are provided
2103 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2104 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2105 and C<User::grent>.  These override the normal built-ins, supplying
2106 versions that return objects with the appropriate names
2107 for each field.  For example:
2108
2109    use File::stat;
2110    use User::pwent;
2111    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2112
2113 Even though it looks like they're the same method calls (uid),
2114 they aren't, because a C<File::stat> object is different from
2115 a C<User::pwent> object.
2116
2117 =item getsockname SOCKET
2118
2119 Returns the packed sockaddr address of this end of the SOCKET connection,
2120 in case you don't know the address because you have several different
2121 IPs that the connection might have come in on.
2122
2123     use Socket;
2124     $mysockaddr = getsockname(SOCK);
2125     ($port, $myaddr) = sockaddr_in($mysockaddr);
2126     printf "Connect to %s [%s]\n",
2127        scalar gethostbyaddr($myaddr, AF_INET),
2128        inet_ntoa($myaddr);
2129
2130 =item getsockopt SOCKET,LEVEL,OPTNAME
2131
2132 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2133 Options may exist at multiple protocol levels depending on the socket
2134 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2135 C<Socket> module) will exist. To query options at another level the
2136 protocol number of the appropriate protocol controlling the option
2137 should be supplied. For example, to indicate that an option is to be
2138 interpreted by the TCP protocol, LEVEL should be set to the protocol
2139 number of TCP, which you can get using getprotobyname.
2140
2141 The call returns a packed string representing the requested socket option,
2142 or C<undef> if there is an error (the error reason will be in $!). What
2143 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2144 your system documentation for details. A very common case however is that
2145 the option is an integer, in which case the result will be an packed
2146 integer which you can decode using unpack with the C<i> (or C<I>) format.
2147
2148 An example testing if Nagle's algorithm is turned on on a socket:
2149
2150     use Socket qw(:all);
2151
2152     defined(my $tcp = getprotobyname("tcp"))
2153         or die "Could not determine the protocol number for tcp";
2154     # my $tcp = IPPROTO_TCP; # Alternative
2155     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2156         or die "Could not query TCP_NODELAY socket option: $!";
2157     my $nodelay = unpack("I", $packed);
2158     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2159
2160
2161 =item glob EXPR
2162
2163 =item glob
2164
2165 In list context, returns a (possibly empty) list of filename expansions on
2166 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2167 scalar context, glob iterates through such filename expansions, returning
2168 undef when the list is exhausted. This is the internal function
2169 implementing the C<< <*.c> >> operator, but you can use it directly. If
2170 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2171 more detail in L<perlop/"I/O Operators">.
2172
2173 Beginning with v5.6.0, this operator is implemented using the standard
2174 C<File::Glob> extension.  See L<File::Glob> for details.
2175
2176 =item gmtime EXPR
2177
2178 =item gmtime
2179
2180 Converts a time as returned by the time function to an 8-element list
2181 with the time localized for the standard Greenwich time zone.
2182 Typically used as follows:
2183
2184     #  0    1    2     3     4    5     6     7
2185     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2186                                             gmtime(time);
2187
2188 All list elements are numeric, and come straight out of the C `struct
2189 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2190 specified time.  $mday is the day of the month, and $mon is the month
2191 itself, in the range C<0..11> with 0 indicating January and 11
2192 indicating December.  $year is the number of years since 1900.  That
2193 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2194 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2195 the year, in the range C<0..364> (or C<0..365> in leap years.)
2196
2197 Note that the $year element is I<not> simply the last two digits of
2198 the year.  If you assume it is, then you create non-Y2K-compliant
2199 programs--and you wouldn't want to do that, would you?
2200
2201 The proper way to get a complete 4-digit year is simply:
2202
2203         $year += 1900;
2204
2205 And to get the last two digits of the year (e.g., '01' in 2001) do:
2206
2207         $year = sprintf("%02d", $year % 100);
2208
2209 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2210
2211 In scalar context, C<gmtime()> returns the ctime(3) value:
2212
2213     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2214
2215 If you need local time instead of GMT use the L</localtime> builtin. 
2216 See also the C<timegm> function provided by the C<Time::Local> module,
2217 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2218
2219 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2220 instead a Perl builtin.  To get somewhat similar but locale dependent date
2221 strings, see the example in L</localtime>.
2222
2223 See L<perlport/gmtime> for portability concerns.
2224
2225 =item goto LABEL
2226
2227 =item goto EXPR
2228
2229 =item goto &NAME
2230
2231 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2232 execution there.  It may not be used to go into any construct that
2233 requires initialization, such as a subroutine or a C<foreach> loop.  It
2234 also can't be used to go into a construct that is optimized away,
2235 or to get out of a block or subroutine given to C<sort>.
2236 It can be used to go almost anywhere else within the dynamic scope,
2237 including out of subroutines, but it's usually better to use some other
2238 construct such as C<last> or C<die>.  The author of Perl has never felt the
2239 need to use this form of C<goto> (in Perl, that is--C is another matter).
2240 (The difference being that C does not offer named loops combined with
2241 loop control.  Perl does, and this replaces most structured uses of C<goto>
2242 in other languages.)
2243
2244 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2245 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2246 necessarily recommended if you're optimizing for maintainability:
2247
2248     goto ("FOO", "BAR", "GLARCH")[$i];
2249
2250 The C<goto-&NAME> form is quite different from the other forms of
2251 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2252 doesn't have the stigma associated with other gotos.  Instead, it
2253 exits the current subroutine (losing any changes set by local()) and
2254 immediately calls in its place the named subroutine using the current
2255 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2256 load another subroutine and then pretend that the other subroutine had
2257 been called in the first place (except that any modifications to C<@_>
2258 in the current subroutine are propagated to the other subroutine.)
2259 After the C<goto>, not even C<caller> will be able to tell that this
2260 routine was called first.
2261
2262 NAME needn't be the name of a subroutine; it can be a scalar variable
2263 containing a code reference, or a block which evaluates to a code
2264 reference.
2265
2266 =item grep BLOCK LIST
2267
2268 =item grep EXPR,LIST
2269
2270 This is similar in spirit to, but not the same as, grep(1) and its
2271 relatives.  In particular, it is not limited to using regular expressions.
2272
2273 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2274 C<$_> to each element) and returns the list value consisting of those
2275 elements for which the expression evaluated to true.  In scalar
2276 context, returns the number of times the expression was true.
2277
2278     @foo = grep(!/^#/, @bar);    # weed out comments
2279
2280 or equivalently,
2281
2282     @foo = grep {!/^#/} @bar;    # weed out comments
2283
2284 Note that C<$_> is an alias to the list value, so it can be used to
2285 modify the elements of the LIST.  While this is useful and supported,
2286 it can cause bizarre results if the elements of LIST are not variables.
2287 Similarly, grep returns aliases into the original list, much as a for
2288 loop's index variable aliases the list elements.  That is, modifying an
2289 element of a list returned by grep (for example, in a C<foreach>, C<map>
2290 or another C<grep>) actually modifies the element in the original list.
2291 This is usually something to be avoided when writing clear code.
2292
2293 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2294 been declared with C<my $_>) then, in addition the be locally aliased to
2295 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2296 can't be seen from the outside, avoiding any potential side-effects.
2297
2298 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2299
2300 =item hex EXPR
2301
2302 =item hex
2303
2304 Interprets EXPR as a hex string and returns the corresponding value.
2305 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2306 L</oct>.)  If EXPR is omitted, uses C<$_>.
2307
2308     print hex '0xAf'; # prints '175'
2309     print hex 'aF';   # same
2310
2311 Hex strings may only represent integers.  Strings that would cause
2312 integer overflow trigger a warning.  Leading whitespace is not stripped,
2313 unlike oct(). To present something as hex, look into L</printf>,
2314 L</sprintf>, or L</unpack>.
2315
2316 =item import LIST
2317
2318 There is no builtin C<import> function.  It is just an ordinary
2319 method (subroutine) defined (or inherited) by modules that wish to export
2320 names to another module.  The C<use> function calls the C<import> method
2321 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2322
2323 =item index STR,SUBSTR,POSITION
2324
2325 =item index STR,SUBSTR
2326
2327 The index function searches for one string within another, but without
2328 the wildcard-like behavior of a full regular-expression pattern match.
2329 It returns the position of the first occurrence of SUBSTR in STR at
2330 or after POSITION.  If POSITION is omitted, starts searching from the
2331 beginning of the string.  The return value is based at C<0> (or whatever
2332 you've set the C<$[> variable to--but don't do that).  If the substring
2333 is not found, returns one less than the base, ordinarily C<-1>.
2334
2335 =item int EXPR
2336
2337 =item int
2338
2339 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2340 You should not use this function for rounding: one because it truncates
2341 towards C<0>, and two because machine representations of floating point
2342 numbers can sometimes produce counterintuitive results.  For example,
2343 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2344 because it's really more like -268.99999999999994315658 instead.  Usually,
2345 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2346 functions will serve you better than will int().
2347
2348 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2349
2350 Implements the ioctl(2) function.  You'll probably first have to say
2351
2352     require "sys/ioctl.ph";     # probably in $Config{archlib}/ioctl.ph
2353
2354 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2355 exist or doesn't have the correct definitions you'll have to roll your
2356 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2357 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2358 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2359 written depending on the FUNCTION--a pointer to the string value of SCALAR
2360 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2361 has no string value but does have a numeric value, that value will be
2362 passed rather than a pointer to the string value.  To guarantee this to be
2363 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2364 functions may be needed to manipulate the values of structures used by
2365 C<ioctl>.
2366
2367 The return value of C<ioctl> (and C<fcntl>) is as follows:
2368
2369         if OS returns:          then Perl returns:
2370             -1                    undefined value
2371              0                  string "0 but true"
2372         anything else               that number
2373
2374 Thus Perl returns true on success and false on failure, yet you can
2375 still easily determine the actual value returned by the operating
2376 system:
2377
2378     $retval = ioctl(...) || -1;
2379     printf "System returned %d\n", $retval;
2380
2381 The special string C<"0 but true"> is exempt from B<-w> complaints
2382 about improper numeric conversions.
2383
2384 =item join EXPR,LIST
2385
2386 Joins the separate strings of LIST into a single string with fields
2387 separated by the value of EXPR, and returns that new string.  Example:
2388
2389     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2390
2391 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2392 first argument.  Compare L</split>.
2393
2394 =item keys HASH
2395
2396 Returns a list consisting of all the keys of the named hash.
2397 (In scalar context, returns the number of keys.)
2398
2399 The keys are returned in an apparently random order.  The actual
2400 random order is subject to change in future versions of perl, but it
2401 is guaranteed to be the same order as either the C<values> or C<each>
2402 function produces (given that the hash has not been modified).  Since
2403 Perl 5.8.1 the ordering is different even between different runs of
2404 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2405 Attacks">).
2406
2407 As a side effect, calling keys() resets the HASH's internal iterator,
2408 see L</each>. (In particular, calling keys() in void context resets
2409 the iterator with no other overhead.)
2410
2411 Here is yet another way to print your environment:
2412
2413     @keys = keys %ENV;
2414     @values = values %ENV;
2415     while (@keys) {
2416         print pop(@keys), '=', pop(@values), "\n";
2417     }
2418
2419 or how about sorted by key:
2420
2421     foreach $key (sort(keys %ENV)) {
2422         print $key, '=', $ENV{$key}, "\n";
2423     }
2424
2425 The returned values are copies of the original keys in the hash, so
2426 modifying them will not affect the original hash.  Compare L</values>.
2427
2428 To sort a hash by value, you'll need to use a C<sort> function.
2429 Here's a descending numeric sort of a hash by its values:
2430
2431     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2432         printf "%4d %s\n", $hash{$key}, $key;
2433     }
2434
2435 As an lvalue C<keys> allows you to increase the number of hash buckets
2436 allocated for the given hash.  This can gain you a measure of efficiency if
2437 you know the hash is going to get big.  (This is similar to pre-extending
2438 an array by assigning a larger number to $#array.)  If you say
2439
2440     keys %hash = 200;
2441
2442 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2443 in fact, since it rounds up to the next power of two.  These
2444 buckets will be retained even if you do C<%hash = ()>, use C<undef
2445 %hash> if you want to free the storage while C<%hash> is still in scope.
2446 You can't shrink the number of buckets allocated for the hash using
2447 C<keys> in this way (but you needn't worry about doing this by accident,
2448 as trying has no effect).
2449
2450 See also C<each>, C<values> and C<sort>.
2451
2452 =item kill SIGNAL, LIST
2453
2454 Sends a signal to a list of processes.  Returns the number of
2455 processes successfully signaled (which is not necessarily the
2456 same as the number actually killed).
2457
2458     $cnt = kill 1, $child1, $child2;
2459     kill 9, @goners;
2460
2461 If SIGNAL is zero, no signal is sent to the process.  This is a
2462 useful way to check that a child process is alive and hasn't changed
2463 its UID.  See L<perlport> for notes on the portability of this
2464 construct.
2465
2466 Unlike in the shell, if SIGNAL is negative, it kills
2467 process groups instead of processes.  (On System V, a negative I<PROCESS>
2468 number will also kill process groups, but that's not portable.)  That
2469 means you usually want to use positive not negative signals.  You may also
2470 use a signal name in quotes.
2471
2472 See L<perlipc/"Signals"> for more details.
2473
2474 =item last LABEL
2475
2476 =item last
2477
2478 The C<last> command is like the C<break> statement in C (as used in
2479 loops); it immediately exits the loop in question.  If the LABEL is
2480 omitted, the command refers to the innermost enclosing loop.  The
2481 C<continue> block, if any, is not executed:
2482
2483     LINE: while (<STDIN>) {
2484         last LINE if /^$/;      # exit when done with header
2485         #...
2486     }
2487
2488 C<last> cannot be used to exit a block which returns a value such as
2489 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2490 a grep() or map() operation.
2491
2492 Note that a block by itself is semantically identical to a loop
2493 that executes once.  Thus C<last> can be used to effect an early
2494 exit out of such a block.
2495
2496 See also L</continue> for an illustration of how C<last>, C<next>, and
2497 C<redo> work.
2498
2499 =item lc EXPR
2500
2501 =item lc
2502
2503 Returns a lowercased version of EXPR.  This is the internal function
2504 implementing the C<\L> escape in double-quoted strings.  Respects
2505 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2506 and L<perlunicode> for more details about locale and Unicode support.
2507
2508 If EXPR is omitted, uses C<$_>.
2509
2510 =item lcfirst EXPR
2511
2512 =item lcfirst
2513
2514 Returns the value of EXPR with the first character lowercased.  This
2515 is the internal function implementing the C<\l> escape in
2516 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2517 locale> in force.  See L<perllocale> and L<perlunicode> for more
2518 details about locale and Unicode support.
2519
2520 If EXPR is omitted, uses C<$_>.
2521
2522 =item length EXPR
2523
2524 =item length
2525
2526 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2527 omitted, returns length of C<$_>.  Note that this cannot be used on
2528 an entire array or hash to find out how many elements these have.
2529 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2530
2531 Note the I<characters>: if the EXPR is in Unicode, you will get the
2532 number of characters, not the number of bytes.  To get the length
2533 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2534
2535 =item link OLDFILE,NEWFILE
2536
2537 Creates a new filename linked to the old filename.  Returns true for
2538 success, false otherwise.
2539
2540 =item listen SOCKET,QUEUESIZE
2541
2542 Does the same thing that the listen system call does.  Returns true if
2543 it succeeded, false otherwise.  See the example in
2544 L<perlipc/"Sockets: Client/Server Communication">.
2545
2546 =item local EXPR
2547
2548 You really probably want to be using C<my> instead, because C<local> isn't
2549 what most people think of as "local".  See
2550 L<perlsub/"Private Variables via my()"> for details.
2551
2552 A local modifies the listed variables to be local to the enclosing
2553 block, file, or eval.  If more than one value is listed, the list must
2554 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2555 for details, including issues with tied arrays and hashes.
2556
2557 =item localtime EXPR
2558
2559 =item localtime
2560
2561 Converts a time as returned by the time function to a 9-element list
2562 with the time analyzed for the local time zone.  Typically used as
2563 follows:
2564
2565     #  0    1    2     3     4    5     6     7     8
2566     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2567                                                 localtime(time);
2568
2569 All list elements are numeric, and come straight out of the C `struct
2570 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2571 of the specified time.
2572
2573 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2574 the range C<0..11> with 0 indicating January and 11 indicating December.
2575 This makes it easy to get a month name from a list:
2576
2577     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2578     print "$abbr[$mon] $mday";
2579     # $mon=9, $mday=18 gives "Oct 18"
2580
2581 C<$year> is the number of years since 1900, not just the last two digits
2582 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2583 to get a complete 4-digit year is simply:
2584
2585     $year += 1900;
2586
2587 To get the last two digits of the year (e.g., '01' in 2001) do:
2588
2589     $year = sprintf("%02d", $year % 100);
2590
2591 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2592 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2593 (or C<0..365> in leap years.)
2594
2595 C<$isdst> is true if the specified time occurs during Daylight Saving
2596 Time, false otherwise.
2597
2598 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2599
2600 In scalar context, C<localtime()> returns the ctime(3) value:
2601
2602     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2603
2604 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2605 instead of local time use the L</gmtime> builtin. See also the
2606 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2607 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2608 and mktime(3) functions.
2609
2610 To get somewhat similar but locale dependent date strings, set up your
2611 locale environment variables appropriately (please see L<perllocale>) and
2612 try for example:
2613
2614     use POSIX qw(strftime);
2615     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2616     # or for GMT formatted appropriately for your locale:
2617     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2618
2619 Note that the C<%a> and C<%b>, the short forms of the day of the week
2620 and the month of the year, may not necessarily be three characters wide.
2621
2622 See L<perlport/localtime> for portability concerns.
2623
2624 =item lock THING
2625
2626 This function places an advisory lock on a shared variable, or referenced
2627 object contained in I<THING> until the lock goes out of scope.
2628
2629 lock() is a "weak keyword" : this means that if you've defined a function
2630 by this name (before any calls to it), that function will be called
2631 instead. (However, if you've said C<use threads>, lock() is always a
2632 keyword.) See L<threads>.
2633
2634 =item log EXPR
2635
2636 =item log
2637
2638 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2639 returns log of C<$_>.  To get the log of another base, use basic algebra:
2640 The base-N log of a number is equal to the natural log of that number
2641 divided by the natural log of N.  For example:
2642
2643     sub log10 {
2644         my $n = shift;
2645         return log($n)/log(10);
2646     }
2647
2648 See also L</exp> for the inverse operation.
2649
2650 =item lstat EXPR
2651
2652 =item lstat
2653
2654 Does the same thing as the C<stat> function (including setting the
2655 special C<_> filehandle) but stats a symbolic link instead of the file
2656 the symbolic link points to.  If symbolic links are unimplemented on
2657 your system, a normal C<stat> is done.  For much more detailed
2658 information, please see the documentation for C<stat>.
2659
2660 If EXPR is omitted, stats C<$_>.
2661
2662 =item m//
2663
2664 The match operator.  See L<perlop>.
2665
2666 =item map BLOCK LIST
2667
2668 =item map EXPR,LIST
2669
2670 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2671 C<$_> to each element) and returns the list value composed of the
2672 results of each such evaluation.  In scalar context, returns the
2673 total number of elements so generated.  Evaluates BLOCK or EXPR in
2674 list context, so each element of LIST may produce zero, one, or
2675 more elements in the returned value.
2676
2677     @chars = map(chr, @nums);
2678
2679 translates a list of numbers to the corresponding characters.  And
2680
2681     %hash = map { getkey($_) => $_ } @array;
2682
2683 is just a funny way to write
2684
2685     %hash = ();
2686     foreach $_ (@array) {
2687         $hash{getkey($_)} = $_;
2688     }
2689
2690 Note that C<$_> is an alias to the list value, so it can be used to
2691 modify the elements of the LIST.  While this is useful and supported,
2692 it can cause bizarre results if the elements of LIST are not variables.
2693 Using a regular C<foreach> loop for this purpose would be clearer in
2694 most cases.  See also L</grep> for an array composed of those items of
2695 the original list for which the BLOCK or EXPR evaluates to true.
2696
2697 If C<$_> is lexical in the scope where the C<map> appears (because it has
2698 been declared with C<my $_>) then, in addition the be locally aliased to
2699 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2700 can't be seen from the outside, avoiding any potential side-effects.
2701
2702 C<{> starts both hash references and blocks, so C<map { ...> could be either
2703 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2704 ahead for the closing C<}> it has to take a guess at which its dealing with
2705 based what it finds just after the C<{>. Usually it gets it right, but if it
2706 doesn't it won't realize something is wrong until it gets to the C<}> and
2707 encounters the missing (or unexpected) comma. The syntax error will be
2708 reported close to the C<}> but you'll need to change something near the C<{>
2709 such as using a unary C<+> to give perl some help:
2710
2711     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2712     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2713     %hash = map { ("\L$_", 1) } @array  # this also works
2714     %hash = map {  lc($_), 1  } @array  # as does this.
2715     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2716
2717     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2718
2719 or to force an anon hash constructor use C<+{>
2720
2721    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2722
2723 and you get list of anonymous hashes each with only 1 entry.
2724
2725 =item mkdir FILENAME,MASK
2726
2727 =item mkdir FILENAME
2728
2729 =item mkdir
2730
2731 Creates the directory specified by FILENAME, with permissions
2732 specified by MASK (as modified by C<umask>).  If it succeeds it
2733 returns true, otherwise it returns false and sets C<$!> (errno).
2734 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2735 to C<$_>.
2736
2737 In general, it is better to create directories with permissive MASK,
2738 and let the user modify that with their C<umask>, than it is to supply
2739 a restrictive MASK and give the user no way to be more permissive.
2740 The exceptions to this rule are when the file or directory should be
2741 kept private (mail files, for instance).  The perlfunc(1) entry on
2742 C<umask> discusses the choice of MASK in more detail.
2743
2744 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2745 number of trailing slashes.  Some operating and filesystems do not get
2746 this right, so Perl automatically removes all trailing slashes to keep
2747 everyone happy.
2748
2749 =item msgctl ID,CMD,ARG
2750
2751 Calls the System V IPC function msgctl(2).  You'll probably have to say
2752
2753     use IPC::SysV;
2754
2755 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2756 then ARG must be a variable which will hold the returned C<msqid_ds>
2757 structure.  Returns like C<ioctl>: the undefined value for error,
2758 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2759 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2760
2761 =item msgget KEY,FLAGS
2762
2763 Calls the System V IPC function msgget(2).  Returns the message queue
2764 id, or the undefined value if there is an error.  See also
2765 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2766
2767 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2768
2769 Calls the System V IPC function msgrcv to receive a message from
2770 message queue ID into variable VAR with a maximum message size of
2771 SIZE.  Note that when a message is received, the message type as a
2772 native long integer will be the first thing in VAR, followed by the
2773 actual message.  This packing may be opened with C<unpack("l! a*")>.
2774 Taints the variable.  Returns true if successful, or false if there is
2775 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2776 C<IPC::SysV::Msg> documentation.
2777
2778 =item msgsnd ID,MSG,FLAGS
2779
2780 Calls the System V IPC function msgsnd to send the message MSG to the
2781 message queue ID.  MSG must begin with the native long integer message
2782 type, and be followed by the length of the actual message, and finally
2783 the message itself.  This kind of packing can be achieved with
2784 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2785 or false if there is an error.  See also C<IPC::SysV>
2786 and C<IPC::SysV::Msg> documentation.
2787
2788 =item my EXPR
2789
2790 =item my TYPE EXPR
2791
2792 =item my EXPR : ATTRS
2793
2794 =item my TYPE EXPR : ATTRS
2795
2796 A C<my> declares the listed variables to be local (lexically) to the
2797 enclosing block, file, or C<eval>.  If more than one value is listed,
2798 the list must be placed in parentheses.
2799
2800 The exact semantics and interface of TYPE and ATTRS are still
2801 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2802 and attributes are handled using the C<attributes> pragma, or starting
2803 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2804 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2805 L<attributes>, and L<Attribute::Handlers>.
2806
2807 =item next LABEL
2808
2809 =item next
2810
2811 The C<next> command is like the C<continue> statement in C; it starts
2812 the next iteration of the loop:
2813
2814     LINE: while (<STDIN>) {
2815         next LINE if /^#/;      # discard comments
2816         #...
2817     }
2818
2819 Note that if there were a C<continue> block on the above, it would get
2820 executed even on discarded lines.  If the LABEL is omitted, the command
2821 refers to the innermost enclosing loop.
2822
2823 C<next> cannot be used to exit a block which returns a value such as
2824 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2825 a grep() or map() operation.
2826
2827 Note that a block by itself is semantically identical to a loop
2828 that executes once.  Thus C<next> will exit such a block early.
2829
2830 See also L</continue> for an illustration of how C<last>, C<next>, and
2831 C<redo> work.
2832
2833 =item no Module VERSION LIST
2834
2835 =item no Module VERSION
2836
2837 =item no Module LIST
2838
2839 =item no Module
2840
2841 See the C<use> function, of which C<no> is the opposite.
2842
2843 =item oct EXPR
2844
2845 =item oct
2846
2847 Interprets EXPR as an octal string and returns the corresponding
2848 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2849 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2850 binary string.  Leading whitespace is ignored in all three cases.)
2851 The following will handle decimal, binary, octal, and hex in the standard
2852 Perl or C notation:
2853
2854     $val = oct($val) if $val =~ /^0/;
2855
2856 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2857 in octal), use sprintf() or printf():
2858
2859     $perms = (stat("filename"))[2] & 07777;
2860     $oct_perms = sprintf "%lo", $perms;
2861
2862 The oct() function is commonly used when a string such as C<644> needs
2863 to be converted into a file mode, for example. (Although perl will
2864 automatically convert strings into numbers as needed, this automatic
2865 conversion assumes base 10.)
2866
2867 =item open FILEHANDLE,EXPR
2868
2869 =item open FILEHANDLE,MODE,EXPR
2870
2871 =item open FILEHANDLE,MODE,EXPR,LIST
2872
2873 =item open FILEHANDLE,MODE,REFERENCE
2874
2875 =item open FILEHANDLE
2876
2877 Opens the file whose filename is given by EXPR, and associates it with
2878 FILEHANDLE.
2879
2880 (The following is a comprehensive reference to open(): for a gentler
2881 introduction you may consider L<perlopentut>.)
2882
2883 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2884 the variable is assigned a reference to a new anonymous filehandle,
2885 otherwise if FILEHANDLE is an expression, its value is used as the name of
2886 the real filehandle wanted.  (This is considered a symbolic reference, so
2887 C<use strict 'refs'> should I<not> be in effect.)
2888
2889 If EXPR is omitted, the scalar variable of the same name as the
2890 FILEHANDLE contains the filename.  (Note that lexical variables--those
2891 declared with C<my>--will not work for this purpose; so if you're
2892 using C<my>, specify EXPR in your call to open.)
2893
2894 If three or more arguments are specified then the mode of opening and
2895 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2896 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2897 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2898 the file is opened for appending, again being created if necessary.
2899
2900 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2901 indicate that you want both read and write access to the file; thus
2902 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2903 '+>' >> mode would clobber the file first.  You can't usually use
2904 either read-write mode for updating textfiles, since they have
2905 variable length records.  See the B<-i> switch in L<perlrun> for a
2906 better approach.  The file is created with permissions of C<0666>
2907 modified by the process' C<umask> value.
2908
2909 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2910 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2911
2912 In the 2-arguments (and 1-argument) form of the call the mode and
2913 filename should be concatenated (in this order), possibly separated by
2914 spaces.  It is possible to omit the mode in these forms if the mode is
2915 C<< '<' >>.
2916
2917 If the filename begins with C<'|'>, the filename is interpreted as a
2918 command to which output is to be piped, and if the filename ends with a
2919 C<'|'>, the filename is interpreted as a command which pipes output to
2920 us.  See L<perlipc/"Using open() for IPC">
2921 for more examples of this.  (You are not allowed to C<open> to a command
2922 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2923 and L<perlipc/"Bidirectional Communication with Another Process">
2924 for alternatives.)
2925
2926 For three or more arguments if MODE is C<'|-'>, the filename is
2927 interpreted as a command to which output is to be piped, and if MODE
2928 is C<'-|'>, the filename is interpreted as a command which pipes
2929 output to us.  In the 2-arguments (and 1-argument) form one should
2930 replace dash (C<'-'>) with the command.
2931 See L<perlipc/"Using open() for IPC"> for more examples of this.
2932 (You are not allowed to C<open> to a command that pipes both in I<and>
2933 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2934 L<perlipc/"Bidirectional Communication"> for alternatives.)
2935
2936 In the three-or-more argument form of pipe opens, if LIST is specified
2937 (extra arguments after the command name) then LIST becomes arguments
2938 to the command invoked if the platform supports it.  The meaning of
2939 C<open> with more than three arguments for non-pipe modes is not yet
2940 specified. Experimental "layers" may give extra LIST arguments
2941 meaning.
2942
2943 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2944 and opening C<< '>-' >> opens STDOUT.
2945
2946 You may use the three-argument form of open to specify IO "layers"
2947 (sometimes also referred to as "disciplines") to be applied to the handle
2948 that affect how the input and output are processed (see L<open> and
2949 L<PerlIO> for more details). For example
2950
2951   open(FH, "<:utf8", "file")
2952
2953 will open the UTF-8 encoded file containing Unicode characters,
2954 see L<perluniintro>. (Note that if layers are specified in the
2955 three-arg form then default layers set by the C<open> pragma are
2956 ignored.)
2957
2958 Open returns nonzero upon success, the undefined value otherwise.  If
2959 the C<open> involved a pipe, the return value happens to be the pid of
2960 the subprocess.
2961
2962 If you're running Perl on a system that distinguishes between text
2963 files and binary files, then you should check out L</binmode> for tips
2964 for dealing with this.  The key distinction between systems that need
2965 C<binmode> and those that don't is their text file formats.  Systems
2966 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2967 character, and which encode that character in C as C<"\n">, do not
2968 need C<binmode>.  The rest need it.
2969
2970 When opening a file, it's usually a bad idea to continue normal execution
2971 if the request failed, so C<open> is frequently used in connection with
2972 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2973 where you want to make a nicely formatted error message (but there are
2974 modules that can help with that problem)) you should always check
2975 the return value from opening a file.  The infrequent exception is when
2976 working with an unopened filehandle is actually what you want to do.
2977
2978 As a special case the 3 arg form with a read/write mode and the third
2979 argument being C<undef>:
2980
2981     open(TMP, "+>", undef) or die ...
2982
2983 opens a filehandle to an anonymous temporary file.  Also using "+<"
2984 works for symmetry, but you really should consider writing something
2985 to the temporary file first.  You will need to seek() to do the
2986 reading.
2987
2988 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
2989 changed this (ie Configure -Uuseperlio), you can open file handles to
2990 "in memory" files held in Perl scalars via:
2991
2992     open($fh, '>', \$variable) || ..
2993
2994 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2995 file, you have to close it first:
2996
2997     close STDOUT;
2998     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2999
3000 Examples:
3001
3002     $ARTICLE = 100;
3003     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3004     while (<ARTICLE>) {...
3005
3006     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3007     # if the open fails, output is discarded
3008
3009     open(DBASE, '+<', 'dbase.mine')             # open for update
3010         or die "Can't open 'dbase.mine' for update: $!";
3011
3012     open(DBASE, '+<dbase.mine')                 # ditto
3013         or die "Can't open 'dbase.mine' for update: $!";
3014
3015     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3016         or die "Can't start caesar: $!";
3017
3018     open(ARTICLE, "caesar <$article |")         # ditto
3019         or die "Can't start caesar: $!";
3020
3021     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3022         or die "Can't start sort: $!";
3023
3024     # in memory files
3025     open(MEMORY,'>', \$var)
3026         or die "Can't open memory file: $!";
3027     print MEMORY "foo!\n";                      # output will end up in $var
3028
3029     # process argument list of files along with any includes
3030
3031     foreach $file (@ARGV) {
3032         process($file, 'fh00');
3033     }
3034
3035     sub process {
3036         my($filename, $input) = @_;
3037         $input++;               # this is a string increment
3038         unless (open($input, $filename)) {
3039             print STDERR "Can't open $filename: $!\n";
3040             return;
3041         }
3042
3043         local $_;
3044         while (<$input>) {              # note use of indirection
3045             if (/^#include "(.*)"/) {
3046                 process($1, $input);
3047                 next;
3048             }
3049             #...                # whatever
3050         }
3051     }
3052
3053 See L<perliol> for detailed info on PerlIO.
3054
3055 You may also, in the Bourne shell tradition, specify an EXPR beginning
3056 with C<< '>&' >>, in which case the rest of the string is interpreted
3057 as the name of a filehandle (or file descriptor, if numeric) to be
3058 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3059 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3060 The mode you specify should match the mode of the original filehandle.
3061 (Duping a filehandle does not take into account any existing contents
3062 of IO buffers.) If you use the 3 arg form then you can pass either a
3063 number, the name of a filehandle or the normal "reference to a glob".
3064
3065 Here is a script that saves, redirects, and restores C<STDOUT> and
3066 C<STDERR> using various methods:
3067
3068     #!/usr/bin/perl
3069     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3070     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3071
3072     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3073     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3074
3075     select STDERR; $| = 1;      # make unbuffered
3076     select STDOUT; $| = 1;      # make unbuffered
3077
3078     print STDOUT "stdout 1\n";  # this works for
3079     print STDERR "stderr 1\n";  # subprocesses too
3080
3081     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3082     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3083
3084     print STDOUT "stdout 2\n";
3085     print STDERR "stderr 2\n";
3086
3087 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3088 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3089 that file descriptor (and not call L<dup(2)>); this is more
3090 parsimonious of file descriptors.  For example:
3091
3092     # open for input, reusing the fileno of $fd
3093     open(FILEHANDLE, "<&=$fd")
3094
3095 or
3096
3097     open(FILEHANDLE, "<&=", $fd)
3098
3099 or
3100
3101     # open for append, using the fileno of OLDFH
3102     open(FH, ">>&=", OLDFH)
3103
3104 or
3105
3106     open(FH, ">>&=OLDFH")
3107
3108 Being parsimonious on filehandles is also useful (besides being
3109 parsimonious) for example when something is dependent on file
3110 descriptors, like for example locking using flock().  If you do just
3111 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3112 descriptor as B, and therefore flock(A) will not flock(B), and vice
3113 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3114 the same file descriptor.
3115
3116 Note that if you are using Perls older than 5.8.0, Perl will be using
3117 the standard C libraries' fdopen() to implement the "=" functionality.
3118 On many UNIX systems fdopen() fails when file descriptors exceed a
3119 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3120 most often the default.
3121
3122 You can see whether Perl has been compiled with PerlIO or not by
3123 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3124 is C<define>, you have PerlIO, otherwise you don't.
3125
3126 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3127 with 2-arguments (or 1-argument) form of open(), then
3128 there is an implicit fork done, and the return value of open is the pid
3129 of the child within the parent process, and C<0> within the child
3130 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3131 The filehandle behaves normally for the parent, but i/o to that
3132 filehandle is piped from/to the STDOUT/STDIN of the child process.
3133 In the child process the filehandle isn't opened--i/o happens from/to
3134 the new STDOUT or STDIN.  Typically this is used like the normal
3135 piped open when you want to exercise more control over just how the
3136 pipe command gets executed, such as when you are running setuid, and
3137 don't want to have to scan shell commands for metacharacters.
3138 The following triples are more or less equivalent:
3139
3140     open(FOO, "|tr '[a-z]' '[A-Z]'");
3141     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3142     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3143     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3144
3145     open(FOO, "cat -n '$file'|");
3146     open(FOO, '-|', "cat -n '$file'");
3147     open(FOO, '-|') || exec 'cat', '-n', $file;
3148     open(FOO, '-|', "cat", '-n', $file);
3149
3150 The last example in each block shows the pipe as "list form", which is
3151 not yet supported on all platforms.  A good rule of thumb is that if
3152 your platform has true C<fork()> (in other words, if your platform is
3153 UNIX) you can use the list form.
3154
3155 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3156
3157 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3158 output before any operation that may do a fork, but this may not be
3159 supported on some platforms (see L<perlport>).  To be safe, you may need
3160 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3161 of C<IO::Handle> on any open handles.
3162
3163 On systems that support a close-on-exec flag on files, the flag will
3164 be set for the newly opened file descriptor as determined by the value
3165 of $^F.  See L<perlvar/$^F>.
3166
3167 Closing any piped filehandle causes the parent process to wait for the
3168 child to finish, and returns the status value in C<$?> and
3169 C<${^CHILD_ERROR_NATIVE}>.
3170
3171 The filename passed to 2-argument (or 1-argument) form of open() will
3172 have leading and trailing whitespace deleted, and the normal
3173 redirection characters honored.  This property, known as "magic open",
3174 can often be used to good effect.  A user could specify a filename of
3175 F<"rsh cat file |">, or you could change certain filenames as needed:
3176
3177     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3178     open(FH, $filename) or die "Can't open $filename: $!";
3179
3180 Use 3-argument form to open a file with arbitrary weird characters in it,
3181
3182     open(FOO, '<', $file);
3183
3184 otherwise it's necessary to protect any leading and trailing whitespace:
3185
3186     $file =~ s#^(\s)#./$1#;
3187     open(FOO, "< $file\0");
3188
3189 (this may not work on some bizarre filesystems).  One should
3190 conscientiously choose between the I<magic> and 3-arguments form
3191 of open():
3192
3193     open IN, $ARGV[0];
3194
3195 will allow the user to specify an argument of the form C<"rsh cat file |">,
3196 but will not work on a filename which happens to have a trailing space, while
3197
3198     open IN, '<', $ARGV[0];
3199
3200 will have exactly the opposite restrictions.
3201
3202 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3203 should use the C<sysopen> function, which involves no such magic (but
3204 may use subtly different filemodes than Perl open(), which is mapped
3205 to C fopen()).  This is
3206 another way to protect your filenames from interpretation.  For example:
3207
3208     use IO::Handle;
3209     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3210         or die "sysopen $path: $!";
3211     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3212     print HANDLE "stuff $$\n";
3213     seek(HANDLE, 0, 0);
3214     print "File contains: ", <HANDLE>;
3215
3216 Using the constructor from the C<IO::Handle> package (or one of its
3217 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3218 filehandles that have the scope of whatever variables hold references to
3219 them, and automatically close whenever and however you leave that scope:
3220
3221     use IO::File;
3222     #...
3223     sub read_myfile_munged {
3224         my $ALL = shift;
3225         my $handle = new IO::File;
3226         open($handle, "myfile") or die "myfile: $!";
3227         $first = <$handle>
3228             or return ();     # Automatically closed here.
3229         mung $first or die "mung failed";       # Or here.
3230         return $first, <$handle> if $ALL;       # Or here.
3231         $first;                                 # Or here.
3232     }
3233
3234 See L</seek> for some details about mixing reading and writing.
3235
3236 =item opendir DIRHANDLE,EXPR
3237
3238 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3239 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3240 DIRHANDLE may be an expression whose value can be used as an indirect
3241 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3242 scalar variable (or array or hash element), the variable is assigned a
3243 reference to a new anonymous dirhandle.
3244 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3245
3246 =item ord EXPR
3247
3248 =item ord
3249
3250 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3251 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3252 uses C<$_>.
3253
3254 For the reverse, see L</chr>.
3255 See L<perlunicode> and L<encoding> for more about Unicode.
3256
3257 =item our EXPR
3258
3259 =item our EXPR TYPE
3260
3261 =item our EXPR : ATTRS
3262
3263 =item our TYPE EXPR : ATTRS
3264
3265 C<our> associates a simple name with a package variable in the current
3266 package for the remander of the lexical scope.  The listed variables
3267 are declared to be valid globals within the enclosing block, file, or
3268 C<eval>.  That is, it has the same scoping rules as a "my"
3269 declaration, but does not create a local variable.  When C<use strict
3270 'vars'> is in effect, the C<our> declaration lets you use the declared
3271 global variable without qualifying it with a package name.  (But only
3272 within the lexical scope of the C<our> declaration.  In this it
3273 differs from "use vars", which is package scoped.)
3274
3275 If more than one value is listed, the list must be placed in
3276 parentheses.
3277
3278     our $foo;
3279     our($bar, $baz);
3280
3281 An C<our> declaration declares a global variable that will be visible
3282 across its entire lexical scope, even across package boundaries.  The
3283 package in which the variable is entered is determined at the point
3284 of the declaration, not at the point of use.  This means the following
3285 behavior holds:
3286
3287     package Foo;
3288     our $bar;           # declares $Foo::bar for rest of lexical scope
3289     $bar = 20;
3290
3291     package Bar;
3292     print $bar;         # prints 20 as it refers to $Foo::bar
3293
3294 Multiple C<our> declarations in the same lexical scope are allowed
3295 if they are in different packages.  If they happen to be in the same
3296 package, Perl will emit warnings if you have asked for them.
3297
3298     use warnings;
3299     package Foo;
3300     our $bar;           # declares $Foo::bar for rest of lexical scope
3301     $bar = 20;
3302
3303     package Bar;
3304     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3305     print $bar;         # prints 30
3306
3307     our $bar;           # emits warning
3308
3309 An C<our> declaration may also have a list of attributes associated
3310 with it.
3311
3312 The exact semantics and interface of TYPE and ATTRS are still
3313 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3314 and attributes are handled using the C<attributes> pragma, or starting
3315 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3316 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3317 L<attributes>, and L<Attribute::Handlers>.
3318
3319 The only currently recognized C<our()> attribute is C<unique> which
3320 indicates that a single copy of the global is to be used by all
3321 interpreters should the program happen to be running in a
3322 multi-interpreter environment. (The default behaviour would be for
3323 each interpreter to have its own copy of the global.)  Examples:
3324
3325     our @EXPORT : unique = qw(foo);
3326     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3327     our $VERSION : unique = "1.00";
3328
3329 Note that this attribute also has the effect of making the global
3330 readonly when the first new interpreter is cloned (for example,
3331 when the first new thread is created).
3332
3333 Multi-interpreter environments can come to being either through the
3334 fork() emulation on Windows platforms, or by embedding perl in a
3335 multi-threaded application.  The C<unique> attribute does nothing in
3336 all other environments.
3337
3338 Warning: the current implementation of this attribute operates on the
3339 typeglob associated with the variable; this means that C<our $x : unique>
3340 also has the effect of C<our @x : unique; our %x : unique>. This may be
3341 subject to change.
3342
3343 =item pack TEMPLATE,LIST
3344
3345 Takes a LIST of values and converts it into a string using the rules
3346 given by the TEMPLATE.  The resulting string is the concatenation of
3347 the converted values.  Typically, each converted value looks
3348 like its machine-level representation.  For example, on 32-bit machines
3349 an integer may be represented by a sequence of 4 bytes which will be 
3350 converted to a sequence of 4 characters.
3351
3352 The TEMPLATE is a sequence of characters that give the order and type
3353 of values, as follows:
3354
3355     a   A string with arbitrary binary data, will be null padded.
3356     A   A text (ASCII) string, will be space padded.
3357     Z   A null terminated (ASCIZ) string, will be null padded.
3358
3359     b   A bit string (ascending bit order inside each byte, like vec()).
3360     B   A bit string (descending bit order inside each byte).
3361     h   A hex string (low nybble first).
3362     H   A hex string (high nybble first).
3363
3364     c   A signed char (8-bit) value.
3365     C   An unsigned C char (octet) even under Unicode. Should normally not
3366         be used. See U and W instead.
3367     W   An unsigned char value (can be greater than 255).
3368
3369     s   A signed short (16-bit) value.
3370     S   An unsigned short value.
3371
3372     l   A signed long (32-bit) value.
3373     L   An unsigned long value.
3374
3375     q   A signed quad (64-bit) value.
3376     Q   An unsigned quad value.
3377           (Quads are available only if your system supports 64-bit
3378            integer values _and_ if Perl has been compiled to support those.
3379            Causes a fatal error otherwise.)
3380
3381     i   A signed integer value.
3382     I   A unsigned integer value.
3383           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3384            size depends on what a local C compiler calls 'int'.)
3385  
3386     n   An unsigned short (16-bit) in "network" (big-endian) order.
3387     N   An unsigned long (32-bit) in "network" (big-endian) order.
3388     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3389     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3390
3391     j   A Perl internal signed integer value (IV).
3392     J   A Perl internal unsigned integer value (UV).
3393
3394     f   A single-precision float in the native format.
3395     d   A double-precision float in the native format.
3396
3397     F   A Perl internal floating point value (NV) in the native format
3398     D   A long double-precision float in the native format.
3399           (Long doubles are available only if your system supports long
3400            double values _and_ if Perl has been compiled to support those.
3401            Causes a fatal error otherwise.)
3402
3403     p   A pointer to a null-terminated string.
3404     P   A pointer to a structure (fixed-length string).
3405
3406     u   A uuencoded string.
3407     U   A Unicode character number.  Encodes to UTF-8 internally
3408         (or UTF-EBCDIC in EBCDIC platforms).
3409
3410     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3411         details).  Its bytes represent an unsigned integer in base 128,
3412         most significant digit first, with as few digits as possible.  Bit
3413         eight (the high bit) is set on each byte except the last.
3414
3415     x   A null byte.
3416     X   Back up a byte.
3417     @   Null fill or truncate to absolute position, counted from the
3418         start of the innermost ()-group.
3419     .   Null fill or truncate to absolute position specified by value.
3420     (   Start of a ()-group.
3421
3422 Some letters in the TEMPLATE may optionally be followed by one or
3423 more of these modifiers (the second column lists the letters for
3424 which the modifier is valid):
3425
3426     !   sSlLiI     Forces native (short, long, int) sizes instead
3427                    of fixed (16-/32-bit) sizes.
3428
3429         xX         Make x and X act as alignment commands.
3430
3431         nNvV       Treat integers as signed instead of unsigned.
3432
3433         @.         Specify position as byte offset in the internal
3434                    representation of the packed string. Efficient but
3435                    dangerous.
3436
3437     >   sSiIlLqQ   Force big-endian byte-order on the type.
3438         jJfFdDpP   (The "big end" touches the construct.)
3439
3440     <   sSiIlLqQ   Force little-endian byte-order on the type.
3441         jJfFdDpP   (The "little end" touches the construct.)
3442
3443 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3444 in which case they force a certain byte-order on all components of
3445 that group, including subgroups.
3446
3447 The following rules apply:
3448
3449 =over 8
3450
3451 =item *
3452
3453 Each letter may optionally be followed by a number giving a repeat
3454 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3455 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3456 that many values from the LIST.  A C<*> for the repeat count means to
3457 use however many items are left, except for C<@>, C<x>, C<X>, where it
3458 is equivalent to C<0>, for <.> where it means relative to string start
3459 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3460 A numeric repeat count may optionally be enclosed in brackets, as in
3461 C<pack 'C[80]', @arr>.
3462
3463 One can replace the numeric repeat count by a template enclosed in brackets;
3464 then the packed length of this template in bytes is used as a count.
3465 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3466 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3467 If the template in brackets contains alignment commands (such as C<x![d]>),
3468 its packed length is calculated as if the start of the template has the maximal
3469 possible alignment.
3470
3471 When used with C<Z>, C<*> results in the addition of a trailing null
3472 byte (so the packed result will be one longer than the byte C<length>
3473 of the item).
3474
3475 When used with C<@>, the repeat count represents an offset from the start
3476 of the innermost () group.
3477
3478 When used with C<.>, the repeat count is used to determine the starting
3479 position from where the value offset is calculated. If the repeat count
3480 is 0, it's relative to the current position. If the repeat count is C<*>,
3481 the offset is relative to the start of the packed string. And if its an
3482 integer C<n> the offset is relative to the start of the n-th innermost
3483 () group (or the start of the string if C<n> is bigger then the group
3484 level).
3485
3486 The repeat count for C<u> is interpreted as the maximal number of bytes
3487 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3488 count should not be more than 65.
3489
3490 =item *
3491
3492 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3493 string of length count, padding with nulls or spaces as necessary.  When
3494 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3495 after the first null, and C<a> returns data verbatim.
3496
3497 If the value-to-pack is too long, it is truncated.  If too long and an
3498 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3499 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3500 count is 0).
3501
3502 =item *
3503
3504 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3505 Each character of the input field of pack() generates 1 bit of the result.
3506 Each result bit is based on the least-significant bit of the corresponding
3507 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3508 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3509
3510 Starting from the beginning of the input string of pack(), each 8-tuple
3511 of characters is converted to 1 character of output.  With format C<b>
3512 the first character of the 8-tuple determines the least-significant bit of a
3513 character, and with format C<B> it determines the most-significant bit of
3514 a character.
3515
3516 If the length of the input string is not exactly divisible by 8, the
3517 remainder is packed as if the input string were padded by null characters
3518 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3519
3520 If the input string of pack() is longer than needed, extra characters are 
3521 ignored. A C<*> for the repeat count of pack() means to use all the 
3522 characters of the input field.  On unpack()ing the bits are converted to a 
3523 string of C<"0">s and C<"1">s.
3524
3525 =item *
3526
3527 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3528 representable as hexadecimal digits, 0-9a-f) long.
3529
3530 Each character of the input field of pack() generates 4 bits of the result.
3531 For non-alphabetical characters the result is based on the 4 least-significant
3532 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3533 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3534 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3535 is compatible with the usual hexadecimal digits, so that C<"a"> and
3536 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3537 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3538
3539 Starting from the beginning of the input string of pack(), each pair
3540 of characters is converted to 1 character of output.  With format C<h> the
3541 first character of the pair determines the least-significant nybble of the
3542 output character, and with format C<H> it determines the most-significant
3543 nybble.
3544
3545 If the length of the input string is not even, it behaves as if padded
3546 by a null character at the end.  Similarly, during unpack()ing the "extra"
3547 nybbles are ignored.
3548
3549 If the input string of pack() is longer than needed, extra characters are
3550 ignored.
3551 A C<*> for the repeat count of pack() means to use all the characters of
3552 the input field.  On unpack()ing the nybbles are converted to a string
3553 of hexadecimal digits.
3554
3555 =item *
3556
3557 The C<p> type packs a pointer to a null-terminated string.  You are
3558 responsible for ensuring the string is not a temporary value (which can
3559 potentially get deallocated before you get around to using the packed result).
3560 The C<P> type packs a pointer to a structure of the size indicated by the
3561 length.  A NULL pointer is created if the corresponding value for C<p> or
3562 C<P> is C<undef>, similarly for unpack().
3563
3564 If your system has a strange pointer size (i.e. a pointer is neither as
3565 big as an int nor as big as a long), it may not be possible to pack or
3566 unpack pointers in big- or little-endian byte order.  Attempting to do
3567 so will result in a fatal error.
3568
3569 =item *
3570
3571 The C</> template character allows packing and unpacking of a sequence of
3572 items where the packed structure contains a packed item count followed by 
3573 the packed items themselves.
3574 You write I<length-item>C</>I<sequence-item>.
3575
3576 The I<length-item> can be any C<pack> template letter, and describes
3577 how the length value is packed.  The ones likely to be of most use are
3578 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3579 SNMP) and C<N> (for Sun XDR).
3580
3581 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3582 the minimum of that and the number of available items is used as argument
3583 for the I<length-item>. If it has no repeat count or uses a '*', the number
3584 of available items is used. For C<unpack> the repeat count is always obtained
3585 by decoding the packed item count, and the I<sequence-item> must not have a
3586 repeat count.
3587
3588 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3589 the I<length-item> is a string length, not a number of strings. If there is
3590 an explicit repeat count for pack, the packed string will be adjusted to that
3591 given length.
3592
3593     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3594     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3595     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3596     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3597
3598 The I<length-item> is not returned explicitly from C<unpack>.
3599
3600 Adding a count to the I<length-item> letter is unlikely to do anything
3601 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3602 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3603 which Perl does not regard as legal in numeric strings.
3604
3605 =item *
3606
3607 The integer types C<s>, C<S>, C<l>, and C<L> may be
3608 followed by a C<!> modifier to signify native shorts or
3609 longs--as you can see from above for example a bare C<l> does mean
3610 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3611 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3612 see whether using C<!> makes any difference by
3613
3614         print length(pack("s")), " ", length(pack("s!")), "\n";
3615         print length(pack("l")), " ", length(pack("l!")), "\n";
3616
3617 C<i!> and C<I!> also work but only because of completeness;
3618 they are identical to C<i> and C<I>.
3619
3620 The actual sizes (in bytes) of native shorts, ints, longs, and long
3621 longs on the platform where Perl was built are also available via
3622 L<Config>:
3623
3624        use Config;
3625        print $Config{shortsize},    "\n";
3626        print $Config{intsize},      "\n";
3627        print $Config{longsize},     "\n";
3628        print $Config{longlongsize}, "\n";
3629
3630 (The C<$Config{longlongsize}> will be undefined if your system does
3631 not support long longs.)
3632
3633 =item *
3634
3635 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3636 are inherently non-portable between processors and operating systems
3637 because they obey the native byteorder and endianness.  For example a
3638 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3639 (arranged in and handled by the CPU registers) into bytes as
3640
3641         0x12 0x34 0x56 0x78     # big-endian
3642         0x78 0x56 0x34 0x12     # little-endian
3643
3644 Basically, the Intel and VAX CPUs are little-endian, while everybody
3645 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3646 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3647 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3648 mode.
3649
3650 The names `big-endian' and `little-endian' are comic references to
3651 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3652 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3653 the egg-eating habits of the Lilliputians.
3654
3655 Some systems may have even weirder byte orders such as
3656
3657         0x56 0x78 0x12 0x34
3658         0x34 0x12 0x78 0x56
3659
3660 You can see your system's preference with
3661
3662         print join(" ", map { sprintf "%#02x", $_ }
3663                             unpack("W*",pack("L",0x12345678))), "\n";
3664
3665 The byteorder on the platform where Perl was built is also available
3666 via L<Config>:
3667
3668         use Config;
3669         print $Config{byteorder}, "\n";
3670
3671 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3672 and C<'87654321'> are big-endian.
3673
3674 If you want portable packed integers you can either use the formats
3675 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3676 modifiers.  These modifiers are only available as of perl 5.9.2.
3677 See also L<perlport>.
3678
3679 =item *
3680
3681 All integer and floating point formats as well as C<p> and C<P> and
3682 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3683 to force big- or little- endian byte-order, respectively.
3684 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3685 signed integers, 64-bit integers and floating point values.  However,
3686 there are some things to keep in mind.
3687
3688 Exchanging signed integers between different platforms only works
3689 if all platforms store them in the same format.  Most platforms store
3690 signed integers in two's complement, so usually this is not an issue.
3691
3692 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3693 formats on big- or little-endian machines.  Otherwise, attempting to
3694 do so will result in a fatal error.
3695
3696 Forcing big- or little-endian byte-order on floating point values for
3697 data exchange can only work if all platforms are using the same
3698 binary representation (e.g. IEEE floating point format).  Even if all
3699 platforms are using IEEE, there may be subtle differences.  Being able
3700 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3701 but also very dangerous if you don't know exactly what you're doing.
3702 It is definetely not a general way to portably store floating point
3703 values.
3704
3705 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3706 all types inside the group that accept the byte-order modifiers,
3707 including all subgroups.  It will silently be ignored for all other
3708 types.  You are not allowed to override the byte-order within a group
3709 that already has a byte-order modifier suffix.
3710
3711 =item *
3712
3713 Real numbers (floats and doubles) are in the native machine format only;
3714 due to the multiplicity of floating formats around, and the lack of a
3715 standard "network" representation, no facility for interchange has been
3716 made.  This means that packed floating point data written on one machine
3717 may not be readable on another - even if both use IEEE floating point
3718 arithmetic (as the endian-ness of the memory representation is not part
3719 of the IEEE spec).  See also L<perlport>.
3720
3721 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3722 modifiers to force big- or little-endian byte-order on floating point values.
3723
3724 Note that Perl uses doubles (or long doubles, if configured) internally for
3725 all numeric calculation, and converting from double into float and thence back
3726 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3727 will not in general equal $foo).
3728
3729 =item *
3730
3731 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3732 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3733 where the packed string is processed in its UTF-8-encoded Unicode form on
3734 a byte by byte basis. Character mode is the default unless the format string 
3735 starts with an C<U>. You can switch mode at any moment with an explicit 
3736 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3737 or until the end of the ()-group in which it was entered.
3738
3739 =item *
3740
3741 You must yourself do any alignment or padding by inserting for example
3742 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3743 could know where the characters are going to or coming from.  Therefore
3744 C<pack> (and C<unpack>) handle their output and input as flat
3745 sequences of characters.
3746
3747 =item *
3748
3749 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3750 take a repeat count, both as postfix, and for unpack() also via the C</>
3751 template character. Within each repetition of a group, positioning with
3752 C<@> starts again at 0. Therefore, the result of
3753
3754     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3755
3756 is the string "\0a\0\0bc".
3757
3758 =item *
3759
3760 C<x> and C<X> accept C<!> modifier.  In this case they act as
3761 alignment commands: they jump forward/back to the closest position
3762 aligned at a multiple of C<count> characters. For example, to pack() or
3763 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3764 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3765 aligned on the double's size.
3766
3767 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3768 both result in no-ops.
3769
3770 =item *
3771
3772 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3773 will represent signed 16-/32-bit integers in big-/little-endian order.
3774 This is only portable if all platforms sharing the packed data use the
3775 same binary representation for signed integers (e.g. all platforms are
3776 using two's complement representation).
3777
3778 =item *
3779
3780 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3781 White space may be used to separate pack codes from each other, but
3782 modifiers and a repeat count must follow immediately.
3783
3784 =item *
3785
3786 If TEMPLATE requires more arguments to pack() than actually given, pack()
3787 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3788 to pack() than actually given, extra arguments are ignored.
3789
3790 =back
3791
3792 Examples:
3793
3794     $foo = pack("WWWW",65,66,67,68);
3795     # foo eq "ABCD"
3796     $foo = pack("W4",65,66,67,68);
3797     # same thing
3798     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3799     # same thing with Unicode circled letters.
3800     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3801     # same thing with Unicode circled letters. You don't get the UTF-8
3802     # bytes because the U at the start of the format caused a switch to
3803     # U0-mode, so the UTF-8 bytes get joined into characters
3804     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3805     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3806     # This is the UTF-8 encoding of the string in the previous example
3807
3808     $foo = pack("ccxxcc",65,66,67,68);
3809     # foo eq "AB\0\0CD"
3810
3811     # note: the above examples featuring "W" and "c" are true
3812     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3813     # and UTF-8.  In EBCDIC the first example would be
3814     # $foo = pack("WWWW",193,194,195,196);
3815
3816     $foo = pack("s2",1,2);
3817     # "\1\0\2\0" on little-endian
3818     # "\0\1\0\2" on big-endian
3819
3820     $foo = pack("a4","abcd","x","y","z");
3821     # "abcd"
3822
3823     $foo = pack("aaaa","abcd","x","y","z");
3824     # "axyz"
3825
3826     $foo = pack("a14","abcdefg");
3827     # "abcdefg\0\0\0\0\0\0\0"
3828
3829     $foo = pack("i9pl", gmtime);
3830     # a real struct tm (on my system anyway)
3831
3832     $utmp_template = "Z8 Z8 Z16 L";
3833     $utmp = pack($utmp_template, @utmp1);
3834     # a struct utmp (BSDish)
3835
3836     @utmp2 = unpack($utmp_template, $utmp);
3837     # "@utmp1" eq "@utmp2"
3838
3839     sub bintodec {
3840         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3841     }
3842
3843     $foo = pack('sx2l', 12, 34);
3844     # short 12, two zero bytes padding, long 34
3845     $bar = pack('s@4l', 12, 34);
3846     # short 12, zero fill to position 4, long 34
3847     # $foo eq $bar
3848     $baz = pack('s.l', 12, 4, 34);
3849     # short 12, zero fill to position 4, long 34
3850
3851     $foo = pack('nN', 42, 4711);
3852     # pack big-endian 16- and 32-bit unsigned integers
3853     $foo = pack('S>L>', 42, 4711);
3854     # exactly the same
3855     $foo = pack('s<l<', -42, 4711);
3856     # pack little-endian 16- and 32-bit signed integers
3857     $foo = pack('(sl)<', -42, 4711);
3858     # exactly the same
3859
3860 The same template may generally also be used in unpack().
3861
3862 =item package NAMESPACE
3863
3864 =item package
3865
3866 Declares the compilation unit as being in the given namespace.  The scope
3867 of the package declaration is from the declaration itself through the end
3868 of the enclosing block, file, or eval (the same as the C<my> operator).
3869 All further unqualified dynamic identifiers will be in this namespace.
3870 A package statement affects only dynamic variables--including those
3871 you've used C<local> on--but I<not> lexical variables, which are created
3872 with C<my>.  Typically it would be the first declaration in a file to
3873 be included by the C<require> or C<use> operator.  You can switch into a
3874 package in more than one place; it merely influences which symbol table
3875 is used by the compiler for the rest of that block.  You can refer to
3876 variables and filehandles in other packages by prefixing the identifier
3877 with the package name and a double colon:  C<$Package::Variable>.
3878 If the package name is null, the C<main> package as assumed.  That is,
3879 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3880 still seen in older code).
3881
3882 If NAMESPACE is omitted, then there is no current package, and all
3883 identifiers must be fully qualified or lexicals.  However, you are
3884 strongly advised not to make use of this feature. Its use can cause
3885 unexpected behaviour, even crashing some versions of Perl. It is
3886 deprecated, and will be removed from a future release.
3887
3888 See L<perlmod/"Packages"> for more information about packages, modules,
3889 and classes.  See L<perlsub> for other scoping issues.
3890
3891 =item pipe READHANDLE,WRITEHANDLE
3892
3893 Opens a pair of connected pipes like the corresponding system call.
3894 Note that if you set up a loop of piped processes, deadlock can occur
3895 unless you are very careful.  In addition, note that Perl's pipes use
3896 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3897 after each command, depending on the application.
3898
3899 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3900 for examples of such things.
3901
3902 On systems that support a close-on-exec flag on files, the flag will be set
3903 for the newly opened file descriptors as determined by the value of $^F.
3904 See L<perlvar/$^F>.
3905
3906 =item pop ARRAY
3907
3908 =item pop
3909
3910 Pops and returns the last value of the array, shortening the array by
3911 one element.  Has an effect similar to
3912
3913     $ARRAY[$#ARRAY--]
3914
3915 If there are no elements in the array, returns the undefined value
3916 (although this may happen at other times as well).  If ARRAY is
3917 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3918 array in subroutines, just like C<shift>.
3919
3920 =item pos SCALAR
3921
3922 =item pos
3923
3924 Returns the offset of where the last C<m//g> search left off for the variable
3925 in question (C<$_> is used when the variable is not specified).  Note that
3926 0 is a valid match offset, while C<undef> indicates that the search position
3927 is reset (usually due to match failure, but can also be because no match has
3928 yet been performed on the scalar). C<pos> directly accesses the location used
3929 by the regexp engine to store the offset, so assigning to C<pos> will change
3930 that offset, and so will also influence the C<\G> zero-width assertion in
3931 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
3932 the return from C<pos> won't change either in this case.  See L<perlre> and
3933 L<perlop>.
3934
3935 =item print FILEHANDLE LIST
3936
3937 =item print LIST
3938
3939 =item print
3940
3941 Prints a string or a list of strings.  Returns true if successful.
3942 FILEHANDLE may be a scalar variable name, in which case the variable
3943 contains the name of or a reference to the filehandle, thus introducing
3944 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3945 the next token is a term, it may be misinterpreted as an operator
3946 unless you interpose a C<+> or put parentheses around the arguments.)
3947 If FILEHANDLE is omitted, prints by default to standard output (or
3948 to the last selected output channel--see L</select>).  If LIST is
3949 also omitted, prints C<$_> to the currently selected output channel.
3950 To set the default output channel to something other than STDOUT
3951 use the select operation.  The current value of C<$,> (if any) is
3952 printed between each LIST item.  The current value of C<$\> (if
3953 any) is printed after the entire LIST has been printed.  Because
3954 print takes a LIST, anything in the LIST is evaluated in list
3955 context, and any subroutine that you call will have one or more of
3956 its expressions evaluated in list context.  Also be careful not to
3957 follow the print keyword with a left parenthesis unless you want
3958 the corresponding right parenthesis to terminate the arguments to
3959 the print--interpose a C<+> or put parentheses around all the
3960 arguments.
3961
3962 Note that if you're storing FILEHANDLEs in an array, or if you're using
3963 any other expression more complex than a scalar variable to retrieve it,
3964 you will have to use a block returning the filehandle value instead:
3965
3966     print { $files[$i] } "stuff\n";
3967     print { $OK ? STDOUT : STDERR } "stuff\n";
3968
3969 =item printf FILEHANDLE FORMAT, LIST
3970
3971 =item printf FORMAT, LIST
3972
3973 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3974 (the output record separator) is not appended.  The first argument
3975 of the list will be interpreted as the C<printf> format. See C<sprintf>
3976 for an explanation of the format argument. If C<use locale> is in effect,
3977 the character used for the decimal point in formatted real numbers is
3978 affected by the LC_NUMERIC locale.  See L<perllocale>.
3979
3980 Don't fall into the trap of using a C<printf> when a simple
3981 C<print> would do.  The C<print> is more efficient and less
3982 error prone.
3983
3984 =item prototype FUNCTION
3985
3986 Returns the prototype of a function as a string (or C<undef> if the
3987 function has no prototype).  FUNCTION is a reference to, or the name of,
3988 the function whose prototype you want to retrieve.
3989
3990 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3991 name for Perl builtin.  If the builtin is not I<overridable> (such as
3992 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3993 C<system>) returns C<undef> because the builtin does not really behave
3994 like a Perl function.  Otherwise, the string describing the equivalent
3995 prototype is returned.
3996
3997 =item push ARRAY,LIST
3998
3999 Treats ARRAY as a stack, and pushes the values of LIST
4000 onto the end of ARRAY.  The length of ARRAY increases by the length of
4001 LIST.  Has the same effect as
4002
4003     for $value (LIST) {
4004         $ARRAY[++$#ARRAY] = $value;
4005     }
4006
4007 but is more efficient.  Returns the new number of elements in the array.
4008
4009 =item q/STRING/
4010
4011 =item qq/STRING/
4012
4013 =item qr/STRING/
4014
4015 =item qx/STRING/
4016
4017 =item qw/STRING/
4018
4019 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4020
4021 =item quotemeta EXPR
4022
4023 =item quotemeta
4024
4025 Returns the value of EXPR with all non-"word"
4026 characters backslashed.  (That is, all characters not matching
4027 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4028 returned string, regardless of any locale settings.)
4029 This is the internal function implementing
4030 the C<\Q> escape in double-quoted strings.
4031
4032 If EXPR is omitted, uses C<$_>.
4033
4034 =item rand EXPR
4035
4036 =item rand
4037
4038 Returns a random fractional number greater than or equal to C<0> and less
4039 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4040 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4041 also special-cased as C<1> - this has not been documented before perl 5.8.0
4042 and is subject to change in future versions of perl.  Automatically calls
4043 C<srand> unless C<srand> has already been called.  See also C<srand>.
4044
4045 Apply C<int()> to the value returned by C<rand()> if you want random
4046 integers instead of random fractional numbers.  For example,
4047
4048     int(rand(10))
4049
4050 returns a random integer between C<0> and C<9>, inclusive.
4051
4052 (Note: If your rand function consistently returns numbers that are too
4053 large or too small, then your version of Perl was probably compiled
4054 with the wrong number of RANDBITS.)
4055
4056 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4057
4058 =item read FILEHANDLE,SCALAR,LENGTH
4059
4060 Attempts to read LENGTH I<characters> of data into variable SCALAR
4061 from the specified FILEHANDLE.  Returns the number of characters
4062 actually read, C<0> at end of file, or undef if there was an error (in
4063 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4064 so that the last character actually read is the last character of the
4065 scalar after the read.
4066
4067 An OFFSET may be specified to place the read data at some place in the
4068 string other than the beginning.  A negative OFFSET specifies
4069 placement at that many characters counting backwards from the end of
4070 the string.  A positive OFFSET greater than the length of SCALAR
4071 results in the string being padded to the required size with C<"\0">
4072 bytes before the result of the read is appended.
4073
4074 The call is actually implemented in terms of either Perl's or system's
4075 fread() call.  To get a true read(2) system call, see C<sysread>.
4076
4077 Note the I<characters>: depending on the status of the filehandle,
4078 either (8-bit) bytes or characters are read.  By default all
4079 filehandles operate on bytes, but for example if the filehandle has
4080 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4081 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4082 characters, not bytes.  Similarly for the C<:encoding> pragma:
4083 in that case pretty much any characters can be read.
4084
4085 =item readdir DIRHANDLE
4086
4087 Returns the next directory entry for a directory opened by C<opendir>.
4088 If used in list context, returns all the rest of the entries in the
4089 directory.  If there are no more entries, returns an undefined value in
4090 scalar context or a null list in list context.
4091
4092 If you're planning to filetest the return values out of a C<readdir>, you'd
4093 better prepend the directory in question.  Otherwise, because we didn't
4094 C<chdir> there, it would have been testing the wrong file.
4095
4096     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4097     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4098     closedir DIR;
4099
4100 =item readline EXPR
4101
4102 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4103 context, each call reads and returns the next line, until end-of-file is
4104 reached, whereupon the subsequent call returns undef.  In list context,
4105 reads until end-of-file is reached and returns a list of lines.  Note that
4106 the notion of "line" used here is however you may have defined it
4107 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4108
4109 When C<$/> is set to C<undef>, when readline() is in scalar
4110 context (i.e. file slurp mode), and when an empty file is read, it
4111 returns C<''> the first time, followed by C<undef> subsequently.
4112
4113 This is the internal function implementing the C<< <EXPR> >>
4114 operator, but you can use it directly.  The C<< <EXPR> >>
4115 operator is discussed in more detail in L<perlop/"I/O Operators">.
4116
4117     $line = <STDIN>;
4118     $line = readline(*STDIN);           # same thing
4119
4120 If readline encounters an operating system error, C<$!> will be set with the
4121 corresponding error message.  It can be helpful to check C<$!> when you are
4122 reading from filehandles you don't trust, such as a tty or a socket.  The
4123 following example uses the operator form of C<readline>, and takes the necessary
4124 steps to ensure that C<readline> was successful.
4125
4126     for (;;) {
4127         undef $!;
4128         unless (defined( $line = <> )) {
4129             die $! if $!;
4130             last; # reached EOF
4131         }
4132         # ...
4133     }
4134
4135 =item readlink EXPR
4136
4137 =item readlink
4138
4139 Returns the value of a symbolic link, if symbolic links are
4140 implemented.  If not, gives a fatal error.  If there is some system
4141 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4142 omitted, uses C<$_>.
4143
4144 =item readpipe EXPR
4145
4146 EXPR is executed as a system command.
4147 The collected standard output of the command is returned.
4148 In scalar context, it comes back as a single (potentially
4149 multi-line) string.  In list context, returns a list of lines
4150 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4151 This is the internal function implementing the C<qx/EXPR/>
4152 operator, but you can use it directly.  The C<qx/EXPR/>
4153 operator is discussed in more detail in L<perlop/"I/O Operators">.
4154
4155 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4156
4157 Receives a message on a socket.  Attempts to receive LENGTH characters
4158 of data into variable SCALAR from the specified SOCKET filehandle.
4159 SCALAR will be grown or shrunk to the length actually read.  Takes the
4160 same flags as the system call of the same name.  Returns the address
4161 of the sender if SOCKET's protocol supports this; returns an empty
4162 string otherwise.  If there's an error, returns the undefined value.
4163 This call is actually implemented in terms of recvfrom(2) system call.
4164 See L<perlipc/"UDP: Message Passing"> for examples.
4165
4166 Note the I<characters>: depending on the status of the socket, either
4167 (8-bit) bytes or characters are received.  By default all sockets
4168 operate on bytes, but for example if the socket has been changed using
4169 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4170 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4171 characters, not bytes.  Similarly for the C<:encoding> pragma:
4172 in that case pretty much any characters can be read.
4173
4174 =item redo LABEL
4175
4176 =item redo
4177
4178 The C<redo> command restarts the loop block without evaluating the
4179 conditional again.  The C<continue> block, if any, is not executed.  If
4180 the LABEL is omitted, the command refers to the innermost enclosing
4181 loop.  This command is normally used by programs that want to lie to
4182 themselves about what was just input:
4183
4184     # a simpleminded Pascal comment stripper
4185     # (warning: assumes no { or } in strings)
4186     LINE: while (<STDIN>) {
4187         while (s|({.*}.*){.*}|$1 |) {}
4188         s|{.*}| |;
4189         if (s|{.*| |) {
4190             $front = $_;
4191             while (<STDIN>) {
4192                 if (/}/) {      # end of comment?
4193                     s|^|$front\{|;
4194                     redo LINE;
4195                 }
4196             }
4197         }
4198         print;
4199     }
4200
4201 C<redo> cannot be used to retry a block which returns a value such as
4202 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4203 a grep() or map() operation.
4204
4205 Note that a block by itself is semantically identical to a loop
4206 that executes once.  Thus C<redo> inside such a block will effectively
4207 turn it into a looping construct.
4208
4209 See also L</continue> for an illustration of how C<last>, C<next>, and
4210 C<redo> work.
4211
4212 =item ref EXPR
4213
4214 =item ref
4215
4216 Returns a non-empty string if EXPR is a reference, the empty
4217 string otherwise. If EXPR
4218 is not specified, C<$_> will be used.  The value returned depends on the
4219 type of thing the reference is a reference to.
4220 Builtin types include:
4221
4222     SCALAR
4223     ARRAY
4224     HASH
4225     CODE
4226     REF
4227     GLOB
4228     LVALUE
4229
4230 If the referenced object has been blessed into a package, then that package
4231 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4232
4233     if (ref($r) eq "HASH") {
4234         print "r is a reference to a hash.\n";
4235     }
4236     unless (ref($r)) {
4237         print "r is not a reference at all.\n";
4238     }
4239
4240 See also L<perlref>.
4241
4242 =item rename OLDNAME,NEWNAME
4243
4244 Changes the name of a file; an existing file NEWNAME will be
4245 clobbered.  Returns true for success, false otherwise.
4246
4247 Behavior of this function varies wildly depending on your system
4248 implementation.  For example, it will usually not work across file system
4249 boundaries, even though the system I<mv> command sometimes compensates
4250 for this.  Other restrictions include whether it works on directories,
4251 open files, or pre-existing files.  Check L<perlport> and either the
4252 rename(2) manpage or equivalent system documentation for details.
4253
4254 =item require VERSION
4255
4256 =item require EXPR
4257
4258 =item require
4259
4260 Demands a version of Perl specified by VERSION, or demands some semantics
4261 specified by EXPR or by C<$_> if EXPR is not supplied.
4262
4263 VERSION may be either a numeric argument such as 5.006, which will be
4264 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4265 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4266 VERSION is greater than the version of the current Perl interpreter.
4267 Compare with L</use>, which can do a similar check at compile time.
4268
4269 Specifying VERSION as a literal of the form v5.6.1 should generally be
4270 avoided, because it leads to misleading error messages under earlier
4271 versions of Perl which do not support this syntax.  The equivalent numeric
4272 version should be used instead.
4273
4274     require v5.6.1;     # run time version check
4275     require 5.6.1;      # ditto
4276     require 5.006_001;  # ditto; preferred for backwards compatibility
4277
4278 Otherwise, demands that a library file be included if it hasn't already
4279 been included.  The file is included via the do-FILE mechanism, which is
4280 essentially just a variety of C<eval>.  Has semantics similar to the
4281 following subroutine:
4282
4283     sub require {
4284        my ($filename) = @_;
4285        if (exists $INC{$filename}) {
4286            return 1 if $INC{$filename};
4287            die "Compilation failed in require";
4288        }
4289        my ($realfilename,$result);
4290        ITER: {
4291            foreach $prefix (@INC) {
4292                $realfilename = "$prefix/$filename";
4293                if (-f $realfilename) {
4294                    $INC{$filename} = $realfilename;
4295                    $result = do $realfilename;
4296                    last ITER;
4297                }
4298            }
4299            die "Can't find $filename in \@INC";
4300        }
4301        if ($@) {
4302            $INC{$filename} = undef;
4303            die $@;
4304        } elsif (!$result) {
4305            delete $INC{$filename};
4306            die "$filename did not return true value";
4307        } else {
4308            return $result;
4309        }
4310     }
4311
4312 Note that the file will not be included twice under the same specified
4313 name.
4314
4315 The file must return true as the last statement to indicate
4316 successful execution of any initialization code, so it's customary to
4317 end such a file with C<1;> unless you're sure it'll return true
4318 otherwise.  But it's better just to put the C<1;>, in case you add more
4319 statements.
4320
4321 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4322 replaces "F<::>" with "F</>" in the filename for you,
4323 to make it easy to load standard modules.  This form of loading of
4324 modules does not risk altering your namespace.
4325
4326 In other words, if you try this:
4327
4328         require Foo::Bar;    # a splendid bareword
4329
4330 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4331 directories specified in the C<@INC> array.
4332
4333 But if you try this:
4334
4335         $class = 'Foo::Bar';
4336         require $class;      # $class is not a bareword
4337     #or
4338         require "Foo::Bar";  # not a bareword because of the ""
4339
4340 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4341 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4342
4343         eval "require $class";
4344
4345 Now that you understand how C<require> looks for files in the case of
4346 a bareword argument, there is a little extra functionality going on
4347 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4348 it will first look for a filename with a "F<.pmc>" extension.  A file
4349 with this extension is assumed to be Perl bytecode generated by
4350 L<B::Bytecode|B::Bytecode>.  If this file is found, and its modification
4351 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4352 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4353
4354 You can also insert hooks into the import facility, by putting directly
4355 Perl code into the @INC array.  There are three forms of hooks: subroutine
4356 references, array references and blessed objects.
4357
4358 Subroutine references are the simplest case.  When the inclusion system
4359 walks through @INC and encounters a subroutine, this subroutine gets
4360 called with two parameters, the first being a reference to itself, and the
4361 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4362 subroutine should return C<undef> or a filehandle, from which the file to
4363 include will be read.  If C<undef> is returned, C<require> will look at
4364 the remaining elements of @INC.
4365
4366 If the hook is an array reference, its first element must be a subroutine
4367 reference.  This subroutine is called as above, but the first parameter is
4368 the array reference.  This enables to pass indirectly some arguments to
4369 the subroutine.
4370
4371 In other words, you can write:
4372
4373     push @INC, \&my_sub;
4374     sub my_sub {
4375         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4376         ...
4377     }
4378
4379 or:
4380
4381     push @INC, [ \&my_sub, $x, $y, ... ];
4382     sub my_sub {
4383         my ($arrayref, $filename) = @_;
4384         # Retrieve $x, $y, ...
4385         my @parameters = @$arrayref[1..$#$arrayref];
4386         ...
4387     }
4388
4389 If the hook is an object, it must provide an INC method, that will be
4390 called as above, the first parameter being the object itself.  (Note that
4391 you must fully qualify the sub's name, as it is always forced into package
4392 C<main>.)  Here is a typical code layout:
4393
4394     # In Foo.pm
4395     package Foo;
4396     sub new { ... }
4397     sub Foo::INC {
4398         my ($self, $filename) = @_;
4399         ...
4400     }
4401
4402     # In the main program
4403     push @INC, new Foo(...);
4404
4405 Note that these hooks are also permitted to set the %INC entry
4406 corresponding to the files they have loaded. See L<perlvar/%INC>.
4407
4408 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4409
4410 =item reset EXPR
4411
4412 =item reset
4413
4414 Generally used in a C<continue> block at the end of a loop to clear
4415 variables and reset C<??> searches so that they work again.  The
4416 expression is interpreted as a list of single characters (hyphens
4417 allowed for ranges).  All variables and arrays beginning with one of
4418 those letters are reset to their pristine state.  If the expression is
4419 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4420 only variables or searches in the current package.  Always returns
4421 1.  Examples:
4422
4423     reset 'X';          # reset all X variables
4424     reset 'a-z';        # reset lower case variables
4425     reset;              # just reset ?one-time? searches
4426
4427 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4428 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4429 variables--lexical variables are unaffected, but they clean themselves
4430 up on scope exit anyway, so you'll probably want to use them instead.
4431 See L</my>.
4432
4433 =item return EXPR
4434
4435 =item return
4436
4437 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4438 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4439 context, depending on how the return value will be used, and the context
4440 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4441 is given, returns an empty list in list context, the undefined value in
4442 scalar context, and (of course) nothing at all in a void context.
4443
4444 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4445 or do FILE will automatically return the value of the last expression
4446 evaluated.)
4447
4448 =item reverse LIST
4449
4450 In list context, returns a list value consisting of the elements
4451 of LIST in the opposite order.  In scalar context, concatenates the
4452 elements of LIST and returns a string value with all characters
4453 in the opposite order.
4454
4455     print reverse <>;           # line tac, last line first
4456
4457     undef $/;                   # for efficiency of <>
4458     print scalar reverse <>;    # character tac, last line tsrif
4459
4460 Used without arguments in scalar context, reverse() reverses C<$_>.
4461
4462 This operator is also handy for inverting a hash, although there are some
4463 caveats.  If a value is duplicated in the original hash, only one of those
4464 can be represented as a key in the inverted hash.  Also, this has to
4465 unwind one hash and build a whole new one, which may take some time
4466 on a large hash, such as from a DBM file.
4467
4468     %by_name = reverse %by_address;     # Invert the hash
4469
4470 =item rewinddir DIRHANDLE
4471
4472 Sets the current position to the beginning of the directory for the
4473 C<readdir> routine on DIRHANDLE.
4474
4475 =item rindex STR,SUBSTR,POSITION
4476
4477 =item rindex STR,SUBSTR
4478
4479 Works just like index() except that it returns the position of the LAST
4480 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4481 last occurrence at or before that position.
4482
4483 =item rmdir FILENAME
4484
4485 =item rmdir
4486
4487 Deletes the directory specified by FILENAME if that directory is
4488 empty.  If it succeeds it returns true, otherwise it returns false and
4489 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4490
4491 =item s///
4492
4493 The substitution operator.  See L<perlop>.
4494
4495 =item scalar EXPR
4496
4497 Forces EXPR to be interpreted in scalar context and returns the value
4498 of EXPR.
4499
4500     @counts = ( scalar @a, scalar @b, scalar @c );
4501
4502 There is no equivalent operator to force an expression to
4503 be interpolated in list context because in practice, this is never
4504 needed.  If you really wanted to do so, however, you could use
4505 the construction C<@{[ (some expression) ]}>, but usually a simple
4506 C<(some expression)> suffices.
4507
4508 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4509 parenthesized list, this behaves as a scalar comma expression, evaluating
4510 all but the last element in void context and returning the final element
4511 evaluated in scalar context.  This is seldom what you want.
4512
4513 The following single statement:
4514
4515         print uc(scalar(&foo,$bar)),$baz;
4516
4517 is the moral equivalent of these two:
4518
4519         &foo;
4520         print(uc($bar),$baz);
4521
4522 See L<perlop> for more details on unary operators and the comma operator.
4523
4524 =item seek FILEHANDLE,POSITION,WHENCE
4525
4526 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4527 FILEHANDLE may be an expression whose value gives the name of the
4528 filehandle.  The values for WHENCE are C<0> to set the new position
4529 I<in bytes> to POSITION, C<1> to set it to the current position plus
4530 POSITION, and C<2> to set it to EOF plus POSITION (typically
4531 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4532 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4533 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4534 otherwise.
4535
4536 Note the I<in bytes>: even if the filehandle has been set to
4537 operate on characters (for example by using the C<:utf8> open
4538 layer), tell() will return byte offsets, not character offsets
4539 (because implementing that would render seek() and tell() rather slow).
4540
4541 If you want to position file for C<sysread> or C<syswrite>, don't use
4542 C<seek>--buffering makes its effect on the file's system position
4543 unpredictable and non-portable.  Use C<sysseek> instead.
4544
4545 Due to the rules and rigors of ANSI C, on some systems you have to do a
4546 seek whenever you switch between reading and writing.  Amongst other
4547 things, this may have the effect of calling stdio's clearerr(3).
4548 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4549
4550     seek(TEST,0,1);
4551
4552 This is also useful for applications emulating C<tail -f>.  Once you hit
4553 EOF on your read, and then sleep for a while, you might have to stick in a
4554 seek() to reset things.  The C<seek> doesn't change the current position,
4555 but it I<does> clear the end-of-file condition on the handle, so that the
4556 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4557
4558 If that doesn't work (some IO implementations are particularly
4559 cantankerous), then you may need something more like this:
4560
4561     for (;;) {
4562         for ($curpos = tell(FILE); $_ = <FILE>;
4563              $curpos = tell(FILE)) {
4564             # search for some stuff and put it into files
4565         }
4566         sleep($for_a_while);
4567         seek(FILE, $curpos, 0);
4568     }
4569
4570 =item seekdir DIRHANDLE,POS
4571
4572 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4573 must be a value returned by C<telldir>.  Has the same caveats about
4574 possible directory compaction as the corresponding system library
4575 routine.
4576
4577 =item select FILEHANDLE
4578
4579 =item select
4580
4581 Returns the currently selected filehandle.  Sets the current default
4582 filehandle for output, if FILEHANDLE is supplied.  This has two
4583 effects: first, a C<write> or a C<print> without a filehandle will
4584 default to this FILEHANDLE.  Second, references to variables related to
4585 output will refer to this output channel.  For example, if you have to
4586 set the top of form format for more than one output channel, you might
4587 do the following:
4588
4589     select(REPORT1);
4590     $^ = 'report1_top';
4591     select(REPORT2);
4592     $^ = 'report2_top';
4593
4594 FILEHANDLE may be an expression whose value gives the name of the
4595 actual filehandle.  Thus:
4596
4597     $oldfh = select(STDERR); $| = 1; select($oldfh);
4598
4599 Some programmers may prefer to think of filehandles as objects with
4600 methods, preferring to write the last example as:
4601
4602     use IO::Handle;
4603     STDERR->autoflush(1);
4604
4605 =item select RBITS,WBITS,EBITS,TIMEOUT
4606
4607 This calls the select(2) system call with the bit masks specified, which
4608 can be constructed using C<fileno> and C<vec>, along these lines:
4609
4610     $rin = $win = $ein = '';
4611     vec($rin,fileno(STDIN),1) = 1;
4612     vec($win,fileno(STDOUT),1) = 1;
4613     $ein = $rin | $win;
4614
4615 If you want to select on many filehandles you might wish to write a
4616 subroutine:
4617
4618     sub fhbits {
4619         my(@fhlist) = split(' ',$_[0]);
4620         my($bits);
4621         for (@fhlist) {
4622             vec($bits,fileno($_),1) = 1;