This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
c452c387056bf44a02e772b97b96c6267c0a1754
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss, plus
3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
4 # on non ASCII-ish platforms need to be skipped
5
6
7 # NOTE:
8 #
9 # Increment ($x++) has a certain amount of cleverness for things like
10 #
11 #   $x = 'zz';
12 #   $x++; # $x eq 'aaa';
13 #
14 # stands more chance of breaking than just a simple
15 #
16 #   $x = $x + 1
17 #
18 # In this file, we use the latter "Baby Perl" approach, and increment
19 # will be worked over by t/op/inc.t
20
21 $Level = 1;
22 my $test = 1;
23 my $planned;
24 my $noplan;
25 my $Perl;       # Safer version of $^X set by which_perl()
26
27 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
28 $::IS_ASCII  = ord 'A' ==  65;
29 $::IS_EBCDIC = ord 'A' == 193;
30
31 $TODO = 0;
32 $NO_ENDING = 0;
33 $Tests_Are_Passing = 1;
34
35 # Use this instead of print to avoid interference while testing globals.
36 sub _print {
37     local($\, $", $,) = (undef, ' ', '');
38     print STDOUT @_;
39 }
40
41 sub _print_stderr {
42     local($\, $", $,) = (undef, ' ', '');
43     print STDERR @_;
44 }
45
46 sub plan {
47     my $n;
48     if (@_ == 1) {
49         $n = shift;
50         if ($n eq 'no_plan') {
51           undef $n;
52           $noplan = 1;
53         }
54     } else {
55         my %plan = @_;
56         $n = $plan{tests};
57     }
58     _print "1..$n\n" unless $noplan;
59     $planned = $n;
60 }
61
62
63 # Set the plan at the end.  See Test::More::done_testing.
64 sub done_testing {
65     my $n = $test - 1;
66     $n = shift if @_;
67
68     _print "1..$n\n";
69     $planned = $n;
70 }
71
72
73 END {
74     my $ran = $test - 1;
75     if (!$NO_ENDING) {
76         if (defined $planned && $planned != $ran) {
77             _print_stderr
78                 "# Looks like you planned $planned tests but ran $ran.\n";
79         } elsif ($noplan) {
80             _print "1..$ran\n";
81         }
82     }
83 }
84
85 sub _diag {
86     return unless @_;
87     my @mess = _comment(@_);
88     $TODO ? _print(@mess) : _print_stderr(@mess);
89 }
90
91 # Use this instead of "print STDERR" when outputting failure diagnostic
92 # messages
93 sub diag {
94     _diag(@_);
95 }
96
97 # Use this instead of "print" when outputting informational messages
98 sub note {
99     return unless @_;
100     _print( _comment(@_) );
101 }
102
103 sub is_miniperl {
104     return !defined &DynaLoader::boot_DynaLoader;
105 }
106
107 sub _comment {
108     return map { /^#/ ? "$_\n" : "# $_\n" }
109            map { split /\n/ } @_;
110 }
111
112 sub _have_dynamic_extension {
113     my $extension = shift;
114     unless (eval {require Config; 1}) {
115         warn "test.pl had problems loading Config: $@";
116         return 1;
117     }
118     $extension =~ s!::!/!g;
119     return 1 if ($Config::Config{extensions} =~ /\b$extension\b/);
120 }
121
122 sub skip_all {
123     if (@_) {
124         _print "1..0 # Skip @_\n";
125     } else {
126         _print "1..0\n";
127     }
128     exit(0);
129 }
130
131 sub skip_all_if_miniperl {
132     skip_all(@_) if is_miniperl();
133 }
134
135 sub skip_all_without_dynamic_extension {
136     my ($extension) = @_;
137     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
138     return if &_have_dynamic_extension;
139     skip_all("$extension was not built");
140 }
141
142 sub skip_all_without_perlio {
143     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
144 }
145
146 sub skip_all_without_config {
147     unless (eval {require Config; 1}) {
148         warn "test.pl had problems loading Config: $@";
149         return;
150     }
151     foreach (@_) {
152         next if $Config::Config{$_};
153         my $key = $_; # Need to copy, before trying to modify.
154         $key =~ s/^use//;
155         $key =~ s/^d_//;
156         skip_all("no $key");
157     }
158 }
159
160 sub find_git_or_skip {
161     my ($source_dir, $reason);
162     if (-d '.git') {
163         $source_dir = '.';
164     } elsif (-l 'MANIFEST' && -l 'AUTHORS') {
165         my $where = readlink 'MANIFEST';
166         die "Can't readling MANIFEST: $!" unless defined $where;
167         die "Confusing symlink target for MANIFEST, '$where'"
168             unless $where =~ s!/MANIFEST\z!!;
169         if (-d "$where/.git") {
170             # Looks like we are in a symlink tree
171             if (exists $ENV{GIT_DIR}) {
172                 diag("Found source tree at $where, but \$ENV{GIT_DIR} is $ENV{GIT_DIR}. Not changing it");
173             } else {
174                 note("Found source tree at $where, setting \$ENV{GIT_DIR}");
175                 $ENV{GIT_DIR} = "$where/.git";
176             }
177             $source_dir = $where;
178         }
179     }
180     if ($source_dir) {
181         my $version_string = `git --version`;
182         if (defined $version_string
183               && $version_string =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
184             return $source_dir if eval "v$1 ge v1.5.0";
185             # If you have earlier than 1.5.0 and it works, change this test
186             $reason = "in git checkout, but git version '$1$2' too old";
187         } else {
188             $reason = "in git checkout, but cannot run git";
189         }
190     } else {
191         $reason = 'not being run from a git checkout';
192     }
193     skip_all($reason) if $_[0] && $_[0] eq 'all';
194     skip($reason, @_);
195 }
196
197 sub BAIL_OUT {
198     my ($reason) = @_;
199     _print("Bail out!  $reason\n");
200     exit 255;
201 }
202
203 sub _ok {
204     my ($pass, $where, $name, @mess) = @_;
205     # Do not try to microoptimize by factoring out the "not ".
206     # VMS will avenge.
207     my $out;
208     if ($name) {
209         # escape out '#' or it will interfere with '# skip' and such
210         $name =~ s/#/\\#/g;
211         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
212     } else {
213         $out = $pass ? "ok $test" : "not ok $test";
214     }
215
216     if ($TODO) {
217         $out = $out . " # TODO $TODO";
218     } else {
219         $Tests_Are_Passing = 0 unless $pass;
220     }
221
222     _print "$out\n";
223
224     if ($pass) {
225         note @mess; # Ensure that the message is properly escaped.
226     }
227     else {
228         my $msg = "# Failed test $test - ";
229         $msg.= "$name " if $name;
230         $msg .= "$where\n";
231         _diag $msg;
232         _diag @mess;
233     }
234
235     $test = $test + 1; # don't use ++
236
237     return $pass;
238 }
239
240 sub _where {
241     my @caller = caller($Level);
242     return "at $caller[1] line $caller[2]";
243 }
244
245 # DON'T use this for matches. Use like() instead.
246 sub ok ($@) {
247     my ($pass, $name, @mess) = @_;
248     _ok($pass, _where(), $name, @mess);
249 }
250
251 sub _q {
252     my $x = shift;
253     return 'undef' unless defined $x;
254     my $q = $x;
255     $q =~ s/\\/\\\\/g;
256     $q =~ s/'/\\'/g;
257     return "'$q'";
258 }
259
260 sub _qq {
261     my $x = shift;
262     return defined $x ? '"' . display ($x) . '"' : 'undef';
263 };
264
265 # keys are the codes \n etc map to, values are 2 char strings such as \n
266 my %backslash_escape;
267 foreach my $x (split //, 'nrtfa\\\'"') {
268     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
269 }
270 # A way to display scalars containing control characters and Unicode.
271 # Trying to avoid setting $_, or relying on local $_ to work.
272 sub display {
273     my @result;
274     foreach my $x (@_) {
275         if (defined $x and not ref $x) {
276             my $y = '';
277             foreach my $c (unpack("U*", $x)) {
278                 if ($c > 255) {
279                     $y = $y . sprintf "\\x{%x}", $c;
280                 } elsif ($backslash_escape{$c}) {
281                     $y = $y . $backslash_escape{$c};
282                 } else {
283                     my $z = chr $c; # Maybe we can get away with a literal...
284                     if ($z =~ /[[:^print:]]/) {
285
286                         # Use octal for characters traditionally expressed as
287                         # such: the low controls, which on EBCDIC aren't
288                         # necessarily the same ones as on ASCII platforms, but
289                         # are small ordinals, nonetheless
290                         if ($c <= 037) {
291                             $z = sprintf "\\%03o", $c;
292                         } else {
293                             $z = sprintf "\\x{%x}", $c;
294                         }
295                     }
296                     $y = $y . $z;
297                 }
298             }
299             $x = $y;
300         }
301         return $x unless wantarray;
302         push @result, $x;
303     }
304     return @result;
305 }
306
307 sub is ($$@) {
308     my ($got, $expected, $name, @mess) = @_;
309
310     my $pass;
311     if( !defined $got || !defined $expected ) {
312         # undef only matches undef
313         $pass = !defined $got && !defined $expected;
314     }
315     else {
316         $pass = $got eq $expected;
317     }
318
319     unless ($pass) {
320         unshift(@mess, "#      got "._qq($got)."\n",
321                        "# expected "._qq($expected)."\n");
322     }
323     _ok($pass, _where(), $name, @mess);
324 }
325
326 sub isnt ($$@) {
327     my ($got, $isnt, $name, @mess) = @_;
328
329     my $pass;
330     if( !defined $got || !defined $isnt ) {
331         # undef only matches undef
332         $pass = defined $got || defined $isnt;
333     }
334     else {
335         $pass = $got ne $isnt;
336     }
337
338     unless( $pass ) {
339         unshift(@mess, "# it should not be "._qq($got)."\n",
340                        "# but it is.\n");
341     }
342     _ok($pass, _where(), $name, @mess);
343 }
344
345 sub cmp_ok ($$$@) {
346     my($got, $type, $expected, $name, @mess) = @_;
347
348     my $pass;
349     {
350         local $^W = 0;
351         local($@,$!);   # don't interfere with $@
352                         # eval() sometimes resets $!
353         $pass = eval "\$got $type \$expected";
354     }
355     unless ($pass) {
356         # It seems Irix long doubles can have 2147483648 and 2147483648
357         # that stringify to the same thing but are actually numerically
358         # different. Display the numbers if $type isn't a string operator,
359         # and the numbers are stringwise the same.
360         # (all string operators have alphabetic names, so tr/a-z// is true)
361         # This will also show numbers for some unneeded cases, but will
362         # definitely be helpful for things such as == and <= that fail
363         if ($got eq $expected and $type !~ tr/a-z//) {
364             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
365         }
366         unshift(@mess, "#      got "._qq($got)."\n",
367                        "# expected $type "._qq($expected)."\n");
368     }
369     _ok($pass, _where(), $name, @mess);
370 }
371
372 # Check that $got is within $range of $expected
373 # if $range is 0, then check it's exact
374 # else if $expected is 0, then $range is an absolute value
375 # otherwise $range is a fractional error.
376 # Here $range must be numeric, >= 0
377 # Non numeric ranges might be a useful future extension. (eg %)
378 sub within ($$$@) {
379     my ($got, $expected, $range, $name, @mess) = @_;
380     my $pass;
381     if (!defined $got or !defined $expected or !defined $range) {
382         # This is a fail, but doesn't need extra diagnostics
383     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
384         # This is a fail
385         unshift @mess, "# got, expected and range must be numeric\n";
386     } elsif ($range < 0) {
387         # This is also a fail
388         unshift @mess, "# range must not be negative\n";
389     } elsif ($range == 0) {
390         # Within 0 is ==
391         $pass = $got == $expected;
392     } elsif ($expected == 0) {
393         # If expected is 0, treat range as absolute
394         $pass = ($got <= $range) && ($got >= - $range);
395     } else {
396         my $diff = $got - $expected;
397         $pass = abs ($diff / $expected) < $range;
398     }
399     unless ($pass) {
400         if ($got eq $expected) {
401             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
402         }
403         unshift@mess, "#      got "._qq($got)."\n",
404                       "# expected "._qq($expected)." (within "._qq($range).")\n";
405     }
406     _ok($pass, _where(), $name, @mess);
407 }
408
409 # Note: this isn't quite as fancy as Test::More::like().
410
411 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
412 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
413
414 sub like_yn ($$$@) {
415     my ($flip, undef, $expected, $name, @mess) = @_;
416     my $pass;
417     $pass = $_[1] =~ /$expected/ if !$flip;
418     $pass = $_[1] !~ /$expected/ if $flip;
419     unless ($pass) {
420         unshift(@mess, "#      got '$_[1]'\n",
421                 $flip
422                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
423     }
424     local $Level = $Level + 1;
425     _ok($pass, _where(), $name, @mess);
426 }
427
428 sub pass {
429     _ok(1, '', @_);
430 }
431
432 sub fail {
433     _ok(0, _where(), @_);
434 }
435
436 sub curr_test {
437     $test = shift if @_;
438     return $test;
439 }
440
441 sub next_test {
442   my $retval = $test;
443   $test = $test + 1; # don't use ++
444   $retval;
445 }
446
447 # Note: can't pass multipart messages since we try to
448 # be compatible with Test::More::skip().
449 sub skip {
450     my $why = shift;
451     my $n    = @_ ? shift : 1;
452     for (1..$n) {
453         _print "ok $test # skip $why\n";
454         $test = $test + 1;
455     }
456     local $^W = 0;
457     last SKIP;
458 }
459
460 sub skip_if_miniperl {
461     skip(@_) if is_miniperl();
462 }
463
464 sub skip_without_dynamic_extension {
465     my ($extension) = @_;
466     skip("no dynamic loading on miniperl, no $extension") if is_miniperl();
467     return if &_have_dynamic_extension;
468     skip("$extension was not built");
469 }
470
471 sub todo_skip {
472     my $why = shift;
473     my $n   = @_ ? shift : 1;
474
475     for (1..$n) {
476         _print "not ok $test # TODO & SKIP $why\n";
477         $test = $test + 1;
478     }
479     local $^W = 0;
480     last TODO;
481 }
482
483 sub eq_array {
484     my ($ra, $rb) = @_;
485     return 0 unless $#$ra == $#$rb;
486     for my $i (0..$#$ra) {
487         next     if !defined $ra->[$i] && !defined $rb->[$i];
488         return 0 if !defined $ra->[$i];
489         return 0 if !defined $rb->[$i];
490         return 0 unless $ra->[$i] eq $rb->[$i];
491     }
492     return 1;
493 }
494
495 sub eq_hash {
496   my ($orig, $suspect) = @_;
497   my $fail;
498   while (my ($key, $value) = each %$suspect) {
499     # Force a hash recompute if this perl's internals can cache the hash key.
500     $key = "" . $key;
501     if (exists $orig->{$key}) {
502       if (
503         defined $orig->{$key} != defined $value
504         || (defined $value && $orig->{$key} ne $value)
505       ) {
506         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
507                      " now ", _qq($value), "\n";
508         $fail = 1;
509       }
510     } else {
511       _print "# key ", _qq($key), " is ", _qq($value),
512                    ", not in original.\n";
513       $fail = 1;
514     }
515   }
516   foreach (keys %$orig) {
517     # Force a hash recompute if this perl's internals can cache the hash key.
518     $_ = "" . $_;
519     next if (exists $suspect->{$_});
520     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
521     $fail = 1;
522   }
523   !$fail;
524 }
525
526 # We only provide a subset of the Test::More functionality.
527 sub require_ok ($) {
528     my ($require) = @_;
529     if ($require =~ tr/[A-Za-z0-9:.]//c) {
530         fail("Invalid character in \"$require\", passed to require_ok");
531     } else {
532         eval <<REQUIRE_OK;
533 require $require;
534 REQUIRE_OK
535         is($@, '', _where(), "require $require");
536     }
537 }
538
539 sub use_ok ($) {
540     my ($use) = @_;
541     if ($use =~ tr/[A-Za-z0-9:.]//c) {
542         fail("Invalid character in \"$use\", passed to use");
543     } else {
544         eval <<USE_OK;
545 use $use;
546 USE_OK
547         is($@, '', _where(), "use $use");
548     }
549 }
550
551 # runperl - Runs a separate perl interpreter.
552 # Arguments :
553 #   switches => [ command-line switches ]
554 #   nolib    => 1 # don't use -I../lib (included by default)
555 #   non_portable => Don't warn if a one liner contains quotes
556 #   prog     => one-liner (avoid quotes)
557 #   progs    => [ multi-liner (avoid quotes) ]
558 #   progfile => perl script
559 #   stdin    => string to feed the stdin (or undef to redirect from /dev/null)
560 #   stderr   => redirect stderr to stdout
561 #   args     => [ command-line arguments to the perl program ]
562 #   verbose  => print the command line
563
564 my $is_mswin    = $^O eq 'MSWin32';
565 my $is_netware  = $^O eq 'NetWare';
566 my $is_vms      = $^O eq 'VMS';
567 my $is_cygwin   = $^O eq 'cygwin';
568
569 sub _quote_args {
570     my ($runperl, $args) = @_;
571
572     foreach (@$args) {
573         # In VMS protect with doublequotes because otherwise
574         # DCL will lowercase -- unless already doublequoted.
575        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
576        $runperl = $runperl . ' ' . $_;
577     }
578     return $runperl;
579 }
580
581 sub _create_runperl { # Create the string to qx in runperl().
582     my %args = @_;
583     my $runperl = which_perl();
584     if ($runperl =~ m/\s/) {
585         $runperl = qq{"$runperl"};
586     }
587     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
588     if ($ENV{PERL_RUNPERL_DEBUG}) {
589         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
590     }
591     unless ($args{nolib}) {
592         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
593     }
594     if ($args{switches}) {
595         local $Level = 2;
596         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
597             unless ref $args{switches} eq "ARRAY";
598         $runperl = _quote_args($runperl, $args{switches});
599     }
600     if (defined $args{prog}) {
601         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
602             if defined $args{progs};
603         $args{progs} = [$args{prog}]
604     }
605     if (defined $args{progs}) {
606         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
607             unless ref $args{progs} eq "ARRAY";
608         foreach my $prog (@{$args{progs}}) {
609             if ($prog =~ tr/'"// && !$args{non_portable}) {
610                 warn "quotes in prog >>$prog<< are not portable";
611             }
612             if ($is_mswin || $is_netware || $is_vms) {
613                 $runperl = $runperl . qq ( -e "$prog" );
614             }
615             else {
616                 $runperl = $runperl . qq ( -e '$prog' );
617             }
618         }
619     } elsif (defined $args{progfile}) {
620         $runperl = $runperl . qq( "$args{progfile}");
621     } else {
622         # You probably didn't want to be sucking in from the upstream stdin
623         die "test.pl:runperl(): none of prog, progs, progfile, args, "
624             . " switches or stdin specified"
625             unless defined $args{args} or defined $args{switches}
626                 or defined $args{stdin};
627     }
628     if (defined $args{stdin}) {
629         # so we don't try to put literal newlines and crs onto the
630         # command line.
631         $args{stdin} =~ s/\n/\\n/g;
632         $args{stdin} =~ s/\r/\\r/g;
633
634         if ($is_mswin || $is_netware || $is_vms) {
635             $runperl = qq{$Perl -e "print qq(} .
636                 $args{stdin} . q{)" | } . $runperl;
637         }
638         else {
639             $runperl = qq{$Perl -e 'print qq(} .
640                 $args{stdin} . q{)' | } . $runperl;
641         }
642     } elsif (exists $args{stdin}) {
643         # Using the pipe construction above can cause fun on systems which use
644         # ksh as /bin/sh, as ksh does pipes differently (with one less process)
645         # With sh, for the command line 'perl -e 'print qq()' | perl -e ...'
646         # the sh process forks two children, which use exec to start the two
647         # perl processes. The parent shell process persists for the duration of
648         # the pipeline, and the second perl process starts with no children.
649         # With ksh (and zsh), the shell saves a process by forking a child for
650         # just the first perl process, and execing itself to start the second.
651         # This means that the second perl process starts with one child which
652         # it didn't create. This causes "fun" when if the tests assume that
653         # wait (or waitpid) will only return information about processes
654         # started within the test.
655         # They also cause fun on VMS, where the pipe implementation returns
656         # the exit code of the process at the front of the pipeline, not the
657         # end. This messes up any test using OPTION FATAL.
658         # Hence it's useful to have a way to make STDIN be at eof without
659         # needing a pipeline, so that the fork tests have a sane environment
660         # without these surprises.
661
662         # /dev/null appears to be surprisingly portable.
663         $runperl = $runperl . ($is_mswin ? ' <nul' : ' </dev/null');
664     }
665     if (defined $args{args}) {
666         $runperl = _quote_args($runperl, $args{args});
667     }
668     $runperl = $runperl . ' 2>&1' if $args{stderr};
669     if ($args{verbose}) {
670         my $runperldisplay = $runperl;
671         $runperldisplay =~ s/\n/\n\#/g;
672         _print_stderr "# $runperldisplay\n";
673     }
674     return $runperl;
675 }
676
677 sub runperl {
678     die "test.pl:runperl() does not take a hashref"
679         if ref $_[0] and ref $_[0] eq 'HASH';
680     my $runperl = &_create_runperl;
681     my $result;
682
683     my $tainted = ${^TAINT};
684     my %args = @_;
685     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
686
687     if ($tainted) {
688         # We will assume that if you're running under -T, you really mean to
689         # run a fresh perl, so we'll brute force launder everything for you
690         my $sep;
691
692         if (! eval {require Config; 1}) {
693             warn "test.pl had problems loading Config: $@";
694             $sep = ':';
695         } else {
696             $sep = $Config::Config{path_sep};
697         }
698
699         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
700         local @ENV{@keys} = ();
701         # Untaint, plus take out . and empty string:
702         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
703         $ENV{PATH} =~ /(.*)/s;
704         local $ENV{PATH} =
705             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
706                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
707                     split quotemeta ($sep), $1;
708         if ($is_cygwin) {   # Must have /bin under Cygwin
709             if (length $ENV{PATH}) {
710                 $ENV{PATH} = $ENV{PATH} . $sep;
711             }
712             $ENV{PATH} = $ENV{PATH} . '/bin';
713         }
714         $runperl =~ /(.*)/s;
715         $runperl = $1;
716
717         $result = `$runperl`;
718     } else {
719         $result = `$runperl`;
720     }
721     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
722     return $result;
723 }
724
725 # Nice alias
726 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
727
728 sub DIE {
729     _print_stderr "# @_\n";
730     exit 1;
731 }
732
733 # A somewhat safer version of the sometimes wrong $^X.
734 sub which_perl {
735     unless (defined $Perl) {
736         $Perl = $^X;
737
738         # VMS should have 'perl' aliased properly
739         return $Perl if $is_vms;
740
741         my $exe;
742         if (! eval {require Config; 1}) {
743             warn "test.pl had problems loading Config: $@";
744             $exe = '';
745         } else {
746             $exe = $Config::Config{_exe};
747         }
748        $exe = '' unless defined $exe;
749
750         # This doesn't absolutize the path: beware of future chdirs().
751         # We could do File::Spec->abs2rel() but that does getcwd()s,
752         # which is a bit heavyweight to do here.
753
754         if ($Perl =~ /^perl\Q$exe\E$/i) {
755             my $perl = "perl$exe";
756             if (! eval {require File::Spec; 1}) {
757                 warn "test.pl had problems loading File::Spec: $@";
758                 $Perl = "./$perl";
759             } else {
760                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
761             }
762         }
763
764         # Build up the name of the executable file from the name of
765         # the command.
766
767         if ($Perl !~ /\Q$exe\E$/i) {
768             $Perl = $Perl . $exe;
769         }
770
771         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
772
773         # For subcommands to use.
774         $ENV{PERLEXE} = $Perl;
775     }
776     return $Perl;
777 }
778
779 sub unlink_all {
780     my $count = 0;
781     foreach my $file (@_) {
782         1 while unlink $file;
783         if( -f $file ){
784             _print_stderr "# Couldn't unlink '$file': $!\n";
785         }else{
786             ++$count;
787         }
788     }
789     $count;
790 }
791
792 # _num_to_alpha - Returns a string of letters representing a positive integer.
793 # Arguments :
794 #   number to convert
795 #   maximum number of letters
796
797 # returns undef if the number is negative
798 # returns undef if the number of letters is greater than the maximum wanted
799
800 # _num_to_alpha( 0) eq 'A';
801 # _num_to_alpha( 1) eq 'B';
802 # _num_to_alpha(25) eq 'Z';
803 # _num_to_alpha(26) eq 'AA';
804 # _num_to_alpha(27) eq 'AB';
805
806 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
807
808 # Avoid ++ -- ranges split negative numbers
809 sub _num_to_alpha{
810     my($num,$max_char) = @_;
811     return unless $num >= 0;
812     my $alpha = '';
813     my $char_count = 0;
814     $max_char = 0 if $max_char < 0;
815
816     while( 1 ){
817         $alpha = $letters[ $num % 26 ] . $alpha;
818         $num = int( $num / 26 );
819         last if $num == 0;
820         $num = $num - 1;
821
822         # char limit
823         next unless $max_char;
824         $char_count = $char_count + 1;
825         return if $char_count == $max_char;
826     }
827     return $alpha;
828 }
829
830 my %tmpfiles;
831 END { unlink_all keys %tmpfiles }
832
833 # A regexp that matches the tempfile names
834 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
835
836 # Avoid ++, avoid ranges, avoid split //
837 my $tempfile_count = 0;
838 sub tempfile {
839     while(1){
840         my $try = "tmp$$";
841         my $alpha = _num_to_alpha($tempfile_count,2);
842         last unless defined $alpha;
843         $try = $try . $alpha;
844         $tempfile_count = $tempfile_count + 1;
845
846         # Need to note all the file names we allocated, as a second request may
847         # come before the first is created.
848         if (!$tmpfiles{$try} && !-e $try) {
849             # We have a winner
850             $tmpfiles{$try} = 1;
851             return $try;
852         }
853     }
854     die "Can't find temporary file name starting \"tmp$$\"";
855 }
856
857 # This is the temporary file for _fresh_perl
858 my $tmpfile = tempfile();
859
860 sub _fresh_perl {
861     my($prog, $action, $expect, $runperl_args, $name) = @_;
862
863     # Given the choice of the mis-parsable {}
864     # (we want an anon hash, but a borked lexer might think that it's a block)
865     # or relying on taking a reference to a lexical
866     # (\ might be mis-parsed, and the reference counting on the pad may go
867     #  awry)
868     # it feels like the least-worse thing is to assume that auto-vivification
869     # works. At least, this is only going to be a run-time failure, so won't
870     # affect tests using this file but not this function.
871     $runperl_args->{progfile} ||= $tmpfile;
872     $runperl_args->{stderr}     = 1 unless exists $runperl_args->{stderr};
873
874     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
875     print TEST $prog;
876     close TEST or die "Cannot close $tmpfile: $!";
877
878     my $results = runperl(%$runperl_args);
879     my $status = $?;
880
881     # Clean up the results into something a bit more predictable.
882     $results  =~ s/\n+$//;
883     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
884     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
885
886     # bison says 'parse error' instead of 'syntax error',
887     # various yaccs may or may not capitalize 'syntax'.
888     $results =~ s/^(syntax|parse) error/syntax error/mig;
889
890     if ($is_vms) {
891         # some tests will trigger VMS messages that won't be expected
892         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
893
894         # pipes double these sometimes
895         $results =~ s/\n\n/\n/g;
896     }
897
898     # Use the first line of the program as a name if none was given
899     unless( $name ) {
900         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
901         $name = $name . '...' if length $first_line > length $name;
902     }
903
904     # Historically this was implemented using a closure, but then that means
905     # that the tests for closures avoid using this code. Given that there
906     # are exactly two callers, doing exactly two things, the simpler approach
907     # feels like a better trade off.
908     my $pass;
909     if ($action eq 'eq') {
910         $pass = is($results, $expect, $name);
911     } elsif ($action eq '=~') {
912         $pass = like($results, $expect, $name);
913     } else {
914         die "_fresh_perl can't process action '$action'";
915     }
916         
917     unless ($pass) {
918         _diag "# PROG: \n$prog\n";
919         _diag "# STATUS: $status\n";
920     }
921
922     return $pass;
923 }
924
925 #
926 # fresh_perl_is
927 #
928 # Combination of run_perl() and is().
929 #
930
931 sub fresh_perl_is {
932     my($prog, $expected, $runperl_args, $name) = @_;
933
934     # _fresh_perl() is going to clip the trailing newlines off the result.
935     # This will make it so the test author doesn't have to know that.
936     $expected =~ s/\n+$//;
937
938     local $Level = 2;
939     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
940 }
941
942 #
943 # fresh_perl_like
944 #
945 # Combination of run_perl() and like().
946 #
947
948 sub fresh_perl_like {
949     my($prog, $expected, $runperl_args, $name) = @_;
950     local $Level = 2;
951     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
952 }
953
954 # Many tests use the same format in __DATA__ or external files to specify a
955 # sequence of (fresh) tests to run, extra files they may temporarily need, and
956 # what the expected output is. So have excatly one copy of the code to run that
957 #
958 # Each program is source code to run followed by an "EXPECT" line, followed
959 # by the expected output.
960 #
961 # The code to run may begin with a command line switch such as -w or -0777
962 # (alphanumerics only), and may contain (note the '# ' on each):
963 #   # TODO reason for todo
964 #   # SKIP reason for skip
965 #   # SKIP ?code to test if this should be skipped
966 #   # NAME name of the test (as with ok($ok, $name))
967 #
968 # The expected output may contain:
969 #   OPTION list of options
970 #   OPTIONS list of options
971 #
972 # The possible options for OPTION may be:
973 #   regex - the expected output is a regular expression
974 #   random - all lines match but in any order
975 #   fatal - the code will fail fatally (croak, die)
976 #
977 # If the actual output contains a line "SKIPPED" the test will be
978 # skipped.
979 #
980 # If the actual output contains a line "PREFIX", any output starting with that
981 # line will be ignored when comparing with the expected output
982 #
983 # If the global variable $FATAL is true then OPTION fatal is the
984 # default.
985
986 sub _setup_one_file {
987     my $fh = shift;
988     # Store the filename as a program that started at line 0.
989     # Real files count lines starting at line 1.
990     my @these = (0, shift);
991     my ($lineno, $current);
992     while (<$fh>) {
993         if ($_ eq "########\n") {
994             if (defined $current) {
995                 push @these, $lineno, $current;
996             }
997             undef $current;
998         } else {
999             if (!defined $current) {
1000                 $lineno = $.;
1001             }
1002             $current .= $_;
1003         }
1004     }
1005     if (defined $current) {
1006         push @these, $lineno, $current;
1007     }
1008     ((scalar @these) / 2 - 1, @these);
1009 }
1010
1011 sub setup_multiple_progs {
1012     my ($tests, @prgs);
1013     foreach my $file (@_) {
1014         next if $file =~ /(?:~|\.orig|,v)$/;
1015         next if $file =~ /perlio$/ && !PerlIO::Layer->find('perlio');
1016         next if -d $file;
1017
1018         open my $fh, '<', $file or die "Cannot open $file: $!\n" ;
1019         my $found;
1020         while (<$fh>) {
1021             if (/^__END__/) {
1022                 ++$found;
1023                 last;
1024             }
1025         }
1026         # This is an internal error, and should never happen. All bar one of
1027         # the files had an __END__ marker to signal the end of their preamble,
1028         # although for some it wasn't technically necessary as they have no
1029         # tests. It might be possible to process files without an __END__ by
1030         # seeking back to the start and treating the whole file as tests, but
1031         # it's simpler and more reliable just to make the rule that all files
1032         # must have __END__ in. This should never fail - a file without an
1033         # __END__ should not have been checked in, because the regression tests
1034         # would not have passed.
1035         die "Could not find '__END__' in $file"
1036             unless $found;
1037
1038         my ($t, @p) = _setup_one_file($fh, $file);
1039         $tests += $t;
1040         push @prgs, @p;
1041
1042         close $fh
1043             or die "Cannot close $file: $!\n";
1044     }
1045     return ($tests, @prgs);
1046 }
1047
1048 sub run_multiple_progs {
1049     my $up = shift;
1050     my @prgs;
1051     if ($up) {
1052         # The tests in lib run in a temporary subdirectory of t, and always
1053         # pass in a list of "programs" to run
1054         @prgs = @_;
1055     } else {
1056         # The tests below t run in t and pass in a file handle. In theory we
1057         # can pass (caller)[1] as the second argument to report errors with
1058         # the filename of our caller, as the handle is always DATA. However,
1059         # line numbers in DATA count from the __END__ token, so will be wrong.
1060         # Which is more confusing than not providing line numbers. So, for now,
1061         # don't provide line numbers. No obvious clean solution - one hack
1062         # would be to seek DATA back to the start and read to the __END__ token,
1063         # but that feels almost like we should just open $0 instead.
1064
1065         # Not going to rely on undef in list assignment.
1066         my $dummy;
1067         ($dummy, @prgs) = _setup_one_file(shift);
1068     }
1069
1070     my $tmpfile = tempfile();
1071
1072     my ($file, $line);
1073   PROGRAM:
1074     while (defined ($line = shift @prgs)) {
1075         $_ = shift @prgs;
1076         unless ($line) {
1077             $file = $_;
1078             if (defined $file) {
1079                 print "# From $file\n";
1080             }
1081             next;
1082         }
1083         my $switch = "";
1084         my @temps ;
1085         my @temp_path;
1086         if (s/^(\s*-\w+)//) {
1087             $switch = $1;
1088         }
1089         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
1090
1091         my %reason;
1092         foreach my $what (qw(skip todo)) {
1093             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
1094             # If the SKIP reason starts ? then it's taken as a code snippet to
1095             # evaluate. This provides the flexibility to have conditional SKIPs
1096             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
1097                 my $temp = eval $reason{$what};
1098                 if ($@) {
1099                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
1100                 }
1101                 $reason{$what} = $temp;
1102             }
1103         }
1104
1105         my $name = '';
1106         if ($prog =~ s/^#\s*NAME\s+(.+)\n//m) {
1107             $name = $1;
1108         }
1109
1110         if ($reason{skip}) {
1111         SKIP:
1112           {
1113             skip($name ? "$name - $reason{skip}" : $reason{skip}, 1);
1114           }
1115           next PROGRAM;
1116         }
1117
1118         if ($prog =~ /--FILE--/) {
1119             my @files = split(/\n?--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
1120             shift @files ;
1121             die "Internal error: test $_ didn't split into pairs, got " .
1122                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
1123                     if @files % 2;
1124             while (@files > 2) {
1125                 my $filename = shift @files;
1126                 my $code = shift @files;
1127                 push @temps, $filename;
1128                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
1129                     require File::Path;
1130                     File::Path::mkpath($1);
1131                     push(@temp_path, $1);
1132                 }
1133                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
1134                 print $fh $code;
1135                 close $fh or die "Cannot close $filename: $!\n";
1136             }
1137             shift @files;
1138             $prog = shift @files;
1139         }
1140
1141         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
1142         print $fh q{
1143         BEGIN {
1144             open STDERR, '>&', STDOUT
1145               or die "Can't dup STDOUT->STDERR: $!;";
1146         }
1147         };
1148         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
1149         print $fh $prog,"\n";
1150         close $fh or die "Cannot close $tmpfile: $!";
1151         my $results = runperl( stderr => 1, progfile => $tmpfile,
1152                                stdin => undef, $up
1153                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
1154                                : (switches => [$switch])
1155                                 );
1156         my $status = $?;
1157         $results =~ s/\n+$//;
1158         # allow expected output to be written as if $prog is on STDIN
1159         $results =~ s/$::tempfile_regexp/-/g;
1160         if ($^O eq 'VMS') {
1161             # some tests will trigger VMS messages that won't be expected
1162             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1163
1164             # pipes double these sometimes
1165             $results =~ s/\n\n/\n/g;
1166         }
1167         # bison says 'parse error' instead of 'syntax error',
1168         # various yaccs may or may not capitalize 'syntax'.
1169         $results =~ s/^(syntax|parse) error/syntax error/mig;
1170         # allow all tests to run when there are leaks
1171         $results =~ s/Scalars leaked: \d+\n//g;
1172
1173         $expected =~ s/\n+$//;
1174         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
1175         # any special options? (OPTIONS foo bar zap)
1176         my $option_regex = 0;
1177         my $option_random = 0;
1178         my $fatal = $FATAL;
1179         if ($expected =~ s/^OPTIONS? (.+)\n//) {
1180             foreach my $option (split(' ', $1)) {
1181                 if ($option eq 'regex') { # allow regular expressions
1182                     $option_regex = 1;
1183                 }
1184                 elsif ($option eq 'random') { # all lines match, but in any order
1185                     $option_random = 1;
1186                 }
1187                 elsif ($option eq 'fatal') { # perl should fail
1188                     $fatal = 1;
1189                 }
1190                 else {
1191                     die "$0: Unknown OPTION '$option'\n";
1192                 }
1193             }
1194         }
1195         die "$0: can't have OPTION regex and random\n"
1196             if $option_regex + $option_random > 1;
1197         my $ok = 0;
1198         if ($results =~ s/^SKIPPED\n//) {
1199             print "$results\n" ;
1200             $ok = 1;
1201         }
1202         else {
1203             if ($option_random) {
1204                 my @got = sort split "\n", $results;
1205                 my @expected = sort split "\n", $expected;
1206
1207                 $ok = "@got" eq "@expected";
1208             }
1209             elsif ($option_regex) {
1210                 $ok = $results =~ /^$expected/;
1211             }
1212             elsif ($prefix) {
1213                 $ok = $results =~ /^\Q$expected/;
1214             }
1215             else {
1216                 $ok = $results eq $expected;
1217             }
1218
1219             if ($ok && $fatal && !($status >> 8)) {
1220                 $ok = 0;
1221             }
1222         }
1223
1224         local $::TODO = $reason{todo};
1225
1226         unless ($ok) {
1227             my $err_line = "PROG: $switch\n$prog\n" .
1228                            "EXPECTED:\n$expected\n";
1229             $err_line   .= "EXIT STATUS: != 0\n" if $fatal;
1230             $err_line   .= "GOT:\n$results\n";
1231             $err_line   .= "EXIT STATUS: " . ($status >> 8) . "\n" if $fatal;
1232             if ($::TODO) {
1233                 $err_line =~ s/^/# /mg;
1234                 print $err_line;  # Harness can't filter it out from STDERR.
1235             }
1236             else {
1237                 print STDERR $err_line;
1238             }
1239         }
1240
1241         if (defined $file) {
1242             _ok($ok, "at $file line $line", $name);
1243         } else {
1244             # We don't have file and line number data for the test, so report
1245             # errors as coming from our caller.
1246             local $Level = $Level + 1;
1247             ok($ok, $name);
1248         }
1249
1250         foreach (@temps) {
1251             unlink $_ if $_;
1252         }
1253         foreach (@temp_path) {
1254             File::Path::rmtree $_ if -d $_;
1255         }
1256     }
1257 }
1258
1259 sub can_ok ($@) {
1260     my($proto, @methods) = @_;
1261     my $class = ref $proto || $proto;
1262
1263     unless( @methods ) {
1264         return _ok( 0, _where(), "$class->can(...)" );
1265     }
1266
1267     my @nok = ();
1268     foreach my $method (@methods) {
1269         local($!, $@);  # don't interfere with caller's $@
1270                         # eval sometimes resets $!
1271         eval { $proto->can($method) } || push @nok, $method;
1272     }
1273
1274     my $name;
1275     $name = @methods == 1 ? "$class->can('$methods[0]')"
1276                           : "$class->can(...)";
1277
1278     _ok( !@nok, _where(), $name );
1279 }
1280
1281
1282 # Call $class->new( @$args ); and run the result through object_ok.
1283 # See Test::More::new_ok
1284 sub new_ok {
1285     my($class, $args, $obj_name) = @_;
1286     $args ||= [];
1287     $object_name = "The object" unless defined $obj_name;
1288
1289     local $Level = $Level + 1;
1290
1291     my $obj;
1292     my $ok = eval { $obj = $class->new(@$args); 1 };
1293     my $error = $@;
1294
1295     if($ok) {
1296         object_ok($obj, $class, $object_name);
1297     }
1298     else {
1299         ok( 0, "new() died" );
1300         diag("Error was:  $@");
1301     }
1302
1303     return $obj;
1304
1305 }
1306
1307
1308 sub isa_ok ($$;$) {
1309     my($object, $class, $obj_name) = @_;
1310
1311     my $diag;
1312     $obj_name = 'The object' unless defined $obj_name;
1313     my $name = "$obj_name isa $class";
1314     if( !defined $object ) {
1315         $diag = "$obj_name isn't defined";
1316     }
1317     else {
1318         my $whatami = ref $object ? 'object' : 'class';
1319
1320         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1321         local($@, $!);  # eval sometimes resets $!
1322         my $rslt = eval { $object->isa($class) };
1323         my $error = $@;  # in case something else blows away $@
1324
1325         if( $error ) {
1326             if( $error =~ /^Can't call method "isa" on unblessed reference/ ) {
1327                 # It's an unblessed reference
1328                 $obj_name = 'The reference' unless defined $obj_name;
1329                 if( !UNIVERSAL::isa($object, $class) ) {
1330                     my $ref = ref $object;
1331                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1332                 }
1333             }
1334             elsif( $error =~ /Can't call method "isa" without a package/ ) {
1335                 # It's something that can't even be a class
1336                 $obj_name = 'The thing' unless defined $obj_name;
1337                 $diag = "$obj_name isn't a class or reference";
1338             }
1339             else {
1340                 die <<WHOA;
1341 WHOA! I tried to call ->isa on your object and got some weird error.
1342 This should never happen.  Please contact the author immediately.
1343 Here's the error.
1344 $@
1345 WHOA
1346             }
1347         }
1348         elsif( !$rslt ) {
1349             $obj_name = "The $whatami" unless defined $obj_name;
1350             my $ref = ref $object;
1351             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1352         }
1353     }
1354
1355     _ok( !$diag, _where(), $name );
1356 }
1357
1358
1359 sub class_ok {
1360     my($class, $isa, $class_name) = @_;
1361
1362     # Written so as to count as one test
1363     local $Level = $Level + 1;
1364     if( ref $class ) {
1365         ok( 0, "$class is a refrence, not a class name" );
1366     }
1367     else {
1368         isa_ok($class, $isa, $class_name);
1369     }
1370 }
1371
1372
1373 sub object_ok {
1374     my($obj, $isa, $obj_name) = @_;
1375
1376     local $Level = $Level + 1;
1377     if( !ref $obj ) {
1378         ok( 0, "$obj is not a reference" );
1379     }
1380     else {
1381         isa_ok($obj, $isa, $obj_name);
1382     }
1383 }
1384
1385
1386 # Purposefully avoiding a closure.
1387 sub __capture {
1388     push @::__capture, join "", @_;
1389 }
1390     
1391 sub capture_warnings {
1392     my $code = shift;
1393
1394     local @::__capture;
1395     local $SIG {__WARN__} = \&__capture;
1396     &$code;
1397     return @::__capture;
1398 }
1399
1400 # This will generate a variable number of tests.
1401 # Use done_testing() instead of a fixed plan.
1402 sub warnings_like {
1403     my ($code, $expect, $name) = @_;
1404     local $Level = $Level + 1;
1405
1406     my @w = capture_warnings($code);
1407
1408     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1409     foreach my $e (@$expect) {
1410         if (ref $e) {
1411             like(shift @w, $e, $name);
1412         } else {
1413             is(shift @w, $e, $name);
1414         }
1415     }
1416     if (@w) {
1417         diag("Saw these additional warnings:");
1418         diag($_) foreach @w;
1419     }
1420 }
1421
1422 sub _fail_excess_warnings {
1423     my($expect, $got, $name) = @_;
1424     local $Level = $Level + 1;
1425     # This will fail, and produce diagnostics
1426     is($expect, scalar @$got, $name);
1427     diag("Saw these warnings:");
1428     diag($_) foreach @$got;
1429 }
1430
1431 sub warning_is {
1432     my ($code, $expect, $name) = @_;
1433     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1434         if ref $expect;
1435     local $Level = $Level + 1;
1436     my @w = capture_warnings($code);
1437     if (@w > 1) {
1438         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1439     } else {
1440         is($w[0], $expect, $name);
1441     }
1442 }
1443
1444 sub warning_like {
1445     my ($code, $expect, $name) = @_;
1446     die sprintf "Expect must be a regexp object"
1447         unless ref $expect eq 'Regexp';
1448     local $Level = $Level + 1;
1449     my @w = capture_warnings($code);
1450     if (@w > 1) {
1451         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1452     } else {
1453         like($w[0], $expect, $name);
1454     }
1455 }
1456
1457 # Set a watchdog to timeout the entire test file
1458 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1459 #        _AFTER_ the 'threads' module is loaded.
1460 sub watchdog ($;$)
1461 {
1462     my $timeout = shift;
1463     my $method  = shift || "";
1464     my $timeout_msg = 'Test process timed out - terminating';
1465
1466     # Valgrind slows perl way down so give it more time before dying.
1467     $timeout *= 10 if $ENV{PERL_VALGRIND};
1468
1469     my $pid_to_kill = $$;   # PID for this process
1470
1471     if ($method eq "alarm") {
1472         goto WATCHDOG_VIA_ALARM;
1473     }
1474
1475     # shut up use only once warning
1476     my $threads_on = $threads::threads && $threads::threads;
1477
1478     # Don't use a watchdog process if 'threads' is loaded -
1479     #   use a watchdog thread instead
1480     if (!$threads_on || $method eq "process") {
1481
1482         # On Windows and VMS, try launching a watchdog process
1483         #   using system(1, ...) (see perlport.pod)
1484         if ($is_mswin || $is_vms) {
1485             # On Windows, try to get the 'real' PID
1486             if ($is_mswin) {
1487                 eval { require Win32; };
1488                 if (defined(&Win32::GetCurrentProcessId)) {
1489                     $pid_to_kill = Win32::GetCurrentProcessId();
1490                 }
1491             }
1492
1493             # If we still have a fake PID, we can't use this method at all
1494             return if ($pid_to_kill <= 0);
1495
1496             # Launch watchdog process
1497             my $watchdog;
1498             eval {
1499                 local $SIG{'__WARN__'} = sub {
1500                     _diag("Watchdog warning: $_[0]");
1501                 };
1502                 my $sig = $is_vms ? 'TERM' : 'KILL';
1503                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
1504                                                     "warn qq/# $timeout_msg" . '\n/;' .
1505                                                     "kill($sig, $pid_to_kill);");
1506                 $watchdog = system(1, $cmd);
1507             };
1508             if ($@ || ($watchdog <= 0)) {
1509                 _diag('Failed to start watchdog');
1510                 _diag($@) if $@;
1511                 undef($watchdog);
1512                 return;
1513             }
1514
1515             # Add END block to parent to terminate and
1516             #   clean up watchdog process
1517             eval "END { local \$! = 0; local \$? = 0;
1518                         wait() if kill('KILL', $watchdog); };";
1519             return;
1520         }
1521
1522         # Try using fork() to generate a watchdog process
1523         my $watchdog;
1524         eval { $watchdog = fork() };
1525         if (defined($watchdog)) {
1526             if ($watchdog) {   # Parent process
1527                 # Add END block to parent to terminate and
1528                 #   clean up watchdog process
1529                 eval "END { local \$! = 0; local \$? = 0;
1530                             wait() if kill('KILL', $watchdog); };";
1531                 return;
1532             }
1533
1534             ### Watchdog process code
1535
1536             # Load POSIX if available
1537             eval { require POSIX; };
1538
1539             # Execute the timeout
1540             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1541             sleep(2);
1542
1543             # Kill test process if still running
1544             if (kill(0, $pid_to_kill)) {
1545                 _diag($timeout_msg);
1546                 kill('KILL', $pid_to_kill);
1547                 if ($is_cygwin) {
1548                     # sometimes the above isn't enough on cygwin
1549                     sleep 1; # wait a little, it might have worked after all
1550                     system("/bin/kill -f $pid_to_kill");
1551                 }
1552             }
1553
1554             # Don't execute END block (added at beginning of this file)
1555             $NO_ENDING = 1;
1556
1557             # Terminate ourself (i.e., the watchdog)
1558             POSIX::_exit(1) if (defined(&POSIX::_exit));
1559             exit(1);
1560         }
1561
1562         # fork() failed - fall through and try using a thread
1563     }
1564
1565     # Use a watchdog thread because either 'threads' is loaded,
1566     #   or fork() failed
1567     if (eval {require threads; 1}) {
1568         'threads'->create(sub {
1569                 # Load POSIX if available
1570                 eval { require POSIX; };
1571
1572                 # Execute the timeout
1573                 my $time_left = $timeout;
1574                 do {
1575                     $time_left = $time_left - sleep($time_left);
1576                 } while ($time_left > 0);
1577
1578                 # Kill the parent (and ourself)
1579                 select(STDERR); $| = 1;
1580                 _diag($timeout_msg);
1581                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1582                 my $sig = $is_vms ? 'TERM' : 'KILL';
1583                 kill($sig, $pid_to_kill);
1584             })->detach();
1585         return;
1586     }
1587
1588     # If everything above fails, then just use an alarm timeout
1589 WATCHDOG_VIA_ALARM:
1590     if (eval { alarm($timeout); 1; }) {
1591         # Load POSIX if available
1592         eval { require POSIX; };
1593
1594         # Alarm handler will do the actual 'killing'
1595         $SIG{'ALRM'} = sub {
1596             select(STDERR); $| = 1;
1597             _diag($timeout_msg);
1598             POSIX::_exit(1) if (defined(&POSIX::_exit));
1599             my $sig = $is_vms ? 'TERM' : 'KILL';
1600             kill($sig, $pid_to_kill);
1601         };
1602     }
1603 }
1604
1605 # The following 2 functions allow tests to work on both EBCDIC and
1606 # ASCII-ish platforms.  They convert string scalars between the native
1607 # character set and the set of 256 characters which is usually called
1608 # Latin1.
1609
1610 sub native_to_latin1($) {
1611     my $string = shift;
1612
1613     return $string if ord('^') == 94;   # ASCII, Latin1
1614     my $output = "";
1615     for my $i (0 .. length($string) - 1) {
1616         $output .= chr(ord_native_to_latin1(ord(substr($string, $i, 1))));
1617     }
1618     # Preserve utf8ness of input onto the output, even if it didn't need to be
1619     # utf8
1620     utf8::upgrade($output) if utf8::is_utf8($string);
1621
1622     return $output;
1623 }
1624
1625 sub latin1_to_native($) {
1626     my $string = shift;
1627
1628     return $string if ord('^') == 94;   # ASCII, Latin1
1629     my $output = "";
1630     for my $i (0 .. length($string) - 1) {
1631         $output .= chr(ord_latin1_to_native(ord(substr($string, $i, 1))));
1632     }
1633     # Preserve utf8ness of input onto the output, even if it didn't need to be
1634     # utf8
1635     utf8::upgrade($output) if utf8::is_utf8($string);
1636
1637     return $output;
1638 }
1639
1640 sub ord_latin1_to_native {
1641     # given an input code point, return the platform's native
1642     # equivalent value.  Anything above latin1 is itself.
1643
1644     my $ord = shift;
1645     return $ord if ord('^') == 94;   # ASCII, Latin1
1646     return utf8::unicode_to_native($ord);
1647 }
1648
1649 sub ord_native_to_latin1 {
1650     # given an input platform code point, return the latin1 equivalent value.
1651     # Anything above latin1 is itself.
1652
1653     my $ord = shift;
1654     return $ord if ord('^') == 94;   # ASCII, Latin1
1655     return utf8::native_to_unicode($ord);
1656 }
1657
1658 1;