This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
c3ba7366da9e28191fecc4e41df6525da70a33b6
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>, 
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
238 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<unlink>,
239 C<utime>, C<wait>, C<waitpid>
240
241 For more information about the portability of these functions, see
242 L<perlport> and other available platform-specific documentation.
243
244 =head2 Alphabetical Listing of Perl Functions
245
246 =over 8
247
248 =item I<-X> FILEHANDLE
249
250 =item I<-X> EXPR
251
252 =item I<-X>
253
254 A file test, where X is one of the letters listed below.  This unary
255 operator takes one argument, either a filename or a filehandle, and
256 tests the associated file to see if something is true about it.  If the
257 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
258 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
259 the undefined value if the file doesn't exist.  Despite the funny
260 names, precedence is the same as any other named unary operator, and
261 the argument may be parenthesized like any other unary operator.  The
262 operator may be any of:
263 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
264 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
265
266     -r  File is readable by effective uid/gid.
267     -w  File is writable by effective uid/gid.
268     -x  File is executable by effective uid/gid.
269     -o  File is owned by effective uid.
270
271     -R  File is readable by real uid/gid.
272     -W  File is writable by real uid/gid.
273     -X  File is executable by real uid/gid.
274     -O  File is owned by real uid.
275
276     -e  File exists.
277     -z  File has zero size.
278     -s  File has nonzero size (returns size).
279
280     -f  File is a plain file.
281     -d  File is a directory.
282     -l  File is a symbolic link.
283     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
284     -S  File is a socket.
285     -b  File is a block special file.
286     -c  File is a character special file.
287     -t  Filehandle is opened to a tty.
288
289     -u  File has setuid bit set.
290     -g  File has setgid bit set.
291     -k  File has sticky bit set.
292
293     -T  File is an ASCII text file.
294     -B  File is a "binary" file (opposite of -T).
295
296     -M  Age of file in days when script started.
297     -A  Same for access time.
298     -C  Same for inode change time.
299
300 Example:
301
302     while (<>) {
303         chop;
304         next unless -f $_;      # ignore specials
305         #...
306     }
307
308 The interpretation of the file permission operators C<-r>, C<-R>,
309 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
310 of the file and the uids and gids of the user.  There may be other
311 reasons you can't actually read, write, or execute the file.  Such
312 reasons may be for example network filesystem access controls, ACLs
313 (access control lists), read-only filesystems, and unrecognized
314 executable formats.
315
316 Also note that, for the superuser on the local filesystems, the C<-r>,
317 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
318 if any execute bit is set in the mode.  Scripts run by the superuser
319 may thus need to do a stat() to determine the actual mode of the file,
320 or temporarily set their effective uid to something else.
321
322 If you are using ACLs, there is a pragma called C<filetest> that may
323 produce more accurate results than the bare stat() mode bits.
324 When under the C<use filetest 'access'> the above-mentioned filetests
325 will test whether the permission can (not) be granted using the
326 access() family of system calls.  Also note that the C<-x> and C<-X> may
327 under this pragma return true even if there are no execute permission
328 bits set (nor any extra execute permission ACLs).  This strangeness is
329 due to the underlying system calls' definitions.  Read the
330 documentation for the C<filetest> pragma for more information.
331
332 Note that C<-s/a/b/> does not do a negated substitution.  Saying
333 C<-exp($foo)> still works as expected, however--only single letters
334 following a minus are interpreted as file tests.
335
336 The C<-T> and C<-B> switches work as follows.  The first block or so of the
337 file is examined for odd characters such as strange control codes or
338 characters with the high bit set.  If too many strange characters (>30%)
339 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
340 containing null in the first block is considered a binary file.  If C<-T>
341 or C<-B> is used on a filehandle, the current stdio buffer is examined
342 rather than the first block.  Both C<-T> and C<-B> return true on a null
343 file, or a file at EOF when testing a filehandle.  Because you have to
344 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
345 against the file first, as in C<next unless -f $file && -T $file>.
346
347 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
348 the special filehandle consisting of a solitary underline, then the stat
349 structure of the previous file test (or stat operator) is used, saving
350 a system call.  (This doesn't work with C<-t>, and you need to remember
351 that lstat() and C<-l> will leave values in the stat structure for the
352 symbolic link, not the real file.)  Example:
353
354     print "Can do.\n" if -r $a || -w _ || -x _;
355
356     stat($filename);
357     print "Readable\n" if -r _;
358     print "Writable\n" if -w _;
359     print "Executable\n" if -x _;
360     print "Setuid\n" if -u _;
361     print "Setgid\n" if -g _;
362     print "Sticky\n" if -k _;
363     print "Text\n" if -T _;
364     print "Binary\n" if -B _;
365
366 =item abs VALUE
367
368 =item abs
369
370 Returns the absolute value of its argument.
371 If VALUE is omitted, uses C<$_>.
372
373 =item accept NEWSOCKET,GENERICSOCKET
374
375 Accepts an incoming socket connect, just as the accept(2) system call
376 does.  Returns the packed address if it succeeded, false otherwise.
377 See the example in L<perlipc/"Sockets: Client/Server Communication">.
378
379 On systems that support a close-on-exec flag on files, the flag will
380 be set for the newly opened file descriptor, as determined by the
381 value of $^F.  See L<perlvar/$^F>.
382
383 =item alarm SECONDS
384
385 =item alarm
386
387 Arranges to have a SIGALRM delivered to this process after the
388 specified number of seconds have elapsed.  If SECONDS is not specified,
389 the value stored in C<$_> is used. (On some machines,
390 unfortunately, the elapsed time may be up to one second less than you
391 specified because of how seconds are counted.)  Only one timer may be
392 counting at once.  Each call disables the previous timer, and an
393 argument of C<0> may be supplied to cancel the previous timer without
394 starting a new one.  The returned value is the amount of time remaining
395 on the previous timer.
396
397 For delays of finer granularity than one second, you may use Perl's
398 four-argument version of select() leaving the first three arguments
399 undefined, or you might be able to use the C<syscall> interface to
400 access setitimer(2) if your system supports it.  The Time::HiRes module
401 from CPAN may also prove useful.
402
403 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
404 (C<sleep> may be internally implemented in your system with C<alarm>)
405
406 If you want to use C<alarm> to time out a system call you need to use an
407 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
408 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
409 restart system calls on some systems.  Using C<eval>/C<die> always works,
410 modulo the caveats given in L<perlipc/"Signals">.
411
412     eval {
413         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
414         alarm $timeout;
415         $nread = sysread SOCKET, $buffer, $size;
416         alarm 0;
417     };
418     if ($@) {
419         die unless $@ eq "alarm\n";   # propagate unexpected errors
420         # timed out
421     }
422     else {
423         # didn't
424     }
425
426 =item atan2 Y,X
427
428 Returns the arctangent of Y/X in the range -PI to PI.
429
430 For the tangent operation, you may use the C<Math::Trig::tan>
431 function, or use the familiar relation:
432
433     sub tan { sin($_[0]) / cos($_[0])  }
434
435 =item bind SOCKET,NAME
436
437 Binds a network address to a socket, just as the bind system call
438 does.  Returns true if it succeeded, false otherwise.  NAME should be a
439 packed address of the appropriate type for the socket.  See the examples in
440 L<perlipc/"Sockets: Client/Server Communication">.
441
442 =item binmode FILEHANDLE, DISCIPLINE
443
444 =item binmode FILEHANDLE
445
446 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
447 on systems where the run-time libraries distinguish between binary and
448 text files.  If FILEHANDLE is an expression, the value is taken as the
449 name of the filehandle.  DISCIPLINE can be either of C<":raw"> for
450 binary mode or C<":crlf"> for "text" mode.  If the DISCIPLINE is
451 omitted, it defaults to C<":raw">.
452
453 binmode() should be called after open() but before any I/O is done on
454 the filehandle.
455
456 On many systems binmode() currently has no effect, but in future, it
457 will be extended to support user-defined input and output disciplines.
458 On some systems binmode() is necessary when you're not working with a
459 text file.  For the sake of portability it is a good idea to always use
460 it when appropriate, and to never use it when it isn't appropriate.
461
462 In other words:  Regardless of platform, use binmode() on binary
463 files, and do not use binmode() on text files.
464
465 The C<open> pragma can be used to establish default disciplines.
466 See L<open>.
467
468 The operating system, device drivers, C libraries, and Perl run-time
469 system all work together to let the programmer treat a single
470 character (C<\n>) as the line terminator, irrespective of the external
471 representation.  On many operating systems, the native text file
472 representation matches the internal representation, but on some
473 platforms the external representation of C<\n> is made up of more than
474 one character.
475
476 Mac OS and all variants of Unix use a single character to end each line
477 in the external representation of text (even though that single
478 character is not necessarily the same across these platforms).
479 Consequently binmode() has no effect on these operating systems.  In
480 other systems like VMS, MS-DOS and the various flavors of MS-Windows
481 your program sees a C<\n> as a simple C<\cJ>, but what's stored in text
482 files are the two characters C<\cM\cJ>.  That means that, if you don't
483 use binmode() on these systems, C<\cM\cJ> sequences on disk will be
484 converted to C<\n> on input, and any C<\n> in your program will be
485 converted back to C<\cM\cJ> on output.  This is what you want for text
486 files, but it can be disastrous for binary files.
487
488 Another consequence of using binmode() (on some systems) is that
489 special end-of-file markers will be seen as part of the data stream.
490 For systems from the Microsoft family this means that if your binary
491 data contains C<\cZ>, the I/O subsystem will regard it as the end of
492 the file, unless you use binmode().
493
494 binmode() is not only important for readline() and print() operations,
495 but also when using read(), seek(), sysread(), syswrite() and tell()
496 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
497 in L<perlvar> for how to manually set your input and output
498 line-termination sequences.
499
500 =item bless REF,CLASSNAME
501
502 =item bless REF
503
504 This function tells the thingy referenced by REF that it is now an object
505 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
506 is used.  Because a C<bless> is often the last thing in a constructor,
507 it returns the reference for convenience.  Always use the two-argument
508 version if the function doing the blessing might be inherited by a
509 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
510 (and blessings) of objects.
511
512 Consider always blessing objects in CLASSNAMEs that are mixed case.
513 Namespaces with all lowercase names are considered reserved for
514 Perl pragmata.  Builtin types have all uppercase names, so to prevent
515 confusion, you may wish to avoid such package names as well.  Make sure
516 that CLASSNAME is a true value.
517
518 See L<perlmod/"Perl Modules">.
519
520 =item caller EXPR
521
522 =item caller
523
524 Returns the context of the current subroutine call.  In scalar context,
525 returns the caller's package name if there is a caller, that is, if
526 we're in a subroutine or C<eval> or C<require>, and the undefined value
527 otherwise.  In list context, returns
528
529     ($package, $filename, $line) = caller;
530
531 With EXPR, it returns some extra information that the debugger uses to
532 print a stack trace.  The value of EXPR indicates how many call frames
533 to go back before the current one.
534
535     ($package, $filename, $line, $subroutine, $hasargs,
536     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
537
538 Here $subroutine may be C<(eval)> if the frame is not a subroutine
539 call, but an C<eval>.  In such a case additional elements $evaltext and
540 C<$is_require> are set: C<$is_require> is true if the frame is created by a
541 C<require> or C<use> statement, $evaltext contains the text of the
542 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
543 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
544 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
545 frame.  C<$hasargs> is true if a new instance of C<@_> was set up for the
546 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
547 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
548 change between versions of Perl, and are not meant for external use.
549
550 Furthermore, when called from within the DB package, caller returns more
551 detailed information: it sets the list variable C<@DB::args> to be the
552 arguments with which the subroutine was invoked.
553
554 Be aware that the optimizer might have optimized call frames away before
555 C<caller> had a chance to get the information.  That means that C<caller(N)>
556 might not return information about the call frame you expect it do, for
557 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the 
558 previous time C<caller> was called.
559
560 =item chdir EXPR
561
562 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
563 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
564 changes to the directory specified by C<$ENV{LOGDIR}>.  If neither is
565 set, C<chdir> does nothing.  It returns true upon success, false
566 otherwise.  See the example under C<die>.
567
568 =item chmod LIST
569
570 Changes the permissions of a list of files.  The first element of the
571 list must be the numerical mode, which should probably be an octal
572 number, and which definitely should I<not> a string of octal digits:
573 C<0644> is okay, C<'0644'> is not.  Returns the number of files
574 successfully changed.  See also L</oct>, if all you have is a string.
575
576     $cnt = chmod 0755, 'foo', 'bar';
577     chmod 0755, @executables;
578     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
579                                              # --w----r-T
580     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
581     $mode = 0644;   chmod $mode, 'foo';      # this is best
582
583 You can also import the symbolic C<S_I*> constants from the Fcntl
584 module:
585
586     use Fcntl ':mode';
587
588     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
589     # This is identical to the chmod 0755 of the above example.
590
591 =item chomp VARIABLE
592
593 =item chomp LIST
594
595 =item chomp
596
597 This safer version of L</chop> removes any trailing string
598 that corresponds to the current value of C<$/> (also known as
599 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
600 number of characters removed from all its arguments.  It's often used to
601 remove the newline from the end of an input record when you're worried
602 that the final record may be missing its newline.  When in paragraph
603 mode (C<$/ = "">), it removes all trailing newlines from the string.
604 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
605 a reference to an integer or the like, see L<perlvar>) chomp() won't
606 remove anything.  
607 If VARIABLE is omitted, it chomps C<$_>.  Example:
608
609     while (<>) {
610         chomp;  # avoid \n on last field
611         @array = split(/:/);
612         # ...
613     }
614
615 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
616
617 You can actually chomp anything that's an lvalue, including an assignment:
618
619     chomp($cwd = `pwd`);
620     chomp($answer = <STDIN>);
621
622 If you chomp a list, each element is chomped, and the total number of
623 characters removed is returned.
624
625 =item chop VARIABLE
626
627 =item chop LIST
628
629 =item chop
630
631 Chops off the last character of a string and returns the character
632 chopped.  It's used primarily to remove the newline from the end of an
633 input record, but is much more efficient than C<s/\n//> because it neither
634 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
635 Example:
636
637     while (<>) {
638         chop;   # avoid \n on last field
639         @array = split(/:/);
640         #...
641     }
642
643 If VARIABLE is a hash, it chops the hash's values, but not its keys.
644
645 You can actually chop anything that's an lvalue, including an assignment:
646
647     chop($cwd = `pwd`);
648     chop($answer = <STDIN>);
649
650 If you chop a list, each element is chopped.  Only the value of the
651 last C<chop> is returned.
652
653 Note that C<chop> returns the last character.  To return all but the last
654 character, use C<substr($string, 0, -1)>.
655
656 =item chown LIST
657
658 Changes the owner (and group) of a list of files.  The first two
659 elements of the list must be the I<numeric> uid and gid, in that
660 order.  A value of -1 in either position is interpreted by most
661 systems to leave that value unchanged.  Returns the number of files
662 successfully changed.
663
664     $cnt = chown $uid, $gid, 'foo', 'bar';
665     chown $uid, $gid, @filenames;
666
667 Here's an example that looks up nonnumeric uids in the passwd file:
668
669     print "User: ";
670     chomp($user = <STDIN>);
671     print "Files: ";
672     chomp($pattern = <STDIN>);
673
674     ($login,$pass,$uid,$gid) = getpwnam($user)
675         or die "$user not in passwd file";
676
677     @ary = glob($pattern);      # expand filenames
678     chown $uid, $gid, @ary;
679
680 On most systems, you are not allowed to change the ownership of the
681 file unless you're the superuser, although you should be able to change
682 the group to any of your secondary groups.  On insecure systems, these
683 restrictions may be relaxed, but this is not a portable assumption.
684 On POSIX systems, you can detect this condition this way:
685
686     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
687     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
688
689 =item chr NUMBER
690
691 =item chr
692
693 Returns the character represented by that NUMBER in the character set.
694 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
695 chr(0x263a) is a Unicode smiley face. Within the scope of C<use utf8>, 
696 characters higher than 127 are encoded in Unicode; if you don't want
697 this, temporarily C<use bytes> or use C<pack("C*",...)>
698
699 For the reverse, use L</ord>.  
700 See L<utf8> for more about Unicode.
701
702 If NUMBER is omitted, uses C<$_>.
703
704 =item chroot FILENAME
705
706 =item chroot
707
708 This function works like the system call by the same name: it makes the
709 named directory the new root directory for all further pathnames that
710 begin with a C</> by your process and all its children.  (It doesn't
711 change your current working directory, which is unaffected.)  For security
712 reasons, this call is restricted to the superuser.  If FILENAME is
713 omitted, does a C<chroot> to C<$_>.
714
715 =item close FILEHANDLE
716
717 =item close
718
719 Closes the file or pipe associated with the file handle, returning true
720 only if stdio successfully flushes buffers and closes the system file
721 descriptor.  Closes the currently selected filehandle if the argument
722 is omitted.
723
724 You don't have to close FILEHANDLE if you are immediately going to do
725 another C<open> on it, because C<open> will close it for you.  (See
726 C<open>.)  However, an explicit C<close> on an input file resets the line
727 counter (C<$.>), while the implicit close done by C<open> does not.
728
729 If the file handle came from a piped open C<close> will additionally
730 return false if one of the other system calls involved fails or if the
731 program exits with non-zero status.  (If the only problem was that the
732 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe 
733 also waits for the process executing on the pipe to complete, in case you
734 want to look at the output of the pipe afterwards, and 
735 implicitly puts the exit status value of that command into C<$?>.
736
737 Prematurely closing the read end of a pipe (i.e. before the process
738 writing to it at the other end has closed it) will result in a
739 SIGPIPE being delivered to the writer.  If the other end can't
740 handle that, be sure to read all the data before closing the pipe.
741
742 Example:
743
744     open(OUTPUT, '|sort >foo')  # pipe to sort
745         or die "Can't start sort: $!";
746     #...                        # print stuff to output
747     close OUTPUT                # wait for sort to finish
748         or warn $! ? "Error closing sort pipe: $!"
749                    : "Exit status $? from sort";
750     open(INPUT, 'foo')          # get sort's results
751         or die "Can't open 'foo' for input: $!";
752
753 FILEHANDLE may be an expression whose value can be used as an indirect
754 filehandle, usually the real filehandle name.
755
756 =item closedir DIRHANDLE
757
758 Closes a directory opened by C<opendir> and returns the success of that
759 system call.
760
761 DIRHANDLE may be an expression whose value can be used as an indirect
762 dirhandle, usually the real dirhandle name.
763
764 =item connect SOCKET,NAME
765
766 Attempts to connect to a remote socket, just as the connect system call
767 does.  Returns true if it succeeded, false otherwise.  NAME should be a
768 packed address of the appropriate type for the socket.  See the examples in
769 L<perlipc/"Sockets: Client/Server Communication">.
770
771 =item continue BLOCK
772
773 Actually a flow control statement rather than a function.  If there is a
774 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
775 C<foreach>), it is always executed just before the conditional is about to
776 be evaluated again, just like the third part of a C<for> loop in C.  Thus
777 it can be used to increment a loop variable, even when the loop has been
778 continued via the C<next> statement (which is similar to the C C<continue>
779 statement).
780
781 C<last>, C<next>, or C<redo> may appear within a C<continue>
782 block.  C<last> and C<redo> will behave as if they had been executed within
783 the main block.  So will C<next>, but since it will execute a C<continue>
784 block, it may be more entertaining.
785
786     while (EXPR) {
787         ### redo always comes here
788         do_something;
789     } continue {
790         ### next always comes here
791         do_something_else;
792         # then back the top to re-check EXPR
793     }
794     ### last always comes here
795
796 Omitting the C<continue> section is semantically equivalent to using an
797 empty one, logically enough.  In that case, C<next> goes directly back
798 to check the condition at the top of the loop.
799
800 =item cos EXPR
801
802 =item cos
803
804 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
805 takes cosine of C<$_>.
806
807 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
808 function, or use this relation:
809
810     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
811
812 =item crypt PLAINTEXT,SALT
813
814 Encrypts a string exactly like the crypt(3) function in the C library
815 (assuming that you actually have a version there that has not been
816 extirpated as a potential munition).  This can prove useful for checking
817 the password file for lousy passwords, amongst other things.  Only the
818 guys wearing white hats should do this.
819
820 Note that C<crypt> is intended to be a one-way function, much like breaking
821 eggs to make an omelette.  There is no (known) corresponding decrypt
822 function.  As a result, this function isn't all that useful for
823 cryptography.  (For that, see your nearby CPAN mirror.)
824
825 When verifying an existing encrypted string you should use the encrypted
826 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
827 allows your code to work with the standard C<crypt> and with more
828 exotic implementations.  When choosing a new salt create a random two
829 character string whose characters come from the set C<[./0-9A-Za-z]>
830 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
831
832 Here's an example that makes sure that whoever runs this program knows
833 their own password:
834
835     $pwd = (getpwuid($<))[1];
836
837     system "stty -echo";
838     print "Password: ";
839     chomp($word = <STDIN>);
840     print "\n";
841     system "stty echo";
842
843     if (crypt($word, $pwd) ne $pwd) {
844         die "Sorry...\n";
845     } else {
846         print "ok\n";
847     }
848
849 Of course, typing in your own password to whoever asks you
850 for it is unwise.
851
852 The L<crypt> function is unsuitable for encrypting large quantities
853 of data, not least of all because you can't get the information
854 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
855 on your favorite CPAN mirror for a slew of potentially useful
856 modules.
857
858 =item dbmclose HASH
859
860 [This function has been largely superseded by the C<untie> function.]
861
862 Breaks the binding between a DBM file and a hash.
863
864 =item dbmopen HASH,DBNAME,MASK
865
866 [This function has been largely superseded by the C<tie> function.]
867
868 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
869 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
870 argument is I<not> a filehandle, even though it looks like one).  DBNAME
871 is the name of the database (without the F<.dir> or F<.pag> extension if
872 any).  If the database does not exist, it is created with protection
873 specified by MASK (as modified by the C<umask>).  If your system supports
874 only the older DBM functions, you may perform only one C<dbmopen> in your
875 program.  In older versions of Perl, if your system had neither DBM nor
876 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
877 sdbm(3).
878
879 If you don't have write access to the DBM file, you can only read hash
880 variables, not set them.  If you want to test whether you can write,
881 either use file tests or try setting a dummy hash entry inside an C<eval>,
882 which will trap the error.
883
884 Note that functions such as C<keys> and C<values> may return huge lists
885 when used on large DBM files.  You may prefer to use the C<each>
886 function to iterate over large DBM files.  Example:
887
888     # print out history file offsets
889     dbmopen(%HIST,'/usr/lib/news/history',0666);
890     while (($key,$val) = each %HIST) {
891         print $key, ' = ', unpack('L',$val), "\n";
892     }
893     dbmclose(%HIST);
894
895 See also L<AnyDBM_File> for a more general description of the pros and
896 cons of the various dbm approaches, as well as L<DB_File> for a particularly
897 rich implementation.
898
899 You can control which DBM library you use by loading that library
900 before you call dbmopen():
901
902     use DB_File;
903     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
904         or die "Can't open netscape history file: $!";
905
906 =item defined EXPR
907
908 =item defined
909
910 Returns a Boolean value telling whether EXPR has a value other than
911 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
912 checked.
913
914 Many operations return C<undef> to indicate failure, end of file,
915 system error, uninitialized variable, and other exceptional
916 conditions.  This function allows you to distinguish C<undef> from
917 other values.  (A simple Boolean test will not distinguish among
918 C<undef>, zero, the empty string, and C<"0">, which are all equally
919 false.)  Note that since C<undef> is a valid scalar, its presence
920 doesn't I<necessarily> indicate an exceptional condition: C<pop>
921 returns C<undef> when its argument is an empty array, I<or> when the
922 element to return happens to be C<undef>.
923
924 You may also use C<defined(&func)> to check whether subroutine C<&func>
925 has ever been defined.  The return value is unaffected by any forward
926 declarations of C<&foo>.
927
928 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
929 used to report whether memory for that aggregate has ever been
930 allocated.  This behavior may disappear in future versions of Perl.
931 You should instead use a simple test for size:
932
933     if (@an_array) { print "has array elements\n" }
934     if (%a_hash)   { print "has hash members\n"   }
935
936 When used on a hash element, it tells you whether the value is defined,
937 not whether the key exists in the hash.  Use L</exists> for the latter
938 purpose.
939
940 Examples:
941
942     print if defined $switch{'D'};
943     print "$val\n" while defined($val = pop(@ary));
944     die "Can't readlink $sym: $!"
945         unless defined($value = readlink $sym);
946     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
947     $debugging = 0 unless defined $debugging;
948
949 Note:  Many folks tend to overuse C<defined>, and then are surprised to
950 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
951 defined values.  For example, if you say
952
953     "ab" =~ /a(.*)b/;
954
955 The pattern match succeeds, and C<$1> is defined, despite the fact that it
956 matched "nothing".  But it didn't really match nothing--rather, it
957 matched something that happened to be zero characters long.  This is all
958 very above-board and honest.  When a function returns an undefined value,
959 it's an admission that it couldn't give you an honest answer.  So you
960 should use C<defined> only when you're questioning the integrity of what
961 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
962 what you want.
963
964 See also L</undef>, L</exists>, L</ref>.
965
966 =item delete EXPR
967
968 Given an expression that specifies a hash element, array element, hash slice,
969 or array slice, deletes the specified element(s) from the hash or array.
970 In the case of an array, if the array elements happen to be at the end,
971 the size of the array will shrink to the highest element that tests 
972 true for exists() (or 0 if no such element exists).
973
974 Returns each element so deleted or the undefined value if there was no such
975 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
976 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
977 from a C<tie>d hash or array may not necessarily return anything.
978
979 Deleting an array element effectively returns that position of the array
980 to its initial, uninitialized state.  Subsequently testing for the same
981 element with exists() will return false.  Note that deleting array
982 elements in the middle of an array will not shift the index of the ones
983 after them down--use splice() for that.  See L</exists>.
984
985 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
986
987     foreach $key (keys %HASH) {
988         delete $HASH{$key};
989     }
990
991     foreach $index (0 .. $#ARRAY) {
992         delete $ARRAY[$index];
993     }
994
995 And so do these:
996
997     delete @HASH{keys %HASH};
998
999     delete @ARRAY[0 .. $#ARRAY];
1000
1001 But both of these are slower than just assigning the empty list
1002 or undefining %HASH or @ARRAY:
1003
1004     %HASH = ();         # completely empty %HASH
1005     undef %HASH;        # forget %HASH ever existed
1006
1007     @ARRAY = ();        # completely empty @ARRAY
1008     undef @ARRAY;       # forget @ARRAY ever existed
1009
1010 Note that the EXPR can be arbitrarily complicated as long as the final
1011 operation is a hash element, array element,  hash slice, or array slice
1012 lookup:
1013
1014     delete $ref->[$x][$y]{$key};
1015     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1016
1017     delete $ref->[$x][$y][$index];
1018     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1019
1020 =item die LIST
1021
1022 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1023 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1024 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1025 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1026 an C<eval(),> the error message is stuffed into C<$@> and the
1027 C<eval> is terminated with the undefined value.  This makes
1028 C<die> the way to raise an exception.
1029
1030 Equivalent examples:
1031
1032     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1033     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1034
1035 If the value of EXPR does not end in a newline, the current script line
1036 number and input line number (if any) are also printed, and a newline
1037 is supplied.  Note that the "input line number" (also known as "chunk")
1038 is subject to whatever notion of "line" happens to be currently in
1039 effect, and is also available as the special variable C<$.>.
1040 See L<perlvar/"$/"> and L<perlvar/"$.">.
1041
1042 Hint: sometimes appending C<", stopped"> to your message
1043 will cause it to make better sense when the string C<"at foo line 123"> is
1044 appended.  Suppose you are running script "canasta".
1045
1046     die "/etc/games is no good";
1047     die "/etc/games is no good, stopped";
1048
1049 produce, respectively
1050
1051     /etc/games is no good at canasta line 123.
1052     /etc/games is no good, stopped at canasta line 123.
1053
1054 See also exit(), warn(), and the Carp module.
1055
1056 If LIST is empty and C<$@> already contains a value (typically from a
1057 previous eval) that value is reused after appending C<"\t...propagated">.
1058 This is useful for propagating exceptions:
1059
1060     eval { ... };
1061     die unless $@ =~ /Expected exception/;
1062
1063 If C<$@> is empty then the string C<"Died"> is used.
1064
1065 die() can also be called with a reference argument.  If this happens to be
1066 trapped within an eval(), $@ contains the reference.  This behavior permits
1067 a more elaborate exception handling implementation using objects that
1068 maintain arbitrary state about the nature of the exception.  Such a scheme
1069 is sometimes preferable to matching particular string values of $@ using
1070 regular expressions.  Here's an example:
1071
1072     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1073     if ($@) {
1074         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1075             # handle Some::Module::Exception
1076         }
1077         else {
1078             # handle all other possible exceptions
1079         }
1080     }
1081
1082 Because perl will stringify uncaught exception messages before displaying
1083 them, you may want to overload stringification operations on such custom
1084 exception objects.  See L<overload> for details about that.
1085
1086 You can arrange for a callback to be run just before the C<die>
1087 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1088 handler will be called with the error text and can change the error
1089 message, if it sees fit, by calling C<die> again.  See
1090 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1091 L<"eval BLOCK"> for some examples.  Although this feature was meant
1092 to be run only right before your program was to exit, this is not
1093 currently the case--the C<$SIG{__DIE__}> hook is currently called
1094 even inside eval()ed blocks/strings!  If one wants the hook to do
1095 nothing in such situations, put
1096
1097         die @_ if $^S;
1098
1099 as the first line of the handler (see L<perlvar/$^S>).  Because
1100 this promotes strange action at a distance, this counterintuitive
1101 behavior may be fixed in a future release.  
1102
1103 =item do BLOCK
1104
1105 Not really a function.  Returns the value of the last command in the
1106 sequence of commands indicated by BLOCK.  When modified by a loop
1107 modifier, executes the BLOCK once before testing the loop condition.
1108 (On other statements the loop modifiers test the conditional first.)
1109
1110 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1111 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1112 See L<perlsyn> for alternative strategies.
1113
1114 =item do SUBROUTINE(LIST)
1115
1116 A deprecated form of subroutine call.  See L<perlsub>.
1117
1118 =item do EXPR
1119
1120 Uses the value of EXPR as a filename and executes the contents of the
1121 file as a Perl script.  Its primary use is to include subroutines
1122 from a Perl subroutine library.
1123
1124     do 'stat.pl';
1125
1126 is just like
1127
1128     scalar eval `cat stat.pl`;
1129
1130 except that it's more efficient and concise, keeps track of the current
1131 filename for error messages, searches the @INC libraries, and updates
1132 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1133 variables.  It also differs in that code evaluated with C<do FILENAME>
1134 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1135 same, however, in that it does reparse the file every time you call it,
1136 so you probably don't want to do this inside a loop.
1137
1138 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1139 error.  If C<do> can read the file but cannot compile it, it
1140 returns undef and sets an error message in C<$@>.   If the file is
1141 successfully compiled, C<do> returns the value of the last expression
1142 evaluated.
1143
1144 Note that inclusion of library modules is better done with the
1145 C<use> and C<require> operators, which also do automatic error checking
1146 and raise an exception if there's a problem.
1147
1148 You might like to use C<do> to read in a program configuration
1149 file.  Manual error checking can be done this way:
1150
1151     # read in config files: system first, then user 
1152     for $file ("/share/prog/defaults.rc",
1153                "$ENV{HOME}/.someprogrc") 
1154    {
1155         unless ($return = do $file) {
1156             warn "couldn't parse $file: $@" if $@;
1157             warn "couldn't do $file: $!"    unless defined $return;
1158             warn "couldn't run $file"       unless $return;
1159         }
1160     }
1161
1162 =item dump LABEL
1163
1164 =item dump
1165
1166 This function causes an immediate core dump.  See also the B<-u>
1167 command-line switch in L<perlrun>, which does the same thing.
1168 Primarily this is so that you can use the B<undump> program (not
1169 supplied) to turn your core dump into an executable binary after
1170 having initialized all your variables at the beginning of the
1171 program.  When the new binary is executed it will begin by executing
1172 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1173 Think of it as a goto with an intervening core dump and reincarnation.
1174 If C<LABEL> is omitted, restarts the program from the top.
1175
1176 B<WARNING>: Any files opened at the time of the dump will I<not>
1177 be open any more when the program is reincarnated, with possible
1178 resulting confusion on the part of Perl.  
1179
1180 This function is now largely obsolete, partly because it's very
1181 hard to convert a core file into an executable, and because the
1182 real compiler backends for generating portable bytecode and compilable
1183 C code have superseded it.
1184
1185 If you're looking to use L<dump> to speed up your program, consider
1186 generating bytecode or native C code as described in L<perlcc>.  If
1187 you're just trying to accelerate a CGI script, consider using the
1188 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1189 You might also consider autoloading or selfloading, which at least
1190 make your program I<appear> to run faster.  
1191
1192 =item each HASH
1193
1194 When called in list context, returns a 2-element list consisting of the
1195 key and value for the next element of a hash, so that you can iterate over
1196 it.  When called in scalar context, returns the key for only the "next"
1197 element in the hash.
1198
1199 Entries are returned in an apparently random order.  The actual random
1200 order is subject to change in future versions of perl, but it is guaranteed
1201 to be in the same order as either the C<keys> or C<values> function
1202 would produce on the same (unmodified) hash.
1203
1204 When the hash is entirely read, a null array is returned in list context
1205 (which when assigned produces a false (C<0>) value), and C<undef> in
1206 scalar context.  The next call to C<each> after that will start iterating
1207 again.  There is a single iterator for each hash, shared by all C<each>,
1208 C<keys>, and C<values> function calls in the program; it can be reset by
1209 reading all the elements from the hash, or by evaluating C<keys HASH> or
1210 C<values HASH>.  If you add or delete elements of a hash while you're
1211 iterating over it, you may get entries skipped or duplicated, so don't.
1212
1213 The following prints out your environment like the printenv(1) program,
1214 only in a different order:
1215
1216     while (($key,$value) = each %ENV) {
1217         print "$key=$value\n";
1218     }
1219
1220 See also C<keys>, C<values> and C<sort>.
1221
1222 =item eof FILEHANDLE
1223
1224 =item eof ()
1225
1226 =item eof
1227
1228 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1229 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1230 gives the real filehandle.  (Note that this function actually
1231 reads a character and then C<ungetc>s it, so isn't very useful in an
1232 interactive context.)  Do not read from a terminal file (or call
1233 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1234 as terminals may lose the end-of-file condition if you do.
1235
1236 An C<eof> without an argument uses the last file read.  Using C<eof()>
1237 with empty parentheses is very different.  It refers to the pseudo file
1238 formed from the files listed on the command line and accessed via the
1239 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1240 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1241 used will cause C<@ARGV> to be examined to determine if input is
1242 available.
1243
1244 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1245 detect the end of each file, C<eof()> will only detect the end of the
1246 last file.  Examples:
1247
1248     # reset line numbering on each input file
1249     while (<>) {
1250         next if /^\s*#/;        # skip comments 
1251         print "$.\t$_";
1252     } continue {
1253         close ARGV  if eof;     # Not eof()!
1254     }
1255
1256     # insert dashes just before last line of last file
1257     while (<>) {
1258         if (eof()) {            # check for end of current file
1259             print "--------------\n";
1260             close(ARGV);        # close or last; is needed if we
1261                                 # are reading from the terminal
1262         }
1263         print;
1264     }
1265
1266 Practical hint: you almost never need to use C<eof> in Perl, because the
1267 input operators typically return C<undef> when they run out of data, or if
1268 there was an error.
1269
1270 =item eval EXPR
1271
1272 =item eval BLOCK
1273
1274 In the first form, the return value of EXPR is parsed and executed as if it
1275 were a little Perl program.  The value of the expression (which is itself
1276 determined within scalar context) is first parsed, and if there weren't any
1277 errors, executed in the lexical context of the current Perl program, so
1278 that any variable settings or subroutine and format definitions remain
1279 afterwards.  Note that the value is parsed every time the eval executes.
1280 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1281 delay parsing and subsequent execution of the text of EXPR until run time.
1282
1283 In the second form, the code within the BLOCK is parsed only once--at the
1284 same time the code surrounding the eval itself was parsed--and executed
1285 within the context of the current Perl program.  This form is typically
1286 used to trap exceptions more efficiently than the first (see below), while
1287 also providing the benefit of checking the code within BLOCK at compile
1288 time.
1289
1290 The final semicolon, if any, may be omitted from the value of EXPR or within
1291 the BLOCK.
1292
1293 In both forms, the value returned is the value of the last expression
1294 evaluated inside the mini-program; a return statement may be also used, just
1295 as with subroutines.  The expression providing the return value is evaluated
1296 in void, scalar, or list context, depending on the context of the eval itself.
1297 See L</wantarray> for more on how the evaluation context can be determined.
1298
1299 If there is a syntax error or runtime error, or a C<die> statement is
1300 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1301 error message.  If there was no error, C<$@> is guaranteed to be a null
1302 string.  Beware that using C<eval> neither silences perl from printing
1303 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1304 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1305 L</warn> and L<perlvar>.
1306
1307 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1308 determining whether a particular feature (such as C<socket> or C<symlink>)
1309 is implemented.  It is also Perl's exception trapping mechanism, where
1310 the die operator is used to raise exceptions.
1311
1312 If the code to be executed doesn't vary, you may use the eval-BLOCK
1313 form to trap run-time errors without incurring the penalty of
1314 recompiling each time.  The error, if any, is still returned in C<$@>.
1315 Examples:
1316
1317     # make divide-by-zero nonfatal
1318     eval { $answer = $a / $b; }; warn $@ if $@;
1319
1320     # same thing, but less efficient
1321     eval '$answer = $a / $b'; warn $@ if $@;
1322
1323     # a compile-time error
1324     eval { $answer = };                 # WRONG
1325
1326     # a run-time error
1327     eval '$answer =';   # sets $@
1328
1329 Due to the current arguably broken state of C<__DIE__> hooks, when using
1330 the C<eval{}> form as an exception trap in libraries, you may wish not
1331 to trigger any C<__DIE__> hooks that user code may have installed.
1332 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1333 as shown in this example:
1334
1335     # a very private exception trap for divide-by-zero
1336     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1337     warn $@ if $@;
1338
1339 This is especially significant, given that C<__DIE__> hooks can call
1340 C<die> again, which has the effect of changing their error messages:
1341
1342     # __DIE__ hooks may modify error messages
1343     {
1344        local $SIG{'__DIE__'} =
1345               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1346        eval { die "foo lives here" };
1347        print $@ if $@;                # prints "bar lives here"
1348     }
1349
1350 Because this promotes action at a distance, this counterintuitive behavior
1351 may be fixed in a future release.
1352
1353 With an C<eval>, you should be especially careful to remember what's
1354 being looked at when:
1355
1356     eval $x;            # CASE 1
1357     eval "$x";          # CASE 2
1358
1359     eval '$x';          # CASE 3
1360     eval { $x };        # CASE 4
1361
1362     eval "\$$x++";      # CASE 5
1363     $$x++;              # CASE 6
1364
1365 Cases 1 and 2 above behave identically: they run the code contained in
1366 the variable $x.  (Although case 2 has misleading double quotes making
1367 the reader wonder what else might be happening (nothing is).)  Cases 3
1368 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1369 does nothing but return the value of $x.  (Case 4 is preferred for
1370 purely visual reasons, but it also has the advantage of compiling at
1371 compile-time instead of at run-time.)  Case 5 is a place where
1372 normally you I<would> like to use double quotes, except that in this
1373 particular situation, you can just use symbolic references instead, as
1374 in case 6.
1375
1376 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1377 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1378
1379 =item exec LIST
1380
1381 =item exec PROGRAM LIST
1382
1383 The C<exec> function executes a system command I<and never returns>--
1384 use C<system> instead of C<exec> if you want it to return.  It fails and
1385 returns false only if the command does not exist I<and> it is executed
1386 directly instead of via your system's command shell (see below).
1387
1388 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1389 warns you if there is a following statement which isn't C<die>, C<warn>,
1390 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1391 I<really> want to follow an C<exec> with some other statement, you
1392 can use one of these styles to avoid the warning:
1393
1394     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1395     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1396
1397 If there is more than one argument in LIST, or if LIST is an array
1398 with more than one value, calls execvp(3) with the arguments in LIST.
1399 If there is only one scalar argument or an array with one element in it,
1400 the argument is checked for shell metacharacters, and if there are any,
1401 the entire argument is passed to the system's command shell for parsing
1402 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1403 If there are no shell metacharacters in the argument, it is split into
1404 words and passed directly to C<execvp>, which is more efficient.  
1405 Examples:
1406
1407     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1408     exec "sort $outfile | uniq";
1409
1410 If you don't really want to execute the first argument, but want to lie
1411 to the program you are executing about its own name, you can specify
1412 the program you actually want to run as an "indirect object" (without a
1413 comma) in front of the LIST.  (This always forces interpretation of the
1414 LIST as a multivalued list, even if there is only a single scalar in
1415 the list.)  Example:
1416
1417     $shell = '/bin/csh';
1418     exec $shell '-sh';          # pretend it's a login shell
1419
1420 or, more directly,
1421
1422     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1423
1424 When the arguments get executed via the system shell, results will
1425 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1426 for details.
1427
1428 Using an indirect object with C<exec> or C<system> is also more
1429 secure.  This usage (which also works fine with system()) forces
1430 interpretation of the arguments as a multivalued list, even if the
1431 list had just one argument.  That way you're safe from the shell
1432 expanding wildcards or splitting up words with whitespace in them.
1433
1434     @args = ( "echo surprise" );
1435
1436     exec @args;               # subject to shell escapes
1437                                 # if @args == 1
1438     exec { $args[0] } @args;  # safe even with one-arg list
1439
1440 The first version, the one without the indirect object, ran the I<echo>
1441 program, passing it C<"surprise"> an argument.  The second version
1442 didn't--it tried to run a program literally called I<"echo surprise">,
1443 didn't find it, and set C<$?> to a non-zero value indicating failure.
1444
1445 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1446 output before the exec, but this may not be supported on some platforms
1447 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1448 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1449 open handles in order to avoid lost output.
1450
1451 Note that C<exec> will not call your C<END> blocks, nor will it call
1452 any C<DESTROY> methods in your objects.
1453
1454 =item exists EXPR
1455
1456 Given an expression that specifies a hash element or array element,
1457 returns true if the specified element in the hash or array has ever
1458 been initialized, even if the corresponding value is undefined.  The
1459 element is not autovivified if it doesn't exist.
1460
1461     print "Exists\n"    if exists $hash{$key};
1462     print "Defined\n"   if defined $hash{$key};
1463     print "True\n"      if $hash{$key};
1464
1465     print "Exists\n"    if exists $array[$index];
1466     print "Defined\n"   if defined $array[$index];
1467     print "True\n"      if $array[$index];
1468
1469 A hash or array element can be true only if it's defined, and defined if
1470 it exists, but the reverse doesn't necessarily hold true.
1471
1472 Given an expression that specifies the name of a subroutine,
1473 returns true if the specified subroutine has ever been declared, even
1474 if it is undefined.  Mentioning a subroutine name for exists or defined
1475 does not count as declaring it.
1476
1477     print "Exists\n"    if exists &subroutine;
1478     print "Defined\n"   if defined &subroutine;
1479
1480 Note that the EXPR can be arbitrarily complicated as long as the final
1481 operation is a hash or array key lookup or subroutine name:
1482
1483     if (exists $ref->{A}->{B}->{$key})  { }
1484     if (exists $hash{A}{B}{$key})       { }
1485
1486     if (exists $ref->{A}->{B}->[$ix])   { }
1487     if (exists $hash{A}{B}[$ix])        { }
1488
1489     if (exists &{$ref->{A}{B}{$key}})   { }
1490
1491 Although the deepest nested array or hash will not spring into existence
1492 just because its existence was tested, any intervening ones will.
1493 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1494 into existence due to the existence test for the $key element above.
1495 This happens anywhere the arrow operator is used, including even:
1496
1497     undef $ref;
1498     if (exists $ref->{"Some key"})      { }
1499     print $ref;             # prints HASH(0x80d3d5c)
1500
1501 This surprising autovivification in what does not at first--or even
1502 second--glance appear to be an lvalue context may be fixed in a future
1503 release.
1504
1505 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1506 on how exists() acts when used on a pseudo-hash.
1507
1508 Use of a subroutine call, rather than a subroutine name, as an argument
1509 to exists() is an error.
1510
1511     exists &sub;        # OK
1512     exists &sub();      # Error
1513
1514 =item exit EXPR
1515
1516 Evaluates EXPR and exits immediately with that value.    Example:
1517
1518     $ans = <STDIN>;
1519     exit 0 if $ans =~ /^[Xx]/;
1520
1521 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1522 universally recognized values for EXPR are C<0> for success and C<1>
1523 for error; other values are subject to interpretation depending on the
1524 environment in which the Perl program is running.  For example, exiting
1525 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1526 the mailer to return the item undelivered, but that's not true everywhere.
1527
1528 Don't use C<exit> to abort a subroutine if there's any chance that
1529 someone might want to trap whatever error happened.  Use C<die> instead,
1530 which can be trapped by an C<eval>.
1531
1532 The exit() function does not always exit immediately.  It calls any
1533 defined C<END> routines first, but these C<END> routines may not
1534 themselves abort the exit.  Likewise any object destructors that need to
1535 be called are called before the real exit.  If this is a problem, you
1536 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1537 See L<perlmod> for details.
1538
1539 =item exp EXPR
1540
1541 =item exp
1542
1543 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1544 If EXPR is omitted, gives C<exp($_)>.
1545
1546 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1547
1548 Implements the fcntl(2) function.  You'll probably have to say
1549
1550     use Fcntl;
1551
1552 first to get the correct constant definitions.  Argument processing and
1553 value return works just like C<ioctl> below.  
1554 For example:
1555
1556     use Fcntl;
1557     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1558         or die "can't fcntl F_GETFL: $!";
1559
1560 You don't have to check for C<defined> on the return from C<fnctl>.
1561 Like C<ioctl>, it maps a C<0> return from the system call into
1562 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1563 in numeric context.  It is also exempt from the normal B<-w> warnings
1564 on improper numeric conversions.
1565
1566 Note that C<fcntl> will produce a fatal error if used on a machine that
1567 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1568 manpage to learn what functions are available on your system.
1569
1570 =item fileno FILEHANDLE
1571
1572 Returns the file descriptor for a filehandle, or undefined if the
1573 filehandle is not open.  This is mainly useful for constructing
1574 bitmaps for C<select> and low-level POSIX tty-handling operations.
1575 If FILEHANDLE is an expression, the value is taken as an indirect
1576 filehandle, generally its name.
1577
1578 You can use this to find out whether two handles refer to the 
1579 same underlying descriptor:
1580
1581     if (fileno(THIS) == fileno(THAT)) {
1582         print "THIS and THAT are dups\n";
1583     } 
1584
1585 =item flock FILEHANDLE,OPERATION
1586
1587 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1588 for success, false on failure.  Produces a fatal error if used on a
1589 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1590 C<flock> is Perl's portable file locking interface, although it locks
1591 only entire files, not records.
1592
1593 Two potentially non-obvious but traditional C<flock> semantics are
1594 that it waits indefinitely until the lock is granted, and that its locks
1595 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1596 fewer guarantees.  This means that files locked with C<flock> may be
1597 modified by programs that do not also use C<flock>.  See L<perlport>,
1598 your port's specific documentation, or your system-specific local manpages
1599 for details.  It's best to assume traditional behavior if you're writing
1600 portable programs.  (But if you're not, you should as always feel perfectly
1601 free to write for your own system's idiosyncrasies (sometimes called
1602 "features").  Slavish adherence to portability concerns shouldn't get
1603 in the way of your getting your job done.)
1604
1605 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1606 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1607 you can use the symbolic names if you import them from the Fcntl module,
1608 either individually, or as a group using the ':flock' tag.  LOCK_SH
1609 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1610 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1611 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1612 waiting for the lock (check the return status to see if you got it).
1613
1614 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1615 before locking or unlocking it.
1616
1617 Note that the emulation built with lockf(3) doesn't provide shared
1618 locks, and it requires that FILEHANDLE be open with write intent.  These
1619 are the semantics that lockf(3) implements.  Most if not all systems
1620 implement lockf(3) in terms of fcntl(2) locking, though, so the
1621 differing semantics shouldn't bite too many people.
1622
1623 Note also that some versions of C<flock> cannot lock things over the
1624 network; you would need to use the more system-specific C<fcntl> for
1625 that.  If you like you can force Perl to ignore your system's flock(2)
1626 function, and so provide its own fcntl(2)-based emulation, by passing
1627 the switch C<-Ud_flock> to the F<Configure> program when you configure
1628 perl.
1629
1630 Here's a mailbox appender for BSD systems.
1631
1632     use Fcntl ':flock'; # import LOCK_* constants
1633
1634     sub lock {
1635         flock(MBOX,LOCK_EX);
1636         # and, in case someone appended
1637         # while we were waiting...
1638         seek(MBOX, 0, 2);
1639     }
1640
1641     sub unlock {
1642         flock(MBOX,LOCK_UN);
1643     }
1644
1645     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1646             or die "Can't open mailbox: $!";
1647
1648     lock();
1649     print MBOX $msg,"\n\n";
1650     unlock();
1651
1652 On systems that support a real flock(), locks are inherited across fork()
1653 calls, whereas those that must resort to the more capricious fcntl()
1654 function lose the locks, making it harder to write servers.
1655
1656 See also L<DB_File> for other flock() examples.
1657
1658 =item fork
1659
1660 Does a fork(2) system call to create a new process running the
1661 same program at the same point.  It returns the child pid to the
1662 parent process, C<0> to the child process, or C<undef> if the fork is
1663 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1664 are shared, while everything else is copied.  On most systems supporting
1665 fork(), great care has gone into making it extremely efficient (for
1666 example, using copy-on-write technology on data pages), making it the
1667 dominant paradigm for multitasking over the last few decades.
1668
1669 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1670 output before forking the child process, but this may not be supported
1671 on some platforms (see L<perlport>).  To be safe, you may need to set
1672 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1673 C<IO::Handle> on any open handles in order to avoid duplicate output.
1674
1675 If you C<fork> without ever waiting on your children, you will
1676 accumulate zombies.  On some systems, you can avoid this by setting
1677 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1678 forking and reaping moribund children.
1679
1680 Note that if your forked child inherits system file descriptors like
1681 STDIN and STDOUT that are actually connected by a pipe or socket, even
1682 if you exit, then the remote server (such as, say, a CGI script or a
1683 backgrounded job launched from a remote shell) won't think you're done.
1684 You should reopen those to F</dev/null> if it's any issue.
1685
1686 =item format
1687
1688 Declare a picture format for use by the C<write> function.  For
1689 example:
1690
1691     format Something =
1692         Test: @<<<<<<<< @||||| @>>>>>
1693               $str,     $%,    '$' . int($num)
1694     .
1695
1696     $str = "widget";
1697     $num = $cost/$quantity;
1698     $~ = 'Something';
1699     write;
1700
1701 See L<perlform> for many details and examples.
1702
1703 =item formline PICTURE,LIST
1704
1705 This is an internal function used by C<format>s, though you may call it,
1706 too.  It formats (see L<perlform>) a list of values according to the
1707 contents of PICTURE, placing the output into the format output
1708 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1709 Eventually, when a C<write> is done, the contents of
1710 C<$^A> are written to some filehandle, but you could also read C<$^A>
1711 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1712 does one C<formline> per line of form, but the C<formline> function itself
1713 doesn't care how many newlines are embedded in the PICTURE.  This means
1714 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1715 You may therefore need to use multiple formlines to implement a single
1716 record format, just like the format compiler.
1717
1718 Be careful if you put double quotes around the picture, because an C<@>
1719 character may be taken to mean the beginning of an array name.
1720 C<formline> always returns true.  See L<perlform> for other examples.
1721
1722 =item getc FILEHANDLE
1723
1724 =item getc
1725
1726 Returns the next character from the input file attached to FILEHANDLE,
1727 or the undefined value at end of file, or if there was an error.
1728 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1729 efficient.  However, it cannot be used by itself to fetch single
1730 characters without waiting for the user to hit enter.  For that, try
1731 something more like:
1732
1733     if ($BSD_STYLE) {
1734         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1735     }
1736     else {
1737         system "stty", '-icanon', 'eol', "\001";
1738     }
1739
1740     $key = getc(STDIN);
1741
1742     if ($BSD_STYLE) {
1743         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1744     }
1745     else {
1746         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1747     }
1748     print "\n";
1749
1750 Determination of whether $BSD_STYLE should be set
1751 is left as an exercise to the reader.
1752
1753 The C<POSIX::getattr> function can do this more portably on
1754 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1755 module from your nearest CPAN site; details on CPAN can be found on
1756 L<perlmodlib/CPAN>.
1757
1758 =item getlogin
1759
1760 Implements the C library function of the same name, which on most
1761 systems returns the current login from F</etc/utmp>, if any.  If null,
1762 use C<getpwuid>.
1763
1764     $login = getlogin || getpwuid($<) || "Kilroy";
1765
1766 Do not consider C<getlogin> for authentication: it is not as
1767 secure as C<getpwuid>.
1768
1769 =item getpeername SOCKET
1770
1771 Returns the packed sockaddr address of other end of the SOCKET connection.
1772
1773     use Socket;
1774     $hersockaddr    = getpeername(SOCK);
1775     ($port, $iaddr) = sockaddr_in($hersockaddr);
1776     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1777     $herstraddr     = inet_ntoa($iaddr);
1778
1779 =item getpgrp PID
1780
1781 Returns the current process group for the specified PID.  Use
1782 a PID of C<0> to get the current process group for the
1783 current process.  Will raise an exception if used on a machine that
1784 doesn't implement getpgrp(2).  If PID is omitted, returns process
1785 group of current process.  Note that the POSIX version of C<getpgrp>
1786 does not accept a PID argument, so only C<PID==0> is truly portable.
1787
1788 =item getppid
1789
1790 Returns the process id of the parent process.
1791
1792 =item getpriority WHICH,WHO
1793
1794 Returns the current priority for a process, a process group, or a user.
1795 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1796 machine that doesn't implement getpriority(2).
1797
1798 =item getpwnam NAME
1799
1800 =item getgrnam NAME
1801
1802 =item gethostbyname NAME
1803
1804 =item getnetbyname NAME
1805
1806 =item getprotobyname NAME
1807
1808 =item getpwuid UID
1809
1810 =item getgrgid GID
1811
1812 =item getservbyname NAME,PROTO
1813
1814 =item gethostbyaddr ADDR,ADDRTYPE
1815
1816 =item getnetbyaddr ADDR,ADDRTYPE
1817
1818 =item getprotobynumber NUMBER
1819
1820 =item getservbyport PORT,PROTO
1821
1822 =item getpwent
1823
1824 =item getgrent
1825
1826 =item gethostent
1827
1828 =item getnetent
1829
1830 =item getprotoent
1831
1832 =item getservent
1833
1834 =item setpwent
1835
1836 =item setgrent
1837
1838 =item sethostent STAYOPEN
1839
1840 =item setnetent STAYOPEN
1841
1842 =item setprotoent STAYOPEN
1843
1844 =item setservent STAYOPEN
1845
1846 =item endpwent
1847
1848 =item endgrent
1849
1850 =item endhostent
1851
1852 =item endnetent
1853
1854 =item endprotoent
1855
1856 =item endservent
1857
1858 These routines perform the same functions as their counterparts in the
1859 system library.  In list context, the return values from the
1860 various get routines are as follows:
1861
1862     ($name,$passwd,$uid,$gid,
1863        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1864     ($name,$passwd,$gid,$members) = getgr*
1865     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1866     ($name,$aliases,$addrtype,$net) = getnet*
1867     ($name,$aliases,$proto) = getproto*
1868     ($name,$aliases,$port,$proto) = getserv*
1869
1870 (If the entry doesn't exist you get a null list.)
1871
1872 The exact meaning of the $gcos field varies but it usually contains
1873 the real name of the user (as opposed to the login name) and other
1874 information pertaining to the user.  Beware, however, that in many
1875 system users are able to change this information and therefore it
1876 cannot be trusted and therefore the $gcos is tainted (see
1877 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1878 login shell, are also tainted, because of the same reason.
1879
1880 In scalar context, you get the name, unless the function was a
1881 lookup by name, in which case you get the other thing, whatever it is.
1882 (If the entry doesn't exist you get the undefined value.)  For example:
1883
1884     $uid   = getpwnam($name);
1885     $name  = getpwuid($num);
1886     $name  = getpwent();
1887     $gid   = getgrnam($name);
1888     $name  = getgrgid($num;
1889     $name  = getgrent();
1890     #etc.
1891
1892 In I<getpw*()> the fields $quota, $comment, and $expire are special
1893 cases in the sense that in many systems they are unsupported.  If the
1894 $quota is unsupported, it is an empty scalar.  If it is supported, it
1895 usually encodes the disk quota.  If the $comment field is unsupported,
1896 it is an empty scalar.  If it is supported it usually encodes some
1897 administrative comment about the user.  In some systems the $quota
1898 field may be $change or $age, fields that have to do with password
1899 aging.  In some systems the $comment field may be $class.  The $expire
1900 field, if present, encodes the expiration period of the account or the
1901 password.  For the availability and the exact meaning of these fields
1902 in your system, please consult your getpwnam(3) documentation and your
1903 F<pwd.h> file.  You can also find out from within Perl what your
1904 $quota and $comment fields mean and whether you have the $expire field
1905 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1906 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1907 files are only supported if your vendor has implemented them in the
1908 intuitive fashion that calling the regular C library routines gets the
1909 shadow versions if you're running under privilege or if there exists
1910 the shadow(3) functions as found in System V ( this includes Solaris
1911 and Linux.)  Those systems which implement a proprietary shadow password
1912 facility are unlikely to be supported.
1913
1914 The $members value returned by I<getgr*()> is a space separated list of
1915 the login names of the members of the group.
1916
1917 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1918 C, it will be returned to you via C<$?> if the function call fails.  The
1919 C<@addrs> value returned by a successful call is a list of the raw
1920 addresses returned by the corresponding system library call.  In the
1921 Internet domain, each address is four bytes long and you can unpack it
1922 by saying something like:
1923
1924     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1925
1926 The Socket library makes this slightly easier:
1927
1928     use Socket;
1929     $iaddr = inet_aton("127.1"); # or whatever address
1930     $name  = gethostbyaddr($iaddr, AF_INET);
1931
1932     # or going the other way
1933     $straddr = inet_ntoa($iaddr);
1934
1935 If you get tired of remembering which element of the return list
1936 contains which return value, by-name interfaces are provided
1937 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1938 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1939 and C<User::grent>.  These override the normal built-ins, supplying
1940 versions that return objects with the appropriate names
1941 for each field.  For example:
1942
1943    use File::stat;
1944    use User::pwent;
1945    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1946
1947 Even though it looks like they're the same method calls (uid), 
1948 they aren't, because a C<File::stat> object is different from 
1949 a C<User::pwent> object.
1950
1951 =item getsockname SOCKET
1952
1953 Returns the packed sockaddr address of this end of the SOCKET connection,
1954 in case you don't know the address because you have several different
1955 IPs that the connection might have come in on.
1956
1957     use Socket;
1958     $mysockaddr = getsockname(SOCK);
1959     ($port, $myaddr) = sockaddr_in($mysockaddr);
1960     printf "Connect to %s [%s]\n", 
1961        scalar gethostbyaddr($myaddr, AF_INET),
1962        inet_ntoa($myaddr);
1963
1964 =item getsockopt SOCKET,LEVEL,OPTNAME
1965
1966 Returns the socket option requested, or undef if there is an error.
1967
1968 =item glob EXPR
1969
1970 =item glob
1971
1972 Returns the value of EXPR with filename expansions such as the
1973 standard Unix shell F</bin/csh> would do.  This is the internal function
1974 implementing the C<< <*.c> >> operator, but you can use it directly.
1975 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
1976 discussed in more detail in L<perlop/"I/O Operators">.
1977
1978 Beginning with v5.6.0, this operator is implemented using the standard
1979 C<File::Glob> extension.  See L<File::Glob> for details.
1980
1981 =item gmtime EXPR
1982
1983 Converts a time as returned by the time function to a 8-element list
1984 with the time localized for the standard Greenwich time zone.
1985 Typically used as follows:
1986
1987     #  0    1    2     3     4    5     6     7  
1988     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
1989                                             gmtime(time);
1990
1991 All list elements are numeric, and come straight out of the C `struct
1992 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
1993 specified time.  $mday is the day of the month, and $mon is the month
1994 itself, in the range C<0..11> with 0 indicating January and 11
1995 indicating December.  $year is the number of years since 1900.  That
1996 is, $year is C<123> in year 2023.  $wday is the day of the week, with
1997 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
1998 the year, in the range C<0..364> (or C<0..365> in leap years.)  
1999
2000 Note that the $year element is I<not> simply the last two digits of
2001 the year.  If you assume it is, then you create non-Y2K-compliant
2002 programs--and you wouldn't want to do that, would you?
2003
2004 The proper way to get a complete 4-digit year is simply:
2005
2006         $year += 1900;
2007
2008 And to get the last two digits of the year (e.g., '01' in 2001) do:
2009
2010         $year = sprintf("%02d", $year % 100);
2011
2012 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2013
2014 In scalar context, C<gmtime()> returns the ctime(3) value:
2015
2016     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2017
2018 Also see the C<timegm> function provided by the C<Time::Local> module,
2019 and the strftime(3) function available via the POSIX module.
2020
2021 This scalar value is B<not> locale dependent (see L<perllocale>), but
2022 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2023 strftime(3) and mktime(3) functions available via the POSIX module.  To
2024 get somewhat similar but locale dependent date strings, set up your
2025 locale environment variables appropriately (please see L<perllocale>)
2026 and try for example:
2027
2028     use POSIX qw(strftime);
2029     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2030
2031 Note that the C<%a> and C<%b> escapes, which represent the short forms
2032 of the day of the week and the month of the year, may not necessarily
2033 be three characters wide in all locales.
2034
2035 =item goto LABEL
2036
2037 =item goto EXPR
2038
2039 =item goto &NAME
2040
2041 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2042 execution there.  It may not be used to go into any construct that
2043 requires initialization, such as a subroutine or a C<foreach> loop.  It
2044 also can't be used to go into a construct that is optimized away,
2045 or to get out of a block or subroutine given to C<sort>.
2046 It can be used to go almost anywhere else within the dynamic scope,
2047 including out of subroutines, but it's usually better to use some other
2048 construct such as C<last> or C<die>.  The author of Perl has never felt the
2049 need to use this form of C<goto> (in Perl, that is--C is another matter).
2050
2051 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2052 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2053 necessarily recommended if you're optimizing for maintainability:
2054
2055     goto ("FOO", "BAR", "GLARCH")[$i];
2056
2057 The C<goto-&NAME> form is quite different from the other forms of C<goto>.
2058 In fact, it isn't a goto in the normal sense at all, and doesn't have
2059 the stigma associated with other gotos.  Instead, it
2060 substitutes a call to the named subroutine for the currently running
2061 subroutine.  This is used by C<AUTOLOAD> subroutines that wish to load
2062 another subroutine and then pretend that the other subroutine had been
2063 called in the first place (except that any modifications to C<@_>
2064 in the current subroutine are propagated to the other subroutine.)
2065 After the C<goto>, not even C<caller> will be able to tell that this
2066 routine was called first.
2067
2068 NAME needn't be the name of a subroutine; it can be a scalar variable
2069 containing a code reference, or a block which evaluates to a code
2070 reference.
2071
2072 =item grep BLOCK LIST
2073
2074 =item grep EXPR,LIST
2075
2076 This is similar in spirit to, but not the same as, grep(1) and its
2077 relatives.  In particular, it is not limited to using regular expressions.
2078
2079 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2080 C<$_> to each element) and returns the list value consisting of those
2081 elements for which the expression evaluated to true.  In scalar
2082 context, returns the number of times the expression was true.
2083
2084     @foo = grep(!/^#/, @bar);    # weed out comments
2085
2086 or equivalently,
2087
2088     @foo = grep {!/^#/} @bar;    # weed out comments
2089
2090 Note that C<$_> is an alias to the list value, so it can be used to
2091 modify the elements of the LIST.  While this is useful and supported,
2092 it can cause bizarre results if the elements of LIST are not variables.
2093 Similarly, grep returns aliases into the original list, much as a for
2094 loop's index variable aliases the list elements.  That is, modifying an
2095 element of a list returned by grep (for example, in a C<foreach>, C<map>
2096 or another C<grep>) actually modifies the element in the original list.
2097 This is usually something to be avoided when writing clear code.
2098
2099 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2100
2101 =item hex EXPR
2102
2103 =item hex
2104
2105 Interprets EXPR as a hex string and returns the corresponding value.
2106 (To convert strings that might start with either 0, 0x, or 0b, see
2107 L</oct>.)  If EXPR is omitted, uses C<$_>.
2108
2109     print hex '0xAf'; # prints '175'
2110     print hex 'aF';   # same
2111
2112 Hex strings may only represent integers.  Strings that would cause
2113 integer overflow trigger a warning.
2114
2115 =item import
2116
2117 There is no builtin C<import> function.  It is just an ordinary
2118 method (subroutine) defined (or inherited) by modules that wish to export
2119 names to another module.  The C<use> function calls the C<import> method
2120 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
2121
2122 =item index STR,SUBSTR,POSITION
2123
2124 =item index STR,SUBSTR
2125
2126 The index function searches for one string within another, but without
2127 the wildcard-like behavior of a full regular-expression pattern match.
2128 It returns the position of the first occurrence of SUBSTR in STR at
2129 or after POSITION.  If POSITION is omitted, starts searching from the
2130 beginning of the string.  The return value is based at C<0> (or whatever
2131 you've set the C<$[> variable to--but don't do that).  If the substring
2132 is not found, returns one less than the base, ordinarily C<-1>.
2133
2134 =item int EXPR
2135
2136 =item int
2137
2138 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2139 You should not use this function for rounding: one because it truncates
2140 towards C<0>, and two because machine representations of floating point
2141 numbers can sometimes produce counterintuitive results.  For example,
2142 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2143 because it's really more like -268.99999999999994315658 instead.  Usually,
2144 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2145 functions will serve you better than will int().
2146
2147 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2148
2149 Implements the ioctl(2) function.  You'll probably first have to say
2150
2151     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2152
2153 to get the correct function definitions.  If F<ioctl.ph> doesn't
2154 exist or doesn't have the correct definitions you'll have to roll your
2155 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2156 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2157 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2158 written depending on the FUNCTION--a pointer to the string value of SCALAR
2159 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2160 has no string value but does have a numeric value, that value will be
2161 passed rather than a pointer to the string value.  To guarantee this to be
2162 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2163 functions may be needed to manipulate the values of structures used by
2164 C<ioctl>.  
2165
2166 The return value of C<ioctl> (and C<fcntl>) is as follows:
2167
2168         if OS returns:          then Perl returns:
2169             -1                    undefined value
2170              0                  string "0 but true"
2171         anything else               that number
2172
2173 Thus Perl returns true on success and false on failure, yet you can
2174 still easily determine the actual value returned by the operating
2175 system:
2176
2177     $retval = ioctl(...) || -1;
2178     printf "System returned %d\n", $retval;
2179
2180 The special string "C<0> but true" is exempt from B<-w> complaints
2181 about improper numeric conversions.
2182
2183 Here's an example of setting a filehandle named C<REMOTE> to be
2184 non-blocking at the system level.  You'll have to negotiate C<$|>
2185 on your own, though.
2186
2187     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2188
2189     $flags = fcntl(REMOTE, F_GETFL, 0)
2190                 or die "Can't get flags for the socket: $!\n";
2191
2192     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2193                 or die "Can't set flags for the socket: $!\n";
2194
2195 =item join EXPR,LIST
2196
2197 Joins the separate strings of LIST into a single string with fields
2198 separated by the value of EXPR, and returns that new string.  Example:
2199
2200     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2201
2202 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2203 first argument.  Compare L</split>.
2204
2205 =item keys HASH
2206
2207 Returns a list consisting of all the keys of the named hash.  (In
2208 scalar context, returns the number of keys.)  The keys are returned in
2209 an apparently random order.  The actual random order is subject to
2210 change in future versions of perl, but it is guaranteed to be the same
2211 order as either the C<values> or C<each> function produces (given
2212 that the hash has not been modified).  As a side effect, it resets
2213 HASH's iterator.
2214
2215 Here is yet another way to print your environment:
2216
2217     @keys = keys %ENV;
2218     @values = values %ENV;
2219     while (@keys) { 
2220         print pop(@keys), '=', pop(@values), "\n";
2221     }
2222
2223 or how about sorted by key:
2224
2225     foreach $key (sort(keys %ENV)) {
2226         print $key, '=', $ENV{$key}, "\n";
2227     }
2228
2229 The returned values are copies of the original keys in the hash, so
2230 modifying them will not affect the original hash.  Compare L</values>.
2231
2232 To sort a hash by value, you'll need to use a C<sort> function.
2233 Here's a descending numeric sort of a hash by its values:
2234
2235     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2236         printf "%4d %s\n", $hash{$key}, $key;
2237     }
2238
2239 As an lvalue C<keys> allows you to increase the number of hash buckets
2240 allocated for the given hash.  This can gain you a measure of efficiency if
2241 you know the hash is going to get big.  (This is similar to pre-extending
2242 an array by assigning a larger number to $#array.)  If you say
2243
2244     keys %hash = 200;
2245
2246 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2247 in fact, since it rounds up to the next power of two.  These
2248 buckets will be retained even if you do C<%hash = ()>, use C<undef
2249 %hash> if you want to free the storage while C<%hash> is still in scope.
2250 You can't shrink the number of buckets allocated for the hash using
2251 C<keys> in this way (but you needn't worry about doing this by accident,
2252 as trying has no effect).
2253
2254 See also C<each>, C<values> and C<sort>.
2255
2256 =item kill SIGNAL, LIST
2257
2258 Sends a signal to a list of processes.  Returns the number of
2259 processes successfully signaled (which is not necessarily the
2260 same as the number actually killed).
2261
2262     $cnt = kill 1, $child1, $child2;
2263     kill 9, @goners;
2264
2265 If SIGNAL is zero, no signal is sent to the process.  This is a
2266 useful way to check that the process is alive and hasn't changed
2267 its UID.  See L<perlport> for notes on the portability of this
2268 construct.
2269
2270 Unlike in the shell, if SIGNAL is negative, it kills
2271 process groups instead of processes.  (On System V, a negative I<PROCESS>
2272 number will also kill process groups, but that's not portable.)  That
2273 means you usually want to use positive not negative signals.  You may also
2274 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2275
2276 =item last LABEL
2277
2278 =item last
2279
2280 The C<last> command is like the C<break> statement in C (as used in
2281 loops); it immediately exits the loop in question.  If the LABEL is
2282 omitted, the command refers to the innermost enclosing loop.  The
2283 C<continue> block, if any, is not executed:
2284
2285     LINE: while (<STDIN>) {
2286         last LINE if /^$/;      # exit when done with header
2287         #...
2288     }
2289
2290 C<last> cannot be used to exit a block which returns a value such as
2291 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2292 a grep() or map() operation.
2293
2294 Note that a block by itself is semantically identical to a loop
2295 that executes once.  Thus C<last> can be used to effect an early
2296 exit out of such a block.
2297
2298 See also L</continue> for an illustration of how C<last>, C<next>, and
2299 C<redo> work.
2300
2301 =item lc EXPR
2302
2303 =item lc
2304
2305 Returns an lowercased version of EXPR.  This is the internal function
2306 implementing the C<\L> escape in double-quoted strings.
2307 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2308 and L<utf8>.
2309
2310 If EXPR is omitted, uses C<$_>.
2311
2312 =item lcfirst EXPR
2313
2314 =item lcfirst
2315
2316 Returns the value of EXPR with the first character lowercased.  This is
2317 the internal function implementing the C<\l> escape in double-quoted strings.
2318 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2319
2320 If EXPR is omitted, uses C<$_>.
2321
2322 =item length EXPR
2323
2324 =item length
2325
2326 Returns the length in characters of the value of EXPR.  If EXPR is
2327 omitted, returns length of C<$_>.  Note that this cannot be used on 
2328 an entire array or hash to find out how many elements these have.
2329 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2330
2331 =item link OLDFILE,NEWFILE
2332
2333 Creates a new filename linked to the old filename.  Returns true for
2334 success, false otherwise. 
2335
2336 =item listen SOCKET,QUEUESIZE
2337
2338 Does the same thing that the listen system call does.  Returns true if
2339 it succeeded, false otherwise.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2340
2341 =item local EXPR
2342
2343 You really probably want to be using C<my> instead, because C<local> isn't
2344 what most people think of as "local".  See L<perlsub/"Private Variables
2345 via my()"> for details.
2346
2347 A local modifies the listed variables to be local to the enclosing
2348 block, file, or eval.  If more than one value is listed, the list must
2349 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2350 for details, including issues with tied arrays and hashes.
2351
2352 =item localtime EXPR
2353
2354 Converts a time as returned by the time function to a 9-element list
2355 with the time analyzed for the local time zone.  Typically used as
2356 follows:
2357
2358     #  0    1    2     3     4    5     6     7     8
2359     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2360                                                 localtime(time);
2361
2362 All list elements are numeric, and come straight out of the C `struct
2363 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2364 specified time.  $mday is the day of the month, and $mon is the month
2365 itself, in the range C<0..11> with 0 indicating January and 11
2366 indicating December.  $year is the number of years since 1900.  That
2367 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2368 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2369 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2370 is true if the specified time occurs during daylight savings time,
2371 false otherwise.
2372
2373 Note that the $year element is I<not> simply the last two digits of
2374 the year.  If you assume it is, then you create non-Y2K-compliant
2375 programs--and you wouldn't want to do that, would you?
2376
2377 The proper way to get a complete 4-digit year is simply:
2378
2379         $year += 1900;
2380
2381 And to get the last two digits of the year (e.g., '01' in 2001) do:
2382
2383         $year = sprintf("%02d", $year % 100);
2384
2385 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2386
2387 In scalar context, C<localtime()> returns the ctime(3) value:
2388
2389     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2390
2391 This scalar value is B<not> locale dependent, see L<perllocale>, but
2392 instead a Perl builtin.  Also see the C<Time::Local> module
2393 (to convert the second, minutes, hours, ... back to seconds since the
2394 stroke of midnight the 1st of January 1970, the value returned by
2395 time()), and the strftime(3) and mktime(3) functions available via the
2396 POSIX module.  To get somewhat similar but locale dependent date
2397 strings, set up your locale environment variables appropriately
2398 (please see L<perllocale>) and try for example:
2399
2400     use POSIX qw(strftime);
2401     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2402
2403 Note that the C<%a> and C<%b>, the short forms of the day of the week
2404 and the month of the year, may not necessarily be three characters wide.
2405
2406 =item lock
2407
2408     lock I<THING>
2409
2410 This function places an advisory lock on a variable, subroutine,
2411 or referenced object contained in I<THING> until the lock goes out
2412 of scope.  This is a built-in function only if your version of Perl
2413 was built with threading enabled, and if you've said C<use Threads>.
2414 Otherwise a user-defined function by this name will be called.  See
2415 L<Thread>.
2416
2417 =item log EXPR
2418
2419 =item log
2420
2421 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2422 returns log of C<$_>.  To get the log of another base, use basic algebra:
2423 The base-N log of a number is equal to the natural log of that number
2424 divided by the natural log of N.  For example:
2425
2426     sub log10 {
2427         my $n = shift;
2428         return log($n)/log(10);
2429     } 
2430
2431 See also L</exp> for the inverse operation.
2432
2433 =item lstat EXPR
2434
2435 =item lstat
2436
2437 Does the same thing as the C<stat> function (including setting the
2438 special C<_> filehandle) but stats a symbolic link instead of the file
2439 the symbolic link points to.  If symbolic links are unimplemented on
2440 your system, a normal C<stat> is done.
2441
2442 If EXPR is omitted, stats C<$_>.
2443
2444 =item m//
2445
2446 The match operator.  See L<perlop>.
2447
2448 =item map BLOCK LIST
2449
2450 =item map EXPR,LIST
2451
2452 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2453 C<$_> to each element) and returns the list value composed of the
2454 results of each such evaluation.  In scalar context, returns the
2455 total number of elements so generated.  Evaluates BLOCK or EXPR in
2456 list context, so each element of LIST may produce zero, one, or
2457 more elements in the returned value.
2458
2459     @chars = map(chr, @nums);
2460
2461 translates a list of numbers to the corresponding characters.  And
2462
2463     %hash = map { getkey($_) => $_ } @array;
2464
2465 is just a funny way to write
2466
2467     %hash = ();
2468     foreach $_ (@array) {
2469         $hash{getkey($_)} = $_;
2470     }
2471
2472 Note that C<$_> is an alias to the list value, so it can be used to
2473 modify the elements of the LIST.  While this is useful and supported,
2474 it can cause bizarre results if the elements of LIST are not variables.
2475 Using a regular C<foreach> loop for this purpose would be clearer in
2476 most cases.  See also L</grep> for an array composed of those items of
2477 the original list for which the BLOCK or EXPR evaluates to true.
2478
2479 =item mkdir FILENAME,MASK
2480
2481 =item mkdir FILENAME
2482
2483 Creates the directory specified by FILENAME, with permissions
2484 specified by MASK (as modified by C<umask>).  If it succeeds it
2485 returns true, otherwise it returns false and sets C<$!> (errno).
2486 If omitted, MASK defaults to 0777.
2487
2488 In general, it is better to create directories with permissive MASK,
2489 and let the user modify that with their C<umask>, than it is to supply
2490 a restrictive MASK and give the user no way to be more permissive.
2491 The exceptions to this rule are when the file or directory should be
2492 kept private (mail files, for instance).  The perlfunc(1) entry on
2493 C<umask> discusses the choice of MASK in more detail.
2494
2495 =item msgctl ID,CMD,ARG
2496
2497 Calls the System V IPC function msgctl(2).  You'll probably have to say
2498
2499     use IPC::SysV;
2500
2501 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2502 then ARG must be a variable which will hold the returned C<msqid_ds>
2503 structure.  Returns like C<ioctl>: the undefined value for error,
2504 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2505 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2506
2507 =item msgget KEY,FLAGS
2508
2509 Calls the System V IPC function msgget(2).  Returns the message queue
2510 id, or the undefined value if there is an error.  See also
2511 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2512
2513 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2514
2515 Calls the System V IPC function msgrcv to receive a message from
2516 message queue ID into variable VAR with a maximum message size of
2517 SIZE.  Note that when a message is received, the message type as a
2518 native long integer will be the first thing in VAR, followed by the
2519 actual message.  This packing may be opened with C<unpack("l! a*")>.
2520 Taints the variable.  Returns true if successful, or false if there is
2521 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2522 C<IPC::SysV::Msg> documentation.
2523
2524 =item msgsnd ID,MSG,FLAGS
2525
2526 Calls the System V IPC function msgsnd to send the message MSG to the
2527 message queue ID.  MSG must begin with the native long integer message
2528 type, and be followed by the length of the actual message, and finally
2529 the message itself.  This kind of packing can be achieved with
2530 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2531 or false if there is an error.  See also C<IPC::SysV>
2532 and C<IPC::SysV::Msg> documentation.
2533
2534 =item my EXPR
2535
2536 =item my EXPR : ATTRIBUTES
2537
2538 A C<my> declares the listed variables to be local (lexically) to the
2539 enclosing block, file, or C<eval>.  If
2540 more than one value is listed, the list must be placed in parentheses.  See
2541 L<perlsub/"Private Variables via my()"> for details.
2542
2543 =item next LABEL
2544
2545 =item next
2546
2547 The C<next> command is like the C<continue> statement in C; it starts
2548 the next iteration of the loop:
2549
2550     LINE: while (<STDIN>) {
2551         next LINE if /^#/;      # discard comments
2552         #...
2553     }
2554
2555 Note that if there were a C<continue> block on the above, it would get
2556 executed even on discarded lines.  If the LABEL is omitted, the command
2557 refers to the innermost enclosing loop.
2558
2559 C<next> cannot be used to exit a block which returns a value such as
2560 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2561 a grep() or map() operation.
2562
2563 Note that a block by itself is semantically identical to a loop
2564 that executes once.  Thus C<next> will exit such a block early.
2565
2566 See also L</continue> for an illustration of how C<last>, C<next>, and
2567 C<redo> work.
2568
2569 =item no Module LIST
2570
2571 See the L</use> function, which C<no> is the opposite of.
2572
2573 =item oct EXPR
2574
2575 =item oct
2576
2577 Interprets EXPR as an octal string and returns the corresponding
2578 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2579 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2580 binary string.)  The following will handle decimal, binary, octal, and
2581 hex in the standard Perl or C notation:
2582
2583     $val = oct($val) if $val =~ /^0/;
2584
2585 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2586 in octal), use sprintf() or printf():
2587
2588     $perms = (stat("filename"))[2] & 07777;
2589     $oct_perms = sprintf "%lo", $perms;
2590
2591 The oct() function is commonly used when a string such as C<644> needs
2592 to be converted into a file mode, for example. (Although perl will
2593 automatically convert strings into numbers as needed, this automatic
2594 conversion assumes base 10.)
2595
2596 =item open FILEHANDLE,MODE,LIST
2597
2598 =item open FILEHANDLE,EXPR
2599
2600 =item open FILEHANDLE
2601
2602 Opens the file whose filename is given by EXPR, and associates it with
2603 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2604 name of the real filehandle wanted.  (This is considered a symbolic
2605 reference, so C<use strict 'refs'> should I<not> be in effect.)
2606
2607 If EXPR is omitted, the scalar
2608 variable of the same name as the FILEHANDLE contains the filename.
2609 (Note that lexical variables--those declared with C<my>--will not work
2610 for this purpose; so if you're using C<my>, specify EXPR in your call
2611 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2612 files.
2613
2614 If MODE is C<< '<' >> or nothing, the file is opened for input.
2615 If MODE is C<< '>' >>, the file is truncated and opened for
2616 output, being created if necessary.  If MODE is C<<< '>>' >>>,
2617 the file is opened for appending, again being created if necessary. 
2618 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to indicate that
2619 you want both read and write access to the file; thus C<< '+<' >> is almost
2620 always preferred for read/write updates--the C<< '+>' >> mode would clobber the
2621 file first.  You can't usually use either read-write mode for updating
2622 textfiles, since they have variable length records.  See the B<-i>
2623 switch in L<perlrun> for a better approach.  The file is created with
2624 permissions of C<0666> modified by the process' C<umask> value.
2625
2626 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>,
2627 C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2628
2629 In the 2-arguments (and 1-argument) form of the call the mode and
2630 filename should be concatenated (in this order), possibly separated by
2631 spaces.  It is possible to omit the mode if the mode is C<< '<' >>.
2632
2633 If the filename begins with C<'|'>, the filename is interpreted as a
2634 command to which output is to be piped, and if the filename ends with a
2635 C<'|'>, the filename is interpreted as a command which pipes output to
2636 us.  See L<perlipc/"Using open() for IPC">
2637 for more examples of this.  (You are not allowed to C<open> to a command
2638 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2639 and L<perlipc/"Bidirectional Communication with Another Process">
2640 for alternatives.)
2641
2642 If MODE is C<'|-'>, the filename is interpreted as a
2643 command to which output is to be piped, and if MODE is
2644 C<'-|'>, the filename is interpreted as a command which pipes output to
2645 us.  In the 2-arguments (and 1-argument) form one should replace dash
2646 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2647 for more examples of this.  (You are not allowed to C<open> to a command
2648 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2649 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2650
2651 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2652 and opening C<< '>-' >> opens STDOUT.  
2653
2654 Open returns
2655 nonzero upon success, the undefined value otherwise.  If the C<open>
2656 involved a pipe, the return value happens to be the pid of the
2657 subprocess.
2658
2659 If you're unfortunate enough to be running Perl on a system that
2660 distinguishes between text files and binary files (modern operating
2661 systems don't care), then you should check out L</binmode> for tips for
2662 dealing with this.  The key distinction between systems that need C<binmode>
2663 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2664 Plan9, which delimit lines with a single character, and which encode that
2665 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2666
2667 When opening a file, it's usually a bad idea to continue normal execution
2668 if the request failed, so C<open> is frequently used in connection with
2669 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2670 where you want to make a nicely formatted error message (but there are
2671 modules that can help with that problem)) you should always check
2672 the return value from opening a file.  The infrequent exception is when
2673 working with an unopened filehandle is actually what you want to do.
2674
2675 Examples:
2676
2677     $ARTICLE = 100;
2678     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2679     while (<ARTICLE>) {...
2680
2681     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2682     # if the open fails, output is discarded
2683
2684     open(DBASE, '+<', 'dbase.mine')             # open for update
2685         or die "Can't open 'dbase.mine' for update: $!";
2686
2687     open(DBASE, '+<dbase.mine')                 # ditto
2688         or die "Can't open 'dbase.mine' for update: $!";
2689
2690     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2691         or die "Can't start caesar: $!";
2692
2693     open(ARTICLE, "caesar <$article |")         # ditto
2694         or die "Can't start caesar: $!";
2695
2696     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2697         or die "Can't start sort: $!";
2698
2699     # process argument list of files along with any includes
2700
2701     foreach $file (@ARGV) {
2702         process($file, 'fh00');
2703     }
2704
2705     sub process {
2706         my($filename, $input) = @_;
2707         $input++;               # this is a string increment
2708         unless (open($input, $filename)) {
2709             print STDERR "Can't open $filename: $!\n";
2710             return;
2711         }
2712
2713         local $_;
2714         while (<$input>) {              # note use of indirection
2715             if (/^#include "(.*)"/) {
2716                 process($1, $input);
2717                 next;
2718             }
2719             #...                # whatever
2720         }
2721     }
2722
2723 You may also, in the Bourne shell tradition, specify an EXPR beginning
2724 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2725 name of a filehandle (or file descriptor, if numeric) to be
2726 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2727 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2728 mode you specify should match the mode of the original filehandle.
2729 (Duping a filehandle does not take into account any existing contents of
2730 stdio buffers.)  Duping file handles is not yet supported for 3-argument
2731 open().
2732
2733 Here is a script that saves, redirects, and restores STDOUT and
2734 STDERR:
2735
2736     #!/usr/bin/perl
2737     open(OLDOUT, ">&STDOUT");
2738     open(OLDERR, ">&STDERR");
2739
2740     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2741     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2742
2743     select(STDERR); $| = 1;     # make unbuffered
2744     select(STDOUT); $| = 1;     # make unbuffered
2745
2746     print STDOUT "stdout 1\n";  # this works for
2747     print STDERR "stderr 1\n";  # subprocesses too
2748
2749     close(STDOUT);
2750     close(STDERR);
2751
2752     open(STDOUT, ">&OLDOUT");
2753     open(STDERR, ">&OLDERR");
2754
2755     print STDOUT "stdout 2\n";
2756     print STDERR "stderr 2\n";
2757
2758 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will do an
2759 equivalent of C's C<fdopen> of that file descriptor; this is more
2760 parsimonious of file descriptors.  For example:
2761
2762     open(FILEHANDLE, "<&=$fd")
2763
2764 Note that this feature depends on the fdopen() C library function.
2765 On many UNIX systems, fdopen() is known to fail when file descriptors
2766 exceed a certain value, typically 255. If you need more file
2767 descriptors than that, consider rebuilding Perl to use the C<sfio>
2768 library.
2769
2770 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2771 with 2-arguments (or 1-argument) form of open(), then
2772 there is an implicit fork done, and the return value of open is the pid
2773 of the child within the parent process, and C<0> within the child
2774 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2775 The filehandle behaves normally for the parent, but i/o to that
2776 filehandle is piped from/to the STDOUT/STDIN of the child process.
2777 In the child process the filehandle isn't opened--i/o happens from/to
2778 the new STDOUT or STDIN.  Typically this is used like the normal
2779 piped open when you want to exercise more control over just how the
2780 pipe command gets executed, such as when you are running setuid, and
2781 don't want to have to scan shell commands for metacharacters.
2782 The following triples are more or less equivalent:
2783
2784     open(FOO, "|tr '[a-z]' '[A-Z]'");
2785     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2786     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2787
2788     open(FOO, "cat -n '$file'|");
2789     open(FOO, '-|', "cat -n '$file'");
2790     open(FOO, '-|') || exec 'cat', '-n', $file;
2791
2792 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2793
2794 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2795 output before any operation that may do a fork, but this may not be
2796 supported on some platforms (see L<perlport>).  To be safe, you may need
2797 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2798 of C<IO::Handle> on any open handles.
2799
2800 On systems that support a
2801 close-on-exec flag on files, the flag will be set for the newly opened
2802 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2803
2804 Closing any piped filehandle causes the parent process to wait for the
2805 child to finish, and returns the status value in C<$?>.
2806
2807 The filename passed to 2-argument (or 1-argument) form of open()
2808 will have leading and trailing
2809 whitespace deleted, and the normal redirection characters
2810 honored.  This property, known as "magic open", 
2811 can often be used to good effect.  A user could specify a filename of
2812 F<"rsh cat file |">, or you could change certain filenames as needed:
2813
2814     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2815     open(FH, $filename) or die "Can't open $filename: $!";
2816
2817 Use 3-argument form to open a file with arbitrary weird characters in it,
2818
2819     open(FOO, '<', $file);
2820
2821 otherwise it's necessary to protect any leading and trailing whitespace:
2822
2823     $file =~ s#^(\s)#./$1#;
2824     open(FOO, "< $file\0");
2825
2826 (this may not work on some bizarre filesystems).  One should
2827 conscientiously choose between the I<magic> and 3-arguments form
2828 of open():
2829
2830     open IN, $ARGV[0];
2831
2832 will allow the user to specify an argument of the form C<"rsh cat file |">,
2833 but will not work on a filename which happens to have a trailing space, while
2834
2835     open IN, '<', $ARGV[0];
2836
2837 will have exactly the opposite restrictions.
2838
2839 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2840 should use the C<sysopen> function, which involves no such magic (but
2841 may use subtly different filemodes than Perl open(), which is mapped
2842 to C fopen()).  This is
2843 another way to protect your filenames from interpretation.  For example:
2844
2845     use IO::Handle;
2846     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2847         or die "sysopen $path: $!";
2848     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2849     print HANDLE "stuff $$\n");
2850     seek(HANDLE, 0, 0);
2851     print "File contains: ", <HANDLE>;
2852
2853 Using the constructor from the C<IO::Handle> package (or one of its
2854 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2855 filehandles that have the scope of whatever variables hold references to
2856 them, and automatically close whenever and however you leave that scope:
2857
2858     use IO::File;
2859     #...
2860     sub read_myfile_munged {
2861         my $ALL = shift;
2862         my $handle = new IO::File;
2863         open($handle, "myfile") or die "myfile: $!";
2864         $first = <$handle>
2865             or return ();     # Automatically closed here.
2866         mung $first or die "mung failed";       # Or here.
2867         return $first, <$handle> if $ALL;       # Or here.
2868         $first;                                 # Or here.
2869     }
2870
2871 See L</seek> for some details about mixing reading and writing.
2872
2873 =item opendir DIRHANDLE,EXPR
2874
2875 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2876 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2877 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2878
2879 =item ord EXPR
2880
2881 =item ord
2882
2883 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2884 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2885 See L<utf8> for more about Unicode.
2886
2887 =item our EXPR
2888
2889 An C<our> declares the listed variables to be valid globals within
2890 the enclosing block, file, or C<eval>.  That is, it has the same
2891 scoping rules as a "my" declaration, but does not create a local
2892 variable.  If more than one value is listed, the list must be placed
2893 in parentheses.  The C<our> declaration has no semantic effect unless
2894 "use strict vars" is in effect, in which case it lets you use the
2895 declared global variable without qualifying it with a package name.
2896 (But only within the lexical scope of the C<our> declaration.  In this
2897 it differs from "use vars", which is package scoped.)
2898
2899 An C<our> declaration declares a global variable that will be visible
2900 across its entire lexical scope, even across package boundaries.  The
2901 package in which the variable is entered is determined at the point
2902 of the declaration, not at the point of use.  This means the following
2903 behavior holds:
2904
2905     package Foo;
2906     our $bar;           # declares $Foo::bar for rest of lexical scope
2907     $bar = 20;
2908
2909     package Bar;
2910     print $bar;         # prints 20
2911
2912 Multiple C<our> declarations in the same lexical scope are allowed
2913 if they are in different packages.  If they happened to be in the same
2914 package, Perl will emit warnings if you have asked for them.
2915
2916     use warnings;
2917     package Foo;
2918     our $bar;           # declares $Foo::bar for rest of lexical scope
2919     $bar = 20;
2920
2921     package Bar;
2922     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
2923     print $bar;         # prints 30
2924
2925     our $bar;           # emits warning
2926
2927 =item pack TEMPLATE,LIST
2928
2929 Takes a LIST of values and converts it into a string using the rules
2930 given by the TEMPLATE.  The resulting string is the concatenation of
2931 the converted values.  Typically, each converted value looks
2932 like its machine-level representation.  For example, on 32-bit machines
2933 a converted integer may be represented by a sequence of 4 bytes.
2934
2935 The TEMPLATE is a
2936 sequence of characters that give the order and type of values, as
2937 follows:
2938
2939     a   A string with arbitrary binary data, will be null padded.
2940     A   An ASCII string, will be space padded.
2941     Z   A null terminated (asciz) string, will be null padded.
2942
2943     b   A bit string (ascending bit order inside each byte, like vec()).
2944     B   A bit string (descending bit order inside each byte).
2945     h   A hex string (low nybble first).
2946     H   A hex string (high nybble first).
2947
2948     c   A signed char value.
2949     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2950
2951     s   A signed short value.
2952     S   An unsigned short value.
2953           (This 'short' is _exactly_ 16 bits, which may differ from
2954            what a local C compiler calls 'short'.  If you want
2955            native-length shorts, use the '!' suffix.)
2956
2957     i   A signed integer value.
2958     I   An unsigned integer value.
2959           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2960            size depends on what a local C compiler calls 'int',
2961            and may even be larger than the 'long' described in
2962            the next item.)
2963
2964     l   A signed long value.
2965     L   An unsigned long value.
2966           (This 'long' is _exactly_ 32 bits, which may differ from
2967            what a local C compiler calls 'long'.  If you want
2968            native-length longs, use the '!' suffix.)
2969
2970     n   An unsigned short in "network" (big-endian) order.
2971     N   An unsigned long in "network" (big-endian) order.
2972     v   An unsigned short in "VAX" (little-endian) order.
2973     V   An unsigned long in "VAX" (little-endian) order.
2974           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2975            _exactly_ 32 bits, respectively.)
2976
2977     q   A signed quad (64-bit) value.
2978     Q   An unsigned quad value.
2979           (Quads are available only if your system supports 64-bit
2980            integer values _and_ if Perl has been compiled to support those.
2981            Causes a fatal error otherwise.)
2982
2983     f   A single-precision float in the native format.
2984     d   A double-precision float in the native format.
2985
2986     p   A pointer to a null-terminated string.
2987     P   A pointer to a structure (fixed-length string).
2988
2989     u   A uuencoded string.
2990     U   A Unicode character number.  Encodes to UTF-8 internally.
2991         Works even if C<use utf8> is not in effect.
2992
2993     w   A BER compressed integer.  Its bytes represent an unsigned
2994         integer in base 128, most significant digit first, with as
2995         few digits as possible.  Bit eight (the high bit) is set
2996         on each byte except the last.
2997
2998     x   A null byte.
2999     X   Back up a byte.
3000     @   Null fill to absolute position.
3001
3002 The following rules apply:
3003
3004 =over 8
3005
3006 =item *
3007
3008 Each letter may optionally be followed by a number giving a repeat
3009 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3010 C<H>, and C<P> the pack function will gobble up that many values from
3011 the LIST.  A C<*> for the repeat count means to use however many items are
3012 left, except for C<@>, C<x>, C<X>, where it is equivalent
3013 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
3014 same).
3015
3016 When used with C<Z>, C<*> results in the addition of a trailing null
3017 byte (so the packed result will be one longer than the byte C<length>
3018 of the item).
3019
3020 The repeat count for C<u> is interpreted as the maximal number of bytes
3021 to encode per line of output, with 0 and 1 replaced by 45.
3022
3023 =item *
3024
3025 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3026 string of length count, padding with nulls or spaces as necessary.  When
3027 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3028 after the first null, and C<a> returns data verbatim.  When packing,
3029 C<a>, and C<Z> are equivalent.
3030
3031 If the value-to-pack is too long, it is truncated.  If too long and an
3032 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3033 by a null byte.  Thus C<Z> always packs a trailing null byte under
3034 all circumstances.
3035
3036 =item *
3037
3038 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3039 Each byte of the input field of pack() generates 1 bit of the result.
3040 Each result bit is based on the least-significant bit of the corresponding
3041 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3042 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3043
3044 Starting from the beginning of the input string of pack(), each 8-tuple
3045 of bytes is converted to 1 byte of output.  With format C<b>
3046 the first byte of the 8-tuple determines the least-significant bit of a
3047 byte, and with format C<B> it determines the most-significant bit of
3048 a byte.
3049
3050 If the length of the input string is not exactly divisible by 8, the
3051 remainder is packed as if the input string were padded by null bytes
3052 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3053
3054 If the input string of pack() is longer than needed, extra bytes are ignored.
3055 A C<*> for the repeat count of pack() means to use all the bytes of
3056 the input field.  On unpack()ing the bits are converted to a string
3057 of C<"0">s and C<"1">s.
3058
3059 =item *
3060
3061 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3062 representable as hexadecimal digits, 0-9a-f) long.
3063
3064 Each byte of the input field of pack() generates 4 bits of the result.
3065 For non-alphabetical bytes the result is based on the 4 least-significant
3066 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3067 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3068 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3069 is compatible with the usual hexadecimal digits, so that C<"a"> and
3070 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3071 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3072
3073 Starting from the beginning of the input string of pack(), each pair
3074 of bytes is converted to 1 byte of output.  With format C<h> the
3075 first byte of the pair determines the least-significant nybble of the
3076 output byte, and with format C<H> it determines the most-significant
3077 nybble.
3078
3079 If the length of the input string is not even, it behaves as if padded
3080 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3081 nybbles are ignored.
3082
3083 If the input string of pack() is longer than needed, extra bytes are ignored.
3084 A C<*> for the repeat count of pack() means to use all the bytes of
3085 the input field.  On unpack()ing the bits are converted to a string
3086 of hexadecimal digits.
3087
3088 =item *
3089
3090 The C<p> type packs a pointer to a null-terminated string.  You are
3091 responsible for ensuring the string is not a temporary value (which can
3092 potentially get deallocated before you get around to using the packed result).
3093 The C<P> type packs a pointer to a structure of the size indicated by the
3094 length.  A NULL pointer is created if the corresponding value for C<p> or
3095 C<P> is C<undef>, similarly for unpack().
3096
3097 =item *
3098
3099 The C</> template character allows packing and unpacking of strings where
3100 the packed structure contains a byte count followed by the string itself.
3101 You write I<length-item>C</>I<string-item>.
3102
3103 The I<length-item> can be any C<pack> template letter,
3104 and describes how the length value is packed.
3105 The ones likely to be of most use are integer-packing ones like
3106 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3107 and C<N> (for Sun XDR).
3108
3109 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3110 For C<unpack> the length of the string is obtained from the I<length-item>,
3111 but if you put in the '*' it will be ignored.
3112
3113     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3114     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3115     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3116
3117 The I<length-item> is not returned explicitly from C<unpack>.
3118
3119 Adding a count to the I<length-item> letter is unlikely to do anything
3120 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3121 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3122 which Perl does not regard as legal in numeric strings.
3123
3124 =item *
3125
3126 The integer types C<s>, C<S>, C<l>, and C<L> may be
3127 immediately followed by a C<!> suffix to signify native shorts or
3128 longs--as you can see from above for example a bare C<l> does mean
3129 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3130 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3131 see whether using C<!> makes any difference by
3132
3133         print length(pack("s")), " ", length(pack("s!")), "\n";
3134         print length(pack("l")), " ", length(pack("l!")), "\n";
3135
3136 C<i!> and C<I!> also work but only because of completeness;
3137 they are identical to C<i> and C<I>.
3138
3139 The actual sizes (in bytes) of native shorts, ints, longs, and long
3140 longs on the platform where Perl was built are also available via
3141 L<Config>:
3142
3143        use Config;
3144        print $Config{shortsize},    "\n";
3145        print $Config{intsize},      "\n";
3146        print $Config{longsize},     "\n";
3147        print $Config{longlongsize}, "\n";
3148
3149 (The C<$Config{longlongsize}> will be undefine if your system does
3150 not support long longs.) 
3151
3152 =item *
3153
3154 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3155 are inherently non-portable between processors and operating systems
3156 because they obey the native byteorder and endianness.  For example a
3157 4-byte integer 0x12345678 (305419896 decimal) be ordered natively
3158 (arranged in and handled by the CPU registers) into bytes as
3159
3160         0x12 0x34 0x56 0x78     # big-endian
3161         0x78 0x56 0x34 0x12     # little-endian
3162
3163 Basically, the Intel and VAX CPUs are little-endian, while everybody
3164 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3165 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3166 used/uses them in little-endian mode; SGI/Cray uses them in big-endian mode.
3167
3168 The names `big-endian' and `little-endian' are comic references to
3169 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3170 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3171 the egg-eating habits of the Lilliputians.
3172
3173 Some systems may have even weirder byte orders such as
3174
3175         0x56 0x78 0x12 0x34
3176         0x34 0x12 0x78 0x56
3177
3178 You can see your system's preference with
3179
3180         print join(" ", map { sprintf "%#02x", $_ }
3181                             unpack("C*",pack("L",0x12345678))), "\n";
3182
3183 The byteorder on the platform where Perl was built is also available
3184 via L<Config>:
3185
3186         use Config;
3187         print $Config{byteorder}, "\n";
3188
3189 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3190 and C<'87654321'> are big-endian.
3191
3192 If you want portable packed integers use the formats C<n>, C<N>,
3193 C<v>, and C<V>, their byte endianness and size is known.
3194 See also L<perlport>.
3195
3196 =item *
3197
3198 Real numbers (floats and doubles) are in the native machine format only;
3199 due to the multiplicity of floating formats around, and the lack of a
3200 standard "network" representation, no facility for interchange has been
3201 made.  This means that packed floating point data written on one machine
3202 may not be readable on another - even if both use IEEE floating point
3203 arithmetic (as the endian-ness of the memory representation is not part
3204 of the IEEE spec).  See also L<perlport>.
3205
3206 Note that Perl uses doubles internally for all numeric calculation, and
3207 converting from double into float and thence back to double again will
3208 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3209 equal $foo).
3210
3211 =item *
3212
3213 If the pattern begins with a C<U>, the resulting string will be treated
3214 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3215 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3216 characters. If you don't want this to happen, you can begin your pattern
3217 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3218 string, and then follow this with a C<U*> somewhere in your pattern.
3219
3220 =item *
3221
3222 You must yourself do any alignment or padding by inserting for example
3223 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3224 could know where the bytes are going to or coming from.  Therefore
3225 C<pack> (and C<unpack>) handle their output and input as flat
3226 sequences of bytes.
3227
3228 =item *
3229
3230 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3231
3232 =item *
3233
3234 If TEMPLATE requires more arguments to pack() than actually given, pack()
3235 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3236 to pack() than actually given, extra arguments are ignored.
3237
3238 =back
3239
3240 Examples:
3241
3242     $foo = pack("CCCC",65,66,67,68);
3243     # foo eq "ABCD"
3244     $foo = pack("C4",65,66,67,68);
3245     # same thing
3246     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3247     # same thing with Unicode circled letters
3248
3249     $foo = pack("ccxxcc",65,66,67,68);
3250     # foo eq "AB\0\0CD"
3251
3252     # note: the above examples featuring "C" and "c" are true
3253     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3254     # and UTF-8.  In EBCDIC the first example would be
3255     # $foo = pack("CCCC",193,194,195,196);
3256
3257     $foo = pack("s2",1,2);
3258     # "\1\0\2\0" on little-endian
3259     # "\0\1\0\2" on big-endian
3260
3261     $foo = pack("a4","abcd","x","y","z");
3262     # "abcd"
3263
3264     $foo = pack("aaaa","abcd","x","y","z");
3265     # "axyz"
3266
3267     $foo = pack("a14","abcdefg");
3268     # "abcdefg\0\0\0\0\0\0\0"
3269
3270     $foo = pack("i9pl", gmtime);
3271     # a real struct tm (on my system anyway)
3272
3273     $utmp_template = "Z8 Z8 Z16 L";
3274     $utmp = pack($utmp_template, @utmp1);
3275     # a struct utmp (BSDish)
3276
3277     @utmp2 = unpack($utmp_template, $utmp);
3278     # "@utmp1" eq "@utmp2"
3279
3280     sub bintodec {
3281         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3282     }
3283
3284     $foo = pack('sx2l', 12, 34);
3285     # short 12, two zero bytes padding, long 34
3286     $bar = pack('s@4l', 12, 34);
3287     # short 12, zero fill to position 4, long 34
3288     # $foo eq $bar
3289
3290 The same template may generally also be used in unpack().
3291
3292 =item package NAMESPACE
3293
3294 =item package 
3295
3296 Declares the compilation unit as being in the given namespace.  The scope
3297 of the package declaration is from the declaration itself through the end
3298 of the enclosing block, file, or eval (the same as the C<my> operator).
3299 All further unqualified dynamic identifiers will be in this namespace.
3300 A package statement affects only dynamic variables--including those
3301 you've used C<local> on--but I<not> lexical variables, which are created
3302 with C<my>.  Typically it would be the first declaration in a file to
3303 be included by the C<require> or C<use> operator.  You can switch into a
3304 package in more than one place; it merely influences which symbol table
3305 is used by the compiler for the rest of that block.  You can refer to
3306 variables and filehandles in other packages by prefixing the identifier
3307 with the package name and a double colon:  C<$Package::Variable>.
3308 If the package name is null, the C<main> package as assumed.  That is,
3309 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3310 still seen in older code).
3311
3312 If NAMESPACE is omitted, then there is no current package, and all
3313 identifiers must be fully qualified or lexicals.  This is stricter
3314 than C<use strict>, since it also extends to function names.
3315
3316 See L<perlmod/"Packages"> for more information about packages, modules,
3317 and classes.  See L<perlsub> for other scoping issues.
3318
3319 =item pipe READHANDLE,WRITEHANDLE
3320
3321 Opens a pair of connected pipes like the corresponding system call.
3322 Note that if you set up a loop of piped processes, deadlock can occur
3323 unless you are very careful.  In addition, note that Perl's pipes use
3324 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3325 after each command, depending on the application.
3326
3327 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3328 for examples of such things.
3329
3330 On systems that support a close-on-exec flag on files, the flag will be set
3331 for the newly opened file descriptors as determined by the value of $^F.
3332 See L<perlvar/$^F>.
3333
3334 =item pop ARRAY
3335
3336 =item pop
3337
3338 Pops and returns the last value of the array, shortening the array by
3339 one element.  Has an effect similar to
3340
3341     $ARRAY[$#ARRAY--]
3342
3343 If there are no elements in the array, returns the undefined value
3344 (although this may happen at other times as well).  If ARRAY is
3345 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3346 array in subroutines, just like C<shift>.
3347
3348 =item pos SCALAR
3349
3350 =item pos
3351
3352 Returns the offset of where the last C<m//g> search left off for the variable
3353 in question (C<$_> is used when the variable is not specified).  May be
3354 modified to change that offset.  Such modification will also influence
3355 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3356 L<perlop>.
3357
3358 =item print FILEHANDLE LIST
3359
3360 =item print LIST
3361
3362 =item print
3363
3364 Prints a string or a list of strings.  Returns true if successful.
3365 FILEHANDLE may be a scalar variable name, in which case the variable
3366 contains the name of or a reference to the filehandle, thus introducing
3367 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3368 the next token is a term, it may be misinterpreted as an operator
3369 unless you interpose a C<+> or put parentheses around the arguments.)
3370 If FILEHANDLE is omitted, prints by default to standard output (or
3371 to the last selected output channel--see L</select>).  If LIST is
3372 also omitted, prints C<$_> to the currently selected output channel.
3373 To set the default output channel to something other than STDOUT
3374 use the select operation.  The current value of C<$,> (if any) is
3375 printed between each LIST item.  The current value of C<$\> (if
3376 any) is printed after the entire LIST has been printed.  Because
3377 print takes a LIST, anything in the LIST is evaluated in list
3378 context, and any subroutine that you call will have one or more of
3379 its expressions evaluated in list context.  Also be careful not to
3380 follow the print keyword with a left parenthesis unless you want
3381 the corresponding right parenthesis to terminate the arguments to
3382 the print--interpose a C<+> or put parentheses around all the
3383 arguments.
3384
3385 Note that if you're storing FILEHANDLES in an array or other expression,
3386 you will have to use a block returning its value instead:
3387
3388     print { $files[$i] } "stuff\n";
3389     print { $OK ? STDOUT : STDERR } "stuff\n";
3390
3391 =item printf FILEHANDLE FORMAT, LIST
3392
3393 =item printf FORMAT, LIST
3394
3395 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3396 (the output record separator) is not appended.  The first argument
3397 of the list will be interpreted as the C<printf> format.  If C<use locale> is
3398 in effect, the character used for the decimal point in formatted real numbers
3399 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3400
3401 Don't fall into the trap of using a C<printf> when a simple
3402 C<print> would do.  The C<print> is more efficient and less
3403 error prone.
3404
3405 =item prototype FUNCTION
3406
3407 Returns the prototype of a function as a string (or C<undef> if the
3408 function has no prototype).  FUNCTION is a reference to, or the name of,
3409 the function whose prototype you want to retrieve.
3410
3411 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3412 name for Perl builtin.  If the builtin is not I<overridable> (such as
3413 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3414 C<system>) returns C<undef> because the builtin does not really behave
3415 like a Perl function.  Otherwise, the string describing the equivalent
3416 prototype is returned.
3417
3418 =item push ARRAY,LIST
3419
3420 Treats ARRAY as a stack, and pushes the values of LIST
3421 onto the end of ARRAY.  The length of ARRAY increases by the length of
3422 LIST.  Has the same effect as
3423
3424     for $value (LIST) {
3425         $ARRAY[++$#ARRAY] = $value;
3426     }
3427
3428 but is more efficient.  Returns the new number of elements in the array.
3429
3430 =item q/STRING/
3431
3432 =item qq/STRING/
3433
3434 =item qr/STRING/
3435
3436 =item qx/STRING/
3437
3438 =item qw/STRING/
3439
3440 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3441
3442 =item quotemeta EXPR
3443
3444 =item quotemeta
3445
3446 Returns the value of EXPR with all non-"word"
3447 characters backslashed.  (That is, all characters not matching
3448 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3449 returned string, regardless of any locale settings.)
3450 This is the internal function implementing
3451 the C<\Q> escape in double-quoted strings.
3452
3453 If EXPR is omitted, uses C<$_>.
3454
3455 =item rand EXPR
3456
3457 =item rand
3458
3459 Returns a random fractional number greater than or equal to C<0> and less
3460 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3461 omitted, the value C<1> is used.  Automatically calls C<srand> unless
3462 C<srand> has already been called.  See also C<srand>.
3463
3464 (Note: If your rand function consistently returns numbers that are too
3465 large or too small, then your version of Perl was probably compiled
3466 with the wrong number of RANDBITS.)
3467
3468 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3469
3470 =item read FILEHANDLE,SCALAR,LENGTH
3471
3472 Attempts to read LENGTH bytes of data into variable SCALAR from the
3473 specified FILEHANDLE.  Returns the number of bytes actually read,
3474 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
3475 or shrunk to the length actually read.  An OFFSET may be specified to
3476 place the read data at some other place than the beginning of the
3477 string.  This call is actually implemented in terms of stdio's fread(3)
3478 call.  To get a true read(2) system call, see C<sysread>.
3479
3480 =item readdir DIRHANDLE
3481
3482 Returns the next directory entry for a directory opened by C<opendir>.
3483 If used in list context, returns all the rest of the entries in the
3484 directory.  If there are no more entries, returns an undefined value in
3485 scalar context or a null list in list context.
3486
3487 If you're planning to filetest the return values out of a C<readdir>, you'd
3488 better prepend the directory in question.  Otherwise, because we didn't
3489 C<chdir> there, it would have been testing the wrong file.
3490
3491     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3492     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3493     closedir DIR;
3494
3495 =item readline EXPR
3496
3497 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3498 context, each call reads and returns the next line, until end-of-file is
3499 reached, whereupon the subsequent call returns undef.  In list context,
3500 reads until end-of-file is reached and returns a list of lines.  Note that
3501 the notion of "line" used here is however you may have defined it
3502 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3503
3504 When C<$/> is set to C<undef>, when readline() is in scalar
3505 context (i.e. file slurp mode), and when an empty file is read, it
3506 returns C<''> the first time, followed by C<undef> subsequently.
3507
3508 This is the internal function implementing the C<< <EXPR> >>
3509 operator, but you can use it directly.  The C<< <EXPR> >>
3510 operator is discussed in more detail in L<perlop/"I/O Operators">.
3511
3512     $line = <STDIN>;
3513     $line = readline(*STDIN);           # same thing
3514
3515 =item readlink EXPR
3516
3517 =item readlink
3518
3519 Returns the value of a symbolic link, if symbolic links are
3520 implemented.  If not, gives a fatal error.  If there is some system
3521 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3522 omitted, uses C<$_>.
3523
3524 =item readpipe EXPR
3525
3526 EXPR is executed as a system command.
3527 The collected standard output of the command is returned.
3528 In scalar context, it comes back as a single (potentially
3529 multi-line) string.  In list context, returns a list of lines
3530 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3531 This is the internal function implementing the C<qx/EXPR/>
3532 operator, but you can use it directly.  The C<qx/EXPR/>
3533 operator is discussed in more detail in L<perlop/"I/O Operators">.
3534
3535 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3536
3537 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3538 data into variable SCALAR from the specified SOCKET filehandle.  SCALAR
3539 will be grown or shrunk to the length actually read.  Takes the same
3540 flags as the system call of the same name.  Returns the address of the
3541 sender if SOCKET's protocol supports this; returns an empty string
3542 otherwise.  If there's an error, returns the undefined value.  This call
3543 is actually implemented in terms of recvfrom(2) system call.  See
3544 L<perlipc/"UDP: Message Passing"> for examples.
3545
3546 =item redo LABEL
3547
3548 =item redo
3549
3550 The C<redo> command restarts the loop block without evaluating the
3551 conditional again.  The C<continue> block, if any, is not executed.  If
3552 the LABEL is omitted, the command refers to the innermost enclosing
3553 loop.  This command is normally used by programs that want to lie to
3554 themselves about what was just input:
3555
3556     # a simpleminded Pascal comment stripper
3557     # (warning: assumes no { or } in strings)
3558     LINE: while (<STDIN>) {
3559         while (s|({.*}.*){.*}|$1 |) {}
3560         s|{.*}| |;
3561         if (s|{.*| |) {
3562             $front = $_;
3563             while (<STDIN>) {
3564                 if (/}/) {      # end of comment?
3565                     s|^|$front\{|;
3566                     redo LINE;
3567                 }
3568             }
3569         }
3570         print;
3571     }
3572
3573 C<redo> cannot be used to retry a block which returns a value such as
3574 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3575 a grep() or map() operation.
3576
3577 Note that a block by itself is semantically identical to a loop
3578 that executes once.  Thus C<redo> inside such a block will effectively
3579 turn it into a looping construct.
3580
3581 See also L</continue> for an illustration of how C<last>, C<next>, and
3582 C<redo> work.
3583
3584 =item ref EXPR
3585
3586 =item ref
3587
3588 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3589 is not specified, C<$_> will be used.  The value returned depends on the
3590 type of thing the reference is a reference to.
3591 Builtin types include:
3592
3593     SCALAR
3594     ARRAY
3595     HASH
3596     CODE
3597     REF
3598     GLOB
3599     LVALUE
3600
3601 If the referenced object has been blessed into a package, then that package
3602 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3603
3604     if (ref($r) eq "HASH") {
3605         print "r is a reference to a hash.\n";
3606     }
3607     unless (ref($r)) {
3608         print "r is not a reference at all.\n";
3609     }
3610     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3611         print "r is a reference to something that isa hash.\n";
3612     } 
3613
3614 See also L<perlref>.
3615
3616 =item rename OLDNAME,NEWNAME
3617
3618 Changes the name of a file; an existing file NEWNAME will be
3619 clobbered.  Returns true for success, false otherwise.
3620
3621 Behavior of this function varies wildly depending on your system
3622 implementation.  For example, it will usually not work across file system
3623 boundaries, even though the system I<mv> command sometimes compensates
3624 for this.  Other restrictions include whether it works on directories,
3625 open files, or pre-existing files.  Check L<perlport> and either the
3626 rename(2) manpage or equivalent system documentation for details.
3627
3628 =item require VERSION
3629
3630 =item require EXPR
3631
3632 =item require
3633
3634 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3635 supplied.
3636
3637 If a VERSION is specified as a literal of the form v5.6.1,
3638 demands that the current version of Perl (C<$^V> or $PERL_VERSION) be
3639 at least as recent as that version, at run time.  (For compatibility
3640 with older versions of Perl, a numeric argument will also be interpreted
3641 as VERSION.)  Compare with L</use>, which can do a similar check at
3642 compile time.
3643
3644     require v5.6.1;     # run time version check
3645     require 5.6.1;      # ditto
3646     require 5.005_03;   # float version allowed for compatibility
3647
3648 Otherwise, demands that a library file be included if it hasn't already
3649 been included.  The file is included via the do-FILE mechanism, which is
3650 essentially just a variety of C<eval>.  Has semantics similar to the following
3651 subroutine:
3652
3653     sub require {
3654         my($filename) = @_;
3655         return 1 if $INC{$filename};
3656         my($realfilename,$result);
3657         ITER: {
3658             foreach $prefix (@INC) {
3659                 $realfilename = "$prefix/$filename";
3660                 if (-f $realfilename) {
3661                     $INC{$filename} = $realfilename;
3662                     $result = do $realfilename;
3663                     last ITER;
3664                 }
3665             }
3666             die "Can't find $filename in \@INC";
3667         }
3668         delete $INC{$filename} if $@ || !$result;
3669         die $@ if $@;
3670         die "$filename did not return true value" unless $result;
3671         return $result;
3672     }
3673
3674 Note that the file will not be included twice under the same specified
3675 name.  The file must return true as the last statement to indicate
3676 successful execution of any initialization code, so it's customary to
3677 end such a file with C<1;> unless you're sure it'll return true
3678 otherwise.  But it's better just to put the C<1;>, in case you add more
3679 statements.
3680
3681 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3682 replaces "F<::>" with "F</>" in the filename for you,
3683 to make it easy to load standard modules.  This form of loading of
3684 modules does not risk altering your namespace.
3685
3686 In other words, if you try this:
3687
3688         require Foo::Bar;    # a splendid bareword 
3689
3690 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3691 directories specified in the C<@INC> array.
3692
3693 But if you try this:
3694
3695         $class = 'Foo::Bar';
3696         require $class;      # $class is not a bareword
3697     #or
3698         require "Foo::Bar";  # not a bareword because of the ""
3699
3700 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3701 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3702
3703         eval "require $class";
3704
3705 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3706
3707 =item reset EXPR
3708
3709 =item reset
3710
3711 Generally used in a C<continue> block at the end of a loop to clear
3712 variables and reset C<??> searches so that they work again.  The
3713 expression is interpreted as a list of single characters (hyphens
3714 allowed for ranges).  All variables and arrays beginning with one of
3715 those letters are reset to their pristine state.  If the expression is
3716 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3717 only variables or searches in the current package.  Always returns
3718 1.  Examples:
3719
3720     reset 'X';          # reset all X variables
3721     reset 'a-z';        # reset lower case variables
3722     reset;              # just reset ?one-time? searches
3723
3724 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3725 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3726 variables--lexical variables are unaffected, but they clean themselves
3727 up on scope exit anyway, so you'll probably want to use them instead.
3728 See L</my>.
3729
3730 =item return EXPR
3731
3732 =item return
3733
3734 Returns from a subroutine, C<eval>, or C<do FILE> with the value 
3735 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3736 context, depending on how the return value will be used, and the context
3737 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3738 is given, returns an empty list in list context, the undefined value in
3739 scalar context, and (of course) nothing at all in a void context.
3740
3741 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3742 or do FILE will automatically return the value of the last expression
3743 evaluated.)
3744
3745 =item reverse LIST
3746
3747 In list context, returns a list value consisting of the elements
3748 of LIST in the opposite order.  In scalar context, concatenates the
3749 elements of LIST and returns a string value with all characters
3750 in the opposite order.
3751
3752     print reverse <>;           # line tac, last line first
3753
3754     undef $/;                   # for efficiency of <>
3755     print scalar reverse <>;    # character tac, last line tsrif
3756
3757 This operator is also handy for inverting a hash, although there are some
3758 caveats.  If a value is duplicated in the original hash, only one of those
3759 can be represented as a key in the inverted hash.  Also, this has to
3760 unwind one hash and build a whole new one, which may take some time
3761 on a large hash, such as from a DBM file.
3762
3763     %by_name = reverse %by_address;     # Invert the hash
3764
3765 =item rewinddir DIRHANDLE
3766
3767 Sets the current position to the beginning of the directory for the
3768 C<readdir> routine on DIRHANDLE.
3769
3770 =item rindex STR,SUBSTR,POSITION
3771
3772 =item rindex STR,SUBSTR
3773
3774 Works just like index() except that it returns the position of the LAST
3775 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3776 last occurrence at or before that position.
3777
3778 =item rmdir FILENAME
3779
3780 =item rmdir
3781
3782 Deletes the directory specified by FILENAME if that directory is empty.  If it
3783 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3784 FILENAME is omitted, uses C<$_>.
3785
3786 =item s///
3787
3788 The substitution operator.  See L<perlop>.
3789
3790 =item scalar EXPR
3791
3792 Forces EXPR to be interpreted in scalar context and returns the value
3793 of EXPR.
3794
3795     @counts = ( scalar @a, scalar @b, scalar @c );
3796
3797 There is no equivalent operator to force an expression to
3798 be interpolated in list context because in practice, this is never
3799 needed.  If you really wanted to do so, however, you could use
3800 the construction C<@{[ (some expression) ]}>, but usually a simple
3801 C<(some expression)> suffices.
3802
3803 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3804 parenthesized list, this behaves as a scalar comma expression, evaluating
3805 all but the last element in void context and returning the final element
3806 evaluated in scalar context.  This is seldom what you want.
3807
3808 The following single statement:
3809
3810         print uc(scalar(&foo,$bar)),$baz;
3811
3812 is the moral equivalent of these two:
3813
3814         &foo;
3815         print(uc($bar),$baz);
3816
3817 See L<perlop> for more details on unary operators and the comma operator.
3818
3819 =item seek FILEHANDLE,POSITION,WHENCE
3820
3821 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3822 FILEHANDLE may be an expression whose value gives the name of the
3823 filehandle.  The values for WHENCE are C<0> to set the new position to
3824 POSITION, C<1> to set it to the current position plus POSITION, and
3825 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3826 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3827 (start of the file, current position, end of the file) from the Fcntl
3828 module.  Returns C<1> upon success, C<0> otherwise.
3829
3830 If you want to position file for C<sysread> or C<syswrite>, don't use
3831 C<seek>--buffering makes its effect on the file's system position
3832 unpredictable and non-portable.  Use C<sysseek> instead.
3833
3834 Due to the rules and rigors of ANSI C, on some systems you have to do a
3835 seek whenever you switch between reading and writing.  Amongst other
3836 things, this may have the effect of calling stdio's clearerr(3).
3837 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3838
3839     seek(TEST,0,1);
3840
3841 This is also useful for applications emulating C<tail -f>.  Once you hit
3842 EOF on your read, and then sleep for a while, you might have to stick in a
3843 seek() to reset things.  The C<seek> doesn't change the current position,
3844 but it I<does> clear the end-of-file condition on the handle, so that the
3845 next C<< <FILE> >> makes Perl try again to read something.  We hope.
3846
3847 If that doesn't work (some stdios are particularly cantankerous), then
3848 you may need something more like this:
3849
3850     for (;;) {
3851         for ($curpos = tell(FILE); $_ = <FILE>;
3852              $curpos = tell(FILE)) {
3853             # search for some stuff and put it into files
3854         }
3855         sleep($for_a_while);
3856         seek(FILE, $curpos, 0);
3857     }
3858
3859 =item seekdir DIRHANDLE,POS
3860
3861 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
3862 must be a value returned by C<telldir>.  Has the same caveats about
3863 possible directory compaction as the corresponding system library
3864 routine.
3865
3866 =item select FILEHANDLE
3867
3868 =item select
3869
3870 Returns the currently selected filehandle.  Sets the current default
3871 filehandle for output, if FILEHANDLE is supplied.  This has two
3872 effects: first, a C<write> or a C<print> without a filehandle will
3873 default to this FILEHANDLE.  Second, references to variables related to
3874 output will refer to this output channel.  For example, if you have to
3875 set the top of form format for more than one output channel, you might
3876 do the following:
3877
3878     select(REPORT1);
3879     $^ = 'report1_top';
3880     select(REPORT2);
3881     $^ = 'report2_top';
3882
3883 FILEHANDLE may be an expression whose value gives the name of the
3884 actual filehandle.  Thus:
3885
3886     $oldfh = select(STDERR); $| = 1; select($oldfh);
3887
3888 Some programmers may prefer to think of filehandles as objects with
3889 methods, preferring to write the last example as:
3890
3891     use IO::Handle;
3892     STDERR->autoflush(1);
3893
3894 =item select RBITS,WBITS,EBITS,TIMEOUT
3895
3896 This calls the select(2) system call with the bit masks specified, which
3897 can be constructed using C<fileno> and C<vec>, along these lines:
3898
3899     $rin = $win = $ein = '';
3900     vec($rin,fileno(STDIN),1) = 1;
3901     vec($win,fileno(STDOUT),1) = 1;
3902     $ein = $rin | $win;
3903
3904 If you want to select on many filehandles you might wish to write a
3905 subroutine:
3906
3907     sub fhbits {
3908         my(@fhlist) = split(' ',$_[0]);
3909         my($bits);
3910         for (@fhlist) {
3911             vec($bits,fileno($_),1) = 1;
3912         }
3913         $bits;
3914     }
3915     $rin = fhbits('STDIN TTY SOCK');
3916
3917 The usual idiom is:
3918
3919     ($nfound,$timeleft) =
3920       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3921
3922 or to block until something becomes ready just do this
3923
3924     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3925
3926 Most systems do not bother to return anything useful in $timeleft, so
3927 calling select() in scalar context just returns $nfound.
3928
3929 Any of the bit masks can also be undef.  The timeout, if specified, is
3930 in seconds, which may be fractional.  Note: not all implementations are
3931 capable of returning the$timeleft.  If not, they always return
3932 $timeleft equal to the supplied $timeout.
3933
3934 You can effect a sleep of 250 milliseconds this way:
3935
3936     select(undef, undef, undef, 0.25);
3937
3938 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
3939 or <FH>) with C<select>, except as permitted by POSIX, and even
3940 then only on POSIX systems.  You have to use C<sysread> instead.
3941
3942 =item semctl ID,SEMNUM,CMD,ARG
3943
3944 Calls the System V IPC function C<semctl>.  You'll probably have to say
3945
3946     use IPC::SysV;
3947
3948 first to get the correct constant definitions.  If CMD is IPC_STAT or
3949 GETALL, then ARG must be a variable which will hold the returned
3950 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
3951 the undefined value for error, "C<0 but true>" for zero, or the actual
3952 return value otherwise.  The ARG must consist of a vector of native
3953 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
3954 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
3955 documentation.
3956
3957 =item semget KEY,NSEMS,FLAGS
3958
3959 Calls the System V IPC function semget.  Returns the semaphore id, or
3960 the undefined value if there is an error.  See also
3961 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
3962 documentation.
3963
3964 =item semop KEY,OPSTRING
3965
3966 Calls the System V IPC function semop to perform semaphore operations
3967 such as signaling and waiting.  OPSTRING must be a packed array of
3968 semop structures.  Each semop structure can be generated with
3969 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3970 operations is implied by the length of OPSTRING.  Returns true if
3971 successful, or false if there is an error.  As an example, the
3972 following code waits on semaphore $semnum of semaphore id $semid:
3973
3974     $semop = pack("sss", $semnum, -1, 0);
3975     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3976
3977 To signal the semaphore, replace C<-1> with C<1>.  See also
3978 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
3979 documentation.
3980
3981 =item send SOCKET,MSG,FLAGS,TO
3982
3983 =item send SOCKET,MSG,FLAGS
3984
3985 Sends a message on a socket.  Takes the same flags as the system call
3986 of the same name.  On unconnected sockets you must specify a
3987 destination to send TO, in which case it does a C C<sendto>.  Returns
3988 the number of characters sent, or the undefined value if there is an
3989 error.  The C system call sendmsg(2) is currently unimplemented.
3990 See L<perlipc/"UDP: Message Passing"> for examples.
3991
3992 =item setpgrp PID,PGRP
3993
3994 Sets the current process group for the specified PID, C<0> for the current
3995 process.  Will produce a fatal error if used on a machine that doesn't
3996 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
3997 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
3998 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
3999 C<POSIX::setsid()>.
4000
4001 =item setpriority WHICH,WHO,PRIORITY
4002
4003 Sets the current priority for a process, a process group, or a user.
4004 (See setpriority(2).)  Will produce a fatal error if used on a machine
4005 that doesn't implement setpriority(2).
4006
4007 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4008
4009 Sets the socket option requested.  Returns undefined if there is an
4010 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4011 argument.
4012
4013 =item shift ARRAY
4014
4015 =item shift
4016
4017 Shifts the first value of the array off and returns it, shortening the
4018 array by 1 and moving everything down.  If there are no elements in the
4019 array, returns the undefined value.  If ARRAY is omitted, shifts the
4020 C<@_> array within the lexical scope of subroutines and formats, and the
4021 C<@ARGV> array at file scopes or within the lexical scopes established by
4022 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4023 constructs.
4024
4025 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4026 same thing to the left end of an array that C<pop> and C<push> do to the
4027 right end.
4028
4029 =item shmctl ID,CMD,ARG
4030
4031 Calls the System V IPC function shmctl.  You'll probably have to say
4032
4033     use IPC::SysV;
4034
4035 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4036 then ARG must be a variable which will hold the returned C<shmid_ds>
4037 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4038 true" for zero, or the actual return value otherwise.
4039 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4040
4041 =item shmget KEY,SIZE,FLAGS
4042
4043 Calls the System V IPC function shmget.  Returns the shared memory
4044 segment id, or the undefined value if there is an error.
4045 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4046
4047 =item shmread ID,VAR,POS,SIZE
4048
4049 =item shmwrite ID,STRING,POS,SIZE
4050
4051 Reads or writes the System V shared memory segment ID starting at
4052 position POS for size SIZE by attaching to it, copying in/out, and
4053 detaching from it.  When reading, VAR must be a variable that will
4054 hold the data read.  When writing, if STRING is too long, only SIZE
4055 bytes are used; if STRING is too short, nulls are written to fill out
4056 SIZE bytes.  Return true if successful, or false if there is an error.
4057 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4058 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4059
4060 =item shutdown SOCKET,HOW
4061
4062 Shuts down a socket connection in the manner indicated by HOW, which
4063 has the same interpretation as in the system call of the same name.
4064
4065     shutdown(SOCKET, 0);    # I/we have stopped reading data
4066     shutdown(SOCKET, 1);    # I/we have stopped writing data
4067     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4068
4069 This is useful with sockets when you want to tell the other
4070 side you're done writing but not done reading, or vice versa.
4071 It's also a more insistent form of close because it also 
4072 disables the file descriptor in any forked copies in other
4073 processes.
4074
4075 =item sin EXPR
4076
4077 =item sin
4078
4079 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4080 returns sine of C<$_>.
4081
4082 For the inverse sine operation, you may use the C<Math::Trig::asin>
4083 function, or use this relation:
4084
4085     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4086
4087 =item sleep EXPR
4088
4089 =item sleep
4090
4091 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4092 May be interrupted if the process receives a signal such as C<SIGALRM>.
4093 Returns the number of seconds actually slept.  You probably cannot
4094 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4095 using C<alarm>.
4096
4097 On some older systems, it may sleep up to a full second less than what
4098 you requested, depending on how it counts seconds.  Most modern systems
4099 always sleep the full amount.  They may appear to sleep longer than that,
4100 however, because your process might not be scheduled right away in a
4101 busy multitasking system.
4102
4103 For delays of finer granularity than one second, you may use Perl's
4104 C<syscall> interface to access setitimer(2) if your system supports
4105 it, or else see L</select> above.  The Time::HiRes module from CPAN
4106 may also help.
4107
4108 See also the POSIX module's C<sigpause> function.
4109
4110 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4111
4112 Opens a socket of the specified kind and attaches it to filehandle
4113 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4114 the system call of the same name.  You should C<use Socket> first
4115 to get the proper definitions imported.  See the examples in
4116 L<perlipc/"Sockets: Client/Server Communication">.
4117
4118 On systems that support a close-on-exec flag on files, the flag will
4119 be set for the newly opened file descriptor, as determined by the
4120 value of $^F.  See L<perlvar/$^F>.
4121
4122 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4123
4124 Creates an unnamed pair of sockets in the specified domain, of the
4125 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4126 for the system call of the same name.  If unimplemented, yields a fatal
4127 error.  Returns true if successful.
4128
4129 On systems that support a close-on-exec flag on files, the flag will
4130 be set for the newly opened file descriptors, as determined by the value
4131 of $^F.  See L<perlvar/$^F>.
4132
4133 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4134 to C<pipe(Rdr, Wtr)> is essentially:
4135
4136     use Socket;
4137     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4138     shutdown(Rdr, 1);        # no more writing for reader
4139     shutdown(Wtr, 0);        # no more reading for writer
4140
4141 See L<perlipc> for an example of socketpair use.
4142
4143 =item sort SUBNAME LIST
4144
4145 =item sort BLOCK LIST
4146
4147 =item sort LIST
4148
4149 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4150 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4151 specified, it gives the name of a subroutine that returns an integer
4152 less than, equal to, or greater than C<0>, depending on how the elements
4153 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4154 operators are extremely useful in such routines.)  SUBNAME may be a
4155 scalar variable name (unsubscripted), in which case the value provides
4156 the name of (or a reference to) the actual subroutine to use.  In place
4157 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4158 subroutine.
4159
4160 If the subroutine's prototype is C<($$)>, the elements to be compared
4161 are passed by reference in C<@_>, as for a normal subroutine.  This is
4162 slower than unprototyped subroutines, where the elements to be
4163 compared are passed into the subroutine
4164 as the package global variables $a and $b (see example below).  Note that
4165 in the latter case, it is usually counter-productive to declare $a and
4166 $b as lexicals.
4167
4168 In either case, the subroutine may not be recursive.  The values to be
4169 compared are always passed by reference, so don't modify them.
4170
4171 You also cannot exit out of the sort block or subroutine using any of the
4172 loop control operators described in L<perlsyn> or with C<goto>.
4173
4174 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4175 current collation locale.  See L<perllocale>.
4176
4177 Examples:
4178
4179     # sort lexically
4180     @articles = sort @files;
4181
4182     # same thing, but with explicit sort routine
4183     @articles = sort {$a cmp $b} @files;
4184
4185     # now case-insensitively
4186     @articles = sort {uc($a) cmp uc($b)} @files;
4187
4188     # same thing in reversed order
4189     @articles = sort {$b cmp $a} @files;
4190
4191     # sort numerically ascending
4192     @articles = sort {$a <=> $b} @files;
4193
4194     # sort numerically descending
4195     @articles = sort {$b <=> $a} @files;
4196
4197     # this sorts the %age hash by value instead of key
4198     # using an in-line function
4199     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4200
4201     # sort using explicit subroutine name
4202     sub byage {
4203         $age{$a} <=> $age{$b};  # presuming numeric
4204     }
4205     @sortedclass = sort byage @class;
4206
4207     sub backwards { $b cmp $a }
4208     @harry  = qw(dog cat x Cain Abel);
4209     @george = qw(gone chased yz Punished Axed);
4210     print sort @harry;
4211             # prints AbelCaincatdogx
4212     print sort backwards @harry;
4213             # prints xdogcatCainAbel
4214     print sort @george, 'to', @harry;
4215             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4216
4217     # inefficiently sort by descending numeric compare using
4218     # the first integer after the first = sign, or the
4219     # whole record case-insensitively otherwise
4220
4221     @new = sort {
4222         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4223                             ||
4224                     uc($a)  cmp  uc($b)
4225     } @old;
4226
4227     # same thing, but much more efficiently;
4228     # we'll build auxiliary indices instead
4229     # for speed
4230     @nums = @caps = ();
4231     for (@old) {
4232         push @nums, /=(\d+)/;
4233         push @caps, uc($_);
4234     }
4235
4236     @new = @old[ sort {
4237                         $nums[$b] <=> $nums[$a]
4238                                  ||
4239                         $caps[$a] cmp $caps[$b]
4240                        } 0..$#old
4241                ];
4242
4243     # same thing, but without any temps
4244     @new = map { $_->[0] }
4245            sort { $b->[1] <=> $a->[1]
4246                            ||
4247                   $a->[2] cmp $b->[2]
4248            } map { [$_, /=(\d+)/, uc($_)] } @old;
4249
4250     # using a prototype allows you to use any comparison subroutine
4251     # as a sort subroutine (including other package's subroutines)
4252     package other;
4253     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4254
4255     package main;
4256     @new = sort other::backwards @old;
4257
4258 If you're using strict, you I<must not> declare $a
4259 and $b as lexicals.  They are package globals.  That means
4260 if you're in the C<main> package and type
4261   
4262     @articles = sort {$b <=> $a} @files;
4263   
4264 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4265 but if you're in the C<FooPack> package, it's the same as typing
4266
4267     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4268
4269 The comparison function is required to behave.  If it returns
4270 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4271 sometimes saying the opposite, for example) the results are not
4272 well-defined.
4273
4274 =item splice ARRAY,OFFSET,LENGTH,LIST
4275
4276 =item splice ARRAY,OFFSET,LENGTH
4277
4278 =item splice ARRAY,OFFSET
4279
4280 =item splice ARRAY
4281
4282 Removes the elements designated by OFFSET and LENGTH from an array, and
4283 replaces them with the elements of LIST, if any.  In list context,
4284 returns the elements removed from the array.  In scalar context,
4285 returns the last element removed, or C<undef> if no elements are
4286 removed.  The array grows or shrinks as necessary.
4287 If OFFSET is negative then it starts that far from the end of the array.
4288 If LENGTH is omitted, removes everything from OFFSET onward.
4289 If LENGTH is negative, leaves that many elements off the end of the array.
4290 If both OFFSET and LENGTH are omitted, removes everything.
4291
4292 The following equivalences hold (assuming C<$[ == 0>):
4293
4294     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4295     pop(@a)             splice(@a,-1)
4296     shift(@a)           splice(@a,0,1)
4297     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4298     $a[$x] = $y         splice(@a,$x,1,$y)
4299
4300 Example, assuming array lengths are passed before arrays:
4301
4302     sub aeq {   # compare two list values
4303         my(@a) = splice(@_,0,shift);
4304         my(@b) = splice(@_,0,shift);
4305         return 0 unless @a == @b;       # same len?
4306         while (@a) {
4307             return 0 if pop(@a) ne pop(@b);
4308         }
4309         return 1;
4310     }
4311     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4312
4313 =item split /PATTERN/,EXPR,LIMIT
4314
4315 =item split /PATTERN/,EXPR
4316
4317 =item split /PATTERN/
4318
4319 =item split
4320
4321 Splits a string into a list of strings and returns that list.  By default,
4322 empty leading fields are preserved, and empty trailing ones are deleted.
4323
4324 In scalar context, returns the number of fields found and splits into
4325 the C<@_> array.  Use of split in scalar context is deprecated, however,
4326 because it clobbers your subroutine arguments.
4327
4328 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4329 splits on whitespace (after skipping any leading whitespace).  Anything
4330 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4331 that the delimiter may be longer than one character.)
4332
4333 If LIMIT is specified and positive, splits into no more than that
4334 many fields (though it may split into fewer).  If LIMIT is unspecified
4335 or zero, trailing null fields are stripped (which potential users
4336 of C<pop> would do well to remember).  If LIMIT is negative, it is
4337 treated as if an arbitrarily large LIMIT had been specified.
4338
4339 A pattern matching the null string (not to be confused with
4340 a null pattern C<//>, which is just one member of the set of patterns
4341 matching a null string) will split the value of EXPR into separate
4342 characters at each point it matches that way.  For example:
4343
4344     print join(':', split(/ */, 'hi there'));
4345
4346 produces the output 'h:i:t:h:e:r:e'.
4347
4348 The LIMIT parameter can be used to split a line partially
4349
4350     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4351
4352 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4353 one larger than the number of variables in the list, to avoid
4354 unnecessary work.  For the list above LIMIT would have been 4 by
4355 default.  In time critical applications it behooves you not to split
4356 into more fields than you really need.
4357
4358 If the PATTERN contains parentheses, additional list elements are
4359 created from each matching substring in the delimiter.
4360
4361     split(/([,-])/, "1-10,20", 3);
4362
4363 produces the list value
4364
4365     (1, '-', 10, ',', 20)
4366
4367 If you had the entire header of a normal Unix email message in $header,
4368 you could split it up into fields and their values this way:
4369
4370     $header =~ s/\n\s+/ /g;  # fix continuation lines
4371     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4372
4373 The pattern C</PATTERN/> may be replaced with an expression to specify
4374 patterns that vary at runtime.  (To do runtime compilation only once,
4375 use C</$variable/o>.)
4376
4377 As a special case, specifying a PATTERN of space (C<' '>) will split on
4378 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4379 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4380 will give you as many null initial fields as there are leading spaces.
4381 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4382 whitespace produces a null first field.  A C<split> with no arguments
4383 really does a C<split(' ', $_)> internally.
4384
4385 A PATTERN of C</^/> is treated as if it were C</^/m>, since it isn't
4386 much use otherwise.
4387
4388 Example:
4389
4390     open(PASSWD, '/etc/passwd');
4391     while (<PASSWD>) {
4392         ($login, $passwd, $uid, $gid,
4393          $gcos, $home, $shell) = split(/:/);
4394         #...
4395     }
4396
4397 (Note that $shell above will still have a newline on it.  See L</chop>,
4398 L</chomp>, and L</join>.)
4399
4400 =item sprintf FORMAT, LIST
4401
4402 Returns a string formatted by the usual C<printf> conventions of the C
4403 library function C<sprintf>.  See below for more details
4404 and see L<sprintf(3)> or L<printf(3)> on your system for an explanation of
4405 the general principles.
4406
4407 For example:
4408
4409         # Format number with up to 8 leading zeroes
4410         $result = sprintf("%08d", $number);
4411
4412         # Round number to 3 digits after decimal point
4413         $rounded = sprintf("%.3f", $number);
4414
4415 Perl does its own C<sprintf> formatting--it emulates the C
4416 function C<sprintf>, but it doesn't use it (except for floating-point
4417 numbers, and even then only the standard modifiers are allowed).  As a
4418 result, any non-standard extensions in your local C<sprintf> are not
4419 available from Perl.
4420
4421 Unlike C<printf>, C<sprintf> does not do what you probably mean when you
4422 pass it an array as your first argument. The array is given scalar context,
4423 and instead of using the 0th element of the array as the format, Perl will
4424 use the count of elements in the array as the format, which is almost never
4425 useful.
4426
4427 Perl's C<sprintf> permits the following universally-known conversions:
4428
4429    %%   a percent sign
4430    %c   a character with the given number
4431    %s   a string
4432    %d   a signed integer, in decimal
4433    %u   an unsigned integer, in decimal
4434    %o   an unsigned integer, in octal
4435    %x   an unsigned integer, in hexadecimal
4436    %e   a floating-point number, in scientific notation
4437    %f   a floating-point number, in fixed decimal notation
4438    %g   a floating-point number, in %e or %f notation
4439
4440 In addition, Perl permits the following widely-supported conversions:
4441
4442    %X   like %x, but using upper-case letters
4443    %E   like %e, but using an upper-case "E"
4444    %G   like %g, but with an upper-case "E" (if applicable)
4445    %b   an unsigned integer, in binary
4446    %p   a pointer (outputs the Perl value's address in hexadecimal)
4447    %n   special: *stores* the number of characters output so far
4448         into the next variable in the parameter list 
4449
4450 Finally, for backward (and we do mean "backward") compatibility, Perl
4451 permits these unnecessary but widely-supported conversions:
4452
4453    %i   a synonym for %d
4454    %D   a synonym for %ld
4455    %U   a synonym for %lu
4456    %O   a synonym for %lo
4457    %F   a synonym for %f
4458
4459 Note that the number of exponent digits in the scientific notation by
4460 C<%e>, C<%E>, C<%g> and C<%G> for numbers with the modulus of the
4461 exponent less than 100 is system-dependent: it may be three or less
4462 (zero-padded as necessary).  In other words, 1.23 times ten to the
4463 99th may be either "1.23e99" or "1.23e099".
4464
4465 Perl permits the following universally-known flags between the C<%>
4466 and the conversion letter:
4467
4468    space   prefix positive number with a space
4469    +       prefix positive number with a plus sign
4470    -       left-justify within the field
4471    0       use zeros, not spaces, to right-justify
4472    #       prefix non-zero octal with "0", non-zero hex with "0x"
4473    number  minimum field width
4474    .number "precision": digits after decimal point for
4475            floating-point, max length for string, minimum length
4476            for integer
4477    l       interpret integer as C type "long" or "unsigned long"
4478    h       interpret integer as C type "short" or "unsigned short"
4479            If no flags, interpret integer as C type "int" or "unsigned"
4480
4481 There are also two Perl-specific flags:
4482
4483    V       interpret integer as Perl's standard integer type
4484    v       interpret string as a vector of integers, output as
4485            numbers separated either by dots, or by an arbitrary
4486            string received from the argument list when the flag
4487            is preceded by C<*>
4488
4489 Where a number would appear in the flags, an asterisk (C<*>) may be
4490 used instead, in which case Perl uses the next item in the parameter
4491 list as the given number (that is, as the field width or precision).
4492 If a field width obtained through C<*> is negative, it has the same
4493 effect as the C<-> flag: left-justification.
4494
4495 The C<v> flag is useful for displaying ordinal values of characters
4496 in arbitrary strings:
4497
4498     printf "version is v%vd\n", $^V;            # Perl's version
4499     printf "address is %*vX\n", ":", $addr;     # IPv6 address
4500     printf "bits are %*vb\n", " ", $bits;       # random bitstring
4501
4502 If C<use locale> is in effect, the character used for the decimal
4503 point in formatted real numbers is affected by the LC_NUMERIC locale.
4504 See L<perllocale>.
4505
4506 If Perl understands "quads" (64-bit integers) (this requires
4507 either that the platform natively support quads or that Perl
4508 be specifically compiled to support quads), the characters
4509
4510         d u o x X b i D U O
4511
4512 print quads, and they may optionally be preceded by
4513
4514         ll L q
4515
4516 For example
4517
4518         %lld %16LX %qo
4519
4520 You can find out whether your Perl supports quads via L<Config>:
4521
4522         use Config;
4523         ($Config{use64bitint} eq 'define' || $Config{longsize} == 8) &&
4524                 print "quads\n";
4525
4526 If Perl understands "long doubles" (this requires that the platform
4527 support long doubles), the flags
4528
4529         e f g E F G
4530
4531 may optionally be preceded by
4532
4533         ll L
4534
4535 For example
4536
4537         %llf %Lg
4538
4539 You can find out whether your Perl supports long doubles via L<Config>:
4540
4541         use Config;
4542         $Config{d_longdbl} eq 'define' && print "long doubles\n";
4543
4544 =item sqrt EXPR
4545
4546 =item sqrt
4547
4548 Return the square root of EXPR.  If EXPR is omitted, returns square
4549 root of C<$_>.  Only works on non-negative operands, unless you've
4550 loaded the standard Math::Complex module.
4551
4552     use Math::Complex;
4553     print sqrt(-2);    # prints 1.4142135623731i
4554
4555 =item srand EXPR
4556
4557 =item srand
4558
4559 Sets the random number seed for the C<rand> operator.  If EXPR is
4560 omitted, uses a semi-random value supplied by the kernel (if it supports
4561 the F</dev/urandom> device) or based on the current time and process
4562 ID, among other things.  In versions of Perl prior to 5.004 the default
4563 seed was just the current C<time>.  This isn't a particularly good seed,
4564 so many old programs supply their own seed value (often C<time ^ $$> or
4565 C<time ^ ($$ + ($$ << 15))>), but that isn't necessary any more.
4566
4567 In fact, it's usually not necessary to call C<srand> at all, because if
4568 it is not called explicitly, it is called implicitly at the first use of
4569 the C<rand> operator.  However, this was not the case in version of Perl
4570 before 5.004, so if your script will run under older Perl versions, it
4571 should call C<srand>.
4572
4573 Note that you need something much more random than the default seed for
4574 cryptographic purposes.  Checksumming the compressed output of one or more
4575 rapidly changing operating system status programs is the usual method.  For
4576 example:
4577
4578     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
4579
4580 If you're particularly concerned with this, see the C<Math::TrulyRandom>
4581 module in CPAN.
4582
4583 Do I<not> call C<srand> multiple times in your program unless you know
4584 exactly what you're doing and why you're doing it.  The point of the
4585 function is to "seed" the C<rand> function so that C<rand> can produce
4586 a different sequence each time you run your program.  Just do it once at the
4587 top of your program, or you I<won't> get random numbers out of C<rand>!
4588
4589 Frequently called programs (like CGI scripts) that simply use
4590
4591     time ^ $$
4592
4593 for a seed can fall prey to the mathematical property that
4594
4595     a^b == (a+1)^(b+1)
4596
4597 one-third of the time.  So don't do that.
4598
4599 =item stat FILEHANDLE
4600
4601 =item stat EXPR
4602
4603 =item stat
4604
4605 Returns a 13-element list giving the status info for a file, either
4606 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
4607 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
4608 as follows:
4609
4610     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
4611        $atime,$mtime,$ctime,$blksize,$blocks)
4612            = stat($filename);
4613
4614 Not all fields are supported on all filesystem types.  Here are the
4615 meaning of the fields:
4616
4617   0 dev      device number of filesystem
4618   1 ino      inode number
4619   2 mode     file mode  (type and permissions)
4620   3 nlink    number of (hard) links to the file
4621   4 uid      numeric user ID of file's owner
4622   5 gid      numeric group ID of file's owner
4623   6 rdev     the device identifier (special files only)
4624   7 size     total size of file, in bytes
4625   8 atime    last access time in seconds since the epoch
4626   9 mtime    last modify time in seconds since the epoch
4627  10 ctime    inode change time (NOT creation time!) in seconds since the epoch
4628  11 blksize  preferred block size for file system I/O
4629  12 blocks   actual number of blocks allocated
4630
4631 (The epoch was at 00:00 January 1, 1970 GMT.)
4632
4633 If stat is passed the special filehandle consisting of an underline, no
4634 stat is done, but the current contents of the stat structure from the
4635 last stat or filetest are returned.  Example:
4636
4637     if (-x $file && (($d) = stat(_)) && $d < 0) {
4638         print "$file is executable NFS file\n";
4639     }
4640
4641 (This works on machines only for which the device number is negative
4642 under NFS.)
4643
4644 Because the mode contains&