ext/POSIX/t/posix.t

   1 #!./perl
   2
   3 BEGIN {
   4     require Config; import Config;
   5     if ($^O ne 'VMS' and $Config{'extensions'} !~ /\bPOSIX\b/) {
   6         print "1..0\n";
   7         exit 0;
   8     }
   9 }
  10
  11 use Test::More tests => 109;
  12
  13 use POSIX qw(fcntl_h signal_h limits_h _exit getcwd open read strftime write
  14              errno localeconv dup dup2 lseek access);
  15 use strict 'subs';
  16
  17 sub next_test {
  18     my $builder = Test::More->builder;
  19     $builder->current_test($builder->current_test() + 1);
  20 }
  21
  22 $| = 1;
  23
  24 $Is_W32     = $^O eq 'MSWin32';
  25 $Is_Dos     = $^O eq 'dos';
  26 $Is_MacOS   = $^O eq 'MacOS';
  27 $Is_VMS     = $^O eq 'VMS';
  28 $Is_OS2     = $^O eq 'os2';
  29 $Is_UWin    = $^O eq 'uwin';
  30 $Is_OS390   = $^O eq 'os390';
  31
  32 my $vms_unix_rpt = 0;
  33 my $vms_efs = 0;
  34 my $unix_mode = 1;
  35
  36 if ($Is_VMS) {
  37     $unix_mode = 0;
  38     if (eval 'require VMS::Feature') {
  39         $vms_unix_rpt = VMS::Feature::current("filename_unix_report");
  40         $vms_efs = VMS::Feature::current("efs_charset");
  41     } else {
  42         my $unix_rpt = $ENV{'DECC$FILENAME_UNIX_REPORT'} || '';
  43         my $efs_charset = $ENV{'DECC$EFS_CHARSET'} || '';
  44         $vms_unix_rpt = $unix_rpt =~ /^[ET1]/i;
  45         $vms_efs = $efs_charset =~ /^[ET1]/i;
  46     }
  47
  48     # Traditional VMS mode only if VMS is not in UNIX compatible mode.
  49     $unix_mode = ($vms_efs && $vms_unix_rpt);
  50
  51 }
  52
  53 my $testfd = open("Makefile.PL", O_RDONLY, 0);
  54 like($testfd, qr/\A\d+\z/, 'O_RDONLY with open');
  55 read($testfd, $buffer, 4) if $testfd > 2;
  56 is( $buffer, "# Ex",                      '    with read' );
  57
  58 TODO:
  59 {
  60     local $TODO = "read to array element not working";
  61
  62     read($testfd, $buffer[1], 5) if $testfd > 2;
  63     is( $buffer[1], "perl\n",                  '    read to array element' );
  64 }
  65
  66 my $test = next_test();
  67 write(1,"ok $test\nnot ok $test\n", 5);
  68
  69 SKIP: {
  70     skip("no pipe() support on DOS", 2) if $Is_Dos;
  71
  72     @fds = POSIX::pipe();
  73     cmp_ok($fds[0], '>', $testfd, 'POSIX::pipe');
  74
  75     CORE::open($reader = \*READER, "<&=".$fds[0]);
  76     CORE::open($writer = \*WRITER, ">&=".$fds[1]);
  77     my $test = next_test();
  78     print $writer "ok $test\n";
  79     close $writer;
  80     print <$reader>;
  81     close $reader;
  82 }
  83
  84 SKIP: {
  85     skip("no sigaction support on win32/dos", 6) if $Is_W32 || $Is_Dos;
  86
  87     my $sigset = new POSIX::SigSet 1, 3;
  88     $sigset->delset(1);
  89     ok(! $sigset->ismember(1),  'POSIX::SigSet->delset' );
  90     ok(  $sigset->ismember(3),  'POSIX::SigSet->ismember' );
  91
  92     SKIP: {
  93         skip("no kill() support on Mac OS", 4) if $Is_MacOS;
  94
  95         my $sigint_called = 0;
  96
  97         my $mask   = new POSIX::SigSet &SIGINT;
  98         my $action = new POSIX::SigAction 'main::SigHUP', $mask, 0;
  99         sigaction(&SIGHUP, $action);
 100         $SIG{'INT'} = 'SigINT';
 101
 102         # At least OpenBSD/i386 3.3 is okay, as is NetBSD 1.5.
 103         # But not NetBSD 1.6 & 1.6.1: the test makes perl crash.
 104         # So the kill() must not be done with this config in order to
 105         # finish the test.
 106         # For others (darwin & freebsd), let the test fail without crashing.
 107         # the test passes at least from freebsd 8.1
 108         my $todo = $^O eq 'netbsd' && $Config{osvers}=~/^1\.6/;
 109         my $why_todo = "# TODO $^O $Config{osvers} seems to lose blocked signals";
 110         if (!$todo) {
 111           kill 'HUP', $$;
 112         } else {
 113           print "not ok 9 - sigaction SIGHUP ",$why_todo,"\n";
 114           print "not ok 10 - sig mask delayed SIGINT ",$why_todo,"\n";
 115         }
 116         sleep 1;
 117
 118         $todo = 1 if ($^O eq 'freebsd' && $Config{osvers} < 8)
 119                   || ($^O eq 'darwin' && $Config{osvers} < '6.6');
 120         printf "%s 11 - masked SIGINT received %s\n",
 121             $sigint_called ? "ok" : "not ok",
 122             $todo ? $why_todo : '';
 123
 124         print "ok 12 - signal masks successful\n";
 125
 126         sub SigHUP {
 127             print "ok 9 - sigaction SIGHUP\n";
 128             kill 'INT', $$;
 129             sleep 2;
 130             print "ok 10 - sig mask delayed SIGINT\n";
 131         }
 132
 133         sub SigINT {
 134             $sigint_called++;
 135         }
 136
 137         # The order of the above tests is very important, so
 138         # we use literal prints and hard coded numbers.
 139         next_test() for 1..4;
 140     }
 141 }
 142
 143 SKIP: {
 144     skip("_POSIX_OPEN_MAX undefined ($fds[1])",  1) unless &_POSIX_OPEN_MAX;
 145
 146     cmp_ok(&_POSIX_OPEN_MAX, '>=', 16,
 147            "The minimum allowed values according to susv2" );
 148
 149 }
 150
 151 my $pat;
 152 if ( $unix_mode ) {
 153     $pat = qr#[\\/]POSIX$#i;
 154 }
 155 else {
 156     $pat = qr/\.POSIX]/i;
 157 }
 158 like( getcwd(), qr/$pat/, 'getcwd' );
 159
 160 # Check string conversion functions.
 161
 162 SKIP: {
 163     skip("strtod() not present", 2) unless $Config{d_strtod};
 164
 165     if ($Config{d_setlocale}) {
 166         $lc = &POSIX::setlocale(&POSIX::LC_NUMERIC);
 167         &POSIX::setlocale(&POSIX::LC_NUMERIC, 'C');
 168     }
 169
 170     # we're just checking that strtod works, not how accurate it is
 171     ($n, $x) = &POSIX::strtod('3.14159_OR_SO');
 172     cmp_ok(abs("3.14159" - $n), '<', 1e-6, 'strtod works');
 173     is($x, 6, 'strtod works');
 174
 175     &POSIX::setlocale(&POSIX::LC_NUMERIC, $lc) if $Config{d_setlocale};
 176 }
 177
 178 SKIP: {
 179     skip("strtol() not present", 2) unless $Config{d_strtol};
 180
 181     ($n, $x) = &POSIX::strtol('21_PENGUINS');
 182     is($n, 21, 'strtol() number');
 183     is($x, 9,  '         unparsed chars');
 184 }
 185
 186 SKIP: {
 187     skip("strtoul() not present", 2) unless $Config{d_strtoul};
 188
 189     ($n, $x) = &POSIX::strtoul('88_TEARS');
 190     is($n, 88, 'strtoul() number');
 191     is($x, 6,  '          unparsed chars');
 192 }
 193
 194 # Pick up whether we're really able to dynamically load everything.
 195 cmp_ok(&POSIX::acos(1.0), '==', 0.0, 'dynamic loading');
 196
 197 # This can coredump if struct tm has a timezone field and we
 198 # didn't detect it.  If this fails, try adding
 199 # -DSTRUCT_TM_HASZONE to your cflags when compiling ext/POSIX/POSIX.c.
 200 # See ext/POSIX/hints/sunos_4.pl and ext/POSIX/hints/linux.pl
 201 $test = next_test();
 202 print POSIX::strftime("ok $test # %H:%M, on %m/%d/%y\n", localtime());
 203
 204 # If that worked, validate the mini_mktime() routine's normalisation of
 205 # input fields to strftime().
 206 sub try_strftime {
 207     my $expect = shift;
 208     my $got = POSIX::strftime("%a %b %d %H:%M:%S %Y %j", @_);
 209     is($got, $expect, "validating mini_mktime() and strftime(): $expect");
 210 }
 211
 212 if ($Config{d_setlocale}) {
 213     $lc = &POSIX::setlocale(&POSIX::LC_TIME);
 214     &POSIX::setlocale(&POSIX::LC_TIME, 'C');
 215 }
 216
 217 try_strftime("Wed Feb 28 00:00:00 1996 059", 0,0,0, 28,1,96);
 218 SKIP: {
 219     skip("VC++ 8 and Vista's CRTs regard 60 seconds as an invalid parameter", 1)
 220         if ($Is_W32
 221             and (($Config{cc} eq 'cl' and
 222                     $Config{ccversion} =~ /^(\d+)/ and $1 >= 14)
 223                 or ($Config{cc} eq 'icl' and
 224                     `cl --version 2>&1` =~ /^.*Version\s+([\d.]+)/ and $1 >= 14)
 225                 or (Win32::GetOSVersion())[1] >= 6));
 226
 227     try_strftime("Thu Feb 29 00:00:60 1996 060", 60,0,-24, 30,1,96);
 228 }
 229 try_strftime("Fri Mar 01 00:00:00 1996 061", 0,0,-24, 31,1,96);
 230 try_strftime("Sun Feb 28 00:00:00 1999 059", 0,0,0, 28,1,99);
 231 try_strftime("Mon Mar 01 00:00:00 1999 060", 0,0,24, 28,1,99);
 232 try_strftime("Mon Feb 28 00:00:00 2000 059", 0,0,0, 28,1,100);
 233 try_strftime("Tue Feb 29 00:00:00 2000 060", 0,0,0, 0,2,100);
 234 try_strftime("Wed Mar 01 00:00:00 2000 061", 0,0,0, 1,2,100);
 235 try_strftime("Fri Mar 31 00:00:00 2000 091", 0,0,0, 31,2,100);
 236
 237 { # rt 72232
 238
 239   # Std C/POSIX allows day/month to be negative and requires that
 240   # wday/yday be adjusted as needed
 241   # previously mini_mktime() would allow yday to dominate if mday and
 242   # month were both non-positive
 243   # check that yday doesn't dominate
 244   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100);
 245   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100,-1,10);
 246   # it would also allow a positive wday to override the calculated value
 247   # check that wday is recalculated too
 248   try_strftime("Thu Dec 30 00:00:00 1999 364", 0,0,0, -1,0,100,0,10);
 249 }
 250
 251 &POSIX::setlocale(&POSIX::LC_TIME, $lc) if $Config{d_setlocale};
 252
 253 {
 254     for my $test (0, 1) {
 255         $! = 0;
 256         # POSIX::errno is autoloaded.
 257         # Autoloading requires many system calls.
 258         # errno() looks at $! to generate its result.
 259         # Autoloading should not munge the value.
 260         my $foo  = $!;
 261         my $errno = POSIX::errno();
 262
 263         # Force numeric context.
 264         is( $errno + 0, $foo + 0,     'autoloading and errno() mix' );
 265     }
 266 }
 267
 268 SKIP: {
 269   skip("no kill() support on Mac OS", 1) if $Is_MacOS;
 270   is (eval "kill 0", 0, "check we have CORE::kill")
 271     or print "\$\@ is " . _qq($@) . "\n";
 272 }
 273
 274 # Check that we can import the POSIX kill routine
 275 POSIX->import ('kill');
 276 my $result = eval "kill 0";
 277 is ($result, undef, "we should now have POSIX::kill");
 278 # Check usage.
 279 like ($@, qr/^Usage: POSIX::kill\(pid, sig\)/, "check its usage message");
 280
 281 # Check unimplemented.
 282 $result = eval {POSIX::offsetof};
 283 is ($result, undef, "offsetof should fail");
 284 like ($@, qr/^Unimplemented: POSIX::offsetof\(\) is C-specific/,
 285       "check its unimplemented message");
 286
 287 # Check reimplemented.
 288 $result = eval {POSIX::fgets};
 289 is ($result, undef, "fgets should fail");
 290 like ($@, qr/^Use method IO::Handle::gets\(\) instead/,
 291       "check its redef message");
 292
 293 {
 294     no warnings 'deprecated';
 295     # Simplistic tests for the isXXX() functions (bug #16799)
 296     ok( POSIX::isalnum('1'),  'isalnum' );
 297     ok(!POSIX::isalnum('*'),  'isalnum' );
 298     ok( POSIX::isalpha('f'),  'isalpha' );
 299     ok(!POSIX::isalpha('7'),  'isalpha' );
 300     ok( POSIX::iscntrl("\cA"),'iscntrl' );
 301     ok(!POSIX::iscntrl("A"),  'iscntrl' );
 302     ok( POSIX::isdigit('1'),  'isdigit' );
 303     ok(!POSIX::isdigit('z'),  'isdigit' );
 304     ok( POSIX::isgraph('@'),  'isgraph' );
 305     ok(!POSIX::isgraph(' '),  'isgraph' );
 306     ok( POSIX::islower('l'),  'islower' );
 307     ok(!POSIX::islower('L'),  'islower' );
 308     ok( POSIX::isupper('U'),  'isupper' );
 309     ok(!POSIX::isupper('u'),  'isupper' );
 310     ok( POSIX::isprint('$'),  'isprint' );
 311     ok(!POSIX::isprint("\n"), 'isprint' );
 312     ok( POSIX::ispunct('%'),  'ispunct' );
 313     ok(!POSIX::ispunct('u'),  'ispunct' );
 314     ok( POSIX::isspace("\t"), 'isspace' );
 315     ok(!POSIX::isspace('_'),  'isspace' );
 316     ok( POSIX::isxdigit('f'), 'isxdigit' );
 317     ok(!POSIX::isxdigit('g'), 'isxdigit' );
 318     # metaphysical question : what should be returned for an empty string ?
 319     # anyway this shouldn't segfault (bug #24554)
 320     ok( POSIX::isalnum(''),   'isalnum empty string' );
 321     ok( POSIX::isalnum(undef),'isalnum undef' );
 322     # those functions should stringify their arguments
 323     ok(!POSIX::isalpha([]),   'isalpha []' );
 324     ok( POSIX::isprint([]),   'isprint []' );
 325 }
 326
 327 eval { use strict; POSIX->import("S_ISBLK"); my $x = S_ISBLK };
 328 unlike( $@, qr/Can't use string .* as a symbol ref/, "Can import autoloaded constants" );
 329
 330 SKIP: {
 331     skip("localeconv() not present", 20) unless $Config{d_locconv};
 332     my $conv = localeconv;
 333     is(ref $conv, 'HASH', 'localconv returns a hash reference');
 334
 335     foreach (qw(decimal_point thousands_sep grouping int_curr_symbol
 336                 currency_symbol mon_decimal_point mon_thousands_sep
 337                 mon_grouping positive_sign negative_sign)) {
 338     SKIP: {
 339             skip("localeconv has no result for $_", 1)
 340                 unless exists $conv->{$_};
 341             unlike(delete $conv->{$_}, qr/\A\z/,
 342                    "localeconv returned a non-empty string for $_");
 343         }
 344     }
 345
 346     foreach (qw(int_frac_digits frac_digits p_cs_precedes p_sep_by_space
 347                 n_cs_precedes n_sep_by_space p_sign_posn n_sign_posn)) {
 348     SKIP: {
 349             skip("localeconv has no result for $_", 1)
 350                 unless exists $conv->{$_};
 351             like(delete $conv->{$_}, qr/\A-?\d+\z/,
 352                  "localeconv returned an integer for $_");
 353         }
 354     }
 355     is_deeply([%$conv], [], 'no unexpected keys returned by localeconv');
 356 }
 357
 358 my $fd1 = open("Makefile.PL", O_RDONLY, 0);
 359 like($fd1, qr/\A\d+\z/, 'O_RDONLY with open');
 360 cmp_ok($fd1, '>', $testfd);
 361 my $fd2 = dup($fd1);
 362 like($fd2, qr/\A\d+\z/, 'dup');
 363 cmp_ok($fd2, '>', $fd1);
 364 is(POSIX::close($fd1), '0 but true', 'close');
 365 is(POSIX::close($testfd), '0 but true', 'close');
 366 $! = 0;
 367 undef $buffer;
 368 is(read($fd1, $buffer, 4), undef, 'read on closed file handle fails');
 369 cmp_ok($!, '==', POSIX::EBADF);
 370 undef $buffer;
 371 read($fd2, $buffer, 4) if $fd2 > 2;
 372 is($buffer, "# Ex", 'read');
 373 # The descriptor $testfd was using is now free, and is lower than that which
 374 # $fd1 was using. Hence if dup2() behaves as dup(), we'll know :-)
 375 {
 376     $testfd = dup2($fd2, $fd1);
 377     is($testfd, $fd1, 'dup2');
 378     undef $buffer;
 379     read($testfd, $buffer, 4) if $testfd > 2;
 380     is($buffer, 'pect', 'read');
 381     is(lseek($testfd, 0, 0), 0, 'lseek back');
 382     # The two should share file position:
 383     undef $buffer;
 384     read($fd2, $buffer, 4) if $fd2 > 2;
 385     is($buffer, "# Ex", 'read');
 386 }
 387
 388 # The FreeBSD man page warns:
 389 # The access() system call is a potential security hole due to race
 390 # conditions and should never be used.
 391 is(access('Makefile.PL', POSIX::F_OK), '0 but true', 'access');
 392 is(access('Makefile.PL', POSIX::R_OK), '0 but true', 'access');
 393 $! = 0;
 394 is(access('no such file', POSIX::F_OK), undef, 'access on missing file');
 395 cmp_ok($!, '==', POSIX::ENOENT);
 396 is(access('Makefile.PL/nonsense', POSIX::F_OK), undef,
 397    'access on not-a-directory');
 398 SKIP: {
 399     skip("$^O is insufficiently POSIX", 1)
 400         if $Is_W32 || $Is_VMS;
 401     cmp_ok($!, '==', POSIX::ENOTDIR);
 402 }
 403
 404 # Check that output is not flushed by _exit. This test should be last
 405 # in the file, and is not counted in the total number of tests.
 406 if ($^O eq 'vos') {
 407  print "# TODO - hit VOS bug posix-885 - _exit flushes output buffers.\n";
 408 } else {
 409  $| = 0;
 410  # The following line assumes buffered output, which may be not true:
 411  print '@#!*$@(!@#$' unless ($Is_MacOS || $Is_OS2 || $Is_UWin || $Is_OS390 ||
 412                             $Is_VMS ||
 413                             (defined $ENV{PERLIO} &&
 414                              $ENV{PERLIO} eq 'unix' &&
 415                              $Config::Config{useperlio}));
 416  _exit(0);
 417 }