This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
update docs for $`, $&, $' changes
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of line only at the left and right ends of the string to
35 matching them anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in an inverted bracketed
76 character class, which otherwise could be highly confusing.  See
77 L<perlrecharclass/Negation>.
78
79 Another bug involves character classes that match both a sequence of
80 multiple characters, and an initial sub-string of that sequence.  For
81 example,
82
83  /[s\xDF]/i
84
85 should match both a single and a double "s", since C<\xDF> (on ASCII
86 platforms) matches "ss".  However, this bug
87 (L<[perl #89774]|https://rt.perl.org/rt3/Ticket/Display.html?id=89774>)
88 causes it to only match a single "s", even if the final larger match
89 fails, and matching the double "ss" would have succeeded.
90
91 Also, Perl matching doesn't fully conform to the current Unicode C</i>
92 recommendations, which ask that the matching be made upon the NFD
93 (Normalization Form Decomposed) of the text.  However, Unicode is
94 in the process of reconsidering and revising their recommendations.
95
96 =item x
97 X</x>
98
99 Extend your pattern's legibility by permitting whitespace and comments.
100 Details in L</"/x">
101
102 =item p
103 X</p> X<regex, preserve> X<regexp, preserve>
104
105 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
106 ${^POSTMATCH} are available for use after matching.
107
108 =item g and c
109 X</g> X</c>
110
111 Global matching, and keep the Current position after failed matching.
112 Unlike i, m, s and x, these two flags affect the way the regex is used
113 rather than the regex itself. See
114 L<perlretut/"Using regular expressions in Perl"> for further explanation
115 of the g and c modifiers.
116
117 =item a, d, l and u
118 X</a> X</d> X</l> X</u>
119
120 These modifiers, all new in 5.14, affect which character-set semantics
121 (Unicode, etc.) are used, as described below in
122 L</Character set modifiers>.
123
124 =back
125
126 Regular expression modifiers are usually written in documentation
127 as e.g., "the C</x> modifier", even though the delimiter
128 in question might not really be a slash.  The modifiers C</imsxadlup>
129 may also be embedded within the regular expression itself using
130 the C<(?...)> construct, see L</Extended Patterns> below.
131
132 =head3 /x
133
134 C</x> tells
135 the regular expression parser to ignore most whitespace that is neither
136 backslashed nor within a character class.  You can use this to break up
137 your regular expression into (slightly) more readable parts.  The C<#>
138 character is also treated as a metacharacter introducing a comment,
139 just as in ordinary Perl code.  This also means that if you want real
140 whitespace or C<#> characters in the pattern (outside a character
141 class, where they are unaffected by C</x>), then you'll either have to
142 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
143 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
144 making Perl's regular expressions more readable.  Note that you have to
145 be careful not to include the pattern delimiter in the comment--perl has
146 no way of knowing you did not intend to close the pattern early.  See
147 the C-comment deletion code in L<perlop>.  Also note that anything inside
148 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
149 space interpretation within a single multi-character construct.  For
150 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
151 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
152 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
153 but can between the C<(> and C<?>.  Within any delimiters for such a
154 construct, allowed spaces are not affected by C</x>, and depend on the
155 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
156 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
157 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
158 L<perluniprops/Properties accessible through \p{} and \P{}>.
159 X</x>
160
161 =head3 Character set modifiers
162
163 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
164 the character set modifiers; they affect the character set semantics
165 used for the regular expression.
166
167 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
168 to you, and so you need not worry about them very much.  They exist for
169 Perl's internal use, so that complex regular expression data structures
170 can be automatically serialized and later exactly reconstituted,
171 including all their nuances.  But, since Perl can't keep a secret, and
172 there may be rare instances where they are useful, they are documented
173 here.
174
175 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
176 allow code that is to work mostly on ASCII data to not have to concern
177 itself with Unicode.
178
179 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
180 effect at the time of the execution of the pattern match.
181
182 C</u> sets the character set to B<U>nicode.
183
184 C</a> also sets the character set to Unicode, BUT adds several
185 restrictions for B<A>SCII-safe matching.
186
187 C</d> is the old, problematic, pre-5.14 B<D>efault character set
188 behavior.  Its only use is to force that old behavior.
189
190 At any given time, exactly one of these modifiers is in effect.  Their
191 existence allows Perl to keep the originally compiled behavior of a
192 regular expression, regardless of what rules are in effect when it is
193 actually executed.  And if it is interpolated into a larger regex, the
194 original's rules continue to apply to it, and only it.
195
196 The C</l> and C</u> modifiers are automatically selected for
197 regular expressions compiled within the scope of various pragmas,
198 and we recommend that in general, you use those pragmas instead of
199 specifying these modifiers explicitly.  For one thing, the modifiers
200 affect only pattern matching, and do not extend to even any replacement
201 done, whereas using the pragmas give consistent results for all
202 appropriate operations within their scopes.  For example,
203
204  s/foo/\Ubar/il
205
206 will match "foo" using the locale's rules for case-insensitive matching,
207 but the C</l> does not affect how the C<\U> operates.  Most likely you
208 want both of them to use locale rules.  To do this, instead compile the
209 regular expression within the scope of C<use locale>.  This both
210 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
211 lesson is to C<use locale> and not C</l> explicitly.
212
213 Similarly, it would be better to use C<use feature 'unicode_strings'>
214 instead of,
215
216  s/foo/\Lbar/iu
217
218 to get Unicode rules, as the C<\L> in the former (but not necessarily
219 the latter) would also use Unicode rules.
220
221 More detail on each of the modifiers follows.  Most likely you don't
222 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
223 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
224
225 =head4 /l
226
227 means to use the current locale's rules (see L<perllocale>) when pattern
228 matching.  For example, C<\w> will match the "word" characters of that
229 locale, and C<"/i"> case-insensitive matching will match according to
230 the locale's case folding rules.  The locale used will be the one in
231 effect at the time of execution of the pattern match.  This may not be
232 the same as the compilation-time locale, and can differ from one match
233 to another if there is an intervening call of the
234 L<setlocale() function|perllocale/The setlocale function>.
235
236 Perl only supports single-byte locales.  This means that code points
237 above 255 are treated as Unicode no matter what locale is in effect.
238 Under Unicode rules, there are a few case-insensitive matches that cross
239 the 255/256 boundary.  These are disallowed under C</l>.  For example,
240 0xFF (on ASCII platforms) does not caselessly match the character at
241 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
242 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
243 has no way of knowing if that character even exists in the locale, much
244 less what code point it is.
245
246 This modifier may be specified to be the default by C<use locale>, but
247 see L</Which character set modifier is in effect?>.
248 X</l>
249
250 =head4 /u
251
252 means to use Unicode rules when pattern matching.  On ASCII platforms,
253 this means that the code points between 128 and 255 take on their
254 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
255 (Otherwise Perl considers their meanings to be undefined.)  Thus,
256 under this modifier, the ASCII platform effectively becomes a Unicode
257 platform; and hence, for example, C<\w> will match any of the more than
258 100_000 word characters in Unicode.
259
260 Unlike most locales, which are specific to a language and country pair,
261 Unicode classifies all the characters that are letters I<somewhere> in
262 the world as
263 C<\w>.  For example, your locale might not think that C<LATIN SMALL
264 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
265 Unicode does.  Similarly, all the characters that are decimal digits
266 somewhere in the world will match C<\d>; this is hundreds, not 10,
267 possible matches.  And some of those digits look like some of the 10
268 ASCII digits, but mean a different number, so a human could easily think
269 a number is a different quantity than it really is.  For example,
270 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
271 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
272 that are a mixture from different writing systems, creating a security
273 issue.  L<Unicode::UCD/num()> can be used to sort
274 this out.  Or the C</a> modifier can be used to force C<\d> to match
275 just the ASCII 0 through 9.
276
277 Also, under this modifier, case-insensitive matching works on the full
278 set of Unicode
279 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
280 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
281 if you're not prepared, might make it look like a hexadecimal constant,
282 presenting another potential security issue.  See
283 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
284 security issues.
285
286 On the EBCDIC platforms that Perl handles, the native character set is
287 equivalent to Latin-1.  Thus this modifier changes behavior only when
288 the C<"/i"> modifier is also specified, and it turns out it affects only
289 two characters, giving them full Unicode semantics: the C<MICRO SIGN>
290 will match the Greek capital and small letters C<MU>, otherwise not; and
291 the C<LATIN CAPITAL LETTER SHARP S> will match any of C<SS>, C<Ss>,
292 C<sS>, and C<ss>, otherwise not.
293
294 This modifier may be specified to be the default by C<use feature
295 'unicode_strings>, C<use locale ':not_characters'>, or
296 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
297 but see L</Which character set modifier is in effect?>.
298 X</u>
299
300 =head4 /d
301
302 This modifier means to use the "Default" native rules of the platform
303 except when there is cause to use Unicode rules instead, as follows:
304
305 =over 4
306
307 =item 1
308
309 the target string is encoded in UTF-8; or
310
311 =item 2
312
313 the pattern is encoded in UTF-8; or
314
315 =item 3
316
317 the pattern explicitly mentions a code point that is above 255 (say by
318 C<\x{100}>); or
319
320 =item 4
321
322 the pattern uses a Unicode name (C<\N{...}>);  or
323
324 =item 5
325
326 the pattern uses a Unicode property (C<\p{...}>)
327
328 =back
329
330 Another mnemonic for this modifier is "Depends", as the rules actually
331 used depend on various things, and as a result you can get unexpected
332 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
333 become rather infamous, leading to yet another (printable) name for this
334 modifier, "Dodgy".
335
336 On ASCII platforms, the native rules are ASCII, and on EBCDIC platforms
337 (at least the ones that Perl handles), they are Latin-1.
338
339 Here are some examples of how that works on an ASCII platform:
340
341  $str =  "\xDF";      # $str is not in UTF-8 format.
342  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
343  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
344  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
345  chop $str;
346  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
347
348 This modifier is automatically selected by default when none of the
349 others are, so yet another name for it is "Default".
350
351 Because of the unexpected behaviors associated with this modifier, you
352 probably should only use it to maintain weird backward compatibilities.
353
354 =head4 /a (and /aa)
355
356 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
357 unlike the others, may be doubled-up to increase its effect.
358
359 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
360 the Posix character classes to match only in the ASCII range.  They thus
361 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
362 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
363 characters C<[ \f\n\r\t]>; C<\w> means the 63 characters
364 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
365 C<[[:print:]]> match only the appropriate ASCII-range characters.
366
367 This modifier is useful for people who only incidentally use Unicode,
368 and who do not wish to be burdened with its complexities and security
369 concerns.
370
371 With C</a>, one can write C<\d> with confidence that it will only match
372 ASCII characters, and should the need arise to match beyond ASCII, you
373 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
374 similar C<\p{...}> constructs that can match beyond ASCII both white
375 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
376 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
377 doesn't mean you can't use Unicode, it means that to get Unicode
378 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
379 signals Unicode.
380
381 As you would expect, this modifier causes, for example, C<\D> to mean
382 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
383 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
384 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
385 for C<\B>).
386
387 Otherwise, C</a> behaves like the C</u> modifier, in that
388 case-insensitive matching uses Unicode semantics; for example, "k" will
389 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
390 points in the Latin1 range, above ASCII will have Unicode rules when it
391 comes to case-insensitive matching.
392
393 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
394 specify the "a" twice, for example C</aai> or C</aia>.  (The first
395 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
396 adds the C</i> restrictions.)  But, note that code points outside the
397 ASCII range will use Unicode rules for C</i> matching, so the modifier
398 doesn't really restrict things to just ASCII; it just forbids the
399 intermixing of ASCII and non-ASCII.
400
401 To summarize, this modifier provides protection for applications that
402 don't wish to be exposed to all of Unicode.  Specifying it twice
403 gives added protection.
404
405 This modifier may be specified to be the default by C<use re '/a'>
406 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
407 the C</u> modifier explictly if there are a few regular expressions
408 where you do want full Unicode rules (but even here, it's best if
409 everything were under feature C<"unicode_strings">, along with the
410 C<use re '/aa'>).  Also see L</Which character set modifier is in
411 effect?>.
412 X</a>
413 X</aa>
414
415 =head4 Which character set modifier is in effect?
416
417 Which of these modifiers is in effect at any given point in a regular
418 expression depends on a fairly complex set of interactions.  These have
419 been designed so that in general you don't have to worry about it, but
420 this section gives the gory details.  As
421 explained below in L</Extended Patterns> it is possible to explicitly
422 specify modifiers that apply only to portions of a regular expression.
423 The innermost always has priority over any outer ones, and one applying
424 to the whole expression has priority over any of the default settings that are
425 described in the remainder of this section.
426
427 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
428 default modifiers (including these) for regular expressions compiled
429 within its scope.  This pragma has precedence over the other pragmas
430 listed below that also change the defaults.
431
432 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
433 and C<L<use feature 'unicode_strings|feature>>, or
434 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
435 C</u> when not in the same scope as either C<L<use locale|perllocale>>
436 or C<L<use bytes|bytes>>.
437 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
438 sets the default to C</u>, overriding any plain C<use locale>.)
439 Unlike the mechanisms mentioned above, these
440 affect operations besides regular expressions pattern matching, and so
441 give more consistent results with other operators, including using
442 C<\U>, C<\l>, etc. in substitution replacements.
443
444 If none of the above apply, for backwards compatibility reasons, the
445 C</d> modifier is the one in effect by default.  As this can lead to
446 unexpected results, it is best to specify which other rule set should be
447 used.
448
449 =head4 Character set modifier behavior prior to Perl 5.14
450
451 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
452 for regexes compiled within the scope of C<use locale>, and C</d> was
453 implied otherwise.  However, interpolating a regex into a larger regex
454 would ignore the original compilation in favor of whatever was in effect
455 at the time of the second compilation.  There were a number of
456 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
457 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
458 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
459
460 =head2 Regular Expressions
461
462 =head3 Metacharacters
463
464 The patterns used in Perl pattern matching evolved from those supplied in
465 the Version 8 regex routines.  (The routines are derived
466 (distantly) from Henry Spencer's freely redistributable reimplementation
467 of the V8 routines.)  See L<Version 8 Regular Expressions> for
468 details.
469
470 In particular the following metacharacters have their standard I<egrep>-ish
471 meanings:
472 X<metacharacter>
473 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
474
475
476     \        Quote the next metacharacter
477     ^        Match the beginning of the line
478     .        Match any character (except newline)
479     $        Match the end of the line (or before newline at the end)
480     |        Alternation
481     ()       Grouping
482     []       Bracketed Character class
483
484 By default, the "^" character is guaranteed to match only the
485 beginning of the string, the "$" character only the end (or before the
486 newline at the end), and Perl does certain optimizations with the
487 assumption that the string contains only one line.  Embedded newlines
488 will not be matched by "^" or "$".  You may, however, wish to treat a
489 string as a multi-line buffer, such that the "^" will match after any
490 newline within the string (except if the newline is the last character in
491 the string), and "$" will match before any newline.  At the
492 cost of a little more overhead, you can do this by using the /m modifier
493 on the pattern match operator.  (Older programs did this by setting C<$*>,
494 but this option was removed in perl 5.10.)
495 X<^> X<$> X</m>
496
497 To simplify multi-line substitutions, the "." character never matches a
498 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
499 the string is a single line--even if it isn't.
500 X<.> X</s>
501
502 =head3 Quantifiers
503
504 The following standard quantifiers are recognized:
505 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
506
507     *           Match 0 or more times
508     +           Match 1 or more times
509     ?           Match 1 or 0 times
510     {n}         Match exactly n times
511     {n,}        Match at least n times
512     {n,m}       Match at least n but not more than m times
513
514 (If a curly bracket occurs in any other context and does not form part of
515 a backslashed sequence like C<\x{...}>, it is treated
516 as a regular character.  In particular, the lower quantifier bound
517 is not optional.  However, in Perl v5.18, it is planned to issue a
518 deprecation warning for all such occurrences, and in Perl v5.20 to
519 require literal uses of a curly bracket to be escaped, say by preceding
520 them with a backslash or enclosing them within square brackets, (C<"\{">
521 or C<"[{]">).  This change will allow for future syntax extensions (like
522 making the lower bound of a quantifier optional), and better error
523 checking of quantifiers.  Now, a typo in a quantifier silently causes
524 it to be treated as the literal characters.  For example,
525
526     /o{4,3}/
527
528 looks like a quantifier that matches 0 times, since 4 is greater than 3,
529 but it really means to match the sequence of six characters
530 S<C<"o { 4 , 3 }">>.)
531
532 The "*" quantifier is equivalent to C<{0,}>, the "+"
533 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
534 to non-negative integral values less than a preset limit defined when perl is built.
535 This is usually 32766 on the most common platforms.  The actual limit can
536 be seen in the error message generated by code such as this:
537
538     $_ **= $_ , / {$_} / for 2 .. 42;
539
540 By default, a quantified subpattern is "greedy", that is, it will match as
541 many times as possible (given a particular starting location) while still
542 allowing the rest of the pattern to match.  If you want it to match the
543 minimum number of times possible, follow the quantifier with a "?".  Note
544 that the meanings don't change, just the "greediness":
545 X<metacharacter> X<greedy> X<greediness>
546 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
547
548     *?        Match 0 or more times, not greedily
549     +?        Match 1 or more times, not greedily
550     ??        Match 0 or 1 time, not greedily
551     {n}?      Match exactly n times, not greedily (redundant)
552     {n,}?     Match at least n times, not greedily
553     {n,m}?    Match at least n but not more than m times, not greedily
554
555 By default, when a quantified subpattern does not allow the rest of the
556 overall pattern to match, Perl will backtrack. However, this behaviour is
557 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
558 as well.
559
560  *+     Match 0 or more times and give nothing back
561  ++     Match 1 or more times and give nothing back
562  ?+     Match 0 or 1 time and give nothing back
563  {n}+   Match exactly n times and give nothing back (redundant)
564  {n,}+  Match at least n times and give nothing back
565  {n,m}+ Match at least n but not more than m times and give nothing back
566
567 For instance,
568
569    'aaaa' =~ /a++a/
570
571 will never match, as the C<a++> will gobble up all the C<a>'s in the
572 string and won't leave any for the remaining part of the pattern. This
573 feature can be extremely useful to give perl hints about where it
574 shouldn't backtrack. For instance, the typical "match a double-quoted
575 string" problem can be most efficiently performed when written as:
576
577    /"(?:[^"\\]++|\\.)*+"/
578
579 as we know that if the final quote does not match, backtracking will not
580 help. See the independent subexpression
581 L</C<< (?>pattern) >>> for more details;
582 possessive quantifiers are just syntactic sugar for that construct. For
583 instance the above example could also be written as follows:
584
585    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
586
587 =head3 Escape sequences
588
589 Because patterns are processed as double-quoted strings, the following
590 also work:
591
592  \t          tab                   (HT, TAB)
593  \n          newline               (LF, NL)
594  \r          return                (CR)
595  \f          form feed             (FF)
596  \a          alarm (bell)          (BEL)
597  \e          escape (think troff)  (ESC)
598  \cK         control char          (example: VT)
599  \x{}, \x00  character whose ordinal is the given hexadecimal number
600  \N{name}    named Unicode character or character sequence
601  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
602  \o{}, \000  character whose ordinal is the given octal number
603  \l          lowercase next char (think vi)
604  \u          uppercase next char (think vi)
605  \L          lowercase till \E (think vi)
606  \U          uppercase till \E (think vi)
607  \Q          quote (disable) pattern metacharacters till \E
608  \E          end either case modification or quoted section, think vi
609
610 Details are in L<perlop/Quote and Quote-like Operators>.
611
612 =head3 Character Classes and other Special Escapes
613
614 In addition, Perl defines the following:
615 X<\g> X<\k> X<\K> X<backreference>
616
617  Sequence   Note    Description
618   [...]     [1]  Match a character according to the rules of the
619                    bracketed character class defined by the "...".
620                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
621   [[:...:]] [2]  Match a character according to the rules of the POSIX
622                    character class "..." within the outer bracketed
623                    character class.  Example: [[:upper:]] matches any
624                    uppercase character.
625   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
626                    other connector punctuation chars plus Unicode
627                    marks)
628   \W        [3]  Match a non-"word" character
629   \s        [3]  Match a whitespace character
630   \S        [3]  Match a non-whitespace character
631   \d        [3]  Match a decimal digit character
632   \D        [3]  Match a non-digit character
633   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
634   \PP       [3]  Match non-P
635   \X        [4]  Match Unicode "eXtended grapheme cluster"
636   \C             Match a single C-language char (octet) even if that is
637                    part of a larger UTF-8 character.  Thus it breaks up
638                    characters into their UTF-8 bytes, so you may end up
639                    with malformed pieces of UTF-8.  Unsupported in
640                    lookbehind.
641   \1        [5]  Backreference to a specific capture group or buffer.
642                    '1' may actually be any positive integer.
643   \g1       [5]  Backreference to a specific or previous group,
644   \g{-1}    [5]  The number may be negative indicating a relative
645                    previous group and may optionally be wrapped in
646                    curly brackets for safer parsing.
647   \g{name}  [5]  Named backreference
648   \k<name>  [5]  Named backreference
649   \K        [6]  Keep the stuff left of the \K, don't include it in $&
650   \N        [7]  Any character but \n (experimental).  Not affected by
651                    /s modifier
652   \v        [3]  Vertical whitespace
653   \V        [3]  Not vertical whitespace
654   \h        [3]  Horizontal whitespace
655   \H        [3]  Not horizontal whitespace
656   \R        [4]  Linebreak
657
658 =over 4
659
660 =item [1]
661
662 See L<perlrecharclass/Bracketed Character Classes> for details.
663
664 =item [2]
665
666 See L<perlrecharclass/POSIX Character Classes> for details.
667
668 =item [3]
669
670 See L<perlrecharclass/Backslash sequences> for details.
671
672 =item [4]
673
674 See L<perlrebackslash/Misc> for details.
675
676 =item [5]
677
678 See L</Capture groups> below for details.
679
680 =item [6]
681
682 See L</Extended Patterns> below for details.
683
684 =item [7]
685
686 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
687 character or character sequence whose name is C<NAME>; and similarly
688 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
689 code point is I<hex>.  Otherwise it matches any character but C<\n>.
690
691 =back
692
693 =head3 Assertions
694
695 Perl defines the following zero-width assertions:
696 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
697 X<regexp, zero-width assertion>
698 X<regular expression, zero-width assertion>
699 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
700
701     \b  Match a word boundary
702     \B  Match except at a word boundary
703     \A  Match only at beginning of string
704     \Z  Match only at end of string, or before newline at the end
705     \z  Match only at end of string
706     \G  Match only at pos() (e.g. at the end-of-match position
707         of prior m//g)
708
709 A word boundary (C<\b>) is a spot between two characters
710 that has a C<\w> on one side of it and a C<\W> on the other side
711 of it (in either order), counting the imaginary characters off the
712 beginning and end of the string as matching a C<\W>.  (Within
713 character classes C<\b> represents backspace rather than a word
714 boundary, just as it normally does in any double-quoted string.)
715 The C<\A> and C<\Z> are just like "^" and "$", except that they
716 won't match multiple times when the C</m> modifier is used, while
717 "^" and "$" will match at every internal line boundary.  To match
718 the actual end of the string and not ignore an optional trailing
719 newline, use C<\z>.
720 X<\b> X<\A> X<\Z> X<\z> X</m>
721
722 The C<\G> assertion can be used to chain global matches (using
723 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
724 It is also useful when writing C<lex>-like scanners, when you have
725 several patterns that you want to match against consequent substrings
726 of your string; see the previous reference.  The actual location
727 where C<\G> will match can also be influenced by using C<pos()> as
728 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
729 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
730 is modified somewhat, in that contents to the left of C<\G> are
731 not counted when determining the length of the match. Thus the following
732 will not match forever:
733 X<\G>
734
735      my $string = 'ABC';
736      pos($string) = 1;
737      while ($string =~ /(.\G)/g) {
738          print $1;
739      }
740
741 It will print 'A' and then terminate, as it considers the match to
742 be zero-width, and thus will not match at the same position twice in a
743 row.
744
745 It is worth noting that C<\G> improperly used can result in an infinite
746 loop. Take care when using patterns that include C<\G> in an alternation.
747
748 =head3 Capture groups
749
750 The bracketing construct C<( ... )> creates capture groups (also referred to as
751 capture buffers). To refer to the current contents of a group later on, within
752 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
753 for the second, and so on.
754 This is called a I<backreference>.
755 X<regex, capture buffer> X<regexp, capture buffer>
756 X<regex, capture group> X<regexp, capture group>
757 X<regular expression, capture buffer> X<backreference>
758 X<regular expression, capture group> X<backreference>
759 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
760 X<named capture buffer> X<regular expression, named capture buffer>
761 X<named capture group> X<regular expression, named capture group>
762 X<%+> X<$+{name}> X<< \k<name> >>
763 There is no limit to the number of captured substrings that you may use.
764 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
765 a group did not match, the associated backreference won't match either. (This
766 can happen if the group is optional, or in a different branch of an
767 alternation.)
768 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
769 this form, described below.
770
771 You can also refer to capture groups relatively, by using a negative number, so
772 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
773 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
774 example:
775
776         /
777          (Y)            # group 1
778          (              # group 2
779             (X)         # group 3
780             \g{-1}      # backref to group 3
781             \g{-3}      # backref to group 1
782          )
783         /x
784
785 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
786 interpolate regexes into larger regexes and not have to worry about the
787 capture groups being renumbered.
788
789 You can dispense with numbers altogether and create named capture groups.
790 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
791 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
792 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
793 I<name> must not begin with a number, nor contain hyphens.
794 When different groups within the same pattern have the same name, any reference
795 to that name assumes the leftmost defined group.  Named groups count in
796 absolute and relative numbering, and so can also be referred to by those
797 numbers.
798 (It's possible to do things with named capture groups that would otherwise
799 require C<(??{})>.)
800
801 Capture group contents are dynamically scoped and available to you outside the
802 pattern until the end of the enclosing block or until the next successful
803 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
804 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
805 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
806
807 Braces are required in referring to named capture groups, but are optional for
808 absolute or relative numbered ones.  Braces are safer when creating a regex by
809 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
810 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
811 is probably not what you intended.
812
813 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
814 there were no named nor relative numbered capture groups.  Absolute numbered
815 groups were referred to using C<\1>,
816 C<\2>, etc., and this notation is still
817 accepted (and likely always will be).  But it leads to some ambiguities if
818 there are more than 9 capture groups, as C<\10> could mean either the tenth
819 capture group, or the character whose ordinal in octal is 010 (a backspace in
820 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
821 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
822 a backreference only if at least 11 left parentheses have opened before it.
823 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
824 There are several examples below that illustrate these perils.  You can avoid
825 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
826 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
827 digits padded with leading zeros, since a leading zero implies an octal
828 constant.
829
830 The C<\I<digit>> notation also works in certain circumstances outside
831 the pattern.  See L</Warning on \1 Instead of $1> below for details.
832
833 Examples:
834
835     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
836
837     /(.)\g1/                        # find first doubled char
838          and print "'$1' is the first doubled character\n";
839
840     /(?<char>.)\k<char>/            # ... a different way
841          and print "'$+{char}' is the first doubled character\n";
842
843     /(?'char'.)\g1/                 # ... mix and match
844          and print "'$1' is the first doubled character\n";
845
846     if (/Time: (..):(..):(..)/) {   # parse out values
847         $hours = $1;
848         $minutes = $2;
849         $seconds = $3;
850     }
851
852     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
853     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
854     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
855     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
856
857     $a = '(.)\1';        # Creates problems when concatenated.
858     $b = '(.)\g{1}';     # Avoids the problems.
859     "aa" =~ /${a}/;      # True
860     "aa" =~ /${b}/;      # True
861     "aa0" =~ /${a}0/;    # False!
862     "aa0" =~ /${b}0/;    # True
863     "aa\x08" =~ /${a}0/;  # True!
864     "aa\x08" =~ /${b}0/;  # False
865
866 Several special variables also refer back to portions of the previous
867 match.  C<$+> returns whatever the last bracket match matched.
868 C<$&> returns the entire matched string.  (At one point C<$0> did
869 also, but now it returns the name of the program.)  C<$`> returns
870 everything before the matched string.  C<$'> returns everything
871 after the matched string. And C<$^N> contains whatever was matched by
872 the most-recently closed group (submatch). C<$^N> can be used in
873 extended patterns (see below), for example to assign a submatch to a
874 variable.
875 X<$+> X<$^N> X<$&> X<$`> X<$'>
876
877 These special variables, like the C<%+> hash and the numbered match variables
878 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
879 until the end of the enclosing block or until the next successful
880 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
881 X<$+> X<$^N> X<$&> X<$`> X<$'>
882 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
883
884 B<NOTE>: Failed matches in Perl do not reset the match variables,
885 which makes it easier to write code that tests for a series of more
886 specific cases and remembers the best match.
887
888 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
889 C<$'> anywhere in the program, it has to provide them for every
890 pattern match.  This may substantially slow your program.  Perl
891 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
892 price for each pattern that contains capturing parentheses.  (To
893 avoid this cost while retaining the grouping behaviour, use the
894 extended regular expression C<(?: ... )> instead.)  But if you never
895 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
896 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
897 if you can, but if you can't (and some algorithms really appreciate
898 them), once you've used them once, use them at will, because you've
899 already paid the price.  As of 5.17.4, the presence of each of the three
900 variables in a program is recorded separately, and depending on
901 circumstances, perl may be able be more efficient knowing that only C<$&>
902 rather than all three have been seen, for example.
903 X<$&> X<$`> X<$'>
904
905 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
906 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
907 and C<$'>, B<except> that they are only guaranteed to be defined after a
908 successful match that was executed with the C</p> (preserve) modifier.
909 The use of these variables incurs no global performance penalty, unlike
910 their punctuation char equivalents, however at the trade-off that you
911 have to tell perl when you want to use them.
912 X</p> X<p modifier>
913
914 =head2 Quoting metacharacters
915
916 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
917 C<\w>, C<\n>.  Unlike some other regular expression languages, there
918 are no backslashed symbols that aren't alphanumeric.  So anything
919 that looks like \\, \(, \), \<, \>, \{, or \} is always
920 interpreted as a literal character, not a metacharacter.  This was
921 once used in a common idiom to disable or quote the special meanings
922 of regular expression metacharacters in a string that you want to
923 use for a pattern. Simply quote all non-"word" characters:
924
925     $pattern =~ s/(\W)/\\$1/g;
926
927 (If C<use locale> is set, then this depends on the current locale.)
928 Today it is more common to use the quotemeta() function or the C<\Q>
929 metaquoting escape sequence to disable all metacharacters' special
930 meanings like this:
931
932     /$unquoted\Q$quoted\E$unquoted/
933
934 Beware that if you put literal backslashes (those not inside
935 interpolated variables) between C<\Q> and C<\E>, double-quotish
936 backslash interpolation may lead to confusing results.  If you
937 I<need> to use literal backslashes within C<\Q...\E>,
938 consult L<perlop/"Gory details of parsing quoted constructs">.
939
940 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
941
942 =head2 Extended Patterns
943
944 Perl also defines a consistent extension syntax for features not
945 found in standard tools like B<awk> and
946 B<lex>.  The syntax for most of these is a
947 pair of parentheses with a question mark as the first thing within
948 the parentheses.  The character after the question mark indicates
949 the extension.
950
951 The stability of these extensions varies widely.  Some have been
952 part of the core language for many years.  Others are experimental
953 and may change without warning or be completely removed.  Check
954 the documentation on an individual feature to verify its current
955 status.
956
957 A question mark was chosen for this and for the minimal-matching
958 construct because 1) question marks are rare in older regular
959 expressions, and 2) whenever you see one, you should stop and
960 "question" exactly what is going on.  That's psychology....
961
962 =over 4
963
964 =item C<(?#text)>
965 X<(?#)>
966
967 A comment.  The text is ignored.  If the C</x> modifier enables
968 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
969 the comment as soon as it sees a C<)>, so there is no way to put a literal
970 C<)> in the comment.
971
972 =item C<(?adlupimsx-imsx)>
973
974 =item C<(?^alupimsx)>
975 X<(?)> X<(?^)>
976
977 One or more embedded pattern-match modifiers, to be turned on (or
978 turned off, if preceded by C<->) for the remainder of the pattern or
979 the remainder of the enclosing pattern group (if any).
980
981 This is particularly useful for dynamic patterns, such as those read in from a
982 configuration file, taken from an argument, or specified in a table
983 somewhere.  Consider the case where some patterns want to be
984 case-sensitive and some do not:  The case-insensitive ones merely need to
985 include C<(?i)> at the front of the pattern.  For example:
986
987     $pattern = "foobar";
988     if ( /$pattern/i ) { }
989
990     # more flexible:
991
992     $pattern = "(?i)foobar";
993     if ( /$pattern/ ) { }
994
995 These modifiers are restored at the end of the enclosing group. For example,
996
997     ( (?i) blah ) \s+ \g1
998
999 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1000 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1001 modifier outside this group.
1002
1003 These modifiers do not carry over into named subpatterns called in the
1004 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1005 change the case-sensitivity of the "NAME" pattern.
1006
1007 Any of these modifiers can be set to apply globally to all regular
1008 expressions compiled within the scope of a C<use re>.  See
1009 L<re/"'/flags' mode">.
1010
1011 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1012 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1013 C<"d">) may follow the caret to override it.
1014 But a minus sign is not legal with it.
1015
1016 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1017 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1018 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1019 others, and a maximum of one (or two C<a>'s) may appear in the
1020 construct.  Thus, for
1021 example, C<(?-p)> will warn when compiled under C<use warnings>;
1022 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1023
1024 Note also that the C<p> modifier is special in that its presence
1025 anywhere in a pattern has a global effect.
1026
1027 =item C<(?:pattern)>
1028 X<(?:)>
1029
1030 =item C<(?adluimsx-imsx:pattern)>
1031
1032 =item C<(?^aluimsx:pattern)>
1033 X<(?^:)>
1034
1035 This is for clustering, not capturing; it groups subexpressions like
1036 "()", but doesn't make backreferences as "()" does.  So
1037
1038     @fields = split(/\b(?:a|b|c)\b/)
1039
1040 is like
1041
1042     @fields = split(/\b(a|b|c)\b/)
1043
1044 but doesn't spit out extra fields.  It's also cheaper not to capture
1045 characters if you don't need to.
1046
1047 Any letters between C<?> and C<:> act as flags modifiers as with
1048 C<(?adluimsx-imsx)>.  For example,
1049
1050     /(?s-i:more.*than).*million/i
1051
1052 is equivalent to the more verbose
1053
1054     /(?:(?s-i)more.*than).*million/i
1055
1056 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1057 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1058 flags (except C<"d">) may follow the caret, so
1059
1060     (?^x:foo)
1061
1062 is equivalent to
1063
1064     (?x-ims:foo)
1065
1066 The caret tells Perl that this cluster doesn't inherit the flags of any
1067 surrounding pattern, but uses the system defaults (C<d-imsx>),
1068 modified by any flags specified.
1069
1070 The caret allows for simpler stringification of compiled regular
1071 expressions.  These look like
1072
1073     (?^:pattern)
1074
1075 with any non-default flags appearing between the caret and the colon.
1076 A test that looks at such stringification thus doesn't need to have the
1077 system default flags hard-coded in it, just the caret.  If new flags are
1078 added to Perl, the meaning of the caret's expansion will change to include
1079 the default for those flags, so the test will still work, unchanged.
1080
1081 Specifying a negative flag after the caret is an error, as the flag is
1082 redundant.
1083
1084 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1085 to match at the beginning.
1086
1087 =item C<(?|pattern)>
1088 X<(?|)> X<Branch reset>
1089
1090 This is the "branch reset" pattern, which has the special property
1091 that the capture groups are numbered from the same starting point
1092 in each alternation branch. It is available starting from perl 5.10.0.
1093
1094 Capture groups are numbered from left to right, but inside this
1095 construct the numbering is restarted for each branch.
1096
1097 The numbering within each branch will be as normal, and any groups
1098 following this construct will be numbered as though the construct
1099 contained only one branch, that being the one with the most capture
1100 groups in it.
1101
1102 This construct is useful when you want to capture one of a
1103 number of alternative matches.
1104
1105 Consider the following pattern.  The numbers underneath show in
1106 which group the captured content will be stored.
1107
1108
1109     # before  ---------------branch-reset----------- after        
1110     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1111     # 1            2         2  3        2     3     4  
1112
1113 Be careful when using the branch reset pattern in combination with 
1114 named captures. Named captures are implemented as being aliases to 
1115 numbered groups holding the captures, and that interferes with the
1116 implementation of the branch reset pattern. If you are using named
1117 captures in a branch reset pattern, it's best to use the same names,
1118 in the same order, in each of the alternations:
1119
1120    /(?|  (?<a> x ) (?<b> y )
1121       |  (?<a> z ) (?<b> w )) /x
1122
1123 Not doing so may lead to surprises:
1124
1125   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1126   say $+ {a};   # Prints '12'
1127   say $+ {b};   # *Also* prints '12'.
1128
1129 The problem here is that both the group named C<< a >> and the group
1130 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1131
1132 =item Look-Around Assertions
1133 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1134
1135 Look-around assertions are zero-width patterns which match a specific
1136 pattern without including it in C<$&>. Positive assertions match when
1137 their subpattern matches, negative assertions match when their subpattern
1138 fails. Look-behind matches text up to the current match position,
1139 look-ahead matches text following the current match position.
1140
1141 =over 4
1142
1143 =item C<(?=pattern)>
1144 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1145
1146 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1147 matches a word followed by a tab, without including the tab in C<$&>.
1148
1149 =item C<(?!pattern)>
1150 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1151
1152 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1153 matches any occurrence of "foo" that isn't followed by "bar".  Note
1154 however that look-ahead and look-behind are NOT the same thing.  You cannot
1155 use this for look-behind.
1156
1157 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1158 will not do what you want.  That's because the C<(?!foo)> is just saying that
1159 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1160 match.  Use look-behind instead (see below).
1161
1162 =item C<(?<=pattern)> C<\K>
1163 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1164
1165 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1166 matches a word that follows a tab, without including the tab in C<$&>.
1167 Works only for fixed-width look-behind.
1168
1169 There is a special form of this construct, called C<\K>, which causes the
1170 regex engine to "keep" everything it had matched prior to the C<\K> and
1171 not include it in C<$&>. This effectively provides variable-length
1172 look-behind. The use of C<\K> inside of another look-around assertion
1173 is allowed, but the behaviour is currently not well defined.
1174
1175 For various reasons C<\K> may be significantly more efficient than the
1176 equivalent C<< (?<=...) >> construct, and it is especially useful in
1177 situations where you want to efficiently remove something following
1178 something else in a string. For instance
1179
1180   s/(foo)bar/$1/g;
1181
1182 can be rewritten as the much more efficient
1183
1184   s/foo\Kbar//g;
1185
1186 =item C<(?<!pattern)>
1187 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1188
1189 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1190 matches any occurrence of "foo" that does not follow "bar".  Works
1191 only for fixed-width look-behind.
1192
1193 =back
1194
1195 =item C<(?'NAME'pattern)>
1196
1197 =item C<< (?<NAME>pattern) >>
1198 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1199
1200 A named capture group. Identical in every respect to normal capturing
1201 parentheses C<()> but for the additional fact that the group
1202 can be referred to by name in various regular expression
1203 constructs (like C<\g{NAME}>) and can be accessed by name
1204 after a successful match via C<%+> or C<%->. See L<perlvar>
1205 for more details on the C<%+> and C<%-> hashes.
1206
1207 If multiple distinct capture groups have the same name then the
1208 $+{NAME} will refer to the leftmost defined group in the match.
1209
1210 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1211
1212 B<NOTE:> While the notation of this construct is the same as the similar
1213 function in .NET regexes, the behavior is not. In Perl the groups are
1214 numbered sequentially regardless of being named or not. Thus in the
1215 pattern
1216
1217   /(x)(?<foo>y)(z)/
1218
1219 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1220 the opposite which is what a .NET regex hacker might expect.
1221
1222 Currently NAME is restricted to simple identifiers only.
1223 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1224 its Unicode extension (see L<utf8>),
1225 though it isn't extended by the locale (see L<perllocale>).
1226
1227 B<NOTE:> In order to make things easier for programmers with experience
1228 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1229 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1230 support the use of single quotes as a delimiter for the name.
1231
1232 =item C<< \k<NAME> >>
1233
1234 =item C<< \k'NAME' >>
1235
1236 Named backreference. Similar to numeric backreferences, except that
1237 the group is designated by name and not number. If multiple groups
1238 have the same name then it refers to the leftmost defined group in
1239 the current match.
1240
1241 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1242 earlier in the pattern.
1243
1244 Both forms are equivalent.
1245
1246 B<NOTE:> In order to make things easier for programmers with experience
1247 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1248 may be used instead of C<< \k<NAME> >>.
1249
1250 =item C<(?{ code })>
1251 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1252
1253 B<WARNING>: This extended regular expression feature is considered
1254 experimental, and may be changed without notice. Code executed that
1255 has side effects may not perform identically from version to version
1256 due to the effect of future optimisations in the regex engine. The
1257 implementation of this feature was radically overhauled for the 5.18.0
1258 release, and its behaviour in earlier versions of perl was much buggier,
1259 especially in relation to parsing, lexical vars, scoping, recursion and
1260 reentrancy.
1261
1262 This zero-width assertion executes any embedded Perl code.  It always
1263 succeeds, and its return value is set as C<$^R>.
1264
1265 In literal patterns, the code is parsed at the same time as the
1266 surrounding code. While within the pattern, control is passed temporarily
1267 back to the perl parser, until the logically-balancing closing brace is
1268 encountered. This is similar to the way that an array index expression in
1269 a literal string is handled, for example
1270
1271     "abc$array[ 1 + f('[') + g()]def"
1272
1273 In particular, braces do not need to be balanced:
1274
1275     /abc(?{ f('{'); })/def/
1276
1277 Even in a pattern that is interpolated and compiled at run-time, literal
1278 code blocks will be compiled once, at perl compile time; the following
1279 prints "ABCD":
1280
1281     print "D";
1282     my $qr = qr/(?{ BEGIN { print "A" } })/;
1283     my $foo = "foo";
1284     /$foo$qr(?{ BEGIN { print "B" } })/;
1285     BEGIN { print "C" }
1286
1287 In patterns where the text of the code is derived from run-time
1288 information rather than appearing literally in a source code /pattern/,
1289 the code is compiled at the same time that the pattern is compiled, and
1290 fro reasons of security, C<use re 'eval'> must be in scope. This is to
1291 stop user-supplied patterns containing code snippets from being
1292 executable.
1293
1294 In situations where you need enable this with C<use re 'eval'>, you should
1295 also have taint checking enabled.  Better yet, use the carefully
1296 constrained evaluation within a Safe compartment.  See L<perlsec> for
1297 details about both these mechanisms.
1298
1299 From the viewpoint of parsing, lexical variable scope and closures,
1300
1301     /AAA(?{ BBB })CCC/
1302
1303 behaves approximately like
1304
1305     /AAA/ && do { BBB } && /CCC/
1306
1307 Similarly,
1308
1309     qr/AAA(?{ BBB })CCC/
1310
1311 behaves approximately like
1312
1313     sub { /AAA/ && do { BBB } && /CCC/ }
1314
1315 In particular:
1316
1317     { my $i = 1; $r = qr/(?{ print $i })/ }
1318     my $i = 2;
1319     /$r/; # prints "1"
1320
1321 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1322 expression is matching against. You can also use C<pos()> to know what is
1323 the current position of matching within this string.
1324
1325 The code block introduces a new scope from the perspective of lexical
1326 variable declarations, but B<not> from the perspective of C<local> and
1327 similar localizing behaviours. So later code blocks within the same
1328 pattern will still see the values which were localized in earlier blocks.
1329 These accumulated localizations are undone either at the end of a
1330 successful match, or if the assertion is backtracked (compare
1331 L<"Backtracking">). For example,
1332
1333   $_ = 'a' x 8;
1334   m<
1335      (?{ $cnt = 0 })               # Initialize $cnt.
1336      (
1337        a
1338        (?{
1339            local $cnt = $cnt + 1;  # Update $cnt,
1340                                    # backtracking-safe.
1341        })
1342      )*
1343      aaaa
1344      (?{ $res = $cnt })            # On success copy to
1345                                    # non-localized location.
1346    >x;
1347
1348 will initially increment C<$cnt> up to 8; then during backtracking, its
1349 value will be unwound back to 4, which is the value assigned to C<$res>.
1350 At the end of the regex execution, $cnt will be wound back to its initial
1351 value of 0.
1352
1353 This assertion may be used as the condition in a
1354
1355     (?(condition)yes-pattern|no-pattern)
1356
1357 switch.  If I<not> used in this way, the result of evaluation of C<code>
1358 is put into the special variable C<$^R>.  This happens immediately, so
1359 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1360 regular expression.
1361
1362 The assignment to C<$^R> above is properly localized, so the old
1363 value of C<$^R> is restored if the assertion is backtracked; compare
1364 L<"Backtracking">.
1365
1366 Note that the special variable C<$^N>  is particularly useful with code
1367 blocks to capture the results of submatches in variables without having to
1368 keep track of the number of nested parentheses. For example:
1369
1370   $_ = "The brown fox jumps over the lazy dog";
1371   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1372   print "color = $color, animal = $animal\n";
1373
1374
1375 =item C<(??{ code })>
1376 X<(??{})>
1377 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1378
1379 B<WARNING>: This extended regular expression feature is considered
1380 experimental, and may be changed without notice. Code executed that
1381 has side effects may not perform identically from version to version
1382 due to the effect of future optimisations in the regex engine.
1383
1384 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1385 same way as a C<(?{ code })> code block as described above, except that
1386 its return value, rather than being assigned to C<$^R>, is treated as a
1387 pattern, compiled if it's a string (or used as-is if its a qr// object),
1388 then matched as if it were inserted instead of this construct.
1389
1390 During the matching of this sub-pattern, it has its own set of
1391 captures which are valid during the sub-match, but are discarded once
1392 control returns to the main pattern. For example, the following matches,
1393 with the inner pattern capturing "B" and matching "BB", while the outer
1394 pattern captures "A";
1395
1396     my $inner = '(.)\1';
1397     "ABBA" =~ /^(.)(??{ $inner })\1/;
1398     print $1; # prints "A";
1399
1400 Note that this means that  there is no way for the inner pattern to refer
1401 to a capture group defined outside.  (The code block itself can use C<$1>,
1402 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1403
1404     ('a' x 100)=~/(??{'(.)' x 100})/
1405
1406 I<will> match, it will I<not> set $1 on exit.
1407
1408 The following pattern matches a parenthesized group:
1409
1410  $re = qr{
1411             \(
1412             (?:
1413                (?> [^()]+ )  # Non-parens without backtracking
1414              |
1415                (??{ $re })   # Group with matching parens
1416             )*
1417             \)
1418          }x;
1419
1420 See also C<(?PARNO)> for a different, more efficient way to accomplish
1421 the same task.
1422
1423 Executing a postponed regular expression 50 times without consuming any
1424 input string will result in a fatal error.  The maximum depth is compiled
1425 into perl, so changing it requires a custom build.
1426
1427 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1428 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1429 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1430 X<regex, relative recursion>
1431
1432 Similar to C<(??{ code })> except that it does not involve executing any
1433 code or potentially compiling a returned pattern string; instead it treats
1434 the part of the current pattern contained within a specified capture group
1435 as an independent pattern that must match at the current position.
1436 Capture groups contained by the pattern will have the value as determined
1437 by the outermost recursion.
1438
1439 PARNO is a sequence of digits (not starting with 0) whose value reflects
1440 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1441 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1442 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1443 to be relative, with negative numbers indicating preceding capture groups
1444 and positive ones following. Thus C<(?-1)> refers to the most recently
1445 declared group, and C<(?+1)> indicates the next group to be declared.
1446 Note that the counting for relative recursion differs from that of
1447 relative backreferences, in that with recursion unclosed groups B<are>
1448 included.
1449
1450 The following pattern matches a function foo() which may contain
1451 balanced parentheses as the argument.
1452
1453   $re = qr{ (                   # paren group 1 (full function)
1454               foo
1455               (                 # paren group 2 (parens)
1456                 \(
1457                   (             # paren group 3 (contents of parens)
1458                   (?:
1459                    (?> [^()]+ ) # Non-parens without backtracking
1460                   |
1461                    (?2)         # Recurse to start of paren group 2
1462                   )*
1463                   )
1464                 \)
1465               )
1466             )
1467           }x;
1468
1469 If the pattern was used as follows
1470
1471     'foo(bar(baz)+baz(bop))'=~/$re/
1472         and print "\$1 = $1\n",
1473                   "\$2 = $2\n",
1474                   "\$3 = $3\n";
1475
1476 the output produced should be the following:
1477
1478     $1 = foo(bar(baz)+baz(bop))
1479     $2 = (bar(baz)+baz(bop))
1480     $3 = bar(baz)+baz(bop)
1481
1482 If there is no corresponding capture group defined, then it is a
1483 fatal error.  Recursing deeper than 50 times without consuming any input
1484 string will also result in a fatal error.  The maximum depth is compiled
1485 into perl, so changing it requires a custom build.
1486
1487 The following shows how using negative indexing can make it
1488 easier to embed recursive patterns inside of a C<qr//> construct
1489 for later use:
1490
1491     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1492     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1493        # do something here...
1494     }
1495
1496 B<Note> that this pattern does not behave the same way as the equivalent
1497 PCRE or Python construct of the same form. In Perl you can backtrack into
1498 a recursed group, in PCRE and Python the recursed into group is treated
1499 as atomic. Also, modifiers are resolved at compile time, so constructs
1500 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1501 be processed.
1502
1503 =item C<(?&NAME)>
1504 X<(?&NAME)>
1505
1506 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1507 parenthesis to recurse to is determined by name. If multiple parentheses have
1508 the same name, then it recurses to the leftmost.
1509
1510 It is an error to refer to a name that is not declared somewhere in the
1511 pattern.
1512
1513 B<NOTE:> In order to make things easier for programmers with experience
1514 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1515 may be used instead of C<< (?&NAME) >>.
1516
1517 =item C<(?(condition)yes-pattern|no-pattern)>
1518 X<(?()>
1519
1520 =item C<(?(condition)yes-pattern)>
1521
1522 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1523 a true value, matches C<no-pattern> otherwise. A missing pattern always
1524 matches.
1525
1526 C<(condition)> should be one of: 1) an integer in
1527 parentheses (which is valid if the corresponding pair of parentheses
1528 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1529 name in angle brackets or single quotes (which is valid if a group
1530 with the given name matched); or 4) the special symbol (R) (true when
1531 evaluated inside of recursion or eval). Additionally the R may be
1532 followed by a number, (which will be true when evaluated when recursing
1533 inside of the appropriate group), or by C<&NAME>, in which case it will
1534 be true only when evaluated during recursion in the named group.
1535
1536 Here's a summary of the possible predicates:
1537
1538 =over 4
1539
1540 =item (1) (2) ...
1541
1542 Checks if the numbered capturing group has matched something.
1543
1544 =item (<NAME>) ('NAME')
1545
1546 Checks if a group with the given name has matched something.
1547
1548 =item (?=...) (?!...) (?<=...) (?<!...)
1549
1550 Checks whether the pattern matches (or does not match, for the '!'
1551 variants).
1552
1553 =item (?{ CODE })
1554
1555 Treats the return value of the code block as the condition.
1556
1557 =item (R)
1558
1559 Checks if the expression has been evaluated inside of recursion.
1560
1561 =item (R1) (R2) ...
1562
1563 Checks if the expression has been evaluated while executing directly
1564 inside of the n-th capture group. This check is the regex equivalent of
1565
1566   if ((caller(0))[3] eq 'subname') { ... }
1567
1568 In other words, it does not check the full recursion stack.
1569
1570 =item (R&NAME)
1571
1572 Similar to C<(R1)>, this predicate checks to see if we're executing
1573 directly inside of the leftmost group with a given name (this is the same
1574 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1575 stack, but only the name of the innermost active recursion.
1576
1577 =item (DEFINE)
1578
1579 In this case, the yes-pattern is never directly executed, and no
1580 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1581 See below for details.
1582
1583 =back
1584
1585 For example:
1586
1587     m{ ( \( )?
1588        [^()]+
1589        (?(1) \) )
1590      }x
1591
1592 matches a chunk of non-parentheses, possibly included in parentheses
1593 themselves.
1594
1595 A special form is the C<(DEFINE)> predicate, which never executes its
1596 yes-pattern directly, and does not allow a no-pattern. This allows one to
1597 define subpatterns which will be executed only by the recursion mechanism.
1598 This way, you can define a set of regular expression rules that can be
1599 bundled into any pattern you choose.
1600
1601 It is recommended that for this usage you put the DEFINE block at the
1602 end of the pattern, and that you name any subpatterns defined within it.
1603
1604 Also, it's worth noting that patterns defined this way probably will
1605 not be as efficient, as the optimiser is not very clever about
1606 handling them.
1607
1608 An example of how this might be used is as follows:
1609
1610   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1611    (?(DEFINE)
1612      (?<NAME_PAT>....)
1613      (?<ADRESS_PAT>....)
1614    )/x
1615
1616 Note that capture groups matched inside of recursion are not accessible
1617 after the recursion returns, so the extra layer of capturing groups is
1618 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1619 C<$+{NAME}> would be.
1620
1621 Finally, keep in mind that subpatterns created inside a DEFINE block
1622 count towards the absolute and relative number of captures, so this:
1623
1624     my @captures = "a" =~ /(.)                  # First capture
1625                            (?(DEFINE)
1626                                (?<EXAMPLE> 1 )  # Second capture
1627                            )/x;
1628     say scalar @captures;
1629
1630 Will output 2, not 1. This is particularly important if you intend to
1631 compile the definitions with the C<qr//> operator, and later
1632 interpolate them in another pattern.
1633
1634 =item C<< (?>pattern) >>
1635 X<backtrack> X<backtracking> X<atomic> X<possessive>
1636
1637 An "independent" subexpression, one which matches the substring
1638 that a I<standalone> C<pattern> would match if anchored at the given
1639 position, and it matches I<nothing other than this substring>.  This
1640 construct is useful for optimizations of what would otherwise be
1641 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1642 It may also be useful in places where the "grab all you can, and do not
1643 give anything back" semantic is desirable.
1644
1645 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1646 (anchored at the beginning of string, as above) will match I<all>
1647 characters C<a> at the beginning of string, leaving no C<a> for
1648 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1649 since the match of the subgroup C<a*> is influenced by the following
1650 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1651 C<a*ab> will match fewer characters than a standalone C<a*>, since
1652 this makes the tail match.
1653
1654 C<< (?>pattern) >> does not disable backtracking altogether once it has
1655 matched. It is still possible to backtrack past the construct, but not
1656 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1657
1658 An effect similar to C<< (?>pattern) >> may be achieved by writing
1659 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1660 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1661 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1662 (The difference between these two constructs is that the second one
1663 uses a capturing group, thus shifting ordinals of backreferences
1664 in the rest of a regular expression.)
1665
1666 Consider this pattern:
1667
1668     m{ \(
1669           (
1670             [^()]+           # x+
1671           |
1672             \( [^()]* \)
1673           )+
1674        \)
1675      }x
1676
1677 That will efficiently match a nonempty group with matching parentheses
1678 two levels deep or less.  However, if there is no such group, it
1679 will take virtually forever on a long string.  That's because there
1680 are so many different ways to split a long string into several
1681 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1682 to a subpattern of the above pattern.  Consider how the pattern
1683 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1684 seconds, but that each extra letter doubles this time.  This
1685 exponential performance will make it appear that your program has
1686 hung.  However, a tiny change to this pattern
1687
1688     m{ \(
1689           (
1690             (?> [^()]+ )        # change x+ above to (?> x+ )
1691           |
1692             \( [^()]* \)
1693           )+
1694        \)
1695      }x
1696
1697 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1698 this yourself would be a productive exercise), but finishes in a fourth
1699 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1700 however, that, when this construct is followed by a
1701 quantifier, it currently triggers a warning message under
1702 the C<use warnings> pragma or B<-w> switch saying it
1703 C<"matches null string many times in regex">.
1704
1705 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1706 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1707 This was only 4 times slower on a string with 1000000 C<a>s.
1708
1709 The "grab all you can, and do not give anything back" semantic is desirable
1710 in many situations where on the first sight a simple C<()*> looks like
1711 the correct solution.  Suppose we parse text with comments being delimited
1712 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1713 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1714 the comment delimiter, because it may "give up" some whitespace if
1715 the remainder of the pattern can be made to match that way.  The correct
1716 answer is either one of these:
1717
1718     (?>#[ \t]*)
1719     #[ \t]*(?![ \t])
1720
1721 For example, to grab non-empty comments into $1, one should use either
1722 one of these:
1723
1724     / (?> \# [ \t]* ) (        .+ ) /x;
1725     /     \# [ \t]*   ( [^ \t] .* ) /x;
1726
1727 Which one you pick depends on which of these expressions better reflects
1728 the above specification of comments.
1729
1730 In some literature this construct is called "atomic matching" or
1731 "possessive matching".
1732
1733 Possessive quantifiers are equivalent to putting the item they are applied
1734 to inside of one of these constructs. The following equivalences apply:
1735
1736     Quantifier Form     Bracketing Form
1737     ---------------     ---------------
1738     PAT*+               (?>PAT*)
1739     PAT++               (?>PAT+)
1740     PAT?+               (?>PAT?)
1741     PAT{min,max}+       (?>PAT{min,max})
1742
1743 =back
1744
1745 =head2 Special Backtracking Control Verbs
1746
1747 B<WARNING:> These patterns are experimental and subject to change or
1748 removal in a future version of Perl. Their usage in production code should
1749 be noted to avoid problems during upgrades.
1750
1751 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1752 otherwise stated the ARG argument is optional; in some cases, it is
1753 forbidden.
1754
1755 Any pattern containing a special backtracking verb that allows an argument
1756 has the special behaviour that when executed it sets the current package's
1757 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1758 rules apply:
1759
1760 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1761 verb pattern, if the verb was involved in the failure of the match. If the
1762 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1763 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1764 none. Also, the C<$REGMARK> variable will be set to FALSE.
1765
1766 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1767 the C<$REGMARK> variable will be set to the name of the last
1768 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1769 C<(*MARK:NAME)> verb below for more details.
1770
1771 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1772 and most other regex-related variables. They are not local to a scope, nor
1773 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1774 Use C<local> to localize changes to them to a specific scope if necessary.
1775
1776 If a pattern does not contain a special backtracking verb that allows an
1777 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1778
1779 =over 3
1780
1781 =item Verbs that take an argument
1782
1783 =over 4
1784
1785 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1786 X<(*PRUNE)> X<(*PRUNE:NAME)>
1787
1788 This zero-width pattern prunes the backtracking tree at the current point
1789 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1790 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1791 A may backtrack as necessary to match. Once it is reached, matching
1792 continues in B, which may also backtrack as necessary; however, should B
1793 not match, then no further backtracking will take place, and the pattern
1794 will fail outright at the current starting position.
1795
1796 The following example counts all the possible matching strings in a
1797 pattern (without actually matching any of them).
1798
1799     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1800     print "Count=$count\n";
1801
1802 which produces:
1803
1804     aaab
1805     aaa
1806     aa
1807     a
1808     aab
1809     aa
1810     a
1811     ab
1812     a
1813     Count=9
1814
1815 If we add a C<(*PRUNE)> before the count like the following
1816
1817     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1818     print "Count=$count\n";
1819
1820 we prevent backtracking and find the count of the longest matching string
1821 at each matching starting point like so:
1822
1823     aaab
1824     aab
1825     ab
1826     Count=3
1827
1828 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1829
1830 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1831 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1832 replaced with a C<< (?>pattern) >> with no functional difference; however,
1833 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1834 C<< (?>pattern) >> alone.
1835
1836 =item C<(*SKIP)> C<(*SKIP:NAME)>
1837 X<(*SKIP)>
1838
1839 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1840 failure it also signifies that whatever text that was matched leading up
1841 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1842 of this pattern. This effectively means that the regex engine "skips" forward
1843 to this position on failure and tries to match again, (assuming that
1844 there is sufficient room to match).
1845
1846 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1847 C<(*MARK:NAME)> was encountered while matching, then it is that position
1848 which is used as the "skip point". If no C<(*MARK)> of that name was
1849 encountered, then the C<(*SKIP)> operator has no effect. When used
1850 without a name the "skip point" is where the match point was when
1851 executing the (*SKIP) pattern.
1852
1853 Compare the following to the examples in C<(*PRUNE)>; note the string
1854 is twice as long:
1855
1856  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1857  print "Count=$count\n";
1858
1859 outputs
1860
1861     aaab
1862     aaab
1863     Count=2
1864
1865 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1866 executed, the next starting point will be where the cursor was when the
1867 C<(*SKIP)> was executed.
1868
1869 =item C<(*MARK:NAME)> C<(*:NAME)>
1870 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1871
1872 This zero-width pattern can be used to mark the point reached in a string
1873 when a certain part of the pattern has been successfully matched. This
1874 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1875 forward to that point if backtracked into on failure. Any number of
1876 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1877
1878 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1879 can be used to "label" a pattern branch, so that after matching, the
1880 program can determine which branches of the pattern were involved in the
1881 match.
1882
1883 When a match is successful, the C<$REGMARK> variable will be set to the
1884 name of the most recently executed C<(*MARK:NAME)> that was involved
1885 in the match.
1886
1887 This can be used to determine which branch of a pattern was matched
1888 without using a separate capture group for each branch, which in turn
1889 can result in a performance improvement, as perl cannot optimize
1890 C</(?:(x)|(y)|(z))/> as efficiently as something like
1891 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1892
1893 When a match has failed, and unless another verb has been involved in
1894 failing the match and has provided its own name to use, the C<$REGERROR>
1895 variable will be set to the name of the most recently executed
1896 C<(*MARK:NAME)>.
1897
1898 See L</(*SKIP)> for more details.
1899
1900 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1901
1902 =item C<(*THEN)> C<(*THEN:NAME)>
1903
1904 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1905 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1906 failure, it causes the regex engine to try the next alternation in the
1907 innermost enclosing group (capturing or otherwise) that has alternations.
1908 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1909 count as an alternation, as far as C<(*THEN)> is concerned.
1910
1911 Its name comes from the observation that this operation combined with the
1912 alternation operator (C<|>) can be used to create what is essentially a
1913 pattern-based if/then/else block:
1914
1915   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1916
1917 Note that if this operator is used and NOT inside of an alternation then
1918 it acts exactly like the C<(*PRUNE)> operator.
1919
1920   / A (*PRUNE) B /
1921
1922 is the same as
1923
1924   / A (*THEN) B /
1925
1926 but
1927
1928   / ( A (*THEN) B | C ) /
1929
1930 is not the same as
1931
1932   / ( A (*PRUNE) B | C ) /
1933
1934 as after matching the A but failing on the B the C<(*THEN)> verb will
1935 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1936
1937 =back
1938
1939 =item Verbs without an argument
1940
1941 =over 4
1942
1943 =item C<(*COMMIT)>
1944 X<(*COMMIT)>
1945
1946 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1947 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1948 into on failure it causes the match to fail outright. No further attempts
1949 to find a valid match by advancing the start pointer will occur again.
1950 For example,
1951
1952  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1953  print "Count=$count\n";
1954
1955 outputs
1956
1957     aaab
1958     Count=1
1959
1960 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1961 does not match, the regex engine will not try any further matching on the
1962 rest of the string.
1963
1964 =item C<(*FAIL)> C<(*F)>
1965 X<(*FAIL)> X<(*F)>
1966
1967 This pattern matches nothing and always fails. It can be used to force the
1968 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1969 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1970
1971 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1972
1973 =item C<(*ACCEPT)>
1974 X<(*ACCEPT)>
1975
1976 B<WARNING:> This feature is highly experimental. It is not recommended
1977 for production code.
1978
1979 This pattern matches nothing and causes the end of successful matching at
1980 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1981 whether there is actually more to match in the string. When inside of a
1982 nested pattern, such as recursion, or in a subpattern dynamically generated
1983 via C<(??{})>, only the innermost pattern is ended immediately.
1984
1985 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1986 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1987 For instance:
1988
1989   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1990
1991 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1992 be set. If another branch in the inner parentheses was matched, such as in the
1993 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1994
1995 =back
1996
1997 =back
1998
1999 =head2 Backtracking
2000 X<backtrack> X<backtracking>
2001
2002 NOTE: This section presents an abstract approximation of regular
2003 expression behavior.  For a more rigorous (and complicated) view of
2004 the rules involved in selecting a match among possible alternatives,
2005 see L<Combining RE Pieces>.
2006
2007 A fundamental feature of regular expression matching involves the
2008 notion called I<backtracking>, which is currently used (when needed)
2009 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2010 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2011 internally, but the general principle outlined here is valid.
2012
2013 For a regular expression to match, the I<entire> regular expression must
2014 match, not just part of it.  So if the beginning of a pattern containing a
2015 quantifier succeeds in a way that causes later parts in the pattern to
2016 fail, the matching engine backs up and recalculates the beginning
2017 part--that's why it's called backtracking.
2018
2019 Here is an example of backtracking:  Let's say you want to find the
2020 word following "foo" in the string "Food is on the foo table.":
2021
2022     $_ = "Food is on the foo table.";
2023     if ( /\b(foo)\s+(\w+)/i ) {
2024         print "$2 follows $1.\n";
2025     }
2026
2027 When the match runs, the first part of the regular expression (C<\b(foo)>)
2028 finds a possible match right at the beginning of the string, and loads up
2029 $1 with "Foo".  However, as soon as the matching engine sees that there's
2030 no whitespace following the "Foo" that it had saved in $1, it realizes its
2031 mistake and starts over again one character after where it had the
2032 tentative match.  This time it goes all the way until the next occurrence
2033 of "foo". The complete regular expression matches this time, and you get
2034 the expected output of "table follows foo."
2035
2036 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2037 everything between "foo" and "bar".  Initially, you write something
2038 like this:
2039
2040     $_ =  "The food is under the bar in the barn.";
2041     if ( /foo(.*)bar/ ) {
2042         print "got <$1>\n";
2043     }
2044
2045 Which perhaps unexpectedly yields:
2046
2047   got <d is under the bar in the >
2048
2049 That's because C<.*> was greedy, so you get everything between the
2050 I<first> "foo" and the I<last> "bar".  Here it's more effective
2051 to use minimal matching to make sure you get the text between a "foo"
2052 and the first "bar" thereafter.
2053
2054     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2055   got <d is under the >
2056
2057 Here's another example. Let's say you'd like to match a number at the end
2058 of a string, and you also want to keep the preceding part of the match.
2059 So you write this:
2060
2061     $_ = "I have 2 numbers: 53147";
2062     if ( /(.*)(\d*)/ ) {                                # Wrong!
2063         print "Beginning is <$1>, number is <$2>.\n";
2064     }
2065
2066 That won't work at all, because C<.*> was greedy and gobbled up the
2067 whole string. As C<\d*> can match on an empty string the complete
2068 regular expression matched successfully.
2069
2070     Beginning is <I have 2 numbers: 53147>, number is <>.
2071
2072 Here are some variants, most of which don't work:
2073
2074     $_ = "I have 2 numbers: 53147";
2075     @pats = qw{
2076         (.*)(\d*)
2077         (.*)(\d+)
2078         (.*?)(\d*)
2079         (.*?)(\d+)
2080         (.*)(\d+)$
2081         (.*?)(\d+)$
2082         (.*)\b(\d+)$
2083         (.*\D)(\d+)$
2084     };
2085
2086     for $pat (@pats) {
2087         printf "%-12s ", $pat;
2088         if ( /$pat/ ) {
2089             print "<$1> <$2>\n";
2090         } else {
2091             print "FAIL\n";
2092         }
2093     }
2094
2095 That will print out:
2096
2097     (.*)(\d*)    <I have 2 numbers: 53147> <>
2098     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2099     (.*?)(\d*)   <> <>
2100     (.*?)(\d+)   <I have > <2>
2101     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2102     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2103     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2104     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2105
2106 As you see, this can be a bit tricky.  It's important to realize that a
2107 regular expression is merely a set of assertions that gives a definition
2108 of success.  There may be 0, 1, or several different ways that the
2109 definition might succeed against a particular string.  And if there are
2110 multiple ways it might succeed, you need to understand backtracking to
2111 know which variety of success you will achieve.
2112
2113 When using look-ahead assertions and negations, this can all get even
2114 trickier.  Imagine you'd like to find a sequence of non-digits not
2115 followed by "123".  You might try to write that as
2116
2117     $_ = "ABC123";
2118     if ( /^\D*(?!123)/ ) {                # Wrong!
2119         print "Yup, no 123 in $_\n";
2120     }
2121
2122 But that isn't going to match; at least, not the way you're hoping.  It
2123 claims that there is no 123 in the string.  Here's a clearer picture of
2124 why that pattern matches, contrary to popular expectations:
2125
2126     $x = 'ABC123';
2127     $y = 'ABC445';
2128
2129     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2130     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2131
2132     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2133     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2134
2135 This prints
2136
2137     2: got ABC
2138     3: got AB
2139     4: got ABC
2140
2141 You might have expected test 3 to fail because it seems to a more
2142 general purpose version of test 1.  The important difference between
2143 them is that test 3 contains a quantifier (C<\D*>) and so can use
2144 backtracking, whereas test 1 will not.  What's happening is
2145 that you've asked "Is it true that at the start of $x, following 0 or more
2146 non-digits, you have something that's not 123?"  If the pattern matcher had
2147 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2148 fail.
2149
2150 The search engine will initially match C<\D*> with "ABC".  Then it will
2151 try to match C<(?!123)> with "123", which fails.  But because
2152 a quantifier (C<\D*>) has been used in the regular expression, the
2153 search engine can backtrack and retry the match differently
2154 in the hope of matching the complete regular expression.
2155
2156 The pattern really, I<really> wants to succeed, so it uses the
2157 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2158 time.  Now there's indeed something following "AB" that is not
2159 "123".  It's "C123", which suffices.
2160
2161 We can deal with this by using both an assertion and a negation.
2162 We'll say that the first part in $1 must be followed both by a digit
2163 and by something that's not "123".  Remember that the look-aheads
2164 are zero-width expressions--they only look, but don't consume any
2165 of the string in their match.  So rewriting this way produces what
2166 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2167
2168     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2169     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2170
2171     6: got ABC
2172
2173 In other words, the two zero-width assertions next to each other work as though
2174 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2175 matches only if you're at the beginning of the line AND the end of the
2176 line simultaneously.  The deeper underlying truth is that juxtaposition in
2177 regular expressions always means AND, except when you write an explicit OR
2178 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2179 although the attempted matches are made at different positions because "a"
2180 is not a zero-width assertion, but a one-width assertion.
2181
2182 B<WARNING>: Particularly complicated regular expressions can take
2183 exponential time to solve because of the immense number of possible
2184 ways they can use backtracking to try for a match.  For example, without
2185 internal optimizations done by the regular expression engine, this will
2186 take a painfully long time to run:
2187
2188     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2189
2190 And if you used C<*>'s in the internal groups instead of limiting them
2191 to 0 through 5 matches, then it would take forever--or until you ran
2192 out of stack space.  Moreover, these internal optimizations are not
2193 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2194 on the external group, no current optimization is applicable, and the
2195 match takes a long time to finish.
2196
2197 A powerful tool for optimizing such beasts is what is known as an
2198 "independent group",
2199 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2200 zero-length look-ahead/look-behind assertions will not backtrack to make
2201 the tail match, since they are in "logical" context: only
2202 whether they match is considered relevant.  For an example
2203 where side-effects of look-ahead I<might> have influenced the
2204 following match, see L</C<< (?>pattern) >>>.
2205
2206 =head2 Version 8 Regular Expressions
2207 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2208
2209 In case you're not familiar with the "regular" Version 8 regex
2210 routines, here are the pattern-matching rules not described above.
2211
2212 Any single character matches itself, unless it is a I<metacharacter>
2213 with a special meaning described here or above.  You can cause
2214 characters that normally function as metacharacters to be interpreted
2215 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2216 character; "\\" matches a "\"). This escape mechanism is also required
2217 for the character used as the pattern delimiter.
2218
2219 A series of characters matches that series of characters in the target
2220 string, so the pattern C<blurfl> would match "blurfl" in the target
2221 string.
2222
2223 You can specify a character class, by enclosing a list of characters
2224 in C<[]>, which will match any character from the list.  If the
2225 first character after the "[" is "^", the class matches any character not
2226 in the list.  Within a list, the "-" character specifies a
2227 range, so that C<a-z> represents all characters between "a" and "z",
2228 inclusive.  If you want either "-" or "]" itself to be a member of a
2229 class, put it at the start of the list (possibly after a "^"), or
2230 escape it with a backslash.  "-" is also taken literally when it is
2231 at the end of the list, just before the closing "]".  (The
2232 following all specify the same class of three characters: C<[-az]>,
2233 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2234 specifies a class containing twenty-six characters, even on EBCDIC-based
2235 character sets.)  Also, if you try to use the character
2236 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2237 a range, the "-" is understood literally.
2238
2239 Note also that the whole range idea is rather unportable between
2240 character sets--and even within character sets they may cause results
2241 you probably didn't expect.  A sound principle is to use only ranges
2242 that begin from and end at either alphabetics of equal case ([a-e],
2243 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2244 spell out the character sets in full.
2245
2246 Characters may be specified using a metacharacter syntax much like that
2247 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2248 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2249 of three octal digits, matches the character whose coded character set value
2250 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2251 matches the character whose ordinal is I<nn>. The expression \cI<x>
2252 matches the character control-I<x>.  Finally, the "." metacharacter
2253 matches any character except "\n" (unless you use C</s>).
2254
2255 You can specify a series of alternatives for a pattern using "|" to
2256 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2257 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2258 first alternative includes everything from the last pattern delimiter
2259 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2260 the last alternative contains everything from the last "|" to the next
2261 closing pattern delimiter.  That's why it's common practice to include
2262 alternatives in parentheses: to minimize confusion about where they
2263 start and end.
2264
2265 Alternatives are tried from left to right, so the first
2266 alternative found for which the entire expression matches, is the one that
2267 is chosen. This means that alternatives are not necessarily greedy. For
2268 example: when matching C<foo|foot> against "barefoot", only the "foo"
2269 part will match, as that is the first alternative tried, and it successfully
2270 matches the target string. (This might not seem important, but it is
2271 important when you are capturing matched text using parentheses.)
2272
2273 Also remember that "|" is interpreted as a literal within square brackets,
2274 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2275
2276 Within a pattern, you may designate subpatterns for later reference
2277 by enclosing them in parentheses, and you may refer back to the
2278 I<n>th subpattern later in the pattern using the metacharacter
2279 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2280 of their opening parenthesis.  A backreference matches whatever
2281 actually matched the subpattern in the string being examined, not
2282 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2283 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2284 1 matched "0x", even though the rule C<0|0x> could potentially match
2285 the leading 0 in the second number.
2286
2287 =head2 Warning on \1 Instead of $1
2288
2289 Some people get too used to writing things like:
2290
2291     $pattern =~ s/(\W)/\\\1/g;
2292
2293 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2294 shocking the
2295 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2296 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2297 the usual double-quoted string means a control-A.  The customary Unix
2298 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2299 of doing that, you get yourself into trouble if you then add an C</e>
2300 modifier.
2301
2302     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2303
2304 Or if you try to do
2305
2306     s/(\d+)/\1000/;
2307
2308 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2309 C<${1}000>.  The operation of interpolation should not be confused
2310 with the operation of matching a backreference.  Certainly they mean two
2311 different things on the I<left> side of the C<s///>.
2312
2313 =head2 Repeated Patterns Matching a Zero-length Substring
2314
2315 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2316
2317 Regular expressions provide a terse and powerful programming language.  As
2318 with most other power tools, power comes together with the ability
2319 to wreak havoc.
2320
2321 A common abuse of this power stems from the ability to make infinite
2322 loops using regular expressions, with something as innocuous as:
2323
2324     'foo' =~ m{ ( o? )* }x;
2325
2326 The C<o?> matches at the beginning of C<'foo'>, and since the position
2327 in the string is not moved by the match, C<o?> would match again and again
2328 because of the C<*> quantifier.  Another common way to create a similar cycle
2329 is with the looping modifier C<//g>:
2330
2331     @matches = ( 'foo' =~ m{ o? }xg );
2332
2333 or
2334
2335     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2336
2337 or the loop implied by split().
2338
2339 However, long experience has shown that many programming tasks may
2340 be significantly simplified by using repeated subexpressions that
2341 may match zero-length substrings.  Here's a simple example being:
2342
2343     @chars = split //, $string;           # // is not magic in split
2344     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2345
2346 Thus Perl allows such constructs, by I<forcefully breaking
2347 the infinite loop>.  The rules for this are different for lower-level
2348 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2349 ones like the C</g> modifier or split() operator.
2350
2351 The lower-level loops are I<interrupted> (that is, the loop is
2352 broken) when Perl detects that a repeated expression matched a
2353 zero-length substring.   Thus
2354
2355    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2356
2357 is made equivalent to
2358
2359    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2360
2361 For example, this program
2362
2363    #!perl -l
2364    "aaaaab" =~ /
2365      (?:
2366         a                 # non-zero
2367         |                 # or
2368        (?{print "hello"}) # print hello whenever this
2369                           #    branch is tried
2370        (?=(b))            # zero-width assertion
2371      )*  # any number of times
2372     /x;
2373    print $&;
2374    print $1;
2375
2376 prints
2377
2378    hello
2379    aaaaa
2380    b
2381
2382 Notice that "hello" is only printed once, as when Perl sees that the sixth
2383 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2384 the C<*>.
2385
2386 The higher-level loops preserve an additional state between iterations:
2387 whether the last match was zero-length.  To break the loop, the following
2388 match after a zero-length match is prohibited to have a length of zero.
2389 This prohibition interacts with backtracking (see L<"Backtracking">),
2390 and so the I<second best> match is chosen if the I<best> match is of
2391 zero length.
2392
2393 For example:
2394
2395     $_ = 'bar';
2396     s/\w??/<$&>/g;
2397
2398 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2399 match given by non-greedy C<??> is the zero-length match, and the I<second
2400 best> match is what is matched by C<\w>.  Thus zero-length matches
2401 alternate with one-character-long matches.
2402
2403 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2404 position one notch further in the string.
2405
2406 The additional state of being I<matched with zero-length> is associated with
2407 the matched string, and is reset by each assignment to pos().
2408 Zero-length matches at the end of the previous match are ignored
2409 during C<split>.
2410
2411 =head2 Combining RE Pieces
2412
2413 Each of the elementary pieces of regular expressions which were described
2414 before (such as C<ab> or C<\Z>) could match at most one substring
2415 at the given position of the input string.  However, in a typical regular
2416 expression these elementary pieces are combined into more complicated
2417 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2418 (in these examples C<S> and C<T> are regular subexpressions).
2419
2420 Such combinations can include alternatives, leading to a problem of choice:
2421 if we match a regular expression C<a|ab> against C<"abc">, will it match
2422 substring C<"a"> or C<"ab">?  One way to describe which substring is
2423 actually matched is the concept of backtracking (see L<"Backtracking">).
2424 However, this description is too low-level and makes you think
2425 in terms of a particular implementation.
2426
2427 Another description starts with notions of "better"/"worse".  All the
2428 substrings which may be matched by the given regular expression can be
2429 sorted from the "best" match to the "worst" match, and it is the "best"
2430 match which is chosen.  This substitutes the question of "what is chosen?"
2431 by the question of "which matches are better, and which are worse?".
2432
2433 Again, for elementary pieces there is no such question, since at most
2434 one match at a given position is possible.  This section describes the
2435 notion of better/worse for combining operators.  In the description
2436 below C<S> and C<T> are regular subexpressions.
2437
2438 =over 4
2439
2440 =item C<ST>
2441
2442 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2443 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2444 which can be matched by C<T>.
2445
2446 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2447 match than C<A'B'>.
2448
2449 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2450 C<B> is a better match for C<T> than C<B'>.
2451
2452 =item C<S|T>
2453
2454 When C<S> can match, it is a better match than when only C<T> can match.
2455
2456 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2457 two matches for C<T>.
2458
2459 =item C<S{REPEAT_COUNT}>
2460
2461 Matches as C<SSS...S> (repeated as many times as necessary).
2462
2463 =item C<S{min,max}>
2464
2465 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2466
2467 =item C<S{min,max}?>
2468
2469 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2470
2471 =item C<S?>, C<S*>, C<S+>
2472
2473 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2474
2475 =item C<S??>, C<S*?>, C<S+?>
2476
2477 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2478
2479 =item C<< (?>S) >>
2480
2481 Matches the best match for C<S> and only that.
2482
2483 =item C<(?=S)>, C<(?<=S)>
2484
2485 Only the best match for C<S> is considered.  (This is important only if
2486 C<S> has capturing parentheses, and backreferences are used somewhere
2487 else in the whole regular expression.)
2488
2489 =item C<(?!S)>, C<(?<!S)>
2490
2491 For this grouping operator there is no need to describe the ordering, since
2492 only whether or not C<S> can match is important.
2493
2494 =item C<(??{ EXPR })>, C<(?PARNO)>
2495
2496 The ordering is the same as for the regular expression which is
2497 the result of EXPR, or the pattern contained by capture group PARNO.
2498
2499 =item C<(?(condition)yes-pattern|no-pattern)>
2500
2501 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2502 already determined.  The ordering of the matches is the same as for the
2503 chosen subexpression.
2504
2505 =back
2506
2507 The above recipes describe the ordering of matches I<at a given position>.
2508 One more rule is needed to understand how a match is determined for the
2509 whole regular expression: a match at an earlier position is always better
2510 than a match at a later position.
2511
2512 =head2 Creating Custom RE Engines
2513
2514 As of Perl 5.10.0, one can create custom regular expression engines.  This
2515 is not for the faint of heart, as they have to plug in at the C level.  See
2516 L<perlreapi> for more details.
2517
2518 As an alternative, overloaded constants (see L<overload>) provide a simple
2519 way to extend the functionality of the RE engine, by substituting one
2520 pattern for another.
2521
2522 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2523 matches at a boundary between whitespace characters and non-whitespace
2524 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2525 at these positions, so we want to have each C<\Y|> in the place of the
2526 more complicated version.  We can create a module C<customre> to do
2527 this:
2528
2529     package customre;
2530     use overload;
2531
2532     sub import {
2533       shift;
2534       die "No argument to customre::import allowed" if @_;
2535       overload::constant 'qr' => \&convert;
2536     }
2537
2538     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2539
2540     # We must also take care of not escaping the legitimate \\Y|
2541     # sequence, hence the presence of '\\' in the conversion rules.
2542     my %rules = ( '\\' => '\\\\',
2543                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2544     sub convert {
2545       my $re = shift;
2546       $re =~ s{
2547                 \\ ( \\ | Y . )
2548               }
2549               { $rules{$1} or invalid($re,$1) }sgex;
2550       return $re;
2551     }
2552
2553 Now C<use customre> enables the new escape in constant regular
2554 expressions, i.e., those without any runtime variable interpolations.
2555 As documented in L<overload>, this conversion will work only over
2556 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2557 part of this regular expression needs to be converted explicitly
2558 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2559
2560     use customre;
2561     $re = <>;
2562     chomp $re;
2563     $re = customre::convert $re;
2564     /\Y|$re\Y|/;
2565
2566 =head2 PCRE/Python Support
2567
2568 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2569 to the regex syntax. While Perl programmers are encouraged to use the
2570 Perl-specific syntax, the following are also accepted:
2571
2572 =over 4
2573
2574 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2575
2576 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2577
2578 =item C<< (?P=NAME) >>
2579
2580 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2581
2582 =item C<< (?P>NAME) >>
2583
2584 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2585
2586 =back
2587
2588 =head1 BUGS
2589
2590 Many regular expression constructs don't work on EBCDIC platforms.
2591
2592 There are a number of issues with regard to case-insensitive matching
2593 in Unicode rules.  See C<i> under L</Modifiers> above.
2594
2595 This document varies from difficult to understand to completely
2596 and utterly opaque.  The wandering prose riddled with jargon is
2597 hard to fathom in several places.
2598
2599 This document needs a rewrite that separates the tutorial content
2600 from the reference content.
2601
2602 =head1 SEE ALSO
2603
2604 L<perlrequick>.
2605
2606 L<perlretut>.
2607
2608 L<perlop/"Regexp Quote-Like Operators">.
2609
2610 L<perlop/"Gory details of parsing quoted constructs">.
2611
2612 L<perlfaq6>.
2613
2614 L<perlfunc/pos>.
2615
2616 L<perllocale>.
2617
2618 L<perlebcdic>.
2619
2620 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2621 by O'Reilly and Associates.