This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
add perltrap entry about "${#a}", as suggested by
[perl5.git] / pod / perltrap.pod
1 =head1 NAME
2
3 perltrap - Perl traps for the unwary
4
5 =head1 DESCRIPTION
6
7 The biggest trap of all is forgetting to use the B<-w> switch; see
8 L<perlrun>.  The second biggest trap is not making your entire program
9 runnable under C<use strict>.  The third biggest trap is not reading
10 the list of changes in this version of Perl; see L<perldelta>.
11
12 =head2 Awk Traps
13
14 Accustomed B<awk> users should take special note of the following:
15
16 =over 4
17
18 =item *
19
20 The English module, loaded via
21
22     use English;
23
24 allows you to refer to special variables (like C<$/>) with names (like
25 C<$RS>), as though they were in B<awk>; see L<perlvar> for details.
26
27 =item *
28
29 Semicolons are required after all simple statements in Perl (except
30 at the end of a block).  Newline is not a statement delimiter.
31
32 =item *
33
34 Curly brackets are required on C<if>s and C<while>s.
35
36 =item *
37
38 Variables begin with "$", "@" or "%" in Perl.
39
40 =item *
41
42 Arrays index from 0.  Likewise string positions in substr() and
43 index().
44
45 =item *
46
47 You have to decide whether your array has numeric or string indices.
48
49 =item *
50
51 Hash values do not spring into existence upon mere reference.
52
53 =item *
54
55 You have to decide whether you want to use string or numeric
56 comparisons.
57
58 =item *
59
60 Reading an input line does not split it for you.  You get to split it
61 to an array yourself.  And the split() operator has different
62 arguments than B<awk>'s.
63
64 =item *
65
66 The current input line is normally in $_, not $0.  It generally does
67 not have the newline stripped.  ($0 is the name of the program
68 executed.)  See L<perlvar>.
69
70 =item *
71
72 $E<lt>I<digit>E<gt> does not refer to fields--it refers to substrings matched
73 by the last match pattern.
74
75 =item *
76
77 The print() statement does not add field and record separators unless
78 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
79 the English module.
80
81 =item *
82
83 You must open your files before you print to them.
84
85 =item *
86
87 The range operator is "..", not comma.  The comma operator works as in
88 C.
89
90 =item *
91
92 The match operator is "=~", not "~".  ("~" is the one's complement
93 operator, as in C.)
94
95 =item *
96
97 The exponentiation operator is "**", not "^".  "^" is the XOR
98 operator, as in C.  (You know, one could get the feeling that B<awk> is
99 basically incompatible with C.)
100
101 =item *
102
103 The concatenation operator is ".", not the null string.  (Using the
104 null string would render C</pat/ /pat/> unparsable, because the third slash
105 would be interpreted as a division operator--the tokenizer is in fact
106 slightly context sensitive for operators like "/", "?", and "E<gt>".
107 And in fact, "." itself can be the beginning of a number.)
108
109 =item *
110
111 The C<next>, C<exit>, and C<continue> keywords work differently.
112
113 =item *
114
115
116 The following variables work differently:
117
118       Awk       Perl
119       ARGC      $#ARGV or scalar @ARGV
120       ARGV[0]   $0
121       FILENAME  $ARGV
122       FNR       $. - something
123       FS        (whatever you like)
124       NF        $#Fld, or some such
125       NR        $.
126       OFMT      $#
127       OFS       $,
128       ORS       $\
129       RLENGTH   length($&)
130       RS        $/
131       RSTART    length($`)
132       SUBSEP    $;
133
134 =item *
135
136 You cannot set $RS to a pattern, only a string.
137
138 =item *
139
140 When in doubt, run the B<awk> construct through B<a2p> and see what it
141 gives you.
142
143 =back
144
145 =head2 C Traps
146
147 Cerebral C programmers should take note of the following:
148
149 =over 4
150
151 =item *
152
153 Curly brackets are required on C<if>'s and C<while>'s.
154
155 =item *
156
157 You must use C<elsif> rather than C<else if>.
158
159 =item *
160
161 The C<break> and C<continue> keywords from C become in
162 Perl C<last> and C<next>, respectively.
163 Unlike in C, these do I<NOT> work within a C<do { } while> construct.
164
165 =item *
166
167 There's no switch statement.  (But it's easy to build one on the fly.)
168
169 =item *
170
171 Variables begin with "$", "@" or "%" in Perl.
172
173 =item *
174
175 C<printf()> does not implement the "*" format for interpolating
176 field widths, but it's trivial to use interpolation of double-quoted
177 strings to achieve the same effect.
178
179 =item *
180
181 Comments begin with "#", not "/*".
182
183 =item *
184
185 You can't take the address of anything, although a similar operator
186 in Perl is the backslash, which creates a reference.
187
188 =item *
189
190 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
191 ends up in C<$0>.
192
193 =item *
194
195 System calls such as link(), unlink(), rename(), etc. return nonzero for
196 success, not 0.
197
198 =item *
199
200 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
201 to find their names on your system.
202
203 =back
204
205 =head2 Sed Traps
206
207 Seasoned B<sed> programmers should take note of the following:
208
209 =over 4
210
211 =item *
212
213 Backreferences in substitutions use "$" rather than "\".
214
215 =item *
216
217 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
218 in front.
219
220 =item *
221
222 The range operator is C<...>, rather than comma.
223
224 =back
225
226 =head2 Shell Traps
227
228 Sharp shell programmers should take note of the following:
229
230 =over 4
231
232 =item *
233
234 The backtick operator does variable interpolation without regard to
235 the presence of single quotes in the command.
236
237 =item *
238
239 The backtick operator does no translation of the return value, unlike B<csh>.
240
241 =item *
242
243 Shells (especially B<csh>) do several levels of substitution on each
244 command line.  Perl does substitution in only certain constructs
245 such as double quotes, backticks, angle brackets, and search patterns.
246
247 =item *
248
249 Shells interpret scripts a little bit at a time.  Perl compiles the
250 entire program before executing it (except for C<BEGIN> blocks, which
251 execute at compile time).
252
253 =item *
254
255 The arguments are available via @ARGV, not $1, $2, etc.
256
257 =item *
258
259 The environment is not automatically made available as separate scalar
260 variables.
261
262 =back
263
264 =head2 Perl Traps
265
266 Practicing Perl Programmers should take note of the following:
267
268 =over 4
269
270 =item *
271
272 Remember that many operations behave differently in a list
273 context than they do in a scalar one.  See L<perldata> for details.
274
275 =item *
276
277 Avoid barewords if you can, especially all lowercase ones.
278 You can't tell by just looking at it whether a bareword is
279 a function or a string.  By using quotes on strings and
280 parentheses on function calls, you won't ever get them confused.
281
282 =item *
283
284 You cannot discern from mere inspection which builtins
285 are unary operators (like chop() and chdir())
286 and which are list operators (like print() and unlink()).
287 (User-defined subroutines can be B<only> list operators, never
288 unary ones.)  See L<perlop>.
289
290 =item *
291
292 People have a hard time remembering that some functions
293 default to $_, or @ARGV, or whatever, but that others which
294 you might expect to do not.
295
296 =item *
297
298 The E<lt>FHE<gt> construct is not the name of the filehandle, it is a readline
299 operation on that handle.  The data read is assigned to $_ only if the
300 file read is the sole condition in a while loop:
301
302     while (<FH>)      { }
303     while (defined($_ = <FH>)) { }..
304     <FH>;  # data discarded!
305
306 =item *
307
308 Remember not to use "C<=>" when you need "C<=~>";
309 these two constructs are quite different:
310
311     $x =  /foo/;
312     $x =~ /foo/;
313
314 =item *
315
316 The C<do {}> construct isn't a real loop that you can use
317 loop control on.
318
319 =item *
320
321 Use C<my()> for local variables whenever you can get away with
322 it (but see L<perlform> for where you can't).
323 Using C<local()> actually gives a local value to a global
324 variable, which leaves you open to unforeseen side-effects
325 of dynamic scoping.
326
327 =item *
328
329 If you localize an exported variable in a module, its exported value will
330 not change.  The local name becomes an alias to a new value but the
331 external name is still an alias for the original.
332
333 =back
334
335 =head2 Perl4 to Perl5 Traps
336
337 Practicing Perl4 Programmers should take note of the following
338 Perl4-to-Perl5 specific traps.
339
340 They're crudely ordered according to the following list:
341
342 =over 4
343
344 =item Discontinuance, Deprecation, and BugFix traps
345
346 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
347 or deprecated as a perl4 feature with the intent to encourage usage of
348 some other perl5 feature.
349
350 =item Parsing Traps
351
352 Traps that appear to stem from the new parser.
353
354 =item Numerical Traps
355
356 Traps having to do with numerical or mathematical operators.
357
358 =item General data type traps
359
360 Traps involving perl standard data types.
361
362 =item Context Traps - scalar, list contexts
363
364 Traps related to context within lists, scalar statements/declarations.
365
366 =item Precedence Traps
367
368 Traps related to the precedence of parsing, evaluation, and execution of
369 code.
370
371 =item General Regular Expression Traps using s///, etc.
372
373 Traps related to the use of pattern matching.
374
375 =item Subroutine, Signal, Sorting Traps
376
377 Traps related to the use of signals and signal handlers, general subroutines,
378 and sorting, along with sorting subroutines.
379
380 =item OS Traps
381
382 OS-specific traps.
383
384 =item DBM Traps
385
386 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
387
388 =item Unclassified Traps
389
390 Everything else.
391
392 =back
393
394 If you find an example of a conversion trap that is not listed here,
395 please submit it to Bill Middleton <F<wjm@best.com>> for inclusion.
396 Also note that at least some of these can be caught with B<-w>.
397
398 =head2 Discontinuance, Deprecation, and BugFix traps
399
400 Anything that has been discontinued, deprecated, or fixed as
401 a bug from perl4.
402
403 =over 4
404
405 =item * Discontinuance
406
407 Symbols starting with "_" are no longer forced into package main, except
408 for C<$_> itself (and C<@_>, etc.).
409
410     package test;
411     $_legacy = 1;
412
413     package main;
414     print "\$_legacy is ",$_legacy,"\n";
415
416     # perl4 prints: $_legacy is 1
417     # perl5 prints: $_legacy is
418
419 =item * Deprecation
420
421 Double-colon is now a valid package separator in a variable name.  Thus these
422 behave differently in perl4 vs. perl5, because the packages don't exist.
423
424     $a=1;$b=2;$c=3;$var=4;
425     print "$a::$b::$c ";
426     print "$var::abc::xyz\n";
427  
428     # perl4 prints: 1::2::3 4::abc::xyz
429     # perl5 prints: 3
430
431 Given that C<::> is now the preferred package delimiter, it is debatable
432 whether this should be classed as a bug or not.
433 (The older package delimiter, ' ,is used here)
434
435     $x = 10 ;
436     print "x=${'x}\n" ;
437
438     # perl4 prints: x=10
439     # perl5 prints: Can't find string terminator "'" anywhere before EOF
440
441 You can avoid this problem, and remain compatible with perl4, if you
442 always explicitly include the package name:
443
444     $x = 10 ;
445     print "x=${main'x}\n" ;
446
447 Also see precedence traps, for parsing C<$:>.
448
449 =item * BugFix
450
451 The second and third arguments of C<splice()> are now evaluated in scalar
452 context (as the Camel says) rather than list context.
453
454     sub sub1{return(0,2) }          # return a 2-element list
455     sub sub2{ return(1,2,3)}        # return a 3-element list
456     @a1 = ("a","b","c","d","e");
457     @a2 = splice(@a1,&sub1,&sub2);
458     print join(' ',@a2),"\n";
459
460     # perl4 prints: a b
461     # perl5 prints: c d e
462
463 =item * Discontinuance
464
465 You can't do a C<goto> into a block that is optimized away.  Darn.
466
467     goto marker1;
468
469     for(1){
470     marker1:
471         print "Here I is!\n";
472     }
473
474     # perl4 prints: Here I is!
475     # perl5 dumps core (SEGV)
476
477 =item * Discontinuance
478
479 It is no longer syntactically legal to use whitespace as the name
480 of a variable, or as a delimiter for any kind of quote construct.
481 Double darn.
482
483     $a = ("foo bar");
484     $b = q baz ;
485     print "a is $a, b is $b\n";
486
487     # perl4 prints: a is foo bar, b is baz
488     # perl5 errors: Bareword found where operator expected
489
490 =item * Discontinuance
491
492 The archaic while/if BLOCK BLOCK syntax is no longer supported.
493
494     if { 1 } {
495         print "True!";
496     }
497     else {
498         print "False!";
499     }
500
501     # perl4 prints: True!
502     # perl5 errors: syntax error at test.pl line 1, near "if {"
503
504 =item * BugFix
505
506 The C<**> operator now binds more tightly than unary minus.
507 It was documented to work this way before, but didn't.
508
509     print -4**2,"\n";
510
511     # perl4 prints: 16
512     # perl5 prints: -16
513
514 =item * Discontinuance
515
516 The meaning of C<foreach{}> has changed slightly when it is iterating over a
517 list which is not an array.  This used to assign the list to a
518 temporary array, but no longer does so (for efficiency).  This means
519 that you'll now be iterating over the actual values, not over copies of
520 the values.  Modifications to the loop variable can change the original
521 values.
522
523     @list = ('ab','abc','bcd','def');
524     foreach $var (grep(/ab/,@list)){
525         $var = 1;
526     }
527     print (join(':',@list));
528
529     # perl4 prints: ab:abc:bcd:def
530     # perl5 prints: 1:1:bcd:def
531
532 To retain Perl4 semantics you need to assign your list
533 explicitly to a temporary array and then iterate over that.  For
534 example, you might need to change
535
536     foreach $var (grep(/ab/,@list)){
537
538 to
539
540     foreach $var (@tmp = grep(/ab/,@list)){
541
542 Otherwise changing $var will clobber the values of @list.  (This most often
543 happens when you use C<$_> for the loop variable, and call subroutines in
544 the loop that don't properly localize C<$_>.)
545
546 =item * Discontinuance
547
548 C<split> with no arguments now behaves like C<split ' '> (which doesn't
549 return an initial null field if $_ starts with whitespace), it used to
550 behave like C<split /\s+/> (which does).
551
552     $_ = ' hi mom';
553     print join(':', split);
554
555     # perl4 prints: :hi:mom
556     # perl5 prints: hi:mom
557
558 =item * BugFix
559
560 Perl 4 would ignore any text which was attached to an B<-e> switch,
561 always taking the code snippet from the following arg.  Additionally, it
562 would silently accept an B<-e> switch without a following arg.  Both of
563 these behaviors have been fixed.
564
565     perl -e'print "attached to -e"' 'print "separate arg"'
566
567     # perl4 prints: separate arg
568     # perl5 prints: attached to -e
569
570     perl -e
571
572     # perl4 prints:
573     # perl5 dies: No code specified for -e.
574
575 =item * Discontinuance
576
577 In Perl 4 the return value of C<push> was undocumented, but it was
578 actually the last value being pushed onto the target list.  In Perl 5
579 the return value of C<push> is documented, but has changed, it is the
580 number of elements in the resulting list.
581
582     @x = ('existing');
583     print push(@x, 'first new', 'second new');
584
585     # perl4 prints: second new
586     # perl5 prints: 3
587
588 =item * Discontinuance
589
590 In Perl 4 (and versions of Perl 5 before 5.004), C<'\r'> characters in
591 Perl code were silently allowed, although they could cause (mysterious!)
592 failures in certain constructs, particularly here documents.  Now,
593 C<'\r'> characters cause an immediate fatal error.  (Note: In this
594 example, the notation B<\015> represents the incorrect line
595 ending. Depending upon your text viewer, it will look different.)
596
597     print "foo";\015
598     print "bar";
599
600     # perl4     prints: foobar
601     # perl5.003 prints: foobar
602     # perl5.004 dies: Illegal character \015 (carriage return)
603
604 See L<perldiag> for full details.
605
606 =item * Deprecation
607
608 Some error messages will be different.
609
610 =item * Discontinuance
611
612 Some bugs may have been inadvertently removed.  :-)
613
614 =back
615
616 =head2 Parsing Traps
617
618 Perl4-to-Perl5 traps from having to do with parsing.
619
620 =over 4
621
622 =item * Parsing
623
624 Note the space between . and =
625
626     $string . = "more string";
627     print $string;
628
629     # perl4 prints: more string
630     # perl5 prints: syntax error at - line 1, near ". ="
631
632 =item * Parsing
633
634 Better parsing in perl 5
635
636     sub foo {}
637     &foo
638     print("hello, world\n");
639
640     # perl4 prints: hello, world
641     # perl5 prints: syntax error
642
643 =item * Parsing
644
645 "if it looks like a function, it is a function" rule.
646
647   print
648     ($foo == 1) ? "is one\n" : "is zero\n";
649
650     # perl4 prints: is zero
651     # perl5 warns: "Useless use of a constant in void context" if using -w
652
653 =item * Parsing
654
655 String interpolation of the C<$#array> construct differs when braces
656 are to used around the name.
657
658     @ = (1..3);
659     print "${#a}";
660
661     # perl4 prints: 2
662     # perl5 fails with syntax error
663
664     @ = (1..3);
665     print "$#{a}";
666
667     # perl4 prints: {a}
668     # perl5 prints: 2
669
670 =back
671
672 =head2 Numerical Traps
673
674 Perl4-to-Perl5 traps having to do with numerical operators,
675 operands, or output from same.
676
677 =over 5
678
679 =item * Numerical
680
681 Formatted output and significant digits
682
683     print 7.373504 - 0, "\n";
684     printf "%20.18f\n", 7.373504 - 0;
685
686     # Perl4 prints:
687     7.375039999999996141
688     7.37503999999999614
689
690     # Perl5 prints:
691     7.373504
692     7.37503999999999614
693
694 =item * Numerical
695
696 This specific item has been deleted.  It demonstrated how the auto-increment
697 operator would not catch when a number went over the signed int limit.  Fixed
698 in version 5.003_04.  But always be wary when using large integers.
699 If in doubt:
700
701    use Math::BigInt;
702
703 =item * Numerical
704
705 Assignment of return values from numeric equality tests
706 does not work in perl5 when the test evaluates to false (0).
707 Logical tests now return an null, instead of 0
708
709     $p = ($test == 1);
710     print $p,"\n";
711
712     # perl4 prints: 0
713     # perl5 prints:
714
715 Also see L<"General Regular Expression Traps using s///, etc.">
716 for another example of this new feature...
717
718 =back
719
720 =head2 General data type traps
721
722 Perl4-to-Perl5 traps involving most data-types, and their usage
723 within certain expressions and/or context.
724
725 =over 5
726
727 =item * (Arrays)
728
729 Negative array subscripts now count from the end of the array.
730
731     @a = (1, 2, 3, 4, 5);
732     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
733
734     # perl4 prints: The third element of the array is 4 also expressed as
735     # perl5 prints: The third element of the array is 4 also expressed as 4
736
737 =item * (Arrays)
738
739 Setting C<$#array> lower now discards array elements, and makes them
740 impossible to recover.
741
742     @a = (a,b,c,d,e);
743     print "Before: ",join('',@a);
744     $#a =1;
745     print ", After: ",join('',@a);
746     $#a =3;
747     print ", Recovered: ",join('',@a),"\n";
748
749     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
750     # perl5 prints: Before: abcde, After: ab, Recovered: ab
751
752 =item * (Hashes)
753
754 Hashes get defined before use
755
756     local($s,@a,%h);
757     die "scalar \$s defined" if defined($s);
758     die "array \@a defined" if defined(@a);
759     die "hash \%h defined" if defined(%h);
760
761     # perl4 prints:
762     # perl5 dies: hash %h defined
763
764 =item * (Globs)
765
766 glob assignment from variable to variable will fail if the assigned
767 variable is localized subsequent to the assignment
768
769     @a = ("This is Perl 4");
770     *b = *a;
771     local(@a);
772     print @b,"\n";
773
774     # perl4 prints: This is Perl 4
775     # perl5 prints:
776
777 =item * (Globs)
778
779 Assigning C<undef> to a glob has no effect in Perl 5.   In Perl 4
780 it undefines the associated scalar (but may have other side effects
781 including SEGVs).
782
783 =item * (Scalar String)
784
785 Changes in unary negation (of strings)
786 This change effects both the return value and what it
787 does to auto(magic)increment.
788
789     $x = "aaa";
790     print ++$x," : ";
791     print -$x," : ";
792     print ++$x,"\n";
793
794     # perl4 prints: aab : -0 : 1
795     # perl5 prints: aab : -aab : aac
796
797 =item * (Constants)
798
799 perl 4 lets you modify constants:
800
801     $foo = "x";
802     &mod($foo);
803     for ($x = 0; $x < 3; $x++) {
804         &mod("a");
805     }
806     sub mod {
807         print "before: $_[0]";
808         $_[0] = "m";
809         print "  after: $_[0]\n";
810     }
811
812     # perl4:
813     # before: x  after: m
814     # before: a  after: m
815     # before: m  after: m
816     # before: m  after: m
817
818     # Perl5:
819     # before: x  after: m
820     # Modification of a read-only value attempted at foo.pl line 12.
821     # before: a
822
823 =item * (Scalars)
824
825 The behavior is slightly different for:
826
827     print "$x", defined $x
828
829     # perl 4: 1
830     # perl 5: <no output, $x is not called into existence>
831
832 =item * (Variable Suicide)
833
834 Variable suicide behavior is more consistent under Perl 5.
835 Perl5 exhibits the same behavior for hashes and scalars,
836 that perl4 exhibits for only scalars.
837
838     $aGlobal{ "aKey" } = "global value";
839     print "MAIN:", $aGlobal{"aKey"}, "\n";
840     $GlobalLevel = 0;
841     &test( *aGlobal );
842
843     sub test {
844         local( *theArgument ) = @_;
845         local( %aNewLocal ); # perl 4 != 5.001l,m
846         $aNewLocal{"aKey"} = "this should never appear";
847         print "SUB: ", $theArgument{"aKey"}, "\n";
848         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
849         $GlobalLevel++;
850         if( $GlobalLevel<4 ) {
851             &test( *aNewLocal );
852         }
853     }
854
855     # Perl4:
856     # MAIN:global value
857     # SUB: global value
858     # SUB: level 0
859     # SUB: level 1
860     # SUB: level 2
861
862     # Perl5:
863     # MAIN:global value
864     # SUB: global value
865     # SUB: this should never appear
866     # SUB: this should never appear
867     # SUB: this should never appear
868
869 =back
870
871 =head2 Context Traps - scalar, list contexts
872
873 =over 5
874
875 =item * (list context)
876
877 The elements of argument lists for formats are now evaluated in list
878 context.  This means you can interpolate list values now.
879
880     @fmt = ("foo","bar","baz");
881     format STDOUT=
882     @<<<<< @||||| @>>>>>
883     @fmt;
884     .
885     write;
886
887     # perl4 errors:  Please use commas to separate fields in file
888     # perl5 prints: foo     bar      baz
889
890 =item * (scalar context)
891
892 The C<caller()> function now returns a false value in a scalar context
893 if there is no caller.  This lets library files determine if they're
894 being required.
895
896     caller() ? (print "You rang?\n") : (print "Got a 0\n");
897
898     # perl4 errors: There is no caller
899     # perl5 prints: Got a 0
900
901 =item * (scalar context)
902
903 The comma operator in a scalar context is now guaranteed to give a
904 scalar context to its arguments.
905
906     @y= ('a','b','c');
907     $x = (1, 2, @y);
908     print "x = $x\n";
909
910     # Perl4 prints:  x = c   # Thinks list context interpolates list
911     # Perl5 prints:  x = 3   # Knows scalar uses length of list
912
913 =item * (list, builtin)
914
915 C<sprintf()> funkiness (array argument converted to scalar array count)
916 This test could be added to t/op/sprintf.t
917
918     @z = ('%s%s', 'foo', 'bar');
919     $x = sprintf(@z);
920     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
921
922     # perl4 prints: ok 2
923     # perl5 prints: not ok 2
924
925 C<printf()> works fine, though:
926
927     printf STDOUT (@z);
928     print "\n";
929
930     # perl4 prints: foobar
931     # perl5 prints: foobar
932
933 Probably a bug.
934
935 =back
936
937 =head2 Precedence Traps
938
939 Perl4-to-Perl5 traps involving precedence order.
940
941 Perl 4 has almost the same precedence rules as Perl 5 for the operators
942 that they both have.  Perl 4 however, seems to have had some
943 inconsistencies that made the behavior differ from what was documented.
944
945 =over 5
946
947 =item * Precedence
948
949 LHS vs. RHS of any assignment operator.  LHS is evaluated first
950 in perl4, second in perl5; this can affect the relationship
951 between side-effects in sub-expressions.
952
953     @arr = ( 'left', 'right' );
954     $a{shift @arr} = shift @arr;
955     print join( ' ', keys %a );
956
957     # perl4 prints: left
958     # perl5 prints: right
959
960 =item * Precedence
961
962 These are now semantic errors because of precedence:
963
964     @list = (1,2,3,4,5);
965     %map = ("a",1,"b",2,"c",3,"d",4);
966     $n = shift @list + 2;   # first item in list plus 2
967     print "n is $n, ";
968     $m = keys %map + 2;     # number of items in hash plus 2
969     print "m is $m\n";
970
971     # perl4 prints: n is 3, m is 6
972     # perl5 errors and fails to compile
973
974 =item * Precedence
975
976 The precedence of assignment operators is now the same as the precedence
977 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
978 operator.  So you now must parenthesize them in expressions like
979
980     /foo/ ? ($a += 2) : ($a -= 2);
981
982 Otherwise
983
984     /foo/ ? $a += 2 : $a -= 2
985
986 would be erroneously parsed as
987
988     (/foo/ ? $a += 2 : $a) -= 2;
989
990 On the other hand,
991
992     $a += /foo/ ? 1 : 2;
993
994 now works as a C programmer would expect.
995
996 =item * Precedence
997
998     open FOO || die;
999
1000 is now incorrect.  You need parentheses around the filehandle.
1001 Otherwise, perl5 leaves the statement as its default precedence:
1002
1003     open(FOO || die);
1004
1005     # perl4 opens or dies
1006     # perl5 errors: Precedence problem: open FOO should be open(FOO)
1007
1008 =item * Precedence
1009
1010 perl4 gives the special variable, C<$:> precedence, where perl5
1011 treats C<$::> as main C<package>
1012
1013     $a = "x"; print "$::a";
1014
1015     # perl 4 prints: -:a
1016     # perl 5 prints: x
1017
1018 =item * Precedence
1019
1020 perl4 had buggy precedence for the file test operators vis-a-vis
1021 the assignment operators.  Thus, although the precedence table
1022 for perl4 leads one to believe C<-e $foo .= "q"> should parse as
1023 C<((-e $foo) .= "q")>, it actually parses as C<(-e ($foo .= "q"))>.
1024 In perl5, the precedence is as documented.
1025
1026     -e $foo .= "q"
1027
1028     # perl4 prints: no output
1029     # perl5 prints: Can't modify -e in concatenation
1030
1031 =item * Precedence
1032
1033 In perl4, keys(), each() and values() were special high-precedence operators
1034 that operated on a single hash, but in perl5, they are regular named unary
1035 operators.  As documented, named unary operators have lower precedence
1036 than the arithmetic and concatenation operators C<+ - .>, but the perl4
1037 variants of these operators actually bind tighter than C<+ - .>.
1038 Thus, for:
1039
1040     %foo = 1..10;
1041     print keys %foo - 1
1042
1043     # perl4 prints: 4
1044     # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)
1045
1046 The perl4 behavior was probably more useful, if less consistent.
1047
1048 =back
1049
1050 =head2 General Regular Expression Traps using s///, etc.
1051
1052 All types of RE traps.
1053
1054 =over 5
1055
1056 =item * Regular Expression
1057
1058 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1059 interpolate C<$lhs> but not C<$rhs>.  (And still does not match a literal
1060 '$' in string)
1061
1062     $a=1;$b=2;
1063     $string = '1 2 $a $b';
1064     $string =~ s'$a'$b';
1065     print $string,"\n";
1066
1067     # perl4 prints: $b 2 $a $b
1068     # perl5 prints: 1 2 $a $b
1069
1070 =item * Regular Expression
1071
1072 C<m//g> now attaches its state to the searched string rather than the
1073 regular expression.  (Once the scope of a block is left for the sub, the
1074 state of the searched string is lost)
1075
1076     $_ = "ababab";
1077     while(m/ab/g){
1078         &doit("blah");
1079     }
1080     sub doit{local($_) = shift; print "Got $_ "}
1081
1082     # perl4 prints: blah blah blah
1083     # perl5 prints: infinite loop blah...
1084
1085 =item * Regular Expression
1086
1087 Currently, if you use the C<m//o> qualifier on a regular expression
1088 within an anonymous sub, I<all> closures generated from that anonymous
1089 sub will use the regular expression as it was compiled when it was used
1090 the very first time in any such closure.  For instance, if you say
1091
1092     sub build_match {
1093         my($left,$right) = @_;
1094         return sub { $_[0] =~ /$left stuff $right/o; };
1095     }
1096
1097 build_match() will always return a sub which matches the contents of
1098 C<$left> and C<$right> as they were the I<first> time that build_match()
1099 was called, not as they are in the current call.
1100
1101 This is probably a bug, and may change in future versions of Perl.
1102
1103 =item * Regular Expression
1104
1105 If no parentheses are used in a match, Perl4 sets C<$+> to
1106 the whole match, just like C<$&>. Perl5 does not.
1107
1108     "abcdef" =~ /b.*e/;
1109     print "\$+ = $+\n";
1110
1111     # perl4 prints: bcde
1112     # perl5 prints:
1113
1114 =item * Regular Expression
1115
1116 substitution now returns the null string if it fails
1117
1118     $string = "test";
1119     $value = ($string =~ s/foo//);
1120     print $value, "\n";
1121
1122     # perl4 prints: 0
1123     # perl5 prints:
1124
1125 Also see L<Numerical Traps> for another example of this new feature.
1126
1127 =item * Regular Expression
1128
1129 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1130 backtick expansion
1131
1132     $string = "";
1133     $string =~ s`^`hostname`;
1134     print $string, "\n";
1135
1136     # perl4 prints: <the local hostname>
1137     # perl5 prints: hostname
1138
1139 =item * Regular Expression
1140
1141 Stricter parsing of variables used in regular expressions
1142
1143     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1144
1145     # perl4: compiles w/o error
1146     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1147
1148 an added component of this example, apparently from the same script, is
1149 the actual value of the s'd string after the substitution.
1150 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1151
1152     $grpc = 'a';
1153     $opt  = 'r';
1154     $_ = 'bar';
1155     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1156     print ;
1157
1158     # perl4 prints: foo
1159     # perl5 prints: foobar
1160
1161 =item * Regular Expression
1162
1163 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1164 repeatedly, like C</x/> or C<m!x!>.
1165
1166     $test = "once";
1167     sub match { $test =~ m?once?; }
1168     &match();
1169     if( &match() ) {
1170         # m?x? matches more then once
1171         print "perl4\n";
1172     } else {
1173         # m?x? matches only once
1174         print "perl5\n";
1175     }
1176
1177     # perl4 prints: perl4
1178     # perl5 prints: perl5
1179
1180
1181 =back
1182
1183 =head2 Subroutine, Signal, Sorting Traps
1184
1185 The general group of Perl4-to-Perl5 traps having to do with
1186 Signals, Sorting, and their related subroutines, as well as
1187 general subroutine traps.  Includes some OS-Specific traps.
1188
1189 =over 5
1190
1191 =item * (Signals)
1192
1193 Barewords that used to look like strings to Perl will now look like subroutine
1194 calls if a subroutine by that name is defined before the compiler sees them.
1195
1196     sub SeeYa { warn"Hasta la vista, baby!" }
1197     $SIG{'TERM'} = SeeYa;
1198     print "SIGTERM is now $SIG{'TERM'}\n";
1199
1200     # perl4 prints: SIGTERM is main'SeeYa
1201     # perl5 prints: SIGTERM is now main::1
1202
1203 Use B<-w> to catch this one
1204
1205 =item * (Sort Subroutine)
1206
1207 reverse is no longer allowed as the name of a sort subroutine.
1208
1209     sub reverse{ print "yup "; $a <=> $b }
1210     print sort reverse a,b,c;
1211
1212     # perl4 prints: yup yup yup yup abc
1213     # perl5 prints: abc
1214
1215 =item * warn() won't let you specify a filehandle.
1216
1217 Although it _always_ printed to STDERR, warn() would let you specify a
1218 filehandle in perl4.  With perl5 it does not.
1219
1220     warn STDERR "Foo!";
1221
1222     # perl4 prints: Foo!
1223     # perl5 prints: String found where operator expected
1224
1225 =back
1226
1227 =head2 OS Traps
1228
1229 =over 5
1230
1231 =item * (SysV)
1232
1233 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1234 within  the signal handler function, each time a signal was handled with
1235 perl4.  With perl5, the reset is now done correctly.  Any code relying
1236 on the handler _not_ being reset will have to be reworked.
1237
1238 Since version 5.002, Perl uses sigaction() under SysV.
1239
1240     sub gotit {
1241         print "Got @_... ";
1242     }
1243     $SIG{'INT'} = 'gotit';
1244
1245     $| = 1;
1246     $pid = fork;
1247     if ($pid) {
1248         kill('INT', $pid);
1249         sleep(1);
1250         kill('INT', $pid);
1251     } else {
1252         while (1) {sleep(10);}
1253     }
1254
1255     # perl4 (HPUX) prints: Got INT...
1256     # perl5 (HPUX) prints: Got INT... Got INT...
1257
1258 =item * (SysV)
1259
1260 Under SysV OSes, C<seek()> on a file opened to append C<E<gt>E<gt>> now does
1261 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1262 for append,  it  is  impossible to overwrite information already in
1263 the file.
1264
1265     open(TEST,">>seek.test");
1266     $start = tell TEST ;
1267     foreach(1 .. 9){
1268         print TEST "$_ ";
1269     }
1270     $end = tell TEST ;
1271     seek(TEST,$start,0);
1272     print TEST "18 characters here";
1273
1274     # perl4 (solaris) seek.test has: 18 characters here
1275     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1276
1277
1278
1279 =back
1280
1281 =head2 Interpolation Traps
1282
1283 Perl4-to-Perl5 traps having to do with how things get interpolated
1284 within certain expressions, statements, contexts, or whatever.
1285
1286 =over 5
1287
1288 =item * Interpolation
1289
1290 @ now always interpolates an array in double-quotish strings.
1291
1292     print "To: someone@somewhere.com\n";
1293
1294     # perl4 prints: To:someone@somewhere.com
1295     # perl5 errors : In string, @somewhere now must be written as \@somewhere
1296
1297 =item * Interpolation
1298
1299 Double-quoted strings may no longer end with an unescaped $ or @.
1300
1301     $foo = "foo$";
1302     $bar = "bar@";
1303     print "foo is $foo, bar is $bar\n";
1304
1305     # perl4 prints: foo is foo$, bar is bar@
1306     # perl5 errors: Final $ should be \$ or $name
1307
1308 Note: perl5 DOES NOT error on the terminating @ in $bar
1309
1310 =item * Interpolation
1311
1312 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1313 within double quotes (usually when the opening brace is preceded by C<$>
1314 or C<@>).
1315
1316     @www = "buz";
1317     $foo = "foo";
1318     $bar = "bar";
1319     sub foo { return "bar" };
1320     print "|@{w.w.w}|${main'foo}|";
1321
1322     # perl4 prints: |@{w.w.w}|foo|
1323     # perl5 prints: |buz|bar|
1324
1325 Note that you can C<use strict;> to ward off such trappiness under perl5.
1326
1327 =item * Interpolation
1328
1329 The construct "this is $$x" used to interpolate the pid at that
1330 point, but now apparently tries to dereference C<$x>.  C<$$> by itself still
1331 works fine, however.
1332
1333     print "this is $$x\n";
1334
1335     # perl4 prints: this is XXXx   (XXX is the current pid)
1336     # perl5 prints: this is
1337
1338 =item * Interpolation
1339
1340 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1341 C<$>'s to be protected in the specification of the hash name, or both curlies
1342 to be protected.  If both curlies are protected, the result will be compatible
1343 with perl4 and perl5.  This is a very common practice, and should be changed
1344 to use the block form of C<eval{}>  if possible.
1345
1346     $hashname = "foobar";
1347     $key = "baz";
1348     $value = 1234;
1349     eval "\$$hashname{'$key'} = q|$value|";
1350     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1351
1352     # perl4 prints: Yup
1353     # perl5 prints: Nope
1354
1355 Changing
1356
1357     eval "\$$hashname{'$key'} = q|$value|";
1358
1359 to
1360
1361     eval "\$\$hashname{'$key'} = q|$value|";
1362
1363 causes the following result:
1364
1365     # perl4 prints: Nope
1366     # perl5 prints: Yup
1367
1368 or, changing to
1369
1370     eval "\$$hashname\{'$key'\} = q|$value|";
1371
1372 causes the following result:
1373
1374     # perl4 prints: Yup
1375     # perl5 prints: Yup
1376     # and is compatible for both versions
1377
1378
1379 =item * Interpolation
1380
1381 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1382
1383     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1384
1385     # perl4 prints: This is not perl5
1386     # perl5 prints: This is perl5
1387
1388 =item * Interpolation
1389
1390 You also have to be careful about array references.
1391
1392     print "$foo{"
1393
1394     perl 4 prints: {
1395     perl 5 prints: syntax error
1396
1397 =item * Interpolation
1398
1399 Similarly, watch out for:
1400
1401     $foo = "array";
1402     print "\$$foo{bar}\n";
1403
1404     # perl4 prints: $array{bar}
1405     # perl5 prints: $
1406
1407 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1408 happy just to expand $foo to "array" by itself.  Watch out for this
1409 especially in C<eval>'s.
1410
1411 =item * Interpolation
1412
1413 C<qq()> string passed to C<eval>
1414
1415     eval qq(
1416         foreach \$y (keys %\$x\) {
1417             \$count++;
1418         }
1419     );
1420
1421     # perl4 runs this ok
1422     # perl5 prints: Can't find string terminator ")"
1423
1424 =back
1425
1426 =head2 DBM Traps
1427
1428 General DBM traps.
1429
1430 =over 5
1431
1432 =item * DBM
1433
1434 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1435 may cause the same script, run under perl5, to fail.  The build of perl5
1436 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1437 to function properly without C<tie>'ing to an extension dbm implementation.
1438
1439     dbmopen (%dbm, "file", undef);
1440     print "ok\n";
1441
1442     # perl4 prints: ok
1443     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1444
1445
1446 =item * DBM
1447
1448 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1449 may cause the same script, run under perl5, to fail.  The error generated
1450 when exceeding the limit on the key/value size will cause perl5 to exit
1451 immediately.
1452
1453     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1454     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1455     print "YUP\n";
1456
1457     # perl4 prints:
1458     dbm store returned -1, errno 28, key "trap" at - line 3.
1459     YUP
1460
1461     # perl5 prints:
1462     dbm store returned -1, errno 28, key "trap" at - line 3.
1463
1464 =back
1465
1466 =head2 Unclassified Traps
1467
1468 Everything else.
1469
1470 =over 5
1471
1472 =item * C<require>/C<do> trap using returned value
1473
1474 If the file doit.pl has:
1475
1476     sub foo {
1477         $rc = do "./do.pl";
1478         return 8;
1479     }
1480     print &foo, "\n";
1481
1482 And the do.pl file has the following single line:
1483
1484     return 3;
1485
1486 Running doit.pl gives the following:
1487
1488     # perl 4 prints: 3 (aborts the subroutine early)
1489     # perl 5 prints: 8
1490
1491 Same behavior if you replace C<do> with C<require>.
1492
1493 =item * C<split> on empty string with LIMIT specified
1494
1495         $string = '';
1496     @list = split(/foo/, $string, 2)
1497
1498 Perl4 returns a one element list containing the empty string but Perl5
1499 returns an empty list.
1500
1501 =back
1502
1503 As always, if any of these are ever officially declared as bugs,
1504 they'll be fixed and removed.
1505