This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add ampersand to share.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     $CommandSet
631     $CreateTTY
632     $DBGR
633     @dbline
634     $dbline
635     %dbline
636     $dieLevel
637     $filename
638     $histfile
639     $histsize
640     $IN
641     $inhibit_exit
642     @ini_INC
643     $ini_warn
644     $maxtrace
645     $od
646     $onetimedumpDepth
647     @options
648     $osingle
649     $otrace
650     $pager
651     $post
652     %postponed
653     $prc
654     $pre
655     $pretype
656     $psh
657     @RememberOnROptions
658     $remoteport
659     @res
660     $rl
661     @saved
662     $signalLevel
663     $sub
664     $term
665     $usercontext
666     $warnLevel
667 );
668
669 our (
670     @cmdfhs,
671     $evalarg,
672     $frame,
673     $hist,
674     $ImmediateStop,
675     $line,
676     $onetimeDump,
677     %option,
678     $OUT,
679     $packname,
680     $signal,
681     $single,
682     $start,
683     %sub,
684     $subname,
685     $trace,
686     $window,
687 );
688
689 # Used to save @ARGV and extract any debugger-related flags.
690 use vars qw(@ARGS);
691
692 # Used to prevent multiple entries to diesignal()
693 # (if for instance diesignal() itself dies)
694 use vars qw($panic);
695
696 # Used to prevent the debugger from running nonstop
697 # after a restart
698 our ($second_time);
699
700 sub _calc_usercontext {
701     my ($package) = @_;
702
703     # Cancel strict completely for the evaluated code, so the code
704     # the user evaluates won't be affected by it. (Shlomi Fish)
705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
706     . "package $package;";    # this won't let them modify, alas
707 }
708
709 sub eval {
710
711     # 'my' would make it visible from user code
712     #    but so does local! --tchrist
713     # Remember: this localizes @DB::res, not @main::res.
714     local @res;
715     {
716
717         # Try to keep the user code from messing  with us. Save these so that
718         # even if the eval'ed code changes them, we can put them back again.
719         # Needed because the user could refer directly to the debugger's
720         # package globals (and any 'my' variables in this containing scope)
721         # inside the eval(), and we want to try to stay safe.
722         local $otrace  = $trace;
723         local $osingle = $single;
724         local $od      = $^D;
725
726         # Untaint the incoming eval() argument.
727         { ($evalarg) = $evalarg =~ /(.*)/s; }
728
729         # $usercontext built in DB::DB near the comment
730         # "set up the context for DB::eval ..."
731         # Evaluate and save any results.
732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
733
734         # Restore those old values.
735         $trace  = $otrace;
736         $single = $osingle;
737         $^D     = $od;
738     }
739
740     # Save the current value of $@, and preserve it in the debugger's copy
741     # of the saved precious globals.
742     my $at = $@;
743
744     # Since we're only saving $@, we only have to localize the array element
745     # that it will be stored in.
746     local $saved[0];    # Preserve the old value of $@
747     eval { DB::save() };
748
749     # Now see whether we need to report an error back to the user.
750     if ($at) {
751         local $\ = '';
752         print $OUT $at;
753     }
754
755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
756     # are package globals.
757     elsif ($onetimeDump) {
758         if ( $onetimeDump eq 'dump' ) {
759             local $option{dumpDepth} = $onetimedumpDepth
760               if defined $onetimedumpDepth;
761             dumpit( $OUT, \@res );
762         }
763         elsif ( $onetimeDump eq 'methods' ) {
764             methods( $res[0] );
765         }
766     } ## end elsif ($onetimeDump)
767     @res;
768 } ## end sub eval
769
770 ############################################## End lexical danger zone
771
772 # After this point it is safe to introduce lexicals.
773 # The code being debugged will be executing in its own context, and
774 # can't see the inside of the debugger.
775 #
776 # However, one should not overdo it: leave as much control from outside as
777 # possible. If you make something a lexical, it's not going to be addressable
778 # from outside the debugger even if you know its name.
779
780 # This file is automatically included if you do perl -d.
781 # It's probably not useful to include this yourself.
782 #
783 # Before venturing further into these twisty passages, it is
784 # wise to read the perldebguts man page or risk the ire of dragons.
785 #
786 # (It should be noted that perldebguts will tell you a lot about
787 # the underlying mechanics of how the debugger interfaces into the
788 # Perl interpreter, but not a lot about the debugger itself. The new
789 # comments in this code try to address this problem.)
790
791 # Note that no subroutine call is possible until &DB::sub is defined
792 # (for subroutines defined outside of the package DB). In fact the same is
793 # true if $deep is not defined.
794
795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
796
797 # modified Perl debugger, to be run from Emacs in perldb-mode
798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
799 # Johan Vromans -- upgrade to 4.0 pl 10
800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
801 ########################################################################
802
803 =head1 DEBUGGER INITIALIZATION
804
805 The debugger starts up in phases.
806
807 =head2 BASIC SETUP
808
809 First, it initializes the environment it wants to run in: turning off
810 warnings during its own compilation, defining variables which it will need
811 to avoid warnings later, setting itself up to not exit when the program
812 terminates, and defaulting to printing return values for the C<r> command.
813
814 =cut
815
816 # Needed for the statement after exec():
817 #
818 # This BEGIN block is simply used to switch off warnings during debugger
819 # compilation. Probably it would be better practice to fix the warnings,
820 # but this is how it's done at the moment.
821
822 BEGIN {
823     $ini_warn = $^W;
824     $^W       = 0;
825 }    # Switch compilation warnings off until another BEGIN.
826
827 local ($^W) = 0;    # Switch run-time warnings off during init.
828
829 =head2 THREADS SUPPORT
830
831 If we are running under a threaded Perl, we require threads and threads::shared
832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
833 threaded debugger control.  C<-dt> can also be used to set this.
834
835 Each new thread will be announced and the debugger prompt will always inform
836 you of each new thread created.  It will also indicate the thread id in which
837 we are currently running within the prompt like this:
838
839     [tid] DB<$i>
840
841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
842 command prompt.  The prompt will show: C<[0]> when running under threads, but
843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
844
845 While running under threads, when you set or delete a breakpoint (etc.), this
846 will apply to all threads, not just the currently running one.  When you are
847 in a currently executing thread, you will stay there until it completes.  With
848 the current implementation it is not currently possible to hop from one thread
849 to another.
850
851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
852
853 Note that threading support was built into the debugger as of Perl version
854 C<5.8.6> and debugger version C<1.2.8>.
855
856 =cut
857
858 BEGIN {
859     # ensure we can share our non-threaded variables or no-op
860     if ($ENV{PERL5DB_THREADED}) {
861         require threads;
862         require threads::shared;
863         import threads::shared qw(share);
864         $DBGR;
865         share(\$DBGR);
866         lock($DBGR);
867         print "Threads support enabled\n";
868     } else {
869         *lock  = sub(*) {};
870         *share = sub(*) {};
871     }
872 }
873
874 # These variables control the execution of 'dumpvar.pl'.
875 {
876     package dumpvar;
877     use vars qw(
878     $hashDepth
879     $arrayDepth
880     $dumpDBFiles
881     $dumpPackages
882     $quoteHighBit
883     $printUndef
884     $globPrint
885     $usageOnly
886     );
887 }
888
889 # used to control die() reporting in diesignal()
890 {
891     package Carp;
892     use vars qw($CarpLevel);
893 }
894
895 # without threads, $filename is not defined until DB::DB is called
896 # We need the & here because we want to override the prototype.
897 &share(\$main::{'_<'.$filename}) if defined $filename;
898
899 # Command-line + PERLLIB:
900 # Save the contents of @INC before they are modified elsewhere.
901 @ini_INC = @INC;
902
903 # This was an attempt to clear out the previous values of various
904 # trapped errors. Apparently it didn't help. XXX More info needed!
905 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
906
907 # We set these variables to safe values. We don't want to blindly turn
908 # off warnings, because other packages may still want them.
909 $trace = $signal = $single = 0;    # Uninitialized warning suppression
910                                    # (local $^W cannot help - other packages!).
911
912 # Default to not exiting when program finishes; print the return
913 # value when the 'r' command is used to return from a subroutine.
914 $inhibit_exit = $option{PrintRet} = 1;
915
916 use vars qw($trace_to_depth);
917
918 # Default to 1E9 so it won't be limited to a certain recursion depth.
919 $trace_to_depth = 1E9;
920
921 =head1 OPTION PROCESSING
922
923 The debugger's options are actually spread out over the debugger itself and
924 C<dumpvar.pl>; some of these are variables to be set, while others are
925 subs to be called with a value. To try to make this a little easier to
926 manage, the debugger uses a few data structures to define what options
927 are legal and how they are to be processed.
928
929 First, the C<@options> array defines the I<names> of all the options that
930 are to be accepted.
931
932 =cut
933
934 @options = qw(
935   CommandSet   HistFile      HistSize
936   hashDepth    arrayDepth    dumpDepth
937   DumpDBFiles  DumpPackages  DumpReused
938   compactDump  veryCompact   quote
939   HighBit      undefPrint    globPrint
940   PrintRet     UsageOnly     frame
941   AutoTrace    TTY           noTTY
942   ReadLine     NonStop       LineInfo
943   maxTraceLen  recallCommand ShellBang
944   pager        tkRunning     ornaments
945   signalLevel  warnLevel     dieLevel
946   inhibit_exit ImmediateStop bareStringify
947   CreateTTY    RemotePort    windowSize
948   DollarCaretP
949 );
950
951 @RememberOnROptions = qw(DollarCaretP);
952
953 =pod
954
955 Second, C<optionVars> lists the variables that each option uses to save its
956 state.
957
958 =cut
959
960 use vars qw(%optionVars);
961
962 %optionVars = (
963     hashDepth     => \$dumpvar::hashDepth,
964     arrayDepth    => \$dumpvar::arrayDepth,
965     CommandSet    => \$CommandSet,
966     DumpDBFiles   => \$dumpvar::dumpDBFiles,
967     DumpPackages  => \$dumpvar::dumpPackages,
968     DumpReused    => \$dumpvar::dumpReused,
969     HighBit       => \$dumpvar::quoteHighBit,
970     undefPrint    => \$dumpvar::printUndef,
971     globPrint     => \$dumpvar::globPrint,
972     UsageOnly     => \$dumpvar::usageOnly,
973     CreateTTY     => \$CreateTTY,
974     bareStringify => \$dumpvar::bareStringify,
975     frame         => \$frame,
976     AutoTrace     => \$trace,
977     inhibit_exit  => \$inhibit_exit,
978     maxTraceLen   => \$maxtrace,
979     ImmediateStop => \$ImmediateStop,
980     RemotePort    => \$remoteport,
981     windowSize    => \$window,
982     HistFile      => \$histfile,
983     HistSize      => \$histsize,
984 );
985
986 =pod
987
988 Third, C<%optionAction> defines the subroutine to be called to process each
989 option.
990
991 =cut
992
993 use vars qw(%optionAction);
994
995 %optionAction = (
996     compactDump   => \&dumpvar::compactDump,
997     veryCompact   => \&dumpvar::veryCompact,
998     quote         => \&dumpvar::quote,
999     TTY           => \&TTY,
1000     noTTY         => \&noTTY,
1001     ReadLine      => \&ReadLine,
1002     NonStop       => \&NonStop,
1003     LineInfo      => \&LineInfo,
1004     recallCommand => \&recallCommand,
1005     ShellBang     => \&shellBang,
1006     pager         => \&pager,
1007     signalLevel   => \&signalLevel,
1008     warnLevel     => \&warnLevel,
1009     dieLevel      => \&dieLevel,
1010     tkRunning     => \&tkRunning,
1011     ornaments     => \&ornaments,
1012     RemotePort    => \&RemotePort,
1013     DollarCaretP  => \&DollarCaretP,
1014 );
1015
1016 =pod
1017
1018 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1019 option is used.
1020
1021 =cut
1022
1023 # Note that this list is not complete: several options not listed here
1024 # actually require that dumpvar.pl be loaded for them to work, but are
1025 # not in the table. A subsequent patch will correct this problem; for
1026 # the moment, we're just recommenting, and we are NOT going to change
1027 # function.
1028 use vars qw(%optionRequire);
1029
1030 %optionRequire = (
1031     compactDump => 'dumpvar.pl',
1032     veryCompact => 'dumpvar.pl',
1033     quote       => 'dumpvar.pl',
1034 );
1035
1036 =pod
1037
1038 There are a number of initialization-related variables which can be set
1039 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1040 variable. These are:
1041
1042 =over 4
1043
1044 =item C<$rl> - readline control XXX needs more explanation
1045
1046 =item C<$warnLevel> - whether or not debugger takes over warning handling
1047
1048 =item C<$dieLevel> - whether or not debugger takes over die handling
1049
1050 =item C<$signalLevel> - whether or not debugger takes over signal handling
1051
1052 =item C<$pre> - preprompt actions (array reference)
1053
1054 =item C<$post> - postprompt actions (array reference)
1055
1056 =item C<$pretype>
1057
1058 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1059
1060 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1061
1062 =back
1063
1064 =cut
1065
1066 # These guys may be defined in $ENV{PERL5DB} :
1067 $rl          = 1     unless defined $rl;
1068 $warnLevel   = 1     unless defined $warnLevel;
1069 $dieLevel    = 1     unless defined $dieLevel;
1070 $signalLevel = 1     unless defined $signalLevel;
1071 $pre         = []    unless defined $pre;
1072 $post        = []    unless defined $post;
1073 $pretype     = []    unless defined $pretype;
1074 $CreateTTY   = 3     unless defined $CreateTTY;
1075 $CommandSet  = '580' unless defined $CommandSet;
1076
1077 share($rl);
1078 share($warnLevel);
1079 share($dieLevel);
1080 share($signalLevel);
1081 share($pre);
1082 share($post);
1083 share($pretype);
1084 share($rl);
1085 share($CreateTTY);
1086 share($CommandSet);
1087
1088 =pod
1089
1090 The default C<die>, C<warn>, and C<signal> handlers are set up.
1091
1092 =cut
1093
1094 warnLevel($warnLevel);
1095 dieLevel($dieLevel);
1096 signalLevel($signalLevel);
1097
1098 =pod
1099
1100 The pager to be used is needed next. We try to get it from the
1101 environment first.  If it's not defined there, we try to find it in
1102 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1103 then call the C<pager()> function to save the pager name.
1104
1105 =cut
1106
1107 # This routine makes sure $pager is set up so that '|' can use it.
1108 pager(
1109
1110     # If PAGER is defined in the environment, use it.
1111     defined $ENV{PAGER}
1112     ? $ENV{PAGER}
1113
1114       # If not, see if Config.pm defines it.
1115     : eval { require Config }
1116       && defined $Config::Config{pager}
1117     ? $Config::Config{pager}
1118
1119       # If not, fall back to 'more'.
1120     : 'more'
1121   )
1122   unless defined $pager;
1123
1124 =pod
1125
1126 We set up the command to be used to access the man pages, the command
1127 recall character (C<!> unless otherwise defined) and the shell escape
1128 character (C<!> unless otherwise defined). Yes, these do conflict, and
1129 neither works in the debugger at the moment.
1130
1131 =cut
1132
1133 setman();
1134
1135 # Set up defaults for command recall and shell escape (note:
1136 # these currently don't work in linemode debugging).
1137 recallCommand("!") unless defined $prc;
1138 shellBang("!")     unless defined $psh;
1139
1140 =pod
1141
1142 We then set up the gigantic string containing the debugger help.
1143 We also set the limit on the number of arguments we'll display during a
1144 trace.
1145
1146 =cut
1147
1148 sethelp();
1149
1150 # If we didn't get a default for the length of eval/stack trace args,
1151 # set it here.
1152 $maxtrace = 400 unless defined $maxtrace;
1153
1154 =head2 SETTING UP THE DEBUGGER GREETING
1155
1156 The debugger I<greeting> helps to inform the user how many debuggers are
1157 running, and whether the current debugger is the primary or a child.
1158
1159 If we are the primary, we just hang onto our pid so we'll have it when
1160 or if we start a child debugger. If we are a child, we'll set things up
1161 so we'll have a unique greeting and so the parent will give us our own
1162 TTY later.
1163
1164 We save the current contents of the C<PERLDB_PIDS> environment variable
1165 because we mess around with it. We'll also need to hang onto it because
1166 we'll need it if we restart.
1167
1168 Child debuggers make a label out of the current PID structure recorded in
1169 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1170 yet so the parent will give them one later via C<resetterm()>.
1171
1172 =cut
1173
1174 # Save the current contents of the environment; we're about to
1175 # much with it. We'll need this if we have to restart.
1176 use vars qw($ini_pids);
1177 $ini_pids = $ENV{PERLDB_PIDS};
1178
1179 use vars qw ($pids $term_pid);
1180
1181 if ( defined $ENV{PERLDB_PIDS} ) {
1182
1183     # We're a child. Make us a label out of the current PID structure
1184     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1185     # a term yet so the parent will give us one later via resetterm().
1186
1187     my $env_pids = $ENV{PERLDB_PIDS};
1188     $pids = "[$env_pids]";
1189
1190     # Unless we are on OpenVMS, all programs under the DCL shell run under
1191     # the same PID.
1192
1193     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1194         $term_pid         = $$;
1195     }
1196     else {
1197         $ENV{PERLDB_PIDS} .= "->$$";
1198         $term_pid = -1;
1199     }
1200
1201 } ## end if (defined $ENV{PERLDB_PIDS...
1202 else {
1203
1204     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1205     # child debugger, and mark us as the parent, so we'll know to set up
1206     # more TTY's is we have to.
1207     $ENV{PERLDB_PIDS} = "$$";
1208     $pids             = "[pid=$$]";
1209     $term_pid         = $$;
1210 }
1211
1212 use vars qw($pidprompt);
1213 $pidprompt = '';
1214
1215 # Sets up $emacs as a synonym for $slave_editor.
1216 our ($slave_editor);
1217 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1218
1219 =head2 READING THE RC FILE
1220
1221 The debugger will read a file of initialization options if supplied. If
1222 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1223
1224 =cut
1225
1226 # As noted, this test really doesn't check accurately that the debugger
1227 # is running at a terminal or not.
1228
1229 use vars qw($rcfile);
1230 {
1231     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1232     # this is the wrong metric!
1233     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1234 }
1235
1236 =pod
1237
1238 The debugger does a safety test of the file to be read. It must be owned
1239 either by the current user or root, and must only be writable by the owner.
1240
1241 =cut
1242
1243 # This wraps a safety test around "do" to read and evaluate the init file.
1244 #
1245 # This isn't really safe, because there's a race
1246 # between checking and opening.  The solution is to
1247 # open and fstat the handle, but then you have to read and
1248 # eval the contents.  But then the silly thing gets
1249 # your lexical scope, which is unfortunate at best.
1250 sub safe_do {
1251     my $file = shift;
1252
1253     # Just exactly what part of the word "CORE::" don't you understand?
1254     local $SIG{__WARN__};
1255     local $SIG{__DIE__};
1256
1257     unless ( is_safe_file($file) ) {
1258         CORE::warn <<EO_GRIPE;
1259 perldb: Must not source insecure rcfile $file.
1260         You or the superuser must be the owner, and it must not
1261         be writable by anyone but its owner.
1262 EO_GRIPE
1263         return;
1264     } ## end unless (is_safe_file($file...
1265
1266     do $file;
1267     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1268 } ## end sub safe_do
1269
1270 # This is the safety test itself.
1271 #
1272 # Verifies that owner is either real user or superuser and that no
1273 # one but owner may write to it.  This function is of limited use
1274 # when called on a path instead of upon a handle, because there are
1275 # no guarantees that filename (by dirent) whose file (by ino) is
1276 # eventually accessed is the same as the one tested.
1277 # Assumes that the file's existence is not in doubt.
1278 sub is_safe_file {
1279     my $path = shift;
1280     stat($path) || return;    # mysteriously vaporized
1281     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1282
1283     return 0 if $uid != 0 && $uid != $<;
1284     return 0 if $mode & 022;
1285     return 1;
1286 } ## end sub is_safe_file
1287
1288 # If the rcfile (whichever one we decided was the right one to read)
1289 # exists, we safely do it.
1290 if ( -f $rcfile ) {
1291     safe_do("./$rcfile");
1292 }
1293
1294 # If there isn't one here, try the user's home directory.
1295 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1296     safe_do("$ENV{HOME}/$rcfile");
1297 }
1298
1299 # Else try the login directory.
1300 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1301     safe_do("$ENV{LOGDIR}/$rcfile");
1302 }
1303
1304 # If the PERLDB_OPTS variable has options in it, parse those out next.
1305 if ( defined $ENV{PERLDB_OPTS} ) {
1306     parse_options( $ENV{PERLDB_OPTS} );
1307 }
1308
1309 =pod
1310
1311 The last thing we do during initialization is determine which subroutine is
1312 to be used to obtain a new terminal when a new debugger is started. Right now,
1313 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1314 (darwin).
1315
1316 =cut
1317
1318 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1319 # Works if you're running an xterm or xterm-like window, or you're on
1320 # OS/2, or on Mac OS X. This may need some expansion.
1321
1322 if (not defined &get_fork_TTY)       # only if no routine exists
1323 {
1324     if ( defined $remoteport ) {
1325                                                  # Expect an inetd-like server
1326         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1327     }
1328     elsif (defined $ENV{TERM}                    # If we know what kind
1329                                                  # of terminal this is,
1330         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1331         and defined $ENV{DISPLAY}                # and what display it's on,
1332       )
1333     {
1334         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1335     }
1336     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1337         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1338     }
1339     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1340             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1341             and $ENV{TERM_PROGRAM}
1342                 eq 'Apple_Terminal'              # Terminal.app
1343             )
1344     {
1345         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1346     }
1347 } ## end if (not defined &get_fork_TTY...
1348
1349 # untaint $^O, which may have been tainted by the last statement.
1350 # see bug [perl #24674]
1351 $^O =~ m/^(.*)\z/;
1352 $^O = $1;
1353
1354 # Here begin the unreadable code.  It needs fixing.
1355
1356 =head2 RESTART PROCESSING
1357
1358 This section handles the restart command. When the C<R> command is invoked, it
1359 tries to capture all of the state it can into environment variables, and
1360 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1361 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1362 the R command stuffed into the environment variables.
1363
1364   PERLDB_RESTART   - flag only, contains no restart data itself.
1365   PERLDB_HIST      - command history, if it's available
1366   PERLDB_ON_LOAD   - breakpoints set by the rc file
1367   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1368   PERLDB_VISITED   - files that had breakpoints
1369   PERLDB_FILE_...  - breakpoints for a file
1370   PERLDB_OPT       - active options
1371   PERLDB_INC       - the original @INC
1372   PERLDB_PRETYPE   - preprompt debugger actions
1373   PERLDB_PRE       - preprompt Perl code
1374   PERLDB_POST      - post-prompt Perl code
1375   PERLDB_TYPEAHEAD - typeahead captured by readline()
1376
1377 We chug through all these variables and plug the values saved in them
1378 back into the appropriate spots in the debugger.
1379
1380 =cut
1381
1382 use vars qw(%postponed_file @typeahead);
1383
1384 our (@hist, @truehist);
1385
1386 sub _restore_shared_globals_after_restart
1387 {
1388     @hist          = get_list('PERLDB_HIST');
1389     %break_on_load = get_list("PERLDB_ON_LOAD");
1390     %postponed     = get_list("PERLDB_POSTPONE");
1391
1392     share(@hist);
1393     share(@truehist);
1394     share(%break_on_load);
1395     share(%postponed);
1396 }
1397
1398 sub _restore_breakpoints_and_actions {
1399
1400     my @had_breakpoints = get_list("PERLDB_VISITED");
1401
1402     for my $file_idx ( 0 .. $#had_breakpoints ) {
1403         my $filename = $had_breakpoints[$file_idx];
1404         my %pf = get_list("PERLDB_FILE_$file_idx");
1405         $postponed_file{ $filename } = \%pf if %pf;
1406         my @lines = sort {$a <=> $b} keys(%pf);
1407         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1408         for my $line_idx (0 .. $#lines) {
1409             _set_breakpoint_enabled_status(
1410                 $filename,
1411                 $lines[$line_idx],
1412                 ($enabled_statuses[$line_idx] ? 1 : ''),
1413             );
1414         }
1415     }
1416
1417     return;
1418 }
1419
1420 sub _restore_options_after_restart
1421 {
1422     my %options_map = get_list("PERLDB_OPT");
1423
1424     while ( my ( $opt, $val ) = each %options_map ) {
1425         $val =~ s/[\\\']/\\$1/g;
1426         parse_options("$opt'$val'");
1427     }
1428
1429     return;
1430 }
1431
1432 sub _restore_globals_after_restart
1433 {
1434     # restore original @INC
1435     @INC     = get_list("PERLDB_INC");
1436     @ini_INC = @INC;
1437
1438     # return pre/postprompt actions and typeahead buffer
1439     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1440     $pre       = [ get_list("PERLDB_PRE") ];
1441     $post      = [ get_list("PERLDB_POST") ];
1442     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1443
1444     return;
1445 }
1446
1447
1448 if ( exists $ENV{PERLDB_RESTART} ) {
1449
1450     # We're restarting, so we don't need the flag that says to restart anymore.
1451     delete $ENV{PERLDB_RESTART};
1452
1453     # $restart = 1;
1454     _restore_shared_globals_after_restart();
1455
1456     _restore_breakpoints_and_actions();
1457
1458     # restore options
1459     _restore_options_after_restart();
1460
1461     _restore_globals_after_restart();
1462 } ## end if (exists $ENV{PERLDB_RESTART...
1463
1464 =head2 SETTING UP THE TERMINAL
1465
1466 Now, we'll decide how the debugger is going to interact with the user.
1467 If there's no TTY, we set the debugger to run non-stop; there's not going
1468 to be anyone there to enter commands.
1469
1470 =cut
1471
1472 use vars qw($notty $console $tty $LINEINFO);
1473 use vars qw($lineinfo $doccmd);
1474
1475 our ($runnonstop);
1476
1477 if ($notty) {
1478     $runnonstop = 1;
1479     share($runnonstop);
1480 }
1481
1482 =pod
1483
1484 If there is a TTY, we have to determine who it belongs to before we can
1485 proceed. If this is a slave editor or graphical debugger (denoted by
1486 the first command-line switch being '-emacs'), we shift this off and
1487 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1488
1489 =cut
1490
1491 else {
1492
1493     # Is Perl being run from a slave editor or graphical debugger?
1494     # If so, don't use readline, and set $slave_editor = 1.
1495     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1496         $rl = 0;
1497         shift(@main::ARGV);
1498     }
1499
1500     #require Term::ReadLine;
1501
1502 =pod
1503
1504 We then determine what the console should be on various systems:
1505
1506 =over 4
1507
1508 =item * Cygwin - We use C<stdin> instead of a separate device.
1509
1510 =cut
1511
1512     if ( $^O eq 'cygwin' ) {
1513
1514         # /dev/tty is binary. use stdin for textmode
1515         undef $console;
1516     }
1517
1518 =item * Unix - use C</dev/tty>.
1519
1520 =cut
1521
1522     elsif ( -e "/dev/tty" ) {
1523         $console = "/dev/tty";
1524     }
1525
1526 =item * Windows or MSDOS - use C<con>.
1527
1528 =cut
1529
1530     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1531         $console = "con";
1532     }
1533
1534 =item * VMS - use C<sys$command>.
1535
1536 =cut
1537
1538     else {
1539
1540         # everything else is ...
1541         $console = "sys\$command";
1542     }
1543
1544 =pod
1545
1546 =back
1547
1548 Several other systems don't use a specific console. We C<undef $console>
1549 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1550 with a slave editor, Epoc).
1551
1552 =cut
1553
1554     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1555
1556         # /dev/tty is binary. use stdin for textmode
1557         $console = undef;
1558     }
1559
1560     if ( $^O eq 'NetWare' ) {
1561
1562         # /dev/tty is binary. use stdin for textmode
1563         $console = undef;
1564     }
1565
1566     # In OS/2, we need to use STDIN to get textmode too, even though
1567     # it pretty much looks like Unix otherwise.
1568     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1569     {    # In OS/2
1570         $console = undef;
1571     }
1572
1573     # EPOC also falls into the 'got to use STDIN' camp.
1574     if ( $^O eq 'epoc' ) {
1575         $console = undef;
1576     }
1577
1578 =pod
1579
1580 If there is a TTY hanging around from a parent, we use that as the console.
1581
1582 =cut
1583
1584     $console = $tty if defined $tty;
1585
1586 =head2 SOCKET HANDLING
1587
1588 The debugger is capable of opening a socket and carrying out a debugging
1589 session over the socket.
1590
1591 If C<RemotePort> was defined in the options, the debugger assumes that it
1592 should try to start a debugging session on that port. It builds the socket
1593 and then tries to connect the input and output filehandles to it.
1594
1595 =cut
1596
1597     # Handle socket stuff.
1598
1599     if ( defined $remoteport ) {
1600
1601         # If RemotePort was defined in the options, connect input and output
1602         # to the socket.
1603         $IN = $OUT = connect_remoteport();
1604     } ## end if (defined $remoteport)
1605
1606 =pod
1607
1608 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1609 this is probably a situation where multiple debuggers are running (for example,
1610 a backticked command that starts up another debugger). We create a new IN and
1611 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1612 and if we can.
1613
1614 =cut
1615
1616     # Non-socket.
1617     else {
1618
1619         # Two debuggers running (probably a system or a backtick that invokes
1620         # the debugger itself under the running one). create a new IN and OUT
1621         # filehandle, and do the necessary mojo to create a new tty if we
1622         # know how, and we can.
1623         create_IN_OUT(4) if $CreateTTY & 4;
1624         if ($console) {
1625
1626             # If we have a console, check to see if there are separate ins and
1627             # outs to open. (They are assumed identical if not.)
1628
1629             my ( $i, $o ) = split /,/, $console;
1630             $o = $i unless defined $o;
1631
1632             # read/write on in, or just read, or read on STDIN.
1633             open( IN,      "+<$i" )
1634               || open( IN, "<$i" )
1635               || open( IN, "<&STDIN" );
1636
1637             # read/write/create/clobber out, or write/create/clobber out,
1638             # or merge with STDERR, or merge with STDOUT.
1639                  open( OUT, "+>$o" )
1640               || open( OUT, ">$o" )
1641               || open( OUT, ">&STDERR" )
1642               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1643
1644         } ## end if ($console)
1645         elsif ( not defined $console ) {
1646
1647             # No console. Open STDIN.
1648             open( IN, "<&STDIN" );
1649
1650             # merge with STDERR, or with STDOUT.
1651             open( OUT,      ">&STDERR" )
1652               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1653             $console = 'STDIN/OUT';
1654         } ## end elsif (not defined $console)
1655
1656         # Keep copies of the filehandles so that when the pager runs, it
1657         # can close standard input without clobbering ours.
1658         if ($console or (not defined($console))) {
1659             $IN = \*IN;
1660             $OUT = \*OUT;
1661         }
1662     } ## end elsif (from if(defined $remoteport))
1663
1664     # Unbuffer DB::OUT. We need to see responses right away.
1665     $OUT->autoflush(1);
1666
1667     # Line info goes to debugger output unless pointed elsewhere.
1668     # Pointing elsewhere makes it possible for slave editors to
1669     # keep track of file and position. We have both a filehandle
1670     # and a I/O description to keep track of.
1671     $LINEINFO = $OUT     unless defined $LINEINFO;
1672     $lineinfo = $console unless defined $lineinfo;
1673     # share($LINEINFO); # <- unable to share globs
1674     share($lineinfo);   #
1675
1676 =pod
1677
1678 To finish initialization, we show the debugger greeting,
1679 and then call the C<afterinit()> subroutine if there is one.
1680
1681 =cut
1682
1683     # Show the debugger greeting.
1684     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1685     unless ($runnonstop) {
1686         local $\ = '';
1687         local $, = '';
1688         if ( $term_pid eq '-1' ) {
1689             print $OUT "\nDaughter DB session started...\n";
1690         }
1691         else {
1692             print $OUT "\nLoading DB routines from $header\n";
1693             print $OUT (
1694                 "Editor support ",
1695                 $slave_editor ? "enabled" : "available", ".\n"
1696             );
1697             print $OUT
1698 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1699         } ## end else [ if ($term_pid eq '-1')
1700     } ## end unless ($runnonstop)
1701 } ## end else [ if ($notty)
1702
1703 # XXX This looks like a bug to me.
1704 # Why copy to @ARGS and then futz with @args?
1705 @ARGS = @ARGV;
1706 # for (@args) {
1707     # Make sure backslashes before single quotes are stripped out, and
1708     # keep args unless they are numeric (XXX why?)
1709     # s/\'/\\\'/g;                      # removed while not justified understandably
1710     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1711 # }
1712
1713 # If there was an afterinit() sub defined, call it. It will get
1714 # executed in our scope, so it can fiddle with debugger globals.
1715 if ( defined &afterinit ) {    # May be defined in $rcfile
1716     afterinit();
1717 }
1718
1719 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1720 use vars qw($I_m_init);
1721
1722 $I_m_init = 1;
1723
1724 ############################################################ Subroutines
1725
1726 =head1 SUBROUTINES
1727
1728 =head2 DB
1729
1730 This gigantic subroutine is the heart of the debugger. Called before every
1731 statement, its job is to determine if a breakpoint has been reached, and
1732 stop if so; read commands from the user, parse them, and execute
1733 them, and then send execution off to the next statement.
1734
1735 Note that the order in which the commands are processed is very important;
1736 some commands earlier in the loop will actually alter the C<$cmd> variable
1737 to create other commands to be executed later. This is all highly I<optimized>
1738 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1739 see what's happening in any given command.
1740
1741 =cut
1742
1743 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1744
1745 use vars qw(
1746     $action
1747     $cmd
1748     $fall_off_end
1749     $file
1750     $filename_ini
1751     $finished
1752     %had_breakpoints
1753     $level
1754     $max
1755     $package
1756     $try
1757 );
1758
1759 our (
1760     %alias,
1761     $doret,
1762     $end,
1763     $incr,
1764     $laststep,
1765     $rc,
1766     $sh,
1767     $stack_depth,
1768     @stack,
1769     @to_watch,
1770     @old_watch,
1771 );
1772
1773 sub _DB__determine_if_we_should_break
1774 {
1775     # if we have something here, see if we should break.
1776     # $stop is lexical and local to this block - $action on the other hand
1777     # is global.
1778     my $stop;
1779
1780     if ( $dbline{$line}
1781         && _is_breakpoint_enabled($filename, $line)
1782         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1783     {
1784
1785         # Stop if the stop criterion says to just stop.
1786         if ( $stop eq '1' ) {
1787             $signal |= 1;
1788         }
1789
1790         # It's a conditional stop; eval it in the user's context and
1791         # see if we should stop. If so, remove the one-time sigil.
1792         elsif ($stop) {
1793             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1794             DB::eval();
1795             # If the breakpoint is temporary, then delete its enabled status.
1796             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1797                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1798             }
1799         }
1800     } ## end if ($dbline{$line} && ...
1801 }
1802
1803 sub _DB__is_finished {
1804     if ($finished and $level <= 1) {
1805         end_report();
1806         return 1;
1807     }
1808     else {
1809         return;
1810     }
1811 }
1812
1813 sub _DB__read_next_cmd
1814 {
1815     my ($tid) = @_;
1816
1817     # We have a terminal, or can get one ...
1818     if (!$term) {
1819         setterm();
1820     }
1821
1822     # ... and it belogs to this PID or we get one for this PID ...
1823     if ($term_pid != $$) {
1824         resetterm(1);
1825     }
1826
1827     # ... and we got a line of command input ...
1828     $cmd = DB::readline(
1829         "$pidprompt $tid DB"
1830         . ( '<' x $level )
1831         . ( $#hist + 1 )
1832         . ( '>' x $level ) . " "
1833     );
1834
1835     return defined($cmd);
1836 }
1837
1838 sub _DB__trim_command_and_return_first_component {
1839     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1840     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1841
1842     $cmd =~ m{\A(\S*)};
1843     return $1;
1844 }
1845
1846 sub _DB__handle_f_command {
1847     if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
1848         $file =~ s/\s+$//;
1849
1850         # help for no arguments (old-style was return from sub).
1851         if ( !$file ) {
1852             print $OUT
1853             "The old f command is now the r command.\n";    # hint
1854             print $OUT "The new f command switches filenames.\n";
1855             next CMD;
1856         } ## end if (!$file)
1857
1858         # if not in magic file list, try a close match.
1859         if ( !defined $main::{ '_<' . $file } ) {
1860             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1861                 {
1862                     $try = substr( $try, 2 );
1863                     print $OUT "Choosing $try matching '$file':\n";
1864                     $file = $try;
1865                 }
1866             } ## end if (($try) = grep(m#^_<.*$file#...
1867         } ## end if (!defined $main::{ ...
1868
1869         # If not successfully switched now, we failed.
1870         if ( !defined $main::{ '_<' . $file } ) {
1871             print $OUT "No file matching '$file' is loaded.\n";
1872             next CMD;
1873         }
1874
1875         # We switched, so switch the debugger internals around.
1876         elsif ( $file ne $filename ) {
1877             *dbline   = $main::{ '_<' . $file };
1878             $max      = $#dbline;
1879             $filename = $file;
1880             $start    = 1;
1881             $cmd      = "l";
1882         } ## end elsif ($file ne $filename)
1883
1884         # We didn't switch; say we didn't.
1885         else {
1886             print $OUT "Already in $file.\n";
1887             next CMD;
1888         }
1889     }
1890
1891     return;
1892 }
1893
1894 sub _DB__handle_dot_command {
1895     my ($obj) = @_;
1896
1897     # . command.
1898     if ($cmd eq '.') {
1899         $incr = -1;    # stay at current line
1900
1901         # Reset everything to the old location.
1902         $start    = $line;
1903         $filename = $filename_ini;
1904         *dbline   = $main::{ '_<' . $filename };
1905         $max      = $#dbline;
1906
1907         # Now where are we?
1908         print_lineinfo($obj->position());
1909         next CMD;
1910     }
1911
1912     return;
1913 }
1914
1915 sub _DB__handle_y_command {
1916     my ($obj) = @_;
1917
1918     if (my ($match_level, $match_vars)
1919         = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
1920
1921         # See if we've got the necessary support.
1922         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1923             my $Err = $@;
1924             DB::warn(
1925                 $Err =~ /locate/
1926                 ? "PadWalker module not found - please install\n"
1927                 : $Err
1928             );
1929             next CMD;
1930         }
1931
1932         # Load up dumpvar if we don't have it. If we can, that is.
1933         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1934         defined &main::dumpvar
1935             or print $OUT "dumpvar.pl not available.\n"
1936             and next CMD;
1937
1938         # Got all the modules we need. Find them and print them.
1939         my @vars = split( ' ', $match_vars || '' );
1940
1941         # Find the pad.
1942         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1943
1944         # Oops. Can't find it.
1945         if (my $Err = $@) {
1946             $Err =~ s/ at .*//;
1947             DB::warn($Err);
1948             next CMD;
1949         }
1950
1951         # Show the desired vars with dumplex().
1952         my $savout = select($OUT);
1953
1954         # Have dumplex dump the lexicals.
1955         foreach my $key (sort keys %$h) {
1956             dumpvar::dumplex( $key, $h->{$key},
1957                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1958                 @vars );
1959         }
1960         select($savout);
1961         next CMD;
1962     }
1963 }
1964
1965 sub _DB__handle_c_command {
1966     my ($obj) = @_;
1967
1968     if (my ($new_i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
1969
1970         $obj->i_cmd($new_i);
1971
1972         # Hey, show's over. The debugged program finished
1973         # executing already.
1974         next CMD if _DB__is_finished();
1975
1976         # Capture the place to put a one-time break.
1977         $subname = $obj->i_cmd;
1978
1979         #  Probably not needed, since we finish an interactive
1980         #  sub-session anyway...
1981         # local $filename = $filename;
1982         # local *dbline = *dbline; # XXX Would this work?!
1983         #
1984         # The above question wonders if localizing the alias
1985         # to the magic array works or not. Since it's commented
1986         # out, we'll just leave that to speculation for now.
1987
1988         # If the "subname" isn't all digits, we'll assume it
1989         # is a subroutine name, and try to find it.
1990         if ( $subname =~ /\D/ ) {    # subroutine name
1991             # Qualify it to the current package unless it's
1992             # already qualified.
1993             $subname = $package . "::" . $subname
1994             unless $subname =~ /::/;
1995
1996             # find_sub will return "file:line_number" corresponding
1997             # to where the subroutine is defined; we call find_sub,
1998             # break up the return value, and assign it in one
1999             # operation.
2000             ( $file, $new_i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2001
2002             # Force the line number to be numeric.
2003             $obj->i_cmd($new_i + 0);
2004
2005             # If we got a line number, we found the sub.
2006             if ($obj->i_cmd) {
2007
2008                 # Switch all the debugger's internals around so
2009                 # we're actually working with that file.
2010                 $filename = $file;
2011                 *dbline   = $main::{ '_<' . $filename };
2012
2013                 # Mark that there's a breakpoint in this file.
2014                 $had_breakpoints{$filename} |= 1;
2015
2016                 # Scan forward to the first executable line
2017                 # after the 'sub whatever' line.
2018                 $max = $#dbline;
2019                 my $ii = $obj->i_cmd;
2020                 ++$ii while $dbline[$ii] == 0 && $ii < $max;
2021                 $obj->i_cmd($ii);
2022             } ## end if ($i)
2023
2024             # We didn't find a sub by that name.
2025             else {
2026                 print $OUT "Subroutine $subname not found.\n";
2027                 next CMD;
2028             }
2029         } ## end if ($subname =~ /\D/)
2030
2031         # At this point, either the subname was all digits (an
2032         # absolute line-break request) or we've scanned through
2033         # the code following the definition of the sub, looking
2034         # for an executable, which we may or may not have found.
2035         #
2036         # If $i (which we set $subname from) is non-zero, we
2037         # got a request to break at some line somewhere. On
2038         # one hand, if there wasn't any real subroutine name
2039         # involved, this will be a request to break in the current
2040         # file at the specified line, so we have to check to make
2041         # sure that the line specified really is breakable.
2042         #
2043         # On the other hand, if there was a subname supplied, the
2044         # preceding block has moved us to the proper file and
2045         # location within that file, and then scanned forward
2046         # looking for the next executable line. We have to make
2047         # sure that one was found.
2048         #
2049         # On the gripping hand, we can't do anything unless the
2050         # current value of $i points to a valid breakable line.
2051         # Check that.
2052         if ($obj->i_cmd) {
2053
2054             # Breakable?
2055             if ( $dbline[$obj->i_cmd] == 0 ) {
2056                 print $OUT "Line " . $obj->i_cmd . " not breakable.\n";
2057                 next CMD;
2058             }
2059
2060             # Yes. Set up the one-time-break sigil.
2061             $dbline{$obj->i_cmd} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2062             _enable_breakpoint_temp_enabled_status($filename, $obj->i_cmd);
2063         } ## end if ($i)
2064
2065         # Turn off stack tracing from here up.
2066         for my $i (0 .. $stack_depth) {
2067             $stack[ $i ] &= ~1;
2068         }
2069         last CMD;
2070     }
2071
2072     return;
2073 }
2074
2075 sub _DB__handle_forward_slash_command {
2076     my ($obj) = @_;
2077
2078     # The pattern as a string.
2079     use vars qw($inpat);
2080
2081     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2082
2083         # Remove the final slash.
2084         $inpat =~ s:([^\\])/$:$1:;
2085
2086         # If the pattern isn't null ...
2087         if ( $inpat ne "" ) {
2088
2089             # Turn of warn and die procesing for a bit.
2090             local $SIG{__DIE__};
2091             local $SIG{__WARN__};
2092
2093             # Create the pattern.
2094             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2095             if ( $@ ne "" ) {
2096
2097                 # Oops. Bad pattern. No biscuit.
2098                 # Print the eval error and go back for more
2099                 # commands.
2100                 print $OUT "$@";
2101                 next CMD;
2102             }
2103             $obj->pat($inpat);
2104         } ## end if ($inpat ne "")
2105
2106         # Set up to stop on wrap-around.
2107         $end = $start;
2108
2109         # Don't move off the current line.
2110         $incr = -1;
2111
2112         my $pat = $obj->pat;
2113
2114         # Done in eval so nothing breaks if the pattern
2115         # does something weird.
2116         eval
2117         {
2118             no strict q/vars/;
2119             for (;;) {
2120                 # Move ahead one line.
2121                 ++$start;
2122
2123                 # Wrap if we pass the last line.
2124                 $start = 1 if ($start > $max);
2125
2126                 # Stop if we have gotten back to this line again,
2127                 last if ($start == $end);
2128
2129                 # A hit! (Note, though, that we are doing
2130                 # case-insensitive matching. Maybe a qr//
2131                 # expression would be better, so the user could
2132                 # do case-sensitive matching if desired.
2133                 if ($dbline[$start] =~ m/$pat/i) {
2134                     if ($slave_editor) {
2135                         # Handle proper escaping in the slave.
2136                         print $OUT "\032\032$filename:$start:0\n";
2137                     }
2138                     else {
2139                         # Just print the line normally.
2140                         print $OUT "$start:\t",$dbline[$start],"\n";
2141                     }
2142                     # And quit since we found something.
2143                     last;
2144                 }
2145             }
2146         };
2147
2148         if ($@) {
2149             warn $@;
2150         }
2151
2152         # If we wrapped, there never was a match.
2153         if ( $start == $end ) {
2154             print {$OUT} "/$pat/: not found\n";
2155         }
2156         next CMD;
2157     }
2158
2159     return;
2160 }
2161
2162 sub _DB__handle_question_mark_command {
2163     my ($obj) = @_;
2164
2165     # ? - backward pattern search.
2166     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2167
2168         # Get the pattern, remove trailing question mark.
2169         $inpat =~ s:([^\\])\?$:$1:;
2170
2171         # If we've got one ...
2172         if ( $inpat ne "" ) {
2173
2174             # Turn off die & warn handlers.
2175             local $SIG{__DIE__};
2176             local $SIG{__WARN__};
2177             eval '$inpat =~ m' . "\a$inpat\a";
2178
2179             if ( $@ ne "" ) {
2180
2181                 # Ouch. Not good. Print the error.
2182                 print $OUT $@;
2183                 next CMD;
2184             }
2185             $obj->pat($inpat);
2186         } ## end if ($inpat ne "")
2187
2188         # Where we are now is where to stop after wraparound.
2189         $end = $start;
2190
2191         # Don't move away from this line.
2192         $incr = -1;
2193
2194         my $pat = $obj->pat;
2195         # Search inside the eval to prevent pattern badness
2196         # from killing us.
2197         eval {
2198             no strict q/vars/;
2199             for (;;) {
2200                 # Back up a line.
2201                 --$start;
2202
2203                 # Wrap if we pass the first line.
2204
2205                 $start = $max if ($start <= 0);
2206
2207                 # Quit if we get back where we started,
2208                 last if ($start == $end);
2209
2210                 # Match?
2211                 if ($dbline[$start] =~ m/$pat/i) {
2212                     if ($slave_editor) {
2213                         # Yep, follow slave editor requirements.
2214                         print $OUT "\032\032$filename:$start:0\n";
2215                     }
2216                     else {
2217                         # Yep, just print normally.
2218                         print $OUT "$start:\t",$dbline[$start],"\n";
2219                     }
2220
2221                     # Found, so done.
2222                     last;
2223                 }
2224             }
2225         };
2226
2227         # Say we failed if the loop never found anything,
2228         if ( $start == $end ) {
2229             print {$OUT} "?$pat?: not found\n";
2230         }
2231         next CMD;
2232     }
2233
2234     return;
2235 }
2236
2237 sub _DB__handle_restart_and_rerun_commands {
2238     my ($obj) = @_;
2239
2240     # R - restart execution.
2241     # rerun - controlled restart execution.
2242     if (my ($cmd_cmd, $cmd_params) =
2243         $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
2244         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2245
2246         # Close all non-system fds for a clean restart.  A more
2247         # correct method would be to close all fds that were not
2248         # open when the process started, but this seems to be
2249         # hard.  See "debugger 'R'estart and open database
2250         # connections" on p5p.
2251
2252         my $max_fd = 1024; # default if POSIX can't be loaded
2253         if (eval { require POSIX }) {
2254             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2255         }
2256
2257         if (defined $max_fd) {
2258             foreach ($^F+1 .. $max_fd-1) {
2259                 next unless open FD_TO_CLOSE, "<&=$_";
2260                 close(FD_TO_CLOSE);
2261             }
2262         }
2263
2264         # And run Perl again.  We use exec() to keep the
2265         # PID stable (and that way $ini_pids is still valid).
2266         exec(@args) or print {$OUT} "exec failed: $!\n";
2267
2268         last CMD;
2269     }
2270
2271     return;
2272 }
2273
2274 sub _DB__handle_run_command_in_pager_command {
2275     my ($obj) = @_;
2276
2277     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2278         if ( $pager =~ /^\|/ ) {
2279
2280             # Default pager is into a pipe. Redirect I/O.
2281             open( SAVEOUT, ">&STDOUT" )
2282             || DB::warn("Can't save STDOUT");
2283             open( STDOUT, ">&OUT" )
2284             || DB::warn("Can't redirect STDOUT");
2285         } ## end if ($pager =~ /^\|/)
2286         else {
2287
2288             # Not into a pipe. STDOUT is safe.
2289             open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
2290         }
2291
2292         # Fix up environment to record we have less if so.
2293         fix_less();
2294
2295         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2296
2297             # Couldn't open pipe to pager.
2298             DB::warn("Can't pipe output to '$pager'");
2299             if ( $pager =~ /^\|/ ) {
2300
2301                 # Redirect I/O back again.
2302                 open( OUT, ">&STDOUT" )    # XXX: lost message
2303                 || DB::warn("Can't restore DB::OUT");
2304                 open( STDOUT, ">&SAVEOUT" )
2305                 || DB::warn("Can't restore STDOUT");
2306                 close(SAVEOUT);
2307             } ## end if ($pager =~ /^\|/)
2308             else {
2309
2310                 # Redirect I/O. STDOUT already safe.
2311                 open( OUT, ">&STDOUT" )    # XXX: lost message
2312                 || DB::warn("Can't restore DB::OUT");
2313             }
2314             next CMD;
2315         } ## end unless ($piped = open(OUT,...
2316
2317         # Set up broken-pipe handler if necessary.
2318         $SIG{PIPE} = \&DB::catch
2319         if $pager =~ /^\|/
2320         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2321
2322         OUT->autoflush(1);
2323         # Save current filehandle, and put it back.
2324         $obj->selected(scalar( select(OUT) ));
2325         # Don't put it back if pager was a pipe.
2326         if ($cmd !~ /\A\|\|/)
2327         {
2328             select($obj->selected());
2329             $obj->selected("");
2330         }
2331
2332         # Trim off the pipe symbols and run the command now.
2333         $cmd =~ s#\A\|+\s*##;
2334         redo PIPE;
2335     }
2336
2337     return;
2338 }
2339
2340
2341 sub DB {
2342
2343     # lock the debugger and get the thread id for the prompt
2344     lock($DBGR);
2345     my $tid;
2346     my $position;
2347     my ($prefix, $after, $infix);
2348     my $pat;
2349     my $explicit_stop;
2350     my $piped;
2351     my $selected;
2352
2353     if ($ENV{PERL5DB_THREADED}) {
2354         $tid = eval { "[".threads->tid."]" };
2355     }
2356
2357     my $i;
2358
2359     my $obj = DB::Obj->new(
2360         {
2361             position => \$position,
2362             prefix => \$prefix,
2363             after => \$after,
2364             explicit_stop => \$explicit_stop,
2365             infix => \$infix,
2366             i_cmd => \$i,
2367             pat => \$pat,
2368             piped => \$piped,
2369             selected => \$selected,
2370         },
2371     );
2372
2373     $obj->_DB_on_init__initialize_globals(@_);
2374
2375     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2376     # The code being debugged may have altered them.
2377     &save;
2378
2379     # Since DB::DB gets called after every line, we can use caller() to
2380     # figure out where we last were executing. Sneaky, eh? This works because
2381     # caller is returning all the extra information when called from the
2382     # debugger.
2383     local ( $package, $filename, $line ) = caller;
2384     $filename_ini = $filename;
2385
2386     # set up the context for DB::eval, so it can properly execute
2387     # code on behalf of the user. We add the package in so that the
2388     # code is eval'ed in the proper package (not in the debugger!).
2389     local $usercontext = _calc_usercontext($package);
2390
2391     # Create an alias to the active file magical array to simplify
2392     # the code here.
2393     local (*dbline) = $main::{ '_<' . $filename };
2394
2395     # Last line in the program.
2396     $max = $#dbline;
2397
2398     _DB__determine_if_we_should_break(@_);
2399
2400     # Preserve the current stop-or-not, and see if any of the W
2401     # (watch expressions) has changed.
2402     my $was_signal = $signal;
2403
2404     # If we have any watch expressions ...
2405     $obj->_DB__handle_watch_expressions(@_);
2406
2407 =head2 C<watchfunction()>
2408
2409 C<watchfunction()> is a function that can be defined by the user; it is a
2410 function which will be run on each entry to C<DB::DB>; it gets the
2411 current package, filename, and line as its parameters.
2412
2413 The watchfunction can do anything it likes; it is executing in the
2414 debugger's context, so it has access to all of the debugger's internal
2415 data structures and functions.
2416
2417 C<watchfunction()> can control the debugger's actions. Any of the following
2418 will cause the debugger to return control to the user's program after
2419 C<watchfunction()> executes:
2420
2421 =over 4
2422
2423 =item *
2424
2425 Returning a false value from the C<watchfunction()> itself.
2426
2427 =item *
2428
2429 Altering C<$single> to a false value.
2430
2431 =item *
2432
2433 Altering C<$signal> to a false value.
2434
2435 =item *
2436
2437 Turning off the C<4> bit in C<$trace> (this also disables the
2438 check for C<watchfunction()>. This can be done with
2439
2440     $trace &= ~4;
2441
2442 =back
2443
2444 =cut
2445
2446     # If there's a user-defined DB::watchfunction, call it with the
2447     # current package, filename, and line. The function executes in
2448     # the DB:: package.
2449     if ( $trace & 4 ) {    # User-installed watch
2450         return
2451           if watchfunction( $package, $filename, $line )
2452           and not $single
2453           and not $was_signal
2454           and not( $trace & ~4 );
2455     } ## end if ($trace & 4)
2456
2457     # Pick up any alteration to $signal in the watchfunction, and
2458     # turn off the signal now.
2459     $was_signal = $signal;
2460     $signal     = 0;
2461
2462 =head2 GETTING READY TO EXECUTE COMMANDS
2463
2464 The debugger decides to take control if single-step mode is on, the
2465 C<t> command was entered, or the user generated a signal. If the program
2466 has fallen off the end, we set things up so that entering further commands
2467 won't cause trouble, and we say that the program is over.
2468
2469 =cut
2470
2471     # Make sure that we always print if asked for explicitly regardless
2472     # of $trace_to_depth .
2473     $explicit_stop = ($single || $was_signal);
2474
2475     # Check to see if we should grab control ($single true,
2476     # trace set appropriately, or we got a signal).
2477     if ( $explicit_stop || ( $trace & 1 ) ) {
2478         $obj->_DB__grab_control(@_);
2479     } ## end if ($single || ($trace...
2480
2481 =pod
2482
2483 If there's an action to be executed for the line we stopped at, execute it.
2484 If there are any preprompt actions, execute those as well.
2485
2486 =cut
2487
2488     # If there's an action, do it now.
2489     if ($action) {
2490         $evalarg = $action;
2491         DB::eval();
2492     }
2493
2494     # Are we nested another level (e.g., did we evaluate a function
2495     # that had a breakpoint in it at the debugger prompt)?
2496     if ( $single || $was_signal ) {
2497
2498         # Yes, go down a level.
2499         local $level = $level + 1;
2500
2501         # Do any pre-prompt actions.
2502         foreach $evalarg (@$pre) {
2503             DB::eval();
2504         }
2505
2506         # Complain about too much recursion if we passed the limit.
2507         if ($single & 4) {
2508             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2509         }
2510
2511         # The line we're currently on. Set $incr to -1 to stay here
2512         # until we get a command that tells us to advance.
2513         $start = $line;
2514         $incr  = -1;      # for backward motion.
2515
2516         # Tack preprompt debugger actions ahead of any actual input.
2517         @typeahead = ( @$pretype, @typeahead );
2518
2519 =head2 WHERE ARE WE?
2520
2521 XXX Relocate this section?
2522
2523 The debugger normally shows the line corresponding to the current line of
2524 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2525 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2526
2527 C<$incr> controls by how many lines the I<current> line should move forward
2528 after a command is executed. If set to -1, this indicates that the I<current>
2529 line shouldn't change.
2530
2531 C<$start> is the I<current> line. It is used for things like knowing where to
2532 move forwards or backwards from when doing an C<L> or C<-> command.
2533
2534 C<$max> tells the debugger where the last line of the current file is. It's
2535 used to terminate loops most often.
2536
2537 =head2 THE COMMAND LOOP
2538
2539 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2540 in two parts:
2541
2542 =over 4
2543
2544 =item *
2545
2546 The outer part of the loop, starting at the C<CMD> label. This loop
2547 reads a command and then executes it.
2548
2549 =item *
2550
2551 The inner part of the loop, starting at the C<PIPE> label. This part
2552 is wholly contained inside the C<CMD> block and only executes a command.
2553 Used to handle commands running inside a pager.
2554
2555 =back
2556
2557 So why have two labels to restart the loop? Because sometimes, it's easier to
2558 have a command I<generate> another command and then re-execute the loop to do
2559 the new command. This is faster, but perhaps a bit more convoluted.
2560
2561 =cut
2562
2563         # The big command dispatch loop. It keeps running until the
2564         # user yields up control again.
2565         #
2566         # If we have a terminal for input, and we get something back
2567         # from readline(), keep on processing.
2568
2569       CMD:
2570         while (_DB__read_next_cmd($tid))
2571         {
2572
2573             share($cmd);
2574             # ... try to execute the input as debugger commands.
2575
2576             # Don't stop running.
2577             $single = 0;
2578
2579             # No signal is active.
2580             $signal = 0;
2581
2582             # Handle continued commands (ending with \):
2583             if ($cmd =~ s/\\\z/\n/) {
2584                 $cmd .= DB::readline("  cont: ");
2585                 redo CMD;
2586             }
2587
2588 =head4 The null command
2589
2590 A newline entered by itself means I<re-execute the last command>. We grab the
2591 command out of C<$laststep> (where it was recorded previously), and copy it
2592 back into C<$cmd> to be executed below. If there wasn't any previous command,
2593 we'll do nothing below (no command will match). If there was, we also save it
2594 in the command history and fall through to allow the command parsing to pick
2595 it up.
2596
2597 =cut
2598
2599             # Empty input means repeat the last command.
2600             if ($cmd eq '') {
2601                 $cmd = $laststep;
2602             }
2603             chomp($cmd);    # get rid of the annoying extra newline
2604             if (length($cmd) >= 2) {
2605                 push( @hist, $cmd );
2606             }
2607             push( @truehist, $cmd );
2608             share(@hist);
2609             share(@truehist);
2610
2611             # This is a restart point for commands that didn't arrive
2612             # via direct user input. It allows us to 'redo PIPE' to
2613             # re-execute command processing without reading a new command.
2614           PIPE: {
2615                 $i = _DB__trim_command_and_return_first_component();
2616
2617 =head3 COMMAND ALIASES
2618
2619 The debugger can create aliases for commands (these are stored in the
2620 C<%alias> hash). Before a command is executed, the command loop looks it up
2621 in the alias hash and substitutes the contents of the alias for the command,
2622 completely replacing it.
2623
2624 =cut
2625
2626                 # See if there's an alias for the command, and set it up if so.
2627                 if ( $alias{$i} ) {
2628
2629                     # Squelch signal handling; we want to keep control here
2630                     # if something goes loco during the alias eval.
2631                     local $SIG{__DIE__};
2632                     local $SIG{__WARN__};
2633
2634                     # This is a command, so we eval it in the DEBUGGER's
2635                     # scope! Otherwise, we can't see the special debugger
2636                     # variables, or get to the debugger's subs. (Well, we
2637                     # _could_, but why make it even more complicated?)
2638                     eval "\$cmd =~ $alias{$i}";
2639                     if ($@) {
2640                         local $\ = '';
2641                         print $OUT "Couldn't evaluate '$i' alias: $@";
2642                         next CMD;
2643                     }
2644                 } ## end if ($alias{$i})
2645
2646 =head3 MAIN-LINE COMMANDS
2647
2648 All of these commands work up to and after the program being debugged has
2649 terminated.
2650
2651 =head4 C<q> - quit
2652
2653 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2654 try to execute further, cleaning any restart-related stuff out of the
2655 environment, and executing with the last value of C<$?>.
2656
2657 =cut
2658
2659                 if ($cmd eq 'q') {
2660                     $fall_off_end = 1;
2661                     clean_ENV();
2662                     exit $?;
2663                 }
2664
2665 =head4 C<t> - trace [n]
2666
2667 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2668 If level is specified, set C<$trace_to_depth>.
2669
2670 =cut
2671
2672                 $obj->_handle_t_command;
2673
2674 =head4 C<S> - list subroutines matching/not matching a pattern
2675
2676 Walks through C<%sub>, checking to see whether or not to print the name.
2677
2678 =cut
2679
2680                 $obj->_handle_S_command;
2681
2682 =head4 C<X> - list variables in current package
2683
2684 Since the C<V> command actually processes this, just change this to the
2685 appropriate C<V> command and fall through.
2686
2687 =head4 C<V> - list variables
2688
2689 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2690
2691 =cut
2692
2693                 $obj->_handle_V_command_and_X_command;
2694
2695 =head4 C<x> - evaluate and print an expression
2696
2697 Hands the expression off to C<DB::eval>, setting it up to print the value
2698 via C<dumpvar.pl> instead of just printing it directly.
2699
2700 =cut
2701
2702                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2703                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2704
2705                     # handle special  "x 3 blah" syntax XXX propagate
2706                     # doc back to special variables.
2707                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2708                         $onetimedumpDepth = $1;
2709                     }
2710                 }
2711
2712 =head4 C<m> - print methods
2713
2714 Just uses C<DB::methods> to determine what methods are available.
2715
2716 =cut
2717
2718                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2719                     methods($1);
2720                     next CMD;
2721                 }
2722
2723                 # m expr - set up DB::eval to do the work
2724                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2725                     $onetimeDump = 'methods';   #  method output gets used there
2726                 }
2727
2728 =head4 C<f> - switch files
2729
2730 =cut
2731
2732                 _DB__handle_f_command();
2733
2734 =head4 C<.> - return to last-executed line.
2735
2736 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2737 and then we look up the line in the magical C<%dbline> hash.
2738
2739 =cut
2740
2741         _DB__handle_dot_command($obj);
2742
2743 =head4 C<-> - back one window
2744
2745 We change C<$start> to be one window back; if we go back past the first line,
2746 we set it to be the first line. We ser C<$incr> to put us back at the
2747 currently-executing line, and then put a C<l $start +> (list one window from
2748 C<$start>) in C<$cmd> to be executed later.
2749
2750 =cut
2751
2752                 # - - back a window.
2753                 $obj->_handle_dash_command;
2754
2755 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2756
2757 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2758 problems, most notably that the default case of several commands destroying
2759 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2760 retain the old commands for those who were used to using them or who preferred
2761 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2762 deal with them instead of processing them in-line.
2763
2764 =cut
2765
2766                 # All of these commands were remapped in perl 5.8.0;
2767                 # we send them off to the secondary dispatcher (see below).
2768                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2769                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2770                     next CMD;
2771                 }
2772
2773 =head4 C<y> - List lexicals in higher scope
2774
2775 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2776 above the current one and then displays then using C<dumpvar.pl>.
2777
2778 =cut
2779
2780                 _DB__handle_y_command($obj);
2781
2782 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2783
2784 All of the commands below this point don't work after the program being
2785 debugged has ended. All of them check to see if the program has ended; this
2786 allows the commands to be relocated without worrying about a 'line of
2787 demarcation' above which commands can be entered anytime, and below which
2788 they can't.
2789
2790 =head4 C<n> - single step, but don't trace down into subs
2791
2792 Done by setting C<$single> to 2, which forces subs to execute straight through
2793 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2794 so a null command knows what to re-execute.
2795
2796 =cut
2797
2798                 # n - next
2799                 $obj->_handle_n_command;
2800
2801 =head4 C<s> - single-step, entering subs
2802
2803 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2804 subs. Also saves C<s> as C<$lastcmd>.
2805
2806 =cut
2807
2808                 $obj->_handle_s_command;
2809
2810 =head4 C<c> - run continuously, setting an optional breakpoint
2811
2812 Most of the code for this command is taken up with locating the optional
2813 breakpoint, which is either a subroutine name or a line number. We set
2814 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2815 in this and all call levels above this one.
2816
2817 =cut
2818
2819                 # c - start continuous execution.
2820                 _DB__handle_c_command($obj);
2821
2822 =head4 C<r> - return from a subroutine
2823
2824 For C<r> to work properly, the debugger has to stop execution again
2825 immediately after the return is executed. This is done by forcing
2826 single-stepping to be on in the call level above the current one. If
2827 we are printing return values when a C<r> is executed, set C<$doret>
2828 appropriately, and force us out of the command loop.
2829
2830 =cut
2831
2832                 # r - return from the current subroutine.
2833                 $obj->_handle_r_command;
2834
2835 =head4 C<T> - stack trace
2836
2837 Just calls C<DB::print_trace>.
2838
2839 =cut
2840
2841                 $obj->_handle_T_command;
2842
2843 =head4 C<w> - List window around current line.
2844
2845 Just calls C<DB::cmd_w>.
2846
2847 =cut
2848
2849                 $obj->_handle_w_command;
2850
2851 =head4 C<W> - watch-expression processing.
2852
2853 Just calls C<DB::cmd_W>.
2854
2855 =cut
2856
2857                 $obj->_handle_W_command;
2858
2859 =head4 C</> - search forward for a string in the source
2860
2861 We take the argument and treat it as a pattern. If it turns out to be a
2862 bad one, we return the error we got from trying to C<eval> it and exit.
2863 If not, we create some code to do the search and C<eval> it so it can't
2864 mess us up.
2865
2866 =cut
2867
2868                 _DB__handle_forward_slash_command($obj);
2869
2870 =head4 C<?> - search backward for a string in the source
2871
2872 Same as for C</>, except the loop runs backwards.
2873
2874 =cut
2875
2876                 _DB__handle_question_mark_command($obj);
2877
2878 =head4 C<$rc> - Recall command
2879
2880 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2881 that the terminal supports history). It find the the command required, puts it
2882 into C<$cmd>, and redoes the loop to execute it.
2883
2884 =cut
2885
2886                 # $rc - recall command.
2887                 $obj->_handle_rc_recall_command;
2888
2889 =head4 C<$sh$sh> - C<system()> command
2890
2891 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2892 C<STDOUT> from getting messed up.
2893
2894 =cut
2895
2896                 $obj->_handle_sh_sh_command;
2897
2898 =head4 C<$rc I<pattern> $rc> - Search command history
2899
2900 Another command to manipulate C<@hist>: this one searches it with a pattern.
2901 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2902
2903 =cut
2904
2905                 $obj->_handle_rc_search_history_command;
2906
2907 =head4 C<$sh> - Invoke a shell
2908
2909 Uses C<DB::system> to invoke a shell.
2910
2911 =cut
2912
2913                 # $sh - start a shell.
2914                 if ($cmd =~ /\A$sh\z/) {
2915
2916                     # Run the user's shell. If none defined, run Bourne.
2917                     # We resume execution when the shell terminates.
2918                     DB::system( $ENV{SHELL} || "/bin/sh" );
2919                     next CMD;
2920                 }
2921
2922 =head4 C<$sh I<command>> - Force execution of a command in a shell
2923
2924 Like the above, but the command is passed to the shell. Again, we use
2925 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2926
2927 =cut
2928
2929                 # $sh command - start a shell and run a command in it.
2930                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2931
2932                     # XXX: using csh or tcsh destroys sigint retvals!
2933                     #&system($1);  # use this instead
2934
2935                     # use the user's shell, or Bourne if none defined.
2936                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2937                     next CMD;
2938                 }
2939
2940 =head4 C<H> - display commands in history
2941
2942 Prints the contents of C<@hist> (if any).
2943
2944 =cut
2945
2946                 $obj->_handle_H_command;
2947
2948 =head4 C<man, doc, perldoc> - look up documentation
2949
2950 Just calls C<runman()> to print the appropriate document.
2951
2952 =cut
2953
2954                 $obj->_handle_doc_command;
2955
2956 =head4 C<p> - print
2957
2958 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2959 the bottom of the loop.
2960
2961 =cut
2962
2963                 $obj->_handle_p_command;
2964
2965 =head4 C<=> - define command alias
2966
2967 Manipulates C<%alias> to add or list command aliases.
2968
2969 =cut
2970
2971                 # = - set up a command alias.
2972                 $obj->_handle_equal_sign_command;
2973
2974 =head4 C<source> - read commands from a file.
2975
2976 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
2977 pick it up.
2978
2979 =cut
2980
2981                 $obj->_handle_source_command;
2982
2983 =head4 C<enable> C<disable> - enable or disable breakpoints
2984
2985 This enables or disables breakpoints.
2986
2987 =cut
2988
2989                 $obj->_handle_enable_disable_commands;
2990
2991 =head4 C<save> - send current history to a file
2992
2993 Takes the complete history, (not the shrunken version you see with C<H>),
2994 and saves it to the given filename, so it can be replayed using C<source>.
2995
2996 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
2997
2998 =cut
2999
3000                 # save source - write commands to a file for later use
3001                 $obj->_handle_save_command;
3002
3003 =head4 C<R> - restart
3004
3005 Restart the debugger session.
3006
3007 =head4 C<rerun> - rerun the current session
3008
3009 Return to any given position in the B<true>-history list
3010
3011 =cut
3012
3013                 # R - restart execution.
3014                 # rerun - controlled restart execution.
3015                 _DB__handle_restart_and_rerun_commands($obj);
3016
3017 =head4 C<|, ||> - pipe output through the pager.
3018
3019 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3020 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3021 pipe to the pager (restoring the output filehandles if this fails). If this
3022 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3023 set C<$signal>, sending us back into the debugger.
3024
3025 We then trim off the pipe symbols and C<redo> the command loop at the
3026 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3027 reading another.
3028
3029 =cut
3030
3031                 # || - run command in the pager, with output to DB::OUT.
3032                 _DB__handle_run_command_in_pager_command($obj);
3033
3034 =head3 END OF COMMAND PARSING
3035
3036 Anything left in C<$cmd> at this point is a Perl expression that we want to
3037 evaluate. We'll always evaluate in the user's context, and fully qualify
3038 any variables we might want to address in the C<DB> package.
3039
3040 =cut
3041
3042             }    # PIPE:
3043
3044             # Make sure the flag that says "the debugger's running" is
3045             # still on, to make sure we get control again.
3046             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3047
3048             # Run *our* eval that executes in the caller's context.
3049             DB::eval();
3050
3051             # Turn off the one-time-dump stuff now.
3052             if ($onetimeDump) {
3053                 $onetimeDump      = undef;
3054                 $onetimedumpDepth = undef;
3055             }
3056             elsif ( $term_pid == $$ ) {
3057                 eval { # May run under miniperl, when not available...
3058                     STDOUT->flush();
3059                     STDERR->flush();
3060                 };
3061
3062                 # XXX If this is the master pid, print a newline.
3063                 print {$OUT} "\n";
3064             }
3065         } ## end while (($term || &setterm...
3066
3067 =head3 POST-COMMAND PROCESSING
3068
3069 After each command, we check to see if the command output was piped anywhere.
3070 If so, we go through the necessary code to unhook the pipe and go back to
3071 our standard filehandles for input and output.
3072
3073 =cut
3074
3075         continue {    # CMD:
3076
3077             # At the end of every command:
3078             if ($piped) {
3079
3080                 # Unhook the pipe mechanism now.
3081                 if ( $pager =~ /^\|/ ) {
3082
3083                     # No error from the child.
3084                     $? = 0;
3085
3086                     # we cannot warn here: the handle is missing --tchrist
3087                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3088
3089                     # most of the $? crud was coping with broken cshisms
3090                     # $? is explicitly set to 0, so this never runs.
3091                     if ($?) {
3092                         print SAVEOUT "Pager '$pager' failed: ";
3093                         if ( $? == -1 ) {
3094                             print SAVEOUT "shell returned -1\n";
3095                         }
3096                         elsif ( $? >> 8 ) {
3097                             print SAVEOUT ( $? & 127 )
3098                               ? " (SIG#" . ( $? & 127 ) . ")"
3099                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3100                         }
3101                         else {
3102                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3103                         }
3104                     } ## end if ($?)
3105
3106                     # Reopen filehandle for our output (if we can) and
3107                     # restore STDOUT (if we can).
3108                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3109                     open( STDOUT, ">&SAVEOUT" )
3110                       || &warn("Can't restore STDOUT");
3111
3112                     # Turn off pipe exception handler if necessary.
3113                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3114
3115                     # Will stop ignoring SIGPIPE if done like nohup(1)
3116                     # does SIGINT but Perl doesn't give us a choice.
3117                 } ## end if ($pager =~ /^\|/)
3118                 else {
3119
3120                     # Non-piped "pager". Just restore STDOUT.
3121                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3122                 }
3123
3124                 # Close filehandle pager was using, restore the normal one
3125                 # if necessary,
3126                 close(SAVEOUT);
3127                 select($selected), $selected = "" unless $selected eq "";
3128
3129                 # No pipes now.
3130                 $piped = "";
3131             } ## end if ($piped)
3132         }    # CMD:
3133
3134 =head3 COMMAND LOOP TERMINATION
3135
3136 When commands have finished executing, we come here. If the user closed the
3137 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3138 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3139 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3140 The interpreter will then execute the next line and then return control to us
3141 again.
3142
3143 =cut
3144
3145         # No more commands? Quit.
3146         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3147
3148         # Evaluate post-prompt commands.
3149         foreach $evalarg (@$post) {
3150             DB::eval();
3151         }
3152     }    # if ($single || $signal)
3153
3154     # Put the user's globals back where you found them.
3155     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3156     ();
3157 } ## end sub DB
3158
3159 package DB::Obj;
3160
3161 sub new {
3162     my $class = shift;
3163
3164     my $self = bless {}, $class;
3165
3166     $self->_init(@_);
3167
3168     return $self;
3169 }
3170
3171 sub _init {
3172     my ($self, $args) = @_;
3173
3174     %{$self} = (%$self, %$args);
3175
3176     return;
3177 }
3178
3179 {
3180     no strict 'refs';
3181     foreach my $slot_name (qw(
3182         after explicit_stop infix pat piped position prefix selected i_cmd
3183         )) {
3184         my $slot = $slot_name;
3185         *{$slot} = sub {
3186             my $self = shift;
3187
3188             if (@_) {
3189                 ${ $self->{$slot} } = shift;
3190             }
3191
3192             return ${ $self->{$slot} };
3193         };
3194
3195         *{"append_to_$slot"} = sub {
3196             my $self = shift;
3197             my $s = shift;
3198
3199             return $self->$slot($self->$slot . $s);
3200         };
3201     }
3202 }
3203
3204 sub _DB_on_init__initialize_globals
3205 {
3206     my $self = shift;
3207
3208     # Check for whether we should be running continuously or not.
3209     # _After_ the perl program is compiled, $single is set to 1:
3210     if ( $single and not $second_time++ ) {
3211
3212         # Options say run non-stop. Run until we get an interrupt.
3213         if ($runnonstop) {    # Disable until signal
3214                 # If there's any call stack in place, turn off single
3215                 # stepping into subs throughout the stack.
3216             for my $i (0 .. $stack_depth) {
3217                 $stack[ $i ] &= ~1;
3218             }
3219
3220             # And we are now no longer in single-step mode.
3221             $single = 0;
3222
3223             # If we simply returned at this point, we wouldn't get
3224             # the trace info. Fall on through.
3225             # return;
3226         } ## end if ($runnonstop)
3227
3228         elsif ($ImmediateStop) {
3229
3230             # We are supposed to stop here; XXX probably a break.
3231             $ImmediateStop = 0;    # We've processed it; turn it off
3232             $signal        = 1;    # Simulate an interrupt to force
3233                                    # us into the command loop
3234         }
3235     } ## end if ($single and not $second_time...
3236
3237     # If we're in single-step mode, or an interrupt (real or fake)
3238     # has occurred, turn off non-stop mode.
3239     $runnonstop = 0 if $single or $signal;
3240
3241     return;
3242 }
3243
3244 sub _DB__handle_watch_expressions
3245 {
3246     my $self = shift;
3247
3248     if ( $trace & 2 ) {
3249         for my $n (0 .. $#to_watch) {
3250             $evalarg = $to_watch[$n];
3251             local $onetimeDump;    # Tell DB::eval() to not output results
3252
3253             # Fix context DB::eval() wants to return an array, but
3254             # we need a scalar here.
3255             my ($val) = join( "', '", DB::eval() );
3256             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3257
3258             # Did it change?
3259             if ( $val ne $old_watch[$n] ) {
3260
3261                 # Yep! Show the difference, and fake an interrupt.
3262                 $signal = 1;
3263                 print {$OUT} <<EOP;
3264 Watchpoint $n:\t$to_watch[$n] changed:
3265     old value:\t$old_watch[$n]
3266     new value:\t$val
3267 EOP
3268                 $old_watch[$n] = $val;
3269             } ## end if ($val ne $old_watch...
3270         } ## end for my $n (0 ..
3271     } ## end if ($trace & 2)
3272
3273     return;
3274 }
3275
3276 sub _my_print_lineinfo
3277 {
3278     my ($self, $i, $incr_pos) = @_;
3279
3280     if ($frame) {
3281         # Print it indented if tracing is on.
3282         DB::print_lineinfo( ' ' x $stack_depth,
3283             "$i:\t$DB::dbline[$i]" . $self->after );
3284     }
3285     else {
3286         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3287     }
3288 }
3289
3290 sub _curr_line {
3291     return $DB::dbline[$line];
3292 }
3293
3294 sub _DB__grab_control
3295 {
3296     my $self = shift;
3297
3298     # Yes, grab control.
3299     if ($slave_editor) {
3300
3301         # Tell the editor to update its position.
3302         $self->position("\032\032${DB::filename}:$line:0\n");
3303         DB::print_lineinfo($self->position());
3304     }
3305
3306 =pod
3307
3308 Special check: if we're in package C<DB::fake>, we've gone through the
3309 C<END> block at least once. We set up everything so that we can continue
3310 to enter commands and have a valid context to be in.
3311
3312 =cut
3313
3314     elsif ( $DB::package eq 'DB::fake' ) {
3315
3316         # Fallen off the end already.
3317         if (!$DB::term) {
3318             DB::setterm();
3319         }
3320
3321         DB::print_help(<<EOP);
3322 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3323 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3324 B<h q>, B<h R> or B<h o> to get additional info.
3325 EOP
3326
3327         # Set the DB::eval context appropriately.
3328         $DB::package     = 'main';
3329         $DB::usercontext = DB::_calc_usercontext($DB::package);
3330     } ## end elsif ($package eq 'DB::fake')
3331
3332 =pod
3333
3334 If the program hasn't finished executing, we scan forward to the
3335 next executable line, print that out, build the prompt from the file and line
3336 number information, and print that.
3337
3338 =cut
3339
3340     else {
3341
3342
3343         # Still somewhere in the midst of execution. Set up the
3344         #  debugger prompt.
3345         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3346                              # Perl 5 ones (sorry, we don't print Klingon
3347                              #module names)
3348
3349         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3350         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3351         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3352
3353         # Break up the prompt if it's really long.
3354         if ( length($self->prefix()) > 30 ) {
3355             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3356             $self->prefix("");
3357             $self->infix(":\t");
3358         }
3359         else {
3360             $self->infix("):\t");
3361             $self->position(
3362                 $self->prefix . $line. $self->infix
3363                 . $self->_curr_line . $self->after
3364             );
3365         }
3366
3367         # Print current line info, indenting if necessary.
3368         $self->_my_print_lineinfo($line, $self->position);
3369
3370         my $i;
3371         my $line_i = sub { return $DB::dbline[$i]; };
3372
3373         # Scan forward, stopping at either the end or the next
3374         # unbreakable line.
3375         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3376         {    #{ vi
3377
3378             # Drop out on null statements, block closers, and comments.
3379             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3380
3381             # Drop out if the user interrupted us.
3382             last if $signal;
3383
3384             # Append a newline if the line doesn't have one. Can happen
3385             # in eval'ed text, for instance.
3386             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3387
3388             # Next executable line.
3389             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3390                 . $self->after;
3391             $self->append_to_position($incr_pos);
3392             $self->_my_print_lineinfo($i, $incr_pos);
3393         } ## end for ($i = $line + 1 ; $i...
3394     } ## end else [ if ($slave_editor)
3395
3396     return;
3397 }
3398
3399 sub _handle_t_command {
3400     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3401         $trace ^= 1;
3402         local $\ = '';
3403         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3404         print {$OUT} "Trace = "
3405         . ( ( $trace & 1 )
3406             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3407             : "off" ) . "\n";
3408         next CMD;
3409     }
3410
3411     return;
3412 }
3413
3414
3415 sub _handle_S_command {
3416     if (my ($print_all_subs, $should_reverse, $Spatt)
3417         = $DB::cmd =~ /\AS(\s+(!)?(.+))?\z/) {
3418         # $Spatt is the pattern (if any) to use.
3419         # Reverse scan?
3420         my $Srev     = defined $should_reverse;
3421         # No args - print all subs.
3422         my $Snocheck = !defined $print_all_subs;
3423
3424         # Need to make these sane here.
3425         local $\ = '';
3426         local $, = '';
3427
3428         # Search through the debugger's magical hash of subs.
3429         # If $nocheck is true, just print the sub name.
3430         # Otherwise, check it against the pattern. We then use
3431         # the XOR trick to reverse the condition as required.
3432         foreach $subname ( sort( keys %sub ) ) {
3433             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3434                 print $OUT $subname, "\n";
3435             }
3436         }
3437         next CMD;
3438     }
3439
3440     return;
3441 }
3442
3443 sub _handle_V_command_and_X_command {
3444
3445     $DB::cmd =~ s/^X\b/V $DB::package/;
3446
3447     # Bare V commands get the currently-being-debugged package
3448     # added.
3449     if ($DB::cmd eq "V") {
3450         $DB::cmd = "V $DB::package";
3451     }
3452
3453     # V - show variables in package.
3454     if (my ($new_packname, $new_vars_str) =
3455         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3456
3457         # Save the currently selected filehandle and
3458         # force output to debugger's filehandle (dumpvar
3459         # just does "print" for output).
3460         my $savout = select($OUT);
3461
3462         # Grab package name and variables to dump.
3463         $packname = $new_packname;
3464         my @vars     = split( ' ', $new_vars_str );
3465
3466         # If main::dumpvar isn't here, get it.
3467         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3468         if ( defined &main::dumpvar ) {
3469
3470             # We got it. Turn off subroutine entry/exit messages
3471             # for the moment, along with return values.
3472             local $frame = 0;
3473             local $doret = -2;
3474
3475             # must detect sigpipe failures  - not catching
3476             # then will cause the debugger to die.
3477             eval {
3478                 &main::dumpvar(
3479                     $packname,
3480                     defined $option{dumpDepth}
3481                     ? $option{dumpDepth}
3482                     : -1,    # assume -1 unless specified
3483                     @vars
3484                 );
3485             };
3486
3487             # The die doesn't need to include the $@, because
3488             # it will automatically get propagated for us.
3489             if ($@) {
3490                 die unless $@ =~ /dumpvar print failed/;
3491             }
3492         } ## end if (defined &main::dumpvar)
3493         else {
3494
3495             # Couldn't load dumpvar.
3496             print $OUT "dumpvar.pl not available.\n";
3497         }
3498
3499         # Restore the output filehandle, and go round again.
3500         select($savout);
3501         next CMD;
3502     }
3503
3504     return;
3505 }
3506
3507 sub _handle_dash_command {
3508
3509     if ($DB::cmd eq '-') {
3510
3511         # back up by a window; go to 1 if back too far.
3512         $start -= $incr + $window + 1;
3513         $start = 1 if $start <= 0;
3514         $incr  = $window - 1;
3515
3516         # Generate and execute a "l +" command (handled below).
3517         $DB::cmd = 'l ' . ($start) . '+';
3518     }
3519     return;
3520 }
3521
3522 sub _n_or_s_commands_generic {
3523     my ($self, $new_val) = @_;
3524     # n - next
3525     next CMD if DB::_DB__is_finished();
3526
3527     # Single step, but don't enter subs.
3528     $single = $new_val;
3529
3530     # Save for empty command (repeat last).
3531     $laststep = $DB::cmd;
3532     last CMD;
3533 }
3534
3535 sub _n_or_s {
3536     my ($self, $letter, $new_val) = @_;
3537
3538     if ($DB::cmd eq $letter) {
3539         $self->_n_or_s_commands_generic($new_val);
3540     }
3541     elsif ($DB::cmd =~ m#\A\Q$letter\E\b#) {
3542         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3543     }
3544
3545     return;
3546 }
3547
3548 sub _handle_n_command {
3549     my $self = shift;
3550
3551     return $self->_n_or_s('n', 2);
3552 }
3553
3554 sub _handle_s_command {
3555     my $self = shift;
3556
3557     return $self->_n_or_s('s', 1);
3558 }
3559
3560 sub _handle_r_command {
3561     my $self = shift;
3562     # r - return from the current subroutine.
3563     if ($DB::cmd eq 'r') {
3564
3565         # Can't do anything if the program's over.
3566         next CMD if DB::_DB__is_finished();
3567
3568         # Turn on stack trace.
3569         $stack[$stack_depth] |= 1;
3570
3571         # Print return value unless the stack is empty.
3572         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3573         last CMD;
3574     }
3575
3576     return;
3577 }
3578
3579 sub _handle_T_command {
3580     if ($DB::cmd eq 'T') {
3581         DB::print_trace( $OUT, 1 );    # skip DB
3582         next CMD;
3583     }
3584
3585     return;
3586 }
3587
3588 sub _handle_w_command {
3589     if (my ($arg) = $DB::cmd =~ /\Aw\b\s*(.*)/s) {
3590         DB::cmd_w( 'w', $arg );
3591         next CMD;
3592     }
3593
3594     return;
3595 }
3596
3597 sub _handle_W_command {
3598     if (my ($arg) = $DB::cmd =~ /\AW\b\s*(.*)/s) {
3599         DB::cmd_W( 'W', $arg );
3600         next CMD;
3601     }
3602
3603     return;
3604 }
3605
3606 sub _handle_rc_recall_command {
3607     my $self = shift;
3608
3609     # $rc - recall command.
3610     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3611
3612         # No arguments, take one thing off history.
3613         pop(@hist) if length($DB::cmd) > 1;
3614
3615         # Relative (- found)?
3616         #  Y - index back from most recent (by 1 if bare minus)
3617         #  N - go to that particular command slot or the last
3618         #      thing if nothing following.
3619         my $new_i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
3620
3621         $self->i_cmd($new_i);
3622
3623         # Pick out the command desired.
3624         $DB::cmd = $hist[$self->i_cmd];
3625
3626         # Print the command to be executed and restart the loop
3627         # with that command in the buffer.
3628         print {$OUT} $DB::cmd, "\n";
3629         redo CMD;
3630     }
3631
3632     return;
3633 }
3634
3635 sub _handle_rc_search_history_command {
3636     my $self = shift;
3637
3638     # $rc pattern $rc - find a command in the history.
3639     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3640
3641         # Create the pattern to use.
3642         my $pat = "^$arg";
3643         $self->pat($pat);
3644
3645         # Toss off last entry if length is >1 (and it always is).
3646         pop(@hist) if length($DB::cmd) > 1;
3647
3648         my $i = $self->i_cmd;
3649
3650         # Look backward through the history.
3651         SEARCH_HIST:
3652         for ( $i = $#hist ; $i ; --$i ) {
3653             # Stop if we find it.
3654             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3655         }
3656
3657         $self->i_cmd($i);
3658
3659         if ( !$self->i_cmd ) {
3660
3661             # Never found it.
3662             print $OUT "No such command!\n\n";
3663             next CMD;
3664         }
3665
3666         # Found it. Put it in the buffer, print it, and process it.
3667         $DB::cmd = $hist[$self->i_cmd];
3668         print $OUT $DB::cmd, "\n";
3669         redo CMD;
3670     }
3671
3672     return;
3673 }
3674
3675 sub _handle_H_command {
3676     my $self = shift;
3677
3678     if ($DB::cmd =~ /\AH\b\s*\*/) {
3679         @hist = @truehist = ();
3680         print $OUT "History cleansed\n";
3681         next CMD;
3682     }
3683
3684     if (my ($num)
3685         = $DB::cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3686
3687         # Anything other than negative numbers is ignored by
3688         # the (incorrect) pattern, so this test does nothing.
3689         $end = $num ? ( $#hist - $num ) : 0;
3690
3691         # Set to the minimum if less than zero.
3692         $hist = 0 if $hist < 0;
3693
3694         # Start at the end of the array.
3695         # Stay in while we're still above the ending value.
3696         # Tick back by one each time around the loop.
3697         my $i;
3698
3699         for ( $i = $#hist ; $i > $end ; $i-- ) {
3700
3701             # Print the command  unless it has no arguments.
3702             print $OUT "$i: ", $hist[$i], "\n"
3703             unless $hist[$i] =~ /^.?$/;
3704         }
3705
3706         $self->i_cmd($i);
3707
3708         next CMD;
3709     }
3710
3711     return;
3712 }
3713
3714 sub _handle_doc_command {
3715     my $self = shift;
3716
3717     # man, perldoc, doc - show manual pages.
3718     if (my ($man_page)
3719         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3720         runman($man_page);
3721         next CMD;
3722     }
3723
3724     return;
3725 }
3726
3727 sub _handle_p_command {
3728     my $self = shift;
3729
3730     my $print_cmd = 'print {$DB::OUT} ';
3731     # p - print (no args): print $_.
3732     if ($DB::cmd eq 'p') {
3733         $DB::cmd = $print_cmd . '$_';
3734     }
3735
3736     # p - print the given expression.
3737     $DB::cmd =~ s/\Ap\b/$print_cmd /;
3738
3739     return;
3740 }
3741
3742 sub _handle_equal_sign_command {
3743     my $self = shift;
3744
3745     if ($DB::cmd =~ s/\A=\s*//) {
3746         my @keys;
3747         if ( length $DB::cmd == 0 ) {
3748
3749             # No args, get current aliases.
3750             @keys = sort keys %alias;
3751         }
3752         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3753
3754             # Creating a new alias. $k is alias name, $v is
3755             # alias value.
3756
3757             # can't use $_ or kill //g state
3758             for my $x ( $k, $v ) {
3759
3760                 # Escape "alarm" characters.
3761                 $x =~ s/\a/\\a/g;
3762             }
3763
3764             # Substitute key for value, using alarm chars
3765             # as separators (which is why we escaped them in
3766             # the command).
3767             $alias{$k} = "s\a$k\a$v\a";
3768
3769             # Turn off standard warn and die behavior.
3770             local $SIG{__DIE__};
3771             local $SIG{__WARN__};
3772
3773             # Is it valid Perl?
3774             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3775
3776                 # Nope. Bad alias. Say so and get out.
3777                 print $OUT "Can't alias $k to $v: $@\n";
3778                 delete $alias{$k};
3779                 next CMD;
3780             }
3781
3782             # We'll only list the new one.
3783             @keys = ($k);
3784         } ## end elsif (my ($k, $v) = ($DB::cmd...
3785
3786         # The argument is the alias to list.
3787         else {
3788             @keys = ($DB::cmd);
3789         }
3790
3791         # List aliases.
3792         for my $k (@keys) {
3793
3794             # Messy metaquoting: Trim the substitution code off.
3795             # We use control-G as the delimiter because it's not
3796             # likely to appear in the alias.
3797             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3798
3799                 # Print the alias.
3800                 print $OUT "$k\t= $1\n";
3801             }
3802             elsif ( defined $alias{$k} ) {
3803
3804                 # Couldn't trim it off; just print the alias code.
3805                 print $OUT "$k\t$alias{$k}\n";
3806             }
3807             else {
3808
3809                 # No such, dude.
3810                 print "No alias for $k\n";
3811             }
3812         } ## end for my $k (@keys)
3813         next CMD;
3814     }
3815
3816     return;
3817 }
3818
3819 sub _handle_source_command {
3820     my $self = shift;
3821
3822     # source - read commands from a file (or pipe!) and execute.
3823     if (my ($sourced_fn) = $DB::cmd =~ /\Asource\s+(.*\S)/) {
3824         if ( open my $fh, $sourced_fn ) {
3825
3826             # Opened OK; stick it in the list of file handles.
3827             push @cmdfhs, $fh;
3828         }
3829         else {
3830
3831             # Couldn't open it.
3832             DB::warn("Can't execute '$sourced_fn': $!\n");
3833         }
3834         next CMD;
3835     }
3836
3837     return;
3838 }
3839
3840 sub _handle_enable_disable_commands {
3841     my $self = shift;
3842
3843     if (my ($which_cmd, $position)
3844         = $DB::cmd =~ /\A(enable|disable)\s+(\S+)\s*\z/) {
3845
3846         my ($fn, $line_num);
3847         if ($position =~ m{\A\d+\z})
3848         {
3849             $fn = $DB::filename;
3850             $line_num = $position;
3851         }
3852         elsif (my ($new_fn, $new_line_num)
3853             = $position =~ m{\A(.*):(\d+)\z}) {
3854             ($fn, $line_num) = ($new_fn, $new_line_num);
3855         }
3856         else
3857         {
3858             DB::warn("Wrong spec for enable/disable argument.\n");
3859         }
3860
3861         if (defined($fn)) {
3862             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3863                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3864                     ($which_cmd eq 'enable' ? 1 : '')
3865                 );
3866             }
3867             else {
3868                 DB::warn("No breakpoint set at ${fn}:${line_num}\n");
3869             }
3870         }
3871
3872         next CMD;
3873     }
3874
3875     return;
3876 }
3877
3878 sub _handle_save_command {
3879     my $self = shift;
3880
3881     if (my ($new_fn) = $DB::cmd =~ /\Asave\s*(.*)\z/) {
3882         my $filename = $new_fn || '.perl5dbrc';    # default?
3883         if ( open my $fh, '>', $filename ) {
3884
3885             # chomp to remove extraneous newlines from source'd files
3886             chomp( my @truelist =
3887                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3888                 @truehist );
3889             print {$fh} join( "\n", @truelist );
3890             print "commands saved in $filename\n";
3891         }
3892         else {
3893             DB::warn("Can't save debugger commands in '$new_fn': $!\n");
3894         }
3895         next CMD;
3896     }
3897
3898     return;
3899 }
3900
3901 sub _n_or_s_and_arg_commands_generic {
3902     my ($self, $letter, $new_val) = @_;
3903
3904     # s - single-step. Remember the last command was 's'.
3905     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3906         $laststep = $letter;
3907     }
3908
3909     return;
3910 }
3911
3912 sub _handle_sh_sh_command {
3913     my $self = shift;
3914
3915     # $sh$sh - run a shell command (if it's all ASCII).
3916     # Can't run shell commands with Unicode in the debugger, hmm.
3917     if (my ($arg) = $DB::cmd =~ m#\A$sh$sh\s*(.*)#ms) {
3918
3919         # System it.
3920         DB::system($arg);
3921         next CMD;
3922     }
3923 }
3924
3925 package DB;
3926
3927 # The following code may be executed now:
3928 # BEGIN {warn 4}
3929
3930 =head2 sub
3931
3932 C<sub> is called whenever a subroutine call happens in the program being
3933 debugged. The variable C<$DB::sub> contains the name of the subroutine
3934 being called.
3935
3936 The core function of this subroutine is to actually call the sub in the proper
3937 context, capturing its output. This of course causes C<DB::DB> to get called
3938 again, repeating until the subroutine ends and returns control to C<DB::sub>
3939 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3940 return value, and returns its captured copy of the return value as its own
3941 return value. The value then feeds back into the program being debugged as if
3942 C<DB::sub> hadn't been there at all.
3943
3944 C<sub> does all the work of printing the subroutine entry and exit messages
3945 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3946 and also prints the return value if needed (for the C<r> command and if
3947 the 16 bit is set in C<$frame>).
3948
3949 It also tracks the subroutine call depth by saving the current setting of
3950 C<$single> in the C<@stack> package global; if this exceeds the value in
3951 C<$deep>, C<sub> automatically turns on printing of the current depth by
3952 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3953 of stop/don't stop on entry to subs set as it currently is set.
3954
3955 =head3 C<caller()> support
3956
3957 If C<caller()> is called from the package C<DB>, it provides some
3958 additional data, in the following order:
3959
3960 =over 4
3961
3962 =item * C<$package>
3963
3964 The package name the sub was in
3965
3966 =item * C<$filename>
3967
3968 The filename it was defined in
3969
3970 =item * C<$line>
3971
3972 The line number it was defined on
3973
3974 =item * C<$subroutine>
3975
3976 The subroutine name; C<(eval)> if an C<eval>().
3977
3978 =item * C<$hasargs>
3979
3980 1 if it has arguments, 0 if not
3981
3982 =item * C<$wantarray>
3983
3984 1 if array context, 0 if scalar context
3985
3986 =item * C<$evaltext>
3987
3988 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3989
3990 =item * C<$is_require>
3991
3992 frame was created by a C<use> or C<require> statement
3993
3994 =item * C<$hints>
3995
3996 pragma information; subject to change between versions
3997
3998 =item * C<$bitmask>
3999
4000 pragma information; subject to change between versions
4001
4002 =item * C<@DB::args>
4003
4004 arguments with which the subroutine was invoked
4005
4006 =back
4007
4008 =cut
4009
4010 use vars qw($deep);
4011
4012 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4013 # happy. -- Shlomi Fish
4014 sub DB::sub {
4015     # Do not use a regex in this subroutine -> results in corrupted memory
4016     # See: [perl #66110]
4017
4018     # lock ourselves under threads
4019     lock($DBGR);
4020
4021     # Whether or not the autoloader was running, a scalar to put the
4022     # sub's return value in (if needed), and an array to put the sub's
4023     # return value in (if needed).
4024     my ( $al, $ret, @ret ) = "";
4025     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4026         print "creating new thread\n";
4027     }
4028
4029     # If the last ten characters are '::AUTOLOAD', note we've traced
4030     # into AUTOLOAD for $sub.
4031     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4032         no strict 'refs';
4033         $al = " for $$sub" if defined $$sub;
4034     }
4035
4036     # We stack the stack pointer and then increment it to protect us
4037     # from a situation that might unwind a whole bunch of call frames
4038     # at once. Localizing the stack pointer means that it will automatically
4039     # unwind the same amount when multiple stack frames are unwound.
4040     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4041
4042     # Expand @stack.
4043     $#stack = $stack_depth;
4044
4045     # Save current single-step setting.
4046     $stack[-1] = $single;
4047
4048     # Turn off all flags except single-stepping.
4049     $single &= 1;
4050
4051     # If we've gotten really deeply recursed, turn on the flag that will
4052     # make us stop with the 'deep recursion' message.
4053     $single |= 4 if $stack_depth == $deep;
4054
4055     # If frame messages are on ...
4056     (
4057         $frame & 4    # Extended frame entry message
4058         ? (
4059             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
4060
4061             # Why -1? But it works! :-(
4062             # Because print_trace will call add 1 to it and then call
4063             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4064             # in dump_trace.
4065             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4066           )
4067         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4068
4069           # standard frame entry message
4070       )
4071       if $frame;
4072
4073     # Determine the sub's return type, and capture appropriately.
4074     if (wantarray) {
4075
4076         # Called in array context. call sub and capture output.
4077         # DB::DB will recursively get control again if appropriate; we'll come
4078         # back here when the sub is finished.
4079         {
4080             no strict 'refs';
4081             @ret = &$sub;
4082         }
4083
4084         # Pop the single-step value back off the stack.
4085         $single |= $stack[ $stack_depth-- ];
4086
4087         # Check for exit trace messages...
4088         (
4089             $frame & 4    # Extended exit message
4090             ? (
4091                 print_lineinfo( ' ' x $stack_depth, "out " ),
4092                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4093               )
4094             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
4095
4096               # Standard exit message
4097           )
4098           if $frame & 2;
4099
4100         # Print the return info if we need to.
4101         if ( $doret eq $stack_depth or $frame & 16 ) {
4102
4103             # Turn off output record separator.
4104             local $\ = '';
4105             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4106
4107             # Indent if we're printing because of $frame tracing.
4108             print $fh ' ' x $stack_depth if $frame & 16;
4109
4110             # Print the return value.
4111             print $fh "list context return from $sub:\n";
4112             dumpit( $fh, \@ret );
4113
4114             # And don't print it again.
4115             $doret = -2;
4116         } ## end if ($doret eq $stack_depth...
4117             # And we have to return the return value now.
4118         @ret;
4119     } ## end if (wantarray)
4120
4121     # Scalar context.
4122     else {
4123         if ( defined wantarray ) {
4124             no strict 'refs';
4125             # Save the value if it's wanted at all.
4126             $ret = &$sub;
4127         }
4128         else {
4129             no strict 'refs';
4130             # Void return, explicitly.
4131             &$sub;
4132             undef $ret;
4133         }
4134
4135         # Pop the single-step value off the stack.
4136         $single |= $stack[ $stack_depth-- ];
4137
4138         # If we're doing exit messages...
4139         (
4140             $frame & 4    # Extended messages
4141             ? (
4142                 print_lineinfo( ' ' x $stack_depth, "out " ),
4143                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4144               )
4145             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
4146
4147               # Standard messages
4148           )
4149           if $frame & 2;
4150
4151         # If we are supposed to show the return value... same as before.
4152         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4153             local $\ = '';
4154             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4155             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4156             print $fh (
4157                 defined wantarray
4158                 ? "scalar context return from $sub: "
4159                 : "void context return from $sub\n"
4160             );
4161             dumpit( $fh, $ret ) if defined wantarray;
4162             $doret = -2;
4163         } ## end if ($doret eq $stack_depth...
4164
4165         # Return the appropriate scalar value.
4166         $ret;
4167     } ## end else [ if (wantarray)
4168 } ## end sub _sub
4169
4170 sub lsub : lvalue {
4171
4172     no strict 'refs';
4173
4174     # lock ourselves under threads
4175     lock($DBGR);
4176
4177     # Whether or not the autoloader was running, a scalar to put the
4178     # sub's return value in (if needed), and an array to put the sub's
4179     # return value in (if needed).
4180     my ( $al, $ret, @ret ) = "";
4181     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4182         print "creating new thread\n";
4183     }
4184
4185     # If the last ten characters are C'::AUTOLOAD', note we've traced
4186     # into AUTOLOAD for $sub.
4187     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4188         $al = " for $$sub";
4189     }
4190
4191     # We stack the stack pointer and then increment it to protect us
4192     # from a situation that might unwind a whole bunch of call frames
4193     # at once. Localizing the stack pointer means that it will automatically
4194     # unwind the same amount when multiple stack frames are unwound.
4195     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4196
4197     # Expand @stack.
4198     $#stack = $stack_depth;
4199
4200     # Save current single-step setting.
4201     $stack[-1] = $single;
4202
4203     # Turn off all flags except single-stepping.
4204     $single &= 1;
4205
4206     # If we've gotten really deeply recursed, turn on the flag that will
4207     # make us stop with the 'deep recursion' message.
4208     $single |= 4 if $stack_depth == $deep;
4209
4210     # If frame messages are on ...
4211     (
4212         $frame & 4    # Extended frame entry message
4213         ? (
4214             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
4215
4216             # Why -1? But it works! :-(
4217             # Because print_trace will call add 1 to it and then call
4218             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4219             # in dump_trace.
4220             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4221           )
4222         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4223
4224           # standard frame entry message
4225       )
4226       if $frame;
4227
4228     # Pop the single-step value back off the stack.
4229     $single |= $stack[ $stack_depth-- ];
4230
4231     # call the original lvalue sub.
4232     &$sub;
4233 }
4234
4235 # Abstracting common code from multiple places elsewhere:
4236 sub depth_print_lineinfo {
4237     my $always_print = shift;
4238
4239     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4240 }
4241
4242 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4243
4244 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4245 Most of the changes were to systematize the command structure and to eliminate
4246 commands that threw away user input without checking.
4247
4248 The following sections describe the code added to make it easy to support
4249 multiple command sets with conflicting command names. This section is a start
4250 at unifying all command processing to make it simpler to develop commands.
4251
4252 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4253 number, and C<$dbline> (the current line) as arguments.
4254
4255 Support functions in this section which have multiple modes of failure C<die>
4256 on error; the rest simply return a false value.
4257
4258 The user-interface functions (all of the C<cmd_*> functions) just output
4259 error messages.
4260
4261 =head2 C<%set>
4262
4263 The C<%set> hash defines the mapping from command letter to subroutine
4264 name suffix.
4265
4266 C<%set> is a two-level hash, indexed by set name and then by command name.
4267 Note that trying to set the CommandSet to C<foobar> simply results in the
4268 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4269
4270 =cut
4271
4272 ### The API section
4273
4274 my %set = (    #
4275     'pre580' => {
4276         'a' => 'pre580_a',
4277         'A' => 'pre580_null',
4278         'b' => 'pre580_b',
4279         'B' => 'pre580_null',
4280         'd' => 'pre580_null',
4281         'D' => 'pre580_D',
4282         'h' => 'pre580_h',
4283         'M' => 'pre580_null',
4284         'O' => 'o',
4285         'o' => 'pre580_null',
4286         'v' => 'M',
4287         'w' => 'v',
4288         'W' => 'pre580_W',
4289     },
4290     'pre590' => {
4291         '<'  => 'pre590_prepost',
4292         '<<' => 'pre590_prepost',
4293         '>'  => 'pre590_prepost',
4294         '>>' => 'pre590_prepost',
4295         '{'  => 'pre590_prepost',
4296         '{{' => 'pre590_prepost',
4297     },
4298 );
4299
4300 my %breakpoints_data;
4301
4302 sub _has_breakpoint_data_ref {
4303     my ($filename, $line) = @_;
4304
4305     return (
4306         exists( $breakpoints_data{$filename} )
4307             and
4308         exists( $breakpoints_data{$filename}{$line} )
4309     );
4310 }
4311
4312 sub _get_breakpoint_data_ref {
4313     my ($filename, $line) = @_;
4314
4315     return ($breakpoints_data{$filename}{$line} ||= +{});
4316 }
4317
4318 sub _delete_breakpoint_data_ref {
4319     my ($filename, $line) = @_;
4320
4321     delete($breakpoints_data{$filename}{$line});
4322     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4323         delete($breakpoints_data{$filename});
4324     }
4325
4326     return;
4327 }
4328
4329 sub _set_breakpoint_enabled_status {
4330     my ($filename, $line, $status) = @_;
4331
4332     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4333         ($status ? 1 : '')
4334         ;
4335
4336     return;
4337 }
4338
4339 sub _enable_breakpoint_temp_enabled_status {
4340     my ($filename, $line) = @_;
4341
4342     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4343
4344     return;
4345 }
4346
4347 sub _cancel_breakpoint_temp_enabled_status {
4348     my ($filename, $line) = @_;
4349
4350     my $ref = _get_breakpoint_data_ref($filename, $line);
4351
4352     delete ($ref->{'temp_enabled'});
4353
4354     if (! %$ref) {
4355         _delete_breakpoint_data_ref($filename, $line);
4356     }
4357
4358     return;
4359 }
4360
4361 sub _is_breakpoint_enabled {
4362     my ($filename, $line) = @_;
4363
4364     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4365     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4366 }
4367
4368 =head2 C<cmd_wrapper()> (API)
4369
4370 C<cmd_wrapper()> allows the debugger to switch command sets
4371 depending on the value of the C<CommandSet> option.
4372
4373 It tries to look up the command in the C<%set> package-level I<lexical>
4374 (which means external entities can't fiddle with it) and create the name of
4375 the sub to call based on the value found in the hash (if it's there). I<All>
4376 of the commands to be handled in a set have to be added to C<%set>; if they
4377 aren't found, the 5.8.0 equivalent is called (if there is one).
4378
4379 This code uses symbolic references.
4380
4381 =cut
4382
4383 sub cmd_wrapper {
4384     my $cmd      = shift;
4385     my $line     = shift;
4386     my $dblineno = shift;
4387
4388     # Assemble the command subroutine's name by looking up the
4389     # command set and command name in %set. If we can't find it,
4390     # default to the older version of the command.
4391     my $call = 'cmd_'
4392       . ( $set{$CommandSet}{$cmd}
4393           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4394
4395     # Call the command subroutine, call it by name.
4396     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4397 } ## end sub cmd_wrapper
4398
4399 =head3 C<cmd_a> (command)
4400
4401 The C<a> command handles pre-execution actions. These are associated with a
4402 particular line, so they're stored in C<%dbline>. We default to the current
4403 line if none is specified.
4404
4405 =cut
4406
4407 sub cmd_a {
4408     my $cmd    = shift;
4409     my $line   = shift || '';    # [.|line] expr
4410     my $dbline = shift;
4411
4412     # If it's dot (here), or not all digits,  use the current line.
4413     $line =~ s/\A\./$dbline/;
4414
4415     # Should be a line number followed by an expression.
4416     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4417
4418         if (! length($lineno)) {
4419             $lineno = $dbline;
4420         }
4421
4422         # If we have an expression ...
4423         if ( length $expr ) {
4424
4425             # ... but the line isn't breakable, complain.
4426             if ( $dbline[$lineno] == 0 ) {
4427                 print $OUT
4428                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4429             }
4430             else {
4431
4432                 # It's executable. Record that the line has an action.
4433                 $had_breakpoints{$filename} |= 2;
4434
4435                 # Remove any action, temp breakpoint, etc.
4436                 $dbline{$lineno} =~ s/\0[^\0]*//;
4437
4438                 # Add the action to the line.
4439                 $dbline{$lineno} .= "\0" . action($expr);
4440
4441                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4442             }
4443         } ## end if (length $expr)
4444     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4445     else {
4446
4447         # Syntax wrong.
4448         print $OUT
4449           "Adding an action requires an optional lineno and an expression\n"
4450           ;    # hint
4451     }
4452 } ## end sub cmd_a
4453
4454 =head3 C<cmd_A> (command)
4455
4456 Delete actions. Similar to above, except the delete code is in a separate
4457 subroutine, C<delete_action>.
4458
4459 =cut
4460
4461 sub cmd_A {
4462     my $cmd    = shift;
4463     my $line   = shift || '';
4464     my $dbline = shift;
4465
4466     # Dot is this line.
4467     $line =~ s/^\./$dbline/;
4468
4469     # Call delete_action with a null param to delete them all.
4470     # The '1' forces the eval to be true. It'll be false only
4471     # if delete_action blows up for some reason, in which case
4472     # we print $@ and get out.
4473     if ( $line eq '*' ) {
4474         if (! eval { _delete_all_actions(); 1 }) {
4475             print {$OUT} $@;
4476             return;
4477         }
4478     }
4479
4480     # There's a real line  number. Pass it to delete_action.
4481     # Error trapping is as above.
4482     elsif ( $line =~ /^(\S.*)/ ) {
4483         if (! eval { delete_action($1); 1 }) {
4484             print {$OUT} $@;
4485             return;
4486         }
4487     }
4488
4489     # Swing and a miss. Bad syntax.
4490     else {
4491         print $OUT
4492           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4493     }
4494 } ## end sub cmd_A
4495
4496 =head3 C<delete_action> (API)
4497
4498 C<delete_action> accepts either a line number or C<undef>. If a line number
4499 is specified, we check for the line being executable (if it's not, it
4500 couldn't have had an  action). If it is, we just take the action off (this
4501 will get any kind of an action, including breakpoints).
4502
4503 =cut
4504
4505 sub _remove_action_from_dbline {
4506     my $i = shift;
4507
4508     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4509     delete $dbline{$i} if $dbline{$i} eq '';
4510
4511     return;
4512 }
4513
4514 sub _delete_all_actions {
4515     print {$OUT} "Deleting all actions...\n";
4516
4517     for my $file ( keys %had_breakpoints ) {
4518         local *dbline = $main::{ '_<' . $file };
4519         $max = $#dbline;
4520         my $was;
4521         for my $i (1 .. $max) {
4522             if ( defined $dbline{$i} ) {
4523                 _remove_action_from_dbline($i);
4524             }
4525         }
4526
4527         unless ( $had_breakpoints{$file} &= ~2 ) {
4528             delete $had_breakpoints{$file};
4529         }
4530     }
4531
4532     return;
4533 }
4534
4535 sub delete_action {
4536     my $i = shift;
4537
4538     if ( defined($i) ) {
4539         # Can there be one?
4540         die "Line $i has no action .\n" if $dbline[$i] == 0;
4541
4542         # Nuke whatever's there.
4543         _remove_action_from_dbline($i);
4544     }
4545     else {
4546         _delete_all_actions();
4547     }
4548 }
4549
4550 =head3 C<cmd_b> (command)
4551
4552 Set breakpoints. Since breakpoints can be set in so many places, in so many
4553 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4554 we try to parse the command type, and then shuttle it off to an appropriate
4555 subroutine to actually do the work of setting the breakpoint in the right
4556 place.
4557
4558 =cut
4559
4560 sub cmd_b {
4561     my $cmd    = shift;
4562     my $line   = shift;    # [.|line] [cond]
4563     my $dbline = shift;
4564
4565     my $default_cond = sub {
4566         my $cond = shift;
4567         return length($cond) ? $cond : '1';
4568     };
4569
4570     # Make . the current line number if it's there..
4571     $line =~ s/^\.(\s|\z)/$dbline$1/;
4572
4573     # No line number, no condition. Simple break on current line.
4574     if ( $line =~ /^\s*$/ ) {
4575         cmd_b_line( $dbline, 1 );
4576     }
4577
4578     # Break on load for a file.
4579     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4580         $file =~ s/\s+\z//;
4581         cmd_b_load($file);
4582     }
4583
4584     # b compile|postpone <some sub> [<condition>]
4585     # The interpreter actually traps this one for us; we just put the
4586     # necessary condition in the %postponed hash.
4587     elsif ( my ($action, $subname, $cond)
4588         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4589
4590         # De-Perl4-ify the name - ' separators to ::.
4591         $subname =~ s/'/::/g;
4592
4593         # Qualify it into the current package unless it's already qualified.
4594         $subname = "${package}::" . $subname unless $subname =~ /::/;
4595
4596         # Add main if it starts with ::.
4597         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4598
4599         # Save the break type for this sub.
4600         $postponed{$subname} = (($action eq 'postpone')
4601             ? ( "break +0 if " . $default_cond->($cond) )
4602             : "compile");
4603     } ## end elsif ($line =~ ...
4604     # b <filename>:<line> [<condition>]
4605     elsif (my ($filename, $line_num, $cond)
4606         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4607         cmd_b_filename_line(
4608             $filename,
4609             $line_num,
4610             (length($cond) ? $cond : '1'),
4611         );
4612     }
4613     # b <sub name> [<condition>]
4614     elsif ( my ($new_subname, $new_cond) =
4615         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4616
4617         #
4618         $subname = $new_subname;
4619         cmd_b_sub( $subname, $default_cond->($new_cond) );
4620     }
4621
4622     # b <line> [<condition>].
4623     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4624
4625         # Capture the line. If none, it's the current line.
4626         $line = $line_n || $dbline;
4627
4628         # Break on line.
4629         cmd_b_line( $line, $default_cond->($cond) );
4630     }
4631
4632     # Line didn't make sense.
4633     else {
4634         print "confused by line($line)?\n";
4635     }
4636
4637     return;
4638 } ## end sub cmd_b
4639
4640 =head3 C<break_on_load> (API)
4641
4642 We want to break when this file is loaded. Mark this file in the
4643 C<%break_on_load> hash, and note that it has a breakpoint in
4644 C<%had_breakpoints>.
4645
4646 =cut
4647
4648 sub break_on_load {
4649     my $file = shift;
4650     $break_on_load{$file} = 1;
4651     $had_breakpoints{$file} |= 1;
4652 }
4653
4654 =head3 C<report_break_on_load> (API)
4655
4656 Gives us an array of filenames that are set to break on load. Note that
4657 only files with break-on-load are in here, so simply showing the keys
4658 suffices.
4659
4660 =cut
4661
4662 sub report_break_on_load {
4663     sort keys %break_on_load;
4664 }
4665
4666 =head3 C<cmd_b_load> (command)
4667
4668 We take the file passed in and try to find it in C<%INC> (which maps modules
4669 to files they came from). We mark those files for break-on-load via
4670 C<break_on_load> and then report that it was done.
4671
4672 =cut
4673
4674 sub cmd_b_load {
4675     my $file = shift;
4676     my @files;
4677
4678     # This is a block because that way we can use a redo inside it
4679     # even without there being any looping structure at all outside it.
4680     {
4681
4682         # Save short name and full path if found.
4683         push @files, $file;
4684         push @files, $::INC{$file} if $::INC{$file};
4685
4686         # Tack on .pm and do it again unless there was a '.' in the name
4687         # already.
4688         $file .= '.pm', redo unless $file =~ /\./;
4689     }
4690
4691     # Do the real work here.
4692     break_on_load($_) for @files;
4693
4694     # All the files that have break-on-load breakpoints.
4695     @files = report_break_on_load;
4696
4697     # Normalize for the purposes of our printing this.
4698     local $\ = '';
4699     local $" = ' ';
4700     print $OUT "Will stop on load of '@files'.\n";
4701 } ## end sub cmd_b_load
4702
4703 =head3 C<$filename_error> (API package global)
4704
4705 Several of the functions we need to implement in the API need to work both
4706 on the current file and on other files. We don't want to duplicate code, so
4707 C<$filename_error> is used to contain the name of the file that's being
4708 worked on (if it's not the current one).
4709
4710 We can now build functions in pairs: the basic function works on the current
4711 file, and uses C<$filename_error> as part of its error message. Since this is
4712 initialized to C<"">, no filename will appear when we are working on the
4713 current file.
4714
4715 The second function is a wrapper which does the following:
4716
4717 =over 4
4718
4719 =item *
4720
4721 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4722
4723 =item *
4724
4725 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4726
4727 =item *
4728
4729 Calls the first function.
4730
4731 The first function works on the I<current> file (i.e., the one we changed to),
4732 and prints C<$filename_error> in the error message (the name of the other file)
4733 if it needs to. When the functions return, C<*dbline> is restored to point
4734 to the actual current file (the one we're executing in) and
4735 C<$filename_error> is restored to C<"">. This restores everything to
4736 the way it was before the second function was called at all.
4737
4738 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4739 details.
4740
4741 =back
4742
4743 =cut
4744
4745 use vars qw($filename_error);
4746 $filename_error = '';
4747
4748 =head3 breakable_line(from, to) (API)
4749
4750 The subroutine decides whether or not a line in the current file is breakable.
4751 It walks through C<@dbline> within the range of lines specified, looking for
4752 the first line that is breakable.
4753
4754 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4755 first line I<after> C<$to> that's breakable, if there is one.
4756
4757 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4758 first line I<before> C<$to> that's breakable, if there is one.
4759
4760 =cut
4761
4762 sub breakable_line {
4763
4764     my ( $from, $to ) = @_;
4765
4766     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4767     my $i = $from;
4768
4769     # If there are at least 2 arguments, we're trying to search a range.
4770     if ( @_ >= 2 ) {
4771
4772         # $delta is positive for a forward search, negative for a backward one.
4773         my $delta = $from < $to ? +1 : -1;
4774
4775         # Keep us from running off the ends of the file.
4776         my $limit = $delta > 0 ? $#dbline : 1;
4777
4778         # Clever test. If you're a mathematician, it's obvious why this
4779         # test works. If not:
4780         # If $delta is positive (going forward), $limit will be $#dbline.
4781         #    If $to is less than $limit, ($limit - $to) will be positive, times
4782         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4783         #    as the stopping point.
4784         #
4785         #    If $to is greater than $limit, ($limit - $to) is negative,
4786         #    times $delta of 1 (positive), so the result is < 0 and we should
4787         #    use $limit ($#dbline) as the stopping point.
4788         #
4789         # If $delta is negative (going backward), $limit will be 1.
4790         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4791         #    (negative) so the result is > 0, and we use $to as the stopping
4792         #    point.
4793         #
4794         #    If $to is less than zero, ($limit - $to) will be positive,
4795         #    times $delta of -1 (negative), so the result is not > 0, and
4796         #    we use $limit (1) as the stopping point.
4797         #
4798         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4799         #    (negative), still giving zero; the result is not > 0, and
4800         #    we use $limit (1) as the stopping point.
4801         #
4802         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4803         #    (negative), giving a positive (>0) value, so we'll set $limit to
4804         #    $to.
4805
4806         $limit = $to if ( $limit - $to ) * $delta > 0;
4807
4808         # The real search loop.
4809         # $i starts at $from (the point we want to start searching from).
4810         # We move through @dbline in the appropriate direction (determined
4811         # by $delta: either -1 (back) or +1 (ahead).
4812         # We stay in as long as we haven't hit an executable line
4813         # ($dbline[$i] == 0 means not executable) and we haven't reached
4814         # the limit yet (test similar to the above).
4815         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4816
4817     } ## end if (@_ >= 2)
4818
4819     # If $i points to a line that is executable, return that.
4820     return $i unless $dbline[$i] == 0;
4821
4822     # Format the message and print it: no breakable lines in range.
4823     my ( $pl, $upto ) = ( '', '' );
4824     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4825
4826     # If there's a filename in filename_error, we'll see it.
4827     # If not, not.
4828     die "Line$pl $from$upto$filename_error not breakable\n";
4829 } ## end sub breakable_line
4830
4831 =head3 breakable_line_in_filename(file, from, to) (API)
4832
4833 Like C<breakable_line>, but look in another file.
4834
4835 =cut
4836
4837 sub breakable_line_in_filename {
4838
4839     # Capture the file name.