t/op/gv.t

   1 #!./perl
   2
   3 #
   4 # various typeglob tests
   5 #
   6
   7 BEGIN {
   8     chdir 't' if -d 't';
   9     @INC = '../lib';
  10     require './test.pl';
  11 }
  12
  13 use warnings;
  14
  15 plan( tests => 253 );
  16
  17 # type coercion on assignment
  18 $foo = 'foo';
  19 $bar = *main::foo;
  20 $bar = $foo;
  21 is(ref(\$bar), 'SCALAR');
  22 $foo = *main::bar;
  23
  24 # type coercion (not) on misc ops
  25
  26 ok($foo);
  27 is(ref(\$foo), 'GLOB');
  28
  29 unlike ($foo, qr/abcd/);
  30 is(ref(\$foo), 'GLOB');
  31
  32 is($foo, '*main::bar');
  33 is(ref(\$foo), 'GLOB');
  34
  35 {
  36  no warnings;
  37  ${\*$foo} = undef;
  38  is(ref(\$foo), 'GLOB', 'no type coercion when assigning to *{} retval');
  39  $::{phake} = *bar;
  40  is(
  41    \$::{phake}, \*{"phake"},
  42    'symbolic *{} returns symtab entry when FAKE'
  43  );
  44  ${\*{"phake"}} = undef;
  45  is(
  46    ref(\$::{phake}), 'GLOB',
  47   'no type coercion when assigning to retval of symbolic *{}'
  48  );
  49  $::{phaque} = *bar;
  50  eval '
  51    is(
  52      \$::{phaque}, \*phaque,
  53      "compile-time *{} returns symtab entry when FAKE"
  54    );
  55    ${\*phaque} = undef;
  56  ';
  57  is(
  58    ref(\$::{phaque}), 'GLOB',
  59   'no type coercion when assigning to retval of compile-time *{}'
  60  );
  61 }
  62
  63 # type coercion on substitutions that match
  64 $a = *main::foo;
  65 $b = $a;
  66 $a =~ s/^X//;
  67 is(ref(\$a), 'GLOB');
  68 $a =~ s/^\*//;
  69 is($a, 'main::foo');
  70 is(ref(\$b), 'GLOB');
  71
  72 # typeglobs as lvalues
  73 substr($foo, 0, 1) = "XXX";
  74 is(ref(\$foo), 'SCALAR');
  75 is($foo, 'XXXmain::bar');
  76
  77 # returning glob values
  78 sub foo {
  79   local($bar) = *main::foo;
  80   $foo = *main::bar;
  81   return ($foo, $bar);
  82 }
  83
  84 ($fuu, $baa) = foo();
  85 ok(defined $fuu);
  86 is(ref(\$fuu), 'GLOB');
  87
  88
  89 ok(defined $baa);
  90 is(ref(\$baa), 'GLOB');
  91
  92 # nested package globs
  93 # NOTE:  It's probably OK if these semantics change, because the
  94 #        fact that %X::Y:: is stored in %X:: isn't documented.
  95 #        (I hope.)
  96
  97 { package Foo::Bar; no warnings 'once'; $test=1; }
  98 ok(exists $Foo::{'Bar::'});
  99 is($Foo::{'Bar::'}, '*Foo::Bar::');
 100
 101
 102 # test undef operator clearing out entire glob
 103 $foo = 'stuff';
 104 @foo = qw(more stuff);
 105 %foo = qw(even more random stuff);
 106 undef *foo;
 107 is ($foo, undef);
 108 is (scalar @foo, 0);
 109 is (scalar %foo, 0);
 110
 111 {
 112     # test warnings from assignment of undef to glob
 113     my $msg = '';
 114     local $SIG{__WARN__} = sub { $msg = $_[0] };
 115     use warnings;
 116     *foo = 'bar';
 117     is($msg, '');
 118     *foo = undef;
 119     like($msg, qr/Undefined value assigned to typeglob/);
 120
 121     no warnings 'once';
 122     # test warnings for converting globs to other forms
 123     my $copy = *PWOMPF;
 124     foreach ($copy, *SKREEE) {
 125         $msg = '';
 126         my $victim = sprintf "%d", $_;
 127         like($msg, qr/Argument "\*main::[A-Z]{6}" isn't numeric in sprintf/,
 128              "Warning on conversion to IV");
 129         is($victim, 0);
 130
 131         $msg = '';
 132         $victim = sprintf "%u", $_;
 133         like($msg, qr/Argument "\*main::[A-Z]{6}" isn't numeric in sprintf/,
 134              "Warning on conversion to UV");
 135         is($victim, 0);
 136
 137         $msg = '';
 138         $victim = sprintf "%e", $_;
 139         like($msg, qr/Argument "\*main::[A-Z]{6}" isn't numeric in sprintf/,
 140              "Warning on conversion to NV");
 141         like($victim, qr/^0\.0+E\+?00/i, "Expect floating point zero");
 142
 143         $msg = '';
 144         $victim = sprintf "%s", $_;
 145         is($msg, '', "No warning on stringification");
 146         is($victim, '' . $_);
 147     }
 148 }
 149
 150 my $test = curr_test();
 151 # test *glob{THING} syntax
 152 $x = "ok $test\n";
 153 ++$test;
 154 @x = ("ok $test\n");
 155 ++$test;
 156 %x = ("ok $test" => "\n");
 157 ++$test;
 158 sub x { "ok $test\n" }
 159 print ${*x{SCALAR}}, @{*x{ARRAY}}, %{*x{HASH}}, &{*x{CODE}};
 160 # This needs to go here, after the print, as sub x will return the current
 161 # value of test
 162 ++$test;
 163 format x =
 164 XXX This text isn't used. Should it be?
 165 .
 166 curr_test($test);
 167
 168 is (ref *x{FORMAT}, "FORMAT");
 169 is ("@{sub { *_{ARRAY} }->(1..3)}", "1 2 3",
 170     'returning *_{ARRAY} from sub');
 171 *x = *STDOUT;
 172 is (*{*x{GLOB}}, "*main::STDOUT");
 173
 174 {
 175     my $test = curr_test();
 176
 177     print {*x{IO}} "ok $test\n";
 178     ++$test;
 179
 180     my $warn;
 181     local $SIG{__WARN__} = sub {
 182         $warn .= $_[0];
 183     };
 184     my $val = *x{FILEHANDLE};
 185     print {*x{IO}} ($warn =~ /is deprecated/
 186                     ? "ok $test\n" : "not ok $test\n");
 187     curr_test(++$test);
 188 }
 189
 190 is *x{NAME}, 'x', '*foo{NAME}';
 191 is *x{PACKAGE}, 'main', '*foo{PACKAGE}';
 192 { no warnings 'once'; *x = *Foo::y; }
 193 is *x, '*Foo::y', 'glob stringifies as assignee after glob-to-glob assign';
 194 is *x{NAME}, 'x', 'but *foo{NAME} still returns the original name';
 195 is *x{PACKAGE}, 'main', 'and *foo{PACKAGE} the original package';
 196
 197 {
 198     # test if defined() doesn't create any new symbols
 199
 200     my $a = "SYM000";
 201     ok(!defined *{$a});
 202
 203     {
 204         no warnings 'deprecated';
 205         ok(!defined @{$a});
 206     }
 207     ok(!defined *{$a});
 208
 209     {
 210         no warnings 'deprecated';
 211         ok(!defined %{$a});
 212     }
 213     ok(!defined *{$a});
 214
 215     ok(!defined ${$a});
 216     ok(!defined *{$a});
 217
 218     ok(!defined &{$a});
 219     ok(!defined *{$a});
 220
 221     my $state = "not";
 222     *{$a} = sub { $state = "ok" };
 223     ok(defined &{$a});
 224     ok(defined *{$a});
 225     &{$a};
 226     is ($state, 'ok');
 227 }
 228
 229 {
 230     # although it *should* if you're talking about magicals
 231
 232     my $a = "]";
 233     ok(defined *{$a});
 234     ok(defined ${$a});
 235
 236     $a = "1";
 237     "o" =~ /(o)/;
 238     ok(${$a});
 239     ok(defined *{$a});
 240     $a = "2";
 241     ok(!${$a});
 242     ok(defined *{$a});
 243     $a = "1x";
 244     ok(!defined ${$a});
 245     ok(!defined *{$a});
 246     $a = "11";
 247     "o" =~ /(((((((((((o)))))))))))/;
 248     ok(${$a});
 249     ok(defined *{$a});
 250 }
 251
 252 # [ID 20010526.001] localized glob loses value when assigned to
 253
 254 $j=1; %j=(a=>1); @j=(1); local *j=*j; *j = sub{};
 255
 256 is($j, 1);
 257 is($j{a}, 1);
 258 is($j[0], 1);
 259
 260 {
 261     # does pp_readline() handle glob-ness correctly?
 262     my $g = *foo;
 263     $g = <DATA>;
 264     is ($g, "Perl\n");
 265 }
 266
 267 {
 268     my $w = '';
 269     local $SIG{__WARN__} = sub { $w = $_[0] };
 270     sub abc1 ();
 271     local *abc1 = sub { };
 272     is ($w, '');
 273     sub abc2 ();
 274     local *abc2;
 275     *abc2 = sub { };
 276     is ($w, '');
 277     sub abc3 ();
 278     *abc3 = sub { };
 279     like ($w, qr/Prototype mismatch/);
 280 }
 281
 282 {
 283     # [17375] rcatline to formerly-defined undef was broken. Fixed in
 284     # do_readline by checking SvOK. AMS, 20020918
 285     my $x = "not ";
 286     $x  = undef;
 287     $x .= <DATA>;
 288     is ($x, "Rules\n");
 289 }
 290
 291 {
 292     # test the assignment of a GLOB to an LVALUE
 293     my $e = '';
 294     local $SIG{__DIE__} = sub { $e = $_[0] };
 295     my %v;
 296     sub f { $_[0] = 0; $_[0] = "a"; $_[0] = *DATA }
 297     f($v{v});
 298     is ($v{v}, '*main::DATA');
 299     is (ref\$v{v}, 'GLOB', 'lvalue assignment preserves globs');
 300     my $x = readline $v{v};
 301     is ($x, "perl\n");
 302     is ($e, '', '__DIE__ handler never called');
 303 }
 304
 305 {
 306     my $e = '';
 307     # GLOB assignment to tied element
 308     local $SIG{__DIE__} = sub { $e = $_[0] };
 309     sub T::TIEARRAY  { bless [] => "T" }
 310     sub T::STORE     { $_[0]->[ $_[1] ] = $_[2] }
 311     sub T::FETCH     { $_[0]->[ $_[1] ] }
 312     sub T::FETCHSIZE { @{$_[0]} }
 313     tie my @ary => "T";
 314     $ary[0] = *DATA;
 315     is ($ary[0], '*main::DATA');
 316     is (
 317       ref\tied(@ary)->[0], 'GLOB',
 318      'tied elem assignment preserves globs'
 319     );
 320     is ($e, '', '__DIE__ handler not called');
 321     my $x = readline $ary[0];
 322     is($x, "rocks\n");
 323     is ($e, '', '__DIE__ handler never called');
 324 }
 325
 326 {
 327     # Need some sort of die or warn to get the global destruction text if the
 328     # bug is still present
 329     my $output = runperl(prog => <<'EOPROG');
 330 package M;
 331 $| = 1;
 332 sub DESTROY {eval {die qq{Farewell $_[0]}}; print $@}
 333 package main;
 334
 335 bless \$A::B, q{M};
 336 *A:: = \*B::;
 337 EOPROG
 338     like($output, qr/^Farewell M=SCALAR/, "DESTROY was called");
 339     unlike($output, qr/global destruction/,
 340            "unreferenced symbol tables should be cleaned up immediately");
 341 }
 342
 343 # Possibly not the correct test file for these tests.
 344 # There are certain space optimisations implemented via promotion rules to
 345 # GVs
 346
 347 foreach (qw (oonk ga_shloip)) {
 348     ok(!exists $::{$_}, "no symbols of any sort to start with for $_");
 349 }
 350
 351 # A string in place of the typeglob is promoted to the function prototype
 352 $::{oonk} = "pie";
 353 my $proto = eval 'prototype \&oonk';
 354 die if $@;
 355 is ($proto, "pie", "String is promoted to prototype");
 356
 357
 358 # A reference to a value is used to generate a constant subroutine
 359 foreach my $value (3, "Perl rules", \42, qr/whatever/, [1,2,3], {1=>2},
 360                    \*STDIN, \&ok, \undef, *STDOUT) {
 361     delete $::{oonk};
 362     $::{oonk} = \$value;
 363     $proto = eval 'prototype \&oonk';
 364     die if $@;
 365     is ($proto, '', "Prototype for a constant subroutine is empty");
 366
 367     my $got = eval 'oonk';
 368     die if $@;
 369     is (ref $got, ref $value, "Correct type of value (" . ref($value) . ")");
 370     is ($got, $value, "Value is correctly set");
 371 }
 372
 373 delete $::{oonk};
 374 $::{oonk} = \"Value";
 375
 376 *{"ga_shloip"} = \&{"oonk"};
 377
 378 is (ref $::{ga_shloip}, 'SCALAR', "Export of proxy constant as is");
 379 is (ref $::{oonk}, 'SCALAR', "Export doesn't affect original");
 380 is (eval 'ga_shloip', "Value", "Constant has correct value");
 381 is (ref $::{ga_shloip}, 'SCALAR',
 382     "Inlining of constant doesn't change representation");
 383
 384 delete $::{ga_shloip};
 385
 386 eval 'sub ga_shloip (); 1' or die $@;
 387 is ($::{ga_shloip}, '', "Prototype is stored as an empty string");
 388
 389 # Check that a prototype expands.
 390 *{"ga_shloip"} = \&{"oonk"};
 391
 392 is (ref $::{oonk}, 'SCALAR', "Export doesn't affect original");
 393 is (eval 'ga_shloip', "Value", "Constant has correct value");
 394 is (ref \$::{ga_shloip}, 'GLOB', "Symbol table has full typeglob");
 395
 396
 397 @::zwot = ('Zwot!');
 398
 399 # Check that assignment to an existing typeglob works
 400 {
 401   my $w = '';
 402   local $SIG{__WARN__} = sub { $w = $_[0] };
 403   *{"zwot"} = \&{"oonk"};
 404   is($w, '', "Should be no warning");
 405 }
 406
 407 is (ref $::{oonk}, 'SCALAR', "Export doesn't affect original");
 408 is (eval 'zwot', "Value", "Constant has correct value");
 409 is (ref \$::{zwot}, 'GLOB', "Symbol table has full typeglob");
 410 is (join ('!', @::zwot), 'Zwot!', "Existing array still in typeglob");
 411
 412 sub spritsits () {
 413     "Traditional";
 414 }
 415
 416 # Check that assignment to an existing subroutine works
 417 {
 418   my $w = '';
 419   local $SIG{__WARN__} = sub { $w = $_[0] };
 420   *{"spritsits"} = \&{"oonk"};
 421   like($w, qr/^Constant subroutine main::spritsits redefined/,
 422        "Redefining a constant sub should warn");
 423 }
 424
 425 is (ref $::{oonk}, 'SCALAR', "Export doesn't affect original");
 426 is (eval 'spritsits', "Value", "Constant has correct value");
 427 is (ref \$::{spritsits}, 'GLOB', "Symbol table has full typeglob");
 428
 429 # Check that assignment to an existing typeglob works
 430 {
 431   my $w = '';
 432   local $SIG{__WARN__} = sub { $w = $_[0] };
 433   *{"plunk"} = [];
 434   *{"plunk"} = \&{"oonk"};
 435   is($w, '', "Should be no warning");
 436 }
 437
 438 is (ref $::{oonk}, 'SCALAR', "Export doesn't affect original");
 439 is (eval 'plunk', "Value", "Constant has correct value");
 440 is (ref \$::{plunk}, 'GLOB', "Symbol table has full typeglob");
 441
 442 my $gr = eval '\*plunk' or die;
 443
 444 {
 445   my $w = '';
 446   local $SIG{__WARN__} = sub { $w = $_[0] };
 447   *{$gr} = \&{"oonk"};
 448   is($w, '', "Redefining a constant sub to another constant sub with the same underlying value should not warn (It's just re-exporting, and that was always legal)");
 449 }
 450
 451 is (ref $::{oonk}, 'SCALAR', "Export doesn't affect original");
 452 is (eval 'plunk', "Value", "Constant has correct value");
 453 is (ref \$::{plunk}, 'GLOB', "Symbol table has full typeglob");
 454
 455 # Non-void context should defeat the optimisation, and will cause the original
 456 # to be promoted (what change 26482 intended)
 457 my $result;
 458 {
 459   my $w = '';
 460   local $SIG{__WARN__} = sub { $w = $_[0] };
 461   $result = *{"awkkkkkk"} = \&{"oonk"};
 462   is($w, '', "Should be no warning");
 463 }
 464
 465 is (ref \$result, 'GLOB',
 466     "Non void assignment should still return a typeglob");
 467
 468 is (ref \$::{oonk}, 'GLOB', "This export does affect original");
 469 is (eval 'plunk', "Value", "Constant has correct value");
 470 is (ref \$::{plunk}, 'GLOB', "Symbol table has full typeglob");
 471
 472 delete $::{oonk};
 473 $::{oonk} = \"Value";
 474
 475 sub non_dangling {
 476   my $w = '';
 477   local $SIG{__WARN__} = sub { $w = $_[0] };
 478   *{"zap"} = \&{"oonk"};
 479   is($w, '', "Should be no warning");
 480 }
 481
 482 non_dangling();
 483 is (ref $::{oonk}, 'SCALAR', "Export doesn't affect original");
 484 is (eval 'zap', "Value", "Constant has correct value");
 485 is (ref $::{zap}, 'SCALAR', "Exported target is also a PCS");
 486
 487 sub dangling {
 488   local $SIG{__WARN__} = sub { die $_[0] };
 489   *{"biff"} = \&{"oonk"};
 490 }
 491
 492 dangling();
 493 is (ref \$::{oonk}, 'GLOB', "This export does affect original");
 494 is (eval 'biff', "Value", "Constant has correct value");
 495 is (ref \$::{biff}, 'GLOB', "Symbol table has full typeglob");
 496
 497 $::{yarrow} = [4,5,6];
 498 is join("-", eval "yarrow()"), '4-5-6', 'array ref as stash elem';
 499 is ref $::{yarrow}, "ARRAY", 'stash elem is still array ref after use';
 500 is join("-", eval "&yarrow"), '4-5-6', 'calling const list with &';
 501 is join("-", eval "&yarrow(1..10)"), '4-5-6', 'const list ignores & args';
 502 is prototype "yarrow", "", 'const list has "" prototype';
 503 is eval "yarrow", 3, 'const list in scalar cx returns length';
 504
 505 {
 506     use vars qw($glook $smek $foof);
 507     # Check reference assignment isn't affected by the SV type (bug #38439)
 508     $glook = 3;
 509     $smek = 4;
 510     $foof = "halt and cool down";
 511
 512     my $rv = \*smek;
 513     is($glook, 3);
 514     *glook = $rv;
 515     is($glook, 4);
 516
 517     my $pv = "";
 518     $pv = \*smek;
 519     is($foof, "halt and cool down");
 520     *foof = $pv;
 521     is($foof, 4);
 522 }
 523
 524 format =
 525 .
 526
 527 foreach my $value ({1=>2}, *STDOUT{IO}, \&ok, *STDOUT{FORMAT}) {
 528     # *STDOUT{IO} returns a reference to a PVIO. As it's blessed, ref returns
 529     # IO::Handle, which isn't what we want.
 530     my $type = $value;
 531     $type =~ s/.*=//;
 532     $type =~ s/\(.*//;
 533     delete $::{oonk};
 534     $::{oonk} = $value;
 535     $proto = eval 'prototype \&oonk';
 536     like ($@, qr/^Cannot convert a reference to $type to typeglob/,
 537           "Cannot upgrade ref-to-$type to typeglob");
 538 }
 539
 540 {
 541     no warnings qw(once uninitialized);
 542     my $g = \*clatter;
 543     my $r = eval {no strict; ${*{$g}{SCALAR}}};
 544     is ($@, '', "PERL_DONT_CREATE_GVSV shouldn't affect thingy syntax");
 545
 546     $g = \*vowm;
 547     $r = eval {use strict; ${*{$g}{SCALAR}}};
 548     is ($@, '',
 549         "PERL_DONT_CREATE_GVSV shouldn't affect thingy syntax under strict");
 550 }
 551
 552 {
 553     # Bug reported by broquaint on IRC
 554     *slosh::{HASH}->{ISA}=[];
 555     slosh->import;
 556     pass("gv_fetchmeth coped with the unexpected");
 557
 558     # An audit found these:
 559     {
 560         package slosh;
 561         sub rip {
 562             my $s = shift;
 563             $s->SUPER::rip;
 564         }
 565     }
 566     eval {slosh->rip;};
 567     like ($@, qr/^Can't locate object method "rip"/, "Even with SUPER");
 568
 569     is(slosh->isa('swoosh'), '');
 570
 571     $CORE::GLOBAL::{"lock"}=[];
 572     eval "no warnings; lock";
 573     like($@, qr/^Not enough arguments for lock/,
 574        "Can't trip up general keyword overloading");
 575
 576     $CORE::GLOBAL::{"readline"}=[];
 577     eval "<STDOUT> if 0";
 578     is($@, '', "Can't trip up readline overloading");
 579
 580     $CORE::GLOBAL::{"readpipe"}=[];
 581     eval "`` if 0";
 582     is($@, '', "Can't trip up readpipe overloading");
 583 }
 584
 585 {
 586     die if exists $::{BONK};
 587     $::{BONK} = \"powie";
 588     *{"BONK"} = \&{"BONK"};
 589     eval 'is(BONK(), "powie",
 590              "Assignment works when glob created midway (bug 45607)"); 1'
 591         or die $@;
 592 }
 593
 594 # For now these tests are here, but they would probably be better in a file for
 595 # tests for croaks. (And in turn, that probably deserves to be in a different
 596 # directory. Gerard Goossen has a point about the layout being unclear
 597
 598 sub coerce_integer {
 599     no warnings 'numeric';
 600     $_[0] |= 0;
 601 }
 602 sub coerce_number {
 603     no warnings 'numeric';
 604     $_[0] += 0;
 605 }
 606 sub coerce_string {
 607     $_[0] .= '';
 608 }
 609
 610 foreach my $type (qw(integer number string)) {
 611     my $prog = "coerce_$type(*STDERR)";
 612     is (scalar eval "$prog; 1", undef, "$prog failed...");
 613     like ($@, qr/Can't coerce GLOB to $type in/,
 614           "with the correct error message");
 615 }
 616
 617 # RT #65582 anonymous glob should be defined, and not coredump when
 618 # stringified. The behaviours are:
 619 #
 620 #        defined($glob)    "$glob"                   $glob .= ...
 621 # 5.8.8     false           "" with uninit warning   "" with uninit warning
 622 # 5.10.0    true            (coredump)               (coredump)
 623 # 5.1[24]   true            ""                       "" with uninit warning
 624 # 5.16      true            "*__ANON__::..."         "*__ANON__::..."
 625
 626 {
 627     my $io_ref = *STDOUT{IO};
 628     my $glob = *$io_ref;
 629     ok(defined $glob, "RT #65582 anon glob should be defined");
 630
 631     my $warn = '';
 632     local $SIG{__WARN__} = sub { $warn = $_[0] };
 633     use warnings;
 634     my $str = "$glob";
 635     is($warn, '', "RT #65582 anon glob stringification shouldn't warn");
 636     is($str,  '*__ANON__::__ANONIO__',
 637         "RT #65582/#96326 anon glob stringification");
 638 }
 639
 640 # Another stringification bug: Test that recursion does not cause lexical
 641 # handles to lose their names.
 642 sub r {
 643     my @output;
 644     @output = r($_[0]-1) if $_[0];
 645     open my $fh, "TEST";
 646     push @output, $$fh;
 647     close $fh;
 648     @output;
 649 }
 650 is join(' ', r(4)),
 651   '*main::$fh *main::$fh *main::$fh *main::$fh *main::$fh',
 652   'recursion does not cause lex handles to lose their names';
 653
 654 # [perl #71254] - Assigning a glob to a variable that has a current
 655 # match position. (We are testing that Perl_magic_setmglob respects globs'
 656 # special used of SvSCREAM.)
 657 {
 658     $m = 2; $m=~s/./0/gems; $m= *STDERR;
 659     is(
 660         "$m", "*main::STDERR",
 661         '[perl #71254] assignment of globs to vars with pos'
 662     );
 663 }
 664
 665 # [perl #72740] - indirect object syntax, heuristically imputed due to
 666 # the non-existence of a function, should not cause a stash entry to be
 667 # created for the non-existent function.
 668 {
 669         package RT72740a;
 670         my $f = bless({}, RT72740b);
 671         sub s1 { s2 $f; }
 672         our $s4;
 673         sub s3 { s4 $f; }
 674 }
 675 {
 676         package RT72740b;
 677         sub s2 { "RT72740b::s2" }
 678         sub s4 { "RT72740b::s4" }
 679 }
 680 ok(exists($RT72740a::{s1}), "RT72740a::s1 exists");
 681 ok(!exists($RT72740a::{s2}), "RT72740a::s2 does not exist");
 682 ok(exists($RT72740a::{s3}), "RT72740a::s3 exists");
 683 ok(exists($RT72740a::{s4}), "RT72740a::s4 exists");
 684 is(RT72740a::s1(), "RT72740b::s2", "RT72740::s1 parsed correctly");
 685 is(RT72740a::s3(), "RT72740b::s4", "RT72740::s3 parsed correctly");
 686
 687 # [perl #71686] Globs that are in symbol table can be un-globbed
 688 $sym = undef;
 689 $::{fake} = *sym;
 690 is (eval 'local *::fake = \"chuck"; $fake', 'chuck',
 691         "Localized glob didn't coerce into a RV");
 692 is ($@, '', "Can localize FAKE glob that's present in stash");
 693 is (scalar $::{fake}, "*main::sym",
 694         "Localized FAKE glob's value was correctly restored");
 695
 696 # [perl #1804] *$x assignment when $x is a copy of another glob
 697 # And [perl #77508] (same thing with list assignment)
 698 {
 699     no warnings 'once';
 700     my $x = *_random::glob_that_is_not_used_elsewhere;
 701     *$x = sub{};
 702     is(
 703       "$x", '*_random::glob_that_is_not_used_elsewhere',
 704       '[perl #1804] *$x assignment when $x is FAKE',
 705     );
 706     $x = *_random::glob_that_is_not_used_elsewhere;
 707     (my $dummy, *$x) = (undef,[]);
 708     is(
 709       "$x", '*_random::glob_that_is_not_used_elsewhere',
 710       '[perl #77508] *$x list assignment when $x is FAKE',
 711     ) or require Devel::Peek, Devel::Peek::Dump($x);
 712 }
 713
 714 # [perl #76540]
 715 # this caused panics or 'Attempt to free unreferenced scalar'
 716 # (its a compile-time issue, so the die lets us skip the prints)
 717 {
 718     my @warnings;
 719     local $SIG{__WARN__} = sub { push @warnings, @_ };
 720
 721     eval <<'EOF';
 722 BEGIN { $::{FOO} = \'bar' }
 723 die "made it";
 724 print FOO, "\n";
 725 print FOO, "\n";
 726 EOF
 727
 728     like($@, qr/made it/, "#76540 - no panic");
 729     ok(!@warnings, "#76540 - no 'Attempt to free unreferenced scalar'");
 730 }
 731
 732 # [perl #77362] various bugs related to globs as PVLVs
 733 {
 734  no warnings qw 'once void';
 735  my %h; # We pass a key of this hash to the subroutine to get a PVLV.
 736  sub { for(shift) {
 737   # Set up our glob-as-PVLV
 738   $_ = *hon;
 739
 740   # Bad symbol for array
 741   ok eval{ @$_; 1 }, 'PVLV glob slots can be autovivified' or diag $@;
 742
 743   # This should call TIEHANDLE, not TIESCALAR
 744   *thext::TIEHANDLE = sub{};
 745   ok eval{ tie *$_, 'thext'; 1 }, 'PVLV globs can be tied as handles'
 746    or diag $@;
 747
 748   # Assigning undef to the glob should not overwrite it...
 749   {
 750    my $w;
 751    local $SIG{__WARN__} = sub { $w = shift };
 752    *$_ = undef;
 753    is $_, "*main::hon", 'PVLV: assigning undef to the glob does nothing';
 754    like $w, qr\Undefined value assigned to typeglob\,
 755     'PVLV: assigning undef to the glob warns';
 756   }
 757
 758   # Neither should reference assignment.
 759   *$_ = [];
 760   is $_, "*main::hon", "PVLV: arrayref assignment assigns to the AV slot";
 761
 762   # Concatenation should still work.
 763   ok eval { $_ .= 'thlew' }, 'PVLV concatenation does not die' or diag $@;
 764   is $_, '*main::honthlew', 'PVLV concatenation works';
 765
 766   # And we should be able to overwrite it with a string, number, or refer-
 767   # ence, too, if we omit the *.
 768   $_ = *hon; $_ = 'tzor';
 769   is $_, 'tzor', 'PVLV: assigning a string over a glob';
 770   $_ = *hon; $_ = 23;
 771   is $_, 23, 'PVLV: assigning an integer over a glob';
 772   $_ = *hon; $_ = 23.23;
 773   is $_, 23.23, 'PVLV: assigning a float over a glob';
 774   $_ = *hon; $_ = \my $sthat;
 775   is $_, \$sthat, 'PVLV: assigning a reference over a glob';
 776
 777   # This bug was found by code inspection. Could this ever happen in
 778   # real life? :-)
 779   # This duplicates a file handle, accessing it through a PVLV glob, the
 780   # glob having been removed from the symbol table, so a stringified form
 781   # of it does not work. This checks that sv_2io does not stringify a PVLV.
 782   $_ = *quin;
 783   open *quin, "test.pl"; # test.pl is as good a file as any
 784   delete $::{quin};
 785   ok eval { open my $zow, "<&", $_ }, 'PVLV: sv_2io stringifieth not'
 786    or diag $@;
 787
 788   # Similar tests to make sure sv_2cv etc. do not stringify.
 789   *$_ = sub { 1 };
 790   ok eval { &$_ }, "PVLV glob can be called as a sub" or diag $@;
 791   *flelp = sub { 2 };
 792   $_ = 'flelp';
 793   is eval { &$_ }, 2, 'PVLV holding a string can be called as a sub'
 794    or diag $@;
 795
 796   # Coderef-to-glob assignment when the glob is no longer accessible
 797   # under its name: These tests are to make sure the OPpASSIGN_CV_TO_GV
 798   # optimisation takes PVLVs into account, which is why the RHSs have to be
 799   # named subs.
 800   use constant gheen => 'quare';
 801   $_ = *ming;
 802   delete $::{ming};
 803   *$_ = \&gheen;
 804   is eval { &$_ }, 'quare',
 805    'PVLV: constant assignment when the glob is detached from the symtab'
 806     or diag $@;
 807   $_ = *bength;
 808   delete $::{bength};
 809   *gheck = sub { 'lon' };
 810   *$_ = \&gheck;
 811   is eval { &$_ }, 'lon',
 812    'PVLV: coderef assignment when the glob is detached from the symtab'
 813     or diag $@;
 814
 815 SKIP: {
 816     skip_if_miniperl("no dynamic loading on miniperl, so can't load PerlIO::scalar", 1);
 817     # open should accept a PVLV as its first argument
 818     $_ = *hon;
 819     ok eval { open $_,'<', \my $thlext }, 'PVLV can be the first arg to open'
 820         or diag $@;
 821   }
 822
 823   # -t should not stringify
 824   $_ = *thlit; delete $::{thlit};
 825   *$_ = *STDOUT{IO};
 826   ok defined -t $_, 'PVLV: -t does not stringify';
 827
 828   # neither should -T
 829   # but some systems don’t support this on file handles
 830   my $pass;
 831   ok
 832     eval {
 833      open my $quile, "<", 'test.pl';
 834      $_ = *$quile;
 835      $pass = -T $_;
 836      1
 837     } ? $pass : $@ =~ /not implemented on filehandles/,
 838    "PVLV: -T does not stringify";
 839
 840   # Unopened file handle
 841   {
 842    my $w;
 843    local $SIG{__WARN__} = sub { $w .= shift };
 844    $_ = *vor;
 845    close $_;
 846    like $w, qr\unopened filehandle vor\,
 847     'PVLV globs get their names reported in unopened error messages';
 848   }
 849
 850  }}->($h{k});
 851 }
 852
 853 *aieee = 4;
 854 pass('Can assign integers to typeglobs');
 855 *aieee = 3.14;
 856 pass('Can assign floats to typeglobs');
 857 *aieee = 'pi';
 858 pass('Can assign strings to typeglobs');
 859
 860 {
 861   package thrext;
 862   sub TIESCALAR{bless[]}
 863   sub STORE{ die "No!"}
 864   sub FETCH{ no warnings 'once'; *thrit }
 865   tie my $a, "thrext";
 866   () = "$a"; # do a fetch; now $a holds a glob
 867   eval { *$a = sub{} };
 868   untie $a;
 869   eval { $a = "bar" };
 870   ::is $a, "bar",
 871     "[perl #77812] Globs in tied scalars can be reified if STORE dies"
 872 }
 873
 874 # These two crashed prior to 5.13.6. In 5.13.6 they were fatal errors. They
 875 # were fixed in 5.13.7.
 876 ok eval {
 877   my $glob = \*heen::ISA;
 878   delete $::{"heen::"};
 879   *$glob = *bar;
 880 }, "glob-to-*ISA assignment works when *ISA has lost its stash";
 881 ok eval {
 882   my $glob = \*slare::ISA;
 883   delete $::{"slare::"};
 884   *$glob = [];
 885 }, "array-to-*ISA assignment works when *ISA has lost its stash";
 886 # These two crashed in 5.13.6. They were likewise fixed in 5.13.7.
 887 ok eval {
 888   sub greck;
 889   my $glob = do { no warnings "once"; \*phing::foo};
 890   delete $::{"phing::"};
 891   *$glob = *greck;
 892 }, "Assigning a glob-with-sub to a glob that has lost its stash works";
 893 ok eval {
 894   sub pon::foo;
 895   my $glob = \*pon::foo;
 896   delete $::{"pon::"};
 897   *$glob = *foo;
 898 }, "Assigning a glob to a glob-with-sub that has lost its stash works";
 899
 900 {
 901   package Tie::Alias;
 902   sub TIESCALAR{ bless \\pop }
 903   sub FETCH { $${$_[0]} }
 904   sub STORE { $${$_[0]} = $_[1] }
 905   package main;
 906   tie my $alias, 'Tie::Alias', my $var;
 907   no warnings 'once';
 908   $var = *galobbe;
 909   {
 910     local *$alias = [];
 911     $var = 3;
 912     is $alias, 3, "[perl #77926] Glob reification during localisation";
 913   }
 914 }
 915
 916 # This code causes gp_free to call a destructor when a glob is being
 917 # restored on scope exit. The destructor used to see SVs with a refcount of
 918 # zero inside the glob, which could result in crashes (though not in this
 919 # test case, which just panics).
 920 {
 921  no warnings 'once';
 922  my $survived;
 923  *Trit::DESTROY = sub {
 924    $thwext = 42;  # panic
 925    $survived = 1;
 926  };
 927  {
 928   local *thwext;
 929   $thwext = bless[],'Trit';
 930   ();
 931  }
 932  ok $survived,
 933   'no error when gp_free calls a destructor that assigns to the gv';
 934 }
 935
 936 # *{undef}
 937 eval { *{my $undef} = 3 };
 938 like $@, qr/^Can't use an undefined value as a symbol reference at /,
 939   '*{ $undef } assignment';
 940 eval { *{;undef} = 3 };
 941 like $@, qr/^Can't use an undefined value as a symbol reference at /,
 942   '*{ ;undef } assignment';
 943
 944 # [perl #99142] defined &{"foo"} when there is a constant stub
 945 # If I break your module, you get to have it mentioned in Perl's tests. :-)
 946 package HTTP::MobileAttribute::Plugin::Locator {
 947     use constant LOCATOR_GPS => 1;
 948     ::ok defined &{__PACKAGE__."::LOCATOR_GPS"},
 949         'defined &{"name of constant"}';
 950     ::ok Internals::SvREFCNT(${__PACKAGE__."::"}{LOCATOR_GPS}),
 951        "stash elem for slot is not freed prematurely";
 952 }
 953
 954 # Check that constants promoted to CVs point to the right GVs when the name
 955 # contains a null.
 956 package lrcg {
 957   use constant x => 3;
 958   # These two lines abuse the optimisation that copies the scalar ref from
 959   # one stash element to another, to get a constant with a null in its name
 960   *{"yz\0a"} = \&{"x"};
 961   my $ref = \&{"yz\0a"};
 962   ::ok !exists $lrcg::{yz},
 963     'constants w/nulls in their names point 2 the right GVs when promoted';
 964 }
 965
 966 # Look away, please.
 967 # This violates perl's internal structures by fiddling with stashes in a
 968 # way that should never happen, but perl should not start trying to free
 969 # unallocated memory as a result.  There is no ok() or is() because the
 970 # panic that used to occur only occurred during global destruction, and
 971 # only with PERL_DESTRUCT_LEVEL=2.  (The panic itself was sufficient for
 972 # the harness to consider this test script to have failed.)
 973 $::{aoeuaoeuaoeaoeu} = __PACKAGE__; # cow
 974 () = *{"aoeuaoeuaoeaoeu"};
 975
 976 $x = *_119051;
 977 $y = \&$x;
 978 undef $x;
 979 eval { &$y };
 980 pass "No crash due to CvGV(vivified stub) pointing to flattened glob copy";
 981 # Not really supported, but this should not crash either:
 982 $x = *_119051again;
 983 delete $::{_119051again};
 984 $::{_119051again} = $x;    # now we have a fake glob under the right name
 985 $y = \&$x;                 # so when this tries to look up the right GV for
 986 undef $::{_119051again};   # CvGV, it still gets a fake one
 987 eval { $y->() };
 988 pass "No crash due to CvGV pointing to glob copy in the stash";
 989
 990 __END__
 991 Perl
 992 Rules
 993 perl
 994 rocks