This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Generate some delta tables
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Prior to 5.14, generally a property would have either its
166 # map table or its match tables written but not both.  Again, what gets
167 # written is controlled by lists which can easily be changed.  Starting in
168 # 5.14, advantage was taken of this, and all the map tables needed to
169 # reconstruct the Unicode db are now written out, while suppressing the
170 # Unicode .txt files that contain the data.  Our tables are much more compact
171 # than the .txt files, so a significant space savings was achieved.
172
173 # Properties have a 'Type', like binary, or string, or enum depending on how
174 # many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably.  For example, no
185 # folding information was given in early releases, so this program substitutes
186 # lower case instead, just so that a regular expression with the /i option
187 # will do something that actually gives the right results in many cases.
188 # There are also a couple other corrections for version 1.1.5, commented at
189 # the point they are made.  As an example of corrections that weren't made
190 # (but could be) is this statement from DerivedAge.txt: "The supplementary
191 # private use code points and the non-character code points were assigned in
192 # version 2.0, but not specifically listed in the UCD until versions 3.0 and
193 # 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0) More information
194 # on Unicode version glitches is further down in these introductory comments.
195 #
196 # This program works on all non-provisional properties as of 6.0, though the
197 # files for some are suppressed from apparent lack of demand for them.  You
198 # can change which are output by changing lists in this program.
199 #
200 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
201 # loose matchings rules (from Unicode TR18):
202 #
203 #    The recommended names for UCD properties and property values are in
204 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
205 #    [PropValue]. There are both abbreviated names and longer, more
206 #    descriptive names. It is strongly recommended that both names be
207 #    recognized, and that loose matching of property names be used,
208 #    whereby the case distinctions, whitespace, hyphens, and underbar
209 #    are ignored.
210 # The program still allows Fuzzy to override its determination of if loose
211 # matching should be used, but it isn't currently used, as it is no longer
212 # needed; the calculations it makes are good enough.
213 #
214 # SUMMARY OF HOW IT WORKS:
215 #
216 #   Process arguments
217 #
218 #   A list is constructed containing each input file that is to be processed
219 #
220 #   Each file on the list is processed in a loop, using the associated handler
221 #   code for each:
222 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
223 #            first.  These files name the properties and property values.
224 #            Objects are created of all the property and property value names
225 #            that the rest of the input should expect, including all synonyms.
226 #        The other input files give mappings from properties to property
227 #           values.  That is, they list code points and say what the mapping
228 #           is under the given property.  Some files give the mappings for
229 #           just one property; and some for many.  This program goes through
230 #           each file and populates the properties from them.  Some properties
231 #           are listed in more than one file, and Unicode has set up a
232 #           precedence as to which has priority if there is a conflict.  Thus
233 #           the order of processing matters, and this program handles the
234 #           conflict possibility by processing the overriding input files
235 #           last, so that if necessary they replace earlier values.
236 #        After this is all done, the program creates the property mappings not
237 #            furnished by Unicode, but derivable from what it does give.
238 #        The tables of code points that match each property value in each
239 #            property that is accessible by regular expressions are created.
240 #        The Perl-defined properties are created and populated.  Many of these
241 #            require data determined from the earlier steps
242 #        Any Perl-defined synonyms are created, and name clashes between Perl
243 #            and Unicode are reconciled and warned about.
244 #        All the properties are written to files
245 #        Any other files are written, and final warnings issued.
246 #
247 # For clarity, a number of operators have been overloaded to work on tables:
248 #   ~ means invert (take all characters not in the set).  The more
249 #       conventional '!' is not used because of the possibility of confusing
250 #       it with the actual boolean operation.
251 #   + means union
252 #   - means subtraction
253 #   & means intersection
254 # The precedence of these is the order listed.  Parentheses should be
255 # copiously used.  These are not a general scheme.  The operations aren't
256 # defined for a number of things, deliberately, to avoid getting into trouble.
257 # Operations are done on references and affect the underlying structures, so
258 # that the copy constructors for them have been overloaded to not return a new
259 # clone, but the input object itself.
260 #
261 # The bool operator is deliberately not overloaded to avoid confusion with
262 # "should it mean if the object merely exists, or also is non-empty?".
263 #
264 # WHY CERTAIN DESIGN DECISIONS WERE MADE
265 #
266 # This program needs to be able to run under miniperl.  Therefore, it uses a
267 # minimum of other modules, and hence implements some things itself that could
268 # be gotten from CPAN
269 #
270 # This program uses inputs published by the Unicode Consortium.  These can
271 # change incompatibly between releases without the Perl maintainers realizing
272 # it.  Therefore this program is now designed to try to flag these.  It looks
273 # at the directories where the inputs are, and flags any unrecognized files.
274 # It keeps track of all the properties in the files it handles, and flags any
275 # that it doesn't know how to handle.  It also flags any input lines that
276 # don't match the expected syntax, among other checks.
277 #
278 # It is also designed so if a new input file matches one of the known
279 # templates, one hopefully just needs to add it to a list to have it
280 # processed.
281 #
282 # As mentioned earlier, some properties are given in more than one file.  In
283 # particular, the files in the extracted directory are supposedly just
284 # reformattings of the others.  But they contain information not easily
285 # derivable from the other files, including results for Unihan, which this
286 # program doesn't ordinarily look at, and for unassigned code points.  They
287 # also have historically had errors or been incomplete.  In an attempt to
288 # create the best possible data, this program thus processes them first to
289 # glean information missing from the other files; then processes those other
290 # files to override any errors in the extracted ones.  Much of the design was
291 # driven by this need to store things and then possibly override them.
292 #
293 # It tries to keep fatal errors to a minimum, to generate something usable for
294 # testing purposes.  It always looks for files that could be inputs, and will
295 # warn about any that it doesn't know how to handle (the -q option suppresses
296 # the warning).
297 #
298 # Why is there more than one type of range?
299 #   This simplified things.  There are some very specialized code points that
300 #   have to be handled specially for output, such as Hangul syllable names.
301 #   By creating a range type (done late in the development process), it
302 #   allowed this to be stored with the range, and overridden by other input.
303 #   Originally these were stored in another data structure, and it became a
304 #   mess trying to decide if a second file that was for the same property was
305 #   overriding the earlier one or not.
306 #
307 # Why are there two kinds of tables, match and map?
308 #   (And there is a base class shared by the two as well.)  As stated above,
309 #   they actually are for different things.  Development proceeded much more
310 #   smoothly when I (khw) realized the distinction.  Map tables are used to
311 #   give the property value for every code point (actually every code point
312 #   that doesn't map to a default value).  Match tables are used for regular
313 #   expression matches, and are essentially the inverse mapping.  Separating
314 #   the two allows more specialized methods, and error checks so that one
315 #   can't just take the intersection of two map tables, for example, as that
316 #   is nonsensical.
317 #
318 # DEBUGGING
319 #
320 # This program is written so it will run under miniperl.  Occasionally changes
321 # will cause an error where the backtrace doesn't work well under miniperl.
322 # To diagnose the problem, you can instead run it under regular perl, if you
323 # have one compiled.
324 #
325 # There is a good trace facility.  To enable it, first sub DEBUG must be set
326 # to return true.  Then a line like
327 #
328 # local $to_trace = 1 if main::DEBUG;
329 #
330 # can be added to enable tracing in its lexical scope or until you insert
331 # another line:
332 #
333 # local $to_trace = 0 if main::DEBUG;
334 #
335 # then use a line like "trace $a, @b, %c, ...;
336 #
337 # Some of the more complex subroutines already have trace statements in them.
338 # Permanent trace statements should be like:
339 #
340 # trace ... if main::DEBUG && $to_trace;
341 #
342 # If there is just one or a few files that you're debugging, you can easily
343 # cause most everything else to be skipped.  Change the line
344 #
345 # my $debug_skip = 0;
346 #
347 # to 1, and every file whose object is in @input_file_objects and doesn't have
348 # a, 'non_skip => 1,' in its constructor will be skipped.
349 #
350 # To compare the output tables, it may be useful to specify the -annotate
351 # flag.  This causes the tables to expand so there is one entry for each
352 # non-algorithmically named code point giving, currently its name, and its
353 # graphic representation if printable (and you have a font that knows about
354 # it).  This makes it easier to see what the particular code points are in
355 # each output table.  The tables are usable, but because they don't have
356 # ranges (for the most part), a Perl using them will run slower.  Non-named
357 # code points are annotated with a description of their status, and contiguous
358 # ones with the same description will be output as a range rather than
359 # individually.  Algorithmically named characters are also output as ranges,
360 # except when there are just a few contiguous ones.
361 #
362 # FUTURE ISSUES
363 #
364 # The program would break if Unicode were to change its names so that
365 # interior white space, underscores, or dashes differences were significant
366 # within property and property value names.
367 #
368 # It might be easier to use the xml versions of the UCD if this program ever
369 # would need heavy revision, and the ability to handle old versions was not
370 # required.
371 #
372 # There is the potential for name collisions, in that Perl has chosen names
373 # that Unicode could decide it also likes.  There have been such collisions in
374 # the past, with mostly Perl deciding to adopt the Unicode definition of the
375 # name.  However in the 5.2 Unicode beta testing, there were a number of such
376 # collisions, which were withdrawn before the final release, because of Perl's
377 # and other's protests.  These all involved new properties which began with
378 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
379 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
380 # Unicode document, so they are unlikely to be used by Unicode for another
381 # purpose.  However, they might try something beginning with 'In', or use any
382 # of the other Perl-defined properties.  This program will warn you of name
383 # collisions, and refuse to generate tables with them, but manual intervention
384 # will be required in this event.  One scheme that could be implemented, if
385 # necessary, would be to have this program generate another file, or add a
386 # field to mktables.lst that gives the date of first definition of a property.
387 # Each new release of Unicode would use that file as a basis for the next
388 # iteration.  And the Perl synonym addition code could sort based on the age
389 # of the property, so older properties get priority, and newer ones that clash
390 # would be refused; hence existing code would not be impacted, and some other
391 # synonym would have to be used for the new property.  This is ugly, and
392 # manual intervention would certainly be easier to do in the short run; lets
393 # hope it never comes to this.
394 #
395 # A NOTE ON UNIHAN
396 #
397 # This program can generate tables from the Unihan database.  But it doesn't
398 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
399 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
400 # database was split into 8 different files, all beginning with the letters
401 # 'Unihan'.  This program will read those file(s) if present, but it needs to
402 # know which of the many properties in the file(s) should have tables created
403 # for them.  It will create tables for any properties listed in
404 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
405 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
406 # property you want is not in those files of the release you are building
407 # against, you must add it to those two arrays.  Starting in 4.0, the
408 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
409 # is present in the directory, a table will be generated for that property.
410 # In 5.2, several more properties were added.  For your convenience, the two
411 # arrays are initialized with all the 6.0 listed properties that are also in
412 # earlier releases.  But these are commented out.  You can just uncomment the
413 # ones you want, or use them as a template for adding entries for other
414 # properties.
415 #
416 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
417 # and filter_unihan_line() are the functions where this is done.  This program
418 # already does some adjusting to make the lines look more like the rest of the
419 # Unicode DB;  You can see what that is in filter_unihan_line()
420 #
421 # There is a bug in the 3.2 data file in which some values for the
422 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
423 # could be added for these; or for a particular installation, the Unihan.txt
424 # file could be edited to fix them.
425 #
426 # HOW TO ADD A FILE TO BE PROCESSED
427 #
428 # A new file from Unicode needs to have an object constructed for it in
429 # @input_file_objects, probably at the end or at the end of the extracted
430 # ones.  The program should warn you if its name will clash with others on
431 # restrictive file systems, like DOS.  If so, figure out a better name, and
432 # add lines to the README.perl file giving that.  If the file is a character
433 # property, it should be in the format that Unicode has by default
434 # standardized for such files for the more recently introduced ones.
435 # If so, the Input_file constructor for @input_file_objects can just be the
436 # file name and release it first appeared in.  If not, then it should be
437 # possible to construct an each_line_handler() to massage the line into the
438 # standardized form.
439 #
440 # For non-character properties, more code will be needed.  You can look at
441 # the existing entries for clues.
442 #
443 # UNICODE VERSIONS NOTES
444 #
445 # The Unicode UCD has had a number of errors in it over the versions.  And
446 # these remain, by policy, in the standard for that version.  Therefore it is
447 # risky to correct them, because code may be expecting the error.  So this
448 # program doesn't generally make changes, unless the error breaks the Perl
449 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
450 # for U+1105, which causes real problems for the algorithms for Jamo
451 # calculations, so it is changed here.
452 #
453 # But it isn't so clear cut as to what to do about concepts that are
454 # introduced in a later release; should they extend back to earlier releases
455 # where the concept just didn't exist?  It was easier to do this than to not,
456 # so that's what was done.  For example, the default value for code points not
457 # in the files for various properties was probably undefined until changed by
458 # some version.  No_Block for blocks is such an example.  This program will
459 # assign No_Block even in Unicode versions that didn't have it.  This has the
460 # benefit that code being written doesn't have to special case earlier
461 # versions; and the detriment that it doesn't match the Standard precisely for
462 # the affected versions.
463 #
464 # Here are some observations about some of the issues in early versions:
465 #
466 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
467 # the reason is that the CJK block starting at 4E00 was removed from PropList,
468 # and was not put back in until 3.1.0
469 #
470 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
471 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
472 # reason is that 3.2 introduced U+205F=medium math space, which was not
473 # classed as white space, but Perl figured out that it should have been. 4.0
474 # reclassified it correctly.
475 #
476 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
477 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
478 # was left with no code points, as all the ones that mapped to 202 stayed
479 # mapped to 202.  Thus if your program used the numeric name for the class,
480 # it would not have been affected, but if it used the mnemonic, it would have
481 # been.
482 #
483 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
484 # points which eventually came to have this script property value, instead
485 # mapped to "Unknown".  But in the next release all these code points were
486 # moved to \p{sc=common} instead.
487 #
488 # The default for missing code points for BidiClass is complicated.  Starting
489 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
490 # tries to do the best it can for earlier releases.  It is done in
491 # process_PropertyAliases()
492 #
493 ##############################################################################
494
495 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
496                         # and errors
497 my $MAX_LINE_WIDTH = 78;
498
499 # Debugging aid to skip most files so as to not be distracted by them when
500 # concentrating on the ones being debugged.  Add
501 # non_skip => 1,
502 # to the constructor for those files you want processed when you set this.
503 # Files with a first version number of 0 are special: they are always
504 # processed regardless of the state of this flag.  Generally, Jamo.txt and
505 # UnicodeData.txt must not be skipped if you want this program to not die
506 # before normal completion.
507 my $debug_skip = 0;
508
509 # Set to 1 to enable tracing.
510 our $to_trace = 0;
511
512 { # Closure for trace: debugging aid
513     my $print_caller = 1;        # ? Include calling subroutine name
514     my $main_with_colon = 'main::';
515     my $main_colon_length = length($main_with_colon);
516
517     sub trace {
518         return unless $to_trace;        # Do nothing if global flag not set
519
520         my @input = @_;
521
522         local $DB::trace = 0;
523         $DB::trace = 0;          # Quiet 'used only once' message
524
525         my $line_number;
526
527         # Loop looking up the stack to get the first non-trace caller
528         my $caller_line;
529         my $caller_name;
530         my $i = 0;
531         do {
532             $line_number = $caller_line;
533             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
534             $caller = $main_with_colon unless defined $caller;
535
536             $caller_name = $caller;
537
538             # get rid of pkg
539             $caller_name =~ s/.*:://;
540             if (substr($caller_name, 0, $main_colon_length)
541                 eq $main_with_colon)
542             {
543                 $caller_name = substr($caller_name, $main_colon_length);
544             }
545
546         } until ($caller_name ne 'trace');
547
548         # If the stack was empty, we were called from the top level
549         $caller_name = 'main' if ($caller_name eq ""
550                                     || $caller_name eq 'trace');
551
552         my $output = "";
553         foreach my $string (@input) {
554             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
555             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
556                 $output .= simple_dumper($string);
557             }
558             else {
559                 $string = "$string" if ref $string;
560                 $string = $UNDEF unless defined $string;
561                 chomp $string;
562                 $string = '""' if $string eq "";
563                 $output .= " " if $output ne ""
564                                 && $string ne ""
565                                 && substr($output, -1, 1) ne " "
566                                 && substr($string, 0, 1) ne " ";
567                 $output .= $string;
568             }
569         }
570
571         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
572         print STDERR "$caller_name: " if $print_caller;
573         print STDERR $output, "\n";
574         return;
575     }
576 }
577
578 # This is for a rarely used development feature that allows you to compare two
579 # versions of the Unicode standard without having to deal with changes caused
580 # by the code points introduced in the later version.  Change the 0 to a
581 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
582 # code points introduced in that release and earlier will be used; later ones
583 # are thrown away.  You use the version number of the earliest one you want to
584 # compare; then run this program on directory structures containing each
585 # release, and compare the outputs.  These outputs will therefore include only
586 # the code points common to both releases, and you can see the changes caused
587 # just by the underlying release semantic changes.  For versions earlier than
588 # 3.2, you must copy a version of DAge.txt into the directory.
589 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
590 my $compare_versions = DEBUG
591                        && $string_compare_versions
592                        && pack "C*", split /\./, $string_compare_versions;
593
594 sub uniques {
595     # Returns non-duplicated input values.  From "Perl Best Practices:
596     # Encapsulated Cleverness".  p. 455 in first edition.
597
598     my %seen;
599     # Arguably this breaks encapsulation, if the goal is to permit multiple
600     # distinct objects to stringify to the same value, and be interchangeable.
601     # However, for this program, no two objects stringify identically, and all
602     # lists passed to this function are either objects or strings. So this
603     # doesn't affect correctness, but it does give a couple of percent speedup.
604     no overloading;
605     return grep { ! $seen{$_}++ } @_;
606 }
607
608 $0 = File::Spec->canonpath($0);
609
610 my $make_test_script = 0;      # ? Should we output a test script
611 my $write_unchanged_files = 0; # ? Should we update the output files even if
612                                #    we don't think they have changed
613 my $use_directory = "";        # ? Should we chdir somewhere.
614 my $pod_directory;             # input directory to store the pod file.
615 my $pod_file = 'perluniprops';
616 my $t_path;                     # Path to the .t test file
617 my $file_list = 'mktables.lst'; # File to store input and output file names.
618                                # This is used to speed up the build, by not
619                                # executing the main body of the program if
620                                # nothing on the list has changed since the
621                                # previous build
622 my $make_list = 1;             # ? Should we write $file_list.  Set to always
623                                # make a list so that when the pumpking is
624                                # preparing a release, s/he won't have to do
625                                # special things
626 my $glob_list = 0;             # ? Should we try to include unknown .txt files
627                                # in the input.
628 my $output_range_counts = $debugging_build;   # ? Should we include the number
629                                               # of code points in ranges in
630                                               # the output
631 my $annotate = 0;              # ? Should character names be in the output
632
633 # Verbosity levels; 0 is quiet
634 my $NORMAL_VERBOSITY = 1;
635 my $PROGRESS = 2;
636 my $VERBOSE = 3;
637
638 my $verbosity = $NORMAL_VERBOSITY;
639
640 # Process arguments
641 while (@ARGV) {
642     my $arg = shift @ARGV;
643     if ($arg eq '-v') {
644         $verbosity = $VERBOSE;
645     }
646     elsif ($arg eq '-p') {
647         $verbosity = $PROGRESS;
648         $| = 1;     # Flush buffers as we go.
649     }
650     elsif ($arg eq '-q') {
651         $verbosity = 0;
652     }
653     elsif ($arg eq '-w') {
654         $write_unchanged_files = 1; # update the files even if havent changed
655     }
656     elsif ($arg eq '-check') {
657         my $this = shift @ARGV;
658         my $ok = shift @ARGV;
659         if ($this ne $ok) {
660             print "Skipping as check params are not the same.\n";
661             exit(0);
662         }
663     }
664     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
665         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
666     }
667     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
668     {
669         $make_test_script = 1;
670     }
671     elsif ($arg eq '-makelist') {
672         $make_list = 1;
673     }
674     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
675         -d $use_directory or croak "Unknown directory '$use_directory'";
676     }
677     elsif ($arg eq '-L') {
678
679         # Existence not tested until have chdir'd
680         $file_list = shift;
681     }
682     elsif ($arg eq '-globlist') {
683         $glob_list = 1;
684     }
685     elsif ($arg eq '-c') {
686         $output_range_counts = ! $output_range_counts
687     }
688     elsif ($arg eq '-annotate') {
689         $annotate = 1;
690         $debugging_build = 1;
691         $output_range_counts = 1;
692     }
693     else {
694         my $with_c = 'with';
695         $with_c .= 'out' if $output_range_counts;   # Complements the state
696         croak <<END;
697 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
698           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
699           [-check A B ]
700   -c          : Output comments $with_c number of code points in ranges
701   -q          : Quiet Mode: Only output serious warnings.
702   -p          : Set verbosity level to normal plus show progress.
703   -v          : Set Verbosity level high:  Show progress and non-serious
704                 warnings
705   -w          : Write files regardless
706   -C dir      : Change to this directory before proceeding. All relative paths
707                 except those specified by the -P and -T options will be done
708                 with respect to this directory.
709   -P dir      : Output $pod_file file to directory 'dir'.
710   -T path     : Create a test script as 'path'; overrides -maketest
711   -L filelist : Use alternate 'filelist' instead of standard one
712   -globlist   : Take as input all non-Test *.txt files in current and sub
713                 directories
714   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
715                 overrides -T
716   -makelist   : Rewrite the file list $file_list based on current setup
717   -annotate   : Output an annotation for each character in the table files;
718                 useful for debugging mktables, looking at diffs; but is slow,
719                 memory intensive; resulting tables are usable but are slow and
720                 very large (and currently fail the Unicode::UCD.t tests).
721   -check A B  : Executes $0 only if A and B are the same
722 END
723     }
724 }
725
726 # Stores the most-recently changed file.  If none have changed, can skip the
727 # build
728 my $most_recent = (stat $0)[9];   # Do this before the chdir!
729
730 # Change directories now, because need to read 'version' early.
731 if ($use_directory) {
732     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
733         $pod_directory = File::Spec->rel2abs($pod_directory);
734     }
735     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
736         $t_path = File::Spec->rel2abs($t_path);
737     }
738     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
739     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
740         $pod_directory = File::Spec->abs2rel($pod_directory);
741     }
742     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
743         $t_path = File::Spec->abs2rel($t_path);
744     }
745 }
746
747 # Get Unicode version into regular and v-string.  This is done now because
748 # various tables below get populated based on it.  These tables are populated
749 # here to be near the top of the file, and so easily seeable by those needing
750 # to modify things.
751 open my $VERSION, "<", "version"
752                     or croak "$0: can't open required file 'version': $!\n";
753 my $string_version = <$VERSION>;
754 close $VERSION;
755 chomp $string_version;
756 my $v_version = pack "C*", split /\./, $string_version;        # v string
757
758 # The following are the complete names of properties with property values that
759 # are known to not match any code points in some versions of Unicode, but that
760 # may change in the future so they should be matchable, hence an empty file is
761 # generated for them.
762 my @tables_that_may_be_empty = (
763                                 'Joining_Type=Left_Joining',
764                                 );
765 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
766 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
767 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
768                                                     if $v_version ge v4.1.0;
769 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
770                                                     if $v_version ge v6.0.0;
771 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
772                                                     if $v_version ge v6.1.0;
773
774 # The lists below are hashes, so the key is the item in the list, and the
775 # value is the reason why it is in the list.  This makes generation of
776 # documentation easier.
777
778 my %why_suppressed;  # No file generated for these.
779
780 # Files aren't generated for empty extraneous properties.  This is arguable.
781 # Extraneous properties generally come about because a property is no longer
782 # used in a newer version of Unicode.  If we generated a file without code
783 # points, programs that used to work on that property will still execute
784 # without errors.  It just won't ever match (or will always match, with \P{}).
785 # This means that the logic is now likely wrong.  I (khw) think its better to
786 # find this out by getting an error message.  Just move them to the table
787 # above to change this behavior
788 my %why_suppress_if_empty_warn_if_not = (
789
790    # It is the only property that has ever officially been removed from the
791    # Standard.  The database never contained any code points for it.
792    'Special_Case_Condition' => 'Obsolete',
793
794    # Apparently never official, but there were code points in some versions of
795    # old-style PropList.txt
796    'Non_Break' => 'Obsolete',
797 );
798
799 # These would normally go in the warn table just above, but they were changed
800 # a long time before this program was written, so warnings about them are
801 # moot.
802 if ($v_version gt v3.2.0) {
803     push @tables_that_may_be_empty,
804                                 'Canonical_Combining_Class=Attached_Below_Left'
805 }
806
807 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
808 # unless explicitly added.
809 if ($v_version ge v5.2.0) {
810     my $unihan = 'Unihan; remove from list if using Unihan';
811     foreach my $table (qw (
812                            kAccountingNumeric
813                            kOtherNumeric
814                            kPrimaryNumeric
815                            kCompatibilityVariant
816                            kIICore
817                            kIRG_GSource
818                            kIRG_HSource
819                            kIRG_JSource
820                            kIRG_KPSource
821                            kIRG_MSource
822                            kIRG_KSource
823                            kIRG_TSource
824                            kIRG_USource
825                            kIRG_VSource
826                            kRSUnicode
827                         ))
828     {
829         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
830     }
831 }
832
833 # Enum values for to_output_map() method in the Map_Table package.
834 my $EXTERNAL_MAP = 1;
835 my $INTERNAL_MAP = 2;
836 my $OUTPUT_DELTAS = 3;
837
838 # To override computed values for writing the map tables for these properties.
839 # The default for enum map tables is to write them out, so that the Unicode
840 # .txt files can be removed, but all the data to compute any property value
841 # for any code point is available in a more compact form.
842 my %global_to_output_map = (
843     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
844     # get stuck supporting it if things change.  Since it is a STRING
845     # property, it normally would be listed in the pod, but INTERNAL_MAP
846     # suppresses that.
847     Unicode_1_Name => $INTERNAL_MAP,
848
849     Present_In => 0,                # Suppress, as easily computed from Age
850     Block => 0,                     # Suppress, as Blocks.txt is retained.
851
852     # Suppress, as mapping can be found instead from the
853     # Perl_Decomposition_Mapping file
854     Decomposition_Type => 0,
855 );
856
857 # Properties that this program ignores.
858 my @unimplemented_properties;
859
860 # With this release, it is automatically handled if the Unihan db is
861 # downloaded
862 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
863
864 # There are several types of obsolete properties defined by Unicode.  These
865 # must be hand-edited for every new Unicode release.
866 my %why_deprecated;  # Generates a deprecated warning message if used.
867 my %why_stabilized;  # Documentation only
868 my %why_obsolete;    # Documentation only
869
870 {   # Closure
871     my $simple = 'Perl uses the more complete version of this property';
872     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
873
874     my $other_properties = 'other properties';
875     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
876     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
877
878     %why_deprecated = (
879         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
880         'Jamo_Short_Name' => $contributory,
881         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
882         'Other_Alphabetic' => $contributory,
883         'Other_Default_Ignorable_Code_Point' => $contributory,
884         'Other_Grapheme_Extend' => $contributory,
885         'Other_ID_Continue' => $contributory,
886         'Other_ID_Start' => $contributory,
887         'Other_Lowercase' => $contributory,
888         'Other_Math' => $contributory,
889         'Other_Uppercase' => $contributory,
890         'Expands_On_NFC' => $why_no_expand,
891         'Expands_On_NFD' => $why_no_expand,
892         'Expands_On_NFKC' => $why_no_expand,
893         'Expands_On_NFKD' => $why_no_expand,
894     );
895
896     %why_suppressed = (
897         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
898         # contains the same information, but without the algorithmically
899         # determinable Hangul syllables'.  This file is not published, so it's
900         # existence is not noted in the comment.
901         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
902
903         'Indic_Matra_Category' => "Provisional",
904         'Indic_Syllabic_Category' => "Provisional",
905
906         # Don't suppress ISO_Comment, as otherwise special handling is needed
907         # to differentiate between it and gc=c, which can be written as 'isc',
908         # which is the same characters as ISO_Comment's short name.
909
910         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
911
912         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
913         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
914         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
915         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
916
917         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
918     );
919
920     foreach my $property (
921
922             # The following are suppressed because they were made contributory
923             # or deprecated by Unicode before Perl ever thought about
924             # supporting them.
925             'Jamo_Short_Name',
926             'Grapheme_Link',
927             'Expands_On_NFC',
928             'Expands_On_NFD',
929             'Expands_On_NFKC',
930             'Expands_On_NFKD',
931
932             # The following are suppressed because they have been marked
933             # as deprecated for a sufficient amount of time
934             'Other_Alphabetic',
935             'Other_Default_Ignorable_Code_Point',
936             'Other_Grapheme_Extend',
937             'Other_ID_Continue',
938             'Other_ID_Start',
939             'Other_Lowercase',
940             'Other_Math',
941             'Other_Uppercase',
942     ) {
943         $why_suppressed{$property} = $why_deprecated{$property};
944     }
945
946     # Customize the message for all the 'Other_' properties
947     foreach my $property (keys %why_deprecated) {
948         next if (my $main_property = $property) !~ s/^Other_//;
949         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
950     }
951 }
952
953 if ($v_version ge 4.0.0) {
954     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
955     if ($v_version ge 6.0.0) {
956         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
957     }
958 }
959 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
960     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
961     if ($v_version ge 6.0.0) {
962         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
963     }
964 }
965
966 # Probably obsolete forever
967 if ($v_version ge v4.1.0) {
968     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
969 }
970 if ($v_version ge v6.0.0) {
971     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
972     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
973 }
974
975 # This program can create files for enumerated-like properties, such as
976 # 'Numeric_Type'.  This file would be the same format as for a string
977 # property, with a mapping from code point to its value, so you could look up,
978 # for example, the script a code point is in.  But no one so far wants this
979 # mapping, or they have found another way to get it since this is a new
980 # feature.  So no file is generated except if it is in this list.
981 my @output_mapped_properties = split "\n", <<END;
982 END
983
984 # If you are using the Unihan database in a Unicode version before 5.2, you
985 # need to add the properties that you want to extract from it to this table.
986 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
987 # listed, commented out
988 my @cjk_properties = split "\n", <<'END';
989 #cjkAccountingNumeric; kAccountingNumeric
990 #cjkOtherNumeric; kOtherNumeric
991 #cjkPrimaryNumeric; kPrimaryNumeric
992 #cjkCompatibilityVariant; kCompatibilityVariant
993 #cjkIICore ; kIICore
994 #cjkIRG_GSource; kIRG_GSource
995 #cjkIRG_HSource; kIRG_HSource
996 #cjkIRG_JSource; kIRG_JSource
997 #cjkIRG_KPSource; kIRG_KPSource
998 #cjkIRG_KSource; kIRG_KSource
999 #cjkIRG_TSource; kIRG_TSource
1000 #cjkIRG_USource; kIRG_USource
1001 #cjkIRG_VSource; kIRG_VSource
1002 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1003 END
1004
1005 # Similarly for the property values.  For your convenience, the lines in the
1006 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1007 # '#' marks (for Unicode versions before 5.2)
1008 my @cjk_property_values = split "\n", <<'END';
1009 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1010 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1011 ## @missing: 0000..10FFFF; cjkIICore; <none>
1012 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1013 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1014 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1015 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1016 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1017 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1018 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1019 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1020 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1021 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1022 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1023 END
1024
1025 # The input files don't list every code point.  Those not listed are to be
1026 # defaulted to some value.  Below are hard-coded what those values are for
1027 # non-binary properties as of 5.1.  Starting in 5.0, there are
1028 # machine-parsable comment lines in the files the give the defaults; so this
1029 # list shouldn't have to be extended.  The claim is that all missing entries
1030 # for binary properties will default to 'N'.  Unicode tried to change that in
1031 # 5.2, but the beta period produced enough protest that they backed off.
1032 #
1033 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1034 # be in the form that it expects.  The others may be synonyms.
1035 my $CODE_POINT = '<code point>';
1036 my %default_mapping = (
1037     Age => "Unassigned",
1038     # Bidi_Class => Complicated; set in code
1039     Bidi_Mirroring_Glyph => "",
1040     Block => 'No_Block',
1041     Canonical_Combining_Class => 0,
1042     Case_Folding => $CODE_POINT,
1043     Decomposition_Mapping => $CODE_POINT,
1044     Decomposition_Type => 'None',
1045     East_Asian_Width => "Neutral",
1046     FC_NFKC_Closure => $CODE_POINT,
1047     General_Category => 'Cn',
1048     Grapheme_Cluster_Break => 'Other',
1049     Hangul_Syllable_Type => 'NA',
1050     ISO_Comment => "",
1051     Jamo_Short_Name => "",
1052     Joining_Group => "No_Joining_Group",
1053     # Joining_Type => Complicated; set in code
1054     kIICore => 'N',   #                       Is converted to binary
1055     #Line_Break => Complicated; set in code
1056     Lowercase_Mapping => $CODE_POINT,
1057     Name => "",
1058     Name_Alias => "",
1059     NFC_QC => 'Yes',
1060     NFD_QC => 'Yes',
1061     NFKC_QC => 'Yes',
1062     NFKD_QC => 'Yes',
1063     Numeric_Type => 'None',
1064     Numeric_Value => 'NaN',
1065     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1066     Sentence_Break => 'Other',
1067     Simple_Case_Folding => $CODE_POINT,
1068     Simple_Lowercase_Mapping => $CODE_POINT,
1069     Simple_Titlecase_Mapping => $CODE_POINT,
1070     Simple_Uppercase_Mapping => $CODE_POINT,
1071     Titlecase_Mapping => $CODE_POINT,
1072     Unicode_1_Name => "",
1073     Unicode_Radical_Stroke => "",
1074     Uppercase_Mapping => $CODE_POINT,
1075     Word_Break => 'Other',
1076 );
1077
1078 # Below are files that Unicode furnishes, but this program ignores, and why
1079 my %ignored_files = (
1080     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1081     'Index.txt' => 'Alphabetical index of Unicode characters',
1082     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1083     'NamesList.txt' => 'Annotated list of characters',
1084     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1085     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1086     'ReadMe.txt' => 'Documentation',
1087     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1088     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1089     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1090     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1091     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1092     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1093 );
1094
1095 my %skipped_files;  # List of files that we skip
1096
1097 ### End of externally interesting definitions, except for @input_file_objects
1098
1099 my $HEADER=<<"EOF";
1100 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1101 # This file is machine-generated by $0 from the Unicode
1102 # database, Version $string_version.  Any changes made here will be lost!
1103 EOF
1104
1105 my $INTERNAL_ONLY_HEADER = <<"EOF";
1106
1107 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1108 # This file is for internal use by core Perl only.  The format and even the
1109 # name or existence of this file are subject to change without notice.  Don't
1110 # use it directly.
1111 EOF
1112
1113 my $DEVELOPMENT_ONLY=<<"EOF";
1114 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1115 # This file contains information artificially constrained to code points
1116 # present in Unicode release $string_compare_versions.
1117 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1118 # not be used for production.
1119
1120 EOF
1121
1122 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1123 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1124 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1125
1126 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1127 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1128 # to decrease backtracking.  The first regex allows the code point to be at
1129 # the end of a word, but to work properly, the word shouldn't end with a valid
1130 # hex character.  The second one won't match a code point at the end of a
1131 # word, and doesn't have the run-on issue
1132 my $run_on_code_point_re =
1133             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1134 my $code_point_re = qr/\b$run_on_code_point_re/;
1135
1136 # This matches the beginning of the line in the Unicode db files that give the
1137 # defaults for code points not listed (i.e., missing) in the file.  The code
1138 # depends on this ending with a semi-colon, so it can assume it is a valid
1139 # field when the line is split() by semi-colons
1140 my $missing_defaults_prefix =
1141             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1142
1143 # Property types.  Unicode has more types, but these are sufficient for our
1144 # purposes.
1145 my $UNKNOWN = -1;   # initialized to illegal value
1146 my $NON_STRING = 1; # Either binary or enum
1147 my $BINARY = 2;
1148 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1149                        # tables, additional true and false tables are
1150                        # generated so that false is anything matching the
1151                        # default value, and true is everything else.
1152 my $ENUM = 4;       # Include catalog
1153 my $STRING = 5;     # Anything else: string or misc
1154
1155 # Some input files have lines that give default values for code points not
1156 # contained in the file.  Sometimes these should be ignored.
1157 my $NO_DEFAULTS = 0;        # Must evaluate to false
1158 my $NOT_IGNORED = 1;
1159 my $IGNORED = 2;
1160
1161 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1162 # and will appear in the main body of the tables in the output files, but
1163 # there are other types of ranges as well, listed below, that are specially
1164 # handled.   There are pseudo-types as well that will never be stored as a
1165 # type, but will affect the calculation of the type.
1166
1167 # 0 is for normal, non-specials
1168 my $MULTI_CP = 1;           # Sequence of more than code point
1169 my $HANGUL_SYLLABLE = 2;
1170 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1171 my $NULL = 4;               # The map is to the null string; utf8.c can't
1172                             # handle these, nor is there an accepted syntax
1173                             # for them in \p{} constructs
1174 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1175                              # otherwise be $MULTI_CP type are instead type 0
1176
1177 # process_generic_property_file() can accept certain overrides in its input.
1178 # Each of these must begin AND end with $CMD_DELIM.
1179 my $CMD_DELIM = "\a";
1180 my $REPLACE_CMD = 'replace';    # Override the Replace
1181 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1182
1183 my $NO = 0;
1184 my $YES = 1;
1185
1186 # Values for the Replace argument to add_range.
1187 # $NO                      # Don't replace; add only the code points not
1188                            # already present.
1189 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1190                            # the comments at the subroutine definition.
1191 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1192 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1193                            # already there
1194 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1195                            # already there
1196 my $CROAK = 6;             # Die with an error if is already there
1197
1198 # Flags to give property statuses.  The phrases are to remind maintainers that
1199 # if the flag is changed, the indefinite article referring to it in the
1200 # documentation may need to be as well.
1201 my $NORMAL = "";
1202 my $DEPRECATED = 'D';
1203 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1204 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1205 my $DISCOURAGED = 'X';
1206 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1207 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1208 my $STRICTER = 'T';
1209 my $a_bold_stricter = "a 'B<$STRICTER>'";
1210 my $A_bold_stricter = "A 'B<$STRICTER>'";
1211 my $STABILIZED = 'S';
1212 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1213 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1214 my $OBSOLETE = 'O';
1215 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1216 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1217
1218 my %status_past_participles = (
1219     $DISCOURAGED => 'discouraged',
1220     $STABILIZED => 'stabilized',
1221     $OBSOLETE => 'obsolete',
1222     $DEPRECATED => 'deprecated',
1223 );
1224
1225 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1226 # externally documented.
1227 my $ORDINARY = 0;       # The normal fate.
1228 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1229                         # but there is a file written that can be used to
1230                         # reconstruct this table
1231 my $SUPPRESSED = 3;     # The file for this table is not written out.
1232 my $INTERNAL_ONLY = 4;  # The file for this table is written out, but it is
1233                         # for Perl's internal use only
1234 my $PLACEHOLDER = 5;    # A property that is defined as a placeholder in a
1235                         # Unicode version that doesn't have it, but we need it
1236                         # to be defined, if empty, to have things work.
1237                         # Implies no pod entry generated
1238
1239 # The format of the values of the tables:
1240 my $EMPTY_FORMAT = "";
1241 my $BINARY_FORMAT = 'b';
1242 my $DECIMAL_FORMAT = 'd';
1243 my $FLOAT_FORMAT = 'f';
1244 my $INTEGER_FORMAT = 'i';
1245 my $HEX_FORMAT = 'x';
1246 my $RATIONAL_FORMAT = 'r';
1247 my $STRING_FORMAT = 's';
1248 my $DECOMP_STRING_FORMAT = 'c';
1249 my $STRING_WHITE_SPACE_LIST = 'sw';
1250
1251 my %map_table_formats = (
1252     $BINARY_FORMAT => 'binary',
1253     $DECIMAL_FORMAT => 'single decimal digit',
1254     $FLOAT_FORMAT => 'floating point number',
1255     $INTEGER_FORMAT => 'integer',
1256     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1257     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1258     $STRING_FORMAT => 'string',
1259     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1260     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1261 );
1262
1263 # Unicode didn't put such derived files in a separate directory at first.
1264 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1265 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1266 my $AUXILIARY = 'auxiliary';
1267
1268 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1269 # and into UCD.pl for the use of UCD.pm
1270 my %loose_to_file_of;       # loosely maps table names to their respective
1271                             # files
1272 my %stricter_to_file_of;    # same; but for stricter mapping.
1273 my %loose_property_to_file_of; # Maps a loose property name to its map file
1274 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1275                             # in the hash %utf8::SwashInfo
1276 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1277                              # their rational equivalent
1278 my %loose_property_name_of; # Loosely maps (non_string) property names to
1279                             # standard form
1280 my %string_property_loose_to_name; # Same, for string properties.
1281 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1282                             # the property name in standard loose form, and
1283                             # 'value' is the default value for that property,
1284                             # also in standard loose form.
1285 my %loose_to_standard_value; # loosely maps table names to the canonical
1286                             # alias for them
1287 my %ambiguous_names;        # keys are alias names (in standard form) that
1288                             # have more than one possible meaning.
1289 my %prop_aliases;           # Keys are standard property name; values are each
1290                             # one's aliases
1291 my %prop_value_aliases;     # Keys of top level are standard property name;
1292                             # values are keys to another hash,  Each one is
1293                             # one of the property's values, in standard form.
1294                             # The values are that prop-val's aliases.
1295 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1296
1297 # Most properties are immune to caseless matching, otherwise you would get
1298 # nonsensical results, as properties are a function of a code point, not
1299 # everything that is caselessly equivalent to that code point.  For example,
1300 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1301 # be true because 's' and 'S' are equivalent caselessly.  However,
1302 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1303 # extend that concept to those very few properties that are like this.  Each
1304 # such property will match the full range caselessly.  They are hard-coded in
1305 # the program; it's not worth trying to make it general as it's extremely
1306 # unlikely that they will ever change.
1307 my %caseless_equivalent_to;
1308
1309 # These constants names and values were taken from the Unicode standard,
1310 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1311 # syllables.  The '_string' versions are so generated tables can retain the
1312 # hex format, which is the more familiar value
1313 my $SBase_string = "0xAC00";
1314 my $SBase = CORE::hex $SBase_string;
1315 my $LBase_string = "0x1100";
1316 my $LBase = CORE::hex $LBase_string;
1317 my $VBase_string = "0x1161";
1318 my $VBase = CORE::hex $VBase_string;
1319 my $TBase_string = "0x11A7";
1320 my $TBase = CORE::hex $TBase_string;
1321 my $SCount = 11172;
1322 my $LCount = 19;
1323 my $VCount = 21;
1324 my $TCount = 28;
1325 my $NCount = $VCount * $TCount;
1326
1327 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1328 # with the above published constants.
1329 my %Jamo;
1330 my %Jamo_L;     # Leading consonants
1331 my %Jamo_V;     # Vowels
1332 my %Jamo_T;     # Trailing consonants
1333
1334 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1335 # The key is the base name of the code point, and the value is an
1336 # array giving all the ranges that use this base name.  Each range
1337 # is actually a hash giving the 'low' and 'high' values of it.
1338 my %names_ending_in_code_point;
1339 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1340                                         # removed from the names
1341 # Inverse mapping.  The list of ranges that have these kinds of
1342 # names.  Each element contains the low, high, and base names in an
1343 # anonymous hash.
1344 my @code_points_ending_in_code_point;
1345
1346 # Boolean: does this Unicode version have the hangul syllables, and are we
1347 # writing out a table for them?
1348 my $has_hangul_syllables = 0;
1349
1350 # Does this Unicode version have code points whose names end in their
1351 # respective code points, and are we writing out a table for them?  0 for no;
1352 # otherwise points to first property that a table is needed for them, so that
1353 # if multiple tables are needed, we don't create duplicates
1354 my $needing_code_points_ending_in_code_point = 0;
1355
1356 my @backslash_X_tests;     # List of tests read in for testing \X
1357 my @unhandled_properties;  # Will contain a list of properties found in
1358                            # the input that we didn't process.
1359 my @match_properties;      # Properties that have match tables, to be
1360                            # listed in the pod
1361 my @map_properties;        # Properties that get map files written
1362 my @named_sequences;       # NamedSequences.txt contents.
1363 my %potential_files;       # Generated list of all .txt files in the directory
1364                            # structure so we can warn if something is being
1365                            # ignored.
1366 my @files_actually_output; # List of files we generated.
1367 my @more_Names;            # Some code point names are compound; this is used
1368                            # to store the extra components of them.
1369 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1370                            # the minimum before we consider it equivalent to a
1371                            # candidate rational
1372 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1373
1374 # These store references to certain commonly used property objects
1375 my $gc;
1376 my $perl;
1377 my $block;
1378 my $perl_charname;
1379 my $print;
1380 my $Any;
1381 my $script;
1382
1383 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1384 my $has_In_conflicts = 0;
1385 my $has_Is_conflicts = 0;
1386
1387 sub internal_file_to_platform ($) {
1388     # Convert our file paths which have '/' separators to those of the
1389     # platform.
1390
1391     my $file = shift;
1392     return undef unless defined $file;
1393
1394     return File::Spec->join(split '/', $file);
1395 }
1396
1397 sub file_exists ($) {   # platform independent '-e'.  This program internally
1398                         # uses slash as a path separator.
1399     my $file = shift;
1400     return 0 if ! defined $file;
1401     return -e internal_file_to_platform($file);
1402 }
1403
1404 sub objaddr($) {
1405     # Returns the address of the blessed input object.
1406     # It doesn't check for blessedness because that would do a string eval
1407     # every call, and the program is structured so that this is never called
1408     # for a non-blessed object.
1409
1410     no overloading; # If overloaded, numifying below won't work.
1411
1412     # Numifying a ref gives its address.
1413     return pack 'J', $_[0];
1414 }
1415
1416 # These are used only if $annotate is true.
1417 # The entire range of Unicode characters is examined to populate these
1418 # after all the input has been processed.  But most can be skipped, as they
1419 # have the same descriptive phrases, such as being unassigned
1420 my @viacode;            # Contains the 1 million character names
1421 my @printable;          # boolean: And are those characters printable?
1422 my @annotate_char_type; # Contains a type of those characters, specifically
1423                         # for the purposes of annotation.
1424 my $annotate_ranges;    # A map of ranges of code points that have the same
1425                         # name for the purposes of annotation.  They map to the
1426                         # upper edge of the range, so that the end point can
1427                         # be immediately found.  This is used to skip ahead to
1428                         # the end of a range, and avoid processing each
1429                         # individual code point in it.
1430 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1431                                    # characters, but excluding those which are
1432                                    # also noncharacter code points
1433
1434 # The annotation types are an extension of the regular range types, though
1435 # some of the latter are folded into one.  Make the new types negative to
1436 # avoid conflicting with the regular types
1437 my $SURROGATE_TYPE = -1;
1438 my $UNASSIGNED_TYPE = -2;
1439 my $PRIVATE_USE_TYPE = -3;
1440 my $NONCHARACTER_TYPE = -4;
1441 my $CONTROL_TYPE = -5;
1442 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1443
1444 sub populate_char_info ($) {
1445     # Used only with the $annotate option.  Populates the arrays with the
1446     # input code point's info that are needed for outputting more detailed
1447     # comments.  If calling context wants a return, it is the end point of
1448     # any contiguous range of characters that share essentially the same info
1449
1450     my $i = shift;
1451     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1452
1453     $viacode[$i] = $perl_charname->value_of($i) || "";
1454
1455     # A character is generally printable if Unicode says it is,
1456     # but below we make sure that most Unicode general category 'C' types
1457     # aren't.
1458     $printable[$i] = $print->contains($i);
1459
1460     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1461
1462     # Only these two regular types are treated specially for annotations
1463     # purposes
1464     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1465                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1466
1467     # Give a generic name to all code points that don't have a real name.
1468     # We output ranges, if applicable, for these.  Also calculate the end
1469     # point of the range.
1470     my $end;
1471     if (! $viacode[$i]) {
1472         if ($gc-> table('Surrogate')->contains($i)) {
1473             $viacode[$i] = 'Surrogate';
1474             $annotate_char_type[$i] = $SURROGATE_TYPE;
1475             $printable[$i] = 0;
1476             $end = $gc->table('Surrogate')->containing_range($i)->end;
1477         }
1478         elsif ($gc-> table('Private_use')->contains($i)) {
1479             $viacode[$i] = 'Private Use';
1480             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1481             $printable[$i] = 0;
1482             $end = $gc->table('Private_Use')->containing_range($i)->end;
1483         }
1484         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1485                                                                 contains($i))
1486         {
1487             $viacode[$i] = 'Noncharacter';
1488             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1489             $printable[$i] = 0;
1490             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1491                                                     containing_range($i)->end;
1492         }
1493         elsif ($gc-> table('Control')->contains($i)) {
1494             $viacode[$i] = 'Control';
1495             $annotate_char_type[$i] = $CONTROL_TYPE;
1496             $printable[$i] = 0;
1497             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1498         }
1499         elsif ($gc-> table('Unassigned')->contains($i)) {
1500             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1501             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1502             $printable[$i] = 0;
1503
1504             # Because we name the unassigned by the blocks they are in, it
1505             # can't go past the end of that block, and it also can't go past
1506             # the unassigned range it is in.  The special table makes sure
1507             # that the non-characters, which are unassigned, are separated
1508             # out.
1509             $end = min($block->containing_range($i)->end,
1510                        $unassigned_sans_noncharacters-> containing_range($i)->
1511                                                                          end);
1512         }
1513         else {
1514             Carp::my_carp_bug("Can't figure out how to annotate "
1515                               . sprintf("U+%04X", $i)
1516                               . ".  Proceeding anyway.");
1517             $viacode[$i] = 'UNKNOWN';
1518             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1519             $printable[$i] = 0;
1520         }
1521     }
1522
1523     # Here, has a name, but if it's one in which the code point number is
1524     # appended to the name, do that.
1525     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1526         $viacode[$i] .= sprintf("-%04X", $i);
1527         $end = $perl_charname->containing_range($i)->end;
1528     }
1529
1530     # And here, has a name, but if it's a hangul syllable one, replace it with
1531     # the correct name from the Unicode algorithm
1532     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1533         use integer;
1534         my $SIndex = $i - $SBase;
1535         my $L = $LBase + $SIndex / $NCount;
1536         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1537         my $T = $TBase + $SIndex % $TCount;
1538         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1539         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1540         $end = $perl_charname->containing_range($i)->end;
1541     }
1542
1543     return if ! defined wantarray;
1544     return $i if ! defined $end;    # If not a range, return the input
1545
1546     # Save this whole range so can find the end point quickly
1547     $annotate_ranges->add_map($i, $end, $end);
1548
1549     return $end;
1550 }
1551
1552 # Commented code below should work on Perl 5.8.
1553 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1554 ## the native perl version of it (which is what would operate under miniperl)
1555 ## is extremely slow, as it does a string eval every call.
1556 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1557 #                            && defined eval "require Scalar::Util";
1558 #
1559 #sub objaddr($) {
1560 #    # Returns the address of the blessed input object.  Uses the XS version if
1561 #    # available.  It doesn't check for blessedness because that would do a
1562 #    # string eval every call, and the program is structured so that this is
1563 #    # never called for a non-blessed object.
1564 #
1565 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1566 #
1567 #    # Check at least that is a ref.
1568 #    my $pkg = ref($_[0]) or return undef;
1569 #
1570 #    # Change to a fake package to defeat any overloaded stringify
1571 #    bless $_[0], 'main::Fake';
1572 #
1573 #    # Numifying a ref gives its address.
1574 #    my $addr = pack 'J', $_[0];
1575 #
1576 #    # Return to original class
1577 #    bless $_[0], $pkg;
1578 #    return $addr;
1579 #}
1580
1581 sub max ($$) {
1582     my $a = shift;
1583     my $b = shift;
1584     return $a if $a >= $b;
1585     return $b;
1586 }
1587
1588 sub min ($$) {
1589     my $a = shift;
1590     my $b = shift;
1591     return $a if $a <= $b;
1592     return $b;
1593 }
1594
1595 sub clarify_number ($) {
1596     # This returns the input number with underscores inserted every 3 digits
1597     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1598     # checked.
1599
1600     my $number = shift;
1601     my $pos = length($number) - 3;
1602     return $number if $pos <= 1;
1603     while ($pos > 0) {
1604         substr($number, $pos, 0) = '_';
1605         $pos -= 3;
1606     }
1607     return $number;
1608 }
1609
1610
1611 package Carp;
1612
1613 # These routines give a uniform treatment of messages in this program.  They
1614 # are placed in the Carp package to cause the stack trace to not include them,
1615 # although an alternative would be to use another package and set @CARP_NOT
1616 # for it.
1617
1618 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1619
1620 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1621 # and overload trying to load Scalar:Util under miniperl.  See
1622 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1623 undef $overload::VERSION;
1624
1625 sub my_carp {
1626     my $message = shift || "";
1627     my $nofold = shift || 0;
1628
1629     if ($message) {
1630         $message = main::join_lines($message);
1631         $message =~ s/^$0: *//;     # Remove initial program name
1632         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1633         $message = "\n$0: $message;";
1634
1635         # Fold the message with program name, semi-colon end punctuation
1636         # (which looks good with the message that carp appends to it), and a
1637         # hanging indent for continuation lines.
1638         $message = main::simple_fold($message, "", 4) unless $nofold;
1639         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1640                                     # appends is to the same line
1641     }
1642
1643     return $message if defined wantarray;   # If a caller just wants the msg
1644
1645     carp $message;
1646     return;
1647 }
1648
1649 sub my_carp_bug {
1650     # This is called when it is clear that the problem is caused by a bug in
1651     # this program.
1652
1653     my $message = shift;
1654     $message =~ s/^$0: *//;
1655     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1656     carp $message;
1657     return;
1658 }
1659
1660 sub carp_too_few_args {
1661     if (@_ != 2) {
1662         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1663         return;
1664     }
1665
1666     my $args_ref = shift;
1667     my $count = shift;
1668
1669     my_carp_bug("Need at least $count arguments to "
1670         . (caller 1)[3]
1671         . ".  Instead got: '"
1672         . join ', ', @$args_ref
1673         . "'.  No action taken.");
1674     return;
1675 }
1676
1677 sub carp_extra_args {
1678     my $args_ref = shift;
1679     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1680
1681     unless (ref $args_ref) {
1682         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1683         return;
1684     }
1685     my ($package, $file, $line) = caller;
1686     my $subroutine = (caller 1)[3];
1687
1688     my $list;
1689     if (ref $args_ref eq 'HASH') {
1690         foreach my $key (keys %$args_ref) {
1691             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1692         }
1693         $list = join ', ', each %{$args_ref};
1694     }
1695     elsif (ref $args_ref eq 'ARRAY') {
1696         foreach my $arg (@$args_ref) {
1697             $arg = $UNDEF unless defined $arg;
1698         }
1699         $list = join ', ', @$args_ref;
1700     }
1701     else {
1702         my_carp_bug("Can't cope with ref "
1703                 . ref($args_ref)
1704                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1705         return;
1706     }
1707
1708     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1709     return;
1710 }
1711
1712 package main;
1713
1714 { # Closure
1715
1716     # This program uses the inside-out method for objects, as recommended in
1717     # "Perl Best Practices".  This closure aids in generating those.  There
1718     # are two routines.  setup_package() is called once per package to set
1719     # things up, and then set_access() is called for each hash representing a
1720     # field in the object.  These routines arrange for the object to be
1721     # properly destroyed when no longer used, and for standard accessor
1722     # functions to be generated.  If you need more complex accessors, just
1723     # write your own and leave those accesses out of the call to set_access().
1724     # More details below.
1725
1726     my %constructor_fields; # fields that are to be used in constructors; see
1727                             # below
1728
1729     # The values of this hash will be the package names as keys to other
1730     # hashes containing the name of each field in the package as keys, and
1731     # references to their respective hashes as values.
1732     my %package_fields;
1733
1734     sub setup_package {
1735         # Sets up the package, creating standard DESTROY and dump methods
1736         # (unless already defined).  The dump method is used in debugging by
1737         # simple_dumper().
1738         # The optional parameters are:
1739         #   a)  a reference to a hash, that gets populated by later
1740         #       set_access() calls with one of the accesses being
1741         #       'constructor'.  The caller can then refer to this, but it is
1742         #       not otherwise used by these two routines.
1743         #   b)  a reference to a callback routine to call during destruction
1744         #       of the object, before any fields are actually destroyed
1745
1746         my %args = @_;
1747         my $constructor_ref = delete $args{'Constructor_Fields'};
1748         my $destroy_callback = delete $args{'Destroy_Callback'};
1749         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1750
1751         my %fields;
1752         my $package = (caller)[0];
1753
1754         $package_fields{$package} = \%fields;
1755         $constructor_fields{$package} = $constructor_ref;
1756
1757         unless ($package->can('DESTROY')) {
1758             my $destroy_name = "${package}::DESTROY";
1759             no strict "refs";
1760
1761             # Use typeglob to give the anonymous subroutine the name we want
1762             *$destroy_name = sub {
1763                 my $self = shift;
1764                 my $addr = do { no overloading; pack 'J', $self; };
1765
1766                 $self->$destroy_callback if $destroy_callback;
1767                 foreach my $field (keys %{$package_fields{$package}}) {
1768                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1769                     delete $package_fields{$package}{$field}{$addr};
1770                 }
1771                 return;
1772             }
1773         }
1774
1775         unless ($package->can('dump')) {
1776             my $dump_name = "${package}::dump";
1777             no strict "refs";
1778             *$dump_name = sub {
1779                 my $self = shift;
1780                 return dump_inside_out($self, $package_fields{$package}, @_);
1781             }
1782         }
1783         return;
1784     }
1785
1786     sub set_access {
1787         # Arrange for the input field to be garbage collected when no longer
1788         # needed.  Also, creates standard accessor functions for the field
1789         # based on the optional parameters-- none if none of these parameters:
1790         #   'addable'    creates an 'add_NAME()' accessor function.
1791         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1792         #                function.
1793         #   'settable'   creates a 'set_NAME()' accessor function.
1794         #   'constructor' doesn't create an accessor function, but adds the
1795         #                field to the hash that was previously passed to
1796         #                setup_package();
1797         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1798         # 'add' etc. all mean 'addable'.
1799         # The read accessor function will work on both array and scalar
1800         # values.  If another accessor in the parameter list is 'a', the read
1801         # access assumes an array.  You can also force it to be array access
1802         # by specifying 'readable_array' instead of 'readable'
1803         #
1804         # A sort-of 'protected' access can be set-up by preceding the addable,
1805         # readable or settable with some initial portion of 'protected_' (but,
1806         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1807         # "protection" is only by convention.  All that happens is that the
1808         # accessor functions' names begin with an underscore.  So instead of
1809         # calling set_foo, the call is _set_foo.  (Real protection could be
1810         # accomplished by having a new subroutine, end_package, called at the
1811         # end of each package, and then storing the __LINE__ ranges and
1812         # checking them on every accessor.  But that is way overkill.)
1813
1814         # We create anonymous subroutines as the accessors and then use
1815         # typeglobs to assign them to the proper package and name
1816
1817         my $name = shift;   # Name of the field
1818         my $field = shift;  # Reference to the inside-out hash containing the
1819                             # field
1820
1821         my $package = (caller)[0];
1822
1823         if (! exists $package_fields{$package}) {
1824             croak "$0: Must call 'setup_package' before 'set_access'";
1825         }
1826
1827         # Stash the field so DESTROY can get it.
1828         $package_fields{$package}{$name} = $field;
1829
1830         # Remaining arguments are the accessors.  For each...
1831         foreach my $access (@_) {
1832             my $access = lc $access;
1833
1834             my $protected = "";
1835
1836             # Match the input as far as it goes.
1837             if ($access =~ /^(p[^_]*)_/) {
1838                 $protected = $1;
1839                 if (substr('protected_', 0, length $protected)
1840                     eq $protected)
1841                 {
1842
1843                     # Add 1 for the underscore not included in $protected
1844                     $access = substr($access, length($protected) + 1);
1845                     $protected = '_';
1846                 }
1847                 else {
1848                     $protected = "";
1849                 }
1850             }
1851
1852             if (substr('addable', 0, length $access) eq $access) {
1853                 my $subname = "${package}::${protected}add_$name";
1854                 no strict "refs";
1855
1856                 # add_ accessor.  Don't add if already there, which we
1857                 # determine using 'eq' for scalars and '==' otherwise.
1858                 *$subname = sub {
1859                     use strict "refs";
1860                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1861                     my $self = shift;
1862                     my $value = shift;
1863                     my $addr = do { no overloading; pack 'J', $self; };
1864                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1865                     if (ref $value) {
1866                         return if grep { $value == $_ } @{$field->{$addr}};
1867                     }
1868                     else {
1869                         return if grep { $value eq $_ } @{$field->{$addr}};
1870                     }
1871                     push @{$field->{$addr}}, $value;
1872                     return;
1873                 }
1874             }
1875             elsif (substr('constructor', 0, length $access) eq $access) {
1876                 if ($protected) {
1877                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1878                 }
1879                 else {
1880                     $constructor_fields{$package}{$name} = $field;
1881                 }
1882             }
1883             elsif (substr('readable_array', 0, length $access) eq $access) {
1884
1885                 # Here has read access.  If one of the other parameters for
1886                 # access is array, or this one specifies array (by being more
1887                 # than just 'readable_'), then create a subroutine that
1888                 # assumes the data is an array.  Otherwise just a scalar
1889                 my $subname = "${package}::${protected}$name";
1890                 if (grep { /^a/i } @_
1891                     or length($access) > length('readable_'))
1892                 {
1893                     no strict "refs";
1894                     *$subname = sub {
1895                         use strict "refs";
1896                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1897                         my $addr = do { no overloading; pack 'J', $_[0]; };
1898                         if (ref $field->{$addr} ne 'ARRAY') {
1899                             my $type = ref $field->{$addr};
1900                             $type = 'scalar' unless $type;
1901                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1902                             return;
1903                         }
1904                         return scalar @{$field->{$addr}} unless wantarray;
1905
1906                         # Make a copy; had problems with caller modifying the
1907                         # original otherwise
1908                         my @return = @{$field->{$addr}};
1909                         return @return;
1910                     }
1911                 }
1912                 else {
1913
1914                     # Here not an array value, a simpler function.
1915                     no strict "refs";
1916                     *$subname = sub {
1917                         use strict "refs";
1918                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1919                         no overloading;
1920                         return $field->{pack 'J', $_[0]};
1921                     }
1922                 }
1923             }
1924             elsif (substr('settable', 0, length $access) eq $access) {
1925                 my $subname = "${package}::${protected}set_$name";
1926                 no strict "refs";
1927                 *$subname = sub {
1928                     use strict "refs";
1929                     if (main::DEBUG) {
1930                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1931                         Carp::carp_extra_args(\@_) if @_ > 2;
1932                     }
1933                     # $self is $_[0]; $value is $_[1]
1934                     no overloading;
1935                     $field->{pack 'J', $_[0]} = $_[1];
1936                     return;
1937                 }
1938             }
1939             else {
1940                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1941             }
1942         }
1943         return;
1944     }
1945 }
1946
1947 package Input_file;
1948
1949 # All input files use this object, which stores various attributes about them,
1950 # and provides for convenient, uniform handling.  The run method wraps the
1951 # processing.  It handles all the bookkeeping of opening, reading, and closing
1952 # the file, returning only significant input lines.
1953 #
1954 # Each object gets a handler which processes the body of the file, and is
1955 # called by run().  Most should use the generic, default handler, which has
1956 # code scrubbed to handle things you might not expect.  A handler should
1957 # basically be a while(next_line()) {...} loop.
1958 #
1959 # You can also set up handlers to
1960 #   1) call before the first line is read for pre processing
1961 #   2) call to adjust each line of the input before the main handler gets them
1962 #   3) call upon EOF before the main handler exits its loop
1963 #   4) call at the end for post processing
1964 #
1965 # $_ is used to store the input line, and is to be filtered by the
1966 # each_line_handler()s.  So, if the format of the line is not in the desired
1967 # format for the main handler, these are used to do that adjusting.  They can
1968 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1969 # so the $_ output of one is used as the input to the next.  None of the other
1970 # handlers are stackable, but could easily be changed to be so.
1971 #
1972 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1973 # which insert the parameters as lines to be processed before the next input
1974 # file line is read.  This allows the EOF handler to flush buffers, for
1975 # example.  The difference between the two routines is that the lines inserted
1976 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1977 # called it from such a handler, you would get infinite recursion.)  Lines
1978 # inserted by insert_adjusted_lines() go directly to the main handler without
1979 # any adjustments.  If the  post-processing handler calls any of these, there
1980 # will be no effect.  Some error checking for these conditions could be added,
1981 # but it hasn't been done.
1982 #
1983 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1984 # to prevent further processing of the line.  This routine will output the
1985 # message as a warning once, and then keep a count of the lines that have the
1986 # same message, and output that count at the end of the file's processing.
1987 # This keeps the number of messages down to a manageable amount.
1988 #
1989 # get_missings() should be called to retrieve any @missing input lines.
1990 # Messages will be raised if this isn't done if the options aren't to ignore
1991 # missings.
1992
1993 sub trace { return main::trace(@_); }
1994
1995 { # Closure
1996     # Keep track of fields that are to be put into the constructor.
1997     my %constructor_fields;
1998
1999     main::setup_package(Constructor_Fields => \%constructor_fields);
2000
2001     my %file; # Input file name, required
2002     main::set_access('file', \%file, qw{ c r });
2003
2004     my %first_released; # Unicode version file was first released in, required
2005     main::set_access('first_released', \%first_released, qw{ c r });
2006
2007     my %handler;    # Subroutine to process the input file, defaults to
2008                     # 'process_generic_property_file'
2009     main::set_access('handler', \%handler, qw{ c });
2010
2011     my %property;
2012     # name of property this file is for.  defaults to none, meaning not
2013     # applicable, or is otherwise determinable, for example, from each line.
2014     main::set_access('property', \%property, qw{ c });
2015
2016     my %optional;
2017     # If this is true, the file is optional.  If not present, no warning is
2018     # output.  If it is present, the string given by this parameter is
2019     # evaluated, and if false the file is not processed.
2020     main::set_access('optional', \%optional, 'c', 'r');
2021
2022     my %non_skip;
2023     # This is used for debugging, to skip processing of all but a few input
2024     # files.  Add 'non_skip => 1' to the constructor for those files you want
2025     # processed when you set the $debug_skip global.
2026     main::set_access('non_skip', \%non_skip, 'c');
2027
2028     my %skip;
2029     # This is used to skip processing of this input file semi-permanently,
2030     # when it evaluates to true.  The value should be the reason the file is
2031     # being skipped.  It is used for files that we aren't planning to process
2032     # anytime soon, but want to allow to be in the directory and not raise a
2033     # message that we are not handling.  Mostly for test files.  This is in
2034     # contrast to the non_skip element, which is supposed to be used very
2035     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2036     # pretty much will never look at can be placed in the global
2037     # %ignored_files instead.  Ones used here will be added to %skipped files
2038     main::set_access('skip', \%skip, 'c');
2039
2040     my %each_line_handler;
2041     # list of subroutines to look at and filter each non-comment line in the
2042     # file.  defaults to none.  The subroutines are called in order, each is
2043     # to adjust $_ for the next one, and the final one adjusts it for
2044     # 'handler'
2045     main::set_access('each_line_handler', \%each_line_handler, 'c');
2046
2047     my %has_missings_defaults;
2048     # ? Are there lines in the file giving default values for code points
2049     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2050     # the norm, but IGNORED means it has such lines, but the handler doesn't
2051     # use them.  Having these three states allows us to catch changes to the
2052     # UCD that this program should track
2053     main::set_access('has_missings_defaults',
2054                                         \%has_missings_defaults, qw{ c r });
2055
2056     my %pre_handler;
2057     # Subroutine to call before doing anything else in the file.  If undef, no
2058     # such handler is called.
2059     main::set_access('pre_handler', \%pre_handler, qw{ c });
2060
2061     my %eof_handler;
2062     # Subroutine to call upon getting an EOF on the input file, but before
2063     # that is returned to the main handler.  This is to allow buffers to be
2064     # flushed.  The handler is expected to call insert_lines() or
2065     # insert_adjusted() with the buffered material
2066     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2067
2068     my %post_handler;
2069     # Subroutine to call after all the lines of the file are read in and
2070     # processed.  If undef, no such handler is called.
2071     main::set_access('post_handler', \%post_handler, qw{ c });
2072
2073     my %progress_message;
2074     # Message to print to display progress in lieu of the standard one
2075     main::set_access('progress_message', \%progress_message, qw{ c });
2076
2077     my %handle;
2078     # cache open file handle, internal.  Is undef if file hasn't been
2079     # processed at all, empty if has;
2080     main::set_access('handle', \%handle);
2081
2082     my %added_lines;
2083     # cache of lines added virtually to the file, internal
2084     main::set_access('added_lines', \%added_lines);
2085
2086     my %errors;
2087     # cache of errors found, internal
2088     main::set_access('errors', \%errors);
2089
2090     my %missings;
2091     # storage of '@missing' defaults lines
2092     main::set_access('missings', \%missings);
2093
2094     sub new {
2095         my $class = shift;
2096
2097         my $self = bless \do{ my $anonymous_scalar }, $class;
2098         my $addr = do { no overloading; pack 'J', $self; };
2099
2100         # Set defaults
2101         $handler{$addr} = \&main::process_generic_property_file;
2102         $non_skip{$addr} = 0;
2103         $skip{$addr} = 0;
2104         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2105         $handle{$addr} = undef;
2106         $added_lines{$addr} = [ ];
2107         $each_line_handler{$addr} = [ ];
2108         $errors{$addr} = { };
2109         $missings{$addr} = [ ];
2110
2111         # Two positional parameters.
2112         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2113         $file{$addr} = main::internal_file_to_platform(shift);
2114         $first_released{$addr} = shift;
2115
2116         # The rest of the arguments are key => value pairs
2117         # %constructor_fields has been set up earlier to list all possible
2118         # ones.  Either set or push, depending on how the default has been set
2119         # up just above.
2120         my %args = @_;
2121         foreach my $key (keys %args) {
2122             my $argument = $args{$key};
2123
2124             # Note that the fields are the lower case of the constructor keys
2125             my $hash = $constructor_fields{lc $key};
2126             if (! defined $hash) {
2127                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2128                 next;
2129             }
2130             if (ref $hash->{$addr} eq 'ARRAY') {
2131                 if (ref $argument eq 'ARRAY') {
2132                     foreach my $argument (@{$argument}) {
2133                         next if ! defined $argument;
2134                         push @{$hash->{$addr}}, $argument;
2135                     }
2136                 }
2137                 else {
2138                     push @{$hash->{$addr}}, $argument if defined $argument;
2139                 }
2140             }
2141             else {
2142                 $hash->{$addr} = $argument;
2143             }
2144             delete $args{$key};
2145         };
2146
2147         # If the file has a property for it, it means that the property is not
2148         # listed in the file's entries.  So add a handler to the list of line
2149         # handlers to insert the property name into the lines, to provide a
2150         # uniform interface to the final processing subroutine.
2151         # the final code doesn't have to worry about that.
2152         if ($property{$addr}) {
2153             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2154         }
2155
2156         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2157             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2158         }
2159
2160         # If skipping, set to optional, and add to list of ignored files,
2161         # including its reason
2162         if ($skip{$addr}) {
2163             $optional{$addr} = 1;
2164             $skipped_files{$file{$addr}} = $skip{$addr}
2165         }
2166
2167         return $self;
2168     }
2169
2170
2171     use overload
2172         fallback => 0,
2173         qw("") => "_operator_stringify",
2174         "." => \&main::_operator_dot,
2175     ;
2176
2177     sub _operator_stringify {
2178         my $self = shift;
2179
2180         return __PACKAGE__ . " object for " . $self->file;
2181     }
2182
2183     # flag to make sure extracted files are processed early
2184     my $seen_non_extracted_non_age = 0;
2185
2186     sub run {
2187         # Process the input object $self.  This opens and closes the file and
2188         # calls all the handlers for it.  Currently,  this can only be called
2189         # once per file, as it destroy's the EOF handler
2190
2191         my $self = shift;
2192         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2193
2194         my $addr = do { no overloading; pack 'J', $self; };
2195
2196         my $file = $file{$addr};
2197
2198         # Don't process if not expecting this file (because released later
2199         # than this Unicode version), and isn't there.  This means if someone
2200         # copies it into an earlier version's directory, we will go ahead and
2201         # process it.
2202         return if $first_released{$addr} gt $v_version && ! -e $file;
2203
2204         # If in debugging mode and this file doesn't have the non-skip
2205         # flag set, and isn't one of the critical files, skip it.
2206         if ($debug_skip
2207             && $first_released{$addr} ne v0
2208             && ! $non_skip{$addr})
2209         {
2210             print "Skipping $file in debugging\n" if $verbosity;
2211             return;
2212         }
2213
2214         # File could be optional
2215         if ($optional{$addr}) {
2216             return unless -e $file;
2217             my $result = eval $optional{$addr};
2218             if (! defined $result) {
2219                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2220                 return;
2221             }
2222             if (! $result) {
2223                 if ($verbosity) {
2224                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2225                 }
2226                 return;
2227             }
2228         }
2229
2230         if (! defined $file || ! -e $file) {
2231
2232             # If the file doesn't exist, see if have internal data for it
2233             # (based on first_released being 0).
2234             if ($first_released{$addr} eq v0) {
2235                 $handle{$addr} = 'pretend_is_open';
2236             }
2237             else {
2238                 if (! $optional{$addr}  # File could be optional
2239                     && $v_version ge $first_released{$addr})
2240                 {
2241                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2242                 }
2243                 return;
2244             }
2245         }
2246         else {
2247
2248             # Here, the file exists.  Some platforms may change the case of
2249             # its name
2250             if ($seen_non_extracted_non_age) {
2251                 if ($file =~ /$EXTRACTED/i) {
2252                     Carp::my_carp_bug(main::join_lines(<<END
2253 $file should be processed just after the 'Prop...Alias' files, and before
2254 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2255 have subtle problems
2256 END
2257                     ));
2258                 }
2259             }
2260             elsif ($EXTRACTED_DIR
2261                     && $first_released{$addr} ne v0
2262                     && $file !~ /$EXTRACTED/i
2263                     && lc($file) ne 'dage.txt')
2264             {
2265                 # We don't set this (by the 'if' above) if we have no
2266                 # extracted directory, so if running on an early version,
2267                 # this test won't work.  Not worth worrying about.
2268                 $seen_non_extracted_non_age = 1;
2269             }
2270
2271             # And mark the file as having being processed, and warn if it
2272             # isn't a file we are expecting.  As we process the files,
2273             # they are deleted from the hash, so any that remain at the
2274             # end of the program are files that we didn't process.
2275             my $fkey = File::Spec->rel2abs($file);
2276             my $expecting = delete $potential_files{lc($fkey)};
2277
2278             Carp::my_carp("Was not expecting '$file'.") if
2279                     ! $expecting
2280                     && ! defined $handle{$addr};
2281
2282             # Having deleted from expected files, we can quit if not to do
2283             # anything.  Don't print progress unless really want verbosity
2284             if ($skip{$addr}) {
2285                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2286                 return;
2287             }
2288
2289             # Open the file, converting the slashes used in this program
2290             # into the proper form for the OS
2291             my $file_handle;
2292             if (not open $file_handle, "<", $file) {
2293                 Carp::my_carp("Can't open $file.  Skipping: $!");
2294                 return 0;
2295             }
2296             $handle{$addr} = $file_handle; # Cache the open file handle
2297         }
2298
2299         if ($verbosity >= $PROGRESS) {
2300             if ($progress_message{$addr}) {
2301                 print "$progress_message{$addr}\n";
2302             }
2303             else {
2304                 # If using a virtual file, say so.
2305                 print "Processing ", (-e $file)
2306                                        ? $file
2307                                        : "substitute $file",
2308                                      "\n";
2309             }
2310         }
2311
2312
2313         # Call any special handler for before the file.
2314         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2315
2316         # Then the main handler
2317         &{$handler{$addr}}($self);
2318
2319         # Then any special post-file handler.
2320         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2321
2322         # If any errors have been accumulated, output the counts (as the first
2323         # error message in each class was output when it was encountered).
2324         if ($errors{$addr}) {
2325             my $total = 0;
2326             my $types = 0;
2327             foreach my $error (keys %{$errors{$addr}}) {
2328                 $total += $errors{$addr}->{$error};
2329                 delete $errors{$addr}->{$error};
2330                 $types++;
2331             }
2332             if ($total > 1) {
2333                 my $message
2334                         = "A total of $total lines had errors in $file.  ";
2335
2336                 $message .= ($types == 1)
2337                             ? '(Only the first one was displayed.)'
2338                             : '(Only the first of each type was displayed.)';
2339                 Carp::my_carp($message);
2340             }
2341         }
2342
2343         if (@{$missings{$addr}}) {
2344             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2345         }
2346
2347         # If a real file handle, close it.
2348         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2349                                                         ref $handle{$addr};
2350         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2351                                # the file, as opposed to undef
2352         return;
2353     }
2354
2355     sub next_line {
2356         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2357         # if such a line exists.  'logical' means that any lines that have
2358         # been added via insert_lines() will be returned in $_ before the file
2359         # is read again.
2360
2361         my $self = shift;
2362         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2363
2364         my $addr = do { no overloading; pack 'J', $self; };
2365
2366         # Here the file is open (or if the handle is not a ref, is an open
2367         # 'virtual' file).  Get the next line; any inserted lines get priority
2368         # over the file itself.
2369         my $adjusted;
2370
2371         LINE:
2372         while (1) { # Loop until find non-comment, non-empty line
2373             #local $to_trace = 1 if main::DEBUG;
2374             my $inserted_ref = shift @{$added_lines{$addr}};
2375             if (defined $inserted_ref) {
2376                 ($adjusted, $_) = @{$inserted_ref};
2377                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2378                 return 1 if $adjusted;
2379             }
2380             else {
2381                 last if ! ref $handle{$addr}; # Don't read unless is real file
2382                 last if ! defined ($_ = readline $handle{$addr});
2383             }
2384             chomp;
2385             trace $_ if main::DEBUG && $to_trace;
2386
2387             # See if this line is the comment line that defines what property
2388             # value that code points that are not listed in the file should
2389             # have.  The format or existence of these lines is not guaranteed
2390             # by Unicode since they are comments, but the documentation says
2391             # that this was added for machine-readability, so probably won't
2392             # change.  This works starting in Unicode Version 5.0.  They look
2393             # like:
2394             #
2395             # @missing: 0000..10FFFF; Not_Reordered
2396             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2397             # @missing: 0000..10FFFF; ; NaN
2398             #
2399             # Save the line for a later get_missings() call.
2400             if (/$missing_defaults_prefix/) {
2401                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2402                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2403                 }
2404                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2405                     my @defaults = split /\s* ; \s*/x, $_;
2406
2407                     # The first field is the @missing, which ends in a
2408                     # semi-colon, so can safely shift.
2409                     shift @defaults;
2410
2411                     # Some of these lines may have empty field placeholders
2412                     # which get in the way.  An example is:
2413                     # @missing: 0000..10FFFF; ; NaN
2414                     # Remove them.  Process starting from the top so the
2415                     # splice doesn't affect things still to be looked at.
2416                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2417                         next if $defaults[$i] ne "";
2418                         splice @defaults, $i, 1;
2419                     }
2420
2421                     # What's left should be just the property (maybe) and the
2422                     # default.  Having only one element means it doesn't have
2423                     # the property.
2424                     my $default;
2425                     my $property;
2426                     if (@defaults >= 1) {
2427                         if (@defaults == 1) {
2428                             $default = $defaults[0];
2429                         }
2430                         else {
2431                             $property = $defaults[0];
2432                             $default = $defaults[1];
2433                         }
2434                     }
2435
2436                     if (@defaults < 1
2437                         || @defaults > 2
2438                         || ($default =~ /^</
2439                             && $default !~ /^<code *point>$/i
2440                             && $default !~ /^<none>$/i
2441                             && $default !~ /^<script>$/i))
2442                     {
2443                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2444                     }
2445                     else {
2446
2447                         # If the property is missing from the line, it should
2448                         # be the one for the whole file
2449                         $property = $property{$addr} if ! defined $property;
2450
2451                         # Change <none> to the null string, which is what it
2452                         # really means.  If the default is the code point
2453                         # itself, set it to <code point>, which is what
2454                         # Unicode uses (but sometimes they've forgotten the
2455                         # space)
2456                         if ($default =~ /^<none>$/i) {
2457                             $default = "";
2458                         }
2459                         elsif ($default =~ /^<code *point>$/i) {
2460                             $default = $CODE_POINT;
2461                         }
2462                         elsif ($default =~ /^<script>$/i) {
2463
2464                             # Special case this one.  Currently is from
2465                             # ScriptExtensions.txt, and means for all unlisted
2466                             # code points, use their Script property values.
2467                             # For the code points not listed in that file, the
2468                             # default value is 'Unknown'.
2469                             $default = "Unknown";
2470                         }
2471
2472                         # Store them as a sub-arrays with both components.
2473                         push @{$missings{$addr}}, [ $default, $property ];
2474                     }
2475                 }
2476
2477                 # There is nothing for the caller to process on this comment
2478                 # line.
2479                 next;
2480             }
2481
2482             # Remove comments and trailing space, and skip this line if the
2483             # result is empty
2484             s/#.*//;
2485             s/\s+$//;
2486             next if /^$/;
2487
2488             # Call any handlers for this line, and skip further processing of
2489             # the line if the handler sets the line to null.
2490             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2491                 &{$sub_ref}($self);
2492                 next LINE if /^$/;
2493             }
2494
2495             # Here the line is ok.  return success.
2496             return 1;
2497         } # End of looping through lines.
2498
2499         # If there is an EOF handler, call it (only once) and if it generates
2500         # more lines to process go back in the loop to handle them.
2501         if ($eof_handler{$addr}) {
2502             &{$eof_handler{$addr}}($self);
2503             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2504             goto LINE if $added_lines{$addr};
2505         }
2506
2507         # Return failure -- no more lines.
2508         return 0;
2509
2510     }
2511
2512 #   Not currently used, not fully tested.
2513 #    sub peek {
2514 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2515 #        # record.  Not callable from an each_line_handler(), nor does it call
2516 #        # an each_line_handler() on the line.
2517 #
2518 #        my $self = shift;
2519 #        my $addr = do { no overloading; pack 'J', $self; };
2520 #
2521 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2522 #            my ($adjusted, $line) = @{$inserted_ref};
2523 #            next if $adjusted;
2524 #
2525 #            # Remove comments and trailing space, and return a non-empty
2526 #            # resulting line
2527 #            $line =~ s/#.*//;
2528 #            $line =~ s/\s+$//;
2529 #            return $line if $line ne "";
2530 #        }
2531 #
2532 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2533 #        while (1) { # Loop until find non-comment, non-empty line
2534 #            local $to_trace = 1 if main::DEBUG;
2535 #            trace $_ if main::DEBUG && $to_trace;
2536 #            return if ! defined (my $line = readline $handle{$addr});
2537 #            chomp $line;
2538 #            push @{$added_lines{$addr}}, [ 0, $line ];
2539 #
2540 #            $line =~ s/#.*//;
2541 #            $line =~ s/\s+$//;
2542 #            return $line if $line ne "";
2543 #        }
2544 #
2545 #        return;
2546 #    }
2547
2548
2549     sub insert_lines {
2550         # Lines can be inserted so that it looks like they were in the input
2551         # file at the place it was when this routine is called.  See also
2552         # insert_adjusted_lines().  Lines inserted via this routine go through
2553         # any each_line_handler()
2554
2555         my $self = shift;
2556
2557         # Each inserted line is an array, with the first element being 0 to
2558         # indicate that this line hasn't been adjusted, and needs to be
2559         # processed.
2560         no overloading;
2561         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2562         return;
2563     }
2564
2565     sub insert_adjusted_lines {
2566         # Lines can be inserted so that it looks like they were in the input
2567         # file at the place it was when this routine is called.  See also
2568         # insert_lines().  Lines inserted via this routine are already fully
2569         # adjusted, ready to be processed; each_line_handler()s handlers will
2570         # not be called.  This means this is not a completely general
2571         # facility, as only the last each_line_handler on the stack should
2572         # call this.  It could be made more general, by passing to each of the
2573         # line_handlers their position on the stack, which they would pass on
2574         # to this routine, and that would replace the boolean first element in
2575         # the anonymous array pushed here, so that the next_line routine could
2576         # use that to call only those handlers whose index is after it on the
2577         # stack.  But this is overkill for what is needed now.
2578
2579         my $self = shift;
2580         trace $_[0] if main::DEBUG && $to_trace;
2581
2582         # Each inserted line is an array, with the first element being 1 to
2583         # indicate that this line has been adjusted
2584         no overloading;
2585         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2586         return;
2587     }
2588
2589     sub get_missings {
2590         # Returns the stored up @missings lines' values, and clears the list.
2591         # The values are in an array, consisting of the default in the first
2592         # element, and the property in the 2nd.  However, since these lines
2593         # can be stacked up, the return is an array of all these arrays.
2594
2595         my $self = shift;
2596         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2597
2598         my $addr = do { no overloading; pack 'J', $self; };
2599
2600         # If not accepting a list return, just return the first one.
2601         return shift @{$missings{$addr}} unless wantarray;
2602
2603         my @return = @{$missings{$addr}};
2604         undef @{$missings{$addr}};
2605         return @return;
2606     }
2607
2608     sub _insert_property_into_line {
2609         # Add a property field to $_, if this file requires it.
2610
2611         my $self = shift;
2612         my $addr = do { no overloading; pack 'J', $self; };
2613         my $property = $property{$addr};
2614         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2615
2616         $_ =~ s/(;|$)/; $property$1/;
2617         return;
2618     }
2619
2620     sub carp_bad_line {
2621         # Output consistent error messages, using either a generic one, or the
2622         # one given by the optional parameter.  To avoid gazillions of the
2623         # same message in case the syntax of a  file is way off, this routine
2624         # only outputs the first instance of each message, incrementing a
2625         # count so the totals can be output at the end of the file.
2626
2627         my $self = shift;
2628         my $message = shift;
2629         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2630
2631         my $addr = do { no overloading; pack 'J', $self; };
2632
2633         $message = 'Unexpected line' unless $message;
2634
2635         # No trailing punctuation so as to fit with our addenda.
2636         $message =~ s/[.:;,]$//;
2637
2638         # If haven't seen this exact message before, output it now.  Otherwise
2639         # increment the count of how many times it has occurred
2640         unless ($errors{$addr}->{$message}) {
2641             Carp::my_carp("$message in '$_' in "
2642                             . $file{$addr}
2643                             . " at line $..  Skipping this line;");
2644             $errors{$addr}->{$message} = 1;
2645         }
2646         else {
2647             $errors{$addr}->{$message}++;
2648         }
2649
2650         # Clear the line to prevent any further (meaningful) processing of it.
2651         $_ = "";
2652
2653         return;
2654     }
2655 } # End closure
2656
2657 package Multi_Default;
2658
2659 # Certain properties in early versions of Unicode had more than one possible
2660 # default for code points missing from the files.  In these cases, one
2661 # default applies to everything left over after all the others are applied,
2662 # and for each of the others, there is a description of which class of code
2663 # points applies to it.  This object helps implement this by storing the
2664 # defaults, and for all but that final default, an eval string that generates
2665 # the class that it applies to.
2666
2667
2668 {   # Closure
2669
2670     main::setup_package();
2671
2672     my %class_defaults;
2673     # The defaults structure for the classes
2674     main::set_access('class_defaults', \%class_defaults);
2675
2676     my %other_default;
2677     # The default that applies to everything left over.
2678     main::set_access('other_default', \%other_default, 'r');
2679
2680
2681     sub new {
2682         # The constructor is called with default => eval pairs, terminated by
2683         # the left-over default. e.g.
2684         # Multi_Default->new(
2685         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2686         #               -  0x200D',
2687         #        'R' => 'some other expression that evaluates to code points',
2688         #        .
2689         #        .
2690         #        .
2691         #        'U'));
2692
2693         my $class = shift;
2694
2695         my $self = bless \do{my $anonymous_scalar}, $class;
2696         my $addr = do { no overloading; pack 'J', $self; };
2697
2698         while (@_ > 1) {
2699             my $default = shift;
2700             my $eval = shift;
2701             $class_defaults{$addr}->{$default} = $eval;
2702         }
2703
2704         $other_default{$addr} = shift;
2705
2706         return $self;
2707     }
2708
2709     sub get_next_defaults {
2710         # Iterates and returns the next class of defaults.
2711         my $self = shift;
2712         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2713
2714         my $addr = do { no overloading; pack 'J', $self; };
2715
2716         return each %{$class_defaults{$addr}};
2717     }
2718 }
2719
2720 package Alias;
2721
2722 # An alias is one of the names that a table goes by.  This class defines them
2723 # including some attributes.  Everything is currently setup in the
2724 # constructor.
2725
2726
2727 {   # Closure
2728
2729     main::setup_package();
2730
2731     my %name;
2732     main::set_access('name', \%name, 'r');
2733
2734     my %loose_match;
2735     # Should this name match loosely or not.
2736     main::set_access('loose_match', \%loose_match, 'r');
2737
2738     my %make_re_pod_entry;
2739     # Some aliases should not get their own entries in the re section of the
2740     # pod, because they are covered by a wild-card, and some we want to
2741     # discourage use of.  Binary
2742     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
2743
2744     my %ucd;
2745     # Is this documented to be accessible via Unicode::UCD
2746     main::set_access('ucd', \%ucd, 'r', 's');
2747
2748     my %status;
2749     # Aliases have a status, like deprecated, or even suppressed (which means
2750     # they don't appear in documentation).  Enum
2751     main::set_access('status', \%status, 'r');
2752
2753     my %ok_as_filename;
2754     # Similarly, some aliases should not be considered as usable ones for
2755     # external use, such as file names, or we don't want documentation to
2756     # recommend them.  Boolean
2757     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
2758
2759     sub new {
2760         my $class = shift;
2761
2762         my $self = bless \do { my $anonymous_scalar }, $class;
2763         my $addr = do { no overloading; pack 'J', $self; };
2764
2765         $name{$addr} = shift;
2766         $loose_match{$addr} = shift;
2767         $make_re_pod_entry{$addr} = shift;
2768         $ok_as_filename{$addr} = shift;
2769         $status{$addr} = shift;
2770         $ucd{$addr} = shift;
2771
2772         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2773
2774         # Null names are never ok externally
2775         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
2776
2777         return $self;
2778     }
2779 }
2780
2781 package Range;
2782
2783 # A range is the basic unit for storing code points, and is described in the
2784 # comments at the beginning of the program.  Each range has a starting code
2785 # point; an ending code point (not less than the starting one); a value
2786 # that applies to every code point in between the two end-points, inclusive;
2787 # and an enum type that applies to the value.  The type is for the user's
2788 # convenience, and has no meaning here, except that a non-zero type is
2789 # considered to not obey the normal Unicode rules for having standard forms.
2790 #
2791 # The same structure is used for both map and match tables, even though in the
2792 # latter, the value (and hence type) is irrelevant and could be used as a
2793 # comment.  In map tables, the value is what all the code points in the range
2794 # map to.  Type 0 values have the standardized version of the value stored as
2795 # well, so as to not have to recalculate it a lot.
2796
2797 sub trace { return main::trace(@_); }
2798
2799 {   # Closure
2800
2801     main::setup_package();
2802
2803     my %start;
2804     main::set_access('start', \%start, 'r', 's');
2805
2806     my %end;
2807     main::set_access('end', \%end, 'r', 's');
2808
2809     my %value;
2810     main::set_access('value', \%value, 'r');
2811
2812     my %type;
2813     main::set_access('type', \%type, 'r');
2814
2815     my %standard_form;
2816     # The value in internal standard form.  Defined only if the type is 0.
2817     main::set_access('standard_form', \%standard_form);
2818
2819     # Note that if these fields change, the dump() method should as well
2820
2821     sub new {
2822         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2823         my $class = shift;
2824
2825         my $self = bless \do { my $anonymous_scalar }, $class;
2826         my $addr = do { no overloading; pack 'J', $self; };
2827
2828         $start{$addr} = shift;
2829         $end{$addr} = shift;
2830
2831         my %args = @_;
2832
2833         my $value = delete $args{'Value'};  # Can be 0
2834         $value = "" unless defined $value;
2835         $value{$addr} = $value;
2836
2837         $type{$addr} = delete $args{'Type'} || 0;
2838
2839         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2840
2841         if (! $type{$addr}) {
2842             $standard_form{$addr} = main::standardize($value);
2843         }
2844
2845         return $self;
2846     }
2847
2848     use overload
2849         fallback => 0,
2850         qw("") => "_operator_stringify",
2851         "." => \&main::_operator_dot,
2852     ;
2853
2854     sub _operator_stringify {
2855         my $self = shift;
2856         my $addr = do { no overloading; pack 'J', $self; };
2857
2858         # Output it like '0041..0065 (value)'
2859         my $return = sprintf("%04X", $start{$addr})
2860                         .  '..'
2861                         . sprintf("%04X", $end{$addr});
2862         my $value = $value{$addr};
2863         my $type = $type{$addr};
2864         $return .= ' (';
2865         $return .= "$value";
2866         $return .= ", Type=$type" if $type != 0;
2867         $return .= ')';
2868
2869         return $return;
2870     }
2871
2872     sub standard_form {
2873         # The standard form is the value itself if the standard form is
2874         # undefined (that is if the value is special)
2875
2876         my $self = shift;
2877         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2878
2879         my $addr = do { no overloading; pack 'J', $self; };
2880
2881         return $standard_form{$addr} if defined $standard_form{$addr};
2882         return $value{$addr};
2883     }
2884
2885     sub dump {
2886         # Human, not machine readable.  For machine readable, comment out this
2887         # entire routine and let the standard one take effect.
2888         my $self = shift;
2889         my $indent = shift;
2890         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2891
2892         my $addr = do { no overloading; pack 'J', $self; };
2893
2894         my $return = $indent
2895                     . sprintf("%04X", $start{$addr})
2896                     . '..'
2897                     . sprintf("%04X", $end{$addr})
2898                     . " '$value{$addr}';";
2899         if (! defined $standard_form{$addr}) {
2900             $return .= "(type=$type{$addr})";
2901         }
2902         elsif ($standard_form{$addr} ne $value{$addr}) {
2903             $return .= "(standard '$standard_form{$addr}')";
2904         }
2905         return $return;
2906     }
2907 } # End closure
2908
2909 package _Range_List_Base;
2910
2911 # Base class for range lists.  A range list is simply an ordered list of
2912 # ranges, so that the ranges with the lowest starting numbers are first in it.
2913 #
2914 # When a new range is added that is adjacent to an existing range that has the
2915 # same value and type, it merges with it to form a larger range.
2916 #
2917 # Ranges generally do not overlap, except that there can be multiple entries
2918 # of single code point ranges.  This is because of NameAliases.txt.
2919 #
2920 # In this program, there is a standard value such that if two different
2921 # values, have the same standard value, they are considered equivalent.  This
2922 # value was chosen so that it gives correct results on Unicode data
2923
2924 # There are a number of methods to manipulate range lists, and some operators
2925 # are overloaded to handle them.
2926
2927 sub trace { return main::trace(@_); }
2928
2929 { # Closure
2930
2931     our $addr;
2932
2933     main::setup_package();
2934
2935     my %ranges;
2936     # The list of ranges
2937     main::set_access('ranges', \%ranges, 'readable_array');
2938
2939     my %max;
2940     # The highest code point in the list.  This was originally a method, but
2941     # actual measurements said it was used a lot.
2942     main::set_access('max', \%max, 'r');
2943
2944     my %each_range_iterator;
2945     # Iterator position for each_range()
2946     main::set_access('each_range_iterator', \%each_range_iterator);
2947
2948     my %owner_name_of;
2949     # Name of parent this is attached to, if any.  Solely for better error
2950     # messages.
2951     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2952
2953     my %_search_ranges_cache;
2954     # A cache of the previous result from _search_ranges(), for better
2955     # performance
2956     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2957
2958     sub new {
2959         my $class = shift;
2960         my %args = @_;
2961
2962         # Optional initialization data for the range list.
2963         my $initialize = delete $args{'Initialize'};
2964
2965         my $self;
2966
2967         # Use _union() to initialize.  _union() returns an object of this
2968         # class, which means that it will call this constructor recursively.
2969         # But it won't have this $initialize parameter so that it won't
2970         # infinitely loop on this.
2971         return _union($class, $initialize, %args) if defined $initialize;
2972
2973         $self = bless \do { my $anonymous_scalar }, $class;
2974         my $addr = do { no overloading; pack 'J', $self; };
2975
2976         # Optional parent object, only for debug info.
2977         $owner_name_of{$addr} = delete $args{'Owner'};
2978         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2979
2980         # Stringify, in case it is an object.
2981         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2982
2983         # This is used only for error messages, and so a colon is added
2984         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2985
2986         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2987
2988         # Max is initialized to a negative value that isn't adjacent to 0,
2989         # for simpler tests
2990         $max{$addr} = -2;
2991
2992         $_search_ranges_cache{$addr} = 0;
2993         $ranges{$addr} = [];
2994
2995         return $self;
2996     }
2997
2998     use overload
2999         fallback => 0,
3000         qw("") => "_operator_stringify",
3001         "." => \&main::_operator_dot,
3002     ;
3003
3004     sub _operator_stringify {
3005         my $self = shift;
3006         my $addr = do { no overloading; pack 'J', $self; };
3007
3008         return "Range_List attached to '$owner_name_of{$addr}'"
3009                                                 if $owner_name_of{$addr};
3010         return "anonymous Range_List " . \$self;
3011     }
3012
3013     sub _union {
3014         # Returns the union of the input code points.  It can be called as
3015         # either a constructor or a method.  If called as a method, the result
3016         # will be a new() instance of the calling object, containing the union
3017         # of that object with the other parameter's code points;  if called as
3018         # a constructor, the first parameter gives the class that the new object
3019         # should be, and the second parameter gives the code points to go into
3020         # it.
3021         # In either case, there are two parameters looked at by this routine;
3022         # any additional parameters are passed to the new() constructor.
3023         #
3024         # The code points can come in the form of some object that contains
3025         # ranges, and has a conventionally named method to access them; or
3026         # they can be an array of individual code points (as integers); or
3027         # just a single code point.
3028         #
3029         # If they are ranges, this routine doesn't make any effort to preserve
3030         # the range values and types of one input over the other.  Therefore
3031         # this base class should not allow _union to be called from other than
3032         # initialization code, so as to prevent two tables from being added
3033         # together where the range values matter.  The general form of this
3034         # routine therefore belongs in a derived class, but it was moved here
3035         # to avoid duplication of code.  The failure to overload this in this
3036         # class keeps it safe.
3037         #
3038         # It does make the effort during initialization to accept tables with
3039         # multiple values for the same code point, and to preserve the order
3040         # of these.  If there is only one input range or range set, it doesn't
3041         # sort (as it should already be sorted to the desired order), and will
3042         # accept multiple values per code point.  Otherwise it will merge
3043         # multiple values into a single one.
3044
3045         my $self;
3046         my @args;   # Arguments to pass to the constructor
3047
3048         my $class = shift;
3049
3050         # If a method call, will start the union with the object itself, and
3051         # the class of the new object will be the same as self.
3052         if (ref $class) {
3053             $self = $class;
3054             $class = ref $self;
3055             push @args, $self;
3056         }
3057
3058         # Add the other required parameter.
3059         push @args, shift;
3060         # Rest of parameters are passed on to the constructor
3061
3062         # Accumulate all records from both lists.
3063         my @records;
3064         my $input_count = 0;
3065         for my $arg (@args) {
3066             #local $to_trace = 0 if main::DEBUG;
3067             trace "argument = $arg" if main::DEBUG && $to_trace;
3068             if (! defined $arg) {
3069                 my $message = "";
3070                 if (defined $self) {
3071                     no overloading;
3072                     $message .= $owner_name_of{pack 'J', $self};
3073                 }
3074                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
3075                 return;
3076             }
3077
3078             $arg = [ $arg ] if ! ref $arg;
3079             my $type = ref $arg;
3080             if ($type eq 'ARRAY') {
3081                 foreach my $element (@$arg) {
3082                     push @records, Range->new($element, $element);
3083                     $input_count++;
3084                 }
3085             }
3086             elsif ($arg->isa('Range')) {
3087                 push @records, $arg;
3088                 $input_count++;
3089             }
3090             elsif ($arg->can('ranges')) {
3091                 push @records, $arg->ranges;
3092                 $input_count++;
3093             }
3094             else {
3095                 my $message = "";
3096                 if (defined $self) {
3097                     no overloading;
3098                     $message .= $owner_name_of{pack 'J', $self};
3099                 }
3100                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3101                 return;
3102             }
3103         }
3104
3105         # Sort with the range containing the lowest ordinal first, but if
3106         # two ranges start at the same code point, sort with the bigger range
3107         # of the two first, because it takes fewer cycles.
3108         if ($input_count > 1) {
3109             @records = sort { ($a->start <=> $b->start)
3110                                       or
3111                                     # if b is shorter than a, b->end will be
3112                                     # less than a->end, and we want to select
3113                                     # a, so want to return -1
3114                                     ($b->end <=> $a->end)
3115                                    } @records;
3116         }
3117
3118         my $new = $class->new(@_);
3119
3120         # Fold in records so long as they add new information.
3121         for my $set (@records) {
3122             my $start = $set->start;
3123             my $end   = $set->end;
3124             my $value = $set->value;
3125             my $type  = $set->type;
3126             if ($start > $new->max) {
3127                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3128             }
3129             elsif ($end > $new->max) {
3130                 $new->_add_delete('+', $new->max +1, $end, $value,
3131                                                                 Type => $type);
3132             }
3133             elsif ($input_count == 1) {
3134                 # Here, overlaps existing range, but is from a single input,
3135                 # so preserve the multiple values from that input.
3136                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3137                                                 Replace => $MULTIPLE_AFTER);
3138             }
3139         }
3140
3141         return $new;
3142     }
3143
3144     sub range_count {        # Return the number of ranges in the range list
3145         my $self = shift;
3146         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3147
3148         no overloading;
3149         return scalar @{$ranges{pack 'J', $self}};
3150     }
3151
3152     sub min {
3153         # Returns the minimum code point currently in the range list, or if
3154         # the range list is empty, 2 beyond the max possible.  This is a
3155         # method because used so rarely, that not worth saving between calls,
3156         # and having to worry about changing it as ranges are added and
3157         # deleted.
3158
3159         my $self = shift;
3160         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3161
3162         my $addr = do { no overloading; pack 'J', $self; };
3163
3164         # If the range list is empty, return a large value that isn't adjacent
3165         # to any that could be in the range list, for simpler tests
3166         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3167         return $ranges{$addr}->[0]->start;
3168     }
3169
3170     sub contains {
3171         # Boolean: Is argument in the range list?  If so returns $i such that:
3172         #   range[$i]->end < $codepoint <= range[$i+1]->end
3173         # which is one beyond what you want; this is so that the 0th range
3174         # doesn't return false
3175         my $self = shift;
3176         my $codepoint = shift;
3177         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3178
3179         my $i = $self->_search_ranges($codepoint);
3180         return 0 unless defined $i;
3181
3182         # The search returns $i, such that
3183         #   range[$i-1]->end < $codepoint <= range[$i]->end
3184         # So is in the table if and only iff it is at least the start position
3185         # of range $i.
3186         no overloading;
3187         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3188         return $i + 1;
3189     }
3190
3191     sub containing_range {
3192         # Returns the range object that contains the code point, undef if none
3193
3194         my $self = shift;
3195         my $codepoint = shift;
3196         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3197
3198         my $i = $self->contains($codepoint);
3199         return unless $i;
3200
3201         # contains() returns 1 beyond where we should look
3202         no overloading;
3203         return $ranges{pack 'J', $self}->[$i-1];
3204     }
3205
3206     sub value_of {
3207         # Returns the value associated with the code point, undef if none
3208
3209         my $self = shift;
3210         my $codepoint = shift;
3211         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3212
3213         my $range = $self->containing_range($codepoint);
3214         return unless defined $range;
3215
3216         return $range->value;
3217     }
3218
3219     sub type_of {
3220         # Returns the type of the range containing the code point, undef if
3221         # the code point is not in the table
3222
3223         my $self = shift;
3224         my $codepoint = shift;
3225         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3226
3227         my $range = $self->containing_range($codepoint);
3228         return unless defined $range;
3229
3230         return $range->type;
3231     }
3232
3233     sub _search_ranges {
3234         # Find the range in the list which contains a code point, or where it
3235         # should go if were to add it.  That is, it returns $i, such that:
3236         #   range[$i-1]->end < $codepoint <= range[$i]->end
3237         # Returns undef if no such $i is possible (e.g. at end of table), or
3238         # if there is an error.
3239
3240         my $self = shift;
3241         my $code_point = shift;
3242         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3243
3244         my $addr = do { no overloading; pack 'J', $self; };
3245
3246         return if $code_point > $max{$addr};
3247         my $r = $ranges{$addr};                # The current list of ranges
3248         my $range_list_size = scalar @$r;
3249         my $i;
3250
3251         use integer;        # want integer division
3252
3253         # Use the cached result as the starting guess for this one, because,
3254         # an experiment on 5.1 showed that 90% of the time the cache was the
3255         # same as the result on the next call (and 7% it was one less).
3256         $i = $_search_ranges_cache{$addr};
3257         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3258                                             # from an intervening deletion
3259         #local $to_trace = 1 if main::DEBUG;
3260         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3261         return $i if $code_point <= $r->[$i]->end
3262                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3263
3264         # Here the cache doesn't yield the correct $i.  Try adding 1.
3265         if ($i < $range_list_size - 1
3266             && $r->[$i]->end < $code_point &&
3267             $code_point <= $r->[$i+1]->end)
3268         {
3269             $i++;
3270             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3271             $_search_ranges_cache{$addr} = $i;
3272             return $i;
3273         }
3274
3275         # Here, adding 1 also didn't work.  We do a binary search to
3276         # find the correct position, starting with current $i
3277         my $lower = 0;
3278         my $upper = $range_list_size - 1;
3279         while (1) {
3280             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3281
3282             if ($code_point <= $r->[$i]->end) {
3283
3284                 # Here we have met the upper constraint.  We can quit if we
3285                 # also meet the lower one.
3286                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3287
3288                 $upper = $i;        # Still too high.
3289
3290             }
3291             else {
3292
3293                 # Here, $r[$i]->end < $code_point, so look higher up.
3294                 $lower = $i;
3295             }
3296
3297             # Split search domain in half to try again.
3298             my $temp = ($upper + $lower) / 2;
3299
3300             # No point in continuing unless $i changes for next time
3301             # in the loop.
3302             if ($temp == $i) {
3303
3304                 # We can't reach the highest element because of the averaging.
3305                 # So if one below the upper edge, force it there and try one
3306                 # more time.
3307                 if ($i == $range_list_size - 2) {
3308
3309                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3310                     $i = $range_list_size - 1;
3311
3312                     # Change $lower as well so if fails next time through,
3313                     # taking the average will yield the same $i, and we will
3314                     # quit with the error message just below.
3315                     $lower = $i;
3316                     next;
3317                 }
3318                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3319                 return;
3320             }
3321             $i = $temp;
3322         } # End of while loop
3323
3324         if (main::DEBUG && $to_trace) {
3325             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3326             trace "i=  [ $i ]", $r->[$i];
3327             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3328         }
3329
3330         # Here we have found the offset.  Cache it as a starting point for the
3331         # next call.
3332         $_search_ranges_cache{$addr} = $i;
3333         return $i;
3334     }
3335
3336     sub _add_delete {
3337         # Add, replace or delete ranges to or from a list.  The $type
3338         # parameter gives which:
3339         #   '+' => insert or replace a range, returning a list of any changed
3340         #          ranges.
3341         #   '-' => delete a range, returning a list of any deleted ranges.
3342         #
3343         # The next three parameters give respectively the start, end, and
3344         # value associated with the range.  'value' should be null unless the
3345         # operation is '+';
3346         #
3347         # The range list is kept sorted so that the range with the lowest
3348         # starting position is first in the list, and generally, adjacent
3349         # ranges with the same values are merged into a single larger one (see
3350         # exceptions below).
3351         #
3352         # There are more parameters; all are key => value pairs:
3353         #   Type    gives the type of the value.  It is only valid for '+'.
3354         #           All ranges have types; if this parameter is omitted, 0 is
3355         #           assumed.  Ranges with type 0 are assumed to obey the
3356         #           Unicode rules for casing, etc; ranges with other types are
3357         #           not.  Otherwise, the type is arbitrary, for the caller's
3358         #           convenience, and looked at only by this routine to keep
3359         #           adjacent ranges of different types from being merged into
3360         #           a single larger range, and when Replace =>
3361         #           $IF_NOT_EQUIVALENT is specified (see just below).
3362         #   Replace  determines what to do if the range list already contains
3363         #            ranges which coincide with all or portions of the input
3364         #            range.  It is only valid for '+':
3365         #       => $NO            means that the new value is not to replace
3366         #                         any existing ones, but any empty gaps of the
3367         #                         range list coinciding with the input range
3368         #                         will be filled in with the new value.
3369         #       => $UNCONDITIONALLY  means to replace the existing values with
3370         #                         this one unconditionally.  However, if the
3371         #                         new and old values are identical, the
3372         #                         replacement is skipped to save cycles
3373         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3374         #          (the default)  with this one if they are not equivalent.
3375         #                         Ranges are equivalent if their types are the
3376         #                         same, and they are the same string; or if
3377         #                         both are type 0 ranges, if their Unicode
3378         #                         standard forms are identical.  In this last
3379         #                         case, the routine chooses the more "modern"
3380         #                         one to use.  This is because some of the
3381         #                         older files are formatted with values that
3382         #                         are, for example, ALL CAPs, whereas the
3383         #                         derived files have a more modern style,
3384         #                         which looks better.  By looking for this
3385         #                         style when the pre-existing and replacement
3386         #                         standard forms are the same, we can move to
3387         #                         the modern style
3388         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3389         #                         existing one, but has a different value,
3390         #                         don't replace the existing one, but insert
3391         #                         this, one so that the same range can occur
3392         #                         multiple times.  They are stored LIFO, so
3393         #                         that the final one inserted is the first one
3394         #                         returned in an ordered search of the table.
3395         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3396         #                         FIFO, so that this one is inserted after all
3397         #                         others that currently exist.
3398         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3399         #
3400         # "same value" means identical for non-type-0 ranges, and it means
3401         # having the same standard forms for type-0 ranges.
3402
3403         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3404
3405         my $self = shift;
3406         my $operation = shift;   # '+' for add/replace; '-' for delete;
3407         my $start = shift;
3408         my $end   = shift;
3409         my $value = shift;
3410
3411         my %args = @_;
3412
3413         $value = "" if not defined $value;        # warning: $value can be "0"
3414
3415         my $replace = delete $args{'Replace'};
3416         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3417
3418         my $type = delete $args{'Type'};
3419         $type = 0 unless defined $type;
3420
3421         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3422
3423         my $addr = do { no overloading; pack 'J', $self; };
3424
3425         if ($operation ne '+' && $operation ne '-') {
3426             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3427             return;
3428         }
3429         unless (defined $start && defined $end) {
3430             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3431             return;
3432         }
3433         unless ($end >= $start) {
3434             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3435             return;
3436         }
3437         #local $to_trace = 1 if main::DEBUG;
3438
3439         if ($operation eq '-') {
3440             if ($replace != $IF_NOT_EQUIVALENT) {
3441                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3442                 $replace = $IF_NOT_EQUIVALENT;
3443             }
3444             if ($type) {
3445                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3446                 $type = 0;
3447             }
3448             if ($value ne "") {
3449                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3450                 $value = "";
3451             }
3452         }
3453
3454         my $r = $ranges{$addr};               # The current list of ranges
3455         my $range_list_size = scalar @$r;     # And its size
3456         my $max = $max{$addr};                # The current high code point in
3457                                               # the list of ranges
3458
3459         # Do a special case requiring fewer machine cycles when the new range
3460         # starts after the current highest point.  The Unicode input data is
3461         # structured so this is common.
3462         if ($start > $max) {
3463
3464             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3465             return if $operation eq '-'; # Deleting a non-existing range is a
3466                                          # no-op
3467
3468             # If the new range doesn't logically extend the current final one
3469             # in the range list, create a new range at the end of the range
3470             # list.  (max cleverly is initialized to a negative number not
3471             # adjacent to 0 if the range list is empty, so even adding a range
3472             # to an empty range list starting at 0 will have this 'if'
3473             # succeed.)
3474             if ($start > $max + 1        # non-adjacent means can't extend.
3475                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3476                 || @{$r}[-1]->type != $type # types differ, can't extend.
3477             ) {
3478                 push @$r, Range->new($start, $end,
3479                                      Value => $value,
3480                                      Type => $type);
3481             }
3482             else {
3483
3484                 # Here, the new range starts just after the current highest in
3485                 # the range list, and they have the same type and value.
3486                 # Extend the current range to incorporate the new one.
3487                 @{$r}[-1]->set_end($end);
3488             }
3489
3490             # This becomes the new maximum.
3491             $max{$addr} = $end;
3492
3493             return;
3494         }
3495         #local $to_trace = 0 if main::DEBUG;
3496
3497         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3498
3499         # Here, the input range isn't after the whole rest of the range list.
3500         # Most likely 'splice' will be needed.  The rest of the routine finds
3501         # the needed splice parameters, and if necessary, does the splice.
3502         # First, find the offset parameter needed by the splice function for
3503         # the input range.  Note that the input range may span multiple
3504         # existing ones, but we'll worry about that later.  For now, just find
3505         # the beginning.  If the input range is to be inserted starting in a
3506         # position not currently in the range list, it must (obviously) come
3507         # just after the range below it, and just before the range above it.
3508         # Slightly less obviously, it will occupy the position currently
3509         # occupied by the range that is to come after it.  More formally, we
3510         # are looking for the position, $i, in the array of ranges, such that:
3511         #
3512         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3513         #
3514         # (The ordered relationships within existing ranges are also shown in
3515         # the equation above).  However, if the start of the input range is
3516         # within an existing range, the splice offset should point to that
3517         # existing range's position in the list; that is $i satisfies a
3518         # somewhat different equation, namely:
3519         #
3520         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3521         #
3522         # More briefly, $start can come before or after r[$i]->start, and at
3523         # this point, we don't know which it will be.  However, these
3524         # two equations share these constraints:
3525         #
3526         #   r[$i-1]->end < $start <= r[$i]->end
3527         #
3528         # And that is good enough to find $i.
3529
3530         my $i = $self->_search_ranges($start);
3531         if (! defined $i) {
3532             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3533             return;
3534         }
3535
3536         # The search function returns $i such that:
3537         #
3538         # r[$i-1]->end < $start <= r[$i]->end
3539         #
3540         # That means that $i points to the first range in the range list
3541         # that could possibly be affected by this operation.  We still don't
3542         # know if the start of the input range is within r[$i], or if it
3543         # points to empty space between r[$i-1] and r[$i].
3544         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3545
3546         # Special case the insertion of data that is not to replace any
3547         # existing data.
3548         if ($replace == $NO) {  # If $NO, has to be operation '+'
3549             #local $to_trace = 1 if main::DEBUG;
3550             trace "Doesn't replace" if main::DEBUG && $to_trace;
3551
3552             # Here, the new range is to take effect only on those code points
3553             # that aren't already in an existing range.  This can be done by
3554             # looking through the existing range list and finding the gaps in
3555             # the ranges that this new range affects, and then calling this
3556             # function recursively on each of those gaps, leaving untouched
3557             # anything already in the list.  Gather up a list of the changed
3558             # gaps first so that changes to the internal state as new ranges
3559             # are added won't be a problem.
3560             my @gap_list;
3561
3562             # First, if the starting point of the input range is outside an
3563             # existing one, there is a gap from there to the beginning of the
3564             # existing range -- add a span to fill the part that this new
3565             # range occupies
3566             if ($start < $r->[$i]->start) {
3567                 push @gap_list, Range->new($start,
3568                                            main::min($end,
3569                                                      $r->[$i]->start - 1),
3570                                            Type => $type);
3571                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3572             }
3573
3574             # Then look through the range list for other gaps until we reach
3575             # the highest range affected by the input one.
3576             my $j;
3577             for ($j = $i+1; $j < $range_list_size; $j++) {
3578                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3579                 last if $end < $r->[$j]->start;
3580
3581                 # If there is a gap between when this range starts and the
3582                 # previous one ends, add a span to fill it.  Note that just
3583                 # because there are two ranges doesn't mean there is a
3584                 # non-zero gap between them.  It could be that they have
3585                 # different values or types
3586                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3587                     push @gap_list,
3588                         Range->new($r->[$j-1]->end + 1,
3589                                    $r->[$j]->start - 1,
3590                                    Type => $type);
3591                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3592                 }
3593             }
3594
3595             # Here, we have either found an existing range in the range list,
3596             # beyond the area affected by the input one, or we fell off the
3597             # end of the loop because the input range affects the whole rest
3598             # of the range list.  In either case, $j is 1 higher than the
3599             # highest affected range.  If $j == $i, it means that there are no
3600             # affected ranges, that the entire insertion is in the gap between
3601             # r[$i-1], and r[$i], which we already have taken care of before
3602             # the loop.
3603             # On the other hand, if there are affected ranges, it might be
3604             # that there is a gap that needs filling after the final such
3605             # range to the end of the input range
3606             if ($r->[$j-1]->end < $end) {
3607                     push @gap_list, Range->new(main::max($start,
3608                                                          $r->[$j-1]->end + 1),
3609                                                $end,
3610                                                Type => $type);
3611                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3612             }
3613
3614             # Call recursively to fill in all the gaps.
3615             foreach my $gap (@gap_list) {
3616                 $self->_add_delete($operation,
3617                                    $gap->start,
3618                                    $gap->end,
3619                                    $value,
3620                                    Type => $type);
3621             }
3622
3623             return;
3624         }
3625
3626         # Here, we have taken care of the case where $replace is $NO.
3627         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3628         # If inserting a multiple record, this is where it goes, before the
3629         # first (if any) existing one if inserting LIFO.  (If this is to go
3630         # afterwards, FIFO, we below move the pointer to there.)  These imply
3631         # an insertion, and no change to any existing ranges.  Note that $i
3632         # can be -1 if this new range doesn't actually duplicate any existing,
3633         # and comes at the beginning of the list.
3634         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3635
3636             if ($start != $end) {
3637                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3638                 return;
3639             }
3640
3641             # If the new code point is within a current range ...
3642             if ($end >= $r->[$i]->start) {
3643
3644                 # Don't add an exact duplicate, as it isn't really a multiple
3645                 my $existing_value = $r->[$i]->value;
3646                 my $existing_type = $r->[$i]->type;
3647                 return if $value eq $existing_value && $type eq $existing_type;
3648
3649                 # If the multiple value is part of an existing range, we want
3650                 # to split up that range, so that only the single code point
3651                 # is affected.  To do this, we first call ourselves
3652                 # recursively to delete that code point from the table, having
3653                 # preserved its current data above.  Then we call ourselves
3654                 # recursively again to add the new multiple, which we know by
3655                 # the test just above is different than the current code
3656                 # point's value, so it will become a range containing a single
3657                 # code point: just itself.  Finally, we add back in the
3658                 # pre-existing code point, which will again be a single code
3659                 # point range.  Because 'i' likely will have changed as a
3660                 # result of these operations, we can't just continue on, but
3661                 # do this operation recursively as well.  If we are inserting
3662                 # LIFO, the pre-existing code point needs to go after the new
3663                 # one, so use MULTIPLE_AFTER; and vice versa.
3664                 if ($r->[$i]->start != $r->[$i]->end) {
3665                     $self->_add_delete('-', $start, $end, "");
3666                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3667                     return $self->_add_delete('+',
3668                             $start, $end,
3669                             $existing_value,
3670                             Type => $existing_type,
3671                             Replace => ($replace == $MULTIPLE_BEFORE)
3672                                        ? $MULTIPLE_AFTER
3673                                        : $MULTIPLE_BEFORE);
3674                 }
3675             }
3676
3677             # If to place this new record after, move to beyond all existing
3678             # ones.
3679             if ($replace == $MULTIPLE_AFTER) {
3680                 while ($i < @$r && $r->[$i]->start == $start) {
3681                     $i++;
3682                 }
3683             }
3684
3685             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3686             my @return = splice @$r,
3687                                 $i,
3688                                 0,
3689                                 Range->new($start,
3690                                            $end,
3691                                            Value => $value,
3692                                            Type => $type);
3693             if (main::DEBUG && $to_trace) {
3694                 trace "After splice:";
3695                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3696                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3697                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3698                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3699                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3700                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3701             }
3702             return @return;
3703         }
3704
3705         # Here, we have taken care of $NO and $MULTIPLE_foo replaces.  This
3706         # leaves delete, insert, and replace either unconditionally or if not
3707         # equivalent.  $i still points to the first potential affected range.
3708         # Now find the highest range affected, which will determine the length
3709         # parameter to splice.  (The input range can span multiple existing
3710         # ones.)  If this isn't a deletion, while we are looking through the
3711         # range list, see also if this is a replacement rather than a clean
3712         # insertion; that is if it will change the values of at least one
3713         # existing range.  Start off assuming it is an insert, until find it
3714         # isn't.
3715         my $clean_insert = $operation eq '+';
3716         my $j;        # This will point to the highest affected range
3717
3718         # For non-zero types, the standard form is the value itself;
3719         my $standard_form = ($type) ? $value : main::standardize($value);
3720
3721         for ($j = $i; $j < $range_list_size; $j++) {
3722             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3723
3724             # If find a range that it doesn't overlap into, we can stop
3725             # searching
3726             last if $end < $r->[$j]->start;
3727
3728             # Here, overlaps the range at $j.  If the values don't match,
3729             # and so far we think this is a clean insertion, it becomes a
3730             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3731             if ($clean_insert) {
3732                 if ($r->[$j]->standard_form ne $standard_form) {
3733                     $clean_insert = 0;
3734                     if ($replace == $CROAK) {
3735                         main::croak("The range to add "
3736                         . sprintf("%04X", $start)
3737                         . '-'
3738                         . sprintf("%04X", $end)
3739                         . " with value '$value' overlaps an existing range $r->[$j]");
3740                     }
3741                 }
3742                 else {
3743
3744                     # Here, the two values are essentially the same.  If the
3745                     # two are actually identical, replacing wouldn't change
3746                     # anything so skip it.
3747                     my $pre_existing = $r->[$j]->value;
3748                     if ($pre_existing ne $value) {
3749
3750                         # Here the new and old standardized values are the
3751                         # same, but the non-standardized values aren't.  If
3752                         # replacing unconditionally, then replace
3753                         if( $replace == $UNCONDITIONALLY) {
3754                             $clean_insert = 0;
3755                         }
3756                         else {
3757
3758                             # Here, are replacing conditionally.  Decide to
3759                             # replace or not based on which appears to look
3760                             # the "nicest".  If one is mixed case and the
3761                             # other isn't, choose the mixed case one.
3762                             my $new_mixed = $value =~ /[A-Z]/
3763                                             && $value =~ /[a-z]/;
3764                             my $old_mixed = $pre_existing =~ /[A-Z]/
3765                                             && $pre_existing =~ /[a-z]/;
3766
3767                             if ($old_mixed != $new_mixed) {
3768                                 $clean_insert = 0 if $new_mixed;
3769                                 if (main::DEBUG && $to_trace) {
3770                                     if ($clean_insert) {
3771                                         trace "Retaining $pre_existing over $value";
3772                                     }
3773                                     else {
3774                                         trace "Replacing $pre_existing with $value";
3775                                     }
3776                                 }
3777                             }
3778                             else {
3779
3780                                 # Here casing wasn't different between the two.
3781                                 # If one has hyphens or underscores and the
3782                                 # other doesn't, choose the one with the
3783                                 # punctuation.
3784                                 my $new_punct = $value =~ /[-_]/;
3785                                 my $old_punct = $pre_existing =~ /[-_]/;
3786
3787                                 if ($old_punct != $new_punct) {
3788                                     $clean_insert = 0 if $new_punct;
3789                                     if (main::DEBUG && $to_trace) {
3790                                         if ($clean_insert) {
3791                                             trace "Retaining $pre_existing over $value";
3792                                         }
3793                                         else {
3794                                             trace "Replacing $pre_existing with $value";
3795                                         }
3796                                     }
3797                                 }   # else existing one is just as "good";
3798                                     # retain it to save cycles.
3799                             }
3800                         }
3801                     }
3802                 }
3803             }
3804         } # End of loop looking for highest affected range.
3805
3806         # Here, $j points to one beyond the highest range that this insertion
3807         # affects (hence to beyond the range list if that range is the final
3808         # one in the range list).
3809
3810         # The splice length is all the affected ranges.  Get it before
3811         # subtracting, for efficiency, so we don't have to later add 1.
3812         my $length = $j - $i;
3813
3814         $j--;        # $j now points to the highest affected range.
3815         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3816
3817         # Here, have taken care of $NO and $MULTIPLE_foo replaces.
3818         # $j points to the highest affected range.  But it can be < $i or even
3819         # -1.  These happen only if the insertion is entirely in the gap
3820         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3821         # above exited first time through with $end < $r->[$i]->start.  (And
3822         # then we subtracted one from j)  This implies also that $start <
3823         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3824         # $start, so the entire input range is in the gap.
3825         if ($j < $i) {
3826
3827             # Here the entire input range is in the gap before $i.
3828
3829             if (main::DEBUG && $to_trace) {
3830                 if ($i) {
3831                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3832                 }
3833                 else {
3834                     trace "Entire range is before $r->[$i]";
3835                 }
3836             }
3837             return if $operation ne '+'; # Deletion of a non-existent range is
3838                                          # a no-op
3839         }
3840         else {
3841
3842             # Here part of the input range is not in the gap before $i.  Thus,
3843             # there is at least one affected one, and $j points to the highest
3844             # such one.
3845
3846             # At this point, here is the situation:
3847             # This is not an insertion of a multiple, nor of tentative ($NO)
3848             # data.
3849             #   $i  points to the first element in the current range list that
3850             #            may be affected by this operation.  In fact, we know
3851             #            that the range at $i is affected because we are in
3852             #            the else branch of this 'if'
3853             #   $j  points to the highest affected range.
3854             # In other words,
3855             #   r[$i-1]->end < $start <= r[$i]->end
3856             # And:
3857             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3858             #
3859             # Also:
3860             #   $clean_insert is a boolean which is set true if and only if
3861             #        this is a "clean insertion", i.e., not a change nor a
3862             #        deletion (multiple was handled above).
3863
3864             # We now have enough information to decide if this call is a no-op
3865             # or not.  It is a no-op if this is an insertion of already
3866             # existing data.
3867
3868             if (main::DEBUG && $to_trace && $clean_insert
3869                                          && $i == $j
3870                                          && $start >= $r->[$i]->start)
3871             {
3872                     trace "no-op";
3873             }
3874             return if $clean_insert
3875                       && $i == $j # more than one affected range => not no-op
3876
3877                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3878                       # Further, $start and/or $end is >= r[$i]->start
3879                       # The test below hence guarantees that
3880                       #     r[$i]->start < $start <= $end <= r[$i]->end
3881                       # This means the input range is contained entirely in
3882                       # the one at $i, so is a no-op
3883                       && $start >= $r->[$i]->start;
3884         }
3885
3886         # Here, we know that some action will have to be taken.  We have
3887         # calculated the offset and length (though adjustments may be needed)
3888         # for the splice.  Now start constructing the replacement list.
3889         my @replacement;
3890         my $splice_start = $i;
3891
3892         my $extends_below;
3893         my $extends_above;
3894
3895         # See if should extend any adjacent ranges.
3896         if ($operation eq '-') { # Don't extend deletions
3897             $extends_below = $extends_above = 0;
3898         }
3899         else {  # Here, should extend any adjacent ranges.  See if there are
3900                 # any.
3901             $extends_below = ($i > 0
3902                             # can't extend unless adjacent
3903                             && $r->[$i-1]->end == $start -1
3904                             # can't extend unless are same standard value
3905                             && $r->[$i-1]->standard_form eq $standard_form
3906                             # can't extend unless share type
3907                             && $r->[$i-1]->type == $type);
3908             $extends_above = ($j+1 < $range_list_size
3909                             && $r->[$j+1]->start == $end +1
3910                             && $r->[$j+1]->standard_form eq $standard_form
3911                             && $r->[$j+1]->type == $type);
3912         }
3913         if ($extends_below && $extends_above) { # Adds to both
3914             $splice_start--;     # start replace at element below
3915             $length += 2;        # will replace on both sides
3916             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3917
3918             # The result will fill in any gap, replacing both sides, and
3919             # create one large range.
3920             @replacement = Range->new($r->[$i-1]->start,
3921                                       $r->[$j+1]->end,
3922                                       Value => $value,
3923                                       Type => $type);
3924         }
3925         else {
3926
3927             # Here we know that the result won't just be the conglomeration of
3928             # a new range with both its adjacent neighbors.  But it could
3929             # extend one of them.
3930
3931             if ($extends_below) {
3932
3933                 # Here the new element adds to the one below, but not to the
3934                 # one above.  If inserting, and only to that one range,  can
3935                 # just change its ending to include the new one.
3936                 if ($length == 0 && $clean_insert) {
3937                     $r->[$i-1]->set_end($end);
3938                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3939                     return;
3940                 }
3941                 else {
3942                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3943                     $splice_start--;        # start replace at element below
3944                     $length++;              # will replace the element below
3945                     $start = $r->[$i-1]->start;
3946                 }
3947             }
3948             elsif ($extends_above) {
3949
3950                 # Here the new element adds to the one above, but not below.
3951                 # Mirror the code above
3952                 if ($length == 0 && $clean_insert) {
3953                     $r->[$j+1]->set_start($start);
3954                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3955                     return;
3956                 }
3957                 else {
3958                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3959                     $length++;        # will replace the element above
3960                     $end = $r->[$j+1]->end;
3961                 }
3962             }
3963
3964             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3965