This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
bf439aef8544455acce6f782f9edf64159e40198
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start of the string's first line and the end of its last line to
35 matching the start and end of each line within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in a bracketed
76 character class unless the character that maps to them is explicitly
77 mentioned, and it doesn't match them at all if the character class is
78 inverted, which otherwise could be highly confusing.  See
79 L<perlrecharclass/Bracketed Character Classes>, and
80 L<perlrecharclass/Negation>.
81
82 =item x
83 X</x>
84
85 Extend your pattern's legibility by permitting whitespace and comments.
86 Details in L</"/x">
87
88 =item p
89 X</p> X<regex, preserve> X<regexp, preserve>
90
91 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
92 ${^POSTMATCH} are available for use after matching.
93
94 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
95 mechanism, ${^PREMATCH}, ${^MATCH}, and ${^POSTMATCH} will be available
96 after the match regardless of the modifier.
97
98 =item a, d, l and u
99 X</a> X</d> X</l> X</u>
100
101 These modifiers, all new in 5.14, affect which character-set rules
102 (Unicode, etc.) are used, as described below in
103 L</Character set modifiers>.
104
105 =item Other Modifiers
106
107 There are a number of flags that can be found at the end of regular
108 expression constructs that are I<not> generic regular expression flags, but
109 apply to the operation being performed, like matching or substitution (C<m//>
110 or C<s///> respectively).
111
112 Flags described further in
113 L<perlretut/"Using regular expressions in Perl"> are:
114
115   c  - keep the current position during repeated matching
116   g  - globally match the pattern repeatedly in the string
117
118 Substitution-specific modifiers described in
119
120 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualgcer"> are:
121
122   e  - evaluate the right-hand side as an expression
123   ee - evaluate the right side as a string then eval the result
124   o  - pretend to optimize your code, but actually introduce bugs
125   r  - perform non-destructive substitution and return the new value
126
127 =back
128
129 Regular expression modifiers are usually written in documentation
130 as e.g., "the C</x> modifier", even though the delimiter
131 in question might not really be a slash.  The modifiers C</imsxadlup>
132 may also be embedded within the regular expression itself using
133 the C<(?...)> construct, see L</Extended Patterns> below.
134
135 =head3 /x
136
137 C</x> tells
138 the regular expression parser to ignore most whitespace that is neither
139 backslashed nor within a bracketed character class.  You can use this to
140 break up your regular expression into (slightly) more readable parts.
141 Also, the C<#> character is treated as a metacharacter introducing a
142 comment that runs up to the pattern's closing delimiter, or to the end
143 of the current line if the pattern extends onto the next line.  Hence,
144 this is very much like an ordinary Perl code comment.  (You can include
145 the closing delimiter within the comment only if you precede it with a
146 backslash, so be careful!)
147
148 Use of C</x> means that if you want real
149 whitespace or C<#> characters in the pattern (outside a bracketed character
150 class, which is unaffected by C</x>), then you'll either have to
151 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
152 hex, or C<\N{}> escapes.
153 It is ineffective to try to continue a comment onto the next line by
154 escaping the C<\n> with a backslash or C<\Q>.
155
156 You can use L</(?#text)> to create a comment that ends earlier than the
157 end of the current line, but C<text> also can't contain the closing
158 delimiter unless escaped with a backslash.
159
160 Taken together, these features go a long way towards
161 making Perl's regular expressions more readable.  Here's an example:
162
163     # Delete (most) C comments.
164     $program =~ s {
165         /\*     # Match the opening delimiter.
166         .*?     # Match a minimal number of characters.
167         \*/     # Match the closing delimiter.
168     } []gsx;
169
170 Note that anything inside
171 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
172 space interpretation within a single multi-character construct.  For
173 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
174 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
175 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<(>,
176 C<?>, and C<:>.  Within any delimiters for such a
177 construct, allowed spaces are not affected by C</x>, and depend on the
178 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
179 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
180 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
181 L<perluniprops/Properties accessible through \p{} and \P{}>.
182 X</x>
183
184 The set of characters that are deemed whitespace are those that Unicode
185 calls "Pattern White Space", namely:
186
187  U+0009 CHARACTER TABULATION
188  U+000A LINE FEED
189  U+000B LINE TABULATION
190  U+000C FORM FEED
191  U+000D CARRIAGE RETURN
192  U+0020 SPACE
193  U+0085 NEXT LINE
194  U+200E LEFT-TO-RIGHT MARK
195  U+200F RIGHT-TO-LEFT MARK
196  U+2028 LINE SEPARATOR
197  U+2029 PARAGRAPH SEPARATOR
198
199 =head3 Character set modifiers
200
201 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
202 the character set modifiers; they affect the character set rules
203 used for the regular expression.
204
205 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
206 to you, and so you need not worry about them very much.  They exist for
207 Perl's internal use, so that complex regular expression data structures
208 can be automatically serialized and later exactly reconstituted,
209 including all their nuances.  But, since Perl can't keep a secret, and
210 there may be rare instances where they are useful, they are documented
211 here.
212
213 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
214 allow code that is to work mostly on ASCII data to not have to concern
215 itself with Unicode.
216
217 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
218 effect at the time of the execution of the pattern match.
219
220 C</u> sets the character set to B<U>nicode.
221
222 C</a> also sets the character set to Unicode, BUT adds several
223 restrictions for B<A>SCII-safe matching.
224
225 C</d> is the old, problematic, pre-5.14 B<D>efault character set
226 behavior.  Its only use is to force that old behavior.
227
228 At any given time, exactly one of these modifiers is in effect.  Their
229 existence allows Perl to keep the originally compiled behavior of a
230 regular expression, regardless of what rules are in effect when it is
231 actually executed.  And if it is interpolated into a larger regex, the
232 original's rules continue to apply to it, and only it.
233
234 The C</l> and C</u> modifiers are automatically selected for
235 regular expressions compiled within the scope of various pragmas,
236 and we recommend that in general, you use those pragmas instead of
237 specifying these modifiers explicitly.  For one thing, the modifiers
238 affect only pattern matching, and do not extend to even any replacement
239 done, whereas using the pragmas give consistent results for all
240 appropriate operations within their scopes.  For example,
241
242  s/foo/\Ubar/il
243
244 will match "foo" using the locale's rules for case-insensitive matching,
245 but the C</l> does not affect how the C<\U> operates.  Most likely you
246 want both of them to use locale rules.  To do this, instead compile the
247 regular expression within the scope of C<use locale>.  This both
248 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
249 lesson is to C<use locale> and not C</l> explicitly.
250
251 Similarly, it would be better to use C<use feature 'unicode_strings'>
252 instead of,
253
254  s/foo/\Lbar/iu
255
256 to get Unicode rules, as the C<\L> in the former (but not necessarily
257 the latter) would also use Unicode rules.
258
259 More detail on each of the modifiers follows.  Most likely you don't
260 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
261 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
262
263 =head4 /l
264
265 means to use the current locale's rules (see L<perllocale>) when pattern
266 matching.  For example, C<\w> will match the "word" characters of that
267 locale, and C<"/i"> case-insensitive matching will match according to
268 the locale's case folding rules.  The locale used will be the one in
269 effect at the time of execution of the pattern match.  This may not be
270 the same as the compilation-time locale, and can differ from one match
271 to another if there is an intervening call of the
272 L<setlocale() function|perllocale/The setlocale function>.
273
274 The only non-single-byte locale Perl supports is (starting in v5.20)
275 UTF-8.  This means that code points above 255 are treated as Unicode no
276 matter what locale is in effect (since UTF-8 implies Unicode).
277
278 Under Unicode rules, there are a few case-insensitive matches that cross
279 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
280 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
281 platforms) does not caselessly match the character at 0x178, C<LATIN
282 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
283 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
284 knowing if that character even exists in the locale, much less what code
285 point it is.
286
287 In a UTF-8 locale in v5.20 and later, the only visible difference
288 between locale and non-locale in regular expressions should be tainting
289 (see L<perlsec>).
290
291 This modifier may be specified to be the default by C<use locale>, but
292 see L</Which character set modifier is in effect?>.
293 X</l>
294
295 =head4 /u
296
297 means to use Unicode rules when pattern matching.  On ASCII platforms,
298 this means that the code points between 128 and 255 take on their
299 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
300 (Otherwise Perl considers their meanings to be undefined.)  Thus,
301 under this modifier, the ASCII platform effectively becomes a Unicode
302 platform; and hence, for example, C<\w> will match any of the more than
303 100_000 word characters in Unicode.
304
305 Unlike most locales, which are specific to a language and country pair,
306 Unicode classifies all the characters that are letters I<somewhere> in
307 the world as
308 C<\w>.  For example, your locale might not think that C<LATIN SMALL
309 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
310 Unicode does.  Similarly, all the characters that are decimal digits
311 somewhere in the world will match C<\d>; this is hundreds, not 10,
312 possible matches.  And some of those digits look like some of the 10
313 ASCII digits, but mean a different number, so a human could easily think
314 a number is a different quantity than it really is.  For example,
315 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
316 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
317 that are a mixture from different writing systems, creating a security
318 issue.  L<Unicode::UCD/num()> can be used to sort
319 this out.  Or the C</a> modifier can be used to force C<\d> to match
320 just the ASCII 0 through 9.
321
322 Also, under this modifier, case-insensitive matching works on the full
323 set of Unicode
324 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
325 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
326 if you're not prepared, might make it look like a hexadecimal constant,
327 presenting another potential security issue.  See
328 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
329 security issues.
330
331 This modifier may be specified to be the default by C<use feature
332 'unicode_strings>, C<use locale ':not_characters'>, or
333 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
334 but see L</Which character set modifier is in effect?>.
335 X</u>
336
337 =head4 /d
338
339 This modifier means to use the "Default" native rules of the platform
340 except when there is cause to use Unicode rules instead, as follows:
341
342 =over 4
343
344 =item 1
345
346 the target string is encoded in UTF-8; or
347
348 =item 2
349
350 the pattern is encoded in UTF-8; or
351
352 =item 3
353
354 the pattern explicitly mentions a code point that is above 255 (say by
355 C<\x{100}>); or
356
357 =item 4
358
359 the pattern uses a Unicode name (C<\N{...}>);  or
360
361 =item 5
362
363 the pattern uses a Unicode property (C<\p{...}>); or
364
365 =item 6
366
367 the pattern uses L</C<(?[ ])>>
368
369 =back
370
371 Another mnemonic for this modifier is "Depends", as the rules actually
372 used depend on various things, and as a result you can get unexpected
373 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
374 become rather infamous, leading to yet another (printable) name for this
375 modifier, "Dodgy".
376
377 Unless the pattern or string are encoded in UTF-8, only ASCII characters
378 can match positively.
379
380 Here are some examples of how that works on an ASCII platform:
381
382  $str =  "\xDF";      # $str is not in UTF-8 format.
383  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
384  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
385  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
386  chop $str;
387  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
388
389 This modifier is automatically selected by default when none of the
390 others are, so yet another name for it is "Default".
391
392 Because of the unexpected behaviors associated with this modifier, you
393 probably should only use it to maintain weird backward compatibilities.
394
395 =head4 /a (and /aa)
396
397 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
398 unlike the others, may be doubled-up to increase its effect.
399
400 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
401 the Posix character classes to match only in the ASCII range.  They thus
402 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
403 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
404 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, experimentally,
405 the vertical tab; C<\w> means the 63 characters
406 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
407 C<[[:print:]]> match only the appropriate ASCII-range characters.
408
409 This modifier is useful for people who only incidentally use Unicode,
410 and who do not wish to be burdened with its complexities and security
411 concerns.
412
413 With C</a>, one can write C<\d> with confidence that it will only match
414 ASCII characters, and should the need arise to match beyond ASCII, you
415 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
416 similar C<\p{...}> constructs that can match beyond ASCII both white
417 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
418 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
419 doesn't mean you can't use Unicode, it means that to get Unicode
420 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
421 signals Unicode.
422
423 As you would expect, this modifier causes, for example, C<\D> to mean
424 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
425 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
426 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
427 for C<\B>).
428
429 Otherwise, C</a> behaves like the C</u> modifier, in that
430 case-insensitive matching uses Unicode rules; for example, "k" will
431 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
432 points in the Latin1 range, above ASCII will have Unicode rules when it
433 comes to case-insensitive matching.
434
435 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
436 specify the "a" twice, for example C</aai> or C</aia>.  (The first
437 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
438 adds the C</i> restrictions.)  But, note that code points outside the
439 ASCII range will use Unicode rules for C</i> matching, so the modifier
440 doesn't really restrict things to just ASCII; it just forbids the
441 intermixing of ASCII and non-ASCII.
442
443 To summarize, this modifier provides protection for applications that
444 don't wish to be exposed to all of Unicode.  Specifying it twice
445 gives added protection.
446
447 This modifier may be specified to be the default by C<use re '/a'>
448 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
449 the C</u> modifier explicitly if there are a few regular expressions
450 where you do want full Unicode rules (but even here, it's best if
451 everything were under feature C<"unicode_strings">, along with the
452 C<use re '/aa'>).  Also see L</Which character set modifier is in
453 effect?>.
454 X</a>
455 X</aa>
456
457 =head4 Which character set modifier is in effect?
458
459 Which of these modifiers is in effect at any given point in a regular
460 expression depends on a fairly complex set of interactions.  These have
461 been designed so that in general you don't have to worry about it, but
462 this section gives the gory details.  As
463 explained below in L</Extended Patterns> it is possible to explicitly
464 specify modifiers that apply only to portions of a regular expression.
465 The innermost always has priority over any outer ones, and one applying
466 to the whole expression has priority over any of the default settings that are
467 described in the remainder of this section.
468
469 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
470 default modifiers (including these) for regular expressions compiled
471 within its scope.  This pragma has precedence over the other pragmas
472 listed below that also change the defaults.
473
474 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
475 and C<L<use feature 'unicode_strings|feature>>, or
476 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
477 C</u> when not in the same scope as either C<L<use locale|perllocale>>
478 or C<L<use bytes|bytes>>.
479 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
480 sets the default to C</u>, overriding any plain C<use locale>.)
481 Unlike the mechanisms mentioned above, these
482 affect operations besides regular expressions pattern matching, and so
483 give more consistent results with other operators, including using
484 C<\U>, C<\l>, etc. in substitution replacements.
485
486 If none of the above apply, for backwards compatibility reasons, the
487 C</d> modifier is the one in effect by default.  As this can lead to
488 unexpected results, it is best to specify which other rule set should be
489 used.
490
491 =head4 Character set modifier behavior prior to Perl 5.14
492
493 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
494 for regexes compiled within the scope of C<use locale>, and C</d> was
495 implied otherwise.  However, interpolating a regex into a larger regex
496 would ignore the original compilation in favor of whatever was in effect
497 at the time of the second compilation.  There were a number of
498 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
499 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
500 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
501
502 =head2 Regular Expressions
503
504 =head3 Metacharacters
505
506 The patterns used in Perl pattern matching evolved from those supplied in
507 the Version 8 regex routines.  (The routines are derived
508 (distantly) from Henry Spencer's freely redistributable reimplementation
509 of the V8 routines.)  See L<Version 8 Regular Expressions> for
510 details.
511
512 In particular the following metacharacters have their standard I<egrep>-ish
513 meanings:
514 X<metacharacter>
515 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
516
517
518     \        Quote the next metacharacter
519     ^        Match the beginning of the line
520     .        Match any character (except newline)
521     $        Match the end of the string (or before newline at the end
522              of the string)
523     |        Alternation
524     ()       Grouping
525     []       Bracketed Character class
526
527 By default, the "^" character is guaranteed to match only the
528 beginning of the string, the "$" character only the end (or before the
529 newline at the end), and Perl does certain optimizations with the
530 assumption that the string contains only one line.  Embedded newlines
531 will not be matched by "^" or "$".  You may, however, wish to treat a
532 string as a multi-line buffer, such that the "^" will match after any
533 newline within the string (except if the newline is the last character in
534 the string), and "$" will match before any newline.  At the
535 cost of a little more overhead, you can do this by using the /m modifier
536 on the pattern match operator.  (Older programs did this by setting C<$*>,
537 but this option was removed in perl 5.10.)
538 X<^> X<$> X</m>
539
540 To simplify multi-line substitutions, the "." character never matches a
541 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
542 the string is a single line--even if it isn't.
543 X<.> X</s>
544
545 =head3 Quantifiers
546
547 The following standard quantifiers are recognized:
548 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
549
550     *           Match 0 or more times
551     +           Match 1 or more times
552     ?           Match 1 or 0 times
553     {n}         Match exactly n times
554     {n,}        Match at least n times
555     {n,m}       Match at least n but not more than m times
556
557 (If a curly bracket occurs in any other context and does not form part of
558 a backslashed sequence like C<\x{...}>, it is treated as a regular
559 character.  However, a deprecation warning is raised for all such
560 occurrences, and in Perl v5.26, literal uses of a curly bracket will be
561 required to be escaped, say by preceding them with a backslash (C<"\{">)
562 or enclosing them within square brackets  (C<"[{]">).  This change will
563 allow for future syntax extensions (like making the lower bound of a
564 quantifier optional), and better error checking of quantifiers.)
565
566 The "*" quantifier is equivalent to C<{0,}>, the "+"
567 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
568 to non-negative integral values less than a preset limit defined when perl is built.
569 This is usually 32766 on the most common platforms.  The actual limit can
570 be seen in the error message generated by code such as this:
571
572     $_ **= $_ , / {$_} / for 2 .. 42;
573
574 By default, a quantified subpattern is "greedy", that is, it will match as
575 many times as possible (given a particular starting location) while still
576 allowing the rest of the pattern to match.  If you want it to match the
577 minimum number of times possible, follow the quantifier with a "?".  Note
578 that the meanings don't change, just the "greediness":
579 X<metacharacter> X<greedy> X<greediness>
580 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
581
582     *?        Match 0 or more times, not greedily
583     +?        Match 1 or more times, not greedily
584     ??        Match 0 or 1 time, not greedily
585     {n}?      Match exactly n times, not greedily (redundant)
586     {n,}?     Match at least n times, not greedily
587     {n,m}?    Match at least n but not more than m times, not greedily
588
589 Normally when a quantified subpattern does not allow the rest of the
590 overall pattern to match, Perl will backtrack. However, this behaviour is
591 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
592 as well.
593
594  *+     Match 0 or more times and give nothing back
595  ++     Match 1 or more times and give nothing back
596  ?+     Match 0 or 1 time and give nothing back
597  {n}+   Match exactly n times and give nothing back (redundant)
598  {n,}+  Match at least n times and give nothing back
599  {n,m}+ Match at least n but not more than m times and give nothing back
600
601 For instance,
602
603    'aaaa' =~ /a++a/
604
605 will never match, as the C<a++> will gobble up all the C<a>'s in the
606 string and won't leave any for the remaining part of the pattern. This
607 feature can be extremely useful to give perl hints about where it
608 shouldn't backtrack. For instance, the typical "match a double-quoted
609 string" problem can be most efficiently performed when written as:
610
611    /"(?:[^"\\]++|\\.)*+"/
612
613 as we know that if the final quote does not match, backtracking will not
614 help. See the independent subexpression
615 L</C<< (?>pattern) >>> for more details;
616 possessive quantifiers are just syntactic sugar for that construct. For
617 instance the above example could also be written as follows:
618
619    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
620
621 Note that the possessive quantifier modifier can not be be combined
622 with the non-greedy modifier. This is because it would make no sense.
623 Consider the follow equivalency table:
624
625     Illegal         Legal
626     ------------    ------
627     X??+            X{0}
628     X+?+            X{1}
629     X{min,max}?+    X{min}
630
631 =head3 Escape sequences
632
633 Because patterns are processed as double-quoted strings, the following
634 also work:
635
636  \t          tab                   (HT, TAB)
637  \n          newline               (LF, NL)
638  \r          return                (CR)
639  \f          form feed             (FF)
640  \a          alarm (bell)          (BEL)
641  \e          escape (think troff)  (ESC)
642  \cK         control char          (example: VT)
643  \x{}, \x00  character whose ordinal is the given hexadecimal number
644  \N{name}    named Unicode character or character sequence
645  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
646  \o{}, \000  character whose ordinal is the given octal number
647  \l          lowercase next char (think vi)
648  \u          uppercase next char (think vi)
649  \L          lowercase till \E (think vi)
650  \U          uppercase till \E (think vi)
651  \Q          quote (disable) pattern metacharacters till \E
652  \E          end either case modification or quoted section, think vi
653
654 Details are in L<perlop/Quote and Quote-like Operators>.
655
656 =head3 Character Classes and other Special Escapes
657
658 In addition, Perl defines the following:
659 X<\g> X<\k> X<\K> X<backreference>
660
661  Sequence   Note    Description
662   [...]     [1]  Match a character according to the rules of the
663                    bracketed character class defined by the "...".
664                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
665   [[:...:]] [2]  Match a character according to the rules of the POSIX
666                    character class "..." within the outer bracketed
667                    character class.  Example: [[:upper:]] matches any
668                    uppercase character.
669   (?[...])  [8]  Extended bracketed character class
670   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
671                    other connector punctuation chars plus Unicode
672                    marks)
673   \W        [3]  Match a non-"word" character
674   \s        [3]  Match a whitespace character
675   \S        [3]  Match a non-whitespace character
676   \d        [3]  Match a decimal digit character
677   \D        [3]  Match a non-digit character
678   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
679   \PP       [3]  Match non-P
680   \X        [4]  Match Unicode "eXtended grapheme cluster"
681   \C             Match a single C-language char (octet) even if that is
682                    part of a larger UTF-8 character.  Thus it breaks up
683                    characters into their UTF-8 bytes, so you may end up
684                    with malformed pieces of UTF-8.  Unsupported in
685                    lookbehind. (Deprecated.)
686   \1        [5]  Backreference to a specific capture group or buffer.
687                    '1' may actually be any positive integer.
688   \g1       [5]  Backreference to a specific or previous group,
689   \g{-1}    [5]  The number may be negative indicating a relative
690                    previous group and may optionally be wrapped in
691                    curly brackets for safer parsing.
692   \g{name}  [5]  Named backreference
693   \k<name>  [5]  Named backreference
694   \K        [6]  Keep the stuff left of the \K, don't include it in $&
695   \N        [7]  Any character but \n.  Not affected by /s modifier
696   \v        [3]  Vertical whitespace
697   \V        [3]  Not vertical whitespace
698   \h        [3]  Horizontal whitespace
699   \H        [3]  Not horizontal whitespace
700   \R        [4]  Linebreak
701
702 =over 4
703
704 =item [1]
705
706 See L<perlrecharclass/Bracketed Character Classes> for details.
707
708 =item [2]
709
710 See L<perlrecharclass/POSIX Character Classes> for details.
711
712 =item [3]
713
714 See L<perlrecharclass/Backslash sequences> for details.
715
716 =item [4]
717
718 See L<perlrebackslash/Misc> for details.
719
720 =item [5]
721
722 See L</Capture groups> below for details.
723
724 =item [6]
725
726 See L</Extended Patterns> below for details.
727
728 =item [7]
729
730 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
731 character or character sequence whose name is C<NAME>; and similarly
732 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
733 code point is I<hex>.  Otherwise it matches any character but C<\n>.
734
735 =item [8]
736
737 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
738
739 =back
740
741 =head3 Assertions
742
743 Perl defines the following zero-width assertions:
744 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
745 X<regexp, zero-width assertion>
746 X<regular expression, zero-width assertion>
747 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
748
749     \b  Match a word boundary
750     \B  Match except at a word boundary
751     \A  Match only at beginning of string
752     \Z  Match only at end of string, or before newline at the end
753     \z  Match only at end of string
754     \G  Match only at pos() (e.g. at the end-of-match position
755         of prior m//g)
756
757 A word boundary (C<\b>) is a spot between two characters
758 that has a C<\w> on one side of it and a C<\W> on the other side
759 of it (in either order), counting the imaginary characters off the
760 beginning and end of the string as matching a C<\W>.  (Within
761 character classes C<\b> represents backspace rather than a word
762 boundary, just as it normally does in any double-quoted string.)
763 The C<\A> and C<\Z> are just like "^" and "$", except that they
764 won't match multiple times when the C</m> modifier is used, while
765 "^" and "$" will match at every internal line boundary.  To match
766 the actual end of the string and not ignore an optional trailing
767 newline, use C<\z>.
768 X<\b> X<\A> X<\Z> X<\z> X</m>
769
770 The C<\G> assertion can be used to chain global matches (using
771 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
772 It is also useful when writing C<lex>-like scanners, when you have
773 several patterns that you want to match against consequent substrings
774 of your string; see the previous reference.  The actual location
775 where C<\G> will match can also be influenced by using C<pos()> as
776 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
777 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
778 is modified somewhat, in that contents to the left of C<\G> are
779 not counted when determining the length of the match. Thus the following
780 will not match forever:
781 X<\G>
782
783      my $string = 'ABC';
784      pos($string) = 1;
785      while ($string =~ /(.\G)/g) {
786          print $1;
787      }
788
789 It will print 'A' and then terminate, as it considers the match to
790 be zero-width, and thus will not match at the same position twice in a
791 row.
792
793 It is worth noting that C<\G> improperly used can result in an infinite
794 loop. Take care when using patterns that include C<\G> in an alternation.
795
796 Note also that C<s///> will refuse to overwrite part of a substitution
797 that has already been replaced; so for example this will stop after the
798 first iteration, rather than iterating its way backwards through the
799 string:
800
801     $_ = "123456789";
802     pos = 6;
803     s/.(?=.\G)/X/g;
804     print;      # prints 1234X6789, not XXXXX6789
805
806
807 =head3 Capture groups
808
809 The bracketing construct C<( ... )> creates capture groups (also referred to as
810 capture buffers). To refer to the current contents of a group later on, within
811 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
812 for the second, and so on.
813 This is called a I<backreference>.
814 X<regex, capture buffer> X<regexp, capture buffer>
815 X<regex, capture group> X<regexp, capture group>
816 X<regular expression, capture buffer> X<backreference>
817 X<regular expression, capture group> X<backreference>
818 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
819 X<named capture buffer> X<regular expression, named capture buffer>
820 X<named capture group> X<regular expression, named capture group>
821 X<%+> X<$+{name}> X<< \k<name> >>
822 There is no limit to the number of captured substrings that you may use.
823 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
824 a group did not match, the associated backreference won't match either. (This
825 can happen if the group is optional, or in a different branch of an
826 alternation.)
827 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
828 this form, described below.
829
830 You can also refer to capture groups relatively, by using a negative number, so
831 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
832 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
833 example:
834
835         /
836          (Y)            # group 1
837          (              # group 2
838             (X)         # group 3
839             \g{-1}      # backref to group 3
840             \g{-3}      # backref to group 1
841          )
842         /x
843
844 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
845 interpolate regexes into larger regexes and not have to worry about the
846 capture groups being renumbered.
847
848 You can dispense with numbers altogether and create named capture groups.
849 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
850 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
851 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
852 I<name> must not begin with a number, nor contain hyphens.
853 When different groups within the same pattern have the same name, any reference
854 to that name assumes the leftmost defined group.  Named groups count in
855 absolute and relative numbering, and so can also be referred to by those
856 numbers.
857 (It's possible to do things with named capture groups that would otherwise
858 require C<(??{})>.)
859
860 Capture group contents are dynamically scoped and available to you outside the
861 pattern until the end of the enclosing block or until the next successful
862 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
863 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
864 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
865
866 Braces are required in referring to named capture groups, but are optional for
867 absolute or relative numbered ones.  Braces are safer when creating a regex by
868 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
869 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
870 is probably not what you intended.
871
872 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
873 there were no named nor relative numbered capture groups.  Absolute numbered
874 groups were referred to using C<\1>,
875 C<\2>, etc., and this notation is still
876 accepted (and likely always will be).  But it leads to some ambiguities if
877 there are more than 9 capture groups, as C<\10> could mean either the tenth
878 capture group, or the character whose ordinal in octal is 010 (a backspace in
879 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
880 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
881 a backreference only if at least 11 left parentheses have opened before it.
882 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
883 There are several examples below that illustrate these perils.  You can avoid
884 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
885 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
886 digits padded with leading zeros, since a leading zero implies an octal
887 constant.
888
889 The C<\I<digit>> notation also works in certain circumstances outside
890 the pattern.  See L</Warning on \1 Instead of $1> below for details.
891
892 Examples:
893
894     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
895
896     /(.)\g1/                        # find first doubled char
897          and print "'$1' is the first doubled character\n";
898
899     /(?<char>.)\k<char>/            # ... a different way
900          and print "'$+{char}' is the first doubled character\n";
901
902     /(?'char'.)\g1/                 # ... mix and match
903          and print "'$1' is the first doubled character\n";
904
905     if (/Time: (..):(..):(..)/) {   # parse out values
906         $hours = $1;
907         $minutes = $2;
908         $seconds = $3;
909     }
910
911     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
912     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
913     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
914     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
915
916     $a = '(.)\1';        # Creates problems when concatenated.
917     $b = '(.)\g{1}';     # Avoids the problems.
918     "aa" =~ /${a}/;      # True
919     "aa" =~ /${b}/;      # True
920     "aa0" =~ /${a}0/;    # False!
921     "aa0" =~ /${b}0/;    # True
922     "aa\x08" =~ /${a}0/;  # True!
923     "aa\x08" =~ /${b}0/;  # False
924
925 Several special variables also refer back to portions of the previous
926 match.  C<$+> returns whatever the last bracket match matched.
927 C<$&> returns the entire matched string.  (At one point C<$0> did
928 also, but now it returns the name of the program.)  C<$`> returns
929 everything before the matched string.  C<$'> returns everything
930 after the matched string. And C<$^N> contains whatever was matched by
931 the most-recently closed group (submatch). C<$^N> can be used in
932 extended patterns (see below), for example to assign a submatch to a
933 variable.
934 X<$+> X<$^N> X<$&> X<$`> X<$'>
935
936 These special variables, like the C<%+> hash and the numbered match variables
937 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
938 until the end of the enclosing block or until the next successful
939 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
940 X<$+> X<$^N> X<$&> X<$`> X<$'>
941 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
942
943 B<NOTE>: Failed matches in Perl do not reset the match variables,
944 which makes it easier to write code that tests for a series of more
945 specific cases and remembers the best match.
946
947 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
948 beware that once Perl sees that you need one of C<$&>, C<$`>, or
949 C<$'> anywhere in the program, it has to provide them for every
950 pattern match.  This may substantially slow your program.
951
952 Perl uses the same mechanism to produce C<$1>, C<$2>, etc, so you also
953 pay a price for each pattern that contains capturing parentheses.
954 (To avoid this cost while retaining the grouping behaviour, use the
955 extended regular expression C<(?: ... )> instead.)  But if you never
956 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
957 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
958 if you can, but if you can't (and some algorithms really appreciate
959 them), once you've used them once, use them at will, because you've
960 already paid the price.
961 X<$&> X<$`> X<$'>
962
963 Perl 5.16 introduced a slightly more efficient mechanism that notes
964 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
965 thus may only need to copy part of the string.  Perl 5.20 introduced a
966 much more efficient copy-on-write mechanism which eliminates any slowdown.
967
968 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
969 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
970 and C<$'>, B<except> that they are only guaranteed to be defined after a
971 successful match that was executed with the C</p> (preserve) modifier.
972 The use of these variables incurs no global performance penalty, unlike
973 their punctuation char equivalents, however at the trade-off that you
974 have to tell perl when you want to use them.  As of Perl 5.20, these three
975 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
976 X</p> X<p modifier>
977
978 =head2 Quoting metacharacters
979
980 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
981 C<\w>, C<\n>.  Unlike some other regular expression languages, there
982 are no backslashed symbols that aren't alphanumeric.  So anything
983 that looks like \\, \(, \), \[, \], \{, or \} is always
984 interpreted as a literal character, not a metacharacter.  This was
985 once used in a common idiom to disable or quote the special meanings
986 of regular expression metacharacters in a string that you want to
987 use for a pattern. Simply quote all non-"word" characters:
988
989     $pattern =~ s/(\W)/\\$1/g;
990
991 (If C<use locale> is set, then this depends on the current locale.)
992 Today it is more common to use the quotemeta() function or the C<\Q>
993 metaquoting escape sequence to disable all metacharacters' special
994 meanings like this:
995
996     /$unquoted\Q$quoted\E$unquoted/
997
998 Beware that if you put literal backslashes (those not inside
999 interpolated variables) between C<\Q> and C<\E>, double-quotish
1000 backslash interpolation may lead to confusing results.  If you
1001 I<need> to use literal backslashes within C<\Q...\E>,
1002 consult L<perlop/"Gory details of parsing quoted constructs">.
1003
1004 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1005
1006 =head2 Extended Patterns
1007
1008 Perl also defines a consistent extension syntax for features not
1009 found in standard tools like B<awk> and
1010 B<lex>.  The syntax for most of these is a
1011 pair of parentheses with a question mark as the first thing within
1012 the parentheses.  The character after the question mark indicates
1013 the extension.
1014
1015 The stability of these extensions varies widely.  Some have been
1016 part of the core language for many years.  Others are experimental
1017 and may change without warning or be completely removed.  Check
1018 the documentation on an individual feature to verify its current
1019 status.
1020
1021 A question mark was chosen for this and for the minimal-matching
1022 construct because 1) question marks are rare in older regular
1023 expressions, and 2) whenever you see one, you should stop and
1024 "question" exactly what is going on.  That's psychology....
1025
1026 =over 4
1027
1028 =item C<(?#text)>
1029 X<(?#)>
1030
1031 A comment.  The text is ignored.
1032 Note that Perl closes
1033 the comment as soon as it sees a C<)>, so there is no way to put a literal
1034 C<)> in the comment.  The pattern's closing delimiter must be escaped by
1035 a backslash if it appears in the comment.
1036
1037 See L</E<sol>x> for another way to have comments in patterns.
1038
1039 =item C<(?adlupimsx-imsx)>
1040
1041 =item C<(?^alupimsx)>
1042 X<(?)> X<(?^)>
1043
1044 One or more embedded pattern-match modifiers, to be turned on (or
1045 turned off, if preceded by C<->) for the remainder of the pattern or
1046 the remainder of the enclosing pattern group (if any).
1047
1048 This is particularly useful for dynamic patterns, such as those read in from a
1049 configuration file, taken from an argument, or specified in a table
1050 somewhere.  Consider the case where some patterns want to be
1051 case-sensitive and some do not:  The case-insensitive ones merely need to
1052 include C<(?i)> at the front of the pattern.  For example:
1053
1054     $pattern = "foobar";
1055     if ( /$pattern/i ) { }
1056
1057     # more flexible:
1058
1059     $pattern = "(?i)foobar";
1060     if ( /$pattern/ ) { }
1061
1062 These modifiers are restored at the end of the enclosing group. For example,
1063
1064     ( (?i) blah ) \s+ \g1
1065
1066 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1067 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1068 modifier outside this group.
1069
1070 These modifiers do not carry over into named subpatterns called in the
1071 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1072 change the case-sensitivity of the "NAME" pattern.
1073
1074 Any of these modifiers can be set to apply globally to all regular
1075 expressions compiled within the scope of a C<use re>.  See
1076 L<re/"'/flags' mode">.
1077
1078 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1079 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1080 C<"d">) may follow the caret to override it.
1081 But a minus sign is not legal with it.
1082
1083 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1084 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1085 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1086 others, and a maximum of one (or two C<a>'s) may appear in the
1087 construct.  Thus, for
1088 example, C<(?-p)> will warn when compiled under C<use warnings>;
1089 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1090
1091 Note also that the C<p> modifier is special in that its presence
1092 anywhere in a pattern has a global effect.
1093
1094 =item C<(?:pattern)>
1095 X<(?:)>
1096
1097 =item C<(?adluimsx-imsx:pattern)>
1098
1099 =item C<(?^aluimsx:pattern)>
1100 X<(?^:)>
1101
1102 This is for clustering, not capturing; it groups subexpressions like
1103 "()", but doesn't make backreferences as "()" does.  So
1104
1105     @fields = split(/\b(?:a|b|c)\b/)
1106
1107 is like
1108
1109     @fields = split(/\b(a|b|c)\b/)
1110
1111 but doesn't spit out extra fields.  It's also cheaper not to capture
1112 characters if you don't need to.
1113
1114 Any letters between C<?> and C<:> act as flags modifiers as with
1115 C<(?adluimsx-imsx)>.  For example,
1116
1117     /(?s-i:more.*than).*million/i
1118
1119 is equivalent to the more verbose
1120
1121     /(?:(?s-i)more.*than).*million/i
1122
1123 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1124 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1125 flags (except C<"d">) may follow the caret, so
1126
1127     (?^x:foo)
1128
1129 is equivalent to
1130
1131     (?x-ims:foo)
1132
1133 The caret tells Perl that this cluster doesn't inherit the flags of any
1134 surrounding pattern, but uses the system defaults (C<d-imsx>),
1135 modified by any flags specified.
1136
1137 The caret allows for simpler stringification of compiled regular
1138 expressions.  These look like
1139
1140     (?^:pattern)
1141
1142 with any non-default flags appearing between the caret and the colon.
1143 A test that looks at such stringification thus doesn't need to have the
1144 system default flags hard-coded in it, just the caret.  If new flags are
1145 added to Perl, the meaning of the caret's expansion will change to include
1146 the default for those flags, so the test will still work, unchanged.
1147
1148 Specifying a negative flag after the caret is an error, as the flag is
1149 redundant.
1150
1151 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1152 to match at the beginning.
1153
1154 =item C<(?|pattern)>
1155 X<(?|)> X<Branch reset>
1156
1157 This is the "branch reset" pattern, which has the special property
1158 that the capture groups are numbered from the same starting point
1159 in each alternation branch. It is available starting from perl 5.10.0.
1160
1161 Capture groups are numbered from left to right, but inside this
1162 construct the numbering is restarted for each branch.
1163
1164 The numbering within each branch will be as normal, and any groups
1165 following this construct will be numbered as though the construct
1166 contained only one branch, that being the one with the most capture
1167 groups in it.
1168
1169 This construct is useful when you want to capture one of a
1170 number of alternative matches.
1171
1172 Consider the following pattern.  The numbers underneath show in
1173 which group the captured content will be stored.
1174
1175
1176     # before  ---------------branch-reset----------- after        
1177     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1178     # 1            2         2  3        2     3     4  
1179
1180 Be careful when using the branch reset pattern in combination with 
1181 named captures. Named captures are implemented as being aliases to 
1182 numbered groups holding the captures, and that interferes with the
1183 implementation of the branch reset pattern. If you are using named
1184 captures in a branch reset pattern, it's best to use the same names,
1185 in the same order, in each of the alternations:
1186
1187    /(?|  (?<a> x ) (?<b> y )
1188       |  (?<a> z ) (?<b> w )) /x
1189
1190 Not doing so may lead to surprises:
1191
1192   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1193   say $+ {a};   # Prints '12'
1194   say $+ {b};   # *Also* prints '12'.
1195
1196 The problem here is that both the group named C<< a >> and the group
1197 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1198
1199 =item Look-Around Assertions
1200 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1201
1202 Look-around assertions are zero-width patterns which match a specific
1203 pattern without including it in C<$&>. Positive assertions match when
1204 their subpattern matches, negative assertions match when their subpattern
1205 fails. Look-behind matches text up to the current match position,
1206 look-ahead matches text following the current match position.
1207
1208 =over 4
1209
1210 =item C<(?=pattern)>
1211 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1212
1213 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1214 matches a word followed by a tab, without including the tab in C<$&>.
1215
1216 =item C<(?!pattern)>
1217 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1218
1219 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1220 matches any occurrence of "foo" that isn't followed by "bar".  Note
1221 however that look-ahead and look-behind are NOT the same thing.  You cannot
1222 use this for look-behind.
1223
1224 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1225 will not do what you want.  That's because the C<(?!foo)> is just saying that
1226 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1227 match.  Use look-behind instead (see below).
1228
1229 =item C<(?<=pattern)> C<\K>
1230 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1231
1232 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1233 matches a word that follows a tab, without including the tab in C<$&>.
1234 Works only for fixed-width look-behind.
1235
1236 There is a special form of this construct, called C<\K>, which causes the
1237 regex engine to "keep" everything it had matched prior to the C<\K> and
1238 not include it in C<$&>. This effectively provides variable-length
1239 look-behind. The use of C<\K> inside of another look-around assertion
1240 is allowed, but the behaviour is currently not well defined.
1241
1242 For various reasons C<\K> may be significantly more efficient than the
1243 equivalent C<< (?<=...) >> construct, and it is especially useful in
1244 situations where you want to efficiently remove something following
1245 something else in a string. For instance
1246
1247   s/(foo)bar/$1/g;
1248
1249 can be rewritten as the much more efficient
1250
1251   s/foo\Kbar//g;
1252
1253 =item C<(?<!pattern)>
1254 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1255
1256 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1257 matches any occurrence of "foo" that does not follow "bar".  Works
1258 only for fixed-width look-behind.
1259
1260 =back
1261
1262 =item C<(?'NAME'pattern)>
1263
1264 =item C<< (?<NAME>pattern) >>
1265 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1266
1267 A named capture group. Identical in every respect to normal capturing
1268 parentheses C<()> but for the additional fact that the group
1269 can be referred to by name in various regular expression
1270 constructs (like C<\g{NAME}>) and can be accessed by name
1271 after a successful match via C<%+> or C<%->. See L<perlvar>
1272 for more details on the C<%+> and C<%-> hashes.
1273
1274 If multiple distinct capture groups have the same name then the
1275 $+{NAME} will refer to the leftmost defined group in the match.
1276
1277 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1278
1279 B<NOTE:> While the notation of this construct is the same as the similar
1280 function in .NET regexes, the behavior is not. In Perl the groups are
1281 numbered sequentially regardless of being named or not. Thus in the
1282 pattern
1283
1284   /(x)(?<foo>y)(z)/
1285
1286 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1287 the opposite which is what a .NET regex hacker might expect.
1288
1289 Currently NAME is restricted to simple identifiers only.
1290 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1291 its Unicode extension (see L<utf8>),
1292 though it isn't extended by the locale (see L<perllocale>).
1293
1294 B<NOTE:> In order to make things easier for programmers with experience
1295 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1296 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1297 support the use of single quotes as a delimiter for the name.
1298
1299 =item C<< \k<NAME> >>
1300
1301 =item C<< \k'NAME' >>
1302
1303 Named backreference. Similar to numeric backreferences, except that
1304 the group is designated by name and not number. If multiple groups
1305 have the same name then it refers to the leftmost defined group in
1306 the current match.
1307
1308 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1309 earlier in the pattern.
1310
1311 Both forms are equivalent.
1312
1313 B<NOTE:> In order to make things easier for programmers with experience
1314 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1315 may be used instead of C<< \k<NAME> >>.
1316
1317 =item C<(?{ code })>
1318 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1319
1320 B<WARNING>: Using this feature safely requires that you understand its
1321 limitations.  Code executed that has side effects may not perform identically
1322 from version to version due to the effect of future optimisations in the regex
1323 engine.  For more information on this, see L</Embedded Code Execution
1324 Frequency>.
1325
1326 This zero-width assertion executes any embedded Perl code.  It always
1327 succeeds, and its return value is set as C<$^R>.
1328
1329 In literal patterns, the code is parsed at the same time as the
1330 surrounding code. While within the pattern, control is passed temporarily
1331 back to the perl parser, until the logically-balancing closing brace is
1332 encountered. This is similar to the way that an array index expression in
1333 a literal string is handled, for example
1334
1335     "abc$array[ 1 + f('[') + g()]def"
1336
1337 In particular, braces do not need to be balanced:
1338
1339     s/abc(?{ f('{'); })/def/
1340
1341 Even in a pattern that is interpolated and compiled at run-time, literal
1342 code blocks will be compiled once, at perl compile time; the following
1343 prints "ABCD":
1344
1345     print "D";
1346     my $qr = qr/(?{ BEGIN { print "A" } })/;
1347     my $foo = "foo";
1348     /$foo$qr(?{ BEGIN { print "B" } })/;
1349     BEGIN { print "C" }
1350
1351 In patterns where the text of the code is derived from run-time
1352 information rather than appearing literally in a source code /pattern/,
1353 the code is compiled at the same time that the pattern is compiled, and
1354 for reasons of security, C<use re 'eval'> must be in scope. This is to
1355 stop user-supplied patterns containing code snippets from being
1356 executable.
1357
1358 In situations where you need to enable this with C<use re 'eval'>, you should
1359 also have taint checking enabled.  Better yet, use the carefully
1360 constrained evaluation within a Safe compartment.  See L<perlsec> for
1361 details about both these mechanisms.
1362
1363 From the viewpoint of parsing, lexical variable scope and closures,
1364
1365     /AAA(?{ BBB })CCC/
1366
1367 behaves approximately like
1368
1369     /AAA/ && do { BBB } && /CCC/
1370
1371 Similarly,
1372
1373     qr/AAA(?{ BBB })CCC/
1374
1375 behaves approximately like
1376
1377     sub { /AAA/ && do { BBB } && /CCC/ }
1378
1379 In particular:
1380
1381     { my $i = 1; $r = qr/(?{ print $i })/ }
1382     my $i = 2;
1383     /$r/; # prints "1"
1384
1385 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1386 expression is matching against. You can also use C<pos()> to know what is
1387 the current position of matching within this string.
1388
1389 The code block introduces a new scope from the perspective of lexical
1390 variable declarations, but B<not> from the perspective of C<local> and
1391 similar localizing behaviours. So later code blocks within the same
1392 pattern will still see the values which were localized in earlier blocks.
1393 These accumulated localizations are undone either at the end of a
1394 successful match, or if the assertion is backtracked (compare
1395 L<"Backtracking">). For example,
1396
1397   $_ = 'a' x 8;
1398   m<
1399      (?{ $cnt = 0 })               # Initialize $cnt.
1400      (
1401        a
1402        (?{
1403            local $cnt = $cnt + 1;  # Update $cnt,
1404                                    # backtracking-safe.
1405        })
1406      )*
1407      aaaa
1408      (?{ $res = $cnt })            # On success copy to
1409                                    # non-localized location.
1410    >x;
1411
1412 will initially increment C<$cnt> up to 8; then during backtracking, its
1413 value will be unwound back to 4, which is the value assigned to C<$res>.
1414 At the end of the regex execution, $cnt will be wound back to its initial
1415 value of 0.
1416
1417 This assertion may be used as the condition in a
1418
1419     (?(condition)yes-pattern|no-pattern)
1420
1421 switch.  If I<not> used in this way, the result of evaluation of C<code>
1422 is put into the special variable C<$^R>.  This happens immediately, so
1423 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1424 regular expression.
1425
1426 The assignment to C<$^R> above is properly localized, so the old
1427 value of C<$^R> is restored if the assertion is backtracked; compare
1428 L<"Backtracking">.
1429
1430 Note that the special variable C<$^N>  is particularly useful with code
1431 blocks to capture the results of submatches in variables without having to
1432 keep track of the number of nested parentheses. For example:
1433
1434   $_ = "The brown fox jumps over the lazy dog";
1435   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1436   print "color = $color, animal = $animal\n";
1437
1438
1439 =item C<(??{ code })>
1440 X<(??{})>
1441 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1442
1443 B<WARNING>: Using this feature safely requires that you understand its
1444 limitations.  Code executed that has side effects may not perform
1445 identically from version to version due to the effect of future
1446 optimisations in the regex engine.  For more information on this, see
1447 L</Embedded Code Execution Frequency>.
1448
1449 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1450 same way as a C<(?{ code })> code block as described above, except that
1451 its return value, rather than being assigned to C<$^R>, is treated as a
1452 pattern, compiled if it's a string (or used as-is if its a qr// object),
1453 then matched as if it were inserted instead of this construct.
1454
1455 During the matching of this sub-pattern, it has its own set of
1456 captures which are valid during the sub-match, but are discarded once
1457 control returns to the main pattern. For example, the following matches,
1458 with the inner pattern capturing "B" and matching "BB", while the outer
1459 pattern captures "A";
1460
1461     my $inner = '(.)\1';
1462     "ABBA" =~ /^(.)(??{ $inner })\1/;
1463     print $1; # prints "A";
1464
1465 Note that this means that  there is no way for the inner pattern to refer
1466 to a capture group defined outside.  (The code block itself can use C<$1>,
1467 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1468
1469     ('a' x 100)=~/(??{'(.)' x 100})/
1470
1471 I<will> match, it will I<not> set $1 on exit.
1472
1473 The following pattern matches a parenthesized group:
1474
1475  $re = qr{
1476             \(
1477             (?:
1478                (?> [^()]+ )  # Non-parens without backtracking
1479              |
1480                (??{ $re })   # Group with matching parens
1481             )*
1482             \)
1483          }x;
1484
1485 See also
1486 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1487 for a different, more efficient way to accomplish
1488 the same task.
1489
1490 Executing a postponed regular expression 50 times without consuming any
1491 input string will result in a fatal error.  The maximum depth is compiled
1492 into perl, so changing it requires a custom build.
1493
1494 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1495 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1496 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1497 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1498
1499 Recursive subpattern. Treat the contents of a given capture buffer in the
1500 current pattern as an independent subpattern and attempt to match it at
1501 the current position in the string. Information about capture state from
1502 the caller for things like backreferences is available to the subpattern,
1503 but capture buffers set by the subpattern are not visible to the caller.
1504
1505 Similar to C<(??{ code })> except that it does not involve executing any
1506 code or potentially compiling a returned pattern string; instead it treats
1507 the part of the current pattern contained within a specified capture group
1508 as an independent pattern that must match at the current position. Also
1509 different is the treatment of capture buffers, unlike C<(??{ code })>
1510 recursive patterns have access to their callers match state, so one can
1511 use backreferences safely.
1512
1513 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1514 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1515 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1516 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1517 to be relative, with negative numbers indicating preceding capture groups
1518 and positive ones following. Thus C<(?-1)> refers to the most recently
1519 declared group, and C<(?+1)> indicates the next group to be declared.
1520 Note that the counting for relative recursion differs from that of
1521 relative backreferences, in that with recursion unclosed groups B<are>
1522 included.
1523
1524 The following pattern matches a function foo() which may contain
1525 balanced parentheses as the argument.
1526
1527   $re = qr{ (                   # paren group 1 (full function)
1528               foo
1529               (                 # paren group 2 (parens)
1530                 \(
1531                   (             # paren group 3 (contents of parens)
1532                   (?:
1533                    (?> [^()]+ ) # Non-parens without backtracking
1534                   |
1535                    (?2)         # Recurse to start of paren group 2
1536                   )*
1537                   )
1538                 \)
1539               )
1540             )
1541           }x;
1542
1543 If the pattern was used as follows
1544
1545     'foo(bar(baz)+baz(bop))'=~/$re/
1546         and print "\$1 = $1\n",
1547                   "\$2 = $2\n",
1548                   "\$3 = $3\n";
1549
1550 the output produced should be the following:
1551
1552     $1 = foo(bar(baz)+baz(bop))
1553     $2 = (bar(baz)+baz(bop))
1554     $3 = bar(baz)+baz(bop)
1555
1556 If there is no corresponding capture group defined, then it is a
1557 fatal error.  Recursing deeper than 50 times without consuming any input
1558 string will also result in a fatal error.  The maximum depth is compiled
1559 into perl, so changing it requires a custom build.
1560
1561 The following shows how using negative indexing can make it
1562 easier to embed recursive patterns inside of a C<qr//> construct
1563 for later use:
1564
1565     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1566     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1567        # do something here...
1568     }
1569
1570 B<Note> that this pattern does not behave the same way as the equivalent
1571 PCRE or Python construct of the same form. In Perl you can backtrack into
1572 a recursed group, in PCRE and Python the recursed into group is treated
1573 as atomic. Also, modifiers are resolved at compile time, so constructs
1574 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1575 be processed.
1576
1577 =item C<(?&NAME)>
1578 X<(?&NAME)>
1579
1580 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1581 parenthesis to recurse to is determined by name. If multiple parentheses have
1582 the same name, then it recurses to the leftmost.
1583
1584 It is an error to refer to a name that is not declared somewhere in the
1585 pattern.
1586
1587 B<NOTE:> In order to make things easier for programmers with experience
1588 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1589 may be used instead of C<< (?&NAME) >>.
1590
1591 =item C<(?(condition)yes-pattern|no-pattern)>
1592 X<(?()>
1593
1594 =item C<(?(condition)yes-pattern)>
1595
1596 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1597 a true value, matches C<no-pattern> otherwise. A missing pattern always
1598 matches.
1599
1600 C<(condition)> should be one of: 1) an integer in
1601 parentheses (which is valid if the corresponding pair of parentheses
1602 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1603 name in angle brackets or single quotes (which is valid if a group
1604 with the given name matched); or 4) the special symbol (R) (true when
1605 evaluated inside of recursion or eval). Additionally the R may be
1606 followed by a number, (which will be true when evaluated when recursing
1607 inside of the appropriate group), or by C<&NAME>, in which case it will
1608 be true only when evaluated during recursion in the named group.
1609
1610 Here's a summary of the possible predicates:
1611
1612 =over 4
1613
1614 =item (1) (2) ...
1615
1616 Checks if the numbered capturing group has matched something.
1617
1618 =item (<NAME>) ('NAME')
1619
1620 Checks if a group with the given name has matched something.
1621
1622 =item (?=...) (?!...) (?<=...) (?<!...)
1623
1624 Checks whether the pattern matches (or does not match, for the '!'
1625 variants).
1626
1627 =item (?{ CODE })
1628
1629 Treats the return value of the code block as the condition.
1630
1631 =item (R)
1632
1633 Checks if the expression has been evaluated inside of recursion.
1634
1635 =item (R1) (R2) ...
1636
1637 Checks if the expression has been evaluated while executing directly
1638 inside of the n-th capture group. This check is the regex equivalent of
1639
1640   if ((caller(0))[3] eq 'subname') { ... }
1641
1642 In other words, it does not check the full recursion stack.
1643
1644 =item (R&NAME)
1645
1646 Similar to C<(R1)>, this predicate checks to see if we're executing
1647 directly inside of the leftmost group with a given name (this is the same
1648 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1649 stack, but only the name of the innermost active recursion.
1650
1651 =item (DEFINE)
1652
1653 In this case, the yes-pattern is never directly executed, and no
1654 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1655 See below for details.
1656
1657 =back
1658
1659 For example:
1660
1661     m{ ( \( )?
1662        [^()]+
1663        (?(1) \) )
1664      }x
1665
1666 matches a chunk of non-parentheses, possibly included in parentheses
1667 themselves.
1668
1669 A special form is the C<(DEFINE)> predicate, which never executes its
1670 yes-pattern directly, and does not allow a no-pattern. This allows one to
1671 define subpatterns which will be executed only by the recursion mechanism.
1672 This way, you can define a set of regular expression rules that can be
1673 bundled into any pattern you choose.
1674
1675 It is recommended that for this usage you put the DEFINE block at the
1676 end of the pattern, and that you name any subpatterns defined within it.
1677
1678 Also, it's worth noting that patterns defined this way probably will
1679 not be as efficient, as the optimizer is not very clever about
1680 handling them.
1681
1682 An example of how this might be used is as follows:
1683
1684   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1685    (?(DEFINE)
1686      (?<NAME_PAT>....)
1687      (?<ADDRESS_PAT>....)
1688    )/x
1689
1690 Note that capture groups matched inside of recursion are not accessible
1691 after the recursion returns, so the extra layer of capturing groups is
1692 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1693 C<$+{NAME}> would be.
1694
1695 Finally, keep in mind that subpatterns created inside a DEFINE block
1696 count towards the absolute and relative number of captures, so this:
1697
1698     my @captures = "a" =~ /(.)                  # First capture
1699                            (?(DEFINE)
1700                                (?<EXAMPLE> 1 )  # Second capture
1701                            )/x;
1702     say scalar @captures;
1703
1704 Will output 2, not 1. This is particularly important if you intend to
1705 compile the definitions with the C<qr//> operator, and later
1706 interpolate them in another pattern.
1707
1708 =item C<< (?>pattern) >>
1709 X<backtrack> X<backtracking> X<atomic> X<possessive>
1710
1711 An "independent" subexpression, one which matches the substring
1712 that a I<standalone> C<pattern> would match if anchored at the given
1713 position, and it matches I<nothing other than this substring>.  This
1714 construct is useful for optimizations of what would otherwise be
1715 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1716 It may also be useful in places where the "grab all you can, and do not
1717 give anything back" semantic is desirable.
1718
1719 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1720 (anchored at the beginning of string, as above) will match I<all>
1721 characters C<a> at the beginning of string, leaving no C<a> for
1722 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1723 since the match of the subgroup C<a*> is influenced by the following
1724 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1725 C<a*ab> will match fewer characters than a standalone C<a*>, since
1726 this makes the tail match.
1727
1728 C<< (?>pattern) >> does not disable backtracking altogether once it has
1729 matched. It is still possible to backtrack past the construct, but not
1730 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1731
1732 An effect similar to C<< (?>pattern) >> may be achieved by writing
1733 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1734 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1735 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1736 (The difference between these two constructs is that the second one
1737 uses a capturing group, thus shifting ordinals of backreferences
1738 in the rest of a regular expression.)
1739
1740 Consider this pattern:
1741
1742     m{ \(
1743           (
1744             [^()]+           # x+
1745           |
1746             \( [^()]* \)
1747           )+
1748        \)
1749      }x
1750
1751 That will efficiently match a nonempty group with matching parentheses
1752 two levels deep or less.  However, if there is no such group, it
1753 will take virtually forever on a long string.  That's because there
1754 are so many different ways to split a long string into several
1755 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1756 to a subpattern of the above pattern.  Consider how the pattern
1757 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1758 seconds, but that each extra letter doubles this time.  This
1759 exponential performance will make it appear that your program has
1760 hung.  However, a tiny change to this pattern
1761
1762     m{ \(
1763           (
1764             (?> [^()]+ )        # change x+ above to (?> x+ )
1765           |
1766             \( [^()]* \)
1767           )+
1768        \)
1769      }x
1770
1771 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1772 this yourself would be a productive exercise), but finishes in a fourth
1773 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1774 however, that, when this construct is followed by a
1775 quantifier, it currently triggers a warning message under
1776 the C<use warnings> pragma or B<-w> switch saying it
1777 C<"matches null string many times in regex">.
1778
1779 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1780 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1781 This was only 4 times slower on a string with 1000000 C<a>s.
1782
1783 The "grab all you can, and do not give anything back" semantic is desirable
1784 in many situations where on the first sight a simple C<()*> looks like
1785 the correct solution.  Suppose we parse text with comments being delimited
1786 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1787 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1788 the comment delimiter, because it may "give up" some whitespace if
1789 the remainder of the pattern can be made to match that way.  The correct
1790 answer is either one of these:
1791
1792     (?>#[ \t]*)
1793     #[ \t]*(?![ \t])
1794
1795 For example, to grab non-empty comments into $1, one should use either
1796 one of these:
1797
1798     / (?> \# [ \t]* ) (        .+ ) /x;
1799     /     \# [ \t]*   ( [^ \t] .* ) /x;
1800
1801 Which one you pick depends on which of these expressions better reflects
1802 the above specification of comments.
1803
1804 In some literature this construct is called "atomic matching" or
1805 "possessive matching".
1806
1807 Possessive quantifiers are equivalent to putting the item they are applied
1808 to inside of one of these constructs. The following equivalences apply:
1809
1810     Quantifier Form     Bracketing Form
1811     ---------------     ---------------
1812     PAT*+               (?>PAT*)
1813     PAT++               (?>PAT+)
1814     PAT?+               (?>PAT?)
1815     PAT{min,max}+       (?>PAT{min,max})
1816
1817 =item C<(?[ ])>
1818
1819 See L<perlrecharclass/Extended Bracketed Character Classes>.
1820
1821 =back
1822
1823 =head2 Special Backtracking Control Verbs
1824
1825 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1826 otherwise stated the ARG argument is optional; in some cases, it is
1827 forbidden.
1828
1829 Any pattern containing a special backtracking verb that allows an argument
1830 has the special behaviour that when executed it sets the current package's
1831 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1832 rules apply:
1833
1834 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1835 verb pattern, if the verb was involved in the failure of the match. If the
1836 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1837 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1838 none. Also, the C<$REGMARK> variable will be set to FALSE.
1839
1840 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1841 the C<$REGMARK> variable will be set to the name of the last
1842 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1843 C<(*MARK:NAME)> verb below for more details.
1844
1845 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1846 and most other regex-related variables. They are not local to a scope, nor
1847 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1848 Use C<local> to localize changes to them to a specific scope if necessary.
1849
1850 If a pattern does not contain a special backtracking verb that allows an
1851 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1852
1853 =over 3
1854
1855 =item Verbs that take an argument
1856
1857 =over 4
1858
1859 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1860 X<(*PRUNE)> X<(*PRUNE:NAME)>
1861
1862 This zero-width pattern prunes the backtracking tree at the current point
1863 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1864 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1865 A may backtrack as necessary to match. Once it is reached, matching
1866 continues in B, which may also backtrack as necessary; however, should B
1867 not match, then no further backtracking will take place, and the pattern
1868 will fail outright at the current starting position.
1869
1870 The following example counts all the possible matching strings in a
1871 pattern (without actually matching any of them).
1872
1873     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1874     print "Count=$count\n";
1875
1876 which produces:
1877
1878     aaab
1879     aaa
1880     aa
1881     a
1882     aab
1883     aa
1884     a
1885     ab
1886     a
1887     Count=9
1888
1889 If we add a C<(*PRUNE)> before the count like the following
1890
1891     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1892     print "Count=$count\n";
1893
1894 we prevent backtracking and find the count of the longest matching string
1895 at each matching starting point like so:
1896
1897     aaab
1898     aab
1899     ab
1900     Count=3
1901
1902 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1903
1904 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1905 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1906 replaced with a C<< (?>pattern) >> with no functional difference; however,
1907 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1908 C<< (?>pattern) >> alone.
1909
1910 =item C<(*SKIP)> C<(*SKIP:NAME)>
1911 X<(*SKIP)>
1912
1913 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1914 failure it also signifies that whatever text that was matched leading up
1915 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1916 of this pattern. This effectively means that the regex engine "skips" forward
1917 to this position on failure and tries to match again, (assuming that
1918 there is sufficient room to match).
1919
1920 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1921 C<(*MARK:NAME)> was encountered while matching, then it is that position
1922 which is used as the "skip point". If no C<(*MARK)> of that name was
1923 encountered, then the C<(*SKIP)> operator has no effect. When used
1924 without a name the "skip point" is where the match point was when
1925 executing the (*SKIP) pattern.
1926
1927 Compare the following to the examples in C<(*PRUNE)>; note the string
1928 is twice as long:
1929
1930  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1931  print "Count=$count\n";
1932
1933 outputs
1934
1935     aaab
1936     aaab
1937     Count=2
1938
1939 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1940 executed, the next starting point will be where the cursor was when the
1941 C<(*SKIP)> was executed.
1942
1943 =item C<(*MARK:NAME)> C<(*:NAME)>
1944 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1945
1946 This zero-width pattern can be used to mark the point reached in a string
1947 when a certain part of the pattern has been successfully matched. This
1948 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1949 forward to that point if backtracked into on failure. Any number of
1950 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1951
1952 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1953 can be used to "label" a pattern branch, so that after matching, the
1954 program can determine which branches of the pattern were involved in the
1955 match.
1956
1957 When a match is successful, the C<$REGMARK> variable will be set to the
1958 name of the most recently executed C<(*MARK:NAME)> that was involved
1959 in the match.
1960
1961 This can be used to determine which branch of a pattern was matched
1962 without using a separate capture group for each branch, which in turn
1963 can result in a performance improvement, as perl cannot optimize
1964 C</(?:(x)|(y)|(z))/> as efficiently as something like
1965 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1966
1967 When a match has failed, and unless another verb has been involved in
1968 failing the match and has provided its own name to use, the C<$REGERROR>
1969 variable will be set to the name of the most recently executed
1970 C<(*MARK:NAME)>.
1971
1972 See L</(*SKIP)> for more details.
1973
1974 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1975
1976 =item C<(*THEN)> C<(*THEN:NAME)>
1977
1978 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1979 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1980 failure, it causes the regex engine to try the next alternation in the
1981 innermost enclosing group (capturing or otherwise) that has alternations.
1982 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1983 count as an alternation, as far as C<(*THEN)> is concerned.
1984
1985 Its name comes from the observation that this operation combined with the
1986 alternation operator (C<|>) can be used to create what is essentially a
1987 pattern-based if/then/else block:
1988
1989   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1990
1991 Note that if this operator is used and NOT inside of an alternation then
1992 it acts exactly like the C<(*PRUNE)> operator.
1993
1994   / A (*PRUNE) B /
1995
1996 is the same as
1997
1998   / A (*THEN) B /
1999
2000 but
2001
2002   / ( A (*THEN) B | C ) /
2003
2004 is not the same as
2005
2006   / ( A (*PRUNE) B | C ) /
2007
2008 as after matching the A but failing on the B the C<(*THEN)> verb will
2009 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
2010
2011 =back
2012
2013 =item Verbs without an argument
2014
2015 =over 4
2016
2017 =item C<(*COMMIT)>
2018 X<(*COMMIT)>
2019
2020 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2021 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2022 into on failure it causes the match to fail outright. No further attempts
2023 to find a valid match by advancing the start pointer will occur again.
2024 For example,
2025
2026  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2027  print "Count=$count\n";
2028
2029 outputs
2030
2031     aaab
2032     Count=1
2033
2034 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2035 does not match, the regex engine will not try any further matching on the
2036 rest of the string.
2037
2038 =item C<(*FAIL)> C<(*F)>
2039 X<(*FAIL)> X<(*F)>
2040
2041 This pattern matches nothing and always fails. It can be used to force the
2042 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2043 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
2044
2045 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2046
2047 =item C<(*ACCEPT)>
2048 X<(*ACCEPT)>
2049
2050 This pattern matches nothing and causes the end of successful matching at
2051 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2052 whether there is actually more to match in the string. When inside of a
2053 nested pattern, such as recursion, or in a subpattern dynamically generated
2054 via C<(??{})>, only the innermost pattern is ended immediately.
2055
2056 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2057 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2058 For instance:
2059
2060   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2061
2062 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
2063 be set. If another branch in the inner parentheses was matched, such as in the
2064 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
2065
2066 =back
2067
2068 =back
2069
2070 =head2 Backtracking
2071 X<backtrack> X<backtracking>
2072
2073 NOTE: This section presents an abstract approximation of regular
2074 expression behavior.  For a more rigorous (and complicated) view of
2075 the rules involved in selecting a match among possible alternatives,
2076 see L<Combining RE Pieces>.
2077
2078 A fundamental feature of regular expression matching involves the
2079 notion called I<backtracking>, which is currently used (when needed)
2080 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2081 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2082 internally, but the general principle outlined here is valid.
2083
2084 For a regular expression to match, the I<entire> regular expression must
2085 match, not just part of it.  So if the beginning of a pattern containing a
2086 quantifier succeeds in a way that causes later parts in the pattern to
2087 fail, the matching engine backs up and recalculates the beginning
2088 part--that's why it's called backtracking.
2089
2090 Here is an example of backtracking:  Let's say you want to find the
2091 word following "foo" in the string "Food is on the foo table.":
2092
2093     $_ = "Food is on the foo table.";
2094     if ( /\b(foo)\s+(\w+)/i ) {
2095         print "$2 follows $1.\n";
2096     }
2097
2098 When the match runs, the first part of the regular expression (C<\b(foo)>)
2099 finds a possible match right at the beginning of the string, and loads up
2100 $1 with "Foo".  However, as soon as the matching engine sees that there's
2101 no whitespace following the "Foo" that it had saved in $1, it realizes its
2102 mistake and starts over again one character after where it had the
2103 tentative match.  This time it goes all the way until the next occurrence
2104 of "foo". The complete regular expression matches this time, and you get
2105 the expected output of "table follows foo."
2106
2107 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2108 everything between "foo" and "bar".  Initially, you write something
2109 like this:
2110
2111     $_ =  "The food is under the bar in the barn.";
2112     if ( /foo(.*)bar/ ) {
2113         print "got <$1>\n";
2114     }
2115
2116 Which perhaps unexpectedly yields:
2117
2118   got <d is under the bar in the >
2119
2120 That's because C<.*> was greedy, so you get everything between the
2121 I<first> "foo" and the I<last> "bar".  Here it's more effective
2122 to use minimal matching to make sure you get the text between a "foo"
2123 and the first "bar" thereafter.
2124
2125     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2126   got <d is under the >
2127
2128 Here's another example. Let's say you'd like to match a number at the end
2129 of a string, and you also want to keep the preceding part of the match.
2130 So you write this:
2131
2132     $_ = "I have 2 numbers: 53147";
2133     if ( /(.*)(\d*)/ ) {                                # Wrong!
2134         print "Beginning is <$1>, number is <$2>.\n";
2135     }
2136
2137 That won't work at all, because C<.*> was greedy and gobbled up the
2138 whole string. As C<\d*> can match on an empty string the complete
2139 regular expression matched successfully.
2140
2141     Beginning is <I have 2 numbers: 53147>, number is <>.
2142
2143 Here are some variants, most of which don't work:
2144
2145     $_ = "I have 2 numbers: 53147";
2146     @pats = qw{
2147         (.*)(\d*)
2148         (.*)(\d+)
2149         (.*?)(\d*)
2150         (.*?)(\d+)
2151         (.*)(\d+)$
2152         (.*?)(\d+)$
2153         (.*)\b(\d+)$
2154         (.*\D)(\d+)$
2155     };
2156
2157     for $pat (@pats) {
2158         printf "%-12s ", $pat;
2159         if ( /$pat/ ) {
2160             print "<$1> <$2>\n";
2161         } else {
2162             print "FAIL\n";
2163         }
2164     }
2165
2166 That will print out:
2167
2168     (.*)(\d*)    <I have 2 numbers: 53147> <>
2169     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2170     (.*?)(\d*)   <> <>
2171     (.*?)(\d+)   <I have > <2>
2172     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2173     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2174     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2175     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2176
2177 As you see, this can be a bit tricky.  It's important to realize that a
2178 regular expression is merely a set of assertions that gives a definition
2179 of success.  There may be 0, 1, or several different ways that the
2180 definition might succeed against a particular string.  And if there are
2181 multiple ways it might succeed, you need to understand backtracking to
2182 know which variety of success you will achieve.
2183
2184 When using look-ahead assertions and negations, this can all get even
2185 trickier.  Imagine you'd like to find a sequence of non-digits not
2186 followed by "123".  You might try to write that as
2187
2188     $_ = "ABC123";
2189     if ( /^\D*(?!123)/ ) {                # Wrong!
2190         print "Yup, no 123 in $_\n";
2191     }
2192
2193 But that isn't going to match; at least, not the way you're hoping.  It
2194 claims that there is no 123 in the string.  Here's a clearer picture of
2195 why that pattern matches, contrary to popular expectations:
2196
2197     $x = 'ABC123';
2198     $y = 'ABC445';
2199
2200     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2201     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2202
2203     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2204     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2205
2206 This prints
2207
2208     2: got ABC
2209     3: got AB
2210     4: got ABC
2211
2212 You might have expected test 3 to fail because it seems to a more
2213 general purpose version of test 1.  The important difference between
2214 them is that test 3 contains a quantifier (C<\D*>) and so can use
2215 backtracking, whereas test 1 will not.  What's happening is
2216 that you've asked "Is it true that at the start of $x, following 0 or more
2217 non-digits, you have something that's not 123?"  If the pattern matcher had
2218 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2219 fail.
2220
2221 The search engine will initially match C<\D*> with "ABC".  Then it will
2222 try to match C<(?!123)> with "123", which fails.  But because
2223 a quantifier (C<\D*>) has been used in the regular expression, the
2224 search engine can backtrack and retry the match differently
2225 in the hope of matching the complete regular expression.
2226
2227 The pattern really, I<really> wants to succeed, so it uses the
2228 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2229 time.  Now there's indeed something following "AB" that is not
2230 "123".  It's "C123", which suffices.
2231
2232 We can deal with this by using both an assertion and a negation.
2233 We'll say that the first part in $1 must be followed both by a digit
2234 and by something that's not "123".  Remember that the look-aheads
2235 are zero-width expressions--they only look, but don't consume any
2236 of the string in their match.  So rewriting this way produces what
2237 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2238
2239     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2240     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2241
2242     6: got ABC
2243
2244 In other words, the two zero-width assertions next to each other work as though
2245 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2246 matches only if you're at the beginning of the line AND the end of the
2247 line simultaneously.  The deeper underlying truth is that juxtaposition in
2248 regular expressions always means AND, except when you write an explicit OR
2249 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2250 although the attempted matches are made at different positions because "a"
2251 is not a zero-width assertion, but a one-width assertion.
2252
2253 B<WARNING>: Particularly complicated regular expressions can take
2254 exponential time to solve because of the immense number of possible
2255 ways they can use backtracking to try for a match.  For example, without
2256 internal optimizations done by the regular expression engine, this will
2257 take a painfully long time to run:
2258
2259     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2260
2261 And if you used C<*>'s in the internal groups instead of limiting them
2262 to 0 through 5 matches, then it would take forever--or until you ran
2263 out of stack space.  Moreover, these internal optimizations are not
2264 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2265 on the external group, no current optimization is applicable, and the
2266 match takes a long time to finish.
2267
2268 A powerful tool for optimizing such beasts is what is known as an
2269 "independent group",
2270 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2271 zero-length look-ahead/look-behind assertions will not backtrack to make
2272 the tail match, since they are in "logical" context: only
2273 whether they match is considered relevant.  For an example
2274 where side-effects of look-ahead I<might> have influenced the
2275 following match, see L</C<< (?>pattern) >>>.
2276
2277 =head2 Version 8 Regular Expressions
2278 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2279
2280 In case you're not familiar with the "regular" Version 8 regex
2281 routines, here are the pattern-matching rules not described above.
2282
2283 Any single character matches itself, unless it is a I<metacharacter>
2284 with a special meaning described here or above.  You can cause
2285 characters that normally function as metacharacters to be interpreted
2286 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2287 character; "\\" matches a "\"). This escape mechanism is also required
2288 for the character used as the pattern delimiter.
2289
2290 A series of characters matches that series of characters in the target
2291 string, so the pattern C<blurfl> would match "blurfl" in the target
2292 string.
2293
2294 You can specify a character class, by enclosing a list of characters
2295 in C<[]>, which will match any character from the list.  If the
2296 first character after the "[" is "^", the class matches any character not
2297 in the list.  Within a list, the "-" character specifies a
2298 range, so that C<a-z> represents all characters between "a" and "z",
2299 inclusive.  If you want either "-" or "]" itself to be a member of a
2300 class, put it at the start of the list (possibly after a "^"), or
2301 escape it with a backslash.  "-" is also taken literally when it is
2302 at the end of the list, just before the closing "]".  (The
2303 following all specify the same class of three characters: C<[-az]>,
2304 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2305 specifies a class containing twenty-six characters, even on EBCDIC-based
2306 character sets.)  Also, if you try to use the character
2307 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2308 a range, the "-" is understood literally.
2309
2310 Note also that the whole range idea is rather unportable between
2311 character sets--and even within character sets they may cause results
2312 you probably didn't expect.  A sound principle is to use only ranges
2313 that begin from and end at either alphabetics of equal case ([a-e],
2314 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2315 spell out the character sets in full.
2316
2317 Characters may be specified using a metacharacter syntax much like that
2318 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2319 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2320 of three octal digits, matches the character whose coded character set value
2321 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2322 matches the character whose ordinal is I<nn>. The expression \cI<x>
2323 matches the character control-I<x>.  Finally, the "." metacharacter
2324 matches any character except "\n" (unless you use C</s>).
2325
2326 You can specify a series of alternatives for a pattern using "|" to
2327 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2328 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2329 first alternative includes everything from the last pattern delimiter
2330 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2331 the last alternative contains everything from the last "|" to the next
2332 closing pattern delimiter.  That's why it's common practice to include
2333 alternatives in parentheses: to minimize confusion about where they
2334 start and end.
2335
2336 Alternatives are tried from left to right, so the first
2337 alternative found for which the entire expression matches, is the one that
2338 is chosen. This means that alternatives are not necessarily greedy. For
2339 example: when matching C<foo|foot> against "barefoot", only the "foo"
2340 part will match, as that is the first alternative tried, and it successfully
2341 matches the target string. (This might not seem important, but it is
2342 important when you are capturing matched text using parentheses.)
2343
2344 Also remember that "|" is interpreted as a literal within square brackets,
2345 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2346
2347 Within a pattern, you may designate subpatterns for later reference
2348 by enclosing them in parentheses, and you may refer back to the
2349 I<n>th subpattern later in the pattern using the metacharacter
2350 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2351 of their opening parenthesis.  A backreference matches whatever
2352 actually matched the subpattern in the string being examined, not
2353 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2354 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2355 1 matched "0x", even though the rule C<0|0x> could potentially match
2356 the leading 0 in the second number.
2357
2358 =head2 Warning on \1 Instead of $1
2359
2360 Some people get too used to writing things like:
2361
2362     $pattern =~ s/(\W)/\\\1/g;
2363
2364 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2365 shocking the
2366 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2367 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2368 the usual double-quoted string means a control-A.  The customary Unix
2369 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2370 of doing that, you get yourself into trouble if you then add an C</e>
2371 modifier.
2372
2373     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2374
2375 Or if you try to do
2376
2377     s/(\d+)/\1000/;
2378
2379 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2380 C<${1}000>.  The operation of interpolation should not be confused
2381 with the operation of matching a backreference.  Certainly they mean two
2382 different things on the I<left> side of the C<s///>.
2383
2384 =head2 Repeated Patterns Matching a Zero-length Substring
2385
2386 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2387
2388 Regular expressions provide a terse and powerful programming language.  As
2389 with most other power tools, power comes together with the ability
2390 to wreak havoc.
2391
2392 A common abuse of this power stems from the ability to make infinite
2393 loops using regular expressions, with something as innocuous as:
2394
2395     'foo' =~ m{ ( o? )* }x;
2396
2397 The C<o?> matches at the beginning of C<'foo'>, and since the position
2398 in the string is not moved by the match, C<o?> would match again and again
2399 because of the C<*> quantifier.  Another common way to create a similar cycle
2400 is with the looping modifier C<//g>:
2401
2402     @matches = ( 'foo' =~ m{ o? }xg );
2403
2404 or
2405
2406     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2407
2408 or the loop implied by split().
2409
2410 However, long experience has shown that many programming tasks may
2411 be significantly simplified by using repeated subexpressions that
2412 may match zero-length substrings.  Here's a simple example being:
2413
2414     @chars = split //, $string;           # // is not magic in split
2415     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2416
2417 Thus Perl allows such constructs, by I<forcefully breaking
2418 the infinite loop>.  The rules for this are different for lower-level
2419 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2420 ones like the C</g> modifier or split() operator.
2421
2422 The lower-level loops are I<interrupted> (that is, the loop is
2423 broken) when Perl detects that a repeated expression matched a
2424 zero-length substring.   Thus
2425
2426    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2427
2428 is made equivalent to
2429
2430    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2431
2432 For example, this program
2433
2434    #!perl -l
2435    "aaaaab" =~ /
2436      (?:
2437         a                 # non-zero
2438         |                 # or
2439        (?{print "hello"}) # print hello whenever this
2440                           #    branch is tried
2441        (?=(b))            # zero-width assertion
2442      )*  # any number of times
2443     /x;
2444    print $&;
2445    print $1;
2446
2447 prints
2448
2449    hello
2450    aaaaa
2451    b
2452
2453 Notice that "hello" is only printed once, as when Perl sees that the sixth
2454 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2455 the C<*>.
2456
2457 The higher-level loops preserve an additional state between iterations:
2458 whether the last match was zero-length.  To break the loop, the following
2459 match after a zero-length match is prohibited to have a length of zero.
2460 This prohibition interacts with backtracking (see L<"Backtracking">),
2461 and so the I<second best> match is chosen if the I<best> match is of
2462 zero length.
2463
2464 For example:
2465
2466     $_ = 'bar';
2467     s/\w??/<$&>/g;
2468
2469 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2470 match given by non-greedy C<??> is the zero-length match, and the I<second
2471 best> match is what is matched by C<\w>.  Thus zero-length matches
2472 alternate with one-character-long matches.
2473
2474 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2475 position one notch further in the string.
2476
2477 The additional state of being I<matched with zero-length> is associated with
2478 the matched string, and is reset by each assignment to pos().
2479 Zero-length matches at the end of the previous match are ignored
2480 during C<split>.
2481
2482 =head2 Combining RE Pieces
2483
2484 Each of the elementary pieces of regular expressions which were described
2485 before (such as C<ab> or C<\Z>) could match at most one substring
2486 at the given position of the input string.  However, in a typical regular
2487 expression these elementary pieces are combined into more complicated
2488 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2489 (in these examples C<S> and C<T> are regular subexpressions).
2490
2491 Such combinations can include alternatives, leading to a problem of choice:
2492 if we match a regular expression C<a|ab> against C<"abc">, will it match
2493 substring C<"a"> or C<"ab">?  One way to describe which substring is
2494 actually matched is the concept of backtracking (see L<"Backtracking">).
2495 However, this description is too low-level and makes you think
2496 in terms of a particular implementation.
2497
2498 Another description starts with notions of "better"/"worse".  All the
2499 substrings which may be matched by the given regular expression can be
2500 sorted from the "best" match to the "worst" match, and it is the "best"
2501 match which is chosen.  This substitutes the question of "what is chosen?"
2502 by the question of "which matches are better, and which are worse?".
2503
2504 Again, for elementary pieces there is no such question, since at most
2505 one match at a given position is possible.  This section describes the
2506 notion of better/worse for combining operators.  In the description
2507 below C<S> and C<T> are regular subexpressions.
2508
2509 =over 4
2510
2511 =item C<ST>
2512
2513 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2514 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2515 which can be matched by C<T>.
2516
2517 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2518 match than C<A'B'>.
2519
2520 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2521 C<B> is a better match for C<T> than C<B'>.
2522
2523 =item C<S|T>
2524
2525 When C<S> can match, it is a better match than when only C<T> can match.
2526
2527 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2528 two matches for C<T>.
2529
2530 =item C<S{REPEAT_COUNT}>
2531
2532 Matches as C<SSS...S> (repeated as many times as necessary).
2533
2534 =item C<S{min,max}>
2535
2536 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2537
2538 =item C<S{min,max}?>
2539
2540 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2541
2542 =item C<S?>, C<S*>, C<S+>
2543
2544 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2545
2546 =item C<S??>, C<S*?>, C<S+?>
2547
2548 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2549
2550 =item C<< (?>S) >>
2551
2552 Matches the best match for C<S> and only that.
2553
2554 =item C<(?=S)>, C<(?<=S)>
2555
2556 Only the best match for C<S> is considered.  (This is important only if
2557 C<S> has capturing parentheses, and backreferences are used somewhere
2558 else in the whole regular expression.)
2559
2560 =item C<(?!S)>, C<(?<!S)>
2561
2562 For this grouping operator there is no need to describe the ordering, since
2563 only whether or not C<S> can match is important.
2564
2565 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2566
2567 The ordering is the same as for the regular expression which is
2568 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2569
2570 =item C<(?(condition)yes-pattern|no-pattern)>
2571
2572 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2573 already determined.  The ordering of the matches is the same as for the
2574 chosen subexpression.
2575
2576 =back
2577
2578 The above recipes describe the ordering of matches I<at a given position>.
2579 One more rule is needed to understand how a match is determined for the
2580 whole regular expression: a match at an earlier position is always better
2581 than a match at a later position.
2582
2583 =head2 Creating Custom RE Engines
2584
2585 As of Perl 5.10.0, one can create custom regular expression engines.  This
2586 is not for the faint of heart, as they have to plug in at the C level.  See
2587 L<perlreapi> for more details.
2588
2589 As an alternative, overloaded constants (see L<overload>) provide a simple
2590 way to extend the functionality of the RE engine, by substituting one
2591 pattern for another.
2592
2593 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2594 matches at a boundary between whitespace characters and non-whitespace
2595 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2596 at these positions, so we want to have each C<\Y|> in the place of the
2597 more complicated version.  We can create a module C<customre> to do
2598 this:
2599
2600     package customre;
2601     use overload;
2602
2603     sub import {
2604       shift;
2605       die "No argument to customre::import allowed" if @_;
2606       overload::constant 'qr' => \&convert;
2607     }
2608
2609     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2610
2611     # We must also take care of not escaping the legitimate \\Y|
2612     # sequence, hence the presence of '\\' in the conversion rules.
2613     my %rules = ( '\\' => '\\\\',
2614                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2615     sub convert {
2616       my $re = shift;
2617       $re =~ s{
2618                 \\ ( \\ | Y . )
2619               }
2620               { $rules{$1} or invalid($re,$1) }sgex;
2621       return $re;
2622     }
2623
2624 Now C<use customre> enables the new escape in constant regular
2625 expressions, i.e., those without any runtime variable interpolations.
2626 As documented in L<overload>, this conversion will work only over
2627 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2628 part of this regular expression needs to be converted explicitly
2629 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2630
2631     use customre;
2632     $re = <>;
2633     chomp $re;
2634     $re = customre::convert $re;
2635     /\Y|$re\Y|/;
2636
2637 =head2 Embedded Code Execution Frequency
2638
2639 The exact rules for how often (??{}) and (?{}) are executed in a pattern
2640 are unspecified.  In the case of a successful match you can assume that
2641 they DWIM and will be executed in left to right order the appropriate
2642 number of times in the accepting path of the pattern as would any other
2643 meta-pattern.  How non-accepting pathways and match failures affect the
2644 number of times a pattern is executed is specifically unspecified and
2645 may vary depending on what optimizations can be applied to the pattern
2646 and is likely to change from version to version.
2647
2648 For instance in
2649
2650   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
2651
2652 the exact number of times "a" or "b" are printed out is unspecified for
2653 failure, but you may assume they will be printed at least once during
2654 a successful match, additionally you may assume that if "b" is printed,
2655 it will be preceded by at least one "a".
2656
2657 In the case of branching constructs like the following:
2658
2659   /a(b|(?{ print "a" }))c(?{ print "c" })/;
2660
2661 you can assume that the input "ac" will output "ac", and that "abc"
2662 will output only "c".
2663
2664 When embedded code is quantified, successful matches will call the
2665 code once for each matched iteration of the quantifier.  For
2666 example:
2667
2668   "good" =~ /g(?:o(?{print "o"}))*d/;
2669
2670 will output "o" twice.
2671
2672 =head2 PCRE/Python Support
2673
2674 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2675 to the regex syntax. While Perl programmers are encouraged to use the
2676 Perl-specific syntax, the following are also accepted:
2677
2678 =over 4
2679
2680 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2681
2682 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2683
2684 =item C<< (?P=NAME) >>
2685
2686 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2687
2688 =item C<< (?P>NAME) >>
2689
2690 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2691
2692 =back
2693
2694 =head1 BUGS
2695
2696 Many regular expression constructs don't work on EBCDIC platforms.
2697
2698 There are a number of issues with regard to case-insensitive matching
2699 in Unicode rules.  See C<i> under L</Modifiers> above.
2700
2701 This document varies from difficult to understand to completely
2702 and utterly opaque.  The wandering prose riddled with jargon is
2703 hard to fathom in several places.
2704
2705 This document needs a rewrite that separates the tutorial content
2706 from the reference content.
2707
2708 =head1 SEE ALSO
2709
2710 L<perlrequick>.
2711
2712 L<perlretut>.
2713
2714 L<perlop/"Regexp Quote-Like Operators">.
2715
2716 L<perlop/"Gory details of parsing quoted constructs">.
2717
2718 L<perlfaq6>.
2719
2720 L<perlfunc/pos>.
2721
2722 L<perllocale>.
2723
2724 L<perlebcdic>.
2725
2726 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2727 by O'Reilly and Associates.