This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Disable long doubles from pre-5.0 Tru64s.
[perl5.git] / pod / perlsec.pod
1 =head1 NAME
2
3 perlsec - Perl security
4
5 =head1 DESCRIPTION
6
7 Perl is designed to make it easy to program securely even when running
8 with extra privileges, like setuid or setgid programs.  Unlike most
9 command line shells, which are based on multiple substitution passes on
10 each line of the script, Perl uses a more conventional evaluation scheme
11 with fewer hidden snags.  Additionally, because the language has more
12 builtin functionality, it can rely less upon external (and possibly
13 untrustworthy) programs to accomplish its purposes.
14
15 Perl automatically enables a set of special security checks, called I<taint
16 mode>, when it detects its program running with differing real and effective
17 user or group IDs.  The setuid bit in Unix permissions is mode 04000, the
18 setgid bit mode 02000; either or both may be set.  You can also enable taint
19 mode explicitly by using the B<-T> command line flag. This flag is
20 I<strongly> suggested for server programs and any program run on behalf of
21 someone else, such as a CGI script. Once taint mode is on, it's on for
22 the remainder of your script.
23
24 While in this mode, Perl takes special precautions called I<taint
25 checks> to prevent both obvious and subtle traps.  Some of these checks
26 are reasonably simple, such as verifying that path directories aren't
27 writable by others; careful programmers have always used checks like
28 these.  Other checks, however, are best supported by the language itself,
29 and it is these checks especially that contribute to making a set-id Perl
30 program more secure than the corresponding C program.
31
32 You may not use data derived from outside your program to affect
33 something else outside your program--at least, not by accident.  All
34 command line arguments, environment variables, locale information (see
35 L<perllocale>), results of certain system calls (readdir(),
36 readlink(), the variable of shmread(), the messages returned by
37 msgrcv(), the password, gcos and shell fields returned by the
38 getpwxxx() calls), and all file input are marked as "tainted".
39 Tainted data may not be used directly or indirectly in any command
40 that invokes a sub-shell, nor in any command that modifies files,
41 directories, or processes, B<with the following exceptions>:
42
43 =over 4
44
45 =item *
46
47 If you pass a list of arguments to either C<system> or C<exec>,
48 the elements of that list are B<not> checked for taintedness.
49
50 =item *
51
52 Arguments to C<print> and C<syswrite> are B<not> checked for taintedness.
53
54 =back
55
56 Any variable set to a value
57 derived from tainted data will itself be tainted, even if it is
58 logically impossible for the tainted data to alter the variable.
59 Because taintedness is associated with each scalar value, some
60 elements of an array can be tainted and others not.
61
62 For example:
63
64     $arg = shift;               # $arg is tainted
65     $hid = $arg, 'bar';         # $hid is also tainted
66     $line = <>;                 # Tainted
67     $line = <STDIN>;            # Also tainted
68     open FOO, "/home/me/bar" or die $!;
69     $line = <FOO>;              # Still tainted
70     $path = $ENV{'PATH'};       # Tainted, but see below
71     $data = 'abc';              # Not tainted
72
73     system "echo $arg";         # Insecure
74     system "/bin/echo", $arg;   # Secure (doesn't use sh)
75     system "echo $hid";         # Insecure
76     system "echo $data";        # Insecure until PATH set
77
78     $path = $ENV{'PATH'};       # $path now tainted
79
80     $ENV{'PATH'} = '/bin:/usr/bin';
81     delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
82
83     $path = $ENV{'PATH'};       # $path now NOT tainted
84     system "echo $data";        # Is secure now!
85
86     open(FOO, "< $arg");        # OK - read-only file
87     open(FOO, "> $arg");        # Not OK - trying to write
88
89     open(FOO,"echo $arg|");     # Not OK, but...
90     open(FOO,"-|")
91         or exec 'echo', $arg;   # OK
92
93     $shout = `echo $arg`;       # Insecure, $shout now tainted
94
95     unlink $data, $arg;         # Insecure
96     umask $arg;                 # Insecure
97
98     exec "echo $arg";           # Insecure (uses the shell)
99     exec "echo", $arg;          # Secure (doesn't use the shell)
100     exec "sh", '-c', $arg;      # Considered secure, alas!
101
102     @files = <*.c>;             # insecure (uses readdir() or similar)
103     @files = glob('*.c');       # insecure (uses readdir() or similar)
104
105     # In Perl releases older than 5.6.0 the <*.c> and glob('*.c') would
106     # have used an external program to do the filename expansion; but in
107     # either case the result is tainted since the list of filenames comes
108     # from outside of the program.
109
110 If you try to do something insecure, you will get a fatal error saying
111 something like "Insecure dependency" or "Insecure $ENV{PATH}".  Note that you
112 can still write an insecure B<system> or B<exec>, but only by explicitly
113 doing something like the "considered secure" example above.
114
115 =head2 Laundering and Detecting Tainted Data
116
117 To test whether a variable contains tainted data, and whose use would
118 thus trigger an "Insecure dependency" message, you can use the
119 tainted() function of the Scalar::Util module, available in your
120 nearby CPAN mirror, and included in Perl starting from the release 5.8.0.
121 Or you may be able to use the following I<is_tainted()> function.
122
123     sub is_tainted {
124         return ! eval {
125             join('',@_), kill 0;
126             1;
127         };
128     }
129
130 This function makes use of the fact that the presence of tainted data
131 anywhere within an expression renders the entire expression tainted.  It
132 would be inefficient for every operator to test every argument for
133 taintedness.  Instead, the slightly more efficient and conservative
134 approach is used that if any tainted value has been accessed within the
135 same expression, the whole expression is considered tainted.
136
137 But testing for taintedness gets you only so far.  Sometimes you have just
138 to clear your data's taintedness.  The only way to bypass the tainting
139 mechanism is by referencing subpatterns from a regular expression match.
140 Perl presumes that if you reference a substring using $1, $2, etc., that
141 you knew what you were doing when you wrote the pattern.  That means using
142 a bit of thought--don't just blindly untaint anything, or you defeat the
143 entire mechanism.  It's better to verify that the variable has only good
144 characters (for certain values of "good") rather than checking whether it
145 has any bad characters.  That's because it's far too easy to miss bad
146 characters that you never thought of.
147
148 Here's a test to make sure that the data contains nothing but "word"
149 characters (alphabetics, numerics, and underscores), a hyphen, an at sign,
150 or a dot.
151
152     if ($data =~ /^([-\@\w.]+)$/) {
153         $data = $1;                     # $data now untainted
154     } else {
155         die "Bad data in $data";        # log this somewhere
156     }
157
158 This is fairly secure because C</\w+/> doesn't normally match shell
159 metacharacters, nor are dot, dash, or at going to mean something special
160 to the shell.  Use of C</.+/> would have been insecure in theory because
161 it lets everything through, but Perl doesn't check for that.  The lesson
162 is that when untainting, you must be exceedingly careful with your patterns.
163 Laundering data using regular expression is the I<only> mechanism for
164 untainting dirty data, unless you use the strategy detailed below to fork
165 a child of lesser privilege.
166
167 The example does not untaint $data if C<use locale> is in effect,
168 because the characters matched by C<\w> are determined by the locale.
169 Perl considers that locale definitions are untrustworthy because they
170 contain data from outside the program.  If you are writing a
171 locale-aware program, and want to launder data with a regular expression
172 containing C<\w>, put C<no locale> ahead of the expression in the same
173 block.  See L<perllocale/SECURITY> for further discussion and examples.
174
175 =head2 Switches On the "#!" Line
176
177 When you make a script executable, in order to make it usable as a
178 command, the system will pass switches to perl from the script's #!
179 line.  Perl checks that any command line switches given to a setuid
180 (or setgid) script actually match the ones set on the #! line.  Some
181 Unix and Unix-like environments impose a one-switch limit on the #!
182 line, so you may need to use something like C<-wU> instead of C<-w -U>
183 under such systems.  (This issue should arise only in Unix or
184 Unix-like environments that support #! and setuid or setgid scripts.)
185
186 =head2 Cleaning Up Your Path
187
188 For "Insecure C<$ENV{PATH}>" messages, you need to set C<$ENV{'PATH'}> to a
189 known value, and each directory in the path must be non-writable by others
190 than its owner and group.  You may be surprised to get this message even
191 if the pathname to your executable is fully qualified.  This is I<not>
192 generated because you didn't supply a full path to the program; instead,
193 it's generated because you never set your PATH environment variable, or
194 you didn't set it to something that was safe.  Because Perl can't
195 guarantee that the executable in question isn't itself going to turn
196 around and execute some other program that is dependent on your PATH, it
197 makes sure you set the PATH.
198
199 The PATH isn't the only environment variable which can cause problems.
200 Because some shells may use the variables IFS, CDPATH, ENV, and
201 BASH_ENV, Perl checks that those are either empty or untainted when
202 starting subprocesses. You may wish to add something like this to your
203 setid and taint-checking scripts.
204
205     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};   # Make %ENV safer
206
207 It's also possible to get into trouble with other operations that don't
208 care whether they use tainted values.  Make judicious use of the file
209 tests in dealing with any user-supplied filenames.  When possible, do
210 opens and such B<after> properly dropping any special user (or group!)
211 privileges. Perl doesn't prevent you from opening tainted filenames for reading,
212 so be careful what you print out.  The tainting mechanism is intended to
213 prevent stupid mistakes, not to remove the need for thought.
214
215 Perl does not call the shell to expand wild cards when you pass B<system>
216 and B<exec> explicit parameter lists instead of strings with possible shell
217 wildcards in them.  Unfortunately, the B<open>, B<glob>, and
218 backtick functions provide no such alternate calling convention, so more
219 subterfuge will be required.
220
221 Perl provides a reasonably safe way to open a file or pipe from a setuid
222 or setgid program: just create a child process with reduced privilege who
223 does the dirty work for you.  First, fork a child using the special
224 B<open> syntax that connects the parent and child by a pipe.  Now the
225 child resets its ID set and any other per-process attributes, like
226 environment variables, umasks, current working directories, back to the
227 originals or known safe values.  Then the child process, which no longer
228 has any special permissions, does the B<open> or other system call.
229 Finally, the child passes the data it managed to access back to the
230 parent.  Because the file or pipe was opened in the child while running
231 under less privilege than the parent, it's not apt to be tricked into
232 doing something it shouldn't.
233
234 Here's a way to do backticks reasonably safely.  Notice how the B<exec> is
235 not called with a string that the shell could expand.  This is by far the
236 best way to call something that might be subjected to shell escapes: just
237 never call the shell at all.  
238
239         use English;
240         die "Can't fork: $!" unless defined($pid = open(KID, "-|"));
241         if ($pid) {           # parent
242             while (<KID>) {
243                 # do something
244             }
245             close KID;
246         } else {
247             my @temp     = ($EUID, $EGID);
248             my $orig_uid = $UID;
249             my $orig_gid = $GID;
250             $EUID = $UID;
251             $EGID = $GID;
252             # Drop privileges
253             $UID  = $orig_uid;
254             $GID  = $orig_gid;
255             # Make sure privs are really gone
256             ($EUID, $EGID) = @temp;
257             die "Can't drop privileges"
258                 unless $UID == $EUID  && $GID eq $EGID;
259             $ENV{PATH} = "/bin:/usr/bin"; # Minimal PATH.
260             # Consider sanitizing the environment even more.
261             exec 'myprog', 'arg1', 'arg2'
262                 or die "can't exec myprog: $!";
263         }
264
265 A similar strategy would work for wildcard expansion via C<glob>, although
266 you can use C<readdir> instead.
267
268 Taint checking is most useful when although you trust yourself not to have
269 written a program to give away the farm, you don't necessarily trust those
270 who end up using it not to try to trick it into doing something bad.  This
271 is the kind of security checking that's useful for set-id programs and
272 programs launched on someone else's behalf, like CGI programs.
273
274 This is quite different, however, from not even trusting the writer of the
275 code not to try to do something evil.  That's the kind of trust needed
276 when someone hands you a program you've never seen before and says, "Here,
277 run this."  For that kind of safety, check out the Safe module,
278 included standard in the Perl distribution.  This module allows the
279 programmer to set up special compartments in which all system operations
280 are trapped and namespace access is carefully controlled.
281
282 =head2 Security Bugs
283
284 Beyond the obvious problems that stem from giving special privileges to
285 systems as flexible as scripts, on many versions of Unix, set-id scripts
286 are inherently insecure right from the start.  The problem is a race
287 condition in the kernel.  Between the time the kernel opens the file to
288 see which interpreter to run and when the (now-set-id) interpreter turns
289 around and reopens the file to interpret it, the file in question may have
290 changed, especially if you have symbolic links on your system.
291
292 Fortunately, sometimes this kernel "feature" can be disabled.
293 Unfortunately, there are two ways to disable it.  The system can simply
294 outlaw scripts with any set-id bit set, which doesn't help much.
295 Alternately, it can simply ignore the set-id bits on scripts.  If the
296 latter is true, Perl can emulate the setuid and setgid mechanism when it
297 notices the otherwise useless setuid/gid bits on Perl scripts.  It does
298 this via a special executable called B<suidperl> that is automatically
299 invoked for you if it's needed.
300
301 However, if the kernel set-id script feature isn't disabled, Perl will
302 complain loudly that your set-id script is insecure.  You'll need to
303 either disable the kernel set-id script feature, or put a C wrapper around
304 the script.  A C wrapper is just a compiled program that does nothing
305 except call your Perl program.   Compiled programs are not subject to the
306 kernel bug that plagues set-id scripts.  Here's a simple wrapper, written
307 in C:
308
309     #define REAL_PATH "/path/to/script"
310     main(ac, av)
311         char **av;
312     {
313         execv(REAL_PATH, av);
314     }
315
316 Compile this wrapper into a binary executable and then make I<it> rather
317 than your script setuid or setgid.
318
319 In recent years, vendors have begun to supply systems free of this
320 inherent security bug.  On such systems, when the kernel passes the name
321 of the set-id script to open to the interpreter, rather than using a
322 pathname subject to meddling, it instead passes I</dev/fd/3>.  This is a
323 special file already opened on the script, so that there can be no race
324 condition for evil scripts to exploit.  On these systems, Perl should be
325 compiled with C<-DSETUID_SCRIPTS_ARE_SECURE_NOW>.  The B<Configure>
326 program that builds Perl tries to figure this out for itself, so you
327 should never have to specify this yourself.  Most modern releases of
328 SysVr4 and BSD 4.4 use this approach to avoid the kernel race condition.
329
330 Prior to release 5.6.1 of Perl, bugs in the code of B<suidperl> could
331 introduce a security hole.
332
333 =head2 Protecting Your Programs
334
335 There are a number of ways to hide the source to your Perl programs,
336 with varying levels of "security".
337
338 First of all, however, you I<can't> take away read permission, because
339 the source code has to be readable in order to be compiled and
340 interpreted.  (That doesn't mean that a CGI script's source is
341 readable by people on the web, though.)  So you have to leave the
342 permissions at the socially friendly 0755 level.  This lets 
343 people on your local system only see your source.
344
345 Some people mistakenly regard this as a security problem.  If your program does
346 insecure things, and relies on people not knowing how to exploit those
347 insecurities, it is not secure.  It is often possible for someone to
348 determine the insecure things and exploit them without viewing the
349 source.  Security through obscurity, the name for hiding your bugs
350 instead of fixing them, is little security indeed.
351
352 You can try using encryption via source filters (Filter::* from CPAN,
353 or Filter::Util::Call and Filter::Simple since Perl 5.8).
354 But crackers might be able to decrypt it.  You can try using the byte
355 code compiler and interpreter described below, but crackers might be
356 able to de-compile it.  You can try using the native-code compiler
357 described below, but crackers might be able to disassemble it.  These
358 pose varying degrees of difficulty to people wanting to get at your
359 code, but none can definitively conceal it (this is true of every
360 language, not just Perl).
361
362 If you're concerned about people profiting from your code, then the
363 bottom line is that nothing but a restrictive licence will give you
364 legal security.  License your software and pepper it with threatening
365 statements like "This is unpublished proprietary software of XYZ Corp.
366 Your access to it does not give you permission to use it blah blah
367 blah."  You should see a lawyer to be sure your licence's wording will
368 stand up in court.
369
370 =head1 SEE ALSO
371
372 L<perlrun> for its description of cleaning up environment variables.