This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Fix broken link in perlfunc
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed-length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to the switch feature
168
169 C<break>, C<continue>, C<default, >C<given>, C<when>
170
171 These are available only if you enable the C<"switch"> feature.
172 See L<feature> and L<perlsyn/"Switch statements">.  
173 Alternately, include a C<use v5.10> or later to the current scope.
174
175 =item Keywords related to scoping
176
177 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
178
179 C<state> is available only if the C<"state"> feature is enabled. See
180 L<feature>.  Alternately, include a C<use v5.10> or later to the current scope.
181
182 =item Miscellaneous functions
183
184 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
185 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
186
187 =item Functions for processes and process groups
188 X<process> X<pid> X<process id>
189
190 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
191 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
192 C<times>, C<wait>, C<waitpid>
193
194 =item Keywords related to Perl modules
195 X<module>
196
197 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
198
199 =item Keywords related to classes and object-orientation
200 X<object> X<class> X<package>
201
202 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
203 C<untie>, C<use>
204
205 =item Low-level socket functions
206 X<socket> X<sock>
207
208 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
209 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
210 C<socket>, C<socketpair>
211
212 =item System V interprocess communication functions
213 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
214
215 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
216 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
217
218 =item Fetching user and group info
219 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
220
221 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
222 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
223 C<getpwuid>, C<setgrent>, C<setpwent>
224
225 =item Fetching network info
226 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
227
228 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
229 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
230 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
231 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
232 C<setnetent>, C<setprotoent>, C<setservent>
233
234 =item Time-related functions
235 X<time> X<date>
236
237 C<gmtime>, C<localtime>, C<time>, C<times>
238
239 =item Functions new in perl5
240 X<perl5>
241
242 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
243 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
244 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
245 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
246 C<ucfirst>, C<untie>, C<use>, C<when>
247
248 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
249 operator, which can be used in expressions.
250
251 =item Functions obsoleted in perl5
252
253 C<dbmclose>, C<dbmopen>
254
255 =back
256
257 =head2 Portability
258 X<portability> X<Unix> X<portable>
259
260 Perl was born in Unix and can therefore access all common Unix
261 system calls.  In non-Unix environments, the functionality of some
262 Unix system calls may not be available or details of the available
263 functionality may differ slightly.  The Perl functions affected
264 by this are:
265
266 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
267 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
268 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
269 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
270 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
271 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
272 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
273 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
274 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
275 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
276 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
277 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
278 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
279 C<shmwrite>, C<socket>, C<socketpair>,
280 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
281 C<times>, C<truncate>, C<umask>, C<unlink>,
282 C<utime>, C<wait>, C<waitpid>
283
284 For more information about the portability of these functions, see
285 L<perlport> and other available platform-specific documentation.
286
287 =head2 Alphabetical Listing of Perl Functions
288
289 =over 
290
291 =item -X FILEHANDLE
292 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
293 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
294
295 =item -X EXPR
296
297 =item -X DIRHANDLE
298
299 =item -X
300
301 A file test, where X is one of the letters listed below.  This unary
302 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
303 and tests the associated file to see if something is true about it.  If the
304 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
305 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
306 the undefined value if the file doesn't exist.  Despite the funny
307 names, precedence is the same as any other named unary operator.  The
308 operator may be any of:
309
310     -r  File is readable by effective uid/gid.
311     -w  File is writable by effective uid/gid.
312     -x  File is executable by effective uid/gid.
313     -o  File is owned by effective uid.
314
315     -R  File is readable by real uid/gid.
316     -W  File is writable by real uid/gid.
317     -X  File is executable by real uid/gid.
318     -O  File is owned by real uid.
319
320     -e  File exists.
321     -z  File has zero size (is empty).
322     -s  File has nonzero size (returns size in bytes).
323
324     -f  File is a plain file.
325     -d  File is a directory.
326     -l  File is a symbolic link.
327     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
328     -S  File is a socket.
329     -b  File is a block special file.
330     -c  File is a character special file.
331     -t  Filehandle is opened to a tty.
332
333     -u  File has setuid bit set.
334     -g  File has setgid bit set.
335     -k  File has sticky bit set.
336
337     -T  File is an ASCII text file (heuristic guess).
338     -B  File is a "binary" file (opposite of -T).
339
340     -M  Script start time minus file modification time, in days.
341     -A  Same for access time.
342     -C  Same for inode change time (Unix, may differ for other platforms)
343
344 Example:
345
346     while (<>) {
347         chomp;
348         next unless -f $_;  # ignore specials
349         #...
350     }
351
352 Note that C<-s/a/b/> does not do a negated substitution.  Saying
353 C<-exp($foo)> still works as expected, however: only single letters
354 following a minus are interpreted as file tests.
355
356 These operators are exempt from the "looks like a function rule" described
357 above. That is, an opening parenthesis after the operator does not affect
358 how much of the following code constitutes the argument. Put the opening
359 parentheses before the operator to separate it from code that follows (this
360 applies only to operators with higher precedence than unary operators, of
361 course):
362
363     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
364     (-s $file) + 1024  # correct
365
366 The interpretation of the file permission operators C<-r>, C<-R>,
367 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
368 of the file and the uids and gids of the user.  There may be other
369 reasons you can't actually read, write, or execute the file: for
370 example network filesystem access controls, ACLs (access control lists),
371 read-only filesystems, and unrecognized executable formats.  Note
372 that the use of these six specific operators to verify if some operation
373 is possible is usually a mistake, because it may be open to race
374 conditions.
375
376 Also note that, for the superuser on the local filesystems, the C<-r>,
377 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
378 if any execute bit is set in the mode.  Scripts run by the superuser
379 may thus need to do a stat() to determine the actual mode of the file,
380 or temporarily set their effective uid to something else.
381
382 If you are using ACLs, there is a pragma called C<filetest> that may
383 produce more accurate results than the bare stat() mode bits.
384 When under C<use filetest 'access'> the above-mentioned filetests
385 test whether the permission can(not) be granted using the
386 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
387 under this pragma return true even if there are no execute permission
388 bits set (nor any extra execute permission ACLs).  This strangeness is
389 due to the underlying system calls' definitions. Note also that, due to
390 the implementation of C<use filetest 'access'>, the C<_> special
391 filehandle won't cache the results of the file tests when this pragma is
392 in effect.  Read the documentation for the C<filetest> pragma for more
393 information.
394
395 The C<-T> and C<-B> switches work as follows.  The first block or so of the
396 file is examined for odd characters such as strange control codes or
397 characters with the high bit set.  If too many strange characters (>30%)
398 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
399 containing a zero byte in the first block is considered a binary file.  If C<-T>
400 or C<-B> is used on a filehandle, the current IO buffer is examined
401 rather than the first block.  Both C<-T> and C<-B> return true on an empty
402 file, or a file at EOF when testing a filehandle.  Because you have to
403 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
404 against the file first, as in C<next unless -f $file && -T $file>.
405
406 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
407 the special filehandle consisting of a solitary underline, then the stat
408 structure of the previous file test (or stat operator) is used, saving
409 a system call.  (This doesn't work with C<-t>, and you need to remember
410 that lstat() and C<-l> leave values in the stat structure for the
411 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
412 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
413 Example:
414
415     print "Can do.\n" if -r $a || -w _ || -x _;
416
417     stat($filename);
418     print "Readable\n" if -r _;
419     print "Writable\n" if -w _;
420     print "Executable\n" if -x _;
421     print "Setuid\n" if -u _;
422     print "Setgid\n" if -g _;
423     print "Sticky\n" if -k _;
424     print "Text\n" if -T _;
425     print "Binary\n" if -B _;
426
427 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
428 test operators, in a way that C<-f -w -x $file> is equivalent to
429 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
430 the return value of C<-f $file> as an argument to another filetest
431 operator, no special magic will happen.)
432
433 Portability issues: L<perlport/-X>.
434
435 =item abs VALUE
436 X<abs> X<absolute>
437
438 =item abs
439
440 Returns the absolute value of its argument.
441 If VALUE is omitted, uses C<$_>.
442
443 =item accept NEWSOCKET,GENERICSOCKET
444 X<accept>
445
446 Accepts an incoming socket connect, just as accept(2) 
447 does.  Returns the packed address if it succeeded, false otherwise.
448 See the example in L<perlipc/"Sockets: Client/Server Communication">.
449
450 On systems that support a close-on-exec flag on files, the flag will
451 be set for the newly opened file descriptor, as determined by the
452 value of $^F.  See L<perlvar/$^F>.
453
454 =item alarm SECONDS
455 X<alarm>
456 X<SIGALRM>
457 X<timer>
458
459 =item alarm
460
461 Arranges to have a SIGALRM delivered to this process after the
462 specified number of wallclock seconds has elapsed.  If SECONDS is not
463 specified, the value stored in C<$_> is used. (On some machines,
464 unfortunately, the elapsed time may be up to one second less or more
465 than you specified because of how seconds are counted, and process
466 scheduling may delay the delivery of the signal even further.)
467
468 Only one timer may be counting at once.  Each call disables the
469 previous timer, and an argument of C<0> may be supplied to cancel the
470 previous timer without starting a new one.  The returned value is the
471 amount of time remaining on the previous timer.
472
473 For delays of finer granularity than one second, the Time::HiRes module
474 (from CPAN, and starting from Perl 5.8 part of the standard
475 distribution) provides ualarm().  You may also use Perl's four-argument
476 version of select() leaving the first three arguments undefined, or you
477 might be able to use the C<syscall> interface to access setitimer(2) if
478 your system supports it. See L<perlfaq8> for details.
479
480 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
481 C<sleep> may be internally implemented on your system with C<alarm>.
482
483 If you want to use C<alarm> to time out a system call you need to use an
484 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
485 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
486 restart system calls on some systems.  Using C<eval>/C<die> always works,
487 modulo the caveats given in L<perlipc/"Signals">.
488
489     eval {
490         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
491         alarm $timeout;
492         $nread = sysread SOCKET, $buffer, $size;
493         alarm 0;
494     };
495     if ($@) {
496         die unless $@ eq "alarm\n";   # propagate unexpected errors
497         # timed out
498     }
499     else {
500         # didn't
501     }
502
503 For more information see L<perlipc>.
504
505 Portability issues: L<perlport/alarm>.
506
507 =item atan2 Y,X
508 X<atan2> X<arctangent> X<tan> X<tangent>
509
510 Returns the arctangent of Y/X in the range -PI to PI.
511
512 For the tangent operation, you may use the C<Math::Trig::tan>
513 function, or use the familiar relation:
514
515     sub tan { sin($_[0]) / cos($_[0])  }
516
517 The return value for C<atan2(0,0)> is implementation-defined; consult
518 your atan2(3) manpage for more information.
519
520 Portability issues: L<perlport/atan2>.
521
522 =item bind SOCKET,NAME
523 X<bind>
524
525 Binds a network address to a socket, just as bind(2)
526 does.  Returns true if it succeeded, false otherwise.  NAME should be a
527 packed address of the appropriate type for the socket.  See the examples in
528 L<perlipc/"Sockets: Client/Server Communication">.
529
530 =item binmode FILEHANDLE, LAYER
531 X<binmode> X<binary> X<text> X<DOS> X<Windows>
532
533 =item binmode FILEHANDLE
534
535 Arranges for FILEHANDLE to be read or written in "binary" or "text"
536 mode on systems where the run-time libraries distinguish between
537 binary and text files.  If FILEHANDLE is an expression, the value is
538 taken as the name of the filehandle.  Returns true on success,
539 otherwise it returns C<undef> and sets C<$!> (errno).
540
541 On some systems (in general, DOS- and Windows-based systems) binmode()
542 is necessary when you're not working with a text file.  For the sake
543 of portability it is a good idea always to use it when appropriate,
544 and never to use it when it isn't appropriate.  Also, people can
545 set their I/O to be by default UTF8-encoded Unicode, not bytes.
546
547 In other words: regardless of platform, use binmode() on binary data,
548 like images, for example.
549
550 If LAYER is present it is a single string, but may contain multiple
551 directives. The directives alter the behaviour of the filehandle.
552 When LAYER is present, using binmode on a text file makes sense.
553
554 If LAYER is omitted or specified as C<:raw> the filehandle is made
555 suitable for passing binary data. This includes turning off possible CRLF
556 translation and marking it as bytes (as opposed to Unicode characters).
557 Note that, despite what may be implied in I<"Programming Perl"> (the
558 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
559 Other layers that would affect the binary nature of the stream are
560 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
561 PERLIO environment variable.
562
563 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
564 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
565 establish default I/O layers.  See L<open>.
566
567 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
568 in "Programming Perl, 3rd Edition".  However, since the publishing of this
569 book, by many known as "Camel III", the consensus of the naming of this
570 functionality has moved from "discipline" to "layer".  All documentation
571 of this version of Perl therefore refers to "layers" rather than to
572 "disciplines".  Now back to the regularly scheduled documentation...>
573
574 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
575 C<:utf8> just marks the data as UTF-8 without further checking,
576 while C<:encoding(UTF-8)> checks the data for actually being valid
577 UTF-8. More details can be found in L<PerlIO::encoding>.
578
579 In general, binmode() should be called after open() but before any I/O
580 is done on the filehandle.  Calling binmode() normally flushes any
581 pending buffered output data (and perhaps pending input data) on the
582 handle.  An exception to this is the C<:encoding> layer that
583 changes the default character encoding of the handle; see L</open>.
584 The C<:encoding> layer sometimes needs to be called in
585 mid-stream, and it doesn't flush the stream.  The C<:encoding>
586 also implicitly pushes on top of itself the C<:utf8> layer because
587 internally Perl operates on UTF8-encoded Unicode characters.
588
589 The operating system, device drivers, C libraries, and Perl run-time
590 system all conspire to let the programmer treat a single
591 character (C<\n>) as the line terminator, irrespective of external
592 representation.  On many operating systems, the native text file
593 representation matches the internal representation, but on some
594 platforms the external representation of C<\n> is made up of more than
595 one character.
596
597 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
598 a single character to end each line in the external representation of text
599 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
600 flavors of Mac OS, and is LINE FEED on Unix and most VMS files). In other
601 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
602 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
603 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
604 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
605 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
606 output.  This is what you want for text files, but it can be disastrous for
607 binary files.
608
609 Another consequence of using binmode() (on some systems) is that
610 special end-of-file markers will be seen as part of the data stream.
611 For systems from the Microsoft family this means that, if your binary
612 data contain C<\cZ>, the I/O subsystem will regard it as the end of
613 the file, unless you use binmode().
614
615 binmode() is important not only for readline() and print() operations,
616 but also when using read(), seek(), sysread(), syswrite() and tell()
617 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
618 in L<perlvar> for how to manually set your input and output
619 line-termination sequences.
620
621 Portability issues: L<perlport/binmode>.
622
623 =item bless REF,CLASSNAME
624 X<bless>
625
626 =item bless REF
627
628 This function tells the thingy referenced by REF that it is now an object
629 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
630 is used.  Because a C<bless> is often the last thing in a constructor,
631 it returns the reference for convenience.  Always use the two-argument
632 version if a derived class might inherit the function doing the blessing.
633 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
634 of objects.
635
636 Consider always blessing objects in CLASSNAMEs that are mixed case.
637 Namespaces with all lowercase names are considered reserved for
638 Perl pragmata.  Builtin types have all uppercase names. To prevent
639 confusion, you may wish to avoid such package names as well.  Make sure
640 that CLASSNAME is a true value.
641
642 See L<perlmod/"Perl Modules">.
643
644 =item break
645
646 Break out of a C<given()> block.
647
648 This keyword is enabled by the C<"switch"> feature: see
649 L<feature> for more information.  Alternately, include a C<use
650 v5.10> or later to the current scope.
651
652 =item caller EXPR
653 X<caller> X<call stack> X<stack> X<stack trace>
654
655 =item caller
656
657 Returns the context of the current subroutine call.  In scalar context,
658 returns the caller's package name if there I<is> a caller (that is, if
659 we're in a subroutine or C<eval> or C<require>) and the undefined value
660 otherwise.  In list context, returns
661
662     # 0         1          2
663     ($package, $filename, $line) = caller;
664
665 With EXPR, it returns some extra information that the debugger uses to
666 print a stack trace.  The value of EXPR indicates how many call frames
667 to go back before the current one.
668
669     #  0         1          2      3            4
670     ($package, $filename, $line, $subroutine, $hasargs,
671
672     #  5          6          7            8       9         10
673     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
674      = caller($i);
675
676 Here $subroutine may be C<(eval)> if the frame is not a subroutine
677 call, but an C<eval>.  In such a case additional elements $evaltext and
678 C<$is_require> are set: C<$is_require> is true if the frame is created by a
679 C<require> or C<use> statement, $evaltext contains the text of the
680 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
681 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
682 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
683 frame.)  $subroutine may also be C<(unknown)> if this particular
684 subroutine happens to have been deleted from the symbol table.
685 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
686 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
687 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
688 between versions of Perl, and are not meant for external use.
689
690 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
691 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
692 of this hash, as they are the actual values stored in the optree.
693
694 Furthermore, when called from within the DB package, caller returns more
695 detailed information: it sets the list variable C<@DB::args> to be the
696 arguments with which the subroutine was invoked.
697
698 Be aware that the optimizer might have optimized call frames away before
699 C<caller> had a chance to get the information.  That means that C<caller(N)>
700 might not return information about the call frame you expect it to, for
701 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
702 previous time C<caller> was called.
703
704 Be aware that setting C<@DB::args> is I<best effort>, intended for
705 debugging or generating backtraces, and should not be relied upon. In
706 particular, as C<@_> contains aliases to the caller's arguments, Perl does
707 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
708 subroutine makes to C<@_> or its contents, not the original values at call
709 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
710 elements, so under certain cases its elements may have become freed and
711 reallocated for other variables or temporary values. Finally, a side effect
712 of the current implementation is that the effects of C<shift @_> can
713 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
714 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
715 elements), so C<@DB::args> is actually a hybrid of the current state and
716 initial state of C<@_>. Buyer beware.
717
718 =item chdir EXPR
719 X<chdir>
720 X<cd>
721 X<directory, change>
722
723 =item chdir FILEHANDLE
724
725 =item chdir DIRHANDLE
726
727 =item chdir
728
729 Changes the working directory to EXPR, if possible. If EXPR is omitted,
730 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
731 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
732 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
733 neither is set, C<chdir> does nothing. It returns true on success,
734 false otherwise. See the example under C<die>.
735
736 On systems that support fchdir(2), you may pass a filehandle or
737 directory handle as the argument.  On systems that don't support fchdir(2),
738 passing handles raises an exception.
739
740 =item chmod LIST
741 X<chmod> X<permission> X<mode>
742
743 Changes the permissions of a list of files.  The first element of the
744 list must be the numeric mode, which should probably be an octal
745 number, and which definitely should I<not> be a string of octal digits:
746 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
747 successfully changed.  See also L</oct> if all you have is a string.
748
749     $cnt = chmod 0755, "foo", "bar";
750     chmod 0755, @executables;
751     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
752                                              # --w----r-T
753     $mode = "0644"; chmod oct($mode), "foo"; # this is better
754     $mode = 0644;   chmod $mode, "foo";      # this is best
755
756 On systems that support fchmod(2), you may pass filehandles among the
757 files.  On systems that don't support fchmod(2), passing filehandles raises
758 an exception.  Filehandles must be passed as globs or glob references to be
759 recognized; barewords are considered filenames.
760
761     open(my $fh, "<", "foo");
762     my $perm = (stat $fh)[2] & 07777;
763     chmod($perm | 0600, $fh);
764
765 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
766 module:
767
768     use Fcntl qw( :mode );
769     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
770     # Identical to the chmod 0755 of the example above.
771
772 Portability issues: L<perlport/chmod>.
773
774 =item chomp VARIABLE
775 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
776
777 =item chomp( LIST )
778
779 =item chomp
780
781 This safer version of L</chop> removes any trailing string
782 that corresponds to the current value of C<$/> (also known as
783 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
784 number of characters removed from all its arguments.  It's often used to
785 remove the newline from the end of an input record when you're worried
786 that the final record may be missing its newline.  When in paragraph
787 mode (C<$/ = "">), it removes all trailing newlines from the string.
788 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
789 a reference to an integer or the like; see L<perlvar>) chomp() won't
790 remove anything.
791 If VARIABLE is omitted, it chomps C<$_>.  Example:
792
793     while (<>) {
794         chomp;  # avoid \n on last field
795         @array = split(/:/);
796         # ...
797     }
798
799 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
800
801 You can actually chomp anything that's an lvalue, including an assignment:
802
803     chomp($cwd = `pwd`);
804     chomp($answer = <STDIN>);
805
806 If you chomp a list, each element is chomped, and the total number of
807 characters removed is returned.
808
809 Note that parentheses are necessary when you're chomping anything
810 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
811 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
812 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
813 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
814 as C<chomp($a, $b)>.
815
816 =item chop VARIABLE
817 X<chop>
818
819 =item chop( LIST )
820
821 =item chop
822
823 Chops off the last character of a string and returns the character
824 chopped.  It is much more efficient than C<s/.$//s> because it neither
825 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
826 If VARIABLE is a hash, it chops the hash's values, but not its keys.
827
828 You can actually chop anything that's an lvalue, including an assignment.
829
830 If you chop a list, each element is chopped.  Only the value of the
831 last C<chop> is returned.
832
833 Note that C<chop> returns the last character.  To return all but the last
834 character, use C<substr($string, 0, -1)>.
835
836 See also L</chomp>.
837
838 =item chown LIST
839 X<chown> X<owner> X<user> X<group>
840
841 Changes the owner (and group) of a list of files.  The first two
842 elements of the list must be the I<numeric> uid and gid, in that
843 order.  A value of -1 in either position is interpreted by most
844 systems to leave that value unchanged.  Returns the number of files
845 successfully changed.
846
847     $cnt = chown $uid, $gid, 'foo', 'bar';
848     chown $uid, $gid, @filenames;
849
850 On systems that support fchown(2), you may pass filehandles among the
851 files.  On systems that don't support fchown(2), passing filehandles raises
852 an exception.  Filehandles must be passed as globs or glob references to be
853 recognized; barewords are considered filenames.
854
855 Here's an example that looks up nonnumeric uids in the passwd file:
856
857     print "User: ";
858     chomp($user = <STDIN>);
859     print "Files: ";
860     chomp($pattern = <STDIN>);
861
862     ($login,$pass,$uid,$gid) = getpwnam($user)
863         or die "$user not in passwd file";
864
865     @ary = glob($pattern);  # expand filenames
866     chown $uid, $gid, @ary;
867
868 On most systems, you are not allowed to change the ownership of the
869 file unless you're the superuser, although you should be able to change
870 the group to any of your secondary groups.  On insecure systems, these
871 restrictions may be relaxed, but this is not a portable assumption.
872 On POSIX systems, you can detect this condition this way:
873
874     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
875     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
876
877 Portability issues: L<perlport/chmod>.
878
879 =item chr NUMBER
880 X<chr> X<character> X<ASCII> X<Unicode>
881
882 =item chr
883
884 Returns the character represented by that NUMBER in the character set.
885 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
886 chr(0x263a) is a Unicode smiley face.  
887
888 Negative values give the Unicode replacement character (chr(0xfffd)),
889 except under the L<bytes> pragma, where the low eight bits of the value
890 (truncated to an integer) are used.
891
892 If NUMBER is omitted, uses C<$_>.
893
894 For the reverse, use L</ord>.
895
896 Note that characters from 128 to 255 (inclusive) are by default
897 internally not encoded as UTF-8 for backward compatibility reasons.
898
899 See L<perlunicode> for more about Unicode.
900
901 =item chroot FILENAME
902 X<chroot> X<root>
903
904 =item chroot
905
906 This function works like the system call by the same name: it makes the
907 named directory the new root directory for all further pathnames that
908 begin with a C</> by your process and all its children.  (It doesn't
909 change your current working directory, which is unaffected.)  For security
910 reasons, this call is restricted to the superuser.  If FILENAME is
911 omitted, does a C<chroot> to C<$_>.
912
913 Portability issues: L<perlport/chroot>.
914
915 =item close FILEHANDLE
916 X<close>
917
918 =item close
919
920 Closes the file or pipe associated with the filehandle, flushes the IO
921 buffers, and closes the system file descriptor.  Returns true if those
922 operations succeed and if no error was reported by any PerlIO
923 layer.  Closes the currently selected filehandle if the argument is
924 omitted.
925
926 You don't have to close FILEHANDLE if you are immediately going to do
927 another C<open> on it, because C<open> closes it for you.  (See
928 C<open>.)  However, an explicit C<close> on an input file resets the line
929 counter (C<$.>), while the implicit close done by C<open> does not.
930
931 If the filehandle came from a piped open, C<close> returns false if one of
932 the other syscalls involved fails or if its program exits with non-zero
933 status.  If the only problem was that the program exited non-zero, C<$!>
934 will be set to C<0>.  Closing a pipe also waits for the process executing
935 on the pipe to exit--in case you wish to look at the output of the pipe
936 afterwards--and implicitly puts the exit status value of that command into
937 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
938
939 If there are multiple threads running, C<close> on a filehandle from a
940 piped open returns true without waiting for the child process to terminate,
941 if the filehandle is still open in another thread.
942
943 Closing the read end of a pipe before the process writing to it at the
944 other end is done writing results in the writer receiving a SIGPIPE.  If
945 the other end can't handle that, be sure to read all the data before
946 closing the pipe.
947
948 Example:
949
950     open(OUTPUT, '|sort >foo')  # pipe to sort
951         or die "Can't start sort: $!";
952     #...                        # print stuff to output
953     close OUTPUT                # wait for sort to finish
954         or warn $! ? "Error closing sort pipe: $!"
955                    : "Exit status $? from sort";
956     open(INPUT, 'foo')          # get sort's results
957         or die "Can't open 'foo' for input: $!";
958
959 FILEHANDLE may be an expression whose value can be used as an indirect
960 filehandle, usually the real filehandle name or an autovivified handle.
961
962 =item closedir DIRHANDLE
963 X<closedir>
964
965 Closes a directory opened by C<opendir> and returns the success of that
966 system call.
967
968 =item connect SOCKET,NAME
969 X<connect>
970
971 Attempts to connect to a remote socket, just like connect(2).
972 Returns true if it succeeded, false otherwise.  NAME should be a
973 packed address of the appropriate type for the socket.  See the examples in
974 L<perlipc/"Sockets: Client/Server Communication">.
975
976 =item continue BLOCK
977 X<continue>
978
979 =item continue
980
981 C<continue> is actually a flow control statement rather than a function.  If
982 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
983 C<foreach>), it is always executed just before the conditional is about to
984 be evaluated again, just like the third part of a C<for> loop in C.  Thus
985 it can be used to increment a loop variable, even when the loop has been
986 continued via the C<next> statement (which is similar to the C C<continue>
987 statement).
988
989 C<last>, C<next>, or C<redo> may appear within a C<continue>
990 block; C<last> and C<redo> behave as if they had been executed within
991 the main block.  So will C<next>, but since it will execute a C<continue>
992 block, it may be more entertaining.
993
994     while (EXPR) {
995         ### redo always comes here
996         do_something;
997     } continue {
998         ### next always comes here
999         do_something_else;
1000         # then back the top to re-check EXPR
1001     }
1002     ### last always comes here
1003
1004 Omitting the C<continue> section is equivalent to using an
1005 empty one, logically enough, so C<next> goes directly back
1006 to check the condition at the top of the loop.
1007
1008 If the C<"switch"> feature is enabled, C<continue> is also a function that
1009 falls through the current C<when> or C<default> block instead of iterating
1010 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1011 See L<feature> and L<perlsyn/"Switch statements"> for more
1012 information.
1013
1014 =item cos EXPR
1015 X<cos> X<cosine> X<acos> X<arccosine>
1016
1017 =item cos
1018
1019 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1020 takes the cosine of C<$_>.
1021
1022 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1023 function, or use this relation:
1024
1025     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1026
1027 =item crypt PLAINTEXT,SALT
1028 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1029 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1030
1031 Creates a digest string exactly like the crypt(3) function in the C
1032 library (assuming that you actually have a version there that has not
1033 been extirpated as a potential munition).
1034
1035 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1036 into a short string, called a digest, which is returned.  The same
1037 PLAINTEXT and SALT will always return the same string, but there is no
1038 (known) way to get the original PLAINTEXT from the hash.  Small
1039 changes in the PLAINTEXT or SALT will result in large changes in the
1040 digest.
1041
1042 There is no decrypt function.  This function isn't all that useful for
1043 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1044 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1045 primarily used to check if two pieces of text are the same without
1046 having to transmit or store the text itself.  An example is checking
1047 if a correct password is given.  The digest of the password is stored,
1048 not the password itself.  The user types in a password that is
1049 crypt()'d with the same salt as the stored digest.  If the two digests
1050 match, the password is correct.
1051
1052 When verifying an existing digest string you should use the digest as
1053 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1054 to create the digest is visible as part of the digest.  This ensures
1055 crypt() will hash the new string with the same salt as the digest.
1056 This allows your code to work with the standard L<crypt|/crypt> and
1057 with more exotic implementations.  In other words, assume
1058 nothing about the returned string itself nor about how many bytes 
1059 of SALT may matter.
1060
1061 Traditionally the result is a string of 13 bytes: two first bytes of
1062 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1063 the first eight bytes of PLAINTEXT mattered. But alternative
1064 hashing schemes (like MD5), higher level security schemes (like C2),
1065 and implementations on non-Unix platforms may produce different
1066 strings.
1067
1068 When choosing a new salt create a random two character string whose
1069 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1070 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1071 characters is just a recommendation; the characters allowed in
1072 the salt depend solely on your system's crypt library, and Perl can't
1073 restrict what salts C<crypt()> accepts.
1074
1075 Here's an example that makes sure that whoever runs this program knows
1076 their password:
1077
1078     $pwd = (getpwuid($<))[1];
1079
1080     system "stty -echo";
1081     print "Password: ";
1082     chomp($word = <STDIN>);
1083     print "\n";
1084     system "stty echo";
1085
1086     if (crypt($word, $pwd) ne $pwd) {
1087         die "Sorry...\n";
1088     } else {
1089         print "ok\n";
1090     }
1091
1092 Of course, typing in your own password to whoever asks you
1093 for it is unwise.
1094
1095 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1096 of data, not least of all because you can't get the information
1097 back.  Look at the L<Digest> module for more robust algorithms.
1098
1099 If using crypt() on a Unicode string (which I<potentially> has
1100 characters with codepoints above 255), Perl tries to make sense
1101 of the situation by trying to downgrade (a copy of)
1102 the string back to an eight-bit byte string before calling crypt()
1103 (on that copy).  If that works, good.  If not, crypt() dies with
1104 C<Wide character in crypt>.
1105
1106 Portability issues: L<perlport/crypt>.
1107
1108 =item dbmclose HASH
1109 X<dbmclose>
1110
1111 [This function has been largely superseded by the C<untie> function.]
1112
1113 Breaks the binding between a DBM file and a hash.
1114
1115 Portability issues: L<perlport/dbmclose>.
1116
1117 =item dbmopen HASH,DBNAME,MASK
1118 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1119
1120 [This function has been largely superseded by the C<tie> function.]
1121
1122 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1123 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1124 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1125 is the name of the database (without the F<.dir> or F<.pag> extension if
1126 any).  If the database does not exist, it is created with protection
1127 specified by MASK (as modified by the C<umask>).  If your system supports
1128 only the older DBM functions, you may make only one C<dbmopen> call in your
1129 program.  In older versions of Perl, if your system had neither DBM nor
1130 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1131 sdbm(3).
1132
1133 If you don't have write access to the DBM file, you can only read hash
1134 variables, not set them.  If you want to test whether you can write,
1135 either use file tests or try setting a dummy hash entry inside an C<eval> 
1136 to trap the error.
1137
1138 Note that functions such as C<keys> and C<values> may return huge lists
1139 when used on large DBM files.  You may prefer to use the C<each>
1140 function to iterate over large DBM files.  Example:
1141
1142     # print out history file offsets
1143     dbmopen(%HIST,'/usr/lib/news/history',0666);
1144     while (($key,$val) = each %HIST) {
1145         print $key, ' = ', unpack('L',$val), "\n";
1146     }
1147     dbmclose(%HIST);
1148
1149 See also L<AnyDBM_File> for a more general description of the pros and
1150 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1151 rich implementation.
1152
1153 You can control which DBM library you use by loading that library
1154 before you call dbmopen():
1155
1156     use DB_File;
1157     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1158         or die "Can't open netscape history file: $!";
1159
1160 Portability issues: L<perlport/dbmopen>.
1161
1162 =item default BLOCK
1163
1164 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1165 that's always true.  Only available after Perl 5.10, and only if the
1166 C<switch> feature has been requested.  See L</when>.
1167
1168 =item defined EXPR
1169 X<defined> X<undef> X<undefined>
1170
1171 =item defined
1172
1173 Returns a Boolean value telling whether EXPR has a value other than
1174 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1175 checked.
1176
1177 Many operations return C<undef> to indicate failure, end of file,
1178 system error, uninitialized variable, and other exceptional
1179 conditions.  This function allows you to distinguish C<undef> from
1180 other values.  (A simple Boolean test will not distinguish among
1181 C<undef>, zero, the empty string, and C<"0">, which are all equally
1182 false.)  Note that since C<undef> is a valid scalar, its presence
1183 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1184 returns C<undef> when its argument is an empty array, I<or> when the
1185 element to return happens to be C<undef>.
1186
1187 You may also use C<defined(&func)> to check whether subroutine C<&func>
1188 has ever been defined.  The return value is unaffected by any forward
1189 declarations of C<&func>.  A subroutine that is not defined
1190 may still be callable: its package may have an C<AUTOLOAD> method that
1191 makes it spring into existence the first time that it is called; see
1192 L<perlsub>.
1193
1194 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1195 used to report whether memory for that aggregate had ever been
1196 allocated.  This behavior may disappear in future versions of Perl.
1197 You should instead use a simple test for size:
1198
1199     if (@an_array) { print "has array elements\n" }
1200     if (%a_hash)   { print "has hash members\n"   }
1201
1202 When used on a hash element, it tells you whether the value is defined,
1203 not whether the key exists in the hash.  Use L</exists> for the latter
1204 purpose.
1205
1206 Examples:
1207
1208     print if defined $switch{D};
1209     print "$val\n" while defined($val = pop(@ary));
1210     die "Can't readlink $sym: $!"
1211         unless defined($value = readlink $sym);
1212     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1213     $debugging = 0 unless defined $debugging;
1214
1215 Note:  Many folks tend to overuse C<defined> and are then surprised to
1216 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1217 defined values.  For example, if you say
1218
1219     "ab" =~ /a(.*)b/;
1220
1221 The pattern match succeeds and C<$1> is defined, although it
1222 matched "nothing".  It didn't really fail to match anything.  Rather, it
1223 matched something that happened to be zero characters long.  This is all
1224 very above-board and honest.  When a function returns an undefined value,
1225 it's an admission that it couldn't give you an honest answer.  So you
1226 should use C<defined> only when questioning the integrity of what
1227 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1228 what you want.
1229
1230 See also L</undef>, L</exists>, L</ref>.
1231
1232 =item delete EXPR
1233 X<delete>
1234
1235 Given an expression that specifies an element or slice of a hash, C<delete>
1236 deletes the specified elements from that hash so that exists() on that element
1237 no longer returns true.  Setting a hash element to the undefined value does
1238 not remove its key, but deleting it does; see L</exists>.
1239
1240 In list context, returns the value or values deleted, or the last such
1241 element in scalar context.  The return list's length always matches that of
1242 the argument list: deleting non-existent elements returns the undefined value
1243 in their corresponding positions.
1244
1245 delete() may also be used on arrays and array slices, but its behavior is less
1246 straightforward.  Although exists() will return false for deleted entries,
1247 deleting array elements never changes indices of existing values; use shift()
1248 or splice() for that.  However, if all deleted elements fall at the end of an
1249 array, the array's size shrinks to the position of the highest element that
1250 still tests true for exists(), or to 0 if none do.
1251
1252 B<WARNING:> Calling delete on array values is deprecated and likely to
1253 be removed in a future version of Perl.
1254
1255 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1256 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1257 or array may not necessarily return anything; it depends on the implementation
1258 of the C<tied> package's DELETE method, which may do whatever it pleases.
1259
1260 The C<delete local EXPR> construct localizes the deletion to the current
1261 block at run time.  Until the block exits, elements locally deleted
1262 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1263 of composite types">.
1264
1265     %hash = (foo => 11, bar => 22, baz => 33);
1266     $scalar = delete $hash{foo};             # $scalar is 11
1267     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1268     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1269
1270 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1271
1272     foreach $key (keys %HASH) {
1273         delete $HASH{$key};
1274     }
1275
1276     foreach $index (0 .. $#ARRAY) {
1277         delete $ARRAY[$index];
1278     }
1279
1280 And so do these:
1281
1282     delete @HASH{keys %HASH};
1283
1284     delete @ARRAY[0 .. $#ARRAY];
1285
1286 But both are slower than assigning the empty list
1287 or undefining %HASH or @ARRAY, which is the customary 
1288 way to empty out an aggregate:
1289
1290     %HASH = ();     # completely empty %HASH
1291     undef %HASH;    # forget %HASH ever existed
1292
1293     @ARRAY = ();    # completely empty @ARRAY
1294     undef @ARRAY;   # forget @ARRAY ever existed
1295
1296 The EXPR can be arbitrarily complicated provided its
1297 final operation is an element or slice of an aggregate:
1298
1299     delete $ref->[$x][$y]{$key};
1300     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1301
1302     delete $ref->[$x][$y][$index];
1303     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1304
1305 =item die LIST
1306 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1307
1308 C<die> raises an exception. Inside an C<eval> the error message is stuffed
1309 into C<$@> and the C<eval> is terminated with the undefined value.
1310 If the exception is outside of all enclosing C<eval>s, then the uncaught
1311 exception prints LIST to C<STDERR> and exits with a non-zero value. If you
1312 need to exit the process with a specific exit code, see L</exit>.
1313
1314 Equivalent examples:
1315
1316     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1317     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1318
1319 If the last element of LIST does not end in a newline, the current
1320 script line number and input line number (if any) are also printed,
1321 and a newline is supplied.  Note that the "input line number" (also
1322 known as "chunk") is subject to whatever notion of "line" happens to
1323 be currently in effect, and is also available as the special variable
1324 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1325
1326 Hint: sometimes appending C<", stopped"> to your message will cause it
1327 to make better sense when the string C<"at foo line 123"> is appended.
1328 Suppose you are running script "canasta".
1329
1330     die "/etc/games is no good";
1331     die "/etc/games is no good, stopped";
1332
1333 produce, respectively
1334
1335     /etc/games is no good at canasta line 123.
1336     /etc/games is no good, stopped at canasta line 123.
1337
1338 If the output is empty and C<$@> already contains a value (typically from a
1339 previous eval) that value is reused after appending C<"\t...propagated">.
1340 This is useful for propagating exceptions:
1341
1342     eval { ... };
1343     die unless $@ =~ /Expected exception/;
1344
1345 If the output is empty and C<$@> contains an object reference that has a
1346 C<PROPAGATE> method, that method will be called with additional file
1347 and line number parameters.  The return value replaces the value in
1348 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1349 were called.
1350
1351 If C<$@> is empty then the string C<"Died"> is used.
1352
1353 If an uncaught exception results in interpreter exit, the exit code is
1354 determined from the values of C<$!> and C<$?> with this pseudocode:
1355
1356     exit $! if $!;              # errno
1357     exit $? >> 8 if $? >> 8;    # child exit status
1358     exit 255;                   # last resort
1359
1360 The intent is to squeeze as much possible information about the likely cause
1361 into the limited space of the system exit code. However, as C<$!> is the value
1362 of C's C<errno>, which can be set by any system call, this means that the value
1363 of the exit code used by C<die> can be non-predictable, so should not be relied
1364 upon, other than to be non-zero.
1365
1366 You can also call C<die> with a reference argument, and if this is trapped
1367 within an C<eval>, C<$@> contains that reference.  This permits more
1368 elaborate exception handling using objects that maintain arbitrary state
1369 about the exception.  Such a scheme is sometimes preferable to matching
1370 particular string values of C<$@> with regular expressions.  Because C<$@> 
1371 is a global variable and C<eval> may be used within object implementations,
1372 be careful that analyzing the error object doesn't replace the reference in
1373 the global variable.  It's easiest to make a local copy of the reference
1374 before any manipulations.  Here's an example:
1375
1376     use Scalar::Util "blessed";
1377
1378     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1379     if (my $ev_err = $@) {
1380         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1381             # handle Some::Module::Exception
1382         }
1383         else {
1384             # handle all other possible exceptions
1385         }
1386     }
1387
1388 Because Perl stringifies uncaught exception messages before display,
1389 you'll probably want to overload stringification operations on
1390 exception objects.  See L<overload> for details about that.
1391
1392 You can arrange for a callback to be run just before the C<die>
1393 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1394 handler is called with the error text and can change the error
1395 message, if it sees fit, by calling C<die> again.  See
1396 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1397 L<"eval BLOCK"> for some examples.  Although this feature was 
1398 to be run only right before your program was to exit, this is not
1399 currently so: the C<$SIG{__DIE__}> hook is currently called
1400 even inside eval()ed blocks/strings!  If one wants the hook to do
1401 nothing in such situations, put
1402
1403     die @_ if $^S;
1404
1405 as the first line of the handler (see L<perlvar/$^S>).  Because
1406 this promotes strange action at a distance, this counterintuitive
1407 behavior may be fixed in a future release.
1408
1409 See also exit(), warn(), and the Carp module.
1410
1411 =item do BLOCK
1412 X<do> X<block>
1413
1414 Not really a function.  Returns the value of the last command in the
1415 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1416 C<until> loop modifier, executes the BLOCK once before testing the loop
1417 condition. (On other statements the loop modifiers test the conditional
1418 first.)
1419
1420 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1421 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1422 See L<perlsyn> for alternative strategies.
1423
1424 =item do SUBROUTINE(LIST)
1425 X<do>
1426
1427 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1428 a scalar variable or a subroutine beginning with C<&>.
1429
1430 =item do EXPR
1431 X<do>
1432
1433 Uses the value of EXPR as a filename and executes the contents of the
1434 file as a Perl script.
1435
1436     do 'stat.pl';
1437
1438 is just like
1439
1440     eval `cat stat.pl`;
1441
1442 except that it's more efficient and concise, keeps track of the current
1443 filename for error messages, searches the C<@INC> directories, and updates
1444 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1445 these variables.  It also differs in that code evaluated with C<do FILENAME>
1446 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1447 same, however, in that it does reparse the file every time you call it,
1448 so you probably don't want to do this inside a loop.
1449
1450 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1451 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1452 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1453 could fail in a way that also sets C<$!>.  If the file is successfully
1454 compiled, C<do> returns the value of the last expression evaluated.
1455
1456 Inclusion of library modules is better done with the
1457 C<use> and C<require> operators, which also do automatic error checking
1458 and raise an exception if there's a problem.
1459
1460 You might like to use C<do> to read in a program configuration
1461 file.  Manual error checking can be done this way:
1462
1463     # read in config files: system first, then user
1464     for $file ("/share/prog/defaults.rc",
1465                "$ENV{HOME}/.someprogrc")
1466     {
1467         unless ($return = do $file) {
1468             warn "couldn't parse $file: $@" if $@;
1469             warn "couldn't do $file: $!"    unless defined $return;
1470             warn "couldn't run $file"       unless $return;
1471         }
1472     }
1473
1474 =item dump LABEL
1475 X<dump> X<core> X<undump>
1476
1477 =item dump
1478
1479 This function causes an immediate core dump.  See also the B<-u>
1480 command-line switch in L<perlrun>, which does the same thing.
1481 Primarily this is so that you can use the B<undump> program (not
1482 supplied) to turn your core dump into an executable binary after
1483 having initialized all your variables at the beginning of the
1484 program.  When the new binary is executed it will begin by executing
1485 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1486 Think of it as a goto with an intervening core dump and reincarnation.
1487 If C<LABEL> is omitted, restarts the program from the top.
1488
1489 B<WARNING>: Any files opened at the time of the dump will I<not>
1490 be open any more when the program is reincarnated, with possible
1491 resulting confusion by Perl.
1492
1493 This function is now largely obsolete, mostly because it's very hard to
1494 convert a core file into an executable. That's why you should now invoke
1495 it as C<CORE::dump()>, if you don't want to be warned against a possible
1496 typo.
1497
1498 Portability issues: L<perlport/dump>.
1499
1500 =item each HASH
1501 X<each> X<hash, iterator>
1502
1503 =item each ARRAY
1504 X<array, iterator>
1505
1506 =item each EXPR
1507
1508 When called in list context, returns a 2-element list consisting of the key
1509 and value for the next element of a hash, or the index and value for the
1510 next element of an array, so that you can iterate over it.  When called in
1511 scalar context, returns only the key (not the value) in a hash, or the index
1512 in an array.
1513
1514 Hash entries are returned in an apparently random order.  The actual random
1515 order is subject to change in future versions of Perl, but it is
1516 guaranteed to be in the same order as either the C<keys> or C<values>
1517 function would produce on the same (unmodified) hash.  Since Perl
1518 5.8.2 the ordering can be different even between different runs of Perl
1519 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1520
1521 After C<each> has returned all entries from the hash or array, the next
1522 call to C<each> returns the empty list in list context and C<undef> in
1523 scalar context.  The next call following that one restarts iteration.  Each
1524 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1525 and C<values>.  The iterator is implicitly reset when C<each> has reached
1526 the end as just described; it can be explicitly reset by calling C<keys> or
1527 C<values> on the hash or array.  If you add or delete a hash's elements
1528 while iterating over it, entries may be skipped or duplicated--so don't do
1529 that.  Exception: It is always safe to delete the item most recently
1530 returned by C<each()>, so the following code works properly:
1531
1532         while (($key, $value) = each %hash) {
1533           print $key, "\n";
1534           delete $hash{$key};   # This is safe
1535         }
1536
1537 This prints out your environment like the printenv(1) program,
1538 but in a different order:
1539
1540     while (($key,$value) = each %ENV) {
1541         print "$key=$value\n";
1542     }
1543
1544 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1545 reference to an unblessed hash or array.  The argument will be dereferenced
1546 automatically.  This aspect of C<each> is considered highly experimental.
1547 The exact behaviour may change in a future version of Perl.
1548
1549     while (($key,$value) = each $hashref) { ... }
1550
1551 See also C<keys>, C<values>, and C<sort>.
1552
1553 =item eof FILEHANDLE
1554 X<eof>
1555 X<end of file>
1556 X<end-of-file>
1557
1558 =item eof ()
1559
1560 =item eof
1561
1562 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1563 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1564 gives the real filehandle.  (Note that this function actually
1565 reads a character and then C<ungetc>s it, so isn't useful in an
1566 interactive context.)  Do not read from a terminal file (or call
1567 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1568 as terminals may lose the end-of-file condition if you do.
1569
1570 An C<eof> without an argument uses the last file read.  Using C<eof()>
1571 with empty parentheses is different.  It refers to the pseudo file
1572 formed from the files listed on the command line and accessed via the
1573 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1574 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1575 used will cause C<@ARGV> to be examined to determine if input is
1576 available.   Similarly, an C<eof()> after C<< <> >> has returned
1577 end-of-file will assume you are processing another C<@ARGV> list,
1578 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1579 see L<perlop/"I/O Operators">.
1580
1581 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1582 detect the end of each file, whereas C<eof()> will detect the end 
1583 of the very last file only.  Examples:
1584
1585     # reset line numbering on each input file
1586     while (<>) {
1587         next if /^\s*#/;  # skip comments
1588         print "$.\t$_";
1589     } continue {
1590         close ARGV if eof;  # Not eof()!
1591     }
1592
1593     # insert dashes just before last line of last file
1594     while (<>) {
1595         if (eof()) {  # check for end of last file
1596             print "--------------\n";
1597         }
1598         print;
1599         last if eof();          # needed if we're reading from a terminal
1600     }
1601
1602 Practical hint: you almost never need to use C<eof> in Perl, because the
1603 input operators typically return C<undef> when they run out of data or 
1604 encounter an error.
1605
1606 =item eval EXPR
1607 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1608 X<error, handling> X<exception, handling>
1609
1610 =item eval BLOCK
1611
1612 =item eval
1613
1614 In the first form, the return value of EXPR is parsed and executed as if it
1615 were a little Perl program.  The value of the expression (which is itself
1616 determined within scalar context) is first parsed, and if there were no
1617 errors, executed as a block within the lexical context of the current Perl
1618 program. This means, that in particular, any outer lexical variables are
1619 visible to it, and any package variable settings or subroutine and format
1620 definitions remain afterwards.
1621
1622 Note that the value is parsed every time the C<eval> executes.
1623 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1624 delay parsing and subsequent execution of the text of EXPR until run time.
1625
1626 In the second form, the code within the BLOCK is parsed only once--at the
1627 same time the code surrounding the C<eval> itself was parsed--and executed
1628 within the context of the current Perl program.  This form is typically
1629 used to trap exceptions more efficiently than the first (see below), while
1630 also providing the benefit of checking the code within BLOCK at compile
1631 time.
1632
1633 The final semicolon, if any, may be omitted from the value of EXPR or within
1634 the BLOCK.
1635
1636 In both forms, the value returned is the value of the last expression
1637 evaluated inside the mini-program; a return statement may be also used, just
1638 as with subroutines.  The expression providing the return value is evaluated
1639 in void, scalar, or list context, depending on the context of the C<eval> 
1640 itself.  See L</wantarray> for more on how the evaluation context can be 
1641 determined.
1642
1643 If there is a syntax error or runtime error, or a C<die> statement is
1644 executed, C<eval> returns C<undef> in scalar context
1645 or an empty list--or, for syntax errors, a list containing a single
1646 undefined value--in list context, and C<$@> is set to the error
1647 message.  The discrepancy in the return values in list context is
1648 considered a bug by some, and will probably be fixed in a future
1649 release.  If there was no error, C<$@> is guaranteed to be the empty
1650 string.  Beware that using C<eval> neither silences Perl from printing
1651 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1652 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1653 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1654 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1655
1656 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1657 determining whether a particular feature (such as C<socket> or C<symlink>)
1658 is implemented.  It is also Perl's exception-trapping mechanism, where
1659 the die operator is used to raise exceptions.
1660
1661 If you want to trap errors when loading an XS module, some problems with
1662 the binary interface (such as Perl version skew) may be fatal even with
1663 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1664
1665 If the code to be executed doesn't vary, you may use the eval-BLOCK
1666 form to trap run-time errors without incurring the penalty of
1667 recompiling each time.  The error, if any, is still returned in C<$@>.
1668 Examples:
1669
1670     # make divide-by-zero nonfatal
1671     eval { $answer = $a / $b; }; warn $@ if $@;
1672
1673     # same thing, but less efficient
1674     eval '$answer = $a / $b'; warn $@ if $@;
1675
1676     # a compile-time error
1677     eval { $answer = }; # WRONG
1678
1679     # a run-time error
1680     eval '$answer =';   # sets $@
1681
1682 Using the C<eval{}> form as an exception trap in libraries does have some
1683 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1684 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1685 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1686 as this example shows:
1687
1688     # a private exception trap for divide-by-zero
1689     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1690     warn $@ if $@;
1691
1692 This is especially significant, given that C<__DIE__> hooks can call
1693 C<die> again, which has the effect of changing their error messages:
1694
1695     # __DIE__ hooks may modify error messages
1696     {
1697        local $SIG{'__DIE__'} =
1698               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1699        eval { die "foo lives here" };
1700        print $@ if $@;                # prints "bar lives here"
1701     }
1702
1703 Because this promotes action at a distance, this counterintuitive behavior
1704 may be fixed in a future release.
1705
1706 With an C<eval>, you should be especially careful to remember what's
1707 being looked at when:
1708
1709     eval $x;        # CASE 1
1710     eval "$x";      # CASE 2
1711
1712     eval '$x';      # CASE 3
1713     eval { $x };    # CASE 4
1714
1715     eval "\$$x++";  # CASE 5
1716     $$x++;          # CASE 6
1717
1718 Cases 1 and 2 above behave identically: they run the code contained in
1719 the variable $x.  (Although case 2 has misleading double quotes making
1720 the reader wonder what else might be happening (nothing is).)  Cases 3
1721 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1722 does nothing but return the value of $x.  (Case 4 is preferred for
1723 purely visual reasons, but it also has the advantage of compiling at
1724 compile-time instead of at run-time.)  Case 5 is a place where
1725 normally you I<would> like to use double quotes, except that in this
1726 particular situation, you can just use symbolic references instead, as
1727 in case 6.
1728
1729 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1730 of localised variables, which means that for your code to run on older
1731 versions, a temporary is required if you want to mask some but not all
1732 errors:
1733
1734     # alter $@ on nefarious repugnancy only
1735     {
1736        my $e;
1737        {
1738           local $@; # protect existing $@
1739           eval { test_repugnancy() };
1740           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1741           $@ =~ /nefarious/ and $e = $@;
1742        }
1743        die $e if defined $e
1744     }
1745
1746 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1747 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1748
1749 An C<eval ''> executed within the C<DB> package doesn't see the usual
1750 surrounding lexical scope, but rather the scope of the first non-DB piece
1751 of code that called it. You don't normally need to worry about this unless
1752 you are writing a Perl debugger.
1753
1754 =item exec LIST
1755 X<exec> X<execute>
1756
1757 =item exec PROGRAM LIST
1758
1759 The C<exec> function executes a system command I<and never returns>;
1760 use C<system> instead of C<exec> if you want it to return.  It fails and
1761 returns false only if the command does not exist I<and> it is executed
1762 directly instead of via your system's command shell (see below).
1763
1764 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1765 warns you if there is a following statement that isn't C<die>, C<warn>,
1766 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1767 I<really> want to follow an C<exec> with some other statement, you
1768 can use one of these styles to avoid the warning:
1769
1770     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1771     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1772
1773 If there is more than one argument in LIST, or if LIST is an array
1774 with more than one value, calls execvp(3) with the arguments in LIST.
1775 If there is only one scalar argument or an array with one element in it,
1776 the argument is checked for shell metacharacters, and if there are any,
1777 the entire argument is passed to the system's command shell for parsing
1778 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1779 If there are no shell metacharacters in the argument, it is split into
1780 words and passed directly to C<execvp>, which is more efficient.
1781 Examples:
1782
1783     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1784     exec "sort $outfile | uniq";
1785
1786 If you don't really want to execute the first argument, but want to lie
1787 to the program you are executing about its own name, you can specify
1788 the program you actually want to run as an "indirect object" (without a
1789 comma) in front of the LIST.  (This always forces interpretation of the
1790 LIST as a multivalued list, even if there is only a single scalar in
1791 the list.)  Example:
1792
1793     $shell = '/bin/csh';
1794     exec $shell '-sh';    # pretend it's a login shell
1795
1796 or, more directly,
1797
1798     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1799
1800 When the arguments get executed via the system shell, results are
1801 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1802 for details.
1803
1804 Using an indirect object with C<exec> or C<system> is also more
1805 secure.  This usage (which also works fine with system()) forces
1806 interpretation of the arguments as a multivalued list, even if the
1807 list had just one argument.  That way you're safe from the shell
1808 expanding wildcards or splitting up words with whitespace in them.
1809
1810     @args = ( "echo surprise" );
1811
1812     exec @args;               # subject to shell escapes
1813                                 # if @args == 1
1814     exec { $args[0] } @args;  # safe even with one-arg list
1815
1816 The first version, the one without the indirect object, ran the I<echo>
1817 program, passing it C<"surprise"> an argument.  The second version didn't;
1818 it tried to run a program named I<"echo surprise">, didn't find it, and set
1819 C<$?> to a non-zero value indicating failure.
1820
1821 Beginning with v5.6.0, Perl attempts to flush all files opened for
1822 output before the exec, but this may not be supported on some platforms
1823 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1824 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1825 open handles to avoid lost output.
1826
1827 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1828 C<DESTROY> methods on your objects.
1829
1830 Portability issues: L<perlport/exec>.
1831
1832 =item exists EXPR
1833 X<exists> X<autovivification>
1834
1835 Given an expression that specifies an element of a hash, returns true if the
1836 specified element in the hash has ever been initialized, even if the
1837 corresponding value is undefined.
1838
1839     print "Exists\n"    if exists $hash{$key};
1840     print "Defined\n"   if defined $hash{$key};
1841     print "True\n"      if $hash{$key};
1842
1843 exists may also be called on array elements, but its behavior is much less
1844 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1845 that calling exists on array values is deprecated and likely to be removed in
1846 a future version of Perl.
1847
1848     print "Exists\n"    if exists $array[$index];
1849     print "Defined\n"   if defined $array[$index];
1850     print "True\n"      if $array[$index];
1851
1852 A hash or array element can be true only if it's defined and defined only if
1853 it exists, but the reverse doesn't necessarily hold true.
1854
1855 Given an expression that specifies the name of a subroutine,
1856 returns true if the specified subroutine has ever been declared, even
1857 if it is undefined.  Mentioning a subroutine name for exists or defined
1858 does not count as declaring it.  Note that a subroutine that does not
1859 exist may still be callable: its package may have an C<AUTOLOAD>
1860 method that makes it spring into existence the first time that it is
1861 called; see L<perlsub>.
1862
1863     print "Exists\n"  if exists &subroutine;
1864     print "Defined\n" if defined &subroutine;
1865
1866 Note that the EXPR can be arbitrarily complicated as long as the final
1867 operation is a hash or array key lookup or subroutine name:
1868
1869     if (exists $ref->{A}->{B}->{$key})  { }
1870     if (exists $hash{A}{B}{$key})       { }
1871
1872     if (exists $ref->{A}->{B}->[$ix])   { }
1873     if (exists $hash{A}{B}[$ix])        { }
1874
1875     if (exists &{$ref->{A}{B}{$key}})   { }
1876
1877 Although the mostly deeply nested array or hash will not spring into
1878 existence just because its existence was tested, any intervening ones will.
1879 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1880 into existence due to the existence test for the $key element above.
1881 This happens anywhere the arrow operator is used, including even here:
1882
1883     undef $ref;
1884     if (exists $ref->{"Some key"})    { }
1885     print $ref;  # prints HASH(0x80d3d5c)
1886
1887 This surprising autovivification in what does not at first--or even
1888 second--glance appear to be an lvalue context may be fixed in a future
1889 release.
1890
1891 Use of a subroutine call, rather than a subroutine name, as an argument
1892 to exists() is an error.
1893
1894     exists &sub;    # OK
1895     exists &sub();  # Error
1896
1897 =item exit EXPR
1898 X<exit> X<terminate> X<abort>
1899
1900 =item exit
1901
1902 Evaluates EXPR and exits immediately with that value.    Example:
1903
1904     $ans = <STDIN>;
1905     exit 0 if $ans =~ /^[Xx]/;
1906
1907 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1908 universally recognized values for EXPR are C<0> for success and C<1>
1909 for error; other values are subject to interpretation depending on the
1910 environment in which the Perl program is running.  For example, exiting
1911 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1912 the mailer to return the item undelivered, but that's not true everywhere.
1913
1914 Don't use C<exit> to abort a subroutine if there's any chance that
1915 someone might want to trap whatever error happened.  Use C<die> instead,
1916 which can be trapped by an C<eval>.
1917
1918 The exit() function does not always exit immediately.  It calls any
1919 defined C<END> routines first, but these C<END> routines may not
1920 themselves abort the exit.  Likewise any object destructors that need to
1921 be called are called before the real exit.  C<END> routines and destructors
1922 can change the exit status by modifying C<$?>. If this is a problem, you
1923 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1924 See L<perlmod> for details.
1925
1926 Portability issues: L<perlport/exit>.
1927
1928 =item exp EXPR
1929 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1930
1931 =item exp
1932
1933 Returns I<e> (the natural logarithm base) to the power of EXPR.
1934 If EXPR is omitted, gives C<exp($_)>.
1935
1936 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1937 X<fcntl>
1938
1939 Implements the fcntl(2) function.  You'll probably have to say
1940
1941     use Fcntl;
1942
1943 first to get the correct constant definitions.  Argument processing and
1944 value returned work just like C<ioctl> below.
1945 For example:
1946
1947     use Fcntl;
1948     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1949         or die "can't fcntl F_GETFL: $!";
1950
1951 You don't have to check for C<defined> on the return from C<fcntl>.
1952 Like C<ioctl>, it maps a C<0> return from the system call into
1953 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1954 in numeric context.  It is also exempt from the normal B<-w> warnings
1955 on improper numeric conversions.
1956
1957 Note that C<fcntl> raises an exception if used on a machine that
1958 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1959 manpage to learn what functions are available on your system.
1960
1961 Here's an example of setting a filehandle named C<REMOTE> to be
1962 non-blocking at the system level.  You'll have to negotiate C<$|>
1963 on your own, though.
1964
1965     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1966
1967     $flags = fcntl(REMOTE, F_GETFL, 0)
1968                 or die "Can't get flags for the socket: $!\n";
1969
1970     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1971                 or die "Can't set flags for the socket: $!\n";
1972
1973 Portability issues: L<perlport/fcntl>.
1974
1975 =item fileno FILEHANDLE
1976 X<fileno>
1977
1978 Returns the file descriptor for a filehandle, or undefined if the
1979 filehandle is not open.  If there is no real file descriptor at the OS
1980 level, as can happen with filehandles connected to memory objects via
1981 C<open> with a reference for the third argument, -1 is returned.
1982
1983 This is mainly useful for constructing
1984 bitmaps for C<select> and low-level POSIX tty-handling operations.
1985 If FILEHANDLE is an expression, the value is taken as an indirect
1986 filehandle, generally its name.
1987
1988 You can use this to find out whether two handles refer to the
1989 same underlying descriptor:
1990
1991     if (fileno(THIS) == fileno(THAT)) {
1992         print "THIS and THAT are dups\n";
1993     }
1994
1995 =item flock FILEHANDLE,OPERATION
1996 X<flock> X<lock> X<locking>
1997
1998 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1999 for success, false on failure.  Produces a fatal error if used on a
2000 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2001 C<flock> is Perl's portable file-locking interface, although it locks
2002 entire files only, not records.
2003
2004 Two potentially non-obvious but traditional C<flock> semantics are
2005 that it waits indefinitely until the lock is granted, and that its locks
2006 are B<merely advisory>.  Such discretionary locks are more flexible, but
2007 offer fewer guarantees.  This means that programs that do not also use
2008 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2009 your port's specific documentation, and your system-specific local manpages
2010 for details.  It's best to assume traditional behavior if you're writing
2011 portable programs.  (But if you're not, you should as always feel perfectly
2012 free to write for your own system's idiosyncrasies (sometimes called
2013 "features").  Slavish adherence to portability concerns shouldn't get
2014 in the way of your getting your job done.)
2015
2016 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2017 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2018 you can use the symbolic names if you import them from the L<Fcntl> module,
2019 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2020 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2021 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2022 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2023 waiting for the lock; check the return status to see if you got it.
2024
2025 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2026 before locking or unlocking it.
2027
2028 Note that the emulation built with lockf(3) doesn't provide shared
2029 locks, and it requires that FILEHANDLE be open with write intent.  These
2030 are the semantics that lockf(3) implements.  Most if not all systems
2031 implement lockf(3) in terms of fcntl(2) locking, though, so the
2032 differing semantics shouldn't bite too many people.
2033
2034 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2035 be open with read intent to use LOCK_SH and requires that it be open
2036 with write intent to use LOCK_EX.
2037
2038 Note also that some versions of C<flock> cannot lock things over the
2039 network; you would need to use the more system-specific C<fcntl> for
2040 that.  If you like you can force Perl to ignore your system's flock(2)
2041 function, and so provide its own fcntl(2)-based emulation, by passing
2042 the switch C<-Ud_flock> to the F<Configure> program when you configure
2043 and build a new Perl.
2044
2045 Here's a mailbox appender for BSD systems.
2046
2047     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2048
2049     sub lock {
2050         my ($fh) = @_;
2051         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2052
2053         # and, in case someone appended while we were waiting...
2054         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2055     }
2056
2057     sub unlock {
2058         my ($fh) = @_;
2059         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2060     }
2061
2062     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2063         or die "Can't open mailbox: $!";
2064
2065     lock($mbox);
2066     print $mbox $msg,"\n\n";
2067     unlock($mbox);
2068
2069 On systems that support a real flock(2), locks are inherited across fork()
2070 calls, whereas those that must resort to the more capricious fcntl(2)
2071 function lose their locks, making it seriously harder to write servers.
2072
2073 See also L<DB_File> for other flock() examples.
2074
2075 Portability issues: L<perlport/flock>.
2076
2077 =item fork
2078 X<fork> X<child> X<parent>
2079
2080 Does a fork(2) system call to create a new process running the
2081 same program at the same point.  It returns the child pid to the
2082 parent process, C<0> to the child process, or C<undef> if the fork is
2083 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2084 are shared, while everything else is copied.  On most systems supporting
2085 fork(), great care has gone into making it extremely efficient (for
2086 example, using copy-on-write technology on data pages), making it the
2087 dominant paradigm for multitasking over the last few decades.
2088
2089 Beginning with v5.6.0, Perl attempts to flush all files opened for
2090 output before forking the child process, but this may not be supported
2091 on some platforms (see L<perlport>).  To be safe, you may need to set
2092 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2093 C<IO::Handle> on any open handles to avoid duplicate output.
2094
2095 If you C<fork> without ever waiting on your children, you will
2096 accumulate zombies.  On some systems, you can avoid this by setting
2097 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2098 forking and reaping moribund children.
2099
2100 Note that if your forked child inherits system file descriptors like
2101 STDIN and STDOUT that are actually connected by a pipe or socket, even
2102 if you exit, then the remote server (such as, say, a CGI script or a
2103 backgrounded job launched from a remote shell) won't think you're done.
2104 You should reopen those to F</dev/null> if it's any issue.
2105
2106 On some platforms such as Windows, where the fork() system call is not available,
2107 Perl can be built to emulate fork() in the Perl interpreter. The emulation is designed to,
2108 at the level of the Perl program, be as compatible as possible with the "Unix" fork().
2109 However it has limitation that has to be considered in code intended to be portable.
2110 See L<perlfork> for more details.
2111
2112 Portability issues: L<perlport/fork>.
2113
2114 =item format
2115 X<format>
2116
2117 Declare a picture format for use by the C<write> function.  For
2118 example:
2119
2120     format Something =
2121         Test: @<<<<<<<< @||||| @>>>>>
2122               $str,     $%,    '$' . int($num)
2123     .
2124
2125     $str = "widget";
2126     $num = $cost/$quantity;
2127     $~ = 'Something';
2128     write;
2129
2130 See L<perlform> for many details and examples.
2131
2132 =item formline PICTURE,LIST
2133 X<formline>
2134
2135 This is an internal function used by C<format>s, though you may call it,
2136 too.  It formats (see L<perlform>) a list of values according to the
2137 contents of PICTURE, placing the output into the format output
2138 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2139 Eventually, when a C<write> is done, the contents of
2140 C<$^A> are written to some filehandle.  You could also read C<$^A>
2141 and then set C<$^A> back to C<"">.  Note that a format typically
2142 does one C<formline> per line of form, but the C<formline> function itself
2143 doesn't care how many newlines are embedded in the PICTURE.  This means
2144 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2145 You may therefore need to use multiple formlines to implement a single
2146 record format, just like the C<format> compiler.
2147
2148 Be careful if you put double quotes around the picture, because an C<@>
2149 character may be taken to mean the beginning of an array name.
2150 C<formline> always returns true.  See L<perlform> for other examples.
2151
2152 If you are trying to use this instead of C<write> to capture the output,
2153 you may find it easier to open a filehandle to a scalar
2154 (C<< open $fh, ">", \$output >>) and write to that instead.
2155
2156 =item getc FILEHANDLE
2157 X<getc> X<getchar> X<character> X<file, read>
2158
2159 =item getc
2160
2161 Returns the next character from the input file attached to FILEHANDLE,
2162 or the undefined value at end of file or if there was an error (in
2163 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2164 STDIN.  This is not particularly efficient.  However, it cannot be
2165 used by itself to fetch single characters without waiting for the user
2166 to hit enter.  For that, try something more like:
2167
2168     if ($BSD_STYLE) {
2169         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2170     }
2171     else {
2172         system "stty", '-icanon', 'eol', "\001";
2173     }
2174
2175     $key = getc(STDIN);
2176
2177     if ($BSD_STYLE) {
2178         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2179     }
2180     else {
2181         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2182     }
2183     print "\n";
2184
2185 Determination of whether $BSD_STYLE should be set
2186 is left as an exercise to the reader.
2187
2188 The C<POSIX::getattr> function can do this more portably on
2189 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2190 module from your nearest CPAN site; details on CPAN can be found under
2191 L<perlmodlib/CPAN>.
2192
2193 =item getlogin
2194 X<getlogin> X<login>
2195
2196 This implements the C library function of the same name, which on most
2197 systems returns the current login from F</etc/utmp>, if any.  If it
2198 returns the empty string, use C<getpwuid>.
2199
2200     $login = getlogin || getpwuid($<) || "Kilroy";
2201
2202 Do not consider C<getlogin> for authentication: it is not as
2203 secure as C<getpwuid>.
2204
2205 Portability issues: L<perlport/getlogin>.
2206
2207 =item getpeername SOCKET
2208 X<getpeername> X<peer>
2209
2210 Returns the packed sockaddr address of the other end of the SOCKET
2211 connection.
2212
2213     use Socket;
2214     $hersockaddr    = getpeername(SOCK);
2215     ($port, $iaddr) = sockaddr_in($hersockaddr);
2216     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2217     $herstraddr     = inet_ntoa($iaddr);
2218
2219 =item getpgrp PID
2220 X<getpgrp> X<group>
2221
2222 Returns the current process group for the specified PID.  Use
2223 a PID of C<0> to get the current process group for the
2224 current process.  Will raise an exception if used on a machine that
2225 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2226 group of the current process.  Note that the POSIX version of C<getpgrp>
2227 does not accept a PID argument, so only C<PID==0> is truly portable.
2228
2229 Portability issues: L<perlport/getpgrp>.
2230
2231 =item getppid
2232 X<getppid> X<parent> X<pid>
2233
2234 Returns the process id of the parent process.
2235
2236 Note for Linux users: on Linux, the C functions C<getpid()> and
2237 C<getppid()> return different values from different threads. In order to
2238 be portable, this behavior is not reflected by the Perl-level function
2239 C<getppid()>, that returns a consistent value across threads. If you want
2240 to call the underlying C<getppid()>, you may use the CPAN module
2241 C<Linux::Pid>.
2242
2243 Portability issues: L<perlport/getppid>.
2244
2245 =item getpriority WHICH,WHO
2246 X<getpriority> X<priority> X<nice>
2247
2248 Returns the current priority for a process, a process group, or a user.
2249 (See C<getpriority(2)>.)  Will raise a fatal exception if used on a
2250 machine that doesn't implement getpriority(2).
2251
2252 Portability issues: L<perlport/getpriority>.
2253
2254 =item getpwnam NAME
2255 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2256 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2257 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2258 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2259 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2260 X<endnetent> X<endprotoent> X<endservent> 
2261
2262 =item getgrnam NAME
2263
2264 =item gethostbyname NAME
2265
2266 =item getnetbyname NAME
2267
2268 =item getprotobyname NAME
2269
2270 =item getpwuid UID
2271
2272 =item getgrgid GID
2273
2274 =item getservbyname NAME,PROTO
2275
2276 =item gethostbyaddr ADDR,ADDRTYPE
2277
2278 =item getnetbyaddr ADDR,ADDRTYPE
2279
2280 =item getprotobynumber NUMBER
2281
2282 =item getservbyport PORT,PROTO
2283
2284 =item getpwent
2285
2286 =item getgrent
2287
2288 =item gethostent
2289
2290 =item getnetent
2291
2292 =item getprotoent
2293
2294 =item getservent
2295
2296 =item setpwent
2297
2298 =item setgrent
2299
2300 =item sethostent STAYOPEN
2301
2302 =item setnetent STAYOPEN
2303
2304 =item setprotoent STAYOPEN
2305
2306 =item setservent STAYOPEN
2307
2308 =item endpwent
2309
2310 =item endgrent
2311
2312 =item endhostent
2313
2314 =item endnetent
2315
2316 =item endprotoent
2317
2318 =item endservent
2319
2320 These routines are the same as their counterparts in the
2321 system C library.  In list context, the return values from the
2322 various get routines are as follows:
2323
2324     ($name,$passwd,$uid,$gid,
2325        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2326     ($name,$passwd,$gid,$members) = getgr*
2327     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2328     ($name,$aliases,$addrtype,$net) = getnet*
2329     ($name,$aliases,$proto) = getproto*
2330     ($name,$aliases,$port,$proto) = getserv*
2331
2332 (If the entry doesn't exist you get an empty list.)
2333
2334 The exact meaning of the $gcos field varies but it usually contains
2335 the real name of the user (as opposed to the login name) and other
2336 information pertaining to the user.  Beware, however, that in many
2337 system users are able to change this information and therefore it
2338 cannot be trusted and therefore the $gcos is tainted (see
2339 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2340 login shell, are also tainted, for the same reason.
2341
2342 In scalar context, you get the name, unless the function was a
2343 lookup by name, in which case you get the other thing, whatever it is.
2344 (If the entry doesn't exist you get the undefined value.)  For example:
2345
2346     $uid   = getpwnam($name);
2347     $name  = getpwuid($num);
2348     $name  = getpwent();
2349     $gid   = getgrnam($name);
2350     $name  = getgrgid($num);
2351     $name  = getgrent();
2352     #etc.
2353
2354 In I<getpw*()> the fields $quota, $comment, and $expire are special
2355 in that they are unsupported on many systems.  If the
2356 $quota is unsupported, it is an empty scalar.  If it is supported, it
2357 usually encodes the disk quota.  If the $comment field is unsupported,
2358 it is an empty scalar.  If it is supported it usually encodes some
2359 administrative comment about the user.  In some systems the $quota
2360 field may be $change or $age, fields that have to do with password
2361 aging.  In some systems the $comment field may be $class.  The $expire
2362 field, if present, encodes the expiration period of the account or the
2363 password.  For the availability and the exact meaning of these fields
2364 in your system, please consult getpwnam(3) and your system's 
2365 F<pwd.h> file.  You can also find out from within Perl what your
2366 $quota and $comment fields mean and whether you have the $expire field
2367 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2368 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2369 files are supported only if your vendor has implemented them in the
2370 intuitive fashion that calling the regular C library routines gets the
2371 shadow versions if you're running under privilege or if there exists
2372 the shadow(3) functions as found in System V (this includes Solaris
2373 and Linux).  Those systems that implement a proprietary shadow password
2374 facility are unlikely to be supported.
2375
2376 The $members value returned by I<getgr*()> is a space-separated list of
2377 the login names of the members of the group.
2378
2379 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2380 C, it will be returned to you via C<$?> if the function call fails.  The
2381 C<@addrs> value returned by a successful call is a list of raw
2382 addresses returned by the corresponding library call.  In the
2383 Internet domain, each address is four bytes long; you can unpack it
2384 by saying something like:
2385
2386     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2387
2388 The Socket library makes this slightly easier:
2389
2390     use Socket;
2391     $iaddr = inet_aton("127.1"); # or whatever address
2392     $name  = gethostbyaddr($iaddr, AF_INET);
2393
2394     # or going the other way
2395     $straddr = inet_ntoa($iaddr);
2396
2397 In the opposite way, to resolve a hostname to the IP address
2398 you can write this:
2399
2400     use Socket;
2401     $packed_ip = gethostbyname("www.perl.org");
2402     if (defined $packed_ip) {
2403         $ip_address = inet_ntoa($packed_ip);
2404     }
2405
2406 Make sure <gethostbyname()> is called in SCALAR context and that
2407 its return value is checked for definedness.
2408
2409 If you get tired of remembering which element of the return list
2410 contains which return value, by-name interfaces are provided
2411 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2412 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2413 and C<User::grent>.  These override the normal built-ins, supplying
2414 versions that return objects with the appropriate names
2415 for each field.  For example:
2416
2417    use File::stat;
2418    use User::pwent;
2419    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2420
2421 Even though it looks as though they're the same method calls (uid),
2422 they aren't, because a C<File::stat> object is different from
2423 a C<User::pwent> object.
2424
2425 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2426
2427 =item getsockname SOCKET
2428 X<getsockname>
2429
2430 Returns the packed sockaddr address of this end of the SOCKET connection,
2431 in case you don't know the address because you have several different
2432 IPs that the connection might have come in on.
2433
2434     use Socket;
2435     $mysockaddr = getsockname(SOCK);
2436     ($port, $myaddr) = sockaddr_in($mysockaddr);
2437     printf "Connect to %s [%s]\n",
2438        scalar gethostbyaddr($myaddr, AF_INET),
2439        inet_ntoa($myaddr);
2440
2441 =item getsockopt SOCKET,LEVEL,OPTNAME
2442 X<getsockopt>
2443
2444 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2445 Options may exist at multiple protocol levels depending on the socket
2446 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2447 C<Socket> module) will exist. To query options at another level the
2448 protocol number of the appropriate protocol controlling the option
2449 should be supplied. For example, to indicate that an option is to be
2450 interpreted by the TCP protocol, LEVEL should be set to the protocol
2451 number of TCP, which you can get using C<getprotobyname>.
2452
2453 The function returns a packed string representing the requested socket
2454 option, or C<undef> on error, with the reason for the error placed in
2455 C<$!>. Just what is in the packed string depends on LEVEL and OPTNAME;
2456 consult getsockopt(2) for details.  A common case is that the option is an
2457 integer, in which case the result is a packed integer, which you can decode
2458 using C<unpack> with the C<i> (or C<I>) format.
2459
2460 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2461
2462     use Socket qw(:all);
2463
2464     defined(my $tcp = getprotobyname("tcp"))
2465         or die "Could not determine the protocol number for tcp";
2466     # my $tcp = IPPROTO_TCP; # Alternative
2467     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2468         or die "getsockopt TCP_NODELAY: $!";
2469     my $nodelay = unpack("I", $packed);
2470     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2471
2472 Portability issues: L<perlport/getsockopt>.
2473
2474 =item given EXPR BLOCK
2475 X<given>
2476
2477 =item given BLOCK
2478
2479 C<given> is analogous to the C<switch> keyword in other languages. C<given>
2480 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2481 Only available after Perl 5.10.  For example:
2482
2483     use v5.10;
2484     given ($fruit) {
2485         when (/apples?/) {
2486             print "I like apples."
2487         }
2488         when (/oranges?/) {
2489             print "I don't like oranges."
2490         }
2491         default {
2492             print "I don't like anything"
2493         }
2494     }
2495
2496 See L<perlsyn/"Switch statements"> for detailed information.
2497
2498 =item glob EXPR
2499 X<glob> X<wildcard> X<filename, expansion> X<expand>
2500
2501 =item glob
2502
2503 In list context, returns a (possibly empty) list of filename expansions on
2504 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2505 scalar context, glob iterates through such filename expansions, returning
2506 undef when the list is exhausted. This is the internal function
2507 implementing the C<< <*.c> >> operator, but you can use it directly. If
2508 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2509 more detail in L<perlop/"I/O Operators">.
2510
2511 Note that C<glob> splits its arguments on whitespace and treats
2512 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2513 matches all files with a F<.c> or F<.h> extension.  The expression
2514 C<glob(".* *")> matches all files in the current working directory.
2515
2516 If non-empty braces are the only wildcard characters used in the
2517 C<glob>, no filenames are matched, but potentially many strings
2518 are returned.  For example, this produces nine strings, one for
2519 each pairing of fruits and colors:
2520
2521     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2522
2523 Beginning with v5.6.0, this operator is implemented using the standard
2524 C<File::Glob> extension.  See L<File::Glob> for details, including
2525 C<bsd_glob> which does not treat whitespace as a pattern separator.
2526
2527 Portability issues: L<perlport/glob>.
2528
2529 =item gmtime EXPR
2530 X<gmtime> X<UTC> X<Greenwich>
2531
2532 =item gmtime
2533
2534 Works just like L</localtime> but the returned values are
2535 localized for the standard Greenwich time zone.
2536
2537 Note: When called in list context, $isdst, the last value
2538 returned by gmtime, is always C<0>.  There is no
2539 Daylight Saving Time in GMT.
2540
2541 Portability issues: L<perlport/gmtime>.
2542
2543 =item goto LABEL
2544 X<goto> X<jump> X<jmp>
2545
2546 =item goto EXPR
2547
2548 =item goto &NAME
2549
2550 The C<goto-LABEL> form finds the statement labeled with LABEL and
2551 resumes execution there. It can't be used to get out of a block or
2552 subroutine given to C<sort>.  It can be used to go almost anywhere
2553 else within the dynamic scope, including out of subroutines, but it's
2554 usually better to use some other construct such as C<last> or C<die>.
2555 The author of Perl has never felt the need to use this form of C<goto>
2556 (in Perl, that is; C is another matter).  (The difference is that C
2557 does not offer named loops combined with loop control.  Perl does, and
2558 this replaces most structured uses of C<goto> in other languages.)
2559
2560 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2561 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2562 necessarily recommended if you're optimizing for maintainability:
2563
2564     goto ("FOO", "BAR", "GLARCH")[$i];
2565
2566 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2567 function" rule. A pair of parentheses following it does not (necessarily)
2568 delimit its argument. C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2569
2570 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2571 deprecated and will issue a warning.  Even then, it may not be used to
2572 go into any construct that requires initialization, such as a
2573 subroutine or a C<foreach> loop.  It also can't be used to go into a
2574 construct that is optimized away.
2575
2576 The C<goto-&NAME> form is quite different from the other forms of
2577 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2578 doesn't have the stigma associated with other gotos.  Instead, it
2579 exits the current subroutine (losing any changes set by local()) and
2580 immediately calls in its place the named subroutine using the current
2581 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2582 load another subroutine and then pretend that the other subroutine had
2583 been called in the first place (except that any modifications to C<@_>
2584 in the current subroutine are propagated to the other subroutine.)
2585 After the C<goto>, not even C<caller> will be able to tell that this
2586 routine was called first.
2587
2588 NAME needn't be the name of a subroutine; it can be a scalar variable
2589 containing a code reference or a block that evaluates to a code
2590 reference.
2591
2592 =item grep BLOCK LIST
2593 X<grep>
2594
2595 =item grep EXPR,LIST
2596
2597 This is similar in spirit to, but not the same as, grep(1) and its
2598 relatives.  In particular, it is not limited to using regular expressions.
2599
2600 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2601 C<$_> to each element) and returns the list value consisting of those
2602 elements for which the expression evaluated to true.  In scalar
2603 context, returns the number of times the expression was true.
2604
2605     @foo = grep(!/^#/, @bar);    # weed out comments
2606
2607 or equivalently,
2608
2609     @foo = grep {!/^#/} @bar;    # weed out comments
2610
2611 Note that C<$_> is an alias to the list value, so it can be used to
2612 modify the elements of the LIST.  While this is useful and supported,
2613 it can cause bizarre results if the elements of LIST are not variables.
2614 Similarly, grep returns aliases into the original list, much as a for
2615 loop's index variable aliases the list elements.  That is, modifying an
2616 element of a list returned by grep (for example, in a C<foreach>, C<map>
2617 or another C<grep>) actually modifies the element in the original list.
2618 This is usually something to be avoided when writing clear code.
2619
2620 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2621 been declared with C<my $_>) then, in addition to being locally aliased to
2622 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2623 can't be seen from the outside, avoiding any potential side-effects.
2624
2625 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2626
2627 =item hex EXPR
2628 X<hex> X<hexadecimal>
2629
2630 =item hex
2631
2632 Interprets EXPR as a hex string and returns the corresponding value.
2633 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2634 L</oct>.)  If EXPR is omitted, uses C<$_>.
2635
2636     print hex '0xAf'; # prints '175'
2637     print hex 'aF';   # same
2638
2639 Hex strings may only represent integers.  Strings that would cause
2640 integer overflow trigger a warning.  Leading whitespace is not stripped,
2641 unlike oct(). To present something as hex, look into L</printf>,
2642 L</sprintf>, and L</unpack>.
2643
2644 =item import LIST
2645 X<import>
2646
2647 There is no builtin C<import> function.  It is just an ordinary
2648 method (subroutine) defined (or inherited) by modules that wish to export
2649 names to another module.  The C<use> function calls the C<import> method
2650 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2651
2652 =item index STR,SUBSTR,POSITION
2653 X<index> X<indexOf> X<InStr>
2654
2655 =item index STR,SUBSTR
2656
2657 The index function searches for one string within another, but without
2658 the wildcard-like behavior of a full regular-expression pattern match.
2659 It returns the position of the first occurrence of SUBSTR in STR at
2660 or after POSITION.  If POSITION is omitted, starts searching from the
2661 beginning of the string.  POSITION before the beginning of the string
2662 or after its end is treated as if it were the beginning or the end,
2663 respectively.  POSITION and the return value are based at C<0> (or whatever
2664 you've set the C<$[> variable to--but don't do that).  If the substring
2665 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2666
2667 =item int EXPR
2668 X<int> X<integer> X<truncate> X<trunc> X<floor>
2669
2670 =item int
2671
2672 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2673 You should not use this function for rounding: one because it truncates
2674 towards C<0>, and two because machine representations of floating-point
2675 numbers can sometimes produce counterintuitive results.  For example,
2676 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2677 because it's really more like -268.99999999999994315658 instead.  Usually,
2678 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2679 functions will serve you better than will int().
2680
2681 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2682 X<ioctl>
2683
2684 Implements the ioctl(2) function.  You'll probably first have to say
2685
2686     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2687
2688 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2689 exist or doesn't have the correct definitions you'll have to roll your
2690 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2691 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2692 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2693 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2694 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2695 has no string value but does have a numeric value, that value will be
2696 passed rather than a pointer to the string value.  To guarantee this to be
2697 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2698 functions may be needed to manipulate the values of structures used by
2699 C<ioctl>.
2700
2701 The return value of C<ioctl> (and C<fcntl>) is as follows:
2702
2703     if OS returns:      then Perl returns:
2704         -1               undefined value
2705          0              string "0 but true"
2706     anything else           that number
2707
2708 Thus Perl returns true on success and false on failure, yet you can
2709 still easily determine the actual value returned by the operating
2710 system:
2711
2712     $retval = ioctl(...) || -1;
2713     printf "System returned %d\n", $retval;
2714
2715 The special string C<"0 but true"> is exempt from B<-w> complaints
2716 about improper numeric conversions.
2717
2718 Portability issues: L<perlport/ioctl>.
2719
2720 =item join EXPR,LIST
2721 X<join>
2722
2723 Joins the separate strings of LIST into a single string with fields
2724 separated by the value of EXPR, and returns that new string.  Example:
2725
2726     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2727
2728 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2729 first argument.  Compare L</split>.
2730
2731 =item keys HASH
2732 X<keys> X<key>
2733
2734 =item keys ARRAY
2735
2736 =item keys EXPR
2737
2738 Returns a list consisting of all the keys of the named hash, or the indices
2739 of an array. (In scalar context, returns the number of keys or indices.)
2740
2741 The keys of a hash are returned in an apparently random order.  The actual
2742 random order is subject to change in future versions of Perl, but it
2743 is guaranteed to be the same order as either the C<values> or C<each>
2744 function produces (given that the hash has not been modified).  Since
2745 Perl 5.8.1 the ordering can be different even between different runs of
2746 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2747 Attacks">).
2748
2749 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2750 (see L</each>).  In particular, calling keys() in void context resets
2751 the iterator with no other overhead.
2752
2753 Here is yet another way to print your environment:
2754
2755     @keys = keys %ENV;
2756     @values = values %ENV;
2757     while (@keys) {
2758         print pop(@keys), '=', pop(@values), "\n";
2759     }
2760
2761 or how about sorted by key:
2762
2763     foreach $key (sort(keys %ENV)) {
2764         print $key, '=', $ENV{$key}, "\n";
2765     }
2766
2767 The returned values are copies of the original keys in the hash, so
2768 modifying them will not affect the original hash.  Compare L</values>.
2769
2770 To sort a hash by value, you'll need to use a C<sort> function.
2771 Here's a descending numeric sort of a hash by its values:
2772
2773     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2774         printf "%4d %s\n", $hash{$key}, $key;
2775     }
2776
2777 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2778 allocated for the given hash.  This can gain you a measure of efficiency if
2779 you know the hash is going to get big.  (This is similar to pre-extending
2780 an array by assigning a larger number to $#array.)  If you say
2781
2782     keys %hash = 200;
2783
2784 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2785 in fact, since it rounds up to the next power of two.  These
2786 buckets will be retained even if you do C<%hash = ()>, use C<undef
2787 %hash> if you want to free the storage while C<%hash> is still in scope.
2788 You can't shrink the number of buckets allocated for the hash using
2789 C<keys> in this way (but you needn't worry about doing this by accident,
2790 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2791 error.
2792
2793 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2794 a reference to an unblessed hash or array.  The argument will be
2795 dereferenced automatically.  This aspect of C<keys> is considered highly
2796 experimental.  The exact behaviour may change in a future version of Perl.
2797
2798     for (keys $hashref) { ... }
2799     for (keys $obj->get_arrayref) { ... }
2800
2801 See also C<each>, C<values>, and C<sort>.
2802
2803 =item kill SIGNAL, LIST
2804 X<kill> X<signal>
2805
2806 Sends a signal to a list of processes.  Returns the number of
2807 processes successfully signaled (which is not necessarily the
2808 same as the number actually killed).
2809
2810     $cnt = kill 1, $child1, $child2;
2811     kill 9, @goners;
2812
2813 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2814 checks whether it's I<possible> to send a signal to it (that
2815 means, to be brief, that the process is owned by the same user, or we are
2816 the super-user).  This is useful to check that a child process is still
2817 alive (even if only as a zombie) and hasn't changed its UID.  See
2818 L<perlport> for notes on the portability of this construct.
2819
2820 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2821 of processes. That means you usually want to use positive not negative signals.
2822 You may also use a signal name in quotes.
2823
2824 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2825 the operating system.  For example, on POSIX-conforming systems, zero will
2826 signal the current process group and -1 will signal all processes.
2827
2828 See L<perlipc/"Signals"> for more details.
2829
2830 On some platforms such as Windows where the fork() system call is not available.
2831 Perl can be built to emulate fork() at the interpreter level.
2832 This emulation has limitation related to kill that has to be considered,
2833 for code running on Windows and in code intended to be portable.
2834
2835 See L<perlfork> for more details.
2836
2837 Portability issues: L<perlport/kill>.
2838
2839 =item last LABEL
2840 X<last> X<break>
2841
2842 =item last
2843
2844 The C<last> command is like the C<break> statement in C (as used in
2845 loops); it immediately exits the loop in question.  If the LABEL is
2846 omitted, the command refers to the innermost enclosing loop.  The
2847 C<continue> block, if any, is not executed:
2848
2849     LINE: while (<STDIN>) {
2850         last LINE if /^$/;  # exit when done with header
2851         #...
2852     }
2853
2854 C<last> cannot be used to exit a block that returns a value such as
2855 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
2856 a grep() or map() operation.
2857
2858 Note that a block by itself is semantically identical to a loop
2859 that executes once.  Thus C<last> can be used to effect an early
2860 exit out of such a block.
2861
2862 See also L</continue> for an illustration of how C<last>, C<next>, and
2863 C<redo> work.
2864
2865 =item lc EXPR
2866 X<lc> X<lowercase>
2867
2868 =item lc
2869
2870 Returns a lowercased version of EXPR.  This is the internal function
2871 implementing the C<\L> escape in double-quoted strings.
2872
2873 If EXPR is omitted, uses C<$_>.
2874
2875 What gets returned depends on several factors:
2876
2877 =over
2878
2879 =item If C<use bytes> is in effect:
2880
2881 =over
2882
2883 =item On EBCDIC platforms
2884
2885 The results are what the C language system call C<tolower()> returns.
2886
2887 =item On ASCII platforms
2888
2889 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2890 respectively.
2891
2892 =back
2893
2894 =item Otherwise, If EXPR has the UTF8 flag set
2895
2896 If the current package has a subroutine named C<ToLower>, it will be used to
2897 change the case
2898 (See L<perlunicode/"User-Defined Case Mappings (for serious hackers only)">.)
2899 Otherwise Unicode semantics are used for the case change.
2900
2901 =item Otherwise, if C<use locale> is in effect
2902
2903 Respects current LC_CTYPE locale.  See L<perllocale>.
2904
2905 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2906
2907 Unicode semantics are used for the case change.  Any subroutine named
2908 C<ToLower> will be ignored.
2909
2910 =item Otherwise:
2911
2912 =over
2913
2914 =item On EBCDIC platforms
2915
2916 The results are what the C language system call C<tolower()> returns.
2917
2918 =item On ASCII platforms
2919
2920 ASCII semantics are used for the case change.  The lowercase of any character
2921 outside the ASCII range is the character itself.
2922
2923 =back
2924
2925 =back
2926
2927 =item lcfirst EXPR
2928 X<lcfirst> X<lowercase>
2929
2930 =item lcfirst
2931
2932 Returns the value of EXPR with the first character lowercased.  This
2933 is the internal function implementing the C<\l> escape in
2934 double-quoted strings.
2935
2936 If EXPR is omitted, uses C<$_>.
2937
2938 This function behaves the same way under various pragmata, such as in a locale,
2939 as L</lc> does.
2940
2941 =item length EXPR
2942 X<length> X<size>
2943
2944 =item length
2945
2946 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2947 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
2948 C<undef>.
2949
2950 This function cannot be used on an entire array or hash to find out how
2951 many elements these have.  For that, use C<scalar @array> and C<scalar keys
2952 %hash>, respectively.
2953
2954 Like all Perl character operations, length() normally deals in logical
2955 characters, not physical bytes.  For how many bytes a string encoded as
2956 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
2957 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
2958
2959 =item link OLDFILE,NEWFILE
2960 X<link>
2961
2962 Creates a new filename linked to the old filename.  Returns true for
2963 success, false otherwise.
2964
2965 Portability issues: L<perlport/link>.
2966
2967 =item listen SOCKET,QUEUESIZE
2968 X<listen>
2969
2970 Does the same thing that the listen(2) system call does.  Returns true if
2971 it succeeded, false otherwise.  See the example in
2972 L<perlipc/"Sockets: Client/Server Communication">.
2973
2974 =item local EXPR
2975 X<local>
2976
2977 You really probably want to be using C<my> instead, because C<local> isn't
2978 what most people think of as "local".  See
2979 L<perlsub/"Private Variables via my()"> for details.
2980
2981 A local modifies the listed variables to be local to the enclosing
2982 block, file, or eval.  If more than one value is listed, the list must
2983 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2984 for details, including issues with tied arrays and hashes.
2985
2986 The C<delete local EXPR> construct can also be used to localize the deletion
2987 of array/hash elements to the current block.
2988 See L<perlsub/"Localized deletion of elements of composite types">.
2989
2990 =item localtime EXPR
2991 X<localtime> X<ctime>
2992
2993 =item localtime
2994
2995 Converts a time as returned by the time function to a 9-element list
2996 with the time analyzed for the local time zone.  Typically used as
2997 follows:
2998
2999     #  0    1    2     3     4    5     6     7     8
3000     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3001                                                 localtime(time);
3002
3003 All list elements are numeric and come straight out of the C `struct
3004 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3005 of the specified time.
3006
3007 C<$mday> is the day of the month and C<$mon> the month in
3008 the range C<0..11>, with 0 indicating January and 11 indicating December.
3009 This makes it easy to get a month name from a list:
3010
3011     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3012     print "$abbr[$mon] $mday";
3013     # $mon=9, $mday=18 gives "Oct 18"
3014
3015 C<$year> is the number of years since 1900, B<not> just the last two digits
3016 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
3017 to get a 4-digit year is simply:
3018
3019     $year += 1900;
3020
3021 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
3022 to do that, would you?
3023
3024 To get the last two digits of the year (e.g., "01" in 2001) do:
3025
3026     $year = sprintf("%02d", $year % 100);
3027
3028 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3029 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3030 (or C<0..365> in leap years.)
3031
3032 C<$isdst> is true if the specified time occurs during Daylight Saving
3033 Time, false otherwise.
3034
3035 If EXPR is omitted, C<localtime()> uses the current time (as returned
3036 by time(3)).
3037
3038 In scalar context, C<localtime()> returns the ctime(3) value:
3039
3040     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3041
3042 This scalar value is B<not> locale-dependent but is a Perl builtin. For GMT
3043 instead of local time use the L</gmtime> builtin. See also the
3044 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3045 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3046 and mktime(3) functions.
3047
3048 To get somewhat similar but locale-dependent date strings, set up your
3049 locale environment variables appropriately (please see L<perllocale>) and
3050 try for example:
3051
3052     use POSIX qw(strftime);
3053     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3054     # or for GMT formatted appropriately for your locale:
3055     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3056
3057 Note that the C<%a> and C<%b>, the short forms of the day of the week
3058 and the month of the year, may not necessarily be three characters wide.
3059
3060 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3061 by-name access mechanism to the gmtime() and localtime() functions,
3062 respectively.
3063
3064 For a comprehensive date and time representation look at the
3065 L<DateTime> module on CPAN.
3066
3067 Portability issues: L<perlport/localtime>.
3068
3069 =item lock THING
3070 X<lock>
3071
3072 This function places an advisory lock on a shared variable or referenced
3073 object contained in I<THING> until the lock goes out of scope.
3074
3075 lock() is a "weak keyword" : this means that if you've defined a function
3076 by this name (before any calls to it), that function will be called
3077 instead.  If you are not under C<use threads::shared> this does nothing.
3078 See L<threads::shared>.
3079
3080 =item log EXPR
3081 X<log> X<logarithm> X<e> X<ln> X<base>
3082
3083 =item log
3084
3085 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3086 returns the log of C<$_>.  To get the
3087 log of another base, use basic algebra:
3088 The base-N log of a number is equal to the natural log of that number
3089 divided by the natural log of N.  For example:
3090
3091     sub log10 {
3092         my $n = shift;
3093         return log($n)/log(10);
3094     }
3095
3096 See also L</exp> for the inverse operation.
3097
3098 =item lstat EXPR
3099 X<lstat>
3100
3101 =item lstat
3102
3103 Does the same thing as the C<stat> function (including setting the
3104 special C<_> filehandle) but stats a symbolic link instead of the file
3105 the symbolic link points to.  If symbolic links are unimplemented on
3106 your system, a normal C<stat> is done.  For much more detailed
3107 information, please see the documentation for C<stat>.
3108
3109 If EXPR is omitted, stats C<$_>.
3110
3111 Portability issues: L<perlport/lstat>.
3112
3113 =item m//
3114
3115 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3116
3117 =item map BLOCK LIST
3118 X<map>
3119
3120 =item map EXPR,LIST
3121
3122 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3123 C<$_> to each element) and returns the list value composed of the
3124 results of each such evaluation.  In scalar context, returns the
3125 total number of elements so generated.  Evaluates BLOCK or EXPR in
3126 list context, so each element of LIST may produce zero, one, or
3127 more elements in the returned value.
3128
3129     @chars = map(chr, @numbers);
3130
3131 translates a list of numbers to the corresponding characters.
3132
3133     my @squares = map { $_ * $_ } @numbers;
3134
3135 translates a list of numbers to their squared values.
3136
3137     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3138
3139 shows that number of returned elements can differ from the number of
3140 input elements. To omit an element, return an empty list ().
3141 This could also be achieved by writing
3142
3143     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3144
3145 which makes the intention more clear.
3146
3147 Map always returns a list, which can be
3148 assigned to a hash such that the elements
3149 become key/value pairs. See L<perldata> for more details.
3150
3151     %hash = map { get_a_key_for($_) => $_ } @array;
3152
3153 is just a funny way to write
3154
3155     %hash = ();
3156     foreach (@array) {
3157         $hash{get_a_key_for($_)} = $_;
3158     }
3159
3160 Note that C<$_> is an alias to the list value, so it can be used to
3161 modify the elements of the LIST.  While this is useful and supported,
3162 it can cause bizarre results if the elements of LIST are not variables.
3163 Using a regular C<foreach> loop for this purpose would be clearer in
3164 most cases.  See also L</grep> for an array composed of those items of
3165 the original list for which the BLOCK or EXPR evaluates to true.
3166
3167 If C<$_> is lexical in the scope where the C<map> appears (because it has
3168 been declared with C<my $_>), then, in addition to being locally aliased to
3169 the list elements, C<$_> keeps being lexical inside the block; that is, it
3170 can't be seen from the outside, avoiding any potential side-effects.
3171
3172 C<{> starts both hash references and blocks, so C<map { ...> could be either
3173 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
3174 ahead for the closing C<}> it has to take a guess at which it's dealing with
3175 based on what it finds just after the C<{>. Usually it gets it right, but if it
3176 doesn't it won't realize something is wrong until it gets to the C<}> and
3177 encounters the missing (or unexpected) comma. The syntax error will be
3178 reported close to the C<}>, but you'll need to change something near the C<{>
3179 such as using a unary C<+> to give Perl some help:
3180
3181     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3182     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3183     %hash = map { ("\L$_" => 1) } @array  # this also works
3184     %hash = map {  lc($_) => 1  } @array  # as does this.
3185     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3186
3187     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3188
3189 or to force an anon hash constructor use C<+{>:
3190
3191    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3192
3193 to get a list of anonymous hashes each with only one entry apiece.
3194
3195 =item mkdir FILENAME,MASK
3196 X<mkdir> X<md> X<directory, create>
3197
3198 =item mkdir FILENAME
3199
3200 =item mkdir
3201
3202 Creates the directory specified by FILENAME, with permissions
3203 specified by MASK (as modified by C<umask>).  If it succeeds it
3204 returns true; otherwise it returns false and sets C<$!> (errno).
3205 MASK defaults to 0777 if omitted, and FILENAME defaults
3206 to C<$_> if omitted.
3207
3208 In general, it is better to create directories with a permissive MASK
3209 and let the user modify that with their C<umask> than it is to supply
3210 a restrictive MASK and give the user no way to be more permissive.
3211 The exceptions to this rule are when the file or directory should be
3212 kept private (mail files, for instance).  The perlfunc(1) entry on
3213 C<umask> discusses the choice of MASK in more detail.
3214
3215 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3216 number of trailing slashes.  Some operating and filesystems do not get
3217 this right, so Perl automatically removes all trailing slashes to keep
3218 everyone happy.
3219
3220 To recursively create a directory structure, look at
3221 the C<mkpath> function of the L<File::Path> module.
3222
3223 =item msgctl ID,CMD,ARG
3224 X<msgctl>
3225
3226 Calls the System V IPC function msgctl(2).  You'll probably have to say
3227
3228     use IPC::SysV;
3229
3230 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3231 then ARG must be a variable that will hold the returned C<msqid_ds>
3232 structure.  Returns like C<ioctl>: the undefined value for error,
3233 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3234 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3235 C<IPC::Semaphore>.
3236
3237 Portability issues: L<perlport/msgctl>.
3238
3239 =item msgget KEY,FLAGS
3240 X<msgget>
3241
3242 Calls the System V IPC function msgget(2).  Returns the message queue
3243 id, or C<undef> on error.  See also
3244 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3245 C<IPC::Msg>.
3246
3247 Portability issues: L<perlport/msgget>.
3248
3249 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3250 X<msgrcv>
3251
3252 Calls the System V IPC function msgrcv to receive a message from
3253 message queue ID into variable VAR with a maximum message size of
3254 SIZE.  Note that when a message is received, the message type as a
3255 native long integer will be the first thing in VAR, followed by the
3256 actual message.  This packing may be opened with C<unpack("l! a*")>.
3257 Taints the variable.  Returns true if successful, false 
3258 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3259 C<IPC::SysV> and C<IPC::SysV::Msg>.
3260
3261 Portability issues: L<perlport/msgrcv>.
3262
3263 =item msgsnd ID,MSG,FLAGS
3264 X<msgsnd>
3265
3266 Calls the System V IPC function msgsnd to send the message MSG to the
3267 message queue ID.  MSG must begin with the native long integer message
3268 type, be followed by the length of the actual message, and then finally
3269 the message itself.  This kind of packing can be achieved with
3270 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3271 false on error.  See also the C<IPC::SysV>
3272 and C<IPC::SysV::Msg> documentation.
3273
3274 Portability issues: L<perlport/msgsnd>.
3275
3276 =item my EXPR
3277 X<my>
3278
3279 =item my TYPE EXPR
3280
3281 =item my EXPR : ATTRS
3282
3283 =item my TYPE EXPR : ATTRS
3284
3285 A C<my> declares the listed variables to be local (lexically) to the
3286 enclosing block, file, or C<eval>.  If more than one value is listed,
3287 the list must be placed in parentheses.
3288
3289 The exact semantics and interface of TYPE and ATTRS are still
3290 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3291 and attributes are handled using the C<attributes> pragma, or starting
3292 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3293 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3294 L<attributes>, and L<Attribute::Handlers>.
3295
3296 =item next LABEL
3297 X<next> X<continue>
3298
3299 =item next
3300
3301 The C<next> command is like the C<continue> statement in C; it starts
3302 the next iteration of the loop:
3303
3304     LINE: while (<STDIN>) {
3305         next LINE if /^#/;  # discard comments
3306         #...
3307     }
3308
3309 Note that if there were a C<continue> block on the above, it would get
3310 executed even on discarded lines.  If LABEL is omitted, the command
3311 refers to the innermost enclosing loop.
3312
3313 C<next> cannot be used to exit a block which returns a value such as
3314 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3315 a grep() or map() operation.
3316
3317 Note that a block by itself is semantically identical to a loop
3318 that executes once.  Thus C<next> will exit such a block early.
3319
3320 See also L</continue> for an illustration of how C<last>, C<next>, and
3321 C<redo> work.
3322
3323 =item no MODULE VERSION LIST
3324 X<no declarations>
3325 X<unimporting>
3326
3327 =item no MODULE VERSION
3328
3329 =item no MODULE LIST
3330
3331 =item no MODULE
3332
3333 =item no VERSION
3334
3335 See the C<use> function, of which C<no> is the opposite.
3336
3337 =item oct EXPR
3338 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3339
3340 =item oct
3341
3342 Interprets EXPR as an octal string and returns the corresponding
3343 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3344 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3345 binary string.  Leading whitespace is ignored in all three cases.)
3346 The following will handle decimal, binary, octal, and hex in standard
3347 Perl notation:
3348
3349     $val = oct($val) if $val =~ /^0/;
3350
3351 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3352 in octal), use sprintf() or printf():
3353
3354     $dec_perms = (stat("filename"))[2] & 07777;
3355     $oct_perm_str = sprintf "%o", $perms;
3356
3357 The oct() function is commonly used when a string such as C<644> needs
3358 to be converted into a file mode, for example.  Although Perl 
3359 automatically converts strings into numbers as needed, this automatic
3360 conversion assumes base 10.
3361
3362 Leading white space is ignored without warning, as too are any trailing 
3363 non-digits, such as a decimal point (C<oct> only handles non-negative
3364 integers, not negative integers or floating point).
3365
3366 =item open FILEHANDLE,EXPR
3367 X<open> X<pipe> X<file, open> X<fopen>
3368
3369 =item open FILEHANDLE,MODE,EXPR
3370
3371 =item open FILEHANDLE,MODE,EXPR,LIST
3372
3373 =item open FILEHANDLE,MODE,REFERENCE
3374
3375 =item open FILEHANDLE
3376
3377 Opens the file whose filename is given by EXPR, and associates it with
3378 FILEHANDLE.
3379
3380 Simple examples to open a file for reading:
3381
3382     open(my $fh, "<", "input.txt") 
3383         or die "cannot open < input.txt: $!";
3384
3385 and for writing:
3386
3387     open(my $fh, ">", "output.txt") 
3388         or die "cannot open > output.txt: $!";
3389
3390 (The following is a comprehensive reference to open(): for a gentler
3391 introduction you may consider L<perlopentut>.)
3392
3393 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3394 new filehandle is autovivified, meaning that the variable is assigned a
3395 reference to a newly allocated anonymous filehandle.  Otherwise if
3396 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3397 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3398 in effect.)
3399
3400 If EXPR is omitted, the global (package) scalar variable of the same
3401 name as the FILEHANDLE contains the filename.  (Note that lexical 
3402 variables--those declared with C<my> or C<state>--will not work for this
3403 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3404 call to open.)
3405
3406 If three (or more) arguments are specified, the open mode (including
3407 optional encoding) in the second argument are distinct from the filename in
3408 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3409 If MODE is C<< > >>, the file is opened for output, with existing files
3410 first being truncated ("clobbered") and nonexisting files newly created.
3411 If MODE is C<<< >> >>>, the file is opened for appending, again being
3412 created if necessary.
3413
3414 You can put a C<+> in front of the C<< > >> or C<< < >> to
3415 indicate that you want both read and write access to the file; thus
3416 C<< +< >> is almost always preferred for read/write updates--the 
3417 C<< +> >> mode would clobber the file first.  You cant usually use
3418 either read-write mode for updating textfiles, since they have
3419 variable-length records.  See the B<-i> switch in L<perlrun> for a
3420 better approach.  The file is created with permissions of C<0666>
3421 modified by the process's C<umask> value.
3422
3423 These various prefixes correspond to the fopen(3) modes of C<r>,
3424 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3425
3426 In the one- and two-argument forms of the call, the mode and filename
3427 should be concatenated (in that order), preferably separated by white
3428 space.  You can--but shouldn't--omit the mode in these forms when that mode
3429 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3430 the filename argument is a known literal.
3431
3432 For three or more arguments if MODE is C<|->, the filename is
3433 interpreted as a command to which output is to be piped, and if MODE
3434 is C<-|>, the filename is interpreted as a command that pipes
3435 output to us.  In the two-argument (and one-argument) form, one should
3436 replace dash (C<->) with the command.
3437 See L<perlipc/"Using open() for IPC"> for more examples of this.
3438 (You are not allowed to C<open> to a command that pipes both in I<and>
3439 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3440 L<perlipc/"Bidirectional Communication with Another Process"> for
3441 alternatives.)
3442
3443 In the form of pipe opens taking three or more arguments, if LIST is specified
3444 (extra arguments after the command name) then LIST becomes arguments
3445 to the command invoked if the platform supports it.  The meaning of
3446 C<open> with more than three arguments for non-pipe modes is not yet
3447 defined, but experimental "layers" may give extra LIST arguments
3448 meaning.
3449
3450 In the two-argument (and one-argument) form, opening C<< <- >> 
3451 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3452
3453 You may (and usually should) use the three-argument form of open to specify
3454 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3455 that affect how the input and output are processed (see L<open> and
3456 L<PerlIO> for more details). For example:
3457
3458   open(my $fh, "<:encoding(UTF-8)", "filename")
3459     || die "can't open UTF-8 encoded filename: $!";
3460
3461 opens the UTF8-encoded file containing Unicode characters;
3462 see L<perluniintro>. Note that if layers are specified in the
3463 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3464 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3465
3466 Open returns nonzero on success, the undefined value otherwise.  If
3467 the C<open> involved a pipe, the return value happens to be the pid of
3468 the subprocess.
3469
3470 If you're running Perl on a system that distinguishes between text
3471 files and binary files, then you should check out L</binmode> for tips
3472 for dealing with this.  The key distinction between systems that need
3473 C<binmode> and those that don't is their text file formats.  Systems
3474 like Unix, Mac OS, and Plan 9, that end lines with a single
3475 character and encode that character in C as C<"\n"> do not
3476 need C<binmode>.  The rest need it.
3477
3478 When opening a file, it's seldom a good idea to continue 
3479 if the request failed, so C<open> is frequently used with
3480 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3481 where you want to format a suitable error message (but there are
3482 modules that can help with that problem)) always check
3483 the return value from opening a file.  
3484
3485 As a special case the three-argument form with a read/write mode and the third
3486 argument being C<undef>:
3487
3488     open(my $tmp, "+>", undef) or die ...
3489
3490 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3491 works for symmetry, but you really should consider writing something
3492 to the temporary file first.  You will need to seek() to do the
3493 reading.
3494
3495 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3496 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3497 open filehandles directly to Perl scalars via:
3498
3499     open($fh, ">", \$variable) || ..
3500
3501 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3502
3503     close STDOUT;
3504     open(STDOUT, ">", \$variable)
3505         or die "Can't open STDOUT: $!";
3506
3507 General examples:
3508
3509     $ARTICLE = 100;
3510     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3511     while (<ARTICLE>) {...
3512
3513     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3514     # if the open fails, output is discarded
3515
3516     open(my $dbase, "+<", "dbase.mine")      # open for update
3517         or die "Can't open 'dbase.mine' for update: $!";
3518
3519     open(my $dbase, "+<dbase.mine")          # ditto
3520         or die "Can't open 'dbase.mine' for update: $!";
3521
3522     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3523         or die "Can't start caesar: $!";
3524
3525     open(ARTICLE, "caesar <$article |")      # ditto
3526         or die "Can't start caesar: $!";
3527
3528     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3529         or die "Can't start sort: $!";
3530
3531     # in-memory files
3532     open(MEMORY, ">", \$var)
3533         or die "Can't open memory file: $!";
3534     print MEMORY "foo!\n";                   # output will appear in $var
3535
3536     # process argument list of files along with any includes
3537
3538     foreach $file (@ARGV) {
3539         process($file, "fh00");
3540     }
3541
3542     sub process {
3543         my($filename, $input) = @_;
3544         $input++;    # this is a string increment
3545         unless (open($input, "<", $filename)) {
3546             print STDERR "Can't open $filename: $!\n";
3547             return;
3548         }
3549
3550         local $_;
3551         while (<$input>) {    # note use of indirection
3552             if (/^#include "(.*)"/) {
3553                 process($1, $input);
3554                 next;
3555             }
3556             #...          # whatever
3557         }
3558     }
3559
3560 See L<perliol> for detailed info on PerlIO.
3561
3562 You may also, in the Bourne shell tradition, specify an EXPR beginning
3563 with C<< >& >>, in which case the rest of the string is interpreted
3564 as the name of a filehandle (or file descriptor, if numeric) to be
3565 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3566 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3567 The mode you specify should match the mode of the original filehandle.
3568 (Duping a filehandle does not take into account any existing contents
3569 of IO buffers.) If you use the three-argument form, then you can pass either a
3570 number, the name of a filehandle, or the normal "reference to a glob".
3571
3572 Here is a script that saves, redirects, and restores C<STDOUT> and
3573 C<STDERR> using various methods:
3574
3575     #!/usr/bin/perl
3576     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3577     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3578
3579     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3580     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3581
3582     select STDERR; $| = 1;  # make unbuffered
3583     select STDOUT; $| = 1;  # make unbuffered
3584
3585     print STDOUT "stdout 1\n";  # this works for
3586     print STDERR "stderr 1\n";  # subprocesses too
3587
3588     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3589     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3590
3591     print STDOUT "stdout 2\n";
3592     print STDERR "stderr 2\n";
3593
3594 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3595 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3596 that file descriptor (and not call C<dup(2)>); this is more
3597 parsimonious of file descriptors.  For example:
3598
3599     # open for input, reusing the fileno of $fd
3600     open(FILEHANDLE, "<&=$fd")
3601
3602 or
3603
3604     open(FILEHANDLE, "<&=", $fd)
3605
3606 or
3607
3608     # open for append, using the fileno of OLDFH
3609     open(FH, ">>&=", OLDFH)
3610
3611 or
3612
3613     open(FH, ">>&=OLDFH")
3614
3615 Being parsimonious on filehandles is also useful (besides being
3616 parsimonious) for example when something is dependent on file
3617 descriptors, like for example locking using flock().  If you do just
3618 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3619 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3620 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3621 the same underlying system file descriptor.
3622
3623 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3624 fdopen() to implement the C<=> functionality.  On many Unix systems,
3625 fdopen() fails when file descriptors exceed a certain value, typically 255.
3626 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3627
3628 You can see whether your Perl was built with PerlIO by running C<perl -V>
3629 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3630 have PerlIO; otherwise you don't.
3631
3632 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3633 with the one- or two-argument forms of C<open>), 
3634 an implicit C<fork> is done, so C<open> returns twice: in the parent
3635 process it returns the pid
3636 of the child process, and in the child process it returns (a defined) C<0>.
3637 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3638
3639 For example, use either
3640
3641     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
3642
3643 or
3644     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3645
3646 followed by 
3647
3648     if ($child_pid) {
3649         # am the parent:
3650         # either write TO_KID or else read FROM_KID
3651         ...
3652         wait $child_pid;
3653     } else {
3654         # am the child; use STDIN/STDOUT normally
3655         ...
3656         exit;
3657     } 
3658
3659 The filehandle behaves normally for the parent, but I/O to that
3660 filehandle is piped from/to the STDOUT/STDIN of the child process.
3661 In the child process, the filehandle isn't opened--I/O happens from/to
3662 the new STDOUT/STDIN.  Typically this is used like the normal
3663 piped open when you want to exercise more control over just how the
3664 pipe command gets executed, such as when running setuid and
3665 you don't want to have to scan shell commands for metacharacters.
3666
3667 The following blocks are more or less equivalent:
3668
3669     open(FOO, "|tr '[a-z]' '[A-Z]'");
3670     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3671     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3672     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3673
3674     open(FOO, "cat -n '$file'|");
3675     open(FOO, "-|", "cat -n '$file'");
3676     open(FOO, "-|") || exec "cat", "-n", $file;
3677     open(FOO, "-|", "cat", "-n", $file);
3678
3679 The last two examples in each block show the pipe as "list form", which is
3680 not yet supported on all platforms.  A good rule of thumb is that if
3681 your platform has a real C<fork()> (in other words, if your platform is
3682 Unix, including Linux and MacOS X), you can use the list form.  You would 
3683 want to use the list form of the pipe so you can pass literal arguments
3684 to the command without risk of the shell interpreting any shell metacharacters
3685 in them.  However, this also bars you from opening pipes to commands
3686 that intentionally contain shell metacharacters, such as:
3687
3688     open(FOO, "|cat -n | expand -4 | lpr")
3689         // die "Can't open pipeline to lpr: $!";
3690
3691 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3692
3693 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3694 output before any operation that may do a fork, but this may not be
3695 supported on some platforms (see L<perlport>).  To be safe, you may need
3696 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3697 of C<IO::Handle> on any open handles.
3698
3699 On systems that support a close-on-exec flag on files, the flag will
3700 be set for the newly opened file descriptor as determined by the value
3701 of C<$^F>.  See L<perlvar/$^F>.
3702
3703 Closing any piped filehandle causes the parent process to wait for the
3704 child to finish, then returns the status value in C<$?> and
3705 C<${^CHILD_ERROR_NATIVE}>.
3706
3707 The filename passed to the one- and two-argument forms of open() will
3708 have leading and trailing whitespace deleted and normal
3709 redirection characters honored.  This property, known as "magic open",
3710 can often be used to good effect.  A user could specify a filename of
3711 F<"rsh cat file |">, or you could change certain filenames as needed:
3712
3713     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3714     open(FH, $filename) or die "Can't open $filename: $!";
3715
3716 Use the three-argument form to open a file with arbitrary weird characters in it,
3717
3718     open(FOO, "<", $file)
3719         || die "can't open < $file: $!";
3720
3721 otherwise it's necessary to protect any leading and trailing whitespace:
3722
3723     $file =~ s#^(\s)#./$1#;
3724     open(FOO, "< $file\0")
3725         || die "open failed: $!";
3726
3727 (this may not work on some bizarre filesystems).  One should
3728 conscientiously choose between the I<magic> and I<three-argument> form
3729 of open():
3730
3731     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3732
3733 will allow the user to specify an argument of the form C<"rsh cat file |">,
3734 but will not work on a filename that happens to have a trailing space, while
3735
3736     open(IN, "<", $ARGV[0])
3737         || die "can't open < $ARGV[0]: $!";
3738
3739 will have exactly the opposite restrictions.
3740
3741 If you want a "real" C C<open> (see C<open(2)> on your system), then you
3742 should use the C<sysopen> function, which involves no such magic (but may
3743 use subtly different filemodes than Perl open(), which is mapped to C
3744 fopen()).  This is another way to protect your filenames from
3745 interpretation.  For example:
3746
3747     use IO::Handle;
3748     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3749         or die "sysopen $path: $!";
3750     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3751     print HANDLE "stuff $$\n";
3752     seek(HANDLE, 0, 0);
3753     print "File contains: ", <HANDLE>;
3754
3755 Using the constructor from the C<IO::Handle> package (or one of its
3756 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3757 filehandles that have the scope of the variables used to hold them, then
3758 automatically (but silently) close once their reference counts become
3759 zero, typically at scope exit:
3760
3761     use IO::File;
3762     #...
3763     sub read_myfile_munged {
3764         my $ALL = shift;
3765         # or just leave it undef to autoviv
3766         my $handle = IO::File->new;
3767         open($handle, "<", "myfile") or die "myfile: $!";
3768         $first = <$handle>
3769             or return ();     # Automatically closed here.
3770         mung($first) or die "mung failed";  # Or here.
3771         return (first, <$handle>) if $ALL;  # Or here.
3772         return $first;                      # Or here.
3773     }
3774
3775 B<WARNING:> The previous example has a bug because the automatic
3776 close that happens when the refcount on C<handle> does not
3777 properly detect and report failures.  I<Always> close the handle
3778 yourself and inspect the return value.
3779
3780     close($handle) 
3781         || warn "close failed: $!";
3782
3783 See L</seek> for some details about mixing reading and writing.
3784
3785 Portability issues: L<perlport/open>.
3786
3787 =item opendir DIRHANDLE,EXPR
3788 X<opendir>
3789
3790 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3791 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3792 DIRHANDLE may be an expression whose value can be used as an indirect
3793 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3794 scalar variable (or array or hash element), the variable is assigned a
3795 reference to a new anonymous dirhandle; that is, it's autovivified.
3796 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3797
3798 See the example at C<readdir>.
3799
3800 =item ord EXPR
3801 X<ord> X<encoding>
3802
3803 =item ord
3804
3805 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3806 or Unicode) value of the first character of EXPR.  
3807 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3808 (Note I<character>, not byte.)
3809
3810 For the reverse, see L</chr>.
3811 See L<perlunicode> for more about Unicode.
3812
3813 =item our EXPR
3814 X<our> X<global>
3815
3816 =item our TYPE EXPR
3817
3818 =item our EXPR : ATTRS
3819
3820 =item our TYPE EXPR : ATTRS
3821
3822 C<our> associates a simple name with a package variable in the current
3823 package for use within the current scope.  When C<use strict 'vars'> is in
3824 effect, C<our> lets you use declared global variables without qualifying
3825 them with package names, within the lexical scope of the C<our> declaration.
3826 In this way C<our> differs from C<use vars>, which is package-scoped.
3827
3828 Unlike C<my> or C<state>, which allocates storage for a variable and
3829 associates a simple name with that storage for use within the current
3830 scope, C<our> associates a simple name with a package (read: global)
3831 variable in the current package, for use within the current lexical scope.
3832 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
3833 does not necessarily create a variable.
3834
3835 If more than one value is listed, the list must be placed
3836 in parentheses.
3837
3838     our $foo;
3839     our($bar, $baz);
3840
3841 An C<our> declaration declares a global variable that will be visible
3842 across its entire lexical scope, even across package boundaries.  The
3843 package in which the variable is entered is determined at the point
3844 of the declaration, not at the point of use.  This means the following
3845 behavior holds:
3846
3847     package Foo;
3848     our $bar;      # declares $Foo::bar for rest of lexical scope
3849     $bar = 20;
3850
3851     package Bar;
3852     print $bar;    # prints 20, as it refers to $Foo::bar
3853
3854 Multiple C<our> declarations with the same name in the same lexical
3855 scope are allowed if they are in different packages.  If they happen
3856 to be in the same package, Perl will emit warnings if you have asked
3857 for them, just like multiple C<my> declarations.  Unlike a second
3858 C<my> declaration, which will bind the name to a fresh variable, a
3859 second C<our> declaration in the same package, in the same scope, is
3860 merely redundant.
3861
3862     use warnings;
3863     package Foo;
3864     our $bar;      # declares $Foo::bar for rest of lexical scope
3865     $bar = 20;
3866
3867     package Bar;
3868     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3869     print $bar;    # prints 30
3870
3871     our $bar;      # emits warning but has no other effect
3872     print $bar;    # still prints 30
3873
3874 An C<our> declaration may also have a list of attributes associated
3875 with it.
3876
3877 The exact semantics and interface of TYPE and ATTRS are still
3878 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3879 and attributes are handled using the C<attributes> pragma, or starting
3880 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3881 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3882 L<attributes>, and L<Attribute::Handlers>.
3883
3884 =item pack TEMPLATE,LIST
3885 X<pack>
3886
3887 Takes a LIST of values and converts it into a string using the rules
3888 given by the TEMPLATE.  The resulting string is the concatenation of
3889 the converted values.  Typically, each converted value looks
3890 like its machine-level representation.  For example, on 32-bit machines
3891 an integer may be represented by a sequence of 4 bytes, which  will in
3892 Perl be presented as a string that's 4 characters long. 
3893
3894 See L<perlpacktut> for an introduction to this function.
3895
3896 The TEMPLATE is a sequence of characters that give the order and type
3897 of values, as follows:
3898
3899     a  A string with arbitrary binary data, will be null padded.
3900     A  A text (ASCII) string, will be space padded.
3901     Z  A null-terminated (ASCIZ) string, will be null padded.
3902
3903     b  A bit string (ascending bit order inside each byte, like vec()).
3904     B  A bit string (descending bit order inside each byte).
3905     h  A hex string (low nybble first).
3906     H  A hex string (high nybble first).
3907
3908     c  A signed char (8-bit) value.
3909     C  An unsigned char (octet) value.
3910     W  An unsigned char value (can be greater than 255).
3911
3912     s  A signed short (16-bit) value.
3913     S  An unsigned short value.
3914
3915     l  A signed long (32-bit) value.
3916     L  An unsigned long value.
3917
3918     q  A signed quad (64-bit) value.
3919     Q  An unsigned quad value.
3920       (Quads are available only if your system supports 64-bit
3921        integer values _and_ if Perl has been compiled to support those.
3922            Raises an exception otherwise.)
3923
3924     i  A signed integer value.
3925     I  A unsigned integer value.
3926       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3927            size depends on what a local C compiler calls 'int'.)
3928
3929     n  An unsigned short (16-bit) in "network" (big-endian) order.
3930     N  An unsigned long (32-bit) in "network" (big-endian) order.
3931     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3932     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3933
3934     j   A Perl internal signed integer value (IV).
3935     J   A Perl internal unsigned integer value (UV).
3936
3937     f  A single-precision float in native format.
3938     d  A double-precision float in native format.
3939
3940     F  A Perl internal floating-point value (NV) in native format
3941     D  A float of long-double precision in native format.
3942       (Long doubles are available only if your system supports long
3943        double values _and_ if Perl has been compiled to support those.
3944            Raises an exception otherwise.)
3945
3946     p  A pointer to a null-terminated string.
3947     P  A pointer to a structure (fixed-length string).
3948
3949     u  A uuencoded string.
3950     U  A Unicode character number.  Encodes to a character in character mode
3951         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3952
3953     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3954        details).  Its bytes represent an unsigned integer in base 128,
3955        most significant digit first, with as few digits as possible.  Bit
3956        eight (the high bit) is set on each byte except the last.
3957
3958     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
3959     X  Back up a byte.
3960     @  Null-fill or truncate to absolute position, counted from the
3961        start of the innermost ()-group.
3962     .  Null-fill or truncate to absolute position specified by the value.
3963     (  Start of a ()-group.
3964
3965 One or more modifiers below may optionally follow certain letters in the
3966 TEMPLATE (the second column lists letters for which the modifier is valid):
3967
3968     !   sSlLiI     Forces native (short, long, int) sizes instead
3969                    of fixed (16-/32-bit) sizes.
3970
3971         xX         Make x and X act as alignment commands.
3972
3973         nNvV       Treat integers as signed instead of unsigned.
3974
3975         @.         Specify position as byte offset in the internal
3976                    representation of the packed string. Efficient but
3977                    dangerous.
3978
3979     >   sSiIlLqQ   Force big-endian byte-order on the type.
3980         jJfFdDpP   (The "big end" touches the construct.)
3981
3982     <   sSiIlLqQ   Force little-endian byte-order on the type.
3983         jJfFdDpP   (The "little end" touches the construct.)
3984
3985 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
3986 to force a particular byte-order on all components in that group, 
3987 including all its subgroups.
3988
3989 The following rules apply:
3990
3991 =over 
3992
3993 =item *
3994
3995 Each letter may optionally be followed by a number indicating the repeat
3996 count.  A numeric repeat count may optionally be enclosed in brackets, as
3997 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
3998 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
3999 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4000 something else, dscribed below.  Supplying a C<*> for the repeat count
4001 instead of a number means to use however many items are left, except for:
4002
4003 =over 
4004
4005 =item * 
4006
4007 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4008
4009 =item * 
4010
4011 <.>, where it means relative to the start of the string.
4012
4013 =item * 
4014
4015 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4016
4017 =back 
4018
4019 One can replace a numeric repeat count with a template letter enclosed in
4020 brackets to use the packed byte length of the bracketed template for the
4021 repeat count.
4022
4023 For example, the template C<x[L]> skips as many bytes as in a packed long,
4024 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4025 variable-expanded) unpacks.  If the template in brackets contains alignment
4026 commands (such as C<x![d]>), its packed length is calculated as if the
4027 start of the template had the maximal possible alignment.
4028
4029 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4030 trailing null byte, so the resulting string is always one byte longer than
4031 the byte length of the item itself.
4032
4033 When used with C<@>, the repeat count represents an offset from the start
4034 of the innermost C<()> group.
4035
4036 When used with C<.>, the repeat count determines the starting position to
4037 calculate the value offset as follows:
4038
4039 =over 
4040
4041 =item *
4042
4043 If the repeat count is C<0>, it's relative to the current position.
4044
4045 =item *
4046
4047 If the repeat count is C<*>, the offset is relative to the start of the
4048 packed string.
4049
4050 =item *
4051
4052 And if it's an integer I<n>, the offset is relative to the start of the
4053 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4054 bigger then the group level.
4055
4056 =back
4057
4058 The repeat count for C<u> is interpreted as the maximal number of bytes
4059 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
4060 count should not be more than 65.
4061
4062 =item *
4063
4064 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4065 string of length count, padding with nulls or spaces as needed.  When
4066 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4067 after the first null, and C<a> returns data with no stripping at all.
4068
4069 If the value to pack is too long, the result is truncated.  If it's too
4070 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4071 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4072 when the count is 0.
4073
4074 =item *
4075
4076 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4077 Each such format generates 1 bit of the result.  These are typically followed
4078 by a repeat count like C<B8> or C<B64>.
4079
4080 Each result bit is based on the least-significant bit of the corresponding
4081 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4082 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4083
4084 Starting from the beginning of the input string, each 8-tuple
4085 of characters is converted to 1 character of output.  With format C<b>,
4086 the first character of the 8-tuple determines the least-significant bit of a
4087 character; with format C<B>, it determines the most-significant bit of
4088 a character.
4089
4090 If the length of the input string is not evenly divisible by 8, the
4091 remainder is packed as if the input string were padded by null characters
4092 at the end.  Similarly during unpacking, "extra" bits are ignored.
4093
4094 If the input string is longer than needed, remaining characters are ignored.
4095
4096 A C<*> for the repeat count uses all characters of the input field.  
4097 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4098
4099 =item *
4100
4101 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4102 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4103
4104 For each such format, pack() generates 4 bits of result.
4105 With non-alphabetical characters, the result is based on the 4 least-significant
4106 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4107 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4108 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4109 is compatible with the usual hexadecimal digits, so that C<"a"> and
4110 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4111 characters with this format.
4112
4113 Starting from the beginning of the template to pack(), each pair
4114 of characters is converted to 1 character of output.  With format C<h>, the
4115 first character of the pair determines the least-significant nybble of the
4116 output character; with format C<H>, it determines the most-significant
4117 nybble.
4118
4119 If the length of the input string is not even, it behaves as if padded by
4120 a null character at the end.  Similarly, "extra" nybbles are ignored during
4121 unpacking.
4122
4123 If the input string is longer than needed, extra characters are ignored.
4124
4125 A C<*> for the repeat count uses all characters of the input field.  For
4126 unpack(), nybbles are converted to a string of hexadecimal digits.
4127
4128 =item *
4129
4130 The C<p> format packs a pointer to a null-terminated string.  You are
4131 responsible for ensuring that the string is not a temporary value, as that
4132 could potentially get deallocated before you got around to using the packed
4133 result.  The C<P> format packs a pointer to a structure of the size indicated
4134 by the length.  A null pointer is created if the corresponding value for
4135 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4136 unpacks into C<undef>.
4137
4138 If your system has a strange pointer size--meaning a pointer is neither as
4139 big as an int nor as big as a long--it may not be possible to pack or
4140 unpack pointers in big- or little-endian byte order.  Attempting to do
4141 so raises an exception.
4142
4143 =item *
4144
4145 The C</> template character allows packing and unpacking of a sequence of
4146 items where the packed structure contains a packed item count followed by
4147 the packed items themselves.  This is useful when the structure you're
4148 unpacking has encoded the sizes or repeat counts for some of its fields
4149 within the structure itself as separate fields.
4150
4151 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4152 I<length-item> describes how the length value is packed. Formats likely
4153 to be of most use are integer-packing ones like C<n> for Java strings,
4154 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4155
4156 For C<pack>, I<sequence-item> may have a repeat count, in which case
4157 the minimum of that and the number of available items is used as the argument
4158 for I<length-item>. If it has no repeat count or uses a '*', the number
4159 of available items is used.
4160
4161 For C<unpack>, an internal stack of integer arguments unpacked so far is
4162 used. You write C</>I<sequence-item> and the repeat count is obtained by
4163 popping off the last element from the stack. The I<sequence-item> must not
4164 have a repeat count.
4165
4166 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4167 the I<length-item> is the string length, not the number of strings.  With
4168 an explicit repeat count for pack, the packed string is adjusted to that
4169 length.  For example:
4170
4171     unpack("W/a", "\004Gurusamy")           gives ("Guru")
4172     unpack("a3/A A*", "007 Bond  J ")       gives (" Bond", "J")
4173     unpack("a3 x2 /A A*", "007: Bond, J.")  gives ("Bond, J", ".")
4174
4175     pack("n/a* w/a","hello,","world")       gives "\000\006hello,\005world"
4176     pack("a/W2", ord("a") .. ord("z"))      gives "2ab"
4177
4178 The I<length-item> is not returned explicitly from C<unpack>.
4179
4180 Supplying a count to the I<length-item> format letter is only useful with
4181 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4182 introduce C<"\000"> characters, which Perl does not regard as legal in
4183 numeric strings.
4184
4185 =item *
4186
4187 The integer types C<s>, C<S>, C<l>, and C<L> may be
4188 followed by a C<!> modifier to specify native shorts or
4189 longs.  As shown in the example above, a bare C<l> means
4190 exactly 32 bits, although the native C<long> as seen by the local C compiler
4191 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4192 see whether using C<!> makes any difference this way:
4193
4194     printf "format s is %d, s! is %d\n", 
4195         length pack("s"), length pack("s!");
4196
4197     printf "format l is %d, l! is %d\n", 
4198         length pack("l"), length pack("l!");
4199
4200
4201 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4202 they are identical to C<i> and C<I>.
4203
4204 The actual sizes (in bytes) of native shorts, ints, longs, and long
4205 longs on the platform where Perl was built are also available from
4206 the command line:
4207
4208     $ perl -V:{short,int,long{,long}}size
4209     shortsize='2';
4210     intsize='4';
4211     longsize='4';
4212     longlongsize='8';
4213
4214 or programmatically via the C<Config> module:
4215
4216        use Config;
4217        print $Config{shortsize},    "\n";
4218        print $Config{intsize},      "\n";
4219        print $Config{longsize},     "\n";
4220        print $Config{longlongsize}, "\n";
4221
4222 C<$Config{longlongsize}> is undefined on systems without 
4223 long long support.
4224
4225 =item *
4226
4227 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4228 inherently non-portable between processors and operating systems because
4229 they obey native byteorder and endianness.  For example, a 4-byte integer
4230 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4231 handled by the CPU registers) into bytes as
4232
4233     0x12 0x34 0x56 0x78  # big-endian
4234     0x78 0x56 0x34 0x12  # little-endian
4235
4236 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4237 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4238 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4239 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4240
4241 The names I<big-endian> and I<little-endian> are comic references to the
4242 egg-eating habits of the little-endian Lilliputians and the big-endian
4243 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4244 This entered computer lingo via the paper "On Holy Wars and a Plea for
4245 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4246
4247 Some systems may have even weirder byte orders such as
4248
4249    0x56 0x78 0x12 0x34
4250    0x34 0x12 0x78 0x56
4251
4252 You can determine your system endianness with this incantation:
4253
4254    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4255
4256 The byteorder on the platform where Perl was built is also available
4257 via L<Config>:
4258
4259     use Config;
4260     print "$Config{byteorder}\n";
4261
4262 or from the command line:
4263
4264     $ perl -V:byteorder
4265
4266 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4267 and C<"87654321"> are big-endian.
4268
4269 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4270 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4271 immediately below.  See also L<perlport>.
4272
4273 =item *
4274
4275 Starting with Perl 5.9.2, integer and floating-point formats, along with
4276 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4277 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4278 or little-endian byte-order.  These modifiers are especially useful 
4279 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4280 64-bit integers, or floating-point values.
4281
4282 Here are some concerns to keep in mind when using an endianness modifier:
4283
4284 =over
4285
4286 =item * 
4287
4288 Exchanging signed integers between different platforms works only 
4289 when all platforms store them in the same format.  Most platforms store
4290 signed integers in two's-complement notation, so usually this is not an issue.
4291
4292 =item * 
4293
4294 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4295 formats on big- or little-endian machines.  Otherwise, attempting to
4296 use them raises an exception.
4297
4298 =item * 
4299
4300 Forcing big- or little-endian byte-order on floating-point values for
4301 data exchange can work only if all platforms use the same
4302 binary representation such as IEEE floating-point.  Even if all
4303 platforms are using IEEE, there may still be subtle differences.  Being able
4304 to use C<< > >> or C<< < >> on floating-point values can be useful,
4305 but also dangerous if you don't know exactly what you're doing.
4306 It is not a general way to portably store floating-point values.
4307
4308 =item * 
4309
4310 When using C<< > >> or C<< < >> on a C<()> group, this affects
4311 all types inside the group that accept byte-order modifiers,
4312 including all subgroups.  It is silently ignored for all other
4313 types.  You are not allowed to override the byte-order within a group
4314 that already has a byte-order modifier suffix.
4315
4316 =back
4317
4318 =item *
4319
4320 Real numbers (floats and doubles) are in native machine format only.
4321 Due to the multiplicity of floating-point formats and the lack of a
4322 standard "network" representation for them, no facility for interchange has been
4323 made.  This means that packed floating-point data written on one machine
4324 may not be readable on another, even if both use IEEE floating-point
4325 arithmetic (because the endianness of the memory representation is not part
4326 of the IEEE spec).  See also L<perlport>.
4327
4328 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4329 modifiers to force big- or little-endian byte-order on floating-point values.
4330
4331 Because Perl uses doubles (or long doubles, if configured) internally for
4332 all numeric calculation, converting from double into float and thence 
4333 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4334 will not in general equal $foo.
4335
4336 =item *
4337
4338 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4339 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4340 where the packed string is processed in its UTF-8-encoded Unicode form on
4341 a byte-by-byte basis. Character mode is the default unless the format string 
4342 starts with C<U>. You can always switch mode mid-format with an explicit 
4343 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4344 mode change, or until the end of the C<()> group it (directly) applies to.
4345
4346 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4347 bytes is not necessarily obvious.   Probably only the first of these
4348 is what you want:
4349
4350     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4351       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4352     03B1.03C9
4353     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4354       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4355     CE.B1.CF.89
4356     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4357       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4358     CE.B1.CF.89
4359     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4360       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4361     C3.8E.C2.B1.C3.8F.C2.89
4362
4363 Those examples also illustrate that you should not try to use
4364 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4365
4366 =item *
4367
4368 You must yourself do any alignment or padding by inserting, for example,
4369 enough C<"x">es while packing.  There is no way for pack() and unpack()
4370 to know where characters are going to or coming from, so they 
4371 handle their output and input as flat sequences of characters.
4372
4373 =item *
4374
4375 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4376 take a repeat count either as postfix, or for unpack(), also via the C</>
4377 template character.  Within each repetition of a group, positioning with
4378 C<@> starts over at 0. Therefore, the result of
4379
4380     pack("@1A((@2A)@3A)", qw[X Y Z])
4381
4382 is the string C<"\0X\0\0YZ">.
4383
4384 =item *
4385
4386 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4387 jump forward or back to the closest position aligned at a multiple of C<count>
4388 characters. For example, to pack() or unpack() a C structure like
4389
4390     struct {
4391         char   c;    /* one signed, 8-bit character */
4392         double d; 
4393         char   cc[2];
4394     }
4395
4396 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4397 doubles must be aligned to the size of double.
4398
4399 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4400 both are no-ops.
4401
4402 =item *
4403
4404 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4405 represent signed 16-/32-bit integers in big-/little-endian order.
4406 This is portable only when all platforms sharing packed data use the
4407 same binary representation for signed integers; for example, when all
4408 platforms use two's-complement representation.
4409
4410 =item *
4411
4412 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4413 White space can separate pack codes from each other, but modifiers and
4414 repeat counts must follow immediately.  Breaking complex templates into
4415 individual line-by-line components, suitably annotated, can do as much to
4416 improve legibility and maintainability of pack/unpack formats as C</x> can
4417 for complicated pattern matches.
4418
4419 =item *
4420
4421 If TEMPLATE requires more arguments than pack() is given, pack()
4422 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4423 than given, extra arguments are ignored.
4424
4425 =back
4426
4427 Examples:
4428
4429     $foo = pack("WWWW",65,66,67,68);
4430     # foo eq "ABCD"
4431     $foo = pack("W4",65,66,67,68);
4432     # same thing
4433     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4434     # same thing with Unicode circled letters.
4435     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4436     # same thing with Unicode circled letters. You don't get the UTF-8
4437     # bytes because the U at the start of the format caused a switch to
4438     # U0-mode, so the UTF-8 bytes get joined into characters
4439     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4440     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4441     # This is the UTF-8 encoding of the string in the previous example
4442
4443     $foo = pack("ccxxcc",65,66,67,68);
4444     # foo eq "AB\0\0CD"
4445
4446     # NOTE: The examples above featuring "W" and "c" are true
4447     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4448     # and UTF-8.  On EBCDIC systems, the first example would be
4449     #      $foo = pack("WWWW",193,194,195,196);
4450
4451     $foo = pack("s2",1,2);
4452     # "\001\000\002\000" on little-endian
4453     # "\000\001\000\002" on big-endian
4454
4455     $foo = pack("a4","abcd","x","y","z");
4456     # "abcd"
4457
4458     $foo = pack("aaaa","abcd","x","y","z");
4459     # "axyz"
4460
4461     $foo = pack("a14","abcdefg");
4462     # "abcdefg\0\0\0\0\0\0\0"
4463
4464     $foo = pack("i9pl", gmtime);
4465     # a real struct tm (on my system anyway)
4466
4467     $utmp_template = "Z8 Z8 Z16 L";
4468     $utmp = pack($utmp_template, @utmp1);
4469     # a struct utmp (BSDish)
4470
4471     @utmp2 = unpack($utmp_template, $utmp);
4472     # "@utmp1" eq "@utmp2"
4473
4474     sub bintodec {
4475         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4476     }
4477
4478     $foo = pack('sx2l', 12, 34);
4479     # short 12, two zero bytes padding, long 34
4480     $bar = pack('s@4l', 12, 34);
4481     # short 12, zero fill to position 4, long 34
4482     # $foo eq $bar
4483     $baz = pack('s.l', 12, 4, 34);
4484     # short 12, zero fill to position 4, long 34
4485
4486     $foo = pack('nN', 42, 4711);
4487     # pack big-endian 16- and 32-bit unsigned integers
4488     $foo = pack('S>L>', 42, 4711);
4489     # exactly the same
4490     $foo = pack('s<l<', -42, 4711);
4491     # pack little-endian 16- and 32-bit signed integers
4492     $foo = pack('(sl)<', -42, 4711);
4493     # exactly the same
4494
4495 The same template may generally also be used in unpack().
4496
4497 =item package NAMESPACE
4498
4499 =item package NAMESPACE VERSION
4500 X<package> X<module> X<namespace> X<version>
4501
4502 =item package NAMESPACE BLOCK
4503
4504 =item package NAMESPACE VERSION BLOCK
4505 X<package> X<module> X<namespace> X<version>
4506
4507 Declares the BLOCK or the rest of the compilation unit as being in the
4508 given namespace.  The scope of the package declaration is either the
4509 supplied code BLOCK or, in the absence of a BLOCK, from the declaration
4510 itself through the end of current scope (the enclosing block, file, or
4511 C<eval>).  That is, the forms without a BLOCK are operative through the end
4512 of the current scope, just like the C<my>, C<state>, and C<our> operators.
4513 All unqualified dynamic identifiers in this scope will be in the given
4514 namespace, except where overridden by another C<package> declaration or
4515 when they're one of the special identifiers that qualify into C<main::>,
4516 like C<STDOUT>, C<ARGV>, C<ENV>, and the punctuation variables.
4517
4518 A package statement affects dynamic variables only, including those
4519 you've used C<local> on, but I<not> lexical variables, which are created
4520 with C<my>, C<state>, or C<our>.  Typically it would be the first 
4521 declaration in a file included by C<require> or C<use>.  You can switch into a
4522 package in more than one place, since this only determines which default 
4523 symbol table the compiler uses for the rest of that block.  You can refer to
4524 identifiers in other packages than the current one by prefixing the identifier
4525 with the package name and a double colon, as in C<$SomePack::var>
4526 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4527 package as assumed.  That is, C<$::sail> is equivalent to
4528 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4529 code, mostly from Perl 4).
4530
4531 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4532 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4533 "strict" style version number as defined by the L<version> module: a positive
4534 decimal number (integer or decimal-fraction) without exponentiation or else a
4535 dotted-decimal v-string with a leading 'v' character and at least three
4536 components.  You should set C<$VERSION> only once per package.
4537
4538 See L<perlmod/"Packages"> for more information about packages, modules,
4539 and classes.  See L<perlsub> for other scoping issues.
4540
4541 =item pipe READHANDLE,WRITEHANDLE
4542 X<pipe>
4543
4544 Opens a pair of connected pipes like the corresponding system call.
4545 Note that if you set up a loop of piped processes, deadlock can occur
4546 unless you are very careful.  In addition, note that Perl's pipes use
4547 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4548 after each command, depending on the application.
4549
4550 See L<IPC::Open2>, L<IPC::Open3>, and
4551 L<perlipc/"Bidirectional Communication with Another Process">
4552 for examples of such things.
4553
4554 On systems that support a close-on-exec flag on files, that flag is set
4555 on all newly opened file descriptors whose C<fileno>s are I<higher> than 
4556 the current value of $^F (by default 2 for C<STDERR>).  See L<perlvar/$^F>.
4557
4558 =item pop ARRAY
4559 X<pop> X<stack>
4560
4561 =item pop EXPR
4562
4563 =item pop
4564
4565 Pops and returns the last value of the array, shortening the array by
4566 one element.
4567
4568 Returns the undefined value if the array is empty, although this may also
4569 happen at other times.  If ARRAY is omitted, pops the C<@ARGV> array in the
4570 main program, but the C<@_> array in subroutines, just like C<shift>.
4571
4572 Starting with Perl 5.14, C<pop> can take a scalar EXPR, which must hold a
4573 reference to an unblessed array.  The argument will be dereferenced
4574 automatically.  This aspect of C<pop> is considered highly experimental.
4575 The exact behaviour may change in a future version of Perl.
4576
4577 =item pos SCALAR
4578 X<pos> X<match, position>
4579
4580 =item pos
4581
4582 Returns the offset of where the last C<m//g> search left off for the
4583 variable in question (C<$_> is used when the variable is not
4584 specified). Note that 0 is a valid match offset. C<undef> indicates
4585 that the search position is reset (usually due to match failure, but
4586 can also be because no match has yet been run on the scalar).
4587
4588 C<pos> directly accesses the location used by the regexp engine to
4589 store the offset, so assigning to C<pos> will change that offset, and
4590 so will also influence the C<\G> zero-width assertion in regular
4591 expressions. Both of these effects take place for the next match, so
4592 you can't affect the position with C<pos> during the current match,
4593 such as in C<(?{pos() = 5})> or C<s//pos() = 5/e>.
4594
4595 Setting C<pos> also resets the I<matched with zero-length> flag, described
4596 under L<perlre/"Repeated Patterns Matching a Zero-length Substring">.
4597
4598 Because a failed C<m//gc> match doesn't reset the offset, the return
4599 from C<pos> won't change either in this case.  See L<perlre> and
4600 L<perlop>.
4601
4602 =item print FILEHANDLE LIST
4603 X<print>
4604
4605 =item print FILEHANDLE
4606
4607 =item print LIST
4608
4609 =item print
4610
4611 Prints a string or a list of strings.  Returns true if successful.
4612 FILEHANDLE may be a scalar variable containing the name of or a reference
4613 to the filehandle, thus introducing one level of indirection.  (NOTE: If
4614 FILEHANDLE is a variable and the next token is a term, it may be
4615 misinterpreted as an operator unless you interpose a C<+> or put
4616 parentheses around the arguments.) If FILEHANDLE is omitted, prints to the
4617 last selected (see L</select>) output handle.  If LIST is omitted, prints
4618 C<$_> to the currently selected output handle.  To use FILEHANDLE alone to
4619 print the content of C<$_> to it, you must use a real filehandle like
4620 C<FH>, not an indirect one like C<$fh>.  To set the default output handle
4621 to something other than STDOUT, use the select operation.
4622
4623 The current value of C<$,> (if any) is printed between each LIST item.  The
4624 current value of C<$\> (if any) is printed after the entire LIST has been
4625 printed.  Because print takes a LIST, anything in the LIST is evaluated in
4626 list context, including any subroutines whose return lists you pass to
4627 C<print>.  Be careful not to follow the print keyword with a left
4628 parenthesis unless you want the corresponding right parenthesis to
4629 terminate the arguments to the print; put parentheses around all arguments
4630 (or interpose a C<+>, but that doesn't look as good).
4631
4632 If you're storing handles in an array or hash, or in general whenever
4633 you're using any expression more complex than a bareword handle or a plain,
4634 unsubscripted scalar variable to retrieve it, you will have to use a block
4635 returning the filehandle value instead, in which case the LIST may not be
4636 omitted:
4637
4638     print { $files[$i] } "stuff\n";
4639     print { $OK ? STDOUT : STDERR } "stuff\n";
4640
4641 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4642 L<perlipc> for more on signal handling.
4643
4644 =item printf FILEHANDLE FORMAT, LIST
4645 X<printf>
4646
4647 =item printf FILEHANDLE
4648
4649 =item printf FORMAT, LIST
4650
4651 =item printf
4652
4653 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4654 (the output record separator) is not appended.  The first argument of the
4655 list will be interpreted as the C<printf> format. See C<sprintf> for an
4656 explanation of the format argument.    If you omit the LIST, C<$_> is used;
4657 to use FILEHANDLE without a LIST, you must use a real filehandle like
4658 C<FH>, not an indirect one like C<$fh>.  If C<use locale> is in effect and
4659 POSIX::setlocale() has been called, the character used for the decimal
4660 separator in formatted floating-point numbers is affected by the LC_NUMERIC
4661 locale setting.  See L<perllocale> and L<POSIX>.
4662
4663 Don't fall into the trap of using a C<printf> when a simple
4664 C<print> would do.  The C<print> is more efficient and less
4665 error prone.
4666
4667 =item prototype FUNCTION