This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
be9290b72ce53f429f272abc2b74bdbd8b268cd8
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed-length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>,
165 C<dump>, C<eval>, C<evalbytes> C<exit>,
166 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
167 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
168
169 C<__SUB__> is only available with a C<use v5.16> (or higher) declaration or
170 with the C<"current_sub"> feature (see L<feature>).
171
172 =item Keywords related to the switch feature
173
174 C<break>, C<continue>, C<default>, C<given>, C<when>
175
176 Except for C<continue>, these are available only if you enable the
177 C<"switch"> feature or use the C<CORE::> prefix.
178 See L<feature> and L<perlsyn/"Switch statements">.  
179 Alternately, include a C<use v5.10> or later to the current scope.  In Perl
180 5.14 and earlier, C<continue> required the C<"switch"> feature, like the
181 other keywords.
182
183 =item Keywords related to scoping
184
185 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
186
187 C<state> is available only if the C<"state"> feature
188 is enabled or if it is prefixed with C<CORE::>. See
189 L<feature>.  Alternately, include a C<use v5.10> or later to the current scope.
190
191 =item Miscellaneous functions
192
193 C<defined>, C<dump>, C<eval>, C<evalbytes>,
194 C<formline>, C<local>, C<my>, C<our>,
195 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
196
197 =item Functions for processes and process groups
198 X<process> X<pid> X<process id>
199
200 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
201 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
202 C<setpriority>, C<sleep>, C<system>,
203 C<times>, C<wait>, C<waitpid>
204
205 =item Keywords related to Perl modules
206 X<module>
207
208 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
209
210 =item Keywords related to classes and object-orientation
211 X<object> X<class> X<package>
212
213 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
214 C<untie>, C<use>
215
216 =item Low-level socket functions
217 X<socket> X<sock>
218
219 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
220 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
221 C<socket>, C<socketpair>
222
223 =item System V interprocess communication functions
224 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
225
226 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
227 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
228
229 =item Fetching user and group info
230 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
231
232 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
233 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
234 C<getpwuid>, C<setgrent>, C<setpwent>
235
236 =item Fetching network info
237 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
238
239 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
240 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
241 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
242 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
243 C<setnetent>, C<setprotoent>, C<setservent>
244
245 =item Time-related functions
246 X<time> X<date>
247
248 C<gmtime>, C<localtime>, C<time>, C<times>
249
250 =item Functions new in perl5
251 X<perl5>
252
253 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
254 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
255 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
256 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
257 C<ucfirst>, C<untie>, C<use>, C<when>
258
259 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
260 operator, which can be used in expressions.
261
262 =item Functions obsoleted in perl5
263
264 C<dbmclose>, C<dbmopen>
265
266 =back
267
268 =head2 Portability
269 X<portability> X<Unix> X<portable>
270
271 Perl was born in Unix and can therefore access all common Unix
272 system calls.  In non-Unix environments, the functionality of some
273 Unix system calls may not be available or details of the available
274 functionality may differ slightly.  The Perl functions affected
275 by this are:
276
277 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
278 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
279 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
280 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
281 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
282 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
283 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
284 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
285 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
286 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
287 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
288 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
289 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
290 C<shmwrite>, C<socket>, C<socketpair>,
291 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
292 C<times>, C<truncate>, C<umask>, C<unlink>,
293 C<utime>, C<wait>, C<waitpid>
294
295 For more information about the portability of these functions, see
296 L<perlport> and other available platform-specific documentation.
297
298 =head2 Alphabetical Listing of Perl Functions
299
300 =over 
301
302 =item -X FILEHANDLE
303 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
304 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
305
306 =item -X EXPR
307
308 =item -X DIRHANDLE
309
310 =item -X
311
312 A file test, where X is one of the letters listed below.  This unary
313 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
314 and tests the associated file to see if something is true about it.  If the
315 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
316 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
317 the undefined value if the file doesn't exist.  Despite the funny
318 names, precedence is the same as any other named unary operator.  The
319 operator may be any of:
320
321     -r  File is readable by effective uid/gid.
322     -w  File is writable by effective uid/gid.
323     -x  File is executable by effective uid/gid.
324     -o  File is owned by effective uid.
325
326     -R  File is readable by real uid/gid.
327     -W  File is writable by real uid/gid.
328     -X  File is executable by real uid/gid.
329     -O  File is owned by real uid.
330
331     -e  File exists.
332     -z  File has zero size (is empty).
333     -s  File has nonzero size (returns size in bytes).
334
335     -f  File is a plain file.
336     -d  File is a directory.
337     -l  File is a symbolic link.
338     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
339     -S  File is a socket.
340     -b  File is a block special file.
341     -c  File is a character special file.
342     -t  Filehandle is opened to a tty.
343
344     -u  File has setuid bit set.
345     -g  File has setgid bit set.
346     -k  File has sticky bit set.
347
348     -T  File is an ASCII text file (heuristic guess).
349     -B  File is a "binary" file (opposite of -T).
350
351     -M  Script start time minus file modification time, in days.
352     -A  Same for access time.
353     -C  Same for inode change time (Unix, may differ for other platforms)
354
355 Example:
356
357     while (<>) {
358         chomp;
359         next unless -f $_;  # ignore specials
360         #...
361     }
362
363 Note that C<-s/a/b/> does not do a negated substitution.  Saying
364 C<-exp($foo)> still works as expected, however: only single letters
365 following a minus are interpreted as file tests.
366
367 These operators are exempt from the "looks like a function rule" described
368 above.  That is, an opening parenthesis after the operator does not affect
369 how much of the following code constitutes the argument.  Put the opening
370 parentheses before the operator to separate it from code that follows (this
371 applies only to operators with higher precedence than unary operators, of
372 course):
373
374     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
375     (-s $file) + 1024  # correct
376
377 The interpretation of the file permission operators C<-r>, C<-R>,
378 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
379 of the file and the uids and gids of the user.  There may be other
380 reasons you can't actually read, write, or execute the file: for
381 example network filesystem access controls, ACLs (access control lists),
382 read-only filesystems, and unrecognized executable formats.  Note
383 that the use of these six specific operators to verify if some operation
384 is possible is usually a mistake, because it may be open to race
385 conditions.
386
387 Also note that, for the superuser on the local filesystems, the C<-r>,
388 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
389 if any execute bit is set in the mode.  Scripts run by the superuser
390 may thus need to do a stat() to determine the actual mode of the file,
391 or temporarily set their effective uid to something else.
392
393 If you are using ACLs, there is a pragma called C<filetest> that may
394 produce more accurate results than the bare stat() mode bits.
395 When under C<use filetest 'access'> the above-mentioned filetests
396 test whether the permission can(not) be granted using the
397 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
398 under this pragma return true even if there are no execute permission
399 bits set (nor any extra execute permission ACLs).  This strangeness is
400 due to the underlying system calls' definitions. Note also that, due to
401 the implementation of C<use filetest 'access'>, the C<_> special
402 filehandle won't cache the results of the file tests when this pragma is
403 in effect.  Read the documentation for the C<filetest> pragma for more
404 information.
405
406 The C<-T> and C<-B> switches work as follows.  The first block or so of the
407 file is examined for odd characters such as strange control codes or
408 characters with the high bit set.  If too many strange characters (>30%)
409 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
410 containing a zero byte in the first block is considered a binary file.  If C<-T>
411 or C<-B> is used on a filehandle, the current IO buffer is examined
412 rather than the first block.  Both C<-T> and C<-B> return true on an empty
413 file, or a file at EOF when testing a filehandle.  Because you have to
414 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
415 against the file first, as in C<next unless -f $file && -T $file>.
416
417 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
418 the special filehandle consisting of a solitary underline, then the stat
419 structure of the previous file test (or stat operator) is used, saving
420 a system call.  (This doesn't work with C<-t>, and you need to remember
421 that lstat() and C<-l> leave values in the stat structure for the
422 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
423 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
424 Example:
425
426     print "Can do.\n" if -r $a || -w _ || -x _;
427
428     stat($filename);
429     print "Readable\n" if -r _;
430     print "Writable\n" if -w _;
431     print "Executable\n" if -x _;
432     print "Setuid\n" if -u _;
433     print "Setgid\n" if -g _;
434     print "Sticky\n" if -k _;
435     print "Text\n" if -T _;
436     print "Binary\n" if -B _;
437
438 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
439 test operators, in a way that C<-f -w -x $file> is equivalent to
440 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
441 the return value of C<-f $file> as an argument to another filetest
442 operator, no special magic will happen.)
443
444 Portability issues: L<perlport/-X>.
445
446 =item abs VALUE
447 X<abs> X<absolute>
448
449 =item abs
450
451 Returns the absolute value of its argument.
452 If VALUE is omitted, uses C<$_>.
453
454 =item accept NEWSOCKET,GENERICSOCKET
455 X<accept>
456
457 Accepts an incoming socket connect, just as accept(2) 
458 does.  Returns the packed address if it succeeded, false otherwise.
459 See the example in L<perlipc/"Sockets: Client/Server Communication">.
460
461 On systems that support a close-on-exec flag on files, the flag will
462 be set for the newly opened file descriptor, as determined by the
463 value of $^F.  See L<perlvar/$^F>.
464
465 =item alarm SECONDS
466 X<alarm>
467 X<SIGALRM>
468 X<timer>
469
470 =item alarm
471
472 Arranges to have a SIGALRM delivered to this process after the
473 specified number of wallclock seconds has elapsed.  If SECONDS is not
474 specified, the value stored in C<$_> is used. (On some machines,
475 unfortunately, the elapsed time may be up to one second less or more
476 than you specified because of how seconds are counted, and process
477 scheduling may delay the delivery of the signal even further.)
478
479 Only one timer may be counting at once.  Each call disables the
480 previous timer, and an argument of C<0> may be supplied to cancel the
481 previous timer without starting a new one.  The returned value is the
482 amount of time remaining on the previous timer.
483
484 For delays of finer granularity than one second, the Time::HiRes module
485 (from CPAN, and starting from Perl 5.8 part of the standard
486 distribution) provides ualarm().  You may also use Perl's four-argument
487 version of select() leaving the first three arguments undefined, or you
488 might be able to use the C<syscall> interface to access setitimer(2) if
489 your system supports it. See L<perlfaq8> for details.
490
491 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
492 C<sleep> may be internally implemented on your system with C<alarm>.
493
494 If you want to use C<alarm> to time out a system call you need to use an
495 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
496 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
497 restart system calls on some systems.  Using C<eval>/C<die> always works,
498 modulo the caveats given in L<perlipc/"Signals">.
499
500     eval {
501         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
502         alarm $timeout;
503         $nread = sysread SOCKET, $buffer, $size;
504         alarm 0;
505     };
506     if ($@) {
507         die unless $@ eq "alarm\n";   # propagate unexpected errors
508         # timed out
509     }
510     else {
511         # didn't
512     }
513
514 For more information see L<perlipc>.
515
516 Portability issues: L<perlport/alarm>.
517
518 =item atan2 Y,X
519 X<atan2> X<arctangent> X<tan> X<tangent>
520
521 Returns the arctangent of Y/X in the range -PI to PI.
522
523 For the tangent operation, you may use the C<Math::Trig::tan>
524 function, or use the familiar relation:
525
526     sub tan { sin($_[0]) / cos($_[0])  }
527
528 The return value for C<atan2(0,0)> is implementation-defined; consult
529 your atan2(3) manpage for more information.
530
531 Portability issues: L<perlport/atan2>.
532
533 =item bind SOCKET,NAME
534 X<bind>
535
536 Binds a network address to a socket, just as bind(2)
537 does.  Returns true if it succeeded, false otherwise.  NAME should be a
538 packed address of the appropriate type for the socket.  See the examples in
539 L<perlipc/"Sockets: Client/Server Communication">.
540
541 =item binmode FILEHANDLE, LAYER
542 X<binmode> X<binary> X<text> X<DOS> X<Windows>
543
544 =item binmode FILEHANDLE
545
546 Arranges for FILEHANDLE to be read or written in "binary" or "text"
547 mode on systems where the run-time libraries distinguish between
548 binary and text files.  If FILEHANDLE is an expression, the value is
549 taken as the name of the filehandle.  Returns true on success,
550 otherwise it returns C<undef> and sets C<$!> (errno).
551
552 On some systems (in general, DOS- and Windows-based systems) binmode()
553 is necessary when you're not working with a text file.  For the sake
554 of portability it is a good idea always to use it when appropriate,
555 and never to use it when it isn't appropriate.  Also, people can
556 set their I/O to be by default UTF8-encoded Unicode, not bytes.
557
558 In other words: regardless of platform, use binmode() on binary data,
559 like images, for example.
560
561 If LAYER is present it is a single string, but may contain multiple
562 directives. The directives alter the behaviour of the filehandle.
563 When LAYER is present, using binmode on a text file makes sense.
564
565 If LAYER is omitted or specified as C<:raw> the filehandle is made
566 suitable for passing binary data. This includes turning off possible CRLF
567 translation and marking it as bytes (as opposed to Unicode characters).
568 Note that, despite what may be implied in I<"Programming Perl"> (the
569 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
570 Other layers that would affect the binary nature of the stream are
571 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
572 PERLIO environment variable.
573
574 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
575 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
576 establish default I/O layers.  See L<open>.
577
578 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
579 in "Programming Perl, 3rd Edition".  However, since the publishing of this
580 book, by many known as "Camel III", the consensus of the naming of this
581 functionality has moved from "discipline" to "layer".  All documentation
582 of this version of Perl therefore refers to "layers" rather than to
583 "disciplines".  Now back to the regularly scheduled documentation...>
584
585 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
586 C<:utf8> just marks the data as UTF-8 without further checking,
587 while C<:encoding(UTF-8)> checks the data for actually being valid
588 UTF-8. More details can be found in L<PerlIO::encoding>.
589
590 In general, binmode() should be called after open() but before any I/O
591 is done on the filehandle.  Calling binmode() normally flushes any
592 pending buffered output data (and perhaps pending input data) on the
593 handle.  An exception to this is the C<:encoding> layer that
594 changes the default character encoding of the handle; see L</open>.
595 The C<:encoding> layer sometimes needs to be called in
596 mid-stream, and it doesn't flush the stream.  The C<:encoding>
597 also implicitly pushes on top of itself the C<:utf8> layer because
598 internally Perl operates on UTF8-encoded Unicode characters.
599
600 The operating system, device drivers, C libraries, and Perl run-time
601 system all conspire to let the programmer treat a single
602 character (C<\n>) as the line terminator, irrespective of external
603 representation.  On many operating systems, the native text file
604 representation matches the internal representation, but on some
605 platforms the external representation of C<\n> is made up of more than
606 one character.
607
608 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
609 a single character to end each line in the external representation of text
610 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
611 flavors of Mac OS, and is LINE FEED on Unix and most VMS files). In other
612 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
613 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
614 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
615 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
616 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
617 output.  This is what you want for text files, but it can be disastrous for
618 binary files.
619
620 Another consequence of using binmode() (on some systems) is that
621 special end-of-file markers will be seen as part of the data stream.
622 For systems from the Microsoft family this means that, if your binary
623 data contain C<\cZ>, the I/O subsystem will regard it as the end of
624 the file, unless you use binmode().
625
626 binmode() is important not only for readline() and print() operations,
627 but also when using read(), seek(), sysread(), syswrite() and tell()
628 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
629 in L<perlvar> for how to manually set your input and output
630 line-termination sequences.
631
632 Portability issues: L<perlport/binmode>.
633
634 =item bless REF,CLASSNAME
635 X<bless>
636
637 =item bless REF
638
639 This function tells the thingy referenced by REF that it is now an object
640 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
641 is used.  Because a C<bless> is often the last thing in a constructor,
642 it returns the reference for convenience.  Always use the two-argument
643 version if a derived class might inherit the function doing the blessing.
644 SeeL<perlobj> for more about the blessing (and blessings) of objects.
645
646 Consider always blessing objects in CLASSNAMEs that are mixed case.
647 Namespaces with all lowercase names are considered reserved for
648 Perl pragmata.  Builtin types have all uppercase names. To prevent
649 confusion, you may wish to avoid such package names as well.  Make sure
650 that CLASSNAME is a true value.
651
652 See L<perlmod/"Perl Modules">.
653
654 =item break
655
656 Break out of a C<given()> block.
657
658 This keyword is enabled by the C<"switch"> feature: see
659 L<feature> for more information.  You can also access it by
660 prefixing it with C<CORE::>.  Alternately, include a C<use
661 v5.10> or later to the current scope.
662
663 =item caller EXPR
664 X<caller> X<call stack> X<stack> X<stack trace>
665
666 =item caller
667
668 Returns the context of the current subroutine call.  In scalar context,
669 returns the caller's package name if there I<is> a caller (that is, if
670 we're in a subroutine or C<eval> or C<require>) and the undefined value
671 otherwise.  In list context, returns
672
673     # 0         1          2
674     ($package, $filename, $line) = caller;
675
676 With EXPR, it returns some extra information that the debugger uses to
677 print a stack trace.  The value of EXPR indicates how many call frames
678 to go back before the current one.
679
680     #  0         1          2      3            4
681     ($package, $filename, $line, $subroutine, $hasargs,
682
683     #  5          6          7            8       9         10
684     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
685      = caller($i);
686
687 Here $subroutine may be C<(eval)> if the frame is not a subroutine
688 call, but an C<eval>.  In such a case additional elements $evaltext and
689 C<$is_require> are set: C<$is_require> is true if the frame is created by a
690 C<require> or C<use> statement, $evaltext contains the text of the
691 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
692 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
693 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
694 frame.)  $subroutine may also be C<(unknown)> if this particular
695 subroutine happens to have been deleted from the symbol table.
696 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
697 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
698 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
699 between versions of Perl, and are not meant for external use.
700
701 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
702 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
703 of this hash, as they are the actual values stored in the optree.
704
705 Furthermore, when called from within the DB package, caller returns more
706 detailed information: it sets the list variable C<@DB::args> to be the
707 arguments with which the subroutine was invoked.
708
709 Be aware that the optimizer might have optimized call frames away before
710 C<caller> had a chance to get the information.  That means that C<caller(N)>
711 might not return information about the call frame you expect it to, for
712 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
713 previous time C<caller> was called.
714
715 Be aware that setting C<@DB::args> is I<best effort>, intended for
716 debugging or generating backtraces, and should not be relied upon. In
717 particular, as C<@_> contains aliases to the caller's arguments, Perl does
718 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
719 subroutine makes to C<@_> or its contents, not the original values at call
720 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
721 elements, so under certain cases its elements may have become freed and
722 reallocated for other variables or temporary values. Finally, a side effect
723 of the current implementation is that the effects of C<shift @_> can
724 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
725 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
726 elements), so C<@DB::args> is actually a hybrid of the current state and
727 initial state of C<@_>. Buyer beware.
728
729 =item chdir EXPR
730 X<chdir>
731 X<cd>
732 X<directory, change>
733
734 =item chdir FILEHANDLE
735
736 =item chdir DIRHANDLE
737
738 =item chdir
739
740 Changes the working directory to EXPR, if possible. If EXPR is omitted,
741 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
742 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
743 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
744 neither is set, C<chdir> does nothing. It returns true on success,
745 false otherwise. See the example under C<die>.
746
747 On systems that support fchdir(2), you may pass a filehandle or
748 directory handle as the argument.  On systems that don't support fchdir(2),
749 passing handles raises an exception.
750
751 =item chmod LIST
752 X<chmod> X<permission> X<mode>
753
754 Changes the permissions of a list of files.  The first element of the
755 list must be the numeric mode, which should probably be an octal
756 number, and which definitely should I<not> be a string of octal digits:
757 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
758 successfully changed.  See also L</oct> if all you have is a string.
759
760     $cnt = chmod 0755, "foo", "bar";
761     chmod 0755, @executables;
762     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
763                                              # --w----r-T
764     $mode = "0644"; chmod oct($mode), "foo"; # this is better
765     $mode = 0644;   chmod $mode, "foo";      # this is best
766
767 On systems that support fchmod(2), you may pass filehandles among the
768 files.  On systems that don't support fchmod(2), passing filehandles raises
769 an exception.  Filehandles must be passed as globs or glob references to be
770 recognized; barewords are considered filenames.
771
772     open(my $fh, "<", "foo");
773     my $perm = (stat $fh)[2] & 07777;
774     chmod($perm | 0600, $fh);
775
776 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
777 module:
778
779     use Fcntl qw( :mode );
780     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
781     # Identical to the chmod 0755 of the example above.
782
783 Portability issues: L<perlport/chmod>.
784
785 =item chomp VARIABLE
786 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
787
788 =item chomp( LIST )
789
790 =item chomp
791
792 This safer version of L</chop> removes any trailing string
793 that corresponds to the current value of C<$/> (also known as
794 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
795 number of characters removed from all its arguments.  It's often used to
796 remove the newline from the end of an input record when you're worried
797 that the final record may be missing its newline.  When in paragraph
798 mode (C<$/ = "">), it removes all trailing newlines from the string.
799 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
800 a reference to an integer or the like; see L<perlvar>) chomp() won't
801 remove anything.
802 If VARIABLE is omitted, it chomps C<$_>.  Example:
803
804     while (<>) {
805         chomp;  # avoid \n on last field
806         @array = split(/:/);
807         # ...
808     }
809
810 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
811
812 You can actually chomp anything that's an lvalue, including an assignment:
813
814     chomp($cwd = `pwd`);
815     chomp($answer = <STDIN>);
816
817 If you chomp a list, each element is chomped, and the total number of
818 characters removed is returned.
819
820 Note that parentheses are necessary when you're chomping anything
821 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
822 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
823 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
824 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
825 as C<chomp($a, $b)>.
826
827 =item chop VARIABLE
828 X<chop>
829
830 =item chop( LIST )
831
832 =item chop
833
834 Chops off the last character of a string and returns the character
835 chopped.  It is much more efficient than C<s/.$//s> because it neither
836 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
837 If VARIABLE is a hash, it chops the hash's values, but not its keys.
838
839 You can actually chop anything that's an lvalue, including an assignment.
840
841 If you chop a list, each element is chopped.  Only the value of the
842 last C<chop> is returned.
843
844 Note that C<chop> returns the last character.  To return all but the last
845 character, use C<substr($string, 0, -1)>.
846
847 See also L</chomp>.
848
849 =item chown LIST
850 X<chown> X<owner> X<user> X<group>
851
852 Changes the owner (and group) of a list of files.  The first two
853 elements of the list must be the I<numeric> uid and gid, in that
854 order.  A value of -1 in either position is interpreted by most
855 systems to leave that value unchanged.  Returns the number of files
856 successfully changed.
857
858     $cnt = chown $uid, $gid, 'foo', 'bar';
859     chown $uid, $gid, @filenames;
860
861 On systems that support fchown(2), you may pass filehandles among the
862 files.  On systems that don't support fchown(2), passing filehandles raises
863 an exception.  Filehandles must be passed as globs or glob references to be
864 recognized; barewords are considered filenames.
865
866 Here's an example that looks up nonnumeric uids in the passwd file:
867
868     print "User: ";
869     chomp($user = <STDIN>);
870     print "Files: ";
871     chomp($pattern = <STDIN>);
872
873     ($login,$pass,$uid,$gid) = getpwnam($user)
874         or die "$user not in passwd file";
875
876     @ary = glob($pattern);  # expand filenames
877     chown $uid, $gid, @ary;
878
879 On most systems, you are not allowed to change the ownership of the
880 file unless you're the superuser, although you should be able to change
881 the group to any of your secondary groups.  On insecure systems, these
882 restrictions may be relaxed, but this is not a portable assumption.
883 On POSIX systems, you can detect this condition this way:
884
885     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
886     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
887
888 Portability issues: L<perlport/chmod>.
889
890 =item chr NUMBER
891 X<chr> X<character> X<ASCII> X<Unicode>
892
893 =item chr
894
895 Returns the character represented by that NUMBER in the character set.
896 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
897 chr(0x263a) is a Unicode smiley face.  
898
899 Negative values give the Unicode replacement character (chr(0xfffd)),
900 except under the L<bytes> pragma, where the low eight bits of the value
901 (truncated to an integer) are used.
902
903 If NUMBER is omitted, uses C<$_>.
904
905 For the reverse, use L</ord>.
906
907 Note that characters from 128 to 255 (inclusive) are by default
908 internally not encoded as UTF-8 for backward compatibility reasons.
909
910 See L<perlunicode> for more about Unicode.
911
912 =item chroot FILENAME
913 X<chroot> X<root>
914
915 =item chroot
916
917 This function works like the system call by the same name: it makes the
918 named directory the new root directory for all further pathnames that
919 begin with a C</> by your process and all its children.  (It doesn't
920 change your current working directory, which is unaffected.)  For security
921 reasons, this call is restricted to the superuser.  If FILENAME is
922 omitted, does a C<chroot> to C<$_>.
923
924 Portability issues: L<perlport/chroot>.
925
926 =item close FILEHANDLE
927 X<close>
928
929 =item close
930
931 Closes the file or pipe associated with the filehandle, flushes the IO
932 buffers, and closes the system file descriptor.  Returns true if those
933 operations succeed and if no error was reported by any PerlIO
934 layer.  Closes the currently selected filehandle if the argument is
935 omitted.
936
937 You don't have to close FILEHANDLE if you are immediately going to do
938 another C<open> on it, because C<open> closes it for you.  (See
939 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
940 counter (C<$.>), while the implicit close done by C<open> does not.
941
942 If the filehandle came from a piped open, C<close> returns false if one of
943 the other syscalls involved fails or if its program exits with non-zero
944 status.  If the only problem was that the program exited non-zero, C<$!>
945 will be set to C<0>.  Closing a pipe also waits for the process executing
946 on the pipe to exit--in case you wish to look at the output of the pipe
947 afterwards--and implicitly puts the exit status value of that command into
948 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
949
950 If there are multiple threads running, C<close> on a filehandle from a
951 piped open returns true without waiting for the child process to terminate,
952 if the filehandle is still open in another thread.
953
954 Closing the read end of a pipe before the process writing to it at the
955 other end is done writing results in the writer receiving a SIGPIPE.  If
956 the other end can't handle that, be sure to read all the data before
957 closing the pipe.
958
959 Example:
960
961     open(OUTPUT, '|sort >foo')  # pipe to sort
962         or die "Can't start sort: $!";
963     #...                        # print stuff to output
964     close OUTPUT                # wait for sort to finish
965         or warn $! ? "Error closing sort pipe: $!"
966                    : "Exit status $? from sort";
967     open(INPUT, 'foo')          # get sort's results
968         or die "Can't open 'foo' for input: $!";
969
970 FILEHANDLE may be an expression whose value can be used as an indirect
971 filehandle, usually the real filehandle name or an autovivified handle.
972
973 =item closedir DIRHANDLE
974 X<closedir>
975
976 Closes a directory opened by C<opendir> and returns the success of that
977 system call.
978
979 =item connect SOCKET,NAME
980 X<connect>
981
982 Attempts to connect to a remote socket, just like connect(2).
983 Returns true if it succeeded, false otherwise.  NAME should be a
984 packed address of the appropriate type for the socket.  See the examples in
985 L<perlipc/"Sockets: Client/Server Communication">.
986
987 =item continue BLOCK
988 X<continue>
989
990 =item continue
991
992 When followed by a BLOCK, C<continue> is actually a
993 flow control statement rather than a function.  If
994 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
995 C<foreach>), it is always executed just before the conditional is about to
996 be evaluated again, just like the third part of a C<for> loop in C.  Thus
997 it can be used to increment a loop variable, even when the loop has been
998 continued via the C<next> statement (which is similar to the C C<continue>
999 statement).
1000
1001 C<last>, C<next>, or C<redo> may appear within a C<continue>
1002 block; C<last> and C<redo> behave as if they had been executed within
1003 the main block.  So will C<next>, but since it will execute a C<continue>
1004 block, it may be more entertaining.
1005
1006     while (EXPR) {
1007         ### redo always comes here
1008         do_something;
1009     } continue {
1010         ### next always comes here
1011         do_something_else;
1012         # then back the top to re-check EXPR
1013     }
1014     ### last always comes here
1015
1016 Omitting the C<continue> section is equivalent to using an
1017 empty one, logically enough, so C<next> goes directly back
1018 to check the condition at the top of the loop.
1019
1020 When there is no BLOCK, C<continue> is a function that
1021 falls through the current C<when> or C<default> block instead of iterating
1022 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1023 In Perl 5.14 and earlier, this form of C<continue> was
1024 only available when the C<"switch"> feature was enabled.
1025 See L<feature> and L<perlsyn/"Switch statements"> for more
1026 information.
1027
1028 =item cos EXPR
1029 X<cos> X<cosine> X<acos> X<arccosine>
1030
1031 =item cos
1032
1033 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1034 takes the cosine of C<$_>.
1035
1036 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1037 function, or use this relation:
1038
1039     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1040
1041 =item crypt PLAINTEXT,SALT
1042 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1043 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1044
1045 Creates a digest string exactly like the crypt(3) function in the C
1046 library (assuming that you actually have a version there that has not
1047 been extirpated as a potential munition).
1048
1049 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1050 into a short string, called a digest, which is returned.  The same
1051 PLAINTEXT and SALT will always return the same string, but there is no
1052 (known) way to get the original PLAINTEXT from the hash.  Small
1053 changes in the PLAINTEXT or SALT will result in large changes in the
1054 digest.
1055
1056 There is no decrypt function.  This function isn't all that useful for
1057 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1058 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1059 primarily used to check if two pieces of text are the same without
1060 having to transmit or store the text itself.  An example is checking
1061 if a correct password is given.  The digest of the password is stored,
1062 not the password itself.  The user types in a password that is
1063 crypt()'d with the same salt as the stored digest.  If the two digests
1064 match, the password is correct.
1065
1066 When verifying an existing digest string you should use the digest as
1067 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1068 to create the digest is visible as part of the digest.  This ensures
1069 crypt() will hash the new string with the same salt as the digest.
1070 This allows your code to work with the standard L<crypt|/crypt> and
1071 with more exotic implementations.  In other words, assume
1072 nothing about the returned string itself nor about how many bytes 
1073 of SALT may matter.
1074
1075 Traditionally the result is a string of 13 bytes: two first bytes of
1076 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1077 the first eight bytes of PLAINTEXT mattered. But alternative
1078 hashing schemes (like MD5), higher level security schemes (like C2),
1079 and implementations on non-Unix platforms may produce different
1080 strings.
1081
1082 When choosing a new salt create a random two character string whose
1083 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1084 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1085 characters is just a recommendation; the characters allowed in
1086 the salt depend solely on your system's crypt library, and Perl can't
1087 restrict what salts C<crypt()> accepts.
1088
1089 Here's an example that makes sure that whoever runs this program knows
1090 their password:
1091
1092     $pwd = (getpwuid($<))[1];
1093
1094     system "stty -echo";
1095     print "Password: ";
1096     chomp($word = <STDIN>);
1097     print "\n";
1098     system "stty echo";
1099
1100     if (crypt($word, $pwd) ne $pwd) {
1101         die "Sorry...\n";
1102     } else {
1103         print "ok\n";
1104     }
1105
1106 Of course, typing in your own password to whoever asks you
1107 for it is unwise.
1108
1109 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1110 of data, not least of all because you can't get the information
1111 back.  Look at the L<Digest> module for more robust algorithms.
1112
1113 If using crypt() on a Unicode string (which I<potentially> has
1114 characters with codepoints above 255), Perl tries to make sense
1115 of the situation by trying to downgrade (a copy of)
1116 the string back to an eight-bit byte string before calling crypt()
1117 (on that copy).  If that works, good.  If not, crypt() dies with
1118 C<Wide character in crypt>.
1119
1120 Portability issues: L<perlport/crypt>.
1121
1122 =item dbmclose HASH
1123 X<dbmclose>
1124
1125 [This function has been largely superseded by the C<untie> function.]
1126
1127 Breaks the binding between a DBM file and a hash.
1128
1129 Portability issues: L<perlport/dbmclose>.
1130
1131 =item dbmopen HASH,DBNAME,MASK
1132 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1133
1134 [This function has been largely superseded by the
1135 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1136
1137 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1138 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1139 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1140 is the name of the database (without the F<.dir> or F<.pag> extension if
1141 any).  If the database does not exist, it is created with protection
1142 specified by MASK (as modified by the C<umask>).  If your system supports
1143 only the older DBM functions, you may make only one C<dbmopen> call in your
1144 program.  In older versions of Perl, if your system had neither DBM nor
1145 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1146 sdbm(3).
1147
1148 If you don't have write access to the DBM file, you can only read hash
1149 variables, not set them.  If you want to test whether you can write,
1150 either use file tests or try setting a dummy hash entry inside an C<eval> 
1151 to trap the error.
1152
1153 Note that functions such as C<keys> and C<values> may return huge lists
1154 when used on large DBM files.  You may prefer to use the C<each>
1155 function to iterate over large DBM files.  Example:
1156
1157     # print out history file offsets
1158     dbmopen(%HIST,'/usr/lib/news/history',0666);
1159     while (($key,$val) = each %HIST) {
1160         print $key, ' = ', unpack('L',$val), "\n";
1161     }
1162     dbmclose(%HIST);
1163
1164 See also L<AnyDBM_File> for a more general description of the pros and
1165 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1166 rich implementation.
1167
1168 You can control which DBM library you use by loading that library
1169 before you call dbmopen():
1170
1171     use DB_File;
1172     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1173         or die "Can't open netscape history file: $!";
1174
1175 Portability issues: L<perlport/dbmopen>.
1176
1177 =item default BLOCK
1178
1179 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1180 that's always true.  Only available after Perl 5.10, and only if the
1181 C<switch> feature has been requested or if the keyword is prefixed with
1182 C<CORE::>.  See L</when>.
1183
1184 =item defined EXPR
1185 X<defined> X<undef> X<undefined>
1186
1187 =item defined
1188
1189 Returns a Boolean value telling whether EXPR has a value other than
1190 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1191 checked.
1192
1193 Many operations return C<undef> to indicate failure, end of file,
1194 system error, uninitialized variable, and other exceptional
1195 conditions.  This function allows you to distinguish C<undef> from
1196 other values.  (A simple Boolean test will not distinguish among
1197 C<undef>, zero, the empty string, and C<"0">, which are all equally
1198 false.)  Note that since C<undef> is a valid scalar, its presence
1199 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1200 returns C<undef> when its argument is an empty array, I<or> when the
1201 element to return happens to be C<undef>.
1202
1203 You may also use C<defined(&func)> to check whether subroutine C<&func>
1204 has ever been defined.  The return value is unaffected by any forward
1205 declarations of C<&func>.  A subroutine that is not defined
1206 may still be callable: its package may have an C<AUTOLOAD> method that
1207 makes it spring into existence the first time that it is called; see
1208 L<perlsub>.
1209
1210 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1211 used to report whether memory for that aggregate had ever been
1212 allocated.  This behavior may disappear in future versions of Perl.
1213 You should instead use a simple test for size:
1214
1215     if (@an_array) { print "has array elements\n" }
1216     if (%a_hash)   { print "has hash members\n"   }
1217
1218 When used on a hash element, it tells you whether the value is defined,
1219 not whether the key exists in the hash.  Use L</exists> for the latter
1220 purpose.
1221
1222 Examples:
1223
1224     print if defined $switch{D};
1225     print "$val\n" while defined($val = pop(@ary));
1226     die "Can't readlink $sym: $!"
1227         unless defined($value = readlink $sym);
1228     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1229     $debugging = 0 unless defined $debugging;
1230
1231 Note:  Many folks tend to overuse C<defined> and are then surprised to
1232 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1233 defined values.  For example, if you say
1234
1235     "ab" =~ /a(.*)b/;
1236
1237 The pattern match succeeds and C<$1> is defined, although it
1238 matched "nothing".  It didn't really fail to match anything.  Rather, it
1239 matched something that happened to be zero characters long.  This is all
1240 very above-board and honest.  When a function returns an undefined value,
1241 it's an admission that it couldn't give you an honest answer.  So you
1242 should use C<defined> only when questioning the integrity of what
1243 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1244 what you want.
1245
1246 See also L</undef>, L</exists>, L</ref>.
1247
1248 =item delete EXPR
1249 X<delete>
1250
1251 Given an expression that specifies an element or slice of a hash, C<delete>
1252 deletes the specified elements from that hash so that exists() on that element
1253 no longer returns true.  Setting a hash element to the undefined value does
1254 not remove its key, but deleting it does; see L</exists>.
1255
1256 In list context, returns the value or values deleted, or the last such
1257 element in scalar context.  The return list's length always matches that of
1258 the argument list: deleting non-existent elements returns the undefined value
1259 in their corresponding positions.
1260
1261 delete() may also be used on arrays and array slices, but its behavior is less
1262 straightforward.  Although exists() will return false for deleted entries,
1263 deleting array elements never changes indices of existing values; use shift()
1264 or splice() for that.  However, if all deleted elements fall at the end of an
1265 array, the array's size shrinks to the position of the highest element that
1266 still tests true for exists(), or to 0 if none do.
1267
1268 B<WARNING:> Calling delete on array values is deprecated and likely to
1269 be removed in a future version of Perl.
1270
1271 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1272 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1273 or array may not necessarily return anything; it depends on the implementation
1274 of the C<tied> package's DELETE method, which may do whatever it pleases.
1275
1276 The C<delete local EXPR> construct localizes the deletion to the current
1277 block at run time.  Until the block exits, elements locally deleted
1278 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1279 of composite types">.
1280
1281     %hash = (foo => 11, bar => 22, baz => 33);
1282     $scalar = delete $hash{foo};             # $scalar is 11
1283     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1284     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1285
1286 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1287
1288     foreach $key (keys %HASH) {
1289         delete $HASH{$key};
1290     }
1291
1292     foreach $index (0 .. $#ARRAY) {
1293         delete $ARRAY[$index];
1294     }
1295
1296 And so do these:
1297
1298     delete @HASH{keys %HASH};
1299
1300     delete @ARRAY[0 .. $#ARRAY];
1301
1302 But both are slower than assigning the empty list
1303 or undefining %HASH or @ARRAY, which is the customary 
1304 way to empty out an aggregate:
1305
1306     %HASH = ();     # completely empty %HASH
1307     undef %HASH;    # forget %HASH ever existed
1308
1309     @ARRAY = ();    # completely empty @ARRAY
1310     undef @ARRAY;   # forget @ARRAY ever existed
1311
1312 The EXPR can be arbitrarily complicated provided its
1313 final operation is an element or slice of an aggregate:
1314
1315     delete $ref->[$x][$y]{$key};
1316     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1317
1318     delete $ref->[$x][$y][$index];
1319     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1320
1321 =item die LIST
1322 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1323
1324 C<die> raises an exception. Inside an C<eval> the error message is stuffed
1325 into C<$@> and the C<eval> is terminated with the undefined value.
1326 If the exception is outside of all enclosing C<eval>s, then the uncaught
1327 exception prints LIST to C<STDERR> and exits with a non-zero value. If you
1328 need to exit the process with a specific exit code, see L</exit>.
1329
1330 Equivalent examples:
1331
1332     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1333     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1334
1335 If the last element of LIST does not end in a newline, the current
1336 script line number and input line number (if any) are also printed,
1337 and a newline is supplied.  Note that the "input line number" (also
1338 known as "chunk") is subject to whatever notion of "line" happens to
1339 be currently in effect, and is also available as the special variable
1340 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1341
1342 Hint: sometimes appending C<", stopped"> to your message will cause it
1343 to make better sense when the string C<"at foo line 123"> is appended.
1344 Suppose you are running script "canasta".
1345
1346     die "/etc/games is no good";
1347     die "/etc/games is no good, stopped";
1348
1349 produce, respectively
1350
1351     /etc/games is no good at canasta line 123.
1352     /etc/games is no good, stopped at canasta line 123.
1353
1354 If the output is empty and C<$@> already contains a value (typically from a
1355 previous eval) that value is reused after appending C<"\t...propagated">.
1356 This is useful for propagating exceptions:
1357
1358     eval { ... };
1359     die unless $@ =~ /Expected exception/;
1360
1361 If the output is empty and C<$@> contains an object reference that has a
1362 C<PROPAGATE> method, that method will be called with additional file
1363 and line number parameters.  The return value replaces the value in
1364 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1365 were called.
1366
1367 If C<$@> is empty then the string C<"Died"> is used.
1368
1369 If an uncaught exception results in interpreter exit, the exit code is
1370 determined from the values of C<$!> and C<$?> with this pseudocode:
1371
1372     exit $! if $!;              # errno
1373     exit $? >> 8 if $? >> 8;    # child exit status
1374     exit 255;                   # last resort
1375
1376 The intent is to squeeze as much possible information about the likely cause
1377 into the limited space of the system exit code. However, as C<$!> is the value
1378 of C's C<errno>, which can be set by any system call, this means that the value
1379 of the exit code used by C<die> can be non-predictable, so should not be relied
1380 upon, other than to be non-zero.
1381
1382 You can also call C<die> with a reference argument, and if this is trapped
1383 within an C<eval>, C<$@> contains that reference.  This permits more
1384 elaborate exception handling using objects that maintain arbitrary state
1385 about the exception.  Such a scheme is sometimes preferable to matching
1386 particular string values of C<$@> with regular expressions.  Because C<$@> 
1387 is a global variable and C<eval> may be used within object implementations,
1388 be careful that analyzing the error object doesn't replace the reference in
1389 the global variable.  It's easiest to make a local copy of the reference
1390 before any manipulations.  Here's an example:
1391
1392     use Scalar::Util "blessed";
1393
1394     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1395     if (my $ev_err = $@) {
1396         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1397             # handle Some::Module::Exception
1398         }
1399         else {
1400             # handle all other possible exceptions
1401         }
1402     }
1403
1404 Because Perl stringifies uncaught exception messages before display,
1405 you'll probably want to overload stringification operations on
1406 exception objects.  See L<overload> for details about that.
1407
1408 You can arrange for a callback to be run just before the C<die>
1409 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1410 handler is called with the error text and can change the error
1411 message, if it sees fit, by calling C<die> again.  See
1412 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1413 L<"eval BLOCK"> for some examples.  Although this feature was 
1414 to be run only right before your program was to exit, this is not
1415 currently so: the C<$SIG{__DIE__}> hook is currently called
1416 even inside eval()ed blocks/strings!  If one wants the hook to do
1417 nothing in such situations, put
1418
1419     die @_ if $^S;
1420
1421 as the first line of the handler (see L<perlvar/$^S>).  Because
1422 this promotes strange action at a distance, this counterintuitive
1423 behavior may be fixed in a future release.
1424
1425 See also exit(), warn(), and the Carp module.
1426
1427 =item do BLOCK
1428 X<do> X<block>
1429
1430 Not really a function.  Returns the value of the last command in the
1431 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1432 C<until> loop modifier, executes the BLOCK once before testing the loop
1433 condition. (On other statements the loop modifiers test the conditional
1434 first.)
1435
1436 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1437 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1438 See L<perlsyn> for alternative strategies.
1439
1440 =item do SUBROUTINE(LIST)
1441 X<do>
1442
1443 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1444 a scalar variable or a subroutine beginning with C<&>.
1445
1446 =item do EXPR
1447 X<do>
1448
1449 Uses the value of EXPR as a filename and executes the contents of the
1450 file as a Perl script.
1451
1452     do 'stat.pl';
1453
1454 is just like
1455
1456     eval `cat stat.pl`;
1457
1458 except that it's more efficient and concise, keeps track of the current
1459 filename for error messages, searches the C<@INC> directories, and updates
1460 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1461 these variables.  It also differs in that code evaluated with C<do FILENAME>
1462 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1463 same, however, in that it does reparse the file every time you call it,
1464 so you probably don't want to do this inside a loop.
1465
1466 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1467 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1468 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1469 could fail in a way that also sets C<$!>.  If the file is successfully
1470 compiled, C<do> returns the value of the last expression evaluated.
1471
1472 Inclusion of library modules is better done with the
1473 C<use> and C<require> operators, which also do automatic error checking
1474 and raise an exception if there's a problem.
1475
1476 You might like to use C<do> to read in a program configuration
1477 file.  Manual error checking can be done this way:
1478
1479     # read in config files: system first, then user
1480     for $file ("/share/prog/defaults.rc",
1481                "$ENV{HOME}/.someprogrc")
1482     {
1483         unless ($return = do $file) {
1484             warn "couldn't parse $file: $@" if $@;
1485             warn "couldn't do $file: $!"    unless defined $return;
1486             warn "couldn't run $file"       unless $return;
1487         }
1488     }
1489
1490 =item dump LABEL
1491 X<dump> X<core> X<undump>
1492
1493 =item dump
1494
1495 This function causes an immediate core dump.  See also the B<-u>
1496 command-line switch in L<perlrun>, which does the same thing.
1497 Primarily this is so that you can use the B<undump> program (not
1498 supplied) to turn your core dump into an executable binary after
1499 having initialized all your variables at the beginning of the
1500 program.  When the new binary is executed it will begin by executing
1501 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1502 Think of it as a goto with an intervening core dump and reincarnation.
1503 If C<LABEL> is omitted, restarts the program from the top.
1504
1505 B<WARNING>: Any files opened at the time of the dump will I<not>
1506 be open any more when the program is reincarnated, with possible
1507 resulting confusion by Perl.
1508
1509 This function is now largely obsolete, mostly because it's very hard to
1510 convert a core file into an executable. That's why you should now invoke
1511 it as C<CORE::dump()>, if you don't want to be warned against a possible
1512 typo.
1513
1514 Portability issues: L<perlport/dump>.
1515
1516 =item each HASH
1517 X<each> X<hash, iterator>
1518
1519 =item each ARRAY
1520 X<array, iterator>
1521
1522 =item each EXPR
1523
1524 When called in list context, returns a 2-element list consisting of the key
1525 and value for the next element of a hash, or the index and value for the
1526 next element of an array, so that you can iterate over it.  When called in
1527 scalar context, returns only the key (not the value) in a hash, or the index
1528 in an array.
1529
1530 Hash entries are returned in an apparently random order.  The actual random
1531 order is subject to change in future versions of Perl, but it is
1532 guaranteed to be in the same order as either the C<keys> or C<values>
1533 function would produce on the same (unmodified) hash.  Since Perl
1534 5.8.2 the ordering can be different even between different runs of Perl
1535 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1536
1537 After C<each> has returned all entries from the hash or array, the next
1538 call to C<each> returns the empty list in list context and C<undef> in
1539 scalar context.  The next call following that one restarts iteration.  Each
1540 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1541 and C<values>.  The iterator is implicitly reset when C<each> has reached
1542 the end as just described; it can be explicitly reset by calling C<keys> or
1543 C<values> on the hash or array.  If you add or delete a hash's elements
1544 while iterating over it, entries may be skipped or duplicated--so don't do
1545 that.  Exception: It is always safe to delete the item most recently
1546 returned by C<each()>, so the following code works properly:
1547
1548         while (($key, $value) = each %hash) {
1549           print $key, "\n";
1550           delete $hash{$key};   # This is safe
1551         }
1552
1553 This prints out your environment like the printenv(1) program,
1554 but in a different order:
1555
1556     while (($key,$value) = each %ENV) {
1557         print "$key=$value\n";
1558     }
1559
1560 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1561 reference to an unblessed hash or array.  The argument will be dereferenced
1562 automatically.  This aspect of C<each> is considered highly experimental.
1563 The exact behaviour may change in a future version of Perl.
1564
1565     while (($key,$value) = each $hashref) { ... }
1566
1567 See also C<keys>, C<values>, and C<sort>.
1568
1569 =item eof FILEHANDLE
1570 X<eof>
1571 X<end of file>
1572 X<end-of-file>
1573
1574 =item eof ()
1575
1576 =item eof
1577
1578 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1579 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1580 gives the real filehandle.  (Note that this function actually
1581 reads a character and then C<ungetc>s it, so isn't useful in an
1582 interactive context.)  Do not read from a terminal file (or call
1583 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1584 as terminals may lose the end-of-file condition if you do.
1585
1586 An C<eof> without an argument uses the last file read.  Using C<eof()>
1587 with empty parentheses is different.  It refers to the pseudo file
1588 formed from the files listed on the command line and accessed via the
1589 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1590 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1591 used will cause C<@ARGV> to be examined to determine if input is
1592 available.   Similarly, an C<eof()> after C<< <> >> has returned
1593 end-of-file will assume you are processing another C<@ARGV> list,
1594 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1595 see L<perlop/"I/O Operators">.
1596
1597 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1598 detect the end of each file, whereas C<eof()> will detect the end 
1599 of the very last file only.  Examples:
1600
1601     # reset line numbering on each input file
1602     while (<>) {
1603         next if /^\s*#/;  # skip comments
1604         print "$.\t$_";
1605     } continue {
1606         close ARGV if eof;  # Not eof()!
1607     }
1608
1609     # insert dashes just before last line of last file
1610     while (<>) {
1611         if (eof()) {  # check for end of last file
1612             print "--------------\n";
1613         }
1614         print;
1615         last if eof();      # needed if we're reading from a terminal
1616     }
1617
1618 Practical hint: you almost never need to use C<eof> in Perl, because the
1619 input operators typically return C<undef> when they run out of data or 
1620 encounter an error.
1621
1622 =item eval EXPR
1623 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1624 X<error, handling> X<exception, handling>
1625
1626 =item eval BLOCK
1627
1628 =item eval
1629
1630 In the first form, the return value of EXPR is parsed and executed as if it
1631 were a little Perl program.  The value of the expression (which is itself
1632 determined within scalar context) is first parsed, and if there were no
1633 errors, executed as a block within the lexical context of the current Perl
1634 program.  This means, that in particular, any outer lexical variables are
1635 visible to it, and any package variable settings or subroutine and format
1636 definitions remain afterwards.
1637
1638 Note that the value is parsed every time the C<eval> executes.
1639 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1640 delay parsing and subsequent execution of the text of EXPR until run time.
1641
1642 If the C<unicode_eval> feature is enabled (which is the default under a
1643 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1644 characters, so C<use utf8> declarations have no effect, and source filters
1645 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1646 will sometimes be treated as characters and sometimes as bytes, depending
1647 on the internal encoding, and source filters activated within the C<eval>
1648 exhibit the erratic, but historical, behaviour of affecting some outer file
1649 scope that is still compiling.  See also the L</evalbytes> keyword, which
1650 always treats its input as a byte stream and works properly with source
1651 filters, and the L<feature> pragma.
1652
1653 In the second form, the code within the BLOCK is parsed only once--at the
1654 same time the code surrounding the C<eval> itself was parsed--and executed
1655 within the context of the current Perl program.  This form is typically
1656 used to trap exceptions more efficiently than the first (see below), while
1657 also providing the benefit of checking the code within BLOCK at compile
1658 time.
1659
1660 The final semicolon, if any, may be omitted from the value of EXPR or within
1661 the BLOCK.
1662
1663 In both forms, the value returned is the value of the last expression
1664 evaluated inside the mini-program; a return statement may be also used, just
1665 as with subroutines.  The expression providing the return value is evaluated
1666 in void, scalar, or list context, depending on the context of the C<eval> 
1667 itself.  See L</wantarray> for more on how the evaluation context can be 
1668 determined.
1669
1670 If there is a syntax error or runtime error, or a C<die> statement is
1671 executed, C<eval> returns C<undef> in scalar context
1672 or an empty list in list context, and C<$@> is set to the error
1673 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1674 in list context for syntax errors, but not for runtime errors.)
1675 If there was no error, C<$@> is set to the empty string.  A
1676 control flow operator like C<last> or C<goto> can bypass the setting of
1677 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1678 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1679 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1680 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1681 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1682
1683 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1684 determining whether a particular feature (such as C<socket> or C<symlink>)
1685 is implemented.  It is also Perl's exception-trapping mechanism, where
1686 the die operator is used to raise exceptions.
1687
1688 If you want to trap errors when loading an XS module, some problems with
1689 the binary interface (such as Perl version skew) may be fatal even with
1690 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1691
1692 If the code to be executed doesn't vary, you may use the eval-BLOCK
1693 form to trap run-time errors without incurring the penalty of
1694 recompiling each time.  The error, if any, is still returned in C<$@>.
1695 Examples:
1696
1697     # make divide-by-zero nonfatal
1698     eval { $answer = $a / $b; }; warn $@ if $@;
1699
1700     # same thing, but less efficient
1701     eval '$answer = $a / $b'; warn $@ if $@;
1702
1703     # a compile-time error
1704     eval { $answer = }; # WRONG
1705
1706     # a run-time error
1707     eval '$answer =';   # sets $@
1708
1709 Using the C<eval{}> form as an exception trap in libraries does have some
1710 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1711 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1712 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1713 as this example shows:
1714
1715     # a private exception trap for divide-by-zero
1716     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1717     warn $@ if $@;
1718
1719 This is especially significant, given that C<__DIE__> hooks can call
1720 C<die> again, which has the effect of changing their error messages:
1721
1722     # __DIE__ hooks may modify error messages
1723     {
1724        local $SIG{'__DIE__'} =
1725               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1726        eval { die "foo lives here" };
1727        print $@ if $@;                # prints "bar lives here"
1728     }
1729
1730 Because this promotes action at a distance, this counterintuitive behavior
1731 may be fixed in a future release.
1732
1733 With an C<eval>, you should be especially careful to remember what's
1734 being looked at when:
1735
1736     eval $x;        # CASE 1
1737     eval "$x";      # CASE 2
1738
1739     eval '$x';      # CASE 3
1740     eval { $x };    # CASE 4
1741
1742     eval "\$$x++";  # CASE 5
1743     $$x++;          # CASE 6
1744
1745 Cases 1 and 2 above behave identically: they run the code contained in
1746 the variable $x.  (Although case 2 has misleading double quotes making
1747 the reader wonder what else might be happening (nothing is).)  Cases 3
1748 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1749 does nothing but return the value of $x.  (Case 4 is preferred for
1750 purely visual reasons, but it also has the advantage of compiling at
1751 compile-time instead of at run-time.)  Case 5 is a place where
1752 normally you I<would> like to use double quotes, except that in this
1753 particular situation, you can just use symbolic references instead, as
1754 in case 6.
1755
1756 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1757 of localised variables, which means that for your code to run on older
1758 versions, a temporary is required if you want to mask some but not all
1759 errors:
1760
1761     # alter $@ on nefarious repugnancy only
1762     {
1763        my $e;
1764        {
1765           local $@; # protect existing $@
1766           eval { test_repugnancy() };
1767           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1768           $@ =~ /nefarious/ and $e = $@;
1769        }
1770        die $e if defined $e
1771     }
1772
1773 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1774 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1775
1776 An C<eval ''> executed within the C<DB> package doesn't see the usual
1777 surrounding lexical scope, but rather the scope of the first non-DB piece
1778 of code that called it.  You don't normally need to worry about this unless
1779 you are writing a Perl debugger.
1780
1781 =item evalbytes EXPR
1782 X<evalbytes>
1783
1784 =item evalbytes
1785
1786 This function is like L</eval> with a string argument, except it always
1787 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1788 string containing characters whose ordinal value exceeds 255 results in an
1789 error.  Source filters activated within the evaluated code apply to the
1790 code itself.
1791
1792 This function is only available under the C<evalbytes> feature, a
1793 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1794 L<feature> for more information.
1795
1796 =item exec LIST
1797 X<exec> X<execute>
1798
1799 =item exec PROGRAM LIST
1800
1801 The C<exec> function executes a system command I<and never returns>;
1802 use C<system> instead of C<exec> if you want it to return.  It fails and
1803 returns false only if the command does not exist I<and> it is executed
1804 directly instead of via your system's command shell (see below).
1805
1806 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1807 warns you if there is a following statement that isn't C<die>, C<warn>,
1808 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1809 I<really> want to follow an C<exec> with some other statement, you
1810 can use one of these styles to avoid the warning:
1811
1812     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1813     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1814
1815 If there is more than one argument in LIST, or if LIST is an array
1816 with more than one value, calls execvp(3) with the arguments in LIST.
1817 If there is only one scalar argument or an array with one element in it,
1818 the argument is checked for shell metacharacters, and if there are any,
1819 the entire argument is passed to the system's command shell for parsing
1820 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1821 If there are no shell metacharacters in the argument, it is split into
1822 words and passed directly to C<execvp>, which is more efficient.
1823 Examples:
1824
1825     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1826     exec "sort $outfile | uniq";
1827
1828 If you don't really want to execute the first argument, but want to lie
1829 to the program you are executing about its own name, you can specify
1830 the program you actually want to run as an "indirect object" (without a
1831 comma) in front of the LIST.  (This always forces interpretation of the
1832 LIST as a multivalued list, even if there is only a single scalar in
1833 the list.)  Example:
1834
1835     $shell = '/bin/csh';
1836     exec $shell '-sh';    # pretend it's a login shell
1837
1838 or, more directly,
1839
1840     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1841
1842 When the arguments get executed via the system shell, results are
1843 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1844 for details.
1845
1846 Using an indirect object with C<exec> or C<system> is also more
1847 secure.  This usage (which also works fine with system()) forces
1848 interpretation of the arguments as a multivalued list, even if the
1849 list had just one argument.  That way you're safe from the shell
1850 expanding wildcards or splitting up words with whitespace in them.
1851
1852     @args = ( "echo surprise" );
1853
1854     exec @args;               # subject to shell escapes
1855                                 # if @args == 1
1856     exec { $args[0] } @args;  # safe even with one-arg list
1857
1858 The first version, the one without the indirect object, ran the I<echo>
1859 program, passing it C<"surprise"> an argument.  The second version didn't;
1860 it tried to run a program named I<"echo surprise">, didn't find it, and set
1861 C<$?> to a non-zero value indicating failure.
1862
1863 Beginning with v5.6.0, Perl attempts to flush all files opened for
1864 output before the exec, but this may not be supported on some platforms
1865 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1866 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1867 open handles to avoid lost output.
1868
1869 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1870 C<DESTROY> methods on your objects.
1871
1872 Portability issues: L<perlport/exec>.
1873
1874 =item exists EXPR
1875 X<exists> X<autovivification>
1876
1877 Given an expression that specifies an element of a hash, returns true if the
1878 specified element in the hash has ever been initialized, even if the
1879 corresponding value is undefined.
1880
1881     print "Exists\n"    if exists $hash{$key};
1882     print "Defined\n"   if defined $hash{$key};
1883     print "True\n"      if $hash{$key};
1884
1885 exists may also be called on array elements, but its behavior is much less
1886 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1887 that calling exists on array values is deprecated and likely to be removed in
1888 a future version of Perl.
1889
1890     print "Exists\n"    if exists $array[$index];
1891     print "Defined\n"   if defined $array[$index];
1892     print "True\n"      if $array[$index];
1893
1894 A hash or array element can be true only if it's defined and defined only if
1895 it exists, but the reverse doesn't necessarily hold true.
1896
1897 Given an expression that specifies the name of a subroutine,
1898 returns true if the specified subroutine has ever been declared, even
1899 if it is undefined.  Mentioning a subroutine name for exists or defined
1900 does not count as declaring it.  Note that a subroutine that does not
1901 exist may still be callable: its package may have an C<AUTOLOAD>
1902 method that makes it spring into existence the first time that it is
1903 called; see L<perlsub>.
1904
1905     print "Exists\n"  if exists &subroutine;
1906     print "Defined\n" if defined &subroutine;
1907
1908 Note that the EXPR can be arbitrarily complicated as long as the final
1909 operation is a hash or array key lookup or subroutine name:
1910
1911     if (exists $ref->{A}->{B}->{$key})  { }
1912     if (exists $hash{A}{B}{$key})       { }
1913
1914     if (exists $ref->{A}->{B}->[$ix])   { }
1915     if (exists $hash{A}{B}[$ix])        { }
1916
1917     if (exists &{$ref->{A}{B}{$key}})   { }
1918
1919 Although the mostly deeply nested array or hash will not spring into
1920 existence just because its existence was tested, any intervening ones will.
1921 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1922 into existence due to the existence test for the $key element above.
1923 This happens anywhere the arrow operator is used, including even here:
1924
1925     undef $ref;
1926     if (exists $ref->{"Some key"})    { }
1927     print $ref;  # prints HASH(0x80d3d5c)
1928
1929 This surprising autovivification in what does not at first--or even
1930 second--glance appear to be an lvalue context may be fixed in a future
1931 release.
1932
1933 Use of a subroutine call, rather than a subroutine name, as an argument
1934 to exists() is an error.
1935
1936     exists &sub;    # OK
1937     exists &sub();  # Error
1938
1939 =item exit EXPR
1940 X<exit> X<terminate> X<abort>
1941
1942 =item exit
1943
1944 Evaluates EXPR and exits immediately with that value.    Example:
1945
1946     $ans = <STDIN>;
1947     exit 0 if $ans =~ /^[Xx]/;
1948
1949 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1950 universally recognized values for EXPR are C<0> for success and C<1>
1951 for error; other values are subject to interpretation depending on the
1952 environment in which the Perl program is running.  For example, exiting
1953 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1954 the mailer to return the item undelivered, but that's not true everywhere.
1955
1956 Don't use C<exit> to abort a subroutine if there's any chance that
1957 someone might want to trap whatever error happened.  Use C<die> instead,
1958 which can be trapped by an C<eval>.
1959
1960 The exit() function does not always exit immediately.  It calls any
1961 defined C<END> routines first, but these C<END> routines may not
1962 themselves abort the exit.  Likewise any object destructors that need to
1963 be called are called before the real exit.  C<END> routines and destructors
1964 can change the exit status by modifying C<$?>. If this is a problem, you
1965 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1966 See L<perlmod> for details.
1967
1968 Portability issues: L<perlport/exit>.
1969
1970 =item exp EXPR
1971 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1972
1973 =item exp
1974
1975 Returns I<e> (the natural logarithm base) to the power of EXPR.
1976 If EXPR is omitted, gives C<exp($_)>.
1977
1978 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1979 X<fcntl>
1980
1981 Implements the fcntl(2) function.  You'll probably have to say
1982
1983     use Fcntl;
1984
1985 first to get the correct constant definitions.  Argument processing and
1986 value returned work just like C<ioctl> below.
1987 For example:
1988
1989     use Fcntl;
1990     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1991         or die "can't fcntl F_GETFL: $!";
1992
1993 You don't have to check for C<defined> on the return from C<fcntl>.
1994 Like C<ioctl>, it maps a C<0> return from the system call into
1995 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1996 in numeric context.  It is also exempt from the normal B<-w> warnings
1997 on improper numeric conversions.
1998
1999 Note that C<fcntl> raises an exception if used on a machine that
2000 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2001 manpage to learn what functions are available on your system.
2002
2003 Here's an example of setting a filehandle named C<REMOTE> to be
2004 non-blocking at the system level.  You'll have to negotiate C<$|>
2005 on your own, though.
2006
2007     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2008
2009     $flags = fcntl(REMOTE, F_GETFL, 0)
2010                 or die "Can't get flags for the socket: $!\n";
2011
2012     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2013                 or die "Can't set flags for the socket: $!\n";
2014
2015 Portability issues: L<perlport/fcntl>.
2016
2017 =item __FILE__
2018 X<__FILE__>
2019
2020 A special token that returns the name of the file in which it occurs.
2021
2022 =item fileno FILEHANDLE
2023 X<fileno>
2024
2025 Returns the file descriptor for a filehandle, or undefined if the
2026 filehandle is not open.  If there is no real file descriptor at the OS
2027 level, as can happen with filehandles connected to memory objects via
2028 C<open> with a reference for the third argument, -1 is returned.
2029
2030 This is mainly useful for constructing
2031 bitmaps for C<select> and low-level POSIX tty-handling operations.
2032 If FILEHANDLE is an expression, the value is taken as an indirect
2033 filehandle, generally its name.
2034
2035 You can use this to find out whether two handles refer to the
2036 same underlying descriptor:
2037
2038     if (fileno(THIS) == fileno(THAT)) {
2039         print "THIS and THAT are dups\n";
2040     }
2041
2042 =item flock FILEHANDLE,OPERATION
2043 X<flock> X<lock> X<locking>
2044
2045 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2046 for success, false on failure.  Produces a fatal error if used on a
2047 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2048 C<flock> is Perl's portable file-locking interface, although it locks
2049 entire files only, not records.
2050
2051 Two potentially non-obvious but traditional C<flock> semantics are
2052 that it waits indefinitely until the lock is granted, and that its locks
2053 are B<merely advisory>.  Such discretionary locks are more flexible, but
2054 offer fewer guarantees.  This means that programs that do not also use
2055 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2056 your port's specific documentation, and your system-specific local manpages
2057 for details.  It's best to assume traditional behavior if you're writing
2058 portable programs.  (But if you're not, you should as always feel perfectly
2059 free to write for your own system's idiosyncrasies (sometimes called
2060 "features").  Slavish adherence to portability concerns shouldn't get
2061 in the way of your getting your job done.)
2062
2063 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2064 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2065 you can use the symbolic names if you import them from the L<Fcntl> module,
2066 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2067 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2068 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2069 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2070 waiting for the lock; check the return status to see if you got it.
2071
2072 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2073 before locking or unlocking it.
2074
2075 Note that the emulation built with lockf(3) doesn't provide shared
2076 locks, and it requires that FILEHANDLE be open with write intent.  These
2077 are the semantics that lockf(3) implements.  Most if not all systems
2078 implement lockf(3) in terms of fcntl(2) locking, though, so the
2079 differing semantics shouldn't bite too many people.
2080
2081 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2082 be open with read intent to use LOCK_SH and requires that it be open
2083 with write intent to use LOCK_EX.
2084
2085 Note also that some versions of C<flock> cannot lock things over the
2086 network; you would need to use the more system-specific C<fcntl> for
2087 that.  If you like you can force Perl to ignore your system's flock(2)
2088 function, and so provide its own fcntl(2)-based emulation, by passing
2089 the switch C<-Ud_flock> to the F<Configure> program when you configure
2090 and build a new Perl.
2091
2092 Here's a mailbox appender for BSD systems.
2093
2094     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2095
2096     sub lock {
2097         my ($fh) = @_;
2098         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2099
2100         # and, in case someone appended while we were waiting...
2101         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2102     }
2103
2104     sub unlock {
2105         my ($fh) = @_;
2106         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2107     }
2108
2109     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2110         or die "Can't open mailbox: $!";
2111
2112     lock($mbox);
2113     print $mbox $msg,"\n\n";
2114     unlock($mbox);
2115
2116 On systems that support a real flock(2), locks are inherited across fork()
2117 calls, whereas those that must resort to the more capricious fcntl(2)
2118 function lose their locks, making it seriously harder to write servers.
2119
2120 See also L<DB_File> for other flock() examples.
2121
2122 Portability issues: L<perlport/flock>.
2123
2124 =item fork
2125 X<fork> X<child> X<parent>
2126
2127 Does a fork(2) system call to create a new process running the
2128 same program at the same point.  It returns the child pid to the
2129 parent process, C<0> to the child process, or C<undef> if the fork is
2130 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2131 are shared, while everything else is copied.  On most systems supporting
2132 fork(), great care has gone into making it extremely efficient (for
2133 example, using copy-on-write technology on data pages), making it the
2134 dominant paradigm for multitasking over the last few decades.
2135
2136 Beginning with v5.6.0, Perl attempts to flush all files opened for
2137 output before forking the child process, but this may not be supported
2138 on some platforms (see L<perlport>).  To be safe, you may need to set
2139 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2140 C<IO::Handle> on any open handles to avoid duplicate output.
2141
2142 If you C<fork> without ever waiting on your children, you will
2143 accumulate zombies.  On some systems, you can avoid this by setting
2144 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2145 forking and reaping moribund children.
2146
2147 Note that if your forked child inherits system file descriptors like
2148 STDIN and STDOUT that are actually connected by a pipe or socket, even
2149 if you exit, then the remote server (such as, say, a CGI script or a
2150 backgrounded job launched from a remote shell) won't think you're done.
2151 You should reopen those to F</dev/null> if it's any issue.
2152
2153 On some platforms such as Windows, where the fork() system call is not available,
2154 Perl can be built to emulate fork() in the Perl interpreter. The emulation is designed to,
2155 at the level of the Perl program, be as compatible as possible with the "Unix" fork().
2156 However it has limitations that have to be considered in code intended to be portable.
2157 See L<perlfork> for more details.
2158
2159 Portability issues: L<perlport/fork>.
2160
2161 =item format
2162 X<format>
2163
2164 Declare a picture format for use by the C<write> function.  For
2165 example:
2166
2167     format Something =
2168         Test: @<<<<<<<< @||||| @>>>>>
2169               $str,     $%,    '$' . int($num)
2170     .
2171
2172     $str = "widget";
2173     $num = $cost/$quantity;
2174     $~ = 'Something';
2175     write;
2176
2177 See L<perlform> for many details and examples.
2178
2179 =item formline PICTURE,LIST
2180 X<formline>
2181
2182 This is an internal function used by C<format>s, though you may call it,
2183 too.  It formats (see L<perlform>) a list of values according to the
2184 contents of PICTURE, placing the output into the format output
2185 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2186 Eventually, when a C<write> is done, the contents of
2187 C<$^A> are written to some filehandle.  You could also read C<$^A>
2188 and then set C<$^A> back to C<"">.  Note that a format typically
2189 does one C<formline> per line of form, but the C<formline> function itself
2190 doesn't care how many newlines are embedded in the PICTURE.  This means
2191 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2192 You may therefore need to use multiple formlines to implement a single
2193 record format, just like the C<format> compiler.
2194
2195 Be careful if you put double quotes around the picture, because an C<@>
2196 character may be taken to mean the beginning of an array name.
2197 C<formline> always returns true.  See L<perlform> for other examples.
2198
2199 If you are trying to use this instead of C<write> to capture the output,
2200 you may find it easier to open a filehandle to a scalar
2201 (C<< open $fh, ">", \$output >>) and write to that instead.
2202
2203 =item getc FILEHANDLE
2204 X<getc> X<getchar> X<character> X<file, read>
2205
2206 =item getc
2207
2208 Returns the next character from the input file attached to FILEHANDLE,
2209 or the undefined value at end of file or if there was an error (in
2210 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2211 STDIN.  This is not particularly efficient.  However, it cannot be
2212 used by itself to fetch single characters without waiting for the user
2213 to hit enter.  For that, try something more like:
2214
2215     if ($BSD_STYLE) {
2216         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2217     }
2218     else {
2219         system "stty", '-icanon', 'eol', "\001";
2220     }
2221
2222     $key = getc(STDIN);
2223
2224     if ($BSD_STYLE) {
2225         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2226     }
2227     else {
2228         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2229     }
2230     print "\n";
2231
2232 Determination of whether $BSD_STYLE should be set
2233 is left as an exercise to the reader.
2234
2235 The C<POSIX::getattr> function can do this more portably on
2236 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2237 module from your nearest CPAN site; details on CPAN can be found under
2238 L<perlmodlib/CPAN>.
2239
2240 =item getlogin
2241 X<getlogin> X<login>
2242
2243 This implements the C library function of the same name, which on most
2244 systems returns the current login from F</etc/utmp>, if any.  If it
2245 returns the empty string, use C<getpwuid>.
2246
2247     $login = getlogin || getpwuid($<) || "Kilroy";
2248
2249 Do not consider C<getlogin> for authentication: it is not as
2250 secure as C<getpwuid>.
2251
2252 Portability issues: L<perlport/getlogin>.
2253
2254 =item getpeername SOCKET
2255 X<getpeername> X<peer>
2256
2257 Returns the packed sockaddr address of the other end of the SOCKET
2258 connection.
2259
2260     use Socket;
2261     $hersockaddr    = getpeername(SOCK);
2262     ($port, $iaddr) = sockaddr_in($hersockaddr);
2263     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2264     $herstraddr     = inet_ntoa($iaddr);
2265
2266 =item getpgrp PID
2267 X<getpgrp> X<group>
2268
2269 Returns the current process group for the specified PID.  Use
2270 a PID of C<0> to get the current process group for the
2271 current process.  Will raise an exception if used on a machine that
2272 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2273 group of the current process.  Note that the POSIX version of C<getpgrp>
2274 does not accept a PID argument, so only C<PID==0> is truly portable.
2275
2276 Portability issues: L<perlport/getpgrp>.
2277
2278 =item getppid
2279 X<getppid> X<parent> X<pid>
2280
2281 Returns the process id of the parent process.
2282
2283 Note for Linux users: on Linux, the C functions C<getpid()> and
2284 C<getppid()> return different values from different threads. In order to
2285 be portable, this behavior is not reflected by the Perl-level function
2286 C<getppid()>, that returns a consistent value across threads. If you want
2287 to call the underlying C<getppid()>, you may use the CPAN module
2288 C<Linux::Pid>.
2289
2290 Portability issues: L<perlport/getppid>.
2291
2292 =item getpriority WHICH,WHO
2293 X<getpriority> X<priority> X<nice>
2294
2295 Returns the current priority for a process, a process group, or a user.
2296 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2297 machine that doesn't implement getpriority(2).
2298
2299 Portability issues: L<perlport/getpriority>.
2300
2301 =item getpwnam NAME
2302 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2303 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2304 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2305 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2306 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2307 X<endnetent> X<endprotoent> X<endservent> 
2308
2309 =item getgrnam NAME
2310
2311 =item gethostbyname NAME
2312
2313 =item getnetbyname NAME
2314
2315 =item getprotobyname NAME
2316
2317 =item getpwuid UID
2318
2319 =item getgrgid GID
2320
2321 =item getservbyname NAME,PROTO
2322
2323 =item gethostbyaddr ADDR,ADDRTYPE
2324
2325 =item getnetbyaddr ADDR,ADDRTYPE
2326
2327 =item getprotobynumber NUMBER
2328
2329 =item getservbyport PORT,PROTO
2330
2331 =item getpwent
2332
2333 =item getgrent
2334
2335 =item gethostent
2336
2337 =item getnetent
2338
2339 =item getprotoent
2340
2341 =item getservent
2342
2343 =item setpwent
2344
2345 =item setgrent
2346
2347 =item sethostent STAYOPEN
2348
2349 =item setnetent STAYOPEN
2350
2351 =item setprotoent STAYOPEN
2352
2353 =item setservent STAYOPEN
2354
2355 =item endpwent
2356
2357 =item endgrent
2358
2359 =item endhostent
2360
2361 =item endnetent
2362
2363 =item endprotoent
2364
2365 =item endservent
2366
2367 These routines are the same as their counterparts in the
2368 system C library.  In list context, the return values from the
2369 various get routines are as follows:
2370
2371     ($name,$passwd,$uid,$gid,
2372        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2373     ($name,$passwd,$gid,$members) = getgr*
2374     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2375     ($name,$aliases,$addrtype,$net) = getnet*
2376     ($name,$aliases,$proto) = getproto*
2377     ($name,$aliases,$port,$proto) = getserv*
2378
2379 (If the entry doesn't exist you get an empty list.)
2380
2381 The exact meaning of the $gcos field varies but it usually contains
2382 the real name of the user (as opposed to the login name) and other
2383 information pertaining to the user.  Beware, however, that in many
2384 system users are able to change this information and therefore it
2385 cannot be trusted and therefore the $gcos is tainted (see
2386 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2387 login shell, are also tainted, for the same reason.
2388
2389 In scalar context, you get the name, unless the function was a
2390 lookup by name, in which case you get the other thing, whatever it is.
2391 (If the entry doesn't exist you get the undefined value.)  For example:
2392
2393     $uid   = getpwnam($name);
2394     $name  = getpwuid($num);
2395     $name  = getpwent();
2396     $gid   = getgrnam($name);
2397     $name  = getgrgid($num);
2398     $name  = getgrent();
2399     #etc.
2400
2401 In I<getpw*()> the fields $quota, $comment, and $expire are special
2402 in that they are unsupported on many systems.  If the
2403 $quota is unsupported, it is an empty scalar.  If it is supported, it
2404 usually encodes the disk quota.  If the $comment field is unsupported,
2405 it is an empty scalar.  If it is supported it usually encodes some
2406 administrative comment about the user.  In some systems the $quota
2407 field may be $change or $age, fields that have to do with password
2408 aging.  In some systems the $comment field may be $class.  The $expire
2409 field, if present, encodes the expiration period of the account or the
2410 password.  For the availability and the exact meaning of these fields
2411 in your system, please consult getpwnam(3) and your system's 
2412 F<pwd.h> file.  You can also find out from within Perl what your
2413 $quota and $comment fields mean and whether you have the $expire field
2414 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2415 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2416 files are supported only if your vendor has implemented them in the
2417 intuitive fashion that calling the regular C library routines gets the
2418 shadow versions if you're running under privilege or if there exists
2419 the shadow(3) functions as found in System V (this includes Solaris
2420 and Linux).  Those systems that implement a proprietary shadow password
2421 facility are unlikely to be supported.
2422
2423 The $members value returned by I<getgr*()> is a space-separated list of
2424 the login names of the members of the group.
2425
2426 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2427 C, it will be returned to you via C<$?> if the function call fails.  The
2428 C<@addrs> value returned by a successful call is a list of raw
2429 addresses returned by the corresponding library call.  In the
2430 Internet domain, each address is four bytes long; you can unpack it
2431 by saying something like:
2432
2433     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2434
2435 The Socket library makes this slightly easier:
2436
2437     use Socket;
2438     $iaddr = inet_aton("127.1"); # or whatever address
2439     $name  = gethostbyaddr($iaddr, AF_INET);
2440
2441     # or going the other way
2442     $straddr = inet_ntoa($iaddr);
2443
2444 In the opposite way, to resolve a hostname to the IP address
2445 you can write this:
2446
2447     use Socket;
2448     $packed_ip = gethostbyname("www.perl.org");
2449     if (defined $packed_ip) {
2450         $ip_address = inet_ntoa($packed_ip);
2451     }
2452
2453 Make sure C<gethostbyname()> is called in SCALAR context and that
2454 its return value is checked for definedness.
2455
2456 The C<getprotobynumber> function, even though it only takes one argument,
2457 has the precedence of a list operator, so beware:
2458
2459     getprotobynumber $number eq 'icmp'   # WRONG
2460     getprotobynumber($number eq 'icmp')  # actually means this
2461     getprotobynumber($number) eq 'icmp'  # better this way
2462
2463 If you get tired of remembering which element of the return list
2464 contains which return value, by-name interfaces are provided
2465 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2466 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2467 and C<User::grent>.  These override the normal built-ins, supplying
2468 versions that return objects with the appropriate names
2469 for each field.  For example:
2470
2471    use File::stat;
2472    use User::pwent;
2473    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2474
2475 Even though it looks as though they're the same method calls (uid),
2476 they aren't, because a C<File::stat> object is different from
2477 a C<User::pwent> object.
2478
2479 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2480
2481 =item getsockname SOCKET
2482 X<getsockname>
2483
2484 Returns the packed sockaddr address of this end of the SOCKET connection,
2485 in case you don't know the address because you have several different
2486 IPs that the connection might have come in on.
2487
2488     use Socket;
2489     $mysockaddr = getsockname(SOCK);
2490     ($port, $myaddr) = sockaddr_in($mysockaddr);
2491     printf "Connect to %s [%s]\n",
2492        scalar gethostbyaddr($myaddr, AF_INET),
2493        inet_ntoa($myaddr);
2494
2495 =item getsockopt SOCKET,LEVEL,OPTNAME
2496 X<getsockopt>
2497
2498 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2499 Options may exist at multiple protocol levels depending on the socket
2500 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2501 C<Socket> module) will exist. To query options at another level the
2502 protocol number of the appropriate protocol controlling the option
2503 should be supplied. For example, to indicate that an option is to be
2504 interpreted by the TCP protocol, LEVEL should be set to the protocol
2505 number of TCP, which you can get using C<getprotobyname>.
2506
2507 The function returns a packed string representing the requested socket
2508 option, or C<undef> on error, with the reason for the error placed in
2509 C<$!>. Just what is in the packed string depends on LEVEL and OPTNAME;
2510 consult getsockopt(2) for details.  A common case is that the option is an
2511 integer, in which case the result is a packed integer, which you can decode
2512 using C<unpack> with the C<i> (or C<I>) format.
2513
2514 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2515
2516     use Socket qw(:all);
2517
2518     defined(my $tcp = getprotobyname("tcp"))
2519         or die "Could not determine the protocol number for tcp";
2520     # my $tcp = IPPROTO_TCP; # Alternative
2521     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2522         or die "getsockopt TCP_NODELAY: $!";
2523     my $nodelay = unpack("I", $packed);
2524     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2525
2526 Portability issues: L<perlport/getsockopt>.
2527
2528 =item given EXPR BLOCK
2529 X<given>
2530
2531 =item given BLOCK
2532
2533 C<given> is analogous to the C<switch> keyword in other languages. C<given>
2534 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2535 Only available after Perl 5.10.  For example:
2536
2537     use v5.10;
2538     given ($fruit) {
2539         when (/apples?/) {
2540             print "I like apples."
2541         }
2542         when (/oranges?/) {
2543             print "I don't like oranges."
2544         }
2545         default {
2546             print "I don't like anything"
2547         }
2548     }
2549
2550 See L<perlsyn/"Switch statements"> for detailed information.
2551
2552 =item glob EXPR
2553 X<glob> X<wildcard> X<filename, expansion> X<expand>
2554
2555 =item glob
2556
2557 In list context, returns a (possibly empty) list of filename expansions on
2558 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2559 scalar context, glob iterates through such filename expansions, returning
2560 undef when the list is exhausted. This is the internal function
2561 implementing the C<< <*.c> >> operator, but you can use it directly. If
2562 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2563 more detail in L<perlop/"I/O Operators">.
2564
2565 Note that C<glob> splits its arguments on whitespace and treats
2566 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2567 matches all files with a F<.c> or F<.h> extension.  The expression
2568 C<glob(".* *")> matches all files in the current working directory.
2569 If you want to glob filenames that might contain whitespace, you'll
2570 have to use extra quotes around the spacey filename to protect it.
2571 For example, to glob filenames that have an C<e> followed by a space
2572 followed by an C<f>, use either of:
2573
2574     @spacies = <"*e f*">;
2575     @spacies = glob '"*e f*"';
2576     @spacies = glob q("*e f*");
2577
2578 If you had to get a variable through, you could do this:
2579
2580     @spacies = glob "'*${var}e f*'";
2581     @spacies = glob qq("*${var}e f*");
2582
2583 If non-empty braces are the only wildcard characters used in the
2584 C<glob>, no filenames are matched, but potentially many strings
2585 are returned.  For example, this produces nine strings, one for
2586 each pairing of fruits and colors:
2587
2588     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2589
2590 Beginning with v5.6.0, this operator is implemented using the standard
2591 C<File::Glob> extension.  See L<File::Glob> for details, including
2592 C<bsd_glob> which does not treat whitespace as a pattern separator.
2593
2594 Portability issues: L<perlport/glob>.
2595
2596 =item gmtime EXPR
2597 X<gmtime> X<UTC> X<Greenwich>
2598
2599 =item gmtime
2600
2601 Works just like L</localtime> but the returned values are
2602 localized for the standard Greenwich time zone.
2603
2604 Note: When called in list context, $isdst, the last value
2605 returned by gmtime, is always C<0>.  There is no
2606 Daylight Saving Time in GMT.
2607
2608 Portability issues: L<perlport/gmtime>.
2609
2610 =item goto LABEL
2611 X<goto> X<jump> X<jmp>
2612
2613 =item goto EXPR
2614
2615 =item goto &NAME
2616
2617 The C<goto-LABEL> form finds the statement labeled with LABEL and
2618 resumes execution there. It can't be used to get out of a block or
2619 subroutine given to C<sort>.  It can be used to go almost anywhere
2620 else within the dynamic scope, including out of subroutines, but it's
2621 usually better to use some other construct such as C<last> or C<die>.
2622 The author of Perl has never felt the need to use this form of C<goto>
2623 (in Perl, that is; C is another matter).  (The difference is that C
2624 does not offer named loops combined with loop control.  Perl does, and
2625 this replaces most structured uses of C<goto> in other languages.)
2626
2627 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2628 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2629 necessarily recommended if you're optimizing for maintainability:
2630
2631     goto ("FOO", "BAR", "GLARCH")[$i];
2632
2633 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2634 function" rule. A pair of parentheses following it does not (necessarily)
2635 delimit its argument. C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2636
2637 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2638 deprecated and will issue a warning.  Even then, it may not be used to
2639 go into any construct that requires initialization, such as a
2640 subroutine or a C<foreach> loop.  It also can't be used to go into a
2641 construct that is optimized away.
2642
2643 The C<goto-&NAME> form is quite different from the other forms of
2644 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2645 doesn't have the stigma associated with other gotos.  Instead, it
2646 exits the current subroutine (losing any changes set by local()) and
2647 immediately calls in its place the named subroutine using the current
2648 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2649 load another subroutine and then pretend that the other subroutine had
2650 been called in the first place (except that any modifications to C<@_>
2651 in the current subroutine are propagated to the other subroutine.)
2652 After the C<goto>, not even C<caller> will be able to tell that this
2653 routine was called first.
2654
2655 NAME needn't be the name of a subroutine; it can be a scalar variable
2656 containing a code reference or a block that evaluates to a code
2657 reference.
2658
2659 =item grep BLOCK LIST
2660 X<grep>
2661
2662 =item grep EXPR,LIST
2663
2664 This is similar in spirit to, but not the same as, grep(1) and its
2665 relatives.  In particular, it is not limited to using regular expressions.
2666
2667 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2668 C<$_> to each element) and returns the list value consisting of those
2669 elements for which the expression evaluated to true.  In scalar
2670 context, returns the number of times the expression was true.
2671
2672     @foo = grep(!/^#/, @bar);    # weed out comments
2673
2674 or equivalently,
2675
2676     @foo = grep {!/^#/} @bar;    # weed out comments
2677
2678 Note that C<$_> is an alias to the list value, so it can be used to
2679 modify the elements of the LIST.  While this is useful and supported,
2680 it can cause bizarre results if the elements of LIST are not variables.
2681 Similarly, grep returns aliases into the original list, much as a for
2682 loop's index variable aliases the list elements.  That is, modifying an
2683 element of a list returned by grep (for example, in a C<foreach>, C<map>
2684 or another C<grep>) actually modifies the element in the original list.
2685 This is usually something to be avoided when writing clear code.
2686
2687 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2688 been declared with C<my $_>) then, in addition to being locally aliased to
2689 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2690 can't be seen from the outside, avoiding any potential side-effects.
2691
2692 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2693
2694 =item hex EXPR
2695 X<hex> X<hexadecimal>
2696
2697 =item hex
2698
2699 Interprets EXPR as a hex string and returns the corresponding value.
2700 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2701 L</oct>.)  If EXPR is omitted, uses C<$_>.
2702
2703     print hex '0xAf'; # prints '175'
2704     print hex 'aF';   # same
2705
2706 Hex strings may only represent integers.  Strings that would cause
2707 integer overflow trigger a warning.  Leading whitespace is not stripped,
2708 unlike oct(). To present something as hex, look into L</printf>,
2709 L</sprintf>, and L</unpack>.
2710
2711 =item import LIST
2712 X<import>
2713
2714 There is no builtin C<import> function.  It is just an ordinary
2715 method (subroutine) defined (or inherited) by modules that wish to export
2716 names to another module.  The C<use> function calls the C<import> method
2717 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2718
2719 =item index STR,SUBSTR,POSITION
2720 X<index> X<indexOf> X<InStr>
2721
2722 =item index STR,SUBSTR
2723
2724 The index function searches for one string within another, but without
2725 the wildcard-like behavior of a full regular-expression pattern match.
2726 It returns the position of the first occurrence of SUBSTR in STR at
2727 or after POSITION.  If POSITION is omitted, starts searching from the
2728 beginning of the string.  POSITION before the beginning of the string
2729 or after its end is treated as if it were the beginning or the end,
2730 respectively.  POSITION and the return value are based at zero.
2731 If the substring is not found, C<index> returns -1.
2732
2733 =item int EXPR
2734 X<int> X<integer> X<truncate> X<trunc> X<floor>
2735
2736 =item int
2737
2738 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2739 You should not use this function for rounding: one because it truncates
2740 towards C<0>, and two because machine representations of floating-point
2741 numbers can sometimes produce counterintuitive results.  For example,
2742 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2743 because it's really more like -268.99999999999994315658 instead.  Usually,
2744 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2745 functions will serve you better than will int().
2746
2747 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2748 X<ioctl>
2749
2750 Implements the ioctl(2) function.  You'll probably first have to say
2751
2752     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2753
2754 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2755 exist or doesn't have the correct definitions you'll have to roll your
2756 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2757 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2758 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2759 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2760 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2761 has no string value but does have a numeric value, that value will be
2762 passed rather than a pointer to the string value.  To guarantee this to be
2763 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2764 functions may be needed to manipulate the values of structures used by
2765 C<ioctl>.
2766
2767 The return value of C<ioctl> (and C<fcntl>) is as follows:
2768
2769     if OS returns:      then Perl returns:
2770         -1               undefined value
2771          0              string "0 but true"
2772     anything else           that number
2773
2774 Thus Perl returns true on success and false on failure, yet you can
2775 still easily determine the actual value returned by the operating
2776 system:
2777
2778     $retval = ioctl(...) || -1;
2779     printf "System returned %d\n", $retval;
2780
2781 The special string C<"0 but true"> is exempt from B<-w> complaints
2782 about improper numeric conversions.
2783
2784 Portability issues: L<perlport/ioctl>.
2785
2786 =item join EXPR,LIST
2787 X<join>
2788
2789 Joins the separate strings of LIST into a single string with fields
2790 separated by the value of EXPR, and returns that new string.  Example:
2791
2792     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2793
2794 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2795 first argument.  Compare L</split>.
2796
2797 =item keys HASH
2798 X<keys> X<key>
2799
2800 =item keys ARRAY
2801
2802 =item keys EXPR
2803
2804 Returns a list consisting of all the keys of the named hash, or the indices
2805 of an array. (In scalar context, returns the number of keys or indices.)
2806
2807 The keys of a hash are returned in an apparently random order.  The actual
2808 random order is subject to change in future versions of Perl, but it
2809 is guaranteed to be the same order as either the C<values> or C<each>
2810 function produces (given that the hash has not been modified).  Since
2811 Perl 5.8.1 the ordering can be different even between different runs of
2812 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2813 Attacks">).
2814
2815 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2816 (see L</each>).  In particular, calling keys() in void context resets
2817 the iterator with no other overhead.
2818
2819 Here is yet another way to print your environment:
2820
2821     @keys = keys %ENV;
2822     @values = values %ENV;
2823     while (@keys) {
2824         print pop(@keys), '=', pop(@values), "\n";
2825     }
2826
2827 or how about sorted by key:
2828
2829     foreach $key (sort(keys %ENV)) {
2830         print $key, '=', $ENV{$key}, "\n";
2831     }
2832
2833 The returned values are copies of the original keys in the hash, so
2834 modifying them will not affect the original hash.  Compare L</values>.
2835
2836 To sort a hash by value, you'll need to use a C<sort> function.
2837 Here's a descending numeric sort of a hash by its values:
2838
2839     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2840         printf "%4d %s\n", $hash{$key}, $key;
2841     }
2842
2843 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2844 allocated for the given hash.  This can gain you a measure of efficiency if
2845 you know the hash is going to get big.  (This is similar to pre-extending
2846 an array by assigning a larger number to $#array.)  If you say
2847
2848     keys %hash = 200;
2849
2850 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2851 in fact, since it rounds up to the next power of two.  These
2852 buckets will be retained even if you do C<%hash = ()>, use C<undef
2853 %hash> if you want to free the storage while C<%hash> is still in scope.
2854 You can't shrink the number of buckets allocated for the hash using
2855 C<keys> in this way (but you needn't worry about doing this by accident,
2856 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2857 error.
2858
2859 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2860 a reference to an unblessed hash or array.  The argument will be
2861 dereferenced automatically.  This aspect of C<keys> is considered highly
2862 experimental.  The exact behaviour may change in a future version of Perl.
2863
2864     for (keys $hashref) { ... }
2865     for (keys $obj->get_arrayref) { ... }
2866
2867 See also C<each>, C<values>, and C<sort>.
2868
2869 =item kill SIGNAL, LIST
2870
2871 =item kill SIGNAL
2872 X<kill> X<signal>
2873
2874 Sends a signal to a list of processes.  Returns the number of
2875 processes successfully signaled (which is not necessarily the
2876 same as the number actually killed).
2877
2878     $cnt = kill 1, $child1, $child2;
2879     kill 9, @goners;
2880
2881 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2882 checks whether it's I<possible> to send a signal to it (that
2883 means, to be brief, that the process is owned by the same user, or we are
2884 the super-user).  This is useful to check that a child process is still
2885 alive (even if only as a zombie) and hasn't changed its UID.  See
2886 L<perlport> for notes on the portability of this construct.
2887
2888 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2889 of processes. That means you usually want to use positive not negative signals.
2890 You may also use a signal name in quotes.
2891
2892 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2893 the operating system.  For example, on POSIX-conforming systems, zero will
2894 signal the current process group and -1 will signal all processes.
2895
2896 See L<perlipc/"Signals"> for more details.
2897
2898 On some platforms such as Windows where the fork() system call is not available.
2899 Perl can be built to emulate fork() at the interpreter level.
2900 This emulation has limitations related to kill that have to be considered,
2901 for code running on Windows and in code intended to be portable.
2902
2903 See L<perlfork> for more details.
2904
2905 If there is no I<LIST> of processes, no signal is sent, and the return
2906 value is 0.  This form is sometimes used, however, because it causes
2907 tainting checks to be run.  But see
2908 L<perlsec/Laundering and Detecting Tainted Data>.
2909
2910 Portability issues: L<perlport/kill>.
2911
2912 =item last LABEL
2913 X<last> X<break>
2914
2915 =item last
2916
2917 The C<last> command is like the C<break> statement in C (as used in
2918 loops); it immediately exits the loop in question.  If the LABEL is
2919 omitted, the command refers to the innermost enclosing loop.  The
2920 C<continue> block, if any, is not executed:
2921
2922     LINE: while (<STDIN>) {
2923         last LINE if /^$/;  # exit when done with header
2924         #...
2925     }
2926
2927 C<last> cannot be used to exit a block that returns a value such as
2928 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
2929 a grep() or map() operation.
2930
2931 Note that a block by itself is semantically identical to a loop
2932 that executes once.  Thus C<last> can be used to effect an early
2933 exit out of such a block.
2934
2935 See also L</continue> for an illustration of how C<last>, C<next>, and
2936 C<redo> work.
2937
2938 =item lc EXPR
2939 X<lc> X<lowercase>
2940
2941 =item lc
2942
2943 Returns a lowercased version of EXPR.  This is the internal function
2944 implementing the C<\L> escape in double-quoted strings.
2945
2946 If EXPR is omitted, uses C<$_>.
2947
2948 What gets returned depends on several factors:
2949
2950 =over
2951
2952 =item If C<use bytes> is in effect:
2953
2954 =over
2955
2956 =item On EBCDIC platforms
2957
2958 The results are what the C language system call C<tolower()> returns.
2959
2960 =item On ASCII platforms
2961
2962 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2963 respectively.
2964
2965 =back
2966
2967 =item Otherwise, if C<use locale> is in effect
2968
2969 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
2970 semantics for the remaining code points (this last can only happen if
2971 the UTF8 flag is also set).  See L<perllocale>.
2972
2973 A deficiency in this is that case changes that cross the 255/256
2974 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
2975 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
2976 platforms).   But under C<use locale>, the lower case of U+1E9E is
2977 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
2978 current locale, and Perl has no way of knowing if that character even
2979 exists in the locale, much less what code point it is.  Perl returns
2980 the input character unchanged, for all instances (and there aren't
2981 many) where the 255/256 boundary would otherwise be crossed.
2982
2983 =item Otherwise, If EXPR has the UTF8 flag set
2984
2985 Unicode semantics are used for the case change.
2986
2987 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2988
2989 Unicode semantics are used for the case change.
2990
2991 =item Otherwise:
2992
2993 =over
2994
2995 =item On EBCDIC platforms
2996
2997 The results are what the C language system call C<tolower()> returns.
2998
2999 =item On ASCII platforms
3000
3001 ASCII semantics are used for the case change.  The lowercase of any character
3002 outside the ASCII range is the character itself.
3003
3004 =back
3005
3006 =back
3007
3008 =item lcfirst EXPR
3009 X<lcfirst> X<lowercase>
3010
3011 =item lcfirst
3012
3013 Returns the value of EXPR with the first character lowercased.  This
3014 is the internal function implementing the C<\l> escape in
3015 double-quoted strings.
3016
3017 If EXPR is omitted, uses C<$_>.
3018
3019 This function behaves the same way under various pragmata, such as in a locale,
3020 as L</lc> does.
3021
3022 =item length EXPR
3023 X<length> X<size>
3024
3025 =item length
3026
3027 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3028 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3029 C<undef>.
3030
3031 This function cannot be used on an entire array or hash to find out how
3032 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3033 %hash>, respectively.
3034
3035 Like all Perl character operations, length() normally deals in logical
3036 characters, not physical bytes.  For how many bytes a string encoded as
3037 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3038 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3039
3040 =item __LINE__
3041 X<__LINE__>
3042
3043 A special token that compiles to the current line number.
3044
3045 =item link OLDFILE,NEWFILE
3046 X<link>
3047
3048 Creates a new filename linked to the old filename.  Returns true for
3049 success, false otherwise.
3050
3051 Portability issues: L<perlport/link>.
3052
3053 =item listen SOCKET,QUEUESIZE
3054 X<listen>
3055
3056 Does the same thing that the listen(2) system call does.  Returns true if
3057 it succeeded, false otherwise.  See the example in
3058 L<perlipc/"Sockets: Client/Server Communication">.
3059
3060 =item local EXPR
3061 X<local>
3062
3063 You really probably want to be using C<my> instead, because C<local> isn't
3064 what most people think of as "local".  See
3065 L<perlsub/"Private Variables via my()"> for details.
3066
3067 A local modifies the listed variables to be local to the enclosing
3068 block, file, or eval.  If more than one value is listed, the list must
3069 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3070 for details, including issues with tied arrays and hashes.
3071
3072 The C<delete local EXPR> construct can also be used to localize the deletion
3073 of array/hash elements to the current block.
3074 See L<perlsub/"Localized deletion of elements of composite types">.
3075
3076 =item localtime EXPR
3077 X<localtime> X<ctime>
3078
3079 =item localtime
3080
3081 Converts a time as returned by the time function to a 9-element list
3082 with the time analyzed for the local time zone.  Typically used as
3083 follows:
3084
3085     #  0    1    2     3     4    5     6     7     8
3086     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3087                                                 localtime(time);
3088
3089 All list elements are numeric and come straight out of the C `struct
3090 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3091 of the specified time.
3092
3093 C<$mday> is the day of the month and C<$mon> the month in
3094 the range C<0..11>, with 0 indicating January and 11 indicating December.
3095 This makes it easy to get a month name from a list:
3096
3097     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3098     print "$abbr[$mon] $mday";
3099     # $mon=9, $mday=18 gives "Oct 18"
3100
3101 C<$year> is the number of years since 1900, B<not> just the last two digits
3102 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
3103 to get a 4-digit year is simply:
3104
3105     $year += 1900;
3106
3107 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
3108 to do that, would you?
3109
3110 To get the last two digits of the year (e.g., "01" in 2001) do:
3111
3112     $year = sprintf("%02d", $year % 100);
3113
3114 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3115 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3116 (or C<0..365> in leap years.)
3117
3118 C<$isdst> is true if the specified time occurs during Daylight Saving
3119 Time, false otherwise.
3120
3121 If EXPR is omitted, C<localtime()> uses the current time (as returned
3122 by time(3)).
3123
3124 In scalar context, C<localtime()> returns the ctime(3) value:
3125
3126     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3127
3128 This scalar value is B<not> locale-dependent but is a Perl builtin. For GMT
3129 instead of local time use the L</gmtime> builtin. See also the
3130 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3131 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3132 and mktime(3) functions.
3133
3134 To get somewhat similar but locale-dependent date strings, set up your
3135 locale environment variables appropriately (please see L<perllocale>) and
3136 try for example:
3137
3138     use POSIX qw(strftime);
3139     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3140     # or for GMT formatted appropriately for your locale:
3141     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3142
3143 Note that the C<%a> and C<%b>, the short forms of the day of the week
3144 and the month of the year, may not necessarily be three characters wide.
3145
3146 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3147 by-name access mechanism to the gmtime() and localtime() functions,
3148 respectively.
3149
3150 For a comprehensive date and time representation look at the
3151 L<DateTime> module on CPAN.
3152
3153 Portability issues: L<perlport/localtime>.
3154
3155 =item lock THING
3156 X<lock>
3157
3158 This function places an advisory lock on a shared variable or referenced
3159 object contained in I<THING> until the lock goes out of scope.
3160
3161 The value returned is the scalar itself, if the argument is a scalar, or a
3162 reference, if the argument is a hash, array or subroutine.
3163
3164 lock() is a "weak keyword" : this means that if you've defined a function
3165 by this name (before any calls to it), that function will be called
3166 instead.  If you are not under C<use threads::shared> this does nothing.
3167 See L<threads::shared>.
3168
3169 =item log EXPR
3170 X<log> X<logarithm> X<e> X<ln> X<base>
3171
3172 =item log
3173
3174 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3175 returns the log of C<$_>.  To get the
3176 log of another base, use basic algebra:
3177 The base-N log of a number is equal to the natural log of that number
3178 divided by the natural log of N.  For example:
3179
3180     sub log10 {
3181         my $n = shift;
3182         return log($n)/log(10);
3183     }
3184
3185 See also L</exp> for the inverse operation.
3186
3187 =item lstat FILEHANDLE
3188 X<lstat>
3189
3190 =item lstat EXPR
3191
3192 =item lstat DIRHANDLE
3193
3194 =item lstat
3195
3196 Does the same thing as the C<stat> function (including setting the
3197 special C<_> filehandle) but stats a symbolic link instead of the file
3198 the symbolic link points to.  If symbolic links are unimplemented on
3199 your system, a normal C<stat> is done.  For much more detailed
3200 information, please see the documentation for C<stat>.
3201
3202 If EXPR is omitted, stats C<$_>.
3203
3204 Portability issues: L<perlport/lstat>.
3205
3206 =item m//
3207
3208 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3209
3210 =item map BLOCK LIST
3211 X<map>
3212
3213 =item map EXPR,LIST
3214
3215 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3216 C<$_> to each element) and returns the list value composed of the
3217 results of each such evaluation.  In scalar context, returns the
3218 total number of elements so generated.  Evaluates BLOCK or EXPR in
3219 list context, so each element of LIST may produce zero, one, or
3220 more elements in the returned value.
3221
3222     @chars = map(chr, @numbers);
3223
3224 translates a list of numbers to the corresponding characters.
3225
3226     my @squares = map { $_ * $_ } @numbers;
3227
3228 translates a list of numbers to their squared values.
3229
3230     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3231
3232 shows that number of returned elements can differ from the number of
3233 input elements. To omit an element, return an empty list ().
3234 This could also be achieved by writing
3235
3236     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3237
3238 which makes the intention more clear.
3239
3240 Map always returns a list, which can be
3241 assigned to a hash such that the elements
3242 become key/value pairs. See L<perldata> for more details.
3243
3244     %hash = map { get_a_key_for($_) => $_ } @array;
3245
3246 is just a funny way to write
3247
3248     %hash = ();
3249     foreach (@array) {
3250         $hash{get_a_key_for($_)} = $_;
3251     }
3252
3253 Note that C<$_> is an alias to the list value, so it can be used to
3254 modify the elements of the LIST.  While this is useful and supported,
3255 it can cause bizarre results if the elements of LIST are not variables.
3256 Using a regular C<foreach> loop for this purpose would be clearer in
3257 most cases.  See also L</grep> for an array composed of those items of
3258 the original list for which the BLOCK or EXPR evaluates to true.
3259
3260 If C<$_> is lexical in the scope where the C<map> appears (because it has
3261 been declared with C<my $_>), then, in addition to being locally aliased to
3262 the list elements, C<$_> keeps being lexical inside the block; that is, it
3263 can't be seen from the outside, avoiding any potential side-effects.
3264
3265 C<{> starts both hash references and blocks, so C<map { ...> could be either
3266 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
3267 ahead for the closing C<}> it has to take a guess at which it's dealing with
3268 based on what it finds just after the C<{>. Usually it gets it right, but if it
3269 doesn't it won't realize something is wrong until it gets to the C<}> and
3270 encounters the missing (or unexpected) comma. The syntax error will be
3271 reported close to the C<}>, but you'll need to change something near the C<{>
3272 such as using a unary C<+> to give Perl some help:
3273
3274     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3275     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3276     %hash = map { ("\L$_" => 1) } @array  # this also works
3277     %hash = map {  lc($_) => 1  } @array  # as does this.
3278     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3279
3280     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3281
3282 or to force an anon hash constructor use C<+{>:
3283
3284    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3285
3286 to get a list of anonymous hashes each with only one entry apiece.
3287
3288 =item mkdir FILENAME,MASK
3289 X<mkdir> X<md> X<directory, create>
3290
3291 =item mkdir FILENAME
3292
3293 =item mkdir
3294
3295 Creates the directory specified by FILENAME, with permissions
3296 specified by MASK (as modified by C<umask>).  If it succeeds it
3297 returns true; otherwise it returns false and sets C<$!> (errno).
3298 MASK defaults to 0777 if omitted, and FILENAME defaults
3299 to C<$_> if omitted.
3300
3301 In general, it is better to create directories with a permissive MASK
3302 and let the user modify that with their C<umask> than it is to supply
3303 a restrictive MASK and give the user no way to be more permissive.
3304 The exceptions to this rule are when the file or directory should be
3305 kept private (mail files, for instance).  The perlfunc(1) entry on
3306 C<umask> discusses the choice of MASK in more detail.
3307
3308 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3309 number of trailing slashes.  Some operating and filesystems do not get
3310 this right, so Perl automatically removes all trailing slashes to keep
3311 everyone happy.
3312
3313 To recursively create a directory structure, look at
3314 the C<mkpath> function of the L<File::Path> module.
3315
3316 =item msgctl ID,CMD,ARG
3317 X<msgctl>
3318
3319 Calls the System V IPC function msgctl(2).  You'll probably have to say
3320
3321     use IPC::SysV;
3322
3323 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3324 then ARG must be a variable that will hold the returned C<msqid_ds>
3325 structure.  Returns like C<ioctl>: the undefined value for error,
3326 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3327 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3328 C<IPC::Semaphore>.
3329
3330 Portability issues: L<perlport/msgctl>.
3331
3332 =item msgget KEY,FLAGS
3333 X<msgget>
3334
3335 Calls the System V IPC function msgget(2).  Returns the message queue
3336 id, or C<undef> on error.  See also
3337 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3338 C<IPC::Msg>.
3339
3340 Portability issues: L<perlport/msgget>.
3341
3342 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3343 X<msgrcv>
3344
3345 Calls the System V IPC function msgrcv to receive a message from
3346 message queue ID into variable VAR with a maximum message size of
3347 SIZE.  Note that when a message is received, the message type as a
3348 native long integer will be the first thing in VAR, followed by the
3349 actual message.  This packing may be opened with C<unpack("l! a*")>.
3350 Taints the variable.  Returns true if successful, false 
3351 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3352 C<IPC::SysV> and C<IPC::SysV::Msg>.
3353
3354 Portability issues: L<perlport/msgrcv>.
3355
3356 =item msgsnd ID,MSG,FLAGS
3357 X<msgsnd>
3358
3359 Calls the System V IPC function msgsnd to send the message MSG to the
3360 message queue ID.  MSG must begin with the native long integer message
3361 type, be followed by the length of the actual message, and then finally
3362 the message itself.  This kind of packing can be achieved with
3363 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3364 false on error.  See also the C<IPC::SysV>
3365 and C<IPC::SysV::Msg> documentation.
3366
3367 Portability issues: L<perlport/msgsnd>.
3368
3369 =item my EXPR
3370 X<my>
3371
3372 =item my TYPE EXPR
3373
3374 =item my EXPR : ATTRS
3375
3376 =item my TYPE EXPR : ATTRS
3377
3378 A C<my> declares the listed variables to be local (lexically) to the
3379 enclosing block, file, or C<eval>.  If more than one value is listed,
3380 the list must be placed in parentheses.
3381
3382 The exact semantics and interface of TYPE and ATTRS are still
3383 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3384 and attributes are handled using the C<attributes> pragma, or starting
3385 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3386 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3387 L<attributes>, and L<Attribute::Handlers>.
3388
3389 =item next LABEL
3390 X<next> X<continue>
3391
3392 =item next
3393
3394 The C<next> command is like the C<continue> statement in C; it starts
3395 the next iteration of the loop:
3396
3397     LINE: while (<STDIN>) {
3398         next LINE if /^#/;  # discard comments
3399         #...
3400     }
3401
3402 Note that if there were a C<continue> block on the above, it would get
3403 executed even on discarded lines.  If LABEL is omitted, the command
3404 refers to the innermost enclosing loop.
3405
3406 C<next> cannot be used to exit a block which returns a value such as
3407 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3408 a grep() or map() operation.
3409
3410 Note that a block by itself is semantically identical to a loop
3411 that executes once.  Thus C<next> will exit such a block early.
3412
3413 See also L</continue> for an illustration of how C<last>, C<next>, and
3414 C<redo> work.
3415
3416 =item no MODULE VERSION LIST
3417 X<no declarations>
3418 X<unimporting>
3419
3420 =item no MODULE VERSION
3421
3422 =item no MODULE LIST
3423
3424 =item no MODULE
3425
3426 =item no VERSION
3427
3428 See the C<use> function, of which C<no> is the opposite.
3429
3430 =item oct EXPR
3431 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3432
3433 =item oct
3434
3435 Interprets EXPR as an octal string and returns the corresponding
3436 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3437 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3438 binary string.  Leading whitespace is ignored in all three cases.)
3439 The following will handle decimal, binary, octal, and hex in standard
3440 Perl notation:
3441
3442     $val = oct($val) if $val =~ /^0/;
3443
3444 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3445 in octal), use sprintf() or printf():
3446
3447     $dec_perms = (stat("filename"))[2] & 07777;
3448     $oct_perm_str = sprintf "%o", $perms;
3449
3450 The oct() function is commonly used when a string such as C<644> needs
3451 to be converted into a file mode, for example.  Although Perl 
3452 automatically converts strings into numbers as needed, this automatic
3453 conversion assumes base 10.
3454
3455 Leading white space is ignored without warning, as too are any trailing 
3456 non-digits, such as a decimal point (C<oct> only handles non-negative
3457 integers, not negative integers or floating point).
3458
3459 =item open FILEHANDLE,EXPR
3460 X<open> X<pipe> X<file, open> X<fopen>
3461
3462 =item open FILEHANDLE,MODE,EXPR
3463
3464 =item open FILEHANDLE,MODE,EXPR,LIST
3465
3466 =item open FILEHANDLE,MODE,REFERENCE
3467
3468 =item open FILEHANDLE
3469
3470 Opens the file whose filename is given by EXPR, and associates it with
3471 FILEHANDLE.
3472
3473 Simple examples to open a file for reading:
3474
3475     open(my $fh, "<", "input.txt") 
3476         or die "cannot open < input.txt: $!";
3477
3478 and for writing:
3479
3480     open(my $fh, ">", "output.txt") 
3481         or die "cannot open > output.txt: $!";
3482
3483 (The following is a comprehensive reference to open(): for a gentler
3484 introduction you may consider L<perlopentut>.)
3485
3486 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3487 new filehandle is autovivified, meaning that the variable is assigned a
3488 reference to a newly allocated anonymous filehandle.  Otherwise if
3489 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3490 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3491 in effect.)
3492
3493 If EXPR is omitted, the global (package) scalar variable of the same
3494 name as the FILEHANDLE contains the filename.  (Note that lexical 
3495 variables--those declared with C<my> or C<state>--will not work for this
3496 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3497 call to open.)
3498
3499 If three (or more) arguments are specified, the open mode (including
3500 optional encoding) in the second argument are distinct from the filename in
3501 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3502 If MODE is C<< > >>, the file is opened for output, with existing files
3503 first being truncated ("clobbered") and nonexisting files newly created.
3504 If MODE is C<<< >> >>>, the file is opened for appending, again being
3505 created if necessary.
3506
3507 You can put a C<+> in front of the C<< > >> or C<< < >> to
3508 indicate that you want both read and write access to the file; thus
3509 C<< +< >> is almost always preferred for read/write updates--the 
3510 C<< +> >> mode would clobber the file first.  You cant usually use
3511 either read-write mode for updating textfiles, since they have
3512 variable-length records.  See the B<-i> switch in L<perlrun> for a
3513 better approach.  The file is created with permissions of C<0666>
3514 modified by the process's C<umask> value.
3515
3516 These various prefixes correspond to the fopen(3) modes of C<r>,
3517 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3518
3519 In the one- and two-argument forms of the call, the mode and filename
3520 should be concatenated (in that order), preferably separated by white
3521 space.  You can--but shouldn't--omit the mode in these forms when that mode
3522 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3523 the filename argument is a known literal.
3524
3525 For three or more arguments if MODE is C<|->, the filename is
3526 interpreted as a command to which output is to be piped, and if MODE
3527 is C<-|>, the filename is interpreted as a command that pipes
3528 output to us.  In the two-argument (and one-argument) form, one should
3529 replace dash (C<->) with the command.
3530 See L<perlipc/"Using open() for IPC"> for more examples of this.
3531 (You are not allowed to C<open> to a command that pipes both in I<and>
3532 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3533 L<perlipc/"Bidirectional Communication with Another Process"> for
3534 alternatives.)
3535
3536 In the form of pipe opens taking three or more arguments, if LIST is specified
3537 (extra arguments after the command name) then LIST becomes arguments
3538 to the command invoked if the platform supports it.  The meaning of
3539 C<open> with more than three arguments for non-pipe modes is not yet
3540 defined, but experimental "layers" may give extra LIST arguments
3541 meaning.
3542
3543 In the two-argument (and one-argument) form, opening C<< <- >> 
3544 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3545
3546 You may (and usually should) use the three-argument form of open to specify
3547 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3548 that affect how the input and output are processed (see L<open> and
3549 L<PerlIO> for more details). For example:
3550
3551   open(my $fh, "<:encoding(UTF-8)", "filename")
3552     || die "can't open UTF-8 encoded filename: $!";
3553
3554 opens the UTF8-encoded file containing Unicode characters;
3555 see L<perluniintro>. Note that if layers are specified in the
3556 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3557 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3558 Those layers will also be ignored if you specifying a colon with no name
3559 following it.  In that case the default layer for the operating system
3560 (:raw on Unix, :crlf on Windows) is used.
3561
3562 Open returns nonzero on success, the undefined value otherwise.  If
3563 the C<open> involved a pipe, the return value happens to be the pid of
3564 the subprocess.
3565
3566 If you're running Perl on a system that distinguishes between text
3567 files and binary files, then you should check out L</binmode> for tips
3568 for dealing with this.  The key distinction between systems that need
3569 C<binmode> and those that don't is their text file formats.  Systems
3570 like Unix, Mac OS, and Plan 9, that end lines with a single
3571 character and encode that character in C as C<"\n"> do not
3572 need C<binmode>.  The rest need it.
3573
3574 When opening a file, it's seldom a good idea to continue 
3575 if the request failed, so C<open> is frequently used with
3576 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3577 where you want to format a suitable error message (but there are
3578 modules that can help with that problem)) always check
3579 the return value from opening a file.  
3580
3581 As a special case the three-argument form with a read/write mode and the third
3582 argument being C<undef>:
3583
3584     open(my $tmp, "+>", undef) or die ...
3585
3586 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3587 works for symmetry, but you really should consider writing something
3588 to the temporary file first.  You will need to seek() to do the
3589 reading.
3590
3591 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3592 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3593 open filehandles directly to Perl scalars via:
3594
3595     open($fh, ">", \$variable) || ..
3596
3597 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3598
3599     close STDOUT;
3600     open(STDOUT, ">", \$variable)
3601         or die "Can't open STDOUT: $!";
3602
3603 General examples:
3604
3605     $ARTICLE = 100;
3606     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3607     while (<ARTICLE>) {...
3608
3609     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3610     # if the open fails, output is discarded
3611
3612     open(my $dbase, "+<", "dbase.mine")      # open for update
3613         or die "Can't open 'dbase.mine' for update: $!";
3614
3615     open(my $dbase, "+<dbase.mine")          # ditto
3616         or die "Can't open 'dbase.mine' for update: $!";
3617
3618     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3619         or die "Can't start caesar: $!";
3620
3621     open(ARTICLE, "caesar <$article |")      # ditto
3622         or die "Can't start caesar: $!";
3623
3624     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3625         or die "Can't start sort: $!";
3626
3627     # in-memory files
3628     open(MEMORY, ">", \$var)
3629         or die "Can't open memory file: $!";
3630     print MEMORY "foo!\n";                   # output will appear in $var
3631
3632     # process argument list of files along with any includes
3633
3634     foreach $file (@ARGV) {
3635         process($file, "fh00");
3636     }
3637
3638     sub process {
3639         my($filename, $input) = @_;
3640         $input++;    # this is a string increment
3641         unless (open($input, "<", $filename)) {
3642             print STDERR "Can't open $filename: $!\n";
3643             return;
3644         }
3645
3646         local $_;
3647         while (<$input>) {    # note use of indirection
3648             if (/^#include "(.*)"/) {
3649                 process($1, $input);
3650                 next;
3651             }
3652             #...          # whatever
3653         }
3654     }
3655
3656 See L<perliol> for detailed info on PerlIO.
3657
3658 You may also, in the Bourne shell tradition, specify an EXPR beginning
3659 with C<< >& >>, in which case the rest of the string is interpreted
3660 as the name of a filehandle (or file descriptor, if numeric) to be
3661 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3662 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3663 The mode you specify should match the mode of the original filehandle.
3664 (Duping a filehandle does not take into account any existing contents
3665 of IO buffers.) If you use the three-argument form, then you can pass either a
3666 number, the name of a filehandle, or the normal "reference to a glob".
3667
3668 Here is a script that saves, redirects, and restores C<STDOUT> and
3669 C<STDERR> using various methods:
3670
3671     #!/usr/bin/perl
3672     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3673     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3674
3675     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3676     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3677
3678     select STDERR; $| = 1;  # make unbuffered
3679     select STDOUT; $| = 1;  # make unbuffered
3680
3681     print STDOUT "stdout 1\n";  # this works for
3682     print STDERR "stderr 1\n";  # subprocesses too
3683
3684     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3685     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3686
3687     print STDOUT "stdout 2\n";
3688     print STDERR "stderr 2\n";
3689
3690 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3691 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3692 that file descriptor (and not call C<dup(2)>); this is more
3693 parsimonious of file descriptors.  For example:
3694
3695     # open for input, reusing the fileno of $fd
3696     open(FILEHANDLE, "<&=$fd")
3697
3698 or
3699
3700     open(FILEHANDLE, "<&=", $fd)
3701
3702 or
3703
3704     # open for append, using the fileno of OLDFH
3705     open(FH, ">>&=", OLDFH)
3706
3707 or
3708
3709     open(FH, ">>&=OLDFH")
3710
3711 Being parsimonious on filehandles is also useful (besides being
3712 parsimonious) for example when something is dependent on file
3713 descriptors, like for example locking using flock().  If you do just
3714 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3715 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3716 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3717 the same underlying system file descriptor.
3718
3719 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3720 fdopen() to implement the C<=> functionality.  On many Unix systems,
3721 fdopen() fails when file descriptors exceed a certain value, typically 255.
3722 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3723
3724 You can see whether your Perl was built with PerlIO by running C<perl -V>
3725 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3726 have PerlIO; otherwise you don't.
3727
3728 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3729 with the one- or two-argument forms of C<open>), 
3730 an implicit C<fork> is done, so C<open> returns twice: in the parent
3731 process it returns the pid
3732 of the child process, and in the child process it returns (a defined) C<0>.
3733 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3734
3735 For example, use either
3736
3737     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
3738
3739 or
3740     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3741
3742 followed by 
3743
3744     if ($child_pid) {
3745         # am the parent:
3746         # either write TO_KID or else read FROM_KID
3747         ...
3748         wait $child_pid;
3749     } else {
3750         # am the child; use STDIN/STDOUT normally
3751         ...
3752         exit;
3753     } 
3754
3755 The filehandle behaves normally for the parent, but I/O to that
3756 filehandle is piped from/to the STDOUT/STDIN of the child process.
3757 In the child process, the filehandle isn't opened--I/O happens from/to
3758 the new STDOUT/STDIN.  Typically this is used like the normal
3759 piped open when you want to exercise more control over just how the
3760 pipe command gets executed, such as when running setuid and
3761 you don't want to have to scan shell commands for metacharacters.
3762
3763 The following blocks are more or less equivalent:
3764
3765     open(FOO, "|tr '[a-z]' '[A-Z]'");
3766     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3767     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3768     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3769
3770     open(FOO, "cat -n '$file'|");
3771     open(FOO, "-|", "cat -n '$file'");
3772     open(FOO, "-|") || exec "cat", "-n", $file;
3773     open(FOO, "-|", "cat", "-n", $file);
3774
3775 The last two examples in each block show the pipe as "list form", which is
3776 not yet supported on all platforms.  A good rule of thumb is that if
3777 your platform has a real C<fork()> (in other words, if your platform is
3778 Unix, including Linux and MacOS X), you can use the list form.  You would 
3779 want to use the list form of the pipe so you can pass literal arguments
3780 to the command without risk of the shell interpreting any shell metacharacters
3781 in them.  However, this also bars you from opening pipes to commands
3782 that intentionally contain shell metacharacters, such as:
3783
3784     open(FOO, "|cat -n | expand -4 | lpr")
3785         // die "Can't open pipeline to lpr: $!";
3786
3787 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3788
3789 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3790 output before any operation that may do a fork, but this may not be
3791 supported on some platforms (see L<perlport>).  To be safe, you may need
3792 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3793 of C<IO::Handle> on any open handles.
3794
3795 On systems that support a close-on-exec flag on files, the flag will
3796 be set for the newly opened file descriptor as determined by the value
3797 of C<$^F>.  See L<perlvar/$^F>.
3798
3799 Closing any piped filehandle causes the parent process to wait for the
3800 child to finish, then returns the status value in C<$?> and
3801 C<${^CHILD_ERROR_NATIVE}>.
3802
3803 The filename passed to the one- and two-argument forms of open() will
3804 have leading and trailing whitespace deleted and normal
3805 redirection characters honored.  This property, known as "magic open",
3806 can often be used to good effect.  A user could specify a filename of
3807 F<"rsh cat file |">, or you could change certain filenames as needed:
3808
3809     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3810     open(FH, $filename) or die "Can't open $filename: $!";
3811
3812 Use the three-argument form to open a file with arbitrary weird characters in it,
3813
3814     open(FOO, "<", $file)
3815         || die "can't open < $file: $!";
3816
3817 otherwise it's necessary to protect any leading and trailing whitespace:
3818
3819     $file =~ s#^(\s)#./$1#;
3820     open(FOO, "< $file\0")
3821         || die "open failed: $!";
3822
3823 (this may not work on some bizarre filesystems).  One should
3824 conscientiously choose between the I<magic> and I<three-argument> form
3825 of open():
3826
3827     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3828
3829 will allow the user to specify an argument of the form C<"rsh cat file |">,
3830 but will not work on a filename that happens to have a trailing space, while
3831
3832     open(IN, "<", $ARGV[0])
3833         || die "can't open < $ARGV[0]: $!";
3834
3835 will have exactly the opposite restrictions.
3836
3837 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3838 should use the C<sysopen> function, which involves no such magic (but may
3839 use subtly different filemodes than Perl open(), which is mapped to C
3840 fopen()).  This is another way to protect your filenames from
3841 interpretation.  For example:
3842
3843     use IO::Handle;
3844     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3845         or die "sysopen $path: $!";
3846     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3847     print HANDLE "stuff $$\n";
3848     seek(HANDLE, 0, 0);
3849     print "File contains: ", <HANDLE>;
3850
3851 Using the constructor from the C<IO::Handle> package (or one of its
3852 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3853 filehandles that have the scope of the variables used to hold them, then
3854 automatically (but silently) close once their reference counts become
3855 zero, typically at scope exit:
3856
3857     use IO::File;
3858     #...
3859     sub read_myfile_munged {
3860         my $ALL = shift;
3861         # or just leave it undef to autoviv
3862         my $handle = IO::File->new;
3863         open($handle, "<", "myfile") or die "myfile: $!";
3864         $first = <$handle>
3865             or return ();     # Automatically closed here.
3866         mung($first) or die "mung failed";  # Or here.
3867         return (first, <$handle>) if $ALL;  # Or here.
3868         return $first;                      # Or here.
3869     }
3870
3871 B<WARNING:> The previous example has a bug because the automatic
3872 close that happens when the refcount on C<handle> does not
3873 properly detect and report failures.  I<Always> close the handle
3874 yourself and inspect the return value.
3875
3876     close($handle) 
3877         || warn "close failed: $!";
3878
3879 See L</seek> for some details about mixing reading and writing.
3880
3881 Portability issues: L<perlport/open>.
3882
3883 =item opendir DIRHANDLE,EXPR
3884 X<opendir>
3885
3886 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3887 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3888 DIRHANDLE may be an expression whose value can be used as an indirect
3889 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3890 scalar variable (or array or hash element), the variable is assigned a
3891 reference to a new anonymous dirhandle; that is, it's autovivified.
3892 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3893
3894 See the example at C<readdir>.
3895
3896 =item ord EXPR
3897 X<ord> X<encoding>
3898
3899 =item ord
3900
3901 Returns the numeric value of the first character of EXPR.
3902 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3903 (Note I<character>, not byte.)
3904
3905 For the reverse, see L</chr>.
3906 See L<perlunicode> for more about Unicode.
3907
3908 =item our EXPR
3909 X<our> X<global>
3910
3911 =item our TYPE EXPR
3912
3913 =item our EXPR : ATTRS
3914
3915 =item our TYPE EXPR : ATTRS
3916
3917 C<our> associates a simple name with a package variable in the current
3918 package for use within the current scope.  When C<use strict 'vars'> is in
3919 effect, C<our> lets you use declared global variables without qualifying
3920 them with package names, within the lexical scope of the C<our> declaration.
3921 In this way C<our> differs from C<use vars>, which is package-scoped.
3922
3923 Unlike C<my> or C<state>, which allocates storage for a variable and
3924 associates a simple name with that storage for use within the current
3925 scope, C<our> associates a simple name with a package (read: global)
3926 variable in the current package, for use within the current lexical scope.
3927 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
3928 does not necessarily create a variable.
3929
3930 If more than one value is listed, the list must be placed
3931 in parentheses.
3932
3933     our $foo;
3934     our($bar, $baz);
3935
3936 An C<our> declaration declares a global variable that will be visible
3937 across its entire lexical scope, even across package boundaries.  The
3938 package in which the variable is entered is determined at the point
3939 of the declaration, not at the point of use.  This means the following
3940 behavior holds:
3941
3942     package Foo;
3943     our $bar;      # declares $Foo::bar for rest of lexical scope
3944     $bar = 20;
3945
3946     package Bar;
3947     print $bar;    # prints 20, as it refers to $Foo::bar
3948
3949 Multiple C<our> declarations with the same name in the same lexical
3950 scope are allowed if they are in different packages.  If they happen
3951 to be in the same package, Perl will emit warnings if you have asked
3952 for them, just like multiple C<my> declarations.  Unlike a second
3953 C<my> declaration, which will bind the name to a fresh variable, a
3954 second C<our> declaration in the same package, in the same scope, is
3955 merely redundant.
3956
3957     use warnings;
3958     package Foo;
3959     our $bar;      # declares $Foo::bar for rest of lexical scope
3960     $bar = 20;
3961
3962     package Bar;
3963     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3964     print $bar;    # prints 30
3965
3966     our $bar;      # emits warning but has no other effect
3967     print $bar;    # still prints 30
3968
3969 An C<our> declaration may also have a list of attributes associated
3970 with it.
3971
3972 The exact semantics and interface of TYPE and ATTRS are still
3973 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3974 and attributes are handled using the C<attributes> pragma, or starting
3975 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3976 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3977 L<attributes>, and L<Attribute::Handlers>.
3978
3979 =item pack TEMPLATE,LIST
3980 X<pack>
3981
3982 Takes a LIST of values and converts it into a string using the rules
3983 given by the TEMPLATE.  The resulting string is the concatenation of
3984 the converted values.  Typically, each converted value looks
3985 like its machine-level representation.  For example, on 32-bit machines
3986 an integer may be represented by a sequence of 4 bytes, which  will in
3987 Perl be presented as a string that's 4 characters long. 
3988
3989 See L<perlpacktut> for an introduction to this function.
3990
3991 The TEMPLATE is a sequence of characters that give the order and type
3992 of values, as follows:
3993
3994     a  A string with arbitrary binary data, will be null padded.
3995     A  A text (ASCII) string, will be space padded.
3996     Z  A null-terminated (ASCIZ) string, will be null padded.
3997
3998     b  A bit string (ascending bit order inside each byte,
3999        like vec()).
4000     B  A bit string (descending bit order inside each byte).
4001     h  A hex string (low nybble first).
4002     H  A hex string (high nybble first).
4003
4004     c  A signed char (8-bit) value.
4005     C  An unsigned char (octet) value.
4006     W  An unsigned char value (can be greater than 255).
4007
4008     s  A signed short (16-bit) value.
4009     S  An unsigned short value.
4010
4011     l  A signed long (32-bit) value.
4012     L  An unsigned long value.
4013
4014     q  A signed quad (64-bit) value.
4015     Q  An unsigned quad value.
4016          (Quads are available only if your system supports 64-bit
4017           integer values _and_ if Perl has been compiled to support
4018           those.  Raises an exception otherwise.)
4019
4020     i  A signed integer value.
4021     I  A unsigned integer value.
4022          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4023           size depends on what a local C compiler calls 'int'.)
4024
4025     n  An unsigned short (16-bit) in "network" (big-endian) order.
4026     N  An unsigned long (32-bit) in "network" (big-endian) order.
4027     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4028     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4029
4030     j  A Perl internal signed integer value (IV).
4031     J  A Perl internal unsigned integer value (UV).
4032
4033     f  A single-precision float in native format.
4034     d  A double-precision float in native format.
4035
4036     F  A Perl internal floating-point value (NV) in native format
4037     D  A float of long-double precision in native format.
4038          (Long doubles are available only if your system supports
4039           long double values _and_ if Perl has been compiled to
4040           support those.  Raises an exception otherwise.)
4041
4042     p  A pointer to a null-terminated string.
4043     P  A pointer to a structure (fixed-length string).
4044
4045     u  A uuencoded string.
4046     U  A Unicode character number.  Encodes to a character in char-
4047        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4048        byte mode.
4049
4050     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4051        for details).  Its bytes represent an unsigned integer in
4052        base 128, most significant digit first, with as few digits
4053        as possible.  Bit eight (the high bit) is set on each byte
4054        except the last.
4055
4056     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4057     X  Back up a byte.
4058     @  Null-fill or truncate to absolute position, counted from the
4059        start of the innermost ()-group.
4060     .  Null-fill or truncate to absolute position specified by
4061        the value.
4062     (  Start of a ()-group.
4063
4064 One or more modifiers below may optionally follow certain letters in the
4065 TEMPLATE (the second column lists letters for which the modifier is valid):
4066
4067     !   sSlLiI     Forces native (short, long, int) sizes instead
4068                    of fixed (16-/32-bit) sizes.
4069
4070         xX         Make x and X act as alignment commands.
4071
4072         nNvV       Treat integers as signed instead of unsigned.
4073
4074         @.         Specify position as byte offset in the internal
4075                    representation of the packed string. Efficient but
4076                    dangerous.
4077
4078     >   sSiIlLqQ   Force big-endian byte-order on the type.
4079         jJfFdDpP   (The "big end" touches the construct.)
4080
4081     <   sSiIlLqQ   Force little-endian byte-order on the type.
4082         jJfFdDpP   (The "little end" touches the construct.)
4083
4084 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4085 to force a particular byte-order on all components in that group, 
4086 including all its subgroups.
4087
4088 The following rules apply:
4089
4090 =over 
4091
4092 =item *
4093
4094 Each letter may optionally be followed by a number indicating the repeat
4095 count.  A numeric repeat count may optionally be enclosed in brackets, as
4096 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4097 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4098 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4099 something else, described below.  Supplying a C<*> for the repeat count
4100 instead of a number means to use however many items are left, except for:
4101
4102 =over 
4103
4104 =item * 
4105
4106 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4107
4108 =item * 
4109
4110 <.>, where it means relative to the start of the string.
4111
4112 =item * 
4113
4114 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4115
4116 =back 
4117
4118 One can replace a numeric repeat count with a template letter enclosed in
4119 brackets to use the packed byte length of the bracketed template for the
4120 repeat count.
4121
4122 For example, the template C<x[L]> skips as many bytes as in a packed long,
4123 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4124 variable-expanded) unpacks.  If the template in brackets contains alignment
4125 commands (such as C<x![d]>), its packed length is calculated as if the
4126 start of the template had the maximal possible alignment.
4127
4128 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4129 trailing null byte, so the resulting string is always one byte longer than
4130 the byte length of the item itself.
4131
4132 When used with C<@>, the repeat count represents an offset from the start
4133 of the innermost C<()> group.
4134
4135 When used with C<.>, the repeat count determines the starting position to
4136 calculate the value offset as follows:
4137
4138 =over 
4139
4140 =item *
4141
4142 If the repeat count is C<0>, it's relative to the current position.
4143
4144 =item *
4145
4146 If the repeat count is C<*>, the offset is relative to the start of the
4147 packed string.
4148
4149 =item *
4150
4151 And if it's an integer I<n>, the offset is relative to the start of the
4152 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4153 bigger then the group level.
4154
4155 =back
4156
4157 The repeat count for C<u> is interpreted as the maximal number of bytes
4158 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
4159 count should not be more than 65.
4160
4161 =item *
4162
4163 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4164 string of length count, padding with nulls or spaces as needed.  When
4165 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4166 after the first null, and C<a> returns data with no stripping at all.
4167
4168 If the value to pack is too long, the result is truncated.  If it's too
4169 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4170 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4171 when the count is 0.
4172
4173 =item *
4174
4175 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4176 Each such format generates 1 bit of the result.  These are typically followed
4177 by a repeat count like C<B8> or C<B64>.
4178
4179 Each result bit is based on the least-significant bit of the corresponding
4180 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4181 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4182
4183 Starting from the beginning of the input string, each 8-tuple
4184 of characters is converted to 1 character of output.  With format C<b>,
4185 the first character of the 8-tuple determines the least-significant bit of a
4186 character; with format C<B>, it determines the most-significant bit of
4187 a character.
4188
4189 If the length of the input string is not evenly divisible by 8, the
4190 remainder is packed as if the input string were padded by null characters
4191 at the end.  Similarly during unpacking, "extra" bits are ignored.
4192
4193 If the input string is longer than needed, remaining characters are ignored.
4194
4195 A C<*> for the repeat count uses all characters of the input field.  
4196 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4197
4198 =item *
4199
4200 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4201 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4202
4203 For each such format, pack() generates 4 bits of result.
4204 With non-alphabetical characters, the result is based on the 4 least-significant
4205 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4206 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4207 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4208 is compatible with the usual hexadecimal digits, so that C<"a"> and
4209 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4210 characters with this format.
4211
4212 Starting from the beginning of the template to pack(), each pair
4213 of characters is converted to 1 character of output.  With format C<h>, the
4214 first character of the pair determines the least-significant nybble of the
4215 output character; with format C<H>, it determines the most-significant
4216 nybble.
4217
4218 If the length of the input string is not even, it behaves as if padded by
4219 a null character at the end.  Similarly, "extra" nybbles are ignored during
4220 unpacking.
4221
4222 If the input string is longer than needed, extra characters are ignored.
4223
4224 A C<*> for the repeat count uses all characters of the input field.  For
4225 unpack(), nybbles are converted to a string of hexadecimal digits.
4226
4227 =item *
4228
4229 The C<p> format packs a pointer to a null-terminated string.  You are
4230 responsible for ensuring that the string is not a temporary value, as that
4231 could potentially get deallocated before you got around to using the packed
4232 result.  The C<P> format packs a pointer to a structure of the size indicated
4233 by the length.  A null pointer is created if the corresponding value for
4234 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4235 unpacks into C<undef>.
4236
4237 If your system has a strange pointer size--meaning a pointer is neither as
4238 big as an int nor as big as a long--it may not be possible to pack or
4239 unpack pointers in big- or little-endian byte order.  Attempting to do
4240 so raises an exception.
4241
4242 =item *
4243
4244 The C</> template character allows packing and unpacking of a sequence of
4245 items where the packed structure contains a packed item count followed by
4246 the packed items themselves.  This is useful when the structure you're
4247 unpacking has encoded the sizes or repeat counts for some of its fields
4248 within the structure itself as separate fields.
4249
4250 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4251 I<length-item> describes how the length value is packed. Formats likely
4252 to be of most use are integer-packing ones like C<n> for Java strings,
4253 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4254
4255 For C<pack>, I<sequence-item> may have a repeat count, in which case
4256 the minimum of that and the number of available items is used as the argument
4257 for I<length-item>. If it has no repeat count or uses a '*', the number
4258 of available items is used.
4259
4260 For C<unpack>, an internal stack of integer arguments unpacked so far is
4261 used. You write C</>I<sequence-item> and the repeat count is obtained by
4262 popping off the last element from the stack. The I<sequence-item> must not
4263 have a repeat count.
4264
4265 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4266 the I<length-item> is the string length, not the number of strings.  With
4267 an explicit repeat count for pack, the packed string is adjusted to that
4268 length.  For example:
4269
4270  This code:                              gives this result:
4271  
4272   unpack("W/a", "\004Gurusamy")          ("Guru")
4273   unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4274   unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4275
4276   pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4277   pack("a/W2", ord("a") .. ord("z"))    "2ab"
4278
4279 The I<length-item> is not returned explicitly from C<unpack>.
4280
4281 Supplying a count to the I<length-item> format letter is only useful with
4282 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4283 introduce C<"\000"> characters, which Perl does not regard as legal in
4284 numeric strings.
4285
4286 =item *
4287
4288 The integer types C<s>, C<S>, C<l>, and C<L> may be
4289 followed by a C<!> modifier to specify native shorts or
4290 longs.  As shown in the example above, a bare C<l> means
4291 exactly 32 bits, although the native C<long> as seen by the local C compiler
4292 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4293 see whether using C<!> makes any difference this way:
4294
4295     printf "format s is %d, s! is %d\n", 
4296         length pack("s"), length pack("s!");
4297
4298     printf "format l is %d, l! is %d\n", 
4299         length pack("l"), length pack("l!");
4300
4301
4302 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4303 they are identical to C<i> and C<I>.
4304
4305 The actual sizes (in bytes) of native shorts, ints, longs, and long
4306 longs on the platform where Perl was built are also available from
4307 the command line:
4308
4309     $ perl -V:{short,int,long{,long}}size
4310     shortsize='2';
4311     intsize='4';
4312     longsize='4';
4313     longlongsize='8';
4314
4315 or programmatically via the C<Config> module:
4316
4317        use Config;
4318        print $Config{shortsize},    "\n";
4319        print $Config{intsize},      "\n";
4320        print $Config{longsize},     "\n";
4321        print $Config{longlongsize}, "\n";
4322
4323 C<$Config{longlongsize}> is undefined on systems without 
4324 long long support.
4325
4326 =item *
4327
4328 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4329 inherently non-portable between processors and operating systems because
4330 they obey native byteorder and endianness.  For example, a 4-byte integer
4331 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4332 handled by the CPU registers) into bytes as
4333
4334     0x12 0x34 0x56 0x78  # big-endian
4335     0x78 0x56 0x34 0x12  # little-endian
4336
4337 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4338 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4339 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4340 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4341
4342 The names I<big-endian> and I<little-endian> are comic references to the
4343 egg-eating habits of the little-endian Lilliputians and the big-endian
4344 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4345 This entered computer lingo via the paper "On Holy Wars and a Plea for
4346 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4347
4348 Some systems may have even weirder byte orders such as
4349
4350    0x56 0x78 0x12 0x34
4351    0x34 0x12 0x78 0x56
4352
4353 You can determine your system endianness with this incantation:
4354
4355    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4356
4357 The byteorder on the platform where Perl was built is also available
4358 via L<Config>:
4359
4360     use Config;
4361     print "$Config{byteorder}\n";
4362
4363 or from the command line:
4364
4365     $ perl -V:byteorder
4366
4367 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4368 and C<"87654321"> are big-endian.
4369
4370 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4371 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4372 immediately below.  See also L<perlport>.
4373
4374 =item *
4375
4376 Starting with Perl 5.9.2, integer and floating-point formats, along with
4377 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4378 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4379 or little-endian byte-order.  These modifiers are especially useful 
4380 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4381 64-bit integers, or floating-point values.
4382
4383 Here are some concerns to keep in mind when using an endianness modifier:
4384
4385 =over
4386
4387 =item * 
4388
4389 Exchanging signed integers between different platforms works only 
4390 when all platforms store them in the same format.  Most platforms store
4391 signed integers in two's-complement notation, so usually this is not an issue.
4392
4393 =item * 
4394
4395 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4396 formats on big- or little-endian machines.  Otherwise, attempting to
4397 use them raises an exception.
4398
4399 =item * 
4400
4401 Forcing big- or little-endian byte-order on floating-point values for
4402 data exchange can work only if all platforms use the same
4403 binary representation such as IEEE floating-point.  Even if all
4404 platforms are using IEEE, there may still be subtle differences.  Being able
4405 to use C<< > >> or C<< < >> on floating-point values can be useful,
4406 but also dangerous if you don't know exactly what you're doing.
4407 It is not a general way to portably store floating-point values.
4408
4409 =item * 
4410
4411 When using C<< > >> or C<< < >> on a C<()> group, this affects
4412 all types inside the group that accept byte-order modifiers,
4413 including all subgroups.  It is silently ignored for all other
4414 types.  You are not allowed to override the byte-order within a group
4415 that already has a byte-order modifier suffix.
4416
4417 =back
4418
4419 =item *
4420
4421 Real numbers (floats and doubles) are in native machine format only.
4422 Due to the multiplicity of floating-point formats and the lack of a
4423 standard "network" representation for them, no facility for interchange has been
4424 made.  This means that packed floating-point data written on one machine
4425 may not be readable on another, even if both use IEEE floating-point
4426 arithmetic (because the endianness of the memory representation is not part
4427 of the IEEE spec).  See also L<perlport>.
4428
4429 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4430 modifiers to force big- or little-endian byte-order on floating-point values.
4431
4432 Because Perl uses doubles (or long doubles, if configured) internally for
4433 all numeric calculation, converting from double into float and thence 
4434 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4435 will not in general equal $foo.
4436
4437 =item *
4438
4439 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4440 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4441 where the packed string is processed in its UTF-8-encoded Unicode form on
4442 a byte-by-byte basis. Character mode is the default unless the format string 
4443 starts with C<U>. You can always switch mode mid-format with an explicit 
4444 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4445 mode change, or until the end of the C<()> group it (directly) applies to.
4446
4447 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4448 bytes is not necessarily obvious.   Probably only the first of these
4449 is what you want:
4450
4451     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4452       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4453     03B1.03C9
4454     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4455       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4456     CE.B1.CF.89
4457     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4458       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4459     CE.B1.CF.89
4460     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4461       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4462     C3.8E.C2.B1.C3.8F.C2.89
4463
4464 Those examples also illustrate that you should not try to use
4465 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4466
4467 =item *
4468
4469 You must yourself do any alignment or padding by inserting, for example,
4470 enough C<"x">es while packing.  There is no way for pack() and unpack()
4471 to know where characters are going to or coming from, so they 
4472 handle their output and input as flat sequences of characters.
4473
4474 =item *
4475
4476 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4477 take a repeat count either as postfix, or for unpack(), also via the C</>
4478 template character.  Within each repetition of a group, positioning with
4479 C<@> starts over at 0. Therefore, the result of
4480
4481     pack("@1A((@2A)@3A)", qw[X Y Z])
4482
4483 is the string C<"\0X\0\0YZ">.
4484
4485 =item *
4486
4487 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4488 jump forward or back to the closest position aligned at a multiple of C<count>
4489 characters. For example, to pack() or unpack() a C structure like
4490
4491     struct {
4492         char   c;    /* one signed, 8-bit character */
4493         double d; 
4494         char   cc[2];
4495     }
4496
4497 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4498 doubles must be aligned to the size of double.
4499
4500 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4501 both are no-ops.
4502
4503 =item *
4504
4505 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4506 represent signed 16-/32-bit integers in big-/little-endian order.
4507 This is portable only when all platforms sharing packed data use the
4508 same binary representation for signed integers; for example, when all
4509 platforms use two's-complement representation.
4510
4511 =item *
4512
4513 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4514 White space can separate pack codes from each other, but modifiers and
4515 repeat counts must follow immediately.  Breaking complex templates into
4516 individual line-by-line components, suitably annotated, can do as much to
4517 improve legibility and maintainability of pack/unpack formats as C</x> can
4518 for complicated pattern matches.
4519
4520 =item *
4521
4522 If TEMPLATE requires more arguments than pack() is given, pack()
4523 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4524 than given, extra arguments are ignored.
4525
4526 =back
4527
4528 Examples:
4529
4530     $foo = pack("WWWW",65,66,67,68);
4531     # foo eq "ABCD"
4532     $foo = pack("W4",65,66,67,68);
4533     # same thing
4534     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4535     # same thing with Unicode circled letters.
4536     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4537     # same thing with Unicode circled letters. You don't get the
4538     # UTF-8 bytes because the U at the start of the format caused
4539     # a switch to U0-mode, so the UTF-8 bytes get joined into
4540     # characters
4541     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4542     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4543     # This is the UTF-8 encoding of the string in the
4544     # previous example
4545
4546     $foo = pack("ccxxcc",65,66,67,68);
4547     # foo eq "AB\0\0CD"
4548
4549     # NOTE: The examples above featuring "W" and "c" are true
4550     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4551     # and UTF-8.  On EBCDIC systems, the first example would be
4552     #      $foo = pack("WWWW",193,194,195,196);
4553
4554     $foo = pack("s2",1,2);
4555     # "\001\000\002\000" on little-endian
4556     # "\000\001\000\002" on big-endian
4557
4558     $foo = pack("a4","abcd","x","y","z");
4559     # "abcd"
4560
4561     $foo = pack("aaaa","abcd","x","y","z");
4562     # "axyz"
4563
4564     $foo = pack("a14","abcdefg");
4565     # "abcdefg\0\0\0\0\0\0\0"
4566
4567     $foo = pack("i9pl", gmtime);
4568     # a real struct tm (on my system anyway)
4569
4570     $utmp_template = "Z8 Z8 Z16 L";
4571     $utmp = pack($utmp_template, @utmp1);
4572     # a struct utmp (BSDish)
4573
4574     @utmp2 = unpack($utmp_template, $utmp);
4575     # "@utmp1" eq "@utmp2"
4576
4577     sub bintodec {
4578         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4579     }
4580
4581     $foo = pack('sx2l', 12, 34);
4582     # short 12, two zero bytes padding, long 34
4583     $bar = pack('s@4l', 12, 34);
4584     # short 12, zero fill to position 4, long 34
4585     # $foo eq $bar
4586     $baz = pack('s.l', 12, 4, 34);
4587     # short 12, zero fill to position 4, long 34
4588
4589     $foo = pack('nN', 42, 4711);
4590     # pack big-endian 16- and 32-bit unsigned integers
4591     $foo = pack('S>L>', 42, 4711);
4592     # exactly the same
4593     $foo = pack('s<l<', -42, 4711);
4594     # pack little-endian 16- and 32-bit signed integers
4595     $foo = pack('(sl)<', -42, 4711);
4596     # exactly the same
4597
4598 The same template may generally also be used in unpack().
4599
4600 =item package NAMESPACE
4601
4602 =item package NAMESPACE VERSION
4603 X<package> X<module> X<namespace> X<version>
4604
4605 =item package NAMESPACE BLOCK
4606
4607 =item package NAMESPACE VERSION BLOCK
4608 X<package> X<module> X<namespace> X<version>
4609
4610 Declares the BLOCK or the rest of the compilation unit as being in the
4611 given namespace.  The scope of the package declaration is either the
4612 supplied code BLOCK or, in the absence of a BLOCK, from the declaration
4613 itself through the end of current scope (the enclosing block, file, or
4614 C<eval>).  That is, the forms without a BLOCK are operative through the end
4615 of the current scope, just like the C<my>, C<state>, and C<our> operators.
4616 All unqualified dynamic identifiers in this scope will be in the given
4617 namespace, except where overridden by another C<package> declaration or
4618 when they're one of the special identifiers that qualify into C<main::>,
4619 like C<STDOUT>, C<ARGV>, C<ENV>, and the punctuation variables.
4620
4621 A package statement affects dynamic variables only, including those
4622 you've used C<local> on, but I<not> lexical variables, which are created
4623 with C<my>, C<state>, or C<our>.  Typically it would be the first 
4624 declaration in a file included by C<require> or C<use>.  You can switch into a
4625 package in more than one place, since this only determines which default 
4626 symbol table the compiler uses for the rest of that block.  You can refer to
4627 identifiers in other packages than the current one by prefixing the identifier
4628 with the package name and a double colon, as in C<$SomePack::var>
4629 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4630 package as assumed.  That is, C<$::sail> is equivalent to
4631 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4632 code, mostly from Perl 4).
4633
4634 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4635 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4636 "strict" style version number as defined by the L<version> module: a positive
4637 decimal number (integer or decimal-fraction) without exponentiation or else a
4638 dotted-decimal v-string with a leading 'v' character and at least three
4639 components.  You should set C<$VERSION> only once per package.
4640
4641 See L<perlmod/"Packages"> for more information about packages, modules,
4642 and classes.  See L<perlsub> for other scoping issues.
4643
4644 =item pipe READHANDLE,WRITEHANDLE
4645 X<pipe>
4646
4647 Opens a pair of connected pipes like the corresponding system call.
4648 Note that if you set up a loop of piped processes, deadlock can occur
4649 unless you are very careful.  In addition, note that Perl's pipes use
4650 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4651 after each command, depending on the application.
4652
4653 See L<IPC::Open2>, L<IPC::Open3>,&n