This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlre: Fix too long verbatim line
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start of the string's first line and the end of its last line to
35 matching the start and end of each line within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in a bracketed
76 character class unless the character that maps to them is explicitly
77 mentioned, and it doesn't match them at all if the character class is
78 inverted, which otherwise could be highly confusing.  See
79 L<perlrecharclass/Bracketed Character Classes>, and
80 L<perlrecharclass/Negation>.
81
82 =item x
83 X</x>
84
85 Extend your pattern's legibility by permitting whitespace and comments.
86 Details in L</"/x">
87
88 =item p
89 X</p> X<regex, preserve> X<regexp, preserve>
90
91 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
92 ${^POSTMATCH} are available for use after matching.
93
94 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
95 mechanism, ${^PREMATCH}, ${^MATCH}, and ${^POSTMATCH} will be available
96 after the match regardless of the modifier.
97
98 =item a, d, l and u
99 X</a> X</d> X</l> X</u>
100
101 These modifiers, all new in 5.14, affect which character-set rules
102 (Unicode, etc.) are used, as described below in
103 L</Character set modifiers>.
104
105 =item n
106 X</n> X<regex, non-capture> X<regexp, non-capture>
107 X<regular expression, non-capture>
108
109 Prevent the grouping metacharacters C<()> from capturing. This modifier,
110 new in 5.22, will stop C<$1>, C<$2>, etc... from being filled in.
111
112   "hello" =~ /(hi|hello)/;   # $1 is "hello"
113   "hello" =~ /(hi|hello)/n;  # $1 is undef
114
115 This is equivalent to putting ?: at the beginning of every capturing group:
116
117   "hello" =~ /(?:hi|hello)/; # $1 is undef
118
119 C</n> can be negated on a per-group basis. Alternatively, named captures
120 may still be used.
121
122   "hello" =~ /(?-n:(hi|hello))/n;   # $1 is "hello"
123   "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
124                                     # "hello"
125
126 =item Other Modifiers
127
128 There are a number of flags that can be found at the end of regular
129 expression constructs that are I<not> generic regular expression flags, but
130 apply to the operation being performed, like matching or substitution (C<m//>
131 or C<s///> respectively).
132
133 Flags described further in
134 L<perlretut/"Using regular expressions in Perl"> are:
135
136   c  - keep the current position during repeated matching
137   g  - globally match the pattern repeatedly in the string
138
139 Substitution-specific modifiers described in
140
141 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are:
142
143   e  - evaluate the right-hand side as an expression
144   ee - evaluate the right side as a string then eval the result
145   o  - pretend to optimize your code, but actually introduce bugs
146   r  - perform non-destructive substitution and return the new value
147
148 =back
149
150 Regular expression modifiers are usually written in documentation
151 as e.g., "the C</x> modifier", even though the delimiter
152 in question might not really be a slash.  The modifiers C</imsxadlup>
153 may also be embedded within the regular expression itself using
154 the C<(?...)> construct, see L</Extended Patterns> below.
155
156 =head3 /x
157
158 C</x> tells
159 the regular expression parser to ignore most whitespace that is neither
160 backslashed nor within a bracketed character class.  You can use this to
161 break up your regular expression into (slightly) more readable parts.
162 Also, the C<#> character is treated as a metacharacter introducing a
163 comment that runs up to the pattern's closing delimiter, or to the end
164 of the current line if the pattern extends onto the next line.  Hence,
165 this is very much like an ordinary Perl code comment.  (You can include
166 the closing delimiter within the comment only if you precede it with a
167 backslash, so be careful!)
168
169 Use of C</x> means that if you want real
170 whitespace or C<#> characters in the pattern (outside a bracketed character
171 class, which is unaffected by C</x>), then you'll either have to
172 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
173 hex, or C<\N{}> escapes.
174 It is ineffective to try to continue a comment onto the next line by
175 escaping the C<\n> with a backslash or C<\Q>.
176
177 You can use L</(?#text)> to create a comment that ends earlier than the
178 end of the current line, but C<text> also can't contain the closing
179 delimiter unless escaped with a backslash.
180
181 Taken together, these features go a long way towards
182 making Perl's regular expressions more readable.  Here's an example:
183
184     # Delete (most) C comments.
185     $program =~ s {
186         /\*     # Match the opening delimiter.
187         .*?     # Match a minimal number of characters.
188         \*/     # Match the closing delimiter.
189     } []gsx;
190
191 Note that anything inside
192 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
193 space interpretation within a single multi-character construct.  For
194 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
195 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
196 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<(>,
197 C<?>, and C<:>.  Within any delimiters for such a
198 construct, allowed spaces are not affected by C</x>, and depend on the
199 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
200 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
201 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
202 L<perluniprops/Properties accessible through \p{} and \P{}>.
203 X</x>
204
205 The set of characters that are deemed whitespace are those that Unicode
206 calls "Pattern White Space", namely:
207
208  U+0009 CHARACTER TABULATION
209  U+000A LINE FEED
210  U+000B LINE TABULATION
211  U+000C FORM FEED
212  U+000D CARRIAGE RETURN
213  U+0020 SPACE
214  U+0085 NEXT LINE
215  U+200E LEFT-TO-RIGHT MARK
216  U+200F RIGHT-TO-LEFT MARK
217  U+2028 LINE SEPARATOR
218  U+2029 PARAGRAPH SEPARATOR
219
220 =head3 Character set modifiers
221
222 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
223 the character set modifiers; they affect the character set rules
224 used for the regular expression.
225
226 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
227 to you, and so you need not worry about them very much.  They exist for
228 Perl's internal use, so that complex regular expression data structures
229 can be automatically serialized and later exactly reconstituted,
230 including all their nuances.  But, since Perl can't keep a secret, and
231 there may be rare instances where they are useful, they are documented
232 here.
233
234 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
235 allow code that is to work mostly on ASCII data to not have to concern
236 itself with Unicode.
237
238 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
239 effect at the time of the execution of the pattern match.
240
241 C</u> sets the character set to B<U>nicode.
242
243 C</a> also sets the character set to Unicode, BUT adds several
244 restrictions for B<A>SCII-safe matching.
245
246 C</d> is the old, problematic, pre-5.14 B<D>efault character set
247 behavior.  Its only use is to force that old behavior.
248
249 At any given time, exactly one of these modifiers is in effect.  Their
250 existence allows Perl to keep the originally compiled behavior of a
251 regular expression, regardless of what rules are in effect when it is
252 actually executed.  And if it is interpolated into a larger regex, the
253 original's rules continue to apply to it, and only it.
254
255 The C</l> and C</u> modifiers are automatically selected for
256 regular expressions compiled within the scope of various pragmas,
257 and we recommend that in general, you use those pragmas instead of
258 specifying these modifiers explicitly.  For one thing, the modifiers
259 affect only pattern matching, and do not extend to even any replacement
260 done, whereas using the pragmas give consistent results for all
261 appropriate operations within their scopes.  For example,
262
263  s/foo/\Ubar/il
264
265 will match "foo" using the locale's rules for case-insensitive matching,
266 but the C</l> does not affect how the C<\U> operates.  Most likely you
267 want both of them to use locale rules.  To do this, instead compile the
268 regular expression within the scope of C<use locale>.  This both
269 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
270 lesson is to C<use locale> and not C</l> explicitly.
271
272 Similarly, it would be better to use C<use feature 'unicode_strings'>
273 instead of,
274
275  s/foo/\Lbar/iu
276
277 to get Unicode rules, as the C<\L> in the former (but not necessarily
278 the latter) would also use Unicode rules.
279
280 More detail on each of the modifiers follows.  Most likely you don't
281 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
282 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
283
284 =head4 /l
285
286 means to use the current locale's rules (see L<perllocale>) when pattern
287 matching.  For example, C<\w> will match the "word" characters of that
288 locale, and C<"/i"> case-insensitive matching will match according to
289 the locale's case folding rules.  The locale used will be the one in
290 effect at the time of execution of the pattern match.  This may not be
291 the same as the compilation-time locale, and can differ from one match
292 to another if there is an intervening call of the
293 L<setlocale() function|perllocale/The setlocale function>.
294
295 The only non-single-byte locale Perl supports is (starting in v5.20)
296 UTF-8.  This means that code points above 255 are treated as Unicode no
297 matter what locale is in effect (since UTF-8 implies Unicode).
298
299 Under Unicode rules, there are a few case-insensitive matches that cross
300 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
301 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
302 platforms) does not caselessly match the character at 0x178, C<LATIN
303 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
304 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
305 knowing if that character even exists in the locale, much less what code
306 point it is.
307
308 In a UTF-8 locale in v5.20 and later, the only visible difference
309 between locale and non-locale in regular expressions should be tainting
310 (see L<perlsec>).
311
312 This modifier may be specified to be the default by C<use locale>, but
313 see L</Which character set modifier is in effect?>.
314 X</l>
315
316 =head4 /u
317
318 means to use Unicode rules when pattern matching.  On ASCII platforms,
319 this means that the code points between 128 and 255 take on their
320 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
321 (Otherwise Perl considers their meanings to be undefined.)  Thus,
322 under this modifier, the ASCII platform effectively becomes a Unicode
323 platform; and hence, for example, C<\w> will match any of the more than
324 100_000 word characters in Unicode.
325
326 Unlike most locales, which are specific to a language and country pair,
327 Unicode classifies all the characters that are letters I<somewhere> in
328 the world as
329 C<\w>.  For example, your locale might not think that C<LATIN SMALL
330 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
331 Unicode does.  Similarly, all the characters that are decimal digits
332 somewhere in the world will match C<\d>; this is hundreds, not 10,
333 possible matches.  And some of those digits look like some of the 10
334 ASCII digits, but mean a different number, so a human could easily think
335 a number is a different quantity than it really is.  For example,
336 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
337 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
338 that are a mixture from different writing systems, creating a security
339 issue.  L<Unicode::UCD/num()> can be used to sort
340 this out.  Or the C</a> modifier can be used to force C<\d> to match
341 just the ASCII 0 through 9.
342
343 Also, under this modifier, case-insensitive matching works on the full
344 set of Unicode
345 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
346 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
347 if you're not prepared, might make it look like a hexadecimal constant,
348 presenting another potential security issue.  See
349 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
350 security issues.
351
352 This modifier may be specified to be the default by C<use feature
353 'unicode_strings>, C<use locale ':not_characters'>, or
354 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
355 but see L</Which character set modifier is in effect?>.
356 X</u>
357
358 =head4 /d
359
360 This modifier means to use the "Default" native rules of the platform
361 except when there is cause to use Unicode rules instead, as follows:
362
363 =over 4
364
365 =item 1
366
367 the target string is encoded in UTF-8; or
368
369 =item 2
370
371 the pattern is encoded in UTF-8; or
372
373 =item 3
374
375 the pattern explicitly mentions a code point that is above 255 (say by
376 C<\x{100}>); or
377
378 =item 4
379
380 the pattern uses a Unicode name (C<\N{...}>);  or
381
382 =item 5
383
384 the pattern uses a Unicode property (C<\p{...}>); or
385
386 =item 6
387
388 the pattern uses L</C<(?[ ])>>
389
390 =back
391
392 Another mnemonic for this modifier is "Depends", as the rules actually
393 used depend on various things, and as a result you can get unexpected
394 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
395 become rather infamous, leading to yet another (printable) name for this
396 modifier, "Dodgy".
397
398 Unless the pattern or string are encoded in UTF-8, only ASCII characters
399 can match positively.
400
401 Here are some examples of how that works on an ASCII platform:
402
403  $str =  "\xDF";      # $str is not in UTF-8 format.
404  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
405  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
406  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
407  chop $str;
408  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
409
410 This modifier is automatically selected by default when none of the
411 others are, so yet another name for it is "Default".
412
413 Because of the unexpected behaviors associated with this modifier, you
414 probably should only use it to maintain weird backward compatibilities.
415
416 =head4 /a (and /aa)
417
418 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
419 unlike the others, may be doubled-up to increase its effect.
420
421 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
422 the Posix character classes to match only in the ASCII range.  They thus
423 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
424 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
425 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, experimentally,
426 the vertical tab; C<\w> means the 63 characters
427 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
428 C<[[:print:]]> match only the appropriate ASCII-range characters.
429
430 This modifier is useful for people who only incidentally use Unicode,
431 and who do not wish to be burdened with its complexities and security
432 concerns.
433
434 With C</a>, one can write C<\d> with confidence that it will only match
435 ASCII characters, and should the need arise to match beyond ASCII, you
436 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
437 similar C<\p{...}> constructs that can match beyond ASCII both white
438 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
439 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
440 doesn't mean you can't use Unicode, it means that to get Unicode
441 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
442 signals Unicode.
443
444 As you would expect, this modifier causes, for example, C<\D> to mean
445 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
446 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
447 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
448 for C<\B>).
449
450 Otherwise, C</a> behaves like the C</u> modifier, in that
451 case-insensitive matching uses Unicode rules; for example, "k" will
452 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
453 points in the Latin1 range, above ASCII will have Unicode rules when it
454 comes to case-insensitive matching.
455
456 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
457 specify the "a" twice, for example C</aai> or C</aia>.  (The first
458 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
459 adds the C</i> restrictions.)  But, note that code points outside the
460 ASCII range will use Unicode rules for C</i> matching, so the modifier
461 doesn't really restrict things to just ASCII; it just forbids the
462 intermixing of ASCII and non-ASCII.
463
464 To summarize, this modifier provides protection for applications that
465 don't wish to be exposed to all of Unicode.  Specifying it twice
466 gives added protection.
467
468 This modifier may be specified to be the default by C<use re '/a'>
469 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
470 the C</u> modifier explicitly if there are a few regular expressions
471 where you do want full Unicode rules (but even here, it's best if
472 everything were under feature C<"unicode_strings">, along with the
473 C<use re '/aa'>).  Also see L</Which character set modifier is in
474 effect?>.
475 X</a>
476 X</aa>
477
478 =head4 Which character set modifier is in effect?
479
480 Which of these modifiers is in effect at any given point in a regular
481 expression depends on a fairly complex set of interactions.  These have
482 been designed so that in general you don't have to worry about it, but
483 this section gives the gory details.  As
484 explained below in L</Extended Patterns> it is possible to explicitly
485 specify modifiers that apply only to portions of a regular expression.
486 The innermost always has priority over any outer ones, and one applying
487 to the whole expression has priority over any of the default settings that are
488 described in the remainder of this section.
489
490 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
491 default modifiers (including these) for regular expressions compiled
492 within its scope.  This pragma has precedence over the other pragmas
493 listed below that also change the defaults.
494
495 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
496 and C<L<use feature 'unicode_strings|feature>>, or
497 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
498 C</u> when not in the same scope as either C<L<use locale|perllocale>>
499 or C<L<use bytes|bytes>>.
500 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
501 sets the default to C</u>, overriding any plain C<use locale>.)
502 Unlike the mechanisms mentioned above, these
503 affect operations besides regular expressions pattern matching, and so
504 give more consistent results with other operators, including using
505 C<\U>, C<\l>, etc. in substitution replacements.
506
507 If none of the above apply, for backwards compatibility reasons, the
508 C</d> modifier is the one in effect by default.  As this can lead to
509 unexpected results, it is best to specify which other rule set should be
510 used.
511
512 =head4 Character set modifier behavior prior to Perl 5.14
513
514 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
515 for regexes compiled within the scope of C<use locale>, and C</d> was
516 implied otherwise.  However, interpolating a regex into a larger regex
517 would ignore the original compilation in favor of whatever was in effect
518 at the time of the second compilation.  There were a number of
519 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
520 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
521 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
522
523 =head2 Regular Expressions
524
525 =head3 Metacharacters
526
527 The patterns used in Perl pattern matching evolved from those supplied in
528 the Version 8 regex routines.  (The routines are derived
529 (distantly) from Henry Spencer's freely redistributable reimplementation
530 of the V8 routines.)  See L<Version 8 Regular Expressions> for
531 details.
532
533 In particular the following metacharacters have their standard I<egrep>-ish
534 meanings:
535 X<metacharacter>
536 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
537
538
539     \        Quote the next metacharacter
540     ^        Match the beginning of the line
541     .        Match any character (except newline)
542     $        Match the end of the string (or before newline at the end
543              of the string)
544     |        Alternation
545     ()       Grouping
546     []       Bracketed Character class
547
548 By default, the "^" character is guaranteed to match only the
549 beginning of the string, the "$" character only the end (or before the
550 newline at the end), and Perl does certain optimizations with the
551 assumption that the string contains only one line.  Embedded newlines
552 will not be matched by "^" or "$".  You may, however, wish to treat a
553 string as a multi-line buffer, such that the "^" will match after any
554 newline within the string (except if the newline is the last character in
555 the string), and "$" will match before any newline.  At the
556 cost of a little more overhead, you can do this by using the /m modifier
557 on the pattern match operator.  (Older programs did this by setting C<$*>,
558 but this option was removed in perl 5.10.)
559 X<^> X<$> X</m>
560
561 To simplify multi-line substitutions, the "." character never matches a
562 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
563 the string is a single line--even if it isn't.
564 X<.> X</s>
565
566 =head3 Quantifiers
567
568 The following standard quantifiers are recognized:
569 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
570
571     *           Match 0 or more times
572     +           Match 1 or more times
573     ?           Match 1 or 0 times
574     {n}         Match exactly n times
575     {n,}        Match at least n times
576     {n,m}       Match at least n but not more than m times
577
578 (If a curly bracket occurs in any other context and does not form part of
579 a backslashed sequence like C<\x{...}>, it is treated as a regular
580 character.  However, a deprecation warning is raised for all such
581 occurrences, and in Perl v5.26, literal uses of a curly bracket will be
582 required to be escaped, say by preceding them with a backslash (C<"\{">)
583 or enclosing them within square brackets  (C<"[{]">).  This change will
584 allow for future syntax extensions (like making the lower bound of a
585 quantifier optional), and better error checking of quantifiers.)
586
587 The "*" quantifier is equivalent to C<{0,}>, the "+"
588 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
589 to non-negative integral values less than a preset limit defined when perl is built.
590 This is usually 32766 on the most common platforms.  The actual limit can
591 be seen in the error message generated by code such as this:
592
593     $_ **= $_ , / {$_} / for 2 .. 42;
594
595 By default, a quantified subpattern is "greedy", that is, it will match as
596 many times as possible (given a particular starting location) while still
597 allowing the rest of the pattern to match.  If you want it to match the
598 minimum number of times possible, follow the quantifier with a "?".  Note
599 that the meanings don't change, just the "greediness":
600 X<metacharacter> X<greedy> X<greediness>
601 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
602
603     *?        Match 0 or more times, not greedily
604     +?        Match 1 or more times, not greedily
605     ??        Match 0 or 1 time, not greedily
606     {n}?      Match exactly n times, not greedily (redundant)
607     {n,}?     Match at least n times, not greedily
608     {n,m}?    Match at least n but not more than m times, not greedily
609
610 Normally when a quantified subpattern does not allow the rest of the
611 overall pattern to match, Perl will backtrack. However, this behaviour is
612 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
613 as well.
614
615  *+     Match 0 or more times and give nothing back
616  ++     Match 1 or more times and give nothing back
617  ?+     Match 0 or 1 time and give nothing back
618  {n}+   Match exactly n times and give nothing back (redundant)
619  {n,}+  Match at least n times and give nothing back
620  {n,m}+ Match at least n but not more than m times and give nothing back
621
622 For instance,
623
624    'aaaa' =~ /a++a/
625
626 will never match, as the C<a++> will gobble up all the C<a>'s in the
627 string and won't leave any for the remaining part of the pattern. This
628 feature can be extremely useful to give perl hints about where it
629 shouldn't backtrack. For instance, the typical "match a double-quoted
630 string" problem can be most efficiently performed when written as:
631
632    /"(?:[^"\\]++|\\.)*+"/
633
634 as we know that if the final quote does not match, backtracking will not
635 help. See the independent subexpression
636 L</C<< (?>pattern) >>> for more details;
637 possessive quantifiers are just syntactic sugar for that construct. For
638 instance the above example could also be written as follows:
639
640    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
641
642 Note that the possessive quantifier modifier can not be be combined
643 with the non-greedy modifier. This is because it would make no sense.
644 Consider the follow equivalency table:
645
646     Illegal         Legal
647     ------------    ------
648     X??+            X{0}
649     X+?+            X{1}
650     X{min,max}?+    X{min}
651
652 =head3 Escape sequences
653
654 Because patterns are processed as double-quoted strings, the following
655 also work:
656
657  \t          tab                   (HT, TAB)
658  \n          newline               (LF, NL)
659  \r          return                (CR)
660  \f          form feed             (FF)
661  \a          alarm (bell)          (BEL)
662  \e          escape (think troff)  (ESC)
663  \cK         control char          (example: VT)
664  \x{}, \x00  character whose ordinal is the given hexadecimal number
665  \N{name}    named Unicode character or character sequence
666  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
667  \o{}, \000  character whose ordinal is the given octal number
668  \l          lowercase next char (think vi)
669  \u          uppercase next char (think vi)
670  \L          lowercase until \E (think vi)
671  \U          uppercase until \E (think vi)
672  \Q          quote (disable) pattern metacharacters until \E
673  \E          end either case modification or quoted section, think vi
674
675 Details are in L<perlop/Quote and Quote-like Operators>.
676
677 =head3 Character Classes and other Special Escapes
678
679 In addition, Perl defines the following:
680 X<\g> X<\k> X<\K> X<backreference>
681
682  Sequence   Note    Description
683   [...]     [1]  Match a character according to the rules of the
684                    bracketed character class defined by the "...".
685                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
686   [[:...:]] [2]  Match a character according to the rules of the POSIX
687                    character class "..." within the outer bracketed
688                    character class.  Example: [[:upper:]] matches any
689                    uppercase character.
690   (?[...])  [8]  Extended bracketed character class
691   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
692                    other connector punctuation chars plus Unicode
693                    marks)
694   \W        [3]  Match a non-"word" character
695   \s        [3]  Match a whitespace character
696   \S        [3]  Match a non-whitespace character
697   \d        [3]  Match a decimal digit character
698   \D        [3]  Match a non-digit character
699   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
700   \PP       [3]  Match non-P
701   \X        [4]  Match Unicode "eXtended grapheme cluster"
702   \C             Match a single C-language char (octet) even if that is
703                    part of a larger UTF-8 character.  Thus it breaks up
704                    characters into their UTF-8 bytes, so you may end up
705                    with malformed pieces of UTF-8.  Unsupported in
706                    lookbehind. (Deprecated.)
707   \1        [5]  Backreference to a specific capture group or buffer.
708                    '1' may actually be any positive integer.
709   \g1       [5]  Backreference to a specific or previous group,
710   \g{-1}    [5]  The number may be negative indicating a relative
711                    previous group and may optionally be wrapped in
712                    curly brackets for safer parsing.
713   \g{name}  [5]  Named backreference
714   \k<name>  [5]  Named backreference
715   \K        [6]  Keep the stuff left of the \K, don't include it in $&
716   \N        [7]  Any character but \n.  Not affected by /s modifier
717   \v        [3]  Vertical whitespace
718   \V        [3]  Not vertical whitespace
719   \h        [3]  Horizontal whitespace
720   \H        [3]  Not horizontal whitespace
721   \R        [4]  Linebreak
722
723 =over 4
724
725 =item [1]
726
727 See L<perlrecharclass/Bracketed Character Classes> for details.
728
729 =item [2]
730
731 See L<perlrecharclass/POSIX Character Classes> for details.
732
733 =item [3]
734
735 See L<perlrecharclass/Backslash sequences> for details.
736
737 =item [4]
738
739 See L<perlrebackslash/Misc> for details.
740
741 =item [5]
742
743 See L</Capture groups> below for details.
744
745 =item [6]
746
747 See L</Extended Patterns> below for details.
748
749 =item [7]
750
751 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
752 character or character sequence whose name is C<NAME>; and similarly
753 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
754 code point is I<hex>.  Otherwise it matches any character but C<\n>.
755
756 =item [8]
757
758 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
759
760 =back
761
762 =head3 Assertions
763
764 Perl defines the following zero-width assertions:
765 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
766 X<regexp, zero-width assertion>
767 X<regular expression, zero-width assertion>
768 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
769
770     \b  Match a word boundary
771     \B  Match except at a word boundary
772     \A  Match only at beginning of string
773     \Z  Match only at end of string, or before newline at the end
774     \z  Match only at end of string
775     \G  Match only at pos() (e.g. at the end-of-match position
776         of prior m//g)
777
778 A word boundary (C<\b>) is a spot between two characters
779 that has a C<\w> on one side of it and a C<\W> on the other side
780 of it (in either order), counting the imaginary characters off the
781 beginning and end of the string as matching a C<\W>.  (Within
782 character classes C<\b> represents backspace rather than a word
783 boundary, just as it normally does in any double-quoted string.)
784 The C<\A> and C<\Z> are just like "^" and "$", except that they
785 won't match multiple times when the C</m> modifier is used, while
786 "^" and "$" will match at every internal line boundary.  To match
787 the actual end of the string and not ignore an optional trailing
788 newline, use C<\z>.
789 X<\b> X<\A> X<\Z> X<\z> X</m>
790
791 The C<\G> assertion can be used to chain global matches (using
792 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
793 It is also useful when writing C<lex>-like scanners, when you have
794 several patterns that you want to match against consequent substrings
795 of your string; see the previous reference.  The actual location
796 where C<\G> will match can also be influenced by using C<pos()> as
797 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
798 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
799 is modified somewhat, in that contents to the left of C<\G> are
800 not counted when determining the length of the match. Thus the following
801 will not match forever:
802 X<\G>
803
804      my $string = 'ABC';
805      pos($string) = 1;
806      while ($string =~ /(.\G)/g) {
807          print $1;
808      }
809
810 It will print 'A' and then terminate, as it considers the match to
811 be zero-width, and thus will not match at the same position twice in a
812 row.
813
814 It is worth noting that C<\G> improperly used can result in an infinite
815 loop. Take care when using patterns that include C<\G> in an alternation.
816
817 Note also that C<s///> will refuse to overwrite part of a substitution
818 that has already been replaced; so for example this will stop after the
819 first iteration, rather than iterating its way backwards through the
820 string:
821
822     $_ = "123456789";
823     pos = 6;
824     s/.(?=.\G)/X/g;
825     print;      # prints 1234X6789, not XXXXX6789
826
827
828 =head3 Capture groups
829
830 The bracketing construct C<( ... )> creates capture groups (also referred to as
831 capture buffers). To refer to the current contents of a group later on, within
832 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
833 for the second, and so on.
834 This is called a I<backreference>.
835 X<regex, capture buffer> X<regexp, capture buffer>
836 X<regex, capture group> X<regexp, capture group>
837 X<regular expression, capture buffer> X<backreference>
838 X<regular expression, capture group> X<backreference>
839 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
840 X<named capture buffer> X<regular expression, named capture buffer>
841 X<named capture group> X<regular expression, named capture group>
842 X<%+> X<$+{name}> X<< \k<name> >>
843 There is no limit to the number of captured substrings that you may use.
844 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
845 a group did not match, the associated backreference won't match either. (This
846 can happen if the group is optional, or in a different branch of an
847 alternation.)
848 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
849 this form, described below.
850
851 You can also refer to capture groups relatively, by using a negative number, so
852 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
853 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
854 example:
855
856         /
857          (Y)            # group 1
858          (              # group 2
859             (X)         # group 3
860             \g{-1}      # backref to group 3
861             \g{-3}      # backref to group 1
862          )
863         /x
864
865 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
866 interpolate regexes into larger regexes and not have to worry about the
867 capture groups being renumbered.
868
869 You can dispense with numbers altogether and create named capture groups.
870 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
871 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
872 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
873 I<name> must not begin with a number, nor contain hyphens.
874 When different groups within the same pattern have the same name, any reference
875 to that name assumes the leftmost defined group.  Named groups count in
876 absolute and relative numbering, and so can also be referred to by those
877 numbers.
878 (It's possible to do things with named capture groups that would otherwise
879 require C<(??{})>.)
880
881 Capture group contents are dynamically scoped and available to you outside the
882 pattern until the end of the enclosing block or until the next successful
883 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
884 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
885 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
886
887 Braces are required in referring to named capture groups, but are optional for
888 absolute or relative numbered ones.  Braces are safer when creating a regex by
889 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
890 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
891 is probably not what you intended.
892
893 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
894 there were no named nor relative numbered capture groups.  Absolute numbered
895 groups were referred to using C<\1>,
896 C<\2>, etc., and this notation is still
897 accepted (and likely always will be).  But it leads to some ambiguities if
898 there are more than 9 capture groups, as C<\10> could mean either the tenth
899 capture group, or the character whose ordinal in octal is 010 (a backspace in
900 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
901 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
902 a backreference only if at least 11 left parentheses have opened before it.
903 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
904 There are several examples below that illustrate these perils.  You can avoid
905 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
906 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
907 digits padded with leading zeros, since a leading zero implies an octal
908 constant.
909
910 The C<\I<digit>> notation also works in certain circumstances outside
911 the pattern.  See L</Warning on \1 Instead of $1> below for details.
912
913 Examples:
914
915     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
916
917     /(.)\g1/                        # find first doubled char
918          and print "'$1' is the first doubled character\n";
919
920     /(?<char>.)\k<char>/            # ... a different way
921          and print "'$+{char}' is the first doubled character\n";
922
923     /(?'char'.)\g1/                 # ... mix and match
924          and print "'$1' is the first doubled character\n";
925
926     if (/Time: (..):(..):(..)/) {   # parse out values
927         $hours = $1;
928         $minutes = $2;
929         $seconds = $3;
930     }
931
932     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
933     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
934     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
935     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
936
937     $a = '(.)\1';        # Creates problems when concatenated.
938     $b = '(.)\g{1}';     # Avoids the problems.
939     "aa" =~ /${a}/;      # True
940     "aa" =~ /${b}/;      # True
941     "aa0" =~ /${a}0/;    # False!
942     "aa0" =~ /${b}0/;    # True
943     "aa\x08" =~ /${a}0/;  # True!
944     "aa\x08" =~ /${b}0/;  # False
945
946 Several special variables also refer back to portions of the previous
947 match.  C<$+> returns whatever the last bracket match matched.
948 C<$&> returns the entire matched string.  (At one point C<$0> did
949 also, but now it returns the name of the program.)  C<$`> returns
950 everything before the matched string.  C<$'> returns everything
951 after the matched string. And C<$^N> contains whatever was matched by
952 the most-recently closed group (submatch). C<$^N> can be used in
953 extended patterns (see below), for example to assign a submatch to a
954 variable.
955 X<$+> X<$^N> X<$&> X<$`> X<$'>
956
957 These special variables, like the C<%+> hash and the numbered match variables
958 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
959 until the end of the enclosing block or until the next successful
960 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
961 X<$+> X<$^N> X<$&> X<$`> X<$'>
962 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
963
964 B<NOTE>: Failed matches in Perl do not reset the match variables,
965 which makes it easier to write code that tests for a series of more
966 specific cases and remembers the best match.
967
968 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
969 beware that once Perl sees that you need one of C<$&>, C<$`>, or
970 C<$'> anywhere in the program, it has to provide them for every
971 pattern match.  This may substantially slow your program.
972
973 Perl uses the same mechanism to produce C<$1>, C<$2>, etc, so you also
974 pay a price for each pattern that contains capturing parentheses.
975 (To avoid this cost while retaining the grouping behaviour, use the
976 extended regular expression C<(?: ... )> instead.)  But if you never
977 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
978 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
979 if you can, but if you can't (and some algorithms really appreciate
980 them), once you've used them once, use them at will, because you've
981 already paid the price.
982 X<$&> X<$`> X<$'>
983
984 Perl 5.16 introduced a slightly more efficient mechanism that notes
985 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
986 thus may only need to copy part of the string.  Perl 5.20 introduced a
987 much more efficient copy-on-write mechanism which eliminates any slowdown.
988
989 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
990 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
991 and C<$'>, B<except> that they are only guaranteed to be defined after a
992 successful match that was executed with the C</p> (preserve) modifier.
993 The use of these variables incurs no global performance penalty, unlike
994 their punctuation char equivalents, however at the trade-off that you
995 have to tell perl when you want to use them.  As of Perl 5.20, these three
996 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
997 X</p> X<p modifier>
998
999 =head2 Quoting metacharacters
1000
1001 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
1002 C<\w>, C<\n>.  Unlike some other regular expression languages, there
1003 are no backslashed symbols that aren't alphanumeric.  So anything
1004 that looks like \\, \(, \), \[, \], \{, or \} is always
1005 interpreted as a literal character, not a metacharacter.  This was
1006 once used in a common idiom to disable or quote the special meanings
1007 of regular expression metacharacters in a string that you want to
1008 use for a pattern. Simply quote all non-"word" characters:
1009
1010     $pattern =~ s/(\W)/\\$1/g;
1011
1012 (If C<use locale> is set, then this depends on the current locale.)
1013 Today it is more common to use the quotemeta() function or the C<\Q>
1014 metaquoting escape sequence to disable all metacharacters' special
1015 meanings like this:
1016
1017     /$unquoted\Q$quoted\E$unquoted/
1018
1019 Beware that if you put literal backslashes (those not inside
1020 interpolated variables) between C<\Q> and C<\E>, double-quotish
1021 backslash interpolation may lead to confusing results.  If you
1022 I<need> to use literal backslashes within C<\Q...\E>,
1023 consult L<perlop/"Gory details of parsing quoted constructs">.
1024
1025 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1026
1027 =head2 Extended Patterns
1028
1029 Perl also defines a consistent extension syntax for features not
1030 found in standard tools like B<awk> and
1031 B<lex>.  The syntax for most of these is a
1032 pair of parentheses with a question mark as the first thing within
1033 the parentheses.  The character after the question mark indicates
1034 the extension.
1035
1036 The stability of these extensions varies widely.  Some have been
1037 part of the core language for many years.  Others are experimental
1038 and may change without warning or be completely removed.  Check
1039 the documentation on an individual feature to verify its current
1040 status.
1041
1042 A question mark was chosen for this and for the minimal-matching
1043 construct because 1) question marks are rare in older regular
1044 expressions, and 2) whenever you see one, you should stop and
1045 "question" exactly what is going on.  That's psychology....
1046
1047 =over 4
1048
1049 =item C<(?#text)>
1050 X<(?#)>
1051
1052 A comment.  The text is ignored.
1053 Note that Perl closes
1054 the comment as soon as it sees a C<)>, so there is no way to put a literal
1055 C<)> in the comment.  The pattern's closing delimiter must be escaped by
1056 a backslash if it appears in the comment.
1057
1058 See L</E<sol>x> for another way to have comments in patterns.
1059
1060 =item C<(?adlupimsx-imsx)>
1061
1062 =item C<(?^alupimsx)>
1063 X<(?)> X<(?^)>
1064
1065 One or more embedded pattern-match modifiers, to be turned on (or
1066 turned off, if preceded by C<->) for the remainder of the pattern or
1067 the remainder of the enclosing pattern group (if any).
1068
1069 This is particularly useful for dynamic patterns, such as those read in from a
1070 configuration file, taken from an argument, or specified in a table
1071 somewhere.  Consider the case where some patterns want to be
1072 case-sensitive and some do not:  The case-insensitive ones merely need to
1073 include C<(?i)> at the front of the pattern.  For example:
1074
1075     $pattern = "foobar";
1076     if ( /$pattern/i ) { }
1077
1078     # more flexible:
1079
1080     $pattern = "(?i)foobar";
1081     if ( /$pattern/ ) { }
1082
1083 These modifiers are restored at the end of the enclosing group. For example,
1084
1085     ( (?i) blah ) \s+ \g1
1086
1087 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1088 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1089 modifier outside this group.
1090
1091 These modifiers do not carry over into named subpatterns called in the
1092 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1093 change the case-sensitivity of the "NAME" pattern.
1094
1095 Any of these modifiers can be set to apply globally to all regular
1096 expressions compiled within the scope of a C<use re>.  See
1097 L<re/"'/flags' mode">.
1098
1099 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1100 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1101 C<"d">) may follow the caret to override it.
1102 But a minus sign is not legal with it.
1103
1104 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1105 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1106 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1107 others, and a maximum of one (or two C<a>'s) may appear in the
1108 construct.  Thus, for
1109 example, C<(?-p)> will warn when compiled under C<use warnings>;
1110 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1111
1112 Note also that the C<p> modifier is special in that its presence
1113 anywhere in a pattern has a global effect.
1114
1115 =item C<(?:pattern)>
1116 X<(?:)>
1117
1118 =item C<(?adluimsx-imsx:pattern)>
1119
1120 =item C<(?^aluimsx:pattern)>
1121 X<(?^:)>
1122
1123 This is for clustering, not capturing; it groups subexpressions like
1124 "()", but doesn't make backreferences as "()" does.  So
1125
1126     @fields = split(/\b(?:a|b|c)\b/)
1127
1128 is like
1129
1130     @fields = split(/\b(a|b|c)\b/)
1131
1132 but doesn't spit out extra fields.  It's also cheaper not to capture
1133 characters if you don't need to.
1134
1135 Any letters between C<?> and C<:> act as flags modifiers as with
1136 C<(?adluimsx-imsx)>.  For example,
1137
1138     /(?s-i:more.*than).*million/i
1139
1140 is equivalent to the more verbose
1141
1142     /(?:(?s-i)more.*than).*million/i
1143
1144 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1145 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1146 flags (except C<"d">) may follow the caret, so
1147
1148     (?^x:foo)
1149
1150 is equivalent to
1151
1152     (?x-ims:foo)
1153
1154 The caret tells Perl that this cluster doesn't inherit the flags of any
1155 surrounding pattern, but uses the system defaults (C<d-imsx>),
1156 modified by any flags specified.
1157
1158 The caret allows for simpler stringification of compiled regular
1159 expressions.  These look like
1160
1161     (?^:pattern)
1162
1163 with any non-default flags appearing between the caret and the colon.
1164 A test that looks at such stringification thus doesn't need to have the
1165 system default flags hard-coded in it, just the caret.  If new flags are
1166 added to Perl, the meaning of the caret's expansion will change to include
1167 the default for those flags, so the test will still work, unchanged.
1168
1169 Specifying a negative flag after the caret is an error, as the flag is
1170 redundant.
1171
1172 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1173 to match at the beginning.
1174
1175 =item C<(?|pattern)>
1176 X<(?|)> X<Branch reset>
1177
1178 This is the "branch reset" pattern, which has the special property
1179 that the capture groups are numbered from the same starting point
1180 in each alternation branch. It is available starting from perl 5.10.0.
1181
1182 Capture groups are numbered from left to right, but inside this
1183 construct the numbering is restarted for each branch.
1184
1185 The numbering within each branch will be as normal, and any groups
1186 following this construct will be numbered as though the construct
1187 contained only one branch, that being the one with the most capture
1188 groups in it.
1189
1190 This construct is useful when you want to capture one of a
1191 number of alternative matches.
1192
1193 Consider the following pattern.  The numbers underneath show in
1194 which group the captured content will be stored.
1195
1196
1197     # before  ---------------branch-reset----------- after        
1198     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1199     # 1            2         2  3        2     3     4  
1200
1201 Be careful when using the branch reset pattern in combination with 
1202 named captures. Named captures are implemented as being aliases to 
1203 numbered groups holding the captures, and that interferes with the
1204 implementation of the branch reset pattern. If you are using named
1205 captures in a branch reset pattern, it's best to use the same names,
1206 in the same order, in each of the alternations:
1207
1208    /(?|  (?<a> x ) (?<b> y )
1209       |  (?<a> z ) (?<b> w )) /x
1210
1211 Not doing so may lead to surprises:
1212
1213   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1214   say $+ {a};   # Prints '12'
1215   say $+ {b};   # *Also* prints '12'.
1216
1217 The problem here is that both the group named C<< a >> and the group
1218 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1219
1220 =item Look-Around Assertions
1221 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1222
1223 Look-around assertions are zero-width patterns which match a specific
1224 pattern without including it in C<$&>. Positive assertions match when
1225 their subpattern matches, negative assertions match when their subpattern
1226 fails. Look-behind matches text up to the current match position,
1227 look-ahead matches text following the current match position.
1228
1229 =over 4
1230
1231 =item C<(?=pattern)>
1232 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1233
1234 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1235 matches a word followed by a tab, without including the tab in C<$&>.
1236
1237 =item C<(?!pattern)>
1238 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1239
1240 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1241 matches any occurrence of "foo" that isn't followed by "bar".  Note
1242 however that look-ahead and look-behind are NOT the same thing.  You cannot
1243 use this for look-behind.
1244
1245 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1246 will not do what you want.  That's because the C<(?!foo)> is just saying that
1247 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1248 match.  Use look-behind instead (see below).
1249
1250 =item C<(?<=pattern)> C<\K>
1251 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1252
1253 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1254 matches a word that follows a tab, without including the tab in C<$&>.
1255 Works only for fixed-width look-behind.
1256
1257 There is a special form of this construct, called C<\K> (available since
1258 Perl 5.10.0), which causes the
1259 regex engine to "keep" everything it had matched prior to the C<\K> and
1260 not include it in C<$&>. This effectively provides variable-length
1261 look-behind. The use of C<\K> inside of another look-around assertion
1262 is allowed, but the behaviour is currently not well defined.
1263
1264 For various reasons C<\K> may be significantly more efficient than the
1265 equivalent C<< (?<=...) >> construct, and it is especially useful in
1266 situations where you want to efficiently remove something following
1267 something else in a string. For instance
1268
1269   s/(foo)bar/$1/g;
1270
1271 can be rewritten as the much more efficient
1272
1273   s/foo\Kbar//g;
1274
1275 =item C<(?<!pattern)>
1276 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1277
1278 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1279 matches any occurrence of "foo" that does not follow "bar".  Works
1280 only for fixed-width look-behind.
1281
1282 =back
1283
1284 =item C<(?'NAME'pattern)>
1285
1286 =item C<< (?<NAME>pattern) >>
1287 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1288
1289 A named capture group. Identical in every respect to normal capturing
1290 parentheses C<()> but for the additional fact that the group
1291 can be referred to by name in various regular expression
1292 constructs (like C<\g{NAME}>) and can be accessed by name
1293 after a successful match via C<%+> or C<%->. See L<perlvar>
1294 for more details on the C<%+> and C<%-> hashes.
1295
1296 If multiple distinct capture groups have the same name then the
1297 $+{NAME} will refer to the leftmost defined group in the match.
1298
1299 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1300
1301 B<NOTE:> While the notation of this construct is the same as the similar
1302 function in .NET regexes, the behavior is not. In Perl the groups are
1303 numbered sequentially regardless of being named or not. Thus in the
1304 pattern
1305
1306   /(x)(?<foo>y)(z)/
1307
1308 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1309 the opposite which is what a .NET regex hacker might expect.
1310
1311 Currently NAME is restricted to simple identifiers only.
1312 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1313 its Unicode extension (see L<utf8>),
1314 though it isn't extended by the locale (see L<perllocale>).
1315
1316 B<NOTE:> In order to make things easier for programmers with experience
1317 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1318 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1319 support the use of single quotes as a delimiter for the name.
1320
1321 =item C<< \k<NAME> >>
1322
1323 =item C<< \k'NAME' >>
1324
1325 Named backreference. Similar to numeric backreferences, except that
1326 the group is designated by name and not number. If multiple groups
1327 have the same name then it refers to the leftmost defined group in
1328 the current match.
1329
1330 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1331 earlier in the pattern.
1332
1333 Both forms are equivalent.
1334
1335 B<NOTE:> In order to make things easier for programmers with experience
1336 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1337 may be used instead of C<< \k<NAME> >>.
1338
1339 =item C<(?{ code })>
1340 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1341
1342 B<WARNING>: Using this feature safely requires that you understand its
1343 limitations.  Code executed that has side effects may not perform identically
1344 from version to version due to the effect of future optimisations in the regex
1345 engine.  For more information on this, see L</Embedded Code Execution
1346 Frequency>.
1347
1348 This zero-width assertion executes any embedded Perl code.  It always
1349 succeeds, and its return value is set as C<$^R>.
1350
1351 In literal patterns, the code is parsed at the same time as the
1352 surrounding code. While within the pattern, control is passed temporarily
1353 back to the perl parser, until the logically-balancing closing brace is
1354 encountered. This is similar to the way that an array index expression in
1355 a literal string is handled, for example
1356
1357     "abc$array[ 1 + f('[') + g()]def"
1358
1359 In particular, braces do not need to be balanced:
1360
1361     s/abc(?{ f('{'); })/def/
1362
1363 Even in a pattern that is interpolated and compiled at run-time, literal
1364 code blocks will be compiled once, at perl compile time; the following
1365 prints "ABCD":
1366
1367     print "D";
1368     my $qr = qr/(?{ BEGIN { print "A" } })/;
1369     my $foo = "foo";
1370     /$foo$qr(?{ BEGIN { print "B" } })/;
1371     BEGIN { print "C" }
1372
1373 In patterns where the text of the code is derived from run-time
1374 information rather than appearing literally in a source code /pattern/,
1375 the code is compiled at the same time that the pattern is compiled, and
1376 for reasons of security, C<use re 'eval'> must be in scope. This is to
1377 stop user-supplied patterns containing code snippets from being
1378 executable.
1379
1380 In situations where you need to enable this with C<use re 'eval'>, you should
1381 also have taint checking enabled.  Better yet, use the carefully
1382 constrained evaluation within a Safe compartment.  See L<perlsec> for
1383 details about both these mechanisms.
1384
1385 From the viewpoint of parsing, lexical variable scope and closures,
1386
1387     /AAA(?{ BBB })CCC/
1388
1389 behaves approximately like
1390
1391     /AAA/ && do { BBB } && /CCC/
1392
1393 Similarly,
1394
1395     qr/AAA(?{ BBB })CCC/
1396
1397 behaves approximately like
1398
1399     sub { /AAA/ && do { BBB } && /CCC/ }
1400
1401 In particular:
1402
1403     { my $i = 1; $r = qr/(?{ print $i })/ }
1404     my $i = 2;
1405     /$r/; # prints "1"
1406
1407 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1408 expression is matching against. You can also use C<pos()> to know what is
1409 the current position of matching within this string.
1410
1411 The code block introduces a new scope from the perspective of lexical
1412 variable declarations, but B<not> from the perspective of C<local> and
1413 similar localizing behaviours. So later code blocks within the same
1414 pattern will still see the values which were localized in earlier blocks.
1415 These accumulated localizations are undone either at the end of a
1416 successful match, or if the assertion is backtracked (compare
1417 L<"Backtracking">). For example,
1418
1419   $_ = 'a' x 8;
1420   m<
1421      (?{ $cnt = 0 })               # Initialize $cnt.
1422      (
1423        a
1424        (?{
1425            local $cnt = $cnt + 1;  # Update $cnt,
1426                                    # backtracking-safe.
1427        })
1428      )*
1429      aaaa
1430      (?{ $res = $cnt })            # On success copy to
1431                                    # non-localized location.
1432    >x;
1433
1434 will initially increment C<$cnt> up to 8; then during backtracking, its
1435 value will be unwound back to 4, which is the value assigned to C<$res>.
1436 At the end of the regex execution, $cnt will be wound back to its initial
1437 value of 0.
1438
1439 This assertion may be used as the condition in a
1440
1441     (?(condition)yes-pattern|no-pattern)
1442
1443 switch.  If I<not> used in this way, the result of evaluation of C<code>
1444 is put into the special variable C<$^R>.  This happens immediately, so
1445 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1446 regular expression.
1447
1448 The assignment to C<$^R> above is properly localized, so the old
1449 value of C<$^R> is restored if the assertion is backtracked; compare
1450 L<"Backtracking">.
1451
1452 Note that the special variable C<$^N>  is particularly useful with code
1453 blocks to capture the results of submatches in variables without having to
1454 keep track of the number of nested parentheses. For example:
1455
1456   $_ = "The brown fox jumps over the lazy dog";
1457   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1458   print "color = $color, animal = $animal\n";
1459
1460
1461 =item C<(??{ code })>
1462 X<(??{})>
1463 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1464
1465 B<WARNING>: Using this feature safely requires that you understand its
1466 limitations.  Code executed that has side effects may not perform
1467 identically from version to version due to the effect of future
1468 optimisations in the regex engine.  For more information on this, see
1469 L</Embedded Code Execution Frequency>.
1470
1471 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1472 same way as a C<(?{ code })> code block as described above, except that
1473 its return value, rather than being assigned to C<$^R>, is treated as a
1474 pattern, compiled if it's a string (or used as-is if its a qr// object),
1475 then matched as if it were inserted instead of this construct.
1476
1477 During the matching of this sub-pattern, it has its own set of
1478 captures which are valid during the sub-match, but are discarded once
1479 control returns to the main pattern. For example, the following matches,
1480 with the inner pattern capturing "B" and matching "BB", while the outer
1481 pattern captures "A";
1482
1483     my $inner = '(.)\1';
1484     "ABBA" =~ /^(.)(??{ $inner })\1/;
1485     print $1; # prints "A";
1486
1487 Note that this means that  there is no way for the inner pattern to refer
1488 to a capture group defined outside.  (The code block itself can use C<$1>,
1489 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1490
1491     ('a' x 100)=~/(??{'(.)' x 100})/
1492
1493 I<will> match, it will I<not> set $1 on exit.
1494
1495 The following pattern matches a parenthesized group:
1496
1497  $re = qr{
1498             \(
1499             (?:
1500                (?> [^()]+ )  # Non-parens without backtracking
1501              |
1502                (??{ $re })   # Group with matching parens
1503             )*
1504             \)
1505          }x;
1506
1507 See also
1508 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1509 for a different, more efficient way to accomplish
1510 the same task.
1511
1512 Executing a postponed regular expression 50 times without consuming any
1513 input string will result in a fatal error.  The maximum depth is compiled
1514 into perl, so changing it requires a custom build.
1515
1516 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1517 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1518 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1519 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1520
1521 Recursive subpattern. Treat the contents of a given capture buffer in the
1522 current pattern as an independent subpattern and attempt to match it at
1523 the current position in the string. Information about capture state from
1524 the caller for things like backreferences is available to the subpattern,
1525 but capture buffers set by the subpattern are not visible to the caller.
1526
1527 Similar to C<(??{ code })> except that it does not involve executing any
1528 code or potentially compiling a returned pattern string; instead it treats
1529 the part of the current pattern contained within a specified capture group
1530 as an independent pattern that must match at the current position. Also
1531 different is the treatment of capture buffers, unlike C<(??{ code })>
1532 recursive patterns have access to their callers match state, so one can
1533 use backreferences safely.
1534
1535 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1536 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1537 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1538 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1539 to be relative, with negative numbers indicating preceding capture groups
1540 and positive ones following. Thus C<(?-1)> refers to the most recently
1541 declared group, and C<(?+1)> indicates the next group to be declared.
1542 Note that the counting for relative recursion differs from that of
1543 relative backreferences, in that with recursion unclosed groups B<are>
1544 included.
1545
1546 The following pattern matches a function foo() which may contain
1547 balanced parentheses as the argument.
1548
1549   $re = qr{ (                   # paren group 1 (full function)
1550               foo
1551               (                 # paren group 2 (parens)
1552                 \(
1553                   (             # paren group 3 (contents of parens)
1554                   (?:
1555                    (?> [^()]+ ) # Non-parens without backtracking
1556                   |
1557                    (?2)         # Recurse to start of paren group 2
1558                   )*
1559                   )
1560                 \)
1561               )
1562             )
1563           }x;
1564
1565 If the pattern was used as follows
1566
1567     'foo(bar(baz)+baz(bop))'=~/$re/
1568         and print "\$1 = $1\n",
1569                   "\$2 = $2\n",
1570                   "\$3 = $3\n";
1571
1572 the output produced should be the following:
1573
1574     $1 = foo(bar(baz)+baz(bop))
1575     $2 = (bar(baz)+baz(bop))
1576     $3 = bar(baz)+baz(bop)
1577
1578 If there is no corresponding capture group defined, then it is a
1579 fatal error.  Recursing deeper than 50 times without consuming any input
1580 string will also result in a fatal error.  The maximum depth is compiled
1581 into perl, so changing it requires a custom build.
1582
1583 The following shows how using negative indexing can make it
1584 easier to embed recursive patterns inside of a C<qr//> construct
1585 for later use:
1586
1587     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1588     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1589        # do something here...
1590     }
1591
1592 B<Note> that this pattern does not behave the same way as the equivalent
1593 PCRE or Python construct of the same form. In Perl you can backtrack into
1594 a recursed group, in PCRE and Python the recursed into group is treated
1595 as atomic. Also, modifiers are resolved at compile time, so constructs
1596 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1597 be processed.
1598
1599 =item C<(?&NAME)>
1600 X<(?&NAME)>
1601
1602 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1603 parenthesis to recurse to is determined by name. If multiple parentheses have
1604 the same name, then it recurses to the leftmost.
1605
1606 It is an error to refer to a name that is not declared somewhere in the
1607 pattern.
1608
1609 B<NOTE:> In order to make things easier for programmers with experience
1610 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1611 may be used instead of C<< (?&NAME) >>.
1612
1613 =item C<(?(condition)yes-pattern|no-pattern)>
1614 X<(?()>
1615
1616 =item C<(?(condition)yes-pattern)>
1617
1618 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1619 a true value, matches C<no-pattern> otherwise. A missing pattern always
1620 matches.
1621
1622 C<(condition)> should be one of: 1) an integer in
1623 parentheses (which is valid if the corresponding pair of parentheses
1624 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1625 name in angle brackets or single quotes (which is valid if a group
1626 with the given name matched); or 4) the special symbol (R) (true when
1627 evaluated inside of recursion or eval). Additionally the R may be
1628 followed by a number, (which will be true when evaluated when recursing
1629 inside of the appropriate group), or by C<&NAME>, in which case it will
1630 be true only when evaluated during recursion in the named group.
1631
1632 Here's a summary of the possible predicates:
1633
1634 =over 4
1635
1636 =item (1) (2) ...
1637
1638 Checks if the numbered capturing group has matched something.
1639
1640 =item (<NAME>) ('NAME')
1641
1642 Checks if a group with the given name has matched something.
1643
1644 =item (?=...) (?!...) (?<=...) (?<!...)
1645
1646 Checks whether the pattern matches (or does not match, for the '!'
1647 variants).
1648
1649 =item (?{ CODE })
1650
1651 Treats the return value of the code block as the condition.
1652
1653 =item (R)
1654
1655 Checks if the expression has been evaluated inside of recursion.
1656
1657 =item (R1) (R2) ...
1658
1659 Checks if the expression has been evaluated while executing directly
1660 inside of the n-th capture group. This check is the regex equivalent of
1661
1662   if ((caller(0))[3] eq 'subname') { ... }
1663
1664 In other words, it does not check the full recursion stack.
1665
1666 =item (R&NAME)
1667
1668 Similar to C<(R1)>, this predicate checks to see if we're executing
1669 directly inside of the leftmost group with a given name (this is the same
1670 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1671 stack, but only the name of the innermost active recursion.
1672
1673 =item (DEFINE)
1674
1675 In this case, the yes-pattern is never directly executed, and no
1676 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1677 See below for details.
1678
1679 =back
1680
1681 For example:
1682
1683     m{ ( \( )?
1684        [^()]+
1685        (?(1) \) )
1686      }x
1687
1688 matches a chunk of non-parentheses, possibly included in parentheses
1689 themselves.
1690
1691 A special form is the C<(DEFINE)> predicate, which never executes its
1692 yes-pattern directly, and does not allow a no-pattern. This allows one to
1693 define subpatterns which will be executed only by the recursion mechanism.
1694 This way, you can define a set of regular expression rules that can be
1695 bundled into any pattern you choose.
1696
1697 It is recommended that for this usage you put the DEFINE block at the
1698 end of the pattern, and that you name any subpatterns defined within it.
1699
1700 Also, it's worth noting that patterns defined this way probably will
1701 not be as efficient, as the optimizer is not very clever about
1702 handling them.
1703
1704 An example of how this might be used is as follows:
1705
1706   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1707    (?(DEFINE)
1708      (?<NAME_PAT>....)
1709      (?<ADDRESS_PAT>....)
1710    )/x
1711
1712 Note that capture groups matched inside of recursion are not accessible
1713 after the recursion returns, so the extra layer of capturing groups is
1714 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1715 C<$+{NAME}> would be.
1716
1717 Finally, keep in mind that subpatterns created inside a DEFINE block
1718 count towards the absolute and relative number of captures, so this:
1719
1720     my @captures = "a" =~ /(.)                  # First capture
1721                            (?(DEFINE)
1722                                (?<EXAMPLE> 1 )  # Second capture
1723                            )/x;
1724     say scalar @captures;
1725
1726 Will output 2, not 1. This is particularly important if you intend to
1727 compile the definitions with the C<qr//> operator, and later
1728 interpolate them in another pattern.
1729
1730 =item C<< (?>pattern) >>
1731 X<backtrack> X<backtracking> X<atomic> X<possessive>
1732
1733 An "independent" subexpression, one which matches the substring
1734 that a I<standalone> C<pattern> would match if anchored at the given
1735 position, and it matches I<nothing other than this substring>.  This
1736 construct is useful for optimizations of what would otherwise be
1737 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1738 It may also be useful in places where the "grab all you can, and do not
1739 give anything back" semantic is desirable.
1740
1741 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1742 (anchored at the beginning of string, as above) will match I<all>
1743 characters C<a> at the beginning of string, leaving no C<a> for
1744 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1745 since the match of the subgroup C<a*> is influenced by the following
1746 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1747 C<a*ab> will match fewer characters than a standalone C<a*>, since
1748 this makes the tail match.
1749
1750 C<< (?>pattern) >> does not disable backtracking altogether once it has
1751 matched. It is still possible to backtrack past the construct, but not
1752 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1753
1754 An effect similar to C<< (?>pattern) >> may be achieved by writing
1755 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1756 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1757 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1758 (The difference between these two constructs is that the second one
1759 uses a capturing group, thus shifting ordinals of backreferences
1760 in the rest of a regular expression.)
1761
1762 Consider this pattern:
1763
1764     m{ \(
1765           (
1766             [^()]+           # x+
1767           |
1768             \( [^()]* \)
1769           )+
1770        \)
1771      }x
1772
1773 That will efficiently match a nonempty group with matching parentheses
1774 two levels deep or less.  However, if there is no such group, it
1775 will take virtually forever on a long string.  That's because there
1776 are so many different ways to split a long string into several
1777 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1778 to a subpattern of the above pattern.  Consider how the pattern
1779 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1780 seconds, but that each extra letter doubles this time.  This
1781 exponential performance will make it appear that your program has
1782 hung.  However, a tiny change to this pattern
1783
1784     m{ \(
1785           (
1786             (?> [^()]+ )        # change x+ above to (?> x+ )
1787           |
1788             \( [^()]* \)
1789           )+
1790        \)
1791      }x
1792
1793 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1794 this yourself would be a productive exercise), but finishes in a fourth
1795 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1796 however, that, when this construct is followed by a
1797 quantifier, it currently triggers a warning message under
1798 the C<use warnings> pragma or B<-w> switch saying it
1799 C<"matches null string many times in regex">.
1800
1801 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1802 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1803 This was only 4 times slower on a string with 1000000 C<a>s.
1804
1805 The "grab all you can, and do not give anything back" semantic is desirable
1806 in many situations where on the first sight a simple C<()*> looks like
1807 the correct solution.  Suppose we parse text with comments being delimited
1808 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1809 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1810 the comment delimiter, because it may "give up" some whitespace if
1811 the remainder of the pattern can be made to match that way.  The correct
1812 answer is either one of these:
1813
1814     (?>#[ \t]*)
1815     #[ \t]*(?![ \t])
1816
1817 For example, to grab non-empty comments into $1, one should use either
1818 one of these:
1819
1820     / (?> \# [ \t]* ) (        .+ ) /x;
1821     /     \# [ \t]*   ( [^ \t] .* ) /x;
1822
1823 Which one you pick depends on which of these expressions better reflects
1824 the above specification of comments.
1825
1826 In some literature this construct is called "atomic matching" or
1827 "possessive matching".
1828
1829 Possessive quantifiers are equivalent to putting the item they are applied
1830 to inside of one of these constructs. The following equivalences apply:
1831
1832     Quantifier Form     Bracketing Form
1833     ---------------     ---------------
1834     PAT*+               (?>PAT*)
1835     PAT++               (?>PAT+)
1836     PAT?+               (?>PAT?)
1837     PAT{min,max}+       (?>PAT{min,max})
1838
1839 =item C<(?[ ])>
1840
1841 See L<perlrecharclass/Extended Bracketed Character Classes>.
1842
1843 =back
1844
1845 =head2 Special Backtracking Control Verbs
1846
1847 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1848 otherwise stated the ARG argument is optional; in some cases, it is
1849 forbidden.
1850
1851 Any pattern containing a special backtracking verb that allows an argument
1852 has the special behaviour that when executed it sets the current package's
1853 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1854 rules apply:
1855
1856 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1857 verb pattern, if the verb was involved in the failure of the match. If the
1858 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1859 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1860 none. Also, the C<$REGMARK> variable will be set to FALSE.
1861
1862 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1863 the C<$REGMARK> variable will be set to the name of the last
1864 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1865 C<(*MARK:NAME)> verb below for more details.
1866
1867 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1868 and most other regex-related variables. They are not local to a scope, nor
1869 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1870 Use C<local> to localize changes to them to a specific scope if necessary.
1871
1872 If a pattern does not contain a special backtracking verb that allows an
1873 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1874
1875 =over 3
1876
1877 =item Verbs that take an argument
1878
1879 =over 4
1880
1881 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1882 X<(*PRUNE)> X<(*PRUNE:NAME)>
1883
1884 This zero-width pattern prunes the backtracking tree at the current point
1885 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1886 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1887 A may backtrack as necessary to match. Once it is reached, matching
1888 continues in B, which may also backtrack as necessary; however, should B
1889 not match, then no further backtracking will take place, and the pattern
1890 will fail outright at the current starting position.
1891
1892 The following example counts all the possible matching strings in a
1893 pattern (without actually matching any of them).
1894
1895     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1896     print "Count=$count\n";
1897
1898 which produces:
1899
1900     aaab
1901     aaa
1902     aa
1903     a
1904     aab
1905     aa
1906     a
1907     ab
1908     a
1909     Count=9
1910
1911 If we add a C<(*PRUNE)> before the count like the following
1912
1913     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1914     print "Count=$count\n";
1915
1916 we prevent backtracking and find the count of the longest matching string
1917 at each matching starting point like so:
1918
1919     aaab
1920     aab
1921     ab
1922     Count=3
1923
1924 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1925
1926 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1927 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1928 replaced with a C<< (?>pattern) >> with no functional difference; however,
1929 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1930 C<< (?>pattern) >> alone.
1931
1932 =item C<(*SKIP)> C<(*SKIP:NAME)>
1933 X<(*SKIP)>
1934
1935 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1936 failure it also signifies that whatever text that was matched leading up
1937 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1938 of this pattern. This effectively means that the regex engine "skips" forward
1939 to this position on failure and tries to match again, (assuming that
1940 there is sufficient room to match).
1941
1942 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1943 C<(*MARK:NAME)> was encountered while matching, then it is that position
1944 which is used as the "skip point". If no C<(*MARK)> of that name was
1945 encountered, then the C<(*SKIP)> operator has no effect. When used
1946 without a name the "skip point" is where the match point was when
1947 executing the (*SKIP) pattern.
1948
1949 Compare the following to the examples in C<(*PRUNE)>; note the string
1950 is twice as long:
1951
1952  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1953  print "Count=$count\n";
1954
1955 outputs
1956
1957     aaab
1958     aaab
1959     Count=2
1960
1961 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1962 executed, the next starting point will be where the cursor was when the
1963 C<(*SKIP)> was executed.
1964
1965 =item C<(*MARK:NAME)> C<(*:NAME)>
1966 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1967
1968 This zero-width pattern can be used to mark the point reached in a string
1969 when a certain part of the pattern has been successfully matched. This
1970 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1971 forward to that point if backtracked into on failure. Any number of
1972 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1973
1974 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1975 can be used to "label" a pattern branch, so that after matching, the
1976 program can determine which branches of the pattern were involved in the
1977 match.
1978
1979 When a match is successful, the C<$REGMARK> variable will be set to the
1980 name of the most recently executed C<(*MARK:NAME)> that was involved
1981 in the match.
1982
1983 This can be used to determine which branch of a pattern was matched
1984 without using a separate capture group for each branch, which in turn
1985 can result in a performance improvement, as perl cannot optimize
1986 C</(?:(x)|(y)|(z))/> as efficiently as something like
1987 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1988
1989 When a match has failed, and unless another verb has been involved in
1990 failing the match and has provided its own name to use, the C<$REGERROR>
1991 variable will be set to the name of the most recently executed
1992 C<(*MARK:NAME)>.
1993
1994 See L</(*SKIP)> for more details.
1995
1996 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1997
1998 =item C<(*THEN)> C<(*THEN:NAME)>
1999
2000 This is similar to the "cut group" operator C<::> from Perl 6.  Like
2001 C<(*PRUNE)>, this verb always matches, and when backtracked into on
2002 failure, it causes the regex engine to try the next alternation in the
2003 innermost enclosing group (capturing or otherwise) that has alternations.
2004 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
2005 count as an alternation, as far as C<(*THEN)> is concerned.
2006
2007 Its name comes from the observation that this operation combined with the
2008 alternation operator (C<|>) can be used to create what is essentially a
2009 pattern-based if/then/else block:
2010
2011   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2012
2013 Note that if this operator is used and NOT inside of an alternation then
2014 it acts exactly like the C<(*PRUNE)> operator.
2015
2016   / A (*PRUNE) B /
2017
2018 is the same as
2019
2020   / A (*THEN) B /
2021
2022 but
2023
2024   / ( A (*THEN) B | C ) /
2025
2026 is not the same as
2027
2028   / ( A (*PRUNE) B | C ) /
2029
2030 as after matching the A but failing on the B the C<(*THEN)> verb will
2031 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
2032
2033 =back
2034
2035 =item Verbs without an argument
2036
2037 =over 4
2038
2039 =item C<(*COMMIT)>
2040 X<(*COMMIT)>
2041
2042 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2043 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2044 into on failure it causes the match to fail outright. No further attempts
2045 to find a valid match by advancing the start pointer will occur again.
2046 For example,
2047
2048  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2049  print "Count=$count\n";
2050
2051 outputs
2052
2053     aaab
2054     Count=1
2055
2056 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2057 does not match, the regex engine will not try any further matching on the
2058 rest of the string.
2059
2060 =item C<(*FAIL)> C<(*F)>
2061 X<(*FAIL)> X<(*F)>
2062
2063 This pattern matches nothing and always fails. It can be used to force the
2064 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2065 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
2066
2067 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2068
2069 =item C<(*ACCEPT)>
2070 X<(*ACCEPT)>
2071
2072 This pattern matches nothing and causes the end of successful matching at
2073 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2074 whether there is actually more to match in the string. When inside of a
2075 nested pattern, such as recursion, or in a subpattern dynamically generated
2076 via C<(??{})>, only the innermost pattern is ended immediately.
2077
2078 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2079 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2080 For instance:
2081
2082   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2083
2084 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
2085 be set. If another branch in the inner parentheses was matched, such as in the
2086 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
2087
2088 =back
2089
2090 =back
2091
2092 =head2 Backtracking
2093 X<backtrack> X<backtracking>
2094
2095 NOTE: This section presents an abstract approximation of regular
2096 expression behavior.  For a more rigorous (and complicated) view of
2097 the rules involved in selecting a match among possible alternatives,
2098 see L<Combining RE Pieces>.
2099
2100 A fundamental feature of regular expression matching involves the
2101 notion called I<backtracking>, which is currently used (when needed)
2102 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2103 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2104 internally, but the general principle outlined here is valid.
2105
2106 For a regular expression to match, the I<entire> regular expression must
2107 match, not just part of it.  So if the beginning of a pattern containing a
2108 quantifier succeeds in a way that causes later parts in the pattern to
2109 fail, the matching engine backs up and recalculates the beginning
2110 part--that's why it's called backtracking.
2111
2112 Here is an example of backtracking:  Let's say you want to find the
2113 word following "foo" in the string "Food is on the foo table.":
2114
2115     $_ = "Food is on the foo table.";
2116     if ( /\b(foo)\s+(\w+)/i ) {
2117         print "$2 follows $1.\n";
2118     }
2119
2120 When the match runs, the first part of the regular expression (C<\b(foo)>)
2121 finds a possible match right at the beginning of the string, and loads up
2122 $1 with "Foo".  However, as soon as the matching engine sees that there's
2123 no whitespace following the "Foo" that it had saved in $1, it realizes its
2124 mistake and starts over again one character after where it had the
2125 tentative match.  This time it goes all the way until the next occurrence
2126 of "foo". The complete regular expression matches this time, and you get
2127 the expected output of "table follows foo."
2128
2129 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2130 everything between "foo" and "bar".  Initially, you write something
2131 like this:
2132
2133     $_ =  "The food is under the bar in the barn.";
2134     if ( /foo(.*)bar/ ) {
2135         print "got <$1>\n";
2136     }
2137
2138 Which perhaps unexpectedly yields:
2139
2140   got <d is under the bar in the >
2141
2142 That's because C<.*> was greedy, so you get everything between the
2143 I<first> "foo" and the I<last> "bar".  Here it's more effective
2144 to use minimal matching to make sure you get the text between a "foo"
2145 and the first "bar" thereafter.
2146
2147     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2148   got <d is under the >
2149
2150 Here's another example. Let's say you'd like to match a number at the end
2151 of a string, and you also want to keep the preceding part of the match.
2152 So you write this:
2153
2154     $_ = "I have 2 numbers: 53147";
2155     if ( /(.*)(\d*)/ ) {                                # Wrong!
2156         print "Beginning is <$1>, number is <$2>.\n";
2157     }
2158
2159 That won't work at all, because C<.*> was greedy and gobbled up the
2160 whole string. As C<\d*> can match on an empty string the complete
2161 regular expression matched successfully.
2162
2163     Beginning is <I have 2 numbers: 53147>, number is <>.
2164
2165 Here are some variants, most of which don't work:
2166
2167     $_ = "I have 2 numbers: 53147";
2168     @pats = qw{
2169         (.*)(\d*)
2170         (.*)(\d+)
2171         (.*?)(\d*)
2172         (.*?)(\d+)
2173         (.*)(\d+)$
2174         (.*?)(\d+)$
2175         (.*)\b(\d+)$
2176         (.*\D)(\d+)$
2177     };
2178
2179     for $pat (@pats) {
2180         printf "%-12s ", $pat;
2181         if ( /$pat/ ) {
2182             print "<$1> <$2>\n";
2183         } else {
2184             print "FAIL\n";
2185         }
2186     }
2187
2188 That will print out:
2189
2190     (.*)(\d*)    <I have 2 numbers: 53147> <>
2191     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2192     (.*?)(\d*)   <> <>
2193     (.*?)(\d+)   <I have > <2>
2194     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2195     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2196     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2197     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2198
2199 As you see, this can be a bit tricky.  It's important to realize that a
2200 regular expression is merely a set of assertions that gives a definition
2201 of success.  There may be 0, 1, or several different ways that the
2202 definition might succeed against a particular string.  And if there are
2203 multiple ways it might succeed, you need to understand backtracking to
2204 know which variety of success you will achieve.
2205
2206 When using look-ahead assertions and negations, this can all get even
2207 trickier.  Imagine you'd like to find a sequence of non-digits not
2208 followed by "123".  You might try to write that as
2209
2210     $_ = "ABC123";
2211     if ( /^\D*(?!123)/ ) {                # Wrong!
2212         print "Yup, no 123 in $_\n";
2213     }
2214
2215 But that isn't going to match; at least, not the way you're hoping.  It
2216 claims that there is no 123 in the string.  Here's a clearer picture of
2217 why that pattern matches, contrary to popular expectations:
2218
2219     $x = 'ABC123';
2220     $y = 'ABC445';
2221
2222     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2223     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2224
2225     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2226     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2227
2228 This prints
2229
2230     2: got ABC
2231     3: got AB
2232     4: got ABC
2233
2234 You might have expected test 3 to fail because it seems to a more
2235 general purpose version of test 1.  The important difference between
2236 them is that test 3 contains a quantifier (C<\D*>) and so can use
2237 backtracking, whereas test 1 will not.  What's happening is
2238 that you've asked "Is it true that at the start of $x, following 0 or more
2239 non-digits, you have something that's not 123?"  If the pattern matcher had
2240 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2241 fail.
2242
2243 The search engine will initially match C<\D*> with "ABC".  Then it will
2244 try to match C<(?!123)> with "123", which fails.  But because
2245 a quantifier (C<\D*>) has been used in the regular expression, the
2246 search engine can backtrack and retry the match differently
2247 in the hope of matching the complete regular expression.
2248
2249 The pattern really, I<really> wants to succeed, so it uses the
2250 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2251 time.  Now there's indeed something following "AB" that is not
2252 "123".  It's "C123", which suffices.
2253
2254 We can deal with this by using both an assertion and a negation.
2255 We'll say that the first part in $1 must be followed both by a digit
2256 and by something that's not "123".  Remember that the look-aheads
2257 are zero-width expressions--they only look, but don't consume any
2258 of the string in their match.  So rewriting this way produces what
2259 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2260
2261     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2262     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2263
2264     6: got ABC
2265
2266 In other words, the two zero-width assertions next to each other work as though
2267 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2268 matches only if you're at the beginning of the line AND the end of the
2269 line simultaneously.  The deeper underlying truth is that juxtaposition in
2270 regular expressions always means AND, except when you write an explicit OR
2271 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2272 although the attempted matches are made at different positions because "a"
2273 is not a zero-width assertion, but a one-width assertion.
2274
2275 B<WARNING>: Particularly complicated regular expressions can take
2276 exponential time to solve because of the immense number of possible
2277 ways they can use backtracking to try for a match.  For example, without
2278 internal optimizations done by the regular expression engine, this will
2279 take a painfully long time to run:
2280
2281     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2282
2283 And if you used C<*>'s in the internal groups instead of limiting them
2284 to 0 through 5 matches, then it would take forever--or until you ran
2285 out of stack space.  Moreover, these internal optimizations are not
2286 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2287 on the external group, no current optimization is applicable, and the
2288 match takes a long time to finish.
2289
2290 A powerful tool for optimizing such beasts is what is known as an
2291 "independent group",
2292 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2293 zero-length look-ahead/look-behind assertions will not backtrack to make
2294 the tail match, since they are in "logical" context: only
2295 whether they match is considered relevant.  For an example
2296 where side-effects of look-ahead I<might> have influenced the
2297 following match, see L</C<< (?>pattern) >>>.
2298
2299 =head2 Version 8 Regular Expressions
2300 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2301
2302 In case you're not familiar with the "regular" Version 8 regex
2303 routines, here are the pattern-matching rules not described above.
2304
2305 Any single character matches itself, unless it is a I<metacharacter>
2306 with a special meaning described here or above.  You can cause
2307 characters that normally function as metacharacters to be interpreted
2308 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2309 character; "\\" matches a "\"). This escape mechanism is also required
2310 for the character used as the pattern delimiter.
2311
2312 A series of characters matches that series of characters in the target
2313 string, so the pattern C<blurfl> would match "blurfl" in the target
2314 string.
2315
2316 You can specify a character class, by enclosing a list of characters
2317 in C<[]>, which will match any character from the list.  If the
2318 first character after the "[" is "^", the class matches any character not
2319 in the list.  Within a list, the "-" character specifies a
2320 range, so that C<a-z> represents all characters between "a" and "z",
2321 inclusive.  If you want either "-" or "]" itself to be a member of a
2322 class, put it at the start of the list (possibly after a "^"), or
2323 escape it with a backslash.  "-" is also taken literally when it is
2324 at the end of the list, just before the closing "]".  (The
2325 following all specify the same class of three characters: C<[-az]>,
2326 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2327 specifies a class containing twenty-six characters, even on EBCDIC-based
2328 character sets.)  Also, if you try to use the character
2329 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2330 a range, the "-" is understood literally.
2331
2332 Note also that the whole range idea is rather unportable between
2333 character sets--and even within character sets they may cause results
2334 you probably didn't expect.  A sound principle is to use only ranges
2335 that begin from and end at either alphabetics of equal case ([a-e],
2336 [A-E]), or digits ([0-9]).  Anything else is unsafe or unclear.  If in
2337 doubt, spell out the character sets in full.  Specifying the end points
2338 of the range using the C<\N{...}> syntax, using Unicode names or code
2339 points makes the range portable, but still likely not easily
2340 understandable to someone reading the code.  For example,
2341 C<[\N{U+04}-\N{U+07}]> means to match the Unicode code points
2342 C<\N{U+04}>, C<\N{U+05}>, C<\N{U+06}>, and C<\N{U+07}>, whatever their
2343 native values may be on the platform.
2344
2345 Characters may be specified using a metacharacter syntax much like that
2346 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2347 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2348 of three octal digits, matches the character whose coded character set value
2349 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2350 matches the character whose ordinal is I<nn>. The expression \cI<x>
2351 matches the character control-I<x>.  Finally, the "." metacharacter
2352 matches any character except "\n" (unless you use C</s>).
2353
2354 You can specify a series of alternatives for a pattern using "|" to
2355 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2356 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2357 first alternative includes everything from the last pattern delimiter
2358 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2359 the last alternative contains everything from the last "|" to the next
2360 closing pattern delimiter.  That's why it's common practice to include
2361 alternatives in parentheses: to minimize confusion about where they
2362 start and end.
2363
2364 Alternatives are tried from left to right, so the first
2365 alternative found for which the entire expression matches, is the one that
2366 is chosen. This means that alternatives are not necessarily greedy. For
2367 example: when matching C<foo|foot> against "barefoot", only the "foo"
2368 part will match, as that is the first alternative tried, and it successfully
2369 matches the target string. (This might not seem important, but it is
2370 important when you are capturing matched text using parentheses.)
2371
2372 Also remember that "|" is interpreted as a literal within square brackets,
2373 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2374
2375 Within a pattern, you may designate subpatterns for later reference
2376 by enclosing them in parentheses, and you may refer back to the
2377 I<n>th subpattern later in the pattern using the metacharacter
2378 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2379 of their opening parenthesis.  A backreference matches whatever
2380 actually matched the subpattern in the string being examined, not
2381 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2382 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2383 1 matched "0x", even though the rule C<0|0x> could potentially match
2384 the leading 0 in the second number.
2385
2386 =head2 Warning on \1 Instead of $1
2387
2388 Some people get too used to writing things like:
2389
2390     $pattern =~ s/(\W)/\\\1/g;
2391
2392 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2393 shocking the
2394 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2395 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2396 the usual double-quoted string means a control-A.  The customary Unix
2397 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2398 of doing that, you get yourself into trouble if you then add an C</e>
2399 modifier.
2400
2401     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2402
2403 Or if you try to do
2404
2405     s/(\d+)/\1000/;
2406
2407 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2408 C<${1}000>.  The operation of interpolation should not be confused
2409 with the operation of matching a backreference.  Certainly they mean two
2410 different things on the I<left> side of the C<s///>.
2411
2412 =head2 Repeated Patterns Matching a Zero-length Substring
2413
2414 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2415
2416 Regular expressions provide a terse and powerful programming language.  As
2417 with most other power tools, power comes together with the ability
2418 to wreak havoc.
2419
2420 A common abuse of this power stems from the ability to make infinite
2421 loops using regular expressions, with something as innocuous as:
2422
2423     'foo' =~ m{ ( o? )* }x;
2424
2425 The C<o?> matches at the beginning of C<'foo'>, and since the position
2426 in the string is not moved by the match, C<o?> would match again and again
2427 because of the C<*> quantifier.  Another common way to create a similar cycle
2428 is with the looping modifier C<//g>:
2429
2430     @matches = ( 'foo' =~ m{ o? }xg );
2431
2432 or
2433
2434     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2435
2436 or the loop implied by split().
2437
2438 However, long experience has shown that many programming tasks may
2439 be significantly simplified by using repeated subexpressions that
2440 may match zero-length substrings.  Here's a simple example being:
2441
2442     @chars = split //, $string;           # // is not magic in split
2443     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2444
2445 Thus Perl allows such constructs, by I<forcefully breaking
2446 the infinite loop>.  The rules for this are different for lower-level
2447 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2448 ones like the C</g> modifier or split() operator.
2449
2450 The lower-level loops are I<interrupted> (that is, the loop is
2451 broken) when Perl detects that a repeated expression matched a
2452 zero-length substring.   Thus
2453
2454    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2455
2456 is made equivalent to
2457
2458    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2459
2460 For example, this program
2461
2462    #!perl -l
2463    "aaaaab" =~ /
2464      (?:
2465         a                 # non-zero
2466         |                 # or
2467        (?{print "hello"}) # print hello whenever this
2468                           #    branch is tried
2469        (?=(b))            # zero-width assertion
2470      )*  # any number of times
2471     /x;
2472    print $&;
2473    print $1;
2474
2475 prints
2476
2477    hello
2478    aaaaa
2479    b
2480
2481 Notice that "hello" is only printed once, as when Perl sees that the sixth
2482 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2483 the C<*>.
2484
2485 The higher-level loops preserve an additional state between iterations:
2486 whether the last match was zero-length.  To break the loop, the following
2487 match after a zero-length match is prohibited to have a length of zero.
2488 This prohibition interacts with backtracking (see L<"Backtracking">),
2489 and so the I<second best> match is chosen if the I<best> match is of
2490 zero length.
2491
2492 For example:
2493
2494     $_ = 'bar';
2495     s/\w??/<$&>/g;
2496
2497 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2498 match given by non-greedy C<??> is the zero-length match, and the I<second
2499 best> match is what is matched by C<\w>.  Thus zero-length matches
2500 alternate with one-character-long matches.
2501
2502 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2503 position one notch further in the string.
2504
2505 The additional state of being I<matched with zero-length> is associated with
2506 the matched string, and is reset by each assignment to pos().
2507 Zero-length matches at the end of the previous match are ignored
2508 during C<split>.
2509
2510 =head2 Combining RE Pieces
2511
2512 Each of the elementary pieces of regular expressions which were described
2513 before (such as C<ab> or C<\Z>) could match at most one substring
2514 at the given position of the input string.  However, in a typical regular
2515 expression these elementary pieces are combined into more complicated
2516 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2517 (in these examples C<S> and C<T> are regular subexpressions).
2518
2519 Such combinations can include alternatives, leading to a problem of choice:
2520 if we match a regular expression C<a|ab> against C<"abc">, will it match
2521 substring C<"a"> or C<"ab">?  One way to describe which substring is
2522 actually matched is the concept of backtracking (see L<"Backtracking">).
2523 However, this description is too low-level and makes you think
2524 in terms of a particular implementation.
2525
2526 Another description starts with notions of "better"/"worse".  All the
2527 substrings which may be matched by the given regular expression can be
2528 sorted from the "best" match to the "worst" match, and it is the "best"
2529 match which is chosen.  This substitutes the question of "what is chosen?"
2530 by the question of "which matches are better, and which are worse?".
2531
2532 Again, for elementary pieces there is no such question, since at most
2533 one match at a given position is possible.  This section describes the
2534 notion of better/worse for combining operators.  In the description
2535 below C<S> and C<T> are regular subexpressions.
2536
2537 =over 4
2538
2539 =item C<ST>
2540
2541 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2542 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2543 which can be matched by C<T>.
2544
2545 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2546 match than C<A'B'>.
2547
2548 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2549 C<B> is a better match for C<T> than C<B'>.
2550
2551 =item C<S|T>
2552
2553 When C<S> can match, it is a better match than when only C<T> can match.
2554
2555 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2556 two matches for C<T>.
2557
2558 =item C<S{REPEAT_COUNT}>
2559
2560 Matches as C<SSS...S> (repeated as many times as necessary).
2561
2562 =item C<S{min,max}>
2563
2564 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2565
2566 =item C<S{min,max}?>
2567
2568 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2569
2570 =item C<S?>, C<S*>, C<S+>
2571
2572 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2573
2574 =item C<S??>, C<S*?>, C<S+?>
2575
2576 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2577
2578 =item C<< (?>S) >>
2579
2580 Matches the best match for C<S> and only that.
2581
2582 =item C<(?=S)>, C<(?<=S)>
2583
2584 Only the best match for C<S> is considered.  (This is important only if
2585 C<S> has capturing parentheses, and backreferences are used somewhere
2586 else in the whole regular expression.)
2587
2588 =item C<(?!S)>, C<(?<!S)>
2589
2590 For this grouping operator there is no need to describe the ordering, since
2591 only whether or not C<S> can match is important.
2592
2593 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2594
2595 The ordering is the same as for the regular expression which is
2596 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2597
2598 =item C<(?(condition)yes-pattern|no-pattern)>
2599
2600 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2601 already determined.  The ordering of the matches is the same as for the
2602 chosen subexpression.
2603
2604 =back
2605
2606 The above recipes describe the ordering of matches I<at a given position>.
2607 One more rule is needed to understand how a match is determined for the
2608 whole regular expression: a match at an earlier position is always better
2609 than a match at a later position.
2610
2611 =head2 Creating Custom RE Engines
2612
2613 As of Perl 5.10.0, one can create custom regular expression engines.  This
2614 is not for the faint of heart, as they have to plug in at the C level.  See
2615 L<perlreapi> for more details.
2616
2617 As an alternative, overloaded constants (see L<overload>) provide a simple
2618 way to extend the functionality of the RE engine, by substituting one
2619 pattern for another.
2620
2621 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2622 matches at a boundary between whitespace characters and non-whitespace
2623 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2624 at these positions, so we want to have each C<\Y|> in the place of the
2625 more complicated version.  We can create a module C<customre> to do
2626 this:
2627
2628     package customre;
2629     use overload;
2630
2631     sub import {
2632       shift;
2633       die "No argument to customre::import allowed" if @_;
2634       overload::constant 'qr' => \&convert;
2635     }
2636
2637     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2638
2639     # We must also take care of not escaping the legitimate \\Y|
2640     # sequence, hence the presence of '\\' in the conversion rules.
2641     my %rules = ( '\\' => '\\\\',
2642                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2643     sub convert {
2644       my $re = shift;
2645       $re =~ s{
2646                 \\ ( \\ | Y . )
2647               }
2648               { $rules{$1} or invalid($re,$1) }sgex;
2649       return $re;
2650     }
2651
2652 Now C<use customre> enables the new escape in constant regular
2653 expressions, i.e., those without any runtime variable interpolations.
2654 As documented in L<overload>, this conversion will work only over
2655 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2656 part of this regular expression needs to be converted explicitly
2657 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2658
2659     use customre;
2660     $re = <>;
2661     chomp $re;
2662     $re = customre::convert $re;
2663     /\Y|$re\Y|/;
2664
2665 =head2 Embedded Code Execution Frequency
2666
2667 The exact rules for how often (??{}) and (?{}) are executed in a pattern
2668 are unspecified.  In the case of a successful match you can assume that
2669 they DWIM and will be executed in left to right order the appropriate
2670 number of times in the accepting path of the pattern as would any other
2671 meta-pattern.  How non-accepting pathways and match failures affect the
2672 number of times a pattern is executed is specifically unspecified and
2673 may vary depending on what optimizations can be applied to the pattern
2674 and is likely to change from version to version.
2675
2676 For instance in
2677
2678   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
2679
2680 the exact number of times "a" or "b" are printed out is unspecified for
2681 failure, but you may assume they will be printed at least once during
2682 a successful match, additionally you may assume that if "b" is printed,
2683 it will be preceded by at least one "a".
2684
2685 In the case of branching constructs like the following:
2686
2687   /a(b|(?{ print "a" }))c(?{ print "c" })/;
2688
2689 you can assume that the input "ac" will output "ac", and that "abc"
2690 will output only "c".
2691
2692 When embedded code is quantified, successful matches will call the
2693 code once for each matched iteration of the quantifier.  For
2694 example:
2695
2696   "good" =~ /g(?:o(?{print "o"}))*d/;
2697
2698 will output "o" twice.
2699
2700 =head2 PCRE/Python Support
2701
2702 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2703 to the regex syntax. While Perl programmers are encouraged to use the
2704 Perl-specific syntax, the following are also accepted:
2705
2706 =over 4
2707
2708 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2709
2710 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2711
2712 =item C<< (?P=NAME) >>
2713
2714 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2715
2716 =item C<< (?P>NAME) >>
2717
2718 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2719
2720 =back
2721
2722 =head1 BUGS
2723
2724 Many regular expression constructs don't work on EBCDIC platforms.
2725
2726 There are a number of issues with regard to case-insensitive matching
2727 in Unicode rules.  See C<i> under L</Modifiers> above.
2728
2729 This document varies from difficult to understand to completely
2730 and utterly opaque.  The wandering prose riddled with jargon is
2731 hard to fathom in several places.
2732
2733 This document needs a rewrite that separates the tutorial content
2734 from the reference content.
2735
2736 =head1 SEE ALSO
2737
2738 L<perlrequick>.
2739
2740 L<perlretut>.
2741
2742 L<perlop/"Regexp Quote-Like Operators">.
2743
2744 L<perlop/"Gory details of parsing quoted constructs">.
2745
2746 L<perlfaq6>.
2747
2748 L<perlfunc/pos>.
2749
2750 L<perllocale>.
2751
2752 L<perlebcdic>.
2753
2754 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2755 by O'Reilly and Associates.