This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
bd5ff3bc14cf19c543d4d9fdaef4746b37598a5c
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss, plus
3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
4 # on non ASCII-ish platforms need to be skipped
5
6
7 # NOTE:
8 #
9 # Increment ($x++) has a certain amount of cleverness for things like
10 #
11 #   $x = 'zz';
12 #   $x++; # $x eq 'aaa';
13 #
14 # stands more chance of breaking than just a simple
15 #
16 #   $x = $x + 1
17 #
18 # In this file, we use the latter "Baby Perl" approach, and increment
19 # will be worked over by t/op/inc.t
20
21 $Level = 1;
22 my $test = 1;
23 my $planned;
24 my $noplan;
25 my $Perl;       # Safer version of $^X set by which_perl()
26
27 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
28 $::IS_ASCII  = ord 'A' ==  65;
29 $::IS_EBCDIC = ord 'A' == 193;
30
31 $TODO = 0;
32 $NO_ENDING = 0;
33 $Tests_Are_Passing = 1;
34
35 # Use this instead of print to avoid interference while testing globals.
36 sub _print {
37     local($\, $", $,) = (undef, ' ', '');
38     print STDOUT @_;
39 }
40
41 sub _print_stderr {
42     local($\, $", $,) = (undef, ' ', '');
43     print STDERR @_;
44 }
45
46 sub plan {
47     my $n;
48     if (@_ == 1) {
49         $n = shift;
50         if ($n eq 'no_plan') {
51           undef $n;
52           $noplan = 1;
53         }
54     } else {
55         my %plan = @_;
56         $n = $plan{tests};
57     }
58     _print "1..$n\n" unless $noplan;
59     $planned = $n;
60 }
61
62
63 # Set the plan at the end.  See Test::More::done_testing.
64 sub done_testing {
65     my $n = $test - 1;
66     $n = shift if @_;
67
68     _print "1..$n\n";
69     $planned = $n;
70 }
71
72
73 END {
74     my $ran = $test - 1;
75     if (!$NO_ENDING) {
76         if (defined $planned && $planned != $ran) {
77             _print_stderr
78                 "# Looks like you planned $planned tests but ran $ran.\n";
79         } elsif ($noplan) {
80             _print "1..$ran\n";
81         }
82     }
83 }
84
85 sub _diag {
86     return unless @_;
87     my @mess = _comment(@_);
88     $TODO ? _print(@mess) : _print_stderr(@mess);
89 }
90
91 # Use this instead of "print STDERR" when outputting failure diagnostic
92 # messages
93 sub diag {
94     _diag(@_);
95 }
96
97 # Use this instead of "print" when outputting informational messages
98 sub note {
99     return unless @_;
100     _print( _comment(@_) );
101 }
102
103 sub is_miniperl {
104     return !defined &DynaLoader::boot_DynaLoader;
105 }
106
107 sub _comment {
108     return map { /^#/ ? "$_\n" : "# $_\n" }
109            map { split /\n/ } @_;
110 }
111
112 sub skip_all {
113     if (@_) {
114         _print "1..0 # Skip @_\n";
115     } else {
116         _print "1..0\n";
117     }
118     exit(0);
119 }
120
121 sub skip_all_if_miniperl {
122     skip_all(@_) if is_miniperl();
123 }
124
125 sub skip_all_without_dynamic_extension {
126     my $extension = shift;
127     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
128     unless (eval {require Config; 1}) {
129         warn "test.pl had problems loading Config: $@";
130         return;
131     }
132     $extension =~ s!::!/!g;
133     return if ($Config::Config{extensions} =~ /\b$extension\b/);
134     skip_all("$extension was not built");
135 }
136
137 sub skip_all_without_perlio {
138     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
139 }
140
141 sub skip_all_without_config {
142     unless (eval {require Config; 1}) {
143         warn "test.pl had problems loading Config: $@";
144         return;
145     }
146     foreach (@_) {
147         next if $Config::Config{$_};
148         my $key = $_; # Need to copy, before trying to modify.
149         $key =~ s/^use//;
150         $key =~ s/^d_//;
151         skip_all("no $key");
152     }
153 }
154
155 sub find_git_or_skip {
156     my ($source_dir, $reason);
157     if (-d '.git') {
158         $source_dir = '.';
159     } elsif (-l 'MANIFEST' && -l 'AUTHORS') {
160         my $where = readlink 'MANIFEST';
161         die "Can't readling MANIFEST: $!" unless defined $where;
162         die "Confusing symlink target for MANIFEST, '$where'"
163             unless $where =~ s!/MANIFEST\z!!;
164         if (-d "$where/.git") {
165             # Looks like we are in a symlink tree
166             if (exists $ENV{GIT_DIR}) {
167                 diag("Found source tree at $where, but \$ENV{GIT_DIR} is $ENV{GIT_DIR}. Not changing it");
168             } else {
169                 note("Found source tree at $where, setting \$ENV{GIT_DIR}");
170                 $ENV{GIT_DIR} = "$where/.git";
171             }
172             $source_dir = $where;
173         }
174     }
175     if ($source_dir) {
176         my $version_string = `git --version`;
177         if (defined $version_string
178               && $version_string =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
179             return $source_dir if eval "v$1 ge v1.5.0";
180             # If you have earlier than 1.5.0 and it works, change this test
181             $reason = "in git checkout, but git version '$1$2' too old";
182         } else {
183             $reason = "in git checkout, but cannot run git";
184         }
185     } else {
186         $reason = 'not being run from a git checkout';
187     }
188     skip_all($reason) if $_[0] && $_[0] eq 'all';
189     skip($reason, @_);
190 }
191
192 sub BAIL_OUT {
193     my ($reason) = @_;
194     _print("Bail out!  $reason\n");
195     exit 255;
196 }
197
198 sub _ok {
199     my ($pass, $where, $name, @mess) = @_;
200     # Do not try to microoptimize by factoring out the "not ".
201     # VMS will avenge.
202     my $out;
203     if ($name) {
204         # escape out '#' or it will interfere with '# skip' and such
205         $name =~ s/#/\\#/g;
206         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
207     } else {
208         $out = $pass ? "ok $test" : "not ok $test";
209     }
210
211     if ($TODO) {
212         $out = $out . " # TODO $TODO";
213     } else {
214         $Tests_Are_Passing = 0 unless $pass;
215     }
216
217     _print "$out\n";
218
219     if ($pass) {
220         note @mess; # Ensure that the message is properly escaped.
221     }
222     else {
223         my $msg = "# Failed test $test - ";
224         $msg.= "$name " if $name;
225         $msg .= "$where\n";
226         _diag $msg;
227         _diag @mess;
228     }
229
230     $test = $test + 1; # don't use ++
231
232     return $pass;
233 }
234
235 sub _where {
236     my @caller = caller($Level);
237     return "at $caller[1] line $caller[2]";
238 }
239
240 # DON'T use this for matches. Use like() instead.
241 sub ok ($@) {
242     my ($pass, $name, @mess) = @_;
243     _ok($pass, _where(), $name, @mess);
244 }
245
246 sub _q {
247     my $x = shift;
248     return 'undef' unless defined $x;
249     my $q = $x;
250     $q =~ s/\\/\\\\/g;
251     $q =~ s/'/\\'/g;
252     return "'$q'";
253 }
254
255 sub _qq {
256     my $x = shift;
257     return defined $x ? '"' . display ($x) . '"' : 'undef';
258 };
259
260 # keys are the codes \n etc map to, values are 2 char strings such as \n
261 my %backslash_escape;
262 foreach my $x (split //, 'nrtfa\\\'"') {
263     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
264 }
265 # A way to display scalars containing control characters and Unicode.
266 # Trying to avoid setting $_, or relying on local $_ to work.
267 sub display {
268     my @result;
269     foreach my $x (@_) {
270         if (defined $x and not ref $x) {
271             my $y = '';
272             foreach my $c (unpack("U*", $x)) {
273                 if ($c > 255) {
274                     $y = $y . sprintf "\\x{%x}", $c;
275                 } elsif ($backslash_escape{$c}) {
276                     $y = $y . $backslash_escape{$c};
277                 } else {
278                     my $z = chr $c; # Maybe we can get away with a literal...
279                     if ($z =~ /[[:^print:]]/) {
280
281                         # Use octal for characters traditionally expressed as
282                         # such: the low controls
283                         if ($c <= 037) {
284                             $z = sprintf "\\%03o", $c;
285                         } else {
286                             $z = sprintf "\\x{%x}", $c;
287                         }
288                     }
289                     $y = $y . $z;
290                 }
291             }
292             $x = $y;
293         }
294         return $x unless wantarray;
295         push @result, $x;
296     }
297     return @result;
298 }
299
300 sub is ($$@) {
301     my ($got, $expected, $name, @mess) = @_;
302
303     my $pass;
304     if( !defined $got || !defined $expected ) {
305         # undef only matches undef
306         $pass = !defined $got && !defined $expected;
307     }
308     else {
309         $pass = $got eq $expected;
310     }
311
312     unless ($pass) {
313         unshift(@mess, "#      got "._qq($got)."\n",
314                        "# expected "._qq($expected)."\n");
315     }
316     _ok($pass, _where(), $name, @mess);
317 }
318
319 sub isnt ($$@) {
320     my ($got, $isnt, $name, @mess) = @_;
321
322     my $pass;
323     if( !defined $got || !defined $isnt ) {
324         # undef only matches undef
325         $pass = defined $got || defined $isnt;
326     }
327     else {
328         $pass = $got ne $isnt;
329     }
330
331     unless( $pass ) {
332         unshift(@mess, "# it should not be "._qq($got)."\n",
333                        "# but it is.\n");
334     }
335     _ok($pass, _where(), $name, @mess);
336 }
337
338 sub cmp_ok ($$$@) {
339     my($got, $type, $expected, $name, @mess) = @_;
340
341     my $pass;
342     {
343         local $^W = 0;
344         local($@,$!);   # don't interfere with $@
345                         # eval() sometimes resets $!
346         $pass = eval "\$got $type \$expected";
347     }
348     unless ($pass) {
349         # It seems Irix long doubles can have 2147483648 and 2147483648
350         # that stringify to the same thing but are actually numerically
351         # different. Display the numbers if $type isn't a string operator,
352         # and the numbers are stringwise the same.
353         # (all string operators have alphabetic names, so tr/a-z// is true)
354         # This will also show numbers for some unneeded cases, but will
355         # definitely be helpful for things such as == and <= that fail
356         if ($got eq $expected and $type !~ tr/a-z//) {
357             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
358         }
359         unshift(@mess, "#      got "._qq($got)."\n",
360                        "# expected $type "._qq($expected)."\n");
361     }
362     _ok($pass, _where(), $name, @mess);
363 }
364
365 # Check that $got is within $range of $expected
366 # if $range is 0, then check it's exact
367 # else if $expected is 0, then $range is an absolute value
368 # otherwise $range is a fractional error.
369 # Here $range must be numeric, >= 0
370 # Non numeric ranges might be a useful future extension. (eg %)
371 sub within ($$$@) {
372     my ($got, $expected, $range, $name, @mess) = @_;
373     my $pass;
374     if (!defined $got or !defined $expected or !defined $range) {
375         # This is a fail, but doesn't need extra diagnostics
376     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
377         # This is a fail
378         unshift @mess, "# got, expected and range must be numeric\n";
379     } elsif ($range < 0) {
380         # This is also a fail
381         unshift @mess, "# range must not be negative\n";
382     } elsif ($range == 0) {
383         # Within 0 is ==
384         $pass = $got == $expected;
385     } elsif ($expected == 0) {
386         # If expected is 0, treat range as absolute
387         $pass = ($got <= $range) && ($got >= - $range);
388     } else {
389         my $diff = $got - $expected;
390         $pass = abs ($diff / $expected) < $range;
391     }
392     unless ($pass) {
393         if ($got eq $expected) {
394             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
395         }
396         unshift@mess, "#      got "._qq($got)."\n",
397                       "# expected "._qq($expected)." (within "._qq($range).")\n";
398     }
399     _ok($pass, _where(), $name, @mess);
400 }
401
402 # Note: this isn't quite as fancy as Test::More::like().
403
404 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
405 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
406
407 sub like_yn ($$$@) {
408     my ($flip, undef, $expected, $name, @mess) = @_;
409     my $pass;
410     $pass = $_[1] =~ /$expected/ if !$flip;
411     $pass = $_[1] !~ /$expected/ if $flip;
412     unless ($pass) {
413         unshift(@mess, "#      got '$_[1]'\n",
414                 $flip
415                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
416     }
417     local $Level = $Level + 1;
418     _ok($pass, _where(), $name, @mess);
419 }
420
421 sub pass {
422     _ok(1, '', @_);
423 }
424
425 sub fail {
426     _ok(0, _where(), @_);
427 }
428
429 sub curr_test {
430     $test = shift if @_;
431     return $test;
432 }
433
434 sub next_test {
435   my $retval = $test;
436   $test = $test + 1; # don't use ++
437   $retval;
438 }
439
440 # Note: can't pass multipart messages since we try to
441 # be compatible with Test::More::skip().
442 sub skip {
443     my $why = shift;
444     my $n    = @_ ? shift : 1;
445     for (1..$n) {
446         _print "ok $test # skip $why\n";
447         $test = $test + 1;
448     }
449     local $^W = 0;
450     last SKIP;
451 }
452
453 sub skip_if_miniperl {
454     skip(@_) if is_miniperl();
455 }
456
457 sub todo_skip {
458     my $why = shift;
459     my $n   = @_ ? shift : 1;
460
461     for (1..$n) {
462         _print "not ok $test # TODO & SKIP $why\n";
463         $test = $test + 1;
464     }
465     local $^W = 0;
466     last TODO;
467 }
468
469 sub eq_array {
470     my ($ra, $rb) = @_;
471     return 0 unless $#$ra == $#$rb;
472     for my $i (0..$#$ra) {
473         next     if !defined $ra->[$i] && !defined $rb->[$i];
474         return 0 if !defined $ra->[$i];
475         return 0 if !defined $rb->[$i];
476         return 0 unless $ra->[$i] eq $rb->[$i];
477     }
478     return 1;
479 }
480
481 sub eq_hash {
482   my ($orig, $suspect) = @_;
483   my $fail;
484   while (my ($key, $value) = each %$suspect) {
485     # Force a hash recompute if this perl's internals can cache the hash key.
486     $key = "" . $key;
487     if (exists $orig->{$key}) {
488       if ($orig->{$key} ne $value) {
489         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
490                      " now ", _qq($value), "\n";
491         $fail = 1;
492       }
493     } else {
494       _print "# key ", _qq($key), " is ", _qq($value),
495                    ", not in original.\n";
496       $fail = 1;
497     }
498   }
499   foreach (keys %$orig) {
500     # Force a hash recompute if this perl's internals can cache the hash key.
501     $_ = "" . $_;
502     next if (exists $suspect->{$_});
503     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
504     $fail = 1;
505   }
506   !$fail;
507 }
508
509 # We only provide a subset of the Test::More functionality.
510 sub require_ok ($) {
511     my ($require) = @_;
512     if ($require =~ tr/[A-Za-z0-9:.]//c) {
513         fail("Invalid character in \"$require\", passed to require_ok");
514     } else {
515         eval <<REQUIRE_OK;
516 require $require;
517 REQUIRE_OK
518         is($@, '', _where(), "require $require");
519     }
520 }
521
522 sub use_ok ($) {
523     my ($use) = @_;
524     if ($use =~ tr/[A-Za-z0-9:.]//c) {
525         fail("Invalid character in \"$use\", passed to use");
526     } else {
527         eval <<USE_OK;
528 use $use;
529 USE_OK
530         is($@, '', _where(), "use $use");
531     }
532 }
533
534 # runperl - Runs a separate perl interpreter.
535 # Arguments :
536 #   switches => [ command-line switches ]
537 #   nolib    => 1 # don't use -I../lib (included by default)
538 #   non_portable => Don't warn if a one liner contains quotes
539 #   prog     => one-liner (avoid quotes)
540 #   progs    => [ multi-liner (avoid quotes) ]
541 #   progfile => perl script
542 #   stdin    => string to feed the stdin
543 #   stderr   => redirect stderr to stdout
544 #   args     => [ command-line arguments to the perl program ]
545 #   verbose  => print the command line
546
547 my $is_mswin    = $^O eq 'MSWin32';
548 my $is_netware  = $^O eq 'NetWare';
549 my $is_vms      = $^O eq 'VMS';
550 my $is_cygwin   = $^O eq 'cygwin';
551
552 sub _quote_args {
553     my ($runperl, $args) = @_;
554
555     foreach (@$args) {
556         # In VMS protect with doublequotes because otherwise
557         # DCL will lowercase -- unless already doublequoted.
558        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
559        $runperl = $runperl . ' ' . $_;
560     }
561     return $runperl;
562 }
563
564 sub _create_runperl { # Create the string to qx in runperl().
565     my %args = @_;
566     my $runperl = which_perl();
567     if ($runperl =~ m/\s/) {
568         $runperl = qq{"$runperl"};
569     }
570     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
571     if ($ENV{PERL_RUNPERL_DEBUG}) {
572         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
573     }
574     unless ($args{nolib}) {
575         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
576     }
577     if ($args{switches}) {
578         local $Level = 2;
579         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
580             unless ref $args{switches} eq "ARRAY";
581         $runperl = _quote_args($runperl, $args{switches});
582     }
583     if (defined $args{prog}) {
584         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
585             if defined $args{progs};
586         $args{progs} = [$args{prog}]
587     }
588     if (defined $args{progs}) {
589         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
590             unless ref $args{progs} eq "ARRAY";
591         foreach my $prog (@{$args{progs}}) {
592             if ($prog =~ tr/'"// && !$args{non_portable}) {
593                 warn "quotes in prog >>$prog<< are not portable";
594             }
595             if ($is_mswin || $is_netware || $is_vms) {
596                 $runperl = $runperl . qq ( -e "$prog" );
597             }
598             else {
599                 $runperl = $runperl . qq ( -e '$prog' );
600             }
601         }
602     } elsif (defined $args{progfile}) {
603         $runperl = $runperl . qq( "$args{progfile}");
604     } else {
605         # You probably didn't want to be sucking in from the upstream stdin
606         die "test.pl:runperl(): none of prog, progs, progfile, args, "
607             . " switches or stdin specified"
608             unless defined $args{args} or defined $args{switches}
609                 or defined $args{stdin};
610     }
611     if (defined $args{stdin}) {
612         # so we don't try to put literal newlines and crs onto the
613         # command line.
614         $args{stdin} =~ s/\n/\\n/g;
615         $args{stdin} =~ s/\r/\\r/g;
616
617         if ($is_mswin || $is_netware || $is_vms) {
618             $runperl = qq{$Perl -e "print qq(} .
619                 $args{stdin} . q{)" | } . $runperl;
620         }
621         else {
622             $runperl = qq{$Perl -e 'print qq(} .
623                 $args{stdin} . q{)' | } . $runperl;
624         }
625     }
626     if (defined $args{args}) {
627         $runperl = _quote_args($runperl, $args{args});
628     }
629     $runperl = $runperl . ' 2>&1' if $args{stderr};
630     if ($args{verbose}) {
631         my $runperldisplay = $runperl;
632         $runperldisplay =~ s/\n/\n\#/g;
633         _print_stderr "# $runperldisplay\n";
634     }
635     return $runperl;
636 }
637
638 sub runperl {
639     die "test.pl:runperl() does not take a hashref"
640         if ref $_[0] and ref $_[0] eq 'HASH';
641     my $runperl = &_create_runperl;
642     my $result;
643
644     my $tainted = ${^TAINT};
645     my %args = @_;
646     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
647
648     if ($tainted) {
649         # We will assume that if you're running under -T, you really mean to
650         # run a fresh perl, so we'll brute force launder everything for you
651         my $sep;
652
653         if (! eval {require Config; 1}) {
654             warn "test.pl had problems loading Config: $@";
655             $sep = ':';
656         } else {
657             $sep = $Config::Config{path_sep};
658         }
659
660         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
661         local @ENV{@keys} = ();
662         # Untaint, plus take out . and empty string:
663         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
664         $ENV{PATH} =~ /(.*)/s;
665         local $ENV{PATH} =
666             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
667                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
668                     split quotemeta ($sep), $1;
669         if ($is_cygwin) {   # Must have /bin under Cygwin
670             if (length $ENV{PATH}) {
671                 $ENV{PATH} = $ENV{PATH} . $sep;
672             }
673             $ENV{PATH} = $ENV{PATH} . '/bin';
674         }
675         $runperl =~ /(.*)/s;
676         $runperl = $1;
677
678         $result = `$runperl`;
679     } else {
680         $result = `$runperl`;
681     }
682     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
683     return $result;
684 }
685
686 # Nice alias
687 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
688
689 sub DIE {
690     _print_stderr "# @_\n";
691     exit 1;
692 }
693
694 # A somewhat safer version of the sometimes wrong $^X.
695 sub which_perl {
696     unless (defined $Perl) {
697         $Perl = $^X;
698
699         # VMS should have 'perl' aliased properly
700         return $Perl if $is_vms;
701
702         my $exe;
703         if (! eval {require Config; 1}) {
704             warn "test.pl had problems loading Config: $@";
705             $exe = '';
706         } else {
707             $exe = $Config::Config{_exe};
708         }
709        $exe = '' unless defined $exe;
710
711         # This doesn't absolutize the path: beware of future chdirs().
712         # We could do File::Spec->abs2rel() but that does getcwd()s,
713         # which is a bit heavyweight to do here.
714
715         if ($Perl =~ /^perl\Q$exe\E$/i) {
716             my $perl = "perl$exe";
717             if (! eval {require File::Spec; 1}) {
718                 warn "test.pl had problems loading File::Spec: $@";
719                 $Perl = "./$perl";
720             } else {
721                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
722             }
723         }
724
725         # Build up the name of the executable file from the name of
726         # the command.
727
728         if ($Perl !~ /\Q$exe\E$/i) {
729             $Perl = $Perl . $exe;
730         }
731
732         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
733
734         # For subcommands to use.
735         $ENV{PERLEXE} = $Perl;
736     }
737     return $Perl;
738 }
739
740 sub unlink_all {
741     my $count = 0;
742     foreach my $file (@_) {
743         1 while unlink $file;
744         if( -f $file ){
745             _print_stderr "# Couldn't unlink '$file': $!\n";
746         }else{
747             ++$count;
748         }
749     }
750     $count;
751 }
752
753 my %tmpfiles;
754 END { unlink_all keys %tmpfiles }
755
756 # A regexp that matches the tempfile names
757 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
758
759 # Avoid ++, avoid ranges, avoid split //
760 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
761 sub tempfile {
762     my $count = 0;
763     do {
764         my $temp = $count;
765         my $try = "tmp$$";
766         do {
767             $try = $try . $letters[$temp % 26];
768             $temp = int ($temp / 26);
769         } while $temp;
770         # Need to note all the file names we allocated, as a second request may
771         # come before the first is created.
772         if (!-e $try && !$tmpfiles{$try}) {
773             # We have a winner
774             $tmpfiles{$try} = 1;
775             return $try;
776         }
777         $count = $count + 1;
778     } while $count < 26 * 26;
779     die "Can't find temporary file name starting 'tmp$$'";
780 }
781
782 # This is the temporary file for _fresh_perl
783 my $tmpfile = tempfile();
784
785 sub _fresh_perl {
786     my($prog, $action, $expect, $runperl_args, $name) = @_;
787
788     # Given the choice of the mis-parsable {}
789     # (we want an anon hash, but a borked lexer might think that it's a block)
790     # or relying on taking a reference to a lexical
791     # (\ might be mis-parsed, and the reference counting on the pad may go
792     #  awry)
793     # it feels like the least-worse thing is to assume that auto-vivification
794     # works. At least, this is only going to be a run-time failure, so won't
795     # affect tests using this file but not this function.
796     $runperl_args->{progfile} ||= $tmpfile;
797     $runperl_args->{stderr}     = 1 unless exists $runperl_args->{stderr};
798
799     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
800
801     # VMS adjustments
802     if( $is_vms ) {
803         $prog =~ s#/dev/null#NL:#;
804
805         # VMS file locking
806         $prog =~ s{if \(-e _ and -f _ and -r _\)}
807                   {if (-e _ and -f _)}
808     }
809
810     print TEST $prog;
811     close TEST or die "Cannot close $tmpfile: $!";
812
813     my $results = runperl(%$runperl_args);
814     my $status = $?;
815
816     # Clean up the results into something a bit more predictable.
817     $results  =~ s/\n+$//;
818     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
819     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
820
821     # bison says 'parse error' instead of 'syntax error',
822     # various yaccs may or may not capitalize 'syntax'.
823     $results =~ s/^(syntax|parse) error/syntax error/mig;
824
825     if ($is_vms) {
826         # some tests will trigger VMS messages that won't be expected
827         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
828
829         # pipes double these sometimes
830         $results =~ s/\n\n/\n/g;
831     }
832
833     # Use the first line of the program as a name if none was given
834     unless( $name ) {
835         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
836         $name = $name . '...' if length $first_line > length $name;
837     }
838
839     # Historically this was implemented using a closure, but then that means
840     # that the tests for closures avoid using this code. Given that there
841     # are exactly two callers, doing exactly two things, the simpler approach
842     # feels like a better trade off.
843     my $pass;
844     if ($action eq 'eq') {
845         $pass = is($results, $expect, $name);
846     } elsif ($action eq '=~') {
847         $pass = like($results, $expect, $name);
848     } else {
849         die "_fresh_perl can't process action '$action'";
850     }
851         
852     unless ($pass) {
853         _diag "# PROG: \n$prog\n";
854         _diag "# STATUS: $status\n";
855     }
856
857     return $pass;
858 }
859
860 #
861 # fresh_perl_is
862 #
863 # Combination of run_perl() and is().
864 #
865
866 sub fresh_perl_is {
867     my($prog, $expected, $runperl_args, $name) = @_;
868
869     # _fresh_perl() is going to clip the trailing newlines off the result.
870     # This will make it so the test author doesn't have to know that.
871     $expected =~ s/\n+$//;
872
873     local $Level = 2;
874     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
875 }
876
877 #
878 # fresh_perl_like
879 #
880 # Combination of run_perl() and like().
881 #
882
883 sub fresh_perl_like {
884     my($prog, $expected, $runperl_args, $name) = @_;
885     local $Level = 2;
886     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
887 }
888
889 # Many tests use the same format in __DATA__ or external files to specify a
890 # sequence of (fresh) tests to run, extra files they may temporarily need, and
891 # what the expected output is. So have excatly one copy of the code to run that
892 #
893 # Each program is source code to run followed by an "EXPECT" line, followed
894 # by the expected output.
895 #
896 # The code to run may contain (note the '# ' on each):
897 #   # TODO reason for todo
898 #   # SKIP reason for skip
899 #   # SKIP ?code to test if this should be skipped
900 #   # NAME name of the test (as with ok($ok, $name))
901 #
902 # The expected output may contain:
903 #   OPTION list of options
904 #   OPTIONS list of options
905 #   PREFIX
906 #     indicates that the supplied output is only a prefix to the
907 #     expected output
908 #
909 # The possible options for OPTION may be:
910 #   regex - the expected output is a regular expression
911 #   random - all lines match but in any order
912 #   fatal - the code will fail fatally (croak, die)
913 #
914 # If the actual output contains a line "SKIPPED" the test will be
915 # skipped.
916 #
917 # If the global variable $FATAL is true then OPTION fatal is the
918 # default.
919
920 sub run_multiple_progs {
921     my $up = shift;
922     my @prgs;
923     if ($up) {
924         # The tests in lib run in a temporary subdirectory of t, and always
925         # pass in a list of "programs" to run
926         @prgs = @_;
927     } else {
928         # The tests below t run in t and pass in a file handle.
929         my $fh = shift;
930         local $/;
931         @prgs = split "\n########\n", <$fh>;
932     }
933
934     my $tmpfile = tempfile();
935
936     for (@prgs){
937         unless (/\n/) {
938             print "# From $_\n";
939             next;
940         }
941         my $switch = "";
942         my @temps ;
943         my @temp_path;
944         if (s/^(\s*-\w+)//) {
945             $switch = $1;
946         }
947         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
948
949         my %reason;
950         foreach my $what (qw(skip todo)) {
951             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
952             # If the SKIP reason starts ? then it's taken as a code snippet to
953             # evaluate. This provides the flexibility to have conditional SKIPs
954             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
955                 my $temp = eval $reason{$what};
956                 if ($@) {
957                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
958                 }
959                 $reason{$what} = $temp;
960             }
961         }
962         my $name = '';
963         if ($prog =~ s/^#\s*NAME\s+(.+)\n//m) {
964             $name = $1;
965         }
966
967         if ($prog =~ /--FILE--/) {
968             my @files = split(/\n--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
969             shift @files ;
970             die "Internal error: test $_ didn't split into pairs, got " .
971                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
972                     if @files % 2;
973             while (@files > 2) {
974                 my $filename = shift @files;
975                 my $code = shift @files;
976                 push @temps, $filename;
977                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
978                     require File::Path;
979                     File::Path::mkpath($1);
980                     push(@temp_path, $1);
981                 }
982                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
983                 print $fh $code;
984                 close $fh or die "Cannot close $filename: $!\n";
985             }
986             shift @files;
987             $prog = shift @files;
988         }
989
990         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
991         print $fh q{
992         BEGIN {
993             open STDERR, '>&', STDOUT
994               or die "Can't dup STDOUT->STDERR: $!;";
995         }
996         };
997         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
998         print $fh $prog,"\n";
999         close $fh or die "Cannot close $tmpfile: $!";
1000         my $results = runperl( stderr => 1, progfile => $tmpfile, $up
1001                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
1002                                : (switches => [$switch])
1003                                 );
1004         my $status = $?;
1005         $results =~ s/\n+$//;
1006         # allow expected output to be written as if $prog is on STDIN
1007         $results =~ s/$::tempfile_regexp/-/g;
1008         if ($^O eq 'VMS') {
1009             # some tests will trigger VMS messages that won't be expected
1010             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1011
1012             # pipes double these sometimes
1013             $results =~ s/\n\n/\n/g;
1014         }
1015         # bison says 'parse error' instead of 'syntax error',
1016         # various yaccs may or may not capitalize 'syntax'.
1017         $results =~ s/^(syntax|parse) error/syntax error/mig;
1018         # allow all tests to run when there are leaks
1019         $results =~ s/Scalars leaked: \d+\n//g;
1020
1021         $expected =~ s/\n+$//;
1022         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
1023         # any special options? (OPTIONS foo bar zap)
1024         my $option_regex = 0;
1025         my $option_random = 0;
1026         my $fatal = $FATAL;
1027         if ($expected =~ s/^OPTIONS? (.+)\n//) {
1028             foreach my $option (split(' ', $1)) {
1029                 if ($option eq 'regex') { # allow regular expressions
1030                     $option_regex = 1;
1031                 }
1032                 elsif ($option eq 'random') { # all lines match, but in any order
1033                     $option_random = 1;
1034                 }
1035                 elsif ($option eq 'fatal') { # perl should fail
1036                     $fatal = 1;
1037                 }
1038                 else {
1039                     die "$0: Unknown OPTION '$option'\n";
1040                 }
1041             }
1042         }
1043         die "$0: can't have OPTION regex and random\n"
1044             if $option_regex + $option_random > 1;
1045         my $ok = 0;
1046         if ($results =~ s/^SKIPPED\n//) {
1047             print "$results\n" ;
1048             $ok = 1;
1049         }
1050         else {
1051             if ($option_random) {
1052                 my @got = sort split "\n", $results;
1053                 my @expected = sort split "\n", $expected;
1054
1055                 $ok = "@got" eq "@expected";
1056             }
1057             elsif ($option_regex) {
1058                 $ok = $results =~ /^$expected/;
1059             }
1060             elsif ($prefix) {
1061                 $ok = $results =~ /^\Q$expected/;
1062             }
1063             else {
1064                 $ok = $results eq $expected;
1065             }
1066
1067             if ($ok && $fatal && !($status >> 8)) {
1068                 $ok = 0;
1069             }
1070         }
1071
1072         local $::TODO = $reason{todo};
1073
1074         unless ($ok) {
1075             my $err_line = "PROG: $switch\n$prog\n" .
1076                            "EXPECTED:\n$expected\n";
1077             $err_line   .= "EXIT STATUS: != 0\n" if $fatal;
1078             $err_line   .= "GOT:\n$results\n";
1079             $err_line   .= "EXIT STATUS: " . ($status >> 8) . "\n" if $fatal;
1080             if ($::TODO) {
1081                 $err_line =~ s/^/# /mg;
1082                 print $err_line;  # Harness can't filter it out from STDERR.
1083             }
1084             else {
1085                 print STDERR $err_line;
1086             }
1087         }
1088
1089         ok($ok, $name);
1090
1091         foreach (@temps) {
1092             unlink $_ if $_;
1093         }
1094         foreach (@temp_path) {
1095             File::Path::rmtree $_ if -d $_;
1096         }
1097     }
1098 }
1099
1100 sub can_ok ($@) {
1101     my($proto, @methods) = @_;
1102     my $class = ref $proto || $proto;
1103
1104     unless( @methods ) {
1105         return _ok( 0, _where(), "$class->can(...)" );
1106     }
1107
1108     my @nok = ();
1109     foreach my $method (@methods) {
1110         local($!, $@);  # don't interfere with caller's $@
1111                         # eval sometimes resets $!
1112         eval { $proto->can($method) } || push @nok, $method;
1113     }
1114
1115     my $name;
1116     $name = @methods == 1 ? "$class->can('$methods[0]')"
1117                           : "$class->can(...)";
1118
1119     _ok( !@nok, _where(), $name );
1120 }
1121
1122
1123 # Call $class->new( @$args ); and run the result through object_ok.
1124 # See Test::More::new_ok
1125 sub new_ok {
1126     my($class, $args, $obj_name) = @_;
1127     $args ||= [];
1128     $object_name = "The object" unless defined $obj_name;
1129
1130     local $Level = $Level + 1;
1131
1132     my $obj;
1133     my $ok = eval { $obj = $class->new(@$args); 1 };
1134     my $error = $@;
1135
1136     if($ok) {
1137         object_ok($obj, $class, $object_name);
1138     }
1139     else {
1140         ok( 0, "new() died" );
1141         diag("Error was:  $@");
1142     }
1143
1144     return $obj;
1145
1146 }
1147
1148
1149 sub isa_ok ($$;$) {
1150     my($object, $class, $obj_name) = @_;
1151
1152     my $diag;
1153     $obj_name = 'The object' unless defined $obj_name;
1154     my $name = "$obj_name isa $class";
1155     if( !defined $object ) {
1156         $diag = "$obj_name isn't defined";
1157     }
1158     else {
1159         my $whatami = ref $object ? 'object' : 'class';
1160
1161         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1162         local($@, $!);  # eval sometimes resets $!
1163         my $rslt = eval { $object->isa($class) };
1164         my $error = $@;  # in case something else blows away $@
1165
1166         if( $error ) {
1167             if( $error =~ /^Can't call method "isa" on unblessed reference/ ) {
1168                 # It's an unblessed reference
1169                 $obj_name = 'The reference' unless defined $obj_name;
1170                 if( !UNIVERSAL::isa($object, $class) ) {
1171                     my $ref = ref $object;
1172                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1173                 }
1174             }
1175             elsif( $error =~ /Can't call method "isa" without a package/ ) {
1176                 # It's something that can't even be a class
1177                 $obj_name = 'The thing' unless defined $obj_name;
1178                 $diag = "$obj_name isn't a class or reference";
1179             }
1180             else {
1181                 die <<WHOA;
1182 WHOA! I tried to call ->isa on your object and got some weird error.
1183 This should never happen.  Please contact the author immediately.
1184 Here's the error.
1185 $@
1186 WHOA
1187             }
1188         }
1189         elsif( !$rslt ) {
1190             $obj_name = "The $whatami" unless defined $obj_name;
1191             my $ref = ref $object;
1192             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1193         }
1194     }
1195
1196     _ok( !$diag, _where(), $name );
1197 }
1198
1199
1200 sub class_ok {
1201     my($class, $isa, $class_name) = @_;
1202
1203     # Written so as to count as one test
1204     local $Level = $Level + 1;
1205     if( ref $class ) {
1206         ok( 0, "$class is a refrence, not a class name" );
1207     }
1208     else {
1209         isa_ok($class, $isa, $class_name);
1210     }
1211 }
1212
1213
1214 sub object_ok {
1215     my($obj, $isa, $obj_name) = @_;
1216
1217     local $Level = $Level + 1;
1218     if( !ref $obj ) {
1219         ok( 0, "$obj is not a reference" );
1220     }
1221     else {
1222         isa_ok($obj, $isa, $obj_name);
1223     }
1224 }
1225
1226
1227 # Purposefully avoiding a closure.
1228 sub __capture {
1229     push @::__capture, join "", @_;
1230 }
1231     
1232 sub capture_warnings {
1233     my $code = shift;
1234
1235     local @::__capture;
1236     local $SIG {__WARN__} = \&__capture;
1237     &$code;
1238     return @::__capture;
1239 }
1240
1241 # This will generate a variable number of tests.
1242 # Use done_testing() instead of a fixed plan.
1243 sub warnings_like {
1244     my ($code, $expect, $name) = @_;
1245     local $Level = $Level + 1;
1246
1247     my @w = capture_warnings($code);
1248
1249     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1250     foreach my $e (@$expect) {
1251         if (ref $e) {
1252             like(shift @w, $e, $name);
1253         } else {
1254             is(shift @w, $e, $name);
1255         }
1256     }
1257     if (@w) {
1258         diag("Saw these additional warnings:");
1259         diag($_) foreach @w;
1260     }
1261 }
1262
1263 sub _fail_excess_warnings {
1264     my($expect, $got, $name) = @_;
1265     local $Level = $Level + 1;
1266     # This will fail, and produce diagnostics
1267     is($expect, scalar @$got, $name);
1268     diag("Saw these warnings:");
1269     diag($_) foreach @$got;
1270 }
1271
1272 sub warning_is {
1273     my ($code, $expect, $name) = @_;
1274     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1275         if ref $expect;
1276     local $Level = $Level + 1;
1277     my @w = capture_warnings($code);
1278     if (@w > 1) {
1279         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1280     } else {
1281         is($w[0], $expect, $name);
1282     }
1283 }
1284
1285 sub warning_like {
1286     my ($code, $expect, $name) = @_;
1287     die sprintf "Expect must be a regexp object"
1288         unless ref $expect eq 'Regexp';
1289     local $Level = $Level + 1;
1290     my @w = capture_warnings($code);
1291     if (@w > 1) {
1292         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1293     } else {
1294         like($w[0], $expect, $name);
1295     }
1296 }
1297
1298 # Set a watchdog to timeout the entire test file
1299 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1300 #        _AFTER_ the 'threads' module is loaded.
1301 sub watchdog ($;$)
1302 {
1303     my $timeout = shift;
1304     my $method  = shift || "";
1305     my $timeout_msg = 'Test process timed out - terminating';
1306
1307     # Valgrind slows perl way down so give it more time before dying.
1308     $timeout *= 10 if $ENV{PERL_VALGRIND};
1309
1310     my $pid_to_kill = $$;   # PID for this process
1311
1312     if ($method eq "alarm") {
1313         goto WATCHDOG_VIA_ALARM;
1314     }
1315
1316     # shut up use only once warning
1317     my $threads_on = $threads::threads && $threads::threads;
1318
1319     # Don't use a watchdog process if 'threads' is loaded -
1320     #   use a watchdog thread instead
1321     if (!$threads_on || $method eq "process") {
1322
1323         # On Windows and VMS, try launching a watchdog process
1324         #   using system(1, ...) (see perlport.pod)
1325         if ($is_mswin || $is_vms) {
1326             # On Windows, try to get the 'real' PID
1327             if ($is_mswin) {
1328                 eval { require Win32; };
1329                 if (defined(&Win32::GetCurrentProcessId)) {
1330                     $pid_to_kill = Win32::GetCurrentProcessId();
1331                 }
1332             }
1333
1334             # If we still have a fake PID, we can't use this method at all
1335             return if ($pid_to_kill <= 0);
1336
1337             # Launch watchdog process
1338             my $watchdog;
1339             eval {
1340                 local $SIG{'__WARN__'} = sub {
1341                     _diag("Watchdog warning: $_[0]");
1342                 };
1343                 my $sig = $is_vms ? 'TERM' : 'KILL';
1344                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
1345                                                     "warn qq/# $timeout_msg" . '\n/;' .
1346                                                     "kill($sig, $pid_to_kill);");
1347                 $watchdog = system(1, $cmd);
1348             };
1349             if ($@ || ($watchdog <= 0)) {
1350                 _diag('Failed to start watchdog');
1351                 _diag($@) if $@;
1352                 undef($watchdog);
1353                 return;
1354             }
1355
1356             # Add END block to parent to terminate and
1357             #   clean up watchdog process
1358             eval "END { local \$! = 0; local \$? = 0;
1359                         wait() if kill('KILL', $watchdog); };";
1360             return;
1361         }
1362
1363         # Try using fork() to generate a watchdog process
1364         my $watchdog;
1365         eval { $watchdog = fork() };
1366         if (defined($watchdog)) {
1367             if ($watchdog) {   # Parent process
1368                 # Add END block to parent to terminate and
1369                 #   clean up watchdog process
1370                 eval "END { local \$! = 0; local \$? = 0;
1371                             wait() if kill('KILL', $watchdog); };";
1372                 return;
1373             }
1374
1375             ### Watchdog process code
1376
1377             # Load POSIX if available
1378             eval { require POSIX; };
1379
1380             # Execute the timeout
1381             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1382             sleep(2);
1383
1384             # Kill test process if still running
1385             if (kill(0, $pid_to_kill)) {
1386                 _diag($timeout_msg);
1387                 kill('KILL', $pid_to_kill);
1388                 if ($is_cygwin) {
1389                     # sometimes the above isn't enough on cygwin
1390                     sleep 1; # wait a little, it might have worked after all
1391                     system("/bin/kill -f $pid_to_kill");
1392                 }
1393             }
1394
1395             # Don't execute END block (added at beginning of this file)
1396             $NO_ENDING = 1;
1397
1398             # Terminate ourself (i.e., the watchdog)
1399             POSIX::_exit(1) if (defined(&POSIX::_exit));
1400             exit(1);
1401         }
1402
1403         # fork() failed - fall through and try using a thread
1404     }
1405
1406     # Use a watchdog thread because either 'threads' is loaded,
1407     #   or fork() failed
1408     if (eval {require threads; 1}) {
1409         'threads'->create(sub {
1410                 # Load POSIX if available
1411                 eval { require POSIX; };
1412
1413                 # Execute the timeout
1414                 my $time_left = $timeout;
1415                 do {
1416                     $time_left = $time_left - sleep($time_left);
1417                 } while ($time_left > 0);
1418
1419                 # Kill the parent (and ourself)
1420                 select(STDERR); $| = 1;
1421                 _diag($timeout_msg);
1422                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1423                 my $sig = $is_vms ? 'TERM' : 'KILL';
1424                 kill($sig, $pid_to_kill);
1425             })->detach();
1426         return;
1427     }
1428
1429     # If everything above fails, then just use an alarm timeout
1430 WATCHDOG_VIA_ALARM:
1431     if (eval { alarm($timeout); 1; }) {
1432         # Load POSIX if available
1433         eval { require POSIX; };
1434
1435         # Alarm handler will do the actual 'killing'
1436         $SIG{'ALRM'} = sub {
1437             select(STDERR); $| = 1;
1438             _diag($timeout_msg);
1439             POSIX::_exit(1) if (defined(&POSIX::_exit));
1440             my $sig = $is_vms ? 'TERM' : 'KILL';
1441             kill($sig, $pid_to_kill);
1442         };
1443     }
1444 }
1445
1446 my $cp_0037 =   # EBCDIC code page 0037
1447     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x25\x0B\x0C\x0D\x0E\x0F' .
1448     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1449     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1450     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1451     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1452     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBA\xE0\xBB\xB0\x6D' .
1453     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1454     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1455     '\x20\x21\x22\x23\x24\x15\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1456     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1457     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBD\xB4\x9A\x8A\x5F\xCA\xAF\xBC' .
1458     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1459     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1460     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xAD\xAE\x59' .
1461     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1462     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1463
1464 my $cp_1047 =   # EBCDIC code page 1047
1465     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1466     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1467     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1468     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1469     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1470     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xAD\xE0\xBD\x5F\x6D' .
1471     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1472     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1473     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1474     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1475     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBB\xB4\x9A\x8A\xB0\xCA\xAF\xBC' .
1476     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1477     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1478     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xBA\xAE\x59' .
1479     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1480     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1481
1482 my $cp_bc = # EBCDIC code page POSiX-BC
1483     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1484     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1485     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1486     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1487     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1488     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBB\xBC\xBD\x6A\x6D' .
1489     '\x4A\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1490     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xFB\x4F\xFD\xFF\x07' .
1491     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1492     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\x5F' .
1493     '\x41\xAA\xB0\xB1\x9F\xB2\xD0\xB5\x79\xB4\x9A\x8A\xBA\xCA\xAF\xA1' .
1494     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1495     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1496     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xE0\xFE\xDD\xFC\xAD\xAE\x59' .
1497     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1498     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xC0\xDE\xDB\xDC\x8D\x8E\xDF';
1499
1500 my $straight =  # Avoid ranges
1501     '\x00\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0A\x0B\x0C\x0D\x0E\x0F' .
1502     '\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1A\x1B\x1C\x1D\x1E\x1F' .
1503     '\x20\x21\x22\x23\x24\x25\x26\x27\x28\x29\x2A\x2B\x2C\x2D\x2E\x2F' .
1504     '\x30\x31\x32\x33\x34\x35\x36\x37\x38\x39\x3A\x3B\x3C\x3D\x3E\x3F' .
1505     '\x40\x41\x42\x43\x44\x45\x46\x47\x48\x49\x4A\x4B\x4C\x4D\x4E\x4F' .
1506     '\x50\x51\x52\x53\x54\x55\x56\x57\x58\x59\x5A\x5B\x5C\x5D\x5E\x5F' .
1507     '\x60\x61\x62\x63\x64\x65\x66\x67\x68\x69\x6A\x6B\x6C\x6D\x6E\x6F' .
1508     '\x70\x71\x72\x73\x74\x75\x76\x77\x78\x79\x7A\x7B\x7C\x7D\x7E\x7F' .
1509     '\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8A\x8B\x8C\x8D\x8E\x8F' .
1510     '\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9A\x9B\x9C\x9D\x9E\x9F' .
1511     '\xA0\xA1\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xAA\xAB\xAC\xAD\xAE\xAF' .
1512     '\xB0\xB1\xB2\xB3\xB4\xB5\xB6\xB7\xB8\xB9\xBA\xBB\xBC\xBD\xBE\xBF' .
1513     '\xC0\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xCA\xCB\xCC\xCD\xCE\xCF' .
1514     '\xD0\xD1\xD2\xD3\xD4\xD5\xD6\xD7\xD8\xD9\xDA\xDB\xDC\xDD\xDE\xDF' .
1515     '\xE0\xE1\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xEA\xEB\xEC\xED\xEE\xEF' .
1516     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\xFA\xFB\xFC\xFD\xFE\xFF';
1517
1518 # The following 2 functions allow tests to work on both EBCDIC and
1519 # ASCII-ish platforms.  They convert string scalars between the native
1520 # character set and the set of 256 characters which is usually called
1521 # Latin1.
1522 #
1523 # These routines don't work on UTF-EBCDIC and UTF-8.
1524
1525 sub native_to_latin1($) {
1526     my $string = shift;
1527
1528     return $string if ord('^') == 94;   # ASCII, Latin1
1529     my $cp;
1530     if (ord('^') == 95) {    # EBCDIC 1047
1531         $cp = \$cp_1047;
1532     }
1533     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1534         $cp = \$cp_bc;
1535     }
1536     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1537         $cp = \$cp_0037;
1538     }
1539     else {
1540         die "Unknown native character set";
1541     }
1542
1543     eval '$string =~ tr/' . $$cp . '/' . $straight . '/';
1544     return $string;
1545 }
1546
1547 sub latin1_to_native($) {
1548     my $string = shift;
1549
1550     return $string if ord('^') == 94;   # ASCII, Latin1
1551     my $cp;
1552     if (ord('^') == 95) {    # EBCDIC 1047
1553         $cp = \$cp_1047;
1554     }
1555     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1556         $cp = \$cp_bc;
1557     }
1558     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1559         $cp = \$cp_0037;
1560     }
1561     else {
1562         die "Unknown native character set";
1563     }
1564
1565     eval '$string =~ tr/' . $straight . '/' . $$cp . '/';
1566     return $string;
1567 }
1568
1569 sub ord_latin1_to_native {
1570     # given an input code point, return the platform's native
1571     # equivalent value.  Anything above latin1 is itself.
1572
1573     my $ord = shift;
1574     return $ord if $ord > 255;
1575     return ord latin1_to_native(chr $ord);
1576 }
1577
1578 sub ord_native_to_latin1 {
1579     # given an input platform code point, return the latin1 equivalent value.
1580     # Anything above latin1 is itself.
1581
1582     my $ord = shift;
1583     return $ord if $ord > 255;
1584     return ord native_to_latin1(chr $ord);
1585 }
1586
1587 1;