utils/perlbug.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6 use File::Spec::Functions;
   7
   8 # List explicitly here the variables you want Configure to
   9 # generate.  Metaconfig only looks for shell variables, so you
  10 # have to mention them as if they were shell variables, not
  11 # %Config entries.  Thus you write
  12 #  $startperl
  13 # to ensure Configure will look for $Config{startperl}.
  14 #  $perlpath
  15
  16 # This forces PL files to create target in same directory as PL file.
  17 # This is so that make depend always knows where to find PL derivatives.
  18 $origdir = cwd;
  19 chdir dirname($0);
  20 $file = basename($0, '.PL');
  21 $file .= '.com' if $^O eq 'VMS';
  22
  23 open OUT, ">$file" or die "Can't create $file: $!";
  24
  25 # get patchlevel.h timestamp
  26
  27 -e catfile(updir, "patchlevel.h")
  28     or die "Can't find patchlevel.h: $!";
  29
  30 my $patchlevel_date = (stat _)[9];
  31
  32 # TO DO (perhaps): store/embed $Config::config_sh into perlbug. When perlbug is
  33 # used, compare $Config::config_sh with the stored version. If they differ then
  34 # append a list of individual differences to the bug report.
  35
  36
  37 print "Extracting $file (with variable substitutions)\n";
  38
  39 # In this section, perl variables will be expanded during extraction.
  40 # You can use $Config{...} to use Configure variables.
  41
  42 my $extract_version = sprintf("%vd", $^V);
  43
  44 print OUT <<"!GROK!THIS!";
  45 $Config{startperl}
  46     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  47         if \$running_under_some_shell;
  48
  49 my \$config_tag1 = '$extract_version - $Config{cf_time}';
  50
  51 my \$patchlevel_date = $patchlevel_date;
  52 !GROK!THIS!
  53
  54 # In the following, perl variables are not expanded during extraction.
  55
  56 print OUT <<'!NO!SUBS!';
  57 my @patches = Config::local_patches();
  58 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
  59
  60 use warnings;
  61 use strict;
  62 use Config;
  63 use File::Spec;         # keep perlbug Perl 5.005 compatible
  64 use Getopt::Std;
  65 use File::Basename 'basename';
  66
  67 sub paraprint;
  68
  69 BEGIN {
  70     eval { require Mail::Send;};
  71     $::HaveSend = ($@ eq "");
  72     eval { require Mail::Util; } ;
  73     $::HaveUtil = ($@ eq "");
  74     # use secure tempfiles wherever possible
  75     eval { require File::Temp; };
  76     $::HaveTemp = ($@ eq "");
  77     eval { require Module::CoreList; };
  78     $::HaveCoreList = ($@ eq "");
  79 };
  80
  81 my $Version = "1.40";
  82
  83 #TODO:
  84 #       make sure failure (transmission-wise) of Mail::Send is accounted for.
  85 #       (This may work now. Unsure of the original author's issue -JESSE 2008-06-08)
  86 #       - Test -b option
  87
  88 my( $file, $usefile, $cc, $address, $bugaddress, $testaddress, $thanksaddress,
  89     $filename, $messageid, $domain, $subject, $from, $verbose, $ed, $outfile,
  90     $fh, $me, $body, $andcc, %REP, $ok, $thanks, $progname,
  91     $Is_MSWin32, $Is_Linux, $Is_VMS, $Is_OpenBSD,
  92     $report_about_module, $category, $severity,
  93     %opt, $have_attachment, $attachments, $has_patch, $mime_boundary
  94 );
  95
  96 my $perl_version = $^V ? sprintf("%vd", $^V) : $];
  97
  98 my $config_tag2 = "$perl_version - $Config{cf_time}";
  99
 100 Init();
 101
 102 if ($opt{h}) { Help(); exit; }
 103 if ($opt{d}) { Dump(*STDOUT); exit; }
 104 if (!-t STDIN && !$opt{t} && !($ok and not $opt{n})) {
 105     paraprint <<"EOF";
 106 Please use $progname interactively. If you want to
 107 include a file, you can use the -f switch.
 108 EOF
 109     die "\n";
 110 }
 111
 112 Query();
 113 Edit() unless $usefile || ($ok and not $opt{n});
 114 NowWhat();
 115 if ($outfile) {
 116     save_message_to_disk($outfile);
 117 } else {
 118     Send();
 119     if ($thanks) {
 120         print "\nThank you for taking the time to send a thank-you message!\n\n";
 121
 122         paraprint <<EOF
 123 Please note that mailing lists are moderated, your message may take a while to
 124 show up.
 125 EOF
 126     } else {
 127         print "\nThank you for taking the time to file a bug report!\n\n";
 128
 129         paraprint <<EOF
 130 Please note that mailing lists are moderated, your message may take a while to
 131 show up. If you do not receive an automated response acknowledging your message
 132 within a few hours (check your SPAM folder and outgoing mail) please consider
 133 sending an email directly from your mail client to perlbug\@perl.org.
 134 EOF
 135     }
 136
 137 }
 138
 139 exit;
 140
 141 sub ask_for_alternatives { # (category|severity)
 142     my $name = shift;
 143     my %alts = (
 144         'category' => {
 145             'default' => 'core',
 146             'ok'      => 'install',
 147             # Inevitably some of these will end up in RT whatever we do:
 148             'thanks'  => 'thanks',
 149             'opts'    => [qw(core docs install library utilities)], # patch, notabug
 150         },
 151         'severity' => {
 152             'default' => 'low',
 153             'ok'      => 'none',
 154             'thanks'  => 'none',
 155             'opts'    => [qw(critical high medium low wishlist none)], # zero
 156         },
 157     );
 158     die "Invalid alternative ($name) requested\n" unless grep(/^$name$/, keys %alts);
 159     my $alt = "";
 160     my $what = $ok || $thanks;
 161     if ($what) {
 162         $alt = $alts{$name}{$what};
 163     } else {
 164         my @alts = @{$alts{$name}{'opts'}};
 165     print "\n\n";
 166         paraprint <<EOF;
 167 Please pick a $name from the following list:
 168
 169     @alts
 170 EOF
 171         my $err = 0;
 172         do {
 173             if ($err++ > 5) {
 174                 die "Invalid $name: aborting.\n";
 175             }
 176         $alt = _prompt('', "\u$name", $alts{$name}{'default'});
 177                 $alt ||= $alts{$name}{'default'};
 178         } while !((($alt) = grep(/^$alt/i, @alts)));
 179     }
 180     lc $alt;
 181 }
 182
 183 sub Init {
 184     # -------- Setup --------
 185
 186     $Is_MSWin32 = $^O eq 'MSWin32';
 187     $Is_VMS = $^O eq 'VMS';
 188     $Is_Linux = lc($^O) eq 'linux';
 189     $Is_OpenBSD = lc($^O) eq 'openbsd';
 190
 191     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:T:p:", \%opt)) { Help(); exit; };
 192
 193     # This comment is needed to notify metaconfig that we are
 194     # using the $perladmin, $cf_by, and $cf_time definitions.
 195
 196     # -------- Configuration ---------
 197
 198     # perlbug address
 199     $bugaddress = 'perlbug@perl.org';
 200
 201     # Test address
 202     $testaddress = 'perlbug-test@perl.org';
 203
 204     # Thanks address
 205     $thanksaddress = 'perl-thanks@perl.org';
 206
 207     if (basename ($0) =~ /^perlthanks/i) {
 208         # invoked as perlthanks
 209         $opt{T} = 1;
 210         $opt{C} = 1; # don't send a copy to the local admin
 211     }
 212
 213     if ($opt{T}) {
 214         $thanks = 'thanks';
 215     }
 216
 217     $progname = $thanks ? 'perlthanks' : 'perlbug';
 218     # Target address
 219     $address = $opt{a} || ($opt{t} ? $testaddress
 220                             : $thanks ? $thanksaddress : $bugaddress);
 221
 222     # Users address, used in message and in From and Reply-To headers
 223     $from = $opt{r} || "";
 224
 225     # Include verbose configuration information
 226     $verbose = $opt{v} || 0;
 227
 228     # Subject of bug-report message
 229     $subject = $opt{s} || "";
 230
 231     # Send a file
 232     $usefile = ($opt{f} || 0);
 233
 234     # File to send as report
 235     $file = $opt{f} || "";
 236
 237     # We have one or more attachments
 238     $have_attachment = ($opt{p} || 0);
 239     $mime_boundary = ('-' x 12) . "$Version.perlbug" if $have_attachment;
 240
 241     # Comma-separated list of attachments
 242     $attachments = $opt{p} || "";
 243     $has_patch = 0; # TBD based on file type
 244
 245     for my $attachment (split /\s*,\s*/, $attachments) {
 246         unless (-f $attachment && -r $attachment) {
 247             die "The attachment $attachment is not a readable file: $!\n";
 248         }
 249         $has_patch = 1 if $attachment =~ m/\.(patch|diff)$/;
 250     }
 251
 252     # File to output to
 253     $outfile = $opt{F} || "";
 254
 255     # Body of report
 256     $body = $opt{b} || "";
 257
 258     # Editor
 259     $ed = $opt{e} || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
 260         || ($Is_VMS && "edit/tpu")
 261         || ($Is_MSWin32 && "notepad")
 262         || "vi";
 263
 264     # Not OK - provide build failure template by finessing OK report
 265     if ($opt{n}) {
 266         if (substr($opt{n}, 0, 2) eq 'ok' )     {
 267             $opt{o} = substr($opt{n}, 1);
 268         } else {
 269             Help();
 270             exit();
 271         }
 272     }
 273
 274     # OK - send "OK" report for build on this system
 275     $ok = '';
 276     if ($opt{o}) {
 277         if ($opt{o} eq 'k' or $opt{o} eq 'kay') {
 278             my $age = time - $patchlevel_date;
 279             if ($opt{o} eq 'k' and $age > 60 * 24 * 60 * 60 ) {
 280                 my $date = localtime $patchlevel_date;
 281                 print <<"EOF";
 282 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
 283 are more than 60 days old.  This Perl version was constructed on
 284 $date.  If you really want to report this, use
 285 "perlbug -okay" or "perlbug -nokay".
 286 EOF
 287                 exit();
 288             }
 289             # force these options
 290             unless ($opt{n}) {
 291                 $opt{S} = 1; # don't prompt for send
 292                 $opt{b} = 1; # we have a body
 293                 $body = "Perl reported to build OK on this system.\n";
 294             }
 295             $opt{C} = 1; # don't send a copy to the local admin
 296             $opt{s} = 1; # we have a subject line
 297             $subject = ($opt{n} ? 'Not ' : '')
 298                     . "OK: perl $perl_version ${patch_tags}on"
 299                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
 300             $ok = 'ok';
 301         } else {
 302             Help();
 303             exit();
 304         }
 305     }
 306
 307     # Possible administrator addresses, in order of confidence
 308     # (Note that cf_email is not mentioned to metaconfig, since
 309     # we don't really want it. We'll just take it if we have to.)
 310     #
 311     # This has to be after the $ok stuff above because of the way
 312     # that $opt{C} is forced.
 313     $cc = $opt{C} ? "" : (
 314         $opt{c} || $::Config{'perladmin'}
 315         || $::Config{'cf_email'} || $::Config{'cf_by'}
 316     );
 317
 318     if ($::HaveUtil) {
 319                 $domain = Mail::Util::maildomain();
 320     } elsif ($Is_MSWin32) {
 321                 $domain = $ENV{'USERDOMAIN'};
 322     } else {
 323                 require Sys::Hostname;
 324                 $domain = Sys::Hostname::hostname();
 325     }
 326
 327     # Message-Id - rjsf
 328     $messageid = "<$::Config{'version'}_${$}_".time."\@$domain>";
 329
 330     # My username
 331     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
 332             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
 333             : eval { getpwuid($<) };    # May be missing
 334
 335     $from = $::Config{'cf_email'}
 336        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
 337                ($me eq $::Config{'cf_by'});
 338 } # sub Init
 339
 340 sub Query {
 341     # Explain what perlbug is
 342     unless ($ok) {
 343         if ($thanks) {
 344             paraprint <<'EOF';
 345 This program provides an easy way to send a thank-you message back to the
 346 authors and maintainers of perl.
 347
 348 If you wish to submit a bug report, please run it without the -T flag
 349 (or run the program perlbug rather than perlthanks)
 350 EOF
 351         } else {
 352             paraprint <<"EOF";
 353 This program provides an easy way to create a message reporting a
 354 bug in the core perl distribution (along with tests or patches)
 355 to the volunteers who maintain perl at $address.  To send a thank-you
 356 note to $thanksaddress instead of a bug report, please run 'perlthanks'.
 357
 358 Please do not use $0 to send test messages, test whether perl
 359 works, or to report bugs in perl modules from CPAN.
 360
 361 Suggestions for how to find help using Perl can be found at
 362 http://perldoc.perl.org/perlcommunity.html
 363 EOF
 364         }
 365     }
 366
 367     # Prompt for subject of message, if needed
 368
 369     if ($subject && TrivialSubject($subject)) {
 370         $subject = '';
 371     }
 372
 373     unless ($subject) {
 374             print
 375 "First of all, please provide a subject for the message.\n";
 376         if ( not $thanks)  {
 377             paraprint <<EOF;
 378 This should be a concise description of your bug or problem
 379 which will help the volunteers working to improve perl to categorize
 380 and resolve the issue.  Be as specific and descriptive as
 381 you can. A subject like "perl bug" or "perl problem" will make it
 382 much less likely that your issue gets the attention it deserves.
 383 EOF
 384         }
 385
 386         my $err = 0;
 387         do {
 388         $subject = _prompt('','Subject');
 389             if ($err++ == 5) {
 390                 if ($thanks) {
 391                     $subject = 'Thanks for Perl';
 392                 } else {
 393                     die "Aborting.\n";
 394                 }
 395             }
 396         } while (TrivialSubject($subject));
 397     }
 398     $subject = '[PATCH] ' . $subject
 399         if $has_patch && ($subject !~ m/^\[PATCH/i);
 400
 401     # Prompt for return address, if needed
 402     unless ($opt{r}) {
 403         # Try and guess return address
 404         my $guess;
 405
 406         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || $ENV{'EMAIL'}
 407             || $from || '';
 408
 409         unless ($guess) {
 410                 # move $domain to where we can use it elsewhere
 411         if ($domain) {
 412                 if ($Is_VMS && !$::Config{'d_socket'}) {
 413                     $guess = "$domain\:\:$me";
 414                 } else {
 415                     $guess = "$me\@$domain" if $domain;
 416                 }
 417             }
 418         }
 419
 420         if ($guess) {
 421             unless ($ok) {
 422                 paraprint <<EOF;
 423 Perl's developers may need your email address to contact you for
 424 further information about your issue or to inform you when it is
 425 resolved.  If the default shown is not your email address, please
 426 correct it.
 427 EOF
 428             }
 429         } else {
 430             paraprint <<EOF;
 431 Please enter your full internet email address so that Perl's
 432 developers can contact you with questions about your issue or to
 433 inform you that it has been resolved.
 434 EOF
 435         }
 436
 437         if ($ok && $guess) {
 438             # use it
 439             $from = $guess;
 440         } else {
 441             # verify it
 442         $from = _prompt('','Your address',$guess);
 443             $from = $guess if $from eq '';
 444         }
 445     }
 446
 447     if ($from eq $cc or $me eq $cc) {
 448         # Try not to copy ourselves
 449         $cc = "yourself";
 450     }
 451
 452     # Prompt for administrator address, unless an override was given
 453     if( !$opt{C} and !$opt{c} ) {
 454         my $description =  <<EOF;
 455 $0 can send a copy of this report to your local perl
 456 administrator.  If the address below is wrong, please correct it,
 457 or enter 'none' or 'yourself' to not send a copy.
 458 EOF
 459         my $entry = _prompt($description, "Local perl administrator", $cc);
 460
 461         if ($entry ne "") {
 462             $cc = $entry;
 463             $cc = '' if $me eq $cc;
 464         }
 465     }
 466
 467     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
 468     if ($cc) {
 469         $andcc = " and $cc"
 470     } else {
 471         $andcc = ''
 472     }
 473
 474     # Prompt for editor, if no override is given
 475 editor:
 476     unless ($opt{e} || $opt{f} || $opt{b}) {
 477
 478     my $description;
 479
 480         chomp (my $common_end = <<"EOF");
 481 You will probably want to use a text editor to enter the body of
 482 your report. If "$ed" is the editor you want to use, then just press
 483 Enter, otherwise type in the name of the editor you would like to
 484 use.
 485
 486 If you have already composed the body of your report, you may enter
 487 "file", and $0 will prompt you to enter the name of the file
 488 containing your report.
 489 EOF
 490
 491         if ($thanks) {
 492             $description = <<"EOF";
 493 It's now time to compose your thank-you message.
 494
 495 Some information about your local perl configuration will automatically
 496 be included at the end of your message, because we're curious about
 497 the different ways that people build and use perl. If you'd rather
 498 not share this information, you're welcome to delete it.
 499
 500 $common_end
 501 EOF
 502         } else {
 503             $description =  <<"EOF";
 504 It's now time to compose your bug report. Try to make the report
 505 concise but descriptive. Please include any detail which you think
 506 might be relevant or might help the volunteers working to improve
 507 perl. If you are reporting something that does not work as you think
 508 it should, please try to include examples of the actual result and of
 509 what you expected.
 510
 511 Some information about your local perl configuration will automatically
 512 be included at the end of your report. If you are using an unusual
 513 version of perl, it would be useful if you could confirm that you
 514 can replicate the problem on a standard build of perl as well.
 515
 516 $common_end
 517 EOF
 518         }
 519
 520     my $entry = _prompt($description, "Editor", $ed);
 521         $usefile = 0;
 522         if ($entry eq "file") {
 523             $usefile = 1;
 524         } elsif ($entry ne "") {
 525             $ed = $entry;
 526         }
 527     }
 528     if ($::HaveCoreList && !$ok && !$thanks) {
 529         my $description =  <<EOF;
 530 If your bug is about a Perl module rather than a core language
 531 feature, please enter its name here. If it's not, just hit Enter
 532 to skip this question.
 533 EOF
 534
 535     my $entry = '';
 536         while ($entry eq '') {
 537         $entry = _prompt($description, 'Module');
 538             my $first_release = Module::CoreList->first_release($entry);
 539             if ($entry and not $first_release) {
 540                 paraprint <<EOF;
 541 $entry is not a "core" Perl module. Please check that you entered
 542 its name correctly. If it is correct, quit this program, try searching
 543 for $entry on http://rt.cpan.org, and report your issue there.
 544 EOF
 545
 546             $entry = '';
 547         } elsif (my $bug_tracker = $Module::CoreList::bug_tracker{$entry}) {
 548                 paraprint <<"EOF";
 549 $entry included with core Perl is copied directly from the CPAN distribution.
 550 Please report bugs in $entry directly to its maintainers using $bug_tracker
 551 EOF
 552             $entry = '';
 553         } elsif ($entry) {
 554                 $category ||= 'library';
 555                 $report_about_module = $entry;
 556             last;
 557         } else {
 558             last;
 559         }
 560         }
 561     }
 562
 563     # Prompt for category of bug
 564     $category ||= ask_for_alternatives('category');
 565
 566     # Prompt for severity of bug
 567     $severity ||= ask_for_alternatives('severity');
 568
 569     # Generate scratch file to edit report in
 570     $filename = filename();
 571
 572     # Prompt for file to read report from, if needed
 573     if ($usefile and !$file) {
 574 filename:
 575         my $description = <<EOF;
 576 What is the name of the file that contains your report?
 577 EOF
 578         my $entry = _prompt($description, "Filename");
 579
 580         if ($entry eq "") {
 581             paraprint <<EOF;
 582 It seems you didn't enter a filename. Please choose to use a text
 583 editor or enter a filename.
 584 EOF
 585             goto editor;
 586         }
 587
 588         unless (-f $entry and -r $entry) {
 589             paraprint <<EOF;
 590 '$entry' doesn't seem to be a readable file.  You may have mistyped
 591 its name or may not have permission to read it.
 592
 593 If you don't want to use a file as the content of your report, just
 594 hit Enter and you'll be able to select a text editor instead.
 595 EOF
 596             goto filename;
 597         }
 598         $file = $entry;
 599     }
 600
 601     # Generate report
 602     open(REP, '>:raw', $filename) or die "Unable to create report file '$filename': $!\n";
 603     binmode(REP, ':raw :crlf') if $Is_MSWin32;
 604
 605     my $reptype = !$ok ? ($thanks ? 'thank-you' : 'bug')
 606         : $opt{n} ? "build failure" : "success";
 607
 608     print REP <<EOF;
 609 This is a $reptype report for perl from $from,
 610 generated with the help of perlbug $Version running under perl $perl_version.
 611
 612 EOF
 613
 614     if ($body) {
 615         print REP $body;
 616     } elsif ($usefile) {
 617         open(F, '<:raw', $file)
 618                 or die "Unable to read report file from '$file': $!\n";
 619         binmode(F, ':raw :crlf') if $Is_MSWin32;
 620         while (<F>) {
 621             print REP $_
 622         }
 623         close(F) or die "Error closing '$file': $!";
 624     } else {
 625         if ($thanks) {
 626             print REP <<'EOF';
 627
 628 -----------------------------------------------------------------
 629 [Please enter your thank-you message here]
 630
 631
 632
 633 [You're welcome to delete anything below this line]
 634 -----------------------------------------------------------------
 635 EOF
 636         } else {
 637             print REP <<'EOF';
 638
 639 -----------------------------------------------------------------
 640 [Please describe your issue here]
 641
 642
 643
 644 [Please do not change anything below this line]
 645 -----------------------------------------------------------------
 646 EOF
 647         }
 648     }
 649     Dump(*REP);
 650     close(REP) or die "Error closing report file: $!";
 651
 652     # Set up an initial report fingerprint so we can compare it later
 653     _fingerprint_lines_in_report();
 654
 655 } # sub Query
 656
 657 sub Dump {
 658     local(*OUT) = @_;
 659
 660     # these won't have been set if run with -d
 661     $category ||= 'core';
 662     $severity ||= 'low';
 663
 664     print OUT <<EFF;
 665 ---
 666 Flags:
 667     category=$category
 668     severity=$severity
 669 EFF
 670
 671     if ($has_patch) {
 672         print OUT <<EFF;
 673     Type=Patch
 674     PatchStatus=HasPatch
 675 EFF
 676     }
 677
 678     if ($report_about_module ) {
 679         print OUT <<EFF;
 680     module=$report_about_module
 681 EFF
 682     }
 683     if ($opt{A}) {
 684         print OUT <<EFF;
 685     ack=no
 686 EFF
 687     }
 688     print OUT <<EFF;
 689 ---
 690 EFF
 691     print OUT "This perlbug was built using Perl $config_tag1\n",
 692             "It is being executed now by  Perl $config_tag2.\n\n"
 693         if $config_tag2 ne $config_tag1;
 694
 695     print OUT <<EOF;
 696 Site configuration information for perl $perl_version:
 697
 698 EOF
 699     if ($::Config{cf_by} and $::Config{cf_time}) {
 700         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
 701     }
 702     print OUT Config::myconfig;
 703
 704     if (@patches) {
 705         print OUT join "\n    ", "Locally applied patches:", @patches;
 706         print OUT "\n";
 707     };
 708
 709     print OUT <<EOF;
 710
 711 ---
 712 \@INC for perl $perl_version:
 713 EOF
 714     for my $i (@INC) {
 715         print OUT "    $i\n";
 716     }
 717
 718     print OUT <<EOF;
 719
 720 ---
 721 Environment for perl $perl_version:
 722 EOF
 723     my @env =
 724         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
 725     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
 726     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
 727     my %env;
 728     @env{@env} = @env;
 729     for my $env (sort keys %env) {
 730         print OUT "    $env",
 731                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
 732                 "\n";
 733     }
 734     if ($verbose) {
 735         print OUT "\nComplete configuration data for perl $perl_version:\n\n";
 736         my $value;
 737         foreach (sort keys %::Config) {
 738             $value = $::Config{$_};
 739             $value = '' unless defined $value;
 740             $value =~ s/'/\\'/g;
 741             print OUT "$_='$value'\n";
 742         }
 743     }
 744 } # sub Dump
 745
 746 sub Edit {
 747     # Edit the report
 748     if ($usefile || $body) {
 749         my $description = "Please make sure that the name of the editor you want to use is correct.";
 750         my $entry = _prompt($description, 'Editor', $ed);
 751         $ed = $entry unless $entry eq '';
 752     }
 753
 754     _edit_file($ed);
 755 }
 756
 757 sub _edit_file {
 758     my $editor = shift;
 759
 760     my $report_written = 0;
 761
 762     while ( !$report_written ) {
 763         my $exit_status = system("$editor $filename");
 764         if ($exit_status) {
 765             my $desc = <<EOF;
 766 The editor you chose ('$editor') could not be run!
 767
 768 If you mistyped its name, please enter it now, otherwise just press Enter.
 769 EOF
 770             my $entry = _prompt( $desc, 'Editor', $editor );
 771             if ( $entry ne "" ) {
 772                 $editor = $entry;
 773                 next;
 774             } else {
 775                 paraprint <<EOF;
 776 You may want to save your report to a file, so you can edit and
 777 mail it later.
 778 EOF
 779                 return;
 780             }
 781         }
 782         return if ( $ok and not $opt{n} ) || $body;
 783
 784         # Check that we have a report that has some, eh, report in it.
 785
 786         unless ( _fingerprint_lines_in_report() ) {
 787             my $description = <<EOF;
 788 It looks like you didn't enter a report. You may [r]etry your edit
 789 or [c]ancel this report.
 790 EOF
 791             my $action = _prompt( $description, "Action (Retry/Cancel) " );
 792             if ( $action =~ /^[re]/i ) {    # <R>etry <E>dit
 793                 next;
 794             } elsif ( $action =~ /^[cq]/i ) {    # <C>ancel, <Q>uit
 795                 Cancel();                        # cancel exits
 796             }
 797         }
 798         # Ok. the user did what they needed to;
 799         return;
 800
 801     }
 802 }
 803
 804
 805 sub Cancel {
 806     1 while unlink($filename);  # remove all versions under VMS
 807     print "\nQuitting without sending your message.\n";
 808     exit(0);
 809 }
 810
 811 sub NowWhat {
 812     # Report is done, prompt for further action
 813     if( !$opt{S} ) {
 814         while(1) {
 815             my $menu = <<EOF;
 816
 817
 818 You have finished composing your message. At this point, you have
 819 a few options. You can:
 820
 821     * [Se]nd the message to $address$andcc,
 822     * [D]isplay the message on the screen,
 823     * [R]e-edit the message
 824     * Display or change the message's [su]bject
 825     * Save the message to a [f]ile to mail at another time
 826     * [Q]uit without sending a message
 827
 828 EOF
 829       retry:
 830         print $menu;
 831             my $action =  _prompt('', "Action (Send/Display/Edit/Subject/Save to File)",
 832                 $opt{t} ? 'q' : '');
 833         print "\n";
 834             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
 835             if ( SaveMessage() ) { exit }
 836             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
 837                 # Display the message
 838                 print _read_report($filename);
 839                 if ($have_attachment) {
 840                     print "\n\n---\nAttachment(s):\n";
 841                     for my $att (split /\s*,\s*/, $attachments) { print "    $att\n"; }
 842                 }
 843             } elsif ($action =~ /^su/i) { # <Su>bject
 844                 my $reply = _prompt( "Subject: $subject", "If the above subject is fine, press Enter. Otherwise, type a replacement now\nSubject");
 845                 if ($reply ne '') {
 846                     unless (TrivialSubject($reply)) {
 847                         $subject = $reply;
 848                         print "Subject: $subject\n";
 849                     }
 850                 }
 851             } elsif ($action =~ /^se/i) { # <S>end
 852                 # Send the message
 853                 my $reply =  _prompt( "Are you certain you want to send this message?", 'Please type "yes" if you are','no');
 854                 if ($reply =~ /^yes$/) {
 855                     last;
 856                 } else {
 857                     paraprint <<EOF;
 858 You didn't type "yes", so your message has not yet been sent.
 859 EOF
 860                 }
 861             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
 862                 # edit the message
 863                 Edit();
 864             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
 865                 Cancel();
 866             } elsif ($action =~ /^s/i) {
 867                 paraprint <<EOF;
 868 The command you entered was ambiguous. Please type "send", "save" or "subject".
 869 EOF
 870             }
 871         }
 872     }
 873 } # sub NowWhat
 874
 875 sub TrivialSubject {
 876     my $subject = shift;
 877     if ($subject =~
 878         /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
 879         length($subject) < 4 ||
 880         ($subject !~ /\s/ && ! $opt{t})) { # non-whitespace is accepted in test mode
 881         print "\nThe subject you entered wasn't very descriptive. Please try again.\n\n";
 882         return 1;
 883     } else {
 884         return 0;
 885     }
 886 }
 887
 888 sub SaveMessage {
 889     my $file_save = $outfile || "$progname.rep";
 890     my $file = _prompt( '', "Name of file to save message in", $file_save );
 891     save_message_to_disk($file) || return undef;
 892     print "\n";
 893     paraprint <<EOF;
 894 A copy of your message has been saved in '$file' for you to
 895 send to '$address' with your normal mail client.
 896 EOF
 897 }
 898
 899 sub Send {
 900
 901     # Message has been accepted for transmission -- Send the message
 902
 903     # on linux certain "mail" implementations won't accept the subject
 904     # as "~s subject" and thus the Subject header will be corrupted
 905     # so don't use Mail::Send to be safe
 906     eval {
 907         if ( $::HaveSend && !$Is_Linux && !$Is_OpenBSD ) {
 908             _send_message_mailsend();
 909         } elsif ($Is_VMS) {
 910             _send_message_vms();
 911         } else {
 912             _send_message_sendmail();
 913         }
 914     };
 915
 916     if ( my $error = $@ ) {
 917         paraprint <<EOF;
 918 $0 has detected an error while trying to send your message: $error.
 919
 920 Your message may not have been sent. You will now have a chance to save a copy to disk.
 921 EOF
 922         SaveMessage();
 923         return;
 924     }
 925
 926     1 while unlink($filename);    # remove all versions under VMS
 927 }    # sub Send
 928
 929 sub Help {
 930     print <<EOF;
 931
 932 This program is designed to help you generate and send bug reports
 933 (and thank-you notes) about perl5 and the modules which ship with it.
 934
 935 In most cases, you can just run "$0" interactively from a command
 936 line without any special arguments and follow the prompts.
 937
 938 Advanced usage:
 939
 940 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
 941     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
 942     [-p patchfile ]
 943 $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
 944
 945
 946 Options:
 947
 948   -v    Include Verbose configuration data in the report
 949   -f    File containing the body of the report. Use this to
 950         quickly send a prepared message.
 951   -p    File containing a patch or other text attachment. Separate
 952         multiple files with commas.
 953   -F    File to output the resulting mail message to, instead of mailing.
 954   -S    Send without asking for confirmation.
 955   -a    Address to send the report to. Defaults to '$address'.
 956   -c    Address to send copy of report to. Defaults to '$cc'.
 957   -C    Don't send copy to administrator.
 958   -s    Subject to include with the message. You will be prompted
 959         if you don't supply one on the command line.
 960   -b    Body of the report. If not included on the command line, or
 961         in a file with -f, you will get a chance to edit the message.
 962   -r    Your return address. The program will ask you to confirm
 963         this if you don't give it here.
 964   -e    Editor to use.
 965   -t    Test mode. The target address defaults to '$testaddress'.
 966   -T    Thank-you mode. The target address defaults to '$thanksaddress'.
 967   -d    Data mode.  This prints out your configuration data, without mailing
 968         anything. You can use this with -v to get more complete data.
 969   -A    Don't send a bug received acknowledgement to the return address.
 970   -ok   Report successful build on this system to perl porters
 971         (use alone or with -v). Only use -ok if *everything* was ok:
 972         if there were *any* problems at all, use -nok.
 973   -okay As -ok but allow report from old builds.
 974   -nok  Report unsuccessful build on this system to perl porters
 975         (use alone or with -v). You must describe what went wrong
 976         in the body of the report which you will be asked to edit.
 977   -nokay As -nok but allow report from old builds.
 978   -h    Print this help message.
 979
 980 EOF
 981 }
 982
 983 sub filename {
 984     if ($::HaveTemp) {
 985         # Good. Use a secure temp file
 986         my ($fh, $filename) = File::Temp::tempfile(UNLINK => 1);
 987         close($fh);
 988         return $filename;
 989     } else {
 990         # Bah. Fall back to doing things less securely.
 991         my $dir = File::Spec->tmpdir();
 992         $filename = "bugrep0$$";
 993         $filename++ while -e File::Spec->catfile($dir, $filename);
 994         $filename = File::Spec->catfile($dir, $filename);
 995     }
 996 }
 997
 998 sub paraprint {
 999     my @paragraphs = split /\n{2,}/, "@_";
1000     for (@paragraphs) {   # implicit local $_
1001         s/(\S)\s*\n/$1 /g;
1002         write;
1003         print "\n";
1004     }
1005 }
1006
1007 sub _prompt {
1008     my ($explanation, $prompt, $default) = (@_);
1009     if ($explanation) {
1010         print "\n\n";
1011         paraprint $explanation;
1012     }
1013     print $prompt. ($default ? " [$default]" :''). ": ";
1014         my $result = scalar(<>);
1015     return $default if !defined $result; # got eof
1016     chomp($result);
1017         $result =~ s/^\s*(.*?)\s*$/$1/s;
1018     if ($default && $result eq '') {
1019         return $default;
1020     } else {
1021         return $result;
1022     }
1023 }
1024
1025 sub _build_header {
1026     my %attr = (@_);
1027
1028     my $head = '';
1029     for my $header (keys %attr) {
1030         $head .= "$header: ".$attr{$header}."\n";
1031     }
1032     return $head;
1033 }
1034
1035 sub _message_headers {
1036     my %headers = ( To => $address, Subject => $subject );
1037     $headers{'Cc'}         = $cc        if ($cc);
1038     $headers{'Message-Id'} = $messageid if ($messageid);
1039     $headers{'Reply-To'}   = $from      if ($from);
1040     $headers{'From'}       = $from      if ($from);
1041     if ($have_attachment) {
1042         $headers{'MIME-Version'} = '1.0';
1043         $headers{'Content-Type'} = qq{multipart/mixed; boundary=\"$mime_boundary\"};
1044     }
1045     return \%headers;
1046 }
1047
1048 sub _add_body_start {
1049     my $body_start = <<"BODY_START";
1050 This is a multi-part message in MIME format.
1051 --$mime_boundary
1052 Content-Type: text/plain; format=fixed
1053 Content-Transfer-Encoding: 8bit
1054
1055 BODY_START
1056     return $body_start;
1057 }
1058
1059 sub _add_attachments {
1060     my $attach = '';
1061     for my $attachment (split /\s*,\s*/, $attachments) {
1062         my $attach_file = basename($attachment);
1063         $attach .= <<"ATTACHMENT";
1064
1065 --$mime_boundary
1066 Content-Type: text/x-patch; name="$attach_file"
1067 Content-Transfer-Encoding: 8bit
1068 Content-Disposition: attachment; filename="$attach_file"
1069
1070 ATTACHMENT
1071
1072         open my $attach_fh, '<:raw', $attachment
1073             or die "Couldn't open attachment '$attachment': $!\n";
1074         while (<$attach_fh>) { $attach .= $_; }
1075         close($attach_fh) or die "Error closing attachment '$attachment': $!";
1076     }
1077
1078     $attach .= "\n--$mime_boundary--\n";
1079     return $attach;
1080 }
1081
1082 sub _read_report {
1083     my $fname = shift;
1084     my $content;
1085     open( REP, "<:raw", $fname ) or die "Couldn't open file '$fname': $!\n";
1086     binmode(REP, ':raw :crlf') if $Is_MSWin32;
1087     while (<REP>) { $content .= $_; }
1088     close(REP) or die "Error closing report file '$fname': $!";
1089     return $content;
1090 }
1091
1092 sub build_complete_message {
1093     my $content = _build_header(%{_message_headers()}) . "\n\n";
1094     $content .= _add_body_start() if $have_attachment;
1095     $content .= _read_report($filename);
1096     $content .= _add_attachments() if $have_attachment;
1097     return $content;
1098 }
1099
1100 sub save_message_to_disk {
1101     my $file = shift;
1102
1103         open OUTFILE, '>:raw', $file or do { warn  "Couldn't open '$file': $!\n"; return undef};
1104         binmode(OUTFILE, ':raw :crlf') if $Is_MSWin32;
1105
1106         print OUTFILE build_complete_message();
1107         close(OUTFILE) or do { warn  "Error closing $file: $!"; return undef };
1108             print "\nMessage saved.\n";
1109         return 1;
1110 }
1111
1112 sub _send_message_vms {
1113
1114     my $mail_from  = $from;
1115     my $rcpt_to_to = $address;
1116     my $rcpt_to_cc = $cc;
1117
1118     map { $_ =~ s/^[^<]*<//;
1119           $_ =~ s/>[^>]*//; } ($mail_from, $rcpt_to_to, $rcpt_to_cc);
1120
1121     if ( open my $sff_fh, '|-:raw', 'MCR TCPIP$SYSTEM:TCPIP$SMTP_SFF.EXE SYS$INPUT:' ) {
1122         print $sff_fh "MAIL FROM:<$mail_from>\n";
1123         print $sff_fh "RCPT TO:<$rcpt_to_to>\n";
1124         print $sff_fh "RCPT TO:<$rcpt_to_cc>\n" if $rcpt_to_cc;
1125         print $sff_fh "DATA\n";
1126         print $sff_fh build_complete_message();
1127         my $success = close $sff_fh;
1128         if ($success ) {
1129             print "\nMessage sent\n";
1130             return;
1131         }
1132     }
1133     die "Mail transport failed (leaving bug report in $filename): $^E\n";
1134 }
1135
1136 sub _send_message_mailsend {
1137     my $msg = Mail::Send->new();
1138     my %headers = %{_message_headers()};
1139     for my $key ( keys %headers) {
1140         $msg->add($key => $headers{$key});
1141     }
1142
1143     $fh = $msg->open;
1144     binmode($fh, ':raw');
1145     print $fh _add_body_start() if $have_attachment;
1146     print $fh _read_report($filename);
1147     print $fh _add_attachments() if $have_attachment;
1148     $fh->close or die "Error sending mail: $!";
1149
1150     print "\nMessage sent.\n";
1151 }
1152
1153 sub _probe_for_sendmail {
1154     my $sendmail = "";
1155     for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
1156         $sendmail = $_, last if -e $_;
1157     }
1158     if ( $^O eq 'os2' and $sendmail eq "" ) {
1159         my $path = $ENV{PATH};
1160         $path =~ s:\\:/:;
1161         my @path = split /$Config{'path_sep'}/, $path;
1162         for (@path) {
1163             $sendmail = "$_/sendmail",     last if -e "$_/sendmail";
1164             $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
1165         }
1166     }
1167     return $sendmail;
1168 }
1169
1170 sub _send_message_sendmail {
1171     my $sendmail = _probe_for_sendmail();
1172     unless ($sendmail) {
1173         my $message_start = !$Is_Linux && !$Is_OpenBSD ? <<'EOT' : <<'EOT';
1174 It appears that there is no program which looks like "sendmail" on
1175 your system and that the Mail::Send library from CPAN isn't available.
1176 EOT
1177 It appears that there is no program which looks like "sendmail" on
1178 your system.
1179 EOT
1180         paraprint(<<"EOF"), die "\n";
1181 $message_start
1182 Because of this, there's no easy way to automatically send your
1183 message.
1184
1185 A copy of your message has been saved in '$filename' for you to
1186 send to '$address' with your normal mail client.
1187 EOF
1188     }
1189
1190     open( SENDMAIL, "|-:raw", $sendmail, "-t", "-oi", "-f", $from )
1191         || die "'|$sendmail -t -oi -f $from' failed: $!";
1192     print SENDMAIL build_complete_message();
1193     if ( close(SENDMAIL) ) {
1194         print "\nMessage sent\n";
1195     } else {
1196         warn "\nSendmail returned status '", $? >> 8, "'\n";
1197     }
1198 }
1199
1200
1201
1202 # a strange way to check whether any significant editing
1203 # has been done: check whether any new non-empty lines
1204 # have been added.
1205
1206 sub _fingerprint_lines_in_report {
1207     my $new_lines = 0;
1208     # read in the report template once so that
1209     # we can track whether the user does any editing.
1210     # yes, *all* whitespace is ignored.
1211
1212     open(REP, '<:raw', $filename) or die "Unable to open report file '$filename': $!\n";
1213     binmode(REP, ':raw :crlf') if $Is_MSWin32;
1214     while (my $line = <REP>) {
1215         $line =~ s/\s+//g;
1216         $new_lines++ if (!$REP{$line});
1217
1218     }
1219     close(REP) or die "Error closing report file '$filename': $!";
1220     # returns the number of lines with content that wasn't there when last we looked
1221     return $new_lines;
1222 }
1223
1224
1225
1226 format STDOUT =
1227 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
1228 $_
1229 .
1230
1231 __END__
1232
1233 =head1 NAME
1234
1235 perlbug - how to submit bug reports on Perl
1236
1237 =head1 SYNOPSIS
1238
1239 B<perlbug>
1240
1241 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
1242 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
1243 S<[ B<-r> I<returnaddress> ]>
1244 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
1245 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]> S<[ B<-T> ]>
1246
1247 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
1248  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
1249
1250 B<perlthanks>
1251
1252 =head1 DESCRIPTION
1253
1254
1255 This program is designed to help you generate and send bug reports
1256 (and thank-you notes) about perl5 and the modules which ship with it.
1257
1258 In most cases, you can just run it interactively from a command
1259 line without any special arguments and follow the prompts.
1260
1261 If you have found a bug with a non-standard port (one that was not
1262 part of the I<standard distribution>), a binary distribution, or a
1263 non-core module (such as Tk, DBI, etc), then please see the
1264 documentation that came with that distribution to determine the
1265 correct place to report bugs.
1266
1267 If you are unable to send your report using B<perlbug> (most likely
1268 because your system doesn't have a way to send mail that perlbug
1269 recognizes), you may be able to use this tool to compose your report
1270 and save it to a file which you can then send to B<perlbug@perl.org>
1271 using your regular mail client.
1272
1273 In extreme cases, B<perlbug> may not work well enough on your system
1274 to guide you through composing a bug report. In those cases, you
1275 may be able to use B<perlbug -d> to get system configuration
1276 information to include in a manually composed bug report to
1277 B<perlbug@perl.org>.
1278
1279
1280 When reporting a bug, please run through this checklist:
1281
1282 =over 4
1283
1284 =item What version of Perl you are running?
1285
1286 Type C<perl -v> at the command line to find out.
1287
1288 =item Are you running the latest released version of perl?
1289
1290 Look at http://www.perl.org/ to find out.  If you are not using the
1291 latest released version, please try to replicate your bug on the
1292 latest stable release.
1293
1294 Note that reports about bugs in old versions of Perl, especially
1295 those which indicate you haven't also tested the current stable
1296 release of Perl, are likely to receive less attention from the
1297 volunteers who build and maintain Perl than reports about bugs in
1298 the current release.
1299
1300 This tool isn't appropriate for reporting bugs in any version
1301 prior to Perl 5.0.
1302
1303 =item Are you sure what you have is a bug?
1304
1305 A significant number of the bug reports we get turn out to be
1306 documented features in Perl.  Make sure the issue you've run into
1307 isn't intentional by glancing through the documentation that comes
1308 with the Perl distribution.
1309
1310 Given the sheer volume of Perl documentation, this isn't a trivial
1311 undertaking, but if you can point to documentation that suggests
1312 the behaviour you're seeing is I<wrong>, your issue is likely to
1313 receive more attention. You may want to start with B<perldoc>
1314 L<perltrap> for pointers to common traps that new (and experienced)
1315 Perl programmers run into.
1316
1317 If you're unsure of the meaning of an error message you've run
1318 across, B<perldoc> L<perldiag> for an explanation.  If the message
1319 isn't in perldiag, it probably isn't generated by Perl.  You may
1320 have luck consulting your operating system documentation instead.
1321
1322 If you are on a non-UNIX platform B<perldoc> L<perlport>, as some
1323 features may be unimplemented or work differently.
1324
1325 You may be able to figure out what's going wrong using the Perl
1326 debugger.  For information about how to use the debugger B<perldoc>
1327 L<perldebug>.
1328
1329 =item Do you have a proper test case?
1330
1331 The easier it is to reproduce your bug, the more likely it will be
1332 fixed -- if nobody can duplicate your problem, it probably won't be
1333 addressed.
1334
1335 A good test case has most of these attributes: short, simple code;
1336 few dependencies on external commands, modules, or libraries; no
1337 platform-dependent code (unless it's a platform-specific bug);
1338 clear, simple documentation.
1339
1340 A good test case is almost always a good candidate to be included in
1341 Perl's test suite.  If you have the time, consider writing your test case so
1342 that it can be easily included into the standard test suite.
1343
1344 =item Have you included all relevant information?
1345
1346 Be sure to include the B<exact> error messages, if any.
1347 "Perl gave an error" is not an exact error message.
1348
1349 If you get a core dump (or equivalent), you may use a debugger
1350 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
1351 report.
1352
1353 NOTE: unless your Perl has been compiled with debug info
1354 (often B<-g>), the stack trace is likely to be somewhat hard to use
1355 because it will most probably contain only the function names and not
1356 their arguments.  If possible, recompile your Perl with debug info and
1357 reproduce the crash and the stack trace.
1358
1359 =item Can you describe the bug in plain English?
1360
1361 The easier it is to understand a reproducible bug, the more likely
1362 it will be fixed.  Any insight you can provide into the problem
1363 will help a great deal.  In other words, try to analyze the problem
1364 (to the extent you can) and report your discoveries.
1365
1366 =item Can you fix the bug yourself?
1367
1368 If so, that's great news; bug reports with patches are likely to
1369 receive significantly more attention and interest than those without
1370 patches.  Please attach your patch to the report using the C<-p> option.
1371 When sending a patch, create it using C<git format-patch> if possible,
1372 though a unified diff created with C<diff -pu> will do nearly as well.
1373
1374 Your patch may be returned with requests for changes, or requests for more
1375 detailed explanations about your fix.
1376
1377 Here are a few hints for creating high-quality patches:
1378
1379 Make sure the patch is not reversed (the first argument to diff is
1380 typically the original file, the second argument your changed file).
1381 Make sure you test your patch by applying it with C<git am> or the
1382 C<patch> program before you send it on its way.  Try to follow the
1383 same style as the code you are trying to patch.  Make sure your patch
1384 really does work (C<make test>, if the thing you're patching is covered
1385 by Perl's test suite).
1386
1387 =item Can you use C<perlbug> to submit the report?
1388
1389 B<perlbug> will, amongst other things, ensure your report includes
1390 crucial information about your version of perl.  If C<perlbug> is
1391 unable to mail your report after you have typed it in, you may have
1392 to compose the message yourself, add the output produced by C<perlbug
1393 -d> and email it to B<perlbug@perl.org>.  If, for some reason, you
1394 cannot run C<perlbug> at all on your system, be sure to include the
1395 entire output produced by running C<perl -V> (note the uppercase V).
1396
1397 Whether you use C<perlbug> or send the email manually, please make
1398 your Subject line informative.  "a bug" is not informative.  Neither
1399 is "perl crashes" nor is "HELP!!!".  These don't help.  A compact
1400 description of what's wrong is fine.
1401
1402 =item Can you use C<perlbug> to submit a thank-you note?
1403
1404 Yes, you can do this by either using the C<-T> option, or by invoking
1405 the program as C<perlthanks>. Thank-you notes are good. It makes people
1406 smile.
1407
1408 =back
1409
1410 Having done your bit, please be prepared to wait, to be told the
1411 bug is in your code, or possibly to get no reply at all.  The
1412 volunteers who maintain Perl are busy folks, so if your problem is
1413 an obvious bug in your own code, is difficult to understand or is
1414 a duplicate of an existing report, you may not receive a personal
1415 reply.
1416
1417 If it is important to you that your bug be fixed, do monitor the
1418 perl5-porters@perl.org mailing list (mailing lists are moderated, your
1419 message may take a while to show up) and the commit logs to development
1420 versions of Perl, and encourage the maintainers with kind words or
1421 offers of frosty beverages.  (Please do be kind to the maintainers.
1422 Harassing or flaming them is likely to have the opposite effect of the
1423 one you want.)
1424
1425 Feel free to update the ticket about your bug on http://rt.perl.org
1426 if a new version of Perl is released and your bug is still present.
1427
1428 =head1 OPTIONS
1429
1430 =over 8
1431
1432 =item B<-a>
1433
1434 Address to send the report to.  Defaults to B<perlbug@perl.org>.
1435
1436 =item B<-A>
1437
1438 Don't send a bug received acknowledgement to the reply address.
1439 Generally it is only a sensible to use this option if you are a
1440 perl maintainer actively watching perl porters for your message to
1441 arrive.
1442
1443 =item B<-b>
1444
1445 Body of the report.  If not included on the command line, or
1446 in a file with B<-f>, you will get a chance to edit the message.
1447
1448 =item B<-C>
1449
1450 Don't send copy to administrator.
1451
1452 =item B<-c>
1453
1454 Address to send copy of report to.  Defaults to the address of the
1455 local perl administrator (recorded when perl was built).
1456
1457 =item B<-d>
1458
1459 Data mode (the default if you redirect or pipe output).  This prints out
1460 your configuration data, without mailing anything.  You can use this
1461 with B<-v> to get more complete data.
1462
1463 =item B<-e>
1464
1465 Editor to use.
1466
1467 =item B<-f>
1468
1469 File containing the body of the report.  Use this to quickly send a
1470 prepared message.
1471
1472 =item B<-F>
1473
1474 File to output the results to instead of sending as an email. Useful
1475 particularly when running perlbug on a machine with no direct internet
1476 connection.
1477
1478 =item B<-h>
1479
1480 Prints a brief summary of the options.
1481
1482 =item B<-ok>
1483
1484 Report successful build on this system to perl porters. Forces B<-S>
1485 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1486 prompts for a return address if it cannot guess it (for use with
1487 B<make>). Honors return address specified with B<-r>.  You can use this
1488 with B<-v> to get more complete data.   Only makes a report if this
1489 system is less than 60 days old.
1490
1491 =item B<-okay>
1492
1493 As B<-ok> except it will report on older systems.
1494
1495 =item B<-nok>
1496
1497 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1498 supplies a value for B<-s>, then requires you to edit the report
1499 and say what went wrong.  Alternatively, a prepared report may be
1500 supplied using B<-f>.  Only prompts for a return address if it
1501 cannot guess it (for use with B<make>). Honors return address
1502 specified with B<-r>.  You can use this with B<-v> to get more
1503 complete data.  Only makes a report if this system is less than 60
1504 days old.
1505
1506 =item B<-nokay>
1507
1508 As B<-nok> except it will report on older systems.
1509
1510 =item B<-p>
1511
1512 The names of one or more patch files or other text attachments to be
1513 included with the report.  Multiple files must be separated with commas.
1514
1515 =item B<-r>
1516
1517 Your return address.  The program will ask you to confirm its default
1518 if you don't use this option.
1519
1520 =item B<-S>
1521
1522 Send without asking for confirmation.
1523
1524 =item B<-s>
1525
1526 Subject to include with the message.  You will be prompted if you don't
1527 supply one on the command line.
1528
1529 =item B<-t>
1530
1531 Test mode.  The target address defaults to B<perlbug-test@perl.org>.
1532 Also makes it possible to command perlbug from a pipe or file, for
1533 testing purposes.
1534
1535 =item B<-T>
1536
1537 Send a thank-you note instead of a bug report.
1538
1539 =item B<-v>
1540
1541 Include verbose configuration data in the report.
1542
1543 =back
1544
1545 =head1 AUTHORS
1546
1547 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently
1548 I<doc>tored by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>),
1549 Tom Christiansen (E<lt>tchrist@perl.comE<gt>), Nathan Torkington
1550 (E<lt>gnat@frii.comE<gt>), Charles F. Randall (E<lt>cfr@pobox.comE<gt>),
1551 Mike Guy (E<lt>mjtg@cam.ac.ukE<gt>), Dominic Dunlop
1552 (E<lt>domo@computer.orgE<gt>), Hugo van der Sanden (E<lt>hv@crypt.orgE<gt>),
1553 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
1554 (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
1555 Richard Foley (E<lt>richard.foley@rfi.netE<gt>), Jesse Vincent
1556 (E<lt>jesse@bestpractical.comE<gt>), and Craig A. Berry (E<lt>craigberry@mac.comE<gt>).
1557
1558 =head1 SEE ALSO
1559
1560 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1561 diff(1), patch(1), dbx(1), gdb(1)
1562
1563 =head1 BUGS
1564
1565 None known (guess what must have been used to report them?)
1566
1567 =cut
1568
1569 !NO!SUBS!
1570
1571 close OUT or die "Can't close $file: $!";
1572 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1573 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1574 chdir $origdir;