This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ucfirst() new signature diagnostic messages
[perl5.git] / perly.y
1 /*    perly.y
2  *
3  *    Copyright (c) 1991-2002, 2003, 2004, 2005, 2006 Larry Wall
4  *    Copyright (c) 2007, 2008, 2009, 2010, 2011 by Larry Wall and others
5  *
6  *    You may distribute under the terms of either the GNU General Public
7  *    License or the Artistic License, as specified in the README file.
8  *
9  */
10
11 /*
12  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
13  *  All that is gold does not glitter, not all those who wander are lost.'
14  *
15  *     [p.171 of _The Lord of the Rings_, I/x: "Strider"]
16  */
17
18 /*
19  * This file holds the grammar for the Perl language. If edited, you need
20  * to run regen_perly.pl, which re-creates the files perly.h, perly.tab
21  * and perly.act which are derived from this.
22  *
23  * The main job of of this grammar is to call the various newFOO()
24  * functions in op.c to build a syntax tree of OP structs.
25  * It relies on the lexer in toke.c to do the tokenizing.
26  *
27  * Note: due to the way that the cleanup code works WRT to freeing ops on
28  * the parse stack, it is dangerous to assign to the $n variables within
29  * an action.
30  */
31
32 /*  Make the parser re-entrant. */
33
34 %pure-parser
35
36 %start grammar
37
38 %union {
39     I32 ival; /* __DEFAULT__ (marker for regen_perly.pl;
40                                 must always be 1st union member) */
41     char *pval;
42     OP *opval;
43     GV *gvval;
44 }
45
46 %token <ival> GRAMPROG GRAMEXPR GRAMBLOCK GRAMBARESTMT GRAMFULLSTMT GRAMSTMTSEQ
47
48 %token <ival> '{' '}' '[' ']' '-' '+' '@' '%' '&' '=' '.'
49
50 %token <opval> BAREWORD METHOD FUNCMETH THING PMFUNC PRIVATEREF QWLIST
51 %token <opval> FUNC0OP FUNC0SUB UNIOPSUB LSTOPSUB
52 %token <opval> PLUGEXPR PLUGSTMT
53 %token <pval> LABEL
54 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
55 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
56 %token <ival> GIVEN WHEN DEFAULT
57 %token <ival> LOOPEX DOTDOT YADAYADA
58 %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
59 %token <ival> RELOP EQOP MULOP ADDOP
60 %token <ival> DOLSHARP DO HASHBRACK NOAMP
61 %token <ival> LOCAL MY REQUIRE
62 %token <ival> COLONATTR FORMLBRACK FORMRBRACK
63
64 %type <ival> grammar remember mremember
65 %type <ival>  startsub startanonsub startformsub
66
67 %type <ival> mintro
68
69 %type <opval> stmtseq fullstmt labfullstmt barestmt block mblock else
70 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
71 %type <opval> sliceme kvslice gelem
72 %type <opval> listexpr nexpr texpr iexpr mexpr mnexpr
73 %type <opval> optlistexpr optexpr optrepl indirob listop method
74 %type <opval> formname subname proto optsubbody cont my_scalar my_var
75 %type <opval> refgen_topic formblock
76 %type <opval> subattrlist myattrlist myattrterm myterm
77 %type <opval> termbinop termunop anonymous termdo
78 %type <ival>  sigslurpsigil
79 %type <opval> sigvarname sigdefault sigscalarelem sigslurpelem
80 %type <opval> sigelem siglist siglistornull subsignature 
81 %type <opval> formstmtseq formline formarg
82
83 %nonassoc <ival> PREC_LOW
84 %nonassoc LOOPEX
85
86 %left <ival> OROP DOROP
87 %left <ival> ANDOP
88 %right <ival> NOTOP
89 %nonassoc LSTOP LSTOPSUB
90 %left <ival> ','
91 %right <ival> ASSIGNOP
92 %right <ival> '?' ':'
93 %nonassoc DOTDOT YADAYADA
94 %left <ival> OROR DORDOR
95 %left <ival> ANDAND
96 %left <ival> BITOROP
97 %left <ival> BITANDOP
98 %nonassoc EQOP
99 %nonassoc RELOP
100 %nonassoc UNIOP UNIOPSUB
101 %nonassoc REQUIRE
102 %left <ival> SHIFTOP
103 %left ADDOP
104 %left MULOP
105 %left <ival> MATCHOP
106 %right <ival> '!' '~' UMINUS REFGEN
107 %right <ival> POWOP
108 %nonassoc <ival> PREINC PREDEC POSTINC POSTDEC POSTJOIN
109 %left <ival> ARROW
110 %nonassoc <ival> ')'
111 %left <ival> '('
112 %left '[' '{'
113
114 %% /* RULES */
115
116 /* Top-level choice of what kind of thing yyparse was called to parse */
117 grammar :       GRAMPROG
118                         {
119                           parser->expect = XSTATE;
120                         }
121                 remember stmtseq
122                         {
123                           newPROG(block_end($3,$4));
124                           PL_compiling.cop_seq = 0;
125                           $$ = 0;
126                         }
127         |       GRAMEXPR
128                         {
129                           parser->expect = XTERM;
130                         }
131                 optexpr
132                         {
133                           PL_eval_root = $3;
134                           $$ = 0;
135                         }
136         |       GRAMBLOCK
137                         {
138                           parser->expect = XBLOCK;
139                         }
140                 block
141                         {
142                           PL_pad_reset_pending = TRUE;
143                           PL_eval_root = $3;
144                           $$ = 0;
145                           yyunlex();
146                           parser->yychar = YYEOF;
147                         }
148         |       GRAMBARESTMT
149                         {
150                           parser->expect = XSTATE;
151                         }
152                 barestmt
153                         {
154                           PL_pad_reset_pending = TRUE;
155                           PL_eval_root = $3;
156                           $$ = 0;
157                           yyunlex();
158                           parser->yychar = YYEOF;
159                         }
160         |       GRAMFULLSTMT
161                         {
162                           parser->expect = XSTATE;
163                         }
164                 fullstmt
165                         {
166                           PL_pad_reset_pending = TRUE;
167                           PL_eval_root = $3;
168                           $$ = 0;
169                           yyunlex();
170                           parser->yychar = YYEOF;
171                         }
172         |       GRAMSTMTSEQ
173                         {
174                           parser->expect = XSTATE;
175                         }
176                 stmtseq
177                         {
178                           PL_eval_root = $3;
179                           $$ = 0;
180                         }
181         ;
182
183 /* An ordinary block */
184 block   :       '{' remember stmtseq '}'
185                         { if (parser->copline > (line_t)$1)
186                               parser->copline = (line_t)$1;
187                           $$ = block_end($2, $3);
188                         }
189         ;
190
191 /* format body */
192 formblock:      '=' remember ';' FORMRBRACK formstmtseq ';' '.'
193                         { if (parser->copline > (line_t)$1)
194                               parser->copline = (line_t)$1;
195                           $$ = block_end($2, $5);
196                         }
197         ;
198
199 remember:       /* NULL */      /* start a full lexical scope */
200                         { $$ = block_start(TRUE);
201                           parser->parsed_sub = 0; }
202         ;
203
204 mblock  :       '{' mremember stmtseq '}'
205                         { if (parser->copline > (line_t)$1)
206                               parser->copline = (line_t)$1;
207                           $$ = block_end($2, $3);
208                         }
209         ;
210
211 mremember:      /* NULL */      /* start a partial lexical scope */
212                         { $$ = block_start(FALSE);
213                           parser->parsed_sub = 0; }
214         ;
215
216 /* A sequence of statements in the program */
217 stmtseq :       /* NULL */
218                         { $$ = (OP*)NULL; }
219         |       stmtseq fullstmt
220                         {   $$ = op_append_list(OP_LINESEQ, $1, $2);
221                             PL_pad_reset_pending = TRUE;
222                             if ($1 && $2)
223                                 PL_hints |= HINT_BLOCK_SCOPE;
224                         }
225         ;
226
227 /* A sequence of format lines */
228 formstmtseq:    /* NULL */
229                         { $$ = (OP*)NULL; }
230         |       formstmtseq formline
231                         {   $$ = op_append_list(OP_LINESEQ, $1, $2);
232                             PL_pad_reset_pending = TRUE;
233                             if ($1 && $2)
234                                 PL_hints |= HINT_BLOCK_SCOPE;
235                         }
236         ;
237
238 /* A statement in the program, including optional labels */
239 fullstmt:       barestmt
240                         {
241                           $$ = $1 ? newSTATEOP(0, NULL, $1) : NULL;
242                         }
243         |       labfullstmt
244                         { $$ = $1; }
245         ;
246
247 labfullstmt:    LABEL barestmt
248                         {
249                           $$ = newSTATEOP(SVf_UTF8 * $1[strlen($1)+1], $1, $2);
250                         }
251         |       LABEL labfullstmt
252                         {
253                           $$ = newSTATEOP(SVf_UTF8 * $1[strlen($1)+1], $1, $2);
254                         }
255         ;
256
257 /* A bare statement, lacking label and other aspects of state op */
258 barestmt:       PLUGSTMT
259                         { $$ = $1; }
260         |       FORMAT startformsub formname formblock
261                         {
262                           CV *fmtcv = PL_compcv;
263                           newFORM($2, $3, $4);
264                           $$ = (OP*)NULL;
265                           if (CvOUTSIDE(fmtcv) && !CvEVAL(CvOUTSIDE(fmtcv))) {
266                               pad_add_weakref(fmtcv);
267                           }
268                           parser->parsed_sub = 1;
269                         }
270         |       SUB subname startsub
271                         {
272                           if ($2->op_type == OP_CONST) {
273                             const char *const name =
274                                 SvPV_nolen_const(((SVOP*)$2)->op_sv);
275                             if (strEQ(name, "BEGIN") || strEQ(name, "END")
276                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
277                               || strEQ(name, "UNITCHECK"))
278                               CvSPECIAL_on(PL_compcv);
279                           }
280                           else
281                           /* State subs inside anonymous subs need to be
282                              clonable themselves. */
283                           if (CvANON(CvOUTSIDE(PL_compcv))
284                            || CvCLONE(CvOUTSIDE(PL_compcv))
285                            || !PadnameIsSTATE(PadlistNAMESARRAY(CvPADLIST(
286                                                 CvOUTSIDE(PL_compcv)
287                                              ))[$2->op_targ]))
288                               CvCLONE_on(PL_compcv);
289                           parser->in_my = 0;
290                           parser->in_my_stash = NULL;
291                         }
292                 proto subattrlist optsubbody
293                         {
294                           SvREFCNT_inc_simple_void(PL_compcv);
295                           $2->op_type == OP_CONST
296                               ? newATTRSUB($3, $2, $5, $6, $7)
297                               : newMYSUB($3, $2, $5, $6, $7)
298                           ;
299                           $$ = (OP*)NULL;
300                           intro_my();
301                           parser->parsed_sub = 1;
302                         }
303         |       SUB subname startsub
304                         {
305                           if ($2->op_type == OP_CONST) {
306                             const char *const name =
307                                 SvPV_nolen_const(((SVOP*)$2)->op_sv);
308                             if (strEQ(name, "BEGIN") || strEQ(name, "END")
309                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
310                               || strEQ(name, "UNITCHECK"))
311                               CvSPECIAL_on(PL_compcv);
312                           }
313                           else
314                           /* State subs inside anonymous subs need to be
315                              clonable themselves. */
316                           if (CvANON(CvOUTSIDE(PL_compcv))
317                            || CvCLONE(CvOUTSIDE(PL_compcv))
318                            || !PadnameIsSTATE(PadlistNAMESARRAY(CvPADLIST(
319                                                 CvOUTSIDE(PL_compcv)
320                                              ))[$2->op_targ]))
321                               CvCLONE_on(PL_compcv);
322                           parser->in_my = 0;
323                           parser->in_my_stash = NULL;
324                         }
325                 remember subsignature subattrlist '{' stmtseq '}'
326                         {
327                           OP *body;
328                           if (parser->copline > (line_t)$8)
329                               parser->copline = (line_t)$8;
330                           body = block_end($5,
331                                 op_append_list(OP_LINESEQ, $6, $9));
332
333                           SvREFCNT_inc_simple_void(PL_compcv);
334                           $2->op_type == OP_CONST
335                               ? newATTRSUB($3, $2, NULL, $7, body)
336                               : newMYSUB($3, $2, NULL, $7, body)
337                           ;
338                           $$ = (OP*)NULL;
339                           intro_my();
340                           parser->parsed_sub = 1;
341                         }
342         |       PACKAGE BAREWORD BAREWORD ';'
343                         {
344                           package($3);
345                           if ($2)
346                               package_version($2);
347                           $$ = (OP*)NULL;
348                         }
349         |       USE startsub
350                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
351                 BAREWORD BAREWORD optlistexpr ';'
352                         {
353                           SvREFCNT_inc_simple_void(PL_compcv);
354                           utilize($1, $2, $4, $5, $6);
355                           parser->parsed_sub = 1;
356                           $$ = (OP*)NULL;
357                         }
358         |       IF '(' remember mexpr ')' mblock else
359                         {
360                           $$ = block_end($3,
361                               newCONDOP(0, $4, op_scope($6), $7));
362                           parser->copline = (line_t)$1;
363                         }
364         |       UNLESS '(' remember mexpr ')' mblock else
365                         {
366                           $$ = block_end($3,
367                               newCONDOP(0, $4, $7, op_scope($6)));
368                           parser->copline = (line_t)$1;
369                         }
370         |       GIVEN '(' remember mexpr ')' mblock
371                         {
372                           $$ = block_end($3, newGIVENOP($4, op_scope($6), 0));
373                           parser->copline = (line_t)$1;
374                         }
375         |       WHEN '(' remember mexpr ')' mblock
376                         { $$ = block_end($3, newWHENOP($4, op_scope($6))); }
377         |       DEFAULT block
378                         { $$ = newWHENOP(0, op_scope($2)); }
379         |       WHILE '(' remember texpr ')' mintro mblock cont
380                         {
381                           $$ = block_end($3,
382                                   newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
383                                       $4, $7, $8, $6));
384                           parser->copline = (line_t)$1;
385                         }
386         |       UNTIL '(' remember iexpr ')' mintro mblock cont
387                         {
388                           $$ = block_end($3,
389                                   newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
390                                       $4, $7, $8, $6));
391                           parser->copline = (line_t)$1;
392                         }
393         |       FOR '(' remember mnexpr ';'
394                         { parser->expect = XTERM; }
395                 texpr ';'
396                         { parser->expect = XTERM; }
397                 mintro mnexpr ')'
398                 mblock
399                         {
400                           OP *initop = $4;
401                           OP *forop = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
402                                       scalar($7), $13, $11, $10);
403                           if (initop) {
404                               forop = op_prepend_elem(OP_LINESEQ, initop,
405                                   op_append_elem(OP_LINESEQ,
406                                       newOP(OP_UNSTACK, OPf_SPECIAL),
407                                       forop));
408                           }
409                           PL_hints |= HINT_BLOCK_SCOPE;
410                           $$ = block_end($3, forop);
411                           parser->copline = (line_t)$1;
412                         }
413         |       FOR MY remember my_scalar '(' mexpr ')' mblock cont
414                         {
415                           $$ = block_end($3, newFOROP(0, $4, $6, $8, $9));
416                           parser->copline = (line_t)$1;
417                         }
418         |       FOR scalar '(' remember mexpr ')' mblock cont
419                         {
420                           $$ = block_end($4, newFOROP(0,
421                                       op_lvalue($2, OP_ENTERLOOP), $5, $7, $8));
422                           parser->copline = (line_t)$1;
423                         }
424         |       FOR my_refgen remember my_var
425                         { parser->in_my = 0; $<opval>$ = my($4); }
426                 '(' mexpr ')' mblock cont
427                         {
428                           $$ = block_end(
429                                 $3,
430                                 newFOROP(0,
431                                          op_lvalue(
432                                             newUNOP(OP_REFGEN, 0,
433                                                     $<opval>5),
434                                             OP_ENTERLOOP),
435                                          $7, $9, $10)
436                           );
437                           parser->copline = (line_t)$1;
438                         }
439         |       FOR REFGEN refgen_topic '(' remember mexpr ')' mblock cont
440                         {
441                           $$ = block_end($5, newFOROP(
442                                 0, op_lvalue(newUNOP(OP_REFGEN, 0,
443                                                      $3),
444                                              OP_ENTERLOOP), $6, $8, $9));
445                           parser->copline = (line_t)$1;
446                         }
447         |       FOR '(' remember mexpr ')' mblock cont
448                         {
449                           $$ = block_end($3,
450                                   newFOROP(0, (OP*)NULL, $4, $6, $7));
451                           parser->copline = (line_t)$1;
452                         }
453         |       block cont
454                         {
455                           /* a block is a loop that happens once */
456                           $$ = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
457                                   (OP*)NULL, $1, $2, 0);
458                         }
459         |       PACKAGE BAREWORD BAREWORD '{' remember
460                         {
461                           package($3);
462                           if ($2) {
463                               package_version($2);
464                           }
465                         }
466                 stmtseq '}'
467                         {
468                           /* a block is a loop that happens once */
469                           $$ = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
470                                   (OP*)NULL, block_end($5, $7), (OP*)NULL, 0);
471                           if (parser->copline > (line_t)$4)
472                               parser->copline = (line_t)$4;
473                         }
474         |       sideff ';'
475                         {
476                           $$ = $1;
477                         }
478         |       ';'
479                         {
480                           $$ = (OP*)NULL;
481                           parser->copline = NOLINE;
482                         }
483         ;
484
485 /* Format line */
486 formline:       THING formarg
487                         { OP *list;
488                           if ($2) {
489                               OP *term = $2;
490                               list = op_append_elem(OP_LIST, $1, term);
491                           }
492                           else {
493                               list = $1;
494                           }
495                           if (parser->copline == NOLINE)
496                                parser->copline = CopLINE(PL_curcop)-1;
497                           else parser->copline--;
498                           $$ = newSTATEOP(0, NULL,
499                                           op_convert_list(OP_FORMLINE, 0, list));
500                         }
501         ;
502
503 formarg :       /* NULL */
504                         { $$ = NULL; }
505         |       FORMLBRACK stmtseq FORMRBRACK
506                         { $$ = op_unscope($2); }
507         ;
508
509 /* An expression which may have a side-effect */
510 sideff  :       error
511                         { $$ = (OP*)NULL; }
512         |       expr
513                         { $$ = $1; }
514         |       expr IF expr
515                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
516         |       expr UNLESS expr
517                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
518         |       expr WHILE expr
519                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
520         |       expr UNTIL iexpr
521                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1); }
522         |       expr FOR expr
523                         { $$ = newFOROP(0, (OP*)NULL, $3, $1, (OP*)NULL);
524                           parser->copline = (line_t)$2; }
525         |       expr WHEN expr
526                         { $$ = newWHENOP($3, op_scope($1)); }
527         ;
528
529 /* else and elsif blocks */
530 else    :       /* NULL */
531                         { $$ = (OP*)NULL; }
532         |       ELSE mblock
533                         {
534                           ($2)->op_flags |= OPf_PARENS;
535                           $$ = op_scope($2);
536                         }
537         |       ELSIF '(' mexpr ')' mblock else
538                         { parser->copline = (line_t)$1;
539                             $$ = newCONDOP(0,
540                                 newSTATEOP(OPf_SPECIAL,NULL,$3),
541                                 op_scope($5), $6);
542                           PL_hints |= HINT_BLOCK_SCOPE;
543                         }
544         ;
545
546 /* Continue blocks */
547 cont    :       /* NULL */
548                         { $$ = (OP*)NULL; }
549         |       CONTINUE block
550                         { $$ = op_scope($2); }
551         ;
552
553 /* determine whether there are any new my declarations */
554 mintro  :       /* NULL */
555                         { $$ = (PL_min_intro_pending &&
556                             PL_max_intro_pending >=  PL_min_intro_pending);
557                           intro_my(); }
558
559 /* Normal expression */
560 nexpr   :       /* NULL */
561                         { $$ = (OP*)NULL; }
562         |       sideff
563         ;
564
565 /* Boolean expression */
566 texpr   :       /* NULL means true */
567                         { YYSTYPE tmplval;
568                           (void)scan_num("1", &tmplval);
569                           $$ = tmplval.opval; }
570         |       expr
571         ;
572
573 /* Inverted boolean expression */
574 iexpr   :       expr
575                         { $$ = invert(scalar($1)); }
576         ;
577
578 /* Expression with its own lexical scope */
579 mexpr   :       expr
580                         { $$ = $1; intro_my(); }
581         ;
582
583 mnexpr  :       nexpr
584                         { $$ = $1; intro_my(); }
585         ;
586
587 formname:       BAREWORD        { $$ = $1; }
588         |       /* NULL */      { $$ = (OP*)NULL; }
589         ;
590
591 startsub:       /* NULL */      /* start a regular subroutine scope */
592                         { $$ = start_subparse(FALSE, 0);
593                             SAVEFREESV(PL_compcv); }
594
595         ;
596
597 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
598                         { $$ = start_subparse(FALSE, CVf_ANON);
599                             SAVEFREESV(PL_compcv); }
600         ;
601
602 startformsub:   /* NULL */      /* start a format subroutine scope */
603                         { $$ = start_subparse(TRUE, 0);
604                             SAVEFREESV(PL_compcv); }
605         ;
606
607 /* Name of a subroutine - must be a bareword, could be special */
608 subname :       BAREWORD
609         |       PRIVATEREF
610         ;
611
612 /* Subroutine prototype */
613 proto   :       /* NULL */
614                         { $$ = (OP*)NULL; }
615         |       THING
616         ;
617
618 /* Optional list of subroutine attributes */
619 subattrlist:    /* NULL */
620                         { $$ = (OP*)NULL; }
621         |       COLONATTR THING
622                         { $$ = $2; }
623         |       COLONATTR
624                         { $$ = (OP*)NULL; }
625         ;
626
627 /* List of attributes for a "my" variable declaration */
628 myattrlist:     COLONATTR THING
629                         { $$ = $2; }
630         |       COLONATTR
631                         { $$ = (OP*)NULL; }
632         ;
633
634
635
636 /* --------------------------------------
637  * subroutine signature parsing
638  */
639
640 /* the '' or 'foo' part of a '$' or '@foo' etc signature variable  */
641 sigvarname:   /* NULL */
642                         { $$ = (OP*)NULL; }
643         |       PRIVATEREF
644                         { $$ = $1; }
645         ;
646
647 sigslurpsigil:
648                 '@'
649                         { $$ = '@'; }
650         |       '%'
651                         { $$ = '%'; }
652
653 /* @, %, @foo, %foo */
654 sigslurpelem: sigslurpsigil sigvarname sigdefault/* def only to catch errors */ 
655                         {
656                             I32 sigil   = $1;
657                             OP *var     = $2;
658                             OP *defexpr = $3;
659
660                             if (PL_parser->sig_slurpy)
661                                 yyerror("Multiple slurpy parameters not allowed");
662                             PL_parser->sig_slurpy = sigil;
663
664                             if (defexpr)
665                                 yyerror("A slurpy parameter may not have "
666                                         "a default value");
667
668                             $$ = var ? newSTATEOP(0, NULL, var) : (OP*)NULL;
669                         }
670         ;
671
672 /* default part of sub signature scalar element: i.e. '= default_expr' */
673 sigdefault:     /* NULL */
674                         { $$ = (OP*)NULL; }
675         |       ASSIGNOP
676                         { $$ = newOP(OP_NULL, 0); }
677         |       ASSIGNOP term
678                         { $$ = $2; }
679
680
681 /* subroutine signature scalar element: e.g. '$x', '$=', '$x = $default' */
682 sigscalarelem:
683                 '$' sigvarname sigdefault
684                         {
685                             OP *var     = $2;
686                             OP *defexpr = $3;
687
688                             if (PL_parser->sig_slurpy)
689                                 yyerror("Slurpy parameter not last");
690
691                             PL_parser->sig_elems++;
692
693                             if (defexpr) {
694                                 PL_parser->sig_optelems++;
695
696                                 if (   defexpr->op_type == OP_NULL
697                                     && !(defexpr->op_flags & OPf_KIDS))
698                                 {
699                                     /* handle '$=' special case */
700                                     if (var)
701                                         yyerror("Optional parameter "
702                                                     "lacks default expression");
703                                     op_free(defexpr);
704                                 }
705                                 else { 
706                                     /* a normal '=default' expression */ 
707                                     OP *defop = (OP*)alloc_LOGOP(OP_ARGDEFELEM,
708                                                         defexpr,
709                                                         LINKLIST(defexpr));
710                                     /* re-purpose op_targ to hold @_ index */
711                                     defop->op_targ = PL_parser->sig_elems - 1;
712
713                                     if (var) {
714                                         var->op_flags |= OPf_STACKED;
715                                         (void)op_sibling_splice(var,
716                                                         NULL, 0, defop);
717                                         scalar(defop);
718                                     }
719                                     else
720                                         var = newUNOP(OP_NULL, 0, defop);
721
722                                     LINKLIST(var);
723                                     /* NB: normally the first child of a
724                                      * logop is executed before the logop,
725                                      * and it pushes a boolean result
726                                      * ready for the logop. For ARGDEFELEM,
727                                      * the op itself does the boolean
728                                      * calculation, so set the first op to
729                                      * it instead.
730                                      */
731                                     var->op_next = defop;
732                                     defexpr->op_next = var;
733                                 }
734                             }
735                             else {
736                                 if (PL_parser->sig_optelems)
737                                     yyerror("Mandatory parameter "
738                                             "follows optional parameter");
739                             }
740
741                             $$ = var ? newSTATEOP(0, NULL, var) : (OP*)NULL;
742                         }
743         ;
744
745
746 /* subroutine signature element: e.g. '$x = $default' or '%h' */
747 sigelem:        sigscalarelem
748                         { parser->expect = XSIGVAR; $$ = $1; }
749         |       sigslurpelem
750                         { parser->expect = XSIGVAR; $$ = $1; }
751         ;
752
753 /* list of subroutine signature elements */
754 siglist:
755                 siglist ','
756                         { $$ = $1; }
757         |       siglist ',' sigelem
758                         {
759                           $$ = op_append_list(OP_LINESEQ, $1, $3);
760                         }
761         |       sigelem  %prec PREC_LOW
762                         { $$ = $1; }
763         ;
764
765 /* () or (....) */
766 siglistornull:          /* NULL */
767                         { $$ = (OP*)NULL; }
768         |       siglist
769                         { $$ = $1; }
770
771 /* Subroutine signature */
772 subsignature:   '('
773                         {
774                             ENTER;
775                             SAVEINT(PL_parser->sig_elems);
776                             SAVEINT(PL_parser->sig_optelems);
777                             SAVEI8(PL_parser->sig_slurpy);
778                             PL_parser->sig_elems    = 0;
779                             PL_parser->sig_optelems = 0;
780                             PL_parser->sig_slurpy   = 0;
781                             parser->expect = XSIGVAR;
782                         }
783                 siglistornull
784                 ')'
785                         {
786                             OP            *sigops = $3;
787                             UNOP_AUX_item *aux;
788                             OP            *check;
789
790                             assert(FEATURE_SIGNATURES_IS_ENABLED);
791
792                             /* We shouldn't get here otherwise */
793                             Perl_ck_warner_d(aTHX_
794                                 packWARN(WARN_EXPERIMENTAL__SIGNATURES),
795                                 "The signatures feature is experimental");
796
797                             aux = (UNOP_AUX_item*)PerlMemShared_malloc(
798                                 sizeof(UNOP_AUX_item) * 3);
799                             aux[0].uv = PL_parser->sig_elems;
800                             aux[1].uv = PL_parser->sig_optelems;
801                             aux[2].iv = PL_parser->sig_slurpy;
802                             check = newUNOP_AUX(OP_ARGCHECK, 0, NULL, aux);
803                             sigops = op_prepend_elem(OP_LINESEQ, check, sigops);
804                             sigops = op_prepend_elem(OP_LINESEQ,
805                                                 newSTATEOP(0, NULL, NULL),
806                                                 sigops);
807                             /* a nextstate at the end handles context
808                              * correctly for an empty sub body */
809                             $$ = op_append_elem(OP_LINESEQ,
810                                                 sigops,
811                                                 newSTATEOP(0, NULL, NULL));
812
813                             parser->expect = XATTRBLOCK;
814                             LEAVE;
815                         }
816         ;
817
818
819
820 /* Optional subroutine body, for named subroutine declaration */
821 optsubbody:     block
822         |       ';'     { $$ = (OP*)NULL; }
823         ;
824
825 /* Ordinary expressions; logical combinations */
826 expr    :       expr ANDOP expr
827                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
828         |       expr OROP expr
829                         { $$ = newLOGOP($2, 0, $1, $3); }
830         |       expr DOROP expr
831                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
832         |       listexpr %prec PREC_LOW
833         ;
834
835 /* Expressions are a list of terms joined by commas */
836 listexpr:       listexpr ','
837                         { $$ = $1; }
838         |       listexpr ',' term
839                         {
840                           OP* term = $3;
841                           $$ = op_append_elem(OP_LIST, $1, term);
842                         }
843         |       term %prec PREC_LOW
844         ;
845
846 /* List operators */
847 listop  :       LSTOP indirob listexpr /* map {...} @args or print $fh @args */
848                         { $$ = op_convert_list($1, OPf_STACKED,
849                                 op_prepend_elem(OP_LIST, newGVREF($1,$2), $3) );
850                         }
851         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
852                         { $$ = op_convert_list($1, OPf_STACKED,
853                                 op_prepend_elem(OP_LIST, newGVREF($1,$3), $4) );
854                         }
855         |       term ARROW method '(' optexpr ')' /* $foo->bar(list) */
856                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
857                                 op_append_elem(OP_LIST,
858                                     op_prepend_elem(OP_LIST, scalar($1), $5),
859                                     newMETHOP(OP_METHOD, 0, $3)));
860                         }
861         |       term ARROW method                     /* $foo->bar */
862                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
863                                 op_append_elem(OP_LIST, scalar($1),
864                                     newMETHOP(OP_METHOD, 0, $3)));
865                         }
866         |       METHOD indirob optlistexpr           /* new Class @args */
867                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
868                                 op_append_elem(OP_LIST,
869                                     op_prepend_elem(OP_LIST, $2, $3),
870                                     newMETHOP(OP_METHOD, 0, $1)));
871                         }
872         |       FUNCMETH indirob '(' optexpr ')'    /* method $object (@args) */
873                         { $$ = op_convert_list(OP_ENTERSUB, OPf_STACKED,
874                                 op_append_elem(OP_LIST,
875                                     op_prepend_elem(OP_LIST, $2, $4),
876                                     newMETHOP(OP_METHOD, 0, $1)));
877                         }
878         |       LSTOP optlistexpr                    /* print @args */
879                         { $$ = op_convert_list($1, 0, $2); }
880         |       FUNC '(' optexpr ')'                 /* print (@args) */
881                         { $$ = op_convert_list($1, 0, $3); }
882         |       LSTOPSUB startanonsub block /* sub f(&@);   f { foo } ... */
883                         { SvREFCNT_inc_simple_void(PL_compcv);
884                           $<opval>$ = newANONATTRSUB($2, 0, (OP*)NULL, $3); }
885                     optlistexpr         %prec LSTOP  /* ... @bar */
886                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
887                                  op_append_elem(OP_LIST,
888                                    op_prepend_elem(OP_LIST, $<opval>4, $5), $1));
889                         }
890         ;
891
892 /* Names of methods. May use $object->$methodname */
893 method  :       METHOD
894         |       scalar
895         ;
896
897 /* Some kind of subscripted expression */
898 subscripted:    gelem '{' expr ';' '}'        /* *main::{something} */
899                         /* In this and all the hash accessors, ';' is
900                          * provided by the tokeniser */
901                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3)); }
902         |       scalar '[' expr ']'          /* $array[$element] */
903                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3));
904                         }
905         |       term ARROW '[' expr ']'      /* somearef->[$element] */
906                         { $$ = newBINOP(OP_AELEM, 0,
907                                         ref(newAVREF($1),OP_RV2AV),
908                                         scalar($4));
909                         }
910         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
911                         { $$ = newBINOP(OP_AELEM, 0,
912                                         ref(newAVREF($1),OP_RV2AV),
913                                         scalar($3));
914                         }
915         |       scalar '{' expr ';' '}'    /* $foo{bar();} */
916                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
917                         }
918         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
919                         { $$ = newBINOP(OP_HELEM, 0,
920                                         ref(newHVREF($1),OP_RV2HV),
921                                         jmaybe($4)); }
922         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
923                         { $$ = newBINOP(OP_HELEM, 0,
924                                         ref(newHVREF($1),OP_RV2HV),
925                                         jmaybe($3)); }
926         |       term ARROW '(' ')'          /* $subref->() */
927                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
928                                    newCVREF(0, scalar($1))); }
929         |       term ARROW '(' expr ')'     /* $subref->(@args) */
930                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
931                                    op_append_elem(OP_LIST, $4,
932                                        newCVREF(0, scalar($1)))); }
933
934         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
935                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
936                                    op_append_elem(OP_LIST, $3,
937                                                newCVREF(0, scalar($1)))); }
938         |       subscripted '(' ')'        /* $foo->{bar}->() */
939                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
940                                    newCVREF(0, scalar($1))); }
941         |       '(' expr ')' '[' expr ']'            /* list slice */
942                         { $$ = newSLICEOP(0, $5, $2); }
943         |       QWLIST '[' expr ']'            /* list literal slice */
944                         { $$ = newSLICEOP(0, $3, $1); }
945         |       '(' ')' '[' expr ']'                 /* empty list slice! */
946                         { $$ = newSLICEOP(0, $4, (OP*)NULL); }
947     ;
948
949 /* Binary operators between terms */
950 termbinop:      term ASSIGNOP term                     /* $x = $y */
951                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
952         |       term POWOP term                        /* $x ** $y */
953                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
954         |       term MULOP term                        /* $x * $y, $x x $y */
955                         {   if ($2 != OP_REPEAT)
956                                 scalar($1);
957                             $$ = newBINOP($2, 0, $1, scalar($3));
958                         }
959         |       term ADDOP term                        /* $x + $y */
960                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
961         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
962                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
963         |       term RELOP term                        /* $x > $y, etc. */
964                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
965         |       term EQOP term                         /* $x == $y, $x eq $y */
966                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
967         |       term BITANDOP term                     /* $x & $y */
968                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
969         |       term BITOROP term                      /* $x | $y */
970                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
971         |       term DOTDOT term                       /* $x..$y, $x...$y */
972                         { $$ = newRANGE($2, scalar($1), scalar($3)); }
973         |       term ANDAND term                       /* $x && $y */
974                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
975         |       term OROR term                         /* $x || $y */
976                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
977         |       term DORDOR term                       /* $x // $y */
978                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
979         |       term MATCHOP term                      /* $x =~ /$y/ */
980                         { $$ = bind_match($2, $1, $3); }
981     ;
982
983 /* Unary operators and terms */
984 termunop : '-' term %prec UMINUS                       /* -$x */
985                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
986         |       '+' term %prec UMINUS                  /* +$x */
987                         { $$ = $2; }
988
989         |       '!' term                               /* !$x */
990                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
991         |       '~' term                               /* ~$x */
992                         { $$ = newUNOP($1, 0, scalar($2)); }
993         |       term POSTINC                           /* $x++ */
994                         { $$ = newUNOP(OP_POSTINC, 0,
995                                         op_lvalue(scalar($1), OP_POSTINC)); }
996         |       term POSTDEC                           /* $x-- */
997                         { $$ = newUNOP(OP_POSTDEC, 0,
998                                         op_lvalue(scalar($1), OP_POSTDEC));}
999         |       term POSTJOIN    /* implicit join after interpolated ->@ */
1000                         { $$ = op_convert_list(OP_JOIN, 0,
1001                                        op_append_elem(
1002                                         OP_LIST,
1003                                         newSVREF(scalar(
1004                                             newSVOP(OP_CONST,0,
1005                                                     newSVpvs("\""))
1006                                         )),
1007                                         $1
1008                                        ));
1009                         }
1010         |       PREINC term                            /* ++$x */
1011                         { $$ = newUNOP(OP_PREINC, 0,
1012                                         op_lvalue(scalar($2), OP_PREINC)); }
1013         |       PREDEC term                            /* --$x */
1014                         { $$ = newUNOP(OP_PREDEC, 0,
1015                                         op_lvalue(scalar($2), OP_PREDEC)); }
1016
1017     ;
1018
1019 /* Constructors for anonymous data */
1020 anonymous:      '[' expr ']'
1021                         { $$ = newANONLIST($2); }
1022         |       '[' ']'
1023                         { $$ = newANONLIST((OP*)NULL);}
1024         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
1025                         { $$ = newANONHASH($2); }
1026         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
1027                         { $$ = newANONHASH((OP*)NULL); }
1028         |       ANONSUB startanonsub proto subattrlist block            %prec '('
1029                         { SvREFCNT_inc_simple_void(PL_compcv);
1030                           $$ = newANONATTRSUB($2, $3, $4, $5); }
1031         |       ANONSUB startanonsub remember subsignature subattrlist '{' stmtseq '}'  %prec '('
1032                         {
1033                           OP *body;
1034                           if (parser->copline > (line_t)$6)
1035                               parser->copline = (line_t)$6;
1036                           body = block_end($3,
1037                                 op_append_list(OP_LINESEQ, $4, $7));
1038                           SvREFCNT_inc_simple_void(PL_compcv);
1039                           $$ = newANONATTRSUB($2, NULL, $5, body);
1040                         }
1041
1042     ;
1043
1044 /* Things called with "do" */
1045 termdo  :       DO term %prec UNIOP                     /* do $filename */
1046                         { $$ = dofile($2, $1);}
1047         |       DO block        %prec '('               /* do { code */
1048                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, op_scope($2));}
1049         ;
1050
1051 term    :       termbinop
1052         |       termunop
1053         |       anonymous
1054         |       termdo
1055         |       term '?' term ':' term
1056                         { $$ = newCONDOP(0, $1, $3, $5); }
1057         |       REFGEN term                          /* \$x, \@y, \%z */
1058                         { $$ = newUNOP(OP_REFGEN, 0, $2); }
1059         |       MY REFGEN term
1060                         { $$ = newUNOP(OP_REFGEN, 0, localize($3,1)); }
1061         |       myattrterm      %prec UNIOP
1062                         { $$ = $1; }
1063         |       LOCAL term      %prec UNIOP
1064                         { $$ = localize($2,0); }
1065         |       '(' expr ')'
1066                         { $$ = sawparens($2); }
1067         |       QWLIST
1068                         { $$ = $1; }
1069         |       '(' ')'
1070                         { $$ = sawparens(newNULLLIST()); }
1071         |       scalar  %prec '('
1072                         { $$ = $1; }
1073         |       star    %prec '('
1074                         { $$ = $1; }
1075         |       hsh     %prec '('
1076                         { $$ = $1; }
1077         |       ary     %prec '('
1078                         { $$ = $1; }
1079         |       arylen  %prec '('                    /* $#x, $#{ something } */
1080                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
1081         |       subscripted
1082                         { $$ = $1; }
1083         |       sliceme '[' expr ']'                     /* array slice */
1084                         { $$ = op_prepend_elem(OP_ASLICE,
1085                                 newOP(OP_PUSHMARK, 0),
1086                                     newLISTOP(OP_ASLICE, 0,
1087                                         list($3),
1088                                         ref($1, OP_ASLICE)));
1089                           if ($$ && $1)
1090                               $$->op_private |=
1091                                   $1->op_private & OPpSLICEWARNING;
1092                         }
1093         |       kvslice '[' expr ']'                 /* array key/value slice */
1094                         { $$ = op_prepend_elem(OP_KVASLICE,
1095                                 newOP(OP_PUSHMARK, 0),
1096                                     newLISTOP(OP_KVASLICE, 0,
1097                                         list($3),
1098                                         ref(oopsAV($1), OP_KVASLICE)));
1099                           if ($$ && $1)
1100                               $$->op_private |=
1101                                   $1->op_private & OPpSLICEWARNING;
1102                         }
1103         |       sliceme '{' expr ';' '}'                 /* @hash{@keys} */
1104                         { $$ = op_prepend_elem(OP_HSLICE,
1105                                 newOP(OP_PUSHMARK, 0),
1106                                     newLISTOP(OP_HSLICE, 0,
1107                                         list($3),
1108                                         ref(oopsHV($1), OP_HSLICE)));
1109                           if ($$ && $1)
1110                               $$->op_private |=
1111                                   $1->op_private & OPpSLICEWARNING;
1112                         }
1113         |       kvslice '{' expr ';' '}'                 /* %hash{@keys} */
1114                         { $$ = op_prepend_elem(OP_KVHSLICE,
1115                                 newOP(OP_PUSHMARK, 0),
1116                                     newLISTOP(OP_KVHSLICE, 0,
1117                                         list($3),
1118                                         ref($1, OP_KVHSLICE)));
1119                           if ($$ && $1)
1120                               $$->op_private |=
1121                                   $1->op_private & OPpSLICEWARNING;
1122                         }
1123         |       THING   %prec '('
1124                         { $$ = $1; }
1125         |       amper                                /* &foo; */
1126                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
1127         |       amper '(' ')'                 /* &foo() or foo() */
1128                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1));
1129                         }
1130         |       amper '(' expr ')'          /* &foo(@args) or foo(@args) */
1131                         {
1132                           $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1133                                 op_append_elem(OP_LIST, $3, scalar($1)));
1134                         }
1135         |       NOAMP subname optlistexpr       /* foo @args (no parens) */
1136                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1137                             op_append_elem(OP_LIST, $3, scalar($2)));
1138                         }
1139         |       term ARROW '$' '*'
1140                         { $$ = newSVREF($1); }
1141         |       term ARROW '@' '*'
1142                         { $$ = newAVREF($1); }
1143         |       term ARROW '%' '*'
1144                         { $$ = newHVREF($1); }
1145         |       term ARROW '&' '*'
1146                         { $$ = newUNOP(OP_ENTERSUB, 0,
1147                                        scalar(newCVREF($3,$1))); }
1148         |       term ARROW '*' '*'      %prec '('
1149                         { $$ = newGVREF(0,$1); }
1150         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
1151                         { $$ = newOP($1, OPf_SPECIAL);
1152                             PL_hints |= HINT_BLOCK_SCOPE; }
1153         |       LOOPEX term
1154                         { $$ = newLOOPEX($1,$2); }
1155         |       NOTOP listexpr                       /* not $foo */
1156                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
1157         |       UNIOP                                /* Unary op, $_ implied */
1158                         { $$ = newOP($1, 0); }
1159         |       UNIOP block                          /* eval { foo }* */
1160                         { $$ = newUNOP($1, 0, $2); }
1161         |       UNIOP term                           /* Unary op */
1162                         { $$ = newUNOP($1, 0, $2); }
1163         |       REQUIRE                              /* require, $_ implied */
1164                         { $$ = newOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0); }
1165         |       REQUIRE term                         /* require Foo */
1166                         { $$ = newUNOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0, $2); }
1167         |       UNIOPSUB
1168                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1169         |       UNIOPSUB term                        /* Sub treated as unop */
1170                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1171                             op_append_elem(OP_LIST, $2, scalar($1))); }
1172         |       FUNC0                                /* Nullary operator */
1173                         { $$ = newOP($1, 0); }
1174         |       FUNC0 '(' ')'
1175                         { $$ = newOP($1, 0);}
1176         |       FUNC0OP       /* Same as above, but op created in toke.c */
1177                         { $$ = $1; }
1178         |       FUNC0OP '(' ')'
1179                         { $$ = $1; }
1180         |       FUNC0SUB                             /* Sub treated as nullop */
1181                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1182         |       FUNC1 '(' ')'                        /* not () */
1183                         { $$ = ($1 == OP_NOT)
1184                           ? newUNOP($1, 0, newSVOP(OP_CONST, 0, newSViv(0)))
1185                           : newOP($1, OPf_SPECIAL); }
1186         |       FUNC1 '(' expr ')'                   /* not($foo) */
1187                         { $$ = newUNOP($1, 0, $3); }
1188         |       PMFUNC /* m//, s///, qr//, tr/// */
1189                         {
1190                             if (   $1->op_type != OP_TRANS
1191                                 && $1->op_type != OP_TRANSR
1192                                 && (((PMOP*)$1)->op_pmflags & PMf_HAS_CV))
1193                             {
1194                                 $<ival>$ = start_subparse(FALSE, CVf_ANON);
1195                                 SAVEFREESV(PL_compcv);
1196                             } else
1197                                 $<ival>$ = 0;
1198                         }
1199                     '(' listexpr optrepl ')'
1200                         { $$ = pmruntime($1, $4, $5, 1, $<ival>2); }
1201         |       BAREWORD
1202         |       listop
1203         |       YADAYADA
1204                         {
1205                           $$ = newLISTOP(OP_DIE, 0, newOP(OP_PUSHMARK, 0),
1206                                 newSVOP(OP_CONST, 0, newSVpvs("Unimplemented")));
1207                         }
1208         |       PLUGEXPR
1209         ;
1210
1211 /* "my" declarations, with optional attributes */
1212 myattrterm:     MY myterm myattrlist
1213                         { $$ = my_attrs($2,$3); }
1214         |       MY myterm
1215                         { $$ = localize($2,1); }
1216         |       MY REFGEN myterm myattrlist
1217                         { $$ = newUNOP(OP_REFGEN, 0, my_attrs($3,$4)); }
1218         ;
1219
1220 /* Things that can be "my"'d */
1221 myterm  :       '(' expr ')'
1222                         { $$ = sawparens($2); }
1223         |       '(' ')'
1224                         { $$ = sawparens(newNULLLIST()); }
1225
1226         |       scalar  %prec '('
1227                         { $$ = $1; }
1228         |       hsh     %prec '('
1229                         { $$ = $1; }
1230         |       ary     %prec '('
1231                         { $$ = $1; }
1232         ;
1233
1234 /* Basic list expressions */
1235 optlistexpr:    /* NULL */ %prec PREC_LOW
1236                         { $$ = (OP*)NULL; }
1237         |       listexpr    %prec PREC_LOW
1238                         { $$ = $1; }
1239         ;
1240
1241 optexpr:        /* NULL */
1242                         { $$ = (OP*)NULL; }
1243         |       expr
1244                         { $$ = $1; }
1245         ;
1246
1247 optrepl:        /* NULL */
1248                         { $$ = (OP*)NULL; }
1249         |       '/' expr
1250                         { $$ = $2; }
1251         ;
1252
1253 /* A little bit of trickery to make "for my $foo (@bar)" actually be
1254    lexical */
1255 my_scalar:      scalar
1256                         { parser->in_my = 0; $$ = my($1); }
1257         ;
1258
1259 my_var  :       scalar
1260         |       ary
1261         |       hsh
1262         ;
1263
1264 refgen_topic:   my_var
1265         |       amper
1266         ;
1267
1268 my_refgen:      MY REFGEN
1269         |       REFGEN MY
1270         ;
1271
1272 amper   :       '&' indirob
1273                         { $$ = newCVREF($1,$2); }
1274         ;
1275
1276 scalar  :       '$' indirob
1277                         { $$ = newSVREF($2); }
1278         ;
1279
1280 ary     :       '@' indirob
1281                         { $$ = newAVREF($2);
1282                           if ($$) $$->op_private |= $1;
1283                         }
1284         ;
1285
1286 hsh     :       '%' indirob
1287                         { $$ = newHVREF($2);
1288                           if ($$) $$->op_private |= $1;
1289                         }
1290         ;
1291
1292 arylen  :       DOLSHARP indirob
1293                         { $$ = newAVREF($2); }
1294         |       term ARROW DOLSHARP '*'
1295                         { $$ = newAVREF($1); }
1296         ;
1297
1298 star    :       '*' indirob
1299                         { $$ = newGVREF(0,$2); }
1300         ;
1301
1302 sliceme :       ary
1303         |       term ARROW '@'
1304                         { $$ = newAVREF($1); }
1305         ;
1306
1307 kvslice :       hsh
1308         |       term ARROW '%'
1309                         { $$ = newHVREF($1); }
1310         ;
1311
1312 gelem   :       star
1313         |       term ARROW '*'
1314                         { $$ = newGVREF(0,$1); }
1315         ;
1316
1317 /* Indirect objects */
1318 indirob :       BAREWORD
1319                         { $$ = scalar($1); }
1320         |       scalar %prec PREC_LOW
1321                         { $$ = scalar($1); }
1322         |       block
1323                         { $$ = op_scope($1); }
1324
1325         |       PRIVATEREF
1326                         { $$ = $1; }
1327         ;