lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_04';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $evalarg
 639     $filename
 640     $frame
 641     $hist
 642     $histfile
 643     $histsize
 644     $ImmediateStop
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $line
 650     $maxtrace
 651     $od
 652     $onetimeDump
 653     $onetimedumpDepth
 654     %option
 655     @options
 656     $osingle
 657     $otrace
 658     $OUT
 659     $packname
 660     $pager
 661     $post
 662     %postponed
 663     $prc
 664     $pre
 665     $pretype
 666     $psh
 667     @RememberOnROptions
 668     $remoteport
 669     @res
 670     $rl
 671     @saved
 672     $signal
 673     $signalLevel
 674     $single
 675     $start
 676     $sub
 677     %sub
 678     $subname
 679     $term
 680     $trace
 681     $usercontext
 682     $warnLevel
 683     $window
 684 );
 685
 686 # Used to save @ARGV and extract any debugger-related flags.
 687 use vars qw(@ARGS);
 688
 689 # Used to prevent multiple entries to diesignal()
 690 # (if for instance diesignal() itself dies)
 691 use vars qw($panic);
 692
 693 # Used to prevent the debugger from running nonstop
 694 # after a restart
 695 use vars qw($second_time);
 696
 697 sub _calc_usercontext {
 698     my ($package) = @_;
 699
 700     # Cancel strict completely for the evaluated code, so the code
 701     # the user evaluates won't be affected by it. (Shlomi Fish)
 702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
 703     . "package $package;";    # this won't let them modify, alas
 704 }
 705
 706 sub eval {
 707
 708     # 'my' would make it visible from user code
 709     #    but so does local! --tchrist
 710     # Remember: this localizes @DB::res, not @main::res.
 711     local @res;
 712     {
 713
 714         # Try to keep the user code from messing  with us. Save these so that
 715         # even if the eval'ed code changes them, we can put them back again.
 716         # Needed because the user could refer directly to the debugger's
 717         # package globals (and any 'my' variables in this containing scope)
 718         # inside the eval(), and we want to try to stay safe.
 719         local $otrace  = $trace;
 720         local $osingle = $single;
 721         local $od      = $^D;
 722
 723         # Untaint the incoming eval() argument.
 724         { ($evalarg) = $evalarg =~ /(.*)/s; }
 725
 726         # $usercontext built in DB::DB near the comment
 727         # "set up the context for DB::eval ..."
 728         # Evaluate and save any results.
 729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 730
 731         # Restore those old values.
 732         $trace  = $otrace;
 733         $single = $osingle;
 734         $^D     = $od;
 735     }
 736
 737     # Save the current value of $@, and preserve it in the debugger's copy
 738     # of the saved precious globals.
 739     my $at = $@;
 740
 741     # Since we're only saving $@, we only have to localize the array element
 742     # that it will be stored in.
 743     local $saved[0];    # Preserve the old value of $@
 744     eval { &DB::save };
 745
 746     # Now see whether we need to report an error back to the user.
 747     if ($at) {
 748         local $\ = '';
 749         print $OUT $at;
 750     }
 751
 752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 753     # are package globals.
 754     elsif ($onetimeDump) {
 755         if ( $onetimeDump eq 'dump' ) {
 756             local $option{dumpDepth} = $onetimedumpDepth
 757               if defined $onetimedumpDepth;
 758             dumpit( $OUT, \@res );
 759         }
 760         elsif ( $onetimeDump eq 'methods' ) {
 761             methods( $res[0] );
 762         }
 763     } ## end elsif ($onetimeDump)
 764     @res;
 765 } ## end sub eval
 766
 767 ############################################## End lexical danger zone
 768
 769 # After this point it is safe to introduce lexicals.
 770 # The code being debugged will be executing in its own context, and
 771 # can't see the inside of the debugger.
 772 #
 773 # However, one should not overdo it: leave as much control from outside as
 774 # possible. If you make something a lexical, it's not going to be addressable
 775 # from outside the debugger even if you know its name.
 776
 777 # This file is automatically included if you do perl -d.
 778 # It's probably not useful to include this yourself.
 779 #
 780 # Before venturing further into these twisty passages, it is
 781 # wise to read the perldebguts man page or risk the ire of dragons.
 782 #
 783 # (It should be noted that perldebguts will tell you a lot about
 784 # the underlying mechanics of how the debugger interfaces into the
 785 # Perl interpreter, but not a lot about the debugger itself. The new
 786 # comments in this code try to address this problem.)
 787
 788 # Note that no subroutine call is possible until &DB::sub is defined
 789 # (for subroutines defined outside of the package DB). In fact the same is
 790 # true if $deep is not defined.
 791
 792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 793
 794 # modified Perl debugger, to be run from Emacs in perldb-mode
 795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 796 # Johan Vromans -- upgrade to 4.0 pl 10
 797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 798 ########################################################################
 799
 800 =head1 DEBUGGER INITIALIZATION
 801
 802 The debugger starts up in phases.
 803
 804 =head2 BASIC SETUP
 805
 806 First, it initializes the environment it wants to run in: turning off
 807 warnings during its own compilation, defining variables which it will need
 808 to avoid warnings later, setting itself up to not exit when the program
 809 terminates, and defaulting to printing return values for the C<r> command.
 810
 811 =cut
 812
 813 # Needed for the statement after exec():
 814 #
 815 # This BEGIN block is simply used to switch off warnings during debugger
 816 # compilation. Probably it would be better practice to fix the warnings,
 817 # but this is how it's done at the moment.
 818
 819 BEGIN {
 820     $ini_warn = $^W;
 821     $^W       = 0;
 822 }    # Switch compilation warnings off until another BEGIN.
 823
 824 local ($^W) = 0;    # Switch run-time warnings off during init.
 825
 826 =head2 THREADS SUPPORT
 827
 828 If we are running under a threaded Perl, we require threads and threads::shared
 829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 830 threaded debugger control.  C<-dt> can also be used to set this.
 831
 832 Each new thread will be announced and the debugger prompt will always inform
 833 you of each new thread created.  It will also indicate the thread id in which
 834 we are currently running within the prompt like this:
 835
 836         [tid] DB<$i>
 837
 838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 839 command prompt.  The prompt will show: C<[0]> when running under threads, but
 840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 841
 842 While running under threads, when you set or delete a breakpoint (etc.), this
 843 will apply to all threads, not just the currently running one.  When you are
 844 in a currently executing thread, you will stay there until it completes.  With
 845 the current implementation it is not currently possible to hop from one thread
 846 to another.
 847
 848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 849
 850 Note that threading support was built into the debugger as of Perl version
 851 C<5.8.6> and debugger version C<1.2.8>.
 852
 853 =cut
 854
 855 BEGIN {
 856   # ensure we can share our non-threaded variables or no-op
 857   if ($ENV{PERL5DB_THREADED}) {
 858         require threads;
 859         require threads::shared;
 860         import threads::shared qw(share);
 861         $DBGR;
 862         share(\$DBGR);
 863         lock($DBGR);
 864         print "Threads support enabled\n";
 865   } else {
 866         *lock  = sub(*) {};
 867         *share = sub(*) {};
 868   }
 869 }
 870
 871 # These variables control the execution of 'dumpvar.pl'.
 872 {
 873     package dumpvar;
 874     use vars qw(
 875     $hashDepth
 876     $arrayDepth
 877     $dumpDBFiles
 878     $dumpPackages
 879     $quoteHighBit
 880     $printUndef
 881     $globPrint
 882     $usageOnly
 883     );
 884 }
 885
 886 # used to control die() reporting in diesignal()
 887 {
 888     package Carp;
 889     use vars qw($CarpLevel);
 890 }
 891
 892 # without threads, $filename is not defined until DB::DB is called
 893 foreach my $k (keys (%INC)) {
 894         share(\$main::{'_<'.$filename}) if defined $filename;
 895 };
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 if ( exists $ENV{PERLDB_RESTART} ) {
1383
1384     # We're restarting, so we don't need the flag that says to restart anymore.
1385     delete $ENV{PERLDB_RESTART};
1386
1387     # $restart = 1;
1388     @hist          = get_list('PERLDB_HIST');
1389     %break_on_load = get_list("PERLDB_ON_LOAD");
1390     %postponed     = get_list("PERLDB_POSTPONE");
1391
1392         share(@hist);
1393         share(@truehist);
1394         share(%break_on_load);
1395         share(%postponed);
1396
1397     # restore breakpoints/actions
1398     my @had_breakpoints = get_list("PERLDB_VISITED");
1399     for my $file_idx ( 0 .. $#had_breakpoints ) {
1400         my $filename = $had_breakpoints[$file_idx];
1401         my %pf = get_list("PERLDB_FILE_$file_idx");
1402         $postponed_file{ $filename } = \%pf if %pf;
1403         my @lines = sort {$a <=> $b} keys(%pf);
1404         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1405         for my $line_idx (0 .. $#lines) {
1406             _set_breakpoint_enabled_status(
1407                 $filename,
1408                 $lines[$line_idx],
1409                 ($enabled_statuses[$line_idx] ? 1 : ''),
1410             );
1411         }
1412     }
1413
1414     # restore options
1415     my %opt = get_list("PERLDB_OPT");
1416     my ( $opt, $val );
1417     while ( ( $opt, $val ) = each %opt ) {
1418         $val =~ s/[\\\']/\\$1/g;
1419         parse_options("$opt'$val'");
1420     }
1421
1422     # restore original @INC
1423     @INC     = get_list("PERLDB_INC");
1424     @ini_INC = @INC;
1425
1426     # return pre/postprompt actions and typeahead buffer
1427     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1428     $pre       = [ get_list("PERLDB_PRE") ];
1429     $post      = [ get_list("PERLDB_POST") ];
1430     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1431 } ## end if (exists $ENV{PERLDB_RESTART...
1432
1433 =head2 SETTING UP THE TERMINAL
1434
1435 Now, we'll decide how the debugger is going to interact with the user.
1436 If there's no TTY, we set the debugger to run non-stop; there's not going
1437 to be anyone there to enter commands.
1438
1439 =cut
1440
1441 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1442 use vars qw($lineinfo $doccmd);
1443
1444 if ($notty) {
1445     $runnonstop = 1;
1446         share($runnonstop);
1447 }
1448
1449 =pod
1450
1451 If there is a TTY, we have to determine who it belongs to before we can
1452 proceed. If this is a slave editor or graphical debugger (denoted by
1453 the first command-line switch being '-emacs'), we shift this off and
1454 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1455
1456 =cut
1457
1458 else {
1459
1460     # Is Perl being run from a slave editor or graphical debugger?
1461     # If so, don't use readline, and set $slave_editor = 1.
1462     $slave_editor =
1463       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1464     $rl = 0, shift(@main::ARGV) if $slave_editor;
1465
1466     #require Term::ReadLine;
1467
1468 =pod
1469
1470 We then determine what the console should be on various systems:
1471
1472 =over 4
1473
1474 =item * Cygwin - We use C<stdin> instead of a separate device.
1475
1476 =cut
1477
1478     if ( $^O eq 'cygwin' ) {
1479
1480         # /dev/tty is binary. use stdin for textmode
1481         undef $console;
1482     }
1483
1484 =item * Unix - use C</dev/tty>.
1485
1486 =cut
1487
1488     elsif ( -e "/dev/tty" ) {
1489         $console = "/dev/tty";
1490     }
1491
1492 =item * Windows or MSDOS - use C<con>.
1493
1494 =cut
1495
1496     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1497         $console = "con";
1498     }
1499
1500 =item * VMS - use C<sys$command>.
1501
1502 =cut
1503
1504     else {
1505
1506         # everything else is ...
1507         $console = "sys\$command";
1508     }
1509
1510 =pod
1511
1512 =back
1513
1514 Several other systems don't use a specific console. We C<undef $console>
1515 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1516 with a slave editor, Epoc).
1517
1518 =cut
1519
1520     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1521
1522         # /dev/tty is binary. use stdin for textmode
1523         $console = undef;
1524     }
1525
1526     if ( $^O eq 'NetWare' ) {
1527
1528         # /dev/tty is binary. use stdin for textmode
1529         $console = undef;
1530     }
1531
1532     # In OS/2, we need to use STDIN to get textmode too, even though
1533     # it pretty much looks like Unix otherwise.
1534     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1535     {    # In OS/2
1536         $console = undef;
1537     }
1538
1539     # EPOC also falls into the 'got to use STDIN' camp.
1540     if ( $^O eq 'epoc' ) {
1541         $console = undef;
1542     }
1543
1544 =pod
1545
1546 If there is a TTY hanging around from a parent, we use that as the console.
1547
1548 =cut
1549
1550     $console = $tty if defined $tty;
1551
1552 =head2 SOCKET HANDLING
1553
1554 The debugger is capable of opening a socket and carrying out a debugging
1555 session over the socket.
1556
1557 If C<RemotePort> was defined in the options, the debugger assumes that it
1558 should try to start a debugging session on that port. It builds the socket
1559 and then tries to connect the input and output filehandles to it.
1560
1561 =cut
1562
1563     # Handle socket stuff.
1564
1565     if ( defined $remoteport ) {
1566
1567         # If RemotePort was defined in the options, connect input and output
1568         # to the socket.
1569         $IN = $OUT = connect_remoteport();
1570     } ## end if (defined $remoteport)
1571
1572 =pod
1573
1574 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1575 this is probably a situation where multiple debuggers are running (for example,
1576 a backticked command that starts up another debugger). We create a new IN and
1577 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1578 and if we can.
1579
1580 =cut
1581
1582     # Non-socket.
1583     else {
1584
1585         # Two debuggers running (probably a system or a backtick that invokes
1586         # the debugger itself under the running one). create a new IN and OUT
1587         # filehandle, and do the necessary mojo to create a new tty if we
1588         # know how, and we can.
1589         create_IN_OUT(4) if $CreateTTY & 4;
1590         if ($console) {
1591
1592             # If we have a console, check to see if there are separate ins and
1593             # outs to open. (They are assumed identical if not.)
1594
1595             my ( $i, $o ) = split /,/, $console;
1596             $o = $i unless defined $o;
1597
1598             # read/write on in, or just read, or read on STDIN.
1599             open( IN,      "+<$i" )
1600               || open( IN, "<$i" )
1601               || open( IN, "<&STDIN" );
1602
1603             # read/write/create/clobber out, or write/create/clobber out,
1604             # or merge with STDERR, or merge with STDOUT.
1605                  open( OUT, "+>$o" )
1606               || open( OUT, ">$o" )
1607               || open( OUT, ">&STDERR" )
1608               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1609
1610         } ## end if ($console)
1611         elsif ( not defined $console ) {
1612
1613             # No console. Open STDIN.
1614             open( IN, "<&STDIN" );
1615
1616             # merge with STDERR, or with STDOUT.
1617             open( OUT,      ">&STDERR" )
1618               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1619             $console = 'STDIN/OUT';
1620         } ## end elsif (not defined $console)
1621
1622         # Keep copies of the filehandles so that when the pager runs, it
1623         # can close standard input without clobbering ours.
1624         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1625     } ## end elsif (from if(defined $remoteport))
1626
1627     # Unbuffer DB::OUT. We need to see responses right away.
1628     $OUT->autoflush(1);
1629
1630     # Line info goes to debugger output unless pointed elsewhere.
1631     # Pointing elsewhere makes it possible for slave editors to
1632     # keep track of file and position. We have both a filehandle
1633     # and a I/O description to keep track of.
1634     $LINEINFO = $OUT     unless defined $LINEINFO;
1635     $lineinfo = $console unless defined $lineinfo;
1636         # share($LINEINFO); # <- unable to share globs
1637         share($lineinfo);   #
1638
1639 =pod
1640
1641 To finish initialization, we show the debugger greeting,
1642 and then call the C<afterinit()> subroutine if there is one.
1643
1644 =cut
1645
1646     # Show the debugger greeting.
1647     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1648     unless ($runnonstop) {
1649         local $\ = '';
1650         local $, = '';
1651         if ( $term_pid eq '-1' ) {
1652             print $OUT "\nDaughter DB session started...\n";
1653         }
1654         else {
1655             print $OUT "\nLoading DB routines from $header\n";
1656             print $OUT (
1657                 "Editor support ",
1658                 $slave_editor ? "enabled" : "available", ".\n"
1659             );
1660             print $OUT
1661 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1662         } ## end else [ if ($term_pid eq '-1')
1663     } ## end unless ($runnonstop)
1664 } ## end else [ if ($notty)
1665
1666 # XXX This looks like a bug to me.
1667 # Why copy to @ARGS and then futz with @args?
1668 @ARGS = @ARGV;
1669 # for (@args) {
1670     # Make sure backslashes before single quotes are stripped out, and
1671     # keep args unless they are numeric (XXX why?)
1672     # s/\'/\\\'/g;                      # removed while not justified understandably
1673     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1674 # }
1675
1676 # If there was an afterinit() sub defined, call it. It will get
1677 # executed in our scope, so it can fiddle with debugger globals.
1678 if ( defined &afterinit ) {    # May be defined in $rcfile
1679     &afterinit();
1680 }
1681
1682 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1683 use vars qw($I_m_init);
1684
1685 $I_m_init = 1;
1686
1687 ############################################################ Subroutines
1688
1689 =head1 SUBROUTINES
1690
1691 =head2 DB
1692
1693 This gigantic subroutine is the heart of the debugger. Called before every
1694 statement, its job is to determine if a breakpoint has been reached, and
1695 stop if so; read commands from the user, parse them, and execute
1696 them, and then send execution off to the next statement.
1697
1698 Note that the order in which the commands are processed is very important;
1699 some commands earlier in the loop will actually alter the C<$cmd> variable
1700 to create other commands to be executed later. This is all highly I<optimized>
1701 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1702 see what's happening in any given command.
1703
1704 =cut
1705
1706 use vars qw(
1707     $action
1708     %alias
1709     $cmd
1710     $doret
1711     $fall_off_end
1712     $file
1713     $filename_ini
1714     $finished
1715     %had_breakpoints
1716     $incr
1717     $laststep
1718     $level
1719     $max
1720     @old_watch
1721     $package
1722     $rc
1723     $sh
1724     @stack
1725     $stack_depth
1726     @to_watch
1727     $try
1728     $end
1729 );
1730
1731 sub DB {
1732
1733     # lock the debugger and get the thread id for the prompt
1734         lock($DBGR);
1735         my $tid;
1736         my $position;
1737         my ($prefix, $after, $infix);
1738         my $pat;
1739
1740         if ($ENV{PERL5DB_THREADED}) {
1741                 $tid = eval { "[".threads->tid."]" };
1742         }
1743
1744     # Check for whether we should be running continuously or not.
1745     # _After_ the perl program is compiled, $single is set to 1:
1746     if ( $single and not $second_time++ ) {
1747
1748         # Options say run non-stop. Run until we get an interrupt.
1749         if ($runnonstop) {    # Disable until signal
1750                 # If there's any call stack in place, turn off single
1751                 # stepping into subs throughout the stack.
1752             for my $i (0 .. $stack_depth) {
1753                 $stack[ $i ] &= ~1;
1754             }
1755
1756             # And we are now no longer in single-step mode.
1757             $single = 0;
1758
1759             # If we simply returned at this point, we wouldn't get
1760             # the trace info. Fall on through.
1761             # return;
1762         } ## end if ($runnonstop)
1763
1764         elsif ($ImmediateStop) {
1765
1766             # We are supposed to stop here; XXX probably a break.
1767             $ImmediateStop = 0;    # We've processed it; turn it off
1768             $signal        = 1;    # Simulate an interrupt to force
1769                                    # us into the command loop
1770         }
1771     } ## end if ($single and not $second_time...
1772
1773     # If we're in single-step mode, or an interrupt (real or fake)
1774     # has occurred, turn off non-stop mode.
1775     $runnonstop = 0 if $single or $signal;
1776
1777     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1778     # The code being debugged may have altered them.
1779     &save;
1780
1781     # Since DB::DB gets called after every line, we can use caller() to
1782     # figure out where we last were executing. Sneaky, eh? This works because
1783     # caller is returning all the extra information when called from the
1784     # debugger.
1785     local ( $package, $filename, $line ) = caller;
1786     $filename_ini = $filename;
1787
1788     # set up the context for DB::eval, so it can properly execute
1789     # code on behalf of the user. We add the package in so that the
1790     # code is eval'ed in the proper package (not in the debugger!).
1791     local $usercontext = _calc_usercontext($package);
1792
1793     # Create an alias to the active file magical array to simplify
1794     # the code here.
1795     local (*dbline) = $main::{ '_<' . $filename };
1796
1797     # Last line in the program.
1798     $max = $#dbline;
1799
1800     # if we have something here, see if we should break.
1801     {
1802         # $stop is lexical and local to this block - $action on the other hand
1803         # is global.
1804         my $stop;
1805
1806         if ( $dbline{$line}
1807             && _is_breakpoint_enabled($filename, $line)
1808             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1809         {
1810
1811             # Stop if the stop criterion says to just stop.
1812             if ( $stop eq '1' ) {
1813                 $signal |= 1;
1814             }
1815
1816             # It's a conditional stop; eval it in the user's context and
1817             # see if we should stop. If so, remove the one-time sigil.
1818             elsif ($stop) {
1819                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1820                 &eval;
1821                 # If the breakpoint is temporary, then delete its enabled status.
1822                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1823                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1824                 }
1825             }
1826         } ## end if ($dbline{$line} && ...
1827     }
1828
1829     # Preserve the current stop-or-not, and see if any of the W
1830     # (watch expressions) has changed.
1831     my $was_signal = $signal;
1832
1833     # If we have any watch expressions ...
1834     if ( $trace & 2 ) {
1835         for my $n (0 .. $#to_watch) {
1836             $evalarg = $to_watch[$n];
1837             local $onetimeDump;    # Tell DB::eval() to not output results
1838
1839             # Fix context DB::eval() wants to return an array, but
1840             # we need a scalar here.
1841             my ($val) = join( "', '", &eval );
1842             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1843
1844             # Did it change?
1845             if ( $val ne $old_watch[$n] ) {
1846
1847                 # Yep! Show the difference, and fake an interrupt.
1848                 $signal = 1;
1849                 print $OUT <<EOP;
1850 Watchpoint $n:\t$to_watch[$n] changed:
1851     old value:\t$old_watch[$n]
1852     new value:\t$val
1853 EOP
1854                 $old_watch[$n] = $val;
1855             } ## end if ($val ne $old_watch...
1856         } ## end for my $n (0 ..
1857     } ## end if ($trace & 2)
1858
1859 =head2 C<watchfunction()>
1860
1861 C<watchfunction()> is a function that can be defined by the user; it is a
1862 function which will be run on each entry to C<DB::DB>; it gets the
1863 current package, filename, and line as its parameters.
1864
1865 The watchfunction can do anything it likes; it is executing in the
1866 debugger's context, so it has access to all of the debugger's internal
1867 data structures and functions.
1868
1869 C<watchfunction()> can control the debugger's actions. Any of the following
1870 will cause the debugger to return control to the user's program after
1871 C<watchfunction()> executes:
1872
1873 =over 4
1874
1875 =item *
1876
1877 Returning a false value from the C<watchfunction()> itself.
1878
1879 =item *
1880
1881 Altering C<$single> to a false value.
1882
1883 =item *
1884
1885 Altering C<$signal> to a false value.
1886
1887 =item *
1888
1889 Turning off the C<4> bit in C<$trace> (this also disables the
1890 check for C<watchfunction()>. This can be done with
1891
1892     $trace &= ~4;
1893
1894 =back
1895
1896 =cut
1897
1898     # If there's a user-defined DB::watchfunction, call it with the
1899     # current package, filename, and line. The function executes in
1900     # the DB:: package.
1901     if ( $trace & 4 ) {    # User-installed watch
1902         return
1903           if watchfunction( $package, $filename, $line )
1904           and not $single
1905           and not $was_signal
1906           and not( $trace & ~4 );
1907     } ## end if ($trace & 4)
1908
1909     # Pick up any alteration to $signal in the watchfunction, and
1910     # turn off the signal now.
1911     $was_signal = $signal;
1912     $signal     = 0;
1913
1914 =head2 GETTING READY TO EXECUTE COMMANDS
1915
1916 The debugger decides to take control if single-step mode is on, the
1917 C<t> command was entered, or the user generated a signal. If the program
1918 has fallen off the end, we set things up so that entering further commands
1919 won't cause trouble, and we say that the program is over.
1920
1921 =cut
1922
1923     # Make sure that we always print if asked for explicitly regardless
1924     # of $trace_to_depth .
1925     my $explicit_stop = ($single || $was_signal);
1926
1927     # Check to see if we should grab control ($single true,
1928     # trace set appropriately, or we got a signal).
1929     if ( $explicit_stop || ( $trace & 1 ) ) {
1930
1931         # Yes, grab control.
1932         if ($slave_editor) {
1933
1934             # Tell the editor to update its position.
1935             $position = "\032\032$filename:$line:0\n";
1936             print_lineinfo($position);
1937         }
1938
1939 =pod
1940
1941 Special check: if we're in package C<DB::fake>, we've gone through the
1942 C<END> block at least once. We set up everything so that we can continue
1943 to enter commands and have a valid context to be in.
1944
1945 =cut
1946
1947         elsif ( $package eq 'DB::fake' ) {
1948
1949             # Fallen off the end already.
1950             $term || &setterm;
1951             print_help(<<EOP);
1952 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1953   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1954   B<h q>, B<h R> or B<h o> to get additional info.
1955 EOP
1956
1957             # Set the DB::eval context appropriately.
1958             $package     = 'main';
1959             $usercontext = _calc_usercontext($package);
1960         } ## end elsif ($package eq 'DB::fake')
1961
1962 =pod
1963
1964 If the program hasn't finished executing, we scan forward to the
1965 next executable line, print that out, build the prompt from the file and line
1966 number information, and print that.
1967
1968 =cut
1969
1970         else {
1971
1972
1973             # Still somewhere in the midst of execution. Set up the
1974             #  debugger prompt.
1975             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1976                                  # Perl 5 ones (sorry, we don't print Klingon
1977                                  #module names)
1978
1979             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1980             $prefix .= "$sub($filename:";
1981             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1982
1983             # Break up the prompt if it's really long.
1984             if ( length($prefix) > 30 ) {
1985                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1986                 $prefix   = "";
1987                 $infix    = ":\t";
1988             }
1989             else {
1990                 $infix    = "):\t";
1991                 $position = "$prefix$line$infix$dbline[$line]$after";
1992             }
1993
1994             # Print current line info, indenting if necessary.
1995             if ($frame) {
1996                 print_lineinfo( ' ' x $stack_depth,
1997                     "$line:\t$dbline[$line]$after" );
1998             }
1999             else {
2000                 depth_print_lineinfo($explicit_stop, $position);
2001             }
2002
2003             # Scan forward, stopping at either the end or the next
2004             # unbreakable line.
2005             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2006             {    #{ vi
2007
2008                 # Drop out on null statements, block closers, and comments.
2009                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2010
2011                 # Drop out if the user interrupted us.
2012                 last if $signal;
2013
2014                 # Append a newline if the line doesn't have one. Can happen
2015                 # in eval'ed text, for instance.
2016                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2017
2018                 # Next executable line.
2019                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2020                 $position .= $incr_pos;
2021                 if ($frame) {
2022
2023                     # Print it indented if tracing is on.
2024                     print_lineinfo( ' ' x $stack_depth,
2025                         "$i:\t$dbline[$i]$after" );
2026                 }
2027                 else {
2028                     depth_print_lineinfo($explicit_stop, $incr_pos);
2029                 }
2030             } ## end for ($i = $line + 1 ; $i...
2031         } ## end else [ if ($slave_editor)
2032     } ## end if ($single || ($trace...
2033
2034 =pod
2035
2036 If there's an action to be executed for the line we stopped at, execute it.
2037 If there are any preprompt actions, execute those as well.
2038
2039 =cut
2040
2041     # If there's an action, do it now.
2042     $evalarg = $action, &eval if $action;
2043
2044     # Are we nested another level (e.g., did we evaluate a function
2045     # that had a breakpoint in it at the debugger prompt)?
2046     if ( $single || $was_signal ) {
2047
2048         # Yes, go down a level.
2049         local $level = $level + 1;
2050
2051         # Do any pre-prompt actions.
2052         foreach $evalarg (@$pre) {
2053             &eval;
2054         }
2055
2056         # Complain about too much recursion if we passed the limit.
2057         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2058           if $single & 4;
2059
2060         # The line we're currently on. Set $incr to -1 to stay here
2061         # until we get a command that tells us to advance.
2062         $start = $line;
2063         $incr  = -1;      # for backward motion.
2064
2065         # Tack preprompt debugger actions ahead of any actual input.
2066         @typeahead = ( @$pretype, @typeahead );
2067
2068 =head2 WHERE ARE WE?
2069
2070 XXX Relocate this section?
2071
2072 The debugger normally shows the line corresponding to the current line of
2073 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2074 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2075
2076 C<$incr> controls by how many lines the I<current> line should move forward
2077 after a command is executed. If set to -1, this indicates that the I<current>
2078 line shouldn't change.
2079
2080 C<$start> is the I<current> line. It is used for things like knowing where to
2081 move forwards or backwards from when doing an C<L> or C<-> command.
2082
2083 C<$max> tells the debugger where the last line of the current file is. It's
2084 used to terminate loops most often.
2085
2086 =head2 THE COMMAND LOOP
2087
2088 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2089 in two parts:
2090
2091 =over 4
2092
2093 =item *
2094
2095 The outer part of the loop, starting at the C<CMD> label. This loop
2096 reads a command and then executes it.
2097
2098 =item *
2099
2100 The inner part of the loop, starting at the C<PIPE> label. This part
2101 is wholly contained inside the C<CMD> block and only executes a command.
2102 Used to handle commands running inside a pager.
2103
2104 =back
2105
2106 So why have two labels to restart the loop? Because sometimes, it's easier to
2107 have a command I<generate> another command and then re-execute the loop to do
2108 the new command. This is faster, but perhaps a bit more convoluted.
2109
2110 =cut
2111
2112         # The big command dispatch loop. It keeps running until the
2113         # user yields up control again.
2114         #
2115         # If we have a terminal for input, and we get something back
2116         # from readline(), keep on processing.
2117         my $piped;
2118         my $selected;
2119
2120       CMD:
2121         while (
2122
2123             # We have a terminal, or can get one ...
2124             ( $term || &setterm ),
2125
2126             # ... and it belogs to this PID or we get one for this PID ...
2127             ( $term_pid == $$ or resetterm(1) ),
2128
2129             # ... and we got a line of command input ...
2130             defined(
2131                 $cmd = &readline(
2132                         "$pidprompt $tid DB"
2133                       . ( '<' x $level )
2134                       . ( $#hist + 1 )
2135                       . ( '>' x $level ) . " "
2136                 )
2137             )
2138           )
2139         {
2140
2141                         share($cmd);
2142             # ... try to execute the input as debugger commands.
2143
2144             # Don't stop running.
2145             $single = 0;
2146
2147             # No signal is active.
2148             $signal = 0;
2149
2150             # Handle continued commands (ending with \):
2151             if ($cmd =~ s/\\\z/\n/) {
2152                 $cmd .= &readline("  cont: ");
2153                 redo CMD;
2154             }
2155
2156 =head4 The null command
2157
2158 A newline entered by itself means I<re-execute the last command>. We grab the
2159 command out of C<$laststep> (where it was recorded previously), and copy it
2160 back into C<$cmd> to be executed below. If there wasn't any previous command,
2161 we'll do nothing below (no command will match). If there was, we also save it
2162 in the command history and fall through to allow the command parsing to pick
2163 it up.
2164
2165 =cut
2166
2167             # Empty input means repeat the last command.
2168             $cmd =~ /^$/ && ( $cmd = $laststep );
2169             chomp($cmd);    # get rid of the annoying extra newline
2170             push( @hist, $cmd ) if length($cmd) > 1;
2171             push( @truehist, $cmd );
2172                         share(@hist);
2173                         share(@truehist);
2174
2175             # This is a restart point for commands that didn't arrive
2176             # via direct user input. It allows us to 'redo PIPE' to
2177             # re-execute command processing without reading a new command.
2178           PIPE: {
2179                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2180                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2181                 my ($i) = split( /\s+/, $cmd );
2182
2183 =head3 COMMAND ALIASES
2184
2185 The debugger can create aliases for commands (these are stored in the
2186 C<%alias> hash). Before a command is executed, the command loop looks it up
2187 in the alias hash and substitutes the contents of the alias for the command,
2188 completely replacing it.
2189
2190 =cut
2191
2192                 # See if there's an alias for the command, and set it up if so.
2193                 if ( $alias{$i} ) {
2194
2195                     # Squelch signal handling; we want to keep control here
2196                     # if something goes loco during the alias eval.
2197                     local $SIG{__DIE__};
2198                     local $SIG{__WARN__};
2199
2200                     # This is a command, so we eval it in the DEBUGGER's
2201                     # scope! Otherwise, we can't see the special debugger
2202                     # variables, or get to the debugger's subs. (Well, we
2203                     # _could_, but why make it even more complicated?)
2204                     eval "\$cmd =~ $alias{$i}";
2205                     if ($@) {
2206                         local $\ = '';
2207                         print $OUT "Couldn't evaluate '$i' alias: $@";
2208                         next CMD;
2209                     }
2210                 } ## end if ($alias{$i})
2211
2212 =head3 MAIN-LINE COMMANDS
2213
2214 All of these commands work up to and after the program being debugged has
2215 terminated.
2216
2217 =head4 C<q> - quit
2218
2219 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2220 try to execute further, cleaning any restart-related stuff out of the
2221 environment, and executing with the last value of C<$?>.
2222
2223 =cut
2224
2225                 if ($cmd eq 'q') {
2226                     $fall_off_end = 1;
2227                     clean_ENV();
2228                     exit $?;
2229                 }
2230
2231 =head4 C<t> - trace [n]
2232
2233 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2234 If level is specified, set C<$trace_to_depth>.
2235
2236 =cut
2237
2238                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2239                     $trace ^= 1;
2240                     local $\ = '';
2241                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2242                     print $OUT "Trace = "
2243                       . ( ( $trace & 1 )
2244                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2245                       : "off" ) . "\n";
2246                     next CMD;
2247                 }
2248
2249 =head4 C<S> - list subroutines matching/not matching a pattern
2250
2251 Walks through C<%sub>, checking to see whether or not to print the name.
2252
2253 =cut
2254
2255                 if (my ($print_all_subs, $should_reverse, $Spatt)
2256                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2257                     # $Spatt is the pattern (if any) to use.
2258                     # Reverse scan?
2259                     my $Srev     = defined $should_reverse;
2260                     # No args - print all subs.
2261                     my $Snocheck = !defined $print_all_subs;
2262
2263                     # Need to make these sane here.
2264                     local $\ = '';
2265                     local $, = '';
2266
2267                     # Search through the debugger's magical hash of subs.
2268                     # If $nocheck is true, just print the sub name.
2269                     # Otherwise, check it against the pattern. We then use
2270                     # the XOR trick to reverse the condition as required.
2271                     foreach $subname ( sort( keys %sub ) ) {
2272                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2273                             print $OUT $subname, "\n";
2274                         }
2275                     }
2276                     next CMD;
2277                 }
2278
2279 =head4 C<X> - list variables in current package
2280
2281 Since the C<V> command actually processes this, just change this to the
2282 appropriate C<V> command and fall through.
2283
2284 =cut
2285
2286                 $cmd =~ s/^X\b/V $package/;
2287
2288 =head4 C<V> - list variables
2289
2290 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2291
2292 =cut
2293
2294                 # Bare V commands get the currently-being-debugged package
2295                 # added.
2296                 if ($cmd eq "V") {
2297                     $cmd = "V $package";
2298                 }
2299
2300                 # V - show variables in package.
2301                 if (my ($new_packname, $new_vars_str) =
2302                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2303
2304                     # Save the currently selected filehandle and
2305                     # force output to debugger's filehandle (dumpvar
2306                     # just does "print" for output).
2307                     my $savout = select($OUT);
2308
2309                     # Grab package name and variables to dump.
2310                     $packname = $new_packname;
2311                     my @vars     = split( ' ', $new_vars_str );
2312
2313                     # If main::dumpvar isn't here, get it.
2314                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2315                     if ( defined &main::dumpvar ) {
2316
2317                         # We got it. Turn off subroutine entry/exit messages
2318                         # for the moment, along with return values.
2319                         local $frame = 0;
2320                         local $doret = -2;
2321
2322                         # must detect sigpipe failures  - not catching
2323                         # then will cause the debugger to die.
2324                         eval {
2325                             &main::dumpvar(
2326                                 $packname,
2327                                 defined $option{dumpDepth}
2328                                 ? $option{dumpDepth}
2329                                 : -1,    # assume -1 unless specified
2330                                 @vars
2331                             );
2332                         };
2333
2334                         # The die doesn't need to include the $@, because
2335                         # it will automatically get propagated for us.
2336                         if ($@) {
2337                             die unless $@ =~ /dumpvar print failed/;
2338                         }
2339                     } ## end if (defined &main::dumpvar)
2340                     else {
2341
2342                         # Couldn't load dumpvar.
2343                         print $OUT "dumpvar.pl not available.\n";
2344                     }
2345
2346                     # Restore the output filehandle, and go round again.
2347                     select($savout);
2348                     next CMD;
2349                 }
2350
2351 =head4 C<x> - evaluate and print an expression
2352
2353 Hands the expression off to C<DB::eval>, setting it up to print the value
2354 via C<dumpvar.pl> instead of just printing it directly.
2355
2356 =cut
2357
2358                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2359                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2360
2361                     # handle special  "x 3 blah" syntax XXX propagate
2362                     # doc back to special variables.
2363                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2364                         $onetimedumpDepth = $1;
2365                     }
2366                 }
2367
2368 =head4 C<m> - print methods
2369
2370 Just uses C<DB::methods> to determine what methods are available.
2371
2372 =cut
2373
2374                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2375                     methods($1);
2376                     next CMD;
2377                 }
2378
2379                 # m expr - set up DB::eval to do the work
2380                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2381                     $onetimeDump = 'methods';   #  method output gets used there
2382                 }
2383
2384 =head4 C<f> - switch files
2385
2386 =cut
2387
2388                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2389                     $file =~ s/\s+$//;
2390
2391                     # help for no arguments (old-style was return from sub).
2392                     if ( !$file ) {
2393                         print $OUT
2394                           "The old f command is now the r command.\n";    # hint
2395                         print $OUT "The new f command switches filenames.\n";
2396                         next CMD;
2397                     } ## end if (!$file)
2398
2399                     # if not in magic file list, try a close match.
2400                     if ( !defined $main::{ '_<' . $file } ) {
2401                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2402                             {
2403                                 $try = substr( $try, 2 );
2404                                 print $OUT "Choosing $try matching '$file':\n";
2405                                 $file = $try;
2406                             }
2407                         } ## end if (($try) = grep(m#^_<.*$file#...
2408                     } ## end if (!defined $main::{ ...
2409
2410                     # If not successfully switched now, we failed.
2411                     if ( !defined $main::{ '_<' . $file } ) {
2412                         print $OUT "No file matching '$file' is loaded.\n";
2413                         next CMD;
2414                     }
2415
2416                     # We switched, so switch the debugger internals around.
2417                     elsif ( $file ne $filename ) {
2418                         *dbline   = $main::{ '_<' . $file };
2419                         $max      = $#dbline;
2420                         $filename = $file;
2421                         $start    = 1;
2422                         $cmd      = "l";
2423                     } ## end elsif ($file ne $filename)
2424
2425                     # We didn't switch; say we didn't.
2426                     else {
2427                         print $OUT "Already in $file.\n";
2428                         next CMD;
2429                     }
2430                 }
2431
2432 =head4 C<.> - return to last-executed line.
2433
2434 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2435 and then we look up the line in the magical C<%dbline> hash.
2436
2437 =cut
2438
2439                 # . command.
2440                 if ($cmd eq '.') {
2441                     $incr = -1;    # stay at current line
2442
2443                     # Reset everything to the old location.
2444                     $start    = $line;
2445                     $filename = $filename_ini;
2446                     *dbline   = $main::{ '_<' . $filename };
2447                     $max      = $#dbline;
2448
2449                     # Now where are we?
2450                     print_lineinfo($position);
2451                     next CMD;
2452                 }
2453
2454 =head4 C<-> - back one window
2455
2456 We change C<$start> to be one window back; if we go back past the first line,
2457 we set it to be the first line. We ser C<$incr> to put us back at the
2458 currently-executing line, and then put a C<l $start +> (list one window from
2459 C<$start>) in C<$cmd> to be executed later.
2460
2461 =cut
2462
2463                 # - - back a window.
2464                 if ($cmd eq '-') {
2465
2466                     # back up by a window; go to 1 if back too far.
2467                     $start -= $incr + $window + 1;
2468                     $start = 1 if $start <= 0;
2469                     $incr  = $window - 1;
2470
2471                     # Generate and execute a "l +" command (handled below).
2472                     $cmd = 'l ' . ($start) . '+';
2473                 }
2474
2475 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2476
2477 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2478 problems, most notably that the default case of several commands destroying
2479 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2480 retain the old commands for those who were used to using them or who preferred
2481 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2482 deal with them instead of processing them in-line.
2483
2484 =cut
2485
2486                 # All of these commands were remapped in perl 5.8.0;
2487                 # we send them off to the secondary dispatcher (see below).
2488                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2489                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2490                     next CMD;
2491                 }
2492
2493 =head4 C<y> - List lexicals in higher scope
2494
2495 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2496 above the current one and then displays then using C<dumpvar.pl>.
2497
2498 =cut
2499
2500                 if (my ($match_level, $match_vars)
2501                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2502
2503                     # See if we've got the necessary support.
2504                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2505                       or &warn(
2506                         $@ =~ /locate/
2507                         ? "PadWalker module not found - please install\n"
2508                         : $@
2509                       )
2510                       and next CMD;
2511
2512                     # Load up dumpvar if we don't have it. If we can, that is.
2513                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2514                     defined &main::dumpvar
2515                       or print $OUT "dumpvar.pl not available.\n"
2516                       and next CMD;
2517
2518                     # Got all the modules we need. Find them and print them.
2519                     my @vars = split( ' ', $match_vars || '' );
2520
2521                     # Find the pad.
2522                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2523
2524                     # Oops. Can't find it.
2525                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2526
2527                     # Show the desired vars with dumplex().
2528                     my $savout = select($OUT);
2529
2530                     # Have dumplex dump the lexicals.
2531                     dumpvar::dumplex( $_, $h->{$_},
2532                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2533                         @vars )
2534                       for sort keys %$h;
2535                     select($savout);
2536                     next CMD;
2537                 }
2538
2539 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2540
2541 All of the commands below this point don't work after the program being
2542 debugged has ended. All of them check to see if the program has ended; this
2543 allows the commands to be relocated without worrying about a 'line of
2544 demarcation' above which commands can be entered anytime, and below which
2545 they can't.
2546
2547 =head4 C<n> - single step, but don't trace down into subs
2548
2549 Done by setting C<$single> to 2, which forces subs to execute straight through
2550 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2551 so a null command knows what to re-execute.
2552
2553 =cut
2554
2555                 # n - next
2556                 if ($cmd eq 'n') {
2557                     end_report(), next CMD if $finished and $level <= 1;
2558
2559                     # Single step, but don't enter subs.
2560                     $single = 2;
2561
2562                     # Save for empty command (repeat last).
2563                     $laststep = $cmd;
2564                     last CMD;
2565                 }
2566
2567 =head4 C<s> - single-step, entering subs
2568
2569 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2570 subs. Also saves C<s> as C<$lastcmd>.
2571
2572 =cut
2573
2574                 # s - single step.
2575                 if ($cmd eq 's') {
2576
2577                     # Get out and restart the command loop if program
2578                     # has finished.
2579                     end_report(), next CMD if $finished and $level <= 1;
2580
2581                     # Single step should enter subs.
2582                     $single = 1;
2583
2584                     # Save for empty command (repeat last).
2585                     $laststep = $cmd;
2586                     last CMD;
2587                 }
2588
2589 =head4 C<c> - run continuously, setting an optional breakpoint
2590
2591 Most of the code for this command is taken up with locating the optional
2592 breakpoint, which is either a subroutine name or a line number. We set
2593 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2594 in this and all call levels above this one.
2595
2596 =cut
2597
2598                 # c - start continuous execution.
2599                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2600
2601                     # Hey, show's over. The debugged program finished
2602                     # executing already.
2603                     end_report(), next CMD if $finished and $level <= 1;
2604
2605                     # Capture the place to put a one-time break.
2606                     $subname = $i;
2607
2608                     #  Probably not needed, since we finish an interactive
2609                     #  sub-session anyway...
2610                     # local $filename = $filename;
2611                     # local *dbline = *dbline; # XXX Would this work?!
2612                     #
2613                     # The above question wonders if localizing the alias
2614                     # to the magic array works or not. Since it's commented
2615                     # out, we'll just leave that to speculation for now.
2616
2617                     # If the "subname" isn't all digits, we'll assume it
2618                     # is a subroutine name, and try to find it.
2619                     if ( $subname =~ /\D/ ) {    # subroutine name
2620                             # Qualify it to the current package unless it's
2621                             # already qualified.
2622                         $subname = $package . "::" . $subname
2623                           unless $subname =~ /::/;
2624
2625                         # find_sub will return "file:line_number" corresponding
2626                         # to where the subroutine is defined; we call find_sub,
2627                         # break up the return value, and assign it in one
2628                         # operation.
2629                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2630
2631                         # Force the line number to be numeric.
2632                         $i += 0;
2633
2634                         # If we got a line number, we found the sub.
2635                         if ($i) {
2636
2637                             # Switch all the debugger's internals around so
2638                             # we're actually working with that file.
2639                             $filename = $file;
2640                             *dbline   = $main::{ '_<' . $filename };
2641
2642                             # Mark that there's a breakpoint in this file.
2643                             $had_breakpoints{$filename} |= 1;
2644
2645                             # Scan forward to the first executable line
2646                             # after the 'sub whatever' line.
2647                             $max = $#dbline;
2648                             ++$i while $dbline[$i] == 0 && $i < $max;
2649                         } ## end if ($i)
2650
2651                         # We didn't find a sub by that name.
2652                         else {
2653                             print $OUT "Subroutine $subname not found.\n";
2654                             next CMD;
2655                         }
2656                     } ## end if ($subname =~ /\D/)
2657
2658                     # At this point, either the subname was all digits (an
2659                     # absolute line-break request) or we've scanned through
2660                     # the code following the definition of the sub, looking
2661                     # for an executable, which we may or may not have found.
2662                     #
2663                     # If $i (which we set $subname from) is non-zero, we
2664                     # got a request to break at some line somewhere. On
2665                     # one hand, if there wasn't any real subroutine name
2666                     # involved, this will be a request to break in the current
2667                     # file at the specified line, so we have to check to make
2668                     # sure that the line specified really is breakable.
2669                     #
2670                     # On the other hand, if there was a subname supplied, the
2671                     # preceding block has moved us to the proper file and
2672                     # location within that file, and then scanned forward
2673                     # looking for the next executable line. We have to make
2674                     # sure that one was found.
2675                     #
2676                     # On the gripping hand, we can't do anything unless the
2677                     # current value of $i points to a valid breakable line.
2678                     # Check that.
2679                     if ($i) {
2680
2681                         # Breakable?
2682                         if ( $dbline[$i] == 0 ) {
2683                             print $OUT "Line $i not breakable.\n";
2684                             next CMD;
2685                         }
2686
2687                         # Yes. Set up the one-time-break sigil.
2688                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2689                         _enable_breakpoint_temp_enabled_status($filename, $i);
2690                     } ## end if ($i)
2691
2692                     # Turn off stack tracing from here up.
2693                     for my $i (0 .. $stack_depth) {
2694                         $stack[ $i ] &= ~1;
2695                     }
2696                     last CMD;
2697                 }
2698
2699 =head4 C<r> - return from a subroutine
2700
2701 For C<r> to work properly, the debugger has to stop execution again
2702 immediately after the return is executed. This is done by forcing
2703 single-stepping to be on in the call level above the current one. If
2704 we are printing return values when a C<r> is executed, set C<$doret>
2705 appropriately, and force us out of the command loop.
2706
2707 =cut
2708
2709                 # r - return from the current subroutine.
2710                 if ($cmd eq 'r') {
2711
2712                     # Can't do anything if the program's over.
2713                     end_report(), next CMD if $finished and $level <= 1;
2714
2715                     # Turn on stack trace.
2716                     $stack[$stack_depth] |= 1;
2717
2718                     # Print return value unless the stack is empty.
2719                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2720                     last CMD;
2721                 }
2722
2723 =head4 C<T> - stack trace
2724
2725 Just calls C<DB::print_trace>.
2726
2727 =cut
2728
2729                 if ($cmd eq 'T') {
2730                     print_trace( $OUT, 1 );    # skip DB
2731                     next CMD;
2732                 }
2733
2734 =head4 C<w> - List window around current line.
2735
2736 Just calls C<DB::cmd_w>.
2737
2738 =cut
2739
2740                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2741                     &cmd_w( 'w', $arg );
2742                     next CMD;
2743                 }
2744
2745 =head4 C<W> - watch-expression processing.
2746
2747 Just calls C<DB::cmd_W>.
2748
2749 =cut
2750
2751                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2752                     &cmd_W( 'W', $arg );
2753                     next CMD;
2754                 }
2755
2756 =head4 C</> - search forward for a string in the source
2757
2758 We take the argument and treat it as a pattern. If it turns out to be a
2759 bad one, we return the error we got from trying to C<eval> it and exit.
2760 If not, we create some code to do the search and C<eval> it so it can't
2761 mess us up.
2762
2763 =cut
2764
2765                 # The pattern as a string.
2766                 use vars qw($inpat);
2767
2768                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2769
2770                     # Remove the final slash.
2771                     $inpat =~ s:([^\\])/$:$1:;
2772
2773                     # If the pattern isn't null ...
2774                     if ( $inpat ne "" ) {
2775
2776                         # Turn of warn and die procesing for a bit.
2777                         local $SIG{__DIE__};
2778                         local $SIG{__WARN__};
2779
2780                         # Create the pattern.
2781                         eval '$inpat =~ m' . "\a$inpat\a";
2782                         if ( $@ ne "" ) {
2783
2784                             # Oops. Bad pattern. No biscuit.
2785                             # Print the eval error and go back for more
2786                             # commands.
2787                             print $OUT "$@";
2788                             next CMD;
2789                         }
2790                         $pat = $inpat;
2791                     } ## end if ($inpat ne "")
2792
2793                     # Set up to stop on wrap-around.
2794                     $end = $start;
2795
2796                     # Don't move off the current line.
2797                     $incr = -1;
2798
2799                     # Done in eval so nothing breaks if the pattern
2800                     # does something weird.
2801                     eval '
2802                         for (;;) {
2803                             # Move ahead one line.
2804                             ++$start;
2805
2806                             # Wrap if we pass the last line.
2807                             $start = 1 if ($start > $max);
2808
2809                             # Stop if we have gotten back to this line again,
2810                             last if ($start == $end);
2811
2812                             # A hit! (Note, though, that we are doing
2813                             # case-insensitive matching. Maybe a qr//
2814                             # expression would be better, so the user could
2815                             # do case-sensitive matching if desired.
2816                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2817                                 if ($slave_editor) {
2818                                     # Handle proper escaping in the slave.
2819                                     print $OUT "\032\032$filename:$start:0\n";
2820                                 }
2821                                 else {
2822                                     # Just print the line normally.
2823                                     print $OUT "$start:\t",$dbline[$start],"\n";
2824                                 }
2825                                 # And quit since we found something.
2826                                 last;
2827                             }
2828                          } ';
2829
2830                     # If we wrapped, there never was a match.
2831                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2832                     next CMD;
2833                 }
2834
2835 =head4 C<?> - search backward for a string in the source
2836
2837 Same as for C</>, except the loop runs backwards.
2838
2839 =cut
2840
2841                 # ? - backward pattern search.
2842                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2843
2844                     # Get the pattern, remove trailing question mark.
2845                     $inpat =~ s:([^\\])\?$:$1:;
2846
2847                     # If we've got one ...
2848                     if ( $inpat ne "" ) {
2849
2850                         # Turn off die & warn handlers.
2851                         local $SIG{__DIE__};
2852                         local $SIG{__WARN__};
2853                         eval '$inpat =~ m' . "\a$inpat\a";
2854
2855                         if ( $@ ne "" ) {
2856
2857                             # Ouch. Not good. Print the error.
2858                             print $OUT $@;
2859                             next CMD;
2860                         }
2861                         $pat = $inpat;
2862                     } ## end if ($inpat ne "")
2863
2864                     # Where we are now is where to stop after wraparound.
2865                     $end = $start;
2866
2867                     # Don't move away from this line.
2868                     $incr = -1;
2869
2870                     # Search inside the eval to prevent pattern badness
2871                     # from killing us.
2872                     eval '
2873                         for (;;) {
2874                             # Back up a line.
2875                             --$start;
2876
2877                             # Wrap if we pass the first line.
2878
2879                             $start = $max if ($start <= 0);
2880
2881                             # Quit if we get back where we started,
2882                             last if ($start == $end);
2883
2884                             # Match?
2885                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2886                                 if ($slave_editor) {
2887                                     # Yep, follow slave editor requirements.
2888                                     print $OUT "\032\032$filename:$start:0\n";
2889                                 }
2890                                 else {
2891                                     # Yep, just print normally.
2892                                     print $OUT "$start:\t",$dbline[$start],"\n";
2893                                 }
2894
2895                                 # Found, so done.
2896                                 last;
2897                             }
2898                         } ';
2899
2900                     # Say we failed if the loop never found anything,
2901                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2902                     next CMD;
2903                 }
2904
2905 =head4 C<$rc> - Recall command
2906
2907 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2908 that the terminal supports history). It find the the command required, puts it
2909 into C<$cmd>, and redoes the loop to execute it.
2910
2911 =cut
2912
2913                 # $rc - recall command.
2914                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2915
2916                     # No arguments, take one thing off history.
2917                     pop(@hist) if length($cmd) > 1;
2918
2919                     # Relative (- found)?
2920                     #  Y - index back from most recent (by 1 if bare minus)
2921                     #  N - go to that particular command slot or the last
2922                     #      thing if nothing following.
2923                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2924
2925                     # Pick out the command desired.
2926                     $cmd = $hist[$i];
2927
2928                     # Print the command to be executed and restart the loop
2929                     # with that command in the buffer.
2930                     print $OUT $cmd, "\n";
2931                     redo CMD;
2932                 }
2933
2934 =head4 C<$sh$sh> - C<system()> command
2935
2936 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2937 C<STDOUT> from getting messed up.
2938
2939 =cut
2940
2941                 # $sh$sh - run a shell command (if it's all ASCII).
2942                 # Can't run shell commands with Unicode in the debugger, hmm.
2943                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2944
2945                     # System it.
2946                     &system($arg);
2947                     next CMD;
2948                 }
2949
2950 =head4 C<$rc I<pattern> $rc> - Search command history
2951
2952 Another command to manipulate C<@hist>: this one searches it with a pattern.
2953 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2954
2955 =cut
2956
2957                 # $rc pattern $rc - find a command in the history.
2958                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2959
2960                     # Create the pattern to use.
2961                     $pat = "^$arg";
2962
2963                     # Toss off last entry if length is >1 (and it always is).
2964                     pop(@hist) if length($cmd) > 1;
2965
2966                     # Look backward through the history.
2967                     for ( $i = $#hist ; $i ; --$i ) {
2968                         # Stop if we find it.
2969                         last if $hist[$i] =~ /$pat/;
2970                     }
2971
2972                     if ( !$i ) {
2973
2974                         # Never found it.
2975                         print $OUT "No such command!\n\n";
2976                         next CMD;
2977                     }
2978
2979                     # Found it. Put it in the buffer, print it, and process it.
2980                     $cmd = $hist[$i];
2981                     print $OUT $cmd, "\n";
2982                     redo CMD;
2983                 }
2984
2985 =head4 C<$sh> - Invoke a shell
2986
2987 Uses C<DB::system> to invoke a shell.
2988
2989 =cut
2990
2991                 # $sh - start a shell.
2992                 if ($cmd =~ /\A$sh\z/) {
2993
2994                     # Run the user's shell. If none defined, run Bourne.
2995                     # We resume execution when the shell terminates.
2996                     &system( $ENV{SHELL} || "/bin/sh" );
2997                     next CMD;
2998                 }
2999
3000 =head4 C<$sh I<command>> - Force execution of a command in a shell
3001
3002 Like the above, but the command is passed to the shell. Again, we use
3003 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3004
3005 =cut
3006
3007                 # $sh command - start a shell and run a command in it.
3008                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3009
3010                     # XXX: using csh or tcsh destroys sigint retvals!
3011                     #&system($1);  # use this instead
3012
3013                     # use the user's shell, or Bourne if none defined.
3014                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3015                     next CMD;
3016                 }
3017
3018 =head4 C<H> - display commands in history
3019
3020 Prints the contents of C<@hist> (if any).
3021
3022 =cut
3023
3024                 if ($cmd =~ /\AH\b\s*\*/) {
3025                     @hist = @truehist = ();
3026                     print $OUT "History cleansed\n";
3027                     next CMD;
3028                 }
3029
3030                 if (my ($num)
3031                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3032
3033                     # Anything other than negative numbers is ignored by
3034                     # the (incorrect) pattern, so this test does nothing.
3035                     $end = $num ? ( $#hist - $num ) : 0;
3036
3037                     # Set to the minimum if less than zero.
3038                     $hist = 0 if $hist < 0;
3039
3040                     # Start at the end of the array.
3041                     # Stay in while we're still above the ending value.
3042                     # Tick back by one each time around the loop.
3043                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3044
3045                         # Print the command  unless it has no arguments.
3046                         print $OUT "$i: ", $hist[$i], "\n"
3047                           unless $hist[$i] =~ /^.?$/;
3048                     }
3049                     next CMD;
3050                 }
3051
3052 =head4 C<man, doc, perldoc> - look up documentation
3053
3054 Just calls C<runman()> to print the appropriate document.
3055
3056 =cut
3057
3058                 # man, perldoc, doc - show manual pages.
3059                 if (my ($man_page)
3060                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3061                     runman($man_page);
3062                     next CMD;
3063                 }
3064
3065 =head4 C<p> - print
3066
3067 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3068 the bottom of the loop.
3069
3070 =cut
3071
3072                 my $print_cmd = 'print {$DB::OUT} ';
3073                 # p - print (no args): print $_.
3074                 if ($cmd eq 'p') {
3075                     $cmd = $print_cmd . '$_';
3076                 }
3077
3078                 # p - print the given expression.
3079                 $cmd =~ s/\Ap\b/$print_cmd /;
3080
3081 =head4 C<=> - define command alias
3082
3083 Manipulates C<%alias> to add or list command aliases.
3084
3085 =cut
3086
3087                 # = - set up a command alias.
3088                 if ($cmd =~ s/\A=\s*//) {
3089                     my @keys;
3090                     if ( length $cmd == 0 ) {
3091
3092                         # No args, get current aliases.
3093                         @keys = sort keys %alias;
3094                     }
3095                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3096
3097                         # Creating a new alias. $k is alias name, $v is
3098                         # alias value.
3099
3100                         # can't use $_ or kill //g state
3101                         for my $x ( $k, $v ) {
3102
3103                             # Escape "alarm" characters.
3104                             $x =~ s/\a/\\a/g;
3105                         }
3106
3107                         # Substitute key for value, using alarm chars
3108                         # as separators (which is why we escaped them in
3109                         # the command).
3110                         $alias{$k} = "s\a$k\a$v\a";
3111
3112                         # Turn off standard warn and die behavior.
3113                         local $SIG{__DIE__};
3114                         local $SIG{__WARN__};
3115
3116                         # Is it valid Perl?
3117                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3118
3119                             # Nope. Bad alias. Say so and get out.
3120                             print $OUT "Can't alias $k to $v: $@\n";
3121                             delete $alias{$k};
3122                             next CMD;
3123                         }
3124
3125                         # We'll only list the new one.
3126                         @keys = ($k);
3127                     } ## end elsif (my ($k, $v) = ($cmd...
3128
3129                     # The argument is the alias to list.
3130                     else {
3131                         @keys = ($cmd);
3132                     }
3133
3134                     # List aliases.
3135                     for my $k (@keys) {
3136
3137                         # Messy metaquoting: Trim the substitution code off.
3138                         # We use control-G as the delimiter because it's not
3139                         # likely to appear in the alias.
3140                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3141
3142                             # Print the alias.
3143                             print $OUT "$k\t= $1\n";
3144                         }
3145                         elsif ( defined $alias{$k} ) {
3146
3147                             # Couldn't trim it off; just print the alias code.
3148                             print $OUT "$k\t$alias{$k}\n";
3149                         }
3150                         else {
3151
3152                             # No such, dude.
3153                             print "No alias for $k\n";
3154                         }
3155                     } ## end for my $k (@keys)
3156                     next CMD;
3157                 }
3158
3159 =head4 C<source> - read commands from a file.
3160
3161 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3162 pick it up.
3163
3164 =cut
3165
3166                 # source - read commands from a file (or pipe!) and execute.
3167                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3168                     if ( open my $fh, $sourced_fn ) {
3169
3170                         # Opened OK; stick it in the list of file handles.
3171                         push @cmdfhs, $fh;
3172                     }
3173                     else {
3174
3175                         # Couldn't open it.
3176                         &warn("Can't execute '$sourced_fn': $!\n");
3177                     }
3178                     next CMD;
3179                 }
3180
3181                 if (my ($which_cmd, $position)
3182                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3183
3184                     my ($fn, $line_num);
3185                     if ($position =~ m{\A\d+\z})
3186                     {
3187                         $fn = $filename;
3188                         $line_num = $position;
3189                     }
3190                     elsif (my ($new_fn, $new_line_num)
3191                         = $position =~ m{\A(.*):(\d+)\z}) {
3192                         ($fn, $line_num) = ($new_fn, $new_line_num);
3193                     }
3194                     else
3195                     {
3196                         &warn("Wrong spec for enable/disable argument.\n");
3197                     }
3198
3199                     if (defined($fn)) {
3200                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3201                             _set_breakpoint_enabled_status($fn, $line_num,
3202                                 ($which_cmd eq 'enable' ? 1 : '')
3203                             );
3204                         }
3205                         else {
3206                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3207                         }
3208                     }
3209
3210                     next CMD;
3211                 }
3212
3213 =head4 C<save> - send current history to a file
3214
3215 Takes the complete history, (not the shrunken version you see with C<H>),
3216 and saves it to the given filename, so it can be replayed using C<source>.
3217
3218 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3219
3220 =cut
3221
3222                 # save source - write commands to a file for later use
3223                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3224                     my $filename = $new_fn || '.perl5dbrc';    # default?
3225                     if ( open my $fh, '>', $filename ) {
3226
3227                        # chomp to remove extraneous newlines from source'd files
3228                         chomp( my @truelist =
3229                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3230                               @truehist );
3231                         print $fh join( "\n", @truelist );
3232                         print "commands saved in $file\n";
3233                     }
3234                     else {
3235                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3236                     }
3237                     next CMD;
3238                 }
3239
3240 =head4 C<R> - restart
3241
3242 Restart the debugger session.
3243
3244 =head4 C<rerun> - rerun the current session
3245
3246 Return to any given position in the B<true>-history list
3247
3248 =cut
3249
3250                 # R - restart execution.
3251                 # rerun - controlled restart execution.
3252                 if (my ($cmd_cmd, $cmd_params) =
3253                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3254                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3255
3256                     # Close all non-system fds for a clean restart.  A more
3257                     # correct method would be to close all fds that were not
3258                     # open when the process started, but this seems to be
3259                     # hard.  See "debugger 'R'estart and open database
3260                     # connections" on p5p.
3261
3262                     my $max_fd = 1024; # default if POSIX can't be loaded
3263                     if (eval { require POSIX }) {
3264                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3265                     }
3266
3267                     if (defined $max_fd) {
3268                         foreach ($^F+1 .. $max_fd-1) {
3269                             next unless open FD_TO_CLOSE, "<&=$_";
3270                             close(FD_TO_CLOSE);
3271                         }
3272                     }
3273
3274                     # And run Perl again.  We use exec() to keep the
3275                     # PID stable (and that way $ini_pids is still valid).
3276                     exec(@args) || print $OUT "exec failed: $!\n";
3277
3278                     last CMD;
3279                 }
3280
3281 =head4 C<|, ||> - pipe output through the pager.
3282
3283 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3284 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3285 pipe to the pager (restoring the output filehandles if this fails). If this
3286 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3287 set C<$signal>, sending us back into the debugger.
3288
3289 We then trim off the pipe symbols and C<redo> the command loop at the
3290 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3291 reading another.
3292
3293 =cut
3294
3295                 # || - run command in the pager, with output to DB::OUT.
3296                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3297                     if ( $pager =~ /^\|/ ) {
3298
3299                         # Default pager is into a pipe. Redirect I/O.
3300                         open( SAVEOUT, ">&STDOUT" )
3301                           || &warn("Can't save STDOUT");
3302                         open( STDOUT, ">&OUT" )
3303                           || &warn("Can't redirect STDOUT");
3304                     } ## end if ($pager =~ /^\|/)
3305                     else {
3306
3307                         # Not into a pipe. STDOUT is safe.
3308                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3309                     }
3310
3311                     # Fix up environment to record we have less if so.
3312                     fix_less();
3313
3314                     unless ( $piped = open( OUT, $pager ) ) {
3315
3316                         # Couldn't open pipe to pager.
3317                         &warn("Can't pipe output to '$pager'");
3318                         if ( $pager =~ /^\|/ ) {
3319
3320                             # Redirect I/O back again.
3321                             open( OUT, ">&STDOUT" )    # XXX: lost message
3322                               || &warn("Can't restore DB::OUT");
3323                             open( STDOUT, ">&SAVEOUT" )
3324                               || &warn("Can't restore STDOUT");
3325                             close(SAVEOUT);
3326                         } ## end if ($pager =~ /^\|/)
3327                         else {
3328
3329                             # Redirect I/O. STDOUT already safe.
3330                             open( OUT, ">&STDOUT" )    # XXX: lost message
3331                               || &warn("Can't restore DB::OUT");
3332                         }
3333                         next CMD;
3334                     } ## end unless ($piped = open(OUT,...
3335
3336                     # Set up broken-pipe handler if necessary.
3337                     $SIG{PIPE} = \&DB::catch
3338                       if $pager =~ /^\|/
3339                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3340
3341                     OUT->autoflush(1);
3342                     # Save current filehandle, and put it back.
3343                     $selected = select(OUT);
3344                     # Don't put it back if pager was a pipe.
3345                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3346
3347                     # Trim off the pipe symbols and run the command now.
3348                     $cmd =~ s#\A\|+\s*##;
3349                     redo PIPE;
3350                 }
3351
3352 =head3 END OF COMMAND PARSING
3353
3354 Anything left in C<$cmd> at this point is a Perl expression that we want to
3355 evaluate. We'll always evaluate in the user's context, and fully qualify
3356 any variables we might want to address in the C<DB> package.
3357
3358 =cut
3359
3360                 # t - turn trace on.
3361                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3362                     my $trace_arg = $1;
3363                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3364                 }
3365
3366                 # s - single-step. Remember the last command was 's'.
3367                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3368                     $laststep = 's';
3369                 }
3370
3371                 # n - single-step, but not into subs. Remember last command
3372                 # was 'n'.
3373                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3374                     $laststep = 'n';
3375                 }
3376
3377             }    # PIPE:
3378
3379             # Make sure the flag that says "the debugger's running" is
3380             # still on, to make sure we get control again.
3381             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3382
3383             # Run *our* eval that executes in the caller's context.
3384             &eval;
3385
3386             # Turn off the one-time-dump stuff now.
3387             if ($onetimeDump) {
3388                 $onetimeDump      = undef;
3389                 $onetimedumpDepth = undef;
3390             }
3391             elsif ( $term_pid == $$ ) {
3392                 eval {          # May run under miniperl, when not available...
3393                     STDOUT->flush();
3394                     STDERR->flush();
3395                 };
3396
3397                 # XXX If this is the master pid, print a newline.
3398                 print $OUT "\n";
3399             }
3400         } ## end while (($term || &setterm...
3401
3402 =head3 POST-COMMAND PROCESSING
3403
3404 After each command, we check to see if the command output was piped anywhere.
3405 If so, we go through the necessary code to unhook the pipe and go back to
3406 our standard filehandles for input and output.
3407
3408 =cut
3409
3410         continue {    # CMD:
3411
3412             # At the end of every command:
3413             if ($piped) {
3414
3415                 # Unhook the pipe mechanism now.
3416                 if ( $pager =~ /^\|/ ) {
3417
3418                     # No error from the child.
3419                     $? = 0;
3420
3421                     # we cannot warn here: the handle is missing --tchrist
3422                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3423
3424                     # most of the $? crud was coping with broken cshisms
3425                     # $? is explicitly set to 0, so this never runs.
3426                     if ($?) {
3427                         print SAVEOUT "Pager '$pager' failed: ";
3428                         if ( $? == -1 ) {
3429                             print SAVEOUT "shell returned -1\n";
3430                         }
3431                         elsif ( $? >> 8 ) {
3432                             print SAVEOUT ( $? & 127 )
3433                               ? " (SIG#" . ( $? & 127 ) . ")"
3434                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3435                         }
3436                         else {
3437                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3438                         }
3439                     } ## end if ($?)
3440
3441                     # Reopen filehandle for our output (if we can) and
3442                     # restore STDOUT (if we can).
3443                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3444                     open( STDOUT, ">&SAVEOUT" )
3445                       || &warn("Can't restore STDOUT");
3446
3447                     # Turn off pipe exception handler if necessary.
3448                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3449
3450                     # Will stop ignoring SIGPIPE if done like nohup(1)
3451                     # does SIGINT but Perl doesn't give us a choice.
3452                 } ## end if ($pager =~ /^\|/)
3453                 else {
3454
3455                     # Non-piped "pager". Just restore STDOUT.
3456                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3457                 }
3458
3459                 # Close filehandle pager was using, restore the normal one
3460                 # if necessary,
3461                 close(SAVEOUT);
3462                 select($selected), $selected = "" unless $selected eq "";
3463
3464                 # No pipes now.
3465                 $piped = "";
3466             } ## end if ($piped)
3467         }    # CMD:
3468
3469 =head3 COMMAND LOOP TERMINATION
3470
3471 When commands have finished executing, we come here. If the user closed the
3472 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3473 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3474 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3475 The interpreter will then execute the next line and then return control to us
3476 again.
3477
3478 =cut
3479
3480         # No more commands? Quit.
3481         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3482
3483         # Evaluate post-prompt commands.
3484         foreach $evalarg (@$post) {
3485             &eval;
3486         }
3487     }    # if ($single || $signal)
3488
3489     # Put the user's globals back where you found them.
3490     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3491     ();
3492 } ## end sub DB
3493
3494 # The following code may be executed now:
3495 # BEGIN {warn 4}
3496
3497 =head2 sub
3498
3499 C<sub> is called whenever a subroutine call happens in the program being
3500 debugged. The variable C<$DB::sub> contains the name of the subroutine
3501 being called.
3502
3503 The core function of this subroutine is to actually call the sub in the proper
3504 context, capturing its output. This of course causes C<DB::DB> to get called
3505 again, repeating until the subroutine ends and returns control to C<DB::sub>
3506 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3507 return value, and returns its captured copy of the return value as its own
3508 return value. The value then feeds back into the program being debugged as if
3509 C<DB::sub> hadn't been there at all.
3510
3511 C<sub> does all the work of printing the subroutine entry and exit messages
3512 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3513 and also prints the return value if needed (for the C<r> command and if
3514 the 16 bit is set in C<$frame>).
3515
3516 It also tracks the subroutine call depth by saving the current setting of
3517 C<$single> in the C<@stack> package global; if this exceeds the value in
3518 C<$deep>, C<sub> automatically turns on printing of the current depth by
3519 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3520 of stop/don't stop on entry to subs set as it currently is set.
3521
3522 =head3 C<caller()> support
3523
3524 If C<caller()> is called from the package C<DB>, it provides some
3525 additional data, in the following order:
3526
3527 =over 4
3528
3529 =item * C<$package>
3530
3531 The package name the sub was in
3532
3533 =item * C<$filename>
3534
3535 The filename it was defined in
3536
3537 =item * C<$line>
3538
3539 The line number it was defined on
3540
3541 =item * C<$subroutine>
3542
3543 The subroutine name; C<(eval)> if an C<eval>().
3544
3545 =item * C<$hasargs>
3546
3547 1 if it has arguments, 0 if not
3548
3549 =item * C<$wantarray>
3550
3551 1 if array context, 0 if scalar context
3552
3553 =item * C<$evaltext>
3554
3555 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3556
3557 =item * C<$is_require>
3558
3559 frame was created by a C<use> or C<require> statement
3560
3561 =item * C<$hints>
3562
3563 pragma information; subject to change between versions
3564
3565 =item * C<$bitmask>
3566
3567 pragma information; subject to change between versions
3568
3569 =item * C<@DB::args>
3570
3571 arguments with which the subroutine was invoked
3572
3573 =back
3574
3575 =cut
3576
3577 use vars qw($deep);
3578
3579 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3580 # happy. -- Shlomi Fish
3581 sub DB::sub {
3582         # Do not use a regex in this subroutine -> results in corrupted memory
3583         # See: [perl #66110]
3584
3585         # lock ourselves under threads
3586         lock($DBGR);
3587
3588     # Whether or not the autoloader was running, a scalar to put the
3589     # sub's return value in (if needed), and an array to put the sub's
3590     # return value in (if needed).
3591     my ( $al, $ret, @ret ) = "";
3592         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3593                 print "creating new thread\n";
3594         }
3595
3596     # If the last ten characters are '::AUTOLOAD', note we've traced
3597     # into AUTOLOAD for $sub.
3598     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3599         no strict 'refs';
3600         $al = " for $$sub" if defined $$sub;
3601     }
3602
3603     # We stack the stack pointer and then increment it to protect us
3604     # from a situation that might unwind a whole bunch of call frames
3605     # at once. Localizing the stack pointer means that it will automatically
3606     # unwind the same amount when multiple stack frames are unwound.
3607     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3608
3609     # Expand @stack.
3610     $#stack = $stack_depth;
3611
3612     # Save current single-step setting.
3613     $stack[-1] = $single;
3614
3615     # Turn off all flags except single-stepping.
3616     $single &= 1;
3617
3618     # If we've gotten really deeply recursed, turn on the flag that will
3619     # make us stop with the 'deep recursion' message.
3620     $single |= 4 if $stack_depth == $deep;
3621
3622     # If frame messages are on ...
3623     (
3624         $frame & 4    # Extended frame entry message
3625         ? (
3626             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3627
3628             # Why -1? But it works! :-(
3629             # Because print_trace will call add 1 to it and then call
3630             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3631             # in dump_trace.
3632             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3633           )
3634         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3635
3636           # standard frame entry message
3637       )
3638       if $frame;
3639
3640     # Determine the sub's return type, and capture appropriately.
3641     if (wantarray) {
3642
3643         # Called in array context. call sub and capture output.
3644         # DB::DB will recursively get control again if appropriate; we'll come
3645         # back here when the sub is finished.
3646         {
3647             no strict 'refs';
3648             @ret = &$sub;
3649         }
3650
3651         # Pop the single-step value back off the stack.
3652         $single |= $stack[ $stack_depth-- ];
3653
3654         # Check for exit trace messages...
3655         (
3656             $frame & 4    # Extended exit message
3657             ? (
3658                 print_lineinfo( ' ' x $stack_depth, "out " ),
3659                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3660               )
3661             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3662
3663               # Standard exit message
3664           )
3665           if $frame & 2;
3666
3667         # Print the return info if we need to.
3668         if ( $doret eq $stack_depth or $frame & 16 ) {
3669
3670             # Turn off output record separator.
3671             local $\ = '';
3672             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3673
3674             # Indent if we're printing because of $frame tracing.
3675             print $fh ' ' x $stack_depth if $frame & 16;
3676
3677             # Print the return value.
3678             print $fh "list context return from $sub:\n";
3679             dumpit( $fh, \@ret );
3680
3681             # And don't print it again.
3682             $doret = -2;
3683         } ## end if ($doret eq $stack_depth...
3684             # And we have to return the return value now.
3685         @ret;
3686     } ## end if (wantarray)
3687
3688     # Scalar context.
3689     else {
3690         if ( defined wantarray ) {
3691         no strict 'refs';
3692             # Save the value if it's wanted at all.
3693             $ret = &$sub;
3694         }
3695         else {
3696         no strict 'refs';
3697             # Void return, explicitly.
3698             &$sub;
3699             undef $ret;
3700         }
3701
3702         # Pop the single-step value off the stack.
3703         $single |= $stack[ $stack_depth-- ];
3704
3705         # If we're doing exit messages...
3706         (
3707             $frame & 4    # Extended messages
3708             ? (
3709                 print_lineinfo( ' ' x $stack_depth, "out " ),
3710                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3711               )
3712             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3713
3714               # Standard messages
3715           )
3716           if $frame & 2;
3717
3718         # If we are supposed to show the return value... same as before.
3719         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3720             local $\ = '';
3721             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3722             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3723             print $fh (
3724                 defined wantarray
3725                 ? "scalar context return from $sub: "
3726                 : "void context return from $sub\n"
3727             );
3728             dumpit( $fh, $ret ) if defined wantarray;
3729             $doret = -2;
3730         } ## end if ($doret eq $stack_depth...
3731
3732         # Return the appropriate scalar value.
3733         $ret;
3734     } ## end else [ if (wantarray)
3735 } ## end sub _sub
3736
3737 sub lsub : lvalue {
3738
3739     no strict 'refs';
3740
3741         # lock ourselves under threads
3742         lock($DBGR);
3743
3744     # Whether or not the autoloader was running, a scalar to put the
3745     # sub's return value in (if needed), and an array to put the sub's
3746     # return value in (if needed).
3747     my ( $al, $ret, @ret ) = "";
3748         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3749                 print "creating new thread\n";
3750         }
3751
3752     # If the last ten characters are C'::AUTOLOAD', note we've traced
3753     # into AUTOLOAD for $sub.
3754     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3755         $al = " for $$sub";
3756     }
3757
3758     # We stack the stack pointer and then increment it to protect us
3759     # from a situation that might unwind a whole bunch of call frames
3760     # at once. Localizing the stack pointer means that it will automatically
3761     # unwind the same amount when multiple stack frames are unwound.
3762     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3763
3764     # Expand @stack.
3765     $#stack = $stack_depth;
3766
3767     # Save current single-step setting.
3768     $stack[-1] = $single;
3769
3770     # Turn off all flags except single-stepping.
3771     $single &= 1;
3772
3773     # If we've gotten really deeply recursed, turn on the flag that will
3774     # make us stop with the 'deep recursion' message.
3775     $single |= 4 if $stack_depth == $deep;
3776
3777     # If frame messages are on ...
3778     (
3779         $frame & 4    # Extended frame entry message
3780         ? (
3781             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3782
3783             # Why -1? But it works! :-(
3784             # Because print_trace will call add 1 to it and then call
3785             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3786             # in dump_trace.
3787             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3788           )
3789         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3790
3791           # standard frame entry message
3792       )
3793       if $frame;
3794
3795     # Pop the single-step value back off the stack.
3796     $single |= $stack[ $stack_depth-- ];
3797
3798     # call the original lvalue sub.
3799     &$sub;
3800 }
3801
3802 # Abstracting common code from multiple places elsewhere:
3803 sub depth_print_lineinfo {
3804     my $always_print = shift;
3805
3806     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3807 }
3808
3809 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3810
3811 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3812 Most of the changes were to systematize the command structure and to eliminate
3813 commands that threw away user input without checking.
3814
3815 The following sections describe the code added to make it easy to support
3816 multiple command sets with conflicting command names. This section is a start
3817 at unifying all command processing to make it simpler to develop commands.
3818
3819 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3820 number, and C<$dbline> (the current line) as arguments.
3821
3822 Support functions in this section which have multiple modes of failure C<die>
3823 on error; the rest simply return a false value.
3824
3825 The user-interface functions (all of the C<cmd_*> functions) just output
3826 error messages.
3827
3828 =head2 C<%set>
3829
3830 The C<%set> hash defines the mapping from command letter to subroutine
3831 name suffix.
3832
3833 C<%set> is a two-level hash, indexed by set name and then by command name.
3834 Note that trying to set the CommandSet to C<foobar> simply results in the
3835 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3836
3837 =cut
3838
3839 ### The API section
3840
3841 my %set = (    #
3842     'pre580' => {
3843         'a' => 'pre580_a',
3844         'A' => 'pre580_null',
3845         'b' => 'pre580_b',
3846         'B' => 'pre580_null',
3847         'd' => 'pre580_null',
3848         'D' => 'pre580_D',
3849         'h' => 'pre580_h',
3850         'M' => 'pre580_null',
3851         'O' => 'o',
3852         'o' => 'pre580_null',
3853         'v' => 'M',
3854         'w' => 'v',
3855         'W' => 'pre580_W',
3856     },
3857     'pre590' => {
3858         '<'  => 'pre590_prepost',
3859         '<<' => 'pre590_prepost',
3860         '>'  => 'pre590_prepost',
3861         '>>' => 'pre590_prepost',
3862         '{'  => 'pre590_prepost',
3863         '{{' => 'pre590_prepost',
3864     },
3865 );
3866
3867 my %breakpoints_data;
3868
3869 sub _has_breakpoint_data_ref {
3870     my ($filename, $line) = @_;
3871
3872     return (
3873         exists( $breakpoints_data{$filename} )
3874             and
3875         exists( $breakpoints_data{$filename}{$line} )
3876     );
3877 }
3878
3879 sub _get_breakpoint_data_ref {
3880     my ($filename, $line) = @_;
3881
3882     return ($breakpoints_data{$filename}{$line} ||= +{});
3883 }
3884
3885 sub _delete_breakpoint_data_ref {
3886     my ($filename, $line) = @_;
3887
3888     delete($breakpoints_data{$filename}{$line});
3889     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3890         delete($breakpoints_data{$filename});
3891     }
3892
3893     return;
3894 }
3895
3896 sub _set_breakpoint_enabled_status {
3897     my ($filename, $line, $status) = @_;
3898
3899     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3900         ($status ? 1 : '')
3901         ;
3902
3903     return;
3904 }
3905
3906 sub _enable_breakpoint_temp_enabled_status {
3907     my ($filename, $line) = @_;
3908
3909     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3910
3911     return;
3912 }
3913
3914 sub _cancel_breakpoint_temp_enabled_status {
3915     my ($filename, $line) = @_;
3916
3917     my $ref = _get_breakpoint_data_ref($filename, $line);
3918
3919     delete ($ref->{'temp_enabled'});
3920
3921     if (! %$ref) {
3922         _delete_breakpoint_data_ref($filename, $line);
3923     }
3924
3925     return;
3926 }
3927
3928 sub _is_breakpoint_enabled {
3929     my ($filename, $line) = @_;
3930
3931     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3932     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3933 }
3934
3935 =head2 C<cmd_wrapper()> (API)
3936
3937 C<cmd_wrapper()> allows the debugger to switch command sets
3938 depending on the value of the C<CommandSet> option.
3939
3940 It tries to look up the command in the C<%set> package-level I<lexical>
3941 (which means external entities can't fiddle with it) and create the name of
3942 the sub to call based on the value found in the hash (if it's there). I<All>
3943 of the commands to be handled in a set have to be added to C<%set>; if they
3944 aren't found, the 5.8.0 equivalent is called (if there is one).
3945
3946 This code uses symbolic references.
3947
3948 =cut
3949
3950 sub cmd_wrapper {
3951     my $cmd      = shift;
3952     my $line     = shift;
3953     my $dblineno = shift;
3954
3955     # Assemble the command subroutine's name by looking up the
3956     # command set and command name in %set. If we can't find it,
3957     # default to the older version of the command.
3958     my $call = 'cmd_'
3959       . ( $set{$CommandSet}{$cmd}
3960           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3961
3962     # Call the command subroutine, call it by name.
3963     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3964 } ## end sub cmd_wrapper
3965
3966 =head3 C<cmd_a> (command)
3967
3968 The C<a> command handles pre-execution actions. These are associated with a
3969 particular line, so they're stored in C<%dbline>. We default to the current
3970 line if none is specified.
3971
3972 =cut
3973
3974 sub cmd_a {
3975     my $cmd    = shift;
3976     my $line   = shift || '';    # [.|line] expr
3977     my $dbline = shift;
3978
3979     # If it's dot (here), or not all digits,  use the current line.
3980     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3981
3982     # Should be a line number followed by an expression.
3983     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3984         my ( $lineno, $expr ) = ( $1, $2 );
3985
3986         # If we have an expression ...
3987         if ( length $expr ) {
3988
3989             # ... but the line isn't breakable, complain.
3990             if ( $dbline[$lineno] == 0 ) {
3991                 print $OUT
3992                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3993             }
3994             else {
3995
3996                 # It's executable. Record that the line has an action.
3997                 $had_breakpoints{$filename} |= 2;
3998
3999                 # Remove any action, temp breakpoint, etc.
4000                 $dbline{$lineno} =~ s/\0[^\0]*//;
4001
4002                 # Add the action to the line.
4003                 $dbline{$lineno} .= "\0" . action($expr);
4004
4005                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4006             }
4007         } ## end if (length $expr)
4008     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4009     else {
4010
4011         # Syntax wrong.
4012         print $OUT
4013           "Adding an action requires an optional lineno and an expression\n"
4014           ;    # hint
4015     }
4016 } ## end sub cmd_a
4017
4018 =head3 C<cmd_A> (command)
4019
4020 Delete actions. Similar to above, except the delete code is in a separate
4021 subroutine, C<delete_action>.
4022
4023 =cut
4024
4025 sub cmd_A {
4026     my $cmd    = shift;
4027     my $line   = shift || '';
4028     my $dbline = shift;
4029
4030     # Dot is this line.
4031     $line =~ s/^\./$dbline/;
4032
4033     # Call delete_action with a null param to delete them all.
4034     # The '1' forces the eval to be true. It'll be false only
4035     # if delete_action blows up for some reason, in which case
4036     # we print $@ and get out.
4037     if ( $line eq '*' ) {
4038         eval { &delete_action(); 1 } or print $OUT $@ and return;
4039     }
4040
4041     # There's a real line  number. Pass it to delete_action.
4042     # Error trapping is as above.
4043     elsif ( $line =~ /^(\S.*)/ ) {
4044         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4045     }
4046
4047     # Swing and a miss. Bad syntax.
4048     else {
4049         print $OUT
4050           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4051     }
4052 } ## end sub cmd_A
4053
4054 =head3 C<delete_action> (API)
4055
4056 C<delete_action> accepts either a line number or C<undef>. If a line number
4057 is specified, we check for the line being executable (if it's not, it
4058 couldn't have had an  action). If it is, we just take the action off (this
4059 will get any kind of an action, including breakpoints).
4060
4061 =cut
4062
4063 sub delete_action {
4064     my $i = shift;
4065     if ( defined($i) ) {
4066
4067         # Can there be one?
4068         die "Line $i has no action .\n" if $dbline[$i] == 0;
4069
4070         # Nuke whatever's there.
4071         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4072         delete $dbline{$i} if $dbline{$i} eq '';
4073     }
4074     else {
4075         print $OUT "Deleting all actions...\n";
4076         for my $file ( keys %had_breakpoints ) {
4077             local *dbline = $main::{ '_<' . $file };
4078             $max = $#dbline;
4079             my $was;
4080             for $i (1 .. $max) {
4081                 if ( defined $dbline{$i} ) {
4082                     $dbline{$i} =~ s/\0[^\0]*//;
4083                     delete $dbline{$i} if $dbline{$i} eq '';
4084                 }
4085                 unless ( $had_breakpoints{$file} &= ~2 ) {
4086                     delete $had_breakpoints{$file};
4087                 }
4088             } ## end for ($i = 1 .. $max)
4089         } ## end for my $file (keys %had_breakpoints)
4090     } ## end else [ if (defined($i))
4091 } ## end sub delete_action
4092
4093 =head3 C<cmd_b> (command)
4094
4095 Set breakpoints. Since breakpoints can be set in so many places, in so many
4096 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4097 we try to parse the command type, and then shuttle it off to an appropriate
4098 subroutine to actually do the work of setting the breakpoint in the right
4099 place.
4100
4101 =cut
4102
4103 sub cmd_b {
4104     my $cmd    = shift;
4105     my $line   = shift;    # [.|line] [cond]
4106     my $dbline = shift;
4107
4108     # Make . the current line number if it's there..
4109     $line =~ s/^\.(\s|\z)/$dbline$1/;
4110
4111     # No line number, no condition. Simple break on current line.
4112     if ( $line =~ /^\s*$/ ) {
4113         &cmd_b_line( $dbline, 1 );
4114     }
4115
4116     # Break on load for a file.
4117     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4118         my $file = $1;
4119         $file =~ s/\s+$//;
4120         &cmd_b_load($file);
4121     }
4122
4123     # b compile|postpone <some sub> [<condition>]
4124     # The interpreter actually traps this one for us; we just put the
4125     # necessary condition in the %postponed hash.
4126     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4127
4128         # Capture the condition if there is one. Make it true if none.
4129         my $cond = length $3 ? $3 : '1';
4130
4131         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4132         # if it was 'compile'.
4133         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4134
4135         # De-Perl4-ify the name - ' separators to ::.
4136         $subname =~ s/\'/::/g;
4137
4138         # Qualify it into the current package unless it's already qualified.
4139         $subname = "${package}::" . $subname unless $subname =~ /::/;
4140
4141         # Add main if it starts with ::.
4142         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4143
4144         # Save the break type for this sub.
4145         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4146     } ## end elsif ($line =~ ...
4147     # b <filename>:<line> [<condition>]
4148     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4149         my ($filename, $line_num, $cond) = ($1, $2, $3);
4150         cmd_b_filename_line(
4151             $filename,
4152             $line_num,
4153             (length($cond) ? $cond : '1'),
4154         );
4155     }
4156     # b <sub name> [<condition>]
4157     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4158
4159         #
4160         $subname = $1;
4161         my $cond = length $2 ? $2 : '1';
4162         &cmd_b_sub( $subname, $cond );
4163     }
4164
4165     # b <line> [<condition>].
4166     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4167
4168         # Capture the line. If none, it's the current line.
4169         $line = $1 || $dbline;
4170
4171         # If there's no condition, make it '1'.
4172         my $cond = length $2 ? $2 : '1';
4173
4174         # Break on line.
4175         &cmd_b_line( $line, $cond );
4176     }
4177
4178     # Line didn't make sense.
4179     else {
4180         print "confused by line($line)?\n";
4181     }
4182 } ## end sub cmd_b
4183
4184 =head3 C<break_on_load> (API)
4185
4186 We want to break when this file is loaded. Mark this file in the
4187 C<%break_on_load> hash, and note that it has a breakpoint in
4188 C<%had_breakpoints>.
4189
4190 =cut
4191
4192 sub break_on_load {
4193     my $file = shift;
4194     $break_on_load{$file} = 1;
4195     $had_breakpoints{$file} |= 1;
4196 }
4197
4198 =head3 C<report_break_on_load> (API)
4199
4200 Gives us an array of filenames that are set to break on load. Note that
4201 only files with break-on-load are in here, so simply showing the keys
4202 suffices.
4203
4204 =cut
4205
4206 sub report_break_on_load {
4207     sort keys %break_on_load;
4208 }
4209
4210 =head3 C<cmd_b_load> (command)
4211
4212 We take the file passed in and try to find it in C<%INC> (which maps modules
4213 to files they came from). We mark those files for break-on-load via
4214 C<break_on_load> and then report that it was done.
4215
4216 =cut
4217
4218 sub cmd_b_load {
4219     my $file = shift;
4220     my @files;
4221
4222     # This is a block because that way we can use a redo inside it
4223     # even without there being any looping structure at all outside it.
4224     {
4225
4226         # Save short name and full path if found.
4227         push @files, $file;
4228         push @files, $::INC{$file} if $::INC{$file};
4229
4230         # Tack on .pm and do it again unless there was a '.' in the name
4231         # already.
4232         $file .= '.pm', redo unless $file =~ /\./;
4233     }
4234
4235     # Do the real work here.
4236     break_on_load($_) for @files;
4237
4238     # All the files that have break-on-load breakpoints.
4239     @files = report_break_on_load;
4240
4241     # Normalize for the purposes of our printing this.
4242     local $\ = '';
4243     local $" = ' ';
4244     print $OUT "Will stop on load of '@files'.\n";
4245 } ## end sub cmd_b_load
4246
4247 =head3 C<$filename_error> (API package global)
4248
4249 Several of the functions we need to implement in the API need to work both
4250 on the current file and on other files. We don't want to duplicate code, so
4251 C<$filename_error> is used to contain the name of the file that's being
4252 worked on (if it's not the current one).
4253
4254 We can now build functions in pairs: the basic function works on the current
4255 file, and uses C<$filename_error> as part of its error message. Since this is
4256 initialized to C<"">, no filename will appear when we are working on the
4257 current file.
4258
4259 The second function is a wrapper which does the following:
4260
4261 =over 4
4262
4263 =item *
4264
4265 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4266
4267 =item *
4268
4269 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4270
4271 =item *
4272
4273 Calls the first function.
4274
4275 The first function works on the I<current> file (i.e., the one we changed to),
4276 and prints C<$filename_error> in the error message (the name of the other file)
4277 if it needs to. When the functions return, C<*dbline> is restored to point
4278 to the actual current file (the one we're executing in) and
4279 C<$filename_error> is restored to C<"">. This restores everything to
4280 the way it was before the second function was called at all.
4281
4282 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4283 details.
4284
4285 =back
4286
4287 =cut
4288
4289 use vars qw($filename_error);
4290 $filename_error = '';
4291
4292 =head3 breakable_line(from, to) (API)
4293
4294 The subroutine decides whether or not a line in the current file is breakable.
4295 It walks through C<@dbline> within the range of lines specified, looking for
4296 the first line that is breakable.
4297
4298 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4299 first line I<after> C<$to> that's breakable, if there is one.
4300
4301 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4302 first line I<before> C<$to> that's breakable, if there is one.
4303
4304 =cut
4305
4306 sub breakable_line {
4307
4308     my ( $from, $to ) = @_;
4309
4310     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4311     my $i = $from;
4312
4313     # If there are at least 2 arguments, we're trying to search a range.
4314     if ( @_ >= 2 ) {
4315
4316         # $delta is positive for a forward search, negative for a backward one.
4317         my $delta = $from < $to ? +1 : -1;
4318
4319         # Keep us from running off the ends of the file.
4320         my $limit = $delta > 0 ? $#dbline : 1;
4321
4322         # Clever test. If you're a mathematician, it's obvious why this
4323         # test works. If not:
4324         # If $delta is positive (going forward), $limit will be $#dbline.
4325         #    If $to is less than $limit, ($limit - $to) will be positive, times
4326         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4327         #    as the stopping point.
4328         #
4329         #    If $to is greater than $limit, ($limit - $to) is negative,
4330         #    times $delta of 1 (positive), so the result is < 0 and we should
4331         #    use $limit ($#dbline) as the stopping point.
4332         #
4333         # If $delta is negative (going backward), $limit will be 1.
4334         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4335         #    (negative) so the result is > 0, and we use $to as the stopping
4336         #    point.
4337         #
4338         #    If $to is less than zero, ($limit - $to) will be positive,
4339         #    times $delta of -1 (negative), so the result is not > 0, and
4340         #    we use $limit (1) as the stopping point.
4341         #
4342         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4343         #    (negative), still giving zero; the result is not > 0, and
4344         #    we use $limit (1) as the stopping point.
4345         #
4346         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4347         #    (negative), giving a positive (>0) value, so we'll set $limit to
4348         #    $to.
4349
4350         $limit = $to if ( $limit - $to ) * $delta > 0;
4351
4352         # The real search loop.
4353         # $i starts at $from (the point we want to start searching from).
4354         # We move through @dbline in the appropriate direction (determined
4355         # by $delta: either -1 (back) or +1 (ahead).
4356         # We stay in as long as we haven't hit an executable line
4357         # ($dbline[$i] == 0 means not executable) and we haven't reached
4358         # the limit yet (test similar to the above).
4359         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4360
4361     } ## end if (@_ >= 2)
4362
4363     # If $i points to a line that is executable, return that.
4364     return $i unless $dbline[$i] == 0;
4365
4366     # Format the message and print it: no breakable lines in range.
4367     my ( $pl, $upto ) = ( '', '' );
4368     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4369
4370     # If there's a filename in filename_error, we'll see it.
4371     # If not, not.
4372     die "Line$pl $from$upto$filename_error not breakable\n";
4373 } ## end sub breakable_line
4374
4375 =head3 breakable_line_in_filename(file, from, to) (API)
4376
4377 Like C<breakable_line>, but look in another file.
4378
4379 =cut
4380
4381 sub breakable_line_in_filename {
4382
4383     # Capture the file name.
4384     my ($f) = shift;
4385
4386     # Swap the magic line array over there temporarily.
4387     local *dbline = $main::{ '_<' . $f };
4388
4389     # If there's an error, it's in this other file.
4390     local $filename_error = " of '$f'";
4391
4392     # Find the breakable line.
4393     breakable_line(@_);
4394
4395     # *dbline and $filename_error get restored when this block ends.
4396
4397 } ## end sub breakable_line_in_filename
4398
4399 =head3 break_on_line(lineno, [condition]) (API)
4400
4401 Adds a breakpoint with the specified condition (or 1 if no condition was
4402 specified) to the specified line. Dies if it can't.
4403
4404 =cut
4405
4406 sub break_on_line {
4407     my ( $i, $cond ) = @_;
4408
4409     # Always true if no condition supplied.
4410     $cond = 1 unless @_ >= 2;
4411
4412     my $inii  = $i;
4413     my $after = '';
4414     my $pl    = '';
4415
4416     # Woops, not a breakable line. $filename_error allows us to say
4417     # if it was in a different file.
4418     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4419
4420     # Mark this file as having breakpoints in it.
4421     $had_breakpoints{$filename} |= 1;
4422
4423     # If there is an action or condition here already ...
4424     if ( $dbline{$i} ) {
4425
4426         # ... swap this condition for the existing one.
4427         $dbline{$i} =~ s/^[^\0]*/$cond/;
4428     }
4429     else {
4430
4431         # Nothing here - just add the condition.
4432         $dbline{$i} = $cond;
4433
4434         _set_breakpoint_enabled_status($filename, $i, 1);
4435     }
4436 } ## end sub break_on_line
4437
4438 =head3 cmd_b_line(line, [condition]) (command)
4439
4440 Wrapper for C<break_on_line>. Prints the failure message if it
4441 doesn't work.
4442
4443 =cut
4444
4445 sub cmd_b_line {
4446     if (not eval { break_on_line(@_); 1 }) {
4447         local $\ = '';
4448         print $OUT $@ and return;
4449     }
4450
4451     return;
4452 } ## end sub cmd_b_line
4453
4454 =head3 cmd_b_filename_line(line, [condition]) (command)
4455
4456 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4457 doesn't work.
4458
4459 =cut
4460
4461 sub cmd_b_filename_line {
4462     if (not eval { break_on_filename_line(@_); 1 }) {
4463         local $\ = '';
4464         print $OUT $@ and return;
4465     }
4466
4467     return;
4468 }
4469
4470 =head3 break_on_filename_line(file, line, [condition]) (API)
4471
4472 Switches to the file specified and then calls C<break_on_line> to set
4473 the breakpoint.
4474
4475 =cut
4476
4477 sub break_on_filename_line {
4478     my ( $f, $i, $cond ) = @_;
4479
4480     # Always true if condition left off.
4481     $cond = 1 unless @_ >= 3;
4482
4483     # Switch the magical hash temporarily.
4484     local *dbline = $main::{ '_<' . $f };
4485
4486     # Localize the variables that break_on_line uses to make its message.
4487     local $filename_error = " of '$f'";
4488     local $filename       = $f;
4489
4490     # Add the breakpoint.
4491     break_on_line( $i, $cond );
4492 } ## end sub break_on_filename_line
4493
4494 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4495
4496 Switch to another file, search the range of lines specified for an
4497 executable one, and put a breakpoint on the first one you find.
4498
4499 =cut
4500
4501 sub break_on_filename_line_range {
4502     my ( $f, $from, $to, $cond ) = @_;
4503
4504     # Find a breakable line if there is one.
4505     my $i = breakable_line_in_filename( $f, $from, $to );
4506
4507     # Always true if missing.
4508     $cond = 1 unless @_ >= 3;
4509
4510     # Add the breakpoint.
4511     break_on_filename_line( $f, $i, $cond );
4512 } ## end sub break_on_filename_line_range
4513
4514 =head3 subroutine_filename_lines(subname, [condition]) (API)
4515
4516 Search for a subroutine within a given file. The condition is ignored.
4517 Uses C<find_sub> to locate the desired subroutine.
4518
4519 =cut
4520
4521 sub subroutine_filename_lines {
4522     my ( $subname, $cond ) = @_;
4523
4524     # Returned value from find_sub() is fullpathname:startline-endline.
4525     # The match creates the list (fullpathname, start, end). Falling off
4526     # the end of the subroutine returns this implicitly.
4527     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4528 } ## end sub subroutine_filename_lines
4529
4530 =head3 break_subroutine(subname) (API)
4531
4532 Places a break on the first line possible in the specified subroutine. Uses
4533 C<subroutine_filename_lines> to find the subroutine, and
4534 C<break_on_filename_line_range> to place the break.
4535
4536 =cut
4537
4538 sub break_subroutine {
4539     my $subname = shift;
4540
4541     # Get filename, start, and end.
4542     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4543       or die "Subroutine $subname not found.\n";
4544
4545
4546     # Null condition changes to '1' (always true).
4547     my $cond = @_ ? shift(@_) : 1;
4548
4549     # Put a break the first place possible in the range of lines
4550     # that make up this subroutine.
4551     break_on_filename_line_range( $file, $s, $e, $cond );
4552 } ## end sub break_subroutine
4553
4554 =head3 cmd_b_sub(subname, [condition]) (command)
4555
4556 We take the incoming subroutine name and fully-qualify it as best we can.
4557
4558 =over 4
4559
4560 =item 1. If it's already fully-qualified, leave it alone.
4561
4562 =item 2. Try putting it in the current package.
4563
4564 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4565
4566 =item 4. If it starts with '::', put it in 'main::'.
4567
4568 =back
4569
4570 After all this cleanup, we call C<break_subroutine> to try to set the
4571 breakpoint.
4572
4573 =cut
4574
4575 sub cmd_b_sub {
4576     my ( $subname, $cond ) = @_;
4577
4578     # Add always-true condition if we have none.
4579     $cond = 1 unless @_ >= 2;
4580
4581     # If the subname isn't a code reference, qualify it so that
4582     # break_subroutine() will work right.
4583     unless ( ref $subname eq 'CODE' ) {
4584
4585         # Not Perl4.
4586         $subname =~ s/\'/::/g;
4587         my $s = $subname;
4588
4589         # Put it in this package unless it's already qualified.
4590         $subname = "${package}::" . $subname
4591           unless $subname =~ /::/;
4592
4593         # Requalify it into CORE::GLOBAL if qualifying it into this
4594         # package resulted in its not being defined, but only do so
4595         # if it really is in CORE::GLOBAL.
4596         $subname = "CORE::GLOBAL::$s"
4597           if not defined &$subname
4598           and $s !~ /::/
4599           and defined &{"CORE::GLOBAL::$s"};
4600
4601         # Put it in package 'main' if it has a leading ::.
4602         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4603
4604     } ## end unless (ref $subname eq 'CODE')
4605
4606     # Try to set the breakpoint.
4607     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
4608         local $\ = '';
4609         print $OUT $@ and return;
4610     }
4611
4612     return;
4613 } ## end sub cmd_b_sub
4614
4615 =head3 C<cmd_B> - delete breakpoint(s) (command)
4616
4617 The command mostly parses the command line and tries to turn the argument
4618 into a line spec. If it can't, it uses the current line. It then calls
4619 C<delete_breakpoint> to actually do the work.
4620
4621 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4622 thereby deleting all the breakpoints.
4623
4624 =cut
4625
4626 sub cmd_B {
4627     my $cmd = shift;
4628
4629     # No line spec? Use dbline.
4630     # If there is one, use it if it's non-zero, or wipe it out if it is.
4631     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
4632     my $dbline = shift;
4633
4634     # If the line was dot, make the line the current one.
4635     $line =~ s/^\./$dbline/;
4636
4637     # If it's * we're deleting all the breakpoints.
4638     if ( $line eq '*' ) {
4639         if (not eval { delete_breakpoint(); 1 }) {
4640             print {$OUT} $@;
4641         }
4642     }
4643
4644     # If there is a line spec, delete the breakpoint on that line.
4645     elsif ( $line =~ /\A(\S.*)/ ) {
4646         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
4647             local $\ = '';
4648             print {$OUT} $@;
4649         }
4650     } ## end elsif ($line =~ /^(\S.*)/)
4651
4652     # No line spec.
4653     else {
4654         print {$OUT}
4655           "Deleting a breakpoint requires a line number, or '*' for all\n"
4656           ;    # hint
4657     }
4658
4659     return;
4660 } ## end sub cmd_B
4661
4662 =head3 delete_breakpoint([line]) (API)
4663
4664 This actually does the work of deleting either a single breakpoint, or all
4665 of them.
4666
4667 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4668 just drop out with a message saying so. If it is, we remove the condition
4669 part of the 'condition\0action' that says there's a breakpoint here. If,
4670 after we've done that, there's nothing left, we delete the corresponding
4671 line in C<%dbline> to signal that no action needs to be taken for this line.
4672
4673 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4674 which lists all currently-loaded files which have breakpoints. We then look
4675 at each line in each of these files, temporarily switching the C<%dbline>
4676 and C<@dbline> structures to point to the files in question, and do what
4677 we did in the single line case: delete the condition in C<@dbline>, and
4678 delete the key in C<%dbline> if nothing's left.
4679
4680 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4681 C<%break_on_load>, because these structures contain breakpoints for files
4682 and code that haven't been loaded yet. We can just kill these off because there
4683 are no magical debugger structures associated with them.
4684
4685 =cut
4686
4687 sub _remove_breakpoint_entry {
4688     my ($fn, $i) = @_;
4689
4690     delete $dbline{$i};
4691     _delete_breakpoint_data_ref($fn, $i);
4692
4693     return;
4694 }
4695
4696 sub _delete_all_breakpoints {
4697     print {$OUT} "Deleting all breakpoints...\n";
4698
4699     # %had_breakpoints lists every file that had at least one
4700     # breakpoint in it.
4701     for my $fn ( keys %had_breakpoints ) {
4702
4703         # Switch to the desired file temporarily.
4704         local *dbline = $main::{ '_<' . $fn };
4705
4706         $max = $#dbline;
4707
4708         # For all lines in this file ...
4709         for my $i (1 .. $max) {
4710
4711             # If there's a breakpoint or action on this line ...
4712             if ( defined $dbline{$i} ) {
4713
4714                 # ... remove the breakpoint.
4715                 $dbline{$i} =~ s/\A[^\0]+//;
4716                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
4717                     # Remove the entry altogether if no action is there.
4718                     _remove_breakpoint_entry($fn, $i);
4719                 }
4720             } ## end if (defined $dbline{$i...
4721         } ## end for $i (1 .. $max)
4722
4723         # If, after we turn off the "there were breakpoints in this file"
4724         # bit, the entry in %had_breakpoints for this file is zero,
4725         # we should remove this file from the hash.
4726         if ( not $had_breakpoints{$fn} &= (~1) ) {
4727             delete $had_breakpoints{$fn};
4728         }
4729     } ## end for my $fn (keys %had_breakpoints)
4730
4731     # Kill off all the other breakpoints that are waiting for files that
4732     # haven't been loaded yet.
4733     undef %postponed;
4734     undef %postponed_file;
4735     undef %break_on_load;
4736
4737     return;
4738 }
4739
4740 sub _delete_breakpoint_from_line {
4741     my ($i) = @_;
4742
4743     # Woops. This line wasn't breakable at all.
4744     die "Line $i not breakable.\n" if $dbline[$i] == 0;
4745
4746     # Kill the condition, but leave any action.
4747     $dbline{$i} =~ s/\A[^\0]*//;
4748
4749     # Remove the entry entirely if there's no action left.
4750     if ($dbline{$i} eq '') {
4751         _remove_breakpoint_entry($filename, $i);
4752     }
4753
4754     return;
4755 }
4756
4757 sub delete_breakpoint {
4758     my $i = shift;
4759
4760     # If we got a line, delete just that one.
4761     if ( defined($i) ) {
4762         _delete_breakpoint_from_line($i);
4763     }
4764     # No line; delete them all.
4765     else {
4766         _delete_all_breakpoints();
4767     }
4768
4769     return;
4770 }
4771
4772 =head3 cmd_stop (command)
4773
4774 This is meant to be part of the new command API, but it isn't called or used
4775 anywhere else in the debugger. XXX It is probably meant for use in development
4776 of new commands.
4777
4778 =cut
4779
4780 sub cmd_stop {    # As on ^C, but not signal-safy.
4781     $signal = 1;
4782 }
4783
4784 =head3 C<cmd_e> - threads
4785
4786 Display the current thread id:
4787
4788         e
4789
4790 This could be how (when implemented) to send commands to this thread id (e cmd)
4791 or that thread id (e tid cmd).
4792
4793 =cut
4794
4795 sub cmd_e {
4796     my $cmd  = shift;
4797     my $line = shift;
4798         unless (exists($INC{'threads.pm'})) {
4799                 print "threads not loaded($ENV{PERL5DB_THREADED})
4800                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4801         } else {
4802                 my $tid = threads->tid;
4803                 print "thread id: $tid\n";
4804         }
4805 } ## end sub cmd_e
4806
4807 =head3 C<cmd_E> - list of thread ids
4808
4809 Display the list of available thread ids:
4810
4811         E
4812
4813 This could be used (when implemented) to send commands to all threads (E cmd).
4814
4815 =cut
4816
4817 sub cmd_E {
4818     my $cmd  = shift;
4819     my $line = shift;
4820         unless (exists($INC{'threads.pm'})) {
4821                 print "threads not loaded($ENV{PERL5DB_THREADED})
4822                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4823         } else {
4824                 my $tid = threads->tid;
4825                 print "thread ids: ".join(', ',
4826                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4827                 )."\n";
4828         }
4829 } ## end sub cmd_E
4830
4831 =head3 C<cmd_h> - help command (command)
4832
4833 Does the work of either
4834
4835 =over 4
4836
4837 =item *
4838
4839 Showing all the debugger help
4840
4841 =item *
4842
4843 Showing help for a specific command
4844
4845 =back
4846
4847 =cut
4848
4849 use vars qw($help);
4850 use vars qw($summary);
4851
4852 sub cmd_h {
4853     my $cmd = shift;
4854
4855     # If we have no operand, assume null.
4856     my $line = shift || '';
4857
4858     # 'h h'. Print the long-format help.
4859     if ( $line =~ /\Ah\s*\z/ ) {
4860         print_help($help);
4861     }
4862
4863     # 'h <something>'. Search for the command and print only its help.
4864     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
4865
4866         # support long commands; otherwise bogus errors
4867         # happen when you ask for h on <CR> for example
4868         my $qasked = quotemeta($asked);    # for searching; we don't
4869                                            # want to use it as a pattern.
4870                                            # XXX: finds CR but not <CR>
4871
4872         # Search the help string for the command.
4873         if (
4874             $help =~ /^                    # Start of a line
4875                       <?                   # Optional '<'
4876                       (?:[IB]<)            # Optional markup
4877                       $qasked              # The requested command
4878                      /mx
4879           )
4880         {
4881
4882             # It's there; pull it out and print it.
4883             while (
4884                 $help =~ /^
4885                               (<?            # Optional '<'
4886                                  (?:[IB]<)   # Optional markup
4887                                  $qasked     # The command
4888                                  ([\s\S]*?)  # Description line(s)
4889                               \n)            # End of last description line
4890                               (?!\s)         # Next line not starting with
4891                                              # whitespace
4892                              /mgx
4893               )
4894             {
4895                 print_help($1);
4896             }
4897         }
4898
4899         # Not found; not a debugger command.
4900         else {
4901             print_help("B<$asked> is not a debugger command.\n");
4902         }
4903     } ## end elsif ($line =~ /^(\S.*)$/)
4904
4905     # 'h' - print the summary help.
4906     else {
4907         print_help($summary);
4908     }
4909 } ## end sub cmd_h
4910
4911 =head3 C<cmd_i> - inheritance display
4912
4913 Display the (nested) parentage of the module or object given.
4914
4915 =cut
4916
4917 sub cmd_i {
4918     my $cmd  = shift;
4919     my $line = shift;
4920     foreach my $isa ( split( /\s+/, $line ) ) {
4921         $evalarg = $isa;
4922         ($isa) = &eval;
4923         no strict 'refs';
4924         print join(
4925             ', ',
4926             map {
4927                 "$_"
4928                   . (
4929                     defined( ${"$_\::VERSION"} )
4930                     ? ' ' . ${"$_\::VERSION"}
4931                     : undef )
4932               } @{mro::get_linear_isa(ref($isa) || $isa)}
4933         );
4934         print "\n";
4935     }
4936 } ## end sub cmd_i
4937
4938 =head3 C<cmd_l> - list lines (command)
4939
4940 Most of the command is taken up with transforming all the different line
4941 specification syntaxes into 'start-stop'. After that is done, the command
4942 runs a loop over C<@dbline> for the specified range of lines. It handles
4943 the printing of each line and any markers (C<==E<gt>> for current line,
4944 C<b> for break on this line, C<a> for action on this line, C<:> for this
4945 line breakable).
4946
4947 We save the last line listed in the C<$start> global for further listing
4948 later.
4949
4950 =cut
4951
4952 sub cmd_l {
4953     my $current_line = $line;
4954     my $cmd  = shift;
4955     my $line = shift;
4956
4957     # If this is '-something', delete any spaces after the dash.
4958     $line =~ s/^-\s*$/-/;
4959
4960     # If the line is '$something', assume this is a scalar containing a
4961     # line number.
4962     if ( $line =~ /^(\$.*)/s ) {
4963
4964         # Set up for DB::eval() - evaluate in *user* context.
4965         $evalarg = $1;
4966         # $evalarg = $2;
4967         my ($s) = &eval;
4968
4969         # Ooops. Bad scalar.
4970         if ($@) {
4971             print {$OUT} "Error: $@\n";
4972             next CMD;
4973         }
4974
4975         # Good scalar. If it's a reference, find what it points to.
4976         $s = CvGV_name($s);
4977         print {$OUT} "Interpreted as: $1 $s\n";
4978         $line = "$1 $s";
4979
4980         # Call self recursively to really do the command.
4981         cmd_l( 'l', $s );
4982     } ## end if ($line =~ /^(\$.*)/s)
4983
4984     # l name. Try to find a sub by that name.
4985     elsif ( ($subname) = $line =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
4986         my $s = $subname;
4987
4988         # De-Perl4.
4989         $subname =~ s/\'/::/;
4990
4991         # Put it in this package unless it starts with ::.
4992         $subname = $package . "::" . $subname unless $subname =~ /::/;
4993
4994         # Put it in CORE::GLOBAL if t doesn't start with :: and
4995         # it doesn't live in this package and it lives in CORE::GLOBAL.
4996         $subname = "CORE::GLOBAL::$s"
4997           if not defined &$subname
4998           and $s !~ /::/
4999           and defined &{"CORE::GLOBAL::$s"};
5000
5001         # Put leading '::' names into 'main::'.
5002         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5003
5004         # Get name:start-stop from find_sub, and break this up at
5005         # colons.
5006         my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5007
5008         # Pull off start-stop.
5009         my $subrange = pop @pieces;
5010
5011         # If the name contained colons, the split broke it up.
5012         # Put it back together.
5013         $file = join( ':', @pieces );
5014
5015         # If we're not in that file, switch over to it.
5016         if ( $file ne $filename ) {
5017             print $OUT "Switching to file '$file'.\n"
5018               unless $slave_editor;
5019
5020             # Switch debugger's magic structures.
5021             *dbline   = $main::{ '_<' . $file };
5022             $max      = $#dbline;
5023             $filename = $file;
5024         } ## end if ($file ne $filename)
5025
5026         # Subrange is 'start-stop'. If this is less than a window full,
5027         # swap it to 'start+', which will list a window from the start point.
5028         if ($subrange) {
5029             if ( eval($subrange) < -$window ) {
5030                 $subrange =~ s/-.*/+/;
5031             }
5032
5033             # Call self recursively to list the range.
5034             $line = $subrange;
5035             cmd_l( 'l', $subrange );
5036         } ## end if ($subrange)
5037
5038         # Couldn't find it.
5039         else {
5040             print $OUT "Subroutine $subname not found.\n";
5041         }
5042     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5043
5044     # Bare 'l' command.
5045     elsif ( $line !~ /\S/ ) {
5046
5047         # Compute new range to list.
5048         $incr = $window - 1;
5049         $line = $start . '-' . ( $start + $incr );
5050
5051         # Recurse to do it.
5052         cmd_l( 'l', $line );
5053     }
5054
5055     # l [start]+number_of_lines
5056     elsif ( my ($new_start, $new_incr) = $line =~ /\A(\d*)\+(\d*)\z/ ) {
5057
5058         # Don't reset start for 'l +nnn'.
5059         $start = $new_start if $new_start;
5060
5061         # Increment for list. Use window size if not specified.
5062         # (Allows 'l +' to work.)
5063         $incr = $new_incr;
5064         $incr = $window - 1 unless $incr;
5065
5066         # Create a line range we'll understand, and recurse to do it.
5067         $line = $start . '-' . ( $start + $incr );
5068         cmd_l( 'l', $line );
5069     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5070
5071     # l start-stop or l start,stop
5072     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5073
5074         # Determine end point; use end of file if not specified.
5075         my $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5076
5077         # Go on to the end, and then stop.
5078         $end = $max if $end > $max;
5079
5080         # Determine start line.
5081         my $i    = $2;
5082         $i    = $line if $i eq '.';
5083         $i    = 1 if $i < 1;
5084         $incr = $end - $i;
5085
5086         # If we're running under a slave editor, force it to show the lines.
5087         if ($slave_editor) {
5088             print $OUT "\032\032$filename:$i:0\n";
5089             $i = $end;
5090         }
5091
5092         # We're doing it ourselves. We want to show the line and special
5093         # markers for:
5094         # - the current line in execution
5095         # - whether a line is breakable or not
5096         # - whether a line has a break or not
5097         # - whether a line has an action or not
5098         else {
5099             for ( ; $i <= $end ; $i++ ) {
5100
5101                 # Check for breakpoints and actions.
5102                 my ( $stop, $action );
5103                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5104                   if $dbline{$i};
5105
5106                 # ==> if this is the current line in execution,
5107                 # : if it's breakable.
5108                 my $arrow =
5109                   ( $i == $current_line and $filename eq $filename_ini )
5110                   ? '==>'
5111                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5112
5113                 # Add break and action indicators.
5114                 $arrow .= 'b' if $stop;
5115                 $arrow .= 'a' if $action;
5116
5117                 # Print the line.
5118                 print $OUT "$i$arrow\t", $dbline[$i];
5119
5120                 # Move on to the next line. Drop out on an interrupt.
5121                 $i++, last if $signal;
5122             } ## end for (; $i <= $end ; $i++)
5123
5124             # Line the prompt up; print a newline if the last line listed
5125             # didn't have a newline.
5126             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5127         } ## end else [ if ($slave_editor)
5128
5129         # Save the point we last listed to in case another relative 'l'
5130         # command is desired. Don't let it run off the end.
5131         $start = $i;
5132         $start = $max if $start > $max;
5133     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5134 } ## end sub cmd_l
5135
5136 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5137
5138 To list breakpoints, the command has to look determine where all of them are
5139 first. It starts a C<%had_breakpoints>, which tells us what all files have
5140 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5141 magic source and breakpoint data structures) to the file, and then look
5142 through C<%dbline> for lines with breakpoints and/or actions, listing them
5143 out. We look through C<%postponed> not-yet-compiled subroutines that have
5144 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5145 that have breakpoints.
5146
5147 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5148
5149 =cut
5150
5151 sub cmd_L {
5152     my $cmd = shift;
5153
5154     # If no argument, list everything. Pre-5.8.0 version always lists
5155     # everything
5156     my $arg = shift || 'abw';
5157     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5158
5159     # See what is wanted.
5160     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5161     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5162     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5163
5164     # Breaks and actions are found together, so we look in the same place
5165     # for both.
5166     if ( $break_wanted or $action_wanted ) {
5167
5168         # Look in all the files with breakpoints...
5169         for my $file ( keys %had_breakpoints ) {
5170
5171             # Temporary switch to this file.
5172             local *dbline = $main::{ '_<' . $file };
5173
5174             # Set up to look through the whole file.
5175             $max = $#dbline;
5176             my $was;    # Flag: did we print something
5177                         # in this file?
5178
5179             # For each line in the file ...
5180             for my $i (1 .. $max) {
5181
5182                 # We've got something on this line.
5183                 if ( defined $dbline{$i} ) {
5184
5185                     # Print the header if we haven't.
5186                     print $OUT "$file:\n" unless $was++;
5187
5188                     # Print the line.
5189                     print $OUT " $i:\t", $dbline[$i];
5190
5191                     # Pull out the condition and the action.
5192                     my ( $stop, $action ) = split( /\0/, $dbline{$i} );
5193
5194                     # Print the break if there is one and it's wanted.
5195                     print $OUT "   break if (", $stop, ")\n"
5196                       if $stop
5197                       and $break_wanted;
5198
5199                     # Print the action if there is one and it's wanted.
5200                     print $OUT "   action:  ", $action, "\n"
5201                       if $action
5202                       and $action_wanted;
5203
5204                     # Quit if the user hit interrupt.
5205                     last if $signal;
5206                 } ## end if (defined $dbline{$i...
5207             } ## end for my $i (1 .. $max)
5208         } ## end for my $file (keys %had_breakpoints)
5209     } ## end if ($break_wanted or $action_wanted)
5210
5211     # Look for breaks in not-yet-compiled subs:
5212     if ( %postponed and $break_wanted ) {
5213         print $OUT "Postponed breakpoints in subroutines:\n";
5214         my $subname;
5215         for $subname ( keys %postponed ) {
5216             print $OUT " $subname\t$postponed{$subname}\n";
5217             last if $signal;
5218         }
5219     } ## end if (%postponed and $break_wanted)
5220
5221     # Find files that have not-yet-loaded breaks:
5222     my @have = map {    # Combined keys
5223         keys %{ $postponed_file{$_} }
5224     } keys %postponed_file;
5225
5226     # If there are any, list them.
5227     if ( @have and ( $break_wanted or $action_wanted ) ) {
5228         print $OUT "Postponed breakpoints in files:\n";
5229         for my $file ( keys %postponed_file ) {
5230             my $db = $postponed_file{$file};
5231             print $OUT " $file:\n";
5232             for my $line ( sort { $a <=> $b } keys %$db ) {
5233                 print $OUT "  $line:\n";
5234                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5235                 print $OUT "    break if (", $stop, ")\n"
5236                   if $stop
5237                   and $break_wanted;
5238                 print $OUT "    action:  ", $action, "\n"
5239                   if $action
5240                   and $action_wanted;
5241                 last if $signal;
5242             } ## end for $line (sort { $a <=>...
5243             last if $signal;
5244         } ## end for $file (keys %postponed_file)
5245     } ## end if (@have and ($break_wanted...
5246     if ( %break_on_load and $break_wanted ) {
5247         print {$OUT} "Breakpoints on load:\n";
5248         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5249             print {$OUT} " $filename\n";
5250             last BREAK_ON_LOAD if $signal;
5251         }
5252     } ## end if (%break_on_load and...
5253     if ($watch_wanted and ( $trace & 2 )) {
5254         print {$OUT} "Watch-expressions:\n" if @to_watch;
5255         TO_WATCH: for my $expr (@to_watch) {
5256             print {$OUT} " $expr\n";
5257             last TO_WATCH if $signal;
5258         }
5259     }
5260 } ## end sub cmd_L
5261
5262 =head3 C<cmd_M> - list modules (command)
5263
5264 Just call C<list_modules>.
5265
5266 =cut
5267
5268 sub cmd_M {
5269     list_modules();
5270
5271     return;
5272 }
5273
5274 =head3 C<cmd_o> - options (command)
5275
5276 If this is just C<o> by itself, we list the current settings via
5277 C<dump_option>. If there's a nonblank value following it, we pass that on to
5278 C<parse_options> for processing.
5279
5280 =cut
5281
5282 sub cmd_o {
5283     my $cmd = shift;
5284     my $opt = shift || '';    # opt[=val]
5285
5286     # Nonblank. Try to parse and process.
5287     if ( $opt =~ /^(\S.*)/ ) {
5288         &parse_options($1);
5289     }
5290
5291     # Blank. List the current option settings.
5292     else {
5293         for (@options) {
5294             &dump_option($_);
5295         }
5296     }
5297 } ## end sub cmd_o
5298
5299 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5300
5301 Advises the user that the O command has been renamed.
5302
5303 =cut
5304
5305 sub cmd_O {
5306     print $OUT "The old O command is now the o command.\n";             # hint
5307     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5308     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5309 }
5310
5311 =head3 C<cmd_v> - view window (command)
5312
5313 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5314 move back a few lines to list the selected line in context. Uses C<cmd_l>
5315 to do the actual listing after figuring out the range of line to request.
5316
5317 =cut
5318
5319 use vars qw($preview);
5320
5321 sub cmd_v {
5322     my $cmd  = shift;
5323     my $line = shift;
5324
5325     # Extract the line to list around. (Astute readers will have noted that
5326     # this pattern will match whether or not a numeric line is specified,
5327     # which means that we'll always enter this loop (though a non-numeric
5328     # argument results in no action at all)).
5329     if ( $line =~ /^(\d*)$/ ) {
5330
5331         # Total number of lines to list (a windowful).
5332         $incr = $window - 1;
5333
5334         # Set the start to the argument given (if there was one).
5335         $start = $1 if $1;
5336
5337         # Back up by the context amount.
5338         $start -= $preview;
5339
5340         # Put together a linespec that cmd_l will like.
5341         $line = $start . '-' . ( $start + $incr );
5342
5343         # List the lines.
5344         cmd_l( 'l', $line );
5345     } ## end if ($line =~ /^(\d*)$/)
5346 } ## end sub cmd_v
5347
5348 =head3 C<cmd_w> - add a watch expression (command)
5349
5350 The 5.8 version of this command adds a watch expression if one is specified;
5351 it does nothing if entered with no operands.
5352
5353 We extract the expression, save it, evaluate it in the user's context, and
5354 save the value. We'll re-evaluate it each time the debugger passes a line,
5355 and will stop (see the code at the top of the command loop) if the value
5356 of any of the expressions changes.
5357
5358 =cut
5359
5360 sub cmd_w {
5361     my $cmd = shift;
5362
5363     # Null expression if no arguments.
5364     my $expr = shift || '';
5365
5366     # If expression is not null ...
5367     if ( $expr =~ /^(\S.*)/ ) {
5368
5369         # ... save it.
5370         push @to_watch, $expr;
5371
5372         # Parameterize DB::eval and call it to get the expression's value
5373         # in the user's context. This version can handle expressions which
5374         # return a list value.
5375         $evalarg = $expr;
5376         my ($val) = join( ' ', &eval );
5377         $val = ( defined $val ) ? "'$val'" : 'undef';
5378
5379         # Save the current value of the expression.
5380         push @old_watch, $val;
5381
5382         # We are now watching expressions.
5383         $trace |= 2;
5384     } ## end if ($expr =~ /^(\S.*)/)
5385
5386     # You have to give one to get one.
5387     else {
5388         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5389     }
5390 } ## end sub cmd_w
5391
5392 =head3 C<cmd_W> - delete watch expressions (command)
5393
5394 This command accepts either a watch expression to be removed from the list
5395 of watch expressions, or C<*> to delete them all.
5396
5397 If C<*> is specified, we simply empty the watch expression list and the
5398 watch expression value list. We also turn off the bit that says we've got
5399 watch expressions.
5400
5401 If an expression (or partial expression) is specified, we pattern-match
5402 through the expressions and remove the ones that match. We also discard
5403 the corresponding values. If no watch expressions are left, we turn off
5404 the I<watching expressions> bit.
5405
5406 =cut
5407
5408 sub cmd_W {
5409     my $cmd  = shift;
5410     my $expr = shift || '';
5411
5412     # Delete them all.
5413     if ( $expr eq '*' ) {
5414
5415         # Not watching now.
5416         $trace &= ~2;
5417
5418         print $OUT "Deleting all watch expressions ...\n";
5419
5420         # And all gone.
5421         @to_watch = @old_watch = ();
5422     }
5423
5424     # Delete one of them.
5425     elsif ( $expr =~ /^(\S.*)/ ) {
5426
5427         # Where we are in the list.
5428         my $i_cnt = 0;
5429
5430         # For each expression ...
5431         foreach (@to_watch) {
5432             my $val = $to_watch[$i_cnt];
5433
5434             # Does this one match the command argument?
5435             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5436                                       # Yes. Turn it off, and its value too.
5437                 splice( @to_watch,  $i_cnt, 1 );
5438                 splice( @old_watch, $i_cnt, 1 );
5439             }
5440             $i_cnt++;
5441         } ## end foreach (@to_watch)
5442
5443         # We don't bother to turn watching off because
5444         #  a) we don't want to stop calling watchfunction() it it exists
5445         #  b) foreach over a null list doesn't do anything anyway
5446
5447     } ## end elsif ($expr =~ /^(\S.*)/)
5448
5449     # No command arguments entered.
5450     else {
5451         print $OUT
5452           "Deleting a watch-expression requires an expression, or '*' for all\n"
5453           ;    # hint
5454     }
5455 } ## end sub cmd_W
5456
5457 ### END of the API section
5458
5459 =head1 SUPPORT ROUTINES
5460
5461 These are general support routines that are used in a number of places
5462 throughout the debugger.
5463
5464 =head2 save
5465
5466 save() saves the user's versions of globals that would mess us up in C<@saved>,
5467 and installs the versions we like better.
5468
5469 =cut
5470
5471 sub save {
5472
5473     # Save eval failure, command failure, extended OS error, output field
5474     # separator, input record separator, output record separator and
5475     # the warning setting.
5476     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5477
5478     $,  = "";      # output field separator is null string
5479     $/  = "\n";    # input record separator is newline
5480     $\  = "";      # output record separator is null string
5481     $^W = 0;       # warnings are off
5482 } ## end sub save
5483
5484 =head2 C<print_lineinfo> - show where we are now
5485
5486 print_lineinfo prints whatever it is that it is handed; it prints it to the
5487 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5488 us to feed line information to a slave editor without messing up the
5489 debugger output.
5490
5491 =cut
5492
5493 sub print_lineinfo {
5494
5495     # Make the terminal sensible if we're not the primary debugger.
5496     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5497     local $\ = '';
5498     local $, = '';
5499     print $LINEINFO @_;
5500 } ## end sub print_lineinfo
5501
5502 =head2 C<postponed_sub>
5503
5504 Handles setting postponed breakpoints in subroutines once they're compiled.
5505 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5506 range for the subroutine, then mark the file as having a breakpoint,
5507 temporarily switch the C<*dbline> glob over to the source file, and then
5508 search the given range of lines to find a breakable line. If we find one,
5509 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5510
5511 =cut
5512
5513 # The following takes its argument via $evalarg to preserve current @_
5514
5515 sub postponed_sub {
5516
5517     # Get the subroutine name.
5518     my $subname = shift;
5519
5520     # If this is a 'break +<n> if <condition>' ...
5521     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5522
5523         # If there's no offset, use '+0'.
5524         my $offset = $1 || 0;
5525
5526         # find_sub's value is 'fullpath-filename:start-stop'. It's
5527         # possible that the filename might have colons in it too.
5528         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5529         if ($i) {
5530
5531             # We got the start line. Add the offset '+<n>' from
5532             # $postponed{subname}.
5533             $i += $offset;
5534
5535             # Switch to the file this sub is in, temporarily.
5536             local *dbline = $main::{ '_<' . $file };
5537
5538             # No warnings, please.
5539             local $^W = 0;    # != 0 is magical below
5540
5541             # This file's got a breakpoint in it.
5542             $had_breakpoints{$file} |= 1;
5543
5544             # Last line in file.
5545             $max = $#dbline;
5546
5547             # Search forward until we hit a breakable line or get to
5548             # the end of the file.
5549             ++$i until $dbline[$i] != 0 or $i >= $max;
5550
5551             # Copy the breakpoint in and delete it from %postponed.
5552             $dbline{$i} = delete $postponed{$subname};
5553         } ## end if ($i)
5554
5555         # find_sub didn't find the sub.
5556         else {
5557             local $\ = '';
5558             print $OUT "Subroutine $subname not found.\n";
5559         }
5560         return;
5561     } ## end if ($postponed{$subname...
5562     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5563
5564     #print $OUT "In postponed_sub for '$subname'.\n";
5565 } ## end sub postponed_sub
5566
5567 =head2 C<postponed>
5568
5569 Called after each required file is compiled, but before it is executed;
5570 also called if the name of a just-compiled subroutine is a key of
5571 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5572 etc.) into the just-compiled code.
5573
5574 If this is a C<require>'d file, the incoming parameter is the glob
5575 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5576
5577 If it's a subroutine, the incoming parameter is the subroutine name.
5578
5579 =cut
5580
5581 sub postponed {
5582
5583     # If there's a break, process it.
5584     if ($ImmediateStop) {
5585
5586         # Right, we've stopped. Turn it off.
5587         $ImmediateStop = 0;
5588
5589         # Enter the command loop when DB::DB gets called.
5590         $signal = 1;
5591     }
5592
5593     # If this is a subroutine, let postponed_sub() deal with it.
5594     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5595
5596     # Not a subroutine. Deal with the file.
5597     local *dbline = shift;
5598     my $filename = $dbline;
5599     $filename =~ s/^_<//;
5600     local $\ = '';
5601     $signal = 1, print $OUT "'$filename' loaded...\n"
5602       if $break_on_load{$filename};
5603     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5604
5605     # Do we have any breakpoints to put in this file?
5606     return unless $postponed_file{$filename};
5607
5608     # Yes. Mark this file as having breakpoints.
5609     $had_breakpoints{$filename} |= 1;
5610
5611     # "Cannot be done: insufficient magic" - we can't just put the
5612     # breakpoints saved in %postponed_file into %dbline by assigning
5613     # the whole hash; we have to do it one item at a time for the
5614     # breakpoints to be set properly.
5615     #%dbline = %{$postponed_file{$filename}};
5616
5617     # Set the breakpoints, one at a time.
5618     my $key;
5619
5620     for $key ( keys %{ $postponed_file{$filename} } ) {
5621
5622         # Stash the saved breakpoint into the current file's magic line array.
5623         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5624     }
5625
5626     # This file's been compiled; discard the stored breakpoints.
5627     delete $postponed_file{$filename};
5628
5629 } ## end sub postponed
5630
5631 =head2 C<dumpit>
5632
5633 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5634
5635 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5636 a reference to a variable (the thing to be dumped) as its input.
5637
5638 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5639 the currently-selected filehandle, thank you very much). The current
5640 values of the package globals C<$single> and C<$trace> are backed up in
5641 lexicals, and they are turned off (this keeps the debugger from trying
5642 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5643 preserve its current value and it is set to zero to prevent entry/exit
5644 messages from printing, and C<$doret> is localized as well and set to -2 to
5645 prevent return values from being shown.
5646
5647 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5648 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5649 installed version in C<@INC>, yours will be used instead. Possible security
5650 problem?).
5651
5652 It then checks to see if the subroutine C<main::dumpValue> is now defined
5653 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5654 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5655 is called, and picks up the variable to be dumped from the parameter list.
5656
5657 It checks the package global C<%options> to see if there's a C<dumpDepth>
5658 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5659 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5660 structure: -1 means dump everything.
5661
5662 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5663 warning.
5664
5665 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5666 and we then return to the caller.
5667
5668 =cut
5669
5670 sub dumpit {
5671
5672     # Save the current output filehandle and switch to the one
5673     # passed in as the first parameter.
5674     my $savout = select(shift);
5675
5676     # Save current settings of $single and $trace, and then turn them off.
5677     my $osingle = $single;
5678     my $otrace  = $trace;
5679     $single = $trace = 0;
5680
5681     # XXX Okay, what do $frame and $doret do, again?
5682     local $frame = 0;
5683     local $doret = -2;
5684
5685     # Load dumpvar.pl unless we've already got the sub we need from it.
5686     unless ( defined &main::dumpValue ) {
5687         do 'dumpvar.pl' or die $@;
5688     }
5689
5690     # If the load succeeded (or we already had dumpvalue()), go ahead
5691     # and dump things.
5692     if ( defined &main::dumpValue ) {
5693         local $\ = '';
5694         local $, = '';
5695         local $" = ' ';
5696         my $v = shift;
5697         my $maxdepth = shift || $option{dumpDepth};
5698         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5699         &main::dumpValue( $v, $maxdepth );
5700     } ## end if (defined &main::dumpValue)
5701
5702     # Oops, couldn't load dumpvar.pl.
5703     else {
5704         local $\ = '';
5705         print $OUT "dumpvar.pl not available.\n";
5706     }
5707
5708     # Reset $single and $trace to their old values.
5709     $single = $osingle;
5710     $trace  = $otrace;
5711
5712     # Restore the old filehandle.
5713     select($savout);
5714 } ## end sub dumpit
5715
5716 =head2 C<print_trace>
5717
5718 C<print_trace>'s job is to print a stack trace. It does this via the
5719 C<dump_trace> routine, which actually does all the ferreting-out of the
5720 stack trace data. C<print_trace> takes care of formatting it nicely and
5721 printing it to the proper filehandle.
5722
5723 Parameters:
5724
5725 =over 4
5726
5727 =item *
5728
5729 The filehandle to print to.
5730
5731 =item *
5732
5733 How many frames to skip before starting trace.
5734
5735 =item *
5736
5737 How many frames to print.
5738
5739 =item *
5740
5741 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5742
5743 =back
5744
5745 The original comment below seems to be noting that the traceback may not be
5746 correct if this routine is called in a tied method.
5747
5748 =cut
5749
5750 # Tied method do not create a context, so may get wrong message:
5751
5752 sub print_trace {
5753     local $\ = '';
5754     my $fh = shift;
5755
5756     # If this is going to a slave editor, but we're not the primary
5757     # debugger, reset it first.
5758     resetterm(1)
5759       if $fh        eq $LINEINFO    # slave editor
5760       and $LINEINFO eq $OUT         # normal output
5761       and $term_pid != $$;          # not the primary
5762
5763     # Collect the actual trace information to be formatted.
5764     # This is an array of hashes of subroutine call info.
5765     my @sub = dump_trace( $_[0] + 1, $_[1] );
5766
5767     # Grab the "short report" flag from @_.
5768     my $short = $_[2];              # Print short report, next one for sub name
5769
5770     # Run through the traceback info, format it, and print it.
5771     my $s;
5772     for my $i (0 .. $#sub) {
5773
5774         # Drop out if the user has lost interest and hit control-C.
5775         last if $signal;
5776
5777         # Set the separator so arrys print nice.
5778         local $" = ', ';
5779
5780         # Grab and stringify the arguments if they are there.
5781         my $args =
5782           defined $sub[$i]{args}
5783           ? "(@{ $sub[$i]{args} })"
5784           : '';
5785
5786         # Shorten them up if $maxtrace says they're too long.
5787         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5788           if length $args > $maxtrace;
5789
5790         # Get the file name.
5791         my $file = $sub[$i]{file};
5792
5793         # Put in a filename header if short is off.
5794         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
5795
5796         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5797         $s = $sub[$i]{sub};
5798         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5799
5800         # Short report uses trimmed file and sub names.
5801         if ($short) {
5802             my $sub = @_ >= 4 ? $_[3] : $s;
5803             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5804         } ## end if ($short)
5805
5806         # Non-short report includes full names.
5807         else {
5808             print $fh "$sub[$i]{context} = $s$args"
5809               . " called from $file"
5810               . " line $sub[$i]{line}\n";
5811         }
5812     } ## end for my $i (0 .. $#sub)
5813 } ## end sub print_trace
5814
5815 =head2 dump_trace(skip[,count])
5816
5817 Actually collect the traceback information available via C<caller()>. It does
5818 some filtering and cleanup of the data, but mostly it just collects it to
5819 make C<print_trace()>'s job easier.
5820
5821 C<skip> defines the number of stack frames to be skipped, working backwards
5822 from the most current. C<count> determines the total number of frames to
5823 be returned; all of them (well, the first 10^9) are returned if C<count>
5824 is omitted.
5825
5826 This routine returns a list of hashes, from most-recent to least-recent
5827 stack frame. Each has the following keys and values:
5828
5829 =over 4
5830
5831 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5832
5833 =item * C<sub> - subroutine name, or C<eval> information
5834
5835 =item * C<args> - undef, or a reference to an array of arguments
5836
5837 =item * C<file> - the file in which this item was defined (if any)
5838
5839 =item * C<line> - the line on which it was defined
5840
5841 =back
5842
5843 =cut
5844
5845 sub dump_trace {
5846
5847     # How many levels to skip.
5848     my $skip = shift;
5849
5850     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5851     # it's unlikely that we'll have more than a billion stack frames. If you
5852     # do, you've got an awfully big machine...)
5853     my $count = shift || 1e9;
5854
5855     # We increment skip because caller(1) is the first level *back* from
5856     # the current one.  Add $skip to the count of frames so we have a
5857     # simple stop criterion, counting from $skip to $count+$skip.
5858     $skip++;
5859     $count += $skip;
5860
5861     # These variables are used to capture output from caller();
5862     my ( $p, $file, $line, $sub, $h, $context );
5863
5864     my ( $e, $r, @a, @sub, $args );
5865
5866     # XXX Okay... why'd we do that?
5867     my $nothard = not $frame & 8;
5868     local $frame = 0;
5869
5870     # Do not want to trace this.
5871     my $otrace = $trace;
5872     $trace = 0;
5873
5874     # Start out at the skip count.
5875     # If we haven't reached the number of frames requested, and caller() is
5876     # still returning something, stay in the loop. (If we pass the requested
5877     # number of stack frames, or we run out - caller() returns nothing - we
5878     # quit.
5879     # Up the stack frame index to go back one more level each time.
5880     for (
5881         my $i = $skip ;
5882         $i < $count
5883         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5884         $i++
5885     )
5886     {
5887
5888         # Go through the arguments and save them for later.
5889         @a = ();
5890         for my $arg (@args) {
5891             my $type;
5892             if ( not defined $arg ) {    # undefined parameter
5893                 push @a, "undef";
5894             }
5895
5896             elsif ( $nothard and tied $arg ) {    # tied parameter
5897                 push @a, "tied";
5898             }
5899             elsif ( $nothard and $type = ref $arg ) {    # reference
5900                 push @a, "ref($type)";
5901             }
5902             else {                                       # can be stringified
5903                 local $_ =
5904                   "$arg";    # Safe to stringify now - should not call f().
5905
5906                 # Backslash any single-quotes or backslashes.
5907                 s/([\'\\])/\\$1/g;
5908
5909                 # Single-quote it unless it's a number or a colon-separated
5910                 # name.
5911                 s/(.*)/'$1'/s
5912                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5913
5914                 # Turn high-bit characters into meta-whatever.
5915                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5916
5917                 # Turn control characters into ^-whatever.
5918                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5919
5920                 push( @a, $_ );
5921             } ## end else [ if (not defined $arg)
5922         } ## end for $arg (@args)
5923
5924         # If context is true, this is array (@)context.
5925         # If context is false, this is scalar ($) context.
5926         # If neither, context isn't defined. (This is apparently a 'can't
5927         # happen' trap.)
5928         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5929
5930         # if the sub has args ($h true), make an anonymous array of the
5931         # dumped args.
5932         $args = $h ? [@a] : undef;
5933
5934         # remove trailing newline-whitespace-semicolon-end of line sequence
5935         # from the eval text, if any.
5936         $e =~ s/\n\s*\;\s*\Z// if $e;
5937
5938         # Escape backslashed single-quotes again if necessary.
5939         $e =~ s/([\\\'])/\\$1/g if $e;
5940
5941         # if the require flag is true, the eval text is from a require.
5942         if ($r) {
5943             $sub = "require '$e'";
5944         }
5945
5946         # if it's false, the eval text is really from an eval.
5947         elsif ( defined $r ) {
5948             $sub = "eval '$e'";
5949         }
5950
5951         # If the sub is '(eval)', this is a block eval, meaning we don't
5952         # know what the eval'ed text actually was.
5953         elsif ( $sub eq '(eval)' ) {
5954             $sub = "eval {...}";
5955         }
5956
5957         # Stick the collected information into @sub as an anonymous hash.
5958         push(
5959             @sub,
5960             {
5961                 context => $context,
5962                 sub     => $sub,
5963                 args    => $args,
5964                 file    => $file,
5965                 line    => $line
5966             }
5967         );
5968
5969         # Stop processing frames if the user hit control-C.
5970         last if $signal;
5971     } ## end for ($i = $skip ; $i < ...
5972
5973     # Restore the trace value again.
5974     $trace = $otrace;
5975     @sub;
5976 } ## end sub dump_trace
5977
5978 =head2 C<action()>
5979
5980 C<action()> takes input provided as the argument to an add-action command,
5981 either pre- or post-, and makes sure it's a complete command. It doesn't do
5982 any fancy parsing; it just keeps reading input until it gets a string
5983 without a trailing backslash.
5984
5985 =cut
5986
5987 sub action {
5988     my $action = shift;
5989
5990     while ( $action =~ s/\\$// ) {
5991
5992         # We have a backslash on the end. Read more.
5993         $action .= &gets;
5994     } ## end while ($action =~ s/\\$//)
5995
5996     # Return the assembled action.
5997     $action;
5998 } ## end sub action
5999
6000 =head2 unbalanced
6001
6002 This routine mostly just packages up a regular expression to be used
6003 to check that the thing it's being matched against has properly-matched
6004 curly braces.
6005
6006 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6007 speeds things up by only creating the qr//'ed expression once; if it's
6008 already defined, we don't try to define it again. A speed hack.
6009
6010 =cut
6011
6012 use vars qw($balanced_brace_re);
6013
6014 sub unbalanced {
6015
6016     # I hate using globals!
6017     $balanced_brace_re ||= qr{
6018         ^ \{
6019              (?:
6020                  (?> [^{}] + )              # Non-parens without backtracking
6021                 |
6022                  (??{ $balanced_brace_re }) # Group with matching parens
6023               ) *
6024           \} $
6025    }x;
6026     return $_[0] !~ m/$balanced_brace_re/;
6027 } ## end sub unbalanced
6028
6029 =head2 C<gets()>
6030
6031 C<gets()> is a primitive (very primitive) routine to read continuations.
6032 It was devised for reading continuations for actions.
6033 it just reads more input with C<readline()> and returns it.
6034
6035 =cut
6036
6037 sub gets {
6038     &readline("cont: ");
6039 }
6040
6041 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
6042
6043 The C<system()> function assumes that it can just go ahead and use STDIN and
6044 STDOUT, but under the debugger, we want it to use the debugger's input and
6045 outout filehandles.
6046
6047 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
6048 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6049 and then puts everything back again.
6050
6051 =cut
6052
6053 sub system {
6054
6055     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6056     # some non-Unix systems can do system() but have problems with fork().
6057     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
6058     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
6059     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
6060     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
6061
6062     # XXX: using csh or tcsh destroys sigint retvals!
6063     system(@_);
6064     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
6065     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
6066     close(SAVEIN);
6067     close(SAVEOUT);
6068
6069     # most of the $? crud was coping with broken cshisms
6070     if ( $? >> 8 ) {
6071         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6072     }
6073     elsif ($?) {
6074         &warn(
6075             "(Command died of SIG#",
6076             ( $? & 127 ),
6077             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6078             ")", "\n"
6079         );
6080     } ## end elsif ($?)
6081
6082     return $?;
6083
6084 } ## end sub system
6085
6086 =head1 TTY MANAGEMENT
6087
6088 The subs here do some of the terminal management for multiple debuggers.
6089
6090 =head2 setterm
6091
6092 Top-level function called when we want to set up a new terminal for use
6093 by the debugger.
6094
6095 If the C<noTTY> debugger option was set, we'll either use the terminal
6096 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6097 to find one. If we're a forked debugger, we call C<resetterm> to try to
6098 get a whole new terminal if we can.
6099
6100 In either case, we set up the terminal next. If the C<ReadLine> option was
6101 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6102 the appropriate attributes. We then
6103
6104 =cut
6105
6106 use vars qw($ornaments);
6107 use vars qw($rl_attribs);
6108
6109 sub setterm {
6110
6111     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6112     local $frame = 0;
6113     local $doret = -2;
6114     require Term::ReadLine;
6115
6116     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6117     if ($notty) {
6118         if ($tty) {
6119             my ( $i, $o ) = split $tty, /,/;
6120             $o = $i unless defined $o;
6121             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6122             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6123             $IN  = \*IN;
6124             $OUT = \*OUT;
6125             $OUT->autoflush(1);
6126         } ## end if ($tty)
6127
6128         # We don't have a TTY - try to find one via Term::Rendezvous.
6129         else {
6130             require Term::Rendezvous;
6131
6132             # See if we have anything to pass to Term::Rendezvous.
6133             # Use $HOME/.perldbtty$$ if not.
6134             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6135
6136             # Rendezvous and get the filehandles.
6137             my $term_rv = Term::Rendezvous->new( $rv );
6138             $IN  = $term_rv->IN;
6139             $OUT = $term_rv->OUT;
6140         } ## end else [ if ($tty)
6141     } ## end if ($notty)
6142
6143     # We're a daughter debugger. Try to fork off another TTY.
6144     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6145         resetterm(2);
6146     }
6147
6148     # If we shouldn't use Term::ReadLine, don't.
6149     if ( !$rl ) {
6150         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6151     }
6152
6153     # We're using Term::ReadLine. Get all the attributes for this terminal.
6154     else {
6155         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6156
6157         $rl_attribs = $term->Attribs;
6158         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6159           if defined $rl_attribs->{basic_word_break_characters}
6160           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6161         $rl_attribs->{special_prefixes} = '$@&%';
6162         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6163         $rl_attribs->{completion_function} = \&db_complete;
6164     } ## end else [ if (!$rl)
6165
6166     # Set up the LINEINFO filehandle.
6167     $LINEINFO = $OUT     unless defined $LINEINFO;
6168     $lineinfo = $console unless defined $lineinfo;
6169
6170     $term->MinLine(2);
6171
6172     &load_hist();
6173
6174     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6175         $term->SetHistory(@hist);
6176     }
6177
6178     # XXX Ornaments are turned on unconditionally, which is not
6179     # always a good thing.
6180     ornaments($ornaments) if defined $ornaments;
6181     $term_pid = $$;
6182 } ## end sub setterm
6183
6184 sub load_hist {
6185     $histfile //= option_val("HistFile", undef);
6186     return unless defined $histfile;
6187     open my $fh, "<", $histfile or return;
6188     local $/ = "\n";
6189     @hist = ();
6190     while (<$fh>) {
6191         chomp;
6192         push @hist, $_;
6193     }
6194     close $fh;
6195 }
6196
6197 sub save_hist {
6198     return unless defined $histfile;
6199     eval { require File::Path } or return;
6200     eval { require File::Basename } or return;
6201     File::Path::mkpath(File::Basename::dirname($histfile));
6202     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6203     $histsize //= option_val("HistSize",100);
6204     my @copy = grep { $_ ne '?' } @hist;
6205     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6206     for ($start .. $#copy) {
6207         print $fh "$copy[$_]\n";
6208     }
6209     close $fh or die "Could not write '$histfile': $!";
6210 }
6211
6212 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6213
6214 When the process being debugged forks, or the process invokes a command
6215 via C<system()> which starts a new debugger, we need to be able to get a new
6216 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6217 fight over the terminal, and you can never quite be sure who's going to get the
6218 input you're typing.
6219
6220 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6221 is tasked with doing all the necessary operating system mojo to get a new
6222 TTY (and probably another window) and to direct the new debugger to read and
6223 write there.
6224
6225 The debugger provides C<get_fork_TTY> functions which work for TCP
6226 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6227 supported. You are encouraged to write C<get_fork_TTY> functions which
6228 work for I<your> platform and contribute them.
6229
6230 =head3 C<socket_get_fork_TTY>
6231
6232 =cut
6233
6234 sub connect_remoteport {
6235     require IO::Socket;
6236
6237     my $socket = IO::Socket::INET->new(
6238         Timeout  => '10',
6239         PeerAddr => $remoteport,
6240         Proto    => 'tcp',
6241     );
6242     if ( ! $socket ) {
6243         die "Unable to connect to remote host: $remoteport\n";
6244     }
6245     return $socket;
6246 }
6247
6248 sub socket_get_fork_TTY {
6249     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6250
6251     # Do I need to worry about setting $term?
6252
6253     reset_IN_OUT( $IN, $OUT );
6254     return '';
6255 }
6256
6257 =head3 C<xterm_get_fork_TTY>
6258
6259 This function provides the C<get_fork_TTY> function for X11. If a
6260 program running under the debugger forks, a new <xterm> window is opened and
6261 the subsidiary debugger is directed there.
6262
6263 The C<open()> call is of particular note here. We have the new C<xterm>
6264 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6265 command (which prints the device name of the TTY we'll want to use for input
6266 and output to STDOUT, then C<sleep> for a very long time, routing this output
6267 to file number 3. This way we can simply read from the <XT> filehandle (which
6268 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6269
6270 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6271 properly set up.
6272
6273 =cut
6274
6275 sub xterm_get_fork_TTY {
6276     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6277     open XT,
6278 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6279  sleep 10000000' |];
6280
6281     # Get the output from 'tty' and clean it up a little.
6282     my $tty = <XT>;
6283     chomp $tty;
6284
6285     $pidprompt = '';    # Shown anyway in titlebar
6286
6287     # We need $term defined or we can not switch to the newly created xterm
6288     if ($tty ne '' && !defined $term) {
6289         require Term::ReadLine;
6290         if ( !$rl ) {
6291             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6292         }
6293         else {
6294             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6295         }
6296     }
6297     # There's our new TTY.
6298     return $tty;
6299 } ## end sub xterm_get_fork_TTY
6300
6301 =head3 C<os2_get_fork_TTY>
6302
6303 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6304
6305 =cut
6306
6307 # This example function resets $IN, $OUT itself
6308 my $c_pipe = 0;
6309 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6310     local $\  = '';
6311     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6312     my %opt = ( title => "Daughter Perl debugger $pids $name",
6313                 ($rl ? (read_by_key => 1) : ()) );
6314     require OS2::Process;
6315     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6316       or return;
6317     $pidprompt = '';    # Shown anyway in titlebar
6318     reset_IN_OUT($in, $out);
6319     $tty = '*reset*';
6320     return '';          # Indicate that reset_IN_OUT is called
6321 } ## end sub os2_get_fork_TTY
6322
6323 =head3 C<macosx_get_fork_TTY>
6324
6325 The Mac OS X version uses AppleScript to tell Terminal.app to create
6326 a new window.
6327
6328 =cut
6329
6330 # Notes about Terminal.app's AppleScript support,
6331 # (aka things that might break in future OS versions).
6332 #
6333 # The "do script" command doesn't return a reference to the new window
6334 # it creates, but since it appears frontmost and windows are enumerated
6335 # front to back, we can use "first window" === "window 1".
6336 #
6337 # Since "do script" is implemented by supplying the argument (plus a
6338 # return character) as terminal input, there's a potential race condition
6339 # where the debugger could beat the shell to reading the command.
6340 # To prevent this, we wait for the screen to clear before proceeding.
6341 #
6342 # 10.3 and 10.4:
6343 # There's no direct accessor for the tty device name, so we fiddle
6344 # with the window title options until it says what we want.
6345 #
6346 # 10.5:
6347 # There _is_ a direct accessor for the tty device name, _and_ there's
6348 # a new possible component of the window title (the name of the settings
6349 # set).  A separate version is needed.
6350
6351 my @script_versions=
6352
6353     ([237, <<'__LEOPARD__'],
6354 tell application "Terminal"
6355     do script "clear;exec sleep 100000"
6356     tell first tab of first window
6357         copy tty to thetty
6358         set custom title to "forked perl debugger"
6359         set title displays custom title to true
6360         repeat while (length of first paragraph of (get contents)) > 0
6361             delay 0.1
6362         end repeat
6363     end tell
6364 end tell
6365 thetty
6366 __LEOPARD__
6367
6368      [100, <<'__JAGUAR_TIGER__'],
6369 tell application "Terminal"
6370     do script "clear;exec sleep 100000"
6371     tell first window
6372         set title displays shell path to false
6373         set title displays window size to false
6374         set title displays file name to false
6375         set title displays device name to true
6376         set title displays custom title to true
6377         set custom title to ""
6378         copy "/dev/" & name to thetty
6379         set custom title to "forked perl debugger"
6380         repeat while (length of first paragraph of (get contents)) > 0
6381             delay 0.1
6382         end repeat
6383     end tell
6384 end tell
6385 thetty
6386 __JAGUAR_TIGER__
6387
6388 );
6389
6390 sub macosx_get_fork_TTY
6391 {
6392     my($version,$script,$pipe,$tty);
6393
6394     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6395     foreach my $entry (@script_versions) {
6396         if ($version>=$entry->[0]) {
6397             $script=$entry->[1];
6398             last;
6399         }
6400     }
6401     return unless defined($script);
6402     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6403     $tty=readline($pipe);
6404     close($pipe);
6405     return unless defined($tty) && $tty =~ m(^/dev/);
6406     chomp $tty;
6407     return $tty;
6408 }
6409
6410 =head2 C<create_IN_OUT($flags)>
6411
6412 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6413 try to diagnose why.
6414
6415 Flags are:
6416
6417 =over 4
6418
6419 =item * 1 - Don't know how to create a new TTY.
6420
6421 =item * 2 - Debugger has forked, but we can't get a new TTY.
6422
6423 =item * 4 - standard debugger startup is happening.
6424
6425 =back
6426
6427 =cut
6428
6429 use vars qw($fork_TTY);
6430
6431 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6432
6433     # If we know how to get a new TTY, do it! $in will have
6434     # the TTY name if get_fork_TTY works.
6435     my $in = &get_fork_TTY if defined &get_fork_TTY;
6436
6437     # It used to be that
6438     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6439
6440     if ( not defined $in ) {
6441         my $why = shift;
6442
6443         # We don't know how.
6444         print_help(<<EOP) if $why == 1;
6445 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6446 EOP
6447
6448         # Forked debugger.
6449         print_help(<<EOP) if $why == 2;
6450 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6451   This may be an asynchronous session, so the parent debugger may be active.
6452 EOP
6453
6454         # Note that both debuggers are fighting over the same input.
6455         print_help(<<EOP) if $why != 4;
6456   Since two debuggers fight for the same TTY, input is severely entangled.
6457
6458 EOP
6459         print_help(<<EOP);
6460   I know how to switch the output to a different window in xterms, OS/2
6461   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6462   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6463   B<DB::get_fork_TTY()> returning this.
6464
6465   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6466   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6467
6468 EOP
6469     } ## end if (not defined $in)
6470     elsif ( $in ne '' ) {
6471         TTY($in);
6472     }
6473     else {
6474         $console = '';    # Indicate no need to open-from-the-console
6475     }
6476     undef $fork_TTY;
6477 } ## end sub create_IN_OUT
6478
6479 =head2 C<resetterm>
6480
6481 Handles rejiggering the prompt when we've forked off a new debugger.
6482
6483 If the new debugger happened because of a C<system()> that invoked a
6484 program under the debugger, the arrow between the old pid and the new
6485 in the prompt has I<two> dashes instead of one.
6486
6487 We take the current list of pids and add this one to the end. If there
6488 isn't any list yet, we make one up out of the initial pid associated with
6489 the terminal and our new pid, sticking an arrow (either one-dashed or
6490 two dashed) in between them.
6491
6492 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6493 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6494 and try to do that.
6495
6496 =cut
6497
6498 sub resetterm {    # We forked, so we need a different TTY
6499
6500     # Needs to be passed to create_IN_OUT() as well.
6501     my $in = shift;
6502
6503     # resetterm(2): got in here because of a system() starting a debugger.
6504     # resetterm(1): just forked.
6505     my $systemed = $in > 1 ? '-' : '';
6506
6507     # If there's already a list of pids, add this to the end.
6508     if ($pids) {
6509         $pids =~ s/\]/$systemed->$$]/;
6510     }
6511
6512     # No pid list. Time to make one.
6513     else {
6514         $pids = "[$term_pid->$$]";
6515     }
6516
6517     # The prompt we're going to be using for this debugger.
6518     $pidprompt = $pids;
6519
6520     # We now 0wnz this terminal.
6521     $term_pid = $$;
6522
6523     # Just return if we're not supposed to try to create a new TTY.
6524     return unless $CreateTTY & $in;
6525
6526     # Try to create a new IN/OUT pair.
6527     create_IN_OUT($in);
6528 } ## end sub resetterm
6529
6530 =head2 C<readline>
6531
6532 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6533 the next line, print a message saying we got it, add it to the terminal
6534 history (if possible), and return it.
6535
6536 If there's nothing in the typeahead buffer, check the command filehandle stack.
6537 If there are any filehandles there, read from the last one, and return the line
6538 if we got one. If not, we pop the filehandle off and close it, and try the
6539 next one up the stack.
6540
6541 If we've emptied the filehandle stack, we check to see if we've got a socket
6542 open, and we read that and return it if we do. If we don't, we just call the
6543 core C<readline()> and return its value.
6544
6545 =cut
6546
6547 sub readline {
6548
6549     # Localize to prevent it from being smashed in the program being debugged.
6550     local $.;
6551
6552     # If there are stacked filehandles to read from ...
6553     # (Handle it before the typeahead, because we may call source/etc. from
6554     # the typeahead.)
6555     while (@cmdfhs) {
6556
6557         # Read from the last one in the stack.
6558         my $line = CORE::readline( $cmdfhs[-1] );
6559
6560         # If we got a line ...
6561         defined $line
6562           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6563           : close pop @cmdfhs;                            # Pop and close
6564     } ## end while (@cmdfhs)
6565
6566     # Pull a line out of the typeahead if there's stuff there.
6567     if (@typeahead) {
6568
6569         # How many lines left.
6570         my $left = @typeahead;
6571
6572         # Get the next line.
6573         my $got = shift @typeahead;
6574
6575         # Print a message saying we got input from the typeahead.
6576         local $\ = '';
6577         print $OUT "auto(-$left)", shift, $got, "\n";
6578
6579         # Add it to the terminal history (if possible).
6580         $term->AddHistory($got)
6581           if length($got) > 1
6582           and defined $term->Features->{addHistory};
6583         return $got;
6584     } ## end if (@typeahead)
6585
6586     # We really need to read some input. Turn off entry/exit trace and
6587     # return value printing.
6588     local $frame = 0;
6589     local $doret = -2;
6590
6591     # Nothing on the filehandle stack. Socket?
6592     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6593
6594         # Send anything we have to send.
6595         $OUT->write( join( '', @_ ) );
6596
6597         # Receive anything there is to receive.
6598         my $stuff = '';
6599         my $buf;
6600         my $first_time = 1;
6601
6602         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
6603         {
6604             $first_time = 0;
6605             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6606                                             # XXX Don't know. You tell me.
6607         }
6608
6609         # What we got.
6610         return $stuff;
6611     } ## end if (ref $OUT and UNIVERSAL::isa...
6612
6613     # No socket. Just read from the terminal.
6614     else {
6615         return $term->readline(@_);
6616     }
6617 } ## end sub readline
6618
6619 =head1 OPTIONS SUPPORT ROUTINES
6620
6621 These routines handle listing and setting option values.
6622
6623 =head2 C<dump_option> - list the current value of an option setting
6624
6625 This routine uses C<option_val> to look up the value for an option.
6626 It cleans up escaped single-quotes and then displays the option and
6627 its value.
6628
6629 =cut
6630
6631 sub dump_option {
6632     my ( $opt, $val ) = @_;
6633     $val = option_val( $opt, 'N/A' );
6634     $val =~ s/([\\\'])/\\$1/g;
6635     printf $OUT "%20s = '%s'\n", $opt, $val;
6636 } ## end sub dump_option
6637
6638 sub options2remember {
6639     foreach my $k (@RememberOnROptions) {
6640         $option{$k} = option_val( $k, 'N/A' );
6641     }
6642     return %option;
6643 }
6644
6645 =head2 C<option_val> - find the current value of an option
6646
6647 This can't just be a simple hash lookup because of the indirect way that
6648 the option values are stored. Some are retrieved by calling a subroutine,
6649 some are just variables.
6650
6651 You must supply a default value to be used in case the option isn't set.
6652
6653 =cut
6654
6655 sub option_val {
6656     my ( $opt, $default ) = @_;
6657     my $val;
6658
6659     # Does this option exist, and is it a variable?
6660     # If so, retrieve the value via the value in %optionVars.
6661     if (    defined $optionVars{$opt}
6662         and defined ${ $optionVars{$opt} } )
6663     {
6664         $val = ${ $optionVars{$opt} };
6665     }
6666
6667     # Does this option exist, and it's a subroutine?
6668     # If so, call the subroutine via the ref in %optionAction
6669     # and capture the value.
6670     elsif ( defined $optionAction{$opt}
6671         and defined &{ $optionAction{$opt} } )
6672     {
6673         $val = &{ $optionAction{$opt} }();
6674     }
6675
6676     # If there's an action or variable for the supplied option,
6677     # but no value was set, use the default.
6678     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6679         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6680     {
6681         $val = $default;
6682     }
6683
6684     # Otherwise, do the simple hash lookup.
6685     else {
6686         $val = $option{$opt};
6687     }
6688
6689     # If the value isn't defined, use the default.
6690     # Then return whatever the value is.
6691     $val = $default unless defined $val;
6692     $val;
6693 } ## end sub option_val
6694
6695 =head2 C<parse_options>
6696
6697 Handles the parsing and execution of option setting/displaying commands.
6698
6699 An option entered by itself is assumed to be I<set me to 1> (the default value)
6700 if the option is a boolean one. If not, the user is prompted to enter a valid
6701 value or to query the current value (via C<option? >).
6702
6703 If C<option=value> is entered, we try to extract a quoted string from the
6704 value (if it is quoted). If it's not, we just use the whole value as-is.
6705
6706 We load any modules required to service this option, and then we set it: if
6707 it just gets stuck in a variable, we do that; if there's a subroutine to
6708 handle setting the option, we call that.
6709
6710 Finally, if we're running in interactive mode, we display the effect of the
6711 user's command back to the terminal, skipping this if we're setting things
6712 during initialization.
6713
6714 =cut
6715
6716 sub parse_options {
6717     my ($s) = @_;
6718     local $\ = '';
6719
6720     my $option;
6721
6722     # These options need a value. Don't allow them to be clobbered by accident.
6723     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6724       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6725       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6726     };
6727
6728     while (length($s)) {
6729         my $val_defaulted;
6730
6731         # Clean off excess leading whitespace.
6732         $s =~ s/^\s+// && next;
6733
6734         # Options are always all word characters, followed by a non-word
6735         # separator.
6736         if ($s !~ s/^(\w+)(\W?)//) {
6737             print {$OUT} "Invalid option '$s'\n";
6738             last;
6739         }
6740         my ( $opt, $sep ) = ( $1, $2 );
6741
6742         # Make sure that such an option exists.
6743         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
6744           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
6745
6746         unless ($matches) {
6747             print {$OUT} "Unknown option '$opt'\n";
6748             next;
6749         }
6750         if ($matches > 1) {
6751             print {$OUT} "Ambiguous option '$opt'\n";
6752             next;
6753         }
6754         my $val;
6755
6756         # '?' as separator means query, but must have whitespace after it.
6757         if ( "?" eq $sep ) {
6758             if ($s =~ /\A\S/) {
6759                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
6760
6761                 last;
6762             }
6763
6764             #&dump_option($opt);
6765         } ## end if ("?" eq $sep)
6766
6767         # Separator is whitespace (or just a carriage return).
6768         # They're going for a default, which we assume is 1.
6769         elsif ( $sep !~ /\S/ ) {
6770             $val_defaulted = 1;
6771             $val           = "1";   #  this is an evil default; make 'em set it!
6772         }
6773
6774         # Separator is =. Trying to set a value.
6775         elsif ( $sep eq "=" ) {
6776
6777             # If quoted, extract a quoted string.
6778             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6779                 my $quote = $1;
6780                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6781             }
6782
6783             # Not quoted. Use the whole thing. Warn about 'option='.
6784             else {
6785                 $s =~ s/^(\S*)//;
6786                 $val = $1;
6787                 print OUT qq(Option better cleared using $opt=""\n)
6788                   unless length $val;
6789             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6790
6791         } ## end elsif ($sep eq "=")
6792
6793         # "Quoted" with [], <>, or {}.
6794         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6795             my ($end) =
6796               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6797             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6798               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
6799             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6800         } ## end else [ if ("?" eq $sep)
6801
6802         # Exclude non-booleans from getting set to 1 by default.
6803         if ( $opt_needs_val{$option} && $val_defaulted ) {
6804             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6805             print {$OUT}
6806 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
6807             next;
6808         } ## end if ($opt_needs_val{$option...
6809
6810         # Save the option value.
6811         $option{$option} = $val if defined $val;
6812
6813         # Load any module that this option requires.
6814         if ( defined($optionRequire{$option}) && defined($val) ) {
6815             eval qq{
6816             local \$frame = 0;
6817             local \$doret = -2;
6818             require '$optionRequire{$option}';
6819             1;
6820             } || die $@   # XXX: shouldn't happen
6821         }
6822
6823         # Set it.
6824         # Stick it in the proper variable if it goes in a variable.
6825         if (defined($optionVars{$option}) && defined($val)) {
6826             ${ $optionVars{$option} } = $val;
6827         }
6828
6829         # Call the appropriate sub if it gets set via sub.
6830         if (defined($optionAction{$option})
6831           && defined (&{ $optionAction{$option} })
6832           && defined ($val))
6833         {
6834           &{ $optionAction{$option} }($val);
6835         }
6836
6837         # Not initialization - echo the value we set it to.
6838         dump_option($option) if ($OUT ne \*STDERR);
6839     } ## end while (length)
6840 } ## end sub parse_options
6841
6842 =head1 RESTART SUPPORT
6843
6844 These routines are used to store (and restore) lists of items in environment
6845 variables during a restart.
6846
6847 =head2 set_list
6848
6849 Set_list packages up items to be stored in a set of environment variables
6850 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6851 the values). Values outside the standard ASCII charset are stored by encoding
6852 then as hexadecimal values.
6853
6854 =cut
6855
6856 sub set_list {
6857     my ( $stem, @list ) = @_;
6858     my $val;
6859
6860     # VAR_n: how many we have. Scalar assignment gets the number of items.
6861     $ENV{"${stem}_n"} = @list;
6862
6863     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6864     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6865     for my $i ( 0 .. $#list ) {
6866         $val = $list[$i];
6867         $val =~ s/\\/\\\\/g;
6868         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6869         $ENV{"${stem}_$i"} = $val;
6870     } ## end for $i (0 .. $#list)
6871 } ## end sub set_list
6872
6873 =head2 get_list
6874
6875 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6876 back, and then pull VAR_0, VAR_1. etc. back out.
6877
6878 =cut
6879
6880 sub get_list {
6881     my $stem = shift;
6882     my @list;
6883     my $n = delete $ENV{"${stem}_n"};
6884     my $val;
6885     for my $i ( 0 .. $n - 1 ) {
6886         $val = delete $ENV{"${stem}_$i"};
6887         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6888         push @list, $val;
6889     }
6890     @list;
6891 } ## end sub get_list
6892
6893 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6894
6895 =head2 catch()
6896
6897 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6898 set an already-existing global scalar variable to a constant value. This
6899 avoids allocating any memory possibly in the middle of something that will
6900 get all confused if we do, particularly under I<unsafe signals>.
6901
6902 =cut
6903
6904 sub catch {
6905     $signal = 1;
6906     return;    # Put nothing on the stack - malloc/free land!
6907 }
6908
6909 =head2 C<warn()>
6910
6911 C<warn> emits a warning, by joining together its arguments and printing
6912 them, with couple of fillips.
6913
6914 If the composited message I<doesn't> end with a newline, we automatically
6915 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6916 to be set to the filehandle to be used to output warnings; it makes no
6917 assumptions about what filehandles are available.
6918
6919 =cut
6920
6921 sub warn {
6922     my ($msg) = join( "", @_ );
6923     $msg .= ": $!\n" unless $msg =~ /\n$/;
6924     local $\ = '';
6925     print $OUT $msg;
6926 } ## end sub warn
6927
6928 =head1 INITIALIZATION TTY SUPPORT
6929
6930 =head2 C<reset_IN_OUT>
6931
6932 This routine handles restoring the debugger's input and output filehandles
6933 after we've tried and failed to move them elsewhere.  In addition, it assigns
6934 the debugger's output filehandle to $LINEINFO if it was already open there.
6935
6936 =cut
6937
6938 sub reset_IN_OUT {
6939     my $switch_li = $LINEINFO eq $OUT;
6940
6941     # If there's a term and it's able to get a new tty, try to get one.
6942     if ( $term and $term->Features->{newTTY} ) {
6943         ( $IN, $OUT ) = ( shift, shift );
6944         $term->newTTY( $IN, $OUT );
6945     }
6946
6947     # This term can't get a new tty now. Better luck later.
6948     elsif ($term) {
6949         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
6950     }
6951
6952     # Set the filehndles up as they were.
6953     else {
6954         ( $IN, $OUT ) = ( shift, shift );
6955     }
6956
6957     # Unbuffer the output filehandle.
6958     $OUT->autoflush(1);
6959
6960     # Point LINEINFO to the same output filehandle if it was there before.
6961     $LINEINFO = $OUT if $switch_li;
6962 } ## end sub reset_IN_OUT
6963
6964 =head1 OPTION SUPPORT ROUTINES
6965
6966 The following routines are used to process some of the more complicated
6967 debugger options.
6968
6969 =head2 C<TTY>
6970
6971 Sets the input and output filehandles to the specified files or pipes.
6972 If the terminal supports switching, we go ahead and do it. If not, and
6973 there's already a terminal in place, we save the information to take effect
6974 on restart.
6975
6976 If there's no terminal yet (for instance, during debugger initialization),
6977 we go ahead and set C<$console> and C<$tty> to the file indicated.
6978
6979 =cut
6980
6981 sub TTY {
6982
6983     if ( @_ and $term and $term->Features->{newTTY} ) {
6984
6985         # This terminal supports switching to a new TTY.
6986         # Can be a list of two files, or on string containing both names,
6987         # comma-separated.
6988         # XXX Should this perhaps be an assignment from @_?
6989         my ( $in, $out ) = shift;
6990         if ( $in =~ /,/ ) {
6991
6992             # Split list apart if supplied.
6993             ( $in, $out ) = split /,/, $in, 2;
6994         }
6995         else {
6996
6997             # Use the same file for both input and output.
6998             $out = $in;
6999         }
7000
7001         # Open file onto the debugger's filehandles, if you can.
7002         open IN,  $in     or die "cannot open '$in' for read: $!";
7003         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7004
7005         # Swap to the new filehandles.
7006         reset_IN_OUT( \*IN, \*OUT );
7007
7008         # Save the setting for later.
7009         return $tty = $in;
7010     } ## end if (@_ and $term and $term...
7011
7012     # Terminal doesn't support new TTY, or doesn't support readline.
7013     # Can't do it now, try restarting.
7014     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
7015
7016     # Useful if done through PERLDB_OPTS:
7017     $console = $tty = shift if @_;
7018
7019     # Return whatever the TTY is.
7020     $tty or $console;
7021 } ## end sub TTY
7022
7023 =head2 C<noTTY>
7024
7025 Sets the C<$notty> global, controlling whether or not the debugger tries to
7026 get a terminal to read from. If called after a terminal is already in place,
7027 we save the value to use it if we're restarted.
7028
7029 =cut
7030
7031 sub noTTY {
7032     if ($term) {
7033         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7034     }
7035     $notty = shift if @_;
7036     $notty;
7037 } ## end sub noTTY
7038
7039 =head2 C<ReadLine>
7040
7041 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7042 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7043 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7044 the value in case a restart is done so we can change it then.
7045
7046 =cut
7047
7048 sub ReadLine {
7049     if ($term) {
7050         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7051     }
7052     $rl = shift if @_;
7053     $rl;
7054 } ## end sub ReadLine
7055
7056 =head2 C<RemotePort>
7057
7058 Sets the port that the debugger will try to connect to when starting up.
7059 If the terminal's already been set up, we can't do it, but we remember the
7060 setting in case the user does a restart.
7061
7062 =cut
7063
7064 sub RemotePort {
7065     if ($term) {
7066         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7067     }
7068     $remoteport = shift if @_;
7069     $remoteport;
7070 } ## end sub RemotePort
7071
7072 =head2 C<tkRunning>
7073
7074 Checks with the terminal to see if C<Tk> is running, and returns true or
7075 false. Returns false if the current terminal doesn't support C<readline>.
7076
7077 =cut
7078
7079 sub tkRunning {
7080     if ( ${ $term->Features }{tkRunning} ) {
7081         return $term->tkRunning(@_);
7082     }
7083     else {
7084         local $\ = '';
7085         print $OUT "tkRunning not supported by current ReadLine package.\n";
7086         0;
7087     }
7088 } ## end sub tkRunning
7089
7090 =head2 C<NonStop>
7091
7092 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7093 debugger remembers the setting in case you restart, though.
7094
7095 =cut
7096
7097 sub NonStop {
7098     if ($term) {
7099         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7100           if @_;
7101     }
7102     $runnonstop = shift if @_;
7103     $runnonstop;
7104 } ## end sub NonStop
7105
7106 sub DollarCaretP {
7107     if ($term) {
7108         &warn("Some flag changes could not take effect until next 'R'!\n")
7109           if @_;
7110     }
7111     $^P = parse_DollarCaretP_flags(shift) if @_;
7112     expand_DollarCaretP_flags($^P);
7113 }
7114
7115 =head2 C<pager>
7116
7117 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7118 there already.
7119
7120 =cut
7121
7122 sub pager {
7123     if (@_) {
7124         $pager = shift;
7125         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7126     }
7127     $pager;
7128 } ## end sub pager
7129
7130 =head2 C<shellBang>
7131
7132 Sets the shell escape command, and generates a printable copy to be used
7133 in the help.
7134
7135 =cut
7136
7137 sub shellBang {
7138
7139     # If we got an argument, meta-quote it, and add '\b' if it
7140     # ends in a word character.
7141     if (@_) {
7142         $sh = quotemeta shift;
7143         $sh .= "\\b" if $sh =~ /\w$/;
7144     }
7145
7146     # Generate the printable version for the help:
7147     $psh = $sh;    # copy it
7148     $psh =~ s/\\b$//;        # Take off trailing \b if any
7149     $psh =~ s/\\(.)/$1/g;    # De-escape
7150     $psh;                    # return the printable version
7151 } ## end sub shellBang
7152
7153 =head2 C<ornaments>
7154
7155 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7156 was passed as the argument. (This means you can't override the terminal's
7157 ornaments.)
7158
7159 =cut
7160
7161 sub ornaments {
7162     if ( defined $term ) {
7163
7164         # We don't want to show warning backtraces, but we do want die() ones.
7165         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7166
7167         # No ornaments if the terminal doesn't support them.
7168         return '' unless $term->Features->{ornaments};
7169         eval { $term->ornaments(@_) } || '';
7170     }
7171
7172     # Use what was passed in if we can't determine it ourselves.
7173     else {
7174         $ornaments = shift;
7175     }
7176 } ## end sub ornaments
7177
7178 =head2 C<recallCommand>
7179
7180 Sets the recall command, and builds a printable version which will appear in
7181 the help text.
7182
7183 =cut
7184
7185 sub recallCommand {
7186
7187     # If there is input, metaquote it. Add '\b' if it ends with a word
7188     # character.
7189     if (@_) {
7190         $rc = quotemeta shift;
7191         $rc .= "\\b" if $rc =~ /\w$/;
7192     }
7193
7194     # Build it into a printable version.
7195     $prc = $rc;    # Copy it
7196     $prc =~ s/\\b$//;        # Remove trailing \b
7197     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7198     $prc;                    # Return the printable version
7199 } ## end sub recallCommand
7200
7201 =head2 C<LineInfo> - where the line number information goes
7202
7203 Called with no arguments, returns the file or pipe that line info should go to.
7204
7205 Called with an argument (a file or a pipe), it opens that onto the
7206 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7207 file or pipe again to the caller.
7208
7209 =cut
7210
7211 sub LineInfo {
7212     if (@_) {
7213         $lineinfo = shift;
7214
7215         #  If this is a valid "thing to be opened for output", tack a
7216         # '>' onto the front.
7217         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7218
7219         # If this is a pipe, the stream points to a slave editor.
7220         $slave_editor = ( $stream =~ /^\|/ );
7221
7222         # Open it up and unbuffer it.
7223         open( LINEINFO, $stream ) || &warn("Cannot open '$stream' for write");
7224         $LINEINFO = \*LINEINFO;
7225         $LINEINFO->autoflush(1);
7226     }
7227
7228     return $lineinfo;
7229 } ## end sub LineInfo
7230
7231 =head1 COMMAND SUPPORT ROUTINES
7232
7233 These subroutines provide functionality for various commands.
7234
7235 =head2 C<list_modules>
7236
7237 For the C<M> command: list modules loaded and their versions.
7238 Essentially just runs through the keys in %INC, picks each package's
7239 C<$VERSION> variable, gets the file name, and formats the information
7240 for output.
7241
7242 =cut
7243
7244 sub list_modules {    # versions
7245     my %version;
7246     my $file;
7247
7248     # keys are the "as-loaded" name, values are the fully-qualified path
7249     # to the file itself.
7250     for ( keys %INC ) {
7251         $file = $_;                                # get the module name
7252         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7253         s,/,::,g;                                  # change '/' to '::'
7254         s/^perl5db$/DB/;                           # Special case: debugger
7255                                                    # moves to package DB
7256         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7257
7258         # If the package has a $VERSION package global (as all good packages
7259         # should!) decode it and save as partial message.
7260         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7261         if ( defined $pkg_version ) {
7262             $version{$file} = "$pkg_version from ";
7263         }
7264
7265         # Finish up the message with the file the package came from.
7266         $version{$file} .= $INC{$file};
7267     } ## end for (keys %INC)
7268
7269     # Hey, dumpit() formats a hash nicely, so why not use it?
7270     dumpit( $OUT, \%version );
7271 } ## end sub list_modules
7272
7273 =head2 C<sethelp()>
7274
7275 Sets up the monster string used to format and print the help.
7276
7277 =head3 HELP MESSAGE FORMAT
7278
7279 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7280 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7281 easy to parse and portable, but which still allows the help to be a little
7282 nicer than just plain text.
7283
7284 Essentially, you define the command name (usually marked up with C<< B<> >>
7285 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7286 newline. The descriptive text can also be marked up in the same way. If you
7287 need to continue the descriptive text to another line, start that line with
7288 just tabs and then enter the marked-up text.
7289
7290 If you are modifying the help text, I<be careful>. The help-string parser is
7291 not very sophisticated, and if you don't follow these rules it will mangle the
7292 help beyond hope until you fix the string.
7293
7294 =cut
7295
7296 use vars qw($pre580_help);
7297 use vars qw($pre580_summary);
7298
7299 sub sethelp {
7300
7301     # XXX: make sure there are tabs between the command and explanation,
7302     #      or print_help will screw up your formatting if you have
7303     #      eeevil ornaments enabled.  This is an insane mess.
7304
7305     $help = "
7306 Help is currently only available for the new 5.8 command set.
7307 No help is available for the old command set.
7308 We assume you know what you're doing if you switch to it.
7309
7310 B<T>        Stack trace.
7311 B<s> [I<expr>]    Single step [in I<expr>].
7312 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7313 <B<CR>>        Repeat last B<n> or B<s> command.
7314 B<r>        Return from current subroutine.
7315 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7316         at the specified position.
7317 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7318 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7319 B<l> I<line>        List single I<line>.
7320 B<l> I<subname>    List first window of lines from subroutine.
7321 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7322 B<l>        List next window of lines.
7323 B<->        List previous window of lines.
7324 B<v> [I<line>]    View window around I<line>.
7325 B<.>        Return to the executed line.
7326 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7327         I<filename> may be either the full name of the file, or a regular
7328         expression matching the full file name:
7329         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7330         Evals (with saved bodies) are considered to be filenames:
7331         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7332         (in the order of execution).
7333 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7334 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7335 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7336 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7337 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7338 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7339 B<b>        Sets breakpoint on current line)
7340 B<b> [I<line>] [I<condition>]
7341         Set breakpoint; I<line> defaults to the current execution line;
7342         I<condition> breaks if it evaluates to true, defaults to '1'.
7343 B<b> I<subname> [I<condition>]
7344         Set breakpoint at first line of subroutine.
7345 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7346 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7347 B<b> B<postpone> I<subname> [I<condition>]
7348         Set breakpoint at first line of subroutine after
7349         it is compiled.
7350 B<b> B<compile> I<subname>
7351         Stop after the subroutine is compiled.
7352 B<B> [I<line>]    Delete the breakpoint for I<line>.
7353 B<B> I<*>             Delete all breakpoints.
7354 B<a> [I<line>] I<command>
7355         Set an action to be done before the I<line> is executed;
7356         I<line> defaults to the current execution line.
7357         Sequence is: check for breakpoint/watchpoint, print line
7358         if necessary, do action, prompt user if necessary,
7359         execute line.
7360 B<a>        Does nothing
7361 B<A> [I<line>]    Delete the action for I<line>.
7362 B<A> I<*>             Delete all actions.
7363 B<w> I<expr>        Add a global watch-expression.
7364 B<w>             Does nothing
7365 B<W> I<expr>        Delete a global watch-expression.
7366 B<W> I<*>             Delete all watch-expressions.
7367 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7368         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7369 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7370 B<x> I<expr>        Evals expression in list context, dumps the result.
7371 B<m> I<expr>        Evals expression in list context, prints methods callable
7372         on the first element of the result.
7373 B<m> I<class>        Prints methods callable via the given class.
7374 B<M>        Show versions of loaded modules.
7375 B<i> I<class>       Prints nested parents of given class.
7376 B<e>         Display current thread id.
7377 B<E>         Display all thread ids the current one will be identified: <n>.
7378 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7379
7380 B<<> ?            List Perl commands to run before each prompt.
7381 B<<> I<expr>        Define Perl command to run before each prompt.
7382 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7383 B<< *>                Delete the list of perl commands to run before each prompt.
7384 B<>> ?            List Perl commands to run after each prompt.
7385 B<>> I<expr>        Define Perl command to run after each prompt.
7386 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7387 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7388 B<{> I<db_command>    Define debugger command to run before each prompt.
7389 B<{> ?            List debugger commands to run before each prompt.
7390 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7391 B<{ *>             Delete the list of debugger commands to run before each prompt.
7392 B<$prc> I<number>    Redo a previous command (default previous command).
7393 B<$prc> I<-number>    Redo number'th-to-last command.
7394 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7395         See 'B<O> I<recallCommand>' too.
7396 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7397       . (
7398         $rc eq $sh
7399         ? ""
7400         : "
7401 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7402       ) . "
7403         See 'B<O> I<shellBang>' too.
7404 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7405 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7406 B<rerun>           Rerun session to current position.
7407 B<rerun> I<n>         Rerun session to numbered command.
7408 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7409 B<H> I<-number>    Display last number commands (default all).
7410 B<H> I<*>          Delete complete history.
7411 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7412 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7413 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7414 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7415 I<command>        Execute as a perl statement in current package.
7416 B<R>        Pure-man-restart of debugger, some of debugger state
7417         and command-line options may be lost.
7418         Currently the following settings are preserved:
7419         history, breakpoints and actions, debugger B<O>ptions
7420         and the following command-line options: I<-w>, I<-I>, I<-e>.
7421
7422 B<o> [I<opt>] ...    Set boolean option to true
7423 B<o> [I<opt>B<?>]    Query options
7424 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7425         Set options.  Use quotes if spaces in value.
7426     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7427     I<pager>            program for output of \"|cmd\";
7428     I<tkRunning>            run Tk while prompting (with ReadLine);
7429     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7430     I<inhibit_exit>        Allows stepping off the end of the script.
7431     I<ImmediateStop>        Debugger should stop as early as possible.
7432     I<RemotePort>            Remote hostname:port for remote debugging
7433   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7434     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7435     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7436     I<globPrint>             whether to print contents of globs;
7437     I<DumpDBFiles>         dump arrays holding debugged files;
7438     I<DumpPackages>         dump symbol tables of packages;
7439     I<DumpReused>             dump contents of \"reused\" addresses;
7440     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7441     I<bareStringify>         Do not print the overload-stringified value;
7442   Other options include:
7443     I<PrintRet>        affects printing of return value after B<r> command,
7444     I<frame>        affects printing messages on subroutine entry/exit.
7445     I<AutoTrace>    affects printing messages on possible breaking points.
7446     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7447     I<ornaments>     affects screen appearance of the command line.
7448     I<CreateTTY>     bits control attempts to create a new TTY on events:
7449             1: on fork()    2: debugger is started inside debugger
7450             4: on startup
7451     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7452     You can put additional initialization options I<TTY>, I<noTTY>,
7453     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7454     B<R> after you set them).
7455
7456 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7457 B<h>        Summary of debugger commands.
7458 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7459 B<h h>        Long help for debugger commands
7460 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7461         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7462         Set B<\$DB::doccmd> to change viewer.
7463
7464 Type '|h h' for a paged display if this was too hard to read.
7465
7466 ";    # Fix balance of vi % matching: }}}}
7467
7468     #  note: tabs in the following section are not-so-helpful
7469     $summary = <<"END_SUM";
7470 I<List/search source lines:>               I<Control script execution:>
7471   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7472   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7473   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7474   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7475   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7476   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7477 I<Debugger controls:>                        B<L>           List break/watch/actions
7478   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7479   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7480   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7481   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7482   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7483   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7484   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7485   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7486   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7487 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7488   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7489   B<p> I<expr>         Print expression (uses script's current package).
7490   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7491   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7492   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7493   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7494   B<e>     Display thread id     B<E> Display all thread ids.
7495 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7496 END_SUM
7497
7498     # ')}}; # Fix balance of vi % matching
7499
7500     # and this is really numb...
7501     $pre580_help = "
7502 B<T>        Stack trace.
7503 B<s> [I<expr>]    Single step [in I<expr>].
7504 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7505 B<CR>>        Repeat last B<n> or B<s> command.
7506 B<r>        Return from current subroutine.
7507 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7508         at the specified position.
7509 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7510 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7511 B<l> I<line>        List single I<line>.
7512 B<l> I<subname>    List first window of lines from subroutine.
7513 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7514 B<l>        List next window of lines.
7515 B<->        List previous window of lines.
7516 B<w> [I<line>]    List window around I<line>.
7517 B<.>        Return to the executed line.
7518 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7519         I<filename> may be either the full name of the file, or a regular
7520         expression matching the full file name:
7521         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7522         Evals (with saved bodies) are considered to be filenames:
7523         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7524         (in the order of execution).
7525 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7526 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7527 B<L>        List all breakpoints and actions.
7528 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7529 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7530 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7531 B<b> [I<line>] [I<condition>]
7532         Set breakpoint; I<line> defaults to the current execution line;
7533         I<condition> breaks if it evaluates to true, defaults to '1'.
7534 B<b> I<subname> [I<condition>]
7535         Set breakpoint at first line of subroutine.
7536 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7537 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7538 B<b> B<postpone> I<subname> [I<condition>]
7539         Set breakpoint at first line of subroutine after
7540         it is compiled.
7541 B<b> B<compile> I<subname>
7542         Stop after the subroutine is compiled.
7543 B<d> [I<line>]    Delete the breakpoint for I<line>.
7544 B<D>        Delete all breakpoints.
7545 B<a> [I<line>] I<command>
7546         Set an action to be done before the I<line> is executed;
7547         I<line> defaults to the current execution line.
7548         Sequence is: check for breakpoint/watchpoint, print line
7549         if necessary, do action, prompt user if necessary,
7550         execute line.
7551 B<a> [I<line>]    Delete the action for I<line>.
7552 B<A>        Delete all actions.
7553 B<W> I<expr>        Add a global watch-expression.
7554 B<W>        Delete all watch-expressions.
7555 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7556         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7557 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7558 B<x> I<expr>        Evals expression in list context, dumps the result.
7559 B<m> I<expr>        Evals expression in list context, prints methods callable
7560         on the first element of the result.
7561 B<m> I<class>        Prints methods callable via the given class.
7562
7563 B<<> ?            List Perl commands to run before each prompt.
7564 B<<> I<expr>        Define Perl command to run before each prompt.
7565 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7566 B<>> ?            List Perl commands to run after each prompt.
7567 B<>> I<expr>        Define Perl command to run after each prompt.
7568 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7569 B<{> I<db_command>    Define debugger command to run before each prompt.
7570 B<{> ?            List debugger commands to run before each prompt.
7571 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7572 B<$prc> I<number>    Redo a previous command (default previous command).
7573 B<$prc> I<-number>    Redo number'th-to-last command.
7574 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7575         See 'B<O> I<recallCommand>' too.
7576 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7577       . (
7578         $rc eq $sh
7579         ? ""
7580         : "
7581 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7582       ) . "
7583         See 'B<O> I<shellBang>' too.
7584 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7585 B<H> I<-number>    Display last number commands (default all).
7586 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7587 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7588 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7589 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7590 I<command>        Execute as a perl statement in current package.
7591 B<v>        Show versions of loaded modules.
7592 B<R>        Pure-man-restart of debugger, some of debugger state
7593         and command-line options may be lost.
7594         Currently the following settings are preserved:
7595         history, breakpoints and actions, debugger B<O>ptions
7596         and the following command-line options: I<-w>, I<-I>, I<-e>.
7597
7598 B<O> [I<opt>] ...    Set boolean option to true
7599 B<O> [I<opt>B<?>]    Query options
7600 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7601         Set options.  Use quotes if spaces in value.
7602     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7603     I<pager>            program for output of \"|cmd\";
7604     I<tkRunning>            run Tk while prompting (with ReadLine);
7605     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7606     I<inhibit_exit>        Allows stepping off the end of the script.
7607     I<ImmediateStop>        Debugger should stop as early as possible.
7608     I<RemotePort>            Remote hostname:port for remote debugging
7609   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7610     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7611     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7612     I<globPrint>             whether to print contents of globs;
7613     I<DumpDBFiles>         dump arrays holding debugged files;
7614     I<DumpPackages>         dump symbol tables of packages;
7615     I<DumpReused>             dump contents of \"reused\" addresses;
7616     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7617     I<bareStringify>         Do not print the overload-stringified value;
7618   Other options include:
7619     I<PrintRet>        affects printing of return value after B<r> command,
7620     I<frame>        affects printing messages on subroutine entry/exit.
7621     I<AutoTrace>    affects printing messages on possible breaking points.
7622     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7623     I<ornaments>     affects screen appearance of the command line.
7624     I<CreateTTY>     bits control attempts to create a new TTY on events:
7625             1: on fork()    2: debugger is started inside debugger
7626             4: on startup
7627     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7628     You can put additional initialization options I<TTY>, I<noTTY>,
7629     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7630     B<R> after you set them).
7631
7632 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7633 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7634 B<h h>        Summary of debugger commands.
7635 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7636         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7637         Set B<\$DB::doccmd> to change viewer.
7638
7639 Type '|h' for a paged display if this was too hard to read.
7640
7641 ";    # Fix balance of vi % matching: }}}}
7642
7643     #  note: tabs in the following section are not-so-helpful
7644     $pre580_summary = <<"END_SUM";
7645 I<List/search source lines:>               I<Control script execution:>
7646   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7647   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7648   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7649   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7650   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7651   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7652 I<Debugger controls:>                        B<L>           List break/watch/actions
7653   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7654   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7655   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7656   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7657   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7658   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7659   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7660   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7661 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7662   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7663   B<p> I<expr>         Print expression (uses script's current package).
7664   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7665   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7666   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7667   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7668 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7669 END_SUM
7670
7671     # ')}}; # Fix balance of vi % matching
7672
7673 } ## end sub sethelp
7674
7675 =head2 C<print_help()>
7676
7677 Most of what C<print_help> does is just text formatting. It finds the
7678 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7679 terminal control characters to simulate them (courtesy of
7680 C<Term::ReadLine::TermCap>).
7681
7682 =cut
7683
7684 sub print_help {
7685     my $help_str = (@_);
7686
7687     # Restore proper alignment destroyed by eeevil I<> and B<>
7688     # ornaments: A pox on both their houses!
7689     #
7690     # A help command will have everything up to and including
7691     # the first tab sequence padded into a field 16 (or if indented 20)
7692     # wide.  If it's wider than that, an extra space will be added.
7693     $help_str =~ s{
7694         ^                       # only matters at start of line
7695           ( \040{4} | \t )*     # some subcommands are indented
7696           ( < ?                 # so <CR> works
7697             [BI] < [^\t\n] + )  # find an eeevil ornament
7698           ( \t+ )               # original separation, discarded
7699           ( .* )                # this will now start (no earlier) than
7700                                 # column 16
7701     } {
7702         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7703         my $clean = $command;
7704         $clean =~ s/[BI]<([^>]*)>/$1/g;
7705
7706         # replace with this whole string:
7707         ($leadwhite ? " " x 4 : "")
7708       . $command
7709       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7710       . $text;
7711
7712     }mgex;
7713
7714     $help_str =~ s{                          # handle bold ornaments
7715        B < ( [^>] + | > ) >
7716     } {
7717           $Term::ReadLine::TermCap::rl_term_set[2]
7718         . $1
7719         . $Term::ReadLine::TermCap::rl_term_set[3]
7720     }gex;
7721
7722     $help_str =~ s{                         # handle italic ornaments
7723        I < ( [^>] + | > ) >
7724     } {
7725           $Term::ReadLine::TermCap::rl_term_set[0]
7726         . $1
7727         . $Term::ReadLine::TermCap::rl_term_set[1]
7728     }gex;
7729
7730     local $\ = '';
7731     print {$OUT} $help_str;
7732
7733     return;
7734 } ## end sub print_help
7735
7736 =head2 C<fix_less>
7737
7738 This routine does a lot of gyrations to be sure that the pager is C<less>.
7739 It checks for C<less> masquerading as C<more> and records the result in
7740 C<$fixed_less> so we don't have to go through doing the stats again.
7741
7742 =cut
7743
7744 use vars qw($fixed_less);
7745
7746 sub _calc_is_less {
7747     if ($pager =~ /\bless\b/)
7748     {
7749         return 1;
7750     }
7751     elsif ($pager =~ /\bmore\b/)
7752     {
7753         # Nope, set to more. See what's out there.
7754         my @st_more = stat('/usr/bin/more');
7755         my @st_less = stat('/usr/bin/less');
7756
7757         # is it really less, pretending to be more?
7758         return (
7759             @st_more
7760             && @st_less
7761             && $st_more[0] == $st_less[0]
7762             && $st_more[1] == $st_less[1]
7763         );
7764     }
7765     else {
7766         return;
7767     }
7768 }
7769
7770 sub fix_less {
7771
7772     # We already know if this is set.
7773     return if $fixed_less;
7774
7775     # changes environment!
7776     # 'r' added so we don't do (slow) stats again.
7777     $fixed_less = 1 if _calc_is_less();
7778
7779     return;
7780 } ## end sub fix_less
7781
7782 =head1 DIE AND WARN MANAGEMENT
7783
7784 =head2 C<diesignal>
7785
7786 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7787 to debug a debugger problem.
7788
7789 It does its best to report the error that occurred, and then forces the
7790 program, debugger, and everything to die.
7791
7792 =cut
7793
7794 sub diesignal {
7795
7796     # No entry/exit messages.
7797     local $frame = 0;
7798
7799     # No return value prints.
7800     local $doret = -2;
7801
7802     # set the abort signal handling to the default (just terminate).
7803     $SIG{'ABRT'} = 'DEFAULT';
7804
7805     # If we enter the signal handler recursively, kill myself with an
7806     # abort signal (so we just terminate).
7807     kill 'ABRT', $$ if $panic++;
7808
7809     # If we can show detailed info, do so.
7810     if ( defined &Carp::longmess ) {
7811
7812         # Don't recursively enter the warn handler, since we're carping.
7813         local $SIG{__WARN__} = '';
7814
7815         # Skip two levels before reporting traceback: we're skipping
7816         # mydie and confess.
7817         local $Carp::CarpLevel = 2;    # mydie + confess
7818
7819         # Tell us all about it.
7820         &warn( Carp::longmess("Signal @_") );
7821     }
7822
7823     # No Carp. Tell us about the signal as best we can.
7824     else {
7825         local $\ = '';
7826         print $DB::OUT "Got signal @_\n";
7827     }
7828
7829     # Drop dead.
7830     kill 'ABRT', $$;
7831 } ## end sub diesignal
7832
7833 =head2 C<dbwarn>
7834
7835 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7836 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7837
7838 =cut
7839
7840 sub dbwarn {
7841
7842     # No entry/exit trace.
7843     local $frame = 0;
7844
7845     # No return value printing.
7846     local $doret = -2;
7847
7848     # Turn off warn and die handling to prevent recursive entries to this
7849     # routine.
7850     local $SIG{__WARN__} = '';
7851     local $SIG{__DIE__}  = '';
7852
7853     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7854     # done yet), we may not be able to do a require.
7855     eval { require Carp }
7856       if defined $^S;    # If error/warning during compilation,
7857                          # require may be broken.
7858
7859     # Use the core warn() unless Carp loaded OK.
7860     CORE::warn( @_,
7861         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7862       return
7863       unless defined &Carp::longmess;
7864
7865     # Save the current values of $single and $trace, and then turn them off.
7866     my ( $mysingle, $mytrace ) = ( $single, $trace );
7867     $single = 0;
7868     $trace  = 0;
7869
7870     # We can call Carp::longmess without its being "debugged" (which we
7871     # don't want - we just want to use it!). Capture this for later.
7872     my $mess = Carp::longmess(@_);
7873
7874     # Restore $single and $trace to their original values.
7875     ( $single, $trace ) = ( $mysingle, $mytrace );
7876
7877     # Use the debugger's own special way of printing warnings to print
7878     # the stack trace message.
7879     &warn($mess);
7880 } ## end sub dbwarn
7881
7882 =head2 C<dbdie>
7883
7884 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7885 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7886 single stepping and tracing during the call to C<Carp::longmess> to avoid
7887 debugging it - we just want to use it.
7888
7889 If C<dieLevel> is zero, we let the program being debugged handle the
7890 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7891 the debugger takes over all exception handling, printing a backtrace and
7892 displaying the exception via its C<dbwarn()> routine.
7893
7894 =cut
7895
7896 sub dbdie {
7897     local $frame         = 0;
7898     local $doret         = -2;
7899     local $SIG{__DIE__}  = '';
7900     local $SIG{__WARN__} = '';
7901     my $i      = 0;
7902     my $ineval = 0;
7903     my $sub;
7904     if ( $dieLevel > 2 ) {
7905         local $SIG{__WARN__} = \&dbwarn;
7906         &warn(@_);    # Yell no matter what
7907         return;
7908     }
7909     if ( $dieLevel < 2 ) {
7910         die @_ if $^S;    # in eval propagate
7911     }
7912
7913     # The code used to check $^S to see if compilation of the current thing
7914     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7915     eval { require Carp };
7916
7917     die( @_,
7918         "\nCannot print stack trace, load with -MCarp option to see stack" )
7919       unless defined &Carp::longmess;
7920
7921     # We do not want to debug this chunk (automatic disabling works
7922     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7923     # get the stack trace from Carp::longmess (if possible), restore $signal
7924     # and $trace, and then die with the stack trace.
7925     my ( $mysingle, $mytrace ) = ( $single, $trace );
7926     $single = 0;
7927     $trace  = 0;
7928     my $mess = "@_";
7929     {
7930
7931         package Carp;    # Do not include us in the list
7932         eval { $mess = Carp::longmess(@_); };
7933     }
7934     ( $single, $trace ) = ( $mysingle, $mytrace );
7935     die $mess;
7936 } ## end sub dbdie
7937
7938 =head2 C<warnlevel()>
7939
7940 Set the C<$DB::warnLevel> variable that stores the value of the
7941 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7942 results in the debugger taking over all warning handlers. Setting
7943 C<warnLevel> to zero leaves any warning handlers set up by the program
7944 being debugged in place.
7945
7946 =cut
7947
7948 sub warnLevel {
7949     if (@_) {
7950         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
7951         $warnLevel = shift;
7952         if ($warnLevel) {
7953             $SIG{__WARN__} = \&DB::dbwarn;
7954         }
7955         elsif ($prevwarn) {
7956             $SIG{__WARN__} = $prevwarn;
7957         } else {
7958             undef $SIG{__WARN__};
7959         }
7960     } ## end if (@_)
7961     $warnLevel;
7962 } ## end sub warnLevel
7963
7964 =head2 C<dielevel>
7965
7966 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7967 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7968 zero lets you use your own C<die()> handler.
7969
7970 =cut
7971
7972 sub dieLevel {
7973     local $\ = '';
7974     if (@_) {
7975         my $prevdie = $SIG{__DIE__} unless $dieLevel;
7976         $dieLevel = shift;
7977         if ($dieLevel) {
7978
7979             # Always set it to dbdie() for non-zero values.
7980             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7981
7982             # No longer exists, so don't try  to use it.
7983             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7984
7985             # If we've finished initialization, mention that stack dumps
7986             # are enabled, If dieLevel is 1, we won't stack dump if we die
7987             # in an eval().
7988             print $OUT "Stack dump during die enabled",
7989               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7990               if $I_m_init;
7991
7992             # XXX This is probably obsolete, given that diehard() is gone.
7993             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7994         } ## end if ($dieLevel)
7995
7996         # Put the old one back if there was one.
7997         elsif ($prevdie) {
7998             $SIG{__DIE__} = $prevdie;
7999             print $OUT "Default die handler restored.\n";
8000         } else {
8001             undef $SIG{__DIE__};
8002             print $OUT "Die handler removed.\n";
8003         }
8004     } ## end if (@_)
8005     $dieLevel;
8006 } ## end sub dieLevel
8007
8008 =head2 C<signalLevel>
8009
8010 Number three in a series: set C<signalLevel> to zero to keep your own
8011 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8012 takes over and handles them with C<DB::diesignal()>.
8013
8014 =cut
8015
8016 sub signalLevel {
8017     if (@_) {
8018         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8019         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8020         $signalLevel = shift;
8021         if ($signalLevel) {
8022             $SIG{SEGV} = \&DB::diesignal;
8023             $SIG{BUS}  = \&DB::diesignal;
8024         }
8025         else {
8026             $SIG{SEGV} = $prevsegv;
8027             $SIG{BUS}  = $prevbus;
8028         }
8029     } ## end if (@_)
8030     $signalLevel;
8031 } ## end sub signalLevel
8032
8033 =head1 SUBROUTINE DECODING SUPPORT
8034
8035 These subroutines are used during the C<x> and C<X> commands to try to
8036 produce as much information as possible about a code reference. They use
8037 L<Devel::Peek> to try to find the glob in which this code reference lives
8038 (if it does) - this allows us to actually code references which correspond
8039 to named subroutines (including those aliased via glob assignment).
8040
8041 =head2 C<CvGV_name()>
8042
8043 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8044 via that routine. If this fails, return the reference again (when the
8045 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8046
8047 =cut
8048
8049 sub CvGV_name {
8050     my $in   = shift;
8051     my $name = CvGV_name_or_bust($in);
8052     defined $name ? $name : $in;
8053 }
8054
8055 =head2 C<CvGV_name_or_bust> I<coderef>
8056
8057 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8058 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8059 find a glob for this ref.
8060
8061 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8062
8063 =cut
8064
8065 use vars qw($skipCvGV);
8066
8067 sub CvGV_name_or_bust {
8068     my $in = shift;
8069     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8070     return unless ref $in;
8071     $in = \&$in;            # Hard reference...
8072     eval { require Devel::Peek; 1 } or return;
8073     my $gv = Devel::Peek::CvGV($in) or return;
8074     *$gv{PACKAGE} . '::' . *$gv{NAME};
8075 } ## end sub CvGV_name_or_bust
8076
8077 =head2 C<find_sub>
8078
8079 A utility routine used in various places; finds the file where a subroutine
8080 was defined, and returns that filename and a line-number range.
8081
8082 Tries to use C<@sub> first; if it can't find it there, it tries building a
8083 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8084 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8085 this way, it brute-force searches C<%sub>, checking for identical references.
8086
8087 =cut
8088
8089 sub _find_sub_helper {
8090     my $subr = shift;
8091
8092     return unless defined &$subr;
8093     my $name = CvGV_name_or_bust($subr);
8094     my $data;
8095     $data = $sub{$name} if defined $name;
8096     return $data if defined $data;
8097
8098     # Old stupid way...
8099     $subr = \&$subr;    # Hard reference
8100     my $s;
8101     for ( keys %sub ) {
8102         $s = $_, last if $subr eq \&$_;
8103     }
8104     if ($s)
8105     {
8106         return $sub{$s};
8107     }
8108     else
8109     {
8110         return;
8111     }
8112
8113 }
8114
8115 sub find_sub {
8116     my $subr = shift;
8117     return ( $sub{$subr} || _find_sub_helper($subr) );
8118 } ## end sub find_sub
8119
8120 =head2 C<methods>
8121
8122 A subroutine that uses the utility function C<methods_via> to find all the
8123 methods in the class corresponding to the current reference and in
8124 C<UNIVERSAL>.
8125
8126 =cut
8127
8128 use vars qw(%seen);
8129
8130 sub methods {
8131
8132     # Figure out the class - either this is the class or it's a reference
8133     # to something blessed into that class.
8134     my $class = shift;
8135     $class = ref $class if ref $class;
8136
8137     local %seen;
8138
8139     # Show the methods that this class has.
8140     methods_via( $class, '', 1 );
8141
8142     # Show the methods that UNIVERSAL has.
8143     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8144 } ## end sub methods
8145
8146 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8147
8148 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8149 all the parent class methods. C<$class> is the name of the next class to
8150 try; C<$prefix> is the message prefix, which gets built up as we go up the
8151 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8152 higher in the C<@ISA> tree, 0 if we should stop.
8153
8154 =cut
8155
8156 sub methods_via {
8157
8158     # If we've processed this class already, just quit.
8159     my $class = shift;
8160     return if $seen{$class}++;
8161
8162     # This is a package that is contributing the methods we're about to print.
8163     my $prefix  = shift;
8164     my $prepend = $prefix ? "via $prefix: " : '';
8165     my @to_print;
8166
8167     # Extract from all the symbols in this class.
8168     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8169     while (my ($name, $glob) = each %$class_ref) {
8170         # references directly in the symbol table are Proxy Constant
8171         # Subroutines, and are by their very nature defined
8172         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8173         # to a subroutine reference, which can be tested by defined.
8174         # $glob might also be the value -1  (from sub foo;)
8175         # or (say) '$$' (from sub foo ($$);)
8176         # \$glob will be SCALAR in both cases.
8177         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8178             && !$seen{$name}++) {
8179             push @to_print, "$prepend$name\n";
8180         }
8181     }
8182
8183     {
8184         local $\ = '';
8185         local $, = '';
8186         print $DB::OUT $_ foreach sort @to_print;
8187     }
8188
8189     # If the $crawl_upward argument is false, just quit here.
8190     return unless shift;
8191
8192     # $crawl_upward true: keep going up the tree.
8193     # Find all the classes this one is a subclass of.
8194     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8195     for my $name ( @$class_ISA_ref ) {
8196
8197         # Set up the new prefix.
8198         $prepend = $prefix ? $prefix . " -> $name" : $name;
8199
8200         # Crawl up the tree and keep trying to crawl up.
8201         methods_via( $name, $prepend, 1 );
8202     }
8203 } ## end sub methods_via
8204
8205 =head2 C<setman> - figure out which command to use to show documentation
8206
8207 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8208
8209 =cut
8210
8211 sub setman {
8212     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8213       ? "man"         # O Happy Day!
8214       : "perldoc";    # Alas, poor unfortunates
8215 } ## end sub setman
8216
8217 =head2 C<runman> - run the appropriate command to show documentation
8218
8219 Accepts a man page name; runs the appropriate command to display it (set up
8220 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8221 program's STDIN and STDOUT.
8222
8223 =cut
8224
8225 my %_is_in_pods = (map { $_ => 1 }
8226     qw(
8227     5004delta
8228     5005delta
8229     561delta
8230     56delta
8231     570delta
8232     571delta
8233     572delta
8234     573delta
8235     58delta
8236     581delta
8237     582delta
8238     583delta
8239     584delta
8240     590delta
8241     591delta
8242     592delta
8243     aix
8244     amiga
8245     apio
8246     api
8247     artistic
8248     beos
8249     book
8250     boot
8251     bot
8252     bs2000
8253     call
8254     ce
8255     cheat
8256     clib
8257     cn
8258     compile
8259     cygwin
8260     data
8261     dbmfilter
8262     debguts
8263     debtut
8264     debug
8265     delta
8266     dgux
8267     diag
8268     doc
8269     dos
8270     dsc
8271     ebcdic
8272     embed
8273     epoc
8274     faq1
8275     faq2
8276     faq3
8277     faq4
8278     faq5
8279     faq6
8280     faq7
8281     faq8
8282     faq9
8283     faq
8284     filter
8285     fork
8286     form
8287     freebsd
8288     func
8289     gpl
8290     guts
8291     hack
8292     hist
8293     hpux
8294     hurd
8295     intern
8296     intro
8297     iol
8298     ipc
8299     irix
8300     jp
8301     ko
8302     lexwarn
8303     locale
8304     lol
8305     macos
8306     macosx
8307     modinstall
8308     modlib
8309     mod
8310     modstyle
8311     netware
8312     newmod
8313     number
8314     obj
8315     opentut
8316     op
8317     os2
8318     os390
8319     os400
8320     packtut
8321     plan9
8322     pod
8323     podspec
8324     port
8325     qnx
8326     ref
8327     reftut
8328     re
8329     requick
8330     reref
8331     retut
8332     run
8333     sec
8334     solaris
8335     style
8336     sub
8337     syn
8338     thrtut
8339     tie
8340     toc
8341     todo
8342     tooc
8343     toot
8344     trap
8345     tru64
8346     tw
8347     unicode
8348     uniintro
8349     util
8350     uts
8351     var
8352     vms
8353     vos
8354     win32
8355     xs
8356     xstut
8357     )
8358 );
8359
8360 sub runman {
8361     my $page = shift;
8362     unless ($page) {
8363         &system("$doccmd $doccmd");
8364         return;
8365     }
8366
8367     # this way user can override, like with $doccmd="man -Mwhatever"
8368     # or even just "man " to disable the path check.
8369     unless ( $doccmd eq 'man' ) {
8370         &system("$doccmd $page");
8371         return;
8372     }
8373
8374     $page = 'perl' if lc($page) eq 'help';
8375
8376     require Config;
8377     my $man1dir = $Config::Config{'man1dir'};
8378     my $man3dir = $Config::Config{'man3dir'};
8379     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8380     my $manpath = '';
8381     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8382     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8383     chop $manpath if $manpath;
8384
8385     # harmless if missing, I figure
8386     my $oldpath = $ENV{MANPATH};
8387     $ENV{MANPATH} = $manpath if $manpath;
8388     my $nopathopt = $^O =~ /dunno what goes here/;
8389     if (
8390         CORE::system(
8391             $doccmd,
8392
8393             # I just *know* there are men without -M
8394             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8395             split ' ', $page
8396         )
8397       )
8398     {
8399         unless ( $page =~ /^perl\w/ ) {
8400 # do it this way because its easier to slurp in to keep up to date - clunky though.
8401             if (exists($_is_in_pods{$page})) {
8402                 CORE::system( $doccmd,
8403                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8404                     "perl$page" );
8405             }
8406         }
8407     } ## end if (CORE::system($doccmd...
8408     if ( defined $oldpath ) {
8409         $ENV{MANPATH} = $manpath;
8410     }
8411     else {
8412         delete $ENV{MANPATH};
8413     }
8414 } ## end sub runman
8415
8416 #use Carp;                          # This did break, left for debugging
8417
8418 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8419
8420 Because of the way the debugger interface to the Perl core is designed, any
8421 debugger package globals that C<DB::sub()> requires have to be defined before
8422 any subroutines can be called. These are defined in the second C<BEGIN> block.
8423
8424 This block sets things up so that (basically) the world is sane
8425 before the debugger starts executing. We set up various variables that the
8426 debugger has to have set up before the Perl core starts running:
8427
8428 =over 4
8429
8430 =item *
8431
8432 The debugger's own filehandles (copies of STD and STDOUT for now).
8433
8434 =item *
8435
8436 Characters for shell escapes, the recall command, and the history command.
8437
8438 =item *
8439
8440 The maximum recursion depth.
8441
8442 =item *
8443
8444 The size of a C<w> command's window.
8445
8446 =item *
8447
8448 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8449
8450 =item *
8451
8452 The fact that we're not in a sub at all right now.
8453
8454 =item *
8455
8456 The default SIGINT handler for the debugger.
8457
8458 =item *
8459
8460 The appropriate value of the flag in C<$^D> that says the debugger is running
8461
8462 =item *
8463
8464 The current debugger recursion level
8465
8466 =item *
8467
8468 The list of postponed items and the C<$single> stack (XXX define this)
8469
8470 =item *
8471
8472 That we want no return values and no subroutine entry/exit trace.
8473
8474 =back
8475
8476 =cut
8477
8478 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8479
8480 use vars qw($db_stop);
8481
8482 BEGIN {    # This does not compile, alas. (XXX eh?)
8483     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8484     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8485
8486     # Define characters used by command parsing.
8487     $sh       = '!';      # Shell escape (does not work)
8488     $rc       = ',';      # Recall command (does not work)
8489     @hist     = ('?');    # Show history (does not work)
8490     @truehist = ();       # Can be saved for replay (per session)
8491
8492     # This defines the point at which you get the 'deep recursion'
8493     # warning. It MUST be defined or the debugger will not load.
8494     $deep = 100;
8495
8496     # Number of lines around the current one that are shown in the
8497     # 'w' command.
8498     $window = 10;
8499
8500     # How much before-the-current-line context the 'v' command should
8501     # use in calculating the start of the window it will display.
8502     $preview = 3;
8503
8504     # We're not in any sub yet, but we need this to be a defined value.
8505     $sub = '';
8506
8507     # Set up the debugger's interrupt handler. It simply sets a flag
8508     # ($signal) that DB::DB() will check before each command is executed.
8509     $SIG{INT} = \&DB::catch;
8510
8511     # The following lines supposedly, if uncommented, allow the debugger to
8512     # debug itself. Perhaps we can try that someday.
8513     # This may be enabled to debug debugger:
8514     #$warnLevel = 1 unless defined $warnLevel;
8515     #$dieLevel = 1 unless defined $dieLevel;
8516     #$signalLevel = 1 unless defined $signalLevel;
8517
8518     # This is the flag that says "a debugger is running, please call
8519     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8520     # execute anything in the user's context, because we always want to
8521     # get control back.
8522     $db_stop = 0;          # Compiler warning ...
8523     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8524
8525     # This variable records how many levels we're nested in debugging. Used
8526     # Used in the debugger prompt, and in determining whether it's all over or
8527     # not.
8528     $level = 0;            # Level of recursive debugging
8529
8530     # "Triggers bug (?) in perl if we postpone this until runtime."
8531     # XXX No details on this yet, or whether we should fix the bug instead
8532     # of work around it. Stay tuned.
8533     @stack = (0);
8534
8535     # Used to track the current stack depth using the auto-stacked-variable
8536     # trick.
8537     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8538
8539     # Don't print return values on exiting a subroutine.
8540     $doret = -2;
8541
8542     # No extry/exit tracing.
8543     $frame = 0;
8544
8545 } ## end BEGIN
8546
8547 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8548
8549 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8550
8551 =head2 db_complete
8552
8553 C<readline> support - adds command completion to basic C<readline>.
8554
8555 Returns a list of possible completions to C<readline> when invoked. C<readline>
8556 will print the longest common substring following the text already entered.
8557
8558 If there is only a single possible completion, C<readline> will use it in full.
8559
8560 This code uses C<map> and C<grep> heavily to create lists of possible
8561 completion. Think LISP in this section.
8562
8563 =cut
8564
8565 sub db_complete {
8566
8567     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8568     # $text is the text to be completed.
8569     # $line is the incoming line typed by the user.
8570     # $start is the start of the text to be completed in the incoming line.
8571     my ( $text, $line, $start ) = @_;
8572
8573     # Save the initial text.
8574     # The search pattern is current package, ::, extract the next qualifier
8575     # Prefix and pack are set to undef.
8576     my ( $itext, $search, $prefix, $pack ) =
8577       ( $text, "^\Q${package}::\E([^:]+)\$" );
8578
8579 =head3 C<b postpone|compile>
8580
8581 =over 4
8582
8583 =item *
8584
8585 Find all the subroutines that might match in this package
8586
8587 =item *
8588
8589 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8590
8591 =item *
8592
8593 Include all the rest of the subs that are known
8594
8595 =item *
8596
8597 C<grep> out the ones that match the text we have so far
8598
8599 =item *
8600
8601 Return this as the list of possible completions
8602
8603 =back
8604
8605 =cut
8606
8607     return sort grep /^\Q$text/, ( keys %sub ),
8608       qw(postpone load compile),    # subroutines
8609       ( map { /$search/ ? ($1) : () } keys %sub )
8610       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8611
8612 =head3 C<b load>
8613
8614 Get all the possible files from C<@INC> as it currently stands and
8615 select the ones that match the text so far.
8616
8617 =cut
8618
8619     return sort grep /^\Q$text/, values %INC    # files
8620       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8621
8622 =head3  C<V> (list variable) and C<m> (list modules)
8623
8624 There are two entry points for these commands:
8625
8626 =head4 Unqualified package names
8627
8628 Get the top-level packages and grab everything that matches the text
8629 so far. For each match, recursively complete the partial packages to
8630 get all possible matching packages. Return this sorted list.
8631
8632 =cut
8633
8634     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8635       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8636       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8637
8638 =head4 Qualified package names
8639
8640 Take a partially-qualified package and find all subpackages for it
8641 by getting all the subpackages for the package so far, matching all
8642 the subpackages against the text, and discarding all of them which
8643 start with 'main::'. Return this list.
8644
8645 =cut
8646
8647     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8648       grep !/^main::/, grep /^\Q$text/,
8649       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
8650       do { no strict 'refs'; keys %{ $prefix . '::' } }
8651       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8652       and $text =~ /^(.*[^:])::?(\w*)$/
8653       and $prefix = $1;
8654
8655 =head3 C<f> - switch files
8656
8657 Here, we want to get a fully-qualified filename for the C<f> command.
8658 Possibilities are:
8659
8660 =over 4
8661
8662 =item 1. The original source file itself
8663
8664 =item 2. A file from C<@INC>
8665
8666 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8667
8668 =back
8669
8670 =cut
8671
8672     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8673            # We might possibly want to switch to an eval (which has a "filename"
8674            # like '(eval 9)'), so we may need to clean up the completion text
8675            # before proceeding.
8676         $prefix = length($1) - length($text);
8677         $text   = $1;
8678
8679 =pod
8680
8681 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8682 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8683 out of C<%main::>, add the initial source file, and extract the ones that
8684 match the completion text so far.
8685
8686 =cut
8687
8688         return sort
8689           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8690           $0;
8691     } ## end if ($line =~ /^\|*f\s+(.*)/)
8692
8693 =head3 Subroutine name completion
8694
8695 We look through all of the defined subs (the keys of C<%sub>) and
8696 return both all the possible matches to the subroutine name plus
8697 all the matches qualified to the current package.
8698
8699 =cut
8700
8701     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8702         $text = substr $text, 1;
8703         $prefix = "&";
8704         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8705           (
8706             map { /$search/ ? ($1) : () }
8707               keys %sub
8708           );
8709     } ## end if ((substr $text, 0, ...
8710
8711 =head3  Scalar, array, and hash completion: partially qualified package
8712
8713 Much like the above, except we have to do a little more cleanup:
8714
8715 =cut
8716
8717     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8718
8719 =pod
8720
8721 =over 4
8722
8723 =item *
8724
8725 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8726
8727 =cut
8728
8729         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8730
8731 =pod
8732
8733 =item *
8734
8735 Figure out the prefix vs. what needs completing.
8736
8737 =cut
8738
8739         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8740         $text   = $2;
8741
8742 =pod
8743
8744 =item *
8745
8746 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8747
8748 =cut
8749
8750         my @out = do {
8751             no strict 'refs';
8752             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8753             keys %$pack;
8754         };
8755
8756 =pod
8757
8758 =item *
8759
8760 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8761
8762 =cut
8763
8764         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8765             return db_complete( $out[0], $line, $start );
8766         }
8767
8768         # Return the list of possibles.
8769         return sort @out;
8770
8771     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8772
8773 =pod
8774
8775 =back
8776
8777 =head3 Symbol completion: current package or package C<main>.
8778
8779 =cut
8780
8781     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8782 =pod
8783
8784 =over 4
8785
8786 =item *
8787
8788 If it's C<main>, delete main to just get C<::> leading.
8789
8790 =cut
8791
8792         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8793
8794 =pod
8795
8796 =item *
8797
8798 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8799
8800 =cut
8801
8802         $prefix = substr $text, 0, 1;
8803         $text   = substr $text, 1;
8804
8805         my @out;
8806
8807 =pod
8808
8809 =item *
8810
8811 We look for the lexical scope above DB::DB and auto-complete lexical variables
8812 if PadWalker could be loaded.
8813
8814 =cut
8815
8816         if (not $text =~ /::/ and eval { require PadWalker } ) {
8817             my $level = 1;
8818             while (1) {
8819                 my @info = caller($level);
8820                 $level++;
8821                 $level = -1, last
8822                   if not @info;
8823                 last if $info[3] eq 'DB::DB';
8824             }
8825             if ($level > 0) {
8826                 my $lexicals = PadWalker::peek_my($level);
8827                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
8828             }
8829         }
8830
8831 =pod
8832
8833 =item *
8834
8835 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8836
8837 =cut
8838
8839         push @out, map "$prefix$_", grep /^\Q$text/,
8840           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8841           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8842
8843 =item *
8844
8845 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8846
8847 =back
8848
8849 =cut
8850
8851         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8852             return db_complete( $out[0], $line, $start );
8853         }
8854
8855         # Return the list of possibles.
8856         return sort @out;
8857     } ## end if ($text =~ /^[\$@%]/)
8858
8859 =head3 Options
8860
8861 We use C<option_val()> to look up the current value of the option. If there's
8862 only a single value, we complete the command in such a way that it is a
8863 complete command for setting the option in question. If there are multiple
8864 possible values, we generate a command consisting of the option plus a trailing
8865 question mark, which, if executed, will list the current value of the option.
8866
8867 =cut
8868
8869     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8870     {    # Options after space
8871            # We look for the text to be matched in the list of possible options,
8872            # and fetch the current value.
8873         my @out = grep /^\Q$text/, @options;
8874         my $val = option_val( $out[0], undef );
8875
8876         # Set up a 'query option's value' command.
8877         my $out = '? ';
8878         if ( not defined $val or $val =~ /[\n\r]/ ) {
8879
8880             # There's really nothing else we can do.
8881         }
8882
8883         # We have a value. Create a proper option-setting command.
8884         elsif ( $val =~ /\s/ ) {
8885
8886             # XXX This may be an extraneous variable.
8887             my $found;
8888
8889             # We'll want to quote the string (because of the embedded
8890             # whtespace), but we want to make sure we don't end up with
8891             # mismatched quote characters. We try several possibilities.
8892             foreach my $l ( split //, qq/\"\'\#\|/ ) {
8893
8894                 # If we didn't find this quote character in the value,
8895                 # quote it using this quote character.
8896                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8897             }
8898         } ## end elsif ($val =~ /\s/)
8899
8900         # Don't need any quotes.
8901         else {
8902             $out = "=$val ";
8903         }
8904
8905         # If there were multiple possible values, return '? ', which
8906         # makes the command into a query command. If there was just one,
8907         # have readline append that.
8908         $rl_attribs->{completer_terminator_character} =
8909           ( @out == 1 ? $out : '? ' );
8910
8911         # Return list of possibilities.
8912         return sort @out;
8913     } ## end if ((substr $line, 0, ...
8914
8915 =head3 Filename completion
8916
8917 For entering filenames. We simply call C<readline>'s C<filename_list()>
8918 method with the completion text to get the possible completions.
8919
8920 =cut
8921
8922     return $term->filename_list($text);    # filenames
8923
8924 } ## end sub db_complete
8925
8926 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8927
8928 Functions that possibly ought to be somewhere else.
8929
8930 =head2 end_report
8931
8932 Say we're done.
8933
8934 =cut
8935
8936 sub end_report {
8937     local $\ = '';
8938     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
8939 }
8940
8941 =head2 clean_ENV
8942
8943 If we have $ini_pids, save it in the environment; else remove it from the
8944 environment. Used by the C<R> (restart) command.
8945
8946 =cut
8947
8948 sub clean_ENV {
8949     if ( defined($ini_pids) ) {
8950         $ENV{PERLDB_PIDS} = $ini_pids;
8951     }
8952     else {
8953         delete( $ENV{PERLDB_PIDS} );
8954     }
8955 } ## end sub clean_ENV
8956
8957 # PERLDBf_... flag names from perl.h
8958 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8959
8960 BEGIN {
8961     %DollarCaretP_flags = (
8962         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8963         PERLDBf_LINE      => 0x02,     # Keep line #
8964         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8965         PERLDBf_INTER     => 0x08,     # Preserve more data
8966         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8967         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8968         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8969         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8970         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8971         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8972         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8973         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8974     );
8975     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8976     # doesn't need to set it. It's provided for the benefit of profilers and
8977     # other code analysers.
8978
8979     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8980 }
8981
8982 sub parse_DollarCaretP_flags {
8983     my $flags = shift;
8984     $flags =~ s/^\s+//;
8985     $flags =~ s/\s+$//;
8986     my $acu = 0;
8987     foreach my $f ( split /\s*\|\s*/, $flags ) {
8988         my $value;
8989         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8990             $value = hex $1;
8991         }
8992         elsif ( $f =~ /^(\d+)$/ ) {
8993             $value = int $1;
8994         }
8995         elsif ( $f =~ /^DEFAULT$/i ) {
8996             $value = $DollarCaretP_flags{PERLDB_ALL};
8997         }
8998         else {
8999             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9000             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9001             unless ( defined $value ) {
9002                 print $OUT (
9003                     "Unrecognized \$^P flag '$f'!\n",
9004                     "Acceptable flags are: "
9005                       . join( ', ', sort keys %DollarCaretP_flags ),
9006                     ", and hexadecimal and decimal numbers.\n"
9007                 );
9008                 return undef;
9009             }
9010         }
9011         $acu |= $value;
9012     }
9013     $acu;
9014 }
9015
9016 sub expand_DollarCaretP_flags {
9017     my $DollarCaretP = shift;
9018     my @bits         = (
9019         map {
9020             my $n = ( 1 << $_ );
9021             ( $DollarCaretP & $n )
9022               ? ( $DollarCaretP_flags_r{$n}
9023                   || sprintf( '0x%x', $n ) )
9024               : ()
9025           } 0 .. 31
9026     );
9027     return @bits ? join( '|', @bits ) : 0;
9028 }
9029
9030 =over 4
9031
9032 =item rerun
9033
9034 Rerun the current session to:
9035
9036     rerun        current position
9037
9038     rerun 4      command number 4
9039
9040     rerun -4     current command minus 4 (go back 4 steps)
9041
9042 Whether this always makes sense, in the current context is unknowable, and is
9043 in part left as a useful exercise for the reader.  This sub returns the
9044 appropriate arguments to rerun the current session.
9045
9046 =cut
9047
9048 sub rerun {
9049     my $i = shift;
9050     my @args;
9051     pop(@truehist);                      # strim
9052     unless (defined $truehist[$i]) {
9053         print "Unable to return to non-existent command: $i\n";
9054     } else {
9055         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9056         my @temp = @truehist;            # store
9057         push(@DB::typeahead, @truehist); # saved
9058         @truehist = @hist = ();          # flush
9059         @args = &restart();              # setup
9060         &get_list("PERLDB_HIST");        # clean
9061         &set_list("PERLDB_HIST", @temp); # reset
9062     }
9063     return @args;
9064 }
9065
9066 =item restart
9067
9068 Restarting the debugger is a complex operation that occurs in several phases.
9069 First, we try to reconstruct the command line that was used to invoke Perl
9070 and the debugger.
9071
9072 =cut
9073
9074 sub restart {
9075     # I may not be able to resurrect you, but here goes ...
9076     print $OUT
9077 "Warning: some settings and command-line options may be lost!\n";
9078     my ( @script, @flags, $cl );
9079
9080     # If warn was on before, turn it on again.
9081     push @flags, '-w' if $ini_warn;
9082
9083     # Rebuild the -I flags that were on the initial
9084     # command line.
9085     for (@ini_INC) {
9086         push @flags, '-I', $_;
9087     }
9088
9089     # Turn on taint if it was on before.
9090     push @flags, '-T' if ${^TAINT};
9091
9092     # Arrange for setting the old INC:
9093     # Save the current @init_INC in the environment.
9094     set_list( "PERLDB_INC", @ini_INC );
9095
9096     # If this was a perl one-liner, go to the "file"
9097     # corresponding to the one-liner read all the lines
9098     # out of it (except for the first one, which is going
9099     # to be added back on again when 'perl -d' runs: that's
9100     # the 'require perl5db.pl;' line), and add them back on
9101     # to the command line to be executed.
9102     if ( $0 eq '-e' ) {
9103         my $lines = *{$main::{'_<-e'}}{ARRAY};
9104         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9105             chomp( $cl = $lines->[$_] );
9106             push @script, '-e', $cl;
9107         }
9108     } ## end if ($0 eq '-e')
9109
9110     # Otherwise we just reuse the original name we had
9111     # before.
9112     else {
9113         @script = $0;
9114     }
9115
9116 =pod
9117
9118 After the command line  has been reconstructed, the next step is to save
9119 the debugger's status in environment variables. The C<DB::set_list> routine
9120 is used to save aggregate variables (both hashes and arrays); scalars are
9121 just popped into environment variables directly.
9122
9123 =cut
9124
9125     # If the terminal supported history, grab it and
9126     # save that in the environment.
9127     set_list( "PERLDB_HIST",
9128           $term->Features->{getHistory}
9129         ? $term->GetHistory
9130         : @hist );
9131
9132     # Find all the files that were visited during this
9133     # session (i.e., the debugger had magic hashes
9134     # corresponding to them) and stick them in the environment.
9135     my @had_breakpoints = keys %had_breakpoints;
9136     set_list( "PERLDB_VISITED", @had_breakpoints );
9137
9138     # Save the debugger options we chose.
9139     set_list( "PERLDB_OPT", %option );
9140     # set_list( "PERLDB_OPT", options2remember() );
9141
9142     # Save the break-on-loads.
9143     set_list( "PERLDB_ON_LOAD", %break_on_load );
9144
9145 =pod
9146
9147 The most complex part of this is the saving of all of the breakpoints. They
9148 can live in an awful lot of places, and we have to go through all of them,
9149 find the breakpoints, and then save them in the appropriate environment
9150 variable via C<DB::set_list>.
9151
9152 =cut
9153
9154     # Go through all the breakpoints and make sure they're
9155     # still valid.
9156     my @hard;
9157     for ( 0 .. $#had_breakpoints ) {
9158
9159         # We were in this file.
9160         my $file = $had_breakpoints[$_];
9161
9162         # Grab that file's magic line hash.
9163         *dbline = $main::{ '_<' . $file };
9164
9165         # Skip out if it doesn't exist, or if the breakpoint
9166         # is in a postponed file (we'll do postponed ones
9167         # later).
9168         next unless %dbline or $postponed_file{$file};
9169
9170         # In an eval. This is a little harder, so we'll
9171         # do more processing on that below.
9172         ( push @hard, $file ), next
9173           if $file =~ /^\(\w*eval/;
9174
9175         # XXX I have no idea what this is doing. Yet.
9176         my @add;
9177         @add = %{ $postponed_file{$file} }
9178           if $postponed_file{$file};
9179
9180         # Save the list of all the breakpoints for this file.
9181         set_list( "PERLDB_FILE_$_", %dbline, @add );
9182
9183         # Serialize the extra data %breakpoints_data hash.
9184         # That's a bug fix.
9185         set_list( "PERLDB_FILE_ENABLED_$_",
9186             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9187             sort { $a <=> $b } keys(%dbline)
9188         )
9189     } ## end for (0 .. $#had_breakpoints)
9190
9191     # The breakpoint was inside an eval. This is a little
9192     # more difficult. XXX and I don't understand it.
9193     for (@hard) {
9194         # Get over to the eval in question.
9195         *dbline = $main::{ '_<' . $_ };
9196         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9197         for $sub ( keys %sub ) {
9198             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9199             $subs{$sub} = [ $1, $2 ];
9200         }
9201         unless (%subs) {
9202             print $OUT
9203               "No subroutines in $_, ignoring breakpoints.\n";
9204             next;
9205         }
9206       LINES: for $line ( keys %dbline ) {
9207
9208             # One breakpoint per sub only:
9209             my ( $offset, $sub, $found );
9210           SUBS: for $sub ( keys %subs ) {
9211                 if (
9212                     $subs{$sub}->[1] >=
9213                     $line    # Not after the subroutine
9214                     and (
9215                         not defined $offset    # Not caught
9216                         or $offset < 0
9217                     )
9218                   )
9219                 {                              # or badly caught
9220                     $found  = $sub;
9221                     $offset = $line - $subs{$sub}->[0];
9222                     $offset = "+$offset", last SUBS
9223                       if $offset >= 0;
9224                 } ## end if ($subs{$sub}->[1] >=...
9225             } ## end for $sub (keys %subs)
9226             if ( defined $offset ) {
9227                 $postponed{$found} =
9228                   "break $offset if $dbline{$line}";
9229             }
9230             else {
9231                 print $OUT
9232 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9233             }
9234         } ## end for $line (keys %dbline)
9235     } ## end for (@hard)
9236
9237     # Save the other things that don't need to be
9238     # processed.
9239     set_list( "PERLDB_POSTPONE",  %postponed );
9240     set_list( "PERLDB_PRETYPE",   @$pretype );
9241     set_list( "PERLDB_PRE",       @$pre );
9242     set_list( "PERLDB_POST",      @$post );
9243     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9244
9245     # We are officially restarting.
9246     $ENV{PERLDB_RESTART} = 1;
9247
9248     # We are junking all child debuggers.
9249     delete $ENV{PERLDB_PIDS};    # Restore ini state
9250
9251     # Set this back to the initial pid.
9252     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9253
9254 =pod
9255
9256 After all the debugger status has been saved, we take the command we built up
9257 and then return it, so we can C<exec()> it. The debugger will spot the
9258 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9259 from the environment.
9260
9261 =cut
9262
9263     # And run Perl again. Add the "-d" flag, all the
9264     # flags we built up, the script (whether a one-liner
9265     # or a file), add on the -emacs flag for a slave editor,
9266     # and then the old arguments.
9267
9268     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9269
9270 };  # end restart
9271
9272 =back
9273
9274 =head1 END PROCESSING - THE C<END> BLOCK
9275
9276 Come here at the very end of processing. We want to go into a
9277 loop where we allow the user to enter commands and interact with the
9278 debugger, but we don't want anything else to execute.
9279
9280 First we set the C<$finished> variable, so that some commands that
9281 shouldn't be run after the end of program quit working.
9282
9283 We then figure out whether we're truly done (as in the user entered a C<q>
9284 command, or we finished execution while running nonstop). If we aren't,
9285 we set C<$single> to 1 (causing the debugger to get control again).
9286
9287 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9288 message and returns control to the debugger. Repeat.
9289
9290 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9291 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9292 break, run to completion.).
9293
9294 =cut
9295
9296 END {
9297     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9298     $fall_off_end = 1 unless $inhibit_exit;
9299
9300     # Do not stop in at_exit() and destructors on exit:
9301     if ($fall_off_end or $runnonstop) {
9302         &save_hist();
9303     } else {
9304         $DB::single = 1;
9305         DB::fake::at_exit();
9306     }
9307 } ## end END
9308
9309 =head1 PRE-5.8 COMMANDS
9310
9311 Some of the commands changed function quite a bit in the 5.8 command
9312 realignment, so much so that the old code had to be replaced completely.
9313 Because we wanted to retain the option of being able to go back to the
9314 former command set, we moved the old code off to this section.
9315
9316 There's an awful lot of duplicated code here. We've duplicated the
9317 comments to keep things clear.
9318
9319 =head2 Null command
9320
9321 Does nothing. Used to I<turn off> commands.
9322
9323 =cut
9324
9325 sub cmd_pre580_null {
9326
9327     # do nothing...
9328 }
9329
9330 =head2 Old C<a> command.
9331
9332 This version added actions if you supplied them, and deleted them
9333 if you didn't.
9334
9335 =cut
9336
9337 sub cmd_pre580_a {
9338     my $xcmd = shift;
9339     my $cmd  = shift;
9340
9341     # Argument supplied. Add the action.
9342     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9343
9344         # If the line isn't there, use the current line.
9345         my $i = $1 || $line;
9346         my $j = $2;
9347
9348         # If there is an action ...
9349         if ( length $j ) {
9350
9351             # ... but the line isn't breakable, skip it.
9352             if ( $dbline[$i] == 0 ) {
9353                 print $OUT "Line $i may not have an action.\n";
9354             }
9355             else {
9356
9357                 # ... and the line is breakable:
9358                 # Mark that there's an action in this file.
9359                 $had_breakpoints{$filename} |= 2;
9360
9361                 # Delete any current action.
9362                 $dbline{$i} =~ s/\0[^\0]*//;
9363
9364                 # Add the new action, continuing the line as needed.
9365                 $dbline{$i} .= "\0" . action($j);
9366             }
9367         } ## end if (length $j)
9368
9369         # No action supplied.
9370         else {
9371
9372             # Delete the action.
9373             $dbline{$i} =~ s/\0[^\0]*//;
9374
9375             # Mark as having no break or action if nothing's left.
9376             delete $dbline{$i} if $dbline{$i} eq '';
9377         }
9378     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9379 } ## end sub cmd_pre580_a
9380
9381 =head2 Old C<b> command
9382
9383 Add breakpoints.
9384
9385 =cut
9386
9387 sub cmd_pre580_b {
9388     my $xcmd   = shift;
9389     my $cmd    = shift;
9390     my $dbline = shift;
9391
9392     # Break on load.
9393     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9394         my $file = $1;
9395         $file =~ s/\s+$//;
9396         &cmd_b_load($file);
9397     }
9398
9399     # b compile|postpone <some sub> [<condition>]
9400     # The interpreter actually traps this one for us; we just put the
9401     # necessary condition in the %postponed hash.
9402     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9403
9404         # Capture the condition if there is one. Make it true if none.
9405         my $cond = length $3 ? $3 : '1';
9406
9407         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9408         # if it was 'compile'.
9409         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9410
9411         # De-Perl4-ify the name - ' separators to ::.
9412         $subname =~ s/\'/::/g;
9413
9414         # Qualify it into the current package unless it's already qualified.
9415         $subname = "${package}::" . $subname
9416           unless $subname =~ /::/;
9417
9418         # Add main if it starts with ::.
9419         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9420
9421         # Save the break type for this sub.
9422         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9423     } ## end elsif ($cmd =~ ...
9424
9425     # b <sub name> [<condition>]
9426     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9427         my $subname = $1;
9428         my $cond = length $2 ? $2 : '1';
9429         &cmd_b_sub( $subname, $cond );
9430     }
9431     # b <line> [<condition>].
9432     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9433         my $i = $1 || $dbline;
9434         my $cond = length $2 ? $2 : '1';
9435         &cmd_b_line( $i, $cond );
9436     }
9437 } ## end sub cmd_pre580_b
9438
9439 =head2 Old C<D> command.
9440
9441 Delete all breakpoints unconditionally.
9442
9443 =cut
9444
9445 sub cmd_pre580_D {
9446     my $xcmd = shift;
9447     my $cmd  = shift;
9448     if ( $cmd =~ /^\s*$/ ) {
9449         print $OUT "Deleting all breakpoints...\n";
9450
9451         # %had_breakpoints lists every file that had at least one
9452         # breakpoint in it.
9453         my $file;
9454         for $file ( keys %had_breakpoints ) {
9455
9456             # Switch to the desired file temporarily.
9457             local *dbline = $main::{ '_<' . $file };
9458
9459             $max = $#dbline;
9460             my $was;
9461
9462             # For all lines in this file ...
9463             for my $i (1 .. $max) {
9464
9465                 # If there's a breakpoint or action on this line ...
9466                 if ( defined $dbline{$i} ) {
9467
9468                     # ... remove the breakpoint.
9469                     $dbline{$i} =~ s/^[^\0]+//;
9470                     if ( $dbline{$i} =~ s/^\0?$// ) {
9471
9472                         # Remove the entry altogether if no action is there.
9473                         delete $dbline{$i};
9474                     }
9475                 } ## end if (defined $dbline{$i...
9476             } ## end for my $i (1 .. $max)
9477
9478             # If, after we turn off the "there were breakpoints in this file"
9479             # bit, the entry in %had_breakpoints for this file is zero,
9480             # we should remove this file from the hash.
9481             if ( not $had_breakpoints{$file} &= ~1 ) {
9482                 delete $had_breakpoints{$file};
9483             }
9484         } ## end for $file (keys %had_breakpoints)
9485
9486         # Kill off all the other breakpoints that are waiting for files that
9487         # haven't been loaded yet.
9488         undef %postponed;
9489         undef %postponed_file;
9490         undef %break_on_load;
9491     } ## end if ($cmd =~ /^\s*$/)
9492 } ## end sub cmd_pre580_D
9493
9494 =head2 Old C<h> command
9495
9496 Print help. Defaults to printing the long-form help; the 5.8 version
9497 prints the summary by default.
9498
9499 =cut
9500
9501 sub cmd_pre580_h {
9502     my $xcmd = shift;
9503     my $cmd  = shift;
9504
9505     # Print the *right* help, long format.
9506     if ( $cmd =~ /^\s*$/ ) {
9507         print_help($pre580_help);
9508     }
9509
9510     # 'h h' - explicitly-requested summary.
9511     elsif ( $cmd =~ /^h\s*/ ) {
9512         print_help($pre580_summary);
9513     }
9514
9515     # Find and print a command's help.
9516     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9517         my $asked  = $1;                   # for proper errmsg
9518         my $qasked = quotemeta($asked);    # for searching
9519                                            # XXX: finds CR but not <CR>
9520         if (
9521             $pre580_help =~ /^
9522                               <?           # Optional '<'
9523                               (?:[IB]<)    # Optional markup
9524                               $qasked      # The command name
9525                             /mx
9526           )
9527         {
9528
9529             while (
9530                 $pre580_help =~ /^
9531                                   (             # The command help:
9532                                    <?           # Optional '<'
9533                                    (?:[IB]<)    # Optional markup
9534                                    $qasked      # The command name
9535                                    ([\s\S]*?)   # Lines starting with tabs
9536                                    \n           # Final newline
9537                                   )
9538                                   (?!\s)/mgx
9539               )    # Line not starting with space
9540                    # (Next command's help)
9541             {
9542                 print_help($1);
9543             }
9544         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9545
9546         # Help not found.
9547         else {
9548             print_help("B<$asked> is not a debugger command.\n");
9549         }
9550     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9551 } ## end sub cmd_pre580_h
9552
9553 =head2 Old C<W> command
9554
9555 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9556
9557 =cut
9558
9559 sub cmd_pre580_W {
9560     my $xcmd = shift;
9561     my $cmd  = shift;
9562
9563     # Delete all watch expressions.
9564     if ( $cmd =~ /^$/ ) {
9565
9566         # No watching is going on.
9567         $trace &= ~2;
9568
9569         # Kill all the watch expressions and values.
9570         @to_watch = @old_watch = ();
9571     }
9572
9573     # Add a watch expression.
9574     elsif ( $cmd =~ /^(.*)/s ) {
9575
9576         # add it to the list to be watched.
9577         push @to_watch, $1;
9578
9579         # Get the current value of the expression.
9580         # Doesn't handle expressions returning list values!
9581         $evalarg = $1;
9582         my ($val) = &eval;
9583         $val = ( defined $val ) ? "'$val'" : 'undef';
9584
9585         # Save it.
9586         push @old_watch, $val;
9587
9588         # We're watching stuff.
9589         $trace |= 2;
9590
9591     } ## end elsif ($cmd =~ /^(.*)/s)
9592 } ## end sub cmd_pre580_W
9593
9594 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9595
9596 The debugger used to have a bunch of nearly-identical code to handle
9597 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9598 C<cmd_prepost> unify all this into one set of code to handle the
9599 appropriate actions.
9600
9601 =head2 C<cmd_pre590_prepost>
9602
9603 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9604 do something destructive. In pre 5.8 debuggers, the default action was to
9605 delete all the actions.
9606
9607 =cut
9608
9609 sub cmd_pre590_prepost {
9610     my $cmd    = shift;
9611     my $line   = shift || '*';
9612     my $dbline = shift;
9613
9614     return &cmd_prepost( $cmd, $line, $dbline );
9615 } ## end sub cmd_pre590_prepost
9616
9617 =head2 C<cmd_prepost>
9618
9619 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9620 Since the lists of actions are all held in arrays that are pointed to by
9621 references anyway, all we have to do is pick the right array reference and
9622 then use generic code to all, delete, or list actions.
9623
9624 =cut
9625
9626 sub cmd_prepost {
9627     my $cmd = shift;
9628
9629     # No action supplied defaults to 'list'.
9630     my $line = shift || '?';
9631
9632     # Figure out what to put in the prompt.
9633     my $which = '';
9634
9635     # Make sure we have some array or another to address later.
9636     # This means that if ssome reason the tests fail, we won't be
9637     # trying to stash actions or delete them from the wrong place.
9638     my $aref = [];
9639
9640     # < - Perl code to run before prompt.
9641     if ( $cmd =~ /^\</o ) {
9642         $which = 'pre-perl';
9643         $aref  = $pre;
9644     }
9645
9646     # > - Perl code to run after prompt.
9647     elsif ( $cmd =~ /^\>/o ) {
9648         $which = 'post-perl';
9649         $aref  = $post;
9650     }
9651
9652     # { - first check for properly-balanced braces.
9653     elsif ( $cmd =~ /^\{/o ) {
9654         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9655             print $OUT
9656 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9657         }
9658
9659         # Properly balanced. Pre-prompt debugger actions.
9660         else {
9661             $which = 'pre-debugger';
9662             $aref  = $pretype;
9663         }
9664     } ## end elsif ( $cmd =~ /^\{/o )
9665
9666     # Did we find something that makes sense?
9667     unless ($which) {
9668         print $OUT "Confused by command: $cmd\n";
9669     }
9670
9671     # Yes.
9672     else {
9673
9674         # List actions.
9675         if ( $line =~ /^\s*\?\s*$/o ) {
9676             unless (@$aref) {
9677
9678                 # Nothing there. Complain.
9679                 print $OUT "No $which actions.\n";
9680             }
9681             else {
9682
9683                 # List the actions in the selected list.
9684                 print $OUT "$which commands:\n";
9685                 foreach my $action (@$aref) {
9686                     print $OUT "\t$cmd -- $action\n";
9687                 }
9688             } ## end else
9689         } ## end if ( $line =~ /^\s*\?\s*$/o)
9690
9691         # Might be a delete.
9692         else {
9693             if ( length($cmd) == 1 ) {
9694                 if ( $line =~ /^\s*\*\s*$/o ) {
9695
9696                     # It's a delete. Get rid of the old actions in the
9697                     # selected list..
9698                     @$aref = ();
9699                     print $OUT "All $cmd actions cleared.\n";
9700                 }
9701                 else {
9702
9703                     # Replace all the actions. (This is a <, >, or {).
9704                     @$aref = action($line);
9705                 }
9706             } ## end if ( length($cmd) == 1)
9707             elsif ( length($cmd) == 2 ) {
9708
9709                 # Add the action to the line. (This is a <<, >>, or {{).
9710                 push @$aref, action($line);
9711             }
9712             else {
9713
9714                 # <<<, >>>>, {{{{{{ ... something not a command.
9715                 print $OUT
9716                   "Confused by strange length of $which command($cmd)...\n";
9717             }
9718         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9719     } ## end else
9720 } ## end sub cmd_prepost
9721
9722 =head1 C<DB::fake>
9723
9724 Contains the C<at_exit> routine that the debugger uses to issue the
9725 C<Debugged program terminated ...> message after the program completes. See
9726 the C<END> block documentation for more details.
9727
9728 =cut
9729
9730 package DB::fake;
9731
9732 sub at_exit {
9733     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9734 }
9735
9736 package DB;    # Do not trace this 1; below!
9737
9738 1;
9739
9740