This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
b9937591878f2c84cd6fe1816e6b6df13c990b46
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Prior to 5.14, generally a property would have either its
166 # map table or its match tables written but not both.  Again, what gets
167 # written is controlled by lists which can easily be changed.  Starting in
168 # 5.14, advantage was taken of this, and all the map tables needed to
169 # reconstruct the Unicode db are now written out, while suppressing the
170 # Unicode .txt files that contain the data.  Our tables are much more compact
171 # than the .txt files, so a significant space savings was achieved.
172
173 # Properties have a 'Type', like binary, or string, or enum depending on how
174 # many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably, and to keep out
185 # potential security issues.  For example, no
186 # folding information was given in early releases, so this program substitutes
187 # lower case instead, just so that a regular expression with the /i option
188 # will do something that actually gives the right results in many cases.
189 # There are also a couple other corrections for version 1.1.5, commented at
190 # the point they are made.  As an example of corrections that weren't made
191 # (but could be) is this statement from DerivedAge.txt: "The supplementary
192 # private use code points and the non-character code points were assigned in
193 # version 2.0, but not specifically listed in the UCD until versions 3.0 and
194 # 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0) More information
195 # on Unicode version glitches is further down in these introductory comments.
196 #
197 # This program works on all non-provisional properties as of 6.0, though the
198 # files for some are suppressed from apparent lack of demand for them.  You
199 # can change which are output by changing lists in this program.
200 #
201 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
202 # loose matchings rules (from Unicode TR18):
203 #
204 #    The recommended names for UCD properties and property values are in
205 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
206 #    [PropValue]. There are both abbreviated names and longer, more
207 #    descriptive names. It is strongly recommended that both names be
208 #    recognized, and that loose matching of property names be used,
209 #    whereby the case distinctions, whitespace, hyphens, and underbar
210 #    are ignored.
211 # The program still allows Fuzzy to override its determination of if loose
212 # matching should be used, but it isn't currently used, as it is no longer
213 # needed; the calculations it makes are good enough.
214 #
215 # SUMMARY OF HOW IT WORKS:
216 #
217 #   Process arguments
218 #
219 #   A list is constructed containing each input file that is to be processed
220 #
221 #   Each file on the list is processed in a loop, using the associated handler
222 #   code for each:
223 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
224 #            first.  These files name the properties and property values.
225 #            Objects are created of all the property and property value names
226 #            that the rest of the input should expect, including all synonyms.
227 #        The other input files give mappings from properties to property
228 #           values.  That is, they list code points and say what the mapping
229 #           is under the given property.  Some files give the mappings for
230 #           just one property; and some for many.  This program goes through
231 #           each file and populates the properties from them.  Some properties
232 #           are listed in more than one file, and Unicode has set up a
233 #           precedence as to which has priority if there is a conflict.  Thus
234 #           the order of processing matters, and this program handles the
235 #           conflict possibility by processing the overriding input files
236 #           last, so that if necessary they replace earlier values.
237 #        After this is all done, the program creates the property mappings not
238 #            furnished by Unicode, but derivable from what it does give.
239 #        The tables of code points that match each property value in each
240 #            property that is accessible by regular expressions are created.
241 #        The Perl-defined properties are created and populated.  Many of these
242 #            require data determined from the earlier steps
243 #        Any Perl-defined synonyms are created, and name clashes between Perl
244 #            and Unicode are reconciled and warned about.
245 #        All the properties are written to files
246 #        Any other files are written, and final warnings issued.
247 #
248 # For clarity, a number of operators have been overloaded to work on tables:
249 #   ~ means invert (take all characters not in the set).  The more
250 #       conventional '!' is not used because of the possibility of confusing
251 #       it with the actual boolean operation.
252 #   + means union
253 #   - means subtraction
254 #   & means intersection
255 # The precedence of these is the order listed.  Parentheses should be
256 # copiously used.  These are not a general scheme.  The operations aren't
257 # defined for a number of things, deliberately, to avoid getting into trouble.
258 # Operations are done on references and affect the underlying structures, so
259 # that the copy constructors for them have been overloaded to not return a new
260 # clone, but the input object itself.
261 #
262 # The bool operator is deliberately not overloaded to avoid confusion with
263 # "should it mean if the object merely exists, or also is non-empty?".
264 #
265 # WHY CERTAIN DESIGN DECISIONS WERE MADE
266 #
267 # This program needs to be able to run under miniperl.  Therefore, it uses a
268 # minimum of other modules, and hence implements some things itself that could
269 # be gotten from CPAN
270 #
271 # This program uses inputs published by the Unicode Consortium.  These can
272 # change incompatibly between releases without the Perl maintainers realizing
273 # it.  Therefore this program is now designed to try to flag these.  It looks
274 # at the directories where the inputs are, and flags any unrecognized files.
275 # It keeps track of all the properties in the files it handles, and flags any
276 # that it doesn't know how to handle.  It also flags any input lines that
277 # don't match the expected syntax, among other checks.
278 #
279 # It is also designed so if a new input file matches one of the known
280 # templates, one hopefully just needs to add it to a list to have it
281 # processed.
282 #
283 # As mentioned earlier, some properties are given in more than one file.  In
284 # particular, the files in the extracted directory are supposedly just
285 # reformattings of the others.  But they contain information not easily
286 # derivable from the other files, including results for Unihan, which this
287 # program doesn't ordinarily look at, and for unassigned code points.  They
288 # also have historically had errors or been incomplete.  In an attempt to
289 # create the best possible data, this program thus processes them first to
290 # glean information missing from the other files; then processes those other
291 # files to override any errors in the extracted ones.  Much of the design was
292 # driven by this need to store things and then possibly override them.
293 #
294 # It tries to keep fatal errors to a minimum, to generate something usable for
295 # testing purposes.  It always looks for files that could be inputs, and will
296 # warn about any that it doesn't know how to handle (the -q option suppresses
297 # the warning).
298 #
299 # Why is there more than one type of range?
300 #   This simplified things.  There are some very specialized code points that
301 #   have to be handled specially for output, such as Hangul syllable names.
302 #   By creating a range type (done late in the development process), it
303 #   allowed this to be stored with the range, and overridden by other input.
304 #   Originally these were stored in another data structure, and it became a
305 #   mess trying to decide if a second file that was for the same property was
306 #   overriding the earlier one or not.
307 #
308 # Why are there two kinds of tables, match and map?
309 #   (And there is a base class shared by the two as well.)  As stated above,
310 #   they actually are for different things.  Development proceeded much more
311 #   smoothly when I (khw) realized the distinction.  Map tables are used to
312 #   give the property value for every code point (actually every code point
313 #   that doesn't map to a default value).  Match tables are used for regular
314 #   expression matches, and are essentially the inverse mapping.  Separating
315 #   the two allows more specialized methods, and error checks so that one
316 #   can't just take the intersection of two map tables, for example, as that
317 #   is nonsensical.
318 #
319 # DEBUGGING
320 #
321 # This program is written so it will run under miniperl.  Occasionally changes
322 # will cause an error where the backtrace doesn't work well under miniperl.
323 # To diagnose the problem, you can instead run it under regular perl, if you
324 # have one compiled.
325 #
326 # There is a good trace facility.  To enable it, first sub DEBUG must be set
327 # to return true.  Then a line like
328 #
329 # local $to_trace = 1 if main::DEBUG;
330 #
331 # can be added to enable tracing in its lexical scope or until you insert
332 # another line:
333 #
334 # local $to_trace = 0 if main::DEBUG;
335 #
336 # then use a line like "trace $a, @b, %c, ...;
337 #
338 # Some of the more complex subroutines already have trace statements in them.
339 # Permanent trace statements should be like:
340 #
341 # trace ... if main::DEBUG && $to_trace;
342 #
343 # If there is just one or a few files that you're debugging, you can easily
344 # cause most everything else to be skipped.  Change the line
345 #
346 # my $debug_skip = 0;
347 #
348 # to 1, and every file whose object is in @input_file_objects and doesn't have
349 # a, 'non_skip => 1,' in its constructor will be skipped.
350 #
351 # To compare the output tables, it may be useful to specify the -annotate
352 # flag.  This causes the tables to expand so there is one entry for each
353 # non-algorithmically named code point giving, currently its name, and its
354 # graphic representation if printable (and you have a font that knows about
355 # it).  This makes it easier to see what the particular code points are in
356 # each output table.  The tables are usable, but because they don't have
357 # ranges (for the most part), a Perl using them will run slower.  Non-named
358 # code points are annotated with a description of their status, and contiguous
359 # ones with the same description will be output as a range rather than
360 # individually.  Algorithmically named characters are also output as ranges,
361 # except when there are just a few contiguous ones.
362 #
363 # FUTURE ISSUES
364 #
365 # The program would break if Unicode were to change its names so that
366 # interior white space, underscores, or dashes differences were significant
367 # within property and property value names.
368 #
369 # It might be easier to use the xml versions of the UCD if this program ever
370 # would need heavy revision, and the ability to handle old versions was not
371 # required.
372 #
373 # There is the potential for name collisions, in that Perl has chosen names
374 # that Unicode could decide it also likes.  There have been such collisions in
375 # the past, with mostly Perl deciding to adopt the Unicode definition of the
376 # name.  However in the 5.2 Unicode beta testing, there were a number of such
377 # collisions, which were withdrawn before the final release, because of Perl's
378 # and other's protests.  These all involved new properties which began with
379 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
380 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
381 # Unicode document, so they are unlikely to be used by Unicode for another
382 # purpose.  However, they might try something beginning with 'In', or use any
383 # of the other Perl-defined properties.  This program will warn you of name
384 # collisions, and refuse to generate tables with them, but manual intervention
385 # will be required in this event.  One scheme that could be implemented, if
386 # necessary, would be to have this program generate another file, or add a
387 # field to mktables.lst that gives the date of first definition of a property.
388 # Each new release of Unicode would use that file as a basis for the next
389 # iteration.  And the Perl synonym addition code could sort based on the age
390 # of the property, so older properties get priority, and newer ones that clash
391 # would be refused; hence existing code would not be impacted, and some other
392 # synonym would have to be used for the new property.  This is ugly, and
393 # manual intervention would certainly be easier to do in the short run; lets
394 # hope it never comes to this.
395 #
396 # A NOTE ON UNIHAN
397 #
398 # This program can generate tables from the Unihan database.  But it doesn't
399 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
400 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
401 # database was split into 8 different files, all beginning with the letters
402 # 'Unihan'.  This program will read those file(s) if present, but it needs to
403 # know which of the many properties in the file(s) should have tables created
404 # for them.  It will create tables for any properties listed in
405 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
406 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
407 # property you want is not in those files of the release you are building
408 # against, you must add it to those two arrays.  Starting in 4.0, the
409 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
410 # is present in the directory, a table will be generated for that property.
411 # In 5.2, several more properties were added.  For your convenience, the two
412 # arrays are initialized with all the 6.0 listed properties that are also in
413 # earlier releases.  But these are commented out.  You can just uncomment the
414 # ones you want, or use them as a template for adding entries for other
415 # properties.
416 #
417 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
418 # and filter_unihan_line() are the functions where this is done.  This program
419 # already does some adjusting to make the lines look more like the rest of the
420 # Unicode DB;  You can see what that is in filter_unihan_line()
421 #
422 # There is a bug in the 3.2 data file in which some values for the
423 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
424 # could be added for these; or for a particular installation, the Unihan.txt
425 # file could be edited to fix them.
426 #
427 # HOW TO ADD A FILE TO BE PROCESSED
428 #
429 # A new file from Unicode needs to have an object constructed for it in
430 # @input_file_objects, probably at the end or at the end of the extracted
431 # ones.  The program should warn you if its name will clash with others on
432 # restrictive file systems, like DOS.  If so, figure out a better name, and
433 # add lines to the README.perl file giving that.  If the file is a character
434 # property, it should be in the format that Unicode has by default
435 # standardized for such files for the more recently introduced ones.
436 # If so, the Input_file constructor for @input_file_objects can just be the
437 # file name and release it first appeared in.  If not, then it should be
438 # possible to construct an each_line_handler() to massage the line into the
439 # standardized form.
440 #
441 # For non-character properties, more code will be needed.  You can look at
442 # the existing entries for clues.
443 #
444 # UNICODE VERSIONS NOTES
445 #
446 # The Unicode UCD has had a number of errors in it over the versions.  And
447 # these remain, by policy, in the standard for that version.  Therefore it is
448 # risky to correct them, because code may be expecting the error.  So this
449 # program doesn't generally make changes, unless the error breaks the Perl
450 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
451 # for U+1105, which causes real problems for the algorithms for Jamo
452 # calculations, so it is changed here.
453 #
454 # But it isn't so clear cut as to what to do about concepts that are
455 # introduced in a later release; should they extend back to earlier releases
456 # where the concept just didn't exist?  It was easier to do this than to not,
457 # so that's what was done.  For example, the default value for code points not
458 # in the files for various properties was probably undefined until changed by
459 # some version.  No_Block for blocks is such an example.  This program will
460 # assign No_Block even in Unicode versions that didn't have it.  This has the
461 # benefit that code being written doesn't have to special case earlier
462 # versions; and the detriment that it doesn't match the Standard precisely for
463 # the affected versions.
464 #
465 # Here are some observations about some of the issues in early versions:
466 #
467 # The number of code points in \p{alpha} halved in 2.1.9.  It turns out that
468 # the reason is that the CJK block starting at 4E00 was removed from PropList,
469 # and was not put back in until 3.1.0
470 #
471 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
472 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
473 # reason is that 3.2 introduced U+205F=medium math space, which was not
474 # classed as white space, but Perl figured out that it should have been. 4.0
475 # reclassified it correctly.
476 #
477 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
478 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
479 # was left with no code points, as all the ones that mapped to 202 stayed
480 # mapped to 202.  Thus if your program used the numeric name for the class,
481 # it would not have been affected, but if it used the mnemonic, it would have
482 # been.
483 #
484 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
485 # points which eventually came to have this script property value, instead
486 # mapped to "Unknown".  But in the next release all these code points were
487 # moved to \p{sc=common} instead.
488 #
489 # The default for missing code points for BidiClass is complicated.  Starting
490 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
491 # tries to do the best it can for earlier releases.  It is done in
492 # process_PropertyAliases()
493 #
494 ##############################################################################
495
496 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
497                         # and errors
498 my $MAX_LINE_WIDTH = 78;
499
500 # Debugging aid to skip most files so as to not be distracted by them when
501 # concentrating on the ones being debugged.  Add
502 # non_skip => 1,
503 # to the constructor for those files you want processed when you set this.
504 # Files with a first version number of 0 are special: they are always
505 # processed regardless of the state of this flag.  Generally, Jamo.txt and
506 # UnicodeData.txt must not be skipped if you want this program to not die
507 # before normal completion.
508 my $debug_skip = 0;
509
510 # Set to 1 to enable tracing.
511 our $to_trace = 0;
512
513 { # Closure for trace: debugging aid
514     my $print_caller = 1;        # ? Include calling subroutine name
515     my $main_with_colon = 'main::';
516     my $main_colon_length = length($main_with_colon);
517
518     sub trace {
519         return unless $to_trace;        # Do nothing if global flag not set
520
521         my @input = @_;
522
523         local $DB::trace = 0;
524         $DB::trace = 0;          # Quiet 'used only once' message
525
526         my $line_number;
527
528         # Loop looking up the stack to get the first non-trace caller
529         my $caller_line;
530         my $caller_name;
531         my $i = 0;
532         do {
533             $line_number = $caller_line;
534             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
535             $caller = $main_with_colon unless defined $caller;
536
537             $caller_name = $caller;
538
539             # get rid of pkg
540             $caller_name =~ s/.*:://;
541             if (substr($caller_name, 0, $main_colon_length)
542                 eq $main_with_colon)
543             {
544                 $caller_name = substr($caller_name, $main_colon_length);
545             }
546
547         } until ($caller_name ne 'trace');
548
549         # If the stack was empty, we were called from the top level
550         $caller_name = 'main' if ($caller_name eq ""
551                                     || $caller_name eq 'trace');
552
553         my $output = "";
554         foreach my $string (@input) {
555             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
556             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
557                 $output .= simple_dumper($string);
558             }
559             else {
560                 $string = "$string" if ref $string;
561                 $string = $UNDEF unless defined $string;
562                 chomp $string;
563                 $string = '""' if $string eq "";
564                 $output .= " " if $output ne ""
565                                 && $string ne ""
566                                 && substr($output, -1, 1) ne " "
567                                 && substr($string, 0, 1) ne " ";
568                 $output .= $string;
569             }
570         }
571
572         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
573         print STDERR "$caller_name: " if $print_caller;
574         print STDERR $output, "\n";
575         return;
576     }
577 }
578
579 # This is for a rarely used development feature that allows you to compare two
580 # versions of the Unicode standard without having to deal with changes caused
581 # by the code points introduced in the later version.  Change the 0 to a
582 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
583 # code points introduced in that release and earlier will be used; later ones
584 # are thrown away.  You use the version number of the earliest one you want to
585 # compare; then run this program on directory structures containing each
586 # release, and compare the outputs.  These outputs will therefore include only
587 # the code points common to both releases, and you can see the changes caused
588 # just by the underlying release semantic changes.  For versions earlier than
589 # 3.2, you must copy a version of DAge.txt into the directory.
590 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
591 my $compare_versions = DEBUG
592                        && $string_compare_versions
593                        && pack "C*", split /\./, $string_compare_versions;
594
595 sub uniques {
596     # Returns non-duplicated input values.  From "Perl Best Practices:
597     # Encapsulated Cleverness".  p. 455 in first edition.
598
599     my %seen;
600     # Arguably this breaks encapsulation, if the goal is to permit multiple
601     # distinct objects to stringify to the same value, and be interchangeable.
602     # However, for this program, no two objects stringify identically, and all
603     # lists passed to this function are either objects or strings. So this
604     # doesn't affect correctness, but it does give a couple of percent speedup.
605     no overloading;
606     return grep { ! $seen{$_}++ } @_;
607 }
608
609 $0 = File::Spec->canonpath($0);
610
611 my $make_test_script = 0;      # ? Should we output a test script
612 my $make_norm_test_script = 0; # ? Should we output a normalization test script
613 my $write_unchanged_files = 0; # ? Should we update the output files even if
614                                #    we don't think they have changed
615 my $use_directory = "";        # ? Should we chdir somewhere.
616 my $pod_directory;             # input directory to store the pod file.
617 my $pod_file = 'perluniprops';
618 my $t_path;                     # Path to the .t test file
619 my $file_list = 'mktables.lst'; # File to store input and output file names.
620                                # This is used to speed up the build, by not
621                                # executing the main body of the program if
622                                # nothing on the list has changed since the
623                                # previous build
624 my $make_list = 1;             # ? Should we write $file_list.  Set to always
625                                # make a list so that when the pumpking is
626                                # preparing a release, s/he won't have to do
627                                # special things
628 my $glob_list = 0;             # ? Should we try to include unknown .txt files
629                                # in the input.
630 my $output_range_counts = $debugging_build;   # ? Should we include the number
631                                               # of code points in ranges in
632                                               # the output
633 my $annotate = 0;              # ? Should character names be in the output
634
635 # Verbosity levels; 0 is quiet
636 my $NORMAL_VERBOSITY = 1;
637 my $PROGRESS = 2;
638 my $VERBOSE = 3;
639
640 my $verbosity = $NORMAL_VERBOSITY;
641
642 # Process arguments
643 while (@ARGV) {
644     my $arg = shift @ARGV;
645     if ($arg eq '-v') {
646         $verbosity = $VERBOSE;
647     }
648     elsif ($arg eq '-p') {
649         $verbosity = $PROGRESS;
650         $| = 1;     # Flush buffers as we go.
651     }
652     elsif ($arg eq '-q') {
653         $verbosity = 0;
654     }
655     elsif ($arg eq '-w') {
656         $write_unchanged_files = 1; # update the files even if havent changed
657     }
658     elsif ($arg eq '-check') {
659         my $this = shift @ARGV;
660         my $ok = shift @ARGV;
661         if ($this ne $ok) {
662             print "Skipping as check params are not the same.\n";
663             exit(0);
664         }
665     }
666     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
667         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
668     }
669     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
670     {
671         $make_test_script = 1;
672     }
673     elsif ($arg eq '-makenormtest')
674     {
675         $make_norm_test_script = 1;
676     }
677     elsif ($arg eq '-makelist') {
678         $make_list = 1;
679     }
680     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
681         -d $use_directory or croak "Unknown directory '$use_directory'";
682     }
683     elsif ($arg eq '-L') {
684
685         # Existence not tested until have chdir'd
686         $file_list = shift;
687     }
688     elsif ($arg eq '-globlist') {
689         $glob_list = 1;
690     }
691     elsif ($arg eq '-c') {
692         $output_range_counts = ! $output_range_counts
693     }
694     elsif ($arg eq '-annotate') {
695         $annotate = 1;
696         $debugging_build = 1;
697         $output_range_counts = 1;
698     }
699     else {
700         my $with_c = 'with';
701         $with_c .= 'out' if $output_range_counts;   # Complements the state
702         croak <<END;
703 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
704           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
705           [-check A B ]
706   -c          : Output comments $with_c number of code points in ranges
707   -q          : Quiet Mode: Only output serious warnings.
708   -p          : Set verbosity level to normal plus show progress.
709   -v          : Set Verbosity level high:  Show progress and non-serious
710                 warnings
711   -w          : Write files regardless
712   -C dir      : Change to this directory before proceeding. All relative paths
713                 except those specified by the -P and -T options will be done
714                 with respect to this directory.
715   -P dir      : Output $pod_file file to directory 'dir'.
716   -T path     : Create a test script as 'path'; overrides -maketest
717   -L filelist : Use alternate 'filelist' instead of standard one
718   -globlist   : Take as input all non-Test *.txt files in current and sub
719                 directories
720   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
721                 overrides -T
722   -makelist   : Rewrite the file list $file_list based on current setup
723   -annotate   : Output an annotation for each character in the table files;
724                 useful for debugging mktables, looking at diffs; but is slow,
725                 memory intensive; resulting tables are usable but are slow and
726                 very large (and currently fail the Unicode::UCD.t tests).
727   -check A B  : Executes $0 only if A and B are the same
728 END
729     }
730 }
731
732 # Stores the most-recently changed file.  If none have changed, can skip the
733 # build
734 my $most_recent = (stat $0)[9];   # Do this before the chdir!
735
736 # Change directories now, because need to read 'version' early.
737 if ($use_directory) {
738     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
739         $pod_directory = File::Spec->rel2abs($pod_directory);
740     }
741     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
742         $t_path = File::Spec->rel2abs($t_path);
743     }
744     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
745     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
746         $pod_directory = File::Spec->abs2rel($pod_directory);
747     }
748     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
749         $t_path = File::Spec->abs2rel($t_path);
750     }
751 }
752
753 # Get Unicode version into regular and v-string.  This is done now because
754 # various tables below get populated based on it.  These tables are populated
755 # here to be near the top of the file, and so easily seeable by those needing
756 # to modify things.
757 open my $VERSION, "<", "version"
758                     or croak "$0: can't open required file 'version': $!\n";
759 my $string_version = <$VERSION>;
760 close $VERSION;
761 chomp $string_version;
762 my $v_version = pack "C*", split /\./, $string_version;        # v string
763
764 # The following are the complete names of properties with property values that
765 # are known to not match any code points in some versions of Unicode, but that
766 # may change in the future so they should be matchable, hence an empty file is
767 # generated for them.
768 my @tables_that_may_be_empty = (
769                                 'Joining_Type=Left_Joining',
770                                 );
771 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
772 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
773 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
774                                                     if $v_version ge v4.1.0;
775 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
776                                                     if $v_version ge v6.0.0;
777 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
778                                                     if $v_version ge v6.1.0;
779
780 # The lists below are hashes, so the key is the item in the list, and the
781 # value is the reason why it is in the list.  This makes generation of
782 # documentation easier.
783
784 my %why_suppressed;  # No file generated for these.
785
786 # Files aren't generated for empty extraneous properties.  This is arguable.
787 # Extraneous properties generally come about because a property is no longer
788 # used in a newer version of Unicode.  If we generated a file without code
789 # points, programs that used to work on that property will still execute
790 # without errors.  It just won't ever match (or will always match, with \P{}).
791 # This means that the logic is now likely wrong.  I (khw) think its better to
792 # find this out by getting an error message.  Just move them to the table
793 # above to change this behavior
794 my %why_suppress_if_empty_warn_if_not = (
795
796    # It is the only property that has ever officially been removed from the
797    # Standard.  The database never contained any code points for it.
798    'Special_Case_Condition' => 'Obsolete',
799
800    # Apparently never official, but there were code points in some versions of
801    # old-style PropList.txt
802    'Non_Break' => 'Obsolete',
803 );
804
805 # These would normally go in the warn table just above, but they were changed
806 # a long time before this program was written, so warnings about them are
807 # moot.
808 if ($v_version gt v3.2.0) {
809     push @tables_that_may_be_empty,
810                                 'Canonical_Combining_Class=Attached_Below_Left'
811 }
812
813 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
814 # unless explicitly added.
815 if ($v_version ge v5.2.0) {
816     my $unihan = 'Unihan; remove from list if using Unihan';
817     foreach my $table (qw (
818                            kAccountingNumeric
819                            kOtherNumeric
820                            kPrimaryNumeric
821                            kCompatibilityVariant
822                            kIICore
823                            kIRG_GSource
824                            kIRG_HSource
825                            kIRG_JSource
826                            kIRG_KPSource
827                            kIRG_MSource
828                            kIRG_KSource
829                            kIRG_TSource
830                            kIRG_USource
831                            kIRG_VSource
832                            kRSUnicode
833                         ))
834     {
835         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
836     }
837 }
838
839 # Enum values for to_output_map() method in the Map_Table package.
840 my $EXTERNAL_MAP = 1;
841 my $INTERNAL_MAP = 2;
842 my $OUTPUT_ADJUSTED = 3;
843
844 # To override computed values for writing the map tables for these properties.
845 # The default for enum map tables is to write them out, so that the Unicode
846 # .txt files can be removed, but all the data to compute any property value
847 # for any code point is available in a more compact form.
848 my %global_to_output_map = (
849     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
850     # get stuck supporting it if things change.  Since it is a STRING
851     # property, it normally would be listed in the pod, but INTERNAL_MAP
852     # suppresses that.
853     Unicode_1_Name => $INTERNAL_MAP,
854
855     Present_In => 0,                # Suppress, as easily computed from Age
856     Block => 0,                     # Suppress, as Blocks.txt is retained.
857
858     # Suppress, as mapping can be found instead from the
859     # Perl_Decomposition_Mapping file
860     Decomposition_Type => 0,
861 );
862
863 # Properties that this program ignores.
864 my @unimplemented_properties;
865
866 # With this release, it is automatically handled if the Unihan db is
867 # downloaded
868 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
869
870 # There are several types of obsolete properties defined by Unicode.  These
871 # must be hand-edited for every new Unicode release.
872 my %why_deprecated;  # Generates a deprecated warning message if used.
873 my %why_stabilized;  # Documentation only
874 my %why_obsolete;    # Documentation only
875
876 {   # Closure
877     my $simple = 'Perl uses the more complete version of this property';
878     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
879
880     my $other_properties = 'other properties';
881     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
882     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
883
884     %why_deprecated = (
885         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
886         'Jamo_Short_Name' => $contributory,
887         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
888         'Other_Alphabetic' => $contributory,
889         'Other_Default_Ignorable_Code_Point' => $contributory,
890         'Other_Grapheme_Extend' => $contributory,
891         'Other_ID_Continue' => $contributory,
892         'Other_ID_Start' => $contributory,
893         'Other_Lowercase' => $contributory,
894         'Other_Math' => $contributory,
895         'Other_Uppercase' => $contributory,
896         'Expands_On_NFC' => $why_no_expand,
897         'Expands_On_NFD' => $why_no_expand,
898         'Expands_On_NFKC' => $why_no_expand,
899         'Expands_On_NFKD' => $why_no_expand,
900     );
901
902     %why_suppressed = (
903         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
904         # contains the same information, but without the algorithmically
905         # determinable Hangul syllables'.  This file is not published, so it's
906         # existence is not noted in the comment.
907         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
908
909         'Indic_Matra_Category' => "Provisional",
910         'Indic_Syllabic_Category' => "Provisional",
911
912         # Don't suppress ISO_Comment, as otherwise special handling is needed
913         # to differentiate between it and gc=c, which can be written as 'isc',
914         # which is the same characters as ISO_Comment's short name.
915
916         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
917
918         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
919         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
920         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
921         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
922
923         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
924     );
925
926     foreach my $property (
927
928             # The following are suppressed because they were made contributory
929             # or deprecated by Unicode before Perl ever thought about
930             # supporting them.
931             'Jamo_Short_Name',
932             'Grapheme_Link',
933             'Expands_On_NFC',
934             'Expands_On_NFD',
935             'Expands_On_NFKC',
936             'Expands_On_NFKD',
937
938             # The following are suppressed because they have been marked
939             # as deprecated for a sufficient amount of time
940             'Other_Alphabetic',
941             'Other_Default_Ignorable_Code_Point',
942             'Other_Grapheme_Extend',
943             'Other_ID_Continue',
944             'Other_ID_Start',
945             'Other_Lowercase',
946             'Other_Math',
947             'Other_Uppercase',
948     ) {
949         $why_suppressed{$property} = $why_deprecated{$property};
950     }
951
952     # Customize the message for all the 'Other_' properties
953     foreach my $property (keys %why_deprecated) {
954         next if (my $main_property = $property) !~ s/^Other_//;
955         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
956     }
957 }
958
959 if ($v_version ge 4.0.0) {
960     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
961     if ($v_version ge 6.0.0) {
962         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
963     }
964 }
965 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
966     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
967     if ($v_version ge 6.0.0) {
968         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
969     }
970 }
971
972 # Probably obsolete forever
973 if ($v_version ge v4.1.0) {
974     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
975 }
976 if ($v_version ge v6.0.0) {
977     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana (or both)"';
978     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
979 }
980
981 # This program can create files for enumerated-like properties, such as
982 # 'Numeric_Type'.  This file would be the same format as for a string
983 # property, with a mapping from code point to its value, so you could look up,
984 # for example, the script a code point is in.  But no one so far wants this
985 # mapping, or they have found another way to get it since this is a new
986 # feature.  So no file is generated except if it is in this list.
987 my @output_mapped_properties = split "\n", <<END;
988 END
989
990 # If you are using the Unihan database in a Unicode version before 5.2, you
991 # need to add the properties that you want to extract from it to this table.
992 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
993 # listed, commented out
994 my @cjk_properties = split "\n", <<'END';
995 #cjkAccountingNumeric; kAccountingNumeric
996 #cjkOtherNumeric; kOtherNumeric
997 #cjkPrimaryNumeric; kPrimaryNumeric
998 #cjkCompatibilityVariant; kCompatibilityVariant
999 #cjkIICore ; kIICore
1000 #cjkIRG_GSource; kIRG_GSource
1001 #cjkIRG_HSource; kIRG_HSource
1002 #cjkIRG_JSource; kIRG_JSource
1003 #cjkIRG_KPSource; kIRG_KPSource
1004 #cjkIRG_KSource; kIRG_KSource
1005 #cjkIRG_TSource; kIRG_TSource
1006 #cjkIRG_USource; kIRG_USource
1007 #cjkIRG_VSource; kIRG_VSource
1008 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1009 END
1010
1011 # Similarly for the property values.  For your convenience, the lines in the
1012 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1013 # '#' marks (for Unicode versions before 5.2)
1014 my @cjk_property_values = split "\n", <<'END';
1015 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1016 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1017 ## @missing: 0000..10FFFF; cjkIICore; <none>
1018 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1019 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1020 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1021 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1022 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1023 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1024 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1025 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1026 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1027 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1028 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1029 END
1030
1031 # The input files don't list every code point.  Those not listed are to be
1032 # defaulted to some value.  Below are hard-coded what those values are for
1033 # non-binary properties as of 5.1.  Starting in 5.0, there are
1034 # machine-parsable comment lines in the files the give the defaults; so this
1035 # list shouldn't have to be extended.  The claim is that all missing entries
1036 # for binary properties will default to 'N'.  Unicode tried to change that in
1037 # 5.2, but the beta period produced enough protest that they backed off.
1038 #
1039 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1040 # be in the form that it expects.  The others may be synonyms.
1041 my $CODE_POINT = '<code point>';
1042 my %default_mapping = (
1043     Age => "Unassigned",
1044     # Bidi_Class => Complicated; set in code
1045     Bidi_Mirroring_Glyph => "",
1046     Block => 'No_Block',
1047     Canonical_Combining_Class => 0,
1048     Case_Folding => $CODE_POINT,
1049     Decomposition_Mapping => $CODE_POINT,
1050     Decomposition_Type => 'None',
1051     East_Asian_Width => "Neutral",
1052     FC_NFKC_Closure => $CODE_POINT,
1053     General_Category => 'Cn',
1054     Grapheme_Cluster_Break => 'Other',
1055     Hangul_Syllable_Type => 'NA',
1056     ISO_Comment => "",
1057     Jamo_Short_Name => "",
1058     Joining_Group => "No_Joining_Group",
1059     # Joining_Type => Complicated; set in code
1060     kIICore => 'N',   #                       Is converted to binary
1061     #Line_Break => Complicated; set in code
1062     Lowercase_Mapping => $CODE_POINT,
1063     Name => "",
1064     Name_Alias => "",
1065     NFC_QC => 'Yes',
1066     NFD_QC => 'Yes',
1067     NFKC_QC => 'Yes',
1068     NFKD_QC => 'Yes',
1069     Numeric_Type => 'None',
1070     Numeric_Value => 'NaN',
1071     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1072     Sentence_Break => 'Other',
1073     Simple_Case_Folding => $CODE_POINT,
1074     Simple_Lowercase_Mapping => $CODE_POINT,
1075     Simple_Titlecase_Mapping => $CODE_POINT,
1076     Simple_Uppercase_Mapping => $CODE_POINT,
1077     Titlecase_Mapping => $CODE_POINT,
1078     Unicode_1_Name => "",
1079     Unicode_Radical_Stroke => "",
1080     Uppercase_Mapping => $CODE_POINT,
1081     Word_Break => 'Other',
1082 );
1083
1084 # Below are files that Unicode furnishes, but this program ignores, and why
1085 my %ignored_files = (
1086     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1087     'Index.txt' => 'Alphabetical index of Unicode characters',
1088     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1089     'NamesList.txt' => 'Annotated list of characters',
1090     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1091     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1092     'ReadMe.txt' => 'Documentation',
1093     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1094     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1095     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1096     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1097     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1098     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1099 );
1100
1101 my %skipped_files;  # List of files that we skip
1102
1103 ### End of externally interesting definitions, except for @input_file_objects
1104
1105 my $HEADER=<<"EOF";
1106 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1107 # This file is machine-generated by $0 from the Unicode
1108 # database, Version $string_version.  Any changes made here will be lost!
1109 EOF
1110
1111 my $INTERNAL_ONLY_HEADER = <<"EOF";
1112
1113 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1114 # This file is for internal use by core Perl only.  The format and even the
1115 # name or existence of this file are subject to change without notice.  Don't
1116 # use it directly.
1117 EOF
1118
1119 my $DEVELOPMENT_ONLY=<<"EOF";
1120 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1121 # This file contains information artificially constrained to code points
1122 # present in Unicode release $string_compare_versions.
1123 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1124 # not be used for production.
1125
1126 EOF
1127
1128 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1129 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1130 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1131
1132 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1133 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1134 # to decrease backtracking.  The first regex allows the code point to be at
1135 # the end of a word, but to work properly, the word shouldn't end with a valid
1136 # hex character.  The second one won't match a code point at the end of a
1137 # word, and doesn't have the run-on issue
1138 my $run_on_code_point_re =
1139             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1140 my $code_point_re = qr/\b$run_on_code_point_re/;
1141
1142 # This matches the beginning of the line in the Unicode db files that give the
1143 # defaults for code points not listed (i.e., missing) in the file.  The code
1144 # depends on this ending with a semi-colon, so it can assume it is a valid
1145 # field when the line is split() by semi-colons
1146 my $missing_defaults_prefix =
1147             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1148
1149 # Property types.  Unicode has more types, but these are sufficient for our
1150 # purposes.
1151 my $UNKNOWN = -1;   # initialized to illegal value
1152 my $NON_STRING = 1; # Either binary or enum
1153 my $BINARY = 2;
1154 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1155                        # tables, additional true and false tables are
1156                        # generated so that false is anything matching the
1157                        # default value, and true is everything else.
1158 my $ENUM = 4;       # Include catalog
1159 my $STRING = 5;     # Anything else: string or misc
1160
1161 # Some input files have lines that give default values for code points not
1162 # contained in the file.  Sometimes these should be ignored.
1163 my $NO_DEFAULTS = 0;        # Must evaluate to false
1164 my $NOT_IGNORED = 1;
1165 my $IGNORED = 2;
1166
1167 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1168 # and will appear in the main body of the tables in the output files, but
1169 # there are other types of ranges as well, listed below, that are specially
1170 # handled.   There are pseudo-types as well that will never be stored as a
1171 # type, but will affect the calculation of the type.
1172
1173 # 0 is for normal, non-specials
1174 my $MULTI_CP = 1;           # Sequence of more than code point
1175 my $HANGUL_SYLLABLE = 2;
1176 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1177 my $NULL = 4;               # The map is to the null string; utf8.c can't
1178                             # handle these, nor is there an accepted syntax
1179                             # for them in \p{} constructs
1180 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1181                              # otherwise be $MULTI_CP type are instead type 0
1182
1183 # process_generic_property_file() can accept certain overrides in its input.
1184 # Each of these must begin AND end with $CMD_DELIM.
1185 my $CMD_DELIM = "\a";
1186 my $REPLACE_CMD = 'replace';    # Override the Replace
1187 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1188
1189 my $NO = 0;
1190 my $YES = 1;
1191
1192 # Values for the Replace argument to add_range.
1193 # $NO                      # Don't replace; add only the code points not
1194                            # already present.
1195 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1196                            # the comments at the subroutine definition.
1197 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1198 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1199                            # already there
1200 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1201                            # already there
1202 my $CROAK = 6;             # Die with an error if is already there
1203
1204 # Flags to give property statuses.  The phrases are to remind maintainers that
1205 # if the flag is changed, the indefinite article referring to it in the
1206 # documentation may need to be as well.
1207 my $NORMAL = "";
1208 my $DEPRECATED = 'D';
1209 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1210 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1211 my $DISCOURAGED = 'X';
1212 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1213 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1214 my $STRICTER = 'T';
1215 my $a_bold_stricter = "a 'B<$STRICTER>'";
1216 my $A_bold_stricter = "A 'B<$STRICTER>'";
1217 my $STABILIZED = 'S';
1218 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1219 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1220 my $OBSOLETE = 'O';
1221 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1222 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1223
1224 my %status_past_participles = (
1225     $DISCOURAGED => 'discouraged',
1226     $STABILIZED => 'stabilized',
1227     $OBSOLETE => 'obsolete',
1228     $DEPRECATED => 'deprecated',
1229 );
1230
1231 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1232 # externally documented.
1233 my $ORDINARY = 0;       # The normal fate.
1234 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1235                         # but there is a file written that can be used to
1236                         # reconstruct this table
1237 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1238                         # for Perl's internal use only
1239 my $SUPPRESSED = 3;     # The file for this table is not written out, and as a
1240                         # result, we don't bother to do many computations on
1241                         # it.
1242 my $PLACEHOLDER = 4;    # Like $SUPPRESSED, but we go through all the
1243                         # computations anyway, as the values are needed for
1244                         # things to work.  This happens when we have Perl
1245                         # extensions that depend on Unicode tables that
1246                         # wouldn't normally be in a given Unicode version.
1247
1248 # The format of the values of the tables:
1249 my $EMPTY_FORMAT = "";
1250 my $BINARY_FORMAT = 'b';
1251 my $DECIMAL_FORMAT = 'd';
1252 my $FLOAT_FORMAT = 'f';
1253 my $INTEGER_FORMAT = 'i';
1254 my $HEX_FORMAT = 'x';
1255 my $RATIONAL_FORMAT = 'r';
1256 my $STRING_FORMAT = 's';
1257 my $ADJUST_FORMAT = 'a';
1258 my $DECOMP_STRING_FORMAT = 'c';
1259 my $STRING_WHITE_SPACE_LIST = 'sw';
1260
1261 my %map_table_formats = (
1262     $BINARY_FORMAT => 'binary',
1263     $DECIMAL_FORMAT => 'single decimal digit',
1264     $FLOAT_FORMAT => 'floating point number',
1265     $INTEGER_FORMAT => 'integer',
1266     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1267     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1268     $STRING_FORMAT => 'string',
1269     $ADJUST_FORMAT => 'some entries need adjustment',
1270     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1271     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1272 );
1273
1274 # Unicode didn't put such derived files in a separate directory at first.
1275 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1276 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1277 my $AUXILIARY = 'auxiliary';
1278
1279 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1280 # and into UCD.pl for the use of UCD.pm
1281 my %loose_to_file_of;       # loosely maps table names to their respective
1282                             # files
1283 my %stricter_to_file_of;    # same; but for stricter mapping.
1284 my %loose_property_to_file_of; # Maps a loose property name to its map file
1285 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1286                             # in the hash %utf8::SwashInfo
1287 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1288                              # their rational equivalent
1289 my %loose_property_name_of; # Loosely maps (non_string) property names to
1290                             # standard form
1291 my %string_property_loose_to_name; # Same, for string properties.
1292 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1293                             # the property name in standard loose form, and
1294                             # 'value' is the default value for that property,
1295                             # also in standard loose form.
1296 my %loose_to_standard_value; # loosely maps table names to the canonical
1297                             # alias for them
1298 my %ambiguous_names;        # keys are alias names (in standard form) that
1299                             # have more than one possible meaning.
1300 my %prop_aliases;           # Keys are standard property name; values are each
1301                             # one's aliases
1302 my %prop_value_aliases;     # Keys of top level are standard property name;
1303                             # values are keys to another hash,  Each one is
1304                             # one of the property's values, in standard form.
1305                             # The values are that prop-val's aliases.
1306 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1307
1308 # Most properties are immune to caseless matching, otherwise you would get
1309 # nonsensical results, as properties are a function of a code point, not
1310 # everything that is caselessly equivalent to that code point.  For example,
1311 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1312 # be true because 's' and 'S' are equivalent caselessly.  However,
1313 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1314 # extend that concept to those very few properties that are like this.  Each
1315 # such property will match the full range caselessly.  They are hard-coded in
1316 # the program; it's not worth trying to make it general as it's extremely
1317 # unlikely that they will ever change.
1318 my %caseless_equivalent_to;
1319
1320 # These constants names and values were taken from the Unicode standard,
1321 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1322 # syllables.  The '_string' versions are so generated tables can retain the
1323 # hex format, which is the more familiar value
1324 my $SBase_string = "0xAC00";
1325 my $SBase = CORE::hex $SBase_string;
1326 my $LBase_string = "0x1100";
1327 my $LBase = CORE::hex $LBase_string;
1328 my $VBase_string = "0x1161";
1329 my $VBase = CORE::hex $VBase_string;
1330 my $TBase_string = "0x11A7";
1331 my $TBase = CORE::hex $TBase_string;
1332 my $SCount = 11172;
1333 my $LCount = 19;
1334 my $VCount = 21;
1335 my $TCount = 28;
1336 my $NCount = $VCount * $TCount;
1337
1338 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1339 # with the above published constants.
1340 my %Jamo;
1341 my %Jamo_L;     # Leading consonants
1342 my %Jamo_V;     # Vowels
1343 my %Jamo_T;     # Trailing consonants
1344
1345 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1346 # The key is the base name of the code point, and the value is an
1347 # array giving all the ranges that use this base name.  Each range
1348 # is actually a hash giving the 'low' and 'high' values of it.
1349 my %names_ending_in_code_point;
1350 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1351                                         # removed from the names
1352 # Inverse mapping.  The list of ranges that have these kinds of
1353 # names.  Each element contains the low, high, and base names in an
1354 # anonymous hash.
1355 my @code_points_ending_in_code_point;
1356
1357 # To hold Unicode's normalization test suite
1358 my @normalization_tests;
1359
1360 # Boolean: does this Unicode version have the hangul syllables, and are we
1361 # writing out a table for them?
1362 my $has_hangul_syllables = 0;
1363
1364 # Does this Unicode version have code points whose names end in their
1365 # respective code points, and are we writing out a table for them?  0 for no;
1366 # otherwise points to first property that a table is needed for them, so that
1367 # if multiple tables are needed, we don't create duplicates
1368 my $needing_code_points_ending_in_code_point = 0;
1369
1370 my @backslash_X_tests;     # List of tests read in for testing \X
1371 my @unhandled_properties;  # Will contain a list of properties found in
1372                            # the input that we didn't process.
1373 my @match_properties;      # Properties that have match tables, to be
1374                            # listed in the pod
1375 my @map_properties;        # Properties that get map files written
1376 my @named_sequences;       # NamedSequences.txt contents.
1377 my %potential_files;       # Generated list of all .txt files in the directory
1378                            # structure so we can warn if something is being
1379                            # ignored.
1380 my @files_actually_output; # List of files we generated.
1381 my @more_Names;            # Some code point names are compound; this is used
1382                            # to store the extra components of them.
1383 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1384                            # the minimum before we consider it equivalent to a
1385                            # candidate rational
1386 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1387
1388 # These store references to certain commonly used property objects
1389 my $gc;
1390 my $perl;
1391 my $block;
1392 my $perl_charname;
1393 my $print;
1394 my $Any;
1395 my $script;
1396
1397 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1398 my $has_In_conflicts = 0;
1399 my $has_Is_conflicts = 0;
1400
1401 sub internal_file_to_platform ($) {
1402     # Convert our file paths which have '/' separators to those of the
1403     # platform.
1404
1405     my $file = shift;
1406     return undef unless defined $file;
1407
1408     return File::Spec->join(split '/', $file);
1409 }
1410
1411 sub file_exists ($) {   # platform independent '-e'.  This program internally
1412                         # uses slash as a path separator.
1413     my $file = shift;
1414     return 0 if ! defined $file;
1415     return -e internal_file_to_platform($file);
1416 }
1417
1418 sub objaddr($) {
1419     # Returns the address of the blessed input object.
1420     # It doesn't check for blessedness because that would do a string eval
1421     # every call, and the program is structured so that this is never called
1422     # for a non-blessed object.
1423
1424     no overloading; # If overloaded, numifying below won't work.
1425
1426     # Numifying a ref gives its address.
1427     return pack 'J', $_[0];
1428 }
1429
1430 # These are used only if $annotate is true.
1431 # The entire range of Unicode characters is examined to populate these
1432 # after all the input has been processed.  But most can be skipped, as they
1433 # have the same descriptive phrases, such as being unassigned
1434 my @viacode;            # Contains the 1 million character names
1435 my @printable;          # boolean: And are those characters printable?
1436 my @annotate_char_type; # Contains a type of those characters, specifically
1437                         # for the purposes of annotation.
1438 my $annotate_ranges;    # A map of ranges of code points that have the same
1439                         # name for the purposes of annotation.  They map to the
1440                         # upper edge of the range, so that the end point can
1441                         # be immediately found.  This is used to skip ahead to
1442                         # the end of a range, and avoid processing each
1443                         # individual code point in it.
1444 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1445                                    # characters, but excluding those which are
1446                                    # also noncharacter code points
1447
1448 # The annotation types are an extension of the regular range types, though
1449 # some of the latter are folded into one.  Make the new types negative to
1450 # avoid conflicting with the regular types
1451 my $SURROGATE_TYPE = -1;
1452 my $UNASSIGNED_TYPE = -2;
1453 my $PRIVATE_USE_TYPE = -3;
1454 my $NONCHARACTER_TYPE = -4;
1455 my $CONTROL_TYPE = -5;
1456 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1457
1458 sub populate_char_info ($) {
1459     # Used only with the $annotate option.  Populates the arrays with the
1460     # input code point's info that are needed for outputting more detailed
1461     # comments.  If calling context wants a return, it is the end point of
1462     # any contiguous range of characters that share essentially the same info
1463
1464     my $i = shift;
1465     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1466
1467     $viacode[$i] = $perl_charname->value_of($i) || "";
1468
1469     # A character is generally printable if Unicode says it is,
1470     # but below we make sure that most Unicode general category 'C' types
1471     # aren't.
1472     $printable[$i] = $print->contains($i);
1473
1474     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1475
1476     # Only these two regular types are treated specially for annotations
1477     # purposes
1478     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1479                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1480
1481     # Give a generic name to all code points that don't have a real name.
1482     # We output ranges, if applicable, for these.  Also calculate the end
1483     # point of the range.
1484     my $end;
1485     if (! $viacode[$i]) {
1486         my $nonchar;
1487         if ($gc-> table('Private_use')->contains($i)) {
1488             $viacode[$i] = 'Private Use';
1489             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1490             $printable[$i] = 0;
1491             $end = $gc->table('Private_Use')->containing_range($i)->end;
1492         }
1493         elsif ((defined ($nonchar =
1494                             Property::property_ref('Noncharacter_Code_Point'))
1495                && $nonchar->table('Y')->contains($i)))
1496         {
1497             $viacode[$i] = 'Noncharacter';
1498             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1499             $printable[$i] = 0;
1500             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1501                                                     containing_range($i)->end;
1502         }
1503         elsif ($gc-> table('Control')->contains($i)) {
1504             $viacode[$i] = 'Control';
1505             $annotate_char_type[$i] = $CONTROL_TYPE;
1506             $printable[$i] = 0;
1507             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1508         }
1509         elsif ($gc-> table('Unassigned')->contains($i)) {
1510             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1511             $printable[$i] = 0;
1512             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1513                 $viacode[$i] = 'Unassigned';
1514                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1515             }
1516             else {
1517                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1518
1519                 # Because we name the unassigned by the blocks they are in, it
1520                 # can't go past the end of that block, and it also can't go
1521                 # past the unassigned range it is in.  The special table makes
1522                 # sure that the non-characters, which are unassigned, are
1523                 # separated out.
1524                 $end = min($block->containing_range($i)->end,
1525                            $unassigned_sans_noncharacters->
1526                                                     containing_range($i)->end);
1527             }
1528         }
1529         elsif ($v_version lt v2.0.0) {  # No surrogates in earliest releases
1530             $viacode[$i] = $gc->value_of($i);
1531             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1532             $printable[$i] = 0;
1533         }
1534         elsif ($gc-> table('Surrogate')->contains($i)) {
1535             $viacode[$i] = 'Surrogate';
1536             $annotate_char_type[$i] = $SURROGATE_TYPE;
1537             $printable[$i] = 0;
1538             $end = $gc->table('Surrogate')->containing_range($i)->end;
1539         }
1540         else {
1541             Carp::my_carp_bug("Can't figure out how to annotate "
1542                               . sprintf("U+%04X", $i)
1543                               . ".  Proceeding anyway.");
1544             $viacode[$i] = 'UNKNOWN';
1545             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1546             $printable[$i] = 0;
1547         }
1548     }
1549
1550     # Here, has a name, but if it's one in which the code point number is
1551     # appended to the name, do that.
1552     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1553         $viacode[$i] .= sprintf("-%04X", $i);
1554         $end = $perl_charname->containing_range($i)->end;
1555     }
1556
1557     # And here, has a name, but if it's a hangul syllable one, replace it with
1558     # the correct name from the Unicode algorithm
1559     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1560         use integer;
1561         my $SIndex = $i - $SBase;
1562         my $L = $LBase + $SIndex / $NCount;
1563         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1564         my $T = $TBase + $SIndex % $TCount;
1565         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1566         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1567         $end = $perl_charname->containing_range($i)->end;
1568     }
1569
1570     return if ! defined wantarray;
1571     return $i if ! defined $end;    # If not a range, return the input
1572
1573     # Save this whole range so can find the end point quickly
1574     $annotate_ranges->add_map($i, $end, $end);
1575
1576     return $end;
1577 }
1578
1579 # Commented code below should work on Perl 5.8.
1580 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1581 ## the native perl version of it (which is what would operate under miniperl)
1582 ## is extremely slow, as it does a string eval every call.
1583 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1584 #                            && defined eval "require Scalar::Util";
1585 #
1586 #sub objaddr($) {
1587 #    # Returns the address of the blessed input object.  Uses the XS version if
1588 #    # available.  It doesn't check for blessedness because that would do a
1589 #    # string eval every call, and the program is structured so that this is
1590 #    # never called for a non-blessed object.
1591 #
1592 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1593 #
1594 #    # Check at least that is a ref.
1595 #    my $pkg = ref($_[0]) or return undef;
1596 #
1597 #    # Change to a fake package to defeat any overloaded stringify
1598 #    bless $_[0], 'main::Fake';
1599 #
1600 #    # Numifying a ref gives its address.
1601 #    my $addr = pack 'J', $_[0];
1602 #
1603 #    # Return to original class
1604 #    bless $_[0], $pkg;
1605 #    return $addr;
1606 #}
1607
1608 sub max ($$) {
1609     my $a = shift;
1610     my $b = shift;
1611     return $a if $a >= $b;
1612     return $b;
1613 }
1614
1615 sub min ($$) {
1616     my $a = shift;
1617     my $b = shift;
1618     return $a if $a <= $b;
1619     return $b;
1620 }
1621
1622 sub clarify_number ($) {
1623     # This returns the input number with underscores inserted every 3 digits
1624     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1625     # checked.
1626
1627     my $number = shift;
1628     my $pos = length($number) - 3;
1629     return $number if $pos <= 1;
1630     while ($pos > 0) {
1631         substr($number, $pos, 0) = '_';
1632         $pos -= 3;
1633     }
1634     return $number;
1635 }
1636
1637
1638 package Carp;
1639
1640 # These routines give a uniform treatment of messages in this program.  They
1641 # are placed in the Carp package to cause the stack trace to not include them,
1642 # although an alternative would be to use another package and set @CARP_NOT
1643 # for it.
1644
1645 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1646
1647 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1648 # and overload trying to load Scalar:Util under miniperl.  See
1649 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1650 undef $overload::VERSION;
1651
1652 sub my_carp {
1653     my $message = shift || "";
1654     my $nofold = shift || 0;
1655
1656     if ($message) {
1657         $message = main::join_lines($message);
1658         $message =~ s/^$0: *//;     # Remove initial program name
1659         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1660         $message = "\n$0: $message;";
1661
1662         # Fold the message with program name, semi-colon end punctuation
1663         # (which looks good with the message that carp appends to it), and a
1664         # hanging indent for continuation lines.
1665         $message = main::simple_fold($message, "", 4) unless $nofold;
1666         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1667                                     # appends is to the same line
1668     }
1669
1670     return $message if defined wantarray;   # If a caller just wants the msg
1671
1672     carp $message;
1673     return;
1674 }
1675
1676 sub my_carp_bug {
1677     # This is called when it is clear that the problem is caused by a bug in
1678     # this program.
1679
1680     my $message = shift;
1681     $message =~ s/^$0: *//;
1682     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1683     carp $message;
1684     return;
1685 }
1686
1687 sub carp_too_few_args {
1688     if (@_ != 2) {
1689         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1690         return;
1691     }
1692
1693     my $args_ref = shift;
1694     my $count = shift;
1695
1696     my_carp_bug("Need at least $count arguments to "
1697         . (caller 1)[3]
1698         . ".  Instead got: '"
1699         . join ', ', @$args_ref
1700         . "'.  No action taken.");
1701     return;
1702 }
1703
1704 sub carp_extra_args {
1705     my $args_ref = shift;
1706     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1707
1708     unless (ref $args_ref) {
1709         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1710         return;
1711     }
1712     my ($package, $file, $line) = caller;
1713     my $subroutine = (caller 1)[3];
1714
1715     my $list;
1716     if (ref $args_ref eq 'HASH') {
1717         foreach my $key (keys %$args_ref) {
1718             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1719         }
1720         $list = join ', ', each %{$args_ref};
1721     }
1722     elsif (ref $args_ref eq 'ARRAY') {
1723         foreach my $arg (@$args_ref) {
1724             $arg = $UNDEF unless defined $arg;
1725         }
1726         $list = join ', ', @$args_ref;
1727     }
1728     else {
1729         my_carp_bug("Can't cope with ref "
1730                 . ref($args_ref)
1731                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1732         return;
1733     }
1734
1735     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1736     return;
1737 }
1738
1739 package main;
1740
1741 { # Closure
1742
1743     # This program uses the inside-out method for objects, as recommended in
1744     # "Perl Best Practices".  This closure aids in generating those.  There
1745     # are two routines.  setup_package() is called once per package to set
1746     # things up, and then set_access() is called for each hash representing a
1747     # field in the object.  These routines arrange for the object to be
1748     # properly destroyed when no longer used, and for standard accessor
1749     # functions to be generated.  If you need more complex accessors, just
1750     # write your own and leave those accesses out of the call to set_access().
1751     # More details below.
1752
1753     my %constructor_fields; # fields that are to be used in constructors; see
1754                             # below
1755
1756     # The values of this hash will be the package names as keys to other
1757     # hashes containing the name of each field in the package as keys, and
1758     # references to their respective hashes as values.
1759     my %package_fields;
1760
1761     sub setup_package {
1762         # Sets up the package, creating standard DESTROY and dump methods
1763         # (unless already defined).  The dump method is used in debugging by
1764         # simple_dumper().
1765         # The optional parameters are:
1766         #   a)  a reference to a hash, that gets populated by later
1767         #       set_access() calls with one of the accesses being
1768         #       'constructor'.  The caller can then refer to this, but it is
1769         #       not otherwise used by these two routines.
1770         #   b)  a reference to a callback routine to call during destruction
1771         #       of the object, before any fields are actually destroyed
1772
1773         my %args = @_;
1774         my $constructor_ref = delete $args{'Constructor_Fields'};
1775         my $destroy_callback = delete $args{'Destroy_Callback'};
1776         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1777
1778         my %fields;
1779         my $package = (caller)[0];
1780
1781         $package_fields{$package} = \%fields;
1782         $constructor_fields{$package} = $constructor_ref;
1783
1784         unless ($package->can('DESTROY')) {
1785             my $destroy_name = "${package}::DESTROY";
1786             no strict "refs";
1787
1788             # Use typeglob to give the anonymous subroutine the name we want
1789             *$destroy_name = sub {
1790                 my $self = shift;
1791                 my $addr = do { no overloading; pack 'J', $self; };
1792
1793                 $self->$destroy_callback if $destroy_callback;
1794                 foreach my $field (keys %{$package_fields{$package}}) {
1795                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1796                     delete $package_fields{$package}{$field}{$addr};
1797                 }
1798                 return;
1799             }
1800         }
1801
1802         unless ($package->can('dump')) {
1803             my $dump_name = "${package}::dump";
1804             no strict "refs";
1805             *$dump_name = sub {
1806                 my $self = shift;
1807                 return dump_inside_out($self, $package_fields{$package}, @_);
1808             }
1809         }
1810         return;
1811     }
1812
1813     sub set_access {
1814         # Arrange for the input field to be garbage collected when no longer
1815         # needed.  Also, creates standard accessor functions for the field
1816         # based on the optional parameters-- none if none of these parameters:
1817         #   'addable'    creates an 'add_NAME()' accessor function.
1818         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1819         #                function.
1820         #   'settable'   creates a 'set_NAME()' accessor function.
1821         #   'constructor' doesn't create an accessor function, but adds the
1822         #                field to the hash that was previously passed to
1823         #                setup_package();
1824         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1825         # 'add' etc. all mean 'addable'.
1826         # The read accessor function will work on both array and scalar
1827         # values.  If another accessor in the parameter list is 'a', the read
1828         # access assumes an array.  You can also force it to be array access
1829         # by specifying 'readable_array' instead of 'readable'
1830         #
1831         # A sort-of 'protected' access can be set-up by preceding the addable,
1832         # readable or settable with some initial portion of 'protected_' (but,
1833         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1834         # "protection" is only by convention.  All that happens is that the
1835         # accessor functions' names begin with an underscore.  So instead of
1836         # calling set_foo, the call is _set_foo.  (Real protection could be
1837         # accomplished by having a new subroutine, end_package, called at the
1838         # end of each package, and then storing the __LINE__ ranges and
1839         # checking them on every accessor.  But that is way overkill.)
1840
1841         # We create anonymous subroutines as the accessors and then use
1842         # typeglobs to assign them to the proper package and name
1843
1844         my $name = shift;   # Name of the field
1845         my $field = shift;  # Reference to the inside-out hash containing the
1846                             # field
1847
1848         my $package = (caller)[0];
1849
1850         if (! exists $package_fields{$package}) {
1851             croak "$0: Must call 'setup_package' before 'set_access'";
1852         }
1853
1854         # Stash the field so DESTROY can get it.
1855         $package_fields{$package}{$name} = $field;
1856
1857         # Remaining arguments are the accessors.  For each...
1858         foreach my $access (@_) {
1859             my $access = lc $access;
1860
1861             my $protected = "";
1862
1863             # Match the input as far as it goes.
1864             if ($access =~ /^(p[^_]*)_/) {
1865                 $protected = $1;
1866                 if (substr('protected_', 0, length $protected)
1867                     eq $protected)
1868                 {
1869
1870                     # Add 1 for the underscore not included in $protected
1871                     $access = substr($access, length($protected) + 1);
1872                     $protected = '_';
1873                 }
1874                 else {
1875                     $protected = "";
1876                 }
1877             }
1878
1879             if (substr('addable', 0, length $access) eq $access) {
1880                 my $subname = "${package}::${protected}add_$name";
1881                 no strict "refs";
1882
1883                 # add_ accessor.  Don't add if already there, which we
1884                 # determine using 'eq' for scalars and '==' otherwise.
1885                 *$subname = sub {
1886                     use strict "refs";
1887                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1888                     my $self = shift;
1889                     my $value = shift;
1890                     my $addr = do { no overloading; pack 'J', $self; };
1891                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1892                     if (ref $value) {
1893                         return if grep { $value == $_ } @{$field->{$addr}};
1894                     }
1895                     else {
1896                         return if grep { $value eq $_ } @{$field->{$addr}};
1897                     }
1898                     push @{$field->{$addr}}, $value;
1899                     return;
1900                 }
1901             }
1902             elsif (substr('constructor', 0, length $access) eq $access) {
1903                 if ($protected) {
1904                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1905                 }
1906                 else {
1907                     $constructor_fields{$package}{$name} = $field;
1908                 }
1909             }
1910             elsif (substr('readable_array', 0, length $access) eq $access) {
1911
1912                 # Here has read access.  If one of the other parameters for
1913                 # access is array, or this one specifies array (by being more
1914                 # than just 'readable_'), then create a subroutine that
1915                 # assumes the data is an array.  Otherwise just a scalar
1916                 my $subname = "${package}::${protected}$name";
1917                 if (grep { /^a/i } @_
1918                     or length($access) > length('readable_'))
1919                 {
1920                     no strict "refs";
1921                     *$subname = sub {
1922                         use strict "refs";
1923                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1924                         my $addr = do { no overloading; pack 'J', $_[0]; };
1925                         if (ref $field->{$addr} ne 'ARRAY') {
1926                             my $type = ref $field->{$addr};
1927                             $type = 'scalar' unless $type;
1928                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1929                             return;
1930                         }
1931                         return scalar @{$field->{$addr}} unless wantarray;
1932
1933                         # Make a copy; had problems with caller modifying the
1934                         # original otherwise
1935                         my @return = @{$field->{$addr}};
1936                         return @return;
1937                     }
1938                 }
1939                 else {
1940
1941                     # Here not an array value, a simpler function.
1942                     no strict "refs";
1943                     *$subname = sub {
1944                         use strict "refs";
1945                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1946                         no overloading;
1947                         return $field->{pack 'J', $_[0]};
1948                     }
1949                 }
1950             }
1951             elsif (substr('settable', 0, length $access) eq $access) {
1952                 my $subname = "${package}::${protected}set_$name";
1953                 no strict "refs";
1954                 *$subname = sub {
1955                     use strict "refs";
1956                     if (main::DEBUG) {
1957                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1958                         Carp::carp_extra_args(\@_) if @_ > 2;
1959                     }
1960                     # $self is $_[0]; $value is $_[1]
1961                     no overloading;
1962                     $field->{pack 'J', $_[0]} = $_[1];
1963                     return;
1964                 }
1965             }
1966             else {
1967                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1968             }
1969         }
1970         return;
1971     }
1972 }
1973
1974 package Input_file;
1975
1976 # All input files use this object, which stores various attributes about them,
1977 # and provides for convenient, uniform handling.  The run method wraps the
1978 # processing.  It handles all the bookkeeping of opening, reading, and closing
1979 # the file, returning only significant input lines.
1980 #
1981 # Each object gets a handler which processes the body of the file, and is
1982 # called by run().  Most should use the generic, default handler, which has
1983 # code scrubbed to handle things you might not expect.  A handler should
1984 # basically be a while(next_line()) {...} loop.
1985 #
1986 # You can also set up handlers to
1987 #   1) call before the first line is read for pre processing
1988 #   2) call to adjust each line of the input before the main handler gets them
1989 #   3) call upon EOF before the main handler exits its loop
1990 #   4) call at the end for post processing
1991 #
1992 # $_ is used to store the input line, and is to be filtered by the
1993 # each_line_handler()s.  So, if the format of the line is not in the desired
1994 # format for the main handler, these are used to do that adjusting.  They can
1995 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1996 # so the $_ output of one is used as the input to the next.  None of the other
1997 # handlers are stackable, but could easily be changed to be so.
1998 #
1999 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2000 # which insert the parameters as lines to be processed before the next input
2001 # file line is read.  This allows the EOF handler to flush buffers, for
2002 # example.  The difference between the two routines is that the lines inserted
2003 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2004 # called it from such a handler, you would get infinite recursion.)  Lines
2005 # inserted by insert_adjusted_lines() go directly to the main handler without
2006 # any adjustments.  If the  post-processing handler calls any of these, there
2007 # will be no effect.  Some error checking for these conditions could be added,
2008 # but it hasn't been done.
2009 #
2010 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2011 # to prevent further processing of the line.  This routine will output the
2012 # message as a warning once, and then keep a count of the lines that have the
2013 # same message, and output that count at the end of the file's processing.
2014 # This keeps the number of messages down to a manageable amount.
2015 #
2016 # get_missings() should be called to retrieve any @missing input lines.
2017 # Messages will be raised if this isn't done if the options aren't to ignore
2018 # missings.
2019
2020 sub trace { return main::trace(@_); }
2021
2022 { # Closure
2023     # Keep track of fields that are to be put into the constructor.
2024     my %constructor_fields;
2025
2026     main::setup_package(Constructor_Fields => \%constructor_fields);
2027
2028     my %file; # Input file name, required
2029     main::set_access('file', \%file, qw{ c r });
2030
2031     my %first_released; # Unicode version file was first released in, required
2032     main::set_access('first_released', \%first_released, qw{ c r });
2033
2034     my %handler;    # Subroutine to process the input file, defaults to
2035                     # 'process_generic_property_file'
2036     main::set_access('handler', \%handler, qw{ c });
2037
2038     my %property;
2039     # name of property this file is for.  defaults to none, meaning not
2040     # applicable, or is otherwise determinable, for example, from each line.
2041     main::set_access('property', \%property, qw{ c });
2042
2043     my %optional;
2044     # If this is true, the file is optional.  If not present, no warning is
2045     # output.  If it is present, the string given by this parameter is
2046     # evaluated, and if false the file is not processed.
2047     main::set_access('optional', \%optional, 'c', 'r');
2048
2049     my %non_skip;
2050     # This is used for debugging, to skip processing of all but a few input
2051     # files.  Add 'non_skip => 1' to the constructor for those files you want
2052     # processed when you set the $debug_skip global.
2053     main::set_access('non_skip', \%non_skip, 'c');
2054
2055     my %skip;
2056     # This is used to skip processing of this input file semi-permanently,
2057     # when it evaluates to true.  The value should be the reason the file is
2058     # being skipped.  It is used for files that we aren't planning to process
2059     # anytime soon, but want to allow to be in the directory and not raise a
2060     # message that we are not handling.  Mostly for test files.  This is in
2061     # contrast to the non_skip element, which is supposed to be used very
2062     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2063     # pretty much will never look at can be placed in the global
2064     # %ignored_files instead.  Ones used here will be added to %skipped files
2065     main::set_access('skip', \%skip, 'c');
2066
2067     my %each_line_handler;
2068     # list of subroutines to look at and filter each non-comment line in the
2069     # file.  defaults to none.  The subroutines are called in order, each is
2070     # to adjust $_ for the next one, and the final one adjusts it for
2071     # 'handler'
2072     main::set_access('each_line_handler', \%each_line_handler, 'c');
2073
2074     my %has_missings_defaults;
2075     # ? Are there lines in the file giving default values for code points
2076     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2077     # the norm, but IGNORED means it has such lines, but the handler doesn't
2078     # use them.  Having these three states allows us to catch changes to the
2079     # UCD that this program should track
2080     main::set_access('has_missings_defaults',
2081                                         \%has_missings_defaults, qw{ c r });
2082
2083     my %pre_handler;
2084     # Subroutine to call before doing anything else in the file.  If undef, no
2085     # such handler is called.
2086     main::set_access('pre_handler', \%pre_handler, qw{ c });
2087
2088     my %eof_handler;
2089     # Subroutine to call upon getting an EOF on the input file, but before
2090     # that is returned to the main handler.  This is to allow buffers to be
2091     # flushed.  The handler is expected to call insert_lines() or
2092     # insert_adjusted() with the buffered material
2093     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2094
2095     my %post_handler;
2096     # Subroutine to call after all the lines of the file are read in and
2097     # processed.  If undef, no such handler is called.
2098     main::set_access('post_handler', \%post_handler, qw{ c });
2099
2100     my %progress_message;
2101     # Message to print to display progress in lieu of the standard one
2102     main::set_access('progress_message', \%progress_message, qw{ c });
2103
2104     my %handle;
2105     # cache open file handle, internal.  Is undef if file hasn't been
2106     # processed at all, empty if has;
2107     main::set_access('handle', \%handle);
2108
2109     my %added_lines;
2110     # cache of lines added virtually to the file, internal
2111     main::set_access('added_lines', \%added_lines);
2112
2113     my %errors;
2114     # cache of errors found, internal
2115     main::set_access('errors', \%errors);
2116
2117     my %missings;
2118     # storage of '@missing' defaults lines
2119     main::set_access('missings', \%missings);
2120
2121     sub new {
2122         my $class = shift;
2123
2124         my $self = bless \do{ my $anonymous_scalar }, $class;
2125         my $addr = do { no overloading; pack 'J', $self; };
2126
2127         # Set defaults
2128         $handler{$addr} = \&main::process_generic_property_file;
2129         $non_skip{$addr} = 0;
2130         $skip{$addr} = 0;
2131         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2132         $handle{$addr} = undef;
2133         $added_lines{$addr} = [ ];
2134         $each_line_handler{$addr} = [ ];
2135         $errors{$addr} = { };
2136         $missings{$addr} = [ ];
2137
2138         # Two positional parameters.
2139         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2140         $file{$addr} = main::internal_file_to_platform(shift);
2141         $first_released{$addr} = shift;
2142
2143         # The rest of the arguments are key => value pairs
2144         # %constructor_fields has been set up earlier to list all possible
2145         # ones.  Either set or push, depending on how the default has been set
2146         # up just above.
2147         my %args = @_;
2148         foreach my $key (keys %args) {
2149             my $argument = $args{$key};
2150
2151             # Note that the fields are the lower case of the constructor keys
2152             my $hash = $constructor_fields{lc $key};
2153             if (! defined $hash) {
2154                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2155                 next;
2156             }
2157             if (ref $hash->{$addr} eq 'ARRAY') {
2158                 if (ref $argument eq 'ARRAY') {
2159                     foreach my $argument (@{$argument}) {
2160                         next if ! defined $argument;
2161                         push @{$hash->{$addr}}, $argument;
2162                     }
2163                 }
2164                 else {
2165                     push @{$hash->{$addr}}, $argument if defined $argument;
2166                 }
2167             }
2168             else {
2169                 $hash->{$addr} = $argument;
2170             }
2171             delete $args{$key};
2172         };
2173
2174         # If the file has a property for it, it means that the property is not
2175         # listed in the file's entries.  So add a handler to the list of line
2176         # handlers to insert the property name into the lines, to provide a
2177         # uniform interface to the final processing subroutine.
2178         # the final code doesn't have to worry about that.
2179         if ($property{$addr}) {
2180             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2181         }
2182
2183         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2184             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2185         }
2186
2187         # If skipping, set to optional, and add to list of ignored files,
2188         # including its reason
2189         if ($skip{$addr}) {
2190             $optional{$addr} = 1;
2191             $skipped_files{$file{$addr}} = $skip{$addr}
2192         }
2193
2194         return $self;
2195     }
2196
2197
2198     use overload
2199         fallback => 0,
2200         qw("") => "_operator_stringify",
2201         "." => \&main::_operator_dot,
2202         ".=" => \&main::_operator_dot_equal,
2203     ;
2204
2205     sub _operator_stringify {
2206         my $self = shift;
2207
2208         return __PACKAGE__ . " object for " . $self->file;
2209     }
2210
2211     # flag to make sure extracted files are processed early
2212     my $seen_non_extracted_non_age = 0;
2213
2214     sub run {
2215         # Process the input object $self.  This opens and closes the file and
2216         # calls all the handlers for it.  Currently,  this can only be called
2217         # once per file, as it destroy's the EOF handler
2218
2219         my $self = shift;
2220         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2221
2222         my $addr = do { no overloading; pack 'J', $self; };
2223
2224         my $file = $file{$addr};
2225
2226         # Don't process if not expecting this file (because released later
2227         # than this Unicode version), and isn't there.  This means if someone
2228         # copies it into an earlier version's directory, we will go ahead and
2229         # process it.
2230         return if $first_released{$addr} gt $v_version && ! -e $file;
2231
2232         # If in debugging mode and this file doesn't have the non-skip
2233         # flag set, and isn't one of the critical files, skip it.
2234         if ($debug_skip
2235             && $first_released{$addr} ne v0
2236             && ! $non_skip{$addr})
2237         {
2238             print "Skipping $file in debugging\n" if $verbosity;
2239             return;
2240         }
2241
2242         # File could be optional
2243         if ($optional{$addr}) {
2244             return unless -e $file;
2245             my $result = eval $optional{$addr};
2246             if (! defined $result) {
2247                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2248                 return;
2249             }
2250             if (! $result) {
2251                 if ($verbosity) {
2252                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2253                 }
2254                 return;
2255             }
2256         }
2257
2258         if (! defined $file || ! -e $file) {
2259
2260             # If the file doesn't exist, see if have internal data for it
2261             # (based on first_released being 0).
2262             if ($first_released{$addr} eq v0) {
2263                 $handle{$addr} = 'pretend_is_open';
2264             }
2265             else {
2266                 if (! $optional{$addr}  # File could be optional
2267                     && $v_version ge $first_released{$addr})
2268                 {
2269                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2270                 }
2271                 return;
2272             }
2273         }
2274         else {
2275
2276             # Here, the file exists.  Some platforms may change the case of
2277             # its name
2278             if ($seen_non_extracted_non_age) {
2279                 if ($file =~ /$EXTRACTED/i) {
2280                     Carp::my_carp_bug(main::join_lines(<<END
2281 $file should be processed just after the 'Prop...Alias' files, and before
2282 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2283 have subtle problems
2284 END
2285                     ));
2286                 }
2287             }
2288             elsif ($EXTRACTED_DIR
2289                     && $first_released{$addr} ne v0
2290                     && $file !~ /$EXTRACTED/i
2291                     && lc($file) ne 'dage.txt')
2292             {
2293                 # We don't set this (by the 'if' above) if we have no
2294                 # extracted directory, so if running on an early version,
2295                 # this test won't work.  Not worth worrying about.
2296                 $seen_non_extracted_non_age = 1;
2297             }
2298
2299             # And mark the file as having being processed, and warn if it
2300             # isn't a file we are expecting.  As we process the files,
2301             # they are deleted from the hash, so any that remain at the
2302             # end of the program are files that we didn't process.
2303             my $fkey = File::Spec->rel2abs($file);
2304             my $expecting = delete $potential_files{lc($fkey)};
2305
2306             Carp::my_carp("Was not expecting '$file'.") if
2307                     ! $expecting
2308                     && ! defined $handle{$addr};
2309
2310             # Having deleted from expected files, we can quit if not to do
2311             # anything.  Don't print progress unless really want verbosity
2312             if ($skip{$addr}) {
2313                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2314                 return;
2315             }
2316
2317             # Open the file, converting the slashes used in this program
2318             # into the proper form for the OS
2319             my $file_handle;
2320             if (not open $file_handle, "<", $file) {
2321                 Carp::my_carp("Can't open $file.  Skipping: $!");
2322                 return 0;
2323             }
2324             $handle{$addr} = $file_handle; # Cache the open file handle
2325         }
2326
2327         if ($verbosity >= $PROGRESS) {
2328             if ($progress_message{$addr}) {
2329                 print "$progress_message{$addr}\n";
2330             }
2331             else {
2332                 # If using a virtual file, say so.
2333                 print "Processing ", (-e $file)
2334                                        ? $file
2335                                        : "substitute $file",
2336                                      "\n";
2337             }
2338         }
2339
2340
2341         # Call any special handler for before the file.
2342         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2343
2344         # Then the main handler
2345         &{$handler{$addr}}($self);
2346
2347         # Then any special post-file handler.
2348         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2349
2350         # If any errors have been accumulated, output the counts (as the first
2351         # error message in each class was output when it was encountered).
2352         if ($errors{$addr}) {
2353             my $total = 0;
2354             my $types = 0;
2355             foreach my $error (keys %{$errors{$addr}}) {
2356                 $total += $errors{$addr}->{$error};
2357                 delete $errors{$addr}->{$error};
2358                 $types++;
2359             }
2360             if ($total > 1) {
2361                 my $message
2362                         = "A total of $total lines had errors in $file.  ";
2363
2364                 $message .= ($types == 1)
2365                             ? '(Only the first one was displayed.)'
2366                             : '(Only the first of each type was displayed.)';
2367                 Carp::my_carp($message);
2368             }
2369         }
2370
2371         if (@{$missings{$addr}}) {
2372             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2373         }
2374
2375         # If a real file handle, close it.
2376         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2377                                                         ref $handle{$addr};
2378         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2379                                # the file, as opposed to undef
2380         return;
2381     }
2382
2383     sub next_line {
2384         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2385         # if such a line exists.  'logical' means that any lines that have
2386         # been added via insert_lines() will be returned in $_ before the file
2387         # is read again.
2388
2389         my $self = shift;
2390         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2391
2392         my $addr = do { no overloading; pack 'J', $self; };
2393
2394         # Here the file is open (or if the handle is not a ref, is an open
2395         # 'virtual' file).  Get the next line; any inserted lines get priority
2396         # over the file itself.
2397         my $adjusted;
2398
2399         LINE:
2400         while (1) { # Loop until find non-comment, non-empty line
2401             #local $to_trace = 1 if main::DEBUG;
2402             my $inserted_ref = shift @{$added_lines{$addr}};
2403             if (defined $inserted_ref) {
2404                 ($adjusted, $_) = @{$inserted_ref};
2405                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2406                 return 1 if $adjusted;
2407             }
2408             else {
2409                 last if ! ref $handle{$addr}; # Don't read unless is real file
2410                 last if ! defined ($_ = readline $handle{$addr});
2411             }
2412             chomp;
2413             trace $_ if main::DEBUG && $to_trace;
2414
2415             # See if this line is the comment line that defines what property
2416             # value that code points that are not listed in the file should
2417             # have.  The format or existence of these lines is not guaranteed
2418             # by Unicode since they are comments, but the documentation says
2419             # that this was added for machine-readability, so probably won't
2420             # change.  This works starting in Unicode Version 5.0.  They look
2421             # like:
2422             #
2423             # @missing: 0000..10FFFF; Not_Reordered
2424             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2425             # @missing: 0000..10FFFF; ; NaN
2426             #
2427             # Save the line for a later get_missings() call.
2428             if (/$missing_defaults_prefix/) {
2429                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2430                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2431                 }
2432                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2433                     my @defaults = split /\s* ; \s*/x, $_;
2434
2435                     # The first field is the @missing, which ends in a
2436                     # semi-colon, so can safely shift.
2437                     shift @defaults;
2438
2439                     # Some of these lines may have empty field placeholders
2440                     # which get in the way.  An example is:
2441                     # @missing: 0000..10FFFF; ; NaN
2442                     # Remove them.  Process starting from the top so the
2443                     # splice doesn't affect things still to be looked at.
2444                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2445                         next if $defaults[$i] ne "";
2446                         splice @defaults, $i, 1;
2447                     }
2448
2449                     # What's left should be just the property (maybe) and the
2450                     # default.  Having only one element means it doesn't have
2451                     # the property.
2452                     my $default;
2453                     my $property;
2454                     if (@defaults >= 1) {
2455                         if (@defaults == 1) {
2456                             $default = $defaults[0];
2457                         }
2458                         else {
2459                             $property = $defaults[0];
2460                             $default = $defaults[1];
2461                         }
2462                     }
2463
2464                     if (@defaults < 1
2465                         || @defaults > 2
2466                         || ($default =~ /^</
2467                             && $default !~ /^<code *point>$/i
2468                             && $default !~ /^<none>$/i
2469                             && $default !~ /^<script>$/i))
2470                     {
2471                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2472                     }
2473                     else {
2474
2475                         # If the property is missing from the line, it should
2476                         # be the one for the whole file
2477                         $property = $property{$addr} if ! defined $property;
2478
2479                         # Change <none> to the null string, which is what it
2480                         # really means.  If the default is the code point
2481                         # itself, set it to <code point>, which is what
2482                         # Unicode uses (but sometimes they've forgotten the
2483                         # space)
2484                         if ($default =~ /^<none>$/i) {
2485                             $default = "";
2486                         }
2487                         elsif ($default =~ /^<code *point>$/i) {
2488                             $default = $CODE_POINT;
2489                         }
2490                         elsif ($default =~ /^<script>$/i) {
2491
2492                             # Special case this one.  Currently is from
2493                             # ScriptExtensions.txt, and means for all unlisted
2494                             # code points, use their Script property values.
2495                             # For the code points not listed in that file, the
2496                             # default value is 'Unknown'.
2497                             $default = "Unknown";
2498                         }
2499
2500                         # Store them as a sub-arrays with both components.
2501                         push @{$missings{$addr}}, [ $default, $property ];
2502                     }
2503                 }
2504
2505                 # There is nothing for the caller to process on this comment
2506                 # line.
2507                 next;
2508             }
2509
2510             # Remove comments and trailing space, and skip this line if the
2511             # result is empty
2512             s/#.*//;
2513             s/\s+$//;
2514             next if /^$/;
2515
2516             # Call any handlers for this line, and skip further processing of
2517             # the line if the handler sets the line to null.
2518             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2519                 &{$sub_ref}($self);
2520                 next LINE if /^$/;
2521             }
2522
2523             # Here the line is ok.  return success.
2524             return 1;
2525         } # End of looping through lines.
2526
2527         # If there is an EOF handler, call it (only once) and if it generates
2528         # more lines to process go back in the loop to handle them.
2529         if ($eof_handler{$addr}) {
2530             &{$eof_handler{$addr}}($self);
2531             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2532             goto LINE if $added_lines{$addr};
2533         }
2534
2535         # Return failure -- no more lines.
2536         return 0;
2537
2538     }
2539
2540 #   Not currently used, not fully tested.
2541 #    sub peek {
2542 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2543 #        # record.  Not callable from an each_line_handler(), nor does it call
2544 #        # an each_line_handler() on the line.
2545 #
2546 #        my $self = shift;
2547 #        my $addr = do { no overloading; pack 'J', $self; };
2548 #
2549 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2550 #            my ($adjusted, $line) = @{$inserted_ref};
2551 #            next if $adjusted;
2552 #
2553 #            # Remove comments and trailing space, and return a non-empty
2554 #            # resulting line
2555 #            $line =~ s/#.*//;
2556 #            $line =~ s/\s+$//;
2557 #            return $line if $line ne "";
2558 #        }
2559 #
2560 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2561 #        while (1) { # Loop until find non-comment, non-empty line
2562 #            local $to_trace = 1 if main::DEBUG;
2563 #            trace $_ if main::DEBUG && $to_trace;
2564 #            return if ! defined (my $line = readline $handle{$addr});
2565 #            chomp $line;
2566 #            push @{$added_lines{$addr}}, [ 0, $line ];
2567 #
2568 #            $line =~ s/#.*//;
2569 #            $line =~ s/\s+$//;
2570 #            return $line if $line ne "";
2571 #        }
2572 #
2573 #        return;
2574 #    }
2575
2576
2577     sub insert_lines {
2578         # Lines can be inserted so that it looks like they were in the input
2579         # file at the place it was when this routine is called.  See also
2580         # insert_adjusted_lines().  Lines inserted via this routine go through
2581         # any each_line_handler()
2582
2583         my $self = shift;
2584
2585         # Each inserted line is an array, with the first element being 0 to
2586         # indicate that this line hasn't been adjusted, and needs to be
2587         # processed.
2588         no overloading;
2589         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2590         return;
2591     }
2592
2593     sub insert_adjusted_lines {
2594         # Lines can be inserted so that it looks like they were in the input
2595         # file at the place it was when this routine is called.  See also
2596         # insert_lines().  Lines inserted via this routine are already fully
2597         # adjusted, ready to be processed; each_line_handler()s handlers will
2598         # not be called.  This means this is not a completely general
2599         # facility, as only the last each_line_handler on the stack should
2600         # call this.  It could be made more general, by passing to each of the
2601         # line_handlers their position on the stack, which they would pass on
2602         # to this routine, and that would replace the boolean first element in
2603         # the anonymous array pushed here, so that the next_line routine could
2604         # use that to call only those handlers whose index is after it on the
2605         # stack.  But this is overkill for what is needed now.
2606
2607         my $self = shift;
2608         trace $_[0] if main::DEBUG && $to_trace;
2609
2610         # Each inserted line is an array, with the first element being 1 to
2611         # indicate that this line has been adjusted
2612         no overloading;
2613         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2614         return;
2615     }
2616
2617     sub get_missings {
2618         # Returns the stored up @missings lines' values, and clears the list.
2619         # The values are in an array, consisting of the default in the first
2620         # element, and the property in the 2nd.  However, since these lines
2621         # can be stacked up, the return is an array of all these arrays.
2622
2623         my $self = shift;
2624         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2625
2626         my $addr = do { no overloading; pack 'J', $self; };
2627
2628         # If not accepting a list return, just return the first one.
2629         return shift @{$missings{$addr}} unless wantarray;
2630
2631         my @return = @{$missings{$addr}};
2632         undef @{$missings{$addr}};
2633         return @return;
2634     }
2635
2636     sub _insert_property_into_line {
2637         # Add a property field to $_, if this file requires it.
2638
2639         my $self = shift;
2640         my $addr = do { no overloading; pack 'J', $self; };
2641         my $property = $property{$addr};
2642         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2643
2644         $_ =~ s/(;|$)/; $property$1/;
2645         return;
2646     }
2647
2648     sub carp_bad_line {
2649         # Output consistent error messages, using either a generic one, or the
2650         # one given by the optional parameter.  To avoid gazillions of the
2651         # same message in case the syntax of a  file is way off, this routine
2652         # only outputs the first instance of each message, incrementing a
2653         # count so the totals can be output at the end of the file.
2654
2655         my $self = shift;
2656         my $message = shift;
2657         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2658
2659         my $addr = do { no overloading; pack 'J', $self; };
2660
2661         $message = 'Unexpected line' unless $message;
2662
2663         # No trailing punctuation so as to fit with our addenda.
2664         $message =~ s/[.:;,]$//;
2665
2666         # If haven't seen this exact message before, output it now.  Otherwise
2667         # increment the count of how many times it has occurred
2668         unless ($errors{$addr}->{$message}) {
2669             Carp::my_carp("$message in '$_' in "
2670                             . $file{$addr}
2671                             . " at line $..  Skipping this line;");
2672             $errors{$addr}->{$message} = 1;
2673         }
2674         else {
2675             $errors{$addr}->{$message}++;
2676         }
2677
2678         # Clear the line to prevent any further (meaningful) processing of it.
2679         $_ = "";
2680
2681         return;
2682     }
2683 } # End closure
2684
2685 package Multi_Default;
2686
2687 # Certain properties in early versions of Unicode had more than one possible
2688 # default for code points missing from the files.  In these cases, one
2689 # default applies to everything left over after all the others are applied,
2690 # and for each of the others, there is a description of which class of code
2691 # points applies to it.  This object helps implement this by storing the
2692 # defaults, and for all but that final default, an eval string that generates
2693 # the class that it applies to.
2694
2695
2696 {   # Closure
2697
2698     main::setup_package();
2699
2700     my %class_defaults;
2701     # The defaults structure for the classes
2702     main::set_access('class_defaults', \%class_defaults);
2703
2704     my %other_default;
2705     # The default that applies to everything left over.
2706     main::set_access('other_default', \%other_default, 'r');
2707
2708
2709     sub new {
2710         # The constructor is called with default => eval pairs, terminated by
2711         # the left-over default. e.g.
2712         # Multi_Default->new(
2713         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2714         #               -  0x200D',
2715         #        'R' => 'some other expression that evaluates to code points',
2716         #        .
2717         #        .
2718         #        .
2719         #        'U'));
2720
2721         my $class = shift;
2722
2723         my $self = bless \do{my $anonymous_scalar}, $class;
2724         my $addr = do { no overloading; pack 'J', $self; };
2725
2726         while (@_ > 1) {
2727             my $default = shift;
2728             my $eval = shift;
2729             $class_defaults{$addr}->{$default} = $eval;
2730         }
2731
2732         $other_default{$addr} = shift;
2733
2734         return $self;
2735     }
2736
2737     sub get_next_defaults {
2738         # Iterates and returns the next class of defaults.
2739         my $self = shift;
2740         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2741
2742         my $addr = do { no overloading; pack 'J', $self; };
2743
2744         return each %{$class_defaults{$addr}};
2745     }
2746 }
2747
2748 package Alias;
2749
2750 # An alias is one of the names that a table goes by.  This class defines them
2751 # including some attributes.  Everything is currently setup in the
2752 # constructor.
2753
2754
2755 {   # Closure
2756
2757     main::setup_package();
2758
2759     my %name;
2760     main::set_access('name', \%name, 'r');
2761
2762     my %loose_match;
2763     # Should this name match loosely or not.
2764     main::set_access('loose_match', \%loose_match, 'r');
2765
2766     my %make_re_pod_entry;
2767     # Some aliases should not get their own entries in the re section of the
2768     # pod, because they are covered by a wild-card, and some we want to
2769     # discourage use of.  Binary
2770     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
2771
2772     my %ucd;
2773     # Is this documented to be accessible via Unicode::UCD
2774     main::set_access('ucd', \%ucd, 'r', 's');
2775
2776     my %status;
2777     # Aliases have a status, like deprecated, or even suppressed (which means
2778     # they don't appear in documentation).  Enum
2779     main::set_access('status', \%status, 'r');
2780
2781     my %ok_as_filename;
2782     # Similarly, some aliases should not be considered as usable ones for
2783     # external use, such as file names, or we don't want documentation to
2784     # recommend them.  Boolean
2785     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
2786
2787     sub new {
2788         my $class = shift;
2789
2790         my $self = bless \do { my $anonymous_scalar }, $class;
2791         my $addr = do { no overloading; pack 'J', $self; };
2792
2793         $name{$addr} = shift;
2794         $loose_match{$addr} = shift;
2795         $make_re_pod_entry{$addr} = shift;
2796         $ok_as_filename{$addr} = shift;
2797         $status{$addr} = shift;
2798         $ucd{$addr} = shift;
2799
2800         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2801
2802         # Null names are never ok externally
2803         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
2804
2805         return $self;
2806     }
2807 }
2808
2809 package Range;
2810
2811 # A range is the basic unit for storing code points, and is described in the
2812 # comments at the beginning of the program.  Each range has a starting code
2813 # point; an ending code point (not less than the starting one); a value
2814 # that applies to every code point in between the two end-points, inclusive;
2815 # and an enum type that applies to the value.  The type is for the user's
2816 # convenience, and has no meaning here, except that a non-zero type is
2817 # considered to not obey the normal Unicode rules for having standard forms.
2818 #
2819 # The same structure is used for both map and match tables, even though in the
2820 # latter, the value (and hence type) is irrelevant and could be used as a
2821 # comment.  In map tables, the value is what all the code points in the range
2822 # map to.  Type 0 values have the standardized version of the value stored as
2823 # well, so as to not have to recalculate it a lot.
2824
2825 sub trace { return main::trace(@_); }
2826
2827 {   # Closure
2828
2829     main::setup_package();
2830
2831     my %start;
2832     main::set_access('start', \%start, 'r', 's');
2833
2834     my %end;
2835     main::set_access('end', \%end, 'r', 's');
2836
2837     my %value;
2838     main::set_access('value', \%value, 'r');
2839
2840     my %type;
2841     main::set_access('type', \%type, 'r');
2842
2843     my %standard_form;
2844     # The value in internal standard form.  Defined only if the type is 0.
2845     main::set_access('standard_form', \%standard_form);
2846
2847     # Note that if these fields change, the dump() method should as well
2848
2849     sub new {
2850         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2851         my $class = shift;
2852
2853         my $self = bless \do { my $anonymous_scalar }, $class;
2854         my $addr = do { no overloading; pack 'J', $self; };
2855
2856         $start{$addr} = shift;
2857         $end{$addr} = shift;
2858
2859         my %args = @_;
2860
2861         my $value = delete $args{'Value'};  # Can be 0
2862         $value = "" unless defined $value;
2863         $value{$addr} = $value;
2864
2865         $type{$addr} = delete $args{'Type'} || 0;
2866
2867         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2868
2869         if (! $type{$addr}) {
2870             $standard_form{$addr} = main::standardize($value);
2871         }
2872
2873         return $self;
2874     }
2875
2876     use overload
2877         fallback => 0,
2878         qw("") => "_operator_stringify",
2879         "." => \&main::_operator_dot,
2880         ".=" => \&main::_operator_dot_equal,
2881     ;
2882
2883     sub _operator_stringify {
2884         my $self = shift;
2885         my $addr = do { no overloading; pack 'J', $self; };
2886
2887         # Output it like '0041..0065 (value)'
2888         my $return = sprintf("%04X", $start{$addr})
2889                         .  '..'
2890                         . sprintf("%04X", $end{$addr});
2891         my $value = $value{$addr};
2892         my $type = $type{$addr};
2893         $return .= ' (';
2894         $return .= "$value";
2895         $return .= ", Type=$type" if $type != 0;
2896         $return .= ')';
2897
2898         return $return;
2899     }
2900
2901     sub standard_form {
2902         # The standard form is the value itself if the standard form is
2903         # undefined (that is if the value is special)
2904
2905         my $self = shift;
2906         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2907
2908         my $addr = do { no overloading; pack 'J', $self; };
2909
2910         return $standard_form{$addr} if defined $standard_form{$addr};
2911         return $value{$addr};
2912     }
2913
2914     sub dump {
2915         # Human, not machine readable.  For machine readable, comment out this
2916         # entire routine and let the standard one take effect.
2917         my $self = shift;
2918         my $indent = shift;
2919         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2920
2921         my $addr = do { no overloading; pack 'J', $self; };
2922
2923         my $return = $indent
2924                     . sprintf("%04X", $start{$addr})
2925                     . '..'
2926                     . sprintf("%04X", $end{$addr})
2927                     . " '$value{$addr}';";
2928         if (! defined $standard_form{$addr}) {
2929             $return .= "(type=$type{$addr})";
2930         }
2931         elsif ($standard_form{$addr} ne $value{$addr}) {
2932             $return .= "(standard '$standard_form{$addr}')";
2933         }
2934         return $return;
2935     }
2936 } # End closure
2937
2938 package _Range_List_Base;
2939
2940 # Base class for range lists.  A range list is simply an ordered list of
2941 # ranges, so that the ranges with the lowest starting numbers are first in it.
2942 #
2943 # When a new range is added that is adjacent to an existing range that has the
2944 # same value and type, it merges with it to form a larger range.
2945 #
2946 # Ranges generally do not overlap, except that there can be multiple entries
2947 # of single code point ranges.  This is because of NameAliases.txt.
2948 #
2949 # In this program, there is a standard value such that if two different
2950 # values, have the same standard value, they are considered equivalent.  This
2951 # value was chosen so that it gives correct results on Unicode data
2952
2953 # There are a number of methods to manipulate range lists, and some operators
2954 # are overloaded to handle them.
2955
2956 sub trace { return main::trace(@_); }
2957
2958 { # Closure
2959
2960     our $addr;
2961
2962     main::setup_package();
2963
2964     my %ranges;
2965     # The list of ranges
2966     main::set_access('ranges', \%ranges, 'readable_array');
2967
2968     my %max;
2969     # The highest code point in the list.  This was originally a method, but
2970     # actual measurements said it was used a lot.
2971     main::set_access('max', \%max, 'r');
2972
2973     my %each_range_iterator;
2974     # Iterator position for each_range()
2975     main::set_access('each_range_iterator', \%each_range_iterator);
2976
2977     my %owner_name_of;
2978     # Name of parent this is attached to, if any.  Solely for better error
2979     # messages.
2980     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2981
2982     my %_search_ranges_cache;
2983     # A cache of the previous result from _search_ranges(), for better
2984     # performance
2985     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2986
2987     sub new {
2988         my $class = shift;
2989         my %args = @_;
2990
2991         # Optional initialization data for the range list.
2992         my $initialize = delete $args{'Initialize'};
2993
2994         my $self;
2995
2996         # Use _union() to initialize.  _union() returns an object of this
2997         # class, which means that it will call this constructor recursively.
2998         # But it won't have this $initialize parameter so that it won't
2999         # infinitely loop on this.
3000         return _union($class, $initialize, %args) if defined $initialize;
3001
3002         $self = bless \do { my $anonymous_scalar }, $class;
3003         my $addr = do { no overloading; pack 'J', $self; };
3004
3005         # Optional parent object, only for debug info.
3006         $owner_name_of{$addr} = delete $args{'Owner'};
3007         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3008
3009         # Stringify, in case it is an object.
3010         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3011
3012         # This is used only for error messages, and so a colon is added
3013         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3014
3015         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3016
3017         # Max is initialized to a negative value that isn't adjacent to 0,
3018         # for simpler tests
3019         $max{$addr} = -2;
3020
3021         $_search_ranges_cache{$addr} = 0;
3022         $ranges{$addr} = [];
3023
3024         return $self;
3025     }
3026
3027     use overload
3028         fallback => 0,
3029         qw("") => "_operator_stringify",
3030         "." => \&main::_operator_dot,
3031         ".=" => \&main::_operator_dot_equal,
3032     ;
3033
3034     sub _operator_stringify {
3035         my $self = shift;
3036         my $addr = do { no overloading; pack 'J', $self; };
3037
3038         return "Range_List attached to '$owner_name_of{$addr}'"
3039                                                 if $owner_name_of{$addr};
3040         return "anonymous Range_List " . \$self;
3041     }
3042
3043     sub _union {
3044         # Returns the union of the input code points.  It can be called as
3045         # either a constructor or a method.  If called as a method, the result
3046         # will be a new() instance of the calling object, containing the union
3047         # of that object with the other parameter's code points;  if called as
3048         # a constructor, the first parameter gives the class that the new object
3049         # should be, and the second parameter gives the code points to go into
3050         # it.
3051         # In either case, there are two parameters looked at by this routine;
3052         # any additional parameters are passed to the new() constructor.
3053         #
3054         # The code points can come in the form of some object that contains
3055         # ranges, and has a conventionally named method to access them; or
3056         # they can be an array of individual code points (as integers); or
3057         # just a single code point.
3058         #
3059         # If they are ranges, this routine doesn't make any effort to preserve
3060         # the range values and types of one input over the other.  Therefore
3061         # this base class should not allow _union to be called from other than
3062         # initialization code, so as to prevent two tables from being added
3063         # together where the range values matter.  The general form of this
3064         # routine therefore belongs in a derived class, but it was moved here
3065         # to avoid duplication of code.  The failure to overload this in this
3066         # class keeps it safe.
3067         #
3068         # It does make the effort during initialization to accept tables with
3069         # multiple values for the same code point, and to preserve the order
3070         # of these.  If there is only one input range or range set, it doesn't
3071         # sort (as it should already be sorted to the desired order), and will
3072         # accept multiple values per code point.  Otherwise it will merge
3073         # multiple values into a single one.
3074
3075         my $self;
3076         my @args;   # Arguments to pass to the constructor
3077
3078         my $class = shift;
3079
3080         # If a method call, will start the union with the object itself, and
3081         # the class of the new object will be the same as self.
3082         if (ref $class) {
3083             $self = $class;
3084             $class = ref $self;
3085             push @args, $self;
3086         }
3087
3088         # Add the other required parameter.
3089         push @args, shift;
3090         # Rest of parameters are passed on to the constructor
3091
3092         # Accumulate all records from both lists.
3093         my @records;
3094         my $input_count = 0;
3095         for my $arg (@args) {
3096             #local $to_trace = 0 if main::DEBUG;
3097             trace "argument = $arg" if main::DEBUG && $to_trace;
3098             if (! defined $arg) {
3099                 my $message = "";
3100                 if (defined $self) {
3101                     no overloading;
3102                     $message .= $owner_name_of{pack 'J', $self};
3103                 }
3104                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3105                 return;
3106             }
3107
3108             $arg = [ $arg ] if ! ref $arg;
3109             my $type = ref $arg;
3110             if ($type eq 'ARRAY') {
3111                 foreach my $element (@$arg) {
3112                     push @records, Range->new($element, $element);
3113                     $input_count++;
3114                 }
3115             }
3116             elsif ($arg->isa('Range')) {
3117                 push @records, $arg;
3118                 $input_count++;
3119             }
3120             elsif ($arg->can('ranges')) {
3121                 push @records, $arg->ranges;
3122                 $input_count++;
3123             }
3124             else {
3125                 my $message = "";
3126                 if (defined $self) {
3127                     no overloading;
3128                     $message .= $owner_name_of{pack 'J', $self};
3129                 }
3130                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3131                 return;
3132             }
3133         }
3134
3135         # Sort with the range containing the lowest ordinal first, but if
3136         # two ranges start at the same code point, sort with the bigger range
3137         # of the two first, because it takes fewer cycles.
3138         if ($input_count > 1) {
3139             @records = sort { ($a->start <=> $b->start)
3140                                       or
3141                                     # if b is shorter than a, b->end will be
3142                                     # less than a->end, and we want to select
3143                                     # a, so want to return -1
3144                                     ($b->end <=> $a->end)
3145                                    } @records;
3146         }
3147
3148         my $new = $class->new(@_);
3149
3150         # Fold in records so long as they add new information.
3151         for my $set (@records) {
3152             my $start = $set->start;
3153             my $end   = $set->end;
3154             my $value = $set->value;
3155             my $type  = $set->type;
3156             if ($start > $new->max) {
3157                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3158             }
3159             elsif ($end > $new->max) {
3160                 $new->_add_delete('+', $new->max +1, $end, $value,
3161                                                                 Type => $type);
3162             }
3163             elsif ($input_count == 1) {
3164                 # Here, overlaps existing range, but is from a single input,
3165                 # so preserve the multiple values from that input.
3166                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3167                                                 Replace => $MULTIPLE_AFTER);
3168             }
3169         }
3170
3171         return $new;
3172     }
3173
3174     sub range_count {        # Return the number of ranges in the range list
3175         my $self = shift;
3176         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3177
3178         no overloading;
3179         return scalar @{$ranges{pack 'J', $self}};
3180     }
3181
3182     sub min {
3183         # Returns the minimum code point currently in the range list, or if
3184         # the range list is empty, 2 beyond the max possible.  This is a
3185         # method because used so rarely, that not worth saving between calls,
3186         # and having to worry about changing it as ranges are added and
3187         # deleted.
3188
3189         my $self = shift;
3190         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3191
3192         my $addr = do { no overloading; pack 'J', $self; };
3193
3194         # If the range list is empty, return a large value that isn't adjacent
3195         # to any that could be in the range list, for simpler tests
3196         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3197         return $ranges{$addr}->[0]->start;
3198     }
3199
3200     sub contains {
3201         # Boolean: Is argument in the range list?  If so returns $i such that:
3202         #   range[$i]->end < $codepoint <= range[$i+1]->end
3203         # which is one beyond what you want; this is so that the 0th range
3204         # doesn't return false
3205         my $self = shift;
3206         my $codepoint = shift;
3207         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3208
3209         my $i = $self->_search_ranges($codepoint);
3210         return 0 unless defined $i;
3211
3212         # The search returns $i, such that
3213         #   range[$i-1]->end < $codepoint <= range[$i]->end
3214         # So is in the table if and only iff it is at least the start position
3215         # of range $i.
3216         no overloading;
3217         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3218         return $i + 1;
3219     }
3220
3221     sub containing_range {
3222         # Returns the range object that contains the code point, undef if none
3223
3224         my $self = shift;
3225         my $codepoint = shift;
3226         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3227
3228         my $i = $self->contains($codepoint);
3229         return unless $i;
3230
3231         # contains() returns 1 beyond where we should look
3232         no overloading;
3233         return $ranges{pack 'J', $self}->[$i-1];
3234     }
3235
3236     sub value_of {
3237         # Returns the value associated with the code point, undef if none
3238
3239         my $self = shift;
3240         my $codepoint = shift;
3241         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3242
3243         my $range = $self->containing_range($codepoint);
3244         return unless defined $range;
3245
3246         return $range->value;
3247     }
3248
3249     sub type_of {
3250         # Returns the type of the range containing the code point, undef if
3251         # the code point is not in the table
3252
3253         my $self = shift;
3254         my $codepoint = shift;
3255         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3256
3257         my $range = $self->containing_range($codepoint);
3258         return unless defined $range;
3259
3260         return $range->type;
3261     }
3262
3263     sub _search_ranges {
3264         # Find the range in the list which contains a code point, or where it
3265         # should go if were to add it.  That is, it returns $i, such that:
3266         #   range[$i-1]->end < $codepoint <= range[$i]->end
3267         # Returns undef if no such $i is possible (e.g. at end of table), or
3268         # if there is an error.
3269
3270         my $self = shift;
3271         my $code_point = shift;
3272         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3273
3274         my $addr = do { no overloading; pack 'J', $self; };
3275
3276         return if $code_point > $max{$addr};
3277         my $r = $ranges{$addr};                # The current list of ranges
3278         my $range_list_size = scalar @$r;
3279         my $i;
3280
3281         use integer;        # want integer division
3282
3283         # Use the cached result as the starting guess for this one, because,
3284         # an experiment on 5.1 showed that 90% of the time the cache was the
3285         # same as the result on the next call (and 7% it was one less).
3286         $i = $_search_ranges_cache{$addr};
3287         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3288                                             # from an intervening deletion
3289         #local $to_trace = 1 if main::DEBUG;
3290         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3291         return $i if $code_point <= $r->[$i]->end
3292                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3293
3294         # Here the cache doesn't yield the correct $i.  Try adding 1.
3295         if ($i < $range_list_size - 1
3296             && $r->[$i]->end < $code_point &&
3297             $code_point <= $r->[$i+1]->end)
3298         {
3299             $i++;
3300             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3301             $_search_ranges_cache{$addr} = $i;
3302             return $i;
3303         }
3304
3305         # Here, adding 1 also didn't work.  We do a binary search to
3306         # find the correct position, starting with current $i
3307         my $lower = 0;
3308         my $upper = $range_list_size - 1;
3309         while (1) {
3310             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3311
3312             if ($code_point <= $r->[$i]->end) {
3313
3314                 # Here we have met the upper constraint.  We can quit if we
3315                 # also meet the lower one.
3316                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3317
3318                 $upper = $i;        # Still too high.
3319
3320             }
3321             else {
3322
3323                 # Here, $r[$i]->end < $code_point, so look higher up.
3324                 $lower = $i;
3325             }
3326
3327             # Split search domain in half to try again.
3328             my $temp = ($upper + $lower) / 2;
3329
3330             # No point in continuing unless $i changes for next time
3331             # in the loop.
3332             if ($temp == $i) {
3333
3334                 # We can't reach the highest element because of the averaging.
3335                 # So if one below the upper edge, force it there and try one
3336                 # more time.
3337                 if ($i == $range_list_size - 2) {
3338
3339                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3340                     $i = $range_list_size - 1;
3341
3342                     # Change $lower as well so if fails next time through,
3343                     # taking the average will yield the same $i, and we will
3344                     # quit with the error message just below.
3345                     $lower = $i;
3346                     next;
3347                 }
3348                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3349                 return;
3350             }
3351             $i = $temp;
3352         } # End of while loop
3353
3354         if (main::DEBUG && $to_trace) {
3355             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3356             trace "i=  [ $i ]", $r->[$i];
3357             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3358         }
3359
3360         # Here we have found the offset.  Cache it as a starting point for the
3361         # next call.
3362         $_search_ranges_cache{$addr} = $i;
3363         return $i;
3364     }
3365
3366     sub _add_delete {
3367         # Add, replace or delete ranges to or from a list.  The $type
3368         # parameter gives which:
3369         #   '+' => insert or replace a range, returning a list of any changed
3370         #          ranges.
3371         #   '-' => delete a range, returning a list of any deleted ranges.
3372         #
3373         # The next three parameters give respectively the start, end, and
3374         # value associated with the range.  'value' should be null unless the
3375         # operation is '+';
3376         #
3377         # The range list is kept sorted so that the range with the lowest
3378         # starting position is first in the list, and generally, adjacent
3379         # ranges with the same values are merged into a single larger one (see
3380         # exceptions below).
3381         #
3382         # There are more parameters; all are key => value pairs:
3383         #   Type    gives the type of the value.  It is only valid for '+'.
3384         #           All ranges have types; if this parameter is omitted, 0 is
3385         #           assumed.  Ranges with type 0 are assumed to obey the
3386         #           Unicode rules for casing, etc; ranges with other types are
3387         #           not.  Otherwise, the type is arbitrary, for the caller's
3388         #           convenience, and looked at only by this routine to keep
3389         #           adjacent ranges of different types from being merged into
3390         #           a single larger range, and when Replace =>
3391         #           $IF_NOT_EQUIVALENT is specified (see just below).
3392         #   Replace  determines what to do if the range list already contains
3393         #            ranges which coincide with all or portions of the input
3394         #            range.  It is only valid for '+':
3395         #       => $NO            means that the new value is not to replace
3396         #                         any existing ones, but any empty gaps of the
3397         #                         range list coinciding with the input range
3398         #                         will be filled in with the new value.
3399         #       => $UNCONDITIONALLY  means to replace the existing values with
3400         #                         this one unconditionally.  However, if the
3401         #                         new and old values are identical, the
3402         #                         replacement is skipped to save cycles
3403         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3404         #          (the default)  with this one if they are not equivalent.
3405         #                         Ranges are equivalent if their types are the
3406         #                         same, and they are the same string; or if
3407         #                         both are type 0 ranges, if their Unicode
3408         #                         standard forms are identical.  In this last
3409         #                         case, the routine chooses the more "modern"
3410         #                         one to use.  This is because some of the
3411         #                         older files are formatted with values that
3412         #                         are, for example, ALL CAPs, whereas the
3413         #                         derived files have a more modern style,
3414         #                         which looks better.  By looking for this
3415         #                         style when the pre-existing and replacement
3416         #                         standard forms are the same, we can move to
3417         #                         the modern style
3418         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3419         #                         existing one, but has a different value,
3420         #                         don't replace the existing one, but insert
3421         #                         this, one so that the same range can occur
3422         #                         multiple times.  They are stored LIFO, so
3423         #                         that the final one inserted is the first one
3424         #                         returned in an ordered search of the table.
3425         #                         If this is an exact duplicate, including the
3426         #                         value, the original will be moved to be
3427         #                         first, before any other duplicate ranges
3428         #                         with different values.
3429         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3430         #                         FIFO, so that this one is inserted after all
3431         #                         others that currently exist.  If this is an
3432         #                         exact duplicate, including value, of an
3433         #                         existing range, this one is discarded
3434         #                         (leaving the existing one in its original,
3435         #                         higher priority position
3436         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3437         #
3438         # "same value" means identical for non-type-0 ranges, and it means
3439         # having the same standard forms for type-0 ranges.
3440
3441         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3442
3443         my $self = shift;
3444         my $operation = shift;   # '+' for add/replace; '-' for delete;
3445         my $start = shift;
3446         my $end   = shift;
3447         my $value = shift;
3448
3449         my %args = @_;
3450
3451         $value = "" if not defined $value;        # warning: $value can be "0"
3452
3453         my $replace = delete $args{'Replace'};
3454         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3455
3456         my $type = delete $args{'Type'};
3457         $type = 0 unless defined $type;
3458
3459         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3460
3461         my $addr = do { no overloading; pack 'J', $self; };
3462
3463         if ($operation ne '+' && $operation ne '-') {
3464             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3465             return;
3466         }
3467         unless (defined $start && defined $end) {
3468             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3469             return;
3470         }
3471         unless ($end >= $start) {
3472             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3473             return;
3474         }
3475         if ($end > $MAX_UNICODE_CODEPOINT && $operation eq '+') {
3476             Carp::my_carp("$owner_name_of{$addr}Warning: Range '" . sprintf("%04X..%04X", $start, $end) . ") is above the Unicode maximum of " . sprintf("%04X", $MAX_UNICODE_CODEPOINT) . ".  Adding it anyway");
3477         }
3478         #local $to_trace = 1 if main::DEBUG;
3479
3480         if ($operation eq '-') {
3481             if ($replace != $IF_NOT_EQUIVALENT) {
3482                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3483                 $replace = $IF_NOT_EQUIVALENT;
3484             }
3485             if ($type) {
3486                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3487                 $type = 0;
3488             }
3489             if ($value ne "") {
3490                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3491                 $value = "";
3492             }
3493         }
3494
3495         my $r = $ranges{$addr};               # The current list of ranges
3496         my $range_list_size = scalar @$r;     # And its size
3497         my $max = $max{$addr};                # The current high code point in
3498                                               # the list of ranges
3499
3500         # Do a special case requiring fewer machine cycles when the new range
3501         # starts after the current highest point.  The Unicode input data is
3502         # structured so this is common.
3503         if ($start > $max) {
3504
3505             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3506             return if $operation eq '-'; # Deleting a non-existing range is a
3507                                          # no-op
3508
3509             # If the new range doesn't logically extend the current final one
3510             # in the range list, create a new range at the end of the range
3511             # list.  (max cleverly is initialized to a negative number not
3512             # adjacent to 0 if the range list is empty, so even adding a range
3513             # to an empty range list starting at 0 will have this 'if'
3514             # succeed.)
3515             if ($start > $max + 1        # non-adjacent means can't extend.
3516                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3517                 || @{$r}[-1]->type != $type # types differ, can't extend.
3518             ) {
3519                 push @$r, Range->new($start, $end,
3520                                      Value => $value,
3521                                      Type => $type);
3522             }
3523             else {
3524
3525                 # Here, the new range starts just after the current highest in
3526                 # the range list, and they have the same type and value.
3527                 # Extend the current range to incorporate the new one.
3528                 @{$r}[-1]->set_end($end);
3529             }
3530
3531             # This becomes the new maximum.
3532             $max{$addr} = $end;
3533
3534             return;
3535         }
3536         #local $to_trace = 0 if main::DEBUG;
3537
3538         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3539
3540         # Here, the input range isn't after the whole rest of the range list.
3541         # Most likely 'splice' will be needed.  The rest of the routine finds
3542         # the needed splice parameters, and if necessary, does the splice.
3543         # First, find the offset parameter needed by the splice function for
3544         # the input range.  Note that the input range may span multiple
3545         # existing ones, but we'll worry about that later.  For now, just find
3546         # the beginning.  If the input range is to be inserted starting in a
3547         # position not currently in the range list, it must (obviously) come
3548         # just after the range below it, and just before the range above it.
3549         # Slightly less obviously, it will occupy the position currently
3550         # occupied by the range that is to come after it.  More formally, we
3551         # are looking for the position, $i, in the array of ranges, such that:
3552         #
3553         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3554         #
3555         # (The ordered relationships within existing ranges are also shown in
3556         # the equation above).  However, if the start of the input range is
3557         # within an existing range, the splice offset should point to that
3558         # existing range's position in the list; that is $i satisfies a
3559         # somewhat different equation, namely:
3560         #
3561         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3562         #
3563         # More briefly, $start can come before or after r[$i]->start, and at
3564         # this point, we don't know which it will be.  However, these
3565         # two equations share these constraints:
3566         #
3567         #   r[$i-1]->end < $start <= r[$i]->end
3568         #
3569         # And that is good enough to find $i.
3570
3571         my $i = $self->_search_ranges($start);
3572         if (! defined $i) {
3573             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3574             return;
3575         }
3576
3577         # The search function returns $i such that:
3578         #
3579         # r[$i-1]->end < $start <= r[$i]->end
3580         #
3581         # That means that $i points to the first range in the range list
3582         # that could possibly be affected by this operation.  We still don't
3583         # know if the start of the input range is within r[$i], or if it
3584         # points to empty space between r[$i-1] and r[$i].
3585         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3586
3587         # Special case the insertion of data that is not to replace any
3588         # existing data.
3589         if ($replace == $NO) {  # If $NO, has to be operation '+'
3590             #local $to_trace = 1 if main::DEBUG;
3591             trace "Doesn't replace" if main::DEBUG && $to_trace;
3592
3593             # Here, the new range is to take effect only on those code points
3594             # that aren't already in an existing range.  This can be done by
3595             # looking through the existing range list and finding the gaps in
3596             # the ranges that this new range affects, and then calling this
3597             # function recursively on each of those gaps, leaving untouched
3598             # anything already in the list.  Gather up a list of the changed
3599             # gaps first so that changes to the internal state as new ranges
3600             # are added won't be a problem.
3601             my @gap_list;
3602
3603             # First, if the starting point of the input range is outside an
3604             # existing one, there is a gap from there to the beginning of the
3605             # existing range -- add a span to fill the part that this new
3606             # range occupies
3607             if ($start < $r->[$i]->start) {
3608                 push @gap_list, Range->new($start,
3609                                            main::min($end,
3610                                                      $r->[$i]->start - 1),
3611                                            Type => $type);
3612                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3613             }
3614
3615             # Then look through the range list for other gaps until we reach
3616             # the highest range affected by the input one.
3617             my $j;
3618             for ($j = $i+1; $j < $range_list_size; $j++) {
3619                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3620                 last if $end < $r->[$j]->start;
3621
3622                 # If there is a gap between when this range starts and the
3623                 # previous one ends, add a span to fill it.  Note that just
3624                 # because there are two ranges doesn't mean there is a
3625                 # non-zero gap between them.  It could be that they have
3626                 # different values or types
3627                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3628                     push @gap_list,
3629                         Range->new($r->[$j-1]->end + 1,
3630                                    $r->[$j]->start - 1,
3631                                    Type => $type);
3632                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3633                 }
3634             }
3635
3636             # Here, we have either found an existing range in the range list,
3637             # beyond the area affected by the input one, or we fell off the
3638             # end of the loop because the input range affects the whole rest
3639             # of the range list.  In either case, $j is 1 higher than the
3640             # highest affected range.  If $j == $i, it means that there are no
3641             # affected ranges, that the entire insertion is in the gap between
3642             # r[$i-1], and r[$i], which we already have taken care of before
3643             # the loop.
3644             # On the other hand, if there are affected ranges, it might be
3645             # that there is a gap that needs filling after the final such
3646             # range to the end of the input range
3647             if ($r->[$j-1]->end < $end) {
3648                     push @gap_list, Range->new(main::max($start,
3649                                                          $r->[$j-1]->end + 1),
3650                                                $end,
3651                                                Type => $type);
3652                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3653             }
3654
3655             # Call recursively to fill in all the gaps.
3656             foreach my $gap (@gap_list) {
3657                 $self->_add_delete($operation,
3658                                    $gap->start,
3659                                    $gap->end,
3660                                    $value,
3661                                    Type => $type);
3662             }
3663
3664             return;
3665         }
3666
3667         # Here, we have taken care of the case where $replace is $NO.
3668         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3669         # If inserting a multiple record, this is where it goes, before the
3670         # first (if any) existing one if inserting LIFO.  (If this is to go
3671         # afterwards, FIFO, we below move the pointer to there.)  These imply
3672         # an insertion, and no change to any existing ranges.  Note that $i
3673         # can be -1 if this new range doesn't actually duplicate any existing,
3674         # and comes at the beginning of the list.
3675         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3676
3677             if ($start != $end) {
3678                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3679                 return;
3680             }
3681
3682             # If the new code point is within a current range ...
3683             if ($end >= $r->[$i]->start) {
3684
3685                 # Don't add an exact duplicate, as it isn't really a multiple
3686                 my $existing_value = $r->[$i]->value;
3687                 my $existing_type = $r->[$i]->type;
3688                 return if $value eq $existing_value && $type eq $existing_type;
3689
3690                 # If the multiple value is part of an existing range, we want
3691                 # to split up that range, so that only the single code point
3692                 # is affected.  To do this, we first call ourselves
3693                 # recursively to delete that code point from the table, having
3694                 # preserved its current data above.  Then we call ourselves
3695                 # recursively again to add the new multiple, which we know by
3696                 # the test just above is different than the current code
3697                 # point's value, so it will become a range containing a single
3698                 # code point: just itself.  Finally, we add back in the
3699                 # pre-existing code point, which will again be a single code
3700                 # point range.  Because 'i' likely will have changed as a
3701                 # result of these operations, we can't just continue on, but
3702                 # do this operation recursively as well.  If we are inserting
3703                 # LIFO, the pre-existing code point needs to go after the new
3704                 # one, so use MULTIPLE_AFTER; and vice versa.
3705                 if ($r->[$i]->start != $r->[$i]->end) {
3706                     $self->_add_delete('-', $start, $end, "");
3707                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3708                     return $self->_add_delete('+',
3709                             $start, $end,
3710                             $existing_value,
3711                             Type => $existing_type,
3712                             Replace => ($replace == $MULTIPLE_BEFORE)
3713                                        ? $MULTIPLE_AFTER
3714                                        : $MULTIPLE_BEFORE);
3715                 }
3716             }
3717
3718             # If to place this new record after, move to beyond all existing
3719             # ones; but don't add this one if identical to any of them, as it
3720             # isn't really a multiple.  This leaves the original order, so
3721             # that the current request is ignored.  The reasoning is that the
3722             # previous request that wanted this record to have high priority
3723             # should have precedence.
3724             if ($replace == $MULTIPLE_AFTER) {
3725                 while ($i < @$r && $r->[$i]->start == $start) {
3726                     return if $value eq $r->[$i]->value
3727                               && $type eq $r->[$i]->type;
3728                     $i++;
3729                 }
3730             }
3731             else {
3732                 # If instead we are to place this new record before any
3733                 # existing ones, remove any identical ones that come after it.
3734                 # This changes the existing order so that the new one is
3735                 # first, as is being requested.
3736                 for (my $j = $i + 1;
3737                      $j < @$r && $r->[$j]->start == $start;
3738                      $j++)
3739                 {
3740                     if ($value eq $r->[$j]->value && $type eq $r->[$j]->type) {
3741                         splice @$r, $j, 1;
3742                         last;   # There should only be one instance, so no
3743                                 # need to keep looking
3744                     }
3745                 }
3746             }
3747
3748             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3749             my @return = splice @$r,
3750                                 $i,
3751                                 0,
3752                                 Range->new($start,
3753                                            $end,
3754                                            Value => $value,
3755                                            Type => $type);
3756             if (main::DEBUG && $to_trace) {
3757                 trace "After splice:";
3758                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3759                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3760                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3761                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3762                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3763                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3764             }
3765             return @return;
3766         }
3767
3768         # Here, we have taken care of $NO and $MULTIPLE_foo replaces.  This
3769         # leaves delete, insert, and replace either unconditionally or if not
3770         # equivalent.  $i still points to the first potential affected range.
3771         # Now find the highest range affected, which will determine the length
3772         # parameter to splice.  (The input range can span multiple existing
3773         # ones.)  If this isn't a deletion, while we are looking through the
3774         # range list, see also if this is a replacement rather than a clean
3775         # insertion; that is if it will change the values of at least one
3776         # existing range.  Start off assuming it is an insert, until find it
3777         # isn't.
3778         my $clean_insert = $operation eq '+';
3779         my $j;        # This will point to the highest affected range
3780
3781         # For non-zero types, the standard form is the value itself;
3782         my $standard_form = ($type) ? $value : main::standardize($value);
3783
3784         for ($j = $i; $j < $range_list_size; $j++) {
3785             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3786
3787             # If find a range that it doesn't overlap into, we can stop
3788             # searching
3789             last if $end < $r->[$j]->start;
3790
3791             # Here, overlaps the range at $j.  If the values don't match,
3792             # and so far we think this is a clean insertion, it becomes a
3793             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3794             if ($clean_insert) {
3795                 if ($r->[$j]->standard_form ne $standard_form) {
3796                     $clean_insert = 0;
3797                     if ($replace == $CROAK) {
3798                         main::croak("The range to add "
3799                         . sprintf("%04X", $start)
3800                         . '-'
3801                         . sprintf("%04X", $end)
3802                         . " with value '$value' overlaps an existing range $r->[$j]");
3803                     }
3804                 }
3805                 else {
3806
3807                     # Here, the two values are essentially the same.  If the
3808                     # two are actually identical, replacing wouldn't change
3809                     # anything so skip it.
3810                     my $pre_existing = $r->[$j]->value;
3811                     if ($pre_existing ne $value) {
3812
3813                         # Here the new and old standardized values are the
3814                         # same, but the non-standardized values aren't.  If
3815                         # replacing unconditionally, then replace
3816                         if( $replace == $UNCONDITIONALLY) {
3817                             $clean_insert = 0;
3818                         }
3819                         else {
3820
3821                             # Here, are replacing conditionally.  Decide to
3822                             # replace or not based on which appears to look
3823                             # the "nicest".  If one is mixed case and the
3824                             # other isn't, choose the mixed case one.
3825                             my $new_mixed = $value =~ /[A-Z]/
3826                                             && $value =~ /[a-z]/;
3827                             my $old_mixed = $pre_existing =~ /[A-Z]/
3828                                             && $pre_existing =~ /[a-z]/;
3829
3830                             if ($old_mixed != $new_mixed) {
3831                                 $clean_insert = 0 if $new_mixed;
3832                                 if (main::DEBUG && $to_trace) {
3833                                     if ($clean_insert) {
3834                                         trace "Retaining $pre_existing over $value";
3835                                     }
3836                                     else {
3837                                         trace "Replacing $pre_existing with $value";
3838                                     }
3839                                 }
3840                             }
3841                             else {
3842
3843                                 # Here casing wasn't different between the two.
3844                                 # If one has hyphens or underscores and the
3845                                 # other doesn't, choose the one with the
3846                                 # punctuation.
3847                                 my $new_punct = $value =~ /[-_]/;
3848                                 my $old_punct = $pre_existing =~ /[-_]/;
3849
3850                                 if ($old_punct != $new_punct) {
3851                                     $clean_insert = 0 if $new_punct;
3852                                     if (main::DEBUG && $to_trace) {
3853                                         if ($clean_insert) {
3854                                             trace "Retaining $pre_existing over $value";
3855                                         }
3856                                         else {
3857                                             trace "Replacing $pre_existing with $value";
3858                                         }
3859                                     }
3860                                 }   # else existing one is just as "good";
3861                                     # retain it to save cycles.
3862                             }
3863                         }
3864                     }
3865                 }
3866             }
3867         } # End of loop looking for highest affected range.
3868
3869         # Here, $j points to one beyond the highest range that this insertion
3870         # affects (hence to beyond the range list if that range is the final
3871         # one in the range list).
3872
3873         # The splice length is all the affected ranges.  Get it before
3874         # subtracting, for efficiency, so we don't have to later add 1.
3875         my $length = $j - $i;
3876
3877         $j--;        # $j now points to the highest affected range.
3878         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3879
3880         # Here, have taken care of $NO and $MULTIPLE_foo replaces.
3881         # $j points to the highest affected range.  But it can be < $i or even
3882         # -1.  These happen only if the insertion is entirely in the gap
3883         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3884         # above exited first time through with $end < $r->[$i]->start.  (And
3885         # then we subtracted one from j)  This implies also that $start <
3886         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3887         # $start, so the entire input range is in the gap.
3888         if ($j < $i) {
3889
3890             # Here the entire input range is in the gap before $i.
3891
3892             if (main::DEBUG && $to_trace) {
3893                 if ($i) {
3894                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3895                 }
3896                 else {
3897                     trace "Entire range is before $r->[$i]";
3898                 }
3899             }
3900             return if $operation ne '+'; # Deletion of a non-existent range is
3901                                          # a no-op
3902         }
3903         else {
3904
3905             # Here part of the input range is not in the gap before $i.  Thus,
3906             # there is at least one affected one, and $j points to the highest
3907             # such one.
3908
3909             # At this point, here is the situation:
3910             # This is not an insertion of a multiple, nor of tentative ($NO)
3911             # data.
3912             #   $i  points to the first element in the current range list that
3913             #            may be affected by this operation.  In fact, we know
3914             #            that the range at $i is affected because we are in
3915             #            the else branch of this 'if'
3916             #   $j  points to the highest affected range.
3917             # In other words,
3918             #   r[$i-1]->end < $start <= r[$i]->end
3919             # And:
3920             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3921             #
3922             # Also:
3923             #   $clean_insert is a boolean which is set true if and only if
3924             #        this is a "clean insertion", i.e., not a change nor a
3925             #        deletion (multiple was handled above).
3926
3927             # We now have enough information to decide if this call is a no-op
3928             # or not.  It is a no-op if this is an insertion of already
3929             # existing data.
3930
3931             if (main::DEBUG && $to_trace && $clean_insert
3932                                          && $i == $j
3933                                          && $start >= $r->[$i]->start)
3934             {
3935                     trace "no-op";
3936             }
3937             return if $clean_insert
3938                       && $i == $j # more than one affected range => not no-op
3939
3940                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3941                       # Further, $start and/or $end is >= r[$i]->start
3942                       # The test below hence guarantees that
3943                       #     r[$i]->start < $start <= $end <= r[$i]->end
3944                       # This means the input range is contained entirely in
3945                       # the one at $i, so is a no-op
3946                       && $start >= $r->[$i]->start;
3947         }
3948
3949         # Here, we know that some action will have to be taken.  We have
3950         # calculated the offset and length (though adjustments may be needed)
3951         # for the splice.  Now start constructing the replacement list.
3952         my @replacement;
3953         my $splice_start = $i;
3954
3955         my $extends_below;
3956         my $extends_above;