This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Document $DynaLoader::dl_dlext, per sisyphus++.
[perl5.git] / ext / DynaLoader / DynaLoader_pm.PL
1 use Config;
2
3 sub to_string {
4     my ($value) = @_;
5     $value =~ s/\\/\\\\/g;
6     $value =~ s/'/\\'/g;
7     return "'$value'";
8 }
9
10 #
11 # subroutine expand_os_specific expands $^O-specific preprocessing information
12 # so that it will not be re-calculated at runtime in Dynaloader.pm
13 #
14 # Syntax of preprocessor should be kept extremely simple:
15 #  - directives are in double angle brackets <<...>>
16 #  - <<=string>> will be just evaluated
17 #  - for $^O-specific there are two forms:
18 #   <<$^O-eq-osname>>
19 #   <<$^O-ne-osname>>
20 #  this directive should be closed with respectively
21 #   <</$^O-eq-osname>>
22 #   <</$^O-ne-osname>>
23 #  construct <<|$^O-ne-osname>> means #else
24 #  nested <<$^O...>>-constructs are allowed but nested values must be for 
25 #   different OS-names!
26 #   
27 #  -- added by VKON, 03-10-2004 to separate $^O-specific between OSes
28 #     (so that Win32 never checks for $^O eq 'VMS' for example)
29 #
30 # The $^O tests test both for $^O and for $Config{osname}.
31 # The latter is better for some for cross-compilation setups.
32 #
33 sub expand_os_specific {
34     my $s = shift;
35     for ($s) {
36         s/<<=(.*?)>>/$1/gee;
37         s/<<\$\^O-(eq|ne)-(\w+)>>(.*?)<<\/\$\^O-\1-\2>>/
38           my ($op, $os, $expr) = ($1,$2,$3);
39           if ($op ne 'eq' and $op ne 'ne') {die "wrong eq-ne arg in $&"};
40           if ($expr =~ m[^(.*?)<<\|\$\^O-$op-$os>>(.*?)$]s) {
41               # #if;#else;#endif
42               my ($if,$el) = ($1,$2);
43               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
44                   $if
45               }
46               else {
47                   $el
48               }
49           }
50           else {
51               # #if;#endif
52               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
53                   $expr
54               }
55               else {
56                   ""
57               }
58           }
59         /ges;
60         if (/<<(=|\$\^O-)/) {die "bad <<\$^O-eq/ne-osname>> expression.".
61             " Unclosed brackets?";
62         }
63     }
64     $s;
65 }
66
67 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
68 open OUT, ">DynaLoader.pm" or die $!;
69 print OUT <<'EOT';
70
71 # Generated from DynaLoader_pm.PL
72
73 package DynaLoader;
74
75 #   And Gandalf said: 'Many folk like to know beforehand what is to
76 #   be set on the table; but those who have laboured to prepare the
77 #   feast like to keep their secret; for wonder makes the words of
78 #   praise louder.'
79
80 #   (Quote from Tolkien suggested by Anno Siegel.)
81 #
82 # See pod text at end of file for documentation.
83 # See also ext/DynaLoader/README in source tree for other information.
84 #
85 # Tim.Bunce@ig.co.uk, August 1994
86
87 BEGIN {
88     $VERSION = '1.19';
89 }
90
91 use Config;
92
93 # enable debug/trace messages from DynaLoader perl code
94 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
95
96 #
97 # Flags to alter dl_load_file behaviour.  Assigned bits:
98 #   0x01  make symbols available for linking later dl_load_file's.
99 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
100 #         (ignored under VMS; effect is built-in to image linking)
101 #
102 # This is called as a class method $module->dl_load_flags.  The
103 # definition here will be inherited and result on "default" loading
104 # behaviour unless a sub-class of DynaLoader defines its own version.
105 #
106
107 sub dl_load_flags { 0x00 }
108
109 EOT
110
111 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
112     print OUT "(\$dl_dlext, \$dl_so, \$dlsrc) = (",
113               to_string($Config{'dlext'}), ",",
114               to_string($Config{'so'}), ",",
115               to_string($Config{'dlsrc'}), ")\n;" ;
116 }
117 else {
118     print OUT <<'EOT';
119 ($dl_dlext, $dl_so, $dlsrc) = @Config::Config{qw(dlext so dlsrc)};
120 EOT
121 }
122
123 print OUT expand_os_specific(<<'EOT');
124
125 <<$^O-eq-VMS>>
126 # Some systems need special handling to expand file specifications
127 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
128 # See dl_expandspec() for more details. Should be harmless but
129 # inefficient to define on systems that don't need it.
130 $Is_VMS    = $^O eq 'VMS';
131 <</$^O-eq-VMS>>
132 $do_expand = <<$^O-eq-VMS>>1<<|$^O-eq-VMS>>0<</$^O-eq-VMS>>;
133
134 @dl_require_symbols = ();       # names of symbols we need
135 @dl_resolve_using   = ();       # names of files to link with
136 @dl_library_path    = ();       # path to look for files
137
138 #XSLoader.pm may have added elements before we were required
139 #@dl_shared_objects  = ();       # shared objects for symbols we have 
140 #@dl_librefs         = ();       # things we have loaded
141 #@dl_modules         = ();       # Modules we have loaded
142
143 # This is a fix to support DLD's unfortunate desire to relink -lc
144 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
145
146 EOT
147
148 my $cfg_dl_library_path = <<'EOT';
149 push(@dl_library_path, split(' ', $Config::Config{libpth}));
150 EOT
151
152 sub dquoted_comma_list {
153     join(", ", map {'"'.quotemeta($_).'"'} @_);
154 }
155
156 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
157     eval $cfg_dl_library_path;
158     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
159         my $dl_library_path = dquoted_comma_list(@dl_library_path);
160         print OUT <<EOT;
161 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
162
163 \@dl_library_path = ($dl_library_path);
164
165 EOT
166     }
167 }
168 else {
169     print OUT <<EOT;
170 # Initialise \@dl_library_path with the 'standard' library path
171 # for this platform as determined by Configure.
172
173 $cfg_dl_library_path
174
175 EOT
176 }
177
178 my $ldlibpthname;
179 my $ldlibpthname_defined;
180 my $pthsep;
181
182 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
183     $ldlibpthname         = to_string($Config::Config{ldlibpthname});
184     $ldlibpthname_defined = to_string(defined $Config::Config{ldlibpthname} ? 1 : 0);
185     $pthsep               = to_string($Config::Config{path_sep});
186 }
187 else {
188     $ldlibpthname         = q($Config::Config{ldlibpthname});
189     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
190     $pthsep               = q($Config::Config{path_sep});
191 }
192 print OUT <<EOT;
193 my \$ldlibpthname         = $ldlibpthname;
194 my \$ldlibpthname_defined = $ldlibpthname_defined;
195 my \$pthsep               = $pthsep;
196
197 EOT
198
199 my $env_dl_library_path = <<'EOT';
200 if ($ldlibpthname_defined &&
201     exists $ENV{$ldlibpthname}) {
202     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
203 }
204
205 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
206
207 if ($ldlibpthname_defined &&
208     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
209     exists $ENV{LD_LIBRARY_PATH}) {
210     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
211 }
212 EOT
213
214 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
215     eval $env_dl_library_path;
216 }
217 else {
218     print OUT <<EOT;
219 # Add to \@dl_library_path any extra directories we can gather from environment
220 # during runtime.
221
222 $env_dl_library_path
223
224 EOT
225 }
226
227 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
228     my $dl_library_path = dquoted_comma_list(@dl_library_path);
229     print OUT <<EOT;
230 # The below \@dl_library_path has been expanded (%Config, %ENV)
231 # in Perl build time.
232
233 \@dl_library_path = ($dl_library_path);
234
235 EOT
236 }
237
238
239 # following long string contains $^O-specific stuff, which is factored out
240 print OUT expand_os_specific(<<'EOT');
241 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
242 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
243 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
244                                 !defined(&dl_error);
245
246 if ($dl_debug) {
247     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
248     print STDERR "DynaLoader not linked into this perl\n"
249             unless defined(&boot_DynaLoader);
250 }
251
252 1; # End of main code
253
254
255 sub croak   { require Carp; Carp::croak(@_)   }
256
257 sub bootstrap_inherit {
258     my $module = $_[0];
259     local *isa = *{"$module\::ISA"};
260     local @isa = (@isa, 'DynaLoader');
261     # Cannot goto due to delocalization.  Will report errors on a wrong line?
262     bootstrap(@_);
263 }
264
265 sub bootstrap {
266     # use local vars to enable $module.bs script to edit values
267     local(@args) = @_;
268     local($module) = $args[0];
269     local(@dirs, $file);
270
271     unless ($module) {
272         require Carp;
273         Carp::confess("Usage: DynaLoader::bootstrap(module)");
274     }
275
276     # A common error on platforms which don't support dynamic loading.
277     # Since it's fatal and potentially confusing we give a detailed message.
278     croak("Can't load module $module, dynamic loading not available in this perl.\n".
279         "  (You may need to build a new perl executable which either supports\n".
280         "  dynamic loading or has the $module module statically linked into it.)\n")
281         unless defined(&dl_load_file);
282
283
284     <<$^O-eq-os2>>
285     # Can dynaload, but cannot dynaload Perl modules...
286     die 'Dynaloaded Perl modules are not available in this build of Perl' if $OS2::is_static;
287
288     <</$^O-eq-os2>>
289     my @modparts = split(/::/,$module);
290     my $modfname = $modparts[-1];
291
292     # Some systems have restrictions on files names for DLL's etc.
293     # mod2fname returns appropriate file base name (typically truncated)
294     # It may also edit @modparts if required.
295     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
296
297     <<$^O-eq-NetWare>>
298     # Truncate the module name to 8.3 format for NetWare
299         if ((length($modfname) > 8)) {
300                 $modfname = substr($modfname, 0, 8);
301         }
302     <</$^O-eq-NetWare>>
303
304     my $modpname = join('/',@modparts);
305
306     print STDERR "DynaLoader::bootstrap for $module ",
307                        "(auto/$modpname/$modfname.$dl_dlext)\n"
308         if $dl_debug;
309
310     foreach (@INC) {
311         <<$^O-eq-VMS>>chop($_ = VMS::Filespec::unixpath($_));<</$^O-eq-VMS>>
312             my $dir = "$_/auto/$modpname";
313         
314         next unless -d $dir; # skip over uninteresting directories
315         
316         # check for common cases to avoid autoload of dl_findfile
317         my $try = "$dir/$modfname.$dl_dlext";
318         last if $file = ($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
319         
320         # no luck here, save dir for possible later dl_findfile search
321         push @dirs, $dir;
322     }
323     # last resort, let dl_findfile have a go in all known locations
324     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
325
326     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
327         unless $file;   # wording similar to error from 'require'
328
329     <<$^O-eq-VMS>>$file = uc($file) if $Config::Config{d_vms_case_sensitive_symbols};<</$^O-eq-VMS>>
330     my $bootname = "boot_$module";
331     $bootname =~ s/\W/_/g;
332     @dl_require_symbols = ($bootname);
333
334     # Execute optional '.bootstrap' perl script for this module.
335     # The .bs file can be used to configure @dl_resolve_using etc to
336     # match the needs of the individual module on this architecture.
337     my $bs = $file;
338     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
339     if (-s $bs) { # only read file if it's not empty
340         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
341         eval { do $bs; };
342         warn "$bs: $@\n" if $@;
343     }
344
345     my $boot_symbol_ref;
346
347     <<$^O-eq-darwin>>
348     if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
349         goto boot; #extension library has already been loaded, e.g. darwin
350     }
351     <</$^O-eq-darwin>>
352
353     # Many dynamic extension loading problems will appear to come from
354     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
355     # Often these errors are actually occurring in the initialisation
356     # C code of the extension XS file. Perl reports the error as being
357     # in this perl code simply because this was the last perl code
358     # it executed.
359
360     my $libref = dl_load_file($file, $module->dl_load_flags) or
361         croak("Can't load '$file' for module $module: ".dl_error());
362
363     push(@dl_librefs,$libref);  # record loaded object
364
365     my @unresolved = dl_undef_symbols();
366     if (@unresolved) {
367         require Carp;
368         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
369     }
370
371     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
372          croak("Can't find '$bootname' symbol in $file\n");
373
374     push(@dl_modules, $module); # record loaded module
375
376   boot:
377     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
378
379     # See comment block above
380
381         push(@dl_shared_objects, $file); # record files loaded
382
383     &$xs(@args);
384 }
385
386 sub dl_findfile {
387     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
388     # This function does not automatically consider the architecture
389     # or the perl library auto directories.
390     my (@args) = @_;
391     my (@dirs,  $dir);   # which directories to search
392     my (@found);         # full paths to real files we have found
393     #my $dl_ext= <<=to_string($Config::Config{'dlext'})>>; # $Config::Config{'dlext'} suffix for perl extensions
394     #my $dl_so = <<=to_string($Config::Config{'so'})>>; # $Config::Config{'so'} suffix for shared libraries
395
396     print STDERR "dl_findfile(@args)\n" if $dl_debug;
397
398     # accumulate directories but process files as they appear
399     arg: foreach(@args) {
400         #  Special fast case: full filepath requires no search
401         <<$^O-eq-VMS>>
402         if (m%[:>/\]]% && -f $_) {
403             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
404             last arg unless wantarray;
405             next;
406         }
407         <</$^O-eq-VMS>>
408         <<$^O-ne-VMS>>
409         if (m:/: && -f $_) {
410             push(@found,$_);
411             last arg unless wantarray;
412             next;
413         }
414         <</$^O-ne-VMS>>
415
416         # Deal with directories first:
417         #  Using a -L prefix is the preferred option (faster and more robust)
418         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
419
420         #  Otherwise we try to try to spot directories by a heuristic
421         #  (this is a more complicated issue than it first appears)
422         if (m:/: && -d $_) {   push(@dirs, $_); next; }
423
424         <<$^O-eq-VMS>>
425         # VMS: we may be using native VMS directory syntax instead of
426         # Unix emulation, so check this as well
427         if (/[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
428         <</$^O-eq-VMS>>
429
430         #  Only files should get this far...
431         my(@names, $name);    # what filenames to look for
432         if (m:-l: ) {          # convert -lname to appropriate library name
433             s/-l//;
434             push(@names,"lib$_.$dl_so");
435             push(@names,"lib$_.a");
436         } else {                # Umm, a bare name. Try various alternatives:
437             # these should be ordered with the most likely first
438             push(@names,"$_.$dl_dlext")    unless m/\.$dl_dlext$/o;
439             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
440             <<$^O-eq-cygwin>>
441             push(@names,"cyg$_.$dl_so")  unless m:/:;
442             <</$^O-eq-cygwin>>
443             push(@names,"lib$_.$dl_so")  unless m:/:;
444             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
445             push(@names, $_);
446         }
447         my $dirsep = '/';
448         <<$^O-eq-symbian>>
449         $dirsep = '\\';
450         if ($0 =~ /^([a-z]):/i) {
451             my $drive = $1;
452             @dirs = map { "$drive:$_" } @dirs;
453             @dl_library_path = map { "$drive:$_" } @dl_library_path;
454         }
455         <</$^O-eq-symbian>>
456         foreach $dir (@dirs, @dl_library_path) {
457             next unless -d $dir;
458             <<$^O-eq-VMS>>
459             chop($dir = VMS::Filespec::unixpath($dir));
460             <</$^O-eq-VMS>>
461             foreach $name (@names) {
462                 my($file) = "$dir$dirsep$name";
463                 print STDERR " checking in $dir for $name\n" if $dl_debug;
464                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
465                 #$file = _check_file($file);
466                 if ($file) {
467                     push(@found, $file);
468                     next arg; # no need to look any further
469                 }
470             }
471         }
472     }
473     if ($dl_debug) {
474         foreach(@dirs) {
475             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
476         }
477         print STDERR "dl_findfile found: @found\n";
478     }
479     return $found[0] unless wantarray;
480     @found;
481 }
482
483
484 <<$^O-eq-VMS>>
485 # dl_expandspec should be defined in dl_vms.xs
486 <<|$^O-eq-VMS>>
487 sub dl_expandspec {
488     my($spec) = @_;
489     # Optional function invoked if DynaLoader.pm sets $do_expand.
490     # Most systems do not require or use this function.
491     # Some systems may implement it in the dl_*.xs file in which case
492     # this Perl version should be excluded at build time.
493
494     # This function is designed to deal with systems which treat some
495     # 'filenames' in a special way. For example VMS 'Logical Names'
496     # (something like unix environment variables - but different).
497     # This function should recognise such names and expand them into
498     # full file paths.
499     # Must return undef if $spec is invalid or file does not exist.
500
501     my $file = $spec; # default output to input
502
503         return undef unless -f $file;
504     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
505     $file;
506 }
507 <</$^O-eq-VMS>>
508
509 sub dl_find_symbol_anywhere
510 {
511     my $sym = shift;
512     my $libref;
513     foreach $libref (@dl_librefs) {
514         my $symref = dl_find_symbol($libref,$sym);
515         return $symref if $symref;
516     }
517     return undef;
518 }
519
520 __END__
521
522 =head1 NAME
523
524 DynaLoader - Dynamically load C libraries into Perl code
525
526 =head1 SYNOPSIS
527
528     package YourPackage;
529     require DynaLoader;
530     @ISA = qw(... DynaLoader ...);
531     bootstrap YourPackage;
532
533     # optional method for 'global' loading
534     sub dl_load_flags { 0x01 }     
535
536
537 =head1 DESCRIPTION
538
539 This document defines a standard generic interface to the dynamic
540 linking mechanisms available on many platforms.  Its primary purpose is
541 to implement automatic dynamic loading of Perl modules.
542
543 This document serves as both a specification for anyone wishing to
544 implement the DynaLoader for a new platform and as a guide for
545 anyone wishing to use the DynaLoader directly in an application.
546
547 The DynaLoader is designed to be a very simple high-level
548 interface that is sufficiently general to cover the requirements
549 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
550
551 It is also hoped that the interface will cover the needs of OS/2, NT
552 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
553
554 It must be stressed that the DynaLoader, by itself, is practically
555 useless for accessing non-Perl libraries because it provides almost no
556 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
557 library function or supplying arguments.  A C::DynaLib module
558 is available from CPAN sites which performs that function for some
559 common system types.  And since the year 2000, there's also Inline::C,
560 a module that allows you to write Perl subroutines in C.  Also available
561 from your local CPAN site.
562
563 DynaLoader Interface Summary
564
565   @dl_library_path
566   @dl_resolve_using
567   @dl_require_symbols
568   $dl_debug
569   @dl_librefs
570   @dl_modules
571   @dl_shared_objects
572                                                   Implemented in:
573   bootstrap($modulename)                               Perl
574   @filepaths = dl_findfile(@names)                     Perl
575   $flags = $modulename->dl_load_flags                  Perl
576   $symref  = dl_find_symbol_anywhere($symbol)          Perl
577
578   $libref  = dl_load_file($filename, $flags)           C
579   $status  = dl_unload_file($libref)                   C
580   $symref  = dl_find_symbol($libref, $symbol)          C
581   @symbols = dl_undef_symbols()                        C
582   dl_install_xsub($name, $symref [, $filename])        C
583   $message = dl_error                                  C
584
585 =over 4
586
587 =item @dl_library_path
588
589 The standard/default list of directories in which dl_findfile() will
590 search for libraries etc.  Directories are searched in order:
591 $dl_library_path[0], [1], ... etc
592
593 @dl_library_path is initialised to hold the list of 'normal' directories
594 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
595 ensure portability across a wide range of platforms.
596
597 @dl_library_path should also be initialised with any other directories
598 that can be determined from the environment at runtime (such as
599 LD_LIBRARY_PATH for SunOS).
600
601 After initialisation @dl_library_path can be manipulated by an
602 application using push and unshift before calling dl_findfile().
603 Unshift can be used to add directories to the front of the search order
604 either to save search time or to override libraries with the same name
605 in the 'normal' directories.
606
607 The load function that dl_load_file() calls may require an absolute
608 pathname.  The dl_findfile() function and @dl_library_path can be
609 used to search for and return the absolute pathname for the
610 library/object that you wish to load.
611
612 =item @dl_resolve_using
613
614 A list of additional libraries or other shared objects which can be
615 used to resolve any undefined symbols that might be generated by a
616 later call to load_file().
617
618 This is only required on some platforms which do not handle dependent
619 libraries automatically.  For example the Socket Perl extension
620 library (F<auto/Socket/Socket.so>) contains references to many socket
621 functions which need to be resolved when it's loaded.  Most platforms
622 will automatically know where to find the 'dependent' library (e.g.,
623 F</usr/lib/libsocket.so>).  A few platforms need to be told the
624 location of the dependent library explicitly.  Use @dl_resolve_using
625 for this.
626
627 Example usage:
628
629     @dl_resolve_using = dl_findfile('-lsocket');
630
631 =item @dl_require_symbols
632
633 A list of one or more symbol names that are in the library/object file
634 to be dynamically loaded.  This is only required on some platforms.
635
636 =item @dl_librefs
637
638 An array of the handles returned by successful calls to dl_load_file(),
639 made by bootstrap, in the order in which they were loaded.
640 Can be used with dl_find_symbol() to look for a symbol in any of
641 the loaded files.
642
643 =item @dl_modules
644
645 An array of module (package) names that have been bootstrap'ed.
646
647 =item @dl_shared_objects
648
649 An array of file names for the shared objects that were loaded.
650
651 =item dl_error()
652
653 Syntax:
654
655     $message = dl_error();
656
657 Error message text from the last failed DynaLoader function.  Note
658 that, similar to errno in unix, a successful function call does not
659 reset this message.
660
661 Implementations should detect the error as soon as it occurs in any of
662 the other functions and save the corresponding message for later
663 retrieval.  This will avoid problems on some platforms (such as SunOS)
664 where the error message is very temporary (e.g., dlerror()).
665
666 =item $dl_debug
667
668 Internal debugging messages are enabled when $dl_debug is set true.
669 Currently setting $dl_debug only affects the Perl side of the
670 DynaLoader.  These messages should help an application developer to
671 resolve any DynaLoader usage problems.
672
673 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
674
675 For the DynaLoader developer/porter there is a similar debugging
676 variable added to the C code (see dlutils.c) and enabled if Perl was
677 built with the B<-DDEBUGGING> flag.  This can also be set via the
678 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
679 higher for more.
680
681 =item $dl_dlext
682
683 When specified (localised) in a module's F<.pm> file, indicates the extension
684 which the module's loadable object will have. For example:
685
686     local $DynaLoader::dl_dlext = 'unusual_ext';
687
688 would indicate that the module's loadable object has an extension of
689 C<unusual_ext> instead of the more usual C<$Config{dlext}>.  NOTE: This also
690 requires that the module's F<Makefile.PL> specify (in C<WriteMakefile()>):
691
692     DLEXT => 'unusual_ext',
693
694 =item dl_findfile()
695
696 Syntax:
697
698     @filepaths = dl_findfile(@names)
699
700 Determine the full paths (including file suffix) of one or more
701 loadable files given their generic names and optionally one or more
702 directories.  Searches directories in @dl_library_path by default and
703 returns an empty list if no files were found.
704
705 Names can be specified in a variety of platform independent forms.  Any
706 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
707 an appropriate suffix for the platform.
708
709 If a name does not already have a suitable prefix and/or suffix then
710 the corresponding file will be searched for by trying combinations of
711 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
712 and "$name".
713
714 If any directories are included in @names they are searched before
715 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
716 names are treated as filenames to be searched for.
717
718 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
719
720 Example: 
721
722     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
723
724
725 =item dl_expandspec()
726
727 Syntax:
728
729     $filepath = dl_expandspec($spec)
730
731 Some unusual systems, such as VMS, require special filename handling in
732 order to deal with symbolic names for files (i.e., VMS's Logical Names).
733
734 To support these systems a dl_expandspec() function can be implemented
735 either in the F<dl_*.xs> file or code can be added to the dl_expandspec()
736 function in F<DynaLoader.pm>.  See F<DynaLoader_pm.PL> for more information.
737
738 =item dl_load_file()
739
740 Syntax:
741
742     $libref = dl_load_file($filename, $flags)
743
744 Dynamically load $filename, which must be the path to a shared object
745 or library.  An opaque 'library reference' is returned as a handle for
746 the loaded object.  Returns undef on error.
747
748 The $flags argument to alters dl_load_file behaviour.  
749 Assigned bits:
750
751  0x01  make symbols available for linking later dl_load_file's.
752        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
753        (ignored under VMS; this is a normal part of image linking)
754
755 (On systems that provide a handle for the loaded object such as SunOS
756 and HPUX, $libref will be that handle.  On other systems $libref will
757 typically be $filename or a pointer to a buffer containing $filename.
758 The application should not examine or alter $libref in any way.)
759
760 This is the function that does the real work.  It should use the
761 current values of @dl_require_symbols and @dl_resolve_using if required.
762
763     SunOS: dlopen($filename)
764     HP-UX: shl_load($filename)
765     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
766     NeXT:  rld_load($filename, @dl_resolve_using)
767     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
768
769 (The dlopen() function is also used by Solaris and some versions of
770 Linux, and is a common choice when providing a "wrapper" on other
771 mechanisms as is done in the OS/2 port.)
772
773 =item dl_unload_file()
774
775 Syntax:
776
777     $status = dl_unload_file($libref)
778
779 Dynamically unload $libref, which must be an opaque 'library reference' as
780 returned from dl_load_file.  Returns one on success and zero on failure.
781
782 This function is optional and may not necessarily be provided on all platforms.
783 If it is defined, it is called automatically when the interpreter exits for
784 every shared object or library loaded by DynaLoader::bootstrap.  All such
785 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
786 loads the libraries.  The files are unloaded in last-in, first-out order.
787
788 This unloading is usually necessary when embedding a shared-object perl (e.g.
789 one configured with -Duseshrplib) within a larger application, and the perl
790 interpreter is created and destroyed several times within the lifetime of the
791 application.  In this case it is possible that the system dynamic linker will
792 unload and then subsequently reload the shared libperl without relocating any
793 references to it from any files DynaLoaded by the previous incarnation of the
794 interpreter.  As a result, any shared objects opened by DynaLoader may point to
795 a now invalid 'ghost' of the libperl shared object, causing apparently random
796 memory corruption and crashes.  This behaviour is most commonly seen when using
797 Apache and mod_perl built with the APXS mechanism.
798
799     SunOS: dlclose($libref)
800     HP-UX: ???
801     Linux: ???
802     NeXT:  ???
803     VMS:   ???
804
805 (The dlclose() function is also used by Solaris and some versions of
806 Linux, and is a common choice when providing a "wrapper" on other
807 mechanisms as is done in the OS/2 port.)
808
809 =item dl_load_flags()
810
811 Syntax:
812
813     $flags = dl_load_flags $modulename;
814
815 Designed to be a method call, and to be overridden by a derived class
816 (i.e. a class which has DynaLoader in its @ISA).  The definition in
817 DynaLoader itself returns 0, which produces standard behavior from
818 dl_load_file().
819
820 =item dl_find_symbol()
821
822 Syntax:
823
824     $symref = dl_find_symbol($libref, $symbol)
825
826 Return the address of the symbol $symbol or C<undef> if not found.  If the
827 target system has separate functions to search for symbols of different
828 types then dl_find_symbol() should search for function symbols first and
829 then other types.
830
831 The exact manner in which the address is returned in $symref is not
832 currently defined.  The only initial requirement is that $symref can
833 be passed to, and understood by, dl_install_xsub().
834
835     SunOS: dlsym($libref, $symbol)
836     HP-UX: shl_findsym($libref, $symbol)
837     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
838     NeXT:  rld_lookup("_$symbol")
839     VMS:   lib$find_image_symbol($libref,$symbol)
840
841
842 =item dl_find_symbol_anywhere()
843
844 Syntax:
845
846     $symref = dl_find_symbol_anywhere($symbol)
847
848 Applies dl_find_symbol() to the members of @dl_librefs and returns
849 the first match found.
850
851 =item dl_undef_symbols()
852
853 Example
854
855     @symbols = dl_undef_symbols()
856
857 Return a list of symbol names which remain undefined after load_file().
858 Returns C<()> if not known.  Don't worry if your platform does not provide
859 a mechanism for this.  Most do not need it and hence do not provide it,
860 they just return an empty list.
861
862
863 =item dl_install_xsub()
864
865 Syntax:
866
867     dl_install_xsub($perl_name, $symref [, $filename])
868
869 Create a new Perl external subroutine named $perl_name using $symref as
870 a pointer to the function which implements the routine.  This is simply
871 a direct call to newXSUB().  Returns a reference to the installed
872 function.
873
874 The $filename parameter is used by Perl to identify the source file for
875 the function if required by die(), caller() or the debugger.  If
876 $filename is not defined then "DynaLoader" will be used.
877
878
879 =item bootstrap()
880
881 Syntax:
882
883 bootstrap($module [...])
884
885 This is the normal entry point for automatic dynamic loading in Perl.
886
887 It performs the following actions:
888
889 =over 8
890
891 =item *
892
893 locates an auto/$module directory by searching @INC
894
895 =item *
896
897 uses dl_findfile() to determine the filename to load
898
899 =item *
900
901 sets @dl_require_symbols to C<("boot_$module")>
902
903 =item *
904
905 executes an F<auto/$module/$module.bs> file if it exists
906 (typically used to add to @dl_resolve_using any files which
907 are required to load the module on the current platform)
908
909 =item *
910
911 calls dl_load_flags() to determine how to load the file.
912
913 =item *
914
915 calls dl_load_file() to load the file
916
917 =item *
918
919 calls dl_undef_symbols() and warns if any symbols are undefined
920
921 =item *
922
923 calls dl_find_symbol() for "boot_$module"
924
925 =item *
926
927 calls dl_install_xsub() to install it as "${module}::bootstrap"
928
929 =item *
930
931 calls &{"${module}::bootstrap"} to bootstrap the module (actually
932 it uses the function reference returned by dl_install_xsub for speed)
933
934 =back
935
936 All arguments to bootstrap() are passed to the module's bootstrap function.
937 The default code generated by F<xsubpp> expects $module [, $version]
938 If the optional $version argument is not given, it defaults to
939 C<$XS_VERSION // $VERSION> in the module's symbol table. The default code
940 compares the Perl-space version with the version of the compiled XS code,
941 and croaks with an error if they do not match.
942
943 =back
944
945
946 =head1 AUTHOR
947
948 Tim Bunce, 11 August 1994.
949
950 This interface is based on the work and comments of (in no particular
951 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
952 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
953
954 Larry Wall designed the elegant inherited bootstrap mechanism and
955 implemented the first Perl 5 dynamic loader using it.
956
957 Solaris global loading added by Nick Ing-Simmons with design/coding
958 assistance from Tim Bunce, January 1996.
959
960 =cut
961 EOT
962
963 close OUT or die $!;
964