installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '../lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
  12     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
  13     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
  14 use vars qw /$depth/;
  15
  16 BEGIN {
  17     $Is_VMS = $^O eq 'VMS';
  18     $Is_W32 = $^O eq 'MSWin32';
  19     $Is_OS2 = $^O eq 'os2';
  20     $Is_Cygwin = $^O eq 'cygwin';
  21     $Is_Darwin = $^O eq 'darwin';
  22     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  23 }
  24
  25 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  26
  27 use File::Find;
  28 use File::Compare;
  29 use File::Copy ();
  30 use File::Path ();
  31 use ExtUtils::Packlist;
  32 use Config;
  33 use subs qw(unlink link chmod);
  34
  35 if ($Config{d_umask}) {
  36     umask(022); # umasks like 077 aren't that useful for installations
  37 }
  38
  39 $Is_NetWare = $Config{osname} eq 'NetWare';
  40 if ($Is_NetWare) {
  41     $Is_W32 = 0;
  42     $scr_ext = '.pl';
  43 }
  44
  45 # override the ones in the rest of the script
  46 sub mkpath {
  47     File::Path::mkpath(@_) unless $nonono;
  48 }
  49
  50 my $mainperldir = "/usr/bin";
  51 my $exe_ext = $Config{exe_ext};
  52
  53 # Allow ``make install PERLNAME=something_besides_perl'':
  54 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  55
  56 # This is the base used for versioned names, like "perl5.6.0".
  57 # It's separate because a common use of $PERLNAME is to install
  58 # perl as "perl5", if that's used as base for versioned files you
  59 # get "perl55.6.0".
  60 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  61                     ? $ENV{PERLNAME_VERBASE}
  62                     : $perl;
  63 my $dbg = '';
  64 my $ndbg = '';
  65 if ( $Is_VMS ) {
  66     if ( defined $Config{usevmsdebug} ) {
  67         if ( $Config{usevmsdebug} eq 'define' ) {
  68             $dbg = 'dbg';
  69             $ndbg = 'ndbg';
  70         }
  71     }
  72 }
  73
  74 $otherperls = 1;
  75 my $destdir = '';
  76 while (@ARGV) {
  77     $nonono = 1 if $ARGV[0] eq '-n';
  78     $dostrip = 1 if $ARGV[0] eq '-s';
  79     $versiononly = 1 if $ARGV[0] eq '-v';
  80     $versiononly = 0 if $ARGV[0] eq '+v';
  81     $silent = 1 if $ARGV[0] eq '-S';
  82     $otherperls = 0 if $ARGV[0] eq '-o';
  83     $force = 1 if $ARGV[0] eq '-f';
  84     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  85     $archname = 1 if $ARGV[0] eq '-A';
  86     $nwinstall = 1 if $ARGV[0] eq '-netware';
  87     $nopods = 1 if $ARGV[0] eq '-p';
  88     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
  89     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
  90         print <<"EOT";
  91 Usage $0: [switches]
  92   -n        Don't actually run any commands; just print them.
  93   -s        Run strip on installed binaries.
  94   -v        Only install perl as a binary with the version number in the name.
  95             (Override whatever config.sh says)
  96   +v        Install perl as "perl" and as a binary with the version number in
  97             the name.  (Override whatever config.sh says)
  98   -S        Silent mode.
  99   -f        Force installation (don't check if same version is there)
 100   -o        Skip checking for other copies of perl in your PATH.
 101   -V        Verbose mode.
 102   -A        Also install perl with the architecture's name in the perl binary's
 103             name.
 104   -p        Don't install the pod files. [This will break use diagnostics;]
 105   -netware  Install correctly on a Netware server.
 106   -destdir  Prefix installation directories by this string.
 107 EOT
 108         exit;
 109     }
 110     shift;
 111 }
 112
 113 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
 114 my (@scripts, @tolink);
 115 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
 116 while (<SCRIPTS>) {
 117     next if /^#/;
 118     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
 119     next if /a2p/; # a2p is binary, to be installed separately
 120     chomp;
 121     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
 122         push @scripts, $1;
 123         push @tolink, [$1, $2];
 124     } else {
 125         push @scripts, $_;
 126     }
 127 }
 128 close SCRIPTS;
 129
 130 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
 131
 132 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
 133
 134 # Specify here any .pm files that are actually architecture-dependent.
 135 # (Those included with XS extensions under ext/ are automatically
 136 # added later.)
 137 # Now that the default privlib has the full perl version number included,
 138 # we no longer have to play the trick of sticking version-specific .pm
 139 # files under the archlib directory.
 140 my %archpms = (
 141     Config => 1,
 142     lib => 1,
 143     Cwd => 1,
 144 );
 145
 146 if ($^O eq 'dos') {
 147     push(@scripts,'djgpp/fixpmain');
 148     $archpms{config} = $archpms{filehand} = 1;
 149 }
 150
 151 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
 152     push(@scripts, map("$_.exe", @scripts));
 153 }
 154
 155 find(sub {
 156     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
 157         my($path, $modname) = ($1,$2);
 158
 159         # strip trailing component first
 160         $path =~ s{/[^/]*$}{};
 161
 162         # strip optional "/lib";
 163         $path =~ s{/lib\b}{};
 164
 165         # strip any leading /
 166         $path =~ s{^/}{};
 167
 168         # reconstitute canonical module name
 169         $modname = "$path/$modname" if length $path;
 170
 171         # remember it
 172         $archpms{$modname} = 1;
 173     }
 174 }, 'ext');
 175
 176 # print "[$_]\n" for sort keys %archpms;
 177
 178 my $ver = $Config{version};
 179 my $release = substr($],0,3);   # Not used currently.
 180 my $patchlevel = substr($],3,2);
 181 die "Patchlevel of perl ($patchlevel)",
 182     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 183         if $patchlevel != $Config{'PERL_VERSION'};
 184
 185 # Fetch some frequently-used items from %Config
 186 my $installbin = "$destdir$Config{installbin}";
 187 my $installscript = "$destdir$Config{installscript}";
 188 my $installprivlib = "$destdir$Config{installprivlib}";
 189 my $installarchlib = "$destdir$Config{installarchlib}";
 190 my $installsitelib = "$destdir$Config{installsitelib}";
 191 my $installsitearch = "$destdir$Config{installsitearch}";
 192 my $installman1dir = "$destdir$Config{installman1dir}";
 193 my $man1ext = $Config{man1ext};
 194 my $libperl = $Config{libperl};
 195 # Shared library and dynamic loading suffixes.
 196 my $so = $Config{so};
 197 my $dlext = $Config{dlext};
 198 my $dlsrc = $Config{dlsrc};
 199 if ($^O eq 'os390') {
 200     my $pwd;
 201     chomp($pwd=`pwd`);
 202     my $archlibexp = $Config{archlibexp};
 203     my $usedl = $Config{usedl};
 204     if ($usedl eq 'define') {
 205         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
 206     }
 207 }
 208
 209 if ($nwinstall) {
 210     # This is required only if we are installing on a NetWare server
 211     $installscript = $Config{installnwscripts};
 212     $installprivlib = $Config{installnwlib};
 213     $installarchlib = $Config{installnwlib};
 214     $installsitelib = $Config{installnwlib};
 215 }
 216
 217 my $d_dosuid = $Config{d_dosuid};
 218 my $binexp = $Config{binexp};
 219
 220 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 221     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 222               \$installarchlib, \$installsitelib, \$installsitearch,
 223               \$installman1dir ) {
 224         $$_ = unixify($$_);  $$_ =~ s:/$::;
 225     }
 226 }
 227
 228 # Do some quick sanity checks.
 229
 230 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 231
 232    $installbin          || die "No installbin directory in config.sh\n";
 233 -d $installbin          || mkpath($installbin, $verbose, 0777);
 234 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 235 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 236         unless $installbin =~ m#^/afs/# || $nonono;
 237
 238 if (!$Is_NetWare) {
 239 if (!$Is_VMS) {
 240 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 241 }
 242 else {
 243 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
 244     if ($dbg) {
 245         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
 246     }
 247 }
 248 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 249
 250 -f 't/rantests'         || $Is_W32
 251                         || warn "WARNING: You've never run 'make test' or",
 252                                 " some tests failed! (Installing anyway.)\n";
 253 } #if (!$Is_NetWare)
 254
 255 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
 256     my $perldll;
 257
 258     if ($Is_Cygwin) {
 259         $perldll = $libperl;
 260         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
 261         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
 262         $perldll =~ s/^lib/cyg/;
 263         if ($Config{useshrplib} eq 'true') {
 264             # install ld2 and perlld as well
 265             foreach ('ld2', 'perlld') {
 266                 safe_unlink("$installbin/$_");
 267                 copy("$_", "$installbin/$_");
 268                 chmod(0755, "$installbin/$_");
 269             };
 270             open (LD2, ">$installbin/ld2");
 271             print LD2 <<SHELL;
 272 #!/bin/sh
 273 #
 274 # ld wrapper, passes all args to perlld;
 275 #
 276 for trythis in $installbin/perl
 277 do
 278   if [ -x \$trythis ]
 279   then
 280     \$trythis $installbin/perlld "\$\@"
 281     exit \$?
 282   fi
 283 done
 284 # hard luck!
 285 echo I see no perl executable around there
 286 echo perl is required to build dynamic libraries
 287 echo look if the path to perl in /bin/ld2 is correct
 288 exit 1
 289 SHELL
 290             close LD2;
 291             chmod(0755, "$installbin/ld2");
 292         };
 293     } else {
 294         $perldll = 'perl59.' . $dlext;
 295     }
 296
 297     if ($dlsrc ne "dl_none.xs") {
 298         -f $perldll || die "No perl DLL built\n";
 299     }
 300
 301     # Install the DLL
 302     safe_unlink("$installbin/$perldll");
 303     copy("$perldll", "$installbin/$perldll");
 304     chmod(0755, "$installbin/$perldll");
 305 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
 306
 307 # This will be used to store the packlist
 308 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 309
 310 # First we install the version-numbered executables.
 311
 312 if ($Is_VMS) {
 313     safe_unlink("$installbin/perl_setup.com");
 314     copy("perl_setup.com", "$installbin/perl_setup.com");
 315     chmod(0755, "$installbin/perl_setup.com");
 316     safe_unlink("$installbin/$dbg$perl$exe_ext");
 317     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
 318     chmod(0755, "$installbin/$dbg$perl$exe_ext");
 319     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
 320     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
 321     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
 322     if ($ndbg) {
 323         safe_unlink("$installbin/$ndbg$perl$exe_ext");
 324         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
 325         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
 326         safe_unlink("$installbin/${dbg}a2p$exe_ext");
 327         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
 328         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
 329     }
 330 }
 331 elsif ($^O eq 'mpeix') {
 332     # MPE lacks hard links and requires that executables with special
 333     # capabilities reside in the MPE namespace.
 334     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 335     # Install the primary executable into the MPE namespace as perlpath.
 336     copy("perl$exe_ext", $Config{perlpath});
 337     chmod(0755, $Config{perlpath});
 338     # Create a backup copy with the version number.
 339     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 340 }
 341 elsif ($^O ne 'dos') {
 342     if (!$Is_NetWare) {
 343         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 344         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 345         strip("$installbin/$perl_verbase$ver$exe_ext");
 346         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 347     }
 348     else {
 349         # If installing onto a NetWare server
 350         if ($nwinstall) {
 351             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
 352             mkpath($Config{installnwsystem}, 1, 0777);
 353             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
 354             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
 355             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
 356             copy("x2p\\a2p.nlm", $Config{installnwsystem});
 357             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
 358             mkpath($Config{installnwlcgi}, 1, 0777);
 359             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
 360         }
 361     } #if (!$Is_NetWare)
 362 }
 363 else {
 364     safe_unlink("$installbin/$perl.exe");
 365     copy("perl.exe", "$installbin/$perl.exe");
 366 }
 367
 368 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 369 if ($d_dosuid) {
 370     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 371     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 372 }
 373
 374 # Install library files.
 375
 376 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 377
 378 mkpath($installprivlib, $verbose, 0777);
 379 mkpath($installarchlib, $verbose, 0777);
 380 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 381 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 382
 383 if (chdir "lib") {
 384     $do_installarchlib = ! samepath($installarchlib, '.');
 385     $do_installprivlib = ! samepath($installprivlib, '.');
 386     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 387
 388     if ($do_installarchlib || $do_installprivlib) {
 389         find(\&installlib, '.');
 390     }
 391     chdir ".." || die "Can't cd back to source directory: $!\n";
 392 }
 393 else {
 394     warn "Can't cd to lib to install lib files: $!\n";
 395 }
 396
 397 # Install header files and libraries.
 398 mkpath("$installarchlib/CORE", $verbose, 0777);
 399 my @corefiles;
 400 if ($Is_VMS) {  # We did core file selection during build
 401     my $coredir = "lib/$Config{archname}/$ver/CORE";
 402     $coredir =~ tr/./_/;
 403     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 404 }
 405 else {
 406     # [als] hard-coded 'libperl' name... not good!
 407     @corefiles = <*.h libperl*.*>;
 408
 409     # AIX needs perl.exp installed as well.
 410     push(@corefiles,'perl.exp') if $^O eq 'aix';
 411     if ($^O eq 'mpeix') {
 412         # MPE needs mpeixish.h installed as well.
 413         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 414         push(@corefiles,'mpeix/mpeixish.h');
 415     }
 416     # If they have built sperl.o...
 417     push(@corefiles,'sperl.o') if -f 'sperl.o';
 418 }
 419 foreach my $file (@corefiles) {
 420     # HP-UX (at least) needs to maintain execute permissions
 421     # on dynamically-loadable libraries. So we do it for all.
 422     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 423         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 424             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 425             chmod(0555, "$installarchlib/CORE/$file");
 426         } else {
 427             chmod(0444, "$installarchlib/CORE/$file");
 428         }
 429     }
 430 }
 431
 432 # Install main perl executables
 433 # Make links to ordinary names if installbin directory isn't current directory.
 434
 435 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
 436     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 437     if ($^O eq 'mpeix') {
 438         # MPE doesn't support hard links, so use a symlink.
 439         # We don't want another cloned copy.
 440         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 441     } elsif ($^O eq 'vos') {
 442         # VOS doesn't support hard links, so use a symlink.
 443         symlink("$installbin/$perl_verbase$ver$exe_ext",
 444                 "$installbin/$perl$exe_ext");
 445     } else {
 446         link("$installbin/$perl_verbase$ver$exe_ext",
 447                 "$installbin/$perl$exe_ext");
 448     }
 449     link("$installbin/s$perl_verbase$ver$exe_ext",
 450             "$installbin/suid$perl$exe_ext")
 451       if $d_dosuid;
 452 }
 453
 454 # For development purposes it can be very useful to have multiple perls
 455 # build for different "architectures" (eg threading or not) simultaneously.
 456 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 457     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
 458     safe_unlink("$installbin/$archperl");
 459     if ($^O eq 'mpeix') {
 460         # MPE doesn't support hard links, so use a symlink.
 461         # We don't want another cloned copy.
 462         symlink($Config{perlpath}, "$installbin/$archperl");
 463     } elsif ($^O eq 'vos') {
 464         # VOS doesn't support hard links, so use a symlink.
 465         symlink("$installbin/$perl_verbase$ver$exe_ext",
 466                 "$installbin/$archperl");
 467     } else {
 468         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
 469     }
 470 }
 471
 472 # Offer to install perl in a "standard" location
 473
 474 my $mainperl_is_instperl = 0;
 475
 476 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 477     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
 478         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 479     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 480     my($instperl)       = "$installbin/$perl$exe_ext";
 481     my($expinstperl)    = "$binexp/$perl$exe_ext";
 482
 483     # First make sure $usrbinperl is not already the same as the perl we
 484     # just installed.
 485     if (-x $usrbinperl) {
 486         # Try to be clever about mainperl being a symbolic link
 487         # to binexp/perl if binexp and installbin are different.
 488         $mainperl_is_instperl =
 489             samepath($usrbinperl, $instperl) ||
 490             samepath($usrbinperl, $expinstperl) ||
 491              (($binexp ne $installbin) &&
 492               (-l $usrbinperl) &&
 493               ((readlink $usrbinperl) eq $expinstperl));
 494     }
 495     if (! $mainperl_is_instperl) {
 496         unlink($usrbinperl);
 497         ( $Config{'d_link'} eq 'define' &&
 498           eval { CORE::link $instperl, $usrbinperl } )  ||
 499         eval { symlink $expinstperl, $usrbinperl }      ||
 500         copy($instperl, $usrbinperl);
 501
 502         $mainperl_is_instperl = 1;
 503     }
 504 }
 505
 506 # Make links to ordinary names if installbin directory isn't current directory.
 507 if (!$Is_NetWare && $dbg eq '') {
 508     if (! samepath($installbin, 'x2p')) {
 509         my $base = 'a2p';
 510         $base .= $ver if $versiononly;
 511         safe_unlink("$installbin/$base$exe_ext");
 512         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
 513         strip("$installbin/$base$exe_ext");
 514         chmod(0755, "$installbin/$base$exe_ext");
 515     }
 516 }
 517
 518 # cppstdin is just a script, but it is architecture-dependent, so
 519 # it can't safely be shared.  Place it in $installbin.
 520 # Note that Configure doesn't build cppstin if it isn't needed, so
 521 # we skip this if cppstdin doesn't exist.
 522 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 523     safe_unlink("$installbin/cppstdin");
 524     copy("cppstdin", "$installbin/cppstdin");
 525     chmod(0755, "$installbin/cppstdin");
 526 }
 527
 528 sub script_alias {
 529     my ($installscript, $orig, $alias, $scr_ext) = @_;
 530
 531     safe_unlink("$installscript/$alias$scr_ext");
 532     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 533         copy("$installscript/$orig$scr_ext",
 534              "$installscript/$alias$scr_ext");
 535     } elsif ($^O eq 'vos') {
 536         symlink("$installscript/$orig$scr_ext",
 537                 "$installscript/$alias$scr_ext");
 538     } else {
 539         link("$installscript/$orig$scr_ext",
 540              "$installscript/$alias$scr_ext");
 541     }
 542 }
 543
 544 # Install scripts.
 545 mkpath($installscript, $verbose, 0777);
 546 if ($versiononly) {
 547     for (@scripts) {
 548         (my $base = $_) =~ s#.*/##;
 549         $base .= $ver;
 550         copy($_,    "$installscript/$base");
 551         chmod(0755, "$installscript/$base");
 552     }
 553
 554     for (@tolink) {
 555         my ($from, $to) = map { "$_$ver" } @$_;
 556         (my $frbase = $from) =~ s#.*/##;
 557         (my $tobase = $to) =~ s#.*/##;
 558         script_alias($installscript, $frbase, $tobase, $scr_ext);
 559     }
 560 } else {
 561     for (@scripts) {
 562         (my $base = $_) =~ s#.*/##;
 563         copy($_, "$installscript/$base");
 564         chmod(0755, "$installscript/$base");
 565     }
 566
 567     for (@tolink) {
 568         my ($from, $to) = @$_;
 569         (my $frbase = $from) =~ s#.*/##;
 570         (my $tobase = $to) =~ s#.*/##;
 571         script_alias($installscript, $frbase, $tobase, $scr_ext);
 572     }
 573 }
 574
 575 # Install pod pages.  Where? I guess in $installprivlib/pod
 576 # ($installprivlib/pods for cygwin).
 577
 578 my $pod = ($Is_Cygwin || $Is_Darwin) ? 'pods' : 'pod';
 579 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 580     mkpath("${installprivlib}/$pod", $verbose, 0777);
 581
 582     # If Perl 5.003's perldiag.pod is there, rename it.
 583     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 584         read POD, $_, 4000;
 585         close POD;
 586         # Some of Perl 5.003's diagnostic messages ended with periods.
 587         if (/^=.*\.$/m) {
 588             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 589                                "${installprivlib}/$pod/perldiag-5.003.pod");
 590             print "  rename $from $to";
 591             rename($from, $to)
 592                 or warn "Couldn't rename $from to $to: $!\n"
 593                 unless $nonono;
 594         }
 595     }
 596
 597     for (@pods) {
 598         # $_ is a name like  pod/perl.pod
 599         (my $base = $_) =~ s#.*/##;
 600         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 601     }
 602
 603 }
 604
 605 # Check to make sure there aren't other perls around in installer's
 606 # path.  This is probably UNIX-specific.  Check all absolute directories
 607 # in the path except for where public executables are supposed to live.
 608 # Also skip $mainperl if the user opted to have it be a link to the
 609 # installed perl.
 610
 611 if (!$versiononly && $otherperls) {
 612     my ($path, @path);
 613     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
 614     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 615     @path = split(/$dirsep/, $path);
 616     if ($Is_VMS) {
 617         my $i = 0;
 618         while (exists $ENV{'DCL$PATH' . $i}) {
 619             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 620             push(@path,$dir);
 621         }
 622     }
 623     my @otherperls;
 624     my %otherperls;
 625     for (@path) {
 626         next unless m,^/,;
 627         # Use &samepath here because some systems have other dirs linked
 628         # to $mainperldir (like SunOS)
 629         next if samepath($_, $binexp);
 630         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 631         my $otherperl = "$_/$perl$exe_ext";
 632         next if $otherperls{$otherperl}++;
 633         push(@otherperls, $otherperl)
 634             if (-x $otherperl && ! -d $otherperl);
 635     }
 636     if (@otherperls) {
 637         warn "\nWarning: $perl appears in your path in the following " .
 638             "locations beyond where\nwe just installed it:\n";
 639         for (@otherperls) {
 640             warn "    ", $_, "\n";
 641         }
 642         warn "\n";
 643     }
 644
 645 }
 646
 647 $packlist->write() unless $nonono;
 648 print "  Installation complete\n" if $verbose;
 649
 650 exit 0;
 651
 652 ###############################################################################
 653
 654 sub yn {
 655     my($prompt) = @_;
 656     my($answer);
 657     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 658     print STDERR $prompt;
 659     chop($answer = <STDIN>);
 660     $answer = $default if $answer =~ m/^\s*$/;
 661     ($answer =~ m/^[yY]/);
 662 }
 663
 664 sub unlink {
 665     my(@names) = @_;
 666     my($cnt) = 0;
 667
 668     return scalar(@names) if $Is_VMS;
 669
 670     foreach my $name (@names) {
 671         next unless -e $name;
 672         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
 673         print "  unlink $name\n" if $verbose;
 674         ( CORE::unlink($name) and ++$cnt
 675           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 676     }
 677     return $cnt;
 678 }
 679
 680 sub safe_unlink {
 681     return if $nonono or $Is_VMS;
 682     my @names = @_;
 683     foreach my $name (@names) {
 684         next unless -e $name;
 685         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
 686         print "  unlink $name\n" if $verbose;
 687         next if CORE::unlink($name);
 688         warn "Couldn't unlink $name: $!\n";
 689         if ($! =~ /busy/i) {
 690             print "  mv $name $name.old\n" if $verbose;
 691             safe_rename($name, "$name.old")
 692                 or warn "Couldn't rename $name: $!\n";
 693         }
 694     }
 695 }
 696
 697 sub safe_rename {
 698     my($from,$to) = @_;
 699     if (-f $to and not unlink($to)) {
 700         my($i);
 701         for ($i = 1; $i < 50; $i++) {
 702             last if rename($to, "$to.$i");
 703         }
 704         warn("Cannot rename to `$to.$i': $!"), return 0
 705            if $i >= 50; # Give up!
 706     }
 707     link($from,$to) || return 0;
 708     unlink($from);
 709 }
 710
 711 sub link {
 712     my($from,$to) = @_;
 713     my($success) = 0;
 714
 715     my $xfrom = $from;
 716     $xfrom =~ s/^\Q$destdir\E// if $destdir;
 717     my $xto = $to;
 718     $xto =~ s/^\Q$destdir\E// if $destdir;
 719     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
 720     eval {
 721         CORE::link($from, $to)
 722             ? $success++
 723             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 724               ? die "AFS"  # okay inside eval {}
 725               : die "Couldn't link $from to $to: $!\n"
 726           unless $nonono;
 727         $packlist->{$xto} = { from => $xfrom, type => 'link' };
 728     };
 729     if ($@) {
 730         warn "Replacing link() with File::Copy::copy(): $@";
 731         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 732         print "  creating new version of $xto\n"
 733                  if $Is_VMS and -e $to and !$silent;
 734         unless ($nonono or File::Copy::copy($from, $to) and ++$success) {
 735             # Might have been that F::C::c can't overwrite the target
 736             warn "Couldn't copy $from to $to: $!\n"
 737                 unless -f $to and (chmod(0666, $to), unlink $to)
 738                         and File::Copy::copy($from, $to) and ++$success;
 739         }
 740         $packlist->{$xto} = { type => 'file' };
 741     }
 742     $success;
 743 }
 744
 745 sub chmod {
 746     my($mode,$name) = @_;
 747
 748     return if ($^O eq 'dos');
 749     printf "  chmod %o %s\n", $mode, $name if $verbose;
 750     CORE::chmod($mode,$name)
 751         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 752       unless $nonono;
 753 }
 754
 755 sub copy {
 756     my($from,$to) = @_;
 757
 758     my $xto = $to;
 759     $xto =~ s/^\Q$destdir\E// if $destdir;
 760     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
 761     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
 762     unless ($nonono or File::Copy::copy($from, $to)) {
 763         # Might have been that F::C::c can't overwrite the target
 764         warn "Couldn't copy $from to $to: $!\n"
 765             unless -f $to and (chmod(0666, $to), unlink $to)
 766                    and File::Copy::copy($from, $to);
 767     }
 768     $packlist->{$xto} = { type => 'file' };
 769 }
 770
 771 sub samepath {
 772     my($p1, $p2) = @_;
 773
 774     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
 775
 776     if ($p1 ne $p2) {
 777         my($dev1, $ino1, $dev2, $ino2);
 778         ($dev1, $ino1) = stat($p1);
 779         ($dev2, $ino2) = stat($p2);
 780         ($dev1 == $dev2 && $ino1 == $ino2);
 781     }
 782     else {
 783         1;
 784     }
 785 }
 786
 787 sub installlib {
 788     my $dir = $File::Find::dir;
 789     $dir =~ s#^\.(?![^/])/?##;
 790     local($depth) = $dir ? "lib/$dir" : "lib";
 791
 792     my $name = $_;
 793
 794     # Ignore version control directories.
 795     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
 796         $File::Find::prune = 1;
 797         return;
 798     }
 799
 800     # ignore patch backups, RCS files, emacs backup & temp files and the
 801     # .exists files, .PL files, and test files.
 802     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$} ||
 803               $dir  =~ m{/t(?:/|$)};
 804     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
 805     # scripts in lib/ExtUtils, and the prove script in lib/Test/Harness
 806     # (they're installed later with other utils)
 807     return if $name =~ /^(?:cpan|instmodsh|prove)\z/;
 808     # ignore the Makefiles
 809     return if $name =~ /^makefile$/i;
 810     # ignore the test extensions
 811     return if $dir =~ m{ext/XS/(?:APItest|Typemap)/};
 812
 813     $name = "$dir/$name" if $dir ne '';
 814
 815     my $installlib = $installprivlib;
 816     if ($dir =~ /^auto/ ||
 817           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 818           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare))
 819        ) {
 820         $installlib = $installarchlib;
 821         return unless $do_installarchlib;
 822     } else {
 823         return unless $do_installprivlib;
 824     }
 825
 826     if (-f $_) {
 827         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 828             $installlib = $installprivlib;
 829             #We're installing *.al and *.ix files into $installprivlib,
 830             #but we have to delete old *.al and *.ix files from the 5.000
 831             #distribution:
 832             #This might not work because $archname might have changed.
 833             unlink("$installarchlib/$name");
 834         }
 835         my $xname = "$installlib/$name";
 836         $xname =~ s/^\Q$destdir\E// if $destdir;
 837         $packlist->{$xname} = { type => 'file' };
 838         if ($force || compare($_, "$installlib/$name") || $nonono) {
 839             unlink("$installlib/$name");
 840             mkpath("$installlib/$dir", $verbose, 0777);
 841             # HP-UX (at least) needs to maintain execute permissions
 842             # on dynamically-loaded libraries.
 843             if ($Is_NetWare && !$nwinstall) {
 844                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
 845                 # if copied will give problems when building new extensions.
 846                 # Has to be copied if we are installing on a NetWare server and hence
 847                 # the check !$nwinstall
 848                 if (!(/\.(?:nlp|nlm|bs)$/)) {
 849                     copy_if_diff($_, "$installlib/$name")
 850                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 851                                   "$installlib/$name");
 852                 }
 853            } else {
 854                 if (copy_if_diff($_, "$installlib/$name")) {
 855                     if ($name =~ /\.(so|$dlext)$/o) {
 856                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
 857                         chmod(0555, "$installlib/$name");
 858                     } else {
 859                         strip("-S", "$installlib/$name")
 860                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
 861                         chmod(0444, "$installlib/$name");
 862                     }
 863                 }
 864             } #if ($Is_NetWare)
 865         }
 866     }
 867 }
 868
 869 # Copy $from to $to, only if $from is different than $to.
 870 # Also preserve modification times for .a libraries.
 871 # On some systems, if you do
 872 #   ranlib libperl.a
 873 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 874 # and then try to link against the installed libperl.a, you might
 875 # get an error message to the effect that the symbol table is older
 876 # than the library.
 877 # Return true if copying occurred.
 878
 879 sub copy_if_diff {
 880     my($from,$to)=@_;
 881     return 1 if (($^O eq 'VMS') && (-d $from));
 882     my $xto = $to;
 883     $xto =~ s/^\Q$destdir\E// if $destdir;
 884     my $perlpodbadsymlink;
 885     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
 886         -l $from &&
 887         ! -e $from) {
 888         # Some Linux implementations have problems traversing over
 889         # multiple symlinks (when going over NFS?) and fail to read
 890         # the symlink target.  Combine this with the fact that some
 891         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
 892         # and you end up with those pods not getting installed.
 893         $perlpodbadsymlink = 1;
 894     }
 895     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
 896     $packlist->{$xto} = { type => 'file' };
 897     if ($force || compare($from, $to) || $nonono) {
 898         safe_unlink($to);   # In case we don't have write permissions.
 899         if ($nonono) {
 900             $from = $depth . "/" . $from if $depth;
 901         }
 902         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
 903             $from = "README.$1";
 904         }
 905         copy($from, $to);
 906         # Restore timestamps if it's a .a library or for OS/2.
 907         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 908             my ($atime, $mtime) = (stat $from)[8,9];
 909             utime $atime, $mtime, $to;
 910         }
 911         1;
 912     }
 913 }
 914
 915 sub strip
 916 {
 917     my(@args) = @_;
 918
 919     return unless $dostrip;
 920
 921     my @opts;
 922     while (@args && $args[0] =~ /^(-\w+)$/) {
 923         push @opts, shift @args;
 924     }
 925
 926     foreach my $file (@args) {
 927         if (-f $file) {
 928             if ($verbose) {
 929                 print "  strip " . join(' ', @opts);
 930                 print " " if (@opts);
 931                 print "$file\n";
 932             }
 933             system("strip", @opts, $file);
 934         } else {
 935             print "# file '$file' skipped\n" if $verbose;
 936         }
 937     }
 938 }