lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_04';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $evalarg
 639     $filename
 640     $frame
 641     $hist
 642     $histfile
 643     $histsize
 644     $ImmediateStop
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $line
 650     $maxtrace
 651     $od
 652     $onetimeDump
 653     $onetimedumpDepth
 654     %option
 655     @options
 656     $osingle
 657     $otrace
 658     $OUT
 659     $packname
 660     $pager
 661     $post
 662     %postponed
 663     $prc
 664     $pre
 665     $pretype
 666     $psh
 667     @RememberOnROptions
 668     $remoteport
 669     @res
 670     $rl
 671     @saved
 672     $signal
 673     $signalLevel
 674     $single
 675     $start
 676     $sub
 677     %sub
 678     $subname
 679     $term
 680     $trace
 681     $usercontext
 682     $warnLevel
 683     $window
 684 );
 685
 686 # Used to save @ARGV and extract any debugger-related flags.
 687 use vars qw(@ARGS);
 688
 689 # Used to prevent multiple entries to diesignal()
 690 # (if for instance diesignal() itself dies)
 691 use vars qw($panic);
 692
 693 # Used to prevent the debugger from running nonstop
 694 # after a restart
 695 use vars qw($second_time);
 696
 697 sub _calc_usercontext {
 698     my ($package) = @_;
 699
 700     # Cancel strict completely for the evaluated code, so the code
 701     # the user evaluates won't be affected by it. (Shlomi Fish)
 702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
 703     . "package $package;";    # this won't let them modify, alas
 704 }
 705
 706 sub eval {
 707
 708     # 'my' would make it visible from user code
 709     #    but so does local! --tchrist
 710     # Remember: this localizes @DB::res, not @main::res.
 711     local @res;
 712     {
 713
 714         # Try to keep the user code from messing  with us. Save these so that
 715         # even if the eval'ed code changes them, we can put them back again.
 716         # Needed because the user could refer directly to the debugger's
 717         # package globals (and any 'my' variables in this containing scope)
 718         # inside the eval(), and we want to try to stay safe.
 719         local $otrace  = $trace;
 720         local $osingle = $single;
 721         local $od      = $^D;
 722
 723         # Untaint the incoming eval() argument.
 724         { ($evalarg) = $evalarg =~ /(.*)/s; }
 725
 726         # $usercontext built in DB::DB near the comment
 727         # "set up the context for DB::eval ..."
 728         # Evaluate and save any results.
 729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 730
 731         # Restore those old values.
 732         $trace  = $otrace;
 733         $single = $osingle;
 734         $^D     = $od;
 735     }
 736
 737     # Save the current value of $@, and preserve it in the debugger's copy
 738     # of the saved precious globals.
 739     my $at = $@;
 740
 741     # Since we're only saving $@, we only have to localize the array element
 742     # that it will be stored in.
 743     local $saved[0];    # Preserve the old value of $@
 744     eval { &DB::save };
 745
 746     # Now see whether we need to report an error back to the user.
 747     if ($at) {
 748         local $\ = '';
 749         print $OUT $at;
 750     }
 751
 752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 753     # are package globals.
 754     elsif ($onetimeDump) {
 755         if ( $onetimeDump eq 'dump' ) {
 756             local $option{dumpDepth} = $onetimedumpDepth
 757               if defined $onetimedumpDepth;
 758             dumpit( $OUT, \@res );
 759         }
 760         elsif ( $onetimeDump eq 'methods' ) {
 761             methods( $res[0] );
 762         }
 763     } ## end elsif ($onetimeDump)
 764     @res;
 765 } ## end sub eval
 766
 767 ############################################## End lexical danger zone
 768
 769 # After this point it is safe to introduce lexicals.
 770 # The code being debugged will be executing in its own context, and
 771 # can't see the inside of the debugger.
 772 #
 773 # However, one should not overdo it: leave as much control from outside as
 774 # possible. If you make something a lexical, it's not going to be addressable
 775 # from outside the debugger even if you know its name.
 776
 777 # This file is automatically included if you do perl -d.
 778 # It's probably not useful to include this yourself.
 779 #
 780 # Before venturing further into these twisty passages, it is
 781 # wise to read the perldebguts man page or risk the ire of dragons.
 782 #
 783 # (It should be noted that perldebguts will tell you a lot about
 784 # the underlying mechanics of how the debugger interfaces into the
 785 # Perl interpreter, but not a lot about the debugger itself. The new
 786 # comments in this code try to address this problem.)
 787
 788 # Note that no subroutine call is possible until &DB::sub is defined
 789 # (for subroutines defined outside of the package DB). In fact the same is
 790 # true if $deep is not defined.
 791
 792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 793
 794 # modified Perl debugger, to be run from Emacs in perldb-mode
 795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 796 # Johan Vromans -- upgrade to 4.0 pl 10
 797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 798 ########################################################################
 799
 800 =head1 DEBUGGER INITIALIZATION
 801
 802 The debugger starts up in phases.
 803
 804 =head2 BASIC SETUP
 805
 806 First, it initializes the environment it wants to run in: turning off
 807 warnings during its own compilation, defining variables which it will need
 808 to avoid warnings later, setting itself up to not exit when the program
 809 terminates, and defaulting to printing return values for the C<r> command.
 810
 811 =cut
 812
 813 # Needed for the statement after exec():
 814 #
 815 # This BEGIN block is simply used to switch off warnings during debugger
 816 # compilation. Probably it would be better practice to fix the warnings,
 817 # but this is how it's done at the moment.
 818
 819 BEGIN {
 820     $ini_warn = $^W;
 821     $^W       = 0;
 822 }    # Switch compilation warnings off until another BEGIN.
 823
 824 local ($^W) = 0;    # Switch run-time warnings off during init.
 825
 826 =head2 THREADS SUPPORT
 827
 828 If we are running under a threaded Perl, we require threads and threads::shared
 829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 830 threaded debugger control.  C<-dt> can also be used to set this.
 831
 832 Each new thread will be announced and the debugger prompt will always inform
 833 you of each new thread created.  It will also indicate the thread id in which
 834 we are currently running within the prompt like this:
 835
 836         [tid] DB<$i>
 837
 838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 839 command prompt.  The prompt will show: C<[0]> when running under threads, but
 840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 841
 842 While running under threads, when you set or delete a breakpoint (etc.), this
 843 will apply to all threads, not just the currently running one.  When you are
 844 in a currently executing thread, you will stay there until it completes.  With
 845 the current implementation it is not currently possible to hop from one thread
 846 to another.
 847
 848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 849
 850 Note that threading support was built into the debugger as of Perl version
 851 C<5.8.6> and debugger version C<1.2.8>.
 852
 853 =cut
 854
 855 BEGIN {
 856   # ensure we can share our non-threaded variables or no-op
 857   if ($ENV{PERL5DB_THREADED}) {
 858         require threads;
 859         require threads::shared;
 860         import threads::shared qw(share);
 861         $DBGR;
 862         share(\$DBGR);
 863         lock($DBGR);
 864         print "Threads support enabled\n";
 865   } else {
 866         *lock  = sub(*) {};
 867         *share = sub(*) {};
 868   }
 869 }
 870
 871 # This would probably be better done with "use vars", but that wasn't around
 872 # when this code was originally written. (Neither was "use strict".) And on
 873 # the principle of not fiddling with something that was working, this was
 874 # left alone.
 875 warn(               # Do not ;-)
 876     # These variables control the execution of 'dumpvar.pl'.
 877     $dumpvar::hashDepth,
 878     $dumpvar::arrayDepth,
 879     $dumpvar::dumpDBFiles,
 880     $dumpvar::dumpPackages,
 881     $dumpvar::quoteHighBit,
 882     $dumpvar::printUndef,
 883     $dumpvar::globPrint,
 884     $dumpvar::usageOnly,
 885
 886     # used to control die() reporting in diesignal()
 887     $Carp::CarpLevel,
 888
 889
 890   )
 891   if 0;
 892
 893 # without threads, $filename is not defined until DB::DB is called
 894 foreach my $k (keys (%INC)) {
 895         &share(\$main::{'_<'.$filename}) if defined $filename;
 896 };
 897
 898 # Command-line + PERLLIB:
 899 # Save the contents of @INC before they are modified elsewhere.
 900 @ini_INC = @INC;
 901
 902 # This was an attempt to clear out the previous values of various
 903 # trapped errors. Apparently it didn't help. XXX More info needed!
 904 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 905
 906 # We set these variables to safe values. We don't want to blindly turn
 907 # off warnings, because other packages may still want them.
 908 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 909                                    # (local $^W cannot help - other packages!).
 910
 911 # Default to not exiting when program finishes; print the return
 912 # value when the 'r' command is used to return from a subroutine.
 913 $inhibit_exit = $option{PrintRet} = 1;
 914
 915 use vars qw($trace_to_depth);
 916
 917 # Default to 1E9 so it won't be limited to a certain recursion depth.
 918 $trace_to_depth = 1E9;
 919
 920 =head1 OPTION PROCESSING
 921
 922 The debugger's options are actually spread out over the debugger itself and
 923 C<dumpvar.pl>; some of these are variables to be set, while others are
 924 subs to be called with a value. To try to make this a little easier to
 925 manage, the debugger uses a few data structures to define what options
 926 are legal and how they are to be processed.
 927
 928 First, the C<@options> array defines the I<names> of all the options that
 929 are to be accepted.
 930
 931 =cut
 932
 933 @options = qw(
 934   CommandSet   HistFile      HistSize
 935   hashDepth    arrayDepth    dumpDepth
 936   DumpDBFiles  DumpPackages  DumpReused
 937   compactDump  veryCompact   quote
 938   HighBit      undefPrint    globPrint
 939   PrintRet     UsageOnly     frame
 940   AutoTrace    TTY           noTTY
 941   ReadLine     NonStop       LineInfo
 942   maxTraceLen  recallCommand ShellBang
 943   pager        tkRunning     ornaments
 944   signalLevel  warnLevel     dieLevel
 945   inhibit_exit ImmediateStop bareStringify
 946   CreateTTY    RemotePort    windowSize
 947   DollarCaretP
 948 );
 949
 950 @RememberOnROptions = qw(DollarCaretP);
 951
 952 =pod
 953
 954 Second, C<optionVars> lists the variables that each option uses to save its
 955 state.
 956
 957 =cut
 958
 959 use vars qw(%optionVars);
 960
 961 %optionVars = (
 962     hashDepth     => \$dumpvar::hashDepth,
 963     arrayDepth    => \$dumpvar::arrayDepth,
 964     CommandSet    => \$CommandSet,
 965     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 966     DumpPackages  => \$dumpvar::dumpPackages,
 967     DumpReused    => \$dumpvar::dumpReused,
 968     HighBit       => \$dumpvar::quoteHighBit,
 969     undefPrint    => \$dumpvar::printUndef,
 970     globPrint     => \$dumpvar::globPrint,
 971     UsageOnly     => \$dumpvar::usageOnly,
 972     CreateTTY     => \$CreateTTY,
 973     bareStringify => \$dumpvar::bareStringify,
 974     frame         => \$frame,
 975     AutoTrace     => \$trace,
 976     inhibit_exit  => \$inhibit_exit,
 977     maxTraceLen   => \$maxtrace,
 978     ImmediateStop => \$ImmediateStop,
 979     RemotePort    => \$remoteport,
 980     windowSize    => \$window,
 981     HistFile      => \$histfile,
 982     HistSize      => \$histsize,
 983 );
 984
 985 =pod
 986
 987 Third, C<%optionAction> defines the subroutine to be called to process each
 988 option.
 989
 990 =cut
 991
 992 use vars qw(%optionAction);
 993
 994 %optionAction = (
 995     compactDump   => \&dumpvar::compactDump,
 996     veryCompact   => \&dumpvar::veryCompact,
 997     quote         => \&dumpvar::quote,
 998     TTY           => \&TTY,
 999     noTTY         => \&noTTY,
1000     ReadLine      => \&ReadLine,
1001     NonStop       => \&NonStop,
1002     LineInfo      => \&LineInfo,
1003     recallCommand => \&recallCommand,
1004     ShellBang     => \&shellBang,
1005     pager         => \&pager,
1006     signalLevel   => \&signalLevel,
1007     warnLevel     => \&warnLevel,
1008     dieLevel      => \&dieLevel,
1009     tkRunning     => \&tkRunning,
1010     ornaments     => \&ornaments,
1011     RemotePort    => \&RemotePort,
1012     DollarCaretP  => \&DollarCaretP,
1013 );
1014
1015 =pod
1016
1017 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1018 option is used.
1019
1020 =cut
1021
1022 # Note that this list is not complete: several options not listed here
1023 # actually require that dumpvar.pl be loaded for them to work, but are
1024 # not in the table. A subsequent patch will correct this problem; for
1025 # the moment, we're just recommenting, and we are NOT going to change
1026 # function.
1027 use vars qw(%optionRequire);
1028
1029 %optionRequire = (
1030     compactDump => 'dumpvar.pl',
1031     veryCompact => 'dumpvar.pl',
1032     quote       => 'dumpvar.pl',
1033 );
1034
1035 =pod
1036
1037 There are a number of initialization-related variables which can be set
1038 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1039 variable. These are:
1040
1041 =over 4
1042
1043 =item C<$rl> - readline control XXX needs more explanation
1044
1045 =item C<$warnLevel> - whether or not debugger takes over warning handling
1046
1047 =item C<$dieLevel> - whether or not debugger takes over die handling
1048
1049 =item C<$signalLevel> - whether or not debugger takes over signal handling
1050
1051 =item C<$pre> - preprompt actions (array reference)
1052
1053 =item C<$post> - postprompt actions (array reference)
1054
1055 =item C<$pretype>
1056
1057 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1058
1059 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1060
1061 =back
1062
1063 =cut
1064
1065 # These guys may be defined in $ENV{PERL5DB} :
1066 $rl          = 1     unless defined $rl;
1067 $warnLevel   = 1     unless defined $warnLevel;
1068 $dieLevel    = 1     unless defined $dieLevel;
1069 $signalLevel = 1     unless defined $signalLevel;
1070 $pre         = []    unless defined $pre;
1071 $post        = []    unless defined $post;
1072 $pretype     = []    unless defined $pretype;
1073 $CreateTTY   = 3     unless defined $CreateTTY;
1074 $CommandSet  = '580' unless defined $CommandSet;
1075
1076 share($rl);
1077 share($warnLevel);
1078 share($dieLevel);
1079 share($signalLevel);
1080 share($pre);
1081 share($post);
1082 share($pretype);
1083 share($rl);
1084 share($CreateTTY);
1085 share($CommandSet);
1086
1087 =pod
1088
1089 The default C<die>, C<warn>, and C<signal> handlers are set up.
1090
1091 =cut
1092
1093 warnLevel($warnLevel);
1094 dieLevel($dieLevel);
1095 signalLevel($signalLevel);
1096
1097 =pod
1098
1099 The pager to be used is needed next. We try to get it from the
1100 environment first.  If it's not defined there, we try to find it in
1101 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1102 then call the C<pager()> function to save the pager name.
1103
1104 =cut
1105
1106 # This routine makes sure $pager is set up so that '|' can use it.
1107 pager(
1108
1109     # If PAGER is defined in the environment, use it.
1110     defined $ENV{PAGER}
1111     ? $ENV{PAGER}
1112
1113       # If not, see if Config.pm defines it.
1114     : eval { require Config }
1115       && defined $Config::Config{pager}
1116     ? $Config::Config{pager}
1117
1118       # If not, fall back to 'more'.
1119     : 'more'
1120   )
1121   unless defined $pager;
1122
1123 =pod
1124
1125 We set up the command to be used to access the man pages, the command
1126 recall character (C<!> unless otherwise defined) and the shell escape
1127 character (C<!> unless otherwise defined). Yes, these do conflict, and
1128 neither works in the debugger at the moment.
1129
1130 =cut
1131
1132 setman();
1133
1134 # Set up defaults for command recall and shell escape (note:
1135 # these currently don't work in linemode debugging).
1136 &recallCommand("!") unless defined $prc;
1137 &shellBang("!")     unless defined $psh;
1138
1139 =pod
1140
1141 We then set up the gigantic string containing the debugger help.
1142 We also set the limit on the number of arguments we'll display during a
1143 trace.
1144
1145 =cut
1146
1147 sethelp();
1148
1149 # If we didn't get a default for the length of eval/stack trace args,
1150 # set it here.
1151 $maxtrace = 400 unless defined $maxtrace;
1152
1153 =head2 SETTING UP THE DEBUGGER GREETING
1154
1155 The debugger I<greeting> helps to inform the user how many debuggers are
1156 running, and whether the current debugger is the primary or a child.
1157
1158 If we are the primary, we just hang onto our pid so we'll have it when
1159 or if we start a child debugger. If we are a child, we'll set things up
1160 so we'll have a unique greeting and so the parent will give us our own
1161 TTY later.
1162
1163 We save the current contents of the C<PERLDB_PIDS> environment variable
1164 because we mess around with it. We'll also need to hang onto it because
1165 we'll need it if we restart.
1166
1167 Child debuggers make a label out of the current PID structure recorded in
1168 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1169 yet so the parent will give them one later via C<resetterm()>.
1170
1171 =cut
1172
1173 # Save the current contents of the environment; we're about to
1174 # much with it. We'll need this if we have to restart.
1175 use vars qw($ini_pids);
1176 $ini_pids = $ENV{PERLDB_PIDS};
1177
1178 use vars qw ($pids $term_pid);
1179
1180 if ( defined $ENV{PERLDB_PIDS} ) {
1181
1182     # We're a child. Make us a label out of the current PID structure
1183     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1184     # a term yet so the parent will give us one later via resetterm().
1185
1186     my $env_pids = $ENV{PERLDB_PIDS};
1187     $pids = "[$env_pids]";
1188
1189     # Unless we are on OpenVMS, all programs under the DCL shell run under
1190     # the same PID.
1191
1192     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1193         $term_pid         = $$;
1194     }
1195     else {
1196         $ENV{PERLDB_PIDS} .= "->$$";
1197         $term_pid = -1;
1198     }
1199
1200 } ## end if (defined $ENV{PERLDB_PIDS...
1201 else {
1202
1203     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1204     # child debugger, and mark us as the parent, so we'll know to set up
1205     # more TTY's is we have to.
1206     $ENV{PERLDB_PIDS} = "$$";
1207     $pids             = "[pid=$$]";
1208     $term_pid         = $$;
1209 }
1210
1211 use vars qw($pidprompt);
1212 $pidprompt = '';
1213
1214 # Sets up $emacs as a synonym for $slave_editor.
1215 use vars qw($slave_editor);
1216 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1217
1218 =head2 READING THE RC FILE
1219
1220 The debugger will read a file of initialization options if supplied. If
1221 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1222
1223 =cut
1224
1225 # As noted, this test really doesn't check accurately that the debugger
1226 # is running at a terminal or not.
1227
1228 my $dev_tty = '/dev/tty';
1229    $dev_tty = 'TT:' if ($^O eq 'VMS');
1230 use vars qw($rcfile);
1231 if ( -e $dev_tty ) {                      # this is the wrong metric!
1232     $rcfile = ".perldb";
1233 }
1234 else {
1235     $rcfile = "perldb.ini";
1236 }
1237
1238 =pod
1239
1240 The debugger does a safety test of the file to be read. It must be owned
1241 either by the current user or root, and must only be writable by the owner.
1242
1243 =cut
1244
1245 # This wraps a safety test around "do" to read and evaluate the init file.
1246 #
1247 # This isn't really safe, because there's a race
1248 # between checking and opening.  The solution is to
1249 # open and fstat the handle, but then you have to read and
1250 # eval the contents.  But then the silly thing gets
1251 # your lexical scope, which is unfortunate at best.
1252 sub safe_do {
1253     my $file = shift;
1254
1255     # Just exactly what part of the word "CORE::" don't you understand?
1256     local $SIG{__WARN__};
1257     local $SIG{__DIE__};
1258
1259     unless ( is_safe_file($file) ) {
1260         CORE::warn <<EO_GRIPE;
1261 perldb: Must not source insecure rcfile $file.
1262         You or the superuser must be the owner, and it must not
1263         be writable by anyone but its owner.
1264 EO_GRIPE
1265         return;
1266     } ## end unless (is_safe_file($file...
1267
1268     do $file;
1269     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1270 } ## end sub safe_do
1271
1272 # This is the safety test itself.
1273 #
1274 # Verifies that owner is either real user or superuser and that no
1275 # one but owner may write to it.  This function is of limited use
1276 # when called on a path instead of upon a handle, because there are
1277 # no guarantees that filename (by dirent) whose file (by ino) is
1278 # eventually accessed is the same as the one tested.
1279 # Assumes that the file's existence is not in doubt.
1280 sub is_safe_file {
1281     my $path = shift;
1282     stat($path) || return;    # mysteriously vaporized
1283     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1284
1285     return 0 if $uid != 0 && $uid != $<;
1286     return 0 if $mode & 022;
1287     return 1;
1288 } ## end sub is_safe_file
1289
1290 # If the rcfile (whichever one we decided was the right one to read)
1291 # exists, we safely do it.
1292 if ( -f $rcfile ) {
1293     safe_do("./$rcfile");
1294 }
1295
1296 # If there isn't one here, try the user's home directory.
1297 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1298     safe_do("$ENV{HOME}/$rcfile");
1299 }
1300
1301 # Else try the login directory.
1302 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1303     safe_do("$ENV{LOGDIR}/$rcfile");
1304 }
1305
1306 # If the PERLDB_OPTS variable has options in it, parse those out next.
1307 if ( defined $ENV{PERLDB_OPTS} ) {
1308     parse_options( $ENV{PERLDB_OPTS} );
1309 }
1310
1311 =pod
1312
1313 The last thing we do during initialization is determine which subroutine is
1314 to be used to obtain a new terminal when a new debugger is started. Right now,
1315 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1316 (darwin).
1317
1318 =cut
1319
1320 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1321 # Works if you're running an xterm or xterm-like window, or you're on
1322 # OS/2, or on Mac OS X. This may need some expansion.
1323
1324 if (not defined &get_fork_TTY)       # only if no routine exists
1325 {
1326     if ( defined $remoteport ) {
1327                                                  # Expect an inetd-like server
1328         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1329     }
1330     elsif (defined $ENV{TERM}                    # If we know what kind
1331                                                  # of terminal this is,
1332         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1333         and defined $ENV{DISPLAY}                # and what display it's on,
1334       )
1335     {
1336         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1337     }
1338     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1339         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1340     }
1341     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1342             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1343             and $ENV{TERM_PROGRAM}
1344                 eq 'Apple_Terminal'              # Terminal.app
1345             )
1346     {
1347         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1348     }
1349 } ## end if (not defined &get_fork_TTY...
1350
1351 # untaint $^O, which may have been tainted by the last statement.
1352 # see bug [perl #24674]
1353 $^O =~ m/^(.*)\z/;
1354 $^O = $1;
1355
1356 # Here begin the unreadable code.  It needs fixing.
1357
1358 =head2 RESTART PROCESSING
1359
1360 This section handles the restart command. When the C<R> command is invoked, it
1361 tries to capture all of the state it can into environment variables, and
1362 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1363 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1364 the R command stuffed into the environment variables.
1365
1366   PERLDB_RESTART   - flag only, contains no restart data itself.
1367   PERLDB_HIST      - command history, if it's available
1368   PERLDB_ON_LOAD   - breakpoints set by the rc file
1369   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1370   PERLDB_VISITED   - files that had breakpoints
1371   PERLDB_FILE_...  - breakpoints for a file
1372   PERLDB_OPT       - active options
1373   PERLDB_INC       - the original @INC
1374   PERLDB_PRETYPE   - preprompt debugger actions
1375   PERLDB_PRE       - preprompt Perl code
1376   PERLDB_POST      - post-prompt Perl code
1377   PERLDB_TYPEAHEAD - typeahead captured by readline()
1378
1379 We chug through all these variables and plug the values saved in them
1380 back into the appropriate spots in the debugger.
1381
1382 =cut
1383
1384 use vars qw(@hist @truehist %postponed_file @typeahead);
1385
1386 if ( exists $ENV{PERLDB_RESTART} ) {
1387
1388     # We're restarting, so we don't need the flag that says to restart anymore.
1389     delete $ENV{PERLDB_RESTART};
1390
1391     # $restart = 1;
1392     @hist          = get_list('PERLDB_HIST');
1393     %break_on_load = get_list("PERLDB_ON_LOAD");
1394     %postponed     = get_list("PERLDB_POSTPONE");
1395
1396         share(@hist);
1397         share(@truehist);
1398         share(%break_on_load);
1399         share(%postponed);
1400
1401     # restore breakpoints/actions
1402     my @had_breakpoints = get_list("PERLDB_VISITED");
1403     for my $file_idx ( 0 .. $#had_breakpoints ) {
1404         my $filename = $had_breakpoints[$file_idx];
1405         my %pf = get_list("PERLDB_FILE_$file_idx");
1406         $postponed_file{ $filename } = \%pf if %pf;
1407         my @lines = sort {$a <=> $b} keys(%pf);
1408         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1409         for my $line_idx (0 .. $#lines) {
1410             _set_breakpoint_enabled_status(
1411                 $filename,
1412                 $lines[$line_idx],
1413                 ($enabled_statuses[$line_idx] ? 1 : ''),
1414             );
1415         }
1416     }
1417
1418     # restore options
1419     my %opt = get_list("PERLDB_OPT");
1420     my ( $opt, $val );
1421     while ( ( $opt, $val ) = each %opt ) {
1422         $val =~ s/[\\\']/\\$1/g;
1423         parse_options("$opt'$val'");
1424     }
1425
1426     # restore original @INC
1427     @INC     = get_list("PERLDB_INC");
1428     @ini_INC = @INC;
1429
1430     # return pre/postprompt actions and typeahead buffer
1431     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1432     $pre       = [ get_list("PERLDB_PRE") ];
1433     $post      = [ get_list("PERLDB_POST") ];
1434     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1435 } ## end if (exists $ENV{PERLDB_RESTART...
1436
1437 =head2 SETTING UP THE TERMINAL
1438
1439 Now, we'll decide how the debugger is going to interact with the user.
1440 If there's no TTY, we set the debugger to run non-stop; there's not going
1441 to be anyone there to enter commands.
1442
1443 =cut
1444
1445 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1446 use vars qw($lineinfo $doccmd);
1447
1448 if ($notty) {
1449     $runnonstop = 1;
1450         share($runnonstop);
1451 }
1452
1453 =pod
1454
1455 If there is a TTY, we have to determine who it belongs to before we can
1456 proceed. If this is a slave editor or graphical debugger (denoted by
1457 the first command-line switch being '-emacs'), we shift this off and
1458 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1459
1460 =cut
1461
1462 else {
1463
1464     # Is Perl being run from a slave editor or graphical debugger?
1465     # If so, don't use readline, and set $slave_editor = 1.
1466     $slave_editor =
1467       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1468     $rl = 0, shift(@main::ARGV) if $slave_editor;
1469
1470     #require Term::ReadLine;
1471
1472 =pod
1473
1474 We then determine what the console should be on various systems:
1475
1476 =over 4
1477
1478 =item * Cygwin - We use C<stdin> instead of a separate device.
1479
1480 =cut
1481
1482     if ( $^O eq 'cygwin' ) {
1483
1484         # /dev/tty is binary. use stdin for textmode
1485         undef $console;
1486     }
1487
1488 =item * Unix - use C</dev/tty>.
1489
1490 =cut
1491
1492     elsif ( -e "/dev/tty" ) {
1493         $console = "/dev/tty";
1494     }
1495
1496 =item * Windows or MSDOS - use C<con>.
1497
1498 =cut
1499
1500     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1501         $console = "con";
1502     }
1503
1504 =item * VMS - use C<sys$command>.
1505
1506 =cut
1507
1508     else {
1509
1510         # everything else is ...
1511         $console = "sys\$command";
1512     }
1513
1514 =pod
1515
1516 =back
1517
1518 Several other systems don't use a specific console. We C<undef $console>
1519 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1520 with a slave editor, Epoc).
1521
1522 =cut
1523
1524     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1525
1526         # /dev/tty is binary. use stdin for textmode
1527         $console = undef;
1528     }
1529
1530     if ( $^O eq 'NetWare' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         $console = undef;
1534     }
1535
1536     # In OS/2, we need to use STDIN to get textmode too, even though
1537     # it pretty much looks like Unix otherwise.
1538     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1539     {    # In OS/2
1540         $console = undef;
1541     }
1542
1543     # EPOC also falls into the 'got to use STDIN' camp.
1544     if ( $^O eq 'epoc' ) {
1545         $console = undef;
1546     }
1547
1548 =pod
1549
1550 If there is a TTY hanging around from a parent, we use that as the console.
1551
1552 =cut
1553
1554     $console = $tty if defined $tty;
1555
1556 =head2 SOCKET HANDLING
1557
1558 The debugger is capable of opening a socket and carrying out a debugging
1559 session over the socket.
1560
1561 If C<RemotePort> was defined in the options, the debugger assumes that it
1562 should try to start a debugging session on that port. It builds the socket
1563 and then tries to connect the input and output filehandles to it.
1564
1565 =cut
1566
1567     # Handle socket stuff.
1568
1569     if ( defined $remoteport ) {
1570
1571         # If RemotePort was defined in the options, connect input and output
1572         # to the socket.
1573         $IN = $OUT = connect_remoteport();
1574     } ## end if (defined $remoteport)
1575
1576 =pod
1577
1578 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1579 this is probably a situation where multiple debuggers are running (for example,
1580 a backticked command that starts up another debugger). We create a new IN and
1581 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1582 and if we can.
1583
1584 =cut
1585
1586     # Non-socket.
1587     else {
1588
1589         # Two debuggers running (probably a system or a backtick that invokes
1590         # the debugger itself under the running one). create a new IN and OUT
1591         # filehandle, and do the necessary mojo to create a new tty if we
1592         # know how, and we can.
1593         create_IN_OUT(4) if $CreateTTY & 4;
1594         if ($console) {
1595
1596             # If we have a console, check to see if there are separate ins and
1597             # outs to open. (They are assumed identical if not.)
1598
1599             my ( $i, $o ) = split /,/, $console;
1600             $o = $i unless defined $o;
1601
1602             # read/write on in, or just read, or read on STDIN.
1603             open( IN,      "+<$i" )
1604               || open( IN, "<$i" )
1605               || open( IN, "<&STDIN" );
1606
1607             # read/write/create/clobber out, or write/create/clobber out,
1608             # or merge with STDERR, or merge with STDOUT.
1609                  open( OUT, "+>$o" )
1610               || open( OUT, ">$o" )
1611               || open( OUT, ">&STDERR" )
1612               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1613
1614         } ## end if ($console)
1615         elsif ( not defined $console ) {
1616
1617             # No console. Open STDIN.
1618             open( IN, "<&STDIN" );
1619
1620             # merge with STDERR, or with STDOUT.
1621             open( OUT,      ">&STDERR" )
1622               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1623             $console = 'STDIN/OUT';
1624         } ## end elsif (not defined $console)
1625
1626         # Keep copies of the filehandles so that when the pager runs, it
1627         # can close standard input without clobbering ours.
1628         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1629     } ## end elsif (from if(defined $remoteport))
1630
1631     # Unbuffer DB::OUT. We need to see responses right away.
1632     $OUT->autoflush(1);
1633
1634     # Line info goes to debugger output unless pointed elsewhere.
1635     # Pointing elsewhere makes it possible for slave editors to
1636     # keep track of file and position. We have both a filehandle
1637     # and a I/O description to keep track of.
1638     $LINEINFO = $OUT     unless defined $LINEINFO;
1639     $lineinfo = $console unless defined $lineinfo;
1640         # share($LINEINFO); # <- unable to share globs
1641         share($lineinfo);   #
1642
1643 =pod
1644
1645 To finish initialization, we show the debugger greeting,
1646 and then call the C<afterinit()> subroutine if there is one.
1647
1648 =cut
1649
1650     # Show the debugger greeting.
1651     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1652     unless ($runnonstop) {
1653         local $\ = '';
1654         local $, = '';
1655         if ( $term_pid eq '-1' ) {
1656             print $OUT "\nDaughter DB session started...\n";
1657         }
1658         else {
1659             print $OUT "\nLoading DB routines from $header\n";
1660             print $OUT (
1661                 "Editor support ",
1662                 $slave_editor ? "enabled" : "available", ".\n"
1663             );
1664             print $OUT
1665 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1666         } ## end else [ if ($term_pid eq '-1')
1667     } ## end unless ($runnonstop)
1668 } ## end else [ if ($notty)
1669
1670 # XXX This looks like a bug to me.
1671 # Why copy to @ARGS and then futz with @args?
1672 @ARGS = @ARGV;
1673 # for (@args) {
1674     # Make sure backslashes before single quotes are stripped out, and
1675     # keep args unless they are numeric (XXX why?)
1676     # s/\'/\\\'/g;                      # removed while not justified understandably
1677     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1678 # }
1679
1680 # If there was an afterinit() sub defined, call it. It will get
1681 # executed in our scope, so it can fiddle with debugger globals.
1682 if ( defined &afterinit ) {    # May be defined in $rcfile
1683     &afterinit();
1684 }
1685
1686 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1687 use vars qw($I_m_init);
1688
1689 $I_m_init = 1;
1690
1691 ############################################################ Subroutines
1692
1693 =head1 SUBROUTINES
1694
1695 =head2 DB
1696
1697 This gigantic subroutine is the heart of the debugger. Called before every
1698 statement, its job is to determine if a breakpoint has been reached, and
1699 stop if so; read commands from the user, parse them, and execute
1700 them, and then send execution off to the next statement.
1701
1702 Note that the order in which the commands are processed is very important;
1703 some commands earlier in the loop will actually alter the C<$cmd> variable
1704 to create other commands to be executed later. This is all highly I<optimized>
1705 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1706 see what's happening in any given command.
1707
1708 =cut
1709
1710 use vars qw(
1711     $action
1712     %alias
1713     $cmd
1714     $doret
1715     $fall_off_end
1716     $file
1717     $filename_ini
1718     $finished
1719     %had_breakpoints
1720     $incr
1721     $laststep
1722     $level
1723     $max
1724     @old_watch
1725     $package
1726     $rc
1727     $sh
1728     @stack
1729     $stack_depth
1730     @to_watch
1731     $try
1732     $end
1733 );
1734
1735 sub DB {
1736
1737     # lock the debugger and get the thread id for the prompt
1738         lock($DBGR);
1739         my $tid;
1740         my $position;
1741         my ($prefix, $after, $infix);
1742         my $pat;
1743
1744         if ($ENV{PERL5DB_THREADED}) {
1745                 $tid = eval { "[".threads->tid."]" };
1746         }
1747
1748     # Check for whether we should be running continuously or not.
1749     # _After_ the perl program is compiled, $single is set to 1:
1750     if ( $single and not $second_time++ ) {
1751
1752         # Options say run non-stop. Run until we get an interrupt.
1753         if ($runnonstop) {    # Disable until signal
1754                 # If there's any call stack in place, turn off single
1755                 # stepping into subs throughout the stack.
1756             for my $i (0 .. $stack_depth) {
1757                 $stack[ $i ] &= ~1;
1758             }
1759
1760             # And we are now no longer in single-step mode.
1761             $single = 0;
1762
1763             # If we simply returned at this point, we wouldn't get
1764             # the trace info. Fall on through.
1765             # return;
1766         } ## end if ($runnonstop)
1767
1768         elsif ($ImmediateStop) {
1769
1770             # We are supposed to stop here; XXX probably a break.
1771             $ImmediateStop = 0;    # We've processed it; turn it off
1772             $signal        = 1;    # Simulate an interrupt to force
1773                                    # us into the command loop
1774         }
1775     } ## end if ($single and not $second_time...
1776
1777     # If we're in single-step mode, or an interrupt (real or fake)
1778     # has occurred, turn off non-stop mode.
1779     $runnonstop = 0 if $single or $signal;
1780
1781     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1782     # The code being debugged may have altered them.
1783     &save;
1784
1785     # Since DB::DB gets called after every line, we can use caller() to
1786     # figure out where we last were executing. Sneaky, eh? This works because
1787     # caller is returning all the extra information when called from the
1788     # debugger.
1789     local ( $package, $filename, $line ) = caller;
1790     $filename_ini = $filename;
1791
1792     # set up the context for DB::eval, so it can properly execute
1793     # code on behalf of the user. We add the package in so that the
1794     # code is eval'ed in the proper package (not in the debugger!).
1795     local $usercontext = _calc_usercontext($package);
1796
1797     # Create an alias to the active file magical array to simplify
1798     # the code here.
1799     local (*dbline) = $main::{ '_<' . $filename };
1800
1801     # Last line in the program.
1802     $max = $#dbline;
1803
1804     # if we have something here, see if we should break.
1805     {
1806         # $stop is lexical and local to this block - $action on the other hand
1807         # is global.
1808         my $stop;
1809
1810         if ( $dbline{$line}
1811             && _is_breakpoint_enabled($filename, $line)
1812             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1813         {
1814
1815             # Stop if the stop criterion says to just stop.
1816             if ( $stop eq '1' ) {
1817                 $signal |= 1;
1818             }
1819
1820             # It's a conditional stop; eval it in the user's context and
1821             # see if we should stop. If so, remove the one-time sigil.
1822             elsif ($stop) {
1823                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1824                 &eval;
1825                 # If the breakpoint is temporary, then delete its enabled status.
1826                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1827                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1828                 }
1829             }
1830         } ## end if ($dbline{$line} && ...
1831     }
1832
1833     # Preserve the current stop-or-not, and see if any of the W
1834     # (watch expressions) has changed.
1835     my $was_signal = $signal;
1836
1837     # If we have any watch expressions ...
1838     if ( $trace & 2 ) {
1839         for my $n (0 .. $#to_watch) {
1840             $evalarg = $to_watch[$n];
1841             local $onetimeDump;    # Tell DB::eval() to not output results
1842
1843             # Fix context DB::eval() wants to return an array, but
1844             # we need a scalar here.
1845             my ($val) = join( "', '", &eval );
1846             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1847
1848             # Did it change?
1849             if ( $val ne $old_watch[$n] ) {
1850
1851                 # Yep! Show the difference, and fake an interrupt.
1852                 $signal = 1;
1853                 print $OUT <<EOP;
1854 Watchpoint $n:\t$to_watch[$n] changed:
1855     old value:\t$old_watch[$n]
1856     new value:\t$val
1857 EOP
1858                 $old_watch[$n] = $val;
1859             } ## end if ($val ne $old_watch...
1860         } ## end for my $n (0 ..
1861     } ## end if ($trace & 2)
1862
1863 =head2 C<watchfunction()>
1864
1865 C<watchfunction()> is a function that can be defined by the user; it is a
1866 function which will be run on each entry to C<DB::DB>; it gets the
1867 current package, filename, and line as its parameters.
1868
1869 The watchfunction can do anything it likes; it is executing in the
1870 debugger's context, so it has access to all of the debugger's internal
1871 data structures and functions.
1872
1873 C<watchfunction()> can control the debugger's actions. Any of the following
1874 will cause the debugger to return control to the user's program after
1875 C<watchfunction()> executes:
1876
1877 =over 4
1878
1879 =item *
1880
1881 Returning a false value from the C<watchfunction()> itself.
1882
1883 =item *
1884
1885 Altering C<$single> to a false value.
1886
1887 =item *
1888
1889 Altering C<$signal> to a false value.
1890
1891 =item *
1892
1893 Turning off the C<4> bit in C<$trace> (this also disables the
1894 check for C<watchfunction()>. This can be done with
1895
1896     $trace &= ~4;
1897
1898 =back
1899
1900 =cut
1901
1902     # If there's a user-defined DB::watchfunction, call it with the
1903     # current package, filename, and line. The function executes in
1904     # the DB:: package.
1905     if ( $trace & 4 ) {    # User-installed watch
1906         return
1907           if watchfunction( $package, $filename, $line )
1908           and not $single
1909           and not $was_signal
1910           and not( $trace & ~4 );
1911     } ## end if ($trace & 4)
1912
1913     # Pick up any alteration to $signal in the watchfunction, and
1914     # turn off the signal now.
1915     $was_signal = $signal;
1916     $signal     = 0;
1917
1918 =head2 GETTING READY TO EXECUTE COMMANDS
1919
1920 The debugger decides to take control if single-step mode is on, the
1921 C<t> command was entered, or the user generated a signal. If the program
1922 has fallen off the end, we set things up so that entering further commands
1923 won't cause trouble, and we say that the program is over.
1924
1925 =cut
1926
1927     # Make sure that we always print if asked for explicitly regardless
1928     # of $trace_to_depth .
1929     my $explicit_stop = ($single || $was_signal);
1930
1931     # Check to see if we should grab control ($single true,
1932     # trace set appropriately, or we got a signal).
1933     if ( $explicit_stop || ( $trace & 1 ) ) {
1934
1935         # Yes, grab control.
1936         if ($slave_editor) {
1937
1938             # Tell the editor to update its position.
1939             $position = "\032\032$filename:$line:0\n";
1940             print_lineinfo($position);
1941         }
1942
1943 =pod
1944
1945 Special check: if we're in package C<DB::fake>, we've gone through the
1946 C<END> block at least once. We set up everything so that we can continue
1947 to enter commands and have a valid context to be in.
1948
1949 =cut
1950
1951         elsif ( $package eq 'DB::fake' ) {
1952
1953             # Fallen off the end already.
1954             $term || &setterm;
1955             print_help(<<EOP);
1956 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1957   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1958   B<h q>, B<h R> or B<h o> to get additional info.
1959 EOP
1960
1961             # Set the DB::eval context appropriately.
1962             $package     = 'main';
1963             $usercontext = _calc_usercontext($package);
1964         } ## end elsif ($package eq 'DB::fake')
1965
1966 =pod
1967
1968 If the program hasn't finished executing, we scan forward to the
1969 next executable line, print that out, build the prompt from the file and line
1970 number information, and print that.
1971
1972 =cut
1973
1974         else {
1975
1976
1977             # Still somewhere in the midst of execution. Set up the
1978             #  debugger prompt.
1979             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1980                                  # Perl 5 ones (sorry, we don't print Klingon
1981                                  #module names)
1982
1983             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1984             $prefix .= "$sub($filename:";
1985             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1986
1987             # Break up the prompt if it's really long.
1988             if ( length($prefix) > 30 ) {
1989                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1990                 $prefix   = "";
1991                 $infix    = ":\t";
1992             }
1993             else {
1994                 $infix    = "):\t";
1995                 $position = "$prefix$line$infix$dbline[$line]$after";
1996             }
1997
1998             # Print current line info, indenting if necessary.
1999             if ($frame) {
2000                 print_lineinfo( ' ' x $stack_depth,
2001                     "$line:\t$dbline[$line]$after" );
2002             }
2003             else {
2004                 depth_print_lineinfo($explicit_stop, $position);
2005             }
2006
2007             # Scan forward, stopping at either the end or the next
2008             # unbreakable line.
2009             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2010             {    #{ vi
2011
2012                 # Drop out on null statements, block closers, and comments.
2013                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2014
2015                 # Drop out if the user interrupted us.
2016                 last if $signal;
2017
2018                 # Append a newline if the line doesn't have one. Can happen
2019                 # in eval'ed text, for instance.
2020                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2021
2022                 # Next executable line.
2023                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2024                 $position .= $incr_pos;
2025                 if ($frame) {
2026
2027                     # Print it indented if tracing is on.
2028                     print_lineinfo( ' ' x $stack_depth,
2029                         "$i:\t$dbline[$i]$after" );
2030                 }
2031                 else {
2032                     depth_print_lineinfo($explicit_stop, $incr_pos);
2033                 }
2034             } ## end for ($i = $line + 1 ; $i...
2035         } ## end else [ if ($slave_editor)
2036     } ## end if ($single || ($trace...
2037
2038 =pod
2039
2040 If there's an action to be executed for the line we stopped at, execute it.
2041 If there are any preprompt actions, execute those as well.
2042
2043 =cut
2044
2045     # If there's an action, do it now.
2046     $evalarg = $action, &eval if $action;
2047
2048     # Are we nested another level (e.g., did we evaluate a function
2049     # that had a breakpoint in it at the debugger prompt)?
2050     if ( $single || $was_signal ) {
2051
2052         # Yes, go down a level.
2053         local $level = $level + 1;
2054
2055         # Do any pre-prompt actions.
2056         foreach $evalarg (@$pre) {
2057             &eval;
2058         }
2059
2060         # Complain about too much recursion if we passed the limit.
2061         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2062           if $single & 4;
2063
2064         # The line we're currently on. Set $incr to -1 to stay here
2065         # until we get a command that tells us to advance.
2066         $start = $line;
2067         $incr  = -1;      # for backward motion.
2068
2069         # Tack preprompt debugger actions ahead of any actual input.
2070         @typeahead = ( @$pretype, @typeahead );
2071
2072 =head2 WHERE ARE WE?
2073
2074 XXX Relocate this section?
2075
2076 The debugger normally shows the line corresponding to the current line of
2077 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2078 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2079
2080 C<$incr> controls by how many lines the I<current> line should move forward
2081 after a command is executed. If set to -1, this indicates that the I<current>
2082 line shouldn't change.
2083
2084 C<$start> is the I<current> line. It is used for things like knowing where to
2085 move forwards or backwards from when doing an C<L> or C<-> command.
2086
2087 C<$max> tells the debugger where the last line of the current file is. It's
2088 used to terminate loops most often.
2089
2090 =head2 THE COMMAND LOOP
2091
2092 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2093 in two parts:
2094
2095 =over 4
2096
2097 =item *
2098
2099 The outer part of the loop, starting at the C<CMD> label. This loop
2100 reads a command and then executes it.
2101
2102 =item *
2103
2104 The inner part of the loop, starting at the C<PIPE> label. This part
2105 is wholly contained inside the C<CMD> block and only executes a command.
2106 Used to handle commands running inside a pager.
2107
2108 =back
2109
2110 So why have two labels to restart the loop? Because sometimes, it's easier to
2111 have a command I<generate> another command and then re-execute the loop to do
2112 the new command. This is faster, but perhaps a bit more convoluted.
2113
2114 =cut
2115
2116         # The big command dispatch loop. It keeps running until the
2117         # user yields up control again.
2118         #
2119         # If we have a terminal for input, and we get something back
2120         # from readline(), keep on processing.
2121         my $piped;
2122         my $selected;
2123
2124       CMD:
2125         while (
2126
2127             # We have a terminal, or can get one ...
2128             ( $term || &setterm ),
2129
2130             # ... and it belogs to this PID or we get one for this PID ...
2131             ( $term_pid == $$ or resetterm(1) ),
2132
2133             # ... and we got a line of command input ...
2134             defined(
2135                 $cmd = &readline(
2136                         "$pidprompt $tid DB"
2137                       . ( '<' x $level )
2138                       . ( $#hist + 1 )
2139                       . ( '>' x $level ) . " "
2140                 )
2141             )
2142           )
2143         {
2144
2145                         share($cmd);
2146             # ... try to execute the input as debugger commands.
2147
2148             # Don't stop running.
2149             $single = 0;
2150
2151             # No signal is active.
2152             $signal = 0;
2153
2154             # Handle continued commands (ending with \):
2155             if ($cmd =~ s/\\\z/\n/) {
2156                 $cmd .= &readline("  cont: ");
2157                 redo CMD;
2158             }
2159
2160 =head4 The null command
2161
2162 A newline entered by itself means I<re-execute the last command>. We grab the
2163 command out of C<$laststep> (where it was recorded previously), and copy it
2164 back into C<$cmd> to be executed below. If there wasn't any previous command,
2165 we'll do nothing below (no command will match). If there was, we also save it
2166 in the command history and fall through to allow the command parsing to pick
2167 it up.
2168
2169 =cut
2170
2171             # Empty input means repeat the last command.
2172             $cmd =~ /^$/ && ( $cmd = $laststep );
2173             chomp($cmd);    # get rid of the annoying extra newline
2174             push( @hist, $cmd ) if length($cmd) > 1;
2175             push( @truehist, $cmd );
2176                         share(@hist);
2177                         share(@truehist);
2178
2179             # This is a restart point for commands that didn't arrive
2180             # via direct user input. It allows us to 'redo PIPE' to
2181             # re-execute command processing without reading a new command.
2182           PIPE: {
2183                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2184                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2185                 my ($i) = split( /\s+/, $cmd );
2186
2187 =head3 COMMAND ALIASES
2188
2189 The debugger can create aliases for commands (these are stored in the
2190 C<%alias> hash). Before a command is executed, the command loop looks it up
2191 in the alias hash and substitutes the contents of the alias for the command,
2192 completely replacing it.
2193
2194 =cut
2195
2196                 # See if there's an alias for the command, and set it up if so.
2197                 if ( $alias{$i} ) {
2198
2199                     # Squelch signal handling; we want to keep control here
2200                     # if something goes loco during the alias eval.
2201                     local $SIG{__DIE__};
2202                     local $SIG{__WARN__};
2203
2204                     # This is a command, so we eval it in the DEBUGGER's
2205                     # scope! Otherwise, we can't see the special debugger
2206                     # variables, or get to the debugger's subs. (Well, we
2207                     # _could_, but why make it even more complicated?)
2208                     eval "\$cmd =~ $alias{$i}";
2209                     if ($@) {
2210                         local $\ = '';
2211                         print $OUT "Couldn't evaluate '$i' alias: $@";
2212                         next CMD;
2213                     }
2214                 } ## end if ($alias{$i})
2215
2216 =head3 MAIN-LINE COMMANDS
2217
2218 All of these commands work up to and after the program being debugged has
2219 terminated.
2220
2221 =head4 C<q> - quit
2222
2223 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2224 try to execute further, cleaning any restart-related stuff out of the
2225 environment, and executing with the last value of C<$?>.
2226
2227 =cut
2228
2229                 if ($cmd eq 'q') {
2230                     $fall_off_end = 1;
2231                     clean_ENV();
2232                     exit $?;
2233                 }
2234
2235 =head4 C<t> - trace [n]
2236
2237 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2238 If level is specified, set C<$trace_to_depth>.
2239
2240 =cut
2241
2242                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2243                     $trace ^= 1;
2244                     local $\ = '';
2245                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2246                     print $OUT "Trace = "
2247                       . ( ( $trace & 1 )
2248                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2249                       : "off" ) . "\n";
2250                     next CMD;
2251                 }
2252
2253 =head4 C<S> - list subroutines matching/not matching a pattern
2254
2255 Walks through C<%sub>, checking to see whether or not to print the name.
2256
2257 =cut
2258
2259                 if (my ($print_all_subs, $should_reverse, $Spatt)
2260                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2261                     # $Spatt is the pattern (if any) to use.
2262                     # Reverse scan?
2263                     my $Srev     = defined $should_reverse;
2264                     # No args - print all subs.
2265                     my $Snocheck = !defined $print_all_subs;
2266
2267                     # Need to make these sane here.
2268                     local $\ = '';
2269                     local $, = '';
2270
2271                     # Search through the debugger's magical hash of subs.
2272                     # If $nocheck is true, just print the sub name.
2273                     # Otherwise, check it against the pattern. We then use
2274                     # the XOR trick to reverse the condition as required.
2275                     foreach $subname ( sort( keys %sub ) ) {
2276                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2277                             print $OUT $subname, "\n";
2278                         }
2279                     }
2280                     next CMD;
2281                 }
2282
2283 =head4 C<X> - list variables in current package
2284
2285 Since the C<V> command actually processes this, just change this to the
2286 appropriate C<V> command and fall through.
2287
2288 =cut
2289
2290                 $cmd =~ s/^X\b/V $package/;
2291
2292 =head4 C<V> - list variables
2293
2294 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2295
2296 =cut
2297
2298                 # Bare V commands get the currently-being-debugged package
2299                 # added.
2300                 if ($cmd eq "V") {
2301                     $cmd = "V $package";
2302                 }
2303
2304                 # V - show variables in package.
2305                 if (my ($new_packname, $new_vars_str) =
2306                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2307
2308                     # Save the currently selected filehandle and
2309                     # force output to debugger's filehandle (dumpvar
2310                     # just does "print" for output).
2311                     my $savout = select($OUT);
2312
2313                     # Grab package name and variables to dump.
2314                     $packname = $new_packname;
2315                     my @vars     = split( ' ', $new_vars_str );
2316
2317                     # If main::dumpvar isn't here, get it.
2318                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2319                     if ( defined &main::dumpvar ) {
2320
2321                         # We got it. Turn off subroutine entry/exit messages
2322                         # for the moment, along with return values.
2323                         local $frame = 0;
2324                         local $doret = -2;
2325
2326                         # must detect sigpipe failures  - not catching
2327                         # then will cause the debugger to die.
2328                         eval {
2329                             &main::dumpvar(
2330                                 $packname,
2331                                 defined $option{dumpDepth}
2332                                 ? $option{dumpDepth}
2333                                 : -1,    # assume -1 unless specified
2334                                 @vars
2335                             );
2336                         };
2337
2338                         # The die doesn't need to include the $@, because
2339                         # it will automatically get propagated for us.
2340                         if ($@) {
2341                             die unless $@ =~ /dumpvar print failed/;
2342                         }
2343                     } ## end if (defined &main::dumpvar)
2344                     else {
2345
2346                         # Couldn't load dumpvar.
2347                         print $OUT "dumpvar.pl not available.\n";
2348                     }
2349
2350                     # Restore the output filehandle, and go round again.
2351                     select($savout);
2352                     next CMD;
2353                 }
2354
2355 =head4 C<x> - evaluate and print an expression
2356
2357 Hands the expression off to C<DB::eval>, setting it up to print the value
2358 via C<dumpvar.pl> instead of just printing it directly.
2359
2360 =cut
2361
2362                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2363                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2364
2365                     # handle special  "x 3 blah" syntax XXX propagate
2366                     # doc back to special variables.
2367                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2368                         $onetimedumpDepth = $1;
2369                     }
2370                 }
2371
2372 =head4 C<m> - print methods
2373
2374 Just uses C<DB::methods> to determine what methods are available.
2375
2376 =cut
2377
2378                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2379                     methods($1);
2380                     next CMD;
2381                 }
2382
2383                 # m expr - set up DB::eval to do the work
2384                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2385                     $onetimeDump = 'methods';   #  method output gets used there
2386                 }
2387
2388 =head4 C<f> - switch files
2389
2390 =cut
2391
2392                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2393                     $file =~ s/\s+$//;
2394
2395                     # help for no arguments (old-style was return from sub).
2396                     if ( !$file ) {
2397                         print $OUT
2398                           "The old f command is now the r command.\n";    # hint
2399                         print $OUT "The new f command switches filenames.\n";
2400                         next CMD;
2401                     } ## end if (!$file)
2402
2403                     # if not in magic file list, try a close match.
2404                     if ( !defined $main::{ '_<' . $file } ) {
2405                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2406                             {
2407                                 $try = substr( $try, 2 );
2408                                 print $OUT "Choosing $try matching '$file':\n";
2409                                 $file = $try;
2410                             }
2411                         } ## end if (($try) = grep(m#^_<.*$file#...
2412                     } ## end if (!defined $main::{ ...
2413
2414                     # If not successfully switched now, we failed.
2415                     if ( !defined $main::{ '_<' . $file } ) {
2416                         print $OUT "No file matching '$file' is loaded.\n";
2417                         next CMD;
2418                     }
2419
2420                     # We switched, so switch the debugger internals around.
2421                     elsif ( $file ne $filename ) {
2422                         *dbline   = $main::{ '_<' . $file };
2423                         $max      = $#dbline;
2424                         $filename = $file;
2425                         $start    = 1;
2426                         $cmd      = "l";
2427                     } ## end elsif ($file ne $filename)
2428
2429                     # We didn't switch; say we didn't.
2430                     else {
2431                         print $OUT "Already in $file.\n";
2432                         next CMD;
2433                     }
2434                 }
2435
2436 =head4 C<.> - return to last-executed line.
2437
2438 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2439 and then we look up the line in the magical C<%dbline> hash.
2440
2441 =cut
2442
2443                 # . command.
2444                 if ($cmd eq '.') {
2445                     $incr = -1;    # stay at current line
2446
2447                     # Reset everything to the old location.
2448                     $start    = $line;
2449                     $filename = $filename_ini;
2450                     *dbline   = $main::{ '_<' . $filename };
2451                     $max      = $#dbline;
2452
2453                     # Now where are we?
2454                     print_lineinfo($position);
2455                     next CMD;
2456                 }
2457
2458 =head4 C<-> - back one window
2459
2460 We change C<$start> to be one window back; if we go back past the first line,
2461 we set it to be the first line. We ser C<$incr> to put us back at the
2462 currently-executing line, and then put a C<l $start +> (list one window from
2463 C<$start>) in C<$cmd> to be executed later.
2464
2465 =cut
2466
2467                 # - - back a window.
2468                 if ($cmd eq '-') {
2469
2470                     # back up by a window; go to 1 if back too far.
2471                     $start -= $incr + $window + 1;
2472                     $start = 1 if $start <= 0;
2473                     $incr  = $window - 1;
2474
2475                     # Generate and execute a "l +" command (handled below).
2476                     $cmd = 'l ' . ($start) . '+';
2477                 }
2478
2479 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2480
2481 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2482 problems, most notably that the default case of several commands destroying
2483 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2484 retain the old commands for those who were used to using them or who preferred
2485 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2486 deal with them instead of processing them in-line.
2487
2488 =cut
2489
2490                 # All of these commands were remapped in perl 5.8.0;
2491                 # we send them off to the secondary dispatcher (see below).
2492                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2493                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2494                     next CMD;
2495                 }
2496
2497 =head4 C<y> - List lexicals in higher scope
2498
2499 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2500 above the current one and then displays then using C<dumpvar.pl>.
2501
2502 =cut
2503
2504                 if (my ($match_level, $match_vars)
2505                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2506
2507                     # See if we've got the necessary support.
2508                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2509                       or &warn(
2510                         $@ =~ /locate/
2511                         ? "PadWalker module not found - please install\n"
2512                         : $@
2513                       )
2514                       and next CMD;
2515
2516                     # Load up dumpvar if we don't have it. If we can, that is.
2517                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2518                     defined &main::dumpvar
2519                       or print $OUT "dumpvar.pl not available.\n"
2520                       and next CMD;
2521
2522                     # Got all the modules we need. Find them and print them.
2523                     my @vars = split( ' ', $match_vars || '' );
2524
2525                     # Find the pad.
2526                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2527
2528                     # Oops. Can't find it.
2529                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2530
2531                     # Show the desired vars with dumplex().
2532                     my $savout = select($OUT);
2533
2534                     # Have dumplex dump the lexicals.
2535                     dumpvar::dumplex( $_, $h->{$_},
2536                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2537                         @vars )
2538                       for sort keys %$h;
2539                     select($savout);
2540                     next CMD;
2541                 }
2542
2543 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2544
2545 All of the commands below this point don't work after the program being
2546 debugged has ended. All of them check to see if the program has ended; this
2547 allows the commands to be relocated without worrying about a 'line of
2548 demarcation' above which commands can be entered anytime, and below which
2549 they can't.
2550
2551 =head4 C<n> - single step, but don't trace down into subs
2552
2553 Done by setting C<$single> to 2, which forces subs to execute straight through
2554 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2555 so a null command knows what to re-execute.
2556
2557 =cut
2558
2559                 # n - next
2560                 if ($cmd eq 'n') {
2561                     end_report(), next CMD if $finished and $level <= 1;
2562
2563                     # Single step, but don't enter subs.
2564                     $single = 2;
2565
2566                     # Save for empty command (repeat last).
2567                     $laststep = $cmd;
2568                     last CMD;
2569                 }
2570
2571 =head4 C<s> - single-step, entering subs
2572
2573 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2574 subs. Also saves C<s> as C<$lastcmd>.
2575
2576 =cut
2577
2578                 # s - single step.
2579                 if ($cmd eq 's') {
2580
2581                     # Get out and restart the command loop if program
2582                     # has finished.
2583                     end_report(), next CMD if $finished and $level <= 1;
2584
2585                     # Single step should enter subs.
2586                     $single = 1;
2587
2588                     # Save for empty command (repeat last).
2589                     $laststep = $cmd;
2590                     last CMD;
2591                 }
2592
2593 =head4 C<c> - run continuously, setting an optional breakpoint
2594
2595 Most of the code for this command is taken up with locating the optional
2596 breakpoint, which is either a subroutine name or a line number. We set
2597 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2598 in this and all call levels above this one.
2599
2600 =cut
2601
2602                 # c - start continuous execution.
2603                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2604
2605                     # Hey, show's over. The debugged program finished
2606                     # executing already.
2607                     end_report(), next CMD if $finished and $level <= 1;
2608
2609                     # Capture the place to put a one-time break.
2610                     $subname = $i;
2611
2612                     #  Probably not needed, since we finish an interactive
2613                     #  sub-session anyway...
2614                     # local $filename = $filename;
2615                     # local *dbline = *dbline; # XXX Would this work?!
2616                     #
2617                     # The above question wonders if localizing the alias
2618                     # to the magic array works or not. Since it's commented
2619                     # out, we'll just leave that to speculation for now.
2620
2621                     # If the "subname" isn't all digits, we'll assume it
2622                     # is a subroutine name, and try to find it.
2623                     if ( $subname =~ /\D/ ) {    # subroutine name
2624                             # Qualify it to the current package unless it's
2625                             # already qualified.
2626                         $subname = $package . "::" . $subname
2627                           unless $subname =~ /::/;
2628
2629                         # find_sub will return "file:line_number" corresponding
2630                         # to where the subroutine is defined; we call find_sub,
2631                         # break up the return value, and assign it in one
2632                         # operation.
2633                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2634
2635                         # Force the line number to be numeric.
2636                         $i += 0;
2637
2638                         # If we got a line number, we found the sub.
2639                         if ($i) {
2640
2641                             # Switch all the debugger's internals around so
2642                             # we're actually working with that file.
2643                             $filename = $file;
2644                             *dbline   = $main::{ '_<' . $filename };
2645
2646                             # Mark that there's a breakpoint in this file.
2647                             $had_breakpoints{$filename} |= 1;
2648
2649                             # Scan forward to the first executable line
2650                             # after the 'sub whatever' line.
2651                             $max = $#dbline;
2652                             ++$i while $dbline[$i] == 0 && $i < $max;
2653                         } ## end if ($i)
2654
2655                         # We didn't find a sub by that name.
2656                         else {
2657                             print $OUT "Subroutine $subname not found.\n";
2658                             next CMD;
2659                         }
2660                     } ## end if ($subname =~ /\D/)
2661
2662                     # At this point, either the subname was all digits (an
2663                     # absolute line-break request) or we've scanned through
2664                     # the code following the definition of the sub, looking
2665                     # for an executable, which we may or may not have found.
2666                     #
2667                     # If $i (which we set $subname from) is non-zero, we
2668                     # got a request to break at some line somewhere. On
2669                     # one hand, if there wasn't any real subroutine name
2670                     # involved, this will be a request to break in the current
2671                     # file at the specified line, so we have to check to make
2672                     # sure that the line specified really is breakable.
2673                     #
2674                     # On the other hand, if there was a subname supplied, the
2675                     # preceding block has moved us to the proper file and
2676                     # location within that file, and then scanned forward
2677                     # looking for the next executable line. We have to make
2678                     # sure that one was found.
2679                     #
2680                     # On the gripping hand, we can't do anything unless the
2681                     # current value of $i points to a valid breakable line.
2682                     # Check that.
2683                     if ($i) {
2684
2685                         # Breakable?
2686                         if ( $dbline[$i] == 0 ) {
2687                             print $OUT "Line $i not breakable.\n";
2688                             next CMD;
2689                         }
2690
2691                         # Yes. Set up the one-time-break sigil.
2692                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2693                         _enable_breakpoint_temp_enabled_status($filename, $i);
2694                     } ## end if ($i)
2695
2696                     # Turn off stack tracing from here up.
2697                     for my $i (0 .. $stack_depth) {
2698                         $stack[ $i ] &= ~1;
2699                     }
2700                     last CMD;
2701                 }
2702
2703 =head4 C<r> - return from a subroutine
2704
2705 For C<r> to work properly, the debugger has to stop execution again
2706 immediately after the return is executed. This is done by forcing
2707 single-stepping to be on in the call level above the current one. If
2708 we are printing return values when a C<r> is executed, set C<$doret>
2709 appropriately, and force us out of the command loop.
2710
2711 =cut
2712
2713                 # r - return from the current subroutine.
2714                 if ($cmd eq 'r') {
2715
2716                     # Can't do anything if the program's over.
2717                     end_report(), next CMD if $finished and $level <= 1;
2718
2719                     # Turn on stack trace.
2720                     $stack[$stack_depth] |= 1;
2721
2722                     # Print return value unless the stack is empty.
2723                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2724                     last CMD;
2725                 }
2726
2727 =head4 C<T> - stack trace
2728
2729 Just calls C<DB::print_trace>.
2730
2731 =cut
2732
2733                 if ($cmd eq 'T') {
2734                     print_trace( $OUT, 1 );    # skip DB
2735                     next CMD;
2736                 }
2737
2738 =head4 C<w> - List window around current line.
2739
2740 Just calls C<DB::cmd_w>.
2741
2742 =cut
2743
2744                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2745                     &cmd_w( 'w', $arg );
2746                     next CMD;
2747                 }
2748
2749 =head4 C<W> - watch-expression processing.
2750
2751 Just calls C<DB::cmd_W>.
2752
2753 =cut
2754
2755                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2756                     &cmd_W( 'W', $arg );
2757                     next CMD;
2758                 }
2759
2760 =head4 C</> - search forward for a string in the source
2761
2762 We take the argument and treat it as a pattern. If it turns out to be a
2763 bad one, we return the error we got from trying to C<eval> it and exit.
2764 If not, we create some code to do the search and C<eval> it so it can't
2765 mess us up.
2766
2767 =cut
2768
2769                 # The pattern as a string.
2770                 use vars qw($inpat);
2771
2772                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2773
2774                     # Remove the final slash.
2775                     $inpat =~ s:([^\\])/$:$1:;
2776
2777                     # If the pattern isn't null ...
2778                     if ( $inpat ne "" ) {
2779
2780                         # Turn of warn and die procesing for a bit.
2781                         local $SIG{__DIE__};
2782                         local $SIG{__WARN__};
2783
2784                         # Create the pattern.
2785                         eval '$inpat =~ m' . "\a$inpat\a";
2786                         if ( $@ ne "" ) {
2787
2788                             # Oops. Bad pattern. No biscuit.
2789                             # Print the eval error and go back for more
2790                             # commands.
2791                             print $OUT "$@";
2792                             next CMD;
2793                         }
2794                         $pat = $inpat;
2795                     } ## end if ($inpat ne "")
2796
2797                     # Set up to stop on wrap-around.
2798                     $end = $start;
2799
2800                     # Don't move off the current line.
2801                     $incr = -1;
2802
2803                     # Done in eval so nothing breaks if the pattern
2804                     # does something weird.
2805                     eval '
2806                         for (;;) {
2807                             # Move ahead one line.
2808                             ++$start;
2809
2810                             # Wrap if we pass the last line.
2811                             $start = 1 if ($start > $max);
2812
2813                             # Stop if we have gotten back to this line again,
2814                             last if ($start == $end);
2815
2816                             # A hit! (Note, though, that we are doing
2817                             # case-insensitive matching. Maybe a qr//
2818                             # expression would be better, so the user could
2819                             # do case-sensitive matching if desired.
2820                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2821                                 if ($slave_editor) {
2822                                     # Handle proper escaping in the slave.
2823                                     print $OUT "\032\032$filename:$start:0\n";
2824                                 }
2825                                 else {
2826                                     # Just print the line normally.
2827                                     print $OUT "$start:\t",$dbline[$start],"\n";
2828                                 }
2829                                 # And quit since we found something.
2830                                 last;
2831                             }
2832                          } ';
2833
2834                     # If we wrapped, there never was a match.
2835                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2836                     next CMD;
2837                 }
2838
2839 =head4 C<?> - search backward for a string in the source
2840
2841 Same as for C</>, except the loop runs backwards.
2842
2843 =cut
2844
2845                 # ? - backward pattern search.
2846                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2847
2848                     # Get the pattern, remove trailing question mark.
2849                     $inpat =~ s:([^\\])\?$:$1:;
2850
2851                     # If we've got one ...
2852                     if ( $inpat ne "" ) {
2853
2854                         # Turn off die & warn handlers.
2855                         local $SIG{__DIE__};
2856                         local $SIG{__WARN__};
2857                         eval '$inpat =~ m' . "\a$inpat\a";
2858
2859                         if ( $@ ne "" ) {
2860
2861                             # Ouch. Not good. Print the error.
2862                             print $OUT $@;
2863                             next CMD;
2864                         }
2865                         $pat = $inpat;
2866                     } ## end if ($inpat ne "")
2867
2868                     # Where we are now is where to stop after wraparound.
2869                     $end = $start;
2870
2871                     # Don't move away from this line.
2872                     $incr = -1;
2873
2874                     # Search inside the eval to prevent pattern badness
2875                     # from killing us.
2876                     eval '
2877                         for (;;) {
2878                             # Back up a line.
2879                             --$start;
2880
2881                             # Wrap if we pass the first line.
2882
2883                             $start = $max if ($start <= 0);
2884
2885                             # Quit if we get back where we started,
2886                             last if ($start == $end);
2887
2888                             # Match?
2889                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2890                                 if ($slave_editor) {
2891                                     # Yep, follow slave editor requirements.
2892                                     print $OUT "\032\032$filename:$start:0\n";
2893                                 }
2894                                 else {
2895                                     # Yep, just print normally.
2896                                     print $OUT "$start:\t",$dbline[$start],"\n";
2897                                 }
2898
2899                                 # Found, so done.
2900                                 last;
2901                             }
2902                         } ';
2903
2904                     # Say we failed if the loop never found anything,
2905                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2906                     next CMD;
2907                 }
2908
2909 =head4 C<$rc> - Recall command
2910
2911 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2912 that the terminal supports history). It find the the command required, puts it
2913 into C<$cmd>, and redoes the loop to execute it.
2914
2915 =cut
2916
2917                 # $rc - recall command.
2918                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2919
2920                     # No arguments, take one thing off history.
2921                     pop(@hist) if length($cmd) > 1;
2922
2923                     # Relative (- found)?
2924                     #  Y - index back from most recent (by 1 if bare minus)
2925                     #  N - go to that particular command slot or the last
2926                     #      thing if nothing following.
2927                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2928
2929                     # Pick out the command desired.
2930                     $cmd = $hist[$i];
2931
2932                     # Print the command to be executed and restart the loop
2933                     # with that command in the buffer.
2934                     print $OUT $cmd, "\n";
2935                     redo CMD;
2936                 }
2937
2938 =head4 C<$sh$sh> - C<system()> command
2939
2940 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2941 C<STDOUT> from getting messed up.
2942
2943 =cut
2944
2945                 # $sh$sh - run a shell command (if it's all ASCII).
2946                 # Can't run shell commands with Unicode in the debugger, hmm.
2947                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2948
2949                     # System it.
2950                     &system($arg);
2951                     next CMD;
2952                 }
2953
2954 =head4 C<$rc I<pattern> $rc> - Search command history
2955
2956 Another command to manipulate C<@hist>: this one searches it with a pattern.
2957 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2958
2959 =cut
2960
2961                 # $rc pattern $rc - find a command in the history.
2962                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2963
2964                     # Create the pattern to use.
2965                     $pat = "^$arg";
2966
2967                     # Toss off last entry if length is >1 (and it always is).
2968                     pop(@hist) if length($cmd) > 1;
2969
2970                     # Look backward through the history.
2971                     for ( $i = $#hist ; $i ; --$i ) {
2972                         # Stop if we find it.
2973                         last if $hist[$i] =~ /$pat/;
2974                     }
2975
2976                     if ( !$i ) {
2977
2978                         # Never found it.
2979                         print $OUT "No such command!\n\n";
2980                         next CMD;
2981                     }
2982
2983                     # Found it. Put it in the buffer, print it, and process it.
2984                     $cmd = $hist[$i];
2985                     print $OUT $cmd, "\n";
2986                     redo CMD;
2987                 }
2988
2989 =head4 C<$sh> - Invoke a shell
2990
2991 Uses C<DB::system> to invoke a shell.
2992
2993 =cut
2994
2995                 # $sh - start a shell.
2996                 if ($cmd =~ /\A$sh\z/) {
2997
2998                     # Run the user's shell. If none defined, run Bourne.
2999                     # We resume execution when the shell terminates.
3000                     &system( $ENV{SHELL} || "/bin/sh" );
3001                     next CMD;
3002                 }
3003
3004 =head4 C<$sh I<command>> - Force execution of a command in a shell
3005
3006 Like the above, but the command is passed to the shell. Again, we use
3007 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3008
3009 =cut
3010
3011                 # $sh command - start a shell and run a command in it.
3012                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3013
3014                     # XXX: using csh or tcsh destroys sigint retvals!
3015                     #&system($1);  # use this instead
3016
3017                     # use the user's shell, or Bourne if none defined.
3018                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3019                     next CMD;
3020                 }
3021
3022 =head4 C<H> - display commands in history
3023
3024 Prints the contents of C<@hist> (if any).
3025
3026 =cut
3027
3028                 if ($cmd =~ /\AH\b\s*\*/) {
3029                     @hist = @truehist = ();
3030                     print $OUT "History cleansed\n";
3031                     next CMD;
3032                 }
3033
3034                 if (my ($num)
3035                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3036
3037                     # Anything other than negative numbers is ignored by
3038                     # the (incorrect) pattern, so this test does nothing.
3039                     $end = $num ? ( $#hist - $num ) : 0;
3040
3041                     # Set to the minimum if less than zero.
3042                     $hist = 0 if $hist < 0;
3043
3044                     # Start at the end of the array.
3045                     # Stay in while we're still above the ending value.
3046                     # Tick back by one each time around the loop.
3047                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3048
3049                         # Print the command  unless it has no arguments.
3050                         print $OUT "$i: ", $hist[$i], "\n"
3051                           unless $hist[$i] =~ /^.?$/;
3052                     }
3053                     next CMD;
3054                 }
3055
3056 =head4 C<man, doc, perldoc> - look up documentation
3057
3058 Just calls C<runman()> to print the appropriate document.
3059
3060 =cut
3061
3062                 # man, perldoc, doc - show manual pages.
3063                 if (my ($man_page)
3064                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3065                     runman($man_page);
3066                     next CMD;
3067                 }
3068
3069 =head4 C<p> - print
3070
3071 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3072 the bottom of the loop.
3073
3074 =cut
3075
3076                 my $print_cmd = 'print {$DB::OUT} ';
3077                 # p - print (no args): print $_.
3078                 if ($cmd eq 'p') {
3079                     $cmd = $print_cmd . '$_';
3080                 }
3081
3082                 # p - print the given expression.
3083                 $cmd =~ s/\Ap\b/$print_cmd /;
3084
3085 =head4 C<=> - define command alias
3086
3087 Manipulates C<%alias> to add or list command aliases.
3088
3089 =cut
3090
3091                 # = - set up a command alias.
3092                 if ($cmd =~ s/\A=\s*//) {
3093                     my @keys;
3094                     if ( length $cmd == 0 ) {
3095
3096                         # No args, get current aliases.
3097                         @keys = sort keys %alias;
3098                     }
3099                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3100
3101                         # Creating a new alias. $k is alias name, $v is
3102                         # alias value.
3103
3104                         # can't use $_ or kill //g state
3105                         for my $x ( $k, $v ) {
3106
3107                             # Escape "alarm" characters.
3108                             $x =~ s/\a/\\a/g;
3109                         }
3110
3111                         # Substitute key for value, using alarm chars
3112                         # as separators (which is why we escaped them in
3113                         # the command).
3114                         $alias{$k} = "s\a$k\a$v\a";
3115
3116                         # Turn off standard warn and die behavior.
3117                         local $SIG{__DIE__};
3118                         local $SIG{__WARN__};
3119
3120                         # Is it valid Perl?
3121                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3122
3123                             # Nope. Bad alias. Say so and get out.
3124                             print $OUT "Can't alias $k to $v: $@\n";
3125                             delete $alias{$k};
3126                             next CMD;
3127                         }
3128
3129                         # We'll only list the new one.
3130                         @keys = ($k);
3131                     } ## end elsif (my ($k, $v) = ($cmd...
3132
3133                     # The argument is the alias to list.
3134                     else {
3135                         @keys = ($cmd);
3136                     }
3137
3138                     # List aliases.
3139                     for my $k (@keys) {
3140
3141                         # Messy metaquoting: Trim the substitution code off.
3142                         # We use control-G as the delimiter because it's not
3143                         # likely to appear in the alias.
3144                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3145
3146                             # Print the alias.
3147                             print $OUT "$k\t= $1\n";
3148                         }
3149                         elsif ( defined $alias{$k} ) {
3150
3151                             # Couldn't trim it off; just print the alias code.
3152                             print $OUT "$k\t$alias{$k}\n";
3153                         }
3154                         else {
3155
3156                             # No such, dude.
3157                             print "No alias for $k\n";
3158                         }
3159                     } ## end for my $k (@keys)
3160                     next CMD;
3161                 }
3162
3163 =head4 C<source> - read commands from a file.
3164
3165 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3166 pick it up.
3167
3168 =cut
3169
3170                 # source - read commands from a file (or pipe!) and execute.
3171                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3172                     if ( open my $fh, $sourced_fn ) {
3173
3174                         # Opened OK; stick it in the list of file handles.
3175                         push @cmdfhs, $fh;
3176                     }
3177                     else {
3178
3179                         # Couldn't open it.
3180                         &warn("Can't execute '$sourced_fn': $!\n");
3181                     }
3182                     next CMD;
3183                 }
3184
3185                 if (my ($which_cmd, $position)
3186                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3187
3188                     my ($fn, $line_num);
3189                     if ($position =~ m{\A\d+\z})
3190                     {
3191                         $fn = $filename;
3192                         $line_num = $position;
3193                     }
3194                     elsif (my ($new_fn, $new_line_num)
3195                         = $position =~ m{\A(.*):(\d+)\z}) {
3196                         ($fn, $line_num) = ($new_fn, $new_line_num);
3197                     }
3198                     else
3199                     {
3200                         &warn("Wrong spec for enable/disable argument.\n");
3201                     }
3202
3203                     if (defined($fn)) {
3204                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3205                             _set_breakpoint_enabled_status($fn, $line_num,
3206                                 ($which_cmd eq 'enable' ? 1 : '')
3207                             );
3208                         }
3209                         else {
3210                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3211                         }
3212                     }
3213
3214                     next CMD;
3215                 }
3216
3217 =head4 C<save> - send current history to a file
3218
3219 Takes the complete history, (not the shrunken version you see with C<H>),
3220 and saves it to the given filename, so it can be replayed using C<source>.
3221
3222 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3223
3224 =cut
3225
3226                 # save source - write commands to a file for later use
3227                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3228                     my $filename = $new_fn || '.perl5dbrc';    # default?
3229                     if ( open my $fh, '>', $filename ) {
3230
3231                        # chomp to remove extraneous newlines from source'd files
3232                         chomp( my @truelist =
3233                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3234                               @truehist );
3235                         print $fh join( "\n", @truelist );
3236                         print "commands saved in $file\n";
3237                     }
3238                     else {
3239                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3240                     }
3241                     next CMD;
3242                 }
3243
3244 =head4 C<R> - restart
3245
3246 Restart the debugger session.
3247
3248 =head4 C<rerun> - rerun the current session
3249
3250 Return to any given position in the B<true>-history list
3251
3252 =cut
3253
3254                 # R - restart execution.
3255                 # rerun - controlled restart execution.
3256                 if (my ($cmd_cmd, $cmd_params) =
3257                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3258                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3259
3260                     # Close all non-system fds for a clean restart.  A more
3261                     # correct method would be to close all fds that were not
3262                     # open when the process started, but this seems to be
3263                     # hard.  See "debugger 'R'estart and open database
3264                     # connections" on p5p.
3265
3266                     my $max_fd = 1024; # default if POSIX can't be loaded
3267                     if (eval { require POSIX }) {
3268                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3269                     }
3270
3271                     if (defined $max_fd) {
3272                         foreach ($^F+1 .. $max_fd-1) {
3273                             next unless open FD_TO_CLOSE, "<&=$_";
3274                             close(FD_TO_CLOSE);
3275                         }
3276                     }
3277
3278                     # And run Perl again.  We use exec() to keep the
3279                     # PID stable (and that way $ini_pids is still valid).
3280                     exec(@args) || print $OUT "exec failed: $!\n";
3281
3282                     last CMD;
3283                 }
3284
3285 =head4 C<|, ||> - pipe output through the pager.
3286
3287 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3288 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3289 pipe to the pager (restoring the output filehandles if this fails). If this
3290 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3291 set C<$signal>, sending us back into the debugger.
3292
3293 We then trim off the pipe symbols and C<redo> the command loop at the
3294 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3295 reading another.
3296
3297 =cut
3298
3299                 # || - run command in the pager, with output to DB::OUT.
3300                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3301                     if ( $pager =~ /^\|/ ) {
3302
3303                         # Default pager is into a pipe. Redirect I/O.
3304                         open( SAVEOUT, ">&STDOUT" )
3305                           || &warn("Can't save STDOUT");
3306                         open( STDOUT, ">&OUT" )
3307                           || &warn("Can't redirect STDOUT");
3308                     } ## end if ($pager =~ /^\|/)
3309                     else {
3310
3311                         # Not into a pipe. STDOUT is safe.
3312                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3313                     }
3314
3315                     # Fix up environment to record we have less if so.
3316                     fix_less();
3317
3318                     unless ( $piped = open( OUT, $pager ) ) {
3319
3320                         # Couldn't open pipe to pager.
3321                         &warn("Can't pipe output to '$pager'");
3322                         if ( $pager =~ /^\|/ ) {
3323
3324                             # Redirect I/O back again.
3325                             open( OUT, ">&STDOUT" )    # XXX: lost message
3326                               || &warn("Can't restore DB::OUT");
3327                             open( STDOUT, ">&SAVEOUT" )
3328                               || &warn("Can't restore STDOUT");
3329                             close(SAVEOUT);
3330                         } ## end if ($pager =~ /^\|/)
3331                         else {
3332
3333                             # Redirect I/O. STDOUT already safe.
3334                             open( OUT, ">&STDOUT" )    # XXX: lost message
3335                               || &warn("Can't restore DB::OUT");
3336                         }
3337                         next CMD;
3338                     } ## end unless ($piped = open(OUT,...
3339
3340                     # Set up broken-pipe handler if necessary.
3341                     $SIG{PIPE} = \&DB::catch
3342                       if $pager =~ /^\|/
3343                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3344
3345                     OUT->autoflush(1);
3346                     # Save current filehandle, and put it back.
3347                     $selected = select(OUT);
3348                     # Don't put it back if pager was a pipe.
3349                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3350
3351                     # Trim off the pipe symbols and run the command now.
3352                     $cmd =~ s#\A\|+\s*##;
3353                     redo PIPE;
3354                 }
3355
3356 =head3 END OF COMMAND PARSING
3357
3358 Anything left in C<$cmd> at this point is a Perl expression that we want to
3359 evaluate. We'll always evaluate in the user's context, and fully qualify
3360 any variables we might want to address in the C<DB> package.
3361
3362 =cut
3363
3364                 # t - turn trace on.
3365                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3366                     my $trace_arg = $1;
3367                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3368                 }
3369
3370                 # s - single-step. Remember the last command was 's'.
3371                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3372                     $laststep = 's';
3373                 }
3374
3375                 # n - single-step, but not into subs. Remember last command
3376                 # was 'n'.
3377                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3378                     $laststep = 'n';
3379                 }
3380
3381             }    # PIPE:
3382
3383             # Make sure the flag that says "the debugger's running" is
3384             # still on, to make sure we get control again.
3385             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3386
3387             # Run *our* eval that executes in the caller's context.
3388             &eval;
3389
3390             # Turn off the one-time-dump stuff now.
3391             if ($onetimeDump) {
3392                 $onetimeDump      = undef;
3393                 $onetimedumpDepth = undef;
3394             }
3395             elsif ( $term_pid == $$ ) {
3396                 eval {          # May run under miniperl, when not available...
3397                     STDOUT->flush();
3398                     STDERR->flush();
3399                 };
3400
3401                 # XXX If this is the master pid, print a newline.
3402                 print $OUT "\n";
3403             }
3404         } ## end while (($term || &setterm...
3405
3406 =head3 POST-COMMAND PROCESSING
3407
3408 After each command, we check to see if the command output was piped anywhere.
3409 If so, we go through the necessary code to unhook the pipe and go back to
3410 our standard filehandles for input and output.
3411
3412 =cut
3413
3414         continue {    # CMD:
3415
3416             # At the end of every command:
3417             if ($piped) {
3418
3419                 # Unhook the pipe mechanism now.
3420                 if ( $pager =~ /^\|/ ) {
3421
3422                     # No error from the child.
3423                     $? = 0;
3424
3425                     # we cannot warn here: the handle is missing --tchrist
3426                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3427
3428                     # most of the $? crud was coping with broken cshisms
3429                     # $? is explicitly set to 0, so this never runs.
3430                     if ($?) {
3431                         print SAVEOUT "Pager '$pager' failed: ";
3432                         if ( $? == -1 ) {
3433                             print SAVEOUT "shell returned -1\n";
3434                         }
3435                         elsif ( $? >> 8 ) {
3436                             print SAVEOUT ( $? & 127 )
3437                               ? " (SIG#" . ( $? & 127 ) . ")"
3438                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3439                         }
3440                         else {
3441                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3442                         }
3443                     } ## end if ($?)
3444
3445                     # Reopen filehandle for our output (if we can) and
3446                     # restore STDOUT (if we can).
3447                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3448                     open( STDOUT, ">&SAVEOUT" )
3449                       || &warn("Can't restore STDOUT");
3450
3451                     # Turn off pipe exception handler if necessary.
3452                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3453
3454                     # Will stop ignoring SIGPIPE if done like nohup(1)
3455                     # does SIGINT but Perl doesn't give us a choice.
3456                 } ## end if ($pager =~ /^\|/)
3457                 else {
3458
3459                     # Non-piped "pager". Just restore STDOUT.
3460                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3461                 }
3462
3463                 # Close filehandle pager was using, restore the normal one
3464                 # if necessary,
3465                 close(SAVEOUT);
3466                 select($selected), $selected = "" unless $selected eq "";
3467
3468                 # No pipes now.
3469                 $piped = "";
3470             } ## end if ($piped)
3471         }    # CMD:
3472
3473 =head3 COMMAND LOOP TERMINATION
3474
3475 When commands have finished executing, we come here. If the user closed the
3476 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3477 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3478 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3479 The interpreter will then execute the next line and then return control to us
3480 again.
3481
3482 =cut
3483
3484         # No more commands? Quit.
3485         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3486
3487         # Evaluate post-prompt commands.
3488         foreach $evalarg (@$post) {
3489             &eval;
3490         }
3491     }    # if ($single || $signal)
3492
3493     # Put the user's globals back where you found them.
3494     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3495     ();
3496 } ## end sub DB
3497
3498 # The following code may be executed now:
3499 # BEGIN {warn 4}
3500
3501 =head2 sub
3502
3503 C<sub> is called whenever a subroutine call happens in the program being
3504 debugged. The variable C<$DB::sub> contains the name of the subroutine
3505 being called.
3506
3507 The core function of this subroutine is to actually call the sub in the proper
3508 context, capturing its output. This of course causes C<DB::DB> to get called
3509 again, repeating until the subroutine ends and returns control to C<DB::sub>
3510 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3511 return value, and returns its captured copy of the return value as its own
3512 return value. The value then feeds back into the program being debugged as if
3513 C<DB::sub> hadn't been there at all.
3514
3515 C<sub> does all the work of printing the subroutine entry and exit messages
3516 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3517 and also prints the return value if needed (for the C<r> command and if
3518 the 16 bit is set in C<$frame>).
3519
3520 It also tracks the subroutine call depth by saving the current setting of
3521 C<$single> in the C<@stack> package global; if this exceeds the value in
3522 C<$deep>, C<sub> automatically turns on printing of the current depth by
3523 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3524 of stop/don't stop on entry to subs set as it currently is set.
3525
3526 =head3 C<caller()> support
3527
3528 If C<caller()> is called from the package C<DB>, it provides some
3529 additional data, in the following order:
3530
3531 =over 4
3532
3533 =item * C<$package>
3534
3535 The package name the sub was in
3536
3537 =item * C<$filename>
3538
3539 The filename it was defined in
3540
3541 =item * C<$line>
3542
3543 The line number it was defined on
3544
3545 =item * C<$subroutine>
3546
3547 The subroutine name; C<(eval)> if an C<eval>().
3548
3549 =item * C<$hasargs>
3550
3551 1 if it has arguments, 0 if not
3552
3553 =item * C<$wantarray>
3554
3555 1 if array context, 0 if scalar context
3556
3557 =item * C<$evaltext>
3558
3559 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3560
3561 =item * C<$is_require>
3562
3563 frame was created by a C<use> or C<require> statement
3564
3565 =item * C<$hints>
3566
3567 pragma information; subject to change between versions
3568
3569 =item * C<$bitmask>
3570
3571 pragma information; subject to change between versions
3572
3573 =item * C<@DB::args>
3574
3575 arguments with which the subroutine was invoked
3576
3577 =back
3578
3579 =cut
3580
3581 use vars qw($deep);
3582
3583 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3584 # happy. -- Shlomi Fish
3585 sub DB::sub {
3586         # Do not use a regex in this subroutine -> results in corrupted memory
3587         # See: [perl #66110]
3588
3589         # lock ourselves under threads
3590         lock($DBGR);
3591
3592     # Whether or not the autoloader was running, a scalar to put the
3593     # sub's return value in (if needed), and an array to put the sub's
3594     # return value in (if needed).
3595     my ( $al, $ret, @ret ) = "";
3596         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3597                 print "creating new thread\n";
3598         }
3599
3600     # If the last ten characters are '::AUTOLOAD', note we've traced
3601     # into AUTOLOAD for $sub.
3602     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3603         no strict 'refs';
3604         $al = " for $$sub" if defined $$sub;
3605     }
3606
3607     # We stack the stack pointer and then increment it to protect us
3608     # from a situation that might unwind a whole bunch of call frames
3609     # at once. Localizing the stack pointer means that it will automatically
3610     # unwind the same amount when multiple stack frames are unwound.
3611     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3612
3613     # Expand @stack.
3614     $#stack = $stack_depth;
3615
3616     # Save current single-step setting.
3617     $stack[-1] = $single;
3618
3619     # Turn off all flags except single-stepping.
3620     $single &= 1;
3621
3622     # If we've gotten really deeply recursed, turn on the flag that will
3623     # make us stop with the 'deep recursion' message.
3624     $single |= 4 if $stack_depth == $deep;
3625
3626     # If frame messages are on ...
3627     (
3628         $frame & 4    # Extended frame entry message
3629         ? (
3630             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3631
3632             # Why -1? But it works! :-(
3633             # Because print_trace will call add 1 to it and then call
3634             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3635             # in dump_trace.
3636             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3637           )
3638         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3639
3640           # standard frame entry message
3641       )
3642       if $frame;
3643
3644     # Determine the sub's return type, and capture appropriately.
3645     if (wantarray) {
3646
3647         # Called in array context. call sub and capture output.
3648         # DB::DB will recursively get control again if appropriate; we'll come
3649         # back here when the sub is finished.
3650         {
3651             no strict 'refs';
3652             @ret = &$sub;
3653         }
3654
3655         # Pop the single-step value back off the stack.
3656         $single |= $stack[ $stack_depth-- ];
3657
3658         # Check for exit trace messages...
3659         (
3660             $frame & 4    # Extended exit message
3661             ? (
3662                 print_lineinfo( ' ' x $stack_depth, "out " ),
3663                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3664               )
3665             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3666
3667               # Standard exit message
3668           )
3669           if $frame & 2;
3670
3671         # Print the return info if we need to.
3672         if ( $doret eq $stack_depth or $frame & 16 ) {
3673
3674             # Turn off output record separator.
3675             local $\ = '';
3676             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3677
3678             # Indent if we're printing because of $frame tracing.
3679             print $fh ' ' x $stack_depth if $frame & 16;
3680
3681             # Print the return value.
3682             print $fh "list context return from $sub:\n";
3683             dumpit( $fh, \@ret );
3684
3685             # And don't print it again.
3686             $doret = -2;
3687         } ## end if ($doret eq $stack_depth...
3688             # And we have to return the return value now.
3689         @ret;
3690     } ## end if (wantarray)
3691
3692     # Scalar context.
3693     else {
3694         if ( defined wantarray ) {
3695         no strict 'refs';
3696             # Save the value if it's wanted at all.
3697             $ret = &$sub;
3698         }
3699         else {
3700         no strict 'refs';
3701             # Void return, explicitly.
3702             &$sub;
3703             undef $ret;
3704         }
3705
3706         # Pop the single-step value off the stack.
3707         $single |= $stack[ $stack_depth-- ];
3708
3709         # If we're doing exit messages...
3710         (
3711             $frame & 4    # Extended messages
3712             ? (
3713                 print_lineinfo( ' ' x $stack_depth, "out " ),
3714                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3715               )
3716             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3717
3718               # Standard messages
3719           )
3720           if $frame & 2;
3721
3722         # If we are supposed to show the return value... same as before.
3723         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3724             local $\ = '';
3725             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3726             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3727             print $fh (
3728                 defined wantarray
3729                 ? "scalar context return from $sub: "
3730                 : "void context return from $sub\n"
3731             );
3732             dumpit( $fh, $ret ) if defined wantarray;
3733             $doret = -2;
3734         } ## end if ($doret eq $stack_depth...
3735
3736         # Return the appropriate scalar value.
3737         $ret;
3738     } ## end else [ if (wantarray)
3739 } ## end sub _sub
3740
3741 sub lsub : lvalue {
3742
3743     no strict 'refs';
3744
3745         # lock ourselves under threads
3746         lock($DBGR);
3747
3748     # Whether or not the autoloader was running, a scalar to put the
3749     # sub's return value in (if needed), and an array to put the sub's
3750     # return value in (if needed).
3751     my ( $al, $ret, @ret ) = "";
3752         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3753                 print "creating new thread\n";
3754         }
3755
3756     # If the last ten characters are C'::AUTOLOAD', note we've traced
3757     # into AUTOLOAD for $sub.
3758     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3759         $al = " for $$sub";
3760     }
3761
3762     # We stack the stack pointer and then increment it to protect us
3763     # from a situation that might unwind a whole bunch of call frames
3764     # at once. Localizing the stack pointer means that it will automatically
3765     # unwind the same amount when multiple stack frames are unwound.
3766     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3767
3768     # Expand @stack.
3769     $#stack = $stack_depth;
3770
3771     # Save current single-step setting.
3772     $stack[-1] = $single;
3773
3774     # Turn off all flags except single-stepping.
3775     $single &= 1;
3776
3777     # If we've gotten really deeply recursed, turn on the flag that will
3778     # make us stop with the 'deep recursion' message.
3779     $single |= 4 if $stack_depth == $deep;
3780
3781     # If frame messages are on ...
3782     (
3783         $frame & 4    # Extended frame entry message
3784         ? (
3785             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3786
3787             # Why -1? But it works! :-(
3788             # Because print_trace will call add 1 to it and then call
3789             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3790             # in dump_trace.
3791             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3792           )
3793         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3794
3795           # standard frame entry message
3796       )
3797       if $frame;
3798
3799     # Pop the single-step value back off the stack.
3800     $single |= $stack[ $stack_depth-- ];
3801
3802     # call the original lvalue sub.
3803     &$sub;
3804 }
3805
3806 # Abstracting common code from multiple places elsewhere:
3807 sub depth_print_lineinfo {
3808     my $always_print = shift;
3809
3810     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3811 }
3812
3813 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3814
3815 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3816 Most of the changes were to systematize the command structure and to eliminate
3817 commands that threw away user input without checking.
3818
3819 The following sections describe the code added to make it easy to support
3820 multiple command sets with conflicting command names. This section is a start
3821 at unifying all command processing to make it simpler to develop commands.
3822
3823 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3824 number, and C<$dbline> (the current line) as arguments.
3825
3826 Support functions in this section which have multiple modes of failure C<die>
3827 on error; the rest simply return a false value.
3828
3829 The user-interface functions (all of the C<cmd_*> functions) just output
3830 error messages.
3831
3832 =head2 C<%set>
3833
3834 The C<%set> hash defines the mapping from command letter to subroutine
3835 name suffix.
3836
3837 C<%set> is a two-level hash, indexed by set name and then by command name.
3838 Note that trying to set the CommandSet to C<foobar> simply results in the
3839 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3840
3841 =cut
3842
3843 ### The API section
3844
3845 my %set = (    #
3846     'pre580' => {
3847         'a' => 'pre580_a',
3848         'A' => 'pre580_null',
3849         'b' => 'pre580_b',
3850         'B' => 'pre580_null',
3851         'd' => 'pre580_null',
3852         'D' => 'pre580_D',
3853         'h' => 'pre580_h',
3854         'M' => 'pre580_null',
3855         'O' => 'o',
3856         'o' => 'pre580_null',
3857         'v' => 'M',
3858         'w' => 'v',
3859         'W' => 'pre580_W',
3860     },
3861     'pre590' => {
3862         '<'  => 'pre590_prepost',
3863         '<<' => 'pre590_prepost',
3864         '>'  => 'pre590_prepost',
3865         '>>' => 'pre590_prepost',
3866         '{'  => 'pre590_prepost',
3867         '{{' => 'pre590_prepost',
3868     },
3869 );
3870
3871 my %breakpoints_data;
3872
3873 sub _has_breakpoint_data_ref {
3874     my ($filename, $line) = @_;
3875
3876     return (
3877         exists( $breakpoints_data{$filename} )
3878             and
3879         exists( $breakpoints_data{$filename}{$line} )
3880     );
3881 }
3882
3883 sub _get_breakpoint_data_ref {
3884     my ($filename, $line) = @_;
3885
3886     return ($breakpoints_data{$filename}{$line} ||= +{});
3887 }
3888
3889 sub _delete_breakpoint_data_ref {
3890     my ($filename, $line) = @_;
3891
3892     delete($breakpoints_data{$filename}{$line});
3893     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3894         delete($breakpoints_data{$filename});
3895     }
3896
3897     return;
3898 }
3899
3900 sub _set_breakpoint_enabled_status {
3901     my ($filename, $line, $status) = @_;
3902
3903     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3904         ($status ? 1 : '')
3905         ;
3906
3907     return;
3908 }
3909
3910 sub _enable_breakpoint_temp_enabled_status {
3911     my ($filename, $line) = @_;
3912
3913     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3914
3915     return;
3916 }
3917
3918 sub _cancel_breakpoint_temp_enabled_status {
3919     my ($filename, $line) = @_;
3920
3921     my $ref = _get_breakpoint_data_ref($filename, $line);
3922
3923     delete ($ref->{'temp_enabled'});
3924
3925     if (! %$ref) {
3926         _delete_breakpoint_data_ref($filename, $line);
3927     }
3928
3929     return;
3930 }
3931
3932 sub _is_breakpoint_enabled {
3933     my ($filename, $line) = @_;
3934
3935     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3936     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3937 }
3938
3939 =head2 C<cmd_wrapper()> (API)
3940
3941 C<cmd_wrapper()> allows the debugger to switch command sets
3942 depending on the value of the C<CommandSet> option.
3943
3944 It tries to look up the command in the C<%set> package-level I<lexical>
3945 (which means external entities can't fiddle with it) and create the name of
3946 the sub to call based on the value found in the hash (if it's there). I<All>
3947 of the commands to be handled in a set have to be added to C<%set>; if they
3948 aren't found, the 5.8.0 equivalent is called (if there is one).
3949
3950 This code uses symbolic references.
3951
3952 =cut
3953
3954 sub cmd_wrapper {
3955     my $cmd      = shift;
3956     my $line     = shift;
3957     my $dblineno = shift;
3958
3959     # Assemble the command subroutine's name by looking up the
3960     # command set and command name in %set. If we can't find it,
3961     # default to the older version of the command.
3962     my $call = 'cmd_'
3963       . ( $set{$CommandSet}{$cmd}
3964           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3965
3966     # Call the command subroutine, call it by name.
3967     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3968 } ## end sub cmd_wrapper
3969
3970 =head3 C<cmd_a> (command)
3971
3972 The C<a> command handles pre-execution actions. These are associated with a
3973 particular line, so they're stored in C<%dbline>. We default to the current
3974 line if none is specified.
3975
3976 =cut
3977
3978 sub cmd_a {
3979     my $cmd    = shift;
3980     my $line   = shift || '';    # [.|line] expr
3981     my $dbline = shift;
3982
3983     # If it's dot (here), or not all digits,  use the current line.
3984     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3985
3986     # Should be a line number followed by an expression.
3987     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3988         my ( $lineno, $expr ) = ( $1, $2 );
3989
3990         # If we have an expression ...
3991         if ( length $expr ) {
3992
3993             # ... but the line isn't breakable, complain.
3994             if ( $dbline[$lineno] == 0 ) {
3995                 print $OUT
3996                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3997             }
3998             else {
3999
4000                 # It's executable. Record that the line has an action.
4001                 $had_breakpoints{$filename} |= 2;
4002
4003                 # Remove any action, temp breakpoint, etc.
4004                 $dbline{$lineno} =~ s/\0[^\0]*//;
4005
4006                 # Add the action to the line.
4007                 $dbline{$lineno} .= "\0" . action($expr);
4008
4009                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4010             }
4011         } ## end if (length $expr)
4012     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4013     else {
4014
4015         # Syntax wrong.
4016         print $OUT
4017           "Adding an action requires an optional lineno and an expression\n"
4018           ;    # hint
4019     }
4020 } ## end sub cmd_a
4021
4022 =head3 C<cmd_A> (command)
4023
4024 Delete actions. Similar to above, except the delete code is in a separate
4025 subroutine, C<delete_action>.
4026
4027 =cut
4028
4029 sub cmd_A {
4030     my $cmd    = shift;
4031     my $line   = shift || '';
4032     my $dbline = shift;
4033
4034     # Dot is this line.
4035     $line =~ s/^\./$dbline/;
4036
4037     # Call delete_action with a null param to delete them all.
4038     # The '1' forces the eval to be true. It'll be false only
4039     # if delete_action blows up for some reason, in which case
4040     # we print $@ and get out.
4041     if ( $line eq '*' ) {
4042         eval { &delete_action(); 1 } or print $OUT $@ and return;
4043     }
4044
4045     # There's a real line  number. Pass it to delete_action.
4046     # Error trapping is as above.
4047     elsif ( $line =~ /^(\S.*)/ ) {
4048         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4049     }
4050
4051     # Swing and a miss. Bad syntax.
4052     else {
4053         print $OUT
4054           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4055     }
4056 } ## end sub cmd_A
4057
4058 =head3 C<delete_action> (API)
4059
4060 C<delete_action> accepts either a line number or C<undef>. If a line number
4061 is specified, we check for the line being executable (if it's not, it
4062 couldn't have had an  action). If it is, we just take the action off (this
4063 will get any kind of an action, including breakpoints).
4064
4065 =cut
4066
4067 sub delete_action {
4068     my $i = shift;
4069     if ( defined($i) ) {
4070
4071         # Can there be one?
4072         die "Line $i has no action .\n" if $dbline[$i] == 0;
4073
4074         # Nuke whatever's there.
4075         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4076         delete $dbline{$i} if $dbline{$i} eq '';
4077     }
4078     else {
4079         print $OUT "Deleting all actions...\n";
4080         for my $file ( keys %had_breakpoints ) {
4081             local *dbline = $main::{ '_<' . $file };
4082             $max = $#dbline;
4083             my $was;
4084             for $i (1 .. $max) {
4085                 if ( defined $dbline{$i} ) {
4086                     $dbline{$i} =~ s/\0[^\0]*//;
4087                     delete $dbline{$i} if $dbline{$i} eq '';
4088                 }
4089                 unless ( $had_breakpoints{$file} &= ~2 ) {
4090                     delete $had_breakpoints{$file};
4091                 }
4092             } ## end for ($i = 1 .. $max)
4093         } ## end for my $file (keys %had_breakpoints)
4094     } ## end else [ if (defined($i))
4095 } ## end sub delete_action
4096
4097 =head3 C<cmd_b> (command)
4098
4099 Set breakpoints. Since breakpoints can be set in so many places, in so many
4100 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4101 we try to parse the command type, and then shuttle it off to an appropriate
4102 subroutine to actually do the work of setting the breakpoint in the right
4103 place.
4104
4105 =cut
4106
4107 sub cmd_b {
4108     my $cmd    = shift;
4109     my $line   = shift;    # [.|line] [cond]
4110     my $dbline = shift;
4111
4112     # Make . the current line number if it's there..
4113     $line =~ s/^\.(\s|\z)/$dbline$1/;
4114
4115     # No line number, no condition. Simple break on current line.
4116     if ( $line =~ /^\s*$/ ) {
4117         &cmd_b_line( $dbline, 1 );
4118     }
4119
4120     # Break on load for a file.
4121     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4122         my $file = $1;
4123         $file =~ s/\s+$//;
4124         &cmd_b_load($file);
4125     }
4126
4127     # b compile|postpone <some sub> [<condition>]
4128     # The interpreter actually traps this one for us; we just put the
4129     # necessary condition in the %postponed hash.
4130     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4131
4132         # Capture the condition if there is one. Make it true if none.
4133         my $cond = length $3 ? $3 : '1';
4134
4135         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4136         # if it was 'compile'.
4137         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4138
4139         # De-Perl4-ify the name - ' separators to ::.
4140         $subname =~ s/\'/::/g;
4141
4142         # Qualify it into the current package unless it's already qualified.
4143         $subname = "${package}::" . $subname unless $subname =~ /::/;
4144
4145         # Add main if it starts with ::.
4146         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4147
4148         # Save the break type for this sub.
4149         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4150     } ## end elsif ($line =~ ...
4151     # b <filename>:<line> [<condition>]
4152     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4153         my ($filename, $line_num, $cond) = ($1, $2, $3);
4154         cmd_b_filename_line(
4155             $filename,
4156             $line_num,
4157             (length($cond) ? $cond : '1'),
4158         );
4159     }
4160     # b <sub name> [<condition>]
4161     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4162
4163         #
4164         $subname = $1;
4165         my $cond = length $2 ? $2 : '1';
4166         &cmd_b_sub( $subname, $cond );
4167     }
4168
4169     # b <line> [<condition>].
4170     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4171
4172         # Capture the line. If none, it's the current line.
4173         $line = $1 || $dbline;
4174
4175         # If there's no condition, make it '1'.
4176         my $cond = length $2 ? $2 : '1';
4177
4178         # Break on line.
4179         &cmd_b_line( $line, $cond );
4180     }
4181
4182     # Line didn't make sense.
4183     else {
4184         print "confused by line($line)?\n";
4185     }
4186 } ## end sub cmd_b
4187
4188 =head3 C<break_on_load> (API)
4189
4190 We want to break when this file is loaded. Mark this file in the
4191 C<%break_on_load> hash, and note that it has a breakpoint in
4192 C<%had_breakpoints>.
4193
4194 =cut
4195
4196 sub break_on_load {
4197     my $file = shift;
4198     $break_on_load{$file} = 1;
4199     $had_breakpoints{$file} |= 1;
4200 }
4201
4202 =head3 C<report_break_on_load> (API)
4203
4204 Gives us an array of filenames that are set to break on load. Note that
4205 only files with break-on-load are in here, so simply showing the keys
4206 suffices.
4207
4208 =cut
4209
4210 sub report_break_on_load {
4211     sort keys %break_on_load;
4212 }
4213
4214 =head3 C<cmd_b_load> (command)
4215
4216 We take the file passed in and try to find it in C<%INC> (which maps modules
4217 to files they came from). We mark those files for break-on-load via
4218 C<break_on_load> and then report that it was done.
4219
4220 =cut
4221
4222 sub cmd_b_load {
4223     my $file = shift;
4224     my @files;
4225
4226     # This is a block because that way we can use a redo inside it
4227     # even without there being any looping structure at all outside it.
4228     {
4229
4230         # Save short name and full path if found.
4231         push @files, $file;
4232         push @files, $::INC{$file} if $::INC{$file};
4233
4234         # Tack on .pm and do it again unless there was a '.' in the name
4235         # already.
4236         $file .= '.pm', redo unless $file =~ /\./;
4237     }
4238
4239     # Do the real work here.
4240     break_on_load($_) for @files;
4241
4242     # All the files that have break-on-load breakpoints.
4243     @files = report_break_on_load;
4244
4245     # Normalize for the purposes of our printing this.
4246     local $\ = '';
4247     local $" = ' ';
4248     print $OUT "Will stop on load of '@files'.\n";
4249 } ## end sub cmd_b_load
4250
4251 =head3 C<$filename_error> (API package global)
4252
4253 Several of the functions we need to implement in the API need to work both
4254 on the current file and on other files. We don't want to duplicate code, so
4255 C<$filename_error> is used to contain the name of the file that's being
4256 worked on (if it's not the current one).
4257
4258 We can now build functions in pairs: the basic function works on the current
4259 file, and uses C<$filename_error> as part of its error message. Since this is
4260 initialized to C<"">, no filename will appear when we are working on the
4261 current file.
4262
4263 The second function is a wrapper which does the following:
4264
4265 =over 4
4266
4267 =item *
4268
4269 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4270
4271 =item *
4272
4273 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4274
4275 =item *
4276
4277 Calls the first function.
4278
4279 The first function works on the I<current> file (i.e., the one we changed to),
4280 and prints C<$filename_error> in the error message (the name of the other file)
4281 if it needs to. When the functions return, C<*dbline> is restored to point
4282 to the actual current file (the one we're executing in) and
4283 C<$filename_error> is restored to C<"">. This restores everything to
4284 the way it was before the second function was called at all.
4285
4286 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4287 details.
4288
4289 =back
4290
4291 =cut
4292
4293 use vars qw($filename_error);
4294 $filename_error = '';
4295
4296 =head3 breakable_line(from, to) (API)
4297
4298 The subroutine decides whether or not a line in the current file is breakable.
4299 It walks through C<@dbline> within the range of lines specified, looking for
4300 the first line that is breakable.
4301
4302 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4303 first line I<after> C<$to> that's breakable, if there is one.
4304
4305 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4306 first line I<before> C<$to> that's breakable, if there is one.
4307
4308 =cut
4309
4310 sub breakable_line {
4311
4312     my ( $from, $to ) = @_;
4313
4314     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4315     my $i = $from;
4316
4317     # If there are at least 2 arguments, we're trying to search a range.
4318     if ( @_ >= 2 ) {
4319
4320         # $delta is positive for a forward search, negative for a backward one.
4321         my $delta = $from < $to ? +1 : -1;
4322
4323         # Keep us from running off the ends of the file.
4324         my $limit = $delta > 0 ? $#dbline : 1;
4325
4326         # Clever test. If you're a mathematician, it's obvious why this
4327         # test works. If not:
4328         # If $delta is positive (going forward), $limit will be $#dbline.
4329         #    If $to is less than $limit, ($limit - $to) will be positive, times
4330         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4331         #    as the stopping point.
4332         #
4333         #    If $to is greater than $limit, ($limit - $to) is negative,
4334         #    times $delta of 1 (positive), so the result is < 0 and we should
4335         #    use $limit ($#dbline) as the stopping point.
4336         #
4337         # If $delta is negative (going backward), $limit will be 1.
4338         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4339         #    (negative) so the result is > 0, and we use $to as the stopping
4340         #    point.
4341         #
4342         #    If $to is less than zero, ($limit - $to) will be positive,
4343         #    times $delta of -1 (negative), so the result is not > 0, and
4344         #    we use $limit (1) as the stopping point.
4345         #
4346         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4347         #    (negative), still giving zero; the result is not > 0, and
4348         #    we use $limit (1) as the stopping point.
4349         #
4350         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4351         #    (negative), giving a positive (>0) value, so we'll set $limit to
4352         #    $to.
4353
4354         $limit = $to if ( $limit - $to ) * $delta > 0;
4355
4356         # The real search loop.
4357         # $i starts at $from (the point we want to start searching from).
4358         # We move through @dbline in the appropriate direction (determined
4359         # by $delta: either -1 (back) or +1 (ahead).
4360         # We stay in as long as we haven't hit an executable line
4361         # ($dbline[$i] == 0 means not executable) and we haven't reached
4362         # the limit yet (test similar to the above).
4363         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4364
4365     } ## end if (@_ >= 2)
4366
4367     # If $i points to a line that is executable, return that.
4368     return $i unless $dbline[$i] == 0;
4369
4370     # Format the message and print it: no breakable lines in range.
4371     my ( $pl, $upto ) = ( '', '' );
4372     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4373
4374     # If there's a filename in filename_error, we'll see it.
4375     # If not, not.
4376     die "Line$pl $from$upto$filename_error not breakable\n";
4377 } ## end sub breakable_line
4378
4379 =head3 breakable_line_in_filename(file, from, to) (API)
4380
4381 Like C<breakable_line>, but look in another file.
4382
4383 =cut
4384
4385 sub breakable_line_in_filename {
4386
4387     # Capture the file name.
4388     my ($f) = shift;
4389
4390     # Swap the magic line array over there temporarily.
4391     local *dbline = $main::{ '_<' . $f };
4392
4393     # If there's an error, it's in this other file.
4394     local $filename_error = " of '$f'";
4395
4396     # Find the breakable line.
4397     breakable_line(@_);
4398
4399     # *dbline and $filename_error get restored when this block ends.
4400
4401 } ## end sub breakable_line_in_filename
4402
4403 =head3 break_on_line(lineno, [condition]) (API)
4404
4405 Adds a breakpoint with the specified condition (or 1 if no condition was
4406 specified) to the specified line. Dies if it can't.
4407
4408 =cut
4409
4410 sub break_on_line {
4411     my ( $i, $cond ) = @_;
4412
4413     # Always true if no condition supplied.
4414     $cond = 1 unless @_ >= 2;
4415
4416     my $inii  = $i;
4417     my $after = '';
4418     my $pl    = '';
4419
4420     # Woops, not a breakable line. $filename_error allows us to say
4421     # if it was in a different file.
4422     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4423
4424     # Mark this file as having breakpoints in it.
4425     $had_breakpoints{$filename} |= 1;
4426
4427     # If there is an action or condition here already ...
4428     if ( $dbline{$i} ) {
4429
4430         # ... swap this condition for the existing one.
4431         $dbline{$i} =~ s/^[^\0]*/$cond/;
4432     }
4433     else {
4434
4435         # Nothing here - just add the condition.
4436         $dbline{$i} = $cond;
4437
4438         _set_breakpoint_enabled_status($filename, $i, 1);
4439     }
4440 } ## end sub break_on_line
4441
4442 =head3 cmd_b_line(line, [condition]) (command)
4443
4444 Wrapper for C<break_on_line>. Prints the failure message if it
4445 doesn't work.
4446
4447 =cut
4448
4449 sub cmd_b_line {
4450     if (not eval { break_on_line(@_); 1 }) {
4451         local $\ = '';
4452         print $OUT $@ and return;
4453     }
4454
4455     return;
4456 } ## end sub cmd_b_line
4457
4458 =head3 cmd_b_filename_line(line, [condition]) (command)
4459
4460 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4461 doesn't work.
4462
4463 =cut
4464
4465 sub cmd_b_filename_line {
4466     if (not eval { break_on_filename_line(@_); 1 }) {
4467         local $\ = '';
4468         print $OUT $@ and return;
4469     }
4470
4471     return;
4472 }
4473
4474 =head3 break_on_filename_line(file, line, [condition]) (API)
4475
4476 Switches to the file specified and then calls C<break_on_line> to set
4477 the breakpoint.
4478
4479 =cut
4480
4481 sub break_on_filename_line {
4482     my ( $f, $i, $cond ) = @_;
4483
4484     # Always true if condition left off.
4485     $cond = 1 unless @_ >= 3;
4486
4487     # Switch the magical hash temporarily.
4488     local *dbline = $main::{ '_<' . $f };
4489
4490     # Localize the variables that break_on_line uses to make its message.
4491     local $filename_error = " of '$f'";
4492     local $filename       = $f;
4493
4494     # Add the breakpoint.
4495     break_on_line( $i, $cond );
4496 } ## end sub break_on_filename_line
4497
4498 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4499
4500 Switch to another file, search the range of lines specified for an
4501 executable one, and put a breakpoint on the first one you find.
4502
4503 =cut
4504
4505 sub break_on_filename_line_range {
4506     my ( $f, $from, $to, $cond ) = @_;
4507
4508     # Find a breakable line if there is one.
4509     my $i = breakable_line_in_filename( $f, $from, $to );
4510
4511     # Always true if missing.
4512     $cond = 1 unless @_ >= 3;
4513
4514     # Add the breakpoint.
4515     break_on_filename_line( $f, $i, $cond );
4516 } ## end sub break_on_filename_line_range
4517
4518 =head3 subroutine_filename_lines(subname, [condition]) (API)
4519
4520 Search for a subroutine within a given file. The condition is ignored.
4521 Uses C<find_sub> to locate the desired subroutine.
4522
4523 =cut
4524
4525 sub subroutine_filename_lines {
4526     my ( $subname, $cond ) = @_;
4527
4528     # Returned value from find_sub() is fullpathname:startline-endline.
4529     # The match creates the list (fullpathname, start, end). Falling off
4530     # the end of the subroutine returns this implicitly.
4531     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4532 } ## end sub subroutine_filename_lines
4533