This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [PATCH Cwd 2.15] test tweak for VMS
[perl5.git] / ext / Cwd / t / cwd.t
1 #!./perl
2
3 use Cwd;
4 BEGIN {
5     chdir 't' if -d 't';
6 }
7
8 use Config;
9 use strict;
10 use warnings;
11 use File::Spec;
12 use File::Path;
13
14 use Test::More tests => 20;
15
16 my $IsVMS = $^O eq 'VMS';
17 my $IsMacOS = $^O eq 'MacOS';
18
19 # check imports
20 can_ok('main', qw(cwd getcwd fastcwd fastgetcwd));
21 ok( !defined(&chdir),           'chdir() not exported by default' );
22 ok( !defined(&abs_path),        '  nor abs_path()' );
23 ok( !defined(&fast_abs_path),   '  nor fast_abs_path()');
24
25
26 # XXX force Cwd to bootsrap its XSUBs since we have set @INC = "../lib"
27 # XXX and subsequent chdir()s can make them impossible to find
28 eval { fastcwd };
29
30 # Must find an external pwd (or equivalent) command.
31
32 my $pwd = $^O eq 'MSWin32' ? "cmd" : "pwd";
33 my $pwd_cmd =
34     ($^O eq "NetWare") ?
35         "cd" :
36     ($IsMacOS) ?
37         "pwd" :
38         (grep { -x && -f } map { "$_/$pwd$Config{exe_ext}" }
39                            split m/$Config{path_sep}/, $ENV{PATH})[0];
40
41 $pwd_cmd = 'SHOW DEFAULT' if $IsVMS;
42 if ($^O eq 'MSWin32') {
43     $pwd_cmd =~ s,/,\\,g;
44     $pwd_cmd = "$pwd_cmd /c cd";
45 }
46 $pwd_cmd =~ s=\\=/=g if ($^O eq 'dos');
47
48 SKIP: {
49     skip "No native pwd command found to test against", 4 unless $pwd_cmd;
50
51     print "# native pwd = '$pwd_cmd'\n";
52
53     local @ENV{qw(PATH IFS CDPATH ENV BASH_ENV)};
54     my ($pwd_cmd_untainted) = $pwd_cmd =~ /^(.+)$/; # Untaint.
55     chomp(my $start = `$pwd_cmd_untainted`);
56
57     # Win32's cd returns native C:\ style
58     $start =~ s,\\,/,g if ($^O eq 'MSWin32' || $^O eq "NetWare");
59     # DCL SHOW DEFAULT has leading spaces
60     $start =~ s/^\s+// if $IsVMS;
61     SKIP: {
62         skip("'$pwd_cmd' failed, nothing to test against", 4) if $?;
63         skip("/afs seen, paths unlikely to match", 4) if $start =~ m|/afs/|;
64
65         # Darwin's getcwd(3) (which Cwd.xs:bsd_realpath() uses which
66         # Cwd.pm:getcwd uses) has some magic related to the PWD
67         # environment variable: if PWD is set to a directory that
68         # looks about right (guess: has the same (dev,ino) as the '.'?),
69         # the PWD is returned.  However, if that path contains
70         # symlinks, the path will not be equal to the one returned by
71         # /bin/pwd (which probably uses the usual walking upwards in
72         # the path -trick).  This situation is easy to reproduce since
73         # /tmp is a symlink to /private/tmp.  Therefore we invalidate
74         # the PWD to force getcwd(3) to (re)compute the cwd in full.
75         # Admittedly fixing this in the Cwd module would be better
76         # long-term solution but deleting $ENV{PWD} should not be
77         # done light-heartedly. --jhi
78         delete $ENV{PWD} if $^O eq 'darwin';
79
80         my $cwd        = cwd;
81         my $getcwd     = getcwd;
82         my $fastcwd    = fastcwd;
83         my $fastgetcwd = fastgetcwd;
84
85         is($cwd,        $start, 'cwd()');
86         is($getcwd,     $start, 'getcwd()');
87         is($fastcwd,    $start, 'fastcwd()');
88         is($fastgetcwd, $start, 'fastgetcwd()');
89     }
90 }
91
92 my @test_dirs = qw{_ptrslt_ _path_ _to_ _a_ _dir_};
93 my $Test_Dir     = File::Spec->catdir(@test_dirs);
94
95 mkpath([$Test_Dir], 0, 0777);
96 Cwd::chdir $Test_Dir;
97
98 foreach my $func (qw(cwd getcwd fastcwd fastgetcwd)) {
99   my $result = eval "$func()";
100   is $@, '';
101   dir_ends_with( $result, $Test_Dir, "$func()" );
102 }
103
104 # Cwd::chdir should also update $ENV{PWD}
105 dir_ends_with( $ENV{PWD}, $Test_Dir, 'Cwd::chdir() updates $ENV{PWD}' );
106 my $updir = File::Spec->updir;
107 Cwd::chdir $updir;
108 print "#$ENV{PWD}\n";
109 Cwd::chdir $updir;
110 print "#$ENV{PWD}\n";
111 Cwd::chdir $updir;
112 print "#$ENV{PWD}\n";
113 Cwd::chdir $updir;
114 print "#$ENV{PWD}\n";
115 Cwd::chdir $updir;
116 print "#$ENV{PWD}\n";
117
118 rmtree($test_dirs[0], 0, 0);
119
120 {
121   my $check = ($IsVMS   ? qr|\b((?i)t)\]$| :
122                $IsMacOS ? qr|\bt:$| :
123                           qr|\bt$| );
124   
125   like($ENV{PWD}, $check);
126 }
127
128 SKIP: {
129     skip "no symlinks on this platform", 2 unless $Config{d_symlink};
130
131     mkpath([$Test_Dir], 0, 0777);
132     symlink $Test_Dir => "linktest";
133
134     my $abs_path      =  Cwd::abs_path("linktest");
135     my $fast_abs_path =  Cwd::fast_abs_path("linktest");
136     my $want          =  File::Spec->catdir("t", $Test_Dir);
137
138     like($abs_path,      qr|$want$|);
139     like($fast_abs_path, qr|$want$|);
140
141     rmtree($test_dirs[0], 0, 0);
142     unlink "linktest";
143 }
144
145 #############################################
146 # These two routines give us sort of a poor-man's cross-platform
147 # directory comparison routine.
148
149 sub bracketed_form {
150   return join '', map "[$_]",
151     grep length, File::Spec->splitdir(File::Spec->canonpath( shift() ));
152 }
153
154 sub dir_ends_with {
155   my ($dir, $expect) = (shift, shift);
156   my $bracketed_expect = quotemeta bracketed_form($expect);
157   like( bracketed_form($dir), qr|$bracketed_expect$|i, (@_ ? shift : ()) );
158 }
159