This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
make_ext.pl: Add some general comments
[perl5.git] / make_ext.pl
1 #!./miniperl
2 use strict;
3 use warnings;
4 use Config;
5 use constant{IS_CROSS => defined $Config::Config{usecrosscompile} ? 1 : 0,
6              IS_WIN32 => $^O eq 'MSWin32',
7              IS_VMS   => $^O eq 'VMS',
8              IS_UNIX  => $^O ne 'MSWin32' && $^O ne 'VMS',
9 };
10
11 my @ext_dirs = qw(cpan dist ext);
12 my $ext_dirs_re = '(?:' . join('|', @ext_dirs) . ')';
13
14 # This script acts as a simple interface for building extensions.
15
16 # It's actually a cut and shut of the Unix version ext/utils/makeext and the
17 # Windows version win32/build_ext.pl hence the two invocation styles.
18
19 # On Unix, it primarily used by the perl Makefile one extension at a time:
20 #
21 # d_dummy $(dynamic_ext): miniperl preplibrary FORCE
22 #       @$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
23 #
24 # On Windows or VMS,
25 # If '--static' is specified, static extensions will be built.
26 # If '--dynamic' is specified, dynamic extensions will be built.
27 # If '--nonxs' is specified, nonxs extensions will be built.
28 # If '--dynaloader' is specified, DynaLoader will be built.
29 # If '--all' is specified, all extensions will be built.
30 #
31 #    make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static|--dynamic|--all] +ext2 !ext1
32 #
33 # E.g.
34
35 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
36
37 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
38
39 #     make_ext.pl MAKE=dmake --dir=..\ext
40
41 #     make_ext.pl MAKE=dmake --dir=..\ext --target=clean
42
43 # Will skip building extensions which are marked with an '!' char.
44 # Mostly because they still not ported to specified platform.
45
46 # If any extensions are listed with a '+' char then only those
47 # extensions will be built, but only if they aren't countermanded
48 # by an '!ext' and are appropriate to the type of building being done.
49 # An extensions follows the format of Foo/Bar, which would be extension Foo::Bar
50
51 # To fix dependency ordering, on *nix systems, edit Makefile.SH to create a
52 # rule.  That isn't sufficient for other systems; you also have to do
53 # something in this file.  See the code at
54 #       '# XXX hack for dependency # ordering'
55 # below.
56 #
57 # The basic logic is:
58 #   1) if there's a Makefile.PL in git for the module, use it. and call make
59 #   2) If not, auto-generate one (normally)
60 #   3) unless the auto-generation code figures out that the extension is
61 #      *really* simple, in which case don't.  This will be for pure perl
62 #      modules, and all that is needed to be done is to copy from the source
63 #      to the dest directories.
64 #
65 # It may be deleted in a later release of perl so try to
66 # avoid using it for other purposes.
67
68 my (%excl, %incl, %opts, @extspec, @pass_through, $verbose);
69
70 foreach (@ARGV) {
71     if (/^!(.*)$/) {
72         $excl{$1} = 1;
73     } elsif (/^\+(.*)$/) {
74         $incl{$1} = 1;
75     } elsif (/^--verbose$/ or /^-v$/) {
76         $verbose = 1;
77     } elsif (/^--([\w\-]+)$/) {
78         $opts{$1} = 1;
79     } elsif (/^--([\w\-]+)=(.*)$/) {
80         push @{$opts{$1}}, $2;
81     } elsif (/=/) {
82         push @pass_through, $_;
83     } elsif (length) {
84         push @extspec, $_;
85     }
86 }
87
88 my $static = $opts{static} || $opts{all};
89 my $dynamic = $opts{dynamic} || $opts{all};
90 my $nonxs = $opts{nonxs} || $opts{all};
91 my $dynaloader = $opts{dynaloader} || $opts{all};
92
93 # The Perl Makefile.SH will expand all extensions to
94 #       lib/auto/X/X.a  (or lib/auto/X/Y/Y.a if nested)
95 # A user wishing to run make_ext might use
96 #       X (or X/Y or X::Y if nested)
97
98 # canonise into X/Y form (pname)
99
100 foreach (@extspec) {
101     if (s{^lib/auto/}{}) {
102         # Remove lib/auto prefix and /*.* suffix
103         s{/[^/]+\.[^/]+$}{};
104     } elsif (s{^$ext_dirs_re/}{}) {
105         # Remove ext/ prefix and /pm_to_blib suffix
106         s{/pm_to_blib$}{};
107         # Targets are given as files on disk, but the extension spec is still
108         # written using /s for each ::
109         tr!-!/!;
110     } elsif (s{::}{\/}g) {
111         # Convert :: to /
112     } else {
113         s/\..*o//;
114     }
115 }
116
117 my $makecmd  = shift @pass_through; # Should be something like MAKE=make
118 unshift @pass_through, 'PERL_CORE=1';
119
120 my @dirs  = @{$opts{dir} || \@ext_dirs};
121 my $target   = $opts{target}[0];
122 $target = 'all' unless defined $target;
123
124 # Previously, $make was taken from config.sh.  However, the user might
125 # instead be running a possibly incompatible make.  This might happen if
126 # the user types "gmake" instead of a plain "make", for example.  The
127 # correct current value of MAKE will come through from the main perl
128 # makefile as MAKE=/whatever/make in $makecmd.  We'll be cautious in
129 # case third party users of this script (are there any?) don't have the
130 # MAKE=$(MAKE) argument, which was added after 5.004_03.
131 unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
132     die "$0:  WARNING:  Please include MAKE=\$(MAKE) in \@ARGV\n";
133 }
134
135 # This isn't going to cope with anything fancy, such as spaces inside command
136 # names, but neither did what it replaced. Once there is a use case that needs
137 # it, please supply patches. Until then, I'm sticking to KISS
138 my @make = split ' ', $1 || $Config{make} || $ENV{MAKE};
139
140
141 if ($target eq '') {
142     die "make_ext: no make target specified (eg all or clean)\n";
143 } elsif ($target !~ /^(?:all|clean|distclean|realclean|veryclean)$/) {
144     # we are strict about what make_ext is used for because we emulate these
145     # targets for simple modules:
146     die "$0: unknown make target '$target'\n";
147 }
148
149 if (!@extspec and !$static and !$dynamic and !$nonxs and !$dynaloader)  {
150     die "$0: no extension specified\n";
151 }
152
153 my $perl;
154 my %extra_passthrough;
155
156 if (IS_WIN32) {
157     require Cwd;
158     require FindExt;
159     my $build = Cwd::getcwd();
160     $perl = $^X;
161     if ($perl =~ m#^\.\.#) {
162         my $here = $build;
163         $here =~ s{/}{\\}g;
164         $perl = "$here\\$perl";
165     }
166     (my $topdir = $perl) =~ s/\\[^\\]+$//;
167     # miniperl needs to find perlglob and pl2bat
168     $ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
169     my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
170     unless (-f "$pl2bat.bat") {
171         my @args = ($perl, "-I$topdir\\lib", ("$pl2bat.pl") x 2);
172         print "@args\n" if $verbose;
173         system(@args) unless IS_CROSS;
174     }
175
176     print "In $build" if $verbose;
177     foreach my $dir (@dirs) {
178         chdir($dir) or die "Cannot cd to $dir: $!\n";
179         (my $ext = Cwd::getcwd()) =~ s{/}{\\}g;
180         FindExt::scan_ext($ext);
181         FindExt::set_static_extensions(split ' ', $Config{static_ext});
182         chdir $build
183             or die "Couldn't chdir to '$build': $!"; # restore our start directory
184     }
185
186     my @ext;
187     push @ext, FindExt::static_ext() if $static;
188     push @ext, FindExt::dynamic_ext() if $dynamic;
189     push @ext, FindExt::nonxs_ext() if $nonxs;
190     push @ext, 'DynaLoader' if $dynaloader;
191
192     foreach (sort @ext) {
193         if (%incl and !exists $incl{$_}) {
194             #warn "Skipping extension $_, not in inclusion list\n";
195             next;
196         }
197         if (exists $excl{$_}) {
198             warn "Skipping extension $_, not ported to current platform";
199             next;
200         }
201         push @extspec, $_;
202         if($_ ne 'DynaLoader' && FindExt::is_static($_)) {
203             push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
204         }
205     }
206
207     chdir '..'
208         or die "Couldn't chdir to build directory: $!"; # now in the Perl build
209 }
210 elsif (IS_VMS) {
211     $perl = $^X;
212     push @extspec, (split ' ', $Config{static_ext}) if $static;
213     push @extspec, (split ' ', $Config{dynamic_ext}) if $dynamic;
214     push @extspec, (split ' ', $Config{nonxs_ext}) if $nonxs;
215     push @extspec, 'DynaLoader' if $dynaloader;
216 }
217
218 { # XXX hack for dependency ordering
219     # Cwd needs to be built before Encode recurses into subdirectories.
220     # Pod::Simple needs to be built before Pod::Functions
221     # lib needs to be built before IO-Compress
222     # This seems to be the simplest way to ensure this ordering:
223     my (@first, @other);
224     foreach (@extspec) {
225         if ($_ eq 'Cwd' || $_ eq 'Pod/Simple' || $_ eq 'lib') {
226             push @first, $_;
227         } else {
228             push @other, $_;
229         }
230     }
231     @extspec = (@first, @other);
232 }
233
234 if ($Config{osname} eq 'catamount' and @extspec) {
235     # Snowball's chance of building extensions.
236     die "This is $Config{osname}, not building $extspec[0], sorry.\n";
237 }
238 $ENV{PERL_CORE} = 1;
239
240 foreach my $spec (@extspec)  {
241     my $mname = $spec;
242     $mname =~ s!/!::!g;
243     my $ext_pathname;
244
245     # Try new style ext/Data-Dumper/ first
246     my $copy = $spec;
247     $copy =~ tr!/!-!;
248
249     # List/Util.xs lives in Scalar-List-Utils, Cwd.xs lives in PathTools
250     $copy = 'Scalar-List-Utils' if $copy eq 'List-Util';
251     $copy = 'PathTools'         if $copy eq 'Cwd';
252
253     foreach my $dir (@ext_dirs) {
254         if (-d "$dir/$copy") {
255             $ext_pathname = "$dir/$copy";
256             last;
257         }
258     }
259
260     if (!defined $ext_pathname) {
261         if (-d "ext/$spec") {
262             # Old style ext/Data/Dumper/
263             $ext_pathname = "ext/$spec";
264         } else {
265             warn "Can't find extension $spec in any of @ext_dirs";
266             next;
267         }
268     }
269
270     print "\tMaking $mname ($target)\n" if $verbose;
271
272     build_extension($ext_pathname, $perl, $mname, $target,
273                     [@pass_through, @{$extra_passthrough{$spec} || []}]);
274 }
275
276 sub build_extension {
277     my ($ext_dir, $perl, $mname, $target, $pass_through) = @_;
278
279     unless (chdir "$ext_dir") {
280         warn "Cannot cd to $ext_dir: $!";
281         return;
282     }
283
284     my $up = $ext_dir;
285     $up =~ s![^/]+!..!g;
286
287     $perl ||= "$up/miniperl";
288     my $return_dir = $up;
289     my $lib_dir = "$up/lib";
290
291     my ($makefile, $makefile_no_minus_f);
292     if (IS_VMS) {
293         $makefile = 'descrip.mms';
294         if ($target =~ /clean$/
295             && !-f $makefile
296             && -f "${makefile}_old") {
297             $makefile = "${makefile}_old";
298         }
299     } else {
300         $makefile = 'Makefile';
301     }
302     
303     if (-f $makefile) {
304         $makefile_no_minus_f = 0;
305         open my $mfh, '<', $makefile or die "Cannot open $makefile: $!";
306         while (<$mfh>) {
307             # Plagiarised from CPAN::Distribution
308             last if /MakeMaker post_initialize section/;
309             next unless /^#\s+VERSION_FROM\s+=>\s+(.+)/;
310             my $vmod = eval $1;
311             my $oldv;
312             while (<$mfh>) {
313                 next unless /^XS_VERSION = (\S+)/;
314                 $oldv = $1;
315                 last;
316             }
317             last unless defined $oldv;
318             require ExtUtils::MM_Unix;
319             defined (my $newv = parse_version MM $vmod) or last;
320             if (version->parse($newv) ne $oldv) {
321                 close $mfh or die "close $makefile: $!";
322                 _unlink($makefile);
323                 {
324                     no warnings 'deprecated';
325                     goto NO_MAKEFILE;
326                 }
327             }
328         }
329
330         if (IS_CROSS) {
331             # If we're cross-compiling, it's possible that the host's
332             # Makefiles are around.
333             seek($mfh, 0, 0) or die "Cannot seek $makefile: $!";
334             
335             my $cross_makefile;
336             while (<$mfh>) {
337                 # XXX This might not be throughout enough.
338                 # For example, it's possible to cause a false-positive
339                 # if cross compiling on and for the Raspberry Pi,
340                 # which is insane but plausible.
341                 # False positives are really not troublesome, though;
342                 # all they mean is that the module gets rebuilt.
343                 if (/^CC = \Q$Config{cc}\E/) {
344                     $cross_makefile = 1;
345                     last;
346                 }
347             }
348             
349             if (!$cross_makefile) {
350                 print "Deleting non-Cross makefile\n";
351                 close $mfh or die "close $makefile: $!";
352                 _unlink($makefile);
353             }
354         }
355     } else {
356         $makefile_no_minus_f = 1;
357     }
358
359     if ($makefile_no_minus_f || !-f $makefile) {
360         NO_MAKEFILE:
361         if (!-f 'Makefile.PL') {
362             unless (just_pm_to_blib($target, $ext_dir, $mname, $return_dir)) {
363                 # No problems returned, so it has faked everything for us. :-)
364                 chdir $return_dir || die "Cannot cd to $return_dir: $!";
365                 return;
366             }
367
368             print "\nCreating Makefile.PL in $ext_dir for $mname\n" if $verbose;
369             my ($fromname, $key, $value);
370
371             $key = 'ABSTRACT_FROM';
372             # We need to cope well with various possible layouts
373             my @dirs = split /::/, $mname;
374             my $leaf = pop @dirs;
375             my $leafname = "$leaf.pm";
376             my $pathname = join '/', @dirs, $leafname;
377             my @locations = ($leafname, $pathname, "lib/$pathname");
378             foreach (@locations) {
379                 if (-f $_) {
380                     $fromname = $_;
381                     last;
382                 }
383         }
384
385         unless ($fromname) {
386             die "For $mname tried @locations in $ext_dir but can't find source";
387         }
388         ($value = $fromname) =~ s/\.pm\z/.pod/;
389         $value = $fromname unless -e $value;
390
391             if ($mname eq 'Pod::Checker') {
392                 # the abstract in the .pm file is unparseable by MM,
393                 # so special-case it. We can't use the package's own
394                 # Makefile.PL, as it doesn't handle the executable scripts
395                 # right.
396                 $key = 'ABSTRACT';
397                 # this is copied from the CPAN Makefile.PL v 1.171
398                 $value = 'Pod::Checker verifies POD documentation contents for compliance with the POD format specifications';
399             }
400
401             open my $fh, '>', 'Makefile.PL'
402                 or die "Can't open Makefile.PL for writing: $!";
403             printf $fh <<'EOM', $0, $mname, $fromname, $key, $value;
404 #-*- buffer-read-only: t -*-
405
406 # This Makefile.PL was written by %s.
407 # It will be deleted automatically by make realclean
408
409 use strict;
410 use ExtUtils::MakeMaker;
411
412 # This is what the .PL extracts to. Not the ultimate file that is installed.
413 # (ie Win32 runs pl2bat after this)
414
415 # Doing this here avoids all sort of quoting issues that would come from
416 # attempting to write out perl source with literals to generate the arrays and
417 # hash.
418 my @temps = 'Makefile.PL';
419 foreach (glob('scripts/pod*.PL')) {
420     # The various pod*.PL extractors change directory. Doing that with relative
421     # paths in @INC breaks. It seems the lesser of two evils to copy (to avoid)
422     # the chdir doing anything, than to attempt to convert lib paths to
423     # absolute, and potentially run into problems with quoting special
424     # characters in the path to our build dir (such as spaces)
425     require File::Copy;
426
427     my $temp = $_;
428     $temp =~ s!scripts/!!;
429     File::Copy::copy($_, $temp) or die "Can't copy $temp to $_: $!";
430     push @temps, $temp;
431 }
432
433 my $script_ext = $^O eq 'VMS' ? '.com' : '';
434 my %%pod_scripts;
435 foreach (glob('pod*.PL')) {
436     my $script = $_;
437     s/.PL$/$script_ext/i;
438     $pod_scripts{$script} = $_;
439 }
440 my @exe_files = values %%pod_scripts;
441
442 WriteMakefile(
443     NAME          => '%s',
444     VERSION_FROM  => '%s',
445     %-13s => '%s',
446     realclean     => { FILES => "@temps" },
447     (%%pod_scripts ? (
448         PL_FILES  => \%%pod_scripts,
449         EXE_FILES => \@exe_files,
450         clean     => { FILES => "@exe_files" },
451     ) : ()),
452 );
453
454 # ex: set ro:
455 EOM
456             close $fh or die "Can't close Makefile.PL: $!";
457             # As described in commit 23525070d6c0e51f:
458             # Push the atime and mtime of generated Makefile.PLs back 4
459             # seconds. In certain circumstances ( on virtual machines ) the
460             # generated Makefile.PL can produce a Makefile that is older than
461             # the Makefile.PL. Altering the atime and mtime backwards by 4
462             # seconds seems to resolve the issue.
463             eval {
464         my $ftime = (stat('Makefile.PL'))[9] - 4;
465         utime $ftime, $ftime, 'Makefile.PL';
466             };
467         } elsif ($mname =~ /\A(?:Carp
468                             |ExtUtils::CBuilder
469                             |Safe
470                             |Search::Dict)\z/x) {
471             # An explicit list of dual-life extensions that have a Makefile.PL
472             # for CPAN, but we have verified can also be built using the fakery.
473             my ($problem) = just_pm_to_blib($target, $ext_dir, $mname, $return_dir);
474             # We really need to sanity test that we can fake it.
475             # Otherwise "skips" will go undetected, and the build slow down for
476             # everyone, defeating the purpose.
477             if (defined $problem) {
478                 if (-d "$return_dir/.git") {
479                     # Get the list of files that git isn't ignoring:
480                     my @files = `git ls-files --cached --others --exclude-standard 2>/dev/null`;
481                     # on error (eg no git) we get nothing, but that's not a
482                     # problem. The goal is to see if git thinks that the problem
483                     # file is interesting, by getting a positive match with
484                     # something git told us about, and if so bail out:
485                     foreach (@files) {
486                         chomp;
487                         # We really need to sanity test that we can fake it.
488                         # The intent is that this should only fail because
489                         # you've just added a file to the dual-life dist that
490                         # we can't handle. In which case you should either
491                         # 1) remove the dist from the regex a few lines above.
492                         # or
493                         # 2) add the file to regex of "safe" filenames earlier
494                         #    in this function, that starts with ChangeLog
495                         die "FATAL - $0 has $mname in the list of simple extensions, but it now contains file '$problem' which we can't handle"
496                             if $problem eq $_;
497                     }
498                     # There's an unexpected file, but it seems to be something
499                     # that git will ignore. So fall through to the regular
500                     # Makefile.PL handling code below, on the assumption that
501                     # we won't get here for a clean build.
502                 }
503                 warn "WARNING - $0 is building $mname using EU::MM, as it found file '$problem'";
504             } else {
505                 # It faked everything for us.
506                 chdir $return_dir || die "Cannot cd to $return_dir: $!";
507                 return;
508             }
509         }
510
511         # We are going to have to use Makefile.PL:
512         print "\nRunning Makefile.PL in $ext_dir\n" if $verbose;
513
514         my @args = ("-I$lib_dir", 'Makefile.PL');
515         if (IS_VMS) {
516             my $libd = VMS::Filespec::vmspath($lib_dir);
517             push @args, "INST_LIB=$libd", "INST_ARCHLIB=$libd";
518         } else {
519             push @args, 'INSTALLDIRS=perl', 'INSTALLMAN1DIR=none',
520                 'INSTALLMAN3DIR=none';
521         }
522         push @args, @$pass_through;
523         _quote_args(\@args) if IS_VMS;
524         print join(' ', $perl, @args), "\n" if $verbose;
525         my $code = do {
526            local $ENV{PERL_MM_USE_DEFAULT} = 1;
527             system $perl, @args;
528         };
529         if($code != 0){
530             #make sure next build attempt/run of make_ext.pl doesn't succeed
531             _unlink($makefile);
532             die "Unsuccessful Makefile.PL($ext_dir): code=$code";
533         }
534
535         # Right. The reason for this little hack is that we're sitting inside
536         # a program run by ./miniperl, but there are tasks we need to perform
537         # when the 'realclean', 'distclean' or 'veryclean' targets are run.
538         # Unfortunately, they can be run *after* 'clean', which deletes
539         # ./miniperl
540         # So we do our best to leave a set of instructions identical to what
541         # we would do if we are run directly as 'realclean' etc
542         # Whilst we're perfect, unfortunately the targets we call are not, as
543         # some of them rely on a $(PERL) for their own distclean targets.
544         # But this always used to be a problem with the old /bin/sh version of
545         # this.
546         if (IS_UNIX) {
547             foreach my $clean_target ('realclean', 'veryclean') {
548                 fallback_cleanup($return_dir, $clean_target, <<"EOS");
549 cd $ext_dir
550 if test ! -f Makefile -a -f Makefile.old; then
551     echo "Note: Using Makefile.old"
552     make -f Makefile.old $clean_target MAKE='@make' @pass_through
553 else
554     if test ! -f Makefile ; then
555         echo "Warning: No Makefile!"
556     fi
557     @make $clean_target MAKE='@make' @pass_through
558 fi
559 cd $return_dir
560 EOS
561             }
562         }
563     }
564
565     if (not -f $makefile) {
566         print "Warning: No Makefile!\n";
567     }
568
569     if (IS_VMS) {
570         _quote_args($pass_through);
571         @$pass_through = (
572                           "/DESCRIPTION=$makefile",
573                           '/MACRO=(' . join(',',@$pass_through) . ')'
574                          );
575     }
576
577     my @targ = ($target, @$pass_through);
578     print "Making $target in $ext_dir\n@make @targ\n" if $verbose;
579     local $ENV{PERL_INSTALL_QUIET} = 1;
580     my $code = system(@make, @targ);
581     if($code >> 8 != 0){ # probably cleaned itself, try again once more time
582         $code = system(@make, @targ);
583     }
584     die "Unsuccessful make($ext_dir): code=$code" if $code != 0;
585
586     chdir $return_dir || die "Cannot cd to $return_dir: $!";
587 }
588
589 sub _quote_args {
590     my $args = shift; # must be array reference
591
592     # Do not quote qualifiers that begin with '/'.
593     map { if (!/^\//) {
594           $_ =~ s/\"/""/g;     # escape C<"> by doubling
595           $_ = q(").$_.q(");
596         }
597     } @{$args}
598     ;
599 }
600
601 #guarentee that a file is deleted or die, void _unlink($filename)
602 #xxx replace with _unlink_or_rename from EU::Install?
603 sub _unlink {
604     1 while unlink $_[0];
605     my $err = $!;
606     die "Can't unlink $_[0]: $err" if -f $_[0];
607 }
608
609 # Figure out if this extension is simple enough that it would only use
610 # ExtUtils::MakeMaker's pm_to_blib target. If we're confident that it would,
611 # then do all the work ourselves (returning an empty list), else return the
612 # name of a file that we identified as beyond our ability to handle.
613 #
614 # While this is clearly quite a bit more work than just letting
615 # ExtUtils::MakeMaker do it, and effectively is some code duplication, the time
616 # savings are impressive.
617
618 sub just_pm_to_blib {
619     my ($target, $ext_dir, $mname, $return_dir) = @_;
620     my ($has_lib, $has_top, $has_topdir);
621     my ($last) = $mname =~ /([^:]+)$/;
622     my ($first) = $mname =~ /^([^:]+)/;
623
624     my $pm_to_blib = IS_VMS ? 'pm_to_blib.ts' : 'pm_to_blib';
625     my $silent = defined $ENV{MAKEFLAGS} && $ENV{MAKEFLAGS} =~ /\b(s|silent|quiet)\b/;
626
627     foreach my $leaf (<*>) {
628         if (-d $leaf) {
629             $leaf =~ s/\.DIR\z//i
630                 if IS_VMS;
631             next if $leaf =~ /\A(?:\.|\.\.|t|demo)\z/;
632             if ($leaf eq 'lib') {
633                 ++$has_lib;
634                 next;
635             }
636             if ($leaf eq $first) {
637                 ++$has_topdir;
638                 next;
639             }
640         }
641         return $leaf
642             unless -f _;
643         $leaf =~ s/\.\z//
644             if IS_VMS;
645         # Makefile.PL is "safe" to ignore because we will only be called for
646         # directories that hold a Makefile.PL if they are in the exception list.
647         next
648             if $leaf =~ /\A(ChangeLog
649                             |Changes
650                             |LICENSE
651                             |Makefile\.PL
652                             |MANIFEST
653                             |META\.yml
654                             |\Q$pm_to_blib\E
655                             |README
656                             |README\.patching
657                             |README\.release
658                             )\z/xi; # /i to deal with case munging systems.
659         if ($leaf eq "$last.pm") {
660             ++$has_top;
661             next;
662         }
663         return $leaf;
664     }
665     return 'no lib/'
666         unless $has_lib || $has_top;
667     die "Inconsistent module $mname has both lib/ and $first/"
668         if $has_lib && $has_topdir;
669
670     print "Running pm_to_blib for $ext_dir directly\n"
671       unless $silent;
672
673     my %pm;
674     if ($has_top) {
675         my $to = $mname =~ s!::!/!gr;
676         $pm{"$last.pm"} = "../../lib/$to.pm";
677     }
678     if ($has_lib || $has_topdir) {
679         # strictly ExtUtils::MakeMaker uses the pm_to_blib target to install
680         # .pm, pod and .pl files. We're just going to do it for .pm and .pod
681         # files, to avoid problems on case munging file systems. Specifically,
682         # _pm.PL which ExtUtils::MakeMaker should run munges to _PM.PL, and
683         # looks a lot like a regular foo.pl (ie FOO.PL)
684         my @found;
685         require File::Find;
686         unless (eval {
687             File::Find::find({
688                               no_chdir => 1,
689                               wanted => sub {
690                                   return if -d $_;
691                                   # Bail out immediately with the problem file:
692                                   die \$_
693                                       unless -f _;
694                                   die \$_
695                                       unless /\A[^.]+\.(?:pm|pod)\z/i;
696                                   push @found, $_;
697                               }
698                              }, $has_lib ? 'lib' : $first);
699             1;
700         }) {
701             # Problem files aren't really errors:
702             return ${$@}
703                 if ref $@ eq 'SCALAR';
704             # But anything else is:
705             die $@;
706         }
707         if ($has_lib) {
708             $pm{$_} = "../../$_"
709                 foreach @found;
710         } else {
711             $pm{$_} = "../../lib/$_"
712                 foreach @found;
713         }
714     }
715     # This is running under miniperl, so no autodie
716     if ($target eq 'all') {
717         my $need_update = 1;
718         if (-f $pm_to_blib) {
719             # avoid touching pm_to_blib unless there's something that
720             # needs updating, see #126710
721             $need_update = 0;
722             my $test_at = -M _;
723             while (my $from = each(%pm)) {
724                 if (-M $from < $test_at) {
725                     ++$need_update;
726                     last;
727                 }
728             }
729             keys %pm; # reset iterator
730         }
731
732         if ($need_update) {
733             local $ENV{PERL_INSTALL_QUIET} = 1;
734             require ExtUtils::Install;
735             ExtUtils::Install::pm_to_blib(\%pm, '../../lib/auto');
736             open my $fh, '>', $pm_to_blib
737                 or die "Can't open '$pm_to_blib': $!";
738             print $fh "$0 has handled pm_to_blib directly\n";
739             close $fh
740                 or die "Can't close '$pm_to_blib': $!";
741             if (IS_UNIX) {
742                 # Fake the fallback cleanup
743                 my $fallback
744                     = join '', map {s!^\.\./\.\./!!; "rm -f $_\n"} sort values %pm;
745                 foreach my $clean_target ('realclean', 'veryclean') {
746                     fallback_cleanup($return_dir, $clean_target, $fallback);
747                 }
748             }
749         }
750     } else {
751         # A clean target.
752         # For now, make the targets behave the same way as ExtUtils::MakeMaker
753         # does
754         _unlink($pm_to_blib);
755         unless ($target eq 'clean') {
756             # but cheat a bit, by relying on the top level Makefile clean target
757             # to take out our directory lib/auto/...
758             # (which it has to deal with, as cpan/foo/bar creates
759             # lib/auto/foo/bar, but the EU::MM rule will only
760             # rmdir lib/auto/foo/bar, leaving lib/auto/foo
761             _unlink($_)
762                 foreach sort values %pm;
763         }
764     }
765     return;
766 }
767
768 sub fallback_cleanup {
769     my ($dir, $clean_target, $contents) = @_;
770     my $file = "$dir/$clean_target.sh";
771     open my $fh, '>>', $file or die "open $file: $!";
772     # Quite possible that we're being run in parallel here.
773     # Can't use Fcntl this early to get the LOCK_EX
774     flock $fh, 2 or warn "flock $file: $!";
775     print $fh $contents or die "print $file: $!";
776     close $fh or die "close $file: $!";
777 }