This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
b780ec9dab82d5c60c6cd8b77109c13a5bc22901
[perl5.git] / make_ext.pl
1 #!./miniperl
2 use strict;
3 use warnings;
4 use Config;
5 BEGIN {
6     if ($^O eq 'MSWin32') {
7         unshift @INC, ('../dist/Cwd', '../dist/Cwd/lib');
8         require File::Spec::Functions;
9         require FindExt;
10     }
11     else {
12         unshift @INC, 'dist/Cwd';
13     }
14 }
15 use Cwd;
16
17 my $is_Win32 = $^O eq 'MSWin32';
18 my $is_VMS = $^O eq 'VMS';
19 my $is_Unix = !$is_Win32 && !$is_VMS;
20
21 # To clarify, this isn't the entire suite of modules considered "toolchain"
22 # It's not even all modules needed to build ext/
23 # It's just the source paths of the (minimum complete set of) modules in ext/
24 # needed to build the nonxs modules
25 # After which, all nonxs modules are in lib, which was always sufficient to
26 # allow miniperl to build everything else.
27
28 # This list cannot get any longer without overflowing the length limit for
29 # environment variables on VMS
30 my @toolchain = qw(cpan/AutoLoader/lib
31                    dist/Cwd dist/Cwd/lib
32                    dist/ExtUtils-Command/lib
33                    dist/ExtUtils-Install/lib
34                    cpan/ExtUtils-MakeMaker/lib
35                    dist/ExtUtils-Manifest/lib
36                    cpan/File-Path/lib
37                    );
38
39 # Used only in ExtUtils::Liblist::Kid::_win32_ext()
40 push @toolchain, 'cpan/Text-ParseWords/lib' if $is_Win32;
41
42 my @ext_dirs = qw(cpan dist ext);
43 my $ext_dirs_re = '(?:' . join('|', @ext_dirs) . ')';
44
45 # This script acts as a simple interface for building extensions.
46
47 # It's actually a cut and shut of the Unix version ext/utils/makeext and the
48 # Windows version win32/build_ext.pl hence the two invocation styles.
49
50 # On Unix, it primarily used by the perl Makefile one extension at a time:
51 #
52 # d_dummy $(dynamic_ext): miniperl preplibrary FORCE
53 #       @$(RUN) ./miniperl make_ext.pl --target=dynamic $@ MAKE=$(MAKE) LIBPERL_A=$(LIBPERL)
54 #
55 # On Windows or VMS,
56 # If '--static' is specified, static extensions will be built.
57 # If '--dynamic' is specified, dynamic extensions will be built.
58 # If '--nonxs' is specified, nonxs extensions will be built.
59 # If '--dynaloader' is specified, DynaLoader will be built.
60 # If '--all' is specified, all extensions will be built.
61 #
62 #    make_ext.pl "MAKE=make [-make_opts]" --dir=directory [--target=target] [--static|--dynamic|--all] +ext2 !ext1
63 #
64 # E.g.
65
66 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext
67
68 #     make_ext.pl "MAKE=nmake -nologo" --dir=..\ext --target=clean
69
70 #     make_ext.pl MAKE=dmake --dir=..\ext
71
72 #     make_ext.pl MAKE=dmake --dir=..\ext --target=clean
73
74 # Will skip building extensions which are marked with an '!' char.
75 # Mostly because they still not ported to specified platform.
76
77 # If any extensions are listed with a '+' char then only those
78 # extensions will be built, but only if they arent countermanded
79 # by an '!ext' and are appropriate to the type of building being done.
80
81 # It may be deleted in a later release of perl so try to
82 # avoid using it for other purposes.
83
84 my (%excl, %incl, %opts, @extspec, @pass_through);
85
86 foreach (@ARGV) {
87     if (/^!(.*)$/) {
88         $excl{$1} = 1;
89     } elsif (/^\+(.*)$/) {
90         $incl{$1} = 1;
91     } elsif (/^--([\w\-]+)$/) {
92         $opts{$1} = 1;
93     } elsif (/^--([\w\-]+)=(.*)$/) {
94         push @{$opts{$1}}, $2;
95     } elsif (/=/) {
96         push @pass_through, $_;
97     } elsif (length) {
98         push @extspec, $_;
99     }
100 }
101
102 my $static = $opts{static} || $opts{all};
103 my $dynamic = $opts{dynamic} || $opts{all};
104 my $nonxs = $opts{nonxs} || $opts{all};
105 my $dynaloader = $opts{dynaloader} || $opts{all};
106
107 # The Perl Makefile.SH will expand all extensions to
108 #       lib/auto/X/X.a  (or lib/auto/X/Y/Y.a if nested)
109 # A user wishing to run make_ext might use
110 #       X (or X/Y or X::Y if nested)
111
112 # canonise into X/Y form (pname)
113
114 foreach (@extspec) {
115     if (s{^lib/auto/}{}) {
116         # Remove lib/auto prefix and /*.* suffix
117         s{/[^/]+\.[^/]+$}{};
118     } elsif (s{^$ext_dirs_re/}{}) {
119         # Remove ext/ prefix and /pm_to_blib suffix
120         s{/pm_to_blib$}{};
121         # Targets are given as files on disk, but the extension spec is still
122         # written using /s for each ::
123         tr!-!/!;
124     } elsif (s{::}{\/}g) {
125         # Convert :: to /
126     } else {
127         s/\..*o//;
128     }
129 }
130
131 my $makecmd  = shift @pass_through; # Should be something like MAKE=make
132 unshift @pass_through, 'PERL_CORE=1';
133
134 my @dirs  = @{$opts{dir} || \@ext_dirs};
135 my $target   = $opts{target}[0];
136 $target = 'all' unless defined $target;
137
138 # Previously, $make was taken from config.sh.  However, the user might
139 # instead be running a possibly incompatible make.  This might happen if
140 # the user types "gmake" instead of a plain "make", for example.  The
141 # correct current value of MAKE will come through from the main perl
142 # makefile as MAKE=/whatever/make in $makecmd.  We'll be cautious in
143 # case third party users of this script (are there any?) don't have the
144 # MAKE=$(MAKE) argument, which was added after 5.004_03.
145 unless(defined $makecmd and $makecmd =~ /^MAKE=(.*)$/) {
146     die "$0:  WARNING:  Please include MAKE=\$(MAKE) in \@ARGV\n";
147 }
148
149 # This isn't going to cope with anything fancy, such as spaces inside command
150 # names, but neither did what it replaced. Once there is a use case that needs
151 # it, please supply patches. Until then, I'm sticking to KISS
152 my @make = split ' ', $1 || $Config{make} || $ENV{MAKE};
153 # Using an array of 0 or 1 elements makes the subsequent code simpler.
154 my @run = $Config{run};
155 @run = () if not defined $run[0] or $run[0] eq '';
156
157
158 if ($target eq '') {
159     die "make_ext: no make target specified (eg all or clean)\n";
160 } elsif ($target !~ /(?:^all|clean)$/) {
161     # for the time being we are strict about what make_ext is used for
162     die "$0: unknown make target '$target'\n";
163 }
164
165 if (!@extspec and !$static and !$dynamic and !$nonxs and !$dynaloader)  {
166     die "$0: no extension specified\n";
167 }
168
169 my $perl;
170 my %extra_passthrough;
171
172 if ($is_Win32) {
173     my $build = getcwd();
174     $perl = $^X;
175     if ($perl =~ m#^\.\.#) {
176         my $here = $build;
177         $here =~ s{/}{\\}g;
178         $perl = "$here\\$perl";
179     }
180     (my $topdir = $perl) =~ s/\\[^\\]+$//;
181     # miniperl needs to find perlglob and pl2bat
182     $ENV{PATH} = "$topdir;$topdir\\win32\\bin;$ENV{PATH}";
183     my $pl2bat = "$topdir\\win32\\bin\\pl2bat";
184     unless (-f "$pl2bat.bat") {
185         my @args = ($perl, "-I$topdir\\lib", ("$pl2bat.pl") x 2);
186         print "@args\n";
187         system(@args) unless defined $::Cross::platform;
188     }
189
190     print "In $build";
191     foreach my $dir (@dirs) {
192         chdir($dir) or die "Cannot cd to $dir: $!\n";
193         (my $ext = getcwd()) =~ s{/}{\\}g;
194         FindExt::scan_ext($ext);
195         FindExt::set_static_extensions(split ' ', $Config{static_ext});
196         chdir $build
197             or die "Couldn't chdir to '$build': $!"; # restore our start directory
198     }
199
200     my @ext;
201     push @ext, FindExt::static_ext() if $static;
202     push @ext, FindExt::dynamic_ext() if $dynamic;
203     push @ext, FindExt::nonxs_ext() if $nonxs;
204     push @ext, 'DynaLoader' if $dynaloader;
205
206     foreach (sort @ext) {
207         if (%incl and !exists $incl{$_}) {
208             #warn "Skipping extension $_, not in inclusion list\n";
209             next;
210         }
211         if (exists $excl{$_}) {
212             warn "Skipping extension $_, not ported to current platform";
213             next;
214         }
215         push @extspec, $_;
216         if($_ eq 'DynaLoader' and $target !~ /clean$/) {
217             # No, we don't know why nmake can't work out the dependency chain
218             push @{$extra_passthrough{$_}}, 'DynaLoader.c';
219         } elsif(FindExt::is_static($_)) {
220             push @{$extra_passthrough{$_}}, 'LINKTYPE=static';
221         }
222     }
223
224     chdir '..'
225         or die "Couldn't chdir to build directory: $!"; # now in the Perl build
226 }
227 elsif ($is_VMS) {
228     $perl = $^X;
229     push @extspec, (split ' ', $Config{static_ext}) if $static;
230     push @extspec, (split ' ', $Config{dynamic_ext}) if $dynamic;
231     push @extspec, (split ' ', $Config{nonxs_ext}) if $nonxs;
232     push @extspec, 'DynaLoader' if $dynaloader;
233 }
234
235 {
236     # Cwd needs to be built before Encode recurses into subdirectories.
237     # This seems to be the simplest way to ensure this ordering:
238     my (@first, @other);
239     foreach (@extspec) {
240         if ($_ eq 'Cwd') {
241             push @first, $_;
242         } else {
243             push @other, $_;
244         }
245     }
246     @extspec = (@first, @other);
247 }
248
249 if ($Config{osname} eq 'catamount' and @extspec) {
250     # Snowball's chance of building extensions.
251     die "This is $Config{osname}, not building $extspec[0], sorry.\n";
252 }
253
254 foreach my $spec (@extspec)  {
255     my $mname = $spec;
256     $mname =~ s!/!::!g;
257     my $ext_pathname;
258
259     # Try new style ext/Data-Dumper/ first
260     my $copy = $spec;
261     $copy =~ tr!/!-!;
262     foreach my $dir (@ext_dirs) {
263         if (-d "$dir/$copy") {
264             $ext_pathname = "$dir/$copy";
265             last;
266         }
267     }
268
269     if (!defined $ext_pathname) {
270         if (-d "ext/$spec") {
271             # Old style ext/Data/Dumper/
272             $ext_pathname = "ext/$spec";
273         } else {
274             warn "Can't find extension $spec in any of @ext_dirs";
275             next;
276         }
277     }
278
279     print "\tMaking $mname ($target)\n";
280
281     build_extension($ext_pathname, $perl, $mname,
282                     [@pass_through, @{$extra_passthrough{$spec} || []}]);
283 }
284
285 sub build_extension {
286     my ($ext_dir, $perl, $mname, $pass_through) = @_;
287
288     unless (chdir "$ext_dir") {
289         warn "Cannot cd to $ext_dir: $!";
290         return;
291     }
292
293     my $up = $ext_dir;
294     $up =~ s![^/]+!..!g;
295
296     $perl ||= "$up/miniperl";
297     my $return_dir = $up;
298     my $lib_dir = "$up/lib";
299     # $lib_dir must be last, as we're copying files into it, and in a parallel
300     # make there's a race condition if one process tries to open a module that
301     # another process has half-written.
302     my @new_inc = ((map {"$up/$_"} @toolchain), $lib_dir);
303     if ($is_Win32) {
304         @new_inc = map {File::Spec::Functions::rel2abs($_)} @new_inc;
305     }
306     $ENV{PERL5LIB} = join $Config{path_sep}, @new_inc;
307     $ENV{PERL_CORE} = 1;
308     # warn $ENV{PERL5LIB};
309
310     my $makefile;
311     if ($is_VMS) {
312         $makefile = 'descrip.mms';
313         if ($target =~ /clean$/
314             && !-f $makefile
315             && -f "${makefile}_old") {
316             $makefile = "${makefile}_old";
317         }
318     } else {
319         $makefile = 'Makefile';
320     }
321     
322     if (!-f $makefile) {
323         if (!-f 'Makefile.PL') {
324             print "\nCreating Makefile.PL in $ext_dir for $mname\n";
325             my ($fromname, $key, $value);
326             if ($mname eq 'podlators') {
327                 # We need to special case this somewhere, and this is fewer
328                 # lines of code than a core-only Makefile.PL, and no more
329                 # complex
330                 $fromname = 'VERSION';
331                 $key = 'DISTNAME';
332                 $value = 'podlators';
333                 $mname = 'Pod';
334             } else {
335                 $key = 'ABSTRACT_FROM';
336                 # We need to cope well with various possible layouts
337                 my @dirs = split /::/, $mname;
338                 my $leaf = pop @dirs;
339                 my $leafname = "$leaf.pm";
340                 my $pathname = join '/', @dirs, $leafname;
341                 my @locations = ($leafname, $pathname, "lib/$pathname");
342                 foreach (@locations) {
343                     if (-f $_) {
344                         $fromname = $_;
345                         last;
346                     }
347                 }
348
349                 unless ($fromname) {
350                     die "For $mname tried @locations in in $ext_dir but can't find source";
351                 }
352                 ($value = $fromname) =~ s/\.pm\z/.pod/;
353                 $value = $fromname unless -e $value;
354             }
355             open my $fh, '>', 'Makefile.PL'
356                 or die "Can't open Makefile.PL for writing: $!";
357             printf $fh <<'EOM', $0, $mname, $fromname, $key, $value;
358 #-*- buffer-read-only: t -*-
359
360 # This Makefile.PL was written by %s.
361 # It will be deleted automatically by make realclean
362
363 use strict;
364 use ExtUtils::MakeMaker;
365
366 # This is what the .PL extracts to. Not the ultimate file that is installed.
367 # (ie Win32 runs pl2bat after this)
368
369 # Doing this here avoids all sort of quoting issues that would come from
370 # attempting to write out perl source with literals to generate the arrays and
371 # hash.
372 my @temps = 'Makefile.PL';
373 foreach (glob('scripts/pod*.PL')) {
374     # The various pod*.PL extractors change directory. Doing that with relative
375     # paths in @INC breaks. It seems the lesser of two evils to copy (to avoid)
376     # the chdir doing anything, than to attempt to convert lib paths to
377     # absolute, and potentially run into problems with quoting special
378     # characters in the path to our build dir (such as spaces)
379     require File::Copy;
380
381     my $temp = $_;
382     $temp =~ s!scripts/!!;
383     File::Copy::copy($_, $temp) or die "Can't copy $temp to $_: $!";
384     push @temps, $temp;
385 }
386
387 my $script_ext = $^O eq 'VMS' ? '.com' : '';
388 my %%pod_scripts;
389 foreach (glob('pod*.PL')) {
390     my $script = $_;
391     s/.PL$/$script_ext/i;
392     $pod_scripts{$script} = $_;
393 }
394 my @exe_files = values %%pod_scripts;
395
396 WriteMakefile(
397     NAME          => '%s',
398     VERSION_FROM  => '%s',
399     %-13s => '%s',
400     realclean     => { FILES => "@temps" },
401     (%%pod_scripts ? (
402         PL_FILES  => \%%pod_scripts,
403         EXE_FILES => \@exe_files,
404         clean     => { FILES => "@exe_files" },
405     ) : ()),
406 );
407
408 # ex: set ro:
409 EOM
410             close $fh or die "Can't close Makefile.PL: $!";
411         }
412         print "\nRunning Makefile.PL in $ext_dir\n";
413
414         # Presumably this can be simplified
415         my @cross;
416         if (defined $::Cross::platform) {
417             # Inherited from win32/buildext.pl
418             @cross = "-MCross=$::Cross::platform";
419         } elsif ($opts{cross}) {
420             # Inherited from make_ext.pl
421             @cross = '-MCross';
422         }
423             
424         my @args = (@cross, 'Makefile.PL');
425         if ($is_VMS) {
426             my $libd = VMS::Filespec::vmspath($lib_dir);
427             push @args, "INST_LIB=$libd", "INST_ARCHLIB=$libd";
428         } else {
429             push @args, 'INSTALLDIRS=perl', 'INSTALLMAN1DIR=none',
430                 'INSTALLMAN3DIR=none';
431         }
432         push @args, @$pass_through;
433         _quote_args(\@args) if $is_VMS;
434         print join(' ', @run, $perl, @args), "\n";
435         my $code = system @run, $perl, @args;
436         warn "$code from $ext_dir\'s Makefile.PL" if $code;
437
438         # Right. The reason for this little hack is that we're sitting inside
439         # a program run by ./miniperl, but there are tasks we need to perform
440         # when the 'realclean', 'distclean' or 'veryclean' targets are run.
441         # Unfortunately, they can be run *after* 'clean', which deletes
442         # ./miniperl
443         # So we do our best to leave a set of instructions identical to what
444         # we would do if we are run directly as 'realclean' etc
445         # Whilst we're perfect, unfortunately the targets we call are not, as
446         # some of them rely on a $(PERL) for their own distclean targets.
447         # But this always used to be a problem with the old /bin/sh version of
448         # this.
449         if ($is_Unix) {
450             my $suffix = '.sh';
451             foreach my $clean_target ('realclean', 'veryclean') {
452                 my $file = "$return_dir/$clean_target$suffix";
453                 open my $fh, '>>', $file or die "open $file: $!";
454                 # Quite possible that we're being run in parallel here.
455                 # Can't use Fcntl this early to get the LOCK_EX
456                 flock $fh, 2 or warn "flock $file: $!";
457                 print $fh <<"EOS";
458 cd $ext_dir
459 if test ! -f Makefile -a -f Makefile.old; then
460     echo "Note: Using Makefile.old"
461     make -f Makefile.old $clean_target MAKE='@make' @pass_through
462 else
463     if test ! -f Makefile ; then
464         echo "Warning: No Makefile!"
465     fi
466     make $clean_target MAKE='@make' @pass_through
467 fi
468 cd $return_dir
469 EOS
470                 close $fh or die "close $file: $!";
471             }
472         }
473     }
474
475     if (not -f $makefile) {
476         print "Warning: No Makefile!\n";
477     }
478
479     if ($is_VMS) {
480         _macroify_passthrough($pass_through);
481         unshift @$pass_through, "/DESCRIPTION=$makefile";
482     }
483
484     if (!$target or $target !~ /clean$/) {
485         # Give makefile an opportunity to rewrite itself.
486         # reassure users that life goes on...
487         my @args = ('config', @$pass_through);
488         _quote_args(\@args) if $is_VMS;
489         system(@run, @make, @args) and print "@run @make @args failed, continuing anyway...\n";
490     }
491     my @targ = ($target, @$pass_through);
492     _quote_args(\@targ) if $is_VMS;
493     print "Making $target in $ext_dir\n@run @make @targ\n";
494     my $code = system(@run, @make, @targ);
495     die "Unsuccessful make($ext_dir): code=$code" if $code != 0;
496
497     chdir $return_dir || die "Cannot cd to $return_dir: $!";
498 }
499
500 sub _quote_args {
501     my $args = shift; # must be array reference
502
503     # Do not quote qualifiers that begin with '/'.
504     map { if (!/^\//) {
505           $_ =~ s/\"/""/g;     # escape C<"> by doubling
506           $_ = q(").$_.q(");
507         }
508     } @{$args}
509     ;
510 }
511
512 sub _macroify_passthrough {
513     my $passthrough = shift;
514     _quote_args($passthrough);
515     my $macro = '/MACRO=(' . join(',',@$passthrough) . ')';
516     @$passthrough = ();
517     @$passthrough[0] = $macro;  
518 }