This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Consistent spaces after dots in perlsub
[perl5.git] / pod / perlsub.pod
1 =head1 NAME
2 X<subroutine> X<function>
3
4 perlsub - Perl subroutines
5
6 =head1 SYNOPSIS
7
8 To declare subroutines:
9 X<subroutine, declaration> X<sub>
10
11     sub NAME;                     # A "forward" declaration.
12     sub NAME(PROTO);              #  ditto, but with prototypes
13     sub NAME : ATTRS;             #  with attributes
14     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
15
16     sub NAME BLOCK                # A declaration and a definition.
17     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
18     sub NAME SIG BLOCK            #  with signature
19     sub NAME : ATTRS BLOCK        #  with attributes
20     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
21     sub NAME : ATTRS SIG BLOCK    #  with attributes and signature
22
23 To define an anonymous subroutine at runtime:
24 X<subroutine, anonymous>
25
26     $subref = sub BLOCK;                 # no proto
27     $subref = sub (PROTO) BLOCK;         # with proto
28     $subref = sub SIG BLOCK;             # with signature
29     $subref = sub : ATTRS BLOCK;         # with attributes
30     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
31     $subref = sub : ATTRS SIG BLOCK;     # with attribs and signature
32
33 To import subroutines:
34 X<import>
35
36     use MODULE qw(NAME1 NAME2 NAME3);
37
38 To call subroutines:
39 X<subroutine, call> X<call>
40
41     NAME(LIST);    # & is optional with parentheses.
42     NAME LIST;     # Parentheses optional if predeclared/imported.
43     &NAME(LIST);   # Circumvent prototypes.
44     &NAME;         # Makes current @_ visible to called subroutine.
45
46 =head1 DESCRIPTION
47
48 Like many languages, Perl provides for user-defined subroutines.
49 These may be located anywhere in the main program, loaded in from
50 other files via the C<do>, C<require>, or C<use> keywords, or
51 generated on the fly using C<eval> or anonymous subroutines.
52 You can even call a function indirectly using a variable containing
53 its name or a CODE reference.
54
55 The Perl model for function call and return values is simple: all
56 functions are passed as parameters one single flat list of scalars, and
57 all functions likewise return to their caller one single flat list of
58 scalars.  Any arrays or hashes in these call and return lists will
59 collapse, losing their identities--but you may always use
60 pass-by-reference instead to avoid this.  Both call and return lists may
61 contain as many or as few scalar elements as you'd like.  (Often a
62 function without an explicit return statement is called a subroutine, but
63 there's really no difference from Perl's perspective.)
64 X<subroutine, parameter> X<parameter>
65
66 Any arguments passed in show up in the array C<@_>.
67 (They may also show up in lexical variables introduced by a signature;
68 see L</Signatures> below.)  Therefore, if
69 you called a function with two arguments, those would be stored in
70 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
71 elements are aliases for the actual scalar parameters.  In particular,
72 if an element C<$_[0]> is updated, the corresponding argument is
73 updated (or an error occurs if it is not updatable).  If an argument
74 is an array or hash element which did not exist when the function
75 was called, that element is created only when (and if) it is modified
76 or a reference to it is taken.  (Some earlier versions of Perl
77 created the element whether or not the element was assigned to.)
78 Assigning to the whole array C<@_> removes that aliasing, and does
79 not update any arguments.
80 X<subroutine, argument> X<argument> X<@_>
81
82 A C<return> statement may be used to exit a subroutine, optionally
83 specifying the returned value, which will be evaluated in the
84 appropriate context (list, scalar, or void) depending on the context of
85 the subroutine call.  If you specify no return value, the subroutine
86 returns an empty list in list context, the undefined value in scalar
87 context, or nothing in void context.  If you return one or more
88 aggregates (arrays and hashes), these will be flattened together into
89 one large indistinguishable list.
90
91 If no C<return> is found and if the last statement is an expression, its
92 value is returned.  If the last statement is a loop control structure
93 like a C<foreach> or a C<while>, the returned value is unspecified.  The
94 empty sub returns the empty list.
95 X<subroutine, return value> X<return value> X<return>
96
97 Aside from an experimental facility (see L</Signatures> below),
98 Perl does not have named formal parameters.  In practice all you
99 do is assign to a C<my()> list of these.  Variables that aren't
100 declared to be private are global variables.  For gory details
101 on creating private variables, see L<"Private Variables via my()">
102 and L<"Temporary Values via local()">.  To create protected
103 environments for a set of functions in a separate package (and
104 probably a separate file), see L<perlmod/"Packages">.
105 X<formal parameter> X<parameter, formal>
106
107 Example:
108
109     sub max {
110         my $max = shift(@_);
111         foreach $foo (@_) {
112             $max = $foo if $max < $foo;
113         }
114         return $max;
115     }
116     $bestday = max($mon,$tue,$wed,$thu,$fri);
117
118 Example:
119
120     # get a line, combining continuation lines
121     #  that start with whitespace
122
123     sub get_line {
124         $thisline = $lookahead;  # global variables!
125         LINE: while (defined($lookahead = <STDIN>)) {
126             if ($lookahead =~ /^[ \t]/) {
127                 $thisline .= $lookahead;
128             }
129             else {
130                 last LINE;
131             }
132         }
133         return $thisline;
134     }
135
136     $lookahead = <STDIN>;       # get first line
137     while (defined($line = get_line())) {
138         ...
139     }
140
141 Assigning to a list of private variables to name your arguments:
142
143     sub maybeset {
144         my($key, $value) = @_;
145         $Foo{$key} = $value unless $Foo{$key};
146     }
147
148 Because the assignment copies the values, this also has the effect
149 of turning call-by-reference into call-by-value.  Otherwise a
150 function is free to do in-place modifications of C<@_> and change
151 its caller's values.
152 X<call-by-reference> X<call-by-value>
153
154     upcase_in($v1, $v2);  # this changes $v1 and $v2
155     sub upcase_in {
156         for (@_) { tr/a-z/A-Z/ }
157     }
158
159 You aren't allowed to modify constants in this way, of course.  If an
160 argument were actually literal and you tried to change it, you'd take a
161 (presumably fatal) exception.   For example, this won't work:
162 X<call-by-reference> X<call-by-value>
163
164     upcase_in("frederick");
165
166 It would be much safer if the C<upcase_in()> function
167 were written to return a copy of its parameters instead
168 of changing them in place:
169
170     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
171     sub upcase {
172         return unless defined wantarray;  # void context, do nothing
173         my @parms = @_;
174         for (@parms) { tr/a-z/A-Z/ }
175         return wantarray ? @parms : $parms[0];
176     }
177
178 Notice how this (unprototyped) function doesn't care whether it was
179 passed real scalars or arrays.  Perl sees all arguments as one big,
180 long, flat parameter list in C<@_>.  This is one area where
181 Perl's simple argument-passing style shines.  The C<upcase()>
182 function would work perfectly well without changing the C<upcase()>
183 definition even if we fed it things like this:
184
185     @newlist   = upcase(@list1, @list2);
186     @newlist   = upcase( split /:/, $var );
187
188 Do not, however, be tempted to do this:
189
190     (@a, @b)   = upcase(@list1, @list2);
191
192 Like the flattened incoming parameter list, the return list is also
193 flattened on return.  So all you have managed to do here is stored
194 everything in C<@a> and made C<@b> empty.  See 
195 L<Pass by Reference> for alternatives.
196
197 A subroutine may be called using an explicit C<&> prefix.  The
198 C<&> is optional in modern Perl, as are parentheses if the
199 subroutine has been predeclared.  The C<&> is I<not> optional
200 when just naming the subroutine, such as when it's used as
201 an argument to defined() or undef().  Nor is it optional when you
202 want to do an indirect subroutine call with a subroutine name or
203 reference using the C<&$subref()> or C<&{$subref}()> constructs,
204 although the C<< $subref->() >> notation solves that problem.
205 See L<perlref> for more about all that.
206 X<&>
207
208 Subroutines may be called recursively.  If a subroutine is called
209 using the C<&> form, the argument list is optional, and if omitted,
210 no C<@_> array is set up for the subroutine: the C<@_> array at the
211 time of the call is visible to subroutine instead.  This is an
212 efficiency mechanism that new users may wish to avoid.
213 X<recursion>
214
215     &foo(1,2,3);        # pass three arguments
216     foo(1,2,3);         # the same
217
218     foo();              # pass a null list
219     &foo();             # the same
220
221     &foo;               # foo() get current args, like foo(@_) !!
222     foo;                # like foo() IFF sub foo predeclared, else "foo"
223
224 Not only does the C<&> form make the argument list optional, it also
225 disables any prototype checking on arguments you do provide.  This
226 is partly for historical reasons, and partly for having a convenient way
227 to cheat if you know what you're doing.  See L</Prototypes> below.
228 X<&>
229
230 Since Perl 5.16.0, the C<__SUB__> token is available under C<use feature
231 'current_sub'> and C<use 5.16.0>.  It will evaluate to a reference to the
232 currently-running sub, which allows for recursive calls without knowing
233 your subroutine's name.
234
235     use 5.16.0;
236     my $factorial = sub {
237       my ($x) = @_;
238       return 1 if $x == 1;
239       return($x * __SUB__->( $x - 1 ) );
240     };
241
242 The behaviour of C<__SUB__> within a regex code block (such as C</(?{...})/>)
243 is subject to change.
244
245 Subroutines whose names are in all upper case are reserved to the Perl
246 core, as are modules whose names are in all lower case.  A subroutine in
247 all capitals is a loosely-held convention meaning it will be called
248 indirectly by the run-time system itself, usually due to a triggered event.
249 Subroutines whose name start with a left parenthesis are also reserved the 
250 same way.  The following is a list of some subroutines that currently do 
251 special, pre-defined things.
252
253 =over
254
255 =item documented later in this document
256
257 C<AUTOLOAD>
258
259 =item documented in L<perlmod>
260
261 C<CLONE>, C<CLONE_SKIP>, 
262
263 =item documented in L<perlobj>
264
265 C<DESTROY>
266
267 =item documented in L<perltie>
268
269 C<BINMODE>, C<CLEAR>, C<CLOSE>, C<DELETE>, C<DESTROY>, C<EOF>, C<EXISTS>, 
270 C<EXTEND>, C<FETCH>, C<FETCHSIZE>, C<FILENO>, C<FIRSTKEY>, C<GETC>, 
271 C<NEXTKEY>, C<OPEN>, C<POP>, C<PRINT>, C<PRINTF>, C<PUSH>, C<READ>, 
272 C<READLINE>, C<SCALAR>, C<SEEK>, C<SHIFT>, C<SPLICE>, C<STORE>, 
273 C<STORESIZE>, C<TELL>, C<TIEARRAY>, C<TIEHANDLE>, C<TIEHASH>, 
274 C<TIESCALAR>, C<UNSHIFT>, C<UNTIE>, C<WRITE>
275
276 =item documented in L<PerlIO::via>
277
278 C<BINMODE>, C<CLEARERR>, C<CLOSE>, C<EOF>, C<ERROR>, C<FDOPEN>, C<FILENO>, 
279 C<FILL>, C<FLUSH>, C<OPEN>, C<POPPED>, C<PUSHED>, C<READ>, C<SEEK>, 
280 C<SETLINEBUF>, C<SYSOPEN>, C<TELL>, C<UNREAD>, C<UTF8>, C<WRITE>
281
282 =item documented in L<perlfunc>
283
284 L<< C<import> | perlfunc/use >>, L<< C<unimport> | perlfunc/use >>,
285 L<< C<INC> | perlfunc/require >>
286
287 =item documented in L<UNIVERSAL>
288
289 C<VERSION>
290
291 =item documented in L<perldebguts>
292
293 C<DB::DB>, C<DB::sub>, C<DB::lsub>, C<DB::goto>, C<DB::postponed>
294
295 =item undocumented, used internally by the L<overload> feature
296
297 any starting with C<(>
298
299 =back
300
301 The C<BEGIN>, C<UNITCHECK>, C<CHECK>, C<INIT> and C<END> subroutines
302 are not so much subroutines as named special code blocks, of which you
303 can have more than one in a package, and which you can B<not> call
304 explicitly.  See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END">
305
306 =head2 Signatures
307
308 B<WARNING>: Subroutine signatures are experimental.  The feature may be
309 modified or removed in future versions of Perl.
310
311 Perl has an experimental facility to allow a subroutine's formal
312 parameters to be introduced by special syntax, separate from the
313 procedural code of the subroutine body.  The formal parameter list
314 is known as a I<signature>.  The facility must be enabled first by a
315 pragmatic declaration, C<use feature 'signatures'>, and it will produce
316 a warning unless the "experimental::signatures" warnings category is
317 disabled.
318
319 The signature is part of a subroutine's body.  Normally the body of a
320 subroutine is simply a braced block of code.  When using a signature,
321 the signature is a parenthesised list that goes immediately before
322 the braced block.  The signature declares lexical variables that are
323 in scope for the block.  When the subroutine is called, the signature
324 takes control first.  It populates the signature variables from the
325 list of arguments that were passed.  If the argument list doesn't meet
326 the requirements of the signature, then it will throw an exception.
327 When the signature processing is complete, control passes to the block.
328
329 Positional parameters are handled by simply naming scalar variables in
330 the signature.  For example,
331
332     sub foo ($left, $right) {
333         return $left + $right;
334     }
335
336 takes two positional parameters, which must be filled at runtime by
337 two arguments.  By default the parameters are mandatory, and it is
338 not permitted to pass more arguments than expected.  So the above is
339 equivalent to
340
341     sub foo {
342         die "Too many arguments for subroutine" unless @_ <= 2;
343         die "Too few arguments for subroutine" unless @_ >= 2;
344         my $left = $_[0];
345         my $right = $_[1];
346         return $left + $right;
347     }
348
349 An argument can be ignored by omitting the main part of the name from
350 a parameter declaration, leaving just a bare C<$> sigil.  For example,
351
352     sub foo ($first, $, $third) {
353         return "first=$first, third=$third";
354     }
355
356 Although the ignored argument doesn't go into a variable, it is still
357 mandatory for the caller to pass it.
358
359 A positional parameter is made optional by giving a default value,
360 separated from the parameter name by C<=>:
361
362     sub foo ($left, $right = 0) {
363         return $left + $right;
364     }
365
366 The above subroutine may be called with either one or two arguments.
367 The default value expression is evaluated when the subroutine is called,
368 so it may provide different default values for different calls.  It is
369 only evaluated if the argument was actually omitted from the call.
370 For example,
371
372     my $auto_id = 0;
373     sub foo ($thing, $id = $auto_id++) {
374         print "$thing has ID $id";
375     }
376
377 automatically assigns distinct sequential IDs to things for which no
378 ID was supplied by the caller.  A default value expression may also
379 refer to parameters earlier in the signature, making the default for
380 one parameter vary according to the earlier parameters.  For example,
381
382     sub foo ($first_name, $surname, $nickname = $first_name) {
383         print "$first_name $surname is known as \"$nickname\"";
384     }
385
386 An optional parameter can be nameless just like a mandatory parameter.
387 For example,
388
389     sub foo ($thing, $ = 1) {
390         print $thing;
391     }
392
393 The parameter's default value will still be evaluated if the corresponding
394 argument isn't supplied, even though the value won't be stored anywhere.
395 This is in case evaluating it has important side effects.  However, it
396 will be evaluated in void context, so if it doesn't have side effects
397 and is not trivial it will generate a warning if the "void" warning
398 category is enabled.  If a nameless optional parameter's default value
399 is not important, it may be omitted just as the parameter's name was:
400
401     sub foo ($thing, $=) {
402         print $thing;
403     }
404
405 Optional positional parameters must come after all mandatory positional
406 parameters.  (If there are no mandatory positional parameters then an
407 optional positional parameters can be the first thing in the signature.)
408 If there are multiple optional positional parameters and not enough
409 arguments are supplied to fill them all, they will be filled from left
410 to right.
411
412 After positional parameters, additional arguments may be captured in a
413 slurpy parameter.  The simplest form of this is just an array variable:
414
415     sub foo ($filter, @inputs) {
416         print $filter->($_) foreach @inputs;
417     }
418
419 With a slurpy parameter in the signature, there is no upper limit on how
420 many arguments may be passed.  A slurpy array parameter may be nameless
421 just like a positional parameter, in which case its only effect is to
422 turn off the argument limit that would otherwise apply:
423
424     sub foo ($thing, @) {
425         print $thing;
426     }
427
428 A slurpy parameter may instead be a hash, in which case the arguments
429 available to it are interpreted as alternating keys and values.
430 There must be as many keys as values: if there is an odd argument then
431 an exception will be thrown.  Keys will be stringified, and if there are
432 duplicates then the later instance takes precedence over the earlier,
433 as with standard hash construction.
434
435     sub foo ($filter, %inputs) {
436         print $filter->($_, $inputs{$_}) foreach sort keys %inputs;
437     }
438
439 A slurpy hash parameter may be nameless just like other kinds of
440 parameter.  It still insists that the number of arguments available to
441 it be even, even though they're not being put into a variable.
442
443     sub foo ($thing, %) {
444         print $thing;
445     }
446
447 A slurpy parameter, either array or hash, must be the last thing in the
448 signature.  It may follow mandatory and optional positional parameters;
449 it may also be the only thing in the signature.  Slurpy parameters cannot
450 have default values: if no arguments are supplied for them then you get
451 an empty array or empty hash.
452
453 A signature may be entirely empty, in which case all it does is check
454 that the caller passed no arguments:
455
456     sub foo () {
457         return 123;
458     }
459
460 When using a signature, the arguments are still available in the special
461 array variable C<@_>, in addition to the lexical variables of the
462 signature.  There is a difference between the two ways of accessing the
463 arguments: C<@_> I<aliases> the arguments, but the signature variables
464 get I<copies> of the arguments.  So writing to a signature variable
465 only changes that variable, and has no effect on the caller's variables,
466 but writing to an element of C<@_> modifies whatever the caller used to
467 supply that argument.
468
469 There is a potential syntactic ambiguity between signatures and prototypes
470 (see L</Prototypes>), because both start with an opening parenthesis and
471 both can appear in some of the same places, such as just after the name
472 in a subroutine declaration.  For historical reasons, when signatures
473 are not enabled, any opening parenthesis in such a context will trigger
474 very forgiving prototype parsing.  Most signatures will be interpreted
475 as prototypes in those circumstances, but won't be valid prototypes.
476 (A valid prototype cannot contain any alphabetic character.)  This will
477 lead to somewhat confusing error messages.
478
479 To avoid ambiguity, when signatures are enabled the special syntax
480 for prototypes is disabled.  There is no attempt to guess whether a
481 parenthesised group was intended to be a prototype or a signature.
482 To give a subroutine a prototype under these circumstances, use a
483 L<prototype attribute|attributes/Built-in Attributes>.  For example,
484
485     sub foo :prototype($) { $_[0] }
486
487 It is entirely possible for a subroutine to have both a prototype and
488 a signature.  They do different jobs: the prototype affects compilation
489 of calls to the subroutine, and the signature puts argument values into
490 lexical variables at runtime.  You can therefore write
491
492     sub foo :prototype($$) ($left, $right) {
493         return $left + $right;
494     }
495
496 The prototype attribute, and any other attributes, must come before
497 the signature.  The signature always immediately precedes the block of
498 the subroutine's body.
499
500 =head2 Private Variables via my()
501 X<my> X<variable, lexical> X<lexical> X<lexical variable> X<scope, lexical>
502 X<lexical scope> X<attributes, my>
503
504 Synopsis:
505
506     my $foo;            # declare $foo lexically local
507     my (@wid, %get);    # declare list of variables local
508     my $foo = "flurp";  # declare $foo lexical, and init it
509     my @oof = @bar;     # declare @oof lexical, and init it
510     my $x : Foo = $y;   # similar, with an attribute applied
511
512 B<WARNING>: The use of attribute lists on C<my> declarations is still
513 evolving.  The current semantics and interface are subject to change.
514 See L<attributes> and L<Attribute::Handlers>.
515
516 The C<my> operator declares the listed variables to be lexically
517 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
518 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
519 or C<do/require/use>'d file.  If more than one value is listed, the
520 list must be placed in parentheses.  All listed elements must be
521 legal lvalues.  Only alphanumeric identifiers may be lexically
522 scoped--magical built-ins like C<$/> must currently be C<local>ized
523 with C<local> instead.
524
525 Unlike dynamic variables created by the C<local> operator, lexical
526 variables declared with C<my> are totally hidden from the outside
527 world, including any called subroutines.  This is true if it's the
528 same subroutine called from itself or elsewhere--every call gets
529 its own copy.
530 X<local>
531
532 This doesn't mean that a C<my> variable declared in a statically
533 enclosing lexical scope would be invisible.  Only dynamic scopes
534 are cut off.   For example, the C<bumpx()> function below has access
535 to the lexical $x variable because both the C<my> and the C<sub>
536 occurred at the same scope, presumably file scope.
537
538     my $x = 10;
539     sub bumpx { $x++ } 
540
541 An C<eval()>, however, can see lexical variables of the scope it is
542 being evaluated in, so long as the names aren't hidden by declarations within
543 the C<eval()> itself.  See L<perlref>.
544 X<eval, scope of>
545
546 The parameter list to my() may be assigned to if desired, which allows you
547 to initialize your variables.  (If no initializer is given for a
548 particular variable, it is created with the undefined value.)  Commonly
549 this is used to name input parameters to a subroutine.  Examples:
550
551     $arg = "fred";        # "global" variable
552     $n = cube_root(27);
553     print "$arg thinks the root is $n\n";
554  fred thinks the root is 3
555
556     sub cube_root {
557         my $arg = shift;  # name doesn't matter
558         $arg **= 1/3;
559         return $arg;
560     }
561
562 The C<my> is simply a modifier on something you might assign to.  So when
563 you do assign to variables in its argument list, C<my> doesn't
564 change whether those variables are viewed as a scalar or an array.  So
565
566     my ($foo) = <STDIN>;                # WRONG?
567     my @FOO = <STDIN>;
568
569 both supply a list context to the right-hand side, while
570
571     my $foo = <STDIN>;
572
573 supplies a scalar context.  But the following declares only one variable:
574
575     my $foo, $bar = 1;                  # WRONG
576
577 That has the same effect as
578
579     my $foo;
580     $bar = 1;
581
582 The declared variable is not introduced (is not visible) until after
583 the current statement.  Thus,
584
585     my $x = $x;
586
587 can be used to initialize a new $x with the value of the old $x, and
588 the expression
589
590     my $x = 123 and $x == 123
591
592 is false unless the old $x happened to have the value C<123>.
593
594 Lexical scopes of control structures are not bounded precisely by the
595 braces that delimit their controlled blocks; control expressions are
596 part of that scope, too.  Thus in the loop
597
598     while (my $line = <>) {
599         $line = lc $line;
600     } continue {
601         print $line;
602     }
603
604 the scope of $line extends from its declaration throughout the rest of
605 the loop construct (including the C<continue> clause), but not beyond
606 it.  Similarly, in the conditional
607
608     if ((my $answer = <STDIN>) =~ /^yes$/i) {
609         user_agrees();
610     } elsif ($answer =~ /^no$/i) {
611         user_disagrees();
612     } else {
613         chomp $answer;
614         die "'$answer' is neither 'yes' nor 'no'";
615     }
616
617 the scope of $answer extends from its declaration through the rest
618 of that conditional, including any C<elsif> and C<else> clauses, 
619 but not beyond it.  See L<perlsyn/"Simple Statements"> for information
620 on the scope of variables in statements with modifiers.
621
622 The C<foreach> loop defaults to scoping its index variable dynamically
623 in the manner of C<local>.  However, if the index variable is
624 prefixed with the keyword C<my>, or if there is already a lexical
625 by that name in scope, then a new lexical is created instead.  Thus
626 in the loop
627 X<foreach> X<for>
628
629     for my $i (1, 2, 3) {
630         some_function();
631     }
632
633 the scope of $i extends to the end of the loop, but not beyond it,
634 rendering the value of $i inaccessible within C<some_function()>.
635 X<foreach> X<for>
636
637 Some users may wish to encourage the use of lexically scoped variables.
638 As an aid to catching implicit uses to package variables,
639 which are always global, if you say
640
641     use strict 'vars';
642
643 then any variable mentioned from there to the end of the enclosing
644 block must either refer to a lexical variable, be predeclared via
645 C<our> or C<use vars>, or else must be fully qualified with the package name.
646 A compilation error results otherwise.  An inner block may countermand
647 this with C<no strict 'vars'>.
648
649 A C<my> has both a compile-time and a run-time effect.  At compile
650 time, the compiler takes notice of it.  The principal usefulness
651 of this is to quiet C<use strict 'vars'>, but it is also essential
652 for generation of closures as detailed in L<perlref>.  Actual
653 initialization is delayed until run time, though, so it gets executed
654 at the appropriate time, such as each time through a loop, for
655 example.
656
657 Variables declared with C<my> are not part of any package and are therefore
658 never fully qualified with the package name.  In particular, you're not
659 allowed to try to make a package variable (or other global) lexical:
660
661     my $pack::var;      # ERROR!  Illegal syntax
662
663 In fact, a dynamic variable (also known as package or global variables)
664 are still accessible using the fully qualified C<::> notation even while a
665 lexical of the same name is also visible:
666
667     package main;
668     local $x = 10;
669     my    $x = 20;
670     print "$x and $::x\n";
671
672 That will print out C<20> and C<10>.
673
674 You may declare C<my> variables at the outermost scope of a file
675 to hide any such identifiers from the world outside that file.  This
676 is similar in spirit to C's static variables when they are used at
677 the file level.  To do this with a subroutine requires the use of
678 a closure (an anonymous function that accesses enclosing lexicals).
679 If you want to create a private subroutine that cannot be called
680 from outside that block, it can declare a lexical variable containing
681 an anonymous sub reference:
682
683     my $secret_version = '1.001-beta';
684     my $secret_sub = sub { print $secret_version };
685     &$secret_sub();
686
687 As long as the reference is never returned by any function within the
688 module, no outside module can see the subroutine, because its name is not in
689 any package's symbol table.  Remember that it's not I<REALLY> called
690 C<$some_pack::secret_version> or anything; it's just $secret_version,
691 unqualified and unqualifiable.
692
693 This does not work with object methods, however; all object methods
694 have to be in the symbol table of some package to be found.  See
695 L<perlref/"Function Templates"> for something of a work-around to
696 this.
697
698 =head2 Persistent Private Variables
699 X<state> X<state variable> X<static> X<variable, persistent> X<variable, static> X<closure>
700
701 There are two ways to build persistent private variables in Perl 5.10.
702 First, you can simply use the C<state> feature.  Or, you can use closures,
703 if you want to stay compatible with releases older than 5.10.
704
705 =head3 Persistent variables via state()
706
707 Beginning with Perl 5.10.0, you can declare variables with the C<state>
708 keyword in place of C<my>.  For that to work, though, you must have
709 enabled that feature beforehand, either by using the C<feature> pragma, or
710 by using C<-E> on one-liners (see L<feature>).  Beginning with Perl 5.16,
711 the C<CORE::state> form does not require the
712 C<feature> pragma.
713
714 The C<state> keyword creates a lexical variable (following the same scoping
715 rules as C<my>) that persists from one subroutine call to the next.  If a
716 state variable resides inside an anonymous subroutine, then each copy of
717 the subroutine has its own copy of the state variable.  However, the value
718 of the state variable will still persist between calls to the same copy of
719 the anonymous subroutine.  (Don't forget that C<sub { ... }> creates a new
720 subroutine each time it is executed.)
721
722 For example, the following code maintains a private counter, incremented
723 each time the gimme_another() function is called:
724
725     use feature 'state';
726     sub gimme_another { state $x; return ++$x }
727
728 And this example uses anonymous subroutines to create separate counters:
729
730     use feature 'state';
731     sub create_counter {
732         return sub { state $x; return ++$x }
733     }
734
735 Also, since C<$x> is lexical, it can't be reached or modified by any Perl
736 code outside.
737
738 When combined with variable declaration, simple scalar assignment to C<state>
739 variables (as in C<state $x = 42>) is executed only the first time.  When such
740 statements are evaluated subsequent times, the assignment is ignored.  The
741 behavior of this sort of assignment to non-scalar variables is undefined.
742
743 =head3 Persistent variables with closures
744
745 Just because a lexical variable is lexically (also called statically)
746 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
747 within a function it works like a C static.  It normally works more
748 like a C auto, but with implicit garbage collection.  
749
750 Unlike local variables in C or C++, Perl's lexical variables don't
751 necessarily get recycled just because their scope has exited.
752 If something more permanent is still aware of the lexical, it will
753 stick around.  So long as something else references a lexical, that
754 lexical won't be freed--which is as it should be.  You wouldn't want
755 memory being free until you were done using it, or kept around once you
756 were done.  Automatic garbage collection takes care of this for you.
757
758 This means that you can pass back or save away references to lexical
759 variables, whereas to return a pointer to a C auto is a grave error.
760 It also gives us a way to simulate C's function statics.  Here's a
761 mechanism for giving a function private variables with both lexical
762 scoping and a static lifetime.  If you do want to create something like
763 C's static variables, just enclose the whole function in an extra block,
764 and put the static variable outside the function but in the block.
765
766     {
767         my $secret_val = 0;
768         sub gimme_another {
769             return ++$secret_val;
770         }
771     }
772     # $secret_val now becomes unreachable by the outside
773     # world, but retains its value between calls to gimme_another
774
775 If this function is being sourced in from a separate file
776 via C<require> or C<use>, then this is probably just fine.  If it's
777 all in the main program, you'll need to arrange for the C<my>
778 to be executed early, either by putting the whole block above
779 your main program, or more likely, placing merely a C<BEGIN>
780 code block around it to make sure it gets executed before your program
781 starts to run:
782
783     BEGIN {
784         my $secret_val = 0;
785         sub gimme_another {
786             return ++$secret_val;
787         }
788     }
789
790 See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END"> about the
791 special triggered code blocks, C<BEGIN>, C<UNITCHECK>, C<CHECK>,
792 C<INIT> and C<END>.
793
794 If declared at the outermost scope (the file scope), then lexicals
795 work somewhat like C's file statics.  They are available to all
796 functions in that same file declared below them, but are inaccessible
797 from outside that file.  This strategy is sometimes used in modules
798 to create private variables that the whole module can see.
799
800 =head2 Temporary Values via local()
801 X<local> X<scope, dynamic> X<dynamic scope> X<variable, local>
802 X<variable, temporary>
803
804 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
805 it's faster and safer.  Exceptions to this include the global punctuation
806 variables, global filehandles and formats, and direct manipulation of the
807 Perl symbol table itself.  C<local> is mostly used when the current value
808 of a variable must be visible to called subroutines.
809
810 Synopsis:
811
812     # localization of values
813
814     local $foo;                # make $foo dynamically local
815     local (@wid, %get);        # make list of variables local
816     local $foo = "flurp";      # make $foo dynamic, and init it
817     local @oof = @bar;         # make @oof dynamic, and init it
818
819     local $hash{key} = "val";  # sets a local value for this hash entry
820     delete local $hash{key};   # delete this entry for the current block
821     local ($cond ? $v1 : $v2); # several types of lvalues support
822                                # localization
823
824     # localization of symbols
825
826     local *FH;                 # localize $FH, @FH, %FH, &FH  ...
827     local *merlyn = *randal;   # now $merlyn is really $randal, plus
828                                #     @merlyn is really @randal, etc
829     local *merlyn = 'randal';  # SAME THING: promote 'randal' to *randal
830     local *merlyn = \$randal;  # just alias $merlyn, not @merlyn etc
831
832 A C<local> modifies its listed variables to be "local" to the
833 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
834 called from within that block>.  A C<local> just gives temporary
835 values to global (meaning package) variables.  It does I<not> create
836 a local variable.  This is known as dynamic scoping.  Lexical scoping
837 is done with C<my>, which works more like C's auto declarations.
838
839 Some types of lvalues can be localized as well: hash and array elements
840 and slices, conditionals (provided that their result is always
841 localizable), and symbolic references.  As for simple variables, this
842 creates new, dynamically scoped values.
843
844 If more than one variable or expression is given to C<local>, they must be
845 placed in parentheses.  This operator works
846 by saving the current values of those variables in its argument list on a
847 hidden stack and restoring them upon exiting the block, subroutine, or
848 eval.  This means that called subroutines can also reference the local
849 variable, but not the global one.  The argument list may be assigned to if
850 desired, which allows you to initialize your local variables.  (If no
851 initializer is given for a particular variable, it is created with an
852 undefined value.)
853
854 Because C<local> is a run-time operator, it gets executed each time
855 through a loop.  Consequently, it's more efficient to localize your
856 variables outside the loop.
857
858 =head3 Grammatical note on local()
859 X<local, context>
860
861 A C<local> is simply a modifier on an lvalue expression.  When you assign to
862 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
863 as a scalar or an array.  So
864
865     local($foo) = <STDIN>;
866     local @FOO = <STDIN>;
867
868 both supply a list context to the right-hand side, while
869
870     local $foo = <STDIN>;
871
872 supplies a scalar context.
873
874 =head3 Localization of special variables
875 X<local, special variable>
876
877 If you localize a special variable, you'll be giving a new value to it,
878 but its magic won't go away.  That means that all side-effects related
879 to this magic still work with the localized value.
880
881 This feature allows code like this to work :
882
883     # Read the whole contents of FILE in $slurp
884     { local $/ = undef; $slurp = <FILE>; }
885
886 Note, however, that this restricts localization of some values ; for
887 example, the following statement dies, as of perl 5.10.0, with an error
888 I<Modification of a read-only value attempted>, because the $1 variable is
889 magical and read-only :
890
891     local $1 = 2;
892
893 One exception is the default scalar variable: starting with perl 5.14
894 C<local($_)> will always strip all magic from $_, to make it possible
895 to safely reuse $_ in a subroutine.
896
897 B<WARNING>: Localization of tied arrays and hashes does not currently
898 work as described.
899 This will be fixed in a future release of Perl; in the meantime, avoid
900 code that relies on any particular behaviour of localising tied arrays
901 or hashes (localising individual elements is still okay).
902 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
903 details.
904 X<local, tie>
905
906 =head3 Localization of globs
907 X<local, glob> X<glob>
908
909 The construct
910
911     local *name;
912
913 creates a whole new symbol table entry for the glob C<name> in the
914 current package.  That means that all variables in its glob slot ($name,
915 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
916
917 This implies, among other things, that any magic eventually carried by
918 those variables is locally lost.  In other words, saying C<local */>
919 will not have any effect on the internal value of the input record
920 separator.
921
922 =head3 Localization of elements of composite types
923 X<local, composite type element> X<local, array element> X<local, hash element>
924
925 It's also worth taking a moment to explain what happens when you
926 C<local>ize a member of a composite type (i.e. an array or hash element).
927 In this case, the element is C<local>ized I<by name>.  This means that
928 when the scope of the C<local()> ends, the saved value will be
929 restored to the hash element whose key was named in the C<local()>, or
930 the array element whose index was named in the C<local()>.  If that
931 element was deleted while the C<local()> was in effect (e.g. by a
932 C<delete()> from a hash or a C<shift()> of an array), it will spring
933 back into existence, possibly extending an array and filling in the
934 skipped elements with C<undef>.  For instance, if you say
935
936     %hash = ( 'This' => 'is', 'a' => 'test' );
937     @ary  = ( 0..5 );
938     {
939          local($ary[5]) = 6;
940          local($hash{'a'}) = 'drill';
941          while (my $e = pop(@ary)) {
942              print "$e . . .\n";
943              last unless $e > 3;
944          }
945          if (@ary) {
946              $hash{'only a'} = 'test';
947              delete $hash{'a'};
948          }
949     }
950     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
951     print "The array has ",scalar(@ary)," elements: ",
952           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
953
954 Perl will print
955
956     6 . . .
957     4 . . .
958     3 . . .
959     This is a test only a test.
960     The array has 6 elements: 0, 1, 2, undef, undef, 5
961
962 The behavior of local() on non-existent members of composite
963 types is subject to change in future.
964
965 =head3 Localized deletion of elements of composite types
966 X<delete> X<local, composite type element> X<local, array element> X<local, hash element>
967
968 You can use the C<delete local $array[$idx]> and C<delete local $hash{key}>
969 constructs to delete a composite type entry for the current block and restore
970 it when it ends.  They return the array/hash value before the localization,
971 which means that they are respectively equivalent to
972
973     do {
974         my $val = $array[$idx];
975         local  $array[$idx];
976         delete $array[$idx];
977         $val
978     }
979
980 and
981
982     do {
983         my $val = $hash{key};
984         local  $hash{key};
985         delete $hash{key};
986         $val
987     }
988
989 except that for those the C<local> is
990 scoped to the C<do> block.  Slices are
991 also accepted.
992
993     my %hash = (
994      a => [ 7, 8, 9 ],
995      b => 1,
996     )
997
998     {
999      my $a = delete local $hash{a};
1000      # $a is [ 7, 8, 9 ]
1001      # %hash is (b => 1)
1002
1003      {
1004       my @nums = delete local @$a[0, 2]
1005       # @nums is (7, 9)
1006       # $a is [ undef, 8 ]
1007
1008       $a[0] = 999; # will be erased when the scope ends
1009      }
1010      # $a is back to [ 7, 8, 9 ]
1011
1012     }
1013     # %hash is back to its original state
1014
1015 =head2 Lvalue subroutines
1016 X<lvalue> X<subroutine, lvalue>
1017
1018 It is possible to return a modifiable value from a subroutine.
1019 To do this, you have to declare the subroutine to return an lvalue.
1020
1021     my $val;
1022     sub canmod : lvalue {
1023         $val;  # or:  return $val;
1024     }
1025     sub nomod {
1026         $val;
1027     }
1028
1029     canmod() = 5;   # assigns to $val
1030     nomod()  = 5;   # ERROR
1031
1032 The scalar/list context for the subroutine and for the right-hand
1033 side of assignment is determined as if the subroutine call is replaced
1034 by a scalar.  For example, consider:
1035
1036     data(2,3) = get_data(3,4);
1037
1038 Both subroutines here are called in a scalar context, while in:
1039
1040     (data(2,3)) = get_data(3,4);
1041
1042 and in:
1043
1044     (data(2),data(3)) = get_data(3,4);
1045
1046 all the subroutines are called in a list context.
1047
1048 Lvalue subroutines are convenient, but you have to keep in mind that,
1049 when used with objects, they may violate encapsulation.  A normal
1050 mutator can check the supplied argument before setting the attribute
1051 it is protecting, an lvalue subroutine cannot.  If you require any
1052 special processing when storing and retrieving the values, consider
1053 using the CPAN module Sentinel or something similar.
1054
1055 =head2 Lexical Subroutines
1056 X<my sub> X<state sub> X<our sub> X<subroutine, lexical>
1057
1058 B<WARNING>: Lexical subroutines are still experimental.  The feature may be
1059 modified or removed in future versions of Perl.
1060
1061 Lexical subroutines are only available under the C<use feature
1062 'lexical_subs'> pragma, which produces a warning unless the
1063 "experimental::lexical_subs" warnings category is disabled.
1064
1065 Beginning with Perl 5.18, you can declare a private subroutine with C<my>
1066 or C<state>.  As with state variables, the C<state> keyword is only
1067 available under C<use feature 'state'> or C<use 5.010> or higher.
1068
1069 These subroutines are only visible within the block in which they are
1070 declared, and only after that declaration:
1071
1072     no warnings "experimental::lexical_subs";
1073     use feature 'lexical_subs';
1074
1075     foo();              # calls the package/global subroutine
1076     state sub foo {
1077         foo();          # also calls the package subroutine
1078     }
1079     foo();              # calls "state" sub
1080     my $ref = \&foo;    # take a reference to "state" sub
1081
1082     my sub bar { ... }
1083     bar();              # calls "my" sub
1084
1085 To use a lexical subroutine from inside the subroutine itself, you must
1086 predeclare it.  The C<sub foo {...}> subroutine definition syntax respects
1087 any previous C<my sub;> or C<state sub;> declaration.
1088
1089     my sub baz;         # predeclaration
1090     sub baz {           # define the "my" sub
1091         baz();          # recursive call
1092     }
1093
1094 =head3 C<state sub> vs C<my sub>
1095
1096 What is the difference between "state" subs and "my" subs?  Each time that
1097 execution enters a block when "my" subs are declared, a new copy of each
1098 sub is created.  "State" subroutines persist from one execution of the
1099 containing block to the next.
1100
1101 So, in general, "state" subroutines are faster.  But "my" subs are
1102 necessary if you want to create closures:
1103
1104     no warnings "experimental::lexical_subs";
1105     use feature 'lexical_subs';
1106
1107     sub whatever {
1108         my $x = shift;
1109         my sub inner {
1110             ... do something with $x ...
1111         }
1112         inner();
1113     }
1114
1115 In this example, a new C<$x> is created when C<whatever> is called, and
1116 also a new C<inner>, which can see the new C<$x>.  A "state" sub will only
1117 see the C<$x> from the first call to C<whatever>.
1118
1119 =head3 C<our> subroutines
1120
1121 Like C<our $variable>, C<our sub> creates a lexical alias to the package
1122 subroutine of the same name.
1123
1124 The two main uses for this are to switch back to using the package sub
1125 inside an inner scope:
1126
1127     no warnings "experimental::lexical_subs";
1128     use feature 'lexical_subs';
1129
1130     sub foo { ... }
1131
1132     sub bar {
1133         my sub foo { ... }
1134         {
1135             # need to use the outer foo here
1136             our sub foo;
1137             foo();
1138         }
1139     }
1140
1141 and to make a subroutine visible to other packages in the same scope:
1142
1143     package MySneakyModule;
1144
1145     no warnings "experimental::lexical_subs";
1146     use feature 'lexical_subs';
1147
1148     our sub do_something { ... }
1149
1150     sub do_something_with_caller {
1151         package DB;
1152         () = caller 1;          # sets @DB::args
1153         do_something(@args);    # uses MySneakyModule::do_something
1154     }
1155
1156 =head2 Passing Symbol Table Entries (typeglobs)
1157 X<typeglob> X<*>
1158
1159 B<WARNING>: The mechanism described in this section was originally
1160 the only way to simulate pass-by-reference in older versions of
1161 Perl.  While it still works fine in modern versions, the new reference
1162 mechanism is generally easier to work with.  See below.
1163
1164 Sometimes you don't want to pass the value of an array to a subroutine
1165 but rather the name of it, so that the subroutine can modify the global
1166 copy of it rather than working with a local copy.  In perl you can
1167 refer to all objects of a particular name by prefixing the name
1168 with a star: C<*foo>.  This is often known as a "typeglob", because the
1169 star on the front can be thought of as a wildcard match for all the
1170 funny prefix characters on variables and subroutines and such.
1171
1172 When evaluated, the typeglob produces a scalar value that represents
1173 all the objects of that name, including any filehandle, format, or
1174 subroutine.  When assigned to, it causes the name mentioned to refer to
1175 whatever C<*> value was assigned to it.  Example:
1176
1177     sub doubleary {
1178         local(*someary) = @_;
1179         foreach $elem (@someary) {
1180             $elem *= 2;
1181         }
1182     }
1183     doubleary(*foo);
1184     doubleary(*bar);
1185
1186 Scalars are already passed by reference, so you can modify
1187 scalar arguments without using this mechanism by referring explicitly
1188 to C<$_[0]> etc.  You can modify all the elements of an array by passing
1189 all the elements as scalars, but you have to use the C<*> mechanism (or
1190 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
1191 an array.  It will certainly be faster to pass the typeglob (or reference).
1192
1193 Even if you don't want to modify an array, this mechanism is useful for
1194 passing multiple arrays in a single LIST, because normally the LIST
1195 mechanism will merge all the array values so that you can't extract out
1196 the individual arrays.  For more on typeglobs, see
1197 L<perldata/"Typeglobs and Filehandles">.
1198
1199 =head2 When to Still Use local()
1200 X<local> X<variable, local>
1201
1202 Despite the existence of C<my>, there are still three places where the
1203 C<local> operator still shines.  In fact, in these three places, you
1204 I<must> use C<local> instead of C<my>.
1205
1206 =over 4
1207
1208 =item 1.
1209
1210 You need to give a global variable a temporary value, especially $_.
1211
1212 The global variables, like C<@ARGV> or the punctuation variables, must be 
1213 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
1214 it up into chunks separated by lines of equal signs, which are placed
1215 in C<@Fields>.
1216
1217     {
1218         local @ARGV = ("/etc/motd");
1219         local $/ = undef;
1220         local $_ = <>;  
1221         @Fields = split /^\s*=+\s*$/;
1222     } 
1223
1224 It particular, it's important to C<local>ize $_ in any routine that assigns
1225 to it.  Look out for implicit assignments in C<while> conditionals.
1226
1227 =item 2.
1228
1229 You need to create a local file or directory handle or a local function.
1230
1231 A function that needs a filehandle of its own must use
1232 C<local()> on a complete typeglob.   This can be used to create new symbol
1233 table entries:
1234
1235     sub ioqueue {
1236         local  (*READER, *WRITER);    # not my!
1237         pipe    (READER,  WRITER)     or die "pipe: $!";
1238         return (*READER, *WRITER);
1239     }
1240     ($head, $tail) = ioqueue();
1241
1242 See the Symbol module for a way to create anonymous symbol table
1243 entries.
1244
1245 Because assignment of a reference to a typeglob creates an alias, this
1246 can be used to create what is effectively a local function, or at least,
1247 a local alias.
1248
1249     {
1250         local *grow = \&shrink; # only until this block exits
1251         grow();                # really calls shrink()
1252         move();                # if move() grow()s, it shrink()s too
1253     }
1254     grow();                    # get the real grow() again
1255
1256 See L<perlref/"Function Templates"> for more about manipulating
1257 functions by name in this way.
1258
1259 =item 3.
1260
1261 You want to temporarily change just one element of an array or hash.
1262
1263 You can C<local>ize just one element of an aggregate.  Usually this
1264 is done on dynamics:
1265
1266     {
1267         local $SIG{INT} = 'IGNORE';
1268         funct();                            # uninterruptible
1269     } 
1270     # interruptibility automatically restored here
1271
1272 But it also works on lexically declared aggregates.
1273
1274 =back
1275
1276 =head2 Pass by Reference
1277 X<pass by reference> X<pass-by-reference> X<reference>
1278
1279 If you want to pass more than one array or hash into a function--or
1280 return them from it--and have them maintain their integrity, then
1281 you're going to have to use an explicit pass-by-reference.  Before you
1282 do that, you need to understand references as detailed in L<perlref>.
1283 This section may not make much sense to you otherwise.
1284
1285 Here are a few simple examples.  First, let's pass in several arrays
1286 to a function and have it C<pop> all of then, returning a new list
1287 of all their former last elements:
1288
1289     @tailings = popmany ( \@a, \@b, \@c, \@d );
1290
1291     sub popmany {
1292         my $aref;
1293         my @retlist = ();
1294         foreach $aref ( @_ ) {
1295             push @retlist, pop @$aref;
1296         }
1297         return @retlist;
1298     }
1299
1300 Here's how you might write a function that returns a
1301 list of keys occurring in all the hashes passed to it:
1302
1303     @common = inter( \%foo, \%bar, \%joe );
1304     sub inter {
1305         my ($k, $href, %seen); # locals
1306         foreach $href (@_) {
1307             while ( $k = each %$href ) {
1308                 $seen{$k}++;
1309             }
1310         }
1311         return grep { $seen{$_} == @_ } keys %seen;
1312     }
1313
1314 So far, we're using just the normal list return mechanism.
1315 What happens if you want to pass or return a hash?  Well,
1316 if you're using only one of them, or you don't mind them
1317 concatenating, then the normal calling convention is ok, although
1318 a little expensive.
1319
1320 Where people get into trouble is here:
1321
1322     (@a, @b) = func(@c, @d);
1323 or
1324     (%a, %b) = func(%c, %d);
1325
1326 That syntax simply won't work.  It sets just C<@a> or C<%a> and
1327 clears the C<@b> or C<%b>.  Plus the function didn't get passed
1328 into two separate arrays or hashes: it got one long list in C<@_>,
1329 as always.
1330
1331 If you can arrange for everyone to deal with this through references, it's
1332 cleaner code, although not so nice to look at.  Here's a function that
1333 takes two array references as arguments, returning the two array elements
1334 in order of how many elements they have in them:
1335
1336     ($aref, $bref) = func(\@c, \@d);
1337     print "@$aref has more than @$bref\n";
1338     sub func {
1339         my ($cref, $dref) = @_;
1340         if (@$cref > @$dref) {
1341             return ($cref, $dref);
1342         } else {
1343             return ($dref, $cref);
1344         }
1345     }
1346
1347 It turns out that you can actually do this also:
1348
1349     (*a, *b) = func(\@c, \@d);
1350     print "@a has more than @b\n";
1351     sub func {
1352         local (*c, *d) = @_;
1353         if (@c > @d) {
1354             return (\@c, \@d);
1355         } else {
1356             return (\@d, \@c);
1357         }
1358     }
1359
1360 Here we're using the typeglobs to do symbol table aliasing.  It's
1361 a tad subtle, though, and also won't work if you're using C<my>
1362 variables, because only globals (even in disguise as C<local>s)
1363 are in the symbol table.
1364
1365 If you're passing around filehandles, you could usually just use the bare
1366 typeglob, like C<*STDOUT>, but typeglobs references work, too.
1367 For example:
1368
1369     splutter(\*STDOUT);
1370     sub splutter {
1371         my $fh = shift;
1372         print $fh "her um well a hmmm\n";
1373     }
1374
1375     $rec = get_rec(\*STDIN);
1376     sub get_rec {
1377         my $fh = shift;
1378         return scalar <$fh>;
1379     }
1380
1381 If you're planning on generating new filehandles, you could do this.
1382 Notice to pass back just the bare *FH, not its reference.
1383
1384     sub openit {
1385         my $path = shift;
1386         local *FH;
1387         return open (FH, $path) ? *FH : undef;
1388     }
1389
1390 =head2 Prototypes
1391 X<prototype> X<subroutine, prototype>
1392
1393 Perl supports a very limited kind of compile-time argument checking
1394 using function prototyping.  This can be declared in either the PROTO
1395 section or with a L<prototype attribute|attributes/Built-in Attributes>.
1396 If you declare either of
1397
1398     sub mypush (+@)
1399     sub mypush :prototype(+@)
1400
1401 then C<mypush()> takes arguments exactly like C<push()> does.
1402
1403 If subroutine signatures are enabled (see L</Signatures>), then
1404 the shorter PROTO syntax is unavailable, because it would clash with
1405 signatures.  In that case, a prototype can only be declared in the form
1406 of an attribute.
1407
1408 The
1409 function declaration must be visible at compile time.  The prototype
1410 affects only interpretation of new-style calls to the function,
1411 where new-style is defined as not using the C<&> character.  In
1412 other words, if you call it like a built-in function, then it behaves
1413 like a built-in function.  If you call it like an old-fashioned
1414 subroutine, then it behaves like an old-fashioned subroutine.  It
1415 naturally falls out from this rule that prototypes have no influence
1416 on subroutine references like C<\&foo> or on indirect subroutine
1417 calls like C<&{$subref}> or C<< $subref->() >>.
1418
1419 Method calls are not influenced by prototypes either, because the
1420 function to be called is indeterminate at compile time, since
1421 the exact code called depends on inheritance.
1422
1423 Because the intent of this feature is primarily to let you define
1424 subroutines that work like built-in functions, here are prototypes
1425 for some other functions that parse almost exactly like the
1426 corresponding built-in.
1427
1428    Declared as             Called as
1429
1430    sub mylink ($$)         mylink $old, $new
1431    sub myvec ($$$)         myvec $var, $offset, 1
1432    sub myindex ($$;$)      myindex &getstring, "substr"
1433    sub mysyswrite ($$$;$)  mysyswrite $buf, 0, length($buf) - $off, $off
1434    sub myreverse (@)       myreverse $a, $b, $c
1435    sub myjoin ($@)         myjoin ":", $a, $b, $c
1436    sub mypop (+)           mypop @array
1437    sub mysplice (+$$@)     mysplice @array, 0, 2, @pushme
1438    sub mykeys (+)          mykeys %{$hashref}
1439    sub myopen (*;$)        myopen HANDLE, $name
1440    sub mypipe (**)         mypipe READHANDLE, WRITEHANDLE
1441    sub mygrep (&@)         mygrep { /foo/ } $a, $b, $c
1442    sub myrand (;$)         myrand 42
1443    sub mytime ()           mytime
1444
1445 Any backslashed prototype character represents an actual argument
1446 that must start with that character (optionally preceded by C<my>,
1447 C<our> or C<local>), with the exception of C<$>, which will
1448 accept any scalar lvalue expression, such as C<$foo = 7> or
1449 C<< my_function()->[0] >>.  The value passed as part of C<@_> will be a
1450 reference to the actual argument given in the subroutine call,
1451 obtained by applying C<\> to that argument.
1452
1453 You can use the C<\[]> backslash group notation to specify more than one
1454 allowed argument type.  For example:
1455
1456     sub myref (\[$@%&*])
1457
1458 will allow calling myref() as
1459
1460     myref $var
1461     myref @array
1462     myref %hash
1463     myref &sub
1464     myref *glob
1465
1466 and the first argument of myref() will be a reference to
1467 a scalar, an array, a hash, a code, or a glob.
1468
1469 Unbackslashed prototype characters have special meanings.  Any
1470 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
1471 list context.  An argument represented by C<$> forces scalar context.  An
1472 C<&> requires an anonymous subroutine, which, if passed as the first
1473 argument, does not require the C<sub> keyword or a subsequent comma.
1474
1475 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1476 typeglob, or a reference to a typeglob in that slot.  The value will be
1477 available to the subroutine either as a simple scalar, or (in the latter
1478 two cases) as a reference to the typeglob.  If you wish to always convert
1479 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1480 follows:
1481
1482     use Symbol 'qualify_to_ref';
1483
1484     sub foo (*) {
1485         my $fh = qualify_to_ref(shift, caller);
1486         ...
1487     }
1488
1489 The C<+> prototype is a special alternative to C<$> that will act like
1490 C<\[@%]> when given a literal array or hash variable, but will otherwise
1491 force scalar context on the argument.  This is useful for functions which
1492 should accept either a literal array or an array reference as the argument:
1493
1494     sub mypush (+@) {
1495         my $aref = shift;
1496         die "Not an array or arrayref" unless ref $aref eq 'ARRAY';
1497         push @$aref, @_;
1498     }
1499
1500 When using the C<+> prototype, your function must check that the argument
1501 is of an acceptable type.
1502
1503 A semicolon (C<;>) separates mandatory arguments from optional arguments.
1504 It is redundant before C<@> or C<%>, which gobble up everything else.
1505
1506 As the last character of a prototype, or just before a semicolon, a C<@>
1507 or a C<%>, you can use C<_> in place of C<$>: if this argument is not
1508 provided, C<$_> will be used instead.
1509
1510 Note how the last three examples in the table above are treated
1511 specially by the parser.  C<mygrep()> is parsed as a true list
1512 operator, C<myrand()> is parsed as a true unary operator with unary
1513 precedence the same as C<rand()>, and C<mytime()> is truly without
1514 arguments, just like C<time()>.  That is, if you say
1515
1516     mytime +2;
1517
1518 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1519 without a prototype.  If you want to force a unary function to have the
1520 same precedence as a list operator, add C<;> to the end of the prototype:
1521
1522     sub mygetprotobynumber($;);
1523     mygetprotobynumber $a > $b; # parsed as mygetprotobynumber($a > $b)
1524
1525 The interesting thing about C<&> is that you can generate new syntax with it,
1526 provided it's in the initial position:
1527 X<&>
1528
1529     sub try (&@) {
1530         my($try,$catch) = @_;
1531         eval { &$try };
1532         if ($@) {
1533             local $_ = $@;
1534             &$catch;
1535         }
1536     }
1537     sub catch (&) { $_[0] }
1538
1539     try {
1540         die "phooey";
1541     } catch {
1542         /phooey/ and print "unphooey\n";
1543     };
1544
1545 That prints C<"unphooey">.  (Yes, there are still unresolved
1546 issues having to do with visibility of C<@_>.  I'm ignoring that
1547 question for the moment.  (But note that if we make C<@_> lexically
1548 scoped, those anonymous subroutines can act like closures... (Gee,
1549 is this sounding a little Lispish?  (Never mind.))))
1550
1551 And here's a reimplementation of the Perl C<grep> operator:
1552 X<grep>
1553
1554     sub mygrep (&@) {
1555         my $code = shift;
1556         my @result;
1557         foreach $_ (@_) {
1558             push(@result, $_) if &$code;
1559         }
1560         @result;
1561     }
1562
1563 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1564 been intentionally left out of prototypes for the express purpose of
1565 someday in the future adding named, formal parameters.  The current
1566 mechanism's main goal is to let module writers provide better diagnostics
1567 for module users.  Larry feels the notation quite understandable to Perl
1568 programmers, and that it will not intrude greatly upon the meat of the
1569 module, nor make it harder to read.  The line noise is visually
1570 encapsulated into a small pill that's easy to swallow.
1571
1572 If you try to use an alphanumeric sequence in a prototype you will
1573 generate an optional warning - "Illegal character in prototype...".
1574 Unfortunately earlier versions of Perl allowed the prototype to be
1575 used as long as its prefix was a valid prototype.  The warning may be
1576 upgraded to a fatal error in a future version of Perl once the
1577 majority of offending code is fixed.
1578
1579 It's probably best to prototype new functions, not retrofit prototyping
1580 into older ones.  That's because you must be especially careful about
1581 silent impositions of differing list versus scalar contexts.  For example,
1582 if you decide that a function should take just one parameter, like this:
1583
1584     sub func ($) {
1585         my $n = shift;
1586         print "you gave me $n\n";
1587     }
1588
1589 and someone has been calling it with an array or expression
1590 returning a list:
1591
1592     func(@foo);
1593     func( split /:/ );
1594
1595 Then you've just supplied an automatic C<scalar> in front of their
1596 argument, which can be more than a bit surprising.  The old C<@foo>
1597 which used to hold one thing doesn't get passed in.  Instead,
1598 C<func()> now gets passed in a C<1>; that is, the number of elements
1599 in C<@foo>.  And the C<split> gets called in scalar context so it
1600 starts scribbling on your C<@_> parameter list.  Ouch!
1601
1602 If a sub has both a PROTO and a BLOCK, the prototype is not applied
1603 until after the BLOCK is completely defined.  This means that a recursive
1604 function with a prototype has to be predeclared for the prototype to take
1605 effect, like so:
1606
1607         sub foo($$);
1608         sub foo($$) {
1609                 foo 1, 2;
1610         }
1611
1612 This is all very powerful, of course, and should be used only in moderation
1613 to make the world a better place.
1614
1615 =head2 Constant Functions
1616 X<constant>
1617
1618 Functions with a prototype of C<()> are potential candidates for
1619 inlining.  If the result after optimization and constant folding
1620 is either a constant or a lexically-scoped scalar which has no other
1621 references, then it will be used in place of function calls made
1622 without C<&>.  Calls made using C<&> are never inlined.  (See
1623 F<constant.pm> for an easy way to declare most constants.)
1624
1625 The following functions would all be inlined:
1626
1627     sub pi ()           { 3.14159 }             # Not exact, but close.
1628     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1629                                                 # and it's inlined, too!
1630     sub ST_DEV ()       { 0 }
1631     sub ST_INO ()       { 1 }
1632
1633     sub FLAG_FOO ()     { 1 << 8 }
1634     sub FLAG_BAR ()     { 1 << 9 }
1635     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1636
1637     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1638
1639     sub N () { int(OPT_BAZ) / 3 }
1640
1641     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }
1642
1643 Be aware that these will not be inlined; as they contain inner scopes,
1644 the constant folding doesn't reduce them to a single constant:
1645
1646     sub foo_set () { if (FLAG_MASK & FLAG_FOO) { 1 } }
1647
1648     sub baz_val () {
1649         if (OPT_BAZ) {
1650             return 23;
1651         }
1652         else {
1653             return 42;
1654         }
1655     }
1656
1657 As alluded to earlier you can also declare inlined subs dynamically at
1658 BEGIN time if their body consists of a lexically-scoped scalar which
1659 has no other references.  Only the first example here will be inlined:
1660
1661     BEGIN {
1662         my $var = 1;
1663         no strict 'refs';
1664         *INLINED = sub () { $var };
1665     }
1666
1667     BEGIN {
1668         my $var = 1;
1669         my $ref = \$var;
1670         no strict 'refs';
1671         *NOT_INLINED = sub () { $var };
1672     }
1673
1674 A not so obvious caveat with this (see [RT #79908]) is that the
1675 variable will be immediately inlined, and will stop behaving like a
1676 normal lexical variable, e.g. this will print C<79907>, not C<79908>:
1677
1678     BEGIN {
1679         my $x = 79907;
1680         *RT_79908 = sub () { $x };
1681         $x++;
1682     }
1683     print RT_79908(); # prints 79907
1684
1685 If you really want a subroutine with a C<()> prototype that returns a
1686 lexical variable you can easily force it to not be inlined by adding
1687 an explicit C<return>:
1688
1689     BEGIN {
1690         my $x = 79907;
1691         *RT_79908 = sub () { return $x };
1692         $x++;
1693     }
1694     print RT_79908(); # prints 79908
1695
1696 The easiest way to tell if a subroutine was inlined is by using
1697 L<B::Deparse>, consider this example of two subroutines returning
1698 C<1>, one with a C<()> prototype causing it to be inlined, and one
1699 without (with deparse output truncated for clarity):
1700
1701  $ perl -MO=Deparse -le 'sub ONE { 1 } if (ONE) { print ONE if ONE }'
1702  sub ONE {
1703      1;
1704  }
1705  if (ONE ) {
1706      print ONE() if ONE ;
1707  }
1708  $ perl -MO=Deparse -le 'sub ONE () { 1 } if (ONE) { print ONE if ONE }'
1709  sub ONE () { 1 }
1710  do {
1711      print 1
1712  };
1713
1714 If you redefine a subroutine that was eligible for inlining, you'll
1715 get a warning by default.  You can use this warning to tell whether or
1716 not a particular subroutine is considered inlinable, since it's
1717 different than the warning for overriding non-inlined subroutines:
1718
1719     $ perl -e 'sub one () {1} sub one () {2}'
1720     Constant subroutine one redefined at -e line 1.
1721     $ perl -we 'sub one {1} sub one {2}'
1722     Subroutine one redefined at -e line 1.
1723
1724 The warning is considered severe enough not to be affected by the
1725 B<-w> switch (or its absence) because previously compiled invocations
1726 of the function will still be using the old value of the function.  If
1727 you need to be able to redefine the subroutine, you need to ensure
1728 that it isn't inlined, either by dropping the C<()> prototype (which
1729 changes calling semantics, so beware) or by thwarting the inlining
1730 mechanism in some other way, e.g. by adding an explicit C<return>:
1731
1732     sub not_inlined () { return 23 }
1733
1734 =head2 Overriding Built-in Functions
1735 X<built-in> X<override> X<CORE> X<CORE::GLOBAL>
1736
1737 Many built-in functions may be overridden, though this should be tried
1738 only occasionally and for good reason.  Typically this might be
1739 done by a package attempting to emulate missing built-in functionality
1740 on a non-Unix system.
1741
1742 Overriding may be done only by importing the name from a module at
1743 compile time--ordinary predeclaration isn't good enough.  However, the
1744 C<use subs> pragma lets you, in effect, predeclare subs
1745 via the import syntax, and these names may then override built-in ones:
1746
1747     use subs 'chdir', 'chroot', 'chmod', 'chown';
1748     chdir $somewhere;
1749     sub chdir { ... }
1750
1751 To unambiguously refer to the built-in form, precede the
1752 built-in name with the special package qualifier C<CORE::>.  For example,
1753 saying C<CORE::open()> always refers to the built-in C<open()>, even
1754 if the current package has imported some other subroutine called
1755 C<&open()> from elsewhere.  Even though it looks like a regular
1756 function call, it isn't: the CORE:: prefix in that case is part of Perl's
1757 syntax, and works for any keyword, regardless of what is in the CORE
1758 package.  Taking a reference to it, that is, C<\&CORE::open>, only works
1759 for some keywords.  See L<CORE>.
1760
1761 Library modules should not in general export built-in names like C<open>
1762 or C<chdir> as part of their default C<@EXPORT> list, because these may
1763 sneak into someone else's namespace and change the semantics unexpectedly.
1764 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1765 possible for a user to import the name explicitly, but not implicitly.
1766 That is, they could say
1767
1768     use Module 'open';
1769
1770 and it would import the C<open> override.  But if they said
1771
1772     use Module;
1773
1774 they would get the default imports without overrides.
1775
1776 The foregoing mechanism for overriding built-in is restricted, quite
1777 deliberately, to the package that requests the import.  There is a second
1778 method that is sometimes applicable when you wish to override a built-in
1779 everywhere, without regard to namespace boundaries.  This is achieved by
1780 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1781 example that quite brazenly replaces the C<glob> operator with something
1782 that understands regular expressions.
1783
1784     package REGlob;
1785     require Exporter;
1786     @ISA = 'Exporter';
1787     @EXPORT_OK = 'glob';
1788
1789     sub import {
1790         my $pkg = shift;
1791         return unless @_;
1792         my $sym = shift;
1793         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1794         $pkg->export($where, $sym, @_);
1795     }
1796
1797     sub glob {
1798         my $pat = shift;
1799         my @got;
1800         if (opendir my $d, '.') { 
1801             @got = grep /$pat/, readdir $d; 
1802             closedir $d;   
1803         }
1804         return @got;
1805     }
1806     1;
1807
1808 And here's how it could be (ab)used:
1809
1810     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1811     package Foo;
1812     use REGlob 'glob';              # override glob() in Foo:: only
1813     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1814
1815 The initial comment shows a contrived, even dangerous example.
1816 By overriding C<glob> globally, you would be forcing the new (and
1817 subversive) behavior for the C<glob> operator for I<every> namespace,
1818 without the complete cognizance or cooperation of the modules that own
1819 those namespaces.  Naturally, this should be done with extreme caution--if
1820 it must be done at all.
1821
1822 The C<REGlob> example above does not implement all the support needed to
1823 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1824 different behaviors depending on whether it appears in a scalar or list
1825 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1826 context sensitive behaviors, and these must be adequately supported by
1827 a properly written override.  For a fully functional example of overriding
1828 C<glob>, study the implementation of C<File::DosGlob> in the standard
1829 library.
1830
1831 When you override a built-in, your replacement should be consistent (if
1832 possible) with the built-in native syntax.  You can achieve this by using
1833 a suitable prototype.  To get the prototype of an overridable built-in,
1834 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1835 (see L<perlfunc/prototype>).
1836
1837 Note however that some built-ins can't have their syntax expressed by a
1838 prototype (such as C<system> or C<chomp>).  If you override them you won't
1839 be able to fully mimic their original syntax.
1840
1841 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1842 to special magic, their original syntax is preserved, and you don't have
1843 to define a prototype for their replacements.  (You can't override the
1844 C<do BLOCK> syntax, though).
1845
1846 C<require> has special additional dark magic: if you invoke your
1847 C<require> replacement as C<require Foo::Bar>, it will actually receive
1848 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1849
1850 And, as you'll have noticed from the previous example, if you override
1851 C<glob>, the C<< <*> >> glob operator is overridden as well.
1852
1853 In a similar fashion, overriding the C<readline> function also overrides
1854 the equivalent I/O operator C<< <FILEHANDLE> >>.  Also, overriding
1855 C<readpipe> also overrides the operators C<``> and C<qx//>.
1856
1857 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1858
1859 =head2 Autoloading
1860 X<autoloading> X<AUTOLOAD>
1861
1862 If you call a subroutine that is undefined, you would ordinarily
1863 get an immediate, fatal error complaining that the subroutine doesn't
1864 exist.  (Likewise for subroutines being used as methods, when the
1865 method doesn't exist in any base class of the class's package.)
1866 However, if an C<AUTOLOAD> subroutine is defined in the package or
1867 packages used to locate the original subroutine, then that
1868 C<AUTOLOAD> subroutine is called with the arguments that would have
1869 been passed to the original subroutine.  The fully qualified name
1870 of the original subroutine magically appears in the global $AUTOLOAD
1871 variable of the same package as the C<AUTOLOAD> routine.  The name
1872 is not passed as an ordinary argument because, er, well, just
1873 because, that's why.  (As an exception, a method call to a nonexistent
1874 C<import> or C<unimport> method is just skipped instead.  Also, if
1875 the AUTOLOAD subroutine is an XSUB, there are other ways to retrieve the
1876 subroutine name.  See L<perlguts/Autoloading with XSUBs> for details.)
1877
1878
1879 Many C<AUTOLOAD> routines load in a definition for the requested
1880 subroutine using eval(), then execute that subroutine using a special
1881 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1882 without a trace.  (See the source to the standard module documented
1883 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1884 also just emulate the routine and never define it.   For example,
1885 let's pretend that a function that wasn't defined should just invoke
1886 C<system> with those arguments.  All you'd do is:
1887
1888     sub AUTOLOAD {
1889         my $program = $AUTOLOAD;
1890         $program =~ s/.*:://;
1891         system($program, @_);
1892     }
1893     date();
1894     who('am', 'i');
1895     ls('-l');
1896
1897 In fact, if you predeclare functions you want to call that way, you don't
1898 even need parentheses:
1899
1900     use subs qw(date who ls);
1901     date;
1902     who "am", "i";
1903     ls '-l';
1904
1905 A more complete example of this is the Shell module on CPAN, which
1906 can treat undefined subroutine calls as calls to external programs.
1907
1908 Mechanisms are available to help modules writers split their modules
1909 into autoloadable files.  See the standard AutoLoader module
1910 described in L<AutoLoader> and in L<AutoSplit>, the standard
1911 SelfLoader modules in L<SelfLoader>, and the document on adding C
1912 functions to Perl code in L<perlxs>.
1913
1914 =head2 Subroutine Attributes
1915 X<attribute> X<subroutine, attribute> X<attrs>
1916
1917 A subroutine declaration or definition may have a list of attributes
1918 associated with it.  If such an attribute list is present, it is
1919 broken up at space or colon boundaries and treated as though a
1920 C<use attributes> had been seen.  See L<attributes> for details
1921 about what attributes are currently supported.
1922 Unlike the limitation with the obsolescent C<use attrs>, the
1923 C<sub : ATTRLIST> syntax works to associate the attributes with
1924 a pre-declaration, and not just with a subroutine definition.
1925
1926 The attributes must be valid as simple identifier names (without any
1927 punctuation other than the '_' character).  They may have a parameter
1928 list appended, which is only checked for whether its parentheses ('(',')')
1929 nest properly.
1930
1931 Examples of valid syntax (even though the attributes are unknown):
1932
1933     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
1934     sub plugh () : Ugly('\(") :Bad;
1935     sub xyzzy : _5x5 { ... }
1936
1937 Examples of invalid syntax:
1938
1939     sub fnord : switch(10,foo(); # ()-string not balanced
1940     sub snoid : Ugly('(');        # ()-string not balanced
1941     sub xyzzy : 5x5;              # "5x5" not a valid identifier
1942     sub plugh : Y2::north;        # "Y2::north" not a simple identifier
1943     sub snurt : foo + bar;        # "+" not a colon or space
1944
1945 The attribute list is passed as a list of constant strings to the code
1946 which associates them with the subroutine.  In particular, the second example
1947 of valid syntax above currently looks like this in terms of how it's
1948 parsed and invoked:
1949
1950     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1951
1952 For further details on attribute lists and their manipulation,
1953 see L<attributes> and L<Attribute::Handlers>.
1954
1955 =head1 SEE ALSO
1956
1957 See L<perlref/"Function Templates"> for more about references and closures.
1958 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1959 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1960 See L<perlmod> to learn about bundling up your functions in separate files.
1961 See L<perlmodlib> to learn what library modules come standard on your system.
1962 See L<perlootut> to learn how to make object method calls.