This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
b76da4a3ce9d3568bdd9835553ad7cdbe921a407
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix. The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">. The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope. In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>. Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
361 the undefined value if the file doesn't exist.  Despite the funny
362 names, precedence is the same as any other named unary operator.  The
363 operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link.
382     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
383     -S  File is a socket.
384     -b  File is a block special file.
385     -c  File is a character special file.
386     -t  Filehandle is opened to a tty.
387
388     -u  File has setuid bit set.
389     -g  File has setgid bit set.
390     -k  File has sticky bit set.
391
392     -T  File is an ASCII text file (heuristic guess).
393     -B  File is a "binary" file (opposite of -T).
394
395     -M  Script start time minus file modification time, in days.
396     -A  Same for access time.
397     -C  Same for inode change time (Unix, may differ for other
398         platforms)
399
400 Example:
401
402     while (<>) {
403         chomp;
404         next unless -f $_;  # ignore specials
405         #...
406     }
407
408 Note that C<-s/a/b/> does not do a negated substitution.  Saying
409 C<-exp($foo)> still works as expected, however: only single letters
410 following a minus are interpreted as file tests.
411
412 These operators are exempt from the "looks like a function rule" described
413 above.  That is, an opening parenthesis after the operator does not affect
414 how much of the following code constitutes the argument.  Put the opening
415 parentheses before the operator to separate it from code that follows (this
416 applies only to operators with higher precedence than unary operators, of
417 course):
418
419     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
420     (-s $file) + 1024  # correct
421
422 The interpretation of the file permission operators C<-r>, C<-R>,
423 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
424 of the file and the uids and gids of the user.  There may be other
425 reasons you can't actually read, write, or execute the file: for
426 example network filesystem access controls, ACLs (access control lists),
427 read-only filesystems, and unrecognized executable formats.  Note
428 that the use of these six specific operators to verify if some operation
429 is possible is usually a mistake, because it may be open to race
430 conditions.
431
432 Also note that, for the superuser on the local filesystems, the C<-r>,
433 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
434 if any execute bit is set in the mode.  Scripts run by the superuser
435 may thus need to do a stat() to determine the actual mode of the file,
436 or temporarily set their effective uid to something else.
437
438 If you are using ACLs, there is a pragma called C<filetest> that may
439 produce more accurate results than the bare stat() mode bits.
440 When under C<use filetest 'access'> the above-mentioned filetests
441 test whether the permission can(not) be granted using the
442 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
443 under this pragma return true even if there are no execute permission
444 bits set (nor any extra execute permission ACLs).  This strangeness is
445 due to the underlying system calls' definitions.  Note also that, due to
446 the implementation of C<use filetest 'access'>, the C<_> special
447 filehandle won't cache the results of the file tests when this pragma is
448 in effect.  Read the documentation for the C<filetest> pragma for more
449 information.
450
451 The C<-T> and C<-B> switches work as follows.  The first block or so of the
452 file is examined for odd characters such as strange control codes or
453 characters with the high bit set.  If too many strange characters (>30%)
454 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
455 containing a zero byte in the first block is considered a binary file.  If C<-T>
456 or C<-B> is used on a filehandle, the current IO buffer is examined
457 rather than the first block.  Both C<-T> and C<-B> return true on an empty
458 file, or a file at EOF when testing a filehandle.  Because you have to
459 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
460 against the file first, as in C<next unless -f $file && -T $file>.
461
462 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
463 the special filehandle consisting of a solitary underline, then the stat
464 structure of the previous file test (or stat operator) is used, saving
465 a system call.  (This doesn't work with C<-t>, and you need to remember
466 that lstat() and C<-l> leave values in the stat structure for the
467 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
468 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
469 Example:
470
471     print "Can do.\n" if -r $a || -w _ || -x _;
472
473     stat($filename);
474     print "Readable\n" if -r _;
475     print "Writable\n" if -w _;
476     print "Executable\n" if -x _;
477     print "Setuid\n" if -u _;
478     print "Setgid\n" if -g _;
479     print "Sticky\n" if -k _;
480     print "Text\n" if -T _;
481     print "Binary\n" if -B _;
482
483 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
484 test operators, in a way that C<-f -w -x $file> is equivalent to
485 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
486 the return value of C<-f $file> as an argument to another filetest
487 operator, no special magic will happen.)
488
489 Portability issues: L<perlport/-X>.
490
491 To avoid confusing would-be users of your code with mysterious
492 syntax errors, put something like this at the top of your script:
493
494     use 5.010;  # so filetest ops can stack
495
496 =item abs VALUE
497 X<abs> X<absolute>
498
499 =item abs
500
501 =for Pod::Functions absolute value function
502
503 Returns the absolute value of its argument.
504 If VALUE is omitted, uses C<$_>.
505
506 =item accept NEWSOCKET,GENERICSOCKET
507 X<accept>
508
509 =for Pod::Functions accept an incoming socket connect
510
511 Accepts an incoming socket connect, just as accept(2) 
512 does.  Returns the packed address if it succeeded, false otherwise.
513 See the example in L<perlipc/"Sockets: Client/Server Communication">.
514
515 On systems that support a close-on-exec flag on files, the flag will
516 be set for the newly opened file descriptor, as determined by the
517 value of $^F.  See L<perlvar/$^F>.
518
519 =item alarm SECONDS
520 X<alarm>
521 X<SIGALRM>
522 X<timer>
523
524 =item alarm
525
526 =for Pod::Functions schedule a SIGALRM
527
528 Arranges to have a SIGALRM delivered to this process after the
529 specified number of wallclock seconds has elapsed.  If SECONDS is not
530 specified, the value stored in C<$_> is used.  (On some machines,
531 unfortunately, the elapsed time may be up to one second less or more
532 than you specified because of how seconds are counted, and process
533 scheduling may delay the delivery of the signal even further.)
534
535 Only one timer may be counting at once.  Each call disables the
536 previous timer, and an argument of C<0> may be supplied to cancel the
537 previous timer without starting a new one.  The returned value is the
538 amount of time remaining on the previous timer.
539
540 For delays of finer granularity than one second, the Time::HiRes module
541 (from CPAN, and starting from Perl 5.8 part of the standard
542 distribution) provides ualarm().  You may also use Perl's four-argument
543 version of select() leaving the first three arguments undefined, or you
544 might be able to use the C<syscall> interface to access setitimer(2) if
545 your system supports it.  See L<perlfaq8> for details.
546
547 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
548 C<sleep> may be internally implemented on your system with C<alarm>.
549
550 If you want to use C<alarm> to time out a system call you need to use an
551 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
552 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
553 restart system calls on some systems.  Using C<eval>/C<die> always works,
554 modulo the caveats given in L<perlipc/"Signals">.
555
556     eval {
557         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
558         alarm $timeout;
559         $nread = sysread SOCKET, $buffer, $size;
560         alarm 0;
561     };
562     if ($@) {
563         die unless $@ eq "alarm\n";   # propagate unexpected errors
564         # timed out
565     }
566     else {
567         # didn't
568     }
569
570 For more information see L<perlipc>.
571
572 Portability issues: L<perlport/alarm>.
573
574 =item atan2 Y,X
575 X<atan2> X<arctangent> X<tan> X<tangent>
576
577 =for Pod::Functions arctangent of Y/X in the range -PI to PI
578
579 Returns the arctangent of Y/X in the range -PI to PI.
580
581 For the tangent operation, you may use the C<Math::Trig::tan>
582 function, or use the familiar relation:
583
584     sub tan { sin($_[0]) / cos($_[0])  }
585
586 The return value for C<atan2(0,0)> is implementation-defined; consult
587 your atan2(3) manpage for more information.
588
589 Portability issues: L<perlport/atan2>.
590
591 =item bind SOCKET,NAME
592 X<bind>
593
594 =for Pod::Functions binds an address to a socket
595
596 Binds a network address to a socket, just as bind(2)
597 does.  Returns true if it succeeded, false otherwise.  NAME should be a
598 packed address of the appropriate type for the socket.  See the examples in
599 L<perlipc/"Sockets: Client/Server Communication">.
600
601 =item binmode FILEHANDLE, LAYER
602 X<binmode> X<binary> X<text> X<DOS> X<Windows>
603
604 =item binmode FILEHANDLE
605
606 =for Pod::Functions prepare binary files for I/O
607
608 Arranges for FILEHANDLE to be read or written in "binary" or "text"
609 mode on systems where the run-time libraries distinguish between
610 binary and text files.  If FILEHANDLE is an expression, the value is
611 taken as the name of the filehandle.  Returns true on success,
612 otherwise it returns C<undef> and sets C<$!> (errno).
613
614 On some systems (in general, DOS- and Windows-based systems) binmode()
615 is necessary when you're not working with a text file.  For the sake
616 of portability it is a good idea always to use it when appropriate,
617 and never to use it when it isn't appropriate.  Also, people can
618 set their I/O to be by default UTF8-encoded Unicode, not bytes.
619
620 In other words: regardless of platform, use binmode() on binary data,
621 like images, for example.
622
623 If LAYER is present it is a single string, but may contain multiple
624 directives.  The directives alter the behaviour of the filehandle.
625 When LAYER is present, using binmode on a text file makes sense.
626
627 If LAYER is omitted or specified as C<:raw> the filehandle is made
628 suitable for passing binary data.  This includes turning off possible CRLF
629 translation and marking it as bytes (as opposed to Unicode characters).
630 Note that, despite what may be implied in I<"Programming Perl"> (the
631 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
632 Other layers that would affect the binary nature of the stream are
633 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
634 PERLIO environment variable.
635
636 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
637 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
638 establish default I/O layers.  See L<open>.
639
640 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
641 in "Programming Perl, 3rd Edition".  However, since the publishing of this
642 book, by many known as "Camel III", the consensus of the naming of this
643 functionality has moved from "discipline" to "layer".  All documentation
644 of this version of Perl therefore refers to "layers" rather than to
645 "disciplines".  Now back to the regularly scheduled documentation...>
646
647 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
648 C<:utf8> just marks the data as UTF-8 without further checking,
649 while C<:encoding(UTF-8)> checks the data for actually being valid
650 UTF-8.  More details can be found in L<PerlIO::encoding>.
651
652 In general, binmode() should be called after open() but before any I/O
653 is done on the filehandle.  Calling binmode() normally flushes any
654 pending buffered output data (and perhaps pending input data) on the
655 handle.  An exception to this is the C<:encoding> layer that
656 changes the default character encoding of the handle; see L</open>.
657 The C<:encoding> layer sometimes needs to be called in
658 mid-stream, and it doesn't flush the stream.  The C<:encoding>
659 also implicitly pushes on top of itself the C<:utf8> layer because
660 internally Perl operates on UTF8-encoded Unicode characters.
661
662 The operating system, device drivers, C libraries, and Perl run-time
663 system all conspire to let the programmer treat a single
664 character (C<\n>) as the line terminator, irrespective of external
665 representation.  On many operating systems, the native text file
666 representation matches the internal representation, but on some
667 platforms the external representation of C<\n> is made up of more than
668 one character.
669
670 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
671 a single character to end each line in the external representation of text
672 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
673 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
674 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
675 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
676 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
677 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
678 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
679 output.  This is what you want for text files, but it can be disastrous for
680 binary files.
681
682 Another consequence of using binmode() (on some systems) is that
683 special end-of-file markers will be seen as part of the data stream.
684 For systems from the Microsoft family this means that, if your binary
685 data contain C<\cZ>, the I/O subsystem will regard it as the end of
686 the file, unless you use binmode().
687
688 binmode() is important not only for readline() and print() operations,
689 but also when using read(), seek(), sysread(), syswrite() and tell()
690 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
691 in L<perlvar> for how to manually set your input and output
692 line-termination sequences.
693
694 Portability issues: L<perlport/binmode>.
695
696 =item bless REF,CLASSNAME
697 X<bless>
698
699 =item bless REF
700
701 =for Pod::Functions create an object
702
703 This function tells the thingy referenced by REF that it is now an object
704 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
705 is used.  Because a C<bless> is often the last thing in a constructor,
706 it returns the reference for convenience.  Always use the two-argument
707 version if a derived class might inherit the function doing the blessing.
708 See L<perlobj> for more about the blessing (and blessings) of objects.
709
710 Consider always blessing objects in CLASSNAMEs that are mixed case.
711 Namespaces with all lowercase names are considered reserved for
712 Perl pragmata.  Builtin types have all uppercase names.  To prevent
713 confusion, you may wish to avoid such package names as well.  Make sure
714 that CLASSNAME is a true value.
715
716 See L<perlmod/"Perl Modules">.
717
718 =item break
719
720 =for Pod::Functions +switch break out of a C<given> block
721
722 Break out of a C<given()> block.
723
724 This keyword is enabled by the C<"switch"> feature: see
725 L<feature> for more information.  You can also access it by
726 prefixing it with C<CORE::>.  Alternately, include a C<use
727 v5.10> or later to the current scope.
728
729 =item caller EXPR
730 X<caller> X<call stack> X<stack> X<stack trace>
731
732 =item caller
733
734 =for Pod::Functions get context of the current subroutine call
735
736 Returns the context of the current subroutine call.  In scalar context,
737 returns the caller's package name if there I<is> a caller (that is, if
738 we're in a subroutine or C<eval> or C<require>) and the undefined value
739 otherwise.  In list context, returns
740
741     # 0         1          2
742     ($package, $filename, $line) = caller;
743
744 With EXPR, it returns some extra information that the debugger uses to
745 print a stack trace.  The value of EXPR indicates how many call frames
746 to go back before the current one.
747
748     #  0         1          2      3            4
749     ($package, $filename, $line, $subroutine, $hasargs,
750
751     #  5          6          7            8       9         10
752     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
753      = caller($i);
754
755 Here $subroutine may be C<(eval)> if the frame is not a subroutine
756 call, but an C<eval>.  In such a case additional elements $evaltext and
757 C<$is_require> are set: C<$is_require> is true if the frame is created by a
758 C<require> or C<use> statement, $evaltext contains the text of the
759 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
760 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
761 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
762 frame.)  $subroutine may also be C<(unknown)> if this particular
763 subroutine happens to have been deleted from the symbol table.
764 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
765 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
766 compiled with.  C<$hints> corresponds to C<$^H>, and C<$bitmask>
767 corresponds to C<${^WARNING_BITS}>.  The
768 C<$hints> and C<$bitmask> values are subject
769 to change between versions of Perl, and are not meant for external use.
770
771 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
772 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
773 of this hash, as they are the actual values stored in the optree.
774
775 Furthermore, when called from within the DB package in
776 list context, and with an argument, caller returns more
777 detailed information: it sets the list variable C<@DB::args> to be the
778 arguments with which the subroutine was invoked.
779
780 Be aware that the optimizer might have optimized call frames away before
781 C<caller> had a chance to get the information.  That means that C<caller(N)>
782 might not return information about the call frame you expect it to, for
783 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
784 previous time C<caller> was called.
785
786 Be aware that setting C<@DB::args> is I<best effort>, intended for
787 debugging or generating backtraces, and should not be relied upon.  In
788 particular, as C<@_> contains aliases to the caller's arguments, Perl does
789 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
790 subroutine makes to C<@_> or its contents, not the original values at call
791 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
792 elements, so under certain cases its elements may have become freed and
793 reallocated for other variables or temporary values.  Finally, a side effect
794 of the current implementation is that the effects of C<shift @_> can
795 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
796 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
797 elements), so C<@DB::args> is actually a hybrid of the current state and
798 initial state of C<@_>.  Buyer beware.
799
800 =item chdir EXPR
801 X<chdir>
802 X<cd>
803 X<directory, change>
804
805 =item chdir FILEHANDLE
806
807 =item chdir DIRHANDLE
808
809 =item chdir
810
811 =for Pod::Functions change your current working directory
812
813 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
814 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
815 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
816 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
817 neither is set, C<chdir> does nothing.  It returns true on success,
818 false otherwise.  See the example under C<die>.
819
820 On systems that support fchdir(2), you may pass a filehandle or
821 directory handle as the argument.  On systems that don't support fchdir(2),
822 passing handles raises an exception.
823
824 =item chmod LIST
825 X<chmod> X<permission> X<mode>
826
827 =for Pod::Functions changes the permissions on a list of files
828
829 Changes the permissions of a list of files.  The first element of the
830 list must be the numeric mode, which should probably be an octal
831 number, and which definitely should I<not> be a string of octal digits:
832 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
833 successfully changed.  See also L</oct> if all you have is a string.
834
835     $cnt = chmod 0755, "foo", "bar";
836     chmod 0755, @executables;
837     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
838                                              # --w----r-T
839     $mode = "0644"; chmod oct($mode), "foo"; # this is better
840     $mode = 0644;   chmod $mode, "foo";      # this is best
841
842 On systems that support fchmod(2), you may pass filehandles among the
843 files.  On systems that don't support fchmod(2), passing filehandles raises
844 an exception.  Filehandles must be passed as globs or glob references to be
845 recognized; barewords are considered filenames.
846
847     open(my $fh, "<", "foo");
848     my $perm = (stat $fh)[2] & 07777;
849     chmod($perm | 0600, $fh);
850
851 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
852 module:
853
854     use Fcntl qw( :mode );
855     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
856     # Identical to the chmod 0755 of the example above.
857
858 Portability issues: L<perlport/chmod>.
859
860 =item chomp VARIABLE
861 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
862
863 =item chomp( LIST )
864
865 =item chomp
866
867 =for Pod::Functions remove a trailing record separator from a string
868
869 This safer version of L</chop> removes any trailing string
870 that corresponds to the current value of C<$/> (also known as
871 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
872 number of characters removed from all its arguments.  It's often used to
873 remove the newline from the end of an input record when you're worried
874 that the final record may be missing its newline.  When in paragraph
875 mode (C<$/ = "">), it removes all trailing newlines from the string.
876 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
877 a reference to an integer or the like; see L<perlvar>) chomp() won't
878 remove anything.
879 If VARIABLE is omitted, it chomps C<$_>.  Example:
880
881     while (<>) {
882         chomp;  # avoid \n on last field
883         @array = split(/:/);
884         # ...
885     }
886
887 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
888
889 You can actually chomp anything that's an lvalue, including an assignment:
890
891     chomp($cwd = `pwd`);
892     chomp($answer = <STDIN>);
893
894 If you chomp a list, each element is chomped, and the total number of
895 characters removed is returned.
896
897 Note that parentheses are necessary when you're chomping anything
898 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
899 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
900 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
901 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
902 as C<chomp($a, $b)>.
903
904 =item chop VARIABLE
905 X<chop>
906
907 =item chop( LIST )
908
909 =item chop
910
911 =for Pod::Functions remove the last character from a string
912
913 Chops off the last character of a string and returns the character
914 chopped.  It is much more efficient than C<s/.$//s> because it neither
915 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
916 If VARIABLE is a hash, it chops the hash's values, but not its keys.
917
918 You can actually chop anything that's an lvalue, including an assignment.
919
920 If you chop a list, each element is chopped.  Only the value of the
921 last C<chop> is returned.
922
923 Note that C<chop> returns the last character.  To return all but the last
924 character, use C<substr($string, 0, -1)>.
925
926 See also L</chomp>.
927
928 =item chown LIST
929 X<chown> X<owner> X<user> X<group>
930
931 =for Pod::Functions change the ownership on a list of files
932
933 Changes the owner (and group) of a list of files.  The first two
934 elements of the list must be the I<numeric> uid and gid, in that
935 order.  A value of -1 in either position is interpreted by most
936 systems to leave that value unchanged.  Returns the number of files
937 successfully changed.
938
939     $cnt = chown $uid, $gid, 'foo', 'bar';
940     chown $uid, $gid, @filenames;
941
942 On systems that support fchown(2), you may pass filehandles among the
943 files.  On systems that don't support fchown(2), passing filehandles raises
944 an exception.  Filehandles must be passed as globs or glob references to be
945 recognized; barewords are considered filenames.
946
947 Here's an example that looks up nonnumeric uids in the passwd file:
948
949     print "User: ";
950     chomp($user = <STDIN>);
951     print "Files: ";
952     chomp($pattern = <STDIN>);
953
954     ($login,$pass,$uid,$gid) = getpwnam($user)
955         or die "$user not in passwd file";
956
957     @ary = glob($pattern);  # expand filenames
958     chown $uid, $gid, @ary;
959
960 On most systems, you are not allowed to change the ownership of the
961 file unless you're the superuser, although you should be able to change
962 the group to any of your secondary groups.  On insecure systems, these
963 restrictions may be relaxed, but this is not a portable assumption.
964 On POSIX systems, you can detect this condition this way:
965
966     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
967     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
968
969 Portability issues: L<perlport/chmod>.
970
971 =item chr NUMBER
972 X<chr> X<character> X<ASCII> X<Unicode>
973
974 =item chr
975
976 =for Pod::Functions get character this number represents
977
978 Returns the character represented by that NUMBER in the character set.
979 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
980 chr(0x263a) is a Unicode smiley face.  
981
982 Negative values give the Unicode replacement character (chr(0xfffd)),
983 except under the L<bytes> pragma, where the low eight bits of the value
984 (truncated to an integer) are used.
985
986 If NUMBER is omitted, uses C<$_>.
987
988 For the reverse, use L</ord>.
989
990 Note that characters from 128 to 255 (inclusive) are by default
991 internally not encoded as UTF-8 for backward compatibility reasons.
992
993 See L<perlunicode> for more about Unicode.
994
995 =item chroot FILENAME
996 X<chroot> X<root>
997
998 =item chroot
999
1000 =for Pod::Functions make directory new root for path lookups
1001
1002 This function works like the system call by the same name: it makes the
1003 named directory the new root directory for all further pathnames that
1004 begin with a C</> by your process and all its children.  (It doesn't
1005 change your current working directory, which is unaffected.)  For security
1006 reasons, this call is restricted to the superuser.  If FILENAME is
1007 omitted, does a C<chroot> to C<$_>.
1008
1009 Portability issues: L<perlport/chroot>.
1010
1011 =item close FILEHANDLE
1012 X<close>
1013
1014 =item close
1015
1016 =for Pod::Functions close file (or pipe or socket) handle
1017
1018 Closes the file or pipe associated with the filehandle, flushes the IO
1019 buffers, and closes the system file descriptor.  Returns true if those
1020 operations succeed and if no error was reported by any PerlIO
1021 layer.  Closes the currently selected filehandle if the argument is
1022 omitted.
1023
1024 You don't have to close FILEHANDLE if you are immediately going to do
1025 another C<open> on it, because C<open> closes it for you.  (See
1026 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1027 counter (C<$.>), while the implicit close done by C<open> does not.
1028
1029 If the filehandle came from a piped open, C<close> returns false if one of
1030 the other syscalls involved fails or if its program exits with non-zero
1031 status.  If the only problem was that the program exited non-zero, C<$!>
1032 will be set to C<0>.  Closing a pipe also waits for the process executing
1033 on the pipe to exit--in case you wish to look at the output of the pipe
1034 afterwards--and implicitly puts the exit status value of that command into
1035 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1036
1037 If there are multiple threads running, C<close> on a filehandle from a
1038 piped open returns true without waiting for the child process to terminate,
1039 if the filehandle is still open in another thread.
1040
1041 Closing the read end of a pipe before the process writing to it at the
1042 other end is done writing results in the writer receiving a SIGPIPE.  If
1043 the other end can't handle that, be sure to read all the data before
1044 closing the pipe.
1045
1046 Example:
1047
1048     open(OUTPUT, '|sort >foo')  # pipe to sort
1049         or die "Can't start sort: $!";
1050     #...                        # print stuff to output
1051     close OUTPUT                # wait for sort to finish
1052         or warn $! ? "Error closing sort pipe: $!"
1053                    : "Exit status $? from sort";
1054     open(INPUT, 'foo')          # get sort's results
1055         or die "Can't open 'foo' for input: $!";
1056
1057 FILEHANDLE may be an expression whose value can be used as an indirect
1058 filehandle, usually the real filehandle name or an autovivified handle.
1059
1060 =item closedir DIRHANDLE
1061 X<closedir>
1062
1063 =for Pod::Functions close directory handle
1064
1065 Closes a directory opened by C<opendir> and returns the success of that
1066 system call.
1067
1068 =item connect SOCKET,NAME
1069 X<connect>
1070
1071 =for Pod::Functions connect to a remote socket
1072
1073 Attempts to connect to a remote socket, just like connect(2).
1074 Returns true if it succeeded, false otherwise.  NAME should be a
1075 packed address of the appropriate type for the socket.  See the examples in
1076 L<perlipc/"Sockets: Client/Server Communication">.
1077
1078 =item continue BLOCK
1079 X<continue>
1080
1081 =item continue
1082
1083 =for Pod::Functions optional trailing block in a while or foreach
1084
1085 When followed by a BLOCK, C<continue> is actually a
1086 flow control statement rather than a function.  If
1087 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1088 C<foreach>), it is always executed just before the conditional is about to
1089 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1090 it can be used to increment a loop variable, even when the loop has been
1091 continued via the C<next> statement (which is similar to the C C<continue>
1092 statement).
1093
1094 C<last>, C<next>, or C<redo> may appear within a C<continue>
1095 block; C<last> and C<redo> behave as if they had been executed within
1096 the main block.  So will C<next>, but since it will execute a C<continue>
1097 block, it may be more entertaining.
1098
1099     while (EXPR) {
1100         ### redo always comes here
1101         do_something;
1102     } continue {
1103         ### next always comes here
1104         do_something_else;
1105         # then back the top to re-check EXPR
1106     }
1107     ### last always comes here
1108
1109 Omitting the C<continue> section is equivalent to using an
1110 empty one, logically enough, so C<next> goes directly back
1111 to check the condition at the top of the loop.
1112
1113 When there is no BLOCK, C<continue> is a function that
1114 falls through the current C<when> or C<default> block instead of iterating
1115 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1116 In Perl 5.14 and earlier, this form of C<continue> was
1117 only available when the C<"switch"> feature was enabled.
1118 See L<feature> and L<perlsyn/"Switch Statements"> for more
1119 information.
1120
1121 =item cos EXPR
1122 X<cos> X<cosine> X<acos> X<arccosine>
1123
1124 =item cos
1125
1126 =for Pod::Functions cosine function
1127
1128 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1129 takes the cosine of C<$_>.
1130
1131 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1132 function, or use this relation:
1133
1134     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1135
1136 =item crypt PLAINTEXT,SALT
1137 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1138 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1139
1140 =for Pod::Functions one-way passwd-style encryption
1141
1142 Creates a digest string exactly like the crypt(3) function in the C
1143 library (assuming that you actually have a version there that has not
1144 been extirpated as a potential munition).
1145
1146 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1147 into a short string, called a digest, which is returned.  The same
1148 PLAINTEXT and SALT will always return the same string, but there is no
1149 (known) way to get the original PLAINTEXT from the hash.  Small
1150 changes in the PLAINTEXT or SALT will result in large changes in the
1151 digest.
1152
1153 There is no decrypt function.  This function isn't all that useful for
1154 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1155 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1156 primarily used to check if two pieces of text are the same without
1157 having to transmit or store the text itself.  An example is checking
1158 if a correct password is given.  The digest of the password is stored,
1159 not the password itself.  The user types in a password that is
1160 crypt()'d with the same salt as the stored digest.  If the two digests
1161 match, the password is correct.
1162
1163 When verifying an existing digest string you should use the digest as
1164 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1165 to create the digest is visible as part of the digest.  This ensures
1166 crypt() will hash the new string with the same salt as the digest.
1167 This allows your code to work with the standard L<crypt|/crypt> and
1168 with more exotic implementations.  In other words, assume
1169 nothing about the returned string itself nor about how many bytes 
1170 of SALT may matter.
1171
1172 Traditionally the result is a string of 13 bytes: two first bytes of
1173 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1174 the first eight bytes of PLAINTEXT mattered.  But alternative
1175 hashing schemes (like MD5), higher level security schemes (like C2),
1176 and implementations on non-Unix platforms may produce different
1177 strings.
1178
1179 When choosing a new salt create a random two character string whose
1180 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1181 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1182 characters is just a recommendation; the characters allowed in
1183 the salt depend solely on your system's crypt library, and Perl can't
1184 restrict what salts C<crypt()> accepts.
1185
1186 Here's an example that makes sure that whoever runs this program knows
1187 their password:
1188
1189     $pwd = (getpwuid($<))[1];
1190
1191     system "stty -echo";
1192     print "Password: ";
1193     chomp($word = <STDIN>);
1194     print "\n";
1195     system "stty echo";
1196
1197     if (crypt($word, $pwd) ne $pwd) {
1198         die "Sorry...\n";
1199     } else {
1200         print "ok\n";
1201     }
1202
1203 Of course, typing in your own password to whoever asks you
1204 for it is unwise.
1205
1206 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1207 of data, not least of all because you can't get the information
1208 back.  Look at the L<Digest> module for more robust algorithms.
1209
1210 If using crypt() on a Unicode string (which I<potentially> has
1211 characters with codepoints above 255), Perl tries to make sense
1212 of the situation by trying to downgrade (a copy of)
1213 the string back to an eight-bit byte string before calling crypt()
1214 (on that copy).  If that works, good.  If not, crypt() dies with
1215 C<Wide character in crypt>.
1216
1217 Portability issues: L<perlport/crypt>.
1218
1219 =item dbmclose HASH
1220 X<dbmclose>
1221
1222 =for Pod::Functions breaks binding on a tied dbm file
1223
1224 [This function has been largely superseded by the C<untie> function.]
1225
1226 Breaks the binding between a DBM file and a hash.
1227
1228 Portability issues: L<perlport/dbmclose>.
1229
1230 =item dbmopen HASH,DBNAME,MASK
1231 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1232
1233 =for Pod::Functions create binding on a tied dbm file
1234
1235 [This function has been largely superseded by the
1236 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1237
1238 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1239 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1240 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1241 is the name of the database (without the F<.dir> or F<.pag> extension if
1242 any).  If the database does not exist, it is created with protection
1243 specified by MASK (as modified by the C<umask>).  To prevent creation of
1244 the database if it doesn't exist, you may specify a MODE
1245 of 0, and the function will return a false value if it
1246 can't find an existing database.  If your system supports
1247 only the older DBM functions, you may make only one C<dbmopen> call in your
1248 program.  In older versions of Perl, if your system had neither DBM nor
1249 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1250 sdbm(3).
1251
1252 If you don't have write access to the DBM file, you can only read hash
1253 variables, not set them.  If you want to test whether you can write,
1254 either use file tests or try setting a dummy hash entry inside an C<eval> 
1255 to trap the error.
1256
1257 Note that functions such as C<keys> and C<values> may return huge lists
1258 when used on large DBM files.  You may prefer to use the C<each>
1259 function to iterate over large DBM files.  Example:
1260
1261     # print out history file offsets
1262     dbmopen(%HIST,'/usr/lib/news/history',0666);
1263     while (($key,$val) = each %HIST) {
1264         print $key, ' = ', unpack('L',$val), "\n";
1265     }
1266     dbmclose(%HIST);
1267
1268 See also L<AnyDBM_File> for a more general description of the pros and
1269 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1270 rich implementation.
1271
1272 You can control which DBM library you use by loading that library
1273 before you call dbmopen():
1274
1275     use DB_File;
1276     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1277         or die "Can't open netscape history file: $!";
1278
1279 Portability issues: L<perlport/dbmopen>.
1280
1281 =item defined EXPR
1282 X<defined> X<undef> X<undefined>
1283
1284 =item defined
1285
1286 =for Pod::Functions test whether a value, variable, or function is defined
1287
1288 Returns a Boolean value telling whether EXPR has a value other than
1289 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1290 checked.
1291
1292 Many operations return C<undef> to indicate failure, end of file,
1293 system error, uninitialized variable, and other exceptional
1294 conditions.  This function allows you to distinguish C<undef> from
1295 other values.  (A simple Boolean test will not distinguish among
1296 C<undef>, zero, the empty string, and C<"0">, which are all equally
1297 false.)  Note that since C<undef> is a valid scalar, its presence
1298 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1299 returns C<undef> when its argument is an empty array, I<or> when the
1300 element to return happens to be C<undef>.
1301
1302 You may also use C<defined(&func)> to check whether subroutine C<&func>
1303 has ever been defined.  The return value is unaffected by any forward
1304 declarations of C<&func>.  A subroutine that is not defined
1305 may still be callable: its package may have an C<AUTOLOAD> method that
1306 makes it spring into existence the first time that it is called; see
1307 L<perlsub>.
1308
1309 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1310 used to report whether memory for that aggregate had ever been
1311 allocated.  This behavior may disappear in future versions of Perl.
1312 You should instead use a simple test for size:
1313
1314     if (@an_array) { print "has array elements\n" }
1315     if (%a_hash)   { print "has hash members\n"   }
1316
1317 When used on a hash element, it tells you whether the value is defined,
1318 not whether the key exists in the hash.  Use L</exists> for the latter
1319 purpose.
1320
1321 Examples:
1322
1323     print if defined $switch{D};
1324     print "$val\n" while defined($val = pop(@ary));
1325     die "Can't readlink $sym: $!"
1326         unless defined($value = readlink $sym);
1327     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1328     $debugging = 0 unless defined $debugging;
1329
1330 Note:  Many folks tend to overuse C<defined> and are then surprised to
1331 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1332 defined values.  For example, if you say
1333
1334     "ab" =~ /a(.*)b/;
1335
1336 The pattern match succeeds and C<$1> is defined, although it
1337 matched "nothing".  It didn't really fail to match anything.  Rather, it
1338 matched something that happened to be zero characters long.  This is all
1339 very above-board and honest.  When a function returns an undefined value,
1340 it's an admission that it couldn't give you an honest answer.  So you
1341 should use C<defined> only when questioning the integrity of what
1342 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1343 what you want.
1344
1345 See also L</undef>, L</exists>, L</ref>.
1346
1347 =item delete EXPR
1348 X<delete>
1349
1350 =for Pod::Functions deletes a value from a hash
1351
1352 Given an expression that specifies an element or slice of a hash, C<delete>
1353 deletes the specified elements from that hash so that exists() on that element
1354 no longer returns true.  Setting a hash element to the undefined value does
1355 not remove its key, but deleting it does; see L</exists>.
1356
1357 In list context, returns the value or values deleted, or the last such
1358 element in scalar context.  The return list's length always matches that of
1359 the argument list: deleting non-existent elements returns the undefined value
1360 in their corresponding positions.
1361
1362 delete() may also be used on arrays and array slices, but its behavior is less
1363 straightforward.  Although exists() will return false for deleted entries,
1364 deleting array elements never changes indices of existing values; use shift()
1365 or splice() for that.  However, if all deleted elements fall at the end of an
1366 array, the array's size shrinks to the position of the highest element that
1367 still tests true for exists(), or to 0 if none do.
1368
1369 B<WARNING:> Calling delete on array values is deprecated and likely to
1370 be removed in a future version of Perl.
1371
1372 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1373 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1374 or array may not necessarily return anything; it depends on the implementation
1375 of the C<tied> package's DELETE method, which may do whatever it pleases.
1376
1377 The C<delete local EXPR> construct localizes the deletion to the current
1378 block at run time.  Until the block exits, elements locally deleted
1379 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1380 of composite types">.
1381
1382     %hash = (foo => 11, bar => 22, baz => 33);
1383     $scalar = delete $hash{foo};         # $scalar is 11
1384     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1385     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1386
1387 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1388
1389     foreach $key (keys %HASH) {
1390         delete $HASH{$key};
1391     }
1392
1393     foreach $index (0 .. $#ARRAY) {
1394         delete $ARRAY[$index];
1395     }
1396
1397 And so do these:
1398
1399     delete @HASH{keys %HASH};
1400
1401     delete @ARRAY[0 .. $#ARRAY];
1402
1403 But both are slower than assigning the empty list
1404 or undefining %HASH or @ARRAY, which is the customary 
1405 way to empty out an aggregate:
1406
1407     %HASH = ();     # completely empty %HASH
1408     undef %HASH;    # forget %HASH ever existed
1409
1410     @ARRAY = ();    # completely empty @ARRAY
1411     undef @ARRAY;   # forget @ARRAY ever existed
1412
1413 The EXPR can be arbitrarily complicated provided its
1414 final operation is an element or slice of an aggregate:
1415
1416     delete $ref->[$x][$y]{$key};
1417     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1418
1419     delete $ref->[$x][$y][$index];
1420     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1421
1422 =item die LIST
1423 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1424
1425 =for Pod::Functions raise an exception or bail out
1426
1427 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1428 into C<$@> and the C<eval> is terminated with the undefined value.
1429 If the exception is outside of all enclosing C<eval>s, then the uncaught
1430 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1431 need to exit the process with a specific exit code, see L</exit>.
1432
1433 Equivalent examples:
1434
1435     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1436     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1437
1438 If the last element of LIST does not end in a newline, the current
1439 script line number and input line number (if any) are also printed,
1440 and a newline is supplied.  Note that the "input line number" (also
1441 known as "chunk") is subject to whatever notion of "line" happens to
1442 be currently in effect, and is also available as the special variable
1443 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1444
1445 Hint: sometimes appending C<", stopped"> to your message will cause it
1446 to make better sense when the string C<"at foo line 123"> is appended.
1447 Suppose you are running script "canasta".
1448
1449     die "/etc/games is no good";
1450     die "/etc/games is no good, stopped";
1451
1452 produce, respectively
1453
1454     /etc/games is no good at canasta line 123.
1455     /etc/games is no good, stopped at canasta line 123.
1456
1457 If the output is empty and C<$@> already contains a value (typically from a
1458 previous eval) that value is reused after appending C<"\t...propagated">.
1459 This is useful for propagating exceptions:
1460
1461     eval { ... };
1462     die unless $@ =~ /Expected exception/;
1463
1464 If the output is empty and C<$@> contains an object reference that has a
1465 C<PROPAGATE> method, that method will be called with additional file
1466 and line number parameters.  The return value replaces the value in
1467 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1468 were called.
1469
1470 If C<$@> is empty then the string C<"Died"> is used.
1471
1472 If an uncaught exception results in interpreter exit, the exit code is
1473 determined from the values of C<$!> and C<$?> with this pseudocode:
1474
1475     exit $! if $!;              # errno
1476     exit $? >> 8 if $? >> 8;    # child exit status
1477     exit 255;                   # last resort
1478
1479 The intent is to squeeze as much possible information about the likely cause
1480 into the limited space of the system exit
1481 code.  However, as C<$!> is the value
1482 of C's C<errno>, which can be set by any system call, this means that the value
1483 of the exit code used by C<die> can be non-predictable, so should not be relied
1484 upon, other than to be non-zero.
1485
1486 You can also call C<die> with a reference argument, and if this is trapped
1487 within an C<eval>, C<$@> contains that reference.  This permits more
1488 elaborate exception handling using objects that maintain arbitrary state
1489 about the exception.  Such a scheme is sometimes preferable to matching
1490 particular string values of C<$@> with regular expressions.  Because C<$@> 
1491 is a global variable and C<eval> may be used within object implementations,
1492 be careful that analyzing the error object doesn't replace the reference in
1493 the global variable.  It's easiest to make a local copy of the reference
1494 before any manipulations.  Here's an example:
1495
1496     use Scalar::Util "blessed";
1497
1498     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1499     if (my $ev_err = $@) {
1500         if (blessed($ev_err)
1501             && $ev_err->isa("Some::Module::Exception")) {
1502             # handle Some::Module::Exception
1503         }
1504         else {
1505             # handle all other possible exceptions
1506         }
1507     }
1508
1509 Because Perl stringifies uncaught exception messages before display,
1510 you'll probably want to overload stringification operations on
1511 exception objects.  See L<overload> for details about that.
1512
1513 You can arrange for a callback to be run just before the C<die>
1514 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1515 handler is called with the error text and can change the error
1516 message, if it sees fit, by calling C<die> again.  See
1517 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1518 L<"eval BLOCK"> for some examples.  Although this feature was 
1519 to be run only right before your program was to exit, this is not
1520 currently so: the C<$SIG{__DIE__}> hook is currently called
1521 even inside eval()ed blocks/strings!  If one wants the hook to do
1522 nothing in such situations, put
1523
1524     die @_ if $^S;
1525
1526 as the first line of the handler (see L<perlvar/$^S>).  Because
1527 this promotes strange action at a distance, this counterintuitive
1528 behavior may be fixed in a future release.
1529
1530 See also exit(), warn(), and the Carp module.
1531
1532 =item do BLOCK
1533 X<do> X<block>
1534
1535 =for Pod::Functions turn a BLOCK into a TERM
1536
1537 Not really a function.  Returns the value of the last command in the
1538 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1539 C<until> loop modifier, executes the BLOCK once before testing the loop
1540 condition.  (On other statements the loop modifiers test the conditional
1541 first.)
1542
1543 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1544 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1545 See L<perlsyn> for alternative strategies.
1546
1547 =item do SUBROUTINE(LIST)
1548 X<do>
1549
1550 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword
1551 or scalar variable.
1552
1553 =item do EXPR
1554 X<do>
1555
1556 Uses the value of EXPR as a filename and executes the contents of the
1557 file as a Perl script.
1558
1559     do 'stat.pl';
1560
1561 is just like
1562
1563     eval `cat stat.pl`;
1564
1565 except that it's more efficient and concise, keeps track of the current
1566 filename for error messages, searches the C<@INC> directories, and updates
1567 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1568 these variables.  It also differs in that code evaluated with C<do FILENAME>
1569 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1570 same, however, in that it does reparse the file every time you call it,
1571 so you probably don't want to do this inside a loop.
1572
1573 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1574 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1575 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1576 could fail in a way that also sets C<$!>.  If the file is successfully
1577 compiled, C<do> returns the value of the last expression evaluated.
1578
1579 Inclusion of library modules is better done with the
1580 C<use> and C<require> operators, which also do automatic error checking
1581 and raise an exception if there's a problem.
1582
1583 You might like to use C<do> to read in a program configuration
1584 file.  Manual error checking can be done this way:
1585
1586     # read in config files: system first, then user
1587     for $file ("/share/prog/defaults.rc",
1588                "$ENV{HOME}/.someprogrc")
1589     {
1590         unless ($return = do $file) {
1591             warn "couldn't parse $file: $@" if $@;
1592             warn "couldn't do $file: $!"    unless defined $return;
1593             warn "couldn't run $file"       unless $return;
1594         }
1595     }
1596
1597 =item dump LABEL
1598 X<dump> X<core> X<undump>
1599
1600 =item dump EXPR
1601
1602 =item dump
1603
1604 =for Pod::Functions create an immediate core dump
1605
1606 This function causes an immediate core dump.  See also the B<-u>
1607 command-line switch in L<perlrun>, which does the same thing.
1608 Primarily this is so that you can use the B<undump> program (not
1609 supplied) to turn your core dump into an executable binary after
1610 having initialized all your variables at the beginning of the
1611 program.  When the new binary is executed it will begin by executing
1612 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1613 Think of it as a goto with an intervening core dump and reincarnation.
1614 If C<LABEL> is omitted, restarts the program from the top.  The
1615 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1616 computed at run time, being otherwise identical to C<dump LABEL>.
1617
1618 B<WARNING>: Any files opened at the time of the dump will I<not>
1619 be open any more when the program is reincarnated, with possible
1620 resulting confusion by Perl.
1621
1622 This function is now largely obsolete, mostly because it's very hard to
1623 convert a core file into an executable.  That's why you should now invoke
1624 it as C<CORE::dump()>, if you don't want to be warned against a possible
1625 typo.
1626
1627 Unlike most named operators, this has the same precedence as assignment.
1628 It is also exempt from the looks-like-a-function rule, so
1629 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1630 C<dump>.
1631
1632 Portability issues: L<perlport/dump>.
1633
1634 =item each HASH
1635 X<each> X<hash, iterator>
1636
1637 =item each ARRAY
1638 X<array, iterator>
1639
1640 =item each EXPR
1641
1642 =for Pod::Functions retrieve the next key/value pair from a hash
1643
1644 When called on a hash in list context, returns a 2-element list
1645 consisting of the key and value for the next element of a hash.  In Perl
1646 5.12 and later only, it will also return the index and value for the next
1647 element of an array so that you can iterate over it; older Perls consider
1648 this a syntax error.  When called in scalar context, returns only the key
1649 (not the value) in a hash, or the index in an array.
1650
1651 Hash entries are returned in an apparently random order.  The actual random
1652 order is subject to change in future versions of Perl, but it is
1653 guaranteed to be in the same order as either the C<keys> or C<values>
1654 function would produce on the same (unmodified) hash.  Since Perl
1655 5.8.2 the ordering can be different even between different runs of Perl
1656 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1657
1658 After C<each> has returned all entries from the hash or array, the next
1659 call to C<each> returns the empty list in list context and C<undef> in
1660 scalar context; the next call following I<that> one restarts iteration.
1661 Each hash or array has its own internal iterator, accessed by C<each>,
1662 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1663 reached the end as just described; it can be explicitly reset by calling
1664 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1665 elements while iterating over it, entries may be skipped or duplicated--so
1666 don't do that.  Exception: In the current implementation, it is always safe
1667 to delete the item most recently returned by C<each()>, so the following
1668 code works properly:
1669
1670         while (($key, $value) = each %hash) {
1671           print $key, "\n";
1672           delete $hash{$key};   # This is safe
1673         }
1674
1675 This prints out your environment like the printenv(1) program,
1676 but in a different order:
1677
1678     while (($key,$value) = each %ENV) {
1679         print "$key=$value\n";
1680     }
1681
1682 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1683 reference to an unblessed hash or array.  The argument will be dereferenced
1684 automatically.  This aspect of C<each> is considered highly experimental.
1685 The exact behaviour may change in a future version of Perl.
1686
1687     while (($key,$value) = each $hashref) { ... }
1688
1689 To avoid confusing would-be users of your code who are running earlier
1690 versions of Perl with mysterious syntax errors, put this sort of thing at
1691 the top of your file to signal that your code will work I<only> on Perls of
1692 a recent vintage:
1693
1694     use 5.012;  # so keys/values/each work on arrays
1695     use 5.014;  # so keys/values/each work on scalars (experimental)
1696
1697 See also C<keys>, C<values>, and C<sort>.
1698
1699 =item eof FILEHANDLE
1700 X<eof>
1701 X<end of file>
1702 X<end-of-file>
1703
1704 =item eof ()
1705
1706 =item eof
1707
1708 =for Pod::Functions test a filehandle for its end
1709
1710 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1711 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1712 gives the real filehandle.  (Note that this function actually
1713 reads a character and then C<ungetc>s it, so isn't useful in an
1714 interactive context.)  Do not read from a terminal file (or call
1715 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1716 as terminals may lose the end-of-file condition if you do.
1717
1718 An C<eof> without an argument uses the last file read.  Using C<eof()>
1719 with empty parentheses is different.  It refers to the pseudo file
1720 formed from the files listed on the command line and accessed via the
1721 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1722 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1723 used will cause C<@ARGV> to be examined to determine if input is
1724 available.   Similarly, an C<eof()> after C<< <> >> has returned
1725 end-of-file will assume you are processing another C<@ARGV> list,
1726 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1727 see L<perlop/"I/O Operators">.
1728
1729 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1730 detect the end of each file, whereas C<eof()> will detect the end 
1731 of the very last file only.  Examples:
1732
1733     # reset line numbering on each input file
1734     while (<>) {
1735         next if /^\s*#/;  # skip comments
1736         print "$.\t$_";
1737     } continue {
1738         close ARGV if eof;  # Not eof()!
1739     }
1740
1741     # insert dashes just before last line of last file
1742     while (<>) {
1743         if (eof()) {  # check for end of last file
1744             print "--------------\n";
1745         }
1746         print;
1747         last if eof();     # needed if we're reading from a terminal
1748     }
1749
1750 Practical hint: you almost never need to use C<eof> in Perl, because the
1751 input operators typically return C<undef> when they run out of data or 
1752 encounter an error.
1753
1754 =item eval EXPR
1755 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1756 X<error, handling> X<exception, handling>
1757
1758 =item eval BLOCK
1759
1760 =item eval
1761
1762 =for Pod::Functions catch exceptions or compile and run code
1763
1764 In the first form, the return value of EXPR is parsed and executed as if it
1765 were a little Perl program.  The value of the expression (which is itself
1766 determined within scalar context) is first parsed, and if there were no
1767 errors, executed as a block within the lexical context of the current Perl
1768 program.  This means, that in particular, any outer lexical variables are
1769 visible to it, and any package variable settings or subroutine and format
1770 definitions remain afterwards.
1771
1772 Note that the value is parsed every time the C<eval> executes.
1773 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1774 delay parsing and subsequent execution of the text of EXPR until run time.
1775
1776 If the C<unicode_eval> feature is enabled (which is the default under a
1777 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1778 characters, so C<use utf8> declarations have no effect, and source filters
1779 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1780 will sometimes be treated as characters and sometimes as bytes, depending
1781 on the internal encoding, and source filters activated within the C<eval>
1782 exhibit the erratic, but historical, behaviour of affecting some outer file
1783 scope that is still compiling.  See also the L</evalbytes> keyword, which
1784 always treats its input as a byte stream and works properly with source
1785 filters, and the L<feature> pragma.
1786
1787 In the second form, the code within the BLOCK is parsed only once--at the
1788 same time the code surrounding the C<eval> itself was parsed--and executed
1789 within the context of the current Perl program.  This form is typically
1790 used to trap exceptions more efficiently than the first (see below), while
1791 also providing the benefit of checking the code within BLOCK at compile
1792 time.
1793
1794 The final semicolon, if any, may be omitted from the value of EXPR or within
1795 the BLOCK.
1796
1797 In both forms, the value returned is the value of the last expression
1798 evaluated inside the mini-program; a return statement may be also used, just
1799 as with subroutines.  The expression providing the return value is evaluated
1800 in void, scalar, or list context, depending on the context of the C<eval> 
1801 itself.  See L</wantarray> for more on how the evaluation context can be 
1802 determined.
1803
1804 If there is a syntax error or runtime error, or a C<die> statement is
1805 executed, C<eval> returns C<undef> in scalar context
1806 or an empty list in list context, and C<$@> is set to the error
1807 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1808 in list context for syntax errors, but not for runtime errors.)
1809 If there was no error, C<$@> is set to the empty string.  A
1810 control flow operator like C<last> or C<goto> can bypass the setting of
1811 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1812 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1813 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1814 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1815 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1816
1817 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1818 determining whether a particular feature (such as C<socket> or C<symlink>)
1819 is implemented.  It is also Perl's exception-trapping mechanism, where
1820 the die operator is used to raise exceptions.
1821
1822 If you want to trap errors when loading an XS module, some problems with
1823 the binary interface (such as Perl version skew) may be fatal even with
1824 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1825
1826 If the code to be executed doesn't vary, you may use the eval-BLOCK
1827 form to trap run-time errors without incurring the penalty of
1828 recompiling each time.  The error, if any, is still returned in C<$@>.
1829 Examples:
1830
1831     # make divide-by-zero nonfatal
1832     eval { $answer = $a / $b; }; warn $@ if $@;
1833
1834     # same thing, but less efficient
1835     eval '$answer = $a / $b'; warn $@ if $@;
1836
1837     # a compile-time error
1838     eval { $answer = }; # WRONG
1839
1840     # a run-time error
1841     eval '$answer =';   # sets $@
1842
1843 Using the C<eval{}> form as an exception trap in libraries does have some
1844 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1845 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1846 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1847 as this example shows:
1848
1849     # a private exception trap for divide-by-zero
1850     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1851     warn $@ if $@;
1852
1853 This is especially significant, given that C<__DIE__> hooks can call
1854 C<die> again, which has the effect of changing their error messages:
1855
1856     # __DIE__ hooks may modify error messages
1857     {
1858        local $SIG{'__DIE__'} =
1859               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1860        eval { die "foo lives here" };
1861        print $@ if $@;                # prints "bar lives here"
1862     }
1863
1864 Because this promotes action at a distance, this counterintuitive behavior
1865 may be fixed in a future release.
1866
1867 With an C<eval>, you should be especially careful to remember what's
1868 being looked at when:
1869
1870     eval $x;        # CASE 1
1871     eval "$x";      # CASE 2
1872
1873     eval '$x';      # CASE 3
1874     eval { $x };    # CASE 4
1875
1876     eval "\$$x++";  # CASE 5
1877     $$x++;          # CASE 6
1878
1879 Cases 1 and 2 above behave identically: they run the code contained in
1880 the variable $x.  (Although case 2 has misleading double quotes making
1881 the reader wonder what else might be happening (nothing is).)  Cases 3
1882 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1883 does nothing but return the value of $x.  (Case 4 is preferred for
1884 purely visual reasons, but it also has the advantage of compiling at
1885 compile-time instead of at run-time.)  Case 5 is a place where
1886 normally you I<would> like to use double quotes, except that in this
1887 particular situation, you can just use symbolic references instead, as
1888 in case 6.
1889
1890 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1891 of localized variables, which means that for your code to run on older
1892 versions, a temporary is required if you want to mask some but not all
1893 errors:
1894
1895     # alter $@ on nefarious repugnancy only
1896     {
1897        my $e;
1898        {
1899          local $@; # protect existing $@
1900          eval { test_repugnancy() };
1901          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1902          $@ =~ /nefarious/ and $e = $@;
1903        }
1904        die $e if defined $e
1905     }
1906
1907 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1908 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1909
1910 An C<eval ''> executed within the C<DB> package doesn't see the usual
1911 surrounding lexical scope, but rather the scope of the first non-DB piece
1912 of code that called it.  You don't normally need to worry about this unless
1913 you are writing a Perl debugger.
1914
1915 =item evalbytes EXPR
1916 X<evalbytes>
1917
1918 =item evalbytes
1919
1920 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1921
1922 This function is like L</eval> with a string argument, except it always
1923 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1924 string containing characters whose ordinal value exceeds 255 results in an
1925 error.  Source filters activated within the evaluated code apply to the
1926 code itself.
1927
1928 This function is only available under the C<evalbytes> feature, a
1929 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1930 L<feature> for more information.
1931
1932 =item exec LIST
1933 X<exec> X<execute>
1934
1935 =item exec PROGRAM LIST
1936
1937 =for Pod::Functions abandon this program to run another
1938
1939 The C<exec> function executes a system command I<and never returns>;
1940 use C<system> instead of C<exec> if you want it to return.  It fails and
1941 returns false only if the command does not exist I<and> it is executed
1942 directly instead of via your system's command shell (see below).
1943
1944 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1945 warns you if C<exec> is called in void context and if there is a following
1946 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1947 you always do that, right?).  If you I<really> want to follow an C<exec>
1948 with some other statement, you can use one of these styles to avoid the warning:
1949
1950     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1951     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1952
1953 If there is more than one argument in LIST, or if LIST is an array
1954 with more than one value, calls execvp(3) with the arguments in LIST.
1955 If there is only one scalar argument or an array with one element in it,
1956 the argument is checked for shell metacharacters, and if there are any,
1957 the entire argument is passed to the system's command shell for parsing
1958 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1959 If there are no shell metacharacters in the argument, it is split into
1960 words and passed directly to C<execvp>, which is more efficient.
1961 Examples:
1962
1963     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1964     exec "sort $outfile | uniq";
1965
1966 If you don't really want to execute the first argument, but want to lie
1967 to the program you are executing about its own name, you can specify
1968 the program you actually want to run as an "indirect object" (without a
1969 comma) in front of the LIST.  (This always forces interpretation of the
1970 LIST as a multivalued list, even if there is only a single scalar in
1971 the list.)  Example:
1972
1973     $shell = '/bin/csh';
1974     exec $shell '-sh';    # pretend it's a login shell
1975
1976 or, more directly,
1977
1978     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1979
1980 When the arguments get executed via the system shell, results are
1981 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1982 for details.
1983
1984 Using an indirect object with C<exec> or C<system> is also more
1985 secure.  This usage (which also works fine with system()) forces
1986 interpretation of the arguments as a multivalued list, even if the
1987 list had just one argument.  That way you're safe from the shell
1988 expanding wildcards or splitting up words with whitespace in them.
1989
1990     @args = ( "echo surprise" );
1991
1992     exec @args;               # subject to shell escapes
1993                                 # if @args == 1
1994     exec { $args[0] } @args;  # safe even with one-arg list
1995
1996 The first version, the one without the indirect object, ran the I<echo>
1997 program, passing it C<"surprise"> an argument.  The second version didn't;
1998 it tried to run a program named I<"echo surprise">, didn't find it, and set
1999 C<$?> to a non-zero value indicating failure.
2000
2001 Perl attempts to flush all files opened for output before the exec,
2002 but this may not be supported on some platforms (see L<perlport>).
2003 To be safe, you may need to set C<$|> ($AUTOFLUSH in English) or
2004 call the C<autoflush()> method of C<IO::Handle> on any open handles
2005 to avoid lost output.
2006
2007 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2008 C<DESTROY> methods on your objects.
2009
2010 Portability issues: L<perlport/exec>.
2011
2012 =item exists EXPR
2013 X<exists> X<autovivification>
2014
2015 =for Pod::Functions test whether a hash key is present
2016
2017 Given an expression that specifies an element of a hash, returns true if the
2018 specified element in the hash has ever been initialized, even if the
2019 corresponding value is undefined.
2020
2021     print "Exists\n"    if exists $hash{$key};
2022     print "Defined\n"   if defined $hash{$key};
2023     print "True\n"      if $hash{$key};
2024
2025 exists may also be called on array elements, but its behavior is much less
2026 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2027 that calling exists on array values is deprecated and likely to be removed in
2028 a future version of Perl.
2029
2030     print "Exists\n"    if exists $array[$index];
2031     print "Defined\n"   if defined $array[$index];
2032     print "True\n"      if $array[$index];
2033
2034 A hash or array element can be true only if it's defined and defined only if
2035 it exists, but the reverse doesn't necessarily hold true.
2036
2037 Given an expression that specifies the name of a subroutine,
2038 returns true if the specified subroutine has ever been declared, even
2039 if it is undefined.  Mentioning a subroutine name for exists or defined
2040 does not count as declaring it.  Note that a subroutine that does not
2041 exist may still be callable: its package may have an C<AUTOLOAD>
2042 method that makes it spring into existence the first time that it is
2043 called; see L<perlsub>.
2044
2045     print "Exists\n"  if exists &subroutine;
2046     print "Defined\n" if defined &subroutine;
2047
2048 Note that the EXPR can be arbitrarily complicated as long as the final
2049 operation is a hash or array key lookup or subroutine name:
2050
2051     if (exists $ref->{A}->{B}->{$key})  { }
2052     if (exists $hash{A}{B}{$key})       { }
2053
2054     if (exists $ref->{A}->{B}->[$ix])   { }
2055     if (exists $hash{A}{B}[$ix])        { }
2056
2057     if (exists &{$ref->{A}{B}{$key}})   { }
2058
2059 Although the most deeply nested array or hash element will not spring into
2060 existence just because its existence was tested, any intervening ones will.
2061 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2062 into existence due to the existence test for the $key element above.
2063 This happens anywhere the arrow operator is used, including even here:
2064
2065     undef $ref;
2066     if (exists $ref->{"Some key"})    { }
2067     print $ref;  # prints HASH(0x80d3d5c)
2068
2069 This surprising autovivification in what does not at first--or even
2070 second--glance appear to be an lvalue context may be fixed in a future
2071 release.
2072
2073 Use of a subroutine call, rather than a subroutine name, as an argument
2074 to exists() is an error.
2075
2076     exists &sub;    # OK
2077     exists &sub();  # Error
2078
2079 =item exit EXPR
2080 X<exit> X<terminate> X<abort>
2081
2082 =item exit
2083
2084 =for Pod::Functions terminate this program
2085
2086 Evaluates EXPR and exits immediately with that value.    Example:
2087
2088     $ans = <STDIN>;
2089     exit 0 if $ans =~ /^[Xx]/;
2090
2091 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2092 universally recognized values for EXPR are C<0> for success and C<1>
2093 for error; other values are subject to interpretation depending on the
2094 environment in which the Perl program is running.  For example, exiting
2095 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2096 the mailer to return the item undelivered, but that's not true everywhere.
2097
2098 Don't use C<exit> to abort a subroutine if there's any chance that
2099 someone might want to trap whatever error happened.  Use C<die> instead,
2100 which can be trapped by an C<eval>.
2101
2102 The exit() function does not always exit immediately.  It calls any
2103 defined C<END> routines first, but these C<END> routines may not
2104 themselves abort the exit.  Likewise any object destructors that need to
2105 be called are called before the real exit.  C<END> routines and destructors
2106 can change the exit status by modifying C<$?>.  If this is a problem, you
2107 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2108 See L<perlmod> for details.
2109
2110 Portability issues: L<perlport/exit>.
2111
2112 =item exp EXPR
2113 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2114
2115 =item exp
2116
2117 =for Pod::Functions raise I<e> to a power
2118
2119 Returns I<e> (the natural logarithm base) to the power of EXPR.
2120 If EXPR is omitted, gives C<exp($_)>.
2121
2122 =item fc EXPR
2123 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2124
2125 =item fc
2126
2127 =for Pod::Functions +fc return casefolded version of a string
2128
2129 Returns the casefolded version of EXPR.  This is the internal function
2130 implementing the C<\F> escape in double-quoted strings.
2131
2132 Casefolding is the process of mapping strings to a form where case
2133 differences are erased; comparing two strings in their casefolded
2134 form is effectively a way of asking if two strings are equal,
2135 regardless of case.
2136
2137 Roughly, if you ever found yourself writing this
2138
2139     lc($this) eq lc($that)    # Wrong!
2140         # or
2141     uc($this) eq uc($that)    # Also wrong!
2142         # or
2143     $this =~ /^\Q$that\E\z/i  # Right!
2144
2145 Now you can write
2146
2147     fc($this) eq fc($that)
2148
2149 And get the correct results.
2150
2151 Perl only implements the full form of casefolding,
2152 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2153 L<Unicode::UCD/prop_invmap()>.
2154 For further information on casefolding, refer to
2155 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2156 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2157 available at L<http://www.unicode.org/versions/latest/>, as well as the
2158 Case Charts available at L<http://www.unicode.org/charts/case/>.
2159
2160 If EXPR is omitted, uses C<$_>.
2161
2162 This function behaves the same way under various pragma, such as in a locale,
2163 as L</lc> does.
2164
2165 While the Unicode Standard defines two additional forms of casefolding,
2166 one for Turkic languages and one that never maps one character into multiple
2167 characters, these are not provided by the Perl core; However, the CPAN module
2168 C<Unicode::Casing> may be used to provide an implementation.
2169
2170 This keyword is available only when the C<"fc"> feature is enabled,
2171 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2172 include a C<use v5.16> or later to the current scope.
2173
2174 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2175 X<fcntl>
2176
2177 =for Pod::Functions file control system call
2178
2179 Implements the fcntl(2) function.  You'll probably have to say
2180
2181     use Fcntl;
2182
2183 first to get the correct constant definitions.  Argument processing and
2184 value returned work just like C<ioctl> below.
2185 For example:
2186
2187     use Fcntl;
2188     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2189         or die "can't fcntl F_GETFL: $!";
2190
2191 You don't have to check for C<defined> on the return from C<fcntl>.
2192 Like C<ioctl>, it maps a C<0> return from the system call into
2193 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2194 in numeric context.  It is also exempt from the normal B<-w> warnings
2195 on improper numeric conversions.
2196
2197 Note that C<fcntl> raises an exception if used on a machine that
2198 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2199 manpage to learn what functions are available on your system.
2200
2201 Here's an example of setting a filehandle named C<REMOTE> to be
2202 non-blocking at the system level.  You'll have to negotiate C<$|>
2203 on your own, though.
2204
2205     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2206
2207     $flags = fcntl(REMOTE, F_GETFL, 0)
2208                 or die "Can't get flags for the socket: $!\n";
2209
2210     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2211                 or die "Can't set flags for the socket: $!\n";
2212
2213 Portability issues: L<perlport/fcntl>.
2214
2215 =item __FILE__
2216 X<__FILE__>
2217
2218 =for Pod::Functions the name of the current source file
2219
2220 A special token that returns the name of the file in which it occurs.
2221
2222 =item fileno FILEHANDLE
2223 X<fileno>
2224
2225 =for Pod::Functions return file descriptor from filehandle
2226
2227 Returns the file descriptor for a filehandle, or undefined if the
2228 filehandle is not open.  If there is no real file descriptor at the OS
2229 level, as can happen with filehandles connected to memory objects via
2230 C<open> with a reference for the third argument, -1 is returned.
2231
2232 This is mainly useful for constructing
2233 bitmaps for C<select> and low-level POSIX tty-handling operations.
2234 If FILEHANDLE is an expression, the value is taken as an indirect
2235 filehandle, generally its name.
2236
2237 You can use this to find out whether two handles refer to the
2238 same underlying descriptor:
2239
2240     if (fileno(THIS) == fileno(THAT)) {
2241         print "THIS and THAT are dups\n";
2242     }
2243
2244 =item flock FILEHANDLE,OPERATION
2245 X<flock> X<lock> X<locking>
2246
2247 =for Pod::Functions lock an entire file with an advisory lock
2248
2249 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2250 for success, false on failure.  Produces a fatal error if used on a
2251 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2252 C<flock> is Perl's portable file-locking interface, although it locks
2253 entire files only, not records.
2254
2255 Two potentially non-obvious but traditional C<flock> semantics are
2256 that it waits indefinitely until the lock is granted, and that its locks
2257 are B<merely advisory>.  Such discretionary locks are more flexible, but
2258 offer fewer guarantees.  This means that programs that do not also use
2259 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2260 your port's specific documentation, and your system-specific local manpages
2261 for details.  It's best to assume traditional behavior if you're writing
2262 portable programs.  (But if you're not, you should as always feel perfectly
2263 free to write for your own system's idiosyncrasies (sometimes called
2264 "features").  Slavish adherence to portability concerns shouldn't get
2265 in the way of your getting your job done.)
2266
2267 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2268 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2269 you can use the symbolic names if you import them from the L<Fcntl> module,
2270 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2271 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2272 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2273 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2274 waiting for the lock; check the return status to see if you got it.
2275
2276 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2277 before locking or unlocking it.
2278
2279 Note that the emulation built with lockf(3) doesn't provide shared
2280 locks, and it requires that FILEHANDLE be open with write intent.  These
2281 are the semantics that lockf(3) implements.  Most if not all systems
2282 implement lockf(3) in terms of fcntl(2) locking, though, so the
2283 differing semantics shouldn't bite too many people.
2284
2285 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2286 be open with read intent to use LOCK_SH and requires that it be open
2287 with write intent to use LOCK_EX.
2288
2289 Note also that some versions of C<flock> cannot lock things over the
2290 network; you would need to use the more system-specific C<fcntl> for
2291 that.  If you like you can force Perl to ignore your system's flock(2)
2292 function, and so provide its own fcntl(2)-based emulation, by passing
2293 the switch C<-Ud_flock> to the F<Configure> program when you configure
2294 and build a new Perl.
2295
2296 Here's a mailbox appender for BSD systems.
2297
2298     # import LOCK_* and SEEK_END constants
2299     use Fcntl qw(:flock SEEK_END);
2300
2301     sub lock {
2302         my ($fh) = @_;
2303         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2304
2305         # and, in case someone appended while we were waiting...
2306         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2307     }
2308
2309     sub unlock {
2310         my ($fh) = @_;
2311         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2312     }
2313
2314     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2315         or die "Can't open mailbox: $!";
2316
2317     lock($mbox);
2318     print $mbox $msg,"\n\n";
2319     unlock($mbox);
2320
2321 On systems that support a real flock(2), locks are inherited across fork()
2322 calls, whereas those that must resort to the more capricious fcntl(2)
2323 function lose their locks, making it seriously harder to write servers.
2324
2325 See also L<DB_File> for other flock() examples.
2326
2327 Portability issues: L<perlport/flock>.
2328
2329 =item fork
2330 X<fork> X<child> X<parent>
2331
2332 =for Pod::Functions create a new process just like this one
2333
2334 Does a fork(2) system call to create a new process running the
2335 same program at the same point.  It returns the child pid to the
2336 parent process, C<0> to the child process, or C<undef> if the fork is
2337 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2338 are shared, while everything else is copied.  On most systems supporting
2339 fork(), great care has gone into making it extremely efficient (for
2340 example, using copy-on-write technology on data pages), making it the
2341 dominant paradigm for multitasking over the last few decades.
2342
2343 Perl attempts to flush all files opened for
2344 output before forking the child process, but this may not be supported
2345 on some platforms (see L<perlport>).  To be safe, you may need to set
2346 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2347 C<IO::Handle> on any open handles to avoid duplicate output.
2348
2349 If you C<fork> without ever waiting on your children, you will
2350 accumulate zombies.  On some systems, you can avoid this by setting
2351 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2352 forking and reaping moribund children.
2353
2354 Note that if your forked child inherits system file descriptors like
2355 STDIN and STDOUT that are actually connected by a pipe or socket, even
2356 if you exit, then the remote server (such as, say, a CGI script or a
2357 backgrounded job launched from a remote shell) won't think you're done.
2358 You should reopen those to F</dev/null> if it's any issue.
2359
2360 On some platforms such as Windows, where the fork() system call is not available,
2361 Perl can be built to emulate fork() in the Perl interpreter.
2362 The emulation is designed, at the level of the Perl program,
2363 to be as compatible as possible with the "Unix" fork().
2364 However it has limitations that have to be considered in code intended to be portable.
2365 See L<perlfork> for more details.
2366
2367 Portability issues: L<perlport/fork>.
2368
2369 =item format
2370 X<format>
2371
2372 =for Pod::Functions declare a picture format with use by the write() function
2373
2374 Declare a picture format for use by the C<write> function.  For
2375 example:
2376
2377     format Something =
2378         Test: @<<<<<<<< @||||| @>>>>>
2379               $str,     $%,    '$' . int($num)
2380     .
2381
2382     $str = "widget";
2383     $num = $cost/$quantity;
2384     $~ = 'Something';
2385     write;
2386
2387 See L<perlform> for many details and examples.
2388
2389 =item formline PICTURE,LIST
2390 X<formline>
2391
2392 =for Pod::Functions internal function used for formats
2393
2394 This is an internal function used by C<format>s, though you may call it,
2395 too.  It formats (see L<perlform>) a list of values according to the
2396 contents of PICTURE, placing the output into the format output
2397 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2398 Eventually, when a C<write> is done, the contents of
2399 C<$^A> are written to some filehandle.  You could also read C<$^A>
2400 and then set C<$^A> back to C<"">.  Note that a format typically
2401 does one C<formline> per line of form, but the C<formline> function itself
2402 doesn't care how many newlines are embedded in the PICTURE.  This means
2403 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2404 You may therefore need to use multiple formlines to implement a single
2405 record format, just like the C<format> compiler.
2406
2407 Be careful if you put double quotes around the picture, because an C<@>
2408 character may be taken to mean the beginning of an array name.
2409 C<formline> always returns true.  See L<perlform> for other examples.
2410
2411 If you are trying to use this instead of C<write> to capture the output,
2412 you may find it easier to open a filehandle to a scalar
2413 (C<< open $fh, ">", \$output >>) and write to that instead.
2414
2415 =item getc FILEHANDLE
2416 X<getc> X<getchar> X<character> X<file, read>
2417
2418 =item getc
2419
2420 =for Pod::Functions get the next character from the filehandle
2421
2422 Returns the next character from the input file attached to FILEHANDLE,
2423 or the undefined value at end of file or if there was an error (in
2424 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2425 STDIN.  This is not particularly efficient.  However, it cannot be
2426 used by itself to fetch single characters without waiting for the user
2427 to hit enter.  For that, try something more like:
2428
2429     if ($BSD_STYLE) {
2430         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2431     }
2432     else {
2433         system "stty", '-icanon', 'eol', "\001";
2434     }
2435
2436     $key = getc(STDIN);
2437
2438     if ($BSD_STYLE) {
2439         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2440     }
2441     else {
2442         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2443     }
2444     print "\n";
2445
2446 Determination of whether $BSD_STYLE should be set
2447 is left as an exercise to the reader.
2448
2449 The C<POSIX::getattr> function can do this more portably on
2450 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2451 module from your nearest CPAN site; details on CPAN can be found under
2452 L<perlmodlib/CPAN>.
2453
2454 =item getlogin
2455 X<getlogin> X<login>
2456
2457 =for Pod::Functions return who logged in at this tty
2458
2459 This implements the C library function of the same name, which on most
2460 systems returns the current login from F</etc/utmp>, if any.  If it
2461 returns the empty string, use C<getpwuid>.
2462
2463     $login = getlogin || getpwuid($<) || "Kilroy";
2464
2465 Do not consider C<getlogin> for authentication: it is not as
2466 secure as C<getpwuid>.
2467
2468 Portability issues: L<perlport/getlogin>.
2469
2470 =item getpeername SOCKET
2471 X<getpeername> X<peer>
2472
2473 =for Pod::Functions find the other end of a socket connection
2474
2475 Returns the packed sockaddr address of the other end of the SOCKET
2476 connection.
2477
2478     use Socket;
2479     $hersockaddr    = getpeername(SOCK);
2480     ($port, $iaddr) = sockaddr_in($hersockaddr);
2481     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2482     $herstraddr     = inet_ntoa($iaddr);
2483
2484 =item getpgrp PID
2485 X<getpgrp> X<group>
2486
2487 =for Pod::Functions get process group
2488
2489 Returns the current process group for the specified PID.  Use
2490 a PID of C<0> to get the current process group for the
2491 current process.  Will raise an exception if used on a machine that
2492 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2493 group of the current process.  Note that the POSIX version of C<getpgrp>
2494 does not accept a PID argument, so only C<PID==0> is truly portable.
2495
2496 Portability issues: L<perlport/getpgrp>.
2497
2498 =item getppid
2499 X<getppid> X<parent> X<pid>
2500
2501 =for Pod::Functions get parent process ID
2502
2503 Returns the process id of the parent process.
2504
2505 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2506 around non-POSIX thread semantics the minority of Linux systems (and
2507 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2508 has since been removed. See the documentation for L<$$|perlvar/$$> for
2509 details.
2510
2511 Portability issues: L<perlport/getppid>.
2512
2513 =item getpriority WHICH,WHO
2514 X<getpriority> X<priority> X<nice>
2515
2516 =for Pod::Functions get current nice value
2517
2518 Returns the current priority for a process, a process group, or a user.
2519 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2520 machine that doesn't implement getpriority(2).
2521
2522 Portability issues: L<perlport/getpriority>.
2523
2524 =item getpwnam NAME
2525 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2526 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2527 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2528 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2529 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2530 X<endnetent> X<endprotoent> X<endservent> 
2531
2532 =for Pod::Functions get passwd record given user login name
2533
2534 =item getgrnam NAME
2535
2536 =for Pod::Functions get group record given group name
2537
2538 =item gethostbyname NAME
2539
2540 =for Pod::Functions get host record given name
2541
2542 =item getnetbyname NAME
2543
2544 =for Pod::Functions get networks record given name
2545
2546 =item getprotobyname NAME
2547
2548 =for Pod::Functions get protocol record given name
2549
2550 =item getpwuid UID
2551
2552 =for Pod::Functions get passwd record given user ID
2553
2554 =item getgrgid GID
2555
2556 =for Pod::Functions get group record given group user ID
2557
2558 =item getservbyname NAME,PROTO
2559
2560 =for Pod::Functions get services record given its name
2561
2562 =item gethostbyaddr ADDR,ADDRTYPE
2563
2564 =for Pod::Functions get host record given its address
2565
2566 =item getnetbyaddr ADDR,ADDRTYPE
2567
2568 =for Pod::Functions get network record given its address
2569
2570 =item getprotobynumber NUMBER
2571
2572 =for Pod::Functions get protocol record numeric protocol
2573
2574 =item getservbyport PORT,PROTO
2575
2576 =for Pod::Functions get services record given numeric port
2577
2578 =item getpwent
2579
2580 =for Pod::Functions get next passwd record
2581
2582 =item getgrent
2583
2584 =for Pod::Functions get next group record
2585
2586 =item gethostent
2587
2588 =for Pod::Functions get next hosts record
2589
2590 =item getnetent
2591
2592 =for Pod::Functions get next networks record
2593
2594 =item getprotoent
2595
2596 =for Pod::Functions get next protocols record
2597
2598 =item getservent
2599
2600 =for Pod::Functions get next services record
2601
2602 =item setpwent
2603
2604 =for Pod::Functions prepare passwd file for use
2605
2606 =item setgrent
2607
2608 =for Pod::Functions prepare group file for use
2609
2610 =item sethostent STAYOPEN
2611
2612 =for Pod::Functions prepare hosts file for use
2613
2614 =item setnetent STAYOPEN
2615
2616 =for Pod::Functions prepare networks file for use
2617
2618 =item setprotoent STAYOPEN
2619
2620 =for Pod::Functions prepare protocols file for use
2621
2622 =item setservent STAYOPEN
2623
2624 =for Pod::Functions prepare services file for use
2625
2626 =item endpwent
2627
2628 =for Pod::Functions be done using passwd file
2629
2630 =item endgrent
2631
2632 =for Pod::Functions be done using group file
2633
2634 =item endhostent
2635
2636 =for Pod::Functions be done using hosts file
2637
2638 =item endnetent
2639
2640 =for Pod::Functions be done using networks file
2641
2642 =item endprotoent
2643
2644 =for Pod::Functions be done using protocols file
2645
2646 =item endservent
2647
2648 =for Pod::Functions be done using services file
2649
2650 These routines are the same as their counterparts in the
2651 system C library.  In list context, the return values from the
2652 various get routines are as follows:
2653
2654     ($name,$passwd,$uid,$gid,
2655        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2656     ($name,$passwd,$gid,$members) = getgr*
2657     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2658     ($name,$aliases,$addrtype,$net) = getnet*
2659     ($name,$aliases,$proto) = getproto*
2660     ($name,$aliases,$port,$proto) = getserv*
2661
2662 (If the entry doesn't exist you get an empty list.)
2663
2664 The exact meaning of the $gcos field varies but it usually contains
2665 the real name of the user (as opposed to the login name) and other
2666 information pertaining to the user.  Beware, however, that in many
2667 system users are able to change this information and therefore it
2668 cannot be trusted and therefore the $gcos is tainted (see
2669 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2670 login shell, are also tainted, for the same reason.
2671
2672 In scalar context, you get the name, unless the function was a
2673 lookup by name, in which case you get the other thing, whatever it is.
2674 (If the entry doesn't exist you get the undefined value.)  For example:
2675
2676     $uid   = getpwnam($name);
2677     $name  = getpwuid($num);
2678     $name  = getpwent();
2679     $gid   = getgrnam($name);
2680     $name  = getgrgid($num);
2681     $name  = getgrent();
2682     #etc.
2683
2684 In I<getpw*()> the fields $quota, $comment, and $expire are special
2685 in that they are unsupported on many systems.  If the
2686 $quota is unsupported, it is an empty scalar.  If it is supported, it
2687 usually encodes the disk quota.  If the $comment field is unsupported,
2688 it is an empty scalar.  If it is supported it usually encodes some
2689 administrative comment about the user.  In some systems the $quota
2690 field may be $change or $age, fields that have to do with password
2691 aging.  In some systems the $comment field may be $class.  The $expire
2692 field, if present, encodes the expiration period of the account or the
2693 password.  For the availability and the exact meaning of these fields
2694 in your system, please consult getpwnam(3) and your system's 
2695 F<pwd.h> file.  You can also find out from within Perl what your
2696 $quota and $comment fields mean and whether you have the $expire field
2697 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2698 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2699 files are supported only if your vendor has implemented them in the
2700 intuitive fashion that calling the regular C library routines gets the
2701 shadow versions if you're running under privilege or if there exists
2702 the shadow(3) functions as found in System V (this includes Solaris
2703 and Linux).  Those systems that implement a proprietary shadow password
2704 facility are unlikely to be supported.
2705
2706 The $members value returned by I<getgr*()> is a space-separated list of
2707 the login names of the members of the group.
2708
2709 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2710 C, it will be returned to you via C<$?> if the function call fails.  The
2711 C<@addrs> value returned by a successful call is a list of raw
2712 addresses returned by the corresponding library call.  In the
2713 Internet domain, each address is four bytes long; you can unpack it
2714 by saying something like:
2715
2716     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2717
2718 The Socket library makes this slightly easier:
2719
2720     use Socket;
2721     $iaddr = inet_aton("127.1"); # or whatever address
2722     $name  = gethostbyaddr($iaddr, AF_INET);
2723
2724     # or going the other way
2725     $straddr = inet_ntoa($iaddr);
2726
2727 In the opposite way, to resolve a hostname to the IP address
2728 you can write this:
2729
2730     use Socket;
2731     $packed_ip = gethostbyname("www.perl.org");
2732     if (defined $packed_ip) {
2733         $ip_address = inet_ntoa($packed_ip);
2734     }
2735
2736 Make sure C<gethostbyname()> is called in SCALAR context and that
2737 its return value is checked for definedness.
2738
2739 The C<getprotobynumber> function, even though it only takes one argument,
2740 has the precedence of a list operator, so beware:
2741
2742     getprotobynumber $number eq 'icmp'   # WRONG
2743     getprotobynumber($number eq 'icmp')  # actually means this
2744     getprotobynumber($number) eq 'icmp'  # better this way
2745
2746 If you get tired of remembering which element of the return list
2747 contains which return value, by-name interfaces are provided
2748 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2749 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2750 and C<User::grent>.  These override the normal built-ins, supplying
2751 versions that return objects with the appropriate names
2752 for each field.  For example:
2753
2754    use File::stat;
2755    use User::pwent;
2756    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2757
2758 Even though it looks as though they're the same method calls (uid),
2759 they aren't, because a C<File::stat> object is different from
2760 a C<User::pwent> object.
2761
2762 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2763
2764 =item getsockname SOCKET
2765 X<getsockname>
2766
2767 =for Pod::Functions retrieve the sockaddr for a given socket
2768
2769 Returns the packed sockaddr address of this end of the SOCKET connection,
2770 in case you don't know the address because you have several different
2771 IPs that the connection might have come in on.
2772
2773     use Socket;
2774     $mysockaddr = getsockname(SOCK);
2775     ($port, $myaddr) = sockaddr_in($mysockaddr);
2776     printf "Connect to %s [%s]\n",
2777        scalar gethostbyaddr($myaddr, AF_INET),
2778        inet_ntoa($myaddr);
2779
2780 =item getsockopt SOCKET,LEVEL,OPTNAME
2781 X<getsockopt>
2782
2783 =for Pod::Functions get socket options on a given socket
2784
2785 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2786 Options may exist at multiple protocol levels depending on the socket
2787 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2788 C<Socket> module) will exist.  To query options at another level the
2789 protocol number of the appropriate protocol controlling the option
2790 should be supplied.  For example, to indicate that an option is to be
2791 interpreted by the TCP protocol, LEVEL should be set to the protocol
2792 number of TCP, which you can get using C<getprotobyname>.
2793
2794 The function returns a packed string representing the requested socket
2795 option, or C<undef> on error, with the reason for the error placed in
2796 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2797 consult getsockopt(2) for details.  A common case is that the option is an
2798 integer, in which case the result is a packed integer, which you can decode
2799 using C<unpack> with the C<i> (or C<I>) format.
2800
2801 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2802
2803     use Socket qw(:all);
2804
2805     defined(my $tcp = getprotobyname("tcp"))
2806         or die "Could not determine the protocol number for tcp";
2807     # my $tcp = IPPROTO_TCP; # Alternative
2808     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2809         or die "getsockopt TCP_NODELAY: $!";
2810     my $nodelay = unpack("I", $packed);
2811     print "Nagle's algorithm is turned ",
2812            $nodelay ? "off\n" : "on\n";
2813
2814 Portability issues: L<perlport/getsockopt>.
2815
2816 =item glob EXPR
2817 X<glob> X<wildcard> X<filename, expansion> X<expand>
2818
2819 =item glob
2820
2821 =for Pod::Functions expand filenames using wildcards
2822
2823 In list context, returns a (possibly empty) list of filename expansions on
2824 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2825 scalar context, glob iterates through such filename expansions, returning
2826 undef when the list is exhausted.  This is the internal function
2827 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2828 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2829 more detail in L<perlop/"I/O Operators">.
2830
2831 Note that C<glob> splits its arguments on whitespace and treats
2832 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2833 matches all files with a F<.c> or F<.h> extension.  The expression
2834 C<glob(".* *")> matches all files in the current working directory.
2835 If you want to glob filenames that might contain whitespace, you'll
2836 have to use extra quotes around the spacey filename to protect it.
2837 For example, to glob filenames that have an C<e> followed by a space
2838 followed by an C<f>, use either of:
2839
2840     @spacies = <"*e f*">;
2841     @spacies = glob '"*e f*"';
2842     @spacies = glob q("*e f*");
2843
2844 If you had to get a variable through, you could do this:
2845
2846     @spacies = glob "'*${var}e f*'";
2847     @spacies = glob qq("*${var}e f*");
2848
2849 If non-empty braces are the only wildcard characters used in the
2850 C<glob>, no filenames are matched, but potentially many strings
2851 are returned.  For example, this produces nine strings, one for
2852 each pairing of fruits and colors:
2853
2854     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2855
2856 This operator is implemented using the standard
2857 C<File::Glob> extension.  See L<File::Glob> for details, including
2858 C<bsd_glob> which does not treat whitespace as a pattern separator.
2859
2860 Portability issues: L<perlport/glob>.
2861
2862 =item gmtime EXPR
2863 X<gmtime> X<UTC> X<Greenwich>
2864
2865 =item gmtime
2866
2867 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2868
2869 Works just like L</localtime> but the returned values are
2870 localized for the standard Greenwich time zone.
2871
2872 Note: When called in list context, $isdst, the last value
2873 returned by gmtime, is always C<0>.  There is no
2874 Daylight Saving Time in GMT.
2875
2876 Portability issues: L<perlport/gmtime>.
2877
2878 =item goto LABEL
2879 X<goto> X<jump> X<jmp>
2880
2881 =item goto EXPR
2882
2883 =item goto &NAME
2884
2885 =for Pod::Functions create spaghetti code
2886
2887 The C<goto-LABEL> form finds the statement labeled with LABEL and
2888 resumes execution there.  It can't be used to get out of a block or
2889 subroutine given to C<sort>.  It can be used to go almost anywhere
2890 else within the dynamic scope, including out of subroutines, but it's
2891 usually better to use some other construct such as C<last> or C<die>.
2892 The author of Perl has never felt the need to use this form of C<goto>
2893 (in Perl, that is; C is another matter).  (The difference is that C
2894 does not offer named loops combined with loop control.  Perl does, and
2895 this replaces most structured uses of C<goto> in other languages.)
2896
2897 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2898 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2899 necessarily recommended if you're optimizing for maintainability:
2900
2901     goto ("FOO", "BAR", "GLARCH")[$i];
2902
2903 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2904 function" rule.  A pair of parentheses following it does not (necessarily)
2905 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2906 Also, unlike most named operators, this has the same precedence as
2907 assignment.
2908
2909 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2910 deprecated and will issue a warning.  Even then, it may not be used to
2911 go into any construct that requires initialization, such as a
2912 subroutine or a C<foreach> loop.  It also can't be used to go into a
2913 construct that is optimized away.
2914
2915 The C<goto-&NAME> form is quite different from the other forms of
2916 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2917 doesn't have the stigma associated with other gotos.  Instead, it
2918 exits the current subroutine (losing any changes set by local()) and
2919 immediately calls in its place the named subroutine using the current
2920 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2921 load another subroutine and then pretend that the other subroutine had
2922 been called in the first place (except that any modifications to C<@_>
2923 in the current subroutine are propagated to the other subroutine.)
2924 After the C<goto>, not even C<caller> will be able to tell that this
2925 routine was called first.
2926
2927 NAME needn't be the name of a subroutine; it can be a scalar variable
2928 containing a code reference or a block that evaluates to a code
2929 reference.
2930
2931 =item grep BLOCK LIST
2932 X<grep>
2933
2934 =item grep EXPR,LIST
2935
2936 =for Pod::Functions locate elements in a list test true against a given criterion
2937
2938 This is similar in spirit to, but not the same as, grep(1) and its
2939 relatives.  In particular, it is not limited to using regular expressions.
2940
2941 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2942 C<$_> to each element) and returns the list value consisting of those
2943 elements for which the expression evaluated to true.  In scalar
2944 context, returns the number of times the expression was true.
2945
2946     @foo = grep(!/^#/, @bar);    # weed out comments
2947
2948 or equivalently,
2949
2950     @foo = grep {!/^#/} @bar;    # weed out comments
2951
2952 Note that C<$_> is an alias to the list value, so it can be used to
2953 modify the elements of the LIST.  While this is useful and supported,
2954 it can cause bizarre results if the elements of LIST are not variables.
2955 Similarly, grep returns aliases into the original list, much as a for
2956 loop's index variable aliases the list elements.  That is, modifying an
2957 element of a list returned by grep (for example, in a C<foreach>, C<map>
2958 or another C<grep>) actually modifies the element in the original list.
2959 This is usually something to be avoided when writing clear code.
2960
2961 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2962 been declared with C<my $_>) then, in addition to being locally aliased to
2963 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2964 can't be seen from the outside, avoiding any potential side-effects.
2965
2966 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2967
2968 =item hex EXPR
2969 X<hex> X<hexadecimal>
2970
2971 =item hex
2972
2973 =for Pod::Functions convert a string to a hexadecimal number
2974
2975 Interprets EXPR as a hex string and returns the corresponding value.
2976 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2977 L</oct>.)  If EXPR is omitted, uses C<$_>.
2978
2979     print hex '0xAf'; # prints '175'
2980     print hex 'aF';   # same
2981
2982 Hex strings may only represent integers.  Strings that would cause
2983 integer overflow trigger a warning.  Leading whitespace is not stripped,
2984 unlike oct().  To present something as hex, look into L</printf>,
2985 L</sprintf>, and L</unpack>.
2986
2987 =item import LIST
2988 X<import>
2989
2990 =for Pod::Functions patch a module's namespace into your own
2991
2992 There is no builtin C<import> function.  It is just an ordinary
2993 method (subroutine) defined (or inherited) by modules that wish to export
2994 names to another module.  The C<use> function calls the C<import> method
2995 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2996
2997 =item index STR,SUBSTR,POSITION
2998 X<index> X<indexOf> X<InStr>
2999
3000 =item index STR,SUBSTR
3001
3002 =for Pod::Functions find a substring within a string
3003
3004 The index function searches for one string within another, but without
3005 the wildcard-like behavior of a full regular-expression pattern match.
3006 It returns the position of the first occurrence of SUBSTR in STR at
3007 or after POSITION.  If POSITION is omitted, starts searching from the
3008 beginning of the string.  POSITION before the beginning of the string
3009 or after its end is treated as if it were the beginning or the end,
3010 respectively.  POSITION and the return value are based at zero.
3011 If the substring is not found, C<index> returns -1.
3012
3013 =item int EXPR
3014 X<int> X<integer> X<truncate> X<trunc> X<floor>
3015
3016 =item int
3017
3018 =for Pod::Functions get the integer portion of a number
3019
3020 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3021 You should not use this function for rounding: one because it truncates
3022 towards C<0>, and two because machine representations of floating-point
3023 numbers can sometimes produce counterintuitive results.  For example,
3024 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3025 because it's really more like -268.99999999999994315658 instead.  Usually,
3026 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3027 functions will serve you better than will int().
3028
3029 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3030 X<ioctl>
3031
3032 =for Pod::Functions system-dependent device control system call
3033
3034 Implements the ioctl(2) function.  You'll probably first have to say
3035
3036     require "sys/ioctl.ph";  # probably in
3037                              # $Config{archlib}/sys/ioctl.ph
3038
3039 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3040 exist or doesn't have the correct definitions you'll have to roll your
3041 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3042 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3043 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3044 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3045 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3046 has no string value but does have a numeric value, that value will be
3047 passed rather than a pointer to the string value.  To guarantee this to be
3048 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3049 functions may be needed to manipulate the values of structures used by
3050 C<ioctl>.
3051
3052 The return value of C<ioctl> (and C<fcntl>) is as follows:
3053
3054     if OS returns:      then Perl returns:
3055         -1               undefined value
3056          0              string "0 but true"
3057     anything else           that number
3058
3059 Thus Perl returns true on success and false on failure, yet you can
3060 still easily determine the actual value returned by the operating
3061 system:
3062
3063     $retval = ioctl(...) || -1;
3064     printf "System returned %d\n", $retval;
3065
3066 The special string C<"0 but true"> is exempt from B<-w> complaints
3067 about improper numeric conversions.
3068
3069 Portability issues: L<perlport/ioctl>.
3070
3071 =item join EXPR,LIST
3072 X<join>
3073
3074 =for Pod::Functions join a list into a string using a separator
3075
3076 Joins the separate strings of LIST into a single string with fields
3077 separated by the value of EXPR, and returns that new string.  Example:
3078
3079     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3080
3081 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3082 first argument.  Compare L</split>.
3083
3084 =item keys HASH
3085 X<keys> X<key>
3086
3087 =item keys ARRAY
3088
3089 =item keys EXPR
3090
3091 =for Pod::Functions retrieve list of indices from a hash
3092
3093 Called in list context, returns a list consisting of all the keys of the
3094 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3095 releases prior to 5.12 will produce a syntax error if you try to use an
3096 array argument.  In scalar context, returns the number of keys or indices.
3097
3098 The keys of a hash are returned in an apparently random order.  The actual
3099 random order is subject to change in future versions of Perl, but it
3100 is guaranteed to be the same order as either the C<values> or C<each>
3101 function produces (given that the hash has not been modified).  Since
3102 Perl 5.8.1 the ordering can be different even between different runs of
3103 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
3104 Attacks">).
3105
3106 As a side effect, calling keys() resets the internal iterator of the HASH or
3107 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3108 the iterator with no other overhead.
3109
3110 Here is yet another way to print your environment:
3111
3112     @keys = keys %ENV;
3113     @values = values %ENV;
3114     while (@keys) {
3115         print pop(@keys), '=', pop(@values), "\n";
3116     }
3117
3118 or how about sorted by key:
3119
3120     foreach $key (sort(keys %ENV)) {
3121         print $key, '=', $ENV{$key}, "\n";
3122     }
3123
3124 The returned values are copies of the original keys in the hash, so
3125 modifying them will not affect the original hash.  Compare L</values>.
3126
3127 To sort a hash by value, you'll need to use a C<sort> function.
3128 Here's a descending numeric sort of a hash by its values:
3129
3130     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3131         printf "%4d %s\n", $hash{$key}, $key;
3132     }
3133
3134 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3135 allocated for the given hash.  This can gain you a measure of efficiency if
3136 you know the hash is going to get big.  (This is similar to pre-extending
3137 an array by assigning a larger number to $#array.)  If you say
3138
3139     keys %hash = 200;
3140
3141 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3142 in fact, since it rounds up to the next power of two.  These
3143 buckets will be retained even if you do C<%hash = ()>, use C<undef
3144 %hash> if you want to free the storage while C<%hash> is still in scope.
3145 You can't shrink the number of buckets allocated for the hash using
3146 C<keys> in this way (but you needn't worry about doing this by accident,
3147 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3148 error.
3149
3150 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3151 a reference to an unblessed hash or array.  The argument will be
3152 dereferenced automatically.  This aspect of C<keys> is considered highly
3153 experimental.  The exact behaviour may change in a future version of Perl.
3154
3155     for (keys $hashref) { ... }
3156     for (keys $obj->get_arrayref) { ... }
3157
3158 To avoid confusing would-be users of your code who are running earlier
3159 versions of Perl with mysterious syntax errors, put this sort of thing at
3160 the top of your file to signal that your code will work I<only> on Perls of
3161 a recent vintage:
3162
3163     use 5.012;  # so keys/values/each work on arrays
3164     use 5.014;  # so keys/values/each work on scalars (experimental)
3165
3166 See also C<each>, C<values>, and C<sort>.
3167
3168 =item kill SIGNAL, LIST
3169
3170 =item kill SIGNAL
3171 X<kill> X<signal>
3172
3173 =for Pod::Functions send a signal to a process or process group
3174
3175 Sends a signal to a list of processes.  Returns the number of
3176 processes successfully signaled (which is not necessarily the
3177 same as the number actually killed).
3178
3179     $cnt = kill 1, $child1, $child2;
3180     kill 9, @goners;
3181
3182 If SIGNAL is zero, no signal is sent to the process, but C<kill>
3183 checks whether it's I<possible> to send a signal to it (that
3184 means, to be brief, that the process is owned by the same user, or we are
3185 the super-user).  This is useful to check that a child process is still
3186 alive (even if only as a zombie) and hasn't changed its UID.  See
3187 L<perlport> for notes on the portability of this construct.
3188
3189 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
3190 of processes.  That means you usually
3191 want to use positive not negative signals.
3192
3193 You may also use a signal name in quotes.  A negative signal name is the
3194 same as a negative signal number, killing process groups instead of processes.
3195 For example, C<kill -KILL, $pgrp> will send C<SIGKILL> to the entire process
3196 group specified.
3197
3198 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3199 the operating system.  For example, on POSIX-conforming systems, zero will
3200 signal the current process group, -1 will signal all processes, and any
3201 other negative PROCESS number will act as a negative signal number and
3202 kill the entire process group specified.
3203
3204 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3205 A warning may be produced in a future version.
3206
3207 See L<perlipc/"Signals"> for more details.
3208
3209 On some platforms such as Windows where the fork() system call is not available.
3210 Perl can be built to emulate fork() at the interpreter level.
3211 This emulation has limitations related to kill that have to be considered,
3212 for code running on Windows and in code intended to be portable.
3213
3214 See L<perlfork> for more details.
3215
3216 If there is no I<LIST> of processes, no signal is sent, and the return
3217 value is 0.  This form is sometimes used, however, because it causes
3218 tainting checks to be run.  But see
3219 L<perlsec/Laundering and Detecting Tainted Data>.
3220
3221 Portability issues: L<perlport/kill>.
3222
3223 =item last LABEL
3224 X<last> X<break>
3225
3226 =item last EXPR
3227
3228 =item last
3229
3230 =for Pod::Functions exit a block prematurely
3231
3232 The C<last> command is like the C<break> statement in C (as used in
3233 loops); it immediately exits the loop in question.  If the LABEL is
3234 omitted, the command refers to the innermost enclosing
3235 loop.  The C<last EXPR> form, available starting in Perl
3236 5.18.0, allows a label name to be computed at run time,
3237 and is otherwise identical to C<last LABEL>.  The
3238 C<continue> block, if any, is not executed:
3239
3240     LINE: while (<STDIN>) {
3241         last LINE if /^$/;  # exit when done with header
3242         #...
3243     }
3244
3245 C<last> cannot be used to exit a block that returns a value such as
3246 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3247 a grep() or map() operation.
3248
3249 Note that a block by itself is semantically identical to a loop
3250 that executes once.  Thus C<last> can be used to effect an early
3251 exit out of such a block.
3252
3253 See also L</continue> for an illustration of how C<last>, C<next>, and
3254 C<redo> work.
3255
3256 Unlike most named operators, this has the same precedence as assignment.
3257 It is also exempt from the looks-like-a-function rule, so
3258 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3259 C<last>.
3260
3261 =item lc EXPR
3262 X<lc> X<lowercase>
3263
3264 =item lc
3265
3266 =for Pod::Functions return lower-case version of a string
3267
3268 Returns a lowercased version of EXPR.  This is the internal function
3269 implementing the C<\L> escape in double-quoted strings.
3270
3271 If EXPR is omitted, uses C<$_>.
3272
3273 What gets returned depends on several factors:
3274
3275 =over
3276
3277 =item If C<use bytes> is in effect:
3278
3279 =over
3280
3281 =item On EBCDIC platforms
3282
3283 The results are what the C language system call C<tolower()> returns.
3284
3285 =item On ASCII platforms
3286
3287 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3288 respectively.
3289
3290 =back
3291
3292 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3293
3294 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3295 semantics for the remaining code points (this last can only happen if
3296 the UTF8 flag is also set).  See L<perllocale>.
3297
3298 A deficiency in this is that case changes that cross the 255/256
3299 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3300 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3301 platforms).   But under C<use locale>, the lower case of U+1E9E is
3302 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3303 current locale, and Perl has no way of knowing if that character even
3304 exists in the locale, much less what code point it is.  Perl returns
3305 the input character unchanged, for all instances (and there aren't
3306 many) where the 255/256 boundary would otherwise be crossed.
3307
3308 =item Otherwise, If EXPR has the UTF8 flag set:
3309
3310 Unicode semantics are used for the case change.
3311
3312 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'>) is in effect:
3313
3314 Unicode semantics are used for the case change.
3315
3316 =item Otherwise:
3317
3318 =over
3319
3320 =item On EBCDIC platforms
3321
3322 The results are what the C language system call C<tolower()> returns.
3323
3324 =item On ASCII platforms
3325
3326 ASCII semantics are used for the case change.  The lowercase of any character
3327 outside the ASCII range is the character itself.
3328
3329 =back
3330
3331 =back
3332
3333 =item lcfirst EXPR
3334 X<lcfirst> X<lowercase>
3335
3336 =item lcfirst
3337
3338 =for Pod::Functions return a string with just the next letter in lower case
3339
3340 Returns the value of EXPR with the first character lowercased.  This
3341 is the internal function implementing the C<\l> escape in
3342 double-quoted strings.
3343
3344 If EXPR is omitted, uses C<$_>.
3345
3346 This function behaves the same way under various pragmata, such as in a locale,
3347 as L</lc> does.
3348
3349 =item length EXPR
3350 X<length> X<size>
3351
3352 =item length
3353
3354 =for Pod::Functions return the number of bytes in a string
3355
3356 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3357 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3358 C<undef>.
3359
3360 This function cannot be used on an entire array or hash to find out how
3361 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3362 %hash>, respectively.
3363
3364 Like all Perl character operations, length() normally deals in logical
3365 characters, not physical bytes.  For how many bytes a string encoded as
3366 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3367 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3368
3369 =item __LINE__
3370 X<__LINE__>
3371
3372 =for Pod::Functions the current source line number
3373
3374 A special token that compiles to the current line number.
3375
3376 =item link OLDFILE,NEWFILE
3377 X<link>
3378
3379 =for Pod::Functions create a hard link in the filesystem
3380
3381 Creates a new filename linked to the old filename.  Returns true for
3382 success, false otherwise.
3383
3384 Portability issues: L<perlport/link>.
3385
3386 =item listen SOCKET,QUEUESIZE
3387 X<listen>
3388
3389 =for Pod::Functions register your socket as a server
3390
3391 Does the same thing that the listen(2) system call does.  Returns true if
3392 it succeeded, false otherwise.  See the example in
3393 L<perlipc/"Sockets: Client/Server Communication">.
3394
3395 =item local EXPR
3396 X<local>
3397
3398 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3399
3400 You really probably want to be using C<my> instead, because C<local> isn't
3401 what most people think of as "local".  See
3402 L<perlsub/"Private Variables via my()"> for details.
3403
3404 A local modifies the listed variables to be local to the enclosing
3405 block, file, or eval.  If more than one value is listed, the list must
3406 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3407 for details, including issues with tied arrays and hashes.
3408
3409 The C<delete local EXPR> construct can also be used to localize the deletion
3410 of array/hash elements to the current block.
3411 See L<perlsub/"Localized deletion of elements of composite types">.
3412
3413 =item localtime EXPR
3414 X<localtime> X<ctime>
3415
3416 =item localtime
3417
3418 =for Pod::Functions convert UNIX time into record or string using local time
3419
3420 Converts a time as returned by the time function to a 9-element list
3421 with the time analyzed for the local time zone.  Typically used as
3422 follows:
3423
3424     #  0    1    2     3     4    5     6     7     8
3425     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3426                                                 localtime(time);
3427
3428 All list elements are numeric and come straight out of the C `struct
3429 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3430 of the specified time.
3431
3432 C<$mday> is the day of the month and C<$mon> the month in
3433 the range C<0..11>, with 0 indicating January and 11 indicating December.
3434 This makes it easy to get a month name from a list:
3435
3436     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3437     print "$abbr[$mon] $mday";
3438     # $mon=9, $mday=18 gives "Oct 18"
3439
3440 C<$year> contains the number of years since 1900.  To get a 4-digit
3441 year write:
3442
3443     $year += 1900;
3444
3445 To get the last two digits of the year (e.g., "01" in 2001) do:
3446
3447     $year = sprintf("%02d", $year % 100);
3448
3449 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3450 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3451 (or C<0..365> in leap years.)
3452
3453 C<$isdst> is true if the specified time occurs during Daylight Saving
3454 Time, false otherwise.
3455
3456 If EXPR is omitted, C<localtime()> uses the current time (as returned
3457 by time(3)).
3458
3459 In scalar context, C<localtime()> returns the ctime(3) value:
3460
3461     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3462
3463 The format of this scalar value is B<not> locale-dependent
3464 but built into Perl.  For GMT instead of local
3465 time use the L</gmtime> builtin.  See also the
3466 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3467 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3468 and mktime(3) functions.
3469
3470 To get somewhat similar but locale-dependent date strings, set up your
3471 locale environment variables appropriately (please see L<perllocale>) and
3472 try for example:
3473
3474     use POSIX qw(strftime);
3475     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3476     # or for GMT formatted appropriately for your locale:
3477     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3478
3479 Note that the C<%a> and C<%b>, the short forms of the day of the week
3480 and the month of the year, may not necessarily be three characters wide.
3481
3482 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3483 by-name access mechanism to the gmtime() and localtime() functions,
3484 respectively.
3485
3486 For a comprehensive date and time representation look at the
3487 L<DateTime> module on CPAN.
3488
3489 Portability issues: L<perlport/localtime>.
3490
3491 =item lock THING
3492 X<lock>
3493
3494 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3495
3496 This function places an advisory lock on a shared variable or referenced
3497 object contained in I<THING> until the lock goes out of scope.
3498
3499 The value returned is the scalar itself, if the argument is a scalar, or a
3500 reference, if the argument is a hash, array or subroutine.
3501
3502 lock() is a "weak keyword" : this means that if you've defined a function
3503 by this name (before any calls to it), that function will be called
3504 instead.  If you are not under C<use threads::shared> this does nothing.
3505 See L<threads::shared>.
3506
3507 =item log EXPR
3508 X<log> X<logarithm> X<e> X<ln> X<base>
3509
3510 =item log
3511
3512 =for Pod::Functions retrieve the natural logarithm for a number
3513
3514 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3515 returns the log of C<$_>.  To get the
3516 log of another base, use basic algebra:
3517 The base-N log of a number is equal to the natural log of that number
3518 divided by the natural log of N.  For example:
3519
3520     sub log10 {
3521         my $n = shift;
3522         return log($n)/log(10);
3523     }
3524
3525 See also L</exp> for the inverse operation.
3526
3527 =item lstat FILEHANDLE
3528 X<lstat>
3529
3530 =item lstat EXPR
3531
3532 =item lstat DIRHANDLE
3533
3534 =item lstat
3535
3536 =for Pod::Functions stat a symbolic link
3537
3538 Does the same thing as the C<stat> function (including setting the
3539 special C<_> filehandle) but stats a symbolic link instead of the file
3540 the symbolic link points to.  If symbolic links are unimplemented on
3541 your system, a normal C<stat> is done.  For much more detailed
3542 information, please see the documentation for C<stat>.
3543
3544 If EXPR is omitted, stats C<$_>.
3545
3546 Portability issues: L<perlport/lstat>.
3547
3548 =item m//
3549
3550 =for Pod::Functions match a string with a regular expression pattern
3551
3552 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3553
3554 =item map BLOCK LIST
3555 X<map>
3556
3557 =item map EXPR,LIST
3558
3559 =for Pod::Functions apply a change to a list to get back a new list with the changes
3560
3561 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3562 C<$_> to each element) and returns the list value composed of the
3563 results of each such evaluation.  In scalar context, returns the
3564 total number of elements so generated.  Evaluates BLOCK or EXPR in
3565 list context, so each element of LIST may produce zero, one, or
3566 more elements in the returned value.
3567
3568     @chars = map(chr, @numbers);
3569
3570 translates a list of numbers to the corresponding characters.
3571
3572     my @squares = map { $_ * $_ } @numbers;
3573
3574 translates a list of numbers to their squared values.
3575
3576     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3577
3578 shows that number of returned elements can differ from the number of
3579 input elements.  To omit an element, return an empty list ().
3580 This could also be achieved by writing
3581
3582     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3583
3584 which makes the intention more clear.
3585
3586 Map always returns a list, which can be
3587 assigned to a hash such that the elements
3588 become key/value pairs.  See L<perldata> for more details.
3589
3590     %hash = map { get_a_key_for($_) => $_ } @array;
3591
3592 is just a funny way to write
3593
3594     %hash = ();
3595     foreach (@array) {
3596         $hash{get_a_key_for($_)} = $_;
3597     }
3598
3599 Note that C<$_> is an alias to the list value, so it can be used to
3600 modify the elements of the LIST.  While this is useful and supported,
3601 it can cause bizarre results if the elements of LIST are not variables.
3602 Using a regular C<foreach> loop for this purpose would be clearer in
3603 most cases.  See also L</grep> for an array composed of those items of
3604 the original list for which the BLOCK or EXPR evaluates to true.
3605
3606 If C<$_> is lexical in the scope where the C<map> appears (because it has
3607 been declared with C<my $_>), then, in addition to being locally aliased to
3608 the list elements, C<$_> keeps being lexical inside the block; that is, it
3609 can't be seen from the outside, avoiding any potential side-effects.
3610
3611 C<{> starts both hash references and blocks, so C<map { ...> could be either
3612 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3613 ahead for the closing C<}> it has to take a guess at which it's dealing with
3614 based on what it finds just after the
3615 C<{>.  Usually it gets it right, but if it
3616 doesn't it won't realize something is wrong until it gets to the C<}> and
3617 encounters the missing (or unexpected) comma.  The syntax error will be
3618 reported close to the C<}>, but you'll need to change something near the C<{>
3619 such as using a unary C<+> to give Perl some help:
3620
3621     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3622     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3623     %hash = map { ("\L$_" => 1) } @array # this also works
3624     %hash = map {  lc($_) => 1  } @array # as does this.
3625     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3626
3627     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3628
3629 or to force an anon hash constructor use C<+{>:
3630
3631     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3632                                            # comma at end
3633
3634 to get a list of anonymous hashes each with only one entry apiece.
3635
3636 =item mkdir FILENAME,MASK
3637 X<mkdir> X<md> X<directory, create>
3638
3639 =item mkdir FILENAME
3640
3641 =item mkdir
3642
3643 =for Pod::Functions create a directory
3644
3645 Creates the directory specified by FILENAME, with permissions
3646 specified by MASK (as modified by C<umask>).  If it succeeds it
3647 returns true; otherwise it returns false and sets C<$!> (errno).
3648 MASK defaults to 0777 if omitted, and FILENAME defaults
3649 to C<$_> if omitted.
3650
3651 In general, it is better to create directories with a permissive MASK
3652 and let the user modify that with their C<umask> than it is to supply
3653 a restrictive MASK and give the user no way to be more permissive.
3654 The exceptions to this rule are when the file or directory should be
3655 kept private (mail files, for instance).  The perlfunc(1) entry on
3656 C<umask> discusses the choice of MASK in more detail.
3657
3658 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3659 number of trailing slashes.  Some operating and filesystems do not get
3660 this right, so Perl automatically removes all trailing slashes to keep
3661 everyone happy.
3662
3663 To recursively create a directory structure, look at
3664 the C<mkpath> function of the L<File::Path> module.
3665
3666 =item msgctl ID,CMD,ARG
3667 X<msgctl>
3668
3669 =for Pod::Functions SysV IPC message control operations
3670
3671 Calls the System V IPC function msgctl(2).  You'll probably have to say
3672
3673     use IPC::SysV;
3674
3675 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3676 then ARG must be a variable that will hold the returned C<msqid_ds>
3677 structure.  Returns like C<ioctl>: the undefined value for error,
3678 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3679 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3680 C<IPC::Semaphore>.
3681
3682 Portability issues: L<perlport/msgctl>.
3683
3684 =item msgget KEY,FLAGS
3685 X<msgget>
3686
3687 =for Pod::Functions get SysV IPC message queue
3688
3689 Calls the System V IPC function msgget(2).  Returns the message queue
3690 id, or C<undef> on error.  See also
3691 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3692 C<IPC::Msg>.
3693
3694 Portability issues: L<perlport/msgget>.
3695
3696 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3697 X<msgrcv>
3698
3699 =for Pod::Functions receive a SysV IPC message from a message queue
3700
3701 Calls the System V IPC function msgrcv to receive a message from
3702 message queue ID into variable VAR with a maximum message size of
3703 SIZE.  Note that when a message is received, the message type as a
3704 native long integer will be the first thing in VAR, followed by the
3705 actual message.  This packing may be opened with C<unpack("l! a*")>.
3706 Taints the variable.  Returns true if successful, false 
3707 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3708 C<IPC::SysV> and C<IPC::SysV::Msg>.
3709
3710 Portability issues: L<perlport/msgrcv>.
3711
3712 =item msgsnd ID,MSG,FLAGS
3713 X<msgsnd>
3714
3715 =for Pod::Functions send a SysV IPC message to a message queue
3716
3717 Calls the System V IPC function msgsnd to send the message MSG to the
3718 message queue ID.  MSG must begin with the native long integer message
3719 type, be followed by the length of the actual message, and then finally
3720 the message itself.  This kind of packing can be achieved with
3721 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3722 false on error.  See also the C<IPC::SysV>
3723 and C<IPC::SysV::Msg> documentation.
3724
3725 Portability issues: L<perlport/msgsnd>.
3726
3727 =item my EXPR
3728 X<my>
3729
3730 =item my TYPE EXPR
3731
3732 =item my EXPR : ATTRS
3733
3734 =item my TYPE EXPR : ATTRS
3735
3736 =for Pod::Functions declare and assign a local variable (lexical scoping)
3737
3738 A C<my> declares the listed variables to be local (lexically) to the
3739 enclosing block, file, or C<eval>.  If more than one value is listed,
3740 the list must be placed in parentheses.
3741
3742 The exact semantics and interface of TYPE and ATTRS are still
3743 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3744 and attributes are handled using the C<attributes> pragma, or starting
3745 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3746 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3747 L<attributes>, and L<Attribute::Handlers>.
3748
3749 =item next LABEL
3750 X<next> X<continue>
3751
3752 =item next EXPR
3753
3754 =item next
3755
3756 =for Pod::Functions iterate a block prematurely
3757
3758 The C<next> command is like the C<continue> statement in C; it starts
3759 the next iteration of the loop:
3760
3761     LINE: while (<STDIN>) {
3762         next LINE if /^#/;  # discard comments
3763         #...
3764     }
3765
3766 Note that if there were a C<continue> block on the above, it would get
3767 executed even on discarded lines.  If LABEL is omitted, the command
3768 refers to the innermost enclosing loop.  The C<next EXPR> form, available
3769 as of Perl 5.18.0, allows a label name to be computed at run time, being
3770 otherwise identical to C<next LABEL>.
3771
3772 C<next> cannot be used to exit a block which returns a value such as
3773 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3774 a grep() or map() operation.
3775
3776 Note that a block by itself is semantically identical to a loop
3777 that executes once.  Thus C<next> will exit such a block early.
3778
3779 See also L</continue> for an illustration of how C<last>, C<next>, and
3780 C<redo> work.
3781
3782 Unlike most named operators, this has the same precedence as assignment.
3783 It is also exempt from the looks-like-a-function rule, so
3784 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
3785 C<next>.
3786
3787 =item no MODULE VERSION LIST
3788 X<no declarations>
3789 X<unimporting>
3790
3791 =item no MODULE VERSION
3792
3793 =item no MODULE LIST
3794
3795 =item no MODULE
3796
3797 =item no VERSION
3798
3799 =for Pod::Functions unimport some module symbols or semantics at compile time
3800
3801 See the C<use> function, of which C<no> is the opposite.
3802
3803 =item oct EXPR
3804 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3805
3806 =item oct
3807
3808 =for Pod::Functions convert a string to an octal number
3809
3810 Interprets EXPR as an octal string and returns the corresponding
3811 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3812 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3813 binary string.  Leading whitespace is ignored in all three cases.)
3814 The following will handle decimal, binary, octal, and hex in standard
3815 Perl notation:
3816
3817     $val = oct($val) if $val =~ /^0/;
3818
3819 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3820 in octal), use sprintf() or printf():
3821
3822     $dec_perms = (stat("filename"))[2] & 07777;
3823     $oct_perm_str = sprintf "%o", $perms;
3824
3825 The oct() function is commonly used when a string such as C<644> needs
3826 to be converted into a file mode, for example.  Although Perl 
3827 automatically converts strings into numbers as needed, this automatic
3828 conversion assumes base 10.
3829
3830 Leading white space is ignored without warning, as too are any trailing 
3831 non-digits, such as a decimal point (C<oct> only handles non-negative
3832 integers, not negative integers or floating point).
3833
3834 =item open FILEHANDLE,EXPR
3835 X<open> X<pipe> X<file, open> X<fopen>
3836
3837 =item open FILEHANDLE,MODE,EXPR
3838
3839 =item open FILEHANDLE,MODE,EXPR,LIST
3840
3841 =item open FILEHANDLE,MODE,REFERENCE
3842
3843 =item open FILEHANDLE
3844
3845 =for Pod::Functions open a file, pipe, or descriptor
3846
3847 Opens the file whose filename is given by EXPR, and associates it with
3848 FILEHANDLE.
3849
3850 Simple examples to open a file for reading:
3851
3852     open(my $fh, "<", "input.txt") 
3853         or die "cannot open < input.txt: $!";
3854
3855 and for writing:
3856
3857     open(my $fh, ">", "output.txt") 
3858         or die "cannot open > output.txt: $!";
3859
3860 (The following is a comprehensive reference to open(): for a gentler
3861 introduction you may consider L<perlopentut>.)
3862
3863 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3864 new filehandle is autovivified, meaning that the variable is assigned a
3865 reference to a newly allocated anonymous filehandle.  Otherwise if
3866 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3867 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3868 in effect.)
3869
3870 If EXPR is omitted, the global (package) scalar variable of the same
3871 name as the FILEHANDLE contains the filename.  (Note that lexical 
3872 variables--those declared with C<my> or C<state>--will not work for this
3873 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3874 call to open.)
3875
3876 If three (or more) arguments are specified, the open mode (including
3877 optional encoding) in the second argument are distinct from the filename in
3878 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3879 If MODE is C<< > >>, the file is opened for output, with existing files
3880 first being truncated ("clobbered") and nonexisting files newly created.
3881 If MODE is C<<< >> >>>, the file is opened for appending, again being
3882 created if necessary.
3883
3884 You can put a C<+> in front of the C<< > >> or C<< < >> to
3885 indicate that you want both read and write access to the file; thus
3886 C<< +< >> is almost always preferred for read/write updates--the 
3887 C<< +> >> mode would clobber the file first.  You can't usually use
3888 either read-write mode for updating textfiles, since they have
3889 variable-length records.  See the B<-i> switch in L<perlrun> for a
3890 better approach.  The file is created with permissions of C<0666>
3891 modified by the process's C<umask> value.
3892
3893 These various prefixes correspond to the fopen(3) modes of C<r>,
3894 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3895
3896 In the one- and two-argument forms of the call, the mode and filename
3897 should be concatenated (in that order), preferably separated by white
3898 space.  You can--but shouldn't--omit the mode in these forms when that mode
3899 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3900 the filename argument is a known literal.
3901
3902 For three or more arguments if MODE is C<|->, the filename is
3903 interpreted as a command to which output is to be piped, and if MODE
3904 is C<-|>, the filename is interpreted as a command that pipes
3905 output to us.  In the two-argument (and one-argument) form, one should
3906 replace dash (C<->) with the command.
3907 See L<perlipc/"Using open() for IPC"> for more examples of this.
3908 (You are not allowed to C<open> to a command that pipes both in I<and>
3909 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3910 L<perlipc/"Bidirectional Communication with Another Process"> for
3911 alternatives.)
3912
3913 In the form of pipe opens taking three or more arguments, if LIST is specified
3914 (extra arguments after the command name) then LIST becomes arguments
3915 to the command invoked if the platform supports it.  The meaning of
3916 C<open> with more than three arguments for non-pipe modes is not yet
3917 defined, but experimental "layers" may give extra LIST arguments
3918 meaning.
3919
3920 In the two-argument (and one-argument) form, opening C<< <- >> 
3921 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3922
3923 You may (and usually should) use the three-argument form of open to specify
3924 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3925 that affect how the input and output are processed (see L<open> and
3926 L<PerlIO> for more details).  For example:
3927
3928   open(my $fh, "<:encoding(UTF-8)", "filename")
3929     || die "can't open UTF-8 encoded filename: $!";
3930
3931 opens the UTF8-encoded file containing Unicode characters;
3932 see L<perluniintro>.  Note that if layers are specified in the
3933 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3934 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3935 Those layers will also be ignored if you specifying a colon with no name
3936 following it.  In that case the default layer for the operating system
3937 (:raw on Unix, :crlf on Windows) is used.
3938
3939 Open returns nonzero on success, the undefined value otherwise.  If
3940 the C<open> involved a pipe, the return value happens to be the pid of
3941 the subprocess.
3942
3943 If you're running Perl on a system that distinguishes between text
3944 files and binary files, then you should check out L</binmode> for tips
3945 for dealing with this.  The key distinction between systems that need
3946 C<binmode> and those that don't is their text file formats.  Systems
3947 like Unix, Mac OS, and Plan 9, that end lines with a single
3948 character and encode that character in C as C<"\n"> do not
3949 need C<binmode>.  The rest need it.
3950
3951 When opening a file, it's seldom a good idea to continue 
3952 if the request failed, so C<open> is frequently used with
3953 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3954 where you want to format a suitable error message (but there are
3955 modules that can help with that problem)) always check
3956 the return value from opening a file.  
3957
3958 As a special case the three-argument form with a read/write mode and the third
3959 argument being C<undef>:
3960
3961     open(my $tmp, "+>", undef) or die ...
3962
3963 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3964 works for symmetry, but you really should consider writing something
3965 to the temporary file first.  You will need to seek() to do the
3966 reading.
3967
3968 Perl is built using PerlIO by default; Unless you've
3969 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3970 open filehandles directly to Perl scalars via:
3971
3972     open($fh, ">", \$variable) || ..
3973
3974 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3975
3976     close STDOUT;
3977     open(STDOUT, ">", \$variable)
3978         or die "Can't open STDOUT: $!";
3979
3980 General examples:
3981
3982     $ARTICLE = 100;
3983     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3984     while (<ARTICLE>) {...
3985
3986     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3987     # if the open fails, output is discarded
3988
3989     open(my $dbase, "+<", "dbase.mine")      # open for update
3990         or die "Can't open 'dbase.mine' for update: $!";
3991
3992     open(my $dbase, "+<dbase.mine")          # ditto
3993         or die "Can't open 'dbase.mine' for update: $!";
3994
3995     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3996         or die "Can't start caesar: $!";
3997
3998     open(ARTICLE, "caesar <$article |")      # ditto
3999         or die "Can't start caesar: $!";
4000
4001     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
4002         or die "Can't start sort: $!";
4003
4004     # in-memory files
4005     open(MEMORY, ">", \$var)
4006         or die "Can't open memory file: $!";
4007     print MEMORY "foo!\n";              # output will appear in $var
4008
4009     # process argument list of files along with any includes
4010
4011     foreach $file (@ARGV) {
4012         process($file, "fh00");
4013     }
4014
4015     sub process {
4016         my($filename, $input) = @_;
4017         $input++;    # this is a string increment
4018         unless (open($input, "<", $filename)) {
4019             print STDERR "Can't open $filename: $!\n";
4020             return;
4021         }
4022
4023         local $_;
4024         while (<$input>) {    # note use of indirection
4025             if (/^#include "(.*)"/) {
4026                 process($1, $input);
4027                 next;
4028             }
4029             #...          # whatever
4030         }
4031     }
4032
4033 See L<perliol> for detailed info on PerlIO.
4034
4035 You may also, in the Bourne shell tradition, specify an EXPR beginning
4036 with C<< >& >>, in which case the rest of the string is interpreted
4037 as the name of a filehandle (or file descriptor, if numeric) to be
4038 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4039 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4040 The mode you specify should match the mode of the original filehandle.
4041 (Duping a filehandle does not take into account any existing contents
4042 of IO buffers.)  If you use the three-argument
4043 form, then you can pass either a
4044 number, the name of a filehandle, or the normal "reference to a glob".
4045
4046 Here is a script that saves, redirects, and restores C<STDOUT> and
4047 C<STDERR> using various methods:
4048
4049     #!/usr/bin/perl
4050     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4051     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4052
4053     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4054     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4055
4056     select STDERR; $| = 1;  # make unbuffered
4057     select STDOUT; $| = 1;  # make unbuffered
4058
4059     print STDOUT "stdout 1\n";  # this works for
4060     print STDERR "stderr 1\n";  # subprocesses too
4061
4062     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4063     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4064
4065     print STDOUT "stdout 2\n";
4066     print STDERR "stderr 2\n";
4067
4068 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4069 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4070 that file descriptor (and not call C<dup(2)>); this is more
4071 parsimonious of file descriptors.  For example:
4072
4073     # open for input, reusing the fileno of $fd
4074     open(FILEHANDLE, "<&=$fd")
4075
4076 or
4077
4078     open(FILEHANDLE, "<&=", $fd)
4079
4080 or
4081
4082     # open for append, using the fileno of OLDFH
4083     open(FH, ">>&=", OLDFH)
4084
4085 or
4086
4087     open(FH, ">>&=OLDFH")
4088
4089 Being parsimonious on filehandles is also useful (besides being
4090 parsimonious) for example when something is dependent on file
4091 descriptors, like for example locking using flock().  If you do just
4092 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4093 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4094 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4095 the same underlying system file descriptor.
4096
4097 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4098 fdopen() to implement the C<=> functionality.  On many Unix systems,
4099 fdopen() fails when file descriptors exceed a certain value, typically 255.
4100 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4101
4102 You can see whether your Perl was built with PerlIO by running C<perl -V>
4103 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4104 have PerlIO; otherwise you don't.
4105
4106 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4107 with the one- or two-argument forms of C<open>), 
4108 an implicit C<fork> is done, so C<open> returns twice: in the parent
4109 process it returns the pid
4110 of the child process, and in the child process it returns (a defined) C<0>.
4111 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4112
4113 For example, use either
4114
4115     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4116
4117 or
4118
4119     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4120
4121 followed by 
4122
4123     if ($child_pid) {
4124         # am the parent:
4125         # either write TO_KID or else read FROM_KID
4126         ...
4127        waitpid $child_pid, 0;
4128     } else {
4129         # am the child; use STDIN/STDOUT normally
4130         ...
4131         exit;
4132     } 
4133
4134 The filehandle behaves normally for the parent, but I/O to that
4135 filehandle is piped from/to the STDOUT/STDIN of the child process.
4136 In the child process, the filehandle isn't opened--I/O happens from/to
4137 the new STDOUT/STDIN.  Typically this is used like the normal
4138 piped open when you want to exercise more control over just how the
4139 pipe command gets executed, such as when running setuid and
4140 you don't want to have to scan shell commands for metacharacters.
4141
4142 The following blocks are more or less equivalent:
4143
4144     open(FOO, "|tr '[a-z]' '[A-Z]'");
4145     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4146     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4147     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4148
4149     open(FOO, "cat -n '$file'|");
4150     open(FOO, "-|", "cat -n '$file'");
4151     open(FOO, "-|") || exec "cat", "-n", $file;
4152     open(FOO, "-|", "cat", "-n", $file);
4153
4154 The last two examples in each block show the pipe as "list form", which is
4155 not yet supported on all platforms.  A good rule of thumb is that if
4156 your platform has a real C<fork()> (in other words, if your platform is
4157 Unix, including Linux and MacOS X), you can use the list form.  You would 
4158 want to use the list form of the pipe so you can pass literal arguments
4159 to the command without risk of the shell interpreting any shell metacharacters
4160 in them.  However, this also bars you from opening pipes to commands
4161 that intentionally contain shell metacharacters, such as:
4162
4163     open(FOO, "|cat -n | expand -4 | lpr")
4164         // die "Can't open pipeline to lpr: $!";
4165
4166 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4167
4168 Perl will attempt to flush all files opened for
4169 output before any operation that may do a fork, but this may not be
4170 supported on some platforms (see L<perlport>).  To be safe, you may need
4171 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4172 of C<IO::Handle> on any open handles.
4173
4174 On systems that support a close-on-exec flag on files, the flag will
4175 be set for the newly opened file descriptor as determined by the value
4176 of C<$^F>.  See L<perlvar/$^F>.
4177
4178 Closing any piped filehandle causes the parent process to wait for the
4179 child to finish, then returns the status value in C<$?> and
4180 C<${^CHILD_ERROR_NATIVE}>.
4181
4182 The filename passed to the one- and two-argument forms of open() will
4183 have leading and trailing whitespace deleted and normal
4184 redirection characters honored.  This property, known as "magic open",
4185 can often be used to good effect.  A user could specify a filename of
4186 F<"rsh cat file |">, or you could change certain filenames as needed:
4187
4188     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4189     open(FH, $filename) or die "Can't open $filename: $!";
4190
4191 Use the three-argument form to open a file with arbitrary weird characters in it,
4192
4193     open(FOO, "<", $file)
4194         || die "can't open < $file: $!";
4195
4196 otherwise it's necessary to protect any leading and trailing whitespace:
4197
4198     $file =~ s#^(\s)#./$1#;
4199     open(FOO, "< $file\0")
4200         || die "open failed: $!";
4201
4202 (this may not work on some bizarre filesystems).  One should
4203 conscientiously choose between the I<magic> and I<three-argument> form
4204 of open():
4205
4206     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4207
4208 will allow the user to specify an argument of the form C<"rsh cat file |">,
4209 but will not work on a filename that happens to have a trailing space, while
4210
4211     open(IN, "<", $ARGV[0])
4212         || die "can't open < $ARGV[0]: $!";
4213
4214 will have exactly the opposite restrictions.
4215
4216 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4217 should use the C<sysopen> function, which involves no such magic (but may
4218 use subtly different filemodes than Perl open(), which is mapped to C
4219 fopen()).  This is another way to protect your filenames from
4220 interpretation.  For example:
4221
4222     use IO::Handle;
4223     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4224         or die "sysopen $path: $!";
4225     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4226     print HANDLE "stuff $$\n";
4227     seek(HANDLE, 0, 0);
4228     print "File contains: ", <HANDLE>;
4229
4230 Using the constructor from the C<IO::Handle> package (or one of its
4231 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
4232 filehandles that have the scope of the variables used to hold them, then
4233 automatically (but silently) close once their reference counts become
4234 zero, typically at scope exit:
4235
4236     use IO::File;
4237     #...
4238     sub read_myfile_munged {
4239         my $ALL = shift;
4240         # or just leave it undef to autoviv
4241         my $handle = IO::File->new;
4242         open($handle, "<", "myfile") or die "myfile: $!";
4243         $first = <$handle>
4244             or return ();     # Automatically closed here.
4245         mung($first) or die "mung failed";  # Or here.
4246         return (first, <$handle>) if $ALL;  # Or here.
4247         return $first;                      # Or here.
4248     }
4249
4250 B<WARNING:> The previous example has a bug because the automatic
4251 close that happens when the refcount on C<handle> reaches zero does not
4252 properly detect and report failures.  I<Always> close the handle
4253 yourself and inspect the return value.
4254
4255     close($handle) 
4256         || warn "close failed: $!";
4257
4258 See L</seek> for some details about mixing reading and writing.
4259
4260 Portability issues: L<perlport/open>.
4261
4262 =item opendir DIRHANDLE,EXPR
4263 X<opendir>
4264
4265 =for Pod::Functions open a directory
4266
4267 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4268 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4269 DIRHANDLE may be an expression whose value can be used as an indirect
4270 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4271 scalar variable (or array or hash element), the variable is assigned a
4272 reference to a new anonymous dirhandle; that is, it's autovivified.
4273 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4274
4275 See the example at C<readdir>.
4276
4277 =item ord EXPR
4278 X<ord> X<encoding>
4279
4280 =item ord
4281
4282 =for Pod::Functions find a character's numeric representation
4283
4284 Returns the numeric value of the first character of EXPR.
4285 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4286 (Note I<character>, not byte.)
4287
4288 For the reverse, see L</chr>.
4289 See L<perlunicode> for more about Unicode.
4290
4291 =item our EXPR
4292 X<our> X<global>
4293
4294 =item our TYPE EXPR
4295
4296 =item our EXPR : ATTRS
4297
4298 =item our TYPE EXPR : ATTRS
4299
4300 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4301
4302 C<our> makes a lexical alias to a package variable of the same name in the current
4303 package for use within the current lexical scope.
4304
4305 C<our> has the same scoping rules as C<my> or C<state>, but C<our> only
4306 declares an alias, whereas C<my> or C<state> both declare a variable name and
4307 allocate storage for that name within the current scope.
4308
4309 This means that when C<use strict 'vars'> is in effect, C<our> lets you use
4310 a package variable without qualifying it with the package name, but only within
4311 the lexical scope of the C<our> declaration.  In this way, C<our> differs from
4312 C<use vars>, which allows use of an unqualified name I<only> within the
4313 affected package, but across scopes.
4314
4315 If more than one value is listed, the list must be placed
4316 in parentheses.
4317
4318     our $foo;
4319     our($bar, $baz);
4320
4321 An C<our> declaration declares an alias for a package variable that will be visible
4322 across its entire lexical scope, even across package boundaries.  The
4323 package in which the variable is entered is determined at the point
4324 of the declaration, not at the point of use.  This means the following
4325 behavior holds:
4326
4327     package Foo;
4328     our $bar;      # declares $Foo::bar for rest of lexical scope
4329     $bar = 20;
4330
4331     package Bar;
4332     print $bar;    # prints 20, as it refers to $Foo::bar
4333
4334 Multiple C<our> declarations with the same name in the same lexical
4335 scope are allowed if they are in different packages.  If they happen
4336 to be in the same package, Perl will emit warnings if you have asked
4337 for them, just like multiple C<my> declarations.  Unlike a second
4338 C<my> declaration, which will bind the name to a fresh variable, a
4339 second C<our> declaration in the same package, in the same scope, is
4340 merely redundant.
4341
4342     use warnings;
4343     package Foo;
4344     our $bar;      # declares $Foo::bar for rest of lexical scope
4345     $bar = 20;
4346
4347     package Bar;
4348     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4349     print $bar;    # prints 30
4350
4351     our $bar;      # emits warning but has no other effect
4352     print $bar;    # still prints 30
4353
4354 An C<our> declaration may also have a list of attributes associated
4355 with it.
4356
4357 The exact semantics and interface of TYPE and ATTRS are still
4358 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4359 and attributes are handled using the C<attributes> pragma, or, starting
4360 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4361 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4362 L<attributes>, and L<Attribute::Handlers>.
4363
4364 =item pack TEMPLATE,LIST
4365 X<pack>
4366
4367 =for Pod::Functions convert a list into a binary representation
4368
4369 Takes a LIST of values and converts it into a string using the rules
4370 given by the TEMPLATE.  The resulting string is the concatenation of
4371 the converted values.  Typically, each converted value looks
4372 like its machine-level representation.  For example, on 32-bit machines
4373 an integer may be represented by a sequence of 4 bytes, which  will in
4374 Perl be presented as a string that's 4 characters long. 
4375
4376 See L<perlpacktut> for an introduction to this function.
4377
4378 The TEMPLATE is a sequence of characters that give the order and type
4379 of values, as follows:
4380
4381     a  A string with arbitrary binary data, will be null padded.
4382     A  A text (ASCII) string, will be space padded.
4383     Z  A null-terminated (ASCIZ) string, will be null padded.
4384
4385     b  A bit string (ascending bit order inside each byte,
4386        like vec()).
4387     B  A bit string (descending bit order inside each byte).
4388     h  A hex string (low nybble first).
4389     H  A hex string (high nybble first).
4390
4391     c  A signed char (8-bit) value.
4392     C  An unsigned char (octet) value.
4393     W  An unsigned char value (can be greater than 255).
4394
4395     s  A signed short (16-bit) value.
4396     S  An unsigned short value.
4397
4398     l  A signed long (32-bit) value.
4399     L  An unsigned long value.
4400
4401     q  A signed quad (64-bit) value.
4402     Q  An unsigned quad value.
4403          (Quads are available only if your system supports 64-bit
4404           integer values _and_ if Perl has been compiled to support
4405           those.  Raises an exception otherwise.)
4406
4407     i  A signed integer value.
4408     I  A unsigned integer value.
4409          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4410           size depends on what a local C compiler calls 'int'.)
4411
4412     n  An unsigned short (16-bit) in "network" (big-endian) order.
4413     N  An unsigned long (32-bit) in "network" (big-endian) order.
4414     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4415     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4416
4417     j  A Perl internal signed integer value (IV).
4418     J  A Perl internal unsigned integer value (UV).
4419
4420     f  A single-precision float in native format.
4421     d  A double-precision float in native format.
4422
4423     F  A Perl internal floating-point value (NV) in native format
4424     D  A float of long-double precision in native format.
4425          (Long doubles are available only if your system supports
4426           long double values _and_ if Perl has been compiled to
4427           support those.  Raises an exception otherwise.)
4428
4429     p  A pointer to a null-terminated string.
4430     P  A pointer to a structure (fixed-length string).
4431
4432     u  A uuencoded string.
4433     U  A Unicode character number.  Encodes to a character in char-
4434        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4435        byte mode.
4436
4437     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4438        for details).  Its bytes represent an unsigned integer in
4439        base 128, most significant digit first, with as few digits
4440        as possible.  Bit eight (the high bit) is set on each byte
4441        except the last.
4442
4443     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4444     X  Back up a byte.
4445     @  Null-fill or truncate to absolute position, counted from the
4446        start of the innermost ()-group.
4447     .  Null-fill or truncate to absolute position specified by
4448        the value.
4449     (  Start of a ()-group.
4450
4451 One or more modifiers below may optionally follow certain letters in the
4452 TEMPLATE (the second column lists letters for which the modifier is valid):
4453
4454     !   sSlLiI     Forces native (short, long, int) sizes instead
4455                    of fixed (16-/32-bit) sizes.
4456
4457         xX         Make x and X act as alignment commands.
4458
4459         nNvV       Treat integers as signed instead of unsigned.
4460
4461         @.         Specify position as byte offset in the internal
4462                    representation of the packed string.  Efficient
4463                    but dangerous.
4464
4465     >   sSiIlLqQ   Force big-endian byte-order on the type.
4466         jJfFdDpP   (The "big end" touches the construct.)
4467
4468     <   sSiIlLqQ   Force little-endian byte-order on the type.
4469         jJfFdDpP   (The "little end" touches the construct.)
4470
4471 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4472 to force a particular byte-order on all components in that group, 
4473 including all its subgroups.
4474
4475 The following rules apply:
4476
4477 =over 
4478
4479 =item *
4480
4481 Each letter may optionally be followed by a number indicating the repeat
4482 count.  A numeric repeat count may optionally be enclosed in brackets, as
4483 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4484 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4485 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4486 something else, described below.  Supplying a C<*> for the repeat count
4487 instead of a number means to use however many items are left, except for:
4488
4489 =over 
4490
4491 =item * 
4492
4493 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4494
4495 =item * 
4496
4497 <.>, where it means relative to the start of the string.
4498
4499 =item * 
4500
4501 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4502
4503 =back 
4504
4505 One can replace a numeric repeat count with a template letter enclosed in
4506 brackets to use the packed byte length of the bracketed template for the
4507 repeat count.
4508
4509 For example, the template C<x[L]> skips as many bytes as in a packed long,
4510 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4511 variable-expanded) unpacks.  If the template in brackets contains alignment
4512 commands (such as C<x![d]>), its packed length is calculated as if the
4513 start of the template had the maximal possible alignment.
4514
4515 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4516 trailing null byte, so the resulting string is always one byte longer than
4517 the byte length of the item itself.
4518
4519 When used with C<@>, the repeat count represents an offset from the start
4520 of the innermost C<()> group.
4521
4522 When used with C<.>, the repeat count determines the starting position to
4523 calculate the value offset as follows:
4524
4525 =over 
4526
4527 =item *
4528
4529 If the repeat count is C<0>, it's relative to the current position.
4530
4531 =item *
4532
4533 If the repeat count is C<*>, the offset is relative to the start of the
4534 packed string.
4535
4536 =item *
4537
4538 And if it's an integer I<n>, the offset is relative to the start of the
4539 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4540 bigger then the group level.
4541
4542 =back
4543
4544 The repeat count for C<u> is interpreted as the maximal number of bytes
4545 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4546 count should not be more than 65.
4547
4548 =item *
4549
4550 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4551 string of length count, padding with nulls or spaces as needed.  When
4552 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4553 after the first null, and C<a> returns data with no stripping at all.
4554
4555 If the value to pack is too long, the result is truncated.  If it's too
4556 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4557 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4558 when the count is 0.
4559
4560 =item *
4561
4562 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4563 Each such format generates 1 bit of the result.  These are typically followed
4564 by a repeat count like C<B8> or C<B64>.
4565
4566 Each result bit is based on the least-significant bit of the corresponding
4567 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4568 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4569
4570 Starting from the beginning of the input string, each 8-tuple
4571 of characters is converted to 1 character of output.  With format C<b>,
4572 the first character of the 8-tuple determines the least-significant bit of a
4573 character; with format C<B>, it determines the most-significant bit of
4574 a character.
4575
4576 If the length of the input string is not evenly divisible by 8, the
4577 remainder is packed as if the input string were padded by null characters
4578 at the end.  Similarly during unpacking, "extra" bits are ignored.
4579
4580 If the input string is longer than needed, remaining characters are ignored.
4581
4582 A C<*> for the repeat count uses all characters of the input field.  
4583 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4584
4585 =item *
4586
4587 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4588 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4589
4590 For each such format, pack() generates 4 bits of result.
4591 With non-alphabetical characters, the result is based on the 4 least-significant
4592 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4593 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4594 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4595 is compatible with the usual hexadecimal digits, so that C<"a"> and
4596 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4597 characters with this format.
4598
4599 Starting from the beginning of the template to pack(), each pair
4600 of characters is converted to 1 character of output.  With format C<h>, the
4601 first character of the pair determines the least-significant nybble of the
4602 output character; with format C<H>, it determines the most-significant
4603 nybble.
4604
4605 If the length of the input string is not even, it behaves as if padded by
4606 a null character at the end.  Similarly, "extra" nybbles are ignored during
4607 unpacking.
4608
4609 If the input string is longer than needed, extra characters are ignored.
4610
4611 A C<*> for the repeat count uses all characters of the input field.  For
4612 unpack(), nybbles are converted to a string of hexadecimal digits.
4613
4614 =item *
4615
4616 The C<p> format packs a pointer to a null-terminated string.  You are
4617 responsible for ensuring that the string is not a temporary value, as that
4618 could potentially get deallocated before you got around to using the packed
4619 result.  The C<P> format packs a pointer to a structure of the size indicated
4620 by the length.  A null pointer is created if the corresponding value for
4621 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4622 unpacks into C<undef>.
4623
4624 If your system has a strange pointer size--meaning a pointer is neither as
4625 big as an int nor as big as a long--it may not be possible to pack or
4626 unpack pointers in big- or little-endian byte order.  Attempting to do
4627 so raises an exception.
4628
4629 =item *
4630
4631 The C</> template character allows packing and unpacking of a sequence of
4632 items where the packed structure contains a packed item count followed by
4633 the packed items themselves.  This is useful when the structure you're
4634 unpacking has encoded the sizes or repeat counts for some of its fields
4635 within the structure itself as separate fields.
4636
4637 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4638 I<length-item> describes how the length value is packed.  Formats likely
4639 to be of most use are integer-packing ones like C<n> for Java strings,
4640 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4641
4642 For C<pack>, I<sequence-item> may have a repeat count, in which case
4643 the minimum of that and the number of available items is used as the argument
4644 for I<length-item>.  If it has no repeat count or uses a '*', the number
4645 of available items is used.
4646
4647 For C<unpack>, an internal stack of integer arguments unpacked so far is
4648 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4649 popping off the last element from the stack.  The I<sequence-item> must not
4650 have a repeat count.
4651
4652 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4653 the I<length-item> is the string length, not the number of strings.  With
4654 an explicit repeat count for pack, the packed string is adjusted to that
4655 length.  For example:
4656
4657  This code:                             gives this result:
4658  
4659  unpack("W/a", "\004Gurusamy")          ("Guru")
4660  unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4661  unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4662
4663  pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4664  pack("a/W2", ord("a") .. ord("z"))    "2ab"
4665
4666 The I<length-item> is not returned explicitly from C<unpack>.
4667
4668 Supplying a count to the I<length-item> format letter is only useful with
4669 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4670 introduce C<"\000"> characters, which Perl does not regard as legal in
4671 numeric strings.
4672
4673 =item *
4674
4675 The integer types C<s>, C<S>, C<l>, and C<L> may be
4676 followed by a C<!> modifier to specify native shorts or
4677 longs.  As shown in the example above, a bare C<l> means
4678 exactly 32 bits, although the native C<long> as seen by the local C compiler
4679 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4680 see whether using C<!> makes any difference this way:
4681
4682     printf "format s is %d, s! is %d\n", 
4683         length pack("s"), length pack("s!");
4684
4685     printf "format l is %d, l! is %d\n", 
4686         length pack("l"), length pack("l!");
4687
4688
4689 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4690 they are identical&