pod/perlrecharclass.pod

   1 =head1 NAME
   2 X<character class>
   3
   4 perlrecharclass - Perl Regular Expression Character Classes
   5
   6 =head1 DESCRIPTION
   7
   8 The top level documentation about Perl regular expressions
   9 is found in L<perlre>.
  10
  11 This manual page discusses the syntax and use of character
  12 classes in Perl regular expressions.
  13
  14 A character class is a way of denoting a set of characters
  15 in such a way that one character of the set is matched.
  16 It's important to remember that: matching a character class
  17 consumes exactly one character in the source string. (The source
  18 string is the string the regular expression is matched against.)
  19
  20 There are three types of character classes in Perl regular
  21 expressions: the dot, backslash sequences, and the form enclosed in square
  22 brackets.  Keep in mind, though, that often the term "character class" is used
  23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
  24
  25 =head2 The dot
  26
  27 The dot (or period), C<.> is probably the most used, and certainly
  28 the most well-known character class. By default, a dot matches any
  29 character, except for the newline. The default can be changed to
  30 add matching the newline by using the I<single line> modifier: either
  31 for the entire regular expression with the C</s> modifier, or
  32 locally with C<(?s)>.  (The experimental C<\N> backslash sequence, described
  33 below, matches any character except newline without regard to the
  34 I<single line> modifier.)
  35
  36 Here are some examples:
  37
  38  "a"  =~  /./       # Match
  39  "."  =~  /./       # Match
  40  ""   =~  /./       # No match (dot has to match a character)
  41  "\n" =~  /./       # No match (dot does not match a newline)
  42  "\n" =~  /./s      # Match (global 'single line' modifier)
  43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
  44  "ab" =~  /^.$/     # No match (dot matches one character)
  45
  46 =head2 Backslash sequences
  47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
  48 X<\N> X<\v> X<\V> X<\h> X<\H>
  49 X<word> X<whitespace>
  50
  51 A backslash sequence is a sequence of characters, the first one of which is a
  52 backslash.  Perl ascribes special meaning to many such sequences, and some of
  53 these are character classes.  That is, they match a single character each,
  54 provided that the character belongs to the specific set of characters defined
  55 by the sequence.
  56
  57 Here's a list of the backslash sequences that are character classes.  They
  58 are discussed in more detail below.  (For the backslash sequences that aren't
  59 character classes, see L<perlrebackslash>.)
  60
  61  \d             Match a decimal digit character.
  62  \D             Match a non-decimal-digit character.
  63  \w             Match a "word" character.
  64  \W             Match a non-"word" character.
  65  \s             Match a whitespace character.
  66  \S             Match a non-whitespace character.
  67  \h             Match a horizontal whitespace character.
  68  \H             Match a character that isn't horizontal whitespace.
  69  \v             Match a vertical whitespace character.
  70  \V             Match a character that isn't vertical whitespace.
  71  \N             Match a character that isn't a newline.  Experimental.
  72  \pP, \p{Prop}  Match a character that has the given Unicode property.
  73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
  74
  75 =head3 Digits
  76
  77 C<\d> matches a single character that is considered to be a decimal I<digit>.
  78 What is considered a decimal digit depends on several factors, detailed
  79 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
  80 indicate a Unicode interpretation, C<\d> not only matches the digits
  81 '0' - '9', but also Arabic, Devanagari and digits from other languages.
  82 Otherwise, if there is a locale in effect, it will match whatever
  83 characters the locale considers decimal digits.  Without a locale, C<\d>
  84 matches just the digits '0' to '9'.
  85
  86 Unicode digits may cause some confusion, and some security issues.  In UTF-8
  87 strings, C<\d> matches the same characters matched by
  88 C<\p{General_Category=Decimal_Number}>, or synonymously,
  89 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this is the
  90 same set of characters matched by C<\p{Numeric_Type=Decimal}>.
  91
  92 But Unicode also has a different property with a similar name,
  93 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
  94 characters.  These characters are things such as subscripts.
  95
  96 The design intent is for C<\d> to match all the digits (and no other characters)
  97 that can be used with "normal" big-endian positional decimal syntax, whereby a
  98 sequence of such digits {N0, N1, N2, ...Nn} has the numeric value (...(N0 * 10
  99 + N1) * 10 + N2) * 10 ... + Nn).  In Unicode 5.2, the Tamil digits (U+0BE6 -
 100 U+0BEF) can also legally be used in old-style Tamil numbers in which they would
 101 appear no more than one in a row, separated by characters that mean "times 10",
 102 "times 100", etc.  (See L<http://www.unicode.org/notes/tn21>.)
 103
 104 Some of the non-European digits that C<\d> matches look like European ones, but
 105 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
 106 very much like an ASCII DIGIT EIGHT (U+0038).
 107
 108 It may be useful for security purposes for an application to require that all
 109 digits in a row be from the same script.   See L<Unicode::UCD/charscript()>.
 110
 111 Any character that isn't matched by C<\d> will be matched by C<\D>.
 112
 113 =head3 Word characters
 114
 115 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
 116 decimal digit) or an underscore (C<_>), not a whole word.  To match a whole
 117 word, use C<\w+>.  This isn't the same thing as matching an English word, but
 118 is the same as a string of Perl-identifier characters.  What is considered a
 119 word character depends on several factors, detailed below in L</Locale,
 120 EBCDIC, Unicode and UTF-8>.  If those factors indicate a Unicode
 121 interpretation, C<\w> matches the characters that are considered word
 122 characters in the Unicode database. That is, it not only matches ASCII letters,
 123 but also Thai letters, Greek letters, etc.  If a Unicode interpretation
 124 is not indicated, C<\w> matches those characters that are considered
 125 word characters by the current locale or EBCDIC code page.  Without a
 126 locale or EBCDIC code page, C<\w> matches the ASCII letters, digits and
 127 the underscore.
 128
 129 There are a number of security issues with the full Unicode list of word
 130 characters.  See L<http://unicode.org/reports/tr36>.
 131
 132 Also, for a somewhat finer-grained set of characters that are in programming
 133 language identifiers beyond the ASCII range, you may wish to instead use the
 134 more customized Unicode properties, "ID_Start", ID_Continue", "XID_Start", and
 135 "XID_Continue".  See L<http://unicode.org/reports/tr31>.
 136
 137 Any character that isn't matched by C<\w> will be matched by C<\W>.
 138
 139 =head3 Whitespace
 140
 141 C<\s> matches any single character that is considered whitespace.  The exact
 142 set of characters matched by C<\s> depends on several factors, detailed
 143 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
 144 indicate a Unicode interpretation, C<\s> matches what is considered
 145 whitespace in the Unicode database; the complete list is in the table
 146 below. Otherwise, if there is a locale or EBCDIC code page in effect,
 147 C<\s> matches whatever is considered whitespace by the current locale or
 148 EBCDIC code page. Without a locale or EBCDIC code page, C<\s> matches
 149 the horizontal tab (C<\t>), the newline (C<\n>), the form feed (C<\f>),
 150 the carriage return (C<\r>), and the space.  (Note that it doesn't match
 151 the vertical tab, C<\cK>.)  Perhaps the most notable possible surprise
 152 is that C<\s> matches a non-breaking space only if a Unicode
 153 interpretation is indicated, or the locale or EBCDIC code page that is
 154 in effect has that character.
 155
 156 Any character that isn't matched by C<\s> will be matched by C<\S>.
 157
 158 C<\h> will match any character that is considered horizontal whitespace;
 159 this includes the space and the tab characters and a number other characters,
 160 all of which are listed in the table below.  C<\H> will match any character
 161 that is not considered horizontal whitespace.
 162
 163 C<\v> will match any character that is considered vertical whitespace;
 164 this includes the carriage return and line feed characters (newline) plus several
 165 other characters, all listed in the table below.
 166 C<\V> will match any character that is not considered vertical whitespace.
 167
 168 C<\R> matches anything that can be considered a newline under Unicode
 169 rules. It's not a character class, as it can match a multi-character
 170 sequence. Therefore, it cannot be used inside a bracketed character
 171 class; use C<\v> instead (vertical whitespace).
 172 Details are discussed in L<perlrebackslash>.
 173
 174 Note that unlike C<\s>, C<\d> and C<\w>, C<\h> and C<\v> always match
 175 the same characters, without regard to other factors, such as if the
 176 source string is in UTF-8 format or not.
 177
 178 One might think that C<\s> is equivalent to C<[\h\v]>. This is not true.  The
 179 vertical tab (C<"\x0b">) is not matched by C<\s>, it is however considered
 180 vertical whitespace. Furthermore, if the source string is not in UTF-8 format,
 181 and any locale or EBCDIC code page that is in effect doesn't include them, the
 182 next line (ASCII-platform C<"\x85">) and the no-break space (ASCII-platform
 183 C<"\xA0">) characters are not matched by C<\s>, but are by C<\v> and C<\h>
 184 respectively.  If the source string is in UTF-8 format, both the next line and
 185 the no-break space are matched by C<\s>.
 186
 187 The following table is a complete listing of characters matched by
 188 C<\s>, C<\h> and C<\v> as of Unicode 5.2.
 189
 190 The first column gives the code point of the character (in hex format),
 191 the second column gives the (Unicode) name. The third column indicates
 192 by which class(es) the character is matched (assuming no locale or EBCDIC code
 193 page is in effect that changes the C<\s> matching).
 194
 195  0x00009        CHARACTER TABULATION   h s
 196  0x0000a              LINE FEED (LF)    vs
 197  0x0000b             LINE TABULATION    v
 198  0x0000c              FORM FEED (FF)    vs
 199  0x0000d        CARRIAGE RETURN (CR)    vs
 200  0x00020                       SPACE   h s
 201  0x00085             NEXT LINE (NEL)    vs  [1]
 202  0x000a0              NO-BREAK SPACE   h s  [1]
 203  0x01680            OGHAM SPACE MARK   h s
 204  0x0180e   MONGOLIAN VOWEL SEPARATOR   h s
 205  0x02000                     EN QUAD   h s
 206  0x02001                     EM QUAD   h s
 207  0x02002                    EN SPACE   h s
 208  0x02003                    EM SPACE   h s
 209  0x02004          THREE-PER-EM SPACE   h s
 210  0x02005           FOUR-PER-EM SPACE   h s
 211  0x02006            SIX-PER-EM SPACE   h s
 212  0x02007                FIGURE SPACE   h s
 213  0x02008           PUNCTUATION SPACE   h s
 214  0x02009                  THIN SPACE   h s
 215  0x0200a                  HAIR SPACE   h s
 216  0x02028              LINE SEPARATOR    vs
 217  0x02029         PARAGRAPH SEPARATOR    vs
 218  0x0202f       NARROW NO-BREAK SPACE   h s
 219  0x0205f   MEDIUM MATHEMATICAL SPACE   h s
 220  0x03000           IDEOGRAPHIC SPACE   h s
 221
 222 =over 4
 223
 224 =item [1]
 225
 226 NEXT LINE and NO-BREAK SPACE only match C<\s> if the source string is in
 227 UTF-8 format, or the locale or EBCDIC code page that is in effect includes them.
 228
 229 =back
 230
 231 It is worth noting that C<\d>, C<\w>, etc, match single characters, not
 232 complete numbers or words. To match a number (that consists of integers),
 233 use C<\d+>; to match a word, use C<\w+>.
 234
 235 =head3 \N
 236
 237 C<\N> is new in 5.12, and is experimental.  It, like the dot, will match any
 238 character that is not a newline. The difference is that C<\N> is not influenced
 239 by the I<single line> regular expression modifier (see L</The dot> above).  Note
 240 that the form C<\N{...}> may mean something completely different.  When the
 241 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
 242 character that many times.  For example, C<\N{3}> means to match 3
 243 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
 244 is not a legal quantifier, it is presumed to be a named character.  See
 245 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
 246 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
 247 names are, respectively, C<COLON>, C<4F>, and C<F4>.
 248
 249 =head3 Unicode Properties
 250
 251 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
 252 Unicode properties.  One letter property names can be used in the C<\pP> form,
 253 with the property name following the C<\p>, otherwise, braces are required.
 254 When using braces, there is a single form, which is just the property name
 255 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
 256 which means to match if the property "name" for the character has the particular
 257 "value".
 258 For instance, a match for a number can be written as C</\pN/> or as
 259 C</\p{Number}/>, or as C</\p{Number=True}/>.
 260 Lowercase letters are matched by the property I<Lowercase_Letter> which
 261 has as short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
 262 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
 263 (the underscores are optional).
 264 C</\pLl/> is valid, but means something different.
 265 It matches a two character string: a letter (Unicode property C<\pL>),
 266 followed by a lowercase C<l>.
 267
 268 For more details, see L<perlunicode/Unicode Character Properties>; for a
 269 complete list of possible properties, see
 270 L<perluniprops/Properties accessible through \p{} and \P{}>.
 271 It is also possible to define your own properties. This is discussed in
 272 L<perlunicode/User-Defined Character Properties>.
 273
 274
 275 =head4 Examples
 276
 277  "a"  =~  /\w/      # Match, "a" is a 'word' character.
 278  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
 279  "a"  =~  /\d/      # No match, "a" isn't a digit.
 280  "7"  =~  /\d/      # Match, "7" is a digit.
 281  " "  =~  /\s/      # Match, a space is whitespace.
 282  "a"  =~  /\D/      # Match, "a" is a non-digit.
 283  "7"  =~  /\D/      # No match, "7" is not a non-digit.
 284  " "  =~  /\S/      # No match, a space is not non-whitespace.
 285
 286  " "  =~  /\h/      # Match, space is horizontal whitespace.
 287  " "  =~  /\v/      # No match, space is not vertical whitespace.
 288  "\r" =~  /\v/      # Match, a return is vertical whitespace.
 289
 290  "a"  =~  /\pL/     # Match, "a" is a letter.
 291  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
 292
 293  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
 294                            # 'THAI CHARACTER SO SO', and that's in
 295                            # Thai Unicode class.
 296  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
 297
 298
 299 =head2 Bracketed Character Classes
 300
 301 The third form of character class you can use in Perl regular expressions
 302 is the bracketed character class.  In its simplest form, it lists the characters
 303 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
 304 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
 305 character classes, exactly one character will be matched. To match
 306 a longer string consisting of characters mentioned in the character
 307 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
 308 instance, C<[aeiou]+> matches a string of one or more lowercase English vowels.
 309
 310 Repeating a character in a character class has no
 311 effect; it's considered to be in the set only once.
 312
 313 Examples:
 314
 315  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
 316  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
 317  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
 318                            # a single character.
 319  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
 320
 321 =head3 Special Characters Inside a Bracketed Character Class
 322
 323 Most characters that are meta characters in regular expressions (that
 324 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
 325 their special meaning and can be used inside a character class without
 326 the need to escape them. For instance, C<[()]> matches either an opening
 327 parenthesis, or a closing parenthesis, and the parens inside the character
 328 class don't group or capture.
 329
 330 Characters that may carry a special meaning inside a character class are:
 331 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
 332 escaped with a backslash, although this is sometimes not needed, in which
 333 case the backslash may be omitted.
 334
 335 The sequence C<\b> is special inside a bracketed character class. While
 336 outside the character class, C<\b> is an assertion indicating a point
 337 that does not have either two word characters or two non-word characters
 338 on either side, inside a bracketed character class, C<\b> matches a
 339 backspace character.
 340
 341 The sequences
 342 C<\a>,
 343 C<\c>,
 344 C<\e>,
 345 C<\f>,
 346 C<\n>,
 347 C<\N{I<NAME>}>,
 348 C<\N{U+I<wide hex char>}>,
 349 C<\r>,
 350 C<\t>,
 351 and
 352 C<\x>
 353 are also special and have the same meanings as they do outside a
 354 bracketed character class.  (However, inside a bracketed character
 355 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
 356 one in the sequence is used, with a warning.)
 357
 358 Also, a backslash followed by two or three octal digits is considered an octal
 359 number.
 360
 361 A C<[> is not special inside a character class, unless it's the start of a
 362 POSIX character class (see L</POSIX Character Classes> below). It normally does
 363 not need escaping.
 364
 365 A C<]> is normally either the end of a POSIX character class (see
 366 L</POSIX Character Classes> below), or it signals the end of the bracketed
 367 character class.  If you want to include a C<]> in the set of characters, you
 368 must generally escape it.
 369 However, if the C<]> is the I<first> (or the second if the first
 370 character is a caret) character of a bracketed character class, it
 371 does not denote the end of the class (as you cannot have an empty class)
 372 and is considered part of the set of characters that can be matched without
 373 escaping.
 374
 375 Examples:
 376
 377  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
 378  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
 379                       #  is equivalent to a backspace.
 380  "]"   =~ /[][]/      #  Match, as the character class contains.
 381                       #  both [ and ].
 382  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
 383                       #  containing just ], and the character class is
 384                       #  followed by a ].
 385
 386 =head3 Character Ranges
 387
 388 It is not uncommon to want to match a range of characters. Luckily, instead
 389 of listing all the characters in the range, one may use the hyphen (C<->).
 390 If inside a bracketed character class you have two characters separated
 391 by a hyphen, it's treated as if all the characters between the two are in
 392 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
 393 matches any lowercase letter from the first half of the ASCII alphabet.
 394
 395 Note that the two characters on either side of the hyphen are not
 396 necessary both letters or both digits. Any character is possible,
 397 although not advisable.  C<['-?]> contains a range of characters, but
 398 most people will not know which characters that will be. Furthermore,
 399 such ranges may lead to portability problems if the code has to run on
 400 a platform that uses a different character set, such as EBCDIC.
 401
 402 If a hyphen in a character class cannot syntactically be part of a range, for
 403 instance because it is the first or the last character of the character class,
 404 or if it immediately follows a range, the hyphen isn't special, and will be
 405 considered a character that is to be matched literally. You have to escape the
 406 hyphen with a backslash if you want to have a hyphen in your set of characters
 407 to be matched, and its position in the class is such that it could be
 408 considered part of a range.
 409
 410 Examples:
 411
 412  [a-z]       #  Matches a character that is a lower case ASCII letter.
 413  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
 414              #  the letter 'z'.
 415  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
 416  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
 417              #  hyphen ('-'), or the letter 'm'.
 418  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
 419              #  (But not on an EBCDIC platform).
 420
 421
 422 =head3 Negation
 423
 424 It is also possible to instead list the characters you do not want to
 425 match. You can do so by using a caret (C<^>) as the first character in the
 426 character class. For instance, C<[^a-z]> matches a character that is not a
 427 lowercase ASCII letter.
 428
 429 This syntax make the caret a special character inside a bracketed character
 430 class, but only if it is the first character of the class. So if you want
 431 to have the caret as one of the characters you want to match, you either
 432 have to escape the caret, or not list it first.
 433
 434 Examples:
 435
 436  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
 437  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
 438  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
 439  "^"  =~  /[x^]/       #  Match, caret is not special here.
 440
 441 =head3 Backslash Sequences
 442
 443 You can put any backslash sequence character class (with the exception of
 444 C<\N>) inside a bracketed character class, and it will act just
 445 as if you put all the characters matched by the backslash sequence inside the
 446 character class. For instance, C<[a-f\d]> will match any decimal digit, or any
 447 of the lowercase letters between 'a' and 'f' inclusive.
 448
 449 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
 450 or C<\N{U+I<wide hex char>}>, and NOT be the form that matches non-newlines,
 451 for the same reason that a dot C<.> inside a bracketed character class loses
 452 its special meaning: it matches nearly anything, which generally isn't what you
 453 want to happen.
 454
 455
 456 Examples:
 457
 458  /[\p{Thai}\d]/     # Matches a character that is either a Thai
 459                     # character, or a digit.
 460  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
 461                     # character, nor a parenthesis.
 462
 463 Backslash sequence character classes cannot form one of the endpoints
 464 of a range.  Thus, you can't say:
 465
 466  /[\p{Thai}-\d]/     # Wrong!
 467
 468 =head3 POSIX Character Classes
 469 X<character class> X<\p> X<\p{}>
 470 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
 471 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
 472
 473 POSIX character classes have the form C<[:class:]>, where I<class> is
 474 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
 475 I<inside> bracketed character classes, and are a convenient and descriptive
 476 way of listing a group of characters, though they currently suffer from
 477 portability issues (see below and L<Locale, EBCDIC, Unicode and UTF-8>).
 478
 479 Be careful about the syntax,
 480
 481  # Correct:
 482  $string =~ /[[:alpha:]]/
 483
 484  # Incorrect (will warn):
 485  $string =~ /[:alpha:]/
 486
 487 The latter pattern would be a character class consisting of a colon,
 488 and the letters C<a>, C<l>, C<p> and C<h>.
 489 POSIX character classes can be part of a larger bracketed character class.  For
 490 example,
 491
 492  [01[:alpha:]%]
 493
 494 is valid and matches '0', '1', any alphabetic character, and the percent sign.
 495
 496 Perl recognizes the following POSIX character classes:
 497
 498  alpha  Any alphabetical character ("[A-Za-z]").
 499  alnum  Any alphanumerical character. ("[A-Za-z0-9]")
 500  ascii  Any character in the ASCII character set.
 501  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
 502  cntrl  Any control character.  See Note [2] below.
 503  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
 504  graph  Any printable character, excluding a space.  See Note [3] below.
 505  lower  Any lowercase character ("[a-z]").
 506  print  Any printable character, including a space.  See Note [4] below.
 507  punct  Any graphical character excluding "word" characters.  Note [5].
 508  space  Any whitespace character. "\s" plus the vertical tab ("\cK").
 509  upper  Any uppercase character ("[A-Z]").
 510  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
 511  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
 512
 513 Most POSIX character classes have two Unicode-style C<\p> property
 514 counterparts.  (They are not official Unicode properties, but Perl extensions
 515 derived from official Unicode properties.)  The table below shows the relation
 516 between POSIX character classes and these counterparts.
 517
 518 One counterpart, in the column labelled "ASCII-range Unicode" in
 519 the table, will only match characters in the ASCII character set.
 520
 521 The other counterpart, in the column labelled "Full-range Unicode", matches any
 522 appropriate characters in the full Unicode character set.  For example,
 523 C<\p{Alpha}> will match not just the ASCII alphabetic characters, but any
 524 character in the entire Unicode character set that is considered to be
 525 alphabetic.
 526
 527 (Each of the counterparts has various synonyms as well.
 528 L<perluniprops/Properties accessible through \p{} and \P{}> lists all the
 529 synonyms, plus all the characters matched by each of the ASCII-range
 530 properties.  For example C<\p{AHex}> is a synonym for C<\p{ASCII_Hex_Digit}>,
 531 and any C<\p> property name can be prefixed with "Is" such as C<\p{IsAlpha}>.)
 532
 533 Both the C<\p> forms are unaffected by any locale that is in effect, or whether
 534 the string is in UTF-8 format or not, or whether the platform is EBCDIC or not.
 535 In contrast, the POSIX character classes are affected.  If the source string is
 536 in UTF-8 format, the POSIX classes (with the exception of C<[[:punct:]]>, see
 537 Note [5] below) behave like their "Full-range" Unicode counterparts.  If the
 538 source string is not in UTF-8 format, and no locale is in effect, and the
 539 platform is not EBCDIC, all the POSIX classes behave like their ASCII-range
 540 counterparts.  Otherwise, they behave based on the rules of the locale or
 541 EBCDIC code page.
 542
 543 It is proposed to change this behavior in a future release of Perl so that the
 544 the UTF8ness of the source string will be irrelevant to the behavior of the
 545 POSIX character classes.  This means they will always behave in strict
 546 accordance with the official POSIX standard.  That is, if either locale or
 547 EBCDIC code page is present, they will behave in accordance with those; if
 548 absent, the classes will match only their ASCII-range counterparts.  If you
 549 disagree with this proposal, send email to C<perl5-porters@perl.org>.
 550
 551  [[:...:]]      ASCII-range        Full-range  backslash  Note
 552                  Unicode            Unicode    sequence
 553  -----------------------------------------------------
 554    alpha      \p{PosixAlpha}       \p{Alpha}
 555    alnum      \p{PosixAlnum}       \p{Alnum}
 556    ascii      \p{ASCII}
 557    blank      \p{PosixBlank}       \p{Blank} =             [1]
 558                                    \p{HorizSpace}  \h      [1]
 559    cntrl      \p{PosixCntrl}       \p{Cntrl}               [2]
 560    digit      \p{PosixDigit}       \p{Digit}       \d
 561    graph      \p{PosixGraph}       \p{Graph}               [3]
 562    lower      \p{PosixLower}       \p{Lower}
 563    print      \p{PosixPrint}       \p{Print}               [4]
 564    punct      \p{PosixPunct}       \p{Punct}               [5]
 565               \p{PerlSpace}        \p{SpacePerl}   \s      [6]
 566    space      \p{PosixSpace}       \p{Space}               [6]
 567    upper      \p{PosixUpper}       \p{Upper}
 568    word       \p{PerlWord}         \p{Word}        \w
 569    xdigit     \p{ASCII_Hex_Digit}  \p{XDigit}
 570
 571 =over 4
 572
 573 =item [1]
 574
 575 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
 576
 577 =item [2]
 578
 579 Control characters don't produce output as such, but instead usually control
 580 the terminal somehow: for example newline and backspace are control characters.
 581 In the ASCII range, characters whose ordinals are between 0 and 31 inclusive,
 582 plus 127 (C<DEL>) are control characters.
 583
 584 On EBCDIC platforms, it is likely that the code page will define C<[[:cntrl:]]>
 585 to be the EBCDIC equivalents of the ASCII controls, plus the controls
 586 that in Unicode have ordinals from 128 through 159.
 587
 588 =item [3]
 589
 590 Any character that is I<graphical>, that is, visible. This class consists
 591 of all the alphanumerical characters and all punctuation characters.
 592
 593 =item [4]
 594
 595 All printable characters, which is the set of all the graphical characters
 596 plus whitespace characters that are not also controls.
 597
 598 =item [5]
 599
 600 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all the
 601 non-controls, non-alphanumeric, non-space characters:
 602 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
 603 it could alter the behavior of C<[[:punct:]]>).
 604
 605 C<\p{Punct}> matches a somewhat different set in the ASCII range, namely
 606 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing C<[$+E<lt>=E<gt>^`|~]>.
 607 This is because Unicode splits what POSIX considers to be punctuation into two
 608 categories, Punctuation and Symbols.
 609
 610 When the matching string is in UTF-8 format, C<[[:punct:]]> matches what it
 611 matches in the ASCII range, plus what C<\p{Punct}> matches.  This is different
 612 than strictly matching according to C<\p{Punct}>.  Another way to say it is that
 613 for a UTF-8 string, C<[[:punct:]]> matches all the characters that Unicode
 614 considers to be punctuation, plus all the ASCII-range characters that Unicode
 615 considers to be symbols.
 616
 617 =item [6]
 618
 619 C<\p{SpacePerl}> and C<\p{Space}> differ only in that C<\p{Space}> additionally
 620 matches the vertical tab, C<\cK>.   Same for the two ASCII-only range forms.
 621
 622 =back
 623
 624 =head4 Negation
 625 X<character class, negation>
 626
 627 A Perl extension to the POSIX character class is the ability to
 628 negate it. This is done by prefixing the class name with a caret (C<^>).
 629 Some examples:
 630
 631      POSIX         ASCII-range     Full-range  backslash
 632                     Unicode         Unicode    sequence
 633  -----------------------------------------------------
 634  [[:^digit:]]   \P{PosixDigit}     \P{Digit}      \D
 635  [[:^space:]]   \P{PosixSpace}     \P{Space}
 636                 \P{PerlSpace}      \P{SpacePerl}  \S
 637  [[:^word:]]    \P{PerlWord}       \P{Word}       \W
 638
 639 =head4 [= =] and [. .]
 640
 641 Perl will recognize the POSIX character classes C<[=class=]>, and
 642 C<[.class.]>, but does not (yet?) support them.  Use of
 643 such a construct will lead to an error.
 644
 645
 646 =head4 Examples
 647
 648  /[[:digit:]]/            # Matches a character that is a digit.
 649  /[01[:lower:]]/          # Matches a character that is either a
 650                           # lowercase letter, or '0' or '1'.
 651  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
 652                           # except the letters 'a' to 'f'.  This is
 653                           # because the main character class is composed
 654                           # of two POSIX character classes that are ORed
 655                           # together, one that matches any digit, and
 656                           # the other that matches anything that isn't a
 657                           # hex digit.  The result matches all
 658                           # characters except the letters 'a' to 'f' and
 659                           # 'A' to 'F'.
 660
 661
 662 =head2 Locale, EBCDIC, Unicode and UTF-8
 663
 664 Some of the character classes have a somewhat different behaviour depending
 665 on the internal encoding of the source string, if the regular expression
 666 is marked as having Unicode semantics, the locale that is in effect,
 667 and if the program is running on an EBCDIC platform.
 668
 669 C<\w>, C<\d>, C<\s> and the POSIX character classes (and their negations,
 670 including C<\W>, C<\D>, C<\S>) have this behaviour.  (Since the backslash
 671 sequences C<\b> and C<\B> are defined in terms of C<\w> and C<\W>, they also are
 672 affected.)
 673
 674 The rule is that if the source string is in UTF-8 format or the regular
 675 expression is marked as indicating Unicode semantics (see the next
 676 paragraph), the character classes match according to the Unicode
 677 properties.  Otherwise, the character classes match according to
 678 whatever locale or EBCDIC code page is in effect. If there is no locale
 679 nor EBCDIC, they match the ASCII defaults (0 to 9 for C<\d>; 52 letters,
 680 10 digits and underscore for C<\w>; etc.).
 681
 682 A regular expression is marked for Unicode semantics if it is encoded in
 683 utf8 (usually as a result of including a literal character whose code
 684 point is above 255), or if it contains a C<\N{U+...}> or C<\N{I<name>}>
 685 construct, or (starting in Perl 5.14) if it was compiled in the scope of a
 686 C<S<use feature "unicode_strings">> pragma, or has the C<"u"> regular
 687 expression modifier.
 688
 689 The differences in behavior between locale and non-locale semantics
 690 can affect any character whose code point is 255 or less.  The
 691 differences in behavior between Unicode and non-Unicode semantics
 692 affects only ASCII platforms, and only when matching against characters
 693 whose code points are between 128 and 255 inclusive.  See
 694 L<perlunicode/The "Unicode Bug">.
 695
 696 For portability reasons, it may be better to not use C<\w>, C<\d>, C<\s>
 697 or the POSIX character classes, and use the Unicode properties instead.
 698 That way you can control whether you want matching of just characters in
 699 the ASCII character set, or any Unicode characters.
 700 C<S<use feature "unicode_strings">> will allow seamless Unicode behavior
 701 no matter what the internal encodings are, but won't allow restricting
 702 to just the ASCII characters.
 703
 704 =head4 Examples
 705
 706  $str =  "\xDF";      # $str is not in UTF-8 format.
 707  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
 708  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
 709  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
 710  chop $str;
 711  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
 712
 713 =cut