This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
5.004_56: patch for `use Fatal' again
[perl5.git] / pod / perlfunc.pod
1
2 =head1 NAME
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar and list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one list argument.)  For instance, splice() has three scalar
20 arguments followed by a list.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 For functions that can be used in either a scalar or list context,
52 nonabortive failure is generally indicated in a scalar context by
53 returning the undefined value, and in a list context by returning the
54 null list.
55
56 Remember the following rule:
57
58 =over 8
59
60 =item  I<THERE IS NO GENERAL RULE FOR CONVERTING A LIST INTO A SCALAR!>
61
62 =back
63
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in a scalar context.  Some operators return the
66 length of the list that would have been returned in a list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 =head2 Perl Functions by Category
73
74 Here are Perl's functions (including things that look like
75 functions, like some of the keywords and named operators)
76 arranged by category.  Some functions appear in more
77 than one place.
78
79 =over
80
81 =item Functions for SCALARs or strings
82
83 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
84 C<length>, C<oct>, C<ord>, C<pack>, C<q>/STRING/, C<qq>/STRING/, C<reverse>,
85 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y>///
86
87 =item Regular expressions and pattern matching
88
89 C<m>//, C<pos>, C<quotemeta>, C<s>///, C<split>, C<study>
90
91 =item Numeric functions
92
93 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
94 C<sin>, C<sqrt>, C<srand>
95
96 =item Functions for real @ARRAYs
97
98 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
99
100 =item Functions for list data
101
102 C<grep>, C<join>, C<map>, C<qw>/STRING/, C<reverse>, C<sort>, C<unpack>
103
104 =item Functions for real %HASHes
105
106 C<delete>, C<each>, C<exists>, C<keys>, C<values>
107
108 =item Input and output functions
109
110 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
111 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
112 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
113 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
114 C<warn>, C<write>
115
116 =item Functions for fixed length data or records
117
118 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
119
120 =item Functions for filehandles, files, or directories
121
122 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
123 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>, C<readlink>,
124 C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>, C<unlink>, C<utime>
125
126 =item Keywords related to the control flow of your perl program
127
128 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
129 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
130
131 =item Keywords related to scoping
132
133 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
134
135 =item Miscellaneous functions
136
137 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
138 C<scalar>, C<undef>, C<wantarray>
139
140 =item Functions for processes and process groups
141
142 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
143 C<pipe>, C<qx>/STRING/, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
144 C<times>, C<wait>, C<waitpid>
145
146 =item Keywords related to perl modules
147
148 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
149
150 =item Keywords related to classes and object-orientedness
151
152 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
153 C<untie>, C<use>
154
155 =item Low-level socket functions
156
157 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
158 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
159 C<socket>, C<socketpair>
160
161 =item System V interprocess communication functions
162
163 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
164 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
165
166 =item Fetching user and group info
167
168 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
169 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
170 C<getpwuid>, C<setgrent>, C<setpwent>
171
172 =item Fetching network info
173
174 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
175 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
176 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
177 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
178 C<setnetent>, C<setprotoent>, C<setservent>
179
180 =item Time-related functions
181
182 C<gmtime>, C<localtime>, C<time>, C<times>
183
184 =item Functions new in perl5
185
186 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
187 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
188 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
189 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
190
191 * - C<sub> was a keyword in perl4, but in perl5 it is an
192 operator which can be used in expressions.
193
194 =item Functions obsoleted in perl5
195
196 C<dbmclose>, C<dbmopen>
197
198 =back
199
200 =head2 Alphabetical Listing of Perl Functions
201
202 =over 8
203
204 =item I<-X> FILEHANDLE
205
206 =item I<-X> EXPR
207
208 =item I<-X>
209
210 A file test, where X is one of the letters listed below.  This unary
211 operator takes one argument, either a filename or a filehandle, and
212 tests the associated file to see if something is true about it.  If the
213 argument is omitted, tests $_, except for C<-t>, which tests STDIN.
214 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
215 the undefined value if the file doesn't exist.  Despite the funny
216 names, precedence is the same as any other named unary operator, and
217 the argument may be parenthesized like any other unary operator.  The
218 operator may be any of:
219
220     -r  File is readable by effective uid/gid.
221     -w  File is writable by effective uid/gid.
222     -x  File is executable by effective uid/gid.
223     -o  File is owned by effective uid.
224
225     -R  File is readable by real uid/gid.
226     -W  File is writable by real uid/gid.
227     -X  File is executable by real uid/gid.
228     -O  File is owned by real uid.
229
230     -e  File exists.
231     -z  File has zero size.
232     -s  File has nonzero size (returns size).
233
234     -f  File is a plain file.
235     -d  File is a directory.
236     -l  File is a symbolic link.
237     -p  File is a named pipe (FIFO).
238     -S  File is a socket.
239     -b  File is a block special file.
240     -c  File is a character special file.
241     -t  Filehandle is opened to a tty.
242
243     -u  File has setuid bit set.
244     -g  File has setgid bit set.
245     -k  File has sticky bit set.
246
247     -T  File is a text file.
248     -B  File is a binary file (opposite of -T).
249
250     -M  Age of file in days when script started.
251     -A  Same for access time.
252     -C  Same for inode change time.
253
254 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
255 C<-W>, C<-x>, and C<-X> is based solely on the mode of the file and the
256 uids and gids of the user.  There may be other reasons you can't actually
257 read, write or execute the file.  Also note that, for the superuser,
258 C<-r>, C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return
259 1 if any execute bit is set in the mode.  Scripts run by the superuser may
260 thus need to do a stat() to determine the actual mode of the
261 file, or temporarily set the uid to something else.
262
263 Example:
264
265     while (<>) {
266         chop;
267         next unless -f $_;      # ignore specials
268         ...
269     }
270
271 Note that C<-s/a/b/> does not do a negated substitution.  Saying
272 C<-exp($foo)> still works as expected, however--only single letters
273 following a minus are interpreted as file tests.
274
275 The C<-T> and C<-B> switches work as follows.  The first block or so of the
276 file is examined for odd characters such as strange control codes or
277 characters with the high bit set.  If too many odd characters (E<gt>30%)
278 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
279 containing null in the first block is considered a binary file.  If C<-T>
280 or C<-B> is used on a filehandle, the current stdio buffer is examined
281 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
282 file, or a file at EOF when testing a filehandle.  Because you have to
283 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
284 against the file first, as in C<next unless -f $file && -T $file>.
285
286 If any of the file tests (or either the stat() or lstat() operators) are given
287 the special filehandle consisting of a solitary underline, then the stat
288 structure of the previous file test (or stat operator) is used, saving
289 a system call.  (This doesn't work with C<-t>, and you need to remember
290 that lstat() and C<-l> will leave values in the stat structure for the
291 symbolic link, not the real file.)  Example:
292
293     print "Can do.\n" if -r $a || -w _ || -x _;
294
295     stat($filename);
296     print "Readable\n" if -r _;
297     print "Writable\n" if -w _;
298     print "Executable\n" if -x _;
299     print "Setuid\n" if -u _;
300     print "Setgid\n" if -g _;
301     print "Sticky\n" if -k _;
302     print "Text\n" if -T _;
303     print "Binary\n" if -B _;
304
305 =item abs VALUE
306
307 =item abs
308
309 Returns the absolute value of its argument.
310 If VALUE is omitted, uses $_.
311
312 =item accept NEWSOCKET,GENERICSOCKET
313
314 Accepts an incoming socket connect, just as the accept(2) system call
315 does.  Returns the packed address if it succeeded, FALSE otherwise.
316 See example in L<perlipc/"Sockets: Client/Server Communication">.
317
318 =item alarm SECONDS
319
320 =item alarm
321
322 Arranges to have a SIGALRM delivered to this process after the
323 specified number of seconds have elapsed.  If SECONDS is not specified,
324 the value stored in $_ is used. (On some machines,
325 unfortunately, the elapsed time may be up to one second less than you
326 specified because of how seconds are counted.)  Only one timer may be
327 counting at once.  Each call disables the previous timer, and an
328 argument of 0 may be supplied to cancel the previous timer without
329 starting a new one.  The returned value is the amount of time remaining
330 on the previous timer.
331
332 For delays of finer granularity than one second, you may use Perl's
333 syscall() interface to access setitimer(2) if your system supports it,
334 or else see L</select()>.  It is usually a mistake to intermix alarm()
335 and sleep() calls.
336
337 If you want to use alarm() to time out a system call you need to use an
338 eval/die pair.  You can't rely on the alarm causing the system call to
339 fail with $! set to EINTR because Perl sets up signal handlers to
340 restart system calls on some systems.  Using eval/die always works.
341
342     eval {
343         local $SIG{ALRM} = sub { die "alarm\n" };       # NB \n required
344         alarm $timeout;
345         $nread = sysread SOCKET, $buffer, $size;
346         alarm 0;
347     };
348     die if $@ && $@ ne "alarm\n";       # propagate errors
349     if ($@) {
350         # timed out
351     }
352     else {
353         # didn't
354     }
355
356 =item atan2 Y,X
357
358 Returns the arctangent of Y/X in the range -PI to PI.
359
360 For the tangent operation, you may use the POSIX::tan()
361 function, or use the familiar relation:
362
363     sub tan { sin($_[0]) / cos($_[0])  }
364
365 =item bind SOCKET,NAME
366
367 Binds a network address to a socket, just as the bind system call
368 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
369 packed address of the appropriate type for the socket.  See the examples in
370 L<perlipc/"Sockets: Client/Server Communication">.
371
372 =item binmode FILEHANDLE
373
374 Arranges for the file to be read or written in "binary" mode in operating
375 systems that distinguish between binary and text files.  Files that are
376 not in binary mode have CR LF sequences translated to LF on input and LF
377 translated to CR LF on output.  Binmode has no effect under Unix; in MS-DOS
378 and similarly archaic systems, it may be imperative--otherwise your
379 MS-DOS-damaged C library may mangle your file.  The key distinction between
380 systems that need binmode and those that don't is their text file
381 formats.  Systems like Unix and Plan9 that delimit lines with a single
382 character, and that encode that character in C as '\n', do not need
383 C<binmode>.  The rest need it.  If FILEHANDLE is an expression, the value
384 is taken as the name of the filehandle.
385
386 =item bless REF,CLASSNAME
387
388 =item bless REF
389
390 This function tells the thingy referenced by REF that it is now
391 an object in the CLASSNAME package--or the current package if no CLASSNAME
392 is specified, which is often the case.  It returns the reference for
393 convenience, because a bless() is often the last thing in a constructor.
394 Always use the two-argument version if the function doing the blessing
395 might be inherited by a derived class.  See L<perlobj> for more about the
396 blessing (and blessings) of objects.
397
398 =item caller EXPR
399
400 =item caller
401
402 Returns the context of the current subroutine call.  In a scalar context,
403 returns the caller's package name if there is a caller, that is, if
404 we're in a subroutine or eval() or require(), and the undefined value
405 otherwise.  In a list context, returns
406
407     ($package, $filename, $line) = caller;
408
409 With EXPR, it returns some extra information that the debugger uses to
410 print a stack trace.  The value of EXPR indicates how many call frames
411 to go back before the current one.
412
413     ($package, $filename, $line, $subroutine,
414      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
415
416 Here $subroutine may be C<"(eval)"> if the frame is not a subroutine
417 call, but an C<eval>.  In such a case additional elements $evaltext and
418 $is_require are set: $is_require is true if the frame is created by a
419 C<require> or C<use> statement, $evaltext contains the text of the
420 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
421 $filename is C<"(eval)">, but $evaltext is undefined.  (Note also that
422 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
423 frame.
424
425 Furthermore, when called from within the DB package, caller returns more
426 detailed information: it sets the list variable @DB::args to be the
427 arguments with which the subroutine was invoked.
428
429 =item chdir EXPR
430
431 Changes the working directory to EXPR, if possible.  If EXPR is
432 omitted, changes to home directory.  Returns TRUE upon success, FALSE
433 otherwise.  See example under die().
434
435 =item chmod LIST
436
437 Changes the permissions of a list of files.  The first element of the
438 list must be the numerical mode, which should probably be an octal
439 number, and which definitely should I<not> a string of octal digits:
440 C<0644> is okay, C<'0644'> is not.  Returns the number of files
441 successfully changed.  See also L</oct>, if all you have is a string.
442
443     $cnt = chmod 0755, 'foo', 'bar';
444     chmod 0755, @executables;
445     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to --w----r-T
446     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
447     $mode = 0644;   chmod $mode, 'foo';      # this is best
448
449 =item chomp VARIABLE
450
451 =item chomp LIST
452
453 =item chomp
454
455 This is a slightly safer version of L</chop>.  It removes any
456 line ending that corresponds to the current value of C<$/> (also known as
457 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
458 number of characters removed from all its arguments.  It's often used to
459 remove the newline from the end of an input record when you're worried
460 that the final record may be missing its newline.  When in paragraph mode
461 (C<$/ = "">), it removes all trailing newlines from the string.  If
462 VARIABLE is omitted, it chomps $_.  Example:
463
464     while (<>) {
465         chomp;  # avoid \n on last field
466         @array = split(/:/);
467         ...
468     }
469
470 You can actually chomp anything that's an lvalue, including an assignment:
471
472     chomp($cwd = `pwd`);
473     chomp($answer = <STDIN>);
474
475 If you chomp a list, each element is chomped, and the total number of
476 characters removed is returned.
477
478 =item chop VARIABLE
479
480 =item chop LIST
481
482 =item chop
483
484 Chops off the last character of a string and returns the character
485 chopped.  It's used primarily to remove the newline from the end of an
486 input record, but is much more efficient than C<s/\n//> because it neither
487 scans nor copies the string.  If VARIABLE is omitted, chops $_.
488 Example:
489
490     while (<>) {
491         chop;   # avoid \n on last field
492         @array = split(/:/);
493         ...
494     }
495
496 You can actually chop anything that's an lvalue, including an assignment:
497
498     chop($cwd = `pwd`);
499     chop($answer = <STDIN>);
500
501 If you chop a list, each element is chopped.  Only the value of the
502 last chop is returned.
503
504 Note that chop returns the last character.  To return all but the last
505 character, use C<substr($string, 0, -1)>.
506
507 =item chown LIST
508
509 Changes the owner (and group) of a list of files.  The first two
510 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
511 Returns the number of files successfully changed.
512
513     $cnt = chown $uid, $gid, 'foo', 'bar';
514     chown $uid, $gid, @filenames;
515
516 Here's an example that looks up nonnumeric uids in the passwd file:
517
518     print "User: ";
519     chop($user = <STDIN>);
520     print "Files: "
521     chop($pattern = <STDIN>);
522
523     ($login,$pass,$uid,$gid) = getpwnam($user)
524         or die "$user not in passwd file";
525
526     @ary = <${pattern}>;        # expand filenames
527     chown $uid, $gid, @ary;
528
529 On most systems, you are not allowed to change the ownership of the
530 file unless you're the superuser, although you should be able to change
531 the group to any of your secondary groups.  On insecure systems, these
532 restrictions may be relaxed, but this is not a portable assumption.
533
534 =item chr NUMBER
535
536 =item chr
537
538 Returns the character represented by that NUMBER in the character set.
539 For example, C<chr(65)> is "A" in ASCII.  For the reverse, use L</ord>.
540
541 If NUMBER is omitted, uses $_.
542
543 =item chroot FILENAME
544
545 =item chroot
546
547 This function works as the system call by the same name: it makes the
548 named directory the new root directory for all further pathnames that
549 begin with a "/" by your process and all of its children.  (It doesn't
550 change your current working directory, which is unaffected.)  For security
551 reasons, this call is restricted to the superuser.  If FILENAME is
552 omitted, does chroot to $_.
553
554 =item close FILEHANDLE
555
556 Closes the file or pipe associated with the file handle, returning TRUE
557 only if stdio successfully flushes buffers and closes the system file
558 descriptor.
559
560 You don't have to close FILEHANDLE if you are immediately going to do
561 another open() on it, because open() will close it for you.  (See
562 open().)  However, an explicit close on an input file resets the line
563 counter ($.), while the implicit close done by open() does not.
564
565 If the file handle came from a piped open C<close> will additionally
566 return FALSE if one of the other system calls involved fails or if the
567 program exits with non-zero status.  (If the only problem was that the
568 program exited non-zero $! will be set to 0.) Also, closing a pipe will
569 wait for the process executing on the pipe to complete, in case you
570 want to look at the output of the pipe afterwards.  Closing a pipe
571 explicitly also puts the exit status value of the command into C<$?>.
572 Example:
573
574     open(OUTPUT, '|sort >foo')  # pipe to sort
575         or die "Can't start sort: $!";
576     ...                         # print stuff to output
577     close OUTPUT                # wait for sort to finish
578         or warn $! ? "Error closing sort pipe: $!"
579                    : "Exit status $? from sort";
580     open(INPUT, 'foo')          # get sort's results
581         or die "Can't open 'foo' for input: $!";
582
583 FILEHANDLE may be an expression whose value gives the real filehandle name.
584
585 =item closedir DIRHANDLE
586
587 Closes a directory opened by opendir().
588
589 =item connect SOCKET,NAME
590
591 Attempts to connect to a remote socket, just as the connect system call
592 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
593 packed address of the appropriate type for the socket.  See the examples in
594 L<perlipc/"Sockets: Client/Server Communication">.
595
596 =item continue BLOCK
597
598 Actually a flow control statement rather than a function.  If there is a
599 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
600 C<foreach>), it is always executed just before the conditional is about to
601 be evaluated again, just like the third part of a C<for> loop in C.  Thus
602 it can be used to increment a loop variable, even when the loop has been
603 continued via the C<next> statement (which is similar to the C C<continue>
604 statement).
605
606 =item cos EXPR
607
608 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted
609 takes cosine of $_.
610
611 For the inverse cosine operation, you may use the POSIX::acos()
612 function, or use this relation:
613
614     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
615
616 =item crypt PLAINTEXT,SALT
617
618 Encrypts a string exactly like the crypt(3) function in the C library
619 (assuming that you actually have a version there that has not been
620 extirpated as a potential munition).  This can prove useful for checking
621 the password file for lousy passwords, amongst other things.  Only the
622 guys wearing white hats should do this.
623
624 Note that crypt is intended to be a one-way function, much like breaking
625 eggs to make an omelette.  There is no (known) corresponding decrypt
626 function.  As a result, this function isn't all that useful for
627 cryptography.  (For that, see your nearby CPAN mirror.)
628
629 Here's an example that makes sure that whoever runs this program knows
630 their own password:
631
632     $pwd = (getpwuid($<))[1];
633     $salt = substr($pwd, 0, 2);
634
635     system "stty -echo";
636     print "Password: ";
637     chop($word = <STDIN>);
638     print "\n";
639     system "stty echo";
640
641     if (crypt($word, $salt) ne $pwd) {
642         die "Sorry...\n";
643     } else {
644         print "ok\n";
645     }
646
647 Of course, typing in your own password to whoever asks you
648 for it is unwise.
649
650 =item dbmclose HASH
651
652 [This function has been superseded by the untie() function.]
653
654 Breaks the binding between a DBM file and a hash.
655
656 =item dbmopen HASH,DBNAME,MODE
657
658 [This function has been superseded by the tie() function.]
659
660 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(), or Berkeley DB file to a
661 hash.  HASH is the name of the hash.  (Unlike normal open, the first
662 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
663 is the name of the database (without the F<.dir> or F<.pag> extension if
664 any).  If the database does not exist, it is created with protection
665 specified by MODE (as modified by the umask()).  If your system supports
666 only the older DBM functions, you may perform only one dbmopen() in your
667 program.  In older versions of Perl, if your system had neither DBM nor
668 ndbm, calling dbmopen() produced a fatal error; it now falls back to
669 sdbm(3).
670
671 If you don't have write access to the DBM file, you can only read hash
672 variables, not set them.  If you want to test whether you can write,
673 either use file tests or try setting a dummy hash entry inside an eval(),
674 which will trap the error.
675
676 Note that functions such as keys() and values() may return huge array
677 values when used on large DBM files.  You may prefer to use the each()
678 function to iterate over large DBM files.  Example:
679
680     # print out history file offsets
681     dbmopen(%HIST,'/usr/lib/news/history',0666);
682     while (($key,$val) = each %HIST) {
683         print $key, ' = ', unpack('L',$val), "\n";
684     }
685     dbmclose(%HIST);
686
687 See also L<AnyDBM_File> for a more general description of the pros and
688 cons of the various dbm approaches, as well as L<DB_File> for a particularly
689 rich implementation.
690
691 =item defined EXPR
692
693 =item defined
694
695 Returns a Boolean value telling whether EXPR has a value other than
696 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
697 checked.
698
699 Many operations return C<undef> to indicate failure, end of file,
700 system error, uninitialized variable, and other exceptional
701 conditions.  This function allows you to distinguish C<undef> from
702 other values.  (A simple Boolean test will not distinguish among
703 C<undef>, zero, the empty string, and "0", which are all equally
704 false.)  Note that since C<undef> is a valid scalar, its presence
705 doesn't I<necessarily> indicate an exceptional condition: pop()
706 returns C<undef> when its argument is an empty array, I<or> when the
707 element to return happens to be C<undef>.
708
709 You may also use defined() to check whether a subroutine exists.  On
710 the other hand, use of defined() upon aggregates (hashes and arrays)
711 is not guaranteed to produce intuitive results, and should probably be
712 avoided.
713
714 When used on a hash element, it tells you whether the value is defined,
715 not whether the key exists in the hash.  Use L</exists> for the latter
716 purpose.
717
718 Examples:
719
720     print if defined $switch{'D'};
721     print "$val\n" while defined($val = pop(@ary));
722     die "Can't readlink $sym: $!"
723         unless defined($value = readlink $sym);
724     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
725     $debugging = 0 unless defined $debugging;
726
727 Note:  Many folks tend to overuse defined(), and then are surprised to
728 discover that the number 0 and "" (the zero-length string) are, in fact,
729 defined values.  For example, if you say
730
731     "ab" =~ /a(.*)b/;
732
733 the pattern match succeeds, and $1 is defined, despite the fact that it
734 matched "nothing".  But it didn't really match nothing--rather, it
735 matched something that happened to be 0 characters long.  This is all
736 very above-board and honest.  When a function returns an undefined value,
737 it's an admission that it couldn't give you an honest answer.  So you
738 should use defined() only when you're questioning the integrity of what
739 you're trying to do.  At other times, a simple comparison to 0 or "" is
740 what you want.
741
742 Currently, using defined() on an entire array or hash reports whether
743 memory for that aggregate has ever been allocated.  So an array you set
744 to the empty list appears undefined initially, and one that once was full
745 and that you then set to the empty list still appears defined.  You
746 should instead use a simple test for size:
747
748     if (@an_array) { print "has array elements\n" }
749     if (%a_hash)   { print "has hash members\n"   }
750
751 Using undef() on these, however, does clear their memory and then report
752 them as not defined anymore, but you shoudln't do that unless you don't
753 plan to use them again, because it saves time when you load them up
754 again to have memory already ready to be filled.
755
756 This counterintuitive behaviour of defined() on aggregates may be
757 changed, fixed, or broken in a future release of Perl.
758
759 See also L</undef>, L</exists>, L</ref>.
760
761 =item delete EXPR
762
763 Deletes the specified key(s) and their associated values from a hash.
764 For each key, returns the deleted value associated with that key, or
765 the undefined value if there was no such key.  Deleting from C<$ENV{}>
766 modifies the environment.  Deleting from a hash tied to a DBM file
767 deletes the entry from the DBM file.  (But deleting from a tie()d hash
768 doesn't necessarily return anything.)
769
770 The following deletes all the values of a hash:
771
772     foreach $key (keys %HASH) {
773         delete $HASH{$key};
774     }
775
776 And so does this:
777
778     delete @HASH{keys %HASH}
779
780 (But both of these are slower than the undef() command.)  Note that the
781 EXPR can be arbitrarily complicated as long as the final operation is a
782 hash element lookup or hash slice:
783
784     delete $ref->[$x][$y]{$key};
785     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
786
787 =item die LIST
788
789 Outside of an eval(), prints the value of LIST to C<STDERR> and exits with
790 the current value of C<$!> (errno).  If C<$!> is 0, exits with the value of
791 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)>
792 is 0, exits with 255.  Inside an eval(), the error message is stuffed into
793 C<$@>, and the eval() is terminated with the undefined value; this makes
794 die() the way to raise an exception.
795
796 Equivalent examples:
797
798     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
799     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
800
801 If the value of EXPR does not end in a newline, the current script line
802 number and input line number (if any) are also printed, and a newline
803 is supplied.  Hint: sometimes appending ", stopped" to your message
804 will cause it to make better sense when the string "at foo line 123" is
805 appended.  Suppose you are running script "canasta".
806
807     die "/etc/games is no good";
808     die "/etc/games is no good, stopped";
809
810 produce, respectively
811
812     /etc/games is no good at canasta line 123.
813     /etc/games is no good, stopped at canasta line 123.
814
815 See also exit() and warn().
816
817 If LIST is empty and $@ already contains a value (typically from a
818 previous eval) that value is reused after appending "\t...propagated".
819 This is useful for propagating exceptions:
820
821     eval { ... };
822     die unless $@ =~ /Expected exception/;
823
824 If $@ is empty then the string "Died" is used.
825
826 You can arrange for a callback to be called just before the die() does
827 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
828 will be called with the error text and can change the error message, if
829 it sees fit, by calling die() again.  See L<perlvar/$SIG{expr}> for details on
830 setting C<%SIG> entries, and L<"eval BLOCK"> for some examples.
831
832 Note that the C<$SIG{__DIE__}> hook is called even inside eval()ed
833 blocks/strings.  If one wants the hook to do nothing in such
834 situations, put
835
836         die @_ if $^S;
837
838 as the first line of the handler (see L<perlvar/$^S>).
839
840 =item do BLOCK
841
842 Not really a function.  Returns the value of the last command in the
843 sequence of commands indicated by BLOCK.  When modified by a loop
844 modifier, executes the BLOCK once before testing the loop condition.
845 (On other statements the loop modifiers test the conditional first.)
846
847 =item do SUBROUTINE(LIST)
848
849 A deprecated form of subroutine call.  See L<perlsub>.
850
851 =item do EXPR
852
853 Uses the value of EXPR as a filename and executes the contents of the
854 file as a Perl script.  Its primary use is to include subroutines
855 from a Perl subroutine library.
856
857     do 'stat.pl';
858
859 is just like
860
861     scalar eval `cat stat.pl`;
862
863 except that it's more efficient, more concise, keeps track of the
864 current filename for error messages, and searches all the B<-I>
865 libraries if the file isn't in the current directory (see also the @INC
866 array in L<perlvar/Predefined Names>).  It's the same, however, in that it does
867 reparse the file every time you call it, so you probably don't want to
868 do this inside a loop.
869
870 Note that inclusion of library modules is better done with the
871 use() and require() operators, which also do error checking
872 and raise an exception if there's a problem.
873
874 =item dump LABEL
875
876 This causes an immediate core dump.  Primarily this is so that you can
877 use the B<undump> program to turn your core dump into an executable binary
878 after having initialized all your variables at the beginning of the
879 program.  When the new binary is executed it will begin by executing a
880 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
881 it as a goto with an intervening core dump and reincarnation.  If LABEL
882 is omitted, restarts the program from the top.  WARNING: any files
883 opened at the time of the dump will NOT be open any more when the
884 program is reincarnated, with possible resulting confusion on the part
885 of Perl.  See also B<-u> option in L<perlrun>.
886
887 Example:
888
889     #!/usr/bin/perl
890     require 'getopt.pl';
891     require 'stat.pl';
892     %days = (
893         'Sun' => 1,
894         'Mon' => 2,
895         'Tue' => 3,
896         'Wed' => 4,
897         'Thu' => 5,
898         'Fri' => 6,
899         'Sat' => 7,
900     );
901
902     dump QUICKSTART if $ARGV[0] eq '-d';
903
904     QUICKSTART:
905     Getopt('f');
906
907 =item each HASH
908
909 When called in a list context, returns a 2-element array consisting of the
910 key and value for the next element of a hash, so that you can iterate over
911 it.  When called in a scalar context, returns the key for only the next
912 element in the hash.  (Note: Keys may be "0" or "", which are logically
913 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
914 for this reason.)
915
916 Entries are returned in an apparently random order.  When the hash is
917 entirely read, a null array is returned in list context (which when
918 assigned produces a FALSE (0) value), and C<undef> is returned in a
919 scalar context.  The next call to each() after that will start iterating
920 again.  There is a single iterator for each hash, shared by all each(),
921 keys(), and values() function calls in the program; it can be reset by
922 reading all the elements from the hash, or by evaluating C<keys HASH> or
923 C<values HASH>.  If you add or delete elements of a hash while you're
924 iterating over it, you may get entries skipped or duplicated, so don't.
925
926 The following prints out your environment like the printenv(1) program,
927 only in a different order:
928
929     while (($key,$value) = each %ENV) {
930         print "$key=$value\n";
931     }
932
933 See also keys() and values().
934
935 =item eof FILEHANDLE
936
937 =item eof ()
938
939 =item eof
940
941 Returns 1 if the next read on FILEHANDLE will return end of file, or if
942 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
943 gives the real filehandle name.  (Note that this function actually
944 reads a character and then ungetc()s it, so it is not very useful in an
945 interactive context.)  Do not read from a terminal file (or call
946 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
947 as terminals may lose the end-of-file condition if you do.
948
949 An C<eof> without an argument uses the last file read as argument.
950 Empty parentheses () may be used to indicate the pseudo file formed of
951 the files listed on the command line, i.e., C<eof()> is reasonable to
952 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
953 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
954 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
955
956     # reset line numbering on each input file
957     while (<>) {
958         print "$.\t$_";
959         close(ARGV) if (eof);   # Not eof().
960     }
961
962     # insert dashes just before last line of last file
963     while (<>) {
964         if (eof()) {
965             print "--------------\n";
966             close(ARGV);        # close or break; is needed if we
967                                 # are reading from the terminal
968         }
969         print;
970     }
971
972 Practical hint: you almost never need to use C<eof> in Perl, because the
973 input operators return undef when they run out of data.
974
975 =item eval EXPR
976
977 =item eval BLOCK
978
979 In the first form, the return value of EXPR is parsed and executed as if it
980 were a little Perl program.  The value of the expression (which is itself
981 determined within a scalar context) is first parsed, and if there are no
982 errors, executed in the context of the current Perl program, so that any
983 variable settings or subroutine and format definitions remain afterwards.
984 Note that the value is parsed every time the eval executes.  If EXPR is
985 omitted, evaluates C<$_>.  This form is typically used to delay parsing
986 and subsequent execution of the text of EXPR until run time.
987
988 In the second form, the code within the BLOCK is parsed only once--at the
989 same time the code surrounding the eval itself was parsed--and executed
990 within the context of the current Perl program.  This form is typically
991 used to trap exceptions more efficiently than the first (see below), while
992 also providing the benefit of checking the code within BLOCK at compile
993 time.
994
995 The final semicolon, if any, may be omitted from the value of EXPR or within
996 the BLOCK.
997
998 In both forms, the value returned is the value of the last expression
999 evaluated inside the mini-program, or a return statement may be used, just
1000 as with subroutines.  The expression providing the return value is evaluated
1001 in void, scalar or array context, depending on the context of the eval itself.
1002 See L</wantarray> for more on how the evaluation context can be determined.
1003
1004 If there is a syntax error or runtime error, or a die() statement is
1005 executed, an undefined value is returned by eval(), and C<$@> is set to the
1006 error message.  If there was no error, C<$@> is guaranteed to be a null
1007 string.  Beware that using eval() neither silences perl from printing
1008 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1009 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1010 L</warn> and L<perlvar>.
1011
1012 Note that, because eval() traps otherwise-fatal errors, it is useful for
1013 determining whether a particular feature (such as socket() or symlink())
1014 is implemented.  It is also Perl's exception trapping mechanism, where
1015 the die operator is used to raise exceptions.
1016
1017 If the code to be executed doesn't vary, you may use the eval-BLOCK
1018 form to trap run-time errors without incurring the penalty of
1019 recompiling each time.  The error, if any, is still returned in C<$@>.
1020 Examples:
1021
1022     # make divide-by-zero nonfatal
1023     eval { $answer = $a / $b; }; warn $@ if $@;
1024
1025     # same thing, but less efficient
1026     eval '$answer = $a / $b'; warn $@ if $@;
1027
1028     # a compile-time error
1029     eval { $answer = };
1030
1031     # a run-time error
1032     eval '$answer =';   # sets $@
1033
1034 When using the eval{} form as an exception trap in libraries, you may
1035 wish not to trigger any C<__DIE__> hooks that user code may have
1036 installed.  You can use the C<local $SIG{__DIE__}> construct for this
1037 purpose, as shown in this example:
1038
1039     # a very private exception trap for divide-by-zero
1040     eval { local $SIG{'__DIE__'}; $answer = $a / $b; }; warn $@ if $@;
1041
1042 This is especially significant, given that C<__DIE__> hooks can call
1043 die() again, which has the effect of changing their error messages:
1044
1045     # __DIE__ hooks may modify error messages
1046     {
1047        local $SIG{'__DIE__'} = sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1048        eval { die "foo lives here" };
1049        print $@ if $@;                # prints "bar lives here"
1050     }
1051
1052 With an eval(), you should be especially careful to remember what's
1053 being looked at when:
1054
1055     eval $x;            # CASE 1
1056     eval "$x";          # CASE 2
1057
1058     eval '$x';          # CASE 3
1059     eval { $x };        # CASE 4
1060
1061     eval "\$$x++"       # CASE 5
1062     $$x++;              # CASE 6
1063
1064 Cases 1 and 2 above behave identically: they run the code contained in
1065 the variable $x.  (Although case 2 has misleading double quotes making
1066 the reader wonder what else might be happening (nothing is).)  Cases 3
1067 and 4 likewise behave in the same way: they run the code '$x', which
1068 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1069 purely visual reasons, but it also has the advantage of compiling at
1070 compile-time instead of at run-time.)  Case 5 is a place where
1071 normally you I<WOULD> like to use double quotes, except that in this
1072 particular situation, you can just use symbolic references instead, as
1073 in case 6.
1074
1075 =item exec LIST
1076
1077 The exec() function executes a system command I<AND NEVER RETURNS> -
1078 use system() instead of exec() if you want it to return. It fails and
1079 returns FALSE only if the command does not exist I<and> it is executed
1080 directly instead of via your system's command shell (see below).
1081
1082 If there is more than one argument in LIST, or if LIST is an array with
1083 more than one value, calls execvp(3) with the arguments in LIST.  If
1084 there is only one scalar argument, the argument is checked for shell
1085 metacharacters, and if there are any, the entire argument is passed to
1086 the system's command shell for parsing (this is C</bin/sh -c> on Unix
1087 platforms, but varies on other platforms).  If there are no shell
1088 metacharacters in the argument, it is split into words and passed
1089 directly to execvp(), which is more efficient.  Note: exec() and
1090 system() do not flush your output buffer, so you may need to set C<$|>
1091 to avoid lost output.  Examples:
1092
1093     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1094     exec "sort $outfile | uniq";
1095
1096 If you don't really want to execute the first argument, but want to lie
1097 to the program you are executing about its own name, you can specify
1098 the program you actually want to run as an "indirect object" (without a
1099 comma) in front of the LIST.  (This always forces interpretation of the
1100 LIST as a multivalued list, even if there is only a single scalar in
1101 the list.)  Example:
1102
1103     $shell = '/bin/csh';
1104     exec $shell '-sh';          # pretend it's a login shell
1105
1106 or, more directly,
1107
1108     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1109
1110 When the arguments get executed via the system shell, results will
1111 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1112 for details.
1113
1114 =item exists EXPR
1115
1116 Returns TRUE if the specified hash key exists in its hash array, even
1117 if the corresponding value is undefined.
1118
1119     print "Exists\n" if exists $array{$key};
1120     print "Defined\n" if defined $array{$key};
1121     print "True\n" if $array{$key};
1122
1123 A hash element can be TRUE only if it's defined, and defined if
1124 it exists, but the reverse doesn't necessarily hold true.
1125
1126 Note that the EXPR can be arbitrarily complicated as long as the final
1127 operation is a hash key lookup:
1128
1129     if (exists $ref->[$x][$y]{$key}) { ... }
1130
1131 =item exit EXPR
1132
1133 Evaluates EXPR and exits immediately with that value.  (Actually, it
1134 calls any defined C<END> routines first, but the C<END> routines may not
1135 abort the exit.  Likewise any object destructors that need to be called
1136 are called before exit.)  Example:
1137
1138     $ans = <STDIN>;
1139     exit 0 if $ans =~ /^[Xx]/;
1140
1141 See also die().  If EXPR is omitted, exits with 0 status.  The only
1142 universally portable values for EXPR are 0 for success and 1 for error;
1143 all other values are subject to unpredictable interpretation depending
1144 on the environment in which the Perl program is running.
1145
1146 You shouldn't use exit() to abort a subroutine if there's any chance that
1147 someone might want to trap whatever error happened.  Use die() instead,
1148 which can be trapped by an eval().
1149
1150 =item exp EXPR
1151
1152 =item exp
1153
1154 Returns I<e> (the natural logarithm base) to the power of EXPR.
1155 If EXPR is omitted, gives C<exp($_)>.
1156
1157 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1158
1159 Implements the fcntl(2) function.  You'll probably have to say
1160
1161     use Fcntl;
1162
1163 first to get the correct function definitions.  Argument processing and
1164 value return works just like ioctl() below.  Note that fcntl() will produce
1165 a fatal error if used on a machine that doesn't implement fcntl(2).
1166 For example:
1167
1168     use Fcntl;
1169     fcntl($filehandle, F_GETLK, $packed_return_buffer);
1170
1171 =item fileno FILEHANDLE
1172
1173 Returns the file descriptor for a filehandle.  This is useful for
1174 constructing bitmaps for select().  If FILEHANDLE is an expression, the
1175 value is taken as the name of the filehandle.
1176
1177 =item flock FILEHANDLE,OPERATION
1178
1179 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1180 success, FALSE on failure.  Produces a fatal error if used on a machine
1181 that doesn't implement flock(2), fcntl(2) locking, or lockf(3).  flock()
1182 is Perl's portable file locking interface, although it locks only entire
1183 files, not records.
1184
1185 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1186 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1187 you can use the symbolic names if import them from the Fcntl module,
1188 either individually, or as a group using the ':flock' tag.  LOCK_SH
1189 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1190 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1191 LOCK_EX then flock() will return immediately rather than blocking
1192 waiting for the lock (check the return status to see if you got it).
1193
1194 To avoid the possibility of mis-coordination, Perl flushes FILEHANDLE
1195 before (un)locking it.
1196
1197 Note that the emulation built with lockf(3) doesn't provide shared
1198 locks, and it requires that FILEHANDLE be open with write intent.  These
1199 are the semantics that lockf(3) implements.  Most (all?) systems
1200 implement lockf(3) in terms of fcntl(2) locking, though, so the
1201 differing semantics shouldn't bite too many people.
1202
1203 Note also that some versions of flock() cannot lock things over the
1204 network; you would need to use the more system-specific fcntl() for
1205 that.  If you like you can force Perl to ignore your system's flock(2)
1206 function, and so provide its own fcntl(2)-based emulation, by passing
1207 the switch C<-Ud_flock> to the F<Configure> program when you configure
1208 perl.
1209
1210 Here's a mailbox appender for BSD systems.
1211
1212     use Fcntl ':flock'; # import LOCK_* constants
1213
1214     sub lock {
1215         flock(MBOX,LOCK_EX);
1216         # and, in case someone appended
1217         # while we were waiting...
1218         seek(MBOX, 0, 2);
1219     }
1220
1221     sub unlock {
1222         flock(MBOX,LOCK_UN);
1223     }
1224
1225     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1226             or die "Can't open mailbox: $!";
1227
1228     lock();
1229     print MBOX $msg,"\n\n";
1230     unlock();
1231
1232 See also L<DB_File> for other flock() examples.
1233
1234 =item fork
1235
1236 Does a fork(2) system call.  Returns the child pid to the parent process
1237 and 0 to the child process, or C<undef> if the fork is unsuccessful.
1238 Note: unflushed buffers remain unflushed in both processes, which means
1239 you may need to set C<$|> ($AUTOFLUSH in English) or call the autoflush()
1240 method of IO::Handle to avoid duplicate output.
1241
1242 If you fork() without ever waiting on your children, you will accumulate
1243 zombies:
1244
1245     $SIG{CHLD} = sub { wait };
1246
1247 There's also the double-fork trick (error checking on
1248 fork() returns omitted);
1249
1250     unless ($pid = fork) {
1251         unless (fork) {
1252             exec "what you really wanna do";
1253             die "no exec";
1254             # ... or ...
1255             ## (some_perl_code_here)
1256             exit 0;
1257         }
1258         exit 0;
1259     }
1260     waitpid($pid,0);
1261
1262 See also L<perlipc> for more examples of forking and reaping
1263 moribund children.
1264
1265 Note that if your forked child inherits system file descriptors like
1266 STDIN and STDOUT that are actually connected by a pipe or socket, even
1267 if you exit, the remote server (such as, say, httpd or rsh) won't think
1268 you're done.  You should reopen those to /dev/null if it's any issue.
1269
1270 =item format
1271
1272 Declare a picture format with use by the write() function.  For
1273 example:
1274
1275     format Something =
1276         Test: @<<<<<<<< @||||| @>>>>>
1277               $str,     $%,    '$' . int($num)
1278     .
1279
1280     $str = "widget";
1281     $num = $cost/$quantity;
1282     $~ = 'Something';
1283     write;
1284
1285 See L<perlform> for many details and examples.
1286
1287
1288 =item formline PICTURE,LIST
1289
1290 This is an internal function used by C<format>s, though you may call it
1291 too.  It formats (see L<perlform>) a list of values according to the
1292 contents of PICTURE, placing the output into the format output
1293 accumulator, C<$^A> (or $ACCUMULATOR in English).
1294 Eventually, when a write() is done, the contents of
1295 C<$^A> are written to some filehandle, but you could also read C<$^A>
1296 yourself and then set C<$^A> back to "".  Note that a format typically
1297 does one formline() per line of form, but the formline() function itself
1298 doesn't care how many newlines are embedded in the PICTURE.  This means
1299 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1300 You may therefore need to use multiple formlines to implement a single
1301 record format, just like the format compiler.
1302
1303 Be careful if you put double quotes around the picture, because an "C<@>"
1304 character may be taken to mean the beginning of an array name.
1305 formline() always returns TRUE.  See L<perlform> for other examples.
1306
1307 =item getc FILEHANDLE
1308
1309 =item getc
1310
1311 Returns the next character from the input file attached to FILEHANDLE,
1312 or a null string at end of file.  If FILEHANDLE is omitted, reads from STDIN.
1313 This is not particularly efficient.  It cannot be used to get unbuffered
1314 single-characters, however.  For that, try something more like:
1315
1316     if ($BSD_STYLE) {
1317         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1318     }
1319     else {
1320         system "stty", '-icanon', 'eol', "\001";
1321     }
1322
1323     $key = getc(STDIN);
1324
1325     if ($BSD_STYLE) {
1326         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1327     }
1328     else {
1329         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1330     }
1331     print "\n";
1332
1333 Determination of whether $BSD_STYLE should be set
1334 is left as an exercise to the reader.
1335
1336 The POSIX::getattr() function can do this more portably on systems
1337 alleging POSIX compliance.
1338 See also the C<Term::ReadKey> module from your nearest CPAN site;
1339 details on CPAN can be found on L<perlmod/CPAN>.
1340
1341 =item getlogin
1342
1343 Returns the current login from F</etc/utmp>, if any.  If null, use
1344 getpwuid().
1345
1346     $login = getlogin || getpwuid($<) || "Kilroy";
1347
1348 Do not consider getlogin() for authentication: it is not as
1349 secure as getpwuid().
1350
1351 =item getpeername SOCKET
1352
1353 Returns the packed sockaddr address of other end of the SOCKET connection.
1354
1355     use Socket;
1356     $hersockaddr    = getpeername(SOCK);
1357     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1358     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1359     $herstraddr     = inet_ntoa($iaddr);
1360
1361 =item getpgrp PID
1362
1363 Returns the current process group for the specified PID.  Use
1364 a PID of 0 to get the current process group for the
1365 current process.  Will raise an exception if used on a machine that
1366 doesn't implement getpgrp(2).  If PID is omitted, returns process
1367 group of current process.  Note that the POSIX version of getpgrp()
1368 does not accept a PID argument, so only PID==0 is truly portable.
1369
1370 =item getppid
1371
1372 Returns the process id of the parent process.
1373
1374 =item getpriority WHICH,WHO
1375
1376 Returns the current priority for a process, a process group, or a user.
1377 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1378 machine that doesn't implement getpriority(2).
1379
1380 =item getpwnam NAME
1381
1382 =item getgrnam NAME
1383
1384 =item gethostbyname NAME
1385
1386 =item getnetbyname NAME
1387
1388 =item getprotobyname NAME
1389
1390 =item getpwuid UID
1391
1392 =item getgrgid GID
1393
1394 =item getservbyname NAME,PROTO
1395
1396 =item gethostbyaddr ADDR,ADDRTYPE
1397
1398 =item getnetbyaddr ADDR,ADDRTYPE
1399
1400 =item getprotobynumber NUMBER
1401
1402 =item getservbyport PORT,PROTO
1403
1404 =item getpwent
1405
1406 =item getgrent
1407
1408 =item gethostent
1409
1410 =item getnetent
1411
1412 =item getprotoent
1413
1414 =item getservent
1415
1416 =item setpwent
1417
1418 =item setgrent
1419
1420 =item sethostent STAYOPEN
1421
1422 =item setnetent STAYOPEN
1423
1424 =item setprotoent STAYOPEN
1425
1426 =item setservent STAYOPEN
1427
1428 =item endpwent
1429
1430 =item endgrent
1431
1432 =item endhostent
1433
1434 =item endnetent
1435
1436 =item endprotoent
1437
1438 =item endservent
1439
1440 These routines perform the same functions as their counterparts in the
1441 system library.  Within a list context, the return values from the
1442 various get routines are as follows:
1443
1444     ($name,$passwd,$uid,$gid,
1445        $quota,$comment,$gcos,$dir,$shell) = getpw*
1446     ($name,$passwd,$gid,$members) = getgr*
1447     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1448     ($name,$aliases,$addrtype,$net) = getnet*
1449     ($name,$aliases,$proto) = getproto*
1450     ($name,$aliases,$port,$proto) = getserv*
1451
1452 (If the entry doesn't exist you get a null list.)
1453
1454 Within a scalar context, you get the name, unless the function was a
1455 lookup by name, in which case you get the other thing, whatever it is.
1456 (If the entry doesn't exist you get the undefined value.)  For example:
1457
1458     $uid = getpwnam
1459     $name = getpwuid
1460     $name = getpwent
1461     $gid = getgrnam
1462     $name = getgrgid
1463     $name = getgrent
1464     etc.
1465
1466 The $members value returned by I<getgr*()> is a space separated list of
1467 the login names of the members of the group.
1468
1469 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1470 C, it will be returned to you via C<$?> if the function call fails.  The
1471 @addrs value returned by a successful call is a list of the raw
1472 addresses returned by the corresponding system library call.  In the
1473 Internet domain, each address is four bytes long and you can unpack it
1474 by saying something like:
1475
1476     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1477
1478 =item getsockname SOCKET
1479
1480 Returns the packed sockaddr address of this end of the SOCKET connection.
1481
1482     use Socket;
1483     $mysockaddr = getsockname(SOCK);
1484     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1485
1486 =item getsockopt SOCKET,LEVEL,OPTNAME
1487
1488 Returns the socket option requested, or undefined if there is an error.
1489
1490 =item glob EXPR
1491
1492 =item glob
1493
1494 Returns the value of EXPR with filename expansions such as a shell would
1495 do.  This is the internal function implementing the C<E<lt>*.cE<gt>>
1496 operator, but you can use it directly.  If EXPR is omitted, $_ is used.
1497 The C<E<lt>*.cE<gt>> operator is discussed in more detail in
1498 L<perlop/"I/O Operators">.
1499
1500 =item gmtime EXPR
1501
1502 Converts a time as returned by the time function to a 9-element array
1503 with the time localized for the standard Greenwich time zone.
1504 Typically used as follows:
1505
1506     #  0    1    2     3     4    5     6     7     8
1507     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1508                                             gmtime(time);
1509
1510 All array elements are numeric, and come straight out of a struct tm.
1511 In particular this means that $mon has the range 0..11 and $wday has
1512 the range 0..6 with sunday as day 0.  Also, $year is the number of
1513 years since 1900, I<not> simply the last two digits of the year.
1514
1515 If EXPR is omitted, does C<gmtime(time())>.
1516
1517 In a scalar context, returns the ctime(3) value:
1518
1519     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1520
1521 Also see the timegm() function provided by the Time::Local module,
1522 and the strftime(3) function available via the POSIX module.
1523
1524 =item goto LABEL
1525
1526 =item goto EXPR
1527
1528 =item goto &NAME
1529
1530 The goto-LABEL form finds the statement labeled with LABEL and resumes
1531 execution there.  It may not be used to go into any construct that
1532 requires initialization, such as a subroutine or a foreach loop.  It
1533 also can't be used to go into a construct that is optimized away,
1534 or to get out of a block or subroutine given to sort().
1535 It can be used to go almost anywhere else within the dynamic scope,
1536 including out of subroutines, but it's usually better to use some other
1537 construct such as last or die.  The author of Perl has never felt the
1538 need to use this form of goto (in Perl, that is--C is another matter).
1539
1540 The goto-EXPR form expects a label name, whose scope will be resolved
1541 dynamically.  This allows for computed gotos per FORTRAN, but isn't
1542 necessarily recommended if you're optimizing for maintainability:
1543
1544     goto ("FOO", "BAR", "GLARCH")[$i];
1545
1546 The goto-&NAME form is highly magical, and substitutes a call to the
1547 named subroutine for the currently running subroutine.  This is used by
1548 AUTOLOAD subroutines that wish to load another subroutine and then
1549 pretend that the other subroutine had been called in the first place
1550 (except that any modifications to @_ in the current subroutine are
1551 propagated to the other subroutine.)  After the goto, not even caller()
1552 will be able to tell that this routine was called first.
1553
1554 =item grep BLOCK LIST
1555
1556 =item grep EXPR,LIST
1557
1558 This is similar in spirit to, but not the same as, grep(1)
1559 and its relatives.  In particular, it is not limited to using
1560 regular expressions.
1561
1562 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1563 $_ to each element) and returns the list value consisting of those
1564 elements for which the expression evaluated to TRUE.  In a scalar
1565 context, returns the number of times the expression was TRUE.
1566
1567     @foo = grep(!/^#/, @bar);    # weed out comments
1568
1569 or equivalently,
1570
1571     @foo = grep {!/^#/} @bar;    # weed out comments
1572
1573 Note that, because $_ is a reference into the list value, it can be used
1574 to modify the elements of the array.  While this is useful and
1575 supported, it can cause bizarre results if the LIST is not a named
1576 array.  Similarly, grep returns aliases into the original list,
1577 much like the way that L<Foreach Loops>'s index variable aliases the list
1578 elements.  That is, modifying an element of a list returned by grep
1579 (for example, in a C<foreach>, C<map> or another C<grep>)
1580 actually modifies the element in the original list.
1581
1582 See also L</map> for an array composed of the results of the BLOCK or EXPR.
1583
1584 =item hex EXPR
1585
1586 =item hex
1587
1588 Interprets EXPR as a hex string and returns the corresponding
1589 value.  (To convert strings that might start with either 0 or 0x
1590 see L</oct>.)  If EXPR is omitted, uses $_.
1591
1592     print hex '0xAf'; # prints '175'
1593     print hex 'aF';   # same
1594
1595 =item import
1596
1597 There is no builtin import() function.  It is merely an ordinary
1598 method (subroutine) defined (or inherited) by modules that wish to export
1599 names to another module.  The use() function calls the import() method
1600 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1601
1602 =item index STR,SUBSTR,POSITION
1603
1604 =item index STR,SUBSTR
1605
1606 Returns the position of the first occurrence of SUBSTR in STR at or after
1607 POSITION.  If POSITION is omitted, starts searching from the beginning of
1608 the string.  The return value is based at 0 (or whatever you've set the C<$[>
1609 variable to--but don't do that).  If the substring is not found, returns
1610 one less than the base, ordinarily -1.
1611
1612 =item int EXPR
1613
1614 =item int
1615
1616 Returns the integer portion of EXPR.  If EXPR is omitted, uses $_.
1617
1618 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1619
1620 Implements the ioctl(2) function.  You'll probably have to say
1621
1622     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1623
1624 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1625 exist or doesn't have the correct definitions you'll have to roll your
1626 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1627 (There is a Perl script called B<h2ph> that comes with the Perl kit which
1628 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
1629 written depending on the FUNCTION--a pointer to the string value of SCALAR
1630 will be passed as the third argument of the actual ioctl call.  (If SCALAR
1631 has no string value but does have a numeric value, that value will be
1632 passed rather than a pointer to the string value.  To guarantee this to be
1633 TRUE, add a 0 to the scalar before using it.)  The pack() and unpack()
1634 functions are useful for manipulating the values of structures used by
1635 ioctl().  The following example sets the erase character to DEL.
1636
1637     require 'ioctl.ph';
1638     $getp = &TIOCGETP;
1639     die "NO TIOCGETP" if $@ || !$getp;
1640     $sgttyb_t = "ccccs";                # 4 chars and a short
1641     if (ioctl(STDIN,$getp,$sgttyb)) {
1642         @ary = unpack($sgttyb_t,$sgttyb);
1643         $ary[2] = 127;
1644         $sgttyb = pack($sgttyb_t,@ary);
1645         ioctl(STDIN,&TIOCSETP,$sgttyb)
1646             || die "Can't ioctl: $!";
1647     }
1648
1649 The return value of ioctl (and fcntl) is as follows:
1650
1651         if OS returns:          then Perl returns:
1652             -1                    undefined value
1653              0                  string "0 but true"
1654         anything else               that number
1655
1656 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1657 still easily determine the actual value returned by the operating
1658 system:
1659
1660     ($retval = ioctl(...)) || ($retval = -1);
1661     printf "System returned %d\n", $retval;
1662
1663 =item join EXPR,LIST
1664
1665 Joins the separate strings of LIST into a single string with
1666 fields separated by the value of EXPR, and returns the string.
1667 Example:
1668
1669     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1670
1671 See L<perlfunc/split>.
1672
1673 =item keys HASH
1674
1675 Returns a normal array consisting of all the keys of the named hash.  (In
1676 a scalar context, returns the number of keys.)  The keys are returned in
1677 an apparently random order, but it is the same order as either the
1678 values() or each() function produces (given that the hash has not been
1679 modified).  As a side effect, it resets HASH's iterator.
1680
1681 Here is yet another way to print your environment:
1682
1683     @keys = keys %ENV;
1684     @values = values %ENV;
1685     while ($#keys >= 0) {
1686         print pop(@keys), '=', pop(@values), "\n";
1687     }
1688
1689 or how about sorted by key:
1690
1691     foreach $key (sort(keys %ENV)) {
1692         print $key, '=', $ENV{$key}, "\n";
1693     }
1694
1695 To sort an array by value, you'll need to use a C<sort> function.
1696 Here's a descending numeric sort of a hash by its values:
1697
1698     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash)) {
1699         printf "%4d %s\n", $hash{$key}, $key;
1700     }
1701
1702 As an lvalue C<keys> allows you to increase the number of hash buckets
1703 allocated for the given hash.  This can gain you a measure of efficiency if
1704 you know the hash is going to get big.  (This is similar to pre-extending
1705 an array by assigning a larger number to $#array.)  If you say
1706
1707     keys %hash = 200;
1708
1709 then C<%hash> will have at least 200 buckets allocated for it.  These
1710 buckets will be retained even if you do C<%hash = ()>, use C<undef
1711 %hash> if you want to free the storage while C<%hash> is still in scope.
1712 You can't shrink the number of buckets allocated for the hash using
1713 C<keys> in this way (but you needn't worry about doing this by accident,
1714 as trying has no effect).
1715
1716 =item kill LIST
1717
1718 Sends a signal to a list of processes.  The first element of
1719 the list must be the signal to send.  Returns the number of
1720 processes successfully signaled.
1721
1722     $cnt = kill 1, $child1, $child2;
1723     kill 9, @goners;
1724
1725 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1726 process groups instead of processes.  (On System V, a negative I<PROCESS>
1727 number will also kill process groups, but that's not portable.)  That
1728 means you usually want to use positive not negative signals.  You may also
1729 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1730
1731 =item last LABEL
1732
1733 =item last
1734
1735 The C<last> command is like the C<break> statement in C (as used in
1736 loops); it immediately exits the loop in question.  If the LABEL is
1737 omitted, the command refers to the innermost enclosing loop.  The
1738 C<continue> block, if any, is not executed:
1739
1740     LINE: while (<STDIN>) {
1741         last LINE if /^$/;      # exit when done with header
1742         ...
1743     }
1744
1745 =item lc EXPR
1746
1747 =item lc
1748
1749 Returns an lowercased version of EXPR.  This is the internal function
1750 implementing the \L escape in double-quoted strings.
1751 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1752
1753 If EXPR is omitted, uses $_.
1754
1755 =item lcfirst EXPR
1756
1757 =item lcfirst
1758
1759 Returns the value of EXPR with the first character lowercased.  This is
1760 the internal function implementing the \l escape in double-quoted strings.
1761 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
1762
1763 If EXPR is omitted, uses $_.
1764
1765 =item length EXPR
1766
1767 =item length
1768
1769 Returns the length in characters of the value of EXPR.  If EXPR is
1770 omitted, returns length of $_.
1771
1772 =item link OLDFILE,NEWFILE
1773
1774 Creates a new filename linked to the old filename.  Returns 1 for
1775 success, 0 otherwise.
1776
1777 =item listen SOCKET,QUEUESIZE
1778
1779 Does the same thing that the listen system call does.  Returns TRUE if
1780 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1781
1782 =item local EXPR
1783
1784 A local modifies the listed variables to be local to the enclosing block,
1785 subroutine, C<eval{}>, or C<do>.  If more than one value is listed, the
1786 list must be placed in parentheses.  See L<perlsub/"Temporary Values via
1787 local()"> for details, including issues with tied arrays and hashes.
1788
1789 But you really probably want to be using my() instead, because local() isn't
1790 what most people think of as "local").  See L<perlsub/"Private Variables
1791 via my()"> for details.
1792
1793 =item localtime EXPR
1794
1795 Converts a time as returned by the time function to a 9-element array
1796 with the time analyzed for the local time zone.  Typically used as
1797 follows:
1798
1799     #  0    1    2     3     4    5     6     7     8
1800     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1801                                                 localtime(time);
1802
1803 All array elements are numeric, and come straight out of a struct tm.
1804 In particular this means that $mon has the range 0..11 and $wday has
1805 the range 0..6 with sunday as day 0.  Also, $year is the number of
1806 years since 1900, that is, $year is 123 in year 2023.
1807
1808 If EXPR is omitted, uses the current time (C<localtime(time)>).
1809
1810 In a scalar context, returns the ctime(3) value:
1811
1812     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1813
1814 This scalar value is B<not> locale dependent, see L<perllocale>,
1815 but instead a Perl builtin.
1816 Also see the Time::Local module, and the strftime(3) and mktime(3)
1817 function available via the POSIX module.
1818
1819 =item log EXPR
1820
1821 =item log
1822
1823 Returns logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
1824 of $_.
1825
1826 =item lstat FILEHANDLE
1827
1828 =item lstat EXPR
1829
1830 =item lstat
1831
1832 Does the same thing as the stat() function, but stats a symbolic link
1833 instead of the file the symbolic link points to.  If symbolic links are
1834 unimplemented on your system, a normal stat() is done.
1835
1836 If EXPR is omitted, stats $_.
1837
1838 =item m//
1839
1840 The match operator.  See L<perlop>.
1841
1842 =item map BLOCK LIST
1843
1844 =item map EXPR,LIST
1845
1846 Evaluates the BLOCK or EXPR for each element of LIST (locally setting $_ to each
1847 element) and returns the list value composed of the results of each such
1848 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
1849 may produce zero, one, or more elements in the returned value.
1850
1851     @chars = map(chr, @nums);
1852
1853 translates a list of numbers to the corresponding characters.  And
1854
1855     %hash = map { getkey($_) => $_ } @array;
1856
1857 is just a funny way to write
1858
1859     %hash = ();
1860     foreach $_ (@array) {
1861         $hash{getkey($_)} = $_;
1862     }
1863
1864 Note that, because $_ is a reference into the list value, it can be used
1865 to modify the elements of the array.  While this is useful and
1866 supported, it can cause bizarre results if the LIST is not a named
1867 array.  See also L</grep> for an array composed of those items of the 
1868 original list for which the BLOCK or EXPR evaluates to true.
1869
1870 =item mkdir FILENAME,MODE
1871
1872 Creates the directory specified by FILENAME, with permissions specified
1873 by MODE (as modified by umask).  If it succeeds it returns 1, otherwise
1874 it returns 0 and sets C<$!> (errno).
1875
1876 =item msgctl ID,CMD,ARG
1877
1878 Calls the System V IPC function msgctl(2).  If CMD is &IPC_STAT, then ARG
1879 must be a variable which will hold the returned msqid_ds structure.
1880 Returns like ioctl: the undefined value for error, "0 but true" for
1881 zero, or the actual return value otherwise.
1882
1883 =item msgget KEY,FLAGS
1884
1885 Calls the System V IPC function msgget(2).  Returns the message queue id,
1886 or the undefined value if there is an error.
1887
1888 =item msgsnd ID,MSG,FLAGS
1889
1890 Calls the System V IPC function msgsnd to send the message MSG to the
1891 message queue ID.  MSG must begin with the long integer message type,
1892 which may be created with C<pack("l", $type)>.  Returns TRUE if
1893 successful, or FALSE if there is an error.
1894
1895 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
1896
1897 Calls the System V IPC function msgrcv to receive a message from
1898 message queue ID into variable VAR with a maximum message size of
1899 SIZE.  Note that if a message is received, the message type will be the
1900 first thing in VAR, and the maximum length of VAR is SIZE plus the size
1901 of the message type.  Returns TRUE if successful, or FALSE if there is
1902 an error.
1903
1904 =item my EXPR
1905
1906 A "my" declares the listed variables to be local (lexically) to the
1907 enclosing block, subroutine, C<eval>, or C<do/require/use>'d file.  If
1908 more than one value is listed, the list must be placed in parentheses.  See
1909 L<perlsub/"Private Variables via my()"> for details.
1910
1911 =item next LABEL
1912
1913 =item next
1914
1915 The C<next> command is like the C<continue> statement in C; it starts
1916 the next iteration of the loop:
1917
1918     LINE: while (<STDIN>) {
1919         next LINE if /^#/;      # discard comments
1920         ...
1921     }
1922
1923 Note that if there were a C<continue> block on the above, it would get
1924 executed even on discarded lines.  If the LABEL is omitted, the command
1925 refers to the innermost enclosing loop.
1926
1927 =item no Module LIST
1928
1929 See the "use" function, which "no" is the opposite of.
1930
1931 =item oct EXPR
1932
1933 =item oct
1934
1935 Interprets EXPR as an octal string and returns the corresponding
1936 value.  (If EXPR happens to start off with 0x, interprets it as
1937 a hex string instead.)  The following will handle decimal, octal, and
1938 hex in the standard Perl or C notation:
1939
1940     $val = oct($val) if $val =~ /^0/;
1941
1942 If EXPR is omitted, uses $_.  This function is commonly used when
1943 a string such as "644" needs to be converted into a file mode, for
1944 example. (Although perl will automatically convert strings into
1945 numbers as needed, this automatic conversion assumes base 10.)
1946
1947 =item open FILEHANDLE,EXPR
1948
1949 =item open FILEHANDLE
1950
1951 Opens the file whose filename is given by EXPR, and associates it with
1952 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
1953 name of the real filehandle wanted.  If EXPR is omitted, the scalar
1954 variable of the same name as the FILEHANDLE contains the filename.
1955 (Note that lexical variables--those declared with C<my>--will not work
1956 for this purpose; so if you're using C<my>, specify EXPR in your call
1957 to open.)
1958
1959 If the filename begins with '<' or nothing, the file is opened for input.
1960 If the filename begins with '>', the file is truncated and opened for
1961 output.  If the filename begins with '>>', the file is opened for
1962 appending.  You can put a '+' in front of the '>' or '<' to indicate that
1963 you want both read and write access to the file; thus '+<' is almost
1964 always preferred for read/write updates--the '+>' mode would clobber the
1965 file first.  The prefix and the filename may be separated with spaces.
1966 These various prefixes correspond to the fopen(3) modes of 'r', 'r+', 'w',
1967 'w+', 'a', and 'a+'.
1968
1969 If the filename begins with "|", the filename is interpreted as a command
1970 to which output is to be piped, and if the filename ends with a "|", the
1971 filename is interpreted See L<perlipc/"Using open() for IPC"> for more
1972 examples of this.  as command which pipes input to us.  (You may not have
1973 a raw open() to a command that pipes both in I<and> out, but see
1974 L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
1975 for alternatives.)
1976
1977 Opening '-' opens STDIN and opening 'E<gt>-' opens STDOUT.  Open returns
1978 nonzero upon success, the undefined value otherwise.  If the open
1979 involved a pipe, the return value happens to be the pid of the
1980 subprocess.
1981
1982 If you're unfortunate enough to be running Perl on a system that
1983 distinguishes between text files and binary files (modern operating
1984 systems don't care), then you should check out L</binmode> for tips for
1985 dealing with this.  The key distinction between systems that need binmode
1986 and those that don't is their text file formats.  Systems like Unix and
1987 Plan9 that delimit lines with a single character, and that encode that
1988 character in C as '\n', do not need C<binmode>.  The rest need it.
1989
1990 When opening a file, it's usually a bad idea to continue normal execution
1991 if the request failed, so C<open> is frequently used in connection with
1992 C<die>. Even if C<die> won't do what you want (say, in a CGI script,
1993 where you want to make a nicely formatted error message (but there are
1994 modules which can help with that problem)) you should always check
1995 the return value from opening a file. The infrequent exception is when
1996 working with an unopened filehandle is actually what you want to do.
1997
1998 Examples:
1999
2000     $ARTICLE = 100;
2001     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2002     while (<ARTICLE>) {...
2003
2004     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
2005     # if the open fails, output is discarded
2006
2007     open(DBASE, '+<dbase.mine')             # open for update
2008         or die "Can't open 'dbase.mine' for update: $!";
2009
2010     open(ARTICLE, "caesar <$article |")     # decrypt article
2011         or die "Can't start caesar: $!";
2012
2013     open(EXTRACT, "|sort >/tmp/Tmp$$")      # $$ is our process id
2014         or die "Can't start sort: $!";
2015
2016     # process argument list of files along with any includes
2017
2018     foreach $file (@ARGV) {
2019         process($file, 'fh00');
2020     }
2021
2022     sub process {
2023         local($filename, $input) = @_;
2024         $input++;               # this is a string increment
2025         unless (open($input, $filename)) {
2026             print STDERR "Can't open $filename: $!\n";
2027             return;
2028         }
2029
2030         while (<$input>) {              # note use of indirection
2031             if (/^#include "(.*)"/) {
2032                 process($1, $input);
2033                 next;
2034             }
2035             ...         # whatever
2036         }
2037     }
2038
2039 You may also, in the Bourne shell tradition, specify an EXPR beginning
2040 with "E<gt>&", in which case the rest of the string is interpreted as the
2041 name of a filehandle (or file descriptor, if numeric) which is to be
2042 duped and opened.  You may use & after E<gt>, E<gt>E<gt>, E<lt>, +E<gt>,
2043 +E<gt>E<gt>, and +E<lt>.  The
2044 mode you specify should match the mode of the original filehandle.
2045 (Duping a filehandle does not take into account any existing contents of
2046 stdio buffers.)
2047 Here is a script that saves, redirects, and restores STDOUT and
2048 STDERR:
2049
2050     #!/usr/bin/perl
2051     open(SAVEOUT, ">&STDOUT");
2052     open(SAVEERR, ">&STDERR");
2053
2054     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
2055     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
2056
2057     select(STDERR); $| = 1;     # make unbuffered
2058     select(STDOUT); $| = 1;     # make unbuffered
2059
2060     print STDOUT "stdout 1\n";  # this works for
2061     print STDERR "stderr 1\n";  # subprocesses too
2062
2063     close(STDOUT);
2064     close(STDERR);
2065
2066     open(STDOUT, ">&SAVEOUT");
2067     open(STDERR, ">&SAVEERR");
2068
2069     print STDOUT "stdout 2\n";
2070     print STDERR "stderr 2\n";
2071
2072
2073 If you specify "E<lt>&=N", where N is a number, then Perl will do an
2074 equivalent of C's fdopen() of that file descriptor; this is more
2075 parsimonious of file descriptors.  For example:
2076
2077     open(FILEHANDLE, "<&=$fd")
2078
2079 If you open a pipe on the command "-", i.e., either "|-" or "-|", then
2080 there is an implicit fork done, and the return value of open is the pid
2081 of the child within the parent process, and 0 within the child
2082 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2083 The filehandle behaves normally for the parent, but i/o to that
2084 filehandle is piped from/to the STDOUT/STDIN of the child process.
2085 In the child process the filehandle isn't opened--i/o happens from/to
2086 the new STDOUT or STDIN.  Typically this is used like the normal
2087 piped open when you want to exercise more control over just how the
2088 pipe command gets executed, such as when you are running setuid, and
2089 don't want to have to scan shell commands for metacharacters.
2090 The following pairs are more or less equivalent:
2091
2092     open(FOO, "|tr '[a-z]' '[A-Z]'");
2093     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2094
2095     open(FOO, "cat -n '$file'|");
2096     open(FOO, "-|") || exec 'cat', '-n', $file;
2097
2098 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2099
2100 NOTE: On any operation which may do a fork, unflushed buffers remain
2101 unflushed in both processes, which means you may need to set C<$|> to
2102 avoid duplicate output.
2103
2104 Closing any piped filehandle causes the parent process to wait for the
2105 child to finish, and returns the status value in C<$?>.
2106
2107 Using the constructor from the IO::Handle package (or one of its
2108 subclasses, such as IO::File or IO::Socket),
2109 you can generate anonymous filehandles which have the scope of whatever
2110 variables hold references to them, and automatically close whenever
2111 and however you leave that scope:
2112
2113     use IO::File;
2114     ...
2115     sub read_myfile_munged {
2116         my $ALL = shift;
2117         my $handle = new IO::File;
2118         open($handle, "myfile") or die "myfile: $!";
2119         $first = <$handle>
2120             or return ();     # Automatically closed here.
2121         mung $first or die "mung failed";       # Or here.
2122         return $first, <$handle> if $ALL;       # Or here.
2123         $first;                                 # Or here.
2124     }
2125
2126 The filename that is passed to open will have leading and trailing
2127 whitespace deleted.  To open a file with arbitrary weird
2128 characters in it, it's necessary to protect any leading and trailing
2129 whitespace thusly:
2130
2131     $file =~ s#^(\s)#./$1#;
2132     open(FOO, "< $file\0");
2133
2134 If you want a "real" C open() (see L<open(2)> on your system), then
2135 you should use the sysopen() function.  This is another way to
2136 protect your filenames from interpretation.  For example:
2137
2138     use IO::Handle;
2139     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL, 0700)
2140         or die "sysopen $path: $!";
2141     HANDLE->autoflush(1);
2142     HANDLE->print("stuff $$\n");
2143     seek(HANDLE, 0, 0);
2144     print "File contains: ", <HANDLE>;
2145
2146 See L</seek()> for some details about mixing reading and writing.
2147
2148 =item opendir DIRHANDLE,EXPR
2149
2150 Opens a directory named EXPR for processing by readdir(), telldir(),
2151 seekdir(), rewinddir(), and closedir().  Returns TRUE if successful.
2152 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2153
2154 =item ord EXPR
2155
2156 =item ord
2157
2158 Returns the numeric ascii value of the first character of EXPR.  If
2159 EXPR is omitted, uses $_.  For the reverse, see L</chr>.
2160
2161 =item pack TEMPLATE,LIST
2162
2163 Takes an array or list of values and packs it into a binary structure,
2164 returning the string containing the structure.  The TEMPLATE is a
2165 sequence of characters that give the order and type of values, as
2166 follows:
2167
2168     A   An ascii string, will be space padded.
2169     a   An ascii string, will be null padded.
2170     b   A bit string (ascending bit order, like vec()).
2171     B   A bit string (descending bit order).
2172     h   A hex string (low nybble first).
2173     H   A hex string (high nybble first).
2174
2175     c   A signed char value.
2176     C   An unsigned char value.
2177
2178     s   A signed short value.
2179     S   An unsigned short value.
2180           (This 'short' is _exactly_ 16 bits, which may differ from
2181            what a local C compiler calls 'short'.)
2182
2183     i   A signed integer value.
2184     I   An unsigned integer value.
2185           (This 'integer' is _at_least_ 32 bits wide.  Its exact size
2186            depends on what a local C compiler calls 'int', and may
2187            even be larger than the 'long' described in the next item.)
2188
2189     l   A signed long value.
2190     L   An unsigned long value.
2191           (This 'long' is _exactly_ 32 bits, which may differ from
2192            what a local C compiler calls 'long'.)
2193
2194     n   A short in "network" (big-endian) order.
2195     N   A long in "network" (big-endian) order.
2196     v   A short in "VAX" (little-endian) order.
2197     V   A long in "VAX" (little-endian) order.
2198           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2199            _exactly_ 32 bits, respectively.)
2200
2201     f   A single-precision float in the native format.
2202     d   A double-precision float in the native format.
2203
2204     p   A pointer to a null-terminated string.
2205     P   A pointer to a structure (fixed-length string).
2206
2207     u   A uuencoded string.
2208
2209     w   A BER compressed integer.  Its bytes represent an unsigned
2210         integer in base 128, most significant digit first, with as few
2211         digits as possible.  Bit eight (the high bit) is set on each
2212         byte except the last.
2213
2214     x   A null byte.
2215     X   Back up a byte.
2216     @   Null fill to absolute position.
2217
2218 Each letter may optionally be followed by a number which gives a repeat
2219 count.  With all types except "a", "A", "b", "B", "h", "H", and "P" the
2220 pack function will gobble up that many values from the LIST.  A * for the
2221 repeat count means to use however many items are left.  The "a" and "A"
2222 types gobble just one value, but pack it as a string of length count,
2223 padding with nulls or spaces as necessary.  (When unpacking, "A" strips
2224 trailing spaces and nulls, but "a" does not.)  Likewise, the "b" and "B"
2225 fields pack a string that many bits long.  The "h" and "H" fields pack a
2226 string that many nybbles long.  The "p" type packs a pointer to a null-
2227 terminated string.  You are responsible for ensuring the string is not a
2228 temporary value (which can potentially get deallocated before you get
2229 around to using the packed result).  The "P" packs a pointer to a structure
2230 of the size indicated by the length. A NULL pointer is created if the 
2231 corresponding value for "p" or "P" is C<undef>.
2232 Real numbers (floats and doubles) are
2233 in the native machine format only; due to the multiplicity of floating
2234 formats around, and the lack of a standard "network" representation, no
2235 facility for interchange has been made.  This means that packed floating
2236 point data written on one machine may not be readable on another - even if
2237 both use IEEE floating point arithmetic (as the endian-ness of the memory
2238 representation is not part of the IEEE spec).  Note that Perl uses doubles
2239 internally for all numeric calculation, and converting from double into
2240 float and thence back to double again will lose precision (i.e.,
2241 C<unpack("f", pack("f", $foo)>) will not in general equal $foo).
2242
2243 Examples:
2244
2245     $foo = pack("cccc",65,66,67,68);
2246     # foo eq "ABCD"
2247     $foo = pack("c4",65,66,67,68);
2248     # same thing
2249
2250     $foo = pack("ccxxcc",65,66,67,68);
2251     # foo eq "AB\0\0CD"
2252
2253     $foo = pack("s2",1,2);
2254     # "\1\0\2\0" on little-endian
2255     # "\0\1\0\2" on big-endian
2256
2257     $foo = pack("a4","abcd","x","y","z");
2258     # "abcd"
2259
2260     $foo = pack("aaaa","abcd","x","y","z");
2261     # "axyz"
2262
2263     $foo = pack("a14","abcdefg");
2264     # "abcdefg\0\0\0\0\0\0\0"
2265
2266     $foo = pack("i9pl", gmtime);
2267     # a real struct tm (on my system anyway)
2268
2269     sub bintodec {
2270         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2271     }
2272
2273 The same template may generally also be used in the unpack function.
2274
2275 =item package NAMESPACE
2276
2277 Declares the compilation unit as being in the given namespace.  The scope
2278 of the package declaration is from the declaration itself through the end of
2279 the enclosing block (the same scope as the local() operator).  All further
2280 unqualified dynamic identifiers will be in this namespace.  A package
2281 statement affects only dynamic variables--including those you've used
2282 local() on--but I<not> lexical variables created with my().  Typically it
2283 would be the first declaration in a file to be included by the C<require>
2284 or C<use> operator.  You can switch into a package in more than one place;
2285 it influences merely which symbol table is used by the compiler for the
2286 rest of that block.  You can refer to variables and filehandles in other
2287 packages by prefixing the identifier with the package name and a double
2288 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2289 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2290
2291 See L<perlmod/"Packages"> for more information about packages, modules,
2292 and classes.  See L<perlsub> for other scoping issues.
2293
2294 =item pipe READHANDLE,WRITEHANDLE
2295
2296 Opens a pair of connected pipes like the corresponding system call.
2297 Note that if you set up a loop of piped processes, deadlock can occur
2298 unless you are very careful.  In addition, note that Perl's pipes use
2299 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2300 after each command, depending on the application.
2301
2302 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2303 for examples of such things.
2304
2305 =item pop ARRAY
2306
2307 =item pop
2308
2309 Pops and returns the last value of the array, shortening the array by
2310 1.  Has a similar effect to
2311
2312     $tmp = $ARRAY[$#ARRAY--];
2313
2314 If there are no elements in the array, returns the undefined value.
2315 If ARRAY is omitted, pops the
2316 @ARGV array in the main program, and the @_ array in subroutines, just
2317 like shift().
2318
2319 =item pos SCALAR
2320
2321 =item pos
2322
2323 Returns the offset of where the last C<m//g> search left off for the variable
2324 is in question ($_ is used when the variable is not specified).  May be
2325 modified to change that offset.  Such modification will also influence
2326 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2327 L<perlop>.
2328
2329 =item print FILEHANDLE LIST
2330
2331 =item print LIST
2332
2333 =item print
2334
2335 Prints a string or a comma-separated list of strings.  Returns TRUE
2336 if successful.  FILEHANDLE may be a scalar variable name, in which case
2337 the variable contains the name of or a reference to the filehandle, thus introducing one
2338 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2339 token is a term, it may be misinterpreted as an operator unless you
2340 interpose a + or put parentheses around the arguments.)  If FILEHANDLE is
2341 omitted, prints by default to standard output (or to the last selected
2342 output channel--see L</select>).  If LIST is also omitted, prints $_ to
2343 STDOUT.  To set the default output channel to something other than
2344 STDOUT use the select operation.  Note that, because print takes a
2345 LIST, anything in the LIST is evaluated in a list context, and any
2346 subroutine that you call will have one or more of its expressions
2347 evaluated in a list context.  Also be careful not to follow the print
2348 keyword with a left parenthesis unless you want the corresponding right
2349 parenthesis to terminate the arguments to the print--interpose a + or
2350 put parentheses around all the arguments.
2351
2352 Note that if you're storing FILEHANDLES in an array or other expression,
2353 you will have to use a block returning its value instead:
2354
2355     print { $files[$i] } "stuff\n";
2356     print { $OK ? STDOUT : STDERR } "stuff\n";
2357
2358 =item printf FILEHANDLE FORMAT, LIST
2359
2360 =item printf FORMAT, LIST
2361
2362 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>.  The first argument
2363 of the list will be interpreted as the printf format.  If C<use locale> is
2364 in effect, the character used for the decimal point in formatted real numbers
2365 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2366
2367 Don't fall into the trap of using a printf() when a simple
2368 print() would do.  The print() is more efficient, and less
2369 error prone.
2370
2371 =item prototype FUNCTION
2372
2373 Returns the prototype of a function as a string (or C<undef> if the
2374 function has no prototype).  FUNCTION is a reference to, or the name of,
2375 the function whose prototype you want to retrieve.
2376
2377 If FUNCTION is a string starting with C<CORE::>, the rest is taken as
2378 a name for Perl builtin.  If builtin is not I<overridable> (such as
2379 C<qw>) or its arguments cannot be expressed by a prototype (such as
2380 C<system>) - in other words, the builtin does not behave like a Perl
2381 function - returns C<undef>.  Otherwise, the string describing the
2382 equivalent prototype is returned.
2383
2384 =item push ARRAY,LIST
2385
2386 Treats ARRAY as a stack, and pushes the values of LIST
2387 onto the end of ARRAY.  The length of ARRAY increases by the length of
2388 LIST.  Has the same effect as
2389
2390     for $value (LIST) {
2391         $ARRAY[++$#ARRAY] = $value;
2392     }
2393
2394 but is more efficient.  Returns the new number of elements in the array.
2395
2396 =item q/STRING/
2397
2398 =item qq/STRING/
2399
2400 =item qx/STRING/
2401
2402 =item qw/STRING/
2403
2404 Generalized quotes.  See L<perlop>.
2405
2406 =item quotemeta EXPR
2407
2408 =item quotemeta
2409
2410 Returns the value of EXPR with all non-alphanumeric
2411 characters backslashed.  (That is, all characters not matching
2412 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2413 returned string, regardless of any locale settings.)
2414 This is the internal function implementing
2415 the \Q escape in double-quoted strings.
2416
2417 If EXPR is omitted, uses $_.
2418
2419 =item rand EXPR
2420
2421 =item rand
2422
2423 Returns a random fractional number greater than or equal to 0 and less
2424 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
2425 omitted, the value 1 is used.  Automatically calls srand() unless
2426 srand() has already been called.  See also srand().
2427
2428 (Note: If your rand function consistently returns numbers that are too
2429 large or too small, then your version of Perl was probably compiled
2430 with the wrong number of RANDBITS.)
2431
2432 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2433
2434 =item read FILEHANDLE,SCALAR,LENGTH
2435
2436 Attempts to read LENGTH bytes of data into variable SCALAR from the
2437 specified FILEHANDLE.  Returns the number of bytes actually read, or
2438 undef if there was an error.  SCALAR will be grown or shrunk to the
2439 length actually read.  An OFFSET may be specified to place the read
2440 data at some other place than the beginning of the string.  This call
2441 is actually implemented in terms of stdio's fread call.  To get a true
2442 read system call, see sysread().
2443
2444 =item readdir DIRHANDLE
2445
2446 Returns the next directory entry for a directory opened by opendir().
2447 If used in a list context, returns all the rest of the entries in the
2448 directory.  If there are no more entries, returns an undefined value in
2449 a scalar context or a null list in a list context.
2450
2451 If you're planning to filetest the return values out of a readdir(), you'd
2452 better prepend the directory in question.  Otherwise, because we didn't
2453 chdir() there, it would have been testing the wrong file.
2454
2455     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2456     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2457     closedir DIR;
2458
2459 =item readline EXPR
2460
2461 Reads from the file handle EXPR.  In scalar context, a single line
2462 is read and returned.  In list context, reads until end-of-file is
2463 reached and returns a list of lines (however you've defined lines
2464 with $/ or $INPUT_RECORD_SEPARATOR).
2465 This is the internal function implementing the C<E<lt>EXPRE<gt>>
2466 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
2467 operator is discussed in more detail in L<perlop/"I/O Operators">.
2468
2469 =item readlink EXPR
2470
2471 =item readlink
2472
2473 Returns the value of a symbolic link, if symbolic links are
2474 implemented.  If not, gives a fatal error.  If there is some system
2475 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2476 omitted, uses $_.
2477
2478 =item readpipe EXPR
2479
2480 EXPR is interpolated and then executed as a system command.
2481 The collected standard output of the command is returned.
2482 In scalar context, it comes back as a single (potentially
2483 multi-line) string.  In list context, returns a list of lines
2484 (however you've defined lines with $/ or $INPUT_RECORD_SEPARATOR).
2485 This is the internal function implementing the C<qx/EXPR/>
2486 operator, but you can use it directly.  The C<qx/EXPR/>
2487 operator is discussed in more detail in L<perlop/"I/O Operators">.
2488
2489 =item recv SOCKET,SCALAR,LEN,FLAGS
2490
2491 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2492 data into variable SCALAR from the specified SOCKET filehandle.
2493 Actually does a C recvfrom(), so that it can returns the address of the
2494 sender.  Returns the undefined value if there's an error.  SCALAR will
2495 be grown or shrunk to the length actually read.  Takes the same flags
2496 as the system call of the same name.
2497 See L<perlipc/"UDP: Message Passing"> for examples.
2498
2499 =item redo LABEL
2500
2501 =item redo
2502
2503 The C<redo> command restarts the loop block without evaluating the
2504 conditional again.  The C<continue> block, if any, is not executed.  If
2505 the LABEL is omitted, the command refers to the innermost enclosing
2506 loop.  This command is normally used by programs that want to lie to
2507 themselves about what was just input:
2508
2509     # a simpleminded Pascal comment stripper
2510     # (warning: assumes no { or } in strings)
2511     LINE: while (<STDIN>) {
2512         while (s|({.*}.*){.*}|$1 |) {}
2513         s|{.*}| |;
2514         if (s|{.*| |) {
2515             $front = $_;
2516             while (<STDIN>) {
2517                 if (/}/) {      # end of comment?
2518                     s|^|$front{|;
2519                     redo LINE;
2520                 }
2521             }
2522         }
2523         print;
2524     }
2525
2526 =item ref EXPR
2527
2528 =item ref
2529
2530 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2531 is not specified, $_ will be used.  The value returned depends on the
2532 type of thing the reference is a reference to.
2533 Builtin types include:
2534
2535     REF
2536     SCALAR
2537     ARRAY
2538     HASH
2539     CODE
2540     GLOB
2541
2542 If the referenced object has been blessed into a package, then that package
2543 name is returned instead.  You can think of ref() as a typeof() operator.
2544
2545     if (ref($r) eq "HASH") {
2546         print "r is a reference to a hash.\n";
2547     }
2548     if (!ref ($r) {
2549         print "r is not a reference at all.\n";
2550     }
2551
2552 See also L<perlref>.
2553
2554 =item rename OLDNAME,NEWNAME
2555
2556 Changes the name of a file.  Returns 1 for success, 0 otherwise.  Will
2557 not work across file system boundaries.
2558
2559 =item require EXPR
2560
2561 =item require
2562
2563 Demands some semantics specified by EXPR, or by $_ if EXPR is not
2564 supplied.  If EXPR is numeric, demands that the current version of Perl
2565 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2566
2567 Otherwise, demands that a library file be included if it hasn't already
2568 been included.  The file is included via the do-FILE mechanism, which is
2569 essentially just a variety of eval().  Has semantics similar to the following
2570 subroutine:
2571
2572     sub require {
2573         local($filename) = @_;
2574         return 1 if $INC{$filename};
2575         local($realfilename,$result);
2576         ITER: {
2577             foreach $prefix (@INC) {
2578                 $realfilename = "$prefix/$filename";
2579                 if (-f $realfilename) {
2580                     $result = do $realfilename;
2581                     last ITER;
2582                 }
2583             }
2584             die "Can't find $filename in \@INC";
2585         }
2586         die $@ if $@;
2587         die "$filename did not return true value" unless $result;
2588         $INC{$filename} = $realfilename;
2589         $result;
2590     }
2591
2592 Note that the file will not be included twice under the same specified
2593 name.  The file must return TRUE as the last statement to indicate
2594 successful execution of any initialization code, so it's customary to
2595 end such a file with "1;" unless you're sure it'll return TRUE
2596 otherwise.  But it's better just to put the "C<1;>", in case you add more
2597 statements.
2598
2599 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
2600 replaces "F<::>" with "F</>" in the filename for you,
2601 to make it easy to load standard modules.  This form of loading of
2602 modules does not risk altering your namespace.
2603
2604 For a yet-more-powerful import facility, see L</use> and
2605 L<perlmod>.
2606
2607 =item reset EXPR
2608
2609 =item reset
2610
2611 Generally used in a C<continue> block at the end of a loop to clear
2612 variables and reset ?? searches so that they work again.  The
2613 expression is interpreted as a list of single characters (hyphens
2614 allowed for ranges).  All variables and arrays beginning with one of
2615 those letters are reset to their pristine state.  If the expression is
2616 omitted, one-match searches (?pattern?) are reset to match again.  Resets
2617 only variables or searches in the current package.  Always returns
2618 1.  Examples:
2619
2620     reset 'X';          # reset all X variables
2621     reset 'a-z';        # reset lower case variables
2622     reset;              # just reset ?? searches
2623
2624 Resetting "A-Z" is not recommended because you'll wipe out your
2625 ARGV and ENV arrays.  Resets only package variables--lexical variables
2626 are unaffected, but they clean themselves up on scope exit anyway,
2627 so you'll probably want to use them instead.  See L</my>.
2628
2629 =item return EXPR
2630
2631 =item return
2632
2633 Returns from a subroutine, eval(), or do FILE with the value of the
2634 given EXPR.  Evaluation of EXPR may be in a list, scalar, or void
2635 context, depending on how the return value will be used, and the context
2636 may vary from one execution to the next (see wantarray()).  If no EXPR
2637 is given, returns an empty list in a list context, an undefined value in
2638 a scalar context, or nothing in a void context.
2639
2640 (Note that in the absence of a return, a subroutine, eval, or do FILE
2641 will automatically return the value of the last expression evaluated.)
2642
2643 =item reverse LIST
2644
2645 In a list context, returns a list value consisting of the elements
2646 of LIST in the opposite order.  In a scalar context, concatenates the
2647 elements of LIST, and returns a string value consisting of those bytes,
2648 but in the opposite order.
2649
2650     print reverse <>;           # line tac, last line first
2651
2652     undef $/;                   # for efficiency of <>
2653     print scalar reverse <>;    # byte tac, last line tsrif
2654
2655 This operator is also handy for inverting a hash, although there are some
2656 caveats.  If a value is duplicated in the original hash, only one of those
2657 can be represented as a key in the inverted hash.  Also, this has to
2658 unwind one hash and build a whole new one, which may take some time
2659 on a large hash.
2660
2661     %by_name = reverse %by_address;     # Invert the hash
2662
2663 =item rewinddir DIRHANDLE
2664
2665 Sets the current position to the beginning of the directory for the
2666 readdir() routine on DIRHANDLE.
2667
2668 =item rindex STR,SUBSTR,POSITION
2669
2670 =item rindex STR,SUBSTR
2671
2672 Works just like index except that it returns the position of the LAST
2673 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2674 last occurrence at or before that position.
2675
2676 =item rmdir FILENAME
2677
2678 =item rmdir
2679
2680 Deletes the directory specified by FILENAME if it is empty.  If it
2681 succeeds it returns 1, otherwise it returns 0 and sets C<$!> (errno).  If
2682 FILENAME is omitted, uses $_.
2683
2684 =item s///
2685
2686 The substitution operator.  See L<perlop>.
2687
2688 =item scalar EXPR
2689
2690 Forces EXPR to be interpreted in a scalar context and returns the value
2691 of EXPR.
2692
2693     @counts = ( scalar @a, scalar @b, scalar @c );
2694
2695 There is no equivalent operator to force an expression to
2696 be interpolated in a list context because it's in practice never
2697 needed.  If you really wanted to do so, however, you could use
2698 the construction C<@{[ (some expression) ]}>, but usually a simple
2699 C<(some expression)> suffices.
2700
2701 =item seek FILEHANDLE,POSITION,WHENCE
2702
2703 Sets FILEHANDLE's position, just like the fseek() call of stdio.
2704 FILEHANDLE may be an expression whose value gives the name of the
2705 filehandle.  The values for WHENCE are 0 to set the new position to
2706 POSITION, 1 to set it to the current position plus POSITION, and 2 to
2707 set it to EOF plus POSITION (typically negative).  For WHENCE you may
2708 use the constants SEEK_SET, SEEK_CUR, and SEEK_END from either the
2709 IO::Seekable or the POSIX module.  Returns 1 upon success, 0 otherwise.
2710
2711 If you want to position file for sysread() or syswrite(), don't use
2712 seek() -- buffering makes its effect on the file's system position
2713 unpredictable and non-portable.  Use sysseek() instead.
2714
2715 On some systems you have to do a seek whenever you switch between reading
2716 and writing.  Amongst other things, this may have the effect of calling
2717 stdio's clearerr(3).  A WHENCE of 1 (SEEK_CUR) is useful for not moving
2718 the file position:
2719
2720     seek(TEST,0,1);
2721
2722 This is also useful for applications emulating C<tail -f>.  Once you hit
2723 EOF on your read, and then sleep for a while, you might have to stick in a
2724 seek() to reset things.  The seek() doesn't change the current position,
2725 but it I<does> clear the end-of-file condition on the handle, so that the
2726 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
2727
2728 If that doesn't work (some stdios are particularly cantankerous), then
2729 you may need something more like this:
2730
2731     for (;;) {
2732         for ($curpos = tell(FILE); $_ = <FILE>; $curpos = tell(FILE)) {
2733             # search for some stuff and put it into files
2734         }
2735         sleep($for_a_while);
2736         seek(FILE, $curpos, 0);
2737     }
2738
2739 =item seekdir DIRHANDLE,POS
2740
2741 Sets the current position for the readdir() routine on DIRHANDLE.  POS
2742 must be a value returned by telldir().  Has the same caveats about
2743 possible directory compaction as the corresponding system library
2744 routine.
2745
2746 =item select FILEHANDLE
2747
2748 =item select
2749
2750 Returns the currently selected filehandle.  Sets the current default
2751 filehandle for output, if FILEHANDLE is supplied.  This has two
2752 effects: first, a C<write> or a C<print> without a filehandle will
2753 default to this FILEHANDLE.  Second, references to variables related to
2754 output will refer to this output channel.  For example, if you have to
2755 set the top of form format for more than one output channel, you might
2756 do the following:
2757
2758     select(REPORT1);
2759     $^ = 'report1_top';
2760     select(REPORT2);
2761     $^ = 'report2_top';
2762
2763 FILEHANDLE may be an expression whose value gives the name of the
2764 actual filehandle.  Thus:
2765
2766     $oldfh = select(STDERR); $| = 1; select($oldfh);
2767
2768 Some programmers may prefer to think of filehandles as objects with
2769 methods, preferring to write the last example as:
2770
2771     use IO::Handle;
2772     STDERR->autoflush(1);
2773
2774 =item select RBITS,WBITS,EBITS,TIMEOUT
2775
2776 This calls the select(2) system call with the bit masks specified, which
2777 can be constructed using fileno() and vec(), along these lines:
2778
2779     $rin = $win = $ein = '';
2780     vec($rin,fileno(STDIN),1) = 1;
2781     vec($win,fileno(STDOUT),1) = 1;
2782     $ein = $rin | $win;
2783
2784 If you want to select on many filehandles you might wish to write a
2785 subroutine:
2786
2787     sub fhbits {
2788         local(@fhlist) = split(' ',$_[0]);
2789         local($bits);
2790         for (@fhlist) {
2791             vec($bits,fileno($_),1) = 1;
2792         }
2793         $bits;
2794     }
2795     $rin = fhbits('STDIN TTY SOCK');
2796
2797 The usual idiom is:
2798
2799     ($nfound,$timeleft) =
2800       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
2801
2802 or to block until something becomes ready just do this
2803
2804     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
2805
2806 Most systems do not bother to return anything useful in $timeleft, so
2807 calling select() in a scalar context just returns $nfound.
2808
2809 Any of the bit masks can also be undef.  The timeout, if specified, is
2810 in seconds, which may be fractional.  Note: not all implementations are
2811 capable of returning the $timeleft.  If not, they always return
2812 $timeleft equal to the supplied $timeout.
2813
2814 You can effect a sleep of 250 milliseconds this way:
2815
2816     select(undef, undef, undef, 0.25);
2817
2818 B<WARNING>: Do not attempt to mix buffered I/O (like read() or E<lt>FHE<gt>)
2819 with select().  You have to use sysread() instead.
2820
2821 =item semctl ID,SEMNUM,CMD,ARG
2822
2823 Calls the System V IPC function semctl.  If CMD is &IPC_STAT or
2824 &GETALL, then ARG must be a variable which will hold the returned
2825 semid_ds structure or semaphore value array.  Returns like ioctl: the
2826 undefined value for error, "0 but true" for zero, or the actual return
2827 value otherwise.
2828
2829 =item semget KEY,NSEMS,FLAGS
2830
2831 Calls the System V IPC function semget.  Returns the semaphore id, or
2832 the undefined value if there is an error.
2833
2834 =item semop KEY,OPSTRING
2835
2836 Calls the System V IPC function semop to perform semaphore operations
2837 such as signaling and waiting.  OPSTRING must be a packed array of
2838 semop structures.  Each semop structure can be generated with
2839 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
2840 operations is implied by the length of OPSTRING.  Returns TRUE if
2841 successful, or FALSE if there is an error.  As an example, the
2842 following code waits on semaphore $semnum of semaphore id $semid:
2843
2844     $semop = pack("sss", $semnum, -1, 0);
2845     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
2846
2847 To signal the semaphore, replace "-1" with "1".
2848
2849 =item send SOCKET,MSG,FLAGS,TO
2850
2851 =item send SOCKET,MSG,FLAGS
2852
2853 Sends a message on a socket.  Takes the same flags as the system call
2854 of the same name.  On unconnected sockets you must specify a
2855 destination to send TO, in which case it does a C sendto().  Returns
2856 the number of characters sent, or the undefined value if there is an
2857 error.
2858 See L<perlipc/"UDP: Message Passing"> for examples.
2859
2860 =item setpgrp PID,PGRP
2861
2862 Sets the current process group for the specified PID, 0 for the current
2863 process.  Will produce a fatal error if used on a machine that doesn't
2864 implement setpgrp(2).  If the arguments are omitted, it defaults to
2865 0,0.  Note that the POSIX version of setpgrp() does not accept any
2866 arguments, so only setpgrp 0,0 is portable.
2867
2868 =item setpriority WHICH,WHO,PRIORITY
2869
2870 Sets the current priority for a process, a process group, or a user.
2871 (See setpriority(2).)  Will produce a fatal error if used on a machine
2872 that doesn't implement setpriority(2).
2873
2874 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
2875
2876 Sets the socket option requested.  Returns undefined if there is an
2877 error.  OPTVAL may be specified as undef if you don't want to pass an
2878 argument.
2879
2880 =item shift ARRAY
2881
2882 =item shift
2883
2884 Shifts the first value of the array off and returns it, shortening the
2885 array by 1 and moving everything down.  If there are no elements in the
2886 array, returns the undefined value.  If ARRAY is omitted, shifts the
2887 @_ array within the lexical scope of subroutines and formats, and the
2888 @ARGV array at file scopes or within the lexical scopes established by
2889 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
2890 See also unshift(), push(), and pop().  Shift() and unshift() do the
2891 same thing to the left end of an array that pop() and push() do to the
2892 right end.
2893
2894 =item shmctl ID,CMD,ARG
2895
2896 Calls the System V IPC function shmctl.  If CMD is &IPC_STAT, then ARG
2897 must be a variable which will hold the returned shmid_ds structure.
2898 Returns like ioctl: the undefined value for error, "0 but true" for
2899 zero, or the actual return value otherwise.
2900
2901 =item shmget KEY,SIZE,FLAGS
2902
2903 Calls the System V IPC function shmget.  Returns the shared memory
2904 segment id, or the undefined value if there is an error.
2905
2906 =item shmread ID,VAR,POS,SIZE
2907
2908 =item shmwrite ID,STRING,POS,SIZE
2909
2910 Reads or writes the System V shared memory segment ID starting at
2911 position POS for size SIZE by attaching to it, copying in/out, and
2912 detaching from it.  When reading, VAR must be a variable which will
2913 hold the data read.  When writing, if STRING is too long, only SIZE
2914 bytes are used; if STRING is too short, nulls are written to fill out
2915 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
2916
2917 =item shutdown SOCKET,HOW
2918
2919 Shuts down a socket connection in the manner indicated by HOW, which
2920 has the same interpretation as in the system call of the same name.
2921
2922 =item sin EXPR
2923
2924 =item sin
2925
2926 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
2927 returns sine of $_.
2928
2929 For the inverse sine operation, you may use the POSIX::asin()
2930 function, or use this relation:
2931
2932     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
2933
2934 =item sleep EXPR
2935
2936 =item sleep
2937
2938 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
2939 May be interrupted by sending the process a SIGALRM.  Returns the
2940 number of seconds actually slept.  You probably cannot mix alarm() and
2941 sleep() calls, because sleep() is often implemented using alarm().
2942
2943 On some older systems, it may sleep up to a full second less than what
2944 you requested, depending on how it counts seconds.  Most modern systems
2945 always sleep the full amount.
2946
2947 For delays of finer granularity than one second, you may use Perl's
2948 syscall() interface to access setitimer(2) if your system supports it,
2949 or else see L</select()> below.
2950
2951 See also the POSIX module's sigpause() function.
2952
2953 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
2954
2955 Opens a socket of the specified kind and attaches it to filehandle
2956 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
2957 system call of the same name.  You should "use Socket;" first to get
2958 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2959
2960 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
2961
2962 Creates an unnamed pair of sockets in the specified domain, of the
2963 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
2964 for the system call of the same name.  If unimplemented, yields a fatal
2965 error.  Returns TRUE if successful.
2966
2967 =item sort SUBNAME LIST
2968
2969 =item sort BLOCK LIST
2970
2971 =item sort LIST
2972
2973 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
2974 is omitted, sorts in standard string comparison order.  If SUBNAME is
2975 specified, it gives the name of a subroutine that returns an integer
2976 less than, equal to, or greater than 0, depending on how the elements
2977 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
2978 operators are extremely useful in such routines.)  SUBNAME may be a
2979 scalar variable name, in which case the value provides the name of the
2980 subroutine to use.  In place of a SUBNAME, you can provide a BLOCK as
2981 an anonymous, in-line sort subroutine.
2982
2983 In the interests of efficiency the normal calling code for subroutines is
2984 bypassed, with the following effects: the subroutine may not be a
2985 recursive subroutine, and the two elements to be compared are passed into
2986 the subroutine not via @_ but as the package global variables $a and
2987 $b (see example below).  They are passed by reference, so don't
2988 modify $a and $b.  And don't try to declare them as lexicals either.
2989
2990 You also cannot exit out of the sort block or subroutine using any of the
2991 loop control operators described in L<perlsyn> or with goto().
2992
2993 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
2994 current collation locale.  See L<perllocale>.
2995
2996 Examples:
2997
2998     # sort lexically
2999     @articles = sort @files;
3000
3001     # same thing, but with explicit sort routine
3002     @articles = sort {$a cmp $b} @files;
3003
3004     # now case-insensitively
3005     @articles = sort {uc($a) cmp uc($b)} @files;
3006
3007     # same thing in reversed order
3008     @articles = sort {$b cmp $a} @files;
3009
3010     # sort numerically ascending
3011     @articles = sort {$a <=> $b} @files;
3012
3013     # sort numerically descending
3014     @articles = sort {$b <=> $a} @files;
3015
3016     # sort using explicit subroutine name
3017     sub byage {
3018         $age{$a} <=> $age{$b};  # presuming numeric
3019     }
3020     @sortedclass = sort byage @class;
3021
3022     # this sorts the %age hash by value instead of key
3023     # using an in-line function
3024     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3025
3026     sub backwards { $b cmp $a; }
3027     @harry = ('dog','cat','x','Cain','Abel');
3028     @george = ('gone','chased','yz','Punished','Axed');
3029     print sort @harry;
3030             # prints AbelCaincatdogx
3031     print sort backwards @harry;
3032             # prints xdogcatCainAbel
3033     print sort @george, 'to', @harry;
3034             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3035
3036     # inefficiently sort by descending numeric compare using
3037     # the first integer after the first = sign, or the
3038     # whole record case-insensitively otherwise
3039
3040     @new = sort {
3041         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3042                             ||
3043                     uc($a)  cmp  uc($b)
3044     } @old;
3045
3046     # same thing, but much more efficiently;
3047     # we'll build auxiliary indices instead
3048     # for speed
3049     @nums = @caps = ();
3050     for (@old) {
3051         push @nums, /=(\d+)/;
3052         push @caps, uc($_);
3053     }
3054
3055     @new = @old[ sort {
3056                         $nums[$b] <=> $nums[$a]
3057                                  ||
3058                         $caps[$a] cmp $caps[$b]
3059                        } 0..$#old
3060                ];
3061
3062     # same thing using a Schwartzian Transform (no temps)
3063     @new = map { $_->[0] }
3064         sort { $b->[1] <=> $a->[1]
3065                         ||
3066                $a->[2] cmp $b->[2]
3067         } map { [$_, /=(\d+)/, uc($_)] } @old;
3068
3069 If you're using strict, you I<MUST NOT> declare $a
3070 and $b as lexicals.  They are package globals.  That means
3071 if you're in the C<main> package, it's
3072
3073     @articles = sort {$main::b <=> $main::a} @files;
3074
3075 or just
3076
3077     @articles = sort {$::b <=> $::a} @files;
3078
3079 but if you're in the C<FooPack> package, it's
3080
3081     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3082
3083 The comparison function is required to behave.  If it returns
3084 inconsistent results (sometimes saying $x[1] is less than $x[2] and
3085 sometimes saying the opposite, for example) the Perl interpreter will
3086 probably crash and dump core.  This is entirely due to and dependent
3087 upon your system's qsort(3) library routine; this routine often avoids
3088 sanity checks in the interest of speed.
3089
3090 =item splice ARRAY,OFFSET,LENGTH,LIST
3091
3092 =item splice ARRAY,OFFSET,LENGTH
3093
3094 =item splice ARRAY,OFFSET
3095
3096 Removes the elements designated by OFFSET and LENGTH from an array, and
3097 replaces them with the elements of LIST, if any.  Returns the elements
3098 removed from the array.  The array grows or shrinks as necessary.  If
3099 LENGTH is omitted, removes everything from OFFSET onward.  The
3100 following equivalences hold (assuming C<$[ == 0>):
3101
3102     push(@a,$x,$y)      splice(@a,$#a+1,0,$x,$y)
3103     pop(@a)             splice(@a,-1)
3104     shift(@a)           splice(@a,0,1)
3105     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3106     $a[$x] = $y         splice(@a,$x,1,$y);
3107
3108 Example, assuming array lengths are passed before arrays:
3109
3110     sub aeq {   # compare two list values
3111         local(@a) = splice(@_,0,shift);
3112         local(@b) = splice(@_,0,shift);
3113         return 0 unless @a == @b;       # same len?
3114         while (@a) {
3115             return 0 if pop(@a) ne pop(@b);
3116         }
3117         return 1;
3118     }
3119     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3120
3121 =item split /PATTERN/,EXPR,LIMIT
3122
3123 =item split /PATTERN/,EXPR
3124
3125 =item split /PATTERN/
3126
3127 =item split
3128
3129 Splits a string into an array of strings, and returns it.
3130
3131 If not in a list context, returns the number of fields found and splits into
3132 the @_ array.  (In a list context, you can force the split into @_ by
3133 using C<??> as the pattern delimiters, but it still returns the array
3134 value.)  The use of implicit split to @_ is deprecated, however.
3135
3136 If EXPR is omitted, splits the $_ string.  If PATTERN is also omitted,
3137 splits on whitespace (after skipping any leading whitespace).  Anything
3138 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3139 that the delimiter may be longer than one character.)
3140
3141 If LIMIT is specified and is not negative, splits into no more than
3142 that many fields (though it may split into fewer).  If LIMIT is
3143 unspecified, trailing null fields are stripped (which potential users
3144 of pop() would do well to remember).  If LIMIT is negative, it is
3145 treated as if an arbitrarily large LIMIT had been specified.
3146
3147 A pattern matching the null string (not to be confused with
3148 a null pattern C<//>, which is just one member of the set of patterns
3149 matching a null string) will split the value of EXPR into separate
3150 characters at each point it matches that way.  For example:
3151
3152     print join(':', split(/ */, 'hi there'));
3153
3154 produces the output 'h:i:t:h:e:r:e'.
3155
3156 The LIMIT parameter can be used to split a line partially
3157
3158     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3159
3160 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3161 one larger than the number of variables in the list, to avoid
3162 unnecessary work.  For the list above LIMIT would have been 4 by
3163 default.  In time critical applications it behooves you not to split
3164 into more fields than you really need.
3165
3166 If the PATTERN contains parentheses, additional array elements are
3167 created from each matching substring in the delimiter.
3168
3169     split(/([,-])/, "1-10,20", 3);
3170
3171 produces the list value
3172
3173     (1, '-', 10, ',', 20)
3174
3175 If you had the entire header of a normal Unix email message in $header,
3176 you could split it up into fields and their values this way:
3177
3178     $header =~ s/\n\s+/ /g;  # fix continuation lines
3179     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
3180
3181 The pattern C</PATTERN/> may be replaced with an expression to specify
3182 patterns that vary at runtime.  (To do runtime compilation only once,
3183 use C</$variable/o>.)
3184
3185 As a special case, specifying a PATTERN of space (C<' '>) will split on
3186 white space just as split with no arguments does.  Thus, split(' ') can
3187 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3188 will give you as many null initial fields as there are leading spaces.
3189 A split on /\s+/ is like a split(' ') except that any leading
3190 whitespace produces a null first field.  A split with no arguments
3191 really does a C<split(' ', $_)> internally.
3192
3193 Example:
3194
3195     open(passwd, '/etc/passwd');
3196     while (<passwd>) {
3197         ($login, $passwd, $uid, $gid, $gcos,
3198             $home, $shell) = split(/:/);
3199         ...
3200     }
3201
3202 (Note that $shell above will still have a newline on it.  See L</chop>,
3203 L</chomp>, and L</join>.)
3204
3205 =item sprintf FORMAT, LIST
3206
3207 Returns a string formatted by the usual printf conventions of the
3208 C library function sprintf().  See L<sprintf(3)> or L<printf(3)>
3209 on your system for an explanation of the general principles.
3210
3211 Perl does all of its own sprintf() formatting -- it emulates the C
3212 function sprintf(), but it doesn't use it (except for floating-point
3213 numbers, and even then only the standard modifiers are allowed).  As a
3214 result, any non-standard extensions in your local sprintf() are not
3215 available from Perl.
3216
3217 Perl's sprintf() permits the following universally-known conversions:
3218
3219    %%   a percent sign
3220    %c   a character with the given number
3221    %s   a string
3222    %d   a signed integer, in decimal
3223    %u   an unsigned integer, in decimal
3224    %o   an unsigned integer, in octal
3225    %x   an unsigned integer, in hexadecimal
3226    %e   a floating-point number, in scientific notation
3227    %f   a floating-point number, in fixed decimal notation
3228    %g   a floating-point number, in %e or %f notation
3229
3230 In addition, Perl permits the following widely-supported conversions:
3231
3232    %X   like %x, but using upper-case letters
3233    %E   like %e, but using an upper-case "E"
3234    %G   like %g, but with an upper-case "E" (if applicable)
3235    %p   a pointer (outputs the Perl value's address in hexadecimal)
3236    %n   special: *stores* the number of characters output so far
3237         into the next variable in the parameter list 
3238
3239 Finally, for backward (and we do mean "backward") compatibility, Perl
3240 permits these unnecessary but widely-supported conversions:
3241
3242    %i   a synonym for %d
3243    %D   a synonym for %ld
3244    %U   a synonym for %lu
3245    %O   a synonym for %lo
3246    %F   a synonym for %f
3247
3248 Perl permits the following universally-known flags between the C<%>
3249 and the conversion letter:
3250
3251    space   prefix positive number with a space
3252    +       prefix positive number with a plus sign
3253    -       left-justify within the field
3254    0       use zeros, not spaces, to right-justify
3255    #       prefix octal with "0", hex with "0x"
3256    number  minimum field width
3257    .number "precision": digits after decimal point for floating-point,
3258            max length for string, minimum length for integer
3259    l       interpret integer as C type "long" or "unsigned long"
3260    h       interpret integer as C type "short" or "unsigned short"
3261
3262 There is also one Perl-specific flag:
3263
3264    V       interpret integer as Perl's standard integer type
3265
3266 Where a number would appear in the flags, an asterisk ("*") may be
3267 used instead, in which case Perl uses the next item in the parameter
3268 list as the given number (that is, as the field width or precision).
3269 If a field width obtained through "*" is negative, it has the same
3270 effect as the '-' flag: left-justification.
3271
3272 If C<use locale> is in effect, the character used for the decimal
3273 point in formatted real numbers is affected by the LC_NUMERIC locale.
3274 See L<perllocale>.
3275
3276 =item sqrt EXPR
3277
3278 =item sqrt
3279
3280 Return the square root of EXPR.  If EXPR is omitted, returns square
3281 root of $_.
3282
3283 =item srand EXPR
3284
3285 =item srand
3286
3287 Sets the random number seed for the C<rand> operator.  If EXPR is
3288 omitted, uses a semi-random value based on the current time and process
3289 ID, among other things.  In versions of Perl prior to 5.004 the default
3290 seed was just the current time().  This isn't a particularly good seed,
3291 so many old programs supply their own seed value (often C<time ^ $$> or
3292 C<time ^ ($$ + ($$ << 15))>), but that isn't necessary any more.
3293
3294 In fact, it's usually not necessary to call srand() at all, because if
3295 it is not called explicitly, it is called implicitly at the first use of
3296 the C<rand> operator.  However, this was not the case in version of Perl
3297 before 5.004, so if your script will run under older Perl versions, it
3298 should call srand().
3299
3300 Note that you need something much more random than the default seed for
3301 cryptographic purposes.  Checksumming the compressed output of one or more
3302 rapidly changing operating system status programs is the usual method.  For
3303 example:
3304
3305     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3306
3307 If you're particularly concerned with this, see the Math::TrulyRandom
3308 module in CPAN.
3309
3310 Do I<not> call srand() multiple times in your program unless you know
3311 exactly what you're doing and why you're doing it.  The point of the
3312 function is to "seed" the rand() function so that rand() can produce
3313 a different sequence each time you run your program.  Just do it once at the
3314 top of your program, or you I<won't> get random numbers out of rand()!
3315
3316 Frequently called programs (like CGI scripts) that simply use
3317
3318     time ^ $$
3319
3320 for a seed can fall prey to the mathematical property that
3321
3322     a^b == (a+1)^(b+1)
3323
3324 one-third of the time.  So don't do that.
3325
3326 =item stat FILEHANDLE
3327
3328 =item stat EXPR
3329
3330 =item stat
3331
3332 Returns a 13-element array giving the status info for a file, either the
3333 file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted, it
3334 stats $_.  Returns a null list if the stat fails.  Typically used as
3335 follows:
3336
3337
3338     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3339        $atime,$mtime,$ctime,$blksize,$blocks)
3340            = stat($filename);
3341
3342 Not all fields are supported on all filesystem types.  Here are the
3343 meaning of the fields:
3344
3345   0 dev      device number of filesystem
3346   1 ino      inode number
3347   2 mode     file mode  (type and permissions)
3348   3 nlink    number of (hard) links to the file
3349   4 uid      numeric user ID of file's owner
3350   5 gid      numeric group ID of file's owner
3351   6 rdev     the device identifier (special files only)
3352   7 size     total size of file, in bytes
3353   8 atime    last access time since the epoch
3354   9 mtime    last modify time since the epoch
3355  10 ctime    inode change time (NOT creation time!) since the epoch
3356  11 blksize  preferred block size for file system I/O
3357  12 blocks   actual number of blocks allocated
3358
3359 (The epoch was at 00:00 January 1, 1970 GMT.)
3360
3361 If stat is passed the special filehandle consisting of an underline, no
3362 stat is done, but the current contents of the stat structure from the
3363 last stat or filetest are returned.  Example:
3364
3365     if (-x $file && (($d) = stat(_)) && $d < 0) {
3366         print "$file is executable NFS file\n";
3367     }
3368
3369 (This works on machines only for which the device number is negative under NFS.)
3370
3371 =item study SCALAR
3372
3373 =item study
3374
3375 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3376 doing many pattern matches on the string before it is next modified.
3377 This may or may not save time, depending on the nature and number of
3378 patterns you are searching on, and on the distribution of character
3379 frequencies in the string to be searched -- you probably want to compare
3380 run times with and without it to see which runs faster.  Those loops
3381 which scan for many short constant strings (including the constant
3382 parts of more complex patterns) will benefit most.  You may have only
3383 one study active at a time -- if you study a different scalar the first
3384 is "unstudied".  (The way study works is this: a linked list of every
3385 character in the string to be searched is made, so we know, for
3386 example, where all the 'k' characters are.  From each search string,
3387 the rarest character is selected, based on some static frequency tables
3388 constructed from some C programs and English text.  Only those places
3389 that contain this "rarest" character are examined.)
3390
3391 For example, here is a loop which inserts index producing entries
3392 before any line containing a certain pattern:
3393
3394     while (<>) {
3395         study;
3396         print ".IX foo\n" if /\bfoo\b/;
3397         print ".IX bar\n" if /\bbar\b/;
3398         print ".IX blurfl\n" if /\bblurfl\b/;
3399         ...
3400         print;
3401     }
3402
3403 In searching for /\bfoo\b/, only those locations in $_ that contain "f"
3404 will be looked at, because "f" is rarer than "o".  In general, this is
3405 a big win except in pathological cases.  The only question is whether
3406 it saves you more time than it took to build the linked list in the
3407 first place.
3408
3409 Note that if you have to look for strings that you don't know till
3410 runtime, you can build an entire loop as a string and eval that to
3411 avoid recompiling all your patterns all the time.  Together with
3412 undefining $/ to input entire files as one record, this can be very
3413 fast, often faster than specialized programs like fgrep(1).  The following
3414 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3415 out the names of those files that contain a match:
3416
3417     $search = 'while (<>) { study;';
3418     foreach $word (@words) {
3419         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3420     }
3421     $search .= "}";
3422     @ARGV = @files;
3423     undef $/;
3424     eval $search;               # this screams
3425     $/ = "\n";          # put back to normal input delimiter
3426     foreach $file (sort keys(%seen)) {
3427         print $file, "\n";
3428     }
3429
3430 =item sub BLOCK
3431
3432 =item sub NAME
3433
3434 =item sub NAME BLOCK
3435
3436 This is subroutine definition, not a real function I<per se>.  With just a
3437 NAME (and possibly prototypes), it's just a forward declaration.  Without
3438 a NAME, it's an anonymous function declaration, and does actually return a
3439 value: the CODE ref of the closure you just created.  See L<perlsub> and
3440 L<perlref> for details.
3441
3442 =item substr EXPR,OFFSET,LEN
3443
3444 =item substr EXPR,OFFSET
3445
3446 Extracts a substring out of EXPR and returns it.  First character is at
3447 offset 0, or whatever you've set C<$[> to (but don't do that).
3448 If OFFSET is negative (or more precisely, less than C<$[>), starts
3449 that far from the end of the string.  If LEN is omitted, returns
3450 everything to the end of the string.  If LEN is negative, leaves that
3451 many characters off the end of the string.
3452
3453 If you specify a substring which is partly outside the string, the part
3454 within the string is returned.    If the substring is totally outside
3455 the string a warning is produced.
3456
3457 You can use the substr() function
3458 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3459 something shorter than LEN, the string will shrink, and if you assign
3460 something longer than LEN, the string will grow to accommodate it.  To
3461 keep the string the same length you may need to pad or chop your value
3462 using sprintf().
3463
3464 =item symlink OLDFILE,NEWFILE
3465
3466 Creates a new filename symbolically linked to the old filename.
3467 Returns 1 for success, 0 otherwise.  On systems that don't support
3468 symbolic links, produces a fatal error at run time.  To check for that,
3469 use eval:
3470
3471     $symlink_exists = (eval {symlink("","")};, $@ eq '');
3472
3473 =item syscall LIST
3474
3475 Calls the system call specified as the first element of the list,
3476 passing the remaining elements as arguments to the system call.  If
3477 unimplemented, produces a fatal error.  The arguments are interpreted
3478 as follows: if a given argument is numeric, the argument is passed as
3479 an int.  If not, the pointer to the string value is passed.  You are
3480 responsible to make sure a string is pre-extended long enough to
3481 receive any result that might be written into a string.  If your
3482 integer arguments are not literals and have never been interpreted in a
3483 numeric context, you may need to add 0 to them to force them to look
3484 like numbers.
3485
3486     require 'syscall.ph';               # may need to run h2ph
3487     syscall(&SYS_write, fileno(STDOUT), "hi there\n", 9);
3488
3489 Note that Perl supports passing of up to only 14 arguments to your system call,
3490 which in practice should usually suffice.
3491
3492 Syscall returns whatever value returned by the system call it calls.
3493 If the system call fails, syscall returns -1 and sets C<$!> (errno).
3494 Note that some system calls can legitimately return -1.  The proper
3495 way to handle such calls is to assign C<$!=0;> before the call and
3496 check the value of <$!> if syscall returns -1.
3497
3498 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
3499 number of the read end of the pipe it creates.  There is no way
3500 to retrieve the file number of the other end.  You can avoid this 
3501 problem by using C<pipe> instead.
3502
3503 =item sysopen FILEHANDLE,FILENAME,MODE
3504
3505 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3506
3507 Opens the file whose filename is given by FILENAME, and associates it
3508 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3509 the name of the real filehandle wanted.  This function calls the
3510 underlying operating system's C<open> function with the parameters
3511 FILENAME, MODE, PERMS.
3512
3513 The possible values and flag bits of the MODE parameter are
3514 system-dependent; they are available via the standard module C<Fcntl>.
3515 However, for historical reasons, some values are universal: zero means
3516 read-only, one means write-only, and two means read/write.
3517
3518 If the file named by FILENAME does not exist and the C<open> call
3519 creates it (typically because MODE includes the O_CREAT flag), then
3520 the value of PERMS specifies the permissions of the newly created
3521 file.  If PERMS is omitted, the default value is 0666, which allows
3522 read and write for all.  This default is reasonable: see C<umask>.
3523
3524 The IO::File module provides a more object-oriented approach, if you're
3525 into that kind of thing.
3526
3527 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
3528
3529 =item sysread FILEHANDLE,SCALAR,LENGTH
3530
3531 Attempts to read LENGTH bytes of data into variable SCALAR from the
3532 specified FILEHANDLE, using the system call read(2).  It bypasses
3533 stdio, so mixing this with other kinds of reads, print(), write(),
3534 seek(), or tell() can cause confusion because stdio usually buffers
3535 data.  Returns the number of bytes actually read, or undef if there
3536 was an error.  SCALAR will be grown or shrunk so that the last byte
3537 actually read is the last byte of the scalar after the read.
3538
3539 An OFFSET may be specified to place the read data at some place in the
3540 string other than the beginning.  A negative OFFSET specifies
3541 placement at that many bytes counting backwards from the end of the
3542 string.  A positive OFFSET greater than the length of SCALAR results
3543 in the string being padded to the required size with "\0" bytes before
3544 the result of the read is appended.
3545
3546 =item sysseek FILEHANDLE,POSITION,WHENCE
3547
3548 Sets FILEHANDLE's system position using the system call lseek(2).  It
3549 bypasses stdio, so mixing this with reads (other than sysread()),
3550 print(), write(), seek(), or tell() may cause confusion.  FILEHANDLE may
3551 be an expression whose value gives the name of the filehandle.  The
3552 values for WHENCE are 0 to set the new position to POSITION, 1 to set
3553 the it to the current position plus POSITION, and 2 to set it to EOF
3554 plus POSITION (typically negative).  For WHENCE, you may use the
3555 constants SEEK_SET, SEEK_CUR, and SEEK_END from either the IO::Seekable
3556 or the POSIX module.
3557
3558 Returns the new position, or the undefined value on failure.  A position
3559 of zero is returned as the string "0 but true"; thus sysseek() returns
3560 TRUE on success and FALSE on failure, yet you can still easily determine
3561 the new position.
3562
3563 =item system LIST
3564
3565 Does exactly the same thing as "exec LIST" except that a fork is done
3566 first, and the parent process waits for the child process to complete.
3567 Note that argument processing varies depending on the number of
3568 arguments.  The return value is the exit status of the program as
3569 returned by the wait() call.  To get the actual exit value divide by
3570 256.  See also L</exec>.  This is I<NOT> what you want to use to capture
3571 the output from a command, for that you should use merely backticks or
3572 qx//, as described in L<perlop/"`STRING`">.
3573
3574 Because system() and backticks block SIGINT and SIGQUIT, killing the
3575 program they're running doesn't actually interrupt your program.
3576
3577     @args = ("command", "arg1", "arg2");
3578     system(@args) == 0
3579          or die "system @args failed: $?"
3580
3581 Here's a more elaborate example of analysing the return value from
3582 system() on a Unix system to check for all possibilities, including for
3583 signals and core dumps.
3584
3585     $rc = 0xffff & system @args;
3586     printf "system(%s) returned %#04x: ", "@args", $rc;
3587     if ($rc == 0) {
3588         print "ran with normal exit\n";
3589     }
3590     elsif ($rc == 0xff00) {
3591         print "command failed: $!\n";
3592     }
3593     elsif ($rc > 0x80) {
3594         $rc >>= 8;
3595         print "ran with non-zero exit status $rc\n";
3596     }
3597     else {
3598         print "ran with ";
3599         if ($rc &   0x80) {
3600             $rc &= ~0x80;
3601             print "core dump from ";
3602         }
3603         print "signal $rc\n"
3604     }
3605     $ok = ($rc != 0);
3606
3607 When the arguments get executed via the system shell, results will
3608 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
3609 for details.
3610
3611 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
3612
3613 =item syswrite FILEHANDLE,SCALAR,LENGTH
3614
3615 Attempts to write LENGTH bytes of data from variable SCALAR to the
3616 specified FILEHANDLE, using the system call write(2).  It bypasses
3617 stdio, so mixing this with reads (other than sysread()), print(),
3618 write(), seek(), or tell() may cause confusion because stdio usually
3619 buffers data.  Returns the number of bytes actually written, or undef
3620 if there was an error.  If the LENGTH is greater than the available
3621 data in the SCALAR after the OFFSET, only as much data as is available
3622 will be written.
3623
3624 An OFFSET may be specified to write the data from some part of the
3625 string other than the beginning.  A negative OFFSET specifies writing
3626 that many bytes counting backwards from the end of the string.  In the
3627 case the SCALAR is empty you can use OFFSET but only zero offset.
3628
3629 =item tell FILEHANDLE
3630
3631 =item tell
3632
3633 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
3634 expression whose value gives the name of the actual filehandle.  If
3635 FILEHANDLE is omitted, assumes the file last read.
3636
3637 =item telldir DIRHANDLE
3638
3639 Returns the current position of the readdir() routines on DIRHANDLE.
3640 Value may be given to seekdir() to access a particular location in a
3641 directory.  Has the same caveats about possible directory compaction as
3642 the corresponding system library routine.
3643
3644 =item tie VARIABLE,CLASSNAME,LIST
3645
3646 This function binds a variable to a package class that will provide the
3647 implementation for the variable.  VARIABLE is the name of the variable
3648 to be enchanted.  CLASSNAME is the name of a class implementing objects
3649 of correct type.  Any additional arguments are passed to the "new"
3650 method of the class (meaning TIESCALAR, TIEARRAY, or TIEHASH).
3651 Typically these are arguments such as might be passed to the dbm_open()
3652 function of C.  The object returned by the "new" method is also
3653 returned by the tie() function, which would be useful if you want to
3654 access other methods in CLASSNAME.
3655
3656 Note that functions such as keys() and values() may return huge array
3657 values when used on large objects, like DBM files.  You may prefer to
3658 use the each() function to iterate over such.  Example:
3659
3660     # print out history file offsets
3661     use NDBM_File;
3662     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3663     while (($key,$val) = each %HIST) {
3664         print $key, ' = ', unpack('L',$val), "\n";
3665     }
3666     untie(%HIST);
3667
3668 A class implementing a hash should have the following methods:
3669
3670     TIEHASH classname, LIST
3671     DESTROY this
3672     FETCH this, key
3673     STORE this, key, value
3674     DELETE this, key
3675     EXISTS this, key
3676     FIRSTKEY this
3677     NEXTKEY this, lastkey
3678
3679 A class implementing an ordinary array should have the following methods:
3680
3681     TIEARRAY classname, LIST
3682     DESTROY this
3683     FETCH this, key
3684     STORE this, key, value
3685     [others TBD]
3686
3687 A class implementing a scalar should have the following methods:
3688
3689     TIESCALAR classname, LIST
3690     DESTROY this
3691     FETCH this,
3692     STORE this, value
3693
3694 Unlike dbmopen(), the tie() function will not use or require a module
3695 for you--you need to do that explicitly yourself.  See L<DB_File>
3696 or the F<Config> module for interesting tie() implementations.
3697
3698 =item tied VARIABLE
3699
3700 Returns a reference to the object underlying VARIABLE (the same value
3701 that was originally returned by the tie() call which bound the variable
3702 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
3703 package.
3704
3705 =item time
3706
3707 Returns the number of non-leap seconds since whatever time the system
3708 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
3709 and 00:00:00 UTC, January 1, 1970 for most other systems).
3710 Suitable for feeding to gmtime() and localtime().
3711
3712 =item times
3713
3714 Returns a four-element array giving the user and system times, in
3715 seconds, for this process and the children of this process.
3716
3717     ($user,$system,$cuser,$csystem) = times;
3718
3719 =item tr///
3720
3721 The translation operator.  Same as y///. See L<perlop>.
3722
3723 =item truncate FILEHANDLE,LENGTH
3724
3725 =item truncate EXPR,LENGTH
3726
3727 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
3728 specified length.  Produces a fatal error if truncate isn't implemented
3729 on your system.
3730
3731 =item uc EXPR
3732
3733 =item uc
3734
3735 Returns an uppercased version of EXPR.  This is the internal function
3736 implementing the \U escape in double-quoted strings.
3737 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3738
3739 If EXPR is omitted, uses $_.
3740
3741 =item ucfirst EXPR
3742
3743 =item ucfirst
3744
3745 Returns the value of EXPR with the first character uppercased.  This is
3746 the internal function implementing the \u escape in double-quoted strings.
3747 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
3748
3749 If EXPR is omitted, uses $_.
3750
3751 =item umask EXPR
3752
3753 =item umask
3754
3755 Sets the umask for the process to EXPR and returns the previous value.
3756 If EXPR is omitted, merely returns the current umask.  Remember that a
3757 umask is a number, usually given in octal; it is I<not> a string of octal
3758 digits.  See also L</oct>, if all you have is a string.
3759
3760 =item undef EXPR
3761
3762 =item undef
3763
3764 Undefines the value of EXPR, which must be an lvalue.  Use only on a
3765 scalar value, an entire array, an entire hash, or a subroutine name (using
3766 "&").  (Using undef() will probably not do what you expect on most
3767 predefined variables or DBM list values, so don't do that.)  Always
3768 returns the undefined value.  You can omit the EXPR, in which case
3769 nothing is undefined, but you still get an undefined value that you
3770 could, for instance, return from a subroutine, assign to a variable or
3771 pass as a parameter.  Examples:
3772
3773     undef $foo;
3774     undef $bar{'blurfl'};             # Compare to: delete $bar{'blurfl'};
3775     undef @ary;
3776     undef %hash;
3777     undef &mysub;
3778     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
3779     select undef, undef, undef, 0.25;
3780     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
3781
3782 =item unlink LIST
3783
3784 =item unlink
3785
3786 Deletes a list of files.  Returns the number of files successfully
3787 deleted.
3788
3789     $cnt = unlink 'a', 'b', 'c';
3790     unlink @goners;
3791     unlink <*.bak>;
3792
3793 Note: unlink will not delete directories unless you are superuser and
3794 the B<-U> flag is supplied to Perl.  Even if these conditions are
3795 met, be warned that unlinking a directory can inflict damage on your
3796 filesystem.  Use rmdir instead.
3797
3798 If LIST is omitted, uses $_.
3799
3800 =item unpack TEMPLATE,EXPR
3801
3802 Unpack does the reverse of pack: it takes a string representing a
3803 structure and expands it out into a list value, returning the array
3804 value.  (In a scalar context, it returns merely the first value
3805 produced.)  The TEMPLATE has the same format as in the pack function.
3806 Here's a subroutine that does substring:
3807
3808     sub substr {
3809         local($what,$where,$howmuch) = @_;
3810         unpack("x$where a$howmuch", $what);
3811     }
3812
3813 and then there's
3814
3815     sub ordinal { unpack("c",$_[0]); } # same as ord()
3816
3817 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
3818 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
3819 themselves.  Default is a 16-bit checksum.  For example, the following
3820 computes the same number as the System V sum program:
3821
3822     while (<>) {
3823         $checksum += unpack("%16C*", $_);
3824     }
3825     $checksum %= 65536;
3826
3827 The following efficiently counts the number of set bits in a bit vector:
3828
3829     $setbits = unpack("%32b*", $selectmask);
3830
3831 =item untie VARIABLE
3832
3833 Breaks the binding between a variable and a package.  (See tie().)
3834
3835 =item unshift ARRAY,LIST
3836
3837 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
3838 depending on how you look at it.  Prepends list to the front of the
3839 array, and returns the new number of elements in the array.
3840
3841     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
3842
3843 Note the LIST is prepended whole, not one element at a time, so the
3844 prepended elements stay in the same order.  Use reverse to do the
3845 reverse.
3846
3847 =item use Module LIST
3848
3849 =item use Module
3850
3851 =item use Module VERSION LIST
3852
3853 =item use VERSION
3854
3855 Imports some semantics into the current package from the named module,
3856 generally by aliasing certain subroutine or variable names into your
3857 package.  It is exactly equivalent to
3858
3859     BEGIN { require Module; import Module LIST; }
3860
3861 except that Module I<must> be a bareword.
3862
3863 If the first argument to C<use> is a number, it is treated as a version
3864 number instead of a module name.  If the version of the Perl interpreter
3865 is less than VERSION, then an error message is printed and Perl exits
3866 immediately.  This is often useful if you need to check the current
3867 Perl version before C<use>ing library modules which have changed in
3868 incompatible ways from older versions of Perl.  (We try not to do
3869 this more than we have to.)
3870
3871 The BEGIN forces the require and import to happen at compile time.  The
3872 require makes sure the module is loaded into memory if it hasn't been
3873 yet.  The import is not a builtin--it's just an ordinary static method
3874 call into the "Module" package to tell the module to import the list of
3875 features back into the current package.  The module can implement its
3876 import method any way it likes, though most modules just choose to
3877 derive their import method via inheritance from the Exporter class that
3878 is defined in the Exporter module.  See L<Exporter>.  If no import
3879 method can be found then the error is currently silently ignored.  This
3880 may change to a fatal error in a future version.
3881
3882 If you don't want your namespace altered, explicitly supply an empty list:
3883
3884     use Module ();
3885
3886 That is exactly equivalent to
3887
3888     BEGIN { require Module; }
3889
3890 If the VERSION argument is present between Module and LIST, then the
3891 C<use> will call the VERSION method in class Module with the given
3892 version as an argument.  The default VERSION method, inherited from
3893 the Universal class, croaks if the given version is larger than the
3894 value of the variable $Module::VERSION.  (Note that there is not a
3895 comma after VERSION!)
3896
3897 Because this is a wide-open interface, pragmas (compiler directives)
3898 are also implemented this way.  Currently implemented pragmas are:
3899
3900     use integer;
3901     use diagnostics;
3902     use sigtrap qw(SEGV BUS);
3903     use strict  qw(subs vars refs);
3904     use subs    qw(afunc blurfl);
3905
3906 These pseudo-modules import semantics into the current block scope, unlike
3907 ordinary modules, which import symbols into the current package (which are
3908 effective through the end of the file).
3909
3910 There's a corresponding "no" command that unimports meanings imported
3911 by use, i.e., it calls C<unimport Module LIST> instead of C<import>.
3912
3913     no integer;
3914     no strict 'refs';
3915
3916 If no unimport method can be found the call fails with a fatal error.
3917
3918 See L<perlmod> for a list of standard modules and pragmas.
3919
3920 =item utime LIST
3921
3922 Changes the access and modification times on each file of a list of
3923 files.  The first two elements of the list must be the NUMERICAL access
3924 and modification times, in that order.  Returns the number of files
3925 successfully changed.  The inode modification time of each file is set
3926 to the current time.  Example of a "touch" command:
3927
3928     #!/usr/bin/perl
3929     $now = time;
3930     utime $now, $now, @ARGV;
3931
3932 =item values HASH
3933
3934 Returns a normal array consisting of all the values of the named hash.
3935 (In a scalar context, returns the number of values.)  The values are
3936 returned in an apparently random order, but it is the same order as either
3937 the keys() or each() function would produce on the same hash.  As a side
3938 effect, it resets HASH's iterator.  See also keys(), each(), and sort().
3939
3940 =item vec EXPR,OFFSET,BITS
3941
3942 Treats the string in EXPR as a vector of unsigned integers, and
3943 returns the value of the bit field specified by OFFSET.  BITS specifies
3944 the number of bits that are reserved for each entry in the bit
3945 vector.  This must be a power of two from 1 to 32. vec() may also be
3946 assigned to, in which case parentheses are needed to give the expression
3947 the correct precedence as in
3948
3949     vec($image, $max_x * $x + $y, 8) = 3;
3950
3951 Vectors created with vec() can also be manipulated with the logical
3952 operators |, &, and ^, which will assume a bit vector operation is
3953 desired when both operands are strings.
3954
3955 To transform a bit vector into a string or array of 0's and 1's, use these:
3956
3957     $bits = unpack("b*", $vector);
3958     @bits = split(//, unpack("b*", $vector));
3959
3960 If you know the exact length in bits, it can be used in place of the *.
3961
3962 =item wait
3963
3964 Waits for a child process to terminate and returns the pid of the
3965 deceased process, or -1 if there are no child processes.  The status is
3966 returned in C<$?>.
3967
3968 =item waitpid PID,FLAGS
3969
3970 Waits for a particular child process to terminate and returns the pid
3971 of the deceased process, or -1 if there is no such child process.  The
3972 status is returned in C<$?>.  If you say
3973
3974     use POSIX ":sys_wait_h";
3975     ...
3976     waitpid(-1,&WNOHANG);
3977
3978 then you can do a non-blocking wait for any process.  Non-blocking wait
3979 is available on machines supporting either the waitpid(2) or
3980 wait4(2) system calls.  However, waiting for a particular pid with
3981 FLAGS of 0 is implemented everywhere.  (Perl emulates the system call
3982 by remembering the status values of processes that have exited but have
3983 not been harvested by the Perl script yet.)
3984
3985 =item wantarray
3986
3987 Returns TRUE if the context of the currently executing subroutine is
3988 looking for a list value.  Returns FALSE if the context is looking
3989 for a scalar.  Returns the undefined value if the context is looking
3990 for no value (void context).
3991
3992     return unless defined wantarray;    # don't bother doing more
3993     my @a = complex_calculation();
3994     return wantarray ? @a : "@a";
3995
3996 =item warn LIST
3997
3998 Produces a message on STDERR just like die(), but doesn't exit or throw
3999 an exception.
4000
4001 No message is printed if there is a C<$SIG{__WARN__}> handler
4002 installed.  It is the handler's responsibility to deal with the message
4003 as it sees fit (like, for instance, converting it into a die()).  Most
4004 handlers must therefore make arrangements to actually display the
4005 warnings that they are not prepared to deal with, by calling warn()
4006 again in the handler.  Note that this is quite safe and will not
4007 produce an endless loop, since C<__WARN__> hooks are not called from
4008 inside one.
4009
4010 You will find this behavior is slightly different from that of
4011 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
4012 instead call die() again to change it).
4013
4014 Using a C<__WARN__> handler provides a powerful way to silence all
4015 warnings (even the so-called mandatory ones).  An example:
4016
4017     # wipe out *all* compile-time warnings
4018     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
4019     my $foo = 10;
4020     my $foo = 20;          # no warning about duplicate my $foo,
4021                            # but hey, you asked for it!
4022     # no compile-time or run-time warnings before here
4023     $DOWARN = 1;
4024
4025     # run-time warnings enabled after here
4026     warn "\$foo is alive and $foo!";     # does show up
4027
4028 See L<perlvar> for details on setting C<%SIG> entries, and for more
4029 examples.
4030
4031 =item write FILEHANDLE
4032
4033 =item write EXPR
4034
4035 =item write
4036
4037 Writes a formatted record (possibly multi-line) to the specified file,
4038 using the format associated with that file.  By default the format for
4039 a file is the one having the same name as the filehandle, but the
4040 format for the current output channel (see the select() function) may be set
4041 explicitly by assigning the name of the format to the C<$~> variable.
4042
4043 Top of form processing is handled automatically:  if there is
4044 insufficient room on the current page for the formatted record, the
4045 page is advanced by writing a form feed, a special top-of-page format
4046 is used to format the new page header, and then the record is written.
4047 By default the top-of-page format is the name of the filehandle with
4048 "_TOP" appended, but it may be dynamically set to the format of your
4049 choice by assigning the name to the C<$^> variable while the filehandle is
4050 selected.  The number of lines remaining on the current page is in
4051 variable C<$->, which can be set to 0 to force a new page.
4052
4053 If FILEHANDLE is unspecified, output goes to the current default output
4054 channel, which starts out as STDOUT but may be changed by the
4055 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
4056 is evaluated and the resulting string is used to look up the name of
4057 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
4058
4059 Note that write is I<NOT> the opposite of read.  Unfortunately.
4060
4061 =item y///
4062
4063 The translation operator.  Same as tr///.  See L<perlop>.
4064
4065 =back