perly.y

   1 /*    perly.y
   2  *
   3  *    Copyright (c) 1991-2002, 2003, 2004 Larry Wall
   4  *
   5  *    You may distribute under the terms of either the GNU General Public
   6  *    License or the Artistic License, as specified in the README file.
   7  *
   8  */
   9
  10 /*
  11  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
  12  * All that is gold does not glitter, not all those who wander are lost.'
  13  */
  14
  15 /* This file holds the grammar for the Perl language. If edited, you need
  16  * to run regen_perly.pl, which re-creates the files perly.h, perly.tab
  17  * and perly.act which are derived from this.
  18  *
  19  * The main job of of this grammar is to call the various newFOO()
  20  * functions in op.c to build a syntax tree of OP structs.
  21  * It relies on the lexer in toke.c to do the tokenizing.
  22  */
  23
  24 /*  Make the parser re-entrant. */
  25
  26 %pure_parser
  27
  28 %start prog
  29
  30 %union {
  31     I32 ival;
  32     char *pval;
  33 #ifdef PERL_MAD
  34     TOKEN* tkval;
  35 #endif
  36     OP *opval;
  37     GV *gvval;
  38 }
  39
  40 %token <ival> '{'
  41
  42 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF
  43 %token <opval> FUNC0SUB UNIOPSUB LSTOPSUB
  44 %token <pval> LABEL
  45 %token <ival> FORMAT SUB ANONSUB PACKAGE USE
  46 %token <ival> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
  47 %token <ival> GIVEN WHEN DEFAULT
  48 %token <ival> LOOPEX DOTDOT
  49 %token <ival> FUNC0 FUNC1 FUNC UNIOP LSTOP
  50 %token <ival> RELOP EQOP MULOP ADDOP
  51 %token <ival> DOLSHARP DO HASHBRACK NOAMP
  52 %token <ival> LOCAL MY MYSUB REQUIRE
  53 %token COLONATTR
  54
  55 %type <ival> prog decl format startsub startanonsub startformsub mintro
  56 %type <ival> progstart remember mremember '&' savescope mydefsv
  57 %type <opval> block mblock lineseq line loop cond else
  58 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
  59 %type <opval> argexpr nexpr texpr iexpr mexpr mnexpr miexpr
  60 %type <opval> listexpr listexprcom indirob listop method
  61 %type <opval> formname subname proto subbody cont my_scalar
  62 %type <opval> subattrlist myattrlist mysubrout myattrterm myterm
  63 %type <opval> termbinop termunop anonymous termdo
  64 %type <opval> switch case
  65 %type <pval> label
  66
  67 %nonassoc PREC_LOW
  68 %nonassoc LOOPEX
  69
  70 %left <ival> OROP DOROP
  71 %left ANDOP
  72 %right NOTOP
  73 %nonassoc LSTOP LSTOPSUB
  74 %left ','
  75 %right <ival> ASSIGNOP
  76 %right '?' ':'
  77 %nonassoc DOTDOT
  78 %left OROR DORDOR
  79 %left ANDAND
  80 %left <ival> BITOROP
  81 %left <ival> BITANDOP
  82 %nonassoc EQOP
  83 %nonassoc RELOP
  84 %nonassoc UNIOP UNIOPSUB
  85 %nonassoc REQUIRE
  86 %left <ival> SHIFTOP
  87 %left ADDOP
  88 %left MULOP
  89 %left <ival> MATCHOP
  90 %right '!' '~' UMINUS REFGEN
  91 %right <ival> POWOP
  92 %nonassoc PREINC PREDEC POSTINC POSTDEC
  93 %left ARROW
  94 %nonassoc <ival> ')'
  95 %left '('
  96 %left '[' '{'
  97
  98 %token PEG
  99
 100 %% /* RULES */
 101
 102 /* The whole program */
 103 prog    :       progstart
 104         /*CONTINUED*/   lineseq
 105                         { $$ = $1; newPROG(block_end($1,$2)); }
 106         ;
 107
 108 /* An ordinary block */
 109 block   :       '{' remember lineseq '}'
 110                         { if (PL_copline > (line_t)$1)
 111                               PL_copline = (line_t)$1;
 112                           $$ = block_end($2, $3); }
 113         ;
 114
 115 remember:       /* NULL */      /* start a full lexical scope */
 116                         { $$ = block_start(TRUE); }
 117         ;
 118
 119 mydefsv:        /* NULL */      /* lexicalize $_ */
 120                         { $$ = (I32) allocmy("$_"); }
 121         ;
 122
 123 progstart:
 124                 {
 125                     PL_expect = XSTATE; $$ = block_start(TRUE);
 126                 }
 127         ;
 128
 129
 130 mblock  :       '{' mremember lineseq '}'
 131                         { if (PL_copline > (line_t)$1)
 132                               PL_copline = (line_t)$1;
 133                           $$ = block_end($2, $3); }
 134         ;
 135
 136 mremember:      /* NULL */      /* start a partial lexical scope */
 137                         { $$ = block_start(FALSE); }
 138         ;
 139
 140 savescope:      /* NULL */      /* remember stack pos in case of error */
 141                 { $$ = PL_savestack_ix; }
 142
 143 /* A collection of "lines" in the program */
 144 lineseq :       /* NULL */
 145                         { $$ = Nullop; }
 146         |       lineseq decl
 147                         { $$ = $1; }
 148         |       lineseq savescope line
 149                         {   LEAVE_SCOPE($2);
 150                             $$ = append_list(OP_LINESEQ,
 151                                 (LISTOP*)$1, (LISTOP*)$3);
 152                             PL_pad_reset_pending = TRUE;
 153                             if ($1 && $3) PL_hints |= HINT_BLOCK_SCOPE; }
 154         ;
 155
 156 /* A "line" in the program */
 157 line    :       label cond
 158                         { $$ = newSTATEOP(0, $1, $2); }
 159         |       loop    /* loops add their own labels */
 160         |       switch  /* ... and so do switches */
 161                         { $$ = $1; }
 162         |       label case
 163                         { $$ = newSTATEOP(0, $1, $2); }
 164         |       label ';'
 165                         { if ($1 != Nullch) {
 166                               $$ = newSTATEOP(0, $1, newOP(OP_NULL, 0));
 167                             }
 168                             else {
 169                               $$ = Nullop;
 170                               PL_copline = NOLINE;
 171                             }
 172                             PL_expect = XSTATE; }
 173         |       label sideff ';'
 174                         { $$ = newSTATEOP(0, $1, $2);
 175                           PL_expect = XSTATE; }
 176         ;
 177
 178 /* An expression which may have a side-effect */
 179 sideff  :       error
 180                         { $$ = Nullop; }
 181         |       expr
 182                         { $$ = $1; }
 183         |       expr IF expr
 184                         { $$ = newLOGOP(OP_AND, 0, $3, $1); }
 185         |       expr UNLESS expr
 186                         { $$ = newLOGOP(OP_OR, 0, $3, $1); }
 187         |       expr WHILE expr
 188                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1); }
 189         |       expr UNTIL iexpr
 190                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);}
 191         |       expr FOR expr
 192                         { $$ = newFOROP(0, Nullch, (line_t)$2,
 193                                         Nullop, $3, $1, Nullop); }
 194         ;
 195
 196 /* else and elsif blocks */
 197 else    :       /* NULL */
 198                         { $$ = Nullop; }
 199         |       ELSE mblock
 200                         { ($2)->op_flags |= OPf_PARENS; $$ = scope($2); }
 201         |       ELSIF '(' mexpr ')' mblock else
 202                         { PL_copline = (line_t)$1;
 203                             $$ = newCONDOP(0, $3, scope($5), $6);
 204                             PL_hints |= HINT_BLOCK_SCOPE; }
 205         ;
 206
 207 /* Real conditional expressions */
 208 cond    :       IF '(' remember mexpr ')' mblock else
 209                         { PL_copline = (line_t)$1;
 210                             $$ = block_end($3,
 211                                    newCONDOP(0, $4, scope($6), $7)); }
 212         |       UNLESS '(' remember miexpr ')' mblock else
 213                         { PL_copline = (line_t)$1;
 214                             $$ = block_end($3,
 215                                    newCONDOP(0, $4, scope($6), $7)); }
 216         ;
 217
 218 /* Cases for a switch statement */
 219 case    :       WHEN '(' remember mexpr ')' mblock
 220         { $$ = block_end($3,
 221                 newWHENOP($4, scope($6))); }
 222         |       DEFAULT block
 223         { $$ = newWHENOP(0, scope($2)); }
 224         ;
 225
 226 /* Continue blocks */
 227 cont    :       /* NULL */
 228                         { $$ = Nullop; }
 229         |       CONTINUE block
 230                         { $$ = scope($2); }
 231         ;
 232
 233 /* Loops: while, until, for, and a bare block */
 234 loop    :       label WHILE '(' remember texpr ')' mintro mblock cont
 235                         { PL_copline = (line_t)$2;
 236                             $$ = block_end($4,
 237                                    newSTATEOP(0, $1,
 238                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 239                                                 $2, $5, $8, $9, $7))); }
 240         |       label UNTIL '(' remember iexpr ')' mintro mblock cont
 241                         { PL_copline = (line_t)$2;
 242                             $$ = block_end($4,
 243                                    newSTATEOP(0, $1,
 244                                      newWHILEOP(0, 1, (LOOP*)Nullop,
 245                                                 $2, $5, $8, $9, $7))); }
 246         |       label FOR MY remember my_scalar '(' mexpr ')' mblock cont
 247                         { $$ = block_end($4,
 248                                  newFOROP(0, $1, (line_t)$2, $5, $7, $9, $10)); }
 249         |       label FOR scalar '(' remember mexpr ')' mblock cont
 250                         { $$ = block_end($5,
 251                                  newFOROP(0, $1, (line_t)$2, mod($3, OP_ENTERLOOP),
 252                                           $6, $8, $9)); }
 253         |       label FOR '(' remember mexpr ')' mblock cont
 254                         { $$ = block_end($4,
 255                                  newFOROP(0, $1, (line_t)$2, Nullop, $5, $7, $8)); }
 256         |       label FOR '(' remember mnexpr ';' texpr ';' mintro mnexpr ')'
 257                     mblock
 258                         /* basically fake up an initialize-while lineseq */
 259                         { OP *forop;
 260                           PL_copline = (line_t)$2;
 261                           forop = newSTATEOP(0, $1,
 262                                             newWHILEOP(0, 1, (LOOP*)Nullop,
 263                                                 $2, scalar($7),
 264                                                 $12, $10, $9));
 265                           if ($5) {
 266                                 forop = append_elem(OP_LINESEQ,
 267                                         newSTATEOP(0, ($1?savepv($1):Nullch),
 268                                                    $5),
 269                                         forop);
 270                           }
 271
 272                           $$ = block_end($4, forop); }
 273         |       label block cont  /* a block is a loop that happens once */
 274                         { $$ = newSTATEOP(0, $1,
 275                                  newWHILEOP(0, 1, (LOOP*)Nullop,
 276                                             NOLINE, Nullop, $2, $3, 0)); }
 277         ;
 278
 279 /* Switch blocks */
 280 switch  :       label GIVEN '(' remember mydefsv mexpr ')' mblock
 281                         { PL_copline = (line_t) $2;
 282                             $$ = block_end($4,
 283                                 newSTATEOP(0, $1,
 284                                     newGIVENOP($6, scope($8),
 285                                         (PADOFFSET) $5) )); }
 286         ;
 287
 288 /* determine whether there are any new my declarations */
 289 mintro  :       /* NULL */
 290                         { $$ = (PL_min_intro_pending &&
 291                             PL_max_intro_pending >=  PL_min_intro_pending);
 292                           intro_my(); }
 293
 294 /* Normal expression */
 295 nexpr   :       /* NULL */
 296                         { $$ = Nullop; }
 297         |       sideff
 298         ;
 299
 300 /* Boolean expression */
 301 texpr   :       /* NULL means true */
 302                         { (void)scan_num("1", &yylval); $$ = yylval.opval; }
 303         |       expr
 304         ;
 305
 306 /* Inverted boolean expression */
 307 iexpr   :       expr
 308                         { $$ = invert(scalar($1)); }
 309         ;
 310
 311 /* Expression with its own lexical scope */
 312 mexpr   :       expr
 313                         { $$ = $1; intro_my(); }
 314         ;
 315
 316 mnexpr  :       nexpr
 317                         { $$ = $1; intro_my(); }
 318         ;
 319
 320 miexpr  :       iexpr
 321                         { $$ = $1; intro_my(); }
 322         ;
 323
 324 /* Optional "MAIN:"-style loop labels */
 325 label   :       /* empty */
 326                         { $$ = Nullch; }
 327         |       LABEL
 328         ;
 329
 330 /* Some kind of declaration - does not take part in the parse tree */
 331 decl    :       format
 332                         { $$ = 0; }
 333         |       subrout
 334                         { $$ = 0; }
 335         |       mysubrout
 336                         { $$ = 0; }
 337         |       package
 338                         { $$ = 0; }
 339         |       use
 340                         { $$ = 0; }
 341         ;
 342
 343 format  :       FORMAT startformsub formname block
 344                         { SvREFCNT_inc(PL_compcv);
 345                           newFORM($2, $3, $4); }
 346         ;
 347
 348 formname:       WORD            { $$ = $1; }
 349         |       /* NULL */      { $$ = Nullop; }
 350         ;
 351
 352 /* Unimplemented "my sub foo { }" */
 353 mysubrout:      MYSUB startsub subname proto subattrlist subbody
 354                         { SvREFCNT_inc(PL_compcv);
 355                           newMYSUB($2, $3, $4, $5, $6); }
 356         ;
 357
 358 /* Subroutine definition */
 359 subrout :       SUB startsub subname proto subattrlist subbody
 360                         { SvREFCNT_inc(PL_compcv);
 361                           newATTRSUB($2, $3, $4, $5, $6); }
 362         ;
 363
 364 startsub:       /* NULL */      /* start a regular subroutine scope */
 365                         { $$ = start_subparse(FALSE, 0);
 366                             SAVEFREESV(PL_compcv); }
 367         ;
 368
 369 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
 370                         { $$ = start_subparse(FALSE, CVf_ANON);
 371                             SAVEFREESV(PL_compcv); }
 372         ;
 373
 374 startformsub:   /* NULL */      /* start a format subroutine scope */
 375                         { $$ = start_subparse(TRUE, 0);
 376                             SAVEFREESV(PL_compcv); }
 377         ;
 378
 379 /* Name of a subroutine - must be a bareword, could be special */
 380 subname :       WORD    { const char *const name = SvPV_nolen_const(((SVOP*)$1)->op_sv);
 381                           if (strEQ(name, "BEGIN") || strEQ(name, "END")
 382                               || strEQ(name, "INIT") || strEQ(name, "CHECK"))
 383                               CvSPECIAL_on(PL_compcv);
 384                           $$ = $1; }
 385         ;
 386
 387 /* Subroutine prototype */
 388 proto   :       /* NULL */
 389                         { $$ = Nullop; }
 390         |       THING
 391         ;
 392
 393 /* Optional list of subroutine attributes */
 394 subattrlist:    /* NULL */
 395                         { $$ = Nullop; }
 396         |       COLONATTR THING
 397                         { $$ = $2; }
 398         |       COLONATTR
 399                         { $$ = Nullop; }
 400         ;
 401
 402 /* List of attributes for a "my" variable declaration */
 403 myattrlist:     COLONATTR THING
 404                         { $$ = $2; }
 405         |       COLONATTR
 406                         { $$ = Nullop; }
 407         ;
 408
 409 /* Subroutine body - either null or a block */
 410 subbody :       block   { $$ = $1; }
 411         |       ';'     { $$ = Nullop; PL_expect = XSTATE; }
 412         ;
 413
 414 package :       PACKAGE WORD ';'
 415                         { package($2); }
 416         ;
 417
 418 use     :       USE startsub
 419                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
 420                     WORD WORD listexpr ';'
 421                          { SvREFCNT_inc(PL_compcv);
 422                            utilize($1, $2, $4, $5, $6); }
 423         ;
 424
 425 /* Ordinary expressions; logical combinations */
 426 expr    :       expr ANDOP expr
 427                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 428         |       expr OROP expr
 429                         { $$ = newLOGOP($2, 0, $1, $3); }
 430         |       expr DOROP expr
 431                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
 432         |       argexpr %prec PREC_LOW
 433         ;
 434
 435 /* Expressions are a list of terms joined by commas */
 436 argexpr :       argexpr ','
 437                         { $$ = $1; }
 438         |       argexpr ',' term
 439                         { $$ = append_elem(OP_LIST, $1, $3); }
 440         |       term %prec PREC_LOW
 441         ;
 442
 443 /* List operators */
 444 listop  :       LSTOP indirob argexpr /* map {...} @args or print $fh @args */
 445                         { $$ = convert($1, OPf_STACKED,
 446                                 prepend_elem(OP_LIST, newGVREF($1,$2), $3) ); }
 447         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
 448                         { $$ = convert($1, OPf_STACKED,
 449                                 prepend_elem(OP_LIST, newGVREF($1,$3), $4) ); }
 450         |       term ARROW method '(' listexprcom ')' /* $foo->bar(list) */
 451                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 452                                 append_elem(OP_LIST,
 453                                     prepend_elem(OP_LIST, scalar($1), $5),
 454                                     newUNOP(OP_METHOD, 0, $3))); }
 455         |       term ARROW method                     /* $foo->bar */
 456                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 457                                 append_elem(OP_LIST, scalar($1),
 458                                     newUNOP(OP_METHOD, 0, $3))); }
 459         |       METHOD indirob listexpr              /* new Class @args */
 460                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 461                                 append_elem(OP_LIST,
 462                                     prepend_elem(OP_LIST, $2, $3),
 463                                     newUNOP(OP_METHOD, 0, $1))); }
 464         |       FUNCMETH indirob '(' listexprcom ')' /* method $object (@args) */
 465                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
 466                                 append_elem(OP_LIST,
 467                                     prepend_elem(OP_LIST, $2, $4),
 468                                     newUNOP(OP_METHOD, 0, $1))); }
 469         |       LSTOP listexpr                       /* print @args */
 470                         { $$ = convert($1, 0, $2); }
 471         |       FUNC '(' listexprcom ')'             /* print (@args) */
 472                         { $$ = convert($1, 0, $3); }
 473         |       LSTOPSUB startanonsub block /* sub f(&@);   f { foo } ... */
 474                         { SvREFCNT_inc(PL_compcv);
 475                           $3 = newANONATTRSUB($2, 0, Nullop, $3); }
 476                     listexpr            %prec LSTOP  /* ... @bar */
 477                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 478                                  append_elem(OP_LIST,
 479                                    prepend_elem(OP_LIST, $3, $5), $1)); }
 480         ;
 481
 482 /* Names of methods. May use $object->$methodname */
 483 method  :       METHOD
 484         |       scalar
 485         ;
 486
 487 /* Some kind of subscripted expression */
 488 subscripted:    star '{' expr ';' '}'        /* *main::{something} */
 489                         /* In this and all the hash accessors, ';' is
 490                          * provided by the tokeniser */
 491                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3));
 492                             PL_expect = XOPERATOR; }
 493         |       scalar '[' expr ']'          /* $array[$element] */
 494                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3)); }
 495         |       term ARROW '[' expr ']'      /* somearef->[$element] */
 496                         { $$ = newBINOP(OP_AELEM, 0,
 497                                         ref(newAVREF($1),OP_RV2AV),
 498                                         scalar($4));}
 499         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
 500                         { $$ = newBINOP(OP_AELEM, 0,
 501                                         ref(newAVREF($1),OP_RV2AV),
 502                                         scalar($3));}
 503         |       scalar '{' expr ';' '}'    /* $foo->{bar();} */
 504                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
 505                             PL_expect = XOPERATOR; }
 506         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
 507                         { $$ = newBINOP(OP_HELEM, 0,
 508                                         ref(newHVREF($1),OP_RV2HV),
 509                                         jmaybe($4));
 510                             PL_expect = XOPERATOR; }
 511         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
 512                         { $$ = newBINOP(OP_HELEM, 0,
 513                                         ref(newHVREF($1),OP_RV2HV),
 514                                         jmaybe($3));
 515                             PL_expect = XOPERATOR; }
 516         |       term ARROW '(' ')'          /* $subref->() */
 517                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 518                                    newCVREF(0, scalar($1))); }
 519         |       term ARROW '(' expr ')'     /* $subref->(@args) */
 520                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 521                                    append_elem(OP_LIST, $4,
 522                                        newCVREF(0, scalar($1)))); }
 523
 524         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
 525                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 526                                    append_elem(OP_LIST, $3,
 527                                                newCVREF(0, scalar($1)))); }
 528         |       subscripted '(' ')'        /* $foo->{bar}->() */
 529                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 530                                    newCVREF(0, scalar($1))); }
 531         |       '(' expr ')' '[' expr ']'            /* list slice */
 532                         { $$ = newSLICEOP(0, $5, $2); }
 533         |       '(' ')' '[' expr ']'                 /* empty list slice! */
 534                         { $$ = newSLICEOP(0, $4, Nullop); }
 535     ;
 536
 537 /* Binary operators between terms */
 538 termbinop       :       term ASSIGNOP term             /* $x = $y */
 539                         { $$ = newASSIGNOP(OPf_STACKED, $1, $2, $3); }
 540         |       term POWOP term                        /* $x ** $y */
 541                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 542         |       term MULOP term                        /* $x * $y, $x x $y */
 543                         {   if ($2 != OP_REPEAT)
 544                                 scalar($1);
 545                             $$ = newBINOP($2, 0, $1, scalar($3)); }
 546         |       term ADDOP term                        /* $x + $y */
 547                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 548         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
 549                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 550         |       term RELOP term                        /* $x > $y, etc. */
 551                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 552         |       term EQOP term                         /* $x == $y, $x eq $y */
 553                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 554         |       term BITANDOP term                     /* $x & $y */
 555                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 556         |       term BITOROP term                      /* $x | $y */
 557                         { $$ = newBINOP($2, 0, scalar($1), scalar($3)); }
 558         |       term DOTDOT term                       /* $x..$y, $x...$y */
 559                         { $$ = newRANGE($2, scalar($1), scalar($3));}
 560         |       term ANDAND term                       /* $x && $y */
 561                         { $$ = newLOGOP(OP_AND, 0, $1, $3); }
 562         |       term OROR term                         /* $x || $y */
 563                         { $$ = newLOGOP(OP_OR, 0, $1, $3); }
 564         |       term DORDOR term                       /* $x // $y */
 565                         { $$ = newLOGOP(OP_DOR, 0, $1, $3); }
 566         |       term MATCHOP term                      /* $x =~ /$y/ */
 567                         { $$ = bind_match($2, $1, $3); }
 568     ;
 569
 570 /* Unary operators and terms */
 571 termunop : '-' term %prec UMINUS                       /* -$x */
 572                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2)); }
 573         |       '+' term %prec UMINUS                  /* +$x */
 574                         { $$ = $2; }
 575         |       '!' term                               /* !$x */
 576                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 577         |       '~' term                               /* ~$x */
 578                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));}
 579         |       term POSTINC                           /* $x++ */
 580                         { $$ = newUNOP(OP_POSTINC, 0,
 581                                         mod(scalar($1), OP_POSTINC)); }
 582         |       term POSTDEC                           /* $x-- */
 583                         { $$ = newUNOP(OP_POSTDEC, 0,
 584                                         mod(scalar($1), OP_POSTDEC)); }
 585         |       PREINC term                            /* ++$x */
 586                         { $$ = newUNOP(OP_PREINC, 0,
 587                                         mod(scalar($2), OP_PREINC)); }
 588         |       PREDEC term                            /* --$x */
 589                         { $$ = newUNOP(OP_PREDEC, 0,
 590                                         mod(scalar($2), OP_PREDEC)); }
 591
 592     ;
 593
 594 /* Constructors for anonymous data */
 595 anonymous:      '[' expr ']'
 596                         { $$ = newANONLIST($2); }
 597         |       '[' ']'
 598                         { $$ = newANONLIST(Nullop); }
 599         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
 600                         { $$ = newANONHASH($2); }
 601         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
 602                         { $$ = newANONHASH(Nullop); }
 603         |       ANONSUB startanonsub proto subattrlist block    %prec '('
 604                         { SvREFCNT_inc(PL_compcv);
 605                           $$ = newANONATTRSUB($2, $3, $4, $5); }
 606
 607     ;
 608
 609 /* Things called with "do" */
 610 termdo  :       DO term %prec UNIOP                     /* do $filename */
 611                         { $$ = dofile($2, $1); }
 612         |       DO block        %prec '('               /* do { code */
 613                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, scope($2)); }
 614         |       DO WORD '(' ')'                         /* do somesub() */
 615                         { $$ = newUNOP(OP_ENTERSUB,
 616                             OPf_SPECIAL|OPf_STACKED,
 617                             prepend_elem(OP_LIST,
 618                                 scalar(newCVREF(
 619                                     (OPpENTERSUB_AMPER<<8),
 620                                     scalar($2)
 621                                 )),Nullop)); dep();}
 622         |       DO WORD '(' expr ')'                    /* do somesub(@args) */
 623                         { $$ = newUNOP(OP_ENTERSUB,
 624                             OPf_SPECIAL|OPf_STACKED,
 625                             append_elem(OP_LIST,
 626                                 $4,
 627                                 scalar(newCVREF(
 628                                     (OPpENTERSUB_AMPER<<8),
 629                                     scalar($2)
 630                                 )))); dep();}
 631         |       DO scalar '(' ')'                      /* do $subref () */
 632                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 633                             prepend_elem(OP_LIST,
 634                                 scalar(newCVREF(0,scalar($2))), Nullop)); dep();}
 635         |       DO scalar '(' expr ')'                 /* do $subref (@args) */
 636                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
 637                             prepend_elem(OP_LIST,
 638                                 $4,
 639                                 scalar(newCVREF(0,scalar($2))))); dep();}
 640
 641         ;
 642
 643 term    :       termbinop
 644         |       termunop
 645         |       anonymous
 646         |       termdo
 647         |       term '?' term ':' term
 648                         { $$ = newCONDOP(0, $1, $3, $5); }
 649         |       REFGEN term                          /* \$x, \@y, \%z */
 650                         { $$ = newUNOP(OP_REFGEN, 0, mod($2,OP_REFGEN)); }
 651         |       myattrterm      %prec UNIOP
 652                         { $$ = $1; }
 653         |       LOCAL term      %prec UNIOP
 654                         { $$ = localize($2,$1); }
 655         |       '(' expr ')'
 656                         { $$ = sawparens($2); }
 657         |       '(' ')'
 658                         { $$ = sawparens(newNULLLIST()); }
 659         |       scalar  %prec '('
 660                         { $$ = $1; }
 661         |       star    %prec '('
 662                         { $$ = $1; }
 663         |       hsh     %prec '('
 664                         { $$ = $1; }
 665         |       ary     %prec '('
 666                         { $$ = $1; }
 667         |       arylen  %prec '('                    /* $#x, $#{ something } */
 668                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
 669         |       subscripted
 670                         { $$ = $1; }
 671         |       ary '[' expr ']'                     /* array slice */
 672                         { $$ = prepend_elem(OP_ASLICE,
 673                                 newOP(OP_PUSHMARK, 0),
 674                                     newLISTOP(OP_ASLICE, 0,
 675                                         list($3),
 676                                         ref($1, OP_ASLICE))); }
 677         |       ary '{' expr ';' '}'                 /* @hash{@keys} */
 678                         { $$ = prepend_elem(OP_HSLICE,
 679                                 newOP(OP_PUSHMARK, 0),
 680                                     newLISTOP(OP_HSLICE, 0,
 681                                         list($3),
 682                                         ref(oopsHV($1), OP_HSLICE)));
 683                             PL_expect = XOPERATOR; }
 684         |       THING   %prec '('
 685                         { $$ = $1; }
 686         |       amper                                /* &foo; */
 687                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
 688         |       amper '(' ')'                        /* &foo() */
 689                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
 690         |       amper '(' expr ')'                   /* &foo(@args) */
 691                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 692                             append_elem(OP_LIST, $3, scalar($1))); }
 693         |       NOAMP WORD listexpr                  /* foo(@args) */
 694                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 695                             append_elem(OP_LIST, $3, scalar($2))); }
 696         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
 697                         { $$ = newOP($1, OPf_SPECIAL);
 698                             PL_hints |= HINT_BLOCK_SCOPE; }
 699         |       LOOPEX term
 700                         { $$ = newLOOPEX($1,$2); }
 701         |       NOTOP argexpr                        /* not $foo */
 702                         { $$ = newUNOP(OP_NOT, 0, scalar($2)); }
 703         |       UNIOP                                /* Unary op, $_ implied */
 704                         { $$ = newOP($1, 0); }
 705         |       UNIOP block                          /* eval { foo } */
 706                         { $$ = newUNOP($1, 0, $2); }
 707         |       UNIOP term                           /* Unary op */
 708                         { $$ = newUNOP($1, 0, $2); }
 709         |       REQUIRE                              /* require, $_ implied */
 710                         { $$ = newOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0); }
 711         |       REQUIRE term                         /* require Foo */
 712                         { $$ = newUNOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0, $2); }
 713         |       UNIOPSUB term                        /* Sub treated as unop */
 714                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 715                             append_elem(OP_LIST, $2, scalar($1))); }
 716         |       FUNC0                                /* Nullary operator */
 717                         { $$ = newOP($1, 0); }
 718         |       FUNC0 '(' ')'
 719                         { $$ = newOP($1, 0); }
 720         |       FUNC0SUB                             /* Sub treated as nullop */
 721                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
 722                                 scalar($1)); }
 723         |       FUNC1 '(' ')'                        /* not () */
 724                         { $$ = $1 == OP_NOT ? newUNOP($1, 0, newSVOP(OP_CONST, 0, newSViv(0)))
 725                                             : newOP($1, OPf_SPECIAL); }
 726         |       FUNC1 '(' expr ')'                   /* not($foo) */
 727                         { $$ = newUNOP($1, 0, $3); }
 728         |       PMFUNC '(' argexpr ')'           /* m//, s///, tr/// */
 729                         { $$ = pmruntime($1, $3, 1); }
 730         |       WORD
 731         |       listop
 732         ;
 733
 734 /* "my" declarations, with optional attributes */
 735 myattrterm:     MY myterm myattrlist
 736                         { $$ = my_attrs($2,$3); }
 737         |       MY myterm
 738                         { $$ = localize($2,$1); }
 739         ;
 740
 741 /* Things that can be "my"'d */
 742 myterm  :       '(' expr ')'
 743                         { $$ = sawparens($2); }
 744         |       '(' ')'
 745                         { $$ = sawparens(newNULLLIST()); }
 746         |       scalar  %prec '('
 747                         { $$ = $1; }
 748         |       hsh     %prec '('
 749                         { $$ = $1; }
 750         |       ary     %prec '('
 751                         { $$ = $1; }
 752         ;
 753
 754 /* Basic list expressions */
 755 listexpr:       /* NULL */ %prec PREC_LOW
 756                         { $$ = Nullop; }
 757         |       argexpr    %prec PREC_LOW
 758                         { $$ = $1; }
 759         ;
 760
 761 listexprcom:    /* NULL */
 762                         { $$ = Nullop; }
 763         |       expr
 764                         { $$ = $1; }
 765         |       expr ','
 766                         { $$ = $1; }
 767         ;
 768
 769 /* A little bit of trickery to make "for my $foo (@bar)" actually be
 770    lexical */
 771 my_scalar:      scalar
 772                         { PL_in_my = 0; $$ = my($1); }
 773         ;
 774
 775 amper   :       '&' indirob
 776                         { $$ = newCVREF($1,$2); }
 777         ;
 778
 779 scalar  :       '$' indirob
 780                         { $$ = newSVREF($2); }
 781         ;
 782
 783 ary     :       '@' indirob
 784                         { $$ = newAVREF($2); }
 785         ;
 786
 787 hsh     :       '%' indirob
 788                         { $$ = newHVREF($2); }
 789         ;
 790
 791 arylen  :       DOLSHARP indirob
 792                         { $$ = newAVREF($2); }
 793         ;
 794
 795 star    :       '*' indirob
 796                         { $$ = newGVREF(0,$2); }
 797         ;
 798
 799 /* Indirect objects */
 800 indirob :       WORD
 801                         { $$ = scalar($1); }
 802         |       scalar %prec PREC_LOW
 803                         { $$ = scalar($1);  }
 804         |       block
 805                         { $$ = scope($1); }
 806
 807         |       PRIVATEREF
 808                         { $$ = $1; }
 809         ;