This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
s/\bthe the\b/the/g *.pod
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+4;        # Prints 7.
39     print(1+2) + 4;     # Prints 3.
40     print (1+2)+4;      # Also prints 3!
41     print +(1+2)+4;     # Prints 7.
42     print ((1+2)+4);    # Prints 7.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 nonabortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following important rule: There is B<no rule> that relates
56 the behavior of an expression in list context to its behavior in scalar
57 context, or vice versa.  It might do two totally different things.
58 Each operator and function decides which sort of value it would be most
59 appropriate to return in a scalar context.  Some operators return the
60 length of the list that would have been returned in list context.  Some
61 operators return the first value in the list.  Some operators return the
62 last value in the list.  Some operators return a count of successful
63 operations.  In general, they do what you want, unless you want
64 consistency.
65
66 An named array in scalar context is quite different from what would at
67 first glance appear to be a list in scalar context.  You can't get a list
68 like C<(1,2,3)> into being in scalar context, because the compiler knows
69 the context at compile time.  It would generate the scalar comma operator
70 there, not the list construction version of the comma.  That means it
71 was never a list to start with.
72
73 In general, functions in Perl that serve as wrappers for system calls
74 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
75 true when they succeed and C<undef> otherwise, as is usually mentioned
76 in the descriptions below.  This is different from the C interfaces,
77 which return C<-1> on failure.  Exceptions to this rule are C<wait()>,
78 C<waitpid()>, and C<syscall()>.  System calls also set the special C<$!>
79 variable on failure.  Other functions do not, except accidentally.
80
81 =head2 Perl Functions by Category
82
83 Here are Perl's functions (including things that look like
84 functions, like some keywords and named operators)
85 arranged by category.  Some functions appear in more
86 than one place.
87
88 =over
89
90 =item Functions for SCALARs or strings
91
92 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
93 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
94 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
95
96 =item Regular expressions and pattern matching
97
98 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
99
100 =item Numeric functions
101
102 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
103 C<sin>, C<sqrt>, C<srand>
104
105 =item Functions for real @ARRAYs
106
107 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
108
109 =item Functions for list data
110
111 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
112
113 =item Functions for real %HASHes
114
115 C<delete>, C<each>, C<exists>, C<keys>, C<values>
116
117 =item Input and output functions
118
119 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
120 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
121 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
122 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
123 C<warn>, C<write>
124
125 =item Functions for fixed length data or records
126
127 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
128
129 =item Functions for filehandles, files, or directories
130
131 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
132 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
133 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
134 C<unlink>, C<utime>
135
136 =item Keywords related to the control flow of your perl program
137
138 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<else>, C<elsif>,
139 C<eval>, C<exit>, C<for>, C<foreach>, C<goto>, C<if>, C<last>,
140 C<next>, C<redo>, C<return>, C<sub>, C<unless>, C<wantarray>,
141 C<while>, C<until>
142
143 =item Keywords related to scoping
144
145 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
146
147 =item Miscellaneous functions
148
149 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
150 C<scalar>, C<undef>, C<wantarray>
151
152 =item Functions for processes and process groups
153
154 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
155 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
156 C<times>, C<wait>, C<waitpid>
157
158 =item Keywords related to perl modules
159
160 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
161
162 =item Keywords related to classes and object-orientedness
163
164 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
165 C<untie>, C<use>
166
167 =item Low-level socket functions
168
169 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
170 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
171 C<socket>, C<socketpair>
172
173 =item System V interprocess communication functions
174
175 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
176 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
177
178 =item Fetching user and group info
179
180 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
181 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
182 C<getpwuid>, C<setgrent>, C<setpwent>
183
184 =item Fetching network info
185
186 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
187 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
188 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
189 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
190 C<setnetent>, C<setprotoent>, C<setservent>
191
192 =item Time-related functions
193
194 C<gmtime>, C<localtime>, C<time>, C<times>
195
196 =item Functions new in perl5
197
198 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
199 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
200 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
201 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
202
203 * - C<sub> was a keyword in perl4, but in perl5 it is an
204 operator, which can be used in expressions.
205
206 =item Functions obsoleted in perl5
207
208 C<dbmclose>, C<dbmopen>
209
210 =back
211
212 =head2 Portability
213
214 Perl was born in UNIX and therefore it can access all the common UNIX
215 system calls.  In non-UNIX environments the functionality of many
216 UNIX system calls may not be available or the details of the available
217 functionality may be slightly different.  The Perl functions affected
218 by this are:
219
220 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
221 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
222 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
223 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
224 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
225 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
226 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
227 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
228 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
229 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<select>, C<semctl>,
230 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
231 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
232 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
233 C<shmwrite>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
234 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<utime>,
235 C<wait>, C<waitpid>
236
237 For more information about the portability of these functions, see
238 L<perlport> and other available platform-specific documentation.
239
240 =head2 Alphabetical Listing of Perl Functions
241
242 =over 8
243
244 =item I<-X> FILEHANDLE
245
246 =item I<-X> EXPR
247
248 =item I<-X>
249
250 A file test, where X is one of the letters listed below.  This unary
251 operator takes one argument, either a filename or a filehandle, and
252 tests the associated file to see if something is true about it.  If the
253 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
254 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
255 the undefined value if the file doesn't exist.  Despite the funny
256 names, precedence is the same as any other named unary operator, and
257 the argument may be parenthesized like any other unary operator.  The
258 operator may be any of:
259 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
260 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
261
262     -r  File is readable by effective uid/gid.
263     -w  File is writable by effective uid/gid.
264     -x  File is executable by effective uid/gid.
265     -o  File is owned by effective uid.
266
267     -R  File is readable by real uid/gid.
268     -W  File is writable by real uid/gid.
269     -X  File is executable by real uid/gid.
270     -O  File is owned by real uid.
271
272     -e  File exists.
273     -z  File has zero size.
274     -s  File has nonzero size (returns size).
275
276     -f  File is a plain file.
277     -d  File is a directory.
278     -l  File is a symbolic link.
279     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
280     -S  File is a socket.
281     -b  File is a block special file.
282     -c  File is a character special file.
283     -t  Filehandle is opened to a tty.
284
285     -u  File has setuid bit set.
286     -g  File has setgid bit set.
287     -k  File has sticky bit set.
288
289     -T  File is a text file.
290     -B  File is a binary file (opposite of -T).
291
292     -M  Age of file in days when script started.
293     -A  Same for access time.
294     -C  Same for inode change time.
295
296 Example:
297
298     while (<>) {
299         chop;
300         next unless -f $_;      # ignore specials
301         #...
302     }
303
304 The interpretation of the file permission operators C<-r>, C<-R>,
305 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
306 of the file and the uids and gids of the user.  There may be other
307 reasons you can't actually read, write, or execute the file.  Such
308 reasons may be for example network filesystem access controls, ACLs
309 (access control lists), read-only filesystems, and unrecognized
310 executable formats.
311
312 Also note that, for the superuser on the local filesystems, C<-r>,
313 C<-R>, C<-w>, and C<-W> always return 1, and C<-x> and C<-X> return 1
314 if any execute bit is set in the mode.  Scripts run by the superuser
315 may thus need to do a stat() to determine the actual mode of the file,
316 or temporarily set the uid to something else.
317
318 If you are using ACLs, there is a pragma called C<filetest> that may
319 produce more accurate results than the bare stat() mode bits.
320
321 When under the C<use filetest 'access'> the above-mentioned filetests
322 will test whether the permission can (not) be granted using the
323 access() family of system calls.  Also note that the C<-x> and C<-X> may
324 under this pragma return true even if there are no execute permission
325 bits set (nor any extra execute permission ACLs).  This strangeness is
326 due to the underlying system calls' definitions.  Read the
327 documentation for the C<filetest> pragma for more information.
328
329 Note that C<-s/a/b/> does not do a negated substitution.  Saying
330 C<-exp($foo)> still works as expected, however--only single letters
331 following a minus are interpreted as file tests.
332
333 The C<-T> and C<-B> switches work as follows.  The first block or so of the
334 file is examined for odd characters such as strange control codes or
335 characters with the high bit set.  If too many strange characters (E<gt>30%)
336 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
337 containing null in the first block is considered a binary file.  If C<-T>
338 or C<-B> is used on a filehandle, the current stdio buffer is examined
339 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
340 file, or a file at EOF when testing a filehandle.  Because you have to
341 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
342 against the file first, as in C<next unless -f $file && -T $file>.
343
344 If any of the file tests (or either the C<stat()> or C<lstat()> operators) are given
345 the special filehandle consisting of a solitary underline, then the stat
346 structure of the previous file test (or stat operator) is used, saving
347 a system call.  (This doesn't work with C<-t>, and you need to remember
348 that lstat() and C<-l> will leave values in the stat structure for the
349 symbolic link, not the real file.)  Example:
350
351     print "Can do.\n" if -r $a || -w _ || -x _;
352
353     stat($filename);
354     print "Readable\n" if -r _;
355     print "Writable\n" if -w _;
356     print "Executable\n" if -x _;
357     print "Setuid\n" if -u _;
358     print "Setgid\n" if -g _;
359     print "Sticky\n" if -k _;
360     print "Text\n" if -T _;
361     print "Binary\n" if -B _;
362
363 =item abs VALUE
364
365 =item abs
366
367 Returns the absolute value of its argument.
368 If VALUE is omitted, uses C<$_>.
369
370 =item accept NEWSOCKET,GENERICSOCKET
371
372 Accepts an incoming socket connect, just as the accept(2) system call
373 does.  Returns the packed address if it succeeded, FALSE otherwise.
374 See example in L<perlipc/"Sockets: Client/Server Communication">.
375
376 =item alarm SECONDS
377
378 =item alarm
379
380 Arranges to have a SIGALRM delivered to this process after the
381 specified number of seconds have elapsed.  If SECONDS is not specified,
382 the value stored in C<$_> is used. (On some machines,
383 unfortunately, the elapsed time may be up to one second less than you
384 specified because of how seconds are counted.)  Only one timer may be
385 counting at once.  Each call disables the previous timer, and an
386 argument of C<0> may be supplied to cancel the previous timer without
387 starting a new one.  The returned value is the amount of time remaining
388 on the previous timer.
389
390 For delays of finer granularity than one second, you may use Perl's
391 C<syscall()> interface to access setitimer(2) if your system supports it,
392 or else see L</select()>.  It is usually a mistake to intermix C<alarm()>
393 and C<sleep()> calls.
394
395 If you want to use C<alarm()> to time out a system call you need to use an
396 C<eval()>/C<die()> pair.  You can't rely on the alarm causing the system call to
397 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
398 restart system calls on some systems.  Using C<eval()>/C<die()> always works,
399 modulo the caveats given in L<perlipc/"Signals">.
400
401     eval {
402         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
403         alarm $timeout;
404         $nread = sysread SOCKET, $buffer, $size;
405         alarm 0;
406     };
407     if ($@) {
408         die unless $@ eq "alarm\n";   # propagate unexpected errors
409         # timed out
410     }
411     else {
412         # didn't
413     }
414
415 =item atan2 Y,X
416
417 Returns the arctangent of Y/X in the range -PI to PI.
418
419 For the tangent operation, you may use the C<POSIX::tan()>
420 function, or use the familiar relation:
421
422     sub tan { sin($_[0]) / cos($_[0])  }
423
424 =item bind SOCKET,NAME
425
426 Binds a network address to a socket, just as the bind system call
427 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
428 packed address of the appropriate type for the socket.  See the examples in
429 L<perlipc/"Sockets: Client/Server Communication">.
430
431 =item binmode FILEHANDLE
432
433 Arranges for the file to be read or written in "binary" mode in operating
434 systems that distinguish between binary and text files.  Files that are
435 not in binary mode have CR LF sequences translated to LF on input and LF
436 translated to CR LF on output.  Binmode has no effect under Unix; in MS-DOS
437 and similarly archaic systems, it may be imperative--otherwise your
438 MS-DOS-damaged C library may mangle your file.  The key distinction between
439 systems that need C<binmode()> and those that don't is their text file
440 formats.  Systems like Unix, MacOS, and Plan9 that delimit lines with a single
441 character, and that encode that character in C as C<"\n">, do not need
442 C<binmode()>.  The rest need it.  If FILEHANDLE is an expression, the value
443 is taken as the name of the filehandle.
444
445 =item bless REF,CLASSNAME
446
447 =item bless REF
448
449 This function tells the thingy referenced by REF that it is now
450 an object in the CLASSNAME package--or the current package if no CLASSNAME
451 is specified, which is often the case.  It returns the reference for
452 convenience, because a C<bless()> is often the last thing in a constructor.
453 Always use the two-argument version if the function doing the blessing
454 might be inherited by a derived class.  See L<perltoot> and L<perlobj>
455 for more about the blessing (and blessings) of objects.
456
457 Consider always blessing objects in CLASSNAMEs that are mixed case.
458 Namespaces with all lowercase names are considered reserved for Perl
459 pragmata.  Builtin types have all uppercase names, so to prevent confusion,
460 it is best to avoid such package names as well.
461
462 See L<perlmod/"Perl Modules">.
463
464 =item caller EXPR
465
466 =item caller
467
468 Returns the context of the current subroutine call.  In scalar context,
469 returns the caller's package name if there is a caller, that is, if
470 we're in a subroutine or C<eval()> or C<require()>, and the undefined value
471 otherwise.  In list context, returns
472
473     ($package, $filename, $line) = caller;
474
475 With EXPR, it returns some extra information that the debugger uses to
476 print a stack trace.  The value of EXPR indicates how many call frames
477 to go back before the current one.
478
479     ($package, $filename, $line, $subroutine,
480      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
481
482 Here C<$subroutine> may be C<"(eval)"> if the frame is not a subroutine
483 call, but an C<eval()>.  In such a case additional elements C<$evaltext> and
484 C<$is_require> are set: C<$is_require> is true if the frame is created by a
485 C<require> or C<use> statement, C<$evaltext> contains the text of the
486 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
487 C<$filename> is C<"(eval)">, but C<$evaltext> is undefined.  (Note also that
488 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
489 frame.
490
491 Furthermore, when called from within the DB package, caller returns more
492 detailed information: it sets the list variable C<@DB::args> to be the
493 arguments with which the subroutine was invoked.
494
495 Be aware that the optimizer might have optimized call frames away before
496 C<caller()> had a chance to get the information. That means that C<caller(N)>
497 might not return information about the call frame you expect it do, for
498 C<N E<gt> 1>. In particular, C<@DB::args> might have information from the 
499 previous time C<caller()> was called.
500
501 =item chdir EXPR
502
503 Changes the working directory to EXPR, if possible.  If EXPR is
504 omitted, changes to home directory.  Returns TRUE upon success, FALSE
505 otherwise.  See example under C<die()>.
506
507 =item chmod LIST
508
509 Changes the permissions of a list of files.  The first element of the
510 list must be the numerical mode, which should probably be an octal
511 number, and which definitely should I<not> a string of octal digits:
512 C<0644> is okay, C<'0644'> is not.  Returns the number of files
513 successfully changed.  See also L</oct>, if all you have is a string.
514
515     $cnt = chmod 0755, 'foo', 'bar';
516     chmod 0755, @executables;
517     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
518                                              # --w----r-T
519     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
520     $mode = 0644;   chmod $mode, 'foo';      # this is best
521
522 =item chomp VARIABLE
523
524 =item chomp LIST
525
526 =item chomp
527
528 This is a slightly safer version of L</chop>.  It removes any
529 line ending that corresponds to the current value of C<$/> (also known as
530 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
531 number of characters removed from all its arguments.  It's often used to
532 remove the newline from the end of an input record when you're worried
533 that the final record may be missing its newline.  When in paragraph mode
534 (C<$/ = "">), it removes all trailing newlines from the string.  If
535 VARIABLE is omitted, it chomps C<$_>.  Example:
536
537     while (<>) {
538         chomp;  # avoid \n on last field
539         @array = split(/:/);
540         # ...
541     }
542
543 You can actually chomp anything that's an lvalue, including an assignment:
544
545     chomp($cwd = `pwd`);
546     chomp($answer = <STDIN>);
547
548 If you chomp a list, each element is chomped, and the total number of
549 characters removed is returned.
550
551 =item chop VARIABLE
552
553 =item chop LIST
554
555 =item chop
556
557 Chops off the last character of a string and returns the character
558 chopped.  It's used primarily to remove the newline from the end of an
559 input record, but is much more efficient than C<s/\n//> because it neither
560 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
561 Example:
562
563     while (<>) {
564         chop;   # avoid \n on last field
565         @array = split(/:/);
566         #...
567     }
568
569 You can actually chop anything that's an lvalue, including an assignment:
570
571     chop($cwd = `pwd`);
572     chop($answer = <STDIN>);
573
574 If you chop a list, each element is chopped.  Only the value of the
575 last C<chop()> is returned.
576
577 Note that C<chop()> returns the last character.  To return all but the last
578 character, use C<substr($string, 0, -1)>.
579
580 =item chown LIST
581
582 Changes the owner (and group) of a list of files.  The first two
583 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
584 Returns the number of files successfully changed.
585
586     $cnt = chown $uid, $gid, 'foo', 'bar';
587     chown $uid, $gid, @filenames;
588
589 Here's an example that looks up nonnumeric uids in the passwd file:
590
591     print "User: ";
592     chop($user = <STDIN>);
593     print "Files: ";
594     chop($pattern = <STDIN>);
595
596     ($login,$pass,$uid,$gid) = getpwnam($user)
597         or die "$user not in passwd file";
598
599     @ary = glob($pattern);      # expand filenames
600     chown $uid, $gid, @ary;
601
602 On most systems, you are not allowed to change the ownership of the
603 file unless you're the superuser, although you should be able to change
604 the group to any of your secondary groups.  On insecure systems, these
605 restrictions may be relaxed, but this is not a portable assumption.
606
607 =item chr NUMBER
608
609 =item chr
610
611 Returns the character represented by that NUMBER in the character set.
612 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
613 chr(0x263a) is a Unicode smiley face (but only within the scope of a
614 C<use utf8>).  For the reverse, use L</ord>.
615
616 If NUMBER is omitted, uses C<$_>.
617
618 =item chroot FILENAME
619
620 =item chroot
621
622 This function works like the system call by the same name: it makes the
623 named directory the new root directory for all further pathnames that
624 begin with a C<"/"> by your process and all its children.  (It doesn't
625 change your current working directory, which is unaffected.)  For security
626 reasons, this call is restricted to the superuser.  If FILENAME is
627 omitted, does a C<chroot()> to C<$_>.
628
629 =item close FILEHANDLE
630
631 =item close
632
633 Closes the file or pipe associated with the file handle, returning TRUE
634 only if stdio successfully flushes buffers and closes the system file
635 descriptor. Closes the currently selected filehandle if the argument
636 is omitted.
637
638 You don't have to close FILEHANDLE if you are immediately going to do
639 another C<open()> on it, because C<open()> will close it for you.  (See
640 C<open()>.)  However, an explicit C<close()> on an input file resets the line
641 counter (C<$.>), while the implicit close done by C<open()> does not.
642
643 If the file handle came from a piped open C<close()> will additionally
644 return FALSE if one of the other system calls involved fails or if the
645 program exits with non-zero status.  (If the only problem was that the
646 program exited non-zero C<$!> will be set to C<0>.)  Also, closing a pipe 
647 waits for the process executing on the pipe to complete, in case you
648 want to look at the output of the pipe afterwards.  Closing a pipe
649 explicitly also puts the exit status value of the command into C<$?>.
650
651 Example:
652
653     open(OUTPUT, '|sort >foo')  # pipe to sort
654         or die "Can't start sort: $!";
655     #...                        # print stuff to output
656     close OUTPUT                # wait for sort to finish
657         or warn $! ? "Error closing sort pipe: $!"
658                    : "Exit status $? from sort";
659     open(INPUT, 'foo')          # get sort's results
660         or die "Can't open 'foo' for input: $!";
661
662 FILEHANDLE may be an expression whose value can be used as an indirect
663 filehandle, usually the real filehandle name.
664
665 =item closedir DIRHANDLE
666
667 Closes a directory opened by C<opendir()> and returns the success of that
668 system call.
669
670 DIRHANDLE may be an expression whose value can be used as an indirect
671 dirhandle, usually the real dirhandle name.
672
673 =item connect SOCKET,NAME
674
675 Attempts to connect to a remote socket, just as the connect system call
676 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
677 packed address of the appropriate type for the socket.  See the examples in
678 L<perlipc/"Sockets: Client/Server Communication">.
679
680 =item continue BLOCK
681
682 Actually a flow control statement rather than a function.  If there is a
683 C<continue> BLOCK attached to a BLOCK (typically in a L</while> or
684 L</foreach>), it is always executed just before the conditional is about to
685 be evaluated again, just like the third part of a L</for> loop in C.  Thus
686 it can be used to increment a loop variable, even when the loop has been
687 continued via the C<next> statement (which is similar to the C C<continue>
688 statement).
689
690 L</last>, L</next>, or L</redo> may appear within a C<continue>
691 block. C<last> and C<redo> will behave as if they had been executed within
692 the main block. So will C<next>, but since it will execute a C<continue>
693 block, it may be more entertaining.
694
695     while (EXPR) {
696         ### redo always comes here
697         do_something;
698     } continue {
699         ### next always comes here
700         do_something_else;
701         # then back the top to re-check EXPR
702     }
703     ### last always comes here
704
705 Omitting the C<continue> section is semantically equivalent to using an
706 empty one, logically enough. In that case, C<next> goes directly back
707 to check the condition at the top of the loop.
708
709 See also L<perlsyn>.
710
711 =item cos EXPR
712
713 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
714 takes cosine of C<$_>.
715
716 For the inverse cosine operation, you may use the C<POSIX::acos()>
717 function, or use this relation:
718
719     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
720
721 =item crypt PLAINTEXT,SALT
722
723 Encrypts a string exactly like the crypt(3) function in the C library
724 (assuming that you actually have a version there that has not been
725 extirpated as a potential munition).  This can prove useful for checking
726 the password file for lousy passwords, amongst other things.  Only the
727 guys wearing white hats should do this.
728
729 Note that C<crypt()> is intended to be a one-way function, much like breaking
730 eggs to make an omelette.  There is no (known) corresponding decrypt
731 function.  As a result, this function isn't all that useful for
732 cryptography.  (For that, see your nearby CPAN mirror.)
733
734 When verifying an existing encrypted string you should use the encrypted
735 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
736 allows your code to work with the standard C<crypt()> and with more
737 exotic implementations.  When choosing a new salt create a random two
738 character string whose characters come from the set C<[./0-9A-Za-z]>
739 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
740
741 Here's an example that makes sure that whoever runs this program knows
742 their own password:
743
744     $pwd = (getpwuid($<))[1];
745
746     system "stty -echo";
747     print "Password: ";
748     chomp($word = <STDIN>);
749     print "\n";
750     system "stty echo";
751
752     if (crypt($word, $pwd) ne $pwd) {
753         die "Sorry...\n";
754     } else {
755         print "ok\n";
756     }
757
758 Of course, typing in your own password to whoever asks you
759 for it is unwise.
760
761 =item dbmclose HASH
762
763 [This function has been superseded by the C<untie()> function.]
764
765 Breaks the binding between a DBM file and a hash.
766
767 =item dbmopen HASH,DBNAME,MODE
768
769 [This function has been superseded by the C<tie()> function.]
770
771 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
772 hash.  HASH is the name of the hash.  (Unlike normal C<open()>, the first
773 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
774 is the name of the database (without the F<.dir> or F<.pag> extension if
775 any).  If the database does not exist, it is created with protection
776 specified by MODE (as modified by the C<umask()>).  If your system supports
777 only the older DBM functions, you may perform only one C<dbmopen()> in your
778 program.  In older versions of Perl, if your system had neither DBM nor
779 ndbm, calling C<dbmopen()> produced a fatal error; it now falls back to
780 sdbm(3).
781
782 If you don't have write access to the DBM file, you can only read hash
783 variables, not set them.  If you want to test whether you can write,
784 either use file tests or try setting a dummy hash entry inside an C<eval()>,
785 which will trap the error.
786
787 Note that functions such as C<keys()> and C<values()> may return huge lists
788 when used on large DBM files.  You may prefer to use the C<each()>
789 function to iterate over large DBM files.  Example:
790
791     # print out history file offsets
792     dbmopen(%HIST,'/usr/lib/news/history',0666);
793     while (($key,$val) = each %HIST) {
794         print $key, ' = ', unpack('L',$val), "\n";
795     }
796     dbmclose(%HIST);
797
798 See also L<AnyDBM_File> for a more general description of the pros and
799 cons of the various dbm approaches, as well as L<DB_File> for a particularly
800 rich implementation.
801
802 =item defined EXPR
803
804 =item defined
805
806 Returns a Boolean value telling whether EXPR has a value other than
807 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
808 checked.
809
810 Many operations return C<undef> to indicate failure, end of file,
811 system error, uninitialized variable, and other exceptional
812 conditions.  This function allows you to distinguish C<undef> from
813 other values.  (A simple Boolean test will not distinguish among
814 C<undef>, zero, the empty string, and C<"0">, which are all equally
815 false.)  Note that since C<undef> is a valid scalar, its presence
816 doesn't I<necessarily> indicate an exceptional condition: C<pop()>
817 returns C<undef> when its argument is an empty array, I<or> when the
818 element to return happens to be C<undef>.
819
820 You may also use C<defined()> to check whether a subroutine exists, by
821 saying C<defined &func> without parentheses.  On the other hand, use
822 of C<defined()> upon aggregates (hashes and arrays) is not guaranteed to
823 produce intuitive results, and should probably be avoided.
824
825 When used on a hash element, it tells you whether the value is defined,
826 not whether the key exists in the hash.  Use L</exists> for the latter
827 purpose.
828
829 Examples:
830
831     print if defined $switch{'D'};
832     print "$val\n" while defined($val = pop(@ary));
833     die "Can't readlink $sym: $!"
834         unless defined($value = readlink $sym);
835     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
836     $debugging = 0 unless defined $debugging;
837
838 Note:  Many folks tend to overuse C<defined()>, and then are surprised to
839 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
840 defined values.  For example, if you say
841
842     "ab" =~ /a(.*)b/;
843
844 The pattern match succeeds, and C<$1> is defined, despite the fact that it
845 matched "nothing".  But it didn't really match nothing--rather, it
846 matched something that happened to be C<0> characters long.  This is all
847 very above-board and honest.  When a function returns an undefined value,
848 it's an admission that it couldn't give you an honest answer.  So you
849 should use C<defined()> only when you're questioning the integrity of what
850 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
851 what you want.
852
853 Currently, using C<defined()> on an entire array or hash reports whether
854 memory for that aggregate has ever been allocated.  So an array you set
855 to the empty list appears undefined initially, and one that once was full
856 and that you then set to the empty list still appears defined.  You
857 should instead use a simple test for size:
858
859     if (@an_array) { print "has array elements\n" }
860     if (%a_hash)   { print "has hash members\n"   }
861
862 Using C<undef()> on these, however, does clear their memory and then report
863 them as not defined anymore, but you shouldn't do that unless you don't
864 plan to use them again, because it saves time when you load them up
865 again to have memory already ready to be filled.  The normal way to 
866 free up space used by an aggregate is to assign the empty list.
867
868 This counterintuitive behavior of C<defined()> on aggregates may be
869 changed, fixed, or broken in a future release of Perl.
870
871 See also L</undef>, L</exists>, L</ref>.
872
873 =item delete EXPR
874
875 Deletes the specified key(s) and their associated values from a hash.
876 For each key, returns the deleted value associated with that key, or
877 the undefined value if there was no such key.  Deleting from C<$ENV{}>
878 modifies the environment.  Deleting from a hash tied to a DBM file
879 deletes the entry from the DBM file.  (But deleting from a C<tie()>d hash
880 doesn't necessarily return anything.)
881
882 The following deletes all the values of a hash:
883
884     foreach $key (keys %HASH) {
885         delete $HASH{$key};
886     }
887
888 And so does this:
889
890     delete @HASH{keys %HASH}
891
892 (But both of these are slower than just assigning the empty list, or
893 using C<undef()>.)  Note that the EXPR can be arbitrarily complicated as
894 long as the final operation is a hash element lookup or hash slice:
895
896     delete $ref->[$x][$y]{$key};
897     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
898
899 =item die LIST
900
901 Outside an C<eval()>, prints the value of LIST to C<STDERR> and exits with
902 the current value of C<$!> (errno).  If C<$!> is C<0>, exits with the value of
903 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)>
904 is C<0>, exits with C<255>.  Inside an C<eval(),> the error message is stuffed into
905 C<$@> and the C<eval()> is terminated with the undefined value.  This makes
906 C<die()> the way to raise an exception.
907
908 Equivalent examples:
909
910     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
911     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
912
913 If the value of EXPR does not end in a newline, the current script line
914 number and input line number (if any) are also printed, and a newline
915 is supplied.  Hint: sometimes appending C<", stopped"> to your message
916 will cause it to make better sense when the string C<"at foo line 123"> is
917 appended.  Suppose you are running script "canasta".
918
919     die "/etc/games is no good";
920     die "/etc/games is no good, stopped";
921
922 produce, respectively
923
924     /etc/games is no good at canasta line 123.
925     /etc/games is no good, stopped at canasta line 123.
926
927 See also C<exit()> and C<warn()>.
928
929 If LIST is empty and C<$@> already contains a value (typically from a
930 previous eval) that value is reused after appending C<"\t...propagated">.
931 This is useful for propagating exceptions:
932
933     eval { ... };
934     die unless $@ =~ /Expected exception/;
935
936 If C<$@> is empty then the string C<"Died"> is used.
937
938 You can arrange for a callback to be run just before the C<die()> does
939 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
940 will be called with the error text and can change the error message, if
941 it sees fit, by calling C<die()> again.  See L<perlvar/$SIG{expr}> for details on
942 setting C<%SIG> entries, and L<"eval BLOCK"> for some examples.
943
944 Note that the C<$SIG{__DIE__}> hook is called even inside eval()ed
945 blocks/strings.  If one wants the hook to do nothing in such
946 situations, put
947
948         die @_ if $^S;
949
950 as the first line of the handler (see L<perlvar/$^S>).
951
952 =item do BLOCK
953
954 Not really a function.  Returns the value of the last command in the
955 sequence of commands indicated by BLOCK.  When modified by a loop
956 modifier such as L</while> or L</until>, executes the BLOCK once
957 before testing the loop condition.  (On other statements the loop
958 modifiers test the conditional first.)
959
960 C<do BLOCK> does I<not> count as a loop, so the loop control statements
961 L</next>, L</last> or L</redo> cannot be used to leave or restart the block.
962
963 =item do SUBROUTINE(LIST)
964
965 A deprecated form of subroutine call.  See L<perlsub>.
966
967 =item do EXPR
968
969 Uses the value of EXPR as a filename and executes the contents of the
970 file as a Perl script.  Its primary use is to include subroutines
971 from a Perl subroutine library.
972
973     do 'stat.pl';
974
975 is just like
976
977     scalar eval `cat stat.pl`;
978
979 except that it's more efficient and concise, keeps track of the
980 current filename for error messages, and searches all the B<-I>
981 libraries if the file isn't in the current directory (see also the @INC
982 array in L<perlvar/Predefined Names>).  It is also different in how
983 code evaluated with C<do FILENAME> doesn't see lexicals in the enclosing
984 scope like C<eval STRING> does.  It's the same, however, in that it does
985 reparse the file every time you call it, so you probably don't want to
986 do this inside a loop.
987
988 If C<do> cannot read the file, it returns undef and sets C<$!> to the
989 error.    If C<do> can read the file but cannot compile it, it
990 returns undef and sets an error message in C<$@>.   If the file is
991 successfully compiled, C<do> returns the value of the last expression
992 evaluated.
993
994 Note that inclusion of library modules is better done with the
995 C<use()> and C<require()> operators, which also do automatic error checking
996 and raise an exception if there's a problem.
997
998 You might like to use C<do> to read in a program configuration
999 file.  Manual error checking can be done this way:
1000
1001     # read in config files: system first, then user 
1002     for $file ("/share/prog/defaults.rc",
1003                "$ENV{HOME}/.someprogrc") {
1004         unless ($return = do $file) {
1005             warn "couldn't parse $file: $@" if $@;
1006             warn "couldn't do $file: $!"    unless defined $return;
1007             warn "couldn't run $file"       unless $return;
1008         }
1009     }
1010
1011 =item dump LABEL
1012
1013 This causes an immediate core dump.  Primarily this is so that you can
1014 use the B<undump> program to turn your core dump into an executable binary
1015 after having initialized all your variables at the beginning of the
1016 program.  When the new binary is executed it will begin by executing a
1017 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
1018 it as a goto with an intervening core dump and reincarnation.  If C<LABEL>
1019 is omitted, restarts the program from the top.  WARNING: Any files
1020 opened at the time of the dump will NOT be open any more when the
1021 program is reincarnated, with possible resulting confusion on the part
1022 of Perl.  See also B<-u> option in L<perlrun>.
1023
1024 Example:
1025
1026     #!/usr/bin/perl
1027     require 'getopt.pl';
1028     require 'stat.pl';
1029     %days = (
1030         'Sun' => 1,
1031         'Mon' => 2,
1032         'Tue' => 3,
1033         'Wed' => 4,
1034         'Thu' => 5,
1035         'Fri' => 6,
1036         'Sat' => 7,
1037     );
1038
1039     dump QUICKSTART if $ARGV[0] eq '-d';
1040
1041     QUICKSTART:
1042     Getopt('f');
1043
1044 This operator is largely obsolete, partly because it's very hard to 
1045 convert a core file into an executable, and because the real perl-to-C
1046 compiler has superseded it.
1047
1048 =item each HASH
1049
1050 When called in list context, returns a 2-element list consisting of the
1051 key and value for the next element of a hash, so that you can iterate over
1052 it.  When called in scalar context, returns the key for only the "next"
1053 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
1054 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
1055 for this reason.)
1056
1057 Entries are returned in an apparently random order.  The actual random
1058 order is subject to change in future versions of perl, but it is guaranteed
1059 to be in the same order as either the C<keys()> or C<values()> function
1060 would produce on the same (unmodified) hash.
1061
1062 When the hash is entirely read, a null array is returned in list context
1063 (which when assigned produces a FALSE (C<0>) value), and C<undef> in
1064 scalar context.  The next call to C<each()> after that will start iterating
1065 again.  There is a single iterator for each hash, shared by all C<each()>,
1066 C<keys()>, and C<values()> function calls in the program; it can be reset by
1067 reading all the elements from the hash, or by evaluating C<keys HASH> or
1068 C<values HASH>.  If you add or delete elements of a hash while you're
1069 iterating over it, you may get entries skipped or duplicated, so don't.
1070
1071 The following prints out your environment like the printenv(1) program,
1072 only in a different order:
1073
1074     while (($key,$value) = each %ENV) {
1075         print "$key=$value\n";
1076     }
1077
1078 See also C<keys()>, C<values()> and C<sort()>.
1079
1080 =item else BLOCK
1081
1082 =item elsif (EXPR) BLOCK
1083
1084 See L</if>.
1085
1086 =item eof FILEHANDLE
1087
1088 =item eof ()
1089
1090 =item eof
1091
1092 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1093 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1094 gives the real filehandle.  (Note that this function actually
1095 reads a character and then C<ungetc()>s it, so isn't very useful in an
1096 interactive context.)  Do not read from a terminal file (or call
1097 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
1098 as terminals may lose the end-of-file condition if you do.
1099
1100 An C<eof> without an argument uses the last file read as argument.
1101 Using C<eof()> with empty parentheses is very different.  It indicates the pseudo file formed of
1102 the files listed on the command line, i.e., C<eof()> is reasonable to
1103 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
1104 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
1105 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
1106
1107     # reset line numbering on each input file
1108     while (<>) {
1109         next if /^\s*#/;        # skip comments 
1110         print "$.\t$_";
1111     } continue {
1112         close ARGV  if eof;     # Not eof()!
1113     }
1114
1115     # insert dashes just before last line of last file
1116     while (<>) {
1117         if (eof()) {            # check for end of current file
1118             print "--------------\n";
1119             close(ARGV);        # close or break; is needed if we
1120                                 # are reading from the terminal
1121         }
1122         print;
1123     }
1124
1125 Practical hint: you almost never need to use C<eof> in Perl, because the
1126 input operators return false values when they run out of data, or if there
1127 was an error.
1128
1129 =item eval EXPR
1130
1131 =item eval BLOCK
1132
1133 In the first form, the return value of EXPR is parsed and executed as if it
1134 were a little Perl program.  The value of the expression (which is itself
1135 determined within scalar context) is first parsed, and if there weren't any
1136 errors, executed in the context of the current Perl program, so that any
1137 variable settings or subroutine and format definitions remain afterwards.
1138 Note that the value is parsed every time the eval executes.  If EXPR is
1139 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1140 and subsequent execution of the text of EXPR until run time.
1141
1142 In the second form, the code within the BLOCK is parsed only once--at the
1143 same time the code surrounding the eval itself was parsed--and executed
1144 within the context of the current Perl program.  This form is typically
1145 used to trap exceptions more efficiently than the first (see below), while
1146 also providing the benefit of checking the code within BLOCK at compile
1147 time.
1148
1149 The final semicolon, if any, may be omitted from the value of EXPR or within
1150 the BLOCK.
1151
1152 In both forms, the value returned is the value of the last expression
1153 evaluated inside the mini-program; a return statement may be also used, just
1154 as with subroutines.  The expression providing the return value is evaluated
1155 in void, scalar, or list context, depending on the context of the eval itself.
1156 See L</wantarray> for more on how the evaluation context can be determined.
1157
1158 If there is a syntax error or runtime error, or a C<die()> statement is
1159 executed, an undefined value is returned by C<eval()>, and C<$@> is set to the
1160 error message.  If there was no error, C<$@> is guaranteed to be a null
1161 string.  Beware that using C<eval()> neither silences perl from printing
1162 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1163 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1164 L</warn> and L<perlvar>.
1165
1166 Note that, because C<eval()> traps otherwise-fatal errors, it is useful for
1167 determining whether a particular feature (such as C<socket()> or C<symlink()>)
1168 is implemented.  It is also Perl's exception trapping mechanism, where
1169 the die operator is used to raise exceptions.
1170
1171 If the code to be executed doesn't vary, you may use the eval-BLOCK
1172 form to trap run-time errors without incurring the penalty of
1173 recompiling each time.  The error, if any, is still returned in C<$@>.
1174 Examples:
1175
1176     # make divide-by-zero nonfatal
1177     eval { $answer = $a / $b; }; warn $@ if $@;
1178
1179     # same thing, but less efficient
1180     eval '$answer = $a / $b'; warn $@ if $@;
1181
1182     # a compile-time error
1183     eval { $answer = };                 # WRONG
1184
1185     # a run-time error
1186     eval '$answer =';   # sets $@
1187
1188 When using the C<eval{}> form as an exception trap in libraries, you may
1189 wish not to trigger any C<__DIE__> hooks that user code may have
1190 installed.  You can use the C<local $SIG{__DIE__}> construct for this
1191 purpose, as shown in this example:
1192
1193     # a very private exception trap for divide-by-zero
1194     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1195     warn $@ if $@;
1196
1197 This is especially significant, given that C<__DIE__> hooks can call
1198 C<die()> again, which has the effect of changing their error messages:
1199
1200     # __DIE__ hooks may modify error messages
1201     {
1202        local $SIG{'__DIE__'} =
1203               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1204        eval { die "foo lives here" };
1205        print $@ if $@;                # prints "bar lives here"
1206     }
1207
1208 With an C<eval()>, you should be especially careful to remember what's
1209 being looked at when:
1210
1211     eval $x;            # CASE 1
1212     eval "$x";          # CASE 2
1213
1214     eval '$x';          # CASE 3
1215     eval { $x };        # CASE 4
1216
1217     eval "\$$x++";      # CASE 5
1218     $$x++;              # CASE 6
1219
1220 Cases 1 and 2 above behave identically: they run the code contained in
1221 the variable C<$x>.  (Although case 2 has misleading double quotes making
1222 the reader wonder what else might be happening (nothing is).)  Cases 3
1223 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1224 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1225 purely visual reasons, but it also has the advantage of compiling at
1226 compile-time instead of at run-time.)  Case 5 is a place where
1227 normally you I<WOULD> like to use double quotes, except that in this
1228 particular situation, you can just use symbolic references instead, as
1229 in case 6.
1230
1231 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1232 C<next>, C<last> or C<redo> cannot be used to leave or restart the block.
1233
1234
1235 =item exec LIST
1236
1237 =item exec PROGRAM LIST
1238
1239 The C<exec()> function executes a system command I<AND NEVER RETURNS> -
1240 use C<system()> instead of C<exec()> if you want it to return. It fails and
1241 returns FALSE only if the command does not exist I<and> it is executed
1242 directly instead of via your system's command shell (see below).
1243
1244 Since it's a common mistake to use C<exec()> instead of C<system()>, Perl
1245 warns you if there is a following statement which isn't C<die()>, C<warn()>,
1246 or C<exit()> (if C<-w> is set  -  but you always do that).   If you
1247 I<really> want to follow an C<exec()> with some other statement, you
1248 can use one of these styles to avoid the warning:
1249
1250     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1251     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1252
1253 If there is more than one argument in LIST, or if LIST is an array
1254 with more than one value, calls execvp(3) with the arguments in LIST.
1255 If there is only one scalar argument or an array with one element in it,
1256 the argument is checked for shell metacharacters, and if there are any,
1257 the entire argument is passed to the system's command shell for parsing
1258 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1259 If there are no shell metacharacters in the argument, it is split into
1260 words and passed directly to C<execvp()>, which is more efficient.  Note:
1261 C<exec()> and C<system()> do not flush your output buffer, so you may need to
1262 set C<$|> to avoid lost output.  Examples:
1263
1264     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1265     exec "sort $outfile | uniq";
1266
1267 If you don't really want to execute the first argument, but want to lie
1268 to the program you are executing about its own name, you can specify
1269 the program you actually want to run as an "indirect object" (without a
1270 comma) in front of the LIST.  (This always forces interpretation of the
1271 LIST as a multivalued list, even if there is only a single scalar in
1272 the list.)  Example:
1273
1274     $shell = '/bin/csh';
1275     exec $shell '-sh';          # pretend it's a login shell
1276
1277 or, more directly,
1278
1279     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1280
1281 When the arguments get executed via the system shell, results will
1282 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1283 for details.
1284
1285 Using an indirect object with C<exec()> or C<system()> is also more secure.
1286 This usage forces interpretation of the arguments as a multivalued list,
1287 even if the list had just one argument.  That way you're safe from the
1288 shell expanding wildcards or splitting up words with whitespace in them.
1289
1290     @args = ( "echo surprise" );
1291
1292     system @args;               # subject to shell escapes
1293                                 # if @args == 1
1294     system { $args[0] } @args;  # safe even with one-arg list
1295
1296 The first version, the one without the indirect object, ran the I<echo>
1297 program, passing it C<"surprise"> an argument.  The second version
1298 didn't--it tried to run a program literally called I<"echo surprise">,
1299 didn't find it, and set C<$?> to a non-zero value indicating failure.
1300
1301 Note that C<exec()> will not call your C<END> blocks, nor will it call
1302 any C<DESTROY> methods in your objects.
1303
1304 =item exists EXPR
1305
1306 Returns TRUE if the specified hash key exists in its hash array, even
1307 if the corresponding value is undefined.
1308
1309     print "Exists\n" if exists $array{$key};
1310     print "Defined\n" if defined $array{$key};
1311     print "True\n" if $array{$key};
1312
1313 A hash element can be TRUE only if it's defined, and defined if
1314 it exists, but the reverse doesn't necessarily hold true.
1315
1316 Note that the EXPR can be arbitrarily complicated as long as the final
1317 operation is a hash key lookup:
1318
1319     if (exists $ref->{"A"}{"B"}{$key}) { ... }
1320
1321 Although the last element will not spring into existence just because its
1322 existence was tested, intervening ones will.  Thus C<$ref-E<gt>{"A"}>
1323 C<$ref-E<gt>{"B"}> will spring into existence due to the existence
1324 test for a $key element.  This autovivification may be fixed in a later
1325 release.
1326
1327 =item exit EXPR
1328
1329 Evaluates EXPR and exits immediately with that value.  (Actually, it
1330 calls any defined C<END> routines first, but the C<END> routines may not
1331 abort the exit.  Likewise any object destructors that need to be called
1332 are called before exit.)  Example:
1333
1334     $ans = <STDIN>;
1335     exit 0 if $ans =~ /^[Xx]/;
1336
1337 See also C<die()>.  If EXPR is omitted, exits with C<0> status.  The only
1338 universally portable values for EXPR are C<0> for success and C<1> for error;
1339 all other values are subject to unpredictable interpretation depending
1340 on the environment in which the Perl program is running.
1341
1342 You shouldn't use C<exit()> to abort a subroutine if there's any chance that
1343 someone might want to trap whatever error happened.  Use C<die()> instead,
1344 which can be trapped by an C<eval()>.
1345
1346 All C<END{}> blocks are run at exit time.  See L<perlsub> for details.
1347
1348 =item exp EXPR
1349
1350 =item exp
1351
1352 Returns I<e> (the natural logarithm base) to the power of EXPR.
1353 If EXPR is omitted, gives C<exp($_)>.
1354
1355 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1356
1357 Implements the fcntl(2) function.  You'll probably have to say
1358
1359     use Fcntl;
1360
1361 first to get the correct constant definitions.  Argument processing and
1362 value return works just like C<ioctl()> below.  
1363 For example:
1364
1365     use Fcntl;
1366     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1367         or die "can't fcntl F_GETFL: $!";
1368
1369 You don't have to check for C<defined()> on the return from 
1370 C<fnctl()>.  Like C<ioctl()>, it maps a C<0> return from the system
1371 call into "C<0> but true" in Perl.  This string is true in 
1372 boolean context and C<0> in numeric context.  It is also 
1373 exempt from the normal B<-w> warnings on improper numeric
1374 conversions.
1375
1376 Note that C<fcntl()> will produce a fatal error if used on a machine that
1377 doesn't implement fcntl(2).
1378
1379 =item fileno FILEHANDLE
1380
1381 Returns the file descriptor for a filehandle.  This is useful for
1382 constructing bitmaps for C<select()> and low-level POSIX tty-handling
1383 operations.  If FILEHANDLE is an expression, the value is taken as 
1384 an indirect filehandle, generally its name. 
1385
1386 You can use this to find out whether two handles refer to the 
1387 same underlying descriptor:
1388
1389     if (fileno(THIS) == fileno(THAT)) {
1390         print "THIS and THAT are dups\n";
1391     } 
1392
1393 =item flock FILEHANDLE,OPERATION
1394
1395 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns TRUE for
1396 success, FALSE on failure.  Produces a fatal error if used on a machine
1397 that doesn't implement flock(2), fcntl(2) locking, or lockf(3).  C<flock()>
1398 is Perl's portable file locking interface, although it locks only entire
1399 files, not records.
1400
1401 On many platforms (including most versions or clones of Unix), locks
1402 established by C<flock()> are B<merely advisory>.  Such discretionary locks
1403 are more flexible, but offer fewer guarantees.  This means that files
1404 locked with C<flock()> may be modified by programs that do not also use
1405 C<flock()>.  Windows NT and OS/2 are among the platforms which
1406 enforce mandatory locking.  See your local documentation for details.
1407
1408 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1409 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1410 you can use the symbolic names if import them from the Fcntl module,
1411 either individually, or as a group using the ':flock' tag.  LOCK_SH
1412 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1413 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1414 LOCK_EX then C<flock()> will return immediately rather than blocking
1415 waiting for the lock (check the return status to see if you got it).
1416
1417 To avoid the possibility of mis-coordination, Perl flushes FILEHANDLE
1418 before (un)locking it.
1419
1420 Note that the emulation built with lockf(3) doesn't provide shared
1421 locks, and it requires that FILEHANDLE be open with write intent.  These
1422 are the semantics that lockf(3) implements.  Most (all?) systems
1423 implement lockf(3) in terms of fcntl(2) locking, though, so the
1424 differing semantics shouldn't bite too many people.
1425
1426 Note also that some versions of C<flock()> cannot lock things over the
1427 network; you would need to use the more system-specific C<fcntl()> for
1428 that.  If you like you can force Perl to ignore your system's flock(2)
1429 function, and so provide its own fcntl(2)-based emulation, by passing
1430 the switch C<-Ud_flock> to the F<Configure> program when you configure
1431 perl.
1432
1433 Here's a mailbox appender for BSD systems.
1434
1435     use Fcntl ':flock'; # import LOCK_* constants
1436
1437     sub lock {
1438         flock(MBOX,LOCK_EX);
1439         # and, in case someone appended
1440         # while we were waiting...
1441         seek(MBOX, 0, 2);
1442     }
1443
1444     sub unlock {
1445         flock(MBOX,LOCK_UN);
1446     }
1447
1448     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1449             or die "Can't open mailbox: $!";
1450
1451     lock();
1452     print MBOX $msg,"\n\n";
1453     unlock();
1454
1455 See also L<DB_File> for other flock() examples.
1456
1457 =item for (INITIAL; WHILE; EACH) BLOCK
1458
1459 Do INITIAL, enter BLOCK while EXPR is true, at the end of each round
1460 do EACH. For example:
1461
1462         for ($i = 0, $j = 0; $i < 10; $i++) {
1463                 if ($i % 3 == 0) { $j++ }
1464                 print "i = $i, j = $j\n";
1465         }
1466
1467 See L<perlsyn> for more details.  See also L</foreach>, a twin of
1468 C<for>, L</while> and L</until>, close cousins of L<for>, and
1469 L</last>, L</next>, and L</redo> for additional control flow.
1470
1471 =item foreach LOOPVAR (LIST) BLOCK
1472
1473 Enter BLOCK as LOOPVAR set in turn to each element of LIST.
1474 For example:
1475
1476         foreach $rolling (@stones) { print "rolling $stone\n" }
1477
1478         foreach my $file (@files)  { print "file $file\n" }
1479
1480 The LOOPVAR is optional and defaults to C<$_>.  If the elements are
1481 modifiable (as opposed to constants or tied variables) you can modify them.
1482
1483         foreach (@words) { tr/abc/xyz/ }
1484
1485 See L<perlsyn> for more details.  See also L</for>, a twin of
1486 C<foreach>, L</while> and L</until>, close cousins of L<for>, and
1487 L</last>, L</next>, and L</redo> for additional control flow.
1488
1489 =item fork
1490
1491 Does a fork(2) system call.  Returns the child pid to the parent process,
1492 C<0> to the child process, or C<undef> if the fork is unsuccessful.
1493
1494 Note: unflushed buffers remain unflushed in both processes, which means
1495 you may need to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()>
1496 method of C<IO::Handle> to avoid duplicate output.
1497
1498 If you C<fork()> without ever waiting on your children, you will accumulate
1499 zombies:
1500
1501     $SIG{CHLD} = sub { wait };
1502
1503 There's also the double-fork trick (error checking on
1504 C<fork()> returns omitted);
1505
1506     unless ($pid = fork) {
1507         unless (fork) {
1508             exec "what you really wanna do";
1509             die "no exec";
1510             # ... or ...
1511             ## (some_perl_code_here)
1512             exit 0;
1513         }
1514         exit 0;
1515     }
1516     waitpid($pid,0);
1517
1518 See also L<perlipc> for more examples of forking and reaping
1519 moribund children.
1520
1521 Note that if your forked child inherits system file descriptors like
1522 STDIN and STDOUT that are actually connected by a pipe or socket, even
1523 if you exit, then the remote server (such as, say, httpd or rsh) won't think
1524 you're done.  You should reopen those to F</dev/null> if it's any issue.
1525
1526 =item format
1527
1528 Declare a picture format for use by the C<write()> function.  For
1529 example:
1530
1531     format Something =
1532         Test: @<<<<<<<< @||||| @>>>>>
1533               $str,     $%,    '$' . int($num)
1534     .
1535
1536     $str = "widget";
1537     $num = $cost/$quantity;
1538     $~ = 'Something';
1539     write;
1540
1541 See L<perlform> for many details and examples.
1542
1543 =item formline PICTURE,LIST
1544
1545 This is an internal function used by C<format>s, though you may call it,
1546 too.  It formats (see L<perlform>) a list of values according to the
1547 contents of PICTURE, placing the output into the format output
1548 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1549 Eventually, when a C<write()> is done, the contents of
1550 C<$^A> are written to some filehandle, but you could also read C<$^A>
1551 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1552 does one C<formline()> per line of form, but the C<formline()> function itself
1553 doesn't care how many newlines are embedded in the PICTURE.  This means
1554 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1555 You may therefore need to use multiple formlines to implement a single
1556 record format, just like the format compiler.
1557
1558 Be careful if you put double quotes around the picture, because an "C<@>"
1559 character may be taken to mean the beginning of an array name.
1560 C<formline()> always returns TRUE.  See L<perlform> for other examples.
1561
1562 =item getc FILEHANDLE
1563
1564 =item getc
1565
1566 Returns the next character from the input file attached to FILEHANDLE,
1567 or the undefined value at end of file, or if there was an error.  If
1568 FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1569 efficient.  It cannot be used to get unbuffered single-characters,
1570 however.  For that, try something more like:
1571
1572     if ($BSD_STYLE) {
1573         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1574     }
1575     else {
1576         system "stty", '-icanon', 'eol', "\001";
1577     }
1578
1579     $key = getc(STDIN);
1580
1581     if ($BSD_STYLE) {
1582         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1583     }
1584     else {
1585         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1586     }
1587     print "\n";
1588
1589 Determination of whether $BSD_STYLE should be set
1590 is left as an exercise to the reader.
1591
1592 The C<POSIX::getattr()> function can do this more portably on systems
1593 purporting POSIX compliance.
1594 See also the C<Term::ReadKey> module from your nearest CPAN site;
1595 details on CPAN can be found on L<perlmodlib/CPAN>.
1596
1597 =item getlogin
1598
1599 Implements the C library function of the same name, which on most
1600 systems returns the current login from F</etc/utmp>, if any.  If null,
1601 use C<getpwuid()>.
1602
1603     $login = getlogin || getpwuid($<) || "Kilroy";
1604
1605 Do not consider C<getlogin()> for authentication: it is not as
1606 secure as C<getpwuid()>.
1607
1608 =item getpeername SOCKET
1609
1610 Returns the packed sockaddr address of other end of the SOCKET connection.
1611
1612     use Socket;
1613     $hersockaddr    = getpeername(SOCK);
1614     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1615     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1616     $herstraddr     = inet_ntoa($iaddr);
1617
1618 =item getpgrp PID
1619
1620 Returns the current process group for the specified PID.  Use
1621 a PID of C<0> to get the current process group for the
1622 current process.  Will raise an exception if used on a machine that
1623 doesn't implement getpgrp(2).  If PID is omitted, returns process
1624 group of current process.  Note that the POSIX version of C<getpgrp()>
1625 does not accept a PID argument, so only C<PID==0> is truly portable.
1626
1627 =item getppid
1628
1629 Returns the process id of the parent process.
1630
1631 =item getpriority WHICH,WHO
1632
1633 Returns the current priority for a process, a process group, or a user.
1634 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1635 machine that doesn't implement getpriority(2).
1636
1637 =item getpwnam NAME
1638
1639 =item getgrnam NAME
1640
1641 =item gethostbyname NAME
1642
1643 =item getnetbyname NAME
1644
1645 =item getprotobyname NAME
1646
1647 =item getpwuid UID
1648
1649 =item getgrgid GID
1650
1651 =item getservbyname NAME,PROTO
1652
1653 =item gethostbyaddr ADDR,ADDRTYPE
1654
1655 =item getnetbyaddr ADDR,ADDRTYPE
1656
1657 =item getprotobynumber NUMBER
1658
1659 =item getservbyport PORT,PROTO
1660
1661 =item getpwent
1662
1663 =item getgrent
1664
1665 =item gethostent
1666
1667 =item getnetent
1668
1669 =item getprotoent
1670
1671 =item getservent
1672
1673 =item setpwent
1674
1675 =item setgrent
1676
1677 =item sethostent STAYOPEN
1678
1679 =item setnetent STAYOPEN
1680
1681 =item setprotoent STAYOPEN
1682
1683 =item setservent STAYOPEN
1684
1685 =item endpwent
1686
1687 =item endgrent
1688
1689 =item endhostent
1690
1691 =item endnetent
1692
1693 =item endprotoent
1694
1695 =item endservent
1696
1697 These routines perform the same functions as their counterparts in the
1698 system library.  In list context, the return values from the
1699 various get routines are as follows:
1700
1701     ($name,$passwd,$uid,$gid,
1702        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1703     ($name,$passwd,$gid,$members) = getgr*
1704     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1705     ($name,$aliases,$addrtype,$net) = getnet*
1706     ($name,$aliases,$proto) = getproto*
1707     ($name,$aliases,$port,$proto) = getserv*
1708
1709 (If the entry doesn't exist you get a null list.)
1710
1711 In scalar context, you get the name, unless the function was a
1712 lookup by name, in which case you get the other thing, whatever it is.
1713 (If the entry doesn't exist you get the undefined value.)  For example:
1714
1715     $uid   = getpwnam($name);
1716     $name  = getpwuid($num);
1717     $name  = getpwent();
1718     $gid   = getgrnam($name);
1719     $name  = getgrgid($num;
1720     $name  = getgrent();
1721     #etc.
1722
1723 In I<getpw*()> the fields C<$quota>, C<$comment>, and C<$expire> are special
1724 cases in the sense that in many systems they are unsupported.  If the
1725 C<$quota> is unsupported, it is an empty scalar.  If it is supported, it
1726 usually encodes the disk quota.  If the C<$comment> field is unsupported,
1727 it is an empty scalar.  If it is supported it usually encodes some
1728 administrative comment about the user.  In some systems the $quota
1729 field may be C<$change> or C<$age>, fields that have to do with password
1730 aging.  In some systems the C<$comment> field may be C<$class>.  The C<$expire>
1731 field, if present, encodes the expiration period of the account or the
1732 password.  For the availability and the exact meaning of these fields
1733 in your system, please consult your getpwnam(3) documentation and your
1734 F<pwd.h> file.  You can also find out from within Perl which meaning
1735 your C<$quota> and C<$comment> fields have and whether you have the C<$expire>
1736 field by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1737 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.
1738
1739 The C<$members> value returned by I<getgr*()> is a space separated list of
1740 the login names of the members of the group.
1741
1742 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1743 C, it will be returned to you via C<$?> if the function call fails.  The
1744 C<@addrs> value returned by a successful call is a list of the raw
1745 addresses returned by the corresponding system library call.  In the
1746 Internet domain, each address is four bytes long and you can unpack it
1747 by saying something like:
1748
1749     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1750
1751 If you get tired of remembering which element of the return list contains
1752 which return value, by-name interfaces are also provided in modules:
1753 C<File::stat>, C<Net::hostent>, C<Net::netent>, C<Net::protoent>, C<Net::servent>,
1754 C<Time::gmtime>, C<Time::localtime>, and C<User::grent>.  These override the
1755 normal built-in, replacing them with versions that return objects with
1756 the appropriate names for each field.  For example:
1757
1758    use File::stat;
1759    use User::pwent;
1760    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1761
1762 Even though it looks like they're the same method calls (uid), 
1763 they aren't, because a C<File::stat> object is different from a C<User::pwent> object.
1764
1765 =item getsockname SOCKET
1766
1767 Returns the packed sockaddr address of this end of the SOCKET connection.
1768
1769     use Socket;
1770     $mysockaddr = getsockname(SOCK);
1771     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1772
1773 =item getsockopt SOCKET,LEVEL,OPTNAME
1774
1775 Returns the socket option requested, or undef if there is an error.
1776
1777 =item glob EXPR
1778
1779 =item glob
1780
1781 Returns the value of EXPR with filename expansions such as the standard Unix shell F</bin/sh> would
1782 do.  This is the internal function implementing the C<E<lt>*.cE<gt>>
1783 operator, but you can use it directly.  If EXPR is omitted, C<$_> is used.
1784 The C<E<lt>*.cE<gt>> operator is discussed in more detail in
1785 L<perlop/"I/O Operators">.
1786
1787 =item gmtime EXPR
1788
1789 Converts a time as returned by the time function to a 9-element array
1790 with the time localized for the standard Greenwich time zone.
1791 Typically used as follows:
1792
1793     #  0    1    2     3     4    5     6     7     8
1794     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1795                                             gmtime(time);
1796
1797 All array elements are numeric, and come straight out of a struct tm.
1798 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
1799 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
1800 years since 1900, that is, C<$year> is C<123> in year 2023, I<not> simply the last two digits of the year.
1801
1802 If EXPR is omitted, does C<gmtime(time())>.
1803
1804 In scalar context, returns the ctime(3) value:
1805
1806     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1807
1808 Also see the C<timegm()> function provided by the C<Time::Local> module,
1809 and the strftime(3) function available via the POSIX module.
1810
1811 This scalar value is B<not> locale dependent, see L<perllocale>, but
1812 instead a Perl builtin.  Also see the C<Time::Local> module, and the
1813 strftime(3) and mktime(3) function available via the POSIX module.  To
1814 get somewhat similar but locale dependent date strings, set up your
1815 locale environment variables appropriately (please see L<perllocale>)
1816 and try for example:
1817
1818     use POSIX qw(strftime);
1819         $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1820
1821 Note that the C<%a> and C<%b>, the short forms of the day of the week
1822 and the month of the year, may not necessarily be three characters wide.
1823
1824 =item goto LABEL
1825
1826 =item goto EXPR
1827
1828 =item goto &NAME
1829
1830 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1831 execution there.  It may not be used to go into any construct that
1832 requires initialization, such as a subroutine or a C<foreach> loop.  It
1833 also can't be used to go into a construct that is optimized away,
1834 or to get out of a block or subroutine given to C<sort()>.
1835 It can be used to go almost anywhere else within the dynamic scope,
1836 including out of subroutines, but it's usually better to use some other
1837 construct such as C<last> or C<die()>.  The author of Perl has never felt the
1838 need to use this form of C<goto> (in Perl, that is--C is another matter).
1839
1840 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1841 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1842 necessarily recommended if you're optimizing for maintainability:
1843
1844     goto ("FOO", "BAR", "GLARCH")[$i];
1845
1846 The C<goto-&NAME> form is highly magical, and substitutes a call to the
1847 named subroutine for the currently running subroutine.  This is used by
1848 C<AUTOLOAD> subroutines that wish to load another subroutine and then
1849 pretend that the other subroutine had been called in the first place
1850 (except that any modifications to C<@_> in the current subroutine are
1851 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
1852 will be able to tell that this routine was called first.
1853
1854 =item grep BLOCK LIST
1855
1856 =item grep EXPR,LIST
1857
1858 This is similar in spirit to, but not the same as, grep(1)
1859 and its relatives.  In particular, it is not limited to using
1860 regular expressions.
1861
1862 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1863 C<$_> to each element) and returns the list value consisting of those
1864 elements for which the expression evaluated to TRUE.  In a scalar
1865 context, returns the number of times the expression was TRUE.
1866
1867     @foo = grep(!/^#/, @bar);    # weed out comments
1868
1869 or equivalently,
1870
1871     @foo = grep {!/^#/} @bar;    # weed out comments
1872
1873 Note that, because C<$_> is a reference into the list value, it can be used
1874 to modify the elements of the array.  While this is useful and
1875 supported, it can cause bizarre results if the LIST is not a named
1876 array.  Similarly, grep returns aliases into the original list,
1877 much like the way that a for loop's index variable aliases the list
1878 elements.  That is, modifying an element of a list returned by grep
1879 (for example, in a C<foreach>, C<map()> or another C<grep()>)
1880 actually modifies the element in the original list.
1881
1882 See also L</map> for an array composed of the results of the BLOCK or EXPR.
1883
1884 =item hex EXPR
1885
1886 =item hex
1887
1888 Interprets EXPR as a hex string and returns the corresponding
1889 value.  (To convert strings that might start with either 0 or 0x
1890 see L</oct>.)  If EXPR is omitted, uses C<$_>.
1891
1892     print hex '0xAf'; # prints '175'
1893     print hex 'aF';   # same
1894
1895 =item if (EXPR) BLOCK
1896
1897 =item if (EXPR) BLOCK else BLOCK2
1898
1899 =item if (EXPR) BLOCK elsif (EXPR2) BLOCK2
1900
1901 Enter BLOCKs conditionally.  The first EXPR to return true
1902 causes the corresponding BLOCK to be entered, or, in the case
1903 of C<else>, the fall-through default BLOCK.
1904
1905 Note 1: Perl wants BLOCKS, expressions won't do (like they do
1906 e.g. in C, C++, Java, Pascal).
1907
1908 Note 2: It's C<elsif>, not C<elseif>.  You can have as many
1909 C<elsif>s as you want.
1910
1911 See L<perlsyn> for more details.  See also C<unless>.
1912
1913 =item import
1914
1915 There is no builtin C<import()> function.  It is just an ordinary
1916 method (subroutine) defined (or inherited) by modules that wish to export
1917 names to another module.  The C<use()> function calls the C<import()> method
1918 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1919
1920 =item index STR,SUBSTR,POSITION
1921
1922 =item index STR,SUBSTR
1923
1924 Returns the position of the first occurrence of SUBSTR in STR at or after
1925 POSITION.  If POSITION is omitted, starts searching from the beginning of
1926 the string.  The return value is based at C<0> (or whatever you've set the C<$[>
1927 variable to--but don't do that).  If the substring is not found, returns
1928 one less than the base, ordinarily C<-1>.
1929
1930 =item int EXPR
1931
1932 =item int
1933
1934 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
1935 You should not use this for rounding, because it truncates
1936 towards C<0>, and because machine representations of floating point
1937 numbers can sometimes produce counterintuitive results.  Usually C<sprintf()> or C<printf()>,
1938 or the C<POSIX::floor> or C<POSIX::ceil> functions, would serve you better.
1939
1940 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1941
1942 Implements the ioctl(2) function.  You'll probably have to say
1943
1944     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1945
1946 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1947 exist or doesn't have the correct definitions you'll have to roll your
1948 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1949 (There is a Perl script called B<h2ph> that comes with the Perl kit that
1950 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
1951 written depending on the FUNCTION--a pointer to the string value of SCALAR
1952 will be passed as the third argument of the actual C<ioctl()> call.  (If SCALAR
1953 has no string value but does have a numeric value, that value will be
1954 passed rather than a pointer to the string value.  To guarantee this to be
1955 TRUE, add a C<0> to the scalar before using it.)  The C<pack()> and C<unpack()>
1956 functions are useful for manipulating the values of structures used by
1957 C<ioctl()>.  The following example sets the erase character to DEL.
1958
1959     require 'ioctl.ph';
1960     $getp = &TIOCGETP;
1961     die "NO TIOCGETP" if $@ || !$getp;
1962     $sgttyb_t = "ccccs";                # 4 chars and a short
1963     if (ioctl(STDIN,$getp,$sgttyb)) {
1964         @ary = unpack($sgttyb_t,$sgttyb);
1965         $ary[2] = 127;
1966         $sgttyb = pack($sgttyb_t,@ary);
1967         ioctl(STDIN,&TIOCSETP,$sgttyb)
1968             || die "Can't ioctl: $!";
1969     }
1970
1971 The return value of C<ioctl()> (and C<fcntl()>) is as follows:
1972
1973         if OS returns:          then Perl returns:
1974             -1                    undefined value
1975              0                  string "0 but true"
1976         anything else               that number
1977
1978 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1979 still easily determine the actual value returned by the operating
1980 system:
1981
1982     ($retval = ioctl(...)) || ($retval = -1);
1983     printf "System returned %d\n", $retval;
1984
1985 The special string "C<0> but true" is excempt from B<-w> complaints
1986 about improper numeric conversions.
1987
1988 =item join EXPR,LIST
1989
1990 Joins the separate strings of LIST into a single string with
1991 fields separated by the value of EXPR, and returns the string.
1992 Example:
1993
1994     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1995
1996 See L</split>.
1997
1998 =item keys HASH
1999
2000 Returns a list consisting of all the keys of the named hash.  (In a
2001 scalar context, returns the number of keys.)  The keys are returned in
2002 an apparently random order.  The actual random order is subject to
2003 change in future versions of perl, but it is guaranteed to be the same
2004 order as either the C<values()> or C<each()> function produces (given
2005 that the hash has not been modified).  As a side effect, it resets
2006 HASH's iterator.
2007
2008 Here is yet another way to print your environment:
2009
2010     @keys = keys %ENV;
2011     @values = values %ENV;
2012     while ($#keys >= 0) {
2013         print pop(@keys), '=', pop(@values), "\n";
2014     }
2015
2016 or how about sorted by key:
2017
2018     foreach $key (sort(keys %ENV)) {
2019         print $key, '=', $ENV{$key}, "\n";
2020     }
2021
2022 To sort a hash by value, you'll need to use a C<sort()> function.
2023 Here's a descending numeric sort of a hash by its values:
2024
2025     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2026         printf "%4d %s\n", $hash{$key}, $key;
2027     }
2028
2029 As an lvalue C<keys()> allows you to increase the number of hash buckets
2030 allocated for the given hash.  This can gain you a measure of efficiency if
2031 you know the hash is going to get big.  (This is similar to pre-extending
2032 an array by assigning a larger number to $#array.)  If you say
2033
2034     keys %hash = 200;
2035
2036 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2037 in fact, since it rounds up to the next power of two.  These
2038 buckets will be retained even if you do C<%hash = ()>, use C<undef
2039 %hash> if you want to free the storage while C<%hash> is still in scope.
2040 You can't shrink the number of buckets allocated for the hash using
2041 C<keys()> in this way (but you needn't worry about doing this by accident,
2042 as trying has no effect).
2043
2044 See also C<each()>, C<values()> and C<sort()>.
2045
2046 =item kill LIST
2047
2048 Sends a signal to a list of processes.  The first element of
2049 the list must be the signal to send.  Returns the number of
2050 processes successfully signaled.
2051
2052     $cnt = kill 1, $child1, $child2;
2053     kill 9, @goners;
2054
2055 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
2056 process groups instead of processes.  (On System V, a negative I<PROCESS>
2057 number will also kill process groups, but that's not portable.)  That
2058 means you usually want to use positive not negative signals.  You may also
2059 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2060
2061 =item last LABEL
2062
2063 =item last
2064
2065 The C<last> command is like the C<break> statement in C (as used in
2066 loops); it immediately exits the loop in question.  If the LABEL is
2067 omitted, the command refers to the innermost enclosing loop.  The
2068 C<continue> block, if any, is not executed:
2069
2070     LINE: while (<STDIN>) {
2071         last LINE if /^$/;      # exit when done with header
2072         #...
2073     }
2074
2075 C<last> cannot be used to exit a block which returns a value such as
2076 C<eval {}>, C<sub {}> or C<do {}>.
2077
2078 See also L</continue> for an illustration of how C<last>, L</next>, and
2079 L</redo> work.
2080
2081 See also L<perlsyn>.
2082
2083 =item lc EXPR
2084
2085 =item lc
2086
2087 Returns an lowercased version of EXPR.  This is the internal function
2088 implementing the C<\L> escape in double-quoted strings.
2089 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2090
2091 If EXPR is omitted, uses C<$_>.
2092
2093 =item lcfirst EXPR
2094
2095 =item lcfirst
2096
2097 Returns the value of EXPR with the first character lowercased.  This is
2098 the internal function implementing the C<\l> escape in double-quoted strings.
2099 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2100
2101 If EXPR is omitted, uses C<$_>.
2102
2103 =item length EXPR
2104
2105 =item length
2106
2107 Returns the length in characters of the value of EXPR.  If EXPR is
2108 omitted, returns length of C<$_>.
2109
2110 =item link OLDFILE,NEWFILE
2111
2112 Creates a new filename linked to the old filename.  Returns TRUE for
2113 success, FALSE otherwise.
2114
2115 =item listen SOCKET,QUEUESIZE
2116
2117 Does the same thing that the listen system call does.  Returns TRUE if
2118 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
2119
2120 =item local EXPR
2121
2122 A local modifies the listed variables to be local to the enclosing
2123 block, file, or eval.  If more than one value is listed, the list must
2124 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2125 for details, including issues with tied arrays and hashes.
2126
2127 You really probably want to be using C<my()> instead, because C<local()> isn't
2128 what most people think of as "local".  See L<perlsub/"Private Variables
2129 via my()"> for details.
2130
2131 =item localtime EXPR
2132
2133 Converts a time as returned by the time function to a 9-element array
2134 with the time analyzed for the local time zone.  Typically used as
2135 follows:
2136
2137     #  0    1    2     3     4    5     6     7     8
2138     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2139                                                 localtime(time);
2140
2141 All array elements are numeric, and come straight out of a struct tm.
2142 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
2143 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
2144 years since 1900, that is, C<$year> is C<123> in year 2023, and I<not> simply the last two digits of the year.
2145
2146 If EXPR is omitted, uses the current time (C<localtime(time)>).
2147
2148 In scalar context, returns the ctime(3) value:
2149
2150     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2151
2152 This scalar value is B<not> locale dependent, see L<perllocale>, but
2153 instead a Perl builtin.  Also see the C<Time::Local> module, and the
2154 strftime(3) and mktime(3) function available via the POSIX module.  To
2155 get somewhat similar but locale dependent date strings, set up your
2156 locale environment variables appropriately (please see L<perllocale>)
2157 and try for example:
2158
2159     use POSIX qw(strftime);
2160         $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2161
2162 Note that the C<%a> and C<%b>, the short forms of the day of the week
2163 and the month of the year, may not necessarily be three characters wide.
2164
2165 =item log EXPR
2166
2167 =item log
2168
2169 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
2170 of C<$_>.
2171
2172 =item lstat FILEHANDLE
2173
2174 =item lstat EXPR
2175
2176 =item lstat
2177
2178 Does the same thing as the C<stat()> function (including setting the
2179 special C<_> filehandle) but stats a symbolic link instead of the file
2180 the symbolic link points to.  If symbolic links are unimplemented on
2181 your system, a normal C<stat()> is done.
2182
2183 If EXPR is omitted, stats C<$_>.
2184
2185 =item m//
2186
2187 The match operator.  See L<perlop>.
2188
2189 =item map BLOCK LIST
2190
2191 =item map EXPR,LIST
2192
2193 Evaluates the BLOCK or EXPR for each element of LIST (locally setting C<$_> to each
2194 element) and returns the list value composed of the results of each such
2195 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
2196 may produce zero, one, or more elements in the returned value.
2197
2198     @chars = map(chr, @nums);
2199
2200 translates a list of numbers to the corresponding characters.  And
2201
2202     %hash = map { getkey($_) => $_ } @array;
2203
2204 is just a funny way to write
2205
2206     %hash = ();
2207     foreach $_ (@array) {
2208         $hash{getkey($_)} = $_;
2209     }
2210
2211 Note that, because C<$_> is a reference into the list value, it can be used
2212 to modify the elements of the array.  While this is useful and
2213 supported, it can cause bizarre results if the LIST is not a named
2214 array.  See also L</grep> for an array composed of those items of the 
2215 original list for which the BLOCK or EXPR evaluates to true.
2216
2217 =item mkdir FILENAME,MODE
2218
2219 Creates the directory specified by FILENAME, with permissions
2220 specified by MODE (as modified by C<umask>).  If it succeeds it
2221 returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).
2222
2223 In general, it is better to create directories with permissive MODEs,
2224 and let the user modify that with their C<umask>, than it is to supply
2225 a restrictive MODE and give the user no way to be more permissive.
2226 The exceptions to this rule are when the file or directory should be
2227 kept private (mail files, for instance).  The perlfunc(1) entry on
2228 C<umask> discusses the choice of MODE in more detail.
2229
2230 =item msgctl ID,CMD,ARG
2231
2232 Calls the System V IPC function msgctl(2).  You'll probably have to say
2233
2234     use IPC::SysV;
2235
2236 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2237 then ARG must be a variable which will hold the returned C<msqid_ds>
2238 structure.  Returns like C<ioctl()>: the undefined value for error, "C<0> but
2239 true" for zero, or the actual return value otherwise.  See also
2240 C<IPC::SysV> and C<IPC::Semaphore::Msg> documentation.
2241
2242 =item msgget KEY,FLAGS
2243
2244 Calls the System V IPC function msgget(2).  Returns the message queue
2245 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2246 and C<IPC::SysV::Msg> documentation.
2247
2248 =item msgsnd ID,MSG,FLAGS
2249
2250 Calls the System V IPC function msgsnd to send the message MSG to the
2251 message queue ID.  MSG must begin with the long integer message type,
2252 which may be created with C<pack("l", $type)>.  Returns TRUE if
2253 successful, or FALSE if there is an error.  See also C<IPC::SysV>
2254 and C<IPC::SysV::Msg> documentation.
2255
2256 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2257
2258 Calls the System V IPC function msgrcv to receive a message from
2259 message queue ID into variable VAR with a maximum message size of
2260 SIZE.  Note that if a message is received, the message type will be
2261 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2262 size of the message type.  Returns TRUE if successful, or FALSE if
2263 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2264
2265 =item my EXPR
2266
2267 A C<my()> declares the listed variables to be local (lexically) to the
2268 enclosing block, file, or C<eval()>.  If
2269 more than one value is listed, the list must be placed in parentheses.  See
2270 L<perlsub/"Private Variables via my()"> for details.
2271
2272 =item next LABEL
2273
2274 =item next
2275
2276 The C<next> command is like the C<continue> statement in C; it starts
2277 the next iteration of the loop:
2278
2279     LINE: while (<STDIN>) {
2280         next LINE if /^#/;      # discard comments
2281         #...
2282     }
2283
2284 Note that if there were a C<continue> block on the above, it would get
2285 executed even on discarded lines.  If the LABEL is omitted, the command
2286 refers to the innermost enclosing loop.
2287
2288 C<next> cannot be used to exit a block which returns a value such as
2289 C<eval {}>, C<sub {}> or C<do {}>.
2290
2291 See also L</continue> for an illustration of how L</last>, C<next>, and
2292 L</redo> work.
2293
2294 See also L<perlsyn>.
2295
2296 =item no Module LIST
2297
2298 See the L</use> function, which C<no> is the opposite of.
2299
2300 =item oct EXPR
2301
2302 =item oct
2303
2304 Interprets EXPR as an octal string and returns the corresponding
2305 value.  (If EXPR happens to start off with C<0x>, interprets it as
2306 a hex string instead.)  The following will handle decimal, octal, and
2307 hex in the standard Perl or C notation:
2308
2309     $val = oct($val) if $val =~ /^0/;
2310
2311 If EXPR is omitted, uses C<$_>.  This function is commonly used when
2312 a string such as C<644> needs to be converted into a file mode, for
2313 example. (Although perl will automatically convert strings into
2314 numbers as needed, this automatic conversion assumes base 10.)
2315
2316 =item open FILEHANDLE,EXPR
2317
2318 =item open FILEHANDLE
2319
2320 Opens the file whose filename is given by EXPR, and associates it with
2321 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2322 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2323 variable of the same name as the FILEHANDLE contains the filename.
2324 (Note that lexical variables--those declared with C<my()>--will not work
2325 for this purpose; so if you're using C<my()>, specify EXPR in your call
2326 to open.)
2327
2328 If the filename begins with C<'E<lt>'> or nothing, the file is opened for input.
2329 If the filename begins with C<'E<gt>'>, the file is truncated and opened for
2330 output, being created if necessary. If the filename begins with C<'E<gt>E<gt>'>,
2331 the file is opened for appending, again being created if necessary. 
2332 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2333 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2334 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2335 file first.  You can't usually use either read-write mode for updating
2336 textfiles, since they have variable length records.  See the B<-i>
2337 switch in L<perlrun> for a better approach.  The file is created with
2338 permissions of C<0666> modified by the process' C<umask> value.
2339
2340 The prefix and the filename may be separated with spaces.
2341 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2342 C<'w+'>, C<'a'>, and C<'a+'>.
2343
2344 If the filename begins with C<'|'>, the filename is interpreted as a
2345 command to which output is to be piped, and if the filename ends with a
2346 C<'|'>, the filename is interpreted See L<perlipc/"Using open() for IPC">
2347 for more examples of this.  (You are not allowed to C<open()> to a command
2348 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2349 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2350
2351 Opening C<'-'> opens STDIN and opening C<'E<gt>-'> opens STDOUT.  Open returns
2352 nonzero upon success, the undefined value otherwise.  If the C<open()>
2353 involved a pipe, the return value happens to be the pid of the
2354 subprocess.
2355
2356 If you're unfortunate enough to be running Perl on a system that
2357 distinguishes between text files and binary files (modern operating
2358 systems don't care), then you should check out L</binmode> for tips for
2359 dealing with this.  The key distinction between systems that need C<binmode()>
2360 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2361 Plan9, which delimit lines with a single character, and which encode that
2362 character in C as C<"\n">, do not need C<binmode()>.  The rest need it.
2363
2364 When opening a file, it's usually a bad idea to continue normal execution
2365 if the request failed, so C<open()> is frequently used in connection with
2366 C<die()>. Even if C<die()> won't do what you want (say, in a CGI script,
2367 where you want to make a nicely formatted error message (but there are
2368 modules that can help with that problem)) you should always check
2369 the return value from opening a file. The infrequent exception is when
2370 working with an unopened filehandle is actually what you want to do.
2371
2372 Examples:
2373
2374     $ARTICLE = 100;
2375     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2376     while (<ARTICLE>) {...
2377
2378     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
2379     # if the open fails, output is discarded
2380
2381     open(DBASE, '+<dbase.mine')             # open for update
2382         or die "Can't open 'dbase.mine' for update: $!";
2383
2384     open(ARTICLE, "caesar <$article |")     # decrypt article
2385         or die "Can't start caesar: $!";
2386
2387     open(EXTRACT, "|sort >/tmp/Tmp$$")      # $$ is our process id
2388         or die "Can't start sort: $!";
2389
2390     # process argument list of files along with any includes
2391
2392     foreach $file (@ARGV) {
2393         process($file, 'fh00');
2394     }
2395
2396     sub process {
2397         my($filename, $input) = @_;
2398         $input++;               # this is a string increment
2399         unless (open($input, $filename)) {
2400             print STDERR "Can't open $filename: $!\n";
2401             return;
2402         }
2403
2404         local $_;
2405         while (<$input>) {              # note use of indirection
2406             if (/^#include "(.*)"/) {
2407                 process($1, $input);
2408                 next;
2409             }
2410             #...                # whatever
2411         }
2412     }
2413
2414 You may also, in the Bourne shell tradition, specify an EXPR beginning
2415 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2416 name of a filehandle (or file descriptor, if numeric) to be
2417 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>, C<E<lt>>, C<+E<gt>>,
2418 C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2419 mode you specify should match the mode of the original filehandle.
2420 (Duping a filehandle does not take into account any existing contents of
2421 stdio buffers.)
2422 Here is a script that saves, redirects, and restores STDOUT and
2423 STDERR:
2424
2425     #!/usr/bin/perl
2426     open(OLDOUT, ">&STDOUT");
2427     open(OLDERR, ">&STDERR");
2428
2429     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
2430     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
2431
2432     select(STDERR); $| = 1;     # make unbuffered
2433     select(STDOUT); $| = 1;     # make unbuffered
2434
2435     print STDOUT "stdout 1\n";  # this works for
2436     print STDERR "stderr 1\n";  # subprocesses too
2437
2438     close(STDOUT);
2439     close(STDERR);
2440
2441     open(STDOUT, ">&OLDOUT");
2442     open(STDERR, ">&OLDERR");
2443
2444     print STDOUT "stdout 2\n";
2445     print STDERR "stderr 2\n";
2446
2447
2448 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2449 equivalent of C's C<fdopen()> of that file descriptor; this is more
2450 parsimonious of file descriptors.  For example:
2451
2452     open(FILEHANDLE, "<&=$fd")
2453
2454 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>, then
2455 there is an implicit fork done, and the return value of open is the pid
2456 of the child within the parent process, and C<0> within the child
2457 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2458 The filehandle behaves normally for the parent, but i/o to that
2459 filehandle is piped from/to the STDOUT/STDIN of the child process.
2460 In the child process the filehandle isn't opened--i/o happens from/to
2461 the new STDOUT or STDIN.  Typically this is used like the normal
2462 piped open when you want to exercise more control over just how the
2463 pipe command gets executed, such as when you are running setuid, and
2464 don't want to have to scan shell commands for metacharacters.
2465 The following pairs are more or less equivalent:
2466
2467     open(FOO, "|tr '[a-z]' '[A-Z]'");
2468     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2469
2470     open(FOO, "cat -n '$file'|");
2471     open(FOO, "-|") || exec 'cat', '-n', $file;
2472
2473 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2474
2475 NOTE: On any operation that may do a fork, any unflushed buffers remain
2476 unflushed in both processes, which means you may need to set C<$|> to
2477 avoid duplicate output.  On systems that support a close-on-exec flag on
2478 files, the flag will be set for the newly opened file descriptor as
2479 determined by the value of $^F.  See L<perlvar/$^F>.
2480
2481 Closing any piped filehandle causes the parent process to wait for the
2482 child to finish, and returns the status value in C<$?>.
2483
2484 The filename passed to open will have leading and trailing
2485 whitespace deleted, and the normal redirection characters
2486 honored.  This property, known as "magic open", 
2487 can often be used to good effect.  A user could specify a filename of
2488 F<"rsh cat file |">, or you could change certain filenames as needed:
2489
2490     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2491     open(FH, $filename) or die "Can't open $filename: $!";
2492
2493 However, to open a file with arbitrary weird characters in it, it's
2494 necessary to protect any leading and trailing whitespace:
2495
2496     $file =~ s#^(\s)#./$1#;
2497     open(FOO, "< $file\0");
2498
2499 If you want a "real" C C<open()> (see L<open(2)> on your system), then you
2500 should use the C<sysopen()> function, which involves no such magic.  This is
2501 another way to protect your filenames from interpretation.  For example:
2502
2503     use IO::Handle;
2504     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2505         or die "sysopen $path: $!";
2506     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2507     print HANDLE "stuff $$\n");
2508     seek(HANDLE, 0, 0);
2509     print "File contains: ", <HANDLE>;
2510
2511 Using the constructor from the C<IO::Handle> package (or one of its
2512 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2513 filehandles that have the scope of whatever variables hold references to
2514 them, and automatically close whenever and however you leave that scope:
2515
2516     use IO::File;
2517     #...
2518     sub read_myfile_munged {
2519         my $ALL = shift;
2520         my $handle = new IO::File;
2521         open($handle, "myfile") or die "myfile: $!";
2522         $first = <$handle>
2523             or return ();     # Automatically closed here.
2524         mung $first or die "mung failed";       # Or here.
2525         return $first, <$handle> if $ALL;       # Or here.
2526         $first;                                 # Or here.
2527     }
2528
2529 See L</seek> for some details about mixing reading and writing.
2530
2531 =item opendir DIRHANDLE,EXPR
2532
2533 Opens a directory named EXPR for processing by C<readdir()>, C<telldir()>,
2534 C<seekdir()>, C<rewinddir()>, and C<closedir()>.  Returns TRUE if successful.
2535 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2536
2537 =item ord EXPR
2538
2539 =item ord
2540
2541 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2542 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2543
2544 =item pack TEMPLATE,LIST
2545
2546 Takes an array or list of values and packs it into a binary structure,
2547 returning the string containing the structure.  The TEMPLATE is a
2548 sequence of characters that give the order and type of values, as
2549 follows:
2550
2551     A   An ascii string, will be space padded.
2552     a   An ascii string, will be null padded.
2553     b   A bit string (ascending bit order, like vec()).
2554     B   A bit string (descending bit order).
2555     h   A hex string (low nybble first).
2556     H   A hex string (high nybble first).
2557
2558     c   A signed char value.
2559     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2560
2561     s   A signed short value.
2562     S   An unsigned short value.
2563           (This 'short' is _exactly_ 16 bits, which may differ from
2564            what a local C compiler calls 'short'.)
2565
2566     i   A signed integer value.
2567     I   An unsigned integer value.
2568           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2569            size depends on what a local C compiler calls 'int',
2570            and may even be larger than the 'long' described in
2571            the next item.)
2572
2573     l   A signed long value.
2574     L   An unsigned long value.
2575           (This 'long' is _exactly_ 32 bits, which may differ from
2576            what a local C compiler calls 'long'.)
2577
2578     n   A short in "network" (big-endian) order.
2579     N   A long in "network" (big-endian) order.
2580     v   A short in "VAX" (little-endian) order.
2581     V   A long in "VAX" (little-endian) order.
2582           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2583            _exactly_ 32 bits, respectively.)
2584
2585     q   A signed quad (64-bit) value.
2586     Q   An unsigned quad value.
2587           (Available only if your system supports 64-bit integer values
2588            _and_ if Perl has been compiled to support those.
2589            Causes a fatal error otherwise.)
2590
2591     f   A single-precision float in the native format.
2592     d   A double-precision float in the native format.
2593
2594     p   A pointer to a null-terminated string.
2595     P   A pointer to a structure (fixed-length string).
2596
2597     u   A uuencoded string.
2598     U   A Unicode character number.  Encodes to UTF-8 internally.
2599         Works even if C<use utf8> is not in effect.
2600
2601     w   A BER compressed integer.  Its bytes represent an unsigned
2602         integer in base 128, most significant digit first, with as
2603         few digits as possible.  Bit eight (the high bit) is set
2604         on each byte except the last.
2605
2606     x   A null byte.
2607     X   Back up a byte.
2608     @   Null fill to absolute position.
2609
2610 Each letter may optionally be followed by a number giving a repeat
2611 count.  With all types except C<"a">, C<"A">, C<"b">, C<"B">, C<"h">, C<"H">, and C<"P"> the
2612 pack function will gobble up that many values from the LIST.  A C<*> for the
2613 repeat count means to use however many items are left.  The C<"a"> and C<"A">
2614 types gobble just one value, but pack it as a string of length count,
2615 padding with nulls or spaces as necessary.  (When unpacking, C<"A"> strips
2616 trailing spaces and nulls, but C<"a"> does not.)  Likewise, the C<"b"> and C<"B">
2617 fields pack a string that many bits long.  The C<"h"> and C<"H"> fields pack a
2618 string that many nybbles long.  The C<"p"> type packs a pointer to a null-
2619 terminated string.  You are responsible for ensuring the string is not a
2620 temporary value (which can potentially get deallocated before you get
2621 around to using the packed result).  The C<"P"> packs a pointer to a structure
2622 of the size indicated by the length. A NULL pointer is created if the 
2623 corresponding value for C<"p"> or C<"P"> is C<undef>.
2624 Real numbers (floats and doubles) are
2625 in the native machine format only; due to the multiplicity of floating
2626 formats around, and the lack of a standard "network" representation, no
2627 facility for interchange has been made.  This means that packed floating
2628 point data written on one machine may not be readable on another - even if
2629 both use IEEE floating point arithmetic (as the endian-ness of the memory
2630 representation is not part of the IEEE spec).  Note that Perl uses doubles
2631 internally for all numeric calculation, and converting from double into
2632 float and thence back to double again will lose precision (i.e.,
2633 C<unpack("f", pack("f", $foo)>) will not in general equal C<$foo>).
2634
2635 Examples:
2636
2637     $foo = pack("CCCC",65,66,67,68);
2638     # foo eq "ABCD"
2639     $foo = pack("C4",65,66,67,68);
2640     # same thing
2641     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
2642     # same thing with Unicode circled letters
2643
2644     $foo = pack("ccxxcc",65,66,67,68);
2645     # foo eq "AB\0\0CD"
2646
2647     $foo = pack("s2",1,2);
2648     # "\1\0\2\0" on little-endian
2649     # "\0\1\0\2" on big-endian
2650
2651     $foo = pack("a4","abcd","x","y","z");
2652     # "abcd"
2653
2654     $foo = pack("aaaa","abcd","x","y","z");
2655     # "axyz"
2656
2657     $foo = pack("a14","abcdefg");
2658     # "abcdefg\0\0\0\0\0\0\0"
2659
2660     $foo = pack("i9pl", gmtime);
2661     # a real struct tm (on my system anyway)
2662
2663     sub bintodec {
2664         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2665     }
2666
2667 The same template may generally also be used in the unpack function.
2668
2669 =item package 
2670
2671 =item package NAMESPACE
2672
2673 Declares the compilation unit as being in the given namespace.  The scope
2674 of the package declaration is from the declaration itself through the end of
2675 the enclosing block (the same scope as the C<local()> operator).  All further
2676 unqualified dynamic identifiers will be in this namespace.  A package
2677 statement affects only dynamic variables--including those you've used
2678 C<local()> on--but I<not> lexical variables created with C<my()>.  Typically it
2679 would be the first declaration in a file to be included by the C<require>
2680 or C<use> operator.  You can switch into a package in more than one place;
2681 it merely influences which symbol table is used by the compiler for the
2682 rest of that block.  You can refer to variables and filehandles in other
2683 packages by prefixing the identifier with the package name and a double
2684 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2685 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2686
2687 If NAMESPACE is omitted, then there is no current package, and all
2688 identifiers must be fully qualified or lexicals.  This is stricter
2689 than C<use strict>, since it also extends to function names.
2690
2691 See L<perlmod/"Packages"> for more information about packages, modules,
2692 and classes.  See L<perlsub> for other scoping issues.
2693
2694 =item pipe READHANDLE,WRITEHANDLE
2695
2696 Opens a pair of connected pipes like the corresponding system call.
2697 Note that if you set up a loop of piped processes, deadlock can occur
2698 unless you are very careful.  In addition, note that Perl's pipes use
2699 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2700 after each command, depending on the application.
2701
2702 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2703 for examples of such things.
2704
2705 On systems that support a close-on-exec flag on files, the flag will be set
2706 for the newly opened file descriptors as determined by the value of $^F.
2707 See L<perlvar/$^F>.
2708
2709 =item pop ARRAY
2710
2711 =item pop
2712
2713 Pops and returns the last value of the array, shortening the array by
2714 1.  Has a similar effect to
2715
2716     $tmp = $ARRAY[$#ARRAY--];
2717
2718 If there are no elements in the array, returns the undefined value.
2719 If ARRAY is omitted, pops the
2720 C<@ARGV> array in the main program, and the C<@_> array in subroutines, just
2721 like C<shift()>.
2722
2723 =item pos SCALAR
2724
2725 =item pos
2726
2727 Returns the offset of where the last C<m//g> search left off for the variable
2728 is in question (C<$_> is used when the variable is not specified).  May be
2729 modified to change that offset.  Such modification will also influence
2730 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2731 L<perlop>.
2732
2733 =item print FILEHANDLE LIST
2734
2735 =item print LIST
2736
2737 =item print
2738
2739 Prints a string or a comma-separated list of strings.  Returns TRUE
2740 if successful.  FILEHANDLE may be a scalar variable name, in which case
2741 the variable contains the name of or a reference to the filehandle, thus introducing one
2742 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2743 token is a term, it may be misinterpreted as an operator unless you
2744 interpose a C<+> or put parentheses around the arguments.)  If FILEHANDLE is
2745 omitted, prints by default to standard output (or to the last selected
2746 output channel--see L</select>).  If LIST is also omitted, prints C<$_> to
2747 the currently selected output channel.  To set the default output channel to something other than
2748 STDOUT use the select operation.  Note that, because print takes a
2749 LIST, anything in the LIST is evaluated in list context, and any
2750 subroutine that you call will have one or more of its expressions
2751 evaluated in list context.  Also be careful not to follow the print
2752 keyword with a left parenthesis unless you want the corresponding right
2753 parenthesis to terminate the arguments to the print--interpose a C<+> or
2754 put parentheses around all the arguments.
2755
2756 Note that if you're storing FILEHANDLES in an array or other expression,
2757 you will have to use a block returning its value instead:
2758
2759     print { $files[$i] } "stuff\n";
2760     print { $OK ? STDOUT : STDERR } "stuff\n";
2761
2762 =item printf FILEHANDLE FORMAT, LIST
2763
2764 =item printf FORMAT, LIST
2765
2766 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
2767 (the output record separator) is not appended.  The first argument
2768 of the list will be interpreted as the C<printf()> format.  If C<use locale> is
2769 in effect, the character used for the decimal point in formatted real numbers
2770 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2771
2772 Don't fall into the trap of using a C<printf()> when a simple
2773 C<print()> would do.  The C<print()> is more efficient and less
2774 error prone.
2775
2776 =item prototype FUNCTION
2777
2778 Returns the prototype of a function as a string (or C<undef> if the
2779 function has no prototype).  FUNCTION is a reference to, or the name of,
2780 the function whose prototype you want to retrieve.
2781
2782 If FUNCTION is a string starting with C<CORE::>, the rest is taken as
2783 a name for Perl builtin.  If builtin is not I<overridable> (such as
2784 C<qw//>) or its arguments cannot be expressed by a prototype (such as
2785 C<system()>) - in other words, the builtin does not behave like a Perl
2786 function - returns C<undef>.  Otherwise, the string describing the
2787 equivalent prototype is returned.
2788
2789 =item push ARRAY,LIST
2790
2791 Treats ARRAY as a stack, and pushes the values of LIST
2792 onto the end of ARRAY.  The length of ARRAY increases by the length of
2793 LIST.  Has the same effect as
2794
2795     for $value (LIST) {
2796         $ARRAY[++$#ARRAY] = $value;
2797     }
2798
2799 but is more efficient.  Returns the new number of elements in the array.
2800
2801 =item q/STRING/
2802
2803 =item qq/STRING/
2804
2805 =item qr/STRING/
2806
2807 =item qx/STRING/
2808
2809 =item qw/STRING/
2810
2811 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
2812
2813 =item quotemeta EXPR
2814
2815 =item quotemeta
2816
2817 Returns the value of EXPR with all non-alphanumeric
2818 characters backslashed.  (That is, all characters not matching
2819 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2820 returned string, regardless of any locale settings.)
2821 This is the internal function implementing
2822 the C<\Q> escape in double-quoted strings.
2823
2824 If EXPR is omitted, uses C<$_>.
2825
2826 =item rand EXPR
2827
2828 =item rand
2829
2830 Returns a random fractional number greater than or equal to C<0> and less
2831 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
2832 omitted, the value C<1> is used.  Automatically calls C<srand()> unless
2833 C<srand()> has already been called.  See also C<srand()>.
2834
2835 (Note: If your rand function consistently returns numbers that are too
2836 large or too small, then your version of Perl was probably compiled
2837 with the wrong number of RANDBITS.)
2838
2839 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2840
2841 =item read FILEHANDLE,SCALAR,LENGTH
2842
2843 Attempts to read LENGTH bytes of data into variable SCALAR from the
2844 specified FILEHANDLE.  Returns the number of bytes actually read,
2845 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
2846 or shrunk to the length actually read.  An OFFSET may be specified to
2847 place the read data at some other place than the beginning of the
2848 string.  This call is actually implemented in terms of stdio's fread(3)
2849 call.  To get a true read(2) system call, see C<sysread()>.
2850
2851 =item readdir DIRHANDLE
2852
2853 Returns the next directory entry for a directory opened by C<opendir()>.
2854 If used in list context, returns all the rest of the entries in the
2855 directory.  If there are no more entries, returns an undefined value in
2856 scalar context or a null list in list context.
2857
2858 If you're planning to filetest the return values out of a C<readdir()>, you'd
2859 better prepend the directory in question.  Otherwise, because we didn't
2860 C<chdir()> there, it would have been testing the wrong file.
2861
2862     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2863     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2864     closedir DIR;
2865
2866 =item readline EXPR
2867
2868 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar context, a single line
2869 is read and returned.  In list context, reads until end-of-file is
2870 reached and returns a list of lines (however you've defined lines
2871 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2872 This is the internal function implementing the C<E<lt>EXPRE<gt>>
2873 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
2874 operator is discussed in more detail in L<perlop/"I/O Operators">.
2875
2876     $line = <STDIN>;
2877     $line = readline(*STDIN);           # same thing
2878
2879 =item readlink EXPR
2880
2881 =item readlink
2882
2883 Returns the value of a symbolic link, if symbolic links are
2884 implemented.  If not, gives a fatal error.  If there is some system
2885 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2886 omitted, uses C<$_>.
2887
2888 =item readpipe EXPR
2889
2890 EXPR is executed as a system command.
2891 The collected standard output of the command is returned.
2892 In scalar context, it comes back as a single (potentially
2893 multi-line) string.  In list context, returns a list of lines
2894 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2895 This is the internal function implementing the C<qx/EXPR/>
2896 operator, but you can use it directly.  The C<qx/EXPR/>
2897 operator is discussed in more detail in L<perlop/"I/O Operators">.
2898
2899 =item recv SOCKET,SCALAR,LEN,FLAGS
2900
2901 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2902 data into variable SCALAR from the specified SOCKET filehandle.
2903 Actually does a C C<recvfrom()>, so that it can return the address of the
2904 sender.  Returns the undefined value if there's an error.  SCALAR will
2905 be grown or shrunk to the length actually read.  Takes the same flags
2906 as the system call of the same name.
2907 See L<perlipc/"UDP: Message Passing"> for examples.
2908
2909 =item redo LABEL
2910
2911 =item redo
2912
2913 The C<redo> command restarts the loop block without evaluating the
2914 conditional again.  The L</continue> block, if any, is not executed.  If
2915 the LABEL is omitted, the command refers to the innermost enclosing
2916 loop.  This command is normally used by programs that want to lie to
2917 themselves about what was just input:
2918
2919     # a simpleminded Pascal comment stripper
2920     # (warning: assumes no { or } in strings)
2921     LINE: while (<STDIN>) {
2922         while (s|({.*}.*){.*}|$1 |) {}
2923         s|{.*}| |;
2924         if (s|{.*| |) {
2925             $front = $_;
2926             while (<STDIN>) {
2927                 if (/}/) {      # end of comment?
2928                     s|^|$front\{|;
2929                     redo LINE;
2930                 }
2931             }
2932         }
2933         print;
2934     }
2935
2936 C<redo> cannot be used to retry a block which returns a value such as
2937 C<eval {}>, C<sub {}> or C<do {}>.
2938
2939 See also L</continue> for an illustration of how L</last>, L</next>, and
2940 C<redo> work.
2941
2942 See also L<perlsyn>.
2943
2944 =item ref EXPR
2945
2946 =item ref
2947
2948 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2949 is not specified, C<$_> will be used.  The value returned depends on the
2950 type of thing the reference is a reference to.
2951 Builtin types include:
2952
2953     REF
2954     SCALAR
2955     ARRAY
2956     HASH
2957     CODE
2958     GLOB
2959
2960 If the referenced object has been blessed into a package, then that package
2961 name is returned instead.  You can think of C<ref()> as a C<typeof()> operator.
2962
2963     if (ref($r) eq "HASH") {
2964         print "r is a reference to a hash.\n";
2965     }
2966     if (!ref($r)) {
2967         print "r is not a reference at all.\n";
2968     }
2969
2970 See also L<perlref>.
2971
2972 =item rename OLDNAME,NEWNAME
2973
2974 Changes the name of a file.  Returns C<1> for success, C<0> otherwise.  Will
2975 not work across file system boundaries.
2976
2977 =item require EXPR
2978
2979 =item require
2980
2981 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
2982 supplied.  If EXPR is numeric, demands that the current version of Perl
2983 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2984
2985 Otherwise, demands that a library file be included if it hasn't already
2986 been included.  The file is included via the do-FILE mechanism, which is
2987 essentially just a variety of C<eval()>.  Has semantics similar to the following
2988 subroutine:
2989
2990     sub require {
2991         my($filename) = @_;
2992         return 1 if $INC{$filename};
2993         my($realfilename,$result);
2994         ITER: {
2995             foreach $prefix (@INC) {
2996                 $realfilename = "$prefix/$filename";
2997                 if (-f $realfilename) {
2998                     $result = do $realfilename;
2999                     last ITER;
3000                 }
3001             }
3002             die "Can't find $filename in \@INC";
3003         }
3004         die $@ if $@;
3005         die "$filename did not return true value" unless $result;
3006         $INC{$filename} = $realfilename;
3007         return $result;
3008     }
3009
3010 Note that the file will not be included twice under the same specified
3011 name.  The file must return TRUE as the last statement to indicate
3012 successful execution of any initialization code, so it's customary to
3013 end such a file with "C<1;>" unless you're sure it'll return TRUE
3014 otherwise.  But it's better just to put the "C<1;>", in case you add more
3015 statements.
3016
3017 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3018 replaces "F<::>" with "F</>" in the filename for you,
3019 to make it easy to load standard modules.  This form of loading of
3020 modules does not risk altering your namespace.
3021
3022 In other words, if you try this:
3023
3024         require Foo::Bar;    # a splendid bareword 
3025
3026 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3027 directories specified in the C<@INC> array.
3028
3029 But if you try this:
3030
3031         $class = 'Foo::Bar';
3032         require $class;      # $class is not a bareword
3033     #or
3034         require "Foo::Bar";  # not a bareword because of the ""
3035
3036 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3037 will complain about not finding "F<Foo::Bar>" there. In this case you can do:
3038
3039         eval "require $class";
3040
3041 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3042
3043 =item reset EXPR
3044
3045 =item reset
3046
3047 Generally used in a C<continue> block at the end of a loop to clear
3048 variables and reset C<??> searches so that they work again.  The
3049 expression is interpreted as a list of single characters (hyphens
3050 allowed for ranges).  All variables and arrays beginning with one of
3051 those letters are reset to their pristine state.  If the expression is
3052 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3053 only variables or searches in the current package.  Always returns
3054 1.  Examples:
3055
3056     reset 'X';          # reset all X variables
3057     reset 'a-z';        # reset lower case variables
3058     reset;              # just reset ?? searches
3059
3060 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3061 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package variables--lexical variables
3062 are unaffected, but they clean themselves up on scope exit anyway,
3063 so you'll probably want to use them instead.  See L</my>.
3064
3065 =item return EXPR
3066
3067 =item return
3068
3069 Returns from a subroutine, C<eval()>, or C<do FILE> with the value 
3070 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3071 context, depending on how the return value will be used, and the context
3072 may vary from one execution to the next (see C<wantarray()>).  If no EXPR
3073 is given, returns an empty list in list context, an undefined value in
3074 scalar context, or nothing in a void context.
3075
3076 (Note that in the absence of a return, a subroutine, eval, or do FILE
3077 will automatically return the value of the last expression evaluated.)
3078
3079 =item reverse LIST
3080
3081 In list context, returns a list value consisting of the elements
3082 of LIST in the opposite order.  In scalar context, concatenates the
3083 elements of LIST, and returns a string value with all the characters
3084 in the opposite order.
3085
3086     print reverse <>;           # line tac, last line first
3087
3088     undef $/;                   # for efficiency of <>
3089     print scalar reverse <>;    # character tac, last line tsrif
3090
3091 This operator is also handy for inverting a hash, although there are some
3092 caveats.  If a value is duplicated in the original hash, only one of those
3093 can be represented as a key in the inverted hash.  Also, this has to
3094 unwind one hash and build a whole new one, which may take some time
3095 on a large hash.
3096
3097     %by_name = reverse %by_address;     # Invert the hash
3098
3099 =item rewinddir DIRHANDLE
3100
3101 Sets the current position to the beginning of the directory for the
3102 C<readdir()> routine on DIRHANDLE.
3103
3104 =item rindex STR,SUBSTR,POSITION
3105
3106 =item rindex STR,SUBSTR
3107
3108 Works just like index except that it returns the position of the LAST
3109 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3110 last occurrence at or before that position.
3111
3112 =item rmdir FILENAME
3113
3114 =item rmdir
3115
3116 Deletes the directory specified by FILENAME if that directory is empty.  If it
3117 succeeds it returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).  If
3118 FILENAME is omitted, uses C<$_>.
3119
3120 =item s///
3121
3122 The substitution operator.  See L<perlop>.
3123
3124 =item scalar EXPR
3125
3126 Forces EXPR to be interpreted in scalar context and returns the value
3127 of EXPR.
3128
3129     @counts = ( scalar @a, scalar @b, scalar @c );
3130
3131 There is no equivalent operator to force an expression to
3132 be interpolated in list context because it's in practice never
3133 needed.  If you really wanted to do so, however, you could use
3134 the construction C<@{[ (some expression) ]}>, but usually a simple
3135 C<(some expression)> suffices.
3136
3137 =item seek FILEHANDLE,POSITION,WHENCE
3138
3139 Sets FILEHANDLE's position, just like the C<fseek()> call of C<stdio()>.
3140 FILEHANDLE may be an expression whose value gives the name of the
3141 filehandle.  The values for WHENCE are C<0> to set the new position to
3142 POSITION, C<1> to set it to the current position plus POSITION, and C<2> to
3143 set it to EOF plus POSITION (typically negative).  For WHENCE you may
3144 use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> from either the
3145 C<IO::Seekable> or the POSIX module.  Returns C<1> upon success, C<0> otherwise.
3146
3147 If you want to position file for C<sysread()> or C<syswrite()>, don't use
3148 C<seek()> -- buffering makes its effect on the file's system position
3149 unpredictable and non-portable.  Use C<sysseek()> instead.
3150
3151 On some systems you have to do a seek whenever you switch between reading
3152 and writing.  Amongst other things, this may have the effect of calling
3153 stdio's clearerr(3).  A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving
3154 the file position:
3155
3156     seek(TEST,0,1);
3157
3158 This is also useful for applications emulating C<tail -f>.  Once you hit
3159 EOF on your read, and then sleep for a while, you might have to stick in a
3160 seek() to reset things.  The C<seek()> doesn't change the current position,
3161 but it I<does> clear the end-of-file condition on the handle, so that the
3162 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
3163
3164 If that doesn't work (some stdios are particularly cantankerous), then
3165 you may need something more like this:
3166
3167     for (;;) {
3168         for ($curpos = tell(FILE); $_ = <FILE>;
3169              $curpos = tell(FILE)) {
3170             # search for some stuff and put it into files
3171         }
3172         sleep($for_a_while);
3173         seek(FILE, $curpos, 0);
3174     }
3175
3176 =item seekdir DIRHANDLE,POS
3177
3178 Sets the current position for the C<readdir()> routine on DIRHANDLE.  POS
3179 must be a value returned by C<telldir()>.  Has the same caveats about
3180 possible directory compaction as the corresponding system library
3181 routine.
3182
3183 =item select FILEHANDLE
3184
3185 =item select
3186
3187 Returns the currently selected filehandle.  Sets the current default
3188 filehandle for output, if FILEHANDLE is supplied.  This has two
3189 effects: first, a C<write()> or a C<print()> without a filehandle will
3190 default to this FILEHANDLE.  Second, references to variables related to
3191 output will refer to this output channel.  For example, if you have to
3192 set the top of form format for more than one output channel, you might
3193 do the following:
3194
3195     select(REPORT1);
3196     $^ = 'report1_top';
3197     select(REPORT2);
3198     $^ = 'report2_top';
3199
3200 FILEHANDLE may be an expression whose value gives the name of the
3201 actual filehandle.  Thus:
3202
3203     $oldfh = select(STDERR); $| = 1; select($oldfh);
3204
3205 Some programmers may prefer to think of filehandles as objects with
3206 methods, preferring to write the last example as:
3207
3208     use IO::Handle;
3209     STDERR->autoflush(1);
3210
3211 =item select RBITS,WBITS,EBITS,TIMEOUT
3212
3213 This calls the select(2) system call with the bit masks specified, which
3214 can be constructed using C<fileno()> and C<vec()>, along these lines:
3215
3216     $rin = $win = $ein = '';
3217     vec($rin,fileno(STDIN),1) = 1;
3218     vec($win,fileno(STDOUT),1) = 1;
3219     $ein = $rin | $win;
3220
3221 If you want to select on many filehandles you might wish to write a
3222 subroutine:
3223
3224     sub fhbits {
3225         my(@fhlist) = split(' ',$_[0]);
3226         my($bits);
3227         for (@fhlist) {
3228             vec($bits,fileno($_),1) = 1;
3229         }
3230         $bits;
3231     }
3232     $rin = fhbits('STDIN TTY SOCK');
3233
3234 The usual idiom is:
3235
3236     ($nfound,$timeleft) =
3237       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3238
3239 or to block until something becomes ready just do this
3240
3241     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3242
3243 Most systems do not bother to return anything useful in C<$timeleft>, so
3244 calling select() in scalar context just returns C<$nfound>.
3245
3246 Any of the bit masks can also be undef.  The timeout, if specified, is
3247 in seconds, which may be fractional.  Note: not all implementations are
3248 capable of returning theC<$timeleft>.  If not, they always return
3249 C<$timeleft> equal to the supplied C<$timeout>.
3250
3251 You can effect a sleep of 250 milliseconds this way:
3252
3253     select(undef, undef, undef, 0.25);
3254
3255 B<WARNING>: One should not attempt to mix buffered I/O (like C<read()>
3256 or E<lt>FHE<gt>) with C<select()>, except as permitted by POSIX, and even
3257 then only on POSIX systems.  You have to use C<sysread()> instead.
3258
3259 =item semctl ID,SEMNUM,CMD,ARG
3260
3261 Calls the System V IPC function C<semctl()>.  You'll probably have to say
3262
3263     use IPC::SysV;
3264
3265 first to get the correct constant definitions.  If CMD is IPC_STAT or
3266 GETALL, then ARG must be a variable which will hold the returned
3267 semid_ds structure or semaphore value array.  Returns like C<ioctl()>: the
3268 undefined value for error, "C<0> but true" for zero, or the actual return
3269 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3270
3271 =item semget KEY,NSEMS,FLAGS
3272
3273 Calls the System V IPC function semget.  Returns the semaphore id, or
3274 the undefined value if there is an error.  See also C<IPC::SysV> and
3275 C<IPC::SysV::Semaphore> documentation.
3276
3277 =item semop KEY,OPSTRING
3278
3279 Calls the System V IPC function semop to perform semaphore operations
3280 such as signaling and waiting.  OPSTRING must be a packed array of
3281 semop structures.  Each semop structure can be generated with
3282 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3283 operations is implied by the length of OPSTRING.  Returns TRUE if
3284 successful, or FALSE if there is an error.  As an example, the
3285 following code waits on semaphore C<$semnum> of semaphore id C<$semid>:
3286
3287     $semop = pack("sss", $semnum, -1, 0);
3288     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3289
3290 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3291 and C<IPC::SysV::Semaphore> documentation.
3292
3293 =item send SOCKET,MSG,FLAGS,TO
3294
3295 =item send SOCKET,MSG,FLAGS
3296
3297 Sends a message on a socket.  Takes the same flags as the system call
3298 of the same name.  On unconnected sockets you must specify a
3299 destination to send TO, in which case it does a C C<sendto()>.  Returns
3300 the number of characters sent, or the undefined value if there is an
3301 error.
3302 See L<perlipc/"UDP: Message Passing"> for examples.
3303
3304 =item setpgrp PID,PGRP
3305
3306 Sets the current process group for the specified PID, C<0> for the current
3307 process.  Will produce a fatal error if used on a machine that doesn't
3308 implement setpgrp(2).  If the arguments are omitted, it defaults to
3309 C<0,0>.  Note that the POSIX version of C<setpgrp()> does not accept any
3310 arguments, so only setpgrp C<0,0> is portable.
3311
3312 =item setpriority WHICH,WHO,PRIORITY
3313
3314 Sets the current priority for a process, a process group, or a user.
3315 (See setpriority(2).)  Will produce a fatal error if used on a machine
3316 that doesn't implement setpriority(2).
3317
3318 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3319
3320 Sets the socket option requested.  Returns undefined if there is an
3321 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3322 argument.
3323
3324 =item shift ARRAY
3325
3326 =item shift
3327
3328 Shifts the first value of the array off and returns it, shortening the
3329 array by 1 and moving everything down.  If there are no elements in the
3330 array, returns the undefined value.  If ARRAY is omitted, shifts the
3331 C<@_> array within the lexical scope of subroutines and formats, and the
3332 C<@ARGV> array at file scopes or within the lexical scopes established by
3333 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
3334 See also C<unshift()>, C<push()>, and C<pop()>.  C<Shift()> and C<unshift()> do the
3335 same thing to the left end of an array that C<pop()> and C<push()> do to the
3336 right end.
3337
3338 =item shmctl ID,CMD,ARG
3339
3340 Calls the System V IPC function shmctl.  You'll probably have to say
3341
3342     use IPC::SysV;
3343
3344 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3345 then ARG must be a variable which will hold the returned C<shmid_ds>
3346 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3347 true" for zero, or the actual return value otherwise.
3348 See also C<IPC::SysV> documentation.
3349
3350 =item shmget KEY,SIZE,FLAGS
3351
3352 Calls the System V IPC function shmget.  Returns the shared memory
3353 segment id, or the undefined value if there is an error.
3354 See also C<IPC::SysV> documentation.
3355
3356 =item shmread ID,VAR,POS,SIZE
3357
3358 =item shmwrite ID,STRING,POS,SIZE
3359
3360 Reads or writes the System V shared memory segment ID starting at
3361 position POS for size SIZE by attaching to it, copying in/out, and
3362 detaching from it.  When reading, VAR must be a variable that will
3363 hold the data read.  When writing, if STRING is too long, only SIZE
3364 bytes are used; if STRING is too short, nulls are written to fill out
3365 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
3366 See also C<IPC::SysV> documentation.
3367
3368 =item shutdown SOCKET,HOW
3369
3370 Shuts down a socket connection in the manner indicated by HOW, which
3371 has the same interpretation as in the system call of the same name.
3372
3373     shutdown(SOCKET, 0);    # I/we have stopped reading data
3374     shutdown(SOCKET, 1);    # I/we have stopped writing data
3375     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3376
3377 This is useful with sockets when you want to tell the other
3378 side you're done writing but not done reading, or vice versa.
3379 It's also a more insistent form of close because it also 
3380 disables the filedescriptor in any forked copies in other
3381 processes.
3382
3383 =item sin EXPR
3384
3385 =item sin
3386
3387 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3388 returns sine of C<$_>.
3389
3390 For the inverse sine operation, you may use the C<POSIX::asin()>
3391 function, or use this relation:
3392
3393     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3394
3395 =item sleep EXPR
3396
3397 =item sleep
3398
3399 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3400 May be interrupted if the process receives a signal such as C<SIGALRM>.
3401 Returns the number of seconds actually slept.  You probably cannot
3402 mix C<alarm()> and C<sleep()> calls, because C<sleep()> is often implemented
3403 using C<alarm()>.
3404
3405 On some older systems, it may sleep up to a full second less than what
3406 you requested, depending on how it counts seconds.  Most modern systems
3407 always sleep the full amount.  They may appear to sleep longer than that,
3408 however, because your process might not be scheduled right away in a
3409 busy multitasking system.
3410
3411 For delays of finer granularity than one second, you may use Perl's
3412 C<syscall()> interface to access setitimer(2) if your system supports it,
3413 or else see L</select> above.
3414
3415 See also the POSIX module's C<sigpause()> function.
3416
3417 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3418
3419 Opens a socket of the specified kind and attaches it to filehandle
3420 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
3421 system call of the same name.  You should "C<use Socket;>" first to get
3422 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
3423
3424 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3425
3426 Creates an unnamed pair of sockets in the specified domain, of the
3427 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3428 for the system call of the same name.  If unimplemented, yields a fatal
3429 error.  Returns TRUE if successful.
3430
3431 Some systems defined C<pipe()> in terms of C<socketpair()>, in which a call
3432 to C<pipe(Rdr, Wtr)> is essentially:
3433
3434     use Socket;
3435     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3436     shutdown(Rdr, 1);        # no more writing for reader
3437     shutdown(Wtr, 0);        # no more reading for writer
3438
3439 See L<perlipc> for an example of socketpair use.
3440
3441 =item sort SUBNAME LIST
3442
3443 =item sort BLOCK LIST
3444
3445 =item sort LIST
3446
3447 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
3448 is omitted, C<sort()>s in standard string comparison order.  If SUBNAME is
3449 specified, it gives the name of a subroutine that returns an integer
3450 less than, equal to, or greater than C<0>, depending on how the elements
3451 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
3452 operators are extremely useful in such routines.)  SUBNAME may be a
3453 scalar variable name (unsubscripted), in which case the value provides
3454 the name of (or a reference to) the actual subroutine to use.  In place
3455 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
3456 subroutine.
3457
3458 In the interests of efficiency the normal calling code for subroutines is
3459 bypassed, with the following effects: the subroutine may not be a
3460 recursive subroutine, and the two elements to be compared are passed into
3461 the subroutine not via C<@_> but as the package global variables C<$a> and
3462 C<$b> (see example below).  They are passed by reference, so don't
3463 modify C<$a> and C<$b>.  And don't try to declare them as lexicals either.
3464
3465 You also cannot exit out of the sort block or subroutine using any of the
3466 loop control operators described in L<perlsyn> or with C<goto()>.
3467
3468 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3469 current collation locale.  See L<perllocale>.
3470
3471 Examples:
3472
3473     # sort lexically
3474     @articles = sort @files;
3475
3476     # same thing, but with explicit sort routine
3477     @articles = sort {$a cmp $b} @files;
3478
3479     # now case-insensitively
3480     @articles = sort {uc($a) cmp uc($b)} @files;
3481
3482     # same thing in reversed order
3483     @articles = sort {$b cmp $a} @files;
3484
3485     # sort numerically ascending
3486     @articles = sort {$a <=> $b} @files;
3487
3488     # sort numerically descending
3489     @articles = sort {$b <=> $a} @files;
3490
3491     # sort using explicit subroutine name
3492     sub byage {
3493         $age{$a} <=> $age{$b};  # presuming numeric
3494     }
3495     @sortedclass = sort byage @class;
3496
3497     # this sorts the %age hash by value instead of key
3498     # using an in-line function
3499     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3500
3501     sub backwards { $b cmp $a; }
3502     @harry = ('dog','cat','x','Cain','Abel');
3503     @george = ('gone','chased','yz','Punished','Axed');
3504     print sort @harry;
3505             # prints AbelCaincatdogx
3506     print sort backwards @harry;
3507             # prints xdogcatCainAbel
3508     print sort @george, 'to', @harry;
3509             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3510
3511     # inefficiently sort by descending numeric compare using
3512     # the first integer after the first = sign, or the
3513     # whole record case-insensitively otherwise
3514
3515     @new = sort {
3516         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3517                             ||
3518                     uc($a)  cmp  uc($b)
3519     } @old;
3520
3521     # same thing, but much more efficiently;
3522     # we'll build auxiliary indices instead
3523     # for speed
3524     @nums = @caps = ();
3525     for (@old) {
3526         push @nums, /=(\d+)/;
3527         push @caps, uc($_);
3528     }
3529
3530     @new = @old[ sort {
3531                         $nums[$b] <=> $nums[$a]
3532                                  ||
3533                         $caps[$a] cmp $caps[$b]
3534                        } 0..$#old
3535                ];
3536
3537     # same thing using a Schwartzian Transform (no temps)
3538     @new = map { $_->[0] }
3539         sort { $b->[1] <=> $a->[1]
3540                         ||
3541                $a->[2] cmp $b->[2]
3542         } map { [$_, /=(\d+)/, uc($_)] } @old;
3543
3544 If you're using strict, you I<MUST NOT> declare C<$a>
3545 and C<$b> as lexicals.  They are package globals.  That means
3546 if you're in the C<main> package, it's
3547
3548     @articles = sort {$main::b <=> $main::a} @files;
3549
3550 or just
3551
3552     @articles = sort {$::b <=> $::a} @files;
3553
3554 but if you're in the C<FooPack> package, it's
3555
3556     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3557
3558 The comparison function is required to behave.  If it returns
3559 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
3560 sometimes saying the opposite, for example) the results are not
3561 well-defined.
3562
3563 =item splice ARRAY,OFFSET,LENGTH,LIST
3564
3565 =item splice ARRAY,OFFSET,LENGTH
3566
3567 =item splice ARRAY,OFFSET
3568
3569 Removes the elements designated by OFFSET and LENGTH from an array, and
3570 replaces them with the elements of LIST, if any.  In list context,
3571 returns the elements removed from the array.  In scalar context,
3572 returns the last element removed, or C<undef> if no elements are
3573 removed.  The array grows or shrinks as necessary.
3574 If OFFSET is negative then it start that far from the end of the array.
3575 If LENGTH is omitted, removes everything from OFFSET onward.
3576 If LENGTH is negative, leave that many elements off the end of the array.
3577 The following equivalences hold (assuming C<$[ == 0>):
3578
3579     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
3580     pop(@a)             splice(@a,-1)
3581     shift(@a)           splice(@a,0,1)
3582     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3583     $a[$x] = $y         splice(@a,$x,1,$y)
3584
3585 Example, assuming array lengths are passed before arrays:
3586
3587     sub aeq {   # compare two list values
3588         my(@a) = splice(@_,0,shift);
3589         my(@b) = splice(@_,0,shift);
3590         return 0 unless @a == @b;       # same len?
3591         while (@a) {
3592             return 0 if pop(@a) ne pop(@b);
3593         }
3594         return 1;
3595     }
3596     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3597
3598 =item split /PATTERN/,EXPR,LIMIT
3599
3600 =item split /PATTERN/,EXPR
3601
3602 =item split /PATTERN/
3603
3604 =item split
3605
3606 Splits a string into an array of strings, and returns it.  By default,
3607 empty leading fields are preserved, and empty trailing ones are deleted.
3608
3609 If not in list context, returns the number of fields found and splits into
3610 the C<@_> array.  (In list context, you can force the split into C<@_> by
3611 using C<??> as the pattern delimiters, but it still returns the list
3612 value.)  The use of implicit split to C<@_> is deprecated, however, because
3613 it clobbers your subroutine arguments.
3614
3615 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
3616 splits on whitespace (after skipping any leading whitespace).  Anything
3617 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3618 that the delimiter may be longer than one character.)
3619
3620 If LIMIT is specified and positive, splits into no more than that
3621 many fields (though it may split into fewer).  If LIMIT is unspecified
3622 or zero, trailing null fields are stripped (which potential users
3623 of C<pop()> would do well to remember).  If LIMIT is negative, it is
3624 treated as if an arbitrarily large LIMIT had been specified.
3625
3626 A pattern matching the null string (not to be confused with
3627 a null pattern C<//>, which is just one member of the set of patterns
3628 matching a null string) will split the value of EXPR into separate
3629 characters at each point it matches that way.  For example:
3630
3631     print join(':', split(/ */, 'hi there'));
3632
3633 produces the output 'h:i:t:h:e:r:e'.
3634
3635 The LIMIT parameter can be used to split a line partially
3636
3637     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3638
3639 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3640 one larger than the number of variables in the list, to avoid
3641 unnecessary work.  For the list above LIMIT would have been 4 by
3642 default.  In time critical applications it behooves you not to split
3643 into more fields than you really need.
3644
3645 If the PATTERN contains parentheses, additional array elements are
3646 created from each matching substring in the delimiter.
3647
3648     split(/([,-])/, "1-10,20", 3);
3649
3650 produces the list value
3651
3652     (1, '-', 10, ',', 20)
3653
3654 If you had the entire header of a normal Unix email message in C<$header>,
3655 you could split it up into fields and their values this way:
3656
3657     $header =~ s/\n\s+/ /g;  # fix continuation lines
3658     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
3659
3660 The pattern C</PATTERN/> may be replaced with an expression to specify
3661 patterns that vary at runtime.  (To do runtime compilation only once,
3662 use C</$variable/o>.)
3663
3664 As a special case, specifying a PATTERN of space (C<' '>) will split on
3665 white space just as C<split()> with no arguments does.  Thus, C<split(' ')> can
3666 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3667 will give you as many null initial fields as there are leading spaces.
3668 A C<split()> on C</\s+/> is like a C<split(' ')> except that any leading
3669 whitespace produces a null first field.  A C<split()> with no arguments
3670 really does a C<split(' ', $_)> internally.
3671
3672 Example:
3673
3674     open(PASSWD, '/etc/passwd');
3675     while (<PASSWD>) {
3676         ($login, $passwd, $uid, $gid,
3677          $gcos, $home, $shell) = split(/:/);
3678         #...
3679     }
3680
3681 (Note that C<$shell> above will still have a newline on it.  See L</chop>,
3682 L</chomp>, and L</join>.)
3683
3684 =item sprintf FORMAT, LIST
3685
3686 Returns a string formatted by the usual C<printf()> conventions of the
3687 C library function C<sprintf()>.  See L<sprintf(3)> or L<printf(3)>
3688 on your system for an explanation of the general principles.
3689
3690 Perl does its own C<sprintf()> formatting -- it emulates the C
3691 function C<sprintf()>, but it doesn't use it (except for floating-point
3692 numbers, and even then only the standard modifiers are allowed).  As a
3693 result, any non-standard extensions in your local C<sprintf()> are not
3694 available from Perl.
3695
3696 Perl's C<sprintf()> permits the following universally-known conversions:
3697
3698    %%   a percent sign
3699    %c   a character with the given number
3700    %s   a string
3701    %d   a signed integer, in decimal
3702    %u   an unsigned integer, in decimal
3703    %o   an unsigned integer, in octal
3704    %x   an unsigned integer, in hexadecimal
3705    %e   a floating-point number, in scientific notation
3706    %f   a floating-point number, in fixed decimal notation
3707    %g   a floating-point number, in %e or %f notation
3708
3709 In addition, Perl permits the following widely-supported conversions:
3710
3711    %X   like %x, but using upper-case letters
3712    %E   like %e, but using an upper-case "E"
3713    %G   like %g, but with an upper-case "E" (if applicable)
3714    %p   a pointer (outputs the Perl value's address in hexadecimal)
3715    %n   special: *stores* the number of characters output so far
3716         into the next variable in the parameter list 
3717
3718 Finally, for backward (and we do mean "backward") compatibility, Perl
3719 permits these unnecessary but widely-supported conversions:
3720
3721    %i   a synonym for %d
3722    %D   a synonym for %ld
3723    %U   a synonym for %lu
3724    %O   a synonym for %lo
3725    %F   a synonym for %f
3726
3727 Perl permits the following universally-known flags between the C<%>
3728 and the conversion letter:
3729
3730    space   prefix positive number with a space
3731    +       prefix positive number with a plus sign
3732    -       left-justify within the field
3733    0       use zeros, not spaces, to right-justify
3734    #       prefix non-zero octal with "0", non-zero hex with "0x"
3735    number  minimum field width
3736    .number "precision": digits after decimal point for
3737            floating-point, max length for string, minimum length
3738            for integer
3739    l       interpret integer as C type "long" or "unsigned long"
3740    h       interpret integer as C type "short" or "unsigned short"
3741
3742 There is also one Perl-specific flag:
3743
3744    V       interpret integer as Perl's standard integer type
3745
3746 Where a number would appear in the flags, an asterisk ("C<*>") may be
3747 used instead, in which case Perl uses the next item in the parameter
3748 list as the given number (that is, as the field width or precision).
3749 If a field width obtained through "C<*>" is negative, it has the same
3750 effect as the "C<->" flag: left-justification.
3751
3752 If C<use locale> is in effect, the character used for the decimal
3753 point in formatted real numbers is affected by the LC_NUMERIC locale.
3754 See L<perllocale>.
3755
3756 =item sqrt EXPR
3757
3758 =item sqrt
3759
3760 Return the square root of EXPR.  If EXPR is omitted, returns square
3761 root of C<$_>.
3762
3763 =item srand EXPR
3764
3765 =item srand
3766
3767 Sets the random number seed for the C<rand()> operator.  If EXPR is
3768 omitted, uses a semi-random value supplied by the kernel (if it supports
3769 the F</dev/urandom> device) or based on the current time and process
3770 ID, among other things.  In versions of Perl prior to 5.004 the default
3771 seed was just the current C<time()>.  This isn't a particularly good seed,
3772 so many old programs supply their own seed value (often C<time ^ $$> or
3773 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
3774
3775 In fact, it's usually not necessary to call C<srand()> at all, because if
3776 it is not called explicitly, it is called implicitly at the first use of
3777 the C<rand()> operator.  However, this was not the case in version of Perl
3778 before 5.004, so if your script will run under older Perl versions, it
3779 should call C<srand()>.
3780
3781 Note that you need something much more random than the default seed for
3782 cryptographic purposes.  Checksumming the compressed output of one or more
3783 rapidly changing operating system status programs is the usual method.  For
3784 example:
3785
3786     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3787
3788 If you're particularly concerned with this, see the C<Math::TrulyRandom>
3789 module in CPAN.
3790
3791 Do I<not> call C<srand()> multiple times in your program unless you know
3792 exactly what you're doing and why you're doing it.  The point of the
3793 function is to "seed" the C<rand()> function so that C<rand()> can produce
3794 a different sequence each time you run your program.  Just do it once at the
3795 top of your program, or you I<won't> get random numbers out of C<rand()>!
3796
3797 Frequently called programs (like CGI scripts) that simply use
3798
3799     time ^ $$
3800
3801 for a seed can fall prey to the mathematical property that
3802
3803     a^b == (a+1)^(b+1)
3804
3805 one-third of the time.  So don't do that.
3806
3807 =item stat FILEHANDLE
3808
3809 =item stat EXPR
3810
3811 =item stat
3812
3813 Returns a 13-element list giving the status info for a file, either
3814 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
3815 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
3816 as follows:
3817
3818     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3819        $atime,$mtime,$ctime,$blksize,$blocks)
3820            = stat($filename);
3821
3822 Not all fields are supported on all filesystem types.  Here are the
3823 meaning of the fields:
3824
3825   0 dev      device number of filesystem
3826   1 ino      inode number
3827   2 mode     file mode  (type and permissions)
3828   3 nlink    number of (hard) links to the file
3829   4 uid      numeric user ID of file's owner
3830   5 gid      numeric group ID of file's owner
3831   6 rdev     the device identifier (special files only)
3832   7 size     total size of file, in bytes
3833   8 atime    last access time since the epoch
3834   9 mtime    last modify time since the epoch
3835  10 ctime    inode change time (NOT creation time!) since the epoch
3836  11 blksize  preferred block size for file system I/O
3837  12 blocks   actual number of blocks allocated
3838
3839 (The epoch was at 00:00 January 1, 1970 GMT.)
3840
3841 If stat is passed the special filehandle consisting of an underline, no
3842 stat is done, but the current contents of the stat structure from the
3843 last stat or filetest are returned.  Example:
3844
3845     if (-x $file && (($d) = stat(_)) && $d < 0) {
3846         print "$file is executable NFS file\n";
3847     }
3848
3849 (This works on machines only for which the device number is negative under NFS.)
3850
3851 In scalar context, C<stat()> returns a boolean value indicating success
3852 or failure, and, if successful, sets the information associated with
3853 the special filehandle C<_>.
3854
3855 =item study SCALAR
3856
3857 =item study
3858
3859 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3860 doing many pattern matches on the string before it is next modified.
3861 This may or may not save time, depending on the nature and number of
3862 patterns you are searching on, and on the distribution of character
3863 frequencies in the string to be searched -- you probably want to compare
3864 run times with and without it to see which runs faster.  Those loops
3865 which scan for many short constant strings (including the constant
3866 parts of more complex patterns) will benefit most.  You may have only
3867 one C<study()> active at a time -- if you study a different scalar the first
3868 is "unstudied".  (The way C<study()> works is this: a linked list of every
3869 character in the string to be searched is made, so we know, for
3870 example, where all the C<'k'> characters are.  From each search string,
3871 the rarest character is selected, based on some static frequency tables
3872 constructed from some C programs and English text.  Only those places
3873 that contain this "rarest" character are examined.)
3874
3875 For example, here is a loop that inserts index producing entries
3876 before any line containing a certain pattern:
3877
3878     while (<>) {
3879         study;
3880         print ".IX foo\n" if /\bfoo\b/;
3881         print ".IX bar\n" if /\bbar\b/;
3882         print ".IX blurfl\n" if /\bblurfl\b/;
3883         # ...
3884         print;
3885     }
3886
3887 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<"f">
3888 will be looked at, because C<"f"> is rarer than C<"o">.  In general, this is
3889 a big win except in pathological cases.  The only question is whether
3890 it saves you more time than it took to build the linked list in the
3891 first place.
3892
3893 Note that if you have to look for strings that you don't know till
3894 runtime, you can build an entire loop as a string and C<eval()> that to
3895 avoid recompiling all your patterns all the time.  Together with
3896 undefining C<$/> to input entire files as one record, this can be very
3897 fast, often faster than specialized programs like fgrep(1).  The following
3898 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3899 out the names of those files that contain a match:
3900
3901     $search = 'while (<>) { study;';
3902     foreach $word (@words) {
3903         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3904     }
3905     $search .= "}";
3906     @ARGV = @files;
3907     undef $/;
3908     eval $search;               # this screams
3909     $/ = "\n";          # put back to normal input delimiter
3910     foreach $file (sort keys(%seen)) {
3911         print $file, "\n";
3912     }
3913
3914 =item sub BLOCK
3915
3916 =item sub NAME
3917
3918 =item sub NAME BLOCK
3919
3920 This is subroutine definition, not a real function I<per se>.  With just a
3921 NAME (and possibly prototypes), it's just a forward declaration.  Without
3922 a NAME, it's an anonymous function declaration, and does actually return a
3923 value: the CODE ref of the closure you just created.  See L<perlsub> and
3924 L<perlref> for details.
3925
3926 =item substr EXPR,OFFSET,LEN,REPLACEMENT
3927
3928 =item substr EXPR,OFFSET,LEN
3929
3930 =item substr EXPR,OFFSET
3931
3932 Extracts a substring out of EXPR and returns it.  First character is at
3933 offset C<0>, or whatever you've set C<$[> to (but don't do that).
3934 If OFFSET is negative (or more precisely, less than C<$[>), starts
3935 that far from the end of the string.  If LEN is omitted, returns
3936 everything to the end of the string.  If LEN is negative, leaves that
3937 many characters off the end of the string.
3938
3939 If you specify a substring that is partly outside the string, the part
3940 within the string is returned.    If the substring is totally outside
3941 the string a warning is produced.
3942
3943 You can use the C<substr()> function
3944 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3945 something shorter than LEN, the string will shrink, and if you assign
3946 something longer than LEN, the string will grow to accommodate it.  To
3947 keep the string the same length you may need to pad or chop your value
3948 using C<sprintf()>.
3949
3950 An alternative to using C<substr()> as an lvalue is to specify the
3951 replacement string as the 4th argument.  This allows you to replace
3952 parts of the EXPR and return what was there before in one operation.
3953
3954 =item symlink OLDFILE,NEWFILE
3955
3956 Creates a new filename symbolically linked to the old filename.
3957 Returns C<1> for success, C<0> otherwise.  On systems that don't support
3958 symbolic links, produces a fatal error at run time.  To check for that,
3959 use eval:
3960
3961     $symlink_exists =  eval { symlink("",""); 1 };
3962
3963 =item syscall LIST
3964
3965 Calls the system call specified as the first element of the list,
3966 passing the remaining elements as arguments to the system call.  If
3967 unimplemented, produces a fatal error.  The arguments are interpreted
3968 as follows: if a given argument is numeric, the argument is passed as
3969 an int.  If not, the pointer to the string value is passed.  You are
3970 responsible to make sure a string is pre-extended long enough to
3971 receive any result that might be written into a string.  You can't use a
3972 string literal (or other read-only string) as an argument to C<syscall()>
3973 because Perl has to assume that any string pointer might be written
3974 through.  If your
3975 integer arguments are not literals and have never been interpreted in a
3976 numeric context, you may need to add C<0> to them to force them to look
3977 like numbers.  This emulates the C<syswrite()> function (or vice versa):
3978
3979     require 'syscall.ph';               # may need to run h2ph
3980     $s = "hi there\n";
3981     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
3982
3983 Note that Perl supports passing of up to only 14 arguments to your system call,
3984 which in practice should usually suffice.
3985
3986 Syscall returns whatever value returned by the system call it calls.
3987 If the system call fails, C<syscall()> returns C<-1> and sets C<$!> (errno).
3988 Note that some system calls can legitimately return C<-1>.  The proper
3989 way to handle such calls is to assign C<$!=0;> before the call and
3990 check the value of C<$!> if syscall returns C<-1>.
3991
3992 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
3993 number of the read end of the pipe it creates.  There is no way
3994 to retrieve the file number of the other end.  You can avoid this 
3995 problem by using C<pipe()> instead.
3996
3997 =item sysopen FILEHANDLE,FILENAME,MODE
3998
3999 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
4000
4001 Opens the file whose filename is given by FILENAME, and associates it
4002 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
4003 the name of the real filehandle wanted.  This function calls the
4004 underlying operating system's C<open()> function with the parameters
4005 FILENAME, MODE, PERMS.
4006
4007 The possible values and flag bits of the MODE parameter are
4008 system-dependent; they are available via the standard module C<Fcntl>.
4009 For historical reasons, some values work on almost every system
4010 supported by perl: zero means read-only, one means write-only, and two
4011 means read/write.  We know that these values do I<not> work under
4012 OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to
4013 use them in new code.
4014
4015 If the file named by FILENAME does not exist and the C<open()> call creates
4016 it (typically because MODE includes the C<O_CREAT> flag), then the value of
4017 PERMS specifies the permissions of the newly created file.  If you omit
4018 the PERMS argument to C<sysopen()>, Perl uses the octal value C<0666>.
4019 These permission values need to be in octal, and are modified by your
4020 process's current C<umask>.
4021
4022 Seldom if ever use C<0644> as argument to C<sysopen()> because that
4023 takes away the user's option to have a more permissive umask.  Better
4024 to omit it.  See the perlfunc(1) entry on C<umask> for more on this.
4025
4026 The C<IO::File> module provides a more object-oriented approach, if you're
4027 into that kind of thing.
4028
4029 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
4030
4031 =item sysread FILEHANDLE,SCALAR,LENGTH
4032
4033 Attempts to read LENGTH bytes of data into variable SCALAR from the
4034 specified FILEHANDLE, using the system call read(2).  It bypasses stdio,
4035 so mixing this with other kinds of reads, C<print()>, C<write()>,
4036 C<seek()>, C<tell()>, or C<eof()> can cause confusion because stdio
4037 usually buffers data.  Returns the number of bytes actually read, C<0>
4038 at end of file, or undef if there was an error.  SCALAR will be grown or
4039 shrunk so that the last byte actually read is the last byte of the
4040 scalar after the read.
4041
4042 An OFFSET may be specified to place the read data at some place in the
4043 string other than the beginning.  A negative OFFSET specifies
4044 placement at that many bytes counting backwards from the end of the
4045 string.  A positive OFFSET greater than the length of SCALAR results
4046 in the string being padded to the required size with C<"\0"> bytes before
4047 the result of the read is appended.
4048
4049 =item sysseek FILEHANDLE,POSITION,WHENCE
4050
4051 Sets FILEHANDLE's system position using the system call lseek(2).  It
4052 bypasses stdio, so mixing this with reads (other than C<sysread()>),
4053 C<print()>, C<write()>, C<seek()>, C<tell()>, or C<eof()> may cause
4054 confusion.  FILEHANDLE may be an expression whose value gives the name
4055 of the filehandle.  The values for WHENCE are C<0> to set the new
4056 position to POSITION, C<1> to set the it to the current position plus
4057 POSITION, and C<2> to set it to EOF plus POSITION (typically negative).
4058 For WHENCE, you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and
4059 C<SEEK_END> from either the C<IO::Seekable> or the POSIX module.
4060
4061 Returns the new position, or the undefined value on failure.  A position
4062 of zero is returned as the string "C<0> but true"; thus C<sysseek()> returns
4063 TRUE on success and FALSE on failure, yet you can still easily determine
4064 the new position.
4065
4066 =item system LIST
4067
4068 =item system PROGRAM LIST
4069
4070 Does exactly the same thing as "C<exec LIST>" except that a fork is done
4071 first, and the parent process waits for the child process to complete.
4072 Note that argument processing varies depending on the number of
4073 arguments.  If there is more than one argument in LIST, or if LIST is
4074 an array with more than one value, starts the program given by the
4075 first element of the list with arguments given by the rest of the list.
4076 If there is only one scalar argument, the argument is
4077 checked for shell metacharacters, and if there are any, the entire
4078 argument is passed to the system's command shell for parsing (this is
4079 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
4080 there are no shell metacharacters in the argument, it is split into
4081 words and passed directly to C<execvp()>, which is more efficient.
4082
4083 The return value is the exit status of the program as
4084 returned by the C<wait()> call.  To get the actual exit value divide by
4085 256.  See also L</exec>.  This is I<NOT> what you want to use to capture
4086 the output from a command, for that you should use merely backticks or
4087 C<qx//>, as described in L<perlop/"`STRING`">.
4088
4089 Like C<exec()>, C<system()> allows you to lie to a program about its name if
4090 you use the "C<system PROGRAM LIST>" syntax.  Again, see L</exec>.
4091
4092 Because C<system()> and backticks block C<SIGINT> and C<SIGQUIT>, killing the
4093 program they're running doesn't actually interrupt your program.
4094
4095     @args = ("command", "arg1", "arg2");
4096     system(@args) == 0
4097          or die "system @args failed: $?"
4098
4099 You can check all the failure possibilities by inspecting
4100 C<$?> like this:
4101
4102     $exit_value  = $? >> 8;
4103     $signal_num  = $? & 127;
4104     $dumped_core = $? & 128;
4105
4106 When the arguments get executed via the system shell, results
4107 and return codes will be subject to its quirks and capabilities.
4108 See L<perlop/"`STRING`"> and L</exec> for details.
4109
4110 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
4111
4112 =item syswrite FILEHANDLE,SCALAR,LENGTH
4113
4114 =item syswrite FILEHANDLE,SCALAR
4115
4116 Attempts to write LENGTH bytes of data from variable SCALAR to the
4117 specified FILEHANDLE, using the system call write(2).  If LENGTH is
4118 not specified, writes whole SCALAR. It bypasses
4119 stdio, so mixing this with reads (other than C<sysread())>, C<print()>,
4120 C<write()>, C<seek()>, C<tell()>, or C<eof()> may cause confusion
4121 because stdio usually buffers data.  Returns the number of bytes
4122 actually written, or C<undef> if there was an error.  If the LENGTH is
4123 greater than the available data in the SCALAR after the OFFSET, only as
4124 much data as is available will be written.
4125
4126 An OFFSET may be specified to write the data from some part of the
4127 string other than the beginning.  A negative OFFSET specifies writing
4128 that many bytes counting backwards from the end of the string.  In the
4129 case the SCALAR is empty you can use OFFSET but only zero offset.
4130
4131 =item tell FILEHANDLE
4132
4133 =item tell
4134
4135 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
4136 expression whose value gives the name of the actual filehandle.  If
4137 FILEHANDLE is omitted, assumes the file last read.
4138
4139 =item telldir DIRHANDLE
4140
4141 Returns the current position of the C<readdir()> routines on DIRHANDLE.
4142 Value may be given to C<seekdir()> to access a particular location in a
4143 directory.  Has the same caveats about possible directory compaction as
4144 the corresponding system library routine.
4145
4146 =item tie VARIABLE,CLASSNAME,LIST
4147
4148 This function binds a variable to a package class that will provide the
4149 implementation for the variable.  VARIABLE is the name of the variable
4150 to be enchanted.  CLASSNAME is the name of a class implementing objects
4151 of correct type.  Any additional arguments are passed to the "C<new()>"
4152 method of the class (meaning C<TIESCALAR>, C<TIEHANDLE>, C<TIEARRAY>,
4153 or C<TIEHASH>).  Typically these are arguments such as might be passed
4154 to the C<dbm_open()> function of C.  The object returned by the "C<new()>"
4155 method is also returned by the C<tie()> function, which would be useful
4156 if you want to access other methods in CLASSNAME.
4157
4158 Note that functions such as C<keys()> and C<values()> may return huge lists
4159 when used on large objects, like DBM files.  You may prefer to use the
4160 C<each()> function to iterate over such.  Example:
4161
4162     # print out history file offsets
4163     use NDBM_File;
4164     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
4165     while (($key,$val) = each %HIST) {
4166         print $key, ' = ', unpack('L',$val), "\n";
4167     }
4168     untie(%HIST);
4169
4170 A class implementing a hash should have the following methods:
4171
4172     TIEHASH classname, LIST
4173     FETCH this, key
4174     STORE this, key, value
4175     DELETE this, key
4176     CLEAR this
4177     EXISTS this, key
4178     FIRSTKEY this
4179     NEXTKEY this, lastkey
4180     DESTROY this
4181
4182 A class implementing an ordinary array should have the following methods:
4183
4184     TIEARRAY classname, LIST
4185     FETCH this, key
4186     STORE this, key, value
4187     FETCHSIZE this
4188     STORESIZE this, count
4189     CLEAR this
4190     PUSH this, LIST
4191     POP this
4192     SHIFT this
4193     UNSHIFT this, LIST
4194     SPLICE this, offset, length, LIST
4195     EXTEND this, count
4196     DESTROY this
4197
4198 A class implementing a file handle should have the following methods:
4199
4200     TIEHANDLE classname, LIST
4201     READ this, scalar, length, offset
4202     READLINE this
4203     GETC this
4204     WRITE this, scalar, length, offset
4205     PRINT this, LIST
4206     PRINTF this, format, LIST
4207     CLOSE this
4208     DESTROY this
4209
4210 A class implementing a scalar should have the following methods:
4211
4212     TIESCALAR classname, LIST
4213     FETCH this,
4214     STORE this, value
4215     DESTROY this
4216
4217 Not all methods indicated above need be implemented.  See L<perltie>,
4218 L<Tie::Hash>, L<Tie::Array>, L<Tie::Scalar> and L<Tie::Handle>.
4219
4220 Unlike C<dbmopen()>, the C<tie()> function will not use or require a module
4221 for you--you need to do that explicitly yourself.  See L<DB_File>
4222 or the F<Config> module for interesting C<tie()> implementations.
4223
4224 For further details see L<perltie>, L<"tied VARIABLE">.
4225
4226 =item tied VARIABLE
4227
4228 Returns a reference to the object underlying VARIABLE (the same value
4229 that was originally returned by the C<tie()> call that bound the variable
4230 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
4231 package.
4232
4233 =item time
4234
4235 Returns the number of non-leap seconds since whatever time the system
4236 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
4237 and 00:00:00 UTC, January 1, 1970 for most other systems).
4238 Suitable for feeding to C<gmtime()> and C<localtime()>.
4239
4240 =item times
4241
4242 Returns a four-element list giving the user and system times, in
4243 seconds, for this process and the children of this process.
4244
4245     ($user,$system,$cuser,$csystem) = times;
4246
4247 =item tr///
4248
4249 The transliteration operator.  Same as C<y///>. See L<perlop>.
4250
4251 =item truncate FILEHANDLE,LENGTH
4252
4253 =item truncate EXPR,LENGTH
4254
4255 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
4256 specified length.  Produces a fatal error if truncate isn't implemented
4257 on your system.  Returns TRUE if successful, the undefined value
4258 otherwise.
4259
4260 =item uc EXPR
4261
4262 =item uc
4263
4264 Returns an uppercased version of EXPR.  This is the internal function
4265 implementing the C<\U> escape in double-quoted strings.
4266 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4267 Under Unicode (C<use utf8>) it uses the standard Unicode uppercase mappings.  (It
4268 does not attempt to do titlecase mapping on initial letters.  See C<ucfirst()> for that.)
4269
4270 If EXPR is omitted, uses C<$_>.
4271
4272 =item ucfirst EXPR
4273
4274 =item ucfirst
4275
4276 Returns the value of EXPR with the first character
4277 in uppercase (titlecase in Unicode).  This is
4278 the internal function implementing the C<\u> escape in double-quoted strings.
4279 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4280
4281 If EXPR is omitted, uses C<$_>.
4282
4283 =item umask EXPR
4284
4285 =item umask
4286
4287 Sets the umask for the process to EXPR and returns the previous value.
4288 If EXPR is omitted, merely returns the current umask.
4289
4290 The Unix permission C<rwxr-x---> is represented as three sets of three
4291 bits, or three octal digits: C<0750> (the leading 0 indicates octal
4292 and isn't one of the digits).  The C<umask> value is such a number
4293 representing disabled permissions bits.  The permission (or "mode")
4294 values you pass C<mkdir> or C<sysopen> are modified by your umask, so
4295 even if you tell C<sysopen> to create a file with permissions C<0777>,
4296 if your umask is C<0022> then the file will actually be created with
4297 permissions C<0755>.  If your C<umask> were C<0027> (group can't
4298 write; others can't read, write, or execute), then passing
4299 C<sysopen()> C<0666> would create a file with mode C<0640> (C<0666 &~
4300 027> is C<0640>).
4301
4302 Here's some advice: supply a creation mode of C<0666> for regular
4303 files (in C<sysopen()>) and one of C<0777> for directories (in
4304 C<mkdir()>) and executable files.  This gives users the freedom of
4305 choice: if they want protected files, they might choose process umasks
4306 of C<022>, C<027>, or even the particularly antisocial mask of C<077>.
4307 Programs should rarely if ever make policy decisions better left to
4308 the user.  The exception to this is when writing files that should be
4309 kept private: mail files, web browser cookies, I<.rhosts> files, and
4310 so on.
4311
4312 If umask(2) is not implemented on your system and you are trying to
4313 restrict access for I<yourself> (i.e., (EXPR & 0700) > 0), produces a
4314 fatal error at run time.  If umask(2) is not implemented and you are
4315 not trying to restrict access for yourself, returns C<undef>.
4316
4317 Remember that a umask is a number, usually given in octal; it is I<not> a
4318 string of octal digits.  See also L</oct>, if all you have is a string.
4319
4320 =item undef EXPR
4321
4322 =item undef
4323
4324 Undefines the value of EXPR, which must be an lvalue.  Use only on a
4325 scalar value, an array (using "C<@>"), a hash (using "C<%>"), a subroutine
4326 (using "C<&>"), or a typeglob (using "<*>").  (Saying C<undef $hash{$key}>
4327 will probably not do what you expect on most predefined variables or
4328 DBM list values, so don't do that; see L<delete>.)  Always returns the
4329 undefined value.  You can omit the EXPR, in which case nothing is
4330 undefined, but you still get an undefined value that you could, for
4331 instance, return from a subroutine, assign to a variable or pass as a
4332 parameter.  Examples:
4333
4334     undef $foo;
4335     undef $bar{'blurfl'};      # Compare to: delete $bar{'blurfl'};
4336     undef @ary;
4337     undef %hash;
4338     undef &mysub;
4339     undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
4340     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
4341     select undef, undef, undef, 0.25;
4342     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
4343
4344 Note that this is a unary operator, not a list operator.
4345
4346 =item unless (EXPR) BLOCK
4347
4348 The negative counterpart of L</if>.  If the EXPR returns false the
4349 BLOCK is entered.
4350
4351 See also L<perlsyn>.
4352
4353 =item unlink LIST
4354
4355 =item unlink
4356
4357 Deletes a list of files.  Returns the number of files successfully
4358 deleted.
4359
4360     $cnt = unlink 'a', 'b', 'c';
4361     unlink @goners;
4362     unlink <*.bak>;
4363
4364 Note: C<unlink()> will not delete directories unless you are superuser and
4365 the B<-U> flag is supplied to Perl.  Even if these conditions are
4366 met, be warned that unlinking a directory can inflict damage on your
4367 filesystem.  Use C<rmdir()> instead.
4368
4369 If LIST is omitted, uses C<$_>.
4370
4371 =item unpack TEMPLATE,EXPR
4372
4373 C<Unpack()> does the reverse of C<pack()>: it takes a string representing a
4374 structure and expands it out into a list value, returning the array
4375 value.  (In scalar context, it returns merely the first value
4376 produced.)  The TEMPLATE has the same format as in the C<pack()> function.
4377 Here's a subroutine that does substring:
4378
4379     sub substr {
4380         my($what,$where,$howmuch) = @_;
4381         unpack("x$where a$howmuch", $what);
4382     }
4383
4384 and then there's
4385
4386     sub ordinal { unpack("c",$_[0]); } # same as ord()
4387
4388 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
4389 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
4390 themselves.  Default is a 16-bit checksum.  For example, the following
4391 computes the same number as the System V sum program:
4392
4393     while (<>) {
4394         $checksum += unpack("%16C*", $_);
4395     }
4396     $checksum %= 65536;
4397
4398 The following efficiently counts the number of set bits in a bit vector:
4399
4400     $setbits = unpack("%32b*", $selectmask);
4401
4402 =item unshift ARRAY,LIST
4403
4404 Does the opposite of a C<shift()>.  Or the opposite of a C<push()>,
4405 depending on how you look at it.  Prepends list to the front of the
4406 array, and returns the new number of elements in the array.
4407
4408     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
4409
4410 Note the LIST is prepended whole, not one element at a time, so the
4411 prepended elements stay in the same order.  Use C<reverse()> to do the
4412 reverse.
4413
4414 =item until (EXPR) BLOCK
4415
4416 =item do BLOCK until (EXPR)
4417
4418 Enter BLOCK until EXPR returns false.  The first form may avoid entering
4419 the BLOCK, the second form enters the BLOCK at least once.
4420
4421 See L</do>, L</while>, and L</for>.
4422
4423 See also L<perlsyn>.
4424
4425 =item untie VARIABLE
4426
4427 Breaks the binding between a variable and a package.  (See C<tie()>.)
4428
4429 =item use Module LIST
4430
4431 =item use Module
4432
4433 =item use Module VERSION LIST
4434
4435 =item use VERSION
4436
4437 Imports some semantics into the current package from the named module,
4438 generally by aliasing certain subroutine or variable names into your
4439 package.  It is exactly equivalent to
4440
4441     BEGIN { require Module; import Module LIST; }
4442
4443 except that Module I<must> be a bareword.
4444
4445 If the first argument to C<use> is a number, it is treated as a version
4446 number instead of a module name.  If the version of the Perl interpreter
4447 is less than VERSION, then an error message is printed and Perl exits
4448 immediately.  This is often useful if you need to check the current
4449 Perl version before C<use>ing library modules that have changed in
4450 incompatible ways from older versions of Perl.  (We try not to do
4451 this more than we have to.)
4452
4453 The C<BEGIN> forces the C<require> and C<import()> to happen at compile time.  The
4454 C<require> makes sure the module is loaded into memory if it hasn't been
4455 yet.  The C<import()> is not a builtin--it's just an ordinary static method
4456 call into the "C<Module>" package to tell the module to import the list of
4457 features back into the current package.  The module can implement its
4458 C<import()> method any way it likes, though most modules just choose to
4459 derive their C<import()> method via inheritance from the C<Exporter> class that
4460 is defined in the C<Exporter> module.  See L<Exporter>.  If no C<import()>
4461 method can be found then the error is currently silently ignored.  This
4462 may change to a fatal error in a future version.
4463
4464 If you don't want your namespace altered, explicitly supply an empty list:
4465
4466     use Module ();
4467
4468 That is exactly equivalent to
4469
4470     BEGIN { require Module }
4471
4472 If the VERSION argument is present between Module and LIST, then the
4473 C<use> will call the VERSION method in class Module with the given
4474 version as an argument.  The default VERSION method, inherited from
4475 the Universal class, croaks if the given version is larger than the
4476 value of the variable C<$Module::VERSION>.  (Note that there is not a
4477 comma after VERSION!)
4478
4479 Because this is a wide-open interface, pragmas (compiler directives)
4480 are also implemented this way.  Currently implemented pragmas are:
4481
4482     use integer;
4483     use diagnostics;
4484     use sigtrap qw(SEGV BUS);
4485     use strict  qw(subs vars refs);
4486     use subs    qw(afunc blurfl);
4487
4488 Some of these these pseudo-modules import semantics into the current
4489 block scope (like C<strict> or C<integer>, unlike ordinary modules,
4490 which import symbols into the current package (which are effective
4491 through the end of the file).
4492
4493 There's a corresponding "C<no>" command that unimports meanings imported
4494 by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import()>.
4495
4496     no integer;
4497     no strict 'refs';
4498
4499 If no C<unimport()> method can be found the call fails with a fatal error.
4500
4501 See L<perlmod> for a list of standard modules and pragmas.
4502
4503 =item utime LIST
4504
4505 Changes the access and modification times on each file of a list of
4506 files.  The first two elements of the list must be the NUMERICAL access
4507 and modification times, in that order.  Returns the number of files
4508 successfully changed.  The inode modification time of each file is set
4509 to the current time.  This code has the same effect as the "C<touch>"
4510 command if the files already exist:
4511
4512     #!/usr/bin/perl
4513     $now = time;
4514     utime $now, $now, @ARGV;
4515
4516 =item values HASH
4517
4518 Returns a list consisting of all the values of the named hash.  (In a
4519 scalar context, returns the number of values.)  The values are
4520 returned in an apparently random order.  The actual random order is
4521 subject to change in future versions of perl, but it is guaranteed to
4522 be the same order as either the C<keys()> or C<each()> function would
4523 produce on the same (unmodified) hash.
4524
4525 As a side effect, it resets HASH's iterator.  See also C<keys()>, C<each()>,
4526 and C<sort()>.
4527
4528 =item vec EXPR,OFFSET,BITS
4529
4530 Treats the string in EXPR as a vector of unsigned integers, and
4531 returns the value of the bit field specified by OFFSET.  BITS specifies
4532 the number of bits that are reserved for each entry in the bit
4533 vector.  This must be a power of two from 1 to 32. C<vec()> may also be
4534 assigned to, in which case parentheses are needed to give the expression
4535 the correct precedence as in
4536
4537     vec($image, $max_x * $x + $y, 8) = 3;
4538
4539 Vectors created with C<vec()> can also be manipulated with the logical
4540 operators C<|>, C<&>, and C<^>, which will assume a bit vector operation is
4541 desired when both operands are strings.
4542
4543 The following code will build up an ASCII string saying C<'PerlPerlPerl'>.
4544 The comments show the string after each step. Note that this code works
4545 in the same way on big-endian or little-endian machines.
4546
4547     my $foo = '';
4548     vec($foo,  0, 32) = 0x5065726C;     # 'Perl'
4549     vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
4550     vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
4551     vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
4552     vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
4553     vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
4554     vec($foo, 21,  4) = 7;              # 'PerlPerlPer'
4555                                         # 'r' is "\x72"
4556     vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
4557     vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
4558     vec($foo, 94,  1) = 1;              # 'PerlPerlPerl'
4559                                         # 'l' is "\x6c"
4560
4561 To transform a bit vector into a string or array of 0's and 1's, use these:
4562
4563     $bits = unpack("b*", $vector);
4564     @bits = split(//, unpack("b*", $vector));
4565
4566 If you know the exact length in bits, it can be used in place of the C<*>.
4567
4568 =item wait
4569
4570 Waits for a child process to terminate and returns the pid of the
4571 deceased process, or C<-1> if there are no child processes.  The status is
4572 returned in C<$?>.  Note that a return value of C<-1> could mean that
4573 child processes are being automatically reaped, as described in L<perlipc>.
4574
4575 =item waitpid PID,FLAGS
4576
4577 Waits for a particular child process to terminate and returns the pid
4578 of the deceased process, or C<-1> if there is no such child process.  The
4579 status is returned in C<$?>.  If you say
4580
4581     use POSIX ":sys_wait_h";
4582     #...
4583     waitpid(-1,&WNOHANG);
4584
4585 then you can do a non-blocking wait for any process.  Non-blocking wait
4586 is available on machines supporting either the waitpid(2) or
4587 wait4(2) system calls.  However, waiting for a particular pid with
4588 FLAGS of C<0> is implemented everywhere.  (Perl emulates the system call
4589 by remembering the status values of processes that have exited but have
4590 not been harvested by the Perl script yet.)
4591
4592 Note that a return value of C<-1> could mean that child processes are being
4593 automatically reaped.  See L<perlipc> for details, and for other examples.
4594
4595 =item wantarray
4596
4597 Returns TRUE if the context of the currently executing subroutine is
4598 looking for a list value.  Returns FALSE if the context is looking
4599 for a scalar.  Returns the undefined value if the context is looking
4600 for no value (void context).
4601
4602     return unless defined wantarray;    # don't bother doing more
4603     my @a = complex_calculation();
4604     return wantarray ? @a : "@a";
4605
4606 =item warn LIST
4607
4608 Produces a message on STDERR just like C<die()>, but doesn't exit or throw
4609 an exception.
4610
4611 If LIST is empty and C<$@> already contains a value (typically from a
4612 previous eval) that value is used after appending C<"\t...caught">
4613 to C<$@>. This is useful for staying almost, but not entirely similar to
4614 C<die()>.
4615
4616 If C<$@> is empty then the string C<"Warning: Something's wrong"> is used.
4617
4618 No message is printed if there is a C<$SIG{__WARN__}> handler
4619 installed.  It is the handler's responsibility to deal with the message
4620 as it sees fit (like, for instance, converting it into a C<die()>).  Most
4621 handlers must therefore make arrangements to actually display the
4622 warnings that they are not prepared to deal with, by calling C<warn()>
4623 again in the handler.  Note that this is quite safe and will not
4624 produce an endless loop, since C<__WARN__> hooks are not called from
4625 inside one.
4626
4627 You will find this behavior is slightly different from that of
4628 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
4629 instead call C<die()> again to change it).
4630
4631 Using a C<__WARN__> handler provides a powerful way to silence all
4632 warnings (even the so-called mandatory ones).  An example:
4633
4634     # wipe out *all* compile-time warnings
4635     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
4636     my $foo = 10;
4637     my $foo = 20;          # no warning about duplicate my $foo,
4638                            # but hey, you asked for it!
4639     # no compile-time or run-time warnings before here
4640     $DOWARN = 1;
4641
4642     # run-time warnings enabled after here
4643     warn "\$foo is alive and $foo!";     # does show up
4644
4645 See L<perlvar> for details on setting C<%SIG> entries, and for more
4646 examples.
4647
4648 =item while (EXPR) BLOCK
4649
4650 =item do BLOCK while (EXPR)
4651
4652 Enter BLOCK while EXPR is true.  The first form may avoid entering the
4653 BLOCK, the second form enters the BLOCK at least once.
4654
4655 See also L<perlsyn>, L</for>, L</until>, and L</continue>.
4656
4657 =item write FILEHANDLE
4658
4659 =item write EXPR
4660
4661 =item write
4662
4663 Writes a formatted record (possibly multi-line) to the specified FILEHANDLE,
4664 using the format associated with that file.  By default the format for
4665 a file is the one having the same name as the filehandle, but the
4666 format for the current output channel (see the C<select()> function) may be set
4667 explicitly by assigning the name of the format to the C<$~> variable.
4668
4669 Top of form processing is handled automatically:  if there is
4670 insufficient room on the current page for the formatted record, the
4671 page is advanced by writing a form feed, a special top-of-page format
4672 is used to format the new page header, and then the record is written.
4673 By default the top-of-page format is the name of the filehandle with
4674 "_TOP" appended, but it may be dynamically set to the format of your
4675 choice by assigning the name to the C<$^> variable while the filehandle is
4676 selected.  The number of lines remaining on the current page is in
4677 variable C<$->, which can be set to C<0> to force a new page.
4678</