This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
b4f75af0b6246d3285a3e7ace90148158351ed69
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compiliation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25
26 require 5.010_001;
27 use strict;
28 use warnings;
29 use Carp;
30 use Config;
31 use File::Find;
32 use File::Path;
33 use File::Spec;
34 use Text::Tabs;
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 ##########################################################################
40 #
41 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
42 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
43 # a pod file and a .t file
44 #
45 # The structure of this file is:
46 #   First these introductory comments; then
47 #   code needed for everywhere, such as debugging stuff; then
48 #   code to handle input parameters; then
49 #   data structures likely to be of external interest (some of which depend on
50 #       the input parameters, so follows them; then
51 #   more data structures and subroutine and package (class) definitions; then
52 #   the small actual loop to process the input files and finish up; then
53 #   a __DATA__ section, for the .t tests
54 #
55 # This program works on all releases of Unicode through at least 6.0.  The
56 # outputs have been scrutinized most intently for release 5.1.  The others
57 # have been checked for somewhat more than just sanity.  It can handle all
58 # existing Unicode character properties in those releases.
59 #
60 # This program is mostly about Unicode character (or code point) properties.
61 # A property describes some attribute or quality of a code point, like if it
62 # is lowercase or not, its name, what version of Unicode it was first defined
63 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
64 # possibilities by making all properties into mappings from each code point
65 # into some corresponding value.  In the case of it being lowercase or not,
66 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
67 # property maps each Unicode code point to a single value, called a "property
68 # value".  (Hence each Unicode property is a true mathematical function with
69 # exactly one value per code point.)
70 #
71 # When using a property in a regular expression, what is desired isn't the
72 # mapping of the code point to its property's value, but the reverse (or the
73 # mathematical "inverse relation"): starting with the property value, "Does a
74 # code point map to it?"  These are written in a "compound" form:
75 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
76 # files containing the lists of code points that map to each such regular
77 # expression property value, one file per list
78 #
79 # There is also a single form shortcut that Perl adds for many of the commonly
80 # used properties.  This happens for all binary properties, plus script,
81 # general_category, and block properties.
82 #
83 # Thus the outputs of this program are files.  There are map files, mostly in
84 # the 'To' directory; and there are list files for use in regular expression
85 # matching, all in subdirectories of the 'lib' directory, with each
86 # subdirectory being named for the property that the lists in it are for.
87 # Bookkeeping, test, and documentation files are also generated.
88
89 my $matches_directory = 'lib';   # Where match (\p{}) files go.
90 my $map_directory = 'To';        # Where map files go.
91
92 # DATA STRUCTURES
93 #
94 # The major data structures of this program are Property, of course, but also
95 # Table.  There are two kinds of tables, very similar to each other.
96 # "Match_Table" is the data structure giving the list of code points that have
97 # a particular property value, mentioned above.  There is also a "Map_Table"
98 # data structure which gives the property's mapping from code point to value.
99 # There are two structures because the match tables need to be combined in
100 # various ways, such as constructing unions, intersections, complements, etc.,
101 # and the map ones don't.  And there would be problems, perhaps subtle, if
102 # a map table were inadvertently operated on in some of those ways.
103 # The use of separate classes with operations defined on one but not the other
104 # prevents accidentally confusing the two.
105 #
106 # At the heart of each table's data structure is a "Range_List", which is just
107 # an ordered list of "Ranges", plus ancillary information, and methods to
108 # operate on them.  A Range is a compact way to store property information.
109 # Each range has a starting code point, an ending code point, and a value that
110 # is meant to apply to all the code points between the two end points,
111 # inclusive.  For a map table, this value is the property value for those
112 # code points.  Two such ranges could be written like this:
113 #   0x41 .. 0x5A, 'Upper',
114 #   0x61 .. 0x7A, 'Lower'
115 #
116 # Each range also has a type used as a convenience to classify the values.
117 # Most ranges in this program will be Type 0, or normal, but there are some
118 # ranges that have a non-zero type.  These are used only in map tables, and
119 # are for mappings that don't fit into the normal scheme of things.  Mappings
120 # that require a hash entry to communicate with utf8.c are one example;
121 # another example is mappings for charnames.pm to use which indicate a name
122 # that is algorithmically determinable from its code point (and vice-versa).
123 # These are used to significantly compact these tables, instead of listing
124 # each one of the tens of thousands individually.
125 #
126 # In a match table, the value of a range is irrelevant (and hence the type as
127 # well, which will always be 0), and arbitrarily set to the null string.
128 # Using the example above, there would be two match tables for those two
129 # entries, one named Upper would contain the 0x41..0x5A range, and the other
130 # named Lower would contain 0x61..0x7A.
131 #
132 # Actually, there are two types of range lists, "Range_Map" is the one
133 # associated with map tables, and "Range_List" with match tables.
134 # Again, this is so that methods can be defined on one and not the other so as
135 # to prevent operating on them in incorrect ways.
136 #
137 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
138 # in the perl core.  All tables could in theory be written, but some are
139 # suppressed because there is no current practical use for them.  It is easy
140 # to change which get written by changing various lists that are near the top
141 # of the actual code in this file.  The table data structures contain enough
142 # ancillary information to allow them to be treated as separate entities for
143 # writing, such as the path to each one's file.  There is a heading in each
144 # map table that gives the format of its entries, and what the map is for all
145 # the code points missing from it.  (This allows tables to be more compact.)
146 #
147 # The Property data structure contains one or more tables.  All properties
148 # contain a map table (except the $perl property which is a
149 # pseudo-property containing only match tables), and any properties that
150 # are usable in regular expression matches also contain various matching
151 # tables, one for each value the property can have.  A binary property can
152 # have two values, True and False (or Y and N, which are preferred by Unicode
153 # terminology).  Thus each of these properties will have a map table that
154 # takes every code point and maps it to Y or N (but having ranges cuts the
155 # number of entries in that table way down), and two match tables, one
156 # which has a list of all the code points that map to Y, and one for all the
157 # code points that map to N.  (For each of these, a third table is also
158 # generated for the pseudo Perl property.  It contains the identical code
159 # points as the Y table, but can be written, not in the compound form, but in
160 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
161 # properties have several possible values, some have many, and properties like
162 # Name have a different value for every named code point.  Those will not,
163 # unless the controlling lists are changed, have their match tables written
164 # out.  But all the ones which can be used in regular expression \p{} and \P{}
165 # constructs will.  Generally a property will have either its map table or its
166 # match tables written but not both.  Again, what gets written is controlled
167 # by lists which can easily be changed.  Properties have a 'Type', like
168 # binary, or string, or enum depending on how many match tables there are and
169 # the content of the maps.  This 'Type' is different than a range 'Type', so
170 # don't get confused by the two concepts having the same name.
171 #
172 # For information about the Unicode properties, see Unicode's UAX44 document:
173
174 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
175
176 # As stated earlier, this program will work on any release of Unicode so far.
177 # Most obvious problems in earlier data have NOT been corrected except when
178 # necessary to make Perl or this program work reasonably.  For example, no
179 # folding information was given in early releases, so this program uses the
180 # substitute of lower case, just so that a regular expression with the /i
181 # option will do something that actually gives the right results in many
182 # cases.  There are also a couple other corrections for version 1.1.5,
183 # commented at the point they are made.  As an example of corrections that
184 # weren't made (but could be) is this statement from DerivedAge.txt: "The
185 # supplementary private use code points and the non-character code points were
186 # assigned in version 2.0, but not specifically listed in the UCD until
187 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
188 # More information on Unicode version glitches is further down in these
189 # introductory comments.
190 #
191 # This program works on all non-provisional properties as of 6.0, though the
192 # files for some are suppressed from apparent lack of demand for them.  You
193 # can change which are output by changing lists in this program.
194 #
195 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
196 # loose matchings rules (from Unicode TR18):
197 #
198 #    The recommended names for UCD properties and property values are in
199 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
200 #    [PropValue]. There are both abbreviated names and longer, more
201 #    descriptive names. It is strongly recommended that both names be
202 #    recognized, and that loose matching of property names be used,
203 #    whereby the case distinctions, whitespace, hyphens, and underbar
204 #    are ignored.
205 # The program still allows Fuzzy to override its determination of if loose
206 # matching should be used, but it isn't currently used, as it is no longer
207 # needed; the calculations it makes are good enough.
208 #
209 # SUMMARY OF HOW IT WORKS:
210 #
211 #   Process arguments
212 #
213 #   A list is constructed containing each input file that is to be processed
214 #
215 #   Each file on the list is processed in a loop, using the associated handler
216 #   code for each:
217 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
218 #            first.  These files name the properties and property values.
219 #            Objects are created of all the property and property value names
220 #            that the rest of the input should expect, including all synonyms.
221 #        The other input files give mappings from properties to property
222 #           values.  That is, they list code points and say what the mapping
223 #           is under the given property.  Some files give the mappings for
224 #           just one property; and some for many.  This program goes through
225 #           each file and populates the properties from them.  Some properties
226 #           are listed in more than one file, and Unicode has set up a
227 #           precedence as to which has priority if there is a conflict.  Thus
228 #           the order of processing matters, and this program handles the
229 #           conflict possibility by processing the overriding input files
230 #           last, so that if necessary they replace earlier values.
231 #        After this is all done, the program creates the property mappings not
232 #            furnished by Unicode, but derivable from what it does give.
233 #        The tables of code points that match each property value in each
234 #            property that is accessible by regular expressions are created.
235 #        The Perl-defined properties are created and populated.  Many of these
236 #            require data determined from the earlier steps
237 #        Any Perl-defined synonyms are created, and name clashes between Perl
238 #            and Unicode are reconciled and warned about.
239 #        All the properties are written to files
240 #        Any other files are written, and final warnings issued.
241 #
242 # For clarity, a number of operators have been overloaded to work on tables:
243 #   ~ means invert (take all characters not in the set).  The more
244 #       conventional '!' is not used because of the possibility of confusing
245 #       it with the actual boolean operation.
246 #   + means union
247 #   - means subtraction
248 #   & means intersection
249 # The precedence of these is the order listed.  Parentheses should be
250 # copiously used.  These are not a general scheme.  The operations aren't
251 # defined for a number of things, deliberately, to avoid getting into trouble.
252 # Operations are done on references and affect the underlying structures, so
253 # that the copy constructors for them have been overloaded to not return a new
254 # clone, but the input object itself.
255 #
256 # The bool operator is deliberately not overloaded to avoid confusion with
257 # "should it mean if the object merely exists, or also is non-empty?".
258 #
259 # WHY CERTAIN DESIGN DECISIONS WERE MADE
260 #
261 # This program needs to be able to run under miniperl.  Therefore, it uses a
262 # minimum of other modules, and hence implements some things itself that could
263 # be gotten from CPAN
264 #
265 # This program uses inputs published by the Unicode Consortium.  These can
266 # change incompatibly between releases without the Perl maintainers realizing
267 # it.  Therefore this program is now designed to try to flag these.  It looks
268 # at the directories where the inputs are, and flags any unrecognized files.
269 # It keeps track of all the properties in the files it handles, and flags any
270 # that it doesn't know how to handle.  It also flags any input lines that
271 # don't match the expected syntax, among other checks.
272 #
273 # It is also designed so if a new input file matches one of the known
274 # templates, one hopefully just needs to add it to a list to have it
275 # processed.
276 #
277 # As mentioned earlier, some properties are given in more than one file.  In
278 # particular, the files in the extracted directory are supposedly just
279 # reformattings of the others.  But they contain information not easily
280 # derivable from the other files, including results for Unihan, which this
281 # program doesn't ordinarily look at, and for unassigned code points.  They
282 # also have historically had errors or been incomplete.  In an attempt to
283 # create the best possible data, this program thus processes them first to
284 # glean information missing from the other files; then processes those other
285 # files to override any errors in the extracted ones.  Much of the design was
286 # driven by this need to store things and then possibly override them.
287 #
288 # It tries to keep fatal errors to a minimum, to generate something usable for
289 # testing purposes.  It always looks for files that could be inputs, and will
290 # warn about any that it doesn't know how to handle (the -q option suppresses
291 # the warning).
292 #
293 # Why have files written out for binary 'N' matches?
294 #   For binary properties, if you know the mapping for either Y or N; the
295 #   other is trivial to construct, so could be done at Perl run-time by just
296 #   complementing the result, instead of having a file for it.  That is, if
297 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
298 #   not need a file.   The problem is communicating to Perl that a given
299 #   property is binary.  Perl can't figure it out from looking at the N (or
300 #   No), as some non-binary properties have these as property values.  So
301 #   rather than inventing a way to communicate this info back to the core,
302 #   which would have required changes there as well, it was simpler just to
303 #   add the extra tables.
304 #
305 # Why is there more than one type of range?
306 #   This simplified things.  There are some very specialized code points that
307 #   have to be handled specially for output, such as Hangul syllable names.
308 #   By creating a range type (done late in the development process), it
309 #   allowed this to be stored with the range, and overridden by other input.
310 #   Originally these were stored in another data structure, and it became a
311 #   mess trying to decide if a second file that was for the same property was
312 #   overriding the earlier one or not.
313 #
314 # Why are there two kinds of tables, match and map?
315 #   (And there is a base class shared by the two as well.)  As stated above,
316 #   they actually are for different things.  Development proceeded much more
317 #   smoothly when I (khw) realized the distinction.  Map tables are used to
318 #   give the property value for every code point (actually every code point
319 #   that doesn't map to a default value).  Match tables are used for regular
320 #   expression matches, and are essentially the inverse mapping.  Separating
321 #   the two allows more specialized methods, and error checks so that one
322 #   can't just take the intersection of two map tables, for example, as that
323 #   is nonsensical.
324 #
325 # There are no match tables generated for matches of the null string.  These
326 # would look like qr/\p{JSN=}/ currently without modifying the regex code.
327 # Perhaps something like them could be added if necessary.  The JSN does have
328 # a real code point U+110B that maps to the null string, but it is a
329 # contributory property, and therefore not output by default.  And it's easily
330 # handled so far by making the null string the default where it is a
331 # possibility.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope or until you insert
346 # another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # then use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.
364 #
365 # To compare the output tables, it may be useful to specify the -annotate
366 # flag.  This causes the tables to expand so there is one entry for each
367 # non-algorithmically named code point giving, currently its name, and its
368 # graphic representation if printable (and you have a font that knows about
369 # it).  This makes it easier to see what the particular code points are in
370 # each output table.  The tables are usable, but because they don't have
371 # ranges (for the most part), a Perl using them will run slower.  Non-named
372 # code points are annotated with a description of their status, and contiguous
373 # ones with the same description will be output as a range rather than
374 # individually.  Algorithmically named characters are also output as ranges,
375 # except when there are just a few contiguous ones.
376 #
377 # FUTURE ISSUES
378 #
379 # The program would break if Unicode were to change its names so that
380 # interior white space, underscores, or dashes differences were significant
381 # within property and property value names.
382 #
383 # It might be easier to use the xml versions of the UCD if this program ever
384 # would need heavy revision, and the ability to handle old versions was not
385 # required.
386 #
387 # There is the potential for name collisions, in that Perl has chosen names
388 # that Unicode could decide it also likes.  There have been such collisions in
389 # the past, with mostly Perl deciding to adopt the Unicode definition of the
390 # name.  However in the 5.2 Unicode beta testing, there were a number of such
391 # collisions, which were withdrawn before the final release, because of Perl's
392 # and other's protests.  These all involved new properties which began with
393 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
394 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
395 # Unicode document, so they are unlikely to be used by Unicode for another
396 # purpose.  However, they might try something beginning with 'In', or use any
397 # of the other Perl-defined properties.  This program will warn you of name
398 # collisions, and refuse to generate tables with them, but manual intervention
399 # will be required in this event.  One scheme that could be implemented, if
400 # necessary, would be to have this program generate another file, or add a
401 # field to mktables.lst that gives the date of first definition of a property.
402 # Each new release of Unicode would use that file as a basis for the next
403 # iteration.  And the Perl synonym addition code could sort based on the age
404 # of the property, so older properties get priority, and newer ones that clash
405 # would be refused; hence existing code would not be impacted, and some other
406 # synonym would have to be used for the new property.  This is ugly, and
407 # manual intervention would certainly be easier to do in the short run; lets
408 # hope it never comes to this.
409 #
410 # A NOTE ON UNIHAN
411 #
412 # This program can generate tables from the Unihan database.  But it doesn't
413 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
414 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
415 # database was split into 8 different files, all beginning with the letters
416 # 'Unihan'.  This program will read those file(s) if present, but it needs to
417 # know which of the many properties in the file(s) should have tables created
418 # for them.  It will create tables for any properties listed in
419 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
420 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
421 # property you want is not in those files of the release you are building
422 # against, you must add it to those two arrays.  Starting in 4.0, the
423 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
424 # is present in the directory, a table will be generated for that property.
425 # In 5.2, several more properties were added.  For your convenience, the two
426 # arrays are initialized with all the 6.0 listed properties that are also in
427 # earlier releases.  But these are commented out.  You can just uncomment the
428 # ones you want, or use them as a template for adding entries for other
429 # properties.
430 #
431 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
432 # and filter_unihan_line() are the functions where this is done.  This program
433 # already does some adjusting to make the lines look more like the rest of the
434 # Unicode DB;  You can see what that is in filter_unihan_line()
435 #
436 # There is a bug in the 3.2 data file in which some values for the
437 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
438 # could be added for these; or for a particular installation, the Unihan.txt
439 # file could be edited to fix them.
440 #
441 # HOW TO ADD A FILE TO BE PROCESSED
442 #
443 # A new file from Unicode needs to have an object constructed for it in
444 # @input_file_objects, probably at the end or at the end of the extracted
445 # ones.  The program should warn you if its name will clash with others on
446 # restrictive file systems, like DOS.  If so, figure out a better name, and
447 # add lines to the README.perl file giving that.  If the file is a character
448 # property, it should be in the format that Unicode has by default
449 # standardized for such files for the more recently introduced ones.
450 # If so, the Input_file constructor for @input_file_objects can just be the
451 # file name and release it first appeared in.  If not, then it should be
452 # possible to construct an each_line_handler() to massage the line into the
453 # standardized form.
454 #
455 # For non-character properties, more code will be needed.  You can look at
456 # the existing entries for clues.
457 #
458 # UNICODE VERSIONS NOTES
459 #
460 # The Unicode UCD has had a number of errors in it over the versions.  And
461 # these remain, by policy, in the standard for that version.  Therefore it is
462 # risky to correct them, because code may be expecting the error.  So this
463 # program doesn't generally make changes, unless the error breaks the Perl
464 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
465 # for U+1105, which causes real problems for the algorithms for Jamo
466 # calculations, so it is changed here.
467 #
468 # But it isn't so clear cut as to what to do about concepts that are
469 # introduced in a later release; should they extend back to earlier releases
470 # where the concept just didn't exist?  It was easier to do this than to not,
471 # so that's what was done.  For example, the default value for code points not
472 # in the files for various properties was probably undefined until changed by
473 # some version.  No_Block for blocks is such an example.  This program will
474 # assign No_Block even in Unicode versions that didn't have it.  This has the
475 # benefit that code being written doesn't have to special case earlier
476 # versions; and the detriment that it doesn't match the Standard precisely for
477 # the affected versions.
478 #
479 # Here are some observations about some of the issues in early versions:
480 #
481 # The number of code points in \p{alpha} halve in 2.1.9.  It turns out that
482 # the reason is that the CJK block starting at 4E00 was removed from PropList,
483 # and was not put back in until 3.1.0
484 #
485 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
486 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
487 # reason is that 3.2 introduced U+205F=medium math space, which was not
488 # classed as white space, but Perl figured out that it should have been. 4.0
489 # reclassified it correctly.
490 #
491 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
492 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
493 # was left with no code points, as all the ones that mapped to 202 stayed
494 # mapped to 202.  Thus if your program used the numeric name for the class,
495 # it would not have been affected, but if it used the mnemonic, it would have
496 # been.
497 #
498 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
499 # points which eventually came to have this script property value, instead
500 # mapped to "Unknown".  But in the next release all these code points were
501 # moved to \p{sc=common} instead.
502 #
503 # The default for missing code points for BidiClass is complicated.  Starting
504 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
505 # tries to do the best it can for earlier releases.  It is done in
506 # process_PropertyAliases()
507 #
508 ##############################################################################
509
510 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
511                         # and errors
512 my $MAX_LINE_WIDTH = 78;
513
514 # Debugging aid to skip most files so as to not be distracted by them when
515 # concentrating on the ones being debugged.  Add
516 # non_skip => 1,
517 # to the constructor for those files you want processed when you set this.
518 # Files with a first version number of 0 are special: they are always
519 # processed regardless of the state of this flag.
520 my $debug_skip = 0;
521
522 # Set to 1 to enable tracing.
523 our $to_trace = 0;
524
525 { # Closure for trace: debugging aid
526     my $print_caller = 1;        # ? Include calling subroutine name
527     my $main_with_colon = 'main::';
528     my $main_colon_length = length($main_with_colon);
529
530     sub trace {
531         return unless $to_trace;        # Do nothing if global flag not set
532
533         my @input = @_;
534
535         local $DB::trace = 0;
536         $DB::trace = 0;          # Quiet 'used only once' message
537
538         my $line_number;
539
540         # Loop looking up the stack to get the first non-trace caller
541         my $caller_line;
542         my $caller_name;
543         my $i = 0;
544         do {
545             $line_number = $caller_line;
546             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
547             $caller = $main_with_colon unless defined $caller;
548
549             $caller_name = $caller;
550
551             # get rid of pkg
552             $caller_name =~ s/.*:://;
553             if (substr($caller_name, 0, $main_colon_length)
554                 eq $main_with_colon)
555             {
556                 $caller_name = substr($caller_name, $main_colon_length);
557             }
558
559         } until ($caller_name ne 'trace');
560
561         # If the stack was empty, we were called from the top level
562         $caller_name = 'main' if ($caller_name eq ""
563                                     || $caller_name eq 'trace');
564
565         my $output = "";
566         foreach my $string (@input) {
567             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
568             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
569                 $output .= simple_dumper($string);
570             }
571             else {
572                 $string = "$string" if ref $string;
573                 $string = $UNDEF unless defined $string;
574                 chomp $string;
575                 $string = '""' if $string eq "";
576                 $output .= " " if $output ne ""
577                                 && $string ne ""
578                                 && substr($output, -1, 1) ne " "
579                                 && substr($string, 0, 1) ne " ";
580                 $output .= $string;
581             }
582         }
583
584         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
585         print STDERR "$caller_name: " if $print_caller;
586         print STDERR $output, "\n";
587         return;
588     }
589 }
590
591 # This is for a rarely used development feature that allows you to compare two
592 # versions of the Unicode standard without having to deal with changes caused
593 # by the code points introduced in the later verson.  Change the 0 to a SINGLE
594 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
595 # that release and earlier will be used; later ones are thrown away.  You use
596 # the version number of the earliest one you want to compare; then run this
597 # program on directory structures containing each release, and compare the
598 # outputs.  These outputs will therefore include only the code points common
599 # to both releases, and you can see the changes caused just by the underlying
600 # release semantic changes.  For versions earlier than 3.2, you must copy a
601 # version of DAge.txt into the directory.
602 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
603 my $compare_versions = DEBUG
604                        && $string_compare_versions
605                        && pack "C*", split /\./, $string_compare_versions;
606
607 sub uniques {
608     # Returns non-duplicated input values.  From "Perl Best Practices:
609     # Encapsulated Cleverness".  p. 455 in first edition.
610
611     my %seen;
612     # Arguably this breaks encapsulation, if the goal is to permit multiple
613     # distinct objects to stringify to the same value, and be interchangeable.
614     # However, for this program, no two objects stringify identically, and all
615     # lists passed to this function are either objects or strings. So this
616     # doesn't affect correctness, but it does give a couple of percent speedup.
617     no overloading;
618     return grep { ! $seen{$_}++ } @_;
619 }
620
621 $0 = File::Spec->canonpath($0);
622
623 my $make_test_script = 0;      # ? Should we output a test script
624 my $write_unchanged_files = 0; # ? Should we update the output files even if
625                                #    we don't think they have changed
626 my $use_directory = "";        # ? Should we chdir somewhere.
627 my $pod_directory;             # input directory to store the pod file.
628 my $pod_file = 'perluniprops';
629 my $t_path;                     # Path to the .t test file
630 my $file_list = 'mktables.lst'; # File to store input and output file names.
631                                # This is used to speed up the build, by not
632                                # executing the main body of the program if
633                                # nothing on the list has changed since the
634                                # previous build
635 my $make_list = 1;             # ? Should we write $file_list.  Set to always
636                                # make a list so that when the pumpking is
637                                # preparing a release, s/he won't have to do
638                                # special things
639 my $glob_list = 0;             # ? Should we try to include unknown .txt files
640                                # in the input.
641 my $output_range_counts = $debugging_build;   # ? Should we include the number
642                                               # of code points in ranges in
643                                               # the output
644 my $annotate = 0;              # ? Should character names be in the output
645
646 # Verbosity levels; 0 is quiet
647 my $NORMAL_VERBOSITY = 1;
648 my $PROGRESS = 2;
649 my $VERBOSE = 3;
650
651 my $verbosity = $NORMAL_VERBOSITY;
652
653 # Process arguments
654 while (@ARGV) {
655     my $arg = shift @ARGV;
656     if ($arg eq '-v') {
657         $verbosity = $VERBOSE;
658     }
659     elsif ($arg eq '-p') {
660         $verbosity = $PROGRESS;
661         $| = 1;     # Flush buffers as we go.
662     }
663     elsif ($arg eq '-q') {
664         $verbosity = 0;
665     }
666     elsif ($arg eq '-w') {
667         $write_unchanged_files = 1; # update the files even if havent changed
668     }
669     elsif ($arg eq '-check') {
670         my $this = shift @ARGV;
671         my $ok = shift @ARGV;
672         if ($this ne $ok) {
673             print "Skipping as check params are not the same.\n";
674             exit(0);
675         }
676     }
677     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
678         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
679     }
680     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
681     {
682         $make_test_script = 1;
683     }
684     elsif ($arg eq '-makelist') {
685         $make_list = 1;
686     }
687     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
688         -d $use_directory or croak "Unknown directory '$use_directory'";
689     }
690     elsif ($arg eq '-L') {
691
692         # Existence not tested until have chdir'd
693         $file_list = shift;
694     }
695     elsif ($arg eq '-globlist') {
696         $glob_list = 1;
697     }
698     elsif ($arg eq '-c') {
699         $output_range_counts = ! $output_range_counts
700     }
701     elsif ($arg eq '-annotate') {
702         $annotate = 1;
703         $debugging_build = 1;
704         $output_range_counts = 1;
705     }
706     else {
707         my $with_c = 'with';
708         $with_c .= 'out' if $output_range_counts;   # Complements the state
709         croak <<END;
710 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
711           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
712           [-check A B ]
713   -c          : Output comments $with_c number of code points in ranges
714   -q          : Quiet Mode: Only output serious warnings.
715   -p          : Set verbosity level to normal plus show progress.
716   -v          : Set Verbosity level high:  Show progress and non-serious
717                 warnings
718   -w          : Write files regardless
719   -C dir      : Change to this directory before proceeding. All relative paths
720                 except those specified by the -P and -T options will be done
721                 with respect to this directory.
722   -P dir      : Output $pod_file file to directory 'dir'.
723   -T path     : Create a test script as 'path'; overrides -maketest
724   -L filelist : Use alternate 'filelist' instead of standard one
725   -globlist   : Take as input all non-Test *.txt files in current and sub
726                 directories
727   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
728                 overrides -T
729   -makelist   : Rewrite the file list $file_list based on current setup
730   -annotate   : Output an annotation for each character in the table files;
731                 useful for debugging mktables, looking at diffs; but is slow,
732                 memory intensive; resulting tables are usable but slow and
733                 very large.
734   -check A B  : Executes $0 only if A and B are the same
735 END
736     }
737 }
738
739 # Stores the most-recently changed file.  If none have changed, can skip the
740 # build
741 my $most_recent = (stat $0)[9];   # Do this before the chdir!
742
743 # Change directories now, because need to read 'version' early.
744 if ($use_directory) {
745     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
746         $pod_directory = File::Spec->rel2abs($pod_directory);
747     }
748     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
749         $t_path = File::Spec->rel2abs($t_path);
750     }
751     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
752     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
753         $pod_directory = File::Spec->abs2rel($pod_directory);
754     }
755     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
756         $t_path = File::Spec->abs2rel($t_path);
757     }
758 }
759
760 # Get Unicode version into regular and v-string.  This is done now because
761 # various tables below get populated based on it.  These tables are populated
762 # here to be near the top of the file, and so easily seeable by those needing
763 # to modify things.
764 open my $VERSION, "<", "version"
765                     or croak "$0: can't open required file 'version': $!\n";
766 my $string_version = <$VERSION>;
767 close $VERSION;
768 chomp $string_version;
769 my $v_version = pack "C*", split /\./, $string_version;        # v string
770
771 # The following are the complete names of properties with property values that
772 # are known to not match any code points in some versions of Unicode, but that
773 # may change in the future so they should be matchable, hence an empty file is
774 # generated for them.
775 my @tables_that_may_be_empty = (
776                                 'Joining_Type=Left_Joining',
777                                 );
778 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
779 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
780 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
781                                                     if $v_version ge v4.1.0;
782
783 # The lists below are hashes, so the key is the item in the list, and the
784 # value is the reason why it is in the list.  This makes generation of
785 # documentation easier.
786
787 my %why_suppressed;  # No file generated for these.
788
789 # Files aren't generated for empty extraneous properties.  This is arguable.
790 # Extraneous properties generally come about because a property is no longer
791 # used in a newer version of Unicode.  If we generated a file without code
792 # points, programs that used to work on that property will still execute
793 # without errors.  It just won't ever match (or will always match, with \P{}).
794 # This means that the logic is now likely wrong.  I (khw) think its better to
795 # find this out by getting an error message.  Just move them to the table
796 # above to change this behavior
797 my %why_suppress_if_empty_warn_if_not = (
798
799    # It is the only property that has ever officially been removed from the
800    # Standard.  The database never contained any code points for it.
801    'Special_Case_Condition' => 'Obsolete',
802
803    # Apparently never official, but there were code points in some versions of
804    # old-style PropList.txt
805    'Non_Break' => 'Obsolete',
806 );
807
808 # These would normally go in the warn table just above, but they were changed
809 # a long time before this program was written, so warnings about them are
810 # moot.
811 if ($v_version gt v3.2.0) {
812     push @tables_that_may_be_empty,
813                                 'Canonical_Combining_Class=Attached_Below_Left'
814 }
815
816 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
817 # unless explicitly added.
818 if ($v_version ge v5.2.0) {
819     my $unihan = 'Unihan; remove from list if using Unihan';
820     foreach my $table (qw (
821                            kAccountingNumeric
822                            kOtherNumeric
823                            kPrimaryNumeric
824                            kCompatibilityVariant
825                            kIICore
826                            kIRG_GSource
827                            kIRG_HSource
828                            kIRG_JSource
829                            kIRG_KPSource
830                            kIRG_MSource
831                            kIRG_KSource
832                            kIRG_TSource
833                            kIRG_USource
834                            kIRG_VSource
835                            kRSUnicode
836                         ))
837     {
838         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
839     }
840 }
841
842 # Properties that this program ignores.
843 my @unimplemented_properties = (
844 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
845 );
846
847 # There are several types of obsolete properties defined by Unicode.  These
848 # must be hand-edited for every new Unicode release.
849 my %why_deprecated;  # Generates a deprecated warning message if used.
850 my %why_stabilized;  # Documentation only
851 my %why_obsolete;    # Documentation only
852
853 {   # Closure
854     my $simple = 'Perl uses the more complete version of this property';
855     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
856
857     my $other_properties = 'other properties';
858     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
859     my $why_no_expand  = "Deprecated by Unicode: less useful than UTF-specific calculations",
860
861     %why_deprecated = (
862         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
863         'Jamo_Short_Name' => $contributory,
864         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
865         'Other_Alphabetic' => $contributory,
866         'Other_Default_Ignorable_Code_Point' => $contributory,
867         'Other_Grapheme_Extend' => $contributory,
868         'Other_ID_Continue' => $contributory,
869         'Other_ID_Start' => $contributory,
870         'Other_Lowercase' => $contributory,
871         'Other_Math' => $contributory,
872         'Other_Uppercase' => $contributory,
873     );
874
875     %why_suppressed = (
876         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
877         # contains the same information, but without the algorithmically
878         # determinable Hangul syllables'.  This file is not published, so it's
879         # existence is not noted in the comment.
880         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
881
882         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
883         'Unicode_1_Name' => "$simple, and no apparent demand for it, but can access it through Unicode::UCD::charinfo.  If there is no later name for a code point, then this one is used instead in charnames",
884
885         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
886         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
887         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
888         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
889
890         'Name' => "Accessible via 'use charnames;'",
891         'Name_Alias' => "Accessible via 'use charnames;'",
892
893         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
894         Expands_On_NFC => $why_no_expand,
895         Expands_On_NFD => $why_no_expand,
896         Expands_On_NFKC => $why_no_expand,
897         Expands_On_NFKD => $why_no_expand,
898     );
899
900     # The following are suppressed because they were made contributory or
901     # deprecated by Unicode before Perl ever thought about supporting them.
902     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
903         $why_suppressed{$property} = $why_deprecated{$property};
904     }
905
906     # Customize the message for all the 'Other_' properties
907     foreach my $property (keys %why_deprecated) {
908         next if (my $main_property = $property) !~ s/^Other_//;
909         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
910     }
911 }
912
913 if ($v_version ge 4.0.0) {
914     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
915     if ($v_version ge 6.0.0) {
916         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
917     }
918 }
919 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
920     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
921     if ($v_version ge 6.0.0) {
922         $why_deprecated{'ISO_Comment'} = 'No longer needed for chart generation; otherwise not useful, and code points for it have been removed';
923     }
924 }
925
926 # Probably obsolete forever
927 if ($v_version ge v4.1.0) {
928     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
929 }
930
931 # This program can create files for enumerated-like properties, such as
932 # 'Numeric_Type'.  This file would be the same format as for a string
933 # property, with a mapping from code point to its value, so you could look up,
934 # for example, the script a code point is in.  But no one so far wants this
935 # mapping, or they have found another way to get it since this is a new
936 # feature.  So no file is generated except if it is in this list.
937 my @output_mapped_properties = split "\n", <<END;
938 END
939
940 # If you are using the Unihan database, you need to add the properties that
941 # you want to extract from it to this table.  For your convenience, the
942 # properties in the 6.0 PropertyAliases.txt file are listed, commented out
943 my @cjk_properties = split "\n", <<'END';
944 #cjkAccountingNumeric; kAccountingNumeric
945 #cjkOtherNumeric; kOtherNumeric
946 #cjkPrimaryNumeric; kPrimaryNumeric
947 #cjkCompatibilityVariant; kCompatibilityVariant
948 #cjkIICore ; kIICore
949 #cjkIRG_GSource; kIRG_GSource
950 #cjkIRG_HSource; kIRG_HSource
951 #cjkIRG_JSource; kIRG_JSource
952 #cjkIRG_KPSource; kIRG_KPSource
953 #cjkIRG_KSource; kIRG_KSource
954 #cjkIRG_TSource; kIRG_TSource
955 #cjkIRG_USource; kIRG_USource
956 #cjkIRG_VSource; kIRG_VSource
957 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
958 END
959
960 # Similarly for the property values.  For your convenience, the lines in the
961 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
962 # '#' marks
963 my @cjk_property_values = split "\n", <<'END';
964 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
965 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
966 ## @missing: 0000..10FFFF; cjkIICore; <none>
967 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
968 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
969 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
970 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
971 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
972 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
973 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
974 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
975 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
976 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
977 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
978 END
979
980 # The input files don't list every code point.  Those not listed are to be
981 # defaulted to some value.  Below are hard-coded what those values are for
982 # non-binary properties as of 5.1.  Starting in 5.0, there are
983 # machine-parsable comment lines in the files the give the defaults; so this
984 # list shouldn't have to be extended.  The claim is that all missing entries
985 # for binary properties will default to 'N'.  Unicode tried to change that in
986 # 5.2, but the beta period produced enough protest that they backed off.
987 #
988 # The defaults for the fields that appear in UnicodeData.txt in this hash must
989 # be in the form that it expects.  The others may be synonyms.
990 my $CODE_POINT = '<code point>';
991 my %default_mapping = (
992     Age => "Unassigned",
993     # Bidi_Class => Complicated; set in code
994     Bidi_Mirroring_Glyph => "",
995     Block => 'No_Block',
996     Canonical_Combining_Class => 0,
997     Case_Folding => $CODE_POINT,
998     Decomposition_Mapping => $CODE_POINT,
999     Decomposition_Type => 'None',
1000     East_Asian_Width => "Neutral",
1001     FC_NFKC_Closure => $CODE_POINT,
1002     General_Category => 'Cn',
1003     Grapheme_Cluster_Break => 'Other',
1004     Hangul_Syllable_Type => 'NA',
1005     ISO_Comment => "",
1006     Jamo_Short_Name => "",
1007     Joining_Group => "No_Joining_Group",
1008     # Joining_Type => Complicated; set in code
1009     kIICore => 'N',   #                       Is converted to binary
1010     #Line_Break => Complicated; set in code
1011     Lowercase_Mapping => $CODE_POINT,
1012     Name => "",
1013     Name_Alias => "",
1014     NFC_QC => 'Yes',
1015     NFD_QC => 'Yes',
1016     NFKC_QC => 'Yes',
1017     NFKD_QC => 'Yes',
1018     Numeric_Type => 'None',
1019     Numeric_Value => 'NaN',
1020     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1021     Sentence_Break => 'Other',
1022     Simple_Case_Folding => $CODE_POINT,
1023     Simple_Lowercase_Mapping => $CODE_POINT,
1024     Simple_Titlecase_Mapping => $CODE_POINT,
1025     Simple_Uppercase_Mapping => $CODE_POINT,
1026     Titlecase_Mapping => $CODE_POINT,
1027     Unicode_1_Name => "",
1028     Unicode_Radical_Stroke => "",
1029     Uppercase_Mapping => $CODE_POINT,
1030     Word_Break => 'Other',
1031 );
1032
1033 # Below are files that Unicode furnishes, but this program ignores, and why
1034 my %ignored_files = (
1035     'CJKRadicals.txt' => 'Unihan data',
1036     'Index.txt' => 'An index, not actual data',
1037     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
1038     'NamesList.txt' => 'Just adds commentary',
1039     'NormalizationCorrections.txt' => 'Data is already in other files.',
1040     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
1041     'ReadMe.txt' => 'Just comments',
1042     'README.TXT' => 'Just comments',
1043     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
1044     'EmojiSources.txt' => 'Not of general utility: for Japanese legacy cell-phone applications',
1045     'IndicMatraCategory.txt' => 'Provisional',
1046     'IndicSyllabicCategory.txt' => 'Provisional',
1047     'ScriptExtensions.txt' => 'Provisional',
1048 );
1049
1050 ### End of externally interesting definitions, except for @input_file_objects
1051
1052 my $HEADER=<<"EOF";
1053 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1054 # This file is machine-generated by $0 from the Unicode
1055 # database, Version $string_version.  Any changes made here will be lost!
1056 EOF
1057
1058 my $INTERNAL_ONLY=<<"EOF";
1059
1060 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1061 # This file is for internal use by the Perl program only.  The format and even
1062 # the name or existence of this file are subject to change without notice.
1063 # Don't use it directly.
1064 EOF
1065
1066 my $DEVELOPMENT_ONLY=<<"EOF";
1067 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1068 # This file contains information artificially constrained to code points
1069 # present in Unicode release $string_compare_versions.
1070 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1071 # not be used for production.
1072
1073 EOF
1074
1075 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1076 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1077 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1078
1079 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1080 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1081 # to decrease backtracking
1082 my $code_point_re =
1083         qr/ \b (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1084
1085 # This matches the beginning of the line in the Unicode db files that give the
1086 # defaults for code points not listed (i.e., missing) in the file.  The code
1087 # depends on this ending with a semi-colon, so it can assume it is a valid
1088 # field when the line is split() by semi-colons
1089 my $missing_defaults_prefix =
1090             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1091
1092 # Property types.  Unicode has more types, but these are sufficient for our
1093 # purposes.
1094 my $UNKNOWN = -1;   # initialized to illegal value
1095 my $NON_STRING = 1; # Either binary or enum
1096 my $BINARY = 2;
1097 my $ENUM = 3;       # Include catalog
1098 my $STRING = 4;     # Anything else: string or misc
1099
1100 # Some input files have lines that give default values for code points not
1101 # contained in the file.  Sometimes these should be ignored.
1102 my $NO_DEFAULTS = 0;        # Must evaluate to false
1103 my $NOT_IGNORED = 1;
1104 my $IGNORED = 2;
1105
1106 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1107 # and will appear in the main body of the tables in the output files, but
1108 # there are other types of ranges as well, listed below, that are specially
1109 # handled.   There are pseudo-types as well that will never be stored as a
1110 # type, but will affect the calculation of the type.
1111
1112 # 0 is for normal, non-specials
1113 my $MULTI_CP = 1;           # Sequence of more than code point
1114 my $HANGUL_SYLLABLE = 2;
1115 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1116 my $NULL = 4;               # The map is to the null string; utf8.c can't
1117                             # handle these, nor is there an accepted syntax
1118                             # for them in \p{} constructs
1119 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1120                              # otherwise be $MULTI_CP type are instead type 0
1121
1122 # process_generic_property_file() can accept certain overrides in its input.
1123 # Each of these must begin AND end with $CMD_DELIM.
1124 my $CMD_DELIM = "\a";
1125 my $REPLACE_CMD = 'replace';    # Override the Replace
1126 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1127
1128 my $NO = 0;
1129 my $YES = 1;
1130
1131 # Values for the Replace argument to add_range.
1132 # $NO                      # Don't replace; add only the code points not
1133                            # already present.
1134 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1135                            # the comments at the subroutine definition.
1136 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1137 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1138                            # already there
1139
1140 # Flags to give property statuses.  The phrases are to remind maintainers that
1141 # if the flag is changed, the indefinite article referring to it in the
1142 # documentation may need to be as well.
1143 my $NORMAL = "";
1144 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1145                         # it is suppressed
1146 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1147 my $DEPRECATED = 'D';
1148 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1149 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1150 my $DISCOURAGED = 'X';
1151 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1152 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1153 my $STRICTER = 'T';
1154 my $a_bold_stricter = "a 'B<$STRICTER>'";
1155 my $A_bold_stricter = "A 'B<$STRICTER>'";
1156 my $STABILIZED = 'S';
1157 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1158 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1159 my $OBSOLETE = 'O';
1160 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1161 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1162
1163 my %status_past_participles = (
1164     $DISCOURAGED => 'discouraged',
1165     $SUPPRESSED => 'should never be generated',
1166     $STABILIZED => 'stabilized',
1167     $OBSOLETE => 'obsolete',
1168     $DEPRECATED => 'deprecated',
1169 );
1170
1171 # The format of the values of the tables:
1172 my $EMPTY_FORMAT = "";
1173 my $BINARY_FORMAT = 'b';
1174 my $DECIMAL_FORMAT = 'd';
1175 my $FLOAT_FORMAT = 'f';
1176 my $INTEGER_FORMAT = 'i';
1177 my $HEX_FORMAT = 'x';
1178 my $RATIONAL_FORMAT = 'r';
1179 my $STRING_FORMAT = 's';
1180 my $DECOMP_STRING_FORMAT = 'c';
1181
1182 my %map_table_formats = (
1183     $BINARY_FORMAT => 'binary',
1184     $DECIMAL_FORMAT => 'single decimal digit',
1185     $FLOAT_FORMAT => 'floating point number',
1186     $INTEGER_FORMAT => 'integer',
1187     $HEX_FORMAT => 'positive hex whole number; a code point',
1188     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1189     $STRING_FORMAT => 'string',
1190     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1191 );
1192
1193 # Unicode didn't put such derived files in a separate directory at first.
1194 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1195 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1196 my $AUXILIARY = 'auxiliary';
1197
1198 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1199 my %loose_to_file_of;       # loosely maps table names to their respective
1200                             # files
1201 my %stricter_to_file_of;    # same; but for stricter mapping.
1202 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1203                              # their rational equivalent
1204 my %loose_property_name_of; # Loosely maps property names to standard form
1205
1206 # These constants names and values were taken from the Unicode standard,
1207 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1208 # syllables.  The '_string' versions are so generated tables can retain the
1209 # hex format, which is the more familiar value
1210 my $SBase_string = "0xAC00";
1211 my $SBase = CORE::hex $SBase_string;
1212 my $LBase_string = "0x1100";
1213 my $LBase = CORE::hex $LBase_string;
1214 my $VBase_string = "0x1161";
1215 my $VBase = CORE::hex $VBase_string;
1216 my $TBase_string = "0x11A7";
1217 my $TBase = CORE::hex $TBase_string;
1218 my $SCount = 11172;
1219 my $LCount = 19;
1220 my $VCount = 21;
1221 my $TCount = 28;
1222 my $NCount = $VCount * $TCount;
1223
1224 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1225 # with the above published constants.
1226 my %Jamo;
1227 my %Jamo_L;     # Leading consonants
1228 my %Jamo_V;     # Vowels
1229 my %Jamo_T;     # Trailing consonants
1230
1231 my @backslash_X_tests;     # List of tests read in for testing \X
1232 my @unhandled_properties;  # Will contain a list of properties found in
1233                            # the input that we didn't process.
1234 my @match_properties;      # Properties that have match tables, to be
1235                            # listed in the pod
1236 my @map_properties;        # Properties that get map files written
1237 my @named_sequences;       # NamedSequences.txt contents.
1238 my %potential_files;       # Generated list of all .txt files in the directory
1239                            # structure so we can warn if something is being
1240                            # ignored.
1241 my @files_actually_output; # List of files we generated.
1242 my @more_Names;            # Some code point names are compound; this is used
1243                            # to store the extra components of them.
1244 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1245                            # the minimum before we consider it equivalent to a
1246                            # candidate rational
1247 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1248
1249 # These store references to certain commonly used property objects
1250 my $gc;
1251 my $perl;
1252 my $block;
1253 my $perl_charname;
1254 my $print;
1255
1256 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1257 my $has_In_conflicts = 0;
1258 my $has_Is_conflicts = 0;
1259
1260 sub internal_file_to_platform ($) {
1261     # Convert our file paths which have '/' separators to those of the
1262     # platform.
1263
1264     my $file = shift;
1265     return undef unless defined $file;
1266
1267     return File::Spec->join(split '/', $file);
1268 }
1269
1270 sub file_exists ($) {   # platform independent '-e'.  This program internally
1271                         # uses slash as a path separator.
1272     my $file = shift;
1273     return 0 if ! defined $file;
1274     return -e internal_file_to_platform($file);
1275 }
1276
1277 sub objaddr($) {
1278     # Returns the address of the blessed input object.
1279     # It doesn't check for blessedness because that would do a string eval
1280     # every call, and the program is structured so that this is never called
1281     # for a non-blessed object.
1282
1283     no overloading; # If overloaded, numifying below won't work.
1284
1285     # Numifying a ref gives its address.
1286     return pack 'J', $_[0];
1287 }
1288
1289 # These are used only if $annotate is true.
1290 # The entire range of Unicode characters is examined to populate these
1291 # after all the input has been processed.  But most can be skipped, as they
1292 # have the same descriptive phrases, such as being unassigned
1293 my @viacode;            # Contains the 1 million character names
1294 my @printable;          # boolean: And are those characters printable?
1295 my @annotate_char_type; # Contains a type of those characters, specifically
1296                         # for the purposes of annotation.
1297 my $annotate_ranges;    # A map of ranges of code points that have the same
1298                         # name for the purposes of annoation.  They map to the
1299                         # upper edge of the range, so that the end point can
1300                         # be immediately found.  This is used to skip ahead to
1301                         # the end of a range, and avoid processing each
1302                         # individual code point in it.
1303 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1304                                    # characters, but excluding those which are
1305                                    # also noncharacter code points
1306
1307 # The annotation types are an extension of the regular range types, though
1308 # some of the latter are folded into one.  Make the new types negative to
1309 # avoid conflicting with the regular types
1310 my $SURROGATE_TYPE = -1;
1311 my $UNASSIGNED_TYPE = -2;
1312 my $PRIVATE_USE_TYPE = -3;
1313 my $NONCHARACTER_TYPE = -4;
1314 my $CONTROL_TYPE = -5;
1315 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1316
1317 sub populate_char_info ($) {
1318     # Used only with the $annotate option.  Populates the arrays with the
1319     # input code point's info that are needed for outputting more detailed
1320     # comments.  If calling context wants a return, it is the end point of
1321     # any contiguous range of characters that share essentially the same info
1322
1323     my $i = shift;
1324     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1325
1326     $viacode[$i] = $perl_charname->value_of($i) || "";
1327
1328     # A character is generally printable if Unicode says it is,
1329     # but below we make sure that most Unicode general category 'C' types
1330     # aren't.
1331     $printable[$i] = $print->contains($i);
1332
1333     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1334
1335     # Only these two regular types are treated specially for annotations
1336     # purposes
1337     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1338                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1339
1340     # Give a generic name to all code points that don't have a real name.
1341     # We output ranges, if applicable, for these.  Also calculate the end
1342     # point of the range.
1343     my $end;
1344     if (! $viacode[$i]) {
1345         if ($gc-> table('Surrogate')->contains($i)) {
1346             $viacode[$i] = 'Surrogate';
1347             $annotate_char_type[$i] = $SURROGATE_TYPE;
1348             $printable[$i] = 0;
1349             $end = $gc->table('Surrogate')->containing_range($i)->end;
1350         }
1351         elsif ($gc-> table('Private_use')->contains($i)) {
1352             $viacode[$i] = 'Private Use';
1353             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1354             $printable[$i] = 0;
1355             $end = $gc->table('Private_Use')->containing_range($i)->end;
1356         }
1357         elsif (Property::property_ref('Noncharacter_Code_Point')-> table('Y')->
1358                                                                 contains($i))
1359         {
1360             $viacode[$i] = 'Noncharacter';
1361             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1362             $printable[$i] = 0;
1363             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1364                                                     containing_range($i)->end;
1365         }
1366         elsif ($gc-> table('Control')->contains($i)) {
1367             $viacode[$i] = 'Control';
1368             $annotate_char_type[$i] = $CONTROL_TYPE;
1369             $printable[$i] = 0;
1370             $end = 0x81 if $i == 0x80;  # Hard-code this one known case
1371         }
1372         elsif ($gc-> table('Unassigned')->contains($i)) {
1373             $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1374             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1375             $printable[$i] = 0;
1376
1377             # Because we name the unassigned by the blocks they are in, it
1378             # can't go past the end of that block, and it also can't go past
1379             # the unassigned range it is in.  The special table makes sure
1380             # that the non-characters, which are unassigned, are separated
1381             # out.
1382             $end = min($block->containing_range($i)->end,
1383                        $unassigned_sans_noncharacters-> containing_range($i)->
1384                                                                          end);
1385         } else {
1386             my_carp_bug("Can't figure out how to annotate"
1387                         . sprintf("U+%04X", $i)
1388                         . "Proceeding anyway.");
1389             $viacode[$i] = 'UNKNOWN';
1390             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1391             $printable[$i] = 0;
1392         }
1393     }
1394
1395     # Here, has a name, but if it's one in which the code point number is
1396     # appended to the name, do that.
1397     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1398         $viacode[$i] .= sprintf("-%04X", $i);
1399         $end = $perl_charname->containing_range($i)->end;
1400     }
1401
1402     # And here, has a name, but if it's a hangul syllable one, replace it with
1403     # the correct name from the Unicode algorithm
1404     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1405         use integer;
1406         my $SIndex = $i - $SBase;
1407         my $L = $LBase + $SIndex / $NCount;
1408         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1409         my $T = $TBase + $SIndex % $TCount;
1410         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1411         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1412         $end = $perl_charname->containing_range($i)->end;
1413     }
1414
1415     return if ! defined wantarray;
1416     return $i if ! defined $end;    # If not a range, return the input
1417
1418     # Save this whole range so can find the end point quickly
1419     $annotate_ranges->add_map($i, $end, $end);
1420
1421     return $end;
1422 }
1423
1424 # Commented code below should work on Perl 5.8.
1425 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1426 ## the native perl version of it (which is what would operate under miniperl)
1427 ## is extremely slow, as it does a string eval every call.
1428 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1429 #                            && defined eval "require Scalar::Util";
1430 #
1431 #sub objaddr($) {
1432 #    # Returns the address of the blessed input object.  Uses the XS version if
1433 #    # available.  It doesn't check for blessedness because that would do a
1434 #    # string eval every call, and the program is structured so that this is
1435 #    # never called for a non-blessed object.
1436 #
1437 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1438 #
1439 #    # Check at least that is a ref.
1440 #    my $pkg = ref($_[0]) or return undef;
1441 #
1442 #    # Change to a fake package to defeat any overloaded stringify
1443 #    bless $_[0], 'main::Fake';
1444 #
1445 #    # Numifying a ref gives its address.
1446 #    my $addr = pack 'J', $_[0];
1447 #
1448 #    # Return to original class
1449 #    bless $_[0], $pkg;
1450 #    return $addr;
1451 #}
1452
1453 sub max ($$) {
1454     my $a = shift;
1455     my $b = shift;
1456     return $a if $a >= $b;
1457     return $b;
1458 }
1459
1460 sub min ($$) {
1461     my $a = shift;
1462     my $b = shift;
1463     return $a if $a <= $b;
1464     return $b;
1465 }
1466
1467 sub clarify_number ($) {
1468     # This returns the input number with underscores inserted every 3 digits
1469     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1470     # checked.
1471
1472     my $number = shift;
1473     my $pos = length($number) - 3;
1474     return $number if $pos <= 1;
1475     while ($pos > 0) {
1476         substr($number, $pos, 0) = '_';
1477         $pos -= 3;
1478     }
1479     return $number;
1480 }
1481
1482
1483 package Carp;
1484
1485 # These routines give a uniform treatment of messages in this program.  They
1486 # are placed in the Carp package to cause the stack trace to not include them,
1487 # although an alternative would be to use another package and set @CARP_NOT
1488 # for it.
1489
1490 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1491
1492 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1493 # and overload trying to load Scalar:Util under miniperl.  See
1494 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1495 undef $overload::VERSION;
1496
1497 sub my_carp {
1498     my $message = shift || "";
1499     my $nofold = shift || 0;
1500
1501     if ($message) {
1502         $message = main::join_lines($message);
1503         $message =~ s/^$0: *//;     # Remove initial program name
1504         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1505         $message = "\n$0: $message;";
1506
1507         # Fold the message with program name, semi-colon end punctuation
1508         # (which looks good with the message that carp appends to it), and a
1509         # hanging indent for continuation lines.
1510         $message = main::simple_fold($message, "", 4) unless $nofold;
1511         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1512                                     # appends is to the same line
1513     }
1514
1515     return $message if defined wantarray;   # If a caller just wants the msg
1516
1517     carp $message;
1518     return;
1519 }
1520
1521 sub my_carp_bug {
1522     # This is called when it is clear that the problem is caused by a bug in
1523     # this program.
1524
1525     my $message = shift;
1526     $message =~ s/^$0: *//;
1527     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1528     carp $message;
1529     return;
1530 }
1531
1532 sub carp_too_few_args {
1533     if (@_ != 2) {
1534         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1535         return;
1536     }
1537
1538     my $args_ref = shift;
1539     my $count = shift;
1540
1541     my_carp_bug("Need at least $count arguments to "
1542         . (caller 1)[3]
1543         . ".  Instead got: '"
1544         . join ', ', @$args_ref
1545         . "'.  No action taken.");
1546     return;
1547 }
1548
1549 sub carp_extra_args {
1550     my $args_ref = shift;
1551     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1552
1553     unless (ref $args_ref) {
1554         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1555         return;
1556     }
1557     my ($package, $file, $line) = caller;
1558     my $subroutine = (caller 1)[3];
1559
1560     my $list;
1561     if (ref $args_ref eq 'HASH') {
1562         foreach my $key (keys %$args_ref) {
1563             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1564         }
1565         $list = join ', ', each %{$args_ref};
1566     }
1567     elsif (ref $args_ref eq 'ARRAY') {
1568         foreach my $arg (@$args_ref) {
1569             $arg = $UNDEF unless defined $arg;
1570         }
1571         $list = join ', ', @$args_ref;
1572     }
1573     else {
1574         my_carp_bug("Can't cope with ref "
1575                 . ref($args_ref)
1576                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1577         return;
1578     }
1579
1580     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1581     return;
1582 }
1583
1584 package main;
1585
1586 { # Closure
1587
1588     # This program uses the inside-out method for objects, as recommended in
1589     # "Perl Best Practices".  This closure aids in generating those.  There
1590     # are two routines.  setup_package() is called once per package to set
1591     # things up, and then set_access() is called for each hash representing a
1592     # field in the object.  These routines arrange for the object to be
1593     # properly destroyed when no longer used, and for standard accessor
1594     # functions to be generated.  If you need more complex accessors, just
1595     # write your own and leave those accesses out of the call to set_access().
1596     # More details below.
1597
1598     my %constructor_fields; # fields that are to be used in constructors; see
1599                             # below
1600
1601     # The values of this hash will be the package names as keys to other
1602     # hashes containing the name of each field in the package as keys, and
1603     # references to their respective hashes as values.
1604     my %package_fields;
1605
1606     sub setup_package {
1607         # Sets up the package, creating standard DESTROY and dump methods
1608         # (unless already defined).  The dump method is used in debugging by
1609         # simple_dumper().
1610         # The optional parameters are:
1611         #   a)  a reference to a hash, that gets populated by later
1612         #       set_access() calls with one of the accesses being
1613         #       'constructor'.  The caller can then refer to this, but it is
1614         #       not otherwise used by these two routines.
1615         #   b)  a reference to a callback routine to call during destruction
1616         #       of the object, before any fields are actually destroyed
1617
1618         my %args = @_;
1619         my $constructor_ref = delete $args{'Constructor_Fields'};
1620         my $destroy_callback = delete $args{'Destroy_Callback'};
1621         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1622
1623         my %fields;
1624         my $package = (caller)[0];
1625
1626         $package_fields{$package} = \%fields;
1627         $constructor_fields{$package} = $constructor_ref;
1628
1629         unless ($package->can('DESTROY')) {
1630             my $destroy_name = "${package}::DESTROY";
1631             no strict "refs";
1632
1633             # Use typeglob to give the anonymous subroutine the name we want
1634             *$destroy_name = sub {
1635                 my $self = shift;
1636                 my $addr = do { no overloading; pack 'J', $self; };
1637
1638                 $self->$destroy_callback if $destroy_callback;
1639                 foreach my $field (keys %{$package_fields{$package}}) {
1640                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1641                     delete $package_fields{$package}{$field}{$addr};
1642                 }
1643                 return;
1644             }
1645         }
1646
1647         unless ($package->can('dump')) {
1648             my $dump_name = "${package}::dump";
1649             no strict "refs";
1650             *$dump_name = sub {
1651                 my $self = shift;
1652                 return dump_inside_out($self, $package_fields{$package}, @_);
1653             }
1654         }
1655         return;
1656     }
1657
1658     sub set_access {
1659         # Arrange for the input field to be garbage collected when no longer
1660         # needed.  Also, creates standard accessor functions for the field
1661         # based on the optional parameters-- none if none of these parameters:
1662         #   'addable'    creates an 'add_NAME()' accessor function.
1663         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1664         #                function.
1665         #   'settable'   creates a 'set_NAME()' accessor function.
1666         #   'constructor' doesn't create an accessor function, but adds the
1667         #                field to the hash that was previously passed to
1668         #                setup_package();
1669         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1670         # 'add' etc. all mean 'addable'.
1671         # The read accessor function will work on both array and scalar
1672         # values.  If another accessor in the parameter list is 'a', the read
1673         # access assumes an array.  You can also force it to be array access
1674         # by specifying 'readable_array' instead of 'readable'
1675         #
1676         # A sort-of 'protected' access can be set-up by preceding the addable,
1677         # readable or settable with some initial portion of 'protected_' (but,
1678         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1679         # "protection" is only by convention.  All that happens is that the
1680         # accessor functions' names begin with an underscore.  So instead of
1681         # calling set_foo, the call is _set_foo.  (Real protection could be
1682         # accomplished by having a new subroutine, end_package, called at the
1683         # end of each package, and then storing the __LINE__ ranges and
1684         # checking them on every accessor.  But that is way overkill.)
1685
1686         # We create anonymous subroutines as the accessors and then use
1687         # typeglobs to assign them to the proper package and name
1688
1689         my $name = shift;   # Name of the field
1690         my $field = shift;  # Reference to the inside-out hash containing the
1691                             # field
1692
1693         my $package = (caller)[0];
1694
1695         if (! exists $package_fields{$package}) {
1696             croak "$0: Must call 'setup_package' before 'set_access'";
1697         }
1698
1699         # Stash the field so DESTROY can get it.
1700         $package_fields{$package}{$name} = $field;
1701
1702         # Remaining arguments are the accessors.  For each...
1703         foreach my $access (@_) {
1704             my $access = lc $access;
1705
1706             my $protected = "";
1707
1708             # Match the input as far as it goes.
1709             if ($access =~ /^(p[^_]*)_/) {
1710                 $protected = $1;
1711                 if (substr('protected_', 0, length $protected)
1712                     eq $protected)
1713                 {
1714
1715                     # Add 1 for the underscore not included in $protected
1716                     $access = substr($access, length($protected) + 1);
1717                     $protected = '_';
1718                 }
1719                 else {
1720                     $protected = "";
1721                 }
1722             }
1723
1724             if (substr('addable', 0, length $access) eq $access) {
1725                 my $subname = "${package}::${protected}add_$name";
1726                 no strict "refs";
1727
1728                 # add_ accessor.  Don't add if already there, which we
1729                 # determine using 'eq' for scalars and '==' otherwise.
1730                 *$subname = sub {
1731                     use strict "refs";
1732                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1733                     my $self = shift;
1734                     my $value = shift;
1735                     my $addr = do { no overloading; pack 'J', $self; };
1736                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1737                     if (ref $value) {
1738                         return if grep { $value == $_ } @{$field->{$addr}};
1739                     }
1740                     else {
1741                         return if grep { $value eq $_ } @{$field->{$addr}};
1742                     }
1743                     push @{$field->{$addr}}, $value;
1744                     return;
1745                 }
1746             }
1747             elsif (substr('constructor', 0, length $access) eq $access) {
1748                 if ($protected) {
1749                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1750                 }
1751                 else {
1752                     $constructor_fields{$package}{$name} = $field;
1753                 }
1754             }
1755             elsif (substr('readable_array', 0, length $access) eq $access) {
1756
1757                 # Here has read access.  If one of the other parameters for
1758                 # access is array, or this one specifies array (by being more
1759                 # than just 'readable_'), then create a subroutine that
1760                 # assumes the data is an array.  Otherwise just a scalar
1761                 my $subname = "${package}::${protected}$name";
1762                 if (grep { /^a/i } @_
1763                     or length($access) > length('readable_'))
1764                 {
1765                     no strict "refs";
1766                     *$subname = sub {
1767                         use strict "refs";
1768                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1769                         my $addr = do { no overloading; pack 'J', $_[0]; };
1770                         if (ref $field->{$addr} ne 'ARRAY') {
1771                             my $type = ref $field->{$addr};
1772                             $type = 'scalar' unless $type;
1773                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1774                             return;
1775                         }
1776                         return scalar @{$field->{$addr}} unless wantarray;
1777
1778                         # Make a copy; had problems with caller modifying the
1779                         # original otherwise
1780                         my @return = @{$field->{$addr}};
1781                         return @return;
1782                     }
1783                 }
1784                 else {
1785
1786                     # Here not an array value, a simpler function.
1787                     no strict "refs";
1788                     *$subname = sub {
1789                         use strict "refs";
1790                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1791                         no overloading;
1792                         return $field->{pack 'J', $_[0]};
1793                     }
1794                 }
1795             }
1796             elsif (substr('settable', 0, length $access) eq $access) {
1797                 my $subname = "${package}::${protected}set_$name";
1798                 no strict "refs";
1799                 *$subname = sub {
1800                     use strict "refs";
1801                     if (main::DEBUG) {
1802                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1803                         Carp::carp_extra_args(\@_) if @_ > 2;
1804                     }
1805                     # $self is $_[0]; $value is $_[1]
1806                     no overloading;
1807                     $field->{pack 'J', $_[0]} = $_[1];
1808                     return;
1809                 }
1810             }
1811             else {
1812                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1813             }
1814         }
1815         return;
1816     }
1817 }
1818
1819 package Input_file;
1820
1821 # All input files use this object, which stores various attributes about them,
1822 # and provides for convenient, uniform handling.  The run method wraps the
1823 # processing.  It handles all the bookkeeping of opening, reading, and closing
1824 # the file, returning only significant input lines.
1825 #
1826 # Each object gets a handler which processes the body of the file, and is
1827 # called by run().  Most should use the generic, default handler, which has
1828 # code scrubbed to handle things you might not expect.  A handler should
1829 # basically be a while(next_line()) {...} loop.
1830 #
1831 # You can also set up handlers to
1832 #   1) call before the first line is read for pre processing
1833 #   2) call to adjust each line of the input before the main handler gets them
1834 #   3) call upon EOF before the main handler exits its loop
1835 #   4) call at the end for post processing
1836 #
1837 # $_ is used to store the input line, and is to be filtered by the
1838 # each_line_handler()s.  So, if the format of the line is not in the desired
1839 # format for the main handler, these are used to do that adjusting.  They can
1840 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1841 # so the $_ output of one is used as the input to the next.  None of the other
1842 # handlers are stackable, but could easily be changed to be so.
1843 #
1844 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1845 # which insert the parameters as lines to be processed before the next input
1846 # file line is read.  This allows the EOF handler to flush buffers, for
1847 # example.  The difference between the two routines is that the lines inserted
1848 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1849 # called it from such a handler, you would get infinite recursion.)  Lines
1850 # inserted by insert_adjusted_lines() go directly to the main handler without
1851 # any adjustments.  If the  post-processing handler calls any of these, there
1852 # will be no effect.  Some error checking for these conditions could be added,
1853 # but it hasn't been done.
1854 #
1855 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1856 # to prevent further processing of the line.  This routine will output the
1857 # message as a warning once, and then keep a count of the lines that have the
1858 # same message, and output that count at the end of the file's processing.
1859 # This keeps the number of messages down to a manageable amount.
1860 #
1861 # get_missings() should be called to retrieve any @missing input lines.
1862 # Messages will be raised if this isn't done if the options aren't to ignore
1863 # missings.
1864
1865 sub trace { return main::trace(@_); }
1866
1867 { # Closure
1868     # Keep track of fields that are to be put into the constructor.
1869     my %constructor_fields;
1870
1871     main::setup_package(Constructor_Fields => \%constructor_fields);
1872
1873     my %file; # Input file name, required
1874     main::set_access('file', \%file, qw{ c r });
1875
1876     my %first_released; # Unicode version file was first released in, required
1877     main::set_access('first_released', \%first_released, qw{ c r });
1878
1879     my %handler;    # Subroutine to process the input file, defaults to
1880                     # 'process_generic_property_file'
1881     main::set_access('handler', \%handler, qw{ c });
1882
1883     my %property;
1884     # name of property this file is for.  defaults to none, meaning not
1885     # applicable, or is otherwise determinable, for example, from each line.
1886     main::set_access('property', \%property, qw{ c });
1887
1888     my %optional;
1889     # If this is true, the file is optional.  If not present, no warning is
1890     # output.  If it is present, the string given by this parameter is
1891     # evaluated, and if false the file is not processed.
1892     main::set_access('optional', \%optional, 'c', 'r');
1893
1894     my %non_skip;
1895     # This is used for debugging, to skip processing of all but a few input
1896     # files.  Add 'non_skip => 1' to the constructor for those files you want
1897     # processed when you set the $debug_skip global.
1898     main::set_access('non_skip', \%non_skip, 'c');
1899
1900     my %skip;
1901     # This is used to skip processing of this input file semi-permanently.
1902     # It is used for files that we aren't planning to process anytime soon,
1903     # but want to allow to be in the directory and not raise a message that we
1904     # are not handling.  Mostly for test files.  This is in contrast to the
1905     # non_skip element, which is supposed to be used very temporarily for
1906     # debugging.  Sets 'optional' to 1
1907     main::set_access('skip', \%skip, 'c');
1908
1909     my %each_line_handler;
1910     # list of subroutines to look at and filter each non-comment line in the
1911     # file.  defaults to none.  The subroutines are called in order, each is
1912     # to adjust $_ for the next one, and the final one adjusts it for
1913     # 'handler'
1914     main::set_access('each_line_handler', \%each_line_handler, 'c');
1915
1916     my %has_missings_defaults;
1917     # ? Are there lines in the file giving default values for code points
1918     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1919     # the norm, but IGNORED means it has such lines, but the handler doesn't
1920     # use them.  Having these three states allows us to catch changes to the
1921     # UCD that this program should track
1922     main::set_access('has_missings_defaults',
1923                                         \%has_missings_defaults, qw{ c r });
1924
1925     my %pre_handler;
1926     # Subroutine to call before doing anything else in the file.  If undef, no
1927     # such handler is called.
1928     main::set_access('pre_handler', \%pre_handler, qw{ c });
1929
1930     my %eof_handler;
1931     # Subroutine to call upon getting an EOF on the input file, but before
1932     # that is returned to the main handler.  This is to allow buffers to be
1933     # flushed.  The handler is expected to call insert_lines() or
1934     # insert_adjusted() with the buffered material
1935     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1936
1937     my %post_handler;
1938     # Subroutine to call after all the lines of the file are read in and
1939     # processed.  If undef, no such handler is called.
1940     main::set_access('post_handler', \%post_handler, qw{ c });
1941
1942     my %progress_message;
1943     # Message to print to display progress in lieu of the standard one
1944     main::set_access('progress_message', \%progress_message, qw{ c });
1945
1946     my %handle;
1947     # cache open file handle, internal.  Is undef if file hasn't been
1948     # processed at all, empty if has;
1949     main::set_access('handle', \%handle);
1950
1951     my %added_lines;
1952     # cache of lines added virtually to the file, internal
1953     main::set_access('added_lines', \%added_lines);
1954
1955     my %errors;
1956     # cache of errors found, internal
1957     main::set_access('errors', \%errors);
1958
1959     my %missings;
1960     # storage of '@missing' defaults lines
1961     main::set_access('missings', \%missings);
1962
1963     sub new {
1964         my $class = shift;
1965
1966         my $self = bless \do{ my $anonymous_scalar }, $class;
1967         my $addr = do { no overloading; pack 'J', $self; };
1968
1969         # Set defaults
1970         $handler{$addr} = \&main::process_generic_property_file;
1971         $non_skip{$addr} = 0;
1972         $skip{$addr} = 0;
1973         $has_missings_defaults{$addr} = $NO_DEFAULTS;
1974         $handle{$addr} = undef;
1975         $added_lines{$addr} = [ ];
1976         $each_line_handler{$addr} = [ ];
1977         $errors{$addr} = { };
1978         $missings{$addr} = [ ];
1979
1980         # Two positional parameters.
1981         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1982         $file{$addr} = main::internal_file_to_platform(shift);
1983         $first_released{$addr} = shift;
1984
1985         # The rest of the arguments are key => value pairs
1986         # %constructor_fields has been set up earlier to list all possible
1987         # ones.  Either set or push, depending on how the default has been set
1988         # up just above.
1989         my %args = @_;
1990         foreach my $key (keys %args) {
1991             my $argument = $args{$key};
1992
1993             # Note that the fields are the lower case of the constructor keys
1994             my $hash = $constructor_fields{lc $key};
1995             if (! defined $hash) {
1996                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
1997                 next;
1998             }
1999             if (ref $hash->{$addr} eq 'ARRAY') {
2000                 if (ref $argument eq 'ARRAY') {
2001                     foreach my $argument (@{$argument}) {
2002                         next if ! defined $argument;
2003                         push @{$hash->{$addr}}, $argument;
2004                     }
2005                 }
2006                 else {
2007                     push @{$hash->{$addr}}, $argument if defined $argument;
2008                 }
2009             }
2010             else {
2011                 $hash->{$addr} = $argument;
2012             }
2013             delete $args{$key};
2014         };
2015
2016         # If the file has a property for it, it means that the property is not
2017         # listed in the file's entries.  So add a handler to the list of line
2018         # handlers to insert the property name into the lines, to provide a
2019         # uniform interface to the final processing subroutine.
2020         # the final code doesn't have to worry about that.
2021         if ($property{$addr}) {
2022             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2023         }
2024
2025         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2026             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2027         }
2028
2029         $optional{$addr} = 1 if $skip{$addr};
2030
2031         return $self;
2032     }
2033
2034
2035     use overload
2036         fallback => 0,
2037         qw("") => "_operator_stringify",
2038         "." => \&main::_operator_dot,
2039     ;
2040
2041     sub _operator_stringify {
2042         my $self = shift;
2043
2044         return __PACKAGE__ . " object for " . $self->file;
2045     }
2046
2047     # flag to make sure extracted files are processed early
2048     my $seen_non_extracted_non_age = 0;
2049
2050     sub run {
2051         # Process the input object $self.  This opens and closes the file and
2052         # calls all the handlers for it.  Currently,  this can only be called
2053         # once per file, as it destroy's the EOF handler
2054
2055         my $self = shift;
2056         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2057
2058         my $addr = do { no overloading; pack 'J', $self; };
2059
2060         my $file = $file{$addr};
2061
2062         # Don't process if not expecting this file (because released later
2063         # than this Unicode version), and isn't there.  This means if someone
2064         # copies it into an earlier version's directory, we will go ahead and
2065         # process it.
2066         return if $first_released{$addr} gt $v_version && ! -e $file;
2067
2068         # If in debugging mode and this file doesn't have the non-skip
2069         # flag set, and isn't one of the critical files, skip it.
2070         if ($debug_skip
2071             && $first_released{$addr} ne v0
2072             && ! $non_skip{$addr})
2073         {
2074             print "Skipping $file in debugging\n" if $verbosity;
2075             return;
2076         }
2077
2078         # File could be optional
2079         if ($optional{$addr}) {
2080             return unless -e $file;
2081             my $result = eval $optional{$addr};
2082             if (! defined $result) {
2083                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2084                 return;
2085             }
2086             if (! $result) {
2087                 if ($verbosity) {
2088                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2089                 }
2090                 return;
2091             }
2092         }
2093
2094         if (! defined $file || ! -e $file) {
2095
2096             # If the file doesn't exist, see if have internal data for it
2097             # (based on first_released being 0).
2098             if ($first_released{$addr} eq v0) {
2099                 $handle{$addr} = 'pretend_is_open';
2100             }
2101             else {
2102                 if (! $optional{$addr}  # File could be optional
2103                     && $v_version ge $first_released{$addr})
2104                 {
2105                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2106                 }
2107                 return;
2108             }
2109         }
2110         else {
2111
2112             # Here, the file exists.  Some platforms may change the case of
2113             # its name
2114             if ($seen_non_extracted_non_age) {
2115                 if ($file =~ /$EXTRACTED/i) {
2116                     Carp::my_carp_bug(join_lines(<<END
2117 $file should be processed just after the 'Prop...Alias' files, and before
2118 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2119 have subtle problems
2120 END
2121                     ));
2122                 }
2123             }
2124             elsif ($EXTRACTED_DIR
2125                     && $first_released{$addr} ne v0
2126                     && $file !~ /$EXTRACTED/i
2127                     && lc($file) ne 'dage.txt')
2128             {
2129                 # We don't set this (by the 'if' above) if we have no
2130                 # extracted directory, so if running on an early version,
2131                 # this test won't work.  Not worth worrying about.
2132                 $seen_non_extracted_non_age = 1;
2133             }
2134
2135             # And mark the file as having being processed, and warn if it
2136             # isn't a file we are expecting.  As we process the files,
2137             # they are deleted from the hash, so any that remain at the
2138             # end of the program are files that we didn't process.
2139             my $fkey = File::Spec->rel2abs($file);
2140             my $expecting = delete $potential_files{$fkey};
2141             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
2142             Carp::my_carp("Was not expecting '$file'.") if
2143                     ! $expecting
2144                     && ! defined $handle{$addr};
2145
2146             # Having deleted from expected files, we can quit if not to do
2147             # anything.  Don't print progress unless really want verbosity
2148             if ($skip{$addr}) {
2149                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2150                 return;
2151             }
2152
2153             # Open the file, converting the slashes used in this program
2154             # into the proper form for the OS
2155             my $file_handle;
2156             if (not open $file_handle, "<", $file) {
2157                 Carp::my_carp("Can't open $file.  Skipping: $!");
2158                 return 0;
2159             }
2160             $handle{$addr} = $file_handle; # Cache the open file handle
2161         }
2162
2163         if ($verbosity >= $PROGRESS) {
2164             if ($progress_message{$addr}) {
2165                 print "$progress_message{$addr}\n";
2166             }
2167             else {
2168                 # If using a virtual file, say so.
2169                 print "Processing ", (-e $file)
2170                                        ? $file
2171                                        : "substitute $file",
2172                                      "\n";
2173             }
2174         }
2175
2176
2177         # Call any special handler for before the file.
2178         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2179
2180         # Then the main handler
2181         &{$handler{$addr}}($self);
2182
2183         # Then any special post-file handler.
2184         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2185
2186         # If any errors have been accumulated, output the counts (as the first
2187         # error message in each class was output when it was encountered).
2188         if ($errors{$addr}) {
2189             my $total = 0;
2190             my $types = 0;
2191             foreach my $error (keys %{$errors{$addr}}) {
2192                 $total += $errors{$addr}->{$error};
2193                 delete $errors{$addr}->{$error};
2194                 $types++;
2195             }
2196             if ($total > 1) {
2197                 my $message
2198                         = "A total of $total lines had errors in $file.  ";
2199
2200                 $message .= ($types == 1)
2201                             ? '(Only the first one was displayed.)'
2202                             : '(Only the first of each type was displayed.)';
2203                 Carp::my_carp($message);
2204             }
2205         }
2206
2207         if (@{$missings{$addr}}) {
2208             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2209         }
2210
2211         # If a real file handle, close it.
2212         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2213                                                         ref $handle{$addr};
2214         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2215                                # the file, as opposed to undef
2216         return;
2217     }
2218
2219     sub next_line {
2220         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2221         # if such a line exists.  'logical' means that any lines that have
2222         # been added via insert_lines() will be returned in $_ before the file
2223         # is read again.
2224
2225         my $self = shift;
2226         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2227
2228         my $addr = do { no overloading; pack 'J', $self; };
2229
2230         # Here the file is open (or if the handle is not a ref, is an open
2231         # 'virtual' file).  Get the next line; any inserted lines get priority
2232         # over the file itself.
2233         my $adjusted;
2234
2235         LINE:
2236         while (1) { # Loop until find non-comment, non-empty line
2237             #local $to_trace = 1 if main::DEBUG;
2238             my $inserted_ref = shift @{$added_lines{$addr}};
2239             if (defined $inserted_ref) {
2240                 ($adjusted, $_) = @{$inserted_ref};
2241                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2242                 return 1 if $adjusted;
2243             }
2244             else {
2245                 last if ! ref $handle{$addr}; # Don't read unless is real file
2246                 last if ! defined ($_ = readline $handle{$addr});
2247             }
2248             chomp;
2249             trace $_ if main::DEBUG && $to_trace;
2250
2251             # See if this line is the comment line that defines what property
2252             # value that code points that are not listed in the file should
2253             # have.  The format or existence of these lines is not guaranteed
2254             # by Unicode since they are comments, but the documentation says
2255             # that this was added for machine-readability, so probably won't
2256             # change.  This works starting in Unicode Version 5.0.  They look
2257             # like:
2258             #
2259             # @missing: 0000..10FFFF; Not_Reordered
2260             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2261             # @missing: 0000..10FFFF; ; NaN
2262             #
2263             # Save the line for a later get_missings() call.
2264             if (/$missing_defaults_prefix/) {
2265                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2266                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2267                 }
2268                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2269                     my @defaults = split /\s* ; \s*/x, $_;
2270
2271                     # The first field is the @missing, which ends in a
2272                     # semi-colon, so can safely shift.
2273                     shift @defaults;
2274
2275                     # Some of these lines may have empty field placeholders
2276                     # which get in the way.  An example is:
2277                     # @missing: 0000..10FFFF; ; NaN
2278                     # Remove them.  Process starting from the top so the
2279                     # splice doesn't affect things still to be looked at.
2280                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2281                         next if $defaults[$i] ne "";
2282                         splice @defaults, $i, 1;
2283                     }
2284
2285                     # What's left should be just the property (maybe) and the
2286                     # default.  Having only one element means it doesn't have
2287                     # the property.
2288                     my $default;
2289                     my $property;
2290                     if (@defaults >= 1) {
2291                         if (@defaults == 1) {
2292                             $default = $defaults[0];
2293                         }
2294                         else {
2295                             $property = $defaults[0];
2296                             $default = $defaults[1];
2297                         }
2298                     }
2299
2300                     if (@defaults < 1
2301                         || @defaults > 2
2302                         || ($default =~ /^</
2303                             && $default !~ /^<code *point>$/i
2304                             && $default !~ /^<none>$/i))
2305                     {
2306                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2307                     }
2308                     else {
2309
2310                         # If the property is missing from the line, it should
2311                         # be the one for the whole file
2312                         $property = $property{$addr} if ! defined $property;
2313
2314                         # Change <none> to the null string, which is what it
2315                         # really means.  If the default is the code point
2316                         # itself, set it to <code point>, which is what
2317                         # Unicode uses (but sometimes they've forgotten the
2318                         # space)
2319                         if ($default =~ /^<none>$/i) {
2320                             $default = "";
2321                         }
2322                         elsif ($default =~ /^<code *point>$/i) {
2323                             $default = $CODE_POINT;
2324                         }
2325
2326                         # Store them as a sub-arrays with both components.
2327                         push @{$missings{$addr}}, [ $default, $property ];
2328                     }
2329                 }
2330
2331                 # There is nothing for the caller to process on this comment
2332                 # line.
2333                 next;
2334             }
2335
2336             # Remove comments and trailing space, and skip this line if the
2337             # result is empty
2338             s/#.*//;
2339             s/\s+$//;
2340             next if /^$/;
2341
2342             # Call any handlers for this line, and skip further processing of
2343             # the line if the handler sets the line to null.
2344             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2345                 &{$sub_ref}($self);
2346                 next LINE if /^$/;
2347             }
2348
2349             # Here the line is ok.  return success.
2350             return 1;
2351         } # End of looping through lines.
2352
2353         # If there is an EOF handler, call it (only once) and if it generates
2354         # more lines to process go back in the loop to handle them.
2355         if ($eof_handler{$addr}) {
2356             &{$eof_handler{$addr}}($self);
2357             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2358             goto LINE if $added_lines{$addr};
2359         }
2360
2361         # Return failure -- no more lines.
2362         return 0;
2363
2364     }
2365
2366 #   Not currently used, not fully tested.
2367 #    sub peek {
2368 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2369 #        # record.  Not callable from an each_line_handler(), nor does it call
2370 #        # an each_line_handler() on the line.
2371 #
2372 #        my $self = shift;
2373 #        my $addr = do { no overloading; pack 'J', $self; };
2374 #
2375 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2376 #            my ($adjusted, $line) = @{$inserted_ref};
2377 #            next if $adjusted;
2378 #
2379 #            # Remove comments and trailing space, and return a non-empty
2380 #            # resulting line
2381 #            $line =~ s/#.*//;
2382 #            $line =~ s/\s+$//;
2383 #            return $line if $line ne "";
2384 #        }
2385 #
2386 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2387 #        while (1) { # Loop until find non-comment, non-empty line
2388 #            local $to_trace = 1 if main::DEBUG;
2389 #            trace $_ if main::DEBUG && $to_trace;
2390 #            return if ! defined (my $line = readline $handle{$addr});
2391 #            chomp $line;
2392 #            push @{$added_lines{$addr}}, [ 0, $line ];
2393 #
2394 #            $line =~ s/#.*//;
2395 #            $line =~ s/\s+$//;
2396 #            return $line if $line ne "";
2397 #        }
2398 #
2399 #        return;
2400 #    }
2401
2402
2403     sub insert_lines {
2404         # Lines can be inserted so that it looks like they were in the input
2405         # file at the place it was when this routine is called.  See also
2406         # insert_adjusted_lines().  Lines inserted via this routine go through
2407         # any each_line_handler()
2408
2409         my $self = shift;
2410
2411         # Each inserted line is an array, with the first element being 0 to
2412         # indicate that this line hasn't been adjusted, and needs to be
2413         # processed.
2414         no overloading;
2415         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2416         return;
2417     }
2418
2419     sub insert_adjusted_lines {
2420         # Lines can be inserted so that it looks like they were in the input
2421         # file at the place it was when this routine is called.  See also
2422         # insert_lines().  Lines inserted via this routine are already fully
2423         # adjusted, ready to be processed; each_line_handler()s handlers will
2424         # not be called.  This means this is not a completely general
2425         # facility, as only the last each_line_handler on the stack should
2426         # call this.  It could be made more general, by passing to each of the
2427         # line_handlers their position on the stack, which they would pass on
2428         # to this routine, and that would replace the boolean first element in
2429         # the anonymous array pushed here, so that the next_line routine could
2430         # use that to call only those handlers whose index is after it on the
2431         # stack.  But this is overkill for what is needed now.
2432
2433         my $self = shift;
2434         trace $_[0] if main::DEBUG && $to_trace;
2435
2436         # Each inserted line is an array, with the first element being 1 to
2437         # indicate that this line has been adjusted
2438         no overloading;
2439         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2440         return;
2441     }
2442
2443     sub get_missings {
2444         # Returns the stored up @missings lines' values, and clears the list.
2445         # The values are in an array, consisting of the default in the first
2446         # element, and the property in the 2nd.  However, since these lines
2447         # can be stacked up, the return is an array of all these arrays.
2448
2449         my $self = shift;
2450         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2451
2452         my $addr = do { no overloading; pack 'J', $self; };
2453
2454         # If not accepting a list return, just return the first one.
2455         return shift @{$missings{$addr}} unless wantarray;
2456
2457         my @return = @{$missings{$addr}};
2458         undef @{$missings{$addr}};
2459         return @return;
2460     }
2461
2462     sub _insert_property_into_line {
2463         # Add a property field to $_, if this file requires it.
2464
2465         my $self = shift;
2466         my $addr = do { no overloading; pack 'J', $self; };
2467         my $property = $property{$addr};
2468         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2469
2470         $_ =~ s/(;|$)/; $property$1/;
2471         return;
2472     }
2473
2474     sub carp_bad_line {
2475         # Output consistent error messages, using either a generic one, or the
2476         # one given by the optional parameter.  To avoid gazillions of the
2477         # same message in case the syntax of a  file is way off, this routine
2478         # only outputs the first instance of each message, incrementing a
2479         # count so the totals can be output at the end of the file.
2480
2481         my $self = shift;
2482         my $message = shift;
2483         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2484
2485         my $addr = do { no overloading; pack 'J', $self; };
2486
2487         $message = 'Unexpected line' unless $message;
2488
2489         # No trailing punctuation so as to fit with our addenda.
2490         $message =~ s/[.:;,]$//;
2491
2492         # If haven't seen this exact message before, output it now.  Otherwise
2493         # increment the count of how many times it has occurred
2494         unless ($errors{$addr}->{$message}) {
2495             Carp::my_carp("$message in '$_' in "
2496                             . $file{$addr}
2497                             . " at line $..  Skipping this line;");
2498             $errors{$addr}->{$message} = 1;
2499         }
2500         else {
2501             $errors{$addr}->{$message}++;
2502         }
2503
2504         # Clear the line to prevent any further (meaningful) processing of it.
2505         $_ = "";
2506
2507         return;
2508     }
2509 } # End closure
2510
2511 package Multi_Default;
2512
2513 # Certain properties in early versions of Unicode had more than one possible
2514 # default for code points missing from the files.  In these cases, one
2515 # default applies to everything left over after all the others are applied,
2516 # and for each of the others, there is a description of which class of code
2517 # points applies to it.  This object helps implement this by storing the
2518 # defaults, and for all but that final default, an eval string that generates
2519 # the class that it applies to.
2520
2521
2522 {   # Closure
2523
2524     main::setup_package();
2525
2526     my %class_defaults;
2527     # The defaults structure for the classes
2528     main::set_access('class_defaults', \%class_defaults);
2529
2530     my %other_default;
2531     # The default that applies to everything left over.
2532     main::set_access('other_default', \%other_default, 'r');
2533
2534
2535     sub new {
2536         # The constructor is called with default => eval pairs, terminated by
2537         # the left-over default. e.g.
2538         # Multi_Default->new(
2539         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2540         #               -  0x200D',
2541         #        'R' => 'some other expression that evaluates to code points',
2542         #        .
2543         #        .
2544         #        .
2545         #        'U'));
2546
2547         my $class = shift;
2548
2549         my $self = bless \do{my $anonymous_scalar}, $class;
2550         my $addr = do { no overloading; pack 'J', $self; };
2551
2552         while (@_ > 1) {
2553             my $default = shift;
2554             my $eval = shift;
2555             $class_defaults{$addr}->{$default} = $eval;
2556         }
2557
2558         $other_default{$addr} = shift;
2559
2560         return $self;
2561     }
2562
2563     sub get_next_defaults {
2564         # Iterates and returns the next class of defaults.
2565         my $self = shift;
2566         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2567
2568         my $addr = do { no overloading; pack 'J', $self; };
2569
2570         return each %{$class_defaults{$addr}};
2571     }
2572 }
2573
2574 package Alias;
2575
2576 # An alias is one of the names that a table goes by.  This class defines them
2577 # including some attributes.  Everything is currently setup in the
2578 # constructor.
2579
2580
2581 {   # Closure
2582
2583     main::setup_package();
2584
2585     my %name;
2586     main::set_access('name', \%name, 'r');
2587
2588     my %loose_match;
2589     # Determined by the constructor code if this name should match loosely or
2590     # not.  The constructor parameters can override this, but it isn't fully
2591     # implemented, as should have ability to override Unicode one's via
2592     # something like a set_loose_match()
2593     main::set_access('loose_match', \%loose_match, 'r');
2594
2595     my %make_pod_entry;
2596     # Some aliases should not get their own entries because they are covered
2597     # by a wild-card, and some we want to discourage use of.  Binary
2598     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2599
2600     my %status;
2601     # Aliases have a status, like deprecated, or even suppressed (which means
2602     # they don't appear in documentation).  Enum
2603     main::set_access('status', \%status, 'r');
2604
2605     my %externally_ok;
2606     # Similarly, some aliases should not be considered as usable ones for
2607     # external use, such as file names, or we don't want documentation to
2608     # recommend them.  Boolean
2609     main::set_access('externally_ok', \%externally_ok, 'r');
2610
2611     sub new {
2612         my $class = shift;
2613
2614         my $self = bless \do { my $anonymous_scalar }, $class;
2615         my $addr = do { no overloading; pack 'J', $self; };
2616
2617         $name{$addr} = shift;
2618         $loose_match{$addr} = shift;
2619         $make_pod_entry{$addr} = shift;
2620         $externally_ok{$addr} = shift;
2621         $status{$addr} = shift;
2622
2623         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2624
2625         # Null names are never ok externally
2626         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2627
2628         return $self;
2629     }
2630 }
2631
2632 package Range;
2633
2634 # A range is the basic unit for storing code points, and is described in the
2635 # comments at the beginning of the program.  Each range has a starting code
2636 # point; an ending code point (not less than the starting one); a value
2637 # that applies to every code point in between the two end-points, inclusive;
2638 # and an enum type that applies to the value.  The type is for the user's
2639 # convenience, and has no meaning here, except that a non-zero type is
2640 # considered to not obey the normal Unicode rules for having standard forms.
2641 #
2642 # The same structure is used for both map and match tables, even though in the
2643 # latter, the value (and hence type) is irrelevant and could be used as a
2644 # comment.  In map tables, the value is what all the code points in the range
2645 # map to.  Type 0 values have the standardized version of the value stored as
2646 # well, so as to not have to recalculate it a lot.
2647
2648 sub trace { return main::trace(@_); }
2649
2650 {   # Closure
2651
2652     main::setup_package();
2653
2654     my %start;
2655     main::set_access('start', \%start, 'r', 's');
2656
2657     my %end;
2658     main::set_access('end', \%end, 'r', 's');
2659
2660     my %value;
2661     main::set_access('value', \%value, 'r');
2662
2663     my %type;
2664     main::set_access('type', \%type, 'r');
2665
2666     my %standard_form;
2667     # The value in internal standard form.  Defined only if the type is 0.
2668     main::set_access('standard_form', \%standard_form);
2669
2670     # Note that if these fields change, the dump() method should as well
2671
2672     sub new {
2673         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2674         my $class = shift;
2675
2676         my $self = bless \do { my $anonymous_scalar }, $class;
2677         my $addr = do { no overloading; pack 'J', $self; };
2678
2679         $start{$addr} = shift;
2680         $end{$addr} = shift;
2681
2682         my %args = @_;
2683
2684         my $value = delete $args{'Value'};  # Can be 0
2685         $value = "" unless defined $value;
2686         $value{$addr} = $value;
2687
2688         $type{$addr} = delete $args{'Type'} || 0;
2689
2690         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2691
2692         if (! $type{$addr}) {
2693             $standard_form{$addr} = main::standardize($value);
2694         }
2695
2696         return $self;
2697     }
2698
2699     use overload
2700         fallback => 0,
2701         qw("") => "_operator_stringify",
2702         "." => \&main::_operator_dot,
2703     ;
2704
2705     sub _operator_stringify {
2706         my $self = shift;
2707         my $addr = do { no overloading; pack 'J', $self; };
2708
2709         # Output it like '0041..0065 (value)'
2710         my $return = sprintf("%04X", $start{$addr})
2711                         .  '..'
2712                         . sprintf("%04X", $end{$addr});
2713         my $value = $value{$addr};
2714         my $type = $type{$addr};
2715         $return .= ' (';
2716         $return .= "$value";
2717         $return .= ", Type=$type" if $type != 0;
2718         $return .= ')';
2719
2720         return $return;
2721     }
2722
2723     sub standard_form {
2724         # The standard form is the value itself if the standard form is
2725         # undefined (that is if the value is special)
2726
2727         my $self = shift;
2728         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2729
2730         my $addr = do { no overloading; pack 'J', $self; };
2731
2732         return $standard_form{$addr} if defined $standard_form{$addr};
2733         return $value{$addr};
2734     }
2735
2736     sub dump {
2737         # Human, not machine readable.  For machine readable, comment out this
2738         # entire routine and let the standard one take effect.
2739         my $self = shift;
2740         my $indent = shift;
2741         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2742
2743         my $addr = do { no overloading; pack 'J', $self; };
2744
2745         my $return = $indent
2746                     . sprintf("%04X", $start{$addr})
2747                     . '..'
2748                     . sprintf("%04X", $end{$addr})
2749                     . " '$value{$addr}';";
2750         if (! defined $standard_form{$addr}) {
2751             $return .= "(type=$type{$addr})";
2752         }
2753         elsif ($standard_form{$addr} ne $value{$addr}) {
2754             $return .= "(standard '$standard_form{$addr}')";
2755         }
2756         return $return;
2757     }
2758 } # End closure
2759
2760 package _Range_List_Base;
2761
2762 # Base class for range lists.  A range list is simply an ordered list of
2763 # ranges, so that the ranges with the lowest starting numbers are first in it.
2764 #
2765 # When a new range is added that is adjacent to an existing range that has the
2766 # same value and type, it merges with it to form a larger range.
2767 #
2768 # Ranges generally do not overlap, except that there can be multiple entries
2769 # of single code point ranges.  This is because of NameAliases.txt.
2770 #
2771 # In this program, there is a standard value such that if two different
2772 # values, have the same standard value, they are considered equivalent.  This
2773 # value was chosen so that it gives correct results on Unicode data
2774
2775 # There are a number of methods to manipulate range lists, and some operators
2776 # are overloaded to handle them.
2777
2778 sub trace { return main::trace(@_); }
2779
2780 { # Closure
2781
2782     our $addr;
2783
2784     main::setup_package();
2785
2786     my %ranges;
2787     # The list of ranges
2788     main::set_access('ranges', \%ranges, 'readable_array');
2789
2790     my %max;
2791     # The highest code point in the list.  This was originally a method, but
2792     # actual measurements said it was used a lot.
2793     main::set_access('max', \%max, 'r');
2794
2795     my %each_range_iterator;
2796     # Iterator position for each_range()
2797     main::set_access('each_range_iterator', \%each_range_iterator);
2798
2799     my %owner_name_of;
2800     # Name of parent this is attached to, if any.  Solely for better error
2801     # messages.
2802     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2803
2804     my %_search_ranges_cache;
2805     # A cache of the previous result from _search_ranges(), for better
2806     # performance
2807     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2808
2809     sub new {
2810         my $class = shift;
2811         my %args = @_;
2812
2813         # Optional initialization data for the range list.
2814         my $initialize = delete $args{'Initialize'};
2815
2816         my $self;
2817
2818         # Use _union() to initialize.  _union() returns an object of this
2819         # class, which means that it will call this constructor recursively.
2820         # But it won't have this $initialize parameter so that it won't
2821         # infinitely loop on this.
2822         return _union($class, $initialize, %args) if defined $initialize;
2823
2824         $self = bless \do { my $anonymous_scalar }, $class;
2825         my $addr = do { no overloading; pack 'J', $self; };
2826
2827         # Optional parent object, only for debug info.
2828         $owner_name_of{$addr} = delete $args{'Owner'};
2829         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2830
2831         # Stringify, in case it is an object.
2832         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2833
2834         # This is used only for error messages, and so a colon is added
2835         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2836
2837         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2838
2839         # Max is initialized to a negative value that isn't adjacent to 0,
2840         # for simpler tests
2841         $max{$addr} = -2;
2842
2843         $_search_ranges_cache{$addr} = 0;
2844         $ranges{$addr} = [];
2845
2846         return $self;
2847     }
2848
2849     use overload
2850         fallback => 0,
2851         qw("") => "_operator_stringify",
2852         "." => \&main::_operator_dot,
2853     ;
2854
2855     sub _operator_stringify {
2856         my $self = shift;
2857         my $addr = do { no overloading; pack 'J', $self; };
2858
2859         return "Range_List attached to '$owner_name_of{$addr}'"
2860                                                 if $owner_name_of{$addr};
2861         return "anonymous Range_List " . \$self;
2862     }
2863
2864     sub _union {
2865         # Returns the union of the input code points.  It can be called as
2866         # either a constructor or a method.  If called as a method, the result
2867         # will be a new() instance of the calling object, containing the union
2868         # of that object with the other parameter's code points;  if called as
2869         # a constructor, the first parameter gives the class the new object
2870         # should be, and the second parameter gives the code points to go into
2871         # it.
2872         # In either case, there are two parameters looked at by this routine;
2873         # any additional parameters are passed to the new() constructor.
2874         #
2875         # The code points can come in the form of some object that contains
2876         # ranges, and has a conventionally named method to access them; or
2877         # they can be an array of individual code points (as integers); or
2878         # just a single code point.
2879         #
2880         # If they are ranges, this routine doesn't make any effort to preserve
2881         # the range values of one input over the other.  Therefore this base
2882         # class should not allow _union to be called from other than
2883         # initialization code, so as to prevent two tables from being added
2884         # together where the range values matter.  The general form of this
2885         # routine therefore belongs in a derived class, but it was moved here
2886         # to avoid duplication of code.  The failure to overload this in this
2887         # class keeps it safe.
2888         #
2889
2890         my $self;
2891         my @args;   # Arguments to pass to the constructor
2892
2893         my $class = shift;
2894
2895         # If a method call, will start the union with the object itself, and
2896         # the class of the new object will be the same as self.
2897         if (ref $class) {
2898             $self = $class;
2899             $class = ref $self;
2900             push @args, $self;
2901         }
2902
2903         # Add the other required parameter.
2904         push @args, shift;
2905         # Rest of parameters are passed on to the constructor
2906
2907         # Accumulate all records from both lists.
2908         my @records;
2909         for my $arg (@args) {
2910             #local $to_trace = 0 if main::DEBUG;
2911             trace "argument = $arg" if main::DEBUG && $to_trace;
2912             if (! defined $arg) {
2913                 my $message = "";
2914                 if (defined $self) {
2915                     no overloading;
2916                     $message .= $owner_name_of{pack 'J', $self};
2917                 }
2918                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2919                 return;
2920             }
2921             $arg = [ $arg ] if ! ref $arg;
2922             my $type = ref $arg;
2923             if ($type eq 'ARRAY') {
2924                 foreach my $element (@$arg) {
2925                     push @records, Range->new($element, $element);
2926                 }
2927             }
2928             elsif ($arg->isa('Range')) {
2929                 push @records, $arg;
2930             }
2931             elsif ($arg->can('ranges')) {
2932                 push @records, $arg->ranges;
2933             }
2934             else {
2935                 my $message = "";
2936                 if (defined $self) {
2937                     no overloading;
2938                     $message .= $owner_name_of{pack 'J', $self};
2939                 }
2940                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2941                 return;
2942             }
2943         }
2944
2945         # Sort with the range containing the lowest ordinal first, but if
2946         # two ranges start at the same code point, sort with the bigger range
2947         # of the two first, because it takes fewer cycles.
2948         @records = sort { ($a->start <=> $b->start)
2949                                       or
2950                                     # if b is shorter than a, b->end will be
2951                                     # less than a->end, and we want to select
2952                                     # a, so want to return -1
2953                                     ($b->end <=> $a->end)
2954                                    } @records;
2955
2956         my $new = $class->new(@_);
2957
2958         # Fold in records so long as they add new information.
2959         for my $set (@records) {
2960             my $start = $set->start;
2961             my $end   = $set->end;
2962             my $value   = $set->value;
2963             if ($start > $new->max) {
2964                 $new->_add_delete('+', $start, $end, $value);
2965             }
2966             elsif ($end > $new->max) {
2967                 $new->_add_delete('+', $new->max +1, $end, $value);
2968             }
2969         }
2970
2971         return $new;
2972     }
2973
2974     sub range_count {        # Return the number of ranges in the range list
2975         my $self = shift;
2976         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2977
2978         no overloading;
2979         return scalar @{$ranges{pack 'J', $self}};
2980     }
2981
2982     sub min {
2983         # Returns the minimum code point currently in the range list, or if
2984         # the range list is empty, 2 beyond the max possible.  This is a
2985         # method because used so rarely, that not worth saving between calls,
2986         # and having to worry about changing it as ranges are added and
2987         # deleted.
2988
2989         my $self = shift;
2990         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2991
2992         my $addr = do { no overloading; pack 'J', $self; };
2993
2994         # If the range list is empty, return a large value that isn't adjacent
2995         # to any that could be in the range list, for simpler tests
2996         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
2997         return $ranges{$addr}->[0]->start;
2998     }
2999
3000     sub contains {
3001         # Boolean: Is argument in the range list?  If so returns $i such that:
3002         #   range[$i]->end < $codepoint <= range[$i+1]->end
3003         # which is one beyond what you want; this is so that the 0th range
3004         # doesn't return false
3005         my $self = shift;
3006         my $codepoint = shift;
3007         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3008
3009         my $i = $self->_search_ranges($codepoint);
3010         return 0 unless defined $i;
3011
3012         # The search returns $i, such that
3013         #   range[$i-1]->end < $codepoint <= range[$i]->end
3014         # So is in the table if and only iff it is at least the start position
3015         # of range $i.
3016         no overloading;
3017         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3018         return $i + 1;
3019     }
3020
3021     sub containing_range {
3022         # Returns the range object that contains the code point, undef if none
3023
3024         my $self = shift;
3025         my $codepoint = shift;
3026         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3027
3028         my $i = $self->contains($codepoint);
3029         return unless $i;
3030
3031         # contains() returns 1 beyond where we should look
3032         no overloading;
3033         return $ranges{pack 'J', $self}->[$i-1];
3034     }
3035
3036     sub value_of {
3037         # Returns the value associated with the code point, undef if none
3038
3039         my $self = shift;
3040         my $codepoint = shift;
3041         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3042
3043         my $range = $self->containing_range($codepoint);
3044         return unless defined $range;
3045
3046         return $range->value;
3047     }
3048
3049     sub type_of {
3050         # Returns the type of the range containing the code point, undef if
3051         # the code point is not in the table
3052
3053         my $self = shift;
3054         my $codepoint = shift;
3055         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3056
3057         my $range = $self->containing_range($codepoint);
3058         return unless defined $range;
3059
3060         return $range->type;
3061     }
3062
3063     sub _search_ranges {
3064         # Find the range in the list which contains a code point, or where it
3065         # should go if were to add it.  That is, it returns $i, such that:
3066         #   range[$i-1]->end < $codepoint <= range[$i]->end
3067         # Returns undef if no such $i is possible (e.g. at end of table), or
3068         # if there is an error.
3069
3070         my $self = shift;
3071         my $code_point = shift;
3072         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3073
3074         my $addr = do { no overloading; pack 'J', $self; };
3075
3076         return if $code_point > $max{$addr};
3077         my $r = $ranges{$addr};                # The current list of ranges
3078         my $range_list_size = scalar @$r;
3079         my $i;
3080
3081         use integer;        # want integer division
3082
3083         # Use the cached result as the starting guess for this one, because,
3084         # an experiment on 5.1 showed that 90% of the time the cache was the
3085         # same as the result on the next call (and 7% it was one less).
3086         $i = $_search_ranges_cache{$addr};
3087         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3088                                             # from an intervening deletion
3089         #local $to_trace = 1 if main::DEBUG;
3090         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3091         return $i if $code_point <= $r->[$i]->end
3092                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3093
3094         # Here the cache doesn't yield the correct $i.  Try adding 1.
3095         if ($i < $range_list_size - 1
3096             && $r->[$i]->end < $code_point &&
3097             $code_point <= $r->[$i+1]->end)
3098         {
3099             $i++;
3100             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3101             $_search_ranges_cache{$addr} = $i;
3102             return $i;
3103         }
3104
3105         # Here, adding 1 also didn't work.  We do a binary search to
3106         # find the correct position, starting with current $i
3107         my $lower = 0;
3108         my $upper = $range_list_size - 1;
3109         while (1) {
3110             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3111
3112             if ($code_point <= $r->[$i]->end) {
3113
3114                 # Here we have met the upper constraint.  We can quit if we
3115                 # also meet the lower one.
3116                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3117
3118                 $upper = $i;        # Still too high.
3119
3120             }
3121             else {
3122
3123                 # Here, $r[$i]->end < $code_point, so look higher up.
3124                 $lower = $i;
3125             }
3126
3127             # Split search domain in half to try again.
3128             my $temp = ($upper + $lower) / 2;
3129
3130             # No point in continuing unless $i changes for next time
3131             # in the loop.
3132             if ($temp == $i) {
3133
3134                 # We can't reach the highest element because of the averaging.
3135                 # So if one below the upper edge, force it there and try one
3136                 # more time.
3137                 if ($i == $range_list_size - 2) {
3138
3139                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3140                     $i = $range_list_size - 1;
3141
3142                     # Change $lower as well so if fails next time through,
3143                     # taking the average will yield the same $i, and we will
3144                     # quit with the error message just below.
3145                     $lower = $i;
3146                     next;
3147                 }
3148                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3149                 return;
3150             }
3151             $i = $temp;
3152         } # End of while loop
3153
3154         if (main::DEBUG && $to_trace) {
3155             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3156             trace "i=  [ $i ]", $r->[$i];
3157             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3158         }
3159
3160         # Here we have found the offset.  Cache it as a starting point for the
3161         # next call.
3162         $_search_ranges_cache{$addr} = $i;
3163         return $i;
3164     }
3165
3166     sub _add_delete {
3167         # Add, replace or delete ranges to or from a list.  The $type
3168         # parameter gives which:
3169         #   '+' => insert or replace a range, returning a list of any changed
3170         #          ranges.
3171         #   '-' => delete a range, returning a list of any deleted ranges.
3172         #
3173         # The next three parameters give respectively the start, end, and
3174         # value associated with the range.  'value' should be null unless the
3175         # operation is '+';
3176         #
3177         # The range list is kept sorted so that the range with the lowest
3178         # starting position is first in the list, and generally, adjacent
3179         # ranges with the same values are merged into a single larger one (see
3180         # exceptions below).
3181         #
3182         # There are more parameters; all are key => value pairs:
3183         #   Type    gives the type of the value.  It is only valid for '+'.
3184         #           All ranges have types; if this parameter is omitted, 0 is
3185         #           assumed.  Ranges with type 0 are assumed to obey the
3186         #           Unicode rules for casing, etc; ranges with other types are
3187         #           not.  Otherwise, the type is arbitrary, for the caller's
3188         #           convenience, and looked at only by this routine to keep
3189         #           adjacent ranges of different types from being merged into
3190         #           a single larger range, and when Replace =>
3191         #           $IF_NOT_EQUIVALENT is specified (see just below).
3192         #   Replace  determines what to do if the range list already contains
3193         #            ranges which coincide with all or portions of the input
3194         #            range.  It is only valid for '+':
3195         #       => $NO            means that the new value is not to replace
3196         #                         any existing ones, but any empty gaps of the
3197         #                         range list coinciding with the input range
3198         #                         will be filled in with the new value.
3199         #       => $UNCONDITIONALLY  means to replace the existing values with
3200         #                         this one unconditionally.  However, if the
3201         #                         new and old values are identical, the
3202         #                         replacement is skipped to save cycles
3203         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3204         #                         with this one if they are not equivalent.
3205         #                         Ranges are equivalent if their types are the
3206         #                         same, and they are the same string; or if
3207         #                         both are type 0 ranges, if their Unicode
3208         #                         standard forms are identical.  In this last
3209         #                         case, the routine chooses the more "modern"
3210         #                         one to use.  This is because some of the
3211         #                         older files are formatted with values that
3212         #                         are, for example, ALL CAPs, whereas the
3213         #                         derived files have a more modern style,
3214         #                         which looks better.  By looking for this
3215         #                         style when the pre-existing and replacement
3216         #                         standard forms are the same, we can move to
3217         #                         the modern style
3218         #       => $MULTIPLE      means that if this range duplicates an
3219         #                         existing one, but has a different value,
3220         #                         don't replace the existing one, but insert
3221         #                         this, one so that the same range can occur
3222         #                         multiple times.  They are stored LIFO, so
3223         #                         that the final one inserted is the first one
3224         #                         returned in an ordered search of the table.
3225         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3226         #
3227         # "same value" means identical for non-type-0 ranges, and it means
3228         # having the same standard forms for type-0 ranges.
3229
3230         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3231
3232         my $self = shift;
3233         my $operation = shift;   # '+' for add/replace; '-' for delete;
3234         my $start = shift;
3235         my $end   = shift;
3236         my $value = shift;
3237
3238         my %args = @_;
3239
3240         $value = "" if not defined $value;        # warning: $value can be "0"
3241
3242         my $replace = delete $args{'Replace'};
3243         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3244
3245         my $type = delete $args{'Type'};
3246         $type = 0 unless defined $type;
3247
3248         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3249
3250         my $addr = do { no overloading; pack 'J', $self; };
3251
3252         if ($operation ne '+' && $operation ne '-') {
3253             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3254             return;
3255         }
3256         unless (defined $start && defined $end) {
3257             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3258             return;
3259         }
3260         unless ($end >= $start) {
3261             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3262             return;
3263         }
3264         #local $to_trace = 1 if main::DEBUG;
3265
3266         if ($operation eq '-') {
3267             if ($replace != $IF_NOT_EQUIVALENT) {
3268                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3269                 $replace = $IF_NOT_EQUIVALENT;
3270             }
3271             if ($type) {
3272                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3273                 $type = 0;
3274             }
3275             if ($value ne "") {
3276                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3277                 $value = "";
3278             }
3279         }
3280
3281         my $r = $ranges{$addr};               # The current list of ranges
3282         my $range_list_size = scalar @$r;     # And its size
3283         my $max = $max{$addr};                # The current high code point in
3284                                               # the list of ranges
3285
3286         # Do a special case requiring fewer machine cycles when the new range
3287         # starts after the current highest point.  The Unicode input data is
3288         # structured so this is common.
3289         if ($start > $max) {
3290
3291             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3292             return if $operation eq '-'; # Deleting a non-existing range is a
3293                                          # no-op
3294
3295             # If the new range doesn't logically extend the current final one
3296             # in the range list, create a new range at the end of the range
3297             # list.  (max cleverly is initialized to a negative number not
3298             # adjacent to 0 if the range list is empty, so even adding a range
3299             # to an empty range list starting at 0 will have this 'if'
3300             # succeed.)
3301             if ($start > $max + 1        # non-adjacent means can't extend.
3302                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3303                 || @{$r}[-1]->type != $type # types differ, can't extend.
3304             ) {
3305                 push @$r, Range->new($start, $end,
3306                                      Value => $value,
3307                                      Type => $type);
3308             }
3309             else {
3310
3311                 # Here, the new range starts just after the current highest in
3312                 # the range list, and they have the same type and value.
3313                 # Extend the current range to incorporate the new one.
3314                 @{$r}[-1]->set_end($end);
3315             }
3316
3317             # This becomes the new maximum.
3318             $max{$addr} = $end;
3319
3320             return;
3321         }
3322         #local $to_trace = 0 if main::DEBUG;
3323
3324         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3325
3326         # Here, the input range isn't after the whole rest of the range list.
3327         # Most likely 'splice' will be needed.  The rest of the routine finds
3328         # the needed splice parameters, and if necessary, does the splice.
3329         # First, find the offset parameter needed by the splice function for
3330         # the input range.  Note that the input range may span multiple
3331         # existing ones, but we'll worry about that later.  For now, just find
3332         # the beginning.  If the input range is to be inserted starting in a
3333         # position not currently in the range list, it must (obviously) come
3334         # just after the range below it, and just before the range above it.
3335         # Slightly less obviously, it will occupy the position currently
3336         # occupied by the range that is to come after it.  More formally, we
3337         # are looking for the position, $i, in the array of ranges, such that:
3338         #
3339         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3340         #
3341         # (The ordered relationships within existing ranges are also shown in
3342         # the equation above).  However, if the start of the input range is
3343         # within an existing range, the splice offset should point to that
3344         # existing range's position in the list; that is $i satisfies a
3345         # somewhat different equation, namely:
3346         #
3347         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3348         #
3349         # More briefly, $start can come before or after r[$i]->start, and at
3350         # this point, we don't know which it will be.  However, these
3351         # two equations share these constraints:
3352         #
3353         #   r[$i-1]->end < $start <= r[$i]->end
3354         #
3355         # And that is good enough to find $i.
3356
3357         my $i = $self->_search_ranges($start);
3358         if (! defined $i) {
3359             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3360             return;
3361         }
3362
3363         # The search function returns $i such that:
3364         #
3365         # r[$i-1]->end < $start <= r[$i]->end
3366         #
3367         # That means that $i points to the first range in the range list
3368         # that could possibly be affected by this operation.  We still don't
3369         # know if the start of the input range is within r[$i], or if it
3370         # points to empty space between r[$i-1] and r[$i].
3371         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3372
3373         # Special case the insertion of data that is not to replace any
3374         # existing data.
3375         if ($replace == $NO) {  # If $NO, has to be operation '+'
3376             #local $to_trace = 1 if main::DEBUG;
3377             trace "Doesn't replace" if main::DEBUG && $to_trace;
3378
3379             # Here, the new range is to take effect only on those code points
3380             # that aren't already in an existing range.  This can be done by
3381             # looking through the existing range list and finding the gaps in
3382             # the ranges that this new range affects, and then calling this
3383             # function recursively on each of those gaps, leaving untouched
3384             # anything already in the list.  Gather up a list of the changed
3385             # gaps first so that changes to the internal state as new ranges
3386             # are added won't be a problem.
3387             my @gap_list;
3388
3389             # First, if the starting point of the input range is outside an
3390             # existing one, there is a gap from there to the beginning of the
3391             # existing range -- add a span to fill the part that this new
3392             # range occupies
3393             if ($start < $r->[$i]->start) {
3394                 push @gap_list, Range->new($start,
3395                                            main::min($end,
3396                                                      $r->[$i]->start - 1),
3397                                            Type => $type);
3398                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3399             }
3400
3401             # Then look through the range list for other gaps until we reach
3402             # the highest range affected by the input one.
3403             my $j;
3404             for ($j = $i+1; $j < $range_list_size; $j++) {
3405                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3406                 last if $end < $r->[$j]->start;
3407
3408                 # If there is a gap between when this range starts and the
3409                 # previous one ends, add a span to fill it.  Note that just
3410                 # because there are two ranges doesn't mean there is a
3411                 # non-zero gap between them.  It could be that they have
3412                 # different values or types
3413                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3414                     push @gap_list,
3415                         Range->new($r->[$j-1]->end + 1,
3416                                    $r->[$j]->start - 1,
3417                                    Type => $type);
3418                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3419                 }
3420             }
3421
3422             # Here, we have either found an existing range in the range list,
3423             # beyond the area affected by the input one, or we fell off the
3424             # end of the loop because the input range affects the whole rest
3425             # of the range list.  In either case, $j is 1 higher than the
3426             # highest affected range.  If $j == $i, it means that there are no
3427             # affected ranges, that the entire insertion is in the gap between
3428             # r[$i-1], and r[$i], which we already have taken care of before
3429             # the loop.
3430             # On the other hand, if there are affected ranges, it might be
3431             # that there is a gap that needs filling after the final such
3432             # range to the end of the input range
3433             if ($r->[$j-1]->end < $end) {
3434                     push @gap_list, Range->new(main::max($start,
3435                                                          $r->[$j-1]->end + 1),
3436                                                $end,
3437                                                Type => $type);
3438                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3439             }
3440
3441             # Call recursively to fill in all the gaps.
3442             foreach my $gap (@gap_list) {
3443                 $self->_add_delete($operation,
3444                                    $gap->start,
3445                                    $gap->end,
3446                                    $value,
3447                                    Type => $type);
3448             }
3449
3450             return;
3451         }
3452
3453         # Here, we have taken care of the case where $replace is $NO.
3454         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3455         # If inserting a multiple record, this is where it goes, before the
3456         # first (if any) existing one.  This implies an insertion, and no
3457         # change to any existing ranges.  Note that $i can be -1 if this new
3458         # range doesn't actually duplicate any existing, and comes at the
3459         # beginning of the list.
3460         if ($replace == $MULTIPLE) {
3461
3462             if ($start != $end) {
3463                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3464                 return;
3465             }
3466
3467             # Don't add an exact duplicate, as it isn't really a multiple
3468             if ($end >= $r->[$i]->start) {
3469                 if ($r->[$i]->start != $r->[$i]->end) {
3470                     Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the other range ($r->[$i]) contains more than one code point.  No action taken.");
3471                     return;
3472                 }
3473                 return if $value eq $r->[$i]->value && $type eq $r->[$i]->type;
3474             }
3475
3476             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3477             my @return = splice @$r,
3478                                 $i,
3479                                 0,
3480                                 Range->new($start,
3481                                            $end,
3482                                            Value => $value,
3483                                            Type => $type);
3484             if (main::DEBUG && $to_trace) {
3485                 trace "After splice:";
3486                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3487                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3488                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3489                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3490                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3491                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3492             }
3493             return @return;
3494         }
3495
3496         # Here, we have taken care of $NO and $MULTIPLE replaces.  This leaves
3497         # delete, insert, and replace either unconditionally or if not
3498         # equivalent.  $i still points to the first potential affected range.
3499         # Now find the highest range affected, which will determine the length
3500         # parameter to splice.  (The input range can span multiple existing
3501         # ones.)  If this isn't a deletion, while we are looking through the
3502         # range list, see also if this is a replacement rather than a clean
3503         # insertion; that is if it will change the values of at least one
3504         # existing range.  Start off assuming it is an insert, until find it
3505         # isn't.
3506         my $clean_insert = $operation eq '+';
3507         my $j;        # This will point to the highest affected range
3508
3509         # For non-zero types, the standard form is the value itself;
3510         my $standard_form = ($type) ? $value : main::standardize($value);
3511
3512         for ($j = $i; $j < $range_list_size; $j++) {
3513             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3514
3515             # If find a range that it doesn't overlap into, we can stop
3516             # searching
3517             last if $end < $r->[$j]->start;
3518
3519             # Here, overlaps the range at $j.  If the values don't match,
3520             # and so far we think this is a clean insertion, it becomes a
3521             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3522             if ($clean_insert) {
3523                 if ($r->[$j]->standard_form ne $standard_form) {
3524                     $clean_insert = 0;
3525                 }
3526                 else {
3527
3528                     # Here, the two values are essentially the same.  If the
3529                     # two are actually identical, replacing wouldn't change
3530                     # anything so skip it.
3531                     my $pre_existing = $r->[$j]->value;
3532                     if ($pre_existing ne $value) {
3533
3534                         # Here the new and old standardized values are the
3535                         # same, but the non-standardized values aren't.  If
3536                         # replacing unconditionally, then replace
3537                         if( $replace == $UNCONDITIONALLY) {
3538                             $clean_insert = 0;
3539                         }
3540                         else {
3541
3542                             # Here, are replacing conditionally.  Decide to
3543                             # replace or not based on which appears to look
3544                             # the "nicest".  If one is mixed case and the
3545                             # other isn't, choose the mixed case one.
3546                             my $new_mixed = $value =~ /[A-Z]/
3547                                             && $value =~ /[a-z]/;
3548                             my $old_mixed = $pre_existing =~ /[A-Z]/
3549                                             && $pre_existing =~ /[a-z]/;
3550
3551                             if ($old_mixed != $new_mixed) {
3552                                 $clean_insert = 0 if $new_mixed;
3553                                 if (main::DEBUG && $to_trace) {
3554                                     if ($clean_insert) {
3555                                         trace "Retaining $pre_existing over $value";
3556                                     }
3557                                     else {
3558                                         trace "Replacing $pre_existing with $value";
3559                                     }
3560                                 }
3561                             }
3562                             else {
3563
3564                                 # Here casing wasn't different between the two.
3565                                 # If one has hyphens or underscores and the
3566                                 # other doesn't, choose the one with the
3567                                 # punctuation.
3568                                 my $new_punct = $value =~ /[-_]/;
3569                                 my $old_punct = $pre_existing =~ /[-_]/;
3570
3571                                 if ($old_punct != $new_punct) {
3572                                     $clean_insert = 0 if $new_punct;
3573                                     if (main::DEBUG && $to_trace) {
3574                                         if ($clean_insert) {
3575                                             trace "Retaining $pre_existing over $value";
3576                                         }
3577                                         else {
3578                                             trace "Replacing $pre_existing with $value";
3579                                         }
3580                                     }
3581                                 }   # else existing one is just as "good";
3582                                     # retain it to save cycles.
3583                             }
3584                         }
3585                     }
3586                 }
3587             }
3588         } # End of loop looking for highest affected range.
3589
3590         # Here, $j points to one beyond the highest range that this insertion
3591         # affects (hence to beyond the range list if that range is the final
3592         # one in the range list).
3593
3594         # The splice length is all the affected ranges.  Get it before
3595         # subtracting, for efficiency, so we don't have to later add 1.
3596         my $length = $j - $i;
3597
3598         $j--;        # $j now points to the highest affected range.
3599         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3600
3601         # Here, have taken care of $NO and $MULTIPLE replaces.
3602         # $j points to the highest affected range.  But it can be < $i or even
3603         # -1.  These happen only if the insertion is entirely in the gap
3604         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3605         # above exited first time through with $end < $r->[$i]->start.  (And
3606         # then we subtracted one from j)  This implies also that $start <
3607         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3608         # $start, so the entire input range is in the gap.
3609         if ($j < $i) {
3610
3611             # Here the entire input range is in the gap before $i.
3612
3613             if (main::DEBUG && $to_trace) {
3614                 if ($i) {
3615                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3616                 }
3617                 else {
3618                     trace "Entire range is before $r->[$i]";
3619                 }
3620             }
3621             return if $operation ne '+'; # Deletion of a non-existent range is
3622                                          # a no-op
3623         }
3624         else {
3625
3626             # Here part of the input range is not in the gap before $i.  Thus,
3627             # there is at least one affected one, and $j points to the highest
3628             # such one.
3629
3630             # At this point, here is the situation:
3631             # This is not an insertion of a multiple, nor of tentative ($NO)
3632             # data.
3633             #   $i  points to the first element in the current range list that
3634             #            may be affected by this operation.  In fact, we know
3635             #            that the range at $i is affected because we are in
3636             #            the else branch of this 'if'
3637             #   $j  points to the highest affected range.
3638             # In other words,
3639             #   r[$i-1]->end < $start <= r[$i]->end
3640             # And:
3641             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3642             #
3643             # Also:
3644             #   $clean_insert is a boolean which is set true if and only if
3645             #        this is a "clean insertion", i.e., not a change nor a
3646             #        deletion (multiple was handled above).
3647
3648             # We now have enough information to decide if this call is a no-op
3649             # or not.  It is a no-op if this is an insertion of already
3650             # existing data.
3651
3652             if (main::DEBUG && $to_trace && $clean_insert
3653                                          && $i == $j
3654                                          && $start >= $r->[$i]->start)
3655             {
3656                     trace "no-op";
3657             }
3658             return if $clean_insert
3659                       && $i == $j # more than one affected range => not no-op
3660
3661                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3662                       # Further, $start and/or $end is >= r[$i]->start
3663                       # The test below hence guarantees that
3664                       #     r[$i]->start < $start <= $end <= r[$i]->end
3665                       # This means the input range is contained entirely in
3666                       # the one at $i, so is a no-op
3667                       && $start >= $r->[$i]->start;
3668         }
3669
3670         # Here, we know that some action will have to be taken.  We have
3671         # calculated the offset and length (though adjustments may be needed)
3672         # for the splice.  Now start constructing the replacement list.
3673         my @replacement;
3674         my $splice_start = $i;
3675
3676         my $extends_below;
3677         my $extends_above;
3678
3679         # See if should extend any adjacent ranges.
3680         if ($operation eq '-') { # Don't extend deletions
3681             $extends_below = $extends_above = 0;
3682         }
3683         else {  # Here, should extend any adjacent ranges.  See if there are
3684                 # any.
3685             $extends_below = ($i > 0
3686                             # can't extend unless adjacent
3687                             && $r->[$i-1]->end == $start -1
3688                             # can't extend unless are same standard value
3689                             && $r->[$i-1]->standard_form eq $standard_form
3690                             # can't extend unless share type
3691                             && $r->[$i-1]->type == $type);
3692             $extends_above = ($j+1 < $range_list_size
3693                             && $r->[$j+1]->start == $end +1
3694                             && $r->[$j+1]->standard_form eq $standard_form
3695                             && $r->[$j+1]->type == $type);
3696         }
3697         if ($extends_below && $extends_above) { # Adds to both
3698             $splice_start--;     # start replace at element below
3699             $length += 2;        # will replace on both sides
3700             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3701
3702             # The result will fill in any gap, replacing both sides, and
3703             # create one large range.
3704             @replacement = Range->new($r->[$i-1]->start,
3705                                       $r->[$j+1]->end,
3706                                       Value => $value,
3707                                       Type => $type);
3708         }
3709         else {
3710
3711             # Here we know that the result won't just be the conglomeration of
3712             # a new range with both its adjacent neighbors.  But it could
3713             # extend one of them.
3714
3715             if ($extends_below) {
3716
3717                 # Here the new element adds to the one below, but not to the
3718                 # one above.  If inserting, and only to that one range,  can
3719                 # just change its ending to include the new one.
3720                 if ($length == 0 && $clean_insert) {
3721                     $r->[$i-1]->set_end($end);
3722                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3723                     return;
3724                 }
3725                 else {
3726                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3727                     $splice_start--;        # start replace at element below
3728                     $length++;              # will replace the element below
3729                     $start = $r->[$i-1]->start;
3730                 }
3731             }
3732             elsif ($extends_above) {
3733
3734                 # Here the new element adds to the one above, but not below.
3735                 # Mirror the code above
3736                 if ($length == 0 && $clean_insert) {
3737                     $r->[$j+1]->set_start($start);
3738                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3739                     return;
3740                 }
3741                 else {
3742                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3743                     $length++;        # will replace the element above
3744                     $end = $r->[$j+1]->end;
3745                 }
3746             }
3747
3748             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3749
3750             # Finally, here we know there will have to be a splice.
3751             # If the change or delete affects only the highest portion of the
3752             # first affected range, the range will have to be split.  The
3753             # splice will remove the whole range, but will replace it by a new
3754             # range containing just the unaffected part.  So, in this case,
3755             # add to the replacement list just this unaffected portion.
3756             if (! $extends_below
3757                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3758             {
3759                 push @replacement,
3760                     Range->new($r->[$i]->start,
3761                                $start - 1,
3762                                Value => $r->[$i]->value,
3763                                Type => $r->[$i]->type);
3764             }
3765
3766             # In the case of an insert or change, but not a delete, we have to
3767             # put in the new stuff;  this comes next.
3768             if ($operation eq '+') {
3769                 push @replacement, Range->new($start,
3770                                               $end,
3771                                               Value => $value,
3772                                               Type => $type);
3773             }
3774
3775             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3776             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3777
3778             # And finally, if we're changing or deleting only a portion of the
3779             # highest affected range, it must be split, as the lowest one was.
3780             if (! $extends_above
3781                 && $j >= 0  # Remember that j can be -1 if before first
3782                             # current element
3783                 && $end >= $r->[$j]->start
3784                 && $end < $r->[$j]->end)
3785             {
3786                 push @replacement,
3787                     Range->new($end + 1,
3788                                $r->[$j]->end,
3789                                Value => $r->[$j]->value,
3790                                Type => $r->[$j]->type);
3791             }
3792         }
3793
3794         # And do the splice, as calculated above
3795         if (main::DEBUG && $to_trace) {
3796             trace "replacing $length element(s) at $i with ";
3797             foreach my $replacement (@replacement) {
3798                 trace "    $replacement";
3799             }
3800             trace "Before splice:";
3801             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3802             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3803             trace "i  =[", $i, "]", $r->[$i];
3804             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3805             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3806         }
3807
3808         my @return = splice @$r, $splice_start, $length, @replacement;
3809
3810         if (main::DEBUG && $to_trace) {
3811             trace "After splice:";
3812             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3813             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3814             trace "i  =[", $i, "]", $r->[$i];
3815             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3816             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3817             trace "removed @return";
3818         }
3819
3820         # An actual deletion could have changed the maximum in the list.
3821         # There was no deletion if the splice didn't return something, but
3822         # otherwise recalculate it.  This is done too rarely to worry about
3823         # performance.
3824         if ($operation eq '-' && @return) {
3825             $max{$addr} = $r->[-1]->end;
3826         }
3827         return @return;
3828     }
3829
3830     sub reset_each_range {  # reset the iterator for each_range();
3831         my $self = shift;
3832         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3833
3834         no overloading;
3835         undef $each_range_iterator{pack 'J', $self};
3836         return;
3837     }
3838
3839     sub each_range {
3840         # Iterate over each range in a range list.  Results are undefined if
3841         # the range list is changed during the iteration.
3842
3843         my $self = shift;
3844         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3845
3846         my $addr = do { no overloading; pack 'J', $self; };
3847
3848         return if $self->is_empty;
3849
3850         $each_range_iterator{$addr} = -1
3851                                 if ! defined $each_range_iterator{$addr};
3852         $each_range_iterator{$addr}++;
3853         return $ranges{$addr}->[$each_range_iterator{$addr}]
3854                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3855         undef $each_range_iterator{$addr};
3856         return;
3857     }
3858
3859     sub count {        # Returns count of code points in range list
3860         my $self = shift;
3861         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3862
3863         my $addr = do { no overloading; pack 'J', $self; };
3864
3865         my $count = 0;
3866         foreach my $range (@{$ranges{$addr}}) {
3867             $count += $range->end - $range->start + 1;
3868         }
3869         return $count;
3870     }
3871
3872     sub delete_range {    # Delete a range
3873         my $self = shift;
3874         my $start = shift;
3875         my $end = shift;
3876
3877         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3878
3879         return $self->_add_delete('-', $start, $end, "");
3880     }
3881
3882     sub is_empty { # Returns boolean as to if a range list is empty
3883         my $self = shift;
3884         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3885
3886         no overloading;
3887         return scalar @{$ranges{pack 'J', $self}} == 0;
3888     }
3889
3890     sub hash {
3891         # Quickly returns a scalar suitable for separating tables into
3892         # buckets, i.e. it is a hash function of the contents of a table, so
3893         # there are relatively few conflicts.
3894
3895         my $self = shift;
3896         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3897
3898         my $addr = do { no overloading; pack 'J', $self; };
3899
3900         # These are quickly computable.  Return looks like 'min..max;count'
3901         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3902     }
3903 } # End closure for _Range_List_Base
3904
3905 package Range_List;
3906 use base '_Range_List_Base';
3907
3908 # A Range_List is a range list for match tables; i.e. the range values are
3909 # not significant.  Thus a number of operations can be safely added to it,
3910 # such as inversion, intersection.  Note that union is also an unsafe
3911 # operation when range values are cared about, and that method is in the base
3912 # class, not here.  But things are set up so that that method is callable only
3913 # during initialization.  Only in this derived class, is there an operation
3914 # that combines two tables.  A Range_Map can thus be used to initialize a
3915 # Range_List, and its mappings will be in the list, but are not significant to
3916 # this class.
3917
3918 sub trace { return main::trace(@_); }
3919
3920 { # Closure
3921
3922     use overload
3923         fallback => 0,
3924         '+' => sub { my $self = shift;
3925                     my $other = shift;
3926
3927                     return $self->_union($other)
3928                 },
3929         '&' => sub { my $self = shift;
3930                     my $other = shift;
3931
3932                     return $self->_intersect($other, 0);
3933                 },
3934         '~' => "_invert",
3935         '-' => "_subtract",
3936     ;
3937
3938     sub _invert {
3939         # Returns a new Range_List that gives all code points not in $self.
3940
3941         my $self = shift;
3942
3943         my $new = Range_List->new;
3944
3945         # Go through each range in the table, finding the gaps between them
3946         my $max = -1;   # Set so no gap before range beginning at 0
3947         for my $range ($self->ranges) {
3948             my $start = $range->start;
3949             my $end   = $range->end;
3950
3951             # If there is a gap before this range, the inverse will contain
3952             # that gap.
3953             if ($start > $max + 1) {
3954                 $new->add_range($max + 1, $start - 1);
3955             }
3956             $max = $end;
3957         }
3958
3959         # And finally, add the gap from the end of the table to the max
3960         # possible code point
3961         if ($max < $LAST_UNICODE_CODEPOINT) {
3962             $new->add_range($max + 1, $LAST_UNICODE_CODEPOINT);
3963         }
3964         return $new;
3965     }
3966
3967     sub _subtract {
3968         # Returns a new Range_List with the argument deleted from it.  The
3969         # argument can be a single code point, a range, or something that has
3970         # a range, with the _range_list() method on it returning them
3971
3972         my $self = shift;
3973         my $other = shift;
3974         my $reversed = shift;
3975         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3976
3977         if ($reversed) {
3978             Carp::my_carp_bug("Can't cope with a "
3979              .  __PACKAGE__
3980              . " being the second parameter in a '-'.  Subtraction ignored.");
3981             return $self;
3982         }
3983
3984         my $new = Range_List->new(Initialize => $self);
3985
3986         if (! ref $other) { # Single code point
3987             $new->delete_range($other, $other);
3988         }
3989         elsif ($other->isa('Range')) {
3990             $new->delete_range($other->start, $other->end);