This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlexperiment: mark regexp backtracking verbs as accepted
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of line only at the left and right ends of the string to
35 matching them anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in a bracketed
76 character class unless the character that maps to them is explicitly
77 mentioned, and it doesn't match them at all if the character class is
78 inverted, which otherwise could be highly confusing.  See
79 L<perlrecharclass/Bracketed Character Classes>, and
80 L<perlrecharclass/Negation>.
81
82 =item x
83 X</x>
84
85 Extend your pattern's legibility by permitting whitespace and comments.
86 Details in L</"/x">
87
88 =item p
89 X</p> X<regex, preserve> X<regexp, preserve>
90
91 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
92 ${^POSTMATCH} are available for use after matching.
93
94 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
95 mechanism, ${^PREMATCH}, ${^MATCH}, and ${^POSTMATCH} will be available
96 after the match regardless of the modifier.
97
98 =item g and c
99 X</g> X</c>
100
101 Global matching, and keep the Current position after failed matching.
102 Unlike i, m, s and x, these two flags affect the way the regex is used
103 rather than the regex itself. See
104 L<perlretut/"Using regular expressions in Perl"> for further explanation
105 of the g and c modifiers.
106
107 =item a, d, l and u
108 X</a> X</d> X</l> X</u>
109
110 These modifiers, all new in 5.14, affect which character-set semantics
111 (Unicode, etc.) are used, as described below in
112 L</Character set modifiers>.
113
114 =back
115
116 Regular expression modifiers are usually written in documentation
117 as e.g., "the C</x> modifier", even though the delimiter
118 in question might not really be a slash.  The modifiers C</imsxadlup>
119 may also be embedded within the regular expression itself using
120 the C<(?...)> construct, see L</Extended Patterns> below.
121
122 =head3 /x
123
124 C</x> tells
125 the regular expression parser to ignore most whitespace that is neither
126 backslashed nor within a character class.  You can use this to break up
127 your regular expression into (slightly) more readable parts.  The C<#>
128 character is also treated as a metacharacter introducing a comment,
129 just as in ordinary Perl code.  This also means that if you want real
130 whitespace or C<#> characters in the pattern (outside a character
131 class, where they are unaffected by C</x>), then you'll either have to
132 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
133 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
134 making Perl's regular expressions more readable.  Note that you have to
135 be careful not to include the pattern delimiter in the comment--perl has
136 no way of knowing you did not intend to close the pattern early.  See
137 the C-comment deletion code in L<perlop>.  Also note that anything inside
138 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
139 space interpretation within a single multi-character construct.  For
140 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
141 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
142 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<(>,
143 C<?>, and C<:>.  Within any delimiters for such a
144 construct, allowed spaces are not affected by C</x>, and depend on the
145 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
146 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
147 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
148 L<perluniprops/Properties accessible through \p{} and \P{}>.
149 X</x>
150
151 =head3 Character set modifiers
152
153 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
154 the character set modifiers; they affect the character set semantics
155 used for the regular expression.
156
157 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
158 to you, and so you need not worry about them very much.  They exist for
159 Perl's internal use, so that complex regular expression data structures
160 can be automatically serialized and later exactly reconstituted,
161 including all their nuances.  But, since Perl can't keep a secret, and
162 there may be rare instances where they are useful, they are documented
163 here.
164
165 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
166 allow code that is to work mostly on ASCII data to not have to concern
167 itself with Unicode.
168
169 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
170 effect at the time of the execution of the pattern match.
171
172 C</u> sets the character set to B<U>nicode.
173
174 C</a> also sets the character set to Unicode, BUT adds several
175 restrictions for B<A>SCII-safe matching.
176
177 C</d> is the old, problematic, pre-5.14 B<D>efault character set
178 behavior.  Its only use is to force that old behavior.
179
180 At any given time, exactly one of these modifiers is in effect.  Their
181 existence allows Perl to keep the originally compiled behavior of a
182 regular expression, regardless of what rules are in effect when it is
183 actually executed.  And if it is interpolated into a larger regex, the
184 original's rules continue to apply to it, and only it.
185
186 The C</l> and C</u> modifiers are automatically selected for
187 regular expressions compiled within the scope of various pragmas,
188 and we recommend that in general, you use those pragmas instead of
189 specifying these modifiers explicitly.  For one thing, the modifiers
190 affect only pattern matching, and do not extend to even any replacement
191 done, whereas using the pragmas give consistent results for all
192 appropriate operations within their scopes.  For example,
193
194  s/foo/\Ubar/il
195
196 will match "foo" using the locale's rules for case-insensitive matching,
197 but the C</l> does not affect how the C<\U> operates.  Most likely you
198 want both of them to use locale rules.  To do this, instead compile the
199 regular expression within the scope of C<use locale>.  This both
200 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
201 lesson is to C<use locale> and not C</l> explicitly.
202
203 Similarly, it would be better to use C<use feature 'unicode_strings'>
204 instead of,
205
206  s/foo/\Lbar/iu
207
208 to get Unicode rules, as the C<\L> in the former (but not necessarily
209 the latter) would also use Unicode rules.
210
211 More detail on each of the modifiers follows.  Most likely you don't
212 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
213 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
214
215 =head4 /l
216
217 means to use the current locale's rules (see L<perllocale>) when pattern
218 matching.  For example, C<\w> will match the "word" characters of that
219 locale, and C<"/i"> case-insensitive matching will match according to
220 the locale's case folding rules.  The locale used will be the one in
221 effect at the time of execution of the pattern match.  This may not be
222 the same as the compilation-time locale, and can differ from one match
223 to another if there is an intervening call of the
224 L<setlocale() function|perllocale/The setlocale function>.
225
226 Perl only supports single-byte locales.  This means that code points
227 above 255 are treated as Unicode no matter what locale is in effect.
228 Under Unicode rules, there are a few case-insensitive matches that cross
229 the 255/256 boundary.  These are disallowed under C</l>.  For example,
230 0xFF (on ASCII platforms) does not caselessly match the character at
231 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
232 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
233 has no way of knowing if that character even exists in the locale, much
234 less what code point it is.
235
236 This modifier may be specified to be the default by C<use locale>, but
237 see L</Which character set modifier is in effect?>.
238 X</l>
239
240 =head4 /u
241
242 means to use Unicode rules when pattern matching.  On ASCII platforms,
243 this means that the code points between 128 and 255 take on their
244 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
245 (Otherwise Perl considers their meanings to be undefined.)  Thus,
246 under this modifier, the ASCII platform effectively becomes a Unicode
247 platform; and hence, for example, C<\w> will match any of the more than
248 100_000 word characters in Unicode.
249
250 Unlike most locales, which are specific to a language and country pair,
251 Unicode classifies all the characters that are letters I<somewhere> in
252 the world as
253 C<\w>.  For example, your locale might not think that C<LATIN SMALL
254 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
255 Unicode does.  Similarly, all the characters that are decimal digits
256 somewhere in the world will match C<\d>; this is hundreds, not 10,
257 possible matches.  And some of those digits look like some of the 10
258 ASCII digits, but mean a different number, so a human could easily think
259 a number is a different quantity than it really is.  For example,
260 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
261 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
262 that are a mixture from different writing systems, creating a security
263 issue.  L<Unicode::UCD/num()> can be used to sort
264 this out.  Or the C</a> modifier can be used to force C<\d> to match
265 just the ASCII 0 through 9.
266
267 Also, under this modifier, case-insensitive matching works on the full
268 set of Unicode
269 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
270 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
271 if you're not prepared, might make it look like a hexadecimal constant,
272 presenting another potential security issue.  See
273 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
274 security issues.
275
276 This modifier may be specified to be the default by C<use feature
277 'unicode_strings>, C<use locale ':not_characters'>, or
278 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
279 but see L</Which character set modifier is in effect?>.
280 X</u>
281
282 =head4 /d
283
284 This modifier means to use the "Default" native rules of the platform
285 except when there is cause to use Unicode rules instead, as follows:
286
287 =over 4
288
289 =item 1
290
291 the target string is encoded in UTF-8; or
292
293 =item 2
294
295 the pattern is encoded in UTF-8; or
296
297 =item 3
298
299 the pattern explicitly mentions a code point that is above 255 (say by
300 C<\x{100}>); or
301
302 =item 4
303
304 the pattern uses a Unicode name (C<\N{...}>);  or
305
306 =item 5
307
308 the pattern uses a Unicode property (C<\p{...}>); or
309
310 =item 6
311
312 the pattern uses L</C<(?[ ])>>
313
314 =back
315
316 Another mnemonic for this modifier is "Depends", as the rules actually
317 used depend on various things, and as a result you can get unexpected
318 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
319 become rather infamous, leading to yet another (printable) name for this
320 modifier, "Dodgy".
321
322 Unless the pattern or string are encoded in UTF-8, only ASCII characters
323 can match positively.
324
325 Here are some examples of how that works on an ASCII platform:
326
327  $str =  "\xDF";      # $str is not in UTF-8 format.
328  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
329  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
330  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
331  chop $str;
332  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
333
334 This modifier is automatically selected by default when none of the
335 others are, so yet another name for it is "Default".
336
337 Because of the unexpected behaviors associated with this modifier, you
338 probably should only use it to maintain weird backward compatibilities.
339
340 =head4 /a (and /aa)
341
342 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
343 unlike the others, may be doubled-up to increase its effect.
344
345 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
346 the Posix character classes to match only in the ASCII range.  They thus
347 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
348 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
349 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, experimentally,
350 the vertical tab; C<\w> means the 63 characters
351 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
352 C<[[:print:]]> match only the appropriate ASCII-range characters.
353
354 This modifier is useful for people who only incidentally use Unicode,
355 and who do not wish to be burdened with its complexities and security
356 concerns.
357
358 With C</a>, one can write C<\d> with confidence that it will only match
359 ASCII characters, and should the need arise to match beyond ASCII, you
360 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
361 similar C<\p{...}> constructs that can match beyond ASCII both white
362 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
363 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
364 doesn't mean you can't use Unicode, it means that to get Unicode
365 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
366 signals Unicode.
367
368 As you would expect, this modifier causes, for example, C<\D> to mean
369 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
370 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
371 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
372 for C<\B>).
373
374 Otherwise, C</a> behaves like the C</u> modifier, in that
375 case-insensitive matching uses Unicode semantics; for example, "k" will
376 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
377 points in the Latin1 range, above ASCII will have Unicode rules when it
378 comes to case-insensitive matching.
379
380 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
381 specify the "a" twice, for example C</aai> or C</aia>.  (The first
382 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
383 adds the C</i> restrictions.)  But, note that code points outside the
384 ASCII range will use Unicode rules for C</i> matching, so the modifier
385 doesn't really restrict things to just ASCII; it just forbids the
386 intermixing of ASCII and non-ASCII.
387
388 To summarize, this modifier provides protection for applications that
389 don't wish to be exposed to all of Unicode.  Specifying it twice
390 gives added protection.
391
392 This modifier may be specified to be the default by C<use re '/a'>
393 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
394 the C</u> modifier explicitly if there are a few regular expressions
395 where you do want full Unicode rules (but even here, it's best if
396 everything were under feature C<"unicode_strings">, along with the
397 C<use re '/aa'>).  Also see L</Which character set modifier is in
398 effect?>.
399 X</a>
400 X</aa>
401
402 =head4 Which character set modifier is in effect?
403
404 Which of these modifiers is in effect at any given point in a regular
405 expression depends on a fairly complex set of interactions.  These have
406 been designed so that in general you don't have to worry about it, but
407 this section gives the gory details.  As
408 explained below in L</Extended Patterns> it is possible to explicitly
409 specify modifiers that apply only to portions of a regular expression.
410 The innermost always has priority over any outer ones, and one applying
411 to the whole expression has priority over any of the default settings that are
412 described in the remainder of this section.
413
414 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
415 default modifiers (including these) for regular expressions compiled
416 within its scope.  This pragma has precedence over the other pragmas
417 listed below that also change the defaults.
418
419 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
420 and C<L<use feature 'unicode_strings|feature>>, or
421 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
422 C</u> when not in the same scope as either C<L<use locale|perllocale>>
423 or C<L<use bytes|bytes>>.
424 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
425 sets the default to C</u>, overriding any plain C<use locale>.)
426 Unlike the mechanisms mentioned above, these
427 affect operations besides regular expressions pattern matching, and so
428 give more consistent results with other operators, including using
429 C<\U>, C<\l>, etc. in substitution replacements.
430
431 If none of the above apply, for backwards compatibility reasons, the
432 C</d> modifier is the one in effect by default.  As this can lead to
433 unexpected results, it is best to specify which other rule set should be
434 used.
435
436 =head4 Character set modifier behavior prior to Perl 5.14
437
438 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
439 for regexes compiled within the scope of C<use locale>, and C</d> was
440 implied otherwise.  However, interpolating a regex into a larger regex
441 would ignore the original compilation in favor of whatever was in effect
442 at the time of the second compilation.  There were a number of
443 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
444 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
445 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
446
447 =head2 Regular Expressions
448
449 =head3 Metacharacters
450
451 The patterns used in Perl pattern matching evolved from those supplied in
452 the Version 8 regex routines.  (The routines are derived
453 (distantly) from Henry Spencer's freely redistributable reimplementation
454 of the V8 routines.)  See L<Version 8 Regular Expressions> for
455 details.
456
457 In particular the following metacharacters have their standard I<egrep>-ish
458 meanings:
459 X<metacharacter>
460 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
461
462
463     \        Quote the next metacharacter
464     ^        Match the beginning of the line
465     .        Match any character (except newline)
466     $        Match the end of the line (or before newline at the end)
467     |        Alternation
468     ()       Grouping
469     []       Bracketed Character class
470
471 By default, the "^" character is guaranteed to match only the
472 beginning of the string, the "$" character only the end (or before the
473 newline at the end), and Perl does certain optimizations with the
474 assumption that the string contains only one line.  Embedded newlines
475 will not be matched by "^" or "$".  You may, however, wish to treat a
476 string as a multi-line buffer, such that the "^" will match after any
477 newline within the string (except if the newline is the last character in
478 the string), and "$" will match before any newline.  At the
479 cost of a little more overhead, you can do this by using the /m modifier
480 on the pattern match operator.  (Older programs did this by setting C<$*>,
481 but this option was removed in perl 5.10.)
482 X<^> X<$> X</m>
483
484 To simplify multi-line substitutions, the "." character never matches a
485 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
486 the string is a single line--even if it isn't.
487 X<.> X</s>
488
489 =head3 Quantifiers
490
491 The following standard quantifiers are recognized:
492 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
493
494     *           Match 0 or more times
495     +           Match 1 or more times
496     ?           Match 1 or 0 times
497     {n}         Match exactly n times
498     {n,}        Match at least n times
499     {n,m}       Match at least n but not more than m times
500
501 (If a curly bracket occurs in any other context and does not form part of
502 a backslashed sequence like C<\x{...}>, it is treated as a regular
503 character.  In particular, the lower quantifier bound is not optional,
504 and a typo in a quantifier silently causes it to be treated as the
505 literal characters.  For example,
506
507     /o{4,3}/
508
509 looks like a quantifier that matches 0 times, since 4 is greater than 3,
510 but it really means to match the sequence of six characters
511 S<C<"o { 4 , 3 }">>.  It is planned to eventually require literal uses
512 of curly brackets to be escaped, say by preceding them with a backslash
513 or enclosing them within square brackets, (C<"\{"> or C<"[{]">).  This
514 change will allow for future syntax extensions (like making the lower
515 bound of a quantifier optional), and better error checking.  In the
516 meantime, you should get in the habit of escaping all instances where
517 you mean a literal "{".)
518
519 The "*" quantifier is equivalent to C<{0,}>, the "+"
520 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
521 to non-negative integral values less than a preset limit defined when perl is built.
522 This is usually 32766 on the most common platforms.  The actual limit can
523 be seen in the error message generated by code such as this:
524
525     $_ **= $_ , / {$_} / for 2 .. 42;
526
527 By default, a quantified subpattern is "greedy", that is, it will match as
528 many times as possible (given a particular starting location) while still
529 allowing the rest of the pattern to match.  If you want it to match the
530 minimum number of times possible, follow the quantifier with a "?".  Note
531 that the meanings don't change, just the "greediness":
532 X<metacharacter> X<greedy> X<greediness>
533 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
534
535     *?        Match 0 or more times, not greedily
536     +?        Match 1 or more times, not greedily
537     ??        Match 0 or 1 time, not greedily
538     {n}?      Match exactly n times, not greedily (redundant)
539     {n,}?     Match at least n times, not greedily
540     {n,m}?    Match at least n but not more than m times, not greedily
541
542 Normally when a quantified subpattern does not allow the rest of the
543 overall pattern to match, Perl will backtrack. However, this behaviour is
544 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
545 as well.
546
547  *+     Match 0 or more times and give nothing back
548  ++     Match 1 or more times and give nothing back
549  ?+     Match 0 or 1 time and give nothing back
550  {n}+   Match exactly n times and give nothing back (redundant)
551  {n,}+  Match at least n times and give nothing back
552  {n,m}+ Match at least n but not more than m times and give nothing back
553
554 For instance,
555
556    'aaaa' =~ /a++a/
557
558 will never match, as the C<a++> will gobble up all the C<a>'s in the
559 string and won't leave any for the remaining part of the pattern. This
560 feature can be extremely useful to give perl hints about where it
561 shouldn't backtrack. For instance, the typical "match a double-quoted
562 string" problem can be most efficiently performed when written as:
563
564    /"(?:[^"\\]++|\\.)*+"/
565
566 as we know that if the final quote does not match, backtracking will not
567 help. See the independent subexpression
568 L</C<< (?>pattern) >>> for more details;
569 possessive quantifiers are just syntactic sugar for that construct. For
570 instance the above example could also be written as follows:
571
572    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
573
574 Note that the possessive quantifier modifier can not be be combined
575 with the non-greedy modifier. This is because it would make no sense.
576 Consider the follow equivalency table:
577
578     Illegal         Legal
579     ------------    ------
580     X??+            X{0}
581     X+?+            X{1}
582     X{min,max}?+    X{min}
583
584 =head3 Escape sequences
585
586 Because patterns are processed as double-quoted strings, the following
587 also work:
588
589  \t          tab                   (HT, TAB)
590  \n          newline               (LF, NL)
591  \r          return                (CR)
592  \f          form feed             (FF)
593  \a          alarm (bell)          (BEL)
594  \e          escape (think troff)  (ESC)
595  \cK         control char          (example: VT)
596  \x{}, \x00  character whose ordinal is the given hexadecimal number
597  \N{name}    named Unicode character or character sequence
598  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
599  \o{}, \000  character whose ordinal is the given octal number
600  \l          lowercase next char (think vi)
601  \u          uppercase next char (think vi)
602  \L          lowercase till \E (think vi)
603  \U          uppercase till \E (think vi)
604  \Q          quote (disable) pattern metacharacters till \E
605  \E          end either case modification or quoted section, think vi
606
607 Details are in L<perlop/Quote and Quote-like Operators>.
608
609 =head3 Character Classes and other Special Escapes
610
611 In addition, Perl defines the following:
612 X<\g> X<\k> X<\K> X<backreference>
613
614  Sequence   Note    Description
615   [...]     [1]  Match a character according to the rules of the
616                    bracketed character class defined by the "...".
617                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
618   [[:...:]] [2]  Match a character according to the rules of the POSIX
619                    character class "..." within the outer bracketed
620                    character class.  Example: [[:upper:]] matches any
621                    uppercase character.
622   (?[...])  [8]  Extended bracketed character class
623   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
624                    other connector punctuation chars plus Unicode
625                    marks)
626   \W        [3]  Match a non-"word" character
627   \s        [3]  Match a whitespace character
628   \S        [3]  Match a non-whitespace character
629   \d        [3]  Match a decimal digit character
630   \D        [3]  Match a non-digit character
631   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
632   \PP       [3]  Match non-P
633   \X        [4]  Match Unicode "eXtended grapheme cluster"
634   \C             Match a single C-language char (octet) even if that is
635                    part of a larger UTF-8 character.  Thus it breaks up
636                    characters into their UTF-8 bytes, so you may end up
637                    with malformed pieces of UTF-8.  Unsupported in
638                    lookbehind.
639   \1        [5]  Backreference to a specific capture group or buffer.
640                    '1' may actually be any positive integer.
641   \g1       [5]  Backreference to a specific or previous group,
642   \g{-1}    [5]  The number may be negative indicating a relative
643                    previous group and may optionally be wrapped in
644                    curly brackets for safer parsing.
645   \g{name}  [5]  Named backreference
646   \k<name>  [5]  Named backreference
647   \K        [6]  Keep the stuff left of the \K, don't include it in $&
648   \N        [7]  Any character but \n.  Not affected by /s modifier
649   \v        [3]  Vertical whitespace
650   \V        [3]  Not vertical whitespace
651   \h        [3]  Horizontal whitespace
652   \H        [3]  Not horizontal whitespace
653   \R        [4]  Linebreak
654
655 =over 4
656
657 =item [1]
658
659 See L<perlrecharclass/Bracketed Character Classes> for details.
660
661 =item [2]
662
663 See L<perlrecharclass/POSIX Character Classes> for details.
664
665 =item [3]
666
667 See L<perlrecharclass/Backslash sequences> for details.
668
669 =item [4]
670
671 See L<perlrebackslash/Misc> for details.
672
673 =item [5]
674
675 See L</Capture groups> below for details.
676
677 =item [6]
678
679 See L</Extended Patterns> below for details.
680
681 =item [7]
682
683 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
684 character or character sequence whose name is C<NAME>; and similarly
685 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
686 code point is I<hex>.  Otherwise it matches any character but C<\n>.
687
688 =item [8]
689
690 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
691
692 =back
693
694 =head3 Assertions
695
696 Perl defines the following zero-width assertions:
697 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
698 X<regexp, zero-width assertion>
699 X<regular expression, zero-width assertion>
700 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
701
702     \b  Match a word boundary
703     \B  Match except at a word boundary
704     \A  Match only at beginning of string
705     \Z  Match only at end of string, or before newline at the end
706     \z  Match only at end of string
707     \G  Match only at pos() (e.g. at the end-of-match position
708         of prior m//g)
709
710 A word boundary (C<\b>) is a spot between two characters
711 that has a C<\w> on one side of it and a C<\W> on the other side
712 of it (in either order), counting the imaginary characters off the
713 beginning and end of the string as matching a C<\W>.  (Within
714 character classes C<\b> represents backspace rather than a word
715 boundary, just as it normally does in any double-quoted string.)
716 The C<\A> and C<\Z> are just like "^" and "$", except that they
717 won't match multiple times when the C</m> modifier is used, while
718 "^" and "$" will match at every internal line boundary.  To match
719 the actual end of the string and not ignore an optional trailing
720 newline, use C<\z>.
721 X<\b> X<\A> X<\Z> X<\z> X</m>
722
723 The C<\G> assertion can be used to chain global matches (using
724 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
725 It is also useful when writing C<lex>-like scanners, when you have
726 several patterns that you want to match against consequent substrings
727 of your string; see the previous reference.  The actual location
728 where C<\G> will match can also be influenced by using C<pos()> as
729 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
730 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
731 is modified somewhat, in that contents to the left of C<\G> are
732 not counted when determining the length of the match. Thus the following
733 will not match forever:
734 X<\G>
735
736      my $string = 'ABC';
737      pos($string) = 1;
738      while ($string =~ /(.\G)/g) {
739          print $1;
740      }
741
742 It will print 'A' and then terminate, as it considers the match to
743 be zero-width, and thus will not match at the same position twice in a
744 row.
745
746 It is worth noting that C<\G> improperly used can result in an infinite
747 loop. Take care when using patterns that include C<\G> in an alternation.
748
749 =head3 Capture groups
750
751 The bracketing construct C<( ... )> creates capture groups (also referred to as
752 capture buffers). To refer to the current contents of a group later on, within
753 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
754 for the second, and so on.
755 This is called a I<backreference>.
756 X<regex, capture buffer> X<regexp, capture buffer>
757 X<regex, capture group> X<regexp, capture group>
758 X<regular expression, capture buffer> X<backreference>
759 X<regular expression, capture group> X<backreference>
760 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
761 X<named capture buffer> X<regular expression, named capture buffer>
762 X<named capture group> X<regular expression, named capture group>
763 X<%+> X<$+{name}> X<< \k<name> >>
764 There is no limit to the number of captured substrings that you may use.
765 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
766 a group did not match, the associated backreference won't match either. (This
767 can happen if the group is optional, or in a different branch of an
768 alternation.)
769 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
770 this form, described below.
771
772 You can also refer to capture groups relatively, by using a negative number, so
773 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
774 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
775 example:
776
777         /
778          (Y)            # group 1
779          (              # group 2
780             (X)         # group 3
781             \g{-1}      # backref to group 3
782             \g{-3}      # backref to group 1
783          )
784         /x
785
786 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
787 interpolate regexes into larger regexes and not have to worry about the
788 capture groups being renumbered.
789
790 You can dispense with numbers altogether and create named capture groups.
791 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
792 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
793 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
794 I<name> must not begin with a number, nor contain hyphens.
795 When different groups within the same pattern have the same name, any reference
796 to that name assumes the leftmost defined group.  Named groups count in
797 absolute and relative numbering, and so can also be referred to by those
798 numbers.
799 (It's possible to do things with named capture groups that would otherwise
800 require C<(??{})>.)
801
802 Capture group contents are dynamically scoped and available to you outside the
803 pattern until the end of the enclosing block or until the next successful
804 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
805 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
806 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
807
808 Braces are required in referring to named capture groups, but are optional for
809 absolute or relative numbered ones.  Braces are safer when creating a regex by
810 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
811 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
812 is probably not what you intended.
813
814 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
815 there were no named nor relative numbered capture groups.  Absolute numbered
816 groups were referred to using C<\1>,
817 C<\2>, etc., and this notation is still
818 accepted (and likely always will be).  But it leads to some ambiguities if
819 there are more than 9 capture groups, as C<\10> could mean either the tenth
820 capture group, or the character whose ordinal in octal is 010 (a backspace in
821 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
822 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
823 a backreference only if at least 11 left parentheses have opened before it.
824 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
825 There are several examples below that illustrate these perils.  You can avoid
826 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
827 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
828 digits padded with leading zeros, since a leading zero implies an octal
829 constant.
830
831 The C<\I<digit>> notation also works in certain circumstances outside
832 the pattern.  See L</Warning on \1 Instead of $1> below for details.
833
834 Examples:
835
836     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
837
838     /(.)\g1/                        # find first doubled char
839          and print "'$1' is the first doubled character\n";
840
841     /(?<char>.)\k<char>/            # ... a different way
842          and print "'$+{char}' is the first doubled character\n";
843
844     /(?'char'.)\g1/                 # ... mix and match
845          and print "'$1' is the first doubled character\n";
846
847     if (/Time: (..):(..):(..)/) {   # parse out values
848         $hours = $1;
849         $minutes = $2;
850         $seconds = $3;
851     }
852
853     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
854     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
855     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
856     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
857
858     $a = '(.)\1';        # Creates problems when concatenated.
859     $b = '(.)\g{1}';     # Avoids the problems.
860     "aa" =~ /${a}/;      # True
861     "aa" =~ /${b}/;      # True
862     "aa0" =~ /${a}0/;    # False!
863     "aa0" =~ /${b}0/;    # True
864     "aa\x08" =~ /${a}0/;  # True!
865     "aa\x08" =~ /${b}0/;  # False
866
867 Several special variables also refer back to portions of the previous
868 match.  C<$+> returns whatever the last bracket match matched.
869 C<$&> returns the entire matched string.  (At one point C<$0> did
870 also, but now it returns the name of the program.)  C<$`> returns
871 everything before the matched string.  C<$'> returns everything
872 after the matched string. And C<$^N> contains whatever was matched by
873 the most-recently closed group (submatch). C<$^N> can be used in
874 extended patterns (see below), for example to assign a submatch to a
875 variable.
876 X<$+> X<$^N> X<$&> X<$`> X<$'>
877
878 These special variables, like the C<%+> hash and the numbered match variables
879 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
880 until the end of the enclosing block or until the next successful
881 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
882 X<$+> X<$^N> X<$&> X<$`> X<$'>
883 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
884
885 B<NOTE>: Failed matches in Perl do not reset the match variables,
886 which makes it easier to write code that tests for a series of more
887 specific cases and remembers the best match.
888
889 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
890 beware that once Perl sees that you need one of C<$&>, C<$`>, or
891 C<$'> anywhere in the program, it has to provide them for every
892 pattern match.  This may substantially slow your program.
893
894 Perl uses the same mechanism to produce C<$1>, C<$2>, etc, so you also
895 pay a price for each pattern that contains capturing parentheses.
896 (To avoid this cost while retaining the grouping behaviour, use the
897 extended regular expression C<(?: ... )> instead.)  But if you never
898 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
899 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
900 if you can, but if you can't (and some algorithms really appreciate
901 them), once you've used them once, use them at will, because you've
902 already paid the price.
903 X<$&> X<$`> X<$'>
904
905 Perl 5.16 introduced a slightly more efficient mechanism that notes
906 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
907 thus may only need to copy part of the string.  Perl 5.20 introduced a
908 much more efficient copy-on-write mechanism which eliminates any slowdown.
909
910 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
911 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
912 and C<$'>, B<except> that they are only guaranteed to be defined after a
913 successful match that was executed with the C</p> (preserve) modifier.
914 The use of these variables incurs no global performance penalty, unlike
915 their punctuation char equivalents, however at the trade-off that you
916 have to tell perl when you want to use them.  As of Perl 5.20, these three
917 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
918 X</p> X<p modifier>
919
920 =head2 Quoting metacharacters
921
922 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
923 C<\w>, C<\n>.  Unlike some other regular expression languages, there
924 are no backslashed symbols that aren't alphanumeric.  So anything
925 that looks like \\, \(, \), \[, \], \{, or \} is always
926 interpreted as a literal character, not a metacharacter.  This was
927 once used in a common idiom to disable or quote the special meanings
928 of regular expression metacharacters in a string that you want to
929 use for a pattern. Simply quote all non-"word" characters:
930
931     $pattern =~ s/(\W)/\\$1/g;
932
933 (If C<use locale> is set, then this depends on the current locale.)
934 Today it is more common to use the quotemeta() function or the C<\Q>
935 metaquoting escape sequence to disable all metacharacters' special
936 meanings like this:
937
938     /$unquoted\Q$quoted\E$unquoted/
939
940 Beware that if you put literal backslashes (those not inside
941 interpolated variables) between C<\Q> and C<\E>, double-quotish
942 backslash interpolation may lead to confusing results.  If you
943 I<need> to use literal backslashes within C<\Q...\E>,
944 consult L<perlop/"Gory details of parsing quoted constructs">.
945
946 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
947
948 =head2 Extended Patterns
949
950 Perl also defines a consistent extension syntax for features not
951 found in standard tools like B<awk> and
952 B<lex>.  The syntax for most of these is a
953 pair of parentheses with a question mark as the first thing within
954 the parentheses.  The character after the question mark indicates
955 the extension.
956
957 The stability of these extensions varies widely.  Some have been
958 part of the core language for many years.  Others are experimental
959 and may change without warning or be completely removed.  Check
960 the documentation on an individual feature to verify its current
961 status.
962
963 A question mark was chosen for this and for the minimal-matching
964 construct because 1) question marks are rare in older regular
965 expressions, and 2) whenever you see one, you should stop and
966 "question" exactly what is going on.  That's psychology....
967
968 =over 4
969
970 =item C<(?#text)>
971 X<(?#)>
972
973 A comment.  The text is ignored.  If the C</x> modifier enables
974 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
975 the comment as soon as it sees a C<)>, so there is no way to put a literal
976 C<)> in the comment.
977
978 =item C<(?adlupimsx-imsx)>
979
980 =item C<(?^alupimsx)>
981 X<(?)> X<(?^)>
982
983 One or more embedded pattern-match modifiers, to be turned on (or
984 turned off, if preceded by C<->) for the remainder of the pattern or
985 the remainder of the enclosing pattern group (if any).
986
987 This is particularly useful for dynamic patterns, such as those read in from a
988 configuration file, taken from an argument, or specified in a table
989 somewhere.  Consider the case where some patterns want to be
990 case-sensitive and some do not:  The case-insensitive ones merely need to
991 include C<(?i)> at the front of the pattern.  For example:
992
993     $pattern = "foobar";
994     if ( /$pattern/i ) { }
995
996     # more flexible:
997
998     $pattern = "(?i)foobar";
999     if ( /$pattern/ ) { }
1000
1001 These modifiers are restored at the end of the enclosing group. For example,
1002
1003     ( (?i) blah ) \s+ \g1
1004
1005 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1006 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1007 modifier outside this group.
1008
1009 These modifiers do not carry over into named subpatterns called in the
1010 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1011 change the case-sensitivity of the "NAME" pattern.
1012
1013 Any of these modifiers can be set to apply globally to all regular
1014 expressions compiled within the scope of a C<use re>.  See
1015 L<re/"'/flags' mode">.
1016
1017 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1018 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1019 C<"d">) may follow the caret to override it.
1020 But a minus sign is not legal with it.
1021
1022 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1023 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1024 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1025 others, and a maximum of one (or two C<a>'s) may appear in the
1026 construct.  Thus, for
1027 example, C<(?-p)> will warn when compiled under C<use warnings>;
1028 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1029
1030 Note also that the C<p> modifier is special in that its presence
1031 anywhere in a pattern has a global effect.
1032
1033 =item C<(?:pattern)>
1034 X<(?:)>
1035
1036 =item C<(?adluimsx-imsx:pattern)>
1037
1038 =item C<(?^aluimsx:pattern)>
1039 X<(?^:)>
1040
1041 This is for clustering, not capturing; it groups subexpressions like
1042 "()", but doesn't make backreferences as "()" does.  So
1043
1044     @fields = split(/\b(?:a|b|c)\b/)
1045
1046 is like
1047
1048     @fields = split(/\b(a|b|c)\b/)
1049
1050 but doesn't spit out extra fields.  It's also cheaper not to capture
1051 characters if you don't need to.
1052
1053 Any letters between C<?> and C<:> act as flags modifiers as with
1054 C<(?adluimsx-imsx)>.  For example,
1055
1056     /(?s-i:more.*than).*million/i
1057
1058 is equivalent to the more verbose
1059
1060     /(?:(?s-i)more.*than).*million/i
1061
1062 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1063 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1064 flags (except C<"d">) may follow the caret, so
1065
1066     (?^x:foo)
1067
1068 is equivalent to
1069
1070     (?x-ims:foo)
1071
1072 The caret tells Perl that this cluster doesn't inherit the flags of any
1073 surrounding pattern, but uses the system defaults (C<d-imsx>),
1074 modified by any flags specified.
1075
1076 The caret allows for simpler stringification of compiled regular
1077 expressions.  These look like
1078
1079     (?^:pattern)
1080
1081 with any non-default flags appearing between the caret and the colon.
1082 A test that looks at such stringification thus doesn't need to have the
1083 system default flags hard-coded in it, just the caret.  If new flags are
1084 added to Perl, the meaning of the caret's expansion will change to include
1085 the default for those flags, so the test will still work, unchanged.
1086
1087 Specifying a negative flag after the caret is an error, as the flag is
1088 redundant.
1089
1090 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1091 to match at the beginning.
1092
1093 =item C<(?|pattern)>
1094 X<(?|)> X<Branch reset>
1095
1096 This is the "branch reset" pattern, which has the special property
1097 that the capture groups are numbered from the same starting point
1098 in each alternation branch. It is available starting from perl 5.10.0.
1099
1100 Capture groups are numbered from left to right, but inside this
1101 construct the numbering is restarted for each branch.
1102
1103 The numbering within each branch will be as normal, and any groups
1104 following this construct will be numbered as though the construct
1105 contained only one branch, that being the one with the most capture
1106 groups in it.
1107
1108 This construct is useful when you want to capture one of a
1109 number of alternative matches.
1110
1111 Consider the following pattern.  The numbers underneath show in
1112 which group the captured content will be stored.
1113
1114
1115     # before  ---------------branch-reset----------- after        
1116     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1117     # 1            2         2  3        2     3     4  
1118
1119 Be careful when using the branch reset pattern in combination with 
1120 named captures. Named captures are implemented as being aliases to 
1121 numbered groups holding the captures, and that interferes with the
1122 implementation of the branch reset pattern. If you are using named
1123 captures in a branch reset pattern, it's best to use the same names,
1124 in the same order, in each of the alternations:
1125
1126    /(?|  (?<a> x ) (?<b> y )
1127       |  (?<a> z ) (?<b> w )) /x
1128
1129 Not doing so may lead to surprises:
1130
1131   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1132   say $+ {a};   # Prints '12'
1133   say $+ {b};   # *Also* prints '12'.
1134
1135 The problem here is that both the group named C<< a >> and the group
1136 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1137
1138 =item Look-Around Assertions
1139 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1140
1141 Look-around assertions are zero-width patterns which match a specific
1142 pattern without including it in C<$&>. Positive assertions match when
1143 their subpattern matches, negative assertions match when their subpattern
1144 fails. Look-behind matches text up to the current match position,
1145 look-ahead matches text following the current match position.
1146
1147 =over 4
1148
1149 =item C<(?=pattern)>
1150 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1151
1152 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1153 matches a word followed by a tab, without including the tab in C<$&>.
1154
1155 =item C<(?!pattern)>
1156 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1157
1158 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1159 matches any occurrence of "foo" that isn't followed by "bar".  Note
1160 however that look-ahead and look-behind are NOT the same thing.  You cannot
1161 use this for look-behind.
1162
1163 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1164 will not do what you want.  That's because the C<(?!foo)> is just saying that
1165 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1166 match.  Use look-behind instead (see below).
1167
1168 =item C<(?<=pattern)> C<\K>
1169 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1170
1171 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1172 matches a word that follows a tab, without including the tab in C<$&>.
1173 Works only for fixed-width look-behind.
1174
1175 There is a special form of this construct, called C<\K>, which causes the
1176 regex engine to "keep" everything it had matched prior to the C<\K> and
1177 not include it in C<$&>. This effectively provides variable-length
1178 look-behind. The use of C<\K> inside of another look-around assertion
1179 is allowed, but the behaviour is currently not well defined.
1180
1181 For various reasons C<\K> may be significantly more efficient than the
1182 equivalent C<< (?<=...) >> construct, and it is especially useful in
1183 situations where you want to efficiently remove something following
1184 something else in a string. For instance
1185
1186   s/(foo)bar/$1/g;
1187
1188 can be rewritten as the much more efficient
1189
1190   s/foo\Kbar//g;
1191
1192 =item C<(?<!pattern)>
1193 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1194
1195 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1196 matches any occurrence of "foo" that does not follow "bar".  Works
1197 only for fixed-width look-behind.
1198
1199 =back
1200
1201 =item C<(?'NAME'pattern)>
1202
1203 =item C<< (?<NAME>pattern) >>
1204 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1205
1206 A named capture group. Identical in every respect to normal capturing
1207 parentheses C<()> but for the additional fact that the group
1208 can be referred to by name in various regular expression
1209 constructs (like C<\g{NAME}>) and can be accessed by name
1210 after a successful match via C<%+> or C<%->. See L<perlvar>
1211 for more details on the C<%+> and C<%-> hashes.
1212
1213 If multiple distinct capture groups have the same name then the
1214 $+{NAME} will refer to the leftmost defined group in the match.
1215
1216 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1217
1218 B<NOTE:> While the notation of this construct is the same as the similar
1219 function in .NET regexes, the behavior is not. In Perl the groups are
1220 numbered sequentially regardless of being named or not. Thus in the
1221 pattern
1222
1223   /(x)(?<foo>y)(z)/
1224
1225 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1226 the opposite which is what a .NET regex hacker might expect.
1227
1228 Currently NAME is restricted to simple identifiers only.
1229 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1230 its Unicode extension (see L<utf8>),
1231 though it isn't extended by the locale (see L<perllocale>).
1232
1233 B<NOTE:> In order to make things easier for programmers with experience
1234 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1235 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1236 support the use of single quotes as a delimiter for the name.
1237
1238 =item C<< \k<NAME> >>
1239
1240 =item C<< \k'NAME' >>
1241
1242 Named backreference. Similar to numeric backreferences, except that
1243 the group is designated by name and not number. If multiple groups
1244 have the same name then it refers to the leftmost defined group in
1245 the current match.
1246
1247 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1248 earlier in the pattern.
1249
1250 Both forms are equivalent.
1251
1252 B<NOTE:> In order to make things easier for programmers with experience
1253 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1254 may be used instead of C<< \k<NAME> >>.
1255
1256 =item C<(?{ code })>
1257 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1258
1259 B<WARNING>: This extended regular expression feature is considered
1260 experimental, and may be changed without notice. Code executed that
1261 has side effects may not perform identically from version to version
1262 due to the effect of future optimisations in the regex engine. The
1263 implementation of this feature was radically overhauled for the 5.18.0
1264 release, and its behaviour in earlier versions of perl was much buggier,
1265 especially in relation to parsing, lexical vars, scoping, recursion and
1266 reentrancy.
1267
1268 This zero-width assertion executes any embedded Perl code.  It always
1269 succeeds, and its return value is set as C<$^R>.
1270
1271 In literal patterns, the code is parsed at the same time as the
1272 surrounding code. While within the pattern, control is passed temporarily
1273 back to the perl parser, until the logically-balancing closing brace is
1274 encountered. This is similar to the way that an array index expression in
1275 a literal string is handled, for example
1276
1277     "abc$array[ 1 + f('[') + g()]def"
1278
1279 In particular, braces do not need to be balanced:
1280
1281     s/abc(?{ f('{'); })/def/
1282
1283 Even in a pattern that is interpolated and compiled at run-time, literal
1284 code blocks will be compiled once, at perl compile time; the following
1285 prints "ABCD":
1286
1287     print "D";
1288     my $qr = qr/(?{ BEGIN { print "A" } })/;
1289     my $foo = "foo";
1290     /$foo$qr(?{ BEGIN { print "B" } })/;
1291     BEGIN { print "C" }
1292
1293 In patterns where the text of the code is derived from run-time
1294 information rather than appearing literally in a source code /pattern/,
1295 the code is compiled at the same time that the pattern is compiled, and
1296 for reasons of security, C<use re 'eval'> must be in scope. This is to
1297 stop user-supplied patterns containing code snippets from being
1298 executable.
1299
1300 In situations where you need to enable this with C<use re 'eval'>, you should
1301 also have taint checking enabled.  Better yet, use the carefully
1302 constrained evaluation within a Safe compartment.  See L<perlsec> for
1303 details about both these mechanisms.
1304
1305 From the viewpoint of parsing, lexical variable scope and closures,
1306
1307     /AAA(?{ BBB })CCC/
1308
1309 behaves approximately like
1310
1311     /AAA/ && do { BBB } && /CCC/
1312
1313 Similarly,
1314
1315     qr/AAA(?{ BBB })CCC/
1316
1317 behaves approximately like
1318
1319     sub { /AAA/ && do { BBB } && /CCC/ }
1320
1321 In particular:
1322
1323     { my $i = 1; $r = qr/(?{ print $i })/ }
1324     my $i = 2;
1325     /$r/; # prints "1"
1326
1327 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1328 expression is matching against. You can also use C<pos()> to know what is
1329 the current position of matching within this string.
1330
1331 The code block introduces a new scope from the perspective of lexical
1332 variable declarations, but B<not> from the perspective of C<local> and
1333 similar localizing behaviours. So later code blocks within the same
1334 pattern will still see the values which were localized in earlier blocks.
1335 These accumulated localizations are undone either at the end of a
1336 successful match, or if the assertion is backtracked (compare
1337 L<"Backtracking">). For example,
1338
1339   $_ = 'a' x 8;
1340   m<
1341      (?{ $cnt = 0 })               # Initialize $cnt.
1342      (
1343        a
1344        (?{
1345            local $cnt = $cnt + 1;  # Update $cnt,
1346                                    # backtracking-safe.
1347        })
1348      )*
1349      aaaa
1350      (?{ $res = $cnt })            # On success copy to
1351                                    # non-localized location.
1352    >x;
1353
1354 will initially increment C<$cnt> up to 8; then during backtracking, its
1355 value will be unwound back to 4, which is the value assigned to C<$res>.
1356 At the end of the regex execution, $cnt will be wound back to its initial
1357 value of 0.
1358
1359 This assertion may be used as the condition in a
1360
1361     (?(condition)yes-pattern|no-pattern)
1362
1363 switch.  If I<not> used in this way, the result of evaluation of C<code>
1364 is put into the special variable C<$^R>.  This happens immediately, so
1365 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1366 regular expression.
1367
1368 The assignment to C<$^R> above is properly localized, so the old
1369 value of C<$^R> is restored if the assertion is backtracked; compare
1370 L<"Backtracking">.
1371
1372 Note that the special variable C<$^N>  is particularly useful with code
1373 blocks to capture the results of submatches in variables without having to
1374 keep track of the number of nested parentheses. For example:
1375
1376   $_ = "The brown fox jumps over the lazy dog";
1377   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1378   print "color = $color, animal = $animal\n";
1379
1380
1381 =item C<(??{ code })>
1382 X<(??{})>
1383 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1384
1385 B<WARNING>: This extended regular expression feature is considered
1386 experimental, and may be changed without notice. Code executed that
1387 has side effects may not perform identically from version to version
1388 due to the effect of future optimisations in the regex engine.
1389
1390 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1391 same way as a C<(?{ code })> code block as described above, except that
1392 its return value, rather than being assigned to C<$^R>, is treated as a
1393 pattern, compiled if it's a string (or used as-is if its a qr// object),
1394 then matched as if it were inserted instead of this construct.
1395
1396 During the matching of this sub-pattern, it has its own set of
1397 captures which are valid during the sub-match, but are discarded once
1398 control returns to the main pattern. For example, the following matches,
1399 with the inner pattern capturing "B" and matching "BB", while the outer
1400 pattern captures "A";
1401
1402     my $inner = '(.)\1';
1403     "ABBA" =~ /^(.)(??{ $inner })\1/;
1404     print $1; # prints "A";
1405
1406 Note that this means that  there is no way for the inner pattern to refer
1407 to a capture group defined outside.  (The code block itself can use C<$1>,
1408 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1409
1410     ('a' x 100)=~/(??{'(.)' x 100})/
1411
1412 I<will> match, it will I<not> set $1 on exit.
1413
1414 The following pattern matches a parenthesized group:
1415
1416  $re = qr{
1417             \(
1418             (?:
1419                (?> [^()]+ )  # Non-parens without backtracking
1420              |
1421                (??{ $re })   # Group with matching parens
1422             )*
1423             \)
1424          }x;
1425
1426 See also
1427 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1428 for a different, more efficient way to accomplish
1429 the same task.
1430
1431 Executing a postponed regular expression 50 times without consuming any
1432 input string will result in a fatal error.  The maximum depth is compiled
1433 into perl, so changing it requires a custom build.
1434
1435 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1436 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1437 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1438 X<regex, relative recursion>
1439
1440 Similar to C<(??{ code })> except that it does not involve executing any
1441 code or potentially compiling a returned pattern string; instead it treats
1442 the part of the current pattern contained within a specified capture group
1443 as an independent pattern that must match at the current position.
1444 Capture groups contained by the pattern will have the value as determined
1445 by the outermost recursion.
1446
1447 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1448 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1449 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1450 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1451 to be relative, with negative numbers indicating preceding capture groups
1452 and positive ones following. Thus C<(?-1)> refers to the most recently
1453 declared group, and C<(?+1)> indicates the next group to be declared.
1454 Note that the counting for relative recursion differs from that of
1455 relative backreferences, in that with recursion unclosed groups B<are>
1456 included.
1457
1458 The following pattern matches a function foo() which may contain
1459 balanced parentheses as the argument.
1460
1461   $re = qr{ (                   # paren group 1 (full function)
1462               foo
1463               (                 # paren group 2 (parens)
1464                 \(
1465                   (             # paren group 3 (contents of parens)
1466                   (?:
1467                    (?> [^()]+ ) # Non-parens without backtracking
1468                   |
1469                    (?2)         # Recurse to start of paren group 2
1470                   )*
1471                   )
1472                 \)
1473               )
1474             )
1475           }x;
1476
1477 If the pattern was used as follows
1478
1479     'foo(bar(baz)+baz(bop))'=~/$re/
1480         and print "\$1 = $1\n",
1481                   "\$2 = $2\n",
1482                   "\$3 = $3\n";
1483
1484 the output produced should be the following:
1485
1486     $1 = foo(bar(baz)+baz(bop))
1487     $2 = (bar(baz)+baz(bop))
1488     $3 = bar(baz)+baz(bop)
1489
1490 If there is no corresponding capture group defined, then it is a
1491 fatal error.  Recursing deeper than 50 times without consuming any input
1492 string will also result in a fatal error.  The maximum depth is compiled
1493 into perl, so changing it requires a custom build.
1494
1495 The following shows how using negative indexing can make it
1496 easier to embed recursive patterns inside of a C<qr//> construct
1497 for later use:
1498
1499     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1500     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1501        # do something here...
1502     }
1503
1504 B<Note> that this pattern does not behave the same way as the equivalent
1505 PCRE or Python construct of the same form. In Perl you can backtrack into
1506 a recursed group, in PCRE and Python the recursed into group is treated
1507 as atomic. Also, modifiers are resolved at compile time, so constructs
1508 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1509 be processed.
1510
1511 =item C<(?&NAME)>
1512 X<(?&NAME)>
1513
1514 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1515 parenthesis to recurse to is determined by name. If multiple parentheses have
1516 the same name, then it recurses to the leftmost.
1517
1518 It is an error to refer to a name that is not declared somewhere in the
1519 pattern.
1520
1521 B<NOTE:> In order to make things easier for programmers with experience
1522 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1523 may be used instead of C<< (?&NAME) >>.
1524
1525 =item C<(?(condition)yes-pattern|no-pattern)>
1526 X<(?()>
1527
1528 =item C<(?(condition)yes-pattern)>
1529
1530 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1531 a true value, matches C<no-pattern> otherwise. A missing pattern always
1532 matches.
1533
1534 C<(condition)> should be one of: 1) an integer in
1535 parentheses (which is valid if the corresponding pair of parentheses
1536 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1537 name in angle brackets or single quotes (which is valid if a group
1538 with the given name matched); or 4) the special symbol (R) (true when
1539 evaluated inside of recursion or eval). Additionally the R may be
1540 followed by a number, (which will be true when evaluated when recursing
1541 inside of the appropriate group), or by C<&NAME>, in which case it will
1542 be true only when evaluated during recursion in the named group.
1543
1544 Here's a summary of the possible predicates:
1545
1546 =over 4
1547
1548 =item (1) (2) ...
1549
1550 Checks if the numbered capturing group has matched something.
1551
1552 =item (<NAME>) ('NAME')
1553
1554 Checks if a group with the given name has matched something.
1555
1556 =item (?=...) (?!...) (?<=...) (?<!...)
1557
1558 Checks whether the pattern matches (or does not match, for the '!'
1559 variants).
1560
1561 =item (?{ CODE })
1562
1563 Treats the return value of the code block as the condition.
1564
1565 =item (R)
1566
1567 Checks if the expression has been evaluated inside of recursion.
1568
1569 =item (R1) (R2) ...
1570
1571 Checks if the expression has been evaluated while executing directly
1572 inside of the n-th capture group. This check is the regex equivalent of
1573
1574   if ((caller(0))[3] eq 'subname') { ... }
1575
1576 In other words, it does not check the full recursion stack.
1577
1578 =item (R&NAME)
1579
1580 Similar to C<(R1)>, this predicate checks to see if we're executing
1581 directly inside of the leftmost group with a given name (this is the same
1582 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1583 stack, but only the name of the innermost active recursion.
1584
1585 =item (DEFINE)
1586
1587 In this case, the yes-pattern is never directly executed, and no
1588 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1589 See below for details.
1590
1591 =back
1592
1593 For example:
1594
1595     m{ ( \( )?
1596        [^()]+
1597        (?(1) \) )
1598      }x
1599
1600 matches a chunk of non-parentheses, possibly included in parentheses
1601 themselves.
1602
1603 A special form is the C<(DEFINE)> predicate, which never executes its
1604 yes-pattern directly, and does not allow a no-pattern. This allows one to
1605 define subpatterns which will be executed only by the recursion mechanism.
1606 This way, you can define a set of regular expression rules that can be
1607 bundled into any pattern you choose.
1608
1609 It is recommended that for this usage you put the DEFINE block at the
1610 end of the pattern, and that you name any subpatterns defined within it.
1611
1612 Also, it's worth noting that patterns defined this way probably will
1613 not be as efficient, as the optimizer is not very clever about
1614 handling them.
1615
1616 An example of how this might be used is as follows:
1617
1618   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1619    (?(DEFINE)
1620      (?<NAME_PAT>....)
1621      (?<ADRESS_PAT>....)
1622    )/x
1623
1624 Note that capture groups matched inside of recursion are not accessible
1625 after the recursion returns, so the extra layer of capturing groups is
1626 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1627 C<$+{NAME}> would be.
1628
1629 Finally, keep in mind that subpatterns created inside a DEFINE block
1630 count towards the absolute and relative number of captures, so this:
1631
1632     my @captures = "a" =~ /(.)                  # First capture
1633                            (?(DEFINE)
1634                                (?<EXAMPLE> 1 )  # Second capture
1635                            )/x;
1636     say scalar @captures;
1637
1638 Will output 2, not 1. This is particularly important if you intend to
1639 compile the definitions with the C<qr//> operator, and later
1640 interpolate them in another pattern.
1641
1642 =item C<< (?>pattern) >>
1643 X<backtrack> X<backtracking> X<atomic> X<possessive>
1644
1645 An "independent" subexpression, one which matches the substring
1646 that a I<standalone> C<pattern> would match if anchored at the given
1647 position, and it matches I<nothing other than this substring>.  This
1648 construct is useful for optimizations of what would otherwise be
1649 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1650 It may also be useful in places where the "grab all you can, and do not
1651 give anything back" semantic is desirable.
1652
1653 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1654 (anchored at the beginning of string, as above) will match I<all>
1655 characters C<a> at the beginning of string, leaving no C<a> for
1656 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1657 since the match of the subgroup C<a*> is influenced by the following
1658 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1659 C<a*ab> will match fewer characters than a standalone C<a*>, since
1660 this makes the tail match.
1661
1662 C<< (?>pattern) >> does not disable backtracking altogether once it has
1663 matched. It is still possible to backtrack past the construct, but not
1664 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1665
1666 An effect similar to C<< (?>pattern) >> may be achieved by writing
1667 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1668 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1669 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1670 (The difference between these two constructs is that the second one
1671 uses a capturing group, thus shifting ordinals of backreferences
1672 in the rest of a regular expression.)
1673
1674 Consider this pattern:
1675
1676     m{ \(
1677           (
1678             [^()]+           # x+
1679           |
1680             \( [^()]* \)
1681           )+
1682        \)
1683      }x
1684
1685 That will efficiently match a nonempty group with matching parentheses
1686 two levels deep or less.  However, if there is no such group, it
1687 will take virtually forever on a long string.  That's because there
1688 are so many different ways to split a long string into several
1689 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1690 to a subpattern of the above pattern.  Consider how the pattern
1691 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1692 seconds, but that each extra letter doubles this time.  This
1693 exponential performance will make it appear that your program has
1694 hung.  However, a tiny change to this pattern
1695
1696     m{ \(
1697           (
1698             (?> [^()]+ )        # change x+ above to (?> x+ )
1699           |
1700             \( [^()]* \)
1701           )+
1702        \)
1703      }x
1704
1705 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1706 this yourself would be a productive exercise), but finishes in a fourth
1707 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1708 however, that, when this construct is followed by a
1709 quantifier, it currently triggers a warning message under
1710 the C<use warnings> pragma or B<-w> switch saying it
1711 C<"matches null string many times in regex">.
1712
1713 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1714 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1715 This was only 4 times slower on a string with 1000000 C<a>s.
1716
1717 The "grab all you can, and do not give anything back" semantic is desirable
1718 in many situations where on the first sight a simple C<()*> looks like
1719 the correct solution.  Suppose we parse text with comments being delimited
1720 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1721 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1722 the comment delimiter, because it may "give up" some whitespace if
1723 the remainder of the pattern can be made to match that way.  The correct
1724 answer is either one of these:
1725
1726     (?>#[ \t]*)
1727     #[ \t]*(?![ \t])
1728
1729 For example, to grab non-empty comments into $1, one should use either
1730 one of these:
1731
1732     / (?> \# [ \t]* ) (        .+ ) /x;
1733     /     \# [ \t]*   ( [^ \t] .* ) /x;
1734
1735 Which one you pick depends on which of these expressions better reflects
1736 the above specification of comments.
1737
1738 In some literature this construct is called "atomic matching" or
1739 "possessive matching".
1740
1741 Possessive quantifiers are equivalent to putting the item they are applied
1742 to inside of one of these constructs. The following equivalences apply:
1743
1744     Quantifier Form     Bracketing Form
1745     ---------------     ---------------
1746     PAT*+               (?>PAT*)
1747     PAT++               (?>PAT+)
1748     PAT?+               (?>PAT?)
1749     PAT{min,max}+       (?>PAT{min,max})
1750
1751 =item C<(?[ ])>
1752
1753 See L<perlrecharclass/Extended Bracketed Character Classes>.
1754
1755 =back
1756
1757 =head2 Special Backtracking Control Verbs
1758
1759 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1760 otherwise stated the ARG argument is optional; in some cases, it is
1761 forbidden.
1762
1763 Any pattern containing a special backtracking verb that allows an argument
1764 has the special behaviour that when executed it sets the current package's
1765 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1766 rules apply:
1767
1768 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1769 verb pattern, if the verb was involved in the failure of the match. If the
1770 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1771 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1772 none. Also, the C<$REGMARK> variable will be set to FALSE.
1773
1774 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1775 the C<$REGMARK> variable will be set to the name of the last
1776 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1777 C<(*MARK:NAME)> verb below for more details.
1778
1779 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1780 and most other regex-related variables. They are not local to a scope, nor
1781 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1782 Use C<local> to localize changes to them to a specific scope if necessary.
1783
1784 If a pattern does not contain a special backtracking verb that allows an
1785 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1786
1787 =over 3
1788
1789 =item Verbs that take an argument
1790
1791 =over 4
1792
1793 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1794 X<(*PRUNE)> X<(*PRUNE:NAME)>
1795
1796 This zero-width pattern prunes the backtracking tree at the current point
1797 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1798 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1799 A may backtrack as necessary to match. Once it is reached, matching
1800 continues in B, which may also backtrack as necessary; however, should B
1801 not match, then no further backtracking will take place, and the pattern
1802 will fail outright at the current starting position.
1803
1804 The following example counts all the possible matching strings in a
1805 pattern (without actually matching any of them).
1806
1807     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1808     print "Count=$count\n";
1809
1810 which produces:
1811
1812     aaab
1813     aaa
1814     aa
1815     a
1816     aab
1817     aa
1818     a
1819     ab
1820     a
1821     Count=9
1822
1823 If we add a C<(*PRUNE)> before the count like the following
1824
1825     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1826     print "Count=$count\n";
1827
1828 we prevent backtracking and find the count of the longest matching string
1829 at each matching starting point like so:
1830
1831     aaab
1832     aab
1833     ab
1834     Count=3
1835
1836 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1837
1838 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1839 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1840 replaced with a C<< (?>pattern) >> with no functional difference; however,
1841 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1842 C<< (?>pattern) >> alone.
1843
1844 =item C<(*SKIP)> C<(*SKIP:NAME)>
1845 X<(*SKIP)>
1846
1847 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1848 failure it also signifies that whatever text that was matched leading up
1849 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1850 of this pattern. This effectively means that the regex engine "skips" forward
1851 to this position on failure and tries to match again, (assuming that
1852 there is sufficient room to match).
1853
1854 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1855 C<(*MARK:NAME)> was encountered while matching, then it is that position
1856 which is used as the "skip point". If no C<(*MARK)> of that name was
1857 encountered, then the C<(*SKIP)> operator has no effect. When used
1858 without a name the "skip point" is where the match point was when
1859 executing the (*SKIP) pattern.
1860
1861 Compare the following to the examples in C<(*PRUNE)>; note the string
1862 is twice as long:
1863
1864  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1865  print "Count=$count\n";
1866
1867 outputs
1868
1869     aaab
1870     aaab
1871     Count=2
1872
1873 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1874 executed, the next starting point will be where the cursor was when the
1875 C<(*SKIP)> was executed.
1876
1877 =item C<(*MARK:NAME)> C<(*:NAME)>
1878 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1879
1880 This zero-width pattern can be used to mark the point reached in a string
1881 when a certain part of the pattern has been successfully matched. This
1882 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1883 forward to that point if backtracked into on failure. Any number of
1884 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1885
1886 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1887 can be used to "label" a pattern branch, so that after matching, the
1888 program can determine which branches of the pattern were involved in the
1889 match.
1890
1891 When a match is successful, the C<$REGMARK> variable will be set to the
1892 name of the most recently executed C<(*MARK:NAME)> that was involved
1893 in the match.
1894
1895 This can be used to determine which branch of a pattern was matched
1896 without using a separate capture group for each branch, which in turn
1897 can result in a performance improvement, as perl cannot optimize
1898 C</(?:(x)|(y)|(z))/> as efficiently as something like
1899 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1900
1901 When a match has failed, and unless another verb has been involved in
1902 failing the match and has provided its own name to use, the C<$REGERROR>
1903 variable will be set to the name of the most recently executed
1904 C<(*MARK:NAME)>.
1905
1906 See L</(*SKIP)> for more details.
1907
1908 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1909
1910 =item C<(*THEN)> C<(*THEN:NAME)>
1911
1912 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1913 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1914 failure, it causes the regex engine to try the next alternation in the
1915 innermost enclosing group (capturing or otherwise) that has alternations.
1916 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1917 count as an alternation, as far as C<(*THEN)> is concerned.
1918
1919 Its name comes from the observation that this operation combined with the
1920 alternation operator (C<|>) can be used to create what is essentially a
1921 pattern-based if/then/else block:
1922
1923   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1924
1925 Note that if this operator is used and NOT inside of an alternation then
1926 it acts exactly like the C<(*PRUNE)> operator.
1927
1928   / A (*PRUNE) B /
1929
1930 is the same as
1931
1932   / A (*THEN) B /
1933
1934 but
1935
1936   / ( A (*THEN) B | C ) /
1937
1938 is not the same as
1939
1940   / ( A (*PRUNE) B | C ) /
1941
1942 as after matching the A but failing on the B the C<(*THEN)> verb will
1943 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1944
1945 =back
1946
1947 =item Verbs without an argument
1948
1949 =over 4
1950
1951 =item C<(*COMMIT)>
1952 X<(*COMMIT)>
1953
1954 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1955 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1956 into on failure it causes the match to fail outright. No further attempts
1957 to find a valid match by advancing the start pointer will occur again.
1958 For example,
1959
1960  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1961  print "Count=$count\n";
1962
1963 outputs
1964
1965     aaab
1966     Count=1
1967
1968 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1969 does not match, the regex engine will not try any further matching on the
1970 rest of the string.
1971
1972 =item C<(*FAIL)> C<(*F)>
1973 X<(*FAIL)> X<(*F)>
1974
1975 This pattern matches nothing and always fails. It can be used to force the
1976 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1977 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1978
1979 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1980
1981 =item C<(*ACCEPT)>
1982 X<(*ACCEPT)>
1983
1984 This pattern matches nothing and causes the end of successful matching at
1985 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1986 whether there is actually more to match in the string. When inside of a
1987 nested pattern, such as recursion, or in a subpattern dynamically generated
1988 via C<(??{})>, only the innermost pattern is ended immediately.
1989
1990 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1991 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1992 For instance:
1993
1994   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1995
1996 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1997 be set. If another branch in the inner parentheses was matched, such as in the
1998 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1999
2000 =back
2001
2002 =back
2003
2004 =head2 Backtracking
2005 X<backtrack> X<backtracking>
2006
2007 NOTE: This section presents an abstract approximation of regular
2008 expression behavior.  For a more rigorous (and complicated) view of
2009 the rules involved in selecting a match among possible alternatives,
2010 see L<Combining RE Pieces>.
2011
2012 A fundamental feature of regular expression matching involves the
2013 notion called I<backtracking>, which is currently used (when needed)
2014 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2015 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2016 internally, but the general principle outlined here is valid.
2017
2018 For a regular expression to match, the I<entire> regular expression must
2019 match, not just part of it.  So if the beginning of a pattern containing a
2020 quantifier succeeds in a way that causes later parts in the pattern to
2021 fail, the matching engine backs up and recalculates the beginning
2022 part--that's why it's called backtracking.
2023
2024 Here is an example of backtracking:  Let's say you want to find the
2025 word following "foo" in the string "Food is on the foo table.":
2026
2027     $_ = "Food is on the foo table.";
2028     if ( /\b(foo)\s+(\w+)/i ) {
2029         print "$2 follows $1.\n";
2030     }
2031
2032 When the match runs, the first part of the regular expression (C<\b(foo)>)
2033 finds a possible match right at the beginning of the string, and loads up
2034 $1 with "Foo".  However, as soon as the matching engine sees that there's
2035 no whitespace following the "Foo" that it had saved in $1, it realizes its
2036 mistake and starts over again one character after where it had the
2037 tentative match.  This time it goes all the way until the next occurrence
2038 of "foo". The complete regular expression matches this time, and you get
2039 the expected output of "table follows foo."
2040
2041 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2042 everything between "foo" and "bar".  Initially, you write something
2043 like this:
2044
2045     $_ =  "The food is under the bar in the barn.";
2046     if ( /foo(.*)bar/ ) {
2047         print "got <$1>\n";
2048     }
2049
2050 Which perhaps unexpectedly yields:
2051
2052   got <d is under the bar in the >
2053
2054 That's because C<.*> was greedy, so you get everything between the
2055 I<first> "foo" and the I<last> "bar".  Here it's more effective
2056 to use minimal matching to make sure you get the text between a "foo"
2057 and the first "bar" thereafter.
2058
2059     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2060   got <d is under the >
2061
2062 Here's another example. Let's say you'd like to match a number at the end
2063 of a string, and you also want to keep the preceding part of the match.
2064 So you write this:
2065
2066     $_ = "I have 2 numbers: 53147";
2067     if ( /(.*)(\d*)/ ) {                                # Wrong!
2068         print "Beginning is <$1>, number is <$2>.\n";
2069     }
2070
2071 That won't work at all, because C<.*> was greedy and gobbled up the
2072 whole string. As C<\d*> can match on an empty string the complete
2073 regular expression matched successfully.
2074
2075     Beginning is <I have 2 numbers: 53147>, number is <>.
2076
2077 Here are some variants, most of which don't work:
2078
2079     $_ = "I have 2 numbers: 53147";
2080     @pats = qw{
2081         (.*)(\d*)
2082         (.*)(\d+)
2083         (.*?)(\d*)
2084         (.*?)(\d+)
2085         (.*)(\d+)$
2086         (.*?)(\d+)$
2087         (.*)\b(\d+)$
2088         (.*\D)(\d+)$
2089     };
2090
2091     for $pat (@pats) {
2092         printf "%-12s ", $pat;
2093         if ( /$pat/ ) {
2094             print "<$1> <$2>\n";
2095         } else {
2096             print "FAIL\n";
2097         }
2098     }
2099
2100 That will print out:
2101
2102     (.*)(\d*)    <I have 2 numbers: 53147> <>
2103     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2104     (.*?)(\d*)   <> <>
2105     (.*?)(\d+)   <I have > <2>
2106     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2107     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2108     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2109     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2110
2111 As you see, this can be a bit tricky.  It's important to realize that a
2112 regular expression is merely a set of assertions that gives a definition
2113 of success.  There may be 0, 1, or several different ways that the
2114 definition might succeed against a particular string.  And if there are
2115 multiple ways it might succeed, you need to understand backtracking to
2116 know which variety of success you will achieve.
2117
2118 When using look-ahead assertions and negations, this can all get even
2119 trickier.  Imagine you'd like to find a sequence of non-digits not
2120 followed by "123".  You might try to write that as
2121
2122     $_ = "ABC123";
2123     if ( /^\D*(?!123)/ ) {                # Wrong!
2124         print "Yup, no 123 in $_\n";
2125     }
2126
2127 But that isn't going to match; at least, not the way you're hoping.  It
2128 claims that there is no 123 in the string.  Here's a clearer picture of
2129 why that pattern matches, contrary to popular expectations:
2130
2131     $x = 'ABC123';
2132     $y = 'ABC445';
2133
2134     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2135     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2136
2137     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2138     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2139
2140 This prints
2141
2142     2: got ABC
2143     3: got AB
2144     4: got ABC
2145
2146 You might have expected test 3 to fail because it seems to a more
2147 general purpose version of test 1.  The important difference between
2148 them is that test 3 contains a quantifier (C<\D*>) and so can use
2149 backtracking, whereas test 1 will not.  What's happening is
2150 that you've asked "Is it true that at the start of $x, following 0 or more
2151 non-digits, you have something that's not 123?"  If the pattern matcher had
2152 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2153 fail.
2154
2155 The search engine will initially match C<\D*> with "ABC".  Then it will
2156 try to match C<(?!123)> with "123", which fails.  But because
2157 a quantifier (C<\D*>) has been used in the regular expression, the
2158 search engine can backtrack and retry the match differently
2159 in the hope of matching the complete regular expression.
2160
2161 The pattern really, I<really> wants to succeed, so it uses the
2162 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2163 time.  Now there's indeed something following "AB" that is not
2164 "123".  It's "C123", which suffices.
2165
2166 We can deal with this by using both an assertion and a negation.
2167 We'll say that the first part in $1 must be followed both by a digit
2168 and by something that's not "123".  Remember that the look-aheads
2169 are zero-width expressions--they only look, but don't consume any
2170 of the string in their match.  So rewriting this way produces what
2171 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2172
2173     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2174     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2175
2176     6: got ABC
2177
2178 In other words, the two zero-width assertions next to each other work as though
2179 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2180 matches only if you're at the beginning of the line AND the end of the
2181 line simultaneously.  The deeper underlying truth is that juxtaposition in
2182 regular expressions always means AND, except when you write an explicit OR
2183 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2184 although the attempted matches are made at different positions because "a"
2185 is not a zero-width assertion, but a one-width assertion.
2186
2187 B<WARNING>: Particularly complicated regular expressions can take
2188 exponential time to solve because of the immense number of possible
2189 ways they can use backtracking to try for a match.  For example, without
2190 internal optimizations done by the regular expression engine, this will
2191 take a painfully long time to run:
2192
2193     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2194
2195 And if you used C<*>'s in the internal groups instead of limiting them
2196 to 0 through 5 matches, then it would take forever--or until you ran
2197 out of stack space.  Moreover, these internal optimizations are not
2198 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2199 on the external group, no current optimization is applicable, and the
2200 match takes a long time to finish.
2201
2202 A powerful tool for optimizing such beasts is what is known as an
2203 "independent group",
2204 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2205 zero-length look-ahead/look-behind assertions will not backtrack to make
2206 the tail match, since they are in "logical" context: only
2207 whether they match is considered relevant.  For an example
2208 where side-effects of look-ahead I<might> have influenced the
2209 following match, see L</C<< (?>pattern) >>>.
2210
2211 =head2 Version 8 Regular Expressions
2212 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2213
2214 In case you're not familiar with the "regular" Version 8 regex
2215 routines, here are the pattern-matching rules not described above.
2216
2217 Any single character matches itself, unless it is a I<metacharacter>
2218 with a special meaning described here or above.  You can cause
2219 characters that normally function as metacharacters to be interpreted
2220 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2221 character; "\\" matches a "\"). This escape mechanism is also required
2222 for the character used as the pattern delimiter.
2223
2224 A series of characters matches that series of characters in the target
2225 string, so the pattern C<blurfl> would match "blurfl" in the target
2226 string.
2227
2228 You can specify a character class, by enclosing a list of characters
2229 in C<[]>, which will match any character from the list.  If the
2230 first character after the "[" is "^", the class matches any character not
2231 in the list.  Within a list, the "-" character specifies a
2232 range, so that C<a-z> represents all characters between "a" and "z",
2233 inclusive.  If you want either "-" or "]" itself to be a member of a
2234 class, put it at the start of the list (possibly after a "^"), or
2235 escape it with a backslash.  "-" is also taken literally when it is
2236 at the end of the list, just before the closing "]".  (The
2237 following all specify the same class of three characters: C<[-az]>,
2238 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2239 specifies a class containing twenty-six characters, even on EBCDIC-based
2240 character sets.)  Also, if you try to use the character
2241 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2242 a range, the "-" is understood literally.
2243
2244 Note also that the whole range idea is rather unportable between
2245 character sets--and even within character sets they may cause results
2246 you probably didn't expect.  A sound principle is to use only ranges
2247 that begin from and end at either alphabetics of equal case ([a-e],
2248 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2249 spell out the character sets in full.
2250
2251 Characters may be specified using a metacharacter syntax much like that
2252 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2253 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2254 of three octal digits, matches the character whose coded character set value
2255 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2256 matches the character whose ordinal is I<nn>. The expression \cI<x>
2257 matches the character control-I<x>.  Finally, the "." metacharacter
2258 matches any character except "\n" (unless you use C</s>).
2259
2260 You can specify a series of alternatives for a pattern using "|" to
2261 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2262 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2263 first alternative includes everything from the last pattern delimiter
2264 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2265 the last alternative contains everything from the last "|" to the next
2266 closing pattern delimiter.  That's why it's common practice to include
2267 alternatives in parentheses: to minimize confusion about where they
2268 start and end.
2269
2270 Alternatives are tried from left to right, so the first
2271 alternative found for which the entire expression matches, is the one that
2272 is chosen. This means that alternatives are not necessarily greedy. For
2273 example: when matching C<foo|foot> against "barefoot", only the "foo"
2274 part will match, as that is the first alternative tried, and it successfully
2275 matches the target string. (This might not seem important, but it is
2276 important when you are capturing matched text using parentheses.)
2277
2278 Also remember that "|" is interpreted as a literal within square brackets,
2279 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2280
2281 Within a pattern, you may designate subpatterns for later reference
2282 by enclosing them in parentheses, and you may refer back to the
2283 I<n>th subpattern later in the pattern using the metacharacter
2284 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2285 of their opening parenthesis.  A backreference matches whatever
2286 actually matched the subpattern in the string being examined, not
2287 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2288 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2289 1 matched "0x", even though the rule C<0|0x> could potentially match
2290 the leading 0 in the second number.
2291
2292 =head2 Warning on \1 Instead of $1
2293
2294 Some people get too used to writing things like:
2295
2296     $pattern =~ s/(\W)/\\\1/g;
2297
2298 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2299 shocking the
2300 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2301 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2302 the usual double-quoted string means a control-A.  The customary Unix
2303 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2304 of doing that, you get yourself into trouble if you then add an C</e>
2305 modifier.
2306
2307     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2308
2309 Or if you try to do
2310
2311     s/(\d+)/\1000/;
2312
2313 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2314 C<${1}000>.  The operation of interpolation should not be confused
2315 with the operation of matching a backreference.  Certainly they mean two
2316 different things on the I<left> side of the C<s///>.
2317
2318 =head2 Repeated Patterns Matching a Zero-length Substring
2319
2320 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2321
2322 Regular expressions provide a terse and powerful programming language.  As
2323 with most other power tools, power comes together with the ability
2324 to wreak havoc.
2325
2326 A common abuse of this power stems from the ability to make infinite
2327 loops using regular expressions, with something as innocuous as:
2328
2329     'foo' =~ m{ ( o? )* }x;
2330
2331 The C<o?> matches at the beginning of C<'foo'>, and since the position
2332 in the string is not moved by the match, C<o?> would match again and again
2333 because of the C<*> quantifier.  Another common way to create a similar cycle
2334 is with the looping modifier C<//g>:
2335
2336     @matches = ( 'foo' =~ m{ o? }xg );
2337
2338 or
2339
2340     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2341
2342 or the loop implied by split().
2343
2344 However, long experience has shown that many programming tasks may
2345 be significantly simplified by using repeated subexpressions that
2346 may match zero-length substrings.  Here's a simple example being:
2347
2348     @chars = split //, $string;           # // is not magic in split
2349     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2350
2351 Thus Perl allows such constructs, by I<forcefully breaking
2352 the infinite loop>.  The rules for this are different for lower-level
2353 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2354 ones like the C</g> modifier or split() operator.
2355
2356 The lower-level loops are I<interrupted> (that is, the loop is
2357 broken) when Perl detects that a repeated expression matched a
2358 zero-length substring.   Thus
2359
2360    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2361
2362 is made equivalent to
2363
2364    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2365
2366 For example, this program
2367
2368    #!perl -l
2369    "aaaaab" =~ /
2370      (?:
2371         a                 # non-zero
2372         |                 # or
2373        (?{print "hello"}) # print hello whenever this
2374                           #    branch is tried
2375        (?=(b))            # zero-width assertion
2376      )*  # any number of times
2377     /x;
2378    print $&;
2379    print $1;
2380
2381 prints
2382
2383    hello
2384    aaaaa
2385    b
2386
2387 Notice that "hello" is only printed once, as when Perl sees that the sixth
2388 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2389 the C<*>.
2390
2391 The higher-level loops preserve an additional state between iterations:
2392 whether the last match was zero-length.  To break the loop, the following
2393 match after a zero-length match is prohibited to have a length of zero.
2394 This prohibition interacts with backtracking (see L<"Backtracking">),
2395 and so the I<second best> match is chosen if the I<best> match is of
2396 zero length.
2397
2398 For example:
2399
2400     $_ = 'bar';
2401     s/\w??/<$&>/g;
2402
2403 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2404 match given by non-greedy C<??> is the zero-length match, and the I<second
2405 best> match is what is matched by C<\w>.  Thus zero-length matches
2406 alternate with one-character-long matches.
2407
2408 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2409 position one notch further in the string.
2410
2411 The additional state of being I<matched with zero-length> is associated with
2412 the matched string, and is reset by each assignment to pos().
2413 Zero-length matches at the end of the previous match are ignored
2414 during C<split>.
2415
2416 =head2 Combining RE Pieces
2417
2418 Each of the elementary pieces of regular expressions which were described
2419 before (such as C<ab> or C<\Z>) could match at most one substring
2420 at the given position of the input string.  However, in a typical regular
2421 expression these elementary pieces are combined into more complicated
2422 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2423 (in these examples C<S> and C<T> are regular subexpressions).
2424
2425 Such combinations can include alternatives, leading to a problem of choice:
2426 if we match a regular expression C<a|ab> against C<"abc">, will it match
2427 substring C<"a"> or C<"ab">?  One way to describe which substring is
2428 actually matched is the concept of backtracking (see L<"Backtracking">).
2429 However, this description is too low-level and makes you think
2430 in terms of a particular implementation.
2431
2432 Another description starts with notions of "better"/"worse".  All the
2433 substrings which may be matched by the given regular expression can be
2434 sorted from the "best" match to the "worst" match, and it is the "best"
2435 match which is chosen.  This substitutes the question of "what is chosen?"
2436 by the question of "which matches are better, and which are worse?".
2437
2438 Again, for elementary pieces there is no such question, since at most
2439 one match at a given position is possible.  This section describes the
2440 notion of better/worse for combining operators.  In the description
2441 below C<S> and C<T> are regular subexpressions.
2442
2443 =over 4
2444
2445 =item C<ST>
2446
2447 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2448 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2449 which can be matched by C<T>.
2450
2451 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2452 match than C<A'B'>.
2453
2454 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2455 C<B> is a better match for C<T> than C<B'>.
2456
2457 =item C<S|T>
2458
2459 When C<S> can match, it is a better match than when only C<T> can match.
2460
2461 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2462 two matches for C<T>.
2463
2464 =item C<S{REPEAT_COUNT}>
2465
2466 Matches as C<SSS...S> (repeated as many times as necessary).
2467
2468 =item C<S{min,max}>
2469
2470 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2471
2472 =item C<S{min,max}?>
2473
2474 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2475
2476 =item C<S?>, C<S*>, C<S+>
2477
2478 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2479
2480 =item C<S??>, C<S*?>, C<S+?>
2481
2482 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2483
2484 =item C<< (?>S) >>
2485
2486 Matches the best match for C<S> and only that.
2487
2488 =item C<(?=S)>, C<(?<=S)>
2489
2490 Only the best match for C<S> is considered.  (This is important only if
2491 C<S> has capturing parentheses, and backreferences are used somewhere
2492 else in the whole regular expression.)
2493
2494 =item C<(?!S)>, C<(?<!S)>
2495
2496 For this grouping operator there is no need to describe the ordering, since
2497 only whether or not C<S> can match is important.
2498
2499 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2500
2501 The ordering is the same as for the regular expression which is
2502 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2503
2504 =item C<(?(condition)yes-pattern|no-pattern)>
2505
2506 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2507 already determined.  The ordering of the matches is the same as for the
2508 chosen subexpression.
2509
2510 =back
2511
2512 The above recipes describe the ordering of matches I<at a given position>.
2513 One more rule is needed to understand how a match is determined for the
2514 whole regular expression: a match at an earlier position is always better
2515 than a match at a later position.
2516
2517 =head2 Creating Custom RE Engines
2518
2519 As of Perl 5.10.0, one can create custom regular expression engines.  This
2520 is not for the faint of heart, as they have to plug in at the C level.  See
2521 L<perlreapi> for more details.
2522
2523 As an alternative, overloaded constants (see L<overload>) provide a simple
2524 way to extend the functionality of the RE engine, by substituting one
2525 pattern for another.
2526
2527 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2528 matches at a boundary between whitespace characters and non-whitespace
2529 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2530 at these positions, so we want to have each C<\Y|> in the place of the
2531 more complicated version.  We can create a module C<customre> to do
2532 this:
2533
2534     package customre;
2535     use overload;
2536
2537     sub import {
2538       shift;
2539       die "No argument to customre::import allowed" if @_;
2540       overload::constant 'qr' => \&convert;
2541     }
2542
2543     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2544
2545     # We must also take care of not escaping the legitimate \\Y|
2546     # sequence, hence the presence of '\\' in the conversion rules.
2547     my %rules = ( '\\' => '\\\\',
2548                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2549     sub convert {
2550       my $re = shift;
2551       $re =~ s{
2552                 \\ ( \\ | Y . )
2553               }
2554               { $rules{$1} or invalid($re,$1) }sgex;
2555       return $re;
2556     }
2557
2558 Now C<use customre> enables the new escape in constant regular
2559 expressions, i.e., those without any runtime variable interpolations.
2560 As documented in L<overload>, this conversion will work only over
2561 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2562 part of this regular expression needs to be converted explicitly
2563 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2564
2565     use customre;
2566     $re = <>;
2567     chomp $re;
2568     $re = customre::convert $re;
2569     /\Y|$re\Y|/;
2570
2571 =head2 PCRE/Python Support
2572
2573 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2574 to the regex syntax. While Perl programmers are encouraged to use the
2575 Perl-specific syntax, the following are also accepted:
2576
2577 =over 4
2578
2579 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2580
2581 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2582
2583 =item C<< (?P=NAME) >>
2584
2585 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2586
2587 =item C<< (?P>NAME) >>
2588
2589 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2590
2591 =back
2592
2593 =head1 BUGS
2594
2595 Many regular expression constructs don't work on EBCDIC platforms.
2596
2597 There are a number of issues with regard to case-insensitive matching
2598 in Unicode rules.  See C<i> under L</Modifiers> above.
2599
2600 This document varies from difficult to understand to completely
2601 and utterly opaque.  The wandering prose riddled with jargon is
2602 hard to fathom in several places.
2603
2604 This document needs a rewrite that separates the tutorial content
2605 from the reference content.
2606
2607 =head1 SEE ALSO
2608
2609 L<perlrequick>.
2610
2611 L<perlretut>.
2612
2613 L<perlop/"Regexp Quote-Like Operators">.
2614
2615 L<perlop/"Gory details of parsing quoted constructs">.
2616
2617 L<perlfaq6>.
2618
2619 L<perlfunc/pos>.
2620
2621 L<perllocale>.
2622
2623 L<perlebcdic>.
2624
2625 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2626 by O'Reilly and Associates.