This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
various pod tweaks (from M.J.T. Guy <mjtg@cus.cam.ac.uk>)
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2
3 perlop - Perl operators and precedence
4
5 =head1 SYNOPSIS
6
7 Perl operators have the following associativity and precedence,
8 listed from highest precedence to lowest.  Operators borrowed from
9 C keep the same precedence relationship with each other, even where
10 C's precedence is slightly screwy.  (This makes learning Perl easier
11 for C folks.)  With very few exceptions, these all operate on scalar
12 values only, not array values.
13
14     left        terms and list operators (leftward)
15     left        ->
16     nonassoc    ++ --
17     right       **
18     right       ! ~ \ and unary + and -
19     left        =~ !~
20     left        * / % x
21     left        + - .
22     left        << >>
23     nonassoc    named unary operators
24     nonassoc    < > <= >= lt gt le ge
25     nonassoc    == != <=> eq ne cmp
26     left        &
27     left        | ^
28     left        &&
29     left        ||
30     nonassoc    ..  ...
31     right       ?:
32     right       = += -= *= etc.
33     left        , =>
34     nonassoc    list operators (rightward)
35     right       not
36     left        and
37     left        or xor
38
39 In the following sections, these operators are covered in precedence order.
40
41 Many operators can be overloaded for objects.  See L<overload>.
42
43 =head1 DESCRIPTION
44
45 =head2 Terms and List Operators (Leftward)
46
47 A TERM has the highest precedence in Perl.  They include variables,
48 quote and quote-like operators, any expression in parentheses,
49 and any function whose arguments are parenthesized.  Actually, there
50 aren't really functions in this sense, just list operators and unary
51 operators behaving as functions because you put parentheses around
52 the arguments.  These are all documented in L<perlfunc>.
53
54 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
55 is followed by a left parenthesis as the next token, the operator and
56 arguments within parentheses are taken to be of highest precedence,
57 just like a normal function call.
58
59 In the absence of parentheses, the precedence of list operators such as
60 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
61 whether you are looking at the left side or the right side of the operator.
62 For example, in
63
64     @ary = (1, 3, sort 4, 2);
65     print @ary;         # prints 1324
66
67 the commas on the right of the sort are evaluated before the sort,
68 but the commas on the left are evaluated after.  In other words,
69 list operators tend to gobble up all arguments that follow, and
70 then act like a simple TERM with regard to the preceding expression.
71 Be careful with parentheses:
72
73     # These evaluate exit before doing the print:
74     print($foo, exit);  # Obviously not what you want.
75     print $foo, exit;   # Nor is this.
76
77     # These do the print before evaluating exit:
78     (print $foo), exit; # This is what you want.
79     print($foo), exit;  # Or this.
80     print ($foo), exit; # Or even this.
81
82 Also note that
83
84     print ($foo & 255) + 1, "\n";
85
86 probably doesn't do what you expect at first glance.  See
87 L<Named Unary Operators> for more discussion of this.
88
89 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
90 well as subroutine and method calls, and the anonymous
91 constructors C<[]> and C<{}>.
92
93 See also L<Quote and Quote-like Operators> toward the end of this section,
94 as well as L<"I/O Operators">.
95
96 =head2 The Arrow Operator
97
98 "C<-E<gt>>" is an infix dereference operator, just as it is in C
99 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
100 C<(...)> subscript, then the left side must be either a hard or
101 symbolic reference to an array, a hash, or a subroutine respectively.
102 (Or technically speaking, a location capable of holding a hard
103 reference, if it's an array or hash reference being used for
104 assignment.)  See L<perlreftut> and L<perlref>.
105
106 Otherwise, the right side is a method name or a simple scalar
107 variable containing either the method name or a subroutine reference,
108 and the left side must be either an object (a blessed reference)
109 or a class name (that is, a package name).  See L<perlobj>.
110
111 =head2 Auto-increment and Auto-decrement
112
113 "++" and "--" work as in C.  That is, if placed before a variable, they
114 increment or decrement the variable before returning the value, and if
115 placed after, increment or decrement the variable after returning the value.
116
117 The auto-increment operator has a little extra builtin magic to it.  If
118 you increment a variable that is numeric, or that has ever been used in
119 a numeric context, you get a normal increment.  If, however, the
120 variable has been used in only string contexts since it was set, and
121 has a value that is not the empty string and matches the pattern
122 C</^[a-zA-Z]*[0-9]*$/>, the increment is done as a string, preserving each
123 character within its range, with carry:
124
125     print ++($foo = '99');      # prints '100'
126     print ++($foo = 'a0');      # prints 'a1'
127     print ++($foo = 'Az');      # prints 'Ba'
128     print ++($foo = 'zz');      # prints 'aaa'
129
130 The auto-decrement operator is not magical.
131
132 =head2 Exponentiation
133
134 Binary "**" is the exponentiation operator.  It binds even more
135 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
136 implemented using C's pow(3) function, which actually works on doubles
137 internally.)
138
139 =head2 Symbolic Unary Operators
140
141 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
142 precedence version of this.
143
144 Unary "-" performs arithmetic negation if the operand is numeric.  If
145 the operand is an identifier, a string consisting of a minus sign
146 concatenated with the identifier is returned.  Otherwise, if the string
147 starts with a plus or minus, a string starting with the opposite sign
148 is returned.  One effect of these rules is that C<-bareword> is equivalent
149 to C<"-bareword">.
150
151 Unary "~" performs bitwise negation, i.e., 1's complement.  For example,
152 C<0666 &~ 027> is 0640.  (See also L<Integer Arithmetic> and L<Bitwise
153 String Operators>.)
154
155 Unary "+" has no effect whatsoever, even on strings.  It is useful
156 syntactically for separating a function name from a parenthesized expression
157 that would otherwise be interpreted as the complete list of function
158 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
159
160 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
161 and L<perlref>.  Do not confuse this behavior with the behavior of
162 backslash within a string, although both forms do convey the notion
163 of protecting the next thing from interpolation.
164
165 =head2 Binding Operators
166
167 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
168 search or modify the string $_ by default.  This operator makes that kind
169 of operation work on some other string.  The right argument is a search
170 pattern, substitution, or transliteration.  The left argument is what is
171 supposed to be searched, substituted, or transliterated instead of the default
172 $_.  The return value indicates the success of the operation.  (If the
173 right argument is an expression rather than a search pattern,
174 substitution, or transliteration, it is interpreted as a search pattern at run
175 time.  This can be is less efficient than an explicit search, because the
176 pattern must be compiled every time the expression is evaluated.
177
178 Binary "!~" is just like "=~" except the return value is negated in
179 the logical sense.
180
181 =head2 Multiplicative Operators
182
183 Binary "*" multiplies two numbers.
184
185 Binary "/" divides two numbers.
186
187 Binary "%" computes the modulus of two numbers.  Given integer
188 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
189 C<$a> minus the largest multiple of C<$b> that is not greater than
190 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
191 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
192 result will be less than or equal to zero). 
193 Note than when C<use integer> is in scope, "%" give you direct access
194 to the modulus operator as implemented by your C compiler.  This
195 operator is not as well defined for negative operands, but it will
196 execute faster.
197
198 Binary "x" is the repetition operator.  In scalar context, it
199 returns a string consisting of the left operand repeated the number of
200 times specified by the right operand.  In list context, if the left
201 operand is a list in parentheses, it repeats the list.
202
203     print '-' x 80;             # print row of dashes
204
205     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
206
207     @ones = (1) x 80;           # a list of 80 1's
208     @ones = (5) x @ones;        # set all elements to 5
209
210
211 =head2 Additive Operators
212
213 Binary "+" returns the sum of two numbers.
214
215 Binary "-" returns the difference of two numbers.
216
217 Binary "." concatenates two strings.
218
219 =head2 Shift Operators
220
221 Binary "<<" returns the value of its left argument shifted left by the
222 number of bits specified by the right argument.  Arguments should be
223 integers.  (See also L<Integer Arithmetic>.)
224
225 Binary ">>" returns the value of its left argument shifted right by
226 the number of bits specified by the right argument.  Arguments should
227 be integers.  (See also L<Integer Arithmetic>.)
228
229 =head2 Named Unary Operators
230
231 The various named unary operators are treated as functions with one
232 argument, with optional parentheses.  These include the filetest
233 operators, like C<-f>, C<-M>, etc.  See L<perlfunc>.
234
235 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
236 is followed by a left parenthesis as the next token, the operator and
237 arguments within parentheses are taken to be of highest precedence,
238 just like a normal function call.  Examples:
239
240     chdir $foo    || die;       # (chdir $foo) || die
241     chdir($foo)   || die;       # (chdir $foo) || die
242     chdir ($foo)  || die;       # (chdir $foo) || die
243     chdir +($foo) || die;       # (chdir $foo) || die
244
245 but, because * is higher precedence than ||:
246
247     chdir $foo * 20;    # chdir ($foo * 20)
248     chdir($foo) * 20;   # (chdir $foo) * 20
249     chdir ($foo) * 20;  # (chdir $foo) * 20
250     chdir +($foo) * 20; # chdir ($foo * 20)
251
252     rand 10 * 20;       # rand (10 * 20)
253     rand(10) * 20;      # (rand 10) * 20
254     rand (10) * 20;     # (rand 10) * 20
255     rand +(10) * 20;    # rand (10 * 20)
256
257 See also L<"Terms and List Operators (Leftward)">.
258
259 =head2 Relational Operators
260
261 Binary "E<lt>" returns true if the left argument is numerically less than
262 the right argument.
263
264 Binary "E<gt>" returns true if the left argument is numerically greater
265 than the right argument.
266
267 Binary "E<lt>=" returns true if the left argument is numerically less than
268 or equal to the right argument.
269
270 Binary "E<gt>=" returns true if the left argument is numerically greater
271 than or equal to the right argument.
272
273 Binary "lt" returns true if the left argument is stringwise less than
274 the right argument.
275
276 Binary "gt" returns true if the left argument is stringwise greater
277 than the right argument.
278
279 Binary "le" returns true if the left argument is stringwise less than
280 or equal to the right argument.
281
282 Binary "ge" returns true if the left argument is stringwise greater
283 than or equal to the right argument.
284
285 =head2 Equality Operators
286
287 Binary "==" returns true if the left argument is numerically equal to
288 the right argument.
289
290 Binary "!=" returns true if the left argument is numerically not equal
291 to the right argument.
292
293 Binary "E<lt>=E<gt>" returns -1, 0, or 1 depending on whether the left
294 argument is numerically less than, equal to, or greater than the right
295 argument.
296
297 Binary "eq" returns true if the left argument is stringwise equal to
298 the right argument.
299
300 Binary "ne" returns true if the left argument is stringwise not equal
301 to the right argument.
302
303 Binary "cmp" returns -1, 0, or 1 depending on whether the left argument is stringwise
304 less than, equal to, or greater than the right argument.
305
306 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
307 by the current locale if C<use locale> is in effect.  See L<perllocale>.
308
309 =head2 Bitwise And
310
311 Binary "&" returns its operators ANDed together bit by bit.
312 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
313
314 =head2 Bitwise Or and Exclusive Or
315
316 Binary "|" returns its operators ORed together bit by bit.
317 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
318
319 Binary "^" returns its operators XORed together bit by bit.
320 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
321
322 =head2 C-style Logical And
323
324 Binary "&&" performs a short-circuit logical AND operation.  That is,
325 if the left operand is false, the right operand is not even evaluated.
326 Scalar or list context propagates down to the right operand if it
327 is evaluated.
328
329 =head2 C-style Logical Or
330
331 Binary "||" performs a short-circuit logical OR operation.  That is,
332 if the left operand is true, the right operand is not even evaluated.
333 Scalar or list context propagates down to the right operand if it
334 is evaluated.
335
336 The C<||> and C<&&> operators differ from C's in that, rather than returning
337 0 or 1, they return the last value evaluated.  Thus, a reasonably portable
338 way to find out the home directory (assuming it's not "0") might be:
339
340     $home = $ENV{'HOME'} || $ENV{'LOGDIR'} ||
341         (getpwuid($<))[7] || die "You're homeless!\n";
342
343 In particular, this means that you shouldn't use this
344 for selecting between two aggregates for assignment:
345
346     @a = @b || @c;              # this is wrong
347     @a = scalar(@b) || @c;      # really meant this
348     @a = @b ? @b : @c;          # this works fine, though
349
350 As more readable alternatives to C<&&> and C<||> when used for
351 control flow, Perl provides C<and> and C<or> operators (see below).
352 The short-circuit behavior is identical.  The precedence of "and" and
353 "or" is much lower, however, so that you can safely use them after a
354 list operator without the need for parentheses:
355
356     unlink "alpha", "beta", "gamma"
357             or gripe(), next LINE;
358
359 With the C-style operators that would have been written like this:
360
361     unlink("alpha", "beta", "gamma")
362             || (gripe(), next LINE);
363
364 Use "or" for assignment is unlikely to do what you want; see below.
365
366 =head2 Range Operators
367
368 Binary ".." is the range operator, which is really two different
369 operators depending on the context.  In list context, it returns an
370 array of values counting (up by ones) from the left value to the right
371 value.  If the left value is greater than the right value then it
372 returns the empty array.  The range operator is useful for writing
373 C<foreach (1..10)> loops and for doing slice operations on arrays.  In
374 the current implementation, no temporary array is created when the
375 range operator is used as the expression in C<foreach> loops, but older
376 versions of Perl might burn a lot of memory when you write something
377 like this:
378
379     for (1 .. 1_000_000) {
380         # code
381     }
382
383 In scalar context, ".." returns a boolean value.  The operator is
384 bistable, like a flip-flop, and emulates the line-range (comma) operator
385 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
386 own boolean state.  It is false as long as its left operand is false.
387 Once the left operand is true, the range operator stays true until the
388 right operand is true, I<AFTER> which the range operator becomes false
389 again.  It doesn't become false till the next time the range operator is
390 evaluated.  It can test the right operand and become false on the same
391 evaluation it became true (as in B<awk>), but it still returns true once.
392 If you don't want it to test the right operand till the next
393 evaluation, as in B<sed>, just use three dots ("...") instead of
394 two.  In all other regards, "..." behaves just like ".." does.
395
396 The right operand is not evaluated while the operator is in the
397 "false" state, and the left operand is not evaluated while the
398 operator is in the "true" state.  The precedence is a little lower
399 than || and &&.  The value returned is either the empty string for
400 false, or a sequence number (beginning with 1) for true.  The
401 sequence number is reset for each range encountered.  The final
402 sequence number in a range has the string "E0" appended to it, which
403 doesn't affect its numeric value, but gives you something to search
404 for if you want to exclude the endpoint.  You can exclude the
405 beginning point by waiting for the sequence number to be greater
406 than 1.  If either operand of scalar ".." is a constant expression,
407 that operand is implicitly compared to the C<$.> variable, the
408 current line number.  Examples:
409
410 As a scalar operator:
411
412     if (101 .. 200) { print; }  # print 2nd hundred lines
413     next line if (1 .. /^$/);   # skip header lines
414     s/^/> / if (/^$/ .. eof()); # quote body
415
416     # parse mail messages
417     while (<>) {
418         $in_header =   1  .. /^$/;
419         $in_body   = /^$/ .. eof();
420         # do something based on those
421     } continue {
422         close ARGV if eof;              # reset $. each file
423     }
424
425 As a list operator:
426
427     for (101 .. 200) { print; } # print $_ 100 times
428     @foo = @foo[0 .. $#foo];    # an expensive no-op
429     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
430
431 The range operator (in list context) makes use of the magical
432 auto-increment algorithm if the operands are strings.  You
433 can say
434
435     @alphabet = ('A' .. 'Z');
436
437 to get all normal letters of the alphabet, or
438
439     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
440
441 to get a hexadecimal digit, or
442
443     @z2 = ('01' .. '31');  print $z2[$mday];
444
445 to get dates with leading zeros.  If the final value specified is not
446 in the sequence that the magical increment would produce, the sequence
447 goes until the next value would be longer than the final value
448 specified.
449
450 =head2 Conditional Operator
451
452 Ternary "?:" is the conditional operator, just as in C.  It works much
453 like an if-then-else.  If the argument before the ? is true, the
454 argument before the : is returned, otherwise the argument after the :
455 is returned.  For example:
456
457     printf "I have %d dog%s.\n", $n,
458             ($n == 1) ? '' : "s";
459
460 Scalar or list context propagates downward into the 2nd
461 or 3rd argument, whichever is selected.
462
463     $a = $ok ? $b : $c;  # get a scalar
464     @a = $ok ? @b : @c;  # get an array
465     $a = $ok ? @b : @c;  # oops, that's just a count!
466
467 The operator may be assigned to if both the 2nd and 3rd arguments are
468 legal lvalues (meaning that you can assign to them):
469
470     ($a_or_b ? $a : $b) = $c;
471
472 Because this operator produces an assignable result, using assignments
473 without parentheses will get you in trouble.  For example, this:
474
475     $a % 2 ? $a += 10 : $a += 2
476
477 Really means this:
478
479     (($a % 2) ? ($a += 10) : $a) += 2
480
481 Rather than this:
482
483     ($a % 2) ? ($a += 10) : ($a += 2)
484
485 That should probably be written more simply as:
486
487     $a += ($a % 2) ? 10 : 2;
488
489 =head2 Assignment Operators
490
491 "=" is the ordinary assignment operator.
492
493 Assignment operators work as in C.  That is,
494
495     $a += 2;
496
497 is equivalent to
498
499     $a = $a + 2;
500
501 although without duplicating any side effects that dereferencing the lvalue
502 might trigger, such as from tie().  Other assignment operators work similarly.
503 The following are recognized:
504
505     **=    +=    *=    &=    <<=    &&=
506            -=    /=    |=    >>=    ||=
507            .=    %=    ^=
508                  x=
509
510 Although these are grouped by family, they all have the precedence
511 of assignment.
512
513 Unlike in C, the scalar assignment operator produces a valid lvalue.
514 Modifying an assignment is equivalent to doing the assignment and
515 then modifying the variable that was assigned to.  This is useful
516 for modifying a copy of something, like this:
517
518     ($tmp = $global) =~ tr [A-Z] [a-z];
519
520 Likewise,
521
522     ($a += 2) *= 3;
523
524 is equivalent to
525
526     $a += 2;
527     $a *= 3;
528
529 Similarly, a list assignment in list context produces the list of
530 lvalues assigned to, and a list assignment in scalar context returns
531 the number of elements produced by the expression on the right hand
532 side of the assignment.
533
534 =head2 Comma Operator
535
536 Binary "," is the comma operator.  In scalar context it evaluates
537 its left argument, throws that value away, then evaluates its right
538 argument and returns that value.  This is just like C's comma operator.
539
540 In list context, it's just the list argument separator, and inserts
541 both its arguments into the list.
542
543 The =E<gt> digraph is mostly just a synonym for the comma operator.  It's useful for
544 documenting arguments that come in pairs.  As of release 5.001, it also forces
545 any word to the left of it to be interpreted as a string.
546
547 =head2 List Operators (Rightward)
548
549 On the right side of a list operator, it has very low precedence,
550 such that it controls all comma-separated expressions found there.
551 The only operators with lower precedence are the logical operators
552 "and", "or", and "not", which may be used to evaluate calls to list
553 operators without the need for extra parentheses:
554
555     open HANDLE, "filename"
556         or die "Can't open: $!\n";
557
558 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
559
560 =head2 Logical Not
561
562 Unary "not" returns the logical negation of the expression to its right.
563 It's the equivalent of "!" except for the very low precedence.
564
565 =head2 Logical And
566
567 Binary "and" returns the logical conjunction of the two surrounding
568 expressions.  It's equivalent to && except for the very low
569 precedence.  This means that it short-circuits: i.e., the right
570 expression is evaluated only if the left expression is true.
571
572 =head2 Logical or and Exclusive Or
573
574 Binary "or" returns the logical disjunction of the two surrounding
575 expressions.  It's equivalent to || except for the very low precedence.
576 This makes it useful for control flow
577
578     print FH $data              or die "Can't write to FH: $!";
579
580 This means that it short-circuits: i.e., the right expression is evaluated
581 only if the left expression is false.  Due to its precedence, you should
582 probably avoid using this for assignment, only for control flow.
583
584     $a = $b or $c;              # bug: this is wrong
585     ($a = $b) or $c;            # really means this
586     $a = $b || $c;              # better written this way
587
588 However, when it's a list-context assignment and you're trying to use
589 "||" for control flow, you probably need "or" so that the assignment
590 takes higher precedence.
591
592     @info = stat($file) || die;     # oops, scalar sense of stat!
593     @info = stat($file) or die;     # better, now @info gets its due
594
595 Then again, you could always use parentheses. 
596
597 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
598 It cannot short circuit, of course.
599
600 =head2 C Operators Missing From Perl
601
602 Here is what C has that Perl doesn't:
603
604 =over 8
605
606 =item unary &
607
608 Address-of operator.  (But see the "\" operator for taking a reference.)
609
610 =item unary *
611
612 Dereference-address operator. (Perl's prefix dereferencing
613 operators are typed: $, @, %, and &.)
614
615 =item (TYPE)
616
617 Type-casting operator.
618
619 =back
620
621 =head2 Quote and Quote-like Operators
622
623 While we usually think of quotes as literal values, in Perl they
624 function as operators, providing various kinds of interpolating and
625 pattern matching capabilities.  Perl provides customary quote characters
626 for these behaviors, but also provides a way for you to choose your
627 quote character for any of them.  In the following table, a C<{}> represents
628 any pair of delimiters you choose.  
629
630     Customary  Generic        Meaning        Interpolates
631         ''       q{}          Literal             no
632         ""      qq{}          Literal             yes
633         ``      qx{}          Command             yes (unless '' is delimiter)
634                 qw{}         Word list            no
635         //       m{}       Pattern match          yes (unless '' is delimiter)
636                 qr{}          Pattern             yes (unless '' is delimiter)
637                  s{}{}      Substitution          yes (unless '' is delimiter)
638                 tr{}{}    Transliteration         no (but see below)
639
640 Non-bracketing delimiters use the same character fore and aft, but the four
641 sorts of brackets (round, angle, square, curly) will all nest, which means
642 that 
643
644         q{foo{bar}baz} 
645         
646 is the same as 
647
648         'foo{bar}baz'
649
650 Note, however, that this does not always work for quoting Perl code:
651
652         $s = q{ if($a eq "}") ... }; # WRONG
653
654 is a syntax error. The C<Text::Balanced> module on CPAN is able to do this
655 properly.
656
657 There can be whitespace between the operator and the quoting
658 characters, except when C<#> is being used as the quoting character.
659 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
660 operator C<q> followed by a comment.  Its argument will be taken
661 from the next line.  This allows you to write:
662
663     s {foo}  # Replace foo
664       {bar}  # with bar.
665
666 For constructs that do interpolate, variables beginning with "C<$>"
667 or "C<@>" are interpolated, as are the following escape sequences.  Within
668 a transliteration, the first eleven of these sequences may be used.
669
670     \t          tab             (HT, TAB)
671     \n          newline         (NL)
672     \r          return          (CR)
673     \f          form feed       (FF)
674     \b          backspace       (BS)
675     \a          alarm (bell)    (BEL)
676     \e          escape          (ESC)
677     \033        octal char      (ESC)
678     \x1b        hex char        (ESC)
679     \x{263a}    wide hex char   (SMILEY)
680     \c[         control char    (ESC)
681     \N{name}    named char
682
683     \l          lowercase next char
684     \u          uppercase next char
685     \L          lowercase till \E
686     \U          uppercase till \E
687     \E          end case modification
688     \Q          quote non-word characters till \E
689
690 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
691 and C<\U> is taken from the current locale.  See L<perllocale>.  For
692 documentation of C<\N{name}>, see L<charnames>.
693
694 All systems use the virtual C<"\n"> to represent a line terminator,
695 called a "newline".  There is no such thing as an unvarying, physical
696 newline character.  It is only an illusion that the operating system,
697 device drivers, C libraries, and Perl all conspire to preserve.  Not all
698 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
699 on a Mac, these are reversed, and on systems without line terminator,
700 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
701 you mean a "newline" for your system, but use the literal ASCII when you
702 need an exact character.  For example, most networking protocols expect
703 and prefer a CR+LF (C<"\012\015"> or C<"\cJ\cM">) for line terminators,
704 and although they often accept just C<"\012">, they seldom tolerate just
705 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
706 you may be burned some day.
707
708 You cannot include a literal C<$> or C<@> within a C<\Q> sequence. 
709 An unescaped C<$> or C<@> interpolates the corresponding variable, 
710 while escaping will cause the literal string C<\$> to be inserted.
711 You'll need to write something like C<m/\Quser\E\@\Qhost/>. 
712
713 Patterns are subject to an additional level of interpretation as a
714 regular expression.  This is done as a second pass, after variables are
715 interpolated, so that regular expressions may be incorporated into the
716 pattern from the variables.  If this is not what you want, use C<\Q> to
717 interpolate a variable literally.
718
719 Apart from the behavior described above, Perl does not expand
720 multiple levels of interpolation.  In particular, contrary to the
721 expectations of shell programmers, back-quotes do I<NOT> interpolate
722 within double quotes, nor do single quotes impede evaluation of
723 variables when used within double quotes.
724
725 =head2 Regexp Quote-Like Operators
726
727 Here are the quote-like operators that apply to pattern
728 matching and related activities.
729
730 =over 8
731
732 =item ?PATTERN?
733
734 This is just like the C</pattern/> search, except that it matches only
735 once between calls to the reset() operator.  This is a useful
736 optimization when you want to see only the first occurrence of
737 something in each file of a set of files, for instance.  Only C<??>
738 patterns local to the current package are reset.
739
740     while (<>) {
741         if (?^$?) {
742                             # blank line between header and body
743         }
744     } continue {
745         reset if eof;       # clear ?? status for next file
746     }
747
748 This usage is vaguely depreciated, which means it just might possibly
749 be removed in some distant future version of Perl, perhaps somewhere
750 around the year 2168.
751
752 =item m/PATTERN/cgimosx
753
754 =item /PATTERN/cgimosx
755
756 Searches a string for a pattern match, and in scalar context returns
757 true if it succeeds, false if it fails.  If no string is specified
758 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
759 string specified with C<=~> need not be an lvalue--it may be the
760 result of an expression evaluation, but remember the C<=~> binds
761 rather tightly.)  See also L<perlre>.  See L<perllocale> for
762 discussion of additional considerations that apply when C<use locale>
763 is in effect.
764
765 Options are:
766
767     c   Do not reset search position on a failed match when /g is in effect.
768     g   Match globally, i.e., find all occurrences.
769     i   Do case-insensitive pattern matching.
770     m   Treat string as multiple lines.
771     o   Compile pattern only once.
772     s   Treat string as single line.
773     x   Use extended regular expressions.
774
775 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
776 you can use any pair of non-alphanumeric, non-whitespace characters 
777 as delimiters.  This is particularly useful for matching path names
778 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
779 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
780 If "'" is the delimiter, no interpolation is performed on the PATTERN.
781
782 PATTERN may contain variables, which will be interpolated (and the
783 pattern recompiled) every time the pattern search is evaluated, except
784 for when the delimiter is a single quote.  (Note that C<$)> and C<$|>
785 might not be interpolated because they look like end-of-string tests.)
786 If you want such a pattern to be compiled only once, add a C</o> after
787 the trailing delimiter.  This avoids expensive run-time recompilations,
788 and is useful when the value you are interpolating won't change over
789 the life of the script.  However, mentioning C</o> constitutes a promise
790 that you won't change the variables in the pattern.  If you change them,
791 Perl won't even notice.  See also L<qr//>.
792
793 If the PATTERN evaluates to the empty string, the last
794 I<successfully> matched regular expression is used instead.
795
796 If the C</g> option is not used, C<m//> in list context returns a
797 list consisting of the subexpressions matched by the parentheses in the
798 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
799 also set, and that this differs from Perl 4's behavior.)  When there are
800 no parentheses in the pattern, the return value is the list C<(1)> for
801 success.  With or without parentheses, an empty list is returned upon
802 failure.
803
804 Examples:
805
806     open(TTY, '/dev/tty');
807     <TTY> =~ /^y/i && foo();    # do foo if desired
808
809     if (/Version: *([0-9.]*)/) { $version = $1; }
810
811     next if m#^/usr/spool/uucp#;
812
813     # poor man's grep
814     $arg = shift;
815     while (<>) {
816         print if /$arg/o;       # compile only once
817     }
818
819     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
820
821 This last example splits $foo into the first two words and the
822 remainder of the line, and assigns those three fields to $F1, $F2, and
823 $Etc.  The conditional is true if any variables were assigned, i.e., if
824 the pattern matched.
825
826 The C</g> modifier specifies global pattern matching--that is,
827 matching as many times as possible within the string.  How it behaves
828 depends on the context.  In list context, it returns a list of the
829 substrings matched by any capturing parentheses in the regular
830 expression.  If there are no parentheses, it returns a list of all
831 the matched strings, as if there were parentheses around the whole
832 pattern.
833
834 In scalar context, each execution of C<m//g> finds the next match,
835 returning true if it matches, and false if there is no further match.
836 The position after the last match can be read or set using the pos()
837 function; see L<perlfunc/pos>.   A failed match normally resets the
838 search position to the beginning of the string, but you can avoid that
839 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
840 string also resets the search position.
841
842 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
843 zero-width assertion that matches the exact position where the previous
844 C<m//g>, if any, left off.  The C<\G> assertion is not supported without
845 the C</g> modifier.  (Currently, without C</g>, C<\G> behaves just like
846 C<\A>, but that's accidental and may change in the future.)
847
848 Examples:
849
850     # list context
851     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
852
853     # scalar context
854     $/ = ""; $* = 1;  # $* deprecated in modern perls
855     while (defined($paragraph = <>)) {
856         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
857             $sentences++;
858         }
859     }
860     print "$sentences\n";
861
862     # using m//gc with \G
863     $_ = "ppooqppqq";
864     while ($i++ < 2) {
865         print "1: '";
866         print $1 while /(o)/gc; print "', pos=", pos, "\n";
867         print "2: '";
868         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
869         print "3: '";
870         print $1 while /(p)/gc; print "', pos=", pos, "\n";
871     }
872
873 The last example should print:
874
875     1: 'oo', pos=4
876     2: 'q', pos=5
877     3: 'pp', pos=7
878     1: '', pos=7
879     2: 'q', pos=8
880     3: '', pos=8
881
882 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
883 combine several regexps like this to process a string part-by-part,
884 doing different actions depending on which regexp matched.  Each
885 regexp tries to match where the previous one leaves off.
886
887  $_ = <<'EOL';
888       $url = new URI::URL "http://www/";   die if $url eq "xXx";
889  EOL
890  LOOP:
891     {
892       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
893       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
894       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
895       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
896       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
897       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
898       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
899       print ". That's all!\n";
900     }
901
902 Here is the output (split into several lines):
903
904  line-noise lowercase line-noise lowercase UPPERCASE line-noise
905  UPPERCASE line-noise lowercase line-noise lowercase line-noise
906  lowercase lowercase line-noise lowercase lowercase line-noise
907  MiXeD line-noise. That's all!
908
909 =item q/STRING/
910
911 =item C<'STRING'>
912
913 A single-quoted, literal string.  A backslash represents a backslash
914 unless followed by the delimiter or another backslash, in which case
915 the delimiter or backslash is interpolated.
916
917     $foo = q!I said, "You said, 'She said it.'"!;
918     $bar = q('This is it.');
919     $baz = '\n';                # a two-character string
920
921 =item qq/STRING/
922
923 =item "STRING"
924
925 A double-quoted, interpolated string.
926
927     $_ .= qq
928      (*** The previous line contains the naughty word "$1".\n)
929                 if /\b(tcl|java|python)\b/i;      # :-)
930     $baz = "\n";                # a one-character string
931
932 =item qr/STRING/imosx
933
934 This operators quotes--and compiles--its I<STRING> as a regular
935 expression.  I<STRING> is interpolated the same way as I<PATTERN>
936 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
937 is done.  Returns a Perl value which may be used instead of the
938 corresponding C</STRING/imosx> expression.
939
940 For example,
941
942     $rex = qr/my.STRING/is;
943     s/$rex/foo/;
944
945 is equivalent to
946
947     s/my.STRING/foo/is;
948
949 The result may be used as a subpattern in a match:
950
951     $re = qr/$pattern/;
952     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
953     $string =~ $re;             # or used standalone
954     $string =~ /$re/;           # or this way
955
956 Since Perl may compile the pattern at the moment of execution of qr()
957 operator, using qr() may have speed advantages in some situations,
958 notably if the result of qr() is used standalone:
959
960     sub match {
961         my $patterns = shift;
962         my @compiled = map qr/$_/i, @$patterns;
963         grep {
964             my $success = 0;
965             foreach my $pat @compiled {
966                 $success = 1, last if /$pat/;
967             }
968             $success;
969         } @_;
970     }
971
972 Precompilation of the pattern into an internal representation at
973 the moment of qr() avoids a need to recompile the pattern every
974 time a match C</$pat/> is attempted.  (Perl has many other internal
975 optimizations, but none would be triggered in the above example if
976 we did not use qr() operator.)
977
978 Options are:
979
980     i   Do case-insensitive pattern matching.
981     m   Treat string as multiple lines.
982     o   Compile pattern only once.
983     s   Treat string as single line.
984     x   Use extended regular expressions.
985
986 See L<perlre> for additional information on valid syntax for STRING, and
987 for a detailed look at the semantics of regular expressions.
988
989 =item qx/STRING/
990
991 =item `STRING`
992
993 A string which is (possibly) interpolated and then executed as a system
994 command with C</bin/sh> or its equivalent.  Shell wildcards, pipes,
995 and redirections will be honored.  The collected standard output of the
996 command is returned; standard error is unaffected.  In scalar context,
997 it comes back as a single (potentially multi-line) string.  In list
998 context, returns a list of lines (however you've defined lines with $/
999 or $INPUT_RECORD_SEPARATOR).
1000
1001 Because backticks do not affect standard error, use shell file descriptor
1002 syntax (assuming the shell supports this) if you care to address this.
1003 To capture a command's STDERR and STDOUT together:
1004
1005     $output = `cmd 2>&1`;
1006
1007 To capture a command's STDOUT but discard its STDERR:
1008
1009     $output = `cmd 2>/dev/null`;
1010
1011 To capture a command's STDERR but discard its STDOUT (ordering is
1012 important here):
1013
1014     $output = `cmd 2>&1 1>/dev/null`;
1015
1016 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1017 but leave its STDOUT to come out the old STDERR:
1018
1019     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1020
1021 To read both a command's STDOUT and its STDERR separately, it's easiest
1022 and safest to redirect them separately to files, and then read from those
1023 files when the program is done:
1024
1025     system("program args 1>/tmp/program.stdout 2>/tmp/program.stderr");
1026
1027 Using single-quote as a delimiter protects the command from Perl's
1028 double-quote interpolation, passing it on to the shell instead:
1029
1030     $perl_info  = qx(ps $$);            # that's Perl's $$
1031     $shell_info = qx'ps $$';            # that's the new shell's $$
1032
1033 How that string gets evaluated is entirely subject to the command
1034 interpreter on your system.  On most platforms, you will have to protect
1035 shell metacharacters if you want them treated literally.  This is in
1036 practice difficult to do, as it's unclear how to escape which characters.
1037 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1038 to emulate backticks safely.
1039
1040 On some platforms (notably DOS-like ones), the shell may not be
1041 capable of dealing with multiline commands, so putting newlines in
1042 the string may not get you what you want.  You may be able to evaluate
1043 multiple commands in a single line by separating them with the command
1044 separator character, if your shell supports that (e.g. C<;> on many Unix
1045 shells; C<&> on the Windows NT C<cmd> shell).
1046
1047 Beware that some command shells may place restrictions on the length
1048 of the command line.  You must ensure your strings don't exceed this
1049 limit after any necessary interpolations.  See the platform-specific
1050 release notes for more details about your particular environment.
1051
1052 Using this operator can lead to programs that are difficult to port,
1053 because the shell commands called vary between systems, and may in
1054 fact not be present at all.  As one example, the C<type> command under
1055 the POSIX shell is very different from the C<type> command under DOS.
1056 That doesn't mean you should go out of your way to avoid backticks
1057 when they're the right way to get something done.  Perl was made to be
1058 a glue language, and one of the things it glues together is commands.
1059 Just understand what you're getting yourself into.
1060
1061 See L<"I/O Operators"> for more discussion.
1062
1063 =item qw/STRING/
1064
1065 Evaluates to a list of the words extracted out of STRING, using embedded
1066 whitespace as the word delimiters.  It can be understood as being roughly
1067 equivalent to:
1068
1069     split(' ', q/STRING/);
1070
1071 the difference being that it generates a real list at compile time.  So
1072 this expression:
1073
1074     qw(foo bar baz)
1075
1076 is exactly equivalent to the list:
1077
1078     ('foo', 'bar', 'baz')
1079
1080 Some frequently seen examples:
1081
1082     use POSIX qw( setlocale localeconv )
1083     @EXPORT = qw( foo bar baz );
1084
1085 A common mistake is to try to separate the words with comma or to
1086 put comments into a multi-line C<qw>-string.  For this reason, the
1087 B<-w> switch (that is, the C<$^W> variable) produces warnings if
1088 the STRING contains the "," or the "#" character.
1089
1090 =item s/PATTERN/REPLACEMENT/egimosx
1091
1092 Searches a string for a pattern, and if found, replaces that pattern
1093 with the replacement text and returns the number of substitutions
1094 made.  Otherwise it returns false (specifically, the empty string).
1095
1096 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1097 variable is searched and modified.  (The string specified with C<=~> must
1098 be scalar variable, an array element, a hash element, or an assignment
1099 to one of those, i.e., an lvalue.)
1100
1101 If the delimiter chosen is a single quote, no interpolation is
1102 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1103 PATTERN contains a $ that looks like a variable rather than an
1104 end-of-string test, the variable will be interpolated into the pattern
1105 at run-time.  If you want the pattern compiled only once the first time
1106 the variable is interpolated, use the C</o> option.  If the pattern
1107 evaluates to the empty string, the last successfully executed regular
1108 expression is used instead.  See L<perlre> for further explanation on these.
1109 See L<perllocale> for discussion of additional considerations that apply
1110 when C<use locale> is in effect.
1111
1112 Options are:
1113
1114     e   Evaluate the right side as an expression.
1115     g   Replace globally, i.e., all occurrences.
1116     i   Do case-insensitive pattern matching.
1117     m   Treat string as multiple lines.
1118     o   Compile pattern only once.
1119     s   Treat string as single line.
1120     x   Use extended regular expressions.
1121
1122 Any non-alphanumeric, non-whitespace delimiter may replace the
1123 slashes.  If single quotes are used, no interpretation is done on the
1124 replacement string (the C</e> modifier overrides this, however).  Unlike
1125 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1126 text is not evaluated as a command.  If the
1127 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1128 pair of quotes, which may or may not be bracketing quotes, e.g.,
1129 C<s(foo)(bar)> or C<sE<lt>fooE<gt>/bar/>.  A C</e> will cause the
1130 replacement portion to be interpreted as a full-fledged Perl expression
1131 and eval()ed right then and there.  It is, however, syntax checked at
1132 compile-time.
1133
1134 Examples:
1135
1136     s/\bgreen\b/mauve/g;                # don't change wintergreen
1137
1138     $path =~ s|/usr/bin|/usr/local/bin|;
1139
1140     s/Login: $foo/Login: $bar/; # run-time pattern
1141
1142     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1143
1144     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1145
1146     $_ = 'abc123xyz';
1147     s/\d+/$&*2/e;               # yields 'abc246xyz'
1148     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1149     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1150
1151     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1152     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1153     s/^=(\w+)/&pod($1)/ge;      # use function call
1154
1155     # expand variables in $_, but dynamics only, using
1156     # symbolic dereferencing
1157     s/\$(\w+)/${$1}/g;
1158
1159     # /e's can even nest;  this will expand
1160     # any embedded scalar variable (including lexicals) in $_
1161     s/(\$\w+)/$1/eeg;
1162
1163     # Delete (most) C comments.
1164     $program =~ s {
1165         /\*     # Match the opening delimiter.
1166         .*?     # Match a minimal number of characters.
1167         \*/     # Match the closing delimiter.
1168     } []gsx;
1169
1170     s/^\s*(.*?)\s*$/$1/;        # trim white space in $_, expensively
1171
1172     for ($variable) {           # trim white space in $variable, cheap
1173         s/^\s+//;
1174         s/\s+$//;
1175     }
1176
1177     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1178
1179 Note the use of $ instead of \ in the last example.  Unlike
1180 B<sed>, we use the \E<lt>I<digit>E<gt> form in only the left hand side.
1181 Anywhere else it's $E<lt>I<digit>E<gt>.
1182
1183 Occasionally, you can't use just a C</g> to get all the changes
1184 to occur that you might want.  Here are two common cases:
1185
1186     # put commas in the right places in an integer
1187     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;  
1188
1189     # expand tabs to 8-column spacing
1190     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1191
1192 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsUC
1193
1194 =item y/SEARCHLIST/REPLACEMENTLIST/cdsUC
1195
1196 Transliterates all occurrences of the characters found in the search list
1197 with the corresponding character in the replacement list.  It returns
1198 the number of characters replaced or deleted.  If no string is
1199 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1200 string specified with =~ must be a scalar variable, an array element, a
1201 hash element, or an assignment to one of those, i.e., an lvalue.)
1202
1203 A character range may be specified with a hyphen, so C<tr/A-J/0-9/> 
1204 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1205 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1206 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1207 its own pair of quotes, which may or may not be bracketing quotes,
1208 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1209
1210 Note also that the whole range idea is rather unportable between
1211 character sets--and even within character sets they may cause results
1212 you probably didn't expect.  A sound principle is to use only ranges
1213 that begin from and end at either alphabets of equal case (a-e, A-E),
1214 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1215 character sets in full.
1216
1217 Options:
1218
1219     c   Complement the SEARCHLIST.
1220     d   Delete found but unreplaced characters.
1221     s   Squash duplicate replaced characters.
1222     U   Translate to/from UTF-8.
1223     C   Translate to/from 8-bit char (octet).
1224
1225 If the C</c> modifier is specified, the SEARCHLIST character set
1226 is complemented.  If the C</d> modifier is specified, any characters
1227 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1228 (Note that this is slightly more flexible than the behavior of some
1229 B<tr> programs, which delete anything they find in the SEARCHLIST,
1230 period.) If the C</s> modifier is specified, sequences of characters
1231 that were transliterated to the same character are squashed down
1232 to a single instance of the character.
1233
1234 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1235 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1236 than the SEARCHLIST, the final character is replicated till it is long
1237 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1238 This latter is useful for counting characters in a class or for
1239 squashing character sequences in a class.
1240
1241 The first C</U> or C</C> modifier applies to the left side of the translation.
1242 The second one applies to the right side.  If present, these modifiers override
1243 the current utf8 state.
1244
1245 Examples:
1246
1247     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1248
1249     $cnt = tr/*/*/;             # count the stars in $_
1250
1251     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1252
1253     $cnt = tr/0-9//;            # count the digits in $_
1254
1255     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1256
1257     ($HOST = $host) =~ tr/a-z/A-Z/;
1258
1259     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1260
1261     tr [\200-\377]
1262        [\000-\177];             # delete 8th bit
1263
1264     tr/\0-\xFF//CU;             # change Latin-1 to Unicode
1265     tr/\0-\x{FF}//UC;           # change Unicode to Latin-1
1266
1267 If multiple transliterations are given for a character, only the
1268 first one is used:
1269
1270     tr/AAA/XYZ/
1271
1272 will transliterate any A to X.
1273
1274 Because the transliteration table is built at compile time, neither
1275 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1276 interpolation.  That means that if you want to use variables, you
1277 must use an eval():
1278
1279     eval "tr/$oldlist/$newlist/";
1280     die $@ if $@;
1281
1282     eval "tr/$oldlist/$newlist/, 1" or die $@;
1283
1284 =back
1285
1286 =head2 Gory details of parsing quoted constructs
1287
1288 When presented with something that might have several different
1289 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1290 principle to pick the most probable interpretation.  This strategy
1291 is so successful that Perl programmers often do not suspect the
1292 ambivalence of what they write.  But from time to time, Perl's
1293 notions differ substantially from what the author honestly meant.
1294
1295 This section hopes to clarify how Perl handles quoted constructs.
1296 Although the most common reason to learn this is to unravel labyrinthine
1297 regular expressions, because the initial steps of parsing are the
1298 same for all quoting operators, they are all discussed together.
1299
1300 The most important Perl parsing rule is the first one discussed
1301 below: when processing a quoted construct, Perl first finds the end
1302 of that construct, then interprets its contents.  If you understand
1303 this rule, you may skip the rest of this section on the first
1304 reading.  The other rules are likely to contradict the user's
1305 expectations much less frequently than this first one.
1306
1307 Some passes discussed below are performed concurrently, but because
1308 their results are the same, we consider them individually.  For different
1309 quoting constructs, Perl performs different numbers of passes, from
1310 one to five, but these passes are always performed in the same order.
1311
1312 =over
1313
1314 =item Finding the end
1315
1316 The first pass is finding the end of the quoted construct, whether
1317 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1318 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1319 terminates C<qq[]> construct, or a C<E<gt>> which terminates a
1320 fileglob started with C<E<lt>>.
1321
1322 When searching for single-character non-pairing delimiters, such
1323 as C</>, combinations of C<\\> and C<\/> are skipped.  However,
1324 when searching for single-character pairing delimiter like C<[>,
1325 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1326 C<[>, C<]> are skipped as well.  When searching for multicharacter
1327 delimiters, nothing is skipped.
1328
1329 For constructs with three-part delimiters (C<s///>, C<y///>, and
1330 C<tr///>), the search is repeated once more.
1331
1332 During this search no attention is paid to the semantics of the construct.
1333 Thus:
1334
1335     "$hash{"$foo/$bar"}"
1336
1337 or:
1338
1339     m/ 
1340       bar       # NOT a comment, this slash / terminated m//!
1341      /x
1342
1343 do not form legal quoted expressions.   The quoted part ends on the
1344 first C<"> and C</>, and the rest happens to be a syntax error.
1345 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1346 the example above is not C<m//x>, but rather C<m//> with no C</x>
1347 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1348
1349 =item Removal of backslashes before delimiters
1350
1351 During the second pass, text between the starting and ending
1352 delimiters is copied to a safe location, and the C<\> is removed
1353 from combinations consisting of C<\> and delimiter--or delimiters,
1354 meaning both starting and ending delimiters will should these differ.
1355 This removal does not happen for multi-character delimiters.
1356 Note that the combination C<\\> is left intact, just as it was.
1357
1358 Starting from this step no information about the delimiters is
1359 used in parsing.
1360
1361 =item Interpolation
1362
1363 The next step is interpolation in the text obtained, which is now
1364 delimiter-independent.  There are four different cases.
1365
1366 =over
1367
1368 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1369
1370 No interpolation is performed.
1371
1372 =item C<''>, C<q//>
1373
1374 The only interpolation is removal of C<\> from pairs C<\\>.
1375
1376 =item C<"">, C<``>, C<qq//>, C<qx//>, C<<file*globE<gt>>
1377
1378 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1379 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1380 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1381 The other combinations are replaced with appropriate expansions.
1382
1383 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1384 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1385 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1386 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1387 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1388 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1389 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1390
1391   $str = '\t';
1392   return "\Q$str";
1393
1394 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1395
1396 Interpolated scalars and arrays are converted internally to the C<join> and
1397 C<.> catentation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1398
1399   $foo . " XXX '" . (join $", @arr) . "'";
1400
1401 All operations above are performed simultaneously, left to right.
1402
1403 Because the result of C<"\Q STRING \E"> has all metacharacters
1404 quoted, there is no way to insert a literal C<$> or C<@> inside a
1405 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1406 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1407 scalar.
1408
1409 Note also that the interpolation code needs to make a decision on
1410 where the interpolated scalar ends.  For instance, whether 
1411 C<"a $b -E<gt> {c}"> really means:
1412
1413   "a " . $b . " -> {c}";
1414
1415 or:
1416
1417   "a " . $b -> {c};
1418
1419 Most of the time, the longest possible text that does not include
1420 spaces between components and which contains matching braces or
1421 brackets.  because the outcome may be determined by voting based
1422 on heuristic estimators, the result is not strictly predictable.
1423 Fortunately, it's usually correct for ambiguous cases.
1424
1425 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, 
1426
1427 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1428 happens (almost) as with C<qq//> constructs, but the substitution
1429 of C<\> followed by RE-special chars (including C<\>) is not
1430 performed.  Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1431 a C<#>-comment in a C<//x>-regular expression, no processing is
1432 performed whatsoever.  This is the first step at which the presence
1433 of the C<//x> modifier is relevant.
1434
1435 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1436 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1437 different estimators) to be either an array element or C<$var>
1438 followed by an RE alternative.  This is where the notation
1439 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1440 array element C<-9>, not as a regular expression from the variable
1441 C<$arr> followed by a digit, which would be the interpretation of
1442 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1443 the result is not predictable.
1444
1445 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1446 the replacement text of C<s///> to correct the incorrigible
1447 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1448 is emitted if the B<-w> command-line flag (that is, the C<$^W> variable)
1449 was set.
1450
1451 The lack of processing of C<\\> creates specific restrictions on
1452 the post-processed text.  If the delimiter is C</>, one cannot get
1453 the combination C<\/> into the result of this step.  C</> will
1454 finish the regular expression, C<\/> will be stripped to C</> on
1455 the previous step, and C<\\/> will be left as is.  Because C</> is
1456 equivalent to C<\/> inside a regular expression, this does not
1457 matter unless the delimiter happens to be character special to the
1458 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1459 alphanumeric char, as in:
1460
1461   m m ^ a \s* b mmx;
1462
1463 In the RE above, which is intentionally obfuscated for illustration, the
1464 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1465 RE is the same as for C<m/ ^ a s* b /mx>).  There's more than one 
1466 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1467 non-whitespace choices.
1468
1469 =back
1470
1471 This step is the last one for all constructs except regular expressions,
1472 which are processed further.
1473
1474 =item Interpolation of regular expressions
1475
1476 Previous steps were performed during the compilation of Perl code,
1477 but this one happens at run time--although it may be optimized to
1478 be calculated at compile time if appropriate.  After preprocessing
1479 described above, and possibly after evaluation if catenation,
1480 joining, casing translation, or metaquoting are involved, the
1481 resulting I<string> is passed to the RE engine for compilation.
1482
1483 Whatever happens in the RE engine might be better discussed in L<perlre>,
1484 but for the sake of continuity, we shall do so here.
1485
1486 This is another step where the presence of the C<//x> modifier is
1487 relevant.  The RE engine scans the string from left to right and
1488 converts it to a finite automaton.
1489
1490 Backslashed characters are either replaced with corresponding
1491 literal strings (as with C<\{>), or else they generate special nodes
1492 in the finite automaton (as with C<\b>).  Characters special to the
1493 RE engine (such as C<|>) generate corresponding nodes or groups of
1494 nodes.  C<(?#...)> comments are ignored.  All the rest is either
1495 converted to literal strings to match, or else is ignored (as is
1496 whitespace and C<#>-style comments if C<//x> is present).
1497
1498 Parsing of the bracketed character class construct, C<[...]>, is
1499 rather different than the rule used for the rest of the pattern.
1500 The terminator of this construct is found using the same rules as
1501 for finding the terminator of a C<{}>-delimited construct, the only
1502 exception being that C<]> immediately following C<[> is treated as
1503 though preceded by a backslash.  Similarly, the terminator of
1504 C<(?{...})> is found using the same rules as for finding the
1505 terminator of a C<{}>-delimited construct.
1506
1507 It is possible to inspect both the string given to RE engine and the
1508 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
1509 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1510 switch documented in L<perlrun/Switches>.
1511
1512 =item Optimization of regular expressions
1513
1514 This step is listed for completeness only.  Since it does not change
1515 semantics, details of this step are not documented and are subject
1516 to change without notice.  This step is performed over the finite
1517 automaton that was generated during the previous pass.
1518
1519 It is at this stage that C<split()> silently optimizes C</^/> to
1520 mean C</^/m>.
1521
1522 =back
1523
1524 =head2 I/O Operators
1525
1526 There are several I/O operators you should know about.
1527
1528 A string enclosed by backticks (grave accents) first undergoes
1529 double-quote interpolation.  It is then interpreted as an external
1530 command, and the output of that command is the value of the
1531 pseudo-literal, j
1532 string consisting of all output is returned.  In list context, a
1533 list of values is returned, one per line of output.  (You can set
1534 C<$/> to use a different line terminator.)  The command is executed
1535 each time the pseudo-literal is evaluated.  The status value of the
1536 command is returned in C<$?> (see L<perlvar> for the interpretation
1537 of C<$?>).  Unlike in B<csh>, no translation is done on the return
1538 data--newlines remain newlines.  Unlike in any of the shells, single
1539 quotes do not hide variable names in the command from interpretation.
1540 To pass a literal dollar-sign through to the shell you need to hide
1541 it with a backslash.  The generalized form of backticks is C<qx//>.
1542 (Because backticks always undergo shell expansion as well, see
1543 L<perlsec> for security concerns.)
1544
1545 In scalar context, evaluating a filehandle in angle brackets yields
1546 the next line from that file (the newline, if any, included), or
1547 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
1548 (sometimes known as file-slurp mode) and the file is empty, it
1549 returns C<''> the first time, followed by C<undef> subsequently.
1550
1551 Ordinarily you must assign the returned value to a variable, but
1552 there is one situation where an automatic assignment happens.  If
1553 and only if the input symbol is the only thing inside the conditional
1554 of a C<while> statement (even if disguised as a C<for(;;)> loop),
1555 the value is automatically assigned to the global variable $_,
1556 destroying whatever was there previously.  (This may seem like an
1557 odd thing to you, but you'll use the construct in almost every Perl
1558 script you write.)  The $_ variables is not implicitly localized.
1559 You'll have to put a C<local $_;> before the loop if you want that
1560 to happen.
1561
1562 The following lines are equivalent:
1563
1564     while (defined($_ = <STDIN>)) { print; }
1565     while ($_ = <STDIN>) { print; }
1566     while (<STDIN>) { print; }
1567     for (;<STDIN>;) { print; }
1568     print while defined($_ = <STDIN>);
1569     print while ($_ = <STDIN>);
1570     print while <STDIN>;
1571
1572 This also behaves similarly, but avoids $_ :
1573
1574     while (my $line = <STDIN>) { print $line }    
1575
1576 In these loop constructs, the assigned value (whether assignment
1577 is automatic or explicit) is then tested to see whether it is
1578 defined.  The defined test avoids problems where line has a string
1579 value that would be treated as false by Perl, for example a "" or
1580 a "0" with no trailing newline.  If you really mean for such values
1581 to terminate the loop, they should be tested for explicitly:
1582
1583     while (($_ = <STDIN>) ne '0') { ... }
1584     while (<STDIN>) { last unless $_; ... }
1585
1586 In other boolean contexts, C<E<lt>I<filehandle>E<gt>> without an
1587 explicit C<defined> test or comparison elicit a warning if the B<-w>
1588 command-line switch (the C<$^W> variable) is in effect.
1589
1590 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
1591 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
1592 in packages, where they would be interpreted as local identifiers
1593 rather than global.)  Additional filehandles may be created with
1594 the open() function, amongst others.  See L<perlopentut> and
1595 L<perlfunc/open> for details on this.
1596
1597 If a E<lt>FILEHANDLEE<gt> is used in a context that is looking for
1598 a list, a list comprising all input lines is returned, one line per
1599 list element.  It's easy to grow to a rather large data space this
1600 way, so use with care.
1601
1602 E<lt>FILEHANDLEE<gt> may also be spelled C<readline(*FILEHANDLE)>.
1603 See L<perlfunc/readline>.
1604
1605 The null filehandle E<lt>E<gt> is special: it can be used to emulate the
1606 behavior of B<sed> and B<awk>.  Input from E<lt>E<gt> comes either from
1607 standard input, or from each file listed on the command line.  Here's
1608 how it works: the first time E<lt>E<gt> is evaluated, the @ARGV array is
1609 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
1610 gives you standard input.  The @ARGV array is then processed as a list
1611 of filenames.  The loop
1612
1613     while (<>) {
1614         ...                     # code for each line
1615     }
1616
1617 is equivalent to the following Perl-like pseudo code:
1618
1619     unshift(@ARGV, '-') unless @ARGV;
1620     while ($ARGV = shift) {
1621         open(ARGV, $ARGV);
1622         while (<ARGV>) {
1623             ...         # code for each line
1624         }
1625     }
1626
1627 except that it isn't so cumbersome to say, and will actually work.
1628 It really does shift the @ARGV array and put the current filename
1629 into the $ARGV variable.  It also uses filehandle I<ARGV>
1630 internally--E<lt>E<gt> is just a synonym for E<lt>ARGVE<gt>, which
1631 is magical.  (The pseudo code above doesn't work because it treats
1632 E<lt>ARGVE<gt> as non-magical.)
1633
1634 You can modify @ARGV before the first E<lt>E<gt> as long as the array ends up
1635 containing the list of filenames you really want.  Line numbers (C<$.>)
1636 continue as though the input were one big happy file.  See the example
1637 in L<perlfunc/eof> for how to reset line numbers on each file.
1638
1639 If you want to set @ARGV to your own list of files, go right ahead.  
1640 This sets @ARGV to all plain text files if no @ARGV was given:
1641
1642     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
1643
1644 You can even set them to pipe commands.  For example, this automatically
1645 filters compressed arguments through B<gzip>:
1646
1647     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
1648
1649 If you want to pass switches into your script, you can use one of the
1650 Getopts modules or put a loop on the front like this:
1651
1652     while ($_ = $ARGV[0], /^-/) {
1653         shift;
1654         last if /^--$/;
1655         if (/^-D(.*)/) { $debug = $1 }
1656         if (/^-v/)     { $verbose++  }
1657         # ...           # other switches
1658     }
1659
1660     while (<>) {
1661         # ...           # code for each line
1662     }
1663
1664 The E<lt>E<gt> symbol will return C<undef> for end-of-file only once.  
1665 If you call it again after this, it will assume you are processing another 
1666 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
1667
1668 If angle brackets contain is a simple scalar variable (e.g.,
1669 E<lt>$fooE<gt>), then that variable contains the name of the
1670 filehandle to input from, or its typeglob, or a reference to the
1671 same.  For example:
1672
1673     $fh = \*STDIN;
1674     $line = <$fh>;
1675
1676 If what's within the angle brackets is neither a filehandle nor a simple
1677 scalar variable containing a filehandle name, typeglob, or typeglob
1678 reference, it is interpreted as a filename pattern to be globbed, and
1679 either a list of filenames or the next filename in the list is returned,
1680 depending on context.  This distinction is determined on syntactic
1681 grounds alone.  That means C<E<lt>$xE<gt>> is always a readline() from
1682 an indirect handle, but C<E<lt>$hash{key}E<gt>> is always a glob().
1683 That's because $x is a simple scalar variable, but C<$hash{key}> is
1684 not--it's a hash element.
1685
1686 One level of double-quote interpretation is done first, but you can't
1687 say C<E<lt>$fooE<gt>> because that's an indirect filehandle as explained
1688 in the previous paragraph.  (In older versions of Perl, programmers
1689 would insert curly brackets to force interpretation as a filename glob:
1690 C<E<lt>${foo}E<gt>>.  These days, it's considered cleaner to call the
1691 internal function directly as C<glob($foo)>, which is probably the right
1692 way to have done it in the first place.)  For example:
1693
1694     while (<*.c>) {
1695         chmod 0644, $_;
1696     }
1697
1698 is equivalent to
1699
1700     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
1701     while (<FOO>) {
1702         chop;
1703         chmod 0644, $_;
1704     }
1705
1706 In fact, it's currently implemented that way, but this is expected
1707 to be made completely internal in the near future.  (Which means
1708 it will not work on filenames with spaces in them unless you have
1709 csh(1) on your machine.)  Of course, the shortest way to do the
1710 above is:
1711
1712     chmod 0644, <*.c>;
1713
1714 Because globbing currently invokes a shell, it's often faster to
1715 call readdir() yourself and do your own grep() on the filenames.
1716 Furthermore, due to its current implementation of using a shell,
1717 the glob() routine may get "Arg list too long" errors (unless you've
1718 installed tcsh(1L) as F</bin/csh> or hacked your F<config.sh>).
1719
1720 A (file)glob evaluates its (embedded) argument only when it is
1721 starting a new list.  All values must be read before it will start
1722 over.  In list context, this isn't important because you automatically
1723 get them all anyway.  However, in scalar context the operator returns
1724 the next value each time it's called, or C
1725 run out.  As with filehandle reads, an automatic C<defined> is
1726 generated when the glob occurs in the test part of a C<while>,
1727 because legal glob returns (e.g. a file called F<0>) would otherwise
1728 terminate the loop.  Again, C<undef> is returned only once.  So if
1729 you're expecting a single value from a glob, it is much better to
1730 say
1731
1732     ($file) = <blurch*>;
1733
1734 than
1735
1736     $file = <blurch*>;
1737
1738 because the latter will alternate between returning a filename and
1739 returning false.
1740
1741 It you're trying to do variable interpolation, it's definitely better
1742 to use the glob() function, because the older notation can cause people
1743 to become confused with the indirect filehandle notation.
1744
1745     @files = glob("$dir/*.[ch]");
1746     @files = glob($files[$i]);
1747
1748 =head2 Constant Folding
1749
1750 Like C, Perl does a certain amount of expression evaluation at
1751 compile time whenever it determines that all arguments to an
1752 operator are static and have no side effects.  In particular, string
1753 concatenation happens at compile time between literals that don't do
1754 variable substitution.  Backslash interpolation also happens at
1755 compile time.  You can say
1756
1757     'Now is the time for all' . "\n" .
1758         'good men to come to.'
1759
1760 and this all reduces to one string internally.  Likewise, if
1761 you say
1762
1763     foreach $file (@filenames) {
1764         if (-s $file > 5 + 100 * 2**16) {  }
1765     }
1766
1767 the compiler will precompute the number which that expression
1768 represents so that the interpreter won't have to.
1769
1770 =head2 Bitwise String Operators
1771
1772 Bitstrings of any size may be manipulated by the bitwise operators
1773 (C<~ | & ^>).
1774
1775 If the operands to a binary bitwise op are strings of different
1776 sizes, B<|> and B<^> ops act as though the shorter operand had
1777 additional zero bits on the right, while the B<&> op acts as though
1778 the longer operand were truncated to the length of the shorter.
1779 The granularity for such extension or truncation is one or more
1780 bytes.
1781
1782     # ASCII-based examples 
1783     print "j p \n" ^ " a h";            # prints "JAPH\n"
1784     print "JA" | "  ph\n";              # prints "japh\n"
1785     print "japh\nJunk" & '_____';       # prints "JAPH\n";
1786     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
1787
1788 If you are intending to manipulate bitstrings, be certain that
1789 you're supplying bitstrings: If an operand is a number, that will imply
1790 a B<numeric> bitwise operation.  You may explicitly show which type of
1791 operation you intend by using C<""> or C<0+>, as in the examples below.
1792
1793     $foo =  150  |  105 ;       # yields 255  (0x96 | 0x69 is 0xFF)
1794     $foo = '150' |  105 ;       # yields 255
1795     $foo =  150  | '105';       # yields 255
1796     $foo = '150' | '105';       # yields string '155' (under ASCII)
1797
1798     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
1799     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
1800
1801 See L<perlfunc/vec> for information on how to manipulate individual bits
1802 in a bit vector.
1803
1804 =head2 Integer Arithmetic
1805
1806 By default, Perl assumes that it must do most of its arithmetic in
1807 floating point.  But by saying
1808
1809     use integer;
1810
1811 you may tell the compiler that it's okay to use integer operations
1812 (if it feels like it) from here to the end of the enclosing BLOCK.
1813 An inner BLOCK may countermand this by saying
1814
1815     no integer;
1816
1817 which lasts until the end of that BLOCK.  Note that this doesn't
1818 mean everything is only an integer, merely that Perl may use integer
1819 operations if it is so inclined.  For example, even under C<use
1820 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
1821 or so.
1822
1823 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
1824 and ">>") always produce integral results.  (But see also L<Bitwise
1825 String Operators>.)  However, C<use integer> still has meaning for
1826 them.  By default, their results are interpreted as unsigned integers, but
1827 if C<use integer> is in effect, their results are interpreted
1828 as signed integers.  For example, C<~0> usually evaluates to a large
1829 integral value.  However, C<use integer; ~0> is C<-1> on twos-complement
1830 machines.
1831
1832 =head2 Floating-point Arithmetic
1833
1834 While C<use integer> provides integer-only arithmetic, there is no
1835 analogous mechanism to provide automatic rounding or truncation to a
1836 certain number of decimal places.  For rounding to a certain number
1837 of digits, sprintf() or printf() is usually the easiest route.
1838 See L<perlfaq4>.
1839
1840 Floating-point numbers are only approximations to what a mathematician
1841 would call real numbers.  There are infinitely more reals than floats,
1842 so some corners must be cut.  For example:
1843
1844     printf "%.20g\n", 123456789123456789;
1845     #        produces 123456789123456784
1846
1847 Testing for exact equality of floating-point equality or inequality is
1848 not a good idea.  Here's a (relatively expensive) work-around to compare
1849 whether two floating-point numbers are equal to a particular number of
1850 decimal places.  See Knuth, volume II, for a more robust treatment of
1851 this topic.
1852
1853     sub fp_equal {
1854         my ($X, $Y, $POINTS) = @_;
1855         my ($tX, $tY);
1856         $tX = sprintf("%.${POINTS}g", $X);
1857         $tY = sprintf("%.${POINTS}g", $Y);
1858         return $tX eq $tY;
1859     }
1860
1861 The POSIX module (part of the standard perl distribution) implements
1862 ceil(), floor(), and other mathematical and trigonometric functions.
1863 The Math::Complex module (part of the standard perl distribution)
1864 defines mathematical functions that work on both the reals and the
1865 imaginary numbers.  Math::Complex not as efficient as POSIX, but
1866 POSIX can't work with complex numbers.
1867
1868 Rounding in financial applications can have serious implications, and
1869 the rounding method used should be specified precisely.  In these
1870 cases, it probably pays not to trust whichever system rounding is
1871 being used by Perl, but to instead implement the rounding function you
1872 need yourself.
1873
1874 =head2 Bigger Numbers
1875
1876 The standard Math::BigInt and Math::BigFloat modules provide
1877 variable-precision arithmetic and overloaded operators, although
1878 they're currently pretty slow.  At the cost of some space and
1879 considerable speed, they avoid the normal pitfalls associated with
1880 limited-precision representations.
1881
1882     use Math::BigInt;
1883     $x = Math::BigInt->new('123456789123456789');
1884     print $x * $x;
1885
1886     # prints +15241578780673678515622620750190521
1887
1888 The non-standard modules SSLeay::BN and Math::Pari provide
1889 equivalent functionality (and much more) with a substantial
1890 performance savings.