This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
various pod tweaks (from M.J.T. Guy <mjtg@cus.cam.ac.uk>)
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
204 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>, C<stat>, C<symlink>, C<syscall>,
238 C<sysopen>, C<system>, C<times>, C<truncate>, C<umask>, C<unlink>,
239 C<utime>, C<wait>, C<waitpid>
240
241 For more information about the portability of these functions, see
242 L<perlport> and other available platform-specific documentation.
243
244 =head2 Alphabetical Listing of Perl Functions
245
246 =over 8
247
248 =item I<-X> FILEHANDLE
249
250 =item I<-X> EXPR
251
252 =item I<-X>
253
254 A file test, where X is one of the letters listed below.  This unary
255 operator takes one argument, either a filename or a filehandle, and
256 tests the associated file to see if something is true about it.  If the
257 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
258 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
259 the undefined value if the file doesn't exist.  Despite the funny
260 names, precedence is the same as any other named unary operator, and
261 the argument may be parenthesized like any other unary operator.  The
262 operator may be any of:
263 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
264 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
265
266     -r  File is readable by effective uid/gid.
267     -w  File is writable by effective uid/gid.
268     -x  File is executable by effective uid/gid.
269     -o  File is owned by effective uid.
270
271     -R  File is readable by real uid/gid.
272     -W  File is writable by real uid/gid.
273     -X  File is executable by real uid/gid.
274     -O  File is owned by real uid.
275
276     -e  File exists.
277     -z  File has zero size.
278     -s  File has nonzero size (returns size).
279
280     -f  File is a plain file.
281     -d  File is a directory.
282     -l  File is a symbolic link.
283     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
284     -S  File is a socket.
285     -b  File is a block special file.
286     -c  File is a character special file.
287     -t  Filehandle is opened to a tty.
288
289     -u  File has setuid bit set.
290     -g  File has setgid bit set.
291     -k  File has sticky bit set.
292
293     -T  File is an ASCII text file.
294     -B  File is a "binary" file (opposite of -T).
295
296     -M  Age of file in days when script started.
297     -A  Same for access time.
298     -C  Same for inode change time.
299
300 Example:
301
302     while (<>) {
303         chop;
304         next unless -f $_;      # ignore specials
305         #...
306     }
307
308 The interpretation of the file permission operators C<-r>, C<-R>,
309 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
310 of the file and the uids and gids of the user.  There may be other
311 reasons you can't actually read, write, or execute the file.  Such
312 reasons may be for example network filesystem access controls, ACLs
313 (access control lists), read-only filesystems, and unrecognized
314 executable formats.
315
316 Also note that, for the superuser on the local filesystems, the C<-r>,
317 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
318 if any execute bit is set in the mode.  Scripts run by the superuser
319 may thus need to do a stat() to determine the actual mode of the file,
320 or temporarily set their effective uid to something else.
321
322 If you are using ACLs, there is a pragma called C<filetest> that may
323 produce more accurate results than the bare stat() mode bits.
324 When under the C<use filetest 'access'> the above-mentioned filetests
325 will test whether the permission can (not) be granted using the
326 access() family of system calls.  Also note that the C<-x> and C<-X> may
327 under this pragma return true even if there are no execute permission
328 bits set (nor any extra execute permission ACLs).  This strangeness is
329 due to the underlying system calls' definitions.  Read the
330 documentation for the C<filetest> pragma for more information.
331
332 Note that C<-s/a/b/> does not do a negated substitution.  Saying
333 C<-exp($foo)> still works as expected, however--only single letters
334 following a minus are interpreted as file tests.
335
336 The C<-T> and C<-B> switches work as follows.  The first block or so of the
337 file is examined for odd characters such as strange control codes or
338 characters with the high bit set.  If too many strange characters (E<gt>30%)
339 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
340 containing null in the first block is considered a binary file.  If C<-T>
341 or C<-B> is used on a filehandle, the current stdio buffer is examined
342 rather than the first block.  Both C<-T> and C<-B> return true on a null
343 file, or a file at EOF when testing a filehandle.  Because you have to
344 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
345 against the file first, as in C<next unless -f $file && -T $file>.
346
347 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
348 the special filehandle consisting of a solitary underline, then the stat
349 structure of the previous file test (or stat operator) is used, saving
350 a system call.  (This doesn't work with C<-t>, and you need to remember
351 that lstat() and C<-l> will leave values in the stat structure for the
352 symbolic link, not the real file.)  Example:
353
354     print "Can do.\n" if -r $a || -w _ || -x _;
355
356     stat($filename);
357     print "Readable\n" if -r _;
358     print "Writable\n" if -w _;
359     print "Executable\n" if -x _;
360     print "Setuid\n" if -u _;
361     print "Setgid\n" if -g _;
362     print "Sticky\n" if -k _;
363     print "Text\n" if -T _;
364     print "Binary\n" if -B _;
365
366 =item abs VALUE
367
368 =item abs
369
370 Returns the absolute value of its argument.
371 If VALUE is omitted, uses C<$_>.
372
373 =item accept NEWSOCKET,GENERICSOCKET
374
375 Accepts an incoming socket connect, just as the accept(2) system call
376 does.  Returns the packed address if it succeeded, false otherwise.
377 See the example in L<perlipc/"Sockets: Client/Server Communication">.
378
379 =item alarm SECONDS
380
381 =item alarm
382
383 Arranges to have a SIGALRM delivered to this process after the
384 specified number of seconds have elapsed.  If SECONDS is not specified,
385 the value stored in C<$_> is used. (On some machines,
386 unfortunately, the elapsed time may be up to one second less than you
387 specified because of how seconds are counted.)  Only one timer may be
388 counting at once.  Each call disables the previous timer, and an
389 argument of C<0> may be supplied to cancel the previous timer without
390 starting a new one.  The returned value is the amount of time remaining
391 on the previous timer.
392
393 For delays of finer granularity than one second, you may use Perl's
394 four-argument version of select() leaving the first three arguments
395 undefined, or you might be able to use the C<syscall> interface to
396 access setitimer(2) if your system supports it.  The Time::HiRes module
397 from CPAN may also prove useful.
398
399 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
400 (C<sleep> may be internally implemented in your system with C<alarm>)
401
402 If you want to use C<alarm> to time out a system call you need to use an
403 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
404 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
405 restart system calls on some systems.  Using C<eval>/C<die> always works,
406 modulo the caveats given in L<perlipc/"Signals">.
407
408     eval {
409         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
410         alarm $timeout;
411         $nread = sysread SOCKET, $buffer, $size;
412         alarm 0;
413     };
414     if ($@) {
415         die unless $@ eq "alarm\n";   # propagate unexpected errors
416         # timed out
417     }
418     else {
419         # didn't
420     }
421
422 =item atan2 Y,X
423
424 Returns the arctangent of Y/X in the range -PI to PI.
425
426 For the tangent operation, you may use the C<POSIX::tan()>
427 function, or use the familiar relation:
428
429     sub tan { sin($_[0]) / cos($_[0])  }
430
431 =item bind SOCKET,NAME
432
433 Binds a network address to a socket, just as the bind system call
434 does.  Returns true if it succeeded, false otherwise.  NAME should be a
435 packed address of the appropriate type for the socket.  See the examples in
436 L<perlipc/"Sockets: Client/Server Communication">.
437
438 =item binmode FILEHANDLE
439
440 Arranges for FILEHANDLE to be read or written in "binary" mode on
441 systems whose run-time libraries force the programmer to guess
442 between binary and text files.  If FILEHANDLE is an expression, the
443 value is taken as the name of the filehandle.  binmode() should be
444 called after the C<open> but before any I/O is done on the filehandle.
445 The only way to reset binary mode on a filehandle is to reopen the
446 file.
447
448 The operating system, device drivers, C libraries, and Perl run-time
449 system all conspire to let the programmer conveniently treat a
450 simple, one-byte C<\n> as the line terminator, irrespective of its
451 external representation.  On Unix and its brethren, the native file
452 representation exactly matches the internal representation, making
453 everyone's lives unbelievably simpler.  Consequently, L<binmode>
454 has no effect under Unix, Plan9, or Mac OS, all of which use C<\n>
455 to end each line.  (Unix and Plan9 think C<\n> means C<\cJ> and
456 C<\r> means C<\cM>, whereas the Mac goes the other way--it uses
457 C<\cM> for c<\n> and C<\cJ> to mean C<\r>.  But that's ok, because
458 it's only one byte, and the internal and external representations
459 match.)
460
461 In legacy systems like MS-DOS and its embellishments, your program
462 sees a C<\n> as a simple C<\cJ> (just as in Unix), but oddly enough,
463 that's not what's physically stored on disk.  What's worse, these
464 systems refuse to help you with this; it's up to you to remember
465 what to do.  And you mustn't go applying binmode() with wild abandon,
466 either, because if your system does care about binmode(), then using
467 it when you shouldn't is just as perilous as failing to use it when
468 you should.
469
470 That means that on any version of Microsoft WinXX that you might
471 care to name (or not), binmode() causes C<\cM\cJ> sequences on disk
472 to be converted to C<\n> when read into your program, and causes
473 any C<\n> in your program to be converted back to C<\cM\cJ> on
474 output to disk.  This sad discrepancy leads to no end of
475 problems in not just the readline operator, but also when using
476 seek(), tell(), and read() calls.  See L<perlport> for other painful
477 details.  See the C<$/> and C<$\> variables in L<perlvar> for how
478 to manually set your input and output line-termination sequences.
479
480 =item bless REF,CLASSNAME
481
482 =item bless REF
483
484 This function tells the thingy referenced by REF that it is now an object
485 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
486 is used.  Because a C<bless> is often the last thing in a constructor,
487 it returns the reference for convenience.  Always use the two-argument
488 version if the function doing the blessing might be inherited by a
489 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
490 (and blessings) of objects.
491
492 Consider always blessing objects in CLASSNAMEs that are mixed case.
493 Namespaces with all lowercase names are considered reserved for
494 Perl pragmata.  Builtin types have all uppercase names, so to prevent
495 confusion, you may wish to avoid such package names as well.  Make sure
496 that CLASSNAME is a true value.
497
498 See L<perlmod/"Perl Modules">.
499
500 =item caller EXPR
501
502 =item caller
503
504 Returns the context of the current subroutine call.  In scalar context,
505 returns the caller's package name if there is a caller, that is, if
506 we're in a subroutine or C<eval> or C<require>, and the undefined value
507 otherwise.  In list context, returns
508
509     ($package, $filename, $line) = caller;
510
511 With EXPR, it returns some extra information that the debugger uses to
512 print a stack trace.  The value of EXPR indicates how many call frames
513 to go back before the current one.
514
515     ($package, $filename, $line, $subroutine, $hasargs,
516     $wantarray, $evaltext, $is_require, $hints) = caller($i);
517
518 Here $subroutine may be C<"(eval)"> if the frame is not a subroutine
519 call, but an C<eval>.  In such a case additional elements $evaltext and
520 C<$is_require> are set: C<$is_require> is true if the frame is created by a
521 C<require> or C<use> statement, $evaltext contains the text of the
522 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
523 $filename is C<"(eval)">, but $evaltext is undefined.  (Note also that
524 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
525 frame.  C<$hints> contains pragmatic hints that the caller was
526 compiled with.  It currently only reflects the hint corresponding to
527 C<use utf8>.
528
529 Furthermore, when called from within the DB package, caller returns more
530 detailed information: it sets the list variable C<@DB::args> to be the
531 arguments with which the subroutine was invoked.
532
533 Be aware that the optimizer might have optimized call frames away before
534 C<caller> had a chance to get the information.  That means that C<caller(N)>
535 might not return information about the call frame you expect it do, for
536 C<N E<gt> 1>.  In particular, C<@DB::args> might have information from the 
537 previous time C<caller> was called.
538
539 =item chdir EXPR
540
541 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
542 changes to the user's home directory.  Returns true upon success,
543 false otherwise.  See the example under C<die>.
544
545 =item chmod LIST
546
547 Changes the permissions of a list of files.  The first element of the
548 list must be the numerical mode, which should probably be an octal
549 number, and which definitely should I<not> a string of octal digits:
550 C<0644> is okay, C<'0644'> is not.  Returns the number of files
551 successfully changed.  See also L</oct>, if all you have is a string.
552
553     $cnt = chmod 0755, 'foo', 'bar';
554     chmod 0755, @executables;
555     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
556                                              # --w----r-T
557     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
558     $mode = 0644;   chmod $mode, 'foo';      # this is best
559
560 =item chomp VARIABLE
561
562 =item chomp LIST
563
564 =item chomp
565
566 This safer version of L</chop> removes any trailing string
567 that corresponds to the current value of C<$/> (also known as
568 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
569 number of characters removed from all its arguments.  It's often used to
570 remove the newline from the end of an input record when you're worried
571 that the final record may be missing its newline.  When in paragraph
572 mode (C<$/ = "">), it removes all trailing newlines from the string.
573 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
574 a reference to an integer or the like, see L<perlvar>) chomp() won't
575 remove anything.  
576 If VARIABLE is omitted, it chomps C<$_>.  Example:
577
578     while (<>) {
579         chomp;  # avoid \n on last field
580         @array = split(/:/);
581         # ...
582     }
583
584 You can actually chomp anything that's an lvalue, including an assignment:
585
586     chomp($cwd = `pwd`);
587     chomp($answer = <STDIN>);
588
589 If you chomp a list, each element is chomped, and the total number of
590 characters removed is returned.
591
592 =item chop VARIABLE
593
594 =item chop LIST
595
596 =item chop
597
598 Chops off the last character of a string and returns the character
599 chopped.  It's used primarily to remove the newline from the end of an
600 input record, but is much more efficient than C<s/\n//> because it neither
601 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
602 Example:
603
604     while (<>) {
605         chop;   # avoid \n on last field
606         @array = split(/:/);
607         #...
608     }
609
610 You can actually chop anything that's an lvalue, including an assignment:
611
612     chop($cwd = `pwd`);
613     chop($answer = <STDIN>);
614
615 If you chop a list, each element is chopped.  Only the value of the
616 last C<chop> is returned.
617
618 Note that C<chop> returns the last character.  To return all but the last
619 character, use C<substr($string, 0, -1)>.
620
621 =item chown LIST
622
623 Changes the owner (and group) of a list of files.  The first two
624 elements of the list must be the I<numeric> uid and gid, in that
625 order.  A value of -1 in either position is interpreted by most
626 systems to leave that value unchanged.  Returns the number of files
627 successfully changed.
628
629     $cnt = chown $uid, $gid, 'foo', 'bar';
630     chown $uid, $gid, @filenames;
631
632 Here's an example that looks up nonnumeric uids in the passwd file:
633
634     print "User: ";
635     chomp($user = <STDIN>);
636     print "Files: ";
637     chomp($pattern = <STDIN>);
638
639     ($login,$pass,$uid,$gid) = getpwnam($user)
640         or die "$user not in passwd file";
641
642     @ary = glob($pattern);      # expand filenames
643     chown $uid, $gid, @ary;
644
645 On most systems, you are not allowed to change the ownership of the
646 file unless you're the superuser, although you should be able to change
647 the group to any of your secondary groups.  On insecure systems, these
648 restrictions may be relaxed, but this is not a portable assumption.
649 On POSIX systems, you can detect this condition this way:
650
651     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
652     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
653
654 =item chr NUMBER
655
656 =item chr
657
658 Returns the character represented by that NUMBER in the character set.
659 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
660 chr(0x263a) is a Unicode smiley face (but only within the scope of
661 a C<use utf8>).  For the reverse, use L</ord>.  
662 See L<utf8> for more about Unicode.
663
664 If NUMBER is omitted, uses C<$_>.
665
666 =item chroot FILENAME
667
668 =item chroot
669
670 This function works like the system call by the same name: it makes the
671 named directory the new root directory for all further pathnames that
672 begin with a C<"/"> by your process and all its children.  (It doesn't
673 change your current working directory, which is unaffected.)  For security
674 reasons, this call is restricted to the superuser.  If FILENAME is
675 omitted, does a C<chroot> to C<$_>.
676
677 =item close FILEHANDLE
678
679 =item close
680
681 Closes the file or pipe associated with the file handle, returning true
682 only if stdio successfully flushes buffers and closes the system file
683 descriptor.  Closes the currently selected filehandle if the argument
684 is omitted.
685
686 You don't have to close FILEHANDLE if you are immediately going to do
687 another C<open> on it, because C<open> will close it for you.  (See
688 C<open>.)  However, an explicit C<close> on an input file resets the line
689 counter (C<$.>), while the implicit close done by C<open> does not.
690
691 If the file handle came from a piped open C<close> will additionally
692 return false if one of the other system calls involved fails or if the
693 program exits with non-zero status.  (If the only problem was that the
694 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe 
695 also waits for the process executing on the pipe to complete, in case you
696 want to look at the output of the pipe afterwards, and 
697 implicitly puts the exit status value of that command into C<$?>.
698
699 Prematurely closing the read end of a pipe (i.e. before the process
700 writing to it at the other end has closed it) will result in a
701 SIGPIPE being delivered to the writer.  If the other end can't
702 handle that, be sure to read all the data before closing the pipe.
703
704 Example:
705
706     open(OUTPUT, '|sort >foo')  # pipe to sort
707         or die "Can't start sort: $!";
708     #...                        # print stuff to output
709     close OUTPUT                # wait for sort to finish
710         or warn $! ? "Error closing sort pipe: $!"
711                    : "Exit status $? from sort";
712     open(INPUT, 'foo')          # get sort's results
713         or die "Can't open 'foo' for input: $!";
714
715 FILEHANDLE may be an expression whose value can be used as an indirect
716 filehandle, usually the real filehandle name.
717
718 =item closedir DIRHANDLE
719
720 Closes a directory opened by C<opendir> and returns the success of that
721 system call.
722
723 DIRHANDLE may be an expression whose value can be used as an indirect
724 dirhandle, usually the real dirhandle name.
725
726 =item connect SOCKET,NAME
727
728 Attempts to connect to a remote socket, just as the connect system call
729 does.  Returns true if it succeeded, false otherwise.  NAME should be a
730 packed address of the appropriate type for the socket.  See the examples in
731 L<perlipc/"Sockets: Client/Server Communication">.
732
733 =item continue BLOCK
734
735 Actually a flow control statement rather than a function.  If there is a
736 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
737 C<foreach>), it is always executed just before the conditional is about to
738 be evaluated again, just like the third part of a C<for> loop in C.  Thus
739 it can be used to increment a loop variable, even when the loop has been
740 continued via the C<next> statement (which is similar to the C C<continue>
741 statement).
742
743 C<last>, C<next>, or C<redo> may appear within a C<continue>
744 block.  C<last> and C<redo> will behave as if they had been executed within
745 the main block.  So will C<next>, but since it will execute a C<continue>
746 block, it may be more entertaining.
747
748     while (EXPR) {
749         ### redo always comes here
750         do_something;
751     } continue {
752         ### next always comes here
753         do_something_else;
754         # then back the top to re-check EXPR
755     }
756     ### last always comes here
757
758 Omitting the C<continue> section is semantically equivalent to using an
759 empty one, logically enough.  In that case, C<next> goes directly back
760 to check the condition at the top of the loop.
761
762 =item cos EXPR
763
764 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
765 takes cosine of C<$_>.
766
767 For the inverse cosine operation, you may use the C<POSIX::acos()>
768 function, or use this relation:
769
770     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
771
772 =item crypt PLAINTEXT,SALT
773
774 Encrypts a string exactly like the crypt(3) function in the C library
775 (assuming that you actually have a version there that has not been
776 extirpated as a potential munition).  This can prove useful for checking
777 the password file for lousy passwords, amongst other things.  Only the
778 guys wearing white hats should do this.
779
780 Note that C<crypt> is intended to be a one-way function, much like breaking
781 eggs to make an omelette.  There is no (known) corresponding decrypt
782 function.  As a result, this function isn't all that useful for
783 cryptography.  (For that, see your nearby CPAN mirror.)
784
785 When verifying an existing encrypted string you should use the encrypted
786 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
787 allows your code to work with the standard C<crypt> and with more
788 exotic implementations.  When choosing a new salt create a random two
789 character string whose characters come from the set C<[./0-9A-Za-z]>
790 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
791
792 Here's an example that makes sure that whoever runs this program knows
793 their own password:
794
795     $pwd = (getpwuid($<))[1];
796
797     system "stty -echo";
798     print "Password: ";
799     chomp($word = <STDIN>);
800     print "\n";
801     system "stty echo";
802
803     if (crypt($word, $pwd) ne $pwd) {
804         die "Sorry...\n";
805     } else {
806         print "ok\n";
807     }
808
809 Of course, typing in your own password to whoever asks you
810 for it is unwise.
811
812 The L<crypt> function is unsuitable for encrypting large quantities
813 of data, not least of all because you can't get the information
814 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
815 on your favorite CPAN mirror for a slew of potentially useful
816 modules.
817
818 =item dbmclose HASH
819
820 [This function has been largely superseded by the C<untie> function.]
821
822 Breaks the binding between a DBM file and a hash.
823
824 =item dbmopen HASH,DBNAME,MASK
825
826 [This function has been largely superseded by the C<tie> function.]
827
828 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
829 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
830 argument is I<not> a filehandle, even though it looks like one).  DBNAME
831 is the name of the database (without the F<.dir> or F<.pag> extension if
832 any).  If the database does not exist, it is created with protection
833 specified by MASK (as modified by the C<umask>).  If your system supports
834 only the older DBM functions, you may perform only one C<dbmopen> in your
835 program.  In older versions of Perl, if your system had neither DBM nor
836 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
837 sdbm(3).
838
839 If you don't have write access to the DBM file, you can only read hash
840 variables, not set them.  If you want to test whether you can write,
841 either use file tests or try setting a dummy hash entry inside an C<eval>,
842 which will trap the error.
843
844 Note that functions such as C<keys> and C<values> may return huge lists
845 when used on large DBM files.  You may prefer to use the C<each>
846 function to iterate over large DBM files.  Example:
847
848     # print out history file offsets
849     dbmopen(%HIST,'/usr/lib/news/history',0666);
850     while (($key,$val) = each %HIST) {
851         print $key, ' = ', unpack('L',$val), "\n";
852     }
853     dbmclose(%HIST);
854
855 See also L<AnyDBM_File> for a more general description of the pros and
856 cons of the various dbm approaches, as well as L<DB_File> for a particularly
857 rich implementation.
858
859 You can control which DBM library you use by loading that library
860 before you call dbmopen():
861
862     use DB_File;
863     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
864         or die "Can't open netscape history file: $!";
865
866 =item defined EXPR
867
868 =item defined
869
870 Returns a Boolean value telling whether EXPR has a value other than
871 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
872 checked.
873
874 Many operations return C<undef> to indicate failure, end of file,
875 system error, uninitialized variable, and other exceptional
876 conditions.  This function allows you to distinguish C<undef> from
877 other values.  (A simple Boolean test will not distinguish among
878 C<undef>, zero, the empty string, and C<"0">, which are all equally
879 false.)  Note that since C<undef> is a valid scalar, its presence
880 doesn't I<necessarily> indicate an exceptional condition: C<pop>
881 returns C<undef> when its argument is an empty array, I<or> when the
882 element to return happens to be C<undef>.
883
884 You may also use C<defined(&func)> to check whether subroutine C<&func>
885 has ever been defined.  The return value is unaffected by any forward
886 declarations of C<&foo>.
887
888 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
889 used to report whether memory for that aggregate has ever been
890 allocated.  This behavior may disappear in future versions of Perl.
891 You should instead use a simple test for size:
892
893     if (@an_array) { print "has array elements\n" }
894     if (%a_hash)   { print "has hash members\n"   }
895
896 When used on a hash element, it tells you whether the value is defined,
897 not whether the key exists in the hash.  Use L</exists> for the latter
898 purpose.
899
900 Examples:
901
902     print if defined $switch{'D'};
903     print "$val\n" while defined($val = pop(@ary));
904     die "Can't readlink $sym: $!"
905         unless defined($value = readlink $sym);
906     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
907     $debugging = 0 unless defined $debugging;
908
909 Note:  Many folks tend to overuse C<defined>, and then are surprised to
910 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
911 defined values.  For example, if you say
912
913     "ab" =~ /a(.*)b/;
914
915 The pattern match succeeds, and C<$1> is defined, despite the fact that it
916 matched "nothing".  But it didn't really match nothing--rather, it
917 matched something that happened to be zero characters long.  This is all
918 very above-board and honest.  When a function returns an undefined value,
919 it's an admission that it couldn't give you an honest answer.  So you
920 should use C<defined> only when you're questioning the integrity of what
921 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
922 what you want.
923
924 See also L</undef>, L</exists>, L</ref>.
925
926 =item delete EXPR
927
928 Deletes the specified key(s) and their associated values from a hash.
929 For each key, returns the deleted value associated with that key, or
930 the undefined value if there was no such key.  Deleting from C<$ENV{}>
931 modifies the environment.  Deleting from a hash tied to a DBM file
932 deletes the entry from the DBM file.  (But deleting from a C<tie>d hash
933 doesn't necessarily return anything.)
934
935 The following deletes all the values of a hash:
936
937     foreach $key (keys %HASH) {
938         delete $HASH{$key};
939     }
940
941 And so does this:
942
943     delete @HASH{keys %HASH}
944
945 But both of these are slower than just assigning the empty list
946 or undefining it:
947
948     %hash = ();         # completely empty %hash
949     undef %hash;        # forget %hash every existed
950
951 Note that the EXPR can be arbitrarily complicated as long as the final
952 operation is a hash element lookup or hash slice:
953
954     delete $ref->[$x][$y]{$key};
955     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
956
957 =item die LIST
958
959 Outside an C<eval>, prints the value of LIST to C<STDERR> and
960 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
961 exits with the value of C<($? E<gt>E<gt> 8)> (backtick `command`
962 status).  If C<($? E<gt>E<gt> 8)> is C<0>, exits with C<255>.  Inside
963 an C<eval(),> the error message is stuffed into C<$@> and the
964 C<eval> is terminated with the undefined value.  This makes
965 C<die> the way to raise an exception.
966
967 Equivalent examples:
968
969     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
970     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
971
972 If the value of EXPR does not end in a newline, the current script line
973 number and input line number (if any) are also printed, and a newline
974 is supplied.  Note that the "input line number" (also known as "chunk")
975 is subject to whatever notion of "line" happens to be currently in
976 effect, and is also available as the special variable C<$.>.
977 See L<perlvar/"$/"> and L<perlvar/"$.">.
978
979 Hint: sometimes appending C<", stopped"> to your message
980 will cause it to make better sense when the string C<"at foo line 123"> is
981 appended.  Suppose you are running script "canasta".
982
983     die "/etc/games is no good";
984     die "/etc/games is no good, stopped";
985
986 produce, respectively
987
988     /etc/games is no good at canasta line 123.
989     /etc/games is no good, stopped at canasta line 123.
990
991 See also exit(), warn(), and the Carp module.
992
993 If LIST is empty and C<$@> already contains a value (typically from a
994 previous eval) that value is reused after appending C<"\t...propagated">.
995 This is useful for propagating exceptions:
996
997     eval { ... };
998     die unless $@ =~ /Expected exception/;
999
1000 If C<$@> is empty then the string C<"Died"> is used.
1001
1002 die() can also be called with a reference argument.  If this happens to be
1003 trapped within an eval(), $@ contains the reference.  This behavior permits
1004 a more elaborate exception handling implementation using objects that
1005 maintain arbitary state about the nature of the exception.  Such a scheme
1006 is sometimes preferable to matching particular string values of $@ using
1007 regular expressions.  Here's an example:
1008
1009     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1010     if ($@) {
1011         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1012             # handle Some::Module::Exception
1013         }
1014         else {
1015             # handle all other possible exceptions
1016         }
1017     }
1018
1019 Because perl will stringify uncaught exception messages before displaying
1020 them, you may want to overload stringification operations on such custom
1021 exception objects.  See L<overload> for details about that.
1022
1023 You can arrange for a callback to be run just before the C<die>
1024 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1025 handler will be called with the error text and can change the error
1026 message, if it sees fit, by calling C<die> again.  See
1027 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1028 L<"eval BLOCK"> for some examples.  Although this feature was meant
1029 to be run only right before your program was to exit, this is not
1030 currently the case--the C<$SIG{__DIE__}> hook is currently called
1031 even inside eval()ed blocks/strings!  If one wants the hook to do
1032 nothing in such situations, put
1033
1034         die @_ if $^S;
1035
1036 as the first line of the handler (see L<perlvar/$^S>).  Because
1037 this promotes strange action at a distance, this counterintuitive
1038 behavior may be fixed in a future release.  
1039
1040 =item do BLOCK
1041
1042 Not really a function.  Returns the value of the last command in the
1043 sequence of commands indicated by BLOCK.  When modified by a loop
1044 modifier, executes the BLOCK once before testing the loop condition.
1045 (On other statements the loop modifiers test the conditional first.)
1046
1047 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1048 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1049 See L<perlsyn> for alternative strategies.
1050
1051 =item do SUBROUTINE(LIST)
1052
1053 A deprecated form of subroutine call.  See L<perlsub>.
1054
1055 =item do EXPR
1056
1057 Uses the value of EXPR as a filename and executes the contents of the
1058 file as a Perl script.  Its primary use is to include subroutines
1059 from a Perl subroutine library.
1060
1061     do 'stat.pl';
1062
1063 is just like
1064
1065     scalar eval `cat stat.pl`;
1066
1067 except that it's more efficient and concise, keeps track of the current
1068 filename for error messages, searches the @INC libraries, and updates
1069 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1070 variables.  It also differs in that code evaluated with C<do FILENAME>
1071 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1072 same, however, in that it does reparse the file every time you call it,
1073 so you probably don't want to do this inside a loop.
1074
1075 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1076 error.  If C<do> can read the file but cannot compile it, it
1077 returns undef and sets an error message in C<$@>.   If the file is
1078 successfully compiled, C<do> returns the value of the last expression
1079 evaluated.
1080
1081 Note that inclusion of library modules is better done with the
1082 C<use> and C<require> operators, which also do automatic error checking
1083 and raise an exception if there's a problem.
1084
1085 You might like to use C<do> to read in a program configuration
1086 file.  Manual error checking can be done this way:
1087
1088     # read in config files: system first, then user 
1089     for $file ("/share/prog/defaults.rc",
1090                "$ENV{HOME}/.someprogrc") 
1091    {
1092         unless ($return = do $file) {
1093             warn "couldn't parse $file: $@" if $@;
1094             warn "couldn't do $file: $!"    unless defined $return;
1095             warn "couldn't run $file"       unless $return;
1096         }
1097     }
1098
1099 =item dump LABEL
1100
1101 =item dump
1102
1103 This function causes an immediate core dump.  See also the B<-u>
1104 command-line switch in L<perlrun>, which does the same thing.
1105 Primarily this is so that you can use the B<undump> program (not
1106 supplied) to turn your core dump into an executable binary after
1107 having initialized all your variables at the beginning of the
1108 program.  When the new binary is executed it will begin by executing
1109 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1110 Think of it as a goto with an intervening core dump and reincarnation.
1111 If C<LABEL> is omitted, restarts the program from the top.
1112
1113 B<WARNING>: Any files opened at the time of the dump will I<not>
1114 be open any more when the program is reincarnated, with possible
1115 resulting confusion on the part of Perl.  
1116
1117 This function is now largely obsolete, partly because it's very
1118 hard to convert a core file into an executable, and because the
1119 real compiler backends for generating portable bytecode and compilable
1120 C code have superseded it.
1121
1122 If you're looking to use L<dump> to speed up your program, consider
1123 generating bytecode or native C code as described in L<perlcc>.  If
1124 you're just trying to accelerate a CGI script, consider using the
1125 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1126 You might also consider autoloading or selfloading, which at least
1127 make your program I<appear> to run faster.  
1128
1129 =item each HASH
1130
1131 When called in list context, returns a 2-element list consisting of the
1132 key and value for the next element of a hash, so that you can iterate over
1133 it.  When called in scalar context, returns the key for only the "next"
1134 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
1135 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
1136 for this reason.)
1137
1138 Entries are returned in an apparently random order.  The actual random
1139 order is subject to change in future versions of perl, but it is guaranteed
1140 to be in the same order as either the C<keys> or C<values> function
1141 would produce on the same (unmodified) hash.
1142
1143 When the hash is entirely read, a null array is returned in list context
1144 (which when assigned produces a false (C<0>) value), and C<undef> in
1145 scalar context.  The next call to C<each> after that will start iterating
1146 again.  There is a single iterator for each hash, shared by all C<each>,
1147 C<keys>, and C<values> function calls in the program; it can be reset by
1148 reading all the elements from the hash, or by evaluating C<keys HASH> or
1149 C<values HASH>.  If you add or delete elements of a hash while you're
1150 iterating over it, you may get entries skipped or duplicated, so don't.
1151
1152 The following prints out your environment like the printenv(1) program,
1153 only in a different order:
1154
1155     while (($key,$value) = each %ENV) {
1156         print "$key=$value\n";
1157     }
1158
1159 See also C<keys>, C<values> and C<sort>.
1160
1161 =item eof FILEHANDLE
1162
1163 =item eof ()
1164
1165 =item eof
1166
1167 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1168 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1169 gives the real filehandle.  (Note that this function actually
1170 reads a character and then C<ungetc>s it, so isn't very useful in an
1171 interactive context.)  Do not read from a terminal file (or call
1172 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1173 as terminals may lose the end-of-file condition if you do.
1174
1175 An C<eof> without an argument uses the last file read as argument.
1176 Using C<eof()> with empty parentheses is very different.  It indicates
1177 the pseudo file formed of the files listed on the command line,
1178 i.e., C<eof()> is reasonable to use inside a C<while (E<lt>E<gt>)>
1179 loop to detect the end of only the last file.  Use C<eof(ARGV)> or
1180 C<eof> without the parentheses to test I<each> file in a while
1181 (E<lt>E<gt>) loop.  Examples:
1182
1183     # reset line numbering on each input file
1184     while (<>) {
1185         next if /^\s*#/;        # skip comments 
1186         print "$.\t$_";
1187     } continue {
1188         close ARGV  if eof;     # Not eof()!
1189     }
1190
1191     # insert dashes just before last line of last file
1192     while (<>) {
1193         if (eof()) {            # check for end of current file
1194             print "--------------\n";
1195             close(ARGV);        # close or last; is needed if we
1196                                 # are reading from the terminal
1197         }
1198         print;
1199     }
1200
1201 Practical hint: you almost never need to use C<eof> in Perl, because the
1202 input operators return false values when they run out of data, or if there
1203 was an error.
1204
1205 =item eval EXPR
1206
1207 =item eval BLOCK
1208
1209 In the first form, the return value of EXPR is parsed and executed as if it
1210 were a little Perl program.  The value of the expression (which is itself
1211 determined within scalar context) is first parsed, and if there weren't any
1212 errors, executed in the context of the current Perl program, so that any
1213 variable settings or subroutine and format definitions remain afterwards.
1214 Note that the value is parsed every time the eval executes.  If EXPR is
1215 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1216 and subsequent execution of the text of EXPR until run time.
1217
1218 In the second form, the code within the BLOCK is parsed only once--at the
1219 same time the code surrounding the eval itself was parsed--and executed
1220 within the context of the current Perl program.  This form is typically
1221 used to trap exceptions more efficiently than the first (see below), while
1222 also providing the benefit of checking the code within BLOCK at compile
1223 time.
1224
1225 The final semicolon, if any, may be omitted from the value of EXPR or within
1226 the BLOCK.
1227
1228 In both forms, the value returned is the value of the last expression
1229 evaluated inside the mini-program; a return statement may be also used, just
1230 as with subroutines.  The expression providing the return value is evaluated
1231 in void, scalar, or list context, depending on the context of the eval itself.
1232 See L</wantarray> for more on how the evaluation context can be determined.
1233
1234 If there is a syntax error or runtime error, or a C<die> statement is
1235 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1236 error message.  If there was no error, C<$@> is guaranteed to be a null
1237 string.  Beware that using C<eval> neither silences perl from printing
1238 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1239 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1240 L</warn> and L<perlvar>.
1241
1242 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1243 determining whether a particular feature (such as C<socket> or C<symlink>)
1244 is implemented.  It is also Perl's exception trapping mechanism, where
1245 the die operator is used to raise exceptions.
1246
1247 If the code to be executed doesn't vary, you may use the eval-BLOCK
1248 form to trap run-time errors without incurring the penalty of
1249 recompiling each time.  The error, if any, is still returned in C<$@>.
1250 Examples:
1251
1252     # make divide-by-zero nonfatal
1253     eval { $answer = $a / $b; }; warn $@ if $@;
1254
1255     # same thing, but less efficient
1256     eval '$answer = $a / $b'; warn $@ if $@;
1257
1258     # a compile-time error
1259     eval { $answer = };                 # WRONG
1260
1261     # a run-time error
1262     eval '$answer =';   # sets $@
1263
1264 Due to the current arguably broken state of C<__DIE__> hooks, when using
1265 the C<eval{}> form as an exception trap in libraries, you may wish not
1266 to trigger any C<__DIE__> hooks that user code may have installed.
1267 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1268 as shown in this example:
1269
1270     # a very private exception trap for divide-by-zero
1271     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1272     warn $@ if $@;
1273
1274 This is especially significant, given that C<__DIE__> hooks can call
1275 C<die> again, which has the effect of changing their error messages:
1276
1277     # __DIE__ hooks may modify error messages
1278     {
1279        local $SIG{'__DIE__'} =
1280               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1281        eval { die "foo lives here" };
1282        print $@ if $@;                # prints "bar lives here"
1283     }
1284
1285 Because this promotes action at a distance, this counterintuitive behavior
1286 may be fixed in a future release.
1287
1288 With an C<eval>, you should be especially careful to remember what's
1289 being looked at when:
1290
1291     eval $x;            # CASE 1
1292     eval "$x";          # CASE 2
1293
1294     eval '$x';          # CASE 3
1295     eval { $x };        # CASE 4
1296
1297     eval "\$$x++";      # CASE 5
1298     $$x++;              # CASE 6
1299
1300 Cases 1 and 2 above behave identically: they run the code contained in
1301 the variable $x.  (Although case 2 has misleading double quotes making
1302 the reader wonder what else might be happening (nothing is).)  Cases 3
1303 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1304 does nothing but return the value of $x.  (Case 4 is preferred for
1305 purely visual reasons, but it also has the advantage of compiling at
1306 compile-time instead of at run-time.)  Case 5 is a place where
1307 normally you I<would> like to use double quotes, except that in this
1308 particular situation, you can just use symbolic references instead, as
1309 in case 6.
1310
1311 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1312 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1313
1314 =item exec LIST
1315
1316 =item exec PROGRAM LIST
1317
1318 The C<exec> function executes a system command I<and never returns>--
1319 use C<system> instead of C<exec> if you want it to return.  It fails and
1320 returns false only if the command does not exist I<and> it is executed
1321 directly instead of via your system's command shell (see below).
1322
1323 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1324 warns you if there is a following statement which isn't C<die>, C<warn>,
1325 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1326 I<really> want to follow an C<exec> with some other statement, you
1327 can use one of these styles to avoid the warning:
1328
1329     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1330     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1331
1332 If there is more than one argument in LIST, or if LIST is an array
1333 with more than one value, calls execvp(3) with the arguments in LIST.
1334 If there is only one scalar argument or an array with one element in it,
1335 the argument is checked for shell metacharacters, and if there are any,
1336 the entire argument is passed to the system's command shell for parsing
1337 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1338 If there are no shell metacharacters in the argument, it is split into
1339 words and passed directly to C<execvp>, which is more efficient.  
1340 Examples:
1341
1342     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1343     exec "sort $outfile | uniq";
1344
1345 If you don't really want to execute the first argument, but want to lie
1346 to the program you are executing about its own name, you can specify
1347 the program you actually want to run as an "indirect object" (without a
1348 comma) in front of the LIST.  (This always forces interpretation of the
1349 LIST as a multivalued list, even if there is only a single scalar in
1350 the list.)  Example:
1351
1352     $shell = '/bin/csh';
1353     exec $shell '-sh';          # pretend it's a login shell
1354
1355 or, more directly,
1356
1357     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1358
1359 When the arguments get executed via the system shell, results will
1360 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1361 for details.
1362
1363 Using an indirect object with C<exec> or C<system> is also more
1364 secure.  This usage (which also works fine with system()) forces
1365 interpretation of the arguments as a multivalued list, even if the
1366 list had just one argument.  That way you're safe from the shell
1367 expanding wildcards or splitting up words with whitespace in them.
1368
1369     @args = ( "echo surprise" );
1370
1371     exec @args;               # subject to shell escapes
1372                                 # if @args == 1
1373     exec { $args[0] } @args;  # safe even with one-arg list
1374
1375 The first version, the one without the indirect object, ran the I<echo>
1376 program, passing it C<"surprise"> an argument.  The second version
1377 didn't--it tried to run a program literally called I<"echo surprise">,
1378 didn't find it, and set C<$?> to a non-zero value indicating failure.
1379
1380 Note that C<exec> will not call your C<END> blocks, nor will it call
1381 any C<DESTROY> methods in your objects.
1382
1383 =item exists EXPR
1384
1385 Returns true if the specified hash key exists in its hash, even
1386 if the corresponding value is undefined.
1387
1388     print "Exists\n"    if exists $array{$key};
1389     print "Defined\n"   if defined $array{$key};
1390     print "True\n"      if $array{$key};
1391
1392 A hash element can be true only if it's defined, and defined if
1393 it exists, but the reverse doesn't necessarily hold true.
1394
1395 Note that the EXPR can be arbitrarily complicated as long as the final
1396 operation is a hash key lookup:
1397
1398     if (exists $ref->{A}->{B}->{$key})  { }
1399     if (exists $hash{A}{B}{$key})       { }
1400
1401 Although the last element will not spring into existence just because
1402 its existence was tested, intervening ones will.  Thus C<$ref-E<gt>{"A"}>
1403 and C<$ref-E<gt>{"A"}-E<gt>{"B"}> will spring into existence due to the
1404 existence test for a $key element.  This happens anywhere the arrow
1405 operator is used, including even 
1406
1407     undef $ref;
1408     if (exists $ref->{"Some key"})      { }
1409     print $ref;             # prints HASH(0x80d3d5c)
1410
1411 This surprising autovivification in what does not at first--or even
1412 second--glance appear to be an lvalue context may be fixed in a future
1413 release.
1414
1415 See L<perlref/"Pseudo-hashes"> for specifics on how exists() acts when
1416 used on a pseudo-hash.
1417
1418 =item exit EXPR
1419
1420 Evaluates EXPR and exits immediately with that value.    Example:
1421
1422     $ans = <STDIN>;
1423     exit 0 if $ans =~ /^[Xx]/;
1424
1425 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1426 universally recognized values for EXPR are C<0> for success and C<1>
1427 for error; other values are subject to interpretation depending on the
1428 environment in which the Perl program is running.  For example, exiting
1429 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1430 the mailer to return the item undelivered, but that's not true everywhere.
1431
1432 Don't use C<exit> to abort a subroutine if there's any chance that
1433 someone might want to trap whatever error happened.  Use C<die> instead,
1434 which can be trapped by an C<eval>.
1435
1436 The exit() function does not always exit immediately.  It calls any
1437 defined C<END> routines first, but these C<END> routines may not
1438 themselves abort the exit.  Likewise any object destructors that need to
1439 be called are called before the real exit.  If this is a problem, you
1440 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1441 See L<perlmod> for details.
1442
1443 =item exp EXPR
1444
1445 =item exp
1446
1447 Returns I<e> (the natural logarithm base) to the power of EXPR.  
1448 If EXPR is omitted, gives C<exp($_)>.
1449
1450 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1451
1452 Implements the fcntl(2) function.  You'll probably have to say
1453
1454     use Fcntl;
1455
1456 first to get the correct constant definitions.  Argument processing and
1457 value return works just like C<ioctl> below.  
1458 For example:
1459
1460     use Fcntl;
1461     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1462         or die "can't fcntl F_GETFL: $!";
1463
1464 You don't have to check for C<defined> on the return from C<fnctl>.
1465 Like C<ioctl>, it maps a C<0> return from the system call into C<"0
1466 but true"> in Perl.  This string is true in boolean context and C<0>
1467 in numeric context.  It is also exempt from the normal B<-w> warnings
1468 on improper numeric conversions.
1469
1470 Note that C<fcntl> will produce a fatal error if used on a machine that
1471 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1472 manpage to learn what functions are available on your system.
1473
1474 =item fileno FILEHANDLE
1475
1476 Returns the file descriptor for a filehandle, or undefined if the
1477 filehandle is not open.  This is mainly useful for constructing
1478 bitmaps for C<select> and low-level POSIX tty-handling operations.
1479 If FILEHANDLE is an expression, the value is taken as an indirect
1480 filehandle, generally its name.
1481
1482 You can use this to find out whether two handles refer to the 
1483 same underlying descriptor:
1484
1485     if (fileno(THIS) == fileno(THAT)) {
1486         print "THIS and THAT are dups\n";
1487     } 
1488
1489 =item flock FILEHANDLE,OPERATION
1490
1491 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1492 for success, false on failure.  Produces a fatal error if used on a
1493 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1494 C<flock> is Perl's portable file locking interface, although it locks
1495 only entire files, not records.
1496
1497 Two potentially non-obvious but traditional C<flock> semantics are
1498 that it waits indefinitely until the lock is granted, and that its locks
1499 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1500 fewer guarantees.  This means that files locked with C<flock> may be
1501 modified by programs that do not also use C<flock>.  See L<perlport>,
1502 your port's specific documentation, or your system-specific local manpages
1503 for details.  It's best to assume traditional behavior if you're writing
1504 portable programs.  (But if you're not, you should as always feel perfectly
1505 free to write for your own system's idiosyncrasies (sometimes called
1506 "features").  Slavish adherence to portability concerns shouldn't get
1507 in the way of your getting your job done.)
1508
1509 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1510 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1511 you can use the symbolic names if import them from the Fcntl module,
1512 either individually, or as a group using the ':flock' tag.  LOCK_SH
1513 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1514 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1515 LOCK_EX then C<flock> will return immediately rather than blocking
1516 waiting for the lock (check the return status to see if you got it).
1517
1518 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1519 before locking or unlocking it.
1520
1521 Note that the emulation built with lockf(3) doesn't provide shared
1522 locks, and it requires that FILEHANDLE be open with write intent.  These
1523 are the semantics that lockf(3) implements.  Most if not all systems
1524 implement lockf(3) in terms of fcntl(2) locking, though, so the
1525 differing semantics shouldn't bite too many people.
1526
1527 Note also that some versions of C<flock> cannot lock things over the
1528 network; you would need to use the more system-specific C<fcntl> for
1529 that.  If you like you can force Perl to ignore your system's flock(2)
1530 function, and so provide its own fcntl(2)-based emulation, by passing
1531 the switch C<-Ud_flock> to the F<Configure> program when you configure
1532 perl.
1533
1534 Here's a mailbox appender for BSD systems.
1535
1536     use Fcntl ':flock'; # import LOCK_* constants
1537
1538     sub lock {
1539         flock(MBOX,LOCK_EX);
1540         # and, in case someone appended
1541         # while we were waiting...
1542         seek(MBOX, 0, 2);
1543     }
1544
1545     sub unlock {
1546         flock(MBOX,LOCK_UN);
1547     }
1548
1549     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1550             or die "Can't open mailbox: $!";
1551
1552     lock();
1553     print MBOX $msg,"\n\n";
1554     unlock();
1555
1556 On systems that support a real flock(), locks are inherited across fork()
1557 calls, whereas those that must resort to the more capricious fcntl()
1558 function lose the locks, making it harder to write servers.
1559
1560 See also L<DB_File> for other flock() examples.
1561
1562 =item fork
1563
1564 Does a fork(2) system call to create a new process running the
1565 same program at the same point.  It returns the child pid to the
1566 parent process, C<0> to the child process, or C<undef> if the fork is
1567 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1568 are shared, while everything else is copied.  On most systems supporting
1569 fork(), great care has gone into making it extremely efficient (for
1570 example, using copy-on-write technology on data pages), making it the
1571 dominant paradigm for multitasking over the last few decades.
1572
1573 All files opened for output are flushed before forking the child process.
1574
1575 If you C<fork> without ever waiting on your children, you will
1576 accumulate zombies.  On some systems, you can avoid this by setting
1577 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1578 forking and reaping moribund children.
1579
1580 Note that if your forked child inherits system file descriptors like
1581 STDIN and STDOUT that are actually connected by a pipe or socket, even
1582 if you exit, then the remote server (such as, say, a CGI script or a
1583 backgrounded job launched from a remote shell) won't think you're done.
1584 You should reopen those to F</dev/null> if it's any issue.
1585
1586 =item format
1587
1588 Declare a picture format for use by the C<write> function.  For
1589 example:
1590
1591     format Something =
1592         Test: @<<<<<<<< @||||| @>>>>>
1593               $str,     $%,    '$' . int($num)
1594     .
1595
1596     $str = "widget";
1597     $num = $cost/$quantity;
1598     $~ = 'Something';
1599     write;
1600
1601 See L<perlform> for many details and examples.
1602
1603 =item formline PICTURE,LIST
1604
1605 This is an internal function used by C<format>s, though you may call it,
1606 too.  It formats (see L<perlform>) a list of values according to the
1607 contents of PICTURE, placing the output into the format output
1608 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1609 Eventually, when a C<write> is done, the contents of
1610 C<$^A> are written to some filehandle, but you could also read C<$^A>
1611 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1612 does one C<formline> per line of form, but the C<formline> function itself
1613 doesn't care how many newlines are embedded in the PICTURE.  This means
1614 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1615 You may therefore need to use multiple formlines to implement a single
1616 record format, just like the format compiler.
1617
1618 Be careful if you put double quotes around the picture, because an C<@>
1619 character may be taken to mean the beginning of an array name.
1620 C<formline> always returns true.  See L<perlform> for other examples.
1621
1622 =item getc FILEHANDLE
1623
1624 =item getc
1625
1626 Returns the next character from the input file attached to FILEHANDLE,
1627 or the undefined value at end of file, or if there was an error.
1628 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1629 efficient.  However, it cannot be used by itself to fetch single
1630 characters without waiting for the user to hit enter.  For that, try
1631 something more like:
1632
1633     if ($BSD_STYLE) {
1634         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1635     }
1636     else {
1637         system "stty", '-icanon', 'eol', "\001";
1638     }
1639
1640     $key = getc(STDIN);
1641
1642     if ($BSD_STYLE) {
1643         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1644     }
1645     else {
1646         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1647     }
1648     print "\n";
1649
1650 Determination of whether $BSD_STYLE should be set
1651 is left as an exercise to the reader.
1652
1653 The C<POSIX::getattr> function can do this more portably on
1654 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1655 module from your nearest CPAN site; details on CPAN can be found on
1656 L<perlmodlib/CPAN>.
1657
1658 =item getlogin
1659
1660 Implements the C library function of the same name, which on most
1661 systems returns the current login from F</etc/utmp>, if any.  If null,
1662 use C<getpwuid>.
1663
1664     $login = getlogin || getpwuid($<) || "Kilroy";
1665
1666 Do not consider C<getlogin> for authentication: it is not as
1667 secure as C<getpwuid>.
1668
1669 =item getpeername SOCKET
1670
1671 Returns the packed sockaddr address of other end of the SOCKET connection.
1672
1673     use Socket;
1674     $hersockaddr    = getpeername(SOCK);
1675     ($port, $iaddr) = sockaddr_in($hersockaddr);
1676     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1677     $herstraddr     = inet_ntoa($iaddr);
1678
1679 =item getpgrp PID
1680
1681 Returns the current process group for the specified PID.  Use
1682 a PID of C<0> to get the current process group for the
1683 current process.  Will raise an exception if used on a machine that
1684 doesn't implement getpgrp(2).  If PID is omitted, returns process
1685 group of current process.  Note that the POSIX version of C<getpgrp>
1686 does not accept a PID argument, so only C<PID==0> is truly portable.
1687
1688 =item getppid
1689
1690 Returns the process id of the parent process.
1691
1692 =item getpriority WHICH,WHO
1693
1694 Returns the current priority for a process, a process group, or a user.
1695 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1696 machine that doesn't implement getpriority(2).
1697
1698 =item getpwnam NAME
1699
1700 =item getgrnam NAME
1701
1702 =item gethostbyname NAME
1703
1704 =item getnetbyname NAME
1705
1706 =item getprotobyname NAME
1707
1708 =item getpwuid UID
1709
1710 =item getgrgid GID
1711
1712 =item getservbyname NAME,PROTO
1713
1714 =item gethostbyaddr ADDR,ADDRTYPE
1715
1716 =item getnetbyaddr ADDR,ADDRTYPE
1717
1718 =item getprotobynumber NUMBER
1719
1720 =item getservbyport PORT,PROTO
1721
1722 =item getpwent
1723
1724 =item getgrent
1725
1726 =item gethostent
1727
1728 =item getnetent
1729
1730 =item getprotoent
1731
1732 =item getservent
1733
1734 =item setpwent
1735
1736 =item setgrent
1737
1738 =item sethostent STAYOPEN
1739
1740 =item setnetent STAYOPEN
1741
1742 =item setprotoent STAYOPEN
1743
1744 =item setservent STAYOPEN
1745
1746 =item endpwent
1747
1748 =item endgrent
1749
1750 =item endhostent
1751
1752 =item endnetent
1753
1754 =item endprotoent
1755
1756 =item endservent
1757
1758 These routines perform the same functions as their counterparts in the
1759 system library.  In list context, the return values from the
1760 various get routines are as follows:
1761
1762     ($name,$passwd,$uid,$gid,
1763        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1764     ($name,$passwd,$gid,$members) = getgr*
1765     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1766     ($name,$aliases,$addrtype,$net) = getnet*
1767     ($name,$aliases,$proto) = getproto*
1768     ($name,$aliases,$port,$proto) = getserv*
1769
1770 (If the entry doesn't exist you get a null list.)
1771
1772 In scalar context, you get the name, unless the function was a
1773 lookup by name, in which case you get the other thing, whatever it is.
1774 (If the entry doesn't exist you get the undefined value.)  For example:
1775
1776     $uid   = getpwnam($name);
1777     $name  = getpwuid($num);
1778     $name  = getpwent();
1779     $gid   = getgrnam($name);
1780     $name  = getgrgid($num;
1781     $name  = getgrent();
1782     #etc.
1783
1784 In I<getpw*()> the fields $quota, $comment, and $expire are
1785 special cases in the sense that in many systems they are unsupported.
1786 If the $quota is unsupported, it is an empty scalar.  If it is
1787 supported, it usually encodes the disk quota.  If the $comment
1788 field is unsupported, it is an empty scalar.  If it is supported it
1789 usually encodes some administrative comment about the user.  In some
1790 systems the $quota field may be $change or $age, fields that have
1791 to do with password aging.  In some systems the $comment field may
1792 be $class.  The $expire field, if present, encodes the expiration
1793 period of the account or the password.  For the availability and the
1794 exact meaning of these fields in your system, please consult your
1795 getpwnam(3) documentation and your F<pwd.h> file.  You can also find
1796 out from within Perl what your $quota and $comment fields mean
1797 and whether you have the $expire field by using the C<Config> module
1798 and the values C<d_pwquota>, C<d_pwage>, C<d_pwchange>, C<d_pwcomment>,
1799 and C<d_pwexpire>.  Shadow password files are only supported if your
1800 vendor has implemented them in the intuitive fashion that calling the
1801 regular C library routines gets the shadow versions if you're running
1802 under privilege.  Those that incorrectly implement a separate library
1803 call are not supported.
1804
1805 The $members value returned by I<getgr*()> is a space separated list of
1806 the login names of the members of the group.
1807
1808 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1809 C, it will be returned to you via C<$?> if the function call fails.  The
1810 C<@addrs> value returned by a successful call is a list of the raw
1811 addresses returned by the corresponding system library call.  In the
1812 Internet domain, each address is four bytes long and you can unpack it
1813 by saying something like:
1814
1815     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1816
1817 The Socket library makes this slightly easier:
1818
1819     use Socket;
1820     $iaddr = inet_aton("127.1"); # or whatever address
1821     $name  = gethostbyaddr($iaddr, AF_INET);
1822
1823     # or going the other way
1824     $straddr = inet_ntoa($iaddr);
1825
1826 If you get tired of remembering which element of the return list
1827 contains which return value, by-name interfaces are provided
1828 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1829 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1830 and C<User::grent>.  These override the normal built-ins, supplying
1831 versions that return objects with the appropriate names
1832 for each field.  For example:
1833
1834    use File::stat;
1835    use User::pwent;
1836    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1837
1838 Even though it looks like they're the same method calls (uid), 
1839 they aren't, because a C<File::stat> object is different from 
1840 a C<User::pwent> object.
1841
1842 =item getsockname SOCKET
1843
1844 Returns the packed sockaddr address of this end of the SOCKET connection,
1845 in case you don't know the address because you have several different
1846 IPs that the connection might have come in on.
1847
1848     use Socket;
1849     $mysockaddr = getsockname(SOCK);
1850     ($port, $myaddr) = sockaddr_in($mysockaddr);
1851     printf "Connect to %s [%s]\n", 
1852        scalar gethostbyaddr($myaddr, AF_INET),
1853        inet_ntoa($myaddr);
1854
1855 =item getsockopt SOCKET,LEVEL,OPTNAME
1856
1857 Returns the socket option requested, or undef if there is an error.
1858
1859 =item glob EXPR
1860
1861 =item glob
1862
1863 Returns the value of EXPR with filename expansions such as the
1864 standard Unix shell F</bin/csh> would do.  This is the internal function
1865 implementing the C<E<lt>*.cE<gt>> operator, but you can use it directly.
1866 If EXPR is omitted, C<$_> is used.  The C<E<lt>*.cE<gt>> operator is
1867 discussed in more detail in L<perlop/"I/O Operators">.
1868
1869 =item gmtime EXPR
1870
1871 Converts a time as returned by the time function to a 9-element list
1872 with the time localized for the standard Greenwich time zone.
1873 Typically used as follows:
1874
1875     #  0    1    2     3     4    5     6     7     8
1876     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1877                                             gmtime(time);
1878
1879 All list elements are numeric, and come straight out of a struct tm.
1880 In particular this means that $mon has the range C<0..11> and $wday
1881 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
1882 number of years since 1900, that is, $year is C<123> in year 2023,
1883 I<not> simply the last two digits of the year.  If you assume it is,
1884 then you create non-Y2K-compliant programs--and you wouldn't want to do
1885 that, would you?
1886
1887 If EXPR is omitted, does C<gmtime(time())>.
1888
1889 In scalar context, returns the ctime(3) value:
1890
1891     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1892
1893 Also see the C<timegm> function provided by the C<Time::Local> module,
1894 and the strftime(3) function available via the POSIX module.
1895
1896 This scalar value is B<not> locale dependent (see L<perllocale>), but
1897 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
1898 strftime(3) and mktime(3) functions available via the POSIX module.  To
1899 get somewhat similar but locale dependent date strings, set up your
1900 locale environment variables appropriately (please see L<perllocale>)
1901 and try for example:
1902
1903     use POSIX qw(strftime);
1904     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1905
1906 Note that the C<%a> and C<%b> escapes, which represent the short forms
1907 of the day of the week and the month of the year, may not necessarily
1908 be three characters wide in all locales.
1909
1910 =item goto LABEL
1911
1912 =item goto EXPR
1913
1914 =item goto &NAME
1915
1916 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1917 execution there.  It may not be used to go into any construct that
1918 requires initialization, such as a subroutine or a C<foreach> loop.  It
1919 also can't be used to go into a construct that is optimized away,
1920 or to get out of a block or subroutine given to C<sort>.
1921 It can be used to go almost anywhere else within the dynamic scope,
1922 including out of subroutines, but it's usually better to use some other
1923 construct such as C<last> or C<die>.  The author of Perl has never felt the
1924 need to use this form of C<goto> (in Perl, that is--C is another matter).
1925
1926 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1927 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1928 necessarily recommended if you're optimizing for maintainability:
1929
1930     goto ("FOO", "BAR", "GLARCH")[$i];
1931
1932 The C<goto-&NAME> form is highly magical, and substitutes a call to the
1933 named subroutine for the currently running subroutine.  This is used by
1934 C<AUTOLOAD> subroutines that wish to load another subroutine and then
1935 pretend that the other subroutine had been called in the first place
1936 (except that any modifications to C<@_> in the current subroutine are
1937 propagated to the other subroutine.)  After the C<goto>, not even C<caller>
1938 will be able to tell that this routine was called first.
1939
1940 =item grep BLOCK LIST
1941
1942 =item grep EXPR,LIST
1943
1944 This is similar in spirit to, but not the same as, grep(1) and its
1945 relatives.  In particular, it is not limited to using regular expressions.
1946
1947 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1948 C<$_> to each element) and returns the list value consisting of those
1949 elements for which the expression evaluated to true.  In scalar
1950 context, returns the number of times the expression was true.
1951
1952     @foo = grep(!/^#/, @bar);    # weed out comments
1953
1954 or equivalently,
1955
1956     @foo = grep {!/^#/} @bar;    # weed out comments
1957
1958 Note that, because C<$_> is a reference into the list value, it can
1959 be used to modify the elements of the array.  While this is useful and
1960 supported, it can cause bizarre results if the LIST is not a named array.
1961 Similarly, grep returns aliases into the original list, much as a for
1962 loop's index variable aliases the list elements.  That is, modifying an
1963 element of a list returned by grep (for example, in a C<foreach>, C<map>
1964 or another C<grep>) actually modifies the element in the original list.
1965 This is usually something to be avoided when writing clear code.
1966
1967 See also L</map> for a list composed of the results of the BLOCK or EXPR.
1968
1969 =item hex EXPR
1970
1971 =item hex
1972
1973 Interprets EXPR as a hex string and returns the corresponding value.
1974 (To convert strings that might start with either 0, 0x, or 0b, see
1975 L</oct>.)  If EXPR is omitted, uses C<$_>.
1976
1977     print hex '0xAf'; # prints '175'
1978     print hex 'aF';   # same
1979
1980 Hex strings may only represent integers.  Strings that would cause
1981 integer overflow trigger a mandatory error message.
1982
1983 =item import
1984
1985 There is no builtin C<import> function.  It is just an ordinary
1986 method (subroutine) defined (or inherited) by modules that wish to export
1987 names to another module.  The C<use> function calls the C<import> method
1988 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1989
1990 =item index STR,SUBSTR,POSITION
1991
1992 =item index STR,SUBSTR
1993
1994 The index function searches for one string within another, but without
1995 the wildcard-like behavior of a full regular-expression pattern match.
1996 It returns the position of the first occurrence of SUBSTR in STR at
1997 or after POSITION.  If POSITION is omitted, starts searching from the
1998 beginning of the string.  The return value is based at C<0> (or whatever
1999 you've set the C<$[> variable to--but don't do that).  If the substring
2000 is not found, returns one less than the base, ordinarily C<-1>.
2001
2002 =item int EXPR
2003
2004 =item int
2005
2006 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2007 You should not use this function for rounding: one because it truncates
2008 towards C<0>, and two because machine representations of floating point
2009 numbers can sometimes produce counterintuitive results.  For example,
2010 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2011 because it's really more like -268.99999999999994315658 instead.  Usually,
2012 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2013 functions will serve you better than will int().
2014
2015 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2016
2017 Implements the ioctl(2) function.  You'll probably first have to say
2018
2019     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2020
2021 to get the correct function definitions.  If F<ioctl.ph> doesn't
2022 exist or doesn't have the correct definitions you'll have to roll your
2023 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
2024 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2025 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2026 written depending on the FUNCTION--a pointer to the string value of SCALAR
2027 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2028 has no string value but does have a numeric value, that value will be
2029 passed rather than a pointer to the string value.  To guarantee this to be
2030 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2031 functions may be needed to manipulate the values of structures used by
2032 C<ioctl>.  
2033
2034 The return value of C<ioctl> (and C<fcntl>) is as follows:
2035
2036         if OS returns:          then Perl returns:
2037             -1                    undefined value
2038              0                  string "0 but true"
2039         anything else               that number
2040
2041 Thus Perl returns true on success and false on failure, yet you can
2042 still easily determine the actual value returned by the operating
2043 system:
2044
2045     $retval = ioctl(...) || -1;
2046     printf "System returned %d\n", $retval;
2047
2048 The special string "C<0> but true" is exempt from B<-w> complaints
2049 about improper numeric conversions.
2050
2051 Here's an example of setting a filehandle named C<REMOTE> to be
2052 non-blocking at the system level.  You'll have to negotiate C<$|>
2053 on your own, though.
2054
2055     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2056
2057     $flags = fcntl(REMOTE, F_GETFL, 0)
2058                 or die "Can't get flags for the socket: $!\n";
2059
2060     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2061                 or die "Can't set flags for the socket: $!\n";
2062
2063 =item join EXPR,LIST
2064
2065 Joins the separate strings of LIST into a single string with fields
2066 separated by the value of EXPR, and returns that new string.  Example:
2067
2068     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2069
2070 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2071 first argument.  Compare L</split>.
2072
2073 =item keys HASH
2074
2075 Returns a list consisting of all the keys of the named hash.  (In
2076 scalar context, returns the number of keys.)  The keys are returned in
2077 an apparently random order.  The actual random order is subject to
2078 change in future versions of perl, but it is guaranteed to be the same
2079 order as either the C<values> or C<each> function produces (given
2080 that the hash has not been modified).  As a side effect, it resets
2081 HASH's iterator.
2082
2083 Here is yet another way to print your environment:
2084
2085     @keys = keys %ENV;
2086     @values = values %ENV;
2087     while (@keys) { 
2088         print pop(@keys), '=', pop(@values), "\n";
2089     }
2090
2091 or how about sorted by key:
2092
2093     foreach $key (sort(keys %ENV)) {
2094         print $key, '=', $ENV{$key}, "\n";
2095     }
2096
2097 To sort a hash by value, you'll need to use a C<sort> function.
2098 Here's a descending numeric sort of a hash by its values:
2099
2100     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2101         printf "%4d %s\n", $hash{$key}, $key;
2102     }
2103
2104 As an lvalue C<keys> allows you to increase the number of hash buckets
2105 allocated for the given hash.  This can gain you a measure of efficiency if
2106 you know the hash is going to get big.  (This is similar to pre-extending
2107 an array by assigning a larger number to $#array.)  If you say
2108
2109     keys %hash = 200;
2110
2111 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2112 in fact, since it rounds up to the next power of two.  These
2113 buckets will be retained even if you do C<%hash = ()>, use C<undef
2114 %hash> if you want to free the storage while C<%hash> is still in scope.
2115 You can't shrink the number of buckets allocated for the hash using
2116 C<keys> in this way (but you needn't worry about doing this by accident,
2117 as trying has no effect).
2118
2119 See also C<each>, C<values> and C<sort>.
2120
2121 =item kill SIGNAL, LIST
2122
2123 Sends a signal to a list of processes.  Returns the number of
2124 processes successfully signaled (which is not necessarily the
2125 same as the number actually killed).
2126
2127     $cnt = kill 1, $child1, $child2;
2128     kill 9, @goners;
2129
2130 If SIGNAL is zero, no signal is sent to the process.  This is a
2131 useful way to check that the process is alive and hasn't changed
2132 its UID.  See L<perlport> for notes on the portability of this
2133 construct.
2134
2135 Unlike in the shell, if SIGNAL is negative, it kills
2136 process groups instead of processes.  (On System V, a negative I<PROCESS>
2137 number will also kill process groups, but that's not portable.)  That
2138 means you usually want to use positive not negative signals.  You may also
2139 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2140
2141 =item last LABEL
2142
2143 =item last
2144
2145 The C<last> command is like the C<break> statement in C (as used in
2146 loops); it immediately exits the loop in question.  If the LABEL is
2147 omitted, the command refers to the innermost enclosing loop.  The
2148 C<continue> block, if any, is not executed:
2149
2150     LINE: while (<STDIN>) {
2151         last LINE if /^$/;      # exit when done with header
2152         #...
2153     }
2154
2155 C<last> cannot be used to exit a block which returns a value such as
2156 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2157 a grep() or map() operation.
2158
2159 Note that a block by itself is semantically identical to a loop
2160 that executes once.  Thus C<last> can be used to effect an early
2161 exit out of such a block.
2162
2163 See also L</continue> for an illustration of how C<last>, C<next>, and
2164 C<redo> work.
2165
2166 =item lc EXPR
2167
2168 =item lc
2169
2170 Returns an lowercased version of EXPR.  This is the internal function
2171 implementing the C<\L> escape in double-quoted strings.
2172 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2173 and L<utf8>.
2174
2175 If EXPR is omitted, uses C<$_>.
2176
2177 =item lcfirst EXPR
2178
2179 =item lcfirst
2180
2181 Returns the value of EXPR with the first character lowercased.  This is
2182 the internal function implementing the C<\l> escape in double-quoted strings.
2183 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
2184
2185 If EXPR is omitted, uses C<$_>.
2186
2187 =item length EXPR
2188
2189 =item length
2190
2191 Returns the length in characters of the value of EXPR.  If EXPR is
2192 omitted, returns length of C<$_>.  Note that this cannot be used on 
2193 an entire array or hash to find out how many elements these have.
2194 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2195
2196 =item link OLDFILE,NEWFILE
2197
2198 Creates a new filename linked to the old filename.  Returns true for
2199 success, false otherwise. 
2200
2201 =item listen SOCKET,QUEUESIZE
2202
2203 Does the same thing that the listen system call does.  Returns true if
2204 it succeeded, false otherwise.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
2205
2206 =item local EXPR
2207
2208 You really probably want to be using C<my> instead, because C<local> isn't
2209 what most people think of as "local".  See L<perlsub/"Private Variables
2210 via my()"> for details.
2211
2212 A local modifies the listed variables to be local to the enclosing
2213 block, file, or eval.  If more than one value is listed, the list must
2214 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2215 for details, including issues with tied arrays and hashes.
2216
2217 =item localtime EXPR
2218
2219 Converts a time as returned by the time function to a 9-element list
2220 with the time analyzed for the local time zone.  Typically used as
2221 follows:
2222
2223     #  0    1    2     3     4    5     6     7     8
2224     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2225                                                 localtime(time);
2226
2227 All list elements are numeric, and come straight out of a struct tm.
2228 In particular this means that $mon has the range C<0..11> and $wday
2229 has the range C<0..6> with sunday as day C<0>.  Also, $year is the
2230 number of years since 1900, that is, $year is C<123> in year 2023,
2231 and I<not> simply the last two digits of the year.  If you assume it is,
2232 then you create non-Y2K-compliant programs--and you wouldn't want to do
2233 that, would you?
2234
2235 If EXPR is omitted, uses the current time (C<localtime(time)>).
2236
2237 In scalar context, returns the ctime(3) value:
2238
2239     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2240
2241 This scalar value is B<not> locale dependent, see L<perllocale>, but
2242 instead a Perl builtin.  Also see the C<Time::Local> module
2243 (to convert the second, minutes, hours, ... back to seconds since the
2244 stroke of midnight the 1st of January 1970, the value returned by
2245 time()), and the strftime(3) and mktime(3) function available via the
2246 POSIX module.  To get somewhat similar but locale dependent date
2247 strings, set up your locale environment variables appropriately
2248 (please see L<perllocale>) and try for example:
2249
2250     use POSIX qw(strftime);
2251     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2252
2253 Note that the C<%a> and C<%b>, the short forms of the day of the week
2254 and the month of the year, may not necessarily be three characters wide.
2255
2256 =item lock
2257
2258     lock I<THING>
2259
2260 This function places an advisory lock on a variable, subroutine,
2261 or referenced object contained in I<THING> until the lock goes out
2262 of scope.  This is a built-in function only if your version of Perl
2263 was built with threading enabled, and if you've said C<use Threads>.
2264 Otherwise a user-defined function by this name will be called.  See
2265 L<Thread>.
2266
2267 =item log EXPR
2268
2269 =item log
2270
2271 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2272 returns log of C<$_>.  To get the log of another base, use basic algebra:
2273 The base-N log of a number is equal to the natural log of that number
2274 divided by the natural log of N.  For example:
2275
2276     sub log10 {
2277         my $n = shift;
2278         return log($n)/log(10);
2279     } 
2280
2281 See also L</exp> for the inverse operation.
2282
2283 =item lstat FILEHANDLE
2284
2285 =item lstat EXPR
2286
2287 =item lstat
2288
2289 Does the same thing as the C<stat> function (including setting the
2290 special C<_> filehandle) but stats a symbolic link instead of the file
2291 the symbolic link points to.  If symbolic links are unimplemented on
2292 your system, a normal C<stat> is done.
2293
2294 If EXPR is omitted, stats C<$_>.
2295
2296 =item m//
2297
2298 The match operator.  See L<perlop>.
2299
2300 =item map BLOCK LIST
2301
2302 =item map EXPR,LIST
2303
2304 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2305 C<$_> to each element) and returns the list value composed of the
2306 results of each such evaluation.  In scalar context, returns the
2307 total number of elements so generated.  Evaluates BLOCK or EXPR in
2308 list context, so each element of LIST may produce zero, one, or
2309 more elements in the returned value.
2310
2311     @chars = map(chr, @nums);
2312
2313 translates a list of numbers to the corresponding characters.  And
2314
2315     %hash = map { getkey($_) => $_ } @array;
2316
2317 is just a funny way to write
2318
2319     %hash = ();
2320     foreach $_ (@array) {
2321         $hash{getkey($_)} = $_;
2322     }
2323
2324 Note that, because C<$_> is a reference into the list value, it can
2325 be used to modify the elements of the array.  While this is useful and
2326 supported, it can cause bizarre results if the LIST is not a named array.
2327 Using a regular C<foreach> loop for this purpose would be clearer in
2328 most cases.  See also L</grep> for an array composed of those items of
2329 the original list for which the BLOCK or EXPR evaluates to true.
2330
2331 =item mkdir FILENAME,MASK
2332
2333 Creates the directory specified by FILENAME, with permissions
2334 specified by MASK (as modified by C<umask>).  If it succeeds it
2335 returns true, otherwise it returns false and sets C<$!> (errno).
2336
2337 In general, it is better to create directories with permissive MASK,
2338 and let the user modify that with their C<umask>, than it is to supply
2339 a restrictive MASK and give the user no way to be more permissive.
2340 The exceptions to this rule are when the file or directory should be
2341 kept private (mail files, for instance).  The perlfunc(1) entry on
2342 C<umask> discusses the choice of MASK in more detail.
2343
2344 =item msgctl ID,CMD,ARG
2345
2346 Calls the System V IPC function msgctl(2).  You'll probably have to say
2347
2348     use IPC::SysV;
2349
2350 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2351 then ARG must be a variable which will hold the returned C<msqid_ds>
2352 structure.  Returns like C<ioctl>: the undefined value for error, C<"0 but
2353 true"> for zero, or the actual return value otherwise.  See also
2354 C<IPC::SysV> and C<IPC::Semaphore> documentation.
2355
2356 =item msgget KEY,FLAGS
2357
2358 Calls the System V IPC function msgget(2).  Returns the message queue
2359 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2360 and C<IPC::Msg> documentation.
2361
2362 =item msgsnd ID,MSG,FLAGS
2363
2364 Calls the System V IPC function msgsnd to send the message MSG to the
2365 message queue ID.  MSG must begin with the long integer message type,
2366 which may be created with C<pack("l", $type)>.  Returns true if
2367 successful, or false if there is an error.  See also C<IPC::SysV>
2368 and C<IPC::SysV::Msg> documentation.
2369
2370 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2371
2372 Calls the System V IPC function msgrcv to receive a message from
2373 message queue ID into variable VAR with a maximum message size of
2374 SIZE.  Note that if a message is received, the message type will be
2375 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2376 size of the message type.  Returns true if successful, or false if
2377 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2378
2379 =item my EXPR
2380
2381 =item my EXPR : ATTRIBUTES
2382
2383 A C<my> declares the listed variables to be local (lexically) to the
2384 enclosing block, file, or C<eval>.  If
2385 more than one value is listed, the list must be placed in parentheses.  See
2386 L<perlsub/"Private Variables via my()"> for details.
2387
2388 =item next LABEL
2389
2390 =item next
2391
2392 The C<next> command is like the C<continue> statement in C; it starts
2393 the next iteration of the loop:
2394
2395     LINE: while (<STDIN>) {
2396         next LINE if /^#/;      # discard comments
2397         #...
2398     }
2399
2400 Note that if there were a C<continue> block on the above, it would get
2401 executed even on discarded lines.  If the LABEL is omitted, the command
2402 refers to the innermost enclosing loop.
2403
2404 C<next> cannot be used to exit a block which returns a value such as
2405 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2406 a grep() or map() operation.
2407
2408 Note that a block by itself is semantically identical to a loop
2409 that executes once.  Thus C<next> will exit such a block early.
2410
2411 See also L</continue> for an illustration of how C<last>, C<next>, and
2412 C<redo> work.
2413
2414 =item no Module LIST
2415
2416 See the L</use> function, which C<no> is the opposite of.
2417
2418 =item oct EXPR
2419
2420 =item oct
2421
2422 Interprets EXPR as an octal string and returns the corresponding
2423 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2424 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2425 binary string.)  The following will handle decimal, binary, octal, and
2426 hex in the standard Perl or C notation:
2427
2428     $val = oct($val) if $val =~ /^0/;
2429
2430 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2431 in octal), use sprintf() or printf():
2432
2433     $perms = (stat("filename"))[2] & 07777;
2434     $oct_perms = sprintf "%lo", $perms;
2435
2436 The oct() function is commonly used when a string such as C<644> needs
2437 to be converted into a file mode, for example. (Although perl will
2438 automatically convert strings into numbers as needed, this automatic
2439 conversion assumes base 10.)
2440
2441 =item open FILEHANDLE,MODE,EXPR
2442
2443 =item open FILEHANDLE,EXPR
2444
2445 =item open FILEHANDLE
2446
2447 Opens the file whose filename is given by EXPR, and associates it with
2448 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2449 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2450 variable of the same name as the FILEHANDLE contains the filename.
2451 (Note that lexical variables--those declared with C<my>--will not work
2452 for this purpose; so if you're using C<my>, specify EXPR in your call
2453 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2454 files.
2455
2456 If MODE is C<'E<lt>'> or nothing, the file is opened for input.
2457 If MODE is C<'E<gt>'>, the file is truncated and opened for
2458 output, being created if necessary.  If MODE is C<'E<gt>E<gt>'>,
2459 the file is opened for appending, again being created if necessary. 
2460 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2461 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2462 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2463 file first.  You can't usually use either read-write mode for updating
2464 textfiles, since they have variable length records.  See the B<-i>
2465 switch in L<perlrun> for a better approach.  The file is created with
2466 permissions of C<0666> modified by the process' C<umask> value.
2467
2468 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>, C<'w'>,
2469 C<'w+'>, C<'a'>, and C<'a+'>.
2470
2471 In the 2-arguments (and 1-argument) form of the call the mode and
2472 filename should be concatenated (in this order), possibly separated by
2473 spaces.  It is possible to omit the mode if the mode is C<'E<lt>'>.
2474
2475 If the filename begins with C<'|'>, the filename is interpreted as a
2476 command to which output is to be piped, and if the filename ends with a
2477 C<'|'>, the filename is interpreted as a command which pipes output to
2478 us.  See L<perlipc/"Using open() for IPC">
2479 for more examples of this.  (You are not allowed to C<open> to a command
2480 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2481 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2482
2483 If MODE is C<'|-'>, the filename is interpreted as a
2484 command to which output is to be piped, and if MODE is
2485 C<'-|'>, the filename is interpreted as a command which pipes output to
2486 us.  In the 2-arguments (and 1-argument) form one should replace dash
2487 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2488 for more examples of this.  (You are not allowed to C<open> to a command
2489 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2490 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2491
2492 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2493 and opening C<'E<gt>-'> opens STDOUT.  
2494
2495 Open returns
2496 nonzero upon success, the undefined value otherwise.  If the C<open>
2497 involved a pipe, the return value happens to be the pid of the
2498 subprocess.
2499
2500 If you're unfortunate enough to be running Perl on a system that
2501 distinguishes between text files and binary files (modern operating
2502 systems don't care), then you should check out L</binmode> for tips for
2503 dealing with this.  The key distinction between systems that need C<binmode>
2504 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2505 Plan9, which delimit lines with a single character, and which encode that
2506 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2507
2508 When opening a file, it's usually a bad idea to continue normal execution
2509 if the request failed, so C<open> is frequently used in connection with
2510 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2511 where you want to make a nicely formatted error message (but there are
2512 modules that can help with that problem)) you should always check
2513 the return value from opening a file.  The infrequent exception is when
2514 working with an unopened filehandle is actually what you want to do.
2515
2516 Examples:
2517
2518     $ARTICLE = 100;
2519     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2520     while (<ARTICLE>) {...
2521
2522     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2523     # if the open fails, output is discarded
2524
2525     open(DBASE, '+<', 'dbase.mine')             # open for update
2526         or die "Can't open 'dbase.mine' for update: $!";
2527
2528     open(DBASE, '+<dbase.mine')                 # ditto
2529         or die "Can't open 'dbase.mine' for update: $!";
2530
2531     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2532         or die "Can't start caesar: $!";
2533
2534     open(ARTICLE, "caesar <$article |")         # ditto
2535         or die "Can't start caesar: $!";
2536
2537     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2538         or die "Can't start sort: $!";
2539
2540     # process argument list of files along with any includes
2541
2542     foreach $file (@ARGV) {
2543         process($file, 'fh00');
2544     }
2545
2546     sub process {
2547         my($filename, $input) = @_;
2548         $input++;               # this is a string increment
2549         unless (open($input, $filename)) {
2550             print STDERR "Can't open $filename: $!\n";
2551             return;
2552         }
2553
2554         local $_;
2555         while (<$input>) {              # note use of indirection
2556             if (/^#include "(.*)"/) {
2557                 process($1, $input);
2558                 next;
2559             }
2560             #...                # whatever
2561         }
2562     }
2563
2564 You may also, in the Bourne shell tradition, specify an EXPR beginning
2565 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2566 name of a filehandle (or file descriptor, if numeric) to be
2567 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>,
2568 C<E<lt>>, C<+E<gt>>, C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2569 mode you specify should match the mode of the original filehandle.
2570 (Duping a filehandle does not take into account any existing contents of
2571 stdio buffers.)  Duping file handles is not yet supported for 3-argument
2572 open().
2573
2574 Here is a script that saves, redirects, and restores STDOUT and
2575 STDERR:
2576
2577     #!/usr/bin/perl
2578     open(OLDOUT, ">&STDOUT");
2579     open(OLDERR, ">&STDERR");
2580
2581     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2582     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2583
2584     select(STDERR); $| = 1;     # make unbuffered
2585     select(STDOUT); $| = 1;     # make unbuffered
2586
2587     print STDOUT "stdout 1\n";  # this works for
2588     print STDERR "stderr 1\n";  # subprocesses too
2589
2590     close(STDOUT);
2591     close(STDERR);
2592
2593     open(STDOUT, ">&OLDOUT");
2594     open(STDERR, ">&OLDERR");
2595
2596     print STDOUT "stdout 2\n";
2597     print STDERR "stderr 2\n";
2598
2599 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2600 equivalent of C's C<fdopen> of that file descriptor; this is more
2601 parsimonious of file descriptors.  For example:
2602
2603     open(FILEHANDLE, "<&=$fd")
2604
2605 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2606 with 2-arguments (or 1-argument) form of open(), then
2607 there is an implicit fork done, and the return value of open is the pid
2608 of the child within the parent process, and C<0> within the child
2609 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2610 The filehandle behaves normally for the parent, but i/o to that
2611 filehandle is piped from/to the STDOUT/STDIN of the child process.
2612 In the child process the filehandle isn't opened--i/o happens from/to
2613 the new STDOUT or STDIN.  Typically this is used like the normal
2614 piped open when you want to exercise more control over just how the
2615 pipe command gets executed, such as when you are running setuid, and
2616 don't want to have to scan shell commands for metacharacters.
2617 The following triples are more or less equivalent:
2618
2619     open(FOO, "|tr '[a-z]' '[A-Z]'");
2620     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2621     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2622
2623     open(FOO, "cat -n '$file'|");
2624     open(FOO, '-|', "cat -n '$file'");
2625     open(FOO, '-|') || exec 'cat', '-n', $file;
2626
2627 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2628
2629 NOTE: On any operation that may do a fork, all files opened for output
2630 are flushed before the fork is attempted.  On systems that support a
2631 close-on-exec flag on files, the flag will be set for the newly opened
2632 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2633
2634 Closing any piped filehandle causes the parent process to wait for the
2635 child to finish, and returns the status value in C<$?>.
2636
2637 The filename passed to 2-argument (or 1-argument) form of open()
2638 will have leading and trailing
2639 whitespace deleted, and the normal redirection characters
2640 honored.  This property, known as "magic open", 
2641 can often be used to good effect.  A user could specify a filename of
2642 F<"rsh cat file |">, or you could change certain filenames as needed:
2643
2644     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2645     open(FH, $filename) or die "Can't open $filename: $!";
2646
2647 Use 3-argument form to open a file with arbitrary weird characters in it,
2648
2649     open(FOO, '<', $file);
2650
2651 otherwise it's necessary to protect any leading and trailing whitespace:
2652
2653     $file =~ s#^(\s)#./$1#;
2654     open(FOO, "< $file\0");
2655
2656 (this may not work on some bizzare filesystems).  One should
2657 conscientiously choose between the the I<magic> and 3-arguments form
2658 of open():
2659
2660     open IN, $ARGV[0];
2661
2662 will allow the user to specify an argument of the form C<"rsh cat file |">,
2663 but will not work on a filename which happens to have a trailing space, while
2664
2665     open IN, '<', $ARGV[0];
2666
2667 will have exactly the opposite restrictions.
2668
2669 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2670 should use the C<sysopen> function, which involves no such magic (but
2671 may use subtly different filemodes than Perl open(), which is mapped
2672 to C fopen()).  This is
2673 another way to protect your filenames from interpretation.  For example:
2674
2675     use IO::Handle;
2676     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2677         or die "sysopen $path: $!";
2678     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2679     print HANDLE "stuff $$\n");
2680     seek(HANDLE, 0, 0);
2681     print "File contains: ", <HANDLE>;
2682
2683 Using the constructor from the C<IO::Handle> package (or one of its
2684 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2685 filehandles that have the scope of whatever variables hold references to
2686 them, and automatically close whenever and however you leave that scope:
2687
2688     use IO::File;
2689     #...
2690     sub read_myfile_munged {
2691         my $ALL = shift;
2692         my $handle = new IO::File;
2693         open($handle, "myfile") or die "myfile: $!";
2694         $first = <$handle>
2695             or return ();     # Automatically closed here.
2696         mung $first or die "mung failed";       # Or here.
2697         return $first, <$handle> if $ALL;       # Or here.
2698         $first;                                 # Or here.
2699     }
2700
2701 See L</seek> for some details about mixing reading and writing.
2702
2703 =item opendir DIRHANDLE,EXPR
2704
2705 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2706 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2707 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2708
2709 =item ord EXPR
2710
2711 =item ord
2712
2713 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2714 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2715 See L<utf8> for more about Unicode.
2716
2717 =item our EXPR
2718
2719 An C<our> declares the listed variables to be valid globals within
2720 the enclosing block, file, or C<eval>.  That is, it has the same
2721 scoping rules as a "my" declaration, but does not create a local
2722 variable.  If more than one value is listed, the list must be placed
2723 in parentheses.  The C<our> declaration has no semantic effect unless
2724 "use strict vars" is in effect, in which case it lets you use the
2725 declared global variable without qualifying it with a package name.
2726 (But only within the lexical scope of the C<our> declaration.  In this
2727 it differs from "use vars", which is package scoped.)
2728
2729 =item pack TEMPLATE,LIST
2730
2731 Takes a LIST of values and converts it into a string using the rules
2732 given by the TEMPLATE.  The resulting string is the concatenation of
2733 the converted values.  Typically, each converted value looks
2734 like its machine-level representation.  For example, on 32-bit machines
2735 a converted integer may be represented by a sequence of 4 bytes.
2736
2737 The TEMPLATE is a
2738 sequence of characters that give the order and type of values, as
2739 follows:
2740
2741     a   A string with arbitrary binary data, will be null padded.
2742     A   An ascii string, will be space padded.
2743     Z   A null terminated (asciz) string, will be null padded.
2744
2745     b   A bit string (ascending bit order inside each byte, like vec()).
2746     B   A bit string (descending bit order inside each byte).
2747     h   A hex string (low nybble first).
2748     H   A hex string (high nybble first).
2749
2750     c   A signed char value.
2751     C   An unsigned char value.  Only does bytes.  See U for Unicode.
2752
2753     s   A signed short value.
2754     S   An unsigned short value.
2755           (This 'short' is _exactly_ 16 bits, which may differ from
2756            what a local C compiler calls 'short'.  If you want
2757            native-length shorts, use the '!' suffix.)
2758
2759     i   A signed integer value.
2760     I   An unsigned integer value.
2761           (This 'integer' is _at_least_ 32 bits wide.  Its exact
2762            size depends on what a local C compiler calls 'int',
2763            and may even be larger than the 'long' described in
2764            the next item.)
2765
2766     l   A signed long value.
2767     L   An unsigned long value.
2768           (This 'long' is _exactly_ 32 bits, which may differ from
2769            what a local C compiler calls 'long'.  If you want
2770            native-length longs, use the '!' suffix.)
2771
2772     n   A short in "network" (big-endian) order.
2773     N   A long in "network" (big-endian) order.
2774     v   A short in "VAX" (little-endian) order.
2775     V   A long in "VAX" (little-endian) order.
2776           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2777            _exactly_ 32 bits, respectively.)
2778
2779     q   A signed quad (64-bit) value.
2780     Q   An unsigned quad value.
2781           (Quads are available only if your system supports 64-bit
2782            integer values _and_ if Perl has been compiled to support those.
2783            Causes a fatal error otherwise.)
2784
2785     f   A single-precision float in the native format.
2786     d   A double-precision float in the native format.
2787
2788     p   A pointer to a null-terminated string.
2789     P   A pointer to a structure (fixed-length string).
2790
2791     u   A uuencoded string.
2792     U   A Unicode character number.  Encodes to UTF-8 internally.
2793         Works even if C<use utf8> is not in effect.
2794
2795     w   A BER compressed integer.  Its bytes represent an unsigned
2796         integer in base 128, most significant digit first, with as
2797         few digits as possible.  Bit eight (the high bit) is set
2798         on each byte except the last.
2799
2800     x   A null byte.
2801     X   Back up a byte.
2802     @   Null fill to absolute position.
2803
2804 The following rules apply:
2805
2806 =over 8
2807
2808 =item *
2809
2810 Each letter may optionally be followed by a number giving a repeat
2811 count.  With all types except C<"a">, C<"A">, C<"Z">, C<"b">, C<"B">, C<"h">,
2812 C<"H">, and C<"P"> the pack function will gobble up that many values from
2813 the LIST.  A C<*> for the repeat count means to use however many items are
2814 left, except for C<"@">, C<"x">, C<"X">, where it is equivalent
2815 to C<"0">, and C<"u">, where it is equivalent to 1 (or 45, what is the
2816 same).
2817
2818 When used with C<"Z">, C<*> results in the addition of a trailing null
2819 byte (so the packed result will be one longer than the byte C<length>
2820 of the item).
2821
2822 The repeat count for C<"u"> is interpreted as the maximal number of bytes
2823 to encode per line of output, with 0 and 1 replaced by 45.
2824
2825 =item *
2826
2827 The C<"a">, C<"A">, and C<"Z"> types gobble just one value, but pack it as a
2828 string of length count, padding with nulls or spaces as necessary.  When
2829 unpacking, C<"A"> strips trailing spaces and nulls, C<"Z"> strips everything
2830 after the first null, and C<"a"> returns data verbatim.  When packing,
2831 C<"a">, and C<"Z"> are equivalent.
2832
2833 If the value-to-pack is too long, it is truncated.  If too long and an
2834 explicit count is provided, C<"Z"> packs only C<$count-1> bytes, followed
2835 by a null byte.  Thus C<"Z"> always packs a trailing null byte under
2836 all circumstances.
2837
2838 =item *
2839
2840 Likewise, the C<"b"> and C<"B"> fields pack a string that many bits long.
2841 Each byte of the input field generates 1 bit of the result basing on
2842 the least-signifant bit of each input byte, i.e., on C<ord($byte)%2>.
2843 In particular, bytes C<"0"> and C<"1"> generate bits 0 and 1.
2844
2845 Starting from the beginning of the input string, each 8-tuple of bytes
2846 is converted to 1 byte of output.  If the length of the input string
2847 is not divisible by 8, the remainder is packed as if padded by 0s.
2848 Similarly, during unpack()ing the "extra" bits are ignored.
2849
2850 If the input string is longer than needed, extra bytes are ignored.
2851 A C<*> for the repeat count of pack() means to use all the bytes of
2852 the input field.  On unpack()ing the bits are converted to a string
2853 of C<"0">s and C<"1">s.
2854
2855 =item *
2856
2857 The C<"h"> and C<"H"> fields pack a string that many nybbles (4-bit groups,
2858 representable as hexadecimal digits, 0-9a-f) long.
2859
2860 =item *
2861
2862 The C<"p"> type packs a pointer to a null-terminated string.  You are
2863 responsible for ensuring the string is not a temporary value (which can
2864 potentially get deallocated before you get around to using the packed result).
2865 The C<"P"> type packs a pointer to a structure of the size indicated by the
2866 length.  A NULL pointer is created if the corresponding value for C<"p"> or
2867 C<"P"> is C<undef>, similarly for unpack().
2868
2869 =item *
2870
2871 The C<"/"> character allows packing and unpacking of strings where the
2872 packed structure contains a byte count followed by the string itself.
2873 You write I<length-item>C</>I<string-item>.
2874
2875 The I<length-item> can be any C<pack> template letter,
2876 and describes how the length value is packed.
2877 The ones likely to be of most use are integer-packing ones like
2878 C<"n"> (for Java strings), C<"w"> (for ASN.1 or SNMP)
2879 and C<"N"> (for Sun XDR).
2880
2881 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
2882 For C<unpack> the length of the string is obtained from the I<length-item>,
2883 but if you put in the '*' it will be ignored.
2884
2885     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
2886     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
2887     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
2888
2889 The I<length-item> is not returned explicitly from C<unpack>.
2890
2891 Adding a count to the I<length-item> letter
2892 is unlikely to do anything useful,
2893 unless that letter is C<"A">, C<"a"> or C<"Z">.
2894 Packing with a I<length-item> of C<"a"> or C<"Z">
2895 may introduce C<"\000"> characters,
2896 which Perl does not regard as legal in numeric strings.
2897
2898 =item *
2899
2900 The integer types C<"s">, C<"S">, C<"l">, and C<"L"> may be
2901 immediately followed by a C<"!"> suffix to signify native shorts or
2902 longs--as you can see from above for example a bare C<"l"> does mean
2903 exactly 32 bits, the native C<long> (as seen by the local C compiler)
2904 may be larger.  This is an issue mainly in 64-bit platforms.  You can
2905 see whether using C<"!"> makes any difference by
2906
2907         print length(pack("s")), " ", length(pack("s!")), "\n";
2908         print length(pack("l")), " ", length(pack("l!")), "\n";
2909
2910 C<"i!"> and C<"I!"> also work but only because of completeness;
2911 they are identical to C<"i"> and C<"I">.
2912
2913 The actual sizes (in bytes) of native shorts, ints, longs, and long
2914 longs on the platform where Perl was built are also available via
2915 L<Config>:
2916
2917        use Config;
2918        print $Config{shortsize},    "\n";
2919        print $Config{intsize},      "\n";
2920        print $Config{longsize},     "\n";
2921        print $Config{longlongsize}, "\n";
2922
2923 (The C<$Config{longlongsize}> will be undefine if your system does
2924 not support long longs.) 
2925
2926 =item *
2927
2928 The integer formats C<"s">, C<"S">, C<"i">, C<"I">, C<"l">, and C<"L">
2929 are inherently non-portable between processors and operating systems
2930 because they obey the native byteorder and endianness.  For example a
2931 4-byte integer 0x12345678 (305419896 decimal) be ordered natively
2932 (arranged in and handled by the CPU registers) into bytes as
2933  
2934         0x12 0x34 0x56 0x78     # little-endian
2935         0x78 0x56 0x34 0x12     # big-endian
2936  
2937 Basically, the Intel, Alpha, and VAX CPUs and little-endian, while
2938 everybody else, for example Motorola m68k/88k, PPC, Sparc, HP PA,
2939 Power, and Cray are big-endian.  MIPS can be either: Digital used it
2940 in little-endian mode; SGI uses it in big-endian mode.
2941
2942 The names `big-endian' and `little-endian' are comic references to
2943 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
2944 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
2945 the egg-eating habits of the Lilliputians.
2946  
2947 Some systems may have even weirder byte orders such as
2948  
2949         0x56 0x78 0x12 0x34
2950         0x34 0x12 0x78 0x56
2951  
2952 You can see your system's preference with
2953
2954         print join(" ", map { sprintf "%#02x", $_ }
2955                             unpack("C*",pack("L",0x12345678))), "\n";
2956
2957 The byteorder on the platform where Perl was built is also available
2958 via L<Config>:
2959
2960         use Config;
2961         print $Config{byteorder}, "\n";
2962
2963 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
2964 and C<'87654321'> are big-endian.
2965
2966 If you want portable packed integers use the formats C<"n">, C<"N">,
2967 C<"v">, and C<"V">, their byte endianness and size is known.
2968 See also L<perlport>.
2969
2970 =item *
2971
2972 Real numbers (floats and doubles) are in the native machine format only;
2973 due to the multiplicity of floating formats around, and the lack of a
2974 standard "network" representation, no facility for interchange has been
2975 made.  This means that packed floating point data written on one machine
2976 may not be readable on another - even if both use IEEE floating point
2977 arithmetic (as the endian-ness of the memory representation is not part
2978 of the IEEE spec).  See also L<perlport>.
2979
2980 Note that Perl uses doubles internally for all numeric calculation, and
2981 converting from double into float and thence back to double again will
2982 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
2983 equal $foo).
2984
2985 =item *
2986
2987 You must yourself do any alignment or padding by inserting for example
2988 enough C<'x'>es while packing.  There is no way to pack() and unpack()
2989 could know where the bytes are going to or coming from.  Therefore
2990 C<pack> (and C<unpack>) handle their output and input as flat
2991 sequences of bytes.
2992
2993 =item *
2994
2995 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
2996
2997 =item *
2998
2999 If TEMPLATE requires more arguments to pack() than actually given, pack()
3000 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3001 to pack() than actually given, extra arguments are ignored.
3002
3003 =back
3004
3005 Examples:
3006
3007     $foo = pack("CCCC",65,66,67,68);
3008     # foo eq "ABCD"
3009     $foo = pack("C4",65,66,67,68);
3010     # same thing
3011     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3012     # same thing with Unicode circled letters
3013
3014     $foo = pack("ccxxcc",65,66,67,68);
3015     # foo eq "AB\0\0CD"
3016
3017     # note: the above examples featuring "C" and "c" are true
3018     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3019     # and UTF-8.  In EBCDIC the first example would be
3020     # $foo = pack("CCCC",193,194,195,196);
3021
3022     $foo = pack("s2",1,2);
3023     # "\1\0\2\0" on little-endian
3024     # "\0\1\0\2" on big-endian
3025
3026     $foo = pack("a4","abcd","x","y","z");
3027     # "abcd"
3028
3029     $foo = pack("aaaa","abcd","x","y","z");
3030     # "axyz"
3031
3032     $foo = pack("a14","abcdefg");
3033     # "abcdefg\0\0\0\0\0\0\0"
3034
3035     $foo = pack("i9pl", gmtime);
3036     # a real struct tm (on my system anyway)
3037
3038     $utmp_template = "Z8 Z8 Z16 L";
3039     $utmp = pack($utmp_template, @utmp1);
3040     # a struct utmp (BSDish)
3041
3042     @utmp2 = unpack($utmp_template, $utmp);
3043     # "@utmp1" eq "@utmp2"
3044
3045     sub bintodec {
3046         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3047     }
3048
3049     $foo = pack('sx2l', 12, 34);
3050     # short 12, two zero bytes padding, long 34
3051     $bar = pack('s@4l', 12, 34);
3052     # short 12, zero fill to position 4, long 34
3053     # $foo eq $bar
3054
3055 The same template may generally also be used in unpack().
3056
3057 =item package 
3058
3059 =item package NAMESPACE
3060
3061 Declares the compilation unit as being in the given namespace.  The scope
3062 of the package declaration is from the declaration itself through the end
3063 of the enclosing block, file, or eval (the same as the C<my> operator).
3064 All further unqualified dynamic identifiers will be in this namespace.
3065 A package statement affects only dynamic variables--including those
3066 you've used C<local> on--but I<not> lexical variables, which are created
3067 with C<my>.  Typically it would be the first declaration in a file to
3068 be included by the C<require> or C<use> operator.  You can switch into a
3069 package in more than one place; it merely influences which symbol table
3070 is used by the compiler for the rest of that block.  You can refer to
3071 variables and filehandles in other packages by prefixing the identifier
3072 with the package name and a double colon:  C<$Package::Variable>.
3073 If the package name is null, the C<main> package as assumed.  That is,
3074 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3075 still seen in older code).
3076
3077 If NAMESPACE is omitted, then there is no current package, and all
3078 identifiers must be fully qualified or lexicals.  This is stricter
3079 than C<use strict>, since it also extends to function names.
3080
3081 See L<perlmod/"Packages"> for more information about packages, modules,
3082 and classes.  See L<perlsub> for other scoping issues.
3083
3084 =item pipe READHANDLE,WRITEHANDLE
3085
3086 Opens a pair of connected pipes like the corresponding system call.
3087 Note that if you set up a loop of piped processes, deadlock can occur
3088 unless you are very careful.  In addition, note that Perl's pipes use
3089 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3090 after each command, depending on the application.
3091
3092 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3093 for examples of such things.
3094
3095 On systems that support a close-on-exec flag on files, the flag will be set
3096 for the newly opened file descriptors as determined by the value of $^F.
3097 See L<perlvar/$^F>.
3098
3099 =item pop ARRAY
3100
3101 =item pop
3102
3103 Pops and returns the last value of the array, shortening the array by
3104 one element.  Has an effect similar to
3105
3106     $ARRAY[$#ARRAY--]
3107
3108 If there are no elements in the array, returns the undefined value
3109 (although this may happen at other times as well).  If ARRAY is
3110 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3111 array in subroutines, just like C<shift>.
3112
3113 =item pos SCALAR
3114
3115 =item pos
3116
3117 Returns the offset of where the last C<m//g> search left off for the variable
3118 is in question (C<$_> is used when the variable is not specified).  May be
3119 modified to change that offset.  Such modification will also influence
3120 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3121 L<perlop>.
3122
3123 =item print FILEHANDLE LIST
3124
3125 =item print LIST
3126
3127 =item print
3128
3129 Prints a string or a list of strings.  Returns true if successful.
3130 FILEHANDLE may be a scalar variable name, in which case the variable
3131 contains the name of or a reference to the filehandle, thus introducing
3132 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3133 the next token is a term, it may be misinterpreted as an operator
3134 unless you interpose a C<+> or put parentheses around the arguments.)
3135 If FILEHANDLE is omitted, prints by default to standard output (or
3136 to the last selected output channel--see L</select>).  If LIST is
3137 also omitted, prints C<$_> to the currently selected output channel.
3138 To set the default output channel to something other than STDOUT
3139 use the select operation.  The current value of C<$,> (if any) is
3140 printed between each LIST item.  The current value of C<$\> (if
3141 any) is printed after the entire LIST has been printed.  Because
3142 print takes a LIST, anything in the LIST is evaluated in list
3143 context, and any subroutine that you call will have one or more of
3144 its expressions evaluated in list context.  Also be careful not to
3145 follow the print keyword with a left parenthesis unless you want
3146 the corresponding right parenthesis to terminate the arguments to
3147 the print--interpose a C<+> or put parentheses around all the
3148 arguments.
3149
3150 Note that if you're storing FILEHANDLES in an array or other expression,
3151 you will have to use a block returning its value instead:
3152
3153     print { $files[$i] } "stuff\n";
3154     print { $OK ? STDOUT : STDERR } "stuff\n";
3155
3156 =item printf FILEHANDLE FORMAT, LIST
3157
3158 =item printf FORMAT, LIST
3159
3160 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3161 (the output record separator) is not appended.  The first argument
3162 of the list will be interpreted as the C<printf> format.  If C<use locale> is
3163 in effect, the character used for the decimal point in formatted real numbers
3164 is affected by the LC_NUMERIC locale.  See L<perllocale>.
3165
3166 Don't fall into the trap of using a C<printf> when a simple
3167 C<print> would do.  The C<print> is more efficient and less
3168 error prone.
3169
3170 =item prototype FUNCTION
3171
3172 Returns the prototype of a function as a string (or C<undef> if the
3173 function has no prototype).  FUNCTION is a reference to, or the name of,
3174 the function whose prototype you want to retrieve.
3175
3176 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3177 name for Perl builtin.  If the builtin is not I<overridable> (such as
3178 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3179 C<system>) returns C<undef> because the builtin does not really behave
3180 like a Perl function.  Otherwise, the string describing the equivalent
3181 prototype is returned.
3182
3183 =item push ARRAY,LIST
3184
3185 Treats ARRAY as a stack, and pushes the values of LIST
3186 onto the end of ARRAY.  The length of ARRAY increases by the length of
3187 LIST.  Has the same effect as
3188
3189     for $value (LIST) {
3190         $ARRAY[++$#ARRAY] = $value;
3191     }
3192
3193 but is more efficient.  Returns the new number of elements in the array.
3194
3195 =item q/STRING/
3196
3197 =item qq/STRING/
3198
3199 =item qr/STRING/
3200
3201 =item qx/STRING/
3202
3203 =item qw/STRING/
3204
3205 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3206
3207 =item quotemeta EXPR
3208
3209 =item quotemeta
3210
3211 Returns the value of EXPR with all non-alphanumeric
3212 characters backslashed.  (That is, all characters not matching
3213 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3214 returned string, regardless of any locale settings.)
3215 This is the internal function implementing
3216 the C<\Q> escape in double-quoted strings.
3217
3218 If EXPR is omitted, uses C<$_>.
3219
3220 =item rand EXPR
3221
3222 =item rand
3223
3224 Returns a random fractional number greater than or equal to C<0> and less
3225 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3226 omitted, the value C<1> is used.  Automatically calls C<srand> unless
3227 C<srand> has already been called.  See also C<srand>.
3228
3229 (Note: If your rand function consistently returns numbers that are too
3230 large or too small, then your version of Perl was probably compiled
3231 with the wrong number of RANDBITS.)
3232
3233 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3234
3235 =item read FILEHANDLE,SCALAR,LENGTH
3236
3237 Attempts to read LENGTH bytes of data into variable SCALAR from the
3238 specified FILEHANDLE.  Returns the number of bytes actually read,
3239 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
3240 or shrunk to the length actually read.  An OFFSET may be specified to
3241 place the read data at some other place than the beginning of the
3242 string.  This call is actually implemented in terms of stdio's fread(3)
3243 call.  To get a true read(2) system call, see C<sysread>.
3244
3245 =item readdir DIRHANDLE
3246
3247 Returns the next directory entry for a directory opened by C<opendir>.
3248 If used in list context, returns all the rest of the entries in the
3249 directory.  If there are no more entries, returns an undefined value in
3250 scalar context or a null list in list context.
3251
3252 If you're planning to filetest the return values out of a C<readdir>, you'd
3253 better prepend the directory in question.  Otherwise, because we didn't
3254 C<chdir> there, it would have been testing the wrong file.
3255
3256     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3257     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3258     closedir DIR;
3259
3260 =item readline EXPR
3261
3262 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3263 context, each call reads and returns the next line, until end-of-file is
3264 reached, whereupon the subsequent call returns undef.  In list context,
3265 reads until end-of-file is reached and returns a list of lines.  Note that
3266 the notion of "line" used here is however you may have defined it
3267 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3268
3269 When C<$/> is set to C<undef>, when readline() is in scalar
3270 context (i.e. file slurp mode), and when an empty file is read, it
3271 returns C<''> the first time, followed by C<undef> subsequently.
3272
3273 This is the internal function implementing the C<E<lt>EXPRE<gt>>
3274 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
3275 operator is discussed in more detail in L<perlop/"I/O Operators">.
3276
3277     $line = <STDIN>;
3278     $line = readline(*STDIN);           # same thing
3279
3280 =item readlink EXPR
3281
3282 =item readlink
3283
3284 Returns the value of a symbolic link, if symbolic links are
3285 implemented.  If not, gives a fatal error.  If there is some system
3286 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3287 omitted, uses C<$_>.
3288
3289 =item readpipe EXPR
3290
3291 EXPR is executed as a system command.
3292 The collected standard output of the command is returned.
3293 In scalar context, it comes back as a single (potentially
3294 multi-line) string.  In list context, returns a list of lines
3295 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3296 This is the internal function implementing the C<qx/EXPR/>
3297 operator, but you can use it directly.  The C<qx/EXPR/>
3298 operator is discussed in more detail in L<perlop/"I/O Operators">.
3299
3300 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3301
3302 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3303 data into variable SCALAR from the specified SOCKET filehandle.  SCALAR
3304 will be grown or shrunk to the length actually read.  Takes the same
3305 flags as the system call of the same name.  Returns the address of the
3306 sender if SOCKET's protocol supports this; returns an empty string
3307 otherwise.  If there's an error, returns the undefined value.  This call
3308 is actually implemented in terms of recvfrom(2) system call.  See
3309 L<perlipc/"UDP: Message Passing"> for examples.
3310
3311 =item redo LABEL
3312
3313 =item redo
3314
3315 The C<redo> command restarts the loop block without evaluating the
3316 conditional again.  The C<continue> block, if any, is not executed.  If
3317 the LABEL is omitted, the command refers to the innermost enclosing
3318 loop.  This command is normally used by programs that want to lie to
3319 themselves about what was just input:
3320
3321     # a simpleminded Pascal comment stripper
3322     # (warning: assumes no { or } in strings)
3323     LINE: while (<STDIN>) {
3324         while (s|({.*}.*){.*}|$1 |) {}
3325         s|{.*}| |;
3326         if (s|{.*| |) {
3327             $front = $_;
3328             while (<STDIN>) {
3329                 if (/}/) {      # end of comment?
3330                     s|^|$front\{|;
3331                     redo LINE;
3332                 }
3333             }
3334         }
3335         print;
3336     }
3337
3338 C<redo> cannot be used to retry a block which returns a value such as
3339 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3340 a grep() or map() operation.
3341
3342 Note that a block by itself is semantically identical to a loop
3343 that executes once.  Thus C<redo> inside such a block will effectively
3344 turn it into a looping construct.
3345
3346 See also L</continue> for an illustration of how C<last>, C<next>, and
3347 C<redo> work.
3348
3349 =item ref EXPR
3350
3351 =item ref
3352
3353 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3354 is not specified, C<$_> will be used.  The value returned depends on the
3355 type of thing the reference is a reference to.
3356 Builtin types include:
3357
3358     SCALAR
3359     ARRAY
3360     HASH
3361     CODE
3362     REF
3363     GLOB
3364     LVALUE
3365
3366 If the referenced object has been blessed into a package, then that package
3367 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3368
3369     if (ref($r) eq "HASH") {
3370         print "r is a reference to a hash.\n";
3371     }
3372     unless (ref($r)) {
3373         print "r is not a reference at all.\n";
3374     }
3375     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3376         print "r is a reference to something that isa hash.\n";
3377     } 
3378
3379 See also L<perlref>.
3380
3381 =item rename OLDNAME,NEWNAME
3382
3383 Changes the name of a file; an existing file NEWNAME will be
3384 clobbered.  Returns true for success, false otherwise.
3385
3386 Behavior of this function varies wildly depending on your system
3387 implementation.  For example, it will usually not work across file system
3388 boundaries, even though the system I<mv> command sometimes compensates
3389 for this.  Other restrictions include whether it works on directories,
3390 open files, or pre-existing files.  Check L<perlport> and either the
3391 rename(2) manpage or equivalent system documentation for details.
3392
3393 =item require EXPR
3394
3395 =item require
3396
3397 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3398 supplied.  If EXPR is numeric, demands that the current version of Perl
3399 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
3400
3401 Otherwise, demands that a library file be included if it hasn't already
3402 been included.  The file is included via the do-FILE mechanism, which is
3403 essentially just a variety of C<eval>.  Has semantics similar to the following
3404 subroutine:
3405
3406     sub require {
3407         my($filename) = @_;
3408         return 1 if $INC{$filename};
3409         my($realfilename,$result);
3410         ITER: {
3411             foreach $prefix (@INC) {
3412                 $realfilename = "$prefix/$filename";
3413                 if (-f $realfilename) {
3414                     $result = do $realfilename;
3415                     last ITER;
3416                 }
3417             }
3418             die "Can't find $filename in \@INC";
3419         }
3420         die $@ if $@;
3421         die "$filename did not return true value" unless $result;
3422         $INC{$filename} = $realfilename;
3423         return $result;
3424     }
3425
3426 Note that the file will not be included twice under the same specified
3427 name.  The file must return true as the last statement to indicate
3428 successful execution of any initialization code, so it's customary to
3429 end such a file with C<1;> unless you're sure it'll return true
3430 otherwise.  But it's better just to put the C<1;>, in case you add more
3431 statements.
3432
3433 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3434 replaces "F<::>" with "F</>" in the filename for you,
3435 to make it easy to load standard modules.  This form of loading of
3436 modules does not risk altering your namespace.
3437
3438 In other words, if you try this:
3439
3440         require Foo::Bar;    # a splendid bareword 
3441
3442 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
3443 directories specified in the C<@INC> array.
3444
3445 But if you try this:
3446
3447         $class = 'Foo::Bar';
3448         require $class;      # $class is not a bareword
3449     #or
3450         require "Foo::Bar";  # not a bareword because of the ""
3451
3452 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
3453 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3454
3455         eval "require $class";
3456
3457 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3458
3459 =item reset EXPR
3460
3461 =item reset
3462
3463 Generally used in a C<continue> block at the end of a loop to clear
3464 variables and reset C<??> searches so that they work again.  The
3465 expression is interpreted as a list of single characters (hyphens
3466 allowed for ranges).  All variables and arrays beginning with one of
3467 those letters are reset to their pristine state.  If the expression is
3468 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3469 only variables or searches in the current package.  Always returns
3470 1.  Examples:
3471
3472     reset 'X';          # reset all X variables
3473     reset 'a-z';        # reset lower case variables
3474     reset;              # just reset ?one-time? searches
3475
3476 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3477 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3478 variables--lexical variables are unaffected, but they clean themselves
3479 up on scope exit anyway, so you'll probably want to use them instead.
3480 See L</my>.
3481
3482 =item return EXPR
3483
3484 =item return
3485
3486 Returns from a subroutine, C<eval>, or C<do FILE> with the value 
3487 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3488 context, depending on how the return value will be used, and the context
3489 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3490 is given, returns an empty list in list context, the undefined value in
3491 scalar context, and (of course) nothing at all in a void context.
3492
3493 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3494 or do FILE will automatically return the value of the last expression
3495 evaluated.)
3496
3497 =item reverse LIST
3498
3499 In list context, returns a list value consisting of the elements
3500 of LIST in the opposite order.  In scalar context, concatenates the
3501 elements of LIST and returns a string value with all characters
3502 in the opposite order.
3503
3504     print reverse <>;           # line tac, last line first
3505
3506     undef $/;                   # for efficiency of <>
3507     print scalar reverse <>;    # character tac, last line tsrif
3508
3509 This operator is also handy for inverting a hash, although there are some
3510 caveats.  If a value is duplicated in the original hash, only one of those
3511 can be represented as a key in the inverted hash.  Also, this has to
3512 unwind one hash and build a whole new one, which may take some time
3513 on a large hash, such as from a DBM file.
3514
3515     %by_name = reverse %by_address;     # Invert the hash
3516
3517 =item rewinddir DIRHANDLE
3518
3519 Sets the current position to the beginning of the directory for the
3520 C<readdir> routine on DIRHANDLE.
3521
3522 =item rindex STR,SUBSTR,POSITION
3523
3524 =item rindex STR,SUBSTR
3525
3526 Works just like index() except that it returns the position of the LAST
3527 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3528 last occurrence at or before that position.
3529
3530 =item rmdir FILENAME
3531
3532 =item rmdir
3533
3534 Deletes the directory specified by FILENAME if that directory is empty.  If it
3535 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3536 FILENAME is omitted, uses C<$_>.
3537
3538 =item s///
3539
3540 The substitution operator.  See L<perlop>.
3541
3542 =item scalar EXPR
3543
3544 Forces EXPR to be interpreted in scalar context and returns the value
3545 of EXPR.
3546
3547     @counts = ( scalar @a, scalar @b, scalar @c );
3548
3549 There is no equivalent operator to force an expression to
3550 be interpolated in list context because in practice, this is never
3551 needed.  If you really wanted to do so, however, you could use
3552 the construction C<@{[ (some expression) ]}>, but usually a simple
3553 C<(some expression)> suffices.
3554
3555 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3556 parenthesized list, this behaves as a scalar comma expression, evaluating
3557 all but the last element in void context and returning the final element
3558 evaluated in scalar context.  This is seldom what you want.
3559
3560 The following single statement:
3561
3562         print uc(scalar(&foo,$bar)),$baz;
3563
3564 is the moral equivalent of these two:
3565
3566         &foo;
3567         print(uc($bar),$baz);
3568
3569 See L<perlop> for more details on unary operators and the comma operator.
3570
3571 =item seek FILEHANDLE,POSITION,WHENCE
3572
3573 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3574 FILEHANDLE may be an expression whose value gives the name of the
3575 filehandle.  The values for WHENCE are C<0> to set the new position to
3576 POSITION, C<1> to set it to the current position plus POSITION, and
3577 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3578 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3579 (start of the file, current position, end of the file) from any of the
3580 modules Fcntl, C<IO::Seekable>, or POSIX.  Returns C<1> upon success,
3581 C<0> otherwise.
3582
3583 If you want to position file for C<sysread> or C<syswrite>, don't use
3584 C<seek>--buffering makes its effect on the file's system position
3585 unpredictable and non-portable.  Use C<sysseek> instead.
3586
3587 Due to the rules and rigors of ANSI C, on some systems you have to do a
3588 seek whenever you switch between reading and writing.  Amongst other
3589 things, this may have the effect of calling stdio's clearerr(3).
3590 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3591
3592     seek(TEST,0,1);
3593
3594 This is also useful for applications emulating C<tail -f>.  Once you hit
3595 EOF on your read, and then sleep for a while, you might have to stick in a
3596 seek() to reset things.  The C<seek> doesn't change the current position,
3597 but it I<does> clear the end-of-file condition on the handle, so that the
3598 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
3599
3600 If that doesn't work (some stdios are particularly cantankerous), then
3601 you may need something more like this:
3602
3603     for (;;) {
3604         for ($curpos = tell(FILE); $_ = <FILE>;
3605              $curpos = tell(FILE)) {
3606             # search for some stuff and put it into files
3607         }
3608         sleep($for_a_while);
3609         seek(FILE, $curpos, 0);
3610     }
3611
3612 =item seekdir DIRHANDLE,POS
3613
3614 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
3615 must be a value returned by C<telldir>.  Has the same caveats about
3616 possible directory compaction as the corresponding system library
3617 routine.
3618
3619 =item select FILEHANDLE
3620
3621 =item select
3622
3623 Returns the currently selected filehandle.  Sets the current default
3624 filehandle for output, if FILEHANDLE is supplied.  This has two
3625 effects: first, a C<write> or a C<print> without a filehandle will
3626 default to this FILEHANDLE.  Second, references to variables related to
3627 output will refer to this output channel.  For example, if you have to
3628 set the top of form format for more than one output channel, you might
3629 do the following:
3630
3631     select(REPORT1);
3632     $^ = 'report1_top';
3633     select(REPORT2);
3634     $^ = 'report2_top';
3635
3636 FILEHANDLE may be an expression whose value gives the name of the
3637 actual filehandle.  Thus:
3638
3639     $oldfh = select(STDERR); $| = 1; select($oldfh);
3640
3641 Some programmers may prefer to think of filehandles as objects with
3642 methods, preferring to write the last example as:
3643
3644     use IO::Handle;
3645     STDERR->autoflush(1);
3646
3647 =item select RBITS,WBITS,EBITS,TIMEOUT
3648
3649 This calls the select(2) system call with the bit masks specified, which
3650 can be constructed using C<fileno> and C<vec>, along these lines:
3651
3652     $rin = $win = $ein = '';
3653     vec($rin,fileno(STDIN),1) = 1;
3654     vec($win,fileno(STDOUT),1) = 1;
3655     $ein = $rin | $win;
3656
3657 If you want to select on many filehandles you might wish to write a
3658 subroutine:
3659
3660     sub fhbits {
3661         my(@fhlist) = split(' ',$_[0]);
3662         my($bits);
3663         for (@fhlist) {
3664             vec($bits,fileno($_),1) = 1;
3665         }
3666         $bits;
3667     }
3668     $rin = fhbits('STDIN TTY SOCK');
3669
3670 The usual idiom is:
3671
3672     ($nfound,$timeleft) =
3673       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3674
3675 or to block until something becomes ready just do this
3676
3677     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3678
3679 Most systems do not bother to return anything useful in $timeleft, so
3680 calling select() in scalar context just returns $nfound.
3681
3682 Any of the bit masks can also be undef.  The timeout, if specified, is
3683 in seconds, which may be fractional.  Note: not all implementations are
3684 capable of returning the$timeleft.  If not, they always return
3685 $timeleft equal to the supplied $timeout.
3686
3687 You can effect a sleep of 250 milliseconds this way:
3688
3689     select(undef, undef, undef, 0.25);
3690
3691 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
3692 or E<lt>FHE<gt>) with C<select>, except as permitted by POSIX, and even
3693 then only on POSIX systems.  You have to use C<sysread> instead.
3694
3695 =item semctl ID,SEMNUM,CMD,ARG
3696
3697 Calls the System V IPC function C<semctl>.  You'll probably have to say
3698
3699     use IPC::SysV;
3700
3701 first to get the correct constant definitions.  If CMD is IPC_STAT or
3702 GETALL, then ARG must be a variable which will hold the returned
3703 semid_ds structure or semaphore value array.  Returns like C<ioctl>: the
3704 undefined value for error, "C<0 but true>" for zero, or the actual return
3705 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3706
3707 =item semget KEY,NSEMS,FLAGS
3708
3709 Calls the System V IPC function semget.  Returns the semaphore id, or
3710 the undefined value if there is an error.  See also C<IPC::SysV> and
3711 C<IPC::SysV::Semaphore> documentation.
3712
3713 =item semop KEY,OPSTRING
3714
3715 Calls the System V IPC function semop to perform semaphore operations
3716 such as signaling and waiting.  OPSTRING must be a packed array of
3717 semop structures.  Each semop structure can be generated with
3718 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3719 operations is implied by the length of OPSTRING.  Returns true if
3720 successful, or false if there is an error.  As an example, the
3721 following code waits on semaphore $semnum of semaphore id $semid:
3722
3723     $semop = pack("sss", $semnum, -1, 0);
3724     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3725
3726 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3727 and C<IPC::SysV::Semaphore> documentation.
3728
3729 =item send SOCKET,MSG,FLAGS,TO
3730
3731 =item send SOCKET,MSG,FLAGS
3732
3733 Sends a message on a socket.  Takes the same flags as the system call
3734 of the same name.  On unconnected sockets you must specify a
3735 destination to send TO, in which case it does a C C<sendto>.  Returns
3736 the number of characters sent, or the undefined value if there is an
3737 error.  The C system call sendmsg(2) is currently unimplemented.
3738 See L<perlipc/"UDP: Message Passing"> for examples.
3739
3740 =item setpgrp PID,PGRP
3741
3742 Sets the current process group for the specified PID, C<0> for the current
3743 process.  Will produce a fatal error if used on a machine that doesn't
3744 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
3745 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
3746 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
3747 C<POSIX::setsid()>.
3748
3749 =item setpriority WHICH,WHO,PRIORITY
3750
3751 Sets the current priority for a process, a process group, or a user.
3752 (See setpriority(2).)  Will produce a fatal error if used on a machine
3753 that doesn't implement setpriority(2).
3754
3755 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3756
3757 Sets the socket option requested.  Returns undefined if there is an
3758 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3759 argument.
3760
3761 =item shift ARRAY
3762
3763 =item shift
3764
3765 Shifts the first value of the array off and returns it, shortening the
3766 array by 1 and moving everything down.  If there are no elements in the
3767 array, returns the undefined value.  If ARRAY is omitted, shifts the
3768 C<@_> array within the lexical scope of subroutines and formats, and the
3769 C<@ARGV> array at file scopes or within the lexical scopes established by
3770 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
3771 See also C<unshift>, C<push>, and C<pop>.  C<Shift()> and C<unshift> do the
3772 same thing to the left end of an array that C<pop> and C<push> do to the
3773 right end.
3774
3775 =item shmctl ID,CMD,ARG
3776
3777 Calls the System V IPC function shmctl.  You'll probably have to say
3778
3779     use IPC::SysV;
3780
3781 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3782 then ARG must be a variable which will hold the returned C<shmid_ds>
3783 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3784 true" for zero, or the actual return value otherwise.
3785 See also C<IPC::SysV> documentation.
3786
3787 =item shmget KEY,SIZE,FLAGS
3788
3789 Calls the System V IPC function shmget.  Returns the shared memory
3790 segment id, or the undefined value if there is an error.
3791 See also C<IPC::SysV> documentation.
3792
3793 =item shmread ID,VAR,POS,SIZE
3794
3795 =item shmwrite ID,STRING,POS,SIZE
3796
3797 Reads or writes the System V shared memory segment ID starting at
3798 position POS for size SIZE by attaching to it, copying in/out, and
3799 detaching from it.  When reading, VAR must be a variable that will
3800 hold the data read.  When writing, if STRING is too long, only SIZE
3801 bytes are used; if STRING is too short, nulls are written to fill out
3802 SIZE bytes.  Return true if successful, or false if there is an error.
3803 See also C<IPC::SysV> documentation and the C<IPC::Shareable> module
3804 from CPAN.
3805
3806 =item shutdown SOCKET,HOW
3807
3808 Shuts down a socket connection in the manner indicated by HOW, which
3809 has the same interpretation as in the system call of the same name.
3810
3811     shutdown(SOCKET, 0);    # I/we have stopped reading data
3812     shutdown(SOCKET, 1);    # I/we have stopped writing data
3813     shutdown(SOCKET, 2);    # I/we have stopped using this socket
3814
3815 This is useful with sockets when you want to tell the other
3816 side you're done writing but not done reading, or vice versa.
3817 It's also a more insistent form of close because it also 
3818 disables the file descriptor in any forked copies in other
3819 processes.
3820
3821 =item sin EXPR
3822
3823 =item sin
3824
3825 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3826 returns sine of C<$_>.
3827
3828 For the inverse sine operation, you may use the C<POSIX::asin>
3829 function, or use this relation:
3830
3831     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3832
3833 =item sleep EXPR
3834
3835 =item sleep
3836
3837 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3838 May be interrupted if the process receives a signal such as C<SIGALRM>.
3839 Returns the number of seconds actually slept.  You probably cannot
3840 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
3841 using C<alarm>.
3842
3843 On some older systems, it may sleep up to a full second less than what
3844 you requested, depending on how it counts seconds.  Most modern systems
3845 always sleep the full amount.  They may appear to sleep longer than that,
3846 however, because your process might not be scheduled right away in a
3847 busy multitasking system.
3848
3849 For delays of finer granularity than one second, you may use Perl's
3850 C<syscall> interface to access setitimer(2) if your system supports
3851 it, or else see L</select> above.  The Time::HiRes module from CPAN
3852 may also help.
3853
3854 See also the POSIX module's C<sigpause> function.
3855
3856 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3857
3858 Opens a socket of the specified kind and attaches it to filehandle
3859 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
3860 the system call of the same name.  You should C<use Socket> first
3861 to get the proper definitions imported.  See the examples in
3862 L<perlipc/"Sockets: Client/Server Communication">.
3863
3864 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3865
3866 Creates an unnamed pair of sockets in the specified domain, of the
3867 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3868 for the system call of the same name.  If unimplemented, yields a fatal
3869 error.  Returns true if successful.
3870
3871 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
3872 to C<pipe(Rdr, Wtr)> is essentially:
3873
3874     use Socket;
3875     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3876     shutdown(Rdr, 1);        # no more writing for reader
3877     shutdown(Wtr, 0);        # no more reading for writer
3878
3879 See L<perlipc> for an example of socketpair use.
3880
3881 =item sort SUBNAME LIST
3882
3883 =item sort BLOCK LIST
3884
3885 =item sort LIST
3886
3887 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
3888 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
3889 specified, it gives the name of a subroutine that returns an integer
3890 less than, equal to, or greater than C<0>, depending on how the elements
3891 of the list are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
3892 operators are extremely useful in such routines.)  SUBNAME may be a
3893 scalar variable name (unsubscripted), in which case the value provides
3894 the name of (or a reference to) the actual subroutine to use.  In place
3895 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
3896 subroutine.
3897
3898 In the interests of efficiency the normal calling code for subroutines is
3899 bypassed, with the following effects: the subroutine may not be a
3900 recursive subroutine, and the two elements to be compared are passed into
3901 the subroutine not via C<@_> but as the package global variables $a and
3902 $b (see example below).  They are passed by reference, so don't
3903 modify $a and $b.  And don't try to declare them as lexicals either.
3904
3905 You also cannot exit out of the sort block or subroutine using any of the
3906 loop control operators described in L<perlsyn> or with C<goto>.
3907
3908 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3909 current collation locale.  See L<perllocale>.
3910
3911 Examples:
3912
3913     # sort lexically
3914     @articles = sort @files;
3915
3916     # same thing, but with explicit sort routine
3917     @articles = sort {$a cmp $b} @files;
3918
3919     # now case-insensitively
3920     @articles = sort {uc($a) cmp uc($b)} @files;
3921
3922     # same thing in reversed order
3923     @articles = sort {$b cmp $a} @files;
3924
3925     # sort numerically ascending
3926     @articles = sort {$a <=> $b} @files;
3927
3928     # sort numerically descending
3929     @articles = sort {$b <=> $a} @files;
3930
3931     # this sorts the %age hash by value instead of key
3932     # using an in-line function
3933     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3934
3935     # sort using explicit subroutine name
3936     sub byage {
3937         $age{$a} <=> $age{$b};  # presuming numeric
3938     }
3939     @sortedclass = sort byage @class;
3940
3941     sub backwards { $b cmp $a }
3942     @harry  = qw(dog cat x Cain Abel);
3943     @george = qw(gone chased yz Punished Axed);
3944     print sort @harry;
3945             # prints AbelCaincatdogx
3946     print sort backwards @harry;
3947             # prints xdogcatCainAbel
3948     print sort @george, 'to', @harry;
3949             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3950
3951     # inefficiently sort by descending numeric compare using
3952     # the first integer after the first = sign, or the
3953     # whole record case-insensitively otherwise
3954
3955     @new = sort {
3956         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3957                             ||
3958                     uc($a)  cmp  uc($b)
3959     } @old;
3960
3961     # same thing, but much more efficiently;
3962     # we'll build auxiliary indices instead
3963     # for speed
3964     @nums = @caps = ();
3965     for (@old) {
3966         push @nums, /=(\d+)/;
3967         push @caps, uc($_);
3968     }
3969
3970     @new = @old[ sort {
3971                         $nums[$b] <=> $nums[$a]
3972                                  ||
3973                         $caps[$a] cmp $caps[$b]
3974                        } 0..$#old
3975                ];
3976
3977     # same thing, but without any temps
3978     @new = map { $_->[0] }
3979            sort { $b->[1] <=> $a->[1]
3980                            ||
3981                   $a->[2] cmp $b->[2]
3982            } map { [$_, /=(\d+)/, uc($_)] } @old;
3983
3984 If you're using strict, you I<must not> declare $a
3985 and $b as lexicals.  They are package globals.  That means
3986 if you're in the C<main> package, it's
3987
3988     @articles = sort {$main::b <=> $main::a} @files;
3989
3990 or just
3991
3992     @articles = sort {$::b <=> $::a} @files;
3993
3994 but if you're in the C<FooPack> package, it's
3995
3996     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3997
3998 The comparison function is required to behave.  If it returns
3999 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4000 sometimes saying the opposite, for example) the results are not
4001 well-defined.
4002
4003 =item splice ARRAY,OFFSET,LENGTH,LIST
4004
4005 =item splice ARRAY,OFFSET,LENGTH
4006
4007 =item splice ARRAY,OFFSET
4008
4009 Removes the elements designated by OFFSET and LENGTH from an array, and
4010 replaces them with the elements of LIST, if any.  In list context,
4011 returns the elements removed from the array.  In scalar context,
4012 returns the last element removed, or C<undef> if no elements are
4013 removed.  The array grows or shrinks as necessary.
4014 If OFFSET is negative then it starts that far from the end of the array.
4015 If LENGTH is omitted, removes everything from OFFSET onward.
4016 If LENGTH is negative, leave that many elements off the end of the array.
4017 The following equivalences hold (assuming C<$[ == 0>):
4018
4019     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4020     pop(@a)             splice(@a,-1)
4021     shift(@a)           splice(@a,0,1)
4022     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4023     $a[$x] = $y         splice(@a,$x,1,$y)
4024
4025 Example, assuming array lengths are passed before arrays:
4026
4027     sub aeq {   # compare two list values
4028         my(@a) = splice(@_,0,shift);
4029         my(@b) = splice(@_,0,shift);
4030         return 0 unless @a == @b;       # same len?
4031         while (@a) {
4032             return 0 if pop(@a) ne pop(@b);
4033         }
4034         return 1;
4035     }
4036     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4037
4038 =item split /PATTERN/,EXPR,LIMIT
4039
4040 =item split /PATTERN/,EXPR
4041
4042 =item split /PATTERN/
4043
4044 =item split
4045
4046 Splits a string into a list of strings and returns that list.  By default,
4047 empty leading fields are preserved, and empty trailing ones are deleted.
4048
4049 If not in list context, returns the number of fields found and splits into
4050 the C<@_> array.  (In list context, you can force the split into C<@_> by
4051 using C<??> as the pattern delimiters, but it still returns the list
4052 value.)  The use of implicit split to C<@_> is deprecated, however, because
4053 it clobbers your subroutine arguments.
4054
4055 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4056 splits on whitespace (after skipping any leading whitespace).  Anything
4057 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4058 that the delimiter may be longer than one character.)
4059
4060 If LIMIT is specified and positive, splits into no more than that
4061 many fields (though it may split into fewer).  If LIMIT is unspecified
4062 or zero, trailing null fields are stripped (which potential users
4063 of C<pop> would do well to remember).  If LIMIT is negative, it is
4064 treated as if an arbitrarily large LIMIT had been specified.
4065
4066 A pattern matching the null string (not to be confused with
4067 a null pattern C<//>, which is just one member of the set of patterns
4068 matching a null string) will split the value of EXPR into separate
4069 characters at each point it matches that way.  For example:
4070
4071     print join(':', split(/ */, 'hi there'));
4072
4073 produces the output 'h:i:t:h:e:r:e'.
4074
4075 The LIMIT parameter can be used to split a line partially
4076
4077     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4078
4079 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4080 one larger than the number of variables in the list, to avoid
4081 unnecessary work.  For the list above LIMIT would have been 4 by
4082 default.  In time critical applications it behooves you not to split
4083 into more fields than you really need.
4084
4085 If the PATTERN contains parentheses, additional list elements are
4086 created from each matching substring in the delimiter.
4087
4088     split(/([,-])/, "1-10,20", 3);
4089
4090 produces the list value
4091
4092     (1, '-', 10, ',', 20)
4093
4094 If you had the entire header of a normal Unix email message in $header,
4095 you could split it up into fields and their values this way:
4096
4097     $header =~ s/\n\s+/ /g;  # fix continuation lines
4098     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4099
4100 The pattern C</PATTERN/> may be replaced with an expression to specify
4101 patterns that vary at runtime.  (To do runtime compilation only once,
4102 use C</$variable/o>.)
4103
4104 As a special case, specifying a PATTERN of space (C<' '>) will split on
4105 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4106 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4107 will give you as many null initial fields as there are leading spaces.
4108 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4109 whitespace produces a null first field.  A C<split> with no arguments
4110 really does a C<split(' ', $_)> internally.
4111
4112 Example:
4113
4114     open(PASSWD, '/etc/passwd');
4115     while (<PASSWD>) {
4116         ($login, $passwd, $uid, $gid,
4117          $gcos, $home, $shell) = split(/:/);
4118         #...
4119     }
4120
4121 (Note that $shell above will still have a newline on it.  See L</chop>,
4122 L</chomp>, and L</join>.)
4123
4124 =item sprintf FORMAT, LIST
4125
4126 Returns a string formatted by the usual C<printf> conventions of the
4127 C library function C<sprintf>.  See L<sprintf(3)> or L<printf(3)>
4128 on your system for an explanation of the general principles.
4129
4130 Perl does its own C<sprintf> formatting--it emulates the C
4131 function C<sprintf>, but it doesn't use it (except for floating-point
4132 numbers, and even then only the standard modifiers are allowed).  As a
4133 result, any non-standard extensions in your local C<sprintf> are not
4134 available from Perl.
4135
4136 Perl's C<sprintf> permits the following universally-known conversions:
4137
4138    %%   a percent sign
4139    %c   a character with the given number
4140    %s   a string
4141    %d   a signed integer, in decimal
4142    %u   an unsigned integer, in decimal
4143    %o   an unsigned integer, in octal
4144    %x   an unsigned integer, in hexadecimal
4145    %e   a floating-point number, in scientific notation
4146    %f   a floating-point number, in fixed decimal notation
4147    %g   a floating-point number, in %e or %f notation
4148
4149 In addition, Perl permits the following widely-supported conversions:
4150
4151    %X   like %x, but using upper-case letters
4152    %E   like %e, but using an upper-case "E"
4153    %G   like %g, but with an upper-case "E" (if applicable)
4154    %b   an unsigned integer, in binary
4155    %p   a pointer (outputs the Perl value's address in hexadecimal)
4156    %n   special: *stores* the number of characters output so far
4157         into the next variable in the parameter list 
4158
4159 Finally, for backward (and we do mean "backward") compatibility, Perl
4160 permits these unnecessary but widely-supported conversions:
4161
4162    %i   a synonym for %d
4163    %D   a synonym for %ld
4164    %U   a synonym for %lu
4165    %O   a synonym for %lo
4166    %F   a synonym for %f
4167
4168 Perl permits the following universally-known flags between the C<%>
4169 and the conversion letter:
4170
4171    space   prefix positive number with a space
4172    +       prefix positive number with a plus sign
4173    -       left-justify within the field
4174    0       use zeros, not spaces, to right-justify
4175    #       prefix non-zero octal with "0", non-zero hex with "0x"
4176    number  minimum field width
4177    .number "precision": digits after decimal point for
4178            floating-point, max length for string, minimum length
4179            for integer
4180    l       interpret integer as C type "long" or "unsigned long"
4181    h       interpret integer as C type "short" or "unsigned short"
4182            If no flags, interpret integer as C type "int" or "unsigned"
4183
4184 There is also one Perl-specific flag:
4185
4186    V       interpret integer as Perl's standard integer type
4187
4188 Where a number would appear in the flags, an asterisk (C<*>) may be
4189 used instead, in which case Perl uses the next item in the parameter
4190 list as the given number (that is, as the field width or precision).
4191 If a field width obtained through C<*> is negative, it has the same
4192 effect as the C<-> flag: left-justification.
4193
4194 If C<use locale> is in effect, the character used for the decimal
4195 point in formatted real numbers is affected by the LC_NUMERIC locale.
4196 See L<perllocale>.
4197
4198 To cope with broken systems that allow the standard locales to be
4199 overridden by malicious users, the return value may be tainted
4200 if any of the floating point formats are used and the conversion
4201 yields something that doesn't look like a normal C-locale floating
4202 point number.  This happens regardless of whether C<use locale> is
4203 in effect or not.
4204
4205 If Perl understands "quads" (64-bit integers) (this requires
4206 either that the platform natively supports quads or that Perl
4207 has been specifically compiled to support quads), the characters
4208
4209         d u o x X b i D U O
4210
4211 print quads, and they may optionally be preceded by
4212
4213         ll L q
4214
4215 For example
4216
4217         %lld %16LX %qo
4218
4219 You can find out whether your Perl supports quads via L<Config>:
4220
4221         use Config;
4222         ($Config{use64bits} eq 'define' || $Config{longsize} == 8) &&
4223                 print "quads\n";
4224
4225 If Perl understands "long doubles" (this requires that the platform
4226 supports long doubles), the flags
4227
4228         e f g E F G
4229
4230 may optionally be preceded by
4231
4232         ll L
4233
4234 For example
4235
4236         %llf %Lg
4237
4238 You can find out whether your Perl supports long doubles via L<Config>:
4239
4240         use Config;
4241         $Config{d_longdbl} eq 'define' && print "long doubles\n";
4242
4243 =item sqrt EXPR
4244
4245 =item sqrt
4246
4247 Return the square root of EXPR.  If EXPR is omitted, returns square
4248 root of C<$_>.  Only works on non-negative operands, unless you've
4249 loaded the standard Math::Complex module.
4250
4251     use Math::Complex;
4252     print sqrt(-2);    # prints 1.4142135623731i
4253
4254 =item srand EXPR
4255
4256 =item srand
4257
4258 Sets the random number seed for the C<rand> operator.  If EXPR is
4259 omitted, uses a semi-random value supplied by the kernel (if it supports
4260 the F</dev/urandom> device) or based on the current time and process
4261 ID, among other things.  In versions of Perl prior to 5.004 the default
4262 seed was just the current C<time>.  This isn't a particularly good seed,
4263 so many old programs supply their own seed value (often C<time ^ $$> or
4264 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
4265
4266 In fact, it's usually not necessary to call C<srand> at all, because if
4267 it is not called explicitly, it is called implicitly at the first use of
4268 the C<rand> operator.  However, this was not the case in version of Perl
4269 before 5.004, so if your script will run under older Perl versions, it
4270 should call C<srand>.
4271
4272 Note that you need something much more random than the default seed for
4273 cryptographic purposes.  Checksumming the compressed output of one or more
4274 rapidly changing operating system status programs is the usual method.  For
4275 example:
4276
4277     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
4278
4279 If you're particularly concerned with this, see the C<Math::TrulyRandom>
4280 module in CPAN.
4281
4282 Do I<not> call C<srand> multiple times in your program unless you know
4283 exactly what you're doing and why you're doing it.  The point of the
4284 function is to "seed" the C<rand> function so that C<rand> can produce
4285 a different sequence each time you run your program.  Just do it once at the
4286 top of your program, or you I<won't> get random numbers out of C<rand>!
4287
4288 Frequently called programs (like CGI scripts) that simply use
4289
4290     time ^ $$
4291
4292 for a seed can fall prey to the mathematical property that
4293
4294     a^b == (a+1)^(b+1)
4295
4296 one-third of the time.  So don't do that.
4297
4298 =item stat FILEHANDLE
4299
4300 =item stat EXPR
4301
4302 =item stat
4303
4304 Returns a 13-element list giving the status info for a file, either
4305 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
4306 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
4307 as follows:
4308
4309     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
4310        $atime,$mtime,$ctime,$blksize,$blocks)
4311            = stat($filename);
4312
4313 Not all fields are supported on all filesystem types.  Here are the
4314 meaning of the fields:
4315
4316   0 dev      device number of filesystem
4317   1 ino      inode number
4318   2 mode     file mode  (type and permissions)
4319   3 nlink    number of (hard) links to the file
4320   4 uid      numeric user ID of file's owner
4321   5 gid      numeric group ID of file's owner
4322   6 rdev     the device identifier (special files only)
4323   7 size     total size of file, in bytes
4324   8 atime    last access time since the epoch
4325   9 mtime    last modify time since the epoch
4326  10 ctime    inode change time (NOT creation time!) since the epoch
4327  11 blksize  preferred block size for file system I/O
4328  12 blocks   actual number of blocks allocated
4329
4330 (The epoch was at 00:00 January 1, 1970 GMT.)
4331
4332 If stat is passed the special filehandle consisting of an underline, no
4333 stat is done, but the current contents of the stat structure from the
4334 last stat or filetest are returned.  Example:
4335
4336     if (-x $file && (($d) = stat(_)) && $d < 0) {
4337         print "$file is executable NFS file\n";
4338     }
4339
4340 (This works on machines only for which the device number is negative under NFS.)
4341
4342 Because the mode contains both the file type and its permissions, you
4343 should mask off the file type portion and (s)printf using a C<"%o"> 
4344 if you want to see the real permissions.
4345
4346     $mode = (stat($filename))[2];
4347     printf "Permissions are %04o\n", $mode & 07777;
4348
4349 In scalar context, C<stat> returns a boolean value indicating success
4350 or failure, and, if successful, sets the information associated with
4351 the special filehandle C<_>.
4352
4353 The File::stat module provides a convenient, by-name access mechanism:
4354
4355     use File::stat;
4356     $sb = stat($filename);
4357     printf "File is %s, size is %s, perm %04o, mtime %s\n", 
4358         $filename, $sb->size, $sb->mode & 07777,
4359         scalar localtime $sb->mtime;
4360
4361 =item study SCALAR
4362
4363 =item study
4364
4365 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
4366 doing many pattern matches on the string before it is next modified.
4367 This may or may not save time, depending on the nature and number of
4368 patterns you are searching on, and on the distribution of character
4369 frequencies in the string to be searched--you probably want to compare
4370 run times with and without it to see which runs faster.  Those loops
4371 which scan for many short constant strings (including the constant
4372 parts of more complex patterns) will benefit most.  You may have only
4373 one C<study> active at a time--if you study a different scalar the first
4374 is "unstudied".  (The way C<study> works is this: a linked list of every
4375 character in the string to be searched is made, so we know, for
4376 example, where all the C<'k'> characters are.  From each search string,
4377 the rarest character is selected, based on some static frequency tables
4378 constructed from some C programs and English text.  Only those places
4379 that contain this "rarest" character are examined.)
4380
4381 For example, here is a loop that inserts index producing entries
4382 before any line containing a certain pattern:
4383
4384     while (<>) {
4385         study;
4386         print ".IX foo\n"       if /\bfoo\b/;
4387         print ".IX bar\n"       if /\bbar\b/;
4388         print ".IX blurfl\n"    if /\bblurfl\b/;
4389         # ...
4390         print;
4391     }
4392
4393 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<"f">
4394 will be looked at, because C<"f"> is rarer than C<"o">.  In general, this is
4395 a big win except in pathological cases.  The only question is whether
4396 it saves you more time than it took to build the linked list in the
4397 first place.
4398
4399 Note that if you have to look for strings that you don't know till
4400 runtime, you can build an entire loop as a string and C<eval> that to
4401 avoid recompiling all your patterns all the time.  Together with
4402 undefining C<$/> to input entire files as one record, this can be very
4403 fast, often faster than specialized programs like fgrep(1).  The following
4404 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
4405 out the names of those files that contain a match:
4406
4407     $search = 'while (<>) { study;';
4408     foreach $word (@words) {
4409         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
4410     }
4411     $search .= "}";
4412     @ARGV = @files;
4413     undef $/;
4414     eval $search;               # this screams
4415     $/ = "\n";          # put back to normal input delimiter
4416     foreach $file (sort keys(%seen)) {
4417         print $file, "\n";
4418     }
4419
4420 =item sub BLOCK
4421
4422 =item sub NAME
4423
4424 =item sub NAME BLOCK
4425
4426 This is subroutine definition, not a real function I<per se>.  With just a
4427 NAME (and possibly prototypes or attributes), it's just a forward declaration.
4428 Without a NAME, it's an anonymous function declaration, and does actually
4429 return a value: the CODE ref of the closure you just created.  See L<perlsub>
4430 and L<perlref> for details.
4431
4432 =item substr EXPR,OFFSET,LENGTH,REPLACEMENT
4433
4434 =item substr EXPR,OFFSET,LENGTH
4435
4436 =item substr EXPR,OFFSET
4437
4438 Extracts a substring out of EXPR and returns it.  First character is at
4439 offset C<0>, or whatever you've set C<$[> to (but don't do that).
4440 If OFFSET is negative (or more precisely, less than C<$[>), starts
4441 that far from the end of the string.  If LENGTH is omitted, returns
4442 everything to the end of the string.  If LENGTH is negative, leaves that
4443 many characters off the end of the string.
4444
4445 You can use the substr() function as an lvalue, in which case EXPR
4446 must itself be an lvalue.  If you assign something shorter than LENGTH,
4447 the string will shrink, and if you assign something longer than LENGTH,
4448 the string will grow to accommodate it.  To keep the string the same
4449 length you may need to pad or chop your value using C<sprintf>.
4450
4451 If OFFSET and LENGTH specify a substring that is partly outside the
4452 string, only the part within the string is returned.  If the substring
4453 is beyond either end of the string, substr() returns the undefined
4454 value and produces a warning.  When used as an lvalue, specifying a
4455 substring that is entirely outside the string is a fatal error.
4456 Here's an example showing the behavior for boundary cases:
4457
4458     my $name = 'fred';
4459     substr($name, 4) = 'dy';            # $name is now 'freddy'
4460     my $null = substr $name, 6, 2;      # returns '' (no warning)
4461     my $oops = substr $name, 7;         # returns undef, with warning
4462     substr($name, 7) = 'gap';           # fatal error
4463
4464 An alternative to using substr() as an lvalue is to specify the
4465 replacement string as the 4th argument.  This allows you to replace
4466 parts of the EXPR and return what was there before in one operation,
4467 just as you can with splice().
4468
4469 =item symlink OLDFILE,NEWFILE
4470
4471 Creates a new filename symbolically linked to the old filename.
4472 Returns C<1> for success, C<0> otherwise.  On systems that don't support
4473 symbolic links, produces a fatal error at run time.  To check for that,
4474 use eval:
4475
4476     $symlink_exists = eval { symlink("",""); 1 };
4477
4478 =item syscall LIST
4479
4480 Calls the system call specified as the first element of the list,
4481 passing the remaining elements as arguments to the system call.  If
4482 unimplemented, produces a fatal error.  The arguments are interpreted
4483 as follows: if a given argument is numeric, the argument is passed as
4484 an int.  If not, the pointer to the string value is passed.  You are
4485 responsible to make sure a string is pre-extended long enough to
4486 receive any result that might be written into a string.  You can't use a
4487 string literal (or other read-only string) as an argument to C<syscall>
4488 because Perl has to assume that any string pointer might be written
4489 through.  If your
4490 integer arguments are not literals and have never been interpreted in a
4491 numeric context, you may need to add C<0> to them to force them to look
4492 like numbers.  This emulates the C<syswrite> function (or vice versa):
4493
4494     require 'syscall.ph';               # may need to run h2ph
4495     $s = "hi there\n";
4496     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
4497
4498 Note that Perl supports passing of up to only 14 arguments to your system call,
4499 which in practice should usually suffice.
4500
4501 Syscall returns whatever value returned by the system call it calls.
4502 If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno).
4503 Note that some system calls can legitimately return C<-1>.  The proper
4504 way to handle such calls is to assign C<$!=0;> before the call and
4505 check the value of C<$!> if syscall returns C<-1>.
4506
4507 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
4508 number of the read end of the pipe it creates.  There is no way
4509 to retrieve the file number of the other end.  You can avoid this 
4510 problem by using C<pipe> instead.
4511
4512 =item sysopen FILEHANDLE,FILENAME,MODE
4513
4514 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
4515
4516 Opens the file whose filename is given by FILENAME, and associates it
4517 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
4518 the name of the real filehandle wanted.  This function calls the
4519 underlying operating system's C<open> function with the parameters
4520 FILENAME, MODE, PERMS.
4521
4522 The possible values and flag bits of the MODE parameter are
4523 system-dependent; they are available via the standard module C<Fcntl>.
4524 See the documentation of your operating system's C<open> to see which
4525 values and flag bits are available.  You may combine several flags
4526 using the C<|>-operator.
4527
4528 Some of the most common values are C<O_RDONLY> for opening the file in
4529 read-only mode, C<O_WRONLY> for opening the file in write-only mode,
4530 and C<O_RDWR> for opening the file in read-write mode, and.
4531
4532 For historical reasons, some values work on almost every system
4533 supported by perl: zero means read-only, one means write-only, and two
4534 means read/write.  We know that these values do I<not> work under
4535 OS/390 & VM/ESA Unix and on the Macintosh; you probably don't want to
4536 se them in new code, use thhe constants discussed in the preceding
4537 paragraph.
4538
4539 If the file named by FILENAME does not exist and the C<open> call creates
4540 it (typically because MODE includes the C<O_CREAT> flag), then the value of
4541 PERMS specifies the permissions of the newly created file.  If you omit
4542 the PERMS argument to C<sysopen>, Perl uses the octal value C<0666>.
4543 These permission values need to be in octal, and are modified by your
4544 process's current C<umask>.
4545
4546 In many systems the C<O_EXCL> flag is available for opening files in
4547 exclusive mode.  This is B<not> locking: exclusiveness means here that
4548 if the file already exists, sysopen() fails.  The C<O_EXCL> wins
4549 C<O_TRUNC>.
4550
4551 Sometimes you may want to truncate an already-existing file: C<O_TRUNC>.
4552
4553 You should seldom if ever use C<0644> as argument to C<sysopen>, because
4554 that takes away the user's option to have a more permissive umask.
4555 Better to omit it.  See the perlfunc(1) entry on C<umask> for more
4556 on this.
4557
4558 See L<perlopentut> for a kinder, gentler explanation of opening files.
4559
4560 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
4561
4562 =item sysread FILEHANDLE,SCALAR,LENGTH
4563
4564 Attempts to read LENGTH bytes of data into variable SCALAR from the
4565 specified FILEHANDLE, using the system call read(2).  It bypasses stdio,
4566 so mixing this with other kinds of reads, C<print>, C<write>,
4567 C<seek>, C<tell>, or C<eof> can cause confusion because stdio
4568 usually buffers data.  Returns the number of bytes actually read, C<0>
4569 at end of file, or undef if there was an error.  SCALAR will be grown or
4570 shrunk so that the last byte actually read is the last byte of the
4571 scalar after the read.
4572
4573 An OFFSET may be specified to place the read data at some place in the
4574 string other than the beginning.  A negative OFFSET specifies
4575 placement at that many bytes counting backwards from the end of the
4576 string.  A positive OFFSET greater than the length of SCALAR results
4577 in the string being padded to the required size with C<"\0"> bytes before
4578 the result of the read is appended.
4579
4580 There is no syseof() function, which is ok, since eof() doesn't work
4581 very well on device files (like ttys) anyway.  Use sysread() and check
4582 for a return value for 0 to decide whether you're done.
4583
4584 =item sysseek FILEHANDLE,POSITION,WHENCE
4585
4586 Sets FILEHANDLE's system position using the system call lseek(2).  It
4587 bypasses stdio, so mixing this with reads (other than C<sysread>),
4588 C<print>, C<write>, C<seek>, C<tell>, or C<eof> may cause confusion.
4589 FILEHANDLE may be an expression whose value gives the name of the
4590 filehandle.  The values for WHENCE are C<0> to set the new position to
4591 POSITION, C<1> to set the it to the current position plus POSITION,
4592 and C<2> to set it to EOF plus POSITION (typically negative).  For
4593 WHENCE, you may also use the constants C<SEEK_SET>, C<SEEK_CUR>, and
4594 C<SEEK_END> (start of the file, current position, end of the file)
4595 from any of the modules Fcntl, C<IO::Seekable>, or POSIX.
4596
4597 Returns the new position, or the undefined value on failure.  A position
4598 of zero is returned as the string C<"0 but true">; thus C<sysseek> returns
4599 true on success and false on failure, yet you can still easily determine
4600 the new position.
4601
4602 =item system LIST
4603
4604 =item system PROGRAM LIST
4605
4606 Does exactly the same thing as C<exec LIST>, except that a fork is
4607 done first, and the parent process waits for the child process to
4608 complete.  Note that argument processing varies depending on the
4609 number of arguments.  If there is more than one argument in LIST,
4610 or if LIST is an array with more than one value, starts the program
4611 given by the first element of the list with arguments given by the
4612 rest of the list.  If there is only one scalar argument, the argument
4613 is checked for shell metacharacters, and if there are any, the
4614 entire argument is passed to the system's command shell for parsing
4615 (this is C</bin/sh -c> on Unix platforms, but varies on other
4616 platforms).  If there are no shell metacharacters in the argument,
4617 it is split into words and passed directly to C<execvp>, which is
4618 more efficient.
4619
4620 All files opened for output are flushed before attempting the exec().
4621
4622 The return value is the exit status of the program as
4623 returned by the C<wait> call.  To get the actual exit value divide by
4624 256.  See also L</exec>.  This is I<not> what you want to use to capture
4625 the output from a command, for that you should use merely backticks or
4626 C<qx//>, as described in L<perlop/"`STRING`">.  Return value of -1
4627 indicates a failure to start the program (inspect $! for the reason).
4628
4629 Like C<exec>, C<system> allows you to lie to a program about its name if
4630 you use the C<system PROGRAM LIST> syntax.  Again, see L</exec>.
4631
4632 Because C<system> and backticks block C<SIGINT> and C<SIGQUIT>, killing the
4633 program they're running doesn't actually interrupt your program.
4634
4635     @args = ("command", "arg1", "arg2");
4636     system(@args) == 0
4637          or die "system @args failed: $?"
4638
4639 You can check all the failure possibilities by inspecting
4640 C<$?> like this:
4641
4642     $exit_value  = $? >> 8;
4643     $signal_num  = $? & 127;
4644     $dumped_core = $? & 128;
4645
4646 When the arguments get executed via the system shell, results
4647 and return codes will be subject to its quirks and capabilities.
4648 See L<perlop/"`STRING`"> and L</exec> for details.
4649
4650 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
4651
4652 =item syswrite FILEHANDLE,SCALAR,LENGTH
4653
4654 =item syswrite FILEHANDLE,SCALAR
4655
4656 Attempts to write LENGTH bytes of data from variable SCALAR to the
4657 specified FILEHANDLE, using the system call write(2).  If LENGTH