This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
b1c7ae05b82c3a3c5d1af7d138959bedc55d56da
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr; { no overloading; $addr = 0+$self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted this change.)
17
18 require 5.010_001;
19 use strict;
20 use warnings;
21 use Carp;
22 use File::Find;
23 use File::Path;
24 use File::Spec;
25 use Text::Tabs;
26
27 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
28
29 ##########################################################################
30 #
31 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
32 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
33 # a pod file and a .t file
34 #
35 # The structure of this file is:
36 #   First these introductory comments; then
37 #   code needed for everywhere, such as debugging stuff; then
38 #   code to handle input parameters; then
39 #   data structures likely to be of external interest (some of which depend on
40 #       the input parameters, so follows them; then
41 #   more data structures and subroutine and package (class) definitions; then
42 #   the small actual loop to process the input files and finish up; then
43 #   a __DATA__ section, for the .t tests
44 #
45 # This program works on all releases of Unicode through at least 5.2.  The
46 # outputs have been scrutinized most intently for release 5.1.  The others
47 # have been checked for somewhat more than just sanity.  It can handle all
48 # existing Unicode character properties in those releases.
49 #
50 # This program is mostly about Unicode character (or code point) properties.
51 # A property describes some attribute or quality of a code point, like if it
52 # is lowercase or not, its name, what version of Unicode it was first defined
53 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
54 # possibilities by making all properties into mappings from each code point
55 # into some corresponding value.  In the case of it being lowercase or not,
56 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
57 # property maps each Unicode code point to a single value, called a "property
58 # value".  (Hence each Unicode property is a true mathematical function with
59 # exactly one value per code point.)
60 #
61 # When using a property in a regular expression, what is desired isn't the
62 # mapping of the code point to its property's value, but the reverse (or the
63 # mathematical "inverse relation"): starting with the property value, "Does a
64 # code point map to it?"  These are written in a "compound" form:
65 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
66 # files containing the lists of code points that map to each such regular
67 # expression property value, one file per list
68 #
69 # There is also a single form shortcut that Perl adds for many of the commonly
70 # used properties.  This happens for all binary properties, plus script,
71 # general_category, and block properties.
72 #
73 # Thus the outputs of this program are files.  There are map files, mostly in
74 # the 'To' directory; and there are list files for use in regular expression
75 # matching, all in subdirectories of the 'lib' directory, with each
76 # subdirectory being named for the property that the lists in it are for.
77 # Bookkeeping, test, and documentation files are also generated.
78
79 my $matches_directory = 'lib';   # Where match (\p{}) files go.
80 my $map_directory = 'To';        # Where map files go.
81
82 # DATA STRUCTURES
83 #
84 # The major data structures of this program are Property, of course, but also
85 # Table.  There are two kinds of tables, very similar to each other.
86 # "Match_Table" is the data structure giving the list of code points that have
87 # a particular property value, mentioned above.  There is also a "Map_Table"
88 # data structure which gives the property's mapping from code point to value.
89 # There are two structures because the match tables need to be combined in
90 # various ways, such as constructing unions, intersections, complements, etc.,
91 # and the map ones don't.  And there would be problems, perhaps subtle, if
92 # a map table were inadvertently operated on in some of those ways.
93 # The use of separate classes with operations defined on one but not the other
94 # prevents accidentally confusing the two.
95 #
96 # At the heart of each table's data structure is a "Range_List", which is just
97 # an ordered list of "Ranges", plus ancillary information, and methods to
98 # operate on them.  A Range is a compact way to store property information.
99 # Each range has a starting code point, an ending code point, and a value that
100 # is meant to apply to all the code points between the two end points,
101 # inclusive.  For a map table, this value is the property value for those
102 # code points.  Two such ranges could be written like this:
103 #   0x41 .. 0x5A, 'Upper',
104 #   0x61 .. 0x7A, 'Lower'
105 #
106 # Each range also has a type used as a convenience to classify the values.
107 # Most ranges in this program will be Type 0, or normal, but there are some
108 # ranges that have a non-zero type.  These are used only in map tables, and
109 # are for mappings that don't fit into the normal scheme of things.  Mappings
110 # that require a hash entry to communicate with utf8.c are one example;
111 # another example is mappings for charnames.pm to use which indicate a name
112 # that is algorithmically determinable from its code point (and vice-versa).
113 # These are used to significantly compact these tables, instead of listing
114 # each one of the tens of thousands individually.
115 #
116 # In a match table, the value of a range is irrelevant (and hence the type as
117 # well, which will always be 0), and arbitrarily set to the null string.
118 # Using the example above, there would be two match tables for those two
119 # entries, one named Upper would contain the 0x41..0x5A range, and the other
120 # named Lower would contain 0x61..0x7A.
121 #
122 # Actually, there are two types of range lists, "Range_Map" is the one
123 # associated with map tables, and "Range_List" with match tables.
124 # Again, this is so that methods can be defined on one and not the other so as
125 # to prevent operating on them in incorrect ways.
126 #
127 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
128 # in the perl core.  All tables could in theory be written, but some are
129 # suppressed because there is no current practical use for them.  It is easy
130 # to change which get written by changing various lists that are near the top
131 # of the actual code in this file.  The table data structures contain enough
132 # ancillary information to allow them to be treated as separate entities for
133 # writing, such as the path to each one's file.  There is a heading in each
134 # map table that gives the format of its entries, and what the map is for all
135 # the code points missing from it.  (This allows tables to be more compact.)
136 #
137 # The Property data structure contains one or more tables.  All properties
138 # contain a map table (except the $perl property which is a
139 # pseudo-property containing only match tables), and any properties that
140 # are usable in regular expression matches also contain various matching
141 # tables, one for each value the property can have.  A binary property can
142 # have two values, True and False (or Y and N, which are preferred by Unicode
143 # terminology).  Thus each of these properties will have a map table that
144 # takes every code point and maps it to Y or N (but having ranges cuts the
145 # number of entries in that table way down), and two match tables, one
146 # which has a list of all the code points that map to Y, and one for all the
147 # code points that map to N.  (For each of these, a third table is also
148 # generated for the pseudo Perl property.  It contains the identical code
149 # points as the Y table, but can be written, not in the compound form, but in
150 # a "single" form like \p{IsUppercase}.)  Many properties are binary, but some
151 # properties have several possible values, some have many, and properties like
152 # Name have a different value for every named code point.  Those will not,
153 # unless the controlling lists are changed, have their match tables written
154 # out.  But all the ones which can be used in regular expression \p{} and \P{}
155 # constructs will.  Generally a property will have either its map table or its
156 # match tables written but not both.  Again, what gets written is controlled
157 # by lists which can easily be changed.
158 #
159 # For information about the Unicode properties, see Unicode's UAX44 document:
160
161 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
162
163 # As stated earlier, this program will work on any release of Unicode so far.
164 # Most obvious problems in earlier data have NOT been corrected except when
165 # necessary to make Perl or this program work reasonably.  For example, no
166 # folding information was given in early releases, so this program uses the
167 # substitute of lower case, just so that a regular expression with the /i
168 # option will do something that actually gives the right results in many
169 # cases.  There are also a couple other corrections for version 1.1.5,
170 # commented at the point they are made.  As an example of corrections that
171 # weren't made (but could be) is this statement from DerivedAge.txt: "The
172 # supplementary private use code points and the non-character code points were
173 # assigned in version 2.0, but not specifically listed in the UCD until
174 # versions 3.0 and 3.1 respectively."  (To be precise it was 3.0.1 not 3.0.0)
175 # More information on Unicode version glitches is further down in these
176 # introductory comments.
177 #
178 # This program works on all properties as of 5.2, though the files for some
179 # are suppressed from apparent lack of demand for them.  You can change which
180 # are output by changing lists in this program.
181 #
182 # The old version of mktables emphasized the term "Fuzzy" to mean Unocde's
183 # loose matchings rules (from Unicode TR18):
184 #
185 #    The recommended names for UCD properties and property values are in
186 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
187 #    [PropValue]. There are both abbreviated names and longer, more
188 #    descriptive names. It is strongly recommended that both names be
189 #    recognized, and that loose matching of property names be used,
190 #    whereby the case distinctions, whitespace, hyphens, and underbar
191 #    are ignored.
192 # The program still allows Fuzzy to override its determination of if loose
193 # matching should be used, but it isn't currently used, as it is no longer
194 # needed; the calculations it makes are good enough.
195 #
196 # SUMMARY OF HOW IT WORKS:
197 #
198 #   Process arguments
199 #
200 #   A list is constructed containing each input file that is to be processed
201 #
202 #   Each file on the list is processed in a loop, using the associated handler
203 #   code for each:
204 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
205 #            first.  These files name the properties and property values.
206 #            Objects are created of all the property and property value names
207 #            that the rest of the input should expect, including all synonyms.
208 #        The other input files give mappings from properties to property
209 #           values.  That is, they list code points and say what the mapping
210 #           is under the given property.  Some files give the mappings for
211 #           just one property; and some for many.  This program goes through
212 #           each file and populates the properties from them.  Some properties
213 #           are listed in more than one file, and Unicode has set up a
214 #           precedence as to which has priority if there is a conflict.  Thus
215 #           the order of processing matters, and this program handles the
216 #           conflict possibility by processing the overriding input files
217 #           last, so that if necessary they replace earlier values.
218 #        After this is all done, the program creates the property mappings not
219 #            furnished by Unicode, but derivable from what it does give.
220 #        The tables of code points that match each property value in each
221 #            property that is accessible by regular expressions are created.
222 #        The Perl-defined properties are created and populated.  Many of these
223 #            require data determined from the earlier steps
224 #        Any Perl-defined synonyms are created, and name clashes between Perl
225 #            and Unicode are reconciled and warned about.
226 #        All the properties are written to files
227 #        Any other files are written, and final warnings issued.
228 #
229 # For clarity, a number of operators have been overloaded to work on tables:
230 #   ~ means invert (take all characters not in the set).  The more
231 #       conventional '!' is not used because of the possibility of confusing
232 #       it with the actual boolean operation.
233 #   + means union
234 #   - means subtraction
235 #   & means intersection
236 # The precedence of these is the order listed.  Parentheses should be
237 # copiously used.  These are not a general scheme.  The operations aren't
238 # defined for a number of things, deliberately, to avoid getting into trouble.
239 # Operations are done on references and affect the underlying structures, so
240 # that the copy constructors for them have been overloaded to not return a new
241 # clone, but the input object itself.
242 #
243 # The bool operator is deliberately not overloaded to avoid confusion with
244 # "should it mean if the object merely exists, or also is non-empty?".
245 #
246 # WHY CERTAIN DESIGN DECISIONS WERE MADE
247 #
248 # This program needs to be able to run under miniperl.  Therefore, it uses a
249 # minimum of other modules, and hence implements some things itself that could
250 # be gotten from CPAN
251 #
252 # This program uses inputs published by the Unicode Consortium.  These can
253 # change incompatibly between releases without the Perl maintainers realizing
254 # it.  Therefore this program is now designed to try to flag these.  It looks
255 # at the directories where the inputs are, and flags any unrecognized files.
256 # It keeps track of all the properties in the files it handles, and flags any
257 # that it doesn't know how to handle.  It also flags any input lines that
258 # don't match the expected syntax, among other checks.
259 #
260 # It is also designed so if a new input file matches one of the known
261 # templates, one hopefully just needs to add it to a list to have it
262 # processed.
263 #
264 # As mentioned earlier, some properties are given in more than one file.  In
265 # particular, the files in the extracted directory are supposedly just
266 # reformattings of the others.  But they contain information not easily
267 # derivable from the other files, including results for Unihan, which this
268 # program doesn't ordinarily look at, and for unassigned code points.  They
269 # also have historically had errors or been incomplete.  In an attempt to
270 # create the best possible data, this program thus processes them first to
271 # glean information missing from the other files; then processes those other
272 # files to override any errors in the extracted ones.  Much of the design was
273 # driven by this need to store things and then possibly override them.
274 #
275 # It tries to keep fatal errors to a minimum, to generate something usable for
276 # testing purposes.  It always looks for files that could be inputs, and will
277 # warn about any that it doesn't know how to handle (the -q option suppresses
278 # the warning).
279 #
280 # Why have files written out for binary 'N' matches?
281 #   For binary properties, if you know the mapping for either Y or N; the
282 #   other is trivial to construct, so could be done at Perl run-time by just
283 #   complementing the result, instead of having a file for it.  That is, if
284 #   someone types in \p{foo: N}, Perl could translate that to \P{foo: Y} and
285 #   not need a file.   The problem is communicating to Perl that a given
286 #   property is binary.  Perl can't figure it out from looking at the N (or
287 #   No), as some non-binary properties have these as property values.  So
288 #   rather than inventing a way to communicate this info back to the core,
289 #   which would have required changes there as well, it was simpler just to
290 #   add the extra tables.
291 #
292 # Why is there more than one type of range?
293 #   This simplified things.  There are some very specialized code points that
294 #   have to be handled specially for output, such as Hangul syllable names.
295 #   By creating a range type (done late in the development process), it
296 #   allowed this to be stored with the range, and overridden by other input.
297 #   Originally these were stored in another data structure, and it became a
298 #   mess trying to decide if a second file that was for the same property was
299 #   overriding the earlier one or not.
300 #
301 # Why are there two kinds of tables, match and map?
302 #   (And there is a base class shared by the two as well.)  As stated above,
303 #   they actually are for different things.  Development proceeded much more
304 #   smoothly when I (khw) realized the distinction.  Map tables are used to
305 #   give the property value for every code point (actually every code point
306 #   that doesn't map to a default value).  Match tables are used for regular
307 #   expression matches, and are essentially the inverse mapping.  Separating
308 #   the two allows more specialized methods, and error checks so that one
309 #   can't just take the intersection of two map tables, for example, as that
310 #   is nonsensical.
311 #
312 # There are no match tables generated for matches of the null string.  These
313 # would like like qr/\p{JSN=}/ currently without modifying the regex code.
314 # Perhaps something like them could be added if necessary.  The JSN does have
315 # a real code point U+110B that maps to the null string, but it is a
316 # contributory property, and therefore not output by default.  And it's easily
317 # handled so far by making the null string the default where it is a
318 # possibility.
319 #
320 # DEBUGGING
321 #
322 # This program is written so it will run under miniperl.  Occasionally changes
323 # will cause an error where the backtrace doesn't work well under miniperl.
324 # To diagnose the problem, you can instead run it under regular perl, if you
325 # have one compiled.
326 #
327 # There is a good trace facility.  To enable it, first sub DEBUG must be set
328 # to return true.  Then a line like
329 #
330 # local $to_trace = 1 if main::DEBUG;
331 #
332 # can be added to enable tracing in its lexical scope or until you insert
333 # another line:
334 #
335 # local $to_trace = 0 if main::DEBUG;
336 #
337 # then use a line like "trace $a, @b, %c, ...;
338 #
339 # Some of the more complex subroutines already have trace statements in them.
340 # Permanent trace statements should be like:
341 #
342 # trace ... if main::DEBUG && $to_trace;
343 #
344 # If there is just one or a few files that you're debugging, you can easily
345 # cause most everything else to be skipped.  Change the line
346 #
347 # my $debug_skip = 0;
348 #
349 # to 1, and every file whose object is in @input_file_objects and doesn't have
350 # a, 'non_skip => 1,' in its constructor will be skipped.
351 #
352 # FUTURE ISSUES
353 #
354 # The program would break if Unicode were to change its names so that
355 # interior white space, underscores, or dashes differences were significant
356 # within property and property value names.
357 #
358 # It might be easier to use the xml versions of the UCD if this program ever
359 # would need heavy revision, and the ability to handle old versions was not
360 # required.
361 #
362 # There is the potential for name collisions, in that Perl has chosen names
363 # that Unicode could decide it also likes.  There have been such collisions in
364 # the past, with mostly Perl deciding to adopt the Unicode definition of the
365 # name.  However in the 5.2 Unicode beta testing, there were a number of such
366 # collisions, which were withdrawn before the final release, because of Perl's
367 # and other's protests.  These all involved new properties which began with
368 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
369 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
370 # Unicode document, so they are unlikely to be used by Unicode for another
371 # purpose.  However, they might try something beginning with 'In', or use any
372 # of the other Perl-defined properties.  This program will warn you of name
373 # collisions, and refuse to generate tables with them, but manual intervention
374 # will be required in this event.  One scheme that could be implemented, if
375 # necessary, would be to have this program generate another file, or add a
376 # field to mktables.lst that gives the date of first definition of a property.
377 # Each new release of Unicode would use that file as a basis for the next
378 # iteration.  And the Perl synonym addition code could sort based on the age
379 # of the property, so older properties get priority, and newer ones that clash
380 # would be refused; hence existing code would not be impacted, and some other
381 # synonym would have to be used for the new property.  This is ugly, and
382 # manual intervention would certainly be easier to do in the short run; lets
383 # hope it never comes to this.
384 #
385 # A NOTE ON UNIHAN
386 #
387 # This program can generate tables from the Unihan database.  But it doesn't
388 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
389 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
390 # database was split into 8 different files, all beginning with the letters
391 # 'Unihan'.  This program will read those file(s) if present, but it needs to
392 # know which of the many properties in the file(s) should have tables created
393 # for them.  It will create tables for any properties listed in
394 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
395 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
396 # property you want is not in those files of the release you are building
397 # against, you must add it to those two arrays.  Starting in 4.0, the
398 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
399 # is present in the directory, a table will be generated for that property.
400 # In 5.2, several more properties were added.  For your convenience, the two
401 # arrays are initialized with all the 5.2 listed properties that are also in
402 # earlier releases.  But these are commented out.  You can just uncomment the
403 # ones you want, or use them as a template for adding entries for other
404 # properties.
405 #
406 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
407 # and filter_unihan_line() are the functions where this is done.  This program
408 # already does some adjusting to make the lines look more like the rest of the
409 # Unicode DB;  You can see what that is in filter_unihan_line()
410 #
411 # There is a bug in the 3.2 data file in which some values for the
412 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
413 # could be added for these; or for a particular installation, the Unihan.txt
414 # file could be edited to fix them.
415 # have to be
416 #
417 # HOW TO ADD A FILE TO BE PROCESSED
418 #
419 # A new file from Unicode needs to have an object constructed for it in
420 # @input_file_objects, probably at the end or at the end of the extracted
421 # ones.  The program should warn you if its name will clash with others on
422 # restrictive file systems, like DOS.  If so, figure out a better name, and
423 # add lines to the README.perl file giving that.  If the file is a character
424 # property, it should be in the format that Unicode has by default
425 # standardized for such files for the more recently introduced ones.
426 # If so, the Input_file constructor for @input_file_objects can just be the
427 # file name and release it first appeared in.  If not, then it should be
428 # possible to construct an each_line_handler() to massage the line into the
429 # standardized form.
430 #
431 # For non-character properties, more code will be needed.  You can look at
432 # the existing entries for clues.
433 #
434 # UNICODE VERSIONS NOTES
435 #
436 # The Unicode UCD has had a number of errors in it over the versions.  And
437 # these remain, by policy, in the standard for that version.  Therefore it is
438 # risky to correct them, because code may be expecting the error.  So this
439 # program doesn't generally make changes, unless the error breaks the Perl
440 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
441 # for U+1105, which causes real problems for the algorithms for Jamo
442 # calculations, so it is changed here.
443 #
444 # But it isn't so clear cut as to what to do about concepts that are
445 # introduced in a later release; should they extend back to earlier releases
446 # where the concept just didn't exist?  It was easier to do this than to not,
447 # so that's what was done.  For example, the default value for code points not
448 # in the files for various properties was probably undefined until changed by
449 # some version.  No_Block for blocks is such an example.  This program will
450 # assign No_Block even in Unicode versions that didn't have it.  This has the
451 # benefit that code being written doesn't have to special case earlier
452 # versions; and the detriment that it doesn't match the Standard precisely for
453 # the affected versions.
454 #
455 # Here are some observations about some of the issues in early versions:
456 #
457 # The number of code points in \p{alpha} halve in 2.1.9.  It turns out that
458 # the reason is that the CJK block starting at 4E00 was removed from PropList,
459 # and was not put back in until 3.1.0
460 #
461 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
462 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
463 # reason is that 3.2 introduced U+205F=medium math space, which was not
464 # classed as white space, but Perl figured out that it should have been. 4.0
465 # reclassified it correctly.
466 #
467 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
468 # this was erroneously a synonym for 202.  In 4.0, ATB became 202, and ATBL
469 # was left with no code points, as all the ones that mapped to 202 stayed
470 # mapped to 202.  Thus if your program used the numeric name for the class,
471 # it would not have been affected, but if it used the mnemonic, it would have
472 # been.
473 #
474 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
475 # points which eventually came to have this script property value, instead
476 # mapped to "Unknown".  But in the next release all these code points were
477 # moved to \p{sc=common} instead.
478 #
479 # The default for missing code points for BidiClass is complicated.  Starting
480 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
481 # tries to do the best it can for earlier releases.  It is done in
482 # process_PropertyAliases()
483 #
484 ##############################################################################
485
486 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
487                         # and errors
488 my $MAX_LINE_WIDTH = 78;
489
490 # Debugging aid to skip most files so as to not be distracted by them when
491 # concentrating on the ones being debugged.  Add
492 # non_skip => 1,
493 # to the constructor for those files you want processed when you set this.
494 # Files with a first version number of 0 are special: they are always
495 # processed regardless of the state of this flag.
496 my $debug_skip = 0;
497
498 # Set to 1 to enable tracing.
499 our $to_trace = 0;
500
501 { # Closure for trace: debugging aid
502     my $print_caller = 1;        # ? Include calling subroutine name
503     my $main_with_colon = 'main::';
504     my $main_colon_length = length($main_with_colon);
505
506     sub trace {
507         return unless $to_trace;        # Do nothing if global flag not set
508
509         my @input = @_;
510
511         local $DB::trace = 0;
512         $DB::trace = 0;          # Quiet 'used only once' message
513
514         my $line_number;
515
516         # Loop looking up the stack to get the first non-trace caller
517         my $caller_line;
518         my $caller_name;
519         my $i = 0;
520         do {
521             $line_number = $caller_line;
522             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
523             $caller = $main_with_colon unless defined $caller;
524
525             $caller_name = $caller;
526
527             # get rid of pkg
528             $caller_name =~ s/.*:://;
529             if (substr($caller_name, 0, $main_colon_length)
530                 eq $main_with_colon)
531             {
532                 $caller_name = substr($caller_name, $main_colon_length);
533             }
534
535         } until ($caller_name ne 'trace');
536
537         # If the stack was empty, we were called from the top level
538         $caller_name = 'main' if ($caller_name eq ""
539                                     || $caller_name eq 'trace');
540
541         my $output = "";
542         foreach my $string (@input) {
543             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
544             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
545                 $output .= simple_dumper($string);
546             }
547             else {
548                 $string = "$string" if ref $string;
549                 $string = $UNDEF unless defined $string;
550                 chomp $string;
551                 $string = '""' if $string eq "";
552                 $output .= " " if $output ne ""
553                                 && $string ne ""
554                                 && substr($output, -1, 1) ne " "
555                                 && substr($string, 0, 1) ne " ";
556                 $output .= $string;
557             }
558         }
559
560         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
561         print STDERR "$caller_name: " if $print_caller;
562         print STDERR $output, "\n";
563         return;
564     }
565 }
566
567 # This is for a rarely used development feature that allows you to compare two
568 # versions of the Unicode standard without having to deal with changes caused
569 # by the code points introduced in the later verson.  Change the 0 to a SINGLE
570 # dotted Unicode release number (e.g. 2.1).  Only code points introduced in
571 # that release and earlier will be used; later ones are thrown away.  You use
572 # the version number of the earliest one you want to compare; then run this
573 # program on directory structures containing each release, and compare the
574 # outputs.  These outputs will therefore include only the code points common
575 # to both releases, and you can see the changes caused just by the underlying
576 # release semantic changes.  For versions earlier than 3.2, you must copy a
577 # version of DAge.txt into the directory.
578 my $string_compare_versions = DEBUG && 0; #  e.g., v2.1;
579 my $compare_versions = DEBUG
580                        && $string_compare_versions
581                        && pack "C*", split /\./, $string_compare_versions;
582
583 sub uniques {
584     # Returns non-duplicated input values.  From "Perl Best Practices:
585     # Encapsulated Cleverness".  p. 455 in first edition.
586
587     my %seen;
588     return grep { ! $seen{$_}++ } @_;
589 }
590
591 $0 = File::Spec->canonpath($0);
592
593 my $make_test_script = 0;      # ? Should we output a test script
594 my $write_unchanged_files = 0; # ? Should we update the output files even if
595                                #    we don't think they have changed
596 my $use_directory = "";        # ? Should we chdir somewhere.
597 my $pod_directory;             # input directory to store the pod file.
598 my $pod_file = 'perluniprops';
599 my $t_path;                     # Path to the .t test file
600 my $file_list = 'mktables.lst'; # File to store input and output file names.
601                                # This is used to speed up the build, by not
602                                # executing the main body of the program if
603                                # nothing on the list has changed since the
604                                # previous build
605 my $make_list = 1;             # ? Should we write $file_list.  Set to always
606                                # make a list so that when the pumpking is
607                                # preparing a release, s/he won't have to do
608                                # special things
609 my $glob_list = 0;             # ? Should we try to include unknown .txt files
610                                # in the input.
611 my $output_range_counts = 1;   # ? Should we include the number of code points
612                                # in ranges in the output
613 # Verbosity levels; 0 is quiet
614 my $NORMAL_VERBOSITY = 1;
615 my $PROGRESS = 2;
616 my $VERBOSE = 3;
617
618 my $verbosity = $NORMAL_VERBOSITY;
619
620 # Process arguments
621 while (@ARGV) {
622     my $arg = shift @ARGV;
623     if ($arg eq '-v') {
624         $verbosity = $VERBOSE;
625     }
626     elsif ($arg eq '-p') {
627         $verbosity = $PROGRESS;
628         $| = 1;     # Flush buffers as we go.
629     }
630     elsif ($arg eq '-q') {
631         $verbosity = 0;
632     }
633     elsif ($arg eq '-w') {
634         $write_unchanged_files = 1; # update the files even if havent changed
635     }
636     elsif ($arg eq '-check') {
637         my $this = shift @ARGV;
638         my $ok = shift @ARGV;
639         if ($this ne $ok) {
640             print "Skipping as check params are not the same.\n";
641             exit(0);
642         }
643     }
644     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
645         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
646     }
647     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
648     {
649         $make_test_script = 1;
650     }
651     elsif ($arg eq '-makelist') {
652         $make_list = 1;
653     }
654     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
655         -d $use_directory or croak "Unknown directory '$use_directory'";
656     }
657     elsif ($arg eq '-L') {
658
659         # Existence not tested until have chdir'd
660         $file_list = shift;
661     }
662     elsif ($arg eq '-globlist') {
663         $glob_list = 1;
664     }
665     elsif ($arg eq '-c') {
666         $output_range_counts = ! $output_range_counts
667     }
668     else {
669         my $with_c = 'with';
670         $with_c .= 'out' if $output_range_counts;   # Complements the state
671         croak <<END;
672 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
673           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
674           [-check A B ]
675   -c          : Output comments $with_c number of code points in ranges
676   -q          : Quiet Mode: Only output serious warnings.
677   -p          : Set verbosity level to normal plus show progress.
678   -v          : Set Verbosity level high:  Show progress and non-serious
679                 warnings
680   -w          : Write files regardless
681   -C dir      : Change to this directory before proceeding. All relative paths
682                 except those specified by the -P and -T options will be done
683                 with respect to this directory.
684   -P dir      : Output $pod_file file to directory 'dir'.
685   -T path     : Create a test script as 'path'; overrides -maketest
686   -L filelist : Use alternate 'filelist' instead of standard one
687   -globlist   : Take as input all non-Test *.txt files in current and sub
688                 directories
689   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
690                 overrides -T
691   -makelist   : Rewrite the file list $file_list based on current setup
692   -check A B  : Executes $0 only if A and B are the same
693 END
694     }
695 }
696
697 # Stores the most-recently changed file.  If none have changed, can skip the
698 # build
699 my $youngest = -M $0;   # Do this before the chdir!
700
701 # Change directories now, because need to read 'version' early.
702 if ($use_directory) {
703     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
704         $pod_directory = File::Spec->rel2abs($pod_directory);
705     }
706     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
707         $t_path = File::Spec->rel2abs($t_path);
708     }
709     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
710     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
711         $pod_directory = File::Spec->abs2rel($pod_directory);
712     }
713     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
714         $t_path = File::Spec->abs2rel($t_path);
715     }
716 }
717
718 # Get Unicode version into regular and v-string.  This is done now because
719 # various tables below get populated based on it.  These tables are populated
720 # here to be near the top of the file, and so easily seeable by those needing
721 # to modify things.
722 open my $VERSION, "<", "version"
723                     or croak "$0: can't open required file 'version': $!\n";
724 my $string_version = <$VERSION>;
725 close $VERSION;
726 chomp $string_version;
727 my $v_version = pack "C*", split /\./, $string_version;        # v string
728
729 # The following are the complete names of properties with property values that
730 # are known to not match any code points in some versions of Unicode, but that
731 # may change in the future so they should be matchable, hence an empty file is
732 # generated for them.
733 my @tables_that_may_be_empty = (
734                                 'Joining_Type=Left_Joining',
735                                 );
736 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
737 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
738 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
739                                                     if $v_version ge v4.1.0;
740
741 # The lists below are hashes, so the key is the item in the list, and the
742 # value is the reason why it is in the list.  This makes generation of
743 # documentation easier.
744
745 my %why_suppressed;  # No file generated for these.
746
747 # Files aren't generated for empty extraneous properties.  This is arguable.
748 # Extraneous properties generally come about because a property is no longer
749 # used in a newer version of Unicode.  If we generated a file without code
750 # points, programs that used to work on that property will still execute
751 # without errors.  It just won't ever match (or will always match, with \P{}).
752 # This means that the logic is now likely wrong.  I (khw) think its better to
753 # find this out by getting an error message.  Just move them to the table
754 # above to change this behavior
755 my %why_suppress_if_empty_warn_if_not = (
756
757    # It is the only property that has ever officially been removed from the
758    # Standard.  The database never contained any code points for it.
759    'Special_Case_Condition' => 'Obsolete',
760
761    # Apparently never official, but there were code points in some versions of
762    # old-style PropList.txt
763    'Non_Break' => 'Obsolete',
764 );
765
766 # These would normally go in the warn table just above, but they were changed
767 # a long time before this program was written, so warnings about them are
768 # moot.
769 if ($v_version gt v3.2.0) {
770     push @tables_that_may_be_empty,
771                                 'Canonical_Combining_Class=Attached_Below_Left'
772 }
773
774 # These are listed in the Property aliases file in 5.2, but Unihan is ignored
775 # unless explicitly added.
776 if ($v_version ge v5.2.0) {
777     my $unihan = 'Unihan; remove from list if using Unihan';
778     foreach my $table qw (
779                            kAccountingNumeric
780                            kOtherNumeric
781                            kPrimaryNumeric
782                            kCompatibilityVariant
783                            kIICore
784                            kIRG_GSource
785                            kIRG_HSource
786                            kIRG_JSource
787                            kIRG_KPSource
788                            kIRG_MSource
789                            kIRG_KSource
790                            kIRG_TSource
791                            kIRG_USource
792                            kIRG_VSource
793                            kRSUnicode
794                         )
795     {
796         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
797     }
798 }
799
800 # Properties that this program ignores.
801 my @unimplemented_properties = (
802 'Unicode_Radical_Stroke'    # Remove if changing to handle this one.
803 );
804
805 # There are several types of obsolete properties defined by Unicode.  These
806 # must be hand-edited for every new Unicode release.
807 my %why_deprecated;  # Generates a deprecated warning message if used.
808 my %why_stabilized;  # Documentation only
809 my %why_obsolete;    # Documentation only
810
811 {   # Closure
812     my $simple = 'Perl uses the more complete version of this property';
813     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
814
815     my $other_properties = 'other properties';
816     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
817     my $why_no_expand  = "Easily computed, and yet doesn't cover the common encoding forms (UTF-16/8)",
818
819     %why_deprecated = (
820         'Grapheme_Link' => 'Deprecated by Unicode.  Use ccc=vr (Canonical_Combining_Class=Virama) instead',
821         'Jamo_Short_Name' => $contributory,
822         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
823         'Other_Alphabetic' => $contributory,
824         'Other_Default_Ignorable_Code_Point' => $contributory,
825         'Other_Grapheme_Extend' => $contributory,
826         'Other_ID_Continue' => $contributory,
827         'Other_ID_Start' => $contributory,
828         'Other_Lowercase' => $contributory,
829         'Other_Math' => $contributory,
830         'Other_Uppercase' => $contributory,
831     );
832
833     %why_suppressed = (
834         # There is a lib/unicore/Decomposition.pl (used by normalize.pm) which
835         # contains the same information, but without the algorithmically
836         # determinable Hangul syllables'.  This file is not published, so it's
837         # existence is not noted in the comment.
838         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize',
839
840         'ISO_Comment' => 'Apparently no demand for it, but can access it through Unicode::UCD::charinfo.  Obsoleted, and code points for it removed in Unicode 5.2',
841         'Unicode_1_Name' => "$simple, and no apparent demand for it, but can access it through Unicode::UCD::charinfo.  If there is no later name for a code point, then this one is used instead in charnames",
842
843         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold",
844         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
845         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
846         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo",
847
848         'Name' => "Accessible via 'use charnames;'",
849         'Name_Alias' => "Accessible via 'use charnames;'",
850
851         # These are sort of jumping the gun; deprecation is proposed for
852         # Unicode version 6.0, but they have never been exposed by Perl, and
853         # likely are soon to be deprecated, so best not to expose them.
854         FC_NFKC_Closure => 'Use NFKC_Casefold instead',
855         Expands_On_NFC => $why_no_expand,
856         Expands_On_NFD => $why_no_expand,
857         Expands_On_NFKC => $why_no_expand,
858         Expands_On_NFKD => $why_no_expand,
859     );
860
861     # The following are suppressed because they were made contributory or
862     # deprecated by Unicode before Perl ever thought about supporting them.
863     foreach my $property ('Jamo_Short_Name', 'Grapheme_Link') {
864         $why_suppressed{$property} = $why_deprecated{$property};
865     }
866
867     # Customize the message for all the 'Other_' properties
868     foreach my $property (keys %why_deprecated) {
869         next if (my $main_property = $property) !~ s/^Other_//;
870         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
871     }
872 }
873
874 if ($v_version ge 4.0.0) {
875     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
876 }
877 if ($v_version ge 5.2.0) {
878     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
879 }
880
881 # Probably obsolete forever
882 if ($v_version ge v4.1.0) {
883     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common"';
884 }
885
886 # This program can create files for enumerated-like properties, such as
887 # 'Numeric_Type'.  This file would be the same format as for a string
888 # property, with a mapping from code point to its value, so you could look up,
889 # for example, the script a code point is in.  But no one so far wants this
890 # mapping, or they have found another way to get it since this is a new
891 # feature.  So no file is generated except if it is in this list.
892 my @output_mapped_properties = split "\n", <<END;
893 END
894
895 # If you are using the Unihan database, you need to add the properties that
896 # you want to extract from it to this table.  For your convenience, the
897 # properties in the 5.2 PropertyAliases.txt file are listed, commented out
898 my @cjk_properties = split "\n", <<'END';
899 #cjkAccountingNumeric; kAccountingNumeric
900 #cjkOtherNumeric; kOtherNumeric
901 #cjkPrimaryNumeric; kPrimaryNumeric
902 #cjkCompatibilityVariant; kCompatibilityVariant
903 #cjkIICore ; kIICore
904 #cjkIRG_GSource; kIRG_GSource
905 #cjkIRG_HSource; kIRG_HSource
906 #cjkIRG_JSource; kIRG_JSource
907 #cjkIRG_KPSource; kIRG_KPSource
908 #cjkIRG_KSource; kIRG_KSource
909 #cjkIRG_TSource; kIRG_TSource
910 #cjkIRG_USource; kIRG_USource
911 #cjkIRG_VSource; kIRG_VSource
912 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
913 END
914
915 # Similarly for the property values.  For your convenience, the lines in the
916 # 5.2 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
917 # '#' marks
918 my @cjk_property_values = split "\n", <<'END';
919 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
920 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
921 ## @missing: 0000..10FFFF; cjkIICore; <none>
922 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
923 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
924 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
925 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
926 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
927 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
928 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
929 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
930 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
931 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
932 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
933 END
934
935 # The input files don't list every code point.  Those not listed are to be
936 # defaulted to some value.  Below are hard-coded what those values are for
937 # non-binary properties as of 5.1.  Starting in 5.0, there are
938 # machine-parsable comment lines in the files the give the defaults; so this
939 # list shouldn't have to be extended.  The claim is that all missing entries
940 # for binary properties will default to 'N'.  Unicode tried to change that in
941 # 5.2, but the beta period produced enough protest that they backed off.
942 #
943 # The defaults for the fields that appear in UnicodeData.txt in this hash must
944 # be in the form that it expects.  The others may be synonyms.
945 my $CODE_POINT = '<code point>';
946 my %default_mapping = (
947     Age => "Unassigned",
948     # Bidi_Class => Complicated; set in code
949     Bidi_Mirroring_Glyph => "",
950     Block => 'No_Block',
951     Canonical_Combining_Class => 0,
952     Case_Folding => $CODE_POINT,
953     Decomposition_Mapping => $CODE_POINT,
954     Decomposition_Type => 'None',
955     East_Asian_Width => "Neutral",
956     FC_NFKC_Closure => $CODE_POINT,
957     General_Category => 'Cn',
958     Grapheme_Cluster_Break => 'Other',
959     Hangul_Syllable_Type => 'NA',
960     ISO_Comment => "",
961     Jamo_Short_Name => "",
962     Joining_Group => "No_Joining_Group",
963     # Joining_Type => Complicated; set in code
964     kIICore => 'N',   #                       Is converted to binary
965     #Line_Break => Complicated; set in code
966     Lowercase_Mapping => $CODE_POINT,
967     Name => "",
968     Name_Alias => "",
969     NFC_QC => 'Yes',
970     NFD_QC => 'Yes',
971     NFKC_QC => 'Yes',
972     NFKD_QC => 'Yes',
973     Numeric_Type => 'None',
974     Numeric_Value => 'NaN',
975     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
976     Sentence_Break => 'Other',
977     Simple_Case_Folding => $CODE_POINT,
978     Simple_Lowercase_Mapping => $CODE_POINT,
979     Simple_Titlecase_Mapping => $CODE_POINT,
980     Simple_Uppercase_Mapping => $CODE_POINT,
981     Titlecase_Mapping => $CODE_POINT,
982     Unicode_1_Name => "",
983     Unicode_Radical_Stroke => "",
984     Uppercase_Mapping => $CODE_POINT,
985     Word_Break => 'Other',
986 );
987
988 # Below are files that Unicode furnishes, but this program ignores, and why
989 my %ignored_files = (
990     'CJKRadicals.txt' => 'Unihan data',
991     'Index.txt' => 'An index, not actual data',
992     'NamedSqProv.txt' => 'Not officially part of the Unicode standard; Append it to NamedSequences.txt if you want to process the contents.',
993     'NamesList.txt' => 'Just adds commentary',
994     'NormalizationCorrections.txt' => 'Data is already in other files.',
995     'Props.txt' => 'Adds nothing to PropList.txt; only in very early releases',
996     'ReadMe.txt' => 'Just comments',
997     'README.TXT' => 'Just comments',
998     'StandardizedVariants.txt' => 'Only for glyph changes, not a Unicode character property.  Does not fit into current scheme where one code point is mapped',
999 );
1000
1001 ### End of externally interesting definitions, except for @input_file_objects
1002
1003 my $HEADER=<<"EOF";
1004 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1005 # This file is machine-generated by $0 from the Unicode
1006 # database, Version $string_version.  Any changes made here will be lost!
1007 EOF
1008
1009 my $INTERNAL_ONLY=<<"EOF";
1010
1011 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1012 # This file is for internal use by the Perl program only.  The format and even
1013 # the name or existence of this file are subject to change without notice.
1014 # Don't use it directly.
1015 EOF
1016
1017 my $DEVELOPMENT_ONLY=<<"EOF";
1018 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1019 # This file contains information artificially constrained to code points
1020 # present in Unicode release $string_compare_versions.
1021 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1022 # not be used for production.
1023
1024 EOF
1025
1026 my $LAST_UNICODE_CODEPOINT_STRING = "10FFFF";
1027 my $LAST_UNICODE_CODEPOINT = hex $LAST_UNICODE_CODEPOINT_STRING;
1028 my $MAX_UNICODE_CODEPOINTS = $LAST_UNICODE_CODEPOINT + 1;
1029
1030 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1031 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1032 # to decrease backtracking
1033 my $code_point_re =
1034         qr/ \b (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1035
1036 # This matches the beginning of the line in the Unicode db files that give the
1037 # defaults for code points not listed (i.e., missing) in the file.  The code
1038 # depends on this ending with a semi-colon, so it can assume it is a valid
1039 # field when the line is split() by semi-colons
1040 my $missing_defaults_prefix =
1041             qr/^#\s+\@missing:\s+0000\.\.$LAST_UNICODE_CODEPOINT_STRING\s*;/;
1042
1043 # Property types.  Unicode has more types, but these are sufficient for our
1044 # purposes.
1045 my $UNKNOWN = -1;   # initialized to illegal value
1046 my $NON_STRING = 1; # Either binary or enum
1047 my $BINARY = 2;
1048 my $ENUM = 3;       # Include catalog
1049 my $STRING = 4;     # Anything else: string or misc
1050
1051 # Some input files have lines that give default values for code points not
1052 # contained in the file.  Sometimes these should be ignored.
1053 my $NO_DEFAULTS = 0;        # Must evaluate to false
1054 my $NOT_IGNORED = 1;
1055 my $IGNORED = 2;
1056
1057 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1058 # and will appear in the main body of the tables in the output files, but
1059 # there are other types of ranges as well, listed below, that are specially
1060 # handled.   There are pseudo-types as well that will never be stored as a
1061 # type, but will affect the calculation of the type.
1062
1063 # 0 is for normal, non-specials
1064 my $MULTI_CP = 1;           # Sequence of more than code point
1065 my $HANGUL_SYLLABLE = 2;
1066 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1067 my $NULL = 4;               # The map is to the null string; utf8.c can't
1068                             # handle these, nor is there an accepted syntax
1069                             # for them in \p{} constructs
1070 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1071                              # otherwise be $MULTI_CP type are instead type 0
1072
1073 # process_generic_property_file() can accept certain overrides in its input.
1074 # Each of these must begin AND end with $CMD_DELIM.
1075 my $CMD_DELIM = "\a";
1076 my $REPLACE_CMD = 'replace';    # Override the Replace
1077 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1078
1079 my $NO = 0;
1080 my $YES = 1;
1081
1082 # Values for the Replace argument to add_range.
1083 # $NO                      # Don't replace; add only the code points not
1084                            # already present.
1085 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1086                            # the comments at the subroutine definition.
1087 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1088 my $MULTIPLE = 4;          # Don't replace, but add a duplicate record if
1089                            # already there
1090
1091 # Flags to give property statuses.  The phrases are to remind maintainers that
1092 # if the flag is changed, the indefinite article referring to it in the
1093 # documentation may need to be as well.
1094 my $NORMAL = "";
1095 my $SUPPRESSED = 'z';   # The character should never actually be seen, since
1096                         # it is suppressed
1097 my $PLACEHOLDER = 'P';  # Implies no pod entry generated
1098 my $DEPRECATED = 'D';
1099 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1100 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1101 my $DISCOURAGED = 'X';
1102 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1103 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1104 my $STRICTER = 'T';
1105 my $a_bold_stricter = "a 'B<$STRICTER>'";
1106 my $A_bold_stricter = "A 'B<$STRICTER>'";
1107 my $STABILIZED = 'S';
1108 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1109 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1110 my $OBSOLETE = 'O';
1111 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1112 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1113
1114 my %status_past_participles = (
1115     $DISCOURAGED => 'discouraged',
1116     $SUPPRESSED => 'should never be generated',
1117     $STABILIZED => 'stabilized',
1118     $OBSOLETE => 'obsolete',
1119     $DEPRECATED => 'deprecated',
1120 );
1121
1122 # The format of the values of the map tables:
1123 my $BINARY_FORMAT = 'b';
1124 my $DECIMAL_FORMAT = 'd';
1125 my $FLOAT_FORMAT = 'f';
1126 my $INTEGER_FORMAT = 'i';
1127 my $HEX_FORMAT = 'x';
1128 my $RATIONAL_FORMAT = 'r';
1129 my $STRING_FORMAT = 's';
1130
1131 my %map_table_formats = (
1132     $BINARY_FORMAT => 'binary',
1133     $DECIMAL_FORMAT => 'single decimal digit',
1134     $FLOAT_FORMAT => 'floating point number',
1135     $INTEGER_FORMAT => 'integer',
1136     $HEX_FORMAT => 'positive hex whole number; a code point',
1137     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1138     $STRING_FORMAT => 'arbitrary string',
1139 );
1140
1141 # Unicode didn't put such derived files in a separate directory at first.
1142 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1143 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1144 my $AUXILIARY = 'auxiliary';
1145
1146 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1147 my %loose_to_file_of;       # loosely maps table names to their respective
1148                             # files
1149 my %stricter_to_file_of;    # same; but for stricter mapping.
1150 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1151                              # their rational equivalent
1152 my %loose_property_name_of; # Loosely maps property names to standard form
1153
1154 # These constants names and values were taken from the Unicode standard,
1155 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1156 # syllables
1157 my $SBase = 0xAC00;
1158 my $LBase = 0x1100;
1159 my $VBase = 0x1161;
1160 my $TBase = 0x11A7;
1161 my $SCount = 11172;
1162 my $LCount = 19;
1163 my $VCount = 21;
1164 my $TCount = 28;
1165 my $NCount = $VCount * $TCount;
1166
1167 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1168 # with the above published constants.
1169 my %Jamo;
1170 my %Jamo_L;     # Leading consonants
1171 my %Jamo_V;     # Vowels
1172 my %Jamo_T;     # Trailing consonants
1173
1174 my @backslash_X_tests;     # List of tests read in for testing \X
1175 my @unhandled_properties;  # Will contain a list of properties found in
1176                            # the input that we didn't process.
1177 my @match_properties;      # Properties that have match tables, to be
1178                            # listed in the pod
1179 my @map_properties;        # Properties that get map files written
1180 my @named_sequences;       # NamedSequences.txt contents.
1181 my %potential_files;       # Generated list of all .txt files in the directory
1182                            # structure so we can warn if something is being
1183                            # ignored.
1184 my @files_actually_output; # List of files we generated.
1185 my @more_Names;            # Some code point names are compound; this is used
1186                            # to store the extra components of them.
1187 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1188                            # the minimum before we consider it equivalent to a
1189                            # candidate rational
1190 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1191
1192 # These store references to certain commonly used property objects
1193 my $gc;
1194 my $perl;
1195 my $block;
1196
1197 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1198 my $has_In_conflicts = 0;
1199 my $has_Is_conflicts = 0;
1200
1201 sub internal_file_to_platform ($) {
1202     # Convert our file paths which have '/' separators to those of the
1203     # platform.
1204
1205     my $file = shift;
1206     return undef unless defined $file;
1207
1208     return File::Spec->join(split '/', $file);
1209 }
1210
1211 sub file_exists ($) {   # platform independent '-e'.  This program internally
1212                         # uses slash as a path separator.
1213     my $file = shift;
1214     return 0 if ! defined $file;
1215     return -e internal_file_to_platform($file);
1216 }
1217
1218 sub objaddr($) {
1219     # Returns the address of the blessed input object.
1220     # It doesn't check for blessedness because that would do a string eval
1221     # every call, and the program is structured so that this is never called
1222     # for a non-blessed object.
1223
1224     no overloading; # If overloaded, numifying below won't work.
1225
1226     # Numifying a ref gives its address.
1227     return 0 + $_[0];
1228 }
1229
1230 # Commented code below should work on Perl 5.8.
1231 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1232 ## the native perl version of it (which is what would operate under miniperl)
1233 ## is extremely slow, as it does a string eval every call.
1234 #my $has_fast_scalar_util = $\18 !~ /miniperl/
1235 #                            && defined eval "require Scalar::Util";
1236 #
1237 #sub objaddr($) {
1238 #    # Returns the address of the blessed input object.  Uses the XS version if
1239 #    # available.  It doesn't check for blessedness because that would do a
1240 #    # string eval every call, and the program is structured so that this is
1241 #    # never called for a non-blessed object.
1242 #
1243 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1244 #
1245 #    # Check at least that is a ref.
1246 #    my $pkg = ref($_[0]) or return undef;
1247 #
1248 #    # Change to a fake package to defeat any overloaded stringify
1249 #    bless $_[0], 'main::Fake';
1250 #
1251 #    # Numifying a ref gives its address.
1252 #    my $addr = 0 + $_[0];
1253 #
1254 #    # Return to original class
1255 #    bless $_[0], $pkg;
1256 #    return $addr;
1257 #}
1258
1259 sub max ($$) {
1260     my $a = shift;
1261     my $b = shift;
1262     return $a if $a >= $b;
1263     return $b;
1264 }
1265
1266 sub min ($$) {
1267     my $a = shift;
1268     my $b = shift;
1269     return $a if $a <= $b;
1270     return $b;
1271 }
1272
1273 sub clarify_number ($) {
1274     # This returns the input number with underscores inserted every 3 digits
1275     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1276     # checked.
1277
1278     my $number = shift;
1279     my $pos = length($number) - 3;
1280     return $number if $pos <= 1;
1281     while ($pos > 0) {
1282         substr($number, $pos, 0) = '_';
1283         $pos -= 3;
1284     }
1285     return $number;
1286 }
1287
1288
1289 package Carp;
1290
1291 # These routines give a uniform treatment of messages in this program.  They
1292 # are placed in the Carp package to cause the stack trace to not include them,
1293 # although an alternative would be to use another package and set @CARP_NOT
1294 # for it.
1295
1296 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1297
1298 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1299 # and overload trying to load Scalar:Util under miniperl.  See
1300 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1301 undef $overload::VERSION;
1302
1303 sub my_carp {
1304     my $message = shift || "";
1305     my $nofold = shift || 0;
1306
1307     if ($message) {
1308         $message = main::join_lines($message);
1309         $message =~ s/^$0: *//;     # Remove initial program name
1310         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1311         $message = "\n$0: $message;";
1312
1313         # Fold the message with program name, semi-colon end punctuation
1314         # (which looks good with the message that carp appends to it), and a
1315         # hanging indent for continuation lines.
1316         $message = main::simple_fold($message, "", 4) unless $nofold;
1317         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1318                                     # appends is to the same line
1319     }
1320
1321     return $message if defined wantarray;   # If a caller just wants the msg
1322
1323     carp $message;
1324     return;
1325 }
1326
1327 sub my_carp_bug {
1328     # This is called when it is clear that the problem is caused by a bug in
1329     # this program.
1330
1331     my $message = shift;
1332     $message =~ s/^$0: *//;
1333     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1334     carp $message;
1335     return;
1336 }
1337
1338 sub carp_too_few_args {
1339     if (@_ != 2) {
1340         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1341         return;
1342     }
1343
1344     my $args_ref = shift;
1345     my $count = shift;
1346
1347     my_carp_bug("Need at least $count arguments to "
1348         . (caller 1)[3]
1349         . ".  Instead got: '"
1350         . join ', ', @$args_ref
1351         . "'.  No action taken.");
1352     return;
1353 }
1354
1355 sub carp_extra_args {
1356     my $args_ref = shift;
1357     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1358
1359     unless (ref $args_ref) {
1360         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1361         return;
1362     }
1363     my ($package, $file, $line) = caller;
1364     my $subroutine = (caller 1)[3];
1365
1366     my $list;
1367     if (ref $args_ref eq 'HASH') {
1368         foreach my $key (keys %$args_ref) {
1369             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1370         }
1371         $list = join ', ', each %{$args_ref};
1372     }
1373     elsif (ref $args_ref eq 'ARRAY') {
1374         foreach my $arg (@$args_ref) {
1375             $arg = $UNDEF unless defined $arg;
1376         }
1377         $list = join ', ', @$args_ref;
1378     }
1379     else {
1380         my_carp_bug("Can't cope with ref "
1381                 . ref($args_ref)
1382                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1383         return;
1384     }
1385
1386     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1387     return;
1388 }
1389
1390 package main;
1391
1392 { # Closure
1393
1394     # This program uses the inside-out method for objects, as recommended in
1395     # "Perl Best Practices".  This closure aids in generating those.  There
1396     # are two routines.  setup_package() is called once per package to set
1397     # things up, and then set_access() is called for each hash representing a
1398     # field in the object.  These routines arrange for the object to be
1399     # properly destroyed when no longer used, and for standard accessor
1400     # functions to be generated.  If you need more complex accessors, just
1401     # write your own and leave those accesses out of the call to set_access().
1402     # More details below.
1403
1404     my %constructor_fields; # fields that are to be used in constructors; see
1405                             # below
1406
1407     # The values of this hash will be the package names as keys to other
1408     # hashes containing the name of each field in the package as keys, and
1409     # references to their respective hashes as values.
1410     my %package_fields;
1411
1412     sub setup_package {
1413         # Sets up the package, creating standard DESTROY and dump methods
1414         # (unless already defined).  The dump method is used in debugging by
1415         # simple_dumper().
1416         # The optional parameters are:
1417         #   a)  a reference to a hash, that gets populated by later
1418         #       set_access() calls with one of the accesses being
1419         #       'constructor'.  The caller can then refer to this, but it is
1420         #       not otherwise used by these two routines.
1421         #   b)  a reference to a callback routine to call during destruction
1422         #       of the object, before any fields are actually destroyed
1423
1424         my %args = @_;
1425         my $constructor_ref = delete $args{'Constructor_Fields'};
1426         my $destroy_callback = delete $args{'Destroy_Callback'};
1427         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1428
1429         my %fields;
1430         my $package = (caller)[0];
1431
1432         $package_fields{$package} = \%fields;
1433         $constructor_fields{$package} = $constructor_ref;
1434
1435         unless ($package->can('DESTROY')) {
1436             my $destroy_name = "${package}::DESTROY";
1437             no strict "refs";
1438
1439             # Use typeglob to give the anonymous subroutine the name we want
1440             *$destroy_name = sub {
1441                 my $self = shift;
1442                 my $addr; { no overloading; $addr = 0+$self; }
1443
1444                 $self->$destroy_callback if $destroy_callback;
1445                 foreach my $field (keys %{$package_fields{$package}}) {
1446                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1447                     delete $package_fields{$package}{$field}{$addr};
1448                 }
1449                 return;
1450             }
1451         }
1452
1453         unless ($package->can('dump')) {
1454             my $dump_name = "${package}::dump";
1455             no strict "refs";
1456             *$dump_name = sub {
1457                 my $self = shift;
1458                 return dump_inside_out($self, $package_fields{$package}, @_);
1459             }
1460         }
1461         return;
1462     }
1463
1464     sub set_access {
1465         # Arrange for the input field to be garbage collected when no longer
1466         # needed.  Also, creates standard accessor functions for the field
1467         # based on the optional parameters-- none if none of these parameters:
1468         #   'addable'    creates an 'add_NAME()' accessor function.
1469         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1470         #                function.
1471         #   'settable'   creates a 'set_NAME()' accessor function.
1472         #   'constructor' doesn't create an accessor function, but adds the
1473         #                field to the hash that was previously passed to
1474         #                setup_package();
1475         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1476         # 'add' etc. all mean 'addable'.
1477         # The read accessor function will work on both array and scalar
1478         # values.  If another accessor in the parameter list is 'a', the read
1479         # access assumes an array.  You can also force it to be array access
1480         # by specifying 'readable_array' instead of 'readable'
1481         #
1482         # A sort-of 'protected' access can be set-up by preceding the addable,
1483         # readable or settable with some initial portion of 'protected_' (but,
1484         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1485         # "protection" is only by convention.  All that happens is that the
1486         # accessor functions' names begin with an underscore.  So instead of
1487         # calling set_foo, the call is _set_foo.  (Real protection could be
1488         # accomplished by having a new subroutine, end_package called at the
1489         # end of each package, and then storing the __LINE__ ranges and
1490         # checking them on every accessor.  But that is way overkill.)
1491
1492         # We create anonymous subroutines as the accessors and then use
1493         # typeglobs to assign them to the proper package and name
1494
1495         my $name = shift;   # Name of the field
1496         my $field = shift;  # Reference to the inside-out hash containing the
1497                             # field
1498
1499         my $package = (caller)[0];
1500
1501         if (! exists $package_fields{$package}) {
1502             croak "$0: Must call 'setup_package' before 'set_access'";
1503         }
1504
1505         # Stash the field so DESTROY can get it.
1506         $package_fields{$package}{$name} = $field;
1507
1508         # Remaining arguments are the accessors.  For each...
1509         foreach my $access (@_) {
1510             my $access = lc $access;
1511
1512             my $protected = "";
1513
1514             # Match the input as far as it goes.
1515             if ($access =~ /^(p[^_]*)_/) {
1516                 $protected = $1;
1517                 if (substr('protected_', 0, length $protected)
1518                     eq $protected)
1519                 {
1520
1521                     # Add 1 for the underscore not included in $protected
1522                     $access = substr($access, length($protected) + 1);
1523                     $protected = '_';
1524                 }
1525                 else {
1526                     $protected = "";
1527                 }
1528             }
1529
1530             if (substr('addable', 0, length $access) eq $access) {
1531                 my $subname = "${package}::${protected}add_$name";
1532                 no strict "refs";
1533
1534                 # add_ accessor.  Don't add if already there, which we
1535                 # determine using 'eq' for scalars and '==' otherwise.
1536                 *$subname = sub {
1537                     use strict "refs";
1538                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1539                     my $self = shift;
1540                     my $value = shift;
1541                     my $addr; { no overloading; $addr = 0+$self; }
1542                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1543                     if (ref $value) {
1544                         return if grep { $value == $_ } @{$field->{$addr}};
1545                     }
1546                     else {
1547                         return if grep { $value eq $_ } @{$field->{$addr}};
1548                     }
1549                     push @{$field->{$addr}}, $value;
1550                     return;
1551                 }
1552             }
1553             elsif (substr('constructor', 0, length $access) eq $access) {
1554                 if ($protected) {
1555                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1556                 }
1557                 else {
1558                     $constructor_fields{$package}{$name} = $field;
1559                 }
1560             }
1561             elsif (substr('readable_array', 0, length $access) eq $access) {
1562
1563                 # Here has read access.  If one of the other parameters for
1564                 # access is array, or this one specifies array (by being more
1565                 # than just 'readable_'), then create a subroutine that
1566                 # assumes the data is an array.  Otherwise just a scalar
1567                 my $subname = "${package}::${protected}$name";
1568                 if (grep { /^a/i } @_
1569                     or length($access) > length('readable_'))
1570                 {
1571                     no strict "refs";
1572                     *$subname = sub {
1573                         use strict "refs";
1574                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1575                         my $addr; { no overloading; $addr = 0+$_[0]; }
1576                         if (ref $field->{$addr} ne 'ARRAY') {
1577                             my $type = ref $field->{$addr};
1578                             $type = 'scalar' unless $type;
1579                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1580                             return;
1581                         }
1582                         return scalar @{$field->{$addr}} unless wantarray;
1583
1584                         # Make a copy; had problems with caller modifying the
1585                         # original otherwise
1586                         my @return = @{$field->{$addr}};
1587                         return @return;
1588                     }
1589                 }
1590                 else {
1591
1592                     # Here not an array value, a simpler function.
1593                     no strict "refs";
1594                     *$subname = sub {
1595                         use strict "refs";
1596                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1597                         no overloading;
1598                         return $field->{0+$_[0]};
1599                     }
1600                 }
1601             }
1602             elsif (substr('settable', 0, length $access) eq $access) {
1603                 my $subname = "${package}::${protected}set_$name";
1604                 no strict "refs";
1605                 *$subname = sub {
1606                     use strict "refs";
1607                     if (main::DEBUG) {
1608                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
1609                         Carp::carp_extra_args(\@_) if @_ > 2;
1610                     }
1611                     # $self is $_[0]; $value is $_[1]
1612                     no overloading;
1613                     $field->{0+$_[0]} = $_[1];
1614                     return;
1615                 }
1616             }
1617             else {
1618                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
1619             }
1620         }
1621         return;
1622     }
1623 }
1624
1625 package Input_file;
1626
1627 # All input files use this object, which stores various attributes about them,
1628 # and provides for convenient, uniform handling.  The run method wraps the
1629 # processing.  It handles all the bookkeeping of opening, reading, and closing
1630 # the file, returning only significant input lines.
1631 #
1632 # Each object gets a handler which processes the body of the file, and is
1633 # called by run().  Most should use the generic, default handler, which has
1634 # code scrubbed to handle things you might not expect.  A handler should
1635 # basically be a while(next_line()) {...} loop.
1636 #
1637 # You can also set up handlers to
1638 #   1) call before the first line is read for pre processing
1639 #   2) call to adjust each line of the input before the main handler gets them
1640 #   3) call upon EOF before the main handler exits its loop
1641 #   4) call at the end for post processing
1642 #
1643 # $_ is used to store the input line, and is to be filtered by the
1644 # each_line_handler()s.  So, if the format of the line is not in the desired
1645 # format for the main handler, these are used to do that adjusting.  They can
1646 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
1647 # so the $_ output of one is used as the input to the next.  None of the other
1648 # handlers are stackable, but could easily be changed to be so.
1649 #
1650 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
1651 # which insert the parameters as lines to be processed before the next input
1652 # file line is read.  This allows the EOF handler to flush buffers, for
1653 # example.  The difference between the two routines is that the lines inserted
1654 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
1655 # called it from such a handler, you would get infinite recursion.)  Lines
1656 # inserted by insert_adjusted_lines() go directly to the main handler without
1657 # any adjustments.  If the  post-processing handler calls any of these, there
1658 # will be no effect.  Some error checking for these conditions could be added,
1659 # but it hasn't been done.
1660 #
1661 # carp_bad_line() should be called to warn of bad input lines, which clears $_
1662 # to prevent further processing of the line.  This routine will output the
1663 # message as a warning once, and then keep a count of the lines that have the
1664 # same message, and output that count at the end of the file's processing.
1665 # This keeps the number of messages down to a manageable amount.
1666 #
1667 # get_missings() should be called to retrieve any @missing input lines.
1668 # Messages will be raised if this isn't done if the options aren't to ignore
1669 # missings.
1670
1671 sub trace { return main::trace(@_); }
1672
1673 { # Closure
1674     # Keep track of fields that are to be put into the constructor.
1675     my %constructor_fields;
1676
1677     main::setup_package(Constructor_Fields => \%constructor_fields);
1678
1679     my %file; # Input file name, required
1680     main::set_access('file', \%file, qw{ c r });
1681
1682     my %first_released; # Unicode version file was first released in, required
1683     main::set_access('first_released', \%first_released, qw{ c r });
1684
1685     my %handler;    # Subroutine to process the input file, defaults to
1686                     # 'process_generic_property_file'
1687     main::set_access('handler', \%handler, qw{ c });
1688
1689     my %property;
1690     # name of property this file is for.  defaults to none, meaning not
1691     # applicable, or is otherwise determinable, for example, from each line.
1692     main::set_access('property', \%property, qw{ c });
1693
1694     my %optional;
1695     # If this is true, the file is optional.  If not present, no warning is
1696     # output.  If it is present, the string given by this parameter is
1697     # evaluated, and if false the file is not processed.
1698     main::set_access('optional', \%optional, 'c', 'r');
1699
1700     my %non_skip;
1701     # This is used for debugging, to skip processing of all but a few input
1702     # files.  Add 'non_skip => 1' to the constructor for those files you want
1703     # processed when you set the $debug_skip global.
1704     main::set_access('non_skip', \%non_skip, 'c');
1705
1706     my %skip;
1707     # This is used to skip processing of this input file semi-permanently.
1708     # It is used for files that we aren't planning to process anytime soon,
1709     # but want to allow to be in the directory and not raise a message that we
1710     # are not handling.  Mostly for test files.  This is in contrast to the
1711     # non_skip element, which is supposed to be used very temporarily for
1712     # debugging.  Sets 'optional' to 1
1713     main::set_access('skip', \%skip, 'c');
1714
1715     my %each_line_handler;
1716     # list of subroutines to look at and filter each non-comment line in the
1717     # file.  defaults to none.  The subroutines are called in order, each is
1718     # to adjust $_ for the next one, and the final one adjusts it for
1719     # 'handler'
1720     main::set_access('each_line_handler', \%each_line_handler, 'c');
1721
1722     my %has_missings_defaults;
1723     # ? Are there lines in the file giving default values for code points
1724     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
1725     # the norm, but IGNORED means it has such lines, but the handler doesn't
1726     # use them.  Having these three states allows us to catch changes to the
1727     # UCD that this program should track
1728     main::set_access('has_missings_defaults',
1729                                         \%has_missings_defaults, qw{ c r });
1730
1731     my %pre_handler;
1732     # Subroutine to call before doing anything else in the file.  If undef, no
1733     # such handler is called.
1734     main::set_access('pre_handler', \%pre_handler, qw{ c });
1735
1736     my %eof_handler;
1737     # Subroutine to call upon getting an EOF on the input file, but before
1738     # that is returned to the main handler.  This is to allow buffers to be
1739     # flushed.  The handler is expected to call insert_lines() or
1740     # insert_adjusted() with the buffered material
1741     main::set_access('eof_handler', \%eof_handler, qw{ c r });
1742
1743     my %post_handler;
1744     # Subroutine to call after all the lines of the file are read in and
1745     # processed.  If undef, no such handler is called.
1746     main::set_access('post_handler', \%post_handler, qw{ c });
1747
1748     my %progress_message;
1749     # Message to print to display progress in lieu of the standard one
1750     main::set_access('progress_message', \%progress_message, qw{ c });
1751
1752     my %handle;
1753     # cache open file handle, internal.  Is undef if file hasn't been
1754     # processed at all, empty if has;
1755     main::set_access('handle', \%handle);
1756
1757     my %added_lines;
1758     # cache of lines added virtually to the file, internal
1759     main::set_access('added_lines', \%added_lines);
1760
1761     my %errors;
1762     # cache of errors found, internal
1763     main::set_access('errors', \%errors);
1764
1765     my %missings;
1766     # storage of '@missing' defaults lines
1767     main::set_access('missings', \%missings);
1768
1769     sub new {
1770         my $class = shift;
1771
1772         my $self = bless \do{ my $anonymous_scalar }, $class;
1773         my $addr; { no overloading; $addr = 0+$self; }
1774
1775         # Set defaults
1776         $handler{$addr} = \&main::process_generic_property_file;
1777         $non_skip{$addr} = 0;
1778         $skip{$addr} = 0;
1779         $has_missings_defaults{$addr} = $NO_DEFAULTS;
1780         $handle{$addr} = undef;
1781         $added_lines{$addr} = [ ];
1782         $each_line_handler{$addr} = [ ];
1783         $errors{$addr} = { };
1784         $missings{$addr} = [ ];
1785
1786         # Two positional parameters.
1787         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1788         $file{$addr} = main::internal_file_to_platform(shift);
1789         $first_released{$addr} = shift;
1790
1791         # The rest of the arguments are key => value pairs
1792         # %constructor_fields has been set up earlier to list all possible
1793         # ones.  Either set or push, depending on how the default has been set
1794         # up just above.
1795         my %args = @_;
1796         foreach my $key (keys %args) {
1797             my $argument = $args{$key};
1798
1799             # Note that the fields are the lower case of the constructor keys
1800             my $hash = $constructor_fields{lc $key};
1801             if (! defined $hash) {
1802                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
1803                 next;
1804             }
1805             if (ref $hash->{$addr} eq 'ARRAY') {
1806                 if (ref $argument eq 'ARRAY') {
1807                     foreach my $argument (@{$argument}) {
1808                         next if ! defined $argument;
1809                         push @{$hash->{$addr}}, $argument;
1810                     }
1811                 }
1812                 else {
1813                     push @{$hash->{$addr}}, $argument if defined $argument;
1814                 }
1815             }
1816             else {
1817                 $hash->{$addr} = $argument;
1818             }
1819             delete $args{$key};
1820         };
1821
1822         # If the file has a property for it, it means that the property is not
1823         # listed in the file's entries.  So add a handler to the list of line
1824         # handlers to insert the property name into the lines, to provide a
1825         # uniform interface to the final processing subroutine.
1826         # the final code doesn't have to worry about that.
1827         if ($property{$addr}) {
1828             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
1829         }
1830
1831         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
1832             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
1833         }
1834
1835         $optional{$addr} = 1 if $skip{$addr};
1836
1837         return $self;
1838     }
1839
1840
1841     use overload
1842         fallback => 0,
1843         qw("") => "_operator_stringify",
1844         "." => \&main::_operator_dot,
1845     ;
1846
1847     sub _operator_stringify {
1848         my $self = shift;
1849
1850         return __PACKAGE__ . " object for " . $self->file;
1851     }
1852
1853     # flag to make sure extracted files are processed early
1854     my $seen_non_extracted_non_age = 0;
1855
1856     sub run {
1857         # Process the input object $self.  This opens and closes the file and
1858         # calls all the handlers for it.  Currently,  this can only be called
1859         # once per file, as it destroy's the EOF handler
1860
1861         my $self = shift;
1862         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1863
1864         my $addr; { no overloading; $addr = 0+$self; }
1865
1866         my $file = $file{$addr};
1867
1868         # Don't process if not expecting this file (because released later
1869         # than this Unicode version), and isn't there.  This means if someone
1870         # copies it into an earlier version's directory, we will go ahead and
1871         # process it.
1872         return if $first_released{$addr} gt $v_version && ! -e $file;
1873
1874         # If in debugging mode and this file doesn't have the non-skip
1875         # flag set, and isn't one of the critical files, skip it.
1876         if ($debug_skip
1877             && $first_released{$addr} ne v0
1878             && ! $non_skip{$addr})
1879         {
1880             print "Skipping $file in debugging\n" if $verbosity;
1881             return;
1882         }
1883
1884         # File could be optional
1885         if ($optional{$addr}) {
1886             return unless -e $file;
1887             my $result = eval $optional{$addr};
1888             if (! defined $result) {
1889                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
1890                 return;
1891             }
1892             if (! $result) {
1893                 if ($verbosity) {
1894                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
1895                 }
1896                 return;
1897             }
1898         }
1899
1900         if (! defined $file || ! -e $file) {
1901
1902             # If the file doesn't exist, see if have internal data for it
1903             # (based on first_released being 0).
1904             if ($first_released{$addr} eq v0) {
1905                 $handle{$addr} = 'pretend_is_open';
1906             }
1907             else {
1908                 if (! $optional{$addr}  # File could be optional
1909                     && $v_version ge $first_released{$addr})
1910                 {
1911                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
1912                 }
1913                 return;
1914             }
1915         }
1916         else {
1917
1918             # Here, the file exists.  Some platforms may change the case of
1919             # its name
1920             if ($seen_non_extracted_non_age) {
1921                 if ($file =~ /$EXTRACTED/i) {
1922                     Carp::my_carp_bug(join_lines(<<END
1923 $file should be processed just after the 'Prop...Alias' files, and before
1924 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
1925 have subtle problems
1926 END
1927                     ));
1928                 }
1929             }
1930             elsif ($EXTRACTED_DIR
1931                     && $first_released{$addr} ne v0
1932                     && $file !~ /$EXTRACTED/i
1933                     && lc($file) ne 'dage.txt')
1934             {
1935                 # We don't set this (by the 'if' above) if we have no
1936                 # extracted directory, so if running on an early version,
1937                 # this test won't work.  Not worth worrying about.
1938                 $seen_non_extracted_non_age = 1;
1939             }
1940
1941             # And mark the file as having being processed, and warn if it
1942             # isn't a file we are expecting.  As we process the files,
1943             # they are deleted from the hash, so any that remain at the
1944             # end of the program are files that we didn't process.
1945             my $fkey = File::Spec->rel2abs($file);
1946             my $expecting = delete $potential_files{$fkey};
1947             $expecting = delete $potential_files{lc($fkey)} unless defined $expecting;
1948             Carp::my_carp("Was not expecting '$file'.") if
1949                     ! $expecting
1950                     && ! defined $handle{$addr};
1951
1952             # Having deleted from expected files, we can quit if not to do
1953             # anything.  Don't print progress unless really want verbosity
1954             if ($skip{$addr}) {
1955                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
1956                 return;
1957             }
1958
1959             # Open the file, converting the slashes used in this program
1960             # into the proper form for the OS
1961             my $file_handle;
1962             if (not open $file_handle, "<", $file) {
1963                 Carp::my_carp("Can't open $file.  Skipping: $!");
1964                 return 0;
1965             }
1966             $handle{$addr} = $file_handle; # Cache the open file handle
1967         }
1968
1969         if ($verbosity >= $PROGRESS) {
1970             if ($progress_message{$addr}) {
1971                 print "$progress_message{$addr}\n";
1972             }
1973             else {
1974                 # If using a virtual file, say so.
1975                 print "Processing ", (-e $file)
1976                                        ? $file
1977                                        : "substitute $file",
1978                                      "\n";
1979             }
1980         }
1981
1982
1983         # Call any special handler for before the file.
1984         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
1985
1986         # Then the main handler
1987         &{$handler{$addr}}($self);
1988
1989         # Then any special post-file handler.
1990         &{$post_handler{$addr}}($self) if $post_handler{$addr};
1991
1992         # If any errors have been accumulated, output the counts (as the first
1993         # error message in each class was output when it was encountered).
1994         if ($errors{$addr}) {
1995             my $total = 0;
1996             my $types = 0;
1997             foreach my $error (keys %{$errors{$addr}}) {
1998                 $total += $errors{$addr}->{$error};
1999                 delete $errors{$addr}->{$error};
2000                 $types++;
2001             }
2002             if ($total > 1) {
2003                 my $message
2004                         = "A total of $total lines had errors in $file.  ";
2005
2006                 $message .= ($types == 1)
2007                             ? '(Only the first one was displayed.)'
2008                             : '(Only the first of each type was displayed.)';
2009                 Carp::my_carp($message);
2010             }
2011         }
2012
2013         if (@{$missings{$addr}}) {
2014             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2015         }
2016
2017         # If a real file handle, close it.
2018         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2019                                                         ref $handle{$addr};
2020         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2021                                # the file, as opposed to undef
2022         return;
2023     }
2024
2025     sub next_line {
2026         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2027         # if such a line exists.  'logical' means that any lines that have
2028         # been added via insert_lines() will be returned in $_ before the file
2029         # is read again.
2030
2031         my $self = shift;
2032         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2033
2034         my $addr; { no overloading; $addr = 0+$self; }
2035
2036         # Here the file is open (or if the handle is not a ref, is an open
2037         # 'virtual' file).  Get the next line; any inserted lines get priority
2038         # over the file itself.
2039         my $adjusted;
2040
2041         LINE:
2042         while (1) { # Loop until find non-comment, non-empty line
2043             #local $to_trace = 1 if main::DEBUG;
2044             my $inserted_ref = shift @{$added_lines{$addr}};
2045             if (defined $inserted_ref) {
2046                 ($adjusted, $_) = @{$inserted_ref};
2047                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2048                 return 1 if $adjusted;
2049             }
2050             else {
2051                 last if ! ref $handle{$addr}; # Don't read unless is real file
2052                 last if ! defined ($_ = readline $handle{$addr});
2053             }
2054             chomp;
2055             trace $_ if main::DEBUG && $to_trace;
2056
2057             # See if this line is the comment line that defines what property
2058             # value that code points that are not listed in the file should
2059             # have.  The format or existence of these lines is not guaranteed
2060             # by Unicode since they are comments, but the documentation says
2061             # that this was added for machine-readability, so probably won't
2062             # change.  This works starting in Unicode Version 5.0.  They look
2063             # like:
2064             #
2065             # @missing: 0000..10FFFF; Not_Reordered
2066             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2067             # @missing: 0000..10FFFF; ; NaN
2068             #
2069             # Save the line for a later get_missings() call.
2070             if (/$missing_defaults_prefix/) {
2071                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2072                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2073                 }
2074                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2075                     my @defaults = split /\s* ; \s*/x, $_;
2076
2077                     # The first field is the @missing, which ends in a
2078                     # semi-colon, so can safely shift.
2079                     shift @defaults;
2080
2081                     # Some of these lines may have empty field placeholders
2082                     # which get in the way.  An example is:
2083                     # @missing: 0000..10FFFF; ; NaN
2084                     # Remove them.  Process starting from the top so the
2085                     # splice doesn't affect things still to be looked at.
2086                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2087                         next if $defaults[$i] ne "";
2088                         splice @defaults, $i, 1;
2089                     }
2090
2091                     # What's left should be just the property (maybe) and the
2092                     # default.  Having only one element means it doesn't have
2093                     # the property.
2094                     my $default;
2095                     my $property;
2096                     if (@defaults >= 1) {
2097                         if (@defaults == 1) {
2098                             $default = $defaults[0];
2099                         }
2100                         else {
2101                             $property = $defaults[0];
2102                             $default = $defaults[1];
2103                         }
2104                     }
2105
2106                     if (@defaults < 1
2107                         || @defaults > 2
2108                         || ($default =~ /^</
2109                             && $default !~ /^<code *point>$/i
2110                             && $default !~ /^<none>$/i))
2111                     {
2112                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2113                     }
2114                     else {
2115
2116                         # If the property is missing from the line, it should
2117                         # be the one for the whole file
2118                         $property = $property{$addr} if ! defined $property;
2119
2120                         # Change <none> to the null string, which is what it
2121                         # really means.  If the default is the code point
2122                         # itself, set it to <code point>, which is what
2123                         # Unicode uses (but sometimes they've forgotten the
2124                         # space)
2125                         if ($default =~ /^<none>$/i) {
2126                             $default = "";
2127                         }
2128                         elsif ($default =~ /^<code *point>$/i) {
2129                             $default = $CODE_POINT;
2130                         }
2131
2132                         # Store them as a sub-arrays with both components.
2133                         push @{$missings{$addr}}, [ $default, $property ];
2134                     }
2135                 }
2136
2137                 # There is nothing for the caller to process on this comment
2138                 # line.
2139                 next;
2140             }
2141
2142             # Remove comments and trailing space, and skip this line if the
2143             # result is empty
2144             s/#.*//;
2145             s/\s+$//;
2146             next if /^$/;
2147
2148             # Call any handlers for this line, and skip further processing of
2149             # the line if the handler sets the line to null.
2150             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2151                 &{$sub_ref}($self);
2152                 next LINE if /^$/;
2153             }
2154
2155             # Here the line is ok.  return success.
2156             return 1;
2157         } # End of looping through lines.
2158
2159         # If there is an EOF handler, call it (only once) and if it generates
2160         # more lines to process go back in the loop to handle them.
2161         if ($eof_handler{$addr}) {
2162             &{$eof_handler{$addr}}($self);
2163             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2164             goto LINE if $added_lines{$addr};
2165         }
2166
2167         # Return failure -- no more lines.
2168         return 0;
2169
2170     }
2171
2172 #   Not currently used, not fully tested.
2173 #    sub peek {
2174 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2175 #        # record.  Not callable from an each_line_handler(), nor does it call
2176 #        # an each_line_handler() on the line.
2177 #
2178 #        my $self = shift;
2179 #        my $addr; { no overloading; $addr = 0+$self; }
2180 #
2181 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2182 #            my ($adjusted, $line) = @{$inserted_ref};
2183 #            next if $adjusted;
2184 #
2185 #            # Remove comments and trailing space, and return a non-empty
2186 #            # resulting line
2187 #            $line =~ s/#.*//;
2188 #            $line =~ s/\s+$//;
2189 #            return $line if $line ne "";
2190 #        }
2191 #
2192 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2193 #        while (1) { # Loop until find non-comment, non-empty line
2194 #            local $to_trace = 1 if main::DEBUG;
2195 #            trace $_ if main::DEBUG && $to_trace;
2196 #            return if ! defined (my $line = readline $handle{$addr});
2197 #            chomp $line;
2198 #            push @{$added_lines{$addr}}, [ 0, $line ];
2199 #
2200 #            $line =~ s/#.*//;
2201 #            $line =~ s/\s+$//;
2202 #            return $line if $line ne "";
2203 #        }
2204 #
2205 #        return;
2206 #    }
2207
2208
2209     sub insert_lines {
2210         # Lines can be inserted so that it looks like they were in the input
2211         # file at the place it was when this routine is called.  See also
2212         # insert_adjusted_lines().  Lines inserted via this routine go through
2213         # any each_line_handler()
2214
2215         my $self = shift;
2216
2217         # Each inserted line is an array, with the first element being 0 to
2218         # indicate that this line hasn't been adjusted, and needs to be
2219         # processed.
2220         no overloading;
2221         push @{$added_lines{0+$self}}, map { [ 0, $_ ] } @_;
2222         return;
2223     }
2224
2225     sub insert_adjusted_lines {
2226         # Lines can be inserted so that it looks like they were in the input
2227         # file at the place it was when this routine is called.  See also
2228         # insert_lines().  Lines inserted via this routine are already fully
2229         # adjusted, ready to be processed; each_line_handler()s handlers will
2230         # not be called.  This means this is not a completely general
2231         # facility, as only the last each_line_handler on the stack should
2232         # call this.  It could be made more general, by passing to each of the
2233         # line_handlers their position on the stack, which they would pass on
2234         # to this routine, and that would replace the boolean first element in
2235         # the anonymous array pushed here, so that the next_line routine could
2236         # use that to call only those handlers whose index is after it on the
2237         # stack.  But this is overkill for what is needed now.
2238
2239         my $self = shift;
2240         trace $_[0] if main::DEBUG && $to_trace;
2241
2242         # Each inserted line is an array, with the first element being 1 to
2243         # indicate that this line has been adjusted
2244         no overloading;
2245         push @{$added_lines{0+$self}}, map { [ 1, $_ ] } @_;
2246         return;
2247     }
2248
2249     sub get_missings {
2250         # Returns the stored up @missings lines' values, and clears the list.
2251         # The values are in an array, consisting of the default in the first
2252         # element, and the property in the 2nd.  However, since these lines
2253         # can be stacked up, the return is an array of all these arrays.
2254
2255         my $self = shift;
2256         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2257
2258         my $addr; { no overloading; $addr = 0+$self; }
2259
2260         # If not accepting a list return, just return the first one.
2261         return shift @{$missings{$addr}} unless wantarray;
2262
2263         my @return = @{$missings{$addr}};
2264         undef @{$missings{$addr}};
2265         return @return;
2266     }
2267
2268     sub _insert_property_into_line {
2269         # Add a property field to $_, if this file requires it.
2270
2271         my $self = shift;
2272         my $addr; { no overloading; $addr = 0+$self; }
2273         my $property = $property{$addr};
2274         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2275
2276         $_ =~ s/(;|$)/; $property$1/;
2277         return;
2278     }
2279
2280     sub carp_bad_line {
2281         # Output consistent error messages, using either a generic one, or the
2282         # one given by the optional parameter.  To avoid gazillions of the
2283         # same message in case the syntax of a  file is way off, this routine
2284         # only outputs the first instance of each message, incrementing a
2285         # count so the totals can be output at the end of the file.
2286
2287         my $self = shift;
2288         my $message = shift;
2289         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2290
2291         my $addr; { no overloading; $addr = 0+$self; }
2292
2293         $message = 'Unexpected line' unless $message;
2294
2295         # No trailing punctuation so as to fit with our addenda.
2296         $message =~ s/[.:;,]$//;
2297
2298         # If haven't seen this exact message before, output it now.  Otherwise
2299         # increment the count of how many times it has occurred
2300         unless ($errors{$addr}->{$message}) {
2301             Carp::my_carp("$message in '$_' in "
2302                             . $file{$addr}
2303                             . " at line $..  Skipping this line;");
2304             $errors{$addr}->{$message} = 1;
2305         }
2306         else {
2307             $errors{$addr}->{$message}++;
2308         }
2309
2310         # Clear the line to prevent any further (meaningful) processing of it.
2311         $_ = "";
2312
2313         return;
2314     }
2315 } # End closure
2316
2317 package Multi_Default;
2318
2319 # Certain properties in early versions of Unicode had more than one possible
2320 # default for code points missing from the files.  In these cases, one
2321 # default applies to everything left over after all the others are applied,
2322 # and for each of the others, there is a description of which class of code
2323 # points applies to it.  This object helps implement this by storing the
2324 # defaults, and for all but that final default, an eval string that generates
2325 # the class that it applies to.
2326
2327
2328 {   # Closure
2329
2330     main::setup_package();
2331
2332     my %class_defaults;
2333     # The defaults structure for the classes
2334     main::set_access('class_defaults', \%class_defaults);
2335
2336     my %other_default;
2337     # The default that applies to everything left over.
2338     main::set_access('other_default', \%other_default, 'r');
2339
2340
2341     sub new {
2342         # The constructor is called with default => eval pairs, terminated by
2343         # the left-over default. e.g.
2344         # Multi_Default->new(
2345         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2346         #               -  0x200D',
2347         #        'R' => 'some other expression that evaluates to code points',
2348         #        .
2349         #        .
2350         #        .
2351         #        'U'));
2352
2353         my $class = shift;
2354
2355         my $self = bless \do{my $anonymous_scalar}, $class;
2356         my $addr; { no overloading; $addr = 0+$self; }
2357
2358         while (@_ > 1) {
2359             my $default = shift;
2360             my $eval = shift;
2361             $class_defaults{$addr}->{$default} = $eval;
2362         }
2363
2364         $other_default{$addr} = shift;
2365
2366         return $self;
2367     }
2368
2369     sub get_next_defaults {
2370         # Iterates and returns the next class of defaults.
2371         my $self = shift;
2372         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2373
2374         my $addr; { no overloading; $addr = 0+$self; }
2375
2376         return each %{$class_defaults{$addr}};
2377     }
2378 }
2379
2380 package Alias;
2381
2382 # An alias is one of the names that a table goes by.  This class defines them
2383 # including some attributes.  Everything is currently setup in the
2384 # constructor.
2385
2386
2387 {   # Closure
2388
2389     main::setup_package();
2390
2391     my %name;
2392     main::set_access('name', \%name, 'r');
2393
2394     my %loose_match;
2395     # Determined by the constructor code if this name should match loosely or
2396     # not.  The constructor parameters can override this, but it isn't fully
2397     # implemented, as should have ability to override Unicode one's via
2398     # something like a set_loose_match()
2399     main::set_access('loose_match', \%loose_match, 'r');
2400
2401     my %make_pod_entry;
2402     # Some aliases should not get their own entries because they are covered
2403     # by a wild-card, and some we want to discourage use of.  Binary
2404     main::set_access('make_pod_entry', \%make_pod_entry, 'r');
2405
2406     my %status;
2407     # Aliases have a status, like deprecated, or even suppressed (which means
2408     # they don't appear in documentation).  Enum
2409     main::set_access('status', \%status, 'r');
2410
2411     my %externally_ok;
2412     # Similarly, some aliases should not be considered as usable ones for
2413     # external use, such as file names, or we don't want documentation to
2414     # recommend them.  Boolean
2415     main::set_access('externally_ok', \%externally_ok, 'r');
2416
2417     sub new {
2418         my $class = shift;
2419
2420         my $self = bless \do { my $anonymous_scalar }, $class;
2421         my $addr; { no overloading; $addr = 0+$self; }
2422
2423         $name{$addr} = shift;
2424         $loose_match{$addr} = shift;
2425         $make_pod_entry{$addr} = shift;
2426         $externally_ok{$addr} = shift;
2427         $status{$addr} = shift;
2428
2429         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2430
2431         # Null names are never ok externally
2432         $externally_ok{$addr} = 0 if $name{$addr} eq "";
2433
2434         return $self;
2435     }
2436 }
2437
2438 package Range;
2439
2440 # A range is the basic unit for storing code points, and is described in the
2441 # comments at the beginning of the program.  Each range has a starting code
2442 # point; an ending code point (not less than the starting one); a value
2443 # that applies to every code point in between the two end-points, inclusive;
2444 # and an enum type that applies to the value.  The type is for the user's
2445 # convenience, and has no meaning here, except that a non-zero type is
2446 # considered to not obey the normal Unicode rules for having standard forms.
2447 #
2448 # The same structure is used for both map and match tables, even though in the
2449 # latter, the value (and hence type) is irrelevant and could be used as a
2450 # comment.  In map tables, the value is what all the code points in the range
2451 # map to.  Type 0 values have the standardized version of the value stored as
2452 # well, so as to not have to recalculate it a lot.
2453
2454 sub trace { return main::trace(@_); }
2455
2456 {   # Closure
2457
2458     main::setup_package();
2459
2460     my %start;
2461     main::set_access('start', \%start, 'r', 's');
2462
2463     my %end;
2464     main::set_access('end', \%end, 'r', 's');
2465
2466     my %value;
2467     main::set_access('value', \%value, 'r');
2468
2469     my %type;
2470     main::set_access('type', \%type, 'r');
2471
2472     my %standard_form;
2473     # The value in internal standard form.  Defined only if the type is 0.
2474     main::set_access('standard_form', \%standard_form);
2475
2476     # Note that if these fields change, the dump() method should as well
2477
2478     sub new {
2479         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
2480         my $class = shift;
2481
2482         my $self = bless \do { my $anonymous_scalar }, $class;
2483         my $addr; { no overloading; $addr = 0+$self; }
2484
2485         $start{$addr} = shift;
2486         $end{$addr} = shift;
2487
2488         my %args = @_;
2489
2490         my $value = delete $args{'Value'};  # Can be 0
2491         $value = "" unless defined $value;
2492         $value{$addr} = $value;
2493
2494         $type{$addr} = delete $args{'Type'} || 0;
2495
2496         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2497
2498         if (! $type{$addr}) {
2499             $standard_form{$addr} = main::standardize($value);
2500         }
2501
2502         return $self;
2503     }
2504
2505     use overload
2506         fallback => 0,
2507         qw("") => "_operator_stringify",
2508         "." => \&main::_operator_dot,
2509     ;
2510
2511     sub _operator_stringify {
2512         my $self = shift;
2513         my $addr; { no overloading; $addr = 0+$self; }
2514
2515         # Output it like '0041..0065 (value)'
2516         my $return = sprintf("%04X", $start{$addr})
2517                         .  '..'
2518                         . sprintf("%04X", $end{$addr});
2519         my $value = $value{$addr};
2520         my $type = $type{$addr};
2521         $return .= ' (';
2522         $return .= "$value";
2523         $return .= ", Type=$type" if $type != 0;
2524         $return .= ')';
2525
2526         return $return;
2527     }
2528
2529     sub standard_form {
2530         # The standard form is the value itself if the standard form is
2531         # undefined (that is if the value is special)
2532
2533         my $self = shift;
2534         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2535
2536         my $addr; { no overloading; $addr = 0+$self; }
2537
2538         return $standard_form{$addr} if defined $standard_form{$addr};
2539         return $value{$addr};
2540     }
2541
2542     sub dump {
2543         # Human, not machine readable.  For machine readable, comment out this
2544         # entire routine and let the standard one take effect.
2545         my $self = shift;
2546         my $indent = shift;
2547         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2548
2549         my $addr; { no overloading; $addr = 0+$self; }
2550
2551         my $return = $indent
2552                     . sprintf("%04X", $start{$addr})
2553                     . '..'
2554                     . sprintf("%04X", $end{$addr})
2555                     . " '$value{$addr}';";
2556         if (! defined $standard_form{$addr}) {
2557             $return .= "(type=$type{$addr})";
2558         }
2559         elsif ($standard_form{$addr} ne $value{$addr}) {
2560             $return .= "(standard '$standard_form{$addr}')";
2561         }
2562         return $return;
2563     }
2564 } # End closure
2565
2566 package _Range_List_Base;
2567
2568 # Base class for range lists.  A range list is simply an ordered list of
2569 # ranges, so that the ranges with the lowest starting numbers are first in it.
2570 #
2571 # When a new range is added that is adjacent to an existing range that has the
2572 # same value and type, it merges with it to form a larger range.
2573 #
2574 # Ranges generally do not overlap, except that there can be multiple entries
2575 # of single code point ranges.  This is because of NameAliases.txt.
2576 #
2577 # In this program, there is a standard value such that if two different
2578 # values, have the same standard value, they are considered equivalent.  This
2579 # value was chosen so that it gives correct results on Unicode data
2580
2581 # There are a number of methods to manipulate range lists, and some operators
2582 # are overloaded to handle them.
2583
2584 sub trace { return main::trace(@_); }
2585
2586 { # Closure
2587
2588     our $addr;
2589
2590     main::setup_package();
2591
2592     my %ranges;
2593     # The list of ranges
2594     main::set_access('ranges', \%ranges, 'readable_array');
2595
2596     my %max;
2597     # The highest code point in the list.  This was originally a method, but
2598     # actual measurements said it was used a lot.
2599     main::set_access('max', \%max, 'r');
2600
2601     my %each_range_iterator;
2602     # Iterator position for each_range()
2603     main::set_access('each_range_iterator', \%each_range_iterator);
2604
2605     my %owner_name_of;
2606     # Name of parent this is attached to, if any.  Solely for better error
2607     # messages.
2608     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
2609
2610     my %_search_ranges_cache;
2611     # A cache of the previous result from _search_ranges(), for better
2612     # performance
2613     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
2614
2615     sub new {
2616         my $class = shift;
2617         my %args = @_;
2618
2619         # Optional initialization data for the range list.
2620         my $initialize = delete $args{'Initialize'};
2621
2622         my $self;
2623
2624         # Use _union() to initialize.  _union() returns an object of this
2625         # class, which means that it will call this constructor recursively.
2626         # But it won't have this $initialize parameter so that it won't
2627         # infinitely loop on this.
2628         return _union($class, $initialize, %args) if defined $initialize;
2629
2630         $self = bless \do { my $anonymous_scalar }, $class;
2631         my $addr; { no overloading; $addr = 0+$self; }
2632
2633         # Optional parent object, only for debug info.
2634         $owner_name_of{$addr} = delete $args{'Owner'};
2635         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
2636
2637         # Stringify, in case it is an object.
2638         $owner_name_of{$addr} = "$owner_name_of{$addr}";
2639
2640         # This is used only for error messages, and so a colon is added
2641         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
2642
2643         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
2644
2645         # Max is initialized to a negative value that isn't adjacent to 0,
2646         # for simpler tests
2647         $max{$addr} = -2;
2648
2649         $_search_ranges_cache{$addr} = 0;
2650         $ranges{$addr} = [];
2651
2652         return $self;
2653     }
2654
2655     use overload
2656         fallback => 0,
2657         qw("") => "_operator_stringify",
2658         "." => \&main::_operator_dot,
2659     ;
2660
2661     sub _operator_stringify {
2662         my $self = shift;
2663         my $addr; { no overloading; $addr = 0+$self; }
2664
2665         return "Range_List attached to '$owner_name_of{$addr}'"
2666                                                 if $owner_name_of{$addr};
2667         return "anonymous Range_List " . \$self;
2668     }
2669
2670     sub _union {
2671         # Returns the union of the input code points.  It can be called as
2672         # either a constructor or a method.  If called as a method, the result
2673         # will be a new() instance of the calling object, containing the union
2674         # of that object with the other parameter's code points;  if called as
2675         # a constructor, the first parameter gives the class the new object
2676         # should be, and the second parameter gives the code points to go into
2677         # it.
2678         # In either case, there are two parameters looked at by this routine;
2679         # any additional parameters are passed to the new() constructor.
2680         #
2681         # The code points can come in the form of some object that contains
2682         # ranges, and has a conventionally named method to access them; or
2683         # they can be an array of individual code points (as integers); or
2684         # just a single code point.
2685         #
2686         # If they are ranges, this routine doesn't make any effort to preserve
2687         # the range values of one input over the other.  Therefore this base
2688         # class should not allow _union to be called from other than
2689         # initialization code, so as to prevent two tables from being added
2690         # together where the range values matter.  The general form of this
2691         # routine therefore belongs in a derived class, but it was moved here
2692         # to avoid duplication of code.  The failure to overload this in this
2693         # class keeps it safe.
2694         #
2695
2696         my $self;
2697         my @args;   # Arguments to pass to the constructor
2698
2699         my $class = shift;
2700
2701         # If a method call, will start the union with the object itself, and
2702         # the class of the new object will be the same as self.
2703         if (ref $class) {
2704             $self = $class;
2705             $class = ref $self;
2706             push @args, $self;
2707         }
2708
2709         # Add the other required parameter.
2710         push @args, shift;
2711         # Rest of parameters are passed on to the constructor
2712
2713         # Accumulate all records from both lists.
2714         my @records;
2715         for my $arg (@args) {
2716             #local $to_trace = 0 if main::DEBUG;
2717             trace "argument = $arg" if main::DEBUG && $to_trace;
2718             if (! defined $arg) {
2719                 my $message = "";
2720                 if (defined $self) {
2721                     no overloading;
2722                     $message .= $owner_name_of{0+$self};
2723                 }
2724                 Carp::my_carp_bug($message .= "Undefined argument to _union.  No union done.");
2725                 return;
2726             }
2727             $arg = [ $arg ] if ! ref $arg;
2728             my $type = ref $arg;
2729             if ($type eq 'ARRAY') {
2730                 foreach my $element (@$arg) {
2731                     push @records, Range->new($element, $element);
2732                 }
2733             }
2734             elsif ($arg->isa('Range')) {
2735                 push @records, $arg;
2736             }
2737             elsif ($arg->can('ranges')) {
2738                 push @records, $arg->ranges;
2739             }
2740             else {
2741                 my $message = "";
2742                 if (defined $self) {
2743                     no overloading;
2744                     $message .= $owner_name_of{0+$self};
2745                 }
2746                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
2747                 return;
2748             }
2749         }
2750
2751         # Sort with the range containing the lowest ordinal first, but if
2752         # two ranges start at the same code point, sort with the bigger range
2753         # of the two first, because it takes fewer cycles.
2754         @records = sort { ($a->start <=> $b->start)
2755                                       or
2756                                     # if b is shorter than a, b->end will be
2757                                     # less than a->end, and we want to select
2758                                     # a, so want to return -1
2759                                     ($b->end <=> $a->end)
2760                                    } @records;
2761
2762         my $new = $class->new(@_);
2763
2764         # Fold in records so long as they add new information.
2765         for my $set (@records) {
2766             my $start = $set->start;
2767             my $end   = $set->end;
2768             my $value   = $set->value;
2769             if ($start > $new->max) {
2770                 $new->_add_delete('+', $start, $end, $value);
2771             }
2772             elsif ($end > $new->max) {
2773                 $new->_add_delete('+', $new->max +1, $end, $value);
2774             }
2775         }
2776
2777         return $new;
2778     }
2779
2780     sub range_count {        # Return the number of ranges in the range list
2781         my $self = shift;
2782         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2783
2784         no overloading;
2785         return scalar @{$ranges{0+$self}};
2786     }
2787
2788     sub min {
2789         # Returns the minimum code point currently in the range list, or if
2790         # the range list is empty, 2 beyond the max possible.  This is a
2791         # method because used so rarely, that not worth saving between calls,
2792         # and having to worry about changing it as ranges are added and
2793         # deleted.
2794
2795         my $self = shift;
2796         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2797
2798         my $addr; { no overloading; $addr = 0+$self; }
2799
2800         # If the range list is empty, return a large value that isn't adjacent
2801         # to any that could be in the range list, for simpler tests
2802         return $LAST_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
2803         return $ranges{$addr}->[0]->start;
2804     }
2805
2806     sub contains {
2807         # Boolean: Is argument in the range list?  If so returns $i such that:
2808         #   range[$i]->end < $codepoint <= range[$i+1]->end
2809         # which is one beyond what you want; this is so that the 0th range
2810         # doesn't return false
2811         my $self = shift;
2812         my $codepoint = shift;
2813         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2814
2815         my $i = $self->_search_ranges($codepoint);
2816         return 0 unless defined $i;
2817
2818         # The search returns $i, such that
2819         #   range[$i-1]->end < $codepoint <= range[$i]->end
2820         # So is in the table if and only iff it is at least the start position
2821         # of range $i.
2822         no overloading;
2823         return 0 if $ranges{0+$self}->[$i]->start > $codepoint;
2824         return $i + 1;
2825     }
2826
2827     sub value_of {
2828         # Returns the value associated with the code point, undef if none
2829
2830         my $self = shift;
2831         my $codepoint = shift;
2832         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2833
2834         my $i = $self->contains($codepoint);
2835         return unless $i;
2836
2837         # contains() returns 1 beyond where we should look
2838         no overloading;
2839         return $ranges{0+$self}->[$i-1]->value;
2840     }
2841
2842     sub _search_ranges {
2843         # Find the range in the list which contains a code point, or where it
2844         # should go if were to add it.  That is, it returns $i, such that:
2845         #   range[$i-1]->end < $codepoint <= range[$i]->end
2846         # Returns undef if no such $i is possible (e.g. at end of table), or
2847         # if there is an error.
2848
2849         my $self = shift;
2850         my $code_point = shift;
2851         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2852
2853         my $addr; { no overloading; $addr = 0+$self; }
2854
2855         return if $code_point > $max{$addr};
2856         my $r = $ranges{$addr};                # The current list of ranges
2857         my $range_list_size = scalar @$r;
2858         my $i;
2859
2860         use integer;        # want integer division
2861
2862         # Use the cached result as the starting guess for this one, because,
2863         # an experiment on 5.1 showed that 90% of the time the cache was the
2864         # same as the result on the next call (and 7% it was one less).
2865         $i = $_search_ranges_cache{$addr};
2866         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
2867                                             # from an intervening deletion
2868         #local $to_trace = 1 if main::DEBUG;
2869         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
2870         return $i if $code_point <= $r->[$i]->end
2871                      && ($i == 0 || $r->[$i-1]->end < $code_point);
2872
2873         # Here the cache doesn't yield the correct $i.  Try adding 1.
2874         if ($i < $range_list_size - 1
2875             && $r->[$i]->end < $code_point &&
2876             $code_point <= $r->[$i+1]->end)
2877         {
2878             $i++;
2879             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
2880             $_search_ranges_cache{$addr} = $i;
2881             return $i;
2882         }
2883
2884         # Here, adding 1 also didn't work.  We do a binary search to
2885         # find the correct position, starting with current $i
2886         my $lower = 0;
2887         my $upper = $range_list_size - 1;
2888         while (1) {
2889             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
2890
2891             if ($code_point <= $r->[$i]->end) {
2892
2893                 # Here we have met the upper constraint.  We can quit if we
2894                 # also meet the lower one.
2895                 last if $i == 0 || $r->[$i-1]->end < $code_point;
2896
2897                 $upper = $i;        # Still too high.
2898
2899             }
2900             else {
2901
2902                 # Here, $r[$i]->end < $code_point, so look higher up.
2903                 $lower = $i;
2904             }
2905
2906             # Split search domain in half to try again.
2907             my $temp = ($upper + $lower) / 2;
2908
2909             # No point in continuing unless $i changes for next time
2910             # in the loop.
2911             if ($temp == $i) {
2912
2913                 # We can't reach the highest element because of the averaging.
2914                 # So if one below the upper edge, force it there and try one
2915                 # more time.
2916                 if ($i == $range_list_size - 2) {
2917
2918                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
2919                     $i = $range_list_size - 1;
2920
2921                     # Change $lower as well so if fails next time through,
2922                     # taking the average will yield the same $i, and we will
2923                     # quit with the error message just below.
2924                     $lower = $i;
2925                     next;
2926                 }
2927                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
2928                 return;
2929             }
2930             $i = $temp;
2931         } # End of while loop
2932
2933         if (main::DEBUG && $to_trace) {
2934             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
2935             trace "i=  [ $i ]", $r->[$i];
2936             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
2937         }
2938
2939         # Here we have found the offset.  Cache it as a starting point for the
2940         # next call.
2941         $_search_ranges_cache{$addr} = $i;
2942         return $i;
2943     }
2944
2945     sub _add_delete {
2946         # Add, replace or delete ranges to or from a list.  The $type
2947         # parameter gives which:
2948         #   '+' => insert or replace a range, returning a list of any changed
2949         #          ranges.
2950         #   '-' => delete a range, returning a list of any deleted ranges.
2951         #
2952         # The next three parameters give respectively the start, end, and
2953         # value associated with the range.  'value' should be null unless the
2954         # operation is '+';
2955         #
2956         # The range list is kept sorted so that the range with the lowest
2957         # starting position is first in the list, and generally, adjacent
2958         # ranges with the same values are merged into single larger one (see
2959         # exceptions below).
2960         #
2961         # There are more parameters, all are key => value pairs:
2962         #   Type    gives the type of the value.  It is only valid for '+'.
2963         #           All ranges have types; if this parameter is omitted, 0 is
2964         #           assumed.  Ranges with type 0 are assumed to obey the
2965         #           Unicode rules for casing, etc; ranges with other types are
2966         #           not.  Otherwise, the type is arbitrary, for the caller's
2967         #           convenience, and looked at only by this routine to keep
2968         #           adjacent ranges of different types from being merged into
2969         #           a single larger range, and when Replace =>
2970         #           $IF_NOT_EQUIVALENT is specified (see just below).
2971         #   Replace  determines what to do if the range list already contains
2972         #            ranges which coincide with all or portions of the input
2973         #            range.  It is only valid for '+':
2974         #       => $NO            means that the new value is not to replace
2975         #                         any existing ones, but any empty gaps of the
2976         #                         range list coinciding with the input range
2977         #                         will be filled in with the new value.
2978         #       => $UNCONDITIONALLY  means to replace the existing values with
2979         #                         this one unconditionally.  However, if the
2980         #                         new and old values are identical, the
2981         #                         replacement is skipped to save cycles
2982         #       => $IF_NOT_EQUIVALENT means to replace the existing values
2983         #                         with this one if they are not equivalent.
2984         #                         Ranges are equivalent if their types are the
2985         #                         same, and they are the same string, or if
2986         #                         both are type 0 ranges, if their Unicode
2987         #                         standard forms are identical.  In this last
2988         #                         case, the routine chooses the more "modern"
2989         #                         one to use.  This is because some of the
2990         #                         older files are formatted with values that
2991         #                         are, for example, ALL CAPs, whereas the
2992         #                         derived files have a more modern style,
2993         #                         which looks better.  By looking for this
2994         #                         style when the pre-existing and replacement
2995         #                         standard forms are the same, we can move to
2996         #                         the modern style
2997         #       => $MULTIPLE      means that if this range duplicates an
2998         #                         existing one, but has a different value,
2999         #                         don't replace the existing one, but insert
3000         #                         this, one so that the same range can occur
3001         #                         multiple times.
3002         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3003         #
3004         # "same value" means identical for type-0 ranges, and it means having
3005         # the same standard forms for non-type-0 ranges.
3006
3007         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3008
3009         my $self = shift;
3010         my $operation = shift;   # '+' for add/replace; '-' for delete;
3011         my $start = shift;
3012         my $end   = shift;
3013         my $value = shift;
3014
3015         my %args = @_;
3016
3017         $value = "" if not defined $value;        # warning: $value can be "0"
3018
3019         my $replace = delete $args{'Replace'};
3020         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3021
3022         my $type = delete $args{'Type'};
3023         $type = 0 unless defined $type;
3024
3025         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3026
3027         my $addr; { no overloading; $addr = 0+$self; }
3028
3029         if ($operation ne '+' && $operation ne '-') {
3030             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3031             return;
3032         }
3033         unless (defined $start && defined $end) {
3034             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3035             return;
3036         }
3037         unless ($end >= $start) {
3038             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3039             return;
3040         }
3041         #local $to_trace = 1 if main::DEBUG;
3042
3043         if ($operation eq '-') {
3044             if ($replace != $IF_NOT_EQUIVALENT) {
3045                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3046                 $replace = $IF_NOT_EQUIVALENT;
3047             }
3048             if ($type) {
3049                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3050                 $type = 0;
3051             }
3052             if ($value ne "") {
3053                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3054                 $value = "";
3055             }
3056         }
3057
3058         my $r = $ranges{$addr};               # The current list of ranges
3059         my $range_list_size = scalar @$r;     # And its size
3060         my $max = $max{$addr};                # The current high code point in
3061                                               # the list of ranges
3062
3063         # Do a special case requiring fewer machine cycles when the new range
3064         # starts after the current highest point.  The Unicode input data is
3065         # structured so this is common.
3066         if ($start > $max) {
3067
3068             trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) type=$type" if main::DEBUG && $to_trace;
3069             return if $operation eq '-'; # Deleting a non-existing range is a
3070                                          # no-op
3071
3072             # If the new range doesn't logically extend the current final one
3073             # in the range list, create a new range at the end of the range
3074             # list.  (max cleverly is initialized to a negative number not
3075             # adjacent to 0 if the range list is empty, so even adding a range
3076             # to an empty range list starting at 0 will have this 'if'
3077             # succeed.)
3078             if ($start > $max + 1        # non-adjacent means can't extend.
3079                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3080                 || @{$r}[-1]->type != $type # types differ, can't extend.
3081             ) {
3082                 push @$r, Range->new($start, $end,
3083                                      Value => $value,
3084                                      Type => $type);
3085             }
3086             else {
3087
3088                 # Here, the new range starts just after the current highest in
3089                 # the range list, and they have the same type and value.
3090                 # Extend the current range to incorporate the new one.
3091                 @{$r}[-1]->set_end($end);
3092             }
3093
3094             # This becomes the new maximum.
3095             $max{$addr} = $end;
3096
3097             return;
3098         }
3099         #local $to_trace = 0 if main::DEBUG;
3100
3101         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3102
3103         # Here, the input range isn't after the whole rest of the range list.
3104         # Most likely 'splice' will be needed.  The rest of the routine finds
3105         # the needed splice parameters, and if necessary, does the splice.
3106         # First, find the offset parameter needed by the splice function for
3107         # the input range.  Note that the input range may span multiple
3108         # existing ones, but we'll worry about that later.  For now, just find
3109         # the beginning.  If the input range is to be inserted starting in a
3110         # position not currently in the range list, it must (obviously) come
3111         # just after the range below it, and just before the range above it.
3112         # Slightly less obviously, it will occupy the position currently
3113         # occupied by the range that is to come after it.  More formally, we
3114         # are looking for the position, $i, in the array of ranges, such that:
3115         #
3116         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3117         #
3118         # (The ordered relationships within existing ranges are also shown in
3119         # the equation above).  However, if the start of the input range is
3120         # within an existing range, the splice offset should point to that
3121         # existing range's position in the list; that is $i satisfies a
3122         # somewhat different equation, namely:
3123         #
3124         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3125         #
3126         # More briefly, $start can come before or after r[$i]->start, and at
3127         # this point, we don't know which it will be.  However, these
3128         # two equations share these constraints:
3129         #
3130         #   r[$i-1]->end < $start <= r[$i]->end
3131         #
3132         # And that is good enough to find $i.
3133
3134         my $i = $self->_search_ranges($start);
3135         if (! defined $i) {
3136             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3137             return;
3138         }
3139
3140         # The search function returns $i such that:
3141         #
3142         # r[$i-1]->end < $start <= r[$i]->end
3143         #
3144         # That means that $i points to the first range in the range list
3145         # that could possibly be affected by this operation.  We still don't
3146         # know if the start of the input range is within r[$i], or if it
3147         # points to empty space between r[$i-1] and r[$i].
3148         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3149
3150         # Special case the insertion of data that is not to replace any
3151         # existing data.
3152         if ($replace == $NO) {  # If $NO, has to be operation '+'
3153             #local $to_trace = 1 if main::DEBUG;
3154             trace "Doesn't replace" if main::DEBUG && $to_trace;
3155
3156             # Here, the new range is to take effect only on those code points
3157             # that aren't already in an existing range.  This can be done by
3158             # looking through the existing range list and finding the gaps in
3159             # the ranges that this new range affects, and then calling this
3160             # function recursively on each of those gaps, leaving untouched
3161             # anything already in the list.  Gather up a list of the changed
3162             # gaps first so that changes to the internal state as new ranges
3163             # are added won't be a problem.
3164             my @gap_list;
3165
3166             # First, if the starting point of the input range is outside an
3167             # existing one, there is a gap from there to the beginning of the
3168             # existing range -- add a span to fill the part that this new
3169             # range occupies
3170             if ($start < $r->[$i]->start) {
3171                 push @gap_list, Range->new($start,
3172                                            main::min($end,
3173                                                      $r->[$i]->start - 1),
3174                                            Type => $type);
3175                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3176             }
3177
3178             # Then look through the range list for other gaps until we reach
3179             # the highest range affected by the input one.
3180             my $j;
3181             for ($j = $i+1; $j < $range_list_size; $j++) {
3182                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3183                 last if $end < $r->[$j]->start;
3184
3185                 # If there is a gap between when this range starts and the
3186                 # previous one ends, add a span to fill it.  Note that just
3187                 # because there are two ranges doesn't mean there is a
3188                 # non-zero gap between them.  It could be that they have
3189                 # different values or types
3190                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3191                     push @gap_list,
3192                         Range->new($r->[$j-1]->end + 1,
3193                                    $r->[$j]->start - 1,
3194                                    Type => $type);
3195                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3196                 }
3197             }
3198
3199             # Here, we have either found an existing range in the range list,
3200             # beyond the area affected by the input one, or we fell off the
3201             # end of the loop because the input range affects the whole rest
3202             # of the range list.  In either case, $j is 1 higher than the
3203             # highest affected range.  If $j == $i, it means that there are no
3204             # affected ranges, that the entire insertion is in the gap between
3205             # r[$i-1], and r[$i], which we already have taken care of before
3206             # the loop.
3207             # On the other hand, if there are affected ranges, it might be
3208             # that there is a gap that needs filling after the final such
3209             # range to the end of the input range
3210             if ($r->[$j-1]->end < $end) {
3211                     push @gap_list, Range->new(main::max($start,
3212                                                          $r->[$j-1]->end + 1),
3213                                                $end,
3214                                                Type => $type);
3215                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3216             }
3217
3218             # Call recursively to fill in all the gaps.
3219             foreach my $gap (@gap_list) {
3220                 $self->_add_delete($operation,
3221                                    $gap->start,
3222                                    $gap->end,
3223                                    $value,
3224                                    Type => $type);
3225             }
3226
3227             return;
3228         }
3229
3230         # Here, we have taken care of the case where $replace is $NO, which
3231         # means that whatever action we now take is done unconditionally.  It
3232         # still could be that this call will result in a no-op, if duplicates
3233         # aren't allowed, and we are inserting a range that merely duplicates
3234         # data already in the range list; or also if deleting a non-existent
3235         # range.
3236         # $i still points to the first potential affected range.  Now find the
3237         # highest range affected, which will determine the length parameter to
3238         # splice.  (The input range can span multiple existing ones.)  While
3239         # we are looking through the range list, see also if this is an
3240         # insertion that will change the values of at least one of the
3241         # affected ranges.  We don't need to do this check unless this is an
3242         # insertion of non-multiples, and also since this is a boolean, we
3243         # don't need to do it if have already determined that it will make a
3244         # change; just unconditionally change them.  $cdm is created to be 1
3245         # if either of these is true. (The 'c' in the name comes from below)
3246         my $cdm = ($operation eq '-' || $replace == $MULTIPLE);
3247         my $j;        # This will point to the highest affected range
3248
3249         # For non-zero types, the standard form is the value itself;
3250         my $standard_form = ($type) ? $value : main::standardize($value);
3251
3252         for ($j = $i; $j < $range_list_size; $j++) {
3253             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3254
3255             # If find a range that it doesn't overlap into, we can stop
3256             # searching
3257             last if $end < $r->[$j]->start;
3258
3259             # Here, overlaps the range at $j.  If the value's don't match,
3260             # and this is supposedly an insertion, it becomes a change
3261             # instead.  This is what the 'c' stands for in $cdm.
3262             if (! $cdm) {
3263                 if ($r->[$j]->standard_form ne $standard_form) {
3264                     $cdm = 1;
3265                 }
3266                 else {
3267
3268                     # Here, the two values are essentially the same.  If the
3269                     # two are actually identical, replacing wouldn't change
3270                     # anything so skip it.
3271                     my $pre_existing = $r->[$j]->value;
3272                     if ($pre_existing ne $value) {
3273
3274                         # Here the new and old standardized values are the
3275                         # same, but the non-standardized values aren't.  If
3276                         # replacing unconditionally, then replace
3277                         if( $replace == $UNCONDITIONALLY) {
3278                             $cdm = 1;
3279                         }
3280                         else {
3281
3282                             # Here, are replacing conditionally.  Decide to
3283                             # replace or not based on which appears to look
3284                             # the "nicest".  If one is mixed case and the
3285                             # other isn't, choose the mixed case one.
3286                             my $new_mixed = $value =~ /[A-Z]/
3287                                             && $value =~ /[a-z]/;
3288                             my $old_mixed = $pre_existing =~ /[A-Z]/
3289                                             && $pre_existing =~ /[a-z]/;
3290
3291                             if ($old_mixed != $new_mixed) {
3292                                 $cdm = 1 if $new_mixed;
3293                                 if (main::DEBUG && $to_trace) {
3294                                     if ($cdm) {
3295                                         trace "Replacing $pre_existing with $value";
3296                                     }
3297                                     else {
3298                                         trace "Retaining $pre_existing over $value";
3299                                     }
3300                                 }
3301                             }
3302                             else {
3303
3304                                 # Here casing wasn't different between the two.
3305                                 # If one has hyphens or underscores and the
3306                                 # other doesn't, choose the one with the
3307                                 # punctuation.
3308                                 my $new_punct = $value =~ /[-_]/;
3309                                 my $old_punct = $pre_existing =~ /[-_]/;
3310
3311                                 if ($old_punct != $new_punct) {
3312                                     $cdm = 1 if $new_punct;
3313                                     if (main::DEBUG && $to_trace) {
3314                                         if ($cdm) {
3315                                             trace "Replacing $pre_existing with $value";
3316                                         }
3317                                         else {
3318                                             trace "Retaining $pre_existing over $value";
3319                                         }
3320                                     }
3321                                 }   # else existing one is just as "good";
3322                                     # retain it to save cycles.
3323                             }
3324                         }
3325                     }
3326                 }
3327             }
3328         } # End of loop looking for highest affected range.
3329
3330         # Here, $j points to one beyond the highest range that this insertion
3331         # affects (hence to beyond the range list if that range is the final
3332         # one in the range list).
3333
3334         # The splice length is all the affected ranges.  Get it before
3335         # subtracting, for efficiency, so we don't have to later add 1.
3336         my $length = $j - $i;
3337
3338         $j--;        # $j now points to the highest affected range.
3339         trace "Final affected range is $j: $r->[$j]" if main::DEBUG && $to_trace;
3340
3341         # If inserting a multiple record, this is where it goes, after all the
3342         # existing ones for this range.  This implies an insertion, and no
3343         # change to any existing ranges.  Note that $j can be -1 if this new
3344         # range doesn't actually duplicate any existing, and comes at the
3345         # beginning of the list, in which case we can handle it like any other
3346         # insertion, and is easier to do so.
3347         if ($replace == $MULTIPLE && $j >= 0) {
3348
3349             # This restriction could be remedied with a little extra work, but
3350             # it won't hopefully ever be necessary
3351             if ($r->[$j]->start != $r->[$j]->end) {
3352                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple when the other range ($r->[$j]) contains more than one code point.  No action taken.");
3353                 return;
3354             }
3355
3356             # Don't add an exact duplicate, as it isn't really a multiple
3357             return if $value eq $r->[$j]->value && $type eq $r->[$j]->type;
3358
3359             trace "Adding multiple record at $j+1 with $start..$end, $value" if main::DEBUG && $to_trace;
3360             my @return = splice @$r,
3361                                 $j+1,
3362                                 0,
3363                                 Range->new($start,
3364                                            $end,
3365                                            Value => $value,
3366                                            Type => $type);
3367             if (main::DEBUG && $to_trace) {
3368                 trace "After splice:";
3369                 trace 'j-2=[', $j-2, ']', $r->[$j-2] if $j >= 2;
3370                 trace 'j-1=[', $j-1, ']', $r->[$j-1] if $j >= 1;
3371                 trace "j  =[", $j, "]", $r->[$j] if $j >= 0;
3372                 trace 'j+1=[', $j+1, ']', $r->[$j+1] if $j < @$r - 1;
3373                 trace 'j+2=[', $j+2, ']', $r->[$j+2] if $j < @$r - 2;
3374                 trace 'j+3=[', $j+3, ']', $r->[$j+3] if $j < @$r - 3;
3375             }
3376             return @return;
3377         }
3378
3379         # Here, have taken care of $NO and $MULTIPLE replaces.
3380         # $j points to the highest affected range.  But it can be < $i or even
3381         # -1.  These happen only if the insertion is entirely in the gap
3382         # between r[$i-1] and r[$i].  Here's why: j < i means that the j loop
3383         # above exited first time through with $end < $r->[$i]->start.  (And
3384         # then we subtracted one from j)  This implies also that $start <
3385         # $r->[$i]->start, but we know from above that $r->[$i-1]->end <
3386         # $start, so the entire input range is in the gap.
3387         if ($j < $i) {
3388
3389             # Here the entire input range is in the gap before $i.
3390
3391             if (main::DEBUG && $to_trace) {
3392                 if ($i) {
3393                     trace "Entire range is between $r->[$i-1] and $r->[$i]";
3394                 }
3395                 else {
3396                     trace "Entire range is before $r->[$i]";
3397                 }
3398             }
3399             return if $operation ne '+'; # Deletion of a non-existent range is
3400                                          # a no-op
3401         }
3402         else {
3403
3404             # Here the entire input range is not in the gap before $i.  There
3405             # is an affected one, and $j points to the highest such one.
3406
3407             # At this point, here is the situation:
3408             # This is not an insertion of a multiple, nor of tentative ($NO)
3409             # data.
3410             #   $i  points to the first element in the current range list that
3411             #            may be affected by this operation.  In fact, we know
3412             #            that the range at $i is affected because we are in
3413             #            the else branch of this 'if'
3414             #   $j  points to the highest affected range.
3415             # In other words,
3416             #   r[$i-1]->end < $start <= r[$i]->end
3417             # And:
3418             #   r[$i-1]->end < $start <= $end <= r[$j]->end
3419             #
3420             # Also:
3421             #   $cdm is a boolean which is set true if and only if this is a
3422             #        change or deletion (multiple was handled above).  In
3423             #        other words, it could be renamed to be just $cd.
3424
3425             # We now have enough information to decide if this call is a no-op
3426             # or not.  It is a no-op if it is a deletion of a non-existent
3427             # range, or an insertion of already existing data.
3428
3429             if (main::DEBUG && $to_trace && ! $cdm
3430                                          && $i == $j
3431                                          && $start >= $r->[$i]->start)
3432             {
3433                     trace "no-op";
3434             }
3435             return if ! $cdm      # change or delete => not no-op
3436                       && $i == $j # more than one affected range => not no-op
3437
3438                       # Here, r[$i-1]->end < $start <= $end <= r[$i]->end
3439                       # Further, $start and/or $end is >= r[$i]->start
3440                       # The test below hence guarantees that
3441                       #     r[$i]->start < $start <= $end <= r[$i]->end
3442                       # This means the input range is contained entirely in
3443                       # the one at $i, so is a no-op
3444                       && $start >= $r->[$i]->start;
3445         }
3446
3447         # Here, we know that some action will have to be taken.  We have
3448         # calculated the offset and length (though adjustments may be needed)
3449         # for the splice.  Now start constructing the replacement list.
3450         my @replacement;
3451         my $splice_start = $i;
3452
3453         my $extends_below;
3454         my $extends_above;
3455
3456         # See if should extend any adjacent ranges.
3457         if ($operation eq '-') { # Don't extend deletions
3458             $extends_below = $extends_above = 0;
3459         }
3460         else {  # Here, should extend any adjacent ranges.  See if there are
3461                 # any.
3462             $extends_below = ($i > 0
3463                             # can't extend unless adjacent
3464                             && $r->[$i-1]->end == $start -1
3465                             # can't extend unless are same standard value
3466                             && $r->[$i-1]->standard_form eq $standard_form
3467                             # can't extend unless share type
3468                             && $r->[$i-1]->type == $type);
3469             $extends_above = ($j+1 < $range_list_size
3470                             && $r->[$j+1]->start == $end +1
3471                             && $r->[$j+1]->standard_form eq $standard_form
3472                             && $r->[$j-1]->type == $type);
3473         }
3474         if ($extends_below && $extends_above) { # Adds to both
3475             $splice_start--;     # start replace at element below
3476             $length += 2;        # will replace on both sides
3477             trace "Extends both below and above ranges" if main::DEBUG && $to_trace;
3478
3479             # The result will fill in any gap, replacing both sides, and
3480             # create one large range.
3481             @replacement = Range->new($r->[$i-1]->start,
3482                                       $r->[$j+1]->end,
3483                                       Value => $value,
3484                                       Type => $type);
3485         }
3486         else {
3487
3488             # Here we know that the result won't just be the conglomeration of
3489             # a new range with both its adjacent neighbors.  But it could
3490             # extend one of them.
3491
3492             if ($extends_below) {
3493
3494                 # Here the new element adds to the one below, but not to the
3495                 # one above.  If inserting, and only to that one range,  can
3496                 # just change its ending to include the new one.
3497                 if ($length == 0 && ! $cdm) {
3498                     $r->[$i-1]->set_end($end);
3499                     trace "inserted range extends range to below so it is now $r->[$i-1]" if main::DEBUG && $to_trace;
3500                     return;
3501                 }
3502                 else {
3503                     trace "Changing inserted range to start at ", sprintf("%04X",  $r->[$i-1]->start), " instead of ", sprintf("%04X", $start) if main::DEBUG && $to_trace;
3504                     $splice_start--;        # start replace at element below
3505                     $length++;              # will replace the element below
3506                     $start = $r->[$i-1]->start;
3507                 }
3508             }
3509             elsif ($extends_above) {
3510
3511                 # Here the new element adds to the one above, but not below.
3512                 # Mirror the code above
3513                 if ($length == 0 && ! $cdm) {
3514                     $r->[$j+1]->set_start($start);
3515                     trace "inserted range extends range to above so it is now $r->[$j+1]" if main::DEBUG && $to_trace;
3516                     return;
3517                 }
3518                 else {
3519                     trace "Changing inserted range to end at ", sprintf("%04X",  $r->[$j+1]->end), " instead of ", sprintf("%04X", $end) if main::DEBUG && $to_trace;
3520                     $length++;        # will replace the element above
3521                     $end = $r->[$j+1]->end;
3522                 }
3523             }
3524
3525             trace "Range at $i is $r->[$i]" if main::DEBUG && $to_trace;
3526
3527             # Finally, here we know there will have to be a splice.
3528             # If the change or delete affects only the highest portion of the
3529             # first affected range, the range will have to be split.  The
3530             # splice will remove the whole range, but will replace it by a new
3531             # range containing just the unaffected part.  So, in this case,
3532             # add to the replacement list just this unaffected portion.
3533             if (! $extends_below
3534                 && $start > $r->[$i]->start && $start <= $r->[$i]->end)
3535             {
3536                 push @replacement,
3537                     Range->new($r->[$i]->start,
3538                                $start - 1,
3539                                Value => $r->[$i]->value,
3540                                Type => $r->[$i]->type);
3541             }
3542
3543             # In the case of an insert or change, but not a delete, we have to
3544             # put in the new stuff;  this comes next.
3545             if ($operation eq '+') {
3546                 push @replacement, Range->new($start,
3547                                               $end,
3548                                               Value => $value,
3549                                               Type => $type);
3550             }
3551
3552             trace "Range at $j is $r->[$j]" if main::DEBUG && $to_trace && $j != $i;
3553             #trace "$end >=", $r->[$j]->start, " && $end <", $r->[$j]->end if main::DEBUG && $to_trace;
3554
3555             # And finally, if we're changing or deleting only a portion of the
3556             # highest affected range, it must be split, as the lowest one was.
3557             if (! $extends_above
3558                 && $j >= 0  # Remember that j can be -1 if before first
3559                             # current element
3560                 && $end >= $r->[$j]->start
3561                 && $end < $r->[$j]->end)
3562             {
3563                 push @replacement,
3564                     Range->new($end + 1,
3565                                $r->[$j]->end,
3566                                Value => $r->[$j]->value,
3567                                Type => $r->[$j]->type);
3568             }
3569         }
3570
3571         # And do the splice, as calculated above
3572         if (main::DEBUG && $to_trace) {
3573             trace "replacing $length element(s) at $i with ";
3574             foreach my $replacement (@replacement) {
3575                 trace "    $replacement";
3576             }
3577             trace "Before splice:";
3578             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3579             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3580             trace "i  =[", $i, "]", $r->[$i];
3581             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3582             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3583         }
3584
3585         my @return = splice @$r, $splice_start, $length, @replacement;
3586
3587         if (main::DEBUG && $to_trace) {
3588             trace "After splice:";
3589             trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3590             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3591             trace "i  =[", $i, "]", $r->[$i];
3592             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3593             trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3594             trace "removed @return";
3595         }
3596
3597         # An actual deletion could have changed the maximum in the list.
3598         # There was no deletion if the splice didn't return something, but
3599         # otherwise recalculate it.  This is done too rarely to worry about
3600         # performance.
3601         if ($operation eq '-' && @return) {
3602             $max{$addr} = $r->[-1]->end;
3603         }
3604         return @return;
3605     }
3606
3607     sub reset_each_range {  # reset the iterator for each_range();
3608         my $self = shift;
3609         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3610
3611         no overloading;
3612         undef $each_range_iterator{0+$self};
3613         return;
3614     }
3615
3616     sub each_range {
3617         # Iterate over each range in a range list.  Results are undefined if
3618         # the range list is changed during the iteration.
3619
3620         my $self = shift;
3621         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3622
3623         my $addr; { no overloading; $addr = 0+$self; }
3624
3625         return if $self->is_empty;
3626
3627         $each_range_iterator{$addr} = -1
3628                                 if ! defined $each_range_iterator{$addr};
3629         $each_range_iterator{$addr}++;
3630         return $ranges{$addr}->[$each_range_iterator{$addr}]
3631                         if $each_range_iterator{$addr} < @{$ranges{$addr}};
3632         undef $each_range_iterator{$addr};
3633         return;
3634     }
3635
3636     sub count {        # Returns count of code points in range list
3637         my $self = shift;
3638         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3639
3640         my $addr; { no overloading; $addr = 0+$self; }
3641
3642         my $count = 0;
3643         foreach my $range (@{$ranges{$addr}}) {
3644             $count += $range->end - $range->start + 1;
3645         }
3646         return $count;
3647     }
3648
3649     sub delete_range {    # Delete a range
3650         my $self = shift;
3651         my $start = shift;
3652         my $end = shift;
3653
3654         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3655
3656         return $self->_add_delete('-', $start, $end, "");
3657     }
3658
3659     sub is_empty { # Returns boolean as to if a range list is empty
3660         my $self = shift;
3661         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3662
3663         no overloading;
3664         return scalar @{$ranges{0+$self}} == 0;
3665     }
3666
3667     sub hash {
3668         # Quickly returns a scalar suitable for separating tables into
3669         # buckets, i.e. it is a hash function of the contents of a table, so
3670         # there are relatively few conflicts.
3671
3672         my $self = shift;
3673         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3674
3675         my $addr; { no overloading; $addr = 0+$self; }
3676
3677         # These are quickly computable.  Return looks like 'min..max;count'
3678         return $self->min . "..$max{$addr};" . scalar @{$ranges{$addr}};
3679     }
3680 } # End closure for _Range_List_Base
3681
3682 package Range_List;
3683 use base '_Range_List_Base';
3684
3685 # A Range_List is a range list for match tables; i.e. the range values are
3686 # not significant.  Thus a number of operations can be safely added to it,
3687 # such as inversion, intersection.  Note that union is also an unsafe
3688 # operation when range values are cared about, and that method is in the base
3689 # class, not here.  But things are set up so that that method is callable only
3690 # during initialization.  Only in this derived class, is there an operation
3691 # that combines two tables.  A Range_Map can thus be used to initialize a
3692 # Range_List, and its mappings will be in the list, but are not significant to
3693 # this class.
3694
3695 sub trace { return main::trace(@_); }
3696
3697 { # Closure
3698
3699     use overload
3700         fallback => 0,
3701         '+' => sub { my $self = shift;
3702                     my $other = shift;
3703
3704                     return $self->_union($other)
3705                 },
3706         '&' => sub { my $self = shift;
3707                     my $other = shift;
3708
3709                     return $self->_intersect($other, 0);
3710                 },
3711         '~' => "_invert",
3712         '-' => "_subtract",
3713     ;
3714
3715     sub _invert {
3716         # Returns a new Range_List that gives all code points not in $self.
3717
3718         my $self = shift;
3719
3720         my $new = Range_List->new;
3721
3722         # Go through each range in the table, finding the gaps between them
3723         my $max = -1;   # Set so no gap before range beginning at 0
3724         for my $range ($self->ranges) {
3725             my $start = $range->start;
3726             my $end   = $range->end;
3727
3728             # If there is a gap before this range, the inverse will contain
3729             # that gap.
3730             if ($start > $max + 1) {
3731                 $new->add_range($max + 1, $start - 1);
3732             }
3733             $max = $end;
3734         }
3735
3736         # And finally, add the gap from the end of the table to the max
3737         # possible code point
3738         if ($max < $LAST_UNICODE_CODEPOINT) {
3739             $new->add_range($max + 1, $LAST_UNICODE_CODEPOINT);
3740         }
3741         return $new;
3742     }
3743
3744     sub _subtract {
3745         # Returns a new Range_List with the argument deleted from it.  The
3746         # argument can be a single code point, a range, or something that has
3747         # a range, with the _range_list() method on it returning them
3748
3749         my $self = shift;
3750         my $other = shift;
3751         my $reversed = shift;
3752         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3753
3754         if ($reversed) {
3755             Carp::my_carp_bug("Can't cope with a "
3756              .  __PACKAGE__
3757              . " being the second parameter in a '-'.  Subtraction ignored.");
3758             return $self;
3759         }
3760
3761         my $new = Range_List->new(Initialize => $self);
3762
3763         if (! ref $other) { # Single code point
3764             $new->delete_range($other, $other);
3765         }
3766         elsif ($other->isa('Range')) {
3767             $new->delete_range($other->start, $other->end);
3768         }
3769         elsif ($other->can('_range_list')) {
3770             foreach my $range ($other->_range_list->ranges) {
3771                 $new->delete_range($range->start, $range->end);
3772             }
3773         }
3774         else {
3775             Carp::my_carp_bug("Can't cope with a "
3776                         . ref($other)
3777                         . " argument to '-'.  Subtraction ignored."
3778                         );
3779             return $self;
3780         }
3781
3782         return $new;
3783     }
3784
3785     sub _intersect {
3786         # Returns either a boolean giving whether the two inputs' range lists
3787         # intersect (overlap), or a new Range_List containing the intersection
3788         # of the two lists.  The optional final parameter being true indicates
3789         # to do the check instead of the intersection.
3790
3791         my $a_object = shift;
3792         my $b_object = shift;
3793         my $check_if_overlapping = shift;
3794         $check_if_overlapping = 0 unless defined $check_if_overlapping;
3795         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3796
3797         if (! defined $b_object) {
3798             my $message = "";
3799             $message .= $a_object->_owner_name_of if defined $a_object;
3800             Carp::my_carp_bug($message .= "Called with undefined value.  Intersection not done.");
3801             return;
3802         }
3803
3804         # a & b = !(!a | !b), or in our terminology = ~ ( ~a + -b )
3805         # Thus the intersection could be much more simply be written:
3806         #   return ~(~$a_object + ~$b_object);
3807         # But, this is slower, and when taking the inverse of a large
3808         # range_size_1 table, back when such tables were always stored that
3809         # way, it became prohibitively slow, hence the code was changed to the
3810         # below
3811
3812         if ($b_object->isa('Range')) {
3813             $b_object = Range_List->new(Initialize => $b_object,
3814                                         Owner => $a_object->_owner_name_of);
3815         }
3816         $b_object = $b_object->_range_list if $b_object->can('_range_list');
3817
3818         my @a_ranges = $a_object->ranges;
3819         my @b_ranges = $b_object->ranges;
3820
3821         #local $to_trace = 1 if main::DEBUG;
3822         trace "intersecting $a_object with ", scalar @a_ranges, "ranges and $b_object with", scalar @b_ranges, " ranges" if main::DEBUG && $to_trace;
3823
3824         # Start with the first range in each list
3825         my $a_i = 0;
3826         my $range_a = $a_ranges[$a_i];
3827         my $b_i = 0;
3828         my $range_b = $b_ranges[$b_i];
3829
3830         my $new = __PACKAGE__->new(Owner => $a_object->_owner_name_of)
3831                                                 if ! $check_if_overlapping;
3832
3833         # If either list is empty, there is no intersection and no overlap
3834         if (! defined $range_a || ! defined $range_b) {
3835             return $check_if_overlapping ? 0 : $new;
3836         }
3837         trace "range_a[$a_i]=$range_a; range_b[$b_i]=$range_b" if main::DEBUG && $to_trace;
3838
3839         # Otherwise, must calculate the intersection/overlap.  Start with the
3840         # very first code point in each list
3841         my $a = $range_a->start;
3842         my $b = $range_b->start;
3843
3844         # Loop through all the ranges of each list; in each iteration, $a and
3845         # $b are the current code points in their respective lists
3846         while (1) {
3847
3848             # If $a and $b are the same code point, ...
3849             if ($a == $b) {
3850
3851                 # it means the lists overlap.  If just checking for overlap
3852                 # know the answer now,
3853                 return 1 if $check_if_overlapping;
3854
3855                 # The intersection includes this code point plus anything else
3856                 # common to both current ranges.
3857                 my $start = $a;
3858                 my $end = main::min($range_a->end, $range_b->end);
3859                 if (! $check_if_overlapping) {
3860                     trace "adding intersection range ", sprintf("%04X", $start) . ".." . sprintf("%04X", $end) if main::DEBUG && $to_trace;
3861                     $new->add_range($start, $end);
3862                 }
3863
3864                 # Skip ahead to the end of the current intersect
3865                 $a = $b = $end;
3866
3867                 # If the current intersect ends at the end of either range (as
3868                 # it must for at least one of them), the next possible one
3869                 # will be the beginning code point in it's list's next range.
3870                 if ($a == $range_a->end) {
3871                     $range_a = $a_ranges[++$a_i];
3872                     last unless defined $range_a;
3873                     $a = $range_a->start;
3874                 }
3875                 if ($b == $range_b->end) {
3876                     $range_b = $b_ranges[++$b_i];
3877                     last unless defined $range_b;
3878                     $b = $range_b->start;
3879                 }
3880
3881                 trace "range_a[$a_i]=$range_a; range_b[$b_i]=$range_b" if main::DEBUG && $to_trace;
3882             }
3883             elsif ($a < $b) {
3884
3885                 # Not equal, but if the range containing $a encompasses $b,
3886                 # change $a to be the middle of the range where it does equal
3887                 # $b, so the next iteration will get the intersection
3888                 if ($range_a->end >= $b) {
3889                     $a = $b;
3890                 }
3891                 else {
3892
3893                     # Here, the current range containing $a is entirely below
3894                     # $b.  Go try to find a range that could contain $b.
3895                     $a_i = $a_object->_search_ranges($b);
3896
3897                     # If no range found, quit.
3898                     last unless defined $a_i;
3899
3900                     # The search returns $a_i, such that
3901                     #   range_a[$a_i-1]->end < $b <= range_a[$a_i]->end
3902                     # Set $a to the beginning of this new range, and repeat.
3903                     $range_a = $a_ranges[$a_i];
3904                     $a = $range_a->start;
3905                 }
3906             }
3907             else { # Here, $b < $a.
3908
3909                 # Mirror image code to the leg just above
3910                 if ($range_b->end >= $a) {
3911                     $b = $a;
3912                 }
3913                 else {
3914                     $b_i = $b_object->_search_ranges($a);
3915                     last unless defined $b_i;
3916                     $range_b = $b_ranges[$b_i];
3917                     $b = $range_b->start;
3918                 }
3919             }
3920         } # End of looping through ranges.
3921
3922         # Intersection fully computed, or now know that there is no overlap
3923         return $check_if_overlapping ? 0 : $new;
3924     }
3925
3926     sub overlaps {
3927         # Returns boolean giving whether the two arguments overlap somewhere
3928
3929         my $self = shift;
3930         my $other = shift;
3931         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3932
3933         return $self->_intersect($other, 1);
3934     }
3935
3936     sub add_range {
3937         # Add a range to the list.
3938
3939         my $self = shift;
3940         my $start = shift;
3941         my $end = shift;
3942         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3943
3944         return $self->_add_delete('+', $start, $end, "");
3945     }
3946
3947     my $non_ASCII = (ord('A') != 65);   # Assumes test on same platform
3948
3949     sub is_code_point_usable {
3950         # This used only for making the test script.  See if the input
3951         # proposed trial code point is one that Perl will handle.  If second
3952         # parameter is 0, it won't select some code points for various
3953         # reasons, noted below.
3954
3955         my $code = shift;
3956         my $try_hard = shift;
3957         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3958
3959         return 0 if $code < 0;                # Never use a negative
3960
3961         # For non-ASCII, we shun the characters that don't have Perl encoding-
3962         # independent symbols for them.  'A' is such a symbol, so is "\n".
3963         return $try_hard if $non_ASCII
3964                             && $code <= 0xFF
3965                             && ($code >= 0x7F
3966                                 || ($code >= 0x0E && $code <= 0x1F)
3967                                 || ($code >= 0x01 && $code <= 0x06)
3968                                 || $code == 0x0B);
3969
3970         # shun null.  I'm (khw) not sure why this was done, but NULL would be
3971         # the character very frequently used.
3972         return $try_hard if $code == 0x0000;
3973
3974         return 0 if $try_hard;  # XXX Temporary until fix utf8.c
3975
3976         # shun non-character code points.
3977         return $try_hard if $code >= 0xFDD0 && $code <= 0xFDEF;
3978         return $try_hard if ($code & 0xFFFE) == 0xFFFE; # includes FFFF
3979
3980         return $try_hard if $code > $LAST_UNICODE_CODEPOINT;   # keep in range
3981         return $try_hard if $code >= 0xD800 && $code <= 0xDFFF; # no surrogate
3982
3983         return 1;
3984     }
3985
3986     sub get_valid_code_point {
3987         # Return a code point that's part of the range list.  Returns nothing