lib/feature.pm

   1 package feature;
   2
   3 our $VERSION = '1.17';
   4
   5 # (feature name) => (internal name, used in %^H)
   6 my %feature = (
   7     switch          => 'feature_switch',
   8     say             => "feature_say",
   9     state           => "feature_state",
  10     unicode_strings => "feature_unicode",
  11 );
  12
  13 # This gets set (for now) in $^H as well as in %^H,
  14 # for runtime speed of the uc/lc/ucfirst/lcfirst functions.
  15 # See HINT_UNI_8_BIT in perl.h.
  16 our $hint_uni8bit = 0x00000800;
  17
  18 # NB. the latest bundle must be loaded by the -E switch (see toke.c)
  19
  20 my %feature_bundle = (
  21     "5.10" => [qw(switch say state)],
  22     "5.11" => [qw(switch say state unicode_strings)],
  23     "5.12" => [qw(switch say state unicode_strings)],
  24     "5.13" => [qw(switch say state unicode_strings)],
  25 );
  26
  27 # special case
  28 $feature_bundle{"5.9.5"} = $feature_bundle{"5.10"};
  29
  30 # TODO:
  31 # - think about versioned features (use feature switch => 2)
  32
  33 =head1 NAME
  34
  35 feature - Perl pragma to enable new features
  36
  37 =head1 SYNOPSIS
  38
  39     use feature qw(switch say);
  40     given ($foo) {
  41         when (1)          { say "\$foo == 1" }
  42         when ([2,3])      { say "\$foo == 2 || \$foo == 3" }
  43         when (/^a[bc]d$/) { say "\$foo eq 'abd' || \$foo eq 'acd'" }
  44         when ($_ > 100)   { say "\$foo > 100" }
  45         default           { say "None of the above" }
  46     }
  47
  48     use feature ':5.10'; # loads all features available in perl 5.10
  49
  50 =head1 DESCRIPTION
  51
  52 It is usually impossible to add new syntax to Perl without breaking
  53 some existing programs. This pragma provides a way to minimize that
  54 risk. New syntactic constructs, or new semantic meanings to older
  55 constructs, can be enabled by C<use feature 'foo'>, and will be parsed
  56 only when the appropriate feature pragma is in scope.
  57
  58 =head2 Lexical effect
  59
  60 Like other pragmas (C<use strict>, for example), features have a lexical
  61 effect. C<use feature qw(foo)> will only make the feature "foo" available
  62 from that point to the end of the enclosing block.
  63
  64     {
  65         use feature 'say';
  66         say "say is available here";
  67     }
  68     print "But not here.\n";
  69
  70 =head2 C<no feature>
  71
  72 Features can also be turned off by using C<no feature "foo">. This too
  73 has lexical effect.
  74
  75     use feature 'say';
  76     say "say is available here";
  77     {
  78         no feature 'say';
  79         print "But not here.\n";
  80     }
  81     say "Yet it is here.";
  82
  83 C<no feature> with no features specified will turn off all features.
  84
  85 =head2 The 'switch' feature
  86
  87 C<use feature 'switch'> tells the compiler to enable the Perl 6
  88 given/when construct.
  89
  90 See L<perlsyn/"Switch statements"> for details.
  91
  92 =head2 The 'say' feature
  93
  94 C<use feature 'say'> tells the compiler to enable the Perl 6
  95 C<say> function.
  96
  97 See L<perlfunc/say> for details.
  98
  99 =head2 the 'state' feature
 100
 101 C<use feature 'state'> tells the compiler to enable C<state>
 102 variables.
 103
 104 See L<perlsub/"Persistent Private Variables"> for details.
 105
 106 =head2 the 'unicode_strings' feature
 107
 108 C<use feature 'unicode_strings'> tells the compiler to treat
 109 all strings outside of C<use locale> and C<use bytes> as Unicode. It is
 110 available starting with Perl 5.11.3, but is not fully implemented.
 111
 112 See L<perlunicode/The "Unicode Bug"> for details.
 113
 114 =head1 FEATURE BUNDLES
 115
 116 It's possible to load a whole slew of features in one go, using
 117 a I<feature bundle>. The name of a feature bundle is prefixed with
 118 a colon, to distinguish it from an actual feature. At present, the
 119 only feature bundle is C<use feature ":5.10"> which is equivalent
 120 to C<use feature qw(switch say state)>.
 121
 122 Specifying sub-versions such as the C<0> in C<5.10.0> in feature bundles has
 123 no effect: feature bundles are guaranteed to be the same for all sub-versions.
 124
 125 =head1 IMPLICIT LOADING
 126
 127 There are two ways to load the C<feature> pragma implicitly :
 128
 129 =over 4
 130
 131 =item *
 132
 133 By using the C<-E> switch on the command-line instead of C<-e>. It enables
 134 all available features in the main compilation unit (that is, the one-liner.)
 135
 136 =item *
 137
 138 By requiring explicitly a minimal Perl version number for your program, with
 139 the C<use VERSION> construct, and when the version is higher than or equal to
 140 5.10.0. That is,
 141
 142     use 5.10.0;
 143
 144 will do an implicit
 145
 146     use feature ':5.10';
 147
 148 and so on. Note how the trailing sub-version is automatically stripped from the
 149 version.
 150
 151 But to avoid portability warnings (see L<perlfunc/use>), you may prefer:
 152
 153     use 5.010;
 154
 155 with the same effect.
 156
 157 =back
 158
 159 =cut
 160
 161 sub import {
 162     my $class = shift;
 163     if (@_ == 0) {
 164         croak("No features specified");
 165     }
 166     while (@_) {
 167         my $name = shift(@_);
 168         if (substr($name, 0, 1) eq ":") {
 169             my $v = substr($name, 1);
 170             if (!exists $feature_bundle{$v}) {
 171                 $v =~ s/^([0-9]+)\.([0-9]+).[0-9]+$/$1.$2/;
 172                 if (!exists $feature_bundle{$v}) {
 173                     unknown_feature_bundle(substr($name, 1));
 174                 }
 175             }
 176             unshift @_, @{$feature_bundle{$v}};
 177             next;
 178         }
 179         if (!exists $feature{$name}) {
 180             unknown_feature($name);
 181         }
 182         $^H{$feature{$name}} = 1;
 183         $^H |= $hint_uni8bit if $name eq 'unicode_strings';
 184     }
 185 }
 186
 187 sub unimport {
 188     my $class = shift;
 189
 190     # A bare C<no feature> should disable *all* features
 191     if (!@_) {
 192         delete @^H{ values(%feature) };
 193         $^H &= ~ $hint_uni8bit;
 194         return;
 195     }
 196
 197     while (@_) {
 198         my $name = shift;
 199         if (substr($name, 0, 1) eq ":") {
 200             my $v = substr($name, 1);
 201             if (!exists $feature_bundle{$v}) {
 202                 $v =~ s/^([0-9]+)\.([0-9]+).[0-9]+$/$1.$2/;
 203                 if (!exists $feature_bundle{$v}) {
 204                     unknown_feature_bundle(substr($name, 1));
 205                 }
 206             }
 207             unshift @_, @{$feature_bundle{$v}};
 208             next;
 209         }
 210         if (!exists($feature{$name})) {
 211             unknown_feature($name);
 212         }
 213         else {
 214             delete $^H{$feature{$name}};
 215             $^H &= ~ $hint_uni8bit if $name eq 'unicode_strings';
 216         }
 217     }
 218 }
 219
 220 sub unknown_feature {
 221     my $feature = shift;
 222     croak(sprintf('Feature "%s" is not supported by Perl %vd',
 223             $feature, $^V));
 224 }
 225
 226 sub unknown_feature_bundle {
 227     my $feature = shift;
 228     croak(sprintf('Feature bundle "%s" is not supported by Perl %vd',
 229             $feature, $^V));
 230 }
 231
 232 sub croak {
 233     require Carp;
 234     Carp::croak(@_);
 235 }
 236
 237 1;