This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
b126c279c265cb8bcfa92a3511459c578422da3d
[perl5.git] / dist / PathTools / lib / File / Spec / OS2.pm
1 package File::Spec::OS2;
2
3 use strict;
4 require File::Spec::Unix;
5
6 our $VERSION = '3.69';
7 $VERSION =~ tr/_//d;
8
9 our @ISA = qw(File::Spec::Unix);
10
11 sub devnull {
12     return "/dev/nul";
13 }
14
15 sub case_tolerant {
16     return 1;
17 }
18
19 sub file_name_is_absolute {
20     my ($self,$file) = @_;
21     return scalar($file =~ m{^([a-z]:)?[\\/]}is);
22 }
23
24 sub path {
25     my $path = $ENV{PATH};
26     $path =~ s:\\:/:g;
27     my @path = split(';',$path);
28     foreach (@path) { $_ = '.' if $_ eq '' }
29     return @path;
30 }
31
32 sub _cwd {
33     # In OS/2 the "require Cwd" is unnecessary bloat.
34     return Cwd::sys_cwd();
35 }
36
37 sub tmpdir {
38     my $cached = $_[0]->_cached_tmpdir(qw 'TMPDIR TEMP TMP');
39     return $cached if defined $cached;
40     my @d = @ENV{qw(TMPDIR TEMP TMP)};  # function call could autovivivy
41     $_[0]->_cache_tmpdir(
42         $_[0]->_tmpdir( @d, '/tmp', '/' ), qw 'TMPDIR TEMP TMP'
43     );
44 }
45
46 sub catdir {
47     my $self = shift;
48     my @args = @_;
49     foreach (@args) {
50         tr[\\][/];
51         # append a backslash to each argument unless it has one there
52         $_ .= "/" unless m{/$};
53     }
54     return $self->canonpath(join('', @args));
55 }
56
57 sub canonpath {
58     my ($self,$path) = @_;
59     return unless defined $path;
60
61     $path =~ s/^([a-z]:)/\l$1/s;
62     $path =~ s|\\|/|g;
63     $path =~ s|([^/])/+|$1/|g;                  # xx////xx  -> xx/xx
64     $path =~ s|(/\.)+/|/|g;                     # xx/././xx -> xx/xx
65     $path =~ s|^(\./)+(?=[^/])||s;              # ./xx      -> xx
66     $path =~ s|/\Z(?!\n)||
67              unless $path =~ m#^([a-z]:)?/\Z(?!\n)#si;# xx/       -> xx
68     $path =~ s{^/\.\.$}{/};                     # /..    -> /
69     1 while $path =~ s{^/\.\.}{};               # /../xx -> /xx
70     return $path;
71 }
72
73
74 sub splitpath {
75     my ($self,$path, $nofile) = @_;
76     my ($volume,$directory,$file) = ('','','');
77     if ( $nofile ) {
78         $path =~ 
79             m{^( (?:[a-zA-Z]:|(?:\\\\|//)[^\\/]+[\\/][^\\/]+)? ) 
80                  (.*)
81              }xs;
82         $volume    = $1;
83         $directory = $2;
84     }
85     else {
86         $path =~ 
87             m{^ ( (?: [a-zA-Z]: |
88                       (?:\\\\|//)[^\\/]+[\\/][^\\/]+
89                   )?
90                 )
91                 ( (?:.*[\\\\/](?:\.\.?\Z(?!\n))?)? )
92                 (.*)
93              }xs;
94         $volume    = $1;
95         $directory = $2;
96         $file      = $3;
97     }
98
99     return ($volume,$directory,$file);
100 }
101
102
103 sub splitdir {
104     my ($self,$directories) = @_ ;
105     split m|[\\/]|, $directories, -1;
106 }
107
108
109 sub catpath {
110     my ($self,$volume,$directory,$file) = @_;
111
112     # If it's UNC, make sure the glue separator is there, reusing
113     # whatever separator is first in the $volume
114     $volume .= $1
115         if ( $volume =~ m@^([\\/])[\\/][^\\/]+[\\/][^\\/]+\Z(?!\n)@s &&
116              $directory =~ m@^[^\\/]@s
117            ) ;
118
119     $volume .= $directory ;
120
121     # If the volume is not just A:, make sure the glue separator is 
122     # there, reusing whatever separator is first in the $volume if possible.
123     if ( $volume !~ m@^[a-zA-Z]:\Z(?!\n)@s &&
124          $volume =~ m@[^\\/]\Z(?!\n)@      &&
125          $file   =~ m@[^\\/]@
126        ) {
127         $volume =~ m@([\\/])@ ;
128         my $sep = $1 ? $1 : '/' ;
129         $volume .= $sep ;
130     }
131
132     $volume .= $file ;
133
134     return $volume ;
135 }
136
137
138 sub abs2rel {
139     my($self,$path,$base) = @_;
140
141     # Clean up $path
142     if ( ! $self->file_name_is_absolute( $path ) ) {
143         $path = $self->rel2abs( $path ) ;
144     } else {
145         $path = $self->canonpath( $path ) ;
146     }
147
148     # Figure out the effective $base and clean it up.
149     if ( !defined( $base ) || $base eq '' ) {
150         $base = $self->_cwd();
151     } elsif ( ! $self->file_name_is_absolute( $base ) ) {
152         $base = $self->rel2abs( $base ) ;
153     } else {
154         $base = $self->canonpath( $base ) ;
155     }
156
157     # Split up paths
158     my ( $path_volume, $path_directories, $path_file ) = $self->splitpath( $path, 1 ) ;
159     my ( $base_volume, $base_directories ) = $self->splitpath( $base, 1 ) ;
160     return $path unless $path_volume eq $base_volume;
161
162     # Now, remove all leading components that are the same
163     my @pathchunks = $self->splitdir( $path_directories );
164     my @basechunks = $self->splitdir( $base_directories );
165
166     while ( @pathchunks && 
167             @basechunks && 
168             lc( $pathchunks[0] ) eq lc( $basechunks[0] ) 
169           ) {
170         shift @pathchunks ;
171         shift @basechunks ;
172     }
173
174     # No need to catdir, we know these are well formed.
175     $path_directories = CORE::join( '/', @pathchunks );
176     $base_directories = CORE::join( '/', @basechunks );
177
178     # $base_directories now contains the directories the resulting relative
179     # path must ascend out of before it can descend to $path_directory.  So, 
180     # replace all names with $parentDir
181
182     #FA Need to replace between backslashes...
183     $base_directories =~ s|[^\\/]+|..|g ;
184
185     # Glue the two together, using a separator if necessary, and preventing an
186     # empty result.
187
188     #FA Must check that new directories are not empty.
189     if ( $path_directories ne '' && $base_directories ne '' ) {
190         $path_directories = "$base_directories/$path_directories" ;
191     } else {
192         $path_directories = "$base_directories$path_directories" ;
193     }
194
195     return $self->canonpath( 
196         $self->catpath( "", $path_directories, $path_file ) 
197     ) ;
198 }
199
200
201 sub rel2abs {
202     my ($self,$path,$base ) = @_;
203
204     if ( ! $self->file_name_is_absolute( $path ) ) {
205
206         if ( !defined( $base ) || $base eq '' ) {
207             $base = $self->_cwd();
208         }
209         elsif ( ! $self->file_name_is_absolute( $base ) ) {
210             $base = $self->rel2abs( $base ) ;
211         }
212         else {
213             $base = $self->canonpath( $base ) ;
214         }
215
216         my ( $path_directories, $path_file ) =
217             ($self->splitpath( $path, 1 ))[1,2] ;
218
219         my ( $base_volume, $base_directories ) =
220             $self->splitpath( $base, 1 ) ;
221
222         $path = $self->catpath( 
223             $base_volume, 
224             $self->catdir( $base_directories, $path_directories ), 
225             $path_file
226         ) ;
227     }
228
229     return $self->canonpath( $path ) ;
230 }
231
232 1;
233 __END__
234
235 =head1 NAME
236
237 File::Spec::OS2 - methods for OS/2 file specs
238
239 =head1 SYNOPSIS
240
241  require File::Spec::OS2; # Done internally by File::Spec if needed
242
243 =head1 DESCRIPTION
244
245 See L<File::Spec> and L<File::Spec::Unix>.  This package overrides the
246 implementation of these methods, not the semantics.
247
248 Amongst the changes made for OS/2 are...
249
250 =over 4
251
252 =item tmpdir
253
254 Modifies the list of places temp directory information is looked for.
255
256     $ENV{TMPDIR}
257     $ENV{TEMP}
258     $ENV{TMP}
259     /tmp
260     /
261
262 =item splitpath
263
264 Volumes can be drive letters or UNC sharenames (\\server\share).
265
266 =back
267
268 =head1 COPYRIGHT
269
270 Copyright (c) 2004 by the Perl 5 Porters.  All rights reserved.
271
272 This program is free software; you can redistribute it and/or modify
273 it under the same terms as Perl itself.
274
275 =cut