This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
b0b3175407aa74b5bb43b26f4714bfeab31f61ab
[perl5.git] / ext / B / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPpPAD_STATE
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          CVf_METHOD CVf_LOCKED CVf_LVALUE
21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED),
23          ($] < 5.009 ? 'PMf_SKIPWHITE' : 'RXf_SKIPWHITE');
24 $VERSION = 0.83;
25 use strict;
26 use vars qw/$AUTOLOAD/;
27 use warnings ();
28
29 # Changes between 0.50 and 0.51:
30 # - fixed nulled leave with live enter in sort { }
31 # - fixed reference constants (\"str")
32 # - handle empty programs gracefully
33 # - handle infinte loops (for (;;) {}, while (1) {})
34 # - differentiate between `for my $x ...' and `my $x; for $x ...'
35 # - various minor cleanups
36 # - moved globals into an object
37 # - added `-u', like B::C
38 # - package declarations using cop_stash
39 # - subs, formats and code sorted by cop_seq
40 # Changes between 0.51 and 0.52:
41 # - added pp_threadsv (special variables under USE_5005THREADS)
42 # - added documentation
43 # Changes between 0.52 and 0.53:
44 # - many changes adding precedence contexts and associativity
45 # - added `-p' and `-s' output style options
46 # - various other minor fixes
47 # Changes between 0.53 and 0.54:
48 # - added support for new `for (1..100)' optimization,
49 #   thanks to Gisle Aas
50 # Changes between 0.54 and 0.55:
51 # - added support for new qr// construct
52 # - added support for new pp_regcreset OP
53 # Changes between 0.55 and 0.56:
54 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
55 # - fixed $# on non-lexicals broken in last big rewrite
56 # - added temporary fix for change in opcode of OP_STRINGIFY
57 # - fixed problem in 0.54's for() patch in `for (@ary)'
58 # - fixed precedence in conditional of ?:
59 # - tweaked list paren elimination in `my($x) = @_'
60 # - made continue-block detection trickier wrt. null ops
61 # - fixed various prototype problems in pp_entersub
62 # - added support for sub prototypes that never get GVs
63 # - added unquoting for special filehandle first arg in truncate
64 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
65 # - added semicolons at the ends of blocks
66 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
67 # Changes between 0.56 and 0.561:
68 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
69 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
70 # Changes between 0.561 and 0.57:
71 # - stylistic changes to symbolic constant stuff
72 # - handled scope in s///e replacement code
73 # - added unquote option for expanding "" into concats, etc.
74 # - split method and proto parts of pp_entersub into separate functions
75 # - various minor cleanups
76 # Changes after 0.57:
77 # - added parens in \&foo (patch by Albert Dvornik)
78 # Changes between 0.57 and 0.58:
79 # - fixed `0' statements that weren't being printed
80 # - added methods for use from other programs
81 #   (based on patches from James Duncan and Hugo van der Sanden)
82 # - added -si and -sT to control indenting (also based on a patch from Hugo)
83 # - added -sv to print something else instead of '???'
84 # - preliminary version of utf8 tr/// handling
85 # Changes after 0.58:
86 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
87 # - added support for Hugo's new OP_SETSTATE (like nextstate)
88 # Changes between 0.58 and 0.59
89 # - added support for Chip's OP_METHOD_NAMED
90 # - added support for Ilya's OPpTARGET_MY optimization
91 # - elided arrows before `()' subscripts when possible
92 # Changes between 0.59 and 0.60
93 # - support for method attribues was added
94 # - some warnings fixed
95 # - separate recognition of constant subs
96 # - rewrote continue block handling, now recoginizing for loops
97 # - added more control of expanding control structures
98 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
99 # - many bug-fixes
100 # - support for pragmas and 'use'
101 # - support for the little-used $[ variable
102 # - support for __DATA__ sections
103 # - UTF8 support
104 # - BEGIN, CHECK, INIT and END blocks
105 # - scoping of subroutine declarations fixed
106 # - compile-time output from the input program can be suppressed, so that the
107 #   output is just the deparsed code. (a change to O.pm in fact)
108 # - our() declarations
109 # - *all* the known bugs are now listed in the BUGS section
110 # - comprehensive test mechanism (TEST -deparse)
111 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
112 # - bug-fixes
113 # - new switch -P
114 # - support for command-line switches (-l, -0, etc.)
115 # Changes between 0.63 and 0.64
116 # - support for //, CHECK blocks, and assertions
117 # - improved handling of foreach loops and lexicals
118 # - option to use Data::Dumper for constants
119 # - more bug fixes
120 # - discovered lots more bugs not yet fixed
121 #
122 # ...
123 #
124 # Changes between 0.72 and 0.73
125 # - support new switch constructs
126
127 # Todo:
128 #  (See also BUGS section at the end of this file)
129 #
130 # - finish tr/// changes
131 # - add option for even more parens (generalize \&foo change)
132 # - left/right context
133 # - copy comments (look at real text with $^P?)
134 # - avoid semis in one-statement blocks
135 # - associativity of &&=, ||=, ?:
136 # - ',' => '=>' (auto-unquote?)
137 # - break long lines ("\r" as discretionary break?)
138 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
139 # - more style options: brace style, hex vs. octal, quotes, ...
140 # - print big ints as hex/octal instead of decimal (heuristic?)
141 # - handle `my $x if 0'?
142 # - version using op_next instead of op_first/sibling?
143 # - avoid string copies (pass arrays, one big join?)
144 # - here-docs?
145
146 # Current test.deparse failures
147 # comp/hints 6 - location of BEGIN blocks wrt. block openings
148 # run/switchI 1 - missing -I switches entirely
149 #    perl -Ifoo -e 'print @INC'
150 # op/caller 2 - warning mask propagates backwards before warnings::register
151 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
152 # op/getpid 2 - can't assign to shared my() declaration (threads only)
153 #    'my $x : shared = 5'
154 # op/override 7 - parens on overriden require change v-string interpretation
155 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
156 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
157 # op/pat 774 - losing Unicode-ness of Latin1-only strings
158 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
159 # op/recurse 12 - missing parens on recursive call makes it look like method
160 #    'sub f { f($x) }'
161 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
162 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
163 # op/tiehandle compile - "use strict" deparsed in the wrong place
164 # uni/tr_ several
165 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
166 # ext/Data/Dumper/t/dumper compile
167 # ext/DB_file/several
168 # ext/Encode/several
169 # ext/Ernno/Errno warnings
170 # ext/IO/lib/IO/t/io_sel 23
171 # ext/PerlIO/t/encoding compile
172 # ext/POSIX/t/posix 6
173 # ext/Socket/Socket 8
174 # ext/Storable/t/croak compile
175 # lib/Attribute/Handlers/t/multi compile
176 # lib/bignum/ several
177 # lib/charnames 35
178 # lib/constant 32
179 # lib/English 40
180 # lib/ExtUtils/t/bytes 4
181 # lib/File/DosGlob compile
182 # lib/Filter/Simple/t/data 1
183 # lib/Math/BigInt/t/constant 1
184 # lib/Net/t/config Deparse-warning
185 # lib/overload compile
186 # lib/Switch/ several
187 # lib/Symbol 4
188 # lib/Test/Simple several
189 # lib/Term/Complete
190 # lib/Tie/File/t/29_downcopy 5
191 # lib/vars 22
192
193 # Object fields (were globals):
194 #
195 # avoid_local:
196 # (local($a), local($b)) and local($a, $b) have the same internal
197 # representation but the short form looks better. We notice we can
198 # use a large-scale local when checking the list, but need to prevent
199 # individual locals too. This hash holds the addresses of OPs that
200 # have already had their local-ness accounted for. The same thing
201 # is done with my().
202 #
203 # curcv:
204 # CV for current sub (or main program) being deparsed
205 #
206 # curcvlex:
207 # Cached hash of lexical variables for curcv: keys are names,
208 # each value is an array of pairs, indicating the cop_seq of scopes
209 # in which a var of that name is valid.
210 #
211 # curcop:
212 # COP for statement being deparsed
213 #
214 # curstash:
215 # name of the current package for deparsed code
216 #
217 # subs_todo:
218 # array of [cop_seq, CV, is_format?] for subs and formats we still
219 # want to deparse
220 #
221 # protos_todo:
222 # as above, but [name, prototype] for subs that never got a GV
223 #
224 # subs_done, forms_done:
225 # keys are addresses of GVs for subs and formats we've already
226 # deparsed (or at least put into subs_todo)
227 #
228 # subs_declared
229 # keys are names of subs for which we've printed declarations.
230 # That means we can omit parentheses from the arguments.
231 #
232 # subs_deparsed
233 # Keeps track of fully qualified names of all deparsed subs.
234 #
235 # parens: -p
236 # linenums: -l
237 # unquote: -q
238 # cuddle: ` ' or `\n', depending on -sC
239 # indent_size: -si
240 # use_tabs: -sT
241 # ex_const: -sv
242
243 # A little explanation of how precedence contexts and associativity
244 # work:
245 #
246 # deparse() calls each per-op subroutine with an argument $cx (short
247 # for context, but not the same as the cx* in the perl core), which is
248 # a number describing the op's parents in terms of precedence, whether
249 # they're inside an expression or at statement level, etc.  (see
250 # chart below). When ops with children call deparse on them, they pass
251 # along their precedence. Fractional values are used to implement
252 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
253 # parentheses hacks. The major disadvantage of this scheme is that
254 # it doesn't know about right sides and left sides, so say if you
255 # assign a listop to a variable, it can't tell it's allowed to leave
256 # the parens off the listop.
257
258 # Precedences:
259 # 26             [TODO] inside interpolation context ("")
260 # 25 left        terms and list operators (leftward)
261 # 24 left        ->
262 # 23 nonassoc    ++ --
263 # 22 right       **
264 # 21 right       ! ~ \ and unary + and -
265 # 20 left        =~ !~
266 # 19 left        * / % x
267 # 18 left        + - .
268 # 17 left        << >>
269 # 16 nonassoc    named unary operators
270 # 15 nonassoc    < > <= >= lt gt le ge
271 # 14 nonassoc    == != <=> eq ne cmp
272 # 13 left        &
273 # 12 left        | ^
274 # 11 left        &&
275 # 10 left        ||
276 #  9 nonassoc    ..  ...
277 #  8 right       ?:
278 #  7 right       = += -= *= etc.
279 #  6 left        , =>
280 #  5 nonassoc    list operators (rightward)
281 #  4 right       not
282 #  3 left        and
283 #  2 left        or xor
284 #  1             statement modifiers
285 #  0.5           statements, but still print scopes as do { ... }
286 #  0             statement level
287
288 # Nonprinting characters with special meaning:
289 # \cS - steal parens (see maybe_parens_unop)
290 # \n - newline and indent
291 # \t - increase indent
292 # \b - decrease indent (`outdent')
293 # \f - flush left (no indent)
294 # \cK - kill following semicolon, if any
295
296 sub null {
297     my $op = shift;
298     return class($op) eq "NULL";
299 }
300
301 sub todo {
302     my $self = shift;
303     my($cv, $is_form) = @_;
304     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
305     my $seq;
306     if ($cv->OUTSIDE_SEQ) {
307         $seq = $cv->OUTSIDE_SEQ;
308     } elsif (!null($cv->START) and is_state($cv->START)) {
309         $seq = $cv->START->cop_seq;
310     } else {
311         $seq = 0;
312     }
313     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
314     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
315         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
316     }
317 }
318
319 sub next_todo {
320     my $self = shift;
321     my $ent = shift @{$self->{'subs_todo'}};
322     my $cv = $ent->[1];
323     my $gv = $cv->GV;
324     my $name = $self->gv_name($gv);
325     if ($ent->[2]) {
326         return "format $name =\n"
327             . $self->deparse_format($ent->[1]). "\n";
328     } else {
329         $self->{'subs_declared'}{$name} = 1;
330         if ($name eq "BEGIN") {
331             my $use_dec = $self->begin_is_use($cv);
332             if (defined ($use_dec) and $self->{'expand'} < 5) {
333                 return () if 0 == length($use_dec);
334                 return $use_dec;
335             }
336         }
337         my $l = '';
338         if ($self->{'linenums'}) {
339             my $line = $gv->LINE;
340             my $file = $gv->FILE;
341             $l = "\n\f#line $line \"$file\"\n";
342         }
343         my $p = '';
344         if (class($cv->STASH) ne "SPECIAL") {
345             my $stash = $cv->STASH->NAME;
346             if ($stash ne $self->{'curstash'}) {
347                 $p = "package $stash;\n";
348                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
349                 $self->{'curstash'} = $stash;
350             }
351             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
352         }
353         return "${p}${l}sub $name " . $self->deparse_sub($cv);
354     }
355 }
356
357 # Return a "use" declaration for this BEGIN block, if appropriate
358 sub begin_is_use {
359     my ($self, $cv) = @_;
360     my $root = $cv->ROOT;
361     local @$self{qw'curcv curcvlex'} = ($cv);
362 #require B::Debug;
363 #B::walkoptree($cv->ROOT, "debug");
364     my $lineseq = $root->first;
365     return if $lineseq->name ne "lineseq";
366
367     my $req_op = $lineseq->first->sibling;
368     return if $req_op->name ne "require";
369
370     my $module;
371     if ($req_op->first->private & OPpCONST_BARE) {
372         # Actually it should always be a bareword
373         $module = $self->const_sv($req_op->first)->PV;
374         $module =~ s[/][::]g;
375         $module =~ s/.pm$//;
376     }
377     else {
378         $module = $self->const($self->const_sv($req_op->first), 6);
379     }
380
381     my $version;
382     my $version_op = $req_op->sibling;
383     return if class($version_op) eq "NULL";
384     if ($version_op->name eq "lineseq") {
385         # We have a version parameter; skip nextstate & pushmark
386         my $constop = $version_op->first->next->next;
387
388         return unless $self->const_sv($constop)->PV eq $module;
389         $constop = $constop->sibling;
390         $version = $self->const_sv($constop);
391         if (class($version) eq "IV") {
392             $version = $version->int_value;
393         } elsif (class($version) eq "NV") {
394             $version = $version->NV;
395         } elsif (class($version) ne "PVMG") {
396             # Includes PVIV and PVNV
397             $version = $version->PV;
398         } else {
399             # version specified as a v-string
400             $version = 'v'.join '.', map ord, split //, $version->PV;
401         }
402         $constop = $constop->sibling;
403         return if $constop->name ne "method_named";
404         return if $self->const_sv($constop)->PV ne "VERSION";
405     }
406
407     $lineseq = $version_op->sibling;
408     return if $lineseq->name ne "lineseq";
409     my $entersub = $lineseq->first->sibling;
410     if ($entersub->name eq "stub") {
411         return "use $module $version ();\n" if defined $version;
412         return "use $module ();\n";
413     }
414     return if $entersub->name ne "entersub";
415
416     # See if there are import arguments
417     my $args = '';
418
419     my $svop = $entersub->first->sibling; # Skip over pushmark
420     return unless $self->const_sv($svop)->PV eq $module;
421
422     # Pull out the arguments
423     for ($svop=$svop->sibling; $svop->name ne "method_named";
424                 $svop = $svop->sibling) {
425         $args .= ", " if length($args);
426         $args .= $self->deparse($svop, 6);
427     }
428
429     my $use = 'use';
430     my $method_named = $svop;
431     return if $method_named->name ne "method_named";
432     my $method_name = $self->const_sv($method_named)->PV;
433
434     if ($method_name eq "unimport") {
435         $use = 'no';
436     }
437
438     # Certain pragmas are dealt with using hint bits,
439     # so we ignore them here
440     if ($module eq 'strict' || $module eq 'integer'
441         || $module eq 'bytes' || $module eq 'warnings'
442         || $module eq 'feature') {
443         return "";
444     }
445
446     if (defined $version && length $args) {
447         return "$use $module $version ($args);\n";
448     } elsif (defined $version) {
449         return "$use $module $version;\n";
450     } elsif (length $args) {
451         return "$use $module ($args);\n";
452     } else {
453         return "$use $module;\n";
454     }
455 }
456
457 sub stash_subs {
458     my ($self, $pack) = @_;
459     my (@ret, $stash);
460     if (!defined $pack) {
461         $pack = '';
462         $stash = \%::;
463     }
464     else {
465         $pack =~ s/(::)?$/::/;
466         no strict 'refs';
467         $stash = \%$pack;
468     }
469     my %stash = svref_2object($stash)->ARRAY;
470     while (my ($key, $val) = each %stash) {
471         my $class = class($val);
472         if ($class eq "PV") {
473             # Just a prototype. As an ugly but fairly effective way
474             # to find out if it belongs here is to see if the AUTOLOAD
475             # (if any) for the stash was defined in one of our files.
476             my $A = $stash{"AUTOLOAD"};
477             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
478                 && class($A->CV) eq "CV") {
479                 my $AF = $A->FILE;
480                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
481             }
482             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
483         } elsif ($class eq "IV") {
484             # Just a name. As above.
485             my $A = $stash{"AUTOLOAD"};
486             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
487                 && class($A->CV) eq "CV") {
488                 my $AF = $A->FILE;
489                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
490             }
491             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
492         } elsif ($class eq "GV") {
493             if (class(my $cv = $val->CV) ne "SPECIAL") {
494                 next if $self->{'subs_done'}{$$val}++;
495                 next if $$val != ${$cv->GV};   # Ignore imposters
496                 $self->todo($cv, 0);
497             }
498             if (class(my $cv = $val->FORM) ne "SPECIAL") {
499                 next if $self->{'forms_done'}{$$val}++;
500                 next if $$val != ${$cv->GV};   # Ignore imposters
501                 $self->todo($cv, 1);
502             }
503             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
504                 $self->stash_subs($pack . $key)
505                     unless $pack eq '' && $key eq 'main::';
506                     # avoid infinite recursion
507             }
508         }
509     }
510 }
511
512 sub print_protos {
513     my $self = shift;
514     my $ar;
515     my @ret;
516     foreach $ar (@{$self->{'protos_todo'}}) {
517         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
518         push @ret, "sub " . $ar->[0] .  "$proto;\n";
519     }
520     delete $self->{'protos_todo'};
521     return @ret;
522 }
523
524 sub style_opts {
525     my $self = shift;
526     my $opts = shift;
527     my $opt;
528     while (length($opt = substr($opts, 0, 1))) {
529         if ($opt eq "C") {
530             $self->{'cuddle'} = " ";
531             $opts = substr($opts, 1);
532         } elsif ($opt eq "i") {
533             $opts =~ s/^i(\d+)//;
534             $self->{'indent_size'} = $1;
535         } elsif ($opt eq "T") {
536             $self->{'use_tabs'} = 1;
537             $opts = substr($opts, 1);
538         } elsif ($opt eq "v") {
539             $opts =~ s/^v([^.]*)(.|$)//;
540             $self->{'ex_const'} = $1;
541         }
542     }
543 }
544
545 sub new {
546     my $class = shift;
547     my $self = bless {}, $class;
548     $self->{'cuddle'} = "\n";
549     $self->{'curcop'} = undef;
550     $self->{'curstash'} = "main";
551     $self->{'ex_const'} = "'???'";
552     $self->{'expand'} = 0;
553     $self->{'files'} = {};
554     $self->{'indent_size'} = 4;
555     $self->{'linenums'} = 0;
556     $self->{'parens'} = 0;
557     $self->{'subs_todo'} = [];
558     $self->{'unquote'} = 0;
559     $self->{'use_dumper'} = 0;
560     $self->{'use_tabs'} = 0;
561
562     $self->{'ambient_arybase'} = 0;
563     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
564     $self->{'ambient_hints'} = 0;
565     $self->{'ambient_hinthash'} = undef;
566     $self->init();
567
568     while (my $arg = shift @_) {
569         if ($arg eq "-d") {
570             $self->{'use_dumper'} = 1;
571             require Data::Dumper;
572         } elsif ($arg =~ /^-f(.*)/) {
573             $self->{'files'}{$1} = 1;
574         } elsif ($arg eq "-l") {
575             $self->{'linenums'} = 1;
576         } elsif ($arg eq "-p") {
577             $self->{'parens'} = 1;
578         } elsif ($arg eq "-P") {
579             $self->{'noproto'} = 1;
580         } elsif ($arg eq "-q") {
581             $self->{'unquote'} = 1;
582         } elsif (substr($arg, 0, 2) eq "-s") {
583             $self->style_opts(substr $arg, 2);
584         } elsif ($arg =~ /^-x(\d)$/) {
585             $self->{'expand'} = $1;
586         }
587     }
588     return $self;
589 }
590
591 {
592     # Mask out the bits that L<warnings::register> uses
593     my $WARN_MASK;
594     BEGIN {
595         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
596     }
597     sub WARN_MASK () {
598         return $WARN_MASK;
599     }
600 }
601
602 # Initialise the contextual information, either from
603 # defaults provided with the ambient_pragmas method,
604 # or from perl's own defaults otherwise.
605 sub init {
606     my $self = shift;
607
608     $self->{'arybase'}  = $self->{'ambient_arybase'};
609     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
610                                 ? $self->{'ambient_warnings'} & WARN_MASK
611                                 : undef;
612     $self->{'hints'}    = $self->{'ambient_hints'};
613     $self->{'hints'} &= 0xFF if $] < 5.009;
614     $self->{'hinthash'} = $self->{'ambient_hinthash'};
615
616     # also a convenient place to clear out subs_declared
617     delete $self->{'subs_declared'};
618 }
619
620 sub compile {
621     my(@args) = @_;
622     return sub {
623         my $self = B::Deparse->new(@args);
624         # First deparse command-line args
625         if (defined $^I) { # deparse -i
626             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
627         }
628         if ($^W) { # deparse -w
629             print qq(BEGIN { \$^W = $^W; }\n);
630         }
631         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
632             my $fs = perlstring($/) || 'undef';
633             my $bs = perlstring($O::savebackslash) || 'undef';
634             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
635         }
636         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
637         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
638             ? B::unitcheck_av->ARRAY
639             : ();
640         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
641         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
642         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
643         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
644             $self->todo($block, 0);
645         }
646         $self->stash_subs();
647         local($SIG{"__DIE__"}) =
648           sub {
649               if ($self->{'curcop'}) {
650                   my $cop = $self->{'curcop'};
651                   my($line, $file) = ($cop->line, $cop->file);
652                   print STDERR "While deparsing $file near line $line,\n";
653               }
654             };
655         $self->{'curcv'} = main_cv;
656         $self->{'curcvlex'} = undef;
657         print $self->print_protos;
658         @{$self->{'subs_todo'}} =
659           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
660         print $self->indent($self->deparse_root(main_root)), "\n"
661           unless null main_root;
662         my @text;
663         while (scalar(@{$self->{'subs_todo'}})) {
664             push @text, $self->next_todo;
665         }
666         print $self->indent(join("", @text)), "\n" if @text;
667
668         # Print __DATA__ section, if necessary
669         no strict 'refs';
670         my $laststash = defined $self->{'curcop'}
671             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
672         if (defined *{$laststash."::DATA"}{IO}) {
673             print "package $laststash;\n"
674                 unless $laststash eq $self->{'curstash'};
675             print "__DATA__\n";
676             print readline(*{$laststash."::DATA"});
677         }
678     }
679 }
680
681 sub coderef2text {
682     my $self = shift;
683     my $sub = shift;
684     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
685
686     $self->init();
687     return $self->indent($self->deparse_sub(svref_2object($sub)));
688 }
689
690 sub ambient_pragmas {
691     my $self = shift;
692     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
693
694     while (@_ > 1) {
695         my $name = shift();
696         my $val  = shift();
697
698         if ($name eq 'strict') {
699             require strict;
700
701             if ($val eq 'none') {
702                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
703                 next();
704             }
705
706             my @names;
707             if ($val eq "all") {
708                 @names = qw/refs subs vars/;
709             }
710             elsif (ref $val) {
711                 @names = @$val;
712             }
713             else {
714                 @names = split' ', $val;
715             }
716             $hint_bits |= strict::bits(@names);
717         }
718
719         elsif ($name eq '$[') {
720             $arybase = $val;
721         }
722
723         elsif ($name eq 'integer'
724             || $name eq 'bytes'
725             || $name eq 'utf8') {
726             require "$name.pm";
727             if ($val) {
728                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
729             }
730             else {
731                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
732             }
733         }
734
735         elsif ($name eq 're') {
736             require re;
737             if ($val eq 'none') {
738                 $hint_bits &= ~re::bits(qw/taint eval/);
739                 next();
740             }
741
742             my @names;
743             if ($val eq 'all') {
744                 @names = qw/taint eval/;
745             }
746             elsif (ref $val) {
747                 @names = @$val;
748             }
749             else {
750                 @names = split' ',$val;
751             }
752             $hint_bits |= re::bits(@names);
753         }
754
755         elsif ($name eq 'warnings') {
756             if ($val eq 'none') {
757                 $warning_bits = $warnings::NONE;
758                 next();
759             }
760
761             my @names;
762             if (ref $val) {
763                 @names = @$val;
764             }
765             else {
766                 @names = split/\s+/, $val;
767             }
768
769             $warning_bits = $warnings::NONE if !defined ($warning_bits);
770             $warning_bits |= warnings::bits(@names);
771         }
772
773         elsif ($name eq 'warning_bits') {
774             $warning_bits = $val;
775         }
776
777         elsif ($name eq 'hint_bits') {
778             $hint_bits = $val;
779         }
780
781         elsif ($name eq '%^H') {
782             $hinthash = $val;
783         }
784
785         else {
786             croak "Unknown pragma type: $name";
787         }
788     }
789     if (@_) {
790         croak "The ambient_pragmas method expects an even number of args";
791     }
792
793     $self->{'ambient_arybase'} = $arybase;
794     $self->{'ambient_warnings'} = $warning_bits;
795     $self->{'ambient_hints'} = $hint_bits;
796     $self->{'ambient_hinthash'} = $hinthash;
797 }
798
799 # This method is the inner loop, so try to keep it simple
800 sub deparse {
801     my $self = shift;
802     my($op, $cx) = @_;
803
804     Carp::confess("Null op in deparse") if !defined($op)
805                                         || class($op) eq "NULL";
806     my $meth = "pp_" . $op->name;
807     return $self->$meth($op, $cx);
808 }
809
810 sub indent {
811     my $self = shift;
812     my $txt = shift;
813     my @lines = split(/\n/, $txt);
814     my $leader = "";
815     my $level = 0;
816     my $line;
817     for $line (@lines) {
818         my $cmd = substr($line, 0, 1);
819         if ($cmd eq "\t" or $cmd eq "\b") {
820             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
821             if ($self->{'use_tabs'}) {
822                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
823             } else {
824                 $leader = " " x $level;
825             }
826             $line = substr($line, 1);
827         }
828         if (substr($line, 0, 1) eq "\f") {
829             $line = substr($line, 1); # no indent
830         } else {
831             $line = $leader . $line;
832         }
833         $line =~ s/\cK;?//g;
834     }
835     return join("\n", @lines);
836 }
837
838 sub deparse_sub {
839     my $self = shift;
840     my $cv = shift;
841     my $proto = "";
842 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
843 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
844     local $self->{'curcop'} = $self->{'curcop'};
845     if ($cv->FLAGS & SVf_POK) {
846         $proto = "(". $cv->PV . ") ";
847     }
848     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
849         $proto .= ": ";
850         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
851         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
852         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
853     }
854
855     local($self->{'curcv'}) = $cv;
856     local($self->{'curcvlex'});
857     local(@$self{qw'curstash warnings hints hinthash'})
858                 = @$self{qw'curstash warnings hints hinthash'};
859     my $body;
860     if (not null $cv->ROOT) {
861         my $lineseq = $cv->ROOT->first;
862         if ($lineseq->name eq "lineseq") {
863             my @ops;
864             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
865                 push @ops, $o;
866             }
867             $body = $self->lineseq(undef, @ops).";";
868             my $scope_en = $self->find_scope_en($lineseq);
869             if (defined $scope_en) {
870                 my $subs = join"", $self->seq_subs($scope_en);
871                 $body .= ";\n$subs" if length($subs);
872             }
873         }
874         else {
875             $body = $self->deparse($cv->ROOT->first, 0);
876         }
877     }
878     else {
879         my $sv = $cv->const_sv;
880         if ($$sv) {
881             # uh-oh. inlinable sub... format it differently
882             return $proto . "{ " . $self->const($sv, 0) . " }\n";
883         } else { # XSUB? (or just a declaration)
884             return "$proto;\n";
885         }
886     }
887     return $proto ."{\n\t$body\n\b}" ."\n";
888 }
889
890 sub deparse_format {
891     my $self = shift;
892     my $form = shift;
893     my @text;
894     local($self->{'curcv'}) = $form;
895     local($self->{'curcvlex'});
896     local($self->{'in_format'}) = 1;
897     local(@$self{qw'curstash warnings hints hinthash'})
898                 = @$self{qw'curstash warnings hints hinthash'};
899     my $op = $form->ROOT;
900     my $kid;
901     return "\f." if $op->first->name eq 'stub'
902                 || $op->first->name eq 'nextstate';
903     $op = $op->first->first; # skip leavewrite, lineseq
904     while (not null $op) {
905         $op = $op->sibling; # skip nextstate
906         my @exprs;
907         $kid = $op->first->sibling; # skip pushmark
908         push @text, "\f".$self->const_sv($kid)->PV;
909         $kid = $kid->sibling;
910         for (; not null $kid; $kid = $kid->sibling) {
911             push @exprs, $self->deparse($kid, 0);
912         }
913         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
914         $op = $op->sibling;
915     }
916     return join("", @text) . "\f.";
917 }
918
919 sub is_scope {
920     my $op = shift;
921     return $op->name eq "leave" || $op->name eq "scope"
922       || $op->name eq "lineseq"
923         || ($op->name eq "null" && class($op) eq "UNOP"
924             && (is_scope($op->first) || $op->first->name eq "enter"));
925 }
926
927 sub is_state {
928     my $name = $_[0]->name;
929     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
930 }
931
932 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
933     my $op = shift;
934     return (!null($op) and null($op->sibling)
935             and $op->name eq "null" and class($op) eq "UNOP"
936             and (($op->first->name =~ /^(and|or)$/
937                   and $op->first->first->sibling->name eq "lineseq")
938                  or ($op->first->name eq "lineseq"
939                      and not null $op->first->first->sibling
940                      and $op->first->first->sibling->name eq "unstack")
941                  ));
942 }
943
944 # Check if the op and its sibling are the initialization and the rest of a
945 # for (..;..;..) { ... } loop
946 sub is_for_loop {
947     my $op = shift;
948     # This OP might be almost anything, though it won't be a
949     # nextstate. (It's the initialization, so in the canonical case it
950     # will be an sassign.) The sibling is a lineseq whose first child
951     # is a nextstate and whose second is a leaveloop.
952     my $lseq = $op->sibling;
953     if (!is_state $op and !null($lseq) and $lseq->name eq "lineseq") {
954         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
955             && (my $sib = $lseq->first->sibling)) {
956             return (!null($sib) && $sib->name eq "leaveloop");
957         }
958     }
959     return 0;
960 }
961
962 sub is_scalar {
963     my $op = shift;
964     return ($op->name eq "rv2sv" or
965             $op->name eq "padsv" or
966             $op->name eq "gv" or # only in array/hash constructs
967             $op->flags & OPf_KIDS && !null($op->first)
968               && $op->first->name eq "gvsv");
969 }
970
971 sub maybe_parens {
972     my $self = shift;
973     my($text, $cx, $prec) = @_;
974     if ($prec < $cx              # unary ops nest just fine
975         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
976         or $self->{'parens'})
977     {
978         $text = "($text)";
979         # In a unop, let parent reuse our parens; see maybe_parens_unop
980         $text = "\cS" . $text if $cx == 16;
981         return $text;
982     } else {
983         return $text;
984     }
985 }
986
987 # same as above, but get around the `if it looks like a function' rule
988 sub maybe_parens_unop {
989     my $self = shift;
990     my($name, $kid, $cx) = @_;
991     if ($cx > 16 or $self->{'parens'}) {
992         $kid =  $self->deparse($kid, 1);
993         if ($name eq "umask" && $kid =~ /^\d+$/) {
994             $kid = sprintf("%#o", $kid);
995         }
996         return "$name($kid)";
997     } else {
998         $kid = $self->deparse($kid, 16);
999         if ($name eq "umask" && $kid =~ /^\d+$/) {
1000             $kid = sprintf("%#o", $kid);
1001         }
1002         if (substr($kid, 0, 1) eq "\cS") {
1003             # use kid's parens
1004             return $name . substr($kid, 1);
1005         } elsif (substr($kid, 0, 1) eq "(") {
1006             # avoid looks-like-a-function trap with extra parens
1007             # (`+' can lead to ambiguities)
1008             return "$name(" . $kid  . ")";
1009         } else {
1010             return "$name $kid";
1011         }
1012     }
1013 }
1014
1015 sub maybe_parens_func {
1016     my $self = shift;
1017     my($func, $text, $cx, $prec) = @_;
1018     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1019         return "$func($text)";
1020     } else {
1021         return "$func $text";
1022     }
1023 }
1024
1025 sub maybe_local {
1026     my $self = shift;
1027     my($op, $cx, $text) = @_;
1028     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1029     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1030         and not $self->{'avoid_local'}{$$op}) {
1031         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1032         if( $our_local eq 'our' ) {
1033             # XXX This assertion fails code with non-ASCII identifiers,
1034             # like ./ext/Encode/t/jperl.t
1035             die "Unexpected our($text)\n" unless $text =~ /^\W(\w+::)*\w+\z/;
1036             $text =~ s/(\w+::)+//;
1037         }
1038         if (want_scalar($op)) {
1039             return "$our_local $text";
1040         } else {
1041             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1042         }
1043     } else {
1044         return $text;
1045     }
1046 }
1047
1048 sub maybe_targmy {
1049     my $self = shift;
1050     my($op, $cx, $func, @args) = @_;
1051     if ($op->private & OPpTARGET_MY) {
1052         my $var = $self->padname($op->targ);
1053         my $val = $func->($self, $op, 7, @args);
1054         return $self->maybe_parens("$var = $val", $cx, 7);
1055     } else {
1056         return $func->($self, $op, $cx, @args);
1057     }
1058 }
1059
1060 sub padname_sv {
1061     my $self = shift;
1062     my $targ = shift;
1063     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1064 }
1065
1066 sub maybe_my {
1067     my $self = shift;
1068     my($op, $cx, $text) = @_;
1069     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1070         my $my = $op->private & OPpPAD_STATE ? "state" : "my";
1071         if (want_scalar($op)) {
1072             return "$my $text";
1073         } else {
1074             return $self->maybe_parens_func($my, $text, $cx, 16);
1075         }
1076     } else {
1077         return $text;
1078     }
1079 }
1080
1081 # The following OPs don't have functions:
1082
1083 # pp_padany -- does not exist after parsing
1084
1085 sub AUTOLOAD {
1086     if ($AUTOLOAD =~ s/^.*::pp_//) {
1087         warn "unexpected OP_".uc $AUTOLOAD;
1088         return "XXX";
1089     } else {
1090         die "Undefined subroutine $AUTOLOAD called";
1091     }
1092 }
1093
1094 sub DESTROY {}  #       Do not AUTOLOAD
1095
1096 # $root should be the op which represents the root of whatever
1097 # we're sequencing here. If it's undefined, then we don't append
1098 # any subroutine declarations to the deparsed ops, otherwise we
1099 # append appropriate declarations.
1100 sub lineseq {
1101     my($self, $root, @ops) = @_;
1102     my($expr, @exprs);
1103
1104     my $out_cop = $self->{'curcop'};
1105     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1106     my $limit_seq;
1107     if (defined $root) {
1108         $limit_seq = $out_seq;
1109         my $nseq;
1110         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1111         $limit_seq = $nseq if !defined($limit_seq)
1112                            or defined($nseq) && $nseq < $limit_seq;
1113     }
1114     $limit_seq = $self->{'limit_seq'}
1115         if defined($self->{'limit_seq'})
1116         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1117     local $self->{'limit_seq'} = $limit_seq;
1118
1119     $self->walk_lineseq($root, \@ops,
1120                        sub { push @exprs, $_[0]} );
1121
1122     my $body = join(";\n", grep {length} @exprs);
1123     my $subs = "";
1124     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1125         $subs = join "\n", $self->seq_subs($limit_seq);
1126     }
1127     return join(";\n", grep {length} $body, $subs);
1128 }
1129
1130 sub scopeop {
1131     my($real_block, $self, $op, $cx) = @_;
1132     my $kid;
1133     my @kids;
1134
1135     local(@$self{qw'curstash warnings hints hinthash'})
1136                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1137     if ($real_block) {
1138         $kid = $op->first->sibling; # skip enter
1139         if (is_miniwhile($kid)) {
1140             my $top = $kid->first;
1141             my $name = $top->name;
1142             if ($name eq "and") {
1143                 $name = "while";
1144             } elsif ($name eq "or") {
1145                 $name = "until";
1146             } else { # no conditional -> while 1 or until 0
1147                 return $self->deparse($top->first, 1) . " while 1";
1148             }
1149             my $cond = $top->first;
1150             my $body = $cond->sibling->first; # skip lineseq
1151             $cond = $self->deparse($cond, 1);
1152             $body = $self->deparse($body, 1);
1153             return "$body $name $cond";
1154         }
1155     } else {
1156         $kid = $op->first;
1157     }
1158     for (; !null($kid); $kid = $kid->sibling) {
1159         push @kids, $kid;
1160     }
1161     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1162         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1163     } else {
1164         my $lineseq = $self->lineseq($op, @kids);
1165         return (length ($lineseq) ? "$lineseq;" : "");
1166     }
1167 }
1168
1169 sub pp_scope { scopeop(0, @_); }
1170 sub pp_lineseq { scopeop(0, @_); }
1171 sub pp_leave { scopeop(1, @_); }
1172
1173 # This is a special case of scopeop and lineseq, for the case of the
1174 # main_root. The difference is that we print the output statements as
1175 # soon as we get them, for the sake of impatient users.
1176 sub deparse_root {
1177     my $self = shift;
1178     my($op) = @_;
1179     local(@$self{qw'curstash warnings hints hinthash'})
1180       = @$self{qw'curstash warnings hints hinthash'};
1181     my @kids;
1182     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1183     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1184         push @kids, $kid;
1185     }
1186     $self->walk_lineseq($op, \@kids,
1187                         sub { print $self->indent($_[0].';');
1188                               print "\n" unless $_[1] == $#kids;
1189                           });
1190 }
1191
1192 sub walk_lineseq {
1193     my ($self, $op, $kids, $callback) = @_;
1194     my @kids = @$kids;
1195     for (my $i = 0; $i < @kids; $i++) {
1196         my $expr = "";
1197         if (is_state $kids[$i]) {
1198             $expr = $self->deparse($kids[$i++], 0);
1199             if ($i > $#kids) {
1200                 $callback->($expr, $i);
1201                 last;
1202             }
1203         }
1204         if (is_for_loop($kids[$i])) {
1205             $callback->($expr . $self->for_loop($kids[$i], 0), $i++);
1206             next;
1207         }
1208         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1209         $expr =~ s/;\n?\z//;
1210         $callback->($expr, $i);
1211     }
1212 }
1213
1214 # The BEGIN {} is used here because otherwise this code isn't executed
1215 # when you run B::Deparse on itself.
1216 my %globalnames;
1217 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1218             "ENV", "ARGV", "ARGVOUT", "_"); }
1219
1220 sub gv_name {
1221     my $self = shift;
1222     my $gv = shift;
1223 Carp::confess() unless ref($gv) eq "B::GV";
1224     my $stash = $gv->STASH->NAME;
1225     my $name = $gv->SAFENAME;
1226     if ($stash eq 'main' && $name =~ /^::/) {
1227         $stash = '::';
1228     }
1229     elsif (($stash eq 'main' && $globalnames{$name})
1230         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1231             && ($stash eq 'main' || $name !~ /::/))
1232         or $name =~ /^[^A-Za-z_:]/)
1233     {
1234         $stash = "";
1235     } else {
1236         $stash = $stash . "::";
1237     }
1238     if ($name =~ /^(\^..|{)/) {
1239         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1240     }
1241     return $stash . $name;
1242 }
1243
1244 # Return the name to use for a stash variable.
1245 # If a lexical with the same name is in scope, it may need to be
1246 # fully-qualified.
1247 sub stash_variable {
1248     my ($self, $prefix, $name) = @_;
1249
1250     return "$prefix$name" if $name =~ /::/;
1251
1252     unless ($prefix eq '$' || $prefix eq '@' || #'
1253             $prefix eq '%' || $prefix eq '$#') {
1254         return "$prefix$name";
1255     }
1256
1257     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1258     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1259     return "$prefix$name";
1260 }
1261
1262 sub lex_in_scope {
1263     my ($self, $name) = @_;
1264     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1265
1266     return 0 if !defined($self->{'curcop'});
1267     my $seq = $self->{'curcop'}->cop_seq;
1268     return 0 if !exists $self->{'curcvlex'}{$name};
1269     for my $a (@{$self->{'curcvlex'}{$name}}) {
1270         my ($st, $en) = @$a;
1271         return 1 if $seq > $st && $seq <= $en;
1272     }
1273     return 0;
1274 }
1275
1276 sub populate_curcvlex {
1277     my $self = shift;
1278     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1279         my $padlist = $cv->PADLIST;
1280         # an undef CV still in lexical chain
1281         next if class($padlist) eq "SPECIAL";
1282         my @padlist = $padlist->ARRAY;
1283         my @ns = $padlist[0]->ARRAY;
1284
1285         for (my $i=0; $i<@ns; ++$i) {
1286             next if class($ns[$i]) eq "SPECIAL";
1287             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1288             if (class($ns[$i]) eq "PV") {
1289                 # Probably that pesky lexical @_
1290                 next;
1291             }
1292             my $name = $ns[$i]->PVX;
1293             my ($seq_st, $seq_en) =
1294                 ($ns[$i]->FLAGS & SVf_FAKE)
1295                     ? (0, 999999)
1296                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1297
1298             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1299         }
1300     }
1301 }
1302
1303 sub find_scope_st { ((find_scope(@_))[0]); }
1304 sub find_scope_en { ((find_scope(@_))[1]); }
1305
1306 # Recurses down the tree, looking for pad variable introductions and COPs
1307 sub find_scope {
1308     my ($self, $op, $scope_st, $scope_en) = @_;
1309     carp("Undefined op in find_scope") if !defined $op;
1310     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1311
1312     my @queue = ($op);
1313     while(my $op = shift @queue ) {
1314         for (my $o=$op->first; $$o; $o=$o->sibling) {
1315             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1316                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1317                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1318                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1319                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1320                 return ($scope_st, $scope_en);
1321             }
1322             elsif (is_state($o)) {
1323                 my $c = $o->cop_seq;
1324                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1325                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1326                 return ($scope_st, $scope_en);
1327             }
1328             elsif ($o->flags & OPf_KIDS) {
1329                 unshift (@queue, $o);
1330             }
1331         }
1332     }
1333
1334     return ($scope_st, $scope_en);
1335 }
1336
1337 # Returns a list of subs which should be inserted before the COP
1338 sub cop_subs {
1339     my ($self, $op, $out_seq) = @_;
1340     my $seq = $op->cop_seq;
1341     # If we have nephews, then our sequence number indicates
1342     # the cop_seq of the end of some sort of scope.
1343     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1344         and my $nseq = $self->find_scope_st($op->sibling) ) {
1345         $seq = $nseq;
1346     }
1347     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1348     return $self->seq_subs($seq);
1349 }
1350
1351 sub seq_subs {
1352     my ($self, $seq) = @_;
1353     my @text;
1354 #push @text, "# ($seq)\n";
1355
1356     return "" if !defined $seq;
1357     while (scalar(@{$self->{'subs_todo'}})
1358            and $seq > $self->{'subs_todo'}[0][0]) {
1359         push @text, $self->next_todo;
1360     }
1361     return @text;
1362 }
1363
1364 # Notice how subs and formats are inserted between statements here;
1365 # also $[ assignments and pragmas.
1366 sub pp_nextstate {
1367     my $self = shift;
1368     my($op, $cx) = @_;
1369     $self->{'curcop'} = $op;
1370     my @text;
1371     push @text, $self->cop_subs($op);
1372     push @text, $op->label . ": " if $op->label;
1373     my $stash = $op->stashpv;
1374     if ($stash ne $self->{'curstash'}) {
1375         push @text, "package $stash;\n";
1376         $self->{'curstash'} = $stash;
1377     }
1378
1379     if ($self->{'arybase'} != $op->arybase) {
1380         push @text, '$[ = '. $op->arybase .";\n";
1381         $self->{'arybase'} = $op->arybase;
1382     }
1383
1384     my $warnings = $op->warnings;
1385     my $warning_bits;
1386     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1387         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1388     }
1389     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1390         $warning_bits = $warnings::NONE;
1391     }
1392     elsif ($warnings->isa("B::SPECIAL")) {
1393         $warning_bits = undef;
1394     }
1395     else {
1396         $warning_bits = $warnings->PV & WARN_MASK;
1397     }
1398
1399     if (defined ($warning_bits) and
1400        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1401         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1402         $self->{'warnings'} = $warning_bits;
1403     }
1404
1405     if ($self->{'hints'} != $op->hints) {
1406         push @text, declare_hints($self->{'hints'}, $op->hints);
1407         $self->{'hints'} = $op->hints;
1408     }
1409
1410     # hack to check that the hint hash hasn't changed
1411     if ($] > 5.009 &&
1412         "@{[sort %{$self->{'hinthash'} || {}}]}"
1413         ne "@{[sort %{$op->hints_hash->HASH || {}}]}") {
1414         push @text, declare_hinthash($self->{'hinthash'}, $op->hints_hash->HASH, $self->{indent_size});
1415         $self->{'hinthash'} = $op->hints_hash->HASH;
1416     }
1417
1418     # This should go after of any branches that add statements, to
1419     # increase the chances that it refers to the same line it did in
1420     # the original program.
1421     if ($self->{'linenums'}) {
1422         push @text, "\f#line " . $op->line .
1423           ' "' . $op->file, qq'"\n';
1424     }
1425
1426     return join("", @text);
1427 }
1428
1429 sub declare_warnings {
1430     my ($from, $to) = @_;
1431     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1432         return "use warnings;\n";
1433     }
1434     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1435         return "no warnings;\n";
1436     }
1437     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1438 }
1439
1440 sub declare_hints {
1441     my ($from, $to) = @_;
1442     my $use = $to   & ~$from;
1443     my $no  = $from & ~$to;
1444     my $decls = "";
1445     for my $pragma (hint_pragmas($use)) {
1446         $decls .= "use $pragma;\n";
1447     }
1448     for my $pragma (hint_pragmas($no)) {
1449         $decls .= "no $pragma;\n";
1450     }
1451     return $decls;
1452 }
1453
1454 sub declare_hinthash {
1455     my ($from, $to, $indent) = @_;
1456     my @decls;
1457     for my $key (keys %$to) {
1458         next if $key =~ /^open[<>]$/;
1459         if (!defined $from->{$key} or $from->{$key} ne $to->{$key}) {
1460             push @decls, qq(\$^H{'$key'} = q($to->{$key}););
1461         }
1462     }
1463     for my $key (keys %$from) {
1464         next if $key =~ /^open[<>]$/;
1465         if (!exists $to->{$key}) {
1466             push @decls, qq(delete \$^H{'$key'};);
1467         }
1468     }
1469     @decls or return '';
1470     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1471 }
1472
1473 sub hint_pragmas {
1474     my ($bits) = @_;
1475     my @pragmas;
1476     push @pragmas, "integer" if $bits & 0x1;
1477     push @pragmas, "strict 'refs'" if $bits & 0x2;
1478     push @pragmas, "bytes" if $bits & 0x8;
1479     return @pragmas;
1480 }
1481
1482 sub pp_dbstate { pp_nextstate(@_) }
1483 sub pp_setstate { pp_nextstate(@_) }
1484
1485 sub pp_unstack { return "" } # see also leaveloop
1486
1487 sub baseop {
1488     my $self = shift;
1489     my($op, $cx, $name) = @_;
1490     return $name;
1491 }
1492
1493 sub pp_stub {
1494     my $self = shift;
1495     my($op, $cx, $name) = @_;
1496     if ($cx >= 1) {
1497         return "()";
1498     }
1499     else {
1500         return "();";
1501     }
1502 }
1503 sub pp_wantarray { baseop(@_, "wantarray") }
1504 sub pp_fork { baseop(@_, "fork") }
1505 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1506 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1507 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1508 sub pp_tms { baseop(@_, "times") }
1509 sub pp_ghostent { baseop(@_, "gethostent") }
1510 sub pp_gnetent { baseop(@_, "getnetent") }
1511 sub pp_gprotoent { baseop(@_, "getprotoent") }
1512 sub pp_gservent { baseop(@_, "getservent") }
1513 sub pp_ehostent { baseop(@_, "endhostent") }
1514 sub pp_enetent { baseop(@_, "endnetent") }
1515 sub pp_eprotoent { baseop(@_, "endprotoent") }
1516 sub pp_eservent { baseop(@_, "endservent") }
1517 sub pp_gpwent { baseop(@_, "getpwent") }
1518 sub pp_spwent { baseop(@_, "setpwent") }
1519 sub pp_epwent { baseop(@_, "endpwent") }
1520 sub pp_ggrent { baseop(@_, "getgrent") }
1521 sub pp_sgrent { baseop(@_, "setgrent") }
1522 sub pp_egrent { baseop(@_, "endgrent") }
1523 sub pp_getlogin { baseop(@_, "getlogin") }
1524
1525 sub POSTFIX () { 1 }
1526
1527 # I couldn't think of a good short name, but this is the category of
1528 # symbolic unary operators with interesting precedence
1529
1530 sub pfixop {
1531     my $self = shift;
1532     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1533     my $kid = $op->first;
1534     $kid = $self->deparse($kid, $prec);
1535     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1536                                $cx, $prec);
1537 }
1538
1539 sub pp_preinc { pfixop(@_, "++", 23) }
1540 sub pp_predec { pfixop(@_, "--", 23) }
1541 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1542 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1543 sub pp_i_preinc { pfixop(@_, "++", 23) }
1544 sub pp_i_predec { pfixop(@_, "--", 23) }
1545 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1546 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1547 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1548
1549 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1550 sub real_negate {
1551     my $self = shift;
1552     my($op, $cx) = @_;
1553     if ($op->first->name =~ /^(i_)?negate$/) {
1554         # avoid --$x
1555         $self->pfixop($op, $cx, "-", 21.5);
1556     } else {
1557         $self->pfixop($op, $cx, "-", 21);       
1558     }
1559 }
1560 sub pp_i_negate { pp_negate(@_) }
1561
1562 sub pp_not {
1563     my $self = shift;
1564     my($op, $cx) = @_;
1565     if ($cx <= 4) {
1566         $self->pfixop($op, $cx, "not ", 4);
1567     } else {
1568         $self->pfixop($op, $cx, "!", 21);       
1569     }
1570 }
1571
1572 sub unop {
1573     my $self = shift;
1574     my($op, $cx, $name) = @_;
1575     my $kid;
1576     if ($op->flags & OPf_KIDS) {
1577         $kid = $op->first;
1578         if (defined prototype("CORE::$name")
1579            && prototype("CORE::$name") =~ /^;?\*/
1580            && $kid->name eq "rv2gv") {
1581             $kid = $kid->first;
1582         }
1583
1584         return $self->maybe_parens_unop($name, $kid, $cx);
1585     } else {
1586         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1587     }
1588 }
1589
1590 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1591 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1592 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1593 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1594 sub pp_defined { unop(@_, "defined") }
1595 sub pp_undef { unop(@_, "undef") }
1596 sub pp_study { unop(@_, "study") }
1597 sub pp_ref { unop(@_, "ref") }
1598 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1599
1600 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1601 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1602 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1603 sub pp_srand { unop(@_, "srand") }
1604 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1605 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1606 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1607 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1608 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1609 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1610 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1611
1612 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1613 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1614 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1615
1616 sub pp_each { unop(@_, "each") }
1617 sub pp_values { unop(@_, "values") }
1618 sub pp_keys { unop(@_, "keys") }
1619 sub pp_pop { unop(@_, "pop") }
1620 sub pp_shift { unop(@_, "shift") }
1621
1622 sub pp_caller { unop(@_, "caller") }
1623 sub pp_reset { unop(@_, "reset") }
1624 sub pp_exit { unop(@_, "exit") }
1625 sub pp_prototype { unop(@_, "prototype") }
1626
1627 sub pp_close { unop(@_, "close") }
1628 sub pp_fileno { unop(@_, "fileno") }
1629 sub pp_umask { unop(@_, "umask") }
1630 sub pp_untie { unop(@_, "untie") }
1631 sub pp_tied { unop(@_, "tied") }
1632 sub pp_dbmclose { unop(@_, "dbmclose") }
1633 sub pp_getc { unop(@_, "getc") }
1634 sub pp_eof { unop(@_, "eof") }
1635 sub pp_tell { unop(@_, "tell") }
1636 sub pp_getsockname { unop(@_, "getsockname") }
1637 sub pp_getpeername { unop(@_, "getpeername") }
1638
1639 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1640 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1641 sub pp_readlink { unop(@_, "readlink") }
1642 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1643 sub pp_readdir { unop(@_, "readdir") }
1644 sub pp_telldir { unop(@_, "telldir") }
1645 sub pp_rewinddir { unop(@_, "rewinddir") }
1646 sub pp_closedir { unop(@_, "closedir") }
1647 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1648 sub pp_localtime { unop(@_, "localtime") }
1649 sub pp_gmtime { unop(@_, "gmtime") }
1650 sub pp_alarm { unop(@_, "alarm") }
1651 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1652
1653 sub pp_dofile { unop(@_, "do") }
1654 sub pp_entereval { unop(@_, "eval") }
1655
1656 sub pp_ghbyname { unop(@_, "gethostbyname") }
1657 sub pp_gnbyname { unop(@_, "getnetbyname") }
1658 sub pp_gpbyname { unop(@_, "getprotobyname") }
1659 sub pp_shostent { unop(@_, "sethostent") }
1660 sub pp_snetent { unop(@_, "setnetent") }
1661 sub pp_sprotoent { unop(@_, "setprotoent") }
1662 sub pp_sservent { unop(@_, "setservent") }
1663 sub pp_gpwnam { unop(@_, "getpwnam") }
1664 sub pp_gpwuid { unop(@_, "getpwuid") }
1665 sub pp_ggrnam { unop(@_, "getgrnam") }
1666 sub pp_ggrgid { unop(@_, "getgrgid") }
1667
1668 sub pp_lock { unop(@_, "lock") }
1669
1670 sub pp_continue { unop(@_, "continue"); }
1671 sub pp_break {
1672     my ($self, $op) = @_;
1673     return "" if $op->flags & OPf_SPECIAL;
1674     unop(@_, "break");
1675 }
1676
1677 sub givwhen {
1678     my $self = shift;
1679     my($op, $cx, $givwhen) = @_;
1680
1681     my $enterop = $op->first;
1682     my ($head, $block);
1683     if ($enterop->flags & OPf_SPECIAL) {
1684         $head = "default";
1685         $block = $self->deparse($enterop->first, 0);
1686     }
1687     else {
1688         my $cond = $enterop->first;
1689         my $cond_str = $self->deparse($cond, 1);
1690         $head = "$givwhen ($cond_str)";
1691         $block = $self->deparse($cond->sibling, 0);
1692     }
1693
1694     return "$head {\n".
1695         "\t$block\n".
1696         "\b}\cK";
1697 }
1698
1699 sub pp_leavegiven { givwhen(@_, "given"); }
1700 sub pp_leavewhen  { givwhen(@_, "when"); }
1701
1702 sub pp_exists {
1703     my $self = shift;
1704     my($op, $cx) = @_;
1705     my $arg;
1706     if ($op->private & OPpEXISTS_SUB) {
1707         # Checking for the existence of a subroutine
1708         return $self->maybe_parens_func("exists",
1709                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1710     }
1711     if ($op->flags & OPf_SPECIAL) {
1712         # Array element, not hash element
1713         return $self->maybe_parens_func("exists",
1714                                 $self->pp_aelem($op->first, 16), $cx, 16);
1715     }
1716     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1717                                     $cx, 16);
1718 }
1719
1720 sub pp_delete {
1721     my $self = shift;
1722     my($op, $cx) = @_;
1723     my $arg;
1724     if ($op->private & OPpSLICE) {
1725         if ($op->flags & OPf_SPECIAL) {
1726             # Deleting from an array, not a hash
1727             return $self->maybe_parens_func("delete",
1728                                         $self->pp_aslice($op->first, 16),
1729                                         $cx, 16);
1730         }
1731         return $self->maybe_parens_func("delete",
1732                                         $self->pp_hslice($op->first, 16),
1733                                         $cx, 16);
1734     } else {
1735         if ($op->flags & OPf_SPECIAL) {
1736             # Deleting from an array, not a hash
1737             return $self->maybe_parens_func("delete",
1738                                         $self->pp_aelem($op->first, 16),
1739                                         $cx, 16);
1740         }
1741         return $self->maybe_parens_func("delete",
1742                                         $self->pp_helem($op->first, 16),
1743                                         $cx, 16);
1744     }
1745 }
1746
1747 sub pp_require {
1748     my $self = shift;
1749     my($op, $cx) = @_;
1750     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1751     if (class($op) eq "UNOP" and $op->first->name eq "const"
1752         and $op->first->private & OPpCONST_BARE)
1753     {
1754         my $name = $self->const_sv($op->first)->PV;
1755         $name =~ s[/][::]g;
1756         $name =~ s/\.pm//g;
1757         return "$opname $name";
1758     } else {    
1759         $self->unop($op, $cx, $opname);
1760     }
1761 }
1762
1763 sub pp_scalar {
1764     my $self = shift;
1765     my($op, $cx) = @_;
1766     my $kid = $op->first;
1767     if (not null $kid->sibling) {
1768         # XXX Was a here-doc
1769         return $self->dquote($op);
1770     }
1771     $self->unop(@_, "scalar");
1772 }
1773
1774
1775 sub padval {
1776     my $self = shift;
1777     my $targ = shift;
1778     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1779 }
1780
1781 sub anon_hash_or_list {
1782     my $self = shift;
1783     my($op, $cx) = @_;
1784
1785     my($pre, $post) = @{{"anonlist" => ["[","]"],
1786                          "anonhash" => ["{","}"]}->{$op->name}};
1787     my($expr, @exprs);
1788     $op = $op->first->sibling; # skip pushmark
1789     for (; !null($op); $op = $op->sibling) {
1790         $expr = $self->deparse($op, 6);
1791         push @exprs, $expr;
1792     }
1793     if ($pre eq "{" and $cx < 1) {
1794         # Disambiguate that it's not a block
1795         $pre = "+{";
1796     }
1797     return $pre . join(", ", @exprs) . $post;
1798 }
1799
1800 sub pp_anonlist {
1801     my $self = shift;
1802     my ($op, $cx) = @_;
1803     if ($op->flags & OPf_SPECIAL) {
1804         return $self->anon_hash_or_list($op, $cx);
1805     }
1806     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1807     return 'XXX';
1808 }
1809
1810 *pp_anonhash = \&pp_anonlist;
1811
1812 sub pp_refgen {
1813     my $self = shift;   
1814     my($op, $cx) = @_;
1815     my $kid = $op->first;
1816     if ($kid->name eq "null") {
1817         $kid = $kid->first;
1818         if ($kid->name eq "anonlist" || $kid->name eq "anonhash") {
1819             return $self->anon_hash_or_list($op, $cx);
1820         } elsif (!null($kid->sibling) and
1821                  $kid->sibling->name eq "anoncode") {
1822             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1823         } elsif ($kid->name eq "pushmark") {
1824             my $sib_name = $kid->sibling->name;
1825             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1826                 and not $kid->sibling->flags & OPf_REF)
1827             {
1828                 # The @a in \(@a) isn't in ref context, but only when the
1829                 # parens are there.
1830                 return "\\(" . $self->pp_list($op->first) . ")";
1831             } elsif ($sib_name eq 'entersub') {
1832                 my $text = $self->deparse($kid->sibling, 1);
1833                 # Always show parens for \(&func()), but only with -p otherwise
1834                 $text = "($text)" if $self->{'parens'}
1835                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1836                 return "\\$text";
1837             }
1838         }
1839     }
1840     $self->pfixop($op, $cx, "\\", 20);
1841 }
1842
1843 sub e_anoncode {
1844     my ($self, $info) = @_;
1845     my $text = $self->deparse_sub($info->{code});
1846     return "sub " . $text;
1847 }
1848
1849 sub pp_srefgen { pp_refgen(@_) }
1850
1851 sub pp_readline {
1852     my $self = shift;
1853     my($op, $cx) = @_;
1854     my $kid = $op->first;
1855     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1856     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1857     return $self->unop($op, $cx, "readline");
1858 }
1859
1860 sub pp_rcatline {
1861     my $self = shift;
1862     my($op) = @_;
1863     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1864 }
1865
1866 # Unary operators that can occur as pseudo-listops inside double quotes
1867 sub dq_unop {
1868     my $self = shift;
1869     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1870     my $kid;
1871     if ($op->flags & OPf_KIDS) {
1872        $kid = $op->first;
1873        # If there's more than one kid, the first is an ex-pushmark.
1874        $kid = $kid->sibling if not null $kid->sibling;
1875        return $self->maybe_parens_unop($name, $kid, $cx);
1876     } else {
1877        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1878     }
1879 }
1880
1881 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1882 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1883 sub pp_uc { dq_unop(@_, "uc") }
1884 sub pp_lc { dq_unop(@_, "lc") }
1885 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1886
1887 sub loopex {
1888     my $self = shift;
1889     my ($op, $cx, $name) = @_;
1890     if (class($op) eq "PVOP") {
1891         return "$name " . $op->pv;
1892     } elsif (class($op) eq "OP") {
1893         return $name;
1894     } elsif (class($op) eq "UNOP") {
1895         # Note -- loop exits are actually exempt from the
1896         # looks-like-a-func rule, but a few extra parens won't hurt
1897         return $self->maybe_parens_unop($name, $op->first, $cx);
1898     }
1899 }
1900
1901 sub pp_last { loopex(@_, "last") }
1902 sub pp_next { loopex(@_, "next") }
1903 sub pp_redo { loopex(@_, "redo") }
1904 sub pp_goto { loopex(@_, "goto") }
1905 sub pp_dump { loopex(@_, "dump") }
1906
1907 sub ftst {
1908     my $self = shift;
1909     my($op, $cx, $name) = @_;
1910     if (class($op) eq "UNOP") {
1911         # Genuine `-X' filetests are exempt from the LLAFR, but not
1912         # l?stat(); for the sake of clarity, give'em all parens
1913         return $self->maybe_parens_unop($name, $op->first, $cx);
1914     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
1915         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1916     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1917         return $name;
1918     }
1919 }
1920
1921 sub pp_lstat    { ftst(@_, "lstat") }
1922 sub pp_stat     { ftst(@_, "stat") }
1923 sub pp_ftrread  { ftst(@_, "-R") }
1924 sub pp_ftrwrite { ftst(@_, "-W") }
1925 sub pp_ftrexec  { ftst(@_, "-X") }
1926 sub pp_fteread  { ftst(@_, "-r") }
1927 sub pp_ftewrite { ftst(@_, "-w") }
1928 sub pp_fteexec  { ftst(@_, "-x") }
1929 sub pp_ftis     { ftst(@_, "-e") }
1930 sub pp_fteowned { ftst(@_, "-O") }
1931 sub pp_ftrowned { ftst(@_, "-o") }
1932 sub pp_ftzero   { ftst(@_, "-z") }
1933 sub pp_ftsize   { ftst(@_, "-s") }
1934 sub pp_ftmtime  { ftst(@_, "-M") }
1935 sub pp_ftatime  { ftst(@_, "-A") }
1936 sub pp_ftctime  { ftst(@_, "-C") }
1937 sub pp_ftsock   { ftst(@_, "-S") }
1938 sub pp_ftchr    { ftst(@_, "-c") }
1939 sub pp_ftblk    { ftst(@_, "-b") }
1940 sub pp_ftfile   { ftst(@_, "-f") }
1941 sub pp_ftdir    { ftst(@_, "-d") }
1942 sub pp_ftpipe   { ftst(@_, "-p") }
1943 sub pp_ftlink   { ftst(@_, "-l") }
1944 sub pp_ftsuid   { ftst(@_, "-u") }
1945 sub pp_ftsgid   { ftst(@_, "-g") }
1946 sub pp_ftsvtx   { ftst(@_, "-k") }
1947 sub pp_fttty    { ftst(@_, "-t") }
1948 sub pp_fttext   { ftst(@_, "-T") }
1949 sub pp_ftbinary { ftst(@_, "-B") }
1950
1951 sub SWAP_CHILDREN () { 1 }
1952 sub ASSIGN () { 2 } # has OP= variant
1953 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1954
1955 my(%left, %right);
1956
1957 sub assoc_class {
1958     my $op = shift;
1959     my $name = $op->name;
1960     if ($name eq "concat" and $op->first->name eq "concat") {
1961         # avoid spurious `=' -- see comment in pp_concat
1962         return "concat";
1963     }
1964     if ($name eq "null" and class($op) eq "UNOP"
1965         and $op->first->name =~ /^(and|x?or)$/
1966         and null $op->first->sibling)
1967     {
1968         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1969         # with a null that's used as the common end point of the two
1970         # flows of control. For precedence purposes, ignore it.
1971         # (COND_EXPRs have these too, but we don't bother with
1972         # their associativity).
1973         return assoc_class($op->first);
1974     }
1975     return $name . ($op->flags & OPf_STACKED ? "=" : "");
1976 }
1977
1978 # Left associative operators, like `+', for which
1979 # $a + $b + $c is equivalent to ($a + $b) + $c
1980
1981 BEGIN {
1982     %left = ('multiply' => 19, 'i_multiply' => 19,
1983              'divide' => 19, 'i_divide' => 19,
1984              'modulo' => 19, 'i_modulo' => 19,
1985              'repeat' => 19,
1986              'add' => 18, 'i_add' => 18,
1987              'subtract' => 18, 'i_subtract' => 18,
1988              'concat' => 18,
1989              'left_shift' => 17, 'right_shift' => 17,
1990              'bit_and' => 13,
1991              'bit_or' => 12, 'bit_xor' => 12,
1992              'and' => 3,
1993              'or' => 2, 'xor' => 2,
1994             );
1995 }
1996
1997 sub deparse_binop_left {
1998     my $self = shift;
1999     my($op, $left, $prec) = @_;
2000     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2001         and $left{assoc_class($op)} == $left{assoc_class($left)})
2002     {
2003         return $self->deparse($left, $prec - .00001);
2004     } else {
2005         return $self->deparse($left, $prec);    
2006     }
2007 }
2008
2009 # Right associative operators, like `=', for which
2010 # $a = $b = $c is equivalent to $a = ($b = $c)
2011
2012 BEGIN {
2013     %right = ('pow' => 22,
2014               'sassign=' => 7, 'aassign=' => 7,
2015               'multiply=' => 7, 'i_multiply=' => 7,
2016               'divide=' => 7, 'i_divide=' => 7,
2017               'modulo=' => 7, 'i_modulo=' => 7,
2018               'repeat=' => 7,
2019               'add=' => 7, 'i_add=' => 7,
2020               'subtract=' => 7, 'i_subtract=' => 7,
2021               'concat=' => 7,
2022               'left_shift=' => 7, 'right_shift=' => 7,
2023               'bit_and=' => 7,
2024               'bit_or=' => 7, 'bit_xor=' => 7,
2025               'andassign' => 7,
2026               'orassign' => 7,
2027              );
2028 }
2029
2030 sub deparse_binop_right {
2031     my $self = shift;
2032     my($op, $right, $prec) = @_;
2033     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2034         and $right{assoc_class($op)} == $right{assoc_class($right)})
2035     {
2036         return $self->deparse($right, $prec - .00001);
2037     } else {
2038         return $self->deparse($right, $prec);   
2039     }
2040 }
2041
2042 sub binop {
2043     my $self = shift;
2044     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2045     my $left = $op->first;
2046     my $right = $op->last;
2047     my $eq = "";
2048     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2049         $eq = "=";
2050         $prec = 7;
2051     }
2052     if ($flags & SWAP_CHILDREN) {
2053         ($left, $right) = ($right, $left);
2054     }
2055     $left = $self->deparse_binop_left($op, $left, $prec);
2056     $left = "($left)" if $flags & LIST_CONTEXT
2057                 && $left !~ /^(my|our|local|)[\@\(]/;
2058     $right = $self->deparse_binop_right($op, $right, $prec);
2059     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2060 }
2061
2062 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2063 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2064 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2065 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2066 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2067 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2068 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2069 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2070 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2071 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2072 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2073
2074 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2075 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2076 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2077 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2078 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2079
2080 sub pp_eq { binop(@_, "==", 14) }
2081 sub pp_ne { binop(@_, "!=", 14) }
2082 sub pp_lt { binop(@_, "<", 15) }
2083 sub pp_gt { binop(@_, ">", 15) }
2084 sub pp_ge { binop(@_, ">=", 15) }
2085 sub pp_le { binop(@_, "<=", 15) }
2086 sub pp_ncmp { binop(@_, "<=>", 14) }
2087 sub pp_i_eq { binop(@_, "==", 14) }
2088 sub pp_i_ne { binop(@_, "!=", 14) }
2089 sub pp_i_lt { binop(@_, "<", 15) }
2090 sub pp_i_gt { binop(@_, ">", 15) }
2091 sub pp_i_ge { binop(@_, ">=", 15) }
2092 sub pp_i_le { binop(@_, "<=", 15) }
2093 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2094
2095 sub pp_seq { binop(@_, "eq", 14) }
2096 sub pp_sne { binop(@_, "ne", 14) }
2097 sub pp_slt { binop(@_, "lt", 15) }
2098 sub pp_sgt { binop(@_, "gt", 15) }
2099 sub pp_sge { binop(@_, "ge", 15) }
2100 sub pp_sle { binop(@_, "le", 15) }
2101 sub pp_scmp { binop(@_, "cmp", 14) }
2102
2103 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2104 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2105
2106 sub pp_smartmatch {
2107     my ($self, $op, $cx) = @_;
2108     if ($op->flags & OPf_SPECIAL) {
2109         return $self->deparse($op->first, $cx);
2110     }
2111     else {
2112         binop(@_, "~~", 14);
2113     }
2114 }
2115
2116 # `.' is special because concats-of-concats are optimized to save copying
2117 # by making all but the first concat stacked. The effect is as if the
2118 # programmer had written `($a . $b) .= $c', except legal.
2119 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2120 sub real_concat {
2121     my $self = shift;
2122     my($op, $cx) = @_;
2123     my $left = $op->first;
2124     my $right = $op->last;
2125     my $eq = "";
2126     my $prec = 18;
2127     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2128         $eq = "=";
2129         $prec = 7;
2130     }
2131     $left = $self->deparse_binop_left($op, $left, $prec);
2132     $right = $self->deparse_binop_right($op, $right, $prec);
2133     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2134 }
2135
2136 # `x' is weird when the left arg is a list
2137 sub pp_repeat {
2138     my $self = shift;
2139     my($op, $cx) = @_;
2140     my $left = $op->first;
2141     my $right = $op->last;
2142     my $eq = "";
2143     my $prec = 19;
2144     if ($op->flags & OPf_STACKED) {
2145         $eq = "=";
2146         $prec = 7;
2147     }
2148     if (null($right)) { # list repeat; count is inside left-side ex-list
2149         my $kid = $left->first->sibling; # skip pushmark
2150         my @exprs;
2151         for (; !null($kid->sibling); $kid = $kid->sibling) {
2152             push @exprs, $self->deparse($kid, 6);
2153         }
2154         $right = $kid;
2155         $left = "(" . join(", ", @exprs). ")";
2156     } else {
2157         $left = $self->deparse_binop_left($op, $left, $prec);
2158     }
2159     $right = $self->deparse_binop_right($op, $right, $prec);
2160     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2161 }
2162
2163 sub range {
2164     my $self = shift;
2165     my ($op, $cx, $type) = @_;
2166     my $left = $op->first;
2167     my $right = $left->sibling;
2168     $left = $self->deparse($left, 9);
2169     $right = $self->deparse($right, 9);
2170     return $self->maybe_parens("$left $type $right", $cx, 9);
2171 }
2172
2173 sub pp_flop {
2174     my $self = shift;
2175     my($op, $cx) = @_;
2176     my $flip = $op->first;
2177     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2178     return $self->range($flip->first, $cx, $type);
2179 }
2180
2181 # one-line while/until is handled in pp_leave
2182
2183 sub logop {
2184     my $self = shift;
2185     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2186     my $left = $op->first;
2187     my $right = $op->first->sibling;
2188     if ($cx < 1 and is_scope($right) and $blockname
2189         and $self->{'expand'} < 7)
2190     { # if ($a) {$b}
2191         $left = $self->deparse($left, 1);
2192         $right = $self->deparse($right, 0);
2193         return "$blockname ($left) {\n\t$right\n\b}\cK";
2194     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2195              and $self->{'expand'} < 7) { # $b if $a
2196         $right = $self->deparse($right, 1);
2197         $left = $self->deparse($left, 1);
2198         return "$right $blockname $left";
2199     } elsif ($cx > $lowprec and $highop) { # $a && $b
2200         $left = $self->deparse_binop_left($op, $left, $highprec);
2201         $right = $self->deparse_binop_right($op, $right, $highprec);
2202         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2203     } else { # $a and $b
2204         $left = $self->deparse_binop_left($op, $left, $lowprec);
2205         $right = $self->deparse_binop_right($op, $right, $lowprec);
2206         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2207     }
2208 }
2209
2210 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2211 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2212 sub pp_dor { logop(@_, "err", 2, "//", 10, "") }
2213
2214 # xor is syntactically a logop, but it's really a binop (contrary to
2215 # old versions of opcode.pl). Syntax is what matters here.
2216 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2217
2218 sub logassignop {
2219     my $self = shift;
2220     my ($op, $cx, $opname) = @_;
2221     my $left = $op->first;
2222     my $right = $op->first->sibling->first; # skip sassign
2223     $left = $self->deparse($left, 7);
2224     $right = $self->deparse($right, 7);
2225     return $self->maybe_parens("$left $opname $right", $cx, 7);
2226 }
2227
2228 sub pp_andassign { logassignop(@_, "&&=") }
2229 sub pp_orassign  { logassignop(@_, "||=") }
2230 sub pp_dorassign { logassignop(@_, "//=") }
2231
2232 sub listop {
2233     my $self = shift;
2234     my($op, $cx, $name) = @_;
2235     my(@exprs);
2236     my $parens = ($cx >= 5) || $self->{'parens'};
2237     my $kid = $op->first->sibling;
2238     return $name if null $kid;
2239     my $first;
2240     $name = "socketpair" if $name eq "sockpair";
2241     my $proto = prototype("CORE::$name");
2242     if (defined $proto
2243         && $proto =~ /^;?\*/
2244         && $kid->name eq "rv2gv") {
2245         $first = $self->deparse($kid->first, 6);
2246     }
2247     else {
2248         $first = $self->deparse($kid, 6);
2249     }
2250     if ($name eq "chmod" && $first =~ /^\d+$/) {
2251         $first = sprintf("%#o", $first);
2252     }
2253     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2254     push @exprs, $first;
2255     $kid = $kid->sibling;
2256     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2257         push @exprs, $self->deparse($kid->first, 6);
2258         $kid = $kid->sibling;
2259     }
2260     for (; !null($kid); $kid = $kid->sibling) {
2261         push @exprs, $self->deparse($kid, 6);
2262     }
2263     if ($parens) {
2264         return "$name(" . join(", ", @exprs) . ")";
2265     } else {
2266         return "$name " . join(", ", @exprs);
2267     }
2268 }
2269
2270 sub pp_bless { listop(@_, "bless") }
2271 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2272 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2273 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2274 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2275 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2276 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2277 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2278 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2279 sub pp_unpack { listop(@_, "unpack") }
2280 sub pp_pack { listop(@_, "pack") }
2281 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2282 sub pp_splice { listop(@_, "splice") }
2283 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2284 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2285 sub pp_reverse { listop(@_, "reverse") }
2286 sub pp_warn { listop(@_, "warn") }
2287 sub pp_die { listop(@_, "die") }
2288 # Actually, return is exempt from the LLAFR (see examples in this very
2289 # module!), but for consistency's sake, ignore that fact
2290 sub pp_return { listop(@_, "return") }
2291 sub pp_open { listop(@_, "open") }
2292 sub pp_pipe_op { listop(@_, "pipe") }
2293 sub pp_tie { listop(@_, "tie") }
2294 sub pp_binmode { listop(@_, "binmode") }
2295 sub pp_dbmopen { listop(@_, "dbmopen") }
2296 sub pp_sselect { listop(@_, "select") }
2297 sub pp_select { listop(@_, "select") }
2298 sub pp_read { listop(@_, "read") }
2299 sub pp_sysopen { listop(@_, "sysopen") }
2300 sub pp_sysseek { listop(@_, "sysseek") }
2301 sub pp_sysread { listop(@_, "sysread") }
2302 sub pp_syswrite { listop(@_, "syswrite") }
2303 sub pp_send { listop(@_, "send") }
2304 sub pp_recv { listop(@_, "recv") }
2305 sub pp_seek { listop(@_, "seek") }
2306 sub pp_fcntl { listop(@_, "fcntl") }
2307 sub pp_ioctl { listop(@_, "ioctl") }
2308 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2309 sub pp_socket { listop(@_, "socket") }
2310 sub pp_sockpair { listop(@_, "sockpair") }
2311 sub pp_bind { listop(@_, "bind") }
2312 sub pp_connect { listop(@_, "connect") }
2313 sub pp_listen { listop(@_, "listen") }
2314 sub pp_accept { listop(@_, "accept") }
2315 sub pp_shutdown { listop(@_, "shutdown") }
2316 sub pp_gsockopt { listop(@_, "getsockopt") }
2317 sub pp_ssockopt { listop(@_, "setsockopt") }
2318 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2319 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2320 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2321 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2322 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2323 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2324 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2325 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2326 sub pp_open_dir { listop(@_, "opendir") }
2327 sub pp_seekdir { listop(@_, "seekdir") }
2328 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2329 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2330 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2331 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2332 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2333 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2334 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2335 sub pp_shmget { listop(@_, "shmget") }
2336 sub pp_shmctl { listop(@_, "shmctl") }
2337 sub pp_shmread { listop(@_, "shmread") }
2338 sub pp_shmwrite { listop(@_, "shmwrite") }
2339 sub pp_msgget { listop(@_, "msgget") }
2340 sub pp_msgctl { listop(@_, "msgctl") }
2341 sub pp_msgsnd { listop(@_, "msgsnd") }
2342 sub pp_msgrcv { listop(@_, "msgrcv") }
2343 sub pp_semget { listop(@_, "semget") }
2344 sub pp_semctl { listop(@_, "semctl") }
2345 sub pp_semop { listop(@_, "semop") }
2346 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2347 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2348 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2349 sub pp_gsbyname { listop(@_, "getservbyname") }
2350 sub pp_gsbyport { listop(@_, "getservbyport") }
2351 sub pp_syscall { listop(@_, "syscall") }
2352
2353 sub pp_glob {
2354     my $self = shift;
2355     my($op, $cx) = @_;
2356     my $text = $self->dq($op->first->sibling);  # skip pushmark
2357     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2358         or $text =~ /[<>]/) {
2359         return 'glob(' . single_delim('qq', '"', $text) . ')';
2360     } else {
2361         return '<' . $text . '>';
2362     }
2363 }
2364
2365 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2366 # be a filehandle. This could probably be better fixed in the core
2367 # by moving the GV lookup into ck_truc.
2368
2369 sub pp_truncate {
2370     my $self = shift;
2371     my($op, $cx) = @_;
2372     my(@exprs);
2373     my $parens = ($cx >= 5) || $self->{'parens'};
2374     my $kid = $op->first->sibling;
2375     my $fh;
2376     if ($op->flags & OPf_SPECIAL) {
2377         # $kid is an OP_CONST
2378         $fh = $self->const_sv($kid)->PV;
2379     } else {
2380         $fh = $self->deparse($kid, 6);
2381         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2382     }
2383     my $len = $self->deparse($kid->sibling, 6);
2384     if ($parens) {
2385         return "truncate($fh, $len)";
2386     } else {
2387         return "truncate $fh, $len";
2388     }
2389 }
2390
2391 sub indirop {
2392     my $self = shift;
2393     my($op, $cx, $name) = @_;
2394     my($expr, @exprs);
2395     my $kid = $op->first->sibling;
2396     my $indir = "";
2397     if ($op->flags & OPf_STACKED) {
2398         $indir = $kid;
2399         $indir = $indir->first; # skip rv2gv
2400         if (is_scope($indir)) {
2401             $indir = "{" . $self->deparse($indir, 0) . "}";
2402             $indir = "{;}" if $indir eq "{}";
2403         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2404             $indir = $self->const_sv($indir)->PV;
2405         } else {
2406             $indir = $self->deparse($indir, 24);
2407         }
2408         $indir = $indir . " ";
2409         $kid = $kid->sibling;
2410     }
2411     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2412         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2413                                                   : '{$a <=> $b} ';
2414     }
2415     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2416         $indir = '{$b cmp $a} ';
2417     }
2418     for (; !null($kid); $kid = $kid->sibling) {
2419         $expr = $self->deparse($kid, 6);
2420         push @exprs, $expr;
2421     }
2422     my $name2 = $name;
2423     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2424         $name2 = 'reverse sort';
2425     }
2426     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2427         return "$exprs[0] = $name2 $indir $exprs[0]";
2428     }
2429
2430     my $args = $indir . join(", ", @exprs);
2431     if ($indir ne "" and $name eq "sort") {
2432         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2433         # give bareword warnings in that case. Therefore if context
2434         # requires, we'll put parens around the outside "(sort f 1, 2,
2435         # 3)". Unfortunately, we'll currently think the parens are
2436         # necessary more often that they really are, because we don't
2437         # distinguish which side of an assignment we're on.
2438         if ($cx >= 5) {
2439             return "($name2 $args)";
2440         } else {
2441             return "$name2 $args";
2442         }
2443     } else {
2444         return $self->maybe_parens_func($name2, $args, $cx, 5);
2445     }
2446
2447 }
2448
2449 sub pp_prtf { indirop(@_, "printf") }
2450 sub pp_print { indirop(@_, "print") }
2451 sub pp_say  { indirop(@_, "say") }
2452 sub pp_sort { indirop(@_, "sort") }
2453
2454 sub mapop {
2455     my $self = shift;
2456     my($op, $cx, $name) = @_;
2457     my($expr, @exprs);
2458     my $kid = $op->first; # this is the (map|grep)start
2459     $kid = $kid->first->sibling; # skip a pushmark
2460     my $code = $kid->first; # skip a null
2461     if (is_scope $code) {
2462         $code = "{" . $self->deparse($code, 0) . "} ";
2463     } else {
2464         $code = $self->deparse($code, 24) . ", ";
2465     }
2466     $kid = $kid->sibling;
2467     for (; !null($kid); $kid = $kid->sibling) {
2468         $expr = $self->deparse($kid, 6);
2469         push @exprs, $expr if defined $expr;
2470     }
2471     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2472 }
2473
2474 sub pp_mapwhile { mapop(@_, "map") }
2475 sub pp_grepwhile { mapop(@_, "grep") }
2476 sub pp_mapstart { baseop(@_, "map") }
2477 sub pp_grepstart { baseop(@_, "grep") }
2478
2479 sub pp_list {
2480     my $self = shift;
2481     my($op, $cx) = @_;
2482     my($expr, @exprs);
2483     my $kid = $op->first->sibling; # skip pushmark
2484     my $lop;
2485     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2486     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2487         # This assumes that no other private flags equal 128, and that
2488         # OPs that store things other than flags in their op_private,
2489         # like OP_AELEMFAST, won't be immediate children of a list.
2490         #
2491         # OP_ENTERSUB can break this logic, so check for it.
2492         # I suspect that open and exit can too.
2493
2494         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2495                 or $lop->name eq "undef")
2496             or $lop->name eq "entersub"
2497             or $lop->name eq "exit"
2498             or $lop->name eq "open")
2499         {
2500             $local = ""; # or not
2501             last;
2502         }
2503         if ($lop->name =~ /^pad[ash]v$/) {
2504             if ($lop->private & OPpPAD_STATE) { # state()
2505                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2506                 $local = "state";
2507             } else { # my()
2508                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2509                 $local = "my";
2510             }
2511         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2512                         && $lop->private & OPpOUR_INTRO
2513                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2514                         && $lop->first->private & OPpOUR_INTRO) { # our()
2515             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2516             $local = "our";
2517         } elsif ($lop->name ne "undef"
2518                 # specifically avoid the "reverse sort" optimisation,
2519                 # where "reverse" is nullified
2520                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2521         {
2522             # local()
2523             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2524             $local = "local";
2525         }
2526     }
2527     $local = "" if $local eq "either"; # no point if it's all undefs
2528     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2529     for (; !null($kid); $kid = $kid->sibling) {
2530         if ($local) {
2531             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2532                 $lop = $kid->first;
2533             } else {
2534                 $lop = $kid;
2535             }
2536             $self->{'avoid_local'}{$$lop}++;
2537             $expr = $self->deparse($kid, 6);
2538             delete $self->{'avoid_local'}{$$lop};
2539         } else {
2540             $expr = $self->deparse($kid, 6);
2541         }
2542         push @exprs, $expr;
2543     }
2544     if ($local) {
2545         return "$local(" . join(", ", @exprs) . ")";
2546     } else {
2547         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
2548     }
2549 }
2550
2551 sub is_ifelse_cont {
2552     my $op = shift;
2553     return ($op->name eq "null" and class($op) eq "UNOP"
2554             and $op->first->name =~ /^(and|cond_expr)$/
2555             and is_scope($op->first->first->sibling));
2556 }
2557
2558 sub pp_cond_expr {
2559     my $self = shift;
2560     my($op, $cx) = @_;
2561     my $cond = $op->first;
2562     my $true = $cond->sibling;
2563     my $false = $true->sibling;
2564     my $cuddle = $self->{'cuddle'};
2565     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2566             (is_scope($false) || is_ifelse_cont($false))
2567             and $self->{'expand'} < 7) {
2568         $cond = $self->deparse($cond, 8);
2569         $true = $self->deparse($true, 6);
2570         $false = $self->deparse($false, 8);
2571         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2572     }
2573
2574     $cond = $self->deparse($cond, 1);
2575     $true = $self->deparse($true, 0);
2576     my $head = "if ($cond) {\n\t$true\n\b}";
2577     my @elsifs;
2578     while (!null($false) and is_ifelse_cont($false)) {
2579         my $newop = $false->first;
2580         my $newcond = $newop->first;
2581         my $newtrue = $newcond->sibling;
2582         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2583         $newcond = $self->deparse($newcond, 1);
2584         $newtrue = $self->deparse($newtrue, 0);
2585         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2586     }
2587     if (!null($false)) {
2588         $false = $cuddle . "else {\n\t" .
2589           $self->deparse($false, 0) . "\n\b}\cK";
2590     } else {
2591         $false = "\cK";
2592     }
2593     return $head . join($cuddle, "", @elsifs) . $false;
2594 }
2595
2596 sub pp_once {
2597     my ($self, $op, $cx) = @_;
2598     my $cond = $op->first;
2599     my $true = $cond->sibling;
2600
2601     return $self->deparse($true, $cx);
2602 }
2603
2604 sub loop_common {
2605     my $self = shift;
2606     my($op, $cx, $init) = @_;
2607     my $enter = $op->first;
2608     my $kid = $enter->sibling;
2609     local(@$self{qw'curstash warnings hints hinthash'})
2610                 = @$self{qw'curstash warnings hints hinthash'};
2611     my $head = "";
2612     my $bare = 0;
2613     my $body;
2614     my $cond = undef;
2615     if ($kid->name eq "lineseq") { # bare or infinite loop
2616         if ($kid->last->name eq "unstack") { # infinite
2617             $head = "while (1) "; # Can't use for(;;) if there's a continue
2618             $cond = "";
2619         } else {
2620             $bare = 1;
2621         }
2622         $body = $kid;
2623     } elsif ($enter->name eq "enteriter") { # foreach
2624         my $ary = $enter->first->sibling; # first was pushmark
2625         my $var = $ary->sibling;
2626         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2627             # "reverse" was optimised away
2628             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2629         } elsif ($enter->flags & OPf_STACKED
2630             and not null $ary->first->sibling->sibling)
2631         {
2632             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2633               $self->deparse($ary->first->sibling->sibling, 9);
2634         } else {
2635             $ary = $self->deparse($ary, 1);
2636         }
2637         if (null $var) {
2638             if ($enter->flags & OPf_SPECIAL) { # thread special var
2639                 $var = $self->pp_threadsv($enter, 1);
2640             } else { # regular my() variable
2641                 $var = $self->pp_padsv($enter, 1);
2642             }
2643         } elsif ($var->name eq "rv2gv") {
2644             $var = $self->pp_rv2sv($var, 1);
2645             if ($enter->private & OPpOUR_INTRO) {
2646                 # our declarations don't have package names
2647                 $var =~ s/^(.).*::/$1/;
2648                 $var = "our $var";
2649             }
2650         } elsif ($var->name eq "gv") {
2651             $var = "\$" . $self->deparse($var, 1);
2652         }
2653         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2654         if (!is_state $body->first and $body->first->name ne "stub") {
2655             confess unless $var eq '$_';
2656             $body = $body->first;
2657             return $self->deparse($body, 2) . " foreach ($ary)";
2658         }
2659         $head = "foreach $var ($ary) ";
2660     } elsif ($kid->name eq "null") { # while/until
2661         $kid = $kid->first;
2662         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2663         $cond = $self->deparse($kid->first, 1);
2664         $head = "$name ($cond) ";
2665         $body = $kid->first->sibling;
2666     } elsif ($kid->name eq "stub") { # bare and empty
2667         return "{;}"; # {} could be a hashref
2668     }
2669     # If there isn't a continue block, then the next pointer for the loop
2670     # will point to the unstack, which is kid's last child, except
2671     # in a bare loop, when it will point to the leaveloop. When neither of
2672     # these conditions hold, then the second-to-last child is the continue
2673     # block (or the last in a bare loop).
2674     my $cont_start = $enter->nextop;
2675     my $cont;
2676     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2677         if ($bare) {
2678             $cont = $body->last;
2679         } else {
2680             $cont = $body->first;
2681             while (!null($cont->sibling->sibling)) {
2682                 $cont = $cont->sibling;
2683             }
2684         }
2685         my $state = $body->first;
2686         my $cuddle = $self->{'cuddle'};
2687         my @states;
2688         for (; $$state != $$cont; $state = $state->sibling) {
2689             push @states, $state;
2690         }
2691         $body = $self->lineseq(undef, @states);
2692         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2693             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2694             $cont = "\cK";
2695         } else {
2696             $cont = $cuddle . "continue {\n\t" .
2697               $self->deparse($cont, 0) . "\n\b}\cK";
2698         }
2699     } else {
2700         return "" if !defined $body;
2701         if (length $init) {
2702             $head = "for ($init; $cond;) ";
2703         }
2704         $cont = "\cK";
2705         $body = $self->deparse($body, 0);
2706     }
2707     $body =~ s/;?$/;\n/;
2708
2709     return $head . "{\n\t" . $body . "\b}" . $cont;
2710 }
2711
2712 sub pp_leaveloop { shift->loop_common(@_, "") }
2713
2714 sub for_loop {
2715     my $self = shift;
2716     my($op, $cx) = @_;
2717     my $init = $self->deparse($op, 1);
2718     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2719 }
2720
2721 sub pp_leavetry {
2722     my $self = shift;
2723     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2724 }
2725
2726 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2727 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2728 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2729 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2730
2731 sub pp_null {
2732     my $self = shift;
2733     my($op, $cx) = @_;
2734     if (class($op) eq "OP") {
2735         # old value is lost
2736         return $self->{'ex_const'} if $op->targ == OP_CONST;
2737     } elsif ($op->first->name eq "pushmark") {
2738         return $self->pp_list($op, $cx);
2739     } elsif ($op->first->name eq "enter") {
2740         return $self->pp_leave($op, $cx);
2741     } elsif ($op->first->name eq "leave") {
2742         return $self->pp_leave($op->first, $cx);
2743     } elsif ($op->first->name eq "scope") {
2744         return $self->pp_scope($op->first, $cx);
2745     } elsif ($op->targ == OP_STRINGIFY) {
2746         return $self->dquote($op, $cx);
2747     } elsif (!null($op->first->sibling) and
2748              $op->first->sibling->name eq "readline" and
2749              $op->first->sibling->flags & OPf_STACKED) {
2750         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2751                                    . $self->deparse($op->first->sibling, 7),
2752                                    $cx, 7);
2753     } elsif (!null($op->first->sibling) and
2754              $op->first->sibling->name eq "trans" and
2755              $op->first->sibling->flags & OPf_STACKED) {
2756         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2757                                    . $self->deparse($op->first->sibling, 20),
2758                                    $cx, 20);
2759     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2760         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2761     } elsif (!null($op->first->sibling) and
2762              $op->first->sibling->name eq "null" and
2763              class($op->first->sibling) eq "UNOP" and
2764              $op->first->sibling->first->flags & OPf_STACKED and
2765              $op->first->sibling->first->name eq "rcatline") {
2766         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2767                                    . $self->deparse($op->first->sibling, 18),
2768                                    $cx, 18);
2769     } else {
2770         return $self->deparse($op->first, $cx);
2771     }
2772 }
2773
2774 sub padname {
2775     my $self = shift;
2776     my $targ = shift;
2777     return $self->padname_sv($targ)->PVX;
2778 }
2779
2780 sub padany {
2781     my $self = shift;
2782     my $op = shift;
2783     return substr($self->padname($op->targ), 1); # skip $/@/%
2784 }
2785
2786 sub pp_padsv {
2787     my $self = shift;
2788     my($op, $cx) = @_;
2789     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2790 }
2791
2792 sub pp_padav { pp_padsv(@_) }
2793 sub pp_padhv { pp_padsv(@_) }
2794
2795 my @threadsv_names;
2796
2797 BEGIN {
2798     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2799                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2800                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2801                        "!", "@");
2802 }
2803
2804 sub pp_threadsv {
2805     my $self = shift;
2806     my($op, $cx) = @_;
2807     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2808 }
2809
2810 sub gv_or_padgv {
2811     my $self = shift;
2812     my $op = shift;
2813     if (class($op) eq "PADOP") {
2814         return $self->padval($op->padix);
2815     } else { # class($op) eq "SVOP"
2816         return $op->gv;
2817     }
2818 }
2819
2820 sub pp_gvsv {
2821     my $self = shift;
2822     my($op, $cx) = @_;
2823     my $gv = $self->gv_or_padgv($op);
2824     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2825                                  $self->gv_name($gv)));
2826 }
2827
2828 sub pp_gv {
2829     my $self = shift;
2830     my($op, $cx) = @_;
2831     my $gv = $self->gv_or_padgv($op);
2832     return $self->gv_name($gv);
2833 }
2834
2835 sub pp_aelemfast {
2836     my $self = shift;
2837     my($op, $cx) = @_;
2838     my $name;
2839     if ($op->flags & OPf_SPECIAL) { # optimised PADAV
2840         $name = $self->padname($op->targ);
2841         $name =~ s/^@/\$/;
2842     }
2843     else {
2844         my $gv = $self->gv_or_padgv($op);
2845         $name = $self->gv_name($gv);
2846         $name = $self->{'curstash'}."::$name"
2847             if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2848         $name = '$' . $name;
2849     }
2850
2851     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2852 }
2853
2854 sub rv2x {
2855     my $self = shift;
2856     my($op, $cx, $type) = @_;
2857
2858     if (class($op) eq 'NULL' || !$op->can("first")) {
2859         carp("Unexpected op in pp_rv2x");
2860         return 'XXX';
2861     }
2862     my $kid = $op->first;
2863     if ($kid->name eq "gv") {
2864         return $self->stash_variable($type, $self->deparse($kid, 0));
2865     } elsif (is_scalar $kid) {
2866         my $str = $self->deparse($kid, 0);
2867         if ($str =~ /^\$([^\w\d])\z/) {
2868             # "$$+" isn't a legal way to write the scalar dereference
2869             # of $+, since the lexer can't tell you aren't trying to
2870             # do something like "$$ + 1" to get one more than your
2871             # PID. Either "${$+}" or "$${+}" are workable
2872             # disambiguations, but if the programmer did the former,
2873             # they'd be in the "else" clause below rather than here.
2874             # It's not clear if this should somehow be unified with
2875             # the code in dq and re_dq that also adds lexer
2876             # disambiguation braces.
2877             $str = '$' . "{$1}"; #'
2878         }
2879         return $type . $str;
2880     } else {
2881         return $type . "{" . $self->deparse($kid, 0) . "}";
2882     }
2883 }
2884
2885 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2886 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2887 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2888
2889 # skip rv2av
2890 sub pp_av2arylen {
2891     my $self = shift;
2892     my($op, $cx) = @_;
2893     if ($op->first->name eq "padav") {
2894         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2895     } else {
2896         return $self->maybe_local($op, $cx,
2897                                   $self->rv2x($op->first, $cx, '$#'));
2898     }
2899 }
2900
2901 # skip down to the old, ex-rv2cv
2902 sub pp_rv2cv {
2903     my ($self, $op, $cx) = @_;
2904     if (!null($op->first) && $op->first->name eq 'null' &&
2905         $op->first->targ eq OP_LIST)
2906     {
2907         return $self->rv2x($op->first->first->sibling, $cx, "&")
2908     }
2909     else {
2910         return $self->rv2x($op, $cx, "")
2911     }
2912 }
2913
2914 sub list_const {
2915     my $self = shift;
2916     my($cx, @list) = @_;
2917     my @a = map $self->const($_, 6), @list;
2918     if (@a == 0) {
2919         return "()";
2920     } elsif (@a == 1) {
2921         return $a[0];
2922     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
2923         # collapse (-1,0,1,2) into (-1..2)
2924         my ($s, $e) = @a[0,-1];
2925         my $i = $s;
2926         return $self->maybe_parens("$s..$e", $cx, 9)
2927           unless grep $i++ != $_, @a;
2928     }
2929     return $self->maybe_parens(join(", ", @a), $cx, 6);
2930 }
2931
2932 sub pp_rv2av {
2933     my $self = shift;
2934     my($op, $cx) = @_;
2935     my $kid = $op->first;
2936     if ($kid->name eq "const") { # constant list
2937         my $av = $self->const_sv($kid);
2938         return $self->list_const($cx, $av->ARRAY);
2939     } else {
2940         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2941     }
2942  }
2943
2944 sub is_subscriptable {
2945     my $op = shift;
2946     if ($op->name =~ /^[ahg]elem/) {
2947         return 1;
2948     } elsif ($op->name eq "entersub") {
2949         my $kid = $op->first;
2950         return 0 unless null $kid->sibling;
2951         $kid = $kid->first;
2952         $kid = $kid->sibling until null $kid->sibling;
2953         return 0 if is_scope($kid);
2954         $kid = $kid->first;
2955         return 0 if $kid->name eq "gv";
2956         return 0 if is_scalar($kid);
2957         return is_subscriptable($kid);  
2958     } else {
2959         return 0;
2960     }
2961 }
2962
2963 sub elem_or_slice_array_name
2964 {
2965     my $self = shift;
2966     my ($array, $left, $padname, $allow_arrow) = @_;
2967
2968     if ($array->name eq $padname) {
2969         return $self->padany($array);
2970     } elsif (is_scope($array)) { # ${expr}[0]
2971         return "{" . $self->deparse($array, 0) . "}";
2972     } elsif ($array->name eq "gv") {
2973         $array = $self->gv_name($self->gv_or_padgv($array));
2974         if ($array !~ /::/) {
2975             my $prefix = ($left eq '[' ? '@' : '%');
2976             $array = $self->{curstash}.'::'.$array
2977                 if $self->lex_in_scope($prefix . $array);
2978         }
2979         return $array;
2980     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
2981         return $self->deparse($array, 24);
2982     } else {
2983         return undef;
2984     }
2985 }
2986
2987 sub elem_or_slice_single_index
2988 {
2989     my $self = shift;
2990     my ($idx) = @_;
2991
2992     $idx = $self->deparse($idx, 1);
2993
2994     # Outer parens in an array index will confuse perl
2995     # if we're interpolating in a regular expression, i.e.
2996     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
2997     #
2998     # If $self->{parens}, then an initial '(' will
2999     # definitely be paired with a final ')'. If
3000     # !$self->{parens}, the misleading parens won't
3001     # have been added in the first place.
3002     #
3003     # [You might think that we could get "(...)...(...)"
3004     # where the initial and final parens do not match
3005     # each other. But we can't, because the above would
3006     # only happen if there's an infix binop between the
3007     # two pairs of parens, and *that* means that the whole
3008     # expression would be parenthesized as well.]
3009     #
3010     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3011
3012     # Hash-element braces will autoquote a bareword inside themselves.
3013     # We need to make sure that C<$hash{warn()}> doesn't come out as
3014     # C<$hash{warn}>, which has a quite different meaning. Currently
3015     # B::Deparse will always quote strings, even if the string was a
3016     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3017     # for constant strings.) So we can cheat slightly here - if we see
3018     # a bareword, we know that it is supposed to be a function call.
3019     #
3020     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3021
3022     return $idx;
3023 }
3024
3025 sub elem {
3026     my $self = shift;
3027     my ($op, $cx, $left, $right, $padname) = @_;
3028     my($array, $idx) = ($op->first, $op->first->sibling);
3029
3030     $idx = $self->elem_or_slice_single_index($idx);
3031
3032     unless ($array->name eq $padname) { # Maybe this has been fixed     
3033         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3034     }
3035     if (my $array_name=$self->elem_or_slice_array_name
3036             ($array, $left, $padname, 1)) {
3037         return "\$" . $array_name . $left . $idx . $right;
3038     } else {
3039         # $x[20][3]{hi} or expr->[20]
3040         my $arrow = is_subscriptable($array) ? "" : "->";
3041         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3042     }
3043
3044 }
3045
3046 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3047 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3048
3049 sub pp_gelem {
3050     my $self = shift;
3051     my($op, $cx) = @_;
3052     my($glob, $part) = ($op->first, $op->last);
3053     $glob = $glob->first; # skip rv2gv
3054     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3055     my $scope = is_scope($glob);
3056     $glob = $self->deparse($glob, 0);
3057     $part = $self->deparse($part, 1);
3058     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3059 }
3060
3061 sub slice {
3062     my $self = shift;
3063     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3064     my $last;
3065     my(@elems, $kid, $array, $list);
3066     if (class($op) eq "LISTOP") {
3067         $last = $op->last;
3068     } else { # ex-hslice inside delete()
3069         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3070         $last = $kid;
3071     }
3072     $array = $last;
3073     $array = $array->first
3074         if $array->name eq $regname or $array->name eq "null";
3075     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3076     $kid = $op->first->sibling; # skip pushmark
3077     if ($kid->name eq "list") {
3078         $kid = $kid->first->sibling; # skip list, pushmark
3079         for (; !null $kid; $kid = $kid->sibling) {
3080             push @elems, $self->deparse($kid, 6);
3081         }
3082         $list = join(", ", @elems);
3083     } else {
3084         $list = $self->elem_or_slice_single_index($kid);
3085     }
3086     return "\@" . $array . $left . $list . $right;
3087 }
3088
3089 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3090 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3091
3092 sub pp_lslice {
3093     my $self = shift;
3094     my($op, $cx) = @_;
3095     my $idx = $op->first;
3096     my $list = $op->last;
3097     my(@elems, $kid);
3098     $list = $self->deparse($list, 1);
3099     $idx = $self->deparse($idx, 1);
3100     return "($list)" . "[$idx]";
3101 }
3102
3103 sub want_scalar {
3104     my $op = shift;
3105     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3106 }
3107
3108 sub want_list {
3109     my $op = shift;
3110     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3111 }
3112
3113 sub _method {
3114     my $self = shift;
3115     my($op, $cx) = @_;
3116     my $kid = $op->first->sibling; # skip pushmark
3117     my($meth, $obj, @exprs);
3118     if ($kid->name eq "list" and want_list $kid) {
3119         # When an indirect object isn't a bareword but the args are in
3120         # parens, the parens aren't part of the method syntax (the LLAFR
3121         # doesn't apply), but they make a list with OPf_PARENS set that
3122         # doesn't get flattened by the append_elem that adds the method,
3123         # making a (object, arg1, arg2, ...) list where the object
3124         # usually is. This can be distinguished from
3125         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3126         # object) because in the later the list is in scalar context
3127         # as the left side of -> always is, while in the former
3128         # the list is in list context as method arguments always are.
3129         # (Good thing there aren't method prototypes!)
3130         $meth = $kid->sibling;
3131         $kid = $kid->first->sibling; # skip pushmark
3132         $obj = $kid;
3133         $kid = $kid->sibling;
3134         for (; not null $kid; $kid = $kid->sibling) {
3135             push @exprs, $kid;
3136         }
3137     } else {
3138         $obj = $kid;
3139         $kid = $kid->sibling;
3140         for (; !null ($kid->sibling) && $kid->name ne "method_named";
3141               $kid = $kid->sibling) {
3142             push @exprs, $kid
3143         }
3144         $meth = $kid;
3145     }
3146
3147     if ($meth->name eq "method_named") {
3148         $meth = $self->const_sv($meth)->PV;
3149     } else {
3150         $meth = $meth->first;
3151         if ($meth->name eq "const") {
3152             # As of 5.005_58, this case is probably obsoleted by the
3153             # method_named case above
3154             $meth = $self->const_sv($meth)->PV; # needs to be bare
3155         }
3156     }
3157
3158     return { method => $meth, variable_method => ref($meth),
3159              object => $obj, args => \@exprs  };
3160 }
3161
3162 # compat function only
3163 sub method {
3164     my $self = shift;
3165     my $info = $self->_method(@_);
3166     return $self->e_method( $self->_method(@_) );
3167 }
3168
3169 sub e_method {
3170     my ($self, $info) = @_;
3171     my $obj = $self->deparse($info->{object}, 24);
3172
3173     my $meth = $info->{method};
3174     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3175     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3176     my $kid = $obj . "->" . $meth;
3177     if (length $args) {
3178         return $kid . "(" . $args . ")"; # parens mandatory
3179     } else {
3180         return $kid;
3181     }
3182 }
3183
3184 # returns "&" if the prototype doesn't match the args,
3185 # or ("", $args_after_prototype_demunging) if it does.
3186 sub check_proto {
3187     my $self = shift;
3188     return "&" if $self->{'noproto'};
3189     my($proto, @args) = @_;
3190     my($arg, $real);
3191     my $doneok = 0;
3192     my @reals;
3193     # An unbackslashed @ or % gobbles up the rest of the args
3194     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3195     while ($proto) {
3196         $proto =~ s/^(\\?[\$\@&%*]|\\\[[\$\@&%*]+\]|;)//;
3197         my $chr = $1;
3198         if ($chr eq "") {
3199             return "&" if @args;
3200         } elsif ($chr eq ";") {
3201             $doneok = 1;
3202         } elsif ($chr eq "@" or $chr eq "%") {
3203             push @reals, map($self->deparse($_, 6), @args);
3204             @args = ();
3205         } else {
3206             $arg = shift @args;
3207             last unless $arg;
3208             if ($chr eq "\$") {
3209                 if (want_scalar $arg) {
3210                     push @reals, $self->deparse($arg, 6);
3211                 } else {
3212                     return "&";
3213                 }
3214             } elsif ($chr eq "&") {
3215                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3216                     push @reals, $self->deparse($arg, 6);
3217                 } else {
3218                     return "&";
3219                 }
3220             } elsif ($chr eq "*") {
3221                 if ($arg->name =~ /^s?refgen$/
3222                     and $arg->first->first->name eq "rv2gv")
3223                   {
3224                       $real = $arg->first->first; # skip refgen, null
3225                       if ($real->first->name eq "gv") {
3226                           push @reals, $self->deparse($real, 6);
3227                       } else {
3228                           push @reals, $self->deparse($real->first, 6);
3229                       }
3230                   } else {
3231                       return "&";
3232                   }
3233             } elsif (substr($chr, 0, 1) eq "\\") {
3234                 $chr =~ tr/\\[]//d;
3235                 if ($arg->name =~ /^s?refgen$/ and
3236                     !null($real = $arg->first) and
3237                     ($chr =~ /\$/ && is_scalar($real->first)
3238                      or ($chr =~ /@/
3239                          && class($real->first->sibling) ne 'NULL'
3240                          && $real->first->sibling->name
3241                          =~ /^(rv2|pad)av$/)
3242                      or ($chr =~ /%/
3243                          && class($real->first->sibling) ne 'NULL'
3244                          && $real->first->sibling->name
3245                          =~ /^(rv2|pad)hv$/)
3246                      #or ($chr =~ /&/ # This doesn't work
3247                      #   && $real->first->name eq "rv2cv")
3248                      or ($chr =~ /\*/
3249                          && $real->first->name eq "rv2gv")))
3250                   {
3251                       push @reals, $self->deparse($real, 6);
3252                   } else {
3253                       return "&";
3254                   }
3255             }
3256        }
3257     }
3258     return "&" if $proto and !$doneok; # too few args and no `;'
3259     return "&" if @args;               # too many args
3260     return ("", join ", ", @reals);
3261 }
3262
3263 sub pp_entersub {
3264     my $self = shift;
3265     my($op, $cx) = @_;
3266     return $self->e_method($self->_method($op, $cx))
3267         unless null $op->first->sibling;
3268     my $prefix = "";
3269     my $amper = "";
3270     my($kid, @exprs);
3271     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3272         $prefix = "do ";
3273     } elsif ($op->private & OPpENTERSUB_AMPER) {
3274         $amper = "&";
3275     }
3276     $kid = $op->first;
3277     $kid = $kid->first->sibling; # skip ex-list, pushmark
3278     for (; not null $kid->sibling; $kid = $kid->sibling) {
3279         push @exprs, $kid;
3280     }
3281     my $simple = 0;
3282     my $proto = undef;
3283     if (is_scope($kid)) {
3284         $amper = "&";
3285         $kid = "{" . $self->deparse($kid, 0) . "}";
3286     } elsif ($kid->first->name eq "gv") {
3287         my $gv = $self->gv_or_padgv($kid->first);
3288         if (class($gv->CV) ne "SPECIAL") {
3289             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3290         }
3291         $simple = 1; # only calls of named functions can be prototyped
3292         $kid = $self->deparse($kid, 24);
3293         if (!$amper) {
3294             if ($kid eq 'main::') {
3295                 $kid = '::';
3296             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3297                 $kid = single_delim("q", "'", $kid) . '->';
3298             }
3299         }
3300     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3301         $amper = "&";
3302         $kid = $self->deparse($kid, 24);
3303     } else {
3304         $prefix = "";
3305         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3306         $kid = $self->deparse($kid, 24) . $arrow;
3307     }
3308
3309     # Doesn't matter how many prototypes there are, if
3310     # they haven't happened yet!
3311     my $declared;
3312     {
3313         no strict 'refs';
3314         no warnings 'uninitialized';
3315         $declared = exists $self->{'subs_declared'}{$kid}
3316             || (
3317                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3318                  && !exists
3319                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3320                  && defined prototype $self->{'curstash'}."::".$kid
3321                );
3322         if (!$declared && defined($proto)) {
3323             # Avoid "too early to check prototype" warning
3324             ($amper, $proto) = ('&');
3325         }
3326     }
3327
3328     my $args;
3329     if ($declared and defined $proto and not $amper) {
3330         ($amper, $args) = $self->check_proto($proto, @exprs);
3331         if ($amper eq "&") {
3332             $args = join(", ", map($self->deparse($_, 6), @exprs));
3333         }
3334     } else {
3335         $args = join(", ", map($self->deparse($_, 6), @exprs));
3336     }
3337     if ($prefix or $amper) {
3338         if ($op->flags & OPf_STACKED) {
3339             return $prefix . $amper . $kid . "(" . $args . ")";
3340         } else {
3341             return $prefix . $amper. $kid;
3342         }
3343     } else {
3344         # glob() invocations can be translated into calls of
3345         # CORE::GLOBAL::glob with a second parameter, a number.
3346         # Reverse this.
3347         if ($kid eq "CORE::GLOBAL::glob") {
3348             $kid = "glob";
3349             $args =~ s/\s*,[^,]+$//;
3350         }
3351
3352         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
3353         # so it must have been translated from a keyword call. Translate
3354         # it back.
3355         $kid =~ s/^CORE::GLOBAL:://;
3356
3357         my $dproto = defined($proto) ? $proto : "undefined";
3358         if (!$declared) {
3359             return "$kid(" . $args . ")";
3360         } elsif ($dproto eq "") {
3361             return $kid;
3362         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3363             # is_scalar is an excessively conservative test here:
3364             # really, we should be comparing to the precedence of the
3365             # top operator of $exprs[0] (ala unop()), but that would
3366             # take some major code restructuring to do right.
3367             return $self->maybe_parens_func($kid, $args, $cx, 16);
3368         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3369             return $self->maybe_parens_func($kid, $args, $cx, 5);
3370         } else {
3371             return "$kid(" . $args . ")";
3372         }
3373     }
3374 }
3375
3376 sub pp_enterwrite { unop(@_, "write") }
3377
3378 # escape things that cause interpolation in double quotes,
3379 # but not character escapes
3380 sub uninterp {
3381     my($str) = @_;
3382     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3383     return $str;
3384 }
3385
3386 {
3387 my $bal;
3388 BEGIN {
3389     use re "eval";
3390     # Matches any string which is balanced with respect to {braces}
3391     $bal = qr(
3392       (?:
3393         [^\\{}]
3394       | \\\\
3395       | \\[{}]
3396       | \{(??{$bal})\}
3397       )*
3398     )x;
3399 }
3400
3401 # the same, but treat $|, $), $( and $ at the end of the string differently
3402 sub re_uninterp {
3403     my($str) = @_;
3404
3405     $str =~ s/
3406           ( ^|\G                  # $1
3407           | [^\\]
3408           )
3409
3410           (                       # $2
3411             (?:\\\\)*
3412           )
3413
3414           (                       # $3
3415             (\(\?\??\{$bal\}\))   # $4
3416           | [\$\@]
3417             (?!\||\)|\(|$)
3418           | \\[uUlLQE]
3419           )
3420
3421         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3422
3423     return $str;
3424 }
3425
3426 # This is for regular expressions with the /x modifier
3427 # We have to leave comments unmangled.
3428 sub re_uninterp_extended {
3429     my($str) = @_;
3430
3431     $str =~ s/
3432           ( ^|\G                  # $1
3433           | [^\\]
3434           )
3435
3436           (                       # $2
3437             (?:\\\\)*
3438           )
3439
3440           (                       # $3
3441             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3442             | \#[^\n]*            #     (skip over comments)
3443             )
3444           | [\$\@]
3445             (?!\||\)|\(|$|\s)
3446           | \\[uUlLQE]
3447           )
3448
3449         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3450
3451     return $str;
3452 }
3453 }
3454
3455 my %unctrl = # portable to to EBCDIC
3456     (
3457      "\c@" => '\c@',    # unused
3458      "\cA" => '\cA',
3459      "\cB" => '\cB',
3460      "\cC" => '\cC',
3461      "\cD" => '\cD',
3462      "\cE" => '\cE',
3463      "\cF" => '\cF',
3464      "\cG" => '\cG',
3465      "\cH" => '\cH',
3466      "\cI" => '\cI',
3467      "\cJ" => '\cJ',
3468      "\cK" => '\cK',
3469      "\cL" => '\cL',
3470      "\cM" => '\cM',
3471      "\cN" => '\cN',
3472      "\cO" => '\cO',
3473      "\cP" => '\cP',
3474      "\cQ" => '\cQ',
3475      "\cR" => '\cR',
3476      "\cS" => '\cS',
3477      "\cT" => '\cT',
3478      "\cU" => '\cU',
3479      "\cV" => '\cV',
3480      "\cW" => '\cW',
3481      "\cX" => '\cX',
3482      "\cY" => '\cY',
3483      "\cZ" => '\cZ',
3484      "\c[" => '\c[',    # unused
3485      "\c\\" => '\c\\',  # unused
3486      "\c]" => '\c]',    # unused
3487      "\c_" => '\c_',    # unused
3488     );
3489
3490 # character escapes, but not delimiters that might need to be escaped
3491 sub escape_str { # ASCII, UTF8
3492     my($str) = @_;
3493     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3494     $str =~ s/\a/\\a/g;
3495 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3496     $str =~ s/\t/\\t/g;
3497     $str =~ s/\n/\\n/g;
3498     $str =~ s/\e/\\e/g;
3499     $str =~ s/\f/\\f/g;
3500     $str =~ s/\r/\\r/g;
3501     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3502     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3503     return $str;
3504 }
3505
3506 # For regexes with the /x modifier.
3507 # Leave whitespace unmangled.
3508 sub escape_extended_re {
3509     my($str) = @_;
3510     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3511     $str =~ s/([[:^print:]])/
3512         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3513     $str =~ s/\n/\n\f/g;
3514     return $str;
3515 }
3516
3517 # Don't do this for regexen
3518 sub unback {
3519     my($str) = @_;
3520     $str =~ s/\\/\\\\/g;
3521     return $str;
3522 }
3523
3524 # Remove backslashes which precede literal control characters,
3525 # to avoid creating ambiguity when we escape the latter.
3526 sub re_unback {
3527     my($str) = @_;
3528
3529     # the insane complexity here is due to the behaviour of "\c\"
3530     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3531     return $str;
3532 }
3533
3534 sub balanced_delim {
3535     my($str) = @_;
3536     my @str = split //, $str;
3537     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3538     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3539         ($open, $close) = @$ar;
3540         $fail = 0; $cnt = 0; $last_bs = 0;
3541         for $c (@str) {
3542             if ($c eq $open) {
3543                 $fail = 1 if $last_bs;
3544                 $cnt++;
3545             } elsif ($c eq $close) {
3546                 $fail = 1 if $last_bs;
3547                 $cnt--;
3548                 if ($cnt < 0) {
3549                     # qq()() isn't ")("
3550                     $fail = 1;
3551                     last;
3552                 }
3553             }
3554             $last_bs = $c eq '\\';
3555         }
3556         $fail = 1 if $cnt != 0;
3557         return ($open, "$open$str$close") if not $fail;
3558     }
3559     return ("", $str);
3560 }
3561
3562 sub single_delim {
3563     my($q, $default, $str) = @_;
3564     return "$default$str$default" if $default and index($str, $default) == -1;
3565     if ($q ne 'qr') {
3566         (my $succeed, $str) = balanced_delim($str);
3567         return "$q$str" if $succeed;
3568     }
3569     for my $delim ('/', '"', '#') {
3570         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3571     }
3572     if ($default) {
3573         $str =~ s/$default/\\$default/g;
3574         return "$default$str$default";
3575     } else {
3576         $str =~ s[/][\\/]g;
3577         return "$q/$str/";
3578     }
3579 }
3580
3581 my $max_prec;
3582 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3583
3584 # Split a floating point number into an integer mantissa and a binary
3585 # exponent. Assumes you've already made sure the number isn't zero or
3586 # some weird infinity or NaN.
3587 sub split_float {
3588     my($f) = @_;
3589     my $exponent = 0;
3590     if ($f == int($f)) {
3591         while ($f % 2 == 0) {
3592             $f /= 2;
3593             $exponent++;
3594         }
3595     } else {
3596         while ($f != int($f)) {
3597             $f *= 2;
3598             $exponent--;
3599         }
3600     }
3601     my $mantissa = sprintf("%.0f", $f);
3602     return ($mantissa, $exponent);
3603 }
3604
3605 sub const {
3606     my $self = shift;
3607     my($sv, $cx) = @_;
3608     if ($self->{'use_dumper'}) {
3609         return $self->const_dumper($sv, $cx);
3610     }
3611     if (class($sv) eq "SPECIAL") {
3612         # sv_undef, sv_yes, sv_no
3613         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3614     } elsif (class($sv) eq "NULL") {
3615        return 'undef';
3616     }
3617     # convert a version object into the "v1.2.3" string in its V magic
3618     if ($sv->FLAGS & SVs_RMG) {
3619         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3620             return $mg->PTR if $mg->TYPE eq 'V';
3621         }
3622     }
3623
3624     if ($sv->FLAGS & SVf_IOK) {
3625         my $str = $sv->int_value;
3626         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3627         return $str;
3628     } elsif ($sv->FLAGS & SVf_NOK) {
3629         my $nv = $sv->NV;
3630         if ($nv == 0) {
3631             if (pack("F", $nv) eq pack("F", 0)) {
3632                 # positive zero
3633                 return "0";
3634             } else {
3635                 # negative zero
3636                 return $self->maybe_parens("-.0", $cx, 21);
3637             }
3638         } elsif (1/$nv == 0) {
3639             if ($nv > 0) {
3640                 # positive infinity
3641                 return $self->maybe_parens("9**9**9", $cx, 22);
3642             } else {
3643                 # negative infinity
3644                 return $self->maybe_parens("-9**9**9", $cx, 21);
3645             }
3646         } elsif ($nv != $nv) {
3647             # NaN
3648             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3649                 # the normal kind
3650                 return "sin(9**9**9)";
3651             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3652                 # the inverted kind
3653                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3654             } else {
3655                 # some other kind
3656                 my $hex = unpack("h*", pack("F", $nv));
3657                 return qq'unpack("F", pack("h*", "$hex"))';
3658             }
3659         }
3660         # first, try the default stringification
3661         my $str = "$nv";
3662         if ($str != $nv) {
3663             # failing that, try using more precision
3664             $str = sprintf("%.${max_prec}g", $nv);
3665 #           if (pack("F", $str) ne pack("F", $nv)) {
3666             if ($str != $nv) {
3667                 # not representable in decimal with whatever sprintf()
3668                 # and atof() Perl is using here.
3669                 my($mant, $exp) = split_float($nv);
3670                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3671             }
3672         }
3673         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3674         return $str;
3675     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3676         my $ref = $sv->RV;
3677         if (class($ref) eq "AV") {
3678             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3679         } elsif (class($ref) eq "HV") {
3680             my %hash = $ref->ARRAY;
3681             my @elts;
3682             for my $k (sort keys %hash) {
3683                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3684             }
3685             return "{" . join(", ", @elts) . "}";
3686         } elsif (class($ref) eq "CV") {
3687             return "sub " . $self->deparse_sub($ref);
3688         }
3689         if ($ref->FLAGS & SVs_SMG) {
3690             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3691                 if ($mg->TYPE eq 'r') {
3692                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3693                     return single_delim("qr", "", $re);
3694                 }
3695             }
3696         }
3697         
3698         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3699     } elsif ($sv->FLAGS & SVf_POK) {
3700         my $str = $sv->PV;
3701         if ($str =~ /[[:^print:]]/) {
3702             return single_delim("qq", '"', uninterp escape_str unback $str);
3703         } else {
3704             return single_delim("q", "'", unback $str);
3705         }
3706     } else {
3707         return "undef";
3708     }
3709 }
3710
3711 sub const_dumper {
3712     my $self = shift;
3713     my($sv, $cx) = @_;
3714     my $ref = $sv->object_2svref();
3715     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3716     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3717     my $str = $dumper->Dump();
3718     if ($str =~ /^\$v/) {
3719         return '${my ' . $str . ' \$v}';
3720     } else {
3721         return $str;
3722     }
3723 }
3724
3725 sub const_sv {
3726     my $self = shift;
3727     my $op = shift;
3728     my $sv = $op->sv;
3729     # the constant could be in the pad (under useithreads)
3730     $sv = $self->padval($op->targ) unless $$sv;
3731     return $sv;
3732 }
3733
3734 sub pp_const {
3735     my $self = shift;
3736     my($op, $cx) = @_;
3737     if ($op->private & OPpCONST_ARYBASE) {
3738         return '$[';
3739     }
3740 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3741 #       return $self->const_sv($op)->PV;
3742 #    }
3743     my $sv = $self->const_sv($op);
3744     return $self->const($sv, $cx);
3745 }
3746
3747 sub dq {
3748     my $self = shift;
3749     my $op = shift;
3750     my $type = $op->name;
3751     if ($type eq "const") {
3752         return '$[' if $op->private & OPpCONST_ARYBASE;
3753         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3754     } elsif ($type eq "concat") {
3755         my $first = $self->dq($op->first);
3756         my $last  = $self->dq($op->last);
3757
3758         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3759         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3760             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3761             || ($last =~ /^[:'{\[\w_]/ && #'
3762                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3763
3764         return $first . $last;
3765     } elsif ($type eq "uc") {
3766         return '\U' . $self->dq($op->first->sibling) . '\E';
3767     } elsif ($type eq "lc") {
3768         return '\L' . $self->dq($op->first->sibling) . '\E';
3769     } elsif ($type eq "ucfirst") {
3770         return '\u' . $self->dq($op->first->sibling);
3771     } elsif ($type eq "lcfirst") {
3772         return '\l' . $self->dq($op->first->sibling);
3773     } elsif ($type eq "quotemeta") {
3774         return '\Q' . $self->dq($op->first->sibling) . '\E';
3775     } elsif ($type eq "join") {
3776         return $self->deparse($op->last, 26); # was join($", @ary)
3777     } else {
3778         return $self->deparse($op, 26);
3779     }
3780 }
3781
3782 sub pp_backtick {
3783     my $self = shift;
3784     my($op, $cx) = @_;
3785     # skip pushmark if it exists (readpipe() vs ``)
3786     my $child = $op->first->sibling->isa('B::NULL')
3787         ? $op->first->first : $op->first->sibling;
3788     return single_delim("qx", '`', $self->dq($child));
3789 }
3790
3791 sub dquote {
3792     my $self = shift;
3793     my($op, $cx) = @_;
3794     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3795     return $self->deparse($kid, $cx) if $self->{'unquote'};
3796     $self->maybe_targmy($kid, $cx,
3797                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3798 }
3799
3800 # OP_STRINGIFY is a listop, but it only ever has one arg
3801 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3802
3803 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3804 # note that tr(from)/to/ is OK, but not tr/from/(to)
3805 sub double_delim {
3806     my($from, $to) = @_;
3807     my($succeed, $delim);
3808     if ($from !~ m[/] and $to !~ m[/]) {
3809         return "/$from/$to/";
3810     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3811         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3812             return "$from$to";
3813         } else {
3814             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3815                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3816             }
3817             $to =~ s[/][\\/]g;
3818             return "$from/$to/";
3819         }
3820     } else {
3821         for $delim ('/', '"', '#') { # note no '
3822             return "$delim$from$delim$to$delim"
3823                 if index($to . $from, $delim) == -1;
3824         }
3825         $from =~ s[/][\\/]g;
3826         $to =~ s[/][\\/]g;
3827         return "/$from/$to/";   
3828     }
3829 }
3830
3831 # Only used by tr///, so backslashes hyphens
3832 sub pchr { # ASCII
3833     my($n) = @_;
3834     if ($n == ord '\\') {
3835         return '\\\\';
3836     } elsif ($n == ord "-") {
3837         return "\\-";
3838     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3839         return chr($n);
3840     } elsif ($n == ord "\a") {
3841         return '\\a';
3842     } elsif ($n == ord "\b") {
3843         return '\\b';
3844     } elsif ($n == ord "\t") {
3845         return '\\t';
3846     } elsif ($n == ord "\n") {
3847         return '\\n';
3848     } elsif ($n == ord "\e") {
3849         return '\\e';
3850     } elsif ($n == ord "\f") {
3851         return '\\f';
3852     } elsif ($n == ord "\r") {
3853         return '\\r';
3854     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3855         return '\\c' . chr(ord("@") + $n);
3856     } else {
3857 #       return '\x' . sprintf("%02x", $n);
3858         return '\\' . sprintf("%03o", $n);
3859     }
3860 }
3861
3862 sub collapse {
3863     my(@chars) = @_;
3864     my($str, $c, $tr) = ("");
3865     for ($c = 0; $c < @chars; $c++) {
3866         $tr = $chars[$c];
3867         $str .= pchr($tr);
3868         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3869             $chars[$c + 2] == $tr + 2)
3870         {
3871             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3872               {}
3873             $str .= "-";
3874             $str .= pchr($chars[$c]);
3875         }
3876     }
3877     return $str;
3878 }
3879
3880 sub tr_decode_byte {
3881     my($table, $flags) = @_;
3882     my(@table) = unpack("s*", $table);
3883     splice @table, 0x100, 1;   # Number of subsequent elements
3884     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3885     if ($table[ord "-"] != -1 and
3886         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3887     {
3888         $tr = $table[ord "-"];
3889         $table[ord "-"] = -1;
3890         if ($tr >= 0) {
3891             @from = ord("-");
3892             @to = $tr;
3893         } else { # -2 ==> delete
3894             $delhyphen = 1;
3895         }
3896     }
3897     for ($c = 0; $c < @table; $c++) {
3898         $tr = $table[$c];
3899         if ($tr >= 0) {
3900             push @from, $c; push @to, $tr;
3901         } elsif ($tr == -2) {
3902             push @delfrom, $c;
3903         }
3904     }
3905     @from = (@from, @delfrom);
3906     if ($flags & OPpTRANS_COMPLEMENT) {
3907         my @newfrom = ();
3908         my %from;
3909         @from{@from} = (1) x @from;
3910         for ($c = 0; $c < 256; $c++) {
3911             push @newfrom, $c unless $from{$c};
3912         }
3913         @from = @newfrom;
3914     }
3915     unless ($flags & OPpTRANS_DELETE || !@to) {
3916         pop @to while $#to and $to[$#to] == $to[$#to -1];
3917     }
3918     my($from, $to);
3919     $from = collapse(@from);
3920     $to = collapse(@to);
3921     $from .= "-" if $delhyphen;
3922     return ($from, $to);
3923 }
3924
3925 sub tr_chr {
3926     my $x = shift;
3927     if ($x == ord "-") {
3928         return "\\-";
3929     } elsif ($x == ord "\\") {
3930         return "\\\\";
3931     } else {
3932         return chr $x;
3933     }
3934 }
3935
3936 # XXX This doesn't yet handle all cases correctly either
3937
3938 sub tr_decode_utf8 {
3939     my($swash_hv, $flags) = @_;
3940     my %swash = $swash_hv->ARRAY;
3941     my $final = undef;
3942     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3943     my $none = $swash{"NONE"}->IV;
3944     my $extra = $none + 1;
3945     my(@from, @delfrom, @to);
3946     my $line;
3947     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3948         my($min, $max, $result) = split(/\t/, $line);
3949         $min = hex $min;
3950         if (length $max) {
3951             $max = hex $max;
3952         } else {
3953             $max = $min;
3954         }
3955         $result = hex $result;
3956         if ($result == $extra) {
3957             push @delfrom, [$min, $max];
3958         } else {
3959             push @from, [$min, $max];
3960             push @to, [$result, $result + $max - $min];
3961         }
3962     }
3963     for my $i (0 .. $#from) {
3964         if ($from[$i][0] == ord '-') {
3965             unshift @from, splice(@from, $i, 1);
3966             unshift @to, splice(@to, $i, 1);
3967             last;
3968         } elsif ($from[$i][1] == ord '-') {
3969             $from[$i][1]--;
3970             $to[$i][1]--;
3971             unshift @from, ord '-';
3972             unshift @to, ord '-';
3973             last;
3974         }
3975     }
3976     for my $i (0 .. $#delfrom) {
3977         if ($delfrom[$i][0] == ord '-') {
3978             push @delfrom, splice(@delfrom, $i, 1);
3979             last;
3980         } elsif ($delfrom[$i][1] == ord '-') {
3981             $delfrom[$i][1]--;
3982             push @delfrom, ord '-';
3983             last;
3984         }
3985     }
3986     if (defined $final and $to[$#to][1] != $final) {
3987         push @to, [$final, $final];
3988     }
3989     push @from, @delfrom;
3990     if ($flags & OPpTRANS_COMPLEMENT) {
3991         my @newfrom;
3992         my $next = 0;
3993         for my $i (0 .. $#from) {
3994             push @newfrom, [$next, $from[$i][0] - 1];
3995             $next = $from[$i][1] + 1;
3996         }
3997         @from = ();
3998         for my $range (@newfrom) {
3999             if ($range->[0] <= $range->[1]) {
4000                 push @from, $range;
4001             }
4002         }
4003     }
4004     my($from, $to, $diff);
4005     for my $chunk (@from) {
4006         $diff = $chunk->[1] - $chunk->[0];
4007         if ($diff > 1) {
4008             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4009         } elsif ($diff == 1) {
4010             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4011         } else {
4012             $from .= tr_chr($chunk->[0]);
4013         }
4014     }
4015     for my $chunk (@to) {
4016         $diff = $chunk->[1] - $chunk->[0];
4017         if ($diff > 1) {
4018             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4019         } elsif ($diff == 1) {
4020             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4021         } else {
4022             $to .= tr_chr($chunk->[0]);
4023         }
4024     }
4025     #$final = sprintf("%04x", $final) if defined $final;
4026     #$none = sprintf("%04x", $none) if defined $none;
4027     #$extra = sprintf("%04x", $extra) if defined $extra;
4028     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4029     #print STDERR $swash{'LIST'}->PV;
4030     return (escape_str($from), escape_str($to));
4031 }
4032
4033 sub pp_trans {
4034     my $self = shift;
4035     my($op, $cx) = @_;
4036     my($from, $to);
4037     if (class($op) eq "PVOP") {
4038         ($from, $to) = tr_decode_byte($op->pv, $op->private);
4039     } else { # class($op) eq "SVOP"
4040         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
4041     }
4042     my $flags = "";
4043     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
4044     $flags .= "d" if $op->private & OPpTRANS_DELETE;
4045     $to = "" if $from eq $to and $flags eq "";
4046     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
4047     return "tr" . double_delim($from, $to) . $flags;
4048 }
4049
4050 # Like dq(), but different
4051 sub re_dq {
4052     my $self = shift;
4053     my ($op, $extended) = @_;
4054
4055     my $type = $op->name;
4056     if ($type eq "const") {
4057         return '$[' if $op->private & OPpCONST_ARYBASE;
4058         my $unbacked = re_unback($self->const_sv($op)->as_string);
4059         return re_uninterp_extended(escape_extended_re($unbacked))
4060             if $extended;
4061         return re_uninterp(escape_str($unbacked));
4062     } elsif ($type eq "concat") {
4063         my $first = $self->re_dq($op->first, $extended);
4064         my $last  = $self->re_dq($op->last,  $extended);
4065
4066         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4067         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4068             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4069             || ($last =~ /^[{\[\w_]/ &&
4070                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4071
4072         return $first . $last;
4073     } elsif ($type eq "uc") {
4074         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4075     } elsif ($type eq "lc") {
4076         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4077     } elsif ($type eq "ucfirst") {
4078         return '\u' . $self->re_dq($op->first->sibling, $extended);
4079     } elsif ($type eq "lcfirst") {
4080         return '\l' . $self->re_dq($op->first->sibling, $extended);
4081     } elsif ($type eq "quotemeta") {
4082         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4083     } elsif ($type eq "join") {
4084         return $self->deparse($op->last, 26); # was join($", @ary)
4085     } else {
4086         return $self->deparse($op, 26);
4087     }
4088 }
4089
4090 sub pure_string {
4091     my ($self, $op) = @_;
4092     return 0 if null $op;
4093     my $type = $op->name;
4094
4095     if ($type eq 'const') {
4096         return 1;
4097     }
4098     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4099         return $self->pure_string($op->first->sibling);
4100     }
4101     elsif ($type eq 'join') {
4102         my $join_op = $op->first->sibling;  # Skip pushmark
4103         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4104
4105         my $gvop = $join_op->first;
4106         return 0 unless $gvop->name eq 'gvsv';
4107         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4108
4109         return 0 unless ${$join_op->sibling} eq ${$op->last};
4110         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4111     }
4112     elsif ($type eq 'concat') {
4113         return $self->pure_string($op->first)
4114             && $self->pure_string($op->last);
4115     }
4116     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4117         return 1;
4118     }
4119     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4120            $op->first->name eq "null" and $op->first->can('first')
4121            and not null $op->first->first and
4122            $op->first->first->name eq "aelemfast") {
4123         return 1;
4124     }
4125     else {
4126         return 0;
4127     }
4128
4129     return 1;
4130 }
4131
4132 sub regcomp {
4133     my $self = shift;
4134     my($op, $cx, $extended) = @_;
4135     my $kid = $op->first;
4136     $kid = $kid->first if $kid->name eq "regcmaybe";
4137     $kid = $kid->first if $kid->name eq "regcreset";
4138     if ($kid->name eq "null" and !null($kid->first)
4139         and $kid->first->name eq 'pushmark')
4140     {
4141         my $str = '';
4142         $kid = $kid->first->sibling;
4143         while (!null($kid)) {
4144             $str .= $self->re_dq($kid, $extended);
4145             $kid = $kid->sibling;
4146         }
4147         return $str, 1;
4148     }
4149
4150     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4151     return ($self->deparse($kid, $cx), 0);
4152 }
4153
4154 sub pp_regcomp {
4155     my ($self, $op, $cx) = @_;
4156     return (($self->regcomp($op, $cx, 0))[0]);
4157 }
4158
4159 # osmic acid -- see osmium tetroxide
4160
4161 my %matchwords;
4162 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4163     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4164     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4165
4166 sub matchop {
4167     my $self = shift;
4168     my($op, $cx, $name, $delim) = @_;
4169     my $kid = $op->first;
4170     my ($binop, $var, $re) = ("", "", "");
4171     if ($op->flags & OPf_STACKED) {
4172         $binop = 1;
4173         $var = $self->deparse($kid, 20);
4174         $kid = $kid->sibling;
4175     }
4176     my $quote = 1;
4177     my $extended = ($op->pmflags & PMf_EXTENDED);
4178     if (null $kid) {
4179         my $unbacked = re_unback($op->precomp);
4180         if ($extended) {
4181             $re = re_uninterp_extended(escape_extended_re($unbacked));
4182         } else {
4183             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4184         }
4185     } elsif ($kid->name ne 'regcomp') {
4186         carp("found ".$kid->name." where regcomp expected");
4187     } else {
4188         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4189     }
4190     my $flags = "";
4191     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4192     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4193     $flags .= "i" if $op->pmflags & PMf_FOLD;
4194     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4195     $flags .= "o" if $op->pmflags & PMf_KEEP;
4196     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4197     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4198     $flags = $matchwords{$flags} if $matchwords{$flags};
4199     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4200         $re =~ s/\?/\\?/g;
4201         $re = "?$re?";
4202     } elsif ($quote) {
4203         $re = single_delim($name, $delim, $re);
4204     }
4205     $re = $re . $flags if $quote;
4206     if ($binop) {
4207         return $self->maybe_parens("$var =~ $re", $cx, 20);
4208     } else {
4209         return $re;
4210     }
4211 }
4212
4213 sub pp_match { matchop(@_, "m", "/") }
4214 sub pp_pushre { matchop(@_, "m", "/") }
4215 sub pp_qr { matchop(@_, "qr", "") }
4216
4217 sub pp_split {
4218     my $self = shift;
4219     my($op, $cx) = @_;
4220     my($kid, @exprs, $ary, $expr);
4221     $kid = $op->first;
4222
4223     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4224     # root of a replacement; it's either empty, or abused to point to
4225     # the GV for an array we split into (an optimization to save
4226     # assignment overhead). Depending on whether we're using ithreads,
4227     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs
4228     # figures out for us which it is.
4229     my $replroot = $kid->pmreplroot;
4230     my $gv = 0;
4231     if (ref($replroot) eq "B::GV") {
4232         $gv = $replroot;
4233     } elsif (!ref($replroot) and $replroot > 0) {
4234         $gv = $self->padval($replroot);
4235     }
4236     $ary = $self->stash_variable('@', $self->gv_name($gv)) if $gv;
4237
4238     for (; !null($kid); $kid = $kid->sibling) {
4239         push @exprs, $self->deparse($kid, 6);
4240     }
4241
4242     # handle special case of split(), and split(' ') that compiles to /\s+/
4243     $kid = $op->first;
4244     if ( $kid->flags & OPf_SPECIAL
4245          and ( $] < 5.009 ? $kid->pmflags & PMf_SKIPWHITE()
4246               : $kid->reflags & RXf_SKIPWHITE() ) ) {
4247         $exprs[0] = "' '";
4248     }
4249
4250     $expr = "split(" . join(", ", @exprs) . ")";
4251     if ($ary) {
4252         return $self->maybe_parens("$ary = $expr", $cx, 7);
4253     } else {
4254         return $expr;
4255     }
4256 }
4257
4258 # oxime -- any of various compounds obtained chiefly by the action of
4259 # hydroxylamine on aldehydes and ketones and characterized by the
4260 # bivalent grouping C=NOH [Webster's Tenth]
4261
4262 my %substwords;
4263 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
4264     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
4265     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
4266     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
4267
4268 sub pp_subst {
4269     my $self = shift;
4270     my($op, $cx) = @_;
4271     my $kid = $op->first;
4272     my($binop, $var, $re, $repl) = ("", "", "", "");
4273     if ($op->flags & OPf_STACKED) {
4274         $binop = 1;
4275         $var = $self->deparse($kid, 20);
4276         $kid = $kid->sibling;
4277     }
4278     my $flags = "";
4279     if (null($op->pmreplroot)) {
4280         $repl = $self->dq($kid);
4281         $kid = $kid->sibling;
4282     } else {
4283         $repl = $op->pmreplroot->first; # skip substcont
4284         while ($repl->name eq "entereval") {
4285             $repl = $repl->first;
4286             $flags .= "e";
4287         }
4288         if ($op->pmflags & PMf_EVAL) {
4289             $repl = $self->deparse($repl->first, 0);
4290         } else {
4291             $repl = $self->dq($repl);   
4292         }
4293     }
4294     my $extended = ($op->pmflags & PMf_EXTENDED);
4295     if (null $kid) {
4296         my $unbacked = re_unback($op->precomp);
4297         if ($extended) {
4298             $re = re_uninterp_extended(escape_extended_re($unbacked));
4299         }
4300         else {
4301             $re = re_uninterp(escape_str($unbacked));
4302         }
4303     } else {
4304         ($re) = $self->regcomp($kid, 1, $extended);
4305     }
4306     $flags .= "e" if $op->pmflags & PMf_EVAL;
4307     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4308     $flags .= "i" if $op->pmflags & PMf_FOLD;
4309     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4310     $flags .= "o" if $op->pmflags & PMf_KEEP;
4311     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4312     $flags .= "x" if $extended;
4313     $flags = $substwords{$flags} if $substwords{$flags};
4314     if ($binop) {
4315         return $self->maybe_parens("$var =~ s"
4316                                    . double_delim($re, $repl) . $flags,
4317                                    $cx, 20);
4318     } else {
4319         return "s". double_delim($re, $repl) . $flags;  
4320     }
4321 }
4322
4323 1;
4324 __END__
4325
4326 =head1 NAME
4327
4328 B::Deparse - Perl compiler backend to produce perl code
4329
4330 =head1 SYNOPSIS
4331
4332 B<perl> B<-MO=Deparse>[B<,-d>][B<,-f>I<FILE>][B<,-p>][B<,-q>][B<,-l>]
4333         [B<,-s>I<LETTERS>][B<,-x>I<LEVEL>] I<prog.pl>
4334
4335 =head1 DESCRIPTION
4336
4337 B::Deparse is a backend module for the Perl compiler that generates
4338 perl source code, based on the internal compiled structure that perl
4339 itself creates after parsing a program. The output of B::Deparse won't
4340 be exactly the same as the original source, since perl doesn't keep
4341 track of comments or whitespace, and there isn't a one-to-one
4342 correspondence between perl's syntactical constructions and their
4343 compiled form, but it will often be close. When you use the B<-p>
4344 option, the output also includes parentheses even when they are not
4345 required by precedence, which can make it easy to see if perl is
4346 parsing your expressions the way you intended.
4347
4348 While B::Deparse goes to some lengths to try to figure out what your
4349 original program was doing, some parts of the language can still trip
4350 it up; it still fails even on some parts of Perl's own test suite. If
4351 you encounter a failure other than the most common ones described in
4352 the BUGS section below, you can help contribute to B::Deparse's
4353 ongoing development by submitting a bug report with a small
4354 example.
4355
4356 =head1 OPTIONS
4357
4358 As with all compiler backend options, these must follow directly after
4359 the '-MO=Deparse', separated by a comma but not any white space.
4360
4361 =over 4
4362
4363 =item B<-d>
4364
4365 Output data values (when they appear as constants) using Data::Dumper.
4366 Without this option, B::Deparse will use some simple routines of its
4367 own for the same purpose. Currently, Data::Dumper is better for some
4368 kinds of data (such as complex structures with sharing and
4369 self-reference) while the built-in routines are better for others
4370 (such as odd floating-point values).
4371
4372 =item B<-f>I<FILE>
4373
4374 Normally, B::Deparse deparses the main code of a program, and all the subs
4375 defined in the same file. To include subs defined in other files, pass the
4376 B<-f> option with the filename. You can pass the B<-f> option several times, to
4377 include more than one secondary file.  (Most of the time you don't want to
4378 use it at all.)  You can also use this option to include subs which are
4379 defined in the scope of a B<#line> directive with two parameters.
4380
4381 =item B<-l>
4382
4383 Add '#line' declarations to the output based on the line and file
4384 locations of the original code.
4385
4386 =item B<-p>
4387
4388 Print extra parentheses. Without this option, B::Deparse includes
4389 parentheses in its output only when they are needed, based on the
4390 structure of your program. With B<-p>, it uses parentheses (almost)
4391 whenever they would be legal. This can be useful if you are used to
4392 LISP, or if you want to see how perl parses your input. If you say
4393
4394     if ($var & 0x7f == 65) {print "Gimme an A!"}
4395     print ($which ? $a : $b), "\n";
4396     $name = $ENV{USER} or "Bob";
4397
4398 C<B::Deparse,-p> will print
4399
4400     if (($var & 0)) {
4401         print('Gimme an A!')
4402     };
4403     (print(($which ? $a : $b)), '???');
4404     (($name = $ENV{'USER'}) or '???')
4405
4406 which probably isn't what you intended (the C<'???'> is a sign that
4407 perl optimized away a constant value).
4408
4409 =item B<-P>
4410
4411 Disable prototype checking. With this option, all function calls are
4412 deparsed as if no prototype was defined for them. In other words,
4413
4414     perl -MO=Deparse,-P -e 'sub foo (\@) { 1 } foo @x'
4415
4416 will print
4417
4418     sub foo (\@) {
4419         1;
4420     }
4421     &foo(\@x);
4422
4423 making clear how the parameters are actually passed to C<foo>.
4424
4425 =item B<-q>
4426
4427 Expand double-quoted strings into the corresponding combinations of
4428 concatenation, uc, ucfirst, lc, lcfirst, quotemeta, and join. For
4429 instance, print
4430
4431     print "Hello, $world, @ladies, \u$gentlemen\E, \u\L$me!";
4432
4433 as
4434
4435     print 'Hello, ' . $world . ', ' . join($", @ladies) . ', '
4436           . ucfirst($gentlemen) . ', ' . ucfirst(lc $me . '!');
4437
4438 Note that the expanded form represents the way perl handles such
4439 constructions internally -- this option actually turns off the reverse
4440 translation that B::Deparse usually does. On the other hand, note that
4441 C<$x = "$y"> is not the same as C<$x = $y>: the former makes the value
4442 of $y into a string before doing the assignment.
4443
4444 =item B<-s>I<LETTERS>
4445
4446 Tweak the style of B::Deparse's output. The letters should follow
4447 directly after the 's', with no space or punctuation. The following
4448 options are available:
4449
4450 =over 4
4451
4452 =item B<C>
4453
4454 Cuddle C<elsif>, C<else>, and C<continue> blocks. For example, print
4455
4456     if (...) {
4457          ...
4458     } else {
4459          ...
4460     }
4461
4462 instead of
4463
4464     if (...) {
4465          ...
4466     }
4467     else {
4468          ...
4469     }
4470
4471 The default is not to cuddle.
4472
4473 =item B<i>I<NUMBER>
4474
4475 Indent lines by multiples of I<NUMBER> columns. The default is 4 columns.
4476
4477 =item B<T>
4478
4479 Use tabs for each 8 columns of indent. The default is to use only spaces.
4480 For instance, if the style options are B<-si4T>, a line that's indented
4481 3 times will be preceded by one tab and four spaces; if the options were
4482 B<-si8T>, the same line would be preceded by three tabs.
4483
4484 =item B<v>I<STRING>B<.>
4485
4486 Print I<STRING> for the value of a constant that can't be determined
4487 because it was optimized away (mnemonic: this happens when a constant
4488 is used in B<v>oid context). The end of the string is marked by a period.
4489 The string should be a valid perl expression, generally a constant.
4490 Note that unless it's a number, it probably needs to be quoted, and on
4491 a command line quotes need to be protected from the shell. Some
4492 conventional values include 0, 1, 42, '', 'foo', and
4493 'Useless use of constant omitted' (which may need to be
4494 B<-sv"'Useless use of constant omitted'.">
4495 or something similar depending on your shell). The default is '???'.
4496 If you're using B::Deparse on a module or other file that's require'd,
4497 you shouldn't use a value that evaluates to false, since the customary
4498 true constant at the end of a module will be in void context when the
4499 file is compiled as a main program.
4500
4501 =back
4502
4503 =item B<-x>I<LEVEL>
4504
4505 Expand conventional syntax constructions into equivalent ones that expose
4506 their internal operation. I<LEVEL> should be a digit, with higher values