This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
aefd4aea13a2f491ce6bbcd2a20dc9cb96a38026
[perl5.git] / configure.com
1 $ sav_ver = 'F$VERIFY(0)'
2 $! SET VERIFY
3 $!
4 $! For example, if you unpacked perl into: [USER.PERL5_00n...] then you will 
5 $! want to cd into the tree and execute Configure:
6 $!
7 $! $ SET DEFAULT [USER.PERL5_xxx]
8 $! $ @Configure 
9 $!
10 $! or
11 $!
12 $! $ SET DEFAULT [USER.PERL5_xxx]
13 $! $ @Configure "-des"
14 $!
15 $! That's it. If you get into a bind trying to build perl on VMS then 
16 $! definitely read through the README.VMS file.
17 $! Beyond that send email to vmsperl@perl.org
18 $!
19 $! ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
20 $!
21 $! send suggestions to: 
22 $!  Dan Sugalski <dan@sidhe.org>
23 $! Thank you!!!!
24 $!
25 $! Adapted and converted from Larry Wall & Andy Dougherty's
26 $! "Configure generated by metaconfig 3.0 PL60." by Peter Prymmer
27 $! (a Bourne sh[ell] script for configuring the installation of perl 
28 $! on non-VMS systems) in the perl5.002|3 epoch (spring/summer 1996)
29 $! with much valuable help from Charles Bailey & 
30 $! the whole VMSPerl crew.
31 $! Extended and messed about with by Dan Sugalski
32 $!
33 $! SET NOVERIFY
34 $ sav_ver = F$VERIFY(sav_ver)
35 $!
36 $! VMS-isms we will need:
37 $ echo = "write sys$output "
38 $ cat  = "type"
39 $ gcc_symbol = "gcc"
40 $ ans = ""
41 $ macros = ""
42 $ extra_fags = ""
43 $ user_c_flags = ""
44 $ use_debugging_perl = "y"
45 $ use_ieee_math = "n"
46 $ be_case_sensitive = "n"
47 $ use_vmsdebug_perl = "n"
48 $ use64bitall = "n"
49 $ use64bitint = "n"
50 $ C_Compiler_Replace = "CC="
51 $ Thread_Live_Dangerously = "MT="
52 $ use_two_pot_malloc = "N"
53 $ use_pack_malloc = "N"
54 $ use_debugmalloc = "N"
55 $ d_secintgenv = "N"
56 $ cc_flags = ""
57 $ use_multiplicity = "N"
58 $ vms_default_directory_name = F$ENVIRONMENT("DEFAULT")
59 $ max_allowed_dir_depth = 3  ! e.g. [A.B.PERL5_xxx] not [A.B.C.PERL5_xxx]
60 $! max_allowed_dir_depth = 2  ! e.g. [A.PERL5_xxx] not [A.B.PERL5_xxx]
61 $!
62 $ vms_filcnt = F$GETJPI ("","FILCNT")
63 $!
64 $!: compute my invocation name
65 $ me = F$ENVIRONMENT("PROCEDURE")
66 $!
67 $! Many null statements (begin with colon ':') in the Bourne shell version of
68 $! this script serve as comments/placeholders. I have retained some of the ones
69 $! that will help you compare this .COM file to the sh version - as well as
70 $! leave placeholders for future improvements to this .COM file.
71 $! sfn = VMS "skipped for now"
72 $!
73 $!: Proper PATH separator                              !sfn
74 $!: Proper PATH setting                                !sfn
75 $!: Sanity checks                                      !sfn "Say '@''$me''"
76 $!: On HP-UX, large Configure scripts may exercise a bug in /bin/sh !sfn
77 $!: Configure runs within the UU subdirectory          !->after find MANIFEST
78 $!   <big long list of default values (mostly null)>
79 $!: We must find out about Eunice early                !(?)
80 $!: list of known cpp symbols, sorted alphabetically   !sfn
81 $!   al = al + "..."
82 $!: default library list                               !sfn
83 $!   <no hints files in use (yet?)>
84 $!: Extra object files, if any, needed on this platform. !sfn
85 $!: Possible local include directories to search.      !sfn
86 $!: Set locincpth to "" in a hint file to defeat local include searches. !sfn
87 $!locincpth="/usr/local/include /opt/local/include /usr/gnu/include" !sfn
88 $!locincpth="$locincpth /opt/gnu/include /usr/GNU/include /opt/GNU/include"
89 $!: no include file wanted by default                  !sfn
90 $!inclwanted=''                                        !sfn
91 $!: Possible local library directories to search.      !sfn
92 $!loclibpth="/usr/local/lib /opt/local/lib /usr/gnu/lib" !sfn
93 $!loclibpth="$loclibpth /opt/gnu/lib /usr/GNU/lib /opt/GNU/lib" !sfn
94 $!: general looking path for locating libraries        !sfn
95 $!glibpth="/lib/pa1.1 /usr/shlib /usr/lib/large /lib /usr/lib" !sfn
96 $!glibpth="$glibpth $xlibpth /lib/large /usr/lib/small /lib/small" !sfn
97 $!glibpth="$glibpth /usr/ccs/lib /usr/ucblib /usr/shlib" !sfn
98 $!: Private path used by Configure to find libraries.  Its value !sfn
99 $!: is prepended to libpth. This variable takes care of special !sfn
100 $!: machines, like the mips.  Usually, it should be empty. !sfn
101 $!plibpth=''                                           !sfn
102 $!: full support for void wanted by default            !sfn
103 $!defvoidused=15                                       !sfn
104 $!: List of libraries we want.                         !sfn
105 $!libswanted='net socket inet nsl nm ndbm gdbm dbm db malloc dl' !sfn
106 $!libswanted="$libswanted dld ld sun m c cposix posix ndir dir crypt" !sfn
107 $!libswanted="$libswanted ucb bsd BSD PW x"            !sfn
108 $!: We probably want to search /usr/shlib before most other libraries. !sfn
109 $!: This is only used by the lib/ExtUtils/MakeMaker.pm routine extliblist. !sfn
110 $!glibpth=`echo " $glibpth " | sed -e 's! /usr/shlib ! !'` !sfn
111 $!glibpth="/usr/shlib $glibpth"                        !sfn
112 $!: Do not use vfork unless overridden by a hint file. !sfn
113 $!usevfork=false                                       !sfn
114 $!: script used to extract .SH files with variable substitutions !sfn
115 $!: produce awk script to parse command line options   !sfn
116 $!sfn (assume no sed awk) see below
117 $!: process the command line options         
118 $!
119 $!: set up default values
120 $ fastread=""
121 $ reuseval="false"
122 $ maniskip = "false"
123 $ config_sh=""
124 $ alldone=""
125 $ error=""
126 $ silent=""
127 $ extractsh=""
128 $ override=""
129 $ knowitall=""
130 $ Using_Dec_C = ""
131 $ Using_Gnu_C = ""
132 $ Dec_C_Version = ""
133 $ use_threads = "F"
134 $ use_5005_threads = "N"
135 $ use_ithreads = "N"
136 $!
137 $!: option parsing
138 $ IF (P1 .NES. "")
139 $ THEN            !one or more switches was thrown
140 $   i = 1
141 $   bang = 0
142 $Param_loop:
143 $   IF (P'i'.NES."") THEN bang = bang + 1
144 $   i = i + 1
145 $   IF (i.LT.9) THEN GOTO Param_loop !DCL allows P1..P8
146 $!
147 $   i = 1
148 $Opt_loop:
149 $   IF (F$EXTRACT(0,1,P'i') .EQS. "-") THEN P'i' = P'i' - "-"
150 $   IF (F$EXTRACT(0,1,P'i') .EQS. "/") THEN P'i' = P'i' - "/"
151 $Remove_quotation_mark:
152 $   P'i' = P'i' - """"
153 $   IF F$LOCATE("""",P'i') .LT. F$LENGTH(P'i') THEN GOTO Remove_quotation_mark
154 $   gotopt      = "f" !"alse"
155 $   gotshortopt = "f" !"alse"
156 $   IF (F$EXTRACT(0,1,P'i') .EQS. "d")
157 $   THEN
158 $     fastread    = "yes"
159 $     gotopt      = "t" !"rue"
160 $     P'i'        = P'i' - "d"
161 $     gotshortopt = "t" !"rue"
162 $   ENDIF
163 $   IF (F$EXTRACT(0,1,P'i') .EQS. "e")
164 $   THEN
165 $     alldone = "cont"
166 $     gotopt = "t"
167 $     P'i' = P'i' - "e"
168 $     gotshortopt = "t"
169 $   ENDIF
170 $   IF (F$EXTRACT(0,1,P'i') .EQS. "f") !"-f")
171 $   THEN
172 $     P'i' = P'i' - "f"
173 $     config_sh = P'i'
174 $     IF (F$SEARCH(config_sh).NES."")
175 $     THEN
176 $       test_config_sh = F$FILE_ATTRIBUTES(config_sh,"PRO")
177 $       IF (F$LOCATE("R",test_config_sh).NE.F$LENGTH(test_config_sh)) 
178 $       THEN
179 $         CONTINUE !at this point check UIC && if test allows...
180 $                  !to be continued ?
181 $       ELSE
182 $         echo "''me': cannot read config file ''config_sh'."
183 $         error="true"
184 $       ENDIF
185 $     ELSE
186 $       echo "''me': cannot read config file ''config_sh'."
187 $       error="true"
188 $     ENDIF
189 $     gotopt = "t"
190 $   ENDIF
191 $   IF (F$EXTRACT(0,1,P'i') .EQS. "h")
192 $   THEN
193 $     error = "true"
194 $     gotopt = "t"
195 $     P'i' = P'i' - "h"
196 $     gotshortopt = "t"
197 $   ENDIF
198 $   IF (F$EXTRACT(0,1,P'i') .EQS. "m")
199 $   THEN
200 $     maniskip = "true"
201 $     gotopt = "t"
202 $     P'i' = P'i' - "m"
203 $     gotshortopt = "t"
204 $   ENDIF
205 $   IF (F$EXTRACT(0,1,P'i') .EQS. "r")
206 $   THEN
207 $     reuseval = "true"
208 $     gotopt = "t"
209 $     P'i' = P'i' - "r"
210 $     gotshortopt = "t"
211 $   ENDIF
212 $   IF (F$EXTRACT(0,1,P'i') .EQS. "s")
213 $   THEN
214 $     silent = "true"
215 $     gotopt = "t"
216 $     P'i' = P'i' - "s"
217 $     gotshortopt = "t"
218 $   ENDIF
219 $   IF (F$EXTRACT(0,1,P'i') .EQS. "E") !"-E")
220 $   THEN
221 $     alldone = "exit"
222 $     gotopt = "t"
223 $   ENDIF
224 $   IF (F$EXTRACT(0,1,P'i') .EQS. "K") !"-K")
225 $   THEN
226 $     knowitall = "true"
227 $     gotopt = "t"
228 $     P'i' = P'i' - "K"
229 $     gotshortopt = "t"
230 $   ENDIF
231 $   IF (F$EXTRACT(0,1,P'i') .EQS. "O")
232 $   THEN
233 $     override = "true"
234 $     gotopt = "t"
235 $     P'i' = P'i' - "O"
236 $     gotshortopt = "t"
237 $   ENDIF
238 $   IF (F$EXTRACT(0,1,P'i') .EQS. "S") !"-S")
239 $   THEN
240 $     extractsh = "true" !VMS?
241 $     gotopt = "t"
242 $     P'i' = P'i' - "S"
243 $     gotshortopt = "t"
244 $   ENDIF
245 $   IF (F$EXTRACT(0,1,P'i') .EQS. "D") !"-D")
246 $   THEN
247 $     P'i' = P'i' - "D"
248 $!Hmm.. this part needs work
249 $!       P'i'
250 $     IF (F$LOCATE("=",P'i') .EQ. F$LENGTH(P'i'))
251 $     THEN
252 $       P'i' = "define"
253 $     ELSE 
254 $       IF (F$LOCATE("=",P'i') .EQ. (F$LENGTH(P'i') - 1))
255 $       THEN
256 $         me = F$PARSE(me,,,"NAME") + F$PARSE(me,,,"TYPE")
257 $         echo "''me': use '-Usymbol=val' not '-Dsymbol='."
258 $         echo "''me': ignoring -D",P'i'
259 $       ELSE
260 $!Hmm.. this part needs work
261 $!           'F$EXTRACT(0,F$LOCATE("=",P'i'),P'i')' = -
262 $! 'F$EXTRACT(F$LOCATE("=",P'i'),P'i'),F$LENGTH(P'i'),P'i')'
263 $       ENDIF
264 $     ENDIF
265 $     ECHO "P''i' =>",P'i',"<="  !Diag
266 $     gotopt = "t"
267 $   ENDIF
268 $   IF (F$EXTRACT(0,1,P'i') .EQS. "U") !"-U")
269 $   THEN
270 $     P'i' = P'i' - "U"
271 $     IF (F$LOCATE("=",P'i') .EQ. F$LENGTH(P'i'))
272 $     THEN
273 $       P'i' = ""
274 $     ELSE 
275 $       IF (F$LOCATE("=",P'i') .LT. (F$LENGTH(P'i') - 1))
276 $       THEN
277 $         me = F$PARSE(me,,,"NAME") + F$PARSE(me,,,"TYPE")
278 $         echo "''me': use '-Dsymbol=val' not '-Usymbol=val'."
279 $         echo "''me': ignoring -U",P'i'
280 $       ELSE
281 $         P'i' = "undef"
282 $       ENDIF
283 $     ENDIF
284 $     ECHO "P''i' =>",P'i',"<="  !Diag
285 $     gotopt = "t"
286 $   ENDIF
287 $   IF (F$EXTRACT(0,1,P'i') .EQS. "V")
288 $   THEN
289 $     me = F$PARSE(me,,,"NAME") + F$PARSE(me,,,"TYPE")
290 $     echo "''me' generated by an unknown version of EDT."
291 $     STOP
292 $     EXIT !0
293 $   ENDIF
294 $   IF .NOT.gotopt 
295 $   THEN
296 $     echo "''me': unknown option ",P'i'
297 $     error = "true"
298 $   ENDIF
299 $   IF (F$LENGTH(P'i').GT.0).AND.(gotshortopt) THEN i = i - 1 !clustered switch
300 $   i = i + 1 
301 $   IF (i .LT. (bang + 1)) THEN GOTO Opt_loop
302 $!
303 $ ENDIF  ! (P1 .NES. "")
304 $!
305 $ IF (error)
306 $ THEN
307 $   me = F$PARSE(me,,,"DIRECTORY")+ F$PARSE(me,,,"NAME")
308 $   echo "Usage: @''me' [-dehmrEKOSV] [-fconfig.sh] [-Dsymbol] [-Dsymbol=value]"
309 $   echo "                [-Usymbol]  [-Usymbol=]"
310 $   TYPE SYS$INPUT
311  "-d" : use defaults for all answers.
312  "-e" : go on without questioning past the production of config.sh.    *
313  "-f" : specify an alternate default configuration file.
314  "-h" : print this help message and exit (with an error status).
315  "-m" : skip the MANIFEST check to see that all files are present
316  "-r" : reuse C symbols value if possible (skips costly nm extraction).*
317  "-s" : silent mode, only echoes questions and essential information.
318  -"D" : define symbol to have some value:                              *
319          -"Dsymbol"         symbol gets the value 'define'
320          -"Dsymbol=value"   symbol gets the value 'value'
321   -E  : stop at the end of questions, after having produced config.sh. *
322   -K  : do not use unless you know what you are doing.
323   -O  : let -D and -U override definitions from loaded configuration file. *
324   -S  : perform variable substitutions on all .SH files (can mix with -f) *
325  -"U" : undefine symbol:                                               *
326          -"Usymbol"    symbol gets the value 'undef'
327          -"Usymbol="   symbol gets completely empty
328   -V  : print version number and exit (with a zero status).
329 $   echo "%Config-I-VMS, lower case switches must be enclosed"
330 $   echo "-Config-I-VMS, in double quotation marks, e.g.:"
331 $   echo "-Config-I-VMS,   @Configure ""-des"""
332 $   echo "-Config-I-VMS, * indicates switch may not be fully implemented for VMS."
333 $   SET DEFAULT 'vms_default_directory_name' !be kind rewind
334 $   STOP
335 $   EXIT 3 ! $STATUS = "%X00000003" (informational)
336 $ ENDIF
337 $!
338 $ GOTO Check_silence
339 $!
340 $Shut_up:
341 $ IF F$Mode() .eqs. "BATCH"
342 $ THEN
343 $   STDOUT = F$GetQuI("DISPLAY_JOB","LOG_SPECIFICATION",,"THIS_JOB")
344 $   WRITE SYS$OUTPUT "Warning: Executing in batch mode.  To avoid file locking conflicts,"
345 $   WRITE SYS$OUTPUT "output intended for SYS$OUTPUT will be sent to a new version"
346 $   WRITE SYS$OUTPUT STDOUT
347 $ ELSE
348 $   STDOUT = F$TRNLNM("SYS$OUTPUT")
349 $ ENDIF
350 $ DEFINE SYS$OUTPUT "_NLA0:"
351 $ echo4 = "write STDOUT "
352 $ cat4 = "TYPE/OUTPUT=''STDOUT'"
353 $ open/write/share=read STDOUT 'STDOUT'
354 $ RETURN
355 $!
356 $Check_silence:
357 $ IF (silent) 
358 $ THEN
359 $   GOSUB Shut_up
360 $ ELSE
361 $   echo4 = "write SYS$OUTPUT "
362 $   cat4 = "TYPE"
363 $ ENDIF
364 $!
365 $!: run the defines and the undefines, if any, but leave the file out there...
366 $! Unfortunately Configure.COM in DCL is not yet set up to do this - 
367 $! maybe someday
368 $!
369 $!: set package name
370 $ package = "perl5"
371 $ packageup = F$EDIT((package - "5"),"UPCASE")
372 $!
373 $!: Eunice requires " " instead of "", can you believe it
374 $ echo ""
375 $!: Here we go...
376 $ echo "Beginning of configuration questions for ''package'."
377 $ echo ""
378 $!
379 $!: Some greps do not return status, grrr.
380 $ contains = "SEARCH"
381 $!
382 $!: first determine how to suppress newline on echo command !cant DCL is record oriented
383 $! echo "Checking ''echo' to see how to suppress newlines..."
384 $! echo "giving up..."
385 $! echo "The star should be here-->*"
386 $!
387 $!: Now test for existence of everything in MANIFEST
388 $ echo ""
389 $ echo4 "First let's make sure your kit is complete.  Checking..."
390 $ manifestfound = "" 
391 $ miss_list = "" 
392 $! Here I assume we are in the [foo.PERL5xxx.VMS...] tree
393 $! because the search routine simply does set def [-] if necessary.
394 $ file_2_find = "MANIFEST" !I hope this one is not in [foo.PERL5xxx.VMS...] 
395 $Research_manifest:
396 $ manifestfound = F$SEARCH(file_2_find)
397 $ IF (manifestfound .EQS. "")
398 $ THEN
399 $   IF F$PARSE(F$ENVIRONMENT("DEFAULT"),,,"DIRECTORY",).NES."[000000]"
400 $   THEN
401 $     SET DEFAULT [-]
402 $     GOTO Research_manifest
403 $   ELSE
404 $     echo ""
405 $     echo "There is no MANIFEST file.  I hope your kit is complete !"
406 $     miss_list = ""
407 $     GOTO Beyond_manifest
408 $   ENDIF
409 $ ELSE
410 $! MANIFEST. has been found and we have set def'ed there - 
411 $! time to bail out before it's too late.
412 $ tmp = f$extract(1,3,f$edit(f$getsyi("VERSION"),"TRIM,COLLAPSE"))
413 $ IF (tmp .GES. "7.2") .AND. (F$GETSYI("HW_MODEL") .GE. 1024) THEN GOTO Beyond_depth_check
414 $   IF (F$ELEMENT(max_allowed_dir_depth,".",F$ENVIRONMENT("Default")).nes.".")
415 $   THEN
416 $     TYPE SYS$INPUT:
417 %Config-E-VMS, ERROR:
418  Sorry! It apears as though your perl build sub-directory is already too
419  deep into the VMS file system. Please try moving stuff into a shallower 
420  directory (or altering the "max_allowed_dir_depth" parameter).
421 $     echo4 "ABORTING..."
422 $     SET DEFAULT 'vms_default_directory_name' !be kind rewind
423 $     STOP
424 $     EXIT !2 !$STATUS = "%X00000002" (error)
425 $   ENDIF
426 $Beyond_depth_check:
427 $!
428 $! after finding MANIFEST let's create (but not yet enter) the UU subdirectory
429 $!
430 $   IF (manifestfound .NES. "")
431 $   THEN
432 $     IF ( F$SEARCH("UU.DIR").EQS."" )
433 $     THEN
434 $       CREATE/DIRECTORY [.UU]
435 $     ELSE
436 $       IF ( F$SEARCH("[.UU]*.*").NES."" ) THEN DELETE/NOLOG [.UU]*.*;*
437 $     ENDIF
438 $!: Configure runs within the UU subdirectory
439 $     SET DEFAULT [.UU]
440 $!
441 $! a little redundancy never hurt anybody?
442 $     file_2_find = "[-]" + file_2_find
443 $     manifestfound = F$SEARCH(file_2_find)
444 $!
445 $     OPEN/WRITE MISSING MISSING.
446 $!change to "FALSE" if you wish to skip the manifest search 
447 $!(which after all is rather slow in DCL :-)
448 $     IF (maniskip)
449 $     THEN
450 $       echo "Skipping MANIFEST check as requested"
451 $     ELSE
452 $!
453 $       OPEN/READ CONFIG 'manifestfound'
454 $Read_loop_manifest:
455 $       READ/END_OF_FILE = Done_manifest CONFIG line
456 $! This algorithm turns "foo/bar/baz.c" into "[.foo.bar]baz.c"
457 $! pvhp@lns62.lns.cornell.edu 10-JUN-1996 20:31:46
458 $! 2-MAR-1998 15:46:11 Improved to turn "foo/bar/baz.c.buz"
459 $! into "[.foo.bar]baz.c_buz as happens with vmstar and unzip
460 $       line = F$EDIT(line,"TRIM, COMPRESS")
461 $       file_2_find = F$EXTRACT(0,F$LOCATE(" ",line),line) 
462 $       IF F$LOCATE("/",file_2_find) .NE. F$LENGTH(file_2_find) 
463 $       THEN 
464 $Re_strip_line_manifest:
465 $         loca = F$LOCATE("/",file_2_find)
466 $         ante = F$EXTRACT(0,loca,file_2_find)
467 $         post = F$EXTRACT(loca,F$LENGTH(file_2_find),file_2_find)
468 $         test_this = ante + "." + (post - "/")
469 $         IF F$LOCATE("/",test_this) .NE. F$LENGTH(test_this)
470 $         THEN 
471 $           file_2_find = ante + "." + (post - "/")
472 $           GOTO Re_strip_line_manifest
473 $         ELSE
474 $           file_2_find = ante + "]" + (post - "/")
475 $         ENDIF
476 $           file_2_find = "[-."+file_2_find
477 $       ELSE
478 $         file_2_find = "[-]" + file_2_find
479 $       ENDIF
480 $!
481 $       dirname = F$EXTRACT(0,F$LOCATE("]",file_2_find),file_2_find) + "]"
482 $       file_2_find = file_2_find - dirname
483 $       dots = 0
484 $Dot_loop:
485 $       dot_ele = F$ELEMENT(dots,".",file_2_find)
486 $       IF dot_ele .EQS. "." THEN GOTO Eo_dot_loop
487 $       IF dots .eq. 0
488 $       THEN basename = f$extract(0,f$locate(".",file_2_find),file_2_find) + "."
489 $       ELSE basename = basename + dot_ele + "_"
490 $       ENDIF
491 $       dots = dots + 1
492 $       GOTO dot_loop
493 $Eo_dot_loop:
494 $       IF (((f$length(file_2_find)+1) .eq. f$length(basename)) .and. -
495              (f$extract(f$length(basename)-1,1,basename) .eqs. "_")) THEN -
496           basename = f$extract(0,f$length(basename)-1,basename)
497 $       file_2_find = dirname + basename
498 $!
499 $       found = F$SEARCH(file_2_find)
500 $       IF (found .EQS. "" .AND. dots .GT. 2)
501 $       THEN
502 $! 17-DEC-1999 Improved to turn "[.foo.bar]baz.c_buz" into
503 $! "[.foo.bar]baz_c.buz" to cover unzipped archives and put
504 $! "[.foo.bar]baz.c_buz,baz_c.buz" into missing list if neither is found.
505 $         basename[f$locate(".",basename),1] := _
506 $         dot_ele = F$ELEMENT(dots - 1,"_",basename)
507 $         basename = -
508             f$extract(0,f$length(basename)-(f$length(dot_ele)+1),basename) -
509               + "." + dot_ele
510 $         found = F$SEARCH(dirname + basename)
511 $         file_2_find = file_2_find + "," + basename
512 $       ENDIF
513 $       IF (found .EQS. "")
514 $       THEN
515 $         WRITE MISSING file_2_find
516 $         IF ((F$LENGTH(miss_list)+F$LENGTH(file_2_find)).LT.250)
517 $         THEN
518 $           miss_list = miss_list + "," + file_2_find
519 $         ENDIF
520 $       ENDIF
521 $       GOTO Read_loop_manifest
522 $Done_manifest:
523 $       CLOSE CONFIG
524 $     ENDIF  !"TRUE"
525 $     CLOSE MISSING
526 $   ENDIF ! (manifestfound .NES. "")
527 $Beyond_manifest:
528 $   IF (miss_list .NES. "")
529 $   THEN
530 $     echo "Some of the files not found include:"
531 $     cat4 MISSING.
532 $   ENDIF
533 $   IF ((miss_list .NES. "").OR.(manifestfound .EQS. ""))
534 $   THEN
535 $     TYPE SYS$INPUT:
536
537 THIS PACKAGE SEEMS TO BE INCOMPLETE.
538
539 You have the option of continuing the configuration process, despite the
540 distinct possibility that your kit is damaged, by typing 'y'es.  If you
541 do, don't blame me if something goes wrong.  I advise you to type 'n'o
542 and contact the author (dan@sidhe.org)
543
544 $     READ SYS$COMMAND/PROMPT="Continue? [n] " ans
545 $     IF ans
546 $     THEN
547 $       echo4 "Continuing..."
548 $     ELSE
549 $       echo4 "ABORTING..."
550 $       GOTO Clean_up
551 $     ENDIF
552 $   ELSE
553 $     echo4 "Looks good..."
554 $     DELETE/NOLOG MISSING.;
555 $   ENDIF ! (miss_list .NES. "")
556 $ ENDIF   ! (manifestfound .EQS. "") ELSE 
557 $!
558 $! after finding MANIFEST (see above)
559 $!: Configure runs within the UU subdirectory 
560 $!
561 $!: compute the number of columns on the terminal for proper question formatting
562 $! (sfn, will assume 80-ish)
563 $!
564 $!: set up the echo used in my read              !sfn
565 $!: now set up to do reads with possible shell escape and default assignment !sfn
566 $ GOTO Beyond_myread
567 $!
568 $myread:
569 $ ans = ""
570 $ If (fastread)
571 $ Then
572 $   echo4 "''rp'"
573 $ Else
574 $   If (silent)
575 $   Then
576 $     READ SYS$COMMAND/PROMPT="''rp'" ans
577 $   Else
578 $     echo ""
579 $     READ SYS$COMMAND/PROMPT="''rp'" ans
580 $   Endif
581 $ Endif
582 $ RETURN
583 $!
584 $Beyond_myread:
585 $!
586 $!: create .config dir to save info across Configure sessions
587 $ IF ( F$SEARCH("[-]CONFIG.DIR").EQS."" )
588 $ THEN
589 $   CREATE/DIRECTORY [-.CONFIG]
590 $   OPEN/WRITE CONFIG [-.CONFIG]README.
591 $   WRITE CONFIG -
592       "This directory created by Configure to save information that should"
593 $   WRITE CONFIG -
594       "persist across sessions."
595 $   WRITE CONFIG ""
596 $   WRITE CONFIG -
597       "You may safely delete it if you wish."
598 $   CLOSE CONFIG
599 $ ENDIF
600 $!
601 $!: general instructions
602 $ needman = "true"
603 $ firsttime = "true"
604 $ user = F$EDIT(F$GETJPI("","USERNAME"),"TRIM,COLLAPSE")
605 $ IF .NOT.(F$SEARCH("[-.CONFIG]INSTRUCT.").EQS."")
606 $ THEN
607 $   messages = F$ENVIRONMENT("MESSAGE")
608 $   SET MESSAGE/NOFAC/NOSEV/NOIDENT/NOTEXT
609 $   contains /NOOUTPUT [-.CONFIG]INSTRUCT. 'user'
610 $   IF .NOT.($status.EQ.%X08D78053)
611 $   THEN
612 $     firsttime=""
613 $     dflt = "n"
614 $     rp = "Would you like to see the instructions? [''dflt'] "
615 $     GOSUB myread
616 $     if .NOT.ans THEN needman=""
617 $   ENDIF
618 $   SET MESSAGE 'messages'
619 $ ENDIF
620 $ if (fastread.AND.silent.AND.(alldone.eqs."cont")) THEN needman=""
621 $!
622 $ IF (needman)
623 $ THEN
624 $   TYPE SYS$INPUT:
625
626 This installation shell script will examine your system and ask you questions
627 to determine how the perl5 package should be installed. If you get
628 stuck on a question, you may use a ^C or ^Y shell escape to STOP this
629 process, edit something, then restart this process as you just did.
630 Many of the questions will have default answers in square
631 brackets; typing carriage return will give you the default.
632
633 $   READ SYS$COMMAND/PROMPT="Type carriage return to continue " ans
634 $   TYPE SYS$INPUT:
635
636 In a hurry? You may run '@Configure "-d"'.  This will bypass nearly all
637 the questions and use the computed defaults (or the previous answers provided 
638 there was already a config.sh file). Type '@Configure "-h"' for a list of 
639 options.
640
641 $   READ SYS$COMMAND/PROMPT="Type carriage return to continue " ans
642 $   TYPE SYS$INPUT:
643
644 Much effort has been expended to ensure that this shell script will
645 run on any VMS system.  If despite that it blows up on yours, your
646 best bet is to edit Configure.com and @ it again.  Whatever problems
647 you have with Configure.com, let me (dan@sidhe.org) know how I blew
648 it.
649
650 $!This installation script affects things in two ways:
651 $!
652 $!1) it may do direct variable substitutions on some of the files included
653 $!   in this kit.
654 $!2) it builds a config.h file for inclusion in C programs.  You may edit
655 $!   any of these files as the need arises after running this script.
656 $!
657 $!If you make a mistake on a question, there is no easy way to back up to it
658 $!currently.
659 $!
660 $   READ SYS$COMMAND/PROMPT="Type carriage return to continue " ans
661 $   IF (F$SEARCH("[-.CONFIG]INSTRUCT.").EQS."")
662 $   THEN
663 $     OPEN/WRITE CONFIG [-.CONFIG]INSTRUCT.
664 $     WRITE CONFIG user 
665 $     CLOSE CONFIG
666 $   ENDIF
667 $ ENDIF  !(needman .EQS. "true")
668 $!
669 $!: see if sh knows # comments             !sfn
670 $ sharpbang = "$ "
671 $!: figure out how to guarantee sh startup !sfn
672 $!: find out where common programs are     !sfn
673 $!loclist="awk/cat/comm/cp/echo/expr/find/grep/ln/ls/mkdir/rm/sed/sort/touch/tr/uniq"
674 $!trylist="Mcc/byacc/cpp/csh/date/egrep/less/line/more/nroff/perl/pg/sendmail/test/uname"
675 $! echo "I don't know where '$file' is, and my life depends on it."
676 $! echo "Go find a public domain implementation or fix your PATH setting!"
677 $! echo ""
678 $! echo "Don't worry if any of the following aren't found..."
679 $!: determine whether symbolic links are supported !sfn
680 $!: see whether [:lower:] and [:upper:] are supported character classes !sfn
681 $!: set up the translation script tr, must be called with ./tr of course !sfn
682 $!
683 $!: Try to determine whether config.sh was made on this system
684 $!: Get old answers from old config file if Configure was run on the
685 $!: same system, otherwise use the hints.
686 $ config_sh_es = "''config_sh'/[-]config.sh/[-.vms]config.vms/"
687 $ i = 0
688 $ max = 3
689 $Config_sh_look:
690 $ config_sh = F$ELEMENT(i,"/",config_sh_es)
691 $ i = i + 1
692 $ IF (config_sh.NES."/").AND.(config_sh.NES."")
693 $ THEN
694 $   configshfound = F$SEARCH(config_sh)
695 $   IF (configshfound.NES."") THEN GOTO Config_sh_found
696 $ ENDIF
697 $ IF (i.LT.max) THEN GOTO Config_sh_look
698 $ IF (configshfound.EQS."") THEN GOTO Beyond_config_sh
699 $Config_sh_found:
700 $ echo ""
701 $ echo "Fetching default answers from ''config_sh'..."
702 $!we actually do not have "hints/" for VMS
703 $!     TYPE SYS$INPUT:
704 $!
705 $!First time through, eh?  I have some defaults handy for the following systems:
706 $!
707 $!     echo "     ","VMS_VAX"
708 $!     echo "     ","VMS_AXP"
709 $!        : Now look for a hint file osname_osvers, unless one has been
710 $!        : specified already.
711 $!     TYPE SYS$INPUT:
712 $!
713 $!You may give one or more space-separated answers, or "none" if appropriate.
714 $!If your OS version has no hints, DO NOT give a wrong version -- say "none".
715 $!
716 $!     READ SYS$COMMAND/PROMPT="Which of these apply, if any? " ans
717 $!
718 $Beyond_config_sh:
719 $!
720 $!: Restore computed paths          !sfn
721 $!
722 $! genconfig.pl has "osname='VMS'"
723 $ osname = F$EDIT(F$GETSYI("NODE_SWTYPE"),"COLLAPSE") 
724 $! %Config-I-VMS, a necessary error trap (could be PC running VCL)
725 $!
726 $ IF (osname .NES. "VMS")
727 $ THEN
728 $   echo4 "Hmm.. I wonder what ''osname' is (?)"
729 $   TYPE SYS$INPUT:
730
731 %Config-E-VMS, ERROR:
732
733            Err, you do not appear to be running VMS!
734  This procedure is intended to Configure the building of Perl for VMS.
735
736 $   READ SYS$COMMAND/PROMPT="Continue anyway? [n] " ans
737 $   IF ans
738 $   THEN
739 $     echo4 "Continuing..."
740 $   ELSE
741 $     echo4 "ABORTING..."
742 $     SET DEFAULT 'vms_default_directory_name' !be kind rewind
743 $     STOP
744 $     EXIT 2 !$STATUS = "%X00000002" (error)
745 $   ENDIF
746 $ ELSE           !we are on VMS huzzah!
747 $   IF .NOT.silent 
748 $   THEN TYPE SYS$INPUT:
749
750 Configure uses the operating system name and version to set some defaults.
751 The default value is probably right if the name rings a bell. Otherwise,
752 since spelling matters for me, either accept the default or answer "none"
753 to leave it blank.
754 $   ENDIF
755 $   rp = "Operating system name? [''osname'] "
756 $   GOSUB myread
757 $   IF ans.nes.""
758 $   THEN
759 $     IF (ans.NES.osname) !.AND.knowitall
760 $     THEN
761 $       echo4 "I'll go with ''osname' anyway..."
762 $     ENDIF
763 $   ENDIF
764 $ ENDIF !(osname .NES./.EQS. "VMS")
765 $!
766 $!: who configured the system
767 $! see 'user' above.
768 $ cf_by = F$EDIT(user,"LOWERCASE")
769 $! cf_time = F$CVTIME()                 !superceded by procedure below
770 $ osvers = F$GETSYI("VERSION")
771 $!
772 $! Peter Prymmer has seen:
773 $!  "SYS$TIMEZONE_DIFFERENTIAL" = "-46800"  (sic)
774 $!  "SYS$TIME_ZONE" = "EDT"
775 $!
776 $! Charles Lane recommended:
777 $!  "SYS$TIMEZONE_DIFFERENTIAL" = "-14400"
778 $!  "NEWS_TIMEZONE" = "-0500"
779 $!  "ST_TIMEZONE" = "EDT"
780 $!  "JAN_TIME_ZONE" = "EST  "
781 $!  "MULTINET_TIMEZONE" = "EST"
782 $!  "DAYLIGHT_SAVINGS"  = "1"
783 $!
784 $! Charles Bailey recommends (in ANU NEWS Doc Jan 1995):
785 $!   "PMDF_Timezone"
786 $!   "Multinet_Timezone"
787 $!   "TCPware_Timezone"
788 $!   "WIN$Time_Zone"
789 $!
790 $! This snippet o' DCL returns a string in default Unix `date` format,
791 $! and it will prompt to set SYS$TIMEZONE_DIFFERENTIAL.
792 $! Peter Prymmer pvhp@lns62.lns.cornell.edu
793 $!
794 $ MIN_TZO = -840  !units are minutes here
795 $ MAX_TZO =  840
796 $!
797 $ wkday  = F$EXTRACT(0,3,F$CVTIME(,,"WEEKDAY"))
798 $ monn   = F$CVTIME(,,"MONTH")
799 $ mday   = F$EXTRACT(8,2,F$CVTIME(,,"DATE"))
800 $ hour   = F$CVTIME(,,"HOUR")
801 $ min    = F$CVTIME(,,"MINUTE")
802 $ sec    = F$CVTIME(,,"SECOND")
803 $ year   = F$CVTIME(,,"YEAR")
804 $!
805 $ months = "/Jan/Feb/Mar/Apr/May/Jun/Jul/Aug/Sep/Oct/Nov/Dec/"
806 $ i = 0
807 $Mon_loop:
808 $ i = i + 1
809 $ mon = F$ELEMENT(i,"/",months)
810 $ IF i.LT.monn THEN GOTO Mon_loop
811 $!
812 $ tzneedset = "t"
813 $ systz = F$TRNLNM("SYS$TIMEZONE_DIFFERENTIAL")
814 $ IF systz.NES.""
815 $ THEN
816 $   tzhour = F$INTEGER(systz)/3600
817 $   tzmins = F$INTEGER(systz)/60
818 $   tzminrem = tzmins - tzhour*60
819 $   IF tzminrem.lt.0 THEN tzminrem = -1*tzminrem  !keeps !2ZL happy
820 $   IF tzhour.ge.0 
821 $   THEN signothetime = "+" 
822 $     IF tzhour.EQ.0.AND.tzminrem.EQ.0 
823 $     THEN direction = "on GMT/"
824 $     ELSE direction = "east of "
825 $     ENDIF
826 $   ELSE signothetime = "-"
827 $     tzhour = -1*tzhour                          !keeps !UL happy
828 $     direction = "west of "
829 $   ENDIF
830 $   echo ""
831 $   echo "%Config-I-VMS,"
832 $   echo "According to the setting of your ""SYS$TIMEZONE_DIFFERENTIAL"" (= ''systz')"
833 $   IF tzminrem.ne.0
834 $   THEN
835 $     tzspan = "''tzhour' hours & ''tzminrem' minutes"
836 $   ELSE
837 $     tzspan = "''tzhour' hours"
838 $   ENDIF
839 $   dflt = "y"
840 $   echo "Your system is ''tzspan' ''direction'UTC in England."
841 $   rp = "%Config-I-VMS, (''systz') Is this UTC Time Zone Offset correct? [''dflt'] "
842 $   GOSUB myread
843 $   IF ans.OR.(ans.EQS."") 
844 $   THEN 
845 $     tzneedset = "f"
846 $     tzd = systz
847 $     GOTO Beyond_TimeZone
848 $   ENDIF
849 $ ELSE
850 $   echo ""
851 $   echo4 "%Config-I-VMS,"
852 $   echo4 """SYS$TIMEZONE_DIFFERENTIAL"" does not appear to be DEFINEd on your system"
853 $ ENDIF
854 $!
855 $TZSet:
856 $ echo ""
857 $ echo "Please tell me in hh:mm form what time offset from GMT/UTC in England"
858 $ echo "you are.  As an example Eastern (US) Standard Time is -5:00 offset, but"
859 $ echo "Eastern Daylight Time (summer) is -4:00 offset."
860 $ dflt = "0:00"
861 $ rp = "Enter the Time Zone offset: [''dflt'] "
862 $ GOSUB myread
863 $ ans = F$Edit(ans,"collapse,trim,uncomment,upcase")
864 $ IF ans.EQS."" THEN ans = dflt
865 $ tzhour   = F$ELEMENT(0,":","''ans'") !first
866 $ IF tzhour.EQS."" THEN tzhour = 0
867 $ tzhour   = F$INTEGER(tzhour)
868 $ tzminrem = F$ELEMENT(1,":","''ans'") !second
869 $ IF tzminrem.NES."" 
870 $ THEN 
871 $   tzminrem = F$INTEGER(tzminrem)
872 $   IF F$EXTRACT(0,1,"''ans'") .EQS. "-" THEN tzminrem = tzminrem * -1
873 $ ELSE 
874 $   tzminrem = 0
875 $ ENDIF
876 $ tzmins = tzhour*60 + tzminrem
877 $ tzd = F$STRING(tzmins*60)
878 $ IF tzhour .GE. 0 
879 $ THEN
880 $   signothetime = "+" 
881 $ ELSE
882 $   tzhour = -1*tzhour       !keeps !UL happy
883 $   signothetime = "-"
884 $ ENDIF
885 $ IF (tzmins.GT.MAX_TZO).OR.(tzmins.LT.MIN_TZO)
886 $ THEN
887 $   echo ""
888 $   echo "%Config-W-VMS-TIMERANGE, Response must be in the range -14:00 to 14:00."
889 $   goto TZSet
890 $ ENDIF
891 $!
892 $Beyond_TimeZone:
893 $ tz = f$fao("UTC!AS!UL:!2ZL",signothetime,tzhour,tzminrem)
894 $ cf_time = "''wkday' ''mon' ''mday' ''hour':''min':''sec' ''tz' ''year'"
895 $!
896 $!: determine the architecture name  
897 $! genconfig.pl has either archname='VMS_AXP' or 'VMS_VAX'
898 $!
899 $ IF (F$GETSYI("HW_MODEL") .LT. 1024)
900 $ THEN 
901 $   archname = "VMS_VAX"
902 $   otherarch = "an Alpha"
903 $ ELSE
904 $   archname = "VMS_AXP"
905 $   otherarch = "a VAX"
906 $ ENDIF
907 $ rp = "What is your architecture name? [''archname'] "
908 $ GOSUB myread
909 $ IF ans.NES.""
910 $ THEN
911 $   ans = F$EDIT(ans,"COLLAPSE, UPCASE")
912 $   IF (ans.NES.archname) !.AND.knowitall
913 $   THEN
914 $     echo4 "I'll go with ''archname' anyway..."
915 $   ENDIF
916 $ ENDIF
917 $ dflt = "n"
918 $ rp = "Will you be sharing your PERL_ROOT with ''otherarch'? [''dflt'] "
919 $ GOSUB myread
920 $ if ans.NES.""
921 $ THEN
922 $   ans = F$EXTRACT(0,1,F$EDIT(ans,"COLLAPSE, UPCASE"))
923 $ ENDIF
924 $ IF (ans.NES."Y")
925 $ THEN
926 $   sharedperl = "N"
927 $ ELSE
928 $   sharedperl = "Y"
929 $   IF (archname.EQS."VMS_AXP")
930 $   THEN
931 $     macros = macros + """AXE=1"","
932 $   ENDIF
933 $ ENDIF
934 $!
935 $!: is AFS running?                       !sfn
936 $!: decide how portable to be.  Allow command line overrides. !sfn
937 $!: set up shell script to do ~ expansion !sfn
938 $!: expand filename                       !sfn
939 $!: now set up to get a file name         !sfn
940 $!
941 $ prefix = F$ENVIRONMENT("DEFAULT") - ".UU]" + "]"
942 $ prefix = F$PARSE(prefix,,,,"NO_CONCEAL") - "][" - ".;"
943 $ prefixbase = prefix - "]"
944 $ prefix = prefixbase + ".]"
945 $!: determine root of directory hierarchy where package will be installed.
946 $ dflt = prefix
947 $ IF .NOT.silent 
948 $ THEN 
949 $   echo ""
950 $   echo "By default, ''package' will be installed in ''dflt', pod"
951 $   echo "pages under ''prefixbase'LIB.POD], etc..., i.e. with ''dflt' as prefix for"
952 $   echo "all installation directories."
953 $   echo "On ''osname' the ''prefix' is used to DEFINE the ''packageup'_ROOT prior to installation"
954 $   echo "as well as during subsequent use of ''package' via ''packageup'_SETUP.COM."
955 $ ENDIF
956 $ rp = "Installation prefix to use (for ''packageup'_ROOT)? [ ''dflt' ] "
957 $ GOSUB myread
958 $ IF ans.NES.""
959 $ THEN 
960 $   prefix = ans
961 $   IF F$LOCATE(".]",ans) .EQ. F$LENGTH(ans) THEN prefix = prefix - "]" + ".]"
962 $ ELSE 
963 $   prefix = dflt
964 $ ENDIF
965 $!
966 $! Check here for pre-existing PERL_ROOT.
967 $!  -> ask if removal desired.
968 $! Check here for writability of requested PERL_ROOT if it is not the default (cwd).
969 $!  -> recommend letting PERL_ROOT be PERL_SRC if requested PERL_ROOT is not writable.
970 $!
971 $ vms_skip_install = "true"
972 $ dflt = "y"
973 $! echo ""
974 $ rp = "%Config-I-VMS, Do you wish to skip the remaining """"where install"""" questions? [''dflt'] "
975 $ GOSUB myread
976 $ IF (.NOT.ans).AND.(ans.NES."") THEN vms_skip_install = "false"
977 $ IF (.NOT.vms_skip_install)
978 $ THEN
979 $!
980 $!: set the prefixit variable, to compute a suitable default value
981 $!
982 $!: determine where private library files go
983 $!: Usual default is /usr/local/lib/perl5.  Also allow things like 
984 $!: /opt/perl/lib, since /opt/perl/lib/perl5 would be redundant.
985 $   IF .NOT.silent 
986 $   THEN TYPE SYS$INPUT:
987
988 There are some auxiliary files for perl5 that need to be put into a
989 private library directory that is accessible by everyone.
990 $   ENDIF
991 $   dflt = prefix - ".]" + ".LIB]"
992 $   rp = "Pathname where the private library files will reside? " 
993 $   rp = F$FAO("!AS!/!AS",rp,"[ ''dflt' ] ")
994 $   GOSUB myread
995 $   IF ans.NES.""
996 $   THEN privlib = ans
997 $   ELSE privlib = dflt
998 $   ENDIF
999 $!
1000 $ ENDIF !%Config-I-VMS, skip remaining "where install" questions
1001 $!
1002 $ perl_symbol = "true"
1003 $ perl_verb = ""
1004 $ dflt = "y"
1005 $ IF .NOT.silent 
1006 $ THEN 
1007 $   echo ""
1008 $   echo "%Config-I-VMS, You may choose to write ''packageup'_SETUP.COM to assign a foreign"
1009 $   echo "-Config-I-VMS, symbol to invoke ''package', which is the usual method."
1010 $   echO "-Config-I-VMS, If you do not do so then you would need a DCL command verb at the"
1011 $   echo "-Config-I-VMS, process or the system wide level."
1012 $ ENDIF
1013 $ rp = "Invoke perl as a global symbol foreign command [''dflt'] "
1014 $ GOSUB myread
1015 $ IF (.NOT.ans).AND.(ans.NES."") THEN perl_symbol = "false"
1016 $!
1017 $ IF (.NOT.perl_symbol)
1018 $ THEN
1019 $   dflt = "y"
1020 $   IF .NOT.silent 
1021 $   THEN 
1022 $     echo ""
1023 $     echo "%Config-I-VMS, Since you won't be using a symbol you must choose to put the ''packageup'"
1024 $     echo "-Config-I-VMS, verb in a per-process table or in the system wide DCLTABLES (which"
1025 $     echo "-Config-I-VMS, would require write privilege)."
1026 $   ENDIF
1027 $   rp = "Invoke perl as a per process command verb [ ''dflt' ] "
1028 $   GOSUB myread
1029 $   IF (.NOT.ans).AND.(ans.NES."")
1030 $   THEN perl_verb = "DCLTABLES"
1031 $   ELSE perl_verb = "PROCESS"
1032 $   ENDIF
1033 $ ENDIF ! (.NOT.perl_symbol)
1034 $!
1035 $!: set the base revision
1036 $ baserev="5"
1037 $!: get the patchlevel
1038 $ echo ""
1039 $ echo4 "Getting the current patchlevel..." !>&4
1040 $ patchlevel_h = F$SEARCH("[-]patchlevel.h")
1041 $ IF (patchlevel_h.NES."")
1042 $ THEN
1043 $   got_patch = "false"
1044 $   got_sub   = "false"
1045 $   OPEN/READONLY CONFIG 'patchlevel_h' 
1046 $Patchlevel_h_loop:
1047 $   READ/END_Of_File=Close_patch CONFIG line
1048 $   IF ((F$LOCATE("#define PERL_VERSION",line).NE.F$LENGTH(line)).AND.(.NOT.got_patch))
1049 $   THEN
1050 $     line = F$EDIT(line,"COMPRESS, TRIM")
1051 $     patchlevel = F$ELEMENT(2," ",line)
1052 $     got_patch = "true"
1053 $   ENDIF
1054 $   IF ((F$LOCATE("#define PERL_SUBVERSION",line).NE.F$LENGTH(line)).AND.(.NOT.got_sub))
1055 $   THEN
1056 $     line = F$EDIT(line,"COMPRESS, TRIM")
1057 $     subversion = F$ELEMENT(2," ",line)
1058 $     got_sub = "true"
1059 $   ENDIF
1060 $   IF (.NOT.got_patch).OR.(.NOT.got_sub) THEN GOTO Patchlevel_h_loop
1061 $Close_patch:
1062 $   CLOSE CONFIG
1063 $   ELSE
1064 $     patchlevel="0"
1065 $     subversion="0"
1066 $ ENDIF
1067 $ echo "(You have ''package' ''baserev' PL''patchlevel' sub''subversion'.)"
1068 $! This whole thing needs replacing w/ F$FAO() calls:
1069 $ patchlevel = F$INTEGER(patchlevel)
1070 $ IF patchlevel.LT.10
1071 $ THEN patchlevel = "00" + F$STRING(patchlevel)
1072 $ ELSE patchlevel = "0" + F$STRING(patchlevel)
1073 $ ENDIF
1074 $ subversion = F$INTEGER(subversion)
1075 $ IF subversion.GT.0
1076 $ THEN
1077 $   IF subversion.LT.10
1078 $   THEN subversion = "0" + F$STRING(subversion)
1079 $   ELSE subversion = F$STRING(subversion)
1080 $   ENDIF
1081 $ ELSE subversion = ""
1082 $ ENDIF
1083 $!
1084 $ version = baserev + "_" + patchlevel + "_" + subversion
1085 $!
1086 $ IF (.NOT.vms_skip_install)
1087 $ THEN
1088 $!: set the prefixup variable, to restore leading tilda escape !sfn
1089 $!: set the prefixup variable, to restore leading tilde escape !sfn
1090 $!
1091 $!: determine where public architecture dependent libraries go
1092 $   IF (.NOT.silent) 
1093 $   THEN 
1094 $     echo ""
1095 $     echo "''package' contains architecture-dependent library files.  If you are"
1096 $   ENDIF
1097 $   IF (.NOT.silent) 
1098 $   THEN TYPE SYS$INPUT:
1099 sharing libraries in a heterogeneous environment, you might store
1100 these files in a separate location.  Otherwise, you can just include
1101 them with the rest of the public library files.
1102 $   ENDIF
1103 $   dflt = privlib - "]" + "." + archname + "." + version + "]"
1104 $   rp = "Where do you want to put the public architecture-dependent libraries? "
1105 $   rp = F$FAO("!AS!/!AS",rp,"[ ''dflt' ] ")
1106 $   GOSUB myread
1107 $   IF ans.NES.""
1108 $   THEN archlib = ans
1109 $   ELSE archlib = dflt
1110 $   ENDIF
1111 $!
1112 $!: set up the script used to warn in case of inconsistency !sfn
1113 $!: function used to set $1 to $val                         !sfn
1114 $!
1115 $ ENDIF !%Config-I-VMS, skip "where install" questions
1116 $! This quotation from Configure has to be included on VMS:
1117 $ TYPE SYS$INPUT:
1118
1119 There is, however, a strange, musty smell in the air that reminds me of
1120 something...hmm...yes...I've got it...there's a VMS nearby, or I'm a Blit.
1121 $ CONTINUE
1122 $ IF (.NOT.vms_skip_install)
1123 $ THEN
1124 $!: it so happens the Eunice I know will not run shell scripts in Unix format
1125 $!
1126 $!: see if setuid scripts can be secure           !sfn
1127 $!: now see if they want to do setuid emulation   !sfn
1128 $!
1129 $!: determine where site specific libraries go.
1130 $   IF .NOT.silent 
1131 $   THEN TYPE SYS$INPUT:
1132
1133 The installation process will also create a directory for
1134 site-specific extensions and modules.  Some users find it convenient
1135 to place all local files in this directory rather than in the main
1136 distribution directory.
1137 $   ENDIF
1138 $   dflt = privlib - "]" + ".SITE_PERL]"
1139 $   rp = "Pathname for the site-specific library files? "
1140 $   rp = F$FAO("!AS!/!AS",rp,"[ ''dflt' ] ")
1141 $   GOSUB myread
1142 $   IF ans.NES.""
1143 $   THEN sitelib = ans
1144 $   ELSE sitelib = dflt
1145 $   ENDIF
1146 $!
1147 $!: determine where site specific architecture-dependent libraries go.
1148 $   IF .NOT.silent 
1149 $   THEN TYPE SYS$INPUT:
1150
1151 The installation process will also create a directory for
1152 architecture-dependent site-specific extensions and modules.
1153 $   ENDIF
1154 $   dflt = sitelib - "]" + "." + archname + "]"
1155 $   rp = "Pathname for the site-specific architecture-dependent library files? "
1156 $   rp = F$FAO("!AS!/!AS",rp,"[ ''dflt' ] ")
1157 $   GOSUB myread
1158 $   IF ans.NES.""
1159 $   THEN sitearch = ans
1160 $   ELSE sitearch = dflt
1161 $   ENDIF
1162 $!
1163 $!: determine where old public architecture dependent libraries might be
1164 $!
1165 $!: determine where public executables go
1166 $   dflt = prefix - ".]" + ".BIN]"
1167 $   rp = "Pathname where the public executables will reside? "
1168 $   rp = F$FAO("!AS!/!AS",rp,"[ ''dflt' ] ")
1169 $   GOSUB myread
1170 $   IF ans.NES.""
1171 $   THEN bin = ans
1172 $   ELSE bin = dflt
1173 $   ENDIF
1174 $!
1175 $!: determine where manual pages are on this system
1176 $!: What suffix to use on installed man pages
1177 $!: see if we can have long filenames
1178 $!: determine where library module manual pages go
1179 $!: What suffix to use on installed man pages
1180 $!: see what memory models we can support
1181 $!
1182 $ ENDIF !%Config-I-VMS, skip "where install" questions
1183 $!
1184 $!: see if we need a special compiler
1185 $! cc_list = "cc/decc|gcc" !%Config-I-VMS, compiler symbols/commands
1186 $!
1187 $ nocc = "f"
1188 $ vms_cc_dflt = ""
1189 $ vms_cc_available = ""
1190 $!
1191 $ OPEN/WRITE CONFIG ccvms.c
1192 $ WRITE CONFIG "#include <stdlib.h>"  !DECC is sooo picky
1193 $ WRITE CONFIG "#include <stdio.h>"
1194 $ WRITE CONFIG "int main() {"
1195 $ WRITE CONFIG "#ifdef __DECC"
1196 $ WRITE CONFIG "        printf(""/DECC\n"");"
1197 $ WRITE CONFIG "#else"
1198 $ WRITE CONFIG "        printf(""/VAXC\n"");"
1199 $ WRITE CONFIG "#endif"
1200 $ WRITE CONFIG "        exit(0);"
1201 $ WRITE CONFIG "}"
1202 $ CLOSE CONFIG
1203 $!
1204 $! DEFINE SYS$ERROR _NLA0:
1205 $! DEFINE SYS$OUTPUT _NLA0:
1206 $ cc/NoObj/list=ccvms.lis ccvms.c
1207 $ tmp = $status
1208 $! DEASSIGN SYS$OUTPUT
1209 $! DEASSIGN SYS$ERROR
1210 $ IF (silent) THEN GOSUB Shut_up
1211 $! echo "%Config-I-VMS, After cc compile $status = >''tmp'<" !diagnostic
1212 $!
1213 $ IF tmp.NE.%X10B90001
1214 $ THEN 
1215 $  IF tmp.NE.%X10000001
1216 $  THEN 
1217 $    nocc = "t"  !%X10000001 is return from gcc
1218 $    GOTO Gcc_initial_check
1219 $  ENDIF
1220 $ ENDIF
1221 $!
1222 $ GOSUB List_Parse
1223 $ IF .NOT.silent THEN echo ""
1224 $ echo "%Config-I-VMS, Default ""cc"" is ''line' ''archsufx' ''F$GETSYI("VERSION")'" 
1225 $ IF F$LOCATE("VAX",line).NE.F$LENGTH(line) 
1226 $ THEN 
1227 $   IF .NOT.silent
1228 $   THEN 
1229 $     echo "%Config-I-VMS, Will try cc/decc..."
1230 $   ENDIF
1231 $   DEFINE SYS$ERROR _NLA0:
1232 $   DEFINE SYS$OUTPUT _NLA0:
1233 $   SET NOON
1234 $   cc/decc/NoObj/list=ccvms.lis ccvms.c
1235 $   tmp = $status
1236 $   DEASSIGN SYS$OUTPUT
1237 $   DEASSIGN SYS$ERROR
1238 $   SET ON
1239 $   IF (silent) THEN GOSUB Shut_up
1240 $   IF tmp.NE.%X10B90001
1241 $   THEN
1242 $     echo "%Config-I-VMS, Apparently you don't have that one."
1243 $   ELSE
1244 $     GOSUB List_parse
1245 $     echo "%Config-I-VMS, You also have: ''line' ''archsufx' ''F$GETSYI("VERSION")'"
1246 $     vms_cc_available = vms_cc_available + "cc/decc "
1247 $   ENDIF
1248 $ ELSE
1249 $   IF (F$LOCATE("DEC",line).NE.F$LENGTH(line)).or.(F$LOCATE("Compaq",line).NE.F$LENGTH(line))
1250 $   THEN 
1251 $     vms_cc_dflt = "/decc"
1252 $     vms_cc_available = vms_cc_available + "cc/decc "
1253 $   ENDIF
1254 $ ENDIF
1255 $!
1256 $Gcc_initial_check:
1257 $ echo "%Config-I-VMS, Checking for Gcc"
1258 $ OPEN/WRITE CONFIG gccvers.lis
1259 $ DEFINE SYS$ERROR CONFIG
1260 $ DEFINE SYS$OUTPUT CONFIG
1261 $ 'gcc_symbol'/noobj/version _nla0:
1262 $ tmp = $status
1263 $ DEASSIGN SYS$OUTPUT
1264 $ DEASSIGN SYS$ERROR
1265 $ IF (silent) THEN GOSUB Shut_up
1266 $ CLOSE CONFIG
1267 $ IF (tmp.NE.%X10000001).and.(tmp.ne.%X00030001)
1268 $ THEN
1269 $   echo "%Config-I-VMS, Symbol ""''gcc_symbol'"" is not defined. I guess you don't have it."
1270 $   goto cc_cleanup
1271 $ ENDIF
1272 $ OPEN/READ CONFIG gccvers.lis
1273 $GCC_List_Read:
1274 $ READ/END_OF_FILE=GCC_List_End CONFIG line
1275 $ GOTO GCC_List_Read
1276 $GCC_List_End:
1277 $ CLOSE CONFIG
1278 $ echo line
1279 $ vms_cc_available = vms_cc_available + "''gcc_symbol' "
1280 $ DELETE/NOLOG/NOCONFIRM gccvers.lis;
1281 $!
1282 $CC_Cleanup:
1283 $ DELETE/NOLOG/NOCONFIRM ccvms.*;
1284 $CC_Desired:
1285 $!: see if we need a special compiler
1286 $! echo ""
1287 $ echo "%Config-I-VMS, available compiler(s):"
1288 $ echo "( ''vms_cc_available')"
1289 $ IF .NOT.nocc 
1290 $ THEN
1291 $   dflt = "cc''vms_cc_dflt'"  !-> "cc" in case first compile went OK
1292 $ ELSE
1293 $   dflt = gcc_symbol
1294 $ ENDIF
1295 $ rp = "Use which C compiler? [''dflt'] "
1296 $ GOSUB myread
1297 $ IF ans.NES.""
1298 $ THEN
1299 $   ans = F$EDIT(ans,"TRIM, COMPRESS, LOWERCASE")
1300 $   Mcc = ans
1301 $   IF (F$LOCATE("dec",ans).NE.F$LENGTH(ans)).or.(F$LOCATE("compaq",ans).NE.F$LENGTH(ans))
1302 $   THEN
1303 $     Mcc = "cc/decc"
1304 $     Using_Dec_C = "Yes"
1305 $     C_COMPILER_Replace = "CC=cc=''Mcc'"
1306 $   ENDIF
1307 $   IF Mcc.NES.dflt
1308 $   THEN
1309 $     IF (F$LOCATE("dec",dflt).NE.F$LENGTH(dflt)).or(F$LOCATE("compaq",dflt).NE.F$LENGTH(dflt))
1310 $     THEN 
1311 $       C_COMPILER_Replace = "CC=cc=''Mcc'"
1312 $     ELSE
1313 $       Using_Dec_C = "Yes"
1314 $     ENDIF
1315 $   ELSE
1316 $     IF Mcc .EQS. "cc/decc"
1317 $     THEN
1318 $       Using_Dec_C = "Yes"
1319 $       C_COMPILER_Replace = "CC=cc=''Mcc'"
1320 $     ENDIF
1321 $   ENDIF
1322 $ ELSE 
1323 $   Mcc = dflt
1324 $   IF Mcc .EQS. "cc/decc"
1325 $   THEN
1326 $     Using_Dec_C = "Yes"
1327 $     C_COMPILER_Replace = "CC=cc=''Mcc'"
1328 $   ENDIF
1329 $   IF Mcc .EQS. "gcc"
1330 $   THEN
1331 $     Using_Gnu_C = "Yes"
1332 $     C_COMPILER_Replace = "CC=cc=''Mcc'"
1333 $   ENDIF
1334 $ ENDIF
1335 $Decc_Version_check:
1336 $ IF "''Using_Dec_C'".EQS."Yes"
1337 $ THEN
1338 $   echo ""
1339 $   echo4 "Checking for Dec C's version number..." !>&4
1340 $   OPEN/WRITE CONFIG deccvers.c
1341 $   WRITE CONFIG "#include <stdlib.h>"  !DECC is sooo picky
1342 $   WRITE CONFIG "#include <stdio.h>"
1343 $   WRITE CONFIG "int main() {"
1344 $   WRITE CONFIG "#ifdef __DECC"
1345 $   WRITE CONFIG "#ifdef __DECC_VER"
1346 $   WRITE CONFIG "        printf(""%i\n"", __DECC_VER);"
1347 $   WRITE CONFIG "#else"
1348 $   WRITE CONFIG "        printf(""%i\n"", ""1"");"
1349 $   WRITE CONFIG "#endif"
1350 $   WRITE CONFIG "#endif"
1351 $   WRITE CONFIG "        exit(0);"
1352 $   WRITE CONFIG "}"
1353 $   CLOSE CONFIG
1354 $   DEFINE SYS$ERROR _NLA0:
1355 $   DEFINE SYS$OUTPUT _NLA0:
1356 $   'Mcc' deccvers.c
1357 $   tmp = $status
1358 $   DEASSIGN SYS$ERROR _NLA0:
1359 $   DEASSIGN SYS$OUTPUT _NLA0:
1360 $   IF (silent) THEN GOSUB Shut_up
1361 $   DEFINE SYS$ERROR _NLA0:
1362 $   DEFINE SYS$OUTPUT _NLA0:
1363 $   link deccvers.obj
1364 $   tmp = $status
1365 $   DEASSIGN SYS$ERROR
1366 $   DEASSIGN SYS$OUTPUT
1367 $   IF (silent) THEN GOSUB Shut_up
1368 $   OPEN/WRITE CONFIG deccvers.out
1369 $   DEFINE SYS$ERROR CONFIG
1370 $   DEFINE SYS$OUTPUT CONFIG
1371 $   mcr []deccvers.exe
1372 $   tmp = $status
1373 $   CLOSE CONFIG
1374 $   DEASSIGN SYS$OUTPUT
1375 $   DEASSIGN SYS$ERROR
1376 $   IF (silent) THEN GOSUB Shut_up
1377 $   OPEN/READ CONFIG deccvers.out
1378 $   READ/END_OF_FILE=Dec_c_cleanup CONFIG line
1379 $Dec_c_cleanup:
1380 $   CLOSE CONFIG
1381 $!   DELETE/NOLOG/NOCONFIRM deccvers.*;
1382 $   echo "You are using Dec C ''line'"
1383 $   Dec_C_Version = line
1384 $   Dec_C_Version = Dec_C_Version + 0
1385 $   if Dec_C_Version.ge.60200000 THEN CC_FLAGS = CC_FLAGS + "/NOANSI_ALIAS"
1386 $ ENDIF
1387 $Gcc_check:
1388 $ if "''using_gnu_c'" .eqs. "Yes"
1389 $ THEN
1390 $ vaxcrtl_olb = F$SEARCH("SYS$LIBRARY:VAXCRTL.OLB")
1391 $ vaxcrtl_exe = F$SEARCH("SYS$SHARE:VAXCRTL.EXE")
1392 $ gcclib_olb  = F$SEARCH("GNU_CC:[000000]GCCLIB.OLB")
1393 $ IF gcclib_olb .EQS. "" 
1394 $ THEN 
1395 $! These objects/libs come w/ gcc 2.7.2 for AXP:
1396 $   tmp = F$SEARCH("GNU_CC:[000000]libgcc2.olb")
1397 $   IF tmp .NES. "" then gcclib_olb = tmp
1398 $   tmp = F$SEARCH("GNU_CC:[000000]libgcclib.olb")
1399 $   IF tmp .NES. "" 
1400 $   THEN 
1401 $     IF gcclib_olb .EQS. "" 
1402 $     THEN gcclib_olb = tmp
1403 $     ELSE gcclib_olb = gcclib_olb + "/lib," + tmp
1404 $     ENDIF
1405 $   ENDIF
1406 $   tmp = F$SEARCH("SYS$LIBRARY:VAXCRTL.OLB")
1407 $   IF tmp .NES. "" 
1408 $   THEN 
1409 $     IF gcclib_olb .EQS. "" 
1410 $     THEN gcclib_olb = tmp
1411 $     ELSE gcclib_olb = gcclib_olb + "/lib," + tmp
1412 $     ENDIF
1413 $   ENDIF
1414 $   tmp = F$SEARCH("GNU_CC:[000000]crt0.obj")
1415 $   IF tmp .NES. "" 
1416 $   THEN 
1417 $     IF gcclib_olb .EQS. "" 
1418 $     THEN gcclib_olb = tmp
1419 $     ELSE gcclib_olb = gcclib_olb + "/lib," + tmp
1420 $     ENDIF
1421 $   ENDIF
1422 $   IF gcclib_olb .EQS. vaxcrtl_olb THEN gcclib_olb = "" !goofy order of axplibs
1423 $ ELSE
1424 $   gcclib_olb = gcclib_olb + "/lib"
1425 $ ENDIF
1426 $ IF   gcclib_olb .NES. "" .AND. -
1427      (vaxcrtl_olb .NES. "" .OR. -
1428       vaxcrtl_exe .NES. "" )
1429 $ THEN
1430 $   echo ""
1431 $   echo4 "Checking for GNU cc in disguise and/or its version number..." !>&4
1432 $   OPEN/WRITE CONFIG gccvers.c
1433 $   WRITE CONFIG "#include <stdlib.h>"  !DECC is sooo picky
1434 $   WRITE CONFIG "#include <stdio.h>"
1435 $   WRITE CONFIG "int main() {"
1436 $   WRITE CONFIG "#ifdef __GNUC__"
1437 $   WRITE CONFIG "#ifdef __VERSION__"
1438 $   WRITE CONFIG "        printf(""%s\n"", __VERSION__);"
1439 $   WRITE CONFIG "#else"
1440 $   WRITE CONFIG "        printf(""%s\n"", ""1"");"
1441 $   WRITE CONFIG "#endif"
1442 $   WRITE CONFIG "#endif"
1443 $   WRITE CONFIG "        exit(0);"
1444 $   WRITE CONFIG "}"
1445 $   CLOSE CONFIG
1446 $   DEFINE SYS$ERROR _NLA0:
1447 $   DEFINE SYS$OUTPUT _NLA0:
1448 $   'Mcc' gccvers.c
1449 $   tmp = $status
1450 $   DEASSIGN SYS$ERROR _NLA0:
1451 $   DEASSIGN SYS$OUTPUT _NLA0:
1452 $   IF (silent) THEN GOSUB Shut_up
1453 $   DEFINE SYS$ERROR _NLA0:
1454 $   DEFINE SYS$OUTPUT _NLA0:
1455 $   IF vaxcrtl_exe .EQS. ""
1456 $   THEN 
1457 $     IF F$LOCATE("VAXCRTL",gcclib_olb).NE.F$LENGTH(gcclib_olb)
1458 $     THEN 
1459 $       link gccvers.obj,'gcclib_olb',SYS$LIBRARY:VAXCRTL/Library
1460 $       tmp = $status
1461 $     ELSE
1462 $       link gccvers.obj,'gcclib_olb'
1463 $       tmp = $status
1464 $     ENDIF
1465 $   ELSE
1466 $     OPEN/WRITE CONFIG GCCVERS.OPT
1467 $     WRITE CONFIG "SYS$SHARE:VAXCRTL/SHARE"
1468 $     CLOSE CONFIG
1469 $     link gccvers.obj,GCCVERS.OPT/OPT,'gcclib_olb'
1470 $     tmp = $status
1471 $   ENDIF
1472 $   DEASSIGN SYS$ERROR
1473 $   DEASSIGN SYS$OUTPUT
1474 $   IF (silent) THEN GOSUB Shut_up
1475 $   OPEN/WRITE CONFIG gccvers.out
1476 $   DEFINE SYS$ERROR CONFIG
1477 $   DEFINE SYS$OUTPUT CONFIG
1478 $   mcr []gccvers.exe
1479 $   tmp = $status
1480 $   CLOSE CONFIG
1481 $   DEASSIGN SYS$OUTPUT
1482 $   DEASSIGN SYS$ERROR
1483 $   IF (silent) THEN GOSUB Shut_up
1484 $   OPEN/READ CONFIG gccvers.out
1485 $   READ/END_OF_FILE=Gcc_cleanup CONFIG line
1486 $Gcc_cleanup:
1487 $   CLOSE CONFIG
1488 $   DELETE/NOLOG/NOCONFIRM gccvers.*;
1489 $   IF F$LOCATE("GNU C version ",line).NE.F$LENGTH(line)
1490 $   THEN 
1491 $     echo "You are not using GNU cc."
1492 $     GOTO Host_name
1493 $   ELSE 
1494 $     echo "You are using GNU cc ''line'"
1495 $     Using_Gnu_C = "Yes"
1496 $     C_COMPILER_Replace = "CC=cc=''Mcc'"
1497 $     GOTO Include_dirs
1498 $   ENDIF
1499 $ ENDIF
1500 $endif
1501 $ GOTO Host_name
1502 $!
1503 $List_Parse:
1504 $ OPEN/READ CONFIG ccvms.lis
1505 $ READ CONFIG line
1506 $ IF (F$GETSYI("HW_MODEL") .LT. 1024)
1507 $ THEN
1508 $   read CONFIG line
1509 $   archsufx = "VAX"
1510 $ ELSE
1511 $   archsufx = "AXP"
1512 $ ENDIF
1513 $ CLOSE CONFIG
1514 $ line = F$EDIT(line,"TRIM,COMPRESS")
1515 $ line = line - "Page 1"           ! occurs at end all compilers
1516 $ line = line - "CCVMS "           ! filename appears w/ VAXC
1517 $ line = line - "Source Listing "  ! Seen w/ AXP DECC
1518 $ tmp = F$EXTRACT(0,20,line)       !timestamp, e.g. "30-JUL-1996 21:12:54 "
1519 $ line = line - tmp
1520 $ line = F$EDIT(line,"TRIM")       !bit redundant but we're in no big hurry
1521 $ DELETE/NOLOG/NOCONFIRM ccvms.lis;
1522 $ RETURN
1523 $!
1524 $Include_dirs:
1525 $!: What should the include directory be ?
1526 $ dflt = gcclib_olb 
1527 $ rp = "Where are the include files you want to use? "
1528 $ IF f$length( rp + "[''dflt'] " ).gt.76
1529 $ THEN rp = F$FAO("!AS!/!AS",rp,"[''dflt'] ")
1530 $ ELSE rp = rp + "[''dflt'] "
1531 $ ENDIF
1532 $ GOSUB myread
1533 $ usrinc = ans
1534 $!
1535 $!: see if we have to deal with yellow pages, now NIS.
1536 $!: now get the host name
1537 $Host_name:
1538 $ echo ""
1539 $ echo4 "Figuring out host name..." !>&4
1540 $ myhostname = ""
1541 $  IF myhostname.eqs."" THEN myhostname = F$TRNLNM("ARPANET_HOST_NAME")
1542 $  IF myhostname.eqs."" THEN myhostname = F$TRNLNM("INTERNET_HOST_NAME")
1543 $  IF myhostname.eqs."" THEN myhostname = F$TRNLNM("MULTINET_HOST_NAME")
1544 $  IF myhostname.eqs."" THEN myhostname = F$TRNLNM("UCX$INET_HOST_NAME")
1545 $  IF myhostname.eqs."".and. -
1546       F$TRNLNM("UCX$INET_HOST") .nes. "" .and. -
1547       F$TRNLNM("UCX$INET_DOMAIN") .nes. "" THEN - 
1548      myhostname = F$TRNLNM("UCX$INET_HOST") + "." + F$TRNLNM("UCX$INET_DOMAIN") 
1549 $  IF myhostname.eqs."" THEN myhostname = F$TRNLNM("TCPWARE_DOMAINNAME")
1550 $  IF myhostname.eqs."" THEN myhostname = F$TRNLNM("NEWS_ADDRESS")
1551 $  IF myhostname.eqs."" THEN myhostname = F$TRNLNM("SYS$NODE") - "::"
1552 $  IF myhostname.eqs."" THEN myhostname = F$EDIT(F$GETSYI("SCSNODE"),"TRIM")
1553 $!: you do not want to know about this
1554 $!: verify guess
1555 $ rp = "Your host name appears to be """"''myhostname'"""". Right? "
1556 $ GOSUB myread
1557 $ IF (.not.ans).and.(ans.NES."")
1558 $   THEN 
1559 $     READ SYS$COMMAND/PROMPT= - 
1560  "Please type the (one word) name of your host: " ans
1561 $     myhostname = ans
1562 $ ENDIF
1563 $!: translate upper to lower if necessary
1564 $ myhostname = F$EDIT(myhostname,"COLLAPSE")
1565 $ mylowhostname = F$EDIT(myhostname," LOWERCASE")
1566 $ IF mylowhostname.NES.myhostname
1567 $ THEN
1568 $   echo "(Normalizing case in your host name)"
1569 $   myhostname = mylowhostname
1570 $ ENDIF
1571 $!
1572 $ fp = F$LOCATE(".",myhostname)
1573 $ mydomain = F$EXTRACT(fp,(F$LENGTH(myhostname)-fp)+1,myhostname)
1574 $ IF mydomain.NES.""  !no periods in DECnet names like "MYDECNODE::"
1575 $ THEN
1576 $   rp = "What is your domain name? [''mydomain'] "
1577 $   GOSUB myread
1578 $   IF ans .nes. "" THEN mydomain = ans
1579 $!: translate upper to lower if necessary
1580 $   mydomain = F$EDIT(mydomain,"COLLAPSE")
1581 $   mylowdomain = F$EDIT(mydomain," LOWERCASE")
1582 $   IF mylowdomain.NES.mydomain
1583 $   THEN
1584 $     echo "(Normalizing case in your domain name)"
1585 $     mydomain = mylowdomain
1586 $   ENDIF
1587 $ ENDIF
1588 $ myhostname = myhostname - mydomain
1589 $ echo "(Trimming domain name from host name--host name is now ''myhostname')"
1590 $ IF .NOT.silent 
1591 $ THEN TYPE SYS$INPUT:
1592
1593 I need to get your e-mail address in Internet format if possible, i.e.
1594 something like user@host.domain. Please answer accurately since I have
1595 no easy means to double check it. The default value provided below
1596 is most probably close to the reality but may not be valid from outside
1597 your organization...
1598 $ ENDIF
1599 $ dflt = "''cf_by'@''myhostname'"+"''mydomain'"
1600 $ rp = "What is your e-mail address? [''dflt'] "
1601 $ GOSUB myread
1602 $ IF ans .nes. ""
1603 $ THEN cf_email = ans
1604 $ ELSE cf_email = dflt
1605 $ ENDIF
1606 $!
1607 $ IF .NOT.silent 
1608 $ THEN TYPE SYS$INPUT:
1609
1610 If you or somebody else will be maintaining perl at your site, please
1611 fill in the correct e-mail address here so that they may be contacted
1612 if necessary. Currently, the "perlbug" program included with perl
1613 will send mail to this address in addition to perlbug@perl.com. You may
1614 enter "none" for no administrator.
1615 $ ENDIF
1616 $ dflt = "''cf_email'"
1617 $ rp = "Perl administrator e-mail address [''dflt'] "
1618 $ GOSUB myread
1619 $ IF ans .nes. ""
1620 $ THEN perladmin = ans
1621 $ ELSE perladmin = dflt
1622 $ ENDIF
1623 $!
1624 $!: determine where public executable scripts go
1625 $!: determine perl absolute location
1626 $!: figure out how to guarantee perl startup
1627 $!
1628 $!: see how we invoke the C preprocessor
1629 $! echo ""
1630 $! echo4 "Now, how can we feed standard input to your C preprocessor..." !>&4
1631 $!: Set private lib path
1632 $!: Now check and see which directories actually exist, avoiding duplicates
1633 $!: determine optimize, if desired, or use for debug flag also
1634 $!: We will not override a previous value, but we might want to
1635 $!: augment a hint file
1636 $!: the following weeds options from ccflags that are of no interest to cpp
1637 $!: flags used in final linking phase
1638 $!: Try to guess additional flags to pick up local libraries.
1639 $!: coherency check
1640 $! echo ""
1641 $! echo4 "Checking your choice of C compiler and flags for coherency..." !>&4
1642 $!: compute shared library extension
1643 $!: Looking for optional libraries
1644 $!: see if nm is to be used to determine whether a symbol is defined or not
1645 $!: get list of predefined functions in a handy place
1646 $!: see if we have sigaction
1647 $!: see whether socketshr exists
1648 $ IF (F$SEARCH(F$PARSE("SocketShr","Sys$Share:.Exe")).NES."")
1649 $ THEN
1650 $   has_socketshr     = "T"
1651 $   echo ""
1652 $   echo4 "Hmm... Looks like you have SOCKETSHR's Berkeley networking support."
1653 $ endif
1654 $ if (Dec_C_Version .ge. 50200000)
1655 $ THEN
1656 $   Has_Dec_C_Sockets = "T"
1657 $   echo ""
1658 $   echo4 "Hmm... Looks like you've got Dec C's Berkeley networking support."
1659 $ ENDIF
1660 $ ! Hey, we've got both. Default to Dec C, then, since it's better
1661 $ if ("''Has_socketshr'".eq."T") .or.("''has_dec_c_sockets'".eq."T")
1662 $ THEN
1663 $   echo ""
1664 $   echo "You've got sockets available. Which socket stack do you want to"
1665 $   echo "build into perl?"
1666 $   if "''has_dec_c_sockets'".eqs."T"
1667 $   THEN
1668 $     dflt = "DECC"
1669 $   else
1670 $     dflt = "SOCKETSHR"
1671 $   endif
1672 $   rp = "Choose socket stack (NONE"
1673 $   if "''has_socketshr'".eqs."T" THEN rp = rp + ",SOCKETSHR"
1674 $   if "''has_dec_c_sockets'".eqs."T" THEN rp = rp + ",DECC"
1675 $   rp = rp + ") [''dflt'] "
1676 $   GOSUB myread
1677 $   IF "''ans'".eqs."" THEN ans = "''dflt'"
1678 $   has_dec_c_sockets = "F"
1679 $   has_socketshr = "F"
1680 $   ans = F$EDIT(ans,"TRIM,COMPRESS,LOWERCASE")
1681 $   IF ans.eqs."decc" then has_dec_c_sockets = "T"
1682 $   IF ans.eqs."socketshr" then has_socketshr = "T"
1683 $ endif
1684 $!
1685 $!
1686 $! Ask if they want to build with VMS_DEBUG perl
1687 $ echo ""
1688 $ echo "Perl can be built to run under the VMS debugger."
1689 $ echo "You should only select this option if you are debugging"
1690 $ echo "perl itself.  This can be a useful feature if you are "
1691 $ echo "embedding perl in a program."
1692 $ dflt = "n"
1693 $ rp = "Build a VMS-DEBUG version of Perl? [''dflt'] "
1694 $ GOSUB myread
1695 $ IF ans.eqs."" then ans = dflt
1696 $ IF F$EXTRACT(0, 1, F$EDIT(ans,"COLLAPSE,UPCASE")) .eqs. "Y"
1697 $ THEN
1698 $   use_vmsdebug_perl = "Y"
1699 $   macros = macros + """__DEBUG__=1"","
1700 $ ELSE
1701 $   use_vmsdebug_perl = "N"
1702 $ ENDIF
1703 $!
1704 $! Ask if they want to build with MULTIPLICITY
1705 $ echo ""
1706 $ echo "The perl interpreter engine can be built in a way that makes it
1707 $ echo "possible for a program that embeds perl into it (and yes, you can
1708 $ echo "do that--it's pretty keen) to have multiple perl interpreters active
1709 $ echo "at once. There is some performance overhead, however, so you
1710 $ echo "probably don't want to choose this unless you're going to be doing
1711 $ echo "funky perl embedding."
1712 $ dflt = "n"
1713 $ rp = "Build with MULTIPLICITY? [''dflt'] "
1714 $ GOSUB myread
1715 $ if ans.eqs."" then ans = dflt
1716 $ IF F$EXTRACT(0, 1, F$EDIT(ans,"COLLAPSE,UPCASE")) .eqs. "Y"
1717 $ THEN
1718 $   use_multiplicity="Y"
1719 $ ELSE
1720 $   use_multiplicity="N"
1721 $ ENDIF
1722 $!
1723 $! Ask if they want to build with 64-bit support
1724 $ IF (Archname.eqs."VMS_AXP").and.("''f$extract(1,3, f$getsyi(""version""))'".ges."7.1")
1725 $ THEN
1726 $   dflt = use64bitint
1727 $   echo ""
1728 $   echo "You can have native 64-bit long integers.
1729 $   echo ""
1730 $   echo "Perl can be built to take advantage of 64-bit integer types
1731 $   echo "on some systems, which provide a much larger range for perl's 
1732 $   echo "mathematical operations.  (Note that does *not* enable 64-bit 
1733 $   echo "fileops at the moment, as Dec C doesn't do that yet)."
1734 $   echo "Choosing this option will most probably introduce binary incompatibilities.
1735 $   echo ""
1736 $   echo "If this doesn't make any sense to you, just accept the default ''dflt'.
1737 $   rp = "Try to use 64-bit integers, if available? [''dflt'] "
1738 $   GOSUB myread
1739 $   IF ans .EQS. "" THEN ans = dflt
1740 $   IF (f$extract(0, 1, f$edit(ans,"COLLAPSE,UPCASE")) .EQS. "Y")
1741 $   THEN
1742 $     use64bitint="Y"
1743 $   ELSE
1744 $     use64bitint="N"
1745 $   ENDIF
1746 $   IF (use64bitint)
1747 $   THEN
1748 $     dflt = use64bitall
1749 $     echo ""
1750 $     echo "Since you chose 64-bitness you may want to try maximal 64-bitness.
1751 $     echo "What you have chosen is minimal 64-bitness which means just enough
1752 $     echo "to get 64-bit integers.  The maximal means using as much 64-bitness
1753 $     echo "as is possible on the platform.  This in turn means even more binary
1754 $     echo "incompatibilities.  On the other hand, your platform may not have
1755 $     echo "any more maximal 64-bitness than what you already have chosen.
1756 $     echo ""
1757 $     echo "If this doesn't make any sense to you, just accept the default ''dflt'.
1758 $     rp = "Try to use full 64-bit support, if available? [''dflt'] "
1759 $     GOSUB myread
1760 $     IF ans .EQS. "" THEN ans = dflt
1761 $     IF (f$extract(0, 1, f$edit(ans,"COLLAPSE,UPCASE")) .EQS. "Y")
1762 $     THEN
1763 $       use64bitall="Y"
1764 $     ELSE
1765 $       use64bitall="N"
1766 $     ENDIF
1767 $   ENDIF
1768 $ ENDIF ! AXP && >= 7.1
1769 $!
1770 $! Ask about threads, if appropriate
1771 $ if (Using_Dec_C.eqs."Yes")
1772 $ THEN
1773 $   echo ""
1774 $   echo "This version of Perl can be built with threads. While really nifty,
1775 $   echo "they are a beta feature, and there is a speed penalty for perl
1776 $   echo "programs if you build with threads *even if you don't use them*
1777 $   dflt = "n"
1778 $   rp = "Build with threads? [''dflt'] "
1779 $   GOSUB myread
1780 $   if ans.eqs."" then ans = dflt
1781 $   if (f$extract(0, 1, "''ans'").eqs."Y").or.(f$extract(0, 1, "''ans'").eqs."y")
1782 $   THEN
1783 $     use_threads="T"
1784 $!
1785 $     ! Shall we do the 5.005-stype threads, or IThreads?
1786 $     echo "As of 5.5.640, Perl has two different internal threading
1787 $     echo "implementations, the 5.005 version (5005threads) and an
1788 $     echo "interpreter-based version (ithreads) that has one
1789 $     echo "interpreter per thread.  Both are very experimental.  This
1790 $     echo "arrangement exists to help developers work out which one
1791 $     echo "is better.
1792 $     echo "
1793 $     echo "If you're a casual user, you probably don't want
1794 $     echo "interpreter-threads at this time.  There doesn't yet exist
1795 $     echo "a way to create threads from within Perl in this model,
1796 $     echo "i.e., ""use Thread;"" will NOT work.
1797 $     echo "
1798 $     dflt = "n"
1799 $     rp = "Build with Interpreter threads? [''dflt']
1800 $     GOSUB myread
1801 $     if ans.eqs."" then ans = dflt
1802 $     if (f$extract(0, 1, "''ans'").eqs."Y").or.(f$extract(0, 1, "''ans'").eqs."y")
1803 $     THEN
1804 $       use_ithreads="Y"
1805 $       use_5005_threads="N"
1806 $     ELSE
1807 $       use_ithreads="N"
1808 $       use_5005_threads="Y"
1809 $     ENDIF
1810 $     ! Are they on VMS 7.1 on an alpha?
1811 $     if (Archname.eqs."VMS_AXP").and.("''f$extract(1,3, f$getsyi(""version""))'".ges."7.1")
1812 $     THEN
1813 $       echo ""
1814 $       echo "Threaded perl can be linked to use multiple kernel threads
1815 $       echo "and system upcalls on VMS 7.1+ on Alpha systems. This feature
1816 $       echo "allows multiple threads to execute simultaneously on an SMP
1817 $       echo "system as well as preventing a single thread from blocking
1818 $       echo "all the threads in a program, even on a single-processor
1819 $       echo "machine. Unfortunately this feature isn't safe on an
1820 $       echo "unpatched 7.1 system. (Several OS patches were required when
1821 $       echo "this procedure was written)
1822 $       dflt = "n"
1823 $       rp = "Enable multiple kernel threads and upcalls? [''dflt'] "
1824 $       gosub myread
1825 $       if ans.eqs."" then ans="''dflt'"
1826 $       if f$extract(0, 1, f$edit(ans,"TRIM,COMPRESS,UPCASE")).eqs."Y"
1827 $       THEN
1828 $         Thread_Live_Dangerously = "MT=MT=1"
1829 $       ENDIF
1830 $     ENDIF
1831 $   ENDIF
1832 $ ENDIF
1833 $ if archname .eqs. "VMS_AXP"
1834 $ then
1835 $!
1836 $! Case sensitive?
1837 $ echo ""
1838 $ echo "By default, perl (and pretty much everything else on VMS) uses
1839 $ echo "case-insensitive linker symbols. Which is to say, when the
1840 $ echo "underlying C code makes a call to a routine called Perl_foo in
1841 $ echo "the source, the name in the object modules or shareable images
1842 $ echo "is really PERL_FOO. There are some packages that use an
1843 $ echo "embedded perl interpreter that instead require case-sensitive
1844 $ echo "linker symbols.
1845 $ echo ""
1846 $ echo "If you have no idea what this means, and don't have
1847 $ echo "any program requiring anything, choose the default.
1848 $ dflt = be_case_sensitive
1849 $ rp = "Case-sensitive symbols [''dflt'] "
1850 $ gosub myread
1851 $ if ans.eqs."" then ans="''dflt'"
1852 $ be_case_sensitive = "''ans'"
1853 $!
1854 $! IEEE math?
1855 $ echo ""
1856 $ echo "Perl normally uses G_FLOAT format floating point numbers
1857 $ echo "internally, as do most things on VMS. You can, however, build
1858 $ echo "with IEEE floating point numbers instead if you need to.
1859 $ dflt = use_ieee_math
1860 $ rp = "Use IEEE math [''dflt'] "
1861 $ gosub myread
1862 $ if ans.eqs."" then ans="''dflt'"
1863 $ use_ieee_math = "''ans'"
1864 $ endif
1865 $! CC Flags
1866 $ echo ""
1867 $ echo "You can, if you need to, pass extra flags on to the C
1868 $ echo "compiler. In general you should only do this if you really,
1869 $ echo "really know what you're doing.
1870 $ dflt = user_c_flags
1871 $ rp = "Extra C flags [''dflt'] "
1872 $ gosub myread
1873 $ if ans.eqs."" then ans="''dflt'"
1874 $ user_c_flags = "''ans'"
1875 $!
1876 $! Ask whether they want to use secure logical translation when tainting
1877 $ echo ""
1878 $ echo "As Perl starts up, it checks several logical names, such as"
1879 $ echo "PERL5LIB and PERL_ENV_TABLES, which allow you to modify aspects"
1880 $ echo "of its behavior.  For additional security, you may limit this"
1881 $ echo "process to executive- and kernel-mode translation when tainting"
1882 $ echo "is enabled.  In this case, logical names normally skipped when"
1883 $ echo "tainting is enabled (e.g. PERL5OPTS) are translated as well."
1884 $ echo "If you do not choose to do this, the usual order of access modes"
1885 $ echo "is used for logical name translation."
1886 $ echo ""
1887 $ echo "This restriction does not apply to the %ENV hash or to implicit"
1888 $ echo "logical name translation during parsing of file specifications;"
1889 $ echo "these always use the normal sequence of access modes for logical"
1890 $ echo "name translation."
1891 $ dflt = "y"
1892 $ rp = "Use secure logical name translation? [''dflt'] "
1893 $ GOSUB myread
1894 $ if ans.eqs."" then ans="''dflt'"
1895 $ d_secintgenv = f$extract(0, 1, f$edit(ans,"TRIM,COMPRESS,UPCASE"))
1896 $!
1897 $! Ask whether they want to default filetypes
1898 $ echo ""
1899 $ echo "When you pass the name of a program to Perl on the command line,"
1900 $ echo "it generally doesn't supply any defaults unless the -S command"
1901 $ echo "line switch is specified.  In keeping with the VMS tradition of"
1902 $ echo "default file types, however, you can configure Perl to try default"
1903 $ echo "file types of nothing, .pl, and .com, in that order (e.g. typing"
1904 $ echo """$ perl foo"" would cause Perl to look for foo., then foo.pl, and"
1905 $ echo "finally foo.com)."
1906 $ dflt = "n"
1907 $ rp = "Always use default file types? [''dflt'] "
1908 $ GOSUB myread
1909 $ if ans.eqs."" then ans="''dflt'"
1910 $ d_alwdeftype = f$extract(0, 1, f$edit(ans,"COLLAPSE,UPCASE"))
1911 $!
1912 $! Ask if they want to use perl's memory allocator
1913 $ echo ""
1914 $ echo "Perl has a built-in memory allocator that's tuned for perl's
1915 $ echo "normal memory usage. It's oftentimes better than the standard
1916 $ echo "system memory allocator. It also has the advantage of providing
1917 $ echo "memory allocation statistics, if you choose to enable them.
1918 $ dflt = "n"
1919 $ rp = "Build with perl's memory allocator? [''dflt'] "
1920 $ GOSUB myread
1921 $ if ans.eqs."" then ans="''dflt'"
1922 $ mymalloc = f$extract(0, 1, f$edit(ans,"COLLAPSE,UPCASE"))
1923 $ if mymalloc.eqs."Y"
1924 $ THEN
1925 $   if use_debugging_perl.eqs."Y"
1926 $   THEN
1927 $     echo ""
1928 $     echo "Perl can keep statistics on memory usage if you choose to use
1929 $     echo "them. This is useful for debugging, but does have some
1930 $     echo "performance overhead.
1931 $     dflt = "n"
1932 $     rp = "Do you want the debugging memory allocator? [''dflt'] "
1933 $     gosub myread
1934 $     if ans.eqs."" then ans="''dflt'"
1935 $     use_debugmalloc = f$extract(0, 1, f$edit(ans, "COLLAPSE,UPCASE"))
1936 $   ENDIF
1937 $   ! Check which memory allocator we want
1938 $   echo ""
1939 $   echo "There are currently three different memory allocators: the
1940 $   echo "default (which is a pretty good general-purpose memory manager),
1941 $   echo "the TWO_POT allocator (which is optimized to save memory for
1942 $   echo "larger allocations), and PACK_MALLOC (which is optimized to save
1943 $   echo "memory for smaller allocations). They're all good, but if your
1944 $   echo "usage tends towards larger chunks use TWO_POT, otherwise use
1945 $   echo "PACK_MALLOC."
1946 $   dflt = "DEFAULT"
1947 $   rp = "Memory allocator (DEFAULT, TWO_POT, PACK_MALLOC) [''dflt'] "
1948 $   GOSUB myread
1949 $   if ans.eqs."" then ans = "''dflt'"
1950 $   if ans.eqs."TWO_POT" then use_two_pot_malloc = "Y"
1951 $   if ans.eqs."PACK_MALLOC" then use_pack_malloc = "Y"
1952 $ ENDIF
1953 $!
1954 $! Ask for their default list of extensions to build
1955 $ echo ""
1956 $ echo "It's time to specify which modules you want to build into
1957 $ echo "perl. Most of these are standard and should be chosen, though
1958 $ echo "you might, for example, want to build GDBM_File instead of
1959 $ echo "SDBM_File if you have the GDBM library built on your machine.
1960 $ echo "Whatever you do, make sure the re module is first or things will
1961 $ echo "break badly"
1962 $ echo "
1963 $ echo "Which modules do you want to build into perl?"
1964 $! dflt = "Fcntl Errno File::Glob IO Opcode Byteloader Devel::Peek Devel::DProf Data::Dumper attrs re VMS::Stdio VMS::DCLsym B SDBM_File"
1965 $ dflt = "re Fcntl Errno File::Glob IO Opcode Devel::Peek Devel::DProf Data::Dumper attrs VMS::Stdio VMS::DCLsym B SDBM_File Thread Sys::Hostname"
1966 $ if Using_Dec_C.eqs."Yes"
1967 $ THEN
1968 $   dflt = dflt + " POSIX"
1969 $ ENDIF
1970 $ rp = "[''dflt'] "
1971 $ GOSUB myread
1972 $ if ans.eqs."" then ans = "''dflt'"
1973 $ a = ""
1974 $ j = 0
1975 $ xloop1:
1976 $   x = f$elem(j," ",ans)
1977 $   j = j + 1
1978 $   if x .eqs. " " then goto exloop1
1979 $   xloop2:
1980 $       k = f$locate("::",x)
1981 $       if k .ge. f$len(x) then goto exloop2
1982 $       x = f$extract(0,k,x) + "/" + f$extract(k+2,f$len(x)-2,x)
1983 $   goto xloop2
1984 $   exloop2:
1985 $   a = a + " " + x
1986 $ goto xloop1
1987 $ exloop1:
1988 $ ans = f$edit(a,"trim")
1989 $!
1990 $ a = ""
1991 $ j = 0
1992 $ xloop3:
1993 $   x = f$elem(j," ",dflt)
1994 $   j = j + 1
1995 $   if x .eqs. " " then goto exloop3
1996 $   xloop4:
1997 $       k = f$locate("::",x)
1998 $       if k .ge. f$len(x) then goto exloop4
1999 $       x = f$extract(0,k,x) + "/" + f$extract(k+2,f$len(x)-2,x)
2000 $   goto xloop4
2001 $   exloop4:
2002 $   a = a + " " + x
2003 $ goto xloop3
2004 $ exloop3:
2005 $ dflt = f$edit(a,"trim")
2006 $!
2007 $ extensions = "''ans'"
2008 $ perl_known_extensions = "''dflt'"
2009 $!
2010 $! %Config-I-VMS, determine build/make utility here (make gmake mmk mms)
2011 $ echo ""
2012 $ echo "%Config-I-VMS, Checking your ""make"" utilities..."
2013 $! If the 'build' that you use is not here add it and it's test
2014 $! switch to the _END_ of these strings (and increment max_build)
2015 $! (e.g. builders = builders + "/FOOMAKE" 
2016 $!       probers  = probers + " -fooVersionSwitch"
2017 $! ) & please let me know about it.
2018 $ builders = "IMAKE/GNUMAKE/MGMAKE/GMAKE/MAKE/MMS/MMK"
2019 $ probers  = "-f Makefile. -v!-f Makefile. -v!-f Makefile. -v!-f Makefile. -v!-f Makefile. -v!/IDENT!/IDENT"
2020 $ max_build = 7
2021 $!
2022 $ orig_dflt = "MMK"
2023 $ default_set = ""
2024 $ ok_builders = ""
2025 $ OPEN/WRITE/ERROR=Open_error CONFIG Makefile.
2026 $ WRITE CONFIG "dont_make_anything_yet:"
2027 $ WRITE CONFIG F$FAO("!_")
2028 $ CLOSE CONFIG
2029 $ n = 0
2030 $ messages = F$ENVIRONMENT("MESSAGE")
2031 $Build_probe:
2032 $ build = F$ELEMENT(n,"/",builders)
2033 $ probe  = F$ELEMENT(n,"!",probers)
2034 $ echo "Testing whether you have ''build' on your system..."
2035 $ SET NOON
2036 $ ON CONTROL_Y THEN GOTO Reenable_messages_build
2037 $ SET MESSAGE/NOFAC/NOSEV/NOIDENT/NOTEXT
2038 $ 'build' 'probe'
2039 $ IF ($SEVERITY .EQ. 1)
2040 $ THEN 
2041 $   echo "OK."
2042 $   IF (build .EQS. orig_dflt) 
2043 $   THEN 
2044 $     default_set = "TRUE"
2045 $     dflt = build
2046 $   ENDIF
2047 $   ok_builders = ok_builders + " " + build
2048 $   IF (.NOT. default_set) THEN dflt = build
2049 $ ELSE 
2050 $   echo "Nope."
2051 $ ENDIF
2052 $Reenable_messages_build:
2053 $ SET MESSAGE 'messages'
2054 $ SET ON
2055 $ n = n + 1
2056 $ IF (n .LT. max_build) THEN GOTO Build_probe
2057 $!
2058 $ echo ""
2059 $ IF (ok_builders .NES. "") 
2060 $ THEN
2061 $   echo "Here is the list of builders you can apparently use:"
2062 $   echo "(",ok_builders," )"
2063 $   rp = "Which """"make"""" utility do you wish to use [''dflt']? "
2064 $   GOSUB myread
2065 $   ans = F$EDIT(ans,"TRIM, COMPRESS")
2066 $   ans = F$EXTRACT(0,F$LOCATE(" ",ans),ans) !throw out "-f Makefile." here
2067 $   IF (ans .EQS. "") 
2068 $   THEN build = dflt
2069 $   ELSE build = ans
2070 $   ENDIF
2071 $ ELSE
2072 $   TYPE SYS$INPUT:
2073
2074 %Config-E-VMS, ERROR:
2075  Well this looks pretty serious. Perl5 cannot be compiled without a "make"
2076  utility of some sort and after checking my "builders" list I cannot find
2077  the symbol or command you use on your system to compile programs.
2078
2079 $   READ SYS$COMMAND/PROMPT="%Config-I-VMS, Which ""MMS"" do you use? " ans
2080 $   ans = F$EDIT(ans,"TRIM, COMPRESS")
2081 $   ans = F$EXTRACT(0,F$LOCATE(" ",ans),ans) !throw out "-f Makefile." here
2082 $   IF (ans .EQS. "") 
2083 $   THEN build = dflt
2084 $     echo "I don't know where 'make' is, and my life depends on it."
2085 $     echo "Go find a make program or fix your DCL$PATH setting!"
2086 $     echo "ABORTING..."
2087 $     SET DEFAULT 'vms_default_directory_name' !be kind rewind
2088 $     STOP
2089 $     EXIT 2 !$STATUS = "%X00000002" (error)
2090 $   ELSE 
2091 $     build = ans
2092 $   ENDIF
2093 $ ENDIF
2094 $!
2095 $ DELETE/NOLOG Makefile.;
2096 $ GOTO Beyond_open
2097 $Open_error:
2098 $ TYPE SYS$INPUT:
2099
2100  There seems to be trouble. I just tried to create a file in
2101 $ echo4 'F$ENVIRONMENT("DEFAULT")'
2102 $ TYPE SYS$INPUT:
2103  but was unsuccessful. I am stopping now. Please check that directories'
2104  PROTECTION bits. I will leave you in the directory where you started
2105  Configure.com
2106 $ echo4 "ABORTING..."
2107 $ GOTO Clean_up
2108 $ STOP
2109 $ EXIT
2110 $!
2111 $Beyond_open:
2112 $! echo " Very well I will proceed with ""''build'"""
2113 $ make = F$EDIT(build,"UPCASE")
2114 $!
2115 $!: locate the preferred pager for this system
2116 $!pagers = "most|more|less|type/page"
2117 $!rp='What pager is used on your system?'
2118 $!
2119 $! update [.vms]config.vms here
2120 $!
2121 $! update makefile here
2122 $! echo4 "Updating makefile..."
2123 $!
2124 $ IF (make .EQS. "MMS").OR.(make .EQS. "MMK")
2125 $ THEN 
2126 $   makefile    = ""             !wrt MANIFEST dir
2127 $   UUmakefile  = "DESCRIP.MMS"  !wrt CWD dir
2128 $   DEFmakefile = "DESCRIP.MMS"  !wrt DEF dir (?)
2129 $ ELSE
2130 $   makefile    = " -f [.VMS]Makefile." !wrt MANIFEST dir
2131 $   UUmakefile  = "[-.VMS]Makefile."    !wrt CWD dir
2132 $   DEFmakefile = "[-.VMS]Makefile."    !wrt DEF dir (?)
2133 $ ENDIF
2134 $!
2135 $ IF macros.NES."" 
2136 $ THEN 
2137 $   tmp = F$LENGTH(macros)
2138 $   macros = F$EXTRACT(0,(tmp-1),macros) !miss trailing comma
2139 $   macros = "/macro=(" + macros  + ")"
2140 $ ENDIF
2141 $! Build up the extra C flags
2142 $!
2143 $ if use_ieee_math
2144 $ then
2145 $   extra_flags = "''extra_flags'" + "/float=ieee/ieee=denorm_results"
2146 $ endif
2147 $ if be_case_sensitive
2148 $ then
2149 $   extra_flags = "''extra_flags'" + "/Names=As_Is"
2150 $ endif
2151 $ extra_flags = "''extra_flags'" + "''user_c_flags'"
2152 $!
2153 $! Invoke the subconfig piece
2154 $!
2155 $ echo ""
2156 $ echo4 "Checking the C run-time library"
2157 $ dflt = F$ENVIRONMENT("DEFAULT")
2158 $ SET DEFAULT [-.vms]
2159 $ @subconfigure
2160 $ SET DEFAULT 'dflt
2161 $!
2162 $!  Warn of dangerous symbols or logical names
2163 $!
2164 $Bad_environment: SUBROUTINE
2165 $   Bad_env = ""
2166 $   IF p2 .eqs. "SYMBOL"
2167 $   THEN
2168 $     IF f$type('p1) .nes. "" THEN  Bad_env := SYMBOL
2169 $   ELSE
2170 $     IF f$trnlnm(p1) .nes. "" THEN Bad_env := LOGICAL
2171 $   ENDIF
2172 $   IF Bad_env .eqs. "SYMBOL" .or. Bad_env .eqs. "LOGICAL"
2173 $   THEN
2174 $     IF f$search("config.msg") .nes. ""
2175 $     THEN
2176 $       OPEN/APPEND CONFIG config.msg
2177 $     ELSE
2178 $       OPEN/WRITE CONFIG config.msg
2179 $     ENDIF
2180 $     IF Bad_env .eqs. "SYMBOL"
2181 $     THEN
2182 $       WRITE CONFIG ""
2183 $       WRITE CONFIG "Symbol name ''p1' found in environment as " + &p1
2184 $       WRITE CONFIG " delete before building ''package' via:"
2185 $       WRITE CONFIG "     $ DELETE/SYMBOL/GLOBAL ''p1'"
2186 $       IF f$locate("""",&p1) .ge. f$length(&p1)
2187 $       THEN
2188 $       WRITE CONFIG " after building, testing, and installing ''package'
2189 $       WRITE CONFIG " restore the symbol with:"
2190 $       WRITE CONFIG "     $ ''p1' == """ + &p1 + """"
2191 $       ENDIF
2192 $     ENDIF
2193 $     IF Bad_env .eqs. "LOGICAL"
2194 $     THEN
2195 $       WRITE CONFIG ""
2196 $       WRITE CONFIG "Logical name ''p1' found in environment as " + f$trnlnm(p1)
2197 $       WRITE CONFIG " deassign before building ''package'"
2198 $     ENDIF
2199 $     CLOSE CONFIG
2200 $     Bad_env = ""
2201 $   ENDIF
2202 $ EXIT
2203 $ ENDSUBROUTINE ! Bad_environment
2204 $ echo ""
2205 $ echo4 "%Config-I-VMS, Checking for dangerous pre-existing global symbols and logical names."
2206 $ CALL Bad_environment "TMP"
2207 $ CALL Bad_environment "LIB"
2208 $ CALL Bad_environment "T"
2209 $ CALL Bad_environment "FOO"
2210 $ CALL Bad_environment "EXT"
2211 $ CALL Bad_environment "TEST" "SYMBOL"
2212 $ IF f$search("config.msg") .eqs. "" THEN echo "OK."
2213 $!
2214 $! %Config-I-VMS, write perl_setup.com here
2215 $!
2216 $ IF (.NOT.perl_symbol)
2217 $ THEN
2218 $   file_2_find = "[-]''packageup'.cld"
2219 $   echo ""
2220 $   echo4 "%Config-I-VMS, The perl.cld file is now being written..."
2221 $   OPEN/WRITE CONFIG 'file_2_find'
2222 $   IF (use_vmsdebug_perl)
2223 $   THEN
2224 $     WRITE CONFIG "define verb dbgperl"
2225 $     WRITE CONFIG F$FAO("!_!AS","image ''packageup'_root:[000000]dbgperl''ext'")
2226 $     WRITE CONFIG F$FAO("!_!AS","cliflags (foreign)")
2227 $     WRITE CONFIG ""
2228 $     WRITE CONFIG "define verb perl"
2229 $     WRITE CONFIG F$FAO("!_!AS","image ''packageup'_root:[000000]ndbgPerl''ext'")
2230 $     WRITE CONFIG F$FAO("!_!AS","cliflags (foreign)")
2231 $   ELSE
2232 $     WRITE CONFIG "define verb perl"
2233 $     WRITE CONFIG F$FAO("!_!AS","image ''packageup'_root:[000000]perl''ext'")
2234 $     WRITE CONFIG F$FAO("!_!AS","cliflags (foreign)")
2235 $   ENDIF
2236 $   CLOSE CONFIG
2237 $ ENDIF ! (.NOT.perl_symbol)
2238 $ echo ""
2239 $ echo4 "%Config-I-VMS, The perl_setup.com file is now being written..."
2240 $ file_2_find = "[-]perl_setup.com"
2241 $ OPEN/WRITE CONFIG 'file_2_find'
2242 $ WRITE CONFIG "$!"
2243 $ WRITE CONFIG "$! Perl_Setup.com    ''cf_time'"
2244 $ IF cf_email.NES.perladmin
2245 $ THEN
2246 $ WRITE CONFIG "$! perl configured by ''cf_email'"
2247 $ ELSE
2248 $ WRITE CONFIG "$! This perl configured & administered by ''perladmin'"
2249 $ ENDIF
2250 $ WRITE CONFIG "$!"
2251 $ prefix = prefix - "000000."
2252 $ IF F$LOCATE(".]",prefix) .EQ. F$LENGTH(prefix) THEN -
2253     prefix = prefix - "]" + ".]" 
2254 $ WRITE CONFIG "$ define/translation=concealed Perl_Root ''prefix'"
2255 $ WRITE CONFIG "$ ext = "".exe"""
2256 $ IF sharedperl .EQS. "Y"
2257 $ THEN
2258 $   write config "$ if f$getsyi(""ARCH_NAME"") .nes. ""VAX"" then ext = "".AXE"""
2259 $ ENDIF
2260 $ IF (perl_symbol)
2261 $ THEN
2262 $   IF (use_vmsdebug_perl)
2263 $   THEN
2264 $     WRITE CONFIG "$ dbgperl :== $Perl_Root:[000000]dbgPerl'ext'"
2265 $     WRITE CONFIG "$ perl    :== $Perl_Root:[000000]ndbgPerl'ext'"
2266 $     WRITE CONFIG "$ define dbgPerlShr Perl_Root:[000000]dbgPerlShr'ext'"
2267 $   ELSE
2268 $     WRITE CONFIG "$ perl :== $Perl_Root:[000000]Perl'ext'"
2269 $     WRITE CONFIG "$ define PerlShr Perl_Root:[000000]PerlShr'ext'"
2270 $   ENDIF
2271 $ ELSE ! .NOT.perl_symbol
2272 $   IF (use_vmsdebug_perl)
2273 $   THEN
2274 $     WRITE CONFIG "$ define dbgPerlShr Perl_Root:[000000]dbgPerlShr'ext'"
2275 $   ELSE
2276 $     WRITE CONFIG "$ define PerlShr Perl_Root:[000000]PerlShr'ext'"
2277 $   ENDIF
2278 $   IF perl_verb .EQS. "PROCESS"
2279 $   THEN
2280 $     WRITE CONFIG "$ set command ''packagup'_ROOT:[000000]''packageup'.CLD"
2281 $   ENDIF
2282 $ ENDIF !  perl_symbol
2283 $ WRITE CONFIG "$ define/nolog pod2text Perl_Root:[lib.pod]pod2text.com"
2284 $ WRITE CONFIG "$ define/nolog pod2html Perl_Root:[lib.pod]pod2html.com"
2285 $ WRITE CONFIG "$ define/nolog pod2man  Perl_Root:[lib.pod]pod2man.com"
2286 $!
2287 $ IF (tzneedset)
2288 $ THEN
2289 $ WRITE CONFIG "$ define SYS$TIMEZONE_DIFFERENTIAL ''tzd'"
2290 $ ELSE    !leave in but commented out (in case setting was from perl :-)
2291 $ WRITE CONFIG "$! define SYS$TIMEZONE_DIFFERENTIAL ''tzd'"
2292 $ ENDIF
2293 $ WRITE CONFIG "$!"
2294 $ WRITE CONFIG "$! Symbols for commonly used scripts:"
2295 $ WRITE CONFIG "$!"
2296 $ IF (perl_symbol)
2297 $ THEN
2298 $   WRITE CONFIG "$ Perldoc  == ""'"+"'Perl' Perl_Root:[lib.pod]Perldoc.com -t"""
2299 $   WRITE CONFIG "$ pod2text == ""'"+"'Perl' pod2text"""
2300 $   WRITE CONFIG "$ pod2html == ""'"+"'Perl' pod2html"""
2301 $   WRITE CONFIG "$ pod2latex == ""'"+"'Perl' Perl_Root:[lib.pod]pod2latex.com"""
2302 $   WRITE CONFIG "$!pod2man  == ""'"+"'Perl' pod2man"""
2303 $   WRITE CONFIG "$!Perlbug  == ""'"+"'Perl' Perl_Root:[lib]Perlbug.com"""
2304 $   WRITE CONFIG "$ c2ph     == ""'"+"'Perl' Perl_Root:[utils]c2ph.com"""
2305 $   IF F$LOCATE("Devel::DProf",extensions) .LT. F$LENGTH(extensions)
2306 $   THEN
2307 $     WRITE CONFIG "$ dprofpp     == ""'"+"'Perl' Perl_Root:[utils]dprofpp.com"""
2308 $   ENDIF 
2309 $   WRITE CONFIG "$ h2ph     == ""'"+"'Perl' Perl_Root:[utils]h2ph.com"""
2310 $   WRITE CONFIG "$ h2xs     == ""'"+"'Perl' Perl_Root:[utils]h2xs.com"""
2311 $   WRITE CONFIG "$!perlcc   == ""'"+"'Perl' Perl_Root:[utils]perlcc.com"""
2312 $   WRITE CONFIG "$ splain   == ""'"+"'Perl' Perl_Root:[utils]splain.com"""
2313 $ ELSE
2314 $   WRITE CONFIG "$ Perldoc  == ""Perl Perl_Root:[lib.pod]Perldoc.com -t"""
2315 $   WRITE CONFIG "$ pod2text == ""Perl pod2text"""
2316 $   WRITE CONFIG "$ pod2html == ""Perl pod2html"""
2317 $   WRITE CONFIG "$ pod2latex == ""Perl Perl_Root:[lib.pod]pod2latex.com"""
2318 $   WRITE CONFIG "$!pod2man  == ""Perl pod2man"""
2319 $   WRITE CONFIG "$!Perlbug  == ""Perl Perl_Root:[lib]Perlbug.com"""
2320 $   WRITE CONFIG "$ c2ph     == ""Perl Perl_Root:[utils]c2ph.com"""
2321 $   IF F$LOCATE("Devel::DProf",extensions) .LT. F$LENGTH(extensions)
2322 $   THEN
2323 $     WRITE CONFIG "$ dprofpp     == ""Perl Perl_Root:[utils]dprofpp.com"""
2324 $   ENDIF 
2325 $   WRITE CONFIG "$ h2ph     == ""Perl Perl_Root:[utils]h2ph.com"""
2326 $   WRITE CONFIG "$ h2xs     == ""Perl Perl_Root:[utils]h2xs.com"""
2327 $   WRITE CONFIG "$!perlcc   == ""Perl Perl_Root:[utils]perlcc.com"""
2328 $   WRITE CONFIG "$ splain   == ""Perl Perl_Root:[utils]splain.com"""
2329 $ ENDIF
2330 $ CLOSE CONFIG
2331 $!
2332 $ echo  ""
2333 $ echo  "%Config-I-VMS, The file can be found at:"
2334 $ echo4 "-Config-I-VMS, ''F$SEARCH(file_2_find)'"
2335 $ echo  "-Config-I-VMS, Add that file (or an @ call to it) to your [SY]LOGIN.COM"
2336 $ echo  "-Config-I-VMS, when you are satisfied with a successful compilation,"
2337 $ echo  "-Config-I-VMS, testing, and installation of your perl."
2338 $ echo  ""
2339 $ IF ((.NOT.perl_symbol) .AND. (perl_verb .EQS. "DCLTABLES"))
2340 $ THEN
2341 $   file_2_find = "[-]''packageup'_install.com"
2342 $   OPEN/WRITE CONFIG 'file_2_find
2343 $   WRITE CONFIG "$ set command perl /table=sys$common:[syslib]dcltables.exe -"
2344 $   WRITE CONFIG "    /output=sys$common:[syslib]dcltables.exe"
2345 $   WRITE CONFIG "$ install replace sys$common:[syslib]dcltables.exe"
2346 $   CLOSE CONFIG
2347 $   echo4 ""
2348 $   echo4 "%Config-I-VMS, In order to install the ''packageup' verb into DCLTABLES run:"
2349 $   echo4 "-Config-I-VMS, @ ''F$SEARCH(file_2_find)'"
2350 $   echo4 "-Config-I-VMS, after a successful build, test, and install.  Do so with CMKRNL privilege."
2351 $   echo4 ""
2352 $ ENDIF
2353 $!
2354 $!figure out where we "are" by parsing 'vms_default_directory_name' 
2355 $!
2356 $ set_def_command = ""
2357 $ dflt = F$ENVIRONMENT("DEFAULT") - ".UU]" 
2358 $ tmp = vms_default_directory_name - dflt - "]"
2359 $ i = 0
2360 $ IF tmp .EQS. "" THEN GOTO Beyond_set_def_loop
2361 $Set_def_loop:
2362 $ tmp1 = F$ELEMENT(i,".",tmp)
2363 $ IF tmp1 .EQS. "." THEN GOTO Beyond_set_def_loop
2364 $ IF i .EQ. 0 
2365 $ THEN set_def_command = "set default [-"
2366 $ ELSE set_def_command = set_def_command + "-"
2367 $ ENDIF
2368 $ i = i + 1
2369 $ GOTO Set_def_loop
2370 $Beyond_set_def_loop:
2371 $ IF set_def_command.NES.""
2372 $ THEN
2373 $   set_def_command = set_def_command - "-" + "]"
2374 $   echo4 ""
2375 $   echo4 "In order to build ''package' you must now issue the commands:"
2376 $   echo4 ""
2377 $   echo4 " ''set_def_command'"
2378 $ ELSE
2379 $   echo4 ""
2380 $   echo4 "In order to build ''package' you must now issue the command:"
2381 $   echo4 ""
2382 $ ENDIF
2383 $ echo4 " ''make'''makefile'", macros
2384 $ echo4 ""
2385 $!
2386 $ IF ( F$SEARCH("config.msg").NES."" ) 
2387 $ THEN
2388 $   echo "Hmm.  I also noted the following information while running:"
2389 $   echo ""
2390 $   type config.msg
2391 $   SET PROTECTION=(SYSTEM:RWED,OWNER:RWED) config.msg
2392 $   DELETE/NOLOG/NOCONFIRM config.msg;
2393 $ ENDIF
2394 $!
2395 $Clean_up:
2396 $ IF (silent)
2397 $ THEN
2398 $   DEASSIGN SYS$OUTPUT
2399 $!   DEASSIGN SYS$ERROR
2400 $ ENDIF
2401 $ IF F$GETJPI("","FILCNT").NE.vms_filcnt THEN CLOSE CONFIG
2402 $ IF F$GETJPI("","FILCNT").NE.vms_filcnt 
2403 $ THEN WRITE SYS$ERROR "%Config-W-VMS, WARNING: There is a file still open"
2404 $ ENDIF
2405 $ dflt = F$ENVIRONMENT("DEFAULT")
2406 $ IF F$LOCATE("UU]",dflt).EQS.(F$LENGTH(dflt)-3)
2407 $ THEN
2408 $   IF ( F$SEARCH("[]*.*").NES."" ) THEN DELETE/NOLOG/NOCONFIRM []*.*;*
2409 $   SET DEFAULT [-]
2410 $   SET PROTECTION=(SYSTEM:RWED,OWNER:RWED) UU.DIR
2411 $   DELETE/NOLOG/NOCONFIRM UU.DIR;
2412 $ ENDIF
2413 $ SET DEFAULT 'vms_default_directory_name' !be kind rewind
2414 $ STOP
2415 $ EXIT
2416 $!: End of Configure