This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Upgrade to Devel::PPPort 3.09_02
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127
128 The default input and pattern-searching space.  The following pairs are
129 equivalent:
130
131     while (<>) {...}    # equivalent only in while!
132     while (defined($_ = <>)) {...}
133
134     /^Subject:/
135     $_ =~ /^Subject:/
136
137     tr/a-z/A-Z/
138     $_ =~ tr/a-z/A-Z/
139
140     chomp
141     chomp($_)
142
143 Here are the places where Perl will assume $_ even if you
144 don't use it:
145
146 =over 3
147
148 =item *
149
150 Various unary functions, including functions like ord() and int(), as well
151 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
152 STDIN.
153
154 =item *
155
156 Various list functions like print() and unlink().
157
158 =item *
159
160 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
161 without an C<=~> operator.
162
163 =item *
164
165 The default iterator variable in a C<foreach> loop if no other
166 variable is supplied.
167
168 =item *
169
170 The implicit iterator variable in the grep() and map() functions.
171
172 =item *
173
174 The default place to put an input record when a C<< <FH> >>
175 operation's result is tested by itself as the sole criterion of a C<while>
176 test.  Outside a C<while> test, this will not happen.
177
178 =back
179
180 As C<$_> is a global variable, this may lead in some cases to unwanted
181 side-effects.  As of perl 5.9.1, you can now use a lexical version of
182 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
183 declaring C<our $> restores the global C<$_> in the current scope.
184
185 (Mnemonic: underline is understood in certain operations.)
186
187 =back
188
189 =over 8
190
191 =item $a
192
193 =item $b
194
195 Special package variables when using sort(), see L<perlfunc/sort>.
196 Because of this specialness $a and $b don't need to be declared
197 (using use vars, or our()) even when using the C<strict 'vars'> pragma.
198 Don't lexicalize them with C<my $a> or C<my $b> if you want to be
199 able to use them in the sort() comparison block or function.
200
201 =back
202
203 =over 8
204
205 =item $<I<digits>>
206
207 Contains the subpattern from the corresponding set of capturing
208 parentheses from the last pattern match, not counting patterns
209 matched in nested blocks that have been exited already.  (Mnemonic:
210 like \digits.)  These variables are all read-only and dynamically
211 scoped to the current BLOCK.
212
213 =item $MATCH
214
215 =item $&
216
217 The string matched by the last successful pattern match (not counting
218 any matches hidden within a BLOCK or eval() enclosed by the current
219 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
220 and dynamically scoped to the current BLOCK.
221
222 The use of this variable anywhere in a program imposes a considerable
223 performance penalty on all regular expression matches.  See L</BUGS>.
224
225 =item $PREMATCH
226
227 =item $`
228
229 The string preceding whatever was matched by the last successful
230 pattern match (not counting any matches hidden within a BLOCK or eval
231 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
232 string.)  This variable is read-only.
233
234 The use of this variable anywhere in a program imposes a considerable
235 performance penalty on all regular expression matches.  See L</BUGS>.
236
237 =item $POSTMATCH
238
239 =item $'
240
241 The string following whatever was matched by the last successful
242 pattern match (not counting any matches hidden within a BLOCK or eval()
243 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
244 string.)  Example:
245
246     local $_ = 'abcdefghi';
247     /def/;
248     print "$`:$&:$'\n";         # prints abc:def:ghi
249
250 This variable is read-only and dynamically scoped to the current BLOCK.
251
252 The use of this variable anywhere in a program imposes a considerable
253 performance penalty on all regular expression matches.  See L</BUGS>.
254
255 =item $LAST_PAREN_MATCH
256
257 =item $+
258
259 The text matched by the last bracket of the last successful search pattern.
260 This is useful if you don't know which one of a set of alternative patterns
261 matched. For example:
262
263     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
264
265 (Mnemonic: be positive and forward looking.)
266 This variable is read-only and dynamically scoped to the current BLOCK.
267
268 =item $^N
269
270 The text matched by the used group most-recently closed (i.e. the group
271 with the rightmost closing parenthesis) of the last successful search
272 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
273 recently closed.)
274
275 This is primarily used inside C<(?{...})> blocks for examining text
276 recently matched. For example, to effectively capture text to a variable
277 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
278
279      (?:(...)(?{ $var = $^N }))
280
281 By setting and then using C<$var> in this way relieves you from having to
282 worry about exactly which numbered set of parentheses they are.
283
284 This variable is dynamically scoped to the current BLOCK.
285
286 =item @LAST_MATCH_END
287
288 =item @+
289
290 This array holds the offsets of the ends of the last successful
291 submatches in the currently active dynamic scope.  C<$+[0]> is
292 the offset into the string of the end of the entire match.  This
293 is the same value as what the C<pos> function returns when called
294 on the variable that was matched against.  The I<n>th element
295 of this array holds the offset of the I<n>th submatch, so
296 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
297 past where $2 ends, and so on.  You can use C<$#+> to determine
298 how many subgroups were in the last successful match.  See the
299 examples given for the C<@-> variable.
300
301 =item HANDLE->input_line_number(EXPR)
302
303 =item $INPUT_LINE_NUMBER
304
305 =item $NR
306
307 =item $.
308
309 Current line number for the last filehandle accessed. 
310
311 Each filehandle in Perl counts the number of lines that have been read
312 from it.  (Depending on the value of C<$/>, Perl's idea of what
313 constitutes a line may not match yours.)  When a line is read from a
314 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
315 called on it, C<$.> becomes an alias to the line counter for that
316 filehandle.
317
318 You can adjust the counter by assigning to C<$.>, but this will not
319 actually move the seek pointer.  I<Localizing C<$.> will not localize
320 the filehandle's line count>.  Instead, it will localize perl's notion
321 of which filehandle C<$.> is currently aliased to.
322
323 C<$.> is reset when the filehandle is closed, but B<not> when an open
324 filehandle is reopened without an intervening close().  For more
325 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
326 an explicit close, line numbers increase across ARGV files (but see
327 examples in L<perlfunc/eof>).
328
329 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
330 line counter for a given filehandle without having to worry about
331 which handle you last accessed.
332
333 (Mnemonic: many programs use "." to mean the current line number.)
334
335 =item IO::Handle->input_record_separator(EXPR)
336
337 =item $INPUT_RECORD_SEPARATOR
338
339 =item $RS
340
341 =item $/
342
343 The input record separator, newline by default.  This 
344 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
345 variable, including treating empty lines as a terminator if set to
346 the null string.  (An empty line cannot contain any spaces
347 or tabs.)  You may set it to a multi-character string to match a
348 multi-character terminator, or to C<undef> to read through the end
349 of file.  Setting it to C<"\n\n"> means something slightly
350 different than setting to C<"">, if the file contains consecutive
351 empty lines.  Setting to C<""> will treat two or more consecutive
352 empty lines as a single empty line.  Setting to C<"\n\n"> will
353 blindly assume that the next input character belongs to the next
354 paragraph, even if it's a newline.  (Mnemonic: / delimits
355 line boundaries when quoting poetry.)
356
357     local $/;           # enable "slurp" mode
358     local $_ = <FH>;    # whole file now here
359     s/\n[ \t]+/ /g;
360
361 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
362 better for something. :-)
363
364 Setting C<$/> to a reference to an integer, scalar containing an integer, or
365 scalar that's convertible to an integer will attempt to read records
366 instead of lines, with the maximum record size being the referenced
367 integer.  So this:
368
369     local $/ = \32768; # or \"32768", or \$var_containing_32768
370     open my $fh, $myfile or die $!;
371     local $_ = <$fh>;
372
373 will read a record of no more than 32768 bytes from FILE.  If you're
374 not reading from a record-oriented file (or your OS doesn't have
375 record-oriented files), then you'll likely get a full chunk of data
376 with every read.  If a record is larger than the record size you've
377 set, you'll get the record back in pieces.  Trying to set the record
378 size to zero or less will cause reading in the (rest of the) whole file.
379
380 On VMS, record reads are done with the equivalent of C<sysread>,
381 so it's best not to mix record and non-record reads on the same
382 file.  (This is unlikely to be a problem, because any file you'd
383 want to read in record mode is probably unusable in line mode.)
384 Non-VMS systems do normal I/O, so it's safe to mix record and
385 non-record reads of a file.
386
387 See also L<perlport/"Newlines">.  Also see C<$.>.
388
389 =item HANDLE->autoflush(EXPR)
390
391 =item $OUTPUT_AUTOFLUSH
392
393 =item $|
394
395 If set to nonzero, forces a flush right away and after every write
396 or print on the currently selected output channel.  Default is 0
397 (regardless of whether the channel is really buffered by the
398 system or not; C<$|> tells you only whether you've asked Perl
399 explicitly to flush after each write).  STDOUT will
400 typically be line buffered if output is to the terminal and block
401 buffered otherwise.  Setting this variable is useful primarily when
402 you are outputting to a pipe or socket, such as when you are running
403 a Perl program under B<rsh> and want to see the output as it's
404 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
405 for that.  (Mnemonic: when you want your pipes to be piping hot.)
406
407 =item IO::Handle->output_field_separator EXPR
408
409 =item $OUTPUT_FIELD_SEPARATOR
410
411 =item $OFS
412
413 =item $,
414
415 The output field separator for the print operator.  If defined, this
416 value is printed between each of print's arguments.  Default is C<undef>.
417 (Mnemonic: what is printed when there is a "," in your print statement.)
418
419 =item IO::Handle->output_record_separator EXPR
420
421 =item $OUTPUT_RECORD_SEPARATOR
422
423 =item $ORS
424
425 =item $\
426
427 The output record separator for the print operator.  If defined, this
428 value is printed after the last of print's arguments.  Default is C<undef>.
429 (Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
430 Also, it's just like C<$/>, but it's what you get "back" from Perl.)
431
432 =item $LIST_SEPARATOR
433
434 =item $"
435
436 This is like C<$,> except that it applies to array and slice values
437 interpolated into a double-quoted string (or similar interpreted
438 string).  Default is a space.  (Mnemonic: obvious, I think.)
439
440 =item $SUBSCRIPT_SEPARATOR
441
442 =item $SUBSEP
443
444 =item $;
445
446 The subscript separator for multidimensional array emulation.  If you
447 refer to a hash element as
448
449     $foo{$a,$b,$c}
450
451 it really means
452
453     $foo{join($;, $a, $b, $c)}
454
455 But don't put
456
457     @foo{$a,$b,$c}      # a slice--note the @
458
459 which means
460
461     ($foo{$a},$foo{$b},$foo{$c})
462
463 Default is "\034", the same as SUBSEP in B<awk>.  If your
464 keys contain binary data there might not be any safe value for C<$;>.
465 (Mnemonic: comma (the syntactic subscript separator) is a
466 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
467 taken for something more important.)
468
469 Consider using "real" multidimensional arrays as described
470 in L<perllol>.
471
472 =item HANDLE->format_page_number(EXPR)
473
474 =item $FORMAT_PAGE_NUMBER
475
476 =item $%
477
478 The current page number of the currently selected output channel.
479 Used with formats.
480 (Mnemonic: % is page number in B<nroff>.)
481
482 =item HANDLE->format_lines_per_page(EXPR)
483
484 =item $FORMAT_LINES_PER_PAGE
485
486 =item $=
487
488 The current page length (printable lines) of the currently selected
489 output channel.  Default is 60.  
490 Used with formats.
491 (Mnemonic: = has horizontal lines.)
492
493 =item HANDLE->format_lines_left(EXPR)
494
495 =item $FORMAT_LINES_LEFT
496
497 =item $-
498
499 The number of lines left on the page of the currently selected output
500 channel.  
501 Used with formats.
502 (Mnemonic: lines_on_page - lines_printed.)
503
504 =item @LAST_MATCH_START
505
506 =item @-
507
508 $-[0] is the offset of the start of the last successful match.
509 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
510 I<n>-th subpattern, or undef if the subpattern did not match.
511
512 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
513 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
514 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
515 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the last
516 matched subgroup in the last successful match.  Contrast with
517 C<$#+>, the number of subgroups in the regular expression.  Compare
518 with C<@+>.
519
520 This array holds the offsets of the beginnings of the last
521 successful submatches in the currently active dynamic scope.
522 C<$-[0]> is the offset into the string of the beginning of the
523 entire match.  The I<n>th element of this array holds the offset
524 of the I<n>th submatch, so C<$-[1]> is the offset where $1
525 begins, C<$-[2]> the offset where $2 begins, and so on.
526
527 After a match against some variable $var:
528
529 =over 5
530
531 =item C<$`> is the same as C<substr($var, 0, $-[0])>
532
533 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
534
535 =item C<$'> is the same as C<substr($var, $+[0])>
536
537 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
538
539 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
540
541 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
542
543 =back
544
545 =item HANDLE->format_name(EXPR)
546
547 =item $FORMAT_NAME
548
549 =item $~
550
551 The name of the current report format for the currently selected output
552 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
553 C<$^>.)
554
555 =item HANDLE->format_top_name(EXPR)
556
557 =item $FORMAT_TOP_NAME
558
559 =item $^
560
561 The name of the current top-of-page format for the currently selected
562 output channel.  Default is the name of the filehandle with _TOP
563 appended.  (Mnemonic: points to top of page.)
564
565 =item IO::Handle->format_line_break_characters EXPR
566
567 =item $FORMAT_LINE_BREAK_CHARACTERS
568
569 =item $:
570
571 The current set of characters after which a string may be broken to
572 fill continuation fields (starting with ^) in a format.  Default is
573 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
574 poetry is a part of a line.)
575
576 =item IO::Handle->format_formfeed EXPR
577
578 =item $FORMAT_FORMFEED
579
580 =item $^L
581
582 What formats output as a form feed.  Default is \f.
583
584 =item $ACCUMULATOR
585
586 =item $^A
587
588 The current value of the write() accumulator for format() lines.  A format
589 contains formline() calls that put their result into C<$^A>.  After
590 calling its format, write() prints out the contents of C<$^A> and empties.
591 So you never really see the contents of C<$^A> unless you call
592 formline() yourself and then look at it.  See L<perlform> and
593 L<perlfunc/formline()>.
594
595 =item $CHILD_ERROR
596
597 =item $?
598
599 The status returned by the last pipe close, backtick (C<``>) command,
600 successful call to wait() or waitpid(), or from the system()
601 operator.  This is just the 16-bit status word returned by the
602 traditional Unix wait() system call (or else is made up to look like it).  Thus, the
603 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
604 C<$? & 127> gives which signal, if any, the process died from, and
605 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
606 similar to B<sh> and B<ksh>.)
607
608 Additionally, if the C<h_errno> variable is supported in C, its value
609 is returned via $? if any C<gethost*()> function fails.
610
611 If you have installed a signal handler for C<SIGCHLD>, the
612 value of C<$?> will usually be wrong outside that handler.
613
614 Inside an C<END> subroutine C<$?> contains the value that is going to be
615 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
616 change the exit status of your program.  For example:
617
618     END {
619         $? = 1 if $? == 255;  # die would make it 255
620     } 
621
622 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
623 actual VMS exit status, instead of the default emulation of POSIX
624 status; see L<perlvms/$?> for details.
625
626 Also see L<Error Indicators>.
627
628 =item ${^CHILD_ERROR_NATIVE}
629
630 The native status returned by the last pipe close, backtick (C<``>)
631 command, successful call to wait() or waitpid(), or from the system()
632 operator.  On POSIX-like systems this value can be decoded with the
633 WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED, WSTOPSIG
634 and WIFCONTINUED functions provided by the L<POSIX> module.
635
636 Under VMS this reflects the actual VMS exit status; i.e. it is the same
637 as $? when the pragma C<use vmsish 'status'> is in effect.
638
639 =item ${^ENCODING}
640
641 The I<object reference> to the Encode object that is used to convert
642 the source code to Unicode.  Thanks to this variable your perl script
643 does not have to be written in UTF-8.  Default is I<undef>.  The direct
644 manipulation of this variable is highly discouraged.  See L<encoding>
645 for more details.
646
647 =item $OS_ERROR
648
649 =item $ERRNO
650
651 =item $!
652
653 If used numerically, yields the current value of the C C<errno>
654 variable, or in other words, if a system or library call fails, it
655 sets this variable.  This means that the value of C<$!> is meaningful
656 only I<immediately> after a B<failure>:
657
658     if (open(FH, $filename)) {
659         # Here $! is meaningless.
660         ...
661     } else {
662         # ONLY here is $! meaningful.
663         ...
664         # Already here $! might be meaningless.
665     }
666     # Since here we might have either success or failure,
667     # here $! is meaningless.
668
669 In the above I<meaningless> stands for anything: zero, non-zero,
670 C<undef>.  A successful system or library call does B<not> set
671 the variable to zero.
672
673 If used as a string, yields the corresponding system error string.
674 You can assign a number to C<$!> to set I<errno> if, for instance,
675 you want C<"$!"> to return the string for error I<n>, or you want
676 to set the exit value for the die() operator.  (Mnemonic: What just
677 went bang?)
678
679 Also see L<Error Indicators>.
680
681 =item %!
682
683 Each element of C<%!> has a true value only if C<$!> is set to that
684 value.  For example, C<$!{ENOENT}> is true if and only if the current
685 value of C<$!> is C<ENOENT>; that is, if the most recent error was
686 "No such file or directory" (or its moral equivalent: not all operating
687 systems give that exact error, and certainly not all languages).
688 To check if a particular key is meaningful on your system, use
689 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
690 See L<Errno> for more information, and also see above for the
691 validity of C<$!>.
692
693 =item $EXTENDED_OS_ERROR
694
695 =item $^E
696
697 Error information specific to the current operating system.  At
698 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
699 (and for MacPerl).  On all other platforms, C<$^E> is always just
700 the same as C<$!>.
701
702 Under VMS, C<$^E> provides the VMS status value from the last
703 system error.  This is more specific information about the last
704 system error than that provided by C<$!>.  This is particularly
705 important when C<$!> is set to B<EVMSERR>.
706
707 Under OS/2, C<$^E> is set to the error code of the last call to
708 OS/2 API either via CRT, or directly from perl.
709
710 Under Win32, C<$^E> always returns the last error information
711 reported by the Win32 call C<GetLastError()> which describes
712 the last error from within the Win32 API.  Most Win32-specific
713 code will report errors via C<$^E>.  ANSI C and Unix-like calls
714 set C<errno> and so most portable Perl code will report errors
715 via C<$!>. 
716
717 Caveats mentioned in the description of C<$!> generally apply to
718 C<$^E>, also.  (Mnemonic: Extra error explanation.)
719
720 Also see L<Error Indicators>.
721
722 =item $EVAL_ERROR
723
724 =item $@
725
726 The Perl syntax error message from the last eval() operator.
727 If $@ is the null string, the last eval() parsed and executed
728 correctly (although the operations you invoked may have failed in the
729 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
730
731 Warning messages are not collected in this variable.  You can,
732 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
733 as described below.
734
735 Also see L<Error Indicators>.
736
737 =item $PROCESS_ID
738
739 =item $PID
740
741 =item $$
742
743 The process number of the Perl running this script.  You should
744 consider this variable read-only, although it will be altered
745 across fork() calls.  (Mnemonic: same as shells.)
746
747 Note for Linux users: on Linux, the C functions C<getpid()> and
748 C<getppid()> return different values from different threads. In order to
749 be portable, this behavior is not reflected by C<$$>, whose value remains
750 consistent across threads. If you want to call the underlying C<getpid()>,
751 you may use the CPAN module C<Linux::Pid>.
752
753 =item $REAL_USER_ID
754
755 =item $UID
756
757 =item $<
758
759 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
760 if you're running setuid.)  You can change both the real uid and
761 the effective uid at the same time by using POSIX::setuid().  Since
762 changes to $< require a system call, check $! after a change attempt to 
763 detect any possible errors.
764
765 =item $EFFECTIVE_USER_ID
766
767 =item $EUID
768
769 =item $>
770
771 The effective uid of this process.  Example:
772
773     $< = $>;            # set real to effective uid
774     ($<,$>) = ($>,$<);  # swap real and effective uid
775
776 You can change both the effective uid and the real uid at the same
777 time by using POSIX::setuid().  Changes to $> require a check to $!
778 to detect any possible errors after an attempted change. 
779
780 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
781 C<< $< >> and C<< $> >> can be swapped only on machines
782 supporting setreuid().
783
784 =item $REAL_GROUP_ID
785
786 =item $GID
787
788 =item $(
789
790 The real gid of this process.  If you are on a machine that supports
791 membership in multiple groups simultaneously, gives a space separated
792 list of groups you are in.  The first number is the one returned by
793 getgid(), and the subsequent ones by getgroups(), one of which may be
794 the same as the first number.
795
796 However, a value assigned to C<$(> must be a single number used to
797 set the real gid.  So the value given by C<$(> should I<not> be assigned
798 back to C<$(> without being forced numeric, such as by adding zero.
799
800 You can change both the real gid and the effective gid at the same
801 time by using POSIX::setgid().  Changes to $( require a check to $!
802 to detect any possible errors after an attempted change.
803
804 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
805 group you I<left>, if you're running setgid.)
806
807 =item $EFFECTIVE_GROUP_ID
808
809 =item $EGID
810
811 =item $)
812
813 The effective gid of this process.  If you are on a machine that
814 supports membership in multiple groups simultaneously, gives a space
815 separated list of groups you are in.  The first number is the one
816 returned by getegid(), and the subsequent ones by getgroups(), one of
817 which may be the same as the first number.
818
819 Similarly, a value assigned to C<$)> must also be a space-separated
820 list of numbers.  The first number sets the effective gid, and
821 the rest (if any) are passed to setgroups().  To get the effect of an
822 empty list for setgroups(), just repeat the new effective gid; that is,
823 to force an effective gid of 5 and an effectively empty setgroups()
824 list, say C< $) = "5 5" >.
825
826 You can change both the effective gid and the real gid at the same
827 time by using POSIX::setgid() (use only a single numeric argument).
828 Changes to $) require a check to $! to detect any possible errors
829 after an attempted change.
830
831 (Mnemonic: parentheses are used to I<group> things.  The effective gid
832 is the group that's I<right> for you, if you're running setgid.)
833
834 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
835 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
836 and C<$)> can be swapped only on machines supporting setregid().
837
838 =item $PROGRAM_NAME
839
840 =item $0
841
842 Contains the name of the program being executed.
843
844 On some (read: not all) operating systems assigning to C<$0> modifies
845 the argument area that the C<ps> program sees.  On some platforms you
846 may have to use special C<ps> options or a different C<ps> to see the
847 changes.  Modifying the $0 is more useful as a way of indicating the
848 current program state than it is for hiding the program you're
849 running.  (Mnemonic: same as B<sh> and B<ksh>.)
850
851 Note that there are platform specific limitations on the maximum
852 length of C<$0>.  In the most extreme case it may be limited to the
853 space occupied by the original C<$0>.
854
855 In some platforms there may be arbitrary amount of padding, for
856 example space characters, after the modified name as shown by C<ps>.
857 In some platforms this padding may extend all the way to the original
858 length of the argument area, no matter what you do (this is the case
859 for example with Linux 2.2).
860
861 Note for BSD users: setting C<$0> does not completely remove "perl"
862 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
863 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
864 and the " (perl)" suffix are shown depends on your exact BSD variant
865 and version).  This is an operating system feature, Perl cannot help it.
866
867 In multithreaded scripts Perl coordinates the threads so that any
868 thread may modify its copy of the C<$0> and the change becomes visible
869 to ps(1) (assuming the operating system plays along).  Note that
870 the view of C<$0> the other threads have will not change since they
871 have their own copies of it.
872
873 =item $[
874
875 The index of the first element in an array, and of the first character
876 in a substring.  Default is 0, but you could theoretically set it
877 to 1 to make Perl behave more like B<awk> (or Fortran) when
878 subscripting and when evaluating the index() and substr() functions.
879 (Mnemonic: [ begins subscripts.)
880
881 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
882 directive, and cannot influence the behavior of any other file.
883 (That's why you can only assign compile-time constants to it.)
884 Its use is highly discouraged.
885
886 Note that, unlike other compile-time directives (such as L<strict>),
887 assignment to C<$[> can be seen from outer lexical scopes in the same file.
888 However, you can use local() on it to strictly bind its value to a
889 lexical block.
890
891 =item $]
892
893 The version + patchlevel / 1000 of the Perl interpreter.  This variable
894 can be used to determine whether the Perl interpreter executing a
895 script is in the right range of versions.  (Mnemonic: Is this version
896 of perl in the right bracket?)  Example:
897
898     warn "No checksumming!\n" if $] < 3.019;
899
900 See also the documentation of C<use VERSION> and C<require VERSION>
901 for a convenient way to fail if the running Perl interpreter is too old.
902
903 The floating point representation can sometimes lead to inaccurate
904 numeric comparisons.  See C<$^V> for a more modern representation of
905 the Perl version that allows accurate string comparisons.
906
907 =item $COMPILING
908
909 =item $^C
910
911 The current value of the flag associated with the B<-c> switch.
912 Mainly of use with B<-MO=...> to allow code to alter its behavior
913 when being compiled, such as for example to AUTOLOAD at compile
914 time rather than normal, deferred loading.  See L<perlcc>.  Setting
915 C<$^C = 1> is similar to calling C<B::minus_c>.
916
917 =item $DEBUGGING
918
919 =item $^D
920
921 The current value of the debugging flags.  (Mnemonic: value of B<-D>
922 switch.) May be read or set. Like its command-line equivalent, you can use
923 numeric or symbolic values, eg C<$^D = 10> or C<$^D = "st">.
924
925 =item ${^RE_DEBUG_FLAGS}
926
927 The current value of the regex debugging flags. Set to 0 for no debug output
928 even when the re 'debug' module is loaded. See L<re> for details.
929
930 =item ${^RE_TRIE_MAXBUF}
931
932 Controls how certain regex optimisations are applied and how much memory they
933 utilize. This value by default is 65536 which corresponds to a 512kB temporary
934 cache. Set this to a higher value to trade memory for speed when matching
935 large alternations. Set it to a lower value if you want the optimisations to
936 be as conservative of memory as possible but still occur, and set it to a
937 negative value to prevent the optimisation and conserve the most memory.
938 Under normal situations this variable should be of no interest to you.
939
940 =item $SYSTEM_FD_MAX
941
942 =item $^F
943
944 The maximum system file descriptor, ordinarily 2.  System file
945 descriptors are passed to exec()ed processes, while higher file
946 descriptors are not.  Also, during an open(), system file descriptors are
947 preserved even if the open() fails.  (Ordinary file descriptors are
948 closed before the open() is attempted.)  The close-on-exec
949 status of a file descriptor will be decided according to the value of
950 C<$^F> when the corresponding file, pipe, or socket was opened, not the
951 time of the exec().
952
953 =item $^H
954
955 WARNING: This variable is strictly for internal use only.  Its availability,
956 behavior, and contents are subject to change without notice.
957
958 This variable contains compile-time hints for the Perl interpreter.  At the
959 end of compilation of a BLOCK the value of this variable is restored to the
960 value when the interpreter started to compile the BLOCK.
961
962 When perl begins to parse any block construct that provides a lexical scope
963 (e.g., eval body, required file, subroutine body, loop body, or conditional
964 block), the existing value of $^H is saved, but its value is left unchanged.
965 When the compilation of the block is completed, it regains the saved value.
966 Between the points where its value is saved and restored, code that
967 executes within BEGIN blocks is free to change the value of $^H.
968
969 This behavior provides the semantic of lexical scoping, and is used in,
970 for instance, the C<use strict> pragma.
971
972 The contents should be an integer; different bits of it are used for
973 different pragmatic flags.  Here's an example:
974
975     sub add_100 { $^H |= 0x100 }
976
977     sub foo {
978         BEGIN { add_100() }
979         bar->baz($boon);
980     }
981
982 Consider what happens during execution of the BEGIN block.  At this point
983 the BEGIN block has already been compiled, but the body of foo() is still
984 being compiled.  The new value of $^H will therefore be visible only while
985 the body of foo() is being compiled.
986
987 Substitution of the above BEGIN block with:
988
989     BEGIN { require strict; strict->import('vars') }
990
991 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
992 version of the same lexical pragma:
993
994     BEGIN { require strict; strict->import('vars') if $condition }
995
996 =item %^H
997
998 The %^H hash provides the same scoping semantic as $^H.  This makes it
999 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
1000
1001 =item $INPLACE_EDIT
1002
1003 =item $^I
1004
1005 The current value of the inplace-edit extension.  Use C<undef> to disable
1006 inplace editing.  (Mnemonic: value of B<-i> switch.)
1007
1008 =item $^M
1009
1010 By default, running out of memory is an untrappable, fatal error.
1011 However, if suitably built, Perl can use the contents of C<$^M>
1012 as an emergency memory pool after die()ing.  Suppose that your Perl
1013 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
1014 Then
1015
1016     $^M = 'a' x (1 << 16);
1017
1018 would allocate a 64K buffer for use in an emergency.  See the
1019 F<INSTALL> file in the Perl distribution for information on how to
1020 add custom C compilation flags when compiling perl.  To discourage casual
1021 use of this advanced feature, there is no L<English|English> long name for
1022 this variable.
1023
1024 =item $OSNAME
1025
1026 =item $^O
1027
1028 The name of the operating system under which this copy of Perl was
1029 built, as determined during the configuration process.  The value
1030 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1031 B<-V> command-line switch documented in L<perlrun>.
1032
1033 In Windows platforms, $^O is not very helpful: since it is always
1034 C<MSWin32>, it doesn't tell the difference between
1035 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1036 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1037 between the variants.
1038
1039 =item ${^OPEN}
1040
1041 An internal variable used by PerlIO.  A string in two parts, separated
1042 by a C<\0> byte, the first part describes the input layers, the second
1043 part describes the output layers.
1044
1045 =item $PERLDB
1046
1047 =item $^P
1048
1049 The internal variable for debugging support.  The meanings of the
1050 various bits are subject to change, but currently indicate:
1051
1052 =over 6
1053
1054 =item 0x01
1055
1056 Debug subroutine enter/exit.
1057
1058 =item 0x02
1059
1060 Line-by-line debugging.
1061
1062 =item 0x04
1063
1064 Switch off optimizations.
1065
1066 =item 0x08
1067
1068 Preserve more data for future interactive inspections.
1069
1070 =item 0x10
1071
1072 Keep info about source lines on which a subroutine is defined.
1073
1074 =item 0x20
1075
1076 Start with single-step on.
1077
1078 =item 0x40
1079
1080 Use subroutine address instead of name when reporting.
1081
1082 =item 0x80
1083
1084 Report C<goto &subroutine> as well.
1085
1086 =item 0x100
1087
1088 Provide informative "file" names for evals based on the place they were compiled.
1089
1090 =item 0x200
1091
1092 Provide informative names to anonymous subroutines based on the place they
1093 were compiled.
1094
1095 =item 0x400
1096
1097 Debug assertion subroutines enter/exit.
1098
1099 =back
1100
1101 Some bits may be relevant at compile-time only, some at
1102 run-time only.  This is a new mechanism and the details may change.
1103
1104 =item $LAST_REGEXP_CODE_RESULT
1105
1106 =item $^R
1107
1108 The result of evaluation of the last successful C<(?{ code })>
1109 regular expression assertion (see L<perlre>).  May be written to.
1110
1111 =item $EXCEPTIONS_BEING_CAUGHT
1112
1113 =item $^S
1114
1115 Current state of the interpreter.
1116
1117     $^S         State
1118     ---------   -------------------
1119     undef       Parsing module/eval
1120     true (1)    Executing an eval
1121     false (0)   Otherwise
1122
1123 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1124
1125 =item $BASETIME
1126
1127 =item $^T
1128
1129 The time at which the program began running, in seconds since the
1130 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1131 and B<-C> filetests are based on this value.
1132
1133 =item ${^TAINT}
1134
1135 Reflects if taint mode is on or off.  1 for on (the program was run with
1136 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1137 B<-t> or B<-TU>).  This variable is read-only.
1138
1139 =item ${^UNICODE}
1140
1141 Reflects certain Unicode settings of Perl.  See L<perlrun>
1142 documentation for the C<-C> switch for more information about
1143 the possible values. This variable is set during Perl startup
1144 and is thereafter read-only.
1145
1146 =item ${^UTF8CACHE}
1147
1148 This variable controls the state of the internal UTF-8 offset caching code.
1149 1 for on (the default), 0 for off, -1 to debug the caching code by checking
1150 all its results against linear scans, and panicking on any discrepancy.
1151
1152 =item ${^UTF8LOCALE}
1153
1154 This variable indicates whether an UTF-8 locale was detected by perl at
1155 startup. This information is used by perl when it's in
1156 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
1157 switch); see L<perlrun> for more info on this.
1158
1159 =item $PERL_VERSION
1160
1161 =item $^V
1162
1163 The revision, version, and subversion of the Perl interpreter, represented
1164 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1165 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1166 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1167 potentially be in Unicode range.
1168
1169 This variable first appeared in perl 5.6.0; earlier versions of perl will
1170 see an undefined value.
1171
1172 This can be used to determine whether the Perl interpreter executing a
1173 script is in the right range of versions.  (Mnemonic: use ^V for Version
1174 Control.)  Example:
1175
1176     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
1177
1178 To convert C<$^V> into its string representation use sprintf()'s
1179 C<"%vd"> conversion:
1180
1181     printf "version is v%vd\n", $^V;  # Perl's version
1182
1183 See the documentation of C<use VERSION> and C<require VERSION>
1184 for a convenient way to fail if the running Perl interpreter is too old.
1185
1186 See also C<$]> for an older representation of the Perl version.
1187
1188 =item $WARNING
1189
1190 =item $^W
1191
1192 The current value of the warning switch, initially true if B<-w>
1193 was used, false otherwise, but directly modifiable.  (Mnemonic:
1194 related to the B<-w> switch.)  See also L<warnings>.
1195
1196 =item ${^WARNING_BITS}
1197
1198 The current set of warning checks enabled by the C<use warnings> pragma.
1199 See the documentation of C<warnings> for more details.
1200
1201 =item ${^WIN32_SLOPPY_STAT}
1202
1203 If this variable is set to a true value, then stat() on Windows will
1204 not try to open the file. This means that the link count cannot be
1205 determined and file attributes may be out of date if additional
1206 hardlinks to the file exist. On the other hand, not opening the file
1207 is considerably faster, especially for files on network drives.
1208
1209 This variable could be set in the F<sitecustomize.pl> file to
1210 configure the local Perl installation to use "sloppy" stat() by
1211 default.  See L<perlrun> for more information about site
1212 customization.
1213
1214 =item $EXECUTABLE_NAME
1215
1216 =item $^X
1217
1218 The name used to execute the current copy of Perl, from C's
1219 C<argv[0]> or (where supported) F</proc/self/exe>.
1220
1221 Depending on the host operating system, the value of $^X may be
1222 a relative or absolute pathname of the perl program file, or may
1223 be the string used to invoke perl but not the pathname of the
1224 perl program file.  Also, most operating systems permit invoking
1225 programs that are not in the PATH environment variable, so there
1226 is no guarantee that the value of $^X is in PATH.  For VMS, the
1227 value may or may not include a version number.
1228
1229 You usually can use the value of $^X to re-invoke an independent
1230 copy of the same perl that is currently running, e.g.,
1231
1232   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1233
1234 But recall that not all operating systems support forking or
1235 capturing of the output of commands, so this complex statement
1236 may not be portable.
1237
1238 It is not safe to use the value of $^X as a path name of a file,
1239 as some operating systems that have a mandatory suffix on
1240 executable files do not require use of the suffix when invoking
1241 a command.  To convert the value of $^X to a path name, use the
1242 following statements:
1243
1244   # Build up a set of file names (not command names).
1245   use Config;
1246   $this_perl = $^X;
1247   if ($^O ne 'VMS')
1248      {$this_perl .= $Config{_exe}
1249           unless $this_perl =~ m/$Config{_exe}$/i;}
1250
1251 Because many operating systems permit anyone with read access to
1252 the Perl program file to make a copy of it, patch the copy, and
1253 then execute the copy, the security-conscious Perl programmer
1254 should take care to invoke the installed copy of perl, not the
1255 copy referenced by $^X.  The following statements accomplish
1256 this goal, and produce a pathname that can be invoked as a
1257 command or referenced as a file.
1258
1259   use Config;
1260   $secure_perl_path = $Config{perlpath};
1261   if ($^O ne 'VMS')
1262      {$secure_perl_path .= $Config{_exe}
1263           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1264
1265 =item ARGV
1266
1267 The special filehandle that iterates over command-line filenames in
1268 C<@ARGV>. Usually written as the null filehandle in the angle operator
1269 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1270 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1271 corresponding to the last file opened by C<< <> >>. In particular,
1272 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1273 may not cause your function to automatically read the contents of all the
1274 files in C<@ARGV>.
1275
1276 =item $ARGV
1277
1278 contains the name of the current file when reading from <>.
1279
1280 =item @ARGV
1281
1282 The array @ARGV contains the command-line arguments intended for
1283 the script.  C<$#ARGV> is generally the number of arguments minus
1284 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1285 command name itself.  See C<$0> for the command name.
1286
1287 =item ARGVOUT
1288
1289 The special filehandle that points to the currently open output file
1290 when doing edit-in-place processing with B<-i>.  Useful when you have
1291 to do a lot of inserting and don't want to keep modifying $_.  See
1292 L<perlrun> for the B<-i> switch.
1293
1294 =item @F
1295
1296 The array @F contains the fields of each line read in when autosplit
1297 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1298 is package-specific, and must be declared or given a full package name
1299 if not in package main when running under C<strict 'vars'>.
1300
1301 =item @INC
1302
1303 The array @INC contains the list of places that the C<do EXPR>,
1304 C<require>, or C<use> constructs look for their library files.  It
1305 initially consists of the arguments to any B<-I> command-line
1306 switches, followed by the default Perl library, probably
1307 F</usr/local/lib/perl>, followed by ".", to represent the current
1308 directory.  ("." will not be appended if taint checks are enabled, either by
1309 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1310 the C<use lib> pragma to get the machine-dependent library properly
1311 loaded also:
1312
1313     use lib '/mypath/libdir/';
1314     use SomeMod;
1315
1316 You can also insert hooks into the file inclusion system by putting Perl
1317 code directly into @INC.  Those hooks may be subroutine references, array
1318 references or blessed objects.  See L<perlfunc/require> for details.
1319
1320 =item @_
1321
1322 Within a subroutine the array @_ contains the parameters passed to that
1323 subroutine.  See L<perlsub>.
1324
1325 =item %INC
1326
1327 The hash %INC contains entries for each filename included via the
1328 C<do>, C<require>, or C<use> operators.  The key is the filename
1329 you specified (with module names converted to pathnames), and the
1330 value is the location of the file found.  The C<require>
1331 operator uses this hash to determine whether a particular file has
1332 already been included.
1333
1334 If the file was loaded via a hook (e.g. a subroutine reference, see
1335 L<perlfunc/require> for a description of these hooks), this hook is
1336 by default inserted into %INC in place of a filename.  Note, however,
1337 that the hook may have set the %INC entry by itself to provide some more
1338 specific info.
1339
1340 =item %ENV
1341
1342 =item $ENV{expr}
1343
1344 The hash %ENV contains your current environment.  Setting a
1345 value in C<ENV> changes the environment for any child processes
1346 you subsequently fork() off.
1347
1348 =item %SIG
1349
1350 =item $SIG{expr}
1351
1352 The hash %SIG contains signal handlers for signals.  For example:
1353
1354     sub handler {       # 1st argument is signal name
1355         my($sig) = @_;
1356         print "Caught a SIG$sig--shutting down\n";
1357         close(LOG);
1358         exit(0);
1359     }
1360
1361     $SIG{'INT'}  = \&handler;
1362     $SIG{'QUIT'} = \&handler;
1363     ...
1364     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1365     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1366
1367 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1368 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1369 this special case.
1370
1371 Here are some other examples:
1372
1373     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1374     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1375     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1376     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1377
1378 Be sure not to use a bareword as the name of a signal handler,
1379 lest you inadvertently call it. 
1380
1381 If your system has the sigaction() function then signal handlers are
1382 installed using it.  This means you get reliable signal handling.
1383
1384 The default delivery policy of signals changed in Perl 5.8.0 from 
1385 immediate (also known as "unsafe") to deferred, also known as 
1386 "safe signals".  See L<perlipc> for more information.
1387
1388 Certain internal hooks can be also set using the %SIG hash.  The
1389 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1390 about to be printed.  The warning message is passed as the first
1391 argument.  The presence of a __WARN__ hook causes the ordinary printing
1392 of warnings to STDERR to be suppressed.  You can use this to save warnings
1393 in a variable, or turn warnings into fatal errors, like this:
1394
1395     local $SIG{__WARN__} = sub { die $_[0] };
1396     eval $proggie;
1397
1398 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1399 is about to be thrown.  The error message is passed as the first
1400 argument.  When a __DIE__ hook routine returns, the exception
1401 processing continues as it would have in the absence of the hook,
1402 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
1403 The C<__DIE__> handler is explicitly disabled during the call, so that you
1404 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1405
1406 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1407 even inside an eval().  Do not use this to rewrite a pending exception
1408 in C<$@>, or as a bizarre substitute for overriding CORE::GLOBAL::die().
1409 This strange action at a distance may be fixed in a future release
1410 so that C<$SIG{__DIE__}> is only called if your program is about
1411 to exit, as was the original intent.  Any other use is deprecated.
1412
1413 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1414 they may be called to report (probable) errors found by the parser.
1415 In such a case the parser may be in inconsistent state, so any
1416 attempt to evaluate Perl code from such a handler will probably
1417 result in a segfault.  This means that warnings or errors that
1418 result from parsing Perl should be used with extreme caution, like
1419 this:
1420
1421     require Carp if defined $^S;
1422     Carp::confess("Something wrong") if defined &Carp::confess;
1423     die "Something wrong, but could not load Carp to give backtrace...
1424          To see backtrace try starting Perl with -MCarp switch";
1425
1426 Here the first line will load Carp I<unless> it is the parser who
1427 called the handler.  The second line will print backtrace and die if
1428 Carp was available.  The third line will be executed only if Carp was
1429 not available.
1430
1431 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1432 L<warnings> for additional information.
1433
1434 =back
1435
1436 =head2 Error Indicators
1437
1438 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1439 about different types of error conditions that may appear during
1440 execution of a Perl program.  The variables are shown ordered by
1441 the "distance" between the subsystem which reported the error and
1442 the Perl process.  They correspond to errors detected by the Perl
1443 interpreter, C library, operating system, or an external program,
1444 respectively.
1445
1446 To illustrate the differences between these variables, consider the 
1447 following Perl expression, which uses a single-quoted string:
1448
1449     eval q{
1450         open my $pipe, "/cdrom/install |" or die $!;
1451         my @res = <$pipe>;
1452         close $pipe or die "bad pipe: $?, $!";
1453     };
1454
1455 After execution of this statement all 4 variables may have been set.  
1456
1457 C<$@> is set if the string to be C<eval>-ed did not compile (this
1458 may happen if C<open> or C<close> were imported with bad prototypes),
1459 or if Perl code executed during evaluation die()d .  In these cases
1460 the value of $@ is the compile error, or the argument to C<die>
1461 (which will interpolate C<$!> and C<$?>).  (See also L<Fatal>,
1462 though.)
1463
1464 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1465 and C<close> are translated to calls in the C run-time library and
1466 thence to the operating system kernel.  C<$!> is set to the C library's
1467 C<errno> if one of these calls fails. 
1468
1469 Under a few operating systems, C<$^E> may contain a more verbose
1470 error indicator, such as in this case, "CDROM tray not closed."
1471 Systems that do not support extended error messages leave C<$^E>
1472 the same as C<$!>.
1473
1474 Finally, C<$?> may be set to non-0 value if the external program
1475 F</cdrom/install> fails.  The upper eight bits reflect specific
1476 error conditions encountered by the program (the program's exit()
1477 value).   The lower eight bits reflect mode of failure, like signal
1478 death and core dump information  See wait(2) for details.  In
1479 contrast to C<$!> and C<$^E>, which are set only if error condition
1480 is detected, the variable C<$?> is set on each C<wait> or pipe
1481 C<close>, overwriting the old value.  This is more like C<$@>, which
1482 on every eval() is always set on failure and cleared on success.
1483
1484 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1485 and C<$?>.
1486
1487 =head2 Technical Note on the Syntax of Variable Names
1488
1489 Variable names in Perl can have several formats.  Usually, they
1490 must begin with a letter or underscore, in which case they can be
1491 arbitrarily long (up to an internal limit of 251 characters) and
1492 may contain letters, digits, underscores, or the special sequence
1493 C<::> or C<'>.  In this case, the part before the last C<::> or
1494 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1495
1496 Perl variable names may also be a sequence of digits or a single
1497 punctuation or control character.  These names are all reserved for
1498 special uses by Perl; for example, the all-digits names are used
1499 to hold data captured by backreferences after a regular expression
1500 match.  Perl has a special syntax for the single-control-character
1501 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1502 character.  For example, the notation C<$^W> (dollar-sign caret
1503 C<W>) is the scalar variable whose name is the single character
1504 control-C<W>.  This is better than typing a literal control-C<W>
1505 into your program.
1506
1507 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1508 strings that begin with control characters (or better yet, a caret).
1509 These variables must be written in the form C<${^Foo}>; the braces
1510 are not optional.  C<${^Foo}> denotes the scalar variable whose
1511 name is a control-C<F> followed by two C<o>'s.  These variables are
1512 reserved for future special uses by Perl, except for the ones that
1513 begin with C<^_> (control-underscore or caret-underscore).  No
1514 control-character name that begins with C<^_> will acquire a special
1515 meaning in any future version of Perl; such names may therefore be
1516 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1517
1518 Perl identifiers that begin with digits, control characters, or
1519 punctuation characters are exempt from the effects of the C<package>
1520 declaration and are always forced to be in package C<main>; they are
1521 also exempt from C<strict 'vars'> errors.  A few other names are also
1522 exempt in these ways:
1523
1524         ENV             STDIN
1525         INC             STDOUT
1526         ARGV            STDERR
1527         ARGVOUT         _
1528         SIG
1529
1530 In particular, the new special C<${^_XYZ}> variables are always taken
1531 to be in package C<main>, regardless of any C<package> declarations
1532 presently in scope.  
1533
1534 =head1 BUGS
1535
1536 Due to an unfortunate accident of Perl's implementation, C<use
1537 English> imposes a considerable performance penalty on all regular
1538 expression matches in a program, regardless of whether they occur
1539 in the scope of C<use English>.  For that reason, saying C<use
1540 English> in libraries is strongly discouraged.  See the
1541 Devel::SawAmpersand module documentation from CPAN
1542 ( http://www.cpan.org/modules/by-module/Devel/ )
1543 for more information.
1544
1545 Having to even think about the C<$^S> variable in your exception
1546 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1547 invites grievous and difficult to track down errors.  Avoid it
1548 and use an C<END{}> or CORE::GLOBAL::die override instead.