This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
ae8ff64254dad96031635828e6ae82e335ddc504
[perl5.git] / t / loc_tools.pl
1 # Common tools for test files files to find the locales which exist on the
2 # system.  Caller should have defined ok() for the unlikely event that setup
3 # here fails, and should have verified that this isn't miniperl before calling
4 # the functions.
5
6 # Note that it's okay that some languages have their native names
7 # capitalized here even though that's not "right".  They are lowercased
8 # anyway later during the scanning process (and besides, some clueless
9 # vendor might have them capitalized erroneously anyway).
10
11 sub _trylocale ($$$$) { # Adds the locale given by the first parameter to the
12                         # list given by the 3rd iff the platform supports the
13                         # locale in each of the categories given by the 2nd
14                         # parameter, which is either a single category or a
15                         # reference to a list of categories
16                         # The 4th parameter is true if to reject locales that
17                         # aren't apparently fully compatible with Perl.
18     my $locale = shift;
19     my $categories = shift;
20     my $list = shift;
21     my $only_plays_well = shift;
22
23     return if ! $locale || grep { $locale eq $_ } @$list;
24
25     $categories = [ $categories ] unless ref $categories;
26
27     my $badutf8 = 0;
28     my $plays_well = 1;
29
30     use warnings 'locale';
31
32     local $SIG{__WARN__} = sub {
33         $badutf8 = 1 if $_[0] =~ /Malformed UTF-8/;
34         $plays_well = 0 if $_[0] =~ /Locale .* may not work well/i
35     };
36
37     foreach my $category (@$categories) {
38         return unless setlocale($category, $locale);
39         return if $only_plays_well && ! $plays_well;
40     }
41
42     if ($badutf8) {
43         ok(0, "Verify locale name doesn't contain malformed utf8");
44         return;
45     }
46     push @$list, $locale;
47 }
48
49 sub _decode_encodings {
50     my @enc;
51
52     foreach (split(/ /, shift)) {
53         if (/^(\d+)$/) {
54             push @enc, "ISO8859-$1";
55             push @enc, "iso8859$1";     # HP
56             if ($1 eq '1') {
57                  push @enc, "roman8";   # HP
58             }
59             push @enc, $_;
60             push @enc, "$_.UTF-8";
61             push @enc, "$_.65001"; # Windows UTF-8
62             push @enc, "$_.ACP"; # Windows ANSI code page
63             push @enc, "$_.OCP"; # Windows OEM code page
64             push @enc, "$_.1252"; # Windows
65         }
66     }
67     if ($^O eq 'os390') {
68         push @enc, qw(IBM-037 IBM-819 IBM-1047);
69     }
70     push @enc, "UTF-8";
71     push @enc, "65001"; # Windows UTF-8
72
73     return @enc;
74 }
75
76 # Initialize this hash so that it looks like e.g.,
77 #   6 => 'CTYPE',
78 # where 6 is the value of &POSIX::LC_CTYPE
79 my %category_name;
80 eval { require POSIX; import POSIX 'locale_h'; };
81 unless ($@) {
82     my $number_for_missing_category = 0;
83     foreach my $name (qw(ALL COLLATE CTYPE MESSAGES MONETARY NUMERIC TIME)) {
84         my $number = eval "&POSIX::LC_$name";
85
86         # Use a negative number if the platform doesn't support this category,
87         # so we have an entry for all ones that might be specified in calls to
88         # us.
89         $number = --$number_for_missing_category if $@;
90
91         $category_name{$number} = "$name";
92     }
93 }
94
95 sub locales_enabled(;$) {
96     # Returns 0 if no locale handling is available on this platform; otherwise
97     # 1.
98     #
99     # The optional parameter is a reference to a list of individual POSIX
100     # locale categories.  If present, this function also returns 0 if any of
101     # them are individually not available on this platform; otherwise 1.
102     # Actually, it is acceptable for the list to be just a simple scalar
103     # denoting a single category.
104     #
105     # If any of the individual categories specified by the optional parameter
106     # is all digits, it is taken to be the C enum for the category (e.g.,
107     # &POSIX::LC_CTYPE).  Otherwise it should be a string name of the
108     # category, like 'LC_TIME'.  The initial 'LC_' is optional.  It is a fatal
109     # error to call this with something that isn't a known category
110
111     use Config;;
112
113     return 0 unless    $Config{d_setlocale}
114                         # I (khw) cargo-culted the '?' in the pattern on the
115                         # next line.
116                     && $Config{ccflags} !~ /\bD?NO_LOCALE\b/;
117
118     # Done with the global possibilities.  Now check if any passed in category
119     # is disabled.
120     my $categories_ref = shift;
121     $categories_ref = [ $categories_ref ] if ! ref $categories_ref;
122     for my $category (@$categories_ref) {
123         if ($category =~ /\D/) {
124             $category =~ s/ ^ LC_ //x;
125             die "Invalid locale category name '$category'"
126                 unless grep { $category eq $_ } values %category_name;
127         }
128         else {
129             die "Invalid locale category number '$category'"
130                 unless grep { $category == $_ } keys %category_name;
131             $category = $category_name{$category};
132         }
133
134         return 0 if $Config{ccflags} =~ /\bD?NO_LOCALE_$category\b/;
135     }
136
137     return 1;
138 }
139
140
141 sub find_locales ($;$) {  # Returns an array of all the locales we found on the
142                           # system.  If the optional 2nd parameter is
143                           # non-zero, the list is restricted to those locales
144                           # that play well with Perl.
145                           # The first parameter is either a single locale
146                           # category or a reference to a list of categories to
147                           # find valid locales for it (or in the case of
148                           # multiple) for all of them.
149     my $categories = shift;
150     my $only_plays_well = shift // 0;
151
152     return unless locales_enabled($categories);
153
154     # Visual C's CRT goes silly on strings of the form "en_US.ISO8859-1"
155     # and mingw32 uses said silly CRT
156     # This doesn't seem to be an issue any more, at least on Windows XP,
157     # so re-enable the tests for Windows XP onwards.
158     my $winxp = ($^O eq 'MSWin32' && defined &Win32::GetOSVersion &&
159                     join('.', (Win32::GetOSVersion())[1..2]) >= 5.1);
160     return if ((($^O eq 'MSWin32' && !$winxp) || $^O eq 'NetWare')
161                 && $Config{cc} =~ /^(cl|gcc|g\+\+|ici)/i);
162
163     # UWIN seems to loop after taint tests, just skip for now
164     return if ($^O =~ /^uwin/);
165
166     # Done this way in case this is 'required' in the caller before seeing if
167     # this is miniperl.
168     eval { require POSIX; import POSIX 'locale_h'; };
169     unless (defined &POSIX::LC_CTYPE) {
170       return;
171     }
172
173     _trylocale("C", $categories, \@Locale, $only_plays_well);
174     _trylocale("POSIX", $categories, \@Locale, $only_plays_well);
175     foreach (0..15) {
176         _trylocale("ISO8859-$_", $categories, \@Locale, $only_plays_well);
177         _trylocale("iso8859$_", $categories, \@Locale, $only_plays_well);
178         _trylocale("iso8859-$_", $categories, \@Locale, $only_plays_well);
179         _trylocale("iso_8859_$_", $categories, \@Locale, $only_plays_well);
180         _trylocale("isolatin$_", $categories, \@Locale, $only_plays_well);
181         _trylocale("isolatin-$_", $categories, \@Locale, $only_plays_well);
182         _trylocale("iso_latin_$_", $categories, \@Locale, $only_plays_well);
183     }
184
185     # Sanitize the environment so that we can run the external 'locale'
186     # program without the taint mode getting grumpy.
187
188     # $ENV{PATH} is special in VMS.
189     delete local $ENV{PATH} if $^O ne 'VMS' or $Config{d_setenv};
190
191     # Other subversive stuff.
192     delete local @ENV{qw(IFS CDPATH ENV BASH_ENV)};
193
194     if (-x "/usr/bin/locale"
195         && open(LOCALES, "/usr/bin/locale -a 2>/dev/null|"))
196     {
197         while (<LOCALES>) {
198             # It seems that /usr/bin/locale steadfastly outputs 8 bit data, which
199             # ain't great when we're running this testPERL_UNICODE= so that utf8
200             # locales will cause all IO hadles to default to (assume) utf8
201             next unless utf8::valid($_);
202             chomp;
203             _trylocale($_, $categories, \@Locale, $only_plays_well);
204         }
205         close(LOCALES);
206     } elsif ($^O eq 'VMS'
207              && defined($ENV{'SYS$I18N_LOCALE'})
208              && -d 'SYS$I18N_LOCALE')
209     {
210     # The SYS$I18N_LOCALE logical name search list was not present on
211     # VAX VMS V5.5-12, but was on AXP && VAX VMS V6.2 as well as later versions.
212         opendir(LOCALES, "SYS\$I18N_LOCALE:");
213         while ($_ = readdir(LOCALES)) {
214             chomp;
215             _trylocale($_, $categories, \@Locale, $only_plays_well);
216         }
217         close(LOCALES);
218     } elsif (($^O eq 'openbsd' || $^O eq 'bitrig' ) && -e '/usr/share/locale') {
219
220     # OpenBSD doesn't have a locale executable, so reading /usr/share/locale
221     # is much easier and faster than the last resort method.
222
223         opendir(LOCALES, '/usr/share/locale');
224         while ($_ = readdir(LOCALES)) {
225             chomp;
226             _trylocale($_, $categories, \@Locale, $only_plays_well);
227         }
228         close(LOCALES);
229     } else { # Final fallback.  Try our list of locales hard-coded here
230
231         # This is going to be slow.
232         my @Data;
233
234         # Locales whose name differs if the utf8 bit is on are stored in these two
235         # files with appropriate encodings.
236         if ($^H & 0x08 || (${^OPEN} || "") =~ /:utf8/) {
237             @Data = do "lib/locale/utf8";
238         } else {
239             @Data = do "lib/locale/latin1";
240         }
241
242         # The rest of the locales are in this file.
243         push @Data, <DATA>;
244
245         foreach my $line (@Data) {
246             my ($locale_name, $language_codes, $country_codes, $encodings) =
247                 split /:/, $line;
248             my @enc = _decode_encodings($encodings);
249             foreach my $loc (split(/ /, $locale_name)) {
250                 _trylocale($loc, $categories, \@Locale, $only_plays_well);
251                 foreach my $enc (@enc) {
252                     _trylocale("$loc.$enc", $categories, \@Locale,
253                                                             $only_plays_well);
254                 }
255                 $loc = lc $loc;
256                 foreach my $enc (@enc) {
257                     _trylocale("$loc.$enc", $categories, \@Locale,
258                                                             $only_plays_well);
259                 }
260             }
261             foreach my $lang (split(/ /, $language_codes)) {
262                 _trylocale($lang, $categories, \@Locale, $only_plays_well);
263                 foreach my $country (split(/ /, $country_codes)) {
264                     my $lc = "${lang}_${country}";
265                     _trylocale($lc, $categories, \@Locale, $only_plays_well);
266                     foreach my $enc (@enc) {
267                         _trylocale("$lc.$enc", $categories, \@Locale,
268                                                             $only_plays_well);
269                     }
270                     my $lC = "${lang}_\U${country}";
271                     _trylocale($lC, $categories, \@Locale, $only_plays_well);
272                     foreach my $enc (@enc) {
273                         _trylocale("$lC.$enc", $categories, \@Locale,
274                                                             $only_plays_well);
275                     }
276                 }
277             }
278         }
279     }
280
281     @Locale = sort @Locale;
282
283     return @Locale;
284 }
285
286 sub is_locale_utf8 ($) { # Return a boolean as to if core Perl thinks the input
287                          # is a UTF-8 locale
288
289     # On z/OS, even locales marked as UTF-8 aren't.
290     return 0 if ord "A" != 65;
291
292     eval { require POSIX; import POSIX 'locale_h'; };
293     return 0 if ! defined &POSIX::LC_CTYPE;
294     return 0 if ! locales_enabled('LC_CTYPE');
295
296     my $locale = shift;
297
298     use locale;
299     no warnings 'locale'; # We may be trying out a weird locale
300
301     my $save_locale = setlocale(&POSIX::LC_CTYPE());
302     if (! $save_locale) {
303         ok(0, "Verify could save previous locale");
304         return 0;
305     }
306
307     if (! setlocale(&POSIX::LC_CTYPE(), $locale)) {
308         ok(0, "Verify could setlocale to $locale");
309         return 0;
310     }
311
312     my $ret = 0;
313
314     # Use an op that gives different results for UTF-8 than any other locale.
315     # If a platform has UTF-8 locales, there should be at least one locale on
316     # most platforms with UTF-8 in its name, so if there is a bug in the op
317     # giving a false negative, we should get a failure for those locales as we
318     # go through testing all the locales on the platform.
319     if (CORE::fc(chr utf8::unicode_to_native(0xdf)) ne "ss") {
320         if ($locale =~ /UTF-?8/i) {
321             ok (0, "Verify $locale with UTF-8 in name is a UTF-8 locale");
322         }
323     }
324     else {
325         $ret = 1;
326     }
327
328     die "Couldn't restore locale '$save_locale'"
329         unless setlocale(&POSIX::LC_CTYPE(), $save_locale);
330
331     return $ret;
332 }
333
334 sub find_utf8_ctype_locale (;$) { # Return the name of a locale that core Perl
335                                   # thinks is a UTF-8 LC_CTYPE locale.
336                                   # Optional parameter is a reference to a
337                                   # list of locales to try; if omitted, this
338                                   # tries all locales it can find on the
339                                   # platform
340     my $locales_ref = shift;
341
342     if (! defined $locales_ref) {
343         eval { require POSIX; import POSIX 'locale_h'; };
344         return if ! defined &POSIX::LC_CTYPE;
345
346         my @locales = find_locales(&POSIX::LC_CTYPE(),
347                                    1 # Reject iffy locales.
348                                   );
349         $locales_ref = \@locales;
350     }
351
352     foreach my $locale (@$locales_ref) {
353         return $locale if is_locale_utf8($locale);
354     }
355
356     return;
357 }
358
359 1
360
361 # Format of data is: locale_name, language_codes, country_codes, encodings
362 __DATA__
363 Afrikaans:af:za:1 15
364 Arabic:ar:dz eg sa:6 arabic8
365 Brezhoneg Breton:br:fr:1 15
366 Bulgarski Bulgarian:bg:bg:5
367 Chinese:zh:cn tw:cn.EUC eucCN eucTW euc.CN euc.TW Big5 GB2312 tw.EUC
368 Hrvatski Croatian:hr:hr:2
369 Cymraeg Welsh:cy:cy:1 14 15
370 Czech:cs:cz:2
371 Dansk Danish:da:dk:1 15
372 Nederlands Dutch:nl:be nl:1 15
373 English American British:en:au ca gb ie nz us uk zw:1 15 cp850
374 Esperanto:eo:eo:3
375 Eesti Estonian:et:ee:4 6 13
376 Suomi Finnish:fi:fi:1 15
377 Flamish::fl:1 15
378 Deutsch German:de:at be ch de lu:1 15
379 Euskaraz Basque:eu:es fr:1 15
380 Galego Galician:gl:es:1 15
381 Ellada Greek:el:gr:7 g8
382 Frysk:fy:nl:1 15
383 Greenlandic:kl:gl:4 6
384 Hebrew:iw:il:8 hebrew8
385 Hungarian:hu:hu:2
386 Indonesian:id:id:1 15
387 Gaeilge Irish:ga:IE:1 14 15
388 Italiano Italian:it:ch it:1 15
389 Nihongo Japanese:ja:jp:euc eucJP jp.EUC sjis
390 Korean:ko:kr:
391 Latine Latin:la:va:1 15
392 Latvian:lv:lv:4 6 13
393 Lithuanian:lt:lt:4 6 13
394 Macedonian:mk:mk:1 15
395 Maltese:mt:mt:3
396 Moldovan:mo:mo:2
397 Norsk Norwegian:no no\@nynorsk nb nn:no:1 15
398 Occitan:oc:es:1 15
399 Polski Polish:pl:pl:2
400 Rumanian:ro:ro:2
401 Russki Russian:ru:ru su ua:5 koi8 koi8r KOI8-R koi8u cp1251 cp866
402 Serbski Serbian:sr:yu:5
403 Slovak:sk:sk:2
404 Slovene Slovenian:sl:si:2
405 Sqhip Albanian:sq:sq:1 15
406 Svenska Swedish:sv:fi se:1 15
407 Thai:th:th:11 tis620
408 Turkish:tr:tr:9 turkish8
409 Yiddish:yi::1 15