This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Upgrade to CGI-3.20
[perl5.git] / lib / CGI.pm
1 package CGI;
2 require 5.004;
3 use Carp 'croak';
4
5 # See the bottom of this file for the POD documentation.  Search for the
6 # string '=head'.
7
8 # You can run this file through either pod2man or pod2html to produce pretty
9 # documentation in manual or html file format (these utilities are part of the
10 # Perl 5 distribution).
11
12 # Copyright 1995-1998 Lincoln D. Stein.  All rights reserved.
13 # It may be used and modified freely, but I do request that this copyright
14 # notice remain attached to the file.  You may modify this module as you 
15 # wish, but if you redistribute a modified version, please attach a note
16 # listing the modifications you have made.
17
18 # The most recent version and complete docs are available at:
19 #   http://stein.cshl.org/WWW/software/CGI/
20
21 $CGI::revision = '$Id: CGI.pm,v 1.208 2006/04/23 14:25:14 lstein Exp $';
22 $CGI::VERSION='3.20';
23
24 # HARD-CODED LOCATION FOR FILE UPLOAD TEMPORARY FILES.
25 # UNCOMMENT THIS ONLY IF YOU KNOW WHAT YOU'RE DOING.
26 # $CGITempFile::TMPDIRECTORY = '/usr/tmp';
27 use CGI::Util qw(rearrange make_attributes unescape escape expires ebcdic2ascii ascii2ebcdic);
28
29 #use constant XHTML_DTD => ['-//W3C//DTD XHTML Basic 1.0//EN',
30 #                           'http://www.w3.org/TR/xhtml-basic/xhtml-basic10.dtd'];
31
32 use constant XHTML_DTD => ['-//W3C//DTD XHTML 1.0 Transitional//EN',
33                            'http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd'];
34
35 {
36   local $^W = 0;
37   $TAINTED = substr("$0$^X",0,0);
38 }
39
40 $MOD_PERL = 0; # no mod_perl by default
41 @SAVED_SYMBOLS = ();
42
43
44 # >>>>> Here are some globals that you might want to adjust <<<<<<
45 sub initialize_globals {
46     # Set this to 1 to enable copious autoloader debugging messages
47     $AUTOLOAD_DEBUG = 0;
48
49     # Set this to 1 to generate XTML-compatible output
50     $XHTML = 1;
51
52     # Change this to the preferred DTD to print in start_html()
53     # or use default_dtd('text of DTD to use');
54     $DEFAULT_DTD = [ '-//W3C//DTD HTML 4.01 Transitional//EN',
55                      'http://www.w3.org/TR/html4/loose.dtd' ] ;
56
57     # Set this to 1 to enable NOSTICKY scripts
58     # or: 
59     #    1) use CGI qw(-nosticky)
60     #    2) $CGI::nosticky(1)
61     $NOSTICKY = 0;
62
63     # Set this to 1 to enable NPH scripts
64     # or: 
65     #    1) use CGI qw(-nph)
66     #    2) CGI::nph(1)
67     #    3) print header(-nph=>1)
68     $NPH = 0;
69
70     # Set this to 1 to enable debugging from @ARGV
71     # Set to 2 to enable debugging from STDIN
72     $DEBUG = 1;
73
74     # Set this to 1 to make the temporary files created
75     # during file uploads safe from prying eyes
76     # or do...
77     #    1) use CGI qw(:private_tempfiles)
78     #    2) CGI::private_tempfiles(1);
79     $PRIVATE_TEMPFILES = 0;
80
81     # Set this to 1 to generate automatic tab indexes
82     $TABINDEX = 0;
83
84     # Set this to 1 to cause files uploaded in multipart documents
85     # to be closed, instead of caching the file handle
86     # or:
87     #    1) use CGI qw(:close_upload_files)
88     #    2) $CGI::close_upload_files(1);
89     # Uploads with many files run out of file handles.
90     # Also, for performance, since the file is already on disk,
91     # it can just be renamed, instead of read and written.
92     $CLOSE_UPLOAD_FILES = 0;
93
94     # Set this to a positive value to limit the size of a POSTing
95     # to a certain number of bytes:
96     $POST_MAX = -1;
97
98     # Change this to 1 to disable uploads entirely:
99     $DISABLE_UPLOADS = 0;
100
101     # Automatically determined -- don't change
102     $EBCDIC = 0;
103
104     # Change this to 1 to suppress redundant HTTP headers
105     $HEADERS_ONCE = 0;
106
107     # separate the name=value pairs by semicolons rather than ampersands
108     $USE_PARAM_SEMICOLONS = 1;
109
110     # Do not include undefined params parsed from query string
111     # use CGI qw(-no_undef_params);
112     $NO_UNDEF_PARAMS = 0;
113
114     # Other globals that you shouldn't worry about.
115     undef $Q;
116     $BEEN_THERE = 0;
117     $DTD_PUBLIC_IDENTIFIER = "";
118     undef @QUERY_PARAM;
119     undef %EXPORT;
120     undef $QUERY_CHARSET;
121     undef %QUERY_FIELDNAMES;
122
123     # prevent complaints by mod_perl
124     1;
125 }
126
127 # ------------------ START OF THE LIBRARY ------------
128
129 *end_form = \&endform;
130
131 # make mod_perlhappy
132 initialize_globals();
133
134 # FIGURE OUT THE OS WE'RE RUNNING UNDER
135 # Some systems support the $^O variable.  If not
136 # available then require() the Config library
137 unless ($OS) {
138     unless ($OS = $^O) {
139         require Config;
140         $OS = $Config::Config{'osname'};
141     }
142 }
143 if ($OS =~ /^MSWin/i) {
144   $OS = 'WINDOWS';
145 } elsif ($OS =~ /^VMS/i) {
146   $OS = 'VMS';
147 } elsif ($OS =~ /^dos/i) {
148   $OS = 'DOS';
149 } elsif ($OS =~ /^MacOS/i) {
150     $OS = 'MACINTOSH';
151 } elsif ($OS =~ /^os2/i) {
152     $OS = 'OS2';
153 } elsif ($OS =~ /^epoc/i) {
154     $OS = 'EPOC';
155 } elsif ($OS =~ /^cygwin/i) {
156     $OS = 'CYGWIN';
157 } else {
158     $OS = 'UNIX';
159 }
160
161 # Some OS logic.  Binary mode enabled on DOS, NT and VMS
162 $needs_binmode = $OS=~/^(WINDOWS|DOS|OS2|MSWin|CYGWIN)/;
163
164 # This is the default class for the CGI object to use when all else fails.
165 $DefaultClass = 'CGI' unless defined $CGI::DefaultClass;
166
167 # This is where to look for autoloaded routines.
168 $AutoloadClass = $DefaultClass unless defined $CGI::AutoloadClass;
169
170 # The path separator is a slash, backslash or semicolon, depending
171 # on the paltform.
172 $SL = {
173      UNIX    => '/',  OS2 => '\\', EPOC      => '/', CYGWIN => '/',
174      WINDOWS => '\\', DOS => '\\', MACINTOSH => ':', VMS    => '/'
175     }->{$OS};
176
177 # This no longer seems to be necessary
178 # Turn on NPH scripts by default when running under IIS server!
179 # $NPH++ if defined($ENV{'SERVER_SOFTWARE'}) && $ENV{'SERVER_SOFTWARE'}=~/IIS/;
180 $IIS++ if defined($ENV{'SERVER_SOFTWARE'}) && $ENV{'SERVER_SOFTWARE'}=~/IIS/;
181
182 # Turn on special checking for Doug MacEachern's modperl
183 if (exists $ENV{MOD_PERL}) {
184   # mod_perl handlers may run system() on scripts using CGI.pm;
185   # Make sure so we don't get fooled by inherited $ENV{MOD_PERL}
186   if (exists $ENV{MOD_PERL_API_VERSION} && $ENV{MOD_PERL_API_VERSION} == 2) {
187     $MOD_PERL = 2;
188     require Apache2::Response;
189     require Apache2::RequestRec;
190     require Apache2::RequestUtil;
191     require Apache2::RequestIO;
192     require APR::Pool;
193   } else {
194     $MOD_PERL = 1;
195     require Apache;
196   }
197 }
198
199 # Turn on special checking for ActiveState's PerlEx
200 $PERLEX++ if defined($ENV{'GATEWAY_INTERFACE'}) && $ENV{'GATEWAY_INTERFACE'} =~ /^CGI-PerlEx/;
201
202 # Define the CRLF sequence.  I can't use a simple "\r\n" because the meaning
203 # of "\n" is different on different OS's (sometimes it generates CRLF, sometimes LF
204 # and sometimes CR).  The most popular VMS web server
205 # doesn't accept CRLF -- instead it wants a LR.  EBCDIC machines don't
206 # use ASCII, so \015\012 means something different.  I find this all 
207 # really annoying.
208 $EBCDIC = "\t" ne "\011";
209 if ($OS eq 'VMS') {
210   $CRLF = "\n";
211 } elsif ($EBCDIC) {
212   $CRLF= "\r\n";
213 } else {
214   $CRLF = "\015\012";
215 }
216
217 if ($needs_binmode) {
218     $CGI::DefaultClass->binmode(\*main::STDOUT);
219     $CGI::DefaultClass->binmode(\*main::STDIN);
220     $CGI::DefaultClass->binmode(\*main::STDERR);
221 }
222
223 %EXPORT_TAGS = (
224                 ':html2'=>['h1'..'h6',qw/p br hr ol ul li dl dt dd menu code var strong em
225                            tt u i b blockquote pre img a address cite samp dfn html head
226                            base body Link nextid title meta kbd start_html end_html
227                            input Select option comment charset escapeHTML/],
228                 ':html3'=>[qw/div table caption th td TR Tr sup Sub strike applet Param 
229                            embed basefont style span layer ilayer font frameset frame script small big Area Map/],
230                 ':html4'=>[qw/abbr acronym bdo col colgroup del fieldset iframe
231                             ins label legend noframes noscript object optgroup Q 
232                             thead tbody tfoot/], 
233                 ':netscape'=>[qw/blink fontsize center/],
234                 ':form'=>[qw/textfield textarea filefield password_field hidden checkbox checkbox_group 
235                           submit reset defaults radio_group popup_menu button autoEscape
236                           scrolling_list image_button start_form end_form startform endform
237                           start_multipart_form end_multipart_form isindex tmpFileName uploadInfo URL_ENCODED MULTIPART/],
238                 ':cgi'=>[qw/param upload path_info path_translated request_uri url self_url script_name 
239                          cookie Dump
240                          raw_cookie request_method query_string Accept user_agent remote_host content_type
241                          remote_addr referer server_name server_software server_port server_protocol virtual_port
242                          virtual_host remote_ident auth_type http append
243                          save_parameters restore_parameters param_fetch
244                          remote_user user_name header redirect import_names put 
245                          Delete Delete_all url_param cgi_error/],
246                 ':ssl' => [qw/https/],
247                 ':cgi-lib' => [qw/ReadParse PrintHeader HtmlTop HtmlBot SplitParam Vars/],
248                 ':html' => [qw/:html2 :html3 :html4 :netscape/],
249                 ':standard' => [qw/:html2 :html3 :html4 :form :cgi/],
250                 ':push' => [qw/multipart_init multipart_start multipart_end multipart_final/],
251                 ':all' => [qw/:html2 :html3 :netscape :form :cgi :internal :html4/]
252                 );
253
254 # Custom 'can' method for both autoloaded and non-autoloaded subroutines.
255 # Author: Cees Hek <cees@sitesuite.com.au>
256
257 sub can {
258         my($class, $method) = @_;
259
260         # See if UNIVERSAL::can finds it.
261
262         if (my $func = $class -> SUPER::can($method) ){
263                 return $func;
264         }
265
266         # Try to compile the function.
267
268         eval {
269                 # _compile looks at $AUTOLOAD for the function name.
270
271                 local $AUTOLOAD = join "::", $class, $method;
272                 &_compile;
273         };
274
275         # Now that the function is loaded (if it exists)
276         # just use UNIVERSAL::can again to do the work.
277
278         return $class -> SUPER::can($method);
279 }
280
281 # to import symbols into caller
282 sub import {
283     my $self = shift;
284
285     # This causes modules to clash.
286     undef %EXPORT_OK;
287     undef %EXPORT;
288
289     $self->_setup_symbols(@_);
290     my ($callpack, $callfile, $callline) = caller;
291
292     # To allow overriding, search through the packages
293     # Till we find one in which the correct subroutine is defined.
294     my @packages = ($self,@{"$self\:\:ISA"});
295     foreach $sym (keys %EXPORT) {
296         my $pck;
297         my $def = ${"$self\:\:AutoloadClass"} || $DefaultClass;
298         foreach $pck (@packages) {
299             if (defined(&{"$pck\:\:$sym"})) {
300                 $def = $pck;
301                 last;
302             }
303         }
304         *{"${callpack}::$sym"} = \&{"$def\:\:$sym"};
305     }
306 }
307
308 sub compile {
309     my $pack = shift;
310     $pack->_setup_symbols('-compile',@_);
311 }
312
313 sub expand_tags {
314     my($tag) = @_;
315     return ("start_$1","end_$1") if $tag=~/^(?:\*|start_|end_)(.+)/;
316     my(@r);
317     return ($tag) unless $EXPORT_TAGS{$tag};
318     foreach (@{$EXPORT_TAGS{$tag}}) {
319         push(@r,&expand_tags($_));
320     }
321     return @r;
322 }
323
324 #### Method: new
325 # The new routine.  This will check the current environment
326 # for an existing query string, and initialize itself, if so.
327 ####
328 sub new {
329   my($class,@initializer) = @_;
330   my $self = {};
331
332   bless $self,ref $class || $class || $DefaultClass;
333
334   # always use a tempfile
335   $self->{'use_tempfile'} = 1;
336
337   if (ref($initializer[0])
338       && (UNIVERSAL::isa($initializer[0],'Apache')
339           ||
340           UNIVERSAL::isa($initializer[0],'Apache2::RequestRec')
341          )) {
342     $self->r(shift @initializer);
343   }
344  if (ref($initializer[0]) 
345      && (UNIVERSAL::isa($initializer[0],'CODE'))) {
346     $self->upload_hook(shift @initializer, shift @initializer);
347     $self->{'use_tempfile'} = shift @initializer if (@initializer > 0);
348   }
349   if ($MOD_PERL) {
350     if ($MOD_PERL == 1) {
351       $self->r(Apache->request) unless $self->r;
352       my $r = $self->r;
353       $r->register_cleanup(\&CGI::_reset_globals);
354     }
355     else {
356       # XXX: once we have the new API
357       # will do a real PerlOptions -SetupEnv check
358       $self->r(Apache2::RequestUtil->request) unless $self->r;
359       my $r = $self->r;
360       $r->subprocess_env unless exists $ENV{REQUEST_METHOD};
361       $r->pool->cleanup_register(\&CGI::_reset_globals);
362     }
363     undef $NPH;
364   }
365   $self->_reset_globals if $PERLEX;
366   $self->init(@initializer);
367   return $self;
368 }
369
370 # We provide a DESTROY method so that we can ensure that
371 # temporary files are closed (via Fh->DESTROY) before they
372 # are unlinked (via CGITempFile->DESTROY) because it is not
373 # possible to unlink an open file on Win32. We explicitly
374 # call DESTROY on each, rather than just undefing them and
375 # letting Perl DESTROY them by garbage collection, in case the
376 # user is still holding any reference to them as well.
377 sub DESTROY {
378   my $self = shift;
379   if ($OS eq 'WINDOWS') {
380     foreach my $href (values %{$self->{'.tmpfiles'}}) {
381       $href->{hndl}->DESTROY if defined $href->{hndl};
382       $href->{name}->DESTROY if defined $href->{name};
383     }
384   }
385 }
386
387 sub r {
388   my $self = shift;
389   my $r = $self->{'.r'};
390   $self->{'.r'} = shift if @_;
391   $r;
392 }
393
394 sub upload_hook {
395   my $self;
396   if (ref $_[0] eq 'CODE') {
397     $CGI::Q = $self = $CGI::DefaultClass->new(@_);
398   } else {
399     $self = shift;
400   }
401   my ($hook,$data,$use_tempfile) = @_;
402   $self->{'.upload_hook'} = $hook;
403   $self->{'.upload_data'} = $data;
404   $self->{'use_tempfile'} = $use_tempfile if defined $use_tempfile;
405 }
406
407 #### Method: param
408 # Returns the value(s)of a named parameter.
409 # If invoked in a list context, returns the
410 # entire list.  Otherwise returns the first
411 # member of the list.
412 # If name is not provided, return a list of all
413 # the known parameters names available.
414 # If more than one argument is provided, the
415 # second and subsequent arguments are used to
416 # set the value of the parameter.
417 ####
418 sub param {
419     my($self,@p) = self_or_default(@_);
420     return $self->all_parameters unless @p;
421     my($name,$value,@other);
422
423     # For compatibility between old calling style and use_named_parameters() style, 
424     # we have to special case for a single parameter present.
425     if (@p > 1) {
426         ($name,$value,@other) = rearrange([NAME,[DEFAULT,VALUE,VALUES]],@p);
427         my(@values);
428
429         if (substr($p[0],0,1) eq '-') {
430             @values = defined($value) ? (ref($value) && ref($value) eq 'ARRAY' ? @{$value} : $value) : ();
431         } else {
432             foreach ($value,@other) {
433                 push(@values,$_) if defined($_);
434             }
435         }
436         # If values is provided, then we set it.
437         if (defined $value) {
438             $self->add_parameter($name);
439             $self->{$name}=[@values];
440         }
441     } else {
442         $name = $p[0];
443     }
444
445     return unless defined($name) && $self->{$name};
446     return wantarray ? @{$self->{$name}} : $self->{$name}->[0];
447 }
448
449 sub self_or_default {
450     return @_ if defined($_[0]) && (!ref($_[0])) &&($_[0] eq 'CGI');
451     unless (defined($_[0]) && 
452             (ref($_[0]) eq 'CGI' || UNIVERSAL::isa($_[0],'CGI')) # slightly optimized for common case
453             ) {
454         $Q = $CGI::DefaultClass->new unless defined($Q);
455         unshift(@_,$Q);
456     }
457     return wantarray ? @_ : $Q;
458 }
459
460 sub self_or_CGI {
461     local $^W=0;                # prevent a warning
462     if (defined($_[0]) &&
463         (substr(ref($_[0]),0,3) eq 'CGI' 
464          || UNIVERSAL::isa($_[0],'CGI'))) {
465         return @_;
466     } else {
467         return ($DefaultClass,@_);
468     }
469 }
470
471 ########################################
472 # THESE METHODS ARE MORE OR LESS PRIVATE
473 # GO TO THE __DATA__ SECTION TO SEE MORE
474 # PUBLIC METHODS
475 ########################################
476
477 # Initialize the query object from the environment.
478 # If a parameter list is found, this object will be set
479 # to an associative array in which parameter names are keys
480 # and the values are stored as lists
481 # If a keyword list is found, this method creates a bogus
482 # parameter list with the single parameter 'keywords'.
483
484 sub init {
485   my $self = shift;
486   my($query_string,$meth,$content_length,$fh,@lines) = ('','','','');
487
488   my $initializer = shift;  # for backward compatibility
489   local($/) = "\n";
490
491     # set autoescaping on by default
492     $self->{'escape'} = 1;
493
494     # if we get called more than once, we want to initialize
495     # ourselves from the original query (which may be gone
496     # if it was read from STDIN originally.)
497     if (defined(@QUERY_PARAM) && !defined($initializer)) {
498         foreach (@QUERY_PARAM) {
499             $self->param('-name'=>$_,'-value'=>$QUERY_PARAM{$_});
500         }
501         $self->charset($QUERY_CHARSET);
502         $self->{'.fieldnames'} = {%QUERY_FIELDNAMES};
503         return;
504     }
505
506     $meth=$ENV{'REQUEST_METHOD'} if defined($ENV{'REQUEST_METHOD'});
507     $content_length = defined($ENV{'CONTENT_LENGTH'}) ? $ENV{'CONTENT_LENGTH'} : 0;
508
509     $fh = to_filehandle($initializer) if $initializer;
510
511     # set charset to the safe ISO-8859-1
512     $self->charset('ISO-8859-1');
513
514   METHOD: {
515
516       # avoid unreasonably large postings
517       if (($POST_MAX > 0) && ($content_length > $POST_MAX)) {
518         # quietly read and discard the post
519           my $buffer;
520           my $tmplength = $content_length;
521           while($tmplength > 0) {
522                  my $maxbuffer = ($tmplength < 10000)?$tmplength:10000;
523                  my $bytesread = $MOD_PERL ? $self->r->read($buffer,$maxbuffer) : read(STDIN,$buffer,$maxbuffer);
524                  $tmplength -= $bytesread;
525           }
526           $self->cgi_error("413 Request entity too large");
527           last METHOD;
528        }
529
530       # Process multipart postings, but only if the initializer is
531       # not defined.
532       if ($meth eq 'POST'
533           && defined($ENV{'CONTENT_TYPE'})
534           && $ENV{'CONTENT_TYPE'}=~m|^multipart/form-data|
535           && !defined($initializer)
536           ) {
537           my($boundary) = $ENV{'CONTENT_TYPE'} =~ /boundary=\"?([^\";,]+)\"?/;
538           $self->read_multipart($boundary,$content_length);
539           last METHOD;
540       } 
541
542       # If initializer is defined, then read parameters
543       # from it.
544       if (defined($initializer)) {
545           if (UNIVERSAL::isa($initializer,'CGI')) {
546               $query_string = $initializer->query_string;
547               last METHOD;
548           }
549           if (ref($initializer) && ref($initializer) eq 'HASH') {
550               foreach (keys %$initializer) {
551                   $self->param('-name'=>$_,'-value'=>$initializer->{$_});
552               }
553               last METHOD;
554           }
555           
556           if (defined($fh) && ($fh ne '')) {
557               while (<$fh>) {
558                   chomp;
559                   last if /^=/;
560                   push(@lines,$_);
561               }
562               # massage back into standard format
563               if ("@lines" =~ /=/) {
564                   $query_string=join("&",@lines);
565               } else {
566                   $query_string=join("+",@lines);
567               }
568               last METHOD;
569           }
570
571           if (defined($fh) && ($fh ne '')) {
572               while (<$fh>) {
573                   chomp;
574                   last if /^=/;
575                   push(@lines,$_);
576               }
577               # massage back into standard format
578               if ("@lines" =~ /=/) {
579                   $query_string=join("&",@lines);
580               } else {
581                   $query_string=join("+",@lines);
582               }
583               last METHOD;
584           }
585
586           # last chance -- treat it as a string
587           $initializer = $$initializer if ref($initializer) eq 'SCALAR';
588           $query_string = $initializer;
589
590           last METHOD;
591       }
592
593       # If method is GET or HEAD, fetch the query from
594       # the environment.
595       if ($meth=~/^(GET|HEAD)$/) {
596           if ($MOD_PERL) {
597             $query_string = $self->r->args;
598           } else {
599               $query_string = $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
600               $query_string ||= $ENV{'REDIRECT_QUERY_STRING'} if defined $ENV{'REDIRECT_QUERY_STRING'};
601           }
602           last METHOD;
603       }
604
605       if ($meth eq 'POST') {
606           $self->read_from_client(\$query_string,$content_length,0)
607               if $content_length > 0;
608           # Some people want to have their cake and eat it too!
609           # Uncomment this line to have the contents of the query string
610           # APPENDED to the POST data.
611           # $query_string .= (length($query_string) ? '&' : '') . $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
612           last METHOD;
613       }
614
615       # If $meth is not of GET, POST or HEAD, assume we're being debugged offline.
616       # Check the command line and then the standard input for data.
617       # We use the shellwords package in order to behave the way that
618       # UN*X programmers expect.
619       if ($DEBUG)
620       {
621           my $cmdline_ret = read_from_cmdline();
622           $query_string = $cmdline_ret->{'query_string'};
623           if (defined($cmdline_ret->{'subpath'}))
624           {
625               $self->path_info($cmdline_ret->{'subpath'});
626           }
627       }
628   }
629
630 # YL: Begin Change for XML handler 10/19/2001
631     if ($meth eq 'POST'
632         && defined($ENV{'CONTENT_TYPE'})
633         && $ENV{'CONTENT_TYPE'} !~ m|^application/x-www-form-urlencoded|
634         && $ENV{'CONTENT_TYPE'} !~ m|^multipart/form-data| ) {
635         my($param) = 'POSTDATA' ;
636         $self->add_parameter($param) ;
637       push (@{$self->{$param}},$query_string);
638       undef $query_string ;
639     }
640 # YL: End Change for XML handler 10/19/2001
641
642     # We now have the query string in hand.  We do slightly
643     # different things for keyword lists and parameter lists.
644     if (defined $query_string && length $query_string) {
645         if ($query_string =~ /[&=;]/) {
646             $self->parse_params($query_string);
647         } else {
648             $self->add_parameter('keywords');
649             $self->{'keywords'} = [$self->parse_keywordlist($query_string)];
650         }
651     }
652
653     # Special case.  Erase everything if there is a field named
654     # .defaults.
655     if ($self->param('.defaults')) {
656       $self->delete_all();
657     }
658
659     # Associative array containing our defined fieldnames
660     $self->{'.fieldnames'} = {};
661     foreach ($self->param('.cgifields')) {
662         $self->{'.fieldnames'}->{$_}++;
663     }
664     
665     # Clear out our default submission button flag if present
666     $self->delete('.submit');
667     $self->delete('.cgifields');
668
669     $self->save_request unless defined $initializer;
670 }
671
672 # FUNCTIONS TO OVERRIDE:
673 # Turn a string into a filehandle
674 sub to_filehandle {
675     my $thingy = shift;
676     return undef unless $thingy;
677     return $thingy if UNIVERSAL::isa($thingy,'GLOB');
678     return $thingy if UNIVERSAL::isa($thingy,'FileHandle');
679     if (!ref($thingy)) {
680         my $caller = 1;
681         while (my $package = caller($caller++)) {
682             my($tmp) = $thingy=~/[\':]/ ? $thingy : "$package\:\:$thingy"; 
683             return $tmp if defined(fileno($tmp));
684         }
685     }
686     return undef;
687 }
688
689 # send output to the browser
690 sub put {
691     my($self,@p) = self_or_default(@_);
692     $self->print(@p);
693 }
694
695 # print to standard output (for overriding in mod_perl)
696 sub print {
697     shift;
698     CORE::print(@_);
699 }
700
701 # get/set last cgi_error
702 sub cgi_error {
703     my ($self,$err) = self_or_default(@_);
704     $self->{'.cgi_error'} = $err if defined $err;
705     return $self->{'.cgi_error'};
706 }
707
708 sub save_request {
709     my($self) = @_;
710     # We're going to play with the package globals now so that if we get called
711     # again, we initialize ourselves in exactly the same way.  This allows
712     # us to have several of these objects.
713     @QUERY_PARAM = $self->param; # save list of parameters
714     foreach (@QUERY_PARAM) {
715       next unless defined $_;
716       $QUERY_PARAM{$_}=$self->{$_};
717     }
718     $QUERY_CHARSET = $self->charset;
719     %QUERY_FIELDNAMES = %{$self->{'.fieldnames'}};
720 }
721
722 sub parse_params {
723     my($self,$tosplit) = @_;
724     my(@pairs) = split(/[&;]/,$tosplit);
725     my($param,$value);
726     foreach (@pairs) {
727         ($param,$value) = split('=',$_,2);
728         next unless defined $param;
729         next if $NO_UNDEF_PARAMS and not defined $value;
730         $value = '' unless defined $value;
731         $param = unescape($param);
732         $value = unescape($value);
733         $self->add_parameter($param);
734         push (@{$self->{$param}},$value);
735     }
736 }
737
738 sub add_parameter {
739     my($self,$param)=@_;
740     return unless defined $param;
741     push (@{$self->{'.parameters'}},$param) 
742         unless defined($self->{$param});
743 }
744
745 sub all_parameters {
746     my $self = shift;
747     return () unless defined($self) && $self->{'.parameters'};
748     return () unless @{$self->{'.parameters'}};
749     return @{$self->{'.parameters'}};
750 }
751
752 # put a filehandle into binary mode (DOS)
753 sub binmode {
754     return unless defined($_[1]) && defined fileno($_[1]);
755     CORE::binmode($_[1]);
756 }
757
758 sub _make_tag_func {
759     my ($self,$tagname) = @_;
760     my $func = qq(
761         sub $tagname {
762          my (\$q,\$a,\@rest) = self_or_default(\@_);
763          my(\$attr) = '';
764          if (ref(\$a) && ref(\$a) eq 'HASH') {
765             my(\@attr) = make_attributes(\$a,\$q->{'escape'});
766             \$attr = " \@attr" if \@attr;
767           } else {
768             unshift \@rest,\$a if defined \$a;
769           }
770         );
771     if ($tagname=~/start_(\w+)/i) {
772         $func .= qq! return "<\L$1\E\$attr>";} !;
773     } elsif ($tagname=~/end_(\w+)/i) {
774         $func .= qq! return "<\L/$1\E>"; } !;
775     } else {
776         $func .= qq#
777             return \$XHTML ? "\L<$tagname\E\$attr />" : "\L<$tagname\E\$attr>" unless \@rest;
778             my(\$tag,\$untag) = ("\L<$tagname\E\$attr>","\L</$tagname>\E");
779             my \@result = map { "\$tag\$_\$untag" } 
780                               (ref(\$rest[0]) eq 'ARRAY') ? \@{\$rest[0]} : "\@rest";
781             return "\@result";
782             }#;
783     }
784 return $func;
785 }
786
787 sub AUTOLOAD {
788     print STDERR "CGI::AUTOLOAD for $AUTOLOAD\n" if $CGI::AUTOLOAD_DEBUG;
789     my $func = &_compile;
790     goto &$func;
791 }
792
793 sub _compile {
794     my($func) = $AUTOLOAD;
795     my($pack,$func_name);
796     {
797         local($1,$2); # this fixes an obscure variable suicide problem.
798         $func=~/(.+)::([^:]+)$/;
799         ($pack,$func_name) = ($1,$2);
800         $pack=~s/::SUPER$//;    # fix another obscure problem
801         $pack = ${"$pack\:\:AutoloadClass"} || $CGI::DefaultClass
802             unless defined(${"$pack\:\:AUTOLOADED_ROUTINES"});
803
804         my($sub) = \%{"$pack\:\:SUBS"};
805         unless (%$sub) {
806            my($auto) = \${"$pack\:\:AUTOLOADED_ROUTINES"};
807            local ($@,$!);
808            eval "package $pack; $$auto";
809            croak("$AUTOLOAD: $@") if $@;
810            $$auto = '';  # Free the unneeded storage (but don't undef it!!!)
811        }
812        my($code) = $sub->{$func_name};
813
814        $code = "sub $AUTOLOAD { }" if (!$code and $func_name eq 'DESTROY');
815        if (!$code) {
816            (my $base = $func_name) =~ s/^(start_|end_)//i;
817            if ($EXPORT{':any'} || 
818                $EXPORT{'-any'} ||
819                $EXPORT{$base} || 
820                (%EXPORT_OK || grep(++$EXPORT_OK{$_},&expand_tags(':html')))
821                    && $EXPORT_OK{$base}) {
822                $code = $CGI::DefaultClass->_make_tag_func($func_name);
823            }
824        }
825        croak("Undefined subroutine $AUTOLOAD\n") unless $code;
826        local ($@,$!);
827        eval "package $pack; $code";
828        if ($@) {
829            $@ =~ s/ at .*\n//;
830            croak("$AUTOLOAD: $@");
831        }
832     }       
833     CORE::delete($sub->{$func_name});  #free storage
834     return "$pack\:\:$func_name";
835 }
836
837 sub _selected {
838   my $self = shift;
839   my $value = shift;
840   return '' unless $value;
841   return $XHTML ? qq(selected="selected" ) : qq(selected );
842 }
843
844 sub _checked {
845   my $self = shift;
846   my $value = shift;
847   return '' unless $value;
848   return $XHTML ? qq(checked="checked" ) : qq(checked );
849 }
850
851 sub _reset_globals { initialize_globals(); }
852
853 sub _setup_symbols {
854     my $self = shift;
855     my $compile = 0;
856
857     # to avoid reexporting unwanted variables
858     undef %EXPORT;
859
860     foreach (@_) {
861         $HEADERS_ONCE++,         next if /^[:-]unique_headers$/;
862         $NPH++,                  next if /^[:-]nph$/;
863         $NOSTICKY++,             next if /^[:-]nosticky$/;
864         $DEBUG=0,                next if /^[:-]no_?[Dd]ebug$/;
865         $DEBUG=2,                next if /^[:-][Dd]ebug$/;
866         $USE_PARAM_SEMICOLONS++, next if /^[:-]newstyle_urls$/;
867         $XHTML++,                next if /^[:-]xhtml$/;
868         $XHTML=0,                next if /^[:-]no_?xhtml$/;
869         $USE_PARAM_SEMICOLONS=0, next if /^[:-]oldstyle_urls$/;
870         $PRIVATE_TEMPFILES++,    next if /^[:-]private_tempfiles$/;
871         $TABINDEX++,             next if /^[:-]tabindex$/;
872         $CLOSE_UPLOAD_FILES++,   next if /^[:-]close_upload_files$/;
873         $EXPORT{$_}++,           next if /^[:-]any$/;
874         $compile++,              next if /^[:-]compile$/;
875         $NO_UNDEF_PARAMS++,      next if /^[:-]no_undef_params$/;
876         
877         # This is probably extremely evil code -- to be deleted some day.
878         if (/^[-]autoload$/) {
879             my($pkg) = caller(1);
880             *{"${pkg}::AUTOLOAD"} = sub { 
881                 my($routine) = $AUTOLOAD;
882                 $routine =~ s/^.*::/CGI::/;
883                 &$routine;
884             };
885             next;
886         }
887
888         foreach (&expand_tags($_)) {
889             tr/a-zA-Z0-9_//cd;  # don't allow weird function names
890             $EXPORT{$_}++;
891         }
892     }
893     _compile_all(keys %EXPORT) if $compile;
894     @SAVED_SYMBOLS = @_;
895 }
896
897 sub charset {
898   my ($self,$charset) = self_or_default(@_);
899   $self->{'.charset'} = $charset if defined $charset;
900   $self->{'.charset'};
901 }
902
903 sub element_id {
904   my ($self,$new_value) = self_or_default(@_);
905   $self->{'.elid'} = $new_value if defined $new_value;
906   sprintf('%010d',$self->{'.elid'}++);
907 }
908
909 sub element_tab {
910   my ($self,$new_value) = self_or_default(@_);
911   $self->{'.etab'} ||= 1;
912   $self->{'.etab'} = $new_value if defined $new_value;
913   my $tab = $self->{'.etab'}++;
914   return '' unless $TABINDEX or defined $new_value;
915   return qq(tabindex="$tab" );
916 }
917
918 ###############################################################################
919 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
920 ###############################################################################
921 $AUTOLOADED_ROUTINES = '';      # get rid of -w warning
922 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
923
924 %SUBS = (
925
926 'URL_ENCODED'=> <<'END_OF_FUNC',
927 sub URL_ENCODED { 'application/x-www-form-urlencoded'; }
928 END_OF_FUNC
929
930 'MULTIPART' => <<'END_OF_FUNC',
931 sub MULTIPART {  'multipart/form-data'; }
932 END_OF_FUNC
933
934 'SERVER_PUSH' => <<'END_OF_FUNC',
935 sub SERVER_PUSH { 'multipart/x-mixed-replace;boundary="' . shift() . '"'; }
936 END_OF_FUNC
937
938 'new_MultipartBuffer' => <<'END_OF_FUNC',
939 # Create a new multipart buffer
940 sub new_MultipartBuffer {
941     my($self,$boundary,$length) = @_;
942     return MultipartBuffer->new($self,$boundary,$length);
943 }
944 END_OF_FUNC
945
946 'read_from_client' => <<'END_OF_FUNC',
947 # Read data from a file handle
948 sub read_from_client {
949     my($self, $buff, $len, $offset) = @_;
950     local $^W=0;                # prevent a warning
951     return $MOD_PERL
952         ? $self->r->read($$buff, $len, $offset)
953         : read(\*STDIN, $$buff, $len, $offset);
954 }
955 END_OF_FUNC
956
957 'delete' => <<'END_OF_FUNC',
958 #### Method: delete
959 # Deletes the named parameter entirely.
960 ####
961 sub delete {
962     my($self,@p) = self_or_default(@_);
963     my(@names) = rearrange([NAME],@p);
964     my @to_delete = ref($names[0]) eq 'ARRAY' ? @$names[0] : @names;
965     my %to_delete;
966     foreach my $name (@to_delete)
967     {
968         CORE::delete $self->{$name};
969         CORE::delete $self->{'.fieldnames'}->{$name};
970         $to_delete{$name}++;
971     }
972     @{$self->{'.parameters'}}=grep { !exists($to_delete{$_}) } $self->param();
973     return;
974 }
975 END_OF_FUNC
976
977 #### Method: import_names
978 # Import all parameters into the given namespace.
979 # Assumes namespace 'Q' if not specified
980 ####
981 'import_names' => <<'END_OF_FUNC',
982 sub import_names {
983     my($self,$namespace,$delete) = self_or_default(@_);
984     $namespace = 'Q' unless defined($namespace);
985     die "Can't import names into \"main\"\n" if \%{"${namespace}::"} == \%::;
986     if ($delete || $MOD_PERL || exists $ENV{'FCGI_ROLE'}) {
987         # can anyone find an easier way to do this?
988         foreach (keys %{"${namespace}::"}) {
989             local *symbol = "${namespace}::${_}";
990             undef $symbol;
991             undef @symbol;
992             undef %symbol;
993         }
994     }
995     my($param,@value,$var);
996     foreach $param ($self->param) {
997         # protect against silly names
998         ($var = $param)=~tr/a-zA-Z0-9_/_/c;
999         $var =~ s/^(?=\d)/_/;
1000         local *symbol = "${namespace}::$var";
1001         @value = $self->param($param);
1002         @symbol = @value;
1003         $symbol = $value[0];
1004     }
1005 }
1006 END_OF_FUNC
1007
1008 #### Method: keywords
1009 # Keywords acts a bit differently.  Calling it in a list context
1010 # returns the list of keywords.  
1011 # Calling it in a scalar context gives you the size of the list.
1012 ####
1013 'keywords' => <<'END_OF_FUNC',
1014 sub keywords {
1015     my($self,@values) = self_or_default(@_);
1016     # If values is provided, then we set it.
1017     $self->{'keywords'}=[@values] if @values;
1018     my(@result) = defined($self->{'keywords'}) ? @{$self->{'keywords'}} : ();
1019     @result;
1020 }
1021 END_OF_FUNC
1022
1023 # These are some tie() interfaces for compatibility
1024 # with Steve Brenner's cgi-lib.pl routines
1025 'Vars' => <<'END_OF_FUNC',
1026 sub Vars {
1027     my $q = shift;
1028     my %in;
1029     tie(%in,CGI,$q);
1030     return %in if wantarray;
1031     return \%in;
1032 }
1033 END_OF_FUNC
1034
1035 # These are some tie() interfaces for compatibility
1036 # with Steve Brenner's cgi-lib.pl routines
1037 'ReadParse' => <<'END_OF_FUNC',
1038 sub ReadParse {
1039     local(*in);
1040     if (@_) {
1041         *in = $_[0];
1042     } else {
1043         my $pkg = caller();
1044         *in=*{"${pkg}::in"};
1045     }
1046     tie(%in,CGI);
1047     return scalar(keys %in);
1048 }
1049 END_OF_FUNC
1050
1051 'PrintHeader' => <<'END_OF_FUNC',
1052 sub PrintHeader {
1053     my($self) = self_or_default(@_);
1054     return $self->header();
1055 }
1056 END_OF_FUNC
1057
1058 'HtmlTop' => <<'END_OF_FUNC',
1059 sub HtmlTop {
1060     my($self,@p) = self_or_default(@_);
1061     return $self->start_html(@p);
1062 }
1063 END_OF_FUNC
1064
1065 'HtmlBot' => <<'END_OF_FUNC',
1066 sub HtmlBot {
1067     my($self,@p) = self_or_default(@_);
1068     return $self->end_html(@p);
1069 }
1070 END_OF_FUNC
1071
1072 'SplitParam' => <<'END_OF_FUNC',
1073 sub SplitParam {
1074     my ($param) = @_;
1075     my (@params) = split ("\0", $param);
1076     return (wantarray ? @params : $params[0]);
1077 }
1078 END_OF_FUNC
1079
1080 'MethGet' => <<'END_OF_FUNC',
1081 sub MethGet {
1082     return request_method() eq 'GET';
1083 }
1084 END_OF_FUNC
1085
1086 'MethPost' => <<'END_OF_FUNC',
1087 sub MethPost {
1088     return request_method() eq 'POST';
1089 }
1090 END_OF_FUNC
1091
1092 'TIEHASH' => <<'END_OF_FUNC',
1093 sub TIEHASH {
1094     my $class = shift;
1095     my $arg   = $_[0];
1096     if (ref($arg) && UNIVERSAL::isa($arg,'CGI')) {
1097        return $arg;
1098     }
1099     return $Q ||= $class->new(@_);
1100 }
1101 END_OF_FUNC
1102
1103 'STORE' => <<'END_OF_FUNC',
1104 sub STORE {
1105     my $self = shift;
1106     my $tag  = shift;
1107     my $vals = shift;
1108     my @vals = index($vals,"\0")!=-1 ? split("\0",$vals) : $vals;
1109     $self->param(-name=>$tag,-value=>\@vals);
1110 }
1111 END_OF_FUNC
1112
1113 'FETCH' => <<'END_OF_FUNC',
1114 sub FETCH {
1115     return $_[0] if $_[1] eq 'CGI';
1116     return undef unless defined $_[0]->param($_[1]);
1117     return join("\0",$_[0]->param($_[1]));
1118 }
1119 END_OF_FUNC
1120
1121 'FIRSTKEY' => <<'END_OF_FUNC',
1122 sub FIRSTKEY {
1123     $_[0]->{'.iterator'}=0;
1124     $_[0]->{'.parameters'}->[$_[0]->{'.iterator'}++];
1125 }
1126 END_OF_FUNC
1127
1128 'NEXTKEY' => <<'END_OF_FUNC',
1129 sub NEXTKEY {
1130     $_[0]->{'.parameters'}->[$_[0]->{'.iterator'}++];
1131 }
1132 END_OF_FUNC
1133
1134 'EXISTS' => <<'END_OF_FUNC',
1135 sub EXISTS {
1136     exists $_[0]->{$_[1]};
1137 }
1138 END_OF_FUNC
1139
1140 'DELETE' => <<'END_OF_FUNC',
1141 sub DELETE {
1142     $_[0]->delete($_[1]);
1143 }
1144 END_OF_FUNC
1145
1146 'CLEAR' => <<'END_OF_FUNC',
1147 sub CLEAR {
1148     %{$_[0]}=();
1149 }
1150 ####
1151 END_OF_FUNC
1152
1153 ####
1154 # Append a new value to an existing query
1155 ####
1156 'append' => <<'EOF',
1157 sub append {
1158     my($self,@p) = self_or_default(@_);
1159     my($name,$value) = rearrange([NAME,[VALUE,VALUES]],@p);
1160     my(@values) = defined($value) ? (ref($value) ? @{$value} : $value) : ();
1161     if (@values) {
1162         $self->add_parameter($name);
1163         push(@{$self->{$name}},@values);
1164     }
1165     return $self->param($name);
1166 }
1167 EOF
1168
1169 #### Method: delete_all
1170 # Delete all parameters
1171 ####
1172 'delete_all' => <<'EOF',
1173 sub delete_all {
1174     my($self) = self_or_default(@_);
1175     my @param = $self->param();
1176     $self->delete(@param);
1177 }
1178 EOF
1179
1180 'Delete' => <<'EOF',
1181 sub Delete {
1182     my($self,@p) = self_or_default(@_);
1183     $self->delete(@p);
1184 }
1185 EOF
1186
1187 'Delete_all' => <<'EOF',
1188 sub Delete_all {
1189     my($self,@p) = self_or_default(@_);
1190     $self->delete_all(@p);
1191 }
1192 EOF
1193
1194 #### Method: autoescape
1195 # If you want to turn off the autoescaping features,
1196 # call this method with undef as the argument
1197 'autoEscape' => <<'END_OF_FUNC',
1198 sub autoEscape {
1199     my($self,$escape) = self_or_default(@_);
1200     my $d = $self->{'escape'};
1201     $self->{'escape'} = $escape;
1202     $d;
1203 }
1204 END_OF_FUNC
1205
1206
1207 #### Method: version
1208 # Return the current version
1209 ####
1210 'version' => <<'END_OF_FUNC',
1211 sub version {
1212     return $VERSION;
1213 }
1214 END_OF_FUNC
1215
1216 #### Method: url_param
1217 # Return a parameter in the QUERY_STRING, regardless of
1218 # whether this was a POST or a GET
1219 ####
1220 'url_param' => <<'END_OF_FUNC',
1221 sub url_param {
1222     my ($self,@p) = self_or_default(@_);
1223     my $name = shift(@p);
1224     return undef unless exists($ENV{QUERY_STRING});
1225     unless (exists($self->{'.url_param'})) {
1226         $self->{'.url_param'}={}; # empty hash
1227         if ($ENV{QUERY_STRING} =~ /=/) {
1228             my(@pairs) = split(/[&;]/,$ENV{QUERY_STRING});
1229             my($param,$value);
1230             foreach (@pairs) {
1231                 ($param,$value) = split('=',$_,2);
1232                 $param = unescape($param);
1233                 $value = unescape($value);
1234                 push(@{$self->{'.url_param'}->{$param}},$value);
1235             }
1236         } else {
1237             $self->{'.url_param'}->{'keywords'} = [$self->parse_keywordlist($ENV{QUERY_STRING})];
1238         }
1239     }
1240     return keys %{$self->{'.url_param'}} unless defined($name);
1241     return () unless $self->{'.url_param'}->{$name};
1242     return wantarray ? @{$self->{'.url_param'}->{$name}}
1243                      : $self->{'.url_param'}->{$name}->[0];
1244 }
1245 END_OF_FUNC
1246
1247 #### Method: Dump
1248 # Returns a string in which all the known parameter/value 
1249 # pairs are represented as nested lists, mainly for the purposes 
1250 # of debugging.
1251 ####
1252 'Dump' => <<'END_OF_FUNC',
1253 sub Dump {
1254     my($self) = self_or_default(@_);
1255     my($param,$value,@result);
1256     return '<ul></ul>' unless $self->param;
1257     push(@result,"<ul>");
1258     foreach $param ($self->param) {
1259         my($name)=$self->escapeHTML($param);
1260         push(@result,"<li><strong>$param</strong></li>");
1261         push(@result,"<ul>");
1262         foreach $value ($self->param($param)) {
1263             $value = $self->escapeHTML($value);
1264             $value =~ s/\n/<br \/>\n/g;
1265             push(@result,"<li>$value</li>");
1266         }
1267         push(@result,"</ul>");
1268     }
1269     push(@result,"</ul>");
1270     return join("\n",@result);
1271 }
1272 END_OF_FUNC
1273
1274 #### Method as_string
1275 #
1276 # synonym for "dump"
1277 ####
1278 'as_string' => <<'END_OF_FUNC',
1279 sub as_string {
1280     &Dump(@_);
1281 }
1282 END_OF_FUNC
1283
1284 #### Method: save
1285 # Write values out to a filehandle in such a way that they can
1286 # be reinitialized by the filehandle form of the new() method
1287 ####
1288 'save' => <<'END_OF_FUNC',
1289 sub save {
1290     my($self,$filehandle) = self_or_default(@_);
1291     $filehandle = to_filehandle($filehandle);
1292     my($param);
1293     local($,) = '';  # set print field separator back to a sane value
1294     local($\) = '';  # set output line separator to a sane value
1295     foreach $param ($self->param) {
1296         my($escaped_param) = escape($param);
1297         my($value);
1298         foreach $value ($self->param($param)) {
1299             print $filehandle "$escaped_param=",escape("$value"),"\n";
1300         }
1301     }
1302     foreach (keys %{$self->{'.fieldnames'}}) {
1303           print $filehandle ".cgifields=",escape("$_"),"\n";
1304     }
1305     print $filehandle "=\n";    # end of record
1306 }
1307 END_OF_FUNC
1308
1309
1310 #### Method: save_parameters
1311 # An alias for save() that is a better name for exportation.
1312 # Only intended to be used with the function (non-OO) interface.
1313 ####
1314 'save_parameters' => <<'END_OF_FUNC',
1315 sub save_parameters {
1316     my $fh = shift;
1317     return save(to_filehandle($fh));
1318 }
1319 END_OF_FUNC
1320
1321 #### Method: restore_parameters
1322 # A way to restore CGI parameters from an initializer.
1323 # Only intended to be used with the function (non-OO) interface.
1324 ####
1325 'restore_parameters' => <<'END_OF_FUNC',
1326 sub restore_parameters {
1327     $Q = $CGI::DefaultClass->new(@_);
1328 }
1329 END_OF_FUNC
1330
1331 #### Method: multipart_init
1332 # Return a Content-Type: style header for server-push
1333 # This has to be NPH on most web servers, and it is advisable to set $| = 1
1334 #
1335 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1336 # contribution, updated by Andrew Benham (adsb@bigfoot.com)
1337 ####
1338 'multipart_init' => <<'END_OF_FUNC',
1339 sub multipart_init {
1340     my($self,@p) = self_or_default(@_);
1341     my($boundary,@other) = rearrange([BOUNDARY],@p);
1342     $boundary = $boundary || '------- =_aaaaaaaaaa0';
1343     $self->{'separator'} = "$CRLF--$boundary$CRLF";
1344     $self->{'final_separator'} = "$CRLF--$boundary--$CRLF";
1345     $type = SERVER_PUSH($boundary);
1346     return $self->header(
1347         -nph => 0,
1348         -type => $type,
1349         (map { split "=", $_, 2 } @other),
1350     ) . "WARNING: YOUR BROWSER DOESN'T SUPPORT THIS SERVER-PUSH TECHNOLOGY." . $self->multipart_end;
1351 }
1352 END_OF_FUNC
1353
1354
1355 #### Method: multipart_start
1356 # Return a Content-Type: style header for server-push, start of section
1357 #
1358 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1359 # contribution, updated by Andrew Benham (adsb@bigfoot.com)
1360 ####
1361 'multipart_start' => <<'END_OF_FUNC',
1362 sub multipart_start {
1363     my(@header);
1364     my($self,@p) = self_or_default(@_);
1365     my($type,@other) = rearrange([TYPE],@p);
1366     $type = $type || 'text/html';
1367     push(@header,"Content-Type: $type");
1368
1369     # rearrange() was designed for the HTML portion, so we
1370     # need to fix it up a little.
1371     foreach (@other) {
1372         # Don't use \s because of perl bug 21951
1373         next unless my($header,$value) = /([^ \r\n\t=]+)=\"?(.+?)\"?$/;
1374         ($_ = $header) =~ s/^(\w)(.*)/$1 . lc ($2) . ': '.$self->unescapeHTML($value)/e;
1375     }
1376     push(@header,@other);
1377     my $header = join($CRLF,@header)."${CRLF}${CRLF}";
1378     return $header;
1379 }
1380 END_OF_FUNC
1381
1382
1383 #### Method: multipart_end
1384 # Return a MIME boundary separator for server-push, end of section
1385 #
1386 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1387 # contribution
1388 ####
1389 'multipart_end' => <<'END_OF_FUNC',
1390 sub multipart_end {
1391     my($self,@p) = self_or_default(@_);
1392     return $self->{'separator'};
1393 }
1394 END_OF_FUNC
1395
1396
1397 #### Method: multipart_final
1398 # Return a MIME boundary separator for server-push, end of all sections
1399 #
1400 # Contributed by Andrew Benham (adsb@bigfoot.com)
1401 ####
1402 'multipart_final' => <<'END_OF_FUNC',
1403 sub multipart_final {
1404     my($self,@p) = self_or_default(@_);
1405     return $self->{'final_separator'} . "WARNING: YOUR BROWSER DOESN'T SUPPORT THIS SERVER-PUSH TECHNOLOGY." . $CRLF;
1406 }
1407 END_OF_FUNC
1408
1409
1410 #### Method: header
1411 # Return a Content-Type: style header
1412 #
1413 ####
1414 'header' => <<'END_OF_FUNC',
1415 sub header {
1416     my($self,@p) = self_or_default(@_);
1417     my(@header);
1418
1419     return "" if $self->{'.header_printed'}++ and $HEADERS_ONCE;
1420
1421     my($type,$status,$cookie,$target,$expires,$nph,$charset,$attachment,$p3p,@other) = 
1422         rearrange([['TYPE','CONTENT_TYPE','CONTENT-TYPE'],
1423                             'STATUS',['COOKIE','COOKIES'],'TARGET',
1424                             'EXPIRES','NPH','CHARSET',
1425                             'ATTACHMENT','P3P'],@p);
1426
1427     $nph     ||= $NPH;
1428
1429     $type ||= 'text/html' unless defined($type);
1430
1431     if (defined $charset) {
1432       $self->charset($charset);
1433     } else {
1434       $charset = $self->charset if $type =~ /^text\//;
1435     }
1436    $charset ||= '';
1437
1438     # rearrange() was designed for the HTML portion, so we
1439     # need to fix it up a little.
1440     foreach (@other) {
1441         # Don't use \s because of perl bug 21951
1442         next unless my($header,$value) = /([^ \r\n\t=]+)=\"?(.+?)\"?$/;
1443         ($_ = $header) =~ s/^(\w)(.*)/"\u$1\L$2" . ': '.$self->unescapeHTML($value)/e;
1444     }
1445
1446     $type .= "; charset=$charset"
1447       if     $type ne ''
1448          and $type !~ /\bcharset\b/
1449          and defined $charset
1450          and $charset ne '';
1451
1452     # Maybe future compatibility.  Maybe not.
1453     my $protocol = $ENV{SERVER_PROTOCOL} || 'HTTP/1.0';
1454     push(@header,$protocol . ' ' . ($status || '200 OK')) if $nph;
1455     push(@header,"Server: " . &server_software()) if $nph;
1456
1457     push(@header,"Status: $status") if $status;
1458     push(@header,"Window-Target: $target") if $target;
1459     if ($p3p) {
1460        $p3p = join ' ',@$p3p if ref($p3p) eq 'ARRAY';
1461        push(@header,qq(P3P: policyref="/w3c/p3p.xml", CP="$p3p"));
1462     }
1463     # push all the cookies -- there may be several
1464     if ($cookie) {
1465         my(@cookie) = ref($cookie) && ref($cookie) eq 'ARRAY' ? @{$cookie} : $cookie;
1466         foreach (@cookie) {
1467             my $cs = UNIVERSAL::isa($_,'CGI::Cookie') ? $_->as_string : $_;
1468             push(@header,"Set-Cookie: $cs") if $cs ne '';
1469         }
1470     }
1471     # if the user indicates an expiration time, then we need
1472     # both an Expires and a Date header (so that the browser is
1473     # uses OUR clock)
1474     push(@header,"Expires: " . expires($expires,'http'))
1475         if $expires;
1476     push(@header,"Date: " . expires(0,'http')) if $expires || $cookie || $nph;
1477     push(@header,"Pragma: no-cache") if $self->cache();
1478     push(@header,"Content-Disposition: attachment; filename=\"$attachment\"") if $attachment;
1479     push(@header,map {ucfirst $_} @other);
1480     push(@header,"Content-Type: $type") if $type ne '';
1481     my $header = join($CRLF,@header)."${CRLF}${CRLF}";
1482     if ($MOD_PERL and not $nph) {
1483         $self->r->send_cgi_header($header);
1484         return '';
1485     }
1486     return $header;
1487 }
1488 END_OF_FUNC
1489
1490
1491 #### Method: cache
1492 # Control whether header() will produce the no-cache
1493 # Pragma directive.
1494 ####
1495 'cache' => <<'END_OF_FUNC',
1496 sub cache {
1497     my($self,$new_value) = self_or_default(@_);
1498     $new_value = '' unless $new_value;
1499     if ($new_value ne '') {
1500         $self->{'cache'} = $new_value;
1501     }
1502     return $self->{'cache'};
1503 }
1504 END_OF_FUNC
1505
1506
1507 #### Method: redirect
1508 # Return a Location: style header
1509 #
1510 ####
1511 'redirect' => <<'END_OF_FUNC',
1512 sub redirect {
1513     my($self,@p) = self_or_default(@_);
1514     my($url,$target,$status,$cookie,$nph,@other) = 
1515          rearrange([[LOCATION,URI,URL],TARGET,STATUS,['COOKIE','COOKIES'],NPH],@p);
1516     $status = '302 Found' unless defined $status;
1517     $url ||= $self->self_url;
1518     my(@o);
1519     foreach (@other) { tr/\"//d; push(@o,split("=",$_,2)); }
1520     unshift(@o,
1521          '-Status'  => $status,
1522          '-Location'=> $url,
1523          '-nph'     => $nph);
1524     unshift(@o,'-Target'=>$target) if $target;
1525     unshift(@o,'-Type'=>'');
1526     my @unescaped;
1527     unshift(@unescaped,'-Cookie'=>$cookie) if $cookie;
1528     return $self->header((map {$self->unescapeHTML($_)} @o),@unescaped);
1529 }
1530 END_OF_FUNC
1531
1532
1533 #### Method: start_html
1534 # Canned HTML header
1535 #
1536 # Parameters:
1537 # $title -> (optional) The title for this HTML document (-title)
1538 # $author -> (optional) e-mail address of the author (-author)
1539 # $base -> (optional) if set to true, will enter the BASE address of this document
1540 #          for resolving relative references (-base) 
1541 # $xbase -> (optional) alternative base at some remote location (-xbase)
1542 # $target -> (optional) target window to load all links into (-target)
1543 # $script -> (option) Javascript code (-script)
1544 # $no_script -> (option) Javascript <noscript> tag (-noscript)
1545 # $meta -> (optional) Meta information tags
1546 # $head -> (optional) any other elements you'd like to incorporate into the <head> tag
1547 #           (a scalar or array ref)
1548 # $style -> (optional) reference to an external style sheet
1549 # @other -> (optional) any other named parameters you'd like to incorporate into
1550 #           the <body> tag.
1551 ####
1552 'start_html' => <<'END_OF_FUNC',
1553 sub start_html {
1554     my($self,@p) = &self_or_default(@_);
1555     my($title,$author,$base,$xbase,$script,$noscript,
1556         $target,$meta,$head,$style,$dtd,$lang,$encoding,$declare_xml,@other) = 
1557         rearrange([TITLE,AUTHOR,BASE,XBASE,SCRIPT,NOSCRIPT,TARGET,
1558                    META,HEAD,STYLE,DTD,LANG,ENCODING,DECLARE_XML],@p);
1559
1560     $self->element_id(0);
1561     $self->element_tab(0);
1562
1563     $encoding = lc($self->charset) unless defined $encoding;
1564
1565     # Need to sort out the DTD before it's okay to call escapeHTML().
1566     my(@result,$xml_dtd);
1567     if ($dtd) {
1568         if (defined(ref($dtd)) and (ref($dtd) eq 'ARRAY')) {
1569             $dtd = $DEFAULT_DTD unless $dtd->[0] =~ m|^-//|;
1570         } else {
1571             $dtd = $DEFAULT_DTD unless $dtd =~ m|^-//|;
1572         }
1573     } else {
1574         $dtd = $XHTML ? XHTML_DTD : $DEFAULT_DTD;
1575     }
1576
1577     $xml_dtd++ if ref($dtd) eq 'ARRAY' && $dtd->[0] =~ /\bXHTML\b/i;
1578     $xml_dtd++ if ref($dtd) eq '' && $dtd =~ /\bXHTML\b/i;
1579     push @result,qq(<?xml version="1.0" encoding="$encoding"?>) if $xml_dtd && $declare_xml;
1580
1581     if (ref($dtd) && ref($dtd) eq 'ARRAY') {
1582         push(@result,qq(<!DOCTYPE html\n\tPUBLIC "$dtd->[0]"\n\t "$dtd->[1]">));
1583         $DTD_PUBLIC_IDENTIFIER = $dtd->[0];
1584     } else {
1585         push(@result,qq(<!DOCTYPE html\n\tPUBLIC "$dtd">));
1586         $DTD_PUBLIC_IDENTIFIER = $dtd;
1587     }
1588
1589     # Now that we know whether we're using the HTML 3.2 DTD or not, it's okay to
1590     # call escapeHTML().  Strangely enough, the title needs to be escaped as
1591     # HTML while the author needs to be escaped as a URL.
1592     $title = $self->escapeHTML($title || 'Untitled Document');
1593     $author = $self->escape($author);
1594
1595     if ($DTD_PUBLIC_IDENTIFIER =~ /[^X]HTML (2\.0|3\.2)/i) {
1596         $lang = "" unless defined $lang;
1597         $XHTML = 0;
1598     }
1599     else {
1600         $lang = 'en-US' unless defined $lang;
1601     }
1602
1603     my $lang_bits = $lang ne '' ? qq( lang="$lang" xml:lang="$lang") : '';
1604     my $meta_bits = qq(<meta http-equiv="Content-Type" content="text/html; charset=$encoding" />) 
1605                     if $XHTML && $encoding && !$declare_xml;
1606
1607     push(@result,$XHTML ? qq(<html xmlns="http://www.w3.org/1999/xhtml"$lang_bits>\n<head>\n<title>$title</title>)
1608                         : ($lang ? qq(<html lang="$lang">) : "<html>")
1609                           . "<head><title>$title</title>");
1610         if (defined $author) {
1611     push(@result,$XHTML ? "<link rev=\"made\" href=\"mailto:$author\" />"
1612                         : "<link rev=\"made\" href=\"mailto:$author\">");
1613         }
1614
1615     if ($base || $xbase || $target) {
1616         my $href = $xbase || $self->url('-path'=>1);
1617         my $t = $target ? qq/ target="$target"/ : '';
1618         push(@result,$XHTML ? qq(<base href="$href"$t />) : qq(<base href="$href"$t>));
1619     }
1620
1621     if ($meta && ref($meta) && (ref($meta) eq 'HASH')) {
1622         foreach (keys %$meta) { push(@result,$XHTML ? qq(<meta name="$_" content="$meta->{$_}" />) 
1623                         : qq(<meta name="$_" content="$meta->{$_}">)); }
1624     }
1625
1626     push(@result,ref($head) ? @$head : $head) if $head;
1627
1628     # handle the infrequently-used -style and -script parameters
1629     push(@result,$self->_style($style))   if defined $style;
1630     push(@result,$self->_script($script)) if defined $script;
1631     push(@result,$meta_bits)              if defined $meta_bits;
1632
1633     # handle -noscript parameter
1634     push(@result,<<END) if $noscript;
1635 <noscript>
1636 $noscript
1637 </noscript>
1638 END
1639     ;
1640     my($other) = @other ? " @other" : '';
1641     push(@result,"</head>\n<body$other>\n");
1642     return join("\n",@result);
1643 }
1644 END_OF_FUNC
1645
1646 ### Method: _style
1647 # internal method for generating a CSS style section
1648 ####
1649 '_style' => <<'END_OF_FUNC',
1650 sub _style {
1651     my ($self,$style) = @_;
1652     my (@result);
1653     my $type = 'text/css';
1654
1655     my $cdata_start = $XHTML ? "\n<!--/* <![CDATA[ */" : "\n<!-- ";
1656     my $cdata_end   = $XHTML ? "\n/* ]]> */-->\n" : " -->\n";
1657
1658     my @s = ref($style) eq 'ARRAY' ? @$style : $style;
1659
1660     for my $s (@s) {
1661       if (ref($s)) {
1662        my($src,$code,$verbatim,$stype,$foo,@other) =
1663            rearrange([qw(SRC CODE VERBATIM TYPE FOO)],
1664                       ('-foo'=>'bar',
1665                        ref($s) eq 'ARRAY' ? @$s : %$s));
1666        $type  = $stype if $stype;
1667        my $other = @other ? join ' ',@other : '';
1668
1669        if (ref($src) eq "ARRAY") # Check to see if the $src variable is an array reference
1670        { # If it is, push a LINK tag for each one
1671            foreach $src (@$src)
1672          {
1673            push(@result,$XHTML ? qq(<link rel="stylesheet" type="$type" href="$src" $other/>)
1674                              : qq(<link rel="stylesheet" type="$type" href="$src"$other>)) if $src;
1675          }
1676        }
1677        else
1678        { # Otherwise, push the single -src, if it exists.
1679          push(@result,$XHTML ? qq(<link rel="stylesheet" type="$type" href="$src" $other/>)
1680                              : qq(<link rel="stylesheet" type="$type" href="$src"$other>)
1681               ) if $src;
1682         }
1683      if ($verbatim) {
1684            my @v = ref($verbatim) eq 'ARRAY' ? @$verbatim : $verbatim;
1685            push(@result, "<style type=\"text/css\">\n$_\n</style>") foreach @v;
1686       }
1687       my @c = ref($code) eq 'ARRAY' ? @$code : $code if $code;
1688       push(@result,style({'type'=>$type},"$cdata_start\n$_\n$cdata_end")) foreach @c;
1689
1690       } else {
1691            my $src = $s;
1692            push(@result,$XHTML ? qq(<link rel="stylesheet" type="$type" href="$src" $other/>)
1693                                : qq(<link rel="stylesheet" type="$type" href="$src"$other>));
1694       }
1695     }
1696     @result;
1697 }
1698 END_OF_FUNC
1699
1700 '_script' => <<'END_OF_FUNC',
1701 sub _script {
1702     my ($self,$script) = @_;
1703     my (@result);
1704
1705     my (@scripts) = ref($script) eq 'ARRAY' ? @$script : ($script);
1706     foreach $script (@scripts) {
1707         my($src,$code,$language);
1708         if (ref($script)) { # script is a hash
1709             ($src,$code,$language, $type) =
1710                 rearrange([SRC,CODE,LANGUAGE,TYPE],
1711                                  '-foo'=>'bar', # a trick to allow the '-' to be omitted
1712                                  ref($script) eq 'ARRAY' ? @$script : %$script);
1713             # User may not have specified language
1714             $language ||= 'JavaScript';
1715             unless (defined $type) {
1716                 $type = lc $language;
1717                 # strip '1.2' from 'javascript1.2'
1718                 $type =~ s/^(\D+).*$/text\/$1/;
1719             }
1720         } else {
1721             ($src,$code,$language, $type) = ('',$script,'JavaScript', 'text/javascript');
1722         }
1723
1724     my $comment = '//';  # javascript by default
1725     $comment = '#' if $type=~/perl|tcl/i;
1726     $comment = "'" if $type=~/vbscript/i;
1727
1728     my ($cdata_start,$cdata_end);
1729     if ($XHTML) {
1730        $cdata_start    = "$comment<![CDATA[\n";
1731        $cdata_end     .= "\n$comment]]>";
1732     } else {
1733        $cdata_start  =  "\n<!-- Hide script\n";
1734        $cdata_end    = $comment;
1735        $cdata_end   .= " End script hiding -->\n";
1736    }
1737      my(@satts);
1738      push(@satts,'src'=>$src) if $src;
1739      push(@satts,'language'=>$language) unless defined $type;
1740      push(@satts,'type'=>$type);
1741      $code = $cdata_start . $code . $cdata_end if defined $code;
1742      push(@result,$self->script({@satts},$code || ''));
1743     }
1744     @result;
1745 }
1746 END_OF_FUNC
1747
1748 #### Method: end_html
1749 # End an HTML document.
1750 # Trivial method for completeness.  Just returns "</body>"
1751 ####
1752 'end_html' => <<'END_OF_FUNC',
1753 sub end_html {
1754     return "\n</body>\n</html>";
1755 }
1756 END_OF_FUNC
1757
1758
1759 ################################
1760 # METHODS USED IN BUILDING FORMS
1761 ################################
1762
1763 #### Method: isindex
1764 # Just prints out the isindex tag.
1765 # Parameters:
1766 #  $action -> optional URL of script to run
1767 # Returns:
1768 #   A string containing a <isindex> tag
1769 'isindex' => <<'END_OF_FUNC',
1770 sub isindex {
1771     my($self,@p) = self_or_default(@_);
1772     my($action,@other) = rearrange([ACTION],@p);
1773     $action = qq/ action="$action"/ if $action;
1774     my($other) = @other ? " @other" : '';
1775     return $XHTML ? "<isindex$action$other />" : "<isindex$action$other>";
1776 }
1777 END_OF_FUNC
1778
1779
1780 #### Method: startform
1781 # Start a form
1782 # Parameters:
1783 #   $method -> optional submission method to use (GET or POST)
1784 #   $action -> optional URL of script to run
1785 #   $enctype ->encoding to use (URL_ENCODED or MULTIPART)
1786 'startform' => <<'END_OF_FUNC',
1787 sub startform {
1788     my($self,@p) = self_or_default(@_);
1789
1790     my($method,$action,$enctype,@other) = 
1791         rearrange([METHOD,ACTION,ENCTYPE],@p);
1792
1793     $method  = $self->escapeHTML(lc($method) || 'post');
1794     $enctype = $self->escapeHTML($enctype || &URL_ENCODED);
1795     if (defined $action) {
1796        $action = $self->escapeHTML($action);
1797     }
1798     else {
1799        $action = $self->escapeHTML($self->request_uri);
1800     }
1801     $action = qq(action="$action");
1802     my($other) = @other ? " @other" : '';
1803     $self->{'.parametersToAdd'}={};
1804     return qq/<form method="$method" $action enctype="$enctype"$other>\n/;
1805 }
1806 END_OF_FUNC
1807
1808
1809 #### Method: start_form
1810 # synonym for startform
1811 'start_form' => <<'END_OF_FUNC',
1812 sub start_form {
1813     $XHTML ? &start_multipart_form : &startform;
1814 }
1815 END_OF_FUNC
1816
1817 'end_multipart_form' => <<'END_OF_FUNC',
1818 sub end_multipart_form {
1819     &endform;
1820 }
1821 END_OF_FUNC
1822
1823 #### Method: start_multipart_form
1824 # synonym for startform
1825 'start_multipart_form' => <<'END_OF_FUNC',
1826 sub start_multipart_form {
1827     my($self,@p) = self_or_default(@_);
1828     if (defined($p[0]) && substr($p[0],0,1) eq '-') {
1829       return $self->startform(-enctype=>&MULTIPART,@p);
1830     } else {
1831         my($method,$action,@other) = 
1832             rearrange([METHOD,ACTION],@p);
1833         return $self->startform($method,$action,&MULTIPART,@other);
1834     }
1835 }
1836 END_OF_FUNC
1837
1838
1839 #### Method: endform
1840 # End a form
1841 'endform' => <<'END_OF_FUNC',
1842 sub endform {
1843     my($self,@p) = self_or_default(@_);
1844     if ( $NOSTICKY ) {
1845     return wantarray ? ("</form>") : "\n</form>";
1846     } else {
1847       if (my @fields = $self->get_fields) {
1848          return wantarray ? ("<div>",@fields,"</div>","</form>")
1849                           : "<div>".(join '',@fields)."</div>\n</form>";
1850       } else {
1851          return "</form>";
1852       }
1853     }
1854 }
1855 END_OF_FUNC
1856
1857
1858 '_textfield' => <<'END_OF_FUNC',
1859 sub _textfield {
1860     my($self,$tag,@p) = self_or_default(@_);
1861     my($name,$default,$size,$maxlength,$override,$tabindex,@other) = 
1862         rearrange([NAME,[DEFAULT,VALUE,VALUES],SIZE,MAXLENGTH,[OVERRIDE,FORCE],TABINDEX],@p);
1863
1864     my $current = $override ? $default : 
1865         (defined($self->param($name)) ? $self->param($name) : $default);
1866
1867     $current = defined($current) ? $self->escapeHTML($current,1) : '';
1868     $name = defined($name) ? $self->escapeHTML($name) : '';
1869     my($s) = defined($size) ? qq/ size="$size"/ : '';
1870     my($m) = defined($maxlength) ? qq/ maxlength="$maxlength"/ : '';
1871     my($other) = @other ? " @other" : '';
1872     # this entered at cristy's request to fix problems with file upload fields
1873     # and WebTV -- not sure it won't break stuff
1874     my($value) = $current ne '' ? qq(value="$current") : '';
1875     $tabindex = $self->element_tab($tabindex);
1876     return $XHTML ? qq(<input type="$tag" name="$name" $tabindex$value$s$m$other />) 
1877                   : qq(<input type="$tag" name="$name" $value$s$m$other>);
1878 }
1879 END_OF_FUNC
1880
1881 #### Method: textfield
1882 # Parameters:
1883 #   $name -> Name of the text field
1884 #   $default -> Optional default value of the field if not
1885 #                already defined.
1886 #   $size ->  Optional width of field in characaters.
1887 #   $maxlength -> Optional maximum number of characters.
1888 # Returns:
1889 #   A string containing a <input type="text"> field
1890 #
1891 'textfield' => <<'END_OF_FUNC',
1892 sub textfield {
1893     my($self,@p) = self_or_default(@_);
1894     $self->_textfield('text',@p);
1895 }
1896 END_OF_FUNC
1897
1898
1899 #### Method: filefield
1900 # Parameters:
1901 #   $name -> Name of the file upload field
1902 #   $size ->  Optional width of field in characaters.
1903 #   $maxlength -> Optional maximum number of characters.
1904 # Returns:
1905 #   A string containing a <input type="file"> field
1906 #
1907 'filefield' => <<'END_OF_FUNC',
1908 sub filefield {
1909     my($self,@p) = self_or_default(@_);
1910     $self->_textfield('file',@p);
1911 }
1912 END_OF_FUNC
1913
1914
1915 #### Method: password
1916 # Create a "secret password" entry field
1917 # Parameters:
1918 #   $name -> Name of the field
1919 #   $default -> Optional default value of the field if not
1920 #                already defined.
1921 #   $size ->  Optional width of field in characters.
1922 #   $maxlength -> Optional maximum characters that can be entered.
1923 # Returns:
1924 #   A string containing a <input type="password"> field
1925 #
1926 'password_field' => <<'END_OF_FUNC',
1927 sub password_field {
1928     my ($self,@p) = self_or_default(@_);
1929     $self->_textfield('password',@p);
1930 }
1931 END_OF_FUNC
1932
1933 #### Method: textarea
1934 # Parameters:
1935 #   $name -> Name of the text field
1936 #   $default -> Optional default value of the field if not
1937 #                already defined.
1938 #   $rows ->  Optional number of rows in text area
1939 #   $columns -> Optional number of columns in text area
1940 # Returns:
1941 #   A string containing a <textarea></textarea> tag
1942 #
1943 'textarea' => <<'END_OF_FUNC',
1944 sub textarea {
1945     my($self,@p) = self_or_default(@_);
1946     my($name,$default,$rows,$cols,$override,$tabindex,@other) =
1947         rearrange([NAME,[DEFAULT,VALUE],ROWS,[COLS,COLUMNS],[OVERRIDE,FORCE],TABINDEX],@p);
1948
1949     my($current)= $override ? $default :
1950         (defined($self->param($name)) ? $self->param($name) : $default);
1951
1952     $name = defined($name) ? $self->escapeHTML($name) : '';
1953     $current = defined($current) ? $self->escapeHTML($current) : '';
1954     my($r) = $rows ? qq/ rows="$rows"/ : '';
1955     my($c) = $cols ? qq/ cols="$cols"/ : '';
1956     my($other) = @other ? " @other" : '';
1957     $tabindex = $self->element_tab($tabindex);
1958     return qq{<textarea name="$name" $tabindex$r$c$other>$current</textarea>};
1959 }
1960 END_OF_FUNC
1961
1962
1963 #### Method: button
1964 # Create a javascript button.
1965 # Parameters:
1966 #   $name ->  (optional) Name for the button. (-name)
1967 #   $value -> (optional) Value of the button when selected (and visible name) (-value)
1968 #   $onclick -> (optional) Text of the JavaScript to run when the button is
1969 #                clicked.
1970 # Returns:
1971 #   A string containing a <input type="button"> tag
1972 ####
1973 'button' => <<'END_OF_FUNC',
1974 sub button {
1975     my($self,@p) = self_or_default(@_);
1976
1977     my($label,$value,$script,$tabindex,@other) = rearrange([NAME,[VALUE,LABEL],
1978                                                             [ONCLICK,SCRIPT],TABINDEX],@p);
1979
1980     $label=$self->escapeHTML($label);
1981     $value=$self->escapeHTML($value,1);
1982     $script=$self->escapeHTML($script);
1983
1984     my($name) = '';
1985     $name = qq/ name="$label"/ if $label;
1986     $value = $value || $label;
1987     my($val) = '';
1988     $val = qq/ value="$value"/ if $value;
1989     $script = qq/ onclick="$script"/ if $script;
1990     my($other) = @other ? " @other" : '';
1991     $tabindex = $self->element_tab($tabindex);
1992     return $XHTML ? qq(<input type="button" $tabindex$name$val$script$other />)
1993                   : qq(<input type="button"$name$val$script$other>);
1994 }
1995 END_OF_FUNC
1996
1997
1998 #### Method: submit
1999 # Create a "submit query" button.
2000 # Parameters:
2001 #   $name ->  (optional) Name for the button.
2002 #   $value -> (optional) Value of the button when selected (also doubles as label).
2003 #   $label -> (optional) Label printed on the button(also doubles as the value).
2004 # Returns:
2005 #   A string containing a <input type="submit"> tag
2006 ####
2007 'submit' => <<'END_OF_FUNC',
2008 sub submit {
2009     my($self,@p) = self_or_default(@_);
2010
2011     my($label,$value,$tabindex,@other) = rearrange([NAME,[VALUE,LABEL],TABINDEX],@p);
2012
2013     $label=$self->escapeHTML($label);
2014     $value=$self->escapeHTML($value,1);
2015
2016     my $name = $NOSTICKY ? '' : 'name=".submit" ';
2017     $name = qq/name="$label" / if defined($label);
2018     $value = defined($value) ? $value : $label;
2019     my $val = '';
2020     $val = qq/value="$value" / if defined($value);
2021     $tabindex = $self->element_tab($tabindex);
2022     my($other) = @other ? "@other " : '';
2023     return $XHTML ? qq(<input type="submit" $tabindex$name$val$other/>)
2024                   : qq(<input type="submit" $name$val$other>);
2025 }
2026 END_OF_FUNC
2027
2028
2029 #### Method: reset
2030 # Create a "reset" button.
2031 # Parameters:
2032 #   $name -> (optional) Name for the button.
2033 # Returns:
2034 #   A string containing a <input type="reset"> tag
2035 ####
2036 'reset' => <<'END_OF_FUNC',
2037 sub reset {
2038     my($self,@p) = self_or_default(@_);
2039     my($label,$value,$tabindex,@other) = rearrange(['NAME',['VALUE','LABEL'],TABINDEX],@p);
2040     $label=$self->escapeHTML($label);
2041     $value=$self->escapeHTML($value,1);
2042     my ($name) = ' name=".reset"';
2043     $name = qq/ name="$label"/ if defined($label);
2044     $value = defined($value) ? $value : $label;
2045     my($val) = '';
2046     $val = qq/ value="$value"/ if defined($value);
2047     my($other) = @other ? " @other" : '';
2048     $tabindex = $self->element_tab($tabindex);
2049     return $XHTML ? qq(<input type="reset" $tabindex$name$val$other />)
2050                   : qq(<input type="reset"$name$val$other>);
2051 }
2052 END_OF_FUNC
2053
2054
2055 #### Method: defaults
2056 # Create a "defaults" button.
2057 # Parameters:
2058 #   $name -> (optional) Name for the button.
2059 # Returns:
2060 #   A string containing a <input type="submit" name=".defaults"> tag
2061 #
2062 # Note: this button has a special meaning to the initialization script,
2063 # and tells it to ERASE the current query string so that your defaults
2064 # are used again!
2065 ####
2066 'defaults' => <<'END_OF_FUNC',
2067 sub defaults {
2068     my($self,@p) = self_or_default(@_);
2069
2070     my($label,$tabindex,@other) = rearrange([[NAME,VALUE],TABINDEX],@p);
2071
2072     $label=$self->escapeHTML($label,1);
2073     $label = $label || "Defaults";
2074     my($value) = qq/ value="$label"/;
2075     my($other) = @other ? " @other" : '';
2076     $tabindex = $self->element_tab($tabindex);
2077     return $XHTML ? qq(<input type="submit" name=".defaults" $tabindex$value$other />)
2078                   : qq/<input type="submit" NAME=".defaults"$value$other>/;
2079 }
2080 END_OF_FUNC
2081
2082
2083 #### Method: comment
2084 # Create an HTML <!-- comment -->
2085 # Parameters: a string
2086 'comment' => <<'END_OF_FUNC',
2087 sub comment {
2088     my($self,@p) = self_or_CGI(@_);
2089     return "<!-- @p -->";
2090 }
2091 END_OF_FUNC
2092
2093 #### Method: checkbox
2094 # Create a checkbox that is not logically linked to any others.
2095 # The field value is "on" when the button is checked.
2096 # Parameters:
2097 #   $name -> Name of the checkbox
2098 #   $checked -> (optional) turned on by default if true
2099 #   $value -> (optional) value of the checkbox, 'on' by default
2100 #   $label -> (optional) a user-readable label printed next to the box.
2101 #             Otherwise the checkbox name is used.
2102 # Returns:
2103 #   A string containing a <input type="checkbox"> field
2104 ####
2105 'checkbox' => <<'END_OF_FUNC',
2106 sub checkbox {
2107     my($self,@p) = self_or_default(@_);
2108
2109     my($name,$checked,$value,$label,$override,$tabindex,@other) = 
2110         rearrange([NAME,[CHECKED,SELECTED,ON],VALUE,LABEL,[OVERRIDE,FORCE],TABINDEX],@p);
2111
2112     $value = defined $value ? $value : 'on';
2113
2114     if (!$override && ($self->{'.fieldnames'}->{$name} || 
2115                        defined $self->param($name))) {
2116         $checked = grep($_ eq $value,$self->param($name)) ? $self->_checked(1) : '';
2117     } else {
2118         $checked = $self->_checked($checked);
2119     }
2120     my($the_label) = defined $label ? $label : $name;
2121     $name = $self->escapeHTML($name);
2122     $value = $self->escapeHTML($value,1);
2123     $the_label = $self->escapeHTML($the_label);
2124     my($other) = @other ? "@other " : '';
2125     $tabindex = $self->element_tab($tabindex);
2126     $self->register_parameter($name);
2127     return $XHTML ? CGI::label(qq{<input type="checkbox" name="$name" value="$value" $tabindex$checked$other/>$the_label})
2128                   : qq{<input type="checkbox" name="$name" value="$value"$checked$other>$the_label};
2129 }
2130 END_OF_FUNC
2131
2132
2133
2134 # Escape HTML -- used internally
2135 'escapeHTML' => <<'END_OF_FUNC',
2136 sub escapeHTML {
2137          # hack to work around  earlier hacks
2138          push @_,$_[0] if @_==1 && $_[0] eq 'CGI';
2139          my ($self,$toencode,$newlinestoo) = CGI::self_or_default(@_);
2140          return undef unless defined($toencode);
2141          return $toencode if ref($self) && !$self->{'escape'};
2142          $toencode =~ s{&}{&amp;}gso;
2143          $toencode =~ s{<}{&lt;}gso;
2144          $toencode =~ s{>}{&gt;}gso;
2145          if ($DTD_PUBLIC_IDENTIFIER =~ /[^X]HTML 3\.2/i) {
2146              # $quot; was accidentally omitted from the HTML 3.2 DTD -- see
2147              # <http://validator.w3.org/docs/errors.html#bad-entity> /
2148              # <http://lists.w3.org/Archives/Public/www-html/1997Mar/0003.html>.
2149              $toencode =~ s{"}{&#34;}gso;
2150          }
2151          else {
2152              $toencode =~ s{"}{&quot;}gso;
2153          }
2154          my $latin = uc $self->{'.charset'} eq 'ISO-8859-1' ||
2155                      uc $self->{'.charset'} eq 'WINDOWS-1252';
2156          if ($latin) {  # bug in some browsers
2157                 $toencode =~ s{'}{&#39;}gso;
2158                 $toencode =~ s{\x8b}{&#8249;}gso;
2159                 $toencode =~ s{\x9b}{&#8250;}gso;
2160                 if (defined $newlinestoo && $newlinestoo) {
2161                      $toencode =~ s{\012}{&#10;}gso;
2162                      $toencode =~ s{\015}{&#13;}gso;
2163                 }
2164          }
2165          return $toencode;
2166 }
2167 END_OF_FUNC
2168
2169 # unescape HTML -- used internally
2170 'unescapeHTML' => <<'END_OF_FUNC',
2171 sub unescapeHTML {
2172     # hack to work around  earlier hacks
2173     push @_,$_[0] if @_==1 && $_[0] eq 'CGI';
2174     my ($self,$string) = CGI::self_or_default(@_);
2175     return undef unless defined($string);
2176     my $latin = defined $self->{'.charset'} ? $self->{'.charset'} =~ /^(ISO-8859-1|WINDOWS-1252)$/i
2177                                             : 1;
2178     # thanks to Randal Schwartz for the correct solution to this one
2179     $string=~ s[&(.*?);]{
2180         local $_ = $1;
2181         /^amp$/i        ? "&" :
2182         /^quot$/i       ? '"' :
2183         /^gt$/i         ? ">" :
2184         /^lt$/i         ? "<" :
2185         /^#(\d+)$/ && $latin         ? chr($1) :
2186         /^#x([0-9a-f]+)$/i && $latin ? chr(hex($1)) :
2187         $_
2188         }gex;
2189     return $string;
2190 }
2191 END_OF_FUNC
2192
2193 # Internal procedure - don't use
2194 '_tableize' => <<'END_OF_FUNC',
2195 sub _tableize {
2196     my($rows,$columns,$rowheaders,$colheaders,@elements) = @_;
2197     my @rowheaders = $rowheaders ? @$rowheaders : ();
2198     my @colheaders = $colheaders ? @$colheaders : ();
2199     my($result);
2200
2201     if (defined($columns)) {
2202         $rows = int(0.99 + @elements/$columns) unless defined($rows);
2203     }
2204     if (defined($rows)) {
2205         $columns = int(0.99 + @elements/$rows) unless defined($columns);
2206     }
2207
2208     # rearrange into a pretty table
2209     $result = "<table>";
2210     my($row,$column);
2211     unshift(@colheaders,'') if @colheaders && @rowheaders;
2212     $result .= "<tr>" if @colheaders;
2213     foreach (@colheaders) {
2214         $result .= "<th>$_</th>";
2215     }
2216     for ($row=0;$row<$rows;$row++) {
2217         $result .= "<tr>";
2218         $result .= "<th>$rowheaders[$row]</th>" if @rowheaders;
2219         for ($column=0;$column<$columns;$column++) {
2220             $result .= "<td>" . $elements[$column*$rows + $row] . "</td>"
2221                 if defined($elements[$column*$rows + $row]);
2222         }
2223         $result .= "</tr>";
2224     }
2225     $result .= "</table>";
2226     return $result;
2227 }
2228 END_OF_FUNC
2229
2230
2231 #### Method: radio_group
2232 # Create a list of logically-linked radio buttons.
2233 # Parameters:
2234 #   $name -> Common name for all the buttons.
2235 #   $values -> A pointer to a regular array containing the
2236 #             values for each button in the group.
2237 #   $default -> (optional) Value of the button to turn on by default.  Pass '-'
2238 #               to turn _nothing_ on.
2239 #   $linebreak -> (optional) Set to true to place linebreaks
2240 #             between the buttons.
2241 #   $labels -> (optional)
2242 #             A pointer to an associative array of labels to print next to each checkbox
2243 #             in the form $label{'value'}="Long explanatory label".
2244 #             Otherwise the provided values are used as the labels.
2245 # Returns:
2246 #   An ARRAY containing a series of <input type="radio"> fields
2247 ####
2248 'radio_group' => <<'END_OF_FUNC',
2249 sub radio_group {
2250     my($self,@p) = self_or_default(@_);
2251    $self->_box_group('radio',@p);
2252 }
2253 END_OF_FUNC
2254
2255 #### Method: checkbox_group
2256 # Create a list of logically-linked checkboxes.
2257 # Parameters:
2258 #   $name -> Common name for all the check boxes
2259 #   $values -> A pointer to a regular array containing the
2260 #             values for each checkbox in the group.
2261 #   $defaults -> (optional)
2262 #             1. If a pointer to a regular array of checkbox values,
2263 #             then this will be used to decide which
2264 #             checkboxes to turn on by default.
2265 #             2. If a scalar, will be assumed to hold the
2266 #             value of a single checkbox in the group to turn on. 
2267 #   $linebreak -> (optional) Set to true to place linebreaks
2268 #             between the buttons.
2269 #   $labels -> (optional)
2270 #             A pointer to an associative array of labels to print next to each checkbox
2271 #             in the form $label{'value'}="Long explanatory label".
2272 #             Otherwise the provided values are used as the labels.
2273 # Returns:
2274 #   An ARRAY containing a series of <input type="checkbox"> fields
2275 ####
2276
2277 'checkbox_group' => <<'END_OF_FUNC',
2278 sub checkbox_group {
2279     my($self,@p) = self_or_default(@_);
2280    $self->_box_group('checkbox',@p);
2281 }
2282 END_OF_FUNC
2283
2284 '_box_group' => <<'END_OF_FUNC',
2285 sub _box_group {
2286     my $self     = shift;
2287     my $box_type = shift;
2288
2289     my($name,$values,$defaults,$linebreak,$labels,$attributes,
2290        $rows,$columns,$rowheaders,$colheaders,
2291        $override,$nolabels,$tabindex,@other) =
2292        rearrange([      NAME,[VALUES,VALUE],[DEFAULT,DEFAULTS],LINEBREAK,LABELS,ATTRIBUTES,
2293                         ROWS,[COLUMNS,COLS],ROWHEADERS,COLHEADERS,
2294                         [OVERRIDE,FORCE],NOLABELS,TABINDEX
2295                  ],@_);
2296     my($result,$checked);
2297
2298
2299     my(@elements,@values);
2300     @values = $self->_set_values_and_labels($values,\$labels,$name);
2301     my %checked = $self->previous_or_default($name,$defaults,$override);
2302
2303     # If no check array is specified, check the first by default
2304     $checked{$values[0]}++ if $box_type eq 'radio' && !%checked;
2305
2306     $name=$self->escapeHTML($name);
2307
2308     my %tabs = ();
2309     if ($TABINDEX && $tabindex) {
2310       if (!ref $tabindex) {
2311           $self->element_tab($tabindex);
2312       } elsif (ref $tabindex eq 'ARRAY') {
2313           %tabs = map {$_=>$self->element_tab} @$tabindex;
2314       } elsif (ref $tabindex eq 'HASH') {
2315           %tabs = %$tabindex;
2316       }
2317     }
2318     %tabs = map {$_=>$self->element_tab} @values unless %tabs;
2319
2320     my $other = @other ? "@other " : '';
2321     my $radio_checked;
2322     foreach (@values) {
2323         my $checkit = $self->_checked($box_type eq 'radio' ? ($checked{$_} && !$radio_checked++)
2324                                                            : $checked{$_});
2325         my($break);
2326         if ($linebreak) {
2327           $break = $XHTML ? "<br />" : "<br>";
2328         }
2329         else {
2330           $break = '';
2331         }
2332         my($label)='';
2333         unless (defined($nolabels) && $nolabels) {
2334             $label = $_;
2335             $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2336             $label = $self->escapeHTML($label,1);
2337         }
2338         my $attribs = $self->_set_attributes($_, $attributes);
2339         my $tab     = $tabs{$_};
2340         $_=$self->escapeHTML($_);
2341         if ($XHTML) {
2342            push @elements,
2343               CGI::label(
2344                    qq(<input type="$box_type" name="$name" value="$_" $checkit$other$tab$attribs/>$label)).${break};
2345         } else {
2346            push(@elements,qq/<input type="$box_type" name="$name" value="$_"$checkit$other$tab$attribs>${label}${break}/);
2347         }
2348     }
2349     $self->register_parameter($name);
2350     return wantarray ? @elements : "@elements"
2351            unless defined($columns) || defined($rows);
2352     return _tableize($rows,$columns,$rowheaders,$colheaders,@elements);
2353 }
2354 END_OF_FUNC
2355
2356
2357 #### Method: popup_menu
2358 # Create a popup menu.
2359 # Parameters:
2360 #   $name -> Name for all the menu
2361 #   $values -> A pointer to a regular array containing the
2362 #             text of each menu item.
2363 #   $default -> (optional) Default item to display
2364 #   $labels -> (optional)
2365 #             A pointer to an associative array of labels to print next to each checkbox
2366 #             in the form $label{'value'}="Long explanatory label".
2367 #             Otherwise the provided values are used as the labels.
2368 # Returns:
2369 #   A string containing the definition of a popup menu.
2370 ####
2371 'popup_menu' => <<'END_OF_FUNC',
2372 sub popup_menu {
2373     my($self,@p) = self_or_default(@_);
2374
2375     my($name,$values,$default,$labels,$attributes,$override,$tabindex,@other) =
2376        rearrange([NAME,[VALUES,VALUE],[DEFAULT,DEFAULTS],LABELS,
2377        ATTRIBUTES,[OVERRIDE,FORCE],TABINDEX],@p);
2378     my($result,$selected);
2379
2380     if (!$override && defined($self->param($name))) {
2381         $selected = $self->param($name);
2382     } else {
2383         $selected = $default;
2384     }
2385     $name=$self->escapeHTML($name);
2386     my($other) = @other ? " @other" : '';
2387
2388     my(@values);
2389     @values = $self->_set_values_and_labels($values,\$labels,$name);
2390     $tabindex = $self->element_tab($tabindex);
2391     $result = qq/<select name="$name" $tabindex$other>\n/;
2392     foreach (@values) {
2393         if (/<optgroup/) {
2394             foreach (split(/\n/)) {
2395                 my $selectit = $XHTML ? 'selected="selected"' : 'selected';
2396                 s/(value="$selected")/$selectit $1/ if defined $selected;
2397                 $result .= "$_\n";
2398             }
2399         }
2400         else {
2401           my $attribs = $self->_set_attributes($_, $attributes);
2402           my($selectit) = defined($selected) ? $self->_selected($selected eq $_) : '';
2403           my($label) = $_;
2404           $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2405           my($value) = $self->escapeHTML($_);
2406           $label=$self->escapeHTML($label,1);
2407           $result .= "<option${attribs} ${selectit}value=\"$value\">$label</option>\n";
2408         }
2409     }
2410
2411     $result .= "</select>";
2412     return $result;
2413 }
2414 END_OF_FUNC
2415
2416
2417 #### Method: optgroup
2418 # Create a optgroup.
2419 # Parameters:
2420 #   $name -> Label for the group
2421 #   $values -> A pointer to a regular array containing the
2422 #              values for each option line in the group.
2423 #   $labels -> (optional)
2424 #              A pointer to an associative array of labels to print next to each item
2425 #              in the form $label{'value'}="Long explanatory label".
2426 #              Otherwise the provided values are used as the labels.
2427 #   $labeled -> (optional)
2428 #               A true value indicates the value should be used as the label attribute
2429 #               in the option elements.
2430 #               The label attribute specifies the option label presented to the user.
2431 #               This defaults to the content of the <option> element, but the label
2432 #               attribute allows authors to more easily use optgroup without sacrificing
2433 #               compatibility with browsers that do not support option groups.
2434 #   $novals -> (optional)
2435 #              A true value indicates to suppress the val attribute in the option elements
2436 # Returns:
2437 #   A string containing the definition of an option group.
2438 ####
2439 'optgroup' => <<'END_OF_FUNC',
2440 sub optgroup {
2441     my($self,@p) = self_or_default(@_);
2442     my($name,$values,$attributes,$labeled,$noval,$labels,@other)
2443         = rearrange([NAME,[VALUES,VALUE],ATTRIBUTES,LABELED,NOVALS,LABELS],@p);
2444
2445     my($result,@values);
2446     @values = $self->_set_values_and_labels($values,\$labels,$name,$labeled,$novals);
2447     my($other) = @other ? " @other" : '';
2448
2449     $name=$self->escapeHTML($name);
2450     $result = qq/<optgroup label="$name"$other>\n/;
2451     foreach (@values) {
2452         if (/<optgroup/) {
2453             foreach (split(/\n/)) {
2454                 my $selectit = $XHTML ? 'selected="selected"' : 'selected';
2455                 s/(value="$selected")/$selectit $1/ if defined $selected;
2456                 $result .= "$_\n";
2457             }
2458         }
2459         else {
2460             my $attribs = $self->_set_attributes($_, $attributes);
2461             my($label) = $_;
2462             $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2463             $label=$self->escapeHTML($label);
2464             my($value)=$self->escapeHTML($_,1);
2465             $result .= $labeled ? $novals ? "<option$attribs label=\"$value\">$label</option>\n"
2466                                           : "<option$attribs label=\"$value\" value=\"$value\">$label</option>\n"
2467                                 : $novals ? "<option$attribs>$label</option>\n"
2468                                           : "<option$attribs value=\"$value\">$label</option>\n";
2469         }
2470     }
2471     $result .= "</optgroup>";
2472     return $result;
2473 }
2474 END_OF_FUNC
2475
2476
2477 #### Method: scrolling_list
2478 # Create a scrolling list.
2479 # Parameters:
2480 #   $name -> name for the list
2481 #   $values -> A pointer to a regular array containing the
2482 #             values for each option line in the list.
2483 #   $defaults -> (optional)
2484 #             1. If a pointer to a regular array of options,
2485 #             then this will be used to decide which
2486 #             lines to turn on by default.
2487 #             2. Otherwise holds the value of the single line to turn on.
2488 #   $size -> (optional) Size of the list.
2489 #   $multiple -> (optional) If set, allow multiple selections.
2490 #   $labels -> (optional)
2491 #             A pointer to an associative array of labels to print next to each checkbox
2492 #             in the form $label{'value'}="Long explanatory label".
2493 #             Otherwise the provided values are used as the labels.
2494 # Returns:
2495 #   A string containing the definition of a scrolling list.
2496 ####
2497 'scrolling_list' => <<'END_OF_FUNC',
2498 sub scrolling_list {
2499     my($self,@p) = self_or_default(@_);
2500     my($name,$values,$defaults,$size,$multiple,$labels,$attributes,$override,$tabindex,@other)
2501         = rearrange([NAME,[VALUES,VALUE],[DEFAULTS,DEFAULT],
2502           SIZE,MULTIPLE,LABELS,ATTRIBUTES,[OVERRIDE,FORCE],TABINDEX],@p);
2503
2504     my($result,@values);
2505     @values = $self->_set_values_and_labels($values,\$labels,$name);
2506
2507     $size = $size || scalar(@values);
2508
2509     my(%selected) = $self->previous_or_default($name,$defaults,$override);
2510     my($is_multiple) = $multiple ? qq/ multiple="multiple"/ : '';
2511     my($has_size) = $size ? qq/ size="$size"/: '';
2512     my($other) = @other ? " @other" : '';
2513
2514     $name=$self->escapeHTML($name);
2515     $tabindex = $self->element_tab($tabindex);
2516     $result = qq/<select name="$name" $tabindex$has_size$is_multiple$other>\n/;
2517     foreach (@values) {
2518         my($selectit) = $self->_selected($selected{$_});
2519         my($label) = $_;
2520         $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2521         $label=$self->escapeHTML($label);
2522         my($value)=$self->escapeHTML($_,1);
2523         my $attribs = $self->_set_attributes($_, $attributes);
2524         $result .= "<option ${selectit}${attribs}value=\"$value\">$label</option>\n";
2525     }
2526     $result .= "</select>";
2527     $self->register_parameter($name);
2528     return $result;
2529 }
2530 END_OF_FUNC
2531
2532
2533 #### Method: hidden
2534 # Parameters:
2535 #   $name -> Name of the hidden field
2536 #   @default -> (optional) Initial values of field (may be an array)
2537 #      or
2538 #   $default->[initial values of field]
2539 # Returns:
2540 #   A string containing a <input type="hidden" name="name" value="value">
2541 ####
2542 'hidden' => <<'END_OF_FUNC',
2543 sub hidden {
2544     my($self,@p) = self_or_default(@_);
2545
2546     # this is the one place where we departed from our standard
2547     # calling scheme, so we have to special-case (darn)
2548     my(@result,@value);
2549     my($name,$default,$override,@other) = 
2550         rearrange([NAME,[DEFAULT,VALUE,VALUES],[OVERRIDE,FORCE]],@p);
2551
2552     my $do_override = 0;
2553     if ( ref($p[0]) || substr($p[0],0,1) eq '-') {
2554         @value = ref($default) ? @{$default} : $default;
2555         $do_override = $override;
2556     } else {
2557         foreach ($default,$override,@other) {
2558             push(@value,$_) if defined($_);
2559         }
2560     }
2561
2562     # use previous values if override is not set
2563     my @prev = $self->param($name);
2564     @value = @prev if !$do_override && @prev;
2565
2566     $name=$self->escapeHTML($name);
2567     foreach (@value) {
2568         $_ = defined($_) ? $self->escapeHTML($_,1) : '';
2569         push @result,$XHTML ? qq(<input type="hidden" name="$name" value="$_" @other />)
2570                             : qq(<input type="hidden" name="$name" value="$_" @other>);
2571     }
2572     return wantarray ? @result : join('',@result);
2573 }
2574 END_OF_FUNC
2575
2576
2577 #### Method: image_button
2578 # Parameters:
2579 #   $name -> Name of the button
2580 #   $src ->  URL of the image source
2581 #   $align -> Alignment style (TOP, BOTTOM or MIDDLE)
2582 # Returns:
2583 #   A string containing a <input type="image" name="name" src="url" align="alignment">
2584 ####
2585 'image_button' => <<'END_OF_FUNC',
2586 sub image_button {
2587     my($self,@p) = self_or_default(@_);
2588
2589     my($name,$src,$alignment,@other) =
2590         rearrange([NAME,SRC,ALIGN],@p);
2591
2592     my($align) = $alignment ? " align=\U\"$alignment\"" : '';
2593     my($other) = @other ? " @other" : '';
2594     $name=$self->escapeHTML($name);
2595     return $XHTML ? qq(<input type="image" name="$name" src="$src"$align$other />)
2596                   : qq/<input type="image" name="$name" src="$src"$align$other>/;
2597 }
2598 END_OF_FUNC
2599
2600
2601 #### Method: self_url
2602 # Returns a URL containing the current script and all its
2603 # param/value pairs arranged as a query.  You can use this
2604 # to create a link that, when selected, will reinvoke the
2605 # script with all its state information preserved.
2606 ####
2607 'self_url' => <<'END_OF_FUNC',
2608 sub self_url {
2609     my($self,@p) = self_or_default(@_);
2610     return $self->url('-path_info'=>1,'-query'=>1,'-full'=>1,@p);
2611 }
2612 END_OF_FUNC
2613
2614
2615 # This is provided as a synonym to self_url() for people unfortunate
2616 # enough to have incorporated it into their programs already!
2617 'state' => <<'END_OF_FUNC',
2618 sub state {
2619     &self_url;
2620 }
2621 END_OF_FUNC
2622
2623
2624 #### Method: url
2625 # Like self_url, but doesn't return the query string part of
2626 # the URL.
2627 ####
2628 'url' => <<'END_OF_FUNC',
2629 sub url {
2630     my($self,@p) = self_or_default(@_);
2631     my ($relative,$absolute,$full,$path_info,$query,$base,$rewrite) = 
2632         rearrange(['RELATIVE','ABSOLUTE','FULL',['PATH','PATH_INFO'],['QUERY','QUERY_STRING'],'BASE','REWRITE'],@p);
2633     my $url  = '';
2634     $full++      if $base || !($relative || $absolute);
2635     $rewrite++   unless defined $rewrite;
2636
2637     my $path        =  $self->path_info;
2638     my $script_name =  $self->script_name;
2639     my $request_uri =  unescape($self->request_uri) || '';
2640     my $query_str   =  $self->query_string;
2641
2642     my $rewrite_in_use = $request_uri && $request_uri !~ /^$script_name/;
2643     undef $path if $rewrite_in_use && $rewrite;  # path not valid when rewriting active
2644
2645     my $uri         =  $rewrite && $request_uri ? $request_uri : $script_name;
2646     $uri            =~ s/\?.*$//;                                 # remove query string
2647     $uri            =~ s/\Q$path\E$//      if defined $path;      # remove path
2648
2649     if ($full) {
2650         my $protocol = $self->protocol();
2651         $url = "$protocol://";
2652         my $vh = http('x_forwarded_host') || http('host');
2653         if ($vh) {
2654             $url .= $vh;
2655         } else {
2656             $url .= server_name();
2657             my $port = $self->server_port;
2658             $url .= ":" . $port
2659                 unless (lc($protocol) eq 'http'  && $port == 80)
2660                     || (lc($protocol) eq 'https' && $port == 443);
2661         }
2662         return $url if $base;
2663         $url .= $uri;
2664     } elsif ($relative) {
2665         ($url) = $uri =~ m!([^/]+)$!;
2666     } elsif ($absolute) {
2667         $url = $uri;
2668     }
2669
2670     $url .= $path         if $path_info and defined $path;
2671     $url .= "?$query_str" if $query     and $query_str ne '';
2672     $url =~ s/([^a-zA-Z0-9_.%;&?\/\\:+=~-])/sprintf("%%%02X",ord($1))/eg;
2673     return $url;
2674 }
2675
2676 END_OF_FUNC
2677
2678 #### Method: cookie
2679 # Set or read a cookie from the specified name.
2680 # Cookie can then be passed to header().
2681 # Usual rules apply to the stickiness of -value.
2682 #  Parameters:
2683 #   -name -> name for this cookie (optional)
2684 #   -value -> value of this cookie (scalar, array or hash) 
2685 #   -path -> paths for which this cookie is valid (optional)
2686 #   -domain -> internet domain in which this cookie is valid (optional)
2687 #   -secure -> if true, cookie only passed through secure channel (optional)
2688 #   -expires -> expiry date in format Wdy, DD-Mon-YYYY HH:MM:SS GMT (optional)
2689 ####
2690 'cookie' => <<'END_OF_FUNC',
2691 sub cookie {
2692     my($self,@p) = self_or_default(@_);
2693     my($name,$value,$path,$domain,$secure,$expires) =
2694         rearrange([NAME,[VALUE,VALUES],PATH,DOMAIN,SECURE,EXPIRES],@p);
2695
2696     require CGI::Cookie;
2697
2698     # if no value is supplied, then we retrieve the
2699     # value of the cookie, if any.  For efficiency, we cache the parsed
2700     # cookies in our state variables.
2701     unless ( defined($value) ) {
2702         $self->{'.cookies'} = CGI::Cookie->fetch
2703             unless $self->{'.cookies'};
2704
2705         # If no name is supplied, then retrieve the names of all our cookies.
2706         return () unless $self->{'.cookies'};
2707         return keys %{$self->{'.cookies'}} unless $name;
2708         return () unless $self->{'.cookies'}->{$name};
2709         return $self->{'.cookies'}->{$name}->value if defined($name) && $name ne '';
2710     }
2711
2712     # If we get here, we're creating a new cookie
2713     return undef unless defined($name) && $name ne '';  # this is an error
2714
2715     my @param;
2716     push(@param,'-name'=>$name);
2717     push(@param,'-value'=>$value);
2718     push(@param,'-domain'=>$domain) if $domain;
2719     push(@param,'-path'=>$path) if $path;
2720     push(@param,'-expires'=>$expires) if $expires;
2721     push(@param,'-secure'=>$secure) if $secure;
2722
2723     return new CGI::Cookie(@param);
2724 }
2725 END_OF_FUNC
2726
2727 'parse_keywordlist' => <<'END_OF_FUNC',
2728 sub parse_keywordlist {
2729     my($self,$tosplit) = @_;
2730     $tosplit = unescape($tosplit); # unescape the keywords
2731     $tosplit=~tr/+/ /;          # pluses to spaces
2732     my(@keywords) = split(/\s+/,$tosplit);
2733     return @keywords;
2734 }
2735 END_OF_FUNC
2736
2737 'param_fetch' => <<'END_OF_FUNC',
2738 sub param_fetch {
2739     my($self,@p) = self_or_default(@_);
2740     my($name) = rearrange([NAME],@p);
2741     unless (exists($self->{$name})) {
2742         $self->add_parameter($name);
2743         $self->{$name} = [];
2744     }
2745     
2746     return $self->{$name};
2747 }
2748 END_OF_FUNC
2749
2750 ###############################################
2751 # OTHER INFORMATION PROVIDED BY THE ENVIRONMENT
2752 ###############################################
2753
2754 #### Method: path_info
2755 # Return the extra virtual path information provided
2756 # after the URL (if any)
2757 ####
2758 'path_info' => <<'END_OF_FUNC',
2759 sub path_info {
2760     my ($self,$info) = self_or_default(@_);
2761     if (defined($info)) {
2762         $info = "/$info" if $info ne '' &&  substr($info,0,1) ne '/';
2763         $self->{'.path_info'} = $info;
2764     } elsif (! defined($self->{'.path_info'}) ) {
2765         my (undef,$path_info) = $self->_name_and_path_from_env;
2766         $self->{'.path_info'} = $path_info || '';
2767     }
2768     return $self->{'.path_info'};
2769 }
2770 END_OF_FUNC
2771
2772 # WE USE THIS TO COMPENSATE FOR A BUG IN APACHE 2 PRESENT AT LEAST UP THROUGH 2.0.54
2773 '_name_and_path_from_env' => <<'END_OF_FUNC',
2774 sub _name_and_path_from_env {
2775    my $self = shift;
2776    my $raw_script_name = $ENV{SCRIPT_NAME} || '';
2777    my $raw_path_info   = $ENV{PATH_INFO}   || '';
2778    my $uri             = unescape($self->request_uri) || '';
2779
2780    my $protected    = quotemeta($raw_path_info);
2781    $raw_script_name =~ s/$protected$//;
2782
2783    my @uri_double_slashes  = $uri =~ m^(/{2,}?)^g;
2784    my @path_double_slashes = "$raw_script_name $raw_path_info" =~ m^(/{2,}?)^g;
2785
2786    my $apache_bug      = @uri_double_slashes != @path_double_slashes;
2787    return ($raw_script_name,$raw_path_info) unless $apache_bug;
2788
2789    my $path_info_search = quotemeta($raw_path_info);
2790    $path_info_search    =~ s!/!/+!g;
2791    if ($uri =~ m/^(.+)($path_info_search)/) {
2792        return ($1,$2);
2793    } else {
2794        return ($raw_script_name,$raw_path_info);
2795    }
2796 }
2797 END_OF_FUNC
2798
2799
2800 #### Method: request_method
2801 # Returns 'POST', 'GET', 'PUT' or 'HEAD'
2802 ####
2803 'request_method' => <<'END_OF_FUNC',
2804 sub request_method {
2805     return $ENV{'REQUEST_METHOD'};
2806 }
2807 END_OF_FUNC
2808
2809 #### Method: content_type
2810 # Returns the content_type string
2811 ####
2812 'content_type' => <<'END_OF_FUNC',
2813 sub content_type {
2814     return $ENV{'CONTENT_TYPE'};
2815 }
2816 END_OF_FUNC
2817
2818 #### Method: path_translated
2819 # Return the physical path information provided
2820 # by the URL (if any)
2821 ####
2822 'path_translated' => <<'END_OF_FUNC',
2823 sub path_translated {
2824     return $ENV{'PATH_TRANSLATED'};
2825 }
2826 END_OF_FUNC
2827
2828
2829 #### Method: request_uri
2830 # Return the literal request URI
2831 ####
2832 'request_uri' => <<'END_OF_FUNC',
2833 sub request_uri {
2834     return $ENV{'REQUEST_URI'};
2835 }
2836 END_OF_FUNC
2837
2838
2839 #### Method: query_string
2840 # Synthesize a query string from our current
2841 # parameters
2842 ####
2843 'query_string' => <<'END_OF_FUNC',
2844 sub query_string {
2845     my($self) = self_or_default(@_);
2846     my($param,$value,@pairs);
2847     foreach $param ($self->param) {
2848         my($eparam) = escape($param);
2849         foreach $value ($self->param($param)) {
2850             $value = escape($value);
2851             next unless defined $value;
2852             push(@pairs,"$eparam=$value");
2853         }
2854     }
2855     foreach (keys %{$self->{'.fieldnames'}}) {
2856       push(@pairs,".cgifields=".escape("$_"));
2857     }
2858     return join($USE_PARAM_SEMICOLONS ? ';' : '&',@pairs);
2859 }
2860 END_OF_FUNC
2861
2862
2863 #### Method: accept
2864 # Without parameters, returns an array of the
2865 # MIME types the browser accepts.
2866 # With a single parameter equal to a MIME
2867 # type, will return undef if the browser won't
2868 # accept it, 1 if the browser accepts it but
2869 # doesn't give a preference, or a floating point
2870 # value between 0.0 and 1.0 if the browser
2871 # declares a quantitative score for it.
2872 # This handles MIME type globs correctly.
2873 ####
2874 'Accept' => <<'END_OF_FUNC',
2875 sub Accept {
2876     my($self,$search) = self_or_CGI(@_);
2877     my(%prefs,$type,$pref,$pat);
2878     
2879     my(@accept) = split(',',$self->http('accept'));
2880
2881     foreach (@accept) {
2882         ($pref) = /q=(\d\.\d+|\d+)/;
2883         ($type) = m#(\S+/[^;]+)#;
2884         next unless $type;
2885         $prefs{$type}=$pref || 1;
2886     }
2887
2888     return keys %prefs unless $search;
2889     
2890     # if a search type is provided, we may need to
2891     # perform a pattern matching operation.
2892     # The MIME types use a glob mechanism, which
2893     # is easily translated into a perl pattern match
2894
2895     # First return the preference for directly supported
2896     # types:
2897     return $prefs{$search} if $prefs{$search};
2898
2899     # Didn't get it, so try pattern matching.
2900     foreach (keys %prefs) {
2901         next unless /\*/;       # not a pattern match
2902         ($pat = $_) =~ s/([^\w*])/\\$1/g; # escape meta characters
2903         $pat =~ s/\*/.*/g; # turn it into a pattern
2904         return $prefs{$_} if $search=~/$pat/;
2905     }
2906 }
2907 END_OF_FUNC
2908
2909
2910 #### Method: user_agent
2911 # If called with no parameters, returns the user agent.
2912 # If called with one parameter, does a pattern match (case
2913 # insensitive) on the user agent.
2914 ####
2915 'user_agent' => <<'END_OF_FUNC',
2916 sub user_agent {
2917     my($self,$match)=self_or_CGI(@_);
2918     return $self->http('user_agent') unless $match;
2919     return $self->http('user_agent') =~ /$match/i;
2920 }
2921 END_OF_FUNC
2922
2923
2924 #### Method: raw_cookie
2925 # Returns the magic cookies for the session.
2926 # The cookies are not parsed or altered in any way, i.e.
2927 # cookies are returned exactly as given in the HTTP
2928 # headers.  If a cookie name is given, only that cookie's
2929 # value is returned, otherwise the entire raw cookie
2930 # is returned.
2931 ####
2932 'raw_cookie' => <<'END_OF_FUNC',
2933 sub raw_cookie {
2934     my($self,$key) = self_or_CGI(@_);
2935
2936     require CGI::Cookie;
2937
2938     if (defined($key)) {
2939         $self->{'.raw_cookies'} = CGI::Cookie->raw_fetch
2940             unless $self->{'.raw_cookies'};
2941
2942         return () unless $self->{'.raw_cookies'};
2943         return () unless $self->{'.raw_cookies'}->{$key};
2944         return $self->{'.raw_cookies'}->{$key};
2945     }
2946     return $self->http('cookie') || $ENV{'COOKIE'} || '';
2947 }
2948 END_OF_FUNC
2949
2950 #### Method: virtual_host
2951 # Return the name of the virtual_host, which
2952 # is not always the same as the server
2953 ######
2954 'virtual_host' => <<'END_OF_FUNC',
2955 sub virtual_host {
2956     my $vh = http('x_forwarded_host') || http('host') || server_name();
2957     $vh =~ s/:\d+$//;           # get rid of port number
2958     return $vh;
2959 }
2960 END_OF_FUNC
2961
2962 #### Method: remote_host
2963 # Return the name of the remote host, or its IP
2964 # address if unavailable.  If this variable isn't
2965 # defined, it returns "localhost" for debugging
2966 # purposes.
2967 ####
2968 'remote_host' => <<'END_OF_FUNC',
2969 sub remote_host {
2970     return $ENV{'REMOTE_HOST'} || $ENV{'REMOTE_ADDR'} 
2971     || 'localhost';
2972 }
2973 END_OF_FUNC
2974
2975
2976 #### Method: remote_addr
2977 # Return the IP addr of the remote host.
2978 ####
2979 'remote_addr' => <<'END_OF_FUNC',
2980 sub remote_addr {
2981     return $ENV{'REMOTE_ADDR'} || '127.0.0.1';
2982 }
2983 END_OF_FUNC
2984
2985
2986 #### Method: script_name
2987 # Return the partial URL to this script for
2988 # self-referencing scripts.  Also see
2989 # self_url(), which returns a URL with all state information
2990 # preserved.
2991 ####
2992 'script_name' => <<'END_OF_FUNC',
2993 sub script_name {
2994     my ($self,@p) = self_or_default(@_);
2995     if (@p) {
2996         $self->{'.script_name'} = shift;
2997     } elsif (!exists $self->{'.script_name'}) {
2998         my ($script_name,$path_info) = $self->_name_and_path_from_env();
2999         $self->{'.script_name'} = $script_name;
3000     }
3001     return $self->{'.script_name'};
3002 }
3003 END_OF_FUNC
3004
3005
3006 #### Method: referer
3007 # Return the HTTP_REFERER: useful for generating
3008 # a GO BACK button.
3009 ####
3010 'referer' => <<'END_OF_FUNC',
3011 sub referer {
3012     my($self) = self_or_CGI(@_);
3013     return $self->http('referer');
3014 }
3015 END_OF_FUNC
3016
3017
3018 #### Method: server_name
3019 # Return the name of the server
3020 ####
3021 'server_name' => <<'END_OF_FUNC',
3022 sub server_name {
3023     return $ENV{'SERVER_NAME'} || 'localhost';
3024 }
3025 END_OF_FUNC
3026
3027 #### Method: server_software
3028 # Return the name of the server software
3029 ####
3030 'server_software' => <<'END_OF_FUNC',
3031 sub server_software {
3032     return $ENV{'SERVER_SOFTWARE'} || 'cmdline';
3033 }
3034 END_OF_FUNC
3035
3036 #### Method: virtual_port
3037 # Return the server port, taking virtual hosts into account
3038 ####
3039 'virtual_port' => <<'END_OF_FUNC',
3040 sub virtual_port {
3041     my($self) = self_or_default(@_);
3042     my $vh = $self->http('x_forwarded_host') || $self->http('host');
3043     my $protocol = $self->protocol;
3044     if ($vh) {
3045         return ($vh =~ /:(\d+)$/)[0] || ($protocol eq 'https' ? 443 : 80);
3046     } else {
3047         return $self->server_port();
3048     }
3049 }
3050 END_OF_FUNC
3051
3052 #### Method: server_port
3053 # Return the tcp/ip port the server is running on
3054 ####
3055 'server_port' => <<'END_OF_FUNC',
3056 sub server_port {
3057     return $ENV{'SERVER_PORT'} || 80; # for debugging
3058 }
3059 END_OF_FUNC
3060
3061 #### Method: server_protocol
3062 # Return the protocol (usually HTTP/1.0)
3063 ####
3064 'server_protocol' => <<'END_OF_FUNC',
3065 sub server_protocol {
3066     return $ENV{'SERVER_PROTOCOL'} || 'HTTP/1.0'; # for debugging
3067 }
3068 END_OF_FUNC
3069
3070 #### Method: http
3071 # Return the value of an HTTP variable, or
3072 # the list of variables if none provided
3073 ####
3074 'http' => <<'END_OF_FUNC',
3075 sub http {
3076     my ($self,$parameter) = self_or_CGI(@_);
3077     return $ENV{$parameter} if $parameter=~/^HTTP/;
3078     $parameter =~ tr/-/_/;
3079     return $ENV{"HTTP_\U$parameter\E"} if $parameter;
3080     my(@p);
3081     foreach (keys %ENV) {
3082         push(@p,$_) if /^HTTP/;
3083     }
3084     return @p;
3085 }
3086 END_OF_FUNC
3087
3088 #### Method: https
3089 # Return the value of HTTPS
3090 ####
3091 'https' => <<'END_OF_FUNC',
3092 sub https {
3093     local($^W)=0;
3094     my ($self,$parameter) = self_or_CGI(@_);
3095     return $ENV{HTTPS} unless $parameter;
3096     return $ENV{$parameter} if $parameter=~/^HTTPS/;
3097     $parameter =~ tr/-/_/;
3098     return $ENV{"HTTPS_\U$parameter\E"} if $parameter;
3099     my(@p);
3100     foreach (keys %ENV) {
3101         push(@p,$_) if /^HTTPS/;
3102     }
3103     return @p;
3104 }
3105 END_OF_FUNC
3106
3107 #### Method: protocol
3108 # Return the protocol (http or https currently)
3109 ####
3110 'protocol' => <<'END_OF_FUNC',
3111 sub protocol {
3112     local($^W)=0;
3113     my $self = shift;
3114     return 'https' if uc($self->https()) eq 'ON'; 
3115     return 'https' if $self->server_port == 443;
3116     my $prot = $self->server_protocol;
3117     my($protocol,$version) = split('/',$prot);
3118     return "\L$protocol\E";
3119 }
3120 END_OF_FUNC
3121
3122 #### Method: remote_ident
3123 # Return the identity of the remote user
3124 # (but only if his host is running identd)
3125 ####
3126 'remote_ident' => <<'END_OF_FUNC',
3127 sub remote_ident {
3128     return $ENV{'REMOTE_IDENT'};
3129 }
3130 END_OF_FUNC
3131
3132
3133 #### Method: auth_type
3134 # Return the type of use verification/authorization in use, if any.
3135 ####
3136 'auth_type' => <<'END_OF_FUNC',
3137 sub auth_type {
3138     return $ENV{'AUTH_TYPE'};
3139 }
3140 END_OF_FUNC
3141
3142
3143 #### Method: remote_user
3144 # Return the authorization name used for user
3145 # verification.
3146 ####
3147 'remote_user' => <<'END_OF_FUNC',
3148 sub remote_user {
3149     return $ENV{'REMOTE_USER'};
3150 }
3151 END_OF_FUNC
3152
3153
3154 #### Method: user_name
3155 # Try to return the remote user's name by hook or by
3156 # crook
3157 ####
3158 'user_name' => <<'END_OF_FUNC',
3159 sub user_name {
3160     my ($self) = self_or_CGI(@_);
3161     return $self->http('from') || $ENV{'REMOTE_IDENT'} || $ENV{'REMOTE_USER'};
3162 }
3163 END_OF_FUNC
3164
3165 #### Method: nosticky
3166 # Set or return the NOSTICKY global flag
3167 ####
3168 'nosticky' => <<'END_OF_FUNC',
3169 sub nosticky {
3170     my ($self,$param) = self_or_CGI(@_);
3171     $CGI::NOSTICKY = $param if defined($param);
3172     return $CGI::NOSTICKY;
3173 }
3174 END_OF_FUNC
3175
3176 #### Method: nph
3177 # Set or return the NPH global flag
3178 ####
3179 'nph' => <<'END_OF_FUNC',
3180 sub nph {
3181     my ($self,$param) = self_or_CGI(@_);
3182     $CGI::NPH = $param if defined($param);
3183     return $CGI::NPH;
3184 }
3185 END_OF_FUNC
3186
3187 #### Method: private_tempfiles
3188 # Set or return the private_tempfiles global flag
3189 ####
3190 'private_tempfiles' => <<'END_OF_FUNC',
3191 sub private_tempfiles {
3192     my ($self,$param) = self_or_CGI(@_);
3193     $CGI::PRIVATE_TEMPFILES = $param if defined($param);
3194     return $CGI::PRIVATE_TEMPFILES;
3195 }
3196 END_OF_FUNC
3197 #### Method: close_upload_files
3198 # Set or return the close_upload_files global flag
3199 ####
3200 'close_upload_files' => <<'END_OF_FUNC',
3201 sub close_upload_files {
3202     my ($self,$param) = self_or_CGI(@_);
3203     $CGI::CLOSE_UPLOAD_FILES = $param if defined($param);
3204     return $CGI::CLOSE_UPLOAD_FILES;
3205 }
3206 END_OF_FUNC
3207
3208
3209 #### Method: default_dtd
3210 # Set or return the default_dtd global
3211 ####
3212 'default_dtd' => <<'END_OF_FUNC',
3213 sub default_dtd {
3214     my ($self,$param,$param2) = self_or_CGI(@_);
3215     if (defined $param2 && defined $param) {
3216         $CGI::DEFAULT_DTD = [ $param, $param2 ];
3217     } elsif (defined $param) {
3218         $CGI::DEFAULT_DTD = $param;
3219     }
3220     return $CGI::DEFAULT_DTD;
3221 }
3222 END_OF_FUNC
3223
3224 # -------------- really private subroutines -----------------
3225 'previous_or_default' => <<'END_OF_FUNC',
3226 sub previous_or_default {
3227     my($self,$name,$defaults,$override) = @_;
3228     my(%selected);
3229
3230     if (!$override && ($self->{'.fieldnames'}->{$name} || 
3231                        defined($self->param($name)) ) ) {
3232         grep($selected{$_}++,$self->param($name));
3233     } elsif (defined($defaults) && ref($defaults) && 
3234              (ref($defaults) eq 'ARRAY')) {
3235         grep($selected{$_}++,@{$defaults});
3236     } else {
3237         $selected{$defaults}++ if defined($defaults);
3238     }
3239
3240     return %selected;
3241 }
3242 END_OF_FUNC
3243
3244 'register_parameter' => <<'END_OF_FUNC',
3245 sub register_parameter {
3246     my($self,$param) = @_;
3247     $self->{'.parametersToAdd'}->{$param}++;
3248 }
3249 END_OF_FUNC
3250
3251 'get_fields' => <<'END_OF_FUNC',
3252 sub get_fields {
3253     my($self) = @_;
3254     return $self->CGI::hidden('-name'=>'.cgifields',
3255                               '-values'=>[keys %{$self->{'.parametersToAdd'}}],
3256                               '-override'=>1);
3257 }
3258 END_OF_FUNC
3259
3260 'read_from_cmdline' => <<'END_OF_FUNC',
3261 sub read_from_cmdline {
3262     my($input,@words);
3263     my($query_string);
3264     my($subpath);
3265     if ($DEBUG && @ARGV) {
3266         @words = @ARGV;
3267     } elsif ($DEBUG > 1) {
3268         require "shellwords.pl";
3269         print STDERR "(offline mode: enter name=value pairs on standard input; press ^D or ^Z when done)\n";
3270         chomp(@lines = <STDIN>); # remove newlines
3271         $input = join(" ",@lines);
3272         @words = &shellwords($input);    
3273     }
3274     foreach (@words) {
3275         s/\\=/%3D/g;
3276         s/\\&/%26/g;        
3277     }
3278
3279     if ("@words"=~/=/) {
3280         $query_string = join('&',@words);
3281     } else {
3282         $query_string = join('+',@words);
3283     }
3284     if ($query_string =~ /^(.*?)\?(.*)$/)
3285     {
3286         $query_string = $2;
3287         $subpath = $1;
3288     }
3289     return { 'query_string' => $query_string, 'subpath' => $subpath };
3290 }
3291 END_OF_FUNC
3292
3293 #####
3294 # subroutine: read_multipart
3295 #
3296 # Read multipart data and store it into our parameters.
3297 # An interesting feature is that if any of the parts is a file, we
3298 # create a temporary file and open up a filehandle on it so that the
3299 # caller can read from it if necessary.
3300 #####
3301 'read_multipart' => <<'END_OF_FUNC',
3302 sub read_multipart {
3303     my($self,$boundary,$length) = @_;
3304     my($buffer) = $self->new_MultipartBuffer($boundary,$length);
3305     return unless $buffer;
3306     my(%header,$body);
3307     my $filenumber = 0;
3308     while (!$buffer->eof) {
3309         %header = $buffer->readHeader;
3310
3311         unless (%header) {
3312             $self->cgi_error("400 Bad request (malformed multipart POST)");
3313             return;
3314         }
3315
3316         my($param)= $header{'Content-Disposition'}=~/ name="([^"]*)"/;
3317         $param .= $TAINTED;
3318
3319         # Bug:  Netscape doesn't escape quotation marks in file names!!!
3320         my($filename) = $header{'Content-Disposition'}=~/ filename="([^"]*)"/;
3321         # Test for Opera's multiple upload feature
3322         my($multipart) = ( defined( $header{'Content-Type'} ) &&
3323                 $header{'Content-Type'} =~ /multipart\/mixed/ ) ?
3324                 1 : 0;
3325
3326         # add this parameter to our list
3327         $self->add_parameter($param);
3328
3329         # If no filename specified, then just read the data and assign it
3330         # to our parameter list.
3331         if ( ( !defined($filename) || $filename eq '' ) && !$multipart ) {
3332             my($value) = $buffer->readBody;
3333             $value .= $TAINTED;
3334             push(@{$self->{$param}},$value);
3335             next;
3336         }
3337
3338         my ($tmpfile,$tmp,$filehandle);
3339       UPLOADS: {
3340           # If we get here, then we are dealing with a potentially large
3341           # uploaded form.  Save the data to a temporary file, then open
3342           # the file for reading.
3343
3344           # skip the file if uploads disabled
3345           if ($DISABLE_UPLOADS) {
3346               while (defined($data = $buffer->read)) { }
3347               last UPLOADS;
3348           }
3349
3350           # set the filename to some recognizable value
3351           if ( ( !defined($filename) || $filename eq '' ) && $multipart ) {
3352               $filename = "multipart/mixed";
3353           }
3354
3355           # choose a relatively unpredictable tmpfile sequence number
3356           my $seqno = unpack("%16C*",join('',localtime,grep {defined $_} values %ENV));
3357           for (my $cnt=10;$cnt>0;$cnt--) {
3358             next unless $tmpfile = new CGITempFile($seqno);
3359             $tmp = $tmpfile->as_string;
3360             last if defined($filehandle = Fh->new($filename,$tmp,$PRIVATE_TEMPFILES));
3361             $seqno += int rand(100);
3362           }
3363           die "CGI open of tmpfile: $!\n" unless defined $filehandle;
3364           $CGI::DefaultClass->binmode($filehandle) if $CGI::needs_binmode 
3365                      && defined fileno($filehandle);
3366
3367           # if this is an multipart/mixed attachment, save the header
3368           # together with the body for later parsing with an external
3369           # MIME parser module
3370           if ( $multipart ) {
3371               foreach ( keys %header ) {
3372                   print $filehandle "$_: $header{$_}${CRLF}";
3373               }
3374               print $filehandle "${CRLF}";
3375           }
3376
3377           my ($data);
3378           local($\) = '';
3379           my $totalbytes;
3380           while (defined($data = $buffer->read)) {
3381               if (defined $self->{'.upload_hook'})
3382                {
3383                   $totalbytes += length($data);
3384                    &{$self->{'.upload_hook'}}($filename ,$data, $totalbytes, $self->{'.upload_data'});
3385               }
3386               print $filehandle $data if ($self->{'use_tempfile'});
3387           }
3388
3389           # back up to beginning of file
3390           seek($filehandle,0,0);
3391
3392       ## Close the filehandle if requested this allows a multipart MIME
3393       ## upload to contain many files, and we won't die due to too many
3394       ## open file handles. The user can access the files using the hash
3395       ## below.
3396       close $filehandle if $CLOSE_UPLOAD_FILES;
3397           $CGI::DefaultClass->binmode($filehandle) if $CGI::needs_binmode;
3398
3399           # Save some information about the uploaded file where we can get
3400           # at it later.
3401           # Use the typeglob as the key, as this is guaranteed to be
3402           # unique for each filehandle.  Don't use the file descriptor as
3403           # this will be re-used for each filehandle if the
3404           # close_upload_files feature is used.
3405           $self->{'.tmpfiles'}->{$$filehandle}= {
3406               hndl => $filehandle,
3407               name => $tmpfile,
3408               info => {%header},
3409           };
3410           push(@{$self->{$param}},$filehandle);
3411       }
3412     }
3413 }
3414 END_OF_FUNC
3415
3416 'upload' =><<'END_OF_FUNC',
3417 sub upload {
3418     my($self,$param_name) = self_or_default(@_);
3419     my @param = grep(ref && fileno($_), $self->param($param_name));
3420     return unless @param;
3421     return wantarray ? @param : $param[0];
3422 }
3423 END_OF_FUNC
3424
3425 'tmpFileName' => <<'END_OF_FUNC',
3426 sub tmpFileName {
3427     my($self,$filename) = self_or_default(@_);
3428     return $self->{'.tmpfiles'}->{$$filename}->{name} ?
3429         $self->{'.tmpfiles'}->{$$filename}->{name}->as_string
3430             : '';
3431 }
3432 END_OF_FUNC
3433
3434 'uploadInfo' => <<'END_OF_FUNC',
3435 sub uploadInfo {
3436     my($self,$filename) = self_or_default(@_);
3437     return $self->{'.tmpfiles'}->{$$filename}->{info};
3438 }
3439 END_OF_FUNC
3440
3441 # internal routine, don't use
3442 '_set_values_and_labels' => <<'END_OF_FUNC',
3443 sub _set_values_and_labels {
3444     my $self = shift;
3445     my ($v,$l,$n) = @_;
3446     $$l = $v if ref($v) eq 'HASH' && !ref($$l);
3447     return $self->param($n) if !defined($v);
3448     return $v if !ref($v);
3449     return ref($v) eq 'HASH' ? keys %$v : @$v;
3450 }
3451 END_OF_FUNC
3452
3453 # internal routine, don't use
3454 '_set_attributes' => <<'END_OF_FUNC',
3455 sub _set_attributes {
3456     my $self = shift;
3457     my($element, $attributes) = @_;
3458     return '' unless defined($attributes->{$element});
3459     $attribs = ' ';
3460     foreach my $attrib (keys %{$attributes->{$element}}) {
3461         (my $clean_attrib = $attrib) =~ s/^-//;
3462         $attribs .= "@{[lc($clean_attrib)]}=\"$attributes->{$element}{$attrib}\" ";
3463     }
3464     $attribs =~ s/ $//;
3465     return $attribs;
3466 }
3467 END_OF_FUNC
3468
3469 '_compile_all' => <<'END_OF_FUNC',
3470 sub _compile_all {
3471     foreach (@_) {
3472         next if defined(&$_);
3473         $AUTOLOAD = "CGI::$_";
3474         _compile();
3475     }
3476 }
3477 END_OF_FUNC
3478
3479 );
3480 END_OF_AUTOLOAD
3481 ;
3482
3483 #########################################################
3484 # Globals and stubs for other packages that we use.
3485 #########################################################
3486
3487 ################### Fh -- lightweight filehandle ###############
3488 package Fh;
3489 use overload 
3490     '""'  => \&asString,
3491     'cmp' => \&compare,
3492     'fallback'=>1;
3493
3494 $FH='fh00000';
3495
3496 *Fh::AUTOLOAD = \&CGI::AUTOLOAD;
3497
3498 sub DESTROY {
3499     my $self = shift;
3500     close $self;
3501 }
3502
3503 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3504 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3505 %SUBS =  (
3506 'asString' => <<'END_OF_FUNC',
3507 sub asString {
3508     my $self = shift;
3509     # get rid of package name
3510     (my $i = $$self) =~ s/^\*(\w+::fh\d{5})+//; 
3511     $i =~ s/%(..)/ chr(hex($1)) /eg;
3512     return $i.$CGI::TAINTED;
3513 # BEGIN DEAD CODE
3514 # This was an extremely clever patch that allowed "use strict refs".
3515 # Unfortunately it relied on another bug that caused leaky file descriptors.
3516 # The underlying bug has been fixed, so this no longer works.  However
3517 # "strict refs" still works for some reason.
3518 #    my $self = shift;
3519 #    return ${*{$self}{SCALAR}};
3520 # END DEAD CODE
3521 }
3522 END_OF_FUNC
3523
3524 'compare' => <<'END_OF_FUNC',
3525 sub compare {
3526     my $self = shift;
3527     my $value = shift;
3528     return "$self" cmp $value;
3529 }
3530 END_OF_FUNC
3531
3532 'new'  => <<'END_OF_FUNC',
3533 sub new {
3534     my($pack,$name,$file,$delete) = @_;
3535     _setup_symbols(@SAVED_SYMBOLS) if @SAVED_SYMBOLS;
3536     require Fcntl unless defined &Fcntl::O_RDWR;
3537     (my $safename = $name) =~ s/([':%])/ sprintf '%%%02X', ord $1 /eg;
3538     my $fv = ++$FH . $safename;
3539     my $ref = \*{"Fh::$fv"};
3540     $file =~ m!^([a-zA-Z0-9_ \'\":/.\$\\-]+)$! || return;
3541     my $safe = $1;
3542     sysopen($ref,$safe,Fcntl::O_RDWR()|Fcntl::O_CREAT()|Fcntl::O_EXCL(),0600) || return;
3543     unlink($safe) if $delete;
3544     CORE::delete $Fh::{$fv};
3545     return bless $ref,$pack;
3546 }
3547 END_OF_FUNC
3548
3549 );
3550 END_OF_AUTOLOAD
3551
3552 ######################## MultipartBuffer ####################
3553 package MultipartBuffer;
3554
3555 use constant DEBUG => 0;
3556
3557 # how many bytes to read at a time.  We use
3558 # a 4K buffer by default.
3559 $INITIAL_FILLUNIT = 1024 * 4;
3560 $TIMEOUT = 240*60;       # 4 hour timeout for big files
3561 $SPIN_LOOP_MAX = 2000;  # bug fix for some Netscape servers
3562 $CRLF=$CGI::CRLF;
3563
3564 #reuse the autoload function
3565 *MultipartBuffer::AUTOLOAD = \&CGI::AUTOLOAD;
3566
3567 # avoid autoloader warnings
3568 sub DESTROY {}
3569
3570 ###############################################################################
3571 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
3572 ###############################################################################
3573 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3574 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3575 %SUBS =  (
3576
3577 'new' => <<'END_OF_FUNC',
3578 sub new {
3579     my($package,$interface,$boundary,$length) = @_;
3580     $FILLUNIT = $INITIAL_FILLUNIT;
3581     $CGI::DefaultClass->binmode($IN); # if $CGI::needs_binmode;  # just do it always
3582
3583     # If the user types garbage into the file upload field,
3584     # then Netscape passes NOTHING to the server (not good).
3585     # We may hang on this read in that case. So we implement
3586     # a read timeout.  If nothing is ready to read
3587     # by then, we return.
3588
3589     # Netscape seems to be a little bit unreliable
3590     # about providing boundary strings.
3591     my $boundary_read = 0;
3592     if ($boundary) {
3593
3594         # Under the MIME spec, the boundary consists of the 
3595         # characters "--" PLUS the Boundary string
3596
3597         # BUG: IE 3.01 on the Macintosh uses just the boundary -- not
3598         # the two extra hyphens.  We do a special case here on the user-agent!!!!
3599         $boundary = "--$boundary" unless CGI::user_agent('MSIE\s+3\.0[12];\s*Mac|DreamPassport');
3600
3601     } else { # otherwise we find it ourselves
3602         my($old);
3603         ($old,$/) = ($/,$CRLF); # read a CRLF-delimited line
3604         $boundary = <STDIN>;      # BUG: This won't work correctly under mod_perl
3605         $length -= length($boundary);
3606         chomp($boundary);               # remove the CRLF
3607         $/ = $old;                      # restore old line separator
3608         $boundary_read++;
3609     }
3610
3611     my $self = {LENGTH=>$length,
3612                 CHUNKED=>!defined $length,
3613                 BOUNDARY=>$boundary,
3614                 INTERFACE=>$interface,
3615                 BUFFER=>'',
3616             };
3617
3618     $FILLUNIT = length($boundary)
3619         if length($boundary) > $FILLUNIT;
3620
3621     my $retval = bless $self,ref $package || $package;
3622
3623     # Read the preamble and the topmost (boundary) line plus the CRLF.
3624     unless ($boundary_read) {
3625       while ($self->read(0)) { }
3626     }
3627     die "Malformed multipart POST: data truncated\n" if $self->eof;
3628
3629     return $retval;
3630 }
3631 END_OF_FUNC
3632
3633 'readHeader' => <<'END_OF_FUNC',
3634 sub readHeader {
3635     my($self) = @_;
3636     my($end);
3637     my($ok) = 0;
3638     my($bad) = 0;
3639
3640     local($CRLF) = "\015\012" if $CGI::OS eq 'VMS' || $CGI::EBCDIC;
3641
3642     do {
3643         $self->fillBuffer($FILLUNIT);
3644         $ok++ if ($end = index($self->{BUFFER},"${CRLF}${CRLF}")) >= 0;
3645         $ok++ if $self->{BUFFER} eq '';
3646         $bad++ if !$ok && $self->{LENGTH} <= 0;
3647         # this was a bad idea
3648         # $FILLUNIT *= 2 if length($self->{BUFFER}) >= $FILLUNIT; 
3649     } until $ok || $bad;
3650     return () if $bad;
3651
3652     #EBCDIC NOTE: translate header into EBCDIC, but watch out for continuation lines!
3653
3654     my($header) = substr($self->{BUFFER},0,$end+2);
3655     substr($self->{BUFFER},0,$end+4) = '';
3656     my %return;
3657
3658     if ($CGI::EBCDIC) {
3659       warn "untranslated header=$header\n" if DEBUG;
3660       $header = CGI::Util::ascii2ebcdic($header);
3661       warn "translated header=$header\n" if DEBUG;
3662     }
3663
3664     # See RFC 2045 Appendix A and RFC 822 sections 3.4.8
3665     #   (Folding Long Header Fields), 3.4.3 (Comments)
3666     #   and 3.4.5 (Quoted-Strings).
3667
3668     my $token = '[-\w!\#$%&\'*+.^_\`|{}~]';
3669     $header=~s/$CRLF\s+/ /og;           # merge continuation lines
3670
3671     while ($header=~/($token+):\s+([^$CRLF]*)/mgox) {
3672         my ($field_name,$field_value) = ($1,$2);
3673         $field_name =~ s/\b(\w)/uc($1)/eg; #canonicalize
3674         $return{$field_name}=$field_value;
3675     }
3676     return %return;
3677 }
3678 END_OF_FUNC
3679
3680 # This reads and returns the body as a single scalar value.
3681 'readBody' => <<'END_OF_FUNC',
3682 sub readBody {
3683     my($self) = @_;
3684     my($data);
3685     my($returnval)='';
3686
3687     #EBCDIC NOTE: want to translate returnval into EBCDIC HERE
3688
3689     while (defined($data = $self->read)) {
3690         $returnval .= $data;
3691     }
3692
3693     if ($CGI::EBCDIC) {
3694       warn "untranslated body=$returnval\n" if DEBUG;
3695       $returnval = CGI::Util::ascii2ebcdic($returnval);
3696       warn "translated body=$returnval\n"   if DEBUG;
3697     }
3698     return $returnval;
3699 }
3700 END_OF_FUNC
3701
3702 # This will read $bytes or until the boundary is hit, whichever happens
3703 # first.  After the boundary is hit, we return undef.  The next read will
3704 # skip over the boundary and begin reading again;
3705 'read' => <<'END_OF_FUNC',
3706 sub read {
3707     my($self,$bytes) = @_;
3708
3709     # default number of bytes to read
3710     $bytes = $bytes || $FILLUNIT;
3711
3712     # Fill up our internal buffer in such a way that the boundary
3713     # is never split between reads.
3714     $self->fillBuffer($bytes);
3715
3716     my $boundary_start = $CGI::EBCDIC ? CGI::Util::ebcdic2ascii($self->{BOUNDARY})      : $self->{BOUNDARY};
3717     my $boundary_end   = $CGI::EBCDIC ? CGI::Util::ebcdic2ascii($self->{BOUNDARY}.'--') : $self->{BOUNDARY}.'--';
3718
3719     # Find the boundary in the buffer (it may not be there).
3720     my $start = index($self->{BUFFER},$boundary_start);
3721
3722     warn "boundary=$self->{BOUNDARY} length=$self->{LENGTH} start=$start\n" if DEBUG;
3723
3724     # protect against malformed multipart POST operations
3725     die "Malformed multipart POST\n" unless $self->{CHUNKED} || ($start >= 0 || $self->{LENGTH} > 0);
3726
3727     #EBCDIC NOTE: want to translate boundary search into ASCII here.
3728
3729     # If the boundary begins the data, then skip past it
3730     # and return undef.
3731     if ($start == 0) {
3732
3733         # clear us out completely if we've hit the last boundary.
3734         if (index($self->{BUFFER},$boundary_end)==0) {
3735             $self->{BUFFER}='';
3736             $self->{LENGTH}=0;
3737             return undef;
3738         }
3739
3740         # just remove the boundary.
3741         substr($self->{BUFFER},0,length($boundary_start))='';
3742         $self->{BUFFER} =~ s/^\012\015?//;
3743         return undef;
3744     }
3745
3746     my $bytesToReturn;
3747     if ($start > 0) {           # read up to the boundary
3748         $bytesToReturn = $start-2 > $bytes ? $bytes : $start;
3749     } else {    # read the requested number of bytes
3750         # leave enough bytes in the buffer to allow us to read
3751         # the boundary.  Thanks to Kevin Hendrick for finding
3752         # this one.
3753         $bytesToReturn = $bytes - (length($boundary_start)+1);
3754     }
3755
3756     my $returnval=substr($self->{BUFFER},0,$bytesToReturn);
3757     substr($self->{BUFFER},0,$bytesToReturn)='';
3758     
3759     # If we hit the boundary, remove the CRLF from the end.
3760     return ($bytesToReturn==$start)
3761            ? substr($returnval,0,-2) : $returnval;
3762 }
3763 END_OF_FUNC
3764
3765
3766 # This fills up our internal buffer in such a way that the
3767 # boundary is never split between reads
3768 'fillBuffer' => <<'END_OF_FUNC',
3769 sub fillBuffer {
3770     my($self,$bytes) = @_;
3771     return unless $self->{CHUNKED} || $self->{LENGTH};
3772
3773     my($boundaryLength) = length($self->{BOUNDARY});
3774     my($bufferLength) = length($self->{BUFFER});
3775     my($bytesToRead) = $bytes - $bufferLength + $boundaryLength + 2;
3776     $bytesToRead = $self->{LENGTH} if !$self->{CHUNKED} && $self->{LENGTH} < $bytesToRead;
3777
3778     # Try to read some data.  We may hang here if the browser is screwed up.
3779     my $bytesRead = $self->{INTERFACE}->read_from_client(\$self->{BUFFER},
3780                                                          $bytesToRead,
3781                                                          $bufferLength);
3782     warn "bytesToRead=$bytesToRead, bufferLength=$bufferLength, buffer=$self->{BUFFER}\n" if DEBUG;
3783     $self->{BUFFER} = '' unless defined $self->{BUFFER};
3784
3785     # An apparent bug in the Apache server causes the read()
3786     # to return zero bytes repeatedly without blocking if the
3787     # remote user aborts during a file transfer.  I don't know how
3788     # they manage this, but the workaround is to abort if we get
3789     # more than SPIN_LOOP_MAX consecutive zero reads.
3790     if ($bytesRead <= 0) {
3791         die  "CGI.pm: Server closed socket during multipart read (client aborted?).\n"
3792             if ($self->{ZERO_LOOP_COUNTER}++ >= $SPIN_LOOP_MAX);
3793     } else {
3794         $self->{ZERO_LOOP_COUNTER}=0;
3795     }
3796
3797     $self->{LENGTH} -= $bytesRead if !$self->{CHUNKED} && $bytesRead;
3798 }
3799 END_OF_FUNC
3800
3801
3802 # Return true when we've finished reading
3803 'eof' => <<'END_OF_FUNC'
3804 sub eof {
3805     my($self) = @_;
3806     return 1 if (length($self->{BUFFER}) == 0)
3807                  && ($self->{LENGTH} <= 0);
3808     undef;
3809 }
3810 END_OF_FUNC
3811
3812 );
3813 END_OF_AUTOLOAD
3814
3815 ####################################################################################
3816 ################################## TEMPORARY FILES #################################
3817 ####################################################################################
3818 package CGITempFile;
3819
3820 sub find_tempdir {
3821   $SL = $CGI::SL;
3822   $MAC = $CGI::OS eq 'MACINTOSH';
3823   my ($vol) = $MAC ? MacPerl::Volumes() =~ /:(.*)/ : "";
3824   unless (defined $TMPDIRECTORY) {
3825     @TEMP=("${SL}usr${SL}tmp","${SL}var${SL}tmp",
3826            "C:${SL}temp","${SL}tmp","${SL}temp",
3827            "${vol}${SL}Temporary Items",
3828            "${SL}WWW_ROOT", "${SL}SYS\$SCRATCH",
3829            "C:${SL}system${SL}temp");
3830     unshift(@TEMP,$ENV{'TMPDIR'}) if defined $ENV{'TMPDIR'};
3831
3832     # this feature was supposed to provide per-user tmpfiles, but
3833     # it is problematic.
3834     #    unshift(@TEMP,(getpwuid($<))[7].'/tmp') if $CGI::OS eq 'UNIX';
3835     # Rob: getpwuid() is unfortunately UNIX specific. On brain dead OS'es this
3836     #    : can generate a 'getpwuid() not implemented' exception, even though
3837     #    : it's never called.  Found under DOS/Win with the DJGPP perl port.
3838     #    : Refer to getpwuid() only at run-time if we're fortunate and have  UNIX.
3839     # unshift(@TEMP,(eval {(getpwuid($>))[7]}).'/tmp') if $CGI::OS eq 'UNIX' and $> != 0;
3840
3841     foreach (@TEMP) {
3842       do {$TMPDIRECTORY = $_; last} if -d $_ && -w _;
3843     }
3844   }
3845   $TMPDIRECTORY  = $MAC ? "" : "." unless $TMPDIRECTORY;
3846 }
3847
3848 find_tempdir();
3849
3850 $MAXTRIES = 5000;
3851
3852 # cute feature, but overload implementation broke it
3853 # %OVERLOAD = ('""'=>'as_string');
3854 *CGITempFile::AUTOLOAD = \&CGI::AUTOLOAD;
3855
3856 sub DESTROY {
3857     my($self) = @_;
3858     $$self =~ m!^([a-zA-Z0-9_ \'\":/.\$\\-]+)$! || return;
3859     my $safe = $1;             # untaint operation
3860     unlink $safe;              # get rid of the file
3861 }
3862
3863 ###############################################################################
3864 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
3865 ###############################################################################
3866 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3867 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3868 %SUBS = (
3869
3870 'new' => <<'END_OF_FUNC',
3871 sub new {
3872     my($package,$sequence) = @_;
3873     my $filename;
3874     find_tempdir() unless -w $TMPDIRECTORY;
3875     for (my $i = 0; $i < $MAXTRIES; $i++) {
3876         last if ! -f ($filename = sprintf("${TMPDIRECTORY}${SL}CGItemp%d",$sequence++));
3877     }
3878     # check that it is a more-or-less valid filename
3879     return unless $filename =~ m!^([a-zA-Z0-9_ \'\":/.\$\\-]+)$!;
3880     # this used to untaint, now it doesn't
3881     # $filename = $1;
3882     return bless \$filename;
3883 }
3884 END_OF_FUNC
3885
3886 'as_string' => <<'END_OF_FUNC'
3887 sub as_string {
3888     my($self) = @_;
3889     return $$self;
3890 }
3891 END_OF_FUNC
3892
3893 );
3894 END_OF_AUTOLOAD
3895
3896 package CGI;
3897
3898 # We get a whole bunch of warnings about "possibly uninitialized variables"
3899 # when running with the -w switch.  Touch them all once to get rid of the
3900 # warnings.  This is ugly and I hate it.
3901 if ($^W) {
3902     $CGI::CGI = '';
3903     $CGI::CGI=<<EOF;
3904     $CGI::VERSION;
3905     $MultipartBuffer::SPIN_LOOP_MAX;
3906     $MultipartBuffer::CRLF;
3907     $MultipartBuffer::TIMEOUT;
3908     $MultipartBuffer::INITIAL_FILLUNIT;
3909 EOF
3910     ;
3911 }
3912
3913 1;
3914
3915 __END__
3916
3917 =head1 NAME
3918
3919 CGI - Simple Common Gateway Interface Class
3920
3921 =head1 SYNOPSIS
3922
3923   # CGI script that creates a fill-out form
3924   # and echoes back its values.
3925
3926   use CGI qw/:standard/;
3927   print header,
3928         start_html('A Simple Example'),
3929         h1('A Simple Example'),
3930         start_form,
3931         "What's your name? ",textfield('name'),p,
3932         "What's the combination?", p,
3933         checkbox_group(-name=>'words',
3934                        -values=>['eenie','meenie','minie','moe'],
3935                        -defaults=>['eenie','minie']), p,
3936         "What's your favorite color? ",
3937         popup_menu(-name=>'color',
3938                    -values=>['red','green','blue','chartreuse']),p,
3939         submit,
3940         end_form,
3941         hr;
3942
3943    if (param()) {
3944        my $name      = param('name');
3945        my $keywords  = join ', ',param('words');
3946        my $color     = param('color');
3947        print "Your name is",em(escapeHTML($name)),p,
3948              "The keywords are: ",em(escapeHTML($keywords)),p,
3949              "Your favorite color is ",em(escapeHTML($color)),
3950              hr;
3951    }
3952
3953 =head1 ABSTRACT
3954
3955 This perl library uses perl5 objects to make it easy to create Web
3956 fill-out forms and parse their contents.  This package defines CGI
3957 objects, entities that contain the values of the current query string
3958 and other state variables.  Using a CGI object's methods, you can
3959 examine keywords and parameters passed to your script, and create
3960 forms whose initial values are taken from the current query (thereby
3961 preserving state information).  The module provides shortcut functions
3962 that produce boilerplate HTML, reducing typing and coding errors. It
3963 also provides functionality for some of the more advanced features of
3964 CGI scripting, including support for file uploads, cookies, cascading
3965 style sheets, server push, and frames.
3966
3967 CGI.pm also provides a simple function-oriented programming style for
3968 those who don't need its object-oriented features.
3969
3970 The current version of CGI.pm is available at
3971
3972   http://www.genome.wi.mit.edu/ftp/pub/software/WWW/cgi_docs.html
3973   ftp://ftp-genome.wi.mit.edu/pub/software/WWW/
3974
3975 =head1 DESCRIPTION
3976
3977 =head2 PROGRAMMING STYLE
3978
3979 There are two styles of programming with CGI.pm, an object-oriented
3980 style and a function-oriented style.  In the object-oriented style you
3981 create one or more CGI objects and then use object methods to create
3982 the various elements of the page.  Each CGI object starts out with the
3983 list of named parameters that were passed to your CGI script by the
3984 server.  You can modify the objects, save them to a file or database
3985 and recreate them.  Because each object corresponds to the "state" of
3986 the CGI script, and because each object's parameter list is
3987 independent of the others, this allows you to save the state of the
3988 script and restore it later.
3989
3990 For example, using the object oriented style, here is how you create
3991 a simple "Hello World" HTML page:
3992
3993    #!/usr/local/bin/perl -w
3994    use CGI;                             # load CGI routines
3995    $q = new CGI;                        # create new CGI object
3996    print $q->header,                    # create the HTTP header
3997          $q->start_html('hello world'), # start the HTML
3998          $q->h1('hello world'),         # level 1 header
3999          $q->end_html;                  # end the HTML
4000
4001 In the function-oriented style, there is one default CGI object that
4002 you rarely deal with directly.  Instead you just call functions to
4003 retrieve CGI parameters, create HTML tags, manage cookies, and so
4004 on.  This provides you with a cleaner programming interface, but
4005 limits you to using one CGI object at a time.  The following example
4006 prints the same page, but uses the function-oriented interface.
4007 The main differences are that we now need to import a set of functions
4008 into our name space (usually the "standard" functions), and we don't
4009 need to create the CGI object.
4010
4011    #!/usr/local/bin/perl
4012    use CGI qw/:standard/;           # load standard CGI routines
4013    print header,                    # create the HTTP header
4014          start_html('hello world'), # start the HTML
4015          h1('hello world'),         # level 1 header
4016          end_html;                  # end the HTML
4017
4018 The examples in this document mainly use the object-oriented style.
4019 See HOW TO IMPORT FUNCTIONS for important information on
4020 function-oriented programming in CGI.pm
4021
4022 =head2 CALLING CGI.PM ROUTINES
4023
4024 Most CGI.pm routines accept several arguments, sometimes as many as 20
4025 optional ones!  To simplify this interface, all routines use a named
4026 argument calling style that looks like this:
4027
4028    print $q->header(-type=>'image/gif',-expires=>'+3d');
4029
4030 Each argument name is preceded by a dash.  Neither case nor order
4031 matters in the argument list.  -type, -Type, and -TYPE are all
4032 acceptable.  In fact, only the first argument needs to begin with a
4033 dash.  If a dash is present in the first argument, CGI.pm assumes
4034 dashes for the subsequent ones.
4035
4036 Several routines are commonly called with just one argument.  In the
4037 case of these routines you can provide the single argument without an
4038 argument name.  header() happens to be one of these routines.  In this
4039 case, the single argument is the document type.
4040
4041    print $q->header('text/html');
4042
4043 Other such routines are documented below.
4044
4045 Sometimes named arguments expect a scalar, sometimes a reference to an
4046 array, and sometimes a reference to a hash.  Often, you can pass any
4047 type of argument and the routine will do whatever is most appropriate.
4048 For example, the param() routine is used to set a CGI parameter to a
4049 single or a multi-valued value.  The two cases are shown below:
4050
4051    $q->param(-name=>'veggie',-value=>'tomato');
4052    $q->param(-name=>'veggie',-value=>['tomato','tomahto','potato','potahto']);
4053
4054 A large number of routines in CGI.pm actually aren't specifically
4055 defined in the module, but are generated automatically as needed.
4056 These are the "HTML shortcuts," routines that generate HTML tags for
4057 use in dynamically-generated pages.  HTML tags have both attributes
4058 (the attribute="value" pairs within the tag itself) and contents (the
4059 part between the opening and closing pairs.)  To distinguish between
4060 attributes and contents, CGI.pm uses the convention of passing HTML
4061 attributes as a hash reference as the first argument, and the
4062 contents, if any, as any subsequent arguments.  It works out like
4063 this:
4064
4065    Code                           Generated HTML
4066    ----                           --------------
4067    h1()                           <h1>
4068    h1('some','contents');         <h1>some contents</h1>
4069    h1({-align=>left});            <h1 align="LEFT">
4070    h1({-align=>left},'contents'); <h1 align="LEFT">contents</h1>
4071
4072 HTML tags are described in more detail later.
4073
4074 Many newcomers to CGI.pm are puzzled by the difference between the
4075 calling conventions for the HTML shortcuts, which require curly braces
4076 around the HTML tag attributes, and the calling conventions for other
4077 routines, which manage to generate attributes without the curly
4078 brackets.  Don't be confused.  As a convenience the curly braces are
4079 optional in all but the HTML shortcuts.  If you like, you can use
4080 curly braces when calling any routine that takes named arguments.  For
4081 example:
4082
4083    print $q->header( {-type=>'image/gif',-expires=>'+3d'} );
4084
4085 If you use the B<-w> switch, you will be warned that some CGI.pm argument
4086 names conflict with built-in Perl functions.  The most frequent of
4087 these is the -values argument, used to create multi-valued menus,
4088 radio button clusters and the like.  To get around this warning, you
4089 have several choices:
4090
4091 =over 4
4092
4093 =item 1.
4094
4095 Use another name for the argument, if one is available. 
4096 For example, -value is an alias for -values.
4097
4098 =item 2.
4099
4100 Change the capitalization, e.g. -Values
4101
4102 =item 3.
4103
4104 Put quotes around the argument name, e.g. '-values'
4105
4106 =back
4107
4108 Many routines will do something useful with a named argument that it
4109 doesn't recognize.  For example, you can produce non-standard HTTP
4110 header fields by providing them as named arguments:
4111
4112   print $q->header(-type  =>  'text/html',
4113                    -cost  =>  'Three smackers',
4114                    -annoyance_level => 'high',
4115                    -complaints_to   => 'bit bucket');
4116
4117 This will produce the following nonstandard HTTP header:
4118
4119    HTTP/1.0 200 OK
4120    Cost: Three smackers
4121    Annoyance-level: high
4122    Complaints-to: bit bucket
4123    Content-type: text/html
4124
4125 Notice the way that underscores are translated automatically into
4126 hyphens.  HTML-generating routines perform a different type of
4127 translation. 
4128
4129 This feature allows you to keep up with the rapidly changing HTTP and
4130 HTML "standards".
4131
4132 =head2 CREATING A NEW QUERY OBJECT (OBJECT-ORIENTED STYLE):
4133
4134      $query = new CGI;
4135
4136 This will parse the input (from both POST and GET methods) and store
4137 it into a perl5 object called $query.  
4138
4139 =head2 CREATING A NEW QUERY OBJECT FROM AN INPUT FILE
4140
4141      $query = new CGI(INPUTFILE);
4142
4143 If you provide a file handle to the new() method, it will read
4144 parameters from the file (or STDIN, or whatever).  The file can be in
4145 any of the forms describing below under debugging (i.e. a series of
4146 newline delimited TAG=VALUE pairs will work).  Conveniently, this type
4147 of file is created by the save() method (see below).  Multiple records
4148 can be saved and restored.
4149
4150 Perl purists will be pleased to know that this syntax accepts
4151 references to file handles, or even references to filehandle globs,
4152 which is the "official" way to pass a filehandle:
4153
4154     $query = new CGI(\*STDIN);
4155
4156 You can also initialize the CGI object with a FileHandle or IO::File
4157 object.
4158
4159 If you are using the function-oriented interface and want to
4160 initialize CGI state from a file handle, the way to do this is with
4161 B<restore_parameters()>.  This will (re)initialize the
4162 default CGI object from the indicated file handle.
4163
4164     open (IN,"test.in") || die;
4165     restore_parameters(IN);
4166     close IN;
4167
4168 You can also initialize the query object from an associative array
4169 reference:
4170
4171     $query = new CGI( {'dinosaur'=>'barney',
4172                        'song'=>'I love you',
4173                        'friends'=>[qw/Jessica George Nancy/]}
4174                     );
4175
4176 or from a properly formatted, URL-escaped query string:
4177
4178     $query = new CGI('dinosaur=barney&color=purple');
4179
4180 or from a previously existing CGI object (currently this clones the
4181 parameter list, but none of the other object-specific fields, such as
4182 autoescaping):
4183
4184     $old_query = new CGI;
4185     $new_query = new CGI($old_query);
4186
4187 To create an empty query, initialize it from an empty string or hash:
4188
4189    $empty_query = new CGI("");
4190
4191        -or-
4192
4193    $empty_query = new CGI({});
4194
4195 =head2 FETCHING A LIST OF KEYWORDS FROM THE QUERY:
4196
4197      @keywords = $query->keywords
4198
4199 If the script was invoked as the result of an <ISINDEX> search, the
4200 parsed keywords can be obtained as an array using the keywords() method.
4201
4202 =head2 FETCHING THE NAMES OF ALL THE PARAMETERS PASSED TO YOUR SCRIPT:
4203
4204      @names = $query->param
4205
4206 If the script was invoked with a parameter list
4207 (e.g. "name1=value1&name2=value2&name3=value3"), the param() method
4208 will return the parameter names as a list.  If the script was invoked
4209 as an <ISINDEX> script and contains a string without ampersands
4210 (e.g. "value1+value2+value3") , there will be a single parameter named
4211 "keywords" containing the "+"-delimited keywords.
4212
4213 NOTE: As of version 1.5, the array of parameter names returned will
4214 be in the same order as they were submitted by the browser.
4215 Usually this order is the same as the order in which the 
4216 parameters are defined in the form (however, this isn't part
4217 of the spec, and so isn't guaranteed).
4218
4219 =head2 FETCHING THE VALUE OR VALUES OF A SINGLE NAMED PARAMETER:
4220
4221     @values = $query->param('foo');
4222
4223               -or-
4224
4225     $value = $query->param('foo');
4226
4227 Pass the param() method a single argument to fetch the value of the
4228 named parameter. If the parameter is multivalued (e.g. from multiple
4229 selections in a scrolling list), you can ask to receive an array.  Otherwise
4230 the method will return a single value.
4231
4232 If a value is not given in the query string, as in the queries
4233 "name1=&name2=" or "name1&name2", it will be returned as an empty
4234 string.  This feature is new in 2.63.
4235
4236
4237 If the parameter does not exist at all, then param() will return undef
4238 in a scalar context, and the empty list in a list context.
4239
4240
4241 =head2 SETTING THE VALUE(S) OF A NAMED PARAMETER:
4242
4243     $query->param('foo','an','array','of','values');
4244
4245 This sets the value for the named parameter 'foo' to an array of
4246 values.  This is one way to change the value of a field AFTER
4247 the script has been invoked once before.  (Another way is with
4248 the -override parameter accepted by all methods that generate
4249 form elements.)
4250
4251 param() also recognizes a named parameter style of calling described
4252 in more detail later:
4253
4254     $query->param(-name=>'foo',-values=>['an','array','of','values']);
4255
4256                               -or-
4257
4258     $query->param(-name=>'foo',-value=>'the value');
4259
4260 =head2 APPENDING ADDITIONAL VALUES TO A NAMED PARAMETER:
4261
4262    $query->append(-name=>'foo',-values=>['yet','more','values']);
4263
4264 This adds a value or list of values to the named parameter.  The
4265 values are appended to the end of the parameter if it already exists.
4266 Otherwise the parameter is created.  Note that this method only
4267 recognizes the named argument calling syntax.
4268
4269 =head2 IMPORTING ALL PARAMETERS INTO A NAMESPACE:
4270
4271    $query->import_names('R');
4272
4273 This creates a series of variables in the 'R' namespace.  For example,
4274 $R::foo, @R:foo.  For keyword lists, a variable @R::keywords will appear.
4275 If no namespace is given, this method will assume 'Q'.
4276 WARNING:  don't import anything into 'main'; this is a major security
4277 risk!!!!
4278
4279 NOTE 1: Variable names are transformed as necessary into legal Perl
4280 variable names.  All non-legal characters are transformed into
4281 underscores.  If you need to keep the original names, you should use
4282 the param() method instead to access CGI variables by name.
4283
4284 NOTE 2: In older versions, this method was called B<import()>.  As of version 2.20, 
4285 this name has been removed completely to avoid conflict with the built-in
4286 Perl module B<import> operator.
4287
4288 =head2 DELETING A PARAMETER COMPLETELY:
4289
4290     $query->delete('foo','bar','baz');
4291
4292 This completely clears a list of parameters.  It sometimes useful for
4293 resetting parameters that you don't want passed down between script
4294 invocations.
4295
4296 If you are using the function call interface, use "Delete()" instead
4297 to avoid conflicts with Perl's built-in delete operator.
4298
4299 =head2 DELETING ALL PARAMETERS:
4300
4301    $query->delete_all();
4302
4303 This clears the CGI object completely.  It might be useful to ensure
4304 that all the defaults are taken when you create a fill-out form.
4305
4306 Use Delete_all() instead if you are using the function call interface.
4307
4308 =head2 HANDLING NON-URLENCODED ARGUMENTS
4309
4310
4311 If POSTed data is not of type application/x-www-form-urlencoded or
4312 multipart/form-data, then the POSTed data will not be processed, but
4313 instead be returned as-is in a parameter named POSTDATA.  To retrieve
4314 it, use code like this:
4315
4316    my $data = $query->param('POSTDATA');
4317
4318 (If you don't know what the preceding means, don't worry about it.  It
4319 only affects people trying to use CGI for XML processing and other
4320 specialized tasks.)
4321
4322
4323 =head2 DIRECT ACCESS TO THE PARAMETER LIST:
4324
4325    $q->param_fetch('address')->[1] = '1313 Mockingbird Lane';
4326    unshift @{$q->param_fetch(-name=>'address')},'George Munster';
4327
4328 If you need access to the parameter list in a way that isn't covered
4329 by the methods above, you can obtain a direct reference to it by
4330 calling the B<param_fetch()> method with the name of the .  This
4331 will return an array reference to the named parameters, which you then
4332 can manipulate in any way you like.
4333
4334 You can also use a named argument style using the B<-name> argument.
4335
4336 =head2 FETCHING THE PARAMETER LIST AS A HASH:
4337
4338     $params = $q->Vars;
4339     print $params->{'address'};
4340     @foo = split("\0",$params->{'foo'});
4341     %params = $q->Vars;
4342
4343     use CGI ':cgi-lib';
4344     $params = Vars;
4345
4346 Many people want to fetch the entire parameter list as a hash in which
4347 the keys are the names of the CGI parameters, and the values are the
4348 parameters' values.  The Vars() method does this.  Called in a scalar
4349 context, it returns the parameter list as a tied hash reference.
4350 Changing a key changes the value of the parameter in the underlying
4351 CGI parameter list.  Called in a list context, it returns the
4352 parameter list as an ordinary hash.  This allows you to read the
4353 contents of the parameter list, but not to change it.
4354
4355 When using this, the thing you must watch out for are multivalued CGI
4356 parameters.  Because a hash cannot distinguish between scalar and
4357 list context, multivalued parameters will be returned as a packed
4358 string, separated by the "\0" (null) character.  You must split this
4359 packed string in order to get at the individual values.  This is the
4360 convention introduced long ago by Steve Brenner in his cgi-lib.pl
4361 module for Perl version 4.
4362
4363 If you wish to use Vars() as a function, import the I<:cgi-lib> set of
4364 function calls (also see the section on CGI-LIB compatibility).
4365
4366 =head2 SAVING THE STATE OF THE SCRIPT TO A FILE:
4367
4368     $query->save(\*FILEHANDLE)
4369
4370 This will write the current state of the form to the provided
4371 filehandle.  You can read it back in by providing a filehandle
4372 to the new() method.  Note that the filehandle can be a file, a pipe,
4373 or whatever!
4374
4375 The format of the saved file is:
4376
4377         NAME1=VALUE1
4378         NAME1=VALUE1'
4379         NAME2=VALUE2
4380         NAME3=VALUE3
4381         =
4382
4383 Both name and value are URL escaped.  Multi-valued CGI parameters are
4384 represented as repeated names.  A session record is delimited by a
4385 single = symbol.  You can write out multiple records and read them
4386 back in with several calls to B<new>.  You can do this across several
4387 sessions by opening the file in append mode, allowing you to create
4388 primitive guest books, or to keep a history of users' queries.  Here's
4389 a short example of creating multiple session records:
4390
4391    use CGI;
4392
4393    open (OUT,">>test.out") || die;
4394    $records = 5;
4395    foreach (0..$records) {
4396        my $q = new CGI;
4397        $q->param(-name=>'counter',-value=>$_);
4398        $q->save(\*OUT);
4399    }
4400    close OUT;
4401
4402    # reopen for reading
4403    open (IN,"test.out") || die;
4404    while (!eof(IN)) {
4405        my $q = new CGI(\*IN);
4406        print $q->param('counter'),"\n";
4407    }
4408
4409 The file format used for save/restore is identical to that used by the
4410 Whitehead Genome Center's data exchange format "Boulderio", and can be
4411 manipulated and even databased using Boulderio utilities.  See
4412
4413   http://stein.cshl.org/boulder/
4414
4415 for further details.
4416
4417 If you wish to use this method from the function-oriented (non-OO)
4418 interface, the exported name for this method is B<save_parameters()>.
4419
4420 =head2 RETRIEVING CGI ERRORS
4421
4422 Errors can occur while processing user input, particularly when
4423 processing uploaded files.  When these errors occur, CGI will stop
4424 processing and return an empty parameter list.  You can test for
4425 the existence and nature of errors using the I<cgi_error()> function.
4426 The error messages are formatted as HTTP status codes. You can either
4427 incorporate the error text into an HTML page, or use it as the value
4428 of the HTTP status:
4429
4430     my $error = $q->cgi_error;
4431     if ($error) {
4432         print $q->header(-status=>$error),
4433               $q->start_html('Problems'),
4434               $q->h2('Request not processed'),
4435               $q->strong($error);
4436         exit 0;
4437     }
4438
4439 When using the function-oriented interface (see the next section),
4440 errors may only occur the first time you call I<param()>. Be ready
4441 for this!
4442
4443 =head2 USING THE FUNCTION-ORIENTED INTERFACE
4444
4445 To use the function-oriented interface, you must specify which CGI.pm
4446 routines or sets of routines to import into your script's namespace.
4447 There is a small overhead associated with this importation, but it
4448 isn't much.
4449
4450    use CGI <list of methods>;
4451
4452 The listed methods will be imported into the current package; you can
4453 call them directly without creating a CGI object first.  This example
4454 shows how to import the B<param()> and B<header()>
4455 methods, and then use them directly:
4456
4457    use CGI 'param','header';
4458    print header('text/plain');
4459    $zipcode = param('zipcode');
4460
4461 More frequently, you'll import common sets of functions by referring
4462 to the groups by name.  All function sets are preceded with a ":"
4463 character as in ":html3" (for tags defined in the HTML 3 standard).
4464
4465 Here is a list of the function sets you can import:
4466
4467 =over 4
4468
4469 =item B<:cgi>
4470
4471 Import all CGI-handling methods, such as B<param()>, B<path_info()>
4472 and the like.
4473
4474 =item B<:form>
4475
4476 Import all fill-out form generating methods, such as B<textfield()>.
4477
4478 =item B<:html2>
4479
4480 Import all methods that generate HTML 2.0 standard elements.
4481
4482 =item B<:html3>
4483
4484 Import all methods that generate HTML 3.0 elements (such as
4485 <table>, <super> and <sub>).
4486
4487 =item B<:html4>
4488
4489 Import all methods that generate HTML 4 elements (such as
4490 <abbrev>, <acronym> and <thead>).
4491
4492 =item B<:netscape>
4493
4494 Import all methods that generate Netscape-specific HTML extensions.
4495
4496 =item B<:html>
4497
4498 Import all HTML-generating shortcuts (i.e. 'html2' + 'html3' +
4499 'netscape')...
4500
4501 =item B<:standard>
4502
4503 Import "standard" features, 'html2', 'html3', 'html4', 'form' and 'cgi'.
4504
4505 =item B<:all>
4506
4507 Import all the available methods.  For the full list, see the CGI.pm
4508 code, where the variable %EXPORT_TAGS is defined.
4509
4510 =back
4511
4512 If you import a function name that is not part of CGI.pm, the module
4513 will treat it as a new HTML tag and generate the appropriate
4514 subroutine.  You can then use it like any other HTML tag.  This is to
4515 provide for the rapidly-evolving HTML "standard."  For example, say
4516 Microsoft comes out with a new tag called <gradient> (which causes the
4517 user's desktop to be flooded with a rotating gradient fill until his
4518 machine reboots).  You don't need to wait for a new version of CGI.pm
4519 to start using it immediately:
4520
4521    use CGI qw/:standard :html3 gradient/;
4522    print gradient({-start=>'red',-end=>'blue'});
4523
4524 Note that in the interests of execution speed CGI.pm does B<not> use
4525 the standard L<Exporter> syntax for specifying load symbols.  This may
4526 change in the future.
4527
4528 If you import any of the state-maintaining CGI or form-generating
4529 methods, a default CGI object will be created and initialized
4530 automatically the first time you use any of the methods that require
4531 one to be present.  This includes B<param()>, B<textfield()>,
4532 B<submit()> and the like.  (If you need direct access to the CGI
4533 object, you can find it in the global variable B<$CGI::Q>).  By
4534 importing CGI.pm methods, you can create visually elegant scripts:
4535
4536    use CGI qw/:standard/;
4537    print 
4538        header,
4539        start_html('Simple Script'),
4540        h1('Simple Script'),
4541        start_form,
4542        "What's your name? ",textfield('name'),p,
4543        "What's the combination?",
4544        checkbox_group(-name=>'words',
4545                       -values=>['eenie','meenie','minie','moe'],
4546                       -defaults=>['eenie','moe']),p,
4547        "What's your favorite color?",
4548        popup_menu(-name=>'color',
4549                   -values=>['red','green','blue','chartreuse']),p,
4550        submit,
4551        end_form,
4552        hr,"\n";
4553
4554     if (param) {
4555        print 
4556            "Your name is ",em(param('name')),p,
4557            "The keywords are: ",em(join(", ",param('words'))),p,
4558            "Your favorite color is ",em(param('color')),".\n";
4559     }
4560     print end_html;
4561
4562 =head2 PRAGMAS
4563
4564 In addition to the function sets, there are a number of pragmas that
4565 you can import.  Pragmas, which are always preceded by a hyphen,
4566 change the way that CGI.pm functions in various ways.  Pragmas,
4567 function sets, and individual functions can all be imported in the
4568 same use() line.  For example, the following use statement imports the
4569 standard set of functions and enables debugging mode (pragma
4570 -debug):
4571
4572    use CGI qw/:standard -debug/;
4573
4574 The current list of pragmas is as follows:
4575
4576 =over 4
4577
4578 =item -any
4579
4580 When you I<use CGI -any>, then any method that the query object
4581 doesn't recognize will be interpreted as a new HTML tag.  This allows
4582 you to support the next I<ad hoc> Netscape or Microsoft HTML
4583 extension.  This lets you go wild with new and unsupported tags:
4584
4585    use CGI qw(-any);
4586    $q=new CGI;
4587    print $q->gradient({speed=>'fast',start=>'red',end=>'blue'});
4588
4589 Since using <cite>any</cite> causes any mistyped method name
4590 to be interpreted as an HTML tag, use it with care or not at
4591 all.
4592
4593 =item -compile
4594
4595 This causes the indicated autoloaded methods to be compiled up front,
4596 rather than deferred to later.  This is useful for scripts that run
4597 for an extended period of time under FastCGI or mod_perl, and for
4598 those destined to be crunched by Malcom Beattie's Perl compiler.  Use
4599 it in conjunction with the methods or method families you plan to use.
4600
4601    use CGI qw(-compile :standard :html3);
4602
4603 or even
4604
4605    use CGI qw(-compile :all);
4606
4607 Note that using the -compile pragma in this way will always have
4608 the effect of importing the compiled functions into the current
4609 namespace.  If you want to compile without importing use the
4610 compile() method instead:
4611
4612    use CGI();
4613    CGI->compile();
4614
4615 This is particularly useful in a mod_perl environment, in which you
4616 might want to precompile all CGI routines in a startup script, and
4617 then import the functions individually in each mod_perl script.
4618
4619 =item -nosticky
4620
4621 By default the CGI module implements a state-preserving behavior
4622 called "sticky" fields.  The way this works is that if you are
4623 regenerating a form, the methods that generate the form field values
4624 will interrogate param() to see if similarly-named parameters are
4625 present in the query string. If they find a like-named parameter, they
4626 will use it to set their default values.
4627
4628 Sometimes this isn't what you want.  The B<-nosticky> pragma prevents
4629 this behavior.  You can also selectively change the sticky behavior in
4630 each element that you generate.
4631
4632 =item -tabindex
4633
4634 Automatically add tab index attributes to each form field. With this
4635 option turned off, you can still add tab indexes manually by passing a
4636 -tabindex option to each field-generating method.
4637
4638 =item -no_undef_params
4639
4640 This keeps CGI.pm from including undef params in the parameter list.
4641
4642 =item -no_xhtml
4643
4644 By default, CGI.pm versions 2.69 and higher emit XHTML
4645 (http://www.w3.org/TR/xhtml1/).  The -no_xhtml pragma disables this
4646 feature.  Thanks to Michalis Kabrianis <kabrianis@hellug.gr> for this
4647 feature.
4648
4649 If start_html()'s -dtd parameter specifies an HTML 2.0 or 3.2 DTD, 
4650 XHTML will automatically be disabled without needing to use this 
4651 pragma.
4652
4653 =item -nph
4654
4655 This makes CGI.pm produce a header appropriate for an NPH (no
4656 parsed header) script.  You may need to do other things as well
4657 to tell the server that the script is NPH.  See the discussion
4658 of NPH scripts below.
4659
4660 =item -newstyle_urls
4661
4662 Separate the name=value pairs in CGI parameter query strings with
4663 semicolons rather than ampersands.  For example:
4664
4665    ?name=fred;age=24;favorite_color=3
4666
4667 Semicolon-delimited query strings are always accepted, but will not be
4668 emitted by self_url() and query_string() unless the -newstyle_urls
4669 pragma is specified.
4670
4671 This became the default in version 2.64.
4672
4673 =item -oldstyle_urls
4674
4675 Separate the name=value pairs in CGI parameter query strings with
4676 ampersands rather than semicolons.  This is no longer the default.
4677
4678 =item -autoload
4679
4680 This overrides the autoloader so that any function in your program
4681 that is not recognized is referred to CGI.pm for possible evaluation.
4682 This allows you to use all the CGI.pm functions without adding them to
4683 your symbol table, which is of concern for mod_perl users who are
4684 worried about memory consumption.  I<Warning:> when
4685 I<-autoload> is in effect, you cannot use "poetry mode"
4686 (functions without the parenthesis).  Use I<hr()> rather
4687 than I<hr>, or add something like I<use subs qw/hr p header/> 
4688 to the top of your script.
4689
4690 =item -no_debug
4691
4692 This turns off the command-line processing features.  If you want to
4693 run a CGI.pm script from the command line to produce HTML, and you
4694 don't want it to read CGI parameters from the command line or STDIN,
4695 then use this pragma:
4696
4697    use CGI qw(-no_debug :standard);
4698
4699 =item -debug
4700
4701 This turns on full debugging.  In addition to reading CGI arguments
4702 from the command-line processing, CGI.pm will pause and try to read
4703 arguments from STDIN, producing the message "(offline mode: enter
4704 name=value pairs on standard input)" features.
4705
4706 See the section on debugging for more details.
4707
4708 =item -private_tempfiles
4709
4710 CGI.pm can process uploaded file. Ordinarily it spools the uploaded
4711 file to a temporary directory, then deletes the file when done.
4712 However, this opens the risk of eavesdropping as described in the file
4713 upload section.  Another CGI script author could peek at this data
4714 during the upload, even if it is confidential information. On Unix
4715 systems, the -private_tempfiles pragma will cause the temporary file
4716 to be unlinked as soon as it is opened and before any data is written
4717 into it, reducing, but not eliminating the risk of eavesdropping
4718 (there is still a potential race condition).  To make life harder for
4719 the attacker, the program chooses tempfile names by calculating a 32
4720 bit checksum of the incoming HTTP headers.
4721
4722 To ensure that the temporary file cannot be read by other CGI scripts,
4723 use suEXEC or a CGI wrapper program to run your script.  The temporary
4724 file is created with mode 0600 (neither world nor group readable).
4725
4726 The temporary directory is selected using the following algorithm:
4727
4728     1. if the current user (e.g. "nobody") has a directory named
4729     "tmp" in its home directory, use that (Unix systems only).
4730
4731     2. if the environment variable TMPDIR exists, use the location
4732     indicated.
4733
4734     3. Otherwise try the locations /usr/tmp, /var/tmp, C:\temp,
4735     /tmp, /temp, ::Temporary Items, and \WWW_ROOT.
4736
4737 Each of these locations is checked that it is a directory and is
4738 writable.  If not, the algorithm tries the next choice.
4739
4740 =back
4741
4742 =head2 SPECIAL FORMS FOR IMPORTING HTML-TAG FUNCTIONS
4743
4744 Many of the methods generate HTML tags.  As described below, tag
4745 functions automatically generate both the opening and closing tags.
4746 For example:
4747
4748   print h1('Level 1 Header');
4749
4750 produces
4751
4752   <h1>Level 1 Header</h1>
4753
4754 There will be some times when you want to produce the start and end
4755 tags yourself.  In this case, you can use the form start_I<tag_name>
4756 and end_I<tag_name>, as in:
4757
4758   print start_h1,'Level 1 Header',end_h1;
4759
4760 With a few exceptions (described below), start_I<tag_name> and
4761 end_I<tag_name> functions are not generated automatically when you
4762 I<use CGI>.  However, you can specify the tags you want to generate
4763 I<start/end> functions for by putting an asterisk in front of their
4764 name, or, alternatively, requesting either "start_I<tag_name>" or
4765 "end_I<tag_name>" in the import list.
4766
4767 Example:
4768
4769   use CGI qw/:standard *table start_ul/;
4770
4771 In this example, the following functions are generated in addition to
4772 the standard ones:
4773
4774 =over 4
4775
4776 =item 1. start_table() (generates a <table> tag)
4777
4778 =item 2. end_table() (generates a </table> tag)
4779
4780 =item 3. start_ul() (generates a <ul> tag)
4781
4782 =item 4. end_ul() (generates a </ul> tag)
4783
4784 =back
4785
4786 =head1 GENERATING DYNAMIC DOCUMENTS
4787
4788 Most of CGI.pm's functions deal with creating documents on the fly.
4789 Generally you will produce the HTTP header first, followed by the
4790 document itself.  CGI.pm provides functions for generating HTTP
4791 headers of various types as well as for generating HTML.  For creating
4792 GIF images, see the GD.pm module.
4793
4794 Each of these functions produces a fragment of HTML or HTTP which you
4795 can print out directly so that it displays in the browser window,
4796 append to a string, or save to a file for later use.
4797
4798 =head2 CREATING A STANDARD HTTP HEADER:
4799
4800 Normally the first thing you will do in any CGI script is print out an
4801 HTTP header.  This tells the browser what type of document to expect,
4802 and gives other optional information, such as the language, expiration
4803 date, and whether to cache the document.  The header can also be
4804 manipulated for special purposes, such as server push and pay per view
4805 pages.
4806
4807         print header;
4808
4809              -or-
4810
4811         print header('image/gif');
4812
4813              -or-
4814
4815         print header('text/html','204 No response');
4816
4817              -or-
4818
4819         print header(-type=>'image/gif',
4820                              -nph=>1,
4821                              -status=>'402 Payment required',
4822                              -expires=>'+3d',
4823                              -cookie=>$cookie,
4824                              -charset=>'utf-7',
4825                              -attachment=>'foo.gif',
4826                              -Cost=>'$2.00');
4827
4828 header() returns the Content-type: header.  You can provide your own
4829 MIME type if you choose, otherwise it defaults to text/html.  An
4830 optional second parameter specifies the status code and a human-readable
4831 message.  For example, you can specify 204, "No response" to create a
4832 script that tells the browser to do nothing at all.
4833
4834 The last example shows the named argument style for passing arguments
4835 to the CGI methods using named parameters.  Recognized parameters are
4836 B<-type>, B<-status>, B<-expires>, and B<-cookie>.  Any other named
4837 parameters will be stripped of their initial hyphens and turned into
4838 header fields, allowing you to specify any HTTP header you desire.
4839 Internal underscores will be turned into hyphens:
4840
4841     print header(-Content_length=>3002);
4842
4843 Most browsers will not cache the output from CGI scripts.  Every time
4844 the browser reloads the page, the script is invoked anew.  You can
4845 change this behavior with the B<-expires> parameter.  When you specify
4846 an absolute or relative expiration interval with this parameter, some
4847 browsers and proxy servers will cache the script's output until the
4848 indicated expiration date.  The following forms are all valid for the
4849 -expires field:
4850
4851         +30s                              30 seconds from now
4852         +10m                              ten minutes from now
4853         +1h                               one hour from now
4854         -1d                               yesterday (i.e. "ASAP!")
4855         now                               immediately
4856         +3M                               in three months
4857         +10y                              in ten years time
4858         Thursday, 25-Apr-1999 00:40:33 GMT  at the indicated time & date
4859
4860 The B<-cookie> parameter generates a header that tells the browser to provide
4861 a "magic cookie" during all subsequent transactions with your script.
4862 Netscape cookies have a special format that includes interesting attributes
4863 such as expiration time.  Use the cookie() method to create and retrieve
4864 session cookies.
4865
4866 The B<-nph> parameter, if set to a true value, will issue the correct
4867 headers to work with a NPH (no-parse-header) script.  This is important
4868 to use with certain servers that expect all their scripts to be NPH.
4869
4870 The B<-charset> parameter can be used to control the character set
4871 sent to the browser.  If not provided, defaults to ISO-8859-1.  As a
4872 side effect, this sets the charset() method as well.
4873
4874 The B<-attachment> parameter can be used to turn the page into an
4875 attachment.  Instead of displaying the page, some browsers will prompt
4876 the user to save it to disk.  The value of the argument is the
4877 suggested name for the saved file.  In order for this to work, you may
4878 have to set the B<-type> to "application/octet-stream".
4879
4880 The B<-p3p> parameter will add a P3P tag to the outgoing header.  The
4881 parameter can be an arrayref or a space-delimited string of P3P tags.
4882 For example:
4883
4884    print header(-p3p=>[qw(CAO DSP LAW CURa)]);
4885    print header(-p3p=>'CAO DSP LAW CURa');
4886
4887 In either case, the outgoing header will be formatted as:
4888
4889   P3P: policyref="/w3c/p3p.xml" cp="CAO DSP LAW CURa"
4890
4891 =head2 GENERATING A REDIRECTION HEADER
4892
4893    print redirect('http://somewhere.else/in/movie/land');
4894
4895 Sometimes you don't want to produce a document yourself, but simply
4896 redirect the browser elsewhere, perhaps choosing a URL based on the
4897 time of day or the identity of the user.  
4898
4899 The redirect() function redirects the browser to a different URL.  If
4900 you use redirection like this, you should B<not> print out a header as
4901 well.
4902
4903 You should always use full URLs (including the http: or ftp: part) in
4904 redirection requests.  Relative URLs will not work correctly.
4905
4906 You can also use named arguments:
4907
4908     print redirect(-uri=>'http://somewhere.else/in/movie/land',
4909                            -nph=>1,
4910                            -status=>301);
4911
4912 The B<-nph> parameter, if set to a true value, will issue the correct
4913 headers to work with a NPH (no-parse-header) script.  This is important
4914 to use with certain servers, such as Microsoft IIS, which
4915 expect all their scripts to be NPH.
4916
4917 The B<-status> parameter will set the status of the redirect.  HTTP
4918 defines three different possible redirection status codes:
4919
4920      301 Moved Permanently
4921      302 Found
4922      303 See Other
4923
4924 The default if not specified is 302, which means "moved temporarily."
4925 You may change the status to another status code if you wish.  Be
4926 advised that changing the status to anything other than 301, 302 or
4927 303 will probably break redirection.
4928
4929 =head2 CREATING THE HTML DOCUMENT HEADER
4930
4931    print start_html(-title=>'Secrets of the Pyramids',
4932                             -author=>'fred@capricorn.org',
4933                             -base=>'true',
4934                             -target=>'_blank',
4935                             -meta=>{'keywords'=>'pharaoh secret mummy',
4936                                     'copyright'=>'copyright 1996 King Tut'},
4937                             -style=>{'src'=>'/styles/style1.css'},
4938                             -BGCOLOR=>'blue');
4939
4940 After creating the HTTP header, most CGI scripts will start writing
4941 out an HTML document.  The start_html() routine creates the top of the
4942 page, along with a lot of optional information that controls the
4943 page's appearance and behavior.