installperl

   1 #!./perl
   2
   3 BEGIN {
   4     require 5.004;
   5     chdir '..' if !-d 'lib' and -d '..\lib';
   6     @INC = 'lib';
   7     $ENV{PERL5LIB} = 'lib';
   8 }
   9
  10 use strict;
  11 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $nonono, $dostrip,
  12     $versiononly, $silent, $verbose, $otherperls);
  13 use vars qw /$depth/;
  14
  15 BEGIN {
  16     $Is_VMS = $^O eq 'VMS';
  17     $Is_W32 = $^O eq 'MSWin32';
  18     $Is_OS2 = $^O eq 'os2';
  19     $Is_Cygwin = $^O eq 'cygwin';
  20     if ($Is_VMS) { eval 'use VMS::Filespec;' }
  21 }
  22
  23 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
  24
  25 use File::Find;
  26 use File::Compare;
  27 use File::Copy ();
  28 use File::Path ();
  29 use ExtUtils::Packlist;
  30 use Config;
  31 use subs qw(unlink link chmod);
  32
  33 # override the ones in the rest of the script
  34 sub mkpath {
  35     File::Path::mkpath(@_) unless $nonono;
  36 }
  37
  38 my $mainperldir = "/usr/bin";
  39 my $exe_ext = $Config{exe_ext};
  40
  41 # Allow ``make install PERLNAME=something_besides_perl'':
  42 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
  43
  44 # This is the base used for versioned names, like "perl5.6.0".
  45 # It's separate because a common use of $PERLNAME is to install
  46 # perl as "perl5", if that's used as base for versioned files you
  47 # get "perl55.6.0".
  48 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
  49                     ? $ENV{PERLNAME_VERBASE}
  50                     : $perl;
  51
  52 $otherperls = 1;
  53 while (@ARGV) {
  54     $nonono = 1 if $ARGV[0] eq '-n';
  55     $dostrip = 1 if $ARGV[0] eq '-s';
  56     $versiononly = 1 if $ARGV[0] eq '-v';
  57     $silent = 1 if $ARGV[0] eq '-S';
  58     $otherperls = 0 if $ARGV[0] eq '-o';
  59     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
  60     shift;
  61 }
  62
  63 $versiononly = 1 if $Config{versiononly};
  64
  65 my @scripts = qw(utils/c2ph utils/h2ph utils/h2xs utils/perlbug utils/perldoc
  66                 utils/pl2pm utils/splain utils/perlcc utils/dprofpp
  67                 x2p/s2p x2p/find2perl
  68                 pod/pod2man pod/pod2html pod/pod2latex pod/pod2text
  69                 pod/pod2usage pod/podchecker pod/podselect);
  70
  71 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
  72
  73 my @pods = (<pod/*.pod>);
  74
  75 # Specify here any .pm files that are actually architecture-dependent.
  76 # (Those included with XS extensions under ext/ are automatically
  77 # added later.)
  78 # Now that the default privlib has the full perl version number included,
  79 # we no longer have to play the trick of sticking version-specific .pm
  80 # files under the archlib directory.
  81 my %archpms = (
  82     Config => 1,
  83 );
  84
  85 if ($^O eq 'dos') {
  86     push(@scripts,'djgpp/fixpmain');
  87     $archpms{config} = $archpms{filehand} = 1;
  88 }
  89
  90 if ((-e "testcompile") && (defined($ENV{'COMPILE'})))
  91 {
  92         push(@scripts, map("$_.exe", @scripts));
  93 }
  94
  95 find(sub {
  96         if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
  97             my($path, $modname) = ($1,$2);
  98
  99             # strip trailing component first
 100             $path =~ s{/[^/]*$}{};
 101
 102             # strip optional "/lib";
 103             $path =~ s{/lib\b}{};
 104
 105             # strip any leading /
 106             $path =~ s{^/}{};
 107
 108             # reconstitute canonical module name
 109             $modname = "$path/$modname" if length $path;
 110
 111             # remember it
 112             $archpms{$modname} = 1;
 113         }
 114     }, 'ext');
 115
 116 # print "[$_]\n" for sort keys %archpms;
 117
 118 my $ver = $Config{version};
 119 my $release = substr($],0,3);   # Not used presently.
 120 my $patchlevel = substr($],3,2);
 121 die "Patchlevel of perl ($patchlevel)",
 122     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
 123         if $patchlevel != $Config{'PERL_VERSION'};
 124
 125 # Fetch some frequently-used items from %Config
 126 my $installbin = $Config{installbin};
 127 my $installscript = $Config{installscript};
 128 my $installprivlib = $Config{installprivlib};
 129 my $installarchlib = $Config{installarchlib};
 130 my $installsitelib = $Config{installsitelib};
 131 my $installsitearch = $Config{installsitearch};
 132 my $installman1dir = $Config{installman1dir};
 133 my $man1ext = $Config{man1ext};
 134 my $libperl = $Config{libperl};
 135 # Shared library and dynamic loading suffixes.
 136 my $so = $Config{so};
 137 my $dlext = $Config{dlext};
 138 my $dlsrc = $Config{dlsrc};
 139
 140 my $d_dosuid = $Config{d_dosuid};
 141 my $binexp = $Config{binexp};
 142
 143 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
 144     foreach ( \$installbin,     \$installscript,  \$installprivlib,
 145               \$installarchlib, \$installsitelib, \$installsitearch,
 146               \$installman1dir ) {
 147       $$_ = unixify($$_);  $$_ =~ s:/$::;
 148     }
 149 }
 150
 151 # Do some quick sanity checks.
 152
 153 if ($d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
 154
 155    $installbin          || die "No installbin directory in config.sh\n";
 156 -d $installbin          || mkpath($installbin, $verbose, 0777);
 157 -d $installbin          || $nonono || die "$installbin is not a directory\n";
 158 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
 159         unless $installbin =~ m#^/afs/# || $nonono;
 160
 161 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
 162 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
 163
 164 -f 't/rantests'         || $Is_W32
 165                         || warn "WARNING: You've never run 'make test'!!!",
 166                                 "  (Installing anyway.)\n";
 167
 168 if ($Is_W32 or $Is_Cygwin) {
 169   my $perldll;
 170
 171   if ($Is_Cygwin) {
 172     $perldll = $libperl;
 173     $perldll =~ s/(\..*)?$/.$dlext/;
 174     if ($Config{useshrplib} eq 'true') {
 175       # install ld2 and perlld as well
 176       foreach ('ld2', 'perlld') {
 177         safe_unlink("$installbin/$_");
 178         copy("$_", "$installbin/$_");
 179         chmod(0755, "$installbin/$_");
 180       };
 181     };
 182   } else {
 183     $perldll = 'perl56.' . $dlext;
 184   }
 185
 186   if ($dlsrc ne "dl_none.xs") {
 187     -f $perldll || die "No perl DLL built\n";
 188   }
 189   # Install the DLL
 190
 191   safe_unlink("$installbin/$perldll");
 192   copy("$perldll", "$installbin/$perldll");
 193   chmod(0755, "$installbin/$perldll");
 194
 195 } # if ($Is_W32 or $Is_Cygwin)
 196
 197 # This will be used to store the packlist
 198 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
 199
 200 # First we install the version-numbered executables.
 201
 202 if ($Is_VMS) {
 203     safe_unlink("$installbin/$perl$exe_ext");
 204     copy("perl$exe_ext", "$installbin/$perl$exe_ext");
 205     chmod(0755, "$installbin/$perl$exe_ext");
 206     safe_unlink("$installbin/${perl}shr$exe_ext");
 207     copy("perlshr$exe_ext", "$installbin/${perl}shr$exe_ext");
 208     chmod(0755, "$installbin/${perl}shr$exe_ext");
 209 }
 210 elsif ($^O eq 'mpeix') {
 211     # MPE lacks hard links and requires that executables with special
 212     # capabilities reside in the MPE namespace.
 213     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
 214     # Install the primary executable into the MPE namespace as perlpath.
 215     copy("perl$exe_ext", $Config{perlpath});
 216     chmod(0755, $Config{perlpath});
 217     # Create a backup copy with the version number.
 218     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
 219 }
 220 elsif ($^O ne 'dos') {
 221     safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
 222     copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
 223     strip("$installbin/$perl_verbase$ver$exe_ext");
 224     chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
 225 }
 226 else {
 227     safe_unlink("$installbin/$perl.exe");
 228     copy("perl.exe", "$installbin/$perl.exe");
 229 }
 230
 231 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
 232 if ($d_dosuid) {
 233     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
 234     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
 235 }
 236
 237 # Install library files.
 238
 239 my ($do_installarchlib, $do_installprivlib) = (0, 0);
 240
 241 mkpath($installprivlib, $verbose, 0777);
 242 mkpath($installarchlib, $verbose, 0777);
 243 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
 244 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
 245
 246 if (chdir "lib") {
 247     $do_installarchlib = ! samepath($installarchlib, '.');
 248     $do_installprivlib = ! samepath($installprivlib, '.');
 249     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
 250
 251     if ($do_installarchlib || $do_installprivlib) {
 252         find(\&installlib, '.');
 253     }
 254     chdir ".." || die "Can't cd back to source directory: $!\n";
 255 }
 256 else {
 257     warn "Can't cd to lib to install lib files: $!\n";
 258 }
 259
 260 # Install header files and libraries.
 261 mkpath("$installarchlib/CORE", $verbose, 0777);
 262 my @corefiles;
 263 if ($Is_VMS) {  # We did core file selection during build
 264     my $coredir = "lib/$Config{archname}/$ver/CORE";
 265     $coredir =~ tr/./_/;
 266     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
 267 }
 268 else {
 269     # [als] hard-coded 'libperl' name... not good!
 270     @corefiles = <*.h libperl*.*>;
 271
 272     # AIX needs perl.exp installed as well.
 273     push(@corefiles,'perl.exp') if $^O eq 'aix';
 274     if ($^O eq 'mpeix') {
 275         # MPE needs mpeixish.h installed as well.
 276         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
 277         push(@corefiles,'mpeix/mpeixish.h');
 278     }
 279     # If they have built sperl.o...
 280     push(@corefiles,'sperl.o') if -f 'sperl.o';
 281 }
 282 foreach my $file (@corefiles) {
 283     # HP-UX (at least) needs to maintain execute permissions
 284     # on dynamically-loadable libraries. So we do it for all.
 285     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
 286         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
 287             chmod(0555, "$installarchlib/CORE/$file");
 288             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
 289         } else {
 290             chmod(0444, "$installarchlib/CORE/$file");
 291         }
 292     }
 293 }
 294
 295 # Install main perl executables
 296 # Make links to ordinary names if installbin directory isn't current directory.
 297
 298 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
 299     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
 300     if ($^O eq 'mpeix') {
 301         # MPE doesn't support hard links, so use a symlink.
 302         # We don't want another cloned copy.
 303         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
 304     } else {
 305         link("$installbin/$perl_verbase$ver$exe_ext",
 306                 "$installbin/$perl$exe_ext");
 307     }
 308     link("$installbin/s$perl_verbase$ver$exe_ext",
 309             "$installbin/suid$perl$exe_ext")
 310       if $d_dosuid;
 311 }
 312
 313 # Offer to install perl in a "standard" location
 314
 315 my $mainperl_is_instperl = 0;
 316
 317 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
 318     !$versiononly && !$nonono && !$Is_W32 && !$Is_VMS && -t STDIN && -t STDERR
 319         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
 320     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
 321     my($instperl)       = "$installbin/$perl$exe_ext";
 322     my($expinstperl)    = "$binexp/$perl$exe_ext";
 323
 324     # First make sure $usrbinperl is not already the same as the perl we
 325     # just installed.
 326     if (-x $usrbinperl) {
 327         # Try to be clever about mainperl being a symbolic link
 328         # to binexp/perl if binexp and installbin are different.
 329         $mainperl_is_instperl =
 330             samepath($usrbinperl, $instperl) ||
 331             samepath($usrbinperl, $expinstperl) ||
 332              (($binexp ne $installbin) &&
 333               (-l $usrbinperl) &&
 334               ((readlink $usrbinperl) eq $expinstperl));
 335     }
 336     if ((! $mainperl_is_instperl) &&
 337         (yn("Many scripts expect perl to be installed as $usrbinperl.\n" .
 338              "Do you wish to have $usrbinperl be the same as\n" .
 339              "$expinstperl? [y] ")))
 340     {
 341         unlink($usrbinperl);
 342         ( $Config{'d_link'} eq 'define' &&
 343           eval { CORE::link $instperl, $usrbinperl } )  ||
 344         eval { symlink $expinstperl, $usrbinperl }      ||
 345         copy($instperl, $usrbinperl);
 346
 347         $mainperl_is_instperl = 1;
 348     }
 349 }
 350
 351 # Make links to ordinary names if installbin directory isn't current directory.
 352
 353 if (!$versiononly && ! samepath($installbin, 'x2p')) {
 354     safe_unlink("$installbin/a2p$exe_ext");
 355     copy("x2p/a2p$exe_ext", "$installbin/a2p$exe_ext");
 356     chmod(0755, "$installbin/a2p$exe_ext");
 357 }
 358
 359 # cppstdin is just a script, but it is architecture-dependent, so
 360 # it can't safely be shared.  Place it in $installbin.
 361 # Note that Configure doesn't build cppstin if it isn't needed, so
 362 # we skip this if cppstdin doesn't exist.
 363 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
 364     safe_unlink("$installbin/cppstdin");
 365     copy("cppstdin", "$installbin/cppstdin");
 366     chmod(0755, "$installbin/cppstdin");
 367 }
 368
 369 if (! $versiononly) {
 370     # Install scripts.
 371
 372     mkpath($installscript, $verbose, 0777);
 373
 374     for (@scripts) {
 375         (my $base = $_) =~ s#.*/##;
 376         copy($_, "$installscript/$base");
 377         chmod(0755, "$installscript/$base");
 378     }
 379
 380     # pstruct should be a link to c2ph
 381     safe_unlink("$installscript/pstruct$scr_ext");
 382     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
 383         copy("$installscript/c2ph$scr_ext",
 384              "$installscript/pstruct$scr_ext");
 385     } else {
 386         link("$installscript/c2ph$scr_ext",
 387              "$installscript/pstruct$scr_ext");
 388     }
 389 }
 390
 391 # Install pod pages.  Where? I guess in $installprivlib/pod
 392 # ($installprivlib/pods for cygwin).
 393
 394 my $pod = $Is_Cygwin ? 'pods' : 'pod';
 395 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
 396     mkpath("${installprivlib}/$pod", $verbose, 0777);
 397
 398     # If Perl 5.003's perldiag.pod is there, rename it.
 399     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
 400         read POD, $_, 4000;
 401         close POD;
 402         # Some of Perl 5.003's diagnostic messages ended with periods.
 403         if (/^=.*\.$/m) {
 404             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
 405                                "${installprivlib}/$pod/perldiag-5.003.pod");
 406             print "  rename $from $to";
 407             rename($from, $to)
 408                 or warn "Couldn't rename $from to $to: $!\n"
 409                 unless $nonono;
 410         }
 411     }
 412
 413     for (@pods) {
 414         # $_ is a name like  pod/perl.pod
 415         (my $base = $_) =~ s#.*/##;
 416         copy_if_diff($_, "${installprivlib}/$pod/${base}");
 417     }
 418
 419 }
 420
 421 # Check to make sure there aren't other perls around in installer's
 422 # path.  This is probably UNIX-specific.  Check all absolute directories
 423 # in the path except for where public executables are supposed to live.
 424 # Also skip $mainperl if the user opted to have it be a link to the
 425 # installed perl.
 426
 427 if (!$versiononly && $otherperls) {
 428     my ($path, @path);
 429     my $dirsep = ($Is_OS2 || $Is_W32) ? ';' : ':' ;
 430     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
 431     @path = split(/$dirsep/, $path);
 432     if ($Is_VMS) {
 433         my $i = 0;
 434         while (exists $ENV{'DCL$PATH' . $i}) {
 435             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
 436             push(@path,$dir);
 437         }
 438     }
 439     my @otherperls;
 440     my %otherperls;
 441     for (@path) {
 442         next unless m,^/,;
 443         # Use &samepath here because some systems have other dirs linked
 444         # to $mainperldir (like SunOS)
 445         next if samepath($_, $binexp);
 446         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
 447         my $otherperl = "$_/$perl$exe_ext";
 448         next if $otherperls{$otherperl}++;
 449         push(@otherperls, $otherperl)
 450             if (-x $otherperl && ! -d $otherperl);
 451     }
 452     if (@otherperls) {
 453         warn "\nWarning: $perl appears in your path in the following " .
 454             "locations beyond where\nwe just installed it:\n";
 455         for (@otherperls) {
 456             warn "    ", $_, "\n";
 457         }
 458         warn "\n";
 459     }
 460
 461 }
 462
 463 $packlist->write() unless $nonono;
 464 print "  Installation complete\n" if $verbose;
 465
 466 exit 0;
 467
 468 ###############################################################################
 469
 470 sub yn {
 471     my($prompt) = @_;
 472     my($answer);
 473     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
 474     warn $prompt;
 475     chop($answer = <STDIN>);
 476     $answer = $default if $answer =~ m/^\s*$/;
 477     ($answer =~ m/^[yY]/);
 478 }
 479
 480 sub unlink {
 481     my(@names) = @_;
 482     my($cnt) = 0;
 483
 484     return scalar(@names) if $Is_VMS;
 485
 486     foreach my $name (@names) {
 487         next unless -e $name;
 488         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin);
 489         print "  unlink $name\n" if $verbose;
 490         ( CORE::unlink($name) and ++$cnt
 491           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
 492     }
 493     return $cnt;
 494 }
 495
 496 sub safe_unlink {
 497     return if $nonono or $Is_VMS;
 498     my @names = @_;
 499     foreach my $name (@names) {
 500         next unless -e $name;
 501         chmod 0777, $name if ($Is_OS2 || $Is_W32);
 502         print "  unlink $name\n" if $verbose;
 503         next if CORE::unlink($name);
 504         warn "Couldn't unlink $name: $!\n";
 505         if ($! =~ /busy/i) {
 506             print "  mv $name $name.old\n" if $verbose;
 507             safe_rename($name, "$name.old")
 508                 or warn "Couldn't rename $name: $!\n";
 509         }
 510     }
 511 }
 512
 513 sub safe_rename {
 514     my($from,$to) = @_;
 515     if (-f $to and not unlink($to)) {
 516         my($i);
 517         for ($i = 1; $i < 50; $i++) {
 518             last if rename($to, "$to.$i");
 519         }
 520         warn("Cannot rename to `$to.$i': $!"), return 0
 521            if $i >= 50; # Give up!
 522     }
 523     link($from,$to) || return 0;
 524     unlink($from);
 525 }
 526
 527 sub link {
 528     my($from,$to) = @_;
 529     my($success) = 0;
 530
 531     print $verbose ? "  ln $from $to\n" : "  $to\n" unless $silent;
 532     eval {
 533         CORE::link($from, $to)
 534             ? $success++
 535             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 536               ? die "AFS"  # okay inside eval {}
 537               : die "Couldn't link $from to $to: $!\n"
 538           unless $nonono;
 539         $packlist->{$to} = { from => $from, type => 'link' };
 540     };
 541     if ($@) {
 542         warn $@;
 543         print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 544         print "  creating new version of $to\n"
 545                  if $Is_VMS and -e $to and !$silent;
 546         File::Copy::copy($from, $to)
 547             ? $success++
 548             : warn "Couldn't copy $from to $to: $!\n"
 549           unless $nonono;
 550         $packlist->{$to} = { type => 'file' };
 551     }
 552     $success;
 553 }
 554
 555 sub chmod {
 556     my($mode,$name) = @_;
 557
 558     return if ($^O eq 'dos');
 559     printf "  chmod %o %s\n", $mode, $name if $verbose;
 560     CORE::chmod($mode,$name)
 561         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
 562       unless $nonono;
 563 }
 564
 565 sub copy {
 566     my($from,$to) = @_;
 567
 568     print $verbose ? "  cp $from $to\n" : "  $to\n" unless $silent;
 569     print "  creating new version of $to\n" if $Is_VMS and -e $to and !$silent;
 570     File::Copy::copy($from, $to)
 571         || warn "Couldn't copy $from to $to: $!\n"
 572       unless $nonono;
 573     $packlist->{$to} = { type => 'file' };
 574 }
 575
 576 sub samepath {
 577     my($p1, $p2) = @_;
 578
 579     return (lc($p1) eq lc($p2)) if $Is_W32;
 580
 581     if ($p1 ne $p2) {
 582         my($dev1, $ino1, $dev2, $ino2);
 583         ($dev1, $ino1) = stat($p1);
 584         ($dev2, $ino2) = stat($p2);
 585         ($dev1 == $dev2 && $ino1 == $ino2);
 586     }
 587     else {
 588         1;
 589     }
 590 }
 591
 592 sub installlib {
 593     my $dir = $File::Find::dir;
 594     $dir =~ s#^\.(?![^/])/?##;
 595     local($depth) = $dir ? "lib/$dir" : "lib";
 596
 597     my $name = $_;
 598
 599     # Ignore RCS and CVS directories.
 600     if (($name eq 'CVS' or $name eq 'RCS') and -d $name) {
 601         $File::Find::prune = 1;
 602         return;
 603     }
 604
 605     # ignore patch backups, RCS files, emacs backup & temp files and the
 606     # .exists files.
 607     return if $name =~ m{\.orig$|~$|^#.+#$|,v$|^\.exists};
 608
 609     $name = "$dir/$name" if $dir ne '';
 610
 611     my $installlib = $installprivlib;
 612     if ($dir =~ /^auto/ ||
 613           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
 614           ($name =~ /^(.*)\.(?:h|lib)$/i && $Is_W32)
 615        ) {
 616         $installlib = $installarchlib;
 617         return unless $do_installarchlib;
 618     } else {
 619         return unless $do_installprivlib;
 620     }
 621
 622     if (-f $_) {
 623         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$] && $archpms{$1})) {
 624             $installlib = $installprivlib;
 625             #We're installing *.al and *.ix files into $installprivlib,
 626             #but we have to delete old *.al and *.ix files from the 5.000
 627             #distribution:
 628             #This might not work because $archname might have changed.
 629             unlink("$installarchlib/$name");
 630         }
 631         $packlist->{"$installlib/$name"} = { type => 'file' };
 632         if (compare($_, "$installlib/$name") || $nonono) {
 633             unlink("$installlib/$name");
 634             mkpath("$installlib/$dir", $verbose, 0777);
 635             # HP-UX (at least) needs to maintain execute permissions
 636             # on dynamically-loaded libraries.
 637             copy_if_diff($_, "$installlib/$name")
 638                 and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
 639                            "$installlib/$name");
 640         }
 641     }
 642 }
 643
 644 # Copy $from to $to, only if $from is different than $to.
 645 # Also preserve modification times for .a libraries.
 646 # On some systems, if you do
 647 #   ranlib libperl.a
 648 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
 649 # and then try to link against the installed libperl.a, you might
 650 # get an error message to the effect that the symbol table is older
 651 # than the library.
 652 # Return true if copying occurred.
 653
 654 sub copy_if_diff {
 655     my($from,$to)=@_;
 656     return 1 if (($^O eq 'VMS') && (-d $from));
 657     -f $from || warn "$0: $from not found";
 658     $packlist->{$to} = { type => 'file' };
 659     if (compare($from, $to) || $nonono) {
 660         safe_unlink($to);   # In case we don't have write permissions.
 661         if ($nonono) {
 662             $from = $depth . "/" . $from if $depth;
 663         }
 664         copy($from, $to);
 665         # Restore timestamps if it's a .a library or for OS/2.
 666         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
 667             my ($atime, $mtime) = (stat $from)[8,9];
 668             utime $atime, $mtime, $to;
 669         }
 670         1;
 671     }
 672 }
 673
 674 sub strip
 675 {
 676     my(@args) = @_;
 677
 678     return unless $dostrip;
 679
 680     my @opts;
 681     while (@args && $args[0] =~ /^(-\w+)$/) {
 682         push @opts, shift @args;
 683     }
 684
 685     foreach my $file (@args) {
 686         if (-f $file) {
 687             print "  strip $file\n" if $verbose;
 688             system("strip", @opts, $file);
 689         } else {
 690             print "# file '$file' skipped\n" if $verbose;
 691         }
 692     }
 693 }
 694