lib/Exporter.pm

   1 package Exporter;
   2
   3 require 5.001;
   4
   5 use strict;
   6 no strict 'refs';
   7
   8 our $Debug = 0;
   9 our $ExportLevel = 0;
  10 our $Verbose ||= 0;
  11 our $VERSION = '5.562';
  12
  13 sub export_to_level {
  14   require Exporter::Heavy;
  15   goto &Exporter::Heavy::heavy_export_to_level;
  16 }
  17
  18 sub export {
  19   require Exporter::Heavy;
  20   goto &Exporter::Heavy::heavy_export;
  21 }
  22
  23 sub export_tags {
  24   require Exporter::Heavy;
  25   Exporter::Heavy::_push_tags((caller)[0], "EXPORT",    \@_);
  26 }
  27
  28 sub export_ok_tags {
  29   require Exporter::Heavy;
  30   Exporter::Heavy::_push_tags((caller)[0], "EXPORT_OK", \@_);
  31 }
  32
  33 sub import {
  34   my $pkg = shift;
  35   my $callpkg = caller($ExportLevel);
  36
  37   my($exports, $export_cache) = (\@{"$pkg\::EXPORT"},
  38                                  \%{"$pkg\::EXPORT"});
  39   # We *need* to treat @{"$pkg\::EXPORT_FAIL"} since Carp uses it :-(
  40   my($fail) = \@{"$pkg\::EXPORT_FAIL"};
  41   return export $pkg, $callpkg, @_
  42     if $Verbose or $Debug or @$fail > 1;
  43   my $args = @_ or @_ = @$exports;
  44
  45   if ($args and not %$export_cache) {
  46     foreach my $sym (@$exports, @{"$pkg\::EXPORT_OK"}) {
  47       $sym =~ s/^&//;
  48       $export_cache->{$sym} = 1;
  49     }
  50   }
  51   if ($Verbose or $Debug
  52       or grep {/\W/ or $args and not exists $export_cache->{$_}
  53                or @$fail and $_ eq $fail->[0]
  54                or (@{"$pkg\::EXPORT_OK"}
  55                    and $_ eq ${"$pkg\::EXPORT_OK"}[0])} @_) {
  56     return export $pkg, $callpkg, ($args ? @_ : ());
  57   }
  58   local $SIG{__WARN__} =
  59         sub {require Carp; local $Carp::CarpLevel = 1; &Carp::carp};
  60   foreach my $sym (@_) {
  61     # shortcut for the common case of no type character
  62     *{"$callpkg\::$sym"} = \&{"$pkg\::$sym"};
  63   }
  64 }
  65
  66
  67 # Default methods
  68
  69 sub export_fail {
  70     my $self = shift;
  71     @_;
  72 }
  73
  74
  75 sub require_version {
  76     require Exporter::Heavy;
  77     goto &Exporter::Heavy::require_version;
  78 }
  79
  80
  81 1;
  82
  83
  84 =head1 NAME
  85
  86 Exporter - Implements default import method for modules
  87
  88 =head1 SYNOPSIS
  89
  90 In module ModuleName.pm:
  91
  92   package ModuleName;
  93   require Exporter;
  94   @ISA = qw(Exporter);
  95
  96   @EXPORT = qw(...);            # symbols to export by default
  97   @EXPORT_OK = qw(...);         # symbols to export on request
  98   %EXPORT_TAGS = tag => [...];  # define names for sets of symbols
  99
 100 In other files which wish to use ModuleName:
 101
 102   use ModuleName;               # import default symbols into my package
 103
 104   use ModuleName qw(...);       # import listed symbols into my package
 105
 106   use ModuleName ();            # do not import any symbols
 107
 108 =head1 DESCRIPTION
 109
 110 The Exporter module implements a default C<import> method which
 111 many modules choose to inherit rather than implement their own.
 112
 113 Perl automatically calls the C<import> method when processing a
 114 C<use> statement for a module. Modules and C<use> are documented
 115 in L<perlfunc> and L<perlmod>. Understanding the concept of
 116 modules and how the C<use> statement operates is important to
 117 understanding the Exporter.
 118
 119 =head2 How to Export
 120
 121 The arrays C<@EXPORT> and C<@EXPORT_OK> in a module hold lists of
 122 symbols that are going to be exported into the users name space by
 123 default, or which they can request to be exported, respectively.  The
 124 symbols can represent functions, scalars, arrays, hashes, or typeglobs.
 125 The symbols must be given by full name with the exception that the
 126 ampersand in front of a function is optional, e.g.
 127
 128     @EXPORT    = qw(afunc $scalar @array);   # afunc is a function
 129     @EXPORT_OK = qw(&bfunc %hash *typeglob); # explicit prefix on &bfunc
 130
 131 =head2 Selecting What To Export
 132
 133 Do B<not> export method names!
 134
 135 Do B<not> export anything else by default without a good reason!
 136
 137 Exports pollute the namespace of the module user.  If you must export
 138 try to use @EXPORT_OK in preference to @EXPORT and avoid short or
 139 common symbol names to reduce the risk of name clashes.
 140
 141 Generally anything not exported is still accessible from outside the
 142 module using the ModuleName::item_name (or $blessed_ref-E<gt>method)
 143 syntax.  By convention you can use a leading underscore on names to
 144 informally indicate that they are 'internal' and not for public use.
 145
 146 (It is actually possible to get private functions by saying:
 147
 148   my $subref = sub { ... };
 149   &$subref;
 150
 151 But there's no way to call that directly as a method, since a method
 152 must have a name in the symbol table.)
 153
 154 As a general rule, if the module is trying to be object oriented
 155 then export nothing. If it's just a collection of functions then
 156 @EXPORT_OK anything but use @EXPORT with caution.
 157
 158 Other module design guidelines can be found in L<perlmod>.
 159
 160 =head2 Specialised Import Lists
 161
 162 If the first entry in an import list begins with !, : or / then the
 163 list is treated as a series of specifications which either add to or
 164 delete from the list of names to import. They are processed left to
 165 right. Specifications are in the form:
 166
 167     [!]name         This name only
 168     [!]:DEFAULT     All names in @EXPORT
 169     [!]:tag         All names in $EXPORT_TAGS{tag} anonymous list
 170     [!]/pattern/    All names in @EXPORT and @EXPORT_OK which match
 171
 172 A leading ! indicates that matching names should be deleted from the
 173 list of names to import.  If the first specification is a deletion it
 174 is treated as though preceded by :DEFAULT. If you just want to import
 175 extra names in addition to the default set you will still need to
 176 include :DEFAULT explicitly.
 177
 178 e.g., Module.pm defines:
 179
 180     @EXPORT      = qw(A1 A2 A3 A4 A5);
 181     @EXPORT_OK   = qw(B1 B2 B3 B4 B5);
 182     %EXPORT_TAGS = (T1 => [qw(A1 A2 B1 B2)], T2 => [qw(A1 A2 B3 B4)]);
 183
 184     Note that you cannot use tags in @EXPORT or @EXPORT_OK.
 185     Names in EXPORT_TAGS must also appear in @EXPORT or @EXPORT_OK.
 186
 187 An application using Module can say something like:
 188
 189     use Module qw(:DEFAULT :T2 !B3 A3);
 190
 191 Other examples include:
 192
 193     use Socket qw(!/^[AP]F_/ !SOMAXCONN !SOL_SOCKET);
 194     use POSIX  qw(:errno_h :termios_h !TCSADRAIN !/^EXIT/);
 195
 196 Remember that most patterns (using //) will need to be anchored
 197 with a leading ^, e.g., C</^EXIT/> rather than C</EXIT/>.
 198
 199 You can say C<BEGIN { $Exporter::Verbose=1 }> to see how the
 200 specifications are being processed and what is actually being imported
 201 into modules.
 202
 203 =head2 Exporting without using Export's import method
 204
 205 Exporter has a special method, 'export_to_level' which is used in situations
 206 where you can't directly call Export's import method. The export_to_level
 207 method looks like:
 208
 209 MyPackage->export_to_level($where_to_export, $package, @what_to_export);
 210
 211 where $where_to_export is an integer telling how far up the calling stack
 212 to export your symbols, and @what_to_export is an array telling what
 213 symbols *to* export (usually this is @_).  The $package argument is
 214 currently unused.
 215
 216 For example, suppose that you have a module, A, which already has an
 217 import function:
 218
 219 package A;
 220
 221 @ISA = qw(Exporter);
 222 @EXPORT_OK = qw ($b);
 223
 224 sub import
 225 {
 226     $A::b = 1;     # not a very useful import method
 227 }
 228
 229 and you want to Export symbol $A::b back to the module that called
 230 package A. Since Exporter relies on the import method to work, via
 231 inheritance, as it stands Exporter::import() will never get called.
 232 Instead, say the following:
 233
 234 package A;
 235 @ISA = qw(Exporter);
 236 @EXPORT_OK = qw ($b);
 237
 238 sub import
 239 {
 240     $A::b = 1;
 241     A->export_to_level(1, @_);
 242 }
 243
 244 This will export the symbols one level 'above' the current package - ie: to
 245 the program or module that used package A.
 246
 247 Note: Be careful not to modify '@_' at all before you call export_to_level
 248 - or people using your package will get very unexplained results!
 249
 250
 251 =head2 Module Version Checking
 252
 253 The Exporter module will convert an attempt to import a number from a
 254 module into a call to $module_name-E<gt>require_version($value). This can
 255 be used to validate that the version of the module being used is
 256 greater than or equal to the required version.
 257
 258 The Exporter module supplies a default require_version method which
 259 checks the value of $VERSION in the exporting module.
 260
 261 Since the default require_version method treats the $VERSION number as
 262 a simple numeric value it will regard version 1.10 as lower than
 263 1.9. For this reason it is strongly recommended that you use numbers
 264 with at least two decimal places, e.g., 1.09.
 265
 266 =head2 Managing Unknown Symbols
 267
 268 In some situations you may want to prevent certain symbols from being
 269 exported. Typically this applies to extensions which have functions
 270 or constants that may not exist on some systems.
 271
 272 The names of any symbols that cannot be exported should be listed
 273 in the C<@EXPORT_FAIL> array.
 274
 275 If a module attempts to import any of these symbols the Exporter
 276 will give the module an opportunity to handle the situation before
 277 generating an error. The Exporter will call an export_fail method
 278 with a list of the failed symbols:
 279
 280   @failed_symbols = $module_name->export_fail(@failed_symbols);
 281
 282 If the export_fail method returns an empty list then no error is
 283 recorded and all the requested symbols are exported. If the returned
 284 list is not empty then an error is generated for each symbol and the
 285 export fails. The Exporter provides a default export_fail method which
 286 simply returns the list unchanged.
 287
 288 Uses for the export_fail method include giving better error messages
 289 for some symbols and performing lazy architectural checks (put more
 290 symbols into @EXPORT_FAIL by default and then take them out if someone
 291 actually tries to use them and an expensive check shows that they are
 292 usable on that platform).
 293
 294 =head2 Tag Handling Utility Functions
 295
 296 Since the symbols listed within %EXPORT_TAGS must also appear in either
 297 @EXPORT or @EXPORT_OK, two utility functions are provided which allow
 298 you to easily add tagged sets of symbols to @EXPORT or @EXPORT_OK:
 299
 300   %EXPORT_TAGS = (foo => [qw(aa bb cc)], bar => [qw(aa cc dd)]);
 301
 302   Exporter::export_tags('foo');     # add aa, bb and cc to @EXPORT
 303   Exporter::export_ok_tags('bar');  # add aa, cc and dd to @EXPORT_OK
 304
 305 Any names which are not tags are added to @EXPORT or @EXPORT_OK
 306 unchanged but will trigger a warning (with C<-w>) to avoid misspelt tags
 307 names being silently added to @EXPORT or @EXPORT_OK. Future versions
 308 may make this a fatal error.
 309
 310 =cut