This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Dispell the "use utf8" superstition.
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 An named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<sockatmark>, C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<sockatmark>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file.
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Age of file in days when script started.
298     -A  Same for access time.
299     -C  Same for inode change time.
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current stdio buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  Example:
354
355     print "Can do.\n" if -r $a || -w _ || -x _;
356
357     stat($filename);
358     print "Readable\n" if -r _;
359     print "Writable\n" if -w _;
360     print "Executable\n" if -x _;
361     print "Setuid\n" if -u _;
362     print "Setgid\n" if -g _;
363     print "Sticky\n" if -k _;
364     print "Text\n" if -T _;
365     print "Binary\n" if -B _;
366
367 =item abs VALUE
368
369 =item abs
370
371 Returns the absolute value of its argument.
372 If VALUE is omitted, uses C<$_>.
373
374 =item accept NEWSOCKET,GENERICSOCKET
375
376 Accepts an incoming socket connect, just as the accept(2) system call
377 does.  Returns the packed address if it succeeded, false otherwise.
378 See the example in L<perlipc/"Sockets: Client/Server Communication">.
379
380 On systems that support a close-on-exec flag on files, the flag will
381 be set for the newly opened file descriptor, as determined by the
382 value of $^F.  See L<perlvar/$^F>.
383
384 =item alarm SECONDS
385
386 =item alarm
387
388 Arranges to have a SIGALRM delivered to this process after the
389 specified number of seconds have elapsed.  If SECONDS is not specified,
390 the value stored in C<$_> is used. (On some machines,
391 unfortunately, the elapsed time may be up to one second less than you
392 specified because of how seconds are counted.)  Only one timer may be
393 counting at once.  Each call disables the previous timer, and an
394 argument of C<0> may be supplied to cancel the previous timer without
395 starting a new one.  The returned value is the amount of time remaining
396 on the previous timer.
397
398 For delays of finer granularity than one second, you may use Perl's
399 four-argument version of select() leaving the first three arguments
400 undefined, or you might be able to use the C<syscall> interface to
401 access setitimer(2) if your system supports it.  The Time::HiRes
402 module (from CPAN, and starting from Perl 5.8 part of the standard
403 distribution) may also prove useful.
404
405 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
406 (C<sleep> may be internally implemented in your system with C<alarm>)
407
408 If you want to use C<alarm> to time out a system call you need to use an
409 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
410 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
411 restart system calls on some systems.  Using C<eval>/C<die> always works,
412 modulo the caveats given in L<perlipc/"Signals">.
413
414     eval {
415         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
416         alarm $timeout;
417         $nread = sysread SOCKET, $buffer, $size;
418         alarm 0;
419     };
420     if ($@) {
421         die unless $@ eq "alarm\n";   # propagate unexpected errors
422         # timed out
423     }
424     else {
425         # didn't
426     }
427
428 =item atan2 Y,X
429
430 Returns the arctangent of Y/X in the range -PI to PI.
431
432 For the tangent operation, you may use the C<Math::Trig::tan>
433 function, or use the familiar relation:
434
435     sub tan { sin($_[0]) / cos($_[0])  }
436
437 =item bind SOCKET,NAME
438
439 Binds a network address to a socket, just as the bind system call
440 does.  Returns true if it succeeded, false otherwise.  NAME should be a
441 packed address of the appropriate type for the socket.  See the examples in
442 L<perlipc/"Sockets: Client/Server Communication">.
443
444 =item binmode FILEHANDLE, DISCIPLINE
445
446 =item binmode FILEHANDLE
447
448 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
449 on systems where the run-time libraries distinguish between binary and
450 text files.  If FILEHANDLE is an expression, the value is taken as the
451 name of the filehandle.  DISCIPLINE can be either of C<":raw"> for
452 binary mode or C<":crlf"> for "text" mode.  If the DISCIPLINE is
453 omitted, it defaults to C<":raw">.
454
455 binmode() should be called after open() but before any I/O is done on
456 the filehandle.
457
458 On many systems binmode() currently has no effect, but in future, it
459 will be extended to support user-defined input and output disciplines.
460 On some systems binmode() is necessary when you're not working with a
461 text file.  For the sake of portability it is a good idea to always use
462 it when appropriate, and to never use it when it isn't appropriate.
463
464 In other words:  Regardless of platform, use binmode() on binary
465 files, and do not use binmode() on text files.
466
467 The C<open> pragma can be used to establish default disciplines.
468 See L<open>.
469
470 The operating system, device drivers, C libraries, and Perl run-time
471 system all work together to let the programmer treat a single
472 character (C<\n>) as the line terminator, irrespective of the external
473 representation.  On many operating systems, the native text file
474 representation matches the internal representation, but on some
475 platforms the external representation of C<\n> is made up of more than
476 one character.
477
478 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
479 character to end each line in the external representation of text (even
480 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
481 on Unix and most VMS files).  Consequently binmode() has no effect on
482 these operating systems.  In other systems like OS/2, DOS and the various
483 flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>, but
484 what's stored in text files are the two characters C<\cM\cJ>.  That means
485 that, if you don't use binmode() on these systems, C<\cM\cJ> sequences on
486 disk will be converted to C<\n> on input, and any C<\n> in your program
487 will be converted back to C<\cM\cJ> on output.  This is what you want for
488 text files, but it can be disastrous for binary files.
489
490 Another consequence of using binmode() (on some systems) is that
491 special end-of-file markers will be seen as part of the data stream.
492 For systems from the Microsoft family this means that if your binary
493 data contains C<\cZ>, the I/O subsystem will regard it as the end of
494 the file, unless you use binmode().
495
496 binmode() is not only important for readline() and print() operations,
497 but also when using read(), seek(), sysread(), syswrite() and tell()
498 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
499 in L<perlvar> for how to manually set your input and output
500 line-termination sequences.
501
502 =item bless REF,CLASSNAME
503
504 =item bless REF
505
506 This function tells the thingy referenced by REF that it is now an object
507 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
508 is used.  Because a C<bless> is often the last thing in a constructor,
509 it returns the reference for convenience.  Always use the two-argument
510 version if the function doing the blessing might be inherited by a
511 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
512 (and blessings) of objects.
513
514 Consider always blessing objects in CLASSNAMEs that are mixed case.
515 Namespaces with all lowercase names are considered reserved for
516 Perl pragmata.  Builtin types have all uppercase names, so to prevent
517 confusion, you may wish to avoid such package names as well.  Make sure
518 that CLASSNAME is a true value.
519
520 See L<perlmod/"Perl Modules">.
521
522 =item caller EXPR
523
524 =item caller
525
526 Returns the context of the current subroutine call.  In scalar context,
527 returns the caller's package name if there is a caller, that is, if
528 we're in a subroutine or C<eval> or C<require>, and the undefined value
529 otherwise.  In list context, returns
530
531     ($package, $filename, $line) = caller;
532
533 With EXPR, it returns some extra information that the debugger uses to
534 print a stack trace.  The value of EXPR indicates how many call frames
535 to go back before the current one.
536
537     ($package, $filename, $line, $subroutine, $hasargs,
538     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
539
540 Here $subroutine may be C<(eval)> if the frame is not a subroutine
541 call, but an C<eval>.  In such a case additional elements $evaltext and
542 C<$is_require> are set: C<$is_require> is true if the frame is created by a
543 C<require> or C<use> statement, $evaltext contains the text of the
544 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
545 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
546 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
547 frame.  C<$hasargs> is true if a new instance of C<@_> was set up for the
548 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
549 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
550 change between versions of Perl, and are not meant for external use.
551
552 Furthermore, when called from within the DB package, caller returns more
553 detailed information: it sets the list variable C<@DB::args> to be the
554 arguments with which the subroutine was invoked.
555
556 Be aware that the optimizer might have optimized call frames away before
557 C<caller> had a chance to get the information.  That means that C<caller(N)>
558 might not return information about the call frame you expect it do, for
559 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
560 previous time C<caller> was called.
561
562 =item chdir EXPR
563
564 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
565 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
566 changes to the directory specified by C<$ENV{LOGDIR}>.  If neither is
567 set, C<chdir> does nothing.  It returns true upon success, false
568 otherwise.  See the example under C<die>.
569
570 =item chmod LIST
571
572 Changes the permissions of a list of files.  The first element of the
573 list must be the numerical mode, which should probably be an octal
574 number, and which definitely should I<not> a string of octal digits:
575 C<0644> is okay, C<'0644'> is not.  Returns the number of files
576 successfully changed.  See also L</oct>, if all you have is a string.
577
578     $cnt = chmod 0755, 'foo', 'bar';
579     chmod 0755, @executables;
580     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
581                                              # --w----r-T
582     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
583     $mode = 0644;   chmod $mode, 'foo';      # this is best
584
585 You can also import the symbolic C<S_I*> constants from the Fcntl
586 module:
587
588     use Fcntl ':mode';
589
590     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
591     # This is identical to the chmod 0755 of the above example.
592
593 =item chomp VARIABLE
594
595 =item chomp LIST
596
597 =item chomp
598
599 This safer version of L</chop> removes any trailing string
600 that corresponds to the current value of C<$/> (also known as
601 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
602 number of characters removed from all its arguments.  It's often used to
603 remove the newline from the end of an input record when you're worried
604 that the final record may be missing its newline.  When in paragraph
605 mode (C<$/ = "">), it removes all trailing newlines from the string.
606 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
607 a reference to an integer or the like, see L<perlvar>) chomp() won't
608 remove anything.
609 If VARIABLE is omitted, it chomps C<$_>.  Example:
610
611     while (<>) {
612         chomp;  # avoid \n on last field
613         @array = split(/:/);
614         # ...
615     }
616
617 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
618
619 You can actually chomp anything that's an lvalue, including an assignment:
620
621     chomp($cwd = `pwd`);
622     chomp($answer = <STDIN>);
623
624 If you chomp a list, each element is chomped, and the total number of
625 characters removed is returned.
626
627 =item chop VARIABLE
628
629 =item chop LIST
630
631 =item chop
632
633 Chops off the last character of a string and returns the character
634 chopped.  It is much more efficient than C<s/.$//s> because it neither
635 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
636 If VARIABLE is a hash, it chops the hash's values, but not its keys.
637
638 You can actually chop anything that's an lvalue, including an assignment.
639
640 If you chop a list, each element is chopped.  Only the value of the
641 last C<chop> is returned.
642
643 Note that C<chop> returns the last character.  To return all but the last
644 character, use C<substr($string, 0, -1)>.
645
646 =item chown LIST
647
648 Changes the owner (and group) of a list of files.  The first two
649 elements of the list must be the I<numeric> uid and gid, in that
650 order.  A value of -1 in either position is interpreted by most
651 systems to leave that value unchanged.  Returns the number of files
652 successfully changed.
653
654     $cnt = chown $uid, $gid, 'foo', 'bar';
655     chown $uid, $gid, @filenames;
656
657 Here's an example that looks up nonnumeric uids in the passwd file:
658
659     print "User: ";
660     chomp($user = <STDIN>);
661     print "Files: ";
662     chomp($pattern = <STDIN>);
663
664     ($login,$pass,$uid,$gid) = getpwnam($user)
665         or die "$user not in passwd file";
666
667     @ary = glob($pattern);      # expand filenames
668     chown $uid, $gid, @ary;
669
670 On most systems, you are not allowed to change the ownership of the
671 file unless you're the superuser, although you should be able to change
672 the group to any of your secondary groups.  On insecure systems, these
673 restrictions may be relaxed, but this is not a portable assumption.
674 On POSIX systems, you can detect this condition this way:
675
676     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
677     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
678
679 =item chr NUMBER
680
681 =item chr
682
683 Returns the character represented by that NUMBER in the character set.
684 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
685 chr(0x263a) is a Unicode smiley face.  Note that characters from
686 127 to 255 (inclusive) are not encoded in Unicode for backward
687 compatibility reasons.
688
689 For the reverse, use L</ord>.
690 See L<utf8> for more about Unicode.
691
692 If NUMBER is omitted, uses C<$_>.
693
694 =item chroot FILENAME
695
696 =item chroot
697
698 This function works like the system call by the same name: it makes the
699 named directory the new root directory for all further pathnames that
700 begin with a C</> by your process and all its children.  (It doesn't
701 change your current working directory, which is unaffected.)  For security
702 reasons, this call is restricted to the superuser.  If FILENAME is
703 omitted, does a C<chroot> to C<$_>.
704
705 =item close FILEHANDLE
706
707 =item close
708
709 Closes the file or pipe associated with the file handle, returning true
710 only if stdio successfully flushes buffers and closes the system file
711 descriptor.  Closes the currently selected filehandle if the argument
712 is omitted.
713
714 You don't have to close FILEHANDLE if you are immediately going to do
715 another C<open> on it, because C<open> will close it for you.  (See
716 C<open>.)  However, an explicit C<close> on an input file resets the line
717 counter (C<$.>), while the implicit close done by C<open> does not.
718
719 If the file handle came from a piped open C<close> will additionally
720 return false if one of the other system calls involved fails or if the
721 program exits with non-zero status.  (If the only problem was that the
722 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
723 also waits for the process executing on the pipe to complete, in case you
724 want to look at the output of the pipe afterwards, and
725 implicitly puts the exit status value of that command into C<$?>.
726
727 Prematurely closing the read end of a pipe (i.e. before the process
728 writing to it at the other end has closed it) will result in a
729 SIGPIPE being delivered to the writer.  If the other end can't
730 handle that, be sure to read all the data before closing the pipe.
731
732 Example:
733
734     open(OUTPUT, '|sort >foo')  # pipe to sort
735         or die "Can't start sort: $!";
736     #...                        # print stuff to output
737     close OUTPUT                # wait for sort to finish
738         or warn $! ? "Error closing sort pipe: $!"
739                    : "Exit status $? from sort";
740     open(INPUT, 'foo')          # get sort's results
741         or die "Can't open 'foo' for input: $!";
742
743 FILEHANDLE may be an expression whose value can be used as an indirect
744 filehandle, usually the real filehandle name.
745
746 =item closedir DIRHANDLE
747
748 Closes a directory opened by C<opendir> and returns the success of that
749 system call.
750
751 DIRHANDLE may be an expression whose value can be used as an indirect
752 dirhandle, usually the real dirhandle name.
753
754 =item connect SOCKET,NAME
755
756 Attempts to connect to a remote socket, just as the connect system call
757 does.  Returns true if it succeeded, false otherwise.  NAME should be a
758 packed address of the appropriate type for the socket.  See the examples in
759 L<perlipc/"Sockets: Client/Server Communication">.
760
761 =item continue BLOCK
762
763 Actually a flow control statement rather than a function.  If there is a
764 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
765 C<foreach>), it is always executed just before the conditional is about to
766 be evaluated again, just like the third part of a C<for> loop in C.  Thus
767 it can be used to increment a loop variable, even when the loop has been
768 continued via the C<next> statement (which is similar to the C C<continue>
769 statement).
770
771 C<last>, C<next>, or C<redo> may appear within a C<continue>
772 block.  C<last> and C<redo> will behave as if they had been executed within
773 the main block.  So will C<next>, but since it will execute a C<continue>
774 block, it may be more entertaining.
775
776     while (EXPR) {
777         ### redo always comes here
778         do_something;
779     } continue {
780         ### next always comes here
781         do_something_else;
782         # then back the top to re-check EXPR
783     }
784     ### last always comes here
785
786 Omitting the C<continue> section is semantically equivalent to using an
787 empty one, logically enough.  In that case, C<next> goes directly back
788 to check the condition at the top of the loop.
789
790 =item cos EXPR
791
792 =item cos
793
794 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
795 takes cosine of C<$_>.
796
797 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
798 function, or use this relation:
799
800     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
801
802 =item crypt PLAINTEXT,SALT
803
804 Encrypts a string exactly like the crypt(3) function in the C library
805 (assuming that you actually have a version there that has not been
806 extirpated as a potential munition).  This can prove useful for checking
807 the password file for lousy passwords, amongst other things.  Only the
808 guys wearing white hats should do this.
809
810 Note that C<crypt> is intended to be a one-way function, much like breaking
811 eggs to make an omelette.  There is no (known) corresponding decrypt
812 function.  As a result, this function isn't all that useful for
813 cryptography.  (For that, see your nearby CPAN mirror.)
814
815 When verifying an existing encrypted string you should use the encrypted
816 text as the salt (like C<crypt($plain, $crypted) eq $crypted>).  This
817 allows your code to work with the standard C<crypt> and with more
818 exotic implementations.  When choosing a new salt create a random two
819 character string whose characters come from the set C<[./0-9A-Za-z]>
820 (like C<join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
821
822 Here's an example that makes sure that whoever runs this program knows
823 their own password:
824
825     $pwd = (getpwuid($<))[1];
826
827     system "stty -echo";
828     print "Password: ";
829     chomp($word = <STDIN>);
830     print "\n";
831     system "stty echo";
832
833     if (crypt($word, $pwd) ne $pwd) {
834         die "Sorry...\n";
835     } else {
836         print "ok\n";
837     }
838
839 Of course, typing in your own password to whoever asks you
840 for it is unwise.
841
842 The L<crypt> function is unsuitable for encrypting large quantities
843 of data, not least of all because you can't get the information
844 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
845 on your favorite CPAN mirror for a slew of potentially useful
846 modules.
847
848 =item dbmclose HASH
849
850 [This function has been largely superseded by the C<untie> function.]
851
852 Breaks the binding between a DBM file and a hash.
853
854 =item dbmopen HASH,DBNAME,MASK
855
856 [This function has been largely superseded by the C<tie> function.]
857
858 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
859 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
860 argument is I<not> a filehandle, even though it looks like one).  DBNAME
861 is the name of the database (without the F<.dir> or F<.pag> extension if
862 any).  If the database does not exist, it is created with protection
863 specified by MASK (as modified by the C<umask>).  If your system supports
864 only the older DBM functions, you may perform only one C<dbmopen> in your
865 program.  In older versions of Perl, if your system had neither DBM nor
866 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
867 sdbm(3).
868
869 If you don't have write access to the DBM file, you can only read hash
870 variables, not set them.  If you want to test whether you can write,
871 either use file tests or try setting a dummy hash entry inside an C<eval>,
872 which will trap the error.
873
874 Note that functions such as C<keys> and C<values> may return huge lists
875 when used on large DBM files.  You may prefer to use the C<each>
876 function to iterate over large DBM files.  Example:
877
878     # print out history file offsets
879     dbmopen(%HIST,'/usr/lib/news/history',0666);
880     while (($key,$val) = each %HIST) {
881         print $key, ' = ', unpack('L',$val), "\n";
882     }
883     dbmclose(%HIST);
884
885 See also L<AnyDBM_File> for a more general description of the pros and
886 cons of the various dbm approaches, as well as L<DB_File> for a particularly
887 rich implementation.
888
889 You can control which DBM library you use by loading that library
890 before you call dbmopen():
891
892     use DB_File;
893     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
894         or die "Can't open netscape history file: $!";
895
896 =item defined EXPR
897
898 =item defined
899
900 Returns a Boolean value telling whether EXPR has a value other than
901 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
902 checked.
903
904 Many operations return C<undef> to indicate failure, end of file,
905 system error, uninitialized variable, and other exceptional
906 conditions.  This function allows you to distinguish C<undef> from
907 other values.  (A simple Boolean test will not distinguish among
908 C<undef>, zero, the empty string, and C<"0">, which are all equally
909 false.)  Note that since C<undef> is a valid scalar, its presence
910 doesn't I<necessarily> indicate an exceptional condition: C<pop>
911 returns C<undef> when its argument is an empty array, I<or> when the
912 element to return happens to be C<undef>.
913
914 You may also use C<defined(&func)> to check whether subroutine C<&func>
915 has ever been defined.  The return value is unaffected by any forward
916 declarations of C<&foo>.  Note that a subroutine which is not defined
917 may still be callable: its package may have an C<AUTOLOAD> method that
918 makes it spring into existence the first time that it is called -- see
919 L<perlsub>.
920
921 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
922 used to report whether memory for that aggregate has ever been
923 allocated.  This behavior may disappear in future versions of Perl.
924 You should instead use a simple test for size:
925
926     if (@an_array) { print "has array elements\n" }
927     if (%a_hash)   { print "has hash members\n"   }
928
929 When used on a hash element, it tells you whether the value is defined,
930 not whether the key exists in the hash.  Use L</exists> for the latter
931 purpose.
932
933 Examples:
934
935     print if defined $switch{'D'};
936     print "$val\n" while defined($val = pop(@ary));
937     die "Can't readlink $sym: $!"
938         unless defined($value = readlink $sym);
939     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
940     $debugging = 0 unless defined $debugging;
941
942 Note:  Many folks tend to overuse C<defined>, and then are surprised to
943 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
944 defined values.  For example, if you say
945
946     "ab" =~ /a(.*)b/;
947
948 The pattern match succeeds, and C<$1> is defined, despite the fact that it
949 matched "nothing".  But it didn't really match nothing--rather, it
950 matched something that happened to be zero characters long.  This is all
951 very above-board and honest.  When a function returns an undefined value,
952 it's an admission that it couldn't give you an honest answer.  So you
953 should use C<defined> only when you're questioning the integrity of what
954 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
955 what you want.
956
957 See also L</undef>, L</exists>, L</ref>.
958
959 =item delete EXPR
960
961 Given an expression that specifies a hash element, array element, hash slice,
962 or array slice, deletes the specified element(s) from the hash or array.
963 In the case of an array, if the array elements happen to be at the end,
964 the size of the array will shrink to the highest element that tests
965 true for exists() (or 0 if no such element exists).
966
967 Returns each element so deleted or the undefined value if there was no such
968 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
969 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
970 from a C<tie>d hash or array may not necessarily return anything.
971
972 Deleting an array element effectively returns that position of the array
973 to its initial, uninitialized state.  Subsequently testing for the same
974 element with exists() will return false.  Note that deleting array
975 elements in the middle of an array will not shift the index of the ones
976 after them down--use splice() for that.  See L</exists>.
977
978 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
979
980     foreach $key (keys %HASH) {
981         delete $HASH{$key};
982     }
983
984     foreach $index (0 .. $#ARRAY) {
985         delete $ARRAY[$index];
986     }
987
988 And so do these:
989
990     delete @HASH{keys %HASH};
991
992     delete @ARRAY[0 .. $#ARRAY];
993
994 But both of these are slower than just assigning the empty list
995 or undefining %HASH or @ARRAY:
996
997     %HASH = ();         # completely empty %HASH
998     undef %HASH;        # forget %HASH ever existed
999
1000     @ARRAY = ();        # completely empty @ARRAY
1001     undef @ARRAY;       # forget @ARRAY ever existed
1002
1003 Note that the EXPR can be arbitrarily complicated as long as the final
1004 operation is a hash element, array element,  hash slice, or array slice
1005 lookup:
1006
1007     delete $ref->[$x][$y]{$key};
1008     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1009
1010     delete $ref->[$x][$y][$index];
1011     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1012
1013 =item die LIST
1014
1015 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1016 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1017 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1018 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1019 an C<eval(),> the error message is stuffed into C<$@> and the
1020 C<eval> is terminated with the undefined value.  This makes
1021 C<die> the way to raise an exception.
1022
1023 Equivalent examples:
1024
1025     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1026     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1027
1028 If the value of EXPR does not end in a newline, the current script line
1029 number and input line number (if any) are also printed, and a newline
1030 is supplied.  Note that the "input line number" (also known as "chunk")
1031 is subject to whatever notion of "line" happens to be currently in
1032 effect, and is also available as the special variable C<$.>.
1033 See L<perlvar/"$/"> and L<perlvar/"$.">.
1034
1035 Hint: sometimes appending C<", stopped"> to your message
1036 will cause it to make better sense when the string C<"at foo line 123"> is
1037 appended.  Suppose you are running script "canasta".
1038
1039     die "/etc/games is no good";
1040     die "/etc/games is no good, stopped";
1041
1042 produce, respectively
1043
1044     /etc/games is no good at canasta line 123.
1045     /etc/games is no good, stopped at canasta line 123.
1046
1047 See also exit(), warn(), and the Carp module.
1048
1049 If LIST is empty and C<$@> already contains a value (typically from a
1050 previous eval) that value is reused after appending C<"\t...propagated">.
1051 This is useful for propagating exceptions:
1052
1053     eval { ... };
1054     die unless $@ =~ /Expected exception/;
1055
1056 If C<$@> is empty then the string C<"Died"> is used.
1057
1058 die() can also be called with a reference argument.  If this happens to be
1059 trapped within an eval(), $@ contains the reference.  This behavior permits
1060 a more elaborate exception handling implementation using objects that
1061 maintain arbitrary state about the nature of the exception.  Such a scheme
1062 is sometimes preferable to matching particular string values of $@ using
1063 regular expressions.  Here's an example:
1064
1065     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1066     if ($@) {
1067         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1068             # handle Some::Module::Exception
1069         }
1070         else {
1071             # handle all other possible exceptions
1072         }
1073     }
1074
1075 Because perl will stringify uncaught exception messages before displaying
1076 them, you may want to overload stringification operations on such custom
1077 exception objects.  See L<overload> for details about that.
1078
1079 You can arrange for a callback to be run just before the C<die>
1080 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1081 handler will be called with the error text and can change the error
1082 message, if it sees fit, by calling C<die> again.  See
1083 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1084 L<"eval BLOCK"> for some examples.  Although this feature was meant
1085 to be run only right before your program was to exit, this is not
1086 currently the case--the C<$SIG{__DIE__}> hook is currently called
1087 even inside eval()ed blocks/strings!  If one wants the hook to do
1088 nothing in such situations, put
1089
1090         die @_ if $^S;
1091
1092 as the first line of the handler (see L<perlvar/$^S>).  Because
1093 this promotes strange action at a distance, this counterintuitive
1094 behavior may be fixed in a future release.
1095
1096 =item do BLOCK
1097
1098 Not really a function.  Returns the value of the last command in the
1099 sequence of commands indicated by BLOCK.  When modified by a loop
1100 modifier, executes the BLOCK once before testing the loop condition.
1101 (On other statements the loop modifiers test the conditional first.)
1102
1103 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1104 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1105 See L<perlsyn> for alternative strategies.
1106
1107 =item do SUBROUTINE(LIST)
1108
1109 A deprecated form of subroutine call.  See L<perlsub>.
1110
1111 =item do EXPR
1112
1113 Uses the value of EXPR as a filename and executes the contents of the
1114 file as a Perl script.  Its primary use is to include subroutines
1115 from a Perl subroutine library.
1116
1117     do 'stat.pl';
1118
1119 is just like
1120
1121     eval `cat stat.pl`;
1122
1123 except that it's more efficient and concise, keeps track of the current
1124 filename for error messages, searches the @INC libraries, and updates
1125 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1126 variables.  It also differs in that code evaluated with C<do FILENAME>
1127 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1128 same, however, in that it does reparse the file every time you call it,
1129 so you probably don't want to do this inside a loop.
1130
1131 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1132 error.  If C<do> can read the file but cannot compile it, it
1133 returns undef and sets an error message in C<$@>.   If the file is
1134 successfully compiled, C<do> returns the value of the last expression
1135 evaluated.
1136
1137 Note that inclusion of library modules is better done with the
1138 C<use> and C<require> operators, which also do automatic error checking
1139 and raise an exception if there's a problem.
1140
1141 You might like to use C<do> to read in a program configuration
1142 file.  Manual error checking can be done this way:
1143
1144     # read in config files: system first, then user
1145     for $file ("/share/prog/defaults.rc",
1146                "$ENV{HOME}/.someprogrc")
1147    {
1148         unless ($return = do $file) {
1149             warn "couldn't parse $file: $@" if $@;
1150             warn "couldn't do $file: $!"    unless defined $return;
1151             warn "couldn't run $file"       unless $return;
1152         }
1153     }
1154
1155 =item dump LABEL
1156
1157 =item dump
1158
1159 This function causes an immediate core dump.  See also the B<-u>
1160 command-line switch in L<perlrun>, which does the same thing.
1161 Primarily this is so that you can use the B<undump> program (not
1162 supplied) to turn your core dump into an executable binary after
1163 having initialized all your variables at the beginning of the
1164 program.  When the new binary is executed it will begin by executing
1165 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1166 Think of it as a goto with an intervening core dump and reincarnation.
1167 If C<LABEL> is omitted, restarts the program from the top.
1168
1169 B<WARNING>: Any files opened at the time of the dump will I<not>
1170 be open any more when the program is reincarnated, with possible
1171 resulting confusion on the part of Perl.
1172
1173 This function is now largely obsolete, partly because it's very
1174 hard to convert a core file into an executable, and because the
1175 real compiler backends for generating portable bytecode and compilable
1176 C code have superseded it.
1177
1178 If you're looking to use L<dump> to speed up your program, consider
1179 generating bytecode or native C code as described in L<perlcc>.  If
1180 you're just trying to accelerate a CGI script, consider using the
1181 C<mod_perl> extension to B<Apache>, or the CPAN module, Fast::CGI.
1182 You might also consider autoloading or selfloading, which at least
1183 make your program I<appear> to run faster.
1184
1185 =item each HASH
1186
1187 When called in list context, returns a 2-element list consisting of the
1188 key and value for the next element of a hash, so that you can iterate over
1189 it.  When called in scalar context, returns only the key for the next
1190 element in the hash.
1191
1192 Entries are returned in an apparently random order.  The actual random
1193 order is subject to change in future versions of perl, but it is guaranteed
1194 to be in the same order as either the C<keys> or C<values> function
1195 would produce on the same (unmodified) hash.
1196
1197 When the hash is entirely read, a null array is returned in list context
1198 (which when assigned produces a false (C<0>) value), and C<undef> in
1199 scalar context.  The next call to C<each> after that will start iterating
1200 again.  There is a single iterator for each hash, shared by all C<each>,
1201 C<keys>, and C<values> function calls in the program; it can be reset by
1202 reading all the elements from the hash, or by evaluating C<keys HASH> or
1203 C<values HASH>.  If you add or delete elements of a hash while you're
1204 iterating over it, you may get entries skipped or duplicated, so
1205 don't.  Exception: It is always safe to delete the item most recently
1206 returned by C<each()>, which means that the following code will work:
1207
1208         while (($key, $value) = each %hash) {
1209           print $key, "\n";
1210           delete $hash{$key};   # This is safe
1211         }
1212
1213 The following prints out your environment like the printenv(1) program,
1214 only in a different order:
1215
1216     while (($key,$value) = each %ENV) {
1217         print "$key=$value\n";
1218     }
1219
1220 See also C<keys>, C<values> and C<sort>.
1221
1222 =item eof FILEHANDLE
1223
1224 =item eof ()
1225
1226 =item eof
1227
1228 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1229 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1230 gives the real filehandle.  (Note that this function actually
1231 reads a character and then C<ungetc>s it, so isn't very useful in an
1232 interactive context.)  Do not read from a terminal file (or call
1233 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1234 as terminals may lose the end-of-file condition if you do.
1235
1236 An C<eof> without an argument uses the last file read.  Using C<eof()>
1237 with empty parentheses is very different.  It refers to the pseudo file
1238 formed from the files listed on the command line and accessed via the
1239 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1240 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1241 used will cause C<@ARGV> to be examined to determine if input is
1242 available.
1243
1244 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1245 detect the end of each file, C<eof()> will only detect the end of the
1246 last file.  Examples:
1247
1248     # reset line numbering on each input file
1249     while (<>) {
1250         next if /^\s*#/;        # skip comments
1251         print "$.\t$_";
1252     } continue {
1253         close ARGV  if eof;     # Not eof()!
1254     }
1255
1256     # insert dashes just before last line of last file
1257     while (<>) {
1258         if (eof()) {            # check for end of current file
1259             print "--------------\n";
1260             close(ARGV);        # close or last; is needed if we
1261                                 # are reading from the terminal
1262         }
1263         print;
1264     }
1265
1266 Practical hint: you almost never need to use C<eof> in Perl, because the
1267 input operators typically return C<undef> when they run out of data, or if
1268 there was an error.
1269
1270 =item eval EXPR
1271
1272 =item eval BLOCK
1273
1274 In the first form, the return value of EXPR is parsed and executed as if it
1275 were a little Perl program.  The value of the expression (which is itself
1276 determined within scalar context) is first parsed, and if there weren't any
1277 errors, executed in the lexical context of the current Perl program, so
1278 that any variable settings or subroutine and format definitions remain
1279 afterwards.  Note that the value is parsed every time the eval executes.
1280 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1281 delay parsing and subsequent execution of the text of EXPR until run time.
1282
1283 In the second form, the code within the BLOCK is parsed only once--at the
1284 same time the code surrounding the eval itself was parsed--and executed
1285 within the context of the current Perl program.  This form is typically
1286 used to trap exceptions more efficiently than the first (see below), while
1287 also providing the benefit of checking the code within BLOCK at compile
1288 time.
1289
1290 The final semicolon, if any, may be omitted from the value of EXPR or within
1291 the BLOCK.
1292
1293 In both forms, the value returned is the value of the last expression
1294 evaluated inside the mini-program; a return statement may be also used, just
1295 as with subroutines.  The expression providing the return value is evaluated
1296 in void, scalar, or list context, depending on the context of the eval itself.
1297 See L</wantarray> for more on how the evaluation context can be determined.
1298
1299 If there is a syntax error or runtime error, or a C<die> statement is
1300 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1301 error message.  If there was no error, C<$@> is guaranteed to be a null
1302 string.  Beware that using C<eval> neither silences perl from printing
1303 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1304 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1305 L</warn> and L<perlvar>.
1306
1307 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1308 determining whether a particular feature (such as C<socket> or C<symlink>)
1309 is implemented.  It is also Perl's exception trapping mechanism, where
1310 the die operator is used to raise exceptions.
1311
1312 If the code to be executed doesn't vary, you may use the eval-BLOCK
1313 form to trap run-time errors without incurring the penalty of
1314 recompiling each time.  The error, if any, is still returned in C<$@>.
1315 Examples:
1316
1317     # make divide-by-zero nonfatal
1318     eval { $answer = $a / $b; }; warn $@ if $@;
1319
1320     # same thing, but less efficient
1321     eval '$answer = $a / $b'; warn $@ if $@;
1322
1323     # a compile-time error
1324     eval { $answer = };                 # WRONG
1325
1326     # a run-time error
1327     eval '$answer =';   # sets $@
1328
1329 Due to the current arguably broken state of C<__DIE__> hooks, when using
1330 the C<eval{}> form as an exception trap in libraries, you may wish not
1331 to trigger any C<__DIE__> hooks that user code may have installed.
1332 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1333 as shown in this example:
1334
1335     # a very private exception trap for divide-by-zero
1336     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1337     warn $@ if $@;
1338
1339 This is especially significant, given that C<__DIE__> hooks can call
1340 C<die> again, which has the effect of changing their error messages:
1341
1342     # __DIE__ hooks may modify error messages
1343     {
1344        local $SIG{'__DIE__'} =
1345               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1346        eval { die "foo lives here" };
1347        print $@ if $@;                # prints "bar lives here"
1348     }
1349
1350 Because this promotes action at a distance, this counterintuitive behavior
1351 may be fixed in a future release.
1352
1353 With an C<eval>, you should be especially careful to remember what's
1354 being looked at when:
1355
1356     eval $x;            # CASE 1
1357     eval "$x";          # CASE 2
1358
1359     eval '$x';          # CASE 3
1360     eval { $x };        # CASE 4
1361
1362     eval "\$$x++";      # CASE 5
1363     $$x++;              # CASE 6
1364
1365 Cases 1 and 2 above behave identically: they run the code contained in
1366 the variable $x.  (Although case 2 has misleading double quotes making
1367 the reader wonder what else might be happening (nothing is).)  Cases 3
1368 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1369 does nothing but return the value of $x.  (Case 4 is preferred for
1370 purely visual reasons, but it also has the advantage of compiling at
1371 compile-time instead of at run-time.)  Case 5 is a place where
1372 normally you I<would> like to use double quotes, except that in this
1373 particular situation, you can just use symbolic references instead, as
1374 in case 6.
1375
1376 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1377 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1378
1379 =item exec LIST
1380
1381 =item exec PROGRAM LIST
1382
1383 The C<exec> function executes a system command I<and never returns>--
1384 use C<system> instead of C<exec> if you want it to return.  It fails and
1385 returns false only if the command does not exist I<and> it is executed
1386 directly instead of via your system's command shell (see below).
1387
1388 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1389 warns you if there is a following statement which isn't C<die>, C<warn>,
1390 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1391 I<really> want to follow an C<exec> with some other statement, you
1392 can use one of these styles to avoid the warning:
1393
1394     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1395     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1396
1397 If there is more than one argument in LIST, or if LIST is an array
1398 with more than one value, calls execvp(3) with the arguments in LIST.
1399 If there is only one scalar argument or an array with one element in it,
1400 the argument is checked for shell metacharacters, and if there are any,
1401 the entire argument is passed to the system's command shell for parsing
1402 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1403 If there are no shell metacharacters in the argument, it is split into
1404 words and passed directly to C<execvp>, which is more efficient.
1405 Examples:
1406
1407     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1408     exec "sort $outfile | uniq";
1409
1410 If you don't really want to execute the first argument, but want to lie
1411 to the program you are executing about its own name, you can specify
1412 the program you actually want to run as an "indirect object" (without a
1413 comma) in front of the LIST.  (This always forces interpretation of the
1414 LIST as a multivalued list, even if there is only a single scalar in
1415 the list.)  Example:
1416
1417     $shell = '/bin/csh';
1418     exec $shell '-sh';          # pretend it's a login shell
1419
1420 or, more directly,
1421
1422     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1423
1424 When the arguments get executed via the system shell, results will
1425 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1426 for details.
1427
1428 Using an indirect object with C<exec> or C<system> is also more
1429 secure.  This usage (which also works fine with system()) forces
1430 interpretation of the arguments as a multivalued list, even if the
1431 list had just one argument.  That way you're safe from the shell
1432 expanding wildcards or splitting up words with whitespace in them.
1433
1434     @args = ( "echo surprise" );
1435
1436     exec @args;               # subject to shell escapes
1437                                 # if @args == 1
1438     exec { $args[0] } @args;  # safe even with one-arg list
1439
1440 The first version, the one without the indirect object, ran the I<echo>
1441 program, passing it C<"surprise"> an argument.  The second version
1442 didn't--it tried to run a program literally called I<"echo surprise">,
1443 didn't find it, and set C<$?> to a non-zero value indicating failure.
1444
1445 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1446 output before the exec, but this may not be supported on some platforms
1447 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1448 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1449 open handles in order to avoid lost output.
1450
1451 Note that C<exec> will not call your C<END> blocks, nor will it call
1452 any C<DESTROY> methods in your objects.
1453
1454 =item exists EXPR
1455
1456 Given an expression that specifies a hash element or array element,
1457 returns true if the specified element in the hash or array has ever
1458 been initialized, even if the corresponding value is undefined.  The
1459 element is not autovivified if it doesn't exist.
1460
1461     print "Exists\n"    if exists $hash{$key};
1462     print "Defined\n"   if defined $hash{$key};
1463     print "True\n"      if $hash{$key};
1464
1465     print "Exists\n"    if exists $array[$index];
1466     print "Defined\n"   if defined $array[$index];
1467     print "True\n"      if $array[$index];
1468
1469 A hash or array element can be true only if it's defined, and defined if
1470 it exists, but the reverse doesn't necessarily hold true.
1471
1472 Given an expression that specifies the name of a subroutine,
1473 returns true if the specified subroutine has ever been declared, even
1474 if it is undefined.  Mentioning a subroutine name for exists or defined
1475 does not count as declaring it.  Note that a subroutine which does not
1476 exist may still be callable: its package may have an C<AUTOLOAD>
1477 method that makes it spring into existence the first time that it is
1478 called -- see L<perlsub>.
1479
1480     print "Exists\n"    if exists &subroutine;
1481     print "Defined\n"   if defined &subroutine;
1482
1483 Note that the EXPR can be arbitrarily complicated as long as the final
1484 operation is a hash or array key lookup or subroutine name:
1485
1486     if (exists $ref->{A}->{B}->{$key})  { }
1487     if (exists $hash{A}{B}{$key})       { }
1488
1489     if (exists $ref->{A}->{B}->[$ix])   { }
1490     if (exists $hash{A}{B}[$ix])        { }
1491
1492     if (exists &{$ref->{A}{B}{$key}})   { }
1493
1494 Although the deepest nested array or hash will not spring into existence
1495 just because its existence was tested, any intervening ones will.
1496 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1497 into existence due to the existence test for the $key element above.
1498 This happens anywhere the arrow operator is used, including even:
1499
1500     undef $ref;
1501     if (exists $ref->{"Some key"})      { }
1502     print $ref;             # prints HASH(0x80d3d5c)
1503
1504 This surprising autovivification in what does not at first--or even
1505 second--glance appear to be an lvalue context may be fixed in a future
1506 release.
1507
1508 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1509 on how exists() acts when used on a pseudo-hash.
1510
1511 Use of a subroutine call, rather than a subroutine name, as an argument
1512 to exists() is an error.
1513
1514     exists &sub;        # OK
1515     exists &sub();      # Error
1516
1517 =item exit EXPR
1518
1519 Evaluates EXPR and exits immediately with that value.    Example:
1520
1521     $ans = <STDIN>;
1522     exit 0 if $ans =~ /^[Xx]/;
1523
1524 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1525 universally recognized values for EXPR are C<0> for success and C<1>
1526 for error; other values are subject to interpretation depending on the
1527 environment in which the Perl program is running.  For example, exiting
1528 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1529 the mailer to return the item undelivered, but that's not true everywhere.
1530
1531 Don't use C<exit> to abort a subroutine if there's any chance that
1532 someone might want to trap whatever error happened.  Use C<die> instead,
1533 which can be trapped by an C<eval>.
1534
1535 The exit() function does not always exit immediately.  It calls any
1536 defined C<END> routines first, but these C<END> routines may not
1537 themselves abort the exit.  Likewise any object destructors that need to
1538 be called are called before the real exit.  If this is a problem, you
1539 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1540 See L<perlmod> for details.
1541
1542 =item exp EXPR
1543
1544 =item exp
1545
1546 Returns I<e> (the natural logarithm base) to the power of EXPR.
1547 If EXPR is omitted, gives C<exp($_)>.
1548
1549 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1550
1551 Implements the fcntl(2) function.  You'll probably have to say
1552
1553     use Fcntl;
1554
1555 first to get the correct constant definitions.  Argument processing and
1556 value return works just like C<ioctl> below.
1557 For example:
1558
1559     use Fcntl;
1560     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1561         or die "can't fcntl F_GETFL: $!";
1562
1563 You don't have to check for C<defined> on the return from C<fnctl>.
1564 Like C<ioctl>, it maps a C<0> return from the system call into
1565 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1566 in numeric context.  It is also exempt from the normal B<-w> warnings
1567 on improper numeric conversions.
1568
1569 Note that C<fcntl> will produce a fatal error if used on a machine that
1570 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1571 manpage to learn what functions are available on your system.
1572
1573 =item fileno FILEHANDLE
1574
1575 Returns the file descriptor for a filehandle, or undefined if the
1576 filehandle is not open.  This is mainly useful for constructing
1577 bitmaps for C<select> and low-level POSIX tty-handling operations.
1578 If FILEHANDLE is an expression, the value is taken as an indirect
1579 filehandle, generally its name.
1580
1581 You can use this to find out whether two handles refer to the
1582 same underlying descriptor:
1583
1584     if (fileno(THIS) == fileno(THAT)) {
1585         print "THIS and THAT are dups\n";
1586     }
1587
1588 (Filehandles connected to memory objects via new features of C<open> may
1589 return undefined even though they are open.)
1590
1591
1592 =item flock FILEHANDLE,OPERATION
1593
1594 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1595 for success, false on failure.  Produces a fatal error if used on a
1596 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1597 C<flock> is Perl's portable file locking interface, although it locks
1598 only entire files, not records.
1599
1600 Two potentially non-obvious but traditional C<flock> semantics are
1601 that it waits indefinitely until the lock is granted, and that its locks
1602 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1603 fewer guarantees.  This means that files locked with C<flock> may be
1604 modified by programs that do not also use C<flock>.  See L<perlport>,
1605 your port's specific documentation, or your system-specific local manpages
1606 for details.  It's best to assume traditional behavior if you're writing
1607 portable programs.  (But if you're not, you should as always feel perfectly
1608 free to write for your own system's idiosyncrasies (sometimes called
1609 "features").  Slavish adherence to portability concerns shouldn't get
1610 in the way of your getting your job done.)
1611
1612 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1613 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1614 you can use the symbolic names if you import them from the Fcntl module,
1615 either individually, or as a group using the ':flock' tag.  LOCK_SH
1616 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1617 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1618 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1619 waiting for the lock (check the return status to see if you got it).
1620
1621 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1622 before locking or unlocking it.
1623
1624 Note that the emulation built with lockf(3) doesn't provide shared
1625 locks, and it requires that FILEHANDLE be open with write intent.  These
1626 are the semantics that lockf(3) implements.  Most if not all systems
1627 implement lockf(3) in terms of fcntl(2) locking, though, so the
1628 differing semantics shouldn't bite too many people.
1629
1630 Note also that some versions of C<flock> cannot lock things over the
1631 network; you would need to use the more system-specific C<fcntl> for
1632 that.  If you like you can force Perl to ignore your system's flock(2)
1633 function, and so provide its own fcntl(2)-based emulation, by passing
1634 the switch C<-Ud_flock> to the F<Configure> program when you configure
1635 perl.
1636
1637 Here's a mailbox appender for BSD systems.
1638
1639     use Fcntl ':flock'; # import LOCK_* constants
1640
1641     sub lock {
1642         flock(MBOX,LOCK_EX);
1643         # and, in case someone appended
1644         # while we were waiting...
1645         seek(MBOX, 0, 2);
1646     }
1647
1648     sub unlock {
1649         flock(MBOX,LOCK_UN);
1650     }
1651
1652     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1653             or die "Can't open mailbox: $!";
1654
1655     lock();
1656     print MBOX $msg,"\n\n";
1657     unlock();
1658
1659 On systems that support a real flock(), locks are inherited across fork()
1660 calls, whereas those that must resort to the more capricious fcntl()
1661 function lose the locks, making it harder to write servers.
1662
1663 See also L<DB_File> for other flock() examples.
1664
1665 =item fork
1666
1667 Does a fork(2) system call to create a new process running the
1668 same program at the same point.  It returns the child pid to the
1669 parent process, C<0> to the child process, or C<undef> if the fork is
1670 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1671 are shared, while everything else is copied.  On most systems supporting
1672 fork(), great care has gone into making it extremely efficient (for
1673 example, using copy-on-write technology on data pages), making it the
1674 dominant paradigm for multitasking over the last few decades.
1675
1676 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1677 output before forking the child process, but this may not be supported
1678 on some platforms (see L<perlport>).  To be safe, you may need to set
1679 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1680 C<IO::Handle> on any open handles in order to avoid duplicate output.
1681
1682 If you C<fork> without ever waiting on your children, you will
1683 accumulate zombies.  On some systems, you can avoid this by setting
1684 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1685 forking and reaping moribund children.
1686
1687 Note that if your forked child inherits system file descriptors like
1688 STDIN and STDOUT that are actually connected by a pipe or socket, even
1689 if you exit, then the remote server (such as, say, a CGI script or a
1690 backgrounded job launched from a remote shell) won't think you're done.
1691 You should reopen those to F</dev/null> if it's any issue.
1692
1693 =item format
1694
1695 Declare a picture format for use by the C<write> function.  For
1696 example:
1697
1698     format Something =
1699         Test: @<<<<<<<< @||||| @>>>>>
1700               $str,     $%,    '$' . int($num)
1701     .
1702
1703     $str = "widget";
1704     $num = $cost/$quantity;
1705     $~ = 'Something';
1706     write;
1707
1708 See L<perlform> for many details and examples.
1709
1710 =item formline PICTURE,LIST
1711
1712 This is an internal function used by C<format>s, though you may call it,
1713 too.  It formats (see L<perlform>) a list of values according to the
1714 contents of PICTURE, placing the output into the format output
1715 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1716 Eventually, when a C<write> is done, the contents of
1717 C<$^A> are written to some filehandle, but you could also read C<$^A>
1718 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1719 does one C<formline> per line of form, but the C<formline> function itself
1720 doesn't care how many newlines are embedded in the PICTURE.  This means
1721 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1722 You may therefore need to use multiple formlines to implement a single
1723 record format, just like the format compiler.
1724
1725 Be careful if you put double quotes around the picture, because an C<@>
1726 character may be taken to mean the beginning of an array name.
1727 C<formline> always returns true.  See L<perlform> for other examples.
1728
1729 =item getc FILEHANDLE
1730
1731 =item getc
1732
1733 Returns the next character from the input file attached to FILEHANDLE,
1734 or the undefined value at end of file, or if there was an error.
1735 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1736 efficient.  However, it cannot be used by itself to fetch single
1737 characters without waiting for the user to hit enter.  For that, try
1738 something more like:
1739
1740     if ($BSD_STYLE) {
1741         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1742     }
1743     else {
1744         system "stty", '-icanon', 'eol', "\001";
1745     }
1746
1747     $key = getc(STDIN);
1748
1749     if ($BSD_STYLE) {
1750         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1751     }
1752     else {
1753         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1754     }
1755     print "\n";
1756
1757 Determination of whether $BSD_STYLE should be set
1758 is left as an exercise to the reader.
1759
1760 The C<POSIX::getattr> function can do this more portably on
1761 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1762 module from your nearest CPAN site; details on CPAN can be found on
1763 L<perlmodlib/CPAN>.
1764
1765 =item getlogin
1766
1767 Implements the C library function of the same name, which on most
1768 systems returns the current login from F</etc/utmp>, if any.  If null,
1769 use C<getpwuid>.
1770
1771     $login = getlogin || getpwuid($<) || "Kilroy";
1772
1773 Do not consider C<getlogin> for authentication: it is not as
1774 secure as C<getpwuid>.
1775
1776 =item getpeername SOCKET
1777
1778 Returns the packed sockaddr address of other end of the SOCKET connection.
1779
1780     use Socket;
1781     $hersockaddr    = getpeername(SOCK);
1782     ($port, $iaddr) = sockaddr_in($hersockaddr);
1783     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1784     $herstraddr     = inet_ntoa($iaddr);
1785
1786 =item getpgrp PID
1787
1788 Returns the current process group for the specified PID.  Use
1789 a PID of C<0> to get the current process group for the
1790 current process.  Will raise an exception if used on a machine that
1791 doesn't implement getpgrp(2).  If PID is omitted, returns process
1792 group of current process.  Note that the POSIX version of C<getpgrp>
1793 does not accept a PID argument, so only C<PID==0> is truly portable.
1794
1795 =item getppid
1796
1797 Returns the process id of the parent process.
1798
1799 =item getpriority WHICH,WHO
1800
1801 Returns the current priority for a process, a process group, or a user.
1802 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1803 machine that doesn't implement getpriority(2).
1804
1805 =item getpwnam NAME
1806
1807 =item getgrnam NAME
1808
1809 =item gethostbyname NAME
1810
1811 =item getnetbyname NAME
1812
1813 =item getprotobyname NAME
1814
1815 =item getpwuid UID
1816
1817 =item getgrgid GID
1818
1819 =item getservbyname NAME,PROTO
1820
1821 =item gethostbyaddr ADDR,ADDRTYPE
1822
1823 =item getnetbyaddr ADDR,ADDRTYPE
1824
1825 =item getprotobynumber NUMBER
1826
1827 =item getservbyport PORT,PROTO
1828
1829 =item getpwent
1830
1831 =item getgrent
1832
1833 =item gethostent
1834
1835 =item getnetent
1836
1837 =item getprotoent
1838
1839 =item getservent
1840
1841 =item setpwent
1842
1843 =item setgrent
1844
1845 =item sethostent STAYOPEN
1846
1847 =item setnetent STAYOPEN
1848
1849 =item setprotoent STAYOPEN
1850
1851 =item setservent STAYOPEN
1852
1853 =item endpwent
1854
1855 =item endgrent
1856
1857 =item endhostent
1858
1859 =item endnetent
1860
1861 =item endprotoent
1862
1863 =item endservent
1864
1865 These routines perform the same functions as their counterparts in the
1866 system library.  In list context, the return values from the
1867 various get routines are as follows:
1868
1869     ($name,$passwd,$uid,$gid,
1870        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1871     ($name,$passwd,$gid,$members) = getgr*
1872     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1873     ($name,$aliases,$addrtype,$net) = getnet*
1874     ($name,$aliases,$proto) = getproto*
1875     ($name,$aliases,$port,$proto) = getserv*
1876
1877 (If the entry doesn't exist you get a null list.)
1878
1879 The exact meaning of the $gcos field varies but it usually contains
1880 the real name of the user (as opposed to the login name) and other
1881 information pertaining to the user.  Beware, however, that in many
1882 system users are able to change this information and therefore it
1883 cannot be trusted and therefore the $gcos is tainted (see
1884 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1885 login shell, are also tainted, because of the same reason.
1886
1887 In scalar context, you get the name, unless the function was a
1888 lookup by name, in which case you get the other thing, whatever it is.
1889 (If the entry doesn't exist you get the undefined value.)  For example:
1890
1891     $uid   = getpwnam($name);
1892     $name  = getpwuid($num);
1893     $name  = getpwent();
1894     $gid   = getgrnam($name);
1895     $name  = getgrgid($num;
1896     $name  = getgrent();
1897     #etc.
1898
1899 In I<getpw*()> the fields $quota, $comment, and $expire are special
1900 cases in the sense that in many systems they are unsupported.  If the
1901 $quota is unsupported, it is an empty scalar.  If it is supported, it
1902 usually encodes the disk quota.  If the $comment field is unsupported,
1903 it is an empty scalar.  If it is supported it usually encodes some
1904 administrative comment about the user.  In some systems the $quota
1905 field may be $change or $age, fields that have to do with password
1906 aging.  In some systems the $comment field may be $class.  The $expire
1907 field, if present, encodes the expiration period of the account or the
1908 password.  For the availability and the exact meaning of these fields
1909 in your system, please consult your getpwnam(3) documentation and your
1910 F<pwd.h> file.  You can also find out from within Perl what your
1911 $quota and $comment fields mean and whether you have the $expire field
1912 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1913 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1914 files are only supported if your vendor has implemented them in the
1915 intuitive fashion that calling the regular C library routines gets the
1916 shadow versions if you're running under privilege or if there exists
1917 the shadow(3) functions as found in System V ( this includes Solaris
1918 and Linux.)  Those systems which implement a proprietary shadow password
1919 facility are unlikely to be supported.
1920
1921 The $members value returned by I<getgr*()> is a space separated list of
1922 the login names of the members of the group.
1923
1924 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1925 C, it will be returned to you via C<$?> if the function call fails.  The
1926 C<@addrs> value returned by a successful call is a list of the raw
1927 addresses returned by the corresponding system library call.  In the
1928 Internet domain, each address is four bytes long and you can unpack it
1929 by saying something like:
1930
1931     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1932
1933 The Socket library makes this slightly easier:
1934
1935     use Socket;
1936     $iaddr = inet_aton("127.1"); # or whatever address
1937     $name  = gethostbyaddr($iaddr, AF_INET);
1938
1939     # or going the other way
1940     $straddr = inet_ntoa($iaddr);
1941
1942 If you get tired of remembering which element of the return list
1943 contains which return value, by-name interfaces are provided
1944 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1945 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1946 and C<User::grent>.  These override the normal built-ins, supplying
1947 versions that return objects with the appropriate names
1948 for each field.  For example:
1949
1950    use File::stat;
1951    use User::pwent;
1952    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1953
1954 Even though it looks like they're the same method calls (uid),
1955 they aren't, because a C<File::stat> object is different from
1956 a C<User::pwent> object.
1957
1958 =item getsockname SOCKET
1959
1960 Returns the packed sockaddr address of this end of the SOCKET connection,
1961 in case you don't know the address because you have several different
1962 IPs that the connection might have come in on.
1963
1964     use Socket;
1965     $mysockaddr = getsockname(SOCK);
1966     ($port, $myaddr) = sockaddr_in($mysockaddr);
1967     printf "Connect to %s [%s]\n",
1968        scalar gethostbyaddr($myaddr, AF_INET),
1969        inet_ntoa($myaddr);
1970
1971 =item getsockopt SOCKET,LEVEL,OPTNAME
1972
1973 Returns the socket option requested, or undef if there is an error.
1974
1975 =item glob EXPR
1976
1977 =item glob
1978
1979 Returns the value of EXPR with filename expansions such as the
1980 standard Unix shell F</bin/csh> would do.  This is the internal function
1981 implementing the C<< <*.c> >> operator, but you can use it directly.
1982 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
1983 discussed in more detail in L<perlop/"I/O Operators">.
1984
1985 Beginning with v5.6.0, this operator is implemented using the standard
1986 C<File::Glob> extension.  See L<File::Glob> for details.
1987
1988 =item gmtime EXPR
1989
1990 Converts a time as returned by the time function to a 8-element list
1991 with the time localized for the standard Greenwich time zone.
1992 Typically used as follows:
1993
1994     #  0    1    2     3     4    5     6     7
1995     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
1996                                             gmtime(time);
1997
1998 All list elements are numeric, and come straight out of the C `struct
1999 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2000 specified time.  $mday is the day of the month, and $mon is the month
2001 itself, in the range C<0..11> with 0 indicating January and 11
2002 indicating December.  $year is the number of years since 1900.  That
2003 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2004 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2005 the year, in the range C<0..364> (or C<0..365> in leap years.)
2006
2007 Note that the $year element is I<not> simply the last two digits of
2008 the year.  If you assume it is, then you create non-Y2K-compliant
2009 programs--and you wouldn't want to do that, would you?
2010
2011 The proper way to get a complete 4-digit year is simply:
2012
2013         $year += 1900;
2014
2015 And to get the last two digits of the year (e.g., '01' in 2001) do:
2016
2017         $year = sprintf("%02d", $year % 100);
2018
2019 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2020
2021 In scalar context, C<gmtime()> returns the ctime(3) value:
2022
2023     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2024
2025 Also see the C<timegm> function provided by the C<Time::Local> module,
2026 and the strftime(3) function available via the POSIX module.
2027
2028 This scalar value is B<not> locale dependent (see L<perllocale>), but
2029 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2030 strftime(3) and mktime(3) functions available via the POSIX module.  To
2031 get somewhat similar but locale dependent date strings, set up your
2032 locale environment variables appropriately (please see L<perllocale>)
2033 and try for example:
2034
2035     use POSIX qw(strftime);
2036     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2037
2038 Note that the C<%a> and C<%b> escapes, which represent the short forms
2039 of the day of the week and the month of the year, may not necessarily
2040 be three characters wide in all locales.
2041
2042 =item goto LABEL
2043
2044 =item goto EXPR
2045
2046 =item goto &NAME
2047
2048 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2049 execution there.  It may not be used to go into any construct that
2050 requires initialization, such as a subroutine or a C<foreach> loop.  It
2051 also can't be used to go into a construct that is optimized away,
2052 or to get out of a block or subroutine given to C<sort>.
2053 It can be used to go almost anywhere else within the dynamic scope,
2054 including out of subroutines, but it's usually better to use some other
2055 construct such as C<last> or C<die>.  The author of Perl has never felt the
2056 need to use this form of C<goto> (in Perl, that is--C is another matter).
2057
2058 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2059 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2060 necessarily recommended if you're optimizing for maintainability:
2061
2062     goto ("FOO", "BAR", "GLARCH")[$i];
2063
2064 The C<goto-&NAME> form is quite different from the other forms of C<goto>.
2065 In fact, it isn't a goto in the normal sense at all, and doesn't have
2066 the stigma associated with other gotos.  Instead, it
2067 substitutes a call to the named subroutine for the currently running
2068 subroutine.  This is used by C<AUTOLOAD> subroutines that wish to load
2069 another subroutine and then pretend that the other subroutine had been
2070 called in the first place (except that any modifications to C<@_>
2071 in the current subroutine are propagated to the other subroutine.)
2072 After the C<goto>, not even C<caller> will be able to tell that this
2073 routine was called first.
2074
2075 NAME needn't be the name of a subroutine; it can be a scalar variable
2076 containing a code reference, or a block which evaluates to a code
2077 reference.
2078
2079 =item grep BLOCK LIST
2080
2081 =item grep EXPR,LIST
2082
2083 This is similar in spirit to, but not the same as, grep(1) and its
2084 relatives.  In particular, it is not limited to using regular expressions.
2085
2086 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2087 C<$_> to each element) and returns the list value consisting of those
2088 elements for which the expression evaluated to true.  In scalar
2089 context, returns the number of times the expression was true.
2090
2091     @foo = grep(!/^#/, @bar);    # weed out comments
2092
2093 or equivalently,
2094
2095     @foo = grep {!/^#/} @bar;    # weed out comments
2096
2097 Note that C<$_> is an alias to the list value, so it can be used to
2098 modify the elements of the LIST.  While this is useful and supported,
2099 it can cause bizarre results if the elements of LIST are not variables.
2100 Similarly, grep returns aliases into the original list, much as a for
2101 loop's index variable aliases the list elements.  That is, modifying an
2102 element of a list returned by grep (for example, in a C<foreach>, C<map>
2103 or another C<grep>) actually modifies the element in the original list.
2104 This is usually something to be avoided when writing clear code.
2105
2106 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2107
2108 =item hex EXPR
2109
2110 =item hex
2111
2112 Interprets EXPR as a hex string and returns the corresponding value.
2113 (To convert strings that might start with either 0, 0x, or 0b, see
2114 L</oct>.)  If EXPR is omitted, uses C<$_>.
2115
2116     print hex '0xAf'; # prints '175'
2117     print hex 'aF';   # same
2118
2119 Hex strings may only represent integers.  Strings that would cause
2120 integer overflow trigger a warning.
2121
2122 =item import
2123
2124 There is no builtin C<import> function.  It is just an ordinary
2125 method (subroutine) defined (or inherited) by modules that wish to export
2126 names to another module.  The C<use> function calls the C<import> method
2127 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2128
2129 =item index STR,SUBSTR,POSITION
2130
2131 =item index STR,SUBSTR
2132
2133 The index function searches for one string within another, but without
2134 the wildcard-like behavior of a full regular-expression pattern match.
2135 It returns the position of the first occurrence of SUBSTR in STR at
2136 or after POSITION.  If POSITION is omitted, starts searching from the
2137 beginning of the string.  The return value is based at C<0> (or whatever
2138 you've set the C<$[> variable to--but don't do that).  If the substring
2139 is not found, returns one less than the base, ordinarily C<-1>.
2140
2141 =item int EXPR
2142
2143 =item int
2144
2145 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2146 You should not use this function for rounding: one because it truncates
2147 towards C<0>, and two because machine representations of floating point
2148 numbers can sometimes produce counterintuitive results.  For example,
2149 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2150 because it's really more like -268.99999999999994315658 instead.  Usually,
2151 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2152 functions will serve you better than will int().
2153
2154 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2155
2156 Implements the ioctl(2) function.  You'll probably first have to say
2157
2158     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2159
2160 to get the correct function definitions.  If F<ioctl.ph> doesn't
2161 exist or doesn't have the correct definitions you'll have to roll your
2162 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2163 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2164 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2165 written depending on the FUNCTION--a pointer to the string value of SCALAR
2166 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2167 has no string value but does have a numeric value, that value will be
2168 passed rather than a pointer to the string value.  To guarantee this to be
2169 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2170 functions may be needed to manipulate the values of structures used by
2171 C<ioctl>.
2172
2173 The return value of C<ioctl> (and C<fcntl>) is as follows:
2174
2175         if OS returns:          then Perl returns:
2176             -1                    undefined value
2177              0                  string "0 but true"
2178         anything else               that number
2179
2180 Thus Perl returns true on success and false on failure, yet you can
2181 still easily determine the actual value returned by the operating
2182 system:
2183
2184     $retval = ioctl(...) || -1;
2185     printf "System returned %d\n", $retval;
2186
2187 The special string "C<0> but true" is exempt from B<-w> complaints
2188 about improper numeric conversions.
2189
2190 Here's an example of setting a filehandle named C<REMOTE> to be
2191 non-blocking at the system level.  You'll have to negotiate C<$|>
2192 on your own, though.
2193
2194     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2195
2196     $flags = fcntl(REMOTE, F_GETFL, 0)
2197                 or die "Can't get flags for the socket: $!\n";
2198
2199     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2200                 or die "Can't set flags for the socket: $!\n";
2201
2202 =item join EXPR,LIST
2203
2204 Joins the separate strings of LIST into a single string with fields
2205 separated by the value of EXPR, and returns that new string.  Example:
2206
2207     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2208
2209 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2210 first argument.  Compare L</split>.
2211
2212 =item keys HASH
2213
2214 Returns a list consisting of all the keys of the named hash.  (In
2215 scalar context, returns the number of keys.)  The keys are returned in
2216 an apparently random order.  The actual random order is subject to
2217 change in future versions of perl, but it is guaranteed to be the same
2218 order as either the C<values> or C<each> function produces (given
2219 that the hash has not been modified).  As a side effect, it resets
2220 HASH's iterator.
2221
2222 Here is yet another way to print your environment:
2223
2224     @keys = keys %ENV;
2225     @values = values %ENV;
2226     while (@keys) {
2227         print pop(@keys), '=', pop(@values), "\n";
2228     }
2229
2230 or how about sorted by key:
2231
2232     foreach $key (sort(keys %ENV)) {
2233         print $key, '=', $ENV{$key}, "\n";
2234     }
2235
2236 The returned values are copies of the original keys in the hash, so
2237 modifying them will not affect the original hash.  Compare L</values>.
2238
2239 To sort a hash by value, you'll need to use a C<sort> function.
2240 Here's a descending numeric sort of a hash by its values:
2241
2242     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2243         printf "%4d %s\n", $hash{$key}, $key;
2244     }
2245
2246 As an lvalue C<keys> allows you to increase the number of hash buckets
2247 allocated for the given hash.  This can gain you a measure of efficiency if
2248 you know the hash is going to get big.  (This is similar to pre-extending
2249 an array by assigning a larger number to $#array.)  If you say
2250
2251     keys %hash = 200;
2252
2253 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2254 in fact, since it rounds up to the next power of two.  These
2255 buckets will be retained even if you do C<%hash = ()>, use C<undef
2256 %hash> if you want to free the storage while C<%hash> is still in scope.
2257 You can't shrink the number of buckets allocated for the hash using
2258 C<keys> in this way (but you needn't worry about doing this by accident,
2259 as trying has no effect).
2260
2261 See also C<each>, C<values> and C<sort>.
2262
2263 =item kill SIGNAL, LIST
2264
2265 Sends a signal to a list of processes.  Returns the number of
2266 processes successfully signaled (which is not necessarily the
2267 same as the number actually killed).
2268
2269     $cnt = kill 1, $child1, $child2;
2270     kill 9, @goners;
2271
2272 If SIGNAL is zero, no signal is sent to the process.  This is a
2273 useful way to check that the process is alive and hasn't changed
2274 its UID.  See L<perlport> for notes on the portability of this
2275 construct.
2276
2277 Unlike in the shell, if SIGNAL is negative, it kills
2278 process groups instead of processes.  (On System V, a negative I<PROCESS>
2279 number will also kill process groups, but that's not portable.)  That
2280 means you usually want to use positive not negative signals.  You may also
2281 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2282
2283 =item last LABEL
2284
2285 =item last
2286
2287 The C<last> command is like the C<break> statement in C (as used in
2288 loops); it immediately exits the loop in question.  If the LABEL is
2289 omitted, the command refers to the innermost enclosing loop.  The
2290 C<continue> block, if any, is not executed:
2291
2292     LINE: while (<STDIN>) {
2293         last LINE if /^$/;      # exit when done with header
2294         #...
2295     }
2296
2297 C<last> cannot be used to exit a block which returns a value such as
2298 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2299 a grep() or map() operation.
2300
2301 Note that a block by itself is semantically identical to a loop
2302 that executes once.  Thus C<last> can be used to effect an early
2303 exit out of such a block.
2304
2305 See also L</continue> for an illustration of how C<last>, C<next>, and
2306 C<redo> work.
2307
2308 =item lc EXPR
2309
2310 =item lc
2311
2312 Returns an lowercased version of EXPR.  This is the internal function
2313 implementing the C<\L> escape in double-quoted strings.  Respects
2314 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2315 and L<perlunicode>.
2316
2317 If EXPR is omitted, uses C<$_>.
2318
2319 =item lcfirst EXPR
2320
2321 =item lcfirst
2322
2323 Returns the value of EXPR with the first character lowercased.  This
2324 is the internal function implementing the C<\l> escape in
2325 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2326 locale> in force.  See L<perllocale> and L<perlunicode>.
2327
2328 If EXPR is omitted, uses C<$_>.
2329
2330 =item length EXPR
2331
2332 =item length
2333
2334 Returns the length in characters of the value of EXPR.  If EXPR is
2335 omitted, returns length of C<$_>.  Note that this cannot be used on
2336 an entire array or hash to find out how many elements these have.
2337 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2338
2339 =item link OLDFILE,NEWFILE
2340
2341 Creates a new filename linked to the old filename.  Returns true for
2342 success, false otherwise.
2343
2344 =item listen SOCKET,QUEUESIZE
2345
2346 Does the same thing that the listen system call does.  Returns true if
2347 it succeeded, false otherwise.  See the example in
2348 L<perlipc/"Sockets: Client/Server Communication">.
2349
2350 =item local EXPR
2351
2352 You really probably want to be using C<my> instead, because C<local> isn't
2353 what most people think of as "local".  See
2354 L<perlsub/"Private Variables via my()"> for details.
2355
2356 A local modifies the listed variables to be local to the enclosing
2357 block, file, or eval.  If more than one value is listed, the list must
2358 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2359 for details, including issues with tied arrays and hashes.
2360
2361 =item localtime EXPR
2362
2363 Converts a time as returned by the time function to a 9-element list
2364 with the time analyzed for the local time zone.  Typically used as
2365 follows:
2366
2367     #  0    1    2     3     4    5     6     7     8
2368     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2369                                                 localtime(time);
2370
2371 All list elements are numeric, and come straight out of the C `struct
2372 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2373 specified time.  $mday is the day of the month, and $mon is the month
2374 itself, in the range C<0..11> with 0 indicating January and 11
2375 indicating December.  $year is the number of years since 1900.  That
2376 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2377 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2378 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2379 is true if the specified time occurs during daylight savings time,
2380 false otherwise.
2381
2382 Note that the $year element is I<not> simply the last two digits of
2383 the year.  If you assume it is, then you create non-Y2K-compliant
2384 programs--and you wouldn't want to do that, would you?
2385
2386 The proper way to get a complete 4-digit year is simply:
2387
2388         $year += 1900;
2389
2390 And to get the last two digits of the year (e.g., '01' in 2001) do:
2391
2392         $year = sprintf("%02d", $year % 100);
2393
2394 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2395
2396 In scalar context, C<localtime()> returns the ctime(3) value:
2397
2398     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2399
2400 This scalar value is B<not> locale dependent, see L<perllocale>, but
2401 instead a Perl builtin.  Also see the C<Time::Local> module
2402 (to convert the second, minutes, hours, ... back to seconds since the
2403 stroke of midnight the 1st of January 1970, the value returned by
2404 time()), and the strftime(3) and mktime(3) functions available via the
2405 POSIX module.  To get somewhat similar but locale dependent date
2406 strings, set up your locale environment variables appropriately
2407 (please see L<perllocale>) and try for example:
2408
2409     use POSIX qw(strftime);
2410     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2411
2412 Note that the C<%a> and C<%b>, the short forms of the day of the week
2413 and the month of the year, may not necessarily be three characters wide.
2414
2415 =item lock
2416
2417     lock I<THING>
2418
2419 This function places an advisory lock on a variable, subroutine,
2420 or referenced object contained in I<THING> until the lock goes out
2421 of scope.  This is a built-in function only if your version of Perl
2422 was built with threading enabled, and if you've said C<use Threads>.
2423 Otherwise a user-defined function by this name will be called.  See
2424 L<Thread>.
2425
2426 =item log EXPR
2427
2428 =item log
2429
2430 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2431 returns log of C<$_>.  To get the log of another base, use basic algebra:
2432 The base-N log of a number is equal to the natural log of that number
2433 divided by the natural log of N.  For example:
2434
2435     sub log10 {
2436         my $n = shift;
2437         return log($n)/log(10);
2438     }
2439
2440 See also L</exp> for the inverse operation.
2441
2442 =item lstat EXPR
2443
2444 =item lstat
2445
2446 Does the same thing as the C<stat> function (including setting the
2447 special C<_> filehandle) but stats a symbolic link instead of the file
2448 the symbolic link points to.  If symbolic links are unimplemented on
2449 your system, a normal C<stat> is done.
2450
2451 If EXPR is omitted, stats C<$_>.
2452
2453 =item m//
2454
2455 The match operator.  See L<perlop>.
2456
2457 =item map BLOCK LIST
2458
2459 =item map EXPR,LIST
2460
2461 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2462 C<$_> to each element) and returns the list value composed of the
2463 results of each such evaluation.  In scalar context, returns the
2464 total number of elements so generated.  Evaluates BLOCK or EXPR in
2465 list context, so each element of LIST may produce zero, one, or
2466 more elements in the returned value.
2467
2468     @chars = map(chr, @nums);
2469
2470 translates a list of numbers to the corresponding characters.  And
2471
2472     %hash = map { getkey($_) => $_ } @array;
2473
2474 is just a funny way to write
2475
2476     %hash = ();
2477     foreach $_ (@array) {
2478         $hash{getkey($_)} = $_;
2479     }
2480
2481 Note that C<$_> is an alias to the list value, so it can be used to
2482 modify the elements of the LIST.  While this is useful and supported,
2483 it can cause bizarre results if the elements of LIST are not variables.
2484 Using a regular C<foreach> loop for this purpose would be clearer in
2485 most cases.  See also L</grep> for an array composed of those items of
2486 the original list for which the BLOCK or EXPR evaluates to true.
2487
2488 C<{> starts both hash references and blocks, so C<map { ...> could be either
2489 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2490 ahead for the closing C<}> it has to take a guess at which its dealing with
2491 based what it finds just after the C<{>. Usually it gets it right, but if it
2492 doesn't it won't realize something is wrong until it gets to the C<}> and
2493 encounters the missing (or unexpected) comma. The syntax error will be
2494 reported close to the C<}> but you'll need to change something near the C<{>
2495 such as using a unary C<+> to give perl some help:
2496
2497     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2498     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2499     %hash = map { ("\L$_", 1) } @array  # this also works
2500     %hash = map {  lc($_), 1  } @array  # as does this.
2501     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2502
2503     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2504
2505 or to force an anon hash constructor use C<+{>
2506
2507    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2508
2509 and you get list of anonymous hashes each with only 1 entry.
2510
2511 =item mkdir FILENAME,MASK
2512
2513 =item mkdir FILENAME
2514
2515 Creates the directory specified by FILENAME, with permissions
2516 specified by MASK (as modified by C<umask>).  If it succeeds it
2517 returns true, otherwise it returns false and sets C<$!> (errno).
2518 If omitted, MASK defaults to 0777.
2519
2520 In general, it is better to create directories with permissive MASK,
2521 and let the user modify that with their C<umask>, than it is to supply
2522 a restrictive MASK and give the user no way to be more permissive.
2523 The exceptions to this rule are when the file or directory should be
2524 kept private (mail files, for instance).  The perlfunc(1) entry on
2525 C<umask> discusses the choice of MASK in more detail.
2526
2527 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2528 number of trailing slashes.  Some operating and filesystems do not get
2529 this right, so Perl automatically removes all trailing slashes to keep
2530 everyone happy.
2531
2532 =item msgctl ID,CMD,ARG
2533
2534 Calls the System V IPC function msgctl(2).  You'll probably have to say
2535
2536     use IPC::SysV;
2537
2538 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2539 then ARG must be a variable which will hold the returned C<msqid_ds>
2540 structure.  Returns like C<ioctl>: the undefined value for error,
2541 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2542 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2543
2544 =item msgget KEY,FLAGS
2545
2546 Calls the System V IPC function msgget(2).  Returns the message queue
2547 id, or the undefined value if there is an error.  See also
2548 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2549
2550 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2551
2552 Calls the System V IPC function msgrcv to receive a message from
2553 message queue ID into variable VAR with a maximum message size of
2554 SIZE.  Note that when a message is received, the message type as a
2555 native long integer will be the first thing in VAR, followed by the
2556 actual message.  This packing may be opened with C<unpack("l! a*")>.
2557 Taints the variable.  Returns true if successful, or false if there is
2558 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2559 C<IPC::SysV::Msg> documentation.
2560
2561 =item msgsnd ID,MSG,FLAGS
2562
2563 Calls the System V IPC function msgsnd to send the message MSG to the
2564 message queue ID.  MSG must begin with the native long integer message
2565 type, and be followed by the length of the actual message, and finally
2566 the message itself.  This kind of packing can be achieved with
2567 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2568 or false if there is an error.  See also C<IPC::SysV>
2569 and C<IPC::SysV::Msg> documentation.
2570
2571 =item my EXPR
2572
2573 =item my EXPR : ATTRIBUTES
2574
2575 A C<my> declares the listed variables to be local (lexically) to the
2576 enclosing block, file, or C<eval>.  If
2577 more than one value is listed, the list must be placed in parentheses.  See
2578 L<perlsub/"Private Variables via my()"> for details.
2579
2580 =item next LABEL
2581
2582 =item next
2583
2584 The C<next> command is like the C<continue> statement in C; it starts
2585 the next iteration of the loop:
2586
2587     LINE: while (<STDIN>) {
2588         next LINE if /^#/;      # discard comments
2589         #...
2590     }
2591
2592 Note that if there were a C<continue> block on the above, it would get
2593 executed even on discarded lines.  If the LABEL is omitted, the command
2594 refers to the innermost enclosing loop.
2595
2596 C<next> cannot be used to exit a block which returns a value such as
2597 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2598 a grep() or map() operation.
2599
2600 Note that a block by itself is semantically identical to a loop
2601 that executes once.  Thus C<next> will exit such a block early.
2602
2603 See also L</continue> for an illustration of how C<last>, C<next>, and
2604 C<redo> work.
2605
2606 =item no Module LIST
2607
2608 See the L</use> function, which C<no> is the opposite of.
2609
2610 =item oct EXPR
2611
2612 =item oct
2613
2614 Interprets EXPR as an octal string and returns the corresponding
2615 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2616 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2617 binary string.)  The following will handle decimal, binary, octal, and
2618 hex in the standard Perl or C notation:
2619
2620     $val = oct($val) if $val =~ /^0/;
2621
2622 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2623 in octal), use sprintf() or printf():
2624
2625     $perms = (stat("filename"))[2] & 07777;
2626     $oct_perms = sprintf "%lo", $perms;
2627
2628 The oct() function is commonly used when a string such as C<644> needs
2629 to be converted into a file mode, for example. (Although perl will
2630 automatically convert strings into numbers as needed, this automatic
2631 conversion assumes base 10.)
2632
2633 =item open FILEHANDLE,EXPR
2634
2635 =item open FILEHANDLE,MODE,EXPR
2636
2637 =item open FILEHANDLE,MODE,EXPR,LIST
2638
2639 =item open FILEHANDLE
2640
2641 Opens the file whose filename is given by EXPR, and associates it with
2642 FILEHANDLE.  If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2643 assigned a reference to a new anonymous filehandle, otherwise if FILEHANDLE is an expression,
2644 its value is used as the name of the real filehandle wanted.  (This is considered a symbolic
2645 reference, so C<use strict 'refs'> should I<not> be in effect.)
2646
2647 If EXPR is omitted, the scalar
2648 variable of the same name as the FILEHANDLE contains the filename.
2649 (Note that lexical variables--those declared with C<my>--will not work
2650 for this purpose; so if you're using C<my>, specify EXPR in your call
2651 to open.)  See L<perlopentut> for a kinder, gentler explanation of opening
2652 files.
2653
2654 If three or more arguments are specified then the mode of opening and the file name
2655 are separate. If MODE is C<< '<' >> or nothing, the file is opened for input.
2656 If MODE is C<< '>' >>, the file is truncated and opened for
2657 output, being created if necessary.  If MODE is C<<< '>>' >>>,
2658 the file is opened for appending, again being created if necessary.
2659 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to indicate that
2660 you want both read and write access to the file; thus C<< '+<' >> is almost
2661 always preferred for read/write updates--the C<< '+>' >> mode would clobber the
2662 file first.  You can't usually use either read-write mode for updating
2663 textfiles, since they have variable length records.  See the B<-i>
2664 switch in L<perlrun> for a better approach.  The file is created with
2665 permissions of C<0666> modified by the process' C<umask> value.
2666
2667 These various prefixes correspond to the fopen(3) modes of C<'r'>, C<'r+'>,
2668 C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2669
2670 In the 2-arguments (and 1-argument) form of the call the mode and
2671 filename should be concatenated (in this order), possibly separated by
2672 spaces.  It is possible to omit the mode in these forms if the mode is
2673 C<< '<' >>.
2674
2675 If the filename begins with C<'|'>, the filename is interpreted as a
2676 command to which output is to be piped, and if the filename ends with a
2677 C<'|'>, the filename is interpreted as a command which pipes output to
2678 us.  See L<perlipc/"Using open() for IPC">
2679 for more examples of this.  (You are not allowed to C<open> to a command
2680 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2681 and L<perlipc/"Bidirectional Communication with Another Process">
2682 for alternatives.)
2683
2684 For three or more arguments if MODE is C<'|-'>, the filename is interpreted as a
2685 command to which output is to be piped, and if MODE is
2686 C<'-|'>, the filename is interpreted as a command which pipes output to
2687 us.  In the 2-arguments (and 1-argument) form one should replace dash
2688 (C<'-'>) with the command.  See L<perlipc/"Using open() for IPC">
2689 for more examples of this.  (You are not allowed to C<open> to a command
2690 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2691 and L<perlipc/"Bidirectional Communication"> for alternatives.) In 3+ arg form of
2692 pipe opens then if LIST is specified (extra arguments after the command name) then
2693 LIST becomes arguments to the command invoked if the platform supports it.
2694 The meaning of C<open> with more than three arguments for non-pipe modes
2695 is not yet specified. Experimental "layers" may give extra LIST arguments meaning.
2696
2697 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2698 and opening C<< '>-' >> opens STDOUT.
2699
2700 Open returns
2701 nonzero upon success, the undefined value otherwise.  If the C<open>
2702 involved a pipe, the return value happens to be the pid of the
2703 subprocess.
2704
2705 If you're unfortunate enough to be running Perl on a system that
2706 distinguishes between text files and binary files (modern operating
2707 systems don't care), then you should check out L</binmode> for tips for
2708 dealing with this.  The key distinction between systems that need C<binmode>
2709 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2710 Plan9, which delimit lines with a single character, and which encode that
2711 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2712
2713 In the three argument form MODE may also contain a list of IO "layers" (see L<open> and
2714 L<PerlIO> for more details) to be applied to the handle. This can be used to achieve the
2715 effect of C<binmode> as well as more complex behaviours.
2716
2717 When opening a file, it's usually a bad idea to continue normal execution
2718 if the request failed, so C<open> is frequently used in connection with
2719 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2720 where you want to make a nicely formatted error message (but there are
2721 modules that can help with that problem)) you should always check
2722 the return value from opening a file.  The infrequent exception is when
2723 working with an unopened filehandle is actually what you want to do.
2724
2725 As a special case the 3 arg form with a read/write mode and the third argument
2726 being C<undef>:
2727
2728     open(TMP, "+>", undef) or die ...
2729
2730 opens a filehandle to an anonymous temporary file.
2731
2732
2733 Examples:
2734
2735     $ARTICLE = 100;
2736     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2737     while (<ARTICLE>) {...
2738
2739     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2740     # if the open fails, output is discarded
2741
2742     open(DBASE, '+<', 'dbase.mine')             # open for update
2743         or die "Can't open 'dbase.mine' for update: $!";
2744
2745     open(DBASE, '+<dbase.mine')                 # ditto
2746         or die "Can't open 'dbase.mine' for update: $!";
2747
2748     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2749         or die "Can't start caesar: $!";
2750
2751     open(ARTICLE, "caesar <$article |")         # ditto
2752         or die "Can't start caesar: $!";
2753
2754     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2755         or die "Can't start sort: $!";
2756
2757     # process argument list of files along with any includes
2758
2759     foreach $file (@ARGV) {
2760         process($file, 'fh00');
2761     }
2762
2763     sub process {
2764         my($filename, $input) = @_;
2765         $input++;               # this is a string increment
2766         unless (open($input, $filename)) {
2767             print STDERR "Can't open $filename: $!\n";
2768             return;
2769         }
2770
2771         local $_;
2772         while (<$input>) {              # note use of indirection
2773             if (/^#include "(.*)"/) {
2774                 process($1, $input);
2775                 next;
2776             }
2777             #...                # whatever
2778         }
2779     }
2780
2781 You may also, in the Bourne shell tradition, specify an EXPR beginning
2782 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2783 name of a filehandle (or file descriptor, if numeric) to be
2784 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2785 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2786 mode you specify should match the mode of the original filehandle.
2787 (Duping a filehandle does not take into account any existing contents of
2788 stdio buffers.) If you use the 3 arg form then you can pass either a number,
2789 the name of a filehandle or the normal "reference to a glob".
2790
2791 Here is a script that saves, redirects, and restores STDOUT and
2792 STDERR:
2793
2794     #!/usr/bin/perl
2795     open(my $oldout, ">&", \*STDOUT);
2796     open(OLDERR, ">&STDERR");
2797
2798     open(STDOUT, '>', "foo.out") || die "Can't redirect stdout";
2799     open(STDERR, ">&STDOUT")     || die "Can't dup stdout";
2800
2801     select(STDERR); $| = 1;     # make unbuffered
2802     select(STDOUT); $| = 1;     # make unbuffered
2803
2804     print STDOUT "stdout 1\n";  # this works for
2805     print STDERR "stderr 1\n";  # subprocesses too
2806
2807     close(STDOUT);
2808     close(STDERR);
2809
2810     open(STDOUT, ">&OLDOUT");
2811     open(STDERR, ">&OLDERR");
2812
2813     print STDOUT "stdout 2\n";
2814     print STDERR "stderr 2\n";
2815
2816 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2817 do an equivalent of C's C<fdopen> of that file descriptor; this is
2818 more parsimonious of file descriptors.  For example:
2819
2820     open(FILEHANDLE, "<&=$fd")
2821
2822 or
2823
2824     open(FILEHANDLE, "<&=", $fd)
2825
2826 Note that if Perl is using the standard C libraries' fdopen() then on
2827 many UNIX systems, fdopen() is known to fail when file descriptors
2828 exceed a certain value, typically 255. If you need more file
2829 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2830
2831 You can see whether Perl has been compiled with PerlIO or not by
2832 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2833 is C<define>, you have PerlIO, otherwise you don't.
2834
2835 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2836 with 2-arguments (or 1-argument) form of open(), then
2837 there is an implicit fork done, and the return value of open is the pid
2838 of the child within the parent process, and C<0> within the child
2839 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2840 The filehandle behaves normally for the parent, but i/o to that
2841 filehandle is piped from/to the STDOUT/STDIN of the child process.
2842 In the child process the filehandle isn't opened--i/o happens from/to
2843 the new STDOUT or STDIN.  Typically this is used like the normal
2844 piped open when you want to exercise more control over just how the
2845 pipe command gets executed, such as when you are running setuid, and
2846 don't want to have to scan shell commands for metacharacters.
2847 The following triples are more or less equivalent:
2848
2849     open(FOO, "|tr '[a-z]' '[A-Z]'");
2850     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2851     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2852     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2853
2854     open(FOO, "cat -n '$file'|");
2855     open(FOO, '-|', "cat -n '$file'");
2856     open(FOO, '-|') || exec 'cat', '-n', $file;
2857     open(FOO, '-|', "cat", '-n', $file);
2858
2859 The last example in each block shows the pipe as "list form", which is
2860 not yet supported on all platforms.
2861
2862 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2863
2864 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2865 output before any operation that may do a fork, but this may not be
2866 supported on some platforms (see L<perlport>).  To be safe, you may need
2867 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2868 of C<IO::Handle> on any open handles.
2869
2870 On systems that support a
2871 close-on-exec flag on files, the flag will be set for the newly opened
2872 file descriptor as determined by the value of $^F.  See L<perlvar/$^F>.
2873
2874 Closing any piped filehandle causes the parent process to wait for the
2875 child to finish, and returns the status value in C<$?>.
2876
2877 The filename passed to 2-argument (or 1-argument) form of open()
2878 will have leading and trailing
2879 whitespace deleted, and the normal redirection characters
2880 honored.  This property, known as "magic open",
2881 can often be used to good effect.  A user could specify a filename of
2882 F<"rsh cat file |">, or you could change certain filenames as needed:
2883
2884     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2885     open(FH, $filename) or die "Can't open $filename: $!";
2886
2887 Use 3-argument form to open a file with arbitrary weird characters in it,
2888
2889     open(FOO, '<', $file);
2890
2891 otherwise it's necessary to protect any leading and trailing whitespace:
2892
2893     $file =~ s#^(\s)#./$1#;
2894     open(FOO, "< $file\0");
2895
2896 (this may not work on some bizarre filesystems).  One should
2897 conscientiously choose between the I<magic> and 3-arguments form
2898 of open():
2899
2900     open IN, $ARGV[0];
2901
2902 will allow the user to specify an argument of the form C<"rsh cat file |">,
2903 but will not work on a filename which happens to have a trailing space, while
2904
2905     open IN, '<', $ARGV[0];
2906
2907 will have exactly the opposite restrictions.
2908
2909 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2910 should use the C<sysopen> function, which involves no such magic (but
2911 may use subtly different filemodes than Perl open(), which is mapped
2912 to C fopen()).  This is
2913 another way to protect your filenames from interpretation.  For example:
2914
2915     use IO::Handle;
2916     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2917         or die "sysopen $path: $!";
2918     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2919     print HANDLE "stuff $$\n";
2920     seek(HANDLE, 0, 0);
2921     print "File contains: ", <HANDLE>;
2922
2923 Using the constructor from the C<IO::Handle> package (or one of its
2924 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2925 filehandles that have the scope of whatever variables hold references to
2926 them, and automatically close whenever and however you leave that scope:
2927
2928     use IO::File;
2929     #...
2930     sub read_myfile_munged {
2931         my $ALL = shift;
2932         my $handle = new IO::File;
2933         open($handle, "myfile") or die "myfile: $!";
2934         $first = <$handle>
2935             or return ();     # Automatically closed here.
2936         mung $first or die "mung failed";       # Or here.
2937         return $first, <$handle> if $ALL;       # Or here.
2938         $first;                                 # Or here.
2939     }
2940
2941 See L</seek> for some details about mixing reading and writing.
2942
2943 =item opendir DIRHANDLE,EXPR
2944
2945 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
2946 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
2947 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2948
2949 =item ord EXPR
2950
2951 =item ord
2952
2953 Returns the numeric (ASCII or Unicode) value of the first character of EXPR.  If
2954 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2955 See L<utf8> for more about Unicode.
2956
2957 =item our EXPR
2958
2959 =item our EXPR : ATTRIBUTES
2960
2961 An C<our> declares the listed variables to be valid globals within
2962 the enclosing block, file, or C<eval>.  That is, it has the same
2963 scoping rules as a "my" declaration, but does not create a local
2964 variable.  If more than one value is listed, the list must be placed
2965 in parentheses.  The C<our> declaration has no semantic effect unless
2966 "use strict vars" is in effect, in which case it lets you use the
2967 declared global variable without qualifying it with a package name.
2968 (But only within the lexical scope of the C<our> declaration.  In this
2969 it differs from "use vars", which is package scoped.)
2970
2971 An C<our> declaration declares a global variable that will be visible
2972 across its entire lexical scope, even across package boundaries.  The
2973 package in which the variable is entered is determined at the point
2974 of the declaration, not at the point of use.  This means the following
2975 behavior holds:
2976
2977     package Foo;
2978     our $bar;           # declares $Foo::bar for rest of lexical scope
2979     $bar = 20;
2980
2981     package Bar;
2982     print $bar;         # prints 20
2983
2984 Multiple C<our> declarations in the same lexical scope are allowed
2985 if they are in different packages.  If they happened to be in the same
2986 package, Perl will emit warnings if you have asked for them.
2987
2988     use warnings;
2989     package Foo;
2990     our $bar;           # declares $Foo::bar for rest of lexical scope
2991     $bar = 20;
2992
2993     package Bar;
2994     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
2995     print $bar;         # prints 30
2996
2997     our $bar;           # emits warning
2998
2999 An C<our> declaration may also have a list of attributes associated
3000 with it.  B<WARNING>: This is an experimental feature that may be
3001 changed or removed in future releases of Perl.  It should not be
3002 relied upon.
3003
3004 The only currently recognized attribute is C<unique> which indicates
3005 that a single copy of the global is to be used by all interpreters
3006 should the program happen to be running in a multi-interpreter
3007 environment. (The default behaviour would be for each interpreter to
3008 have its own copy of the global.)  In such an environment, this
3009 attribute also has the effect of making the global readonly.
3010 Examples:
3011
3012     our @EXPORT : unique = qw(foo);
3013     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3014     our $VERSION : unique = "1.00";
3015
3016 Multi-interpreter environments can come to being either through the
3017 fork() emulation on Windows platforms, or by embedding perl in a
3018 multi-threaded application.  The C<unique> attribute does nothing in
3019 all other environments.
3020
3021 =item pack TEMPLATE,LIST
3022
3023 Takes a LIST of values and converts it into a string using the rules
3024 given by the TEMPLATE.  The resulting string is the concatenation of
3025 the converted values.  Typically, each converted value looks
3026 like its machine-level representation.  For example, on 32-bit machines
3027 a converted integer may be represented by a sequence of 4 bytes.
3028
3029 The TEMPLATE is a
3030 sequence of characters that give the order and type of values, as
3031 follows:
3032
3033     a   A string with arbitrary binary data, will be null padded.
3034     A   An ASCII string, will be space padded.
3035     Z   A null terminated (asciz) string, will be null padded.
3036
3037     b   A bit string (ascending bit order inside each byte, like vec()).
3038     B   A bit string (descending bit order inside each byte).
3039     h   A hex string (low nybble first).
3040     H   A hex string (high nybble first).
3041
3042     c   A signed char value.
3043     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3044
3045     s   A signed short value.
3046     S   An unsigned short value.
3047           (This 'short' is _exactly_ 16 bits, which may differ from
3048            what a local C compiler calls 'short'.  If you want
3049            native-length shorts, use the '!' suffix.)
3050
3051     i   A signed integer value.
3052     I   An unsigned integer value.
3053           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3054            size depends on what a local C compiler calls 'int',
3055            and may even be larger than the 'long' described in
3056            the next item.)
3057
3058     l   A signed long value.
3059     L   An unsigned long value.
3060           (This 'long' is _exactly_ 32 bits, which may differ from
3061            what a local C compiler calls 'long'.  If you want
3062            native-length longs, use the '!' suffix.)
3063
3064     n   An unsigned short in "network" (big-endian) order.
3065     N   An unsigned long in "network" (big-endian) order.
3066     v   An unsigned short in "VAX" (little-endian) order.
3067     V   An unsigned long in "VAX" (little-endian) order.
3068           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3069            _exactly_ 32 bits, respectively.)
3070
3071     q   A signed quad (64-bit) value.
3072     Q   An unsigned quad value.
3073           (Quads are available only if your system supports 64-bit
3074            integer values _and_ if Perl has been compiled to support those.
3075            Causes a fatal error otherwise.)
3076
3077     f   A single-precision float in the native format.
3078     d   A double-precision float in the native format.
3079
3080     p   A pointer to a null-terminated string.
3081     P   A pointer to a structure (fixed-length string).
3082
3083     u   A uuencoded string.
3084     U   A Unicode character number.  Encodes to UTF-8 internally
3085         (or UTF-EBCDIC in EBCDIC platforms).
3086
3087     w   A BER compressed integer.  Its bytes represent an unsigned
3088         integer in base 128, most significant digit first, with as
3089         few digits as possible.  Bit eight (the high bit) is set
3090         on each byte except the last.
3091
3092     x   A null byte.
3093     X   Back up a byte.
3094     @   Null fill to absolute position.
3095
3096 The following rules apply:
3097
3098 =over 8
3099
3100 =item *
3101
3102 Each letter may optionally be followed by a number giving a repeat
3103 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3104 C<H>, and C<P> the pack function will gobble up that many values from
3105 the LIST.  A C<*> for the repeat count means to use however many items are
3106 left, except for C<@>, C<x>, C<X>, where it is equivalent
3107 to C<0>, and C<u>, where it is equivalent to 1 (or 45, what is the
3108 same).
3109
3110 When used with C<Z>, C<*> results in the addition of a trailing null
3111 byte (so the packed result will be one longer than the byte C<length>
3112 of the item).
3113
3114 The repeat count for C<u> is interpreted as the maximal number of bytes
3115 to encode per line of output, with 0 and 1 replaced by 45.
3116
3117 =item *
3118
3119 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3120 string of length count, padding with nulls or spaces as necessary.  When
3121 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3122 after the first null, and C<a> returns data verbatim.  When packing,
3123 C<a>, and C<Z> are equivalent.
3124
3125 If the value-to-pack is too long, it is truncated.  If too long and an
3126 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3127 by a null byte.  Thus C<Z> always packs a trailing null byte under
3128 all circumstances.
3129
3130 =item *
3131
3132 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3133 Each byte of the input field of pack() generates 1 bit of the result.
3134 Each result bit is based on the least-significant bit of the corresponding
3135 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3136 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3137
3138 Starting from the beginning of the input string of pack(), each 8-tuple
3139 of bytes is converted to 1 byte of output.  With format C<b>
3140 the first byte of the 8-tuple determines the least-significant bit of a
3141 byte, and with format C<B> it determines the most-significant bit of
3142 a byte.
3143
3144 If the length of the input string is not exactly divisible by 8, the
3145 remainder is packed as if the input string were padded by null bytes
3146 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3147
3148 If the input string of pack() is longer than needed, extra bytes are ignored.
3149 A C<*> for the repeat count of pack() means to use all the bytes of
3150 the input field.  On unpack()ing the bits are converted to a string
3151 of C<"0">s and C<"1">s.
3152
3153 =item *
3154
3155 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3156 representable as hexadecimal digits, 0-9a-f) long.
3157
3158 Each byte of the input field of pack() generates 4 bits of the result.
3159 For non-alphabetical bytes the result is based on the 4 least-significant
3160 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3161 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3162 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3163 is compatible with the usual hexadecimal digits, so that C<"a"> and
3164 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3165 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3166
3167 Starting from the beginning of the input string of pack(), each pair
3168 of bytes is converted to 1 byte of output.  With format C<h> the
3169 first byte of the pair determines the least-significant nybble of the
3170 output byte, and with format C<H> it determines the most-significant
3171 nybble.
3172
3173 If the length of the input string is not even, it behaves as if padded
3174 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3175 nybbles are ignored.
3176
3177 If the input string of pack() is longer than needed, extra bytes are ignored.
3178 A C<*> for the repeat count of pack() means to use all the bytes of
3179 the input field.  On unpack()ing the bits are converted to a string
3180 of hexadecimal digits.
3181
3182 =item *
3183
3184 The C<p> type packs a pointer to a null-terminated string.  You are
3185 responsible for ensuring the string is not a temporary value (which can
3186 potentially get deallocated before you get around to using the packed result).
3187 The C<P> type packs a pointer to a structure of the size indicated by the
3188 length.  A NULL pointer is created if the corresponding value for C<p> or
3189 C<P> is C<undef>, similarly for unpack().
3190
3191 =item *
3192
3193 The C</> template character allows packing and unpacking of strings where
3194 the packed structure contains a byte count followed by the string itself.
3195 You write I<length-item>C</>I<string-item>.
3196
3197 The I<length-item> can be any C<pack> template letter,
3198 and describes how the length value is packed.
3199 The ones likely to be of most use are integer-packing ones like
3200 C<n> (for Java strings), C<w> (for ASN.1 or SNMP)
3201 and C<N> (for Sun XDR).
3202
3203 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3204 For C<unpack> the length of the string is obtained from the I<length-item>,
3205 but if you put in the '*' it will be ignored.
3206
3207     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3208     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3209     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3210
3211 The I<length-item> is not returned explicitly from C<unpack>.
3212
3213 Adding a count to the I<length-item> letter is unlikely to do anything
3214 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3215 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3216 which Perl does not regard as legal in numeric strings.
3217
3218 =item *
3219
3220 The integer types C<s>, C<S>, C<l>, and C<L> may be
3221 immediately followed by a C<!> suffix to signify native shorts or
3222 longs--as you can see from above for example a bare C<l> does mean
3223 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3224 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3225 see whether using C<!> makes any difference by
3226
3227         print length(pack("s")), " ", length(pack("s!")), "\n";
3228         print length(pack("l")), " ", length(pack("l!")), "\n";
3229
3230 C<i!> and C<I!> also work but only because of completeness;
3231 they are identical to C<i> and C<I>.
3232
3233 The actual sizes (in bytes) of native shorts, ints, longs, and long
3234 longs on the platform where Perl was built are also available via
3235 L<Config>:
3236
3237        use Config;
3238        print $Config{shortsize},    "\n";
3239        print $Config{intsize},      "\n";
3240        print $Config{longsize},     "\n";
3241        print $Config{longlongsize}, "\n";
3242
3243 (The C<$Config{longlongsize}> will be undefine if your system does
3244 not support long longs.)
3245
3246 =item *
3247
3248 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, and C<L>
3249 are inherently non-portable between processors and operating systems
3250 because they obey the native byteorder and endianness.  For example a
3251 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3252 (arranged in and handled by the CPU registers) into bytes as
3253
3254         0x12 0x34 0x56 0x78     # big-endian
3255         0x78 0x56 0x34 0x12     # little-endian
3256
3257 Basically, the Intel and VAX CPUs are little-endian, while everybody
3258 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3259 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3260 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3261 mode.
3262
3263 The names `big-endian' and `little-endian' are comic references to
3264 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3265 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3266 the egg-eating habits of the Lilliputians.
3267
3268 Some systems may have even weirder byte orders such as
3269
3270         0x56 0x78 0x12 0x34
3271         0x34 0x12 0x78 0x56
3272
3273 You can see your system's preference with
3274
3275         print join(" ", map { sprintf "%#02x", $_ }
3276                             unpack("C*",pack("L",0x12345678))), "\n";
3277
3278 The byteorder on the platform where Perl was built is also available
3279 via L<Config>:
3280
3281         use Config;
3282         print $Config{byteorder}, "\n";
3283
3284 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3285 and C<'87654321'> are big-endian.
3286
3287 If you want portable packed integers use the formats C<n>, C<N>,
3288 C<v>, and C<V>, their byte endianness and size are known.
3289 See also L<perlport>.
3290
3291 =item *
3292
3293 Real numbers (floats and doubles) are in the native machine format only;
3294 due to the multiplicity of floating formats around, and the lack of a
3295 standard "network" representation, no facility for interchange has been
3296 made.  This means that packed floating point data written on one machine
3297 may not be readable on another - even if both use IEEE floating point
3298 arithmetic (as the endian-ness of the memory representation is not part
3299 of the IEEE spec).  See also L<perlport>.
3300
3301 Note that Perl uses doubles internally for all numeric calculation, and
3302 converting from double into float and thence back to double again will
3303 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3304 equal $foo).
3305
3306 =item *
3307
3308 If the pattern begins with a C<U>, the resulting string will be treated
3309 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3310 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3311 characters. If you don't want this to happen, you can begin your pattern
3312 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3313 string, and then follow this with a C<U*> somewhere in your pattern.
3314
3315 =item *
3316
3317 You must yourself do any alignment or padding by inserting for example
3318 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3319 could know where the bytes are going to or coming from.  Therefore
3320 C<pack> (and C<unpack>) handle their output and input as flat
3321 sequences of bytes.
3322
3323 =item *
3324
3325 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3326
3327 =item *
3328
3329 If TEMPLATE requires more arguments to pack() than actually given, pack()
3330 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3331 to pack() than actually given, extra arguments are ignored.
3332
3333 =back
3334
3335 Examples:
3336
3337     $foo = pack("CCCC",65,66,67,68);
3338     # foo eq "ABCD"
3339     $foo = pack("C4",65,66,67,68);
3340     # same thing
3341     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3342     # same thing with Unicode circled letters
3343
3344     $foo = pack("ccxxcc",65,66,67,68);
3345     # foo eq "AB\0\0CD"
3346
3347     # note: the above examples featuring "C" and "c" are true
3348     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3349     # and UTF-8.  In EBCDIC the first example would be
3350     # $foo = pack("CCCC",193,194,195,196);
3351
3352     $foo = pack("s2",1,2);
3353     # "\1\0\2\0" on little-endian
3354     # "\0\1\0\2" on big-endian
3355
3356     $foo = pack("a4","abcd","x","y","z");
3357     # "abcd"
3358
3359     $foo = pack("aaaa","abcd","x","y","z");
3360     # "axyz"
3361
3362     $foo = pack("a14","abcdefg");
3363     # "abcdefg\0\0\0\0\0\0\0"
3364
3365     $foo = pack("i9pl", gmtime);
3366     # a real struct tm (on my system anyway)
3367
3368     $utmp_template = "Z8 Z8 Z16 L";
3369     $utmp = pack($utmp_template, @utmp1);
3370     # a struct utmp (BSDish)
3371
3372     @utmp2 = unpack($utmp_template, $utmp);
3373     # "@utmp1" eq "@utmp2"
3374
3375     sub bintodec {
3376         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3377     }
3378
3379     $foo = pack('sx2l', 12, 34);
3380     # short 12, two zero bytes padding, long 34
3381     $bar = pack('s@4l', 12, 34);
3382     # short 12, zero fill to position 4, long 34
3383     # $foo eq $bar
3384
3385 The same template may generally also be used in unpack().
3386
3387 =item package NAMESPACE
3388
3389 =item package
3390
3391 Declares the compilation unit as being in the given namespace.  The scope
3392 of the package declaration is from the declaration itself through the end
3393 of the enclosing block, file, or eval (the same as the C<my> operator).
3394 All further unqualified dynamic identifiers will be in this namespace.
3395 A package statement affects only dynamic variables--including those
3396 you've used C<local> on--but I<not> lexical variables, which are created
3397 with C<my>.  Typically it would be the first declaration in a file to
3398 be included by the C<require> or C<use> operator.  You can switch into a
3399 package in more than one place; it merely influences which symbol table
3400 is used by the compiler for the rest of that block.  You can refer to
3401 variables and filehandles in other packages by prefixing the identifier
3402 with the package name and a double colon:  C<$Package::Variable>.
3403 If the package name is null, the C<main> package as assumed.  That is,
3404 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3405 still seen in older code).
3406
3407 If NAMESPACE is omitted, then there is no current package, and all
3408 identifiers must be fully qualified or lexicals.  However, you are
3409 strongly advised not to make use of this feature. Its use can cause
3410 unexpected behaviour, even crashing some versions of Perl. It is
3411 deprecated, and will be removed from a future release.
3412
3413 See L<perlmod/"Packages"> for more information about packages, modules,
3414 and classes.  See L<perlsub> for other scoping issues.
3415
3416 =item pipe READHANDLE,WRITEHANDLE
3417
3418 Opens a pair of connected pipes like the corresponding system call.
3419 Note that if you set up a loop of piped processes, deadlock can occur
3420 unless you are very careful.  In addition, note that Perl's pipes use
3421 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3422 after each command, depending on the application.
3423
3424 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3425 for examples of such things.
3426
3427 On systems that support a close-on-exec flag on files, the flag will be set
3428 for the newly opened file descriptors as determined by the value of $^F.
3429 See L<perlvar/$^F>.
3430
3431 =item pop ARRAY
3432
3433 =item pop
3434
3435 Pops and returns the last value of the array, shortening the array by
3436 one element.  Has an effect similar to
3437
3438     $ARRAY[$#ARRAY--]
3439
3440 If there are no elements in the array, returns the undefined value
3441 (although this may happen at other times as well).  If ARRAY is
3442 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3443 array in subroutines, just like C<shift>.
3444
3445 =item pos SCALAR
3446
3447 =item pos
3448
3449 Returns the offset of where the last C<m//g> search left off for the variable
3450 in question (C<$_> is used when the variable is not specified).  May be
3451 modified to change that offset.  Such modification will also influence
3452 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3453 L<perlop>.
3454
3455 =item print FILEHANDLE LIST
3456
3457 =item print LIST
3458
3459 =item print
3460
3461 Prints a string or a list of strings.  Returns true if successful.
3462 FILEHANDLE may be a scalar variable name, in which case the variable
3463 contains the name of or a reference to the filehandle, thus introducing
3464 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3465 the next token is a term, it may be misinterpreted as an operator
3466 unless you interpose a C<+> or put parentheses around the arguments.)
3467 If FILEHANDLE is omitted, prints by default to standard output (or
3468 to the last selected output channel--see L</select>).  If LIST is
3469 also omitted, prints C<$_> to the currently selected output channel.
3470 To set the default output channel to something other than STDOUT
3471 use the select operation.  The current value of C<$,> (if any) is
3472 printed between each LIST item.  The current value of C<$\> (if
3473 any) is printed after the entire LIST has been printed.  Because
3474 print takes a LIST, anything in the LIST is evaluated in list
3475 context, and any subroutine that you call will have one or more of
3476 its expressions evaluated in list context.  Also be careful not to
3477 follow the print keyword with a left parenthesis unless you want
3478 the corresponding right parenthesis to terminate the arguments to
3479 the print--interpose a C<+> or put parentheses around all the
3480 arguments.
3481
3482 Note that if you're storing FILEHANDLES in an array or other expression,
3483 you will have to use a block returning its value instead:
3484
3485     print { $files[$i] } "stuff\n";
3486     print { $OK ? STDOUT : STDERR } "stuff\n";
3487
3488 =item printf FILEHANDLE FORMAT, LIST
3489
3490 =item printf FORMAT, LIST
3491
3492 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3493 (the output record separator) is not appended.  The first argument
3494 of the list will be interpreted as the C<printf> format. See C<sprintf>
3495 for an explanation of the format argument. If C<use locale> is in effect,
3496 the character used for the decimal point in formatted real numbers is
3497 affected by the LC_NUMERIC locale.  See L<perllocale>.
3498
3499 Don't fall into the trap of using a C<printf> when a simple
3500 C<print> would do.  The C<print> is more efficient and less
3501 error prone.
3502
3503 =item prototype FUNCTION
3504
3505 Returns the prototype of a function as a string (or C<undef> if the
3506 function has no prototype).  FUNCTION is a reference to, or the name of,
3507 the function whose prototype you want to retrieve.
3508
3509 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3510 name for Perl builtin.  If the builtin is not I<overridable> (such as
3511 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3512 C<system>) returns C<undef> because the builtin does not really behave
3513 like a Perl function.  Otherwise, the string describing the equivalent
3514 prototype is returned.
3515
3516 =item push ARRAY,LIST
3517
3518 Treats ARRAY as a stack, and pushes the values of LIST
3519 onto the end of ARRAY.  The length of ARRAY increases by the length of
3520 LIST.  Has the same effect as
3521
3522     for $value (LIST) {
3523         $ARRAY[++$#ARRAY] = $value;
3524     }
3525
3526 but is more efficient.  Returns the new number of elements in the array.
3527
3528 =item q/STRING/
3529
3530 =item qq/STRING/
3531
3532 =item qr/STRING/
3533
3534 =item qx/STRING/
3535
3536 =item qw/STRING/
3537
3538 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3539
3540 =item quotemeta EXPR
3541
3542 =item quotemeta
3543
3544 Returns the value of EXPR with all non-"word"
3545 characters backslashed.  (That is, all characters not matching
3546 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3547 returned string, regardless of any locale settings.)
3548 This is the internal function implementing
3549 the C<\Q> escape in double-quoted strings.
3550
3551 If EXPR is omitted, uses C<$_>.
3552
3553 =item rand EXPR
3554
3555 =item rand
3556
3557 Returns a random fractional number greater than or equal to C<0> and less
3558 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3559 omitted, or a C<0>, the value C<1> is used.  Automatically calls C<srand>
3560 unless C<srand> has already been called.  See also C<srand>.
3561
3562 Apply C<int()> to the value returned by C<rand()> if you want random
3563 integers instead of random fractional numbers.  For example,
3564
3565     int(rand(10))
3566
3567 returns a random integer between C<0> and C<9>, inclusive.
3568
3569 (Note: If your rand function consistently returns numbers that are too
3570 large or too small, then your version of Perl was probably compiled
3571 with the wrong number of RANDBITS.)
3572
3573 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3574
3575 =item read FILEHANDLE,SCALAR,LENGTH
3576
3577 Attempts to read LENGTH bytes of data into variable SCALAR from the
3578 specified FILEHANDLE.  Returns the number of bytes actually read, C<0>
3579 at end of file, or undef if there was an error.  SCALAR will be grown
3580 or shrunk to the length actually read.  If SCALAR needs growing, the
3581 new bytes will be zero bytes.  An OFFSET may be specified to place
3582 the read data into some other place in SCALAR than the beginning.
3583 The call is actually implemented in terms of stdio's fread(3) call.
3584 To get a true read(2) system call, see C<sysread>.
3585
3586 =item readdir DIRHANDLE
3587
3588 Returns the next directory entry for a directory opened by C<opendir>.
3589 If used in list context, returns all the rest of the entries in the
3590 directory.  If there are no more entries, returns an undefined value in
3591 scalar context or a null list in list context.
3592
3593 If you're planning to filetest the return values out of a C<readdir>, you'd
3594 better prepend the directory in question.  Otherwise, because we didn't
3595 C<chdir> there, it would have been testing the wrong file.
3596
3597     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3598     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3599     closedir DIR;
3600
3601 =item readline EXPR
3602
3603 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3604 context, each call reads and returns the next line, until end-of-file is
3605 reached, whereupon the subsequent call returns undef.  In list context,
3606 reads until end-of-file is reached and returns a list of lines.  Note that
3607 the notion of "line" used here is however you may have defined it
3608 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3609
3610 When C<$/> is set to C<undef>, when readline() is in scalar
3611 context (i.e. file slurp mode), and when an empty file is read, it
3612 returns C<''> the first time, followed by C<undef> subsequently.
3613
3614 This is the internal function implementing the C<< <EXPR> >>
3615 operator, but you can use it directly.  The C<< <EXPR> >>
3616 operator is discussed in more detail in L<perlop/"I/O Operators">.
3617
3618     $line = <STDIN>;
3619     $line = readline(*STDIN);           # same thing
3620
3621 =item readlink EXPR
3622
3623 =item readlink
3624
3625 Returns the value of a symbolic link, if symbolic links are
3626 implemented.  If not, gives a fatal error.  If there is some system
3627 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3628 omitted, uses C<$_>.
3629
3630 =item readpipe EXPR
3631
3632 EXPR is executed as a system command.
3633 The collected standard output of the command is returned.
3634 In scalar context, it comes back as a single (potentially
3635 multi-line) string.  In list context, returns a list of lines
3636 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3637 This is the internal function implementing the C<qx/EXPR/>
3638 operator, but you can use it directly.  The C<qx/EXPR/>
3639 operator is discussed in more detail in L<perlop/"I/O Operators">.
3640
3641 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3642
3643 Receives a message on a socket.  Attempts to receive LENGTH bytes of
3644 data into variable SCALAR from the specified SOCKET filehandle.  SCALAR
3645 will be grown or shrunk to the length actually read.  Takes the same
3646 flags as the system call of the same name.  Returns the address of the
3647 sender if SOCKET's protocol supports this; returns an empty string
3648 otherwise.  If there's an error, returns the undefined value.  This call
3649 is actually implemented in terms of recvfrom(2) system call.  See
3650 L<perlipc/"UDP: Message Passing"> for examples.
3651
3652 =item redo LABEL
3653
3654 =item redo
3655
3656 The C<redo> command restarts the loop block without evaluating the
3657 conditional again.  The C<continue> block, if any, is not executed.  If
3658 the LABEL is omitted, the command refers to the innermost enclosing
3659 loop.  This command is normally used by programs that want to lie to
3660 themselves about what was just input:
3661
3662     # a simpleminded Pascal comment stripper
3663     # (warning: assumes no { or } in strings)
3664     LINE: while (<STDIN>) {
3665         while (s|({.*}.*){.*}|$1 |) {}
3666         s|{.*}| |;
3667         if (s|{.*| |) {
3668             $front = $_;
3669             while (<STDIN>) {
3670                 if (/}/) {      # end of comment?
3671                     s|^|$front\{|;
3672                     redo LINE;
3673                 }
3674             }
3675         }
3676         print;
3677     }
3678
3679 C<redo> cannot be used to retry a block which returns a value such as
3680 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3681 a grep() or map() operation.
3682
3683 Note that a block by itself is semantically identical to a loop
3684 that executes once.  Thus C<redo> inside such a block will effectively
3685 turn it into a looping construct.
3686
3687 See also L</continue> for an illustration of how C<last>, C<next>, and
3688 C<redo> work.
3689
3690 =item ref EXPR
3691
3692 =item ref
3693
3694 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3695 is not specified, C<$_> will be used.  The value returned depends on the
3696 type of thing the reference is a reference to.
3697 Builtin types include:
3698
3699     SCALAR
3700     ARRAY
3701     HASH
3702     CODE
3703     REF
3704     GLOB
3705     LVALUE
3706
3707 If the referenced object has been blessed into a package, then that package
3708 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3709
3710     if (ref($r) eq "HASH") {
3711         print "r is a reference to a hash.\n";
3712     }
3713     unless (ref($r)) {
3714         print "r is not a reference at all.\n";
3715     }
3716     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3717         print "r is a reference to something that isa hash.\n";
3718     }
3719
3720 See also L<perlref>.
3721
3722 =item rename OLDNAME,NEWNAME
3723
3724 Changes the name of a file; an existing file NEWNAME will be
3725 clobbered.  Returns true for success, false otherwise.
3726
3727 Behavior of this function varies wildly depending on your system
3728 implementation.  For example, it will usually not work across file system
3729 boundaries, even though the system I<mv> command sometimes compensates
3730 for this.  Other restrictions include whether it works on directories,
3731 open files, or pre-existing files.  Check L<perlport> and either the
3732 rename(2) manpage or equivalent system documentation for details.
3733
3734 =item require VERSION
3735
3736 =item require EXPR
3737
3738 =item require
3739
3740 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
3741 supplied.
3742
3743 If a VERSION is specified as a literal of the form v5.6.1,
3744 demands that the current version of Perl (C<$^V> or $PERL_VERSION) be
3745 at least as recent as that version, at run time.  (For compatibility
3746 with older versions of Perl, a numeric argument will also be interpreted
3747 as VERSION.)  Compare with L</use>, which can do a similar check at
3748 compile time.
3749
3750     require v5.6.1;     # run time version check
3751     require 5.6.1;      # ditto
3752     require 5.005_03;   # float version allowed for compatibility
3753
3754 Otherwise, demands that a library file be included if it hasn't already
3755 been included.  The file is included via the do-FILE mechanism, which is
3756 essentially just a variety of C<eval>.  Has semantics similar to the following
3757 subroutine:
3758
3759     sub require {
3760         my($filename) = @_;
3761         return 1 if $INC{$filename};
3762         my($realfilename,$result);
3763         ITER: {
3764             foreach $prefix (@INC) {
3765                 $realfilename = "$prefix/$filename";
3766                 if (-f $realfilename) {
3767                     $INC{$filename} = $realfilename;
3768                     $result = do $realfilename;
3769                     last ITER;
3770                 }
3771             }
3772             die "Can't find $filename in \@INC";
3773         }
3774         delete $INC{$filename} if $@ || !$result;
3775         die $@ if $@;
3776         die "$filename did not return true value" unless $result;
3777         return $result;
3778     }
3779
3780 Note that the file will not be included twice under the same specified
3781 name.  The file must return true as the last statement to indicate
3782 successful execution of any initialization code, so it's customary to
3783 end such a file with C<1;> unless you're sure it'll return true
3784 otherwise.  But it's better just to put the C<1;>, in case you add more
3785 statements.
3786
3787 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3788 replaces "F<::>" with "F</>" in the filename for you,
3789 to make it easy to load standard modules.  This form of loading of
3790 modules does not risk altering your namespace.
3791
3792 In other words, if you try this:
3793
3794         require Foo::Bar;    # a splendid bareword
3795
3796 The require function will actually look for the "F<Foo/Bar.pm>" file in the
3797 directories specified in the C<@INC> array.
3798
3799 But if you try this:
3800
3801         $class = 'Foo::Bar';
3802         require $class;      # $class is not a bareword
3803     #or
3804         require "Foo::Bar";  # not a bareword because of the ""
3805
3806 The require function will look for the "F<Foo::Bar>" file in the @INC array and
3807 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3808
3809         eval "require $class";
3810
3811 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
3812
3813 =item reset EXPR
3814
3815 =item reset
3816
3817 Generally used in a C<continue> block at the end of a loop to clear
3818 variables and reset C<??> searches so that they work again.  The
3819 expression is interpreted as a list of single characters (hyphens
3820 allowed for ranges).  All variables and arrays beginning with one of
3821 those letters are reset to their pristine state.  If the expression is
3822 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
3823 only variables or searches in the current package.  Always returns
3824 1.  Examples:
3825
3826     reset 'X';          # reset all X variables
3827     reset 'a-z';        # reset lower case variables
3828     reset;              # just reset ?one-time? searches
3829
3830 Resetting C<"A-Z"> is not recommended because you'll wipe out your
3831 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
3832 variables--lexical variables are unaffected, but they clean themselves
3833 up on scope exit anyway, so you'll probably want to use them instead.
3834 See L</my>.
3835
3836 =item return EXPR
3837
3838 =item return
3839
3840 Returns from a subroutine, C<eval>, or C<do FILE> with the value
3841 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
3842 context, depending on how the return value will be used, and the context
3843 may vary from one execution to the next (see C<wantarray>).  If no EXPR
3844 is given, returns an empty list in list context, the undefined value in
3845 scalar context, and (of course) nothing at all in a void context.
3846
3847 (Note that in the absence of a explicit C<return>, a subroutine, eval,
3848 or do FILE will automatically return the value of the last expression
3849 evaluated.)
3850
3851 =item reverse LIST
3852
3853 In list context, returns a list value consisting of the elements
3854 of LIST in the opposite order.  In scalar context, concatenates the
3855 elements of LIST and returns a string value with all characters
3856 in the opposite order.
3857
3858     print reverse <>;           # line tac, last line first
3859
3860     undef $/;                   # for efficiency of <>
3861     print scalar reverse <>;    # character tac, last line tsrif
3862
3863 This operator is also handy for inverting a hash, although there are some
3864 caveats.  If a value is duplicated in the original hash, only one of those
3865 can be represented as a key in the inverted hash.  Also, this has to
3866 unwind one hash and build a whole new one, which may take some time
3867 on a large hash, such as from a DBM file.
3868
3869     %by_name = reverse %by_address;     # Invert the hash
3870
3871 =item rewinddir DIRHANDLE
3872
3873 Sets the current position to the beginning of the directory for the
3874 C<readdir> routine on DIRHANDLE.
3875
3876 =item rindex STR,SUBSTR,POSITION
3877
3878 =item rindex STR,SUBSTR
3879
3880 Works just like index() except that it returns the position of the LAST
3881 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
3882 last occurrence at or before that position.
3883
3884 =item rmdir FILENAME
3885
3886 =item rmdir
3887
3888 Deletes the directory specified by FILENAME if that directory is empty.  If it
3889 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
3890 FILENAME is omitted, uses C<$_>.
3891
3892 =item s///
3893
3894 The substitution operator.  See L<perlop>.
3895
3896 =item scalar EXPR
3897
3898 Forces EXPR to be interpreted in scalar context and returns the value
3899 of EXPR.
3900
3901     @counts = ( scalar @a, scalar @b, scalar @c );
3902
3903 There is no equivalent operator to force an expression to
3904 be interpolated in list context because in practice, this is never
3905 needed.  If you really wanted to do so, however, you could use
3906 the construction C<@{[ (some expression) ]}>, but usually a simple
3907 C<(some expression)> suffices.
3908
3909 Because C<scalar> is unary operator, if you accidentally use for EXPR a
3910 parenthesized list, this behaves as a scalar comma expression, evaluating
3911 all but the last element in void context and returning the final element
3912 evaluated in scalar context.  This is seldom what you want.
3913
3914 The following single statement:
3915
3916         print uc(scalar(&foo,$bar)),$baz;
3917
3918 is the moral equivalent of these two:
3919
3920         &foo;
3921         print(uc($bar),$baz);
3922
3923 See L<perlop> for more details on unary operators and the comma operator.
3924
3925 =item seek FILEHANDLE,POSITION,WHENCE
3926
3927 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
3928 FILEHANDLE may be an expression whose value gives the name of the
3929 filehandle.  The values for WHENCE are C<0> to set the new position to
3930 POSITION, C<1> to set it to the current position plus POSITION, and
3931 C<2> to set it to EOF plus POSITION (typically negative).  For WHENCE
3932 you may use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END>
3933 (start of the file, current position, end of the file) from the Fcntl
3934 module.  Returns C<1> upon success, C<0> otherwise.
3935
3936 If you want to position file for C<sysread> or C<syswrite>, don't use
3937 C<seek>--buffering makes its effect on the file's system position
3938 unpredictable and non-portable.  Use C<sysseek> instead.
3939
3940 Due to the rules and rigors of ANSI C, on some systems you have to do a
3941 seek whenever you switch between reading and writing.  Amongst other
3942 things, this may have the effect of calling stdio's clearerr(3).
3943 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
3944
3945     seek(TEST,0,1);
3946
3947 This is also useful for applications emulating C<tail -f>.  Once you hit
3948 EOF on your read, and then sleep for a while, you might have to stick in a
3949 seek() to reset things.  The C<seek> doesn't change the current position,
3950 but it I<does> clear the end-of-file condition on the handle, so that the
3951 next C<< <FILE> >> makes Perl try again to read something.  We hope.
3952
3953 If that doesn't work (some stdios are particularly cantankerous), then
3954 you may need something more like this:
3955
3956     for (;;) {
3957         for ($curpos = tell(FILE); $_ = <FILE>;
3958              $curpos = tell(FILE)) {
3959             # search for some stuff and put it into files
3960         }
3961         sleep($for_a_while);
3962         seek(FILE, $curpos, 0);
3963     }
3964
3965 =item seekdir DIRHANDLE,POS
3966
3967 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
3968 must be a value returned by C<telldir>.  Has the same caveats about
3969 possible directory compaction as the corresponding system library
3970 routine.
3971
3972 =item select FILEHANDLE
3973
3974 =item select
3975
3976 Returns the currently selected filehandle.  Sets the current default
3977 filehandle for output, if FILEHANDLE is supplied.  This has two
3978 effects: first, a C<write> or a C<print> without a filehandle will
3979 default to this FILEHANDLE.  Second, references to variables related to
3980 output will refer to this output channel.  For example, if you have to
3981 set the top of form format for more than one output channel, you might
3982 do the following:
3983
3984     select(REPORT1);
3985     $^ = 'report1_top';
3986     select(REPORT2);
3987     $^ = 'report2_top';
3988
3989 FILEHANDLE may be an expression whose value gives the name of the
3990 actual filehandle.  Thus:
3991
3992     $oldfh = select(STDERR); $| = 1; select($oldfh);
3993
3994 Some programmers may prefer to think of filehandles as objects with
3995 methods, preferring to write the last example as:
3996
3997     use IO::Handle;
3998     STDERR->autoflush(1);
3999
4000 =item select RBITS,WBITS,EBITS,TIMEOUT
4001
4002 This calls the select(2) system call with the bit masks specified, which
4003 can be constructed using C<fileno> and C<vec>, along these lines:
4004
4005     $rin = $win = $ein = '';
4006     vec($rin,fileno(STDIN),1) = 1;
4007     vec($win,fileno(STDOUT),1) = 1;
4008     $ein = $rin | $win;
4009
4010 If you want to select on many filehandles you might wish to write a
4011 subroutine:
4012
4013     sub fhbits {
4014         my(@fhlist) = split(' ',$_[0]);
4015         my($bits);
4016         for (@fhlist) {
4017             vec($bits,fileno($_),1) = 1;
4018         }
4019         $bits;
4020     }
4021     $rin = fhbits('STDIN TTY SOCK');
4022
4023 The usual idiom is:
4024
4025     ($nfound,$timeleft) =
4026       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4027
4028 or to block until something becomes ready just do this
4029
4030     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4031
4032 Most systems do not bother to return anything useful in $timeleft, so
4033 calling select() in scalar context just returns $nfound.
4034
4035 Any of the bit masks can also be undef.  The timeout, if specified, is
4036 in seconds, which may be fractional.  Note: not all implementations are
4037 capable of returning the$timeleft.  If not, they always return
4038 $timeleft equal to the supplied $timeout.
4039
4040 You can effect a sleep of 250 milliseconds this way:
4041
4042     select(undef, undef, undef, 0.25);
4043
4044 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4045 or <FH>) with C<select>, except as permitted by POSIX, and even
4046 then only on POSIX systems.  You have to use C<sysread> instead.
4047
4048 =item semctl ID,SEMNUM,CMD,ARG
4049
4050 Calls the System V IPC function C<semctl>.  You'll probably have to say
4051
4052     use IPC::SysV;
4053
4054 first to get the correct constant definitions.  If CMD is IPC_STAT or
4055 GETALL, then ARG must be a variable which will hold the returned
4056 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4057 the undefined value for error, "C<0 but true>" for zero, or the actual
4058 return value otherwise.  The ARG must consist of a vector of native
4059 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4060 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4061 documentation.
4062
4063 =item semget KEY,NSEMS,FLAGS
4064
4065 Calls the System V IPC function semget.  Returns the semaphore id, or
4066 the undefined value if there is an error.  See also
4067 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4068 documentation.
4069
4070 =item semop KEY,OPSTRING
4071
4072 Calls the System V IPC function semop to perform semaphore operations
4073 such as signalling and waiting.  OPSTRING must be a packed array of
4074 semop structures.  Each semop structure can be generated with
4075 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4076 operations is implied by the length of OPSTRING.  Returns true if
4077 successful, or false if there is an error.  As an example, the
4078 following code waits on semaphore $semnum of semaphore id $semid:
4079
4080     $semop = pack("s!3", $semnum, -1, 0);
4081     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4082
4083 To signal the semaphore, replace C<-1> with C<1>.  See also
4084 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4085 documentation.
4086
4087 =item send SOCKET,MSG,FLAGS,TO
4088
4089 =item send SOCKET,MSG,FLAGS
4090
4091 Sends a message on a socket.  Takes the same flags as the system call
4092 of the same name.  On unconnected sockets you must specify a
4093 destination to send TO, in which case it does a C C<sendto>.  Returns
4094 the number of characters sent, or the undefined value if there is an
4095 error.  The C system call sendmsg(2) is currently unimplemented.
4096 See L<perlipc/"UDP: Message Passing"> for examples.
4097
4098 =item setpgrp PID,PGRP
4099
4100 Sets the current process group for the specified PID, C<0> for the current
4101 process.  Will produce a fatal error if used on a machine that doesn't
4102 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4103 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4104 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4105 C<POSIX::setsid()>.
4106
4107 =item setpriority WHICH,WHO,PRIORITY
4108
4109 Sets the current priority for a process, a process group, or a user.
4110 (See setpriority(2).)  Will produce a fatal error if used on a machine
4111 that doesn't implement setpriority(2).
4112
4113 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4114
4115 Sets the socket option requested.  Returns undefined if there is an
4116 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4117 argument.
4118
4119 =item shift ARRAY
4120
4121 =item shift
4122
4123 Shifts the first value of the array off and returns it, shortening the
4124 array by 1 and moving everything down.  If there are no elements in the
4125 array, returns the undefined value.  If ARRAY is omitted, shifts the
4126 C<@_> array within the lexical scope of subroutines and formats, and the
4127 C<@ARGV> array at file scopes or within the lexical scopes established by
4128 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4129 constructs.
4130
4131 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4132 same thing to the left end of an array that C<pop> and C<push> do to the
4133 right end.
4134
4135 =item shmctl ID,CMD,ARG
4136
4137 Calls the System V IPC function shmctl.  You'll probably have to say
4138
4139     use IPC::SysV;
4140
4141 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4142 then ARG must be a variable which will hold the returned C<shmid_ds>
4143 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4144 true" for zero, or the actual return value otherwise.
4145 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4146
4147 =item shmget KEY,SIZE,FLAGS
4148
4149 Calls the System V IPC function shmget.  Returns the shared memory
4150 segment id, or the undefined value if there is an error.
4151 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4152
4153 =item shmread ID,VAR,POS,SIZE
4154
4155 =item shmwrite ID,STRING,POS,SIZE
4156
4157 Reads or writes the System V shared memory segment ID starting at
4158 position POS for size SIZE by attaching to it, copying in/out, and
4159 detaching from it.  When reading, VAR must be a variable that will
4160 hold the data read.  When writing, if STRING is too long, only SIZE
4161 bytes are used; if STRING is too short, nulls are written to fill out
4162 SIZE bytes.  Return true if successful, or false if there is an error.
4163 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4164 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4165
4166 =item shutdown SOCKET,HOW
4167
4168 Shuts down a socket connection in the manner indicated by HOW, which
4169 has the same interpretation as in the system call of the same name.
4170
4171     shutdown(SOCKET, 0);    # I/we have stopped reading data
4172     shutdown(SOCKET, 1);    # I/we have stopped writing data
4173     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4174
4175 This is useful with sockets when you want to tell the other
4176 side you're done writing but not done reading, or vice versa.
4177 It's also a more insistent form of close because it also
4178 disables the file descriptor in any forked copies in other
4179 processes.
4180
4181 =item sin EXPR
4182
4183 =item sin
4184
4185 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4186 returns sine of C<$_>.
4187
4188 For the inverse sine operation, you may use the C<Math::Trig::asin>
4189 function, or use this relation:
4190
4191     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4192
4193 =item sleep EXPR
4194
4195 =item sleep
4196
4197 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4198 May be interrupted if the process receives a signal such as C<SIGALRM>.
4199 Returns the number of seconds actually slept.  You probably cannot
4200 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4201 using C<alarm>.
4202
4203 On some older systems, it may sleep up to a full second less than what
4204 you requested, depending on how it counts seconds.  Most modern systems
4205 always sleep the full amount.  They may appear to sleep longer than that,
4206 however, because your process might not be scheduled right away in a
4207 busy multitasking system.
4208
4209 For delays of finer granularity than one second, you may use Perl's
4210 C<syscall> interface to access setitimer(2) if your system supports
4211 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4212 and starting from Perl 5.8 part of the standard distribution) may also
4213 help.
4214
4215 See also the POSIX module's C<pause> function.
4216
4217 =item sockatmark SOCKET
4218
4219 Returns true if the socket is positioned at the out-of-band mark
4220 (also known as the urgent data mark), false otherwise.  Use right
4221 after reading from the socket.
4222
4223 Not available directly, one has to import the function from
4224 the IO::Socket extension
4225
4226     use IO::Socket 'sockatmark';
4227
4228 Even this doesn't guarantee that sockatmark() really is available,
4229 though, because sockatmark() is a relatively recent addition to
4230 the family of socket functions.  If it is unavailable, attempt to
4231 use it will fail
4232
4233         IO::Socket::atmark not implemented on this architecture ...
4234
4235 See also L<IO::Socket>.
4236
4237 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4238
4239 Opens a socket of the specified kind and attaches it to filehandle
4240 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4241 the system call of the same name.  You should C<use Socket> first
4242 to get the proper definitions imported.  See the examples in
4243 L<perlipc/"Sockets: Client/Server Communication">.
4244
4245 On systems that support a close-on-exec flag on files, the flag will
4246 be set for the newly opened file descriptor, as determined by the
4247 value of $^F.  See L<perlvar/$^F>.
4248
4249 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4250
4251 Creates an unnamed pair of sockets in the specified domain, of the
4252 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4253 for the system call of the same name.  If unimplemented, yields a fatal
4254 error.  Returns true if successful.
4255
4256 On systems that support a close-on-exec flag on files, the flag will
4257 be set for the newly opened file descriptors, as determined by the value
4258 of $^F.  See L<perlvar/$^F>.
4259
4260 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4261 to C<pipe(Rdr, Wtr)> is essentially:
4262
4263     use Socket;
4264     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4265     shutdown(Rdr, 1);        # no more writing for reader
4266     shutdown(Wtr, 0);        # no more reading for writer
4267
4268 See L<perlipc> for an example of socketpair use.
4269
4270 =item sort SUBNAME LIST
4271
4272 =item sort BLOCK LIST
4273
4274 =item sort LIST
4275
4276 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4277 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4278 specified, it gives the name of a subroutine that returns an integer
4279 less than, equal to, or greater than C<0>, depending on how the elements
4280 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4281 operators are extremely useful in such routines.)  SUBNAME may be a
4282 scalar variable name (unsubscripted), in which case the value provides
4283 the name of (or a reference to) the actual subroutine to use.  In place
4284 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4285 subroutine.
4286
4287 If the subroutine's prototype is C<($$)>, the elements to be compared
4288 are passed by reference in C<@_>, as for a normal subroutine.  This is
4289 slower than unprototyped subroutines, where the elements to be
4290 compared are passed into the subroutine
4291 as the package global variables $a and $b (see example below).  Note that
4292 in the latter case, it is usually counter-productive to declare $a and
4293 $b as lexicals.
4294
4295 In either case, the subroutine may not be recursive.  The values to be
4296 compared are always passed by reference, so don't modify them.
4297
4298 You also cannot exit out of the sort block or subroutine using any of the
4299 loop control operators described in L<perlsyn> or with C<goto>.
4300
4301 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4302 current collation locale.  See L<perllocale>.
4303
4304 Perl does B<not> guarantee that sort is stable.  (A I<stable> sort
4305 preserves the input order of elements that compare equal.)  5.7 and
4306 5.8 happen to use a stable mergesort, but 5.6 and earlier used quicksort,
4307 which is not stable.  Do not assume that future perls will continue to
4308 use a stable sort.
4309
4310 Examples:
4311
4312     # sort lexically
4313     @articles = sort @files;
4314
4315     # same thing, but with explicit sort routine
4316     @articles = sort {$a cmp $b} @files;
4317
4318     # now case-insensitively
4319     @articles = sort {uc($a) cmp uc($b)} @files;
4320
4321     # same thing in reversed order
4322     @articles = sort {$b cmp $a} @files;
4323
4324     # sort numerically ascending
4325     @articles = sort {$a <=> $b} @files;
4326
4327     # sort numerically descending
4328     @articles = sort {$b <=> $a} @files;
4329
4330     # this sorts the %age hash by value instead of key
4331     # using an in-line function
4332     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4333
4334     # sort using explicit subroutine name
4335     sub byage {
4336         $age{$a} <=> $age{$b};  # presuming numeric
4337     }
4338     @sortedclass = sort byage @class;
4339
4340     sub backwards { $b cmp $a }
4341     @harry  = qw(dog cat x Cain Abel);
4342     @george = qw(gone chased yz Punished Axed);
4343     print sort @harry;
4344             # prints AbelCaincatdogx
4345     print sort backwards @harry;
4346             # prints xdogcatCainAbel
4347     print sort @george, 'to', @harry;
4348             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4349
4350     # inefficiently sort by descending numeric compare using
4351     # the first integer after the first = sign, or the
4352     # whole record case-insensitively otherwise
4353
4354     @new = sort {
4355         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4356                             ||
4357                     uc($a)  cmp  uc($b)
4358     } @old;
4359
4360     # same thing, but much more efficiently;
4361     # we'll build auxiliary indices instead
4362     # for speed
4363     @nums = @caps = ();
4364     for (@old) {
4365         push @nums, /=(\d+)/;
4366         push @caps, uc($_);
4367     }
4368
4369     @new = @old[ sort {
4370                         $nums[$b] <=> $nums[$a]
4371                                  ||
4372                         $caps[$a] cmp $caps[$b]
4373                        } 0..$#old
4374                ];
4375
4376     # same thing, but without any temps
4377     @new = map { $_->[0] }
4378            sort { $b->[1] <=> $a->[1]
4379                            ||
4380                   $a->[2] cmp $b->[2]
4381            } map { [$_, /=(\d+)/, uc($_)] } @old;
4382
4383     # using a prototype allows you to use any comparison subroutine
4384     # as a sort subroutine (including other package's subroutines)
4385     package other;
4386     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4387
4388     package main;
4389     @new = sort other::backwards @old;
4390
4391 If you're using strict, you I<must not> declare $a
4392 and $b as lexicals.  They are package globals.  That means
4393 if you're in the C<main> package and type
4394
4395     @articles = sort {$b <=> $a} @files;
4396
4397 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4398 but if you're in the C<FooPack> package, it's the same as typing
4399
4400     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4401
4402 The comparison function is required to behave.  If it returns
4403 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4404 sometimes saying the opposite, for example) the results are not
4405 well-defined.
4406
4407 =item splice ARRAY,OFFSET,LENGTH,LIST
4408
4409 =item splice ARRAY,OFFSET,LENGTH
4410
4411 =item splice ARRAY,OFFSET
4412
4413 =item splice ARRAY
4414
4415 Removes the elements designated by OFFSET and LENGTH from an array, and
4416 replaces them with the elements of LIST, if any.  In list context,
4417 returns the elements removed from the array.  In scalar context,
4418 returns the last element removed, or C<undef> if no elements are
4419 removed.  The array grows or shrinks as necessary.
4420 If OFFSET is negative then it starts that far from the end of the array.
4421 If LENGTH is omitted, removes everything from OFFSET onward.
4422 If LENGTH is negative, leaves that many elements off the end of the array.
4423 If both OFFSET and LENGTH are omitted, removes everything.
4424
4425 The following equivalences hold (assuming C<$[ == 0>):
4426
4427     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
4428     pop(@a)             splice(@a,-1)
4429     shift(@a)           splice(@a,0,1)
4430     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
4431     $a[$x] = $y         splice(@a,$x,1,$y)
4432
4433 Example, assuming array lengths are passed before arrays:
4434
4435     sub aeq {   # compare two list values
4436         my(@a) = splice(@_,0,shift);
4437         my(@b) = splice(@_,0,shift);
4438         return 0 unless @a == @b;       # same len?
4439         while (@a) {
4440             return 0 if pop(@a) ne pop(@b);
4441         }
4442         return 1;
4443     }
4444     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
4445
4446 =item split /PATTERN/,EXPR,LIMIT
4447
4448 =item split /PATTERN/,EXPR
4449
4450 =item split /PATTERN/
4451
4452 =item split
4453
4454 Splits a string into a list of strings and returns that list.  By default,
4455 empty leading fields are preserved, and empty trailing ones are deleted.
4456
4457 In scalar context, returns the number of fields found and splits into
4458 the C<@_> array.  Use of split in scalar context is deprecated, however,
4459 because it clobbers your subroutine arguments.
4460
4461 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
4462 splits on whitespace (after skipping any leading whitespace).  Anything
4463 matching PATTERN is taken to be a delimiter separating the fields.  (Note
4464 that the delimiter may be longer than one character.)
4465
4466 If LIMIT is specified and positive, it represents the maximum number
4467 of fields the EXPR will be split into, though the actual number of
4468 fields returned depends on the number of times PATTERN matches within
4469 EXPR.  If LIMIT is unspecified or zero, trailing null fields are
4470 stripped (which potential users of C<pop> would do well to remember).
4471 If LIMIT is negative, it is treated as if an arbitrarily large LIMIT
4472 had been specified.  Note that splitting an EXPR that evaluates to the
4473 empty string always returns the empty list, regardless of the LIMIT
4474 specified.
4475
4476 A pattern matching the null string (not to be confused with
4477 a null pattern C<//>, which is just one member of the set of patterns
4478 matching a null string) will split the value of EXPR into separate
4479 characters at each point it matches that way.  For example:
4480
4481     print join(':', split(/ */, 'hi there'));
4482
4483 produces the output 'h:i:t:h:e:r:e'.
4484
4485 Using the empty pattern C<//> specifically matches the null string, and is
4486 not be confused with the use of C<//> to mean "the last successful pattern
4487 match".
4488
4489 Empty leading (or trailing) fields are produced when there positive width
4490 matches at the beginning (or end) of the string; a zero-width match at the
4491 beginning (or end) of the string does not produce an empty field.  For
4492 example:
4493
4494    print join(':', split(/(?=\w)/, 'hi there!'));
4495
4496 produces the output 'h:i :t:h:e:r:e!'.
4497
4498 The LIMIT parameter can be used to split a line partially
4499
4500     ($login, $passwd, $remainder) = split(/:/, $_, 3);
4501
4502 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
4503 one larger than the number of variables in the list, to avoid
4504 unnecessary work.  For the list above LIMIT would have been 4 by
4505 default.  In time critical applications it behooves you not to split
4506 into more fields than you really need.
4507
4508 If the PATTERN contains parentheses, additional list elements are
4509 created from each matching substring in the delimiter.
4510
4511     split(/([,-])/, "1-10,20", 3);
4512
4513 produces the list value
4514
4515     (1, '-', 10, ',', 20)
4516
4517 If you had the entire header of a normal Unix email message in $header,
4518 you could split it up into fields and their values this way:
4519
4520     $header =~ s/\n\s+/ /g;  # fix continuation lines
4521     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
4522
4523 The pattern C</PATTERN/> may be replaced with an expression to specify
4524 patterns that vary at runtime.  (To do runtime compilation only once,
4525 use C</$variable/o>.)
4526
4527 As a special case, specifying a PATTERN of space (C<' '>) will split on
4528 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
4529 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
4530 will give you as many null initial fields as there are leading spaces.
4531 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
4532 whitespace produces a null first field.  A C<split> with no arguments
4533 really does a C<split(' ', $_)> internally.
4534
4535 A PATTERN of C</^/> is treated as if it were C</^/m>, since it isn't
4536 much use otherwise.
4537
4538 Example:
4539
4540     open(PASSWD, '/etc/passwd');
4541     while (<PASSWD>) {
4542         chomp;
4543         ($login, $passwd, $uid, $gid,
4544          $gcos, $home, $shell) = split(/:/);
4545         #...
4546     }
4547
4548 As with regular pattern matching, any capturing parentheses that are not
4549 matched in a C<split()> will be set to C<undef> when returned:
4550
4551     @fields = split /(A)|B/, "1A2B3";
4552     # @fields is (1, 'A', 2, undef, 3)
4553
4554 =item sprintf FORMAT, LIST
4555
4556 Returns a string formatted by the usual C<printf> conventions of the C
4557 library function C<sprintf>.  See below for more details
4558 and see L<sprintf(3)> or L<printf(3)> on your system for an explanation of
4559 the general principles.
4560
4561 For example:
4562
4563         # Format number with up to 8 leading zeroes
4564         $result = sprintf("%08d", $number);
4565
4566         # Round number to 3 digits after decimal point
4567         $rounded = sprintf("%.3f", $number);
4568
4569 Perl does its own C<sprintf> formatting--it emulates the C
4570 function C<sprintf>, but it doesn't use it (except for floating-point
4571 numbers, and even then only the standard modifiers are allowed).  As a
4572 result, any non-standard extensions in your local C<sprintf> are not
4573 available from Perl.
4574
4575 Unlike C<printf>, C<sprintf> does not do what you probably mean when you
4576 pass it an array as your first argument. The array is given scalar context,
4577 and instead of using the 0th element of the array as the format, Perl will
4578 use the count of elements in the array as the format, which is almost never
4579 useful.
4580
4581 Perl's C<sprintf> permits the following universally-known conversions:
4582
4583    %%   a percent sign
4584    %c   a character with the given number
4585    %s   a string
4586    %d   a signed integer, in decimal
4587    %u   an unsigned integer, in decimal
4588    %o   an unsigned integer, in octal
4589    %x   an unsigned integer, in hexadecimal
4590    %e   a floating-point number, in scientific notation
4591    %f   a floating-point number, in fixed decimal notation
4592    %g   a floating-point number, in %e or %f notation
4593
4594 In addition, Perl permits the following widely-supported conversions:
4595
4596    %X   like %x, but using upper-case letters
4597    %E   like %e, but using an upper-case "E"
4598    %G   like %g, but with an upper-case "E" (if applicable)
4599    %b   an unsigned integer, in binary
4600    %p   a pointer (outputs the Perl value's address in hexadecimal)
4601    %n   special: *stores* the number of characters output so far
4602         into the next variable in the parameter list
4603
4604 Finally, for backward (and we do mean "backward") compatibility, Perl
4605 permits these unnecessary but widely-supported conversions:
4606
4607    %i   a synonym for %d
4608    %D   a synonym for %ld
4609    %U   a synonym for %lu
4610    %O   a synonym for %lo
4611    %F   a synonym for %f
4612
4613 Note that the number of exponent digits in the scientific notation by
4614 C<%e>, C<%E>, C<%g> and C<%G> for numbers with the modulus of the
4615 exponent less than 100 is system-dependent: it may be three or less
4616 (zero-padded as necessary).  In other words, 1.23 times ten to the
4617 99th may be either "1.23e99" or "1.23e099".
4618
4619 Perl permits the following universally-known flags between the C<%>
4620 and the conversion letter:
4621
4622    space   prefix positive number with a space
4623    +       prefix positive number with a plus sign
4624    -       left-justify within the field
4625    0       use zeros, not spaces, to right-justify
4626    #       prefix non-zero octal with "0", non-zero hex with "0x"
4627    number  minimum field width
4628    .number "precision": digits after decimal point for
4629            floating-point, max length for string, minimum length
4630            for integer
4631    l       interpret integer as C type "long" or "unsigned long"
4632    h       interpret integer as C type "short" or "unsigned short"
4633            If no flags, interpret integer as C type "int" or "unsigned"
4634
4635 Perl supports parameter ordering, in other words, fetching the
4636 parameters in some explicitly specified "random" ordering as opposed
4637 to the default implicit sequential ordering.  The syntax is, instead
4638 of the C<%> and C<*>, to use C<%>I<digits>C<$> and C<*>I<digits>C<$>,
4639 where the I<digits> is the wanted index, from one upwards.  For example:
4640
4641    printf "%2\$d %1\$d\n", 12, 34;              # will print "34 12\n"
4642    printf "%*2\$d\n",      12, 3;               # will print " 12\n"
4643
4644 Note that using the reordering syntax does not interfere with the usual
4645 implicit sequential fetching of the parameters:
4646
4647    printf "%2\$d %d\n",    12, 34;              # will print "34 12\n"
4648    printf "%2\$d %d %d\n", 12, 34;              # will print "34 12 34\n"
4649    printf "%3\$d %d %d\n&