This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add a comment to mg.c to clarify that words like "raise" and
[perl5.git] / lib / AutoSplit.pm
1 package AutoSplit;
2
3 use 5.006_001;
4 use Exporter ();
5 use Config qw(%Config);
6 use File::Basename ();
7 use File::Path qw(mkpath);
8 use File::Spec::Functions qw(curdir catfile catdir);
9 use strict;
10 our($VERSION, @ISA, @EXPORT, @EXPORT_OK, $Verbose, $Keep, $Maxlen,
11     $CheckForAutoloader, $CheckModTime);
12
13 $VERSION = "1.04_01";
14 @ISA = qw(Exporter);
15 @EXPORT = qw(&autosplit &autosplit_lib_modules);
16 @EXPORT_OK = qw($Verbose $Keep $Maxlen $CheckForAutoloader $CheckModTime);
17
18 =head1 NAME
19
20 AutoSplit - split a package for autoloading
21
22 =head1 SYNOPSIS
23
24  autosplit($file, $dir, $keep, $check, $modtime);
25
26  autosplit_lib_modules(@modules);
27
28 =head1 DESCRIPTION
29
30 This function will split up your program into files that the AutoLoader
31 module can handle. It is used by both the standard perl libraries and by
32 the MakeMaker utility, to automatically configure libraries for autoloading.
33
34 The C<autosplit> interface splits the specified file into a hierarchy 
35 rooted at the directory C<$dir>. It creates directories as needed to reflect
36 class hierarchy, and creates the file F<autosplit.ix>. This file acts as
37 both forward declaration of all package routines, and as timestamp for the
38 last update of the hierarchy.
39
40 The remaining three arguments to C<autosplit> govern other options to
41 the autosplitter.
42
43 =over 2
44
45 =item $keep
46
47 If the third argument, I<$keep>, is false, then any
48 pre-existing C<*.al> files in the autoload directory are removed if
49 they are no longer part of the module (obsoleted functions).
50 $keep defaults to 0.
51
52 =item $check
53
54 The
55 fourth argument, I<$check>, instructs C<autosplit> to check the module
56 currently being split to ensure that it includes a C<use>
57 specification for the AutoLoader module, and skips the module if
58 AutoLoader is not detected.
59 $check defaults to 1.
60
61 =item $modtime
62
63 Lastly, the I<$modtime> argument specifies
64 that C<autosplit> is to check the modification time of the module
65 against that of the C<autosplit.ix> file, and only split the module if
66 it is newer.
67 $modtime defaults to 1.
68
69 =back
70
71 Typical use of AutoSplit in the perl MakeMaker utility is via the command-line
72 with:
73
74  perl -e 'use AutoSplit; autosplit($ARGV[0], $ARGV[1], 0, 1, 1)'
75
76 Defined as a Make macro, it is invoked with file and directory arguments;
77 C<autosplit> will split the specified file into the specified directory and
78 delete obsolete C<.al> files, after checking first that the module does use
79 the AutoLoader, and ensuring that the module is not already currently split
80 in its current form (the modtime test).
81
82 The C<autosplit_lib_modules> form is used in the building of perl. It takes
83 as input a list of files (modules) that are assumed to reside in a directory
84 B<lib> relative to the current directory. Each file is sent to the 
85 autosplitter one at a time, to be split into the directory B<lib/auto>.
86
87 In both usages of the autosplitter, only subroutines defined following the
88 perl I<__END__> token are split out into separate files. Some
89 routines may be placed prior to this marker to force their immediate loading
90 and parsing.
91
92 =head2 Multiple packages
93
94 As of version 1.01 of the AutoSplit module it is possible to have
95 multiple packages within a single file. Both of the following cases
96 are supported:
97
98    package NAME;
99    __END__
100    sub AAA { ... }
101    package NAME::option1;
102    sub BBB { ... }
103    package NAME::option2;
104    sub BBB { ... }
105
106    package NAME;
107    __END__
108    sub AAA { ... }
109    sub NAME::option1::BBB { ... }
110    sub NAME::option2::BBB { ... }
111
112 =head1 DIAGNOSTICS
113
114 C<AutoSplit> will inform the user if it is necessary to create the
115 top-level directory specified in the invocation. It is preferred that
116 the script or installation process that invokes C<AutoSplit> have
117 created the full directory path ahead of time. This warning may
118 indicate that the module is being split into an incorrect path.
119
120 C<AutoSplit> will warn the user of all subroutines whose name causes
121 potential file naming conflicts on machines with drastically limited
122 (8 characters or less) file name length. Since the subroutine name is
123 used as the file name, these warnings can aid in portability to such
124 systems.
125
126 Warnings are issued and the file skipped if C<AutoSplit> cannot locate
127 either the I<__END__> marker or a "package Name;"-style specification.
128
129 C<AutoSplit> will also emit general diagnostics for inability to
130 create directories or files.
131
132 =cut
133
134 # for portability warn about names longer than $maxlen
135 $Maxlen  = 8;   # 8 for dos, 11 (14-".al") for SYSVR3
136 $Verbose = 1;   # 0=none, 1=minimal, 2=list .al files
137 $Keep    = 0;
138 $CheckForAutoloader = 1;
139 $CheckModTime = 1;
140
141 my $IndexFile = "autosplit.ix"; # file also serves as timestamp
142 my $maxflen = 255;
143 $maxflen = 14 if $Config{'d_flexfnam'} ne 'define';
144 if (defined (&Dos::UseLFN)) {
145      $maxflen = Dos::UseLFN() ? 255 : 11;
146 }
147 my $Is_VMS = ($^O eq 'VMS');
148
149 # allow checking for valid ': attrlist' attachments
150 # (we use 'our' rather than 'my' here, due to the rather complex and buggy
151 # behaviour of lexicals with qr// and (??{$lex}) )
152 our $nested;
153 $nested = qr{ \( (?: (?> [^()]+ ) | (??{ $nested }) )* \) }x;
154 our $one_attr = qr{ (?> (?! \d) \w+ (?:$nested)? ) (?:\s*\:\s*|\s+(?!\:)) }x;
155 our $attr_list = qr{ \s* : \s* (?: $one_attr )* }x;
156
157
158
159 sub autosplit{
160     my($file, $autodir,  $keep, $ckal, $ckmt) = @_;
161     # $file    - the perl source file to be split (after __END__)
162     # $autodir - the ".../auto" dir below which to write split subs
163     # Handle optional flags:
164     $keep = $Keep unless defined $keep;
165     $ckal = $CheckForAutoloader unless defined $ckal;
166     $ckmt = $CheckModTime unless defined $ckmt;
167     autosplit_file($file, $autodir, $keep, $ckal, $ckmt);
168 }
169
170 sub carp{
171     require Carp;
172     goto &Carp::carp;
173 }
174
175 # This function is used during perl building/installation
176 # ./miniperl -e 'use AutoSplit; autosplit_lib_modules(@ARGV)' ...
177
178 sub autosplit_lib_modules{
179     my(@modules) = @_; # list of Module names
180
181     while(defined($_ = shift @modules)){
182         while (m#(.*?[^:])::([^:].*)#) { # in case specified as ABC::XYZ
183             $_ = catfile($1, $2);
184         }
185         s|\\|/|g;               # bug in ksh OS/2
186         s#^lib/##s; # incase specified as lib/*.pm
187         my($lib) = catfile(curdir(), "lib");
188         if ($Is_VMS) { # may need to convert VMS-style filespecs
189             $lib =~ s#^\[\]#.\/#;
190         }
191         s#^$lib\W+##s; # incase specified as ./lib/*.pm
192         if ($Is_VMS && /[:>\]]/) { # may need to convert VMS-style filespecs
193             my ($dir,$name) = (/(.*])(.*)/s);
194             $dir =~ s/.*lib[\.\]]//s;
195             $dir =~ s#[\.\]]#/#g;
196             $_ = $dir . $name;
197         }
198         autosplit_file(catfile($lib, $_), catfile($lib, "auto"),
199                        $Keep, $CheckForAutoloader, $CheckModTime);
200     }
201     0;
202 }
203
204
205 # private functions
206
207 my $self_mod_time = (stat __FILE__)[9];
208
209 sub autosplit_file {
210     my($filename, $autodir, $keep, $check_for_autoloader, $check_mod_time)
211         = @_;
212     my(@outfiles);
213     local($_);
214     local($/) = "\n";
215
216     # where to write output files
217     $autodir ||= catfile(curdir(), "lib", "auto");
218     if ($Is_VMS) {
219         ($autodir = VMS::Filespec::unixpath($autodir)) =~ s|/\z||;
220         $filename = VMS::Filespec::unixify($filename); # may have dirs
221     }
222     unless (-d $autodir){
223         mkpath($autodir,0,0755);
224         # We should never need to create the auto dir
225         # here. installperl (or similar) should have done
226         # it. Expecting it to exist is a valuable sanity check against
227         # autosplitting into some random directory by mistake.
228         print "Warning: AutoSplit had to create top-level " .
229             "$autodir unexpectedly.\n";
230     }
231
232     # allow just a package name to be used
233     $filename .= ".pm" unless ($filename =~ m/\.pm\z/);
234
235     open(my $in, "<$filename") or die "AutoSplit: Can't open $filename: $!\n";
236     my($pm_mod_time) = (stat($filename))[9];
237     my($autoloader_seen) = 0;
238     my($in_pod) = 0;
239     my($def_package,$last_package,$this_package,$fnr);
240     while (<$in>) {
241         # Skip pod text.
242         $fnr++;
243         $in_pod = 1 if /^=\w/;
244         $in_pod = 0 if /^=cut/;
245         next if ($in_pod || /^=cut/);
246         next if /^\s*#/;
247
248         # record last package name seen
249         $def_package = $1 if (m/^\s*package\s+([\w:]+)\s*;/);
250         ++$autoloader_seen if m/^\s*(use|require)\s+AutoLoader\b/;
251         ++$autoloader_seen if m/\bISA\s*=.*\bAutoLoader\b/;
252         last if /^__END__/;
253     }
254     if ($check_for_autoloader && !$autoloader_seen){
255         print "AutoSplit skipped $filename: no AutoLoader used\n"
256             if ($Verbose>=2);
257         return 0;
258     }
259     $_ or die "Can't find __END__ in $filename\n";
260
261     $def_package or die "Can't find 'package Name;' in $filename\n";
262
263     my($modpname) = _modpname($def_package); 
264
265     # this _has_ to match so we have a reasonable timestamp file
266     die "Package $def_package ($modpname.pm) does not ".
267         "match filename $filename"
268             unless ($filename =~ m/\Q$modpname.pm\E$/ or
269                     ($^O eq 'dos') or ($^O eq 'MSWin32') or ($^O eq 'NetWare') or
270                     $Is_VMS && $filename =~ m/$modpname.pm/i);
271
272     my($al_idx_file) = catfile($autodir, $modpname, $IndexFile);
273
274     if ($check_mod_time){
275         my($al_ts_time) = (stat("$al_idx_file"))[9] || 1;
276         if ($al_ts_time >= $pm_mod_time and
277             $al_ts_time >= $self_mod_time){
278             print "AutoSplit skipped ($al_idx_file newer than $filename)\n"
279                 if ($Verbose >= 2);
280             return undef;       # one undef, not a list
281         }
282     }
283
284     my($modnamedir) = catdir($autodir, $modpname);
285     print "AutoSplitting $filename ($modnamedir)\n"
286         if $Verbose;
287
288     unless (-d $modnamedir){
289         mkpath($modnamedir,0,0777);
290     }
291
292     # We must try to deal with some SVR3 systems with a limit of 14
293     # characters for file names. Sadly we *cannot* simply truncate all
294     # file names to 14 characters on these systems because we *must*
295     # create filenames which exactly match the names used by AutoLoader.pm.
296     # This is a problem because some systems silently truncate the file
297     # names while others treat long file names as an error.
298
299     my $Is83 = $maxflen==11;  # plain, case INSENSITIVE dos filenames
300
301     my(@subnames, $subname, %proto, %package);
302     my @cache = ();
303     my $caching = 1;
304     $last_package = '';
305     my $out;
306     while (<$in>) {
307         $fnr++;
308         $in_pod = 1 if /^=\w/;
309         $in_pod = 0 if /^=cut/;
310         next if ($in_pod || /^=cut/);
311         # the following (tempting) old coding gives big troubles if a
312         # cut is forgotten at EOF:
313         # next if /^=\w/ .. /^=cut/;
314         if (/^package\s+([\w:]+)\s*;/) {
315             $this_package = $def_package = $1;
316         }
317
318         if (/^sub\s+([\w:]+)(\s*(?:\(.*?\))?(?:$attr_list)?)/) {
319             print $out "# end of $last_package\::$subname\n1;\n"
320                 if $last_package;
321             $subname = $1;
322             my $proto = $2 || '';
323             if ($subname =~ s/(.*):://){
324                 $this_package = $1;
325             } else {
326                 $this_package = $def_package;
327             }
328             my $fq_subname = "$this_package\::$subname";
329             $package{$fq_subname} = $this_package;
330             $proto{$fq_subname} = $proto;
331             push(@subnames, $fq_subname);
332             my($lname, $sname) = ($subname, substr($subname,0,$maxflen-3));
333             $modpname = _modpname($this_package);
334             my($modnamedir) = catdir($autodir, $modpname);
335             mkpath($modnamedir,0,0777);
336             my($lpath) = catfile($modnamedir, "$lname.al");
337             my($spath) = catfile($modnamedir, "$sname.al");
338             my $path;
339
340             if (!$Is83 and open($out, ">$lpath")){
341                 $path=$lpath;
342                 print "  writing $lpath\n" if ($Verbose>=2);
343             } else {
344                 open($out, ">$spath") or die "Can't create $spath: $!\n";
345                 $path=$spath;
346                 print "  writing $spath (with truncated name)\n"
347                         if ($Verbose>=1);
348             }
349             push(@outfiles, $path);
350             my $lineno = $fnr - @cache;
351             print $out <<EOT;
352 # NOTE: Derived from $filename.
353 # Changes made here will be lost when autosplit is run again.
354 # See AutoSplit.pm.
355 package $this_package;
356
357 #line $lineno "$filename (autosplit into $path)"
358 EOT
359             print $out @cache;
360             @cache = ();
361             $caching = 0;
362         }
363         if($caching) {
364             push(@cache, $_) if @cache || /\S/;
365         } else {
366             print $out $_;
367         }
368         if(/^\}/) {
369             if($caching) {
370                 print $out @cache;
371                 @cache = ();
372             }
373             print $out "\n";
374             $caching = 1;
375         }
376         $last_package = $this_package if defined $this_package;
377     }
378     if ($subname) {
379         print $out @cache,"1;\n# end of $last_package\::$subname\n";
380         close($out);
381     }
382     close($in);
383     
384     if (!$keep){  # don't keep any obsolete *.al files in the directory
385         my(%outfiles);
386         # @outfiles{@outfiles} = @outfiles;
387         # perl downcases all filenames on VMS (which upcases all filenames) so
388         # we'd better downcase the sub name list too, or subs with upper case
389         # letters in them will get their .al files deleted right after they're
390         # created. (The mixed case sub name won't match the all-lowercase
391         # filename, and so be cleaned up as a scrap file)
392         if ($Is_VMS or $Is83) {
393             %outfiles = map {lc($_) => lc($_) } @outfiles;
394         } else {
395             @outfiles{@outfiles} = @outfiles;
396         }  
397         my(%outdirs,@outdirs);
398         for (@outfiles) {
399             $outdirs{File::Basename::dirname($_)}||=1;
400         }
401         for my $dir (keys %outdirs) {
402             opendir(my $outdir,$dir);
403             foreach (sort readdir($outdir)){
404                 next unless /\.al\z/;
405                 my($file) = catfile($dir, $_);
406                 $file = lc $file if $Is83 or $Is_VMS;
407                 next if $outfiles{$file};
408                 print "  deleting $file\n" if ($Verbose>=2);
409                 my($deleted,$thistime);  # catch all versions on VMS
410                 do { $deleted += ($thistime = unlink $file) } while ($thistime);
411                 carp ("Unable to delete $file: $!") unless $deleted;
412             }
413             closedir($outdir);
414         }
415     }
416
417     open(my $ts,">$al_idx_file") or
418         carp ("AutoSplit: unable to create timestamp file ($al_idx_file): $!");
419     print $ts "# Index created by AutoSplit for $filename\n";
420     print $ts "#    (file acts as timestamp)\n";
421     $last_package = '';
422     for my $fqs (@subnames) {
423         my($subname) = $fqs;
424         $subname =~ s/.*:://;
425         print $ts "package $package{$fqs};\n"
426             unless $last_package eq $package{$fqs};
427         print $ts "sub $subname $proto{$fqs};\n";
428         $last_package = $package{$fqs};
429     }
430     print $ts "1;\n";
431     close($ts);
432
433     _check_unique($filename, $Maxlen, 1, @outfiles);
434
435     @outfiles;
436 }
437
438 sub _modpname ($) {
439     my($package) = @_;
440     my $modpname = $package;
441     if ($^O eq 'MSWin32') {
442         $modpname =~ s#::#\\#g; 
443     } else {
444         my @modpnames = ();
445         while ($modpname =~ m#(.*?[^:])::([^:].*)#) {
446                push @modpnames, $1;
447                $modpname = $2;
448          }
449         $modpname = catfile(@modpnames, $modpname);
450     }
451     if ($Is_VMS) {
452         $modpname = VMS::Filespec::unixify($modpname); # may have dirs
453     }
454     $modpname;
455 }
456
457 sub _check_unique {
458     my($filename, $maxlen, $warn, @outfiles) = @_;
459     my(%notuniq) = ();
460     my(%shorts)  = ();
461     my(@toolong) = grep(
462                         length(File::Basename::basename($_))
463                         > $maxlen,
464                         @outfiles
465                        );
466
467     foreach (@toolong){
468         my($dir) = File::Basename::dirname($_);
469         my($file) = File::Basename::basename($_);
470         my($trunc) = substr($file,0,$maxlen);
471         $notuniq{$dir}{$trunc} = 1 if $shorts{$dir}{$trunc};
472         $shorts{$dir}{$trunc} = $shorts{$dir}{$trunc} ?
473             "$shorts{$dir}{$trunc}, $file" : $file;
474     }
475     if (%notuniq && $warn){
476         print "$filename: some names are not unique when " .
477             "truncated to $maxlen characters:\n";
478         foreach my $dir (sort keys %notuniq){
479             print " directory $dir:\n";
480             foreach my $trunc (sort keys %{$notuniq{$dir}}) {
481                 print "  $shorts{$dir}{$trunc} truncate to $trunc\n";
482             }
483         }
484     }
485 }
486
487 1;
488 __END__
489
490 # test functions so AutoSplit.pm can be applied to itself:
491 sub test1 ($)   { "test 1\n"; }
492 sub test2 ($$)  { "test 2\n"; }
493 sub test3 ($$$) { "test 3\n"; }
494 sub testtesttesttest4_1  { "test 4\n"; }
495 sub testtesttesttest4_2  { "duplicate test 4\n"; }
496 sub Just::Another::test5 { "another test 5\n"; }
497 sub test6       { return join ":", __FILE__,__LINE__; }
498 package Yet::Another::AutoSplit;
499 sub testtesttesttest4_1 ($)  { "another test 4\n"; }
500 sub testtesttesttest4_2 ($$) { "another duplicate test 4\n"; }
501 package Yet::More::Attributes;
502 sub test_a1 ($) : locked :locked { 1; }
503 sub test_a2 : locked { 1; }