This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
abe18a85ec981d95fa30847c845ba25d0e56d64d
[perl5.git] / dist / B-Deparse / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          CVf_METHOD CVf_LVALUE
21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED),
23          ($] < 5.008004 ? () : 'OPpSORT_INPLACE'),
24          ($] < 5.008006 ? () : qw(OPpSORT_DESCEND OPpITER_REVERSED)),
25          ($] < 5.008009 ? () : qw(OPpCONST_NOVER OPpPAD_STATE)),
26          ($] < 5.009 ? 'PMf_SKIPWHITE' : qw(RXf_SKIPWHITE)),
27          ($] < 5.011 ? 'CVf_LOCKED' : 'OPpREVERSE_INPLACE'),
28          ($] < 5.013 ? () : 'PMf_NONDESTRUCT'),
29          ($] < 5.015003 &&
30              # This empirical feature test is required during the
31              # transitional phase where blead still identifies itself
32              # as 5.15.2 but has had $[ removed.  After blead has its
33              # version number bumped to 5.15.3, this can be reduced to
34              # just test $] < 5.015003.
35              ($] < 5.015002 || do { require B; exists(&B::OPpCONST_ARYBASE) })
36              ? qw(OPpCONST_ARYBASE) : ());
37 $VERSION = "1.08";
38 use strict;
39 use vars qw/$AUTOLOAD/;
40 use warnings ();
41
42 BEGIN {
43     # Easiest way to keep this code portable between version looks to
44     # be to fake up a dummy constant that will never actually be true.
45     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
46                 OPpPAD_STATE RXf_SKIPWHITE CVf_LOCKED OPpREVERSE_INPLACE
47                 PMf_NONDESTRUCT OPpCONST_ARYBASE)) {
48         no strict 'refs';
49         *{$_} = sub () {0} unless *{$_}{CODE};
50     }
51 }
52
53 # Changes between 0.50 and 0.51:
54 # - fixed nulled leave with live enter in sort { }
55 # - fixed reference constants (\"str")
56 # - handle empty programs gracefully
57 # - handle infinite loops (for (;;) {}, while (1) {})
58 # - differentiate between `for my $x ...' and `my $x; for $x ...'
59 # - various minor cleanups
60 # - moved globals into an object
61 # - added `-u', like B::C
62 # - package declarations using cop_stash
63 # - subs, formats and code sorted by cop_seq
64 # Changes between 0.51 and 0.52:
65 # - added pp_threadsv (special variables under USE_5005THREADS)
66 # - added documentation
67 # Changes between 0.52 and 0.53:
68 # - many changes adding precedence contexts and associativity
69 # - added `-p' and `-s' output style options
70 # - various other minor fixes
71 # Changes between 0.53 and 0.54:
72 # - added support for new `for (1..100)' optimization,
73 #   thanks to Gisle Aas
74 # Changes between 0.54 and 0.55:
75 # - added support for new qr// construct
76 # - added support for new pp_regcreset OP
77 # Changes between 0.55 and 0.56:
78 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
79 # - fixed $# on non-lexicals broken in last big rewrite
80 # - added temporary fix for change in opcode of OP_STRINGIFY
81 # - fixed problem in 0.54's for() patch in `for (@ary)'
82 # - fixed precedence in conditional of ?:
83 # - tweaked list paren elimination in `my($x) = @_'
84 # - made continue-block detection trickier wrt. null ops
85 # - fixed various prototype problems in pp_entersub
86 # - added support for sub prototypes that never get GVs
87 # - added unquoting for special filehandle first arg in truncate
88 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
89 # - added semicolons at the ends of blocks
90 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
91 # Changes between 0.56 and 0.561:
92 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
93 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
94 # Changes between 0.561 and 0.57:
95 # - stylistic changes to symbolic constant stuff
96 # - handled scope in s///e replacement code
97 # - added unquote option for expanding "" into concats, etc.
98 # - split method and proto parts of pp_entersub into separate functions
99 # - various minor cleanups
100 # Changes after 0.57:
101 # - added parens in \&foo (patch by Albert Dvornik)
102 # Changes between 0.57 and 0.58:
103 # - fixed `0' statements that weren't being printed
104 # - added methods for use from other programs
105 #   (based on patches from James Duncan and Hugo van der Sanden)
106 # - added -si and -sT to control indenting (also based on a patch from Hugo)
107 # - added -sv to print something else instead of '???'
108 # - preliminary version of utf8 tr/// handling
109 # Changes after 0.58:
110 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
111 # - added support for Hugo's new OP_SETSTATE (like nextstate)
112 # Changes between 0.58 and 0.59
113 # - added support for Chip's OP_METHOD_NAMED
114 # - added support for Ilya's OPpTARGET_MY optimization
115 # - elided arrows before `()' subscripts when possible
116 # Changes between 0.59 and 0.60
117 # - support for method attributes was added
118 # - some warnings fixed
119 # - separate recognition of constant subs
120 # - rewrote continue block handling, now recognizing for loops
121 # - added more control of expanding control structures
122 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
123 # - many bug-fixes
124 # - support for pragmas and 'use'
125 # - support for the little-used $[ variable
126 # - support for __DATA__ sections
127 # - UTF8 support
128 # - BEGIN, CHECK, INIT and END blocks
129 # - scoping of subroutine declarations fixed
130 # - compile-time output from the input program can be suppressed, so that the
131 #   output is just the deparsed code. (a change to O.pm in fact)
132 # - our() declarations
133 # - *all* the known bugs are now listed in the BUGS section
134 # - comprehensive test mechanism (TEST -deparse)
135 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
136 # - bug-fixes
137 # - new switch -P
138 # - support for command-line switches (-l, -0, etc.)
139 # Changes between 0.63 and 0.64
140 # - support for //, CHECK blocks, and assertions
141 # - improved handling of foreach loops and lexicals
142 # - option to use Data::Dumper for constants
143 # - more bug fixes
144 # - discovered lots more bugs not yet fixed
145 #
146 # ...
147 #
148 # Changes between 0.72 and 0.73
149 # - support new switch constructs
150
151 # Todo:
152 #  (See also BUGS section at the end of this file)
153 #
154 # - finish tr/// changes
155 # - add option for even more parens (generalize \&foo change)
156 # - left/right context
157 # - copy comments (look at real text with $^P?)
158 # - avoid semis in one-statement blocks
159 # - associativity of &&=, ||=, ?:
160 # - ',' => '=>' (auto-unquote?)
161 # - break long lines ("\r" as discretionary break?)
162 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
163 # - more style options: brace style, hex vs. octal, quotes, ...
164 # - print big ints as hex/octal instead of decimal (heuristic?)
165 # - handle `my $x if 0'?
166 # - version using op_next instead of op_first/sibling?
167 # - avoid string copies (pass arrays, one big join?)
168 # - here-docs?
169
170 # Current test.deparse failures
171 # comp/hints 6 - location of BEGIN blocks wrt. block openings
172 # run/switchI 1 - missing -I switches entirely
173 #    perl -Ifoo -e 'print @INC'
174 # op/caller 2 - warning mask propagates backwards before warnings::register
175 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
176 # op/getpid 2 - can't assign to shared my() declaration (threads only)
177 #    'my $x : shared = 5'
178 # op/override 7 - parens on overridden require change v-string interpretation
179 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
180 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
181 # op/pat 774 - losing Unicode-ness of Latin1-only strings
182 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
183 # op/recurse 12 - missing parens on recursive call makes it look like method
184 #    'sub f { f($x) }'
185 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
186 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
187 # op/tiehandle compile - "use strict" deparsed in the wrong place
188 # uni/tr_ several
189 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
190 # ext/Data/Dumper/t/dumper compile
191 # ext/DB_file/several
192 # ext/Encode/several
193 # ext/Ernno/Errno warnings
194 # ext/IO/lib/IO/t/io_sel 23
195 # ext/PerlIO/t/encoding compile
196 # ext/POSIX/t/posix 6
197 # ext/Socket/Socket 8
198 # ext/Storable/t/croak compile
199 # lib/Attribute/Handlers/t/multi compile
200 # lib/bignum/ several
201 # lib/charnames 35
202 # lib/constant 32
203 # lib/English 40
204 # lib/ExtUtils/t/bytes 4
205 # lib/File/DosGlob compile
206 # lib/Filter/Simple/t/data 1
207 # lib/Math/BigInt/t/constant 1
208 # lib/Net/t/config Deparse-warning
209 # lib/overload compile
210 # lib/Switch/ several
211 # lib/Symbol 4
212 # lib/Test/Simple several
213 # lib/Term/Complete
214 # lib/Tie/File/t/29_downcopy 5
215 # lib/vars 22
216
217 # Object fields (were globals):
218 #
219 # avoid_local:
220 # (local($a), local($b)) and local($a, $b) have the same internal
221 # representation but the short form looks better. We notice we can
222 # use a large-scale local when checking the list, but need to prevent
223 # individual locals too. This hash holds the addresses of OPs that
224 # have already had their local-ness accounted for. The same thing
225 # is done with my().
226 #
227 # curcv:
228 # CV for current sub (or main program) being deparsed
229 #
230 # curcvlex:
231 # Cached hash of lexical variables for curcv: keys are names,
232 # each value is an array of pairs, indicating the cop_seq of scopes
233 # in which a var of that name is valid.
234 #
235 # curcop:
236 # COP for statement being deparsed
237 #
238 # curstash:
239 # name of the current package for deparsed code
240 #
241 # subs_todo:
242 # array of [cop_seq, CV, is_format?] for subs and formats we still
243 # want to deparse
244 #
245 # protos_todo:
246 # as above, but [name, prototype] for subs that never got a GV
247 #
248 # subs_done, forms_done:
249 # keys are addresses of GVs for subs and formats we've already
250 # deparsed (or at least put into subs_todo)
251 #
252 # subs_declared
253 # keys are names of subs for which we've printed declarations.
254 # That means we can omit parentheses from the arguments. It also means we
255 # need to put CORE:: on core functions of the same name.
256 #
257 # subs_deparsed
258 # Keeps track of fully qualified names of all deparsed subs.
259 #
260 # parens: -p
261 # linenums: -l
262 # unquote: -q
263 # cuddle: ` ' or `\n', depending on -sC
264 # indent_size: -si
265 # use_tabs: -sT
266 # ex_const: -sv
267
268 # A little explanation of how precedence contexts and associativity
269 # work:
270 #
271 # deparse() calls each per-op subroutine with an argument $cx (short
272 # for context, but not the same as the cx* in the perl core), which is
273 # a number describing the op's parents in terms of precedence, whether
274 # they're inside an expression or at statement level, etc.  (see
275 # chart below). When ops with children call deparse on them, they pass
276 # along their precedence. Fractional values are used to implement
277 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
278 # parentheses hacks. The major disadvantage of this scheme is that
279 # it doesn't know about right sides and left sides, so say if you
280 # assign a listop to a variable, it can't tell it's allowed to leave
281 # the parens off the listop.
282
283 # Precedences:
284 # 26             [TODO] inside interpolation context ("")
285 # 25 left        terms and list operators (leftward)
286 # 24 left        ->
287 # 23 nonassoc    ++ --
288 # 22 right       **
289 # 21 right       ! ~ \ and unary + and -
290 # 20 left        =~ !~
291 # 19 left        * / % x
292 # 18 left        + - .
293 # 17 left        << >>
294 # 16 nonassoc    named unary operators
295 # 15 nonassoc    < > <= >= lt gt le ge
296 # 14 nonassoc    == != <=> eq ne cmp
297 # 13 left        &
298 # 12 left        | ^
299 # 11 left        &&
300 # 10 left        ||
301 #  9 nonassoc    ..  ...
302 #  8 right       ?:
303 #  7 right       = += -= *= etc.
304 #  6 left        , =>
305 #  5 nonassoc    list operators (rightward)
306 #  4 right       not
307 #  3 left        and
308 #  2 left        or xor
309 #  1             statement modifiers
310 #  0.5           statements, but still print scopes as do { ... }
311 #  0             statement level
312
313 # Nonprinting characters with special meaning:
314 # \cS - steal parens (see maybe_parens_unop)
315 # \n - newline and indent
316 # \t - increase indent
317 # \b - decrease indent (`outdent')
318 # \f - flush left (no indent)
319 # \cK - kill following semicolon, if any
320
321 sub null {
322     my $op = shift;
323     return class($op) eq "NULL";
324 }
325
326 sub todo {
327     my $self = shift;
328     my($cv, $is_form) = @_;
329     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
330     my $seq;
331     if ($cv->OUTSIDE_SEQ) {
332         $seq = $cv->OUTSIDE_SEQ;
333     } elsif (!null($cv->START) and is_state($cv->START)) {
334         $seq = $cv->START->cop_seq;
335     } else {
336         $seq = 0;
337     }
338     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
339     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
340         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
341     }
342 }
343
344 sub next_todo {
345     my $self = shift;
346     my $ent = shift @{$self->{'subs_todo'}};
347     my $cv = $ent->[1];
348     my $gv = $cv->GV;
349     my $name = $self->gv_name($gv);
350     if ($ent->[2]) {
351         return "format $name =\n"
352             . $self->deparse_format($ent->[1]). "\n";
353     } else {
354         $self->{'subs_declared'}{$name} = 1;
355         if ($name eq "BEGIN") {
356             my $use_dec = $self->begin_is_use($cv);
357             if (defined ($use_dec) and $self->{'expand'} < 5) {
358                 return () if 0 == length($use_dec);
359                 return $use_dec;
360             }
361         }
362         my $l = '';
363         if ($self->{'linenums'}) {
364             my $line = $gv->LINE;
365             my $file = $gv->FILE;
366             $l = "\n\f#line $line \"$file\"\n";
367         }
368         my $p = '';
369         if (class($cv->STASH) ne "SPECIAL") {
370             my $stash = $cv->STASH->NAME;
371             if ($stash ne $self->{'curstash'}) {
372                 $p = "package $stash;\n";
373                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
374                 $self->{'curstash'} = $stash;
375             }
376             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
377         }
378         return "${p}${l}sub $name " . $self->deparse_sub($cv);
379     }
380 }
381
382 # Return a "use" declaration for this BEGIN block, if appropriate
383 sub begin_is_use {
384     my ($self, $cv) = @_;
385     my $root = $cv->ROOT;
386     local @$self{qw'curcv curcvlex'} = ($cv);
387 #require B::Debug;
388 #B::walkoptree($cv->ROOT, "debug");
389     my $lineseq = $root->first;
390     return if $lineseq->name ne "lineseq";
391
392     my $req_op = $lineseq->first->sibling;
393     return if $req_op->name ne "require";
394
395     my $module;
396     if ($req_op->first->private & OPpCONST_BARE) {
397         # Actually it should always be a bareword
398         $module = $self->const_sv($req_op->first)->PV;
399         $module =~ s[/][::]g;
400         $module =~ s/.pm$//;
401     }
402     else {
403         $module = $self->const($self->const_sv($req_op->first), 6);
404     }
405
406     my $version;
407     my $version_op = $req_op->sibling;
408     return if class($version_op) eq "NULL";
409     if ($version_op->name eq "lineseq") {
410         # We have a version parameter; skip nextstate & pushmark
411         my $constop = $version_op->first->next->next;
412
413         return unless $self->const_sv($constop)->PV eq $module;
414         $constop = $constop->sibling;
415         $version = $self->const_sv($constop);
416         if (class($version) eq "IV") {
417             $version = $version->int_value;
418         } elsif (class($version) eq "NV") {
419             $version = $version->NV;
420         } elsif (class($version) ne "PVMG") {
421             # Includes PVIV and PVNV
422             $version = $version->PV;
423         } else {
424             # version specified as a v-string
425             $version = 'v'.join '.', map ord, split //, $version->PV;
426         }
427         $constop = $constop->sibling;
428         return if $constop->name ne "method_named";
429         return if $self->const_sv($constop)->PV ne "VERSION";
430     }
431
432     $lineseq = $version_op->sibling;
433     return if $lineseq->name ne "lineseq";
434     my $entersub = $lineseq->first->sibling;
435     if ($entersub->name eq "stub") {
436         return "use $module $version ();\n" if defined $version;
437         return "use $module ();\n";
438     }
439     return if $entersub->name ne "entersub";
440
441     # See if there are import arguments
442     my $args = '';
443
444     my $svop = $entersub->first->sibling; # Skip over pushmark
445     return unless $self->const_sv($svop)->PV eq $module;
446
447     # Pull out the arguments
448     for ($svop=$svop->sibling; $svop->name ne "method_named";
449                 $svop = $svop->sibling) {
450         $args .= ", " if length($args);
451         $args .= $self->deparse($svop, 6);
452     }
453
454     my $use = 'use';
455     my $method_named = $svop;
456     return if $method_named->name ne "method_named";
457     my $method_name = $self->const_sv($method_named)->PV;
458
459     if ($method_name eq "unimport") {
460         $use = 'no';
461     }
462
463     # Certain pragmas are dealt with using hint bits,
464     # so we ignore them here
465     if ($module eq 'strict' || $module eq 'integer'
466         || $module eq 'bytes' || $module eq 'warnings'
467         || $module eq 'feature') {
468         return "";
469     }
470
471     if (defined $version && length $args) {
472         return "$use $module $version ($args);\n";
473     } elsif (defined $version) {
474         return "$use $module $version;\n";
475     } elsif (length $args) {
476         return "$use $module ($args);\n";
477     } else {
478         return "$use $module;\n";
479     }
480 }
481
482 sub stash_subs {
483     my ($self, $pack) = @_;
484     my (@ret, $stash);
485     if (!defined $pack) {
486         $pack = '';
487         $stash = \%::;
488     }
489     else {
490         $pack =~ s/(::)?$/::/;
491         no strict 'refs';
492         $stash = \%{"main::$pack"};
493     }
494     my %stash = svref_2object($stash)->ARRAY;
495     while (my ($key, $val) = each %stash) {
496         my $class = class($val);
497         if ($class eq "PV") {
498             # Just a prototype. As an ugly but fairly effective way
499             # to find out if it belongs here is to see if the AUTOLOAD
500             # (if any) for the stash was defined in one of our files.
501             my $A = $stash{"AUTOLOAD"};
502             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
503                 && class($A->CV) eq "CV") {
504                 my $AF = $A->FILE;
505                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
506             }
507             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
508         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
509             # Just a name. As above.
510             # But skip proxy constant subroutines, as some form of perl-space
511             # visible code must have created them, be it a use statement, or
512             # some direct symbol-table manipulation code that we will Deparse
513             my $A = $stash{"AUTOLOAD"};
514             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
515                 && class($A->CV) eq "CV") {
516                 my $AF = $A->FILE;
517                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
518             }
519             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
520         } elsif ($class eq "GV") {
521             if (class(my $cv = $val->CV) ne "SPECIAL") {
522                 next if $self->{'subs_done'}{$$val}++;
523                 next if $$val != ${$cv->GV};   # Ignore imposters
524                 $self->todo($cv, 0);
525             }
526             if (class(my $cv = $val->FORM) ne "SPECIAL") {
527                 next if $self->{'forms_done'}{$$val}++;
528                 next if $$val != ${$cv->GV};   # Ignore imposters
529                 $self->todo($cv, 1);
530             }
531             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
532                 $self->stash_subs($pack . $key)
533                     unless $pack eq '' && $key eq 'main::';
534                     # avoid infinite recursion
535             }
536         }
537     }
538 }
539
540 sub print_protos {
541     my $self = shift;
542     my $ar;
543     my @ret;
544     foreach $ar (@{$self->{'protos_todo'}}) {
545         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
546         push @ret, "sub " . $ar->[0] .  "$proto;\n";
547     }
548     delete $self->{'protos_todo'};
549     return @ret;
550 }
551
552 sub style_opts {
553     my $self = shift;
554     my $opts = shift;
555     my $opt;
556     while (length($opt = substr($opts, 0, 1))) {
557         if ($opt eq "C") {
558             $self->{'cuddle'} = " ";
559             $opts = substr($opts, 1);
560         } elsif ($opt eq "i") {
561             $opts =~ s/^i(\d+)//;
562             $self->{'indent_size'} = $1;
563         } elsif ($opt eq "T") {
564             $self->{'use_tabs'} = 1;
565             $opts = substr($opts, 1);
566         } elsif ($opt eq "v") {
567             $opts =~ s/^v([^.]*)(.|$)//;
568             $self->{'ex_const'} = $1;
569         }
570     }
571 }
572
573 sub new {
574     my $class = shift;
575     my $self = bless {}, $class;
576     $self->{'cuddle'} = "\n";
577     $self->{'curcop'} = undef;
578     $self->{'curstash'} = "main";
579     $self->{'ex_const'} = "'???'";
580     $self->{'expand'} = 0;
581     $self->{'files'} = {};
582     $self->{'indent_size'} = 4;
583     $self->{'linenums'} = 0;
584     $self->{'parens'} = 0;
585     $self->{'subs_todo'} = [];
586     $self->{'unquote'} = 0;
587     $self->{'use_dumper'} = 0;
588     $self->{'use_tabs'} = 0;
589
590     $self->{'ambient_arybase'} = 0;
591     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
592     $self->{'ambient_hints'} = 0;
593     $self->{'ambient_hinthash'} = undef;
594     $self->init();
595
596     while (my $arg = shift @_) {
597         if ($arg eq "-d") {
598             $self->{'use_dumper'} = 1;
599             require Data::Dumper;
600         } elsif ($arg =~ /^-f(.*)/) {
601             $self->{'files'}{$1} = 1;
602         } elsif ($arg eq "-l") {
603             $self->{'linenums'} = 1;
604         } elsif ($arg eq "-p") {
605             $self->{'parens'} = 1;
606         } elsif ($arg eq "-P") {
607             $self->{'noproto'} = 1;
608         } elsif ($arg eq "-q") {
609             $self->{'unquote'} = 1;
610         } elsif (substr($arg, 0, 2) eq "-s") {
611             $self->style_opts(substr $arg, 2);
612         } elsif ($arg =~ /^-x(\d)$/) {
613             $self->{'expand'} = $1;
614         }
615     }
616     return $self;
617 }
618
619 {
620     # Mask out the bits that L<warnings::register> uses
621     my $WARN_MASK;
622     BEGIN {
623         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
624     }
625     sub WARN_MASK () {
626         return $WARN_MASK;
627     }
628 }
629
630 # Initialise the contextual information, either from
631 # defaults provided with the ambient_pragmas method,
632 # or from perl's own defaults otherwise.
633 sub init {
634     my $self = shift;
635
636     $self->{'arybase'}  = $self->{'ambient_arybase'};
637     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
638                                 ? $self->{'ambient_warnings'} & WARN_MASK
639                                 : undef;
640     $self->{'hints'}    = $self->{'ambient_hints'};
641     $self->{'hints'} &= 0xFF if $] < 5.009;
642     $self->{'hinthash'} = $self->{'ambient_hinthash'};
643
644     # also a convenient place to clear out subs_declared
645     delete $self->{'subs_declared'};
646 }
647
648 sub compile {
649     my(@args) = @_;
650     return sub {
651         my $self = B::Deparse->new(@args);
652         # First deparse command-line args
653         if (defined $^I) { # deparse -i
654             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
655         }
656         if ($^W) { # deparse -w
657             print qq(BEGIN { \$^W = $^W; }\n);
658         }
659         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
660             my $fs = perlstring($/) || 'undef';
661             my $bs = perlstring($O::savebackslash) || 'undef';
662             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
663         }
664         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
665         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
666             ? B::unitcheck_av->ARRAY
667             : ();
668         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
669         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
670         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
671         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
672             $self->todo($block, 0);
673         }
674         $self->stash_subs();
675         local($SIG{"__DIE__"}) =
676           sub {
677               if ($self->{'curcop'}) {
678                   my $cop = $self->{'curcop'};
679                   my($line, $file) = ($cop->line, $cop->file);
680                   print STDERR "While deparsing $file near line $line,\n";
681               }
682             };
683         $self->{'curcv'} = main_cv;
684         $self->{'curcvlex'} = undef;
685         print $self->print_protos;
686         @{$self->{'subs_todo'}} =
687           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
688         print $self->indent($self->deparse_root(main_root)), "\n"
689           unless null main_root;
690         my @text;
691         while (scalar(@{$self->{'subs_todo'}})) {
692             push @text, $self->next_todo;
693         }
694         print $self->indent(join("", @text)), "\n" if @text;
695
696         # Print __DATA__ section, if necessary
697         no strict 'refs';
698         my $laststash = defined $self->{'curcop'}
699             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
700         if (defined *{$laststash."::DATA"}{IO}) {
701             print "package $laststash;\n"
702                 unless $laststash eq $self->{'curstash'};
703             print "__DATA__\n";
704             print readline(*{$laststash."::DATA"});
705         }
706     }
707 }
708
709 sub coderef2text {
710     my $self = shift;
711     my $sub = shift;
712     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
713
714     $self->init();
715     return $self->indent($self->deparse_sub(svref_2object($sub)));
716 }
717
718 sub ambient_pragmas {
719     my $self = shift;
720     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
721
722     while (@_ > 1) {
723         my $name = shift();
724         my $val  = shift();
725
726         if ($name eq 'strict') {
727             require strict;
728
729             if ($val eq 'none') {
730                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
731                 next();
732             }
733
734             my @names;
735             if ($val eq "all") {
736                 @names = qw/refs subs vars/;
737             }
738             elsif (ref $val) {
739                 @names = @$val;
740             }
741             else {
742                 @names = split' ', $val;
743             }
744             $hint_bits |= strict::bits(@names);
745         }
746
747         elsif ($name eq '$[') {
748             if (OPpCONST_ARYBASE) {
749                 $arybase = $val;
750             } else {
751                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
752             }
753         }
754
755         elsif ($name eq 'integer'
756             || $name eq 'bytes'
757             || $name eq 'utf8') {
758             require "$name.pm";
759             if ($val) {
760                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
761             }
762             else {
763                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
764             }
765         }
766
767         elsif ($name eq 're') {
768             require re;
769             if ($val eq 'none') {
770                 $hint_bits &= ~re::bits(qw/taint eval/);
771                 next();
772             }
773
774             my @names;
775             if ($val eq 'all') {
776                 @names = qw/taint eval/;
777             }
778             elsif (ref $val) {
779                 @names = @$val;
780             }
781             else {
782                 @names = split' ',$val;
783             }
784             $hint_bits |= re::bits(@names);
785         }
786
787         elsif ($name eq 'warnings') {
788             if ($val eq 'none') {
789                 $warning_bits = $warnings::NONE;
790                 next();
791             }
792
793             my @names;
794             if (ref $val) {
795                 @names = @$val;
796             }
797             else {
798                 @names = split/\s+/, $val;
799             }
800
801             $warning_bits = $warnings::NONE if !defined ($warning_bits);
802             $warning_bits |= warnings::bits(@names);
803         }
804
805         elsif ($name eq 'warning_bits') {
806             $warning_bits = $val;
807         }
808
809         elsif ($name eq 'hint_bits') {
810             $hint_bits = $val;
811         }
812
813         elsif ($name eq '%^H') {
814             $hinthash = $val;
815         }
816
817         else {
818             croak "Unknown pragma type: $name";
819         }
820     }
821     if (@_) {
822         croak "The ambient_pragmas method expects an even number of args";
823     }
824
825     $self->{'ambient_arybase'} = $arybase;
826     $self->{'ambient_warnings'} = $warning_bits;
827     $self->{'ambient_hints'} = $hint_bits;
828     $self->{'ambient_hinthash'} = $hinthash;
829 }
830
831 # This method is the inner loop, so try to keep it simple
832 sub deparse {
833     my $self = shift;
834     my($op, $cx) = @_;
835
836     Carp::confess("Null op in deparse") if !defined($op)
837                                         || class($op) eq "NULL";
838     my $meth = "pp_" . $op->name;
839     return $self->$meth($op, $cx);
840 }
841
842 sub indent {
843     my $self = shift;
844     my $txt = shift;
845     my @lines = split(/\n/, $txt);
846     my $leader = "";
847     my $level = 0;
848     my $line;
849     for $line (@lines) {
850         my $cmd = substr($line, 0, 1);
851         if ($cmd eq "\t" or $cmd eq "\b") {
852             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
853             if ($self->{'use_tabs'}) {
854                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
855             } else {
856                 $leader = " " x $level;
857             }
858             $line = substr($line, 1);
859         }
860         if (substr($line, 0, 1) eq "\f") {
861             $line = substr($line, 1); # no indent
862         } else {
863             $line = $leader . $line;
864         }
865         $line =~ s/\cK;?//g;
866     }
867     return join("\n", @lines);
868 }
869
870 sub deparse_sub {
871     my $self = shift;
872     my $cv = shift;
873     my $proto = "";
874 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
875 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
876     local $self->{'curcop'} = $self->{'curcop'};
877     if ($cv->FLAGS & SVf_POK) {
878         $proto = "(". $cv->PV . ") ";
879     }
880     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
881         $proto .= ": ";
882         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
883         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
884         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
885     }
886
887     local($self->{'curcv'}) = $cv;
888     local($self->{'curcvlex'});
889     local(@$self{qw'curstash warnings hints hinthash'})
890                 = @$self{qw'curstash warnings hints hinthash'};
891     my $body;
892     if (not null $cv->ROOT) {
893         my $lineseq = $cv->ROOT->first;
894         if ($lineseq->name eq "lineseq") {
895             my @ops;
896             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
897                 push @ops, $o;
898             }
899             $body = $self->lineseq(undef, @ops).";";
900             my $scope_en = $self->find_scope_en($lineseq);
901             if (defined $scope_en) {
902                 my $subs = join"", $self->seq_subs($scope_en);
903                 $body .= ";\n$subs" if length($subs);
904             }
905         }
906         else {
907             $body = $self->deparse($cv->ROOT->first, 0);
908         }
909     }
910     else {
911         my $sv = $cv->const_sv;
912         if ($$sv) {
913             # uh-oh. inlinable sub... format it differently
914             return $proto . "{ " . $self->const($sv, 0) . " }\n";
915         } else { # XSUB? (or just a declaration)
916             return "$proto;\n";
917         }
918     }
919     return $proto ."{\n\t$body\n\b}" ."\n";
920 }
921
922 sub deparse_format {
923     my $self = shift;
924     my $form = shift;
925     my @text;
926     local($self->{'curcv'}) = $form;
927     local($self->{'curcvlex'});
928     local($self->{'in_format'}) = 1;
929     local(@$self{qw'curstash warnings hints hinthash'})
930                 = @$self{qw'curstash warnings hints hinthash'};
931     my $op = $form->ROOT;
932     my $kid;
933     return "\f." if $op->first->name eq 'stub'
934                 || $op->first->name eq 'nextstate';
935     $op = $op->first->first; # skip leavewrite, lineseq
936     while (not null $op) {
937         $op = $op->sibling; # skip nextstate
938         my @exprs;
939         $kid = $op->first->sibling; # skip pushmark
940         push @text, "\f".$self->const_sv($kid)->PV;
941         $kid = $kid->sibling;
942         for (; not null $kid; $kid = $kid->sibling) {
943             push @exprs, $self->deparse($kid, 0);
944         }
945         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
946         $op = $op->sibling;
947     }
948     return join("", @text) . "\f.";
949 }
950
951 sub is_scope {
952     my $op = shift;
953     return $op->name eq "leave" || $op->name eq "scope"
954       || $op->name eq "lineseq"
955         || ($op->name eq "null" && class($op) eq "UNOP"
956             && (is_scope($op->first) || $op->first->name eq "enter"));
957 }
958
959 sub is_state {
960     my $name = $_[0]->name;
961     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
962 }
963
964 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
965     my $op = shift;
966     return (!null($op) and null($op->sibling)
967             and $op->name eq "null" and class($op) eq "UNOP"
968             and (($op->first->name =~ /^(and|or)$/
969                   and $op->first->first->sibling->name eq "lineseq")
970                  or ($op->first->name eq "lineseq"
971                      and not null $op->first->first->sibling
972                      and $op->first->first->sibling->name eq "unstack")
973                  ));
974 }
975
976 # Check if the op and its sibling are the initialization and the rest of a
977 # for (..;..;..) { ... } loop
978 sub is_for_loop {
979     my $op = shift;
980     # This OP might be almost anything, though it won't be a
981     # nextstate. (It's the initialization, so in the canonical case it
982     # will be an sassign.) The sibling is (old style) a lineseq whose
983     # first child is a nextstate and whose second is a leaveloop, or
984     # (new style) an unstack whose sibling is a leaveloop.
985     my $lseq = $op->sibling;
986     return 0 unless !is_state($op) and !null($lseq);
987     if ($lseq->name eq "lineseq") {
988         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
989             && (my $sib = $lseq->first->sibling)) {
990             return (!null($sib) && $sib->name eq "leaveloop");
991         }
992     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
993         my $sib = $lseq->sibling;
994         return $sib && !null($sib) && $sib->name eq "leaveloop";
995     }
996     return 0;
997 }
998
999 sub is_scalar {
1000     my $op = shift;
1001     return ($op->name eq "rv2sv" or
1002             $op->name eq "padsv" or
1003             $op->name eq "gv" or # only in array/hash constructs
1004             $op->flags & OPf_KIDS && !null($op->first)
1005               && $op->first->name eq "gvsv");
1006 }
1007
1008 sub maybe_parens {
1009     my $self = shift;
1010     my($text, $cx, $prec) = @_;
1011     if ($prec < $cx              # unary ops nest just fine
1012         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1013         or $self->{'parens'})
1014     {
1015         $text = "($text)";
1016         # In a unop, let parent reuse our parens; see maybe_parens_unop
1017         $text = "\cS" . $text if $cx == 16;
1018         return $text;
1019     } else {
1020         return $text;
1021     }
1022 }
1023
1024 # same as above, but get around the `if it looks like a function' rule
1025 sub maybe_parens_unop {
1026     my $self = shift;
1027     my($name, $kid, $cx) = @_;
1028     if ($cx > 16 or $self->{'parens'}) {
1029         $kid =  $self->deparse($kid, 1);
1030         if ($name eq "umask" && $kid =~ /^\d+$/) {
1031             $kid = sprintf("%#o", $kid);
1032         }
1033         return $self->keyword($name) . "($kid)";
1034     } else {
1035         $kid = $self->deparse($kid, 16);
1036         if ($name eq "umask" && $kid =~ /^\d+$/) {
1037             $kid = sprintf("%#o", $kid);
1038         }
1039         $name = $self->keyword($name);
1040         if (substr($kid, 0, 1) eq "\cS") {
1041             # use kid's parens
1042             return $name . substr($kid, 1);
1043         } elsif (substr($kid, 0, 1) eq "(") {
1044             # avoid looks-like-a-function trap with extra parens
1045             # (`+' can lead to ambiguities)
1046             return "$name(" . $kid  . ")";
1047         } else {
1048             return "$name $kid";
1049         }
1050     }
1051 }
1052
1053 sub maybe_parens_func {
1054     my $self = shift;
1055     my($func, $text, $cx, $prec) = @_;
1056     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1057         return "$func($text)";
1058     } else {
1059         return "$func $text";
1060     }
1061 }
1062
1063 sub maybe_local {
1064     my $self = shift;
1065     my($op, $cx, $text) = @_;
1066     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1067     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1068         and not $self->{'avoid_local'}{$$op}) {
1069         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1070         if( $our_local eq 'our' ) {
1071             if ( $text !~ /^\W(\w+::)*\w+\z/
1072              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1073             ) {
1074                 die "Unexpected our($text)\n";
1075             }
1076             $text =~ s/(\w+::)+//;
1077         }
1078         if (want_scalar($op)) {
1079             return "$our_local $text";
1080         } else {
1081             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1082         }
1083     } else {
1084         return $text;
1085     }
1086 }
1087
1088 sub maybe_targmy {
1089     my $self = shift;
1090     my($op, $cx, $func, @args) = @_;
1091     if ($op->private & OPpTARGET_MY) {
1092         my $var = $self->padname($op->targ);
1093         my $val = $func->($self, $op, 7, @args);
1094         return $self->maybe_parens("$var = $val", $cx, 7);
1095     } else {
1096         return $func->($self, $op, $cx, @args);
1097     }
1098 }
1099
1100 sub padname_sv {
1101     my $self = shift;
1102     my $targ = shift;
1103     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1104 }
1105
1106 sub maybe_my {
1107     my $self = shift;
1108     my($op, $cx, $text) = @_;
1109     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1110         my $my = $op->private & OPpPAD_STATE
1111             ? $self->keyword("state")
1112             : "my";
1113         if (want_scalar($op)) {
1114             return "$my $text";
1115         } else {
1116             return $self->maybe_parens_func($my, $text, $cx, 16);
1117         }
1118     } else {
1119         return $text;
1120     }
1121 }
1122
1123 # The following OPs don't have functions:
1124
1125 # pp_padany -- does not exist after parsing
1126
1127 sub AUTOLOAD {
1128     if ($AUTOLOAD =~ s/^.*::pp_//) {
1129         warn "unexpected OP_".uc $AUTOLOAD;
1130         return "XXX";
1131     } else {
1132         die "Undefined subroutine $AUTOLOAD called";
1133     }
1134 }
1135
1136 sub DESTROY {}  #       Do not AUTOLOAD
1137
1138 # $root should be the op which represents the root of whatever
1139 # we're sequencing here. If it's undefined, then we don't append
1140 # any subroutine declarations to the deparsed ops, otherwise we
1141 # append appropriate declarations.
1142 sub lineseq {
1143     my($self, $root, @ops) = @_;
1144     my($expr, @exprs);
1145
1146     my $out_cop = $self->{'curcop'};
1147     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1148     my $limit_seq;
1149     if (defined $root) {
1150         $limit_seq = $out_seq;
1151         my $nseq;
1152         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1153         $limit_seq = $nseq if !defined($limit_seq)
1154                            or defined($nseq) && $nseq < $limit_seq;
1155     }
1156     $limit_seq = $self->{'limit_seq'}
1157         if defined($self->{'limit_seq'})
1158         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1159     local $self->{'limit_seq'} = $limit_seq;
1160
1161     $self->walk_lineseq($root, \@ops,
1162                        sub { push @exprs, $_[0]} );
1163
1164     my $body = join(";\n", grep {length} @exprs);
1165     my $subs = "";
1166     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1167         $subs = join "\n", $self->seq_subs($limit_seq);
1168     }
1169     return join(";\n", grep {length} $body, $subs);
1170 }
1171
1172 sub scopeop {
1173     my($real_block, $self, $op, $cx) = @_;
1174     my $kid;
1175     my @kids;
1176
1177     local(@$self{qw'curstash warnings hints hinthash'})
1178                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1179     if ($real_block) {
1180         $kid = $op->first->sibling; # skip enter
1181         if (is_miniwhile($kid)) {
1182             my $top = $kid->first;
1183             my $name = $top->name;
1184             if ($name eq "and") {
1185                 $name = "while";
1186             } elsif ($name eq "or") {
1187                 $name = "until";
1188             } else { # no conditional -> while 1 or until 0
1189                 return $self->deparse($top->first, 1) . " while 1";
1190             }
1191             my $cond = $top->first;
1192             my $body = $cond->sibling->first; # skip lineseq
1193             $cond = $self->deparse($cond, 1);
1194             $body = $self->deparse($body, 1);
1195             return "$body $name $cond";
1196         }
1197     } else {
1198         $kid = $op->first;
1199     }
1200     for (; !null($kid); $kid = $kid->sibling) {
1201         push @kids, $kid;
1202     }
1203     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1204         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1205     } else {
1206         my $lineseq = $self->lineseq($op, @kids);
1207         return (length ($lineseq) ? "$lineseq;" : "");
1208     }
1209 }
1210
1211 sub pp_scope { scopeop(0, @_); }
1212 sub pp_lineseq { scopeop(0, @_); }
1213 sub pp_leave { scopeop(1, @_); }
1214
1215 # This is a special case of scopeop and lineseq, for the case of the
1216 # main_root. The difference is that we print the output statements as
1217 # soon as we get them, for the sake of impatient users.
1218 sub deparse_root {
1219     my $self = shift;
1220     my($op) = @_;
1221     local(@$self{qw'curstash warnings hints hinthash'})
1222       = @$self{qw'curstash warnings hints hinthash'};
1223     my @kids;
1224     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1225     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1226         push @kids, $kid;
1227     }
1228     $self->walk_lineseq($op, \@kids,
1229                         sub { print $self->indent($_[0].';');
1230                               print "\n" unless $_[1] == $#kids;
1231                           });
1232 }
1233
1234 sub walk_lineseq {
1235     my ($self, $op, $kids, $callback) = @_;
1236     my @kids = @$kids;
1237     for (my $i = 0; $i < @kids; $i++) {
1238         my $expr = "";
1239         if (is_state $kids[$i]) {
1240             $expr = $self->deparse($kids[$i++], 0);
1241             if ($i > $#kids) {
1242                 $callback->($expr, $i);
1243                 last;
1244             }
1245         }
1246         if (is_for_loop($kids[$i])) {
1247             $callback->($expr . $self->for_loop($kids[$i], 0),
1248                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1249             next;
1250         }
1251         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1252         $expr =~ s/;\n?\z//;
1253         $callback->($expr, $i);
1254     }
1255 }
1256
1257 # The BEGIN {} is used here because otherwise this code isn't executed
1258 # when you run B::Deparse on itself.
1259 my %globalnames;
1260 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1261             "ENV", "ARGV", "ARGVOUT", "_"); }
1262
1263 sub gv_name {
1264     my $self = shift;
1265     my $gv = shift;
1266 Carp::confess() unless ref($gv) eq "B::GV";
1267     my $stash = $gv->STASH->NAME;
1268     my $name = $gv->SAFENAME;
1269     if ($stash eq 'main' && $name =~ /^::/) {
1270         $stash = '::';
1271     }
1272     elsif (($stash eq 'main' && $globalnames{$name})
1273         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1274             && ($stash eq 'main' || $name !~ /::/))
1275         or $name =~ /^[^A-Za-z_:]/)
1276     {
1277         $stash = "";
1278     } else {
1279         $stash = $stash . "::";
1280     }
1281     if ($name =~ /^(\^..|{)/) {
1282         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1283     }
1284     return $stash . $name;
1285 }
1286
1287 # Return the name to use for a stash variable.
1288 # If a lexical with the same name is in scope, it may need to be
1289 # fully-qualified.
1290 sub stash_variable {
1291     my ($self, $prefix, $name, $cx) = @_;
1292
1293     return "$prefix$name" if $name =~ /::/;
1294
1295     unless ($prefix eq '$' || $prefix eq '@' || #'
1296             $prefix eq '%' || $prefix eq '$#') {
1297         return "$prefix$name";
1298     }
1299
1300     if (defined $cx && $cx == 26) {
1301         if ($prefix eq '@' && $name =~ /^[^\w+-]$/) {
1302             return "$prefix\{$name}";
1303         }
1304     }
1305
1306     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1307     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1308     return "$prefix$name";
1309 }
1310
1311 sub lex_in_scope {
1312     my ($self, $name) = @_;
1313     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1314
1315     return 0 if !defined($self->{'curcop'});
1316     my $seq = $self->{'curcop'}->cop_seq;
1317     return 0 if !exists $self->{'curcvlex'}{$name};
1318     for my $a (@{$self->{'curcvlex'}{$name}}) {
1319         my ($st, $en) = @$a;
1320         return 1 if $seq > $st && $seq <= $en;
1321     }
1322     return 0;
1323 }
1324
1325 sub populate_curcvlex {
1326     my $self = shift;
1327     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1328         my $padlist = $cv->PADLIST;
1329         # an undef CV still in lexical chain
1330         next if class($padlist) eq "SPECIAL";
1331         my @padlist = $padlist->ARRAY;
1332         my @ns = $padlist[0]->ARRAY;
1333
1334         for (my $i=0; $i<@ns; ++$i) {
1335             next if class($ns[$i]) eq "SPECIAL";
1336             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1337             if (class($ns[$i]) eq "PV") {
1338                 # Probably that pesky lexical @_
1339                 next;
1340             }
1341             my $name = $ns[$i]->PVX;
1342             my ($seq_st, $seq_en) =
1343                 ($ns[$i]->FLAGS & SVf_FAKE)
1344                     ? (0, 999999)
1345                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1346
1347             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1348         }
1349     }
1350 }
1351
1352 sub find_scope_st { ((find_scope(@_))[0]); }
1353 sub find_scope_en { ((find_scope(@_))[1]); }
1354
1355 # Recurses down the tree, looking for pad variable introductions and COPs
1356 sub find_scope {
1357     my ($self, $op, $scope_st, $scope_en) = @_;
1358     carp("Undefined op in find_scope") if !defined $op;
1359     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1360
1361     my @queue = ($op);
1362     while(my $op = shift @queue ) {
1363         for (my $o=$op->first; $$o; $o=$o->sibling) {
1364             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1365                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1366                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1367                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1368                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1369                 return ($scope_st, $scope_en);
1370             }
1371             elsif (is_state($o)) {
1372                 my $c = $o->cop_seq;
1373                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1374                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1375                 return ($scope_st, $scope_en);
1376             }
1377             elsif ($o->flags & OPf_KIDS) {
1378                 unshift (@queue, $o);
1379             }
1380         }
1381     }
1382
1383     return ($scope_st, $scope_en);
1384 }
1385
1386 # Returns a list of subs which should be inserted before the COP
1387 sub cop_subs {
1388     my ($self, $op, $out_seq) = @_;
1389     my $seq = $op->cop_seq;
1390     # If we have nephews, then our sequence number indicates
1391     # the cop_seq of the end of some sort of scope.
1392     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1393         and my $nseq = $self->find_scope_st($op->sibling) ) {
1394         $seq = $nseq;
1395     }
1396     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1397     return $self->seq_subs($seq);
1398 }
1399
1400 sub seq_subs {
1401     my ($self, $seq) = @_;
1402     my @text;
1403 #push @text, "# ($seq)\n";
1404
1405     return "" if !defined $seq;
1406     while (scalar(@{$self->{'subs_todo'}})
1407            and $seq > $self->{'subs_todo'}[0][0]) {
1408         push @text, $self->next_todo;
1409     }
1410     return @text;
1411 }
1412
1413 # Notice how subs and formats are inserted between statements here;
1414 # also $[ assignments and pragmas.
1415 sub pp_nextstate {
1416     my $self = shift;
1417     my($op, $cx) = @_;
1418     $self->{'curcop'} = $op;
1419     my @text;
1420     push @text, $self->cop_subs($op);
1421     my $stash = $op->stashpv;
1422     if ($stash ne $self->{'curstash'}) {
1423         push @text, "package $stash;\n";
1424         $self->{'curstash'} = $stash;
1425     }
1426
1427     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1428         push @text, '$[ = '. $op->arybase .";\n";
1429         $self->{'arybase'} = $op->arybase;
1430     }
1431
1432     my $warnings = $op->warnings;
1433     my $warning_bits;
1434     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1435         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1436     }
1437     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1438         $warning_bits = $warnings::NONE;
1439     }
1440     elsif ($warnings->isa("B::SPECIAL")) {
1441         $warning_bits = undef;
1442     }
1443     else {
1444         $warning_bits = $warnings->PV & WARN_MASK;
1445     }
1446
1447     if (defined ($warning_bits) and
1448        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1449         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1450         $self->{'warnings'} = $warning_bits;
1451     }
1452
1453     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1454     if ($self->{'hints'} != $hints) {
1455         push @text, declare_hints($self->{'hints'}, $hints);
1456         $self->{'hints'} = $hints;
1457     }
1458
1459     # hack to check that the hint hash hasn't changed
1460     if ($] > 5.009 &&
1461         "@{[sort %{$self->{'hinthash'} || {}}]}"
1462         ne "@{[sort %{$op->hints_hash->HASH || {}}]}") {
1463         push @text, declare_hinthash($self->{'hinthash'}, $op->hints_hash->HASH, $self->{indent_size});
1464         $self->{'hinthash'} = $op->hints_hash->HASH;
1465     }
1466
1467     # This should go after of any branches that add statements, to
1468     # increase the chances that it refers to the same line it did in
1469     # the original program.
1470     if ($self->{'linenums'}) {
1471         push @text, "\f#line " . $op->line .
1472           ' "' . $op->file, qq'"\n';
1473     }
1474
1475     push @text, $op->label . ": " if $op->label;
1476
1477     return join("", @text);
1478 }
1479
1480 sub declare_warnings {
1481     my ($from, $to) = @_;
1482     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1483         return "use warnings;\n";
1484     }
1485     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1486         return "no warnings;\n";
1487     }
1488     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1489 }
1490
1491 sub declare_hints {
1492     my ($from, $to) = @_;
1493     my $use = $to   & ~$from;
1494     my $no  = $from & ~$to;
1495     my $decls = "";
1496     for my $pragma (hint_pragmas($use)) {
1497         $decls .= "use $pragma;\n";
1498     }
1499     for my $pragma (hint_pragmas($no)) {
1500         $decls .= "no $pragma;\n";
1501     }
1502     return $decls;
1503 }
1504
1505 # Internal implementation hints that the core sets automatically, so don't need
1506 # (or want) to be passed back to the user
1507 my %ignored_hints = (
1508     'open<' => 1,
1509     'open>' => 1,
1510     ':'     => 1,
1511 );
1512
1513 sub declare_hinthash {
1514     my ($from, $to, $indent) = @_;
1515     my @decls;
1516     for my $key (keys %$to) {
1517         next if $ignored_hints{$key};
1518         if (!defined $from->{$key} or $from->{$key} ne $to->{$key}) {
1519             push @decls, qq(\$^H{'$key'} = q($to->{$key}););
1520         }
1521     }
1522     for my $key (keys %$from) {
1523         next if $ignored_hints{$key};
1524         if (!exists $to->{$key}) {
1525             push @decls, qq(delete \$^H{'$key'};);
1526         }
1527     }
1528     @decls or return '';
1529     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1530 }
1531
1532 sub hint_pragmas {
1533     my ($bits) = @_;
1534     my @pragmas;
1535     push @pragmas, "integer" if $bits & 0x1;
1536     push @pragmas, "strict 'refs'" if $bits & 0x2;
1537     push @pragmas, "bytes" if $bits & 0x8;
1538     return @pragmas;
1539 }
1540
1541 sub pp_dbstate { pp_nextstate(@_) }
1542 sub pp_setstate { pp_nextstate(@_) }
1543
1544 sub pp_unstack { return "" } # see also leaveloop
1545
1546 my %feature_keywords = (
1547   # keyword => 'feature',
1548     state   => 'state',
1549     say     => 'say',
1550     given   => 'switch',
1551     when    => 'switch',
1552     default => 'switch',
1553     break   => 'switch',
1554 );
1555
1556 sub keyword {
1557     my $self = shift;
1558     my $name = shift;
1559     return $name if $name =~ /^CORE::/; # just in case
1560     if (exists $feature_keywords{$name}) {
1561         return
1562           $self->{'hinthash'}
1563            && $self->{'hinthash'}{"feature_$feature_keywords{$name}"}
1564             ? $name
1565             : "CORE::$name";
1566     }
1567     if (
1568       $name !~ /^(?:chom?p|exec|s(?:elect|ystem))\z/
1569        && !defined eval{prototype "CORE::$name"}
1570     ) { return $name }
1571     if (
1572         exists $self->{subs_declared}{$name}
1573          or
1574         exists &{"$self->{curstash}::$name"}
1575     ) {
1576         return "CORE::$name"
1577     }
1578     return $name;
1579 }
1580
1581 sub baseop {
1582     my $self = shift;
1583     my($op, $cx, $name) = @_;
1584     return $self->keyword($name);
1585 }
1586
1587 sub pp_stub {
1588     my $self = shift;
1589     my($op, $cx, $name) = @_;
1590     if ($cx >= 1) {
1591         return "()";
1592     }
1593     else {
1594         return "();";
1595     }
1596 }
1597 sub pp_wantarray { baseop(@_, "wantarray") }
1598 sub pp_fork { baseop(@_, "fork") }
1599 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1600 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1601 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1602 sub pp_tms { baseop(@_, "times") }
1603 sub pp_ghostent { baseop(@_, "gethostent") }
1604 sub pp_gnetent { baseop(@_, "getnetent") }
1605 sub pp_gprotoent { baseop(@_, "getprotoent") }
1606 sub pp_gservent { baseop(@_, "getservent") }
1607 sub pp_ehostent { baseop(@_, "endhostent") }
1608 sub pp_enetent { baseop(@_, "endnetent") }
1609 sub pp_eprotoent { baseop(@_, "endprotoent") }
1610 sub pp_eservent { baseop(@_, "endservent") }
1611 sub pp_gpwent { baseop(@_, "getpwent") }
1612 sub pp_spwent { baseop(@_, "setpwent") }
1613 sub pp_epwent { baseop(@_, "endpwent") }
1614 sub pp_ggrent { baseop(@_, "getgrent") }
1615 sub pp_sgrent { baseop(@_, "setgrent") }
1616 sub pp_egrent { baseop(@_, "endgrent") }
1617 sub pp_getlogin { baseop(@_, "getlogin") }
1618
1619 sub POSTFIX () { 1 }
1620
1621 # I couldn't think of a good short name, but this is the category of
1622 # symbolic unary operators with interesting precedence
1623
1624 sub pfixop {
1625     my $self = shift;
1626     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1627     my $kid = $op->first;
1628     $kid = $self->deparse($kid, $prec);
1629     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1630                                $cx, $prec);
1631 }
1632
1633 sub pp_preinc { pfixop(@_, "++", 23) }
1634 sub pp_predec { pfixop(@_, "--", 23) }
1635 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1636 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1637 sub pp_i_preinc { pfixop(@_, "++", 23) }
1638 sub pp_i_predec { pfixop(@_, "--", 23) }
1639 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1640 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1641 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1642
1643 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1644 sub real_negate {
1645     my $self = shift;
1646     my($op, $cx) = @_;
1647     if ($op->first->name =~ /^(i_)?negate$/) {
1648         # avoid --$x
1649         $self->pfixop($op, $cx, "-", 21.5);
1650     } else {
1651         $self->pfixop($op, $cx, "-", 21);       
1652     }
1653 }
1654 sub pp_i_negate { pp_negate(@_) }
1655
1656 sub pp_not {
1657     my $self = shift;
1658     my($op, $cx) = @_;
1659     if ($cx <= 4) {
1660         $self->pfixop($op, $cx, $self->keyword("not")." ", 4);
1661     } else {
1662         $self->pfixop($op, $cx, "!", 21);       
1663     }
1664 }
1665
1666 sub unop {
1667     my $self = shift;
1668     my($op, $cx, $name) = @_;
1669     my $kid;
1670     if ($op->flags & OPf_KIDS) {
1671         $kid = $op->first;
1672         if (not $name) {
1673             # this deals with 'boolkeys' right now
1674             return $self->deparse($kid,$cx);
1675         }
1676         my $builtinname = $name;
1677         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1678         if (defined prototype($builtinname)
1679            && prototype($builtinname) =~ /^;?\*/
1680            && $kid->name eq "rv2gv") {
1681             $kid = $kid->first;
1682         }
1683
1684         return $self->maybe_parens_unop($name, $kid, $cx);
1685     } else {
1686         return $self->keyword($name)
1687           . ($op->flags & OPf_SPECIAL ? "()" : "");
1688     }
1689 }
1690
1691 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1692 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1693 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1694 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1695 sub pp_defined { unop(@_, "defined") }
1696 sub pp_undef { unop(@_, "undef") }
1697 sub pp_study { unop(@_, "study") }
1698 sub pp_ref { unop(@_, "ref") }
1699 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1700
1701 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1702 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1703 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1704 sub pp_srand { unop(@_, "srand") }
1705 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1706 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1707 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1708 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1709 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1710 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1711 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1712
1713 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1714 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1715 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1716
1717 sub pp_each { unop(@_, "each") }
1718 sub pp_values { unop(@_, "values") }
1719 sub pp_keys { unop(@_, "keys") }
1720 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
1721 sub pp_boolkeys { 
1722     # no name because its an optimisation op that has no keyword
1723     unop(@_,"");
1724 }
1725 sub pp_aeach { unop(@_, "each") }
1726 sub pp_avalues { unop(@_, "values") }
1727 sub pp_akeys { unop(@_, "keys") }
1728 sub pp_pop { unop(@_, "pop") }
1729 sub pp_shift { unop(@_, "shift") }
1730
1731 sub pp_caller { unop(@_, "caller") }
1732 sub pp_reset { unop(@_, "reset") }
1733 sub pp_exit { unop(@_, "exit") }
1734 sub pp_prototype { unop(@_, "prototype") }
1735
1736 sub pp_close { unop(@_, "close") }
1737 sub pp_fileno { unop(@_, "fileno") }
1738 sub pp_umask { unop(@_, "umask") }
1739 sub pp_untie { unop(@_, "untie") }
1740 sub pp_tied { unop(@_, "tied") }
1741 sub pp_dbmclose { unop(@_, "dbmclose") }
1742 sub pp_getc { unop(@_, "getc") }
1743 sub pp_eof { unop(@_, "eof") }
1744 sub pp_tell { unop(@_, "tell") }
1745 sub pp_getsockname { unop(@_, "getsockname") }
1746 sub pp_getpeername { unop(@_, "getpeername") }
1747
1748 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1749 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1750 sub pp_readlink { unop(@_, "readlink") }
1751 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1752 sub pp_readdir { unop(@_, "readdir") }
1753 sub pp_telldir { unop(@_, "telldir") }
1754 sub pp_rewinddir { unop(@_, "rewinddir") }
1755 sub pp_closedir { unop(@_, "closedir") }
1756 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1757 sub pp_localtime { unop(@_, "localtime") }
1758 sub pp_gmtime { unop(@_, "gmtime") }
1759 sub pp_alarm { unop(@_, "alarm") }
1760 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1761
1762 sub pp_dofile { unop(@_, "do") }
1763 sub pp_entereval { unop(@_, "eval") }
1764
1765 sub pp_ghbyname { unop(@_, "gethostbyname") }
1766 sub pp_gnbyname { unop(@_, "getnetbyname") }
1767 sub pp_gpbyname { unop(@_, "getprotobyname") }
1768 sub pp_shostent { unop(@_, "sethostent") }
1769 sub pp_snetent { unop(@_, "setnetent") }
1770 sub pp_sprotoent { unop(@_, "setprotoent") }
1771 sub pp_sservent { unop(@_, "setservent") }
1772 sub pp_gpwnam { unop(@_, "getpwnam") }
1773 sub pp_gpwuid { unop(@_, "getpwuid") }
1774 sub pp_ggrnam { unop(@_, "getgrnam") }
1775 sub pp_ggrgid { unop(@_, "getgrgid") }
1776
1777 sub pp_lock { unop(@_, "lock") }
1778
1779 sub pp_continue { unop(@_, "continue"); }
1780 sub pp_break { unop(@_, "break"); }
1781
1782 sub givwhen {
1783     my $self = shift;
1784     my($op, $cx, $givwhen) = @_;
1785
1786     my $enterop = $op->first;
1787     my ($head, $block);
1788     if ($enterop->flags & OPf_SPECIAL) {
1789         $head = $self->keyword("default");
1790         $block = $self->deparse($enterop->first, 0);
1791     }
1792     else {
1793         my $cond = $enterop->first;
1794         my $cond_str = $self->deparse($cond, 1);
1795         $head = "$givwhen ($cond_str)";
1796         $block = $self->deparse($cond->sibling, 0);
1797     }
1798
1799     return "$head {\n".
1800         "\t$block\n".
1801         "\b}\cK";
1802 }
1803
1804 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
1805 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
1806
1807 sub pp_exists {
1808     my $self = shift;
1809     my($op, $cx) = @_;
1810     my $arg;
1811     if ($op->private & OPpEXISTS_SUB) {
1812         # Checking for the existence of a subroutine
1813         return $self->maybe_parens_func("exists",
1814                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1815     }
1816     if ($op->flags & OPf_SPECIAL) {
1817         # Array element, not hash element
1818         return $self->maybe_parens_func("exists",
1819                                 $self->pp_aelem($op->first, 16), $cx, 16);
1820     }
1821     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1822                                     $cx, 16);
1823 }
1824
1825 sub pp_delete {
1826     my $self = shift;
1827     my($op, $cx) = @_;
1828     my $arg;
1829     if ($op->private & OPpSLICE) {
1830         if ($op->flags & OPf_SPECIAL) {
1831             # Deleting from an array, not a hash
1832             return $self->maybe_parens_func("delete",
1833                                         $self->pp_aslice($op->first, 16),
1834                                         $cx, 16);
1835         }
1836         return $self->maybe_parens_func("delete",
1837                                         $self->pp_hslice($op->first, 16),
1838                                         $cx, 16);
1839     } else {
1840         if ($op->flags & OPf_SPECIAL) {
1841             # Deleting from an array, not a hash
1842             return $self->maybe_parens_func("delete",
1843                                         $self->pp_aelem($op->first, 16),
1844                                         $cx, 16);
1845         }
1846         return $self->maybe_parens_func("delete",
1847                                         $self->pp_helem($op->first, 16),
1848                                         $cx, 16);
1849     }
1850 }
1851
1852 sub pp_require {
1853     my $self = shift;
1854     my($op, $cx) = @_;
1855     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1856     if (class($op) eq "UNOP" and $op->first->name eq "const"
1857         and $op->first->private & OPpCONST_BARE)
1858     {
1859         my $name = $self->const_sv($op->first)->PV;
1860         $name =~ s[/][::]g;
1861         $name =~ s/\.pm//g;
1862         return "$opname $name";
1863     } else {    
1864         $self->unop($op, $cx, $op->first->private & OPpCONST_NOVER ? "no" : $opname);
1865     }
1866 }
1867
1868 sub pp_scalar {
1869     my $self = shift;
1870     my($op, $cx) = @_;
1871     my $kid = $op->first;
1872     if (not null $kid->sibling) {
1873         # XXX Was a here-doc
1874         return $self->dquote($op);
1875     }
1876     $self->unop(@_, "scalar");
1877 }
1878
1879
1880 sub padval {
1881     my $self = shift;
1882     my $targ = shift;
1883     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1884 }
1885
1886 sub anon_hash_or_list {
1887     my $self = shift;
1888     my($op, $cx) = @_;
1889
1890     my($pre, $post) = @{{"anonlist" => ["[","]"],
1891                          "anonhash" => ["{","}"]}->{$op->name}};
1892     my($expr, @exprs);
1893     $op = $op->first->sibling; # skip pushmark
1894     for (; !null($op); $op = $op->sibling) {
1895         $expr = $self->deparse($op, 6);
1896         push @exprs, $expr;
1897     }
1898     if ($pre eq "{" and $cx < 1) {
1899         # Disambiguate that it's not a block
1900         $pre = "+{";
1901     }
1902     return $pre . join(", ", @exprs) . $post;
1903 }
1904
1905 sub pp_anonlist {
1906     my $self = shift;
1907     my ($op, $cx) = @_;
1908     if ($op->flags & OPf_SPECIAL) {
1909         return $self->anon_hash_or_list($op, $cx);
1910     }
1911     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1912     return 'XXX';
1913 }
1914
1915 *pp_anonhash = \&pp_anonlist;
1916
1917 sub pp_refgen {
1918     my $self = shift;   
1919     my($op, $cx) = @_;
1920     my $kid = $op->first;
1921     if ($kid->name eq "null") {
1922         $kid = $kid->first;
1923         if (!null($kid->sibling) and
1924                  $kid->sibling->name eq "anoncode") {
1925             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1926         } elsif ($kid->name eq "pushmark") {
1927             my $sib_name = $kid->sibling->name;
1928             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1929                 and not $kid->sibling->flags & OPf_REF)
1930             {
1931                 # The @a in \(@a) isn't in ref context, but only when the
1932                 # parens are there.
1933                 return "\\(" . $self->pp_list($op->first) . ")";
1934             } elsif ($sib_name eq 'entersub') {
1935                 my $text = $self->deparse($kid->sibling, 1);
1936                 # Always show parens for \(&func()), but only with -p otherwise
1937                 $text = "($text)" if $self->{'parens'}
1938                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1939                 return "\\$text";
1940             }
1941         }
1942     }
1943     $self->pfixop($op, $cx, "\\", 20);
1944 }
1945
1946 sub e_anoncode {
1947     my ($self, $info) = @_;
1948     my $text = $self->deparse_sub($info->{code});
1949     return "sub " . $text;
1950 }
1951
1952 sub pp_srefgen { pp_refgen(@_) }
1953
1954 sub pp_readline {
1955     my $self = shift;
1956     my($op, $cx) = @_;
1957     my $kid = $op->first;
1958     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1959     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1960     return $self->unop($op, $cx, "readline");
1961 }
1962
1963 sub pp_rcatline {
1964     my $self = shift;
1965     my($op) = @_;
1966     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1967 }
1968
1969 # Unary operators that can occur as pseudo-listops inside double quotes
1970 sub dq_unop {
1971     my $self = shift;
1972     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1973     my $kid;
1974     if ($op->flags & OPf_KIDS) {
1975        $kid = $op->first;
1976        # If there's more than one kid, the first is an ex-pushmark.
1977        $kid = $kid->sibling if not null $kid->sibling;
1978        return $self->maybe_parens_unop($name, $kid, $cx);
1979     } else {
1980        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1981     }
1982 }
1983
1984 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1985 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1986 sub pp_uc { dq_unop(@_, "uc") }
1987 sub pp_lc { dq_unop(@_, "lc") }
1988 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1989
1990 sub loopex {
1991     my $self = shift;
1992     my ($op, $cx, $name) = @_;
1993     if (class($op) eq "PVOP") {
1994         return "$name " . $op->pv;
1995     } elsif (class($op) eq "OP") {
1996         return $name;
1997     } elsif (class($op) eq "UNOP") {
1998         # Note -- loop exits are actually exempt from the
1999         # looks-like-a-func rule, but a few extra parens won't hurt
2000         return $self->maybe_parens_unop($name, $op->first, $cx);
2001     }
2002 }
2003
2004 sub pp_last { loopex(@_, "last") }
2005 sub pp_next { loopex(@_, "next") }
2006 sub pp_redo { loopex(@_, "redo") }
2007 sub pp_goto { loopex(@_, "goto") }
2008 sub pp_dump { loopex(@_, $_[0]->keyword("dump")) }
2009
2010 sub ftst {
2011     my $self = shift;
2012     my($op, $cx, $name) = @_;
2013     if (class($op) eq "UNOP") {
2014         # Genuine `-X' filetests are exempt from the LLAFR, but not
2015         # l?stat(); for the sake of clarity, give'em all parens
2016         return $self->maybe_parens_unop($name, $op->first, $cx);
2017     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2018         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2019     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2020         return $name;
2021     }
2022 }
2023
2024 sub pp_lstat    { ftst(@_, "lstat") }
2025 sub pp_stat     { ftst(@_, "stat") }
2026 sub pp_ftrread  { ftst(@_, "-R") }
2027 sub pp_ftrwrite { ftst(@_, "-W") }
2028 sub pp_ftrexec  { ftst(@_, "-X") }
2029 sub pp_fteread  { ftst(@_, "-r") }
2030 sub pp_ftewrite { ftst(@_, "-w") }
2031 sub pp_fteexec  { ftst(@_, "-x") }
2032 sub pp_ftis     { ftst(@_, "-e") }
2033 sub pp_fteowned { ftst(@_, "-O") }
2034 sub pp_ftrowned { ftst(@_, "-o") }
2035 sub pp_ftzero   { ftst(@_, "-z") }
2036 sub pp_ftsize   { ftst(@_, "-s") }
2037 sub pp_ftmtime  { ftst(@_, "-M") }
2038 sub pp_ftatime  { ftst(@_, "-A") }
2039 sub pp_ftctime  { ftst(@_, "-C") }
2040 sub pp_ftsock   { ftst(@_, "-S") }
2041 sub pp_ftchr    { ftst(@_, "-c") }
2042 sub pp_ftblk    { ftst(@_, "-b") }
2043 sub pp_ftfile   { ftst(@_, "-f") }
2044 sub pp_ftdir    { ftst(@_, "-d") }
2045 sub pp_ftpipe   { ftst(@_, "-p") }
2046 sub pp_ftlink   { ftst(@_, "-l") }
2047 sub pp_ftsuid   { ftst(@_, "-u") }
2048 sub pp_ftsgid   { ftst(@_, "-g") }
2049 sub pp_ftsvtx   { ftst(@_, "-k") }
2050 sub pp_fttty    { ftst(@_, "-t") }
2051 sub pp_fttext   { ftst(@_, "-T") }
2052 sub pp_ftbinary { ftst(@_, "-B") }
2053
2054 sub SWAP_CHILDREN () { 1 }
2055 sub ASSIGN () { 2 } # has OP= variant
2056 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2057
2058 my(%left, %right);
2059
2060 sub assoc_class {
2061     my $op = shift;
2062     my $name = $op->name;
2063     if ($name eq "concat" and $op->first->name eq "concat") {
2064         # avoid spurious `=' -- see comment in pp_concat
2065         return "concat";
2066     }
2067     if ($name eq "null" and class($op) eq "UNOP"
2068         and $op->first->name =~ /^(and|x?or)$/
2069         and null $op->first->sibling)
2070     {
2071         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2072         # with a null that's used as the common end point of the two
2073         # flows of control. For precedence purposes, ignore it.
2074         # (COND_EXPRs have these too, but we don't bother with
2075         # their associativity).
2076         return assoc_class($op->first);
2077     }
2078     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2079 }
2080
2081 # Left associative operators, like `+', for which
2082 # $a + $b + $c is equivalent to ($a + $b) + $c
2083
2084 BEGIN {
2085     %left = ('multiply' => 19, 'i_multiply' => 19,
2086              'divide' => 19, 'i_divide' => 19,
2087              'modulo' => 19, 'i_modulo' => 19,
2088              'repeat' => 19,
2089              'add' => 18, 'i_add' => 18,
2090              'subtract' => 18, 'i_subtract' => 18,
2091              'concat' => 18,
2092              'left_shift' => 17, 'right_shift' => 17,
2093              'bit_and' => 13,
2094              'bit_or' => 12, 'bit_xor' => 12,
2095              'and' => 3,
2096              'or' => 2, 'xor' => 2,
2097             );
2098 }
2099
2100 sub deparse_binop_left {
2101     my $self = shift;
2102     my($op, $left, $prec) = @_;
2103     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2104         and $left{assoc_class($op)} == $left{assoc_class($left)})
2105     {
2106         return $self->deparse($left, $prec - .00001);
2107     } else {
2108         return $self->deparse($left, $prec);    
2109     }
2110 }
2111
2112 # Right associative operators, like `=', for which
2113 # $a = $b = $c is equivalent to $a = ($b = $c)
2114
2115 BEGIN {
2116     %right = ('pow' => 22,
2117               'sassign=' => 7, 'aassign=' => 7,
2118               'multiply=' => 7, 'i_multiply=' => 7,
2119               'divide=' => 7, 'i_divide=' => 7,
2120               'modulo=' => 7, 'i_modulo=' => 7,
2121               'repeat=' => 7,
2122               'add=' => 7, 'i_add=' => 7,
2123               'subtract=' => 7, 'i_subtract=' => 7,
2124               'concat=' => 7,
2125               'left_shift=' => 7, 'right_shift=' => 7,
2126               'bit_and=' => 7,
2127               'bit_or=' => 7, 'bit_xor=' => 7,
2128               'andassign' => 7,
2129               'orassign' => 7,
2130              );
2131 }
2132
2133 sub deparse_binop_right {
2134     my $self = shift;
2135     my($op, $right, $prec) = @_;
2136     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2137         and $right{assoc_class($op)} == $right{assoc_class($right)})
2138     {
2139         return $self->deparse($right, $prec - .00001);
2140     } else {
2141         return $self->deparse($right, $prec);   
2142     }
2143 }
2144
2145 sub binop {
2146     my $self = shift;
2147     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2148     my $left = $op->first;
2149     my $right = $op->last;
2150     my $eq = "";
2151     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2152         $eq = "=";
2153         $prec = 7;
2154     }
2155     if ($flags & SWAP_CHILDREN) {
2156         ($left, $right) = ($right, $left);
2157     }
2158     $left = $self->deparse_binop_left($op, $left, $prec);
2159     $left = "($left)" if $flags & LIST_CONTEXT
2160                 && $left !~ /^(my|our|local|)[\@\(]/;
2161     $right = $self->deparse_binop_right($op, $right, $prec);
2162     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2163 }
2164
2165 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2166 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2167 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2168 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2169 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2170 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2171 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2172 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2173 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2174 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2175 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2176
2177 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2178 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2179 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2180 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2181 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2182
2183 sub pp_eq { binop(@_, "==", 14) }
2184 sub pp_ne { binop(@_, "!=", 14) }
2185 sub pp_lt { binop(@_, "<", 15) }
2186 sub pp_gt { binop(@_, ">", 15) }
2187 sub pp_ge { binop(@_, ">=", 15) }
2188 sub pp_le { binop(@_, "<=", 15) }
2189 sub pp_ncmp { binop(@_, "<=>", 14) }
2190 sub pp_i_eq { binop(@_, "==", 14) }
2191 sub pp_i_ne { binop(@_, "!=", 14) }
2192 sub pp_i_lt { binop(@_, "<", 15) }
2193 sub pp_i_gt { binop(@_, ">", 15) }
2194 sub pp_i_ge { binop(@_, ">=", 15) }
2195 sub pp_i_le { binop(@_, "<=", 15) }
2196 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2197
2198 sub pp_seq { binop(@_, "eq", 14) }
2199 sub pp_sne { binop(@_, "ne", 14) }
2200 sub pp_slt { binop(@_, "lt", 15) }
2201 sub pp_sgt { binop(@_, "gt", 15) }
2202 sub pp_sge { binop(@_, "ge", 15) }
2203 sub pp_sle { binop(@_, "le", 15) }
2204 sub pp_scmp { binop(@_, "cmp", 14) }
2205
2206 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2207 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2208
2209 sub pp_smartmatch {
2210     my ($self, $op, $cx) = @_;
2211     if ($op->flags & OPf_SPECIAL) {
2212         return $self->deparse($op->last, $cx);
2213     }
2214     else {
2215         binop(@_, "~~", 14);
2216     }
2217 }
2218
2219 # `.' is special because concats-of-concats are optimized to save copying
2220 # by making all but the first concat stacked. The effect is as if the
2221 # programmer had written `($a . $b) .= $c', except legal.
2222 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2223 sub real_concat {
2224     my $self = shift;
2225     my($op, $cx) = @_;
2226     my $left = $op->first;
2227     my $right = $op->last;
2228     my $eq = "";
2229     my $prec = 18;
2230     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2231         $eq = "=";
2232         $prec = 7;
2233     }
2234     $left = $self->deparse_binop_left($op, $left, $prec);
2235     $right = $self->deparse_binop_right($op, $right, $prec);
2236     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2237 }
2238
2239 # `x' is weird when the left arg is a list
2240 sub pp_repeat {
2241     my $self = shift;
2242     my($op, $cx) = @_;
2243     my $left = $op->first;
2244     my $right = $op->last;
2245     my $eq = "";
2246     my $prec = 19;
2247     if ($op->flags & OPf_STACKED) {
2248         $eq = "=";
2249         $prec = 7;
2250     }
2251     if (null($right)) { # list repeat; count is inside left-side ex-list
2252         my $kid = $left->first->sibling; # skip pushmark
2253         my @exprs;
2254         for (; !null($kid->sibling); $kid = $kid->sibling) {
2255             push @exprs, $self->deparse($kid, 6);
2256         }
2257         $right = $kid;
2258         $left = "(" . join(", ", @exprs). ")";
2259     } else {
2260         $left = $self->deparse_binop_left($op, $left, $prec);
2261     }
2262     $right = $self->deparse_binop_right($op, $right, $prec);
2263     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2264 }
2265
2266 sub range {
2267     my $self = shift;
2268     my ($op, $cx, $type) = @_;
2269     my $left = $op->first;
2270     my $right = $left->sibling;
2271     $left = $self->deparse($left, 9);
2272     $right = $self->deparse($right, 9);
2273     return $self->maybe_parens("$left $type $right", $cx, 9);
2274 }
2275
2276 sub pp_flop {
2277     my $self = shift;
2278     my($op, $cx) = @_;
2279     my $flip = $op->first;
2280     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2281     return $self->range($flip->first, $cx, $type);
2282 }
2283
2284 # one-line while/until is handled in pp_leave
2285
2286 sub logop {
2287     my $self = shift;
2288     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2289     my $left = $op->first;
2290     my $right = $op->first->sibling;
2291     if ($cx < 1 and is_scope($right) and $blockname
2292         and $self->{'expand'} < 7)
2293     { # if ($a) {$b}
2294         $left = $self->deparse($left, 1);
2295         $right = $self->deparse($right, 0);
2296         return "$blockname ($left) {\n\t$right\n\b}\cK";
2297     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2298              and $self->{'expand'} < 7) { # $b if $a
2299         $right = $self->deparse($right, 1);
2300         $left = $self->deparse($left, 1);
2301         return "$right $blockname $left";
2302     } elsif ($cx > $lowprec and $highop) { # $a && $b
2303         $left = $self->deparse_binop_left($op, $left, $highprec);
2304         $right = $self->deparse_binop_right($op, $right, $highprec);
2305         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2306     } else { # $a and $b
2307         $left = $self->deparse_binop_left($op, $left, $lowprec);
2308         $right = $self->deparse_binop_right($op, $right, $lowprec);
2309         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2310     }
2311 }
2312
2313 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2314 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2315 sub pp_dor { logop(@_, "//", 10) }
2316
2317 # xor is syntactically a logop, but it's really a binop (contrary to
2318 # old versions of opcode.pl). Syntax is what matters here.
2319 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2320
2321 sub logassignop {
2322     my $self = shift;
2323     my ($op, $cx, $opname) = @_;
2324     my $left = $op->first;
2325     my $right = $op->first->sibling->first; # skip sassign
2326     $left = $self->deparse($left, 7);
2327     $right = $self->deparse($right, 7);
2328     return $self->maybe_parens("$left $opname $right", $cx, 7);
2329 }
2330
2331 sub pp_andassign { logassignop(@_, "&&=") }
2332 sub pp_orassign  { logassignop(@_, "||=") }
2333 sub pp_dorassign { logassignop(@_, "//=") }
2334
2335 sub listop {
2336     my $self = shift;
2337     my($op, $cx, $name) = @_;
2338     my(@exprs);
2339     my $parens = ($cx >= 5) || $self->{'parens'};
2340     my $kid = $op->first->sibling;
2341     return $self->keyword($name) if null $kid;
2342     my $first;
2343     $name = "socketpair" if $name eq "sockpair";
2344     my $fullname = $self->keyword($name);
2345     my $proto = prototype("CORE::$name");
2346     if (defined $proto
2347         && $proto =~ /^;?\*/
2348         && $kid->name eq "rv2gv") {
2349         $first = $self->deparse($kid->first, 6);
2350     }
2351     else {
2352         $first = $self->deparse($kid, 6);
2353     }
2354     if ($name eq "chmod" && $first =~ /^\d+$/) {
2355         $first = sprintf("%#o", $first);
2356     }
2357     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2358     push @exprs, $first;
2359     $kid = $kid->sibling;
2360     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2361         push @exprs, $self->deparse($kid->first, 6);
2362         $kid = $kid->sibling;
2363     }
2364     for (; !null($kid); $kid = $kid->sibling) {
2365         push @exprs, $self->deparse($kid, 6);
2366     }
2367     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2368         return "$exprs[0] = $fullname"
2369                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2370     }
2371     if ($parens) {
2372         return "$fullname(" . join(", ", @exprs) . ")";
2373     } else {
2374         return "$fullname " . join(", ", @exprs);
2375     }
2376 }
2377
2378 sub pp_bless { listop(@_, "bless") }
2379 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2380 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2381 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2382 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2383 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2384 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2385 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2386 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2387 sub pp_unpack { listop(@_, "unpack") }
2388 sub pp_pack { listop(@_, "pack") }
2389 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2390 sub pp_splice { listop(@_, "splice") }
2391 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2392 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2393 sub pp_reverse { listop(@_, "reverse") }
2394 sub pp_warn { listop(@_, "warn") }
2395 sub pp_die { listop(@_, "die") }
2396 # Actually, return is exempt from the LLAFR (see examples in this very
2397 # module!), but for consistency's sake, ignore that fact
2398 sub pp_return { listop(@_, "return") }
2399 sub pp_open { listop(@_, "open") }
2400 sub pp_pipe_op { listop(@_, "pipe") }
2401 sub pp_tie { listop(@_, "tie") }
2402 sub pp_binmode { listop(@_, "binmode") }
2403 sub pp_dbmopen { listop(@_, "dbmopen") }
2404 sub pp_sselect { listop(@_, "select") }
2405 sub pp_select { listop(@_, "select") }
2406 sub pp_read { listop(@_, "read") }
2407 sub pp_sysopen { listop(@_, "sysopen") }
2408 sub pp_sysseek { listop(@_, "sysseek") }
2409 sub pp_sysread { listop(@_, "sysread") }
2410 sub pp_syswrite { listop(@_, "syswrite") }
2411 sub pp_send { listop(@_, "send") }
2412 sub pp_recv { listop(@_, "recv") }
2413 sub pp_seek { listop(@_, "seek") }
2414 sub pp_fcntl { listop(@_, "fcntl") }
2415 sub pp_ioctl { listop(@_, "ioctl") }
2416 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2417 sub pp_socket { listop(@_, "socket") }
2418 sub pp_sockpair { listop(@_, "sockpair") }
2419 sub pp_bind { listop(@_, "bind") }
2420 sub pp_connect { listop(@_, "connect") }
2421 sub pp_listen { listop(@_, "listen") }
2422 sub pp_accept { listop(@_, "accept") }
2423 sub pp_shutdown { listop(@_, "shutdown") }
2424 sub pp_gsockopt { listop(@_, "getsockopt") }
2425 sub pp_ssockopt { listop(@_, "setsockopt") }
2426 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2427 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2428 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2429 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2430 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2431 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2432 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2433 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2434 sub pp_open_dir { listop(@_, "opendir") }
2435 sub pp_seekdir { listop(@_, "seekdir") }
2436 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2437 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2438 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2439 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2440 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2441 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2442 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2443 sub pp_shmget { listop(@_, "shmget") }
2444 sub pp_shmctl { listop(@_, "shmctl") }
2445 sub pp_shmread { listop(@_, "shmread") }
2446 sub pp_shmwrite { listop(@_, "shmwrite") }
2447 sub pp_msgget { listop(@_, "msgget") }
2448 sub pp_msgctl { listop(@_, "msgctl") }
2449 sub pp_msgsnd { listop(@_, "msgsnd") }
2450 sub pp_msgrcv { listop(@_, "msgrcv") }
2451 sub pp_semget { listop(@_, "semget") }
2452 sub pp_semctl { listop(@_, "semctl") }
2453 sub pp_semop { listop(@_, "semop") }
2454 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2455 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2456 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2457 sub pp_gsbyname { listop(@_, "getservbyname") }
2458 sub pp_gsbyport { listop(@_, "getservbyport") }
2459 sub pp_syscall { listop(@_, "syscall") }
2460
2461 sub pp_glob {
2462     my $self = shift;
2463     my($op, $cx) = @_;
2464     my $text = $self->dq($op->first->sibling);  # skip pushmark
2465     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2466         or $text =~ /[<>]/) {
2467         return 'glob(' . single_delim('qq', '"', $text) . ')';
2468     } else {
2469         return '<' . $text . '>';
2470     }
2471 }
2472
2473 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2474 # be a filehandle. This could probably be better fixed in the core
2475 # by moving the GV lookup into ck_truc.
2476
2477 sub pp_truncate {
2478     my $self = shift;
2479     my($op, $cx) = @_;
2480     my(@exprs);
2481     my $parens = ($cx >= 5) || $self->{'parens'};
2482     my $kid = $op->first->sibling;
2483     my $fh;
2484     if ($op->flags & OPf_SPECIAL) {
2485         # $kid is an OP_CONST
2486         $fh = $self->const_sv($kid)->PV;
2487     } else {
2488         $fh = $self->deparse($kid, 6);
2489         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2490     }
2491     my $len = $self->deparse($kid->sibling, 6);
2492     my $name = $self->keyword('truncate');
2493     if ($parens) {
2494         return "$name($fh, $len)";
2495     } else {
2496         return "$name $fh, $len";
2497     }
2498 }
2499
2500 sub indirop {
2501     my $self = shift;
2502     my($op, $cx, $name) = @_;
2503     my($expr, @exprs);
2504     my $kid = $op->first->sibling;
2505     my $indir = "";
2506     if ($op->flags & OPf_STACKED) {
2507         $indir = $kid;
2508         $indir = $indir->first; # skip rv2gv
2509         if (is_scope($indir)) {
2510             $indir = "{" . $self->deparse($indir, 0) . "}";
2511             $indir = "{;}" if $indir eq "{}";
2512         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2513             $indir = $self->const_sv($indir)->PV;
2514         } else {
2515             $indir = $self->deparse($indir, 24);
2516         }
2517         $indir = $indir . " ";
2518         $kid = $kid->sibling;
2519     }
2520     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2521         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2522                                                   : '{$a <=> $b} ';
2523     }
2524     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2525         $indir = '{$b cmp $a} ';
2526     }
2527     for (; !null($kid); $kid = $kid->sibling) {
2528         $expr = $self->deparse($kid, 6);
2529         push @exprs, $expr;
2530     }
2531     my $name2;
2532     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2533         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2534     }
2535     else { $name2 = $self->keyword($name) }
2536     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2537         return "$exprs[0] = $name2 $indir $exprs[0]";
2538     }
2539
2540     my $args = $indir . join(", ", @exprs);
2541     if ($indir ne "" and $name eq "sort") {
2542         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2543         # give bareword warnings in that case. Therefore if context
2544         # requires, we'll put parens around the outside "(sort f 1, 2,
2545         # 3)". Unfortunately, we'll currently think the parens are
2546         # necessary more often that they really are, because we don't
2547         # distinguish which side of an assignment we're on.
2548         if ($cx >= 5) {
2549             return "($name2 $args)";
2550         } else {
2551             return "$name2 $args";
2552         }
2553     } else {
2554         return $self->maybe_parens_func($name2, $args, $cx, 5);
2555     }
2556
2557 }
2558
2559 sub pp_prtf { indirop(@_, "printf") }
2560 sub pp_print { indirop(@_, "print") }
2561 sub pp_say  { indirop(@_, "say") }
2562 sub pp_sort { indirop(@_, "sort") }
2563
2564 sub mapop {
2565     my $self = shift;
2566     my($op, $cx, $name) = @_;
2567     my($expr, @exprs);
2568     my $kid = $op->first; # this is the (map|grep)start
2569     $kid = $kid->first->sibling; # skip a pushmark
2570     my $code = $kid->first; # skip a null
2571     if (is_scope $code) {
2572         $code = "{" . $self->deparse($code, 0) . "} ";
2573     } else {
2574         $code = $self->deparse($code, 24) . ", ";
2575     }
2576     $kid = $kid->sibling;
2577     for (; !null($kid); $kid = $kid->sibling) {
2578         $expr = $self->deparse($kid, 6);
2579         push @exprs, $expr if defined $expr;
2580     }
2581     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2582 }
2583
2584 sub pp_mapwhile { mapop(@_, "map") }
2585 sub pp_grepwhile { mapop(@_, "grep") }
2586 sub pp_mapstart { baseop(@_, "map") }
2587 sub pp_grepstart { baseop(@_, "grep") }
2588
2589 sub pp_list {
2590     my $self = shift;
2591     my($op, $cx) = @_;
2592     my($expr, @exprs);
2593     my $kid = $op->first->sibling; # skip pushmark
2594     my $lop;
2595     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2596     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2597         # This assumes that no other private flags equal 128, and that
2598         # OPs that store things other than flags in their op_private,
2599         # like OP_AELEMFAST, won't be immediate children of a list.
2600         #
2601         # OP_ENTERSUB can break this logic, so check for it.
2602         # I suspect that open and exit can too.
2603
2604         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2605                 or $lop->name eq "undef")
2606             or $lop->name eq "entersub"
2607             or $lop->name eq "exit"
2608             or $lop->name eq "open")
2609         {
2610             $local = ""; # or not
2611             last;
2612         }
2613         if ($lop->name =~ /^pad[ash]v$/) {
2614             if ($lop->private & OPpPAD_STATE) { # state()
2615                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2616                 $local = "state";
2617             } else { # my()
2618                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2619                 $local = "my";
2620             }
2621         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2622                         && $lop->private & OPpOUR_INTRO
2623                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2624                         && $lop->first->private & OPpOUR_INTRO) { # our()
2625             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2626             $local = "our";
2627         } elsif ($lop->name ne "undef"
2628                 # specifically avoid the "reverse sort" optimisation,
2629                 # where "reverse" is nullified
2630                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2631         {
2632             # local()
2633             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2634             $local = "local";
2635         }
2636     }
2637     $local = "" if $local eq "either"; # no point if it's all undefs
2638     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2639     for (; !null($kid); $kid = $kid->sibling) {
2640         if ($local) {
2641             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2642                 $lop = $kid->first;
2643             } else {
2644                 $lop = $kid;
2645             }
2646             $self->{'avoid_local'}{$$lop}++;
2647             $expr = $self->deparse($kid, 6);
2648             delete $self->{'avoid_local'}{$$lop};
2649         } else {
2650             $expr = $self->deparse($kid, 6);
2651         }
2652         push @exprs, $expr;
2653     }
2654     if ($local) {
2655         return "$local(" . join(", ", @exprs) . ")";
2656     } else {
2657         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
2658     }
2659 }
2660
2661 sub is_ifelse_cont {
2662     my $op = shift;
2663     return ($op->name eq "null" and class($op) eq "UNOP"
2664             and $op->first->name =~ /^(and|cond_expr)$/
2665             and is_scope($op->first->first->sibling));
2666 }
2667
2668 sub pp_cond_expr {
2669     my $self = shift;
2670     my($op, $cx) = @_;
2671     my $cond = $op->first;
2672     my $true = $cond->sibling;
2673     my $false = $true->sibling;
2674     my $cuddle = $self->{'cuddle'};
2675     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2676             (is_scope($false) || is_ifelse_cont($false))
2677             and $self->{'expand'} < 7) {
2678         $cond = $self->deparse($cond, 8);
2679         $true = $self->deparse($true, 6);
2680         $false = $self->deparse($false, 8);
2681         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2682     }
2683
2684     $cond = $self->deparse($cond, 1);
2685     $true = $self->deparse($true, 0);
2686     my $head = "if ($cond) {\n\t$true\n\b}";
2687     my @elsifs;
2688     while (!null($false) and is_ifelse_cont($false)) {
2689         my $newop = $false->first;
2690         my $newcond = $newop->first;
2691         my $newtrue = $newcond->sibling;
2692         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2693         if ($newcond->name eq "lineseq")
2694         {
2695             # lineseq to ensure correct line numbers in elsif()
2696             # Bug #37302 fixed by change #33710.
2697             $newcond = $newcond->first->sibling;
2698         }
2699         $newcond = $self->deparse($newcond, 1);
2700         $newtrue = $self->deparse($newtrue, 0);
2701         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2702     }
2703     if (!null($false)) {
2704         $false = $cuddle . "else {\n\t" .
2705           $self->deparse($false, 0) . "\n\b}\cK";
2706     } else {
2707         $false = "\cK";
2708     }
2709     return $head . join($cuddle, "", @elsifs) . $false;
2710 }
2711
2712 sub pp_once {
2713     my ($self, $op, $cx) = @_;
2714     my $cond = $op->first;
2715     my $true = $cond->sibling;
2716
2717     return $self->deparse($true, $cx);
2718 }
2719
2720 sub loop_common {
2721     my $self = shift;
2722     my($op, $cx, $init) = @_;
2723     my $enter = $op->first;
2724     my $kid = $enter->sibling;
2725     local(@$self{qw'curstash warnings hints hinthash'})
2726                 = @$self{qw'curstash warnings hints hinthash'};
2727     my $head = "";
2728     my $bare = 0;
2729     my $body;
2730     my $cond = undef;
2731     if ($kid->name eq "lineseq") { # bare or infinite loop
2732         if ($kid->last->name eq "unstack") { # infinite
2733             $head = "while (1) "; # Can't use for(;;) if there's a continue
2734             $cond = "";
2735         } else {
2736             $bare = 1;
2737         }
2738         $body = $kid;
2739     } elsif ($enter->name eq "enteriter") { # foreach
2740         my $ary = $enter->first->sibling; # first was pushmark
2741         my $var = $ary->sibling;
2742         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2743             # "reverse" was optimised away
2744             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2745         } elsif ($enter->flags & OPf_STACKED
2746             and not null $ary->first->sibling->sibling)
2747         {
2748             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2749               $self->deparse($ary->first->sibling->sibling, 9);
2750         } else {
2751             $ary = $self->deparse($ary, 1);
2752         }
2753         if (null $var) {
2754             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
2755                 # thread special var, under 5005threads
2756                 $var = $self->pp_threadsv($enter, 1);
2757             } else { # regular my() variable
2758                 $var = $self->pp_padsv($enter, 1);
2759             }
2760         } elsif ($var->name eq "rv2gv") {
2761             $var = $self->pp_rv2sv($var, 1);
2762             if ($enter->private & OPpOUR_INTRO) {
2763                 # our declarations don't have package names
2764                 $var =~ s/^(.).*::/$1/;
2765                 $var = "our $var";
2766             }
2767         } elsif ($var->name eq "gv") {
2768             $var = "\$" . $self->deparse($var, 1);
2769         }
2770         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2771         if (!is_state $body->first and $body->first->name ne "stub") {
2772             confess unless $var eq '$_';
2773             $body = $body->first;
2774             return $self->deparse($body, 2) . " foreach ($ary)";
2775         }
2776         $head = "foreach $var ($ary) ";
2777     } elsif ($kid->name eq "null") { # while/until
2778         $kid = $kid->first;
2779         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2780         $cond = $self->deparse($kid->first, 1);
2781         $head = "$name ($cond) ";
2782         $body = $kid->first->sibling;
2783     } elsif ($kid->name eq "stub") { # bare and empty
2784         return "{;}"; # {} could be a hashref
2785     }
2786     # If there isn't a continue block, then the next pointer for the loop
2787     # will point to the unstack, which is kid's last child, except
2788     # in a bare loop, when it will point to the leaveloop. When neither of
2789     # these conditions hold, then the second-to-last child is the continue
2790     # block (or the last in a bare loop).
2791     my $cont_start = $enter->nextop;
2792     my $cont;
2793     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2794         if ($bare) {
2795             $cont = $body->last;
2796         } else {
2797             $cont = $body->first;
2798             while (!null($cont->sibling->sibling)) {
2799                 $cont = $cont->sibling;
2800             }
2801         }
2802         my $state = $body->first;
2803         my $cuddle = $self->{'cuddle'};
2804         my @states;
2805         for (; $$state != $$cont; $state = $state->sibling) {
2806             push @states, $state;
2807         }
2808         $body = $self->lineseq(undef, @states);
2809         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2810             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2811             $cont = "\cK";
2812         } else {
2813             $cont = $cuddle . "continue {\n\t" .
2814               $self->deparse($cont, 0) . "\n\b}\cK";
2815         }
2816     } else {
2817         return "" if !defined $body;
2818         if (length $init) {
2819             $head = "for ($init; $cond;) ";
2820         }
2821         $cont = "\cK";
2822         $body = $self->deparse($body, 0);
2823     }
2824     $body =~ s/;?$/;\n/;
2825
2826     return $head . "{\n\t" . $body . "\b}" . $cont;
2827 }
2828
2829 sub pp_leaveloop { shift->loop_common(@_, "") }
2830
2831 sub for_loop {
2832     my $self = shift;
2833     my($op, $cx) = @_;
2834     my $init = $self->deparse($op, 1);
2835     my $s = $op->sibling;
2836     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
2837     return $self->loop_common($ll, $cx, $init);
2838 }
2839
2840 sub pp_leavetry {
2841     my $self = shift;
2842     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2843 }
2844
2845 BEGIN { for (qw[ const stringify rv2sv list glob ]) {
2846     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
2847 }}
2848
2849 sub pp_null {
2850     my $self = shift;
2851     my($op, $cx) = @_;
2852     if (class($op) eq "OP") {
2853         # old value is lost
2854         return $self->{'ex_const'} if $op->targ == OP_CONST;
2855     } elsif ($op->first->name eq "pushmark") {
2856         return $self->pp_list($op, $cx);
2857     } elsif ($op->first->name eq "enter") {
2858         return $self->pp_leave($op, $cx);
2859     } elsif ($op->first->name eq "leave") {
2860         return $self->pp_leave($op->first, $cx);
2861     } elsif ($op->first->name eq "scope") {
2862         return $self->pp_scope($op->first, $cx);
2863     } elsif ($op->targ == OP_STRINGIFY) {
2864         return $self->dquote($op, $cx);
2865     } elsif ($op->targ == OP_GLOB) {
2866         return $self->pp_glob(
2867                  $op->first    # entersub
2868                     ->first    # ex-list
2869                     ->first    # pushmark
2870                     ->sibling, # glob
2871                  $cx
2872                );
2873     } elsif (!null($op->first->sibling) and
2874              $op->first->sibling->name eq "readline" and
2875              $op->first->sibling->flags & OPf_STACKED) {
2876         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2877                                    . $self->deparse($op->first->sibling, 7),
2878                                    $cx, 7);
2879     } elsif (!null($op->first->sibling) and
2880              $op->first->sibling->name eq "trans" and
2881              $op->first->sibling->flags & OPf_STACKED) {
2882         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2883                                    . $self->deparse($op->first->sibling, 20),
2884                                    $cx, 20);
2885     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2886         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2887     } elsif (!null($op->first->sibling) and
2888              $op->first->sibling->name eq "null" and
2889              class($op->first->sibling) eq "UNOP" and
2890              $op->first->sibling->first->flags & OPf_STACKED and
2891              $op->first->sibling->first->name eq "rcatline") {
2892         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2893                                    . $self->deparse($op->first->sibling, 18),
2894                                    $cx, 18);
2895     } else {
2896         return $self->deparse($op->first, $cx);
2897     }
2898 }
2899
2900 sub padname {
2901     my $self = shift;
2902     my $targ = shift;
2903     return $self->padname_sv($targ)->PVX;
2904 }
2905
2906 sub padany {
2907     my $self = shift;
2908     my $op = shift;
2909     return substr($self->padname($op->targ), 1); # skip $/@/%
2910 }
2911
2912 sub pp_padsv {
2913     my $self = shift;
2914     my($op, $cx) = @_;
2915     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2916 }
2917
2918 sub pp_padav { pp_padsv(@_) }
2919 sub pp_padhv { pp_padsv(@_) }
2920
2921 my @threadsv_names = B::threadsv_names;
2922 sub pp_threadsv {
2923     my $self = shift;
2924     my($op, $cx) = @_;
2925     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2926 }
2927
2928 sub gv_or_padgv {
2929     my $self = shift;
2930     my $op = shift;
2931     if (class($op) eq "PADOP") {
2932         return $self->padval($op->padix);
2933     } else { # class($op) eq "SVOP"
2934         return $op->gv;
2935     }
2936 }
2937
2938 sub pp_gvsv {
2939     my $self = shift;
2940     my($op, $cx) = @_;
2941     my $gv = $self->gv_or_padgv($op);
2942     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2943                                  $self->gv_name($gv), $cx));
2944 }
2945
2946 sub pp_gv {
2947     my $self = shift;
2948     my($op, $cx) = @_;
2949     my $gv = $self->gv_or_padgv($op);
2950     return $self->gv_name($gv);
2951 }
2952
2953 sub pp_aelemfast_lex {
2954     my $self = shift;
2955     my($op, $cx) = @_;
2956     my $name = $self->padname($op->targ);
2957     $name =~ s/^@/\$/;
2958     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2959 }
2960
2961 sub pp_aelemfast {
2962     my $self = shift;
2963     my($op, $cx) = @_;
2964     # optimised PADAV, pre 5.15
2965     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
2966
2967     my $gv = $self->gv_or_padgv($op);
2968     my $name = $self->gv_name($gv);
2969     $name = $self->{'curstash'}."::$name"
2970         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2971     $name = '$' . $name;
2972     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2973 }
2974
2975 sub rv2x {
2976     my $self = shift;
2977     my($op, $cx, $type) = @_;
2978
2979     if (class($op) eq 'NULL' || !$op->can("first")) {
2980         carp("Unexpected op in pp_rv2x");
2981         return 'XXX';
2982     }
2983     my $kid = $op->first;
2984     if ($kid->name eq "gv") {
2985         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
2986     } elsif (is_scalar $kid) {
2987         my $str = $self->deparse($kid, 0);
2988         if ($str =~ /^\$([^\w\d])\z/) {
2989             # "$$+" isn't a legal way to write the scalar dereference
2990             # of $+, since the lexer can't tell you aren't trying to
2991             # do something like "$$ + 1" to get one more than your
2992             # PID. Either "${$+}" or "$${+}" are workable
2993             # disambiguations, but if the programmer did the former,
2994             # they'd be in the "else" clause below rather than here.
2995             # It's not clear if this should somehow be unified with
2996             # the code in dq and re_dq that also adds lexer
2997             # disambiguation braces.
2998             $str = '$' . "{$1}"; #'
2999         }
3000         return $type . $str;
3001     } else {
3002         return $type . "{" . $self->deparse($kid, 0) . "}";
3003     }
3004 }
3005
3006 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3007 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3008 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3009
3010 # skip rv2av
3011 sub pp_av2arylen {
3012     my $self = shift;
3013     my($op, $cx) = @_;
3014     if ($op->first->name eq "padav") {
3015         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3016     } else {
3017         return $self->maybe_local($op, $cx,
3018                                   $self->rv2x($op->first, $cx, '$#'));
3019     }
3020 }
3021
3022 # skip down to the old, ex-rv2cv
3023 sub pp_rv2cv {
3024     my ($self, $op, $cx) = @_;
3025     if (!null($op->first) && $op->first->name eq 'null' &&
3026         $op->first->targ eq OP_LIST)
3027     {
3028         return $self->rv2x($op->first->first->sibling, $cx, "&")
3029     }
3030     else {
3031         return $self->rv2x($op, $cx, "")
3032     }
3033 }
3034
3035 sub list_const {
3036     my $self = shift;
3037     my($cx, @list) = @_;
3038     my @a = map $self->const($_, 6), @list;
3039     if (@a == 0) {
3040         return "()";
3041     } elsif (@a == 1) {
3042         return $a[0];
3043     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3044         # collapse (-1,0,1,2) into (-1..2)
3045         my ($s, $e) = @a[0,-1];
3046         my $i = $s;
3047         return $self->maybe_parens("$s..$e", $cx, 9)
3048           unless grep $i++ != $_, @a;
3049     }
3050     return $self->maybe_parens(join(", ", @a), $cx, 6);
3051 }
3052
3053 sub pp_rv2av {
3054     my $self = shift;
3055     my($op, $cx) = @_;
3056     my $kid = $op->first;
3057     if ($kid->name eq "const") { # constant list
3058         my $av = $self->const_sv($kid);
3059         return $self->list_const($cx, $av->ARRAY);
3060     } else {
3061         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3062     }
3063  }
3064
3065 sub is_subscriptable {
3066     my $op = shift;
3067     if ($op->name =~ /^[ahg]elem/) {
3068         return 1;
3069     } elsif ($op->name eq "entersub") {
3070         my $kid = $op->first;
3071         return 0 unless null $kid->sibling;
3072         $kid = $kid->first;
3073         $kid = $kid->sibling until null $kid->sibling;
3074         return 0 if is_scope($kid);
3075         $kid = $kid->first;
3076         return 0 if $kid->name eq "gv";
3077         return 0 if is_scalar($kid);
3078         return is_subscriptable($kid);  
3079     } else {
3080         return 0;
3081     }
3082 }
3083
3084 sub elem_or_slice_array_name
3085 {
3086     my $self = shift;
3087     my ($array, $left, $padname, $allow_arrow) = @_;
3088
3089     if ($array->name eq $padname) {
3090         return $self->padany($array);
3091     } elsif (is_scope($array)) { # ${expr}[0]
3092         return "{" . $self->deparse($array, 0) . "}";
3093     } elsif ($array->name eq "gv") {
3094         $array = $self->gv_name($self->gv_or_padgv($array));
3095         if ($array !~ /::/) {
3096             my $prefix = ($left eq '[' ? '@' : '%');
3097             $array = $self->{curstash}.'::'.$array
3098                 if $self->lex_in_scope($prefix . $array);
3099         }
3100         return $array;
3101     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3102         return $self->deparse($array, 24);
3103     } else {
3104         return undef;
3105     }
3106 }
3107
3108 sub elem_or_slice_single_index
3109 {
3110     my $self = shift;
3111     my ($idx) = @_;
3112
3113     $idx = $self->deparse($idx, 1);
3114
3115     # Outer parens in an array index will confuse perl
3116     # if we're interpolating in a regular expression, i.e.
3117     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3118     #
3119     # If $self->{parens}, then an initial '(' will
3120     # definitely be paired with a final ')'. If
3121     # !$self->{parens}, the misleading parens won't
3122     # have been added in the first place.
3123     #
3124     # [You might think that we could get "(...)...(...)"
3125     # where the initial and final parens do not match
3126     # each other. But we can't, because the above would
3127     # only happen if there's an infix binop between the
3128     # two pairs of parens, and *that* means that the whole
3129     # expression would be parenthesized as well.]
3130     #
3131     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3132
3133     # Hash-element braces will autoquote a bareword inside themselves.
3134     # We need to make sure that C<$hash{warn()}> doesn't come out as
3135     # C<$hash{warn}>, which has a quite different meaning. Currently
3136     # B::Deparse will always quote strings, even if the string was a
3137     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3138     # for constant strings.) So we can cheat slightly here - if we see
3139     # a bareword, we know that it is supposed to be a function call.
3140     #
3141     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3142
3143     return $idx;
3144 }
3145
3146 sub elem {
3147     my $self = shift;
3148     my ($op, $cx, $left, $right, $padname) = @_;
3149     my($array, $idx) = ($op->first, $op->first->sibling);
3150
3151     $idx = $self->elem_or_slice_single_index($idx);
3152
3153     unless ($array->name eq $padname) { # Maybe this has been fixed     
3154         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3155     }
3156     if (my $array_name=$self->elem_or_slice_array_name
3157             ($array, $left, $padname, 1)) {
3158         return "\$" . $array_name . $left . $idx . $right;
3159     } else {
3160         # $x[20][3]{hi} or expr->[20]
3161         my $arrow = is_subscriptable($array) ? "" : "->";
3162         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3163     }
3164
3165 }
3166
3167 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3168 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3169
3170 sub pp_gelem {
3171     my $self = shift;
3172     my($op, $cx) = @_;
3173     my($glob, $part) = ($op->first, $op->last);
3174     $glob = $glob->first; # skip rv2gv
3175     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3176     my $scope = is_scope($glob);
3177     $glob = $self->deparse($glob, 0);
3178     $part = $self->deparse($part, 1);
3179     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3180 }
3181
3182 sub slice {
3183     my $self = shift;
3184     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3185     my $last;
3186     my(@elems, $kid, $array, $list);
3187     if (class($op) eq "LISTOP") {
3188         $last = $op->last;
3189     } else { # ex-hslice inside delete()
3190         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3191         $last = $kid;
3192     }
3193     $array = $last;
3194     $array = $array->first
3195         if $array->name eq $regname or $array->name eq "null";
3196     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3197     $kid = $op->first->sibling; # skip pushmark
3198     if ($kid->name eq "list") {
3199         $kid = $kid->first->sibling; # skip list, pushmark
3200         for (; !null $kid; $kid = $kid->sibling) {
3201             push @elems, $self->deparse($kid, 6);
3202         }
3203         $list = join(", ", @elems);
3204     } else {
3205         $list = $self->elem_or_slice_single_index($kid);
3206     }
3207     return "\@" . $array . $left . $list . $right;
3208 }
3209
3210 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3211 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3212
3213 sub pp_lslice {
3214     my $self = shift;
3215     my($op, $cx) = @_;
3216     my $idx = $op->first;
3217     my $list = $op->last;
3218     my(@elems, $kid);
3219     $list = $self->deparse($list, 1);
3220     $idx = $self->deparse($idx, 1);
3221     return "($list)" . "[$idx]";
3222 }
3223
3224 sub want_scalar {
3225     my $op = shift;
3226     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3227 }
3228
3229 sub want_list {
3230     my $op = shift;
3231     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3232 }
3233
3234 sub _method {
3235     my $self = shift;
3236     my($op, $cx) = @_;
3237     my $kid = $op->first->sibling; # skip pushmark
3238     my($meth, $obj, @exprs);
3239     if ($kid->name eq "list" and want_list $kid) {
3240         # When an indirect object isn't a bareword but the args are in
3241         # parens, the parens aren't part of the method syntax (the LLAFR
3242         # doesn't apply), but they make a list with OPf_PARENS set that
3243         # doesn't get flattened by the append_elem that adds the method,
3244         # making a (object, arg1, arg2, ...) list where the object
3245         # usually is. This can be distinguished from
3246         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3247         # object) because in the later the list is in scalar context
3248         # as the left side of -> always is, while in the former
3249         # the list is in list context as method arguments always are.
3250         # (Good thing there aren't method prototypes!)
3251         $meth = $kid->sibling;
3252         $kid = $kid->first->sibling; # skip pushmark
3253         $obj = $kid;
3254         $kid = $kid->sibling;
3255         for (; not null $kid; $kid = $kid->sibling) {
3256             push @exprs, $kid;
3257         }
3258     } else {
3259         $obj = $kid;
3260         $kid = $kid->sibling;
3261         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3262               $kid = $kid->sibling) {
3263             push @exprs, $kid
3264         }
3265         $meth = $kid;
3266     }
3267
3268     if ($meth->name eq "method_named") {
3269         $meth = $self->const_sv($meth)->PV;
3270     } else {
3271         $meth = $meth->first;
3272         if ($meth->name eq "const") {
3273             # As of 5.005_58, this case is probably obsoleted by the
3274             # method_named case above
3275             $meth = $self->const_sv($meth)->PV; # needs to be bare
3276         }
3277     }
3278
3279     return { method => $meth, variable_method => ref($meth),
3280              object => $obj, args => \@exprs  };
3281 }
3282
3283 # compat function only
3284 sub method {
3285     my $self = shift;
3286     my $info = $self->_method(@_);
3287     return $self->e_method( $self->_method(@_) );
3288 }
3289
3290 sub e_method {
3291     my ($self, $info) = @_;
3292     my $obj = $self->deparse($info->{object}, 24);
3293
3294     my $meth = $info->{method};
3295     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3296     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3297     my $kid = $obj . "->" . $meth;
3298     if (length $args) {
3299         return $kid . "(" . $args . ")"; # parens mandatory
3300     } else {
3301         return $kid;
3302     }
3303 }
3304
3305 # returns "&" if the prototype doesn't match the args,
3306 # or ("", $args_after_prototype_demunging) if it does.
3307 sub check_proto {
3308     my $self = shift;
3309     return "&" if $self->{'noproto'};
3310     my($proto, @args) = @_;
3311     my($arg, $real);
3312     my $doneok = 0;
3313     my @reals;
3314     # An unbackslashed @ or % gobbles up the rest of the args
3315     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3316     while ($proto) {
3317         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3318         my $chr = $1;
3319         if ($chr eq "") {
3320             return "&" if @args;
3321         } elsif ($chr eq ";") {
3322             $doneok = 1;
3323         } elsif ($chr eq "@" or $chr eq "%") {
3324             push @reals, map($self->deparse($_, 6), @args);
3325             @args = ();
3326         } else {
3327             $arg = shift @args;
3328             last unless $arg;
3329             if ($chr eq "\$" || $chr eq "_") {
3330                 if (want_scalar $arg) {
3331                     push @reals, $self->deparse($arg, 6);
3332                 } else {
3333                     return "&";
3334                 }
3335             } elsif ($chr eq "&") {
3336                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3337                     push @reals, $self->deparse($arg, 6);
3338                 } else {
3339                     return "&";
3340                 }
3341             } elsif ($chr eq "*") {
3342                 if ($arg->name =~ /^s?refgen$/
3343                     and $arg->first->first->name eq "rv2gv")
3344                   {
3345                       $real = $arg->first->first; # skip refgen, null
3346                       if ($real->first->name eq "gv") {
3347                           push @reals, $self->deparse($real, 6);
3348                       } else {
3349                           push @reals, $self->deparse($real->first, 6);
3350                       }
3351                   } else {
3352                       return "&";
3353                   }
3354             } elsif (substr($chr, 0, 1) eq "\\") {
3355                 $chr =~ tr/\\[]//d;
3356                 if ($arg->name =~ /^s?refgen$/ and
3357                     !null($real = $arg->first) and
3358                     ($chr =~ /\$/ && is_scalar($real->first)
3359                      or ($chr =~ /@/
3360                          && class($real->first->sibling) ne 'NULL'
3361                          && $real->first->sibling->name
3362                          =~ /^(rv2|pad)av$/)
3363                      or ($chr =~ /%/
3364                          && class($real->first->sibling) ne 'NULL'
3365                          && $real->first->sibling->name
3366                          =~ /^(rv2|pad)hv$/)
3367                      #or ($chr =~ /&/ # This doesn't work
3368                      #   && $real->first->name eq "rv2cv")
3369                      or ($chr =~ /\*/
3370                          && $real->first->name eq "rv2gv")))
3371                   {
3372                       push @reals, $self->deparse($real, 6);
3373                   } else {
3374                       return "&";
3375                   }
3376             }
3377        }
3378     }
3379     return "&" if $proto and !$doneok; # too few args and no `;'
3380     return "&" if @args;               # too many args
3381     return ("", join ", ", @reals);
3382 }
3383
3384 sub pp_entersub {
3385     my $self = shift;
3386     my($op, $cx) = @_;
3387     return $self->e_method($self->_method($op, $cx))
3388         unless null $op->first->sibling;
3389     my $prefix = "";
3390     my $amper = "";
3391     my($kid, @exprs);
3392     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3393         $prefix = "do ";
3394     } elsif ($op->private & OPpENTERSUB_AMPER) {
3395         $amper = "&";
3396     }
3397     $kid = $op->first;
3398     $kid = $kid->first->sibling; # skip ex-list, pushmark
3399     for (; not null $kid->sibling; $kid = $kid->sibling) {
3400         push @exprs, $kid;
3401     }
3402     my $simple = 0;
3403     my $proto = undef;
3404     if (is_scope($kid)) {
3405         $amper = "&";
3406         $kid = "{" . $self->deparse($kid, 0) . "}";
3407     } elsif ($kid->first->name eq "gv") {
3408         my $gv = $self->gv_or_padgv($kid->first);
3409         if (class($gv->CV) ne "SPECIAL") {
3410             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3411         }
3412         $simple = 1; # only calls of named functions can be prototyped
3413         $kid = $self->deparse($kid, 24);
3414         if (!$amper) {
3415             if ($kid eq 'main::') {
3416                 $kid = '::';
3417             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3418                 $kid = single_delim("q", "'", $kid) . '->';
3419             }
3420         }
3421     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3422         $amper = "&";
3423         $kid = $self->deparse($kid, 24);
3424     } else {
3425         $prefix = "";
3426         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3427         $kid = $self->deparse($kid, 24) . $arrow;
3428     }
3429
3430     # Doesn't matter how many prototypes there are, if
3431     # they haven't happened yet!
3432     my $declared;
3433     {
3434         no strict 'refs';
3435         no warnings 'uninitialized';
3436         $declared = exists $self->{'subs_declared'}{$kid}
3437             || (
3438                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3439                  && !exists
3440                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3441                  && defined prototype $self->{'curstash'}."::".$kid
3442                );
3443         if (!$declared && defined($proto)) {
3444             # Avoid "too early to check prototype" warning
3445             ($amper, $proto) = ('&');
3446         }
3447     }
3448
3449     my $args;
3450     if ($declared and defined $proto and not $amper) {
3451         ($amper, $args) = $self->check_proto($proto, @exprs);
3452         if ($amper eq "&") {
3453             $args = join(", ", map($self->deparse($_, 6), @exprs));
3454         }
3455     } else {
3456         $args = join(", ", map($self->deparse($_, 6), @exprs));
3457     }
3458     if ($prefix or $amper) {
3459         if ($op->flags & OPf_STACKED) {
3460             return $prefix . $amper . $kid . "(" . $args . ")";
3461         } else {
3462             return $prefix . $amper. $kid;
3463         }
3464     } else {
3465         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3466         # so it must have been translated from a keyword call. Translate
3467         # it back.
3468         $kid =~ s/^CORE::GLOBAL:://;
3469
3470         my $dproto = defined($proto) ? $proto : "undefined";
3471         if (!$declared) {
3472             return "$kid(" . $args . ")";
3473         } elsif ($dproto eq "") {
3474             return $kid;
3475         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3476             # is_scalar is an excessively conservative test here:
3477             # really, we should be comparing to the precedence of the
3478             # top operator of $exprs[0] (ala unop()), but that would
3479             # take some major code restructuring to do right.
3480             return $self->maybe_parens_func($kid, $args, $cx, 16);
3481         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3482             return $self->maybe_parens_func($kid, $args, $cx, 5);
3483         } else {
3484             return "$kid(" . $args . ")";
3485         }
3486     }
3487 }
3488
3489 sub pp_enterwrite { unop(@_, "write") }
3490
3491 # escape things that cause interpolation in double quotes,
3492 # but not character escapes
3493 sub uninterp {
3494     my($str) = @_;
3495     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3496     return $str;
3497 }
3498
3499 {
3500 my $bal;
3501 BEGIN {
3502     use re "eval";
3503     # Matches any string which is balanced with respect to {braces}
3504     $bal = qr(
3505       (?:
3506         [^\\{}]
3507       | \\\\
3508       | \\[{}]
3509       | \{(??{$bal})\}
3510       )*
3511     )x;
3512 }
3513
3514 # the same, but treat $|, $), $( and $ at the end of the string differently
3515 sub re_uninterp {
3516     my($str) = @_;
3517
3518     $str =~ s/
3519           ( ^|\G                  # $1
3520           | [^\\]
3521           )
3522
3523           (                       # $2
3524             (?:\\\\)*
3525           )
3526
3527           (                       # $3
3528             (\(\?\??\{$bal\}\))   # $4
3529           | [\$\@]
3530             (?!\||\)|\(|$)
3531           | \\[uUlLQE]
3532           )
3533
3534         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3535
3536     return $str;
3537 }
3538
3539 # This is for regular expressions with the /x modifier
3540 # We have to leave comments unmangled.
3541 sub re_uninterp_extended {
3542     my($str) = @_;
3543
3544     $str =~ s/
3545           ( ^|\G                  # $1
3546           | [^\\]
3547           )
3548
3549           (                       # $2
3550             (?:\\\\)*
3551           )
3552
3553           (                       # $3
3554             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3555             | \#[^\n]*            #     (skip over comments)
3556             )
3557           | [\$\@]
3558             (?!\||\)|\(|$|\s)
3559           | \\[uUlLQE]
3560           )
3561
3562         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3563
3564     return $str;
3565 }
3566 }
3567
3568 my %unctrl = # portable to to EBCDIC
3569     (
3570      "\c@" => '\c@',    # unused
3571      "\cA" => '\cA',
3572      "\cB" => '\cB',
3573      "\cC" => '\cC',
3574      "\cD" => '\cD',
3575      "\cE" => '\cE',
3576      "\cF" => '\cF',
3577      "\cG" => '\cG',
3578      "\cH" => '\cH',
3579      "\cI" => '\cI',
3580      "\cJ" => '\cJ',
3581      "\cK" => '\cK',
3582      "\cL" => '\cL',
3583      "\cM" => '\cM',
3584      "\cN" => '\cN',
3585      "\cO" => '\cO',
3586      "\cP" => '\cP',
3587      "\cQ" => '\cQ',
3588      "\cR" => '\cR',
3589      "\cS" => '\cS',
3590      "\cT" => '\cT',
3591      "\cU" => '\cU',
3592      "\cV" => '\cV',
3593      "\cW" => '\cW',
3594      "\cX" => '\cX',
3595      "\cY" => '\cY',
3596      "\cZ" => '\cZ',
3597      "\c[" => '\c[',    # unused
3598      "\c\\" => '\c\\',  # unused
3599      "\c]" => '\c]',    # unused
3600      "\c_" => '\c_',    # unused
3601     );
3602
3603 # character escapes, but not delimiters that might need to be escaped
3604 sub escape_str { # ASCII, UTF8
3605     my($str) = @_;
3606     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3607     $str =~ s/\a/\\a/g;
3608 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3609     $str =~ s/\t/\\t/g;
3610     $str =~ s/\n/\\n/g;
3611     $str =~ s/\e/\\e/g;
3612     $str =~ s/\f/\\f/g;
3613     $str =~ s/\r/\\r/g;
3614     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3615     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3616     return $str;
3617 }
3618
3619 # For regexes with the /x modifier.
3620 # Leave whitespace unmangled.
3621 sub escape_extended_re {
3622     my($str) = @_;
3623     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3624     $str =~ s/([[:^print:]])/
3625         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3626     $str =~ s/\n/\n\f/g;
3627     return $str;
3628 }
3629
3630 # Don't do this for regexen
3631 sub unback {
3632     my($str) = @_;
3633     $str =~ s/\\/\\\\/g;
3634     return $str;
3635 }
3636
3637 # Remove backslashes which precede literal control characters,
3638 # to avoid creating ambiguity when we escape the latter.
3639 sub re_unback {
3640     my($str) = @_;
3641
3642     # the insane complexity here is due to the behaviour of "\c\"
3643     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3644     return $str;
3645 }
3646
3647 sub balanced_delim {
3648     my($str) = @_;
3649     my @str = split //, $str;
3650     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3651     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3652         ($open, $close) = @$ar;
3653         $fail = 0; $cnt = 0; $last_bs = 0;
3654         for $c (@str) {
3655             if ($c eq $open) {
3656                 $fail = 1 if $last_bs;
3657                 $cnt++;
3658             } elsif ($c eq $close) {
3659                 $fail = 1 if $last_bs;
3660                 $cnt--;
3661                 if ($cnt < 0) {
3662                     # qq()() isn't ")("
3663                     $fail = 1;
3664                     last;
3665                 }
3666             }
3667             $last_bs = $c eq '\\';
3668         }
3669         $fail = 1 if $cnt != 0;
3670         return ($open, "$open$str$close") if not $fail;
3671     }
3672     return ("", $str);
3673 }
3674
3675 sub single_delim {
3676     my($q, $default, $str) = @_;
3677     return "$default$str$default" if $default and index($str, $default) == -1;
3678     if ($q ne 'qr') {
3679         (my $succeed, $str) = balanced_delim($str);
3680         return "$q$str" if $succeed;
3681     }
3682     for my $delim ('/', '"', '#') {
3683         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3684     }
3685     if ($default) {
3686         $str =~ s/$default/\\$default/g;
3687         return "$default$str$default";
3688     } else {
3689         $str =~ s[/][\\/]g;
3690         return "$q/$str/";
3691     }
3692 }
3693
3694 my $max_prec;
3695 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3696
3697 # Split a floating point number into an integer mantissa and a binary
3698 # exponent. Assumes you've already made sure the number isn't zero or
3699 # some weird infinity or NaN.
3700 sub split_float {
3701     my($f) = @_;
3702     my $exponent = 0;
3703     if ($f == int($f)) {
3704         while ($f % 2 == 0) {
3705             $f /= 2;
3706             $exponent++;
3707         }
3708     } else {
3709         while ($f != int($f)) {
3710             $f *= 2;
3711             $exponent--;
3712         }
3713     }
3714     my $mantissa = sprintf("%.0f", $f);
3715     return ($mantissa, $exponent);
3716 }
3717
3718 sub const {
3719     my $self = shift;
3720     my($sv, $cx) = @_;
3721     if ($self->{'use_dumper'}) {
3722         return $self->const_dumper($sv, $cx);
3723     }
3724     if (class($sv) eq "SPECIAL") {
3725         # sv_undef, sv_yes, sv_no
3726         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3727     }
3728     if (class($sv) eq "NULL") {
3729        return 'undef';
3730     }
3731     # convert a version object into the "v1.2.3" string in its V magic
3732     if ($sv->FLAGS & SVs_RMG) {
3733         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3734             return $mg->PTR if $mg->TYPE eq 'V';
3735         }
3736     }
3737
3738     if ($sv->FLAGS & SVf_IOK) {
3739         my $str = $sv->int_value;
3740         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3741         return $str;
3742     } elsif ($sv->FLAGS & SVf_NOK) {
3743         my $nv = $sv->NV;
3744         if ($nv == 0) {
3745             if (pack("F", $nv) eq pack("F", 0)) {
3746                 # positive zero
3747                 return "0";
3748             } else {
3749                 # negative zero
3750                 return $self->maybe_parens("-.0", $cx, 21);
3751             }
3752         } elsif (1/$nv == 0) {
3753             if ($nv > 0) {
3754                 # positive infinity
3755                 return $self->maybe_parens("9**9**9", $cx, 22);
3756             } else {
3757                 # negative infinity
3758                 return $self->maybe_parens("-9**9**9", $cx, 21);
3759             }
3760         } elsif ($nv != $nv) {
3761             # NaN
3762             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3763                 # the normal kind
3764                 return "sin(9**9**9)";
3765             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3766                 # the inverted kind
3767                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3768             } else {
3769                 # some other kind
3770                 my $hex = unpack("h*", pack("F", $nv));
3771                 return qq'unpack("F", pack("h*", "$hex"))';
3772             }
3773         }
3774         # first, try the default stringification
3775         my $str = "$nv";
3776         if ($str != $nv) {
3777             # failing that, try using more precision
3778             $str = sprintf("%.${max_prec}g", $nv);
3779 #           if (pack("F", $str) ne pack("F", $nv)) {
3780             if ($str != $nv) {
3781                 # not representable in decimal with whatever sprintf()
3782                 # and atof() Perl is using here.
3783                 my($mant, $exp) = split_float($nv);
3784                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3785             }
3786         }
3787         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3788         return $str;
3789     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3790         my $ref = $sv->RV;
3791         if (class($ref) eq "AV") {
3792             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3793         } elsif (class($ref) eq "HV") {
3794             my %hash = $ref->ARRAY;
3795             my @elts;
3796             for my $k (sort keys %hash) {
3797                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3798             }
3799             return "{" . join(", ", @elts) . "}";
3800         } elsif (class($ref) eq "CV") {
3801             return "sub " . $self->deparse_sub($ref);
3802         }
3803         if ($ref->FLAGS & SVs_SMG) {
3804             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3805                 if ($mg->TYPE eq 'r') {
3806                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3807                     return single_delim("qr", "", $re);
3808                 }
3809             }
3810         }
3811         
3812         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3813     } elsif ($sv->FLAGS & SVf_POK) {
3814         my $str = $sv->PV;
3815         if ($str =~ /[[:^print:]]/) {
3816             return single_delim("qq", '"', uninterp escape_str unback $str);
3817         } else {
3818             return single_delim("q", "'", unback $str);
3819         }
3820     } else {
3821         return "undef";
3822     }
3823 }
3824
3825 sub const_dumper {
3826     my $self = shift;
3827     my($sv, $cx) = @_;
3828     my $ref = $sv->object_2svref();
3829     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3830     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3831     my $str = $dumper->Dump();
3832     if ($str =~ /^\$v/) {
3833         return '${my ' . $str . ' \$v}';
3834     } else {
3835         return $str;
3836     }
3837 }
3838
3839 sub const_sv {
3840     my $self = shift;
3841     my $op = shift;
3842     my $sv = $op->sv;
3843     # the constant could be in the pad (under useithreads)
3844     $sv = $self->padval($op->targ) unless $$sv;
3845     return $sv;
3846 }
3847
3848 sub pp_const {
3849     my $self = shift;
3850     my($op, $cx) = @_;
3851     if ($op->private & OPpCONST_ARYBASE) {
3852         return '$[';
3853     }
3854 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3855 #       return $self->const_sv($op)->PV;
3856 #    }
3857     my $sv = $self->const_sv($op);
3858     return $self->const($sv, $cx);
3859 }
3860
3861 sub dq {
3862     my $self = shift;
3863     my $op = shift;
3864     my $type = $op->name;
3865     if ($type eq "const") {
3866         return '$[' if $op->private & OPpCONST_ARYBASE;
3867         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3868     } elsif ($type eq "concat") {
3869         my $first = $self->dq($op->first);
3870         my $last  = $self->dq($op->last);
3871
3872         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3873         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3874             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3875             || ($last =~ /^[:'{\[\w_]/ && #'
3876                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3877
3878         return $first . $last;
3879     } elsif ($type eq "uc") {
3880         return '\U' . $self->dq($op->first->sibling) . '\E';
3881     } elsif ($type eq "lc") {
3882         return '\L' . $self->dq($op->first->sibling) . '\E';
3883     } elsif ($type eq "ucfirst") {
3884         return '\u' . $self->dq($op->first->sibling);
3885     } elsif ($type eq "lcfirst") {
3886         return '\l' . $self->dq($op->first->sibling);
3887     } elsif ($type eq "quotemeta") {
3888         return '\Q' . $self->dq($op->first->sibling) . '\E';
3889     } elsif ($type eq "join") {
3890         return $self->deparse($op->last, 26); # was join($", @ary)
3891     } else {
3892         return $self->deparse($op, 26);
3893     }
3894 }
3895
3896 sub pp_backtick {
3897     my $self = shift;
3898     my($op, $cx) = @_;
3899     # skip pushmark if it exists (readpipe() vs ``)
3900     my $child = $op->first->sibling->isa('B::NULL')
3901         ? $op->first : $op->first->sibling;
3902     if ($self->pure_string($child)) {
3903         return single_delim("qx", '`', $self->dq($child, 1));
3904     }
3905     unop($self, @_, "readpipe");
3906 }
3907
3908 sub dquote {
3909     my $self = shift;
3910     my($op, $cx) = @_;
3911     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3912     return $self->deparse($kid, $cx) if $self->{'unquote'};
3913     $self->maybe_targmy($kid, $cx,
3914                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3915 }
3916
3917 # OP_STRINGIFY is a listop, but it only ever has one arg
3918 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3919
3920 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3921 # note that tr(from)/to/ is OK, but not tr/from/(to)
3922 sub double_delim {
3923     my($from, $to) = @_;
3924     my($succeed, $delim);
3925     if ($from !~ m[/] and $to !~ m[/]) {
3926         return "/$from/$to/";
3927     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3928         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3929             return "$from$to";
3930         } else {
3931             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3932                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3933             }
3934             $to =~ s[/][\\/]g;
3935             return "$from/$to/";
3936         }
3937     } else {
3938         for $delim ('/', '"', '#') { # note no '
3939             return "$delim$from$delim$to$delim"
3940                 if index($to . $from, $delim) == -1;
3941         }
3942         $from =~ s[/][\\/]g;
3943         $to =~ s[/][\\/]g;
3944         return "/$from/$to/";   
3945     }
3946 }
3947
3948 # Only used by tr///, so backslashes hyphens
3949 sub pchr { # ASCII
3950     my($n) = @_;
3951     if ($n == ord '\\') {
3952         return '\\\\';
3953     } elsif ($n == ord "-") {
3954         return "\\-";
3955     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3956         return chr($n);
3957     } elsif ($n == ord "\a") {
3958         return '\\a';
3959     } elsif ($n == ord "\b") {
3960         return '\\b';
3961     } elsif ($n == ord "\t") {
3962         return '\\t';
3963     } elsif ($n == ord "\n") {
3964         return '\\n';
3965     } elsif ($n == ord "\e") {
3966         return '\\e';
3967     } elsif ($n == ord "\f") {
3968         return '\\f';
3969     } elsif ($n == ord "\r") {
3970         return '\\r';
3971     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3972         return '\\c' . chr(ord("@") + $n);
3973     } else {
3974 #       return '\x' . sprintf("%02x", $n);
3975         return '\\' . sprintf("%03o", $n);
3976     }
3977 }
3978
3979 sub collapse {
3980     my(@chars) = @_;
3981     my($str, $c, $tr) = ("");
3982     for ($c = 0; $c < @chars; $c++) {
3983         $tr = $chars[$c];
3984         $str .= pchr($tr);
3985         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3986             $chars[$c + 2] == $tr + 2)
3987         {
3988             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3989               {}
3990             $str .= "-";
3991             $str .= pchr($chars[$c]);
3992         }
3993     }
3994     return $str;
3995 }
3996
3997 sub tr_decode_byte {
3998     my($table, $flags) = @_;
3999     my(@table) = unpack("s*", $table);
4000     splice @table, 0x100, 1;   # Number of subsequent elements
4001     my($c, $tr, @from, @to, @delfrom, $delhyphen);
4002     if ($table[ord "-"] != -1 and
4003         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
4004     {
4005         $tr = $table[ord "-"];
4006         $table[ord "-"] = -1;
4007         if ($tr >= 0) {
4008             @from = ord("-");
4009             @to = $tr;
4010         } else { # -2 ==> delete
4011             $delhyphen = 1;
4012         }
4013     }
4014     for ($c = 0; $c < @table; $c++) {
4015         $tr = $table[$c];
4016         if ($tr >= 0) {
4017             push @from, $c; push @to, $tr;
4018         } elsif ($tr == -2) {
4019             push @delfrom, $c;
4020         }
4021     }
4022     @from = (@from, @delfrom);
4023     if ($flags & OPpTRANS_COMPLEMENT) {
4024         my @newfrom = ();
4025         my %from;
4026         @from{@from} = (1) x @from;
4027         for ($c = 0; $c < 256; $c++) {
4028             push @newfrom, $c unless $from{$c};
4029         }
4030         @from = @newfrom;
4031     }
4032     unless ($flags & OPpTRANS_DELETE || !@to) {
4033         pop @to while $#to and $to[$#to] == $to[$#to -1];
4034     }
4035     my($from, $to);
4036     $from = collapse(@from);
4037     $to = collapse(@to);
4038     $from .= "-" if $delhyphen;
4039     return ($from, $to);
4040 }
4041
4042 sub tr_chr {
4043     my $x = shift;
4044     if ($x == ord "-") {
4045         return "\\-";
4046     } elsif ($x == ord "\\") {
4047         return "\\\\";
4048     } else {
4049         return chr $x;
4050     }
4051 }
4052
4053 # XXX This doesn't yet handle all cases correctly either
4054
4055 sub tr_decode_utf8 {
4056     my($swash_hv, $flags) = @_;
4057     my %swash = $swash_hv->ARRAY;
4058     my $final = undef;
4059     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4060     my $none = $swash{"NONE"}->IV;
4061     my $extra = $none + 1;
4062     my(@from, @delfrom, @to);
4063     my $line;
4064     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4065         my($min, $max, $result) = split(/\t/, $line);
4066         $min = hex $min;
4067         if (length $max) {
4068             $max = hex $max;
4069         } else {
4070             $max = $min;
4071         }
4072         $result = hex $result;
4073         if ($result == $extra) {
4074             push @delfrom, [$min, $max];
4075         } else {
4076             push @from, [$min, $max];
4077             push @to, [$result, $result + $max - $min];
4078         }
4079     }
4080     for my $i (0 .. $#from) {
4081         if ($from[$i][0] == ord '-') {
4082             unshift @from, splice(@from, $i, 1);
4083             unshift @to, splice(@to, $i, 1);
4084             last;
4085         } elsif ($from[$i][1] == ord '-') {
4086             $from[$i][1]--;
4087             $to[$i][1]--;
4088             unshift @from, ord '-';
4089             unshift @to, ord '-';
4090             last;
4091         }
4092     }
4093     for my $i (0 .. $#delfrom) {
4094         if ($delfrom[$i][0] == ord '-') {
4095             push @delfrom, splice(@delfrom, $i, 1);
4096             last;
4097         } elsif ($delfrom[$i][1] == ord '-') {
4098             $delfrom[$i][1]--;
4099             push @delfrom, ord '-';
4100             last;
4101         }
4102     }
4103     if (defined $final and $to[$#to][1] != $final) {
4104         push @to, [$final, $final];
4105     }
4106     push @from, @delfrom;
4107     if ($flags & OPpTRANS_COMPLEMENT) {
4108         my @newfrom;
4109         my $next = 0;
4110         for my $i (0 .. $#from) {
4111             push @newfrom, [$next, $from[$i][0] - 1];
4112             $next = $from[$i][1] + 1;
4113         }
4114         @from = ();
4115         for my $range (@newfrom) {
4116             if ($range->[0] <= $range->[1]) {
4117                 push @from, $range;
4118             }
4119         }
4120     }
4121     my($from, $to, $diff);
4122     for my $chunk (@from) {
4123         $diff = $chunk->[1] - $chunk->[0];
4124         if ($diff > 1) {
4125             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4126         } elsif ($diff == 1) {
4127             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4128         } else {
4129             $from .= tr_chr($chunk->[0]);
4130         }
4131     }
4132     for my $chunk (@to) {
4133         $diff = $chunk->[1] - $chunk->[0];
4134         if ($diff > 1) {
4135             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4136         } elsif ($diff == 1) {
4137             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4138         } else {
4139             $to .= tr_chr($chunk->[0]);
4140         }
4141     }
4142     #$final = sprintf("%04x", $final) if defined $final;
4143     #$none = sprintf("%04x", $none) if defined $none;
4144     #$extra = sprintf("%04x", $extra) if defined $extra;
4145     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4146     #print STDERR $swash{'LIST'}->PV;
4147     return (escape_str($from), escape_str($to));
4148 }
4149
4150 sub pp_trans {
4151     my $self = shift;
4152     my($op, $cx) = @_;
4153     my($from, $to);
4154     my $class = class($op);
4155     my $priv_flags = $op->private;
4156     if ($class eq "PVOP") {
4157         ($from, $to) = tr_decode_byte($op->pv, $priv_flags);
4158     } elsif ($class eq "PADOP") {
4159         ($from, $to)
4160           = tr_decode_utf8($self->padval($op->padix)->RV, $priv_flags);
4161     } else { # class($op) eq "SVOP"
4162         ($from, $to) = tr_decode_utf8($op->sv->RV, $priv_flags);
4163     }
4164     my $flags = "";
4165     $flags .= "c" if $priv_flags & OPpTRANS_COMPLEMENT;
4166     $flags .= "d" if $priv_flags & OPpTRANS_DELETE;
4167     $to = "" if $from eq $to and $flags eq "";
4168     $flags .= "s" if $priv_flags & OPpTRANS_SQUASH;
4169     return "tr" . double_delim($from, $to) . $flags;
4170 }
4171
4172 sub pp_transr { &pp_trans . 'r' }
4173
4174 sub re_dq_disambiguate {
4175     my ($first, $last) = @_;
4176     # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4177     ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4178         $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4179         || ($last =~ /^[{\[\w_]/ &&
4180             $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4181     return $first . $last;
4182 }
4183
4184 # Like dq(), but different
4185 sub re_dq {
4186     my $self = shift;
4187     my ($op, $extended) = @_;
4188
4189     my $type = $op->name;
4190     if ($type eq "const") {
4191         return '$[' if $op->private & OPpCONST_ARYBASE;
4192         my $unbacked = re_unback($self->const_sv($op)->as_string);
4193         return re_uninterp_extended(escape_extended_re($unbacked))
4194             if $extended;
4195         return re_uninterp(escape_str($unbacked));
4196     } elsif ($type eq "concat") {
4197         my $first = $self->re_dq($op->first, $extended);
4198         my $last  = $self->re_dq($op->last,  $extended);
4199         return re_dq_disambiguate($first, $last);
4200     } elsif ($type eq "uc") {
4201         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4202     } elsif ($type eq "lc") {
4203         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4204     } elsif ($type eq "ucfirst") {
4205         return '\u' . $self->re_dq($op->first->sibling, $extended);
4206     } elsif ($type eq "lcfirst") {
4207         return '\l' . $self->re_dq($op->first->sibling, $extended);
4208     } elsif ($type eq "quotemeta") {
4209         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4210     } elsif ($type eq "join") {
4211         return $self->deparse($op->last, 26); # was join($", @ary)
4212     } else {
4213         return $self->deparse($op, 26);
4214     }
4215 }
4216
4217 sub pure_string {
4218     my ($self, $op) = @_;
4219     return 0 if null $op;
4220     my $type = $op->name;
4221
4222     if ($type eq 'const') {
4223         return 1;
4224     }
4225     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4226         return $self->pure_string($op->first->sibling);
4227     }
4228     elsif ($type eq 'join') {
4229         my $join_op = $op->first->sibling;  # Skip pushmark
4230         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4231
4232         my $gvop = $join_op->first;
4233         return 0 unless $gvop->name eq 'gvsv';
4234         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4235
4236         return 0 unless ${$join_op->sibling} eq ${$op->last};
4237         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4238     }
4239     elsif ($type eq 'concat') {
4240         return $self->pure_string($op->first)
4241             && $self->pure_string($op->last);
4242     }
4243     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4244         return 1;
4245     }
4246     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4247            $op->first->name eq "null" and $op->first->can('first')
4248            and not null $op->first->first and
4249            $op->first->first->name eq "aelemfast") {
4250         return 1;
4251     }
4252     else {
4253         return 0;
4254     }
4255
4256     return 1;
4257 }
4258
4259 sub regcomp {
4260     my $self = shift;
4261     my($op, $cx, $extended) = @_;
4262     my $kid = $op->first;
4263     $kid = $kid->first if $kid->name eq "regcmaybe";
4264     $kid = $kid->first if $kid->name eq "regcreset";
4265     if ($kid->name eq "null" and !null($kid->first)
4266         and $kid->first->name eq 'pushmark')
4267     {
4268         my $str = '';
4269         $kid = $kid->first->sibling;
4270         while (!null($kid)) {
4271             my $first = $str;
4272             my $last = $self->re_dq($kid, $extended);
4273             $str = re_dq_disambiguate($first, $last);
4274             $kid = $kid->sibling;
4275         }
4276         return $str, 1;
4277     }
4278
4279     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4280     return ($self->deparse($kid, $cx), 0);
4281 }
4282
4283 sub pp_regcomp {
4284     my ($self, $op, $cx) = @_;
4285     return (($self->regcomp($op, $cx, 0))[0]);
4286 }
4287
4288 # osmic acid -- see osmium tetroxide
4289
4290 my %matchwords;
4291 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4292     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4293     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4294
4295 sub matchop {
4296     my $self = shift;
4297     my($op, $cx, $name, $delim) = @_;
4298     my $kid = $op->first;
4299     my ($binop, $var, $re) = ("", "", "");
4300     if ($op->flags & OPf_STACKED) {
4301         $binop = 1;
4302         $var = $self->deparse($kid, 20);
4303         $kid = $kid->sibling;
4304     }
4305     my $quote = 1;
4306     my $extended = ($op->pmflags & PMf_EXTENDED);
4307     my $rhs_bound_to_defsv;
4308     if (null $kid) {
4309         my $unbacked = re_unback($op->precomp);
4310         if ($extended) {
4311             $re = re_uninterp_extended(escape_extended_re($unbacked));
4312         } else {
4313             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4314         }
4315     } elsif ($kid->name ne 'regcomp') {
4316         carp("found ".$kid->name." where regcomp expected");
4317     } else {
4318         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4319         $rhs_bound_to_defsv = 1 if $kid->first->first->flags & OPf_SPECIAL;
4320     }
4321     my $flags = "";
4322     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4323     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4324     $flags .= "i" if $op->pmflags & PMf_FOLD;
4325     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4326     $flags .= "o" if $op->pmflags & PMf_KEEP;
4327     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4328     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4329     $flags = $matchwords{$flags} if $matchwords{$flags};
4330     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4331         $re =~ s/\?/\\?/g;
4332         $re = "?$re?";
4333     } elsif ($quote) {
4334         $re = single_delim($name, $delim, $re);
4335     }
4336     $re = $re . $flags if $quote;
4337     if ($binop) {
4338         return
4339          $self->maybe_parens(
4340           $rhs_bound_to_defsv
4341            ? "$var =~ (\$_ =~ $re)"
4342            : "$var =~ $re",
4343           $cx, 20
4344          );
4345     } else {
4346         return $re;
4347     }
4348 }
4349
4350 sub pp_match { matchop(@_, "m", "/") }
4351 sub pp_pushre { matchop(@_, "m", "/") }
4352 sub pp_qr { matchop(@_, "qr", "") }
4353
4354 sub pp_split {
4355     my $self = shift;
4356     my($op, $cx) = @_;
4357     my($kid, @exprs, $ary, $expr);
4358     $kid = $op->first;