This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Document issues when using named captures in combination with a branch reset pattern...
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as /ms, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal
93 or hex escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.
99 X</x>
100
101 =head2 Regular Expressions
102
103 =head3 Metacharacters
104
105 The patterns used in Perl pattern matching evolved from those supplied in
106 the Version 8 regex routines.  (The routines are derived
107 (distantly) from Henry Spencer's freely redistributable reimplementation
108 of the V8 routines.)  See L<Version 8 Regular Expressions> for
109 details.
110
111 In particular the following metacharacters have their standard I<egrep>-ish
112 meanings:
113 X<metacharacter>
114 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
115
116
117     \   Quote the next metacharacter
118     ^   Match the beginning of the line
119     .   Match any character (except newline)
120     $   Match the end of the line (or before newline at the end)
121     |   Alternation
122     ()  Grouping
123     []  Character class
124
125 By default, the "^" character is guaranteed to match only the
126 beginning of the string, the "$" character only the end (or before the
127 newline at the end), and Perl does certain optimizations with the
128 assumption that the string contains only one line.  Embedded newlines
129 will not be matched by "^" or "$".  You may, however, wish to treat a
130 string as a multi-line buffer, such that the "^" will match after any
131 newline within the string (except if the newline is the last character in
132 the string), and "$" will match before any newline.  At the
133 cost of a little more overhead, you can do this by using the /m modifier
134 on the pattern match operator.  (Older programs did this by setting C<$*>,
135 but this practice has been removed in perl 5.9.)
136 X<^> X<$> X</m>
137
138 To simplify multi-line substitutions, the "." character never matches a
139 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
140 the string is a single line--even if it isn't.
141 X<.> X</s>
142
143 =head3 Quantifiers
144
145 The following standard quantifiers are recognized:
146 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
147
148     *      Match 0 or more times
149     +      Match 1 or more times
150     ?      Match 1 or 0 times
151     {n}    Match exactly n times
152     {n,}   Match at least n times
153     {n,m}  Match at least n but not more than m times
154
155 (If a curly bracket occurs in any other context, it is treated
156 as a regular character.  In particular, the lower bound
157 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
158 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
159 to integral values less than a preset limit defined when perl is built.
160 This is usually 32766 on the most common platforms.  The actual limit can
161 be seen in the error message generated by code such as this:
162
163     $_ **= $_ , / {$_} / for 2 .. 42;
164
165 By default, a quantified subpattern is "greedy", that is, it will match as
166 many times as possible (given a particular starting location) while still
167 allowing the rest of the pattern to match.  If you want it to match the
168 minimum number of times possible, follow the quantifier with a "?".  Note
169 that the meanings don't change, just the "greediness":
170 X<metacharacter> X<greedy> X<greediness>
171 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
172
173     *?     Match 0 or more times, not greedily
174     +?     Match 1 or more times, not greedily
175     ??     Match 0 or 1 time, not greedily
176     {n}?   Match exactly n times, not greedily
177     {n,}?  Match at least n times, not greedily
178     {n,m}? Match at least n but not more than m times, not greedily
179
180 By default, when a quantified subpattern does not allow the rest of the
181 overall pattern to match, Perl will backtrack. However, this behaviour is
182 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
183 as well.
184
185     *+     Match 0 or more times and give nothing back
186     ++     Match 1 or more times and give nothing back
187     ?+     Match 0 or 1 time and give nothing back
188     {n}+   Match exactly n times and give nothing back (redundant)
189     {n,}+  Match at least n times and give nothing back
190     {n,m}+ Match at least n but not more than m times and give nothing back
191
192 For instance,
193
194    'aaaa' =~ /a++a/
195
196 will never match, as the C<a++> will gobble up all the C<a>'s in the
197 string and won't leave any for the remaining part of the pattern. This
198 feature can be extremely useful to give perl hints about where it
199 shouldn't backtrack. For instance, the typical "match a double-quoted
200 string" problem can be most efficiently performed when written as:
201
202    /"(?:[^"\\]++|\\.)*+"/
203
204 as we know that if the final quote does not match, backtracking will not
205 help. See the independent subexpression C<< (?>...) >> for more details;
206 possessive quantifiers are just syntactic sugar for that construct. For
207 instance the above example could also be written as follows:
208
209    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
210
211 =head3 Escape sequences
212
213 Because patterns are processed as double quoted strings, the following
214 also work:
215 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
216 X<\0> X<\c> X<\N> X<\x>
217
218     \t          tab                   (HT, TAB)
219     \n          newline               (LF, NL)
220     \r          return                (CR)
221     \f          form feed             (FF)
222     \a          alarm (bell)          (BEL)
223     \e          escape (think troff)  (ESC)
224     \033        octal char            (example: ESC)
225     \x1B        hex char              (example: ESC)
226     \x{263a}    long hex char         (example: Unicode SMILEY)
227     \cK         control char          (example: VT)
228     \N{name}    named Unicode character
229     \l          lowercase next char (think vi)
230     \u          uppercase next char (think vi)
231     \L          lowercase till \E (think vi)
232     \U          uppercase till \E (think vi)
233     \E          end case modification (think vi)
234     \Q          quote (disable) pattern metacharacters till \E
235
236 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
237 and C<\U> is taken from the current locale.  See L<perllocale>.  For
238 documentation of C<\N{name}>, see L<charnames>.
239
240 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
241 An unescaped C<$> or C<@> interpolates the corresponding variable,
242 while escaping will cause the literal string C<\$> to be matched.
243 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
244
245 =head3 Character Classes and other Special Escapes
246
247 In addition, Perl defines the following:
248 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
249 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
250 X<word> X<whitespace> X<character class> X<backreference>
251
252     \w       Match a "word" character (alphanumeric plus "_")
253     \W       Match a non-"word" character
254     \s       Match a whitespace character
255     \S       Match a non-whitespace character
256     \d       Match a digit character
257     \D       Match a non-digit character
258     \pP      Match P, named property.  Use \p{Prop} for longer names.
259     \PP      Match non-P
260     \X       Match eXtended Unicode "combining character sequence",
261              equivalent to (?>\PM\pM*)
262     \C       Match a single C char (octet) even under Unicode.
263              NOTE: breaks up characters into their UTF-8 bytes,
264              so you may end up with malformed pieces of UTF-8.
265              Unsupported in lookbehind.
266     \1       Backreference to a specific group.
267              '1' may actually be any positive integer.
268     \g1      Backreference to a specific or previous group,
269     \g{-1}   number may be negative indicating a previous buffer and may
270              optionally be wrapped in curly brackets for safer parsing.
271     \g{name} Named backreference
272     \k<name> Named backreference
273     \K       Keep the stuff left of the \K, don't include it in $&
274     \N       Any character but \n
275     \v       Vertical whitespace
276     \V       Not vertical whitespace
277     \h       Horizontal whitespace
278     \H       Not horizontal whitespace
279     \R       Linebreak
280
281 A C<\w> matches a single alphanumeric character (an alphabetic
282 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
283 to match a string of Perl-identifier characters (which isn't the same
284 as matching an English word).  If C<use locale> is in effect, the list
285 of alphabetic characters generated by C<\w> is taken from the current
286 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
287 C<\d>, and C<\D> within character classes, but they aren't usable
288 as either end of a range. If any of them precedes or follows a "-",
289 the "-" is understood literally. If Unicode is in effect, C<\s> matches
290 also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
291 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
292 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
293 in general.
294 X<\w> X<\W> X<word>
295
296 C<\R> will atomically match a linebreak, including the network line-ending
297 "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
298
299   (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
300
301 B<Note:> C<\R> has no special meaning inside of a character class;
302 use C<\v> instead (vertical whitespace).
303 X<\R>
304
305 The POSIX character class syntax
306 X<character class>
307
308     [:class:]
309
310 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
311 they must always be used within a character class expression.
312
313     # this is correct:
314     $string =~ /[[:alpha:]]/;
315
316     # this is not, and will generate a warning:
317     $string =~ /[:alpha:]/;
318
319 The following table shows the mapping of POSIX character class
320 names, common escapes, literal escape sequences and their equivalent
321 Unicode style property names.
322 X<character class> X<\p> X<\p{}>
323 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
324 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
325
326 B<Note:> up to Perl 5.10 the property names used were shared with
327 standard Unicode properties, this was changed in Perl 5.11, see
328 L<perl5110delta> for details.
329
330     POSIX  Esc  Class               Property            Note
331     --------------------------------------------------------
332     alnum       [0-9A-Za-z]         IsPosixAlnum
333     alpha       [A-Za-z]            IsPosixAlpha
334     ascii       [\000-\177]         IsASCII
335     blank       [\011 ]             IsPosixBlank        [1]
336     cntrl       [\0-\37\177]        IsPosixCntrl
337     digit   \d  [0-9]               IsPosixDigit
338     graph       [!-~]               IsPosixGraph
339     lower       [a-z]               IsPosixLower
340     print       [ -~]               IsPosixPrint
341     punct       [!-/:-@[-`{-~]      IsPosixPunct
342     space       [\11-\15 ]          IsPosixSpace        [2]
343             \s  [\11\12\14\15 ]     IsPerlSpace         [2]
344     upper       [A-Z]               IsPosixUpper
345     word    \w  [0-9A-Z_a-z]        IsPerlWord          [3]
346     xdigit      [0-9A-Fa-f]         IsXDigit
347
348 =over
349
350 =item [1]
351
352 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
353
354 =item [2]
355
356 Note that C<\s> and C<[[:space:]]> are B<not> equivalent as C<[[:space:]]>
357 includes also the (very rare) "vertical tabulator", "\cK" or chr(11) in
358 ASCII.
359
360 =item [3]
361
362 A Perl extension, see above.
363
364 =back
365
366 For example use C<[:upper:]> to match all the uppercase characters.
367 Note that the C<[]> are part of the C<[::]> construct, not part of the
368 whole character class.  For example:
369
370     [01[:alpha:]%]
371
372 matches zero, one, any alphabetic character, and the percent sign.
373
374 =over 4
375
376 =item C<$>
377
378 Currency symbol
379
380 =item C<+> C<< < >> C<=> C<< > >> C<|> C<~>
381
382 Mathematical symbols
383
384 =item C<^> C<`>
385
386 Modifier symbols (accents)
387
388
389 =back
390
391 The other named classes are:
392
393 =over 4
394
395 =item cntrl
396 X<cntrl>
397
398 Any control character.  Usually characters that don't produce output as
399 such but instead control the terminal somehow: for example newline and
400 backspace are control characters.  All characters with ord() less than
401 32 are usually classified as control characters (assuming ASCII,
402 the ISO Latin character sets, and Unicode), as is the character with
403 the ord() value of 127 (C<DEL>).
404
405 =item graph
406 X<graph>
407
408 Any alphanumeric or punctuation (special) character.
409
410 =item print
411 X<print>
412
413 Any alphanumeric or punctuation (special) character or the space character.
414
415 =item punct
416 X<punct>
417
418 Any punctuation (special) character.
419
420 =item xdigit
421 X<xdigit>
422
423 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
424 work just fine) it is included for completeness.
425
426 =back
427
428 You can negate the [::] character classes by prefixing the class name
429 with a '^'. This is a Perl extension.  For example:
430 X<character class, negation>
431
432     POSIX         traditional  Unicode
433
434     [[:^digit:]]    \D         \P{IsPosixDigit}
435     [[:^space:]]    \S         \P{IsPosixSpace}
436     [[:^word:]]     \W         \P{IsPerlWord}
437
438 Perl respects the POSIX standard in that POSIX character classes are
439 only supported within a character class.  The POSIX character classes
440 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
441 use them will cause an error.
442
443 =head3 Assertions
444
445 Perl defines the following zero-width assertions:
446 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
447 X<regexp, zero-width assertion>
448 X<regular expression, zero-width assertion>
449 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
450
451     \b  Match a word boundary
452     \B  Match except at a word boundary
453     \A  Match only at beginning of string
454     \Z  Match only at end of string, or before newline at the end
455     \z  Match only at end of string
456     \G  Match only at pos() (e.g. at the end-of-match position
457         of prior m//g)
458
459 A word boundary (C<\b>) is a spot between two characters
460 that has a C<\w> on one side of it and a C<\W> on the other side
461 of it (in either order), counting the imaginary characters off the
462 beginning and end of the string as matching a C<\W>.  (Within
463 character classes C<\b> represents backspace rather than a word
464 boundary, just as it normally does in any double-quoted string.)
465 The C<\A> and C<\Z> are just like "^" and "$", except that they
466 won't match multiple times when the C</m> modifier is used, while
467 "^" and "$" will match at every internal line boundary.  To match
468 the actual end of the string and not ignore an optional trailing
469 newline, use C<\z>.
470 X<\b> X<\A> X<\Z> X<\z> X</m>
471
472 The C<\G> assertion can be used to chain global matches (using
473 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
474 It is also useful when writing C<lex>-like scanners, when you have
475 several patterns that you want to match against consequent substrings
476 of your string, see the previous reference.  The actual location
477 where C<\G> will match can also be influenced by using C<pos()> as
478 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
479 matches is modified somewhat, in that contents to the left of C<\G> is
480 not counted when determining the length of the match. Thus the following
481 will not match forever:
482 X<\G>
483
484     $str = 'ABC';
485     pos($str) = 1;
486     while (/.\G/g) {
487         print $&;
488     }
489
490 It will print 'A' and then terminate, as it considers the match to
491 be zero-width, and thus will not match at the same position twice in a
492 row.
493
494 It is worth noting that C<\G> improperly used can result in an infinite
495 loop. Take care when using patterns that include C<\G> in an alternation.
496
497 =head3 Capture buffers
498
499 The bracketing construct C<( ... )> creates capture buffers. To refer
500 to the current contents of a buffer later on, within the same pattern,
501 use \1 for the first, \2 for the second, and so on.
502 Outside the match use "$" instead of "\".  (The
503 \<digit> notation works in certain circumstances outside
504 the match.  See the warning below about \1 vs $1 for details.)
505 Referring back to another part of the match is called a
506 I<backreference>.
507 X<regex, capture buffer> X<regexp, capture buffer>
508 X<regular expression, capture buffer> X<backreference>
509
510 There is no limit to the number of captured substrings that you may
511 use.  However Perl also uses \10, \11, etc. as aliases for \010,
512 \011, etc.  (Recall that 0 means octal, so \011 is the character at
513 number 9 in your coded character set; which would be the 10th character,
514 a horizontal tab under ASCII.)  Perl resolves this
515 ambiguity by interpreting \10 as a backreference only if at least 10
516 left parentheses have opened before it.  Likewise \11 is a
517 backreference only if at least 11 left parentheses have opened
518 before it.  And so on.  \1 through \9 are always interpreted as
519 backreferences.
520
521 If the bracketing group did not match, the associated backreference won't
522 match either. (This can happen if the bracketing group is optional, or
523 in a different branch of an alternation.)
524
525 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
526 In order to provide a safer and easier way to construct patterns using
527 backreferences, Perl provides the C<\g{N}> notation (starting with perl
528 5.10.0). The curly brackets are optional, however omitting them is less
529 safe as the meaning of the pattern can be changed by text (such as digits)
530 following it. When N is a positive integer the C<\g{N}> notation is
531 exactly equivalent to using normal backreferences. When N is a negative
532 integer then it is a relative backreference referring to the previous N'th
533 capturing group. When the bracket form is used and N is not an integer, it
534 is treated as a reference to a named buffer.
535
536 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
537 buffer before that. For example:
538
539         /
540          (Y)            # buffer 1
541          (              # buffer 2
542             (X)         # buffer 3
543             \g{-1}      # backref to buffer 3
544             \g{-3}      # backref to buffer 1
545          )
546         /x
547
548 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
549
550 Additionally, as of Perl 5.10.0 you may use named capture buffers and named
551 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
552 to reference. You may also use apostrophes instead of angle brackets to delimit the
553 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
554 It's possible to refer to a named capture buffer by absolute and relative number as well.
555 Outside the pattern, a named capture buffer is available via the C<%+> hash.
556 When different buffers within the same pattern have the same name, C<$+{name}>
557 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
558 to do things with named capture buffers that would otherwise require C<(??{})>
559 code to accomplish.)
560 X<named capture buffer> X<regular expression, named capture buffer>
561 X<%+> X<$+{name}> X<< \k<name> >>
562
563 Examples:
564
565     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
566
567     /(.)\1/                         # find first doubled char
568          and print "'$1' is the first doubled character\n";
569
570     /(?<char>.)\k<char>/            # ... a different way
571          and print "'$+{char}' is the first doubled character\n";
572
573     /(?'char'.)\1/                  # ... mix and match
574          and print "'$1' is the first doubled character\n";
575
576     if (/Time: (..):(..):(..)/) {   # parse out values
577         $hours = $1;
578         $minutes = $2;
579         $seconds = $3;
580     }
581
582 Several special variables also refer back to portions of the previous
583 match.  C<$+> returns whatever the last bracket match matched.
584 C<$&> returns the entire matched string.  (At one point C<$0> did
585 also, but now it returns the name of the program.)  C<$`> returns
586 everything before the matched string.  C<$'> returns everything
587 after the matched string. And C<$^N> contains whatever was matched by
588 the most-recently closed group (submatch). C<$^N> can be used in
589 extended patterns (see below), for example to assign a submatch to a
590 variable.
591 X<$+> X<$^N> X<$&> X<$`> X<$'>
592
593 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
594 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
595 until the end of the enclosing block or until the next successful
596 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
597 X<$+> X<$^N> X<$&> X<$`> X<$'>
598 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
599
600
601 B<NOTE>: Failed matches in Perl do not reset the match variables,
602 which makes it easier to write code that tests for a series of more
603 specific cases and remembers the best match.
604
605 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
606 C<$'> anywhere in the program, it has to provide them for every
607 pattern match.  This may substantially slow your program.  Perl
608 uses the same mechanism to produce $1, $2, etc, so you also pay a
609 price for each pattern that contains capturing parentheses.  (To
610 avoid this cost while retaining the grouping behaviour, use the
611 extended regular expression C<(?: ... )> instead.)  But if you never
612 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
613 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
614 if you can, but if you can't (and some algorithms really appreciate
615 them), once you've used them once, use them at will, because you've
616 already paid the price.  As of 5.005, C<$&> is not so costly as the
617 other two.
618 X<$&> X<$`> X<$'>
619
620 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
621 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
622 and C<$'>, B<except> that they are only guaranteed to be defined after a
623 successful match that was executed with the C</p> (preserve) modifier.
624 The use of these variables incurs no global performance penalty, unlike
625 their punctuation char equivalents, however at the trade-off that you
626 have to tell perl when you want to use them.
627 X</p> X<p modifier>
628
629 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
630 C<\w>, C<\n>.  Unlike some other regular expression languages, there
631 are no backslashed symbols that aren't alphanumeric.  So anything
632 that looks like \\, \(, \), \<, \>, \{, or \} is always
633 interpreted as a literal character, not a metacharacter.  This was
634 once used in a common idiom to disable or quote the special meanings
635 of regular expression metacharacters in a string that you want to
636 use for a pattern. Simply quote all non-"word" characters:
637
638     $pattern =~ s/(\W)/\\$1/g;
639
640 (If C<use locale> is set, then this depends on the current locale.)
641 Today it is more common to use the quotemeta() function or the C<\Q>
642 metaquoting escape sequence to disable all metacharacters' special
643 meanings like this:
644
645     /$unquoted\Q$quoted\E$unquoted/
646
647 Beware that if you put literal backslashes (those not inside
648 interpolated variables) between C<\Q> and C<\E>, double-quotish
649 backslash interpolation may lead to confusing results.  If you
650 I<need> to use literal backslashes within C<\Q...\E>,
651 consult L<perlop/"Gory details of parsing quoted constructs">.
652
653 =head2 Extended Patterns
654
655 Perl also defines a consistent extension syntax for features not
656 found in standard tools like B<awk> and B<lex>.  The syntax is a
657 pair of parentheses with a question mark as the first thing within
658 the parentheses.  The character after the question mark indicates
659 the extension.
660
661 The stability of these extensions varies widely.  Some have been
662 part of the core language for many years.  Others are experimental
663 and may change without warning or be completely removed.  Check
664 the documentation on an individual feature to verify its current
665 status.
666
667 A question mark was chosen for this and for the minimal-matching
668 construct because 1) question marks are rare in older regular
669 expressions, and 2) whenever you see one, you should stop and
670 "question" exactly what is going on.  That's psychology...
671
672 =over 10
673
674 =item C<(?#text)>
675 X<(?#)>
676
677 A comment.  The text is ignored.  If the C</x> modifier enables
678 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
679 the comment as soon as it sees a C<)>, so there is no way to put a literal
680 C<)> in the comment.
681
682 =item C<(?pimsx-imsx)>
683 X<(?)>
684
685 One or more embedded pattern-match modifiers, to be turned on (or
686 turned off, if preceded by C<->) for the remainder of the pattern or
687 the remainder of the enclosing pattern group (if any). This is
688 particularly useful for dynamic patterns, such as those read in from a
689 configuration file, taken from an argument, or specified in a table
690 somewhere.  Consider the case where some patterns want to be case
691 sensitive and some do not:  The case insensitive ones merely need to
692 include C<(?i)> at the front of the pattern.  For example:
693
694     $pattern = "foobar";
695     if ( /$pattern/i ) { }
696
697     # more flexible:
698
699     $pattern = "(?i)foobar";
700     if ( /$pattern/ ) { }
701
702 These modifiers are restored at the end of the enclosing group. For example,
703
704     ( (?i) blah ) \s+ \1
705
706 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
707 repetition of the previous word, assuming the C</x> modifier, and no C</i>
708 modifier outside this group.
709
710 These modifiers do not carry over into named subpatterns called in the
711 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
712 change the case-sensitivity of the "NAME" pattern.
713
714 Note that the C<p> modifier is special in that it can only be enabled,
715 not disabled, and that its presence anywhere in a pattern has a global
716 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
717 when executed under C<use warnings>.
718
719 =item C<(?:pattern)>
720 X<(?:)>
721
722 =item C<(?imsx-imsx:pattern)>
723
724 This is for clustering, not capturing; it groups subexpressions like
725 "()", but doesn't make backreferences as "()" does.  So
726
727     @fields = split(/\b(?:a|b|c)\b/)
728
729 is like
730
731     @fields = split(/\b(a|b|c)\b/)
732
733 but doesn't spit out extra fields.  It's also cheaper not to capture
734 characters if you don't need to.
735
736 Any letters between C<?> and C<:> act as flags modifiers as with
737 C<(?imsx-imsx)>.  For example,
738
739     /(?s-i:more.*than).*million/i
740
741 is equivalent to the more verbose
742
743     /(?:(?s-i)more.*than).*million/i
744
745 =item C<(?|pattern)>
746 X<(?|)> X<Branch reset>
747
748 This is the "branch reset" pattern, which has the special property
749 that the capture buffers are numbered from the same starting point
750 in each alternation branch. It is available starting from perl 5.10.0.
751
752 Capture buffers are numbered from left to right, but inside this
753 construct the numbering is restarted for each branch.
754
755 The numbering within each branch will be as normal, and any buffers
756 following this construct will be numbered as though the construct
757 contained only one branch, that being the one with the most capture
758 buffers in it.
759
760 This construct will be useful when you want to capture one of a
761 number of alternative matches.
762
763 Consider the following pattern.  The numbers underneath show in
764 which buffer the captured content will be stored.
765
766
767     # before  ---------------branch-reset----------- after        
768     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
769     # 1            2         2  3        2     3     4  
770
771 Be careful when using the branch reset pattern in combination with 
772 named captures. Named captures are implemented as being aliases to 
773 numbered buffers holding the captures, and that interferes with the
774 implementation of the branch reset pattern. If you are using named
775 captures in a branch reset pattern, it's best to use the same names,
776 in the same order, in each of the alternations:
777
778    /(?|  (?<a> x ) (?<b> y )
779       |  (?<a> z ) (?<b> w )) /x
780
781 Not doing so may lead to surprises:
782
783   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
784   say $+ {a};   # Prints '12'
785   say $+ {b};   # *Also* prints '12'.
786
787 The problem here is that both the buffer named C<< a >> and the buffer
788 named C<< b >> are aliases for the buffer belonging to C<< $1 >>.
789
790 =item Look-Around Assertions
791 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
792
793 Look-around assertions are zero width patterns which match a specific
794 pattern without including it in C<$&>. Positive assertions match when
795 their subpattern matches, negative assertions match when their subpattern
796 fails. Look-behind matches text up to the current match position,
797 look-ahead matches text following the current match position.
798
799 =over 4
800
801 =item C<(?=pattern)>
802 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
803
804 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
805 matches a word followed by a tab, without including the tab in C<$&>.
806
807 =item C<(?!pattern)>
808 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
809
810 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
811 matches any occurrence of "foo" that isn't followed by "bar".  Note
812 however that look-ahead and look-behind are NOT the same thing.  You cannot
813 use this for look-behind.
814
815 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
816 will not do what you want.  That's because the C<(?!foo)> is just saying that
817 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
818 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
819 say "like" because there's the case of your "bar" not having three characters
820 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
821 Sometimes it's still easier just to say:
822
823     if (/bar/ && $` !~ /foo$/)
824
825 For look-behind see below.
826
827 =item C<(?<=pattern)> C<\K>
828 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
829
830 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
831 matches a word that follows a tab, without including the tab in C<$&>.
832 Works only for fixed-width look-behind.
833
834 There is a special form of this construct, called C<\K>, which causes the
835 regex engine to "keep" everything it had matched prior to the C<\K> and
836 not include it in C<$&>. This effectively provides variable length
837 look-behind. The use of C<\K> inside of another look-around assertion
838 is allowed, but the behaviour is currently not well defined.
839
840 For various reasons C<\K> may be significantly more efficient than the
841 equivalent C<< (?<=...) >> construct, and it is especially useful in
842 situations where you want to efficiently remove something following
843 something else in a string. For instance
844
845   s/(foo)bar/$1/g;
846
847 can be rewritten as the much more efficient
848
849   s/foo\Kbar//g;
850
851 =item C<(?<!pattern)>
852 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
853
854 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
855 matches any occurrence of "foo" that does not follow "bar".  Works
856 only for fixed-width look-behind.
857
858 =back
859
860 =item C<(?'NAME'pattern)>
861
862 =item C<< (?<NAME>pattern) >>
863 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
864
865 A named capture buffer. Identical in every respect to normal capturing
866 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
867 used after a successful match to refer to a named buffer. See C<perlvar>
868 for more details on the C<%+> and C<%-> hashes.
869
870 If multiple distinct capture buffers have the same name then the
871 $+{NAME} will refer to the leftmost defined buffer in the match.
872
873 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
874
875 B<NOTE:> While the notation of this construct is the same as the similar
876 function in .NET regexes, the behavior is not. In Perl the buffers are
877 numbered sequentially regardless of being named or not. Thus in the
878 pattern
879
880   /(x)(?<foo>y)(z)/
881
882 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
883 the opposite which is what a .NET regex hacker might expect.
884
885 Currently NAME is restricted to simple identifiers only.
886 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
887 its Unicode extension (see L<utf8>),
888 though it isn't extended by the locale (see L<perllocale>).
889
890 B<NOTE:> In order to make things easier for programmers with experience
891 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
892 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
893 support the use of single quotes as a delimiter for the name.
894
895 =item C<< \k<NAME> >>
896
897 =item C<< \k'NAME' >>
898
899 Named backreference. Similar to numeric backreferences, except that
900 the group is designated by name and not number. If multiple groups
901 have the same name then it refers to the leftmost defined group in
902 the current match.
903
904 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
905 earlier in the pattern.
906
907 Both forms are equivalent.
908
909 B<NOTE:> In order to make things easier for programmers with experience
910 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
911 may be used instead of C<< \k<NAME> >>.
912
913 =item C<(?{ code })>
914 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
915
916 B<WARNING>: This extended regular expression feature is considered
917 experimental, and may be changed without notice. Code executed that
918 has side effects may not perform identically from version to version
919 due to the effect of future optimisations in the regex engine.
920
921 This zero-width assertion evaluates any embedded Perl code.  It
922 always succeeds, and its C<code> is not interpolated.  Currently,
923 the rules to determine where the C<code> ends are somewhat convoluted.
924
925 This feature can be used together with the special variable C<$^N> to
926 capture the results of submatches in variables without having to keep
927 track of the number of nested parentheses. For example:
928
929   $_ = "The brown fox jumps over the lazy dog";
930   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
931   print "color = $color, animal = $animal\n";
932
933 Inside the C<(?{...})> block, C<$_> refers to the string the regular
934 expression is matching against. You can also use C<pos()> to know what is
935 the current position of matching within this string.
936
937 The C<code> is properly scoped in the following sense: If the assertion
938 is backtracked (compare L<"Backtracking">), all changes introduced after
939 C<local>ization are undone, so that
940
941   $_ = 'a' x 8;
942   m<
943      (?{ $cnt = 0 })                    # Initialize $cnt.
944      (
945        a
946        (?{
947            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
948        })
949      )*
950      aaaa
951      (?{ $res = $cnt })                 # On success copy to non-localized
952                                         # location.
953    >x;
954
955 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
956 introduced value, because the scopes that restrict C<local> operators
957 are unwound.
958
959 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
960 switch.  If I<not> used in this way, the result of evaluation of
961 C<code> is put into the special variable C<$^R>.  This happens
962 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
963 inside the same regular expression.
964
965 The assignment to C<$^R> above is properly localized, so the old
966 value of C<$^R> is restored if the assertion is backtracked; compare
967 L<"Backtracking">.
968
969 For reasons of security, this construct is forbidden if the regular
970 expression involves run-time interpolation of variables, unless the
971 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
972 variables contain results of C<qr//> operator (see
973 L<perlop/"qr/STRING/imosx">).
974
975 This restriction is due to the wide-spread and remarkably convenient
976 custom of using run-time determined strings as patterns.  For example:
977
978     $re = <>;
979     chomp $re;
980     $string =~ /$re/;
981
982 Before Perl knew how to execute interpolated code within a pattern,
983 this operation was completely safe from a security point of view,
984 although it could raise an exception from an illegal pattern.  If
985 you turn on the C<use re 'eval'>, though, it is no longer secure,
986 so you should only do so if you are also using taint checking.
987 Better yet, use the carefully constrained evaluation within a Safe
988 compartment.  See L<perlsec> for details about both these mechanisms.
989
990 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
991 broken. The result is unpredictable and will make perl unstable. The
992 workaround is to use global (C<our>) variables.
993
994 B<WARNING>: Because Perl's regex engine is currently not re-entrant,
995 interpolated code may not invoke the regex engine either directly with
996 C<m//> or C<s///>), or indirectly with functions such as
997 C<split>. Invoking the regex engine in these blocks will make perl
998 unstable.
999
1000 =item C<(??{ code })>
1001 X<(??{})>
1002 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1003
1004 B<WARNING>: This extended regular expression feature is considered
1005 experimental, and may be changed without notice. Code executed that
1006 has side effects may not perform identically from version to version
1007 due to the effect of future optimisations in the regex engine.
1008
1009 This is a "postponed" regular subexpression.  The C<code> is evaluated
1010 at run time, at the moment this subexpression may match.  The result
1011 of evaluation is considered as a regular expression and matched as
1012 if it were inserted instead of this construct.  Note that this means
1013 that the contents of capture buffers defined inside an eval'ed pattern
1014 are not available outside of the pattern, and vice versa, there is no
1015 way for the inner pattern to refer to a capture buffer defined outside.
1016 Thus,
1017
1018     ('a' x 100)=~/(??{'(.)' x 100})/
1019
1020 B<will> match, it will B<not> set $1.
1021
1022 The C<code> is not interpolated.  As before, the rules to determine
1023 where the C<code> ends are currently somewhat convoluted.
1024
1025 The following pattern matches a parenthesized group:
1026
1027   $re = qr{
1028              \(
1029              (?:
1030                 (?> [^()]+ )    # Non-parens without backtracking
1031               |
1032                 (??{ $re })     # Group with matching parens
1033              )*
1034              \)
1035           }x;
1036
1037 See also C<(?PARNO)> for a different, more efficient way to accomplish
1038 the same task.
1039
1040 Because perl's regex engine is not currently re-entrant, delayed
1041 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1042 or indirectly with functions such as C<split>.
1043
1044 Recursing deeper than 50 times without consuming any input string will
1045 result in a fatal error.  The maximum depth is compiled into perl, so
1046 changing it requires a custom build.
1047
1048 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1049 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1050 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1051 X<regex, relative recursion>
1052
1053 Similar to C<(??{ code })> except it does not involve compiling any code,
1054 instead it treats the contents of a capture buffer as an independent
1055 pattern that must match at the current position.  Capture buffers
1056 contained by the pattern will have the value as determined by the
1057 outermost recursion.
1058
1059 PARNO is a sequence of digits (not starting with 0) whose value reflects
1060 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1061 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1062 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1063 to be relative, with negative numbers indicating preceding capture buffers
1064 and positive ones following. Thus C<(?-1)> refers to the most recently
1065 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1066 Note that the counting for relative recursion differs from that of
1067 relative backreferences, in that with recursion unclosed buffers B<are>
1068 included.
1069
1070 The following pattern matches a function foo() which may contain
1071 balanced parentheses as the argument.
1072
1073   $re = qr{ (                    # paren group 1 (full function)
1074               foo
1075               (                  # paren group 2 (parens)
1076                 \(
1077                   (              # paren group 3 (contents of parens)
1078                   (?:
1079                    (?> [^()]+ )  # Non-parens without backtracking
1080                   |
1081                    (?2)          # Recurse to start of paren group 2
1082                   )*
1083                   )
1084                 \)
1085               )
1086             )
1087           }x;
1088
1089 If the pattern was used as follows
1090
1091     'foo(bar(baz)+baz(bop))'=~/$re/
1092         and print "\$1 = $1\n",
1093                   "\$2 = $2\n",
1094                   "\$3 = $3\n";
1095
1096 the output produced should be the following:
1097
1098     $1 = foo(bar(baz)+baz(bop))
1099     $2 = (bar(baz)+baz(bop))
1100     $3 = bar(baz)+baz(bop)
1101
1102 If there is no corresponding capture buffer defined, then it is a
1103 fatal error.  Recursing deeper than 50 times without consuming any input
1104 string will also result in a fatal error.  The maximum depth is compiled
1105 into perl, so changing it requires a custom build.
1106
1107 The following shows how using negative indexing can make it
1108 easier to embed recursive patterns inside of a C<qr//> construct
1109 for later use:
1110
1111     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1112     if (/foo $parens \s+ + \s+ bar $parens/x) {
1113        # do something here...
1114     }
1115
1116 B<Note> that this pattern does not behave the same way as the equivalent
1117 PCRE or Python construct of the same form. In Perl you can backtrack into
1118 a recursed group, in PCRE and Python the recursed into group is treated
1119 as atomic. Also, modifiers are resolved at compile time, so constructs
1120 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1121 be processed.
1122
1123 =item C<(?&NAME)>
1124 X<(?&NAME)>
1125
1126 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1127 parenthesis to recurse to is determined by name. If multiple parentheses have
1128 the same name, then it recurses to the leftmost.
1129
1130 It is an error to refer to a name that is not declared somewhere in the
1131 pattern.
1132
1133 B<NOTE:> In order to make things easier for programmers with experience
1134 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1135 may be used instead of C<< (?&NAME) >>.
1136
1137 =item C<(?(condition)yes-pattern|no-pattern)>
1138 X<(?()>
1139
1140 =item C<(?(condition)yes-pattern)>
1141
1142 Conditional expression.  C<(condition)> should be either an integer in
1143 parentheses (which is valid if the corresponding pair of parentheses
1144 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1145 name in angle brackets or single quotes (which is valid if a buffer
1146 with the given name matched), or the special symbol (R) (true when
1147 evaluated inside of recursion or eval). Additionally the R may be
1148 followed by a number, (which will be true when evaluated when recursing
1149 inside of the appropriate group), or by C<&NAME>, in which case it will
1150 be true only when evaluated during recursion in the named group.
1151
1152 Here's a summary of the possible predicates:
1153
1154 =over 4
1155
1156 =item (1) (2) ...
1157
1158 Checks if the numbered capturing buffer has matched something.
1159
1160 =item (<NAME>) ('NAME')
1161
1162 Checks if a buffer with the given name has matched something.
1163
1164 =item (?{ CODE })
1165
1166 Treats the code block as the condition.
1167
1168 =item (R)
1169
1170 Checks if the expression has been evaluated inside of recursion.
1171
1172 =item (R1) (R2) ...
1173
1174 Checks if the expression has been evaluated while executing directly
1175 inside of the n-th capture group. This check is the regex equivalent of
1176
1177   if ((caller(0))[3] eq 'subname') { ... }
1178
1179 In other words, it does not check the full recursion stack.
1180
1181 =item (R&NAME)
1182
1183 Similar to C<(R1)>, this predicate checks to see if we're executing
1184 directly inside of the leftmost group with a given name (this is the same
1185 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1186 stack, but only the name of the innermost active recursion.
1187
1188 =item (DEFINE)
1189
1190 In this case, the yes-pattern is never directly executed, and no
1191 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1192 See below for details.
1193
1194 =back
1195
1196 For example:
1197
1198     m{ ( \( )?
1199        [^()]+
1200        (?(1) \) )
1201      }x
1202
1203 matches a chunk of non-parentheses, possibly included in parentheses
1204 themselves.
1205
1206 A special form is the C<(DEFINE)> predicate, which never executes directly
1207 its yes-pattern, and does not allow a no-pattern. This allows to define
1208 subpatterns which will be executed only by using the recursion mechanism.
1209 This way, you can define a set of regular expression rules that can be
1210 bundled into any pattern you choose.
1211
1212 It is recommended that for this usage you put the DEFINE block at the
1213 end of the pattern, and that you name any subpatterns defined within it.
1214
1215 Also, it's worth noting that patterns defined this way probably will
1216 not be as efficient, as the optimiser is not very clever about
1217 handling them.
1218
1219 An example of how this might be used is as follows:
1220
1221   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1222    (?(DEFINE)
1223      (?<NAME_PAT>....)
1224      (?<ADRESS_PAT>....)
1225    )/x
1226
1227 Note that capture buffers matched inside of recursion are not accessible
1228 after the recursion returns, so the extra layer of capturing buffers is
1229 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1230 C<$+{NAME}> would be.
1231
1232 =item C<< (?>pattern) >>
1233 X<backtrack> X<backtracking> X<atomic> X<possessive>
1234
1235 An "independent" subexpression, one which matches the substring
1236 that a I<standalone> C<pattern> would match if anchored at the given
1237 position, and it matches I<nothing other than this substring>.  This
1238 construct is useful for optimizations of what would otherwise be
1239 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1240 It may also be useful in places where the "grab all you can, and do not
1241 give anything back" semantic is desirable.
1242
1243 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1244 (anchored at the beginning of string, as above) will match I<all>
1245 characters C<a> at the beginning of string, leaving no C<a> for
1246 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1247 since the match of the subgroup C<a*> is influenced by the following
1248 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1249 C<a*ab> will match fewer characters than a standalone C<a*>, since
1250 this makes the tail match.
1251
1252 An effect similar to C<< (?>pattern) >> may be achieved by writing
1253 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1254 C<a+>, and the following C<\1> eats the matched string; it therefore
1255 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1256 (The difference between these two constructs is that the second one
1257 uses a capturing group, thus shifting ordinals of backreferences
1258 in the rest of a regular expression.)
1259
1260 Consider this pattern:
1261
1262     m{ \(
1263           (
1264             [^()]+              # x+
1265           |
1266             \( [^()]* \)
1267           )+
1268        \)
1269      }x
1270
1271 That will efficiently match a nonempty group with matching parentheses
1272 two levels deep or less.  However, if there is no such group, it
1273 will take virtually forever on a long string.  That's because there
1274 are so many different ways to split a long string into several
1275 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1276 to a subpattern of the above pattern.  Consider how the pattern
1277 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1278 seconds, but that each extra letter doubles this time.  This
1279 exponential performance will make it appear that your program has
1280 hung.  However, a tiny change to this pattern
1281
1282     m{ \(
1283           (
1284             (?> [^()]+ )        # change x+ above to (?> x+ )
1285           |
1286             \( [^()]* \)
1287           )+
1288        \)
1289      }x
1290
1291 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1292 this yourself would be a productive exercise), but finishes in a fourth
1293 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1294 however, that this pattern currently triggers a warning message under
1295 the C<use warnings> pragma or B<-w> switch saying it
1296 C<"matches null string many times in regex">.
1297
1298 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1299 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1300 This was only 4 times slower on a string with 1000000 C<a>s.
1301
1302 The "grab all you can, and do not give anything back" semantic is desirable
1303 in many situations where on the first sight a simple C<()*> looks like
1304 the correct solution.  Suppose we parse text with comments being delimited
1305 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1306 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1307 the comment delimiter, because it may "give up" some whitespace if
1308 the remainder of the pattern can be made to match that way.  The correct
1309 answer is either one of these:
1310
1311     (?>#[ \t]*)
1312     #[ \t]*(?![ \t])
1313
1314 For example, to grab non-empty comments into $1, one should use either
1315 one of these:
1316
1317     / (?> \# [ \t]* ) (        .+ ) /x;
1318     /     \# [ \t]*   ( [^ \t] .* ) /x;
1319
1320 Which one you pick depends on which of these expressions better reflects
1321 the above specification of comments.
1322
1323 In some literature this construct is called "atomic matching" or
1324 "possessive matching".
1325
1326 Possessive quantifiers are equivalent to putting the item they are applied
1327 to inside of one of these constructs. The following equivalences apply:
1328
1329     Quantifier Form     Bracketing Form
1330     ---------------     ---------------
1331     PAT*+               (?>PAT*)
1332     PAT++               (?>PAT+)
1333     PAT?+               (?>PAT?)
1334     PAT{min,max}+       (?>PAT{min,max})
1335
1336 =back
1337
1338 =head2 Special Backtracking Control Verbs
1339
1340 B<WARNING:> These patterns are experimental and subject to change or
1341 removal in a future version of Perl. Their usage in production code should
1342 be noted to avoid problems during upgrades.
1343
1344 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1345 otherwise stated the ARG argument is optional; in some cases, it is
1346 forbidden.
1347
1348 Any pattern containing a special backtracking verb that allows an argument
1349 has the special behaviour that when executed it sets the current packages'
1350 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1351 rules apply:
1352
1353 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1354 verb pattern, if the verb was involved in the failure of the match. If the
1355 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1356 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1357 none. Also, the C<$REGMARK> variable will be set to FALSE.
1358
1359 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1360 the C<$REGMARK> variable will be set to the name of the last
1361 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1362 C<(*MARK:NAME)> verb below for more details.
1363
1364 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1365 and most other regex related variables. They are not local to a scope, nor
1366 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1367 Use C<local> to localize changes to them to a specific scope if necessary.
1368
1369 If a pattern does not contain a special backtracking verb that allows an
1370 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1371
1372 =over 4
1373
1374 =item Verbs that take an argument
1375
1376 =over 4
1377
1378 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1379 X<(*PRUNE)> X<(*PRUNE:NAME)>
1380
1381 This zero-width pattern prunes the backtracking tree at the current point
1382 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1383 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1384 A may backtrack as necessary to match. Once it is reached, matching
1385 continues in B, which may also backtrack as necessary; however, should B
1386 not match, then no further backtracking will take place, and the pattern
1387 will fail outright at the current starting position.
1388
1389 The following example counts all the possible matching strings in a
1390 pattern (without actually matching any of them).
1391
1392     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1393     print "Count=$count\n";
1394
1395 which produces:
1396
1397     aaab
1398     aaa
1399     aa
1400     a
1401     aab
1402     aa
1403     a
1404     ab
1405     a
1406     Count=9
1407
1408 If we add a C<(*PRUNE)> before the count like the following
1409
1410     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1411     print "Count=$count\n";
1412
1413 we prevent backtracking and find the count of the longest matching
1414 at each matching starting point like so:
1415
1416     aaab
1417     aab
1418     ab
1419     Count=3
1420
1421 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1422
1423 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1424 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1425 replaced with a C<< (?>pattern) >> with no functional difference; however,
1426 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1427 C<< (?>pattern) >> alone.
1428
1429
1430 =item C<(*SKIP)> C<(*SKIP:NAME)>
1431 X<(*SKIP)>
1432
1433 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1434 failure it also signifies that whatever text that was matched leading up
1435 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1436 of this pattern. This effectively means that the regex engine "skips" forward
1437 to this position on failure and tries to match again, (assuming that
1438 there is sufficient room to match).
1439
1440 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1441 C<(*MARK:NAME)> was encountered while matching, then it is that position
1442 which is used as the "skip point". If no C<(*MARK)> of that name was
1443 encountered, then the C<(*SKIP)> operator has no effect. When used
1444 without a name the "skip point" is where the match point was when
1445 executing the (*SKIP) pattern.
1446
1447 Compare the following to the examples in C<(*PRUNE)>, note the string
1448 is twice as long:
1449
1450     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1451     print "Count=$count\n";
1452
1453 outputs
1454
1455     aaab
1456     aaab
1457     Count=2
1458
1459 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1460 executed, the next starting point will be where the cursor was when the
1461 C<(*SKIP)> was executed.
1462
1463 =item C<(*MARK:NAME)> C<(*:NAME)>
1464 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1465
1466 This zero-width pattern can be used to mark the point reached in a string
1467 when a certain part of the pattern has been successfully matched. This
1468 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1469 forward to that point if backtracked into on failure. Any number of
1470 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1471 be duplicated.
1472
1473 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1474 can be used to "label" a pattern branch, so that after matching, the
1475 program can determine which branches of the pattern were involved in the
1476 match.
1477
1478 When a match is successful, the C<$REGMARK> variable will be set to the
1479 name of the most recently executed C<(*MARK:NAME)> that was involved
1480 in the match.
1481
1482 This can be used to determine which branch of a pattern was matched
1483 without using a separate capture buffer for each branch, which in turn
1484 can result in a performance improvement, as perl cannot optimize
1485 C</(?:(x)|(y)|(z))/> as efficiently as something like
1486 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1487
1488 When a match has failed, and unless another verb has been involved in
1489 failing the match and has provided its own name to use, the C<$REGERROR>
1490 variable will be set to the name of the most recently executed
1491 C<(*MARK:NAME)>.
1492
1493 See C<(*SKIP)> for more details.
1494
1495 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1496
1497 =item C<(*THEN)> C<(*THEN:NAME)>
1498
1499 This is similar to the "cut group" operator C<::> from Perl 6. Like
1500 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1501 failure, it causes the regex engine to try the next alternation in the
1502 innermost enclosing group (capturing or otherwise).
1503
1504 Its name comes from the observation that this operation combined with the
1505 alternation operator (C<|>) can be used to create what is essentially a
1506 pattern-based if/then/else block:
1507
1508   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1509
1510 Note that if this operator is used and NOT inside of an alternation then
1511 it acts exactly like the C<(*PRUNE)> operator.
1512
1513   / A (*PRUNE) B /
1514
1515 is the same as
1516
1517   / A (*THEN) B /
1518
1519 but
1520
1521   / ( A (*THEN) B | C (*THEN) D ) /
1522
1523 is not the same as
1524
1525   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1526
1527 as after matching the A but failing on the B the C<(*THEN)> verb will
1528 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1529
1530 =item C<(*COMMIT)>
1531 X<(*COMMIT)>
1532
1533 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1534 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1535 into on failure it causes the match to fail outright. No further attempts
1536 to find a valid match by advancing the start pointer will occur again.
1537 For example,
1538
1539     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1540     print "Count=$count\n";
1541
1542 outputs
1543
1544     aaab
1545     Count=1
1546
1547 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1548 does not match, the regex engine will not try any further matching on the
1549 rest of the string.
1550
1551 =back
1552
1553 =item Verbs without an argument
1554
1555 =over 4
1556
1557 =item C<(*FAIL)> C<(*F)>
1558 X<(*FAIL)> X<(*F)>
1559
1560 This pattern matches nothing and always fails. It can be used to force the
1561 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1562 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1563
1564 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1565
1566 =item C<(*ACCEPT)>
1567 X<(*ACCEPT)>
1568
1569 B<WARNING:> This feature is highly experimental. It is not recommended
1570 for production code.
1571
1572 This pattern matches nothing and causes the end of successful matching at
1573 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1574 whether there is actually more to match in the string. When inside of a
1575 nested pattern, such as recursion, or in a subpattern dynamically generated
1576 via C<(??{})>, only the innermost pattern is ended immediately.
1577
1578 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1579 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1580 For instance:
1581
1582   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1583
1584 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1585 be set. If another branch in the inner parentheses were matched, such as in the
1586 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1587
1588 =back
1589
1590 =back
1591
1592 =head2 Backtracking
1593 X<backtrack> X<backtracking>
1594
1595 NOTE: This section presents an abstract approximation of regular
1596 expression behavior.  For a more rigorous (and complicated) view of
1597 the rules involved in selecting a match among possible alternatives,
1598 see L<Combining RE Pieces>.
1599
1600 A fundamental feature of regular expression matching involves the
1601 notion called I<backtracking>, which is currently used (when needed)
1602 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1603 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1604 internally, but the general principle outlined here is valid.
1605
1606 For a regular expression to match, the I<entire> regular expression must
1607 match, not just part of it.  So if the beginning of a pattern containing a
1608 quantifier succeeds in a way that causes later parts in the pattern to
1609 fail, the matching engine backs up and recalculates the beginning
1610 part--that's why it's called backtracking.
1611
1612 Here is an example of backtracking:  Let's say you want to find the
1613 word following "foo" in the string "Food is on the foo table.":
1614
1615     $_ = "Food is on the foo table.";
1616     if ( /\b(foo)\s+(\w+)/i ) {
1617         print "$2 follows $1.\n";
1618     }
1619
1620 When the match runs, the first part of the regular expression (C<\b(foo)>)
1621 finds a possible match right at the beginning of the string, and loads up
1622 $1 with "Foo".  However, as soon as the matching engine sees that there's
1623 no whitespace following the "Foo" that it had saved in $1, it realizes its
1624 mistake and starts over again one character after where it had the
1625 tentative match.  This time it goes all the way until the next occurrence
1626 of "foo". The complete regular expression matches this time, and you get
1627 the expected output of "table follows foo."
1628
1629 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1630 everything between "foo" and "bar".  Initially, you write something
1631 like this:
1632
1633     $_ =  "The food is under the bar in the barn.";
1634     if ( /foo(.*)bar/ ) {
1635         print "got <$1>\n";
1636     }
1637
1638 Which perhaps unexpectedly yields:
1639
1640   got <d is under the bar in the >
1641
1642 That's because C<.*> was greedy, so you get everything between the
1643 I<first> "foo" and the I<last> "bar".  Here it's more effective
1644 to use minimal matching to make sure you get the text between a "foo"
1645 and the first "bar" thereafter.
1646
1647     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1648   got <d is under the >
1649
1650 Here's another example. Let's say you'd like to match a number at the end
1651 of a string, and you also want to keep the preceding part of the match.
1652 So you write this:
1653
1654     $_ = "I have 2 numbers: 53147";
1655     if ( /(.*)(\d*)/ ) {                                # Wrong!
1656         print "Beginning is <$1>, number is <$2>.\n";
1657     }
1658
1659 That won't work at all, because C<.*> was greedy and gobbled up the
1660 whole string. As C<\d*> can match on an empty string the complete
1661 regular expression matched successfully.
1662
1663     Beginning is <I have 2 numbers: 53147>, number is <>.
1664
1665 Here are some variants, most of which don't work:
1666
1667     $_ = "I have 2 numbers: 53147";
1668     @pats = qw{
1669         (.*)(\d*)
1670         (.*)(\d+)
1671         (.*?)(\d*)
1672         (.*?)(\d+)
1673         (.*)(\d+)$
1674         (.*?)(\d+)$
1675         (.*)\b(\d+)$
1676         (.*\D)(\d+)$
1677     };
1678
1679     for $pat (@pats) {
1680         printf "%-12s ", $pat;
1681         if ( /$pat/ ) {
1682             print "<$1> <$2>\n";
1683         } else {
1684             print "FAIL\n";
1685         }
1686     }
1687
1688 That will print out:
1689
1690     (.*)(\d*)    <I have 2 numbers: 53147> <>
1691     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1692     (.*?)(\d*)   <> <>
1693     (.*?)(\d+)   <I have > <2>
1694     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1695     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1696     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1697     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1698
1699 As you see, this can be a bit tricky.  It's important to realize that a
1700 regular expression is merely a set of assertions that gives a definition
1701 of success.  There may be 0, 1, or several different ways that the
1702 definition might succeed against a particular string.  And if there are
1703 multiple ways it might succeed, you need to understand backtracking to
1704 know which variety of success you will achieve.
1705
1706 When using look-ahead assertions and negations, this can all get even
1707 trickier.  Imagine you'd like to find a sequence of non-digits not
1708 followed by "123".  You might try to write that as
1709
1710     $_ = "ABC123";
1711     if ( /^\D*(?!123)/ ) {              # Wrong!
1712         print "Yup, no 123 in $_\n";
1713     }
1714
1715 But that isn't going to match; at least, not the way you're hoping.  It
1716 claims that there is no 123 in the string.  Here's a clearer picture of
1717 why that pattern matches, contrary to popular expectations:
1718
1719     $x = 'ABC123';
1720     $y = 'ABC445';
1721
1722     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1723     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1724
1725     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1726     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1727
1728 This prints
1729
1730     2: got ABC
1731     3: got AB
1732     4: got ABC
1733
1734 You might have expected test 3 to fail because it seems to a more
1735 general purpose version of test 1.  The important difference between
1736 them is that test 3 contains a quantifier (C<\D*>) and so can use
1737 backtracking, whereas test 1 will not.  What's happening is
1738 that you've asked "Is it true that at the start of $x, following 0 or more
1739 non-digits, you have something that's not 123?"  If the pattern matcher had
1740 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1741 fail.
1742
1743 The search engine will initially match C<\D*> with "ABC".  Then it will
1744 try to match C<(?!123> with "123", which fails.  But because
1745 a quantifier (C<\D*>) has been used in the regular expression, the
1746 search engine can backtrack and retry the match differently
1747 in the hope of matching the complete regular expression.
1748
1749 The pattern really, I<really> wants to succeed, so it uses the
1750 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1751 time.  Now there's indeed something following "AB" that is not
1752 "123".  It's "C123", which suffices.
1753
1754 We can deal with this by using both an assertion and a negation.
1755 We'll say that the first part in $1 must be followed both by a digit
1756 and by something that's not "123".  Remember that the look-aheads
1757 are zero-width expressions--they only look, but don't consume any
1758 of the string in their match.  So rewriting this way produces what
1759 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1760
1761     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1762     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1763
1764     6: got ABC
1765
1766 In other words, the two zero-width assertions next to each other work as though
1767 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1768 matches only if you're at the beginning of the line AND the end of the
1769 line simultaneously.  The deeper underlying truth is that juxtaposition in
1770 regular expressions always means AND, except when you write an explicit OR
1771 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1772 although the attempted matches are made at different positions because "a"
1773 is not a zero-width assertion, but a one-width assertion.
1774
1775 B<WARNING>: Particularly complicated regular expressions can take
1776 exponential time to solve because of the immense number of possible
1777 ways they can use backtracking to try for a match.  For example, without
1778 internal optimizations done by the regular expression engine, this will
1779 take a painfully long time to run:
1780
1781     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1782
1783 And if you used C<*>'s in the internal groups instead of limiting them
1784 to 0 through 5 matches, then it would take forever--or until you ran
1785 out of stack space.  Moreover, these internal optimizations are not
1786 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1787 on the external group, no current optimization is applicable, and the
1788 match takes a long time to finish.
1789
1790 A powerful tool for optimizing such beasts is what is known as an
1791 "independent group",
1792 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1793 zero-length look-ahead/look-behind assertions will not backtrack to make
1794 the tail match, since they are in "logical" context: only
1795 whether they match is considered relevant.  For an example
1796 where side-effects of look-ahead I<might> have influenced the
1797 following match, see L<C<< (?>pattern) >>>.
1798
1799 =head2 Version 8 Regular Expressions
1800 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1801
1802 In case you're not familiar with the "regular" Version 8 regex
1803 routines, here are the pattern-matching rules not described above.
1804
1805 Any single character matches itself, unless it is a I<metacharacter>
1806 with a special meaning described here or above.  You can cause
1807 characters that normally function as metacharacters to be interpreted
1808 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1809 character; "\\" matches a "\"). This escape mechanism is also required
1810 for the character used as the pattern delimiter.
1811
1812 A series of characters matches that series of characters in the target
1813 string, so the pattern  C<blurfl> would match "blurfl" in the target
1814 string.
1815
1816 You can specify a character class, by enclosing a list of characters
1817 in C<[]>, which will match any character from the list.  If the
1818 first character after the "[" is "^", the class matches any character not
1819 in the list.  Within a list, the "-" character specifies a
1820 range, so that C<a-z> represents all characters between "a" and "z",
1821 inclusive.  If you want either "-" or "]" itself to be a member of a
1822 class, put it at the start of the list (possibly after a "^"), or
1823 escape it with a backslash.  "-" is also taken literally when it is
1824 at the end of the list, just before the closing "]".  (The
1825 following all specify the same class of three characters: C<[-az]>,
1826 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1827 specifies a class containing twenty-six characters, even on EBCDIC-based
1828 character sets.)  Also, if you try to use the character
1829 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1830 a range, the "-" is understood literally.
1831
1832 Note also that the whole range idea is rather unportable between
1833 character sets--and even within character sets they may cause results
1834 you probably didn't expect.  A sound principle is to use only ranges
1835 that begin from and end at either alphabetics of equal case ([a-e],
1836 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1837 spell out the character sets in full.
1838
1839 Characters may be specified using a metacharacter syntax much like that
1840 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1841 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1842 of octal digits, matches the character whose coded character set value
1843 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1844 matches the character whose numeric value is I<nn>. The expression \cI<x>
1845 matches the character control-I<x>.  Finally, the "." metacharacter
1846 matches any character except "\n" (unless you use C</s>).
1847
1848 You can specify a series of alternatives for a pattern using "|" to
1849 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1850 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1851 first alternative includes everything from the last pattern delimiter
1852 ("(", "[", or the beginning of the pattern) up to the first "|", and
1853 the last alternative contains everything from the last "|" to the next
1854 pattern delimiter.  That's why it's common practice to include
1855 alternatives in parentheses: to minimize confusion about where they
1856 start and end.
1857
1858 Alternatives are tried from left to right, so the first
1859 alternative found for which the entire expression matches, is the one that
1860 is chosen. This means that alternatives are not necessarily greedy. For
1861 example: when matching C<foo|foot> against "barefoot", only the "foo"
1862 part will match, as that is the first alternative tried, and it successfully
1863 matches the target string. (This might not seem important, but it is
1864 important when you are capturing matched text using parentheses.)
1865
1866 Also remember that "|" is interpreted as a literal within square brackets,
1867 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1868
1869 Within a pattern, you may designate subpatterns for later reference
1870 by enclosing them in parentheses, and you may refer back to the
1871 I<n>th subpattern later in the pattern using the metacharacter
1872 \I<n>.  Subpatterns are numbered based on the left to right order
1873 of their opening parenthesis.  A backreference matches whatever
1874 actually matched the subpattern in the string being examined, not
1875 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1876 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1877 1 matched "0x", even though the rule C<0|0x> could potentially match
1878 the leading 0 in the second number.
1879
1880 =head2 Warning on \1 Instead of $1
1881
1882 Some people get too used to writing things like:
1883
1884     $pattern =~ s/(\W)/\\\1/g;
1885
1886 This is grandfathered for the RHS of a substitute to avoid shocking the
1887 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1888 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1889 the usual double-quoted string means a control-A.  The customary Unix
1890 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1891 of doing that, you get yourself into trouble if you then add an C</e>
1892 modifier.
1893
1894     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1895
1896 Or if you try to do
1897
1898     s/(\d+)/\1000/;
1899
1900 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1901 C<${1}000>.  The operation of interpolation should not be confused
1902 with the operation of matching a backreference.  Certainly they mean two
1903 different things on the I<left> side of the C<s///>.
1904
1905 =head2 Repeated Patterns Matching a Zero-length Substring
1906
1907 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1908
1909 Regular expressions provide a terse and powerful programming language.  As
1910 with most other power tools, power comes together with the ability
1911 to wreak havoc.
1912
1913 A common abuse of this power stems from the ability to make infinite
1914 loops using regular expressions, with something as innocuous as:
1915
1916     'foo' =~ m{ ( o? )* }x;
1917
1918 The C<o?> matches at the beginning of C<'foo'>, and since the position
1919 in the string is not moved by the match, C<o?> would match again and again
1920 because of the C<*> quantifier.  Another common way to create a similar cycle
1921 is with the looping modifier C<//g>:
1922
1923     @matches = ( 'foo' =~ m{ o? }xg );
1924
1925 or
1926
1927     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1928
1929 or the loop implied by split().
1930
1931 However, long experience has shown that many programming tasks may
1932 be significantly simplified by using repeated subexpressions that
1933 may match zero-length substrings.  Here's a simple example being:
1934
1935     @chars = split //, $string;           # // is not magic in split
1936     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1937
1938 Thus Perl allows such constructs, by I<forcefully breaking
1939 the infinite loop>.  The rules for this are different for lower-level
1940 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1941 ones like the C</g> modifier or split() operator.
1942
1943 The lower-level loops are I<interrupted> (that is, the loop is
1944 broken) when Perl detects that a repeated expression matched a
1945 zero-length substring.   Thus
1946
1947    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1948
1949 is made equivalent to
1950
1951    m{   (?: NON_ZERO_LENGTH )*
1952       |
1953         (?: ZERO_LENGTH )?
1954     }x;
1955
1956 The higher level-loops preserve an additional state between iterations:
1957 whether the last match was zero-length.  To break the loop, the following
1958 match after a zero-length match is prohibited to have a length of zero.
1959 This prohibition interacts with backtracking (see L<"Backtracking">),
1960 and so the I<second best> match is chosen if the I<best> match is of
1961 zero length.
1962
1963 For example:
1964
1965     $_ = 'bar';
1966     s/\w??/<$&>/g;
1967
1968 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1969 match given by non-greedy C<??> is the zero-length match, and the I<second
1970 best> match is what is matched by C<\w>.  Thus zero-length matches
1971 alternate with one-character-long matches.
1972
1973 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1974 position one notch further in the string.
1975
1976 The additional state of being I<matched with zero-length> is associated with
1977 the matched string, and is reset by each assignment to pos().
1978 Zero-length matches at the end of the previous match are ignored
1979 during C<split>.
1980
1981 =head2 Combining RE Pieces
1982
1983 Each of the elementary pieces of regular expressions which were described
1984 before (such as C<ab> or C<\Z>) could match at most one substring
1985 at the given position of the input string.  However, in a typical regular
1986 expression these elementary pieces are combined into more complicated
1987 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1988 (in these examples C<S> and C<T> are regular subexpressions).
1989
1990 Such combinations can include alternatives, leading to a problem of choice:
1991 if we match a regular expression C<a|ab> against C<"abc">, will it match
1992 substring C<"a"> or C<"ab">?  One way to describe which substring is
1993 actually matched is the concept of backtracking (see L<"Backtracking">).
1994 However, this description is too low-level and makes you think
1995 in terms of a particular implementation.
1996
1997 Another description starts with notions of "better"/"worse".  All the
1998 substrings which may be matched by the given regular expression can be
1999 sorted from the "best" match to the "worst" match, and it is the "best"
2000 match which is chosen.  This substitutes the question of "what is chosen?"
2001 by the question of "which matches are better, and which are worse?".
2002
2003 Again, for elementary pieces there is no such question, since at most
2004 one match at a given position is possible.  This section describes the
2005 notion of better/worse for combining operators.  In the description
2006 below C<S> and C<T> are regular subexpressions.
2007
2008 =over 4
2009
2010 =item C<ST>
2011
2012 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2013 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2014 which can be matched by C<T>.
2015
2016 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2017 match than C<A'B'>.
2018
2019 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2020 C<B> is better match for C<T> than C<B'>.
2021
2022 =item C<S|T>
2023
2024 When C<S> can match, it is a better match than when only C<T> can match.
2025
2026 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2027 two matches for C<T>.
2028
2029 =item C<S{REPEAT_COUNT}>
2030
2031 Matches as C<SSS...S> (repeated as many times as necessary).
2032
2033 =item C<S{min,max}>
2034
2035 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2036
2037 =item C<S{min,max}?>
2038
2039 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2040
2041 =item C<S?>, C<S*>, C<S+>
2042
2043 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2044
2045 =item C<S??>, C<S*?>, C<S+?>
2046
2047 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2048
2049 =item C<< (?>S) >>
2050
2051 Matches the best match for C<S> and only that.
2052
2053 =item C<(?=S)>, C<(?<=S)>
2054
2055 Only the best match for C<S> is considered.  (This is important only if
2056 C<S> has capturing parentheses, and backreferences are used somewhere
2057 else in the whole regular expression.)
2058
2059 =item C<(?!S)>, C<(?<!S)>
2060
2061 For this grouping operator there is no need to describe the ordering, since
2062 only whether or not C<S> can match is important.
2063
2064 =item C<(??{ EXPR })>, C<(?PARNO)>
2065
2066 The ordering is the same as for the regular expression which is
2067 the result of EXPR, or the pattern contained by capture buffer PARNO.
2068
2069 =item C<(?(condition)yes-pattern|no-pattern)>
2070
2071 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2072 already determined.  The ordering of the matches is the same as for the
2073 chosen subexpression.
2074
2075 =back
2076
2077 The above recipes describe the ordering of matches I<at a given position>.
2078 One more rule is needed to understand how a match is determined for the
2079 whole regular expression: a match at an earlier position is always better
2080 than a match at a later position.
2081
2082 =head2 Creating Custom RE Engines
2083
2084 Overloaded constants (see L<overload>) provide a simple way to extend
2085 the functionality of the RE engine.
2086
2087 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2088 matches at a boundary between whitespace characters and non-whitespace
2089 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2090 at these positions, so we want to have each C<\Y|> in the place of the
2091 more complicated version.  We can create a module C<customre> to do
2092 this:
2093
2094     package customre;
2095     use overload;
2096
2097     sub import {
2098       shift;
2099       die "No argument to customre::import allowed" if @_;
2100       overload::constant 'qr' => \&convert;
2101     }
2102
2103     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2104
2105     # We must also take care of not escaping the legitimate \\Y|
2106     # sequence, hence the presence of '\\' in the conversion rules.
2107     my %rules = ( '\\' => '\\\\',
2108                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2109     sub convert {
2110       my $re = shift;
2111       $re =~ s{
2112                 \\ ( \\ | Y . )
2113               }
2114               { $rules{$1} or invalid($re,$1) }sgex;
2115       return $re;
2116     }
2117
2118 Now C<use customre> enables the new escape in constant regular
2119 expressions, i.e., those without any runtime variable interpolations.
2120 As documented in L<overload>, this conversion will work only over
2121 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2122 part of this regular expression needs to be converted explicitly
2123 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2124
2125     use customre;
2126     $re = <>;
2127     chomp $re;
2128     $re = customre::convert $re;
2129     /\Y|$re\Y|/;
2130
2131 =head1 PCRE/Python Support
2132
2133 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2134 to the regex syntax. While Perl programmers are encouraged to use the
2135 Perl specific syntax, the following are also accepted:
2136
2137 =over 4
2138
2139 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2140
2141 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2142
2143 =item C<< (?P=NAME) >>
2144
2145 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2146
2147 =item C<< (?P>NAME) >>
2148
2149 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2150
2151 =back
2152
2153 =head1 BUGS
2154
2155 This document varies from difficult to understand to completely
2156 and utterly opaque.  The wandering prose riddled with jargon is
2157 hard to fathom in several places.
2158
2159 This document needs a rewrite that separates the tutorial content
2160 from the reference content.
2161
2162 =head1 SEE ALSO
2163
2164 L<perlrequick>.
2165
2166 L<perlretut>.
2167
2168 L<perlop/"Regexp Quote-Like Operators">.
2169
2170 L<perlop/"Gory details of parsing quoted constructs">.
2171
2172 L<perlfaq6>.
2173
2174 L<perlfunc/pos>.
2175
2176 L<perllocale>.
2177
2178 L<perlebcdic>.
2179
2180 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2181 by O'Reilly and Associates.